Lady’s Gitweb - Shushe/blob - lib/catalog2transform.xslt

   1 <?xml version="1.0"?>
   2 <!--
   3 SPDX-FileCopyrightText: 2023, 2024 Lady <https://www.ladys.computer/about/#lady>
   4 SPDX-License-Identifier: MPL-2.0
   5 -->
   6 <!--
   7 ⁌ ⛩📰 书社 ∷ lib/catalog2transform.xslt
   8
   9 © 2023–2024 Lady [@ Ladys Computer].
  10
  11 This Source Code Form is subject to the terms of the Mozilla Public License, v 2.0.
  12 If a copy of the M·P·L was not distributed with this file, You can obtain one at <https://mozilla.org/MPL/2.0/>.
  13 -->
  14 <!DOCTYPE transform [
  15         <!ENTITY 书社 "urn:fdc:ladys.computer:20231231:Shu1She4">
  16         <!ENTITY xml "http://www.w3.org/XML/1998/namespace">
  17 ]>
  18 <transform
  19         xmlns="http://www.w3.org/1999/XSL/Transform"
  20         xmlns:catalog="urn:oasis:names:tc:entity:xmlns:xml:catalog"
  21         xmlns:exsl="http://exslt.org/common"
  22         xmlns:exslstr="http://exslt.org/strings"
  23         xmlns:html="http://www.w3.org/1999/xhtml"
  24         xmlns:nie="http://www.semanticdesktop.org/ontologies/2007/01/19/nie#"
  25         xmlns:nfo="http://www.semanticdesktop.org/ontologies/2007/03/22/nfo#"
  26         xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
  27         xmlns:svg="http://www.w3.org/2000/svg"
  28         xmlns:xlink="http://www.w3.org/1999/xlink"
  29         xmlns:xslt="http://www.w3.org/1999/XSL/TransformAlias"
  30         xmlns:书社="urn:fdc:ladys.computer:20231231:Shu1She4"
  31         xmlns:书社vocab="urn:fdc:ladys.computer:20231231:Shu1She4:vocab:"
  32         exclude-result-prefixes="catalog"
  33         version="1.0"
  34 >
  35         <include href="literally.xslt"/>
  36         <namespace-alias stylesheet-prefix="xslt" result-prefix="#default"/>
  37         <param name="METADATA" select="'about:blank'"/>
  38         <variable name="builddir" select="document($METADATA)//书社vocab:BuildDirectory/@nfo:fileUrl"/>
  39         <template match="/">
  40                 <variable name="ids">
  41                         <for-each select="//catalog:uri[@name]">
  42                                 <书社:id>
  43                                         <value-of select="@name"/>
  44                                 </书社:id>
  45                         </for-each>
  46                 </variable>
  47                 <variable name="unique-ids">
  48                         <for-each select="exsl:node-set($ids)/*">
  49                                 <if test="not(preceding-sibling::*[string(.)=string(current())])">
  50                                         <copy-of select="."/>
  51                                 </if>
  52                         </for-each>
  53                 </variable>
  54                 <xslt:transform exclude-result-prefixes="nie nfo" extension-element-prefixes="exsl exslstr" version="1.0">
  55                         <xslt:param name="BUILDTIME" select="'1972-12-31T00:00:00Z'"/>
  56                         <xslt:param name="IDENTIFIER" select="false()"/>
  57                         <xslt:param name="SRCREV" select="false()"/>
  58                         <xslt:param name="THISREV" select="false()"/>
  59                         <xslt:variable name="书社:source" select="/"/>
  60                         <xslt:variable name="书社:about-fragment">
  61                                 <apply-templates select="document($METADATA)" mode="书社:literally">
  62                                         <with-param name="extension-element-namespaces" select="'http://exslt.org/common http://exslt.org/strings'"/>
  63                                 </apply-templates>
  64                         </xslt:variable>
  65                         <xslt:variable name="书社:about" select="exsl:node-set($书社:about-fragment)"/>
  66                         <xslt:variable name="书社:expansion-fragment">
  67                                 <xslt:apply-templates select="$书社:source/node()" mode="书社:expand"/>
  68                         </xslt:variable>
  69                         <xslt:variable name="书社:expansion" select="exsl:node-set($书社:expansion-fragment)"/>
  70                         <xslt:variable name="书社:result-fragment">
  71                                 <xslt:apply-templates select="$书社:expansion/node()"/>
  72                         </xslt:variable>
  73                         <xslt:variable name="书社:result" select="exsl:node-set($书社:result-fragment)"/>
  74                         <xslt:variable name="书社:destination" select="string($书社:about//*[@rdf:about=$IDENTIFIER]/@书社vocab:destination)"/>
  75                         <for-each select="//catalog:uri">
  76                                 <xslt:include href="{@uri}">
  77                                         <attribute name="书社:id">
  78                                                 <value-of select="@name"/>
  79                                         </attribute>
  80                                 </xslt:include>
  81                         </for-each>
  82                         <xslt:template name="书社:apply-attributes">
  83                                 <xslt:param name="and-version" select="false()"/>
  84                                 <xslt:param name="context-nodes" select="/.."/>
  85                                 <xslt:param name="destination-nodes" select="/.."/>
  86                                 <xslt:variable name="additional-attributes" select="$context-nodes/@*"/>
  87                                 <xslt:for-each select="$destination-nodes">
  88                                         <xslt:variable name="existing-attributes" select="@*"/>
  89                                         <xslt:choose>
  90                                                 <xslt:when test="self::*">
  91                                                         <xslt:variable name="context" select="."/>
  92                                                         <xslt:variable name="attribute-names">
  93                                                                 <xslt:for-each select="$existing-attributes|$additional-attributes">
  94                                                                         <书社:attribute>
  95                                                                                 <attribute name="local-name">
  96                                                                                         <text>{local-name()}</text>
  97                                                                                 </attribute>
  98                                                                                 <attribute name="name">
  99                                                                                         <text>{name()}</text>
 100                                                                                 </attribute>
 101                                                                                 <attribute name="namespace-uri">
 102                                                                                         <text>{namespace-uri()}</text>
 103                                                                                 </attribute>
 104                                                                         </书社:attribute>
 105                                                                 </xslt:for-each>
 106                                                         </xslt:variable>
 107                                                         <xslt:variable name="lang">
 108                                                                 <xslt:choose>
 109                                                                         <xslt:when test="(self::html:*|self::svg:*)/@lang">
 110                                                                                 <xslt:value-of select="@lang"/>
 111                                                                         </xslt:when>
 112                                                                         <xslt:when test="@xml:lang">
 113                                                                                 <xslt:value-of select="@xml:lang"/>
 114                                                                         </xslt:when>
 115                                                                         <xslt:when test="$additional-attributes[(parent::html:* or parent::svg:*) and namespace-uri()='' and local-name()='lang']">
 116                                                                                 <xslt:value-of select="$additional-attributes[(parent::html:* or parent::svg:*) and namespace-uri()='' and local-name()='lang']"/>
 117                                                                         </xslt:when>
 118                                                                         <xslt:when test="(self::html:* or self::svg:*) and $additional-attributes[(parent::书社:apply-attributes or parent::书社:apply-attributes-to-root) and namespace-uri()='' and local-name()='lang']">
 119                                                                                 <xslt:value-of select="$additional-attributes[(parent::书社:apply-attributes or parent::书社:apply-attributes-to-root) and namespace-uri()='' and local-name()='lang']"/>
 120                                                                         </xslt:when>
 121                                                                         <xslt:when test="$additional-attributes[namespace-uri()='&xml;' and local-name()='lang']">
 122                                                                                 <xslt:value-of select="$additional-attributes[namespace-uri()='&xml;' and local-name()='lang']"/>
 123                                                                         </xslt:when>
 124                                                                 </xslt:choose>
 125                                                         </xslt:variable>
 126                                                         <xslt:copy>
 127                                                                 <xslt:if test="$and-version and $THISREV">
 128                                                                         <xslt:attribute name="书社:version">
 129                                                                                 <xslt:value-of select="$THISREV"/>
 130                                                                         </xslt:attribute>
 131                                                                 </xslt:if>
 132                                                                 <xslt:if test="string($lang)!=''">
 133                                                                         <xslt:if test="self::html:* or self::svg:*">
 134                                                                                 <xslt:attribute name="lang">
 135                                                                                         <xslt:value-of select="$lang"/>
 136                                                                                 </xslt:attribute>
 137                                                                         </xslt:if>
 138                                                                         <xslt:attribute name="xml:lang">
 139                                                                                 <xslt:value-of select="$lang"/>
 140                                                                         </xslt:attribute>
 141                                                                 </xslt:if>
 142                                                                 <xslt:for-each select="exsl:node-set($attribute-names)/*">
 143                                                                         <xslt:choose>
 144                                                                                 <xslt:when test="@namespace-uri='&xml;'"/>
 145                                                                                 <xslt:when test="$context[self::html:* or self::svg:*] and @namespace-uri='' and @local-name='lang'"/>
 146                                                                                 <xslt:when test="@namespace-uri='&书社;' and @local-name='archived-as' and not($context-nodes/ancestor::*[not(self::书社:apply-attributes-to-root or self::书社:apply-attributes)][1][self::书社:archive])"/>
 147                                                                                 <xslt:when test="@namespace-uri='&书社;' and (@local-name='destination' or @local-name='disable-output-wrapping' or @local-name='version')"/>
 148                                                                                 <xslt:when test="preceding-sibling::*[@local-name=current()/@local-name and @namespace-uri=current()/@namespace-uri]"/>
 149                                                                                 <xslt:otherwise>
 150                                                                                         <xslt:attribute>
 151                                                                                                 <attribute name="name">
 152                                                                                                         <text>{@name}</text>
 153                                                                                                 </attribute>
 154                                                                                                 <attribute name="namespace">
 155                                                                                                         <text>{@namespace-uri}</text>
 156                                                                                                 </attribute>
 157                                                                                                 <xslt:for-each select="$existing-attributes[local-name()=current()/@local-name and namespace-uri()=current()/@namespace-uri]">
 158                                                                                                         <xslt:value-of select="."/>
 159                                                                                                         <xslt:if test="position()!=last()">
 160                                                                                                                 <xslt:text>
 161                                                                                                                         <text> </text>
 162                                                                                                                 </xslt:text>
 163                                                                                                         </xslt:if>
 164                                                                                                 </xslt:for-each>
 165                                                                                                 <xslt:if test="$existing-attributes[local-name()=current()/@local-name and namespace-uri()=current()/@namespace-uri] and $additional-attributes[local-name()=current()/@local-name and namespace-uri()=current()/@namespace-uri]">
 166                                                                                                         <xslt:text>
 167                                                                                                                 <text> </text>
 168                                                                                                         </xslt:text>
 169                                                                                                 </xslt:if>
 170                                                                                                 <xslt:for-each select="$additional-attributes[local-name()=current()/@local-name and namespace-uri()=current()/@namespace-uri]">
 171                                                                                                         <xslt:value-of select="."/>
 172                                                                                                         <xslt:if test="position()!=last()">
 173                                                                                                                 <xslt:text>
 174                                                                                                                         <text> </text>
 175                                                                                                                 </xslt:text>
 176                                                                                                         </xslt:if>
 177                                                                                                 </xslt:for-each>
 178                                                                                         </xslt:attribute>
 179                                                                                 </xslt:otherwise>
 180                                                                         </xslt:choose>
 181                                                                 </xslt:for-each>
 182                                                                 <xslt:copy-of select="node()"/>
 183                                                         </xslt:copy>
 184                                                 </xslt:when>
 185                                                 <xslt:otherwise>
 186                                                         <xslt:copy-of select="."/>
 187                                                 </xslt:otherwise>
 188                                         </xslt:choose>
 189                                 </xslt:for-each>
 190                         </xslt:template>
 191                         <xslt:template name="书社:wrap">
 192                                 <xslt:param name="nodes" select="/.."/>
 193                                 <xslt:variable name="modalinput-fragment">
 194                                         <xslt:copy-of select="$nodes"/>
 195                                         <apply-templates select="exsl:node-set($unique-ids)" mode="书社:literally"/>
 196                                 </xslt:variable>
 197                                 <xslt:variable name="modalinput" select="exsl:node-set($modalinput-fragment)"/>
 198                                 <xslt:variable name="metadata-fragment">
 199                                         <xslt:copy-of select="$nodes[self::html:html]/html:head/node()|$nodes[self::html:head]/node()"/>
 200                                         <xslt:apply-templates select="$modalinput/node()" mode="书社:metadata"/>
 201                                 </xslt:variable>
 202                                 <xslt:variable name="metadata" select="exsl:node-set($metadata-fragment)"/>
 203                                 <html:html>
 204                                         <xslt:copy-of select="$nodes[self::html:html]/@*"/>
 205                                         <xslt:if test="not($nodes[self::html:html]/@书社:archived-as) and $nodes/@书社:archived-as">
 206                                                 <xslt:attribute name="书社:archived-as">
 207                                                         <xslt:value-of select="$nodes/@书社:archived-as"/>
 208                                                 </xslt:attribute>
 209                                         </xslt:if>
 210                                         <xslt:if test="not($nodes[self::html:html]/@lang) and $nodes[self::html:*]/@lang|$nodes[self::svg:*]/@lang|$nodes/@xml:lang">
 211                                                 <xslt:attribute name="lang">
 212                                                         <xslt:value-of select="$nodes[self::html:*]/@lang|$nodes[self::svg:*]/@lang|$nodes/@xml:lang"/>
 213                                                 </xslt:attribute>
 214                                         </xslt:if>
 215                                         <xslt:if test="not($nodes[self::html:html]/@xml:lang) and $nodes[self::html:*]/@lang|$nodes[self::svg:*]/@lang|$nodes/@xml:lang">
 216                                                 <xslt:attribute name="xml:lang">
 217                                                         <xslt:value-of select="$nodes[self::html:*]/@lang|$nodes[self::svg:*]/@lang|$nodes/@xml:lang"/>
 218                                                 </xslt:attribute>
 219                                         </xslt:if>
 220                                         <html:head>
 221                                                 <xslt:copy-of select="$nodes[self::html:html]/html:head/@*|$nodes[self::html:head]/@*"/>
 222                                                 <html:title>
 223                                                         <xslt:for-each select="$metadata/html:title">
 224                                                                 <xslt:value-of select="."/>
 225                                                                 <xslt:if test="position()!=last()">
 226                                                                         <xslt:text>
 227                                                                                 <text> </text>
 228                                                                         </xslt:text>
 229                                                                 </xslt:if>
 230                                                         </xslt:for-each>
 231                                                 </html:title>
 232                                                 <xslt:copy-of select="$metadata/node()[not(self::html:title or self::html:meta and @name='generator')]"/>
 233                                                 <html:meta name="generator">
 234                                                         <xslt:attribute name="content">
 235                                                                 <xslt:for-each select="$metadata/html:meta[@name='generator']">
 236                                                                         <xslt:value-of select="@content"/>
 237                                                                         <xslt:text>
 238                                                                                 <text>, </text>
 239                                                                         </xslt:text>
 240                                                                 </xslt:for-each>
 241                                                                 <xslt:text>
 242                                                                         <text>⛩📰 书社</text>
 243                                                                 </xslt:text>
 244                                                                 <xslt:if test="$THISREV">
 245                                                                         <xslt:text>
 246                                                                                 <text> (</text>
 247                                                                         </xslt:text>
 248                                                                         <xslt:value-of select="$THISREV"/>
 249                                                                         <xslt:text>
 250                                                                                 <text>)</text>
 251                                                                         </xslt:text>
 252                                                                 </xslt:if>
 253                                                         </xslt:attribute>
 254                                                 </html:meta>
 255                                         </html:head>
 256                                         <html:body>
 257                                                 <xslt:copy-of select="$nodes[self::html:html]/html:body/@*|$nodes[self::html:body]/@*"/>
 258                                                 <xslt:apply-templates select="$modalinput/node()" mode="书社:header"/>
 259                                                 <xslt:copy-of select="$nodes[not(self::html:html or self::html:head or self::html:body)]|$nodes[self::html:html]/node()[not(self::html:head or self::html:body)]|$nodes[self::html:html]/html:body/node()|$nodes[self::html:body]/node()"/>
 260                                                 <xslt:apply-templates select="$modalinput/node()" mode="书社:footer"/>
 261                                         </html:body>
 262                                 </html:html>
 263                         </xslt:template>
 264                         <xslt:template match="/" priority="1">
 265                                 <xslt:variable name="result-nodes" select="$书社:result/node()[not(self::书社:apply-attributes-to-root)]|$书社:result/书社:apply-attributes-to-root/descendant::node()[not(self::书社:apply-attributes-to-root) and not(ancestor::*[not(self::书社:apply-attributes-to-root)])]"/>
 266                                 <xslt:variable name="root-with-attributes">
 267                                         <xslt:choose>
 268                                                 <xslt:when test="not($result-nodes/self::html:*) or $result-nodes/self::书社:*[local-name()='raw-text' or local-name()='base64-binary' or local-name()='archive'] or $result-nodes/@书社:disable-output-wrapping or $书社:result//书社:apply-attributes-to-root/@书社:disable-output-wrapping">
 269                                                         <xslt:call-template name="书社:apply-attributes">
 270                                                                 <xslt:with-param name="and-version" select="true()"/>
 271                                                                 <xslt:with-param name="context-nodes" select="$书社:result//书社:apply-attributes-to-root"/>
 272                                                                 <xslt:with-param name="destination-nodes" select="$result-nodes"/>
 273                                                         </xslt:call-template>
 274                                                 </xslt:when>
 275                                                 <xslt:otherwise>
 276                                                         <xslt:variable name="wrapped-result">
 277                                                                 <xslt:call-template name="书社:wrap">
 278                                                                         <xslt:with-param name="nodes" select="$result-nodes"/>
 279                                                                 </xslt:call-template>
 280                                                         </xslt:variable>
 281                                                         <xslt:call-template name="书社:apply-attributes">
 282                                                                 <xslt:with-param name="and-version" select="true()"/>
 283                                                                 <xslt:with-param name="context-nodes" select="$书社:result//书社:apply-attributes-to-root"/>
 284                                                                 <xslt:with-param name="destination-nodes" select="exsl:node-set($wrapped-result)/node()"/>
 285                                                         </xslt:call-template>
 286                                                 </xslt:otherwise>
 287                                         </xslt:choose>
 288                                 </xslt:variable>
 289                                 <xslt:apply-templates select="exsl:node-set($root-with-attributes)/node()" mode="书社:apply"/>
 290                         </xslt:template>
 291                         <xslt:template match="@*|node()" priority="-1">
 292                                 <xslt:copy>
 293                                         <xslt:apply-templates select="@*|node()"/>
 294                                 </xslt:copy>
 295                         </xslt:template>
 296                         <xslt:template match="@书社:destination|@书社:disable-output-wrapping|@书社:archived-as[../ancestor::*[not(self::书社:apply-attributes-to-root or self::书社:apply-attributes)]]" mode="书社:apply" priority="1"/>
 297                         <xslt:template match="书社:archive" mode="书社:apply" priority="1">
 298                                 <xslt:copy>
 299                                         <xslt:for-each select="@*">
 300                                                 <xslt:choose>
 301                                                         <xslt:when test="local-name()='archived-as' and namespace-uri()='&书社;' and ../ancestor::*[not(self::书社:apply-attributes-to-root or self::书社:apply-attributes)]"/>
 302                                                         <xslt:otherwise>
 303                                                                 <xslt:apply-templates select="." mode="书社:apply"/>
 304                                                         </xslt:otherwise>
 305                                                 </xslt:choose>
 306                                         </xslt:for-each>
 307                                         <xslt:for-each select="node()">
 308                                                 <xslt:choose>
 309                                                         <xslt:when test="self::*">
 310                                                                 <xslt:variable name="component">
 311                                                                         <xslt:choose>
 312                                                                                 <xslt:when test="self::书社:*[local-name()='raw-text' or local-name()='base64-binary' or local-name()='archive']|@书社:disable-output-wrapping">
 313                                                                                         <xslt:copy-of select="."/>
 314                                                                                 </xslt:when>
 315                                                                                 <xslt:otherwise>
 316                                                                                         <xslt:call-template name="书社:wrap">
 317                                                                                                 <xslt:with-param name="nodes" select="."/>
 318                                                                                         </xslt:call-template>
 319                                                                                 </xslt:otherwise>
 320                                                                         </xslt:choose>
 321                                                                 </xslt:variable>
 322                                                                 <xslt:apply-templates select="exsl:node-set($component)/node()" mode="书社:apply"/>
 323                                                         </xslt:when>
 324                                                         <xslt:otherwise>
 325                                                                 <xslt:apply-templates select="." mode="书社:apply"/>
 326                                                         </xslt:otherwise>
 327                                                 </xslt:choose>
 328                                         </xslt:for-each>
 329                                 </xslt:copy>
 330                         </xslt:template>
 331                         <xslt:template match="书社:apply-attributes" mode="书社:apply" priority="1">
 332                                 <xslt:variable name="children">
 333                                         <xslt:apply-templates mode="书社:apply"/>
 334                                 </xslt:variable>
 335                                 <xslt:call-template name="书社:apply-attributes">
 336                                         <xslt:with-param name="context-nodes" select="."/>
 337                                         <xslt:with-param name="destination-nodes" select="exsl:node-set($children)/node()"/>
 338                                 </xslt:call-template>
 339                         </xslt:template>
 340                         <xslt:template match="书社:apply-attributes-to-root" mode="书社:apply" priority="1">
 341                                 <xslt:apply-templates mode="书社:apply"/>
 342                         </xslt:template>
 343                         <xslt:template match="@*|node()" mode="书社:apply" priority="-1">
 344                                 <xslt:copy>
 345                                         <xslt:apply-templates select="@*|node()" mode="书社:apply"/>
 346                                 </xslt:copy>
 347                         </xslt:template>
 348                         <xslt:template match="书社:link[@xlink:show='embed' and (not(@xlink:actuate) or @xlink:actuate='none')]" mode="书社:expand" priority="1">
 349                                 <xslt:variable name="identifier" select="string(@xlink:href)"/>
 350                                 <xslt:variable name="is-dir" select="substring($identifier, string-length($identifier))='/'"/>
 351                                 <xslt:variable name="included" select="$书社:about//*[@rdf:about=$identifier or $is-dir and starts-with(@rdf:about, $identifier)]"/>
 352                                 <xslt:choose>
 353                                         <xslt:when test="$included">
 354                                                 <xslt:for-each select="$included">
 355                                                         <xslt:sort select="@rdf:about" data-type="text" lang="zxx" case-order="upper-first"/>
 356                                                         <xslt:variable name="uri" select="书社vocab:hasParsedFile/@nfo:fileUrl"/>
 357                                                         <xslt:variable name="expanded">
 358                                                                 <xslt:apply-templates select="document($uri)" mode="书社:expand">
 359                                                                         <xslt:with-param name="identifier" select="string(@rdf:about)"/>
 360                                                                 </xslt:apply-templates>
 361                                                         </xslt:variable>
 362                                                         <xslt:for-each select="exsl:node-set($expanded)/node()">
 363                                                                 <xslt:copy>
 364                                                                         <xslt:choose>
 365                                                                                 <xslt:when test="self::html:*">
 366                                                                                         <xslt:attribute name="itemscope">itemscope</xslt:attribute>
 367                                                                                         <xslt:attribute name="itemtype">
 368                                                                                                 <xslt:text>
 369                                                                                                         <text>&书社;:embed</text>
 370                                                                                                 </xslt:text>
 371                                                                                                 <xslt:for-each select="exslstr:tokenize(@itemtype)/token[string()!='&书社;:document']">
 372                                                                                                         <xslt:text>
 373                                                                                                                 <text> </text>
 374                                                                                                         </xslt:text>
 375                                                                                                         <xslt:value-of select="."/>
 376                                                                                                 </xslt:for-each>
 377                                                                                         </xslt:attribute>
 378                                                                                         <xslt:copy-of select="@*[not(namespace-uri()='' and (local-name()='itemscope' or local-name()='itemtype'))]|node()"/>
 379                                                                                 </xslt:when>
 380                                                                                 <xslt:otherwise>
 381                                                                                         <xslt:copy-of select="@*|node()"/>
 382                                                                                 </xslt:otherwise>
 383                                                                         </xslt:choose>
 384                                                                 </xslt:copy>
 385                                                         </xslt:for-each>
 386                                                 </xslt:for-each>
 387                                         </xslt:when>
 388                                         <xslt:otherwise>
 389                                                 <xslt:copy>
 390                                                         <xslt:apply-templates select="@*|node()" mode="书社:expand"/>
 391                                                 </xslt:copy>
 392                                         </xslt:otherwise>
 393                                 </xslt:choose>
 394                         </xslt:template>
 395                         <xslt:template match="/node()" mode="书社:expand" priority="0">
 396                                 <xslt:param name="identifier" select="$IDENTIFIER"/>
 397                                 <xslt:copy>
 398                                         <xslt:if test="self::*">
 399                                                 <xslt:attribute name="书社:cksum">
 400                                                         <xslt:value-of select="$书社:about//*[@rdf:about=$identifier]/nfo:hasHash[@nfo:hashAlgorithm='CRC32']/@nfo:hashValue"/>
 401                                                 </xslt:attribute>
 402                                                 <xslt:attribute name="书社:identifier">
 403                                                         <xslt:value-of select="$identifier"/>
 404                                                 </xslt:attribute>
 405                                                 <xslt:attribute name="书社:mtime">
 406                                                         <xslt:value-of select="$书社:about//*[@rdf:about=$identifier]/nfo:fileLastModified"/>
 407                                                 </xslt:attribute>
 408                                         </xslt:if>
 409                                         <xslt:choose>
 410                                                 <xslt:when test="self::html:*">
 411                                                         <xslt:attribute name="itemscope">itemscope</xslt:attribute>
 412                                                         <xslt:attribute name="itemtype">
 413                                                                 <xslt:text>
 414                                                                         <text>&书社;:document</text>
 415                                                                 </xslt:text>
 416                                                                 <xslt:for-each select="exslstr:tokenize(@itemtype)/token">
 417                                                                         <xslt:text>
 418                                                                                 <text> </text>
 419                                                                         </xslt:text>
 420                                                                         <xslt:value-of select="."/>
 421                                                                 </xslt:for-each>
 422                                                         </xslt:attribute>
 423                                                         <xslt:apply-templates select="@*[not(namespace-uri()='' and (local-name()='itemscope' or local-name()='itemtype') or namespace-uri()='&书社;' and (local-name()='cksum' or local-name()='identifier' or local-name()='mtime'))]|node()" mode="书社:expand"/>
 424                                                 </xslt:when>
 425                                                 <xslt:otherwise>
 426                                                         <xslt:apply-templates select="@*[not(namespace-uri()='&书社;' and (local-name()='cksum' or local-name()='identifier' or local-name()='mtime'))]|node()" mode="书社:expand"/>
 427                                                 </xslt:otherwise>
 428                                         </xslt:choose>
 429                                 </xslt:copy>
 430                         </xslt:template>
 431                         <xslt:template match="@*|node()" mode="书社:expand" priority="-1">
 432                                 <xslt:copy>
 433                                         <xslt:apply-templates select="@*|node()" mode="书社:expand"/>
 434                                 </xslt:copy>
 435                         </xslt:template>
 436                         <xslt:template match="text()" mode="书社:header"/>
 437                         <xslt:template match="text()" mode="书社:footer"/>
 438                         <xslt:template match="text()" mode="书社:metadata"/>
 439                         <xslt:output method="xml" encoding="UTF-8" cdata-section-elements="html:script html:style html:textarea 书社:raw-output 书社:raw-text"/>
 440                 </xslt:transform>
 441         </template>
 442         <output method="xml" encoding="UTF-8"/>
 443 </transform>