Lady’s Gitweb - Shushe/blob - lib/catalog2transform.xslt

   1 <?xml version="1.0"?>
   2 <!--
   3 SPDX-FileCopyrightText: 2023, 2024 Lady <https://www.ladys.computer/about/#lady>
   4 SPDX-License-Identifier: MPL-2.0
   5 -->
   6 <!--
   7 ⁌ ⛩️📰 书社 ∷ lib/catalog2transform.xslt
   8
   9 © 2023–2024 Lady [@ Lady’s Computer].
  10
  11 This Source Code Form is subject to the terms of the Mozilla Public License, v 2.0.
  12 If a copy of the M·P·L was not distributed with this file, You can obtain one at <https://mozilla.org/MPL/2.0/>.
  13 -->
  14 <!DOCTYPE transform [
  15         <!ENTITY 书社 "urn:fdc:ladys.computer:20231231:Shu1She4">
  16         <!ENTITY xml "http://www.w3.org/XML/1998/namespace">
  17 ]>
  18 <transform
  19         xmlns="http://www.w3.org/1999/XSL/Transform"
  20         xmlns:html="http://www.w3.org/1999/xhtml"
  21         xmlns:catalog="urn:oasis:names:tc:entity:xmlns:xml:catalog"
  22         xmlns:exsl="http://exslt.org/common"
  23         xmlns:exslstr="http://exslt.org/strings"
  24         xmlns:svg="http://www.w3.org/2000/svg"
  25         xmlns:xlink="http://www.w3.org/1999/xlink"
  26         xmlns:xslt="http://www.w3.org/1999/XSL/TransformAlias"
  27         xmlns:书社="urn:fdc:ladys.computer:20231231:Shu1She4"
  28         version="1.0"
  29 >
  30         <namespace-alias stylesheet-prefix="xslt" result-prefix="#default"/>
  31         <template match="/">
  32                 <xslt:transform exclude-result-prefixes="catalog" extension-element-prefixes="exsl exslstr" version="1.0">
  33                         <xslt:param name="BUILDTIME" select="'1972-12-31T00:00:00Z'"/>
  34                         <xslt:param name="CKSUM" select="false()"/>
  35                         <xslt:param name="CATALOG" select="'catalog'"/>
  36                         <xslt:param name="IDENTIFIER" select="false()"/>
  37                         <xslt:param name="PATH" select="'/unknown'"/>
  38                         <xslt:param name="SRCREV" select="false()"/>
  39                         <xslt:param name="SRCTIME" select="'1972-12-31T00:00:00Z'"/>
  40                         <xslt:param name="THISREV" select="false()"/>
  41                         <xslt:variable name="书社:source" select="/"/>
  42                         <xslt:variable name="书社:expansion">
  43                                 <xslt:apply-templates select="$书社:source/node()" mode="书社:expand"/>
  44                         </xslt:variable>
  45                         <xslt:variable name="书社:result">
  46                                 <xslt:apply-templates select="exsl:node-set($书社:expansion)/node()"/>
  47                         </xslt:variable>
  48                         <xslt:variable name="书社:destination">
  49                                 <xslt:choose>
  50                                         <xslt:when test="string($书社:source/@书社:destination)!=''">
  51                                                 <xslt:value-of select="$书社:source/@书社:destination"/>
  52                                         </xslt:when>
  53                                         <xslt:when test="starts-with($PATH, '/')">
  54                                                 <xslt:value-of select="substring-after($PATH, '/')"/>
  55                                         </xslt:when>
  56                                         <xslt:otherwise>
  57                                                 <xslt:value-of select="$PATH"/>
  58                                         </xslt:otherwise>
  59                                 </xslt:choose>
  60                         </xslt:variable>
  61                         <for-each select="//catalog:uri">
  62                                 <xslt:include href="{@uri}">
  63                                         <if test="contains(@name, ':')">
  64                                                 <attribute name="书社:id">
  65                                                         <value-of select="@name"/>
  66                                                 </attribute>
  67                                         </if>
  68                                 </xslt:include>
  69                         </for-each>
  70                         <xslt:template name="书社:apply-attributes">
  71                                 <xslt:param name="and-version" select="false()"/>
  72                                 <xslt:param name="context-nodes" select="/.."/>
  73                                 <xslt:param name="destination-nodes" select="/.."/>
  74                                 <xslt:variable name="additional-attributes" select="$context-nodes/@*"/>
  75                                 <xslt:for-each select="$destination-nodes">
  76                                         <xslt:variable name="existing-attributes" select="@*"/>
  77                                         <xslt:choose>
  78                                                 <xslt:when test="self::*">
  79                                                         <xslt:variable name="context" select="."/>
  80                                                         <xslt:variable name="attribute-names">
  81                                                                 <xslt:for-each select="$existing-attributes|$additional-attributes">
  82                                                                         <书社:attribute>
  83                                                                                 <attribute name="local-name">
  84                                                                                         <text>{local-name()}</text>
  85                                                                                 </attribute>
  86                                                                                 <attribute name="name">
  87                                                                                         <text>{name()}</text>
  88                                                                                 </attribute>
  89                                                                                 <attribute name="namespace-uri">
  90                                                                                         <text>{namespace-uri()}</text>
  91                                                                                 </attribute>
  92                                                                         </书社:attribute>
  93                                                                 </xslt:for-each>
  94                                                         </xslt:variable>
  95                                                         <xslt:variable name="lang">
  96                                                                 <xslt:choose>
  97                                                                         <xslt:when test="(self::html:*|self::svg:*)/@lang">
  98                                                                                 <xslt:value-of select="@lang"/>
  99                                                                         </xslt:when>
 100                                                                         <xslt:when test="@xml:lang">
 101                                                                                 <xslt:value-of select="@xml:lang"/>
 102                                                                         </xslt:when>
 103                                                                         <xslt:when test="$additional-attributes[(parent::html:* or parent::svg:*) and namespace-uri()='' and local-name()='lang']">
 104                                                                                 <xslt:value-of select="$additional-attributes[(parent::html:* or parent::svg:*) and namespace-uri()='' and local-name()='lang']"/>
 105                                                                         </xslt:when>
 106                                                                         <xslt:when test="(self::html:* or self::svg:*) and $additional-attributes[(parent::书社:apply-attributes or parent::书社:apply-attributes-to-root) and namespace-uri()='' and local-name()='lang']">
 107                                                                                 <xslt:value-of select="$additional-attributes[(parent::书社:apply-attributes or parent::书社:apply-attributes-to-root) and namespace-uri()='' and local-name()='lang']"/>
 108                                                                         </xslt:when>
 109                                                                         <xslt:when test="$additional-attributes[namespace-uri()='&xml;' and local-name()='lang']">
 110                                                                                 <xslt:value-of select="$additional-attributes[namespace-uri()='&xml;' and local-name()='lang']"/>
 111                                                                         </xslt:when>
 112                                                                 </xslt:choose>
 113                                                         </xslt:variable>
 114                                                         <xslt:copy>
 115                                                                 <xslt:if test="$and-version and $THISREV">
 116                                                                         <xslt:attribute name="书社:version">
 117                                                                                 <xslt:value-of select="$THISREV"/>
 118                                                                         </xslt:attribute>
 119                                                                 </xslt:if>
 120                                                                 <xslt:if test="string($lang)!=''">
 121                                                                         <xslt:if test="self::html:* or self::svg:*">
 122                                                                                 <xslt:attribute name="lang">
 123                                                                                         <xslt:value-of select="$lang"/>
 124                                                                                 </xslt:attribute>
 125                                                                         </xslt:if>
 126                                                                         <xslt:attribute name="xml:lang">
 127                                                                                 <xslt:value-of select="$lang"/>
 128                                                                         </xslt:attribute>
 129                                                                 </xslt:if>
 130                                                                 <xslt:for-each select="exsl:node-set($attribute-names)/*">
 131                                                                         <xslt:choose>
 132                                                                                 <xslt:when test="@namespace-uri='&xml;'"/>
 133                                                                                 <xslt:when test="$context[self::html:* or self::svg:*] and @namespace-uri='' and @local-name='lang'"/>
 134                                                                                 <xslt:when test="@namespace-uri='&书社;' and @local-name='archived-as' and not($context-nodes/ancestor::*[not(self::书社:apply-attributes-to-root or self::书社:apply-attributes)][1][self::书社:archive])"/>
 135                                                                                 <xslt:when test="@namespace-uri='&书社;' and (@local-name='destination' or @local-name='disable-output-wrapping' or @local-name='version')"/>
 136                                                                                 <xslt:when test="preceding-sibling::*[@local-name=current()/@local-name and @namespace-uri=current()/@namespace-uri]"/>
 137                                                                                 <xslt:otherwise>
 138                                                                                         <xslt:attribute>
 139                                                                                                 <attribute name="name">
 140                                                                                                         <text>{@name}</text>
 141                                                                                                 </attribute>
 142                                                                                                 <attribute name="namespace">
 143                                                                                                         <text>{@namespace-uri}</text>
 144                                                                                                 </attribute>
 145                                                                                                 <xslt:for-each select="$existing-attributes[local-name()=current()/@local-name and namespace-uri()=current()/@namespace-uri]">
 146                                                                                                         <xslt:value-of select="."/>
 147                                                                                                         <xslt:if test="position()!=last()">
 148                                                                                                                 <xslt:text>
 149                                                                                                                         <text> </text>
 150                                                                                                                 </xslt:text>
 151                                                                                                         </xslt:if>
 152                                                                                                 </xslt:for-each>
 153                                                                                                 <xslt:if test="$existing-attributes[local-name()=current()/@local-name and namespace-uri()=current()/@namespace-uri] and $additional-attributes[local-name()=current()/@local-name and namespace-uri()=current()/@namespace-uri]">
 154                                                                                                         <xslt:text>
 155                                                                                                                 <text> </text>
 156                                                                                                         </xslt:text>
 157                                                                                                 </xslt:if>
 158                                                                                                 <xslt:for-each select="$additional-attributes[local-name()=current()/@local-name and namespace-uri()=current()/@namespace-uri]">
 159                                                                                                         <xslt:value-of select="."/>
 160                                                                                                         <xslt:if test="position()!=last()">
 161                                                                                                                 <xslt:text>
 162                                                                                                                         <text> </text>
 163                                                                                                                 </xslt:text>
 164                                                                                                         </xslt:if>
 165                                                                                                 </xslt:for-each>
 166                                                                                         </xslt:attribute>
 167                                                                                 </xslt:otherwise>
 168                                                                         </xslt:choose>
 169                                                                 </xslt:for-each>
 170                                                                 <xslt:copy-of select="node()"/>
 171                                                         </xslt:copy>
 172                                                 </xslt:when>
 173                                                 <xslt:otherwise>
 174                                                         <xslt:copy-of select="."/>
 175                                                 </xslt:otherwise>
 176                                         </xslt:choose>
 177                                 </xslt:for-each>
 178                         </xslt:template>
 179                         <xslt:template name="书社:wrap">
 180                                 <xslt:param name="nodes" select="/.."/>
 181                                 <xslt:variable name="modalinput">
 182                                         <xslt:copy-of select="$nodes"/>
 183                                         <xslt:copy-of select="document('')/xslt:transform/xslt:include"/>
 184                                 </xslt:variable>
 185                                 <xslt:variable name="metadata">
 186                                         <xslt:copy-of select="$nodes[self::html:html]/html:head/node()|$nodes[self::html:head]/node()"/>
 187                                         <xslt:apply-templates select="exsl:node-set($modalinput)/node()" mode="书社:metadata"/>
 188                                 </xslt:variable>
 189                                 <html:html>
 190                                         <xslt:copy-of select="$nodes[self::html:html]/@*"/>
 191                                         <xslt:if test="not($nodes[self::html:html]/@书社:archived-as) and $nodes/@书社:archived-as">
 192                                                 <xslt:attribute name="书社:archived-as">
 193                                                         <xslt:value-of select="$nodes/@书社:archived-as"/>
 194                                                 </xslt:attribute>
 195                                         </xslt:if>
 196                                         <xslt:if test="not($nodes[self::html:html]/@lang) and $nodes[self::html:*]/@lang|$nodes[self::svg:*]/@lang|$nodes/@xml:lang">
 197                                                 <xslt:attribute name="lang">
 198                                                         <xslt:value-of select="$nodes[self::html:*]/@lang|$nodes[self::svg:*]/@lang|$nodes/@xml:lang"/>
 199                                                 </xslt:attribute>
 200                                         </xslt:if>
 201                                         <xslt:if test="not($nodes[self::html:html]/@xml:lang) and $nodes[self::html:*]/@lang|$nodes[self::svg:*]/@lang|$nodes/@xml:lang">
 202                                                 <xslt:attribute name="xml:lang">
 203                                                         <xslt:value-of select="$nodes[self::html:*]/@lang|$nodes[self::svg:*]/@lang|$nodes/@xml:lang"/>
 204                                                 </xslt:attribute>
 205                                         </xslt:if>
 206                                         <html:head>
 207                                                 <xslt:copy-of select="$nodes[self::html:html]/html:head/@*|$nodes[self::html:head]/@*"/>
 208                                                 <html:title>
 209                                                         <xslt:for-each select="exsl:node-set($metadata)/html:title">
 210                                                                 <xslt:value-of select="."/>
 211                                                                 <xslt:if test="position()!=last()">
 212                                                                         <xslt:text>
 213                                                                                 <text> </text>
 214                                                                         </xslt:text>
 215                                                                 </xslt:if>
 216                                                         </xslt:for-each>
 217                                                 </html:title>
 218                                                 <xslt:copy-of select="exsl:node-set($metadata)/node()[not(self::html:title)]"/>
 219                                                 <html:meta name="generator">
 220                                                         <xslt:attribute name="content">
 221                                                                 <xslt:for-each select="exsl:node-set($metadata)/html:meta[@name='generator']">
 222                                                                         <xslt:value-of select="@content"/>
 223                                                                         <xslt:text>
 224                                                                                 <text>, </text>
 225                                                                         </xslt:text>
 226                                                                 </xslt:for-each>
 227                                                                 <xslt:text>
 228                                                                         <text>⛩️📰 书社</text>
 229                                                                 </xslt:text>
 230                                                                 <xslt:if test="$THISREV">
 231                                                                         <xslt:text>
 232                                                                                 <text> (</text>
 233                                                                         </xslt:text>
 234                                                                         <xslt:value-of select="$THISREV"/>
 235                                                                         <xslt:text>
 236                                                                                 <text>)</text>
 237                                                                         </xslt:text>
 238                                                                 </xslt:if>
 239                                                         </xslt:attribute>
 240                                                 </html:meta>
 241                                         </html:head>
 242                                         <html:body>
 243                                                 <xslt:copy-of select="$nodes[self::html:html]/html:body/@*|$nodes[self::html:body]/@*"/>
 244                                                 <xslt:apply-templates select="exsl:node-set($modalinput)/node()" mode="书社:header"/>
 245                                                 <xslt:copy-of select="$nodes[not(self::html:html or self::html:head or self::html:body)]|$nodes[self::html:html]/node()[not(self::html:head or self::html:body)]|$nodes[self::html:html]/html:body/node()|$nodes[self::html:body]/node()"/>
 246                                                 <xslt:apply-templates select="exsl:node-set($modalinput)/node()" mode="书社:footer"/>
 247                                         </html:body>
 248                                 </html:html>
 249                         </xslt:template>
 250                         <xslt:template match="/" priority="1">
 251                                 <xslt:variable name="result-nodes" select="exsl:node-set($书社:result)/node()[not(self::书社:apply-attributes-to-root)]|exsl:node-set($书社:result)/书社:apply-attributes-to-root/descendant::node()[not(self::书社:apply-attributes-to-root) and not(ancestor::*[not(self::书社:apply-attributes-to-root)])]"/>
 252                                 <xslt:variable name="root-with-attributes">
 253                                         <xslt:choose>
 254                                                 <xslt:when test="$result-nodes/self::书社:*[local-name()='raw-text' or local-name()='base64-binary' or local-name()='archive']|$result-nodes/@书社:disable-output-wrapping|exsl:node-set($书社:result)//书社:apply-attributes-to-root/@书社:disable-output-wrapping">
 255                                                         <xslt:call-template name="书社:apply-attributes">
 256                                                                 <xslt:with-param name="and-version" select="true()"/>
 257                                                                 <xslt:with-param name="context-nodes" select="exsl:node-set($书社:result)//书社:apply-attributes-to-root"/>
 258                                                                 <xslt:with-param name="destination-nodes" select="$result-nodes"/>
 259                                                         </xslt:call-template>
 260                                                 </xslt:when>
 261                                                 <xslt:otherwise>
 262                                                         <xslt:variable name="wrapped-result">
 263                                                                 <xslt:call-template name="书社:wrap">
 264                                                                         <xslt:with-param name="nodes" select="$result-nodes"/>
 265                                                                 </xslt:call-template>
 266                                                         </xslt:variable>
 267                                                         <xslt:call-template name="书社:apply-attributes">
 268                                                                 <xslt:with-param name="and-version" select="true()"/>
 269                                                                 <xslt:with-param name="context-nodes" select="exsl:node-set($书社:result)//书社:apply-attributes-to-root"/>
 270                                                                 <xslt:with-param name="destination-nodes" select="exsl:node-set($wrapped-result)/node()"/>
 271                                                         </xslt:call-template>
 272                                                 </xslt:otherwise>
 273                                         </xslt:choose>
 274                                 </xslt:variable>
 275                                 <xslt:apply-templates select="exsl:node-set($root-with-attributes)/node()" mode="书社:application"/>
 276                         </xslt:template>
 277                         <xslt:template match="@*|node()" priority="-1">
 278                                 <xslt:copy>
 279                                         <xslt:apply-templates select="@*|node()"/>
 280                                 </xslt:copy>
 281                         </xslt:template>
 282                         <xslt:template match="@*|node()" mode="书社:application">
 283                                 <xslt:copy>
 284                                         <xslt:apply-templates select="@*|node()" mode="书社:application"/>
 285                                 </xslt:copy>
 286                         </xslt:template>
 287                         <xslt:template match="@书社:destination|@书社:disable-output-wrapping|@书社:archived-as[../ancestor::*[not(self::书社:apply-attributes-to-root or self::书社:apply-attributes)]]" mode="书社:application" priority="1"/>
 288                         <xslt:template match="书社:archive" mode="书社:application" priority="1">
 289                                 <xslt:copy>
 290                                         <xslt:for-each select="@*">
 291                                                 <xslt:choose>
 292                                                         <xslt:when test="local-name()='archived-as' and namespace-uri()='&书社;' and ../ancestor::*[not(self::书社:apply-attributes-to-root or self::书社:apply-attributes)]"/>
 293                                                         <xslt:otherwise>
 294                                                                 <xslt:apply-templates select="." mode="书社:application"/>
 295                                                         </xslt:otherwise>
 296                                                 </xslt:choose>
 297                                         </xslt:for-each>
 298                                         <xslt:for-each select="node()">
 299                                                 <xslt:choose>
 300                                                         <xslt:when test="self::*">
 301                                                                 <xslt:variable name="component">
 302                                                                         <xslt:choose>
 303                                                                                 <xslt:when test="self::书社:*[local-name()='raw-text' or local-name()='base64-binary' or local-name()='archive']|@书社:disable-output-wrapping">
 304                                                                                         <xslt:copy-of select="."/>
 305                                                                                 </xslt:when>
 306                                                                                 <xslt:otherwise>
 307                                                                                         <xslt:call-template name="书社:wrap">
 308                                                                                                 <xslt:with-param name="nodes" select="."/>
 309                                                                                         </xslt:call-template>
 310                                                                                 </xslt:otherwise>
 311                                                                         </xslt:choose>
 312                                                                 </xslt:variable>
 313                                                                 <xslt:apply-templates select="exsl:node-set($component)/node()" mode="书社:application"/>
 314                                                         </xslt:when>
 315                                                         <xslt:otherwise>
 316                                                                 <xslt:apply-templates select="." mode="书社:application"/>
 317                                                         </xslt:otherwise>
 318                                                 </xslt:choose>
 319                                         </xslt:for-each>
 320                                 </xslt:copy>
 321                         </xslt:template>
 322                         <xslt:template match="书社:apply-attributes" mode="书社:application" priority="1">
 323                                 <xslt:variable name="children">
 324                                         <xslt:apply-templates mode="书社:application"/>
 325                                 </xslt:variable>
 326                                 <xslt:call-template name="书社:apply-attributes">
 327                                         <xslt:with-param name="context-nodes" select="."/>
 328                                         <xslt:with-param name="destination-nodes" select="exsl:node-set($children)/node()"/>
 329                                 </xslt:call-template>
 330                         </xslt:template>
 331                         <xslt:template match="书社:apply-attributes-to-root" mode="书社:application" priority="1">
 332                                 <xslt:apply-templates mode="书社:application"/>
 333                         </xslt:template>
 334                         <xslt:template match="/node()" mode="书社:expand" priority="0">
 335                                 <xslt:copy>
 336                                         <xslt:attribute name="书社:identifier">
 337                                                 <xslt:value-of select="$IDENTIFIER"/>
 338                                         </xslt:attribute>
 339                                         <xslt:choose>
 340                                                 <xslt:when test="self::html:*">
 341                                                         <xslt:attribute name="itemscope">itemscope</xslt:attribute>
 342                                                         <xslt:attribute name="itemtype">
 343                                                                 <xslt:text>
 344                                                                         <text>&书社;:document</text>
 345                                                                 </xslt:text>
 346                                                                 <xslt:for-each select="exslstr:tokenize(@itemtype)/token">
 347                                                                         <xslt:text>
 348                                                                                 <text> </text>
 349                                                                         </xslt:text>
 350                                                                         <xslt:value-of select="."/>
 351                                                                 </xslt:for-each>
 352                                                         </xslt:attribute>
 353                                                         <xslt:apply-templates select="@*[not(namespace-uri()='' and (local-name()='itemscope' or local-name()='itemtype'))]|node()" mode="书社:expand"/>
 354                                                 </xslt:when>
 355                                                 <xslt:otherwise>
 356                                                         <xslt:apply-templates select="@*|node()" mode="书社:expand"/>
 357                                                 </xslt:otherwise>
 358                                         </xslt:choose>
 359                                 </xslt:copy>
 360                         </xslt:template>
 361                         <xslt:template match="书社:link[@xlink:show='embed']" mode="书社:expand" priority="1">
 362                                 <xslt:variable name="identifier" select="string(@xlink:href)"/>
 363                                 <xslt:variable name="uri" select="substring-before(document($CATALOG)//catalog:uri[@name=$identifier]/@uri[1], '#')"/>
 364                                 <xslt:choose>
 365                                         <xslt:when test="$uri">
 366                                                 <xslt:variable name="expanded">
 367                                                         <xslt:apply-templates select="document($uri)" mode="书社:expand"/>
 368                                                 </xslt:variable>
 369                                                 <xslt:for-each select="exsl:node-set($expanded)/node()">
 370                                                         <xslt:copy>
 371                                                                 <xslt:attribute name="书社:identifier">
 372                                                                         <xslt:value-of select="$identifier"/>
 373                                                                 </xslt:attribute>
 374                                                                 <xslt:choose>
 375                                                                         <xslt:when test="self::html:*">
 376                                                                                 <xslt:attribute name="itemscope">itemscope</xslt:attribute>
 377                                                                                 <xslt:attribute name="itemtype">
 378                                                                                         <xslt:text>
 379                                                                                                 <text>&书社;:embed</text>
 380                                                                                         </xslt:text>
 381                                                                                         <xslt:for-each select="exslstr:tokenize(@itemtype)/token[string()!='&书社;:document']">
 382                                                                                                 <xslt:text>
 383                                                                                                         <text> </text>
 384                                                                                                 </xslt:text>
 385                                                                                                 <xslt:value-of select="."/>
 386                                                                                         </xslt:for-each>
 387                                                                                 </xslt:attribute>
 388                                                                                 <xslt:copy-of select="@*[not(namespace-uri()='' and (local-name()='itemscope' or local-name()='itemtype')) and not(namespace-uri()='&书社;' and local-name()='identifier')]|node()"/>
 389                                                                         </xslt:when>
 390                                                                         <xslt:otherwise>
 391                                                                                 <xslt:apply-templates select="@*[not(namespace-uri()='&书社;' and local-name()='identifier')]|node()" mode="书社:expand"/>
 392                                                                         </xslt:otherwise>
 393                                                                 </xslt:choose>
 394                                                         </xslt:copy>
 395                                                 </xslt:for-each>
 396                                         </xslt:when>
 397                                         <xslt:otherwise>
 398                                                 <xslt:copy>
 399                                                         <xslt:apply-templates select="@*|node()" mode="书社:expand"/>
 400                                                 </xslt:copy>
 401                                         </xslt:otherwise>
 402                                 </xslt:choose>
 403                         </xslt:template>
 404                         <xslt:template match="@*|node()[not(self::书社:link) or not(@xlink:show='embed')]" mode="书社:expand" priority="-1">
 405                                 <xslt:copy>
 406                                         <xslt:apply-templates select="@*|node()" mode="书社:expand"/>
 407                                 </xslt:copy>
 408                         </xslt:template>
 409                         <xslt:template match="text()" mode="书社:header"/>
 410                         <xslt:template match="text()" mode="书社:footer"/>
 411                         <xslt:template match="text()" mode="书社:metadata"/>
 412                         <xslt:output method="xml" encoding="UTF-8" cdata-section-elements="html:script html:style html:textarea 书社:raw-output 书社:raw-text"/>
 413                 </xslt:transform>
 414         </template>
 415         <output method="xml" encoding="UTF-8"/>
 416 </transform>