Lady’s Gitweb - Gitweb/blob - gitweb.perl

   1 #!/usr/bin/perl
   2
   3 # gitweb - simple web interface to track changes in git repositories
   4 #
   5 # (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
   6 # (C) 2005, Christian Gierke
   7 #
   8 # This program is licensed under the GPLv2
   9
  10 use strict;
  11 use warnings;
  12 use CGI qw(:standard :escapeHTML -nosticky);
  13 use CGI::Util qw(unescape);
  14 use CGI::Carp qw(fatalsToBrowser);
  15 use Encode;
  16 use Fcntl ':mode';
  17 use File::Find qw();
  18 use File::Basename qw(basename);
  19 binmode STDOUT, ':utf8';
  20
  21 BEGIN {
  22         CGI->compile() if $ENV{'MOD_PERL'};
  23 }
  24
  25 our $cgi = new CGI;
  26 our $version = "++GIT_VERSION++";
  27 our $my_url = $cgi->url();
  28 our $my_uri = $cgi->url(-absolute => 1);
  29
  30 # core git executable to use
  31 # this can just be "git" if your webserver has a sensible PATH
  32 our $GIT = "++GIT_BINDIR++/git";
  33
  34 # absolute fs-path which will be prepended to the project path
  35 #our $projectroot = "/pub/scm";
  36 our $projectroot = "++GITWEB_PROJECTROOT++";
  37
  38 # target of the home link on top of all pages
  39 our $home_link = $my_uri || "/";
  40
  41 # string of the home link on top of all pages
  42 our $home_link_str = "++GITWEB_HOME_LINK_STR++";
  43
  44 # name of your site or organization to appear in page titles
  45 # replace this with something more descriptive for clearer bookmarks
  46 our $site_name = "++GITWEB_SITENAME++"
  47                  || ($ENV{'SERVER_NAME'} || "Untitled") . " Git";
  48
  49 # filename of html text to include at top of each page
  50 our $site_header = "++GITWEB_SITE_HEADER++";
  51 # html text to include at home page
  52 our $home_text = "++GITWEB_HOMETEXT++";
  53 # filename of html text to include at bottom of each page
  54 our $site_footer = "++GITWEB_SITE_FOOTER++";
  55
  56 # URI of stylesheets
  57 our @stylesheets = ("++GITWEB_CSS++");
  58 # URI of a single stylesheet, which can be overridden in GITWEB_CONFIG.
  59 our $stylesheet = undef;
  60
  61 # URI of GIT logo (72x27 size)
  62 our $logo = "++GITWEB_LOGO++";
  63 # URI of GIT favicon, assumed to be image/png type
  64 our $favicon = "++GITWEB_FAVICON++";
  65
  66 # URI and label (title) of GIT logo link
  67 #our $logo_url = "http://www.kernel.org/pub/software/scm/git/docs/";
  68 #our $logo_label = "git documentation";
  69 our $logo_url = "http://git.or.cz/";
  70 our $logo_label = "git homepage";
  71
  72 # source of projects list
  73 our $projects_list = "++GITWEB_LIST++";
  74
  75 # show repository only if this file exists
  76 # (only effective if this variable evaluates to true)
  77 our $export_ok = "++GITWEB_EXPORT_OK++";
  78
  79 # only allow viewing of repositories also shown on the overview page
  80 our $strict_export = "++GITWEB_STRICT_EXPORT++";
  81
  82 # list of git base URLs used for URL to where fetch project from,
  83 # i.e. full URL is "$git_base_url/$project"
  84 our @git_base_url_list = grep { $_ ne '' } ("++GITWEB_BASE_URL++");
  85
  86 # default blob_plain mimetype and default charset for text/plain blob
  87 our $default_blob_plain_mimetype = 'text/plain';
  88 our $default_text_plain_charset  = undef;
  89
  90 # file to use for guessing MIME types before trying /etc/mime.types
  91 # (relative to the current git repository)
  92 our $mimetypes_file = undef;
  93
  94 # You define site-wide feature defaults here; override them with
  95 # $GITWEB_CONFIG as necessary.
  96 our %feature = (
  97         # feature => {
  98         #       'sub' => feature-sub (subroutine),
  99         #       'override' => allow-override (boolean),
 100         #       'default' => [ default options...] (array reference)}
 101         #
 102         # if feature is overridable (it means that allow-override has true value,
 103         # then feature-sub will be called with default options as parameters;
 104         # return value of feature-sub indicates if to enable specified feature
 105         #
 106         # use gitweb_check_feature(<feature>) to check if <feature> is enabled
 107
 108         # Enable the 'blame' blob view, showing the last commit that modified
 109         # each line in the file. This can be very CPU-intensive.
 110
 111         # To enable system wide have in $GITWEB_CONFIG
 112         # $feature{'blame'}{'default'} = [1];
 113         # To have project specific config enable override in $GITWEB_CONFIG
 114         # $feature{'blame'}{'override'} = 1;
 115         # and in project config gitweb.blame = 0|1;
 116         'blame' => {
 117                 'sub' => \&feature_blame,
 118                 'override' => 0,
 119                 'default' => [0]},
 120
 121         # Enable the 'snapshot' link, providing a compressed tarball of any
 122         # tree. This can potentially generate high traffic if you have large
 123         # project.
 124
 125         # To disable system wide have in $GITWEB_CONFIG
 126         # $feature{'snapshot'}{'default'} = [undef];
 127         # To have project specific config enable override in $GITWEB_CONFIG
 128         # $feature{'snapshot'}{'override'} = 1;
 129         # and in project config gitweb.snapshot = none|gzip|bzip2;
 130         'snapshot' => {
 131                 'sub' => \&feature_snapshot,
 132                 'override' => 0,
 133                 #         => [content-encoding, suffix, program]
 134                 'default' => ['x-gzip', 'gz', 'gzip']},
 135
 136         # Enable text search, which will list the commits which match author,
 137         # committer or commit text to a given string.  Enabled by default.
 138         'search' => {
 139                 'override' => 0,
 140                 'default' => [1]},
 141
 142         # Enable the pickaxe search, which will list the commits that modified
 143         # a given string in a file. This can be practical and quite faster
 144         # alternative to 'blame', but still potentially CPU-intensive.
 145
 146         # To enable system wide have in $GITWEB_CONFIG
 147         # $feature{'pickaxe'}{'default'} = [1];
 148         # To have project specific config enable override in $GITWEB_CONFIG
 149         # $feature{'pickaxe'}{'override'} = 1;
 150         # and in project config gitweb.pickaxe = 0|1;
 151         'pickaxe' => {
 152                 'sub' => \&feature_pickaxe,
 153                 'override' => 0,
 154                 'default' => [1]},
 155
 156         # Make gitweb use an alternative format of the URLs which can be
 157         # more readable and natural-looking: project name is embedded
 158         # directly in the path and the query string contains other
 159         # auxiliary information. All gitweb installations recognize
 160         # URL in either format; this configures in which formats gitweb
 161         # generates links.
 162
 163         # To enable system wide have in $GITWEB_CONFIG
 164         # $feature{'pathinfo'}{'default'} = [1];
 165         # Project specific override is not supported.
 166
 167         # Note that you will need to change the default location of CSS,
 168         # favicon, logo and possibly other files to an absolute URL. Also,
 169         # if gitweb.cgi serves as your indexfile, you will need to force
 170         # $my_uri to contain the script name in your $GITWEB_CONFIG.
 171         'pathinfo' => {
 172                 'override' => 0,
 173                 'default' => [0]},
 174
 175         # Make gitweb consider projects in project root subdirectories
 176         # to be forks of existing projects. Given project $projname.git,
 177         # projects matching $projname/*.git will not be shown in the main
 178         # projects list, instead a '+' mark will be added to $projname
 179         # there and a 'forks' view will be enabled for the project, listing
 180         # all the forks. If project list is taken from a file, forks have
 181         # to be listed after the main project.
 182
 183         # To enable system wide have in $GITWEB_CONFIG
 184         # $feature{'forks'}{'default'} = [1];
 185         # Project specific override is not supported.
 186         'forks' => {
 187                 'override' => 0,
 188                 'default' => [0]},
 189 );
 190
 191 sub gitweb_check_feature {
 192         my ($name) = @_;
 193         return unless exists $feature{$name};
 194         my ($sub, $override, @defaults) = (
 195                 $feature{$name}{'sub'},
 196                 $feature{$name}{'override'},
 197                 @{$feature{$name}{'default'}});
 198         if (!$override) { return @defaults; }
 199         if (!defined $sub) {
 200                 warn "feature $name is not overrideable";
 201                 return @defaults;
 202         }
 203         return $sub->(@defaults);
 204 }
 205
 206 sub feature_blame {
 207         my ($val) = git_get_project_config('blame', '--bool');
 208
 209         if ($val eq 'true') {
 210                 return 1;
 211         } elsif ($val eq 'false') {
 212                 return 0;
 213         }
 214
 215         return $_[0];
 216 }
 217
 218 sub feature_snapshot {
 219         my ($ctype, $suffix, $command) = @_;
 220
 221         my ($val) = git_get_project_config('snapshot');
 222
 223         if ($val eq 'gzip') {
 224                 return ('x-gzip', 'gz', 'gzip');
 225         } elsif ($val eq 'bzip2') {
 226                 return ('x-bzip2', 'bz2', 'bzip2');
 227         } elsif ($val eq 'none') {
 228                 return ();
 229         }
 230
 231         return ($ctype, $suffix, $command);
 232 }
 233
 234 sub gitweb_have_snapshot {
 235         my ($ctype, $suffix, $command) = gitweb_check_feature('snapshot');
 236         my $have_snapshot = (defined $ctype && defined $suffix);
 237
 238         return $have_snapshot;
 239 }
 240
 241 sub feature_pickaxe {
 242         my ($val) = git_get_project_config('pickaxe', '--bool');
 243
 244         if ($val eq 'true') {
 245                 return (1);
 246         } elsif ($val eq 'false') {
 247                 return (0);
 248         }
 249
 250         return ($_[0]);
 251 }
 252
 253 # checking HEAD file with -e is fragile if the repository was
 254 # initialized long time ago (i.e. symlink HEAD) and was pack-ref'ed
 255 # and then pruned.
 256 sub check_head_link {
 257         my ($dir) = @_;
 258         my $headfile = "$dir/HEAD";
 259         return ((-e $headfile) ||
 260                 (-l $headfile && readlink($headfile) =~ /^refs\/heads\//));
 261 }
 262
 263 sub check_export_ok {
 264         my ($dir) = @_;
 265         return (check_head_link($dir) &&
 266                 (!$export_ok || -e "$dir/$export_ok"));
 267 }
 268
 269 # rename detection options for git-diff and git-diff-tree
 270 # - default is '-M', with the cost proportional to
 271 #   (number of removed files) * (number of new files).
 272 # - more costly is '-C' (or '-C', '-M'), with the cost proportional to
 273 #   (number of changed files + number of removed files) * (number of new files)
 274 # - even more costly is '-C', '--find-copies-harder' with cost
 275 #   (number of files in the original tree) * (number of new files)
 276 # - one might want to include '-B' option, e.g. '-B', '-M'
 277 our @diff_opts = ('-M'); # taken from git_commit
 278
 279 our $GITWEB_CONFIG = $ENV{'GITWEB_CONFIG'} || "++GITWEB_CONFIG++";
 280 do $GITWEB_CONFIG if -e $GITWEB_CONFIG;
 281
 282 # version of the core git binary
 283 our $git_version = qx($GIT --version) =~ m/git version (.*)$/ ? $1 : "unknown";
 284
 285 $projects_list ||= $projectroot;
 286
 287 # ======================================================================
 288 # input validation and dispatch
 289 our $action = $cgi->param('a');
 290 if (defined $action) {
 291         if ($action =~ m/[^0-9a-zA-Z\.\-_]/) {
 292                 die_error(undef, "Invalid action parameter");
 293         }
 294 }
 295
 296 # parameters which are pathnames
 297 our $project = $cgi->param('p');
 298 if (defined $project) {
 299         if (!validate_pathname($project) ||
 300             !(-d "$projectroot/$project") ||
 301             !check_head_link("$projectroot/$project") ||
 302             ($export_ok && !(-e "$projectroot/$project/$export_ok")) ||
 303             ($strict_export && !project_in_list($project))) {
 304                 undef $project;
 305                 die_error(undef, "No such project");
 306         }
 307 }
 308
 309 our $file_name = $cgi->param('f');
 310 if (defined $file_name) {
 311         if (!validate_pathname($file_name)) {
 312                 die_error(undef, "Invalid file parameter");
 313         }
 314 }
 315
 316 our $file_parent = $cgi->param('fp');
 317 if (defined $file_parent) {
 318         if (!validate_pathname($file_parent)) {
 319                 die_error(undef, "Invalid file parent parameter");
 320         }
 321 }
 322
 323 # parameters which are refnames
 324 our $hash = $cgi->param('h');
 325 if (defined $hash) {
 326         if (!validate_refname($hash)) {
 327                 die_error(undef, "Invalid hash parameter");
 328         }
 329 }
 330
 331 our $hash_parent = $cgi->param('hp');
 332 if (defined $hash_parent) {
 333         if (!validate_refname($hash_parent)) {
 334                 die_error(undef, "Invalid hash parent parameter");
 335         }
 336 }
 337
 338 our $hash_base = $cgi->param('hb');
 339 if (defined $hash_base) {
 340         if (!validate_refname($hash_base)) {
 341                 die_error(undef, "Invalid hash base parameter");
 342         }
 343 }
 344
 345 our $hash_parent_base = $cgi->param('hpb');
 346 if (defined $hash_parent_base) {
 347         if (!validate_refname($hash_parent_base)) {
 348                 die_error(undef, "Invalid hash parent base parameter");
 349         }
 350 }
 351
 352 # other parameters
 353 our $page = $cgi->param('pg');
 354 if (defined $page) {
 355         if ($page =~ m/[^0-9]/) {
 356                 die_error(undef, "Invalid page parameter");
 357         }
 358 }
 359
 360 our $searchtext = $cgi->param('s');
 361 if (defined $searchtext) {
 362         if ($searchtext =~ m/[^a-zA-Z0-9_\.\/\-\+\:\@ ]/) {
 363                 die_error(undef, "Invalid search parameter");
 364         }
 365         if (length($searchtext) < 2) {
 366                 die_error(undef, "At least two characters are required for search parameter");
 367         }
 368         $searchtext = quotemeta $searchtext;
 369 }
 370
 371 our $searchtype = $cgi->param('st');
 372 if (defined $searchtype) {
 373         if ($searchtype =~ m/[^a-z]/) {
 374                 die_error(undef, "Invalid searchtype parameter");
 375         }
 376 }
 377
 378 # now read PATH_INFO and use it as alternative to parameters
 379 sub evaluate_path_info {
 380         return if defined $project;
 381         my $path_info = $ENV{"PATH_INFO"};
 382         return if !$path_info;
 383         $path_info =~ s,^/+,,;
 384         return if !$path_info;
 385         # find which part of PATH_INFO is project
 386         $project = $path_info;
 387         $project =~ s,/+$,,;
 388         while ($project && !check_head_link("$projectroot/$project")) {
 389                 $project =~ s,/*[^/]*$,,;
 390         }
 391         # validate project
 392         $project = validate_pathname($project);
 393         if (!$project ||
 394             ($export_ok && !-e "$projectroot/$project/$export_ok") ||
 395             ($strict_export && !project_in_list($project))) {
 396                 undef $project;
 397                 return;
 398         }
 399         # do not change any parameters if an action is given using the query string
 400         return if $action;
 401         $path_info =~ s,^$project/*,,;
 402         my ($refname, $pathname) = split(/:/, $path_info, 2);
 403         if (defined $pathname) {
 404                 # we got "project.git/branch:filename" or "project.git/branch:dir/"
 405                 # we could use git_get_type(branch:pathname), but it needs $git_dir
 406                 $pathname =~ s,^/+,,;
 407                 if (!$pathname || substr($pathname, -1) eq "/") {
 408                         $action  ||= "tree";
 409                         $pathname =~ s,/$,,;
 410                 } else {
 411                         $action  ||= "blob_plain";
 412                 }
 413                 $hash_base ||= validate_refname($refname);
 414                 $file_name ||= validate_pathname($pathname);
 415         } elsif (defined $refname) {
 416                 # we got "project.git/branch"
 417                 $action ||= "shortlog";
 418                 $hash   ||= validate_refname($refname);
 419         }
 420 }
 421 evaluate_path_info();
 422
 423 # path to the current git repository
 424 our $git_dir;
 425 $git_dir = "$projectroot/$project" if $project;
 426
 427 # dispatch
 428 my %actions = (
 429         "blame" => \&git_blame2,
 430         "blobdiff" => \&git_blobdiff,
 431         "blobdiff_plain" => \&git_blobdiff_plain,
 432         "blob" => \&git_blob,
 433         "blob_plain" => \&git_blob_plain,
 434         "commitdiff" => \&git_commitdiff,
 435         "commitdiff_plain" => \&git_commitdiff_plain,
 436         "commit" => \&git_commit,
 437         "forks" => \&git_forks,
 438         "heads" => \&git_heads,
 439         "history" => \&git_history,
 440         "log" => \&git_log,
 441         "rss" => \&git_rss,
 442         "atom" => \&git_atom,
 443         "search" => \&git_search,
 444         "search_help" => \&git_search_help,
 445         "shortlog" => \&git_shortlog,
 446         "summary" => \&git_summary,
 447         "tag" => \&git_tag,
 448         "tags" => \&git_tags,
 449         "tree" => \&git_tree,
 450         "snapshot" => \&git_snapshot,
 451         "object" => \&git_object,
 452         # those below don't need $project
 453         "opml" => \&git_opml,
 454         "project_list" => \&git_project_list,
 455         "project_index" => \&git_project_index,
 456 );
 457
 458 if (defined $project) {
 459         $action ||= 'summary';
 460 } else {
 461         $action ||= 'project_list';
 462 }
 463 if (!defined($actions{$action})) {
 464         die_error(undef, "Unknown action");
 465 }
 466 if ($action !~ m/^(opml|project_list|project_index)$/ &&
 467     !$project) {
 468         die_error(undef, "Project needed");
 469 }
 470 $actions{$action}->();
 471 exit;
 472
 473 ## ======================================================================
 474 ## action links
 475
 476 sub href(%) {
 477         my %params = @_;
 478         # default is to use -absolute url() i.e. $my_uri
 479         my $href = $params{-full} ? $my_url : $my_uri;
 480
 481         # XXX: Warning: If you touch this, check the search form for updating,
 482         # too.
 483
 484         my @mapping = (
 485                 project => "p",
 486                 action => "a",
 487                 file_name => "f",
 488                 file_parent => "fp",
 489                 hash => "h",
 490                 hash_parent => "hp",
 491                 hash_base => "hb",
 492                 hash_parent_base => "hpb",
 493                 page => "pg",
 494                 order => "o",
 495                 searchtext => "s",
 496                 searchtype => "st",
 497         );
 498         my %mapping = @mapping;
 499
 500         $params{'project'} = $project unless exists $params{'project'};
 501
 502         my ($use_pathinfo) = gitweb_check_feature('pathinfo');
 503         if ($use_pathinfo) {
 504                 # use PATH_INFO for project name
 505                 $href .= "/$params{'project'}" if defined $params{'project'};
 506                 delete $params{'project'};
 507
 508                 # Summary just uses the project path URL
 509                 if (defined $params{'action'} && $params{'action'} eq 'summary') {
 510                         delete $params{'action'};
 511                 }
 512         }
 513
 514         # now encode the parameters explicitly
 515         my @result = ();
 516         for (my $i = 0; $i < @mapping; $i += 2) {
 517                 my ($name, $symbol) = ($mapping[$i], $mapping[$i+1]);
 518                 if (defined $params{$name}) {
 519                         push @result, $symbol . "=" . esc_param($params{$name});
 520                 }
 521         }
 522         $href .= "?" . join(';', @result) if scalar @result;
 523
 524         return $href;
 525 }
 526
 527
 528 ## ======================================================================
 529 ## validation, quoting/unquoting and escaping
 530
 531 sub validate_pathname {
 532         my $input = shift || return undef;
 533
 534         # no '.' or '..' as elements of path, i.e. no '.' nor '..'
 535         # at the beginning, at the end, and between slashes.
 536         # also this catches doubled slashes
 537         if ($input =~ m!(^|/)(|\.|\.\.)(/|$)!) {
 538                 return undef;
 539         }
 540         # no null characters
 541         if ($input =~ m!\0!) {
 542                 return undef;
 543         }
 544         return $input;
 545 }
 546
 547 sub validate_refname {
 548         my $input = shift || return undef;
 549
 550         # textual hashes are O.K.
 551         if ($input =~ m/^[0-9a-fA-F]{40}$/) {
 552                 return $input;
 553         }
 554         # it must be correct pathname
 555         $input = validate_pathname($input)
 556                 or return undef;
 557         # restrictions on ref name according to git-check-ref-format
 558         if ($input =~ m!(/\.|\.\.|[\000-\040\177 ~^:?*\[]|/$)!) {
 559                 return undef;
 560         }
 561         return $input;
 562 }
 563
 564 # very thin wrapper for decode("utf8", $str, Encode::FB_DEFAULT);
 565 sub to_utf8 {
 566         my $str = shift;
 567         return decode("utf8", $str, Encode::FB_DEFAULT);
 568 }
 569
 570 # quote unsafe chars, but keep the slash, even when it's not
 571 # correct, but quoted slashes look too horrible in bookmarks
 572 sub esc_param {
 573         my $str = shift;
 574         $str =~ s/([^A-Za-z0-9\-_.~()\/:@])/sprintf("%%%02X", ord($1))/eg;
 575         $str =~ s/\+/%2B/g;
 576         $str =~ s/ /\+/g;
 577         return $str;
 578 }
 579
 580 # quote unsafe chars in whole URL, so some charactrs cannot be quoted
 581 sub esc_url {
 582         my $str = shift;
 583         $str =~ s/([^A-Za-z0-9\-_.~();\/;?:@&=])/sprintf("%%%02X", ord($1))/eg;
 584         $str =~ s/\+/%2B/g;
 585         $str =~ s/ /\+/g;
 586         return $str;
 587 }
 588
 589 # replace invalid utf8 character with SUBSTITUTION sequence
 590 sub esc_html ($;%) {
 591         my $str = shift;
 592         my %opts = @_;
 593
 594         $str = to_utf8($str);
 595         $str = $cgi->escapeHTML($str);
 596         if ($opts{'-nbsp'}) {
 597                 $str =~ s/ /&nbsp;/g;
 598         }
 599         $str =~ s|([[:cntrl:]])|(($1 ne "\t") ? quot_cec($1) : $1)|eg;
 600         return $str;
 601 }
 602
 603 # quote control characters and escape filename to HTML
 604 sub esc_path {
 605         my $str = shift;
 606         my %opts = @_;
 607
 608         $str = to_utf8($str);
 609         $str = $cgi->escapeHTML($str);
 610         if ($opts{'-nbsp'}) {
 611                 $str =~ s/ /&nbsp;/g;
 612         }
 613         $str =~ s|([[:cntrl:]])|quot_cec($1)|eg;
 614         return $str;
 615 }
 616
 617 # Make control characters "printable", using character escape codes (CEC)
 618 sub quot_cec {
 619         my $cntrl = shift;
 620         my %es = ( # character escape codes, aka escape sequences
 621                    "\t" => '\t',   # tab            (HT)
 622                    "\n" => '\n',   # line feed      (LF)
 623                    "\r" => '\r',   # carrige return (CR)
 624                    "\f" => '\f',   # form feed      (FF)
 625                    "\b" => '\b',   # backspace      (BS)
 626                    "\a" => '\a',   # alarm (bell)   (BEL)
 627                    "\e" => '\e',   # escape         (ESC)
 628                    "\013" => '\v', # vertical tab   (VT)
 629                    "\000" => '\0', # nul character  (NUL)
 630                    );
 631         my $chr = ( (exists $es{$cntrl})
 632                     ? $es{$cntrl}
 633                     : sprintf('\%03o', ord($cntrl)) );
 634         return "<span class=\"cntrl\">$chr</span>";
 635 }
 636
 637 # Alternatively use unicode control pictures codepoints,
 638 # Unicode "printable representation" (PR)
 639 sub quot_upr {
 640         my $cntrl = shift;
 641         my $chr = sprintf('&#%04d;', 0x2400+ord($cntrl));
 642         return "<span class=\"cntrl\">$chr</span>";
 643 }
 644
 645 # git may return quoted and escaped filenames
 646 sub unquote {
 647         my $str = shift;
 648
 649         sub unq {
 650                 my $seq = shift;
 651                 my %es = ( # character escape codes, aka escape sequences
 652                         't' => "\t",   # tab            (HT, TAB)
 653                         'n' => "\n",   # newline        (NL)
 654                         'r' => "\r",   # return         (CR)
 655                         'f' => "\f",   # form feed      (FF)
 656                         'b' => "\b",   # backspace      (BS)
 657                         'a' => "\a",   # alarm (bell)   (BEL)
 658                         'e' => "\e",   # escape         (ESC)
 659                         'v' => "\013", # vertical tab   (VT)
 660                 );
 661
 662                 if ($seq =~ m/^[0-7]{1,3}$/) {
 663                         # octal char sequence
 664                         return chr(oct($seq));
 665                 } elsif (exists $es{$seq}) {
 666                         # C escape sequence, aka character escape code
 667                         return $es{$seq}
 668                 }
 669                 # quoted ordinary character
 670                 return $seq;
 671         }
 672
 673         if ($str =~ m/^"(.*)"$/) {
 674                 # needs unquoting
 675                 $str = $1;
 676                 $str =~ s/\\([^0-7]|[0-7]{1,3})/unq($1)/eg;
 677         }
 678         return $str;
 679 }
 680
 681 # escape tabs (convert tabs to spaces)
 682 sub untabify {
 683         my $line = shift;
 684
 685         while ((my $pos = index($line, "\t")) != -1) {
 686                 if (my $count = (8 - ($pos % 8))) {
 687                         my $spaces = ' ' x $count;
 688                         $line =~ s/\t/$spaces/;
 689                 }
 690         }
 691
 692         return $line;
 693 }
 694
 695 sub project_in_list {
 696         my $project = shift;
 697         my @list = git_get_projects_list();
 698         return @list && scalar(grep { $_->{'path'} eq $project } @list);
 699 }
 700
 701 ## ----------------------------------------------------------------------
 702 ## HTML aware string manipulation
 703
 704 sub chop_str {
 705         my $str = shift;
 706         my $len = shift;
 707         my $add_len = shift || 10;
 708
 709         # allow only $len chars, but don't cut a word if it would fit in $add_len
 710         # if it doesn't fit, cut it if it's still longer than the dots we would add
 711         $str =~ m/^(.{0,$len}[^ \/\-_:\.@]{0,$add_len})(.*)/;
 712         my $body = $1;
 713         my $tail = $2;
 714         if (length($tail) > 4) {
 715                 $tail = " ...";
 716                 $body =~ s/&[^;]*$//; # remove chopped character entities
 717         }
 718         return "$body$tail";
 719 }
 720
 721 ## ----------------------------------------------------------------------
 722 ## functions returning short strings
 723
 724 # CSS class for given age value (in seconds)
 725 sub age_class {
 726         my $age = shift;
 727
 728         if ($age < 60*60*2) {
 729                 return "age0";
 730         } elsif ($age < 60*60*24*2) {
 731                 return "age1";
 732         } else {
 733                 return "age2";
 734         }
 735 }
 736
 737 # convert age in seconds to "nn units ago" string
 738 sub age_string {
 739         my $age = shift;
 740         my $age_str;
 741
 742         if ($age > 60*60*24*365*2) {
 743                 $age_str = (int $age/60/60/24/365);
 744                 $age_str .= " years ago";
 745         } elsif ($age > 60*60*24*(365/12)*2) {
 746                 $age_str = int $age/60/60/24/(365/12);
 747                 $age_str .= " months ago";
 748         } elsif ($age > 60*60*24*7*2) {
 749                 $age_str = int $age/60/60/24/7;
 750                 $age_str .= " weeks ago";
 751         } elsif ($age > 60*60*24*2) {
 752                 $age_str = int $age/60/60/24;
 753                 $age_str .= " days ago";
 754         } elsif ($age > 60*60*2) {
 755                 $age_str = int $age/60/60;
 756                 $age_str .= " hours ago";
 757         } elsif ($age > 60*2) {
 758                 $age_str = int $age/60;
 759                 $age_str .= " min ago";
 760         } elsif ($age > 2) {
 761                 $age_str = int $age;
 762                 $age_str .= " sec ago";
 763         } else {
 764                 $age_str .= " right now";
 765         }
 766         return $age_str;
 767 }
 768
 769 # convert file mode in octal to symbolic file mode string
 770 sub mode_str {
 771         my $mode = oct shift;
 772
 773         if (S_ISDIR($mode & S_IFMT)) {
 774                 return 'drwxr-xr-x';
 775         } elsif (S_ISLNK($mode)) {
 776                 return 'lrwxrwxrwx';
 777         } elsif (S_ISREG($mode)) {
 778                 # git cares only about the executable bit
 779                 if ($mode & S_IXUSR) {
 780                         return '-rwxr-xr-x';
 781                 } else {
 782                         return '-rw-r--r--';
 783                 };
 784         } else {
 785                 return '----------';
 786         }
 787 }
 788
 789 # convert file mode in octal to file type string
 790 sub file_type {
 791         my $mode = shift;
 792
 793         if ($mode !~ m/^[0-7]+$/) {
 794                 return $mode;
 795         } else {
 796                 $mode = oct $mode;
 797         }
 798
 799         if (S_ISDIR($mode & S_IFMT)) {
 800                 return "directory";
 801         } elsif (S_ISLNK($mode)) {
 802                 return "symlink";
 803         } elsif (S_ISREG($mode)) {
 804                 return "file";
 805         } else {
 806                 return "unknown";
 807         }
 808 }
 809
 810 # convert file mode in octal to file type description string
 811 sub file_type_long {
 812         my $mode = shift;
 813
 814         if ($mode !~ m/^[0-7]+$/) {
 815                 return $mode;
 816         } else {
 817                 $mode = oct $mode;
 818         }
 819
 820         if (S_ISDIR($mode & S_IFMT)) {
 821                 return "directory";
 822         } elsif (S_ISLNK($mode)) {
 823                 return "symlink";
 824         } elsif (S_ISREG($mode)) {
 825                 if ($mode & S_IXUSR) {
 826                         return "executable";
 827                 } else {
 828                         return "file";
 829                 };
 830         } else {
 831                 return "unknown";
 832         }
 833 }
 834
 835
 836 ## ----------------------------------------------------------------------
 837 ## functions returning short HTML fragments, or transforming HTML fragments
 838 ## which don't belong to other sections
 839
 840 # format line of commit message.
 841 sub format_log_line_html {
 842         my $line = shift;
 843
 844         $line = esc_html($line, -nbsp=>1);
 845         if ($line =~ m/([0-9a-fA-F]{8,40})/) {
 846                 my $hash_text = $1;
 847                 my $link =
 848                         $cgi->a({-href => href(action=>"object", hash=>$hash_text),
 849                                 -class => "text"}, $hash_text);
 850                 $line =~ s/$hash_text/$link/;
 851         }
 852         return $line;
 853 }
 854
 855 # format marker of refs pointing to given object
 856 sub format_ref_marker {
 857         my ($refs, $id) = @_;
 858         my $markers = '';
 859
 860         if (defined $refs->{$id}) {
 861                 foreach my $ref (@{$refs->{$id}}) {
 862                         my ($type, $name) = qw();
 863                         # e.g. tags/v2.6.11 or heads/next
 864                         if ($ref =~ m!^(.*?)s?/(.*)$!) {
 865                                 $type = $1;
 866                                 $name = $2;
 867                         } else {
 868                                 $type = "ref";
 869                                 $name = $ref;
 870                         }
 871
 872                         $markers .= " <span class=\"$type\" title=\"$ref\">" .
 873                                     esc_html($name) . "</span>";
 874                 }
 875         }
 876
 877         if ($markers) {
 878                 return ' <span class="refs">'. $markers . '</span>';
 879         } else {
 880                 return "";
 881         }
 882 }
 883
 884 # format, perhaps shortened and with markers, title line
 885 sub format_subject_html {
 886         my ($long, $short, $href, $extra) = @_;
 887         $extra = '' unless defined($extra);
 888
 889         if (length($short) < length($long)) {
 890                 return $cgi->a({-href => $href, -class => "list subject",
 891                                 -title => to_utf8($long)},
 892                        esc_html($short) . $extra);
 893         } else {
 894                 return $cgi->a({-href => $href, -class => "list subject"},
 895                        esc_html($long)  . $extra);
 896         }
 897 }
 898
 899 # format patch (diff) line (rather not to be used for diff headers)
 900 sub format_diff_line {
 901         my $line = shift;
 902         my ($from, $to) = @_;
 903         my $char = substr($line, 0, 1);
 904         my $diff_class = "";
 905
 906         chomp $line;
 907
 908         if ($char eq '+') {
 909                 $diff_class = " add";
 910         } elsif ($char eq "-") {
 911                 $diff_class = " rem";
 912         } elsif ($char eq "@") {
 913                 $diff_class = " chunk_header";
 914         } elsif ($char eq "\\") {
 915                 $diff_class = " incomplete";
 916         }
 917         $line = untabify($line);
 918         if ($from && $to && $line =~ m/^\@{2} /) {
 919                 my ($from_text, $from_start, $from_lines, $to_text, $to_start, $to_lines, $section) =
 920                         $line =~ m/^\@{2} (-(\d+)(?:,(\d+))?) (\+(\d+)(?:,(\d+))?) \@{2}(.*)$/;
 921
 922                 $from_lines = 0 unless defined $from_lines;
 923                 $to_lines   = 0 unless defined $to_lines;
 924
 925                 if ($from->{'href'}) {
 926                         $from_text = $cgi->a({-href=>"$from->{'href'}#l$from_start",
 927                                              -class=>"list"}, $from_text);
 928                 }
 929                 if ($to->{'href'}) {
 930                         $to_text   = $cgi->a({-href=>"$to->{'href'}#l$to_start",
 931                                              -class=>"list"}, $to_text);
 932                 }
 933                 $line = "<span class=\"chunk_info\">@@ $from_text $to_text @@</span>" .
 934                         "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
 935                 return "<div class=\"diff$diff_class\">$line</div>\n";
 936         }
 937         return "<div class=\"diff$diff_class\">" . esc_html($line, -nbsp=>1) . "</div>\n";
 938 }
 939
 940 ## ----------------------------------------------------------------------
 941 ## git utility subroutines, invoking git commands
 942
 943 # returns path to the core git executable and the --git-dir parameter as list
 944 sub git_cmd {
 945         return $GIT, '--git-dir='.$git_dir;
 946 }
 947
 948 # returns path to the core git executable and the --git-dir parameter as string
 949 sub git_cmd_str {
 950         return join(' ', git_cmd());
 951 }
 952
 953 # get HEAD ref of given project as hash
 954 sub git_get_head_hash {
 955         my $project = shift;
 956         my $o_git_dir = $git_dir;
 957         my $retval = undef;
 958         $git_dir = "$projectroot/$project";
 959         if (open my $fd, "-|", git_cmd(), "rev-parse", "--verify", "HEAD") {
 960                 my $head = <$fd>;
 961                 close $fd;
 962                 if (defined $head && $head =~ /^([0-9a-fA-F]{40})$/) {
 963                         $retval = $1;
 964                 }
 965         }
 966         if (defined $o_git_dir) {
 967                 $git_dir = $o_git_dir;
 968         }
 969         return $retval;
 970 }
 971
 972 # get type of given object
 973 sub git_get_type {
 974         my $hash = shift;
 975
 976         open my $fd, "-|", git_cmd(), "cat-file", '-t', $hash or return;
 977         my $type = <$fd>;
 978         close $fd or return;
 979         chomp $type;
 980         return $type;
 981 }
 982
 983 sub git_get_project_config {
 984         my ($key, $type) = @_;
 985
 986         return unless ($key);
 987         $key =~ s/^gitweb\.//;
 988         return if ($key =~ m/\W/);
 989
 990         my @x = (git_cmd(), 'config');
 991         if (defined $type) { push @x, $type; }
 992         push @x, "--get";
 993         push @x, "gitweb.$key";
 994         my $val = qx(@x);
 995         chomp $val;
 996         return ($val);
 997 }
 998
 999 # get hash of given path at given ref
1000 sub git_get_hash_by_path {
1001         my $base = shift;
1002         my $path = shift || return undef;
1003         my $type = shift;
1004
1005         $path =~ s,/+$,,;
1006
1007         open my $fd, "-|", git_cmd(), "ls-tree", $base, "--", $path
1008                 or die_error(undef, "Open git-ls-tree failed");
1009         my $line = <$fd>;
1010         close $fd or return undef;
1011
1012         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
1013         $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/;
1014         if (defined $type && $type ne $2) {
1015                 # type doesn't match
1016                 return undef;
1017         }
1018         return $3;
1019 }
1020
1021 ## ......................................................................
1022 ## git utility functions, directly accessing git repository
1023
1024 sub git_get_project_description {
1025         my $path = shift;
1026
1027         open my $fd, "$projectroot/$path/description" or return undef;
1028         my $descr = <$fd>;
1029         close $fd;
1030         chomp $descr;
1031         return $descr;
1032 }
1033
1034 sub git_get_project_url_list {
1035         my $path = shift;
1036
1037         open my $fd, "$projectroot/$path/cloneurl" or return;
1038         my @git_project_url_list = map { chomp; $_ } <$fd>;
1039         close $fd;
1040
1041         return wantarray ? @git_project_url_list : \@git_project_url_list;
1042 }
1043
1044 sub git_get_projects_list {
1045         my ($filter) = @_;
1046         my @list;
1047
1048         $filter ||= '';
1049         $filter =~ s/\.git$//;
1050
1051         my ($check_forks) = gitweb_check_feature('forks');
1052
1053         if (-d $projects_list) {
1054                 # search in directory
1055                 my $dir = $projects_list . ($filter ? "/$filter" : '');
1056                 # remove the trailing "/"
1057                 $dir =~ s!/+$!!;
1058                 my $pfxlen = length("$dir");
1059
1060                 File::Find::find({
1061                         follow_fast => 1, # follow symbolic links
1062                         dangling_symlinks => 0, # ignore dangling symlinks, silently
1063                         wanted => sub {
1064                                 # skip project-list toplevel, if we get it.
1065                                 return if (m!^[/.]$!);
1066                                 # only directories can be git repositories
1067                                 return unless (-d $_);
1068
1069                                 my $subdir = substr($File::Find::name, $pfxlen + 1);
1070                                 # we check related file in $projectroot
1071                                 if ($check_forks and $subdir =~ m#/.#) {
1072                                         $File::Find::prune = 1;
1073                                 } elsif (check_export_ok("$projectroot/$filter/$subdir")) {
1074                                         push @list, { path => ($filter ? "$filter/" : '') . $subdir };
1075                                         $File::Find::prune = 1;
1076                                 }
1077                         },
1078                 }, "$dir");
1079
1080         } elsif (-f $projects_list) {
1081                 # read from file(url-encoded):
1082                 # 'git%2Fgit.git Linus+Torvalds'
1083                 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
1084                 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
1085                 my %paths;
1086                 open my ($fd), $projects_list or return;
1087         PROJECT:
1088                 while (my $line = <$fd>) {
1089                         chomp $line;
1090                         my ($path, $owner) = split ' ', $line;
1091                         $path = unescape($path);
1092                         $owner = unescape($owner);
1093                         if (!defined $path) {
1094                                 next;
1095                         }
1096                         if ($filter ne '') {
1097                                 # looking for forks;
1098                                 my $pfx = substr($path, 0, length($filter));
1099                                 if ($pfx ne $filter) {
1100                                         next PROJECT;
1101                                 }
1102                                 my $sfx = substr($path, length($filter));
1103                                 if ($sfx !~ /^\/.*\.git$/) {
1104                                         next PROJECT;
1105                                 }
1106                         } elsif ($check_forks) {
1107                         PATH:
1108                                 foreach my $filter (keys %paths) {
1109                                         # looking for forks;
1110                                         my $pfx = substr($path, 0, length($filter));
1111                                         if ($pfx ne $filter) {
1112                                                 next PATH;
1113                                         }
1114                                         my $sfx = substr($path, length($filter));
1115                                         if ($sfx !~ /^\/.*\.git$/) {
1116                                                 next PATH;
1117                                         }
1118                                         # is a fork, don't include it in
1119                                         # the list
1120                                         next PROJECT;
1121                                 }
1122                         }
1123                         if (check_export_ok("$projectroot/$path")) {
1124                                 my $pr = {
1125                                         path => $path,
1126                                         owner => to_utf8($owner),
1127                                 };
1128                                 push @list, $pr;
1129                                 (my $forks_path = $path) =~ s/\.git$//;
1130                                 $paths{$forks_path}++;
1131                         }
1132                 }
1133                 close $fd;
1134         }
1135         @list = sort {$a->{'path'} cmp $b->{'path'}} @list;
1136         return @list;
1137 }
1138
1139 sub git_get_project_owner {
1140         my $project = shift;
1141         my $owner;
1142
1143         return undef unless $project;
1144
1145         # read from file (url-encoded):
1146         # 'git%2Fgit.git Linus+Torvalds'
1147         # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
1148         # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
1149         if (-f $projects_list) {
1150                 open (my $fd , $projects_list);
1151                 while (my $line = <$fd>) {
1152                         chomp $line;
1153                         my ($pr, $ow) = split ' ', $line;
1154                         $pr = unescape($pr);
1155                         $ow = unescape($ow);
1156                         if ($pr eq $project) {
1157                                 $owner = to_utf8($ow);
1158                                 last;
1159                         }
1160                 }
1161                 close $fd;
1162         }
1163         if (!defined $owner) {
1164                 $owner = get_file_owner("$projectroot/$project");
1165         }
1166
1167         return $owner;
1168 }
1169
1170 sub git_get_last_activity {
1171         my ($path) = @_;
1172         my $fd;
1173
1174         $git_dir = "$projectroot/$path";
1175         open($fd, "-|", git_cmd(), 'for-each-ref',
1176              '--format=%(committer)',
1177              '--sort=-committerdate',
1178              '--count=1',
1179              'refs/heads') or return;
1180         my $most_recent = <$fd>;
1181         close $fd or return;
1182         if ($most_recent =~ / (\d+) [-+][01]\d\d\d$/) {
1183                 my $timestamp = $1;
1184                 my $age = time - $timestamp;
1185                 return ($age, age_string($age));
1186         }
1187 }
1188
1189 sub git_get_references {
1190         my $type = shift || "";
1191         my %refs;
1192         # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
1193         # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
1194         open my $fd, "-|", git_cmd(), "show-ref", "--dereference",
1195                 ($type ? ("--", "refs/$type") : ()) # use -- <pattern> if $type
1196                 or return;
1197
1198         while (my $line = <$fd>) {
1199                 chomp $line;
1200                 if ($line =~ m!^([0-9a-fA-F]{40})\srefs/($type/?[^^]+)!) {
1201                         if (defined $refs{$1}) {
1202                                 push @{$refs{$1}}, $2;
1203                         } else {
1204                                 $refs{$1} = [ $2 ];
1205                         }
1206                 }
1207         }
1208         close $fd or return;
1209         return \%refs;
1210 }
1211
1212 sub git_get_rev_name_tags {
1213         my $hash = shift || return undef;
1214
1215         open my $fd, "-|", git_cmd(), "name-rev", "--tags", $hash
1216                 or return;
1217         my $name_rev = <$fd>;
1218         close $fd;
1219
1220         if ($name_rev =~ m|^$hash tags/(.*)$|) {
1221                 return $1;
1222         } else {
1223                 # catches also '$hash undefined' output
1224                 return undef;
1225         }
1226 }
1227
1228 ## ----------------------------------------------------------------------
1229 ## parse to hash functions
1230
1231 sub parse_date {
1232         my $epoch = shift;
1233         my $tz = shift || "-0000";
1234
1235         my %date;
1236         my @months = ("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec");
1237         my @days = ("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");
1238         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($epoch);
1239         $date{'hour'} = $hour;
1240         $date{'minute'} = $min;
1241         $date{'mday'} = $mday;
1242         $date{'day'} = $days[$wday];
1243         $date{'month'} = $months[$mon];
1244         $date{'rfc2822'}   = sprintf "%s, %d %s %4d %02d:%02d:%02d +0000",
1245                              $days[$wday], $mday, $months[$mon], 1900+$year, $hour ,$min, $sec;
1246         $date{'mday-time'} = sprintf "%d %s %02d:%02d",
1247                              $mday, $months[$mon], $hour ,$min;
1248         $date{'iso-8601'}  = sprintf "%04d-%02d-%02dT%02d:%02d:%02dZ",
1249                              1900+$year, $mon, $mday, $hour ,$min, $sec;
1250
1251         $tz =~ m/^([+\-][0-9][0-9])([0-9][0-9])$/;
1252         my $local = $epoch + ((int $1 + ($2/60)) * 3600);
1253         ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($local);
1254         $date{'hour_local'} = $hour;
1255         $date{'minute_local'} = $min;
1256         $date{'tz_local'} = $tz;
1257         $date{'iso-tz'} = sprintf("%04d-%02d-%02d %02d:%02d:%02d %s",
1258                                   1900+$year, $mon+1, $mday,
1259                                   $hour, $min, $sec, $tz);
1260         return %date;
1261 }
1262
1263 sub parse_tag {
1264         my $tag_id = shift;
1265         my %tag;
1266         my @comment;
1267
1268         open my $fd, "-|", git_cmd(), "cat-file", "tag", $tag_id or return;
1269         $tag{'id'} = $tag_id;
1270         while (my $line = <$fd>) {
1271                 chomp $line;
1272                 if ($line =~ m/^object ([0-9a-fA-F]{40})$/) {
1273                         $tag{'object'} = $1;
1274                 } elsif ($line =~ m/^type (.+)$/) {
1275                         $tag{'type'} = $1;
1276                 } elsif ($line =~ m/^tag (.+)$/) {
1277                         $tag{'name'} = $1;
1278                 } elsif ($line =~ m/^tagger (.*) ([0-9]+) (.*)$/) {
1279                         $tag{'author'} = $1;
1280                         $tag{'epoch'} = $2;
1281                         $tag{'tz'} = $3;
1282                 } elsif ($line =~ m/--BEGIN/) {
1283                         push @comment, $line;
1284                         last;
1285                 } elsif ($line eq "") {
1286                         last;
1287                 }
1288         }
1289         push @comment, <$fd>;
1290         $tag{'comment'} = \@comment;
1291         close $fd or return;
1292         if (!defined $tag{'name'}) {
1293                 return
1294         };
1295         return %tag
1296 }
1297
1298 sub parse_commit_text {
1299         my ($commit_text, $withparents) = @_;
1300         my @commit_lines = split '\n', $commit_text;
1301         my %co;
1302
1303         pop @commit_lines; # Remove '\0'
1304
1305         my $header = shift @commit_lines;
1306         if (!($header =~ m/^[0-9a-fA-F]{40}/)) {
1307                 return;
1308         }
1309         ($co{'id'}, my @parents) = split ' ', $header;
1310         while (my $line = shift @commit_lines) {
1311                 last if $line eq "\n";
1312                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
1313                         $co{'tree'} = $1;
1314                 } elsif ((!defined $withparents) && ($line =~ m/^parent ([0-9a-fA-F]{40})$/)) {
1315                         push @parents, $1;
1316                 } elsif ($line =~ m/^author (.*) ([0-9]+) (.*)$/) {
1317                         $co{'author'} = $1;
1318                         $co{'author_epoch'} = $2;
1319                         $co{'author_tz'} = $3;
1320                         if ($co{'author'} =~ m/^([^<]+) <([^>]*)>/) {
1321                                 $co{'author_name'}  = $1;
1322                                 $co{'author_email'} = $2;
1323                         } else {
1324                                 $co{'author_name'} = $co{'author'};
1325                         }
1326                 } elsif ($line =~ m/^committer (.*) ([0-9]+) (.*)$/) {
1327                         $co{'committer'} = $1;
1328                         $co{'committer_epoch'} = $2;
1329                         $co{'committer_tz'} = $3;
1330                         $co{'committer_name'} = $co{'committer'};
1331                         if ($co{'committer'} =~ m/^([^<]+) <([^>]*)>/) {
1332                                 $co{'committer_name'}  = $1;
1333                                 $co{'committer_email'} = $2;
1334                         } else {
1335                                 $co{'committer_name'} = $co{'committer'};
1336                         }
1337                 }
1338         }
1339         if (!defined $co{'tree'}) {
1340                 return;
1341         };
1342         $co{'parents'} = \@parents;
1343         $co{'parent'} = $parents[0];
1344
1345         foreach my $title (@commit_lines) {
1346                 $title =~ s/^    //;
1347                 if ($title ne "") {
1348                         $co{'title'} = chop_str($title, 80, 5);
1349                         # remove leading stuff of merges to make the interesting part visible
1350                         if (length($title) > 50) {
1351                                 $title =~ s/^Automatic //;
1352                                 $title =~ s/^merge (of|with) /Merge ... /i;
1353                                 if (length($title) > 50) {
1354                                         $title =~ s/(http|rsync):\/\///;
1355                                 }
1356                                 if (length($title) > 50) {
1357                                         $title =~ s/(master|www|rsync)\.//;
1358                                 }
1359                                 if (length($title) > 50) {
1360                                         $title =~ s/kernel.org:?//;
1361                                 }
1362                                 if (length($title) > 50) {
1363                                         $title =~ s/\/pub\/scm//;
1364                                 }
1365                         }
1366                         $co{'title_short'} = chop_str($title, 50, 5);
1367                         last;
1368                 }
1369         }
1370         if ($co{'title'} eq "") {
1371                 $co{'title'} = $co{'title_short'} = '(no commit message)';
1372         }
1373         # remove added spaces
1374         foreach my $line (@commit_lines) {
1375                 $line =~ s/^    //;
1376         }
1377         $co{'comment'} = \@commit_lines;
1378
1379         my $age = time - $co{'committer_epoch'};
1380         $co{'age'} = $age;
1381         $co{'age_string'} = age_string($age);
1382         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($co{'committer_epoch'});
1383         if ($age > 60*60*24*7*2) {
1384                 $co{'age_string_date'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
1385                 $co{'age_string_age'} = $co{'age_string'};
1386         } else {
1387                 $co{'age_string_date'} = $co{'age_string'};
1388                 $co{'age_string_age'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
1389         }
1390         return %co;
1391 }
1392
1393 sub parse_commit {
1394         my ($commit_id) = @_;
1395         my %co;
1396
1397         local $/ = "\0";
1398
1399         open my $fd, "-|", git_cmd(), "rev-list",
1400                 "--parents",
1401                 "--header",
1402                 "--max-count=1",
1403                 $commit_id,
1404                 "--",
1405                 or die_error(undef, "Open git-rev-list failed");
1406         %co = parse_commit_text(<$fd>, 1);
1407         close $fd;
1408
1409         return %co;
1410 }
1411
1412 sub parse_commits {
1413         my ($commit_id, $maxcount, $skip, $arg, $filename) = @_;
1414         my @cos;
1415
1416         $maxcount ||= 1;
1417         $skip ||= 0;
1418
1419         local $/ = "\0";
1420
1421         open my $fd, "-|", git_cmd(), "rev-list",
1422                 "--header",
1423                 ($arg ? ($arg) : ()),
1424                 ("--max-count=" . $maxcount),
1425                 ("--skip=" . $skip),
1426                 $commit_id,
1427                 "--",
1428                 ($filename ? ($filename) : ())
1429                 or die_error(undef, "Open git-rev-list failed");
1430         while (my $line = <$fd>) {
1431                 my %co = parse_commit_text($line);
1432                 push @cos, \%co;
1433         }
1434         close $fd;
1435
1436         return wantarray ? @cos : \@cos;
1437 }
1438
1439 # parse ref from ref_file, given by ref_id, with given type
1440 sub parse_ref {
1441         my $ref_file = shift;
1442         my $ref_id = shift;
1443         my $type = shift || git_get_type($ref_id);
1444         my %ref_item;
1445
1446         $ref_item{'type'} = $type;
1447         $ref_item{'id'} = $ref_id;
1448         $ref_item{'epoch'} = 0;
1449         $ref_item{'age'} = "unknown";
1450         if ($type eq "tag") {
1451                 my %tag = parse_tag($ref_id);
1452                 $ref_item{'comment'} = $tag{'comment'};
1453                 if ($tag{'type'} eq "commit") {
1454                         my %co = parse_commit($tag{'object'});
1455                         $ref_item{'epoch'} = $co{'committer_epoch'};
1456                         $ref_item{'age'} = $co{'age_string'};
1457                 } elsif (defined($tag{'epoch'})) {
1458                         my $age = time - $tag{'epoch'};
1459                         $ref_item{'epoch'} = $tag{'epoch'};
1460                         $ref_item{'age'} = age_string($age);
1461                 }
1462                 $ref_item{'reftype'} = $tag{'type'};
1463                 $ref_item{'name'} = $tag{'name'};
1464                 $ref_item{'refid'} = $tag{'object'};
1465         } elsif ($type eq "commit"){
1466                 my %co = parse_commit($ref_id);
1467                 $ref_item{'reftype'} = "commit";
1468                 $ref_item{'name'} = $ref_file;
1469                 $ref_item{'title'} = $co{'title'};
1470                 $ref_item{'refid'} = $ref_id;
1471                 $ref_item{'epoch'} = $co{'committer_epoch'};
1472                 $ref_item{'age'} = $co{'age_string'};
1473         } else {
1474                 $ref_item{'reftype'} = $type;
1475                 $ref_item{'name'} = $ref_file;
1476                 $ref_item{'refid'} = $ref_id;
1477         }
1478
1479         return %ref_item;
1480 }
1481
1482 # parse line of git-diff-tree "raw" output
1483 sub parse_difftree_raw_line {
1484         my $line = shift;
1485         my %res;
1486
1487         # ':100644 100644 03b218260e99b78c6df0ed378e59ed9205ccc96d 3b93d5e7cc7f7dd4ebed13a5cc1a4ad976fc94d8 M   ls-files.c'
1488         # ':100644 100644 7f9281985086971d3877aca27704f2aaf9c448ce bc190ebc71bbd923f2b728e505408f5e54bd073a M   rev-tree.c'
1489         if ($line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)([0-9]{0,3})\t(.*)$/) {
1490                 $res{'from_mode'} = $1;
1491                 $res{'to_mode'} = $2;
1492                 $res{'from_id'} = $3;
1493                 $res{'to_id'} = $4;
1494                 $res{'status'} = $5;
1495                 $res{'similarity'} = $6;
1496                 if ($res{'status'} eq 'R' || $res{'status'} eq 'C') { # renamed or copied
1497                         ($res{'from_file'}, $res{'to_file'}) = map { unquote($_) } split("\t", $7);
1498                 } else {
1499                         $res{'file'} = unquote($7);
1500                 }
1501         }
1502         # 'c512b523472485aef4fff9e57b229d9d243c967f'
1503         elsif ($line =~ m/^([0-9a-fA-F]{40})$/) {
1504                 $res{'commit'} = $1;
1505         }
1506
1507         return wantarray ? %res : \%res;
1508 }
1509
1510 # parse line of git-ls-tree output
1511 sub parse_ls_tree_line ($;%) {
1512         my $line = shift;
1513         my %opts = @_;
1514         my %res;
1515
1516         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
1517         $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t(.+)$/s;
1518
1519         $res{'mode'} = $1;
1520         $res{'type'} = $2;
1521         $res{'hash'} = $3;
1522         if ($opts{'-z'}) {
1523                 $res{'name'} = $4;
1524         } else {
1525                 $res{'name'} = unquote($4);
1526         }
1527
1528         return wantarray ? %res : \%res;
1529 }
1530
1531 ## ......................................................................
1532 ## parse to array of hashes functions
1533
1534 sub git_get_heads_list {
1535         my $limit = shift;
1536         my @headslist;
1537
1538         open my $fd, '-|', git_cmd(), 'for-each-ref',
1539                 ($limit ? '--count='.($limit+1) : ()), '--sort=-committerdate',
1540                 '--format=%(objectname) %(refname) %(subject)%00%(committer)',
1541                 'refs/heads'
1542                 or return;
1543         while (my $line = <$fd>) {
1544                 my %ref_item;
1545
1546                 chomp $line;
1547                 my ($refinfo, $committerinfo) = split(/\0/, $line);
1548                 my ($hash, $name, $title) = split(' ', $refinfo, 3);
1549                 my ($committer, $epoch, $tz) =
1550                         ($committerinfo =~ /^(.*) ([0-9]+) (.*)$/);
1551                 $name =~ s!^refs/heads/!!;
1552
1553                 $ref_item{'name'}  = $name;
1554                 $ref_item{'id'}    = $hash;
1555                 $ref_item{'title'} = $title || '(no commit message)';
1556                 $ref_item{'epoch'} = $epoch;
1557                 if ($epoch) {
1558                         $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
1559                 } else {
1560                         $ref_item{'age'} = "unknown";
1561                 }
1562
1563                 push @headslist, \%ref_item;
1564         }
1565         close $fd;
1566
1567         return wantarray ? @headslist : \@headslist;
1568 }
1569
1570 sub git_get_tags_list {
1571         my $limit = shift;
1572         my @tagslist;
1573
1574         open my $fd, '-|', git_cmd(), 'for-each-ref',
1575                 ($limit ? '--count='.($limit+1) : ()), '--sort=-creatordate',
1576                 '--format=%(objectname) %(objecttype) %(refname) '.
1577                 '%(*objectname) %(*objecttype) %(subject)%00%(creator)',
1578                 'refs/tags'
1579                 or return;
1580         while (my $line = <$fd>) {
1581                 my %ref_item;
1582
1583                 chomp $line;
1584                 my ($refinfo, $creatorinfo) = split(/\0/, $line);
1585                 my ($id, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
1586                 my ($creator, $epoch, $tz) =
1587                         ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
1588                 $name =~ s!^refs/tags/!!;
1589
1590                 $ref_item{'type'} = $type;
1591                 $ref_item{'id'} = $id;
1592                 $ref_item{'name'} = $name;
1593                 if ($type eq "tag") {
1594                         $ref_item{'subject'} = $title;
1595                         $ref_item{'reftype'} = $reftype;
1596                         $ref_item{'refid'}   = $refid;
1597                 } else {
1598                         $ref_item{'reftype'} = $type;
1599                         $ref_item{'refid'}   = $id;
1600                 }
1601
1602                 if ($type eq "tag" || $type eq "commit") {
1603                         $ref_item{'epoch'} = $epoch;
1604                         if ($epoch) {
1605                                 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
1606                         } else {
1607                                 $ref_item{'age'} = "unknown";
1608                         }
1609                 }
1610
1611                 push @tagslist, \%ref_item;
1612         }
1613         close $fd;
1614
1615         return wantarray ? @tagslist : \@tagslist;
1616 }
1617
1618 ## ----------------------------------------------------------------------
1619 ## filesystem-related functions
1620
1621 sub get_file_owner {
1622         my $path = shift;
1623
1624         my ($dev, $ino, $mode, $nlink, $st_uid, $st_gid, $rdev, $size) = stat($path);
1625         my ($name, $passwd, $uid, $gid, $quota, $comment, $gcos, $dir, $shell) = getpwuid($st_uid);
1626         if (!defined $gcos) {
1627                 return undef;
1628         }
1629         my $owner = $gcos;
1630         $owner =~ s/[,;].*$//;
1631         return to_utf8($owner);
1632 }
1633
1634 ## ......................................................................
1635 ## mimetype related functions
1636
1637 sub mimetype_guess_file {
1638         my $filename = shift;
1639         my $mimemap = shift;
1640         -r $mimemap or return undef;
1641
1642         my %mimemap;
1643         open(MIME, $mimemap) or return undef;
1644         while (<MIME>) {
1645                 next if m/^#/; # skip comments
1646                 my ($mime, $exts) = split(/\t+/);
1647                 if (defined $exts) {
1648                         my @exts = split(/\s+/, $exts);
1649                         foreach my $ext (@exts) {
1650                                 $mimemap{$ext} = $mime;
1651                         }
1652                 }
1653         }
1654         close(MIME);
1655
1656         $filename =~ /\.([^.]*)$/;
1657         return $mimemap{$1};
1658 }
1659
1660 sub mimetype_guess {
1661         my $filename = shift;
1662         my $mime;
1663         $filename =~ /\./ or return undef;
1664
1665         if ($mimetypes_file) {
1666                 my $file = $mimetypes_file;
1667                 if ($file !~ m!^/!) { # if it is relative path
1668                         # it is relative to project
1669                         $file = "$projectroot/$project/$file";
1670                 }
1671                 $mime = mimetype_guess_file($filename, $file);
1672         }
1673         $mime ||= mimetype_guess_file($filename, '/etc/mime.types');
1674         return $mime;
1675 }
1676
1677 sub blob_mimetype {
1678         my $fd = shift;
1679         my $filename = shift;
1680
1681         if ($filename) {
1682                 my $mime = mimetype_guess($filename);
1683                 $mime and return $mime;
1684         }
1685
1686         # just in case
1687         return $default_blob_plain_mimetype unless $fd;
1688
1689         if (-T $fd) {
1690                 return 'text/plain' .
1691                        ($default_text_plain_charset ? '; charset='.$default_text_plain_charset : '');
1692         } elsif (! $filename) {
1693                 return 'application/octet-stream';
1694         } elsif ($filename =~ m/\.png$/i) {
1695                 return 'image/png';
1696         } elsif ($filename =~ m/\.gif$/i) {
1697                 return 'image/gif';
1698         } elsif ($filename =~ m/\.jpe?g$/i) {
1699                 return 'image/jpeg';
1700         } else {
1701                 return 'application/octet-stream';
1702         }
1703 }
1704
1705 ## ======================================================================
1706 ## functions printing HTML: header, footer, error page
1707
1708 sub git_header_html {
1709         my $status = shift || "200 OK";
1710         my $expires = shift;
1711
1712         my $title = "$site_name";
1713         if (defined $project) {
1714                 $title .= " - " . to_utf8($project);
1715                 if (defined $action) {
1716                         $title .= "/$action";
1717                         if (defined $file_name) {
1718                                 $title .= " - " . esc_path($file_name);
1719                                 if ($action eq "tree" && $file_name !~ m|/$|) {
1720                                         $title .= "/";
1721                                 }
1722                         }
1723                 }
1724         }
1725         my $content_type;
1726         # require explicit support from the UA if we are to send the page as
1727         # 'application/xhtml+xml', otherwise send it as plain old 'text/html'.
1728         # we have to do this because MSIE sometimes globs '*/*', pretending to
1729         # support xhtml+xml but choking when it gets what it asked for.
1730         if (defined $cgi->http('HTTP_ACCEPT') &&
1731             $cgi->http('HTTP_ACCEPT') =~ m/(,|;|\s|^)application\/xhtml\+xml(,|;|\s|$)/ &&
1732             $cgi->Accept('application/xhtml+xml') != 0) {
1733                 $content_type = 'application/xhtml+xml';
1734         } else {
1735                 $content_type = 'text/html';
1736         }
1737         print $cgi->header(-type=>$content_type, -charset => 'utf-8',
1738                            -status=> $status, -expires => $expires);
1739         my $mod_perl_version = $ENV{'MOD_PERL'} ? " $ENV{'MOD_PERL'}" : '';
1740         print <<EOF;
1741 <?xml version="1.0" encoding="utf-8"?>
1742 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
1743 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en-US" lang="en-US">
1744 <!-- git web interface version $version, (C) 2005-2006, Kay Sievers <kay.sievers\@vrfy.org>, Christian Gierke -->
1745 <!-- git core binaries version $git_version -->
1746 <head>
1747 <meta http-equiv="content-type" content="$content_type; charset=utf-8"/>
1748 <meta name="generator" content="gitweb/$version git/$git_version$mod_perl_version"/>
1749 <meta name="robots" content="index, nofollow"/>
1750 <title>$title</title>
1751 EOF
1752 # print out each stylesheet that exist
1753         if (defined $stylesheet) {
1754 #provides backwards capability for those people who define style sheet in a config file
1755                 print '<link rel="stylesheet" type="text/css" href="'.$stylesheet.'"/>'."\n";
1756         } else {
1757                 foreach my $stylesheet (@stylesheets) {
1758                         next unless $stylesheet;
1759                         print '<link rel="stylesheet" type="text/css" href="'.$stylesheet.'"/>'."\n";
1760                 }
1761         }
1762         if (defined $project) {
1763                 printf('<link rel="alternate" title="%s log RSS feed" '.
1764                        'href="%s" type="application/rss+xml" />'."\n",
1765                        esc_param($project), href(action=>"rss"));
1766                 printf('<link rel="alternate" title="%s log Atom feed" '.
1767                        'href="%s" type="application/atom+xml" />'."\n",
1768                        esc_param($project), href(action=>"atom"));
1769         } else {
1770                 printf('<link rel="alternate" title="%s projects list" '.
1771                        'href="%s" type="text/plain; charset=utf-8"/>'."\n",
1772                        $site_name, href(project=>undef, action=>"project_index"));
1773                 printf('<link rel="alternate" title="%s projects feeds" '.
1774                        'href="%s" type="text/x-opml"/>'."\n",
1775                        $site_name, href(project=>undef, action=>"opml"));
1776         }
1777         if (defined $favicon) {
1778                 print qq(<link rel="shortcut icon" href="$favicon" type="image/png"/>\n);
1779         }
1780
1781         print "</head>\n" .
1782               "<body>\n";
1783
1784         if (-f $site_header) {
1785                 open (my $fd, $site_header);
1786                 print <$fd>;
1787                 close $fd;
1788         }
1789
1790         print "<div class=\"page_header\">\n" .
1791               $cgi->a({-href => esc_url($logo_url),
1792                        -title => $logo_label},
1793                       qq(<img src="$logo" width="72" height="27" alt="git" class="logo"/>));
1794         print $cgi->a({-href => esc_url($home_link)}, $home_link_str) . " / ";
1795         if (defined $project) {
1796                 print $cgi->a({-href => href(action=>"summary")}, esc_html($project));
1797                 if (defined $action) {
1798                         print " / $action";
1799                 }
1800                 print "\n";
1801         }
1802         my ($have_search) = gitweb_check_feature('search');
1803         if ((defined $project) && ($have_search)) {
1804                 if (!defined $searchtext) {
1805                         $searchtext = "";
1806                 }
1807                 my $search_hash;
1808                 if (defined $hash_base) {
1809                         $search_hash = $hash_base;
1810                 } elsif (defined $hash) {
1811                         $search_hash = $hash;
1812                 } else {
1813                         $search_hash = "HEAD";
1814                 }
1815                 $cgi->param("a", "search");
1816                 $cgi->param("h", $search_hash);
1817                 $cgi->param("p", $project);
1818                 print $cgi->startform(-method => "get", -action => $my_uri) .
1819                       "<div class=\"search\">\n" .
1820                       $cgi->hidden(-name => "p") . "\n" .
1821                       $cgi->hidden(-name => "a") . "\n" .
1822                       $cgi->hidden(-name => "h") . "\n" .
1823                       $cgi->popup_menu(-name => 'st', -default => 'commit',
1824                                        -values => ['commit', 'author', 'committer', 'pickaxe']) .
1825                       $cgi->sup($cgi->a({-href => href(action=>"search_help")}, "?")) .
1826                       " search:\n",
1827                       $cgi->textfield(-name => "s", -value => $searchtext) . "\n" .
1828                       "</div>" .
1829                       $cgi->end_form() . "\n";
1830         }
1831         print "</div>\n";
1832 }
1833
1834 sub git_footer_html {
1835         print "<div class=\"page_footer\">\n";
1836         if (defined $project) {
1837                 my $descr = git_get_project_description($project);
1838                 if (defined $descr) {
1839                         print "<div class=\"page_footer_text\">" . esc_html($descr) . "</div>\n";
1840                 }
1841                 print $cgi->a({-href => href(action=>"rss"),
1842                               -class => "rss_logo"}, "RSS") . " ";
1843                 print $cgi->a({-href => href(action=>"atom"),
1844                               -class => "rss_logo"}, "Atom") . "\n";
1845         } else {
1846                 print $cgi->a({-href => href(project=>undef, action=>"opml"),
1847                               -class => "rss_logo"}, "OPML") . " ";
1848                 print $cgi->a({-href => href(project=>undef, action=>"project_index"),
1849                               -class => "rss_logo"}, "TXT") . "\n";
1850         }
1851         print "</div>\n" ;
1852
1853         if (-f $site_footer) {
1854                 open (my $fd, $site_footer);
1855                 print <$fd>;
1856                 close $fd;
1857         }
1858
1859         print "</body>\n" .
1860               "</html>";
1861 }
1862
1863 sub die_error {
1864         my $status = shift || "403 Forbidden";
1865         my $error = shift || "Malformed query, file missing or permission denied";
1866
1867         git_header_html($status);
1868         print <<EOF;
1869 <div class="page_body">
1870 <br /><br />
1871 $status - $error
1872 <br />
1873 </div>
1874 EOF
1875         git_footer_html();
1876         exit;
1877 }
1878
1879 ## ----------------------------------------------------------------------
1880 ## functions printing or outputting HTML: navigation
1881
1882 sub git_print_page_nav {
1883         my ($current, $suppress, $head, $treehead, $treebase, $extra) = @_;
1884         $extra = '' if !defined $extra; # pager or formats
1885
1886         my @navs = qw(summary shortlog log commit commitdiff tree);
1887         if ($suppress) {
1888                 @navs = grep { $_ ne $suppress } @navs;
1889         }
1890
1891         my %arg = map { $_ => {action=>$_} } @navs;
1892         if (defined $head) {
1893                 for (qw(commit commitdiff)) {
1894                         $arg{$_}{'hash'} = $head;
1895                 }
1896                 if ($current =~ m/^(tree | log | shortlog | commit | commitdiff | search)$/x) {
1897                         for (qw(shortlog log)) {
1898                                 $arg{$_}{'hash'} = $head;
1899                         }
1900                 }
1901         }
1902         $arg{'tree'}{'hash'} = $treehead if defined $treehead;
1903         $arg{'tree'}{'hash_base'} = $treebase if defined $treebase;
1904
1905         print "<div class=\"page_nav\">\n" .
1906                 (join " | ",
1907                  map { $_ eq $current ?
1908                        $_ : $cgi->a({-href => href(%{$arg{$_}})}, "$_")
1909                  } @navs);
1910         print "<br/>\n$extra<br/>\n" .
1911               "</div>\n";
1912 }
1913
1914 sub format_paging_nav {
1915         my ($action, $hash, $head, $page, $nrevs) = @_;
1916         my $paging_nav;
1917
1918
1919         if ($hash ne $head || $page) {
1920                 $paging_nav .= $cgi->a({-href => href(action=>$action)}, "HEAD");
1921         } else {
1922                 $paging_nav .= "HEAD";
1923         }
1924
1925         if ($page > 0) {
1926                 $paging_nav .= " &sdot; " .
1927                         $cgi->a({-href => href(action=>$action, hash=>$hash, page=>$page-1),
1928                                  -accesskey => "p", -title => "Alt-p"}, "prev");
1929         } else {
1930                 $paging_nav .= " &sdot; prev";
1931         }
1932
1933         if ($nrevs >= (100 * ($page+1)-1)) {
1934                 $paging_nav .= " &sdot; " .
1935                         $cgi->a({-href => href(action=>$action, hash=>$hash, page=>$page+1),
1936                                  -accesskey => "n", -title => "Alt-n"}, "next");
1937         } else {
1938                 $paging_nav .= " &sdot; next";
1939         }
1940
1941         return $paging_nav;
1942 }
1943
1944 ## ......................................................................
1945 ## functions printing or outputting HTML: div
1946
1947 sub git_print_header_div {
1948         my ($action, $title, $hash, $hash_base) = @_;
1949         my %args = ();
1950
1951         $args{'action'} = $action;
1952         $args{'hash'} = $hash if $hash;
1953         $args{'hash_base'} = $hash_base if $hash_base;
1954
1955         print "<div class=\"header\">\n" .
1956               $cgi->a({-href => href(%args), -class => "title"},
1957               $title ? $title : $action) .
1958               "\n</div>\n";
1959 }
1960
1961 #sub git_print_authorship (\%) {
1962 sub git_print_authorship {
1963         my $co = shift;
1964
1965         my %ad = parse_date($co->{'author_epoch'}, $co->{'author_tz'});
1966         print "<div class=\"author_date\">" .
1967               esc_html($co->{'author_name'}) .
1968               " [$ad{'rfc2822'}";
1969         if ($ad{'hour_local'} < 6) {
1970                 printf(" (<span class=\"atnight\">%02d:%02d</span> %s)",
1971                        $ad{'hour_local'}, $ad{'minute_local'}, $ad{'tz_local'});
1972         } else {
1973                 printf(" (%02d:%02d %s)",
1974                        $ad{'hour_local'}, $ad{'minute_local'}, $ad{'tz_local'});
1975         }
1976         print "]</div>\n";
1977 }
1978
1979 sub git_print_page_path {
1980         my $name = shift;
1981         my $type = shift;
1982         my $hb = shift;
1983
1984
1985         print "<div class=\"page_path\">";
1986         print $cgi->a({-href => href(action=>"tree", hash_base=>$hb),
1987                       -title => 'tree root'}, to_utf8("[$project]"));
1988         print " / ";
1989         if (defined $name) {
1990                 my @dirname = split '/', $name;
1991                 my $basename = pop @dirname;
1992                 my $fullname = '';
1993
1994                 foreach my $dir (@dirname) {
1995                         $fullname .= ($fullname ? '/' : '') . $dir;
1996                         print $cgi->a({-href => href(action=>"tree", file_name=>$fullname,
1997                                                      hash_base=>$hb),
1998                                       -title => $fullname}, esc_path($dir));
1999                         print " / ";
2000                 }
2001                 if (defined $type && $type eq 'blob') {
2002                         print $cgi->a({-href => href(action=>"blob_plain", file_name=>$file_name,
2003                                                      hash_base=>$hb),
2004                                       -title => $name}, esc_path($basename));
2005                 } elsif (defined $type && $type eq 'tree') {
2006                         print $cgi->a({-href => href(action=>"tree", file_name=>$file_name,
2007                                                      hash_base=>$hb),
2008                                       -title => $name}, esc_path($basename));
2009                         print " / ";
2010                 } else {
2011                         print esc_path($basename);
2012                 }
2013         }
2014         print "<br/></div>\n";
2015 }
2016
2017 # sub git_print_log (\@;%) {
2018 sub git_print_log ($;%) {
2019         my $log = shift;
2020         my %opts = @_;
2021
2022         if ($opts{'-remove_title'}) {
2023                 # remove title, i.e. first line of log
2024                 shift @$log;
2025         }
2026         # remove leading empty lines
2027         while (defined $log->[0] && $log->[0] eq "") {
2028                 shift @$log;
2029         }
2030
2031         # print log
2032         my $signoff = 0;
2033         my $empty = 0;
2034         foreach my $line (@$log) {
2035                 if ($line =~ m/^ *(signed[ \-]off[ \-]by[ :]|acked[ \-]by[ :]|cc[ :])/i) {
2036                         $signoff = 1;
2037                         $empty = 0;
2038                         if (! $opts{'-remove_signoff'}) {
2039                                 print "<span class=\"signoff\">" . esc_html($line) . "</span><br/>\n";
2040                                 next;
2041                         } else {
2042                                 # remove signoff lines
2043                                 next;
2044                         }
2045                 } else {
2046                         $signoff = 0;
2047                 }
2048
2049                 # print only one empty line
2050                 # do not print empty line after signoff
2051                 if ($line eq "") {
2052                         next if ($empty || $signoff);
2053                         $empty = 1;
2054                 } else {
2055                         $empty = 0;
2056                 }
2057
2058                 print format_log_line_html($line) . "<br/>\n";
2059         }
2060
2061         if ($opts{'-final_empty_line'}) {
2062                 # end with single empty line
2063                 print "<br/>\n" unless $empty;
2064         }
2065 }
2066
2067 # return link target (what link points to)
2068 sub git_get_link_target {
2069         my $hash = shift;
2070         my $link_target;
2071
2072         # read link
2073         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
2074                 or return;
2075         {
2076                 local $/;
2077                 $link_target = <$fd>;
2078         }
2079         close $fd
2080                 or return;
2081
2082         return $link_target;
2083 }
2084
2085 # given link target, and the directory (basedir) the link is in,
2086 # return target of link relative to top directory (top tree);
2087 # return undef if it is not possible (including absolute links).
2088 sub normalize_link_target {
2089         my ($link_target, $basedir, $hash_base) = @_;
2090
2091         # we can normalize symlink target only if $hash_base is provided
2092         return unless $hash_base;
2093
2094         # absolute symlinks (beginning with '/') cannot be normalized
2095         return if (substr($link_target, 0, 1) eq '/');
2096
2097         # normalize link target to path from top (root) tree (dir)
2098         my $path;
2099         if ($basedir) {
2100                 $path = $basedir . '/' . $link_target;
2101         } else {
2102                 # we are in top (root) tree (dir)
2103                 $path = $link_target;
2104         }
2105
2106         # remove //, /./, and /../
2107         my @path_parts;
2108         foreach my $part (split('/', $path)) {
2109                 # discard '.' and ''
2110                 next if (!$part || $part eq '.');
2111                 # handle '..'
2112                 if ($part eq '..') {
2113                         if (@path_parts) {
2114                                 pop @path_parts;
2115                         } else {
2116                                 # link leads outside repository (outside top dir)
2117                                 return;
2118                         }
2119                 } else {
2120                         push @path_parts, $part;
2121                 }
2122         }
2123         $path = join('/', @path_parts);
2124
2125         return $path;
2126 }
2127
2128 # print tree entry (row of git_tree), but without encompassing <tr> element
2129 sub git_print_tree_entry {
2130         my ($t, $basedir, $hash_base, $have_blame) = @_;
2131
2132         my %base_key = ();
2133         $base_key{'hash_base'} = $hash_base if defined $hash_base;
2134
2135         # The format of a table row is: mode list link.  Where mode is
2136         # the mode of the entry, list is the name of the entry, an href,
2137         # and link is the action links of the entry.
2138
2139         print "<td class=\"mode\">" . mode_str($t->{'mode'}) . "</td>\n";
2140         if ($t->{'type'} eq "blob") {
2141                 print "<td class=\"list\">" .
2142                         $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
2143                                                file_name=>"$basedir$t->{'name'}", %base_key),
2144                                 -class => "list"}, esc_path($t->{'name'}));
2145                 if (S_ISLNK(oct $t->{'mode'})) {
2146                         my $link_target = git_get_link_target($t->{'hash'});
2147                         if ($link_target) {
2148                                 my $norm_target = normalize_link_target($link_target, $basedir, $hash_base);
2149                                 if (defined $norm_target) {
2150                                         print " -> " .
2151                                               $cgi->a({-href => href(action=>"object", hash_base=>$hash_base,
2152                                                                      file_name=>$norm_target),
2153                                                        -title => $norm_target}, esc_path($link_target));
2154                                 } else {
2155                                         print " -> " . esc_path($link_target);
2156                                 }
2157                         }
2158                 }
2159                 print "</td>\n";
2160                 print "<td class=\"link\">";
2161                 print $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
2162                                              file_name=>"$basedir$t->{'name'}", %base_key)},
2163                               "blob");
2164                 if ($have_blame) {
2165                         print " | " .
2166                               $cgi->a({-href => href(action=>"blame", hash=>$t->{'hash'},
2167                                                      file_name=>"$basedir$t->{'name'}", %base_key)},
2168                                       "blame");
2169                 }
2170                 if (defined $hash_base) {
2171                         print " | " .
2172                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
2173                                                      hash=>$t->{'hash'}, file_name=>"$basedir$t->{'name'}")},
2174                                       "history");
2175                 }
2176                 print " | " .
2177                         $cgi->a({-href => href(action=>"blob_plain", hash_base=>$hash_base,
2178                                                file_name=>"$basedir$t->{'name'}")},
2179                                 "raw");
2180                 print "</td>\n";
2181
2182         } elsif ($t->{'type'} eq "tree") {
2183                 print "<td class=\"list\">";
2184                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
2185                                              file_name=>"$basedir$t->{'name'}", %base_key)},
2186                               esc_path($t->{'name'}));
2187                 print "</td>\n";
2188                 print "<td class=\"link\">";
2189                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
2190                                              file_name=>"$basedir$t->{'name'}", %base_key)},
2191                               "tree");
2192                 if (defined $hash_base) {
2193                         print " | " .
2194                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
2195                                                      file_name=>"$basedir$t->{'name'}")},
2196                                       "history");
2197                 }
2198                 print "</td>\n";
2199         }
2200 }
2201
2202 ## ......................................................................
2203 ## functions printing large fragments of HTML
2204
2205 sub git_difftree_body {
2206         my ($difftree, $hash, $parent) = @_;
2207         my ($have_blame) = gitweb_check_feature('blame');
2208         print "<div class=\"list_head\">\n";
2209         if ($#{$difftree} > 10) {
2210                 print(($#{$difftree} + 1) . " files changed:\n");
2211         }
2212         print "</div>\n";
2213
2214         print "<table class=\"diff_tree\">\n";
2215         my $alternate = 1;
2216         my $patchno = 0;
2217         foreach my $line (@{$difftree}) {
2218                 my %diff = parse_difftree_raw_line($line);
2219
2220                 if ($alternate) {
2221                         print "<tr class=\"dark\">\n";
2222                 } else {
2223                         print "<tr class=\"light\">\n";
2224                 }
2225                 $alternate ^= 1;
2226
2227                 my ($to_mode_oct, $to_mode_str, $to_file_type);
2228                 my ($from_mode_oct, $from_mode_str, $from_file_type);
2229                 if ($diff{'to_mode'} ne ('0' x 6)) {
2230                         $to_mode_oct = oct $diff{'to_mode'};
2231                         if (S_ISREG($to_mode_oct)) { # only for regular file
2232                                 $to_mode_str = sprintf("%04o", $to_mode_oct & 0777); # permission bits
2233                         }
2234                         $to_file_type = file_type($diff{'to_mode'});
2235                 }
2236                 if ($diff{'from_mode'} ne ('0' x 6)) {
2237                         $from_mode_oct = oct $diff{'from_mode'};
2238                         if (S_ISREG($to_mode_oct)) { # only for regular file
2239                                 $from_mode_str = sprintf("%04o", $from_mode_oct & 0777); # permission bits
2240                         }
2241                         $from_file_type = file_type($diff{'from_mode'});
2242                 }
2243
2244                 if ($diff{'status'} eq "A") { # created
2245                         my $mode_chng = "<span class=\"file_status new\">[new $to_file_type";
2246                         $mode_chng   .= " with mode: $to_mode_str" if $to_mode_str;
2247                         $mode_chng   .= "]</span>";
2248                         print "<td>";
2249                         print $cgi->a({-href => href(action=>"blob", hash=>$diff{'to_id'},
2250                                                      hash_base=>$hash, file_name=>$diff{'file'}),
2251                                       -class => "list"}, esc_path($diff{'file'}));
2252                         print "</td>\n";
2253                         print "<td>$mode_chng</td>\n";
2254                         print "<td class=\"link\">";
2255                         if ($action eq 'commitdiff') {
2256                                 # link to patch
2257                                 $patchno++;
2258                                 print $cgi->a({-href => "#patch$patchno"}, "patch");
2259                                 print " | ";
2260                         }
2261                         print $cgi->a({-href => href(action=>"blob", hash=>$diff{'to_id'},
2262                                                      hash_base=>$hash, file_name=>$diff{'file'})},
2263                                       "blob");
2264                         print "</td>\n";
2265
2266                 } elsif ($diff{'status'} eq "D") { # deleted
2267                         my $mode_chng = "<span class=\"file_status deleted\">[deleted $from_file_type]</span>";
2268                         print "<td>";
2269                         print $cgi->a({-href => href(action=>"blob", hash=>$diff{'from_id'},
2270                                                      hash_base=>$parent, file_name=>$diff{'file'}),
2271                                        -class => "list"}, esc_path($diff{'file'}));
2272                         print "</td>\n";
2273                         print "<td>$mode_chng</td>\n";
2274                         print "<td class=\"link\">";
2275                         if ($action eq 'commitdiff') {
2276                                 # link to patch
2277                                 $patchno++;
2278                                 print $cgi->a({-href => "#patch$patchno"}, "patch");
2279                                 print " | ";
2280                         }
2281                         print $cgi->a({-href => href(action=>"blob", hash=>$diff{'from_id'},
2282                                                      hash_base=>$parent, file_name=>$diff{'file'})},
2283                                       "blob") . " | ";
2284                         if ($have_blame) {
2285                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$parent,
2286                                                              file_name=>$diff{'file'})},
2287                                               "blame") . " | ";
2288                         }
2289                         print $cgi->a({-href => href(action=>"history", hash_base=>$parent,
2290                                                      file_name=>$diff{'file'})},
2291                                       "history");
2292                         print "</td>\n";
2293
2294                 } elsif ($diff{'status'} eq "M" || $diff{'status'} eq "T") { # modified, or type changed
2295                         my $mode_chnge = "";
2296                         if ($diff{'from_mode'} != $diff{'to_mode'}) {
2297                                 $mode_chnge = "<span class=\"file_status mode_chnge\">[changed";
2298                                 if ($from_file_type ne $to_file_type) {
2299                                         $mode_chnge .= " from $from_file_type to $to_file_type";
2300                                 }
2301                                 if (($from_mode_oct & 0777) != ($to_mode_oct & 0777)) {
2302                                         if ($from_mode_str && $to_mode_str) {
2303                                                 $mode_chnge .= " mode: $from_mode_str->$to_mode_str";
2304                                         } elsif ($to_mode_str) {
2305                                                 $mode_chnge .= " mode: $to_mode_str";
2306                                         }
2307                                 }
2308                                 $mode_chnge .= "]</span>\n";
2309                         }
2310                         print "<td>";
2311                         print $cgi->a({-href => href(action=>"blob", hash=>$diff{'to_id'},
2312                                                      hash_base=>$hash, file_name=>$diff{'file'}),
2313                                       -class => "list"}, esc_path($diff{'file'}));
2314                         print "</td>\n";
2315                         print "<td>$mode_chnge</td>\n";
2316                         print "<td class=\"link\">";
2317                         if ($action eq 'commitdiff') {
2318                                 # link to patch
2319                                 $patchno++;
2320                                 print $cgi->a({-href => "#patch$patchno"}, "patch") .
2321                                       " | ";
2322                         } elsif ($diff{'to_id'} ne $diff{'from_id'}) {
2323                                 # "commit" view and modified file (not onlu mode changed)
2324                                 print $cgi->a({-href => href(action=>"blobdiff",
2325                                                              hash=>$diff{'to_id'}, hash_parent=>$diff{'from_id'},
2326                                                              hash_base=>$hash, hash_parent_base=>$parent,
2327                                                              file_name=>$diff{'file'})},
2328                                               "diff") .
2329                                       " | ";
2330                         }
2331                         print $cgi->a({-href => href(action=>"blob", hash=>$diff{'to_id'},
2332                                                      hash_base=>$hash, file_name=>$diff{'file'})},
2333                                        "blob") . " | ";
2334                         if ($have_blame) {
2335                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
2336                                                              file_name=>$diff{'file'})},
2337                                               "blame") . " | ";
2338                         }
2339                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
2340                                                      file_name=>$diff{'file'})},
2341                                       "history");
2342                         print "</td>\n";
2343
2344                 } elsif ($diff{'status'} eq "R" || $diff{'status'} eq "C") { # renamed or copied
2345                         my %status_name = ('R' => 'moved', 'C' => 'copied');
2346                         my $nstatus = $status_name{$diff{'status'}};
2347                         my $mode_chng = "";
2348                         if ($diff{'from_mode'} != $diff{'to_mode'}) {
2349                                 # mode also for directories, so we cannot use $to_mode_str
2350                                 $mode_chng = sprintf(", mode: %04o", $to_mode_oct & 0777);
2351                         }
2352                         print "<td>" .
2353                               $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
2354                                                      hash=>$diff{'to_id'}, file_name=>$diff{'to_file'}),
2355                                       -class => "list"}, esc_path($diff{'to_file'})) . "</td>\n" .
2356                               "<td><span class=\"file_status $nstatus\">[$nstatus from " .
2357                               $cgi->a({-href => href(action=>"blob", hash_base=>$parent,
2358                                                      hash=>$diff{'from_id'}, file_name=>$diff{'from_file'}),
2359                                       -class => "list"}, esc_path($diff{'from_file'})) .
2360                               " with " . (int $diff{'similarity'}) . "% similarity$mode_chng]</span></td>\n" .
2361                               "<td class=\"link\">";
2362                         if ($action eq 'commitdiff') {
2363                                 # link to patch
2364                                 $patchno++;
2365                                 print $cgi->a({-href => "#patch$patchno"}, "patch") .
2366                                       " | ";
2367                         } elsif ($diff{'to_id'} ne $diff{'from_id'}) {
2368                                 # "commit" view and modified file (not only pure rename or copy)
2369                                 print $cgi->a({-href => href(action=>"blobdiff",
2370                                                              hash=>$diff{'to_id'}, hash_parent=>$diff{'from_id'},
2371                                                              hash_base=>$hash, hash_parent_base=>$parent,
2372                                                              file_name=>$diff{'to_file'}, file_parent=>$diff{'from_file'})},
2373                                               "diff") .
2374                                       " | ";
2375                         }
2376                         print $cgi->a({-href => href(action=>"blob", hash=>$diff{'to_id'},
2377                                                      hash_base=>$parent, file_name=>$diff{'to_file'})},
2378                                       "blob") . " | ";
2379                         if ($have_blame) {
2380                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
2381                                                              file_name=>$diff{'to_file'})},
2382                                               "blame") . " | ";
2383                         }
2384                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
2385                                                     file_name=>$diff{'to_file'})},
2386                                       "history");
2387                         print "</td>\n";
2388
2389                 } # we should not encounter Unmerged (U) or Unknown (X) status
2390                 print "</tr>\n";
2391         }
2392         print "</table>\n";
2393 }
2394
2395 sub git_patchset_body {
2396         my ($fd, $difftree, $hash, $hash_parent) = @_;
2397
2398         my $patch_idx = 0;
2399         my $patch_line;
2400         my $diffinfo;
2401         my (%from, %to);
2402
2403         print "<div class=\"patchset\">\n";
2404
2405         # skip to first patch
2406         while ($patch_line = <$fd>) {
2407                 chomp $patch_line;
2408
2409                 last if ($patch_line =~ m/^diff /);
2410         }
2411
2412  PATCH:
2413         while ($patch_line) {
2414                 my @diff_header;
2415                 my ($from_id, $to_id);
2416
2417                 # git diff header
2418                 #assert($patch_line =~ m/^diff /) if DEBUG;
2419                 #assert($patch_line !~ m!$/$!) if DEBUG; # is chomp-ed
2420                 push @diff_header, $patch_line;
2421
2422                 # extended diff header
2423         EXTENDED_HEADER:
2424                 while ($patch_line = <$fd>) {
2425                         chomp $patch_line;
2426
2427                         last EXTENDED_HEADER if ($patch_line =~ m/^--- |^diff /);
2428
2429                         if ($patch_line =~ m/^index ([0-9a-fA-F]{40})..([0-9a-fA-F]{40})/) {
2430                                 $from_id = $1;
2431                                 $to_id   = $2;
2432                         }
2433
2434                         push @diff_header, $patch_line;
2435                 }
2436                 my $last_patch_line = $patch_line;
2437
2438                 # check if current patch belong to current raw line
2439                 # and parse raw git-diff line if needed
2440                 if (defined $diffinfo &&
2441                     $diffinfo->{'from_id'} eq $from_id &&
2442                     $diffinfo->{'to_id'}   eq $to_id) {
2443                         # this is split patch
2444                         print "<div class=\"patch cont\">\n";
2445                 } else {
2446                         # advance raw git-diff output if needed
2447                         $patch_idx++ if defined $diffinfo;
2448
2449                         # read and prepare patch information
2450                         if (ref($difftree->[$patch_idx]) eq "HASH") {
2451                                 # pre-parsed (or generated by hand)
2452                                 $diffinfo = $difftree->[$patch_idx];
2453                         } else {
2454                                 $diffinfo = parse_difftree_raw_line($difftree->[$patch_idx]);
2455                         }
2456                         $from{'file'} = $diffinfo->{'from_file'} || $diffinfo->{'file'};
2457                         $to{'file'}   = $diffinfo->{'to_file'}   || $diffinfo->{'file'};
2458                         if ($diffinfo->{'status'} ne "A") { # not new (added) file
2459                                 $from{'href'} = href(action=>"blob", hash_base=>$hash_parent,
2460                                                      hash=>$diffinfo->{'from_id'},
2461                                                      file_name=>$from{'file'});
2462                         } else {
2463                                 delete $from{'href'};
2464                         }
2465                         if ($diffinfo->{'status'} ne "D") { # not deleted file
2466                                 $to{'href'} = href(action=>"blob", hash_base=>$hash,
2467                                                    hash=>$diffinfo->{'to_id'},
2468                                                    file_name=>$to{'file'});
2469                         } else {
2470                                 delete $to{'href'};
2471                         }
2472                         # this is first patch for raw difftree line with $patch_idx index
2473                         # we index @$difftree array from 0, but number patches from 1
2474                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n";
2475                 }
2476
2477                 # print "git diff" header
2478                 $patch_line = shift @diff_header;
2479                 $patch_line =~ s!^(diff (.*?) )"?a/.*$!$1!;
2480                 if ($from{'href'}) {
2481                         $patch_line .= $cgi->a({-href => $from{'href'}, -class => "path"},
2482                                                'a/' . esc_path($from{'file'}));
2483                 } else { # file was added
2484                         $patch_line .= 'a/' . esc_path($from{'file'});
2485                 }
2486                 $patch_line .= ' ';
2487                 if ($to{'href'}) {
2488                         $patch_line .= $cgi->a({-href => $to{'href'}, -class => "path"},
2489                                                'b/' . esc_path($to{'file'}));
2490                 } else { # file was deleted
2491                         $patch_line .= 'b/' . esc_path($to{'file'});
2492                 }
2493                 print "<div class=\"diff header\">$patch_line</div>\n";
2494
2495                 # print extended diff header
2496                 print "<div class=\"diff extended_header\">\n" if (@diff_header > 0);
2497         EXTENDED_HEADER:
2498                 foreach $patch_line (@diff_header) {
2499                         # match <path>
2500                         if ($patch_line =~ s!^((copy|rename) from ).*$!$1! && $from{'href'}) {
2501                                 $patch_line .= $cgi->a({-href=>$from{'href'}, -class=>"path"},
2502                                                        esc_path($from{'file'}));
2503                         }
2504                         if ($patch_line =~ s!^((copy|rename) to ).*$!$1! && $to{'href'}) {
2505                                 $patch_line .= $cgi->a({-href=>$to{'href'}, -class=>"path"},
2506                                                        esc_path($to{'file'}));
2507                         }
2508                         # match <mode>
2509                         if ($patch_line =~ m/\s(\d{6})$/) {
2510                                 $patch_line .= '<span class="info"> (' .
2511                                                file_type_long($1) .
2512                                                ')</span>';
2513                         }
2514                         # match <hash>
2515                         if ($patch_line =~ m/^index/) {
2516                                 my ($from_link, $to_link);
2517                                 if ($from{'href'}) {
2518                                         $from_link = $cgi->a({-href=>$from{'href'}, -class=>"hash"},
2519                                                              substr($diffinfo->{'from_id'},0,7));
2520                                 } else {
2521                                         $from_link = '0' x 7;
2522                                 }
2523                                 if ($to{'href'}) {
2524                                         $to_link = $cgi->a({-href=>$to{'href'}, -class=>"hash"},
2525                                                            substr($diffinfo->{'to_id'},0,7));
2526                                 } else {
2527                                         $to_link = '0' x 7;
2528                                 }
2529                                 #affirm {
2530                                 #       my ($from_hash, $to_hash) =
2531                                 #               ($patch_line =~ m/^index ([0-9a-fA-F]{40})..([0-9a-fA-F]{40})/);
2532                                 #       my ($from_id, $to_id) =
2533                                 #               ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
2534                                 #       ($from_hash eq $from_id) && ($to_hash eq $to_id);
2535                                 #} if DEBUG;
2536                                 my ($from_id, $to_id) = ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
2537                                 $patch_line =~ s!$from_id\.\.$to_id!$from_link..$to_link!;
2538                         }
2539                         print $patch_line . "<br/>\n";
2540                 }
2541                 print "</div>\n"  if (@diff_header > 0); # class="diff extended_header"
2542
2543                 # from-file/to-file diff header
2544                 $patch_line = $last_patch_line;
2545                 if (! $patch_line) {
2546                         print "</div>\n"; # class="patch"
2547                         last PATCH;
2548                 }
2549                 next PATCH if ($patch_line =~ m/^diff /);
2550                 #assert($patch_line =~ m/^---/) if DEBUG;
2551                 if ($from{'href'} && $patch_line =~ m!^--- "?a/!) {
2552                         $patch_line = '--- a/' .
2553                                       $cgi->a({-href=>$from{'href'}, -class=>"path"},
2554                                               esc_path($from{'file'}));
2555                 }
2556                 print "<div class=\"diff from_file\">$patch_line</div>\n";
2557
2558                 $patch_line = <$fd>;
2559                 chomp $patch_line;
2560
2561                 #assert($patch_line =~ m/^+++/) if DEBUG;
2562                 if ($to{'href'} && $patch_line =~ m!^\+\+\+ "?b/!) {
2563                         $patch_line = '+++ b/' .
2564                                       $cgi->a({-href=>$to{'href'}, -class=>"path"},
2565                                               esc_path($to{'file'}));
2566                 }
2567                 print "<div class=\"diff to_file\">$patch_line</div>\n";
2568
2569                 # the patch itself
2570         LINE:
2571                 while ($patch_line = <$fd>) {
2572                         chomp $patch_line;
2573
2574                         next PATCH if ($patch_line =~ m/^diff /);
2575
2576                         print format_diff_line($patch_line, \%from, \%to);
2577                 }
2578
2579         } continue {
2580                 print "</div>\n"; # class="patch"
2581         }
2582
2583         print "</div>\n"; # class="patchset"
2584 }
2585
2586 # . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
2587
2588 sub git_project_list_body {
2589         my ($projlist, $order, $from, $to, $extra, $no_header) = @_;
2590
2591         my ($check_forks) = gitweb_check_feature('forks');
2592
2593         my @projects;
2594         foreach my $pr (@$projlist) {
2595                 my (@aa) = git_get_last_activity($pr->{'path'});
2596                 unless (@aa) {
2597                         next;
2598                 }
2599                 ($pr->{'age'}, $pr->{'age_string'}) = @aa;
2600                 if (!defined $pr->{'descr'}) {
2601                         my $descr = git_get_project_description($pr->{'path'}) || "";
2602                         $pr->{'descr_long'} = to_utf8($descr);
2603                         $pr->{'descr'} = chop_str($descr, 25, 5);
2604                 }
2605                 if (!defined $pr->{'owner'}) {
2606                         $pr->{'owner'} = get_file_owner("$projectroot/$pr->{'path'}") || "";
2607                 }
2608                 if ($check_forks) {
2609                         my $pname = $pr->{'path'};
2610                         if (($pname =~ s/\.git$//) &&
2611                             ($pname !~ /\/$/) &&
2612                             (-d "$projectroot/$pname")) {
2613                                 $pr->{'forks'} = "-d $projectroot/$pname";
2614                         }
2615                         else {
2616                                 $pr->{'forks'} = 0;
2617                         }
2618                 }
2619                 push @projects, $pr;
2620         }
2621
2622         $order ||= "project";
2623         $from = 0 unless defined $from;
2624         $to = $#projects if (!defined $to || $#projects < $to);
2625
2626         print "<table class=\"project_list\">\n";
2627         unless ($no_header) {
2628                 print "<tr>\n";
2629                 if ($check_forks) {
2630                         print "<th></th>\n";
2631                 }
2632                 if ($order eq "project") {
2633                         @projects = sort {$a->{'path'} cmp $b->{'path'}} @projects;
2634                         print "<th>Project</th>\n";
2635                 } else {
2636                         print "<th>" .
2637                               $cgi->a({-href => href(project=>undef, order=>'project'),
2638                                        -class => "header"}, "Project") .
2639                               "</th>\n";
2640                 }
2641                 if ($order eq "descr") {
2642                         @projects = sort {$a->{'descr'} cmp $b->{'descr'}} @projects;
2643                         print "<th>Description</th>\n";
2644                 } else {
2645                         print "<th>" .
2646                               $cgi->a({-href => href(project=>undef, order=>'descr'),
2647                                        -class => "header"}, "Description") .
2648                               "</th>\n";
2649                 }
2650                 if ($order eq "owner") {
2651                         @projects = sort {$a->{'owner'} cmp $b->{'owner'}} @projects;
2652                         print "<th>Owner</th>\n";
2653                 } else {
2654                         print "<th>" .
2655                               $cgi->a({-href => href(project=>undef, order=>'owner'),
2656                                        -class => "header"}, "Owner") .
2657                               "</th>\n";
2658                 }
2659                 if ($order eq "age") {
2660                         @projects = sort {$a->{'age'} <=> $b->{'age'}} @projects;
2661                         print "<th>Last Change</th>\n";
2662                 } else {
2663                         print "<th>" .
2664                               $cgi->a({-href => href(project=>undef, order=>'age'),
2665                                        -class => "header"}, "Last Change") .
2666                               "</th>\n";
2667                 }
2668                 print "<th></th>\n" .
2669                       "</tr>\n";
2670         }
2671         my $alternate = 1;
2672         for (my $i = $from; $i <= $to; $i++) {
2673                 my $pr = $projects[$i];
2674                 if ($alternate) {
2675                         print "<tr class=\"dark\">\n";
2676                 } else {
2677                         print "<tr class=\"light\">\n";
2678                 }
2679                 $alternate ^= 1;
2680                 if ($check_forks) {
2681                         print "<td>";
2682                         if ($pr->{'forks'}) {
2683                                 print "<!-- $pr->{'forks'} -->\n";
2684                                 print $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "+");
2685                         }
2686                         print "</td>\n";
2687                 }
2688                 print "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
2689                                         -class => "list"}, esc_html($pr->{'path'})) . "</td>\n" .
2690                       "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
2691                                         -class => "list", -title => $pr->{'descr_long'}},
2692                                         esc_html($pr->{'descr'})) . "</td>\n" .
2693                       "<td><i>" . chop_str($pr->{'owner'}, 15) . "</i></td>\n";
2694                 print "<td class=\"". age_class($pr->{'age'}) . "\">" .
2695                       $pr->{'age_string'} . "</td>\n" .
2696                       "<td class=\"link\">" .
2697                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary")}, "summary")   . " | " .
2698                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"shortlog")}, "shortlog") . " | " .
2699                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"log")}, "log") . " | " .
2700                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"tree")}, "tree") .
2701                       ($pr->{'forks'} ? " | " . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "forks") : '') .
2702                       "</td>\n" .
2703                       "</tr>\n";
2704         }
2705         if (defined $extra) {
2706                 print "<tr>\n";
2707                 if ($check_forks) {
2708                         print "<td></td>\n";
2709                 }
2710                 print "<td colspan=\"5\">$extra</td>\n" .
2711                       "</tr>\n";
2712         }
2713         print "</table>\n";
2714 }
2715
2716 sub git_shortlog_body {
2717         # uses global variable $project
2718         my ($commitlist, $from, $to, $refs, $extra) = @_;
2719
2720         my $have_snapshot = gitweb_have_snapshot();
2721
2722         $from = 0 unless defined $from;
2723         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
2724
2725         print "<table class=\"shortlog\" cellspacing=\"0\">\n";
2726         my $alternate = 1;
2727         for (my $i = $from; $i <= $to; $i++) {
2728                 my %co = %{$commitlist->[$i]};
2729                 my $commit = $co{'id'};
2730                 my $ref = format_ref_marker($refs, $commit);
2731                 if ($alternate) {
2732                         print "<tr class=\"dark\">\n";
2733                 } else {
2734                         print "<tr class=\"light\">\n";
2735                 }
2736                 $alternate ^= 1;
2737                 # git_summary() used print "<td><i>$co{'age_string'}</i></td>\n" .
2738                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
2739                       "<td><i>" . esc_html(chop_str($co{'author_name'}, 10)) . "</i></td>\n" .
2740                       "<td>";
2741                 print format_subject_html($co{'title'}, $co{'title_short'},
2742                                           href(action=>"commit", hash=>$commit), $ref);
2743                 print "</td>\n" .
2744                       "<td class=\"link\">" .
2745                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") . " | " .
2746                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") . " | " .
2747                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree");
2748                 if ($have_snapshot) {
2749                         print " | " . $cgi->a({-href => href(action=>"snapshot", hash=>$commit)}, "snapshot");
2750                 }
2751                 print "</td>\n" .
2752                       "</tr>\n";
2753         }
2754         if (defined $extra) {
2755                 print "<tr>\n" .
2756                       "<td colspan=\"4\">$extra</td>\n" .
2757                       "</tr>\n";
2758         }
2759         print "</table>\n";
2760 }
2761
2762 sub git_history_body {
2763         # Warning: assumes constant type (blob or tree) during history
2764         my ($commitlist, $from, $to, $refs, $hash_base, $ftype, $extra) = @_;
2765
2766         $from = 0 unless defined $from;
2767         $to = $#{$commitlist} unless (defined $to && $to <= $#{$commitlist});
2768
2769         print "<table class=\"history\" cellspacing=\"0\">\n";
2770         my $alternate = 1;
2771         for (my $i = $from; $i <= $to; $i++) {
2772                 my %co = %{$commitlist->[$i]};
2773                 if (!%co) {
2774                         next;
2775                 }
2776                 my $commit = $co{'id'};
2777
2778                 my $ref = format_ref_marker($refs, $commit);
2779
2780                 if ($alternate) {
2781                         print "<tr class=\"dark\">\n";
2782                 } else {
2783                         print "<tr class=\"light\">\n";
2784                 }
2785                 $alternate ^= 1;
2786                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
2787                       # shortlog uses      chop_str($co{'author_name'}, 10)
2788                       "<td><i>" . esc_html(chop_str($co{'author_name'}, 15, 3)) . "</i></td>\n" .
2789                       "<td>";
2790                 # originally git_history used chop_str($co{'title'}, 50)
2791                 print format_subject_html($co{'title'}, $co{'title_short'},
2792                                           href(action=>"commit", hash=>$commit), $ref);
2793                 print "</td>\n" .
2794                       "<td class=\"link\">" .
2795                       $cgi->a({-href => href(action=>$ftype, hash_base=>$commit, file_name=>$file_name)}, $ftype) . " | " .
2796                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff");
2797
2798                 if ($ftype eq 'blob') {
2799                         my $blob_current = git_get_hash_by_path($hash_base, $file_name);
2800                         my $blob_parent  = git_get_hash_by_path($commit, $file_name);
2801                         if (defined $blob_current && defined $blob_parent &&
2802                                         $blob_current ne $blob_parent) {
2803                                 print " | " .
2804                                         $cgi->a({-href => href(action=>"blobdiff",
2805                                                                hash=>$blob_current, hash_parent=>$blob_parent,
2806                                                                hash_base=>$hash_base, hash_parent_base=>$commit,
2807                                                                file_name=>$file_name)},
2808                                                 "diff to current");
2809                         }
2810                 }
2811                 print "</td>\n" .
2812                       "</tr>\n";
2813         }
2814         if (defined $extra) {
2815                 print "<tr>\n" .
2816                       "<td colspan=\"4\">$extra</td>\n" .
2817                       "</tr>\n";
2818         }
2819         print "</table>\n";
2820 }
2821
2822 sub git_tags_body {
2823         # uses global variable $project
2824         my ($taglist, $from, $to, $extra) = @_;
2825         $from = 0 unless defined $from;
2826         $to = $#{$taglist} if (!defined $to || $#{$taglist} < $to);
2827
2828         print "<table class=\"tags\" cellspacing=\"0\">\n";
2829         my $alternate = 1;
2830         for (my $i = $from; $i <= $to; $i++) {
2831                 my $entry = $taglist->[$i];
2832                 my %tag = %$entry;
2833                 my $comment = $tag{'subject'};
2834                 my $comment_short;
2835                 if (defined $comment) {
2836                         $comment_short = chop_str($comment, 30, 5);
2837                 }
2838                 if ($alternate) {
2839                         print "<tr class=\"dark\">\n";
2840                 } else {
2841                         print "<tr class=\"light\">\n";
2842                 }
2843                 $alternate ^= 1;
2844                 if (defined $tag{'age'}) {
2845                         print "<td><i>$tag{'age'}</i></td>\n";
2846                 } else {
2847                         print "<td></td>\n";
2848                 }
2849                 print "<td>" .
2850                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'}),
2851                                -class => "list name"}, esc_html($tag{'name'})) .
2852                       "</td>\n" .
2853                       "<td>";
2854                 if (defined $comment) {
2855                         print format_subject_html($comment, $comment_short,
2856                                                   href(action=>"tag", hash=>$tag{'id'}));
2857                 }
2858                 print "</td>\n" .
2859                       "<td class=\"selflink\">";
2860                 if ($tag{'type'} eq "tag") {
2861                         print $cgi->a({-href => href(action=>"tag", hash=>$tag{'id'})}, "tag");
2862                 } else {
2863                         print "&nbsp;";
2864                 }
2865                 print "</td>\n" .
2866                       "<td class=\"link\">" . " | " .
2867                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'})}, $tag{'reftype'});
2868                 if ($tag{'reftype'} eq "commit") {
2869                         print " | " . $cgi->a({-href => href(action=>"shortlog", hash=>$tag{'name'})}, "shortlog") .
2870                               " | " . $cgi->a({-href => href(action=>"log", hash=>$tag{'name'})}, "log");
2871                 } elsif ($tag{'reftype'} eq "blob") {
2872                         print " | " . $cgi->a({-href => href(action=>"blob_plain", hash=>$tag{'refid'})}, "raw");
2873                 }
2874                 print "</td>\n" .
2875                       "</tr>";
2876         }
2877         if (defined $extra) {
2878                 print "<tr>\n" .
2879                       "<td colspan=\"5\">$extra</td>\n" .
2880                       "</tr>\n";
2881         }
2882         print "</table>\n";
2883 }
2884
2885 sub git_heads_body {
2886         # uses global variable $project
2887         my ($headlist, $head, $from, $to, $extra) = @_;
2888         $from = 0 unless defined $from;
2889         $to = $#{$headlist} if (!defined $to || $#{$headlist} < $to);
2890
2891         print "<table class=\"heads\" cellspacing=\"0\">\n";
2892         my $alternate = 1;
2893         for (my $i = $from; $i <= $to; $i++) {
2894                 my $entry = $headlist->[$i];
2895                 my %ref = %$entry;
2896                 my $curr = $ref{'id'} eq $head;
2897                 if ($alternate) {
2898                         print "<tr class=\"dark\">\n";
2899                 } else {
2900                         print "<tr class=\"light\">\n";
2901                 }
2902                 $alternate ^= 1;
2903                 print "<td><i>$ref{'age'}</i></td>\n" .
2904                       ($curr ? "<td class=\"current_head\">" : "<td>") .
2905                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'name'}),
2906                                -class => "list name"},esc_html($ref{'name'})) .
2907                       "</td>\n" .
2908                       "<td class=\"link\">" .
2909                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'name'})}, "shortlog") . " | " .
2910                       $cgi->a({-href => href(action=>"log", hash=>$ref{'name'})}, "log") . " | " .
2911                       $cgi->a({-href => href(action=>"tree", hash=>$ref{'name'}, hash_base=>$ref{'name'})}, "tree") .
2912                       "</td>\n" .
2913                       "</tr>";
2914         }
2915         if (defined $extra) {
2916                 print "<tr>\n" .
2917                       "<td colspan=\"3\">$extra</td>\n" .
2918                       "</tr>\n";
2919         }
2920         print "</table>\n";
2921 }
2922
2923 sub git_search_grep_body {
2924         my ($commitlist, $from, $to, $extra) = @_;
2925         $from = 0 unless defined $from;
2926         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
2927
2928         print "<table class=\"grep\" cellspacing=\"0\">\n";
2929         my $alternate = 1;
2930         for (my $i = $from; $i <= $to; $i++) {
2931                 my %co = %{$commitlist->[$i]};
2932                 if (!%co) {
2933                         next;
2934                 }
2935                 my $commit = $co{'id'};
2936                 if ($alternate) {
2937                         print "<tr class=\"dark\">\n";
2938                 } else {
2939                         print "<tr class=\"light\">\n";
2940                 }
2941                 $alternate ^= 1;
2942                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
2943                       "<td><i>" . esc_html(chop_str($co{'author_name'}, 15, 5)) . "</i></td>\n" .
2944                       "<td>" .
2945                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}), -class => "list subject"},
2946                                esc_html(chop_str($co{'title'}, 50)) . "<br/>");
2947                 my $comment = $co{'comment'};
2948                 foreach my $line (@$comment) {
2949                         if ($line =~ m/^(.*)($searchtext)(.*)$/i) {
2950                                 my $lead = esc_html($1) || "";
2951                                 $lead = chop_str($lead, 30, 10);
2952                                 my $match = esc_html($2) || "";
2953                                 my $trail = esc_html($3) || "";
2954                                 $trail = chop_str($trail, 30, 10);
2955                                 my $text = "$lead<span class=\"match\">$match</span>$trail";
2956                                 print chop_str($text, 80, 5) . "<br/>\n";
2957                         }
2958                 }
2959                 print "</td>\n" .
2960                       "<td class=\"link\">" .
2961                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
2962                       " | " .
2963                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
2964                 print "</td>\n" .
2965                       "</tr>\n";
2966         }
2967         if (defined $extra) {
2968                 print "<tr>\n" .
2969                       "<td colspan=\"3\">$extra</td>\n" .
2970                       "</tr>\n";
2971         }
2972         print "</table>\n";
2973 }
2974
2975 ## ======================================================================
2976 ## ======================================================================
2977 ## actions
2978
2979 sub git_project_list {
2980         my $order = $cgi->param('o');
2981         if (defined $order && $order !~ m/project|descr|owner|age/) {
2982                 die_error(undef, "Unknown order parameter");
2983         }
2984
2985         my @list = git_get_projects_list();
2986         if (!@list) {
2987                 die_error(undef, "No projects found");
2988         }
2989
2990         git_header_html();
2991         if (-f $home_text) {
2992                 print "<div class=\"index_include\">\n";
2993                 open (my $fd, $home_text);
2994                 print <$fd>;
2995                 close $fd;
2996                 print "</div>\n";
2997         }
2998         git_project_list_body(\@list, $order);
2999         git_footer_html();
3000 }
3001
3002 sub git_forks {
3003         my $order = $cgi->param('o');
3004         if (defined $order && $order !~ m/project|descr|owner|age/) {
3005                 die_error(undef, "Unknown order parameter");
3006         }
3007
3008         my @list = git_get_projects_list($project);
3009         if (!@list) {
3010                 die_error(undef, "No forks found");
3011         }
3012
3013         git_header_html();
3014         git_print_page_nav('','');
3015         git_print_header_div('summary', "$project forks");
3016         git_project_list_body(\@list, $order);
3017         git_footer_html();
3018 }
3019
3020 sub git_project_index {
3021         my @projects = git_get_projects_list($project);
3022
3023         print $cgi->header(
3024                 -type => 'text/plain',
3025                 -charset => 'utf-8',
3026                 -content_disposition => 'inline; filename="index.aux"');
3027
3028         foreach my $pr (@projects) {
3029                 if (!exists $pr->{'owner'}) {
3030                         $pr->{'owner'} = get_file_owner("$projectroot/$pr->{'path'}");
3031                 }
3032
3033                 my ($path, $owner) = ($pr->{'path'}, $pr->{'owner'});
3034                 # quote as in CGI::Util::encode, but keep the slash, and use '+' for ' '
3035                 $path  =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
3036                 $owner =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
3037                 $path  =~ s/ /\+/g;
3038                 $owner =~ s/ /\+/g;
3039
3040                 print "$path $owner\n";
3041         }
3042 }
3043
3044 sub git_summary {
3045         my $descr = git_get_project_description($project) || "none";
3046         my %co = parse_commit("HEAD");
3047         my %cd = parse_date($co{'committer_epoch'}, $co{'committer_tz'});
3048         my $head = $co{'id'};
3049
3050         my $owner = git_get_project_owner($project);
3051
3052         my $refs = git_get_references();
3053         # These get_*_list functions return one more to allow us to see if
3054         # there are more ...
3055         my @taglist  = git_get_tags_list(16);
3056         my @headlist = git_get_heads_list(16);
3057         my @forklist;
3058         my ($check_forks) = gitweb_check_feature('forks');
3059
3060         if ($check_forks) {
3061                 @forklist = git_get_projects_list($project);
3062         }
3063
3064         git_header_html();
3065         git_print_page_nav('summary','', $head);
3066
3067         print "<div class=\"title\">&nbsp;</div>\n";
3068         print "<table cellspacing=\"0\">\n" .
3069               "<tr><td>description</td><td>" . esc_html($descr) . "</td></tr>\n" .
3070               "<tr><td>owner</td><td>$owner</td></tr>\n" .
3071               "<tr><td>last change</td><td>$cd{'rfc2822'}</td></tr>\n";
3072         # use per project git URL list in $projectroot/$project/cloneurl
3073         # or make project git URL from git base URL and project name
3074         my $url_tag = "URL";
3075         my @url_list = git_get_project_url_list($project);
3076         @url_list = map { "$_/$project" } @git_base_url_list unless @url_list;
3077         foreach my $git_url (@url_list) {
3078                 next unless $git_url;
3079                 print "<tr><td>$url_tag</td><td>$git_url</td></tr>\n";
3080                 $url_tag = "";
3081         }
3082         print "</table>\n";
3083
3084         if (-s "$projectroot/$project/README.html") {
3085                 if (open my $fd, "$projectroot/$project/README.html") {
3086                         print "<div class=\"title\">readme</div>\n";
3087                         print $_ while (<$fd>);
3088                         close $fd;
3089                 }
3090         }
3091
3092         # we need to request one more than 16 (0..15) to check if
3093         # those 16 are all
3094         my @commitlist = parse_commits($head, 17);
3095         git_print_header_div('shortlog');
3096         git_shortlog_body(\@commitlist, 0, 15, $refs,
3097                           $#commitlist <=  15 ? undef :
3098                           $cgi->a({-href => href(action=>"shortlog")}, "..."));
3099
3100         if (@taglist) {
3101                 git_print_header_div('tags');
3102                 git_tags_body(\@taglist, 0, 15,
3103                               $#taglist <=  15 ? undef :
3104                               $cgi->a({-href => href(action=>"tags")}, "..."));
3105         }
3106
3107         if (@headlist) {
3108                 git_print_header_div('heads');
3109                 git_heads_body(\@headlist, $head, 0, 15,
3110                                $#headlist <= 15 ? undef :
3111                                $cgi->a({-href => href(action=>"heads")}, "..."));
3112         }
3113
3114         if (@forklist) {
3115                 git_print_header_div('forks');
3116                 git_project_list_body(\@forklist, undef, 0, 15,
3117                                       $#forklist <= 15 ? undef :
3118                                       $cgi->a({-href => href(action=>"forks")}, "..."),
3119                                       'noheader');
3120         }
3121
3122         git_footer_html();
3123 }
3124
3125 sub git_tag {
3126         my $head = git_get_head_hash($project);
3127         git_header_html();
3128         git_print_page_nav('','', $head,undef,$head);
3129         my %tag = parse_tag($hash);
3130         git_print_header_div('commit', esc_html($tag{'name'}), $hash);
3131         print "<div class=\"title_text\">\n" .
3132               "<table cellspacing=\"0\">\n" .
3133               "<tr>\n" .
3134               "<td>object</td>\n" .
3135               "<td>" . $cgi->a({-class => "list", -href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
3136                                $tag{'object'}) . "</td>\n" .
3137               "<td class=\"link\">" . $cgi->a({-href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
3138                                               $tag{'type'}) . "</td>\n" .
3139               "</tr>\n";
3140         if (defined($tag{'author'})) {
3141                 my %ad = parse_date($tag{'epoch'}, $tag{'tz'});
3142                 print "<tr><td>author</td><td>" . esc_html($tag{'author'}) . "</td></tr>\n";
3143                 print "<tr><td></td><td>" . $ad{'rfc2822'} .
3144                         sprintf(" (%02d:%02d %s)", $ad{'hour_local'}, $ad{'minute_local'}, $ad{'tz_local'}) .
3145                         "</td></tr>\n";
3146         }
3147         print "</table>\n\n" .
3148               "</div>\n";
3149         print "<div class=\"page_body\">";
3150         my $comment = $tag{'comment'};
3151         foreach my $line (@$comment) {
3152                 chomp $line;
3153                 print esc_html($line, -nbsp=>1) . "<br/>\n";
3154         }
3155         print "</div>\n";
3156         git_footer_html();
3157 }
3158
3159 sub git_blame2 {
3160         my $fd;
3161         my $ftype;
3162
3163         my ($have_blame) = gitweb_check_feature('blame');
3164         if (!$have_blame) {
3165                 die_error('403 Permission denied', "Permission denied");
3166         }
3167         die_error('404 Not Found', "File name not defined") if (!$file_name);
3168         $hash_base ||= git_get_head_hash($project);
3169         die_error(undef, "Couldn't find base commit") unless ($hash_base);
3170         my %co = parse_commit($hash_base)
3171                 or die_error(undef, "Reading commit failed");
3172         if (!defined $hash) {
3173                 $hash = git_get_hash_by_path($hash_base, $file_name, "blob")
3174                         or die_error(undef, "Error looking up file");
3175         }
3176         $ftype = git_get_type($hash);
3177         if ($ftype !~ "blob") {
3178                 die_error('400 Bad Request', "Object is not a blob");
3179         }
3180         open ($fd, "-|", git_cmd(), "blame", '-p', '--',
3181               $file_name, $hash_base)
3182                 or die_error(undef, "Open git-blame failed");
3183         git_header_html();
3184         my $formats_nav =
3185                 $cgi->a({-href => href(action=>"blob", hash=>$hash, hash_base=>$hash_base, file_name=>$file_name)},
3186                         "blob") .
3187                 " | " .
3188                 $cgi->a({-href => href(action=>"history", hash=>$hash, hash_base=>$hash_base, file_name=>$file_name)},
3189                         "history") .
3190                 " | " .
3191                 $cgi->a({-href => href(action=>"blame", file_name=>$file_name)},
3192                         "HEAD");
3193         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
3194         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
3195         git_print_page_path($file_name, $ftype, $hash_base);
3196         my @rev_color = (qw(light2 dark2));
3197         my $num_colors = scalar(@rev_color);
3198         my $current_color = 0;
3199         my $last_rev;
3200         print <<HTML;
3201 <div class="page_body">
3202 <table class="blame">
3203 <tr><th>Commit</th><th>Line</th><th>Data</th></tr>
3204 HTML
3205         my %metainfo = ();
3206         while (1) {
3207                 $_ = <$fd>;
3208                 last unless defined $_;
3209                 my ($full_rev, $orig_lineno, $lineno, $group_size) =
3210                     /^([0-9a-f]{40}) (\d+) (\d+)(?: (\d+))?$/;
3211                 if (!exists $metainfo{$full_rev}) {
3212                         $metainfo{$full_rev} = {};
3213                 }
3214                 my $meta = $metainfo{$full_rev};
3215                 while (<$fd>) {
3216                         last if (s/^\t//);
3217                         if (/^(\S+) (.*)$/) {
3218                                 $meta->{$1} = $2;
3219                         }
3220                 }
3221                 my $data = $_;
3222                 chomp $data;
3223                 my $rev = substr($full_rev, 0, 8);
3224                 my $author = $meta->{'author'};
3225                 my %date = parse_date($meta->{'author-time'},
3226                                       $meta->{'author-tz'});
3227                 my $date = $date{'iso-tz'};
3228                 if ($group_size) {
3229                         $current_color = ++$current_color % $num_colors;
3230                 }
3231                 print "<tr class=\"$rev_color[$current_color]\">\n";
3232                 if ($group_size) {
3233                         print "<td class=\"sha1\"";
3234                         print " title=\"". esc_html($author) . ", $date\"";
3235                         print " rowspan=\"$group_size\"" if ($group_size > 1);
3236                         print ">";
3237                         print $cgi->a({-href => href(action=>"commit",
3238                                                      hash=>$full_rev,
3239                                                      file_name=>$file_name)},
3240                                       esc_html($rev));
3241                         print "</td>\n";
3242                 }
3243                 open (my $dd, "-|", git_cmd(), "rev-parse", "$full_rev^")
3244                         or die_error(undef, "Open git-rev-parse failed");
3245                 my $parent_commit = <$dd>;
3246                 close $dd;
3247                 chomp($parent_commit);
3248                 my $blamed = href(action => 'blame',
3249                                   file_name => $meta->{'filename'},
3250                                   hash_base => $parent_commit);
3251                 print "<td class=\"linenr\">";
3252                 print $cgi->a({ -href => "$blamed#l$orig_lineno",
3253                                 -id => "l$lineno",
3254                                 -class => "linenr" },
3255                               esc_html($lineno));
3256                 print "</td>";
3257                 print "<td class=\"pre\">" . esc_html($data) . "</td>\n";
3258                 print "</tr>\n";
3259         }
3260         print "</table>\n";
3261         print "</div>";
3262         close $fd
3263                 or print "Reading blob failed\n";
3264         git_footer_html();
3265 }
3266
3267 sub git_blame {
3268         my $fd;
3269
3270         my ($have_blame) = gitweb_check_feature('blame');
3271         if (!$have_blame) {
3272                 die_error('403 Permission denied', "Permission denied");
3273         }
3274         die_error('404 Not Found', "File name not defined") if (!$file_name);
3275         $hash_base ||= git_get_head_hash($project);
3276         die_error(undef, "Couldn't find base commit") unless ($hash_base);
3277         my %co = parse_commit($hash_base)
3278                 or die_error(undef, "Reading commit failed");
3279         if (!defined $hash) {
3280                 $hash = git_get_hash_by_path($hash_base, $file_name, "blob")
3281                         or die_error(undef, "Error lookup file");
3282         }
3283         open ($fd, "-|", git_cmd(), "annotate", '-l', '-t', '-r', $file_name, $hash_base)
3284                 or die_error(undef, "Open git-annotate failed");
3285         git_header_html();
3286         my $formats_nav =
3287                 $cgi->a({-href => href(action=>"blob", hash=>$hash, hash_base=>$hash_base, file_name=>$file_name)},
3288                         "blob") .
3289                 " | " .
3290                 $cgi->a({-href => href(action=>"history", hash=>$hash, hash_base=>$hash_base, file_name=>$file_name)},
3291                         "history") .
3292                 " | " .
3293                 $cgi->a({-href => href(action=>"blame", file_name=>$file_name)},
3294                         "HEAD");
3295         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
3296         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
3297         git_print_page_path($file_name, 'blob', $hash_base);
3298         print "<div class=\"page_body\">\n";
3299         print <<HTML;
3300 <table class="blame">
3301   <tr>
3302     <th>Commit</th>
3303     <th>Age</th>
3304     <th>Author</th>
3305     <th>Line</th>
3306     <th>Data</th>
3307   </tr>
3308 HTML
3309         my @line_class = (qw(light dark));
3310         my $line_class_len = scalar (@line_class);
3311         my $line_class_num = $#line_class;
3312         while (my $line = <$fd>) {
3313                 my $long_rev;
3314                 my $short_rev;
3315                 my $author;
3316                 my $time;
3317                 my $lineno;
3318                 my $data;
3319                 my $age;
3320                 my $age_str;
3321                 my $age_class;
3322
3323                 chomp $line;
3324                 $line_class_num = ($line_class_num + 1) % $line_class_len;
3325
3326                 if ($line =~ m/^([0-9a-fA-F]{40})\t\(\s*([^\t]+)\t(\d+) [+-]\d\d\d\d\t(\d+)\)(.*)$/) {
3327                         $long_rev = $1;
3328                         $author   = $2;
3329                         $time     = $3;
3330                         $lineno   = $4;
3331                         $data     = $5;
3332                 } else {
3333                         print qq(  <tr><td colspan="5" class="error">Unable to parse: $line</td></tr>\n);
3334                         next;
3335                 }
3336                 $short_rev  = substr ($long_rev, 0, 8);
3337                 $age        = time () - $time;
3338                 $age_str    = age_string ($age);
3339                 $age_str    =~ s/ /&nbsp;/g;
3340                 $age_class  = age_class($age);
3341                 $author     = esc_html ($author);
3342                 $author     =~ s/ /&nbsp;/g;
3343
3344                 $data = untabify($data);
3345                 $data = esc_html ($data);
3346
3347                 print <<HTML;
3348   <tr class="$line_class[$line_class_num]">
3349     <td class="sha1"><a href="${\href (action=>"commit", hash=>$long_rev)}" class="text">$short_rev..</a></td>
3350     <td class="$age_class">$age_str</td>
3351     <td>$author</td>
3352     <td class="linenr"><a id="$lineno" href="#$lineno" class="linenr">$lineno</a></td>
3353     <td class="pre">$data</td>
3354   </tr>
3355 HTML
3356         } # while (my $line = <$fd>)
3357         print "</table>\n\n";
3358         close $fd
3359                 or print "Reading blob failed.\n";
3360         print "</div>";
3361         git_footer_html();
3362 }
3363
3364 sub git_tags {
3365         my $head = git_get_head_hash($project);
3366         git_header_html();
3367         git_print_page_nav('','', $head,undef,$head);
3368         git_print_header_div('summary', $project);
3369
3370         my @tagslist = git_get_tags_list();
3371         if (@tagslist) {
3372                 git_tags_body(\@tagslist);
3373         }
3374         git_footer_html();
3375 }
3376
3377 sub git_heads {
3378         my $head = git_get_head_hash($project);
3379         git_header_html();
3380         git_print_page_nav('','', $head,undef,$head);
3381         git_print_header_div('summary', $project);
3382
3383         my @headslist = git_get_heads_list();
3384         if (@headslist) {
3385                 git_heads_body(\@headslist, $head);
3386         }
3387         git_footer_html();
3388 }
3389
3390 sub git_blob_plain {
3391         my $expires;
3392
3393         if (!defined $hash) {
3394                 if (defined $file_name) {
3395                         my $base = $hash_base || git_get_head_hash($project);
3396                         $hash = git_get_hash_by_path($base, $file_name, "blob")
3397                                 or die_error(undef, "Error lookup file");
3398                 } else {
3399                         die_error(undef, "No file name defined");
3400                 }
3401         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
3402                 # blobs defined by non-textual hash id's can be cached
3403                 $expires = "+1d";
3404         }
3405
3406         my $type = shift;
3407         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
3408                 or die_error(undef, "Couldn't cat $file_name, $hash");
3409
3410         $type ||= blob_mimetype($fd, $file_name);
3411
3412         # save as filename, even when no $file_name is given
3413         my $save_as = "$hash";
3414         if (defined $file_name) {
3415                 $save_as = $file_name;
3416         } elsif ($type =~ m/^text\//) {
3417                 $save_as .= '.txt';
3418         }
3419
3420         print $cgi->header(
3421                 -type => "$type",
3422                 -expires=>$expires,
3423                 -content_disposition => 'inline; filename="' . "$save_as" . '"');
3424         undef $/;
3425         binmode STDOUT, ':raw';
3426         print <$fd>;
3427         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
3428         $/ = "\n";
3429         close $fd;
3430 }
3431
3432 sub git_blob {
3433         my $expires;
3434
3435         if (!defined $hash) {
3436                 if (defined $file_name) {
3437                         my $base = $hash_base || git_get_head_hash($project);
3438                         $hash = git_get_hash_by_path($base, $file_name, "blob")
3439                                 or die_error(undef, "Error lookup file");
3440                 } else {
3441                         die_error(undef, "No file name defined");
3442                 }
3443         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
3444                 # blobs defined by non-textual hash id's can be cached
3445                 $expires = "+1d";
3446         }
3447
3448         my ($have_blame) = gitweb_check_feature('blame');
3449         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
3450                 or die_error(undef, "Couldn't cat $file_name, $hash");
3451         my $mimetype = blob_mimetype($fd, $file_name);
3452         if ($mimetype !~ m!^(?:text/|image/(?:gif|png|jpeg)$)!) {
3453                 close $fd;
3454                 return git_blob_plain($mimetype);
3455         }
3456         # we can have blame only for text/* mimetype
3457         $have_blame &&= ($mimetype =~ m!^text/!);
3458
3459         git_header_html(undef, $expires);
3460         my $formats_nav = '';
3461         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
3462                 if (defined $file_name) {
3463                         if ($have_blame) {
3464                                 $formats_nav .=
3465                                         $cgi->a({-href => href(action=>"blame", hash_base=>$hash_base,
3466                                                                hash=>$hash, file_name=>$file_name)},
3467                                                 "blame") .
3468                                         " | ";
3469                         }
3470                         $formats_nav .=
3471                                 $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
3472                                                        hash=>$hash, file_name=>$file_name)},
3473                                         "history") .
3474                                 " | " .
3475                                 $cgi->a({-href => href(action=>"blob_plain",
3476                                                        hash=>$hash, file_name=>$file_name)},
3477                                         "raw") .
3478                                 " | " .
3479                                 $cgi->a({-href => href(action=>"blob",
3480                                                        hash_base=>"HEAD", file_name=>$file_name)},
3481                                         "HEAD");
3482                 } else {
3483                         $formats_nav .=
3484                                 $cgi->a({-href => href(action=>"blob_plain", hash=>$hash)}, "raw");
3485                 }
3486                 git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
3487                 git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
3488         } else {
3489                 print "<div class=\"page_nav\">\n" .
3490                       "<br/><br/></div>\n" .
3491                       "<div class=\"title\">$hash</div>\n";
3492         }
3493         git_print_page_path($file_name, "blob", $hash_base);
3494         print "<div class=\"page_body\">\n";
3495         if ($mimetype =~ m!^text/!) {
3496                 my $nr;
3497                 while (my $line = <$fd>) {
3498                         chomp $line;
3499                         $nr++;
3500                         $line = untabify($line);
3501                         printf "<div class=\"pre\"><a id=\"l%i\" href=\"#l%i\" class=\"linenr\">%4i</a> %s</div>\n",
3502                                $nr, $nr, $nr, esc_html($line, -nbsp=>1);
3503                 }
3504         } elsif ($mimetype =~ m!^image/!) {
3505                 print qq!<img type="$mimetype"!;
3506                 if ($file_name) {
3507                         print qq! alt="$file_name" title="$file_name"!;
3508                 }
3509                 print qq! src="! .
3510                       href(action=>"blob_plain", hash=>$hash,
3511                            hash_base=>$hash_base, file_name=>$file_name) .
3512                       qq!" />\n!;
3513         }
3514         close $fd
3515                 or print "Reading blob failed.\n";
3516         print "</div>";
3517         git_footer_html();
3518 }
3519
3520 sub git_tree {
3521         my $have_snapshot = gitweb_have_snapshot();
3522
3523         if (!defined $hash_base) {
3524                 $hash_base = "HEAD";
3525         }
3526         if (!defined $hash) {
3527                 if (defined $file_name) {
3528                         $hash = git_get_hash_by_path($hash_base, $file_name, "tree");
3529                 } else {
3530                         $hash = $hash_base;
3531                 }
3532         }
3533         $/ = "\0";
3534         open my $fd, "-|", git_cmd(), "ls-tree", '-z', $hash
3535                 or die_error(undef, "Open git-ls-tree failed");
3536         my @entries = map { chomp; $_ } <$fd>;
3537         close $fd or die_error(undef, "Reading tree failed");
3538         $/ = "\n";
3539
3540         my $refs = git_get_references();
3541         my $ref = format_ref_marker($refs, $hash_base);
3542         git_header_html();
3543         my $basedir = '';
3544         my ($have_blame) = gitweb_check_feature('blame');
3545         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
3546                 my @views_nav = ();
3547                 if (defined $file_name) {
3548                         push @views_nav,
3549                                 $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
3550                                                        hash=>$hash, file_name=>$file_name)},
3551                                         "history"),
3552                                 $cgi->a({-href => href(action=>"tree",
3553                                                        hash_base=>"HEAD", file_name=>$file_name)},
3554                                         "HEAD"),
3555                 }
3556                 if ($have_snapshot) {
3557                         # FIXME: Should be available when we have no hash base as well.
3558                         push @views_nav,
3559                                 $cgi->a({-href => href(action=>"snapshot", hash=>$hash)},
3560                                         "snapshot");
3561                 }
3562                 git_print_page_nav('tree','', $hash_base, undef, undef, join(' | ', @views_nav));
3563                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash_base);
3564         } else {
3565                 undef $hash_base;
3566                 print "<div class=\"page_nav\">\n";
3567                 print "<br/><br/></div>\n";
3568                 print "<div class=\"title\">$hash</div>\n";
3569         }
3570         if (defined $file_name) {
3571                 $basedir = $file_name;
3572                 if ($basedir ne '' && substr($basedir, -1) ne '/') {
3573                         $basedir .= '/';
3574                 }
3575         }
3576         git_print_page_path($file_name, 'tree', $hash_base);
3577         print "<div class=\"page_body\">\n";
3578         print "<table cellspacing=\"0\">\n";
3579         my $alternate = 1;
3580         # '..' (top directory) link if possible
3581         if (defined $hash_base &&
3582             defined $file_name && $file_name =~ m![^/]+$!) {
3583                 if ($alternate) {
3584                         print "<tr class=\"dark\">\n";
3585                 } else {
3586                         print "<tr class=\"light\">\n";
3587                 }
3588                 $alternate ^= 1;
3589
3590                 my $up = $file_name;
3591                 $up =~ s!/?[^/]+$!!;
3592                 undef $up unless $up;
3593                 # based on git_print_tree_entry
3594                 print '<td class="mode">' . mode_str('040000') . "</td>\n";
3595                 print '<td class="list">';
3596                 print $cgi->a({-href => href(action=>"tree", hash_base=>$hash_base,
3597                                              file_name=>$up)},
3598                               "..");
3599                 print "</td>\n";
3600                 print "<td class=\"link\"></td>\n";
3601
3602                 print "</tr>\n";
3603         }
3604         foreach my $line (@entries) {
3605                 my %t = parse_ls_tree_line($line, -z => 1);
3606
3607                 if ($alternate) {
3608                         print "<tr class=\"dark\">\n";
3609                 } else {
3610                         print "<tr class=\"light\">\n";
3611                 }
3612                 $alternate ^= 1;
3613
3614                 git_print_tree_entry(\%t, $basedir, $hash_base, $have_blame);
3615
3616                 print "</tr>\n";
3617         }
3618         print "</table>\n" .
3619               "</div>";
3620         git_footer_html();
3621 }
3622
3623 sub git_snapshot {
3624         my ($ctype, $suffix, $command) = gitweb_check_feature('snapshot');
3625         my $have_snapshot = (defined $ctype && defined $suffix);
3626         if (!$have_snapshot) {
3627                 die_error('403 Permission denied', "Permission denied");
3628         }
3629
3630         if (!defined $hash) {
3631                 $hash = git_get_head_hash($project);
3632         }
3633
3634         my $filename = to_utf8(basename($project)) . "-$hash.tar.$suffix";
3635
3636         print $cgi->header(
3637                 -type => "application/$ctype",
3638                 -content_disposition => 'inline; filename="' . "$filename" . '"',
3639                 -status => '200 OK');
3640
3641         my $git = git_cmd_str();
3642         my $name = $project;
3643         $name =~ s/\047/\047\\\047\047/g;
3644         open my $fd, "-|",
3645                 "$git archive --format=tar --prefix=\'$name\'/ $hash | $command"
3646                 or die_error(undef, "Execute git-tar-tree failed");
3647         binmode STDOUT, ':raw';
3648         print <$fd>;
3649         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
3650         close $fd;
3651
3652 }
3653
3654 sub git_log {
3655         my $head = git_get_head_hash($project);
3656         if (!defined $hash) {
3657                 $hash = $head;
3658         }
3659         if (!defined $page) {
3660                 $page = 0;
3661         }
3662         my $refs = git_get_references();
3663
3664         my @commitlist = parse_commits($hash, 101, (100 * $page));
3665
3666         my $paging_nav = format_paging_nav('log', $hash, $head, $page, (100 * ($page+1)));
3667
3668         git_header_html();
3669         git_print_page_nav('log','', $hash,undef,undef, $paging_nav);
3670
3671         if (!@commitlist) {
3672                 my %co = parse_commit($hash);
3673
3674                 git_print_header_div('summary', $project);
3675                 print "<div class=\"page_body\"> Last change $co{'age_string'}.<br/><br/></div>\n";
3676         }
3677         my $to = ($#commitlist >= 99) ? (99) : ($#commitlist);
3678         for (my $i = 0; $i <= $to; $i++) {
3679                 my %co = %{$commitlist[$i]};
3680                 next if !%co;
3681                 my $commit = $co{'id'};
3682                 my $ref = format_ref_marker($refs, $commit);
3683                 my %ad = parse_date($co{'author_epoch'});
3684                 git_print_header_div('commit',
3685                                "<span class=\"age\">$co{'age_string'}</span>" .
3686                                esc_html($co{'title'}) . $ref,
3687                                $commit);
3688                 print "<div class=\"title_text\">\n" .
3689                       "<div class=\"log_link\">\n" .
3690                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") .
3691                       " | " .
3692                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") .
3693                       " | " .
3694                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree") .
3695                       "<br/>\n" .
3696                       "</div>\n" .
3697                       "<i>" . esc_html($co{'author_name'}) .  " [$ad{'rfc2822'}]</i><br/>\n" .
3698                       "</div>\n";
3699
3700                 print "<div class=\"log_body\">\n";
3701                 git_print_log($co{'comment'}, -final_empty_line=> 1);
3702                 print "</div>\n";
3703         }
3704         if ($#commitlist >= 100) {
3705                 print "<div class=\"page_nav\">\n";
3706                 print $cgi->a({-href => href(action=>"log", hash=>$hash, page=>$page+1),
3707                                -accesskey => "n", -title => "Alt-n"}, "next");
3708                 print "</div>\n";
3709         }
3710         git_footer_html();
3711 }
3712
3713 sub git_commit {
3714         $hash ||= $hash_base || "HEAD";
3715         my %co = parse_commit($hash);
3716         if (!%co) {
3717                 die_error(undef, "Unknown commit object");
3718         }
3719         my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
3720         my %cd = parse_date($co{'committer_epoch'}, $co{'committer_tz'});
3721
3722         my $parent  = $co{'parent'};
3723         my $parents = $co{'parents'}; # listref
3724
3725         # we need to prepare $formats_nav before any parameter munging
3726         my $formats_nav;
3727         if (!defined $parent) {
3728                 # --root commitdiff
3729                 $formats_nav .= '(initial)';
3730         } elsif (@$parents == 1) {
3731                 # single parent commit
3732                 $formats_nav .=
3733                         '(parent: ' .
3734                         $cgi->a({-href => href(action=>"commit",
3735                                                hash=>$parent)},
3736                                 esc_html(substr($parent, 0, 7))) .
3737                         ')';
3738         } else {
3739                 # merge commit
3740                 $formats_nav .=
3741                         '(merge: ' .
3742                         join(' ', map {
3743                                 $cgi->a({-href => href(action=>"commit",
3744                                                        hash=>$_)},
3745                                         esc_html(substr($_, 0, 7)));
3746                         } @$parents ) .
3747                         ')';
3748         }
3749
3750         if (!defined $parent) {
3751                 $parent = "--root";
3752         }
3753         my @difftree;
3754         if (@$parents <= 1) {
3755                 # difftree output is not printed for merges
3756                 open my $fd, "-|", git_cmd(), "diff-tree", '-r', "--no-commit-id",
3757                         @diff_opts, $parent, $hash, "--"
3758                         or die_error(undef, "Open git-diff-tree failed");
3759                 @difftree = map { chomp; $_ } <$fd>;
3760                 close $fd or die_error(undef, "Reading git-diff-tree failed");
3761         }
3762
3763         # non-textual hash id's can be cached
3764         my $expires;
3765         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
3766                 $expires = "+1d";
3767         }
3768         my $refs = git_get_references();
3769         my $ref = format_ref_marker($refs, $co{'id'});
3770
3771         my $have_snapshot = gitweb_have_snapshot();
3772
3773         git_header_html(undef, $expires);
3774         git_print_page_nav('commit', '',
3775                            $hash, $co{'tree'}, $hash,
3776                            $formats_nav);
3777
3778         if (defined $co{'parent'}) {
3779                 git_print_header_div('commitdiff', esc_html($co{'title'}) . $ref, $hash);
3780         } else {
3781                 git_print_header_div('tree', esc_html($co{'title'}) . $ref, $co{'tree'}, $hash);
3782         }
3783         print "<div class=\"title_text\">\n" .
3784               "<table cellspacing=\"0\">\n";
3785         print "<tr><td>author</td><td>" . esc_html($co{'author'}) . "</td></tr>\n".
3786               "<tr>" .
3787               "<td></td><td> $ad{'rfc2822'}";
3788         if ($ad{'hour_local'} < 6) {
3789                 printf(" (<span class=\"atnight\">%02d:%02d</span> %s)",
3790                        $ad{'hour_local'}, $ad{'minute_local'}, $ad{'tz_local'});
3791         } else {
3792                 printf(" (%02d:%02d %s)",
3793                        $ad{'hour_local'}, $ad{'minute_local'}, $ad{'tz_local'});
3794         }
3795         print "</td>" .
3796               "</tr>\n";
3797         print "<tr><td>committer</td><td>" . esc_html($co{'committer'}) . "</td></tr>\n";
3798         print "<tr><td></td><td> $cd{'rfc2822'}" .
3799               sprintf(" (%02d:%02d %s)", $cd{'hour_local'}, $cd{'minute_local'}, $cd{'tz_local'}) .
3800               "</td></tr>\n";
3801         print "<tr><td>commit</td><td class=\"sha1\">$co{'id'}</td></tr>\n";
3802         print "<tr>" .
3803               "<td>tree</td>" .
3804               "<td class=\"sha1\">" .
3805               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash),
3806                        class => "list"}, $co{'tree'}) .
3807               "</td>" .
3808               "<td class=\"link\">" .
3809               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash)},
3810                       "tree");
3811         if ($have_snapshot) {
3812                 print " | " .
3813                       $cgi->a({-href => href(action=>"snapshot", hash=>$hash)}, "snapshot");
3814         }
3815         print "</td>" .
3816               "</tr>\n";
3817
3818         foreach my $par (@$parents) {
3819                 print "<tr>" .
3820                       "<td>parent</td>" .
3821                       "<td class=\"sha1\">" .
3822                       $cgi->a({-href => href(action=>"commit", hash=>$par),
3823                                class => "list"}, $par) .
3824                       "</td>" .
3825                       "<td class=\"link\">" .
3826                       $cgi->a({-href => href(action=>"commit", hash=>$par)}, "commit") .
3827                       " | " .
3828                       $cgi->a({-href => href(action=>"commitdiff", hash=>$hash, hash_parent=>$par)}, "diff") .
3829                       "</td>" .
3830                       "</tr>\n";
3831         }
3832         print "</table>".
3833               "</div>\n";
3834
3835         print "<div class=\"page_body\">\n";
3836         git_print_log($co{'comment'});
3837         print "</div>\n";
3838
3839         if (@$parents <= 1) {
3840                 # do not output difftree/whatchanged for merges
3841                 git_difftree_body(\@difftree, $hash, $parent);
3842         }
3843
3844         git_footer_html();
3845 }
3846
3847 sub git_object {
3848         # object is defined by:
3849         # - hash or hash_base alone
3850         # - hash_base and file_name
3851         my $type;
3852
3853         # - hash or hash_base alone
3854         if ($hash || ($hash_base && !defined $file_name)) {
3855                 my $object_id = $hash || $hash_base;
3856
3857                 my $git_command = git_cmd_str();
3858                 open my $fd, "-|", "$git_command cat-file -t $object_id 2>/dev/null"
3859                         or die_error('404 Not Found', "Object does not exist");
3860                 $type = <$fd>;
3861                 chomp $type;
3862                 close $fd
3863                         or die_error('404 Not Found', "Object does not exist");
3864
3865         # - hash_base and file_name
3866         } elsif ($hash_base && defined $file_name) {
3867                 $file_name =~ s,/+$,,;
3868
3869                 system(git_cmd(), "cat-file", '-e', $hash_base) == 0
3870                         or die_error('404 Not Found', "Base object does not exist");
3871
3872                 # here errors should not hapen
3873                 open my $fd, "-|", git_cmd(), "ls-tree", $hash_base, "--", $file_name
3874                         or die_error(undef, "Open git-ls-tree failed");
3875                 my $line = <$fd>;
3876                 close $fd;
3877
3878                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
3879                 unless ($line && $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/) {
3880                         die_error('404 Not Found', "File or directory for given base does not exist");
3881                 }
3882                 $type = $2;
3883                 $hash = $3;
3884         } else {
3885                 die_error('404 Not Found', "Not enough information to find object");
3886         }
3887
3888         print $cgi->redirect(-uri => href(action=>$type, -full=>1,
3889                                           hash=>$hash, hash_base=>$hash_base,
3890                                           file_name=>$file_name),
3891                              -status => '302 Found');
3892 }
3893
3894 sub git_blobdiff {
3895         my $format = shift || 'html';
3896
3897         my $fd;
3898         my @difftree;
3899         my %diffinfo;
3900         my $expires;
3901
3902         # preparing $fd and %diffinfo for git_patchset_body
3903         # new style URI
3904         if (defined $hash_base && defined $hash_parent_base) {
3905                 if (defined $file_name) {
3906                         # read raw output
3907                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
3908                                 $hash_parent_base, $hash_base,
3909                                 "--", (defined $file_parent ? $file_parent : ()), $file_name
3910                                 or die_error(undef, "Open git-diff-tree failed");
3911                         @difftree = map { chomp; $_ } <$fd>;
3912                         close $fd
3913                                 or die_error(undef, "Reading git-diff-tree failed");
3914                         @difftree
3915                                 or die_error('404 Not Found', "Blob diff not found");
3916
3917                 } elsif (defined $hash &&
3918                          $hash =~ /[0-9a-fA-F]{40}/) {
3919                         # try to find filename from $hash
3920
3921                         # read filtered raw output
3922                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
3923                                 $hash_parent_base, $hash_base, "--"
3924                                 or die_error(undef, "Open git-diff-tree failed");
3925                         @difftree =
3926                                 # ':100644 100644 03b21826... 3b93d5e7... M     ls-files.c'
3927                                 # $hash == to_id
3928                                 grep { /^:[0-7]{6} [0-7]{6} [0-9a-fA-F]{40} $hash/ }
3929                                 map { chomp; $_ } <$fd>;
3930                         close $fd
3931                                 or die_error(undef, "Reading git-diff-tree failed");
3932                         @difftree
3933                                 or die_error('404 Not Found', "Blob diff not found");
3934
3935                 } else {
3936                         die_error('404 Not Found', "Missing one of the blob diff parameters");
3937                 }
3938
3939                 if (@difftree > 1) {
3940                         die_error('404 Not Found', "Ambiguous blob diff specification");
3941                 }
3942
3943                 %diffinfo = parse_difftree_raw_line($difftree[0]);
3944                 $file_parent ||= $diffinfo{'from_file'} || $file_name || $diffinfo{'file'};
3945                 $file_name   ||= $diffinfo{'to_file'}   || $diffinfo{'file'};
3946
3947                 $hash_parent ||= $diffinfo{'from_id'};
3948                 $hash        ||= $diffinfo{'to_id'};
3949
3950                 # non-textual hash id's can be cached
3951                 if ($hash_base =~ m/^[0-9a-fA-F]{40}$/ &&
3952                     $hash_parent_base =~ m/^[0-9a-fA-F]{40}$/) {
3953                         $expires = '+1d';
3954                 }
3955
3956                 # open patch output
3957                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
3958                         '-p', ($format eq 'html' ? "--full-index" : ()),
3959                         $hash_parent_base, $hash_base,
3960                         "--", (defined $file_parent ? $file_parent : ()), $file_name
3961                         or die_error(undef, "Open git-diff-tree failed");
3962         }
3963
3964         # old/legacy style URI
3965         if (!%diffinfo && # if new style URI failed
3966             defined $hash && defined $hash_parent) {
3967                 # fake git-diff-tree raw output
3968                 $diffinfo{'from_mode'} = $diffinfo{'to_mode'} = "blob";
3969                 $diffinfo{'from_id'} = $hash_parent;
3970                 $diffinfo{'to_id'}   = $hash;
3971                 if (defined $file_name) {
3972                         if (defined $file_parent) {
3973                                 $diffinfo{'status'} = '2';
3974                                 $diffinfo{'from_file'} = $file_parent;
3975                                 $diffinfo{'to_file'}   = $file_name;
3976                         } else { # assume not renamed
3977                                 $diffinfo{'status'} = '1';
3978                                 $diffinfo{'from_file'} = $file_name;
3979                                 $diffinfo{'to_file'}   = $file_name;
3980                         }
3981                 } else { # no filename given
3982                         $diffinfo{'status'} = '2';
3983                         $diffinfo{'from_file'} = $hash_parent;
3984                         $diffinfo{'to_file'}   = $hash;
3985                 }
3986
3987                 # non-textual hash id's can be cached
3988                 if ($hash =~ m/^[0-9a-fA-F]{40}$/ &&
3989                     $hash_parent =~ m/^[0-9a-fA-F]{40}$/) {
3990                         $expires = '+1d';
3991                 }
3992
3993                 # open patch output
3994                 open $fd, "-|", git_cmd(), "diff", @diff_opts,
3995                         '-p', ($format eq 'html' ? "--full-index" : ()),
3996                         $hash_parent, $hash, "--"
3997                         or die_error(undef, "Open git-diff failed");
3998         } else  {
3999                 die_error('404 Not Found', "Missing one of the blob diff parameters")
4000                         unless %diffinfo;
4001         }
4002
4003         # header
4004         if ($format eq 'html') {
4005                 my $formats_nav =
4006                         $cgi->a({-href => href(action=>"blobdiff_plain",
4007                                                hash=>$hash, hash_parent=>$hash_parent,
4008                                                hash_base=>$hash_base, hash_parent_base=>$hash_parent_base,
4009                                                file_name=>$file_name, file_parent=>$file_parent)},
4010                                 "raw");
4011                 git_header_html(undef, $expires);
4012                 if (defined $hash_base && (my %co = parse_commit($hash_base))) {
4013                         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
4014                         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
4015                 } else {
4016                         print "<div class=\"page_nav\"><br/>$formats_nav<br/></div>\n";
4017                         print "<div class=\"title\">$hash vs $hash_parent</div>\n";
4018                 }
4019                 if (defined $file_name) {
4020                         git_print_page_path($file_name, "blob", $hash_base);
4021                 } else {
4022                         print "<div class=\"page_path\"></div>\n";
4023                 }
4024
4025         } elsif ($format eq 'plain') {
4026                 print $cgi->header(
4027                         -type => 'text/plain',
4028                         -charset => 'utf-8',
4029                         -expires => $expires,
4030                         -content_disposition => 'inline; filename="' . "$file_name" . '.patch"');
4031
4032                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
4033
4034         } else {
4035                 die_error(undef, "Unknown blobdiff format");
4036         }
4037
4038         # patch
4039         if ($format eq 'html') {
4040                 print "<div class=\"page_body\">\n";
4041
4042                 git_patchset_body($fd, [ \%diffinfo ], $hash_base, $hash_parent_base);
4043                 close $fd;
4044
4045                 print "</div>\n"; # class="page_body"
4046                 git_footer_html();
4047
4048         } else {
4049                 while (my $line = <$fd>) {
4050                         $line =~ s!a/($hash|$hash_parent)!'a/'.esc_path($diffinfo{'from_file'})!eg;
4051                         $line =~ s!b/($hash|$hash_parent)!'b/'.esc_path($diffinfo{'to_file'})!eg;
4052
4053                         print $line;
4054
4055                         last if $line =~ m!^\+\+\+!;
4056                 }
4057                 local $/ = undef;
4058                 print <$fd>;
4059                 close $fd;
4060         }
4061 }
4062
4063 sub git_blobdiff_plain {
4064         git_blobdiff('plain');
4065 }
4066
4067 sub git_commitdiff {
4068         my $format = shift || 'html';
4069         $hash ||= $hash_base || "HEAD";
4070         my %co = parse_commit($hash);
4071         if (!%co) {
4072                 die_error(undef, "Unknown commit object");
4073         }
4074
4075         # we need to prepare $formats_nav before any parameter munging
4076         my $formats_nav;
4077         if ($format eq 'html') {
4078                 $formats_nav =
4079                         $cgi->a({-href => href(action=>"commitdiff_plain",
4080                                                hash=>$hash, hash_parent=>$hash_parent)},
4081                                 "raw");
4082
4083                 if (defined $hash_parent) {
4084                         # commitdiff with two commits given
4085                         my $hash_parent_short = $hash_parent;
4086                         if ($hash_parent =~ m/^[0-9a-fA-F]{40}$/) {
4087                                 $hash_parent_short = substr($hash_parent, 0, 7);
4088                         }
4089                         $formats_nav .=
4090                                 ' (from: ' .
4091                                 $cgi->a({-href => href(action=>"commitdiff",
4092                                                        hash=>$hash_parent)},
4093                                         esc_html($hash_parent_short)) .
4094                                 ')';
4095                 } elsif (!$co{'parent'}) {
4096                         # --root commitdiff
4097                         $formats_nav .= ' (initial)';
4098                 } elsif (scalar @{$co{'parents'}} == 1) {
4099                         # single parent commit
4100                         $formats_nav .=
4101                                 ' (parent: ' .
4102                                 $cgi->a({-href => href(action=>"commitdiff",
4103                                                        hash=>$co{'parent'})},
4104                                         esc_html(substr($co{'parent'}, 0, 7))) .
4105                                 ')';
4106                 } else {
4107                         # merge commit
4108                         $formats_nav .=
4109                                 ' (merge: ' .
4110                                 join(' ', map {
4111                                         $cgi->a({-href => href(action=>"commitdiff",
4112                                                                hash=>$_)},
4113                                                 esc_html(substr($_, 0, 7)));
4114                                 } @{$co{'parents'}} ) .
4115                                 ')';
4116                 }
4117         }
4118
4119         if (!defined $hash_parent) {
4120                 $hash_parent = $co{'parent'} || '--root';
4121         }
4122
4123         # read commitdiff
4124         my $fd;
4125         my @difftree;
4126         if ($format eq 'html') {
4127                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
4128                         "--no-commit-id", "--patch-with-raw", "--full-index",
4129                         $hash_parent, $hash, "--"
4130                         or die_error(undef, "Open git-diff-tree failed");
4131
4132                 while (my $line = <$fd>) {
4133                         chomp $line;
4134                         # empty line ends raw part of diff-tree output
4135                         last unless $line;
4136                         push @difftree, $line;
4137                 }
4138
4139         } elsif ($format eq 'plain') {
4140                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
4141                         '-p', $hash_parent, $hash, "--"
4142                         or die_error(undef, "Open git-diff-tree failed");
4143
4144         } else {
4145                 die_error(undef, "Unknown commitdiff format");
4146         }
4147
4148         # non-textual hash id's can be cached
4149         my $expires;
4150         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
4151                 $expires = "+1d";
4152         }
4153
4154         # write commit message
4155         if ($format eq 'html') {
4156                 my $refs = git_get_references();
4157                 my $ref = format_ref_marker($refs, $co{'id'});
4158
4159                 git_header_html(undef, $expires);
4160                 git_print_page_nav('commitdiff','', $hash,$co{'tree'},$hash, $formats_nav);
4161                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash);
4162                 git_print_authorship(\%co);
4163                 print "<div class=\"page_body\">\n";
4164                 if (@{$co{'comment'}} > 1) {
4165                         print "<div class=\"log\">\n";
4166                         git_print_log($co{'comment'}, -final_empty_line=> 1, -remove_title => 1);
4167                         print "</div>\n"; # class="log"
4168                 }
4169
4170         } elsif ($format eq 'plain') {
4171                 my $refs = git_get_references("tags");
4172                 my $tagname = git_get_rev_name_tags($hash);
4173                 my $filename = basename($project) . "-$hash.patch";
4174
4175                 print $cgi->header(
4176                         -type => 'text/plain',
4177                         -charset => 'utf-8',
4178                         -expires => $expires,
4179                         -content_disposition => 'inline; filename="' . "$filename" . '"');
4180                 my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
4181                 print <<TEXT;
4182 From: $co{'author'}
4183 Date: $ad{'rfc2822'} ($ad{'tz_local'})
4184 Subject: $co{'title'}
4185 TEXT
4186                 print "X-Git-Tag: $tagname\n" if $tagname;
4187                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
4188
4189                 foreach my $line (@{$co{'comment'}}) {
4190                         print "$line\n";
4191                 }
4192                 print "---\n\n";
4193         }
4194
4195         # write patch
4196         if ($format eq 'html') {
4197                 git_difftree_body(\@difftree, $hash, $hash_parent);
4198                 print "<br/>\n";
4199
4200                 git_patchset_body($fd, \@difftree, $hash, $hash_parent);
4201                 close $fd;
4202                 print "</div>\n"; # class="page_body"
4203                 git_footer_html();
4204
4205         } elsif ($format eq 'plain') {
4206                 local $/ = undef;
4207                 print <$fd>;
4208                 close $fd
4209                         or print "Reading git-diff-tree failed\n";
4210         }
4211 }
4212
4213 sub git_commitdiff_plain {
4214         git_commitdiff('plain');
4215 }
4216
4217 sub git_history {
4218         if (!defined $hash_base) {
4219                 $hash_base = git_get_head_hash($project);
4220         }
4221         if (!defined $page) {
4222                 $page = 0;
4223         }
4224         my $ftype;
4225         my %co = parse_commit($hash_base);
4226         if (!%co) {
4227                 die_error(undef, "Unknown commit object");
4228         }
4229
4230         my $refs = git_get_references();
4231         my $limit = sprintf("--max-count=%i", (100 * ($page+1)));
4232
4233         if (!defined $hash && defined $file_name) {
4234                 $hash = git_get_hash_by_path($hash_base, $file_name);
4235         }
4236         if (defined $hash) {
4237                 $ftype = git_get_type($hash);
4238         }
4239
4240         my @commitlist = parse_commits($hash_base, 101, (100 * $page), "--full-history", $file_name);
4241
4242         my $paging_nav = '';
4243         if ($page > 0) {
4244                 $paging_nav .=
4245                         $cgi->a({-href => href(action=>"history", hash=>$hash, hash_base=>$hash_base,
4246                                                file_name=>$file_name)},
4247                                 "first");
4248                 $paging_nav .= " &sdot; " .
4249                         $cgi->a({-href => href(action=>"history", hash=>$hash, hash_base=>$hash_base,
4250                                                file_name=>$file_name, page=>$page-1),
4251                                  -accesskey => "p", -title => "Alt-p"}, "prev");
4252         } else {
4253                 $paging_nav .= "first";
4254                 $paging_nav .= " &sdot; prev";
4255         }
4256         if ($#commitlist >= 100) {
4257                 $paging_nav .= " &sdot; " .
4258                         $cgi->a({-href => href(action=>"history", hash=>$hash, hash_base=>$hash_base,
4259                                                file_name=>$file_name, page=>$page+1),
4260                                  -accesskey => "n", -title => "Alt-n"}, "next");
4261         } else {
4262                 $paging_nav .= " &sdot; next";
4263         }
4264         my $next_link = '';
4265         if ($#commitlist >= 100) {
4266                 $next_link =
4267                         $cgi->a({-href => href(action=>"history", hash=>$hash, hash_base=>$hash_base,
4268                                                file_name=>$file_name, page=>$page+1),
4269                                  -accesskey => "n", -title => "Alt-n"}, "next");
4270         }
4271
4272         git_header_html();
4273         git_print_page_nav('history','', $hash_base,$co{'tree'},$hash_base, $paging_nav);
4274         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
4275         git_print_page_path($file_name, $ftype, $hash_base);
4276
4277         git_history_body(\@commitlist, 0, 99,
4278                          $refs, $hash_base, $ftype, $next_link);
4279
4280         git_footer_html();
4281 }
4282
4283 sub git_search {
4284         my ($have_search) = gitweb_check_feature('search');
4285         if (!$have_search) {
4286                 die_error('403 Permission denied', "Permission denied");
4287         }
4288         if (!defined $searchtext) {
4289                 die_error(undef, "Text field empty");
4290         }
4291         if (!defined $hash) {
4292                 $hash = git_get_head_hash($project);
4293         }
4294         my %co = parse_commit($hash);
4295         if (!%co) {
4296                 die_error(undef, "Unknown commit object");
4297         }
4298         if (!defined $page) {
4299                 $page = 0;
4300         }
4301
4302         $searchtype ||= 'commit';
4303         if ($searchtype eq 'pickaxe') {
4304                 # pickaxe may take all resources of your box and run for several minutes
4305                 # with every query - so decide by yourself how public you make this feature
4306                 my ($have_pickaxe) = gitweb_check_feature('pickaxe');
4307                 if (!$have_pickaxe) {
4308                         die_error('403 Permission denied', "Permission denied");
4309                 }
4310         }
4311
4312         git_header_html();
4313
4314         if ($searchtype eq 'commit' or $searchtype eq 'author' or $searchtype eq 'committer') {
4315                 my $greptype;
4316                 if ($searchtype eq 'commit') {
4317                         $greptype = "--grep=";
4318                 } elsif ($searchtype eq 'author') {
4319                         $greptype = "--author=";
4320                 } elsif ($searchtype eq 'committer') {
4321                         $greptype = "--committer=";
4322                 }
4323                 $greptype .= $searchtext;
4324                 my @commitlist = parse_commits($hash, 101, (100 * $page), $greptype);
4325
4326                 my $paging_nav = '';
4327                 if ($page > 0) {
4328                         $paging_nav .=
4329                                 $cgi->a({-href => href(action=>"search", hash=>$hash,
4330                                                        searchtext=>$searchtext, searchtype=>$searchtype)},
4331                                         "first");
4332                         $paging_nav .= " &sdot; " .
4333                                 $cgi->a({-href => href(action=>"search", hash=>$hash,
4334                                                        searchtext=>$searchtext, searchtype=>$searchtype,
4335                                                        page=>$page-1),
4336                                          -accesskey => "p", -title => "Alt-p"}, "prev");
4337                 } else {
4338                         $paging_nav .= "first";
4339                         $paging_nav .= " &sdot; prev";
4340                 }
4341                 if ($#commitlist >= 100) {
4342                         $paging_nav .= " &sdot; " .
4343                                 $cgi->a({-href => href(action=>"search", hash=>$hash,
4344                                                        searchtext=>$searchtext, searchtype=>$searchtype,
4345                                                        page=>$page+1),
4346                                          -accesskey => "n", -title => "Alt-n"}, "next");
4347                 } else {
4348                         $paging_nav .= " &sdot; next";
4349                 }
4350                 my $next_link = '';
4351                 if ($#commitlist >= 100) {
4352                         $next_link =
4353                                 $cgi->a({-href => href(action=>"search", hash=>$hash,
4354                                                        searchtext=>$searchtext, searchtype=>$searchtype,
4355                                                        page=>$page+1),
4356                                          -accesskey => "n", -title => "Alt-n"}, "next");
4357                 }
4358
4359                 git_print_page_nav('','', $hash,$co{'tree'},$hash, $paging_nav);
4360                 git_print_header_div('commit', esc_html($co{'title'}), $hash);
4361                 git_search_grep_body(\@commitlist, 0, 99, $next_link);
4362         }
4363
4364         if ($searchtype eq 'pickaxe') {
4365                 git_print_page_nav('','', $hash,$co{'tree'},$hash);
4366                 git_print_header_div('commit', esc_html($co{'title'}), $hash);
4367
4368                 print "<table cellspacing=\"0\">\n";
4369                 my $alternate = 1;
4370                 $/ = "\n";
4371                 my $git_command = git_cmd_str();
4372                 open my $fd, "-|", "$git_command rev-list $hash | " .
4373                         "$git_command diff-tree -r --stdin -S\'$searchtext\'";
4374                 undef %co;
4375                 my @files;
4376                 while (my $line = <$fd>) {
4377                         if (%co && $line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)\t(.*)$/) {
4378                                 my %set;
4379                                 $set{'file'} = $6;
4380                                 $set{'from_id'} = $3;
4381                                 $set{'to_id'} = $4;
4382                                 $set{'id'} = $set{'to_id'};
4383                                 if ($set{'id'} =~ m/0{40}/) {
4384                                         $set{'id'} = $set{'from_id'};
4385                                 }
4386                                 if ($set{'id'} =~ m/0{40}/) {
4387                                         next;
4388                                 }
4389                                 push @files, \%set;
4390                         } elsif ($line =~ m/^([0-9a-fA-F]{40})$/){
4391                                 if (%co) {
4392                                         if ($alternate) {
4393                                                 print "<tr class=\"dark\">\n";
4394                                         } else {
4395                                                 print "<tr class=\"light\">\n";
4396                                         }
4397                                         $alternate ^= 1;
4398                                         print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
4399                                               "<td><i>" . esc_html(chop_str($co{'author_name'}, 15, 5)) . "</i></td>\n" .
4400                                               "<td>" .
4401                                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
4402                                                       -class => "list subject"},
4403                                                       esc_html(chop_str($co{'title'}, 50)) . "<br/>");
4404                                         while (my $setref = shift @files) {
4405                                                 my %set = %$setref;
4406                                                 print $cgi->a({-href => href(action=>"blob", hash_base=>$co{'id'},
4407                                                                              hash=>$set{'id'}, file_name=>$set{'file'}),
4408                                                               -class => "list"},
4409                                                               "<span class=\"match\">" . esc_path($set{'file'}) . "</span>") .
4410                                                       "<br/>\n";
4411                                         }
4412                                         print "</td>\n" .
4413                                               "<td class=\"link\">" .
4414                                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
4415                                               " | " .
4416                                               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
4417                                         print "</td>\n" .
4418                                               "</tr>\n";
4419                                 }
4420                                 %co = parse_commit($1);
4421                         }
4422                 }
4423                 close $fd;
4424
4425                 print "</table>\n";
4426         }
4427         git_footer_html();
4428 }
4429
4430 sub git_search_help {
4431         git_header_html();
4432         git_print_page_nav('','', $hash,$hash,$hash);
4433         print <<EOT;
4434 <dl>
4435 <dt><b>commit</b></dt>
4436 <dd>The commit messages and authorship information will be scanned for the given string.</dd>
4437 <dt><b>author</b></dt>
4438 <dd>Name and e-mail of the change author and date of birth of the patch will be scanned for the given string.</dd>
4439 <dt><b>committer</b></dt>
4440 <dd>Name and e-mail of the committer and date of commit will be scanned for the given string.</dd>
4441 EOT
4442         my ($have_pickaxe) = gitweb_check_feature('pickaxe');
4443         if ($have_pickaxe) {
4444                 print <<EOT;
4445 <dt><b>pickaxe</b></dt>
4446 <dd>All commits that caused the string to appear or disappear from any file (changes that
4447 added, removed or "modified" the string) will be listed. This search can take a while and
4448 takes a lot of strain on the server, so please use it wisely.</dd>
4449 EOT
4450         }
4451         print "</dl>\n";
4452         git_footer_html();
4453 }
4454
4455 sub git_shortlog {
4456         my $head = git_get_head_hash($project);
4457         if (!defined $hash) {
4458                 $hash = $head;
4459         }
4460         if (!defined $page) {
4461                 $page = 0;
4462         }
4463         my $refs = git_get_references();
4464
4465         my @commitlist = parse_commits($hash, 101, (100 * $page));
4466
4467         my $paging_nav = format_paging_nav('shortlog', $hash, $head, $page, (100 * ($page+1)));
4468         my $next_link = '';
4469         if ($#commitlist >= 100) {
4470                 $next_link =
4471                         $cgi->a({-href => href(action=>"shortlog", hash=>$hash, page=>$page+1),
4472                                  -accesskey => "n", -title => "Alt-n"}, "next");
4473         }
4474
4475         git_header_html();
4476         git_print_page_nav('shortlog','', $hash,$hash,$hash, $paging_nav);
4477         git_print_header_div('summary', $project);
4478
4479         git_shortlog_body(\@commitlist, 0, 99, $refs, $next_link);
4480
4481         git_footer_html();
4482 }
4483
4484 ## ......................................................................
4485 ## feeds (RSS, Atom; OPML)
4486
4487 sub git_feed {
4488         my $format = shift || 'atom';
4489         my ($have_blame) = gitweb_check_feature('blame');
4490
4491         # Atom: http://www.atomenabled.org/developers/syndication/
4492         # RSS:  http://www.notestips.com/80256B3A007F2692/1/NAMO5P9UPQ
4493         if ($format ne 'rss' && $format ne 'atom') {
4494                 die_error(undef, "Unknown web feed format");
4495         }
4496
4497         # log/feed of current (HEAD) branch, log of given branch, history of file/directory
4498         my $head = $hash || 'HEAD';
4499         my @commitlist = parse_commits($head, 150);
4500
4501         my %latest_commit;
4502         my %latest_date;
4503         my $content_type = "application/$format+xml";
4504         if (defined $cgi->http('HTTP_ACCEPT') &&
4505                  $cgi->Accept('text/xml') > $cgi->Accept($content_type)) {
4506                 # browser (feed reader) prefers text/xml
4507                 $content_type = 'text/xml';
4508         }
4509         if (defined($commitlist[0])) {
4510                 %latest_commit = %{$commitlist[0]};
4511                 %latest_date   = parse_date($latest_commit{'author_epoch'});
4512                 print $cgi->header(
4513                         -type => $content_type,
4514                         -charset => 'utf-8',
4515                         -last_modified => $latest_date{'rfc2822'});
4516         } else {
4517                 print $cgi->header(
4518                         -type => $content_type,
4519                         -charset => 'utf-8');
4520         }
4521
4522         # Optimization: skip generating the body if client asks only
4523         # for Last-Modified date.
4524         return if ($cgi->request_method() eq 'HEAD');
4525
4526         # header variables
4527         my $title = "$site_name - $project/$action";
4528         my $feed_type = 'log';
4529         if (defined $hash) {
4530                 $title .= " - '$hash'";
4531                 $feed_type = 'branch log';
4532                 if (defined $file_name) {
4533                         $title .= " :: $file_name";
4534                         $feed_type = 'history';
4535                 }
4536         } elsif (defined $file_name) {
4537                 $title .= " - $file_name";
4538                 $feed_type = 'history';
4539         }
4540         $title .= " $feed_type";
4541         my $descr = git_get_project_description($project);
4542         if (defined $descr) {
4543                 $descr = esc_html($descr);
4544         } else {
4545                 $descr = "$project " .
4546                          ($format eq 'rss' ? 'RSS' : 'Atom') .
4547                          " feed";
4548         }
4549         my $owner = git_get_project_owner($project);
4550         $owner = esc_html($owner);
4551
4552         #header
4553         my $alt_url;
4554         if (defined $file_name) {
4555                 $alt_url = href(-full=>1, action=>"history", hash=>$hash, file_name=>$file_name);
4556         } elsif (defined $hash) {
4557                 $alt_url = href(-full=>1, action=>"log", hash=>$hash);
4558         } else {
4559                 $alt_url = href(-full=>1, action=>"summary");
4560         }
4561         print qq!<?xml version="1.0" encoding="utf-8"?>\n!;
4562         if ($format eq 'rss') {
4563                 print <<XML;
4564 <rss version="2.0" xmlns:content="http://purl.org/rss/1.0/modules/content/">
4565 <channel>
4566 XML
4567                 print "<title>$title</title>\n" .
4568                       "<link>$alt_url</link>\n" .
4569                       "<description>$descr</description>\n" .
4570                       "<language>en</language>\n";
4571         } elsif ($format eq 'atom') {
4572                 print <<XML;
4573 <feed xmlns="http://www.w3.org/2005/Atom">
4574 XML
4575                 print "<title>$title</title>\n" .
4576                       "<subtitle>$descr</subtitle>\n" .
4577                       '<link rel="alternate" type="text/html" href="' .
4578                       $alt_url . '" />' . "\n" .
4579                       '<link rel="self" type="' . $content_type . '" href="' .
4580                       $cgi->self_url() . '" />' . "\n" .
4581                       "<id>" . href(-full=>1) . "</id>\n" .
4582                       # use project owner for feed author
4583                       "<author><name>$owner</name></author>\n";
4584                 if (defined $favicon) {
4585                         print "<icon>" . esc_url($favicon) . "</icon>\n";
4586                 }
4587                 if (defined $logo_url) {
4588                         # not twice as wide as tall: 72 x 27 pixels
4589                         print "<logo>" . esc_url($logo) . "</logo>\n";
4590                 }
4591                 if (! %latest_date) {
4592                         # dummy date to keep the feed valid until commits trickle in:
4593                         print "<updated>1970-01-01T00:00:00Z</updated>\n";
4594                 } else {
4595                         print "<updated>$latest_date{'iso-8601'}</updated>\n";
4596                 }
4597         }
4598
4599         # contents
4600         for (my $i = 0; $i <= $#commitlist; $i++) {
4601                 my %co = %{$commitlist[$i]};
4602                 my $commit = $co{'id'};
4603                 # we read 150, we always show 30 and the ones more recent than 48 hours
4604                 if (($i >= 20) && ((time - $co{'author_epoch'}) > 48*60*60)) {
4605                         last;
4606                 }
4607                 my %cd = parse_date($co{'author_epoch'});
4608
4609                 # get list of changed files
4610                 open my $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
4611                         $co{'parent'}, $co{'id'}, "--", (defined $file_name ? $file_name : ())
4612                         or next;
4613                 my @difftree = map { chomp; $_ } <$fd>;
4614                 close $fd
4615                         or next;
4616
4617                 # print element (entry, item)
4618                 my $co_url = href(-full=>1, action=>"commit", hash=>$commit);
4619                 if ($format eq 'rss') {
4620                         print "<item>\n" .
4621                               "<title>" . esc_html($co{'title'}) . "</title>\n" .
4622                               "<author>" . esc_html($co{'author'}) . "</author>\n" .
4623                               "<pubDate>$cd{'rfc2822'}</pubDate>\n" .
4624                               "<guid isPermaLink=\"true\">$co_url</guid>\n" .
4625                               "<link>$co_url</link>\n" .
4626                               "<description>" . esc_html($co{'title'}) . "</description>\n" .
4627                               "<content:encoded>" .
4628                               "<![CDATA[\n";
4629                 } elsif ($format eq 'atom') {
4630                         print "<entry>\n" .
4631                               "<title type=\"html\">" . esc_html($co{'title'}) . "</title>\n" .
4632                               "<updated>$cd{'iso-8601'}</updated>\n" .
4633                               "<author>\n" .
4634                               "  <name>" . esc_html($co{'author_name'}) . "</name>\n";
4635                         if ($co{'author_email'}) {
4636                                 print "  <email>" . esc_html($co{'author_email'}) . "</email>\n";
4637                         }
4638                         print "</author>\n" .
4639                               # use committer for contributor
4640                               "<contributor>\n" .
4641                               "  <name>" . esc_html($co{'committer_name'}) . "</name>\n";
4642                         if ($co{'committer_email'}) {
4643                                 print "  <email>" . esc_html($co{'committer_email'}) . "</email>\n";
4644                         }
4645                         print "</contributor>\n" .
4646                               "<published>$cd{'iso-8601'}</published>\n" .
4647                               "<link rel=\"alternate\" type=\"text/html\" href=\"$co_url\" />\n" .
4648                               "<id>$co_url</id>\n" .
4649                               "<content type=\"xhtml\" xml:base=\"" . esc_url($my_url) . "\">\n" .
4650                               "<div xmlns=\"http://www.w3.org/1999/xhtml\">\n";
4651                 }
4652                 my $comment = $co{'comment'};
4653                 print "<pre>\n";
4654                 foreach my $line (@$comment) {
4655                         $line = esc_html($line);
4656                         print "$line\n";
4657                 }
4658                 print "</pre><ul>\n";
4659                 foreach my $difftree_line (@difftree) {
4660                         my %difftree = parse_difftree_raw_line($difftree_line);
4661                         next if !$difftree{'from_id'};
4662
4663                         my $file = $difftree{'file'} || $difftree{'to_file'};
4664
4665                         print "<li>" .
4666                               "[" .
4667                               $cgi->a({-href => href(-full=>1, action=>"blobdiff",
4668                                                      hash=>$difftree{'to_id'}, hash_parent=>$difftree{'from_id'},
4669                                                      hash_base=>$co{'id'}, hash_parent_base=>$co{'parent'},
4670                                                      file_name=>$file, file_parent=>$difftree{'from_file'}),
4671                                       -title => "diff"}, 'D');
4672                         if ($have_blame) {
4673                                 print $cgi->a({-href => href(-full=>1, action=>"blame",
4674                                                              file_name=>$file, hash_base=>$commit),
4675                                               -title => "blame"}, 'B');
4676                         }
4677                         # if this is not a feed of a file history
4678                         if (!defined $file_name || $file_name ne $file) {
4679                                 print $cgi->a({-href => href(-full=>1, action=>"history",
4680                                                              file_name=>$file, hash=>$commit),
4681                                               -title => "history"}, 'H');
4682                         }
4683                         $file = esc_path($file);
4684                         print "] ".
4685                               "$file</li>\n";
4686                 }
4687                 if ($format eq 'rss') {
4688                         print "</ul>]]>\n" .
4689                               "</content:encoded>\n" .
4690                               "</item>\n";
4691                 } elsif ($format eq 'atom') {
4692                         print "</ul>\n</div>\n" .
4693                               "</content>\n" .
4694                               "</entry>\n";
4695                 }
4696         }
4697
4698         # end of feed
4699         if ($format eq 'rss') {
4700                 print "</channel>\n</rss>\n";
4701         }       elsif ($format eq 'atom') {
4702                 print "</feed>\n";
4703         }
4704 }
4705
4706 sub git_rss {
4707         git_feed('rss');
4708 }
4709
4710 sub git_atom {
4711         git_feed('atom');
4712 }
4713
4714 sub git_opml {
4715         my @list = git_get_projects_list();
4716
4717         print $cgi->header(-type => 'text/xml', -charset => 'utf-8');
4718         print <<XML;
4719 <?xml version="1.0" encoding="utf-8"?>
4720 <opml version="1.0">
4721 <head>
4722   <title>$site_name OPML Export</title>
4723 </head>
4724 <body>
4725 <outline text="git RSS feeds">
4726 XML
4727
4728         foreach my $pr (@list) {
4729                 my %proj = %$pr;
4730                 my $head = git_get_head_hash($proj{'path'});
4731                 if (!defined $head) {
4732                         next;
4733                 }
4734                 $git_dir = "$projectroot/$proj{'path'}";
4735                 my %co = parse_commit($head);
4736                 if (!%co) {
4737                         next;
4738                 }
4739
4740                 my $path = esc_html(chop_str($proj{'path'}, 25, 5));
4741                 my $rss  = "$my_url?p=$proj{'path'};a=rss";
4742                 my $html = "$my_url?p=$proj{'path'};a=summary";
4743                 print "<outline type=\"rss\" text=\"$path\" title=\"$path\" xmlUrl=\"$rss\" htmlUrl=\"$html\"/>\n";
4744         }
4745         print <<XML;
4746 </outline>
4747 </body>
4748 </opml>
4749 XML
4750 }