Lady’s Gitweb - Gitweb/blob - gitweb.perl

   1 #!/usr/bin/perl
   2
   3 # gitweb - simple web interface to track changes in git repositories
   4 #
   5 # (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
   6 # (C) 2005, Christian Gierke
   7 #
   8 # This program is licensed under the GPLv2
   9
  10 use 5.008;
  11 use strict;
  12 use warnings;
  13 use CGI qw(:standard :escapeHTML -nosticky);
  14 use CGI::Util qw(unescape);
  15 use CGI::Carp qw(fatalsToBrowser set_message);
  16 use Encode;
  17 use Fcntl ':mode';
  18 use File::Find qw();
  19 use File::Basename qw(basename);
  20 use Time::HiRes qw(gettimeofday tv_interval);
  21 binmode STDOUT, ':utf8';
  22
  23 our $t0 = [ gettimeofday() ];
  24 our $number_of_git_cmds = 0;
  25
  26 BEGIN {
  27         CGI->compile() if $ENV{'MOD_PERL'};
  28 }
  29
  30 our $version = "++GIT_VERSION++";
  31
  32 our ($my_url, $my_uri, $base_url, $path_info, $home_link);
  33 sub evaluate_uri {
  34         our $cgi;
  35
  36         our $my_url = $cgi->url();
  37         our $my_uri = $cgi->url(-absolute => 1);
  38
  39         # Base URL for relative URLs in gitweb ($logo, $favicon, ...),
  40         # needed and used only for URLs with nonempty PATH_INFO
  41         our $base_url = $my_url;
  42
  43         # When the script is used as DirectoryIndex, the URL does not contain the name
  44         # of the script file itself, and $cgi->url() fails to strip PATH_INFO, so we
  45         # have to do it ourselves. We make $path_info global because it's also used
  46         # later on.
  47         #
  48         # Another issue with the script being the DirectoryIndex is that the resulting
  49         # $my_url data is not the full script URL: this is good, because we want
  50         # generated links to keep implying the script name if it wasn't explicitly
  51         # indicated in the URL we're handling, but it means that $my_url cannot be used
  52         # as base URL.
  53         # Therefore, if we needed to strip PATH_INFO, then we know that we have
  54         # to build the base URL ourselves:
  55         our $path_info = decode_utf8($ENV{"PATH_INFO"});
  56         if ($path_info) {
  57                 if ($my_url =~ s,\Q$path_info\E$,, &&
  58                     $my_uri =~ s,\Q$path_info\E$,, &&
  59                     defined $ENV{'SCRIPT_NAME'}) {
  60                         $base_url = $cgi->url(-base => 1) . $ENV{'SCRIPT_NAME'};
  61                 }
  62         }
  63
  64         # target of the home link on top of all pages
  65         our $home_link = $my_uri || "/";
  66 }
  67
  68 # core git executable to use
  69 # this can just be "git" if your webserver has a sensible PATH
  70 our $GIT = "++GIT_BINDIR++/git";
  71
  72 # absolute fs-path which will be prepended to the project path
  73 #our $projectroot = "/pub/scm";
  74 our $projectroot = "++GITWEB_PROJECTROOT++";
  75
  76 # fs traversing limit for getting project list
  77 # the number is relative to the projectroot
  78 our $project_maxdepth = "++GITWEB_PROJECT_MAXDEPTH++";
  79
  80 # string of the home link on top of all pages
  81 our $home_link_str = "++GITWEB_HOME_LINK_STR++";
  82
  83 # name of your site or organization to appear in page titles
  84 # replace this with something more descriptive for clearer bookmarks
  85 our $site_name = "++GITWEB_SITENAME++"
  86                  || ($ENV{'SERVER_NAME'} || "Untitled") . " Git";
  87
  88 # html snippet to include in the <head> section of each page
  89 our $site_html_head_string = "++GITWEB_SITE_HTML_HEAD_STRING++";
  90 # filename of html text to include at top of each page
  91 our $site_header = "++GITWEB_SITE_HEADER++";
  92 # html text to include at home page
  93 our $home_text = "++GITWEB_HOMETEXT++";
  94 # filename of html text to include at bottom of each page
  95 our $site_footer = "++GITWEB_SITE_FOOTER++";
  96
  97 # URI of stylesheets
  98 our @stylesheets = ("++GITWEB_CSS++");
  99 # URI of a single stylesheet, which can be overridden in GITWEB_CONFIG.
 100 our $stylesheet = undef;
 101
 102 # URI of GIT logo (72x27 size)
 103 our $logo = "++GITWEB_LOGO++";
 104 # URI of GIT favicon, assumed to be image/png type
 105 our $favicon = "++GITWEB_FAVICON++";
 106 # URI of gitweb.js (JavaScript code for gitweb)
 107 our $javascript = "++GITWEB_JS++";
 108
 109 # URI and label (title) of GIT logo link
 110 #our $logo_url = "http://www.kernel.org/pub/software/scm/git/docs/";
 111 #our $logo_label = "git documentation";
 112 our $logo_url = "http://git-scm.com/";
 113 our $logo_label = "git homepage";
 114
 115 # source of projects list
 116 our $projects_list = "++GITWEB_LIST++";
 117
 118 # the width (in characters) of the projects list "Description" column
 119 our $projects_list_description_width = 25;
 120
 121 # group projects by category on the projects list
 122 # (enabled if this variable evaluates to true)
 123 our $projects_list_group_categories = 0;
 124
 125 # default category if none specified
 126 # (leave the empty string for no category)
 127 our $project_list_default_category = "";
 128
 129 # default order of projects list
 130 # valid values are none, project, descr, owner, and age
 131 our $default_projects_order = "project";
 132
 133 # show repository only if this file exists
 134 # (only effective if this variable evaluates to true)
 135 our $export_ok = "++GITWEB_EXPORT_OK++";
 136
 137 # don't generate age column on the projects list page
 138 our $omit_age_column = 0;
 139
 140 # don't generate information about owners of repositories
 141 our $omit_owner=0;
 142
 143 # show repository only if this subroutine returns true
 144 # when given the path to the project, for example:
 145 #    sub { return -e "$_[0]/git-daemon-export-ok"; }
 146 our $export_auth_hook = undef;
 147
 148 # only allow viewing of repositories also shown on the overview page
 149 our $strict_export = "++GITWEB_STRICT_EXPORT++";
 150
 151 # list of git base URLs used for URL to where fetch project from,
 152 # i.e. full URL is "$git_base_url/$project"
 153 our @git_base_url_list = grep { $_ ne '' } ("++GITWEB_BASE_URL++");
 154
 155 # default blob_plain mimetype and default charset for text/plain blob
 156 our $default_blob_plain_mimetype = 'text/plain';
 157 our $default_text_plain_charset  = undef;
 158
 159 # file to use for guessing MIME types before trying /etc/mime.types
 160 # (relative to the current git repository)
 161 our $mimetypes_file = undef;
 162
 163 # assume this charset if line contains non-UTF-8 characters;
 164 # it should be valid encoding (see Encoding::Supported(3pm) for list),
 165 # for which encoding all byte sequences are valid, for example
 166 # 'iso-8859-1' aka 'latin1' (it is decoded without checking, so it
 167 # could be even 'utf-8' for the old behavior)
 168 our $fallback_encoding = 'latin1';
 169
 170 # rename detection options for git-diff and git-diff-tree
 171 # - default is '-M', with the cost proportional to
 172 #   (number of removed files) * (number of new files).
 173 # - more costly is '-C' (which implies '-M'), with the cost proportional to
 174 #   (number of changed files + number of removed files) * (number of new files)
 175 # - even more costly is '-C', '--find-copies-harder' with cost
 176 #   (number of files in the original tree) * (number of new files)
 177 # - one might want to include '-B' option, e.g. '-B', '-M'
 178 our @diff_opts = ('-M'); # taken from git_commit
 179
 180 # Disables features that would allow repository owners to inject script into
 181 # the gitweb domain.
 182 our $prevent_xss = 0;
 183
 184 # Path to the highlight executable to use (must be the one from
 185 # http://www.andre-simon.de due to assumptions about parameters and output).
 186 # Useful if highlight is not installed on your webserver's PATH.
 187 # [Default: highlight]
 188 our $highlight_bin = "++HIGHLIGHT_BIN++";
 189
 190 # information about snapshot formats that gitweb is capable of serving
 191 our %known_snapshot_formats = (
 192         # name => {
 193         #       'display' => display name,
 194         #       'type' => mime type,
 195         #       'suffix' => filename suffix,
 196         #       'format' => --format for git-archive,
 197         #       'compressor' => [compressor command and arguments]
 198         #                       (array reference, optional)
 199         #       'disabled' => boolean (optional)}
 200         #
 201         'tgz' => {
 202                 'display' => 'tar.gz',
 203                 'type' => 'application/x-gzip',
 204                 'suffix' => '.tar.gz',
 205                 'format' => 'tar',
 206                 'compressor' => ['gzip', '-n']},
 207
 208         'tbz2' => {
 209                 'display' => 'tar.bz2',
 210                 'type' => 'application/x-bzip2',
 211                 'suffix' => '.tar.bz2',
 212                 'format' => 'tar',
 213                 'compressor' => ['bzip2']},
 214
 215         'txz' => {
 216                 'display' => 'tar.xz',
 217                 'type' => 'application/x-xz',
 218                 'suffix' => '.tar.xz',
 219                 'format' => 'tar',
 220                 'compressor' => ['xz'],
 221                 'disabled' => 1},
 222
 223         'zip' => {
 224                 'display' => 'zip',
 225                 'type' => 'application/x-zip',
 226                 'suffix' => '.zip',
 227                 'format' => 'zip'},
 228 );
 229
 230 # Aliases so we understand old gitweb.snapshot values in repository
 231 # configuration.
 232 our %known_snapshot_format_aliases = (
 233         'gzip'  => 'tgz',
 234         'bzip2' => 'tbz2',
 235         'xz'    => 'txz',
 236
 237         # backward compatibility: legacy gitweb config support
 238         'x-gzip' => undef, 'gz' => undef,
 239         'x-bzip2' => undef, 'bz2' => undef,
 240         'x-zip' => undef, '' => undef,
 241 );
 242
 243 # Pixel sizes for icons and avatars. If the default font sizes or lineheights
 244 # are changed, it may be appropriate to change these values too via
 245 # $GITWEB_CONFIG.
 246 our %avatar_size = (
 247         'default' => 16,
 248         'double'  => 32
 249 );
 250
 251 # Used to set the maximum load that we will still respond to gitweb queries.
 252 # If server load exceed this value then return "503 server busy" error.
 253 # If gitweb cannot determined server load, it is taken to be 0.
 254 # Leave it undefined (or set to 'undef') to turn off load checking.
 255 our $maxload = 300;
 256
 257 # configuration for 'highlight' (http://www.andre-simon.de/)
 258 # match by basename
 259 our %highlight_basename = (
 260         #'Program' => 'py',
 261         #'Library' => 'py',
 262         'SConstruct' => 'py', # SCons equivalent of Makefile
 263         'Makefile' => 'make',
 264 );
 265 # match by extension
 266 our %highlight_ext = (
 267         # main extensions, defining name of syntax;
 268         # see files in /usr/share/highlight/langDefs/ directory
 269         map { $_ => $_ }
 270                 qw(py c cpp rb java css php sh pl js tex bib xml awk bat ini spec tcl sql make),
 271         # alternate extensions, see /etc/highlight/filetypes.conf
 272         'h' => 'c',
 273         map { $_ => 'sh'  } qw(bash zsh ksh),
 274         map { $_ => 'cpp' } qw(cxx c++ cc),
 275         map { $_ => 'php' } qw(php3 php4 php5 phps),
 276         map { $_ => 'pl'  } qw(perl pm), # perhaps also 'cgi'
 277         map { $_ => 'make'} qw(mak mk),
 278         map { $_ => 'xml' } qw(xhtml html htm),
 279 );
 280
 281 # You define site-wide feature defaults here; override them with
 282 # $GITWEB_CONFIG as necessary.
 283 our %feature = (
 284         # feature => {
 285         #       'sub' => feature-sub (subroutine),
 286         #       'override' => allow-override (boolean),
 287         #       'default' => [ default options...] (array reference)}
 288         #
 289         # if feature is overridable (it means that allow-override has true value),
 290         # then feature-sub will be called with default options as parameters;
 291         # return value of feature-sub indicates if to enable specified feature
 292         #
 293         # if there is no 'sub' key (no feature-sub), then feature cannot be
 294         # overridden
 295         #
 296         # use gitweb_get_feature(<feature>) to retrieve the <feature> value
 297         # (an array) or gitweb_check_feature(<feature>) to check if <feature>
 298         # is enabled
 299
 300         # Enable the 'blame' blob view, showing the last commit that modified
 301         # each line in the file. This can be very CPU-intensive.
 302
 303         # To enable system wide have in $GITWEB_CONFIG
 304         # $feature{'blame'}{'default'} = [1];
 305         # To have project specific config enable override in $GITWEB_CONFIG
 306         # $feature{'blame'}{'override'} = 1;
 307         # and in project config gitweb.blame = 0|1;
 308         'blame' => {
 309                 'sub' => sub { feature_bool('blame', @_) },
 310                 'override' => 0,
 311                 'default' => [0]},
 312
 313         # Enable the 'snapshot' link, providing a compressed archive of any
 314         # tree. This can potentially generate high traffic if you have large
 315         # project.
 316
 317         # Value is a list of formats defined in %known_snapshot_formats that
 318         # you wish to offer.
 319         # To disable system wide have in $GITWEB_CONFIG
 320         # $feature{'snapshot'}{'default'} = [];
 321         # To have project specific config enable override in $GITWEB_CONFIG
 322         # $feature{'snapshot'}{'override'} = 1;
 323         # and in project config, a comma-separated list of formats or "none"
 324         # to disable.  Example: gitweb.snapshot = tbz2,zip;
 325         'snapshot' => {
 326                 'sub' => \&feature_snapshot,
 327                 'override' => 0,
 328                 'default' => ['tgz']},
 329
 330         # Enable text search, which will list the commits which match author,
 331         # committer or commit text to a given string.  Enabled by default.
 332         # Project specific override is not supported.
 333         #
 334         # Note that this controls all search features, which means that if
 335         # it is disabled, then 'grep' and 'pickaxe' search would also be
 336         # disabled.
 337         'search' => {
 338                 'override' => 0,
 339                 'default' => [1]},
 340
 341         # Enable grep search, which will list the files in currently selected
 342         # tree containing the given string. Enabled by default. This can be
 343         # potentially CPU-intensive, of course.
 344         # Note that you need to have 'search' feature enabled too.
 345
 346         # To enable system wide have in $GITWEB_CONFIG
 347         # $feature{'grep'}{'default'} = [1];
 348         # To have project specific config enable override in $GITWEB_CONFIG
 349         # $feature{'grep'}{'override'} = 1;
 350         # and in project config gitweb.grep = 0|1;
 351         'grep' => {
 352                 'sub' => sub { feature_bool('grep', @_) },
 353                 'override' => 0,
 354                 'default' => [1]},
 355
 356         # Enable the pickaxe search, which will list the commits that modified
 357         # a given string in a file. This can be practical and quite faster
 358         # alternative to 'blame', but still potentially CPU-intensive.
 359         # Note that you need to have 'search' feature enabled too.
 360
 361         # To enable system wide have in $GITWEB_CONFIG
 362         # $feature{'pickaxe'}{'default'} = [1];
 363         # To have project specific config enable override in $GITWEB_CONFIG
 364         # $feature{'pickaxe'}{'override'} = 1;
 365         # and in project config gitweb.pickaxe = 0|1;
 366         'pickaxe' => {
 367                 'sub' => sub { feature_bool('pickaxe', @_) },
 368                 'override' => 0,
 369                 'default' => [1]},
 370
 371         # Enable showing size of blobs in a 'tree' view, in a separate
 372         # column, similar to what 'ls -l' does.  This cost a bit of IO.
 373
 374         # To disable system wide have in $GITWEB_CONFIG
 375         # $feature{'show-sizes'}{'default'} = [0];
 376         # To have project specific config enable override in $GITWEB_CONFIG
 377         # $feature{'show-sizes'}{'override'} = 1;
 378         # and in project config gitweb.showsizes = 0|1;
 379         'show-sizes' => {
 380                 'sub' => sub { feature_bool('showsizes', @_) },
 381                 'override' => 0,
 382                 'default' => [1]},
 383
 384         # Make gitweb use an alternative format of the URLs which can be
 385         # more readable and natural-looking: project name is embedded
 386         # directly in the path and the query string contains other
 387         # auxiliary information. All gitweb installations recognize
 388         # URL in either format; this configures in which formats gitweb
 389         # generates links.
 390
 391         # To enable system wide have in $GITWEB_CONFIG
 392         # $feature{'pathinfo'}{'default'} = [1];
 393         # Project specific override is not supported.
 394
 395         # Note that you will need to change the default location of CSS,
 396         # favicon, logo and possibly other files to an absolute URL. Also,
 397         # if gitweb.cgi serves as your indexfile, you will need to force
 398         # $my_uri to contain the script name in your $GITWEB_CONFIG.
 399         'pathinfo' => {
 400                 'override' => 0,
 401                 'default' => [0]},
 402
 403         # Make gitweb consider projects in project root subdirectories
 404         # to be forks of existing projects. Given project $projname.git,
 405         # projects matching $projname/*.git will not be shown in the main
 406         # projects list, instead a '+' mark will be added to $projname
 407         # there and a 'forks' view will be enabled for the project, listing
 408         # all the forks. If project list is taken from a file, forks have
 409         # to be listed after the main project.
 410
 411         # To enable system wide have in $GITWEB_CONFIG
 412         # $feature{'forks'}{'default'} = [1];
 413         # Project specific override is not supported.
 414         'forks' => {
 415                 'override' => 0,
 416                 'default' => [0]},
 417
 418         # Insert custom links to the action bar of all project pages.
 419         # This enables you mainly to link to third-party scripts integrating
 420         # into gitweb; e.g. git-browser for graphical history representation
 421         # or custom web-based repository administration interface.
 422
 423         # The 'default' value consists of a list of triplets in the form
 424         # (label, link, position) where position is the label after which
 425         # to insert the link and link is a format string where %n expands
 426         # to the project name, %f to the project path within the filesystem,
 427         # %h to the current hash (h gitweb parameter) and %b to the current
 428         # hash base (hb gitweb parameter); %% expands to %.
 429
 430         # To enable system wide have in $GITWEB_CONFIG e.g.
 431         # $feature{'actions'}{'default'} = [('graphiclog',
 432         #       '/git-browser/by-commit.html?r=%n', 'summary')];
 433         # Project specific override is not supported.
 434         'actions' => {
 435                 'override' => 0,
 436                 'default' => []},
 437
 438         # Allow gitweb scan project content tags of project repository,
 439         # and display the popular Web 2.0-ish "tag cloud" near the projects
 440         # list.  Note that this is something COMPLETELY different from the
 441         # normal Git tags.
 442
 443         # gitweb by itself can show existing tags, but it does not handle
 444         # tagging itself; you need to do it externally, outside gitweb.
 445         # The format is described in git_get_project_ctags() subroutine.
 446         # You may want to install the HTML::TagCloud Perl module to get
 447         # a pretty tag cloud instead of just a list of tags.
 448
 449         # To enable system wide have in $GITWEB_CONFIG
 450         # $feature{'ctags'}{'default'} = [1];
 451         # Project specific override is not supported.
 452
 453         # In the future whether ctags editing is enabled might depend
 454         # on the value, but using 1 should always mean no editing of ctags.
 455         'ctags' => {
 456                 'override' => 0,
 457                 'default' => [0]},
 458
 459         # The maximum number of patches in a patchset generated in patch
 460         # view. Set this to 0 or undef to disable patch view, or to a
 461         # negative number to remove any limit.
 462
 463         # To disable system wide have in $GITWEB_CONFIG
 464         # $feature{'patches'}{'default'} = [0];
 465         # To have project specific config enable override in $GITWEB_CONFIG
 466         # $feature{'patches'}{'override'} = 1;
 467         # and in project config gitweb.patches = 0|n;
 468         # where n is the maximum number of patches allowed in a patchset.
 469         'patches' => {
 470                 'sub' => \&feature_patches,
 471                 'override' => 0,
 472                 'default' => [16]},
 473
 474         # Avatar support. When this feature is enabled, views such as
 475         # shortlog or commit will display an avatar associated with
 476         # the email of the committer(s) and/or author(s).
 477
 478         # Currently available providers are gravatar and picon.
 479         # If an unknown provider is specified, the feature is disabled.
 480
 481         # Gravatar depends on Digest::MD5.
 482         # Picon currently relies on the indiana.edu database.
 483
 484         # To enable system wide have in $GITWEB_CONFIG
 485         # $feature{'avatar'}{'default'} = ['<provider>'];
 486         # where <provider> is either gravatar or picon.
 487         # To have project specific config enable override in $GITWEB_CONFIG
 488         # $feature{'avatar'}{'override'} = 1;
 489         # and in project config gitweb.avatar = <provider>;
 490         'avatar' => {
 491                 'sub' => \&feature_avatar,
 492                 'override' => 0,
 493                 'default' => ['']},
 494
 495         # Enable displaying how much time and how many git commands
 496         # it took to generate and display page.  Disabled by default.
 497         # Project specific override is not supported.
 498         'timed' => {
 499                 'override' => 0,
 500                 'default' => [0]},
 501
 502         # Enable turning some links into links to actions which require
 503         # JavaScript to run (like 'blame_incremental').  Not enabled by
 504         # default.  Project specific override is currently not supported.
 505         'javascript-actions' => {
 506                 'override' => 0,
 507                 'default' => [0]},
 508
 509         # Enable and configure ability to change common timezone for dates
 510         # in gitweb output via JavaScript.  Enabled by default.
 511         # Project specific override is not supported.
 512         'javascript-timezone' => {
 513                 'override' => 0,
 514                 'default' => [
 515                         'local',     # default timezone: 'utc', 'local', or '(-|+)HHMM' format,
 516                                      # or undef to turn off this feature
 517                         'gitweb_tz', # name of cookie where to store selected timezone
 518                         'datetime',  # CSS class used to mark up dates for manipulation
 519                 ]},
 520
 521         # Syntax highlighting support. This is based on Daniel Svensson's
 522         # and Sham Chukoury's work in gitweb-xmms2.git.
 523         # It requires the 'highlight' program present in $PATH,
 524         # and therefore is disabled by default.
 525
 526         # To enable system wide have in $GITWEB_CONFIG
 527         # $feature{'highlight'}{'default'} = [1];
 528
 529         'highlight' => {
 530                 'sub' => sub { feature_bool('highlight', @_) },
 531                 'override' => 0,
 532                 'default' => [0]},
 533
 534         # Enable displaying of remote heads in the heads list
 535
 536         # To enable system wide have in $GITWEB_CONFIG
 537         # $feature{'remote_heads'}{'default'} = [1];
 538         # To have project specific config enable override in $GITWEB_CONFIG
 539         # $feature{'remote_heads'}{'override'} = 1;
 540         # and in project config gitweb.remote_heads = 0|1;
 541         'remote_heads' => {
 542                 'sub' => sub { feature_bool('remote_heads', @_) },
 543                 'override' => 0,
 544                 'default' => [0]},
 545 );
 546
 547 sub gitweb_get_feature {
 548         my ($name) = @_;
 549         return unless exists $feature{$name};
 550         my ($sub, $override, @defaults) = (
 551                 $feature{$name}{'sub'},
 552                 $feature{$name}{'override'},
 553                 @{$feature{$name}{'default'}});
 554         # project specific override is possible only if we have project
 555         our $git_dir; # global variable, declared later
 556         if (!$override || !defined $git_dir) {
 557                 return @defaults;
 558         }
 559         if (!defined $sub) {
 560                 warn "feature $name is not overridable";
 561                 return @defaults;
 562         }
 563         return $sub->(@defaults);
 564 }
 565
 566 # A wrapper to check if a given feature is enabled.
 567 # With this, you can say
 568 #
 569 #   my $bool_feat = gitweb_check_feature('bool_feat');
 570 #   gitweb_check_feature('bool_feat') or somecode;
 571 #
 572 # instead of
 573 #
 574 #   my ($bool_feat) = gitweb_get_feature('bool_feat');
 575 #   (gitweb_get_feature('bool_feat'))[0] or somecode;
 576 #
 577 sub gitweb_check_feature {
 578         return (gitweb_get_feature(@_))[0];
 579 }
 580
 581
 582 sub feature_bool {
 583         my $key = shift;
 584         my ($val) = git_get_project_config($key, '--bool');
 585
 586         if (!defined $val) {
 587                 return ($_[0]);
 588         } elsif ($val eq 'true') {
 589                 return (1);
 590         } elsif ($val eq 'false') {
 591                 return (0);
 592         }
 593 }
 594
 595 sub feature_snapshot {
 596         my (@fmts) = @_;
 597
 598         my ($val) = git_get_project_config('snapshot');
 599
 600         if ($val) {
 601                 @fmts = ($val eq 'none' ? () : split /\s*[,\s]\s*/, $val);
 602         }
 603
 604         return @fmts;
 605 }
 606
 607 sub feature_patches {
 608         my @val = (git_get_project_config('patches', '--int'));
 609
 610         if (@val) {
 611                 return @val;
 612         }
 613
 614         return ($_[0]);
 615 }
 616
 617 sub feature_avatar {
 618         my @val = (git_get_project_config('avatar'));
 619
 620         return @val ? @val : @_;
 621 }
 622
 623 # checking HEAD file with -e is fragile if the repository was
 624 # initialized long time ago (i.e. symlink HEAD) and was pack-ref'ed
 625 # and then pruned.
 626 sub check_head_link {
 627         my ($dir) = @_;
 628         my $headfile = "$dir/HEAD";
 629         return ((-e $headfile) ||
 630                 (-l $headfile && readlink($headfile) =~ /^refs\/heads\//));
 631 }
 632
 633 sub check_export_ok {
 634         my ($dir) = @_;
 635         return (check_head_link($dir) &&
 636                 (!$export_ok || -e "$dir/$export_ok") &&
 637                 (!$export_auth_hook || $export_auth_hook->($dir)));
 638 }
 639
 640 # process alternate names for backward compatibility
 641 # filter out unsupported (unknown) snapshot formats
 642 sub filter_snapshot_fmts {
 643         my @fmts = @_;
 644
 645         @fmts = map {
 646                 exists $known_snapshot_format_aliases{$_} ?
 647                        $known_snapshot_format_aliases{$_} : $_} @fmts;
 648         @fmts = grep {
 649                 exists $known_snapshot_formats{$_} &&
 650                 !$known_snapshot_formats{$_}{'disabled'}} @fmts;
 651 }
 652
 653 # If it is set to code reference, it is code that it is to be run once per
 654 # request, allowing updating configurations that change with each request,
 655 # while running other code in config file only once.
 656 #
 657 # Otherwise, if it is false then gitweb would process config file only once;
 658 # if it is true then gitweb config would be run for each request.
 659 our $per_request_config = 1;
 660
 661 # read and parse gitweb config file given by its parameter.
 662 # returns true on success, false on recoverable error, allowing
 663 # to chain this subroutine, using first file that exists.
 664 # dies on errors during parsing config file, as it is unrecoverable.
 665 sub read_config_file {
 666         my $filename = shift;
 667         return unless defined $filename;
 668         # die if there are errors parsing config file
 669         if (-e $filename) {
 670                 do $filename;
 671                 die $@ if $@;
 672                 return 1;
 673         }
 674         return;
 675 }
 676
 677 our ($GITWEB_CONFIG, $GITWEB_CONFIG_SYSTEM, $GITWEB_CONFIG_COMMON);
 678 sub evaluate_gitweb_config {
 679         our $GITWEB_CONFIG = $ENV{'GITWEB_CONFIG'} || "++GITWEB_CONFIG++";
 680         our $GITWEB_CONFIG_SYSTEM = $ENV{'GITWEB_CONFIG_SYSTEM'} || "++GITWEB_CONFIG_SYSTEM++";
 681         our $GITWEB_CONFIG_COMMON = $ENV{'GITWEB_CONFIG_COMMON'} || "++GITWEB_CONFIG_COMMON++";
 682
 683         # Protect agains duplications of file names, to not read config twice.
 684         # Only one of $GITWEB_CONFIG and $GITWEB_CONFIG_SYSTEM is used, so
 685         # there possibility of duplication of filename there doesn't matter.
 686         $GITWEB_CONFIG = ""        if ($GITWEB_CONFIG eq $GITWEB_CONFIG_COMMON);
 687         $GITWEB_CONFIG_SYSTEM = "" if ($GITWEB_CONFIG_SYSTEM eq $GITWEB_CONFIG_COMMON);
 688
 689         # Common system-wide settings for convenience.
 690         # Those settings can be ovverriden by GITWEB_CONFIG or GITWEB_CONFIG_SYSTEM.
 691         read_config_file($GITWEB_CONFIG_COMMON);
 692
 693         # Use first config file that exists.  This means use the per-instance
 694         # GITWEB_CONFIG if exists, otherwise use GITWEB_SYSTEM_CONFIG.
 695         read_config_file($GITWEB_CONFIG) and return;
 696         read_config_file($GITWEB_CONFIG_SYSTEM);
 697 }
 698
 699 # Get loadavg of system, to compare against $maxload.
 700 # Currently it requires '/proc/loadavg' present to get loadavg;
 701 # if it is not present it returns 0, which means no load checking.
 702 sub get_loadavg {
 703         if( -e '/proc/loadavg' ){
 704                 open my $fd, '<', '/proc/loadavg'
 705                         or return 0;
 706                 my @load = split(/\s+/, scalar <$fd>);
 707                 close $fd;
 708
 709                 # The first three columns measure CPU and IO utilization of the last one,
 710                 # five, and 10 minute periods.  The fourth column shows the number of
 711                 # currently running processes and the total number of processes in the m/n
 712                 # format.  The last column displays the last process ID used.
 713                 return $load[0] || 0;
 714         }
 715         # additional checks for load average should go here for things that don't export
 716         # /proc/loadavg
 717
 718         return 0;
 719 }
 720
 721 # version of the core git binary
 722 our $git_version;
 723 sub evaluate_git_version {
 724         our $git_version = qx("$GIT" --version) =~ m/git version (.*)$/ ? $1 : "unknown";
 725         $number_of_git_cmds++;
 726 }
 727
 728 sub check_loadavg {
 729         if (defined $maxload && get_loadavg() > $maxload) {
 730                 die_error(503, "The load average on the server is too high");
 731         }
 732 }
 733
 734 # ======================================================================
 735 # input validation and dispatch
 736
 737 # input parameters can be collected from a variety of sources (presently, CGI
 738 # and PATH_INFO), so we define an %input_params hash that collects them all
 739 # together during validation: this allows subsequent uses (e.g. href()) to be
 740 # agnostic of the parameter origin
 741
 742 our %input_params = ();
 743
 744 # input parameters are stored with the long parameter name as key. This will
 745 # also be used in the href subroutine to convert parameters to their CGI
 746 # equivalent, and since the href() usage is the most frequent one, we store
 747 # the name -> CGI key mapping here, instead of the reverse.
 748 #
 749 # XXX: Warning: If you touch this, check the search form for updating,
 750 # too.
 751
 752 our @cgi_param_mapping = (
 753         project => "p",
 754         action => "a",
 755         file_name => "f",
 756         file_parent => "fp",
 757         hash => "h",
 758         hash_parent => "hp",
 759         hash_base => "hb",
 760         hash_parent_base => "hpb",
 761         page => "pg",
 762         order => "o",
 763         searchtext => "s",
 764         searchtype => "st",
 765         snapshot_format => "sf",
 766         extra_options => "opt",
 767         search_use_regexp => "sr",
 768         ctag => "by_tag",
 769         diff_style => "ds",
 770         project_filter => "pf",
 771         # this must be last entry (for manipulation from JavaScript)
 772         javascript => "js"
 773 );
 774 our %cgi_param_mapping = @cgi_param_mapping;
 775
 776 # we will also need to know the possible actions, for validation
 777 our %actions = (
 778         "blame" => \&git_blame,
 779         "blame_incremental" => \&git_blame_incremental,
 780         "blame_data" => \&git_blame_data,
 781         "blobdiff" => \&git_blobdiff,
 782         "blobdiff_plain" => \&git_blobdiff_plain,
 783         "blob" => \&git_blob,
 784         "blob_plain" => \&git_blob_plain,
 785         "commitdiff" => \&git_commitdiff,
 786         "commitdiff_plain" => \&git_commitdiff_plain,
 787         "commit" => \&git_commit,
 788         "forks" => \&git_forks,
 789         "heads" => \&git_heads,
 790         "history" => \&git_history,
 791         "log" => \&git_log,
 792         "patch" => \&git_patch,
 793         "patches" => \&git_patches,
 794         "remotes" => \&git_remotes,
 795         "rss" => \&git_rss,
 796         "atom" => \&git_atom,
 797         "search" => \&git_search,
 798         "search_help" => \&git_search_help,
 799         "shortlog" => \&git_shortlog,
 800         "summary" => \&git_summary,
 801         "tag" => \&git_tag,
 802         "tags" => \&git_tags,
 803         "tree" => \&git_tree,
 804         "snapshot" => \&git_snapshot,
 805         "object" => \&git_object,
 806         # those below don't need $project
 807         "opml" => \&git_opml,
 808         "project_list" => \&git_project_list,
 809         "project_index" => \&git_project_index,
 810 );
 811
 812 # finally, we have the hash of allowed extra_options for the commands that
 813 # allow them
 814 our %allowed_options = (
 815         "--no-merges" => [ qw(rss atom log shortlog history) ],
 816 );
 817
 818 # fill %input_params with the CGI parameters. All values except for 'opt'
 819 # should be single values, but opt can be an array. We should probably
 820 # build an array of parameters that can be multi-valued, but since for the time
 821 # being it's only this one, we just single it out
 822 sub evaluate_query_params {
 823         our $cgi;
 824
 825         while (my ($name, $symbol) = each %cgi_param_mapping) {
 826                 if ($symbol eq 'opt') {
 827                         $input_params{$name} = [ map { decode_utf8($_) } $cgi->param($symbol) ];
 828                 } else {
 829                         $input_params{$name} = decode_utf8($cgi->param($symbol));
 830                 }
 831         }
 832 }
 833
 834 # now read PATH_INFO and update the parameter list for missing parameters
 835 sub evaluate_path_info {
 836         return if defined $input_params{'project'};
 837         return if !$path_info;
 838         $path_info =~ s,^/+,,;
 839         return if !$path_info;
 840
 841         # find which part of PATH_INFO is project
 842         my $project = $path_info;
 843         $project =~ s,/+$,,;
 844         while ($project && !check_head_link("$projectroot/$project")) {
 845                 $project =~ s,/*[^/]*$,,;
 846         }
 847         return unless $project;
 848         $input_params{'project'} = $project;
 849
 850         # do not change any parameters if an action is given using the query string
 851         return if $input_params{'action'};
 852         $path_info =~ s,^\Q$project\E/*,,;
 853
 854         # next, check if we have an action
 855         my $action = $path_info;
 856         $action =~ s,/.*$,,;
 857         if (exists $actions{$action}) {
 858                 $path_info =~ s,^$action/*,,;
 859                 $input_params{'action'} = $action;
 860         }
 861
 862         # list of actions that want hash_base instead of hash, but can have no
 863         # pathname (f) parameter
 864         my @wants_base = (
 865                 'tree',
 866                 'history',
 867         );
 868
 869         # we want to catch, among others
 870         # [$hash_parent_base[:$file_parent]..]$hash_parent[:$file_name]
 871         my ($parentrefname, $parentpathname, $refname, $pathname) =
 872                 ($path_info =~ /^(?:(.+?)(?::(.+))?\.\.)?([^:]+?)?(?::(.+))?$/);
 873
 874         # first, analyze the 'current' part
 875         if (defined $pathname) {
 876                 # we got "branch:filename" or "branch:dir/"
 877                 # we could use git_get_type(branch:pathname), but:
 878                 # - it needs $git_dir
 879                 # - it does a git() call
 880                 # - the convention of terminating directories with a slash
 881                 #   makes it superfluous
 882                 # - embedding the action in the PATH_INFO would make it even
 883                 #   more superfluous
 884                 $pathname =~ s,^/+,,;
 885                 if (!$pathname || substr($pathname, -1) eq "/") {
 886                         $input_params{'action'} ||= "tree";
 887                         $pathname =~ s,/$,,;
 888                 } else {
 889                         # the default action depends on whether we had parent info
 890                         # or not
 891                         if ($parentrefname) {
 892                                 $input_params{'action'} ||= "blobdiff_plain";
 893                         } else {
 894                                 $input_params{'action'} ||= "blob_plain";
 895                         }
 896                 }
 897                 $input_params{'hash_base'} ||= $refname;
 898                 $input_params{'file_name'} ||= $pathname;
 899         } elsif (defined $refname) {
 900                 # we got "branch". In this case we have to choose if we have to
 901                 # set hash or hash_base.
 902                 #
 903                 # Most of the actions without a pathname only want hash to be
 904                 # set, except for the ones specified in @wants_base that want
 905                 # hash_base instead. It should also be noted that hand-crafted
 906                 # links having 'history' as an action and no pathname or hash
 907                 # set will fail, but that happens regardless of PATH_INFO.
 908                 if (defined $parentrefname) {
 909                         # if there is parent let the default be 'shortlog' action
 910                         # (for http://git.example.com/repo.git/A..B links); if there
 911                         # is no parent, dispatch will detect type of object and set
 912                         # action appropriately if required (if action is not set)
 913                         $input_params{'action'} ||= "shortlog";
 914                 }
 915                 if ($input_params{'action'} &&
 916                     grep { $_ eq $input_params{'action'} } @wants_base) {
 917                         $input_params{'hash_base'} ||= $refname;
 918                 } else {
 919                         $input_params{'hash'} ||= $refname;
 920                 }
 921         }
 922
 923         # next, handle the 'parent' part, if present
 924         if (defined $parentrefname) {
 925                 # a missing pathspec defaults to the 'current' filename, allowing e.g.
 926                 # someproject/blobdiff/oldrev..newrev:/filename
 927                 if ($parentpathname) {
 928                         $parentpathname =~ s,^/+,,;
 929                         $parentpathname =~ s,/$,,;
 930                         $input_params{'file_parent'} ||= $parentpathname;
 931                 } else {
 932                         $input_params{'file_parent'} ||= $input_params{'file_name'};
 933                 }
 934                 # we assume that hash_parent_base is wanted if a path was specified,
 935                 # or if the action wants hash_base instead of hash
 936                 if (defined $input_params{'file_parent'} ||
 937                         grep { $_ eq $input_params{'action'} } @wants_base) {
 938                         $input_params{'hash_parent_base'} ||= $parentrefname;
 939                 } else {
 940                         $input_params{'hash_parent'} ||= $parentrefname;
 941                 }
 942         }
 943
 944         # for the snapshot action, we allow URLs in the form
 945         # $project/snapshot/$hash.ext
 946         # where .ext determines the snapshot and gets removed from the
 947         # passed $refname to provide the $hash.
 948         #
 949         # To be able to tell that $refname includes the format extension, we
 950         # require the following two conditions to be satisfied:
 951         # - the hash input parameter MUST have been set from the $refname part
 952         #   of the URL (i.e. they must be equal)
 953         # - the snapshot format MUST NOT have been defined already (e.g. from
 954         #   CGI parameter sf)
 955         # It's also useless to try any matching unless $refname has a dot,
 956         # so we check for that too
 957         if (defined $input_params{'action'} &&
 958                 $input_params{'action'} eq 'snapshot' &&
 959                 defined $refname && index($refname, '.') != -1 &&
 960                 $refname eq $input_params{'hash'} &&
 961                 !defined $input_params{'snapshot_format'}) {
 962                 # We loop over the known snapshot formats, checking for
 963                 # extensions. Allowed extensions are both the defined suffix
 964                 # (which includes the initial dot already) and the snapshot
 965                 # format key itself, with a prepended dot
 966                 while (my ($fmt, $opt) = each %known_snapshot_formats) {
 967                         my $hash = $refname;
 968                         unless ($hash =~ s/(\Q$opt->{'suffix'}\E|\Q.$fmt\E)$//) {
 969                                 next;
 970                         }
 971                         my $sfx = $1;
 972                         # a valid suffix was found, so set the snapshot format
 973                         # and reset the hash parameter
 974                         $input_params{'snapshot_format'} = $fmt;
 975                         $input_params{'hash'} = $hash;
 976                         # we also set the format suffix to the one requested
 977                         # in the URL: this way a request for e.g. .tgz returns
 978                         # a .tgz instead of a .tar.gz
 979                         $known_snapshot_formats{$fmt}{'suffix'} = $sfx;
 980                         last;
 981                 }
 982         }
 983 }
 984
 985 our ($action, $project, $file_name, $file_parent, $hash, $hash_parent, $hash_base,
 986      $hash_parent_base, @extra_options, $page, $searchtype, $search_use_regexp,
 987      $searchtext, $search_regexp, $project_filter);
 988 sub evaluate_and_validate_params {
 989         our $action = $input_params{'action'};
 990         if (defined $action) {
 991                 if (!validate_action($action)) {
 992                         die_error(400, "Invalid action parameter");
 993                 }
 994         }
 995
 996         # parameters which are pathnames
 997         our $project = $input_params{'project'};
 998         if (defined $project) {
 999                 if (!validate_project($project)) {
1000                         undef $project;
1001                         die_error(404, "No such project");
1002                 }
1003         }
1004
1005         our $project_filter = $input_params{'project_filter'};
1006         if (defined $project_filter) {
1007                 if (!validate_pathname($project_filter)) {
1008                         die_error(404, "Invalid project_filter parameter");
1009                 }
1010         }
1011
1012         our $file_name = $input_params{'file_name'};
1013         if (defined $file_name) {
1014                 if (!validate_pathname($file_name)) {
1015                         die_error(400, "Invalid file parameter");
1016                 }
1017         }
1018
1019         our $file_parent = $input_params{'file_parent'};
1020         if (defined $file_parent) {
1021                 if (!validate_pathname($file_parent)) {
1022                         die_error(400, "Invalid file parent parameter");
1023                 }
1024         }
1025
1026         # parameters which are refnames
1027         our $hash = $input_params{'hash'};
1028         if (defined $hash) {
1029                 if (!validate_refname($hash)) {
1030                         die_error(400, "Invalid hash parameter");
1031                 }
1032         }
1033
1034         our $hash_parent = $input_params{'hash_parent'};
1035         if (defined $hash_parent) {
1036                 if (!validate_refname($hash_parent)) {
1037                         die_error(400, "Invalid hash parent parameter");
1038                 }
1039         }
1040
1041         our $hash_base = $input_params{'hash_base'};
1042         if (defined $hash_base) {
1043                 if (!validate_refname($hash_base)) {
1044                         die_error(400, "Invalid hash base parameter");
1045                 }
1046         }
1047
1048         our @extra_options = @{$input_params{'extra_options'}};
1049         # @extra_options is always defined, since it can only be (currently) set from
1050         # CGI, and $cgi->param() returns the empty array in array context if the param
1051         # is not set
1052         foreach my $opt (@extra_options) {
1053                 if (not exists $allowed_options{$opt}) {
1054                         die_error(400, "Invalid option parameter");
1055                 }
1056                 if (not grep(/^$action$/, @{$allowed_options{$opt}})) {
1057                         die_error(400, "Invalid option parameter for this action");
1058                 }
1059         }
1060
1061         our $hash_parent_base = $input_params{'hash_parent_base'};
1062         if (defined $hash_parent_base) {
1063                 if (!validate_refname($hash_parent_base)) {
1064                         die_error(400, "Invalid hash parent base parameter");
1065                 }
1066         }
1067
1068         # other parameters
1069         our $page = $input_params{'page'};
1070         if (defined $page) {
1071                 if ($page =~ m/[^0-9]/) {
1072                         die_error(400, "Invalid page parameter");
1073                 }
1074         }
1075
1076         our $searchtype = $input_params{'searchtype'};
1077         if (defined $searchtype) {
1078                 if ($searchtype =~ m/[^a-z]/) {
1079                         die_error(400, "Invalid searchtype parameter");
1080                 }
1081         }
1082
1083         our $search_use_regexp = $input_params{'search_use_regexp'};
1084
1085         our $searchtext = $input_params{'searchtext'};
1086         our $search_regexp;
1087         if (defined $searchtext) {
1088                 if (length($searchtext) < 2) {
1089                         die_error(403, "At least two characters are required for search parameter");
1090                 }
1091                 if ($search_use_regexp) {
1092                         $search_regexp = $searchtext;
1093                         if (!eval { qr/$search_regexp/; 1; }) {
1094                                 (my $error = $@) =~ s/ at \S+ line \d+.*\n?//;
1095                                 die_error(400, "Invalid search regexp '$search_regexp'",
1096                                           esc_html($error));
1097                         }
1098                 } else {
1099                         $search_regexp = quotemeta $searchtext;
1100                 }
1101         }
1102 }
1103
1104 # path to the current git repository
1105 our $git_dir;
1106 sub evaluate_git_dir {
1107         our $git_dir = "$projectroot/$project" if $project;
1108 }
1109
1110 our (@snapshot_fmts, $git_avatar);
1111 sub configure_gitweb_features {
1112         # list of supported snapshot formats
1113         our @snapshot_fmts = gitweb_get_feature('snapshot');
1114         @snapshot_fmts = filter_snapshot_fmts(@snapshot_fmts);
1115
1116         # check that the avatar feature is set to a known provider name,
1117         # and for each provider check if the dependencies are satisfied.
1118         # if the provider name is invalid or the dependencies are not met,
1119         # reset $git_avatar to the empty string.
1120         our ($git_avatar) = gitweb_get_feature('avatar');
1121         if ($git_avatar eq 'gravatar') {
1122                 $git_avatar = '' unless (eval { require Digest::MD5; 1; });
1123         } elsif ($git_avatar eq 'picon') {
1124                 # no dependencies
1125         } else {
1126                 $git_avatar = '';
1127         }
1128 }
1129
1130 # custom error handler: 'die <message>' is Internal Server Error
1131 sub handle_errors_html {
1132         my $msg = shift; # it is already HTML escaped
1133
1134         # to avoid infinite loop where error occurs in die_error,
1135         # change handler to default handler, disabling handle_errors_html
1136         set_message("Error occured when inside die_error:\n$msg");
1137
1138         # you cannot jump out of die_error when called as error handler;
1139         # the subroutine set via CGI::Carp::set_message is called _after_
1140         # HTTP headers are already written, so it cannot write them itself
1141         die_error(undef, undef, $msg, -error_handler => 1, -no_http_header => 1);
1142 }
1143 set_message(\&handle_errors_html);
1144
1145 # dispatch
1146 sub dispatch {
1147         if (!defined $action) {
1148                 if (defined $hash) {
1149                         $action = git_get_type($hash);
1150                         $action or die_error(404, "Object does not exist");
1151                 } elsif (defined $hash_base && defined $file_name) {
1152                         $action = git_get_type("$hash_base:$file_name");
1153                         $action or die_error(404, "File or directory does not exist");
1154                 } elsif (defined $project) {
1155                         $action = 'summary';
1156                 } else {
1157                         $action = 'project_list';
1158                 }
1159         }
1160         if (!defined($actions{$action})) {
1161                 die_error(400, "Unknown action");
1162         }
1163         if ($action !~ m/^(?:opml|project_list|project_index)$/ &&
1164             !$project) {
1165                 die_error(400, "Project needed");
1166         }
1167         $actions{$action}->();
1168 }
1169
1170 sub reset_timer {
1171         our $t0 = [ gettimeofday() ]
1172                 if defined $t0;
1173         our $number_of_git_cmds = 0;
1174 }
1175
1176 our $first_request = 1;
1177 sub run_request {
1178         reset_timer();
1179
1180         evaluate_uri();
1181         if ($first_request) {
1182                 evaluate_gitweb_config();
1183                 evaluate_git_version();
1184         }
1185         if ($per_request_config) {
1186                 if (ref($per_request_config) eq 'CODE') {
1187                         $per_request_config->();
1188                 } elsif (!$first_request) {
1189                         evaluate_gitweb_config();
1190                 }
1191         }
1192         check_loadavg();
1193
1194         # $projectroot and $projects_list might be set in gitweb config file
1195         $projects_list ||= $projectroot;
1196
1197         evaluate_query_params();
1198         evaluate_path_info();
1199         evaluate_and_validate_params();
1200         evaluate_git_dir();
1201
1202         configure_gitweb_features();
1203
1204         dispatch();
1205 }
1206
1207 our $is_last_request = sub { 1 };
1208 our ($pre_dispatch_hook, $post_dispatch_hook, $pre_listen_hook);
1209 our $CGI = 'CGI';
1210 our $cgi;
1211 sub configure_as_fcgi {
1212         require CGI::Fast;
1213         our $CGI = 'CGI::Fast';
1214
1215         my $request_number = 0;
1216         # let each child service 100 requests
1217         our $is_last_request = sub { ++$request_number > 100 };
1218 }
1219 sub evaluate_argv {
1220         my $script_name = $ENV{'SCRIPT_NAME'} || $ENV{'SCRIPT_FILENAME'} || __FILE__;
1221         configure_as_fcgi()
1222                 if $script_name =~ /\.fcgi$/;
1223
1224         return unless (@ARGV);
1225
1226         require Getopt::Long;
1227         Getopt::Long::GetOptions(
1228                 'fastcgi|fcgi|f' => \&configure_as_fcgi,
1229                 'nproc|n=i' => sub {
1230                         my ($arg, $val) = @_;
1231                         return unless eval { require FCGI::ProcManager; 1; };
1232                         my $proc_manager = FCGI::ProcManager->new({
1233                                 n_processes => $val,
1234                         });
1235                         our $pre_listen_hook    = sub { $proc_manager->pm_manage()        };
1236                         our $pre_dispatch_hook  = sub { $proc_manager->pm_pre_dispatch()  };
1237                         our $post_dispatch_hook = sub { $proc_manager->pm_post_dispatch() };
1238                 },
1239         );
1240 }
1241
1242 sub run {
1243         evaluate_argv();
1244
1245         $first_request = 1;
1246         $pre_listen_hook->()
1247                 if $pre_listen_hook;
1248
1249  REQUEST:
1250         while ($cgi = $CGI->new()) {
1251                 $pre_dispatch_hook->()
1252                         if $pre_dispatch_hook;
1253
1254                 run_request();
1255
1256                 $post_dispatch_hook->()
1257                         if $post_dispatch_hook;
1258                 $first_request = 0;
1259
1260                 last REQUEST if ($is_last_request->());
1261         }
1262
1263  DONE_GITWEB:
1264         1;
1265 }
1266
1267 run();
1268
1269 if (defined caller) {
1270         # wrapped in a subroutine processing requests,
1271         # e.g. mod_perl with ModPerl::Registry, or PSGI with Plack::App::WrapCGI
1272         return;
1273 } else {
1274         # pure CGI script, serving single request
1275         exit;
1276 }
1277
1278 ## ======================================================================
1279 ## action links
1280
1281 # possible values of extra options
1282 # -full => 0|1      - use absolute/full URL ($my_uri/$my_url as base)
1283 # -replay => 1      - start from a current view (replay with modifications)
1284 # -path_info => 0|1 - don't use/use path_info URL (if possible)
1285 # -anchor => ANCHOR - add #ANCHOR to end of URL, implies -replay if used alone
1286 sub href {
1287         my %params = @_;
1288         # default is to use -absolute url() i.e. $my_uri
1289         my $href = $params{-full} ? $my_url : $my_uri;
1290
1291         # implicit -replay, must be first of implicit params
1292         $params{-replay} = 1 if (keys %params == 1 && $params{-anchor});
1293
1294         $params{'project'} = $project unless exists $params{'project'};
1295
1296         if ($params{-replay}) {
1297                 while (my ($name, $symbol) = each %cgi_param_mapping) {
1298                         if (!exists $params{$name}) {
1299                                 $params{$name} = $input_params{$name};
1300                         }
1301                 }
1302         }
1303
1304         my $use_pathinfo = gitweb_check_feature('pathinfo');
1305         if (defined $params{'project'} &&
1306             (exists $params{-path_info} ? $params{-path_info} : $use_pathinfo)) {
1307                 # try to put as many parameters as possible in PATH_INFO:
1308                 #   - project name
1309                 #   - action
1310                 #   - hash_parent or hash_parent_base:/file_parent
1311                 #   - hash or hash_base:/filename
1312                 #   - the snapshot_format as an appropriate suffix
1313
1314                 # When the script is the root DirectoryIndex for the domain,
1315                 # $href here would be something like http://gitweb.example.com/
1316                 # Thus, we strip any trailing / from $href, to spare us double
1317                 # slashes in the final URL
1318                 $href =~ s,/$,,;
1319
1320                 # Then add the project name, if present
1321                 $href .= "/".esc_path_info($params{'project'});
1322                 delete $params{'project'};
1323
1324                 # since we destructively absorb parameters, we keep this
1325                 # boolean that remembers if we're handling a snapshot
1326                 my $is_snapshot = $params{'action'} eq 'snapshot';
1327
1328                 # Summary just uses the project path URL, any other action is
1329                 # added to the URL
1330                 if (defined $params{'action'}) {
1331                         $href .= "/".esc_path_info($params{'action'})
1332                                 unless $params{'action'} eq 'summary';
1333                         delete $params{'action'};
1334                 }
1335
1336                 # Next, we put hash_parent_base:/file_parent..hash_base:/file_name,
1337                 # stripping nonexistent or useless pieces
1338                 $href .= "/" if ($params{'hash_base'} || $params{'hash_parent_base'}
1339                         || $params{'hash_parent'} || $params{'hash'});
1340                 if (defined $params{'hash_base'}) {
1341                         if (defined $params{'hash_parent_base'}) {
1342                                 $href .= esc_path_info($params{'hash_parent_base'});
1343                                 # skip the file_parent if it's the same as the file_name
1344                                 if (defined $params{'file_parent'}) {
1345                                         if (defined $params{'file_name'} && $params{'file_parent'} eq $params{'file_name'}) {
1346                                                 delete $params{'file_parent'};
1347                                         } elsif ($params{'file_parent'} !~ /\.\./) {
1348                                                 $href .= ":/".esc_path_info($params{'file_parent'});
1349                                                 delete $params{'file_parent'};
1350                                         }
1351                                 }
1352                                 $href .= "..";
1353                                 delete $params{'hash_parent'};
1354                                 delete $params{'hash_parent_base'};
1355                         } elsif (defined $params{'hash_parent'}) {
1356                                 $href .= esc_path_info($params{'hash_parent'}). "..";
1357                                 delete $params{'hash_parent'};
1358                         }
1359
1360                         $href .= esc_path_info($params{'hash_base'});
1361                         if (defined $params{'file_name'} && $params{'file_name'} !~ /\.\./) {
1362                                 $href .= ":/".esc_path_info($params{'file_name'});
1363                                 delete $params{'file_name'};
1364                         }
1365                         delete $params{'hash'};
1366                         delete $params{'hash_base'};
1367                 } elsif (defined $params{'hash'}) {
1368                         $href .= esc_path_info($params{'hash'});
1369                         delete $params{'hash'};
1370                 }
1371
1372                 # If the action was a snapshot, we can absorb the
1373                 # snapshot_format parameter too
1374                 if ($is_snapshot) {
1375                         my $fmt = $params{'snapshot_format'};
1376                         # snapshot_format should always be defined when href()
1377                         # is called, but just in case some code forgets, we
1378                         # fall back to the default
1379                         $fmt ||= $snapshot_fmts[0];
1380                         $href .= $known_snapshot_formats{$fmt}{'suffix'};
1381                         delete $params{'snapshot_format'};
1382                 }
1383         }
1384
1385         # now encode the parameters explicitly
1386         my @result = ();
1387         for (my $i = 0; $i < @cgi_param_mapping; $i += 2) {
1388                 my ($name, $symbol) = ($cgi_param_mapping[$i], $cgi_param_mapping[$i+1]);
1389                 if (defined $params{$name}) {
1390                         if (ref($params{$name}) eq "ARRAY") {
1391                                 foreach my $par (@{$params{$name}}) {
1392                                         push @result, $symbol . "=" . esc_param($par);
1393                                 }
1394                         } else {
1395                                 push @result, $symbol . "=" . esc_param($params{$name});
1396                         }
1397                 }
1398         }
1399         $href .= "?" . join(';', @result) if scalar @result;
1400
1401         # final transformation: trailing spaces must be escaped (URI-encoded)
1402         $href =~ s/(\s+)$/CGI::escape($1)/e;
1403
1404         if ($params{-anchor}) {
1405                 $href .= "#".esc_param($params{-anchor});
1406         }
1407
1408         return $href;
1409 }
1410
1411
1412 ## ======================================================================
1413 ## validation, quoting/unquoting and escaping
1414
1415 sub validate_action {
1416         my $input = shift || return undef;
1417         return undef unless exists $actions{$input};
1418         return $input;
1419 }
1420
1421 sub validate_project {
1422         my $input = shift || return undef;
1423         if (!validate_pathname($input) ||
1424                 !(-d "$projectroot/$input") ||
1425                 !check_export_ok("$projectroot/$input") ||
1426                 ($strict_export && !project_in_list($input))) {
1427                 return undef;
1428         } else {
1429                 return $input;
1430         }
1431 }
1432
1433 sub validate_pathname {
1434         my $input = shift || return undef;
1435
1436         # no '.' or '..' as elements of path, i.e. no '.' nor '..'
1437         # at the beginning, at the end, and between slashes.
1438         # also this catches doubled slashes
1439         if ($input =~ m!(^|/)(|\.|\.\.)(/|$)!) {
1440                 return undef;
1441         }
1442         # no null characters
1443         if ($input =~ m!\0!) {
1444                 return undef;
1445         }
1446         return $input;
1447 }
1448
1449 sub validate_refname {
1450         my $input = shift || return undef;
1451
1452         # textual hashes are O.K.
1453         if ($input =~ m/^[0-9a-fA-F]{40}$/) {
1454                 return $input;
1455         }
1456         # it must be correct pathname
1457         $input = validate_pathname($input)
1458                 or return undef;
1459         # restrictions on ref name according to git-check-ref-format
1460         if ($input =~ m!(/\.|\.\.|[\000-\040\177 ~^:?*\[]|/$)!) {
1461                 return undef;
1462         }
1463         return $input;
1464 }
1465
1466 # decode sequences of octets in utf8 into Perl's internal form,
1467 # which is utf-8 with utf8 flag set if needed.  gitweb writes out
1468 # in utf-8 thanks to "binmode STDOUT, ':utf8'" at beginning
1469 sub to_utf8 {
1470         my $str = shift;
1471         return undef unless defined $str;
1472
1473         if (utf8::is_utf8($str) || utf8::decode($str)) {
1474                 return $str;
1475         } else {
1476                 return decode($fallback_encoding, $str, Encode::FB_DEFAULT);
1477         }
1478 }
1479
1480 # quote unsafe chars, but keep the slash, even when it's not
1481 # correct, but quoted slashes look too horrible in bookmarks
1482 sub esc_param {
1483         my $str = shift;
1484         return undef unless defined $str;
1485         $str =~ s/([^A-Za-z0-9\-_.~()\/:@ ]+)/CGI::escape($1)/eg;
1486         $str =~ s/ /\+/g;
1487         return $str;
1488 }
1489
1490 # the quoting rules for path_info fragment are slightly different
1491 sub esc_path_info {
1492         my $str = shift;
1493         return undef unless defined $str;
1494
1495         # path_info doesn't treat '+' as space (specially), but '?' must be escaped
1496         $str =~ s/([^A-Za-z0-9\-_.~();\/;:@&= +]+)/CGI::escape($1)/eg;
1497
1498         return $str;
1499 }
1500
1501 # quote unsafe chars in whole URL, so some characters cannot be quoted
1502 sub esc_url {
1503         my $str = shift;
1504         return undef unless defined $str;
1505         $str =~ s/([^A-Za-z0-9\-_.~();\/;?:@&= ]+)/CGI::escape($1)/eg;
1506         $str =~ s/ /\+/g;
1507         return $str;
1508 }
1509
1510 # quote unsafe characters in HTML attributes
1511 sub esc_attr {
1512
1513         # for XHTML conformance escaping '"' to '&quot;' is not enough
1514         return esc_html(@_);
1515 }
1516
1517 # replace invalid utf8 character with SUBSTITUTION sequence
1518 sub esc_html {
1519         my $str = shift;
1520         my %opts = @_;
1521
1522         return undef unless defined $str;
1523
1524         $str = to_utf8($str);
1525         $str = $cgi->escapeHTML($str);
1526         if ($opts{'-nbsp'}) {
1527                 $str =~ s/ /&nbsp;/g;
1528         }
1529         $str =~ s|([[:cntrl:]])|(($1 ne "\t") ? quot_cec($1) : $1)|eg;
1530         return $str;
1531 }
1532
1533 # quote control characters and escape filename to HTML
1534 sub esc_path {
1535         my $str = shift;
1536         my %opts = @_;
1537
1538         return undef unless defined $str;
1539
1540         $str = to_utf8($str);
1541         $str = $cgi->escapeHTML($str);
1542         if ($opts{'-nbsp'}) {
1543                 $str =~ s/ /&nbsp;/g;
1544         }
1545         $str =~ s|([[:cntrl:]])|quot_cec($1)|eg;
1546         return $str;
1547 }
1548
1549 # Sanitize for use in XHTML + application/xml+xhtm (valid XML 1.0)
1550 sub sanitize {
1551         my $str = shift;
1552
1553         return undef unless defined $str;
1554
1555         $str = to_utf8($str);
1556         $str =~ s|([[:cntrl:]])|($1 =~ /[\t\n\r]/ ? $1 : quot_cec($1))|eg;
1557         return $str;
1558 }
1559
1560 # Make control characters "printable", using character escape codes (CEC)
1561 sub quot_cec {
1562         my $cntrl = shift;
1563         my %opts = @_;
1564         my %es = ( # character escape codes, aka escape sequences
1565                 "\t" => '\t',   # tab            (HT)
1566                 "\n" => '\n',   # line feed      (LF)
1567                 "\r" => '\r',   # carrige return (CR)
1568                 "\f" => '\f',   # form feed      (FF)
1569                 "\b" => '\b',   # backspace      (BS)
1570                 "\a" => '\a',   # alarm (bell)   (BEL)
1571                 "\e" => '\e',   # escape         (ESC)
1572                 "\013" => '\v', # vertical tab   (VT)
1573                 "\000" => '\0', # nul character  (NUL)
1574         );
1575         my $chr = ( (exists $es{$cntrl})
1576                     ? $es{$cntrl}
1577                     : sprintf('\%2x', ord($cntrl)) );
1578         if ($opts{-nohtml}) {
1579                 return $chr;
1580         } else {
1581                 return "<span class=\"cntrl\">$chr</span>";
1582         }
1583 }
1584
1585 # Alternatively use unicode control pictures codepoints,
1586 # Unicode "printable representation" (PR)
1587 sub quot_upr {
1588         my $cntrl = shift;
1589         my %opts = @_;
1590
1591         my $chr = sprintf('&#%04d;', 0x2400+ord($cntrl));
1592         if ($opts{-nohtml}) {
1593                 return $chr;
1594         } else {
1595                 return "<span class=\"cntrl\">$chr</span>";
1596         }
1597 }
1598
1599 # git may return quoted and escaped filenames
1600 sub unquote {
1601         my $str = shift;
1602
1603         sub unq {
1604                 my $seq = shift;
1605                 my %es = ( # character escape codes, aka escape sequences
1606                         't' => "\t",   # tab            (HT, TAB)
1607                         'n' => "\n",   # newline        (NL)
1608                         'r' => "\r",   # return         (CR)
1609                         'f' => "\f",   # form feed      (FF)
1610                         'b' => "\b",   # backspace      (BS)
1611                         'a' => "\a",   # alarm (bell)   (BEL)
1612                         'e' => "\e",   # escape         (ESC)
1613                         'v' => "\013", # vertical tab   (VT)
1614                 );
1615
1616                 if ($seq =~ m/^[0-7]{1,3}$/) {
1617                         # octal char sequence
1618                         return chr(oct($seq));
1619                 } elsif (exists $es{$seq}) {
1620                         # C escape sequence, aka character escape code
1621                         return $es{$seq};
1622                 }
1623                 # quoted ordinary character
1624                 return $seq;
1625         }
1626
1627         if ($str =~ m/^"(.*)"$/) {
1628                 # needs unquoting
1629                 $str = $1;
1630                 $str =~ s/\\([^0-7]|[0-7]{1,3})/unq($1)/eg;
1631         }
1632         return $str;
1633 }
1634
1635 # escape tabs (convert tabs to spaces)
1636 sub untabify {
1637         my $line = shift;
1638
1639         while ((my $pos = index($line, "\t")) != -1) {
1640                 if (my $count = (8 - ($pos % 8))) {
1641                         my $spaces = ' ' x $count;
1642                         $line =~ s/\t/$spaces/;
1643                 }
1644         }
1645
1646         return $line;
1647 }
1648
1649 sub project_in_list {
1650         my $project = shift;
1651         my @list = git_get_projects_list();
1652         return @list && scalar(grep { $_->{'path'} eq $project } @list);
1653 }
1654
1655 ## ----------------------------------------------------------------------
1656 ## HTML aware string manipulation
1657
1658 # Try to chop given string on a word boundary between position
1659 # $len and $len+$add_len. If there is no word boundary there,
1660 # chop at $len+$add_len. Do not chop if chopped part plus ellipsis
1661 # (marking chopped part) would be longer than given string.
1662 sub chop_str {
1663         my $str = shift;
1664         my $len = shift;
1665         my $add_len = shift || 10;
1666         my $where = shift || 'right'; # 'left' | 'center' | 'right'
1667
1668         # Make sure perl knows it is utf8 encoded so we don't
1669         # cut in the middle of a utf8 multibyte char.
1670         $str = to_utf8($str);
1671
1672         # allow only $len chars, but don't cut a word if it would fit in $add_len
1673         # if it doesn't fit, cut it if it's still longer than the dots we would add
1674         # remove chopped character entities entirely
1675
1676         # when chopping in the middle, distribute $len into left and right part
1677         # return early if chopping wouldn't make string shorter
1678         if ($where eq 'center') {
1679                 return $str if ($len + 5 >= length($str)); # filler is length 5
1680                 $len = int($len/2);
1681         } else {
1682                 return $str if ($len + 4 >= length($str)); # filler is length 4
1683         }
1684
1685         # regexps: ending and beginning with word part up to $add_len
1686         my $endre = qr/.{$len}\w{0,$add_len}/;
1687         my $begre = qr/\w{0,$add_len}.{$len}/;
1688
1689         if ($where eq 'left') {
1690                 $str =~ m/^(.*?)($begre)$/;
1691                 my ($lead, $body) = ($1, $2);
1692                 if (length($lead) > 4) {
1693                         $lead = " ...";
1694                 }
1695                 return "$lead$body";
1696
1697         } elsif ($where eq 'center') {
1698                 $str =~ m/^($endre)(.*)$/;
1699                 my ($left, $str)  = ($1, $2);
1700                 $str =~ m/^(.*?)($begre)$/;
1701                 my ($mid, $right) = ($1, $2);
1702                 if (length($mid) > 5) {
1703                         $mid = " ... ";
1704                 }
1705                 return "$left$mid$right";
1706
1707         } else {
1708                 $str =~ m/^($endre)(.*)$/;
1709                 my $body = $1;
1710                 my $tail = $2;
1711                 if (length($tail) > 4) {
1712                         $tail = "... ";
1713                 }
1714                 return "$body$tail";
1715         }
1716 }
1717
1718 # takes the same arguments as chop_str, but also wraps a <span> around the
1719 # result with a title attribute if it does get chopped. Additionally, the
1720 # string is HTML-escaped.
1721 sub chop_and_escape_str {
1722         my ($str) = @_;
1723
1724         my $chopped = chop_str(@_);
1725         $str = to_utf8($str);
1726         if ($chopped eq $str) {
1727                 return esc_html($chopped);
1728         } else {
1729                 $str =~ s/[[:cntrl:]]/?/g;
1730                 return $cgi->span({-title=>$str}, esc_html($chopped));
1731         }
1732 }
1733
1734 # Highlight selected fragments of string, using given CSS class,
1735 # and escape HTML.  It is assumed that fragments do not overlap.
1736 # Regions are passed as list of pairs (array references).
1737 #
1738 # Example: esc_html_hl_regions("foobar", "mark", [ 0, 3 ]) returns
1739 # '<span class="mark">foo</span>bar'
1740 sub esc_html_hl_regions {
1741         my ($str, $css_class, @sel) = @_;
1742         my %opts = grep { ref($_) ne 'ARRAY' } @sel;
1743         @sel     = grep { ref($_) eq 'ARRAY' } @sel;
1744         return esc_html($str, %opts) unless @sel;
1745
1746         my $out = '';
1747         my $pos = 0;
1748
1749         for my $s (@sel) {
1750                 my ($begin, $end) = @$s;
1751
1752                 # Don't create empty <span> elements.
1753                 next if $end <= $begin;
1754
1755                 my $escaped = esc_html(substr($str, $begin, $end - $begin),
1756                                        %opts);
1757
1758                 $out .= esc_html(substr($str, $pos, $begin - $pos), %opts)
1759                         if ($begin - $pos > 0);
1760                 $out .= $cgi->span({-class => $css_class}, $escaped);
1761
1762                 $pos = $end;
1763         }
1764         $out .= esc_html(substr($str, $pos), %opts)
1765                 if ($pos < length($str));
1766
1767         return $out;
1768 }
1769
1770 # return positions of beginning and end of each match
1771 sub matchpos_list {
1772         my ($str, $regexp) = @_;
1773         return unless (defined $str && defined $regexp);
1774
1775         my @matches;
1776         while ($str =~ /$regexp/g) {
1777                 push @matches, [$-[0], $+[0]];
1778         }
1779         return @matches;
1780 }
1781
1782 # highlight match (if any), and escape HTML
1783 sub esc_html_match_hl {
1784         my ($str, $regexp) = @_;
1785         return esc_html($str) unless defined $regexp;
1786
1787         my @matches = matchpos_list($str, $regexp);
1788         return esc_html($str) unless @matches;
1789
1790         return esc_html_hl_regions($str, 'match', @matches);
1791 }
1792
1793
1794 # highlight match (if any) of shortened string, and escape HTML
1795 sub esc_html_match_hl_chopped {
1796         my ($str, $chopped, $regexp) = @_;
1797         return esc_html_match_hl($str, $regexp) unless defined $chopped;
1798
1799         my @matches = matchpos_list($str, $regexp);
1800         return esc_html($chopped) unless @matches;
1801
1802         # filter matches so that we mark chopped string
1803         my $tail = "... "; # see chop_str
1804         unless ($chopped =~ s/\Q$tail\E$//) {
1805                 $tail = '';
1806         }
1807         my $chop_len = length($chopped);
1808         my $tail_len = length($tail);
1809         my @filtered;
1810
1811         for my $m (@matches) {
1812                 if ($m->[0] > $chop_len) {
1813                         push @filtered, [ $chop_len, $chop_len + $tail_len ] if ($tail_len > 0);
1814                         last;
1815                 } elsif ($m->[1] > $chop_len) {
1816                         push @filtered, [ $m->[0], $chop_len + $tail_len ];
1817                         last;
1818                 }
1819                 push @filtered, $m;
1820         }
1821
1822         return esc_html_hl_regions($chopped . $tail, 'match', @filtered);
1823 }
1824
1825 ## ----------------------------------------------------------------------
1826 ## functions returning short strings
1827
1828 # CSS class for given age value (in seconds)
1829 sub age_class {
1830         my $age = shift;
1831
1832         if (!defined $age) {
1833                 return "noage";
1834         } elsif ($age < 60*60*2) {
1835                 return "age0";
1836         } elsif ($age < 60*60*24*2) {
1837                 return "age1";
1838         } else {
1839                 return "age2";
1840         }
1841 }
1842
1843 # convert age in seconds to "nn units ago" string
1844 sub age_string {
1845         my $age = shift;
1846         my $age_str;
1847
1848         if ($age > 60*60*24*365*2) {
1849                 $age_str = (int $age/60/60/24/365);
1850                 $age_str .= " years ago";
1851         } elsif ($age > 60*60*24*(365/12)*2) {
1852                 $age_str = int $age/60/60/24/(365/12);
1853                 $age_str .= " months ago";
1854         } elsif ($age > 60*60*24*7*2) {
1855                 $age_str = int $age/60/60/24/7;
1856                 $age_str .= " weeks ago";
1857         } elsif ($age > 60*60*24*2) {
1858                 $age_str = int $age/60/60/24;
1859                 $age_str .= " days ago";
1860         } elsif ($age > 60*60*2) {
1861                 $age_str = int $age/60/60;
1862                 $age_str .= " hours ago";
1863         } elsif ($age > 60*2) {
1864                 $age_str = int $age/60;
1865                 $age_str .= " min ago";
1866         } elsif ($age > 2) {
1867                 $age_str = int $age;
1868                 $age_str .= " sec ago";
1869         } else {
1870                 $age_str .= " right now";
1871         }
1872         return $age_str;
1873 }
1874
1875 use constant {
1876         S_IFINVALID => 0030000,
1877         S_IFGITLINK => 0160000,
1878 };
1879
1880 # submodule/subproject, a commit object reference
1881 sub S_ISGITLINK {
1882         my $mode = shift;
1883
1884         return (($mode & S_IFMT) == S_IFGITLINK)
1885 }
1886
1887 # convert file mode in octal to symbolic file mode string
1888 sub mode_str {
1889         my $mode = oct shift;
1890
1891         if (S_ISGITLINK($mode)) {
1892                 return 'm---------';
1893         } elsif (S_ISDIR($mode & S_IFMT)) {
1894                 return 'drwxr-xr-x';
1895         } elsif (S_ISLNK($mode)) {
1896                 return 'lrwxrwxrwx';
1897         } elsif (S_ISREG($mode)) {
1898                 # git cares only about the executable bit
1899                 if ($mode & S_IXUSR) {
1900                         return '-rwxr-xr-x';
1901                 } else {
1902                         return '-rw-r--r--';
1903                 };
1904         } else {
1905                 return '----------';
1906         }
1907 }
1908
1909 # convert file mode in octal to file type string
1910 sub file_type {
1911         my $mode = shift;
1912
1913         if ($mode !~ m/^[0-7]+$/) {
1914                 return $mode;
1915         } else {
1916                 $mode = oct $mode;
1917         }
1918
1919         if (S_ISGITLINK($mode)) {
1920                 return "submodule";
1921         } elsif (S_ISDIR($mode & S_IFMT)) {
1922                 return "directory";
1923         } elsif (S_ISLNK($mode)) {
1924                 return "symlink";
1925         } elsif (S_ISREG($mode)) {
1926                 return "file";
1927         } else {
1928                 return "unknown";
1929         }
1930 }
1931
1932 # convert file mode in octal to file type description string
1933 sub file_type_long {
1934         my $mode = shift;
1935
1936         if ($mode !~ m/^[0-7]+$/) {
1937                 return $mode;
1938         } else {
1939                 $mode = oct $mode;
1940         }
1941
1942         if (S_ISGITLINK($mode)) {
1943                 return "submodule";
1944         } elsif (S_ISDIR($mode & S_IFMT)) {
1945                 return "directory";
1946         } elsif (S_ISLNK($mode)) {
1947                 return "symlink";
1948         } elsif (S_ISREG($mode)) {
1949                 if ($mode & S_IXUSR) {
1950                         return "executable";
1951                 } else {
1952                         return "file";
1953                 };
1954         } else {
1955                 return "unknown";
1956         }
1957 }
1958
1959
1960 ## ----------------------------------------------------------------------
1961 ## functions returning short HTML fragments, or transforming HTML fragments
1962 ## which don't belong to other sections
1963
1964 # format line of commit message.
1965 sub format_log_line_html {
1966         my $line = shift;
1967
1968         $line = esc_html($line, -nbsp=>1);
1969         $line =~ s{\b([0-9a-fA-F]{8,40})\b}{
1970                 $cgi->a({-href => href(action=>"object", hash=>$1),
1971                                         -class => "text"}, $1);
1972         }eg;
1973
1974         return $line;
1975 }
1976
1977 # format marker of refs pointing to given object
1978
1979 # the destination action is chosen based on object type and current context:
1980 # - for annotated tags, we choose the tag view unless it's the current view
1981 #   already, in which case we go to shortlog view
1982 # - for other refs, we keep the current view if we're in history, shortlog or
1983 #   log view, and select shortlog otherwise
1984 sub format_ref_marker {
1985         my ($refs, $id) = @_;
1986         my $markers = '';
1987
1988         if (defined $refs->{$id}) {
1989                 foreach my $ref (@{$refs->{$id}}) {
1990                         # this code exploits the fact that non-lightweight tags are the
1991                         # only indirect objects, and that they are the only objects for which
1992                         # we want to use tag instead of shortlog as action
1993                         my ($type, $name) = qw();
1994                         my $indirect = ($ref =~ s/\^\{\}$//);
1995                         # e.g. tags/v2.6.11 or heads/next
1996                         if ($ref =~ m!^(.*?)s?/(.*)$!) {
1997                                 $type = $1;
1998                                 $name = $2;
1999                         } else {
2000                                 $type = "ref";
2001                                 $name = $ref;
2002                         }
2003
2004                         my $class = $type;
2005                         $class .= " indirect" if $indirect;
2006
2007                         my $dest_action = "shortlog";
2008
2009                         if ($indirect) {
2010                                 $dest_action = "tag" unless $action eq "tag";
2011                         } elsif ($action =~ /^(history|(short)?log)$/) {
2012                                 $dest_action = $action;
2013                         }
2014
2015                         my $dest = "";
2016                         $dest .= "refs/" unless $ref =~ m!^refs/!;
2017                         $dest .= $ref;
2018
2019                         my $link = $cgi->a({
2020                                 -href => href(
2021                                         action=>$dest_action,
2022                                         hash=>$dest
2023                                 )}, $name);
2024
2025                         $markers .= " <span class=\"".esc_attr($class)."\" title=\"".esc_attr($ref)."\">" .
2026                                 $link . "</span>";
2027                 }
2028         }
2029
2030         if ($markers) {
2031                 return ' <span class="refs">'. $markers . '</span>';
2032         } else {
2033                 return "";
2034         }
2035 }
2036
2037 # format, perhaps shortened and with markers, title line
2038 sub format_subject_html {
2039         my ($long, $short, $href, $extra) = @_;
2040         $extra = '' unless defined($extra);
2041
2042         if (length($short) < length($long)) {
2043                 $long =~ s/[[:cntrl:]]/?/g;
2044                 return $cgi->a({-href => $href, -class => "list subject",
2045                                 -title => to_utf8($long)},
2046                        esc_html($short)) . $extra;
2047         } else {
2048                 return $cgi->a({-href => $href, -class => "list subject"},
2049                        esc_html($long)) . $extra;
2050         }
2051 }
2052
2053 # Rather than recomputing the url for an email multiple times, we cache it
2054 # after the first hit. This gives a visible benefit in views where the avatar
2055 # for the same email is used repeatedly (e.g. shortlog).
2056 # The cache is shared by all avatar engines (currently gravatar only), which
2057 # are free to use it as preferred. Since only one avatar engine is used for any
2058 # given page, there's no risk for cache conflicts.
2059 our %avatar_cache = ();
2060
2061 # Compute the picon url for a given email, by using the picon search service over at
2062 # http://www.cs.indiana.edu/picons/search.html
2063 sub picon_url {
2064         my $email = lc shift;
2065         if (!$avatar_cache{$email}) {
2066                 my ($user, $domain) = split('@', $email);
2067                 $avatar_cache{$email} =
2068                         "http://www.cs.indiana.edu/cgi-pub/kinzler/piconsearch.cgi/" .
2069                         "$domain/$user/" .
2070                         "users+domains+unknown/up/single";
2071         }
2072         return $avatar_cache{$email};
2073 }
2074
2075 # Compute the gravatar url for a given email, if it's not in the cache already.
2076 # Gravatar stores only the part of the URL before the size, since that's the
2077 # one computationally more expensive. This also allows reuse of the cache for
2078 # different sizes (for this particular engine).
2079 sub gravatar_url {
2080         my $email = lc shift;
2081         my $size = shift;
2082         $avatar_cache{$email} ||=
2083                 "http://www.gravatar.com/avatar/" .
2084                         Digest::MD5::md5_hex($email) . "?s=";
2085         return $avatar_cache{$email} . $size;
2086 }
2087
2088 # Insert an avatar for the given $email at the given $size if the feature
2089 # is enabled.
2090 sub git_get_avatar {
2091         my ($email, %opts) = @_;
2092         my $pre_white  = ($opts{-pad_before} ? "&nbsp;" : "");
2093         my $post_white = ($opts{-pad_after}  ? "&nbsp;" : "");
2094         $opts{-size} ||= 'default';
2095         my $size = $avatar_size{$opts{-size}} || $avatar_size{'default'};
2096         my $url = "";
2097         if ($git_avatar eq 'gravatar') {
2098                 $url = gravatar_url($email, $size);
2099         } elsif ($git_avatar eq 'picon') {
2100                 $url = picon_url($email);
2101         }
2102         # Other providers can be added by extending the if chain, defining $url
2103         # as needed. If no variant puts something in $url, we assume avatars
2104         # are completely disabled/unavailable.
2105         if ($url) {
2106                 return $pre_white .
2107                        "<img width=\"$size\" " .
2108                             "class=\"avatar\" " .
2109                             "src=\"".esc_url($url)."\" " .
2110                             "alt=\"\" " .
2111                        "/>" . $post_white;
2112         } else {
2113                 return "";
2114         }
2115 }
2116
2117 sub format_search_author {
2118         my ($author, $searchtype, $displaytext) = @_;
2119         my $have_search = gitweb_check_feature('search');
2120
2121         if ($have_search) {
2122                 my $performed = "";
2123                 if ($searchtype eq 'author') {
2124                         $performed = "authored";
2125                 } elsif ($searchtype eq 'committer') {
2126                         $performed = "committed";
2127                 }
2128
2129                 return $cgi->a({-href => href(action=>"search", hash=>$hash,
2130                                 searchtext=>$author,
2131                                 searchtype=>$searchtype), class=>"list",
2132                                 title=>"Search for commits $performed by $author"},
2133                                 $displaytext);
2134
2135         } else {
2136                 return $displaytext;
2137         }
2138 }
2139
2140 # format the author name of the given commit with the given tag
2141 # the author name is chopped and escaped according to the other
2142 # optional parameters (see chop_str).
2143 sub format_author_html {
2144         my $tag = shift;
2145         my $co = shift;
2146         my $author = chop_and_escape_str($co->{'author_name'}, @_);
2147         return "<$tag class=\"author\">" .
2148                format_search_author($co->{'author_name'}, "author",
2149                        git_get_avatar($co->{'author_email'}, -pad_after => 1) .
2150                        $author) .
2151                "</$tag>";
2152 }
2153
2154 # format git diff header line, i.e. "diff --(git|combined|cc) ..."
2155 sub format_git_diff_header_line {
2156         my $line = shift;
2157         my $diffinfo = shift;
2158         my ($from, $to) = @_;
2159
2160         if ($diffinfo->{'nparents'}) {
2161                 # combined diff
2162                 $line =~ s!^(diff (.*?) )"?.*$!$1!;
2163                 if ($to->{'href'}) {
2164                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2165                                          esc_path($to->{'file'}));
2166                 } else { # file was deleted (no href)
2167                         $line .= esc_path($to->{'file'});
2168                 }
2169         } else {
2170                 # "ordinary" diff
2171                 $line =~ s!^(diff (.*?) )"?a/.*$!$1!;
2172                 if ($from->{'href'}) {
2173                         $line .= $cgi->a({-href => $from->{'href'}, -class => "path"},
2174                                          'a/' . esc_path($from->{'file'}));
2175                 } else { # file was added (no href)
2176                         $line .= 'a/' . esc_path($from->{'file'});
2177                 }
2178                 $line .= ' ';
2179                 if ($to->{'href'}) {
2180                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2181                                          'b/' . esc_path($to->{'file'}));
2182                 } else { # file was deleted
2183                         $line .= 'b/' . esc_path($to->{'file'});
2184                 }
2185         }
2186
2187         return "<div class=\"diff header\">$line</div>\n";
2188 }
2189
2190 # format extended diff header line, before patch itself
2191 sub format_extended_diff_header_line {
2192         my $line = shift;
2193         my $diffinfo = shift;
2194         my ($from, $to) = @_;
2195
2196         # match <path>
2197         if ($line =~ s!^((copy|rename) from ).*$!$1! && $from->{'href'}) {
2198                 $line .= $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2199                                        esc_path($from->{'file'}));
2200         }
2201         if ($line =~ s!^((copy|rename) to ).*$!$1! && $to->{'href'}) {
2202                 $line .= $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2203                                  esc_path($to->{'file'}));
2204         }
2205         # match single <mode>
2206         if ($line =~ m/\s(\d{6})$/) {
2207                 $line .= '<span class="info"> (' .
2208                          file_type_long($1) .
2209                          ')</span>';
2210         }
2211         # match <hash>
2212         if ($line =~ m/^index [0-9a-fA-F]{40},[0-9a-fA-F]{40}/) {
2213                 # can match only for combined diff
2214                 $line = 'index ';
2215                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2216                         if ($from->{'href'}[$i]) {
2217                                 $line .= $cgi->a({-href=>$from->{'href'}[$i],
2218                                                   -class=>"hash"},
2219                                                  substr($diffinfo->{'from_id'}[$i],0,7));
2220                         } else {
2221                                 $line .= '0' x 7;
2222                         }
2223                         # separator
2224                         $line .= ',' if ($i < $diffinfo->{'nparents'} - 1);
2225                 }
2226                 $line .= '..';
2227                 if ($to->{'href'}) {
2228                         $line .= $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2229                                          substr($diffinfo->{'to_id'},0,7));
2230                 } else {
2231                         $line .= '0' x 7;
2232                 }
2233
2234         } elsif ($line =~ m/^index [0-9a-fA-F]{40}..[0-9a-fA-F]{40}/) {
2235                 # can match only for ordinary diff
2236                 my ($from_link, $to_link);
2237                 if ($from->{'href'}) {
2238                         $from_link = $cgi->a({-href=>$from->{'href'}, -class=>"hash"},
2239                                              substr($diffinfo->{'from_id'},0,7));
2240                 } else {
2241                         $from_link = '0' x 7;
2242                 }
2243                 if ($to->{'href'}) {
2244                         $to_link = $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2245                                            substr($diffinfo->{'to_id'},0,7));
2246                 } else {
2247                         $to_link = '0' x 7;
2248                 }
2249                 my ($from_id, $to_id) = ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
2250                 $line =~ s!$from_id\.\.$to_id!$from_link..$to_link!;
2251         }
2252
2253         return $line . "<br/>\n";
2254 }
2255
2256 # format from-file/to-file diff header
2257 sub format_diff_from_to_header {
2258         my ($from_line, $to_line, $diffinfo, $from, $to, @parents) = @_;
2259         my $line;
2260         my $result = '';
2261
2262         $line = $from_line;
2263         #assert($line =~ m/^---/) if DEBUG;
2264         # no extra formatting for "^--- /dev/null"
2265         if (! $diffinfo->{'nparents'}) {
2266                 # ordinary (single parent) diff
2267                 if ($line =~ m!^--- "?a/!) {
2268                         if ($from->{'href'}) {
2269                                 $line = '--- a/' .
2270                                         $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2271                                                 esc_path($from->{'file'}));
2272                         } else {
2273                                 $line = '--- a/' .
2274                                         esc_path($from->{'file'});
2275                         }
2276                 }
2277                 $result .= qq!<div class="diff from_file">$line</div>\n!;
2278
2279         } else {
2280                 # combined diff (merge commit)
2281                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2282                         if ($from->{'href'}[$i]) {
2283                                 $line = '--- ' .
2284                                         $cgi->a({-href=>href(action=>"blobdiff",
2285                                                              hash_parent=>$diffinfo->{'from_id'}[$i],
2286                                                              hash_parent_base=>$parents[$i],
2287                                                              file_parent=>$from->{'file'}[$i],
2288                                                              hash=>$diffinfo->{'to_id'},
2289                                                              hash_base=>$hash,
2290                                                              file_name=>$to->{'file'}),
2291                                                  -class=>"path",
2292                                                  -title=>"diff" . ($i+1)},
2293                                                 $i+1) .
2294                                         '/' .
2295                                         $cgi->a({-href=>$from->{'href'}[$i], -class=>"path"},
2296                                                 esc_path($from->{'file'}[$i]));
2297                         } else {
2298                                 $line = '--- /dev/null';
2299                         }
2300                         $result .= qq!<div class="diff from_file">$line</div>\n!;
2301                 }
2302         }
2303
2304         $line = $to_line;
2305         #assert($line =~ m/^\+\+\+/) if DEBUG;
2306         # no extra formatting for "^+++ /dev/null"
2307         if ($line =~ m!^\+\+\+ "?b/!) {
2308                 if ($to->{'href'}) {
2309                         $line = '+++ b/' .
2310                                 $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2311                                         esc_path($to->{'file'}));
2312                 } else {
2313                         $line = '+++ b/' .
2314                                 esc_path($to->{'file'});
2315                 }
2316         }
2317         $result .= qq!<div class="diff to_file">$line</div>\n!;
2318
2319         return $result;
2320 }
2321
2322 # create note for patch simplified by combined diff
2323 sub format_diff_cc_simplified {
2324         my ($diffinfo, @parents) = @_;
2325         my $result = '';
2326
2327         $result .= "<div class=\"diff header\">" .
2328                    "diff --cc ";
2329         if (!is_deleted($diffinfo)) {
2330                 $result .= $cgi->a({-href => href(action=>"blob",
2331                                                   hash_base=>$hash,
2332                                                   hash=>$diffinfo->{'to_id'},
2333                                                   file_name=>$diffinfo->{'to_file'}),
2334                                     -class => "path"},
2335                                    esc_path($diffinfo->{'to_file'}));
2336         } else {
2337                 $result .= esc_path($diffinfo->{'to_file'});
2338         }
2339         $result .= "</div>\n" . # class="diff header"
2340                    "<div class=\"diff nodifferences\">" .
2341                    "Simple merge" .
2342                    "</div>\n"; # class="diff nodifferences"
2343
2344         return $result;
2345 }
2346
2347 sub diff_line_class {
2348         my ($line, $from, $to) = @_;
2349
2350         # ordinary diff
2351         my $num_sign = 1;
2352         # combined diff
2353         if ($from && $to && ref($from->{'href'}) eq "ARRAY") {
2354                 $num_sign = scalar @{$from->{'href'}};
2355         }
2356
2357         my @diff_line_classifier = (
2358                 { regexp => qr/^\@\@{$num_sign} /, class => "chunk_header"},
2359                 { regexp => qr/^\\/,               class => "incomplete"  },
2360                 { regexp => qr/^ {$num_sign}/,     class => "ctx" },
2361                 # classifier for context must come before classifier add/rem,
2362                 # or we would have to use more complicated regexp, for example
2363                 # qr/(?= {0,$m}\+)[+ ]{$num_sign}/, where $m = $num_sign - 1;
2364                 { regexp => qr/^[+ ]{$num_sign}/,   class => "add" },
2365                 { regexp => qr/^[- ]{$num_sign}/,   class => "rem" },
2366         );
2367         for my $clsfy (@diff_line_classifier) {
2368                 return $clsfy->{'class'}
2369                         if ($line =~ $clsfy->{'regexp'});
2370         }
2371
2372         # fallback
2373         return "";
2374 }
2375
2376 # assumes that $from and $to are defined and correctly filled,
2377 # and that $line holds a line of chunk header for unified diff
2378 sub format_unidiff_chunk_header {
2379         my ($line, $from, $to) = @_;
2380
2381         my ($from_text, $from_start, $from_lines, $to_text, $to_start, $to_lines, $section) =
2382                 $line =~ m/^\@{2} (-(\d+)(?:,(\d+))?) (\+(\d+)(?:,(\d+))?) \@{2}(.*)$/;
2383
2384         $from_lines = 0 unless defined $from_lines;
2385         $to_lines   = 0 unless defined $to_lines;
2386
2387         if ($from->{'href'}) {
2388                 $from_text = $cgi->a({-href=>"$from->{'href'}#l$from_start",
2389                                      -class=>"list"}, $from_text);
2390         }
2391         if ($to->{'href'}) {
2392                 $to_text   = $cgi->a({-href=>"$to->{'href'}#l$to_start",
2393                                      -class=>"list"}, $to_text);
2394         }
2395         $line = "<span class=\"chunk_info\">@@ $from_text $to_text @@</span>" .
2396                 "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2397         return $line;
2398 }
2399
2400 # assumes that $from and $to are defined and correctly filled,
2401 # and that $line holds a line of chunk header for combined diff
2402 sub format_cc_diff_chunk_header {
2403         my ($line, $from, $to) = @_;
2404
2405         my ($prefix, $ranges, $section) = $line =~ m/^(\@+) (.*?) \@+(.*)$/;
2406         my (@from_text, @from_start, @from_nlines, $to_text, $to_start, $to_nlines);
2407
2408         @from_text = split(' ', $ranges);
2409         for (my $i = 0; $i < @from_text; ++$i) {
2410                 ($from_start[$i], $from_nlines[$i]) =
2411                         (split(',', substr($from_text[$i], 1)), 0);
2412         }
2413
2414         $to_text   = pop @from_text;
2415         $to_start  = pop @from_start;
2416         $to_nlines = pop @from_nlines;
2417
2418         $line = "<span class=\"chunk_info\">$prefix ";
2419         for (my $i = 0; $i < @from_text; ++$i) {
2420                 if ($from->{'href'}[$i]) {
2421                         $line .= $cgi->a({-href=>"$from->{'href'}[$i]#l$from_start[$i]",
2422                                           -class=>"list"}, $from_text[$i]);
2423                 } else {
2424                         $line .= $from_text[$i];
2425                 }
2426                 $line .= " ";
2427         }
2428         if ($to->{'href'}) {
2429                 $line .= $cgi->a({-href=>"$to->{'href'}#l$to_start",
2430                                   -class=>"list"}, $to_text);
2431         } else {
2432                 $line .= $to_text;
2433         }
2434         $line .= " $prefix</span>" .
2435                  "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2436         return $line;
2437 }
2438
2439 # process patch (diff) line (not to be used for diff headers),
2440 # returning HTML-formatted (but not wrapped) line.
2441 # If the line is passed as a reference, it is treated as HTML and not
2442 # esc_html()'ed.
2443 sub format_diff_line {
2444         my ($line, $diff_class, $from, $to) = @_;
2445
2446         if (ref($line)) {
2447                 $line = $$line;
2448         } else {
2449                 chomp $line;
2450                 $line = untabify($line);
2451
2452                 if ($from && $to && $line =~ m/^\@{2} /) {
2453                         $line = format_unidiff_chunk_header($line, $from, $to);
2454                 } elsif ($from && $to && $line =~ m/^\@{3}/) {
2455                         $line = format_cc_diff_chunk_header($line, $from, $to);
2456                 } else {
2457                         $line = esc_html($line, -nbsp=>1);
2458                 }
2459         }
2460
2461         my $diff_classes = "diff";
2462         $diff_classes .= " $diff_class" if ($diff_class);
2463         $line = "<div class=\"$diff_classes\">$line</div>\n";
2464
2465         return $line;
2466 }
2467
2468 # Generates undef or something like "_snapshot_" or "snapshot (_tbz2_ _zip_)",
2469 # linked.  Pass the hash of the tree/commit to snapshot.
2470 sub format_snapshot_links {
2471         my ($hash) = @_;
2472         my $num_fmts = @snapshot_fmts;
2473         if ($num_fmts > 1) {
2474                 # A parenthesized list of links bearing format names.
2475                 # e.g. "snapshot (_tar.gz_ _zip_)"
2476                 return "snapshot (" . join(' ', map
2477                         $cgi->a({
2478                                 -href => href(
2479                                         action=>"snapshot",
2480                                         hash=>$hash,
2481                                         snapshot_format=>$_
2482                                 )
2483                         }, $known_snapshot_formats{$_}{'display'})
2484                 , @snapshot_fmts) . ")";
2485         } elsif ($num_fmts == 1) {
2486                 # A single "snapshot" link whose tooltip bears the format name.
2487                 # i.e. "_snapshot_"
2488                 my ($fmt) = @snapshot_fmts;
2489                 return
2490                         $cgi->a({
2491                                 -href => href(
2492                                         action=>"snapshot",
2493                                         hash=>$hash,
2494                                         snapshot_format=>$fmt
2495                                 ),
2496                                 -title => "in format: $known_snapshot_formats{$fmt}{'display'}"
2497                         }, "snapshot");
2498         } else { # $num_fmts == 0
2499                 return undef;
2500         }
2501 }
2502
2503 ## ......................................................................
2504 ## functions returning values to be passed, perhaps after some
2505 ## transformation, to other functions; e.g. returning arguments to href()
2506
2507 # returns hash to be passed to href to generate gitweb URL
2508 # in -title key it returns description of link
2509 sub get_feed_info {
2510         my $format = shift || 'Atom';
2511         my %res = (action => lc($format));
2512
2513         # feed links are possible only for project views
2514         return unless (defined $project);
2515         # some views should link to OPML, or to generic project feed,
2516         # or don't have specific feed yet (so they should use generic)
2517         return if (!$action || $action =~ /^(?:tags|heads|forks|tag|search)$/x);
2518
2519         my $branch;
2520         # branches refs uses 'refs/heads/' prefix (fullname) to differentiate
2521         # from tag links; this also makes possible to detect branch links
2522         if ((defined $hash_base && $hash_base =~ m!^refs/heads/(.*)$!) ||
2523             (defined $hash      && $hash      =~ m!^refs/heads/(.*)$!)) {
2524                 $branch = $1;
2525         }
2526         # find log type for feed description (title)
2527         my $type = 'log';
2528         if (defined $file_name) {
2529                 $type  = "history of $file_name";
2530                 $type .= "/" if ($action eq 'tree');
2531                 $type .= " on '$branch'" if (defined $branch);
2532         } else {
2533                 $type = "log of $branch" if (defined $branch);
2534         }
2535
2536         $res{-title} = $type;
2537         $res{'hash'} = (defined $branch ? "refs/heads/$branch" : undef);
2538         $res{'file_name'} = $file_name;
2539
2540         return %res;
2541 }
2542
2543 ## ----------------------------------------------------------------------
2544 ## git utility subroutines, invoking git commands
2545
2546 # returns path to the core git executable and the --git-dir parameter as list
2547 sub git_cmd {
2548         $number_of_git_cmds++;
2549         return $GIT, '--git-dir='.$git_dir;
2550 }
2551
2552 # quote the given arguments for passing them to the shell
2553 # quote_command("command", "arg 1", "arg with ' and ! characters")
2554 # => "'command' 'arg 1' 'arg with '\'' and '\!' characters'"
2555 # Try to avoid using this function wherever possible.
2556 sub quote_command {
2557         return join(' ',
2558                 map { my $a = $_; $a =~ s/(['!])/'\\$1'/g; "'$a'" } @_ );
2559 }
2560
2561 # get HEAD ref of given project as hash
2562 sub git_get_head_hash {
2563         return git_get_full_hash(shift, 'HEAD');
2564 }
2565
2566 sub git_get_full_hash {
2567         return git_get_hash(@_);
2568 }
2569
2570 sub git_get_short_hash {
2571         return git_get_hash(@_, '--short=7');
2572 }
2573
2574 sub git_get_hash {
2575         my ($project, $hash, @options) = @_;
2576         my $o_git_dir = $git_dir;
2577         my $retval = undef;
2578         $git_dir = "$projectroot/$project";
2579         if (open my $fd, '-|', git_cmd(), 'rev-parse',
2580             '--verify', '-q', @options, $hash) {
2581                 $retval = <$fd>;
2582                 chomp $retval if defined $retval;
2583                 close $fd;
2584         }
2585         if (defined $o_git_dir) {
2586                 $git_dir = $o_git_dir;
2587         }
2588         return $retval;
2589 }
2590
2591 # get type of given object
2592 sub git_get_type {
2593         my $hash = shift;
2594
2595         open my $fd, "-|", git_cmd(), "cat-file", '-t', $hash or return;
2596         my $type = <$fd>;
2597         close $fd or return;
2598         chomp $type;
2599         return $type;
2600 }
2601
2602 # repository configuration
2603 our $config_file = '';
2604 our %config;
2605
2606 # store multiple values for single key as anonymous array reference
2607 # single values stored directly in the hash, not as [ <value> ]
2608 sub hash_set_multi {
2609         my ($hash, $key, $value) = @_;
2610
2611         if (!exists $hash->{$key}) {
2612                 $hash->{$key} = $value;
2613         } elsif (!ref $hash->{$key}) {
2614                 $hash->{$key} = [ $hash->{$key}, $value ];
2615         } else {
2616                 push @{$hash->{$key}}, $value;
2617         }
2618 }
2619
2620 # return hash of git project configuration
2621 # optionally limited to some section, e.g. 'gitweb'
2622 sub git_parse_project_config {
2623         my $section_regexp = shift;
2624         my %config;
2625
2626         local $/ = "\0";
2627
2628         open my $fh, "-|", git_cmd(), "config", '-z', '-l',
2629                 or return;
2630
2631         while (my $keyval = <$fh>) {
2632                 chomp $keyval;
2633                 my ($key, $value) = split(/\n/, $keyval, 2);
2634
2635                 hash_set_multi(\%config, $key, $value)
2636                         if (!defined $section_regexp || $key =~ /^(?:$section_regexp)\./o);
2637         }
2638         close $fh;
2639
2640         return %config;
2641 }
2642
2643 # convert config value to boolean: 'true' or 'false'
2644 # no value, number > 0, 'true' and 'yes' values are true
2645 # rest of values are treated as false (never as error)
2646 sub config_to_bool {
2647         my $val = shift;
2648
2649         return 1 if !defined $val;             # section.key
2650
2651         # strip leading and trailing whitespace
2652         $val =~ s/^\s+//;
2653         $val =~ s/\s+$//;
2654
2655         return (($val =~ /^\d+$/ && $val) ||   # section.key = 1
2656                 ($val =~ /^(?:true|yes)$/i));  # section.key = true
2657 }
2658
2659 # convert config value to simple decimal number
2660 # an optional value suffix of 'k', 'm', or 'g' will cause the value
2661 # to be multiplied by 1024, 1048576, or 1073741824
2662 sub config_to_int {
2663         my $val = shift;
2664
2665         # strip leading and trailing whitespace
2666         $val =~ s/^\s+//;
2667         $val =~ s/\s+$//;
2668
2669         if (my ($num, $unit) = ($val =~ /^([0-9]*)([kmg])$/i)) {
2670                 $unit = lc($unit);
2671                 # unknown unit is treated as 1
2672                 return $num * ($unit eq 'g' ? 1073741824 :
2673                                $unit eq 'm' ?    1048576 :
2674                                $unit eq 'k' ?       1024 : 1);
2675         }
2676         return $val;
2677 }
2678
2679 # convert config value to array reference, if needed
2680 sub config_to_multi {
2681         my $val = shift;
2682
2683         return ref($val) ? $val : (defined($val) ? [ $val ] : []);
2684 }
2685
2686 sub git_get_project_config {
2687         my ($key, $type) = @_;
2688
2689         return unless defined $git_dir;
2690
2691         # key sanity check
2692         return unless ($key);
2693         # only subsection, if exists, is case sensitive,
2694         # and not lowercased by 'git config -z -l'
2695         if (my ($hi, $mi, $lo) = ($key =~ /^([^.]*)\.(.*)\.([^.]*)$/)) {
2696                 $key = join(".", lc($hi), $mi, lc($lo));
2697         } else {
2698                 $key = lc($key);
2699         }
2700         $key =~ s/^gitweb\.//;
2701         return if ($key =~ m/\W/);
2702
2703         # type sanity check
2704         if (defined $type) {
2705                 $type =~ s/^--//;
2706                 $type = undef
2707                         unless ($type eq 'bool' || $type eq 'int');
2708         }
2709
2710         # get config
2711         if (!defined $config_file ||
2712             $config_file ne "$git_dir/config") {
2713                 %config = git_parse_project_config('gitweb');
2714                 $config_file = "$git_dir/config";
2715         }
2716
2717         # check if config variable (key) exists
2718         return unless exists $config{"gitweb.$key"};
2719
2720         # ensure given type
2721         if (!defined $type) {
2722                 return $config{"gitweb.$key"};
2723         } elsif ($type eq 'bool') {
2724                 # backward compatibility: 'git config --bool' returns true/false
2725                 return config_to_bool($config{"gitweb.$key"}) ? 'true' : 'false';
2726         } elsif ($type eq 'int') {
2727                 return config_to_int($config{"gitweb.$key"});
2728         }
2729         return $config{"gitweb.$key"};
2730 }
2731
2732 # get hash of given path at given ref
2733 sub git_get_hash_by_path {
2734         my $base = shift;
2735         my $path = shift || return undef;
2736         my $type = shift;
2737
2738         $path =~ s,/+$,,;
2739
2740         open my $fd, "-|", git_cmd(), "ls-tree", $base, "--", $path
2741                 or die_error(500, "Open git-ls-tree failed");
2742         my $line = <$fd>;
2743         close $fd or return undef;
2744
2745         if (!defined $line) {
2746                 # there is no tree or hash given by $path at $base
2747                 return undef;
2748         }
2749
2750         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
2751         $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/;
2752         if (defined $type && $type ne $2) {
2753                 # type doesn't match
2754                 return undef;
2755         }
2756         return $3;
2757 }
2758
2759 # get path of entry with given hash at given tree-ish (ref)
2760 # used to get 'from' filename for combined diff (merge commit) for renames
2761 sub git_get_path_by_hash {
2762         my $base = shift || return;
2763         my $hash = shift || return;
2764
2765         local $/ = "\0";
2766
2767         open my $fd, "-|", git_cmd(), "ls-tree", '-r', '-t', '-z', $base
2768                 or return undef;
2769         while (my $line = <$fd>) {
2770                 chomp $line;
2771
2772                 #'040000 tree 595596a6a9117ddba9fe379b6b012b558bac8423  gitweb'
2773                 #'100644 blob e02e90f0429be0d2a69b76571101f20b8f75530f  gitweb/README'
2774                 if ($line =~ m/(?:[0-9]+) (?:.+) $hash\t(.+)$/) {
2775                         close $fd;
2776                         return $1;
2777                 }
2778         }
2779         close $fd;
2780         return undef;
2781 }
2782
2783 ## ......................................................................
2784 ## git utility functions, directly accessing git repository
2785
2786 # get the value of config variable either from file named as the variable
2787 # itself in the repository ($GIT_DIR/$name file), or from gitweb.$name
2788 # configuration variable in the repository config file.
2789 sub git_get_file_or_project_config {
2790         my ($path, $name) = @_;
2791
2792         $git_dir = "$projectroot/$path";
2793         open my $fd, '<', "$git_dir/$name"
2794                 or return git_get_project_config($name);
2795         my $conf = <$fd>;
2796         close $fd;
2797         if (defined $conf) {
2798                 chomp $conf;
2799         }
2800         return $conf;
2801 }
2802
2803 sub git_get_project_description {
2804         my $path = shift;
2805         return git_get_file_or_project_config($path, 'description');
2806 }
2807
2808 sub git_get_project_category {
2809         my $path = shift;
2810         return git_get_file_or_project_config($path, 'category');
2811 }
2812
2813
2814 # supported formats:
2815 # * $GIT_DIR/ctags/<tagname> file (in 'ctags' subdirectory)
2816 #   - if its contents is a number, use it as tag weight,
2817 #   - otherwise add a tag with weight 1
2818 # * $GIT_DIR/ctags file, each line is a tag (with weight 1)
2819 #   the same value multiple times increases tag weight
2820 # * `gitweb.ctag' multi-valued repo config variable
2821 sub git_get_project_ctags {
2822         my $project = shift;
2823         my $ctags = {};
2824
2825         $git_dir = "$projectroot/$project";
2826         if (opendir my $dh, "$git_dir/ctags") {
2827                 my @files = grep { -f $_ } map { "$git_dir/ctags/$_" } readdir($dh);
2828                 foreach my $tagfile (@files) {
2829                         open my $ct, '<', $tagfile
2830                                 or next;
2831                         my $val = <$ct>;
2832                         chomp $val if $val;
2833                         close $ct;
2834
2835                         (my $ctag = $tagfile) =~ s#.*/##;
2836                         if ($val =~ /^\d+$/) {
2837                                 $ctags->{$ctag} = $val;
2838                         } else {
2839                                 $ctags->{$ctag} = 1;
2840                         }
2841                 }
2842                 closedir $dh;
2843
2844         } elsif (open my $fh, '<', "$git_dir/ctags") {
2845                 while (my $line = <$fh>) {
2846                         chomp $line;
2847                         $ctags->{$line}++ if $line;
2848                 }
2849                 close $fh;
2850
2851         } else {
2852                 my $taglist = config_to_multi(git_get_project_config('ctag'));
2853                 foreach my $tag (@$taglist) {
2854                         $ctags->{$tag}++;
2855                 }
2856         }
2857
2858         return $ctags;
2859 }
2860
2861 # return hash, where keys are content tags ('ctags'),
2862 # and values are sum of weights of given tag in every project
2863 sub git_gather_all_ctags {
2864         my $projects = shift;
2865         my $ctags = {};
2866
2867         foreach my $p (@$projects) {
2868                 foreach my $ct (keys %{$p->{'ctags'}}) {
2869                         $ctags->{$ct} += $p->{'ctags'}->{$ct};
2870                 }
2871         }
2872
2873         return $ctags;
2874 }
2875
2876 sub git_populate_project_tagcloud {
2877         my $ctags = shift;
2878
2879         # First, merge different-cased tags; tags vote on casing
2880         my %ctags_lc;
2881         foreach (keys %$ctags) {
2882                 $ctags_lc{lc $_}->{count} += $ctags->{$_};
2883                 if (not $ctags_lc{lc $_}->{topcount}
2884                     or $ctags_lc{lc $_}->{topcount} < $ctags->{$_}) {
2885                         $ctags_lc{lc $_}->{topcount} = $ctags->{$_};
2886                         $ctags_lc{lc $_}->{topname} = $_;
2887                 }
2888         }
2889
2890         my $cloud;
2891         my $matched = $input_params{'ctag'};
2892         if (eval { require HTML::TagCloud; 1; }) {
2893                 $cloud = HTML::TagCloud->new;
2894                 foreach my $ctag (sort keys %ctags_lc) {
2895                         # Pad the title with spaces so that the cloud looks
2896                         # less crammed.
2897                         my $title = esc_html($ctags_lc{$ctag}->{topname});
2898                         $title =~ s/ /&nbsp;/g;
2899                         $title =~ s/^/&nbsp;/g;
2900                         $title =~ s/$/&nbsp;/g;
2901                         if (defined $matched && $matched eq $ctag) {
2902                                 $title = qq(<span class="match">$title</span>);
2903                         }
2904                         $cloud->add($title, href(project=>undef, ctag=>$ctag),
2905                                     $ctags_lc{$ctag}->{count});
2906                 }
2907         } else {
2908                 $cloud = {};
2909                 foreach my $ctag (keys %ctags_lc) {
2910                         my $title = esc_html($ctags_lc{$ctag}->{topname}, -nbsp=>1);
2911                         if (defined $matched && $matched eq $ctag) {
2912                                 $title = qq(<span class="match">$title</span>);
2913                         }
2914                         $cloud->{$ctag}{count} = $ctags_lc{$ctag}->{count};
2915                         $cloud->{$ctag}{ctag} =
2916                                 $cgi->a({-href=>href(project=>undef, ctag=>$ctag)}, $title);
2917                 }
2918         }
2919         return $cloud;
2920 }
2921
2922 sub git_show_project_tagcloud {
2923         my ($cloud, $count) = @_;
2924         if (ref $cloud eq 'HTML::TagCloud') {
2925                 return $cloud->html_and_css($count);
2926         } else {
2927                 my @tags = sort { $cloud->{$a}->{'count'} <=> $cloud->{$b}->{'count'} } keys %$cloud;
2928                 return
2929                         '<div id="htmltagcloud"'.($project ? '' : ' align="center"').'>' .
2930                         join (', ', map {
2931                                 $cloud->{$_}->{'ctag'}
2932                         } splice(@tags, 0, $count)) .
2933                         '</div>';
2934         }
2935 }
2936
2937 sub git_get_project_url_list {
2938         my $path = shift;
2939
2940         $git_dir = "$projectroot/$path";
2941         open my $fd, '<', "$git_dir/cloneurl"
2942                 or return wantarray ?
2943                 @{ config_to_multi(git_get_project_config('url')) } :
2944                    config_to_multi(git_get_project_config('url'));
2945         my @git_project_url_list = map { chomp; $_ } <$fd>;
2946         close $fd;
2947
2948         return wantarray ? @git_project_url_list : \@git_project_url_list;
2949 }
2950
2951 sub git_get_projects_list {
2952         my $filter = shift || '';
2953         my $paranoid = shift;
2954         my @list;
2955
2956         if (-d $projects_list) {
2957                 # search in directory
2958                 my $dir = $projects_list;
2959                 # remove the trailing "/"
2960                 $dir =~ s!/+$!!;
2961                 my $pfxlen = length("$dir");
2962                 my $pfxdepth = ($dir =~ tr!/!!);
2963                 # when filtering, search only given subdirectory
2964                 if ($filter && !$paranoid) {
2965                         $dir .= "/$filter";
2966                         $dir =~ s!/+$!!;
2967                 }
2968
2969                 File::Find::find({
2970                         follow_fast => 1, # follow symbolic links
2971                         follow_skip => 2, # ignore duplicates
2972                         dangling_symlinks => 0, # ignore dangling symlinks, silently
2973                         wanted => sub {
2974                                 # global variables
2975                                 our $project_maxdepth;
2976                                 our $projectroot;
2977                                 # skip project-list toplevel, if we get it.
2978                                 return if (m!^[/.]$!);
2979                                 # only directories can be git repositories
2980                                 return unless (-d $_);
2981                                 # don't traverse too deep (Find is super slow on os x)
2982                                 # $project_maxdepth excludes depth of $projectroot
2983                                 if (($File::Find::name =~ tr!/!!) - $pfxdepth > $project_maxdepth) {
2984                                         $File::Find::prune = 1;
2985                                         return;
2986                                 }
2987
2988                                 my $path = substr($File::Find::name, $pfxlen + 1);
2989                                 # paranoidly only filter here
2990                                 if ($paranoid && $filter && $path !~ m!^\Q$filter\E/!) {
2991                                         next;
2992                                 }
2993                                 # we check related file in $projectroot
2994                                 if (check_export_ok("$projectroot/$path")) {
2995                                         push @list, { path => $path };
2996                                         $File::Find::prune = 1;
2997                                 }
2998                         },
2999                 }, "$dir");
3000
3001         } elsif (-f $projects_list) {
3002                 # read from file(url-encoded):
3003                 # 'git%2Fgit.git Linus+Torvalds'
3004                 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
3005                 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
3006                 open my $fd, '<', $projects_list or return;
3007         PROJECT:
3008                 while (my $line = <$fd>) {
3009                         chomp $line;
3010                         my ($path, $owner) = split ' ', $line;
3011                         $path = unescape($path);
3012                         $owner = unescape($owner);
3013                         if (!defined $path) {
3014                                 next;
3015                         }
3016                         # if $filter is rpovided, check if $path begins with $filter
3017                         if ($filter && $path !~ m!^\Q$filter\E/!) {
3018                                 next;
3019                         }
3020                         if (check_export_ok("$projectroot/$path")) {
3021                                 my $pr = {
3022                                         path => $path
3023                                 };
3024                                 if ($owner) {
3025                                         $pr->{'owner'} = to_utf8($owner);
3026                                 }
3027                                 push @list, $pr;
3028                         }
3029                 }
3030                 close $fd;
3031         }
3032         return @list;
3033 }
3034
3035 # written with help of Tree::Trie module (Perl Artistic License, GPL compatibile)
3036 # as side effects it sets 'forks' field to list of forks for forked projects
3037 sub filter_forks_from_projects_list {
3038         my $projects = shift;
3039
3040         my %trie; # prefix tree of directories (path components)
3041         # generate trie out of those directories that might contain forks
3042         foreach my $pr (@$projects) {
3043                 my $path = $pr->{'path'};
3044                 $path =~ s/\.git$//;      # forks of 'repo.git' are in 'repo/' directory
3045                 next if ($path =~ m!/$!); # skip non-bare repositories, e.g. 'repo/.git'
3046                 next unless ($path);      # skip '.git' repository: tests, git-instaweb
3047                 next unless (-d "$projectroot/$path"); # containing directory exists
3048                 $pr->{'forks'} = [];      # there can be 0 or more forks of project
3049
3050                 # add to trie
3051                 my @dirs = split('/', $path);
3052                 # walk the trie, until either runs out of components or out of trie
3053                 my $ref = \%trie;
3054                 while (scalar @dirs &&
3055                        exists($ref->{$dirs[0]})) {
3056                         $ref = $ref->{shift @dirs};
3057                 }
3058                 # create rest of trie structure from rest of components
3059                 foreach my $dir (@dirs) {
3060                         $ref = $ref->{$dir} = {};
3061                 }
3062                 # create end marker, store $pr as a data
3063                 $ref->{''} = $pr if (!exists $ref->{''});
3064         }
3065
3066         # filter out forks, by finding shortest prefix match for paths
3067         my @filtered;
3068  PROJECT:
3069         foreach my $pr (@$projects) {
3070                 # trie lookup
3071                 my $ref = \%trie;
3072         DIR:
3073                 foreach my $dir (split('/', $pr->{'path'})) {
3074                         if (exists $ref->{''}) {
3075                                 # found [shortest] prefix, is a fork - skip it
3076                                 push @{$ref->{''}{'forks'}}, $pr;
3077                                 next PROJECT;
3078                         }
3079                         if (!exists $ref->{$dir}) {
3080                                 # not in trie, cannot have prefix, not a fork
3081                                 push @filtered, $pr;
3082                                 next PROJECT;
3083                         }
3084                         # If the dir is there, we just walk one step down the trie.
3085                         $ref = $ref->{$dir};
3086                 }
3087                 # we ran out of trie
3088                 # (shouldn't happen: it's either no match, or end marker)
3089                 push @filtered, $pr;
3090         }
3091
3092         return @filtered;
3093 }
3094
3095 # note: fill_project_list_info must be run first,
3096 # for 'descr_long' and 'ctags' to be filled
3097 sub search_projects_list {
3098         my ($projlist, %opts) = @_;
3099         my $tagfilter  = $opts{'tagfilter'};
3100         my $search_re = $opts{'search_regexp'};
3101
3102         return @$projlist
3103                 unless ($tagfilter || $search_re);
3104
3105         # searching projects require filling to be run before it;
3106         fill_project_list_info($projlist,
3107                                $tagfilter  ? 'ctags' : (),
3108                                $search_re ? ('path', 'descr') : ());
3109         my @projects;
3110  PROJECT:
3111         foreach my $pr (@$projlist) {
3112
3113                 if ($tagfilter) {
3114                         next unless ref($pr->{'ctags'}) eq 'HASH';
3115                         next unless
3116                                 grep { lc($_) eq lc($tagfilter) } keys %{$pr->{'ctags'}};
3117                 }
3118
3119                 if ($search_re) {
3120                         next unless
3121                                 $pr->{'path'} =~ /$search_re/ ||
3122                                 $pr->{'descr_long'} =~ /$search_re/;
3123                 }
3124
3125                 push @projects, $pr;
3126         }
3127
3128         return @projects;
3129 }
3130
3131 our $gitweb_project_owner = undef;
3132 sub git_get_project_list_from_file {
3133
3134         return if (defined $gitweb_project_owner);
3135
3136         $gitweb_project_owner = {};
3137         # read from file (url-encoded):
3138         # 'git%2Fgit.git Linus+Torvalds'
3139         # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
3140         # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
3141         if (-f $projects_list) {
3142                 open(my $fd, '<', $projects_list);
3143                 while (my $line = <$fd>) {
3144                         chomp $line;
3145                         my ($pr, $ow) = split ' ', $line;
3146                         $pr = unescape($pr);
3147                         $ow = unescape($ow);
3148                         $gitweb_project_owner->{$pr} = to_utf8($ow);
3149                 }
3150                 close $fd;
3151         }
3152 }
3153
3154 sub git_get_project_owner {
3155         my $project = shift;
3156         my $owner;
3157
3158         return undef unless $project;
3159         $git_dir = "$projectroot/$project";
3160
3161         if (!defined $gitweb_project_owner) {
3162                 git_get_project_list_from_file();
3163         }
3164
3165         if (exists $gitweb_project_owner->{$project}) {
3166                 $owner = $gitweb_project_owner->{$project};
3167         }
3168         if (!defined $owner){
3169                 $owner = git_get_project_config('owner');
3170         }
3171         if (!defined $owner) {
3172                 $owner = get_file_owner("$git_dir");
3173         }
3174
3175         return $owner;
3176 }
3177
3178 sub git_get_last_activity {
3179         my ($path) = @_;
3180         my $fd;
3181
3182         $git_dir = "$projectroot/$path";
3183         open($fd, "-|", git_cmd(), 'for-each-ref',
3184              '--format=%(committer)',
3185              '--sort=-committerdate',
3186              '--count=1',
3187              'refs/heads') or return;
3188         my $most_recent = <$fd>;
3189         close $fd or return;
3190         if (defined $most_recent &&
3191             $most_recent =~ / (\d+) [-+][01]\d\d\d$/) {
3192                 my $timestamp = $1;
3193                 my $age = time - $timestamp;
3194                 return ($age, age_string($age));
3195         }
3196         return (undef, undef);
3197 }
3198
3199 # Implementation note: when a single remote is wanted, we cannot use 'git
3200 # remote show -n' because that command always work (assuming it's a remote URL
3201 # if it's not defined), and we cannot use 'git remote show' because that would
3202 # try to make a network roundtrip. So the only way to find if that particular
3203 # remote is defined is to walk the list provided by 'git remote -v' and stop if
3204 # and when we find what we want.
3205 sub git_get_remotes_list {
3206         my $wanted = shift;
3207         my %remotes = ();
3208
3209         open my $fd, '-|' , git_cmd(), 'remote', '-v';
3210         return unless $fd;
3211         while (my $remote = <$fd>) {
3212                 chomp $remote;
3213                 $remote =~ s!\t(.*?)\s+\((\w+)\)$!!;
3214                 next if $wanted and not $remote eq $wanted;
3215                 my ($url, $key) = ($1, $2);
3216
3217                 $remotes{$remote} ||= { 'heads' => () };
3218                 $remotes{$remote}{$key} = $url;
3219         }
3220         close $fd or return;
3221         return wantarray ? %remotes : \%remotes;
3222 }
3223
3224 # Takes a hash of remotes as first parameter and fills it by adding the
3225 # available remote heads for each of the indicated remotes.
3226 sub fill_remote_heads {
3227         my $remotes = shift;
3228         my @heads = map { "remotes/$_" } keys %$remotes;
3229         my @remoteheads = git_get_heads_list(undef, @heads);
3230         foreach my $remote (keys %$remotes) {
3231                 $remotes->{$remote}{'heads'} = [ grep {
3232                         $_->{'name'} =~ s!^$remote/!!
3233                         } @remoteheads ];
3234         }
3235 }
3236
3237 sub git_get_references {
3238         my $type = shift || "";
3239         my %refs;
3240         # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
3241         # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
3242         open my $fd, "-|", git_cmd(), "show-ref", "--dereference",
3243                 ($type ? ("--", "refs/$type") : ()) # use -- <pattern> if $type
3244                 or return;
3245
3246         while (my $line = <$fd>) {
3247                 chomp $line;
3248                 if ($line =~ m!^([0-9a-fA-F]{40})\srefs/($type.*)$!) {
3249                         if (defined $refs{$1}) {
3250                                 push @{$refs{$1}}, $2;
3251                         } else {
3252                                 $refs{$1} = [ $2 ];
3253                         }
3254                 }
3255         }
3256         close $fd or return;
3257         return \%refs;
3258 }
3259
3260 sub git_get_rev_name_tags {
3261         my $hash = shift || return undef;
3262
3263         open my $fd, "-|", git_cmd(), "name-rev", "--tags", $hash
3264                 or return;
3265         my $name_rev = <$fd>;
3266         close $fd;
3267
3268         if ($name_rev =~ m|^$hash tags/(.*)$|) {
3269                 return $1;
3270         } else {
3271                 # catches also '$hash undefined' output
3272                 return undef;
3273         }
3274 }
3275
3276 ## ----------------------------------------------------------------------
3277 ## parse to hash functions
3278
3279 sub parse_date {
3280         my $epoch = shift;
3281         my $tz = shift || "-0000";
3282
3283         my %date;
3284         my @months = ("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec");
3285         my @days = ("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");
3286         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($epoch);
3287         $date{'hour'} = $hour;
3288         $date{'minute'} = $min;
3289         $date{'mday'} = $mday;
3290         $date{'day'} = $days[$wday];
3291         $date{'month'} = $months[$mon];
3292         $date{'rfc2822'}   = sprintf "%s, %d %s %4d %02d:%02d:%02d +0000",
3293                              $days[$wday], $mday, $months[$mon], 1900+$year, $hour ,$min, $sec;
3294         $date{'mday-time'} = sprintf "%d %s %02d:%02d",
3295                              $mday, $months[$mon], $hour ,$min;
3296         $date{'iso-8601'}  = sprintf "%04d-%02d-%02dT%02d:%02d:%02dZ",
3297                              1900+$year, 1+$mon, $mday, $hour ,$min, $sec;
3298
3299         my ($tz_sign, $tz_hour, $tz_min) =
3300                 ($tz =~ m/^([-+])(\d\d)(\d\d)$/);
3301         $tz_sign = ($tz_sign eq '-' ? -1 : +1);
3302         my $local = $epoch + $tz_sign*((($tz_hour*60) + $tz_min)*60);
3303         ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($local);
3304         $date{'hour_local'} = $hour;
3305         $date{'minute_local'} = $min;
3306         $date{'tz_local'} = $tz;
3307         $date{'iso-tz'} = sprintf("%04d-%02d-%02d %02d:%02d:%02d %s",
3308                                   1900+$year, $mon+1, $mday,
3309                                   $hour, $min, $sec, $tz);
3310         return %date;
3311 }
3312
3313 sub parse_tag {
3314         my $tag_id = shift;
3315         my %tag;
3316         my @comment;
3317
3318         open my $fd, "-|", git_cmd(), "cat-file", "tag", $tag_id or return;
3319         $tag{'id'} = $tag_id;
3320         while (my $line = <$fd>) {
3321                 chomp $line;
3322                 if ($line =~ m/^object ([0-9a-fA-F]{40})$/) {
3323                         $tag{'object'} = $1;
3324                 } elsif ($line =~ m/^type (.+)$/) {
3325                         $tag{'type'} = $1;
3326                 } elsif ($line =~ m/^tag (.+)$/) {
3327                         $tag{'name'} = $1;
3328                 } elsif ($line =~ m/^tagger (.*) ([0-9]+) (.*)$/) {
3329                         $tag{'author'} = $1;
3330                         $tag{'author_epoch'} = $2;
3331                         $tag{'author_tz'} = $3;
3332                         if ($tag{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3333                                 $tag{'author_name'}  = $1;
3334                                 $tag{'author_email'} = $2;
3335                         } else {
3336                                 $tag{'author_name'} = $tag{'author'};
3337                         }
3338                 } elsif ($line =~ m/--BEGIN/) {
3339                         push @comment, $line;
3340                         last;
3341                 } elsif ($line eq "") {
3342                         last;
3343                 }
3344         }
3345         push @comment, <$fd>;
3346         $tag{'comment'} = \@comment;
3347         close $fd or return;
3348         if (!defined $tag{'name'}) {
3349                 return
3350         };
3351         return %tag
3352 }
3353
3354 sub parse_commit_text {
3355         my ($commit_text, $withparents) = @_;
3356         my @commit_lines = split '\n', $commit_text;
3357         my %co;
3358
3359         pop @commit_lines; # Remove '\0'
3360
3361         if (! @commit_lines) {
3362                 return;
3363         }
3364
3365         my $header = shift @commit_lines;
3366         if ($header !~ m/^[0-9a-fA-F]{40}/) {
3367                 return;
3368         }
3369         ($co{'id'}, my @parents) = split ' ', $header;
3370         while (my $line = shift @commit_lines) {
3371                 last if $line eq "\n";
3372                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
3373                         $co{'tree'} = $1;
3374                 } elsif ((!defined $withparents) && ($line =~ m/^parent ([0-9a-fA-F]{40})$/)) {
3375                         push @parents, $1;
3376                 } elsif ($line =~ m/^author (.*) ([0-9]+) (.*)$/) {
3377                         $co{'author'} = to_utf8($1);
3378                         $co{'author_epoch'} = $2;
3379                         $co{'author_tz'} = $3;
3380                         if ($co{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3381                                 $co{'author_name'}  = $1;
3382                                 $co{'author_email'} = $2;
3383                         } else {
3384                                 $co{'author_name'} = $co{'author'};
3385                         }
3386                 } elsif ($line =~ m/^committer (.*) ([0-9]+) (.*)$/) {
3387                         $co{'committer'} = to_utf8($1);
3388                         $co{'committer_epoch'} = $2;
3389                         $co{'committer_tz'} = $3;
3390                         if ($co{'committer'} =~ m/^([^<]+) <([^>]*)>/) {
3391                                 $co{'committer_name'}  = $1;
3392                                 $co{'committer_email'} = $2;
3393                         } else {
3394                                 $co{'committer_name'} = $co{'committer'};
3395                         }
3396                 }
3397         }
3398         if (!defined $co{'tree'}) {
3399                 return;
3400         };
3401         $co{'parents'} = \@parents;
3402         $co{'parent'} = $parents[0];
3403
3404         foreach my $title (@commit_lines) {
3405                 $title =~ s/^    //;
3406                 if ($title ne "") {
3407                         $co{'title'} = chop_str($title, 80, 5);
3408                         # remove leading stuff of merges to make the interesting part visible
3409                         if (length($title) > 50) {
3410                                 $title =~ s/^Automatic //;
3411                                 $title =~ s/^merge (of|with) /Merge ... /i;
3412                                 if (length($title) > 50) {
3413                                         $title =~ s/(http|rsync):\/\///;
3414                                 }
3415                                 if (length($title) > 50) {
3416                                         $title =~ s/(master|www|rsync)\.//;
3417                                 }
3418                                 if (length($title) > 50) {
3419                                         $title =~ s/kernel.org:?//;
3420                                 }
3421                                 if (length($title) > 50) {
3422                                         $title =~ s/\/pub\/scm//;
3423                                 }
3424                         }
3425                         $co{'title_short'} = chop_str($title, 50, 5);
3426                         last;
3427                 }
3428         }
3429         if (! defined $co{'title'} || $co{'title'} eq "") {
3430                 $co{'title'} = $co{'title_short'} = '(no commit message)';
3431         }
3432         # remove added spaces
3433         foreach my $line (@commit_lines) {
3434                 $line =~ s/^    //;
3435         }
3436         $co{'comment'} = \@commit_lines;
3437
3438         my $age = time - $co{'committer_epoch'};
3439         $co{'age'} = $age;
3440         $co{'age_string'} = age_string($age);
3441         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($co{'committer_epoch'});
3442         if ($age > 60*60*24*7*2) {
3443                 $co{'age_string_date'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3444                 $co{'age_string_age'} = $co{'age_string'};
3445         } else {
3446                 $co{'age_string_date'} = $co{'age_string'};
3447                 $co{'age_string_age'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3448         }
3449         return %co;
3450 }
3451
3452 sub parse_commit {
3453         my ($commit_id) = @_;
3454         my %co;
3455
3456         local $/ = "\0";
3457
3458         open my $fd, "-|", git_cmd(), "rev-list",
3459                 "--parents",
3460                 "--header",
3461                 "--max-count=1",
3462                 $commit_id,
3463                 "--",
3464                 or die_error(500, "Open git-rev-list failed");
3465         %co = parse_commit_text(<$fd>, 1);
3466         close $fd;
3467
3468         return %co;
3469 }
3470
3471 sub parse_commits {
3472         my ($commit_id, $maxcount, $skip, $filename, @args) = @_;
3473         my @cos;
3474
3475         $maxcount ||= 1;
3476         $skip ||= 0;
3477
3478         local $/ = "\0";
3479
3480         open my $fd, "-|", git_cmd(), "rev-list",
3481                 "--header",
3482                 @args,
3483                 ("--max-count=" . $maxcount),
3484                 ("--skip=" . $skip),
3485                 @extra_options,
3486                 $commit_id,
3487                 "--",
3488                 ($filename ? ($filename) : ())
3489                 or die_error(500, "Open git-rev-list failed");
3490         while (my $line = <$fd>) {
3491                 my %co = parse_commit_text($line);
3492                 push @cos, \%co;
3493         }
3494         close $fd;
3495
3496         return wantarray ? @cos : \@cos;
3497 }
3498
3499 # parse line of git-diff-tree "raw" output
3500 sub parse_difftree_raw_line {
3501         my $line = shift;
3502         my %res;
3503
3504         # ':100644 100644 03b218260e99b78c6df0ed378e59ed9205ccc96d 3b93d5e7cc7f7dd4ebed13a5cc1a4ad976fc94d8 M   ls-files.c'
3505         # ':100644 100644 7f9281985086971d3877aca27704f2aaf9c448ce bc190ebc71bbd923f2b728e505408f5e54bd073a M   rev-tree.c'
3506         if ($line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)([0-9]{0,3})\t(.*)$/) {
3507                 $res{'from_mode'} = $1;
3508                 $res{'to_mode'} = $2;
3509                 $res{'from_id'} = $3;
3510                 $res{'to_id'} = $4;
3511                 $res{'status'} = $5;
3512                 $res{'similarity'} = $6;
3513                 if ($res{'status'} eq 'R' || $res{'status'} eq 'C') { # renamed or copied
3514                         ($res{'from_file'}, $res{'to_file'}) = map { unquote($_) } split("\t", $7);
3515                 } else {
3516                         $res{'from_file'} = $res{'to_file'} = $res{'file'} = unquote($7);
3517                 }
3518         }
3519         # '::100755 100755 100755 60e79ca1b01bc8b057abe17ddab484699a7f5fdb 94067cc5f73388f33722d52ae02f44692bc07490 94067cc5f73388f33722d52ae02f44692bc07490 MR git-gui/git-gui.sh'
3520         # combined diff (for merge commit)
3521         elsif ($line =~ s/^(::+)((?:[0-7]{6} )+)((?:[0-9a-fA-F]{40} )+)([a-zA-Z]+)\t(.*)$//) {
3522                 $res{'nparents'}  = length($1);
3523                 $res{'from_mode'} = [ split(' ', $2) ];
3524                 $res{'to_mode'} = pop @{$res{'from_mode'}};
3525                 $res{'from_id'} = [ split(' ', $3) ];
3526                 $res{'to_id'} = pop @{$res{'from_id'}};
3527                 $res{'status'} = [ split('', $4) ];
3528                 $res{'to_file'} = unquote($5);
3529         }
3530         # 'c512b523472485aef4fff9e57b229d9d243c967f'
3531         elsif ($line =~ m/^([0-9a-fA-F]{40})$/) {
3532                 $res{'commit'} = $1;
3533         }
3534
3535         return wantarray ? %res : \%res;
3536 }
3537
3538 # wrapper: return parsed line of git-diff-tree "raw" output
3539 # (the argument might be raw line, or parsed info)
3540 sub parsed_difftree_line {
3541         my $line_or_ref = shift;
3542
3543         if (ref($line_or_ref) eq "HASH") {
3544                 # pre-parsed (or generated by hand)
3545                 return $line_or_ref;
3546         } else {
3547                 return parse_difftree_raw_line($line_or_ref);
3548         }
3549 }
3550
3551 # parse line of git-ls-tree output
3552 sub parse_ls_tree_line {
3553         my $line = shift;
3554         my %opts = @_;
3555         my %res;
3556
3557         if ($opts{'-l'}) {
3558                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa   16717  panic.c'
3559                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40}) +(-|[0-9]+)\t(.+)$/s;
3560
3561                 $res{'mode'} = $1;
3562                 $res{'type'} = $2;
3563                 $res{'hash'} = $3;
3564                 $res{'size'} = $4;
3565                 if ($opts{'-z'}) {
3566                         $res{'name'} = $5;
3567                 } else {
3568                         $res{'name'} = unquote($5);
3569                 }
3570         } else {
3571                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
3572                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t(.+)$/s;
3573
3574                 $res{'mode'} = $1;
3575                 $res{'type'} = $2;
3576                 $res{'hash'} = $3;
3577                 if ($opts{'-z'}) {
3578                         $res{'name'} = $4;
3579                 } else {
3580                         $res{'name'} = unquote($4);
3581                 }
3582         }
3583
3584         return wantarray ? %res : \%res;
3585 }
3586
3587 # generates _two_ hashes, references to which are passed as 2 and 3 argument
3588 sub parse_from_to_diffinfo {
3589         my ($diffinfo, $from, $to, @parents) = @_;
3590
3591         if ($diffinfo->{'nparents'}) {
3592                 # combined diff
3593                 $from->{'file'} = [];
3594                 $from->{'href'} = [];
3595                 fill_from_file_info($diffinfo, @parents)
3596                         unless exists $diffinfo->{'from_file'};
3597                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
3598                         $from->{'file'}[$i] =
3599                                 defined $diffinfo->{'from_file'}[$i] ?
3600                                         $diffinfo->{'from_file'}[$i] :
3601                                         $diffinfo->{'to_file'};
3602                         if ($diffinfo->{'status'}[$i] ne "A") { # not new (added) file
3603                                 $from->{'href'}[$i] = href(action=>"blob",
3604                                                            hash_base=>$parents[$i],
3605                                                            hash=>$diffinfo->{'from_id'}[$i],
3606                                                            file_name=>$from->{'file'}[$i]);
3607                         } else {
3608                                 $from->{'href'}[$i] = undef;
3609                         }
3610                 }
3611         } else {
3612                 # ordinary (not combined) diff
3613                 $from->{'file'} = $diffinfo->{'from_file'};
3614                 if ($diffinfo->{'status'} ne "A") { # not new (added) file
3615                         $from->{'href'} = href(action=>"blob", hash_base=>$hash_parent,
3616                                                hash=>$diffinfo->{'from_id'},
3617                                                file_name=>$from->{'file'});
3618                 } else {
3619                         delete $from->{'href'};
3620                 }
3621         }
3622
3623         $to->{'file'} = $diffinfo->{'to_file'};
3624         if (!is_deleted($diffinfo)) { # file exists in result
3625                 $to->{'href'} = href(action=>"blob", hash_base=>$hash,
3626                                      hash=>$diffinfo->{'to_id'},
3627                                      file_name=>$to->{'file'});
3628         } else {
3629                 delete $to->{'href'};
3630         }
3631 }
3632
3633 ## ......................................................................
3634 ## parse to array of hashes functions
3635
3636 sub git_get_heads_list {
3637         my ($limit, @classes) = @_;
3638         @classes = ('heads') unless @classes;
3639         my @patterns = map { "refs/$_" } @classes;
3640         my @headslist;
3641
3642         open my $fd, '-|', git_cmd(), 'for-each-ref',
3643                 ($limit ? '--count='.($limit+1) : ()), '--sort=-committerdate',
3644                 '--format=%(objectname) %(refname) %(subject)%00%(committer)',
3645                 @patterns
3646                 or return;
3647         while (my $line = <$fd>) {
3648                 my %ref_item;
3649
3650                 chomp $line;
3651                 my ($refinfo, $committerinfo) = split(/\0/, $line);
3652                 my ($hash, $name, $title) = split(' ', $refinfo, 3);
3653                 my ($committer, $epoch, $tz) =
3654                         ($committerinfo =~ /^(.*) ([0-9]+) (.*)$/);
3655                 $ref_item{'fullname'}  = $name;
3656                 $name =~ s!^refs/(?:head|remote)s/!!;
3657
3658                 $ref_item{'name'}  = $name;
3659                 $ref_item{'id'}    = $hash;
3660                 $ref_item{'title'} = $title || '(no commit message)';
3661                 $ref_item{'epoch'} = $epoch;
3662                 if ($epoch) {
3663                         $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3664                 } else {
3665                         $ref_item{'age'} = "unknown";
3666                 }
3667
3668                 push @headslist, \%ref_item;
3669         }
3670         close $fd;
3671
3672         return wantarray ? @headslist : \@headslist;
3673 }
3674
3675 sub git_get_tags_list {
3676         my $limit = shift;
3677         my @tagslist;
3678
3679         open my $fd, '-|', git_cmd(), 'for-each-ref',
3680                 ($limit ? '--count='.($limit+1) : ()), '--sort=-creatordate',
3681                 '--format=%(objectname) %(objecttype) %(refname) '.
3682                 '%(*objectname) %(*objecttype) %(subject)%00%(creator)',
3683                 'refs/tags'
3684                 or return;
3685         while (my $line = <$fd>) {
3686                 my %ref_item;
3687
3688                 chomp $line;
3689                 my ($refinfo, $creatorinfo) = split(/\0/, $line);
3690                 my ($id, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
3691                 my ($creator, $epoch, $tz) =
3692                         ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
3693                 $ref_item{'fullname'} = $name;
3694                 $name =~ s!^refs/tags/!!;
3695
3696                 $ref_item{'type'} = $type;
3697                 $ref_item{'id'} = $id;
3698                 $ref_item{'name'} = $name;
3699                 if ($type eq "tag") {
3700                         $ref_item{'subject'} = $title;
3701                         $ref_item{'reftype'} = $reftype;
3702                         $ref_item{'refid'}   = $refid;
3703                 } else {
3704                         $ref_item{'reftype'} = $type;
3705                         $ref_item{'refid'}   = $id;
3706                 }
3707
3708                 if ($type eq "tag" || $type eq "commit") {
3709                         $ref_item{'epoch'} = $epoch;
3710                         if ($epoch) {
3711                                 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3712                         } else {
3713                                 $ref_item{'age'} = "unknown";
3714                         }
3715                 }
3716
3717                 push @tagslist, \%ref_item;
3718         }
3719         close $fd;
3720
3721         return wantarray ? @tagslist : \@tagslist;
3722 }
3723
3724 ## ----------------------------------------------------------------------
3725 ## filesystem-related functions
3726
3727 sub get_file_owner {
3728         my $path = shift;
3729
3730         my ($dev, $ino, $mode, $nlink, $st_uid, $st_gid, $rdev, $size) = stat($path);
3731         my ($name, $passwd, $uid, $gid, $quota, $comment, $gcos, $dir, $shell) = getpwuid($st_uid);
3732         if (!defined $gcos) {
3733                 return undef;
3734         }
3735         my $owner = $gcos;
3736         $owner =~ s/[,;].*$//;
3737         return to_utf8($owner);
3738 }
3739
3740 # assume that file exists
3741 sub insert_file {
3742         my $filename = shift;
3743
3744         open my $fd, '<', $filename;
3745         print map { to_utf8($_) } <$fd>;
3746         close $fd;
3747 }
3748
3749 ## ......................................................................
3750 ## mimetype related functions
3751
3752 sub mimetype_guess_file {
3753         my $filename = shift;
3754         my $mimemap = shift;
3755         -r $mimemap or return undef;
3756
3757         my %mimemap;
3758         open(my $mh, '<', $mimemap) or return undef;
3759         while (<$mh>) {
3760                 next if m/^#/; # skip comments
3761                 my ($mimetype, @exts) = split(/\s+/);
3762                 foreach my $ext (@exts) {
3763                         $mimemap{$ext} = $mimetype;
3764                 }
3765         }
3766         close($mh);
3767
3768         $filename =~ /\.([^.]*)$/;
3769         return $mimemap{$1};
3770 }
3771
3772 sub mimetype_guess {
3773         my $filename = shift;
3774         my $mime;
3775         $filename =~ /\./ or return undef;
3776
3777         if ($mimetypes_file) {
3778                 my $file = $mimetypes_file;
3779                 if ($file !~ m!^/!) { # if it is relative path
3780                         # it is relative to project
3781                         $file = "$projectroot/$project/$file";
3782                 }
3783                 $mime = mimetype_guess_file($filename, $file);
3784         }
3785         $mime ||= mimetype_guess_file($filename, '/etc/mime.types');
3786         return $mime;
3787 }
3788
3789 sub blob_mimetype {
3790         my $fd = shift;
3791         my $filename = shift;
3792
3793         if ($filename) {
3794                 my $mime = mimetype_guess($filename);
3795                 $mime and return $mime;
3796         }
3797
3798         # just in case
3799         return $default_blob_plain_mimetype unless $fd;
3800
3801         if (-T $fd) {
3802                 return 'text/plain';
3803         } elsif (! $filename) {
3804                 return 'application/octet-stream';
3805         } elsif ($filename =~ m/\.png$/i) {
3806                 return 'image/png';
3807         } elsif ($filename =~ m/\.gif$/i) {
3808                 return 'image/gif';
3809         } elsif ($filename =~ m/\.jpe?g$/i) {
3810                 return 'image/jpeg';
3811         } else {
3812                 return 'application/octet-stream';
3813         }
3814 }
3815
3816 sub blob_contenttype {
3817         my ($fd, $file_name, $type) = @_;
3818
3819         $type ||= blob_mimetype($fd, $file_name);
3820         if ($type eq 'text/plain' && defined $default_text_plain_charset) {
3821                 $type .= "; charset=$default_text_plain_charset";
3822         }
3823
3824         return $type;
3825 }
3826
3827 # guess file syntax for syntax highlighting; return undef if no highlighting
3828 # the name of syntax can (in the future) depend on syntax highlighter used
3829 sub guess_file_syntax {
3830         my ($highlight, $mimetype, $file_name) = @_;
3831         return undef unless ($highlight && defined $file_name);
3832         my $basename = basename($file_name, '.in');
3833         return $highlight_basename{$basename}
3834                 if exists $highlight_basename{$basename};
3835
3836         $basename =~ /\.([^.]*)$/;
3837         my $ext = $1 or return undef;
3838         return $highlight_ext{$ext}
3839                 if exists $highlight_ext{$ext};
3840
3841         return undef;
3842 }
3843
3844 # run highlighter and return FD of its output,
3845 # or return original FD if no highlighting
3846 sub run_highlighter {
3847         my ($fd, $highlight, $syntax) = @_;
3848         return $fd unless ($highlight && defined $syntax);
3849
3850         close $fd;
3851         open $fd, quote_command(git_cmd(), "cat-file", "blob", $hash)." | ".
3852                   quote_command($highlight_bin).
3853                   " --replace-tabs=8 --fragment --syntax $syntax |"
3854                 or die_error(500, "Couldn't open file or run syntax highlighter");
3855         return $fd;
3856 }
3857
3858 ## ======================================================================
3859 ## functions printing HTML: header, footer, error page
3860
3861 sub get_page_title {
3862         my $title = to_utf8($site_name);
3863
3864         unless (defined $project) {
3865                 if (defined $project_filter) {
3866                         $title .= " - projects in '" . esc_path($project_filter) . "'";
3867                 }
3868                 return $title;
3869         }
3870         $title .= " - " . to_utf8($project);
3871
3872         return $title unless (defined $action);
3873         $title .= "/$action"; # $action is US-ASCII (7bit ASCII)
3874
3875         return $title unless (defined $file_name);
3876         $title .= " - " . esc_path($file_name);
3877         if ($action eq "tree" && $file_name !~ m|/$|) {
3878                 $title .= "/";
3879         }
3880
3881         return $title;
3882 }
3883
3884 sub get_content_type_html {
3885         # require explicit support from the UA if we are to send the page as
3886         # 'application/xhtml+xml', otherwise send it as plain old 'text/html'.
3887         # we have to do this because MSIE sometimes globs '*/*', pretending to
3888         # support xhtml+xml but choking when it gets what it asked for.
3889         if (defined $cgi->http('HTTP_ACCEPT') &&
3890             $cgi->http('HTTP_ACCEPT') =~ m/(,|;|\s|^)application\/xhtml\+xml(,|;|\s|$)/ &&
3891             $cgi->Accept('application/xhtml+xml') != 0) {
3892                 return 'application/xhtml+xml';
3893         } else {
3894                 return 'text/html';
3895         }
3896 }
3897
3898 sub print_feed_meta {
3899         if (defined $project) {
3900                 my %href_params = get_feed_info();
3901                 if (!exists $href_params{'-title'}) {
3902                         $href_params{'-title'} = 'log';
3903                 }
3904
3905                 foreach my $format (qw(RSS Atom)) {
3906                         my $type = lc($format);
3907                         my %link_attr = (
3908                                 '-rel' => 'alternate',
3909                                 '-title' => esc_attr("$project - $href_params{'-title'} - $format feed"),
3910                                 '-type' => "application/$type+xml"
3911                         );
3912
3913                         $href_params{'extra_options'} = undef;
3914                         $href_params{'action'} = $type;
3915                         $link_attr{'-href'} = href(%href_params);
3916                         print "<link ".
3917                               "rel=\"$link_attr{'-rel'}\" ".
3918                               "title=\"$link_attr{'-title'}\" ".
3919                               "href=\"$link_attr{'-href'}\" ".
3920                               "type=\"$link_attr{'-type'}\" ".
3921                               "/>\n";
3922
3923                         $href_params{'extra_options'} = '--no-merges';
3924                         $link_attr{'-href'} = href(%href_params);
3925                         $link_attr{'-title'} .= ' (no merges)';
3926                         print "<link ".
3927                               "rel=\"$link_attr{'-rel'}\" ".
3928                               "title=\"$link_attr{'-title'}\" ".
3929                               "href=\"$link_attr{'-href'}\" ".
3930                               "type=\"$link_attr{'-type'}\" ".
3931                               "/>\n";
3932                 }
3933
3934         } else {
3935                 printf('<link rel="alternate" title="%s projects list" '.
3936                        'href="%s" type="text/plain; charset=utf-8" />'."\n",
3937                        esc_attr($site_name), href(project=>undef, action=>"project_index"));
3938                 printf('<link rel="alternate" title="%s projects feeds" '.
3939                        'href="%s" type="text/x-opml" />'."\n",
3940                        esc_attr($site_name), href(project=>undef, action=>"opml"));
3941         }
3942 }
3943
3944 sub print_header_links {
3945         my $status = shift;
3946
3947         # print out each stylesheet that exist, providing backwards capability
3948         # for those people who defined $stylesheet in a config file
3949         if (defined $stylesheet) {
3950                 print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
3951         } else {
3952                 foreach my $stylesheet (@stylesheets) {
3953                         next unless $stylesheet;
3954                         print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
3955                 }
3956         }
3957         print_feed_meta()
3958                 if ($status eq '200 OK');
3959         if (defined $favicon) {
3960                 print qq(<link rel="shortcut icon" href=").esc_url($favicon).qq(" type="image/png" />\n);
3961         }
3962 }
3963
3964 sub print_nav_breadcrumbs_path {
3965         my $dirprefix = undef;
3966         while (my $part = shift) {
3967                 $dirprefix .= "/" if defined $dirprefix;
3968                 $dirprefix .= $part;
3969                 print $cgi->a({-href => href(project => undef,
3970                                              project_filter => $dirprefix,
3971                                              action => "project_list")},
3972                               esc_html($part)) . " / ";
3973         }
3974 }
3975
3976 sub print_nav_breadcrumbs {
3977         my %opts = @_;
3978
3979         print $cgi->a({-href => esc_url($home_link)}, $home_link_str) . " / ";
3980         if (defined $project) {
3981                 my @dirname = split '/', $project;
3982                 my $projectbasename = pop @dirname;
3983                 print_nav_breadcrumbs_path(@dirname);
3984                 print $cgi->a({-href => href(action=>"summary")}, esc_html($projectbasename));
3985                 if (defined $action) {
3986                         my $action_print = $action ;
3987                         if (defined $opts{-action_extra}) {
3988                                 $action_print = $cgi->a({-href => href(action=>$action)},
3989                                         $action);
3990                         }
3991                         print " / $action_print";
3992                 }
3993                 if (defined $opts{-action_extra}) {
3994                         print " / $opts{-action_extra}";
3995                 }
3996                 print "\n";
3997         } elsif (defined $project_filter) {
3998                 print_nav_breadcrumbs_path(split '/', $project_filter);
3999         }
4000 }
4001
4002 sub print_search_form {
4003         if (!defined $searchtext) {
4004                 $searchtext = "";
4005         }
4006         my $search_hash;
4007         if (defined $hash_base) {
4008                 $search_hash = $hash_base;
4009         } elsif (defined $hash) {
4010                 $search_hash = $hash;
4011         } else {
4012                 $search_hash = "HEAD";
4013         }
4014         my $action = $my_uri;
4015         my $use_pathinfo = gitweb_check_feature('pathinfo');
4016         if ($use_pathinfo) {
4017                 $action .= "/".esc_url($project);
4018         }
4019         print $cgi->startform(-method => "get", -action => $action) .
4020               "<div class=\"search\">\n" .
4021               (!$use_pathinfo &&
4022               $cgi->input({-name=>"p", -value=>$project, -type=>"hidden"}) . "\n") .
4023               $cgi->input({-name=>"a", -value=>"search", -type=>"hidden"}) . "\n" .
4024               $cgi->input({-name=>"h", -value=>$search_hash, -type=>"hidden"}) . "\n" .
4025               $cgi->popup_menu(-name => 'st', -default => 'commit',
4026                                -values => ['commit', 'grep', 'author', 'committer', 'pickaxe']) .
4027               $cgi->sup($cgi->a({-href => href(action=>"search_help")}, "?")) .
4028               " search:\n",
4029               $cgi->textfield(-name => "s", -value => $searchtext, -override => 1) . "\n" .
4030               "<span title=\"Extended regular expression\">" .
4031               $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
4032                              -checked => $search_use_regexp) .
4033               "</span>" .
4034               "</div>" .
4035               $cgi->end_form() . "\n";
4036 }
4037
4038 sub git_header_html {
4039         my $status = shift || "200 OK";
4040         my $expires = shift;
4041         my %opts = @_;
4042
4043         my $title = get_page_title();
4044         my $content_type = get_content_type_html();
4045         print $cgi->header(-type=>$content_type, -charset => 'utf-8',
4046                            -status=> $status, -expires => $expires)
4047                 unless ($opts{'-no_http_header'});
4048         my $mod_perl_version = $ENV{'MOD_PERL'} ? " $ENV{'MOD_PERL'}" : '';
4049         print <<EOF;
4050 <?xml version="1.0" encoding="utf-8"?>
4051 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
4052 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en-US" lang="en-US">
4053 <!-- git web interface version $version, (C) 2005-2006, Kay Sievers <kay.sievers\@vrfy.org>, Christian Gierke -->
4054 <!-- git core binaries version $git_version -->
4055 <head>
4056 <meta http-equiv="content-type" content="$content_type; charset=utf-8"/>
4057 <meta name="generator" content="gitweb/$version git/$git_version$mod_perl_version"/>
4058 <meta name="robots" content="index, nofollow"/>
4059 <title>$title</title>
4060 EOF
4061         # the stylesheet, favicon etc urls won't work correctly with path_info
4062         # unless we set the appropriate base URL
4063         if ($ENV{'PATH_INFO'}) {
4064                 print "<base href=\"".esc_url($base_url)."\" />\n";
4065         }
4066         print_header_links($status);
4067
4068         if (defined $site_html_head_string) {
4069                 print to_utf8($site_html_head_string);
4070         }
4071
4072         print "</head>\n" .
4073               "<body>\n";
4074
4075         if (defined $site_header && -f $site_header) {
4076                 insert_file($site_header);
4077         }
4078
4079         print "<div class=\"page_header\">\n";
4080         if (defined $logo) {
4081                 print $cgi->a({-href => esc_url($logo_url),
4082                                -title => $logo_label},
4083                               $cgi->img({-src => esc_url($logo),
4084                                          -width => 72, -height => 27,
4085                                          -alt => "git",
4086                                          -class => "logo"}));
4087         }
4088         print_nav_breadcrumbs(%opts);
4089         print "</div>\n";
4090
4091         my $have_search = gitweb_check_feature('search');
4092         if (defined $project && $have_search) {
4093                 print_search_form();
4094         }
4095 }
4096
4097 sub git_footer_html {
4098         my $feed_class = 'rss_logo';
4099
4100         print "<div class=\"page_footer\">\n";
4101         if (defined $project) {
4102                 my $descr = git_get_project_description($project);
4103                 if (defined $descr) {
4104                         print "<div class=\"page_footer_text\">" . esc_html($descr) . "</div>\n";
4105                 }
4106
4107                 my %href_params = get_feed_info();
4108                 if (!%href_params) {
4109                         $feed_class .= ' generic';
4110                 }
4111                 $href_params{'-title'} ||= 'log';
4112
4113                 foreach my $format (qw(RSS Atom)) {
4114                         $href_params{'action'} = lc($format);
4115                         print $cgi->a({-href => href(%href_params),
4116                                       -title => "$href_params{'-title'} $format feed",
4117                                       -class => $feed_class}, $format)."\n";
4118                 }
4119
4120         } else {
4121                 print $cgi->a({-href => href(project=>undef, action=>"opml",
4122                                              project_filter => $project_filter),
4123                               -class => $feed_class}, "OPML") . " ";
4124                 print $cgi->a({-href => href(project=>undef, action=>"project_index",
4125                                              project_filter => $project_filter),
4126                               -class => $feed_class}, "TXT") . "\n";
4127         }
4128         print "</div>\n"; # class="page_footer"
4129
4130         if (defined $t0 && gitweb_check_feature('timed')) {
4131                 print "<div id=\"generating_info\">\n";
4132                 print 'This page took '.
4133                       '<span id="generating_time" class="time_span">'.
4134                       tv_interval($t0, [ gettimeofday() ]).
4135                       ' seconds </span>'.
4136                       ' and '.
4137                       '<span id="generating_cmd">'.
4138                       $number_of_git_cmds.
4139                       '</span> git commands '.
4140                       " to generate.\n";
4141                 print "</div>\n"; # class="page_footer"
4142         }
4143
4144         if (defined $site_footer && -f $site_footer) {
4145                 insert_file($site_footer);
4146         }
4147
4148         print qq!<script type="text/javascript" src="!.esc_url($javascript).qq!"></script>\n!;
4149         if (defined $action &&
4150             $action eq 'blame_incremental') {
4151                 print qq!<script type="text/javascript">\n!.
4152                       qq!startBlame("!. href(action=>"blame_data", -replay=>1) .qq!",\n!.
4153                       qq!           "!. href() .qq!");\n!.
4154                       qq!</script>\n!;
4155         } else {
4156                 my ($jstimezone, $tz_cookie, $datetime_class) =
4157                         gitweb_get_feature('javascript-timezone');
4158
4159                 print qq!<script type="text/javascript">\n!.
4160                       qq!window.onload = function () {\n!;
4161                 if (gitweb_check_feature('javascript-actions')) {
4162                         print qq!       fixLinks();\n!;
4163                 }
4164                 if ($jstimezone && $tz_cookie && $datetime_class) {
4165                         print qq!       var tz_cookie = { name: '$tz_cookie', expires: 14, path: '/' };\n!. # in days
4166                               qq!       onloadTZSetup('$jstimezone', tz_cookie, '$datetime_class');\n!;
4167                 }
4168                 print qq!};\n!.
4169                       qq!</script>\n!;
4170         }
4171
4172         print "</body>\n" .
4173               "</html>";
4174 }
4175
4176 # die_error(<http_status_code>, <error_message>[, <detailed_html_description>])
4177 # Example: die_error(404, 'Hash not found')
4178 # By convention, use the following status codes (as defined in RFC 2616):
4179 # 400: Invalid or missing CGI parameters, or
4180 #      requested object exists but has wrong type.
4181 # 403: Requested feature (like "pickaxe" or "snapshot") not enabled on
4182 #      this server or project.
4183 # 404: Requested object/revision/project doesn't exist.
4184 # 500: The server isn't configured properly, or
4185 #      an internal error occurred (e.g. failed assertions caused by bugs), or
4186 #      an unknown error occurred (e.g. the git binary died unexpectedly).
4187 # 503: The server is currently unavailable (because it is overloaded,
4188 #      or down for maintenance).  Generally, this is a temporary state.
4189 sub die_error {
4190         my $status = shift || 500;
4191         my $error = esc_html(shift) || "Internal Server Error";
4192         my $extra = shift;
4193         my %opts = @_;
4194
4195         my %http_responses = (
4196                 400 => '400 Bad Request',
4197                 403 => '403 Forbidden',
4198                 404 => '404 Not Found',
4199                 500 => '500 Internal Server Error',
4200                 503 => '503 Service Unavailable',
4201         );
4202         git_header_html($http_responses{$status}, undef, %opts);
4203         print <<EOF;
4204 <div class="page_body">
4205 <br /><br />
4206 $status - $error
4207 <br />
4208 EOF
4209         if (defined $extra) {
4210                 print "<hr />\n" .
4211                       "$extra\n";
4212         }
4213         print "</div>\n";
4214
4215         git_footer_html();
4216         goto DONE_GITWEB
4217                 unless ($opts{'-error_handler'});
4218 }
4219
4220 ## ----------------------------------------------------------------------
4221 ## functions printing or outputting HTML: navigation
4222
4223 sub git_print_page_nav {
4224         my ($current, $suppress, $head, $treehead, $treebase, $extra) = @_;
4225         $extra = '' if !defined $extra; # pager or formats
4226
4227         my @navs = qw(summary shortlog log commit commitdiff tree);
4228         if ($suppress) {
4229                 @navs = grep { $_ ne $suppress } @navs;
4230         }
4231
4232         my %arg = map { $_ => {action=>$_} } @navs;
4233         if (defined $head) {
4234                 for (qw(commit commitdiff)) {
4235                         $arg{$_}{'hash'} = $head;
4236                 }
4237                 if ($current =~ m/^(tree | log | shortlog | commit | commitdiff | search)$/x) {
4238                         for (qw(shortlog log)) {
4239                                 $arg{$_}{'hash'} = $head;
4240                         }
4241                 }
4242         }
4243
4244         $arg{'tree'}{'hash'} = $treehead if defined $treehead;
4245         $arg{'tree'}{'hash_base'} = $treebase if defined $treebase;
4246
4247         my @actions = gitweb_get_feature('actions');
4248         my %repl = (
4249                 '%' => '%',
4250                 'n' => $project,         # project name
4251                 'f' => $git_dir,         # project path within filesystem
4252                 'h' => $treehead || '',  # current hash ('h' parameter)
4253                 'b' => $treebase || '',  # hash base ('hb' parameter)
4254         );
4255         while (@actions) {
4256                 my ($label, $link, $pos) = splice(@actions,0,3);
4257                 # insert
4258                 @navs = map { $_ eq $pos ? ($_, $label) : $_ } @navs;
4259                 # munch munch
4260                 $link =~ s/%([%nfhb])/$repl{$1}/g;
4261                 $arg{$label}{'_href'} = $link;
4262         }
4263
4264         print "<div class=\"page_nav\">\n" .
4265                 (join " | ",
4266                  map { $_ eq $current ?
4267                        $_ : $cgi->a({-href => ($arg{$_}{_href} ? $arg{$_}{_href} : href(%{$arg{$_}}))}, "$_")
4268                  } @navs);
4269         print "<br/>\n$extra<br/>\n" .
4270               "</div>\n";
4271 }
4272
4273 # returns a submenu for the nagivation of the refs views (tags, heads,
4274 # remotes) with the current view disabled and the remotes view only
4275 # available if the feature is enabled
4276 sub format_ref_views {
4277         my ($current) = @_;
4278         my @ref_views = qw{tags heads};
4279         push @ref_views, 'remotes' if gitweb_check_feature('remote_heads');
4280         return join " | ", map {
4281                 $_ eq $current ? $_ :
4282                 $cgi->a({-href => href(action=>$_)}, $_)
4283         } @ref_views
4284 }
4285
4286 sub format_paging_nav {
4287         my ($action, $page, $has_next_link) = @_;
4288         my $paging_nav;
4289
4290
4291         if ($page > 0) {
4292                 $paging_nav .=
4293                         $cgi->a({-href => href(-replay=>1, page=>undef)}, "first") .
4294                         " &sdot; " .
4295                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
4296                                  -accesskey => "p", -title => "Alt-p"}, "prev");
4297         } else {
4298                 $paging_nav .= "first &sdot; prev";
4299         }
4300
4301         if ($has_next_link) {
4302                 $paging_nav .= " &sdot; " .
4303                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
4304                                  -accesskey => "n", -title => "Alt-n"}, "next");
4305         } else {
4306                 $paging_nav .= " &sdot; next";
4307         }
4308
4309         return $paging_nav;
4310 }
4311
4312 ## ......................................................................
4313 ## functions printing or outputting HTML: div
4314
4315 sub git_print_header_div {
4316         my ($action, $title, $hash, $hash_base) = @_;
4317         my %args = ();
4318
4319         $args{'action'} = $action;
4320         $args{'hash'} = $hash if $hash;
4321         $args{'hash_base'} = $hash_base if $hash_base;
4322
4323         print "<div class=\"header\">\n" .
4324               $cgi->a({-href => href(%args), -class => "title"},
4325               $title ? $title : $action) .
4326               "\n</div>\n";
4327 }
4328
4329 sub format_repo_url {
4330         my ($name, $url) = @_;
4331         return "<tr class=\"metadata_url\"><td>$name</td><td>$url</td></tr>\n";
4332 }
4333
4334 # Group output by placing it in a DIV element and adding a header.
4335 # Options for start_div() can be provided by passing a hash reference as the
4336 # first parameter to the function.
4337 # Options to git_print_header_div() can be provided by passing an array
4338 # reference. This must follow the options to start_div if they are present.
4339 # The content can be a scalar, which is output as-is, a scalar reference, which
4340 # is output after html escaping, an IO handle passed either as *handle or
4341 # *handle{IO}, or a function reference. In the latter case all following
4342 # parameters will be taken as argument to the content function call.
4343 sub git_print_section {
4344         my ($div_args, $header_args, $content);
4345         my $arg = shift;
4346         if (ref($arg) eq 'HASH') {
4347                 $div_args = $arg;
4348                 $arg = shift;
4349         }
4350         if (ref($arg) eq 'ARRAY') {
4351                 $header_args = $arg;
4352                 $arg = shift;
4353         }
4354         $content = $arg;
4355
4356         print $cgi->start_div($div_args);
4357         git_print_header_div(@$header_args);
4358
4359         if (ref($content) eq 'CODE') {
4360                 $content->(@_);
4361         } elsif (ref($content) eq 'SCALAR') {
4362                 print esc_html($$content);
4363         } elsif (ref($content) eq 'GLOB' or ref($content) eq 'IO::Handle') {
4364                 print <$content>;
4365         } elsif (!ref($content) && defined($content)) {
4366                 print $content;
4367         }
4368
4369         print $cgi->end_div;
4370 }
4371
4372 sub format_timestamp_html {
4373         my $date = shift;
4374         my $strtime = $date->{'rfc2822'};
4375
4376         my (undef, undef, $datetime_class) =
4377                 gitweb_get_feature('javascript-timezone');
4378         if ($datetime_class) {
4379                 $strtime = qq!<span class="$datetime_class">$strtime</span>!;
4380         }
4381
4382         my $localtime_format = '(%02d:%02d %s)';
4383         if ($date->{'hour_local'} < 6) {
4384                 $localtime_format = '(<span class="atnight">%02d:%02d</span> %s)';
4385         }
4386         $strtime .= ' ' .
4387                     sprintf($localtime_format,
4388                             $date->{'hour_local'}, $date->{'minute_local'}, $date->{'tz_local'});
4389
4390         return $strtime;
4391 }
4392
4393 # Outputs the author name and date in long form
4394 sub git_print_authorship {
4395         my $co = shift;
4396         my %opts = @_;
4397         my $tag = $opts{-tag} || 'div';
4398         my $author = $co->{'author_name'};
4399
4400         my %ad = parse_date($co->{'author_epoch'}, $co->{'author_tz'});
4401         print "<$tag class=\"author_date\">" .
4402               format_search_author($author, "author", esc_html($author)) .
4403               " [".format_timestamp_html(\%ad)."]".
4404               git_get_avatar($co->{'author_email'}, -pad_before => 1) .
4405               "</$tag>\n";
4406 }
4407
4408 # Outputs table rows containing the full author or committer information,
4409 # in the format expected for 'commit' view (& similar).
4410 # Parameters are a commit hash reference, followed by the list of people
4411 # to output information for. If the list is empty it defaults to both
4412 # author and committer.
4413 sub git_print_authorship_rows {
4414         my $co = shift;
4415         # too bad we can't use @people = @_ || ('author', 'committer')
4416         my @people = @_;
4417         @people = ('author', 'committer') unless @people;
4418         foreach my $who (@people) {
4419                 my %wd = parse_date($co->{"${who}_epoch"}, $co->{"${who}_tz"});
4420                 print "<tr><td>$who</td><td>" .
4421                       format_search_author($co->{"${who}_name"}, $who,
4422                                            esc_html($co->{"${who}_name"})) . " " .
4423                       format_search_author($co->{"${who}_email"}, $who,
4424                                            esc_html("<" . $co->{"${who}_email"} . ">")) .
4425                       "</td><td rowspan=\"2\">" .
4426                       git_get_avatar($co->{"${who}_email"}, -size => 'double') .
4427                       "</td></tr>\n" .
4428                       "<tr>" .
4429                       "<td></td><td>" .
4430                       format_timestamp_html(\%wd) .
4431                       "</td>" .
4432                       "</tr>\n";
4433         }
4434 }
4435
4436 sub git_print_page_path {
4437         my $name = shift;
4438         my $type = shift;
4439         my $hb = shift;
4440
4441
4442         print "<div class=\"page_path\">";
4443         print $cgi->a({-href => href(action=>"tree", hash_base=>$hb),
4444                       -title => 'tree root'}, to_utf8("[$project]"));
4445         print " / ";
4446         if (defined $name) {
4447                 my @dirname = split '/', $name;
4448                 my $basename = pop @dirname;
4449                 my $fullname = '';
4450
4451                 foreach my $dir (@dirname) {
4452                         $fullname .= ($fullname ? '/' : '') . $dir;
4453                         print $cgi->a({-href => href(action=>"tree", file_name=>$fullname,
4454                                                      hash_base=>$hb),
4455                                       -title => $fullname}, esc_path($dir));
4456                         print " / ";
4457                 }
4458                 if (defined $type && $type eq 'blob') {
4459                         print $cgi->a({-href => href(action=>"blob_plain", file_name=>$file_name,
4460                                                      hash_base=>$hb),
4461                                       -title => $name}, esc_path($basename));
4462                 } elsif (defined $type && $type eq 'tree') {
4463                         print $cgi->a({-href => href(action=>"tree", file_name=>$file_name,
4464                                                      hash_base=>$hb),
4465                                       -title => $name}, esc_path($basename));
4466                         print " / ";
4467                 } else {
4468                         print esc_path($basename);
4469                 }
4470         }
4471         print "<br/></div>\n";
4472 }
4473
4474 sub git_print_log {
4475         my $log = shift;
4476         my %opts = @_;
4477
4478         if ($opts{'-remove_title'}) {
4479                 # remove title, i.e. first line of log
4480                 shift @$log;
4481         }
4482         # remove leading empty lines
4483         while (defined $log->[0] && $log->[0] eq "") {
4484                 shift @$log;
4485         }
4486
4487         # print log
4488         my $signoff = 0;
4489         my $empty = 0;
4490         foreach my $line (@$log) {
4491                 if ($line =~ m/^ *(signed[ \-]off[ \-]by[ :]|acked[ \-]by[ :]|cc[ :])/i) {
4492                         $signoff = 1;
4493                         $empty = 0;
4494                         if (! $opts{'-remove_signoff'}) {
4495                                 print "<span class=\"signoff\">" . esc_html($line) . "</span><br/>\n";
4496                                 next;
4497                         } else {
4498                                 # remove signoff lines
4499                                 next;
4500                         }
4501                 } else {
4502                         $signoff = 0;
4503                 }
4504
4505                 # print only one empty line
4506                 # do not print empty line after signoff
4507                 if ($line eq "") {
4508                         next if ($empty || $signoff);
4509                         $empty = 1;
4510                 } else {
4511                         $empty = 0;
4512                 }
4513
4514                 print format_log_line_html($line) . "<br/>\n";
4515         }
4516
4517         if ($opts{'-final_empty_line'}) {
4518                 # end with single empty line
4519                 print "<br/>\n" unless $empty;
4520         }
4521 }
4522
4523 # return link target (what link points to)
4524 sub git_get_link_target {
4525         my $hash = shift;
4526         my $link_target;
4527
4528         # read link
4529         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
4530                 or return;
4531         {
4532                 local $/ = undef;
4533                 $link_target = <$fd>;
4534         }
4535         close $fd
4536                 or return;
4537
4538         return $link_target;
4539 }
4540
4541 # given link target, and the directory (basedir) the link is in,
4542 # return target of link relative to top directory (top tree);
4543 # return undef if it is not possible (including absolute links).
4544 sub normalize_link_target {
4545         my ($link_target, $basedir) = @_;
4546
4547         # absolute symlinks (beginning with '/') cannot be normalized
4548         return if (substr($link_target, 0, 1) eq '/');
4549
4550         # normalize link target to path from top (root) tree (dir)
4551         my $path;
4552         if ($basedir) {
4553                 $path = $basedir . '/' . $link_target;
4554         } else {
4555                 # we are in top (root) tree (dir)
4556                 $path = $link_target;
4557         }
4558
4559         # remove //, /./, and /../
4560         my @path_parts;
4561         foreach my $part (split('/', $path)) {
4562                 # discard '.' and ''
4563                 next if (!$part || $part eq '.');
4564                 # handle '..'
4565                 if ($part eq '..') {
4566                         if (@path_parts) {
4567                                 pop @path_parts;
4568                         } else {
4569                                 # link leads outside repository (outside top dir)
4570                                 return;
4571                         }
4572                 } else {
4573                         push @path_parts, $part;
4574                 }
4575         }
4576         $path = join('/', @path_parts);
4577
4578         return $path;
4579 }
4580
4581 # print tree entry (row of git_tree), but without encompassing <tr> element
4582 sub git_print_tree_entry {
4583         my ($t, $basedir, $hash_base, $have_blame) = @_;
4584
4585         my %base_key = ();
4586         $base_key{'hash_base'} = $hash_base if defined $hash_base;
4587
4588         # The format of a table row is: mode list link.  Where mode is
4589         # the mode of the entry, list is the name of the entry, an href,
4590         # and link is the action links of the entry.
4591
4592         print "<td class=\"mode\">" . mode_str($t->{'mode'}) . "</td>\n";
4593         if (exists $t->{'size'}) {
4594                 print "<td class=\"size\">$t->{'size'}</td>\n";
4595         }
4596         if ($t->{'type'} eq "blob") {
4597                 print "<td class=\"list\">" .
4598                         $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4599                                                file_name=>"$basedir$t->{'name'}", %base_key),
4600                                 -class => "list"}, esc_path($t->{'name'}));
4601                 if (S_ISLNK(oct $t->{'mode'})) {
4602                         my $link_target = git_get_link_target($t->{'hash'});
4603                         if ($link_target) {
4604                                 my $norm_target = normalize_link_target($link_target, $basedir);
4605                                 if (defined $norm_target) {
4606                                         print " -> " .
4607                                               $cgi->a({-href => href(action=>"object", hash_base=>$hash_base,
4608                                                                      file_name=>$norm_target),
4609                                                        -title => $norm_target}, esc_path($link_target));
4610                                 } else {
4611                                         print " -> " . esc_path($link_target);
4612                                 }
4613                         }
4614                 }
4615                 print "</td>\n";
4616                 print "<td class=\"link\">";
4617                 print $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4618                                              file_name=>"$basedir$t->{'name'}", %base_key)},
4619                               "blob");
4620                 if ($have_blame) {
4621                         print " | " .
4622                               $cgi->a({-href => href(action=>"blame", hash=>$t->{'hash'},
4623                                                      file_name=>"$basedir$t->{'name'}", %base_key)},
4624                                       "blame");
4625                 }
4626                 if (defined $hash_base) {
4627                         print " | " .
4628                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4629                                                      hash=>$t->{'hash'}, file_name=>"$basedir$t->{'name'}")},
4630                                       "history");
4631                 }
4632                 print " | " .
4633                         $cgi->a({-href => href(action=>"blob_plain", hash_base=>$hash_base,
4634                                                file_name=>"$basedir$t->{'name'}")},
4635                                 "raw");
4636                 print "</td>\n";
4637
4638         } elsif ($t->{'type'} eq "tree") {
4639                 print "<td class=\"list\">";
4640                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4641                                              file_name=>"$basedir$t->{'name'}",
4642                                              %base_key)},
4643                               esc_path($t->{'name'}));
4644                 print "</td>\n";
4645                 print "<td class=\"link\">";
4646                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4647                                              file_name=>"$basedir$t->{'name'}",
4648                                              %base_key)},
4649                               "tree");
4650                 if (defined $hash_base) {
4651                         print " | " .
4652                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4653                                                      file_name=>"$basedir$t->{'name'}")},
4654                                       "history");
4655                 }
4656                 print "</td>\n";
4657         } else {
4658                 # unknown object: we can only present history for it
4659                 # (this includes 'commit' object, i.e. submodule support)
4660                 print "<td class=\"list\">" .
4661                       esc_path($t->{'name'}) .
4662                       "</td>\n";
4663                 print "<td class=\"link\">";
4664                 if (defined $hash_base) {
4665                         print $cgi->a({-href => href(action=>"history",
4666                                                      hash_base=>$hash_base,
4667                                                      file_name=>"$basedir$t->{'name'}")},
4668                                       "history");
4669                 }
4670                 print "</td>\n";
4671         }
4672 }
4673
4674 ## ......................................................................
4675 ## functions printing large fragments of HTML
4676
4677 # get pre-image filenames for merge (combined) diff
4678 sub fill_from_file_info {
4679         my ($diff, @parents) = @_;
4680
4681         $diff->{'from_file'} = [ ];
4682         $diff->{'from_file'}[$diff->{'nparents'} - 1] = undef;
4683         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4684                 if ($diff->{'status'}[$i] eq 'R' ||
4685                     $diff->{'status'}[$i] eq 'C') {
4686                         $diff->{'from_file'}[$i] =
4687                                 git_get_path_by_hash($parents[$i], $diff->{'from_id'}[$i]);
4688                 }
4689         }
4690
4691         return $diff;
4692 }
4693
4694 # is current raw difftree line of file deletion
4695 sub is_deleted {
4696         my $diffinfo = shift;
4697
4698         return $diffinfo->{'to_id'} eq ('0' x 40);
4699 }
4700
4701 # does patch correspond to [previous] difftree raw line
4702 # $diffinfo  - hashref of parsed raw diff format
4703 # $patchinfo - hashref of parsed patch diff format
4704 #              (the same keys as in $diffinfo)
4705 sub is_patch_split {
4706         my ($diffinfo, $patchinfo) = @_;
4707
4708         return defined $diffinfo && defined $patchinfo
4709                 && $diffinfo->{'to_file'} eq $patchinfo->{'to_file'};
4710 }
4711
4712
4713 sub git_difftree_body {
4714         my ($difftree, $hash, @parents) = @_;
4715         my ($parent) = $parents[0];
4716         my $have_blame = gitweb_check_feature('blame');
4717         print "<div class=\"list_head\">\n";
4718         if ($#{$difftree} > 10) {
4719                 print(($#{$difftree} + 1) . " files changed:\n");
4720         }
4721         print "</div>\n";
4722
4723         print "<table class=\"" .
4724               (@parents > 1 ? "combined " : "") .
4725               "diff_tree\">\n";
4726
4727         # header only for combined diff in 'commitdiff' view
4728         my $has_header = @$difftree && @parents > 1 && $action eq 'commitdiff';
4729         if ($has_header) {
4730                 # table header
4731                 print "<thead><tr>\n" .
4732                        "<th></th><th></th>\n"; # filename, patchN link
4733                 for (my $i = 0; $i < @parents; $i++) {
4734                         my $par = $parents[$i];
4735                         print "<th>" .
4736                               $cgi->a({-href => href(action=>"commitdiff",
4737                                                      hash=>$hash, hash_parent=>$par),
4738                                        -title => 'commitdiff to parent number ' .
4739                                                   ($i+1) . ': ' . substr($par,0,7)},
4740                                       $i+1) .
4741                               "&nbsp;</th>\n";
4742                 }
4743                 print "</tr></thead>\n<tbody>\n";
4744         }
4745
4746         my $alternate = 1;
4747         my $patchno = 0;
4748         foreach my $line (@{$difftree}) {
4749                 my $diff = parsed_difftree_line($line);
4750
4751                 if ($alternate) {
4752                         print "<tr class=\"dark\">\n";
4753                 } else {
4754                         print "<tr class=\"light\">\n";
4755                 }
4756                 $alternate ^= 1;
4757
4758                 if (exists $diff->{'nparents'}) { # combined diff
4759
4760                         fill_from_file_info($diff, @parents)
4761                                 unless exists $diff->{'from_file'};
4762
4763                         if (!is_deleted($diff)) {
4764                                 # file exists in the result (child) commit
4765                                 print "<td>" .
4766                                       $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4767                                                              file_name=>$diff->{'to_file'},
4768                                                              hash_base=>$hash),
4769                                               -class => "list"}, esc_path($diff->{'to_file'})) .
4770                                       "</td>\n";
4771                         } else {
4772                                 print "<td>" .
4773                                       esc_path($diff->{'to_file'}) .
4774                                       "</td>\n";
4775                         }
4776
4777                         if ($action eq 'commitdiff') {
4778                                 # link to patch
4779                                 $patchno++;
4780                                 print "<td class=\"link\">" .
4781                                       $cgi->a({-href => href(-anchor=>"patch$patchno")},
4782                                               "patch") .
4783                                       " | " .
4784                                       "</td>\n";
4785                         }
4786
4787                         my $has_history = 0;
4788                         my $not_deleted = 0;
4789                         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4790                                 my $hash_parent = $parents[$i];
4791                                 my $from_hash = $diff->{'from_id'}[$i];
4792                                 my $from_path = $diff->{'from_file'}[$i];
4793                                 my $status = $diff->{'status'}[$i];
4794
4795                                 $has_history ||= ($status ne 'A');
4796                                 $not_deleted ||= ($status ne 'D');
4797
4798                                 if ($status eq 'A') {
4799                                         print "<td  class=\"link\" align=\"right\"> | </td>\n";
4800                                 } elsif ($status eq 'D') {
4801                                         print "<td class=\"link\">" .
4802                                               $cgi->a({-href => href(action=>"blob",
4803                                                                      hash_base=>$hash,
4804                                                                      hash=>$from_hash,
4805                                                                      file_name=>$from_path)},
4806                                                       "blob" . ($i+1)) .
4807                                               " | </td>\n";
4808                                 } else {
4809                                         if ($diff->{'to_id'} eq $from_hash) {
4810                                                 print "<td class=\"link nochange\">";
4811                                         } else {
4812                                                 print "<td class=\"link\">";
4813                                         }
4814                                         print $cgi->a({-href => href(action=>"blobdiff",
4815                                                                      hash=>$diff->{'to_id'},
4816                                                                      hash_parent=>$from_hash,
4817                                                                      hash_base=>$hash,
4818                                                                      hash_parent_base=>$hash_parent,
4819                                                                      file_name=>$diff->{'to_file'},
4820                                                                      file_parent=>$from_path)},
4821                                                       "diff" . ($i+1)) .
4822                                               " | </td>\n";
4823                                 }
4824                         }
4825
4826                         print "<td class=\"link\">";
4827                         if ($not_deleted) {
4828                                 print $cgi->a({-href => href(action=>"blob",
4829                                                              hash=>$diff->{'to_id'},
4830                                                              file_name=>$diff->{'to_file'},
4831                                                              hash_base=>$hash)},
4832                                               "blob");
4833                                 print " | " if ($has_history);
4834                         }
4835                         if ($has_history) {
4836                                 print $cgi->a({-href => href(action=>"history",
4837                                                              file_name=>$diff->{'to_file'},
4838                                                              hash_base=>$hash)},
4839                                               "history");
4840                         }
4841                         print "</td>\n";
4842
4843                         print "</tr>\n";
4844                         next; # instead of 'else' clause, to avoid extra indent
4845                 }
4846                 # else ordinary diff
4847
4848                 my ($to_mode_oct, $to_mode_str, $to_file_type);
4849                 my ($from_mode_oct, $from_mode_str, $from_file_type);
4850                 if ($diff->{'to_mode'} ne ('0' x 6)) {
4851                         $to_mode_oct = oct $diff->{'to_mode'};
4852                         if (S_ISREG($to_mode_oct)) { # only for regular file
4853                                 $to_mode_str = sprintf("%04o", $to_mode_oct & 0777); # permission bits
4854                         }
4855                         $to_file_type = file_type($diff->{'to_mode'});
4856                 }
4857                 if ($diff->{'from_mode'} ne ('0' x 6)) {
4858                         $from_mode_oct = oct $diff->{'from_mode'};
4859                         if (S_ISREG($from_mode_oct)) { # only for regular file
4860                                 $from_mode_str = sprintf("%04o", $from_mode_oct & 0777); # permission bits
4861                         }
4862                         $from_file_type = file_type($diff->{'from_mode'});
4863                 }
4864
4865                 if ($diff->{'status'} eq "A") { # created
4866                         my $mode_chng = "<span class=\"file_status new\">[new $to_file_type";
4867                         $mode_chng   .= " with mode: $to_mode_str" if $to_mode_str;
4868                         $mode_chng   .= "]</span>";
4869                         print "<td>";
4870                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4871                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4872                                       -class => "list"}, esc_path($diff->{'file'}));
4873                         print "</td>\n";
4874                         print "<td>$mode_chng</td>\n";
4875                         print "<td class=\"link\">";
4876                         if ($action eq 'commitdiff') {
4877                                 # link to patch
4878                                 $patchno++;
4879                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4880                                               "patch") .
4881                                       " | ";
4882                         }
4883                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4884                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4885                                       "blob");
4886                         print "</td>\n";
4887
4888                 } elsif ($diff->{'status'} eq "D") { # deleted
4889                         my $mode_chng = "<span class=\"file_status deleted\">[deleted $from_file_type]</span>";
4890                         print "<td>";
4891                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4892                                                      hash_base=>$parent, file_name=>$diff->{'file'}),
4893                                        -class => "list"}, esc_path($diff->{'file'}));
4894                         print "</td>\n";
4895                         print "<td>$mode_chng</td>\n";
4896                         print "<td class=\"link\">";
4897                         if ($action eq 'commitdiff') {
4898                                 # link to patch
4899                                 $patchno++;
4900                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4901                                               "patch") .
4902                                       " | ";
4903                         }
4904                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4905                                                      hash_base=>$parent, file_name=>$diff->{'file'})},
4906                                       "blob") . " | ";
4907                         if ($have_blame) {
4908                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$parent,
4909                                                              file_name=>$diff->{'file'})},
4910                                               "blame") . " | ";
4911                         }
4912                         print $cgi->a({-href => href(action=>"history", hash_base=>$parent,
4913                                                      file_name=>$diff->{'file'})},
4914                                       "history");
4915                         print "</td>\n";
4916
4917                 } elsif ($diff->{'status'} eq "M" || $diff->{'status'} eq "T") { # modified, or type changed
4918                         my $mode_chnge = "";
4919                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4920                                 $mode_chnge = "<span class=\"file_status mode_chnge\">[changed";
4921                                 if ($from_file_type ne $to_file_type) {
4922                                         $mode_chnge .= " from $from_file_type to $to_file_type";
4923                                 }
4924                                 if (($from_mode_oct & 0777) != ($to_mode_oct & 0777)) {
4925                                         if ($from_mode_str && $to_mode_str) {
4926                                                 $mode_chnge .= " mode: $from_mode_str->$to_mode_str";
4927                                         } elsif ($to_mode_str) {
4928                                                 $mode_chnge .= " mode: $to_mode_str";
4929                                         }
4930                                 }
4931                                 $mode_chnge .= "]</span>\n";
4932                         }
4933                         print "<td>";
4934                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4935                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4936                                       -class => "list"}, esc_path($diff->{'file'}));
4937                         print "</td>\n";
4938                         print "<td>$mode_chnge</td>\n";
4939                         print "<td class=\"link\">";
4940                         if ($action eq 'commitdiff') {
4941                                 # link to patch
4942                                 $patchno++;
4943                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4944                                               "patch") .
4945                                       " | ";
4946                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4947                                 # "commit" view and modified file (not onlu mode changed)
4948                                 print $cgi->a({-href => href(action=>"blobdiff",
4949                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4950                                                              hash_base=>$hash, hash_parent_base=>$parent,
4951                                                              file_name=>$diff->{'file'})},
4952                                               "diff") .
4953                                       " | ";
4954                         }
4955                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4956                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4957                                        "blob") . " | ";
4958                         if ($have_blame) {
4959                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4960                                                              file_name=>$diff->{'file'})},
4961                                               "blame") . " | ";
4962                         }
4963                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4964                                                      file_name=>$diff->{'file'})},
4965                                       "history");
4966                         print "</td>\n";
4967
4968                 } elsif ($diff->{'status'} eq "R" || $diff->{'status'} eq "C") { # renamed or copied
4969                         my %status_name = ('R' => 'moved', 'C' => 'copied');
4970                         my $nstatus = $status_name{$diff->{'status'}};
4971                         my $mode_chng = "";
4972                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4973                                 # mode also for directories, so we cannot use $to_mode_str
4974                                 $mode_chng = sprintf(", mode: %04o", $to_mode_oct & 0777);
4975                         }
4976                         print "<td>" .
4977                               $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
4978                                                      hash=>$diff->{'to_id'}, file_name=>$diff->{'to_file'}),
4979                                       -class => "list"}, esc_path($diff->{'to_file'})) . "</td>\n" .
4980                               "<td><span class=\"file_status $nstatus\">[$nstatus from " .
4981                               $cgi->a({-href => href(action=>"blob", hash_base=>$parent,
4982                                                      hash=>$diff->{'from_id'}, file_name=>$diff->{'from_file'}),
4983                                       -class => "list"}, esc_path($diff->{'from_file'})) .
4984                               " with " . (int $diff->{'similarity'}) . "% similarity$mode_chng]</span></td>\n" .
4985                               "<td class=\"link\">";
4986                         if ($action eq 'commitdiff') {
4987                                 # link to patch
4988                                 $patchno++;
4989                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4990                                               "patch") .
4991                                       " | ";
4992                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4993                                 # "commit" view and modified file (not only pure rename or copy)
4994                                 print $cgi->a({-href => href(action=>"blobdiff",
4995                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4996                                                              hash_base=>$hash, hash_parent_base=>$parent,
4997                                                              file_name=>$diff->{'to_file'}, file_parent=>$diff->{'from_file'})},
4998                                               "diff") .
4999                                       " | ";
5000                         }
5001                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
5002                                                      hash_base=>$parent, file_name=>$diff->{'to_file'})},
5003                                       "blob") . " | ";
5004                         if ($have_blame) {
5005                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
5006                                                              file_name=>$diff->{'to_file'})},
5007                                               "blame") . " | ";
5008                         }
5009                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
5010                                                     file_name=>$diff->{'to_file'})},
5011                                       "history");
5012                         print "</td>\n";
5013
5014                 } # we should not encounter Unmerged (U) or Unknown (X) status
5015                 print "</tr>\n";
5016         }
5017         print "</tbody>" if $has_header;
5018         print "</table>\n";
5019 }
5020
5021 # Print context lines and then rem/add lines in a side-by-side manner.
5022 sub print_sidebyside_diff_lines {
5023         my ($ctx, $rem, $add) = @_;
5024
5025         # print context block before add/rem block
5026         if (@$ctx) {
5027                 print join '',
5028                         '<div class="chunk_block ctx">',
5029                                 '<div class="old">',
5030                                 @$ctx,
5031                                 '</div>',
5032                                 '<div class="new">',
5033                                 @$ctx,
5034                                 '</div>',
5035                         '</div>';
5036         }
5037
5038         if (!@$add) {
5039                 # pure removal
5040                 print join '',
5041                         '<div class="chunk_block rem">',
5042                                 '<div class="old">',
5043                                 @$rem,
5044                                 '</div>',
5045                         '</div>';
5046         } elsif (!@$rem) {
5047                 # pure addition
5048                 print join '',
5049                         '<div class="chunk_block add">',
5050                                 '<div class="new">',
5051                                 @$add,
5052                                 '</div>',
5053                         '</div>';
5054         } else {
5055                 print join '',
5056                         '<div class="chunk_block chg">',
5057                                 '<div class="old">',
5058                                 @$rem,
5059                                 '</div>',
5060                                 '<div class="new">',
5061                                 @$add,
5062                                 '</div>',
5063                         '</div>';
5064         }
5065 }
5066
5067 # Print context lines and then rem/add lines in inline manner.
5068 sub print_inline_diff_lines {
5069         my ($ctx, $rem, $add) = @_;
5070
5071         print @$ctx, @$rem, @$add;
5072 }
5073
5074 # Format removed and added line, mark changed part and HTML-format them.
5075 # Implementation is based on contrib/diff-highlight
5076 sub format_rem_add_lines_pair {
5077         my ($rem, $add, $num_parents) = @_;
5078
5079         # We need to untabify lines before split()'ing them;
5080         # otherwise offsets would be invalid.
5081         chomp $rem;
5082         chomp $add;
5083         $rem = untabify($rem);
5084         $add = untabify($add);
5085
5086         my @rem = split(//, $rem);
5087         my @add = split(//, $add);
5088         my ($esc_rem, $esc_add);
5089         # Ignore leading +/- characters for each parent.
5090         my ($prefix_len, $suffix_len) = ($num_parents, 0);
5091         my ($prefix_has_nonspace, $suffix_has_nonspace);
5092
5093         my $shorter = (@rem < @add) ? @rem : @add;
5094         while ($prefix_len < $shorter) {
5095                 last if ($rem[$prefix_len] ne $add[$prefix_len]);
5096
5097                 $prefix_has_nonspace = 1 if ($rem[$prefix_len] !~ /\s/);
5098                 $prefix_len++;
5099         }
5100
5101         while ($prefix_len + $suffix_len < $shorter) {
5102                 last if ($rem[-1 - $suffix_len] ne $add[-1 - $suffix_len]);
5103
5104                 $suffix_has_nonspace = 1 if ($rem[-1 - $suffix_len] !~ /\s/);
5105                 $suffix_len++;
5106         }
5107
5108         # Mark lines that are different from each other, but have some common
5109         # part that isn't whitespace.  If lines are completely different, don't
5110         # mark them because that would make output unreadable, especially if
5111         # diff consists of multiple lines.
5112         if ($prefix_has_nonspace || $suffix_has_nonspace) {
5113                 $esc_rem = esc_html_hl_regions($rem, 'marked',
5114                         [$prefix_len, @rem - $suffix_len], -nbsp=>1);
5115                 $esc_add = esc_html_hl_regions($add, 'marked',
5116                         [$prefix_len, @add - $suffix_len], -nbsp=>1);
5117         } else {
5118                 $esc_rem = esc_html($rem, -nbsp=>1);
5119                 $esc_add = esc_html($add, -nbsp=>1);
5120         }
5121
5122         return format_diff_line(\$esc_rem, 'rem'),
5123                format_diff_line(\$esc_add, 'add');
5124 }
5125
5126 # HTML-format diff context, removed and added lines.
5127 sub format_ctx_rem_add_lines {
5128         my ($ctx, $rem, $add, $num_parents) = @_;
5129         my (@new_ctx, @new_rem, @new_add);
5130         my $can_highlight = 0;
5131         my $is_combined = ($num_parents > 1);
5132
5133         # Highlight if every removed line has a corresponding added line.
5134         if (@$add > 0 && @$add == @$rem) {
5135                 $can_highlight = 1;
5136
5137                 # Highlight lines in combined diff only if the chunk contains
5138                 # diff between the same version, e.g.
5139                 #
5140                 #    - a
5141                 #   -  b
5142                 #    + c
5143                 #   +  d
5144                 #
5145                 # Otherwise the highlightling would be confusing.
5146                 if ($is_combined) {
5147                         for (my $i = 0; $i < @$add; $i++) {
5148                                 my $prefix_rem = substr($rem->[$i], 0, $num_parents);
5149                                 my $prefix_add = substr($add->[$i], 0, $num_parents);
5150
5151                                 $prefix_rem =~ s/-/+/g;
5152
5153                                 if ($prefix_rem ne $prefix_add) {
5154                                         $can_highlight = 0;
5155                                         last;
5156                                 }
5157                         }
5158                 }
5159         }
5160
5161         if ($can_highlight) {
5162                 for (my $i = 0; $i < @$add; $i++) {
5163                         my ($line_rem, $line_add) = format_rem_add_lines_pair(
5164                                 $rem->[$i], $add->[$i], $num_parents);
5165                         push @new_rem, $line_rem;
5166                         push @new_add, $line_add;
5167                 }
5168         } else {
5169                 @new_rem = map { format_diff_line($_, 'rem') } @$rem;
5170                 @new_add = map { format_diff_line($_, 'add') } @$add;
5171         }
5172
5173         @new_ctx = map { format_diff_line($_, 'ctx') } @$ctx;
5174
5175         return (\@new_ctx, \@new_rem, \@new_add);
5176 }
5177
5178 # Print context lines and then rem/add lines.
5179 sub print_diff_lines {
5180         my ($ctx, $rem, $add, $diff_style, $num_parents) = @_;
5181         my $is_combined = $num_parents > 1;
5182
5183         ($ctx, $rem, $add) = format_ctx_rem_add_lines($ctx, $rem, $add,
5184                 $num_parents);
5185
5186         if ($diff_style eq 'sidebyside' && !$is_combined) {
5187                 print_sidebyside_diff_lines($ctx, $rem, $add);
5188         } else {
5189                 # default 'inline' style and unknown styles
5190                 print_inline_diff_lines($ctx, $rem, $add);
5191         }
5192 }
5193
5194 sub print_diff_chunk {
5195         my ($diff_style, $num_parents, $from, $to, @chunk) = @_;
5196         my (@ctx, @rem, @add);
5197
5198         # The class of the previous line.
5199         my $prev_class = '';
5200
5201         return unless @chunk;
5202
5203         # incomplete last line might be among removed or added lines,
5204         # or both, or among context lines: find which
5205         for (my $i = 1; $i < @chunk; $i++) {
5206                 if ($chunk[$i][0] eq 'incomplete') {
5207                         $chunk[$i][0] = $chunk[$i-1][0];
5208                 }
5209         }
5210
5211         # guardian
5212         push @chunk, ["", ""];
5213
5214         foreach my $line_info (@chunk) {
5215                 my ($class, $line) = @$line_info;
5216
5217                 # print chunk headers
5218                 if ($class && $class eq 'chunk_header') {
5219                         print format_diff_line($line, $class, $from, $to);
5220                         next;
5221                 }
5222
5223                 ## print from accumulator when have some add/rem lines or end
5224                 # of chunk (flush context lines), or when have add and rem
5225                 # lines and new block is reached (otherwise add/rem lines could
5226                 # be reordered)
5227                 if (!$class || ((@rem || @add) && $class eq 'ctx') ||
5228                     (@rem && @add && $class ne $prev_class)) {
5229                         print_diff_lines(\@ctx, \@rem, \@add,
5230                                          $diff_style, $num_parents);
5231                         @ctx = @rem = @add = ();
5232                 }
5233
5234                 ## adding lines to accumulator
5235                 # guardian value
5236                 last unless $line;
5237                 # rem, add or change
5238                 if ($class eq 'rem') {
5239                         push @rem, $line;
5240                 } elsif ($class eq 'add') {
5241                         push @add, $line;
5242                 }
5243                 # context line
5244                 if ($class eq 'ctx') {
5245                         push @ctx, $line;
5246                 }
5247
5248                 $prev_class = $class;
5249         }
5250 }
5251
5252 sub git_patchset_body {
5253         my ($fd, $diff_style, $difftree, $hash, @hash_parents) = @_;
5254         my ($hash_parent) = $hash_parents[0];
5255
5256         my $is_combined = (@hash_parents > 1);
5257         my $patch_idx = 0;
5258         my $patch_number = 0;
5259         my $patch_line;
5260         my $diffinfo;
5261         my $to_name;
5262         my (%from, %to);
5263         my @chunk; # for side-by-side diff
5264
5265         print "<div class=\"patchset\">\n";
5266
5267         # skip to first patch
5268         while ($patch_line = <$fd>) {
5269                 chomp $patch_line;
5270
5271                 last if ($patch_line =~ m/^diff /);
5272         }
5273
5274  PATCH:
5275         while ($patch_line) {
5276
5277                 # parse "git diff" header line
5278                 if ($patch_line =~ m/^diff --git (\"(?:[^\\\"]*(?:\\.[^\\\"]*)*)\"|[^ "]*) (.*)$/) {
5279                         # $1 is from_name, which we do not use
5280                         $to_name = unquote($2);
5281                         $to_name =~ s!^b/!!;
5282                 } elsif ($patch_line =~ m/^diff --(cc|combined) ("?.*"?)$/) {
5283                         # $1 is 'cc' or 'combined', which we do not use
5284                         $to_name = unquote($2);
5285                 } else {
5286                         $to_name = undef;
5287                 }
5288
5289                 # check if current patch belong to current raw line
5290                 # and parse raw git-diff line if needed
5291                 if (is_patch_split($diffinfo, { 'to_file' => $to_name })) {
5292                         # this is continuation of a split patch
5293                         print "<div class=\"patch cont\">\n";
5294                 } else {
5295                         # advance raw git-diff output if needed
5296                         $patch_idx++ if defined $diffinfo;
5297
5298                         # read and prepare patch information
5299                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5300
5301                         # compact combined diff output can have some patches skipped
5302                         # find which patch (using pathname of result) we are at now;
5303                         if ($is_combined) {
5304                                 while ($to_name ne $diffinfo->{'to_file'}) {
5305                                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
5306                                               format_diff_cc_simplified($diffinfo, @hash_parents) .
5307                                               "</div>\n";  # class="patch"
5308
5309                                         $patch_idx++;
5310                                         $patch_number++;
5311
5312                                         last if $patch_idx > $#$difftree;
5313                                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5314                                 }
5315                         }
5316
5317                         # modifies %from, %to hashes
5318                         parse_from_to_diffinfo($diffinfo, \%from, \%to, @hash_parents);
5319
5320                         # this is first patch for raw difftree line with $patch_idx index
5321                         # we index @$difftree array from 0, but number patches from 1
5322                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n";
5323                 }
5324
5325                 # git diff header
5326                 #assert($patch_line =~ m/^diff /) if DEBUG;
5327                 #assert($patch_line !~ m!$/$!) if DEBUG; # is chomp-ed
5328                 $patch_number++;
5329                 # print "git diff" header
5330                 print format_git_diff_header_line($patch_line, $diffinfo,
5331                                                   \%from, \%to);
5332
5333                 # print extended diff header
5334                 print "<div class=\"diff extended_header\">\n";
5335         EXTENDED_HEADER:
5336                 while ($patch_line = <$fd>) {
5337                         chomp $patch_line;
5338
5339                         last EXTENDED_HEADER if ($patch_line =~ m/^--- |^diff /);
5340
5341                         print format_extended_diff_header_line($patch_line, $diffinfo,
5342                                                                \%from, \%to);
5343                 }
5344                 print "</div>\n"; # class="diff extended_header"
5345
5346                 # from-file/to-file diff header
5347                 if (! $patch_line) {
5348                         print "</div>\n"; # class="patch"
5349                         last PATCH;
5350                 }
5351                 next PATCH if ($patch_line =~ m/^diff /);
5352                 #assert($patch_line =~ m/^---/) if DEBUG;
5353
5354                 my $last_patch_line = $patch_line;
5355                 $patch_line = <$fd>;
5356                 chomp $patch_line;
5357                 #assert($patch_line =~ m/^\+\+\+/) if DEBUG;
5358
5359                 print format_diff_from_to_header($last_patch_line, $patch_line,
5360                                                  $diffinfo, \%from, \%to,
5361                                                  @hash_parents);
5362
5363                 # the patch itself
5364         LINE:
5365                 while ($patch_line = <$fd>) {
5366                         chomp $patch_line;
5367
5368                         next PATCH if ($patch_line =~ m/^diff /);
5369
5370                         my $class = diff_line_class($patch_line, \%from, \%to);
5371
5372                         if ($class eq 'chunk_header') {
5373                                 print_diff_chunk($diff_style, scalar @hash_parents, \%from, \%to, @chunk);
5374                                 @chunk = ();
5375                         }
5376
5377                         push @chunk, [ $class, $patch_line ];
5378                 }
5379
5380         } continue {
5381                 if (@chunk) {
5382                         print_diff_chunk($diff_style, scalar @hash_parents, \%from, \%to, @chunk);
5383                         @chunk = ();
5384                 }
5385                 print "</div>\n"; # class="patch"
5386         }
5387
5388         # for compact combined (--cc) format, with chunk and patch simplification
5389         # the patchset might be empty, but there might be unprocessed raw lines
5390         for (++$patch_idx if $patch_number > 0;
5391              $patch_idx < @$difftree;
5392              ++$patch_idx) {
5393                 # read and prepare patch information
5394                 $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5395
5396                 # generate anchor for "patch" links in difftree / whatchanged part
5397                 print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
5398                       format_diff_cc_simplified($diffinfo, @hash_parents) .
5399                       "</div>\n";  # class="patch"
5400
5401                 $patch_number++;
5402         }
5403
5404         if ($patch_number == 0) {
5405                 if (@hash_parents > 1) {
5406                         print "<div class=\"diff nodifferences\">Trivial merge</div>\n";
5407                 } else {
5408                         print "<div class=\"diff nodifferences\">No differences found</div>\n";
5409                 }
5410         }
5411
5412         print "</div>\n"; # class="patchset"
5413 }
5414
5415 # . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
5416
5417 sub git_project_search_form {
5418         my ($searchtext, $search_use_regexp) = @_;
5419
5420         my $limit = '';
5421         if ($project_filter) {
5422                 $limit = " in '$project_filter/'";
5423         }
5424
5425         print "<div class=\"projsearch\">\n";
5426         print $cgi->startform(-method => 'get', -action => $my_uri) .
5427               $cgi->hidden(-name => 'a', -value => 'project_list')  . "\n";
5428         print $cgi->hidden(-name => 'pf', -value => $project_filter). "\n"
5429                 if (defined $project_filter);
5430         print $cgi->textfield(-name => 's', -value => $searchtext,
5431                               -title => "Search project by name and description$limit",
5432                               -size => 60) . "\n" .
5433               "<span title=\"Extended regular expression\">" .
5434               $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
5435                              -checked => $search_use_regexp) .
5436               "</span>\n" .
5437               $cgi->submit(-name => 'btnS', -value => 'Search') .
5438               $cgi->end_form() . "\n" .
5439               $cgi->a({-href => href(project => undef, searchtext => undef,
5440                                      project_filter => $project_filter)},
5441                       esc_html("List all projects$limit")) . "<br />\n";
5442         print "</div>\n";
5443 }
5444
5445 # entry for given @keys needs filling if at least one of keys in list
5446 # is not present in %$project_info
5447 sub project_info_needs_filling {
5448         my ($project_info, @keys) = @_;
5449
5450         # return List::MoreUtils::any { !exists $project_info->{$_} } @keys;
5451         foreach my $key (@keys) {
5452                 if (!exists $project_info->{$key}) {
5453                         return 1;
5454                 }
5455         }
5456         return;
5457 }
5458
5459 # fills project list info (age, description, owner, category, forks, etc.)
5460 # for each project in the list, removing invalid projects from
5461 # returned list, or fill only specified info.
5462 #
5463 # Invalid projects are removed from the returned list if and only if you
5464 # ask 'age' or 'age_string' to be filled, because they are the only fields
5465 # that run unconditionally git command that requires repository, and
5466 # therefore do always check if project repository is invalid.
5467 #
5468 # USAGE:
5469 # * fill_project_list_info(\@project_list, 'descr_long', 'ctags')
5470 #   ensures that 'descr_long' and 'ctags' fields are filled
5471 # * @project_list = fill_project_list_info(\@project_list)
5472 #   ensures that all fields are filled (and invalid projects removed)
5473 #
5474 # NOTE: modifies $projlist, but does not remove entries from it
5475 sub fill_project_list_info {
5476         my ($projlist, @wanted_keys) = @_;
5477         my @projects;
5478         my $filter_set = sub { return @_; };
5479         if (@wanted_keys) {
5480                 my %wanted_keys = map { $_ => 1 } @wanted_keys;
5481                 $filter_set = sub { return grep { $wanted_keys{$_} } @_; };
5482         }
5483
5484         my $show_ctags = gitweb_check_feature('ctags');
5485  PROJECT:
5486         foreach my $pr (@$projlist) {
5487                 if (project_info_needs_filling($pr, $filter_set->('age', 'age_string'))) {
5488                         my (@activity) = git_get_last_activity($pr->{'path'});
5489                         unless (@activity) {
5490                                 next PROJECT;
5491                         }
5492                         ($pr->{'age'}, $pr->{'age_string'}) = @activity;
5493                 }
5494                 if (project_info_needs_filling($pr, $filter_set->('descr', 'descr_long'))) {
5495                         my $descr = git_get_project_description($pr->{'path'}) || "";
5496                         $descr = to_utf8($descr);
5497                         $pr->{'descr_long'} = $descr;
5498                         $pr->{'descr'} = chop_str($descr, $projects_list_description_width, 5);
5499                 }
5500                 if (project_info_needs_filling($pr, $filter_set->('owner'))) {
5501                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}") || "";
5502                 }
5503                 if ($show_ctags &&
5504                     project_info_needs_filling($pr, $filter_set->('ctags'))) {
5505                         $pr->{'ctags'} = git_get_project_ctags($pr->{'path'});
5506                 }
5507                 if ($projects_list_group_categories &&
5508                     project_info_needs_filling($pr, $filter_set->('category'))) {
5509                         my $cat = git_get_project_category($pr->{'path'}) ||
5510                                                            $project_list_default_category;
5511                         $pr->{'category'} = to_utf8($cat);
5512                 }
5513
5514                 push @projects, $pr;
5515         }
5516
5517         return @projects;
5518 }
5519
5520 sub sort_projects_list {
5521         my ($projlist, $order) = @_;
5522         my @projects;
5523
5524         my %order_info = (
5525                 project => { key => 'path', type => 'str' },
5526                 descr => { key => 'descr_long', type => 'str' },
5527                 owner => { key => 'owner', type => 'str' },
5528                 age => { key => 'age', type => 'num' }
5529         );
5530         my $oi = $order_info{$order};
5531         return @$projlist unless defined $oi;
5532         if ($oi->{'type'} eq 'str') {
5533                 @projects = sort {$a->{$oi->{'key'}} cmp $b->{$oi->{'key'}}} @$projlist;
5534         } else {
5535                 @projects = sort {$a->{$oi->{'key'}} <=> $b->{$oi->{'key'}}} @$projlist;
5536         }
5537
5538         return @projects;
5539 }
5540
5541 # returns a hash of categories, containing the list of project
5542 # belonging to each category
5543 sub build_projlist_by_category {
5544         my ($projlist, $from, $to) = @_;
5545         my %categories;
5546
5547         $from = 0 unless defined $from;
5548         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5549
5550         for (my $i = $from; $i <= $to; $i++) {
5551                 my $pr = $projlist->[$i];
5552                 push @{$categories{ $pr->{'category'} }}, $pr;
5553         }
5554
5555         return wantarray ? %categories : \%categories;
5556 }
5557
5558 # print 'sort by' <th> element, generating 'sort by $name' replay link
5559 # if that order is not selected
5560 sub print_sort_th {
5561         print format_sort_th(@_);
5562 }
5563
5564 sub format_sort_th {
5565         my ($name, $order, $header) = @_;
5566         my $sort_th = "";
5567         $header ||= ucfirst($name);
5568
5569         if ($order eq $name) {
5570                 $sort_th .= "<th>$header</th>\n";
5571         } else {
5572                 $sort_th .= "<th>" .
5573                             $cgi->a({-href => href(-replay=>1, order=>$name),
5574                                      -class => "header"}, $header) .
5575                             "</th>\n";
5576         }
5577
5578         return $sort_th;
5579 }
5580
5581 sub git_project_list_rows {
5582         my ($projlist, $from, $to, $check_forks) = @_;
5583
5584         $from = 0 unless defined $from;
5585         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5586
5587         my $alternate = 1;
5588         for (my $i = $from; $i <= $to; $i++) {
5589                 my $pr = $projlist->[$i];
5590
5591                 if ($alternate) {
5592                         print "<tr class=\"dark\">\n";
5593                 } else {
5594                         print "<tr class=\"light\">\n";
5595                 }
5596                 $alternate ^= 1;
5597
5598                 if ($check_forks) {
5599                         print "<td>";
5600                         if ($pr->{'forks'}) {
5601                                 my $nforks = scalar @{$pr->{'forks'}};
5602                                 if ($nforks > 0) {
5603                                         print $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks"),
5604                                                        -title => "$nforks forks"}, "+");
5605                                 } else {
5606                                         print $cgi->span({-title => "$nforks forks"}, "+");
5607                                 }
5608                         }
5609                         print "</td>\n";
5610                 }
5611                 print "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5612                                         -class => "list"},
5613                                        esc_html_match_hl($pr->{'path'}, $search_regexp)) .
5614                       "</td>\n" .
5615                       "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5616                                         -class => "list",
5617                                         -title => $pr->{'descr_long'}},
5618                                         $search_regexp
5619                                         ? esc_html_match_hl_chopped($pr->{'descr_long'},
5620                                                                     $pr->{'descr'}, $search_regexp)
5621                                         : esc_html($pr->{'descr'})) .
5622                       "</td>\n";
5623                 unless ($omit_owner) {
5624                         print "<td><i>" . chop_and_escape_str($pr->{'owner'}, 15) . "</i></td>\n";
5625                 }
5626                 unless ($omit_age_column) {
5627                         print "<td class=\"". age_class($pr->{'age'}) . "\">" .
5628                             (defined $pr->{'age_string'} ? $pr->{'age_string'} : "No commits") . "</td>\n";
5629                 }
5630                 print"<td class=\"link\">" .
5631                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary")}, "summary")   . " | " .
5632                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"shortlog")}, "shortlog") . " | " .
5633                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"log")}, "log") . " | " .
5634                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"tree")}, "tree") .
5635                       ($pr->{'forks'} ? " | " . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "forks") : '') .
5636                       "</td>\n" .
5637                       "</tr>\n";
5638         }
5639 }
5640
5641 sub git_project_list_body {
5642         # actually uses global variable $project
5643         my ($projlist, $order, $from, $to, $extra, $no_header) = @_;
5644         my @projects = @$projlist;
5645
5646         my $check_forks = gitweb_check_feature('forks');
5647         my $show_ctags  = gitweb_check_feature('ctags');
5648         my $tagfilter = $show_ctags ? $input_params{'ctag'} : undef;
5649         $check_forks = undef
5650                 if ($tagfilter || $search_regexp);
5651
5652         # filtering out forks before filling info allows to do less work
5653         @projects = filter_forks_from_projects_list(\@projects)
5654                 if ($check_forks);
5655         # search_projects_list pre-fills required info
5656         @projects = search_projects_list(\@projects,
5657                                          'search_regexp' => $search_regexp,
5658                                          'tagfilter'  => $tagfilter)
5659                 if ($tagfilter || $search_regexp);
5660         # fill the rest
5661         my @all_fields = ('descr', 'descr_long', 'ctags', 'category');
5662         push @all_fields, ('age', 'age_string') unless($omit_age_column);
5663         push @all_fields, 'owner' unless($omit_owner);
5664         @projects = fill_project_list_info(\@projects, @all_fields);
5665
5666         $order ||= $default_projects_order;
5667         $from = 0 unless defined $from;
5668         $to = $#projects if (!defined $to || $#projects < $to);
5669
5670         # short circuit
5671         if ($from > $to) {
5672                 print "<center>\n".
5673                       "<b>No such projects found</b><br />\n".
5674                       "Click ".$cgi->a({-href=>href(project=>undef)},"here")." to view all projects<br />\n".
5675                       "</center>\n<br />\n";
5676                 return;
5677         }
5678
5679         @projects = sort_projects_list(\@projects, $order);
5680
5681         if ($show_ctags) {
5682                 my $ctags = git_gather_all_ctags(\@projects);
5683                 my $cloud = git_populate_project_tagcloud($ctags);
5684                 print git_show_project_tagcloud($cloud, 64);
5685         }
5686
5687         print "<table class=\"project_list\">\n";
5688         unless ($no_header) {
5689                 print "<tr>\n";
5690                 if ($check_forks) {
5691                         print "<th></th>\n";
5692                 }
5693                 print_sort_th('project', $order, 'Project');
5694                 print_sort_th('descr', $order, 'Description');
5695                 print_sort_th('owner', $order, 'Owner') unless $omit_owner;
5696                 print_sort_th('age', $order, 'Last Change') unless $omit_age_column;
5697                 print "<th></th>\n" . # for links
5698                       "</tr>\n";
5699         }
5700
5701         if ($projects_list_group_categories) {
5702                 # only display categories with projects in the $from-$to window
5703                 @projects = sort {$a->{'category'} cmp $b->{'category'}} @projects[$from..$to];
5704                 my %categories = build_projlist_by_category(\@projects, $from, $to);
5705                 foreach my $cat (sort keys %categories) {
5706                         unless ($cat eq "") {
5707                                 print "<tr>\n";
5708                                 if ($check_forks) {
5709                                         print "<td></td>\n";
5710                                 }
5711                                 print "<td class=\"category\" colspan=\"5\">".esc_html($cat)."</td>\n";
5712                                 print "</tr>\n";
5713                         }
5714
5715                         git_project_list_rows($categories{$cat}, undef, undef, $check_forks);
5716                 }
5717         } else {
5718                 git_project_list_rows(\@projects, $from, $to, $check_forks);
5719         }
5720
5721         if (defined $extra) {
5722                 print "<tr>\n";
5723                 if ($check_forks) {
5724                         print "<td></td>\n";
5725                 }
5726                 print "<td colspan=\"5\">$extra</td>\n" .
5727                       "</tr>\n";
5728         }
5729         print "</table>\n";
5730 }
5731
5732 sub git_log_body {
5733         # uses global variable $project
5734         my ($commitlist, $from, $to, $refs, $extra) = @_;
5735
5736         $from = 0 unless defined $from;
5737         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5738
5739         for (my $i = 0; $i <= $to; $i++) {
5740                 my %co = %{$commitlist->[$i]};
5741                 next if !%co;
5742                 my $commit = $co{'id'};
5743                 my $ref = format_ref_marker($refs, $commit);
5744                 git_print_header_div('commit',
5745                                "<span class=\"age\">$co{'age_string'}</span>" .
5746                                esc_html($co{'title'}) . $ref,
5747                                $commit);
5748                 print "<div class=\"title_text\">\n" .
5749                       "<div class=\"log_link\">\n" .
5750                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") .
5751                       " | " .
5752                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") .
5753                       " | " .
5754                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree") .
5755                       "<br/>\n" .
5756                       "</div>\n";
5757                       git_print_authorship(\%co, -tag => 'span');
5758                       print "<br/>\n</div>\n";
5759
5760                 print "<div class=\"log_body\">\n";
5761                 git_print_log($co{'comment'}, -final_empty_line=> 1);
5762                 print "</div>\n";
5763         }
5764         if ($extra) {
5765                 print "<div class=\"page_nav\">\n";
5766                 print "$extra\n";
5767                 print "</div>\n";
5768         }
5769 }
5770
5771 sub git_shortlog_body {
5772         # uses global variable $project
5773         my ($commitlist, $from, $to, $refs, $extra) = @_;
5774
5775         $from = 0 unless defined $from;
5776         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5777
5778         print "<table class=\"shortlog\">\n";
5779         my $alternate = 1;
5780         for (my $i = $from; $i <= $to; $i++) {
5781                 my %co = %{$commitlist->[$i]};
5782                 my $commit = $co{'id'};
5783                 my $ref = format_ref_marker($refs, $commit);
5784                 if ($alternate) {
5785                         print "<tr class=\"dark\">\n";
5786                 } else {
5787                         print "<tr class=\"light\">\n";
5788                 }
5789                 $alternate ^= 1;
5790                 # git_summary() used print "<td><i>$co{'age_string'}</i></td>\n" .
5791                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5792                       format_author_html('td', \%co, 10) . "<td>";
5793                 print format_subject_html($co{'title'}, $co{'title_short'},
5794                                           href(action=>"commit", hash=>$commit), $ref);
5795                 print "</td>\n" .
5796                       "<td class=\"link\">" .
5797                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") . " | " .
5798                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") . " | " .
5799                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree");
5800                 my $snapshot_links = format_snapshot_links($commit);
5801                 if (defined $snapshot_links) {
5802                         print " | " . $snapshot_links;
5803                 }
5804                 print "</td>\n" .
5805                       "</tr>\n";
5806         }
5807         if (defined $extra) {
5808                 print "<tr>\n" .
5809                       "<td colspan=\"4\">$extra</td>\n" .
5810                       "</tr>\n";
5811         }
5812         print "</table>\n";
5813 }
5814
5815 sub git_history_body {
5816         # Warning: assumes constant type (blob or tree) during history
5817         my ($commitlist, $from, $to, $refs, $extra,
5818             $file_name, $file_hash, $ftype) = @_;
5819
5820         $from = 0 unless defined $from;
5821         $to = $#{$commitlist} unless (defined $to && $to <= $#{$commitlist});
5822
5823         print "<table class=\"history\">\n";
5824         my $alternate = 1;
5825         for (my $i = $from; $i <= $to; $i++) {
5826                 my %co = %{$commitlist->[$i]};
5827                 if (!%co) {
5828                         next;
5829                 }
5830                 my $commit = $co{'id'};
5831
5832                 my $ref = format_ref_marker($refs, $commit);
5833
5834                 if ($alternate) {
5835                         print "<tr class=\"dark\">\n";
5836                 } else {
5837                         print "<tr class=\"light\">\n";
5838                 }
5839                 $alternate ^= 1;
5840                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5841         # shortlog:   format_author_html('td', \%co, 10)
5842                       format_author_html('td', \%co, 15, 3) . "<td>";
5843                 # originally git_history used chop_str($co{'title'}, 50)
5844                 print format_subject_html($co{'title'}, $co{'title_short'},
5845                                           href(action=>"commit", hash=>$commit), $ref);
5846                 print "</td>\n" .
5847                       "<td class=\"link\">" .
5848                       $cgi->a({-href => href(action=>$ftype, hash_base=>$commit, file_name=>$file_name)}, $ftype) . " | " .
5849                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff");
5850
5851                 if ($ftype eq 'blob') {
5852                         my $blob_current = $file_hash;
5853                         my $blob_parent  = git_get_hash_by_path($commit, $file_name);
5854                         if (defined $blob_current && defined $blob_parent &&
5855                                         $blob_current ne $blob_parent) {
5856                                 print " | " .
5857                                         $cgi->a({-href => href(action=>"blobdiff",
5858                                                                hash=>$blob_current, hash_parent=>$blob_parent,
5859                                                                hash_base=>$hash_base, hash_parent_base=>$commit,
5860                                                                file_name=>$file_name)},
5861                                                 "diff to current");
5862                         }
5863                 }
5864                 print "</td>\n" .
5865                       "</tr>\n";
5866         }
5867         if (defined $extra) {
5868                 print "<tr>\n" .
5869                       "<td colspan=\"4\">$extra</td>\n" .
5870                       "</tr>\n";
5871         }
5872         print "</table>\n";
5873 }
5874
5875 sub git_tags_body {
5876         # uses global variable $project
5877         my ($taglist, $from, $to, $extra) = @_;
5878         $from = 0 unless defined $from;
5879         $to = $#{$taglist} if (!defined $to || $#{$taglist} < $to);
5880
5881         print "<table class=\"tags\">\n";
5882         my $alternate = 1;
5883         for (my $i = $from; $i <= $to; $i++) {
5884                 my $entry = $taglist->[$i];
5885                 my %tag = %$entry;
5886                 my $comment = $tag{'subject'};
5887                 my $comment_short;
5888                 if (defined $comment) {
5889                         $comment_short = chop_str($comment, 30, 5);
5890                 }
5891                 if ($alternate) {
5892                         print "<tr class=\"dark\">\n";
5893                 } else {
5894                         print "<tr class=\"light\">\n";
5895                 }
5896                 $alternate ^= 1;
5897                 if (defined $tag{'age'}) {
5898                         print "<td><i>$tag{'age'}</i></td>\n";
5899                 } else {
5900                         print "<td></td>\n";
5901                 }
5902                 print "<td>" .
5903                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'}),
5904                                -class => "list name"}, esc_html($tag{'name'})) .
5905                       "</td>\n" .
5906                       "<td>";
5907                 if (defined $comment) {
5908                         print format_subject_html($comment, $comment_short,
5909                                                   href(action=>"tag", hash=>$tag{'id'}));
5910                 }
5911                 print "</td>\n" .
5912                       "<td class=\"selflink\">";
5913                 if ($tag{'type'} eq "tag") {
5914                         print $cgi->a({-href => href(action=>"tag", hash=>$tag{'id'})}, "tag");
5915                 } else {
5916                         print "&nbsp;";
5917                 }
5918                 print "</td>\n" .
5919                       "<td class=\"link\">" . " | " .
5920                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'})}, $tag{'reftype'});
5921                 if ($tag{'reftype'} eq "commit") {
5922                         print " | " . $cgi->a({-href => href(action=>"shortlog", hash=>$tag{'fullname'})}, "shortlog") .
5923                               " | " . $cgi->a({-href => href(action=>"log", hash=>$tag{'fullname'})}, "log");
5924                 } elsif ($tag{'reftype'} eq "blob") {
5925                         print " | " . $cgi->a({-href => href(action=>"blob_plain", hash=>$tag{'refid'})}, "raw");
5926                 }
5927                 print "</td>\n" .
5928                       "</tr>";
5929         }
5930         if (defined $extra) {
5931                 print "<tr>\n" .
5932                       "<td colspan=\"5\">$extra</td>\n" .
5933                       "</tr>\n";
5934         }
5935         print "</table>\n";
5936 }
5937
5938 sub git_heads_body {
5939         # uses global variable $project
5940         my ($headlist, $head_at, $from, $to, $extra) = @_;
5941         $from = 0 unless defined $from;
5942         $to = $#{$headlist} if (!defined $to || $#{$headlist} < $to);
5943
5944         print "<table class=\"heads\">\n";
5945         my $alternate = 1;
5946         for (my $i = $from; $i <= $to; $i++) {
5947                 my $entry = $headlist->[$i];
5948                 my %ref = %$entry;
5949                 my $curr = defined $head_at && $ref{'id'} eq $head_at;
5950                 if ($alternate) {
5951                         print "<tr class=\"dark\">\n";
5952                 } else {
5953                         print "<tr class=\"light\">\n";
5954                 }
5955                 $alternate ^= 1;
5956                 print "<td><i>$ref{'age'}</i></td>\n" .
5957                       ($curr ? "<td class=\"current_head\">" : "<td>") .
5958                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'}),
5959                                -class => "list name"},esc_html($ref{'name'})) .
5960                       "</td>\n" .
5961                       "<td class=\"link\">" .
5962                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'})}, "shortlog") . " | " .
5963                       $cgi->a({-href => href(action=>"log", hash=>$ref{'fullname'})}, "log") . " | " .
5964                       $cgi->a({-href => href(action=>"tree", hash=>$ref{'fullname'}, hash_base=>$ref{'fullname'})}, "tree") .
5965                       "</td>\n" .
5966                       "</tr>";
5967         }
5968         if (defined $extra) {
5969                 print "<tr>\n" .
5970                       "<td colspan=\"3\">$extra</td>\n" .
5971                       "</tr>\n";
5972         }
5973         print "</table>\n";
5974 }
5975
5976 # Display a single remote block
5977 sub git_remote_block {
5978         my ($remote, $rdata, $limit, $head) = @_;
5979
5980         my $heads = $rdata->{'heads'};
5981         my $fetch = $rdata->{'fetch'};
5982         my $push = $rdata->{'push'};
5983
5984         my $urls_table = "<table class=\"projects_list\">\n" ;
5985
5986         if (defined $fetch) {
5987                 if ($fetch eq $push) {
5988                         $urls_table .= format_repo_url("URL", $fetch);
5989                 } else {
5990                         $urls_table .= format_repo_url("Fetch URL", $fetch);
5991                         $urls_table .= format_repo_url("Push URL", $push) if defined $push;
5992                 }
5993         } elsif (defined $push) {
5994                 $urls_table .= format_repo_url("Push URL", $push);
5995         } else {
5996                 $urls_table .= format_repo_url("", "No remote URL");
5997         }
5998
5999         $urls_table .= "</table>\n";
6000
6001         my $dots;
6002         if (defined $limit && $limit < @$heads) {
6003                 $dots = $cgi->a({-href => href(action=>"remotes", hash=>$remote)}, "...");
6004         }
6005
6006         print $urls_table;
6007         git_heads_body($heads, $head, 0, $limit, $dots);
6008 }
6009
6010 # Display a list of remote names with the respective fetch and push URLs
6011 sub git_remotes_list {
6012         my ($remotedata, $limit) = @_;
6013         print "<table class=\"heads\">\n";
6014         my $alternate = 1;
6015         my @remotes = sort keys %$remotedata;
6016
6017         my $limited = $limit && $limit < @remotes;
6018
6019         $#remotes = $limit - 1 if $limited;
6020
6021         while (my $remote = shift @remotes) {
6022                 my $rdata = $remotedata->{$remote};
6023                 my $fetch = $rdata->{'fetch'};
6024                 my $push = $rdata->{'push'};
6025                 if ($alternate) {
6026                         print "<tr class=\"dark\">\n";
6027                 } else {
6028                         print "<tr class=\"light\">\n";
6029                 }
6030                 $alternate ^= 1;
6031                 print "<td>" .
6032                       $cgi->a({-href=> href(action=>'remotes', hash=>$remote),
6033                                -class=> "list name"},esc_html($remote)) .
6034                       "</td>";
6035                 print "<td class=\"link\">" .
6036                       (defined $fetch ? $cgi->a({-href=> $fetch}, "fetch") : "fetch") .
6037                       " | " .
6038                       (defined $push ? $cgi->a({-href=> $push}, "push") : "push") .
6039                       "</td>";
6040
6041                 print "</tr>\n";
6042         }
6043
6044         if ($limited) {
6045                 print "<tr>\n" .
6046                       "<td colspan=\"3\">" .
6047                       $cgi->a({-href => href(action=>"remotes")}, "...") .
6048                       "</td>\n" . "</tr>\n";
6049         }
6050
6051         print "</table>";
6052 }
6053
6054 # Display remote heads grouped by remote, unless there are too many
6055 # remotes, in which case we only display the remote names
6056 sub git_remotes_body {
6057         my ($remotedata, $limit, $head) = @_;
6058         if ($limit and $limit < keys %$remotedata) {
6059                 git_remotes_list($remotedata, $limit);
6060         } else {
6061                 fill_remote_heads($remotedata);
6062                 while (my ($remote, $rdata) = each %$remotedata) {
6063                         git_print_section({-class=>"remote", -id=>$remote},
6064                                 ["remotes", $remote, $remote], sub {
6065                                         git_remote_block($remote, $rdata, $limit, $head);
6066                                 });
6067                 }
6068         }
6069 }
6070
6071 sub git_search_message {
6072         my %co = @_;
6073
6074         my $greptype;
6075         if ($searchtype eq 'commit') {
6076                 $greptype = "--grep=";
6077         } elsif ($searchtype eq 'author') {
6078                 $greptype = "--author=";
6079         } elsif ($searchtype eq 'committer') {
6080                 $greptype = "--committer=";
6081         }
6082         $greptype .= $searchtext;
6083         my @commitlist = parse_commits($hash, 101, (100 * $page), undef,
6084                                        $greptype, '--regexp-ignore-case',
6085                                        $search_use_regexp ? '--extended-regexp' : '--fixed-strings');
6086
6087         my $paging_nav = '';
6088         if ($page > 0) {
6089                 $paging_nav .=
6090                         $cgi->a({-href => href(-replay=>1, page=>undef)},
6091                                 "first") .
6092                         " &sdot; " .
6093                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
6094                                  -accesskey => "p", -title => "Alt-p"}, "prev");
6095         } else {
6096                 $paging_nav .= "first &sdot; prev";
6097         }
6098         my $next_link = '';
6099         if ($#commitlist >= 100) {
6100                 $next_link =
6101                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
6102                                  -accesskey => "n", -title => "Alt-n"}, "next");
6103                 $paging_nav .= " &sdot; $next_link";
6104         } else {
6105                 $paging_nav .= " &sdot; next";
6106         }
6107
6108         git_header_html();
6109
6110         git_print_page_nav('','', $hash,$co{'tree'},$hash, $paging_nav);
6111         git_print_header_div('commit', esc_html($co{'title'}), $hash);
6112         if ($page == 0 && !@commitlist) {
6113                 print "<p>No match.</p>\n";
6114         } else {
6115                 git_search_grep_body(\@commitlist, 0, 99, $next_link);
6116         }
6117
6118         git_footer_html();
6119 }
6120
6121 sub git_search_changes {
6122         my %co = @_;
6123
6124         local $/ = "\n";
6125         open my $fd, '-|', git_cmd(), '--no-pager', 'log', @diff_opts,
6126                 '--pretty=format:%H', '--no-abbrev', '--raw', "-S$searchtext",
6127                 ($search_use_regexp ? '--pickaxe-regex' : ())
6128                         or die_error(500, "Open git-log failed");
6129
6130         git_header_html();
6131
6132         git_print_page_nav('','', $hash,$co{'tree'},$hash);
6133         git_print_header_div('commit', esc_html($co{'title'}), $hash);
6134
6135         print "<table class=\"pickaxe search\">\n";
6136         my $alternate = 1;
6137         undef %co;
6138         my @files;
6139         while (my $line = <$fd>) {
6140                 chomp $line;
6141                 next unless $line;
6142
6143                 my %set = parse_difftree_raw_line($line);
6144                 if (defined $set{'commit'}) {
6145                         # finish previous commit
6146                         if (%co) {
6147                                 print "</td>\n" .
6148                                       "<td class=\"link\">" .
6149                                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
6150                                               "commit") .
6151                                       " | " .
6152                                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
6153                                                              hash_base=>$co{'id'})},
6154                                               "tree") .
6155                                       "</td>\n" .
6156                                       "</tr>\n";
6157                         }
6158
6159                         if ($alternate) {
6160                                 print "<tr class=\"dark\">\n";
6161                         } else {
6162                                 print "<tr class=\"light\">\n";
6163                         }
6164                         $alternate ^= 1;
6165                         %co = parse_commit($set{'commit'});
6166                         my $author = chop_and_escape_str($co{'author_name'}, 15, 5);
6167                         print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6168                               "<td><i>$author</i></td>\n" .
6169                               "<td>" .
6170                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
6171                                       -class => "list subject"},
6172                                       chop_and_escape_str($co{'title'}, 50) . "<br/>");
6173                 } elsif (defined $set{'to_id'}) {
6174                         next if ($set{'to_id'} =~ m/^0{40}$/);
6175
6176                         print $cgi->a({-href => href(action=>"blob", hash_base=>$co{'id'},
6177                                                      hash=>$set{'to_id'}, file_name=>$set{'to_file'}),
6178                                       -class => "list"},
6179                                       "<span class=\"match\">" . esc_path($set{'file'}) . "</span>") .
6180                               "<br/>\n";
6181                 }
6182         }
6183         close $fd;
6184
6185         # finish last commit (warning: repetition!)
6186         if (%co) {
6187                 print "</td>\n" .
6188                       "<td class=\"link\">" .
6189                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
6190                               "commit") .
6191                       " | " .
6192                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
6193                                              hash_base=>$co{'id'})},
6194                               "tree") .
6195                       "</td>\n" .
6196                       "</tr>\n";
6197         }
6198
6199         print "</table>\n";
6200
6201         git_footer_html();
6202 }
6203
6204 sub git_search_files {
6205         my %co = @_;
6206
6207         local $/ = "\n";
6208         open my $fd, "-|", git_cmd(), 'grep', '-n', '-z',
6209                 $search_use_regexp ? ('-E', '-i') : '-F',
6210                 $searchtext, $co{'tree'}
6211                         or die_error(500, "Open git-grep failed");
6212
6213         git_header_html();
6214
6215         git_print_page_nav('','', $hash,$co{'tree'},$hash);
6216         git_print_header_div('commit', esc_html($co{'title'}), $hash);
6217
6218         print "<table class=\"grep_search\">\n";
6219         my $alternate = 1;
6220         my $matches = 0;
6221         my $lastfile = '';
6222         my $file_href;
6223         while (my $line = <$fd>) {
6224                 chomp $line;
6225                 my ($file, $lno, $ltext, $binary);
6226                 last if ($matches++ > 1000);
6227                 if ($line =~ /^Binary file (.+) matches$/) {
6228                         $file = $1;
6229                         $binary = 1;
6230                 } else {
6231                         ($file, $lno, $ltext) = split(/\0/, $line, 3);
6232                         $file =~ s/^$co{'tree'}://;
6233                 }
6234                 if ($file ne $lastfile) {
6235                         $lastfile and print "</td></tr>\n";
6236                         if ($alternate++) {
6237                                 print "<tr class=\"dark\">\n";
6238                         } else {
6239                                 print "<tr class=\"light\">\n";
6240                         }
6241                         $file_href = href(action=>"blob", hash_base=>$co{'id'},
6242                                           file_name=>$file);
6243                         print "<td class=\"list\">".
6244                                 $cgi->a({-href => $file_href, -class => "list"}, esc_path($file));
6245                         print "</td><td>\n";
6246                         $lastfile = $file;
6247                 }
6248                 if ($binary) {
6249                         print "<div class=\"binary\">Binary file</div>\n";
6250                 } else {
6251                         $ltext = untabify($ltext);
6252                         if ($ltext =~ m/^(.*)($search_regexp)(.*)$/i) {
6253                                 $ltext = esc_html($1, -nbsp=>1);
6254                                 $ltext .= '<span class="match">';
6255                                 $ltext .= esc_html($2, -nbsp=>1);
6256                                 $ltext .= '</span>';
6257                                 $ltext .= esc_html($3, -nbsp=>1);
6258                         } else {
6259                                 $ltext = esc_html($ltext, -nbsp=>1);
6260                         }
6261                         print "<div class=\"pre\">" .
6262                                 $cgi->a({-href => $file_href.'#l'.$lno,
6263                                         -class => "linenr"}, sprintf('%4i', $lno)) .
6264                                 ' ' .  $ltext . "</div>\n";
6265                 }
6266         }
6267         if ($lastfile) {
6268                 print "</td></tr>\n";
6269                 if ($matches > 1000) {
6270                         print "<div class=\"diff nodifferences\">Too many matches, listing trimmed</div>\n";
6271                 }
6272         } else {
6273                 print "<div class=\"diff nodifferences\">No matches found</div>\n";
6274         }
6275         close $fd;
6276
6277         print "</table>\n";
6278
6279         git_footer_html();
6280 }
6281
6282 sub git_search_grep_body {
6283         my ($commitlist, $from, $to, $extra) = @_;
6284         $from = 0 unless defined $from;
6285         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
6286
6287         print "<table class=\"commit_search\">\n";
6288         my $alternate = 1;
6289         for (my $i = $from; $i <= $to; $i++) {
6290                 my %co = %{$commitlist->[$i]};
6291                 if (!%co) {
6292                         next;
6293                 }
6294                 my $commit = $co{'id'};
6295                 if ($alternate) {
6296                         print "<tr class=\"dark\">\n";
6297                 } else {
6298                         print "<tr class=\"light\">\n";
6299                 }
6300                 $alternate ^= 1;
6301                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6302                       format_author_html('td', \%co, 15, 5) .
6303                       "<td>" .
6304                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
6305                                -class => "list subject"},
6306                               chop_and_escape_str($co{'title'}, 50) . "<br/>");
6307                 my $comment = $co{'comment'};
6308                 foreach my $line (@$comment) {
6309                         if ($line =~ m/^(.*?)($search_regexp)(.*)$/i) {
6310                                 my ($lead, $match, $trail) = ($1, $2, $3);
6311                                 $match = chop_str($match, 70, 5, 'center');
6312                                 my $contextlen = int((80 - length($match))/2);
6313                                 $contextlen = 30 if ($contextlen > 30);
6314                                 $lead  = chop_str($lead,  $contextlen, 10, 'left');
6315                                 $trail = chop_str($trail, $contextlen, 10, 'right');
6316
6317                                 $lead  = esc_html($lead);
6318                                 $match = esc_html($match);
6319                                 $trail = esc_html($trail);
6320
6321                                 print "$lead<span class=\"match\">$match</span>$trail<br />";
6322                         }
6323                 }
6324                 print "</td>\n" .
6325                       "<td class=\"link\">" .
6326                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
6327                       " | " .
6328                       $cgi->a({-href => href(action=>"commitdiff", hash=>$co{'id'})}, "commitdiff") .
6329                       " | " .
6330                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
6331                 print "</td>\n" .
6332                       "</tr>\n";
6333         }
6334         if (defined $extra) {
6335                 print "<tr>\n" .
6336                       "<td colspan=\"3\">$extra</td>\n" .
6337                       "</tr>\n";
6338         }
6339         print "</table>\n";
6340 }
6341
6342 ## ======================================================================
6343 ## ======================================================================
6344 ## actions
6345
6346 sub git_project_list {
6347         my $order = $input_params{'order'};
6348         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
6349                 die_error(400, "Unknown order parameter");
6350         }
6351
6352         my @list = git_get_projects_list($project_filter, $strict_export);
6353         if (!@list) {
6354                 die_error(404, "No projects found");
6355         }
6356
6357         git_header_html();
6358         if (defined $home_text && -f $home_text) {
6359                 print "<div class=\"index_include\">\n";
6360                 insert_file($home_text);
6361                 print "</div>\n";
6362         }
6363
6364         git_project_search_form($searchtext, $search_use_regexp);
6365         git_project_list_body(\@list, $order);
6366         git_footer_html();
6367 }
6368
6369 sub git_forks {
6370         my $order = $input_params{'order'};
6371         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
6372                 die_error(400, "Unknown order parameter");
6373         }
6374
6375         my $filter = $project;
6376         $filter =~ s/\.git$//;
6377         my @list = git_get_projects_list($filter);
6378         if (!@list) {
6379                 die_error(404, "No forks found");
6380         }
6381
6382         git_header_html();
6383         git_print_page_nav('','');
6384         git_print_header_div('summary', "$project forks");
6385         git_project_list_body(\@list, $order);
6386         git_footer_html();
6387 }
6388
6389 sub git_project_index {
6390         my @projects = git_get_projects_list($project_filter, $strict_export);
6391         if (!@projects) {
6392                 die_error(404, "No projects found");
6393         }
6394
6395         print $cgi->header(
6396                 -type => 'text/plain',
6397                 -charset => 'utf-8',
6398                 -content_disposition => 'inline; filename="index.aux"');
6399
6400         foreach my $pr (@projects) {
6401                 if (!exists $pr->{'owner'}) {
6402                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}");
6403                 }
6404
6405                 my ($path, $owner) = ($pr->{'path'}, $pr->{'owner'});
6406                 # quote as in CGI::Util::encode, but keep the slash, and use '+' for ' '
6407                 $path  =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
6408                 $owner =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
6409                 $path  =~ s/ /\+/g;
6410                 $owner =~ s/ /\+/g;
6411
6412                 print "$path $owner\n";
6413         }
6414 }
6415
6416 sub git_summary {
6417         my $descr = git_get_project_description($project) || "none";
6418         my %co = parse_commit("HEAD");
6419         my %cd = %co ? parse_date($co{'committer_epoch'}, $co{'committer_tz'}) : ();
6420         my $head = $co{'id'};
6421         my $remote_heads = gitweb_check_feature('remote_heads');
6422
6423         my $owner = git_get_project_owner($project);
6424
6425         my $refs = git_get_references();
6426         # These get_*_list functions return one more to allow us to see if
6427         # there are more ...
6428         my @taglist  = git_get_tags_list(16);
6429         my @headlist = git_get_heads_list(16);
6430         my %remotedata = $remote_heads ? git_get_remotes_list() : ();
6431         my @forklist;
6432         my $check_forks = gitweb_check_feature('forks');
6433
6434         if ($check_forks) {
6435                 # find forks of a project
6436                 my $filter = $project;
6437                 $filter =~ s/\.git$//;
6438                 @forklist = git_get_projects_list($filter);
6439                 # filter out forks of forks
6440                 @forklist = filter_forks_from_projects_list(\@forklist)
6441                         if (@forklist);
6442         }
6443
6444         git_header_html();
6445         git_print_page_nav('summary','', $head);
6446
6447         print "<div class=\"title\">&nbsp;</div>\n";
6448         print "<table class=\"projects_list\">\n" .
6449               "<tr id=\"metadata_desc\"><td>description</td><td>" . esc_html($descr) . "</td></tr>\n";
6450         unless ($omit_owner) {
6451                 print  "<tr id=\"metadata_owner\"><td>owner</td><td>" . esc_html($owner) . "</td></tr>\n";
6452         }
6453         if (defined $cd{'rfc2822'}) {
6454                 print "<tr id=\"metadata_lchange\"><td>last change</td>" .
6455                       "<td>".format_timestamp_html(\%cd)."</td></tr>\n";
6456         }
6457
6458         # use per project git URL list in $projectroot/$project/cloneurl
6459         # or make project git URL from git base URL and project name
6460         my $url_tag = "URL";
6461         my @url_list = git_get_project_url_list($project);
6462         @url_list = map { "$_/$project" } @git_base_url_list unless @url_list;
6463         foreach my $git_url (@url_list) {
6464                 next unless $git_url;
6465                 print format_repo_url($url_tag, $git_url);
6466                 $url_tag = "";
6467         }
6468
6469         # Tag cloud
6470         my $show_ctags = gitweb_check_feature('ctags');
6471         if ($show_ctags) {
6472                 my $ctags = git_get_project_ctags($project);
6473                 if (%$ctags) {
6474                         # without ability to add tags, don't show if there are none
6475                         my $cloud = git_populate_project_tagcloud($ctags);
6476                         print "<tr id=\"metadata_ctags\">" .
6477                               "<td>content tags</td>" .
6478                               "<td>".git_show_project_tagcloud($cloud, 48)."</td>" .
6479                               "</tr>\n";
6480                 }
6481         }
6482
6483         print "</table>\n";
6484
6485         # If XSS prevention is on, we don't include README.html.
6486         # TODO: Allow a readme in some safe format.
6487         if (!$prevent_xss && -s "$projectroot/$project/README.html") {
6488                 print "<div class=\"title\">readme</div>\n" .
6489                       "<div class=\"readme\">\n";
6490                 insert_file("$projectroot/$project/README.html");
6491                 print "\n</div>\n"; # class="readme"
6492         }
6493
6494         # we need to request one more than 16 (0..15) to check if
6495         # those 16 are all
6496         my @commitlist = $head ? parse_commits($head, 17) : ();
6497         if (@commitlist) {
6498                 git_print_header_div('shortlog');
6499                 git_shortlog_body(\@commitlist, 0, 15, $refs,
6500                                   $#commitlist <=  15 ? undef :
6501                                   $cgi->a({-href => href(action=>"shortlog")}, "..."));
6502         }
6503
6504         if (@taglist) {
6505                 git_print_header_div('tags');
6506                 git_tags_body(\@taglist, 0, 15,
6507                               $#taglist <=  15 ? undef :
6508                               $cgi->a({-href => href(action=>"tags")}, "..."));
6509         }
6510
6511         if (@headlist) {
6512                 git_print_header_div('heads');
6513                 git_heads_body(\@headlist, $head, 0, 15,
6514                                $#headlist <= 15 ? undef :
6515                                $cgi->a({-href => href(action=>"heads")}, "..."));
6516         }
6517
6518         if (%remotedata) {
6519                 git_print_header_div('remotes');
6520                 git_remotes_body(\%remotedata, 15, $head);
6521         }
6522
6523         if (@forklist) {
6524                 git_print_header_div('forks');
6525                 git_project_list_body(\@forklist, 'age', 0, 15,
6526                                       $#forklist <= 15 ? undef :
6527                                       $cgi->a({-href => href(action=>"forks")}, "..."),
6528                                       'no_header');
6529         }
6530
6531         git_footer_html();
6532 }
6533
6534 sub git_tag {
6535         my %tag = parse_tag($hash);
6536
6537         if (! %tag) {
6538                 die_error(404, "Unknown tag object");
6539         }
6540
6541         my $head = git_get_head_hash($project);
6542         git_header_html();
6543         git_print_page_nav('','', $head,undef,$head);
6544         git_print_header_div('commit', esc_html($tag{'name'}), $hash);
6545         print "<div class=\"title_text\">\n" .
6546               "<table class=\"object_header\">\n" .
6547               "<tr>\n" .
6548               "<td>object</td>\n" .
6549               "<td>" . $cgi->a({-class => "list", -href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6550                                $tag{'object'}) . "</td>\n" .
6551               "<td class=\"link\">" . $cgi->a({-href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6552                                               $tag{'type'}) . "</td>\n" .
6553               "</tr>\n";
6554         if (defined($tag{'author'})) {
6555                 git_print_authorship_rows(\%tag, 'author');
6556         }
6557         print "</table>\n\n" .
6558               "</div>\n";
6559         print "<div class=\"page_body\">";
6560         my $comment = $tag{'comment'};
6561         foreach my $line (@$comment) {
6562                 chomp $line;
6563                 print esc_html($line, -nbsp=>1) . "<br/>\n";
6564         }
6565         print "</div>\n";
6566         git_footer_html();
6567 }
6568
6569 sub git_blame_common {
6570         my $format = shift || 'porcelain';
6571         if ($format eq 'porcelain' && $input_params{'javascript'}) {
6572                 $format = 'incremental';
6573                 $action = 'blame_incremental'; # for page title etc
6574         }
6575
6576         # permissions
6577         gitweb_check_feature('blame')
6578                 or die_error(403, "Blame view not allowed");
6579
6580         # error checking
6581         die_error(400, "No file name given") unless $file_name;
6582         $hash_base ||= git_get_head_hash($project);
6583         die_error(404, "Couldn't find base commit") unless $hash_base;
6584         my %co = parse_commit($hash_base)
6585                 or die_error(404, "Commit not found");
6586         my $ftype = "blob";
6587         if (!defined $hash) {
6588                 $hash = git_get_hash_by_path($hash_base, $file_name, "blob")
6589                         or die_error(404, "Error looking up file");
6590         } else {
6591                 $ftype = git_get_type($hash);
6592                 if ($ftype !~ "blob") {
6593                         die_error(400, "Object is not a blob");
6594                 }
6595         }
6596
6597         my $fd;
6598         if ($format eq 'incremental') {
6599                 # get file contents (as base)
6600                 open $fd, "-|", git_cmd(), 'cat-file', 'blob', $hash
6601                         or die_error(500, "Open git-cat-file failed");
6602         } elsif ($format eq 'data') {
6603                 # run git-blame --incremental
6604                 open $fd, "-|", git_cmd(), "blame", "--incremental",
6605                         $hash_base, "--", $file_name
6606                         or die_error(500, "Open git-blame --incremental failed");
6607         } else {
6608                 # run git-blame --porcelain
6609                 open $fd, "-|", git_cmd(), "blame", '-p',
6610                         $hash_base, '--', $file_name
6611                         or die_error(500, "Open git-blame --porcelain failed");
6612         }
6613
6614         # incremental blame data returns early
6615         if ($format eq 'data') {
6616                 print $cgi->header(
6617                         -type=>"text/plain", -charset => "utf-8",
6618                         -status=> "200 OK");
6619                 local $| = 1; # output autoflush
6620                 while (my $line = <$fd>) {
6621                         print to_utf8($line);
6622                 }
6623                 close $fd
6624                         or print "ERROR $!\n";
6625
6626                 print 'END';
6627                 if (defined $t0 && gitweb_check_feature('timed')) {
6628                         print ' '.
6629                               tv_interval($t0, [ gettimeofday() ]).
6630                               ' '.$number_of_git_cmds;
6631                 }
6632                 print "\n";
6633
6634                 return;
6635         }
6636
6637         # page header
6638         git_header_html();
6639         my $formats_nav =
6640                 $cgi->a({-href => href(action=>"blob", -replay=>1)},
6641                         "blob") .
6642                 " | ";
6643         if ($format eq 'incremental') {
6644                 $formats_nav .=
6645                         $cgi->a({-href => href(action=>"blame", javascript=>0, -replay=>1)},
6646                                 "blame") . " (non-incremental)";
6647         } else {
6648                 $formats_nav .=
6649                         $cgi->a({-href => href(action=>"blame_incremental", -replay=>1)},
6650                                 "blame") . " (incremental)";
6651         }
6652         $formats_nav .=
6653                 " | " .
6654                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6655                         "history") .
6656                 " | " .
6657                 $cgi->a({-href => href(action=>$action, file_name=>$file_name)},
6658                         "HEAD");
6659         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6660         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6661         git_print_page_path($file_name, $ftype, $hash_base);
6662
6663         # page body
6664         if ($format eq 'incremental') {
6665                 print "<noscript>\n<div class=\"error\"><center><b>\n".
6666                       "This page requires JavaScript to run.\n Use ".
6667                       $cgi->a({-href => href(action=>'blame',javascript=>0,-replay=>1)},
6668                               'this page').
6669                       " instead.\n".
6670                       "</b></center></div>\n</noscript>\n";
6671
6672                 print qq!<div id="progress_bar" style="width: 100%; background-color: yellow"></div>\n!;
6673         }
6674
6675         print qq!<div class="page_body">\n!;
6676         print qq!<div id="progress_info">... / ...</div>\n!
6677                 if ($format eq 'incremental');
6678         print qq!<table id="blame_table" class="blame" width="100%">\n!.
6679               #qq!<col width="5.5em" /><col width="2.5em" /><col width="*" />\n!.
6680               qq!<thead>\n!.
6681               qq!<tr><th>Commit</th><th>Line</th><th>Data</th></tr>\n!.
6682               qq!</thead>\n!.
6683               qq!<tbody>\n!;
6684
6685         my @rev_color = qw(light dark);
6686         my $num_colors = scalar(@rev_color);
6687         my $current_color = 0;
6688
6689         if ($format eq 'incremental') {
6690                 my $color_class = $rev_color[$current_color];
6691
6692                 #contents of a file
6693                 my $linenr = 0;
6694         LINE:
6695                 while (my $line = <$fd>) {
6696                         chomp $line;
6697                         $linenr++;
6698
6699                         print qq!<tr id="l$linenr" class="$color_class">!.
6700                               qq!<td class="sha1"><a href=""> </a></td>!.
6701                               qq!<td class="linenr">!.
6702                               qq!<a class="linenr" href="">$linenr</a></td>!;
6703                         print qq!<td class="pre">! . esc_html($line) . "</td>\n";
6704                         print qq!</tr>\n!;
6705                 }
6706
6707         } else { # porcelain, i.e. ordinary blame
6708                 my %metainfo = (); # saves information about commits
6709
6710                 # blame data
6711         LINE:
6712                 while (my $line = <$fd>) {
6713                         chomp $line;
6714                         # the header: <SHA-1> <src lineno> <dst lineno> [<lines in group>]
6715                         # no <lines in group> for subsequent lines in group of lines
6716                         my ($full_rev, $orig_lineno, $lineno, $group_size) =
6717                            ($line =~ /^([0-9a-f]{40}) (\d+) (\d+)(?: (\d+))?$/);
6718                         if (!exists $metainfo{$full_rev}) {
6719                                 $metainfo{$full_rev} = { 'nprevious' => 0 };
6720                         }
6721                         my $meta = $metainfo{$full_rev};
6722                         my $data;
6723                         while ($data = <$fd>) {
6724                                 chomp $data;
6725                                 last if ($data =~ s/^\t//); # contents of line
6726                                 if ($data =~ /^(\S+)(?: (.*))?$/) {
6727                                         $meta->{$1} = $2 unless exists $meta->{$1};
6728                                 }
6729                                 if ($data =~ /^previous /) {
6730                                         $meta->{'nprevious'}++;
6731                                 }
6732                         }
6733                         my $short_rev = substr($full_rev, 0, 8);
6734                         my $author = $meta->{'author'};
6735                         my %date =
6736                                 parse_date($meta->{'author-time'}, $meta->{'author-tz'});
6737                         my $date = $date{'iso-tz'};
6738                         if ($group_size) {
6739                                 $current_color = ($current_color + 1) % $num_colors;
6740                         }
6741                         my $tr_class = $rev_color[$current_color];
6742                         $tr_class .= ' boundary' if (exists $meta->{'boundary'});
6743                         $tr_class .= ' no-previous' if ($meta->{'nprevious'} == 0);
6744                         $tr_class .= ' multiple-previous' if ($meta->{'nprevious'} > 1);
6745                         print "<tr id=\"l$lineno\" class=\"$tr_class\">\n";
6746                         if ($group_size) {
6747                                 print "<td class=\"sha1\"";
6748                                 print " title=\"". esc_html($author) . ", $date\"";
6749                                 print " rowspan=\"$group_size\"" if ($group_size > 1);
6750                                 print ">";
6751                                 print $cgi->a({-href => href(action=>"commit",
6752                                                              hash=>$full_rev,
6753                                                              file_name=>$file_name)},
6754                                               esc_html($short_rev));
6755                                 if ($group_size >= 2) {
6756                                         my @author_initials = ($author =~ /\b([[:upper:]])\B/g);
6757                                         if (@author_initials) {
6758                                                 print "<br />" .
6759                                                       esc_html(join('', @author_initials));
6760                                                 #           or join('.', ...)
6761                                         }
6762                                 }
6763                                 print "</td>\n";
6764                         }
6765                         # 'previous' <sha1 of parent commit> <filename at commit>
6766                         if (exists $meta->{'previous'} &&
6767                             $meta->{'previous'} =~ /^([a-fA-F0-9]{40}) (.*)$/) {
6768                                 $meta->{'parent'} = $1;
6769                                 $meta->{'file_parent'} = unquote($2);
6770                         }
6771                         my $linenr_commit =
6772                                 exists($meta->{'parent'}) ?
6773                                 $meta->{'parent'} : $full_rev;
6774                         my $linenr_filename =
6775                                 exists($meta->{'file_parent'}) ?
6776                                 $meta->{'file_parent'} : unquote($meta->{'filename'});
6777                         my $blamed = href(action => 'blame',
6778                                           file_name => $linenr_filename,
6779                                           hash_base => $linenr_commit);
6780                         print "<td class=\"linenr\">";
6781                         print $cgi->a({ -href => "$blamed#l$orig_lineno",
6782                                         -class => "linenr" },
6783                                       esc_html($lineno));
6784                         print "</td>";
6785                         print "<td class=\"pre\">" . esc_html($data) . "</td>\n";
6786                         print "</tr>\n";
6787                 } # end while
6788
6789         }
6790
6791         # footer
6792         print "</tbody>\n".
6793               "</table>\n"; # class="blame"
6794         print "</div>\n";   # class="blame_body"
6795         close $fd
6796                 or print "Reading blob failed\n";
6797
6798         git_footer_html();
6799 }
6800
6801 sub git_blame {
6802         git_blame_common();
6803 }
6804
6805 sub git_blame_incremental {
6806         git_blame_common('incremental');
6807 }
6808
6809 sub git_blame_data {
6810         git_blame_common('data');
6811 }
6812
6813 sub git_tags {
6814         my $head = git_get_head_hash($project);
6815         git_header_html();
6816         git_print_page_nav('','', $head,undef,$head,format_ref_views('tags'));
6817         git_print_header_div('summary', $project);
6818
6819         my @tagslist = git_get_tags_list();
6820         if (@tagslist) {
6821                 git_tags_body(\@tagslist);
6822         }
6823         git_footer_html();
6824 }
6825
6826 sub git_heads {
6827         my $head = git_get_head_hash($project);
6828         git_header_html();
6829         git_print_page_nav('','', $head,undef,$head,format_ref_views('heads'));
6830         git_print_header_div('summary', $project);
6831
6832         my @headslist = git_get_heads_list();
6833         if (@headslist) {
6834                 git_heads_body(\@headslist, $head);
6835         }
6836         git_footer_html();
6837 }
6838
6839 # used both for single remote view and for list of all the remotes
6840 sub git_remotes {
6841         gitweb_check_feature('remote_heads')
6842                 or die_error(403, "Remote heads view is disabled");
6843
6844         my $head = git_get_head_hash($project);
6845         my $remote = $input_params{'hash'};
6846
6847         my $remotedata = git_get_remotes_list($remote);
6848         die_error(500, "Unable to get remote information") unless defined $remotedata;
6849
6850         unless (%$remotedata) {
6851                 die_error(404, defined $remote ?
6852                         "Remote $remote not found" :
6853                         "No remotes found");
6854         }
6855
6856         git_header_html(undef, undef, -action_extra => $remote);
6857         git_print_page_nav('', '',  $head, undef, $head,
6858                 format_ref_views($remote ? '' : 'remotes'));
6859
6860         fill_remote_heads($remotedata);
6861         if (defined $remote) {
6862                 git_print_header_div('remotes', "$remote remote for $project");
6863                 git_remote_block($remote, $remotedata->{$remote}, undef, $head);
6864         } else {
6865                 git_print_header_div('summary', "$project remotes");
6866                 git_remotes_body($remotedata, undef, $head);
6867         }
6868
6869         git_footer_html();
6870 }
6871
6872 sub git_blob_plain {
6873         my $type = shift;
6874         my $expires;
6875
6876         if (!defined $hash) {
6877                 if (defined $file_name) {
6878                         my $base = $hash_base || git_get_head_hash($project);
6879                         $hash = git_get_hash_by_path($base, $file_name, "blob")
6880                                 or die_error(404, "Cannot find file");
6881                 } else {
6882                         die_error(400, "No file name defined");
6883                 }
6884         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6885                 # blobs defined by non-textual hash id's can be cached
6886                 $expires = "+1d";
6887         }
6888
6889         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
6890                 or die_error(500, "Open git-cat-file blob '$hash' failed");
6891
6892         # content-type (can include charset)
6893         $type = blob_contenttype($fd, $file_name, $type);
6894
6895         # "save as" filename, even when no $file_name is given
6896         my $save_as = "$hash";
6897         if (defined $file_name) {
6898                 $save_as = $file_name;
6899         } elsif ($type =~ m/^text\//) {
6900                 $save_as .= '.txt';
6901         }
6902
6903         # With XSS prevention on, blobs of all types except a few known safe
6904         # ones are served with "Content-Disposition: attachment" to make sure
6905         # they don't run in our security domain.  For certain image types,
6906         # blob view writes an <img> tag referring to blob_plain view, and we
6907         # want to be sure not to break that by serving the image as an
6908         # attachment (though Firefox 3 doesn't seem to care).
6909         my $sandbox = $prevent_xss &&
6910                 $type !~ m!^(?:text/[a-z]+|image/(?:gif|png|jpeg))(?:[ ;]|$)!;
6911
6912         # serve text/* as text/plain
6913         if ($prevent_xss &&
6914             ($type =~ m!^text/[a-z]+\b(.*)$! ||
6915              ($type =~ m!^[a-z]+/[a-z]\+xml\b(.*)$! && -T $fd))) {
6916                 my $rest = $1;
6917                 $rest = defined $rest ? $rest : '';
6918                 $type = "text/plain$rest";
6919         }
6920
6921         print $cgi->header(
6922                 -type => $type,
6923                 -expires => $expires,
6924                 -content_disposition =>
6925                         ($sandbox ? 'attachment' : 'inline')
6926                         . '; filename="' . $save_as . '"');
6927         local $/ = undef;
6928         binmode STDOUT, ':raw';
6929         print <$fd>;
6930         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
6931         close $fd;
6932 }
6933
6934 sub git_blob {
6935         my $expires;
6936
6937         if (!defined $hash) {
6938                 if (defined $file_name) {
6939                         my $base = $hash_base || git_get_head_hash($project);
6940                         $hash = git_get_hash_by_path($base, $file_name, "blob")
6941                                 or die_error(404, "Cannot find file");
6942                 } else {
6943                         die_error(400, "No file name defined");
6944                 }
6945         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6946                 # blobs defined by non-textual hash id's can be cached
6947                 $expires = "+1d";
6948         }
6949
6950         my $have_blame = gitweb_check_feature('blame');
6951         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
6952                 or die_error(500, "Couldn't cat $file_name, $hash");
6953         my $mimetype = blob_mimetype($fd, $file_name);
6954         # use 'blob_plain' (aka 'raw') view for files that cannot be displayed
6955         if ($mimetype !~ m!^(?:text/|image/(?:gif|png|jpeg)$)! && -B $fd) {
6956                 close $fd;
6957                 return git_blob_plain($mimetype);
6958         }
6959         # we can have blame only for text/* mimetype
6960         $have_blame &&= ($mimetype =~ m!^text/!);
6961
6962         my $highlight = gitweb_check_feature('highlight');
6963         my $syntax = guess_file_syntax($highlight, $mimetype, $file_name);
6964         $fd = run_highlighter($fd, $highlight, $syntax)
6965                 if $syntax;
6966
6967         git_header_html(undef, $expires);
6968         my $formats_nav = '';
6969         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
6970                 if (defined $file_name) {
6971                         if ($have_blame) {
6972                                 $formats_nav .=
6973                                         $cgi->a({-href => href(action=>"blame", -replay=>1)},
6974                                                 "blame") .
6975                                         " | ";
6976                         }
6977                         $formats_nav .=
6978                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6979                                         "history") .
6980                                 " | " .
6981                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
6982                                         "raw") .
6983                                 " | " .
6984                                 $cgi->a({-href => href(action=>"blob",
6985                                                        hash_base=>"HEAD", file_name=>$file_name)},
6986                                         "HEAD");
6987                 } else {
6988                         $formats_nav .=
6989                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
6990                                         "raw");
6991                 }
6992                 git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6993                 git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6994         } else {
6995                 print "<div class=\"page_nav\">\n" .
6996                       "<br/><br/></div>\n" .
6997                       "<div class=\"title\">".esc_html($hash)."</div>\n";
6998         }
6999         git_print_page_path($file_name, "blob", $hash_base);
7000         print "<div class=\"page_body\">\n";
7001         if ($mimetype =~ m!^image/!) {
7002                 print qq!<img type="!.esc_attr($mimetype).qq!"!;
7003                 if ($file_name) {
7004                         print qq! alt="!.esc_attr($file_name).qq!" title="!.esc_attr($file_name).qq!"!;
7005                 }
7006                 print qq! src="! .
7007                       href(action=>"blob_plain", hash=>$hash,
7008                            hash_base=>$hash_base, file_name=>$file_name) .
7009                       qq!" />\n!;
7010         } else {
7011                 my $nr;
7012                 while (my $line = <$fd>) {
7013                         chomp $line;
7014                         $nr++;
7015                         $line = untabify($line);
7016                         printf qq!<div class="pre"><a id="l%i" href="%s#l%i" class="linenr">%4i</a> %s</div>\n!,
7017                                $nr, esc_attr(href(-replay => 1)), $nr, $nr,
7018                                $syntax ? sanitize($line) : esc_html($line, -nbsp=>1);
7019                 }
7020         }
7021         close $fd
7022                 or print "Reading blob failed.\n";
7023         print "</div>";
7024         git_footer_html();
7025 }
7026
7027 sub git_tree {
7028         if (!defined $hash_base) {
7029                 $hash_base = "HEAD";
7030         }
7031         if (!defined $hash) {
7032                 if (defined $file_name) {
7033                         $hash = git_get_hash_by_path($hash_base, $file_name, "tree");
7034                 } else {
7035                         $hash = $hash_base;
7036                 }
7037         }
7038         die_error(404, "No such tree") unless defined($hash);
7039
7040         my $show_sizes = gitweb_check_feature('show-sizes');
7041         my $have_blame = gitweb_check_feature('blame');
7042
7043         my @entries = ();
7044         {
7045                 local $/ = "\0";
7046                 open my $fd, "-|", git_cmd(), "ls-tree", '-z',
7047                         ($show_sizes ? '-l' : ()), @extra_options, $hash
7048                         or die_error(500, "Open git-ls-tree failed");
7049                 @entries = map { chomp; $_ } <$fd>;
7050                 close $fd
7051                         or die_error(404, "Reading tree failed");
7052         }
7053
7054         my $refs = git_get_references();
7055         my $ref = format_ref_marker($refs, $hash_base);
7056         git_header_html();
7057         my $basedir = '';
7058         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7059                 my @views_nav = ();
7060                 if (defined $file_name) {
7061                         push @views_nav,
7062                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
7063                                         "history"),
7064                                 $cgi->a({-href => href(action=>"tree",
7065                                                        hash_base=>"HEAD", file_name=>$file_name)},
7066                                         "HEAD"),
7067                 }
7068                 my $snapshot_links = format_snapshot_links($hash);
7069                 if (defined $snapshot_links) {
7070                         # FIXME: Should be available when we have no hash base as well.
7071                         push @views_nav, $snapshot_links;
7072                 }
7073                 git_print_page_nav('tree','', $hash_base, undef, undef,
7074                                    join(' | ', @views_nav));
7075                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash_base);
7076         } else {
7077                 undef $hash_base;
7078                 print "<div class=\"page_nav\">\n";
7079                 print "<br/><br/></div>\n";
7080                 print "<div class=\"title\">".esc_html($hash)."</div>\n";
7081         }
7082         if (defined $file_name) {
7083                 $basedir = $file_name;
7084                 if ($basedir ne '' && substr($basedir, -1) ne '/') {
7085                         $basedir .= '/';
7086                 }
7087                 git_print_page_path($file_name, 'tree', $hash_base);
7088         }
7089         print "<div class=\"page_body\">\n";
7090         print "<table class=\"tree\">\n";
7091         my $alternate = 1;
7092         # '..' (top directory) link if possible
7093         if (defined $hash_base &&
7094             defined $file_name && $file_name =~ m![^/]+$!) {
7095                 if ($alternate) {
7096                         print "<tr class=\"dark\">\n";
7097                 } else {
7098                         print "<tr class=\"light\">\n";
7099                 }
7100                 $alternate ^= 1;
7101
7102                 my $up = $file_name;
7103                 $up =~ s!/?[^/]+$!!;
7104                 undef $up unless $up;
7105                 # based on git_print_tree_entry
7106                 print '<td class="mode">' . mode_str('040000') . "</td>\n";
7107                 print '<td class="size">&nbsp;</td>'."\n" if $show_sizes;
7108                 print '<td class="list">';
7109                 print $cgi->a({-href => href(action=>"tree",
7110                                              hash_base=>$hash_base,
7111                                              file_name=>$up)},
7112                               "..");
7113                 print "</td>\n";
7114                 print "<td class=\"link\"></td>\n";
7115
7116                 print "</tr>\n";
7117         }
7118         foreach my $line (@entries) {
7119                 my %t = parse_ls_tree_line($line, -z => 1, -l => $show_sizes);
7120
7121                 if ($alternate) {
7122                         print "<tr class=\"dark\">\n";
7123                 } else {
7124                         print "<tr class=\"light\">\n";
7125                 }
7126                 $alternate ^= 1;
7127
7128                 git_print_tree_entry(\%t, $basedir, $hash_base, $have_blame);
7129
7130                 print "</tr>\n";
7131         }
7132         print "</table>\n" .
7133               "</div>";
7134         git_footer_html();
7135 }
7136
7137 sub snapshot_name {
7138         my ($project, $hash) = @_;
7139
7140         # path/to/project.git  -> project
7141         # path/to/project/.git -> project
7142         my $name = to_utf8($project);
7143         $name =~ s,([^/])/*\.git$,$1,;
7144         $name = basename($name);
7145         # sanitize name
7146         $name =~ s/[[:cntrl:]]/?/g;
7147
7148         my $ver = $hash;
7149         if ($hash =~ /^[0-9a-fA-F]+$/) {
7150                 # shorten SHA-1 hash
7151                 my $full_hash = git_get_full_hash($project, $hash);
7152                 if ($full_hash =~ /^$hash/ && length($hash) > 7) {
7153                         $ver = git_get_short_hash($project, $hash);
7154                 }
7155         } elsif ($hash =~ m!^refs/tags/(.*)$!) {
7156                 # tags don't need shortened SHA-1 hash
7157                 $ver = $1;
7158         } else {
7159                 # branches and other need shortened SHA-1 hash
7160                 if ($hash =~ m!^refs/(?:heads|remotes)/(.*)$!) {
7161                         $ver = $1;
7162                 }
7163                 $ver .= '-' . git_get_short_hash($project, $hash);
7164         }
7165         # in case of hierarchical branch names
7166         $ver =~ s!/!.!g;
7167
7168         # name = project-version_string
7169         $name = "$name-$ver";
7170
7171         return wantarray ? ($name, $name) : $name;
7172 }
7173
7174 sub exit_if_unmodified_since {
7175         my ($latest_epoch) = @_;
7176         our $cgi;
7177
7178         my $if_modified = $cgi->http('IF_MODIFIED_SINCE');
7179         if (defined $if_modified) {
7180                 my $since;
7181                 if (eval { require HTTP::Date; 1; }) {
7182                         $since = HTTP::Date::str2time($if_modified);
7183                 } elsif (eval { require Time::ParseDate; 1; }) {
7184                         $since = Time::ParseDate::parsedate($if_modified, GMT => 1);
7185                 }
7186                 if (defined $since && $latest_epoch <= $since) {
7187                         my %latest_date = parse_date($latest_epoch);
7188                         print $cgi->header(
7189                                 -last_modified => $latest_date{'rfc2822'},
7190                                 -status => '304 Not Modified');
7191                         goto DONE_GITWEB;
7192                 }
7193         }
7194 }
7195
7196 sub git_snapshot {
7197         my $format = $input_params{'snapshot_format'};
7198         if (!@snapshot_fmts) {
7199                 die_error(403, "Snapshots not allowed");
7200         }
7201         # default to first supported snapshot format
7202         $format ||= $snapshot_fmts[0];
7203         if ($format !~ m/^[a-z0-9]+$/) {
7204                 die_error(400, "Invalid snapshot format parameter");
7205         } elsif (!exists($known_snapshot_formats{$format})) {
7206                 die_error(400, "Unknown snapshot format");
7207         } elsif ($known_snapshot_formats{$format}{'disabled'}) {
7208                 die_error(403, "Snapshot format not allowed");
7209         } elsif (!grep($_ eq $format, @snapshot_fmts)) {
7210                 die_error(403, "Unsupported snapshot format");
7211         }
7212
7213         my $type = git_get_type("$hash^{}");
7214         if (!$type) {
7215                 die_error(404, 'Object does not exist');
7216         }  elsif ($type eq 'blob') {
7217                 die_error(400, 'Object is not a tree-ish');
7218         }
7219
7220         my ($name, $prefix) = snapshot_name($project, $hash);
7221         my $filename = "$name$known_snapshot_formats{$format}{'suffix'}";
7222
7223         my %co = parse_commit($hash);
7224         exit_if_unmodified_since($co{'committer_epoch'}) if %co;
7225
7226         my $cmd = quote_command(
7227                 git_cmd(), 'archive',
7228                 "--format=$known_snapshot_formats{$format}{'format'}",
7229                 "--prefix=$prefix/", $hash);
7230         if (exists $known_snapshot_formats{$format}{'compressor'}) {
7231                 $cmd .= ' | ' . quote_command(@{$known_snapshot_formats{$format}{'compressor'}});
7232         }
7233
7234         $filename =~ s/(["\\])/\\$1/g;
7235         my %latest_date;
7236         if (%co) {
7237                 %latest_date = parse_date($co{'committer_epoch'}, $co{'committer_tz'});
7238         }
7239
7240         print $cgi->header(
7241                 -type => $known_snapshot_formats{$format}{'type'},
7242                 -content_disposition => 'inline; filename="' . $filename . '"',
7243                 %co ? (-last_modified => $latest_date{'rfc2822'}) : (),
7244                 -status => '200 OK');
7245
7246         open my $fd, "-|", $cmd
7247                 or die_error(500, "Execute git-archive failed");
7248         binmode STDOUT, ':raw';
7249         print <$fd>;
7250         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
7251         close $fd;
7252 }
7253
7254 sub git_log_generic {
7255         my ($fmt_name, $body_subr, $base, $parent, $file_name, $file_hash) = @_;
7256
7257         my $head = git_get_head_hash($project);
7258         if (!defined $base) {
7259                 $base = $head;
7260         }
7261         if (!defined $page) {
7262                 $page = 0;
7263         }
7264         my $refs = git_get_references();
7265
7266         my $commit_hash = $base;
7267         if (defined $parent) {
7268                 $commit_hash = "$parent..$base";
7269         }
7270         my @commitlist =
7271                 parse_commits($commit_hash, 101, (100 * $page),
7272                               defined $file_name ? ($file_name, "--full-history") : ());
7273
7274         my $ftype;
7275         if (!defined $file_hash && defined $file_name) {
7276                 # some commits could have deleted file in question,
7277                 # and not have it in tree, but one of them has to have it
7278                 for (my $i = 0; $i < @commitlist; $i++) {
7279                         $file_hash = git_get_hash_by_path($commitlist[$i]{'id'}, $file_name);
7280                         last if defined $file_hash;
7281                 }
7282         }
7283         if (defined $file_hash) {
7284                 $ftype = git_get_type($file_hash);
7285         }
7286         if (defined $file_name && !defined $ftype) {
7287                 die_error(500, "Unknown type of object");
7288         }
7289         my %co;
7290         if (defined $file_name) {
7291                 %co = parse_commit($base)
7292                         or die_error(404, "Unknown commit object");
7293         }
7294
7295
7296         my $paging_nav = format_paging_nav($fmt_name, $page, $#commitlist >= 100);
7297         my $next_link = '';
7298         if ($#commitlist >= 100) {
7299                 $next_link =
7300                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
7301                                  -accesskey => "n", -title => "Alt-n"}, "next");
7302         }
7303         my $patch_max = gitweb_get_feature('patches');
7304         if ($patch_max && !defined $file_name) {
7305                 if ($patch_max < 0 || @commitlist <= $patch_max) {
7306                         $paging_nav .= " &sdot; " .
7307                                 $cgi->a({-href => href(action=>"patches", -replay=>1)},
7308                                         "patches");
7309                 }
7310         }
7311
7312         git_header_html();
7313         git_print_page_nav($fmt_name,'', $hash,$hash,$hash, $paging_nav);
7314         if (defined $file_name) {
7315                 git_print_header_div('commit', esc_html($co{'title'}), $base);
7316         } else {
7317                 git_print_header_div('summary', $project)
7318         }
7319         git_print_page_path($file_name, $ftype, $hash_base)
7320                 if (defined $file_name);
7321
7322         $body_subr->(\@commitlist, 0, 99, $refs, $next_link,
7323                      $file_name, $file_hash, $ftype);
7324
7325         git_footer_html();
7326 }
7327
7328 sub git_log {
7329         git_log_generic('log', \&git_log_body,
7330                         $hash, $hash_parent);
7331 }
7332
7333 sub git_commit {
7334         $hash ||= $hash_base || "HEAD";
7335         my %co = parse_commit($hash)
7336             or die_error(404, "Unknown commit object");
7337
7338         my $parent  = $co{'parent'};
7339         my $parents = $co{'parents'}; # listref
7340
7341         # we need to prepare $formats_nav before any parameter munging
7342         my $formats_nav;
7343         if (!defined $parent) {
7344                 # --root commitdiff
7345                 $formats_nav .= '(initial)';
7346         } elsif (@$parents == 1) {
7347                 # single parent commit
7348                 $formats_nav .=
7349                         '(parent: ' .
7350                         $cgi->a({-href => href(action=>"commit",
7351                                                hash=>$parent)},
7352                                 esc_html(substr($parent, 0, 7))) .
7353                         ')';
7354         } else {
7355                 # merge commit
7356                 $formats_nav .=
7357                         '(merge: ' .
7358                         join(' ', map {
7359                                 $cgi->a({-href => href(action=>"commit",
7360                                                        hash=>$_)},
7361                                         esc_html(substr($_, 0, 7)));
7362                         } @$parents ) .
7363                         ')';
7364         }
7365         if (gitweb_check_feature('patches') && @$parents <= 1) {
7366                 $formats_nav .= " | " .
7367                         $cgi->a({-href => href(action=>"patch", -replay=>1)},
7368                                 "patch");
7369         }
7370
7371         if (!defined $parent) {
7372                 $parent = "--root";
7373         }
7374         my @difftree;
7375         open my $fd, "-|", git_cmd(), "diff-tree", '-r', "--no-commit-id",
7376                 @diff_opts,
7377                 (@$parents <= 1 ? $parent : '-c'),
7378                 $hash, "--"
7379                 or die_error(500, "Open git-diff-tree failed");
7380         @difftree = map { chomp; $_ } <$fd>;
7381         close $fd or die_error(404, "Reading git-diff-tree failed");
7382
7383         # non-textual hash id's can be cached
7384         my $expires;
7385         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7386                 $expires = "+1d";
7387         }
7388         my $refs = git_get_references();
7389         my $ref = format_ref_marker($refs, $co{'id'});
7390
7391         git_header_html(undef, $expires);
7392         git_print_page_nav('commit', '',
7393                            $hash, $co{'tree'}, $hash,
7394                            $formats_nav);
7395
7396         if (defined $co{'parent'}) {
7397                 git_print_header_div('commitdiff', esc_html($co{'title'}) . $ref, $hash);
7398         } else {
7399                 git_print_header_div('tree', esc_html($co{'title'}) . $ref, $co{'tree'}, $hash);
7400         }
7401         print "<div class=\"title_text\">\n" .
7402               "<table class=\"object_header\">\n";
7403         git_print_authorship_rows(\%co);
7404         print "<tr><td>commit</td><td class=\"sha1\">$co{'id'}</td></tr>\n";
7405         print "<tr>" .
7406               "<td>tree</td>" .
7407               "<td class=\"sha1\">" .
7408               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash),
7409                        class => "list"}, $co{'tree'}) .
7410               "</td>" .
7411               "<td class=\"link\">" .
7412               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash)},
7413                       "tree");
7414         my $snapshot_links = format_snapshot_links($hash);
7415         if (defined $snapshot_links) {
7416                 print " | " . $snapshot_links;
7417         }
7418         print "</td>" .
7419               "</tr>\n";
7420
7421         foreach my $par (@$parents) {
7422                 print "<tr>" .
7423                       "<td>parent</td>" .
7424                       "<td class=\"sha1\">" .
7425                       $cgi->a({-href => href(action=>"commit", hash=>$par),
7426                                class => "list"}, $par) .
7427                       "</td>" .
7428                       "<td class=\"link\">" .
7429                       $cgi->a({-href => href(action=>"commit", hash=>$par)}, "commit") .
7430                       " | " .
7431                       $cgi->a({-href => href(action=>"commitdiff", hash=>$hash, hash_parent=>$par)}, "diff") .
7432                       "</td>" .
7433                       "</tr>\n";
7434         }
7435         print "</table>".
7436               "</div>\n";
7437
7438         print "<div class=\"page_body\">\n";
7439         git_print_log($co{'comment'});
7440         print "</div>\n";
7441
7442         git_difftree_body(\@difftree, $hash, @$parents);
7443
7444         git_footer_html();
7445 }
7446
7447 sub git_object {
7448         # object is defined by:
7449         # - hash or hash_base alone
7450         # - hash_base and file_name
7451         my $type;
7452
7453         # - hash or hash_base alone
7454         if ($hash || ($hash_base && !defined $file_name)) {
7455                 my $object_id = $hash || $hash_base;
7456
7457                 open my $fd, "-|", quote_command(
7458                         git_cmd(), 'cat-file', '-t', $object_id) . ' 2> /dev/null'
7459                         or die_error(404, "Object does not exist");
7460                 $type = <$fd>;
7461                 chomp $type;
7462                 close $fd
7463                         or die_error(404, "Object does not exist");
7464
7465         # - hash_base and file_name
7466         } elsif ($hash_base && defined $file_name) {
7467                 $file_name =~ s,/+$,,;
7468
7469                 system(git_cmd(), "cat-file", '-e', $hash_base) == 0
7470                         or die_error(404, "Base object does not exist");
7471
7472                 # here errors should not hapen
7473                 open my $fd, "-|", git_cmd(), "ls-tree", $hash_base, "--", $file_name
7474                         or die_error(500, "Open git-ls-tree failed");
7475                 my $line = <$fd>;
7476                 close $fd;
7477
7478                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
7479                 unless ($line && $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/) {
7480                         die_error(404, "File or directory for given base does not exist");
7481                 }
7482                 $type = $2;
7483                 $hash = $3;
7484         } else {
7485                 die_error(400, "Not enough information to find object");
7486         }
7487
7488         print $cgi->redirect(-uri => href(action=>$type, -full=>1,
7489                                           hash=>$hash, hash_base=>$hash_base,
7490                                           file_name=>$file_name),
7491                              -status => '302 Found');
7492 }
7493
7494 sub git_blobdiff {
7495         my $format = shift || 'html';
7496         my $diff_style = $input_params{'diff_style'} || 'inline';
7497
7498         my $fd;
7499         my @difftree;
7500         my %diffinfo;
7501         my $expires;
7502
7503         # preparing $fd and %diffinfo for git_patchset_body
7504         # new style URI
7505         if (defined $hash_base && defined $hash_parent_base) {
7506                 if (defined $file_name) {
7507                         # read raw output
7508                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7509                                 $hash_parent_base, $hash_base,
7510                                 "--", (defined $file_parent ? $file_parent : ()), $file_name
7511                                 or die_error(500, "Open git-diff-tree failed");
7512                         @difftree = map { chomp; $_ } <$fd>;
7513                         close $fd
7514                                 or die_error(404, "Reading git-diff-tree failed");
7515                         @difftree
7516                                 or die_error(404, "Blob diff not found");
7517
7518                 } elsif (defined $hash &&
7519                          $hash =~ /[0-9a-fA-F]{40}/) {
7520                         # try to find filename from $hash
7521
7522                         # read filtered raw output
7523                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7524                                 $hash_parent_base, $hash_base, "--"
7525                                 or die_error(500, "Open git-diff-tree failed");
7526                         @difftree =
7527                                 # ':100644 100644 03b21826... 3b93d5e7... M     ls-files.c'
7528                                 # $hash == to_id
7529                                 grep { /^:[0-7]{6} [0-7]{6} [0-9a-fA-F]{40} $hash/ }
7530                                 map { chomp; $_ } <$fd>;
7531                         close $fd
7532                                 or die_error(404, "Reading git-diff-tree failed");
7533                         @difftree
7534                                 or die_error(404, "Blob diff not found");
7535
7536                 } else {
7537                         die_error(400, "Missing one of the blob diff parameters");
7538                 }
7539
7540                 if (@difftree > 1) {
7541                         die_error(400, "Ambiguous blob diff specification");
7542                 }
7543
7544                 %diffinfo = parse_difftree_raw_line($difftree[0]);
7545                 $file_parent ||= $diffinfo{'from_file'} || $file_name;
7546                 $file_name   ||= $diffinfo{'to_file'};
7547
7548                 $hash_parent ||= $diffinfo{'from_id'};
7549                 $hash        ||= $diffinfo{'to_id'};
7550
7551                 # non-textual hash id's can be cached
7552                 if ($hash_base =~ m/^[0-9a-fA-F]{40}$/ &&
7553                     $hash_parent_base =~ m/^[0-9a-fA-F]{40}$/) {
7554                         $expires = '+1d';
7555                 }
7556
7557                 # open patch output
7558                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7559                         '-p', ($format eq 'html' ? "--full-index" : ()),
7560                         $hash_parent_base, $hash_base,
7561                         "--", (defined $file_parent ? $file_parent : ()), $file_name
7562                         or die_error(500, "Open git-diff-tree failed");
7563         }
7564
7565         # old/legacy style URI -- not generated anymore since 1.4.3.
7566         if (!%diffinfo) {
7567                 die_error('404 Not Found', "Missing one of the blob diff parameters")
7568         }
7569
7570         # header
7571         if ($format eq 'html') {
7572                 my $formats_nav =
7573                         $cgi->a({-href => href(action=>"blobdiff_plain", -replay=>1)},
7574                                 "raw");
7575                 $formats_nav .= diff_style_nav($diff_style);
7576                 git_header_html(undef, $expires);
7577                 if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7578                         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
7579                         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
7580                 } else {
7581                         print "<div class=\"page_nav\"><br/>$formats_nav<br/></div>\n";
7582                         print "<div class=\"title\">".esc_html("$hash vs $hash_parent")."</div>\n";
7583                 }
7584                 if (defined $file_name) {
7585                         git_print_page_path($file_name, "blob", $hash_base);
7586                 } else {
7587                         print "<div class=\"page_path\"></div>\n";
7588                 }
7589
7590         } elsif ($format eq 'plain') {
7591                 print $cgi->header(
7592                         -type => 'text/plain',
7593                         -charset => 'utf-8',
7594                         -expires => $expires,
7595                         -content_disposition => 'inline; filename="' . "$file_name" . '.patch"');
7596
7597                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7598
7599         } else {
7600                 die_error(400, "Unknown blobdiff format");
7601         }
7602
7603         # patch
7604         if ($format eq 'html') {
7605                 print "<div class=\"page_body\">\n";
7606
7607                 git_patchset_body($fd, $diff_style,
7608                                   [ \%diffinfo ], $hash_base, $hash_parent_base);
7609                 close $fd;
7610
7611                 print "</div>\n"; # class="page_body"
7612                 git_footer_html();
7613
7614         } else {
7615                 while (my $line = <$fd>) {
7616                         $line =~ s!a/($hash|$hash_parent)!'a/'.esc_path($diffinfo{'from_file'})!eg;
7617                         $line =~ s!b/($hash|$hash_parent)!'b/'.esc_path($diffinfo{'to_file'})!eg;
7618
7619                         print $line;
7620
7621                         last if $line =~ m!^\+\+\+!;
7622                 }
7623                 local $/ = undef;
7624                 print <$fd>;
7625                 close $fd;
7626         }
7627 }
7628
7629 sub git_blobdiff_plain {
7630         git_blobdiff('plain');
7631 }
7632
7633 # assumes that it is added as later part of already existing navigation,
7634 # so it returns "| foo | bar" rather than just "foo | bar"
7635 sub diff_style_nav {
7636         my ($diff_style, $is_combined) = @_;
7637         $diff_style ||= 'inline';
7638
7639         return "" if ($is_combined);
7640
7641         my @styles = (inline => 'inline', 'sidebyside' => 'side by side');
7642         my %styles = @styles;
7643         @styles =
7644                 @styles[ map { $_ * 2 } 0..$#styles/2 ];
7645
7646         return join '',
7647                 map { " | ".$_ }
7648                 map {
7649                         $_ eq $diff_style ? $styles{$_} :
7650                         $cgi->a({-href => href(-replay=>1, diff_style => $_)}, $styles{$_})
7651                 } @styles;
7652 }
7653
7654 sub git_commitdiff {
7655         my %params = @_;
7656         my $format = $params{-format} || 'html';
7657         my $diff_style = $input_params{'diff_style'} || 'inline';
7658
7659         my ($patch_max) = gitweb_get_feature('patches');
7660         if ($format eq 'patch') {
7661                 die_error(403, "Patch view not allowed") unless $patch_max;
7662         }
7663
7664         $hash ||= $hash_base || "HEAD";
7665         my %co = parse_commit($hash)
7666             or die_error(404, "Unknown commit object");
7667
7668         # choose format for commitdiff for merge
7669         if (! defined $hash_parent && @{$co{'parents'}} > 1) {
7670                 $hash_parent = '--cc';
7671         }
7672         # we need to prepare $formats_nav before almost any parameter munging
7673         my $formats_nav;
7674         if ($format eq 'html') {
7675                 $formats_nav =
7676                         $cgi->a({-href => href(action=>"commitdiff_plain", -replay=>1)},
7677                                 "raw");
7678                 if ($patch_max && @{$co{'parents'}} <= 1) {
7679                         $formats_nav .= " | " .
7680                                 $cgi->a({-href => href(action=>"patch", -replay=>1)},
7681                                         "patch");
7682                 }
7683                 $formats_nav .= diff_style_nav($diff_style, @{$co{'parents'}} > 1);
7684
7685                 if (defined $hash_parent &&
7686                     $hash_parent ne '-c' && $hash_parent ne '--cc') {
7687                         # commitdiff with two commits given
7688                         my $hash_parent_short = $hash_parent;
7689                         if ($hash_parent =~ m/^[0-9a-fA-F]{40}$/) {
7690                                 $hash_parent_short = substr($hash_parent, 0, 7);
7691                         }
7692                         $formats_nav .=
7693                                 ' (from';
7694                         for (my $i = 0; $i < @{$co{'parents'}}; $i++) {
7695                                 if ($co{'parents'}[$i] eq $hash_parent) {
7696                                         $formats_nav .= ' parent ' . ($i+1);
7697                                         last;
7698                                 }
7699                         }
7700                         $formats_nav .= ': ' .
7701                                 $cgi->a({-href => href(-replay=>1,
7702                                                        hash=>$hash_parent, hash_base=>undef)},
7703                                         esc_html($hash_parent_short)) .
7704                                 ')';
7705                 } elsif (!$co{'parent'}) {
7706                         # --root commitdiff
7707                         $formats_nav .= ' (initial)';
7708                 } elsif (scalar @{$co{'parents'}} == 1) {
7709                         # single parent commit
7710                         $formats_nav .=
7711                                 ' (parent: ' .
7712                                 $cgi->a({-href => href(-replay=>1,
7713                                                        hash=>$co{'parent'}, hash_base=>undef)},
7714                                         esc_html(substr($co{'parent'}, 0, 7))) .
7715                                 ')';
7716                 } else {
7717                         # merge commit
7718                         if ($hash_parent eq '--cc') {
7719                                 $formats_nav .= ' | ' .
7720                                         $cgi->a({-href => href(-replay=>1,
7721                                                                hash=>$hash, hash_parent=>'-c')},
7722                                                 'combined');
7723                         } else { # $hash_parent eq '-c'
7724                                 $formats_nav .= ' | ' .
7725                                         $cgi->a({-href => href(-replay=>1,
7726                                                                hash=>$hash, hash_parent=>'--cc')},
7727                                                 'compact');
7728                         }
7729                         $formats_nav .=
7730                                 ' (merge: ' .
7731                                 join(' ', map {
7732                                         $cgi->a({-href => href(-replay=>1,
7733                                                                hash=>$_, hash_base=>undef)},
7734                                                 esc_html(substr($_, 0, 7)));
7735                                 } @{$co{'parents'}} ) .
7736                                 ')';
7737                 }
7738         }
7739
7740         my $hash_parent_param = $hash_parent;
7741         if (!defined $hash_parent_param) {
7742                 # --cc for multiple parents, --root for parentless
7743                 $hash_parent_param =
7744                         @{$co{'parents'}} > 1 ? '--cc' : $co{'parent'} || '--root';
7745         }
7746
7747         # read commitdiff
7748         my $fd;
7749         my @difftree;
7750         if ($format eq 'html') {
7751                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7752                         "--no-commit-id", "--patch-with-raw", "--full-index",
7753                         $hash_parent_param, $hash, "--"
7754                         or die_error(500, "Open git-diff-tree failed");
7755
7756                 while (my $line = <$fd>) {
7757                         chomp $line;
7758                         # empty line ends raw part of diff-tree output
7759                         last unless $line;
7760                         push @difftree, scalar parse_difftree_raw_line($line);
7761                 }
7762
7763         } elsif ($format eq 'plain') {
7764                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7765                         '-p', $hash_parent_param, $hash, "--"
7766                         or die_error(500, "Open git-diff-tree failed");
7767         } elsif ($format eq 'patch') {
7768                 # For commit ranges, we limit the output to the number of
7769                 # patches specified in the 'patches' feature.
7770                 # For single commits, we limit the output to a single patch,
7771                 # diverging from the git-format-patch default.
7772                 my @commit_spec = ();
7773                 if ($hash_parent) {
7774                         if ($patch_max > 0) {
7775                                 push @commit_spec, "-$patch_max";
7776                         }
7777                         push @commit_spec, '-n', "$hash_parent..$hash";
7778                 } else {
7779                         if ($params{-single}) {
7780                                 push @commit_spec, '-1';
7781                         } else {
7782                                 if ($patch_max > 0) {
7783                                         push @commit_spec, "-$patch_max";
7784                                 }
7785                                 push @commit_spec, "-n";
7786                         }
7787                         push @commit_spec, '--root', $hash;
7788                 }
7789                 open $fd, "-|", git_cmd(), "format-patch", @diff_opts,
7790                         '--encoding=utf8', '--stdout', @commit_spec
7791                         or die_error(500, "Open git-format-patch failed");
7792         } else {
7793                 die_error(400, "Unknown commitdiff format");
7794         }
7795
7796         # non-textual hash id's can be cached
7797         my $expires;
7798         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7799                 $expires = "+1d";
7800         }
7801
7802         # write commit message
7803         if ($format eq 'html') {
7804                 my $refs = git_get_references();
7805                 my $ref = format_ref_marker($refs, $co{'id'});
7806
7807                 git_header_html(undef, $expires);
7808                 git_print_page_nav('commitdiff','', $hash,$co{'tree'},$hash, $formats_nav);
7809                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash);
7810                 print "<div class=\"title_text\">\n" .
7811                       "<table class=\"object_header\">\n";
7812                 git_print_authorship_rows(\%co);
7813                 print "</table>".
7814                       "</div>\n";
7815                 print "<div class=\"page_body\">\n";
7816                 if (@{$co{'comment'}} > 1) {
7817                         print "<div class=\"log\">\n";
7818                         git_print_log($co{'comment'}, -final_empty_line=> 1, -remove_title => 1);
7819                         print "</div>\n"; # class="log"
7820                 }
7821
7822         } elsif ($format eq 'plain') {
7823                 my $refs = git_get_references("tags");
7824                 my $tagname = git_get_rev_name_tags($hash);
7825                 my $filename = basename($project) . "-$hash.patch";
7826
7827                 print $cgi->header(
7828                         -type => 'text/plain',
7829                         -charset => 'utf-8',
7830                         -expires => $expires,
7831                         -content_disposition => 'inline; filename="' . "$filename" . '"');
7832                 my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
7833                 print "From: " . to_utf8($co{'author'}) . "\n";
7834                 print "Date: $ad{'rfc2822'} ($ad{'tz_local'})\n";
7835                 print "Subject: " . to_utf8($co{'title'}) . "\n";
7836
7837                 print "X-Git-Tag: $tagname\n" if $tagname;
7838                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7839
7840                 foreach my $line (@{$co{'comment'}}) {
7841                         print to_utf8($line) . "\n";
7842                 }
7843                 print "---\n\n";
7844         } elsif ($format eq 'patch') {
7845                 my $filename = basename($project) . "-$hash.patch";
7846
7847                 print $cgi->header(
7848                         -type => 'text/plain',
7849                         -charset => 'utf-8',
7850                         -expires => $expires,
7851                         -content_disposition => 'inline; filename="' . "$filename" . '"');
7852         }
7853
7854         # write patch
7855         if ($format eq 'html') {
7856                 my $use_parents = !defined $hash_parent ||
7857                         $hash_parent eq '-c' || $hash_parent eq '--cc';
7858                 git_difftree_body(\@difftree, $hash,
7859                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
7860                 print "<br/>\n";
7861
7862                 git_patchset_body($fd, $diff_style,
7863                                   \@difftree, $hash,
7864                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
7865                 close $fd;
7866                 print "</div>\n"; # class="page_body"
7867                 git_footer_html();
7868
7869         } elsif ($format eq 'plain') {
7870                 local $/ = undef;
7871                 print <$fd>;
7872                 close $fd
7873                         or print "Reading git-diff-tree failed\n";
7874         } elsif ($format eq 'patch') {
7875                 local $/ = undef;
7876                 print <$fd>;
7877                 close $fd
7878                         or print "Reading git-format-patch failed\n";
7879         }
7880 }
7881
7882 sub git_commitdiff_plain {
7883         git_commitdiff(-format => 'plain');
7884 }
7885
7886 # format-patch-style patches
7887 sub git_patch {
7888         git_commitdiff(-format => 'patch', -single => 1);
7889 }
7890
7891 sub git_patches {
7892         git_commitdiff(-format => 'patch');
7893 }
7894
7895 sub git_history {
7896         git_log_generic('history', \&git_history_body,
7897                         $hash_base, $hash_parent_base,
7898                         $file_name, $hash);
7899 }
7900
7901 sub git_search {
7902         $searchtype ||= 'commit';
7903
7904         # check if appropriate features are enabled
7905         gitweb_check_feature('search')
7906                 or die_error(403, "Search is disabled");
7907         if ($searchtype eq 'pickaxe') {
7908                 # pickaxe may take all resources of your box and run for several minutes
7909                 # with every query - so decide by yourself how public you make this feature
7910                 gitweb_check_feature('pickaxe')
7911                         or die_error(403, "Pickaxe search is disabled");
7912         }
7913         if ($searchtype eq 'grep') {
7914                 # grep search might be potentially CPU-intensive, too
7915                 gitweb_check_feature('grep')
7916                         or die_error(403, "Grep search is disabled");
7917         }
7918
7919         if (!defined $searchtext) {
7920                 die_error(400, "Text field is empty");
7921         }
7922         if (!defined $hash) {
7923                 $hash = git_get_head_hash($project);
7924         }
7925         my %co = parse_commit($hash);
7926         if (!%co) {
7927                 die_error(404, "Unknown commit object");
7928         }
7929         if (!defined $page) {
7930                 $page = 0;
7931         }
7932
7933         if ($searchtype eq 'commit' ||
7934             $searchtype eq 'author' ||
7935             $searchtype eq 'committer') {
7936                 git_search_message(%co);
7937         } elsif ($searchtype eq 'pickaxe') {
7938                 git_search_changes(%co);
7939         } elsif ($searchtype eq 'grep') {
7940                 git_search_files(%co);
7941         } else {
7942                 die_error(400, "Unknown search type");
7943         }
7944 }
7945
7946 sub git_search_help {
7947         git_header_html();
7948         git_print_page_nav('','', $hash,$hash,$hash);
7949         print <<EOT;
7950 <p><strong>Pattern</strong> is by default a normal string that is matched precisely (but without
7951 regard to case, except in the case of pickaxe). However, when you check the <em>re</em> checkbox,
7952 the pattern entered is recognized as the POSIX extended
7953 <a href="http://en.wikipedia.org/wiki/Regular_expression">regular expression</a> (also case
7954 insensitive).</p>
7955 <dl>
7956 <dt><b>commit</b></dt>
7957 <dd>The commit messages and authorship information will be scanned for the given pattern.</dd>
7958 EOT
7959         my $have_grep = gitweb_check_feature('grep');
7960         if ($have_grep) {
7961                 print <<EOT;
7962 <dt><b>grep</b></dt>
7963 <dd>All files in the currently selected tree (HEAD unless you are explicitly browsing
7964     a different one) are searched for the given pattern. On large trees, this search can take
7965 a while and put some strain on the server, so please use it with some consideration. Note that
7966 due to git-grep peculiarity, currently if regexp mode is turned off, the matches are
7967 case-sensitive.</dd>
7968 EOT
7969         }
7970         print <<EOT;
7971 <dt><b>author</b></dt>
7972 <dd>Name and e-mail of the change author and date of birth of the patch will be scanned for the given pattern.</dd>
7973 <dt><b>committer</b></dt>
7974 <dd>Name and e-mail of the committer and date of commit will be scanned for the given pattern.</dd>
7975 EOT
7976         my $have_pickaxe = gitweb_check_feature('pickaxe');
7977         if ($have_pickaxe) {
7978                 print <<EOT;
7979 <dt><b>pickaxe</b></dt>
7980 <dd>All commits that caused the string to appear or disappear from any file (changes that
7981 added, removed or "modified" the string) will be listed. This search can take a while and
7982 takes a lot of strain on the server, so please use it wisely. Note that since you may be
7983 interested even in changes just changing the case as well, this search is case sensitive.</dd>
7984 EOT
7985         }
7986         print "</dl>\n";
7987         git_footer_html();
7988 }
7989
7990 sub git_shortlog {
7991         git_log_generic('shortlog', \&git_shortlog_body,
7992                         $hash, $hash_parent);
7993 }
7994
7995 ## ......................................................................
7996 ## feeds (RSS, Atom; OPML)
7997
7998 sub git_feed {
7999         my $format = shift || 'atom';
8000         my $have_blame = gitweb_check_feature('blame');
8001
8002         # Atom: http://www.atomenabled.org/developers/syndication/
8003         # RSS:  http://www.notestips.com/80256B3A007F2692/1/NAMO5P9UPQ
8004         if ($format ne 'rss' && $format ne 'atom') {
8005                 die_error(400, "Unknown web feed format");
8006         }
8007
8008         # log/feed of current (HEAD) branch, log of given branch, history of file/directory
8009         my $head = $hash || 'HEAD';
8010         my @commitlist = parse_commits($head, 150, 0, $file_name);
8011
8012         my %latest_commit;
8013         my %latest_date;
8014         my $content_type = "application/$format+xml";
8015         if (defined $cgi->http('HTTP_ACCEPT') &&
8016                  $cgi->Accept('text/xml') > $cgi->Accept($content_type)) {
8017                 # browser (feed reader) prefers text/xml
8018                 $content_type = 'text/xml';
8019         }
8020         if (defined($commitlist[0])) {
8021                 %latest_commit = %{$commitlist[0]};
8022                 my $latest_epoch = $latest_commit{'committer_epoch'};
8023                 exit_if_unmodified_since($latest_epoch);
8024                 %latest_date = parse_date($latest_epoch, $latest_commit{'comitter_tz'});
8025         }
8026         print $cgi->header(
8027                 -type => $content_type,
8028                 -charset => 'utf-8',
8029                 %latest_date ? (-last_modified => $latest_date{'rfc2822'}) : (),
8030                 -status => '200 OK');
8031
8032         # Optimization: skip generating the body if client asks only
8033         # for Last-Modified date.
8034         return if ($cgi->request_method() eq 'HEAD');
8035
8036         # header variables
8037         my $title = "$site_name - $project/$action";
8038         my $feed_type = 'log';
8039         if (defined $hash) {
8040                 $title .= " - '$hash'";
8041                 $feed_type = 'branch log';
8042                 if (defined $file_name) {
8043                         $title .= " :: $file_name";
8044                         $feed_type = 'history';
8045                 }
8046         } elsif (defined $file_name) {
8047                 $title .= " - $file_name";
8048                 $feed_type = 'history';
8049         }
8050         $title .= " $feed_type";
8051         my $descr = git_get_project_description($project);
8052         if (defined $descr) {
8053                 $descr = esc_html($descr);
8054         } else {
8055                 $descr = "$project " .
8056                          ($format eq 'rss' ? 'RSS' : 'Atom') .
8057                          " feed";
8058         }
8059         my $owner = git_get_project_owner($project);
8060         $owner = esc_html($owner);
8061
8062         #header
8063         my $alt_url;
8064         if (defined $file_name) {
8065                 $alt_url = href(-full=>1, action=>"history", hash=>$hash, file_name=>$file_name);
8066         } elsif (defined $hash) {
8067                 $alt_url = href(-full=>1, action=>"log", hash=>$hash);
8068         } else {
8069                 $alt_url = href(-full=>1, action=>"summary");
8070         }
8071         print qq!<?xml version="1.0" encoding="utf-8"?>\n!;
8072         if ($format eq 'rss') {
8073                 print <<XML;
8074 <rss version="2.0" xmlns:content="http://purl.org/rss/1.0/modules/content/">
8075 <channel>
8076 XML
8077                 print "<title>$title</title>\n" .
8078                       "<link>$alt_url</link>\n" .
8079                       "<description>$descr</description>\n" .
8080                       "<language>en</language>\n" .
8081                       # project owner is responsible for 'editorial' content
8082                       "<managingEditor>$owner</managingEditor>\n";
8083                 if (defined $logo || defined $favicon) {
8084                         # prefer the logo to the favicon, since RSS
8085                         # doesn't allow both
8086                         my $img = esc_url($logo || $favicon);
8087                         print "<image>\n" .
8088                               "<url>$img</url>\n" .
8089                               "<title>$title</title>\n" .
8090                               "<link>$alt_url</link>\n" .
8091                               "</image>\n";
8092                 }
8093                 if (%latest_date) {
8094                         print "<pubDate>$latest_date{'rfc2822'}</pubDate>\n";
8095                         print "<lastBuildDate>$latest_date{'rfc2822'}</lastBuildDate>\n";
8096                 }
8097                 print "<generator>gitweb v.$version/$git_version</generator>\n";
8098         } elsif ($format eq 'atom') {
8099                 print <<XML;
8100 <feed xmlns="http://www.w3.org/2005/Atom">
8101 XML
8102                 print "<title>$title</title>\n" .
8103                       "<subtitle>$descr</subtitle>\n" .
8104                       '<link rel="alternate" type="text/html" href="' .
8105                       $alt_url . '" />' . "\n" .
8106                       '<link rel="self" type="' . $content_type . '" href="' .
8107                       $cgi->self_url() . '" />' . "\n" .
8108                       "<id>" . href(-full=>1) . "</id>\n" .
8109                       # use project owner for feed author
8110                       "<author><name>$owner</name></author>\n";
8111                 if (defined $favicon) {
8112                         print "<icon>" . esc_url($favicon) . "</icon>\n";
8113                 }
8114                 if (defined $logo) {
8115                         # not twice as wide as tall: 72 x 27 pixels
8116                         print "<logo>" . esc_url($logo) . "</logo>\n";
8117                 }
8118                 if (! %latest_date) {
8119                         # dummy date to keep the feed valid until commits trickle in:
8120                         print "<updated>1970-01-01T00:00:00Z</updated>\n";
8121                 } else {
8122                         print "<updated>$latest_date{'iso-8601'}</updated>\n";
8123                 }
8124                 print "<generator version='$version/$git_version'>gitweb</generator>\n";
8125         }
8126
8127         # contents
8128         for (my $i = 0; $i <= $#commitlist; $i++) {
8129                 my %co = %{$commitlist[$i]};
8130                 my $commit = $co{'id'};
8131                 # we read 150, we always show 30 and the ones more recent than 48 hours
8132                 if (($i >= 20) && ((time - $co{'author_epoch'}) > 48*60*60)) {
8133                         last;
8134                 }
8135                 my %cd = parse_date($co{'author_epoch'}, $co{'author_tz'});
8136
8137                 # get list of changed files
8138                 open my $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
8139                         $co{'parent'} || "--root",
8140                         $co{'id'}, "--", (defined $file_name ? $file_name : ())
8141                         or next;
8142                 my @difftree = map { chomp; $_ } <$fd>;
8143                 close $fd
8144                         or next;
8145
8146                 # print element (entry, item)
8147                 my $co_url = href(-full=>1, action=>"commitdiff", hash=>$commit);
8148                 if ($format eq 'rss') {
8149                         print "<item>\n" .
8150                               "<title>" . esc_html($co{'title'}) . "</title>\n" .
8151                               "<author>" . esc_html($co{'author'}) . "</author>\n" .
8152                               "<pubDate>$cd{'rfc2822'}</pubDate>\n" .
8153                               "<guid isPermaLink=\"true\">$co_url</guid>\n" .
8154                               "<link>$co_url</link>\n" .
8155                               "<description>" . esc_html($co{'title'}) . "</description>\n" .
8156                               "<content:encoded>" .
8157                               "<![CDATA[\n";
8158                 } elsif ($format eq 'atom') {
8159                         print "<entry>\n" .
8160                               "<title type=\"html\">" . esc_html($co{'title'}) . "</title>\n" .
8161                               "<updated>$cd{'iso-8601'}</updated>\n" .
8162                               "<author>\n" .
8163                               "  <name>" . esc_html($co{'author_name'}) . "</name>\n";
8164                         if ($co{'author_email'}) {
8165                                 print "  <email>" . esc_html($co{'author_email'}) . "</email>\n";
8166                         }
8167                         print "</author>\n" .
8168                               # use committer for contributor
8169                               "<contributor>\n" .
8170                               "  <name>" . esc_html($co{'committer_name'}) . "</name>\n";
8171                         if ($co{'committer_email'}) {
8172                                 print "  <email>" . esc_html($co{'committer_email'}) . "</email>\n";
8173                         }
8174                         print "</contributor>\n" .
8175                               "<published>$cd{'iso-8601'}</published>\n" .
8176                               "<link rel=\"alternate\" type=\"text/html\" href=\"$co_url\" />\n" .
8177                               "<id>$co_url</id>\n" .
8178                               "<content type=\"xhtml\" xml:base=\"" . esc_url($my_url) . "\">\n" .
8179                               "<div xmlns=\"http://www.w3.org/1999/xhtml\">\n";
8180                 }
8181                 my $comment = $co{'comment'};
8182                 print "<pre>\n";
8183                 foreach my $line (@$comment) {
8184                         $line = esc_html($line);
8185                         print "$line\n";
8186                 }
8187                 print "</pre><ul>\n";
8188                 foreach my $difftree_line (@difftree) {
8189                         my %difftree = parse_difftree_raw_line($difftree_line);
8190                         next if !$difftree{'from_id'};
8191
8192                         my $file = $difftree{'file'} || $difftree{'to_file'};
8193
8194                         print "<li>" .
8195                               "[" .
8196                               $cgi->a({-href => href(-full=>1, action=>"blobdiff",
8197                                                      hash=>$difftree{'to_id'}, hash_parent=>$difftree{'from_id'},
8198                                                      hash_base=>$co{'id'}, hash_parent_base=>$co{'parent'},
8199                                                      file_name=>$file, file_parent=>$difftree{'from_file'}),
8200                                       -title => "diff"}, 'D');
8201                         if ($have_blame) {
8202                                 print $cgi->a({-href => href(-full=>1, action=>"blame",
8203                                                              file_name=>$file, hash_base=>$commit),
8204                                               -title => "blame"}, 'B');
8205                         }
8206                         # if this is not a feed of a file history
8207                         if (!defined $file_name || $file_name ne $file) {
8208                                 print $cgi->a({-href => href(-full=>1, action=>"history",
8209                                                              file_name=>$file, hash=>$commit),
8210                                               -title => "history"}, 'H');
8211                         }
8212                         $file = esc_path($file);
8213                         print "] ".
8214                               "$file</li>\n";
8215                 }
8216                 if ($format eq 'rss') {
8217                         print "</ul>]]>\n" .
8218                               "</content:encoded>\n" .
8219                               "</item>\n";
8220                 } elsif ($format eq 'atom') {
8221                         print "</ul>\n</div>\n" .
8222                               "</content>\n" .
8223                               "</entry>\n";
8224                 }
8225         }
8226
8227         # end of feed
8228         if ($format eq 'rss') {
8229                 print "</channel>\n</rss>\n";
8230         } elsif ($format eq 'atom') {
8231                 print "</feed>\n";
8232         }
8233 }
8234
8235 sub git_rss {
8236         git_feed('rss');
8237 }
8238
8239 sub git_atom {
8240         git_feed('atom');
8241 }
8242
8243 sub git_opml {
8244         my @list = git_get_projects_list($project_filter, $strict_export);
8245         if (!@list) {
8246                 die_error(404, "No projects found");
8247         }
8248
8249         print $cgi->header(
8250                 -type => 'text/xml',
8251                 -charset => 'utf-8',
8252                 -content_disposition => 'inline; filename="opml.xml"');
8253
8254         my $title = esc_html($site_name);
8255         my $filter = " within subdirectory ";
8256         if (defined $project_filter) {
8257                 $filter .= esc_html($project_filter);
8258         } else {
8259                 $filter = "";
8260         }
8261         print <<XML;
8262 <?xml version="1.0" encoding="utf-8"?>
8263 <opml version="1.0">
8264 <head>
8265   <title>$title OPML Export$filter</title>
8266 </head>
8267 <body>
8268 <outline text="git RSS feeds">
8269 XML
8270
8271         foreach my $pr (@list) {
8272                 my %proj = %$pr;
8273                 my $head = git_get_head_hash($proj{'path'});
8274                 if (!defined $head) {
8275                         next;
8276                 }
8277                 $git_dir = "$projectroot/$proj{'path'}";
8278                 my %co = parse_commit($head);
8279                 if (!%co) {
8280                         next;
8281                 }
8282
8283                 my $path = esc_html(chop_str($proj{'path'}, 25, 5));
8284                 my $rss  = href('project' => $proj{'path'}, 'action' => 'rss', -full => 1);
8285                 my $html = href('project' => $proj{'path'}, 'action' => 'summary', -full => 1);
8286                 print "<outline type=\"rss\" text=\"$path\" title=\"$path\" xmlUrl=\"$rss\" htmlUrl=\"$html\"/>\n";
8287         }
8288         print <<XML;
8289 </outline>
8290 </body>
8291 </opml>
8292 XML
8293 }