Lady’s Gitweb - Gitweb/blob - gitweb.perl

   1 #!/usr/bin/perl
   2
   3 # gitweb - simple web interface to track changes in git repositories
   4 #
   5 # (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
   6 # (C) 2005, Christian Gierke
   7 #
   8 # This program is licensed under the GPLv2
   9
  10 use 5.008;
  11 use strict;
  12 use warnings;
  13 use CGI qw(:standard :escapeHTML -nosticky);
  14 use CGI::Util qw(unescape);
  15 use CGI::Carp qw(fatalsToBrowser set_message);
  16 use Encode;
  17 use Fcntl ':mode';
  18 use File::Find qw();
  19 use File::Basename qw(basename);
  20 use Time::HiRes qw(gettimeofday tv_interval);
  21 binmode STDOUT, ':utf8';
  22
  23 our $t0 = [ gettimeofday() ];
  24 our $number_of_git_cmds = 0;
  25
  26 BEGIN {
  27         CGI->compile() if $ENV{'MOD_PERL'};
  28 }
  29
  30 our $version = "++GIT_VERSION++";
  31
  32 our ($my_url, $my_uri, $base_url, $path_info, $home_link);
  33 sub evaluate_uri {
  34         our $cgi;
  35
  36         our $my_url = $cgi->url();
  37         our $my_uri = $cgi->url(-absolute => 1);
  38
  39         # Base URL for relative URLs in gitweb ($logo, $favicon, ...),
  40         # needed and used only for URLs with nonempty PATH_INFO
  41         our $base_url = $my_url;
  42
  43         # When the script is used as DirectoryIndex, the URL does not contain the name
  44         # of the script file itself, and $cgi->url() fails to strip PATH_INFO, so we
  45         # have to do it ourselves. We make $path_info global because it's also used
  46         # later on.
  47         #
  48         # Another issue with the script being the DirectoryIndex is that the resulting
  49         # $my_url data is not the full script URL: this is good, because we want
  50         # generated links to keep implying the script name if it wasn't explicitly
  51         # indicated in the URL we're handling, but it means that $my_url cannot be used
  52         # as base URL.
  53         # Therefore, if we needed to strip PATH_INFO, then we know that we have
  54         # to build the base URL ourselves:
  55         our $path_info = decode_utf8($ENV{"PATH_INFO"});
  56         if ($path_info) {
  57                 if ($my_url =~ s,\Q$path_info\E$,, &&
  58                     $my_uri =~ s,\Q$path_info\E$,, &&
  59                     defined $ENV{'SCRIPT_NAME'}) {
  60                         $base_url = $cgi->url(-base => 1) . $ENV{'SCRIPT_NAME'};
  61                 }
  62         }
  63
  64         # target of the home link on top of all pages
  65         our $home_link = $my_uri || "/";
  66 }
  67
  68 # core git executable to use
  69 # this can just be "git" if your webserver has a sensible PATH
  70 our $GIT = "++GIT_BINDIR++/git";
  71
  72 # absolute fs-path which will be prepended to the project path
  73 #our $projectroot = "/pub/scm";
  74 our $projectroot = "++GITWEB_PROJECTROOT++";
  75
  76 # fs traversing limit for getting project list
  77 # the number is relative to the projectroot
  78 our $project_maxdepth = "++GITWEB_PROJECT_MAXDEPTH++";
  79
  80 # string of the home link on top of all pages
  81 our $home_link_str = "++GITWEB_HOME_LINK_STR++";
  82
  83 # name of your site or organization to appear in page titles
  84 # replace this with something more descriptive for clearer bookmarks
  85 our $site_name = "++GITWEB_SITENAME++"
  86                  || ($ENV{'SERVER_NAME'} || "Untitled") . " Git";
  87
  88 # html snippet to include in the <head> section of each page
  89 our $site_html_head_string = "++GITWEB_SITE_HTML_HEAD_STRING++";
  90 # filename of html text to include at top of each page
  91 our $site_header = "++GITWEB_SITE_HEADER++";
  92 # html text to include at home page
  93 our $home_text = "++GITWEB_HOMETEXT++";
  94 # filename of html text to include at bottom of each page
  95 our $site_footer = "++GITWEB_SITE_FOOTER++";
  96
  97 # URI of stylesheets
  98 our @stylesheets = ("++GITWEB_CSS++");
  99 # URI of a single stylesheet, which can be overridden in GITWEB_CONFIG.
 100 our $stylesheet = undef;
 101
 102 # URI of GIT logo (72x27 size)
 103 our $logo = "++GITWEB_LOGO++";
 104 # URI of GIT favicon, assumed to be image/png type
 105 our $favicon = "++GITWEB_FAVICON++";
 106 # URI of gitweb.js (JavaScript code for gitweb)
 107 our $javascript = "++GITWEB_JS++";
 108
 109 # URI and label (title) of GIT logo link
 110 #our $logo_url = "http://www.kernel.org/pub/software/scm/git/docs/";
 111 #our $logo_label = "git documentation";
 112 our $logo_url = "http://git-scm.com/";
 113 our $logo_label = "git homepage";
 114
 115 # source of projects list
 116 our $projects_list = "++GITWEB_LIST++";
 117
 118 # the width (in characters) of the projects list "Description" column
 119 our $projects_list_description_width = 25;
 120
 121 # group projects by category on the projects list
 122 # (enabled if this variable evaluates to true)
 123 our $projects_list_group_categories = 0;
 124
 125 # default category if none specified
 126 # (leave the empty string for no category)
 127 our $project_list_default_category = "";
 128
 129 # default order of projects list
 130 # valid values are none, project, descr, owner, and age
 131 our $default_projects_order = "project";
 132
 133 # show repository only if this file exists
 134 # (only effective if this variable evaluates to true)
 135 our $export_ok = "++GITWEB_EXPORT_OK++";
 136
 137 # show repository only if this subroutine returns true
 138 # when given the path to the project, for example:
 139 #    sub { return -e "$_[0]/git-daemon-export-ok"; }
 140 our $export_auth_hook = undef;
 141
 142 # only allow viewing of repositories also shown on the overview page
 143 our $strict_export = "++GITWEB_STRICT_EXPORT++";
 144
 145 # list of git base URLs used for URL to where fetch project from,
 146 # i.e. full URL is "$git_base_url/$project"
 147 our @git_base_url_list = grep { $_ ne '' } ("++GITWEB_BASE_URL++");
 148
 149 # default blob_plain mimetype and default charset for text/plain blob
 150 our $default_blob_plain_mimetype = 'text/plain';
 151 our $default_text_plain_charset  = undef;
 152
 153 # file to use for guessing MIME types before trying /etc/mime.types
 154 # (relative to the current git repository)
 155 our $mimetypes_file = undef;
 156
 157 # assume this charset if line contains non-UTF-8 characters;
 158 # it should be valid encoding (see Encoding::Supported(3pm) for list),
 159 # for which encoding all byte sequences are valid, for example
 160 # 'iso-8859-1' aka 'latin1' (it is decoded without checking, so it
 161 # could be even 'utf-8' for the old behavior)
 162 our $fallback_encoding = 'latin1';
 163
 164 # rename detection options for git-diff and git-diff-tree
 165 # - default is '-M', with the cost proportional to
 166 #   (number of removed files) * (number of new files).
 167 # - more costly is '-C' (which implies '-M'), with the cost proportional to
 168 #   (number of changed files + number of removed files) * (number of new files)
 169 # - even more costly is '-C', '--find-copies-harder' with cost
 170 #   (number of files in the original tree) * (number of new files)
 171 # - one might want to include '-B' option, e.g. '-B', '-M'
 172 our @diff_opts = ('-M'); # taken from git_commit
 173
 174 # Disables features that would allow repository owners to inject script into
 175 # the gitweb domain.
 176 our $prevent_xss = 0;
 177
 178 # Path to the highlight executable to use (must be the one from
 179 # http://www.andre-simon.de due to assumptions about parameters and output).
 180 # Useful if highlight is not installed on your webserver's PATH.
 181 # [Default: highlight]
 182 our $highlight_bin = "++HIGHLIGHT_BIN++";
 183
 184 # information about snapshot formats that gitweb is capable of serving
 185 our %known_snapshot_formats = (
 186         # name => {
 187         #       'display' => display name,
 188         #       'type' => mime type,
 189         #       'suffix' => filename suffix,
 190         #       'format' => --format for git-archive,
 191         #       'compressor' => [compressor command and arguments]
 192         #                       (array reference, optional)
 193         #       'disabled' => boolean (optional)}
 194         #
 195         'tgz' => {
 196                 'display' => 'tar.gz',
 197                 'type' => 'application/x-gzip',
 198                 'suffix' => '.tar.gz',
 199                 'format' => 'tar',
 200                 'compressor' => ['gzip', '-n']},
 201
 202         'tbz2' => {
 203                 'display' => 'tar.bz2',
 204                 'type' => 'application/x-bzip2',
 205                 'suffix' => '.tar.bz2',
 206                 'format' => 'tar',
 207                 'compressor' => ['bzip2']},
 208
 209         'txz' => {
 210                 'display' => 'tar.xz',
 211                 'type' => 'application/x-xz',
 212                 'suffix' => '.tar.xz',
 213                 'format' => 'tar',
 214                 'compressor' => ['xz'],
 215                 'disabled' => 1},
 216
 217         'zip' => {
 218                 'display' => 'zip',
 219                 'type' => 'application/x-zip',
 220                 'suffix' => '.zip',
 221                 'format' => 'zip'},
 222 );
 223
 224 # Aliases so we understand old gitweb.snapshot values in repository
 225 # configuration.
 226 our %known_snapshot_format_aliases = (
 227         'gzip'  => 'tgz',
 228         'bzip2' => 'tbz2',
 229         'xz'    => 'txz',
 230
 231         # backward compatibility: legacy gitweb config support
 232         'x-gzip' => undef, 'gz' => undef,
 233         'x-bzip2' => undef, 'bz2' => undef,
 234         'x-zip' => undef, '' => undef,
 235 );
 236
 237 # Pixel sizes for icons and avatars. If the default font sizes or lineheights
 238 # are changed, it may be appropriate to change these values too via
 239 # $GITWEB_CONFIG.
 240 our %avatar_size = (
 241         'default' => 16,
 242         'double'  => 32
 243 );
 244
 245 # Used to set the maximum load that we will still respond to gitweb queries.
 246 # If server load exceed this value then return "503 server busy" error.
 247 # If gitweb cannot determined server load, it is taken to be 0.
 248 # Leave it undefined (or set to 'undef') to turn off load checking.
 249 our $maxload = 300;
 250
 251 # configuration for 'highlight' (http://www.andre-simon.de/)
 252 # match by basename
 253 our %highlight_basename = (
 254         #'Program' => 'py',
 255         #'Library' => 'py',
 256         'SConstruct' => 'py', # SCons equivalent of Makefile
 257         'Makefile' => 'make',
 258 );
 259 # match by extension
 260 our %highlight_ext = (
 261         # main extensions, defining name of syntax;
 262         # see files in /usr/share/highlight/langDefs/ directory
 263         map { $_ => $_ }
 264                 qw(py c cpp rb java css php sh pl js tex bib xml awk bat ini spec tcl sql make),
 265         # alternate extensions, see /etc/highlight/filetypes.conf
 266         'h' => 'c',
 267         map { $_ => 'sh'  } qw(bash zsh ksh),
 268         map { $_ => 'cpp' } qw(cxx c++ cc),
 269         map { $_ => 'php' } qw(php3 php4 php5 phps),
 270         map { $_ => 'pl'  } qw(perl pm), # perhaps also 'cgi'
 271         map { $_ => 'make'} qw(mak mk),
 272         map { $_ => 'xml' } qw(xhtml html htm),
 273 );
 274
 275 # You define site-wide feature defaults here; override them with
 276 # $GITWEB_CONFIG as necessary.
 277 our %feature = (
 278         # feature => {
 279         #       'sub' => feature-sub (subroutine),
 280         #       'override' => allow-override (boolean),
 281         #       'default' => [ default options...] (array reference)}
 282         #
 283         # if feature is overridable (it means that allow-override has true value),
 284         # then feature-sub will be called with default options as parameters;
 285         # return value of feature-sub indicates if to enable specified feature
 286         #
 287         # if there is no 'sub' key (no feature-sub), then feature cannot be
 288         # overridden
 289         #
 290         # use gitweb_get_feature(<feature>) to retrieve the <feature> value
 291         # (an array) or gitweb_check_feature(<feature>) to check if <feature>
 292         # is enabled
 293
 294         # Enable the 'blame' blob view, showing the last commit that modified
 295         # each line in the file. This can be very CPU-intensive.
 296
 297         # To enable system wide have in $GITWEB_CONFIG
 298         # $feature{'blame'}{'default'} = [1];
 299         # To have project specific config enable override in $GITWEB_CONFIG
 300         # $feature{'blame'}{'override'} = 1;
 301         # and in project config gitweb.blame = 0|1;
 302         'blame' => {
 303                 'sub' => sub { feature_bool('blame', @_) },
 304                 'override' => 0,
 305                 'default' => [0]},
 306
 307         # Enable the 'snapshot' link, providing a compressed archive of any
 308         # tree. This can potentially generate high traffic if you have large
 309         # project.
 310
 311         # Value is a list of formats defined in %known_snapshot_formats that
 312         # you wish to offer.
 313         # To disable system wide have in $GITWEB_CONFIG
 314         # $feature{'snapshot'}{'default'} = [];
 315         # To have project specific config enable override in $GITWEB_CONFIG
 316         # $feature{'snapshot'}{'override'} = 1;
 317         # and in project config, a comma-separated list of formats or "none"
 318         # to disable.  Example: gitweb.snapshot = tbz2,zip;
 319         'snapshot' => {
 320                 'sub' => \&feature_snapshot,
 321                 'override' => 0,
 322                 'default' => ['tgz']},
 323
 324         # Enable text search, which will list the commits which match author,
 325         # committer or commit text to a given string.  Enabled by default.
 326         # Project specific override is not supported.
 327         #
 328         # Note that this controls all search features, which means that if
 329         # it is disabled, then 'grep' and 'pickaxe' search would also be
 330         # disabled.
 331         'search' => {
 332                 'override' => 0,
 333                 'default' => [1]},
 334
 335         # Enable grep search, which will list the files in currently selected
 336         # tree containing the given string. Enabled by default. This can be
 337         # potentially CPU-intensive, of course.
 338         # Note that you need to have 'search' feature enabled too.
 339
 340         # To enable system wide have in $GITWEB_CONFIG
 341         # $feature{'grep'}{'default'} = [1];
 342         # To have project specific config enable override in $GITWEB_CONFIG
 343         # $feature{'grep'}{'override'} = 1;
 344         # and in project config gitweb.grep = 0|1;
 345         'grep' => {
 346                 'sub' => sub { feature_bool('grep', @_) },
 347                 'override' => 0,
 348                 'default' => [1]},
 349
 350         # Enable the pickaxe search, which will list the commits that modified
 351         # a given string in a file. This can be practical and quite faster
 352         # alternative to 'blame', but still potentially CPU-intensive.
 353         # Note that you need to have 'search' feature enabled too.
 354
 355         # To enable system wide have in $GITWEB_CONFIG
 356         # $feature{'pickaxe'}{'default'} = [1];
 357         # To have project specific config enable override in $GITWEB_CONFIG
 358         # $feature{'pickaxe'}{'override'} = 1;
 359         # and in project config gitweb.pickaxe = 0|1;
 360         'pickaxe' => {
 361                 'sub' => sub { feature_bool('pickaxe', @_) },
 362                 'override' => 0,
 363                 'default' => [1]},
 364
 365         # Enable showing size of blobs in a 'tree' view, in a separate
 366         # column, similar to what 'ls -l' does.  This cost a bit of IO.
 367
 368         # To disable system wide have in $GITWEB_CONFIG
 369         # $feature{'show-sizes'}{'default'} = [0];
 370         # To have project specific config enable override in $GITWEB_CONFIG
 371         # $feature{'show-sizes'}{'override'} = 1;
 372         # and in project config gitweb.showsizes = 0|1;
 373         'show-sizes' => {
 374                 'sub' => sub { feature_bool('showsizes', @_) },
 375                 'override' => 0,
 376                 'default' => [1]},
 377
 378         # Make gitweb use an alternative format of the URLs which can be
 379         # more readable and natural-looking: project name is embedded
 380         # directly in the path and the query string contains other
 381         # auxiliary information. All gitweb installations recognize
 382         # URL in either format; this configures in which formats gitweb
 383         # generates links.
 384
 385         # To enable system wide have in $GITWEB_CONFIG
 386         # $feature{'pathinfo'}{'default'} = [1];
 387         # Project specific override is not supported.
 388
 389         # Note that you will need to change the default location of CSS,
 390         # favicon, logo and possibly other files to an absolute URL. Also,
 391         # if gitweb.cgi serves as your indexfile, you will need to force
 392         # $my_uri to contain the script name in your $GITWEB_CONFIG.
 393         'pathinfo' => {
 394                 'override' => 0,
 395                 'default' => [0]},
 396
 397         # Make gitweb consider projects in project root subdirectories
 398         # to be forks of existing projects. Given project $projname.git,
 399         # projects matching $projname/*.git will not be shown in the main
 400         # projects list, instead a '+' mark will be added to $projname
 401         # there and a 'forks' view will be enabled for the project, listing
 402         # all the forks. If project list is taken from a file, forks have
 403         # to be listed after the main project.
 404
 405         # To enable system wide have in $GITWEB_CONFIG
 406         # $feature{'forks'}{'default'} = [1];
 407         # Project specific override is not supported.
 408         'forks' => {
 409                 'override' => 0,
 410                 'default' => [0]},
 411
 412         # Insert custom links to the action bar of all project pages.
 413         # This enables you mainly to link to third-party scripts integrating
 414         # into gitweb; e.g. git-browser for graphical history representation
 415         # or custom web-based repository administration interface.
 416
 417         # The 'default' value consists of a list of triplets in the form
 418         # (label, link, position) where position is the label after which
 419         # to insert the link and link is a format string where %n expands
 420         # to the project name, %f to the project path within the filesystem,
 421         # %h to the current hash (h gitweb parameter) and %b to the current
 422         # hash base (hb gitweb parameter); %% expands to %.
 423
 424         # To enable system wide have in $GITWEB_CONFIG e.g.
 425         # $feature{'actions'}{'default'} = [('graphiclog',
 426         #       '/git-browser/by-commit.html?r=%n', 'summary')];
 427         # Project specific override is not supported.
 428         'actions' => {
 429                 'override' => 0,
 430                 'default' => []},
 431
 432         # Allow gitweb scan project content tags of project repository,
 433         # and display the popular Web 2.0-ish "tag cloud" near the projects
 434         # list.  Note that this is something COMPLETELY different from the
 435         # normal Git tags.
 436
 437         # gitweb by itself can show existing tags, but it does not handle
 438         # tagging itself; you need to do it externally, outside gitweb.
 439         # The format is described in git_get_project_ctags() subroutine.
 440         # You may want to install the HTML::TagCloud Perl module to get
 441         # a pretty tag cloud instead of just a list of tags.
 442
 443         # To enable system wide have in $GITWEB_CONFIG
 444         # $feature{'ctags'}{'default'} = [1];
 445         # Project specific override is not supported.
 446
 447         # In the future whether ctags editing is enabled might depend
 448         # on the value, but using 1 should always mean no editing of ctags.
 449         'ctags' => {
 450                 'override' => 0,
 451                 'default' => [0]},
 452
 453         # The maximum number of patches in a patchset generated in patch
 454         # view. Set this to 0 or undef to disable patch view, or to a
 455         # negative number to remove any limit.
 456
 457         # To disable system wide have in $GITWEB_CONFIG
 458         # $feature{'patches'}{'default'} = [0];
 459         # To have project specific config enable override in $GITWEB_CONFIG
 460         # $feature{'patches'}{'override'} = 1;
 461         # and in project config gitweb.patches = 0|n;
 462         # where n is the maximum number of patches allowed in a patchset.
 463         'patches' => {
 464                 'sub' => \&feature_patches,
 465                 'override' => 0,
 466                 'default' => [16]},
 467
 468         # Avatar support. When this feature is enabled, views such as
 469         # shortlog or commit will display an avatar associated with
 470         # the email of the committer(s) and/or author(s).
 471
 472         # Currently available providers are gravatar and picon.
 473         # If an unknown provider is specified, the feature is disabled.
 474
 475         # Gravatar depends on Digest::MD5.
 476         # Picon currently relies on the indiana.edu database.
 477
 478         # To enable system wide have in $GITWEB_CONFIG
 479         # $feature{'avatar'}{'default'} = ['<provider>'];
 480         # where <provider> is either gravatar or picon.
 481         # To have project specific config enable override in $GITWEB_CONFIG
 482         # $feature{'avatar'}{'override'} = 1;
 483         # and in project config gitweb.avatar = <provider>;
 484         'avatar' => {
 485                 'sub' => \&feature_avatar,
 486                 'override' => 0,
 487                 'default' => ['']},
 488
 489         # Enable displaying how much time and how many git commands
 490         # it took to generate and display page.  Disabled by default.
 491         # Project specific override is not supported.
 492         'timed' => {
 493                 'override' => 0,
 494                 'default' => [0]},
 495
 496         # Enable turning some links into links to actions which require
 497         # JavaScript to run (like 'blame_incremental').  Not enabled by
 498         # default.  Project specific override is currently not supported.
 499         'javascript-actions' => {
 500                 'override' => 0,
 501                 'default' => [0]},
 502
 503         # Enable and configure ability to change common timezone for dates
 504         # in gitweb output via JavaScript.  Enabled by default.
 505         # Project specific override is not supported.
 506         'javascript-timezone' => {
 507                 'override' => 0,
 508                 'default' => [
 509                         'local',     # default timezone: 'utc', 'local', or '(-|+)HHMM' format,
 510                                      # or undef to turn off this feature
 511                         'gitweb_tz', # name of cookie where to store selected timezone
 512                         'datetime',  # CSS class used to mark up dates for manipulation
 513                 ]},
 514
 515         # Syntax highlighting support. This is based on Daniel Svensson's
 516         # and Sham Chukoury's work in gitweb-xmms2.git.
 517         # It requires the 'highlight' program present in $PATH,
 518         # and therefore is disabled by default.
 519
 520         # To enable system wide have in $GITWEB_CONFIG
 521         # $feature{'highlight'}{'default'} = [1];
 522
 523         'highlight' => {
 524                 'sub' => sub { feature_bool('highlight', @_) },
 525                 'override' => 0,
 526                 'default' => [0]},
 527
 528         # Enable displaying of remote heads in the heads list
 529
 530         # To enable system wide have in $GITWEB_CONFIG
 531         # $feature{'remote_heads'}{'default'} = [1];
 532         # To have project specific config enable override in $GITWEB_CONFIG
 533         # $feature{'remote_heads'}{'override'} = 1;
 534         # and in project config gitweb.remote_heads = 0|1;
 535         'remote_heads' => {
 536                 'sub' => sub { feature_bool('remote_heads', @_) },
 537                 'override' => 0,
 538                 'default' => [0]},
 539 );
 540
 541 sub gitweb_get_feature {
 542         my ($name) = @_;
 543         return unless exists $feature{$name};
 544         my ($sub, $override, @defaults) = (
 545                 $feature{$name}{'sub'},
 546                 $feature{$name}{'override'},
 547                 @{$feature{$name}{'default'}});
 548         # project specific override is possible only if we have project
 549         our $git_dir; # global variable, declared later
 550         if (!$override || !defined $git_dir) {
 551                 return @defaults;
 552         }
 553         if (!defined $sub) {
 554                 warn "feature $name is not overridable";
 555                 return @defaults;
 556         }
 557         return $sub->(@defaults);
 558 }
 559
 560 # A wrapper to check if a given feature is enabled.
 561 # With this, you can say
 562 #
 563 #   my $bool_feat = gitweb_check_feature('bool_feat');
 564 #   gitweb_check_feature('bool_feat') or somecode;
 565 #
 566 # instead of
 567 #
 568 #   my ($bool_feat) = gitweb_get_feature('bool_feat');
 569 #   (gitweb_get_feature('bool_feat'))[0] or somecode;
 570 #
 571 sub gitweb_check_feature {
 572         return (gitweb_get_feature(@_))[0];
 573 }
 574
 575
 576 sub feature_bool {
 577         my $key = shift;
 578         my ($val) = git_get_project_config($key, '--bool');
 579
 580         if (!defined $val) {
 581                 return ($_[0]);
 582         } elsif ($val eq 'true') {
 583                 return (1);
 584         } elsif ($val eq 'false') {
 585                 return (0);
 586         }
 587 }
 588
 589 sub feature_snapshot {
 590         my (@fmts) = @_;
 591
 592         my ($val) = git_get_project_config('snapshot');
 593
 594         if ($val) {
 595                 @fmts = ($val eq 'none' ? () : split /\s*[,\s]\s*/, $val);
 596         }
 597
 598         return @fmts;
 599 }
 600
 601 sub feature_patches {
 602         my @val = (git_get_project_config('patches', '--int'));
 603
 604         if (@val) {
 605                 return @val;
 606         }
 607
 608         return ($_[0]);
 609 }
 610
 611 sub feature_avatar {
 612         my @val = (git_get_project_config('avatar'));
 613
 614         return @val ? @val : @_;
 615 }
 616
 617 # checking HEAD file with -e is fragile if the repository was
 618 # initialized long time ago (i.e. symlink HEAD) and was pack-ref'ed
 619 # and then pruned.
 620 sub check_head_link {
 621         my ($dir) = @_;
 622         my $headfile = "$dir/HEAD";
 623         return ((-e $headfile) ||
 624                 (-l $headfile && readlink($headfile) =~ /^refs\/heads\//));
 625 }
 626
 627 sub check_export_ok {
 628         my ($dir) = @_;
 629         return (check_head_link($dir) &&
 630                 (!$export_ok || -e "$dir/$export_ok") &&
 631                 (!$export_auth_hook || $export_auth_hook->($dir)));
 632 }
 633
 634 # process alternate names for backward compatibility
 635 # filter out unsupported (unknown) snapshot formats
 636 sub filter_snapshot_fmts {
 637         my @fmts = @_;
 638
 639         @fmts = map {
 640                 exists $known_snapshot_format_aliases{$_} ?
 641                        $known_snapshot_format_aliases{$_} : $_} @fmts;
 642         @fmts = grep {
 643                 exists $known_snapshot_formats{$_} &&
 644                 !$known_snapshot_formats{$_}{'disabled'}} @fmts;
 645 }
 646
 647 # If it is set to code reference, it is code that it is to be run once per
 648 # request, allowing updating configurations that change with each request,
 649 # while running other code in config file only once.
 650 #
 651 # Otherwise, if it is false then gitweb would process config file only once;
 652 # if it is true then gitweb config would be run for each request.
 653 our $per_request_config = 1;
 654
 655 # read and parse gitweb config file given by its parameter.
 656 # returns true on success, false on recoverable error, allowing
 657 # to chain this subroutine, using first file that exists.
 658 # dies on errors during parsing config file, as it is unrecoverable.
 659 sub read_config_file {
 660         my $filename = shift;
 661         return unless defined $filename;
 662         # die if there are errors parsing config file
 663         if (-e $filename) {
 664                 do $filename;
 665                 die $@ if $@;
 666                 return 1;
 667         }
 668         return;
 669 }
 670
 671 our ($GITWEB_CONFIG, $GITWEB_CONFIG_SYSTEM, $GITWEB_CONFIG_COMMON);
 672 sub evaluate_gitweb_config {
 673         our $GITWEB_CONFIG = $ENV{'GITWEB_CONFIG'} || "++GITWEB_CONFIG++";
 674         our $GITWEB_CONFIG_SYSTEM = $ENV{'GITWEB_CONFIG_SYSTEM'} || "++GITWEB_CONFIG_SYSTEM++";
 675         our $GITWEB_CONFIG_COMMON = $ENV{'GITWEB_CONFIG_COMMON'} || "++GITWEB_CONFIG_COMMON++";
 676
 677         # Protect agains duplications of file names, to not read config twice.
 678         # Only one of $GITWEB_CONFIG and $GITWEB_CONFIG_SYSTEM is used, so
 679         # there possibility of duplication of filename there doesn't matter.
 680         $GITWEB_CONFIG = ""        if ($GITWEB_CONFIG eq $GITWEB_CONFIG_COMMON);
 681         $GITWEB_CONFIG_SYSTEM = "" if ($GITWEB_CONFIG_SYSTEM eq $GITWEB_CONFIG_COMMON);
 682
 683         # Common system-wide settings for convenience.
 684         # Those settings can be ovverriden by GITWEB_CONFIG or GITWEB_CONFIG_SYSTEM.
 685         read_config_file($GITWEB_CONFIG_COMMON);
 686
 687         # Use first config file that exists.  This means use the per-instance
 688         # GITWEB_CONFIG if exists, otherwise use GITWEB_SYSTEM_CONFIG.
 689         read_config_file($GITWEB_CONFIG) and return;
 690         read_config_file($GITWEB_CONFIG_SYSTEM);
 691 }
 692
 693 # Get loadavg of system, to compare against $maxload.
 694 # Currently it requires '/proc/loadavg' present to get loadavg;
 695 # if it is not present it returns 0, which means no load checking.
 696 sub get_loadavg {
 697         if( -e '/proc/loadavg' ){
 698                 open my $fd, '<', '/proc/loadavg'
 699                         or return 0;
 700                 my @load = split(/\s+/, scalar <$fd>);
 701                 close $fd;
 702
 703                 # The first three columns measure CPU and IO utilization of the last one,
 704                 # five, and 10 minute periods.  The fourth column shows the number of
 705                 # currently running processes and the total number of processes in the m/n
 706                 # format.  The last column displays the last process ID used.
 707                 return $load[0] || 0;
 708         }
 709         # additional checks for load average should go here for things that don't export
 710         # /proc/loadavg
 711
 712         return 0;
 713 }
 714
 715 # version of the core git binary
 716 our $git_version;
 717 sub evaluate_git_version {
 718         our $git_version = qx("$GIT" --version) =~ m/git version (.*)$/ ? $1 : "unknown";
 719         $number_of_git_cmds++;
 720 }
 721
 722 sub check_loadavg {
 723         if (defined $maxload && get_loadavg() > $maxload) {
 724                 die_error(503, "The load average on the server is too high");
 725         }
 726 }
 727
 728 # ======================================================================
 729 # input validation and dispatch
 730
 731 # input parameters can be collected from a variety of sources (presently, CGI
 732 # and PATH_INFO), so we define an %input_params hash that collects them all
 733 # together during validation: this allows subsequent uses (e.g. href()) to be
 734 # agnostic of the parameter origin
 735
 736 our %input_params = ();
 737
 738 # input parameters are stored with the long parameter name as key. This will
 739 # also be used in the href subroutine to convert parameters to their CGI
 740 # equivalent, and since the href() usage is the most frequent one, we store
 741 # the name -> CGI key mapping here, instead of the reverse.
 742 #
 743 # XXX: Warning: If you touch this, check the search form for updating,
 744 # too.
 745
 746 our @cgi_param_mapping = (
 747         project => "p",
 748         action => "a",
 749         file_name => "f",
 750         file_parent => "fp",
 751         hash => "h",
 752         hash_parent => "hp",
 753         hash_base => "hb",
 754         hash_parent_base => "hpb",
 755         page => "pg",
 756         order => "o",
 757         searchtext => "s",
 758         searchtype => "st",
 759         snapshot_format => "sf",
 760         extra_options => "opt",
 761         search_use_regexp => "sr",
 762         ctag => "by_tag",
 763         diff_style => "ds",
 764         project_filter => "pf",
 765         # this must be last entry (for manipulation from JavaScript)
 766         javascript => "js"
 767 );
 768 our %cgi_param_mapping = @cgi_param_mapping;
 769
 770 # we will also need to know the possible actions, for validation
 771 our %actions = (
 772         "blame" => \&git_blame,
 773         "blame_incremental" => \&git_blame_incremental,
 774         "blame_data" => \&git_blame_data,
 775         "blobdiff" => \&git_blobdiff,
 776         "blobdiff_plain" => \&git_blobdiff_plain,
 777         "blob" => \&git_blob,
 778         "blob_plain" => \&git_blob_plain,
 779         "commitdiff" => \&git_commitdiff,
 780         "commitdiff_plain" => \&git_commitdiff_plain,
 781         "commit" => \&git_commit,
 782         "forks" => \&git_forks,
 783         "heads" => \&git_heads,
 784         "history" => \&git_history,
 785         "log" => \&git_log,
 786         "patch" => \&git_patch,
 787         "patches" => \&git_patches,
 788         "remotes" => \&git_remotes,
 789         "rss" => \&git_rss,
 790         "atom" => \&git_atom,
 791         "search" => \&git_search,
 792         "search_help" => \&git_search_help,
 793         "shortlog" => \&git_shortlog,
 794         "summary" => \&git_summary,
 795         "tag" => \&git_tag,
 796         "tags" => \&git_tags,
 797         "tree" => \&git_tree,
 798         "snapshot" => \&git_snapshot,
 799         "object" => \&git_object,
 800         # those below don't need $project
 801         "opml" => \&git_opml,
 802         "project_list" => \&git_project_list,
 803         "project_index" => \&git_project_index,
 804 );
 805
 806 # finally, we have the hash of allowed extra_options for the commands that
 807 # allow them
 808 our %allowed_options = (
 809         "--no-merges" => [ qw(rss atom log shortlog history) ],
 810 );
 811
 812 # fill %input_params with the CGI parameters. All values except for 'opt'
 813 # should be single values, but opt can be an array. We should probably
 814 # build an array of parameters that can be multi-valued, but since for the time
 815 # being it's only this one, we just single it out
 816 sub evaluate_query_params {
 817         our $cgi;
 818
 819         while (my ($name, $symbol) = each %cgi_param_mapping) {
 820                 if ($symbol eq 'opt') {
 821                         $input_params{$name} = [ map { decode_utf8($_) } $cgi->param($symbol) ];
 822                 } else {
 823                         $input_params{$name} = decode_utf8($cgi->param($symbol));
 824                 }
 825         }
 826 }
 827
 828 # now read PATH_INFO and update the parameter list for missing parameters
 829 sub evaluate_path_info {
 830         return if defined $input_params{'project'};
 831         return if !$path_info;
 832         $path_info =~ s,^/+,,;
 833         return if !$path_info;
 834
 835         # find which part of PATH_INFO is project
 836         my $project = $path_info;
 837         $project =~ s,/+$,,;
 838         while ($project && !check_head_link("$projectroot/$project")) {
 839                 $project =~ s,/*[^/]*$,,;
 840         }
 841         return unless $project;
 842         $input_params{'project'} = $project;
 843
 844         # do not change any parameters if an action is given using the query string
 845         return if $input_params{'action'};
 846         $path_info =~ s,^\Q$project\E/*,,;
 847
 848         # next, check if we have an action
 849         my $action = $path_info;
 850         $action =~ s,/.*$,,;
 851         if (exists $actions{$action}) {
 852                 $path_info =~ s,^$action/*,,;
 853                 $input_params{'action'} = $action;
 854         }
 855
 856         # list of actions that want hash_base instead of hash, but can have no
 857         # pathname (f) parameter
 858         my @wants_base = (
 859                 'tree',
 860                 'history',
 861         );
 862
 863         # we want to catch, among others
 864         # [$hash_parent_base[:$file_parent]..]$hash_parent[:$file_name]
 865         my ($parentrefname, $parentpathname, $refname, $pathname) =
 866                 ($path_info =~ /^(?:(.+?)(?::(.+))?\.\.)?([^:]+?)?(?::(.+))?$/);
 867
 868         # first, analyze the 'current' part
 869         if (defined $pathname) {
 870                 # we got "branch:filename" or "branch:dir/"
 871                 # we could use git_get_type(branch:pathname), but:
 872                 # - it needs $git_dir
 873                 # - it does a git() call
 874                 # - the convention of terminating directories with a slash
 875                 #   makes it superfluous
 876                 # - embedding the action in the PATH_INFO would make it even
 877                 #   more superfluous
 878                 $pathname =~ s,^/+,,;
 879                 if (!$pathname || substr($pathname, -1) eq "/") {
 880                         $input_params{'action'} ||= "tree";
 881                         $pathname =~ s,/$,,;
 882                 } else {
 883                         # the default action depends on whether we had parent info
 884                         # or not
 885                         if ($parentrefname) {
 886                                 $input_params{'action'} ||= "blobdiff_plain";
 887                         } else {
 888                                 $input_params{'action'} ||= "blob_plain";
 889                         }
 890                 }
 891                 $input_params{'hash_base'} ||= $refname;
 892                 $input_params{'file_name'} ||= $pathname;
 893         } elsif (defined $refname) {
 894                 # we got "branch". In this case we have to choose if we have to
 895                 # set hash or hash_base.
 896                 #
 897                 # Most of the actions without a pathname only want hash to be
 898                 # set, except for the ones specified in @wants_base that want
 899                 # hash_base instead. It should also be noted that hand-crafted
 900                 # links having 'history' as an action and no pathname or hash
 901                 # set will fail, but that happens regardless of PATH_INFO.
 902                 if (defined $parentrefname) {
 903                         # if there is parent let the default be 'shortlog' action
 904                         # (for http://git.example.com/repo.git/A..B links); if there
 905                         # is no parent, dispatch will detect type of object and set
 906                         # action appropriately if required (if action is not set)
 907                         $input_params{'action'} ||= "shortlog";
 908                 }
 909                 if ($input_params{'action'} &&
 910                     grep { $_ eq $input_params{'action'} } @wants_base) {
 911                         $input_params{'hash_base'} ||= $refname;
 912                 } else {
 913                         $input_params{'hash'} ||= $refname;
 914                 }
 915         }
 916
 917         # next, handle the 'parent' part, if present
 918         if (defined $parentrefname) {
 919                 # a missing pathspec defaults to the 'current' filename, allowing e.g.
 920                 # someproject/blobdiff/oldrev..newrev:/filename
 921                 if ($parentpathname) {
 922                         $parentpathname =~ s,^/+,,;
 923                         $parentpathname =~ s,/$,,;
 924                         $input_params{'file_parent'} ||= $parentpathname;
 925                 } else {
 926                         $input_params{'file_parent'} ||= $input_params{'file_name'};
 927                 }
 928                 # we assume that hash_parent_base is wanted if a path was specified,
 929                 # or if the action wants hash_base instead of hash
 930                 if (defined $input_params{'file_parent'} ||
 931                         grep { $_ eq $input_params{'action'} } @wants_base) {
 932                         $input_params{'hash_parent_base'} ||= $parentrefname;
 933                 } else {
 934                         $input_params{'hash_parent'} ||= $parentrefname;
 935                 }
 936         }
 937
 938         # for the snapshot action, we allow URLs in the form
 939         # $project/snapshot/$hash.ext
 940         # where .ext determines the snapshot and gets removed from the
 941         # passed $refname to provide the $hash.
 942         #
 943         # To be able to tell that $refname includes the format extension, we
 944         # require the following two conditions to be satisfied:
 945         # - the hash input parameter MUST have been set from the $refname part
 946         #   of the URL (i.e. they must be equal)
 947         # - the snapshot format MUST NOT have been defined already (e.g. from
 948         #   CGI parameter sf)
 949         # It's also useless to try any matching unless $refname has a dot,
 950         # so we check for that too
 951         if (defined $input_params{'action'} &&
 952                 $input_params{'action'} eq 'snapshot' &&
 953                 defined $refname && index($refname, '.') != -1 &&
 954                 $refname eq $input_params{'hash'} &&
 955                 !defined $input_params{'snapshot_format'}) {
 956                 # We loop over the known snapshot formats, checking for
 957                 # extensions. Allowed extensions are both the defined suffix
 958                 # (which includes the initial dot already) and the snapshot
 959                 # format key itself, with a prepended dot
 960                 while (my ($fmt, $opt) = each %known_snapshot_formats) {
 961                         my $hash = $refname;
 962                         unless ($hash =~ s/(\Q$opt->{'suffix'}\E|\Q.$fmt\E)$//) {
 963                                 next;
 964                         }
 965                         my $sfx = $1;
 966                         # a valid suffix was found, so set the snapshot format
 967                         # and reset the hash parameter
 968                         $input_params{'snapshot_format'} = $fmt;
 969                         $input_params{'hash'} = $hash;
 970                         # we also set the format suffix to the one requested
 971                         # in the URL: this way a request for e.g. .tgz returns
 972                         # a .tgz instead of a .tar.gz
 973                         $known_snapshot_formats{$fmt}{'suffix'} = $sfx;
 974                         last;
 975                 }
 976         }
 977 }
 978
 979 our ($action, $project, $file_name, $file_parent, $hash, $hash_parent, $hash_base,
 980      $hash_parent_base, @extra_options, $page, $searchtype, $search_use_regexp,
 981      $searchtext, $search_regexp, $project_filter);
 982 sub evaluate_and_validate_params {
 983         our $action = $input_params{'action'};
 984         if (defined $action) {
 985                 if (!validate_action($action)) {
 986                         die_error(400, "Invalid action parameter");
 987                 }
 988         }
 989
 990         # parameters which are pathnames
 991         our $project = $input_params{'project'};
 992         if (defined $project) {
 993                 if (!validate_project($project)) {
 994                         undef $project;
 995                         die_error(404, "No such project");
 996                 }
 997         }
 998
 999         our $project_filter = $input_params{'project_filter'};
1000         if (defined $project_filter) {
1001                 if (!validate_pathname($project_filter)) {
1002                         die_error(404, "Invalid project_filter parameter");
1003                 }
1004         }
1005
1006         our $file_name = $input_params{'file_name'};
1007         if (defined $file_name) {
1008                 if (!validate_pathname($file_name)) {
1009                         die_error(400, "Invalid file parameter");
1010                 }
1011         }
1012
1013         our $file_parent = $input_params{'file_parent'};
1014         if (defined $file_parent) {
1015                 if (!validate_pathname($file_parent)) {
1016                         die_error(400, "Invalid file parent parameter");
1017                 }
1018         }
1019
1020         # parameters which are refnames
1021         our $hash = $input_params{'hash'};
1022         if (defined $hash) {
1023                 if (!validate_refname($hash)) {
1024                         die_error(400, "Invalid hash parameter");
1025                 }
1026         }
1027
1028         our $hash_parent = $input_params{'hash_parent'};
1029         if (defined $hash_parent) {
1030                 if (!validate_refname($hash_parent)) {
1031                         die_error(400, "Invalid hash parent parameter");
1032                 }
1033         }
1034
1035         our $hash_base = $input_params{'hash_base'};
1036         if (defined $hash_base) {
1037                 if (!validate_refname($hash_base)) {
1038                         die_error(400, "Invalid hash base parameter");
1039                 }
1040         }
1041
1042         our @extra_options = @{$input_params{'extra_options'}};
1043         # @extra_options is always defined, since it can only be (currently) set from
1044         # CGI, and $cgi->param() returns the empty array in array context if the param
1045         # is not set
1046         foreach my $opt (@extra_options) {
1047                 if (not exists $allowed_options{$opt}) {
1048                         die_error(400, "Invalid option parameter");
1049                 }
1050                 if (not grep(/^$action$/, @{$allowed_options{$opt}})) {
1051                         die_error(400, "Invalid option parameter for this action");
1052                 }
1053         }
1054
1055         our $hash_parent_base = $input_params{'hash_parent_base'};
1056         if (defined $hash_parent_base) {
1057                 if (!validate_refname($hash_parent_base)) {
1058                         die_error(400, "Invalid hash parent base parameter");
1059                 }
1060         }
1061
1062         # other parameters
1063         our $page = $input_params{'page'};
1064         if (defined $page) {
1065                 if ($page =~ m/[^0-9]/) {
1066                         die_error(400, "Invalid page parameter");
1067                 }
1068         }
1069
1070         our $searchtype = $input_params{'searchtype'};
1071         if (defined $searchtype) {
1072                 if ($searchtype =~ m/[^a-z]/) {
1073                         die_error(400, "Invalid searchtype parameter");
1074                 }
1075         }
1076
1077         our $search_use_regexp = $input_params{'search_use_regexp'};
1078
1079         our $searchtext = $input_params{'searchtext'};
1080         our $search_regexp;
1081         if (defined $searchtext) {
1082                 if (length($searchtext) < 2) {
1083                         die_error(403, "At least two characters are required for search parameter");
1084                 }
1085                 if ($search_use_regexp) {
1086                         $search_regexp = $searchtext;
1087                         if (!eval { qr/$search_regexp/; 1; }) {
1088                                 (my $error = $@) =~ s/ at \S+ line \d+.*\n?//;
1089                                 die_error(400, "Invalid search regexp '$search_regexp'",
1090                                           esc_html($error));
1091                         }
1092                 } else {
1093                         $search_regexp = quotemeta $searchtext;
1094                 }
1095         }
1096 }
1097
1098 # path to the current git repository
1099 our $git_dir;
1100 sub evaluate_git_dir {
1101         our $git_dir = "$projectroot/$project" if $project;
1102 }
1103
1104 our (@snapshot_fmts, $git_avatar);
1105 sub configure_gitweb_features {
1106         # list of supported snapshot formats
1107         our @snapshot_fmts = gitweb_get_feature('snapshot');
1108         @snapshot_fmts = filter_snapshot_fmts(@snapshot_fmts);
1109
1110         # check that the avatar feature is set to a known provider name,
1111         # and for each provider check if the dependencies are satisfied.
1112         # if the provider name is invalid or the dependencies are not met,
1113         # reset $git_avatar to the empty string.
1114         our ($git_avatar) = gitweb_get_feature('avatar');
1115         if ($git_avatar eq 'gravatar') {
1116                 $git_avatar = '' unless (eval { require Digest::MD5; 1; });
1117         } elsif ($git_avatar eq 'picon') {
1118                 # no dependencies
1119         } else {
1120                 $git_avatar = '';
1121         }
1122 }
1123
1124 # custom error handler: 'die <message>' is Internal Server Error
1125 sub handle_errors_html {
1126         my $msg = shift; # it is already HTML escaped
1127
1128         # to avoid infinite loop where error occurs in die_error,
1129         # change handler to default handler, disabling handle_errors_html
1130         set_message("Error occured when inside die_error:\n$msg");
1131
1132         # you cannot jump out of die_error when called as error handler;
1133         # the subroutine set via CGI::Carp::set_message is called _after_
1134         # HTTP headers are already written, so it cannot write them itself
1135         die_error(undef, undef, $msg, -error_handler => 1, -no_http_header => 1);
1136 }
1137 set_message(\&handle_errors_html);
1138
1139 # dispatch
1140 sub dispatch {
1141         if (!defined $action) {
1142                 if (defined $hash) {
1143                         $action = git_get_type($hash);
1144                         $action or die_error(404, "Object does not exist");
1145                 } elsif (defined $hash_base && defined $file_name) {
1146                         $action = git_get_type("$hash_base:$file_name");
1147                         $action or die_error(404, "File or directory does not exist");
1148                 } elsif (defined $project) {
1149                         $action = 'summary';
1150                 } else {
1151                         $action = 'project_list';
1152                 }
1153         }
1154         if (!defined($actions{$action})) {
1155                 die_error(400, "Unknown action");
1156         }
1157         if ($action !~ m/^(?:opml|project_list|project_index)$/ &&
1158             !$project) {
1159                 die_error(400, "Project needed");
1160         }
1161         $actions{$action}->();
1162 }
1163
1164 sub reset_timer {
1165         our $t0 = [ gettimeofday() ]
1166                 if defined $t0;
1167         our $number_of_git_cmds = 0;
1168 }
1169
1170 our $first_request = 1;
1171 sub run_request {
1172         reset_timer();
1173
1174         evaluate_uri();
1175         if ($first_request) {
1176                 evaluate_gitweb_config();
1177                 evaluate_git_version();
1178         }
1179         if ($per_request_config) {
1180                 if (ref($per_request_config) eq 'CODE') {
1181                         $per_request_config->();
1182                 } elsif (!$first_request) {
1183                         evaluate_gitweb_config();
1184                 }
1185         }
1186         check_loadavg();
1187
1188         # $projectroot and $projects_list might be set in gitweb config file
1189         $projects_list ||= $projectroot;
1190
1191         evaluate_query_params();
1192         evaluate_path_info();
1193         evaluate_and_validate_params();
1194         evaluate_git_dir();
1195
1196         configure_gitweb_features();
1197
1198         dispatch();
1199 }
1200
1201 our $is_last_request = sub { 1 };
1202 our ($pre_dispatch_hook, $post_dispatch_hook, $pre_listen_hook);
1203 our $CGI = 'CGI';
1204 our $cgi;
1205 sub configure_as_fcgi {
1206         require CGI::Fast;
1207         our $CGI = 'CGI::Fast';
1208
1209         my $request_number = 0;
1210         # let each child service 100 requests
1211         our $is_last_request = sub { ++$request_number > 100 };
1212 }
1213 sub evaluate_argv {
1214         my $script_name = $ENV{'SCRIPT_NAME'} || $ENV{'SCRIPT_FILENAME'} || __FILE__;
1215         configure_as_fcgi()
1216                 if $script_name =~ /\.fcgi$/;
1217
1218         return unless (@ARGV);
1219
1220         require Getopt::Long;
1221         Getopt::Long::GetOptions(
1222                 'fastcgi|fcgi|f' => \&configure_as_fcgi,
1223                 'nproc|n=i' => sub {
1224                         my ($arg, $val) = @_;
1225                         return unless eval { require FCGI::ProcManager; 1; };
1226                         my $proc_manager = FCGI::ProcManager->new({
1227                                 n_processes => $val,
1228                         });
1229                         our $pre_listen_hook    = sub { $proc_manager->pm_manage()        };
1230                         our $pre_dispatch_hook  = sub { $proc_manager->pm_pre_dispatch()  };
1231                         our $post_dispatch_hook = sub { $proc_manager->pm_post_dispatch() };
1232                 },
1233         );
1234 }
1235
1236 sub run {
1237         evaluate_argv();
1238
1239         $first_request = 1;
1240         $pre_listen_hook->()
1241                 if $pre_listen_hook;
1242
1243  REQUEST:
1244         while ($cgi = $CGI->new()) {
1245                 $pre_dispatch_hook->()
1246                         if $pre_dispatch_hook;
1247
1248                 run_request();
1249
1250                 $post_dispatch_hook->()
1251                         if $post_dispatch_hook;
1252                 $first_request = 0;
1253
1254                 last REQUEST if ($is_last_request->());
1255         }
1256
1257  DONE_GITWEB:
1258         1;
1259 }
1260
1261 run();
1262
1263 if (defined caller) {
1264         # wrapped in a subroutine processing requests,
1265         # e.g. mod_perl with ModPerl::Registry, or PSGI with Plack::App::WrapCGI
1266         return;
1267 } else {
1268         # pure CGI script, serving single request
1269         exit;
1270 }
1271
1272 ## ======================================================================
1273 ## action links
1274
1275 # possible values of extra options
1276 # -full => 0|1      - use absolute/full URL ($my_uri/$my_url as base)
1277 # -replay => 1      - start from a current view (replay with modifications)
1278 # -path_info => 0|1 - don't use/use path_info URL (if possible)
1279 # -anchor => ANCHOR - add #ANCHOR to end of URL, implies -replay if used alone
1280 sub href {
1281         my %params = @_;
1282         # default is to use -absolute url() i.e. $my_uri
1283         my $href = $params{-full} ? $my_url : $my_uri;
1284
1285         # implicit -replay, must be first of implicit params
1286         $params{-replay} = 1 if (keys %params == 1 && $params{-anchor});
1287
1288         $params{'project'} = $project unless exists $params{'project'};
1289
1290         if ($params{-replay}) {
1291                 while (my ($name, $symbol) = each %cgi_param_mapping) {
1292                         if (!exists $params{$name}) {
1293                                 $params{$name} = $input_params{$name};
1294                         }
1295                 }
1296         }
1297
1298         my $use_pathinfo = gitweb_check_feature('pathinfo');
1299         if (defined $params{'project'} &&
1300             (exists $params{-path_info} ? $params{-path_info} : $use_pathinfo)) {
1301                 # try to put as many parameters as possible in PATH_INFO:
1302                 #   - project name
1303                 #   - action
1304                 #   - hash_parent or hash_parent_base:/file_parent
1305                 #   - hash or hash_base:/filename
1306                 #   - the snapshot_format as an appropriate suffix
1307
1308                 # When the script is the root DirectoryIndex for the domain,
1309                 # $href here would be something like http://gitweb.example.com/
1310                 # Thus, we strip any trailing / from $href, to spare us double
1311                 # slashes in the final URL
1312                 $href =~ s,/$,,;
1313
1314                 # Then add the project name, if present
1315                 $href .= "/".esc_path_info($params{'project'});
1316                 delete $params{'project'};
1317
1318                 # since we destructively absorb parameters, we keep this
1319                 # boolean that remembers if we're handling a snapshot
1320                 my $is_snapshot = $params{'action'} eq 'snapshot';
1321
1322                 # Summary just uses the project path URL, any other action is
1323                 # added to the URL
1324                 if (defined $params{'action'}) {
1325                         $href .= "/".esc_path_info($params{'action'})
1326                                 unless $params{'action'} eq 'summary';
1327                         delete $params{'action'};
1328                 }
1329
1330                 # Next, we put hash_parent_base:/file_parent..hash_base:/file_name,
1331                 # stripping nonexistent or useless pieces
1332                 $href .= "/" if ($params{'hash_base'} || $params{'hash_parent_base'}
1333                         || $params{'hash_parent'} || $params{'hash'});
1334                 if (defined $params{'hash_base'}) {
1335                         if (defined $params{'hash_parent_base'}) {
1336                                 $href .= esc_path_info($params{'hash_parent_base'});
1337                                 # skip the file_parent if it's the same as the file_name
1338                                 if (defined $params{'file_parent'}) {
1339                                         if (defined $params{'file_name'} && $params{'file_parent'} eq $params{'file_name'}) {
1340                                                 delete $params{'file_parent'};
1341                                         } elsif ($params{'file_parent'} !~ /\.\./) {
1342                                                 $href .= ":/".esc_path_info($params{'file_parent'});
1343                                                 delete $params{'file_parent'};
1344                                         }
1345                                 }
1346                                 $href .= "..";
1347                                 delete $params{'hash_parent'};
1348                                 delete $params{'hash_parent_base'};
1349                         } elsif (defined $params{'hash_parent'}) {
1350                                 $href .= esc_path_info($params{'hash_parent'}). "..";
1351                                 delete $params{'hash_parent'};
1352                         }
1353
1354                         $href .= esc_path_info($params{'hash_base'});
1355                         if (defined $params{'file_name'} && $params{'file_name'} !~ /\.\./) {
1356                                 $href .= ":/".esc_path_info($params{'file_name'});
1357                                 delete $params{'file_name'};
1358                         }
1359                         delete $params{'hash'};
1360                         delete $params{'hash_base'};
1361                 } elsif (defined $params{'hash'}) {
1362                         $href .= esc_path_info($params{'hash'});
1363                         delete $params{'hash'};
1364                 }
1365
1366                 # If the action was a snapshot, we can absorb the
1367                 # snapshot_format parameter too
1368                 if ($is_snapshot) {
1369                         my $fmt = $params{'snapshot_format'};
1370                         # snapshot_format should always be defined when href()
1371                         # is called, but just in case some code forgets, we
1372                         # fall back to the default
1373                         $fmt ||= $snapshot_fmts[0];
1374                         $href .= $known_snapshot_formats{$fmt}{'suffix'};
1375                         delete $params{'snapshot_format'};
1376                 }
1377         }
1378
1379         # now encode the parameters explicitly
1380         my @result = ();
1381         for (my $i = 0; $i < @cgi_param_mapping; $i += 2) {
1382                 my ($name, $symbol) = ($cgi_param_mapping[$i], $cgi_param_mapping[$i+1]);
1383                 if (defined $params{$name}) {
1384                         if (ref($params{$name}) eq "ARRAY") {
1385                                 foreach my $par (@{$params{$name}}) {
1386                                         push @result, $symbol . "=" . esc_param($par);
1387                                 }
1388                         } else {
1389                                 push @result, $symbol . "=" . esc_param($params{$name});
1390                         }
1391                 }
1392         }
1393         $href .= "?" . join(';', @result) if scalar @result;
1394
1395         # final transformation: trailing spaces must be escaped (URI-encoded)
1396         $href =~ s/(\s+)$/CGI::escape($1)/e;
1397
1398         if ($params{-anchor}) {
1399                 $href .= "#".esc_param($params{-anchor});
1400         }
1401
1402         return $href;
1403 }
1404
1405
1406 ## ======================================================================
1407 ## validation, quoting/unquoting and escaping
1408
1409 sub validate_action {
1410         my $input = shift || return undef;
1411         return undef unless exists $actions{$input};
1412         return $input;
1413 }
1414
1415 sub validate_project {
1416         my $input = shift || return undef;
1417         if (!validate_pathname($input) ||
1418                 !(-d "$projectroot/$input") ||
1419                 !check_export_ok("$projectroot/$input") ||
1420                 ($strict_export && !project_in_list($input))) {
1421                 return undef;
1422         } else {
1423                 return $input;
1424         }
1425 }
1426
1427 sub validate_pathname {
1428         my $input = shift || return undef;
1429
1430         # no '.' or '..' as elements of path, i.e. no '.' nor '..'
1431         # at the beginning, at the end, and between slashes.
1432         # also this catches doubled slashes
1433         if ($input =~ m!(^|/)(|\.|\.\.)(/|$)!) {
1434                 return undef;
1435         }
1436         # no null characters
1437         if ($input =~ m!\0!) {
1438                 return undef;
1439         }
1440         return $input;
1441 }
1442
1443 sub validate_refname {
1444         my $input = shift || return undef;
1445
1446         # textual hashes are O.K.
1447         if ($input =~ m/^[0-9a-fA-F]{40}$/) {
1448                 return $input;
1449         }
1450         # it must be correct pathname
1451         $input = validate_pathname($input)
1452                 or return undef;
1453         # restrictions on ref name according to git-check-ref-format
1454         if ($input =~ m!(/\.|\.\.|[\000-\040\177 ~^:?*\[]|/$)!) {
1455                 return undef;
1456         }
1457         return $input;
1458 }
1459
1460 # decode sequences of octets in utf8 into Perl's internal form,
1461 # which is utf-8 with utf8 flag set if needed.  gitweb writes out
1462 # in utf-8 thanks to "binmode STDOUT, ':utf8'" at beginning
1463 sub to_utf8 {
1464         my $str = shift;
1465         return undef unless defined $str;
1466
1467         if (utf8::is_utf8($str) || utf8::decode($str)) {
1468                 return $str;
1469         } else {
1470                 return decode($fallback_encoding, $str, Encode::FB_DEFAULT);
1471         }
1472 }
1473
1474 # quote unsafe chars, but keep the slash, even when it's not
1475 # correct, but quoted slashes look too horrible in bookmarks
1476 sub esc_param {
1477         my $str = shift;
1478         return undef unless defined $str;
1479         $str =~ s/([^A-Za-z0-9\-_.~()\/:@ ]+)/CGI::escape($1)/eg;
1480         $str =~ s/ /\+/g;
1481         return $str;
1482 }
1483
1484 # the quoting rules for path_info fragment are slightly different
1485 sub esc_path_info {
1486         my $str = shift;
1487         return undef unless defined $str;
1488
1489         # path_info doesn't treat '+' as space (specially), but '?' must be escaped
1490         $str =~ s/([^A-Za-z0-9\-_.~();\/;:@&= +]+)/CGI::escape($1)/eg;
1491
1492         return $str;
1493 }
1494
1495 # quote unsafe chars in whole URL, so some characters cannot be quoted
1496 sub esc_url {
1497         my $str = shift;
1498         return undef unless defined $str;
1499         $str =~ s/([^A-Za-z0-9\-_.~();\/;?:@&= ]+)/CGI::escape($1)/eg;
1500         $str =~ s/ /\+/g;
1501         return $str;
1502 }
1503
1504 # quote unsafe characters in HTML attributes
1505 sub esc_attr {
1506
1507         # for XHTML conformance escaping '"' to '&quot;' is not enough
1508         return esc_html(@_);
1509 }
1510
1511 # replace invalid utf8 character with SUBSTITUTION sequence
1512 sub esc_html {
1513         my $str = shift;
1514         my %opts = @_;
1515
1516         return undef unless defined $str;
1517
1518         $str = to_utf8($str);
1519         $str = $cgi->escapeHTML($str);
1520         if ($opts{'-nbsp'}) {
1521                 $str =~ s/ /&nbsp;/g;
1522         }
1523         $str =~ s|([[:cntrl:]])|(($1 ne "\t") ? quot_cec($1) : $1)|eg;
1524         return $str;
1525 }
1526
1527 # quote control characters and escape filename to HTML
1528 sub esc_path {
1529         my $str = shift;
1530         my %opts = @_;
1531
1532         return undef unless defined $str;
1533
1534         $str = to_utf8($str);
1535         $str = $cgi->escapeHTML($str);
1536         if ($opts{'-nbsp'}) {
1537                 $str =~ s/ /&nbsp;/g;
1538         }
1539         $str =~ s|([[:cntrl:]])|quot_cec($1)|eg;
1540         return $str;
1541 }
1542
1543 # Sanitize for use in XHTML + application/xml+xhtm (valid XML 1.0)
1544 sub sanitize {
1545         my $str = shift;
1546
1547         return undef unless defined $str;
1548
1549         $str = to_utf8($str);
1550         $str =~ s|([[:cntrl:]])|($1 =~ /[\t\n\r]/ ? $1 : quot_cec($1))|eg;
1551         return $str;
1552 }
1553
1554 # Make control characters "printable", using character escape codes (CEC)
1555 sub quot_cec {
1556         my $cntrl = shift;
1557         my %opts = @_;
1558         my %es = ( # character escape codes, aka escape sequences
1559                 "\t" => '\t',   # tab            (HT)
1560                 "\n" => '\n',   # line feed      (LF)
1561                 "\r" => '\r',   # carrige return (CR)
1562                 "\f" => '\f',   # form feed      (FF)
1563                 "\b" => '\b',   # backspace      (BS)
1564                 "\a" => '\a',   # alarm (bell)   (BEL)
1565                 "\e" => '\e',   # escape         (ESC)
1566                 "\013" => '\v', # vertical tab   (VT)
1567                 "\000" => '\0', # nul character  (NUL)
1568         );
1569         my $chr = ( (exists $es{$cntrl})
1570                     ? $es{$cntrl}
1571                     : sprintf('\%2x', ord($cntrl)) );
1572         if ($opts{-nohtml}) {
1573                 return $chr;
1574         } else {
1575                 return "<span class=\"cntrl\">$chr</span>";
1576         }
1577 }
1578
1579 # Alternatively use unicode control pictures codepoints,
1580 # Unicode "printable representation" (PR)
1581 sub quot_upr {
1582         my $cntrl = shift;
1583         my %opts = @_;
1584
1585         my $chr = sprintf('&#%04d;', 0x2400+ord($cntrl));
1586         if ($opts{-nohtml}) {
1587                 return $chr;
1588         } else {
1589                 return "<span class=\"cntrl\">$chr</span>";
1590         }
1591 }
1592
1593 # git may return quoted and escaped filenames
1594 sub unquote {
1595         my $str = shift;
1596
1597         sub unq {
1598                 my $seq = shift;
1599                 my %es = ( # character escape codes, aka escape sequences
1600                         't' => "\t",   # tab            (HT, TAB)
1601                         'n' => "\n",   # newline        (NL)
1602                         'r' => "\r",   # return         (CR)
1603                         'f' => "\f",   # form feed      (FF)
1604                         'b' => "\b",   # backspace      (BS)
1605                         'a' => "\a",   # alarm (bell)   (BEL)
1606                         'e' => "\e",   # escape         (ESC)
1607                         'v' => "\013", # vertical tab   (VT)
1608                 );
1609
1610                 if ($seq =~ m/^[0-7]{1,3}$/) {
1611                         # octal char sequence
1612                         return chr(oct($seq));
1613                 } elsif (exists $es{$seq}) {
1614                         # C escape sequence, aka character escape code
1615                         return $es{$seq};
1616                 }
1617                 # quoted ordinary character
1618                 return $seq;
1619         }
1620
1621         if ($str =~ m/^"(.*)"$/) {
1622                 # needs unquoting
1623                 $str = $1;
1624                 $str =~ s/\\([^0-7]|[0-7]{1,3})/unq($1)/eg;
1625         }
1626         return $str;
1627 }
1628
1629 # escape tabs (convert tabs to spaces)
1630 sub untabify {
1631         my $line = shift;
1632
1633         while ((my $pos = index($line, "\t")) != -1) {
1634                 if (my $count = (8 - ($pos % 8))) {
1635                         my $spaces = ' ' x $count;
1636                         $line =~ s/\t/$spaces/;
1637                 }
1638         }
1639
1640         return $line;
1641 }
1642
1643 sub project_in_list {
1644         my $project = shift;
1645         my @list = git_get_projects_list();
1646         return @list && scalar(grep { $_->{'path'} eq $project } @list);
1647 }
1648
1649 ## ----------------------------------------------------------------------
1650 ## HTML aware string manipulation
1651
1652 # Try to chop given string on a word boundary between position
1653 # $len and $len+$add_len. If there is no word boundary there,
1654 # chop at $len+$add_len. Do not chop if chopped part plus ellipsis
1655 # (marking chopped part) would be longer than given string.
1656 sub chop_str {
1657         my $str = shift;
1658         my $len = shift;
1659         my $add_len = shift || 10;
1660         my $where = shift || 'right'; # 'left' | 'center' | 'right'
1661
1662         # Make sure perl knows it is utf8 encoded so we don't
1663         # cut in the middle of a utf8 multibyte char.
1664         $str = to_utf8($str);
1665
1666         # allow only $len chars, but don't cut a word if it would fit in $add_len
1667         # if it doesn't fit, cut it if it's still longer than the dots we would add
1668         # remove chopped character entities entirely
1669
1670         # when chopping in the middle, distribute $len into left and right part
1671         # return early if chopping wouldn't make string shorter
1672         if ($where eq 'center') {
1673                 return $str if ($len + 5 >= length($str)); # filler is length 5
1674                 $len = int($len/2);
1675         } else {
1676                 return $str if ($len + 4 >= length($str)); # filler is length 4
1677         }
1678
1679         # regexps: ending and beginning with word part up to $add_len
1680         my $endre = qr/.{$len}\w{0,$add_len}/;
1681         my $begre = qr/\w{0,$add_len}.{$len}/;
1682
1683         if ($where eq 'left') {
1684                 $str =~ m/^(.*?)($begre)$/;
1685                 my ($lead, $body) = ($1, $2);
1686                 if (length($lead) > 4) {
1687                         $lead = " ...";
1688                 }
1689                 return "$lead$body";
1690
1691         } elsif ($where eq 'center') {
1692                 $str =~ m/^($endre)(.*)$/;
1693                 my ($left, $str)  = ($1, $2);
1694                 $str =~ m/^(.*?)($begre)$/;
1695                 my ($mid, $right) = ($1, $2);
1696                 if (length($mid) > 5) {
1697                         $mid = " ... ";
1698                 }
1699                 return "$left$mid$right";
1700
1701         } else {
1702                 $str =~ m/^($endre)(.*)$/;
1703                 my $body = $1;
1704                 my $tail = $2;
1705                 if (length($tail) > 4) {
1706                         $tail = "... ";
1707                 }
1708                 return "$body$tail";
1709         }
1710 }
1711
1712 # takes the same arguments as chop_str, but also wraps a <span> around the
1713 # result with a title attribute if it does get chopped. Additionally, the
1714 # string is HTML-escaped.
1715 sub chop_and_escape_str {
1716         my ($str) = @_;
1717
1718         my $chopped = chop_str(@_);
1719         $str = to_utf8($str);
1720         if ($chopped eq $str) {
1721                 return esc_html($chopped);
1722         } else {
1723                 $str =~ s/[[:cntrl:]]/?/g;
1724                 return $cgi->span({-title=>$str}, esc_html($chopped));
1725         }
1726 }
1727
1728 # Highlight selected fragments of string, using given CSS class,
1729 # and escape HTML.  It is assumed that fragments do not overlap.
1730 # Regions are passed as list of pairs (array references).
1731 #
1732 # Example: esc_html_hl_regions("foobar", "mark", [ 0, 3 ]) returns
1733 # '<span class="mark">foo</span>bar'
1734 sub esc_html_hl_regions {
1735         my ($str, $css_class, @sel) = @_;
1736         return esc_html($str) unless @sel;
1737
1738         my $out = '';
1739         my $pos = 0;
1740
1741         for my $s (@sel) {
1742                 $out .= esc_html(substr($str, $pos, $s->[0] - $pos))
1743                         if ($s->[0] - $pos > 0);
1744                 $out .= $cgi->span({-class => $css_class},
1745                                    esc_html(substr($str, $s->[0], $s->[1] - $s->[0])));
1746
1747                 $pos = $s->[1];
1748         }
1749         $out .= esc_html(substr($str, $pos))
1750                 if ($pos < length($str));
1751
1752         return $out;
1753 }
1754
1755 # return positions of beginning and end of each match
1756 sub matchpos_list {
1757         my ($str, $regexp) = @_;
1758         return unless (defined $str && defined $regexp);
1759
1760         my @matches;
1761         while ($str =~ /$regexp/g) {
1762                 push @matches, [$-[0], $+[0]];
1763         }
1764         return @matches;
1765 }
1766
1767 # highlight match (if any), and escape HTML
1768 sub esc_html_match_hl {
1769         my ($str, $regexp) = @_;
1770         return esc_html($str) unless defined $regexp;
1771
1772         my @matches = matchpos_list($str, $regexp);
1773         return esc_html($str) unless @matches;
1774
1775         return esc_html_hl_regions($str, 'match', @matches);
1776 }
1777
1778
1779 # highlight match (if any) of shortened string, and escape HTML
1780 sub esc_html_match_hl_chopped {
1781         my ($str, $chopped, $regexp) = @_;
1782         return esc_html_match_hl($str, $regexp) unless defined $chopped;
1783
1784         my @matches = matchpos_list($str, $regexp);
1785         return esc_html($chopped) unless @matches;
1786
1787         # filter matches so that we mark chopped string
1788         my $tail = "... "; # see chop_str
1789         unless ($chopped =~ s/\Q$tail\E$//) {
1790                 $tail = '';
1791         }
1792         my $chop_len = length($chopped);
1793         my $tail_len = length($tail);
1794         my @filtered;
1795
1796         for my $m (@matches) {
1797                 if ($m->[0] > $chop_len) {
1798                         push @filtered, [ $chop_len, $chop_len + $tail_len ] if ($tail_len > 0);
1799                         last;
1800                 } elsif ($m->[1] > $chop_len) {
1801                         push @filtered, [ $m->[0], $chop_len + $tail_len ];
1802                         last;
1803                 }
1804                 push @filtered, $m;
1805         }
1806
1807         return esc_html_hl_regions($chopped . $tail, 'match', @filtered);
1808 }
1809
1810 ## ----------------------------------------------------------------------
1811 ## functions returning short strings
1812
1813 # CSS class for given age value (in seconds)
1814 sub age_class {
1815         my $age = shift;
1816
1817         if (!defined $age) {
1818                 return "noage";
1819         } elsif ($age < 60*60*2) {
1820                 return "age0";
1821         } elsif ($age < 60*60*24*2) {
1822                 return "age1";
1823         } else {
1824                 return "age2";
1825         }
1826 }
1827
1828 # convert age in seconds to "nn units ago" string
1829 sub age_string {
1830         my $age = shift;
1831         my $age_str;
1832
1833         if ($age > 60*60*24*365*2) {
1834                 $age_str = (int $age/60/60/24/365);
1835                 $age_str .= " years ago";
1836         } elsif ($age > 60*60*24*(365/12)*2) {
1837                 $age_str = int $age/60/60/24/(365/12);
1838                 $age_str .= " months ago";
1839         } elsif ($age > 60*60*24*7*2) {
1840                 $age_str = int $age/60/60/24/7;
1841                 $age_str .= " weeks ago";
1842         } elsif ($age > 60*60*24*2) {
1843                 $age_str = int $age/60/60/24;
1844                 $age_str .= " days ago";
1845         } elsif ($age > 60*60*2) {
1846                 $age_str = int $age/60/60;
1847                 $age_str .= " hours ago";
1848         } elsif ($age > 60*2) {
1849                 $age_str = int $age/60;
1850                 $age_str .= " min ago";
1851         } elsif ($age > 2) {
1852                 $age_str = int $age;
1853                 $age_str .= " sec ago";
1854         } else {
1855                 $age_str .= " right now";
1856         }
1857         return $age_str;
1858 }
1859
1860 use constant {
1861         S_IFINVALID => 0030000,
1862         S_IFGITLINK => 0160000,
1863 };
1864
1865 # submodule/subproject, a commit object reference
1866 sub S_ISGITLINK {
1867         my $mode = shift;
1868
1869         return (($mode & S_IFMT) == S_IFGITLINK)
1870 }
1871
1872 # convert file mode in octal to symbolic file mode string
1873 sub mode_str {
1874         my $mode = oct shift;
1875
1876         if (S_ISGITLINK($mode)) {
1877                 return 'm---------';
1878         } elsif (S_ISDIR($mode & S_IFMT)) {
1879                 return 'drwxr-xr-x';
1880         } elsif (S_ISLNK($mode)) {
1881                 return 'lrwxrwxrwx';
1882         } elsif (S_ISREG($mode)) {
1883                 # git cares only about the executable bit
1884                 if ($mode & S_IXUSR) {
1885                         return '-rwxr-xr-x';
1886                 } else {
1887                         return '-rw-r--r--';
1888                 };
1889         } else {
1890                 return '----------';
1891         }
1892 }
1893
1894 # convert file mode in octal to file type string
1895 sub file_type {
1896         my $mode = shift;
1897
1898         if ($mode !~ m/^[0-7]+$/) {
1899                 return $mode;
1900         } else {
1901                 $mode = oct $mode;
1902         }
1903
1904         if (S_ISGITLINK($mode)) {
1905                 return "submodule";
1906         } elsif (S_ISDIR($mode & S_IFMT)) {
1907                 return "directory";
1908         } elsif (S_ISLNK($mode)) {
1909                 return "symlink";
1910         } elsif (S_ISREG($mode)) {
1911                 return "file";
1912         } else {
1913                 return "unknown";
1914         }
1915 }
1916
1917 # convert file mode in octal to file type description string
1918 sub file_type_long {
1919         my $mode = shift;
1920
1921         if ($mode !~ m/^[0-7]+$/) {
1922                 return $mode;
1923         } else {
1924                 $mode = oct $mode;
1925         }
1926
1927         if (S_ISGITLINK($mode)) {
1928                 return "submodule";
1929         } elsif (S_ISDIR($mode & S_IFMT)) {
1930                 return "directory";
1931         } elsif (S_ISLNK($mode)) {
1932                 return "symlink";
1933         } elsif (S_ISREG($mode)) {
1934                 if ($mode & S_IXUSR) {
1935                         return "executable";
1936                 } else {
1937                         return "file";
1938                 };
1939         } else {
1940                 return "unknown";
1941         }
1942 }
1943
1944
1945 ## ----------------------------------------------------------------------
1946 ## functions returning short HTML fragments, or transforming HTML fragments
1947 ## which don't belong to other sections
1948
1949 # format line of commit message.
1950 sub format_log_line_html {
1951         my $line = shift;
1952
1953         $line = esc_html($line, -nbsp=>1);
1954         $line =~ s{\b([0-9a-fA-F]{8,40})\b}{
1955                 $cgi->a({-href => href(action=>"object", hash=>$1),
1956                                         -class => "text"}, $1);
1957         }eg;
1958
1959         return $line;
1960 }
1961
1962 # format marker of refs pointing to given object
1963
1964 # the destination action is chosen based on object type and current context:
1965 # - for annotated tags, we choose the tag view unless it's the current view
1966 #   already, in which case we go to shortlog view
1967 # - for other refs, we keep the current view if we're in history, shortlog or
1968 #   log view, and select shortlog otherwise
1969 sub format_ref_marker {
1970         my ($refs, $id) = @_;
1971         my $markers = '';
1972
1973         if (defined $refs->{$id}) {
1974                 foreach my $ref (@{$refs->{$id}}) {
1975                         # this code exploits the fact that non-lightweight tags are the
1976                         # only indirect objects, and that they are the only objects for which
1977                         # we want to use tag instead of shortlog as action
1978                         my ($type, $name) = qw();
1979                         my $indirect = ($ref =~ s/\^\{\}$//);
1980                         # e.g. tags/v2.6.11 or heads/next
1981                         if ($ref =~ m!^(.*?)s?/(.*)$!) {
1982                                 $type = $1;
1983                                 $name = $2;
1984                         } else {
1985                                 $type = "ref";
1986                                 $name = $ref;
1987                         }
1988
1989                         my $class = $type;
1990                         $class .= " indirect" if $indirect;
1991
1992                         my $dest_action = "shortlog";
1993
1994                         if ($indirect) {
1995                                 $dest_action = "tag" unless $action eq "tag";
1996                         } elsif ($action =~ /^(history|(short)?log)$/) {
1997                                 $dest_action = $action;
1998                         }
1999
2000                         my $dest = "";
2001                         $dest .= "refs/" unless $ref =~ m!^refs/!;
2002                         $dest .= $ref;
2003
2004                         my $link = $cgi->a({
2005                                 -href => href(
2006                                         action=>$dest_action,
2007                                         hash=>$dest
2008                                 )}, $name);
2009
2010                         $markers .= " <span class=\"".esc_attr($class)."\" title=\"".esc_attr($ref)."\">" .
2011                                 $link . "</span>";
2012                 }
2013         }
2014
2015         if ($markers) {
2016                 return ' <span class="refs">'. $markers . '</span>';
2017         } else {
2018                 return "";
2019         }
2020 }
2021
2022 # format, perhaps shortened and with markers, title line
2023 sub format_subject_html {
2024         my ($long, $short, $href, $extra) = @_;
2025         $extra = '' unless defined($extra);
2026
2027         if (length($short) < length($long)) {
2028                 $long =~ s/[[:cntrl:]]/?/g;
2029                 return $cgi->a({-href => $href, -class => "list subject",
2030                                 -title => to_utf8($long)},
2031                        esc_html($short)) . $extra;
2032         } else {
2033                 return $cgi->a({-href => $href, -class => "list subject"},
2034                        esc_html($long)) . $extra;
2035         }
2036 }
2037
2038 # Rather than recomputing the url for an email multiple times, we cache it
2039 # after the first hit. This gives a visible benefit in views where the avatar
2040 # for the same email is used repeatedly (e.g. shortlog).
2041 # The cache is shared by all avatar engines (currently gravatar only), which
2042 # are free to use it as preferred. Since only one avatar engine is used for any
2043 # given page, there's no risk for cache conflicts.
2044 our %avatar_cache = ();
2045
2046 # Compute the picon url for a given email, by using the picon search service over at
2047 # http://www.cs.indiana.edu/picons/search.html
2048 sub picon_url {
2049         my $email = lc shift;
2050         if (!$avatar_cache{$email}) {
2051                 my ($user, $domain) = split('@', $email);
2052                 $avatar_cache{$email} =
2053                         "http://www.cs.indiana.edu/cgi-pub/kinzler/piconsearch.cgi/" .
2054                         "$domain/$user/" .
2055                         "users+domains+unknown/up/single";
2056         }
2057         return $avatar_cache{$email};
2058 }
2059
2060 # Compute the gravatar url for a given email, if it's not in the cache already.
2061 # Gravatar stores only the part of the URL before the size, since that's the
2062 # one computationally more expensive. This also allows reuse of the cache for
2063 # different sizes (for this particular engine).
2064 sub gravatar_url {
2065         my $email = lc shift;
2066         my $size = shift;
2067         $avatar_cache{$email} ||=
2068                 "http://www.gravatar.com/avatar/" .
2069                         Digest::MD5::md5_hex($email) . "?s=";
2070         return $avatar_cache{$email} . $size;
2071 }
2072
2073 # Insert an avatar for the given $email at the given $size if the feature
2074 # is enabled.
2075 sub git_get_avatar {
2076         my ($email, %opts) = @_;
2077         my $pre_white  = ($opts{-pad_before} ? "&nbsp;" : "");
2078         my $post_white = ($opts{-pad_after}  ? "&nbsp;" : "");
2079         $opts{-size} ||= 'default';
2080         my $size = $avatar_size{$opts{-size}} || $avatar_size{'default'};
2081         my $url = "";
2082         if ($git_avatar eq 'gravatar') {
2083                 $url = gravatar_url($email, $size);
2084         } elsif ($git_avatar eq 'picon') {
2085                 $url = picon_url($email);
2086         }
2087         # Other providers can be added by extending the if chain, defining $url
2088         # as needed. If no variant puts something in $url, we assume avatars
2089         # are completely disabled/unavailable.
2090         if ($url) {
2091                 return $pre_white .
2092                        "<img width=\"$size\" " .
2093                             "class=\"avatar\" " .
2094                             "src=\"".esc_url($url)."\" " .
2095                             "alt=\"\" " .
2096                        "/>" . $post_white;
2097         } else {
2098                 return "";
2099         }
2100 }
2101
2102 sub format_search_author {
2103         my ($author, $searchtype, $displaytext) = @_;
2104         my $have_search = gitweb_check_feature('search');
2105
2106         if ($have_search) {
2107                 my $performed = "";
2108                 if ($searchtype eq 'author') {
2109                         $performed = "authored";
2110                 } elsif ($searchtype eq 'committer') {
2111                         $performed = "committed";
2112                 }
2113
2114                 return $cgi->a({-href => href(action=>"search", hash=>$hash,
2115                                 searchtext=>$author,
2116                                 searchtype=>$searchtype), class=>"list",
2117                                 title=>"Search for commits $performed by $author"},
2118                                 $displaytext);
2119
2120         } else {
2121                 return $displaytext;
2122         }
2123 }
2124
2125 # format the author name of the given commit with the given tag
2126 # the author name is chopped and escaped according to the other
2127 # optional parameters (see chop_str).
2128 sub format_author_html {
2129         my $tag = shift;
2130         my $co = shift;
2131         my $author = chop_and_escape_str($co->{'author_name'}, @_);
2132         return "<$tag class=\"author\">" .
2133                format_search_author($co->{'author_name'}, "author",
2134                        git_get_avatar($co->{'author_email'}, -pad_after => 1) .
2135                        $author) .
2136                "</$tag>";
2137 }
2138
2139 # format git diff header line, i.e. "diff --(git|combined|cc) ..."
2140 sub format_git_diff_header_line {
2141         my $line = shift;
2142         my $diffinfo = shift;
2143         my ($from, $to) = @_;
2144
2145         if ($diffinfo->{'nparents'}) {
2146                 # combined diff
2147                 $line =~ s!^(diff (.*?) )"?.*$!$1!;
2148                 if ($to->{'href'}) {
2149                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2150                                          esc_path($to->{'file'}));
2151                 } else { # file was deleted (no href)
2152                         $line .= esc_path($to->{'file'});
2153                 }
2154         } else {
2155                 # "ordinary" diff
2156                 $line =~ s!^(diff (.*?) )"?a/.*$!$1!;
2157                 if ($from->{'href'}) {
2158                         $line .= $cgi->a({-href => $from->{'href'}, -class => "path"},
2159                                          'a/' . esc_path($from->{'file'}));
2160                 } else { # file was added (no href)
2161                         $line .= 'a/' . esc_path($from->{'file'});
2162                 }
2163                 $line .= ' ';
2164                 if ($to->{'href'}) {
2165                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2166                                          'b/' . esc_path($to->{'file'}));
2167                 } else { # file was deleted
2168                         $line .= 'b/' . esc_path($to->{'file'});
2169                 }
2170         }
2171
2172         return "<div class=\"diff header\">$line</div>\n";
2173 }
2174
2175 # format extended diff header line, before patch itself
2176 sub format_extended_diff_header_line {
2177         my $line = shift;
2178         my $diffinfo = shift;
2179         my ($from, $to) = @_;
2180
2181         # match <path>
2182         if ($line =~ s!^((copy|rename) from ).*$!$1! && $from->{'href'}) {
2183                 $line .= $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2184                                        esc_path($from->{'file'}));
2185         }
2186         if ($line =~ s!^((copy|rename) to ).*$!$1! && $to->{'href'}) {
2187                 $line .= $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2188                                  esc_path($to->{'file'}));
2189         }
2190         # match single <mode>
2191         if ($line =~ m/\s(\d{6})$/) {
2192                 $line .= '<span class="info"> (' .
2193                          file_type_long($1) .
2194                          ')</span>';
2195         }
2196         # match <hash>
2197         if ($line =~ m/^index [0-9a-fA-F]{40},[0-9a-fA-F]{40}/) {
2198                 # can match only for combined diff
2199                 $line = 'index ';
2200                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2201                         if ($from->{'href'}[$i]) {
2202                                 $line .= $cgi->a({-href=>$from->{'href'}[$i],
2203                                                   -class=>"hash"},
2204                                                  substr($diffinfo->{'from_id'}[$i],0,7));
2205                         } else {
2206                                 $line .= '0' x 7;
2207                         }
2208                         # separator
2209                         $line .= ',' if ($i < $diffinfo->{'nparents'} - 1);
2210                 }
2211                 $line .= '..';
2212                 if ($to->{'href'}) {
2213                         $line .= $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2214                                          substr($diffinfo->{'to_id'},0,7));
2215                 } else {
2216                         $line .= '0' x 7;
2217                 }
2218
2219         } elsif ($line =~ m/^index [0-9a-fA-F]{40}..[0-9a-fA-F]{40}/) {
2220                 # can match only for ordinary diff
2221                 my ($from_link, $to_link);
2222                 if ($from->{'href'}) {
2223                         $from_link = $cgi->a({-href=>$from->{'href'}, -class=>"hash"},
2224                                              substr($diffinfo->{'from_id'},0,7));
2225                 } else {
2226                         $from_link = '0' x 7;
2227                 }
2228                 if ($to->{'href'}) {
2229                         $to_link = $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2230                                            substr($diffinfo->{'to_id'},0,7));
2231                 } else {
2232                         $to_link = '0' x 7;
2233                 }
2234                 my ($from_id, $to_id) = ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
2235                 $line =~ s!$from_id\.\.$to_id!$from_link..$to_link!;
2236         }
2237
2238         return $line . "<br/>\n";
2239 }
2240
2241 # format from-file/to-file diff header
2242 sub format_diff_from_to_header {
2243         my ($from_line, $to_line, $diffinfo, $from, $to, @parents) = @_;
2244         my $line;
2245         my $result = '';
2246
2247         $line = $from_line;
2248         #assert($line =~ m/^---/) if DEBUG;
2249         # no extra formatting for "^--- /dev/null"
2250         if (! $diffinfo->{'nparents'}) {
2251                 # ordinary (single parent) diff
2252                 if ($line =~ m!^--- "?a/!) {
2253                         if ($from->{'href'}) {
2254                                 $line = '--- a/' .
2255                                         $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2256                                                 esc_path($from->{'file'}));
2257                         } else {
2258                                 $line = '--- a/' .
2259                                         esc_path($from->{'file'});
2260                         }
2261                 }
2262                 $result .= qq!<div class="diff from_file">$line</div>\n!;
2263
2264         } else {
2265                 # combined diff (merge commit)
2266                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2267                         if ($from->{'href'}[$i]) {
2268                                 $line = '--- ' .
2269                                         $cgi->a({-href=>href(action=>"blobdiff",
2270                                                              hash_parent=>$diffinfo->{'from_id'}[$i],
2271                                                              hash_parent_base=>$parents[$i],
2272                                                              file_parent=>$from->{'file'}[$i],
2273                                                              hash=>$diffinfo->{'to_id'},
2274                                                              hash_base=>$hash,
2275                                                              file_name=>$to->{'file'}),
2276                                                  -class=>"path",
2277                                                  -title=>"diff" . ($i+1)},
2278                                                 $i+1) .
2279                                         '/' .
2280                                         $cgi->a({-href=>$from->{'href'}[$i], -class=>"path"},
2281                                                 esc_path($from->{'file'}[$i]));
2282                         } else {
2283                                 $line = '--- /dev/null';
2284                         }
2285                         $result .= qq!<div class="diff from_file">$line</div>\n!;
2286                 }
2287         }
2288
2289         $line = $to_line;
2290         #assert($line =~ m/^\+\+\+/) if DEBUG;
2291         # no extra formatting for "^+++ /dev/null"
2292         if ($line =~ m!^\+\+\+ "?b/!) {
2293                 if ($to->{'href'}) {
2294                         $line = '+++ b/' .
2295                                 $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2296                                         esc_path($to->{'file'}));
2297                 } else {
2298                         $line = '+++ b/' .
2299                                 esc_path($to->{'file'});
2300                 }
2301         }
2302         $result .= qq!<div class="diff to_file">$line</div>\n!;
2303
2304         return $result;
2305 }
2306
2307 # create note for patch simplified by combined diff
2308 sub format_diff_cc_simplified {
2309         my ($diffinfo, @parents) = @_;
2310         my $result = '';
2311
2312         $result .= "<div class=\"diff header\">" .
2313                    "diff --cc ";
2314         if (!is_deleted($diffinfo)) {
2315                 $result .= $cgi->a({-href => href(action=>"blob",
2316                                                   hash_base=>$hash,
2317                                                   hash=>$diffinfo->{'to_id'},
2318                                                   file_name=>$diffinfo->{'to_file'}),
2319                                     -class => "path"},
2320                                    esc_path($diffinfo->{'to_file'}));
2321         } else {
2322                 $result .= esc_path($diffinfo->{'to_file'});
2323         }
2324         $result .= "</div>\n" . # class="diff header"
2325                    "<div class=\"diff nodifferences\">" .
2326                    "Simple merge" .
2327                    "</div>\n"; # class="diff nodifferences"
2328
2329         return $result;
2330 }
2331
2332 sub diff_line_class {
2333         my ($line, $from, $to) = @_;
2334
2335         # ordinary diff
2336         my $num_sign = 1;
2337         # combined diff
2338         if ($from && $to && ref($from->{'href'}) eq "ARRAY") {
2339                 $num_sign = scalar @{$from->{'href'}};
2340         }
2341
2342         my @diff_line_classifier = (
2343                 { regexp => qr/^\@\@{$num_sign} /, class => "chunk_header"},
2344                 { regexp => qr/^\\/,               class => "incomplete"  },
2345                 { regexp => qr/^ {$num_sign}/,     class => "ctx" },
2346                 # classifier for context must come before classifier add/rem,
2347                 # or we would have to use more complicated regexp, for example
2348                 # qr/(?= {0,$m}\+)[+ ]{$num_sign}/, where $m = $num_sign - 1;
2349                 { regexp => qr/^[+ ]{$num_sign}/,   class => "add" },
2350                 { regexp => qr/^[- ]{$num_sign}/,   class => "rem" },
2351         );
2352         for my $clsfy (@diff_line_classifier) {
2353                 return $clsfy->{'class'}
2354                         if ($line =~ $clsfy->{'regexp'});
2355         }
2356
2357         # fallback
2358         return "";
2359 }
2360
2361 # assumes that $from and $to are defined and correctly filled,
2362 # and that $line holds a line of chunk header for unified diff
2363 sub format_unidiff_chunk_header {
2364         my ($line, $from, $to) = @_;
2365
2366         my ($from_text, $from_start, $from_lines, $to_text, $to_start, $to_lines, $section) =
2367                 $line =~ m/^\@{2} (-(\d+)(?:,(\d+))?) (\+(\d+)(?:,(\d+))?) \@{2}(.*)$/;
2368
2369         $from_lines = 0 unless defined $from_lines;
2370         $to_lines   = 0 unless defined $to_lines;
2371
2372         if ($from->{'href'}) {
2373                 $from_text = $cgi->a({-href=>"$from->{'href'}#l$from_start",
2374                                      -class=>"list"}, $from_text);
2375         }
2376         if ($to->{'href'}) {
2377                 $to_text   = $cgi->a({-href=>"$to->{'href'}#l$to_start",
2378                                      -class=>"list"}, $to_text);
2379         }
2380         $line = "<span class=\"chunk_info\">@@ $from_text $to_text @@</span>" .
2381                 "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2382         return $line;
2383 }
2384
2385 # assumes that $from and $to are defined and correctly filled,
2386 # and that $line holds a line of chunk header for combined diff
2387 sub format_cc_diff_chunk_header {
2388         my ($line, $from, $to) = @_;
2389
2390         my ($prefix, $ranges, $section) = $line =~ m/^(\@+) (.*?) \@+(.*)$/;
2391         my (@from_text, @from_start, @from_nlines, $to_text, $to_start, $to_nlines);
2392
2393         @from_text = split(' ', $ranges);
2394         for (my $i = 0; $i < @from_text; ++$i) {
2395                 ($from_start[$i], $from_nlines[$i]) =
2396                         (split(',', substr($from_text[$i], 1)), 0);
2397         }
2398
2399         $to_text   = pop @from_text;
2400         $to_start  = pop @from_start;
2401         $to_nlines = pop @from_nlines;
2402
2403         $line = "<span class=\"chunk_info\">$prefix ";
2404         for (my $i = 0; $i < @from_text; ++$i) {
2405                 if ($from->{'href'}[$i]) {
2406                         $line .= $cgi->a({-href=>"$from->{'href'}[$i]#l$from_start[$i]",
2407                                           -class=>"list"}, $from_text[$i]);
2408                 } else {
2409                         $line .= $from_text[$i];
2410                 }
2411                 $line .= " ";
2412         }
2413         if ($to->{'href'}) {
2414                 $line .= $cgi->a({-href=>"$to->{'href'}#l$to_start",
2415                                   -class=>"list"}, $to_text);
2416         } else {
2417                 $line .= $to_text;
2418         }
2419         $line .= " $prefix</span>" .
2420                  "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2421         return $line;
2422 }
2423
2424 # process patch (diff) line (not to be used for diff headers),
2425 # returning class and HTML-formatted (but not wrapped) line
2426 sub process_diff_line {
2427         my $line = shift;
2428         my ($from, $to) = @_;
2429
2430         my $diff_class = diff_line_class($line, $from, $to);
2431
2432         chomp $line;
2433         $line = untabify($line);
2434
2435         if ($from && $to && $line =~ m/^\@{2} /) {
2436                 $line = format_unidiff_chunk_header($line, $from, $to);
2437                 return $diff_class, $line;
2438
2439         } elsif ($from && $to && $line =~ m/^\@{3}/) {
2440                 $line = format_cc_diff_chunk_header($line, $from, $to);
2441                 return $diff_class, $line;
2442
2443         }
2444         return $diff_class, esc_html($line, -nbsp=>1);
2445 }
2446
2447 # Generates undef or something like "_snapshot_" or "snapshot (_tbz2_ _zip_)",
2448 # linked.  Pass the hash of the tree/commit to snapshot.
2449 sub format_snapshot_links {
2450         my ($hash) = @_;
2451         my $num_fmts = @snapshot_fmts;
2452         if ($num_fmts > 1) {
2453                 # A parenthesized list of links bearing format names.
2454                 # e.g. "snapshot (_tar.gz_ _zip_)"
2455                 return "snapshot (" . join(' ', map
2456                         $cgi->a({
2457                                 -href => href(
2458                                         action=>"snapshot",
2459                                         hash=>$hash,
2460                                         snapshot_format=>$_
2461                                 )
2462                         }, $known_snapshot_formats{$_}{'display'})
2463                 , @snapshot_fmts) . ")";
2464         } elsif ($num_fmts == 1) {
2465                 # A single "snapshot" link whose tooltip bears the format name.
2466                 # i.e. "_snapshot_"
2467                 my ($fmt) = @snapshot_fmts;
2468                 return
2469                         $cgi->a({
2470                                 -href => href(
2471                                         action=>"snapshot",
2472                                         hash=>$hash,
2473                                         snapshot_format=>$fmt
2474                                 ),
2475                                 -title => "in format: $known_snapshot_formats{$fmt}{'display'}"
2476                         }, "snapshot");
2477         } else { # $num_fmts == 0
2478                 return undef;
2479         }
2480 }
2481
2482 ## ......................................................................
2483 ## functions returning values to be passed, perhaps after some
2484 ## transformation, to other functions; e.g. returning arguments to href()
2485
2486 # returns hash to be passed to href to generate gitweb URL
2487 # in -title key it returns description of link
2488 sub get_feed_info {
2489         my $format = shift || 'Atom';
2490         my %res = (action => lc($format));
2491
2492         # feed links are possible only for project views
2493         return unless (defined $project);
2494         # some views should link to OPML, or to generic project feed,
2495         # or don't have specific feed yet (so they should use generic)
2496         return if (!$action || $action =~ /^(?:tags|heads|forks|tag|search)$/x);
2497
2498         my $branch;
2499         # branches refs uses 'refs/heads/' prefix (fullname) to differentiate
2500         # from tag links; this also makes possible to detect branch links
2501         if ((defined $hash_base && $hash_base =~ m!^refs/heads/(.*)$!) ||
2502             (defined $hash      && $hash      =~ m!^refs/heads/(.*)$!)) {
2503                 $branch = $1;
2504         }
2505         # find log type for feed description (title)
2506         my $type = 'log';
2507         if (defined $file_name) {
2508                 $type  = "history of $file_name";
2509                 $type .= "/" if ($action eq 'tree');
2510                 $type .= " on '$branch'" if (defined $branch);
2511         } else {
2512                 $type = "log of $branch" if (defined $branch);
2513         }
2514
2515         $res{-title} = $type;
2516         $res{'hash'} = (defined $branch ? "refs/heads/$branch" : undef);
2517         $res{'file_name'} = $file_name;
2518
2519         return %res;
2520 }
2521
2522 ## ----------------------------------------------------------------------
2523 ## git utility subroutines, invoking git commands
2524
2525 # returns path to the core git executable and the --git-dir parameter as list
2526 sub git_cmd {
2527         $number_of_git_cmds++;
2528         return $GIT, '--git-dir='.$git_dir;
2529 }
2530
2531 # quote the given arguments for passing them to the shell
2532 # quote_command("command", "arg 1", "arg with ' and ! characters")
2533 # => "'command' 'arg 1' 'arg with '\'' and '\!' characters'"
2534 # Try to avoid using this function wherever possible.
2535 sub quote_command {
2536         return join(' ',
2537                 map { my $a = $_; $a =~ s/(['!])/'\\$1'/g; "'$a'" } @_ );
2538 }
2539
2540 # get HEAD ref of given project as hash
2541 sub git_get_head_hash {
2542         return git_get_full_hash(shift, 'HEAD');
2543 }
2544
2545 sub git_get_full_hash {
2546         return git_get_hash(@_);
2547 }
2548
2549 sub git_get_short_hash {
2550         return git_get_hash(@_, '--short=7');
2551 }
2552
2553 sub git_get_hash {
2554         my ($project, $hash, @options) = @_;
2555         my $o_git_dir = $git_dir;
2556         my $retval = undef;
2557         $git_dir = "$projectroot/$project";
2558         if (open my $fd, '-|', git_cmd(), 'rev-parse',
2559             '--verify', '-q', @options, $hash) {
2560                 $retval = <$fd>;
2561                 chomp $retval if defined $retval;
2562                 close $fd;
2563         }
2564         if (defined $o_git_dir) {
2565                 $git_dir = $o_git_dir;
2566         }
2567         return $retval;
2568 }
2569
2570 # get type of given object
2571 sub git_get_type {
2572         my $hash = shift;
2573
2574         open my $fd, "-|", git_cmd(), "cat-file", '-t', $hash or return;
2575         my $type = <$fd>;
2576         close $fd or return;
2577         chomp $type;
2578         return $type;
2579 }
2580
2581 # repository configuration
2582 our $config_file = '';
2583 our %config;
2584
2585 # store multiple values for single key as anonymous array reference
2586 # single values stored directly in the hash, not as [ <value> ]
2587 sub hash_set_multi {
2588         my ($hash, $key, $value) = @_;
2589
2590         if (!exists $hash->{$key}) {
2591                 $hash->{$key} = $value;
2592         } elsif (!ref $hash->{$key}) {
2593                 $hash->{$key} = [ $hash->{$key}, $value ];
2594         } else {
2595                 push @{$hash->{$key}}, $value;
2596         }
2597 }
2598
2599 # return hash of git project configuration
2600 # optionally limited to some section, e.g. 'gitweb'
2601 sub git_parse_project_config {
2602         my $section_regexp = shift;
2603         my %config;
2604
2605         local $/ = "\0";
2606
2607         open my $fh, "-|", git_cmd(), "config", '-z', '-l',
2608                 or return;
2609
2610         while (my $keyval = <$fh>) {
2611                 chomp $keyval;
2612                 my ($key, $value) = split(/\n/, $keyval, 2);
2613
2614                 hash_set_multi(\%config, $key, $value)
2615                         if (!defined $section_regexp || $key =~ /^(?:$section_regexp)\./o);
2616         }
2617         close $fh;
2618
2619         return %config;
2620 }
2621
2622 # convert config value to boolean: 'true' or 'false'
2623 # no value, number > 0, 'true' and 'yes' values are true
2624 # rest of values are treated as false (never as error)
2625 sub config_to_bool {
2626         my $val = shift;
2627
2628         return 1 if !defined $val;             # section.key
2629
2630         # strip leading and trailing whitespace
2631         $val =~ s/^\s+//;
2632         $val =~ s/\s+$//;
2633
2634         return (($val =~ /^\d+$/ && $val) ||   # section.key = 1
2635                 ($val =~ /^(?:true|yes)$/i));  # section.key = true
2636 }
2637
2638 # convert config value to simple decimal number
2639 # an optional value suffix of 'k', 'm', or 'g' will cause the value
2640 # to be multiplied by 1024, 1048576, or 1073741824
2641 sub config_to_int {
2642         my $val = shift;
2643
2644         # strip leading and trailing whitespace
2645         $val =~ s/^\s+//;
2646         $val =~ s/\s+$//;
2647
2648         if (my ($num, $unit) = ($val =~ /^([0-9]*)([kmg])$/i)) {
2649                 $unit = lc($unit);
2650                 # unknown unit is treated as 1
2651                 return $num * ($unit eq 'g' ? 1073741824 :
2652                                $unit eq 'm' ?    1048576 :
2653                                $unit eq 'k' ?       1024 : 1);
2654         }
2655         return $val;
2656 }
2657
2658 # convert config value to array reference, if needed
2659 sub config_to_multi {
2660         my $val = shift;
2661
2662         return ref($val) ? $val : (defined($val) ? [ $val ] : []);
2663 }
2664
2665 sub git_get_project_config {
2666         my ($key, $type) = @_;
2667
2668         return unless defined $git_dir;
2669
2670         # key sanity check
2671         return unless ($key);
2672         # only subsection, if exists, is case sensitive,
2673         # and not lowercased by 'git config -z -l'
2674         if (my ($hi, $mi, $lo) = ($key =~ /^([^.]*)\.(.*)\.([^.]*)$/)) {
2675                 $key = join(".", lc($hi), $mi, lc($lo));
2676         } else {
2677                 $key = lc($key);
2678         }
2679         $key =~ s/^gitweb\.//;
2680         return if ($key =~ m/\W/);
2681
2682         # type sanity check
2683         if (defined $type) {
2684                 $type =~ s/^--//;
2685                 $type = undef
2686                         unless ($type eq 'bool' || $type eq 'int');
2687         }
2688
2689         # get config
2690         if (!defined $config_file ||
2691             $config_file ne "$git_dir/config") {
2692                 %config = git_parse_project_config('gitweb');
2693                 $config_file = "$git_dir/config";
2694         }
2695
2696         # check if config variable (key) exists
2697         return unless exists $config{"gitweb.$key"};
2698
2699         # ensure given type
2700         if (!defined $type) {
2701                 return $config{"gitweb.$key"};
2702         } elsif ($type eq 'bool') {
2703                 # backward compatibility: 'git config --bool' returns true/false
2704                 return config_to_bool($config{"gitweb.$key"}) ? 'true' : 'false';
2705         } elsif ($type eq 'int') {
2706                 return config_to_int($config{"gitweb.$key"});
2707         }
2708         return $config{"gitweb.$key"};
2709 }
2710
2711 # get hash of given path at given ref
2712 sub git_get_hash_by_path {
2713         my $base = shift;
2714         my $path = shift || return undef;
2715         my $type = shift;
2716
2717         $path =~ s,/+$,,;
2718
2719         open my $fd, "-|", git_cmd(), "ls-tree", $base, "--", $path
2720                 or die_error(500, "Open git-ls-tree failed");
2721         my $line = <$fd>;
2722         close $fd or return undef;
2723
2724         if (!defined $line) {
2725                 # there is no tree or hash given by $path at $base
2726                 return undef;
2727         }
2728
2729         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
2730         $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/;
2731         if (defined $type && $type ne $2) {
2732                 # type doesn't match
2733                 return undef;
2734         }
2735         return $3;
2736 }
2737
2738 # get path of entry with given hash at given tree-ish (ref)
2739 # used to get 'from' filename for combined diff (merge commit) for renames
2740 sub git_get_path_by_hash {
2741         my $base = shift || return;
2742         my $hash = shift || return;
2743
2744         local $/ = "\0";
2745
2746         open my $fd, "-|", git_cmd(), "ls-tree", '-r', '-t', '-z', $base
2747                 or return undef;
2748         while (my $line = <$fd>) {
2749                 chomp $line;
2750
2751                 #'040000 tree 595596a6a9117ddba9fe379b6b012b558bac8423  gitweb'
2752                 #'100644 blob e02e90f0429be0d2a69b76571101f20b8f75530f  gitweb/README'
2753                 if ($line =~ m/(?:[0-9]+) (?:.+) $hash\t(.+)$/) {
2754                         close $fd;
2755                         return $1;
2756                 }
2757         }
2758         close $fd;
2759         return undef;
2760 }
2761
2762 ## ......................................................................
2763 ## git utility functions, directly accessing git repository
2764
2765 # get the value of config variable either from file named as the variable
2766 # itself in the repository ($GIT_DIR/$name file), or from gitweb.$name
2767 # configuration variable in the repository config file.
2768 sub git_get_file_or_project_config {
2769         my ($path, $name) = @_;
2770
2771         $git_dir = "$projectroot/$path";
2772         open my $fd, '<', "$git_dir/$name"
2773                 or return git_get_project_config($name);
2774         my $conf = <$fd>;
2775         close $fd;
2776         if (defined $conf) {
2777                 chomp $conf;
2778         }
2779         return $conf;
2780 }
2781
2782 sub git_get_project_description {
2783         my $path = shift;
2784         return git_get_file_or_project_config($path, 'description');
2785 }
2786
2787 sub git_get_project_category {
2788         my $path = shift;
2789         return git_get_file_or_project_config($path, 'category');
2790 }
2791
2792
2793 # supported formats:
2794 # * $GIT_DIR/ctags/<tagname> file (in 'ctags' subdirectory)
2795 #   - if its contents is a number, use it as tag weight,
2796 #   - otherwise add a tag with weight 1
2797 # * $GIT_DIR/ctags file, each line is a tag (with weight 1)
2798 #   the same value multiple times increases tag weight
2799 # * `gitweb.ctag' multi-valued repo config variable
2800 sub git_get_project_ctags {
2801         my $project = shift;
2802         my $ctags = {};
2803
2804         $git_dir = "$projectroot/$project";
2805         if (opendir my $dh, "$git_dir/ctags") {
2806                 my @files = grep { -f $_ } map { "$git_dir/ctags/$_" } readdir($dh);
2807                 foreach my $tagfile (@files) {
2808                         open my $ct, '<', $tagfile
2809                                 or next;
2810                         my $val = <$ct>;
2811                         chomp $val if $val;
2812                         close $ct;
2813
2814                         (my $ctag = $tagfile) =~ s#.*/##;
2815                         if ($val =~ /^\d+$/) {
2816                                 $ctags->{$ctag} = $val;
2817                         } else {
2818                                 $ctags->{$ctag} = 1;
2819                         }
2820                 }
2821                 closedir $dh;
2822
2823         } elsif (open my $fh, '<', "$git_dir/ctags") {
2824                 while (my $line = <$fh>) {
2825                         chomp $line;
2826                         $ctags->{$line}++ if $line;
2827                 }
2828                 close $fh;
2829
2830         } else {
2831                 my $taglist = config_to_multi(git_get_project_config('ctag'));
2832                 foreach my $tag (@$taglist) {
2833                         $ctags->{$tag}++;
2834                 }
2835         }
2836
2837         return $ctags;
2838 }
2839
2840 # return hash, where keys are content tags ('ctags'),
2841 # and values are sum of weights of given tag in every project
2842 sub git_gather_all_ctags {
2843         my $projects = shift;
2844         my $ctags = {};
2845
2846         foreach my $p (@$projects) {
2847                 foreach my $ct (keys %{$p->{'ctags'}}) {
2848                         $ctags->{$ct} += $p->{'ctags'}->{$ct};
2849                 }
2850         }
2851
2852         return $ctags;
2853 }
2854
2855 sub git_populate_project_tagcloud {
2856         my $ctags = shift;
2857
2858         # First, merge different-cased tags; tags vote on casing
2859         my %ctags_lc;
2860         foreach (keys %$ctags) {
2861                 $ctags_lc{lc $_}->{count} += $ctags->{$_};
2862                 if (not $ctags_lc{lc $_}->{topcount}
2863                     or $ctags_lc{lc $_}->{topcount} < $ctags->{$_}) {
2864                         $ctags_lc{lc $_}->{topcount} = $ctags->{$_};
2865                         $ctags_lc{lc $_}->{topname} = $_;
2866                 }
2867         }
2868
2869         my $cloud;
2870         my $matched = $input_params{'ctag'};
2871         if (eval { require HTML::TagCloud; 1; }) {
2872                 $cloud = HTML::TagCloud->new;
2873                 foreach my $ctag (sort keys %ctags_lc) {
2874                         # Pad the title with spaces so that the cloud looks
2875                         # less crammed.
2876                         my $title = esc_html($ctags_lc{$ctag}->{topname});
2877                         $title =~ s/ /&nbsp;/g;
2878                         $title =~ s/^/&nbsp;/g;
2879                         $title =~ s/$/&nbsp;/g;
2880                         if (defined $matched && $matched eq $ctag) {
2881                                 $title = qq(<span class="match">$title</span>);
2882                         }
2883                         $cloud->add($title, href(project=>undef, ctag=>$ctag),
2884                                     $ctags_lc{$ctag}->{count});
2885                 }
2886         } else {
2887                 $cloud = {};
2888                 foreach my $ctag (keys %ctags_lc) {
2889                         my $title = esc_html($ctags_lc{$ctag}->{topname}, -nbsp=>1);
2890                         if (defined $matched && $matched eq $ctag) {
2891                                 $title = qq(<span class="match">$title</span>);
2892                         }
2893                         $cloud->{$ctag}{count} = $ctags_lc{$ctag}->{count};
2894                         $cloud->{$ctag}{ctag} =
2895                                 $cgi->a({-href=>href(project=>undef, ctag=>$ctag)}, $title);
2896                 }
2897         }
2898         return $cloud;
2899 }
2900
2901 sub git_show_project_tagcloud {
2902         my ($cloud, $count) = @_;
2903         if (ref $cloud eq 'HTML::TagCloud') {
2904                 return $cloud->html_and_css($count);
2905         } else {
2906                 my @tags = sort { $cloud->{$a}->{'count'} <=> $cloud->{$b}->{'count'} } keys %$cloud;
2907                 return
2908                         '<div id="htmltagcloud"'.($project ? '' : ' align="center"').'>' .
2909                         join (', ', map {
2910                                 $cloud->{$_}->{'ctag'}
2911                         } splice(@tags, 0, $count)) .
2912                         '</div>';
2913         }
2914 }
2915
2916 sub git_get_project_url_list {
2917         my $path = shift;
2918
2919         $git_dir = "$projectroot/$path";
2920         open my $fd, '<', "$git_dir/cloneurl"
2921                 or return wantarray ?
2922                 @{ config_to_multi(git_get_project_config('url')) } :
2923                    config_to_multi(git_get_project_config('url'));
2924         my @git_project_url_list = map { chomp; $_ } <$fd>;
2925         close $fd;
2926
2927         return wantarray ? @git_project_url_list : \@git_project_url_list;
2928 }
2929
2930 sub git_get_projects_list {
2931         my $filter = shift || '';
2932         my $paranoid = shift;
2933         my @list;
2934
2935         if (-d $projects_list) {
2936                 # search in directory
2937                 my $dir = $projects_list;
2938                 # remove the trailing "/"
2939                 $dir =~ s!/+$!!;
2940                 my $pfxlen = length("$dir");
2941                 my $pfxdepth = ($dir =~ tr!/!!);
2942                 # when filtering, search only given subdirectory
2943                 if ($filter && !$paranoid) {
2944                         $dir .= "/$filter";
2945                         $dir =~ s!/+$!!;
2946                 }
2947
2948                 File::Find::find({
2949                         follow_fast => 1, # follow symbolic links
2950                         follow_skip => 2, # ignore duplicates
2951                         dangling_symlinks => 0, # ignore dangling symlinks, silently
2952                         wanted => sub {
2953                                 # global variables
2954                                 our $project_maxdepth;
2955                                 our $projectroot;
2956                                 # skip project-list toplevel, if we get it.
2957                                 return if (m!^[/.]$!);
2958                                 # only directories can be git repositories
2959                                 return unless (-d $_);
2960                                 # don't traverse too deep (Find is super slow on os x)
2961                                 # $project_maxdepth excludes depth of $projectroot
2962                                 if (($File::Find::name =~ tr!/!!) - $pfxdepth > $project_maxdepth) {
2963                                         $File::Find::prune = 1;
2964                                         return;
2965                                 }
2966
2967                                 my $path = substr($File::Find::name, $pfxlen + 1);
2968                                 # paranoidly only filter here
2969                                 if ($paranoid && $filter && $path !~ m!^\Q$filter\E/!) {
2970                                         next;
2971                                 }
2972                                 # we check related file in $projectroot
2973                                 if (check_export_ok("$projectroot/$path")) {
2974                                         push @list, { path => $path };
2975                                         $File::Find::prune = 1;
2976                                 }
2977                         },
2978                 }, "$dir");
2979
2980         } elsif (-f $projects_list) {
2981                 # read from file(url-encoded):
2982                 # 'git%2Fgit.git Linus+Torvalds'
2983                 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
2984                 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
2985                 open my $fd, '<', $projects_list or return;
2986         PROJECT:
2987                 while (my $line = <$fd>) {
2988                         chomp $line;
2989                         my ($path, $owner) = split ' ', $line;
2990                         $path = unescape($path);
2991                         $owner = unescape($owner);
2992                         if (!defined $path) {
2993                                 next;
2994                         }
2995                         # if $filter is rpovided, check if $path begins with $filter
2996                         if ($filter && $path !~ m!^\Q$filter\E/!) {
2997                                 next;
2998                         }
2999                         if (check_export_ok("$projectroot/$path")) {
3000                                 my $pr = {
3001                                         path => $path,
3002                                         owner => to_utf8($owner),
3003                                 };
3004                                 push @list, $pr;
3005                         }
3006                 }
3007                 close $fd;
3008         }
3009         return @list;
3010 }
3011
3012 # written with help of Tree::Trie module (Perl Artistic License, GPL compatibile)
3013 # as side effects it sets 'forks' field to list of forks for forked projects
3014 sub filter_forks_from_projects_list {
3015         my $projects = shift;
3016
3017         my %trie; # prefix tree of directories (path components)
3018         # generate trie out of those directories that might contain forks
3019         foreach my $pr (@$projects) {
3020                 my $path = $pr->{'path'};
3021                 $path =~ s/\.git$//;      # forks of 'repo.git' are in 'repo/' directory
3022                 next if ($path =~ m!/$!); # skip non-bare repositories, e.g. 'repo/.git'
3023                 next unless ($path);      # skip '.git' repository: tests, git-instaweb
3024                 next unless (-d "$projectroot/$path"); # containing directory exists
3025                 $pr->{'forks'} = [];      # there can be 0 or more forks of project
3026
3027                 # add to trie
3028                 my @dirs = split('/', $path);
3029                 # walk the trie, until either runs out of components or out of trie
3030                 my $ref = \%trie;
3031                 while (scalar @dirs &&
3032                        exists($ref->{$dirs[0]})) {
3033                         $ref = $ref->{shift @dirs};
3034                 }
3035                 # create rest of trie structure from rest of components
3036                 foreach my $dir (@dirs) {
3037                         $ref = $ref->{$dir} = {};
3038                 }
3039                 # create end marker, store $pr as a data
3040                 $ref->{''} = $pr if (!exists $ref->{''});
3041         }
3042
3043         # filter out forks, by finding shortest prefix match for paths
3044         my @filtered;
3045  PROJECT:
3046         foreach my $pr (@$projects) {
3047                 # trie lookup
3048                 my $ref = \%trie;
3049         DIR:
3050                 foreach my $dir (split('/', $pr->{'path'})) {
3051                         if (exists $ref->{''}) {
3052                                 # found [shortest] prefix, is a fork - skip it
3053                                 push @{$ref->{''}{'forks'}}, $pr;
3054                                 next PROJECT;
3055                         }
3056                         if (!exists $ref->{$dir}) {
3057                                 # not in trie, cannot have prefix, not a fork
3058                                 push @filtered, $pr;
3059                                 next PROJECT;
3060                         }
3061                         # If the dir is there, we just walk one step down the trie.
3062                         $ref = $ref->{$dir};
3063                 }
3064                 # we ran out of trie
3065                 # (shouldn't happen: it's either no match, or end marker)
3066                 push @filtered, $pr;
3067         }
3068
3069         return @filtered;
3070 }
3071
3072 # note: fill_project_list_info must be run first,
3073 # for 'descr_long' and 'ctags' to be filled
3074 sub search_projects_list {
3075         my ($projlist, %opts) = @_;
3076         my $tagfilter  = $opts{'tagfilter'};
3077         my $searchtext = $opts{'searchtext'};
3078
3079         return @$projlist
3080                 unless ($tagfilter || $searchtext);
3081
3082         # searching projects require filling to be run before it;
3083         fill_project_list_info($projlist,
3084                                $tagfilter  ? 'ctags' : (),
3085                                $searchtext ? ('path', 'descr') : ());
3086         my @projects;
3087  PROJECT:
3088         foreach my $pr (@$projlist) {
3089
3090                 if ($tagfilter) {
3091                         next unless ref($pr->{'ctags'}) eq 'HASH';
3092                         next unless
3093                                 grep { lc($_) eq lc($tagfilter) } keys %{$pr->{'ctags'}};
3094                 }
3095
3096                 if ($searchtext) {
3097                         next unless
3098                                 $pr->{'path'} =~ /$searchtext/ ||
3099                                 $pr->{'descr_long'} =~ /$searchtext/;
3100                 }
3101
3102                 push @projects, $pr;
3103         }
3104
3105         return @projects;
3106 }
3107
3108 our $gitweb_project_owner = undef;
3109 sub git_get_project_list_from_file {
3110
3111         return if (defined $gitweb_project_owner);
3112
3113         $gitweb_project_owner = {};
3114         # read from file (url-encoded):
3115         # 'git%2Fgit.git Linus+Torvalds'
3116         # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
3117         # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
3118         if (-f $projects_list) {
3119                 open(my $fd, '<', $projects_list);
3120                 while (my $line = <$fd>) {
3121                         chomp $line;
3122                         my ($pr, $ow) = split ' ', $line;
3123                         $pr = unescape($pr);
3124                         $ow = unescape($ow);
3125                         $gitweb_project_owner->{$pr} = to_utf8($ow);
3126                 }
3127                 close $fd;
3128         }
3129 }
3130
3131 sub git_get_project_owner {
3132         my $project = shift;
3133         my $owner;
3134
3135         return undef unless $project;
3136         $git_dir = "$projectroot/$project";
3137
3138         if (!defined $gitweb_project_owner) {
3139                 git_get_project_list_from_file();
3140         }
3141
3142         if (exists $gitweb_project_owner->{$project}) {
3143                 $owner = $gitweb_project_owner->{$project};
3144         }
3145         if (!defined $owner){
3146                 $owner = git_get_project_config('owner');
3147         }
3148         if (!defined $owner) {
3149                 $owner = get_file_owner("$git_dir");
3150         }
3151
3152         return $owner;
3153 }
3154
3155 sub git_get_last_activity {
3156         my ($path) = @_;
3157         my $fd;
3158
3159         $git_dir = "$projectroot/$path";
3160         open($fd, "-|", git_cmd(), 'for-each-ref',
3161              '--format=%(committer)',
3162              '--sort=-committerdate',
3163              '--count=1',
3164              'refs/heads') or return;
3165         my $most_recent = <$fd>;
3166         close $fd or return;
3167         if (defined $most_recent &&
3168             $most_recent =~ / (\d+) [-+][01]\d\d\d$/) {
3169                 my $timestamp = $1;
3170                 my $age = time - $timestamp;
3171                 return ($age, age_string($age));
3172         }
3173         return (undef, undef);
3174 }
3175
3176 # Implementation note: when a single remote is wanted, we cannot use 'git
3177 # remote show -n' because that command always work (assuming it's a remote URL
3178 # if it's not defined), and we cannot use 'git remote show' because that would
3179 # try to make a network roundtrip. So the only way to find if that particular
3180 # remote is defined is to walk the list provided by 'git remote -v' and stop if
3181 # and when we find what we want.
3182 sub git_get_remotes_list {
3183         my $wanted = shift;
3184         my %remotes = ();
3185
3186         open my $fd, '-|' , git_cmd(), 'remote', '-v';
3187         return unless $fd;
3188         while (my $remote = <$fd>) {
3189                 chomp $remote;
3190                 $remote =~ s!\t(.*?)\s+\((\w+)\)$!!;
3191                 next if $wanted and not $remote eq $wanted;
3192                 my ($url, $key) = ($1, $2);
3193
3194                 $remotes{$remote} ||= { 'heads' => () };
3195                 $remotes{$remote}{$key} = $url;
3196         }
3197         close $fd or return;
3198         return wantarray ? %remotes : \%remotes;
3199 }
3200
3201 # Takes a hash of remotes as first parameter and fills it by adding the
3202 # available remote heads for each of the indicated remotes.
3203 sub fill_remote_heads {
3204         my $remotes = shift;
3205         my @heads = map { "remotes/$_" } keys %$remotes;
3206         my @remoteheads = git_get_heads_list(undef, @heads);
3207         foreach my $remote (keys %$remotes) {
3208                 $remotes->{$remote}{'heads'} = [ grep {
3209                         $_->{'name'} =~ s!^$remote/!!
3210                         } @remoteheads ];
3211         }
3212 }
3213
3214 sub git_get_references {
3215         my $type = shift || "";
3216         my %refs;
3217         # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
3218         # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
3219         open my $fd, "-|", git_cmd(), "show-ref", "--dereference",
3220                 ($type ? ("--", "refs/$type") : ()) # use -- <pattern> if $type
3221                 or return;
3222
3223         while (my $line = <$fd>) {
3224                 chomp $line;
3225                 if ($line =~ m!^([0-9a-fA-F]{40})\srefs/($type.*)$!) {
3226                         if (defined $refs{$1}) {
3227                                 push @{$refs{$1}}, $2;
3228                         } else {
3229                                 $refs{$1} = [ $2 ];
3230                         }
3231                 }
3232         }
3233         close $fd or return;
3234         return \%refs;
3235 }
3236
3237 sub git_get_rev_name_tags {
3238         my $hash = shift || return undef;
3239
3240         open my $fd, "-|", git_cmd(), "name-rev", "--tags", $hash
3241                 or return;
3242         my $name_rev = <$fd>;
3243         close $fd;
3244
3245         if ($name_rev =~ m|^$hash tags/(.*)$|) {
3246                 return $1;
3247         } else {
3248                 # catches also '$hash undefined' output
3249                 return undef;
3250         }
3251 }
3252
3253 ## ----------------------------------------------------------------------
3254 ## parse to hash functions
3255
3256 sub parse_date {
3257         my $epoch = shift;
3258         my $tz = shift || "-0000";
3259
3260         my %date;
3261         my @months = ("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec");
3262         my @days = ("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");
3263         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($epoch);
3264         $date{'hour'} = $hour;
3265         $date{'minute'} = $min;
3266         $date{'mday'} = $mday;
3267         $date{'day'} = $days[$wday];
3268         $date{'month'} = $months[$mon];
3269         $date{'rfc2822'}   = sprintf "%s, %d %s %4d %02d:%02d:%02d +0000",
3270                              $days[$wday], $mday, $months[$mon], 1900+$year, $hour ,$min, $sec;
3271         $date{'mday-time'} = sprintf "%d %s %02d:%02d",
3272                              $mday, $months[$mon], $hour ,$min;
3273         $date{'iso-8601'}  = sprintf "%04d-%02d-%02dT%02d:%02d:%02dZ",
3274                              1900+$year, 1+$mon, $mday, $hour ,$min, $sec;
3275
3276         my ($tz_sign, $tz_hour, $tz_min) =
3277                 ($tz =~ m/^([-+])(\d\d)(\d\d)$/);
3278         $tz_sign = ($tz_sign eq '-' ? -1 : +1);
3279         my $local = $epoch + $tz_sign*((($tz_hour*60) + $tz_min)*60);
3280         ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($local);
3281         $date{'hour_local'} = $hour;
3282         $date{'minute_local'} = $min;
3283         $date{'tz_local'} = $tz;
3284         $date{'iso-tz'} = sprintf("%04d-%02d-%02d %02d:%02d:%02d %s",
3285                                   1900+$year, $mon+1, $mday,
3286                                   $hour, $min, $sec, $tz);
3287         return %date;
3288 }
3289
3290 sub parse_tag {
3291         my $tag_id = shift;
3292         my %tag;
3293         my @comment;
3294
3295         open my $fd, "-|", git_cmd(), "cat-file", "tag", $tag_id or return;
3296         $tag{'id'} = $tag_id;
3297         while (my $line = <$fd>) {
3298                 chomp $line;
3299                 if ($line =~ m/^object ([0-9a-fA-F]{40})$/) {
3300                         $tag{'object'} = $1;
3301                 } elsif ($line =~ m/^type (.+)$/) {
3302                         $tag{'type'} = $1;
3303                 } elsif ($line =~ m/^tag (.+)$/) {
3304                         $tag{'name'} = $1;
3305                 } elsif ($line =~ m/^tagger (.*) ([0-9]+) (.*)$/) {
3306                         $tag{'author'} = $1;
3307                         $tag{'author_epoch'} = $2;
3308                         $tag{'author_tz'} = $3;
3309                         if ($tag{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3310                                 $tag{'author_name'}  = $1;
3311                                 $tag{'author_email'} = $2;
3312                         } else {
3313                                 $tag{'author_name'} = $tag{'author'};
3314                         }
3315                 } elsif ($line =~ m/--BEGIN/) {
3316                         push @comment, $line;
3317                         last;
3318                 } elsif ($line eq "") {
3319                         last;
3320                 }
3321         }
3322         push @comment, <$fd>;
3323         $tag{'comment'} = \@comment;
3324         close $fd or return;
3325         if (!defined $tag{'name'}) {
3326                 return
3327         };
3328         return %tag
3329 }
3330
3331 sub parse_commit_text {
3332         my ($commit_text, $withparents) = @_;
3333         my @commit_lines = split '\n', $commit_text;
3334         my %co;
3335
3336         pop @commit_lines; # Remove '\0'
3337
3338         if (! @commit_lines) {
3339                 return;
3340         }
3341
3342         my $header = shift @commit_lines;
3343         if ($header !~ m/^[0-9a-fA-F]{40}/) {
3344                 return;
3345         }
3346         ($co{'id'}, my @parents) = split ' ', $header;
3347         while (my $line = shift @commit_lines) {
3348                 last if $line eq "\n";
3349                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
3350                         $co{'tree'} = $1;
3351                 } elsif ((!defined $withparents) && ($line =~ m/^parent ([0-9a-fA-F]{40})$/)) {
3352                         push @parents, $1;
3353                 } elsif ($line =~ m/^author (.*) ([0-9]+) (.*)$/) {
3354                         $co{'author'} = to_utf8($1);
3355                         $co{'author_epoch'} = $2;
3356                         $co{'author_tz'} = $3;
3357                         if ($co{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3358                                 $co{'author_name'}  = $1;
3359                                 $co{'author_email'} = $2;
3360                         } else {
3361                                 $co{'author_name'} = $co{'author'};
3362                         }
3363                 } elsif ($line =~ m/^committer (.*) ([0-9]+) (.*)$/) {
3364                         $co{'committer'} = to_utf8($1);
3365                         $co{'committer_epoch'} = $2;
3366                         $co{'committer_tz'} = $3;
3367                         if ($co{'committer'} =~ m/^([^<]+) <([^>]*)>/) {
3368                                 $co{'committer_name'}  = $1;
3369                                 $co{'committer_email'} = $2;
3370                         } else {
3371                                 $co{'committer_name'} = $co{'committer'};
3372                         }
3373                 }
3374         }
3375         if (!defined $co{'tree'}) {
3376                 return;
3377         };
3378         $co{'parents'} = \@parents;
3379         $co{'parent'} = $parents[0];
3380
3381         foreach my $title (@commit_lines) {
3382                 $title =~ s/^    //;
3383                 if ($title ne "") {
3384                         $co{'title'} = chop_str($title, 80, 5);
3385                         # remove leading stuff of merges to make the interesting part visible
3386                         if (length($title) > 50) {
3387                                 $title =~ s/^Automatic //;
3388                                 $title =~ s/^merge (of|with) /Merge ... /i;
3389                                 if (length($title) > 50) {
3390                                         $title =~ s/(http|rsync):\/\///;
3391                                 }
3392                                 if (length($title) > 50) {
3393                                         $title =~ s/(master|www|rsync)\.//;
3394                                 }
3395                                 if (length($title) > 50) {
3396                                         $title =~ s/kernel.org:?//;
3397                                 }
3398                                 if (length($title) > 50) {
3399                                         $title =~ s/\/pub\/scm//;
3400                                 }
3401                         }
3402                         $co{'title_short'} = chop_str($title, 50, 5);
3403                         last;
3404                 }
3405         }
3406         if (! defined $co{'title'} || $co{'title'} eq "") {
3407                 $co{'title'} = $co{'title_short'} = '(no commit message)';
3408         }
3409         # remove added spaces
3410         foreach my $line (@commit_lines) {
3411                 $line =~ s/^    //;
3412         }
3413         $co{'comment'} = \@commit_lines;
3414
3415         my $age = time - $co{'committer_epoch'};
3416         $co{'age'} = $age;
3417         $co{'age_string'} = age_string($age);
3418         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($co{'committer_epoch'});
3419         if ($age > 60*60*24*7*2) {
3420                 $co{'age_string_date'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3421                 $co{'age_string_age'} = $co{'age_string'};
3422         } else {
3423                 $co{'age_string_date'} = $co{'age_string'};
3424                 $co{'age_string_age'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3425         }
3426         return %co;
3427 }
3428
3429 sub parse_commit {
3430         my ($commit_id) = @_;
3431         my %co;
3432
3433         local $/ = "\0";
3434
3435         open my $fd, "-|", git_cmd(), "rev-list",
3436                 "--parents",
3437                 "--header",
3438                 "--max-count=1",
3439                 $commit_id,
3440                 "--",
3441                 or die_error(500, "Open git-rev-list failed");
3442         %co = parse_commit_text(<$fd>, 1);
3443         close $fd;
3444
3445         return %co;
3446 }
3447
3448 sub parse_commits {
3449         my ($commit_id, $maxcount, $skip, $filename, @args) = @_;
3450         my @cos;
3451
3452         $maxcount ||= 1;
3453         $skip ||= 0;
3454
3455         local $/ = "\0";
3456
3457         open my $fd, "-|", git_cmd(), "rev-list",
3458                 "--header",
3459                 @args,
3460                 ("--max-count=" . $maxcount),
3461                 ("--skip=" . $skip),
3462                 @extra_options,
3463                 $commit_id,
3464                 "--",
3465                 ($filename ? ($filename) : ())
3466                 or die_error(500, "Open git-rev-list failed");
3467         while (my $line = <$fd>) {
3468                 my %co = parse_commit_text($line);
3469                 push @cos, \%co;
3470         }
3471         close $fd;
3472
3473         return wantarray ? @cos : \@cos;
3474 }
3475
3476 # parse line of git-diff-tree "raw" output
3477 sub parse_difftree_raw_line {
3478         my $line = shift;
3479         my %res;
3480
3481         # ':100644 100644 03b218260e99b78c6df0ed378e59ed9205ccc96d 3b93d5e7cc7f7dd4ebed13a5cc1a4ad976fc94d8 M   ls-files.c'
3482         # ':100644 100644 7f9281985086971d3877aca27704f2aaf9c448ce bc190ebc71bbd923f2b728e505408f5e54bd073a M   rev-tree.c'
3483         if ($line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)([0-9]{0,3})\t(.*)$/) {
3484                 $res{'from_mode'} = $1;
3485                 $res{'to_mode'} = $2;
3486                 $res{'from_id'} = $3;
3487                 $res{'to_id'} = $4;
3488                 $res{'status'} = $5;
3489                 $res{'similarity'} = $6;
3490                 if ($res{'status'} eq 'R' || $res{'status'} eq 'C') { # renamed or copied
3491                         ($res{'from_file'}, $res{'to_file'}) = map { unquote($_) } split("\t", $7);
3492                 } else {
3493                         $res{'from_file'} = $res{'to_file'} = $res{'file'} = unquote($7);
3494                 }
3495         }
3496         # '::100755 100755 100755 60e79ca1b01bc8b057abe17ddab484699a7f5fdb 94067cc5f73388f33722d52ae02f44692bc07490 94067cc5f73388f33722d52ae02f44692bc07490 MR git-gui/git-gui.sh'
3497         # combined diff (for merge commit)
3498         elsif ($line =~ s/^(::+)((?:[0-7]{6} )+)((?:[0-9a-fA-F]{40} )+)([a-zA-Z]+)\t(.*)$//) {
3499                 $res{'nparents'}  = length($1);
3500                 $res{'from_mode'} = [ split(' ', $2) ];
3501                 $res{'to_mode'} = pop @{$res{'from_mode'}};
3502                 $res{'from_id'} = [ split(' ', $3) ];
3503                 $res{'to_id'} = pop @{$res{'from_id'}};
3504                 $res{'status'} = [ split('', $4) ];
3505                 $res{'to_file'} = unquote($5);
3506         }
3507         # 'c512b523472485aef4fff9e57b229d9d243c967f'
3508         elsif ($line =~ m/^([0-9a-fA-F]{40})$/) {
3509                 $res{'commit'} = $1;
3510         }
3511
3512         return wantarray ? %res : \%res;
3513 }
3514
3515 # wrapper: return parsed line of git-diff-tree "raw" output
3516 # (the argument might be raw line, or parsed info)
3517 sub parsed_difftree_line {
3518         my $line_or_ref = shift;
3519
3520         if (ref($line_or_ref) eq "HASH") {
3521                 # pre-parsed (or generated by hand)
3522                 return $line_or_ref;
3523         } else {
3524                 return parse_difftree_raw_line($line_or_ref);
3525         }
3526 }
3527
3528 # parse line of git-ls-tree output
3529 sub parse_ls_tree_line {
3530         my $line = shift;
3531         my %opts = @_;
3532         my %res;
3533
3534         if ($opts{'-l'}) {
3535                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa   16717  panic.c'
3536                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40}) +(-|[0-9]+)\t(.+)$/s;
3537
3538                 $res{'mode'} = $1;
3539                 $res{'type'} = $2;
3540                 $res{'hash'} = $3;
3541                 $res{'size'} = $4;
3542                 if ($opts{'-z'}) {
3543                         $res{'name'} = $5;
3544                 } else {
3545                         $res{'name'} = unquote($5);
3546                 }
3547         } else {
3548                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
3549                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t(.+)$/s;
3550
3551                 $res{'mode'} = $1;
3552                 $res{'type'} = $2;
3553                 $res{'hash'} = $3;
3554                 if ($opts{'-z'}) {
3555                         $res{'name'} = $4;
3556                 } else {
3557                         $res{'name'} = unquote($4);
3558                 }
3559         }
3560
3561         return wantarray ? %res : \%res;
3562 }
3563
3564 # generates _two_ hashes, references to which are passed as 2 and 3 argument
3565 sub parse_from_to_diffinfo {
3566         my ($diffinfo, $from, $to, @parents) = @_;
3567
3568         if ($diffinfo->{'nparents'}) {
3569                 # combined diff
3570                 $from->{'file'} = [];
3571                 $from->{'href'} = [];
3572                 fill_from_file_info($diffinfo, @parents)
3573                         unless exists $diffinfo->{'from_file'};
3574                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
3575                         $from->{'file'}[$i] =
3576                                 defined $diffinfo->{'from_file'}[$i] ?
3577                                         $diffinfo->{'from_file'}[$i] :
3578                                         $diffinfo->{'to_file'};
3579                         if ($diffinfo->{'status'}[$i] ne "A") { # not new (added) file
3580                                 $from->{'href'}[$i] = href(action=>"blob",
3581                                                            hash_base=>$parents[$i],
3582                                                            hash=>$diffinfo->{'from_id'}[$i],
3583                                                            file_name=>$from->{'file'}[$i]);
3584                         } else {
3585                                 $from->{'href'}[$i] = undef;
3586                         }
3587                 }
3588         } else {
3589                 # ordinary (not combined) diff
3590                 $from->{'file'} = $diffinfo->{'from_file'};
3591                 if ($diffinfo->{'status'} ne "A") { # not new (added) file
3592                         $from->{'href'} = href(action=>"blob", hash_base=>$hash_parent,
3593                                                hash=>$diffinfo->{'from_id'},
3594                                                file_name=>$from->{'file'});
3595                 } else {
3596                         delete $from->{'href'};
3597                 }
3598         }
3599
3600         $to->{'file'} = $diffinfo->{'to_file'};
3601         if (!is_deleted($diffinfo)) { # file exists in result
3602                 $to->{'href'} = href(action=>"blob", hash_base=>$hash,
3603                                      hash=>$diffinfo->{'to_id'},
3604                                      file_name=>$to->{'file'});
3605         } else {
3606                 delete $to->{'href'};
3607         }
3608 }
3609
3610 ## ......................................................................
3611 ## parse to array of hashes functions
3612
3613 sub git_get_heads_list {
3614         my ($limit, @classes) = @_;
3615         @classes = ('heads') unless @classes;
3616         my @patterns = map { "refs/$_" } @classes;
3617         my @headslist;
3618
3619         open my $fd, '-|', git_cmd(), 'for-each-ref',
3620                 ($limit ? '--count='.($limit+1) : ()), '--sort=-committerdate',
3621                 '--format=%(objectname) %(refname) %(subject)%00%(committer)',
3622                 @patterns
3623                 or return;
3624         while (my $line = <$fd>) {
3625                 my %ref_item;
3626
3627                 chomp $line;
3628                 my ($refinfo, $committerinfo) = split(/\0/, $line);
3629                 my ($hash, $name, $title) = split(' ', $refinfo, 3);
3630                 my ($committer, $epoch, $tz) =
3631                         ($committerinfo =~ /^(.*) ([0-9]+) (.*)$/);
3632                 $ref_item{'fullname'}  = $name;
3633                 $name =~ s!^refs/(?:head|remote)s/!!;
3634
3635                 $ref_item{'name'}  = $name;
3636                 $ref_item{'id'}    = $hash;
3637                 $ref_item{'title'} = $title || '(no commit message)';
3638                 $ref_item{'epoch'} = $epoch;
3639                 if ($epoch) {
3640                         $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3641                 } else {
3642                         $ref_item{'age'} = "unknown";
3643                 }
3644
3645                 push @headslist, \%ref_item;
3646         }
3647         close $fd;
3648
3649         return wantarray ? @headslist : \@headslist;
3650 }
3651
3652 sub git_get_tags_list {
3653         my $limit = shift;
3654         my @tagslist;
3655
3656         open my $fd, '-|', git_cmd(), 'for-each-ref',
3657                 ($limit ? '--count='.($limit+1) : ()), '--sort=-creatordate',
3658                 '--format=%(objectname) %(objecttype) %(refname) '.
3659                 '%(*objectname) %(*objecttype) %(subject)%00%(creator)',
3660                 'refs/tags'
3661                 or return;
3662         while (my $line = <$fd>) {
3663                 my %ref_item;
3664
3665                 chomp $line;
3666                 my ($refinfo, $creatorinfo) = split(/\0/, $line);
3667                 my ($id, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
3668                 my ($creator, $epoch, $tz) =
3669                         ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
3670                 $ref_item{'fullname'} = $name;
3671                 $name =~ s!^refs/tags/!!;
3672
3673                 $ref_item{'type'} = $type;
3674                 $ref_item{'id'} = $id;
3675                 $ref_item{'name'} = $name;
3676                 if ($type eq "tag") {
3677                         $ref_item{'subject'} = $title;
3678                         $ref_item{'reftype'} = $reftype;
3679                         $ref_item{'refid'}   = $refid;
3680                 } else {
3681                         $ref_item{'reftype'} = $type;
3682                         $ref_item{'refid'}   = $id;
3683                 }
3684
3685                 if ($type eq "tag" || $type eq "commit") {
3686                         $ref_item{'epoch'} = $epoch;
3687                         if ($epoch) {
3688                                 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3689                         } else {
3690                                 $ref_item{'age'} = "unknown";
3691                         }
3692                 }
3693
3694                 push @tagslist, \%ref_item;
3695         }
3696         close $fd;
3697
3698         return wantarray ? @tagslist : \@tagslist;
3699 }
3700
3701 ## ----------------------------------------------------------------------
3702 ## filesystem-related functions
3703
3704 sub get_file_owner {
3705         my $path = shift;
3706
3707         my ($dev, $ino, $mode, $nlink, $st_uid, $st_gid, $rdev, $size) = stat($path);
3708         my ($name, $passwd, $uid, $gid, $quota, $comment, $gcos, $dir, $shell) = getpwuid($st_uid);
3709         if (!defined $gcos) {
3710                 return undef;
3711         }
3712         my $owner = $gcos;
3713         $owner =~ s/[,;].*$//;
3714         return to_utf8($owner);
3715 }
3716
3717 # assume that file exists
3718 sub insert_file {
3719         my $filename = shift;
3720
3721         open my $fd, '<', $filename;
3722         print map { to_utf8($_) } <$fd>;
3723         close $fd;
3724 }
3725
3726 ## ......................................................................
3727 ## mimetype related functions
3728
3729 sub mimetype_guess_file {
3730         my $filename = shift;
3731         my $mimemap = shift;
3732         -r $mimemap or return undef;
3733
3734         my %mimemap;
3735         open(my $mh, '<', $mimemap) or return undef;
3736         while (<$mh>) {
3737                 next if m/^#/; # skip comments
3738                 my ($mimetype, @exts) = split(/\s+/);
3739                 foreach my $ext (@exts) {
3740                         $mimemap{$ext} = $mimetype;
3741                 }
3742         }
3743         close($mh);
3744
3745         $filename =~ /\.([^.]*)$/;
3746         return $mimemap{$1};
3747 }
3748
3749 sub mimetype_guess {
3750         my $filename = shift;
3751         my $mime;
3752         $filename =~ /\./ or return undef;
3753
3754         if ($mimetypes_file) {
3755                 my $file = $mimetypes_file;
3756                 if ($file !~ m!^/!) { # if it is relative path
3757                         # it is relative to project
3758                         $file = "$projectroot/$project/$file";
3759                 }
3760                 $mime = mimetype_guess_file($filename, $file);
3761         }
3762         $mime ||= mimetype_guess_file($filename, '/etc/mime.types');
3763         return $mime;
3764 }
3765
3766 sub blob_mimetype {
3767         my $fd = shift;
3768         my $filename = shift;
3769
3770         if ($filename) {
3771                 my $mime = mimetype_guess($filename);
3772                 $mime and return $mime;
3773         }
3774
3775         # just in case
3776         return $default_blob_plain_mimetype unless $fd;
3777
3778         if (-T $fd) {
3779                 return 'text/plain';
3780         } elsif (! $filename) {
3781                 return 'application/octet-stream';
3782         } elsif ($filename =~ m/\.png$/i) {
3783                 return 'image/png';
3784         } elsif ($filename =~ m/\.gif$/i) {
3785                 return 'image/gif';
3786         } elsif ($filename =~ m/\.jpe?g$/i) {
3787                 return 'image/jpeg';
3788         } else {
3789                 return 'application/octet-stream';
3790         }
3791 }
3792
3793 sub blob_contenttype {
3794         my ($fd, $file_name, $type) = @_;
3795
3796         $type ||= blob_mimetype($fd, $file_name);
3797         if ($type eq 'text/plain' && defined $default_text_plain_charset) {
3798                 $type .= "; charset=$default_text_plain_charset";
3799         }
3800
3801         return $type;
3802 }
3803
3804 # guess file syntax for syntax highlighting; return undef if no highlighting
3805 # the name of syntax can (in the future) depend on syntax highlighter used
3806 sub guess_file_syntax {
3807         my ($highlight, $mimetype, $file_name) = @_;
3808         return undef unless ($highlight && defined $file_name);
3809         my $basename = basename($file_name, '.in');
3810         return $highlight_basename{$basename}
3811                 if exists $highlight_basename{$basename};
3812
3813         $basename =~ /\.([^.]*)$/;
3814         my $ext = $1 or return undef;
3815         return $highlight_ext{$ext}
3816                 if exists $highlight_ext{$ext};
3817
3818         return undef;
3819 }
3820
3821 # run highlighter and return FD of its output,
3822 # or return original FD if no highlighting
3823 sub run_highlighter {
3824         my ($fd, $highlight, $syntax) = @_;
3825         return $fd unless ($highlight && defined $syntax);
3826
3827         close $fd;
3828         open $fd, quote_command(git_cmd(), "cat-file", "blob", $hash)." | ".
3829                   quote_command($highlight_bin).
3830                   " --replace-tabs=8 --fragment --syntax $syntax |"
3831                 or die_error(500, "Couldn't open file or run syntax highlighter");
3832         return $fd;
3833 }
3834
3835 ## ======================================================================
3836 ## functions printing HTML: header, footer, error page
3837
3838 sub get_page_title {
3839         my $title = to_utf8($site_name);
3840
3841         unless (defined $project) {
3842                 if (defined $project_filter) {
3843                         $title .= " - projects in '" . esc_path($project_filter) . "'";
3844                 }
3845                 return $title;
3846         }
3847         $title .= " - " . to_utf8($project);
3848
3849         return $title unless (defined $action);
3850         $title .= "/$action"; # $action is US-ASCII (7bit ASCII)
3851
3852         return $title unless (defined $file_name);
3853         $title .= " - " . esc_path($file_name);
3854         if ($action eq "tree" && $file_name !~ m|/$|) {
3855                 $title .= "/";
3856         }
3857
3858         return $title;
3859 }
3860
3861 sub get_content_type_html {
3862         # require explicit support from the UA if we are to send the page as
3863         # 'application/xhtml+xml', otherwise send it as plain old 'text/html'.
3864         # we have to do this because MSIE sometimes globs '*/*', pretending to
3865         # support xhtml+xml but choking when it gets what it asked for.
3866         if (defined $cgi->http('HTTP_ACCEPT') &&
3867             $cgi->http('HTTP_ACCEPT') =~ m/(,|;|\s|^)application\/xhtml\+xml(,|;|\s|$)/ &&
3868             $cgi->Accept('application/xhtml+xml') != 0) {
3869                 return 'application/xhtml+xml';
3870         } else {
3871                 return 'text/html';
3872         }
3873 }
3874
3875 sub print_feed_meta {
3876         if (defined $project) {
3877                 my %href_params = get_feed_info();
3878                 if (!exists $href_params{'-title'}) {
3879                         $href_params{'-title'} = 'log';
3880                 }
3881
3882                 foreach my $format (qw(RSS Atom)) {
3883                         my $type = lc($format);
3884                         my %link_attr = (
3885                                 '-rel' => 'alternate',
3886                                 '-title' => esc_attr("$project - $href_params{'-title'} - $format feed"),
3887                                 '-type' => "application/$type+xml"
3888                         );
3889
3890                         $href_params{'action'} = $type;
3891                         $link_attr{'-href'} = href(%href_params);
3892                         print "<link ".
3893                               "rel=\"$link_attr{'-rel'}\" ".
3894                               "title=\"$link_attr{'-title'}\" ".
3895                               "href=\"$link_attr{'-href'}\" ".
3896                               "type=\"$link_attr{'-type'}\" ".
3897                               "/>\n";
3898
3899                         $href_params{'extra_options'} = '--no-merges';
3900                         $link_attr{'-href'} = href(%href_params);
3901                         $link_attr{'-title'} .= ' (no merges)';
3902                         print "<link ".
3903                               "rel=\"$link_attr{'-rel'}\" ".
3904                               "title=\"$link_attr{'-title'}\" ".
3905                               "href=\"$link_attr{'-href'}\" ".
3906                               "type=\"$link_attr{'-type'}\" ".
3907                               "/>\n";
3908                 }
3909
3910         } else {
3911                 printf('<link rel="alternate" title="%s projects list" '.
3912                        'href="%s" type="text/plain; charset=utf-8" />'."\n",
3913                        esc_attr($site_name), href(project=>undef, action=>"project_index"));
3914                 printf('<link rel="alternate" title="%s projects feeds" '.
3915                        'href="%s" type="text/x-opml" />'."\n",
3916                        esc_attr($site_name), href(project=>undef, action=>"opml"));
3917         }
3918 }
3919
3920 sub print_header_links {
3921         my $status = shift;
3922
3923         # print out each stylesheet that exist, providing backwards capability
3924         # for those people who defined $stylesheet in a config file
3925         if (defined $stylesheet) {
3926                 print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
3927         } else {
3928                 foreach my $stylesheet (@stylesheets) {
3929                         next unless $stylesheet;
3930                         print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
3931                 }
3932         }
3933         print_feed_meta()
3934                 if ($status eq '200 OK');
3935         if (defined $favicon) {
3936                 print qq(<link rel="shortcut icon" href=").esc_url($favicon).qq(" type="image/png" />\n);
3937         }
3938 }
3939
3940 sub print_nav_breadcrumbs_path {
3941         my $dirprefix = undef;
3942         while (my $part = shift) {
3943                 $dirprefix .= "/" if defined $dirprefix;
3944                 $dirprefix .= $part;
3945                 print $cgi->a({-href => href(project => undef,
3946                                              project_filter => $dirprefix,
3947                                              action => "project_list")},
3948                               esc_html($part)) . " / ";
3949         }
3950 }
3951
3952 sub print_nav_breadcrumbs {
3953         my %opts = @_;
3954
3955         print $cgi->a({-href => esc_url($home_link)}, $home_link_str) . " / ";
3956         if (defined $project) {
3957                 my @dirname = split '/', $project;
3958                 my $projectbasename = pop @dirname;
3959                 print_nav_breadcrumbs_path(@dirname);
3960                 print $cgi->a({-href => href(action=>"summary")}, esc_html($projectbasename));
3961                 if (defined $action) {
3962                         my $action_print = $action ;
3963                         if (defined $opts{-action_extra}) {
3964                                 $action_print = $cgi->a({-href => href(action=>$action)},
3965                                         $action);
3966                         }
3967                         print " / $action_print";
3968                 }
3969                 if (defined $opts{-action_extra}) {
3970                         print " / $opts{-action_extra}";
3971                 }
3972                 print "\n";
3973         } elsif (defined $project_filter) {
3974                 print_nav_breadcrumbs_path(split '/', $project_filter);
3975         }
3976 }
3977
3978 sub print_search_form {
3979         if (!defined $searchtext) {
3980                 $searchtext = "";
3981         }
3982         my $search_hash;
3983         if (defined $hash_base) {
3984                 $search_hash = $hash_base;
3985         } elsif (defined $hash) {
3986                 $search_hash = $hash;
3987         } else {
3988                 $search_hash = "HEAD";
3989         }
3990         my $action = $my_uri;
3991         my $use_pathinfo = gitweb_check_feature('pathinfo');
3992         if ($use_pathinfo) {
3993                 $action .= "/".esc_url($project);
3994         }
3995         print $cgi->startform(-method => "get", -action => $action) .
3996               "<div class=\"search\">\n" .
3997               (!$use_pathinfo &&
3998               $cgi->input({-name=>"p", -value=>$project, -type=>"hidden"}) . "\n") .
3999               $cgi->input({-name=>"a", -value=>"search", -type=>"hidden"}) . "\n" .
4000               $cgi->input({-name=>"h", -value=>$search_hash, -type=>"hidden"}) . "\n" .
4001               $cgi->popup_menu(-name => 'st', -default => 'commit',
4002                                -values => ['commit', 'grep', 'author', 'committer', 'pickaxe']) .
4003               $cgi->sup($cgi->a({-href => href(action=>"search_help")}, "?")) .
4004               " search:\n",
4005               $cgi->textfield(-name => "s", -value => $searchtext, -override => 1) . "\n" .
4006               "<span title=\"Extended regular expression\">" .
4007               $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
4008                              -checked => $search_use_regexp) .
4009               "</span>" .
4010               "</div>" .
4011               $cgi->end_form() . "\n";
4012 }
4013
4014 sub git_header_html {
4015         my $status = shift || "200 OK";
4016         my $expires = shift;
4017         my %opts = @_;
4018
4019         my $title = get_page_title();
4020         my $content_type = get_content_type_html();
4021         print $cgi->header(-type=>$content_type, -charset => 'utf-8',
4022                            -status=> $status, -expires => $expires)
4023                 unless ($opts{'-no_http_header'});
4024         my $mod_perl_version = $ENV{'MOD_PERL'} ? " $ENV{'MOD_PERL'}" : '';
4025         print <<EOF;
4026 <?xml version="1.0" encoding="utf-8"?>
4027 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
4028 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en-US" lang="en-US">
4029 <!-- git web interface version $version, (C) 2005-2006, Kay Sievers <kay.sievers\@vrfy.org>, Christian Gierke -->
4030 <!-- git core binaries version $git_version -->
4031 <head>
4032 <meta http-equiv="content-type" content="$content_type; charset=utf-8"/>
4033 <meta name="generator" content="gitweb/$version git/$git_version$mod_perl_version"/>
4034 <meta name="robots" content="index, nofollow"/>
4035 <title>$title</title>
4036 EOF
4037         # the stylesheet, favicon etc urls won't work correctly with path_info
4038         # unless we set the appropriate base URL
4039         if ($ENV{'PATH_INFO'}) {
4040                 print "<base href=\"".esc_url($base_url)."\" />\n";
4041         }
4042         print_header_links($status);
4043
4044         if (defined $site_html_head_string) {
4045                 print to_utf8($site_html_head_string);
4046         }
4047
4048         print "</head>\n" .
4049               "<body>\n";
4050
4051         if (defined $site_header && -f $site_header) {
4052                 insert_file($site_header);
4053         }
4054
4055         print "<div class=\"page_header\">\n";
4056         if (defined $logo) {
4057                 print $cgi->a({-href => esc_url($logo_url),
4058                                -title => $logo_label},
4059                               $cgi->img({-src => esc_url($logo),
4060                                          -width => 72, -height => 27,
4061                                          -alt => "git",
4062                                          -class => "logo"}));
4063         }
4064         print_nav_breadcrumbs(%opts);
4065         print "</div>\n";
4066
4067         my $have_search = gitweb_check_feature('search');
4068         if (defined $project && $have_search) {
4069                 print_search_form();
4070         }
4071 }
4072
4073 sub git_footer_html {
4074         my $feed_class = 'rss_logo';
4075
4076         print "<div class=\"page_footer\">\n";
4077         if (defined $project) {
4078                 my $descr = git_get_project_description($project);
4079                 if (defined $descr) {
4080                         print "<div class=\"page_footer_text\">" . esc_html($descr) . "</div>\n";
4081                 }
4082
4083                 my %href_params = get_feed_info();
4084                 if (!%href_params) {
4085                         $feed_class .= ' generic';
4086                 }
4087                 $href_params{'-title'} ||= 'log';
4088
4089                 foreach my $format (qw(RSS Atom)) {
4090                         $href_params{'action'} = lc($format);
4091                         print $cgi->a({-href => href(%href_params),
4092                                       -title => "$href_params{'-title'} $format feed",
4093                                       -class => $feed_class}, $format)."\n";
4094                 }
4095
4096         } else {
4097                 print $cgi->a({-href => href(project=>undef, action=>"opml",
4098                                              project_filter => $project_filter),
4099                               -class => $feed_class}, "OPML") . " ";
4100                 print $cgi->a({-href => href(project=>undef, action=>"project_index",
4101                                              project_filter => $project_filter),
4102                               -class => $feed_class}, "TXT") . "\n";
4103         }
4104         print "</div>\n"; # class="page_footer"
4105
4106         if (defined $t0 && gitweb_check_feature('timed')) {
4107                 print "<div id=\"generating_info\">\n";
4108                 print 'This page took '.
4109                       '<span id="generating_time" class="time_span">'.
4110                       tv_interval($t0, [ gettimeofday() ]).
4111                       ' seconds </span>'.
4112                       ' and '.
4113                       '<span id="generating_cmd">'.
4114                       $number_of_git_cmds.
4115                       '</span> git commands '.
4116                       " to generate.\n";
4117                 print "</div>\n"; # class="page_footer"
4118         }
4119
4120         if (defined $site_footer && -f $site_footer) {
4121                 insert_file($site_footer);
4122         }
4123
4124         print qq!<script type="text/javascript" src="!.esc_url($javascript).qq!"></script>\n!;
4125         if (defined $action &&
4126             $action eq 'blame_incremental') {
4127                 print qq!<script type="text/javascript">\n!.
4128                       qq!startBlame("!. href(action=>"blame_data", -replay=>1) .qq!",\n!.
4129                       qq!           "!. href() .qq!");\n!.
4130                       qq!</script>\n!;
4131         } else {
4132                 my ($jstimezone, $tz_cookie, $datetime_class) =
4133                         gitweb_get_feature('javascript-timezone');
4134
4135                 print qq!<script type="text/javascript">\n!.
4136                       qq!window.onload = function () {\n!;
4137                 if (gitweb_check_feature('javascript-actions')) {
4138                         print qq!       fixLinks();\n!;
4139                 }
4140                 if ($jstimezone && $tz_cookie && $datetime_class) {
4141                         print qq!       var tz_cookie = { name: '$tz_cookie', expires: 14, path: '/' };\n!. # in days
4142                               qq!       onloadTZSetup('$jstimezone', tz_cookie, '$datetime_class');\n!;
4143                 }
4144                 print qq!};\n!.
4145                       qq!</script>\n!;
4146         }
4147
4148         print "</body>\n" .
4149               "</html>";
4150 }
4151
4152 # die_error(<http_status_code>, <error_message>[, <detailed_html_description>])
4153 # Example: die_error(404, 'Hash not found')
4154 # By convention, use the following status codes (as defined in RFC 2616):
4155 # 400: Invalid or missing CGI parameters, or
4156 #      requested object exists but has wrong type.
4157 # 403: Requested feature (like "pickaxe" or "snapshot") not enabled on
4158 #      this server or project.
4159 # 404: Requested object/revision/project doesn't exist.
4160 # 500: The server isn't configured properly, or
4161 #      an internal error occurred (e.g. failed assertions caused by bugs), or
4162 #      an unknown error occurred (e.g. the git binary died unexpectedly).
4163 # 503: The server is currently unavailable (because it is overloaded,
4164 #      or down for maintenance).  Generally, this is a temporary state.
4165 sub die_error {
4166         my $status = shift || 500;
4167         my $error = esc_html(shift) || "Internal Server Error";
4168         my $extra = shift;
4169         my %opts = @_;
4170
4171         my %http_responses = (
4172                 400 => '400 Bad Request',
4173                 403 => '403 Forbidden',
4174                 404 => '404 Not Found',
4175                 500 => '500 Internal Server Error',
4176                 503 => '503 Service Unavailable',
4177         );
4178         git_header_html($http_responses{$status}, undef, %opts);
4179         print <<EOF;
4180 <div class="page_body">
4181 <br /><br />
4182 $status - $error
4183 <br />
4184 EOF
4185         if (defined $extra) {
4186                 print "<hr />\n" .
4187                       "$extra\n";
4188         }
4189         print "</div>\n";
4190
4191         git_footer_html();
4192         goto DONE_GITWEB
4193                 unless ($opts{'-error_handler'});
4194 }
4195
4196 ## ----------------------------------------------------------------------
4197 ## functions printing or outputting HTML: navigation
4198
4199 sub git_print_page_nav {
4200         my ($current, $suppress, $head, $treehead, $treebase, $extra) = @_;
4201         $extra = '' if !defined $extra; # pager or formats
4202
4203         my @navs = qw(summary shortlog log commit commitdiff tree);
4204         if ($suppress) {
4205                 @navs = grep { $_ ne $suppress } @navs;
4206         }
4207
4208         my %arg = map { $_ => {action=>$_} } @navs;
4209         if (defined $head) {
4210                 for (qw(commit commitdiff)) {
4211                         $arg{$_}{'hash'} = $head;
4212                 }
4213                 if ($current =~ m/^(tree | log | shortlog | commit | commitdiff | search)$/x) {
4214                         for (qw(shortlog log)) {
4215                                 $arg{$_}{'hash'} = $head;
4216                         }
4217                 }
4218         }
4219
4220         $arg{'tree'}{'hash'} = $treehead if defined $treehead;
4221         $arg{'tree'}{'hash_base'} = $treebase if defined $treebase;
4222
4223         my @actions = gitweb_get_feature('actions');
4224         my %repl = (
4225                 '%' => '%',
4226                 'n' => $project,         # project name
4227                 'f' => $git_dir,         # project path within filesystem
4228                 'h' => $treehead || '',  # current hash ('h' parameter)
4229                 'b' => $treebase || '',  # hash base ('hb' parameter)
4230         );
4231         while (@actions) {
4232                 my ($label, $link, $pos) = splice(@actions,0,3);
4233                 # insert
4234                 @navs = map { $_ eq $pos ? ($_, $label) : $_ } @navs;
4235                 # munch munch
4236                 $link =~ s/%([%nfhb])/$repl{$1}/g;
4237                 $arg{$label}{'_href'} = $link;
4238         }
4239
4240         print "<div class=\"page_nav\">\n" .
4241                 (join " | ",
4242                  map { $_ eq $current ?
4243                        $_ : $cgi->a({-href => ($arg{$_}{_href} ? $arg{$_}{_href} : href(%{$arg{$_}}))}, "$_")
4244                  } @navs);
4245         print "<br/>\n$extra<br/>\n" .
4246               "</div>\n";
4247 }
4248
4249 # returns a submenu for the nagivation of the refs views (tags, heads,
4250 # remotes) with the current view disabled and the remotes view only
4251 # available if the feature is enabled
4252 sub format_ref_views {
4253         my ($current) = @_;
4254         my @ref_views = qw{tags heads};
4255         push @ref_views, 'remotes' if gitweb_check_feature('remote_heads');
4256         return join " | ", map {
4257                 $_ eq $current ? $_ :
4258                 $cgi->a({-href => href(action=>$_)}, $_)
4259         } @ref_views
4260 }
4261
4262 sub format_paging_nav {
4263         my ($action, $page, $has_next_link) = @_;
4264         my $paging_nav;
4265
4266
4267         if ($page > 0) {
4268                 $paging_nav .=
4269                         $cgi->a({-href => href(-replay=>1, page=>undef)}, "first") .
4270                         " &sdot; " .
4271                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
4272                                  -accesskey => "p", -title => "Alt-p"}, "prev");
4273         } else {
4274                 $paging_nav .= "first &sdot; prev";
4275         }
4276
4277         if ($has_next_link) {
4278                 $paging_nav .= " &sdot; " .
4279                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
4280                                  -accesskey => "n", -title => "Alt-n"}, "next");
4281         } else {
4282                 $paging_nav .= " &sdot; next";
4283         }
4284
4285         return $paging_nav;
4286 }
4287
4288 ## ......................................................................
4289 ## functions printing or outputting HTML: div
4290
4291 sub git_print_header_div {
4292         my ($action, $title, $hash, $hash_base) = @_;
4293         my %args = ();
4294
4295         $args{'action'} = $action;
4296         $args{'hash'} = $hash if $hash;
4297         $args{'hash_base'} = $hash_base if $hash_base;
4298
4299         print "<div class=\"header\">\n" .
4300               $cgi->a({-href => href(%args), -class => "title"},
4301               $title ? $title : $action) .
4302               "\n</div>\n";
4303 }
4304
4305 sub format_repo_url {
4306         my ($name, $url) = @_;
4307         return "<tr class=\"metadata_url\"><td>$name</td><td>$url</td></tr>\n";
4308 }
4309
4310 # Group output by placing it in a DIV element and adding a header.
4311 # Options for start_div() can be provided by passing a hash reference as the
4312 # first parameter to the function.
4313 # Options to git_print_header_div() can be provided by passing an array
4314 # reference. This must follow the options to start_div if they are present.
4315 # The content can be a scalar, which is output as-is, a scalar reference, which
4316 # is output after html escaping, an IO handle passed either as *handle or
4317 # *handle{IO}, or a function reference. In the latter case all following
4318 # parameters will be taken as argument to the content function call.
4319 sub git_print_section {
4320         my ($div_args, $header_args, $content);
4321         my $arg = shift;
4322         if (ref($arg) eq 'HASH') {
4323                 $div_args = $arg;
4324                 $arg = shift;
4325         }
4326         if (ref($arg) eq 'ARRAY') {
4327                 $header_args = $arg;
4328                 $arg = shift;
4329         }
4330         $content = $arg;
4331
4332         print $cgi->start_div($div_args);
4333         git_print_header_div(@$header_args);
4334
4335         if (ref($content) eq 'CODE') {
4336                 $content->(@_);
4337         } elsif (ref($content) eq 'SCALAR') {
4338                 print esc_html($$content);
4339         } elsif (ref($content) eq 'GLOB' or ref($content) eq 'IO::Handle') {
4340                 print <$content>;
4341         } elsif (!ref($content) && defined($content)) {
4342                 print $content;
4343         }
4344
4345         print $cgi->end_div;
4346 }
4347
4348 sub format_timestamp_html {
4349         my $date = shift;
4350         my $strtime = $date->{'rfc2822'};
4351
4352         my (undef, undef, $datetime_class) =
4353                 gitweb_get_feature('javascript-timezone');
4354         if ($datetime_class) {
4355                 $strtime = qq!<span class="$datetime_class">$strtime</span>!;
4356         }
4357
4358         my $localtime_format = '(%02d:%02d %s)';
4359         if ($date->{'hour_local'} < 6) {
4360                 $localtime_format = '(<span class="atnight">%02d:%02d</span> %s)';
4361         }
4362         $strtime .= ' ' .
4363                     sprintf($localtime_format,
4364                             $date->{'hour_local'}, $date->{'minute_local'}, $date->{'tz_local'});
4365
4366         return $strtime;
4367 }
4368
4369 # Outputs the author name and date in long form
4370 sub git_print_authorship {
4371         my $co = shift;
4372         my %opts = @_;
4373         my $tag = $opts{-tag} || 'div';
4374         my $author = $co->{'author_name'};
4375
4376         my %ad = parse_date($co->{'author_epoch'}, $co->{'author_tz'});
4377         print "<$tag class=\"author_date\">" .
4378               format_search_author($author, "author", esc_html($author)) .
4379               " [".format_timestamp_html(\%ad)."]".
4380               git_get_avatar($co->{'author_email'}, -pad_before => 1) .
4381               "</$tag>\n";
4382 }
4383
4384 # Outputs table rows containing the full author or committer information,
4385 # in the format expected for 'commit' view (& similar).
4386 # Parameters are a commit hash reference, followed by the list of people
4387 # to output information for. If the list is empty it defaults to both
4388 # author and committer.
4389 sub git_print_authorship_rows {
4390         my $co = shift;
4391         # too bad we can't use @people = @_ || ('author', 'committer')
4392         my @people = @_;
4393         @people = ('author', 'committer') unless @people;
4394         foreach my $who (@people) {
4395                 my %wd = parse_date($co->{"${who}_epoch"}, $co->{"${who}_tz"});
4396                 print "<tr><td>$who</td><td>" .
4397                       format_search_author($co->{"${who}_name"}, $who,
4398                                            esc_html($co->{"${who}_name"})) . " " .
4399                       format_search_author($co->{"${who}_email"}, $who,
4400                                            esc_html("<" . $co->{"${who}_email"} . ">")) .
4401                       "</td><td rowspan=\"2\">" .
4402                       git_get_avatar($co->{"${who}_email"}, -size => 'double') .
4403                       "</td></tr>\n" .
4404                       "<tr>" .
4405                       "<td></td><td>" .
4406                       format_timestamp_html(\%wd) .
4407                       "</td>" .
4408                       "</tr>\n";
4409         }
4410 }
4411
4412 sub git_print_page_path {
4413         my $name = shift;
4414         my $type = shift;
4415         my $hb = shift;
4416
4417
4418         print "<div class=\"page_path\">";
4419         print $cgi->a({-href => href(action=>"tree", hash_base=>$hb),
4420                       -title => 'tree root'}, to_utf8("[$project]"));
4421         print " / ";
4422         if (defined $name) {
4423                 my @dirname = split '/', $name;
4424                 my $basename = pop @dirname;
4425                 my $fullname = '';
4426
4427                 foreach my $dir (@dirname) {
4428                         $fullname .= ($fullname ? '/' : '') . $dir;
4429                         print $cgi->a({-href => href(action=>"tree", file_name=>$fullname,
4430                                                      hash_base=>$hb),
4431                                       -title => $fullname}, esc_path($dir));
4432                         print " / ";
4433                 }
4434                 if (defined $type && $type eq 'blob') {
4435                         print $cgi->a({-href => href(action=>"blob_plain", file_name=>$file_name,
4436                                                      hash_base=>$hb),
4437                                       -title => $name}, esc_path($basename));
4438                 } elsif (defined $type && $type eq 'tree') {
4439                         print $cgi->a({-href => href(action=>"tree", file_name=>$file_name,
4440                                                      hash_base=>$hb),
4441                                       -title => $name}, esc_path($basename));
4442                         print " / ";
4443                 } else {
4444                         print esc_path($basename);
4445                 }
4446         }
4447         print "<br/></div>\n";
4448 }
4449
4450 sub git_print_log {
4451         my $log = shift;
4452         my %opts = @_;
4453
4454         if ($opts{'-remove_title'}) {
4455                 # remove title, i.e. first line of log
4456                 shift @$log;
4457         }
4458         # remove leading empty lines
4459         while (defined $log->[0] && $log->[0] eq "") {
4460                 shift @$log;
4461         }
4462
4463         # print log
4464         my $signoff = 0;
4465         my $empty = 0;
4466         foreach my $line (@$log) {
4467                 if ($line =~ m/^ *(signed[ \-]off[ \-]by[ :]|acked[ \-]by[ :]|cc[ :])/i) {
4468                         $signoff = 1;
4469                         $empty = 0;
4470                         if (! $opts{'-remove_signoff'}) {
4471                                 print "<span class=\"signoff\">" . esc_html($line) . "</span><br/>\n";
4472                                 next;
4473                         } else {
4474                                 # remove signoff lines
4475                                 next;
4476                         }
4477                 } else {
4478                         $signoff = 0;
4479                 }
4480
4481                 # print only one empty line
4482                 # do not print empty line after signoff
4483                 if ($line eq "") {
4484                         next if ($empty || $signoff);
4485                         $empty = 1;
4486                 } else {
4487                         $empty = 0;
4488                 }
4489
4490                 print format_log_line_html($line) . "<br/>\n";
4491         }
4492
4493         if ($opts{'-final_empty_line'}) {
4494                 # end with single empty line
4495                 print "<br/>\n" unless $empty;
4496         }
4497 }
4498
4499 # return link target (what link points to)
4500 sub git_get_link_target {
4501         my $hash = shift;
4502         my $link_target;
4503
4504         # read link
4505         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
4506                 or return;
4507         {
4508                 local $/ = undef;
4509                 $link_target = <$fd>;
4510         }
4511         close $fd
4512                 or return;
4513
4514         return $link_target;
4515 }
4516
4517 # given link target, and the directory (basedir) the link is in,
4518 # return target of link relative to top directory (top tree);
4519 # return undef if it is not possible (including absolute links).
4520 sub normalize_link_target {
4521         my ($link_target, $basedir) = @_;
4522
4523         # absolute symlinks (beginning with '/') cannot be normalized
4524         return if (substr($link_target, 0, 1) eq '/');
4525
4526         # normalize link target to path from top (root) tree (dir)
4527         my $path;
4528         if ($basedir) {
4529                 $path = $basedir . '/' . $link_target;
4530         } else {
4531                 # we are in top (root) tree (dir)
4532                 $path = $link_target;
4533         }
4534
4535         # remove //, /./, and /../
4536         my @path_parts;
4537         foreach my $part (split('/', $path)) {
4538                 # discard '.' and ''
4539                 next if (!$part || $part eq '.');
4540                 # handle '..'
4541                 if ($part eq '..') {
4542                         if (@path_parts) {
4543                                 pop @path_parts;
4544                         } else {
4545                                 # link leads outside repository (outside top dir)
4546                                 return;
4547                         }
4548                 } else {
4549                         push @path_parts, $part;
4550                 }
4551         }
4552         $path = join('/', @path_parts);
4553
4554         return $path;
4555 }
4556
4557 # print tree entry (row of git_tree), but without encompassing <tr> element
4558 sub git_print_tree_entry {
4559         my ($t, $basedir, $hash_base, $have_blame) = @_;
4560
4561         my %base_key = ();
4562         $base_key{'hash_base'} = $hash_base if defined $hash_base;
4563
4564         # The format of a table row is: mode list link.  Where mode is
4565         # the mode of the entry, list is the name of the entry, an href,
4566         # and link is the action links of the entry.
4567
4568         print "<td class=\"mode\">" . mode_str($t->{'mode'}) . "</td>\n";
4569         if (exists $t->{'size'}) {
4570                 print "<td class=\"size\">$t->{'size'}</td>\n";
4571         }
4572         if ($t->{'type'} eq "blob") {
4573                 print "<td class=\"list\">" .
4574                         $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4575                                                file_name=>"$basedir$t->{'name'}", %base_key),
4576                                 -class => "list"}, esc_path($t->{'name'}));
4577                 if (S_ISLNK(oct $t->{'mode'})) {
4578                         my $link_target = git_get_link_target($t->{'hash'});
4579                         if ($link_target) {
4580                                 my $norm_target = normalize_link_target($link_target, $basedir);
4581                                 if (defined $norm_target) {
4582                                         print " -> " .
4583                                               $cgi->a({-href => href(action=>"object", hash_base=>$hash_base,
4584                                                                      file_name=>$norm_target),
4585                                                        -title => $norm_target}, esc_path($link_target));
4586                                 } else {
4587                                         print " -> " . esc_path($link_target);
4588                                 }
4589                         }
4590                 }
4591                 print "</td>\n";
4592                 print "<td class=\"link\">";
4593                 print $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4594                                              file_name=>"$basedir$t->{'name'}", %base_key)},
4595                               "blob");
4596                 if ($have_blame) {
4597                         print " | " .
4598                               $cgi->a({-href => href(action=>"blame", hash=>$t->{'hash'},
4599                                                      file_name=>"$basedir$t->{'name'}", %base_key)},
4600                                       "blame");
4601                 }
4602                 if (defined $hash_base) {
4603                         print " | " .
4604                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4605                                                      hash=>$t->{'hash'}, file_name=>"$basedir$t->{'name'}")},
4606                                       "history");
4607                 }
4608                 print " | " .
4609                         $cgi->a({-href => href(action=>"blob_plain", hash_base=>$hash_base,
4610                                                file_name=>"$basedir$t->{'name'}")},
4611                                 "raw");
4612                 print "</td>\n";
4613
4614         } elsif ($t->{'type'} eq "tree") {
4615                 print "<td class=\"list\">";
4616                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4617                                              file_name=>"$basedir$t->{'name'}",
4618                                              %base_key)},
4619                               esc_path($t->{'name'}));
4620                 print "</td>\n";
4621                 print "<td class=\"link\">";
4622                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4623                                              file_name=>"$basedir$t->{'name'}",
4624                                              %base_key)},
4625                               "tree");
4626                 if (defined $hash_base) {
4627                         print " | " .
4628                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4629                                                      file_name=>"$basedir$t->{'name'}")},
4630                                       "history");
4631                 }
4632                 print "</td>\n";
4633         } else {
4634                 # unknown object: we can only present history for it
4635                 # (this includes 'commit' object, i.e. submodule support)
4636                 print "<td class=\"list\">" .
4637                       esc_path($t->{'name'}) .
4638                       "</td>\n";
4639                 print "<td class=\"link\">";
4640                 if (defined $hash_base) {
4641                         print $cgi->a({-href => href(action=>"history",
4642                                                      hash_base=>$hash_base,
4643                                                      file_name=>"$basedir$t->{'name'}")},
4644                                       "history");
4645                 }
4646                 print "</td>\n";
4647         }
4648 }
4649
4650 ## ......................................................................
4651 ## functions printing large fragments of HTML
4652
4653 # get pre-image filenames for merge (combined) diff
4654 sub fill_from_file_info {
4655         my ($diff, @parents) = @_;
4656
4657         $diff->{'from_file'} = [ ];
4658         $diff->{'from_file'}[$diff->{'nparents'} - 1] = undef;
4659         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4660                 if ($diff->{'status'}[$i] eq 'R' ||
4661                     $diff->{'status'}[$i] eq 'C') {
4662                         $diff->{'from_file'}[$i] =
4663                                 git_get_path_by_hash($parents[$i], $diff->{'from_id'}[$i]);
4664                 }
4665         }
4666
4667         return $diff;
4668 }
4669
4670 # is current raw difftree line of file deletion
4671 sub is_deleted {
4672         my $diffinfo = shift;
4673
4674         return $diffinfo->{'to_id'} eq ('0' x 40);
4675 }
4676
4677 # does patch correspond to [previous] difftree raw line
4678 # $diffinfo  - hashref of parsed raw diff format
4679 # $patchinfo - hashref of parsed patch diff format
4680 #              (the same keys as in $diffinfo)
4681 sub is_patch_split {
4682         my ($diffinfo, $patchinfo) = @_;
4683
4684         return defined $diffinfo && defined $patchinfo
4685                 && $diffinfo->{'to_file'} eq $patchinfo->{'to_file'};
4686 }
4687
4688
4689 sub git_difftree_body {
4690         my ($difftree, $hash, @parents) = @_;
4691         my ($parent) = $parents[0];
4692         my $have_blame = gitweb_check_feature('blame');
4693         print "<div class=\"list_head\">\n";
4694         if ($#{$difftree} > 10) {
4695                 print(($#{$difftree} + 1) . " files changed:\n");
4696         }
4697         print "</div>\n";
4698
4699         print "<table class=\"" .
4700               (@parents > 1 ? "combined " : "") .
4701               "diff_tree\">\n";
4702
4703         # header only for combined diff in 'commitdiff' view
4704         my $has_header = @$difftree && @parents > 1 && $action eq 'commitdiff';
4705         if ($has_header) {
4706                 # table header
4707                 print "<thead><tr>\n" .
4708                        "<th></th><th></th>\n"; # filename, patchN link
4709                 for (my $i = 0; $i < @parents; $i++) {
4710                         my $par = $parents[$i];
4711                         print "<th>" .
4712                               $cgi->a({-href => href(action=>"commitdiff",
4713                                                      hash=>$hash, hash_parent=>$par),
4714                                        -title => 'commitdiff to parent number ' .
4715                                                   ($i+1) . ': ' . substr($par,0,7)},
4716                                       $i+1) .
4717                               "&nbsp;</th>\n";
4718                 }
4719                 print "</tr></thead>\n<tbody>\n";
4720         }
4721
4722         my $alternate = 1;
4723         my $patchno = 0;
4724         foreach my $line (@{$difftree}) {
4725                 my $diff = parsed_difftree_line($line);
4726
4727                 if ($alternate) {
4728                         print "<tr class=\"dark\">\n";
4729                 } else {
4730                         print "<tr class=\"light\">\n";
4731                 }
4732                 $alternate ^= 1;
4733
4734                 if (exists $diff->{'nparents'}) { # combined diff
4735
4736                         fill_from_file_info($diff, @parents)
4737                                 unless exists $diff->{'from_file'};
4738
4739                         if (!is_deleted($diff)) {
4740                                 # file exists in the result (child) commit
4741                                 print "<td>" .
4742                                       $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4743                                                              file_name=>$diff->{'to_file'},
4744                                                              hash_base=>$hash),
4745                                               -class => "list"}, esc_path($diff->{'to_file'})) .
4746                                       "</td>\n";
4747                         } else {
4748                                 print "<td>" .
4749                                       esc_path($diff->{'to_file'}) .
4750                                       "</td>\n";
4751                         }
4752
4753                         if ($action eq 'commitdiff') {
4754                                 # link to patch
4755                                 $patchno++;
4756                                 print "<td class=\"link\">" .
4757                                       $cgi->a({-href => href(-anchor=>"patch$patchno")},
4758                                               "patch") .
4759                                       " | " .
4760                                       "</td>\n";
4761                         }
4762
4763                         my $has_history = 0;
4764                         my $not_deleted = 0;
4765                         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4766                                 my $hash_parent = $parents[$i];
4767                                 my $from_hash = $diff->{'from_id'}[$i];
4768                                 my $from_path = $diff->{'from_file'}[$i];
4769                                 my $status = $diff->{'status'}[$i];
4770
4771                                 $has_history ||= ($status ne 'A');
4772                                 $not_deleted ||= ($status ne 'D');
4773
4774                                 if ($status eq 'A') {
4775                                         print "<td  class=\"link\" align=\"right\"> | </td>\n";
4776                                 } elsif ($status eq 'D') {
4777                                         print "<td class=\"link\">" .
4778                                               $cgi->a({-href => href(action=>"blob",
4779                                                                      hash_base=>$hash,
4780                                                                      hash=>$from_hash,
4781                                                                      file_name=>$from_path)},
4782                                                       "blob" . ($i+1)) .
4783                                               " | </td>\n";
4784                                 } else {
4785                                         if ($diff->{'to_id'} eq $from_hash) {
4786                                                 print "<td class=\"link nochange\">";
4787                                         } else {
4788                                                 print "<td class=\"link\">";
4789                                         }
4790                                         print $cgi->a({-href => href(action=>"blobdiff",
4791                                                                      hash=>$diff->{'to_id'},
4792                                                                      hash_parent=>$from_hash,
4793                                                                      hash_base=>$hash,
4794                                                                      hash_parent_base=>$hash_parent,
4795                                                                      file_name=>$diff->{'to_file'},
4796                                                                      file_parent=>$from_path)},
4797                                                       "diff" . ($i+1)) .
4798                                               " | </td>\n";
4799                                 }
4800                         }
4801
4802                         print "<td class=\"link\">";
4803                         if ($not_deleted) {
4804                                 print $cgi->a({-href => href(action=>"blob",
4805                                                              hash=>$diff->{'to_id'},
4806                                                              file_name=>$diff->{'to_file'},
4807                                                              hash_base=>$hash)},
4808                                               "blob");
4809                                 print " | " if ($has_history);
4810                         }
4811                         if ($has_history) {
4812                                 print $cgi->a({-href => href(action=>"history",
4813                                                              file_name=>$diff->{'to_file'},
4814                                                              hash_base=>$hash)},
4815                                               "history");
4816                         }
4817                         print "</td>\n";
4818
4819                         print "</tr>\n";
4820                         next; # instead of 'else' clause, to avoid extra indent
4821                 }
4822                 # else ordinary diff
4823
4824                 my ($to_mode_oct, $to_mode_str, $to_file_type);
4825                 my ($from_mode_oct, $from_mode_str, $from_file_type);
4826                 if ($diff->{'to_mode'} ne ('0' x 6)) {
4827                         $to_mode_oct = oct $diff->{'to_mode'};
4828                         if (S_ISREG($to_mode_oct)) { # only for regular file
4829                                 $to_mode_str = sprintf("%04o", $to_mode_oct & 0777); # permission bits
4830                         }
4831                         $to_file_type = file_type($diff->{'to_mode'});
4832                 }
4833                 if ($diff->{'from_mode'} ne ('0' x 6)) {
4834                         $from_mode_oct = oct $diff->{'from_mode'};
4835                         if (S_ISREG($from_mode_oct)) { # only for regular file
4836                                 $from_mode_str = sprintf("%04o", $from_mode_oct & 0777); # permission bits
4837                         }
4838                         $from_file_type = file_type($diff->{'from_mode'});
4839                 }
4840
4841                 if ($diff->{'status'} eq "A") { # created
4842                         my $mode_chng = "<span class=\"file_status new\">[new $to_file_type";
4843                         $mode_chng   .= " with mode: $to_mode_str" if $to_mode_str;
4844                         $mode_chng   .= "]</span>";
4845                         print "<td>";
4846                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4847                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4848                                       -class => "list"}, esc_path($diff->{'file'}));
4849                         print "</td>\n";
4850                         print "<td>$mode_chng</td>\n";
4851                         print "<td class=\"link\">";
4852                         if ($action eq 'commitdiff') {
4853                                 # link to patch
4854                                 $patchno++;
4855                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4856                                               "patch") .
4857                                       " | ";
4858                         }
4859                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4860                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4861                                       "blob");
4862                         print "</td>\n";
4863
4864                 } elsif ($diff->{'status'} eq "D") { # deleted
4865                         my $mode_chng = "<span class=\"file_status deleted\">[deleted $from_file_type]</span>";
4866                         print "<td>";
4867                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4868                                                      hash_base=>$parent, file_name=>$diff->{'file'}),
4869                                        -class => "list"}, esc_path($diff->{'file'}));
4870                         print "</td>\n";
4871                         print "<td>$mode_chng</td>\n";
4872                         print "<td class=\"link\">";
4873                         if ($action eq 'commitdiff') {
4874                                 # link to patch
4875                                 $patchno++;
4876                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4877                                               "patch") .
4878                                       " | ";
4879                         }
4880                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4881                                                      hash_base=>$parent, file_name=>$diff->{'file'})},
4882                                       "blob") . " | ";
4883                         if ($have_blame) {
4884                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$parent,
4885                                                              file_name=>$diff->{'file'})},
4886                                               "blame") . " | ";
4887                         }
4888                         print $cgi->a({-href => href(action=>"history", hash_base=>$parent,
4889                                                      file_name=>$diff->{'file'})},
4890                                       "history");
4891                         print "</td>\n";
4892
4893                 } elsif ($diff->{'status'} eq "M" || $diff->{'status'} eq "T") { # modified, or type changed
4894                         my $mode_chnge = "";
4895                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4896                                 $mode_chnge = "<span class=\"file_status mode_chnge\">[changed";
4897                                 if ($from_file_type ne $to_file_type) {
4898                                         $mode_chnge .= " from $from_file_type to $to_file_type";
4899                                 }
4900                                 if (($from_mode_oct & 0777) != ($to_mode_oct & 0777)) {
4901                                         if ($from_mode_str && $to_mode_str) {
4902                                                 $mode_chnge .= " mode: $from_mode_str->$to_mode_str";
4903                                         } elsif ($to_mode_str) {
4904                                                 $mode_chnge .= " mode: $to_mode_str";
4905                                         }
4906                                 }
4907                                 $mode_chnge .= "]</span>\n";
4908                         }
4909                         print "<td>";
4910                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4911                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4912                                       -class => "list"}, esc_path($diff->{'file'}));
4913                         print "</td>\n";
4914                         print "<td>$mode_chnge</td>\n";
4915                         print "<td class=\"link\">";
4916                         if ($action eq 'commitdiff') {
4917                                 # link to patch
4918                                 $patchno++;
4919                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4920                                               "patch") .
4921                                       " | ";
4922                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4923                                 # "commit" view and modified file (not onlu mode changed)
4924                                 print $cgi->a({-href => href(action=>"blobdiff",
4925                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4926                                                              hash_base=>$hash, hash_parent_base=>$parent,
4927                                                              file_name=>$diff->{'file'})},
4928                                               "diff") .
4929                                       " | ";
4930                         }
4931                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4932                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4933                                        "blob") . " | ";
4934                         if ($have_blame) {
4935                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4936                                                              file_name=>$diff->{'file'})},
4937                                               "blame") . " | ";
4938                         }
4939                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4940                                                      file_name=>$diff->{'file'})},
4941                                       "history");
4942                         print "</td>\n";
4943
4944                 } elsif ($diff->{'status'} eq "R" || $diff->{'status'} eq "C") { # renamed or copied
4945                         my %status_name = ('R' => 'moved', 'C' => 'copied');
4946                         my $nstatus = $status_name{$diff->{'status'}};
4947                         my $mode_chng = "";
4948                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4949                                 # mode also for directories, so we cannot use $to_mode_str
4950                                 $mode_chng = sprintf(", mode: %04o", $to_mode_oct & 0777);
4951                         }
4952                         print "<td>" .
4953                               $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
4954                                                      hash=>$diff->{'to_id'}, file_name=>$diff->{'to_file'}),
4955                                       -class => "list"}, esc_path($diff->{'to_file'})) . "</td>\n" .
4956                               "<td><span class=\"file_status $nstatus\">[$nstatus from " .
4957                               $cgi->a({-href => href(action=>"blob", hash_base=>$parent,
4958                                                      hash=>$diff->{'from_id'}, file_name=>$diff->{'from_file'}),
4959                                       -class => "list"}, esc_path($diff->{'from_file'})) .
4960                               " with " . (int $diff->{'similarity'}) . "% similarity$mode_chng]</span></td>\n" .
4961                               "<td class=\"link\">";
4962                         if ($action eq 'commitdiff') {
4963                                 # link to patch
4964                                 $patchno++;
4965                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4966                                               "patch") .
4967                                       " | ";
4968                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4969                                 # "commit" view and modified file (not only pure rename or copy)
4970                                 print $cgi->a({-href => href(action=>"blobdiff",
4971                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4972                                                              hash_base=>$hash, hash_parent_base=>$parent,
4973                                                              file_name=>$diff->{'to_file'}, file_parent=>$diff->{'from_file'})},
4974                                               "diff") .
4975                                       " | ";
4976                         }
4977                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4978                                                      hash_base=>$parent, file_name=>$diff->{'to_file'})},
4979                                       "blob") . " | ";
4980                         if ($have_blame) {
4981                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4982                                                              file_name=>$diff->{'to_file'})},
4983                                               "blame") . " | ";
4984                         }
4985                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4986                                                     file_name=>$diff->{'to_file'})},
4987                                       "history");
4988                         print "</td>\n";
4989
4990                 } # we should not encounter Unmerged (U) or Unknown (X) status
4991                 print "</tr>\n";
4992         }
4993         print "</tbody>" if $has_header;
4994         print "</table>\n";
4995 }
4996
4997 sub print_sidebyside_diff_chunk {
4998         my @chunk = @_;
4999         my (@ctx, @rem, @add);
5000
5001         return unless @chunk;
5002
5003         # incomplete last line might be among removed or added lines,
5004         # or both, or among context lines: find which
5005         for (my $i = 1; $i < @chunk; $i++) {
5006                 if ($chunk[$i][0] eq 'incomplete') {
5007                         $chunk[$i][0] = $chunk[$i-1][0];
5008                 }
5009         }
5010
5011         # guardian
5012         push @chunk, ["", ""];
5013
5014         foreach my $line_info (@chunk) {
5015                 my ($class, $line) = @$line_info;
5016
5017                 # print chunk headers
5018                 if ($class && $class eq 'chunk_header') {
5019                         print $line;
5020                         next;
5021                 }
5022
5023                 ## print from accumulator when type of class of lines change
5024                 # empty contents block on start rem/add block, or end of chunk
5025                 if (@ctx && (!$class || $class eq 'rem' || $class eq 'add')) {
5026                         print join '',
5027                                 '<div class="chunk_block ctx">',
5028                                         '<div class="old">',
5029                                         @ctx,
5030                                         '</div>',
5031                                         '<div class="new">',
5032                                         @ctx,
5033                                         '</div>',
5034                                 '</div>';
5035                         @ctx = ();
5036                 }
5037                 # empty add/rem block on start context block, or end of chunk
5038                 if ((@rem || @add) && (!$class || $class eq 'ctx')) {
5039                         if (!@add) {
5040                                 # pure removal
5041                                 print join '',
5042                                         '<div class="chunk_block rem">',
5043                                                 '<div class="old">',
5044                                                 @rem,
5045                                                 '</div>',
5046                                         '</div>';
5047                         } elsif (!@rem) {
5048                                 # pure addition
5049                                 print join '',
5050                                         '<div class="chunk_block add">',
5051                                                 '<div class="new">',
5052                                                 @add,
5053                                                 '</div>',
5054                                         '</div>';
5055                         } else {
5056                                 # assume that it is change
5057                                 print join '',
5058                                         '<div class="chunk_block chg">',
5059                                                 '<div class="old">',
5060                                                 @rem,
5061                                                 '</div>',
5062                                                 '<div class="new">',
5063                                                 @add,
5064                                                 '</div>',
5065                                         '</div>';
5066                         }
5067                         @rem = @add = ();
5068                 }
5069
5070                 ## adding lines to accumulator
5071                 # guardian value
5072                 last unless $line;
5073                 # rem, add or change
5074                 if ($class eq 'rem') {
5075                         push @rem, $line;
5076                 } elsif ($class eq 'add') {
5077                         push @add, $line;
5078                 }
5079                 # context line
5080                 if ($class eq 'ctx') {
5081                         push @ctx, $line;
5082                 }
5083         }
5084 }
5085
5086 sub git_patchset_body {
5087         my ($fd, $diff_style, $difftree, $hash, @hash_parents) = @_;
5088         my ($hash_parent) = $hash_parents[0];
5089
5090         my $is_combined = (@hash_parents > 1);
5091         my $patch_idx = 0;
5092         my $patch_number = 0;
5093         my $patch_line;
5094         my $diffinfo;
5095         my $to_name;
5096         my (%from, %to);
5097         my @chunk; # for side-by-side diff
5098
5099         print "<div class=\"patchset\">\n";
5100
5101         # skip to first patch
5102         while ($patch_line = <$fd>) {
5103                 chomp $patch_line;
5104
5105                 last if ($patch_line =~ m/^diff /);
5106         }
5107
5108  PATCH:
5109         while ($patch_line) {
5110
5111                 # parse "git diff" header line
5112                 if ($patch_line =~ m/^diff --git (\"(?:[^\\\"]*(?:\\.[^\\\"]*)*)\"|[^ "]*) (.*)$/) {
5113                         # $1 is from_name, which we do not use
5114                         $to_name = unquote($2);
5115                         $to_name =~ s!^b/!!;
5116                 } elsif ($patch_line =~ m/^diff --(cc|combined) ("?.*"?)$/) {
5117                         # $1 is 'cc' or 'combined', which we do not use
5118                         $to_name = unquote($2);
5119                 } else {
5120                         $to_name = undef;
5121                 }
5122
5123                 # check if current patch belong to current raw line
5124                 # and parse raw git-diff line if needed
5125                 if (is_patch_split($diffinfo, { 'to_file' => $to_name })) {
5126                         # this is continuation of a split patch
5127                         print "<div class=\"patch cont\">\n";
5128                 } else {
5129                         # advance raw git-diff output if needed
5130                         $patch_idx++ if defined $diffinfo;
5131
5132                         # read and prepare patch information
5133                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5134
5135                         # compact combined diff output can have some patches skipped
5136                         # find which patch (using pathname of result) we are at now;
5137                         if ($is_combined) {
5138                                 while ($to_name ne $diffinfo->{'to_file'}) {
5139                                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
5140                                               format_diff_cc_simplified($diffinfo, @hash_parents) .
5141                                               "</div>\n";  # class="patch"
5142
5143                                         $patch_idx++;
5144                                         $patch_number++;
5145
5146                                         last if $patch_idx > $#$difftree;
5147                                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5148                                 }
5149                         }
5150
5151                         # modifies %from, %to hashes
5152                         parse_from_to_diffinfo($diffinfo, \%from, \%to, @hash_parents);
5153
5154                         # this is first patch for raw difftree line with $patch_idx index
5155                         # we index @$difftree array from 0, but number patches from 1
5156                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n";
5157                 }
5158
5159                 # git diff header
5160                 #assert($patch_line =~ m/^diff /) if DEBUG;
5161                 #assert($patch_line !~ m!$/$!) if DEBUG; # is chomp-ed
5162                 $patch_number++;
5163                 # print "git diff" header
5164                 print format_git_diff_header_line($patch_line, $diffinfo,
5165                                                   \%from, \%to);
5166
5167                 # print extended diff header
5168                 print "<div class=\"diff extended_header\">\n";
5169         EXTENDED_HEADER:
5170                 while ($patch_line = <$fd>) {
5171                         chomp $patch_line;
5172
5173                         last EXTENDED_HEADER if ($patch_line =~ m/^--- |^diff /);
5174
5175                         print format_extended_diff_header_line($patch_line, $diffinfo,
5176                                                                \%from, \%to);
5177                 }
5178                 print "</div>\n"; # class="diff extended_header"
5179
5180                 # from-file/to-file diff header
5181                 if (! $patch_line) {
5182                         print "</div>\n"; # class="patch"
5183                         last PATCH;
5184                 }
5185                 next PATCH if ($patch_line =~ m/^diff /);
5186                 #assert($patch_line =~ m/^---/) if DEBUG;
5187
5188                 my $last_patch_line = $patch_line;
5189                 $patch_line = <$fd>;
5190                 chomp $patch_line;
5191                 #assert($patch_line =~ m/^\+\+\+/) if DEBUG;
5192
5193                 print format_diff_from_to_header($last_patch_line, $patch_line,
5194                                                  $diffinfo, \%from, \%to,
5195                                                  @hash_parents);
5196
5197                 # the patch itself
5198         LINE:
5199                 while ($patch_line = <$fd>) {
5200                         chomp $patch_line;
5201
5202                         next PATCH if ($patch_line =~ m/^diff /);
5203
5204                         my ($class, $line) = process_diff_line($patch_line, \%from, \%to);
5205                         my $diff_classes = "diff";
5206                         $diff_classes .= " $class" if ($class);
5207                         $line = "<div class=\"$diff_classes\">$line</div>\n";
5208
5209                         if ($diff_style eq 'sidebyside' && !$is_combined) {
5210                                 if ($class eq 'chunk_header') {
5211                                         print_sidebyside_diff_chunk(@chunk);
5212                                         @chunk = ( [ $class, $line ] );
5213                                 } else {
5214                                         push @chunk, [ $class, $line ];
5215                                 }
5216                         } else {
5217                                 # default 'inline' style and unknown styles
5218                                 print $line;
5219                         }
5220                 }
5221
5222         } continue {
5223                 if (@chunk) {
5224                         print_sidebyside_diff_chunk(@chunk);
5225                         @chunk = ();
5226                 }
5227                 print "</div>\n"; # class="patch"
5228         }
5229
5230         # for compact combined (--cc) format, with chunk and patch simplification
5231         # the patchset might be empty, but there might be unprocessed raw lines
5232         for (++$patch_idx if $patch_number > 0;
5233              $patch_idx < @$difftree;
5234              ++$patch_idx) {
5235                 # read and prepare patch information
5236                 $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5237
5238                 # generate anchor for "patch" links in difftree / whatchanged part
5239                 print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
5240                       format_diff_cc_simplified($diffinfo, @hash_parents) .
5241                       "</div>\n";  # class="patch"
5242
5243                 $patch_number++;
5244         }
5245
5246         if ($patch_number == 0) {
5247                 if (@hash_parents > 1) {
5248                         print "<div class=\"diff nodifferences\">Trivial merge</div>\n";
5249                 } else {
5250                         print "<div class=\"diff nodifferences\">No differences found</div>\n";
5251                 }
5252         }
5253
5254         print "</div>\n"; # class="patchset"
5255 }
5256
5257 # . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
5258
5259 sub git_project_search_form {
5260         my ($searchtext, $search_use_regexp);
5261
5262         my $limit = '';
5263         if ($project_filter) {
5264                 $limit = " in '$project_filter/'";
5265         }
5266
5267         print "<div class=\"projsearch\">\n";
5268         print $cgi->startform(-method => 'get', -action => $my_uri) .
5269               $cgi->hidden(-name => 'a', -value => 'project_list')  . "\n";
5270         print $cgi->hidden(-name => 'pf', -value => $project_filter). "\n"
5271                 if (defined $project_filter);
5272         print $cgi->textfield(-name => 's', -value => $searchtext,
5273                               -title => "Search project by name and description$limit",
5274                               -size => 60) . "\n" .
5275               "<span title=\"Extended regular expression\">" .
5276               $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
5277                              -checked => $search_use_regexp) .
5278               "</span>\n" .
5279               $cgi->submit(-name => 'btnS', -value => 'Search') .
5280               $cgi->end_form() . "\n" .
5281               $cgi->a({-href => href(project => undef, searchtext => undef,
5282                                      project_filter => $project_filter)},
5283                       esc_html("List all projects$limit")) . "<br />\n";
5284         print "</div>\n";
5285 }
5286
5287 # entry for given @keys needs filling if at least one of keys in list
5288 # is not present in %$project_info
5289 sub project_info_needs_filling {
5290         my ($project_info, @keys) = @_;
5291
5292         # return List::MoreUtils::any { !exists $project_info->{$_} } @keys;
5293         foreach my $key (@keys) {
5294                 if (!exists $project_info->{$key}) {
5295                         return 1;
5296                 }
5297         }
5298         return;
5299 }
5300
5301 # fills project list info (age, description, owner, category, forks, etc.)
5302 # for each project in the list, removing invalid projects from
5303 # returned list, or fill only specified info.
5304 #
5305 # Invalid projects are removed from the returned list if and only if you
5306 # ask 'age' or 'age_string' to be filled, because they are the only fields
5307 # that run unconditionally git command that requires repository, and
5308 # therefore do always check if project repository is invalid.
5309 #
5310 # USAGE:
5311 # * fill_project_list_info(\@project_list, 'descr_long', 'ctags')
5312 #   ensures that 'descr_long' and 'ctags' fields are filled
5313 # * @project_list = fill_project_list_info(\@project_list)
5314 #   ensures that all fields are filled (and invalid projects removed)
5315 #
5316 # NOTE: modifies $projlist, but does not remove entries from it
5317 sub fill_project_list_info {
5318         my ($projlist, @wanted_keys) = @_;
5319         my @projects;
5320         my $filter_set = sub { return @_; };
5321         if (@wanted_keys) {
5322                 my %wanted_keys = map { $_ => 1 } @wanted_keys;
5323                 $filter_set = sub { return grep { $wanted_keys{$_} } @_; };
5324         }
5325
5326         my $show_ctags = gitweb_check_feature('ctags');
5327  PROJECT:
5328         foreach my $pr (@$projlist) {
5329                 if (project_info_needs_filling($pr, $filter_set->('age', 'age_string'))) {
5330                         my (@activity) = git_get_last_activity($pr->{'path'});
5331                         unless (@activity) {
5332                                 next PROJECT;
5333                         }
5334                         ($pr->{'age'}, $pr->{'age_string'}) = @activity;
5335                 }
5336                 if (project_info_needs_filling($pr, $filter_set->('descr', 'descr_long'))) {
5337                         my $descr = git_get_project_description($pr->{'path'}) || "";
5338                         $descr = to_utf8($descr);
5339                         $pr->{'descr_long'} = $descr;
5340                         $pr->{'descr'} = chop_str($descr, $projects_list_description_width, 5);
5341                 }
5342                 if (project_info_needs_filling($pr, $filter_set->('owner'))) {
5343                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}") || "";
5344                 }
5345                 if ($show_ctags &&
5346                     project_info_needs_filling($pr, $filter_set->('ctags'))) {
5347                         $pr->{'ctags'} = git_get_project_ctags($pr->{'path'});
5348                 }
5349                 if ($projects_list_group_categories &&
5350                     project_info_needs_filling($pr, $filter_set->('category'))) {
5351                         my $cat = git_get_project_category($pr->{'path'}) ||
5352                                                            $project_list_default_category;
5353                         $pr->{'category'} = to_utf8($cat);
5354                 }
5355
5356                 push @projects, $pr;
5357         }
5358
5359         return @projects;
5360 }
5361
5362 sub sort_projects_list {
5363         my ($projlist, $order) = @_;
5364         my @projects;
5365
5366         my %order_info = (
5367                 project => { key => 'path', type => 'str' },
5368                 descr => { key => 'descr_long', type => 'str' },
5369                 owner => { key => 'owner', type => 'str' },
5370                 age => { key => 'age', type => 'num' }
5371         );
5372         my $oi = $order_info{$order};
5373         return @$projlist unless defined $oi;
5374         if ($oi->{'type'} eq 'str') {
5375                 @projects = sort {$a->{$oi->{'key'}} cmp $b->{$oi->{'key'}}} @$projlist;
5376         } else {
5377                 @projects = sort {$a->{$oi->{'key'}} <=> $b->{$oi->{'key'}}} @$projlist;
5378         }
5379
5380         return @projects;
5381 }
5382
5383 # returns a hash of categories, containing the list of project
5384 # belonging to each category
5385 sub build_projlist_by_category {
5386         my ($projlist, $from, $to) = @_;
5387         my %categories;
5388
5389         $from = 0 unless defined $from;
5390         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5391
5392         for (my $i = $from; $i <= $to; $i++) {
5393                 my $pr = $projlist->[$i];
5394                 push @{$categories{ $pr->{'category'} }}, $pr;
5395         }
5396
5397         return wantarray ? %categories : \%categories;
5398 }
5399
5400 # print 'sort by' <th> element, generating 'sort by $name' replay link
5401 # if that order is not selected
5402 sub print_sort_th {
5403         print format_sort_th(@_);
5404 }
5405
5406 sub format_sort_th {
5407         my ($name, $order, $header) = @_;
5408         my $sort_th = "";
5409         $header ||= ucfirst($name);
5410
5411         if ($order eq $name) {
5412                 $sort_th .= "<th>$header</th>\n";
5413         } else {
5414                 $sort_th .= "<th>" .
5415                             $cgi->a({-href => href(-replay=>1, order=>$name),
5416                                      -class => "header"}, $header) .
5417                             "</th>\n";
5418         }
5419
5420         return $sort_th;
5421 }
5422
5423 sub git_project_list_rows {
5424         my ($projlist, $from, $to, $check_forks) = @_;
5425
5426         $from = 0 unless defined $from;
5427         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5428
5429         my $alternate = 1;
5430         for (my $i = $from; $i <= $to; $i++) {
5431                 my $pr = $projlist->[$i];
5432
5433                 if ($alternate) {
5434                         print "<tr class=\"dark\">\n";
5435                 } else {
5436                         print "<tr class=\"light\">\n";
5437                 }
5438                 $alternate ^= 1;
5439
5440                 if ($check_forks) {
5441                         print "<td>";
5442                         if ($pr->{'forks'}) {
5443                                 my $nforks = scalar @{$pr->{'forks'}};
5444                                 if ($nforks > 0) {
5445                                         print $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks"),
5446                                                        -title => "$nforks forks"}, "+");
5447                                 } else {
5448                                         print $cgi->span({-title => "$nforks forks"}, "+");
5449                                 }
5450                         }
5451                         print "</td>\n";
5452                 }
5453                 print "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5454                                         -class => "list"},
5455                                        esc_html_match_hl($pr->{'path'}, $search_regexp)) .
5456                       "</td>\n" .
5457                       "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5458                                         -class => "list",
5459                                         -title => $pr->{'descr_long'}},
5460                                         $search_regexp
5461                                         ? esc_html_match_hl_chopped($pr->{'descr_long'},
5462                                                                     $pr->{'descr'}, $search_regexp)
5463                                         : esc_html($pr->{'descr'})) .
5464                       "</td>\n" .
5465                       "<td><i>" . chop_and_escape_str($pr->{'owner'}, 15) . "</i></td>\n";
5466                 print "<td class=\"". age_class($pr->{'age'}) . "\">" .
5467                       (defined $pr->{'age_string'} ? $pr->{'age_string'} : "No commits") . "</td>\n" .
5468                       "<td class=\"link\">" .
5469                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary")}, "summary")   . " | " .
5470                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"shortlog")}, "shortlog") . " | " .
5471                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"log")}, "log") . " | " .
5472                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"tree")}, "tree") .
5473                       ($pr->{'forks'} ? " | " . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "forks") : '') .
5474                       "</td>\n" .
5475                       "</tr>\n";
5476         }
5477 }
5478
5479 sub git_project_list_body {
5480         # actually uses global variable $project
5481         my ($projlist, $order, $from, $to, $extra, $no_header) = @_;
5482         my @projects = @$projlist;
5483
5484         my $check_forks = gitweb_check_feature('forks');
5485         my $show_ctags  = gitweb_check_feature('ctags');
5486         my $tagfilter = $show_ctags ? $input_params{'ctag'} : undef;
5487         $check_forks = undef
5488                 if ($tagfilter || $searchtext);
5489
5490         # filtering out forks before filling info allows to do less work
5491         @projects = filter_forks_from_projects_list(\@projects)
5492                 if ($check_forks);
5493         # search_projects_list pre-fills required info
5494         @projects = search_projects_list(\@projects,
5495                                          'searchtext' => $searchtext,
5496                                          'tagfilter'  => $tagfilter)
5497                 if ($tagfilter || $searchtext);
5498         # fill the rest
5499         @projects = fill_project_list_info(\@projects);
5500
5501         $order ||= $default_projects_order;
5502         $from = 0 unless defined $from;
5503         $to = $#projects if (!defined $to || $#projects < $to);
5504
5505         # short circuit
5506         if ($from > $to) {
5507                 print "<center>\n".
5508                       "<b>No such projects found</b><br />\n".
5509                       "Click ".$cgi->a({-href=>href(project=>undef)},"here")." to view all projects<br />\n".
5510                       "</center>\n<br />\n";
5511                 return;
5512         }
5513
5514         @projects = sort_projects_list(\@projects, $order);
5515
5516         if ($show_ctags) {
5517                 my $ctags = git_gather_all_ctags(\@projects);
5518                 my $cloud = git_populate_project_tagcloud($ctags);
5519                 print git_show_project_tagcloud($cloud, 64);
5520         }
5521
5522         print "<table class=\"project_list\">\n";
5523         unless ($no_header) {
5524                 print "<tr>\n";
5525                 if ($check_forks) {
5526                         print "<th></th>\n";
5527                 }
5528                 print_sort_th('project', $order, 'Project');
5529                 print_sort_th('descr', $order, 'Description');
5530                 print_sort_th('owner', $order, 'Owner');
5531                 print_sort_th('age', $order, 'Last Change');
5532                 print "<th></th>\n" . # for links
5533                       "</tr>\n";
5534         }
5535
5536         if ($projects_list_group_categories) {
5537                 # only display categories with projects in the $from-$to window
5538                 @projects = sort {$a->{'category'} cmp $b->{'category'}} @projects[$from..$to];
5539                 my %categories = build_projlist_by_category(\@projects, $from, $to);
5540                 foreach my $cat (sort keys %categories) {
5541                         unless ($cat eq "") {
5542                                 print "<tr>\n";
5543                                 if ($check_forks) {
5544                                         print "<td></td>\n";
5545                                 }
5546                                 print "<td class=\"category\" colspan=\"5\">".esc_html($cat)."</td>\n";
5547                                 print "</tr>\n";
5548                         }
5549
5550                         git_project_list_rows($categories{$cat}, undef, undef, $check_forks);
5551                 }
5552         } else {
5553                 git_project_list_rows(\@projects, $from, $to, $check_forks);
5554         }
5555
5556         if (defined $extra) {
5557                 print "<tr>\n";
5558                 if ($check_forks) {
5559                         print "<td></td>\n";
5560                 }
5561                 print "<td colspan=\"5\">$extra</td>\n" .
5562                       "</tr>\n";
5563         }
5564         print "</table>\n";
5565 }
5566
5567 sub git_log_body {
5568         # uses global variable $project
5569         my ($commitlist, $from, $to, $refs, $extra) = @_;
5570
5571         $from = 0 unless defined $from;
5572         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5573
5574         for (my $i = 0; $i <= $to; $i++) {
5575                 my %co = %{$commitlist->[$i]};
5576                 next if !%co;
5577                 my $commit = $co{'id'};
5578                 my $ref = format_ref_marker($refs, $commit);
5579                 git_print_header_div('commit',
5580                                "<span class=\"age\">$co{'age_string'}</span>" .
5581                                esc_html($co{'title'}) . $ref,
5582                                $commit);
5583                 print "<div class=\"title_text\">\n" .
5584                       "<div class=\"log_link\">\n" .
5585                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") .
5586                       " | " .
5587                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") .
5588                       " | " .
5589                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree") .
5590                       "<br/>\n" .
5591                       "</div>\n";
5592                       git_print_authorship(\%co, -tag => 'span');
5593                       print "<br/>\n</div>\n";
5594
5595                 print "<div class=\"log_body\">\n";
5596                 git_print_log($co{'comment'}, -final_empty_line=> 1);
5597                 print "</div>\n";
5598         }
5599         if ($extra) {
5600                 print "<div class=\"page_nav\">\n";
5601                 print "$extra\n";
5602                 print "</div>\n";
5603         }
5604 }
5605
5606 sub git_shortlog_body {
5607         # uses global variable $project
5608         my ($commitlist, $from, $to, $refs, $extra) = @_;
5609
5610         $from = 0 unless defined $from;
5611         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5612
5613         print "<table class=\"shortlog\">\n";
5614         my $alternate = 1;
5615         for (my $i = $from; $i <= $to; $i++) {
5616                 my %co = %{$commitlist->[$i]};
5617                 my $commit = $co{'id'};
5618                 my $ref = format_ref_marker($refs, $commit);
5619                 if ($alternate) {
5620                         print "<tr class=\"dark\">\n";
5621                 } else {
5622                         print "<tr class=\"light\">\n";
5623                 }
5624                 $alternate ^= 1;
5625                 # git_summary() used print "<td><i>$co{'age_string'}</i></td>\n" .
5626                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5627                       format_author_html('td', \%co, 10) . "<td>";
5628                 print format_subject_html($co{'title'}, $co{'title_short'},
5629                                           href(action=>"commit", hash=>$commit), $ref);
5630                 print "</td>\n" .
5631                       "<td class=\"link\">" .
5632                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") . " | " .
5633                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") . " | " .
5634                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree");
5635                 my $snapshot_links = format_snapshot_links($commit);
5636                 if (defined $snapshot_links) {
5637                         print " | " . $snapshot_links;
5638                 }
5639                 print "</td>\n" .
5640                       "</tr>\n";
5641         }
5642         if (defined $extra) {
5643                 print "<tr>\n" .
5644                       "<td colspan=\"4\">$extra</td>\n" .
5645                       "</tr>\n";
5646         }
5647         print "</table>\n";
5648 }
5649
5650 sub git_history_body {
5651         # Warning: assumes constant type (blob or tree) during history
5652         my ($commitlist, $from, $to, $refs, $extra,
5653             $file_name, $file_hash, $ftype) = @_;
5654
5655         $from = 0 unless defined $from;
5656         $to = $#{$commitlist} unless (defined $to && $to <= $#{$commitlist});
5657
5658         print "<table class=\"history\">\n";
5659         my $alternate = 1;
5660         for (my $i = $from; $i <= $to; $i++) {
5661                 my %co = %{$commitlist->[$i]};
5662                 if (!%co) {
5663                         next;
5664                 }
5665                 my $commit = $co{'id'};
5666
5667                 my $ref = format_ref_marker($refs, $commit);
5668
5669                 if ($alternate) {
5670                         print "<tr class=\"dark\">\n";
5671                 } else {
5672                         print "<tr class=\"light\">\n";
5673                 }
5674                 $alternate ^= 1;
5675                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5676         # shortlog:   format_author_html('td', \%co, 10)
5677                       format_author_html('td', \%co, 15, 3) . "<td>";
5678                 # originally git_history used chop_str($co{'title'}, 50)
5679                 print format_subject_html($co{'title'}, $co{'title_short'},
5680                                           href(action=>"commit", hash=>$commit), $ref);
5681                 print "</td>\n" .
5682                       "<td class=\"link\">" .
5683                       $cgi->a({-href => href(action=>$ftype, hash_base=>$commit, file_name=>$file_name)}, $ftype) . " | " .
5684                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff");
5685
5686                 if ($ftype eq 'blob') {
5687                         my $blob_current = $file_hash;
5688                         my $blob_parent  = git_get_hash_by_path($commit, $file_name);
5689                         if (defined $blob_current && defined $blob_parent &&
5690                                         $blob_current ne $blob_parent) {
5691                                 print " | " .
5692                                         $cgi->a({-href => href(action=>"blobdiff",
5693                                                                hash=>$blob_current, hash_parent=>$blob_parent,
5694                                                                hash_base=>$hash_base, hash_parent_base=>$commit,
5695                                                                file_name=>$file_name)},
5696                                                 "diff to current");
5697                         }
5698                 }
5699                 print "</td>\n" .
5700                       "</tr>\n";
5701         }
5702         if (defined $extra) {
5703                 print "<tr>\n" .
5704                       "<td colspan=\"4\">$extra</td>\n" .
5705                       "</tr>\n";
5706         }
5707         print "</table>\n";
5708 }
5709
5710 sub git_tags_body {
5711         # uses global variable $project
5712         my ($taglist, $from, $to, $extra) = @_;
5713         $from = 0 unless defined $from;
5714         $to = $#{$taglist} if (!defined $to || $#{$taglist} < $to);
5715
5716         print "<table class=\"tags\">\n";
5717         my $alternate = 1;
5718         for (my $i = $from; $i <= $to; $i++) {
5719                 my $entry = $taglist->[$i];
5720                 my %tag = %$entry;
5721                 my $comment = $tag{'subject'};
5722                 my $comment_short;
5723                 if (defined $comment) {
5724                         $comment_short = chop_str($comment, 30, 5);
5725                 }
5726                 if ($alternate) {
5727                         print "<tr class=\"dark\">\n";
5728                 } else {
5729                         print "<tr class=\"light\">\n";
5730                 }
5731                 $alternate ^= 1;
5732                 if (defined $tag{'age'}) {
5733                         print "<td><i>$tag{'age'}</i></td>\n";
5734                 } else {
5735                         print "<td></td>\n";
5736                 }
5737                 print "<td>" .
5738                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'}),
5739                                -class => "list name"}, esc_html($tag{'name'})) .
5740                       "</td>\n" .
5741                       "<td>";
5742                 if (defined $comment) {
5743                         print format_subject_html($comment, $comment_short,
5744                                                   href(action=>"tag", hash=>$tag{'id'}));
5745                 }
5746                 print "</td>\n" .
5747                       "<td class=\"selflink\">";
5748                 if ($tag{'type'} eq "tag") {
5749                         print $cgi->a({-href => href(action=>"tag", hash=>$tag{'id'})}, "tag");
5750                 } else {
5751                         print "&nbsp;";
5752                 }
5753                 print "</td>\n" .
5754                       "<td class=\"link\">" . " | " .
5755                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'})}, $tag{'reftype'});
5756                 if ($tag{'reftype'} eq "commit") {
5757                         print " | " . $cgi->a({-href => href(action=>"shortlog", hash=>$tag{'fullname'})}, "shortlog") .
5758                               " | " . $cgi->a({-href => href(action=>"log", hash=>$tag{'fullname'})}, "log");
5759                 } elsif ($tag{'reftype'} eq "blob") {
5760                         print " | " . $cgi->a({-href => href(action=>"blob_plain", hash=>$tag{'refid'})}, "raw");
5761                 }
5762                 print "</td>\n" .
5763                       "</tr>";
5764         }
5765         if (defined $extra) {
5766                 print "<tr>\n" .
5767                       "<td colspan=\"5\">$extra</td>\n" .
5768                       "</tr>\n";
5769         }
5770         print "</table>\n";
5771 }
5772
5773 sub git_heads_body {
5774         # uses global variable $project
5775         my ($headlist, $head_at, $from, $to, $extra) = @_;
5776         $from = 0 unless defined $from;
5777         $to = $#{$headlist} if (!defined $to || $#{$headlist} < $to);
5778
5779         print "<table class=\"heads\">\n";
5780         my $alternate = 1;
5781         for (my $i = $from; $i <= $to; $i++) {
5782                 my $entry = $headlist->[$i];
5783                 my %ref = %$entry;
5784                 my $curr = defined $head_at && $ref{'id'} eq $head_at;
5785                 if ($alternate) {
5786                         print "<tr class=\"dark\">\n";
5787                 } else {
5788                         print "<tr class=\"light\">\n";
5789                 }
5790                 $alternate ^= 1;
5791                 print "<td><i>$ref{'age'}</i></td>\n" .
5792                       ($curr ? "<td class=\"current_head\">" : "<td>") .
5793                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'}),
5794                                -class => "list name"},esc_html($ref{'name'})) .
5795                       "</td>\n" .
5796                       "<td class=\"link\">" .
5797                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'})}, "shortlog") . " | " .
5798                       $cgi->a({-href => href(action=>"log", hash=>$ref{'fullname'})}, "log") . " | " .
5799                       $cgi->a({-href => href(action=>"tree", hash=>$ref{'fullname'}, hash_base=>$ref{'fullname'})}, "tree") .
5800                       "</td>\n" .
5801                       "</tr>";
5802         }
5803         if (defined $extra) {
5804                 print "<tr>\n" .
5805                       "<td colspan=\"3\">$extra</td>\n" .
5806                       "</tr>\n";
5807         }
5808         print "</table>\n";
5809 }
5810
5811 # Display a single remote block
5812 sub git_remote_block {
5813         my ($remote, $rdata, $limit, $head) = @_;
5814
5815         my $heads = $rdata->{'heads'};
5816         my $fetch = $rdata->{'fetch'};
5817         my $push = $rdata->{'push'};
5818
5819         my $urls_table = "<table class=\"projects_list\">\n" ;
5820
5821         if (defined $fetch) {
5822                 if ($fetch eq $push) {
5823                         $urls_table .= format_repo_url("URL", $fetch);
5824                 } else {
5825                         $urls_table .= format_repo_url("Fetch URL", $fetch);
5826                         $urls_table .= format_repo_url("Push URL", $push) if defined $push;
5827                 }
5828         } elsif (defined $push) {
5829                 $urls_table .= format_repo_url("Push URL", $push);
5830         } else {
5831                 $urls_table .= format_repo_url("", "No remote URL");
5832         }
5833
5834         $urls_table .= "</table>\n";
5835
5836         my $dots;
5837         if (defined $limit && $limit < @$heads) {
5838                 $dots = $cgi->a({-href => href(action=>"remotes", hash=>$remote)}, "...");
5839         }
5840
5841         print $urls_table;
5842         git_heads_body($heads, $head, 0, $limit, $dots);
5843 }
5844
5845 # Display a list of remote names with the respective fetch and push URLs
5846 sub git_remotes_list {
5847         my ($remotedata, $limit) = @_;
5848         print "<table class=\"heads\">\n";
5849         my $alternate = 1;
5850         my @remotes = sort keys %$remotedata;
5851
5852         my $limited = $limit && $limit < @remotes;
5853
5854         $#remotes = $limit - 1 if $limited;
5855
5856         while (my $remote = shift @remotes) {
5857                 my $rdata = $remotedata->{$remote};
5858                 my $fetch = $rdata->{'fetch'};
5859                 my $push = $rdata->{'push'};
5860                 if ($alternate) {
5861                         print "<tr class=\"dark\">\n";
5862                 } else {
5863                         print "<tr class=\"light\">\n";
5864                 }
5865                 $alternate ^= 1;
5866                 print "<td>" .
5867                       $cgi->a({-href=> href(action=>'remotes', hash=>$remote),
5868                                -class=> "list name"},esc_html($remote)) .
5869                       "</td>";
5870                 print "<td class=\"link\">" .
5871                       (defined $fetch ? $cgi->a({-href=> $fetch}, "fetch") : "fetch") .
5872                       " | " .
5873                       (defined $push ? $cgi->a({-href=> $push}, "push") : "push") .
5874                       "</td>";
5875
5876                 print "</tr>\n";
5877         }
5878
5879         if ($limited) {
5880                 print "<tr>\n" .
5881                       "<td colspan=\"3\">" .
5882                       $cgi->a({-href => href(action=>"remotes")}, "...") .
5883                       "</td>\n" . "</tr>\n";
5884         }
5885
5886         print "</table>";
5887 }
5888
5889 # Display remote heads grouped by remote, unless there are too many
5890 # remotes, in which case we only display the remote names
5891 sub git_remotes_body {
5892         my ($remotedata, $limit, $head) = @_;
5893         if ($limit and $limit < keys %$remotedata) {
5894                 git_remotes_list($remotedata, $limit);
5895         } else {
5896                 fill_remote_heads($remotedata);
5897                 while (my ($remote, $rdata) = each %$remotedata) {
5898                         git_print_section({-class=>"remote", -id=>$remote},
5899                                 ["remotes", $remote, $remote], sub {
5900                                         git_remote_block($remote, $rdata, $limit, $head);
5901                                 });
5902                 }
5903         }
5904 }
5905
5906 sub git_search_message {
5907         my %co = @_;
5908
5909         my $greptype;
5910         if ($searchtype eq 'commit') {
5911                 $greptype = "--grep=";
5912         } elsif ($searchtype eq 'author') {
5913                 $greptype = "--author=";
5914         } elsif ($searchtype eq 'committer') {
5915                 $greptype = "--committer=";
5916         }
5917         $greptype .= $searchtext;
5918         my @commitlist = parse_commits($hash, 101, (100 * $page), undef,
5919                                        $greptype, '--regexp-ignore-case',
5920                                        $search_use_regexp ? '--extended-regexp' : '--fixed-strings');
5921
5922         my $paging_nav = '';
5923         if ($page > 0) {
5924                 $paging_nav .=
5925                         $cgi->a({-href => href(-replay=>1, page=>undef)},
5926                                 "first") .
5927                         " &sdot; " .
5928                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
5929                                  -accesskey => "p", -title => "Alt-p"}, "prev");
5930         } else {
5931                 $paging_nav .= "first &sdot; prev";
5932         }
5933         my $next_link = '';
5934         if ($#commitlist >= 100) {
5935                 $next_link =
5936                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
5937                                  -accesskey => "n", -title => "Alt-n"}, "next");
5938                 $paging_nav .= " &sdot; $next_link";
5939         } else {
5940                 $paging_nav .= " &sdot; next";
5941         }
5942
5943         git_header_html();
5944
5945         git_print_page_nav('','', $hash,$co{'tree'},$hash, $paging_nav);
5946         git_print_header_div('commit', esc_html($co{'title'}), $hash);
5947         if ($page == 0 && !@commitlist) {
5948                 print "<p>No match.</p>\n";
5949         } else {
5950                 git_search_grep_body(\@commitlist, 0, 99, $next_link);
5951         }
5952
5953         git_footer_html();
5954 }
5955
5956 sub git_search_changes {
5957         my %co = @_;
5958
5959         local $/ = "\n";
5960         open my $fd, '-|', git_cmd(), '--no-pager', 'log', @diff_opts,
5961                 '--pretty=format:%H', '--no-abbrev', '--raw', "-S$searchtext",
5962                 ($search_use_regexp ? '--pickaxe-regex' : ())
5963                         or die_error(500, "Open git-log failed");
5964
5965         git_header_html();
5966
5967         git_print_page_nav('','', $hash,$co{'tree'},$hash);
5968         git_print_header_div('commit', esc_html($co{'title'}), $hash);
5969
5970         print "<table class=\"pickaxe search\">\n";
5971         my $alternate = 1;
5972         undef %co;
5973         my @files;
5974         while (my $line = <$fd>) {
5975                 chomp $line;
5976                 next unless $line;
5977
5978                 my %set = parse_difftree_raw_line($line);
5979                 if (defined $set{'commit'}) {
5980                         # finish previous commit
5981                         if (%co) {
5982                                 print "</td>\n" .
5983                                       "<td class=\"link\">" .
5984                                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
5985                                               "commit") .
5986                                       " | " .
5987                                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
5988                                                              hash_base=>$co{'id'})},
5989                                               "tree") .
5990                                       "</td>\n" .
5991                                       "</tr>\n";
5992                         }
5993
5994                         if ($alternate) {
5995                                 print "<tr class=\"dark\">\n";
5996                         } else {
5997                                 print "<tr class=\"light\">\n";
5998                         }
5999                         $alternate ^= 1;
6000                         %co = parse_commit($set{'commit'});
6001                         my $author = chop_and_escape_str($co{'author_name'}, 15, 5);
6002                         print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6003                               "<td><i>$author</i></td>\n" .
6004                               "<td>" .
6005                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
6006                                       -class => "list subject"},
6007                                       chop_and_escape_str($co{'title'}, 50) . "<br/>");
6008                 } elsif (defined $set{'to_id'}) {
6009                         next if ($set{'to_id'} =~ m/^0{40}$/);
6010
6011                         print $cgi->a({-href => href(action=>"blob", hash_base=>$co{'id'},
6012                                                      hash=>$set{'to_id'}, file_name=>$set{'to_file'}),
6013                                       -class => "list"},
6014                                       "<span class=\"match\">" . esc_path($set{'file'}) . "</span>") .
6015                               "<br/>\n";
6016                 }
6017         }
6018         close $fd;
6019
6020         # finish last commit (warning: repetition!)
6021         if (%co) {
6022                 print "</td>\n" .
6023                       "<td class=\"link\">" .
6024                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
6025                               "commit") .
6026                       " | " .
6027                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
6028                                              hash_base=>$co{'id'})},
6029                               "tree") .
6030                       "</td>\n" .
6031                       "</tr>\n";
6032         }
6033
6034         print "</table>\n";
6035
6036         git_footer_html();
6037 }
6038
6039 sub git_search_files {
6040         my %co = @_;
6041
6042         local $/ = "\n";
6043         open my $fd, "-|", git_cmd(), 'grep', '-n', '-z',
6044                 $search_use_regexp ? ('-E', '-i') : '-F',
6045                 $searchtext, $co{'tree'}
6046                         or die_error(500, "Open git-grep failed");
6047
6048         git_header_html();
6049
6050         git_print_page_nav('','', $hash,$co{'tree'},$hash);
6051         git_print_header_div('commit', esc_html($co{'title'}), $hash);
6052
6053         print "<table class=\"grep_search\">\n";
6054         my $alternate = 1;
6055         my $matches = 0;
6056         my $lastfile = '';
6057         my $file_href;
6058         while (my $line = <$fd>) {
6059                 chomp $line;
6060                 my ($file, $lno, $ltext, $binary);
6061                 last if ($matches++ > 1000);
6062                 if ($line =~ /^Binary file (.+) matches$/) {
6063                         $file = $1;
6064                         $binary = 1;
6065                 } else {
6066                         ($file, $lno, $ltext) = split(/\0/, $line, 3);
6067                         $file =~ s/^$co{'tree'}://;
6068                 }
6069                 if ($file ne $lastfile) {
6070                         $lastfile and print "</td></tr>\n";
6071                         if ($alternate++) {
6072                                 print "<tr class=\"dark\">\n";
6073                         } else {
6074                                 print "<tr class=\"light\">\n";
6075                         }
6076                         $file_href = href(action=>"blob", hash_base=>$co{'id'},
6077                                           file_name=>$file);
6078                         print "<td class=\"list\">".
6079                                 $cgi->a({-href => $file_href, -class => "list"}, esc_path($file));
6080                         print "</td><td>\n";
6081                         $lastfile = $file;
6082                 }
6083                 if ($binary) {
6084                         print "<div class=\"binary\">Binary file</div>\n";
6085                 } else {
6086                         $ltext = untabify($ltext);
6087                         if ($ltext =~ m/^(.*)($search_regexp)(.*)$/i) {
6088                                 $ltext = esc_html($1, -nbsp=>1);
6089                                 $ltext .= '<span class="match">';
6090                                 $ltext .= esc_html($2, -nbsp=>1);
6091                                 $ltext .= '</span>';
6092                                 $ltext .= esc_html($3, -nbsp=>1);
6093                         } else {
6094                                 $ltext = esc_html($ltext, -nbsp=>1);
6095                         }
6096                         print "<div class=\"pre\">" .
6097                                 $cgi->a({-href => $file_href.'#l'.$lno,
6098                                         -class => "linenr"}, sprintf('%4i', $lno)) .
6099                                 ' ' .  $ltext . "</div>\n";
6100                 }
6101         }
6102         if ($lastfile) {
6103                 print "</td></tr>\n";
6104                 if ($matches > 1000) {
6105                         print "<div class=\"diff nodifferences\">Too many matches, listing trimmed</div>\n";
6106                 }
6107         } else {
6108                 print "<div class=\"diff nodifferences\">No matches found</div>\n";
6109         }
6110         close $fd;
6111
6112         print "</table>\n";
6113
6114         git_footer_html();
6115 }
6116
6117 sub git_search_grep_body {
6118         my ($commitlist, $from, $to, $extra) = @_;
6119         $from = 0 unless defined $from;
6120         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
6121
6122         print "<table class=\"commit_search\">\n";
6123         my $alternate = 1;
6124         for (my $i = $from; $i <= $to; $i++) {
6125                 my %co = %{$commitlist->[$i]};
6126                 if (!%co) {
6127                         next;
6128                 }
6129                 my $commit = $co{'id'};
6130                 if ($alternate) {
6131                         print "<tr class=\"dark\">\n";
6132                 } else {
6133                         print "<tr class=\"light\">\n";
6134                 }
6135                 $alternate ^= 1;
6136                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6137                       format_author_html('td', \%co, 15, 5) .
6138                       "<td>" .
6139                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
6140                                -class => "list subject"},
6141                               chop_and_escape_str($co{'title'}, 50) . "<br/>");
6142                 my $comment = $co{'comment'};
6143                 foreach my $line (@$comment) {
6144                         if ($line =~ m/^(.*?)($search_regexp)(.*)$/i) {
6145                                 my ($lead, $match, $trail) = ($1, $2, $3);
6146                                 $match = chop_str($match, 70, 5, 'center');
6147                                 my $contextlen = int((80 - length($match))/2);
6148                                 $contextlen = 30 if ($contextlen > 30);
6149                                 $lead  = chop_str($lead,  $contextlen, 10, 'left');
6150                                 $trail = chop_str($trail, $contextlen, 10, 'right');
6151
6152                                 $lead  = esc_html($lead);
6153                                 $match = esc_html($match);
6154                                 $trail = esc_html($trail);
6155
6156                                 print "$lead<span class=\"match\">$match</span>$trail<br />";
6157                         }
6158                 }
6159                 print "</td>\n" .
6160                       "<td class=\"link\">" .
6161                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
6162                       " | " .
6163                       $cgi->a({-href => href(action=>"commitdiff", hash=>$co{'id'})}, "commitdiff") .
6164                       " | " .
6165                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
6166                 print "</td>\n" .
6167                       "</tr>\n";
6168         }
6169         if (defined $extra) {
6170                 print "<tr>\n" .
6171                       "<td colspan=\"3\">$extra</td>\n" .
6172                       "</tr>\n";
6173         }
6174         print "</table>\n";
6175 }
6176
6177 ## ======================================================================
6178 ## ======================================================================
6179 ## actions
6180
6181 sub git_project_list {
6182         my $order = $input_params{'order'};
6183         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
6184                 die_error(400, "Unknown order parameter");
6185         }
6186
6187         my @list = git_get_projects_list($project_filter, $strict_export);
6188         if (!@list) {
6189                 die_error(404, "No projects found");
6190         }
6191
6192         git_header_html();
6193         if (defined $home_text && -f $home_text) {
6194                 print "<div class=\"index_include\">\n";
6195                 insert_file($home_text);
6196                 print "</div>\n";
6197         }
6198
6199         git_project_search_form($searchtext, $search_use_regexp);
6200         git_project_list_body(\@list, $order);
6201         git_footer_html();
6202 }
6203
6204 sub git_forks {
6205         my $order = $input_params{'order'};
6206         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
6207                 die_error(400, "Unknown order parameter");
6208         }
6209
6210         my $filter = $project;
6211         $filter =~ s/\.git$//;
6212         my @list = git_get_projects_list($filter);
6213         if (!@list) {
6214                 die_error(404, "No forks found");
6215         }
6216
6217         git_header_html();
6218         git_print_page_nav('','');
6219         git_print_header_div('summary', "$project forks");
6220         git_project_list_body(\@list, $order);
6221         git_footer_html();
6222 }
6223
6224 sub git_project_index {
6225         my @projects = git_get_projects_list($project_filter, $strict_export);
6226         if (!@projects) {
6227                 die_error(404, "No projects found");
6228         }
6229
6230         print $cgi->header(
6231                 -type => 'text/plain',
6232                 -charset => 'utf-8',
6233                 -content_disposition => 'inline; filename="index.aux"');
6234
6235         foreach my $pr (@projects) {
6236                 if (!exists $pr->{'owner'}) {
6237                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}");
6238                 }
6239
6240                 my ($path, $owner) = ($pr->{'path'}, $pr->{'owner'});
6241                 # quote as in CGI::Util::encode, but keep the slash, and use '+' for ' '
6242                 $path  =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
6243                 $owner =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
6244                 $path  =~ s/ /\+/g;
6245                 $owner =~ s/ /\+/g;
6246
6247                 print "$path $owner\n";
6248         }
6249 }
6250
6251 sub git_summary {
6252         my $descr = git_get_project_description($project) || "none";
6253         my %co = parse_commit("HEAD");
6254         my %cd = %co ? parse_date($co{'committer_epoch'}, $co{'committer_tz'}) : ();
6255         my $head = $co{'id'};
6256         my $remote_heads = gitweb_check_feature('remote_heads');
6257
6258         my $owner = git_get_project_owner($project);
6259
6260         my $refs = git_get_references();
6261         # These get_*_list functions return one more to allow us to see if
6262         # there are more ...
6263         my @taglist  = git_get_tags_list(16);
6264         my @headlist = git_get_heads_list(16);
6265         my %remotedata = $remote_heads ? git_get_remotes_list() : ();
6266         my @forklist;
6267         my $check_forks = gitweb_check_feature('forks');
6268
6269         if ($check_forks) {
6270                 # find forks of a project
6271                 my $filter = $project;
6272                 $filter =~ s/\.git$//;
6273                 @forklist = git_get_projects_list($filter);
6274                 # filter out forks of forks
6275                 @forklist = filter_forks_from_projects_list(\@forklist)
6276                         if (@forklist);
6277         }
6278
6279         git_header_html();
6280         git_print_page_nav('summary','', $head);
6281
6282         print "<div class=\"title\">&nbsp;</div>\n";
6283         print "<table class=\"projects_list\">\n" .
6284               "<tr id=\"metadata_desc\"><td>description</td><td>" . esc_html($descr) . "</td></tr>\n" .
6285               "<tr id=\"metadata_owner\"><td>owner</td><td>" . esc_html($owner) . "</td></tr>\n";
6286         if (defined $cd{'rfc2822'}) {
6287                 print "<tr id=\"metadata_lchange\"><td>last change</td>" .
6288                       "<td>".format_timestamp_html(\%cd)."</td></tr>\n";
6289         }
6290
6291         # use per project git URL list in $projectroot/$project/cloneurl
6292         # or make project git URL from git base URL and project name
6293         my $url_tag = "URL";
6294         my @url_list = git_get_project_url_list($project);
6295         @url_list = map { "$_/$project" } @git_base_url_list unless @url_list;
6296         foreach my $git_url (@url_list) {
6297                 next unless $git_url;
6298                 print format_repo_url($url_tag, $git_url);
6299                 $url_tag = "";
6300         }
6301
6302         # Tag cloud
6303         my $show_ctags = gitweb_check_feature('ctags');
6304         if ($show_ctags) {
6305                 my $ctags = git_get_project_ctags($project);
6306                 if (%$ctags) {
6307                         # without ability to add tags, don't show if there are none
6308                         my $cloud = git_populate_project_tagcloud($ctags);
6309                         print "<tr id=\"metadata_ctags\">" .
6310                               "<td>content tags</td>" .
6311                               "<td>".git_show_project_tagcloud($cloud, 48)."</td>" .
6312                               "</tr>\n";
6313                 }
6314         }
6315
6316         print "</table>\n";
6317
6318         # If XSS prevention is on, we don't include README.html.
6319         # TODO: Allow a readme in some safe format.
6320         if (!$prevent_xss && -s "$projectroot/$project/README.html") {
6321                 print "<div class=\"title\">readme</div>\n" .
6322                       "<div class=\"readme\">\n";
6323                 insert_file("$projectroot/$project/README.html");
6324                 print "\n</div>\n"; # class="readme"
6325         }
6326
6327         # we need to request one more than 16 (0..15) to check if
6328         # those 16 are all
6329         my @commitlist = $head ? parse_commits($head, 17) : ();
6330         if (@commitlist) {
6331                 git_print_header_div('shortlog');
6332                 git_shortlog_body(\@commitlist, 0, 15, $refs,
6333                                   $#commitlist <=  15 ? undef :
6334                                   $cgi->a({-href => href(action=>"shortlog")}, "..."));
6335         }
6336
6337         if (@taglist) {
6338                 git_print_header_div('tags');
6339                 git_tags_body(\@taglist, 0, 15,
6340                               $#taglist <=  15 ? undef :
6341                               $cgi->a({-href => href(action=>"tags")}, "..."));
6342         }
6343
6344         if (@headlist) {
6345                 git_print_header_div('heads');
6346                 git_heads_body(\@headlist, $head, 0, 15,
6347                                $#headlist <= 15 ? undef :
6348                                $cgi->a({-href => href(action=>"heads")}, "..."));
6349         }
6350
6351         if (%remotedata) {
6352                 git_print_header_div('remotes');
6353                 git_remotes_body(\%remotedata, 15, $head);
6354         }
6355
6356         if (@forklist) {
6357                 git_print_header_div('forks');
6358                 git_project_list_body(\@forklist, 'age', 0, 15,
6359                                       $#forklist <= 15 ? undef :
6360                                       $cgi->a({-href => href(action=>"forks")}, "..."),
6361                                       'no_header');
6362         }
6363
6364         git_footer_html();
6365 }
6366
6367 sub git_tag {
6368         my %tag = parse_tag($hash);
6369
6370         if (! %tag) {
6371                 die_error(404, "Unknown tag object");
6372         }
6373
6374         my $head = git_get_head_hash($project);
6375         git_header_html();
6376         git_print_page_nav('','', $head,undef,$head);
6377         git_print_header_div('commit', esc_html($tag{'name'}), $hash);
6378         print "<div class=\"title_text\">\n" .
6379               "<table class=\"object_header\">\n" .
6380               "<tr>\n" .
6381               "<td>object</td>\n" .
6382               "<td>" . $cgi->a({-class => "list", -href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6383                                $tag{'object'}) . "</td>\n" .
6384               "<td class=\"link\">" . $cgi->a({-href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6385                                               $tag{'type'}) . "</td>\n" .
6386               "</tr>\n";
6387         if (defined($tag{'author'})) {
6388                 git_print_authorship_rows(\%tag, 'author');
6389         }
6390         print "</table>\n\n" .
6391               "</div>\n";
6392         print "<div class=\"page_body\">";
6393         my $comment = $tag{'comment'};
6394         foreach my $line (@$comment) {
6395                 chomp $line;
6396                 print esc_html($line, -nbsp=>1) . "<br/>\n";
6397         }
6398         print "</div>\n";
6399         git_footer_html();
6400 }
6401
6402 sub git_blame_common {
6403         my $format = shift || 'porcelain';
6404         if ($format eq 'porcelain' && $input_params{'javascript'}) {
6405                 $format = 'incremental';
6406                 $action = 'blame_incremental'; # for page title etc
6407         }
6408
6409         # permissions
6410         gitweb_check_feature('blame')
6411                 or die_error(403, "Blame view not allowed");
6412
6413         # error checking
6414         die_error(400, "No file name given") unless $file_name;
6415         $hash_base ||= git_get_head_hash($project);
6416         die_error(404, "Couldn't find base commit") unless $hash_base;
6417         my %co = parse_commit($hash_base)
6418                 or die_error(404, "Commit not found");
6419         my $ftype = "blob";
6420         if (!defined $hash) {
6421                 $hash = git_get_hash_by_path($hash_base, $file_name, "blob")
6422                         or die_error(404, "Error looking up file");
6423         } else {
6424                 $ftype = git_get_type($hash);
6425                 if ($ftype !~ "blob") {
6426                         die_error(400, "Object is not a blob");
6427                 }
6428         }
6429
6430         my $fd;
6431         if ($format eq 'incremental') {
6432                 # get file contents (as base)
6433                 open $fd, "-|", git_cmd(), 'cat-file', 'blob', $hash
6434                         or die_error(500, "Open git-cat-file failed");
6435         } elsif ($format eq 'data') {
6436                 # run git-blame --incremental
6437                 open $fd, "-|", git_cmd(), "blame", "--incremental",
6438                         $hash_base, "--", $file_name
6439                         or die_error(500, "Open git-blame --incremental failed");
6440         } else {
6441                 # run git-blame --porcelain
6442                 open $fd, "-|", git_cmd(), "blame", '-p',
6443                         $hash_base, '--', $file_name
6444                         or die_error(500, "Open git-blame --porcelain failed");
6445         }
6446
6447         # incremental blame data returns early
6448         if ($format eq 'data') {
6449                 print $cgi->header(
6450                         -type=>"text/plain", -charset => "utf-8",
6451                         -status=> "200 OK");
6452                 local $| = 1; # output autoflush
6453                 while (my $line = <$fd>) {
6454                         print to_utf8($line);
6455                 }
6456                 close $fd
6457                         or print "ERROR $!\n";
6458
6459                 print 'END';
6460                 if (defined $t0 && gitweb_check_feature('timed')) {
6461                         print ' '.
6462                               tv_interval($t0, [ gettimeofday() ]).
6463                               ' '.$number_of_git_cmds;
6464                 }
6465                 print "\n";
6466
6467                 return;
6468         }
6469
6470         # page header
6471         git_header_html();
6472         my $formats_nav =
6473                 $cgi->a({-href => href(action=>"blob", -replay=>1)},
6474                         "blob") .
6475                 " | ";
6476         if ($format eq 'incremental') {
6477                 $formats_nav .=
6478                         $cgi->a({-href => href(action=>"blame", javascript=>0, -replay=>1)},
6479                                 "blame") . " (non-incremental)";
6480         } else {
6481                 $formats_nav .=
6482                         $cgi->a({-href => href(action=>"blame_incremental", -replay=>1)},
6483                                 "blame") . " (incremental)";
6484         }
6485         $formats_nav .=
6486                 " | " .
6487                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6488                         "history") .
6489                 " | " .
6490                 $cgi->a({-href => href(action=>$action, file_name=>$file_name)},
6491                         "HEAD");
6492         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6493         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6494         git_print_page_path($file_name, $ftype, $hash_base);
6495
6496         # page body
6497         if ($format eq 'incremental') {
6498                 print "<noscript>\n<div class=\"error\"><center><b>\n".
6499                       "This page requires JavaScript to run.\n Use ".
6500                       $cgi->a({-href => href(action=>'blame',javascript=>0,-replay=>1)},
6501                               'this page').
6502                       " instead.\n".
6503                       "</b></center></div>\n</noscript>\n";
6504
6505                 print qq!<div id="progress_bar" style="width: 100%; background-color: yellow"></div>\n!;
6506         }
6507
6508         print qq!<div class="page_body">\n!;
6509         print qq!<div id="progress_info">... / ...</div>\n!
6510                 if ($format eq 'incremental');
6511         print qq!<table id="blame_table" class="blame" width="100%">\n!.
6512               #qq!<col width="5.5em" /><col width="2.5em" /><col width="*" />\n!.
6513               qq!<thead>\n!.
6514               qq!<tr><th>Commit</th><th>Line</th><th>Data</th></tr>\n!.
6515               qq!</thead>\n!.
6516               qq!<tbody>\n!;
6517
6518         my @rev_color = qw(light dark);
6519         my $num_colors = scalar(@rev_color);
6520         my $current_color = 0;
6521
6522         if ($format eq 'incremental') {
6523                 my $color_class = $rev_color[$current_color];
6524
6525                 #contents of a file
6526                 my $linenr = 0;
6527         LINE:
6528                 while (my $line = <$fd>) {
6529                         chomp $line;
6530                         $linenr++;
6531
6532                         print qq!<tr id="l$linenr" class="$color_class">!.
6533                               qq!<td class="sha1"><a href=""> </a></td>!.
6534                               qq!<td class="linenr">!.
6535                               qq!<a class="linenr" href="">$linenr</a></td>!;
6536                         print qq!<td class="pre">! . esc_html($line) . "</td>\n";
6537                         print qq!</tr>\n!;
6538                 }
6539
6540         } else { # porcelain, i.e. ordinary blame
6541                 my %metainfo = (); # saves information about commits
6542
6543                 # blame data
6544         LINE:
6545                 while (my $line = <$fd>) {
6546                         chomp $line;
6547                         # the header: <SHA-1> <src lineno> <dst lineno> [<lines in group>]
6548                         # no <lines in group> for subsequent lines in group of lines
6549                         my ($full_rev, $orig_lineno, $lineno, $group_size) =
6550                            ($line =~ /^([0-9a-f]{40}) (\d+) (\d+)(?: (\d+))?$/);
6551                         if (!exists $metainfo{$full_rev}) {
6552                                 $metainfo{$full_rev} = { 'nprevious' => 0 };
6553                         }
6554                         my $meta = $metainfo{$full_rev};
6555                         my $data;
6556                         while ($data = <$fd>) {
6557                                 chomp $data;
6558                                 last if ($data =~ s/^\t//); # contents of line
6559                                 if ($data =~ /^(\S+)(?: (.*))?$/) {
6560                                         $meta->{$1} = $2 unless exists $meta->{$1};
6561                                 }
6562                                 if ($data =~ /^previous /) {
6563                                         $meta->{'nprevious'}++;
6564                                 }
6565                         }
6566                         my $short_rev = substr($full_rev, 0, 8);
6567                         my $author = $meta->{'author'};
6568                         my %date =
6569                                 parse_date($meta->{'author-time'}, $meta->{'author-tz'});
6570                         my $date = $date{'iso-tz'};
6571                         if ($group_size) {
6572                                 $current_color = ($current_color + 1) % $num_colors;
6573                         }
6574                         my $tr_class = $rev_color[$current_color];
6575                         $tr_class .= ' boundary' if (exists $meta->{'boundary'});
6576                         $tr_class .= ' no-previous' if ($meta->{'nprevious'} == 0);
6577                         $tr_class .= ' multiple-previous' if ($meta->{'nprevious'} > 1);
6578                         print "<tr id=\"l$lineno\" class=\"$tr_class\">\n";
6579                         if ($group_size) {
6580                                 print "<td class=\"sha1\"";
6581                                 print " title=\"". esc_html($author) . ", $date\"";
6582                                 print " rowspan=\"$group_size\"" if ($group_size > 1);
6583                                 print ">";
6584                                 print $cgi->a({-href => href(action=>"commit",
6585                                                              hash=>$full_rev,
6586                                                              file_name=>$file_name)},
6587                                               esc_html($short_rev));
6588                                 if ($group_size >= 2) {
6589                                         my @author_initials = ($author =~ /\b([[:upper:]])\B/g);
6590                                         if (@author_initials) {
6591                                                 print "<br />" .
6592                                                       esc_html(join('', @author_initials));
6593                                                 #           or join('.', ...)
6594                                         }
6595                                 }
6596                                 print "</td>\n";
6597                         }
6598                         # 'previous' <sha1 of parent commit> <filename at commit>
6599                         if (exists $meta->{'previous'} &&
6600                             $meta->{'previous'} =~ /^([a-fA-F0-9]{40}) (.*)$/) {
6601                                 $meta->{'parent'} = $1;
6602                                 $meta->{'file_parent'} = unquote($2);
6603                         }
6604                         my $linenr_commit =
6605                                 exists($meta->{'parent'}) ?
6606                                 $meta->{'parent'} : $full_rev;
6607                         my $linenr_filename =
6608                                 exists($meta->{'file_parent'}) ?
6609                                 $meta->{'file_parent'} : unquote($meta->{'filename'});
6610                         my $blamed = href(action => 'blame',
6611                                           file_name => $linenr_filename,
6612                                           hash_base => $linenr_commit);
6613                         print "<td class=\"linenr\">";
6614                         print $cgi->a({ -href => "$blamed#l$orig_lineno",
6615                                         -class => "linenr" },
6616                                       esc_html($lineno));
6617                         print "</td>";
6618                         print "<td class=\"pre\">" . esc_html($data) . "</td>\n";
6619                         print "</tr>\n";
6620                 } # end while
6621
6622         }
6623
6624         # footer
6625         print "</tbody>\n".
6626               "</table>\n"; # class="blame"
6627         print "</div>\n";   # class="blame_body"
6628         close $fd
6629                 or print "Reading blob failed\n";
6630
6631         git_footer_html();
6632 }
6633
6634 sub git_blame {
6635         git_blame_common();
6636 }
6637
6638 sub git_blame_incremental {
6639         git_blame_common('incremental');
6640 }
6641
6642 sub git_blame_data {
6643         git_blame_common('data');
6644 }
6645
6646 sub git_tags {
6647         my $head = git_get_head_hash($project);
6648         git_header_html();
6649         git_print_page_nav('','', $head,undef,$head,format_ref_views('tags'));
6650         git_print_header_div('summary', $project);
6651
6652         my @tagslist = git_get_tags_list();
6653         if (@tagslist) {
6654                 git_tags_body(\@tagslist);
6655         }
6656         git_footer_html();
6657 }
6658
6659 sub git_heads {
6660         my $head = git_get_head_hash($project);
6661         git_header_html();
6662         git_print_page_nav('','', $head,undef,$head,format_ref_views('heads'));
6663         git_print_header_div('summary', $project);
6664
6665         my @headslist = git_get_heads_list();
6666         if (@headslist) {
6667                 git_heads_body(\@headslist, $head);
6668         }
6669         git_footer_html();
6670 }
6671
6672 # used both for single remote view and for list of all the remotes
6673 sub git_remotes {
6674         gitweb_check_feature('remote_heads')
6675                 or die_error(403, "Remote heads view is disabled");
6676
6677         my $head = git_get_head_hash($project);
6678         my $remote = $input_params{'hash'};
6679
6680         my $remotedata = git_get_remotes_list($remote);
6681         die_error(500, "Unable to get remote information") unless defined $remotedata;
6682
6683         unless (%$remotedata) {
6684                 die_error(404, defined $remote ?
6685                         "Remote $remote not found" :
6686                         "No remotes found");
6687         }
6688
6689         git_header_html(undef, undef, -action_extra => $remote);
6690         git_print_page_nav('', '',  $head, undef, $head,
6691                 format_ref_views($remote ? '' : 'remotes'));
6692
6693         fill_remote_heads($remotedata);
6694         if (defined $remote) {
6695                 git_print_header_div('remotes', "$remote remote for $project");
6696                 git_remote_block($remote, $remotedata->{$remote}, undef, $head);
6697         } else {
6698                 git_print_header_div('summary', "$project remotes");
6699                 git_remotes_body($remotedata, undef, $head);
6700         }
6701
6702         git_footer_html();
6703 }
6704
6705 sub git_blob_plain {
6706         my $type = shift;
6707         my $expires;
6708
6709         if (!defined $hash) {
6710                 if (defined $file_name) {
6711                         my $base = $hash_base || git_get_head_hash($project);
6712                         $hash = git_get_hash_by_path($base, $file_name, "blob")
6713                                 or die_error(404, "Cannot find file");
6714                 } else {
6715                         die_error(400, "No file name defined");
6716                 }
6717         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6718                 # blobs defined by non-textual hash id's can be cached
6719                 $expires = "+1d";
6720         }
6721
6722         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
6723                 or die_error(500, "Open git-cat-file blob '$hash' failed");
6724
6725         # content-type (can include charset)
6726         $type = blob_contenttype($fd, $file_name, $type);
6727
6728         # "save as" filename, even when no $file_name is given
6729         my $save_as = "$hash";
6730         if (defined $file_name) {
6731                 $save_as = $file_name;
6732         } elsif ($type =~ m/^text\//) {
6733                 $save_as .= '.txt';
6734         }
6735
6736         # With XSS prevention on, blobs of all types except a few known safe
6737         # ones are served with "Content-Disposition: attachment" to make sure
6738         # they don't run in our security domain.  For certain image types,
6739         # blob view writes an <img> tag referring to blob_plain view, and we
6740         # want to be sure not to break that by serving the image as an
6741         # attachment (though Firefox 3 doesn't seem to care).
6742         my $sandbox = $prevent_xss &&
6743                 $type !~ m!^(?:text/[a-z]+|image/(?:gif|png|jpeg))(?:[ ;]|$)!;
6744
6745         # serve text/* as text/plain
6746         if ($prevent_xss &&
6747             ($type =~ m!^text/[a-z]+\b(.*)$! ||
6748              ($type =~ m!^[a-z]+/[a-z]\+xml\b(.*)$! && -T $fd))) {
6749                 my $rest = $1;
6750                 $rest = defined $rest ? $rest : '';
6751                 $type = "text/plain$rest";
6752         }
6753
6754         print $cgi->header(
6755                 -type => $type,
6756                 -expires => $expires,
6757                 -content_disposition =>
6758                         ($sandbox ? 'attachment' : 'inline')
6759                         . '; filename="' . $save_as . '"');
6760         local $/ = undef;
6761         binmode STDOUT, ':raw';
6762         print <$fd>;
6763         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
6764         close $fd;
6765 }
6766
6767 sub git_blob {
6768         my $expires;
6769
6770         if (!defined $hash) {
6771                 if (defined $file_name) {
6772                         my $base = $hash_base || git_get_head_hash($project);
6773                         $hash = git_get_hash_by_path($base, $file_name, "blob")
6774                                 or die_error(404, "Cannot find file");
6775                 } else {
6776                         die_error(400, "No file name defined");
6777                 }
6778         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6779                 # blobs defined by non-textual hash id's can be cached
6780                 $expires = "+1d";
6781         }
6782
6783         my $have_blame = gitweb_check_feature('blame');
6784         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
6785                 or die_error(500, "Couldn't cat $file_name, $hash");
6786         my $mimetype = blob_mimetype($fd, $file_name);
6787         # use 'blob_plain' (aka 'raw') view for files that cannot be displayed
6788         if ($mimetype !~ m!^(?:text/|image/(?:gif|png|jpeg)$)! && -B $fd) {
6789                 close $fd;
6790                 return git_blob_plain($mimetype);
6791         }
6792         # we can have blame only for text/* mimetype
6793         $have_blame &&= ($mimetype =~ m!^text/!);
6794
6795         my $highlight = gitweb_check_feature('highlight');
6796         my $syntax = guess_file_syntax($highlight, $mimetype, $file_name);
6797         $fd = run_highlighter($fd, $highlight, $syntax)
6798                 if $syntax;
6799
6800         git_header_html(undef, $expires);
6801         my $formats_nav = '';
6802         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
6803                 if (defined $file_name) {
6804                         if ($have_blame) {
6805                                 $formats_nav .=
6806                                         $cgi->a({-href => href(action=>"blame", -replay=>1)},
6807                                                 "blame") .
6808                                         " | ";
6809                         }
6810                         $formats_nav .=
6811                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6812                                         "history") .
6813                                 " | " .
6814                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
6815                                         "raw") .
6816                                 " | " .
6817                                 $cgi->a({-href => href(action=>"blob",
6818                                                        hash_base=>"HEAD", file_name=>$file_name)},
6819                                         "HEAD");
6820                 } else {
6821                         $formats_nav .=
6822                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
6823                                         "raw");
6824                 }
6825                 git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6826                 git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6827         } else {
6828                 print "<div class=\"page_nav\">\n" .
6829                       "<br/><br/></div>\n" .
6830                       "<div class=\"title\">".esc_html($hash)."</div>\n";
6831         }
6832         git_print_page_path($file_name, "blob", $hash_base);
6833         print "<div class=\"page_body\">\n";
6834         if ($mimetype =~ m!^image/!) {
6835                 print qq!<img type="!.esc_attr($mimetype).qq!"!;
6836                 if ($file_name) {
6837                         print qq! alt="!.esc_attr($file_name).qq!" title="!.esc_attr($file_name).qq!"!;
6838                 }
6839                 print qq! src="! .
6840                       href(action=>"blob_plain", hash=>$hash,
6841                            hash_base=>$hash_base, file_name=>$file_name) .
6842                       qq!" />\n!;
6843         } else {
6844                 my $nr;
6845                 while (my $line = <$fd>) {
6846                         chomp $line;
6847                         $nr++;
6848                         $line = untabify($line);
6849                         printf qq!<div class="pre"><a id="l%i" href="%s#l%i" class="linenr">%4i</a> %s</div>\n!,
6850                                $nr, esc_attr(href(-replay => 1)), $nr, $nr,
6851                                $syntax ? sanitize($line) : esc_html($line, -nbsp=>1);
6852                 }
6853         }
6854         close $fd
6855                 or print "Reading blob failed.\n";
6856         print "</div>";
6857         git_footer_html();
6858 }
6859
6860 sub git_tree {
6861         if (!defined $hash_base) {
6862                 $hash_base = "HEAD";
6863         }
6864         if (!defined $hash) {
6865                 if (defined $file_name) {
6866                         $hash = git_get_hash_by_path($hash_base, $file_name, "tree");
6867                 } else {
6868                         $hash = $hash_base;
6869                 }
6870         }
6871         die_error(404, "No such tree") unless defined($hash);
6872
6873         my $show_sizes = gitweb_check_feature('show-sizes');
6874         my $have_blame = gitweb_check_feature('blame');
6875
6876         my @entries = ();
6877         {
6878                 local $/ = "\0";
6879                 open my $fd, "-|", git_cmd(), "ls-tree", '-z',
6880                         ($show_sizes ? '-l' : ()), @extra_options, $hash
6881                         or die_error(500, "Open git-ls-tree failed");
6882                 @entries = map { chomp; $_ } <$fd>;
6883                 close $fd
6884                         or die_error(404, "Reading tree failed");
6885         }
6886
6887         my $refs = git_get_references();
6888         my $ref = format_ref_marker($refs, $hash_base);
6889         git_header_html();
6890         my $basedir = '';
6891         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
6892                 my @views_nav = ();
6893                 if (defined $file_name) {
6894                         push @views_nav,
6895                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6896                                         "history"),
6897                                 $cgi->a({-href => href(action=>"tree",
6898                                                        hash_base=>"HEAD", file_name=>$file_name)},
6899                                         "HEAD"),
6900                 }
6901                 my $snapshot_links = format_snapshot_links($hash);
6902                 if (defined $snapshot_links) {
6903                         # FIXME: Should be available when we have no hash base as well.
6904                         push @views_nav, $snapshot_links;
6905                 }
6906                 git_print_page_nav('tree','', $hash_base, undef, undef,
6907                                    join(' | ', @views_nav));
6908                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash_base);
6909         } else {
6910                 undef $hash_base;
6911                 print "<div class=\"page_nav\">\n";
6912                 print "<br/><br/></div>\n";
6913                 print "<div class=\"title\">".esc_html($hash)."</div>\n";
6914         }
6915         if (defined $file_name) {
6916                 $basedir = $file_name;
6917                 if ($basedir ne '' && substr($basedir, -1) ne '/') {
6918                         $basedir .= '/';
6919                 }
6920                 git_print_page_path($file_name, 'tree', $hash_base);
6921         }
6922         print "<div class=\"page_body\">\n";
6923         print "<table class=\"tree\">\n";
6924         my $alternate = 1;
6925         # '..' (top directory) link if possible
6926         if (defined $hash_base &&
6927             defined $file_name && $file_name =~ m![^/]+$!) {
6928                 if ($alternate) {
6929                         print "<tr class=\"dark\">\n";
6930                 } else {
6931                         print "<tr class=\"light\">\n";
6932                 }
6933                 $alternate ^= 1;
6934
6935                 my $up = $file_name;
6936                 $up =~ s!/?[^/]+$!!;
6937                 undef $up unless $up;
6938                 # based on git_print_tree_entry
6939                 print '<td class="mode">' . mode_str('040000') . "</td>\n";
6940                 print '<td class="size">&nbsp;</td>'."\n" if $show_sizes;
6941                 print '<td class="list">';
6942                 print $cgi->a({-href => href(action=>"tree",
6943                                              hash_base=>$hash_base,
6944                                              file_name=>$up)},
6945                               "..");
6946                 print "</td>\n";
6947                 print "<td class=\"link\"></td>\n";
6948
6949                 print "</tr>\n";
6950         }
6951         foreach my $line (@entries) {
6952                 my %t = parse_ls_tree_line($line, -z => 1, -l => $show_sizes);
6953
6954                 if ($alternate) {
6955                         print "<tr class=\"dark\">\n";
6956                 } else {
6957                         print "<tr class=\"light\">\n";
6958                 }
6959                 $alternate ^= 1;
6960
6961                 git_print_tree_entry(\%t, $basedir, $hash_base, $have_blame);
6962
6963                 print "</tr>\n";
6964         }
6965         print "</table>\n" .
6966               "</div>";
6967         git_footer_html();
6968 }
6969
6970 sub snapshot_name {
6971         my ($project, $hash) = @_;
6972
6973         # path/to/project.git  -> project
6974         # path/to/project/.git -> project
6975         my $name = to_utf8($project);
6976         $name =~ s,([^/])/*\.git$,$1,;
6977         $name = basename($name);
6978         # sanitize name
6979         $name =~ s/[[:cntrl:]]/?/g;
6980
6981         my $ver = $hash;
6982         if ($hash =~ /^[0-9a-fA-F]+$/) {
6983                 # shorten SHA-1 hash
6984                 my $full_hash = git_get_full_hash($project, $hash);
6985                 if ($full_hash =~ /^$hash/ && length($hash) > 7) {
6986                         $ver = git_get_short_hash($project, $hash);
6987                 }
6988         } elsif ($hash =~ m!^refs/tags/(.*)$!) {
6989                 # tags don't need shortened SHA-1 hash
6990                 $ver = $1;
6991         } else {
6992                 # branches and other need shortened SHA-1 hash
6993                 if ($hash =~ m!^refs/(?:heads|remotes)/(.*)$!) {
6994                         $ver = $1;
6995                 }
6996                 $ver .= '-' . git_get_short_hash($project, $hash);
6997         }
6998         # in case of hierarchical branch names
6999         $ver =~ s!/!.!g;
7000
7001         # name = project-version_string
7002         $name = "$name-$ver";
7003
7004         return wantarray ? ($name, $name) : $name;
7005 }
7006
7007 sub git_snapshot {
7008         my $format = $input_params{'snapshot_format'};
7009         if (!@snapshot_fmts) {
7010                 die_error(403, "Snapshots not allowed");
7011         }
7012         # default to first supported snapshot format
7013         $format ||= $snapshot_fmts[0];
7014         if ($format !~ m/^[a-z0-9]+$/) {
7015                 die_error(400, "Invalid snapshot format parameter");
7016         } elsif (!exists($known_snapshot_formats{$format})) {
7017                 die_error(400, "Unknown snapshot format");
7018         } elsif ($known_snapshot_formats{$format}{'disabled'}) {
7019                 die_error(403, "Snapshot format not allowed");
7020         } elsif (!grep($_ eq $format, @snapshot_fmts)) {
7021                 die_error(403, "Unsupported snapshot format");
7022         }
7023
7024         my $type = git_get_type("$hash^{}");
7025         if (!$type) {
7026                 die_error(404, 'Object does not exist');
7027         }  elsif ($type eq 'blob') {
7028                 die_error(400, 'Object is not a tree-ish');
7029         }
7030
7031         my ($name, $prefix) = snapshot_name($project, $hash);
7032         my $filename = "$name$known_snapshot_formats{$format}{'suffix'}";
7033         my $cmd = quote_command(
7034                 git_cmd(), 'archive',
7035                 "--format=$known_snapshot_formats{$format}{'format'}",
7036                 "--prefix=$prefix/", $hash);
7037         if (exists $known_snapshot_formats{$format}{'compressor'}) {
7038                 $cmd .= ' | ' . quote_command(@{$known_snapshot_formats{$format}{'compressor'}});
7039         }
7040
7041         $filename =~ s/(["\\])/\\$1/g;
7042         print $cgi->header(
7043                 -type => $known_snapshot_formats{$format}{'type'},
7044                 -content_disposition => 'inline; filename="' . $filename . '"',
7045                 -status => '200 OK');
7046
7047         open my $fd, "-|", $cmd
7048                 or die_error(500, "Execute git-archive failed");
7049         binmode STDOUT, ':raw';
7050         print <$fd>;
7051         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
7052         close $fd;
7053 }
7054
7055 sub git_log_generic {
7056         my ($fmt_name, $body_subr, $base, $parent, $file_name, $file_hash) = @_;
7057
7058         my $head = git_get_head_hash($project);
7059         if (!defined $base) {
7060                 $base = $head;
7061         }
7062         if (!defined $page) {
7063                 $page = 0;
7064         }
7065         my $refs = git_get_references();
7066
7067         my $commit_hash = $base;
7068         if (defined $parent) {
7069                 $commit_hash = "$parent..$base";
7070         }
7071         my @commitlist =
7072                 parse_commits($commit_hash, 101, (100 * $page),
7073                               defined $file_name ? ($file_name, "--full-history") : ());
7074
7075         my $ftype;
7076         if (!defined $file_hash && defined $file_name) {
7077                 # some commits could have deleted file in question,
7078                 # and not have it in tree, but one of them has to have it
7079                 for (my $i = 0; $i < @commitlist; $i++) {
7080                         $file_hash = git_get_hash_by_path($commitlist[$i]{'id'}, $file_name);
7081                         last if defined $file_hash;
7082                 }
7083         }
7084         if (defined $file_hash) {
7085                 $ftype = git_get_type($file_hash);
7086         }
7087         if (defined $file_name && !defined $ftype) {
7088                 die_error(500, "Unknown type of object");
7089         }
7090         my %co;
7091         if (defined $file_name) {
7092                 %co = parse_commit($base)
7093                         or die_error(404, "Unknown commit object");
7094         }
7095
7096
7097         my $paging_nav = format_paging_nav($fmt_name, $page, $#commitlist >= 100);
7098         my $next_link = '';
7099         if ($#commitlist >= 100) {
7100                 $next_link =
7101                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
7102                                  -accesskey => "n", -title => "Alt-n"}, "next");
7103         }
7104         my $patch_max = gitweb_get_feature('patches');
7105         if ($patch_max && !defined $file_name) {
7106                 if ($patch_max < 0 || @commitlist <= $patch_max) {
7107                         $paging_nav .= " &sdot; " .
7108                                 $cgi->a({-href => href(action=>"patches", -replay=>1)},
7109                                         "patches");
7110                 }
7111         }
7112
7113         git_header_html();
7114         git_print_page_nav($fmt_name,'', $hash,$hash,$hash, $paging_nav);
7115         if (defined $file_name) {
7116                 git_print_header_div('commit', esc_html($co{'title'}), $base);
7117         } else {
7118                 git_print_header_div('summary', $project)
7119         }
7120         git_print_page_path($file_name, $ftype, $hash_base)
7121                 if (defined $file_name);
7122
7123         $body_subr->(\@commitlist, 0, 99, $refs, $next_link,
7124                      $file_name, $file_hash, $ftype);
7125
7126         git_footer_html();
7127 }
7128
7129 sub git_log {
7130         git_log_generic('log', \&git_log_body,
7131                         $hash, $hash_parent);
7132 }
7133
7134 sub git_commit {
7135         $hash ||= $hash_base || "HEAD";
7136         my %co = parse_commit($hash)
7137             or die_error(404, "Unknown commit object");
7138
7139         my $parent  = $co{'parent'};
7140         my $parents = $co{'parents'}; # listref
7141
7142         # we need to prepare $formats_nav before any parameter munging
7143         my $formats_nav;
7144         if (!defined $parent) {
7145                 # --root commitdiff
7146                 $formats_nav .= '(initial)';
7147         } elsif (@$parents == 1) {
7148                 # single parent commit
7149                 $formats_nav .=
7150                         '(parent: ' .
7151                         $cgi->a({-href => href(action=>"commit",
7152                                                hash=>$parent)},
7153                                 esc_html(substr($parent, 0, 7))) .
7154                         ')';
7155         } else {
7156                 # merge commit
7157                 $formats_nav .=
7158                         '(merge: ' .
7159                         join(' ', map {
7160                                 $cgi->a({-href => href(action=>"commit",
7161                                                        hash=>$_)},
7162                                         esc_html(substr($_, 0, 7)));
7163                         } @$parents ) .
7164                         ')';
7165         }
7166         if (gitweb_check_feature('patches') && @$parents <= 1) {
7167                 $formats_nav .= " | " .
7168                         $cgi->a({-href => href(action=>"patch", -replay=>1)},
7169                                 "patch");
7170         }
7171
7172         if (!defined $parent) {
7173                 $parent = "--root";
7174         }
7175         my @difftree;
7176         open my $fd, "-|", git_cmd(), "diff-tree", '-r', "--no-commit-id",
7177                 @diff_opts,
7178                 (@$parents <= 1 ? $parent : '-c'),
7179                 $hash, "--"
7180                 or die_error(500, "Open git-diff-tree failed");
7181         @difftree = map { chomp; $_ } <$fd>;
7182         close $fd or die_error(404, "Reading git-diff-tree failed");
7183
7184         # non-textual hash id's can be cached
7185         my $expires;
7186         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7187                 $expires = "+1d";
7188         }
7189         my $refs = git_get_references();
7190         my $ref = format_ref_marker($refs, $co{'id'});
7191
7192         git_header_html(undef, $expires);
7193         git_print_page_nav('commit', '',
7194                            $hash, $co{'tree'}, $hash,
7195                            $formats_nav);
7196
7197         if (defined $co{'parent'}) {
7198                 git_print_header_div('commitdiff', esc_html($co{'title'}) . $ref, $hash);
7199         } else {
7200                 git_print_header_div('tree', esc_html($co{'title'}) . $ref, $co{'tree'}, $hash);
7201         }
7202         print "<div class=\"title_text\">\n" .
7203               "<table class=\"object_header\">\n";
7204         git_print_authorship_rows(\%co);
7205         print "<tr><td>commit</td><td class=\"sha1\">$co{'id'}</td></tr>\n";
7206         print "<tr>" .
7207               "<td>tree</td>" .
7208               "<td class=\"sha1\">" .
7209               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash),
7210                        class => "list"}, $co{'tree'}) .
7211               "</td>" .
7212               "<td class=\"link\">" .
7213               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash)},
7214                       "tree");
7215         my $snapshot_links = format_snapshot_links($hash);
7216         if (defined $snapshot_links) {
7217                 print " | " . $snapshot_links;
7218         }
7219         print "</td>" .
7220               "</tr>\n";
7221
7222         foreach my $par (@$parents) {
7223                 print "<tr>" .
7224                       "<td>parent</td>" .
7225                       "<td class=\"sha1\">" .
7226                       $cgi->a({-href => href(action=>"commit", hash=>$par),
7227                                class => "list"}, $par) .
7228                       "</td>" .
7229                       "<td class=\"link\">" .
7230                       $cgi->a({-href => href(action=>"commit", hash=>$par)}, "commit") .
7231                       " | " .
7232                       $cgi->a({-href => href(action=>"commitdiff", hash=>$hash, hash_parent=>$par)}, "diff") .
7233                       "</td>" .
7234                       "</tr>\n";
7235         }
7236         print "</table>".
7237               "</div>\n";
7238
7239         print "<div class=\"page_body\">\n";
7240         git_print_log($co{'comment'});
7241         print "</div>\n";
7242
7243         git_difftree_body(\@difftree, $hash, @$parents);
7244
7245         git_footer_html();
7246 }
7247
7248 sub git_object {
7249         # object is defined by:
7250         # - hash or hash_base alone
7251         # - hash_base and file_name
7252         my $type;
7253
7254         # - hash or hash_base alone
7255         if ($hash || ($hash_base && !defined $file_name)) {
7256                 my $object_id = $hash || $hash_base;
7257
7258                 open my $fd, "-|", quote_command(
7259                         git_cmd(), 'cat-file', '-t', $object_id) . ' 2> /dev/null'
7260                         or die_error(404, "Object does not exist");
7261                 $type = <$fd>;
7262                 chomp $type;
7263                 close $fd
7264                         or die_error(404, "Object does not exist");
7265
7266         # - hash_base and file_name
7267         } elsif ($hash_base && defined $file_name) {
7268                 $file_name =~ s,/+$,,;
7269
7270                 system(git_cmd(), "cat-file", '-e', $hash_base) == 0
7271                         or die_error(404, "Base object does not exist");
7272
7273                 # here errors should not hapen
7274                 open my $fd, "-|", git_cmd(), "ls-tree", $hash_base, "--", $file_name
7275                         or die_error(500, "Open git-ls-tree failed");
7276                 my $line = <$fd>;
7277                 close $fd;
7278
7279                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
7280                 unless ($line && $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/) {
7281                         die_error(404, "File or directory for given base does not exist");
7282                 }
7283                 $type = $2;
7284                 $hash = $3;
7285         } else {
7286                 die_error(400, "Not enough information to find object");
7287         }
7288
7289         print $cgi->redirect(-uri => href(action=>$type, -full=>1,
7290                                           hash=>$hash, hash_base=>$hash_base,
7291                                           file_name=>$file_name),
7292                              -status => '302 Found');
7293 }
7294
7295 sub git_blobdiff {
7296         my $format = shift || 'html';
7297         my $diff_style = $input_params{'diff_style'} || 'inline';
7298
7299         my $fd;
7300         my @difftree;
7301         my %diffinfo;
7302         my $expires;
7303
7304         # preparing $fd and %diffinfo for git_patchset_body
7305         # new style URI
7306         if (defined $hash_base && defined $hash_parent_base) {
7307                 if (defined $file_name) {
7308                         # read raw output
7309                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7310                                 $hash_parent_base, $hash_base,
7311                                 "--", (defined $file_parent ? $file_parent : ()), $file_name
7312                                 or die_error(500, "Open git-diff-tree failed");
7313                         @difftree = map { chomp; $_ } <$fd>;
7314                         close $fd
7315                                 or die_error(404, "Reading git-diff-tree failed");
7316                         @difftree
7317                                 or die_error(404, "Blob diff not found");
7318
7319                 } elsif (defined $hash &&
7320                          $hash =~ /[0-9a-fA-F]{40}/) {
7321                         # try to find filename from $hash
7322
7323                         # read filtered raw output
7324                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7325                                 $hash_parent_base, $hash_base, "--"
7326                                 or die_error(500, "Open git-diff-tree failed");
7327                         @difftree =
7328                                 # ':100644 100644 03b21826... 3b93d5e7... M     ls-files.c'
7329                                 # $hash == to_id
7330                                 grep { /^:[0-7]{6} [0-7]{6} [0-9a-fA-F]{40} $hash/ }
7331                                 map { chomp; $_ } <$fd>;
7332                         close $fd
7333                                 or die_error(404, "Reading git-diff-tree failed");
7334                         @difftree
7335                                 or die_error(404, "Blob diff not found");
7336
7337                 } else {
7338                         die_error(400, "Missing one of the blob diff parameters");
7339                 }
7340
7341                 if (@difftree > 1) {
7342                         die_error(400, "Ambiguous blob diff specification");
7343                 }
7344
7345                 %diffinfo = parse_difftree_raw_line($difftree[0]);
7346                 $file_parent ||= $diffinfo{'from_file'} || $file_name;
7347                 $file_name   ||= $diffinfo{'to_file'};
7348
7349                 $hash_parent ||= $diffinfo{'from_id'};
7350                 $hash        ||= $diffinfo{'to_id'};
7351
7352                 # non-textual hash id's can be cached
7353                 if ($hash_base =~ m/^[0-9a-fA-F]{40}$/ &&
7354                     $hash_parent_base =~ m/^[0-9a-fA-F]{40}$/) {
7355                         $expires = '+1d';
7356                 }
7357
7358                 # open patch output
7359                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7360                         '-p', ($format eq 'html' ? "--full-index" : ()),
7361                         $hash_parent_base, $hash_base,
7362                         "--", (defined $file_parent ? $file_parent : ()), $file_name
7363                         or die_error(500, "Open git-diff-tree failed");
7364         }
7365
7366         # old/legacy style URI -- not generated anymore since 1.4.3.
7367         if (!%diffinfo) {
7368                 die_error('404 Not Found', "Missing one of the blob diff parameters")
7369         }
7370
7371         # header
7372         if ($format eq 'html') {
7373                 my $formats_nav =
7374                         $cgi->a({-href => href(action=>"blobdiff_plain", -replay=>1)},
7375                                 "raw");
7376                 $formats_nav .= diff_style_nav($diff_style);
7377                 git_header_html(undef, $expires);
7378                 if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7379                         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
7380                         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
7381                 } else {
7382                         print "<div class=\"page_nav\"><br/>$formats_nav<br/></div>\n";
7383                         print "<div class=\"title\">".esc_html("$hash vs $hash_parent")."</div>\n";
7384                 }
7385                 if (defined $file_name) {
7386                         git_print_page_path($file_name, "blob", $hash_base);
7387                 } else {
7388                         print "<div class=\"page_path\"></div>\n";
7389                 }
7390
7391         } elsif ($format eq 'plain') {
7392                 print $cgi->header(
7393                         -type => 'text/plain',
7394                         -charset => 'utf-8',
7395                         -expires => $expires,
7396                         -content_disposition => 'inline; filename="' . "$file_name" . '.patch"');
7397
7398                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7399
7400         } else {
7401                 die_error(400, "Unknown blobdiff format");
7402         }
7403
7404         # patch
7405         if ($format eq 'html') {
7406                 print "<div class=\"page_body\">\n";
7407
7408                 git_patchset_body($fd, $diff_style,
7409                                   [ \%diffinfo ], $hash_base, $hash_parent_base);
7410                 close $fd;
7411
7412                 print "</div>\n"; # class="page_body"
7413                 git_footer_html();
7414
7415         } else {
7416                 while (my $line = <$fd>) {
7417                         $line =~ s!a/($hash|$hash_parent)!'a/'.esc_path($diffinfo{'from_file'})!eg;
7418                         $line =~ s!b/($hash|$hash_parent)!'b/'.esc_path($diffinfo{'to_file'})!eg;
7419
7420                         print $line;
7421
7422                         last if $line =~ m!^\+\+\+!;
7423                 }
7424                 local $/ = undef;
7425                 print <$fd>;
7426                 close $fd;
7427         }
7428 }
7429
7430 sub git_blobdiff_plain {
7431         git_blobdiff('plain');
7432 }
7433
7434 # assumes that it is added as later part of already existing navigation,
7435 # so it returns "| foo | bar" rather than just "foo | bar"
7436 sub diff_style_nav {
7437         my ($diff_style, $is_combined) = @_;
7438         $diff_style ||= 'inline';
7439
7440         return "" if ($is_combined);
7441
7442         my @styles = (inline => 'inline', 'sidebyside' => 'side by side');
7443         my %styles = @styles;
7444         @styles =
7445                 @styles[ map { $_ * 2 } 0..$#styles/2 ];
7446
7447         return join '',
7448                 map { " | ".$_ }
7449                 map {
7450                         $_ eq $diff_style ? $styles{$_} :
7451                         $cgi->a({-href => href(-replay=>1, diff_style => $_)}, $styles{$_})
7452                 } @styles;
7453 }
7454
7455 sub git_commitdiff {
7456         my %params = @_;
7457         my $format = $params{-format} || 'html';
7458         my $diff_style = $input_params{'diff_style'} || 'inline';
7459
7460         my ($patch_max) = gitweb_get_feature('patches');
7461         if ($format eq 'patch') {
7462                 die_error(403, "Patch view not allowed") unless $patch_max;
7463         }
7464
7465         $hash ||= $hash_base || "HEAD";
7466         my %co = parse_commit($hash)
7467             or die_error(404, "Unknown commit object");
7468
7469         # choose format for commitdiff for merge
7470         if (! defined $hash_parent && @{$co{'parents'}} > 1) {
7471                 $hash_parent = '--cc';
7472         }
7473         # we need to prepare $formats_nav before almost any parameter munging
7474         my $formats_nav;
7475         if ($format eq 'html') {
7476                 $formats_nav =
7477                         $cgi->a({-href => href(action=>"commitdiff_plain", -replay=>1)},
7478                                 "raw");
7479                 if ($patch_max && @{$co{'parents'}} <= 1) {
7480                         $formats_nav .= " | " .
7481                                 $cgi->a({-href => href(action=>"patch", -replay=>1)},
7482                                         "patch");
7483                 }
7484                 $formats_nav .= diff_style_nav($diff_style, @{$co{'parents'}} > 1);
7485
7486                 if (defined $hash_parent &&
7487                     $hash_parent ne '-c' && $hash_parent ne '--cc') {
7488                         # commitdiff with two commits given
7489                         my $hash_parent_short = $hash_parent;
7490                         if ($hash_parent =~ m/^[0-9a-fA-F]{40}$/) {
7491                                 $hash_parent_short = substr($hash_parent, 0, 7);
7492                         }
7493                         $formats_nav .=
7494                                 ' (from';
7495                         for (my $i = 0; $i < @{$co{'parents'}}; $i++) {
7496                                 if ($co{'parents'}[$i] eq $hash_parent) {
7497                                         $formats_nav .= ' parent ' . ($i+1);
7498                                         last;
7499                                 }
7500                         }
7501                         $formats_nav .= ': ' .
7502                                 $cgi->a({-href => href(-replay=>1,
7503                                                        hash=>$hash_parent, hash_base=>undef)},
7504                                         esc_html($hash_parent_short)) .
7505                                 ')';
7506                 } elsif (!$co{'parent'}) {
7507                         # --root commitdiff
7508                         $formats_nav .= ' (initial)';
7509                 } elsif (scalar @{$co{'parents'}} == 1) {
7510                         # single parent commit
7511                         $formats_nav .=
7512                                 ' (parent: ' .
7513                                 $cgi->a({-href => href(-replay=>1,
7514                                                        hash=>$co{'parent'}, hash_base=>undef)},
7515                                         esc_html(substr($co{'parent'}, 0, 7))) .
7516                                 ')';
7517                 } else {
7518                         # merge commit
7519                         if ($hash_parent eq '--cc') {
7520                                 $formats_nav .= ' | ' .
7521                                         $cgi->a({-href => href(-replay=>1,
7522                                                                hash=>$hash, hash_parent=>'-c')},
7523                                                 'combined');
7524                         } else { # $hash_parent eq '-c'
7525                                 $formats_nav .= ' | ' .
7526                                         $cgi->a({-href => href(-replay=>1,
7527                                                                hash=>$hash, hash_parent=>'--cc')},
7528                                                 'compact');
7529                         }
7530                         $formats_nav .=
7531                                 ' (merge: ' .
7532                                 join(' ', map {
7533                                         $cgi->a({-href => href(-replay=>1,
7534                                                                hash=>$_, hash_base=>undef)},
7535                                                 esc_html(substr($_, 0, 7)));
7536                                 } @{$co{'parents'}} ) .
7537                                 ')';
7538                 }
7539         }
7540
7541         my $hash_parent_param = $hash_parent;
7542         if (!defined $hash_parent_param) {
7543                 # --cc for multiple parents, --root for parentless
7544                 $hash_parent_param =
7545                         @{$co{'parents'}} > 1 ? '--cc' : $co{'parent'} || '--root';
7546         }
7547
7548         # read commitdiff
7549         my $fd;
7550         my @difftree;
7551         if ($format eq 'html') {
7552                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7553                         "--no-commit-id", "--patch-with-raw", "--full-index",
7554                         $hash_parent_param, $hash, "--"
7555                         or die_error(500, "Open git-diff-tree failed");
7556
7557                 while (my $line = <$fd>) {
7558                         chomp $line;
7559                         # empty line ends raw part of diff-tree output
7560                         last unless $line;
7561                         push @difftree, scalar parse_difftree_raw_line($line);
7562                 }
7563
7564         } elsif ($format eq 'plain') {
7565                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7566                         '-p', $hash_parent_param, $hash, "--"
7567                         or die_error(500, "Open git-diff-tree failed");
7568         } elsif ($format eq 'patch') {
7569                 # For commit ranges, we limit the output to the number of
7570                 # patches specified in the 'patches' feature.
7571                 # For single commits, we limit the output to a single patch,
7572                 # diverging from the git-format-patch default.
7573                 my @commit_spec = ();
7574                 if ($hash_parent) {
7575                         if ($patch_max > 0) {
7576                                 push @commit_spec, "-$patch_max";
7577                         }
7578                         push @commit_spec, '-n', "$hash_parent..$hash";
7579                 } else {
7580                         if ($params{-single}) {
7581                                 push @commit_spec, '-1';
7582                         } else {
7583                                 if ($patch_max > 0) {
7584                                         push @commit_spec, "-$patch_max";
7585                                 }
7586                                 push @commit_spec, "-n";
7587                         }
7588                         push @commit_spec, '--root', $hash;
7589                 }
7590                 open $fd, "-|", git_cmd(), "format-patch", @diff_opts,
7591                         '--encoding=utf8', '--stdout', @commit_spec
7592                         or die_error(500, "Open git-format-patch failed");
7593         } else {
7594                 die_error(400, "Unknown commitdiff format");
7595         }
7596
7597         # non-textual hash id's can be cached
7598         my $expires;
7599         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7600                 $expires = "+1d";
7601         }
7602
7603         # write commit message
7604         if ($format eq 'html') {
7605                 my $refs = git_get_references();
7606                 my $ref = format_ref_marker($refs, $co{'id'});
7607
7608                 git_header_html(undef, $expires);
7609                 git_print_page_nav('commitdiff','', $hash,$co{'tree'},$hash, $formats_nav);
7610                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash);
7611                 print "<div class=\"title_text\">\n" .
7612                       "<table class=\"object_header\">\n";
7613                 git_print_authorship_rows(\%co);
7614                 print "</table>".
7615                       "</div>\n";
7616                 print "<div class=\"page_body\">\n";
7617                 if (@{$co{'comment'}} > 1) {
7618                         print "<div class=\"log\">\n";
7619                         git_print_log($co{'comment'}, -final_empty_line=> 1, -remove_title => 1);
7620                         print "</div>\n"; # class="log"
7621                 }
7622
7623         } elsif ($format eq 'plain') {
7624                 my $refs = git_get_references("tags");
7625                 my $tagname = git_get_rev_name_tags($hash);
7626                 my $filename = basename($project) . "-$hash.patch";
7627
7628                 print $cgi->header(
7629                         -type => 'text/plain',
7630                         -charset => 'utf-8',
7631                         -expires => $expires,
7632                         -content_disposition => 'inline; filename="' . "$filename" . '"');
7633                 my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
7634                 print "From: " . to_utf8($co{'author'}) . "\n";
7635                 print "Date: $ad{'rfc2822'} ($ad{'tz_local'})\n";
7636                 print "Subject: " . to_utf8($co{'title'}) . "\n";
7637
7638                 print "X-Git-Tag: $tagname\n" if $tagname;
7639                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7640
7641                 foreach my $line (@{$co{'comment'}}) {
7642                         print to_utf8($line) . "\n";
7643                 }
7644                 print "---\n\n";
7645         } elsif ($format eq 'patch') {
7646                 my $filename = basename($project) . "-$hash.patch";
7647
7648                 print $cgi->header(
7649                         -type => 'text/plain',
7650                         -charset => 'utf-8',
7651                         -expires => $expires,
7652                         -content_disposition => 'inline; filename="' . "$filename" . '"');
7653         }
7654
7655         # write patch
7656         if ($format eq 'html') {
7657                 my $use_parents = !defined $hash_parent ||
7658                         $hash_parent eq '-c' || $hash_parent eq '--cc';
7659                 git_difftree_body(\@difftree, $hash,
7660                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
7661                 print "<br/>\n";
7662
7663                 git_patchset_body($fd, $diff_style,
7664                                   \@difftree, $hash,
7665                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
7666                 close $fd;
7667                 print "</div>\n"; # class="page_body"
7668                 git_footer_html();
7669
7670         } elsif ($format eq 'plain') {
7671                 local $/ = undef;
7672                 print <$fd>;
7673                 close $fd
7674                         or print "Reading git-diff-tree failed\n";
7675         } elsif ($format eq 'patch') {
7676                 local $/ = undef;
7677                 print <$fd>;
7678                 close $fd
7679                         or print "Reading git-format-patch failed\n";
7680         }
7681 }
7682
7683 sub git_commitdiff_plain {
7684         git_commitdiff(-format => 'plain');
7685 }
7686
7687 # format-patch-style patches
7688 sub git_patch {
7689         git_commitdiff(-format => 'patch', -single => 1);
7690 }
7691
7692 sub git_patches {
7693         git_commitdiff(-format => 'patch');
7694 }
7695
7696 sub git_history {
7697         git_log_generic('history', \&git_history_body,
7698                         $hash_base, $hash_parent_base,
7699                         $file_name, $hash);
7700 }
7701
7702 sub git_search {
7703         $searchtype ||= 'commit';
7704
7705         # check if appropriate features are enabled
7706         gitweb_check_feature('search')
7707                 or die_error(403, "Search is disabled");
7708         if ($searchtype eq 'pickaxe') {
7709                 # pickaxe may take all resources of your box and run for several minutes
7710                 # with every query - so decide by yourself how public you make this feature
7711                 gitweb_check_feature('pickaxe')
7712                         or die_error(403, "Pickaxe search is disabled");
7713         }
7714         if ($searchtype eq 'grep') {
7715                 # grep search might be potentially CPU-intensive, too
7716                 gitweb_check_feature('grep')
7717                         or die_error(403, "Grep search is disabled");
7718         }
7719
7720         if (!defined $searchtext) {
7721                 die_error(400, "Text field is empty");
7722         }
7723         if (!defined $hash) {
7724                 $hash = git_get_head_hash($project);
7725         }
7726         my %co = parse_commit($hash);
7727         if (!%co) {
7728                 die_error(404, "Unknown commit object");
7729         }
7730         if (!defined $page) {
7731                 $page = 0;
7732         }
7733
7734         if ($searchtype eq 'commit' ||
7735             $searchtype eq 'author' ||
7736             $searchtype eq 'committer') {
7737                 git_search_message(%co);
7738         } elsif ($searchtype eq 'pickaxe') {
7739                 git_search_changes(%co);
7740         } elsif ($searchtype eq 'grep') {
7741                 git_search_files(%co);
7742         } else {
7743                 die_error(400, "Unknown search type");
7744         }
7745 }
7746
7747 sub git_search_help {
7748         git_header_html();
7749         git_print_page_nav('','', $hash,$hash,$hash);
7750         print <<EOT;
7751 <p><strong>Pattern</strong> is by default a normal string that is matched precisely (but without
7752 regard to case, except in the case of pickaxe). However, when you check the <em>re</em> checkbox,
7753 the pattern entered is recognized as the POSIX extended
7754 <a href="http://en.wikipedia.org/wiki/Regular_expression">regular expression</a> (also case
7755 insensitive).</p>
7756 <dl>
7757 <dt><b>commit</b></dt>
7758 <dd>The commit messages and authorship information will be scanned for the given pattern.</dd>
7759 EOT
7760         my $have_grep = gitweb_check_feature('grep');
7761         if ($have_grep) {
7762                 print <<EOT;
7763 <dt><b>grep</b></dt>
7764 <dd>All files in the currently selected tree (HEAD unless you are explicitly browsing
7765     a different one) are searched for the given pattern. On large trees, this search can take
7766 a while and put some strain on the server, so please use it with some consideration. Note that
7767 due to git-grep peculiarity, currently if regexp mode is turned off, the matches are
7768 case-sensitive.</dd>
7769 EOT
7770         }
7771         print <<EOT;
7772 <dt><b>author</b></dt>
7773 <dd>Name and e-mail of the change author and date of birth of the patch will be scanned for the given pattern.</dd>
7774 <dt><b>committer</b></dt>
7775 <dd>Name and e-mail of the committer and date of commit will be scanned for the given pattern.</dd>
7776 EOT
7777         my $have_pickaxe = gitweb_check_feature('pickaxe');
7778         if ($have_pickaxe) {
7779                 print <<EOT;
7780 <dt><b>pickaxe</b></dt>
7781 <dd>All commits that caused the string to appear or disappear from any file (changes that
7782 added, removed or "modified" the string) will be listed. This search can take a while and
7783 takes a lot of strain on the server, so please use it wisely. Note that since you may be
7784 interested even in changes just changing the case as well, this search is case sensitive.</dd>
7785 EOT
7786         }
7787         print "</dl>\n";
7788         git_footer_html();
7789 }
7790
7791 sub git_shortlog {
7792         git_log_generic('shortlog', \&git_shortlog_body,
7793                         $hash, $hash_parent);
7794 }
7795
7796 ## ......................................................................
7797 ## feeds (RSS, Atom; OPML)
7798
7799 sub git_feed {
7800         my $format = shift || 'atom';
7801         my $have_blame = gitweb_check_feature('blame');
7802
7803         # Atom: http://www.atomenabled.org/developers/syndication/
7804         # RSS:  http://www.notestips.com/80256B3A007F2692/1/NAMO5P9UPQ
7805         if ($format ne 'rss' && $format ne 'atom') {
7806                 die_error(400, "Unknown web feed format");
7807         }
7808
7809         # log/feed of current (HEAD) branch, log of given branch, history of file/directory
7810         my $head = $hash || 'HEAD';
7811         my @commitlist = parse_commits($head, 150, 0, $file_name);
7812
7813         my %latest_commit;
7814         my %latest_date;
7815         my $content_type = "application/$format+xml";
7816         if (defined $cgi->http('HTTP_ACCEPT') &&
7817                  $cgi->Accept('text/xml') > $cgi->Accept($content_type)) {
7818                 # browser (feed reader) prefers text/xml
7819                 $content_type = 'text/xml';
7820         }
7821         if (defined($commitlist[0])) {
7822                 %latest_commit = %{$commitlist[0]};
7823                 my $latest_epoch = $latest_commit{'committer_epoch'};
7824                 %latest_date   = parse_date($latest_epoch, $latest_commit{'comitter_tz'});
7825                 my $if_modified = $cgi->http('IF_MODIFIED_SINCE');
7826                 if (defined $if_modified) {
7827                         my $since;
7828                         if (eval { require HTTP::Date; 1; }) {
7829                                 $since = HTTP::Date::str2time($if_modified);
7830                         } elsif (eval { require Time::ParseDate; 1; }) {
7831                                 $since = Time::ParseDate::parsedate($if_modified, GMT => 1);
7832                         }
7833                         if (defined $since && $latest_epoch <= $since) {
7834                                 print $cgi->header(
7835                                         -type => $content_type,
7836                                         -charset => 'utf-8',
7837                                         -last_modified => $latest_date{'rfc2822'},
7838                                         -status => '304 Not Modified');
7839                                 return;
7840                         }
7841                 }
7842                 print $cgi->header(
7843                         -type => $content_type,
7844                         -charset => 'utf-8',
7845                         -last_modified => $latest_date{'rfc2822'});
7846         } else {
7847                 print $cgi->header(
7848                         -type => $content_type,
7849                         -charset => 'utf-8');
7850         }
7851
7852         # Optimization: skip generating the body if client asks only
7853         # for Last-Modified date.
7854         return if ($cgi->request_method() eq 'HEAD');
7855
7856         # header variables
7857         my $title = "$site_name - $project/$action";
7858         my $feed_type = 'log';
7859         if (defined $hash) {
7860                 $title .= " - '$hash'";
7861                 $feed_type = 'branch log';
7862                 if (defined $file_name) {
7863                         $title .= " :: $file_name";
7864                         $feed_type = 'history';
7865                 }
7866         } elsif (defined $file_name) {
7867                 $title .= " - $file_name";
7868                 $feed_type = 'history';
7869         }
7870         $title .= " $feed_type";
7871         my $descr = git_get_project_description($project);
7872         if (defined $descr) {
7873                 $descr = esc_html($descr);
7874         } else {
7875                 $descr = "$project " .
7876                          ($format eq 'rss' ? 'RSS' : 'Atom') .
7877                          " feed";
7878         }
7879         my $owner = git_get_project_owner($project);
7880         $owner = esc_html($owner);
7881
7882         #header
7883         my $alt_url;
7884         if (defined $file_name) {
7885                 $alt_url = href(-full=>1, action=>"history", hash=>$hash, file_name=>$file_name);
7886         } elsif (defined $hash) {
7887                 $alt_url = href(-full=>1, action=>"log", hash=>$hash);
7888         } else {
7889                 $alt_url = href(-full=>1, action=>"summary");
7890         }
7891         print qq!<?xml version="1.0" encoding="utf-8"?>\n!;
7892         if ($format eq 'rss') {
7893                 print <<XML;
7894 <rss version="2.0" xmlns:content="http://purl.org/rss/1.0/modules/content/">
7895 <channel>
7896 XML
7897                 print "<title>$title</title>\n" .
7898                       "<link>$alt_url</link>\n" .
7899                       "<description>$descr</description>\n" .
7900                       "<language>en</language>\n" .
7901                       # project owner is responsible for 'editorial' content
7902                       "<managingEditor>$owner</managingEditor>\n";
7903                 if (defined $logo || defined $favicon) {
7904                         # prefer the logo to the favicon, since RSS
7905                         # doesn't allow both
7906                         my $img = esc_url($logo || $favicon);
7907                         print "<image>\n" .
7908                               "<url>$img</url>\n" .
7909                               "<title>$title</title>\n" .
7910                               "<link>$alt_url</link>\n" .
7911                               "</image>\n";
7912                 }
7913                 if (%latest_date) {
7914                         print "<pubDate>$latest_date{'rfc2822'}</pubDate>\n";
7915                         print "<lastBuildDate>$latest_date{'rfc2822'}</lastBuildDate>\n";
7916                 }
7917                 print "<generator>gitweb v.$version/$git_version</generator>\n";
7918         } elsif ($format eq 'atom') {
7919                 print <<XML;
7920 <feed xmlns="http://www.w3.org/2005/Atom">
7921 XML
7922                 print "<title>$title</title>\n" .
7923                       "<subtitle>$descr</subtitle>\n" .
7924                       '<link rel="alternate" type="text/html" href="' .
7925                       $alt_url . '" />' . "\n" .
7926                       '<link rel="self" type="' . $content_type . '" href="' .
7927                       $cgi->self_url() . '" />' . "\n" .
7928                       "<id>" . href(-full=>1) . "</id>\n" .
7929                       # use project owner for feed author
7930                       "<author><name>$owner</name></author>\n";
7931                 if (defined $favicon) {
7932                         print "<icon>" . esc_url($favicon) . "</icon>\n";
7933                 }
7934                 if (defined $logo) {
7935                         # not twice as wide as tall: 72 x 27 pixels
7936                         print "<logo>" . esc_url($logo) . "</logo>\n";
7937                 }
7938                 if (! %latest_date) {
7939                         # dummy date to keep the feed valid until commits trickle in:
7940                         print "<updated>1970-01-01T00:00:00Z</updated>\n";
7941                 } else {
7942                         print "<updated>$latest_date{'iso-8601'}</updated>\n";
7943                 }
7944                 print "<generator version='$version/$git_version'>gitweb</generator>\n";
7945         }
7946
7947         # contents
7948         for (my $i = 0; $i <= $#commitlist; $i++) {
7949                 my %co = %{$commitlist[$i]};
7950                 my $commit = $co{'id'};
7951                 # we read 150, we always show 30 and the ones more recent than 48 hours
7952                 if (($i >= 20) && ((time - $co{'author_epoch'}) > 48*60*60)) {
7953                         last;
7954                 }
7955                 my %cd = parse_date($co{'author_epoch'}, $co{'author_tz'});
7956
7957                 # get list of changed files
7958                 open my $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7959                         $co{'parent'} || "--root",
7960                         $co{'id'}, "--", (defined $file_name ? $file_name : ())
7961                         or next;
7962                 my @difftree = map { chomp; $_ } <$fd>;
7963                 close $fd
7964                         or next;
7965
7966                 # print element (entry, item)
7967                 my $co_url = href(-full=>1, action=>"commitdiff", hash=>$commit);
7968                 if ($format eq 'rss') {
7969                         print "<item>\n" .
7970                               "<title>" . esc_html($co{'title'}) . "</title>\n" .
7971                               "<author>" . esc_html($co{'author'}) . "</author>\n" .
7972                               "<pubDate>$cd{'rfc2822'}</pubDate>\n" .
7973                               "<guid isPermaLink=\"true\">$co_url</guid>\n" .
7974                               "<link>$co_url</link>\n" .
7975                               "<description>" . esc_html($co{'title'}) . "</description>\n" .
7976                               "<content:encoded>" .
7977                               "<![CDATA[\n";
7978                 } elsif ($format eq 'atom') {
7979                         print "<entry>\n" .
7980                               "<title type=\"html\">" . esc_html($co{'title'}) . "</title>\n" .
7981                               "<updated>$cd{'iso-8601'}</updated>\n" .
7982                               "<author>\n" .
7983                               "  <name>" . esc_html($co{'author_name'}) . "</name>\n";
7984                         if ($co{'author_email'}) {
7985                                 print "  <email>" . esc_html($co{'author_email'}) . "</email>\n";
7986                         }
7987                         print "</author>\n" .
7988                               # use committer for contributor
7989                               "<contributor>\n" .
7990                               "  <name>" . esc_html($co{'committer_name'}) . "</name>\n";
7991                         if ($co{'committer_email'}) {
7992                                 print "  <email>" . esc_html($co{'committer_email'}) . "</email>\n";
7993                         }
7994                         print "</contributor>\n" .
7995                               "<published>$cd{'iso-8601'}</published>\n" .
7996                               "<link rel=\"alternate\" type=\"text/html\" href=\"$co_url\" />\n" .
7997                               "<id>$co_url</id>\n" .
7998                               "<content type=\"xhtml\" xml:base=\"" . esc_url($my_url) . "\">\n" .
7999                               "<div xmlns=\"http://www.w3.org/1999/xhtml\">\n";
8000                 }
8001                 my $comment = $co{'comment'};
8002                 print "<pre>\n";
8003                 foreach my $line (@$comment) {
8004                         $line = esc_html($line);
8005                         print "$line\n";
8006                 }
8007                 print "</pre><ul>\n";
8008                 foreach my $difftree_line (@difftree) {
8009                         my %difftree = parse_difftree_raw_line($difftree_line);
8010                         next if !$difftree{'from_id'};
8011
8012                         my $file = $difftree{'file'} || $difftree{'to_file'};
8013
8014                         print "<li>" .
8015                               "[" .
8016                               $cgi->a({-href => href(-full=>1, action=>"blobdiff",
8017                                                      hash=>$difftree{'to_id'}, hash_parent=>$difftree{'from_id'},
8018                                                      hash_base=>$co{'id'}, hash_parent_base=>$co{'parent'},
8019                                                      file_name=>$file, file_parent=>$difftree{'from_file'}),
8020                                       -title => "diff"}, 'D');
8021                         if ($have_blame) {
8022                                 print $cgi->a({-href => href(-full=>1, action=>"blame",
8023                                                              file_name=>$file, hash_base=>$commit),
8024                                               -title => "blame"}, 'B');
8025                         }
8026                         # if this is not a feed of a file history
8027                         if (!defined $file_name || $file_name ne $file) {
8028                                 print $cgi->a({-href => href(-full=>1, action=>"history",
8029                                                              file_name=>$file, hash=>$commit),
8030                                               -title => "history"}, 'H');
8031                         }
8032                         $file = esc_path($file);
8033                         print "] ".
8034                               "$file</li>\n";
8035                 }
8036                 if ($format eq 'rss') {
8037                         print "</ul>]]>\n" .
8038                               "</content:encoded>\n" .
8039                               "</item>\n";
8040                 } elsif ($format eq 'atom') {
8041                         print "</ul>\n</div>\n" .
8042                               "</content>\n" .
8043                               "</entry>\n";
8044                 }
8045         }
8046
8047         # end of feed
8048         if ($format eq 'rss') {
8049                 print "</channel>\n</rss>\n";
8050         } elsif ($format eq 'atom') {
8051                 print "</feed>\n";
8052         }
8053 }
8054
8055 sub git_rss {
8056         git_feed('rss');
8057 }
8058
8059 sub git_atom {
8060         git_feed('atom');
8061 }
8062
8063 sub git_opml {
8064         my @list = git_get_projects_list($project_filter, $strict_export);
8065         if (!@list) {
8066                 die_error(404, "No projects found");
8067         }
8068
8069         print $cgi->header(
8070                 -type => 'text/xml',
8071                 -charset => 'utf-8',
8072                 -content_disposition => 'inline; filename="opml.xml"');
8073
8074         my $title = esc_html($site_name);
8075         my $filter = " within subdirectory ";
8076         if (defined $project_filter) {
8077                 $filter .= esc_html($project_filter);
8078         } else {
8079                 $filter = "";
8080         }
8081         print <<XML;
8082 <?xml version="1.0" encoding="utf-8"?>
8083 <opml version="1.0">
8084 <head>
8085   <title>$title OPML Export$filter</title>
8086 </head>
8087 <body>
8088 <outline text="git RSS feeds">
8089 XML
8090
8091         foreach my $pr (@list) {
8092                 my %proj = %$pr;
8093                 my $head = git_get_head_hash($proj{'path'});
8094                 if (!defined $head) {
8095                         next;
8096                 }
8097                 $git_dir = "$projectroot/$proj{'path'}";
8098                 my %co = parse_commit($head);
8099                 if (!%co) {
8100                         next;
8101                 }
8102
8103                 my $path = esc_html(chop_str($proj{'path'}, 25, 5));
8104                 my $rss  = href('project' => $proj{'path'}, 'action' => 'rss', -full => 1);
8105                 my $html = href('project' => $proj{'path'}, 'action' => 'summary', -full => 1);
8106                 print "<outline type=\"rss\" text=\"$path\" title=\"$path\" xmlUrl=\"$rss\" htmlUrl=\"$html\"/>\n";
8107         }
8108         print <<XML;
8109 </outline>
8110 </body>
8111 </opml>
8112 XML
8113 }