Lady’s Gitweb - Gitweb/blob - gitweb.perl

   1 #!/usr/bin/perl
   2
   3 # gitweb - simple web interface to track changes in git repositories
   4 #
   5 # (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
   6 # (C) 2005, Christian Gierke
   7 #
   8 # This program is licensed under the GPLv2
   9
  10 use 5.008;
  11 use strict;
  12 use warnings;
  13 use CGI qw(:standard :escapeHTML -nosticky);
  14 use CGI::Util qw(unescape);
  15 use CGI::Carp qw(fatalsToBrowser set_message);
  16 use Encode;
  17 use Fcntl ':mode';
  18 use File::Find qw();
  19 use File::Basename qw(basename);
  20 use Time::HiRes qw(gettimeofday tv_interval);
  21 binmode STDOUT, ':utf8';
  22
  23 our $t0 = [ gettimeofday() ];
  24 our $number_of_git_cmds = 0;
  25
  26 BEGIN {
  27         CGI->compile() if $ENV{'MOD_PERL'};
  28 }
  29
  30 our $version = "++GIT_VERSION++";
  31
  32 our ($my_url, $my_uri, $base_url, $path_info, $home_link);
  33 sub evaluate_uri {
  34         our $cgi;
  35
  36         our $my_url = $cgi->url();
  37         our $my_uri = $cgi->url(-absolute => 1);
  38
  39         # Base URL for relative URLs in gitweb ($logo, $favicon, ...),
  40         # needed and used only for URLs with nonempty PATH_INFO
  41         our $base_url = $my_url;
  42
  43         # When the script is used as DirectoryIndex, the URL does not contain the name
  44         # of the script file itself, and $cgi->url() fails to strip PATH_INFO, so we
  45         # have to do it ourselves. We make $path_info global because it's also used
  46         # later on.
  47         #
  48         # Another issue with the script being the DirectoryIndex is that the resulting
  49         # $my_url data is not the full script URL: this is good, because we want
  50         # generated links to keep implying the script name if it wasn't explicitly
  51         # indicated in the URL we're handling, but it means that $my_url cannot be used
  52         # as base URL.
  53         # Therefore, if we needed to strip PATH_INFO, then we know that we have
  54         # to build the base URL ourselves:
  55         our $path_info = decode_utf8($ENV{"PATH_INFO"});
  56         if ($path_info) {
  57                 if ($my_url =~ s,\Q$path_info\E$,, &&
  58                     $my_uri =~ s,\Q$path_info\E$,, &&
  59                     defined $ENV{'SCRIPT_NAME'}) {
  60                         $base_url = $cgi->url(-base => 1) . $ENV{'SCRIPT_NAME'};
  61                 }
  62         }
  63
  64         # target of the home link on top of all pages
  65         our $home_link = $my_uri || "/";
  66 }
  67
  68 # core git executable to use
  69 # this can just be "git" if your webserver has a sensible PATH
  70 our $GIT = "++GIT_BINDIR++/git";
  71
  72 # absolute fs-path which will be prepended to the project path
  73 #our $projectroot = "/pub/scm";
  74 our $projectroot = "++GITWEB_PROJECTROOT++";
  75
  76 # fs traversing limit for getting project list
  77 # the number is relative to the projectroot
  78 our $project_maxdepth = "++GITWEB_PROJECT_MAXDEPTH++";
  79
  80 # string of the home link on top of all pages
  81 our $home_link_str = "++GITWEB_HOME_LINK_STR++";
  82
  83 # name of your site or organization to appear in page titles
  84 # replace this with something more descriptive for clearer bookmarks
  85 our $site_name = "++GITWEB_SITENAME++"
  86                  || ($ENV{'SERVER_NAME'} || "Untitled") . " Git";
  87
  88 # html snippet to include in the <head> section of each page
  89 our $site_html_head_string = "++GITWEB_SITE_HTML_HEAD_STRING++";
  90 # filename of html text to include at top of each page
  91 our $site_header = "++GITWEB_SITE_HEADER++";
  92 # html text to include at home page
  93 our $home_text = "++GITWEB_HOMETEXT++";
  94 # filename of html text to include at bottom of each page
  95 our $site_footer = "++GITWEB_SITE_FOOTER++";
  96
  97 # URI of stylesheets
  98 our @stylesheets = ("++GITWEB_CSS++");
  99 # URI of a single stylesheet, which can be overridden in GITWEB_CONFIG.
 100 our $stylesheet = undef;
 101
 102 # URI of GIT logo (72x27 size)
 103 our $logo = "++GITWEB_LOGO++";
 104 # URI of GIT favicon, assumed to be image/png type
 105 our $favicon = "++GITWEB_FAVICON++";
 106 # URI of gitweb.js (JavaScript code for gitweb)
 107 our $javascript = "++GITWEB_JS++";
 108
 109 # URI and label (title) of GIT logo link
 110 #our $logo_url = "http://www.kernel.org/pub/software/scm/git/docs/";
 111 #our $logo_label = "git documentation";
 112 our $logo_url = "http://git-scm.com/";
 113 our $logo_label = "git homepage";
 114
 115 # source of projects list
 116 our $projects_list = "++GITWEB_LIST++";
 117
 118 # the width (in characters) of the projects list "Description" column
 119 our $projects_list_description_width = 25;
 120
 121 # group projects by category on the projects list
 122 # (enabled if this variable evaluates to true)
 123 our $projects_list_group_categories = 0;
 124
 125 # default category if none specified
 126 # (leave the empty string for no category)
 127 our $project_list_default_category = "";
 128
 129 # default order of projects list
 130 # valid values are none, project, descr, owner, and age
 131 our $default_projects_order = "project";
 132
 133 # show repository only if this file exists
 134 # (only effective if this variable evaluates to true)
 135 our $export_ok = "++GITWEB_EXPORT_OK++";
 136
 137 # show repository only if this subroutine returns true
 138 # when given the path to the project, for example:
 139 #    sub { return -e "$_[0]/git-daemon-export-ok"; }
 140 our $export_auth_hook = undef;
 141
 142 # only allow viewing of repositories also shown on the overview page
 143 our $strict_export = "++GITWEB_STRICT_EXPORT++";
 144
 145 # list of git base URLs used for URL to where fetch project from,
 146 # i.e. full URL is "$git_base_url/$project"
 147 our @git_base_url_list = grep { $_ ne '' } ("++GITWEB_BASE_URL++");
 148
 149 # default blob_plain mimetype and default charset for text/plain blob
 150 our $default_blob_plain_mimetype = 'text/plain';
 151 our $default_text_plain_charset  = undef;
 152
 153 # file to use for guessing MIME types before trying /etc/mime.types
 154 # (relative to the current git repository)
 155 our $mimetypes_file = undef;
 156
 157 # assume this charset if line contains non-UTF-8 characters;
 158 # it should be valid encoding (see Encoding::Supported(3pm) for list),
 159 # for which encoding all byte sequences are valid, for example
 160 # 'iso-8859-1' aka 'latin1' (it is decoded without checking, so it
 161 # could be even 'utf-8' for the old behavior)
 162 our $fallback_encoding = 'latin1';
 163
 164 # rename detection options for git-diff and git-diff-tree
 165 # - default is '-M', with the cost proportional to
 166 #   (number of removed files) * (number of new files).
 167 # - more costly is '-C' (which implies '-M'), with the cost proportional to
 168 #   (number of changed files + number of removed files) * (number of new files)
 169 # - even more costly is '-C', '--find-copies-harder' with cost
 170 #   (number of files in the original tree) * (number of new files)
 171 # - one might want to include '-B' option, e.g. '-B', '-M'
 172 our @diff_opts = ('-M'); # taken from git_commit
 173
 174 # Disables features that would allow repository owners to inject script into
 175 # the gitweb domain.
 176 our $prevent_xss = 0;
 177
 178 # Path to the highlight executable to use (must be the one from
 179 # http://www.andre-simon.de due to assumptions about parameters and output).
 180 # Useful if highlight is not installed on your webserver's PATH.
 181 # [Default: highlight]
 182 our $highlight_bin = "++HIGHLIGHT_BIN++";
 183
 184 # information about snapshot formats that gitweb is capable of serving
 185 our %known_snapshot_formats = (
 186         # name => {
 187         #       'display' => display name,
 188         #       'type' => mime type,
 189         #       'suffix' => filename suffix,
 190         #       'format' => --format for git-archive,
 191         #       'compressor' => [compressor command and arguments]
 192         #                       (array reference, optional)
 193         #       'disabled' => boolean (optional)}
 194         #
 195         'tgz' => {
 196                 'display' => 'tar.gz',
 197                 'type' => 'application/x-gzip',
 198                 'suffix' => '.tar.gz',
 199                 'format' => 'tar',
 200                 'compressor' => ['gzip', '-n']},
 201
 202         'tbz2' => {
 203                 'display' => 'tar.bz2',
 204                 'type' => 'application/x-bzip2',
 205                 'suffix' => '.tar.bz2',
 206                 'format' => 'tar',
 207                 'compressor' => ['bzip2']},
 208
 209         'txz' => {
 210                 'display' => 'tar.xz',
 211                 'type' => 'application/x-xz',
 212                 'suffix' => '.tar.xz',
 213                 'format' => 'tar',
 214                 'compressor' => ['xz'],
 215                 'disabled' => 1},
 216
 217         'zip' => {
 218                 'display' => 'zip',
 219                 'type' => 'application/x-zip',
 220                 'suffix' => '.zip',
 221                 'format' => 'zip'},
 222 );
 223
 224 # Aliases so we understand old gitweb.snapshot values in repository
 225 # configuration.
 226 our %known_snapshot_format_aliases = (
 227         'gzip'  => 'tgz',
 228         'bzip2' => 'tbz2',
 229         'xz'    => 'txz',
 230
 231         # backward compatibility: legacy gitweb config support
 232         'x-gzip' => undef, 'gz' => undef,
 233         'x-bzip2' => undef, 'bz2' => undef,
 234         'x-zip' => undef, '' => undef,
 235 );
 236
 237 # Pixel sizes for icons and avatars. If the default font sizes or lineheights
 238 # are changed, it may be appropriate to change these values too via
 239 # $GITWEB_CONFIG.
 240 our %avatar_size = (
 241         'default' => 16,
 242         'double'  => 32
 243 );
 244
 245 # Used to set the maximum load that we will still respond to gitweb queries.
 246 # If server load exceed this value then return "503 server busy" error.
 247 # If gitweb cannot determined server load, it is taken to be 0.
 248 # Leave it undefined (or set to 'undef') to turn off load checking.
 249 our $maxload = 300;
 250
 251 # configuration for 'highlight' (http://www.andre-simon.de/)
 252 # match by basename
 253 our %highlight_basename = (
 254         #'Program' => 'py',
 255         #'Library' => 'py',
 256         'SConstruct' => 'py', # SCons equivalent of Makefile
 257         'Makefile' => 'make',
 258 );
 259 # match by extension
 260 our %highlight_ext = (
 261         # main extensions, defining name of syntax;
 262         # see files in /usr/share/highlight/langDefs/ directory
 263         map { $_ => $_ }
 264                 qw(py c cpp rb java css php sh pl js tex bib xml awk bat ini spec tcl sql make),
 265         # alternate extensions, see /etc/highlight/filetypes.conf
 266         'h' => 'c',
 267         map { $_ => 'sh'  } qw(bash zsh ksh),
 268         map { $_ => 'cpp' } qw(cxx c++ cc),
 269         map { $_ => 'php' } qw(php3 php4 php5 phps),
 270         map { $_ => 'pl'  } qw(perl pm), # perhaps also 'cgi'
 271         map { $_ => 'make'} qw(mak mk),
 272         map { $_ => 'xml' } qw(xhtml html htm),
 273 );
 274
 275 # You define site-wide feature defaults here; override them with
 276 # $GITWEB_CONFIG as necessary.
 277 our %feature = (
 278         # feature => {
 279         #       'sub' => feature-sub (subroutine),
 280         #       'override' => allow-override (boolean),
 281         #       'default' => [ default options...] (array reference)}
 282         #
 283         # if feature is overridable (it means that allow-override has true value),
 284         # then feature-sub will be called with default options as parameters;
 285         # return value of feature-sub indicates if to enable specified feature
 286         #
 287         # if there is no 'sub' key (no feature-sub), then feature cannot be
 288         # overridden
 289         #
 290         # use gitweb_get_feature(<feature>) to retrieve the <feature> value
 291         # (an array) or gitweb_check_feature(<feature>) to check if <feature>
 292         # is enabled
 293
 294         # Enable the 'blame' blob view, showing the last commit that modified
 295         # each line in the file. This can be very CPU-intensive.
 296
 297         # To enable system wide have in $GITWEB_CONFIG
 298         # $feature{'blame'}{'default'} = [1];
 299         # To have project specific config enable override in $GITWEB_CONFIG
 300         # $feature{'blame'}{'override'} = 1;
 301         # and in project config gitweb.blame = 0|1;
 302         'blame' => {
 303                 'sub' => sub { feature_bool('blame', @_) },
 304                 'override' => 0,
 305                 'default' => [0]},
 306
 307         # Enable the 'snapshot' link, providing a compressed archive of any
 308         # tree. This can potentially generate high traffic if you have large
 309         # project.
 310
 311         # Value is a list of formats defined in %known_snapshot_formats that
 312         # you wish to offer.
 313         # To disable system wide have in $GITWEB_CONFIG
 314         # $feature{'snapshot'}{'default'} = [];
 315         # To have project specific config enable override in $GITWEB_CONFIG
 316         # $feature{'snapshot'}{'override'} = 1;
 317         # and in project config, a comma-separated list of formats or "none"
 318         # to disable.  Example: gitweb.snapshot = tbz2,zip;
 319         'snapshot' => {
 320                 'sub' => \&feature_snapshot,
 321                 'override' => 0,
 322                 'default' => ['tgz']},
 323
 324         # Enable text search, which will list the commits which match author,
 325         # committer or commit text to a given string.  Enabled by default.
 326         # Project specific override is not supported.
 327         #
 328         # Note that this controls all search features, which means that if
 329         # it is disabled, then 'grep' and 'pickaxe' search would also be
 330         # disabled.
 331         'search' => {
 332                 'override' => 0,
 333                 'default' => [1]},
 334
 335         # Enable grep search, which will list the files in currently selected
 336         # tree containing the given string. Enabled by default. This can be
 337         # potentially CPU-intensive, of course.
 338         # Note that you need to have 'search' feature enabled too.
 339
 340         # To enable system wide have in $GITWEB_CONFIG
 341         # $feature{'grep'}{'default'} = [1];
 342         # To have project specific config enable override in $GITWEB_CONFIG
 343         # $feature{'grep'}{'override'} = 1;
 344         # and in project config gitweb.grep = 0|1;
 345         'grep' => {
 346                 'sub' => sub { feature_bool('grep', @_) },
 347                 'override' => 0,
 348                 'default' => [1]},
 349
 350         # Enable the pickaxe search, which will list the commits that modified
 351         # a given string in a file. This can be practical and quite faster
 352         # alternative to 'blame', but still potentially CPU-intensive.
 353         # Note that you need to have 'search' feature enabled too.
 354
 355         # To enable system wide have in $GITWEB_CONFIG
 356         # $feature{'pickaxe'}{'default'} = [1];
 357         # To have project specific config enable override in $GITWEB_CONFIG
 358         # $feature{'pickaxe'}{'override'} = 1;
 359         # and in project config gitweb.pickaxe = 0|1;
 360         'pickaxe' => {
 361                 'sub' => sub { feature_bool('pickaxe', @_) },
 362                 'override' => 0,
 363                 'default' => [1]},
 364
 365         # Enable showing size of blobs in a 'tree' view, in a separate
 366         # column, similar to what 'ls -l' does.  This cost a bit of IO.
 367
 368         # To disable system wide have in $GITWEB_CONFIG
 369         # $feature{'show-sizes'}{'default'} = [0];
 370         # To have project specific config enable override in $GITWEB_CONFIG
 371         # $feature{'show-sizes'}{'override'} = 1;
 372         # and in project config gitweb.showsizes = 0|1;
 373         'show-sizes' => {
 374                 'sub' => sub { feature_bool('showsizes', @_) },
 375                 'override' => 0,
 376                 'default' => [1]},
 377
 378         # Make gitweb use an alternative format of the URLs which can be
 379         # more readable and natural-looking: project name is embedded
 380         # directly in the path and the query string contains other
 381         # auxiliary information. All gitweb installations recognize
 382         # URL in either format; this configures in which formats gitweb
 383         # generates links.
 384
 385         # To enable system wide have in $GITWEB_CONFIG
 386         # $feature{'pathinfo'}{'default'} = [1];
 387         # Project specific override is not supported.
 388
 389         # Note that you will need to change the default location of CSS,
 390         # favicon, logo and possibly other files to an absolute URL. Also,
 391         # if gitweb.cgi serves as your indexfile, you will need to force
 392         # $my_uri to contain the script name in your $GITWEB_CONFIG.
 393         'pathinfo' => {
 394                 'override' => 0,
 395                 'default' => [0]},
 396
 397         # Make gitweb consider projects in project root subdirectories
 398         # to be forks of existing projects. Given project $projname.git,
 399         # projects matching $projname/*.git will not be shown in the main
 400         # projects list, instead a '+' mark will be added to $projname
 401         # there and a 'forks' view will be enabled for the project, listing
 402         # all the forks. If project list is taken from a file, forks have
 403         # to be listed after the main project.
 404
 405         # To enable system wide have in $GITWEB_CONFIG
 406         # $feature{'forks'}{'default'} = [1];
 407         # Project specific override is not supported.
 408         'forks' => {
 409                 'override' => 0,
 410                 'default' => [0]},
 411
 412         # Insert custom links to the action bar of all project pages.
 413         # This enables you mainly to link to third-party scripts integrating
 414         # into gitweb; e.g. git-browser for graphical history representation
 415         # or custom web-based repository administration interface.
 416
 417         # The 'default' value consists of a list of triplets in the form
 418         # (label, link, position) where position is the label after which
 419         # to insert the link and link is a format string where %n expands
 420         # to the project name, %f to the project path within the filesystem,
 421         # %h to the current hash (h gitweb parameter) and %b to the current
 422         # hash base (hb gitweb parameter); %% expands to %.
 423
 424         # To enable system wide have in $GITWEB_CONFIG e.g.
 425         # $feature{'actions'}{'default'} = [('graphiclog',
 426         #       '/git-browser/by-commit.html?r=%n', 'summary')];
 427         # Project specific override is not supported.
 428         'actions' => {
 429                 'override' => 0,
 430                 'default' => []},
 431
 432         # Allow gitweb scan project content tags of project repository,
 433         # and display the popular Web 2.0-ish "tag cloud" near the projects
 434         # list.  Note that this is something COMPLETELY different from the
 435         # normal Git tags.
 436
 437         # gitweb by itself can show existing tags, but it does not handle
 438         # tagging itself; you need to do it externally, outside gitweb.
 439         # The format is described in git_get_project_ctags() subroutine.
 440         # You may want to install the HTML::TagCloud Perl module to get
 441         # a pretty tag cloud instead of just a list of tags.
 442
 443         # To enable system wide have in $GITWEB_CONFIG
 444         # $feature{'ctags'}{'default'} = [1];
 445         # Project specific override is not supported.
 446
 447         # In the future whether ctags editing is enabled might depend
 448         # on the value, but using 1 should always mean no editing of ctags.
 449         'ctags' => {
 450                 'override' => 0,
 451                 'default' => [0]},
 452
 453         # The maximum number of patches in a patchset generated in patch
 454         # view. Set this to 0 or undef to disable patch view, or to a
 455         # negative number to remove any limit.
 456
 457         # To disable system wide have in $GITWEB_CONFIG
 458         # $feature{'patches'}{'default'} = [0];
 459         # To have project specific config enable override in $GITWEB_CONFIG
 460         # $feature{'patches'}{'override'} = 1;
 461         # and in project config gitweb.patches = 0|n;
 462         # where n is the maximum number of patches allowed in a patchset.
 463         'patches' => {
 464                 'sub' => \&feature_patches,
 465                 'override' => 0,
 466                 'default' => [16]},
 467
 468         # Avatar support. When this feature is enabled, views such as
 469         # shortlog or commit will display an avatar associated with
 470         # the email of the committer(s) and/or author(s).
 471
 472         # Currently available providers are gravatar and picon.
 473         # If an unknown provider is specified, the feature is disabled.
 474
 475         # Gravatar depends on Digest::MD5.
 476         # Picon currently relies on the indiana.edu database.
 477
 478         # To enable system wide have in $GITWEB_CONFIG
 479         # $feature{'avatar'}{'default'} = ['<provider>'];
 480         # where <provider> is either gravatar or picon.
 481         # To have project specific config enable override in $GITWEB_CONFIG
 482         # $feature{'avatar'}{'override'} = 1;
 483         # and in project config gitweb.avatar = <provider>;
 484         'avatar' => {
 485                 'sub' => \&feature_avatar,
 486                 'override' => 0,
 487                 'default' => ['']},
 488
 489         # Enable displaying how much time and how many git commands
 490         # it took to generate and display page.  Disabled by default.
 491         # Project specific override is not supported.
 492         'timed' => {
 493                 'override' => 0,
 494                 'default' => [0]},
 495
 496         # Enable turning some links into links to actions which require
 497         # JavaScript to run (like 'blame_incremental').  Not enabled by
 498         # default.  Project specific override is currently not supported.
 499         'javascript-actions' => {
 500                 'override' => 0,
 501                 'default' => [0]},
 502
 503         # Enable and configure ability to change common timezone for dates
 504         # in gitweb output via JavaScript.  Enabled by default.
 505         # Project specific override is not supported.
 506         'javascript-timezone' => {
 507                 'override' => 0,
 508                 'default' => [
 509                         'local',     # default timezone: 'utc', 'local', or '(-|+)HHMM' format,
 510                                      # or undef to turn off this feature
 511                         'gitweb_tz', # name of cookie where to store selected timezone
 512                         'datetime',  # CSS class used to mark up dates for manipulation
 513                 ]},
 514
 515         # Syntax highlighting support. This is based on Daniel Svensson's
 516         # and Sham Chukoury's work in gitweb-xmms2.git.
 517         # It requires the 'highlight' program present in $PATH,
 518         # and therefore is disabled by default.
 519
 520         # To enable system wide have in $GITWEB_CONFIG
 521         # $feature{'highlight'}{'default'} = [1];
 522
 523         'highlight' => {
 524                 'sub' => sub { feature_bool('highlight', @_) },
 525                 'override' => 0,
 526                 'default' => [0]},
 527
 528         # Enable displaying of remote heads in the heads list
 529
 530         # To enable system wide have in $GITWEB_CONFIG
 531         # $feature{'remote_heads'}{'default'} = [1];
 532         # To have project specific config enable override in $GITWEB_CONFIG
 533         # $feature{'remote_heads'}{'override'} = 1;
 534         # and in project config gitweb.remote_heads = 0|1;
 535         'remote_heads' => {
 536                 'sub' => sub { feature_bool('remote_heads', @_) },
 537                 'override' => 0,
 538                 'default' => [0]},
 539 );
 540
 541 sub gitweb_get_feature {
 542         my ($name) = @_;
 543         return unless exists $feature{$name};
 544         my ($sub, $override, @defaults) = (
 545                 $feature{$name}{'sub'},
 546                 $feature{$name}{'override'},
 547                 @{$feature{$name}{'default'}});
 548         # project specific override is possible only if we have project
 549         our $git_dir; # global variable, declared later
 550         if (!$override || !defined $git_dir) {
 551                 return @defaults;
 552         }
 553         if (!defined $sub) {
 554                 warn "feature $name is not overridable";
 555                 return @defaults;
 556         }
 557         return $sub->(@defaults);
 558 }
 559
 560 # A wrapper to check if a given feature is enabled.
 561 # With this, you can say
 562 #
 563 #   my $bool_feat = gitweb_check_feature('bool_feat');
 564 #   gitweb_check_feature('bool_feat') or somecode;
 565 #
 566 # instead of
 567 #
 568 #   my ($bool_feat) = gitweb_get_feature('bool_feat');
 569 #   (gitweb_get_feature('bool_feat'))[0] or somecode;
 570 #
 571 sub gitweb_check_feature {
 572         return (gitweb_get_feature(@_))[0];
 573 }
 574
 575
 576 sub feature_bool {
 577         my $key = shift;
 578         my ($val) = git_get_project_config($key, '--bool');
 579
 580         if (!defined $val) {
 581                 return ($_[0]);
 582         } elsif ($val eq 'true') {
 583                 return (1);
 584         } elsif ($val eq 'false') {
 585                 return (0);
 586         }
 587 }
 588
 589 sub feature_snapshot {
 590         my (@fmts) = @_;
 591
 592         my ($val) = git_get_project_config('snapshot');
 593
 594         if ($val) {
 595                 @fmts = ($val eq 'none' ? () : split /\s*[,\s]\s*/, $val);
 596         }
 597
 598         return @fmts;
 599 }
 600
 601 sub feature_patches {
 602         my @val = (git_get_project_config('patches', '--int'));
 603
 604         if (@val) {
 605                 return @val;
 606         }
 607
 608         return ($_[0]);
 609 }
 610
 611 sub feature_avatar {
 612         my @val = (git_get_project_config('avatar'));
 613
 614         return @val ? @val : @_;
 615 }
 616
 617 # checking HEAD file with -e is fragile if the repository was
 618 # initialized long time ago (i.e. symlink HEAD) and was pack-ref'ed
 619 # and then pruned.
 620 sub check_head_link {
 621         my ($dir) = @_;
 622         my $headfile = "$dir/HEAD";
 623         return ((-e $headfile) ||
 624                 (-l $headfile && readlink($headfile) =~ /^refs\/heads\//));
 625 }
 626
 627 sub check_export_ok {
 628         my ($dir) = @_;
 629         return (check_head_link($dir) &&
 630                 (!$export_ok || -e "$dir/$export_ok") &&
 631                 (!$export_auth_hook || $export_auth_hook->($dir)));
 632 }
 633
 634 # process alternate names for backward compatibility
 635 # filter out unsupported (unknown) snapshot formats
 636 sub filter_snapshot_fmts {
 637         my @fmts = @_;
 638
 639         @fmts = map {
 640                 exists $known_snapshot_format_aliases{$_} ?
 641                        $known_snapshot_format_aliases{$_} : $_} @fmts;
 642         @fmts = grep {
 643                 exists $known_snapshot_formats{$_} &&
 644                 !$known_snapshot_formats{$_}{'disabled'}} @fmts;
 645 }
 646
 647 # If it is set to code reference, it is code that it is to be run once per
 648 # request, allowing updating configurations that change with each request,
 649 # while running other code in config file only once.
 650 #
 651 # Otherwise, if it is false then gitweb would process config file only once;
 652 # if it is true then gitweb config would be run for each request.
 653 our $per_request_config = 1;
 654
 655 # read and parse gitweb config file given by its parameter.
 656 # returns true on success, false on recoverable error, allowing
 657 # to chain this subroutine, using first file that exists.
 658 # dies on errors during parsing config file, as it is unrecoverable.
 659 sub read_config_file {
 660         my $filename = shift;
 661         return unless defined $filename;
 662         # die if there are errors parsing config file
 663         if (-e $filename) {
 664                 do $filename;
 665                 die $@ if $@;
 666                 return 1;
 667         }
 668         return;
 669 }
 670
 671 our ($GITWEB_CONFIG, $GITWEB_CONFIG_SYSTEM, $GITWEB_CONFIG_COMMON);
 672 sub evaluate_gitweb_config {
 673         our $GITWEB_CONFIG = $ENV{'GITWEB_CONFIG'} || "++GITWEB_CONFIG++";
 674         our $GITWEB_CONFIG_SYSTEM = $ENV{'GITWEB_CONFIG_SYSTEM'} || "++GITWEB_CONFIG_SYSTEM++";
 675         our $GITWEB_CONFIG_COMMON = $ENV{'GITWEB_CONFIG_COMMON'} || "++GITWEB_CONFIG_COMMON++";
 676
 677         # Protect agains duplications of file names, to not read config twice.
 678         # Only one of $GITWEB_CONFIG and $GITWEB_CONFIG_SYSTEM is used, so
 679         # there possibility of duplication of filename there doesn't matter.
 680         $GITWEB_CONFIG = ""        if ($GITWEB_CONFIG eq $GITWEB_CONFIG_COMMON);
 681         $GITWEB_CONFIG_SYSTEM = "" if ($GITWEB_CONFIG_SYSTEM eq $GITWEB_CONFIG_COMMON);
 682
 683         # Common system-wide settings for convenience.
 684         # Those settings can be ovverriden by GITWEB_CONFIG or GITWEB_CONFIG_SYSTEM.
 685         read_config_file($GITWEB_CONFIG_COMMON);
 686
 687         # Use first config file that exists.  This means use the per-instance
 688         # GITWEB_CONFIG if exists, otherwise use GITWEB_SYSTEM_CONFIG.
 689         read_config_file($GITWEB_CONFIG) and return;
 690         read_config_file($GITWEB_CONFIG_SYSTEM);
 691 }
 692
 693 # Get loadavg of system, to compare against $maxload.
 694 # Currently it requires '/proc/loadavg' present to get loadavg;
 695 # if it is not present it returns 0, which means no load checking.
 696 sub get_loadavg {
 697         if( -e '/proc/loadavg' ){
 698                 open my $fd, '<', '/proc/loadavg'
 699                         or return 0;
 700                 my @load = split(/\s+/, scalar <$fd>);
 701                 close $fd;
 702
 703                 # The first three columns measure CPU and IO utilization of the last one,
 704                 # five, and 10 minute periods.  The fourth column shows the number of
 705                 # currently running processes and the total number of processes in the m/n
 706                 # format.  The last column displays the last process ID used.
 707                 return $load[0] || 0;
 708         }
 709         # additional checks for load average should go here for things that don't export
 710         # /proc/loadavg
 711
 712         return 0;
 713 }
 714
 715 # version of the core git binary
 716 our $git_version;
 717 sub evaluate_git_version {
 718         our $git_version = qx("$GIT" --version) =~ m/git version (.*)$/ ? $1 : "unknown";
 719         $number_of_git_cmds++;
 720 }
 721
 722 sub check_loadavg {
 723         if (defined $maxload && get_loadavg() > $maxload) {
 724                 die_error(503, "The load average on the server is too high");
 725         }
 726 }
 727
 728 # ======================================================================
 729 # input validation and dispatch
 730
 731 # input parameters can be collected from a variety of sources (presently, CGI
 732 # and PATH_INFO), so we define an %input_params hash that collects them all
 733 # together during validation: this allows subsequent uses (e.g. href()) to be
 734 # agnostic of the parameter origin
 735
 736 our %input_params = ();
 737
 738 # input parameters are stored with the long parameter name as key. This will
 739 # also be used in the href subroutine to convert parameters to their CGI
 740 # equivalent, and since the href() usage is the most frequent one, we store
 741 # the name -> CGI key mapping here, instead of the reverse.
 742 #
 743 # XXX: Warning: If you touch this, check the search form for updating,
 744 # too.
 745
 746 our @cgi_param_mapping = (
 747         project => "p",
 748         action => "a",
 749         file_name => "f",
 750         file_parent => "fp",
 751         hash => "h",
 752         hash_parent => "hp",
 753         hash_base => "hb",
 754         hash_parent_base => "hpb",
 755         page => "pg",
 756         order => "o",
 757         searchtext => "s",
 758         searchtype => "st",
 759         snapshot_format => "sf",
 760         extra_options => "opt",
 761         search_use_regexp => "sr",
 762         ctag => "by_tag",
 763         diff_style => "ds",
 764         project_filter => "pf",
 765         # this must be last entry (for manipulation from JavaScript)
 766         javascript => "js"
 767 );
 768 our %cgi_param_mapping = @cgi_param_mapping;
 769
 770 # we will also need to know the possible actions, for validation
 771 our %actions = (
 772         "blame" => \&git_blame,
 773         "blame_incremental" => \&git_blame_incremental,
 774         "blame_data" => \&git_blame_data,
 775         "blobdiff" => \&git_blobdiff,
 776         "blobdiff_plain" => \&git_blobdiff_plain,
 777         "blob" => \&git_blob,
 778         "blob_plain" => \&git_blob_plain,
 779         "commitdiff" => \&git_commitdiff,
 780         "commitdiff_plain" => \&git_commitdiff_plain,
 781         "commit" => \&git_commit,
 782         "forks" => \&git_forks,
 783         "heads" => \&git_heads,
 784         "history" => \&git_history,
 785         "log" => \&git_log,
 786         "patch" => \&git_patch,
 787         "patches" => \&git_patches,
 788         "remotes" => \&git_remotes,
 789         "rss" => \&git_rss,
 790         "atom" => \&git_atom,
 791         "search" => \&git_search,
 792         "search_help" => \&git_search_help,
 793         "shortlog" => \&git_shortlog,
 794         "summary" => \&git_summary,
 795         "tag" => \&git_tag,
 796         "tags" => \&git_tags,
 797         "tree" => \&git_tree,
 798         "snapshot" => \&git_snapshot,
 799         "object" => \&git_object,
 800         # those below don't need $project
 801         "opml" => \&git_opml,
 802         "project_list" => \&git_project_list,
 803         "project_index" => \&git_project_index,
 804 );
 805
 806 # finally, we have the hash of allowed extra_options for the commands that
 807 # allow them
 808 our %allowed_options = (
 809         "--no-merges" => [ qw(rss atom log shortlog history) ],
 810 );
 811
 812 # fill %input_params with the CGI parameters. All values except for 'opt'
 813 # should be single values, but opt can be an array. We should probably
 814 # build an array of parameters that can be multi-valued, but since for the time
 815 # being it's only this one, we just single it out
 816 sub evaluate_query_params {
 817         our $cgi;
 818
 819         while (my ($name, $symbol) = each %cgi_param_mapping) {
 820                 if ($symbol eq 'opt') {
 821                         $input_params{$name} = [ map { decode_utf8($_) } $cgi->param($symbol) ];
 822                 } else {
 823                         $input_params{$name} = decode_utf8($cgi->param($symbol));
 824                 }
 825         }
 826 }
 827
 828 # now read PATH_INFO and update the parameter list for missing parameters
 829 sub evaluate_path_info {
 830         return if defined $input_params{'project'};
 831         return if !$path_info;
 832         $path_info =~ s,^/+,,;
 833         return if !$path_info;
 834
 835         # find which part of PATH_INFO is project
 836         my $project = $path_info;
 837         $project =~ s,/+$,,;
 838         while ($project && !check_head_link("$projectroot/$project")) {
 839                 $project =~ s,/*[^/]*$,,;
 840         }
 841         return unless $project;
 842         $input_params{'project'} = $project;
 843
 844         # do not change any parameters if an action is given using the query string
 845         return if $input_params{'action'};
 846         $path_info =~ s,^\Q$project\E/*,,;
 847
 848         # next, check if we have an action
 849         my $action = $path_info;
 850         $action =~ s,/.*$,,;
 851         if (exists $actions{$action}) {
 852                 $path_info =~ s,^$action/*,,;
 853                 $input_params{'action'} = $action;
 854         }
 855
 856         # list of actions that want hash_base instead of hash, but can have no
 857         # pathname (f) parameter
 858         my @wants_base = (
 859                 'tree',
 860                 'history',
 861         );
 862
 863         # we want to catch, among others
 864         # [$hash_parent_base[:$file_parent]..]$hash_parent[:$file_name]
 865         my ($parentrefname, $parentpathname, $refname, $pathname) =
 866                 ($path_info =~ /^(?:(.+?)(?::(.+))?\.\.)?([^:]+?)?(?::(.+))?$/);
 867
 868         # first, analyze the 'current' part
 869         if (defined $pathname) {
 870                 # we got "branch:filename" or "branch:dir/"
 871                 # we could use git_get_type(branch:pathname), but:
 872                 # - it needs $git_dir
 873                 # - it does a git() call
 874                 # - the convention of terminating directories with a slash
 875                 #   makes it superfluous
 876                 # - embedding the action in the PATH_INFO would make it even
 877                 #   more superfluous
 878                 $pathname =~ s,^/+,,;
 879                 if (!$pathname || substr($pathname, -1) eq "/") {
 880                         $input_params{'action'} ||= "tree";
 881                         $pathname =~ s,/$,,;
 882                 } else {
 883                         # the default action depends on whether we had parent info
 884                         # or not
 885                         if ($parentrefname) {
 886                                 $input_params{'action'} ||= "blobdiff_plain";
 887                         } else {
 888                                 $input_params{'action'} ||= "blob_plain";
 889                         }
 890                 }
 891                 $input_params{'hash_base'} ||= $refname;
 892                 $input_params{'file_name'} ||= $pathname;
 893         } elsif (defined $refname) {
 894                 # we got "branch". In this case we have to choose if we have to
 895                 # set hash or hash_base.
 896                 #
 897                 # Most of the actions without a pathname only want hash to be
 898                 # set, except for the ones specified in @wants_base that want
 899                 # hash_base instead. It should also be noted that hand-crafted
 900                 # links having 'history' as an action and no pathname or hash
 901                 # set will fail, but that happens regardless of PATH_INFO.
 902                 if (defined $parentrefname) {
 903                         # if there is parent let the default be 'shortlog' action
 904                         # (for http://git.example.com/repo.git/A..B links); if there
 905                         # is no parent, dispatch will detect type of object and set
 906                         # action appropriately if required (if action is not set)
 907                         $input_params{'action'} ||= "shortlog";
 908                 }
 909                 if ($input_params{'action'} &&
 910                     grep { $_ eq $input_params{'action'} } @wants_base) {
 911                         $input_params{'hash_base'} ||= $refname;
 912                 } else {
 913                         $input_params{'hash'} ||= $refname;
 914                 }
 915         }
 916
 917         # next, handle the 'parent' part, if present
 918         if (defined $parentrefname) {
 919                 # a missing pathspec defaults to the 'current' filename, allowing e.g.
 920                 # someproject/blobdiff/oldrev..newrev:/filename
 921                 if ($parentpathname) {
 922                         $parentpathname =~ s,^/+,,;
 923                         $parentpathname =~ s,/$,,;
 924                         $input_params{'file_parent'} ||= $parentpathname;
 925                 } else {
 926                         $input_params{'file_parent'} ||= $input_params{'file_name'};
 927                 }
 928                 # we assume that hash_parent_base is wanted if a path was specified,
 929                 # or if the action wants hash_base instead of hash
 930                 if (defined $input_params{'file_parent'} ||
 931                         grep { $_ eq $input_params{'action'} } @wants_base) {
 932                         $input_params{'hash_parent_base'} ||= $parentrefname;
 933                 } else {
 934                         $input_params{'hash_parent'} ||= $parentrefname;
 935                 }
 936         }
 937
 938         # for the snapshot action, we allow URLs in the form
 939         # $project/snapshot/$hash.ext
 940         # where .ext determines the snapshot and gets removed from the
 941         # passed $refname to provide the $hash.
 942         #
 943         # To be able to tell that $refname includes the format extension, we
 944         # require the following two conditions to be satisfied:
 945         # - the hash input parameter MUST have been set from the $refname part
 946         #   of the URL (i.e. they must be equal)
 947         # - the snapshot format MUST NOT have been defined already (e.g. from
 948         #   CGI parameter sf)
 949         # It's also useless to try any matching unless $refname has a dot,
 950         # so we check for that too
 951         if (defined $input_params{'action'} &&
 952                 $input_params{'action'} eq 'snapshot' &&
 953                 defined $refname && index($refname, '.') != -1 &&
 954                 $refname eq $input_params{'hash'} &&
 955                 !defined $input_params{'snapshot_format'}) {
 956                 # We loop over the known snapshot formats, checking for
 957                 # extensions. Allowed extensions are both the defined suffix
 958                 # (which includes the initial dot already) and the snapshot
 959                 # format key itself, with a prepended dot
 960                 while (my ($fmt, $opt) = each %known_snapshot_formats) {
 961                         my $hash = $refname;
 962                         unless ($hash =~ s/(\Q$opt->{'suffix'}\E|\Q.$fmt\E)$//) {
 963                                 next;
 964                         }
 965                         my $sfx = $1;
 966                         # a valid suffix was found, so set the snapshot format
 967                         # and reset the hash parameter
 968                         $input_params{'snapshot_format'} = $fmt;
 969                         $input_params{'hash'} = $hash;
 970                         # we also set the format suffix to the one requested
 971                         # in the URL: this way a request for e.g. .tgz returns
 972                         # a .tgz instead of a .tar.gz
 973                         $known_snapshot_formats{$fmt}{'suffix'} = $sfx;
 974                         last;
 975                 }
 976         }
 977 }
 978
 979 our ($action, $project, $file_name, $file_parent, $hash, $hash_parent, $hash_base,
 980      $hash_parent_base, @extra_options, $page, $searchtype, $search_use_regexp,
 981      $searchtext, $search_regexp, $project_filter);
 982 sub evaluate_and_validate_params {
 983         our $action = $input_params{'action'};
 984         if (defined $action) {
 985                 if (!validate_action($action)) {
 986                         die_error(400, "Invalid action parameter");
 987                 }
 988         }
 989
 990         # parameters which are pathnames
 991         our $project = $input_params{'project'};
 992         if (defined $project) {
 993                 if (!validate_project($project)) {
 994                         undef $project;
 995                         die_error(404, "No such project");
 996                 }
 997         }
 998
 999         our $project_filter = $input_params{'project_filter'};
1000         if (defined $project_filter) {
1001                 if (!validate_pathname($project_filter)) {
1002                         die_error(404, "Invalid project_filter parameter");
1003                 }
1004         }
1005
1006         our $file_name = $input_params{'file_name'};
1007         if (defined $file_name) {
1008                 if (!validate_pathname($file_name)) {
1009                         die_error(400, "Invalid file parameter");
1010                 }
1011         }
1012
1013         our $file_parent = $input_params{'file_parent'};
1014         if (defined $file_parent) {
1015                 if (!validate_pathname($file_parent)) {
1016                         die_error(400, "Invalid file parent parameter");
1017                 }
1018         }
1019
1020         # parameters which are refnames
1021         our $hash = $input_params{'hash'};
1022         if (defined $hash) {
1023                 if (!validate_refname($hash)) {
1024                         die_error(400, "Invalid hash parameter");
1025                 }
1026         }
1027
1028         our $hash_parent = $input_params{'hash_parent'};
1029         if (defined $hash_parent) {
1030                 if (!validate_refname($hash_parent)) {
1031                         die_error(400, "Invalid hash parent parameter");
1032                 }
1033         }
1034
1035         our $hash_base = $input_params{'hash_base'};
1036         if (defined $hash_base) {
1037                 if (!validate_refname($hash_base)) {
1038                         die_error(400, "Invalid hash base parameter");
1039                 }
1040         }
1041
1042         our @extra_options = @{$input_params{'extra_options'}};
1043         # @extra_options is always defined, since it can only be (currently) set from
1044         # CGI, and $cgi->param() returns the empty array in array context if the param
1045         # is not set
1046         foreach my $opt (@extra_options) {
1047                 if (not exists $allowed_options{$opt}) {
1048                         die_error(400, "Invalid option parameter");
1049                 }
1050                 if (not grep(/^$action$/, @{$allowed_options{$opt}})) {
1051                         die_error(400, "Invalid option parameter for this action");
1052                 }
1053         }
1054
1055         our $hash_parent_base = $input_params{'hash_parent_base'};
1056         if (defined $hash_parent_base) {
1057                 if (!validate_refname($hash_parent_base)) {
1058                         die_error(400, "Invalid hash parent base parameter");
1059                 }
1060         }
1061
1062         # other parameters
1063         our $page = $input_params{'page'};
1064         if (defined $page) {
1065                 if ($page =~ m/[^0-9]/) {
1066                         die_error(400, "Invalid page parameter");
1067                 }
1068         }
1069
1070         our $searchtype = $input_params{'searchtype'};
1071         if (defined $searchtype) {
1072                 if ($searchtype =~ m/[^a-z]/) {
1073                         die_error(400, "Invalid searchtype parameter");
1074                 }
1075         }
1076
1077         our $search_use_regexp = $input_params{'search_use_regexp'};
1078
1079         our $searchtext = $input_params{'searchtext'};
1080         our $search_regexp;
1081         if (defined $searchtext) {
1082                 if (length($searchtext) < 2) {
1083                         die_error(403, "At least two characters are required for search parameter");
1084                 }
1085                 if ($search_use_regexp) {
1086                         $search_regexp = $searchtext;
1087                         if (!eval { qr/$search_regexp/; 1; }) {
1088                                 (my $error = $@) =~ s/ at \S+ line \d+.*\n?//;
1089                                 die_error(400, "Invalid search regexp '$search_regexp'",
1090                                           esc_html($error));
1091                         }
1092                 } else {
1093                         $search_regexp = quotemeta $searchtext;
1094                 }
1095         }
1096 }
1097
1098 # path to the current git repository
1099 our $git_dir;
1100 sub evaluate_git_dir {
1101         our $git_dir = "$projectroot/$project" if $project;
1102 }
1103
1104 our (@snapshot_fmts, $git_avatar);
1105 sub configure_gitweb_features {
1106         # list of supported snapshot formats
1107         our @snapshot_fmts = gitweb_get_feature('snapshot');
1108         @snapshot_fmts = filter_snapshot_fmts(@snapshot_fmts);
1109
1110         # check that the avatar feature is set to a known provider name,
1111         # and for each provider check if the dependencies are satisfied.
1112         # if the provider name is invalid or the dependencies are not met,
1113         # reset $git_avatar to the empty string.
1114         our ($git_avatar) = gitweb_get_feature('avatar');
1115         if ($git_avatar eq 'gravatar') {
1116                 $git_avatar = '' unless (eval { require Digest::MD5; 1; });
1117         } elsif ($git_avatar eq 'picon') {
1118                 # no dependencies
1119         } else {
1120                 $git_avatar = '';
1121         }
1122 }
1123
1124 # custom error handler: 'die <message>' is Internal Server Error
1125 sub handle_errors_html {
1126         my $msg = shift; # it is already HTML escaped
1127
1128         # to avoid infinite loop where error occurs in die_error,
1129         # change handler to default handler, disabling handle_errors_html
1130         set_message("Error occured when inside die_error:\n$msg");
1131
1132         # you cannot jump out of die_error when called as error handler;
1133         # the subroutine set via CGI::Carp::set_message is called _after_
1134         # HTTP headers are already written, so it cannot write them itself
1135         die_error(undef, undef, $msg, -error_handler => 1, -no_http_header => 1);
1136 }
1137 set_message(\&handle_errors_html);
1138
1139 # dispatch
1140 sub dispatch {
1141         if (!defined $action) {
1142                 if (defined $hash) {
1143                         $action = git_get_type($hash);
1144                         $action or die_error(404, "Object does not exist");
1145                 } elsif (defined $hash_base && defined $file_name) {
1146                         $action = git_get_type("$hash_base:$file_name");
1147                         $action or die_error(404, "File or directory does not exist");
1148                 } elsif (defined $project) {
1149                         $action = 'summary';
1150                 } else {
1151                         $action = 'project_list';
1152                 }
1153         }
1154         if (!defined($actions{$action})) {
1155                 die_error(400, "Unknown action");
1156         }
1157         if ($action !~ m/^(?:opml|project_list|project_index)$/ &&
1158             !$project) {
1159                 die_error(400, "Project needed");
1160         }
1161         $actions{$action}->();
1162 }
1163
1164 sub reset_timer {
1165         our $t0 = [ gettimeofday() ]
1166                 if defined $t0;
1167         our $number_of_git_cmds = 0;
1168 }
1169
1170 our $first_request = 1;
1171 sub run_request {
1172         reset_timer();
1173
1174         evaluate_uri();
1175         if ($first_request) {
1176                 evaluate_gitweb_config();
1177                 evaluate_git_version();
1178         }
1179         if ($per_request_config) {
1180                 if (ref($per_request_config) eq 'CODE') {
1181                         $per_request_config->();
1182                 } elsif (!$first_request) {
1183                         evaluate_gitweb_config();
1184                 }
1185         }
1186         check_loadavg();
1187
1188         # $projectroot and $projects_list might be set in gitweb config file
1189         $projects_list ||= $projectroot;
1190
1191         evaluate_query_params();
1192         evaluate_path_info();
1193         evaluate_and_validate_params();
1194         evaluate_git_dir();
1195
1196         configure_gitweb_features();
1197
1198         dispatch();
1199 }
1200
1201 our $is_last_request = sub { 1 };
1202 our ($pre_dispatch_hook, $post_dispatch_hook, $pre_listen_hook);
1203 our $CGI = 'CGI';
1204 our $cgi;
1205 sub configure_as_fcgi {
1206         require CGI::Fast;
1207         our $CGI = 'CGI::Fast';
1208
1209         my $request_number = 0;
1210         # let each child service 100 requests
1211         our $is_last_request = sub { ++$request_number > 100 };
1212 }
1213 sub evaluate_argv {
1214         my $script_name = $ENV{'SCRIPT_NAME'} || $ENV{'SCRIPT_FILENAME'} || __FILE__;
1215         configure_as_fcgi()
1216                 if $script_name =~ /\.fcgi$/;
1217
1218         return unless (@ARGV);
1219
1220         require Getopt::Long;
1221         Getopt::Long::GetOptions(
1222                 'fastcgi|fcgi|f' => \&configure_as_fcgi,
1223                 'nproc|n=i' => sub {
1224                         my ($arg, $val) = @_;
1225                         return unless eval { require FCGI::ProcManager; 1; };
1226                         my $proc_manager = FCGI::ProcManager->new({
1227                                 n_processes => $val,
1228                         });
1229                         our $pre_listen_hook    = sub { $proc_manager->pm_manage()        };
1230                         our $pre_dispatch_hook  = sub { $proc_manager->pm_pre_dispatch()  };
1231                         our $post_dispatch_hook = sub { $proc_manager->pm_post_dispatch() };
1232                 },
1233         );
1234 }
1235
1236 sub run {
1237         evaluate_argv();
1238
1239         $first_request = 1;
1240         $pre_listen_hook->()
1241                 if $pre_listen_hook;
1242
1243  REQUEST:
1244         while ($cgi = $CGI->new()) {
1245                 $pre_dispatch_hook->()
1246                         if $pre_dispatch_hook;
1247
1248                 run_request();
1249
1250                 $post_dispatch_hook->()
1251                         if $post_dispatch_hook;
1252                 $first_request = 0;
1253
1254                 last REQUEST if ($is_last_request->());
1255         }
1256
1257  DONE_GITWEB:
1258         1;
1259 }
1260
1261 run();
1262
1263 if (defined caller) {
1264         # wrapped in a subroutine processing requests,
1265         # e.g. mod_perl with ModPerl::Registry, or PSGI with Plack::App::WrapCGI
1266         return;
1267 } else {
1268         # pure CGI script, serving single request
1269         exit;
1270 }
1271
1272 ## ======================================================================
1273 ## action links
1274
1275 # possible values of extra options
1276 # -full => 0|1      - use absolute/full URL ($my_uri/$my_url as base)
1277 # -replay => 1      - start from a current view (replay with modifications)
1278 # -path_info => 0|1 - don't use/use path_info URL (if possible)
1279 # -anchor => ANCHOR - add #ANCHOR to end of URL, implies -replay if used alone
1280 sub href {
1281         my %params = @_;
1282         # default is to use -absolute url() i.e. $my_uri
1283         my $href = $params{-full} ? $my_url : $my_uri;
1284
1285         # implicit -replay, must be first of implicit params
1286         $params{-replay} = 1 if (keys %params == 1 && $params{-anchor});
1287
1288         $params{'project'} = $project unless exists $params{'project'};
1289
1290         if ($params{-replay}) {
1291                 while (my ($name, $symbol) = each %cgi_param_mapping) {
1292                         if (!exists $params{$name}) {
1293                                 $params{$name} = $input_params{$name};
1294                         }
1295                 }
1296         }
1297
1298         my $use_pathinfo = gitweb_check_feature('pathinfo');
1299         if (defined $params{'project'} &&
1300             (exists $params{-path_info} ? $params{-path_info} : $use_pathinfo)) {
1301                 # try to put as many parameters as possible in PATH_INFO:
1302                 #   - project name
1303                 #   - action
1304                 #   - hash_parent or hash_parent_base:/file_parent
1305                 #   - hash or hash_base:/filename
1306                 #   - the snapshot_format as an appropriate suffix
1307
1308                 # When the script is the root DirectoryIndex for the domain,
1309                 # $href here would be something like http://gitweb.example.com/
1310                 # Thus, we strip any trailing / from $href, to spare us double
1311                 # slashes in the final URL
1312                 $href =~ s,/$,,;
1313
1314                 # Then add the project name, if present
1315                 $href .= "/".esc_path_info($params{'project'});
1316                 delete $params{'project'};
1317
1318                 # since we destructively absorb parameters, we keep this
1319                 # boolean that remembers if we're handling a snapshot
1320                 my $is_snapshot = $params{'action'} eq 'snapshot';
1321
1322                 # Summary just uses the project path URL, any other action is
1323                 # added to the URL
1324                 if (defined $params{'action'}) {
1325                         $href .= "/".esc_path_info($params{'action'})
1326                                 unless $params{'action'} eq 'summary';
1327                         delete $params{'action'};
1328                 }
1329
1330                 # Next, we put hash_parent_base:/file_parent..hash_base:/file_name,
1331                 # stripping nonexistent or useless pieces
1332                 $href .= "/" if ($params{'hash_base'} || $params{'hash_parent_base'}
1333                         || $params{'hash_parent'} || $params{'hash'});
1334                 if (defined $params{'hash_base'}) {
1335                         if (defined $params{'hash_parent_base'}) {
1336                                 $href .= esc_path_info($params{'hash_parent_base'});
1337                                 # skip the file_parent if it's the same as the file_name
1338                                 if (defined $params{'file_parent'}) {
1339                                         if (defined $params{'file_name'} && $params{'file_parent'} eq $params{'file_name'}) {
1340                                                 delete $params{'file_parent'};
1341                                         } elsif ($params{'file_parent'} !~ /\.\./) {
1342                                                 $href .= ":/".esc_path_info($params{'file_parent'});
1343                                                 delete $params{'file_parent'};
1344                                         }
1345                                 }
1346                                 $href .= "..";
1347                                 delete $params{'hash_parent'};
1348                                 delete $params{'hash_parent_base'};
1349                         } elsif (defined $params{'hash_parent'}) {
1350                                 $href .= esc_path_info($params{'hash_parent'}). "..";
1351                                 delete $params{'hash_parent'};
1352                         }
1353
1354                         $href .= esc_path_info($params{'hash_base'});
1355                         if (defined $params{'file_name'} && $params{'file_name'} !~ /\.\./) {
1356                                 $href .= ":/".esc_path_info($params{'file_name'});
1357                                 delete $params{'file_name'};
1358                         }
1359                         delete $params{'hash'};
1360                         delete $params{'hash_base'};
1361                 } elsif (defined $params{'hash'}) {
1362                         $href .= esc_path_info($params{'hash'});
1363                         delete $params{'hash'};
1364                 }
1365
1366                 # If the action was a snapshot, we can absorb the
1367                 # snapshot_format parameter too
1368                 if ($is_snapshot) {
1369                         my $fmt = $params{'snapshot_format'};
1370                         # snapshot_format should always be defined when href()
1371                         # is called, but just in case some code forgets, we
1372                         # fall back to the default
1373                         $fmt ||= $snapshot_fmts[0];
1374                         $href .= $known_snapshot_formats{$fmt}{'suffix'};
1375                         delete $params{'snapshot_format'};
1376                 }
1377         }
1378
1379         # now encode the parameters explicitly
1380         my @result = ();
1381         for (my $i = 0; $i < @cgi_param_mapping; $i += 2) {
1382                 my ($name, $symbol) = ($cgi_param_mapping[$i], $cgi_param_mapping[$i+1]);
1383                 if (defined $params{$name}) {
1384                         if (ref($params{$name}) eq "ARRAY") {
1385                                 foreach my $par (@{$params{$name}}) {
1386                                         push @result, $symbol . "=" . esc_param($par);
1387                                 }
1388                         } else {
1389                                 push @result, $symbol . "=" . esc_param($params{$name});
1390                         }
1391                 }
1392         }
1393         $href .= "?" . join(';', @result) if scalar @result;
1394
1395         # final transformation: trailing spaces must be escaped (URI-encoded)
1396         $href =~ s/(\s+)$/CGI::escape($1)/e;
1397
1398         if ($params{-anchor}) {
1399                 $href .= "#".esc_param($params{-anchor});
1400         }
1401
1402         return $href;
1403 }
1404
1405
1406 ## ======================================================================
1407 ## validation, quoting/unquoting and escaping
1408
1409 sub validate_action {
1410         my $input = shift || return undef;
1411         return undef unless exists $actions{$input};
1412         return $input;
1413 }
1414
1415 sub validate_project {
1416         my $input = shift || return undef;
1417         if (!validate_pathname($input) ||
1418                 !(-d "$projectroot/$input") ||
1419                 !check_export_ok("$projectroot/$input") ||
1420                 ($strict_export && !project_in_list($input))) {
1421                 return undef;
1422         } else {
1423                 return $input;
1424         }
1425 }
1426
1427 sub validate_pathname {
1428         my $input = shift || return undef;
1429
1430         # no '.' or '..' as elements of path, i.e. no '.' nor '..'
1431         # at the beginning, at the end, and between slashes.
1432         # also this catches doubled slashes
1433         if ($input =~ m!(^|/)(|\.|\.\.)(/|$)!) {
1434                 return undef;
1435         }
1436         # no null characters
1437         if ($input =~ m!\0!) {
1438                 return undef;
1439         }
1440         return $input;
1441 }
1442
1443 sub validate_refname {
1444         my $input = shift || return undef;
1445
1446         # textual hashes are O.K.
1447         if ($input =~ m/^[0-9a-fA-F]{40}$/) {
1448                 return $input;
1449         }
1450         # it must be correct pathname
1451         $input = validate_pathname($input)
1452                 or return undef;
1453         # restrictions on ref name according to git-check-ref-format
1454         if ($input =~ m!(/\.|\.\.|[\000-\040\177 ~^:?*\[]|/$)!) {
1455                 return undef;
1456         }
1457         return $input;
1458 }
1459
1460 # decode sequences of octets in utf8 into Perl's internal form,
1461 # which is utf-8 with utf8 flag set if needed.  gitweb writes out
1462 # in utf-8 thanks to "binmode STDOUT, ':utf8'" at beginning
1463 sub to_utf8 {
1464         my $str = shift;
1465         return undef unless defined $str;
1466
1467         if (utf8::is_utf8($str) || utf8::decode($str)) {
1468                 return $str;
1469         } else {
1470                 return decode($fallback_encoding, $str, Encode::FB_DEFAULT);
1471         }
1472 }
1473
1474 # quote unsafe chars, but keep the slash, even when it's not
1475 # correct, but quoted slashes look too horrible in bookmarks
1476 sub esc_param {
1477         my $str = shift;
1478         return undef unless defined $str;
1479         $str =~ s/([^A-Za-z0-9\-_.~()\/:@ ]+)/CGI::escape($1)/eg;
1480         $str =~ s/ /\+/g;
1481         return $str;
1482 }
1483
1484 # the quoting rules for path_info fragment are slightly different
1485 sub esc_path_info {
1486         my $str = shift;
1487         return undef unless defined $str;
1488
1489         # path_info doesn't treat '+' as space (specially), but '?' must be escaped
1490         $str =~ s/([^A-Za-z0-9\-_.~();\/;:@&= +]+)/CGI::escape($1)/eg;
1491
1492         return $str;
1493 }
1494
1495 # quote unsafe chars in whole URL, so some characters cannot be quoted
1496 sub esc_url {
1497         my $str = shift;
1498         return undef unless defined $str;
1499         $str =~ s/([^A-Za-z0-9\-_.~();\/;?:@&= ]+)/CGI::escape($1)/eg;
1500         $str =~ s/ /\+/g;
1501         return $str;
1502 }
1503
1504 # quote unsafe characters in HTML attributes
1505 sub esc_attr {
1506
1507         # for XHTML conformance escaping '"' to '&quot;' is not enough
1508         return esc_html(@_);
1509 }
1510
1511 # replace invalid utf8 character with SUBSTITUTION sequence
1512 sub esc_html {
1513         my $str = shift;
1514         my %opts = @_;
1515
1516         return undef unless defined $str;
1517
1518         $str = to_utf8($str);
1519         $str = $cgi->escapeHTML($str);
1520         if ($opts{'-nbsp'}) {
1521                 $str =~ s/ /&nbsp;/g;
1522         }
1523         $str =~ s|([[:cntrl:]])|(($1 ne "\t") ? quot_cec($1) : $1)|eg;
1524         return $str;
1525 }
1526
1527 # quote control characters and escape filename to HTML
1528 sub esc_path {
1529         my $str = shift;
1530         my %opts = @_;
1531
1532         return undef unless defined $str;
1533
1534         $str = to_utf8($str);
1535         $str = $cgi->escapeHTML($str);
1536         if ($opts{'-nbsp'}) {
1537                 $str =~ s/ /&nbsp;/g;
1538         }
1539         $str =~ s|([[:cntrl:]])|quot_cec($1)|eg;
1540         return $str;
1541 }
1542
1543 # Sanitize for use in XHTML + application/xml+xhtm (valid XML 1.0)
1544 sub sanitize {
1545         my $str = shift;
1546
1547         return undef unless defined $str;
1548
1549         $str = to_utf8($str);
1550         $str =~ s|([[:cntrl:]])|($1 =~ /[\t\n\r]/ ? $1 : quot_cec($1))|eg;
1551         return $str;
1552 }
1553
1554 # Make control characters "printable", using character escape codes (CEC)
1555 sub quot_cec {
1556         my $cntrl = shift;
1557         my %opts = @_;
1558         my %es = ( # character escape codes, aka escape sequences
1559                 "\t" => '\t',   # tab            (HT)
1560                 "\n" => '\n',   # line feed      (LF)
1561                 "\r" => '\r',   # carrige return (CR)
1562                 "\f" => '\f',   # form feed      (FF)
1563                 "\b" => '\b',   # backspace      (BS)
1564                 "\a" => '\a',   # alarm (bell)   (BEL)
1565                 "\e" => '\e',   # escape         (ESC)
1566                 "\013" => '\v', # vertical tab   (VT)
1567                 "\000" => '\0', # nul character  (NUL)
1568         );
1569         my $chr = ( (exists $es{$cntrl})
1570                     ? $es{$cntrl}
1571                     : sprintf('\%2x', ord($cntrl)) );
1572         if ($opts{-nohtml}) {
1573                 return $chr;
1574         } else {
1575                 return "<span class=\"cntrl\">$chr</span>";
1576         }
1577 }
1578
1579 # Alternatively use unicode control pictures codepoints,
1580 # Unicode "printable representation" (PR)
1581 sub quot_upr {
1582         my $cntrl = shift;
1583         my %opts = @_;
1584
1585         my $chr = sprintf('&#%04d;', 0x2400+ord($cntrl));
1586         if ($opts{-nohtml}) {
1587                 return $chr;
1588         } else {
1589                 return "<span class=\"cntrl\">$chr</span>";
1590         }
1591 }
1592
1593 # git may return quoted and escaped filenames
1594 sub unquote {
1595         my $str = shift;
1596
1597         sub unq {
1598                 my $seq = shift;
1599                 my %es = ( # character escape codes, aka escape sequences
1600                         't' => "\t",   # tab            (HT, TAB)
1601                         'n' => "\n",   # newline        (NL)
1602                         'r' => "\r",   # return         (CR)
1603                         'f' => "\f",   # form feed      (FF)
1604                         'b' => "\b",   # backspace      (BS)
1605                         'a' => "\a",   # alarm (bell)   (BEL)
1606                         'e' => "\e",   # escape         (ESC)
1607                         'v' => "\013", # vertical tab   (VT)
1608                 );
1609
1610                 if ($seq =~ m/^[0-7]{1,3}$/) {
1611                         # octal char sequence
1612                         return chr(oct($seq));
1613                 } elsif (exists $es{$seq}) {
1614                         # C escape sequence, aka character escape code
1615                         return $es{$seq};
1616                 }
1617                 # quoted ordinary character
1618                 return $seq;
1619         }
1620
1621         if ($str =~ m/^"(.*)"$/) {
1622                 # needs unquoting
1623                 $str = $1;
1624                 $str =~ s/\\([^0-7]|[0-7]{1,3})/unq($1)/eg;
1625         }
1626         return $str;
1627 }
1628
1629 # escape tabs (convert tabs to spaces)
1630 sub untabify {
1631         my $line = shift;
1632
1633         while ((my $pos = index($line, "\t")) != -1) {
1634                 if (my $count = (8 - ($pos % 8))) {
1635                         my $spaces = ' ' x $count;
1636                         $line =~ s/\t/$spaces/;
1637                 }
1638         }
1639
1640         return $line;
1641 }
1642
1643 sub project_in_list {
1644         my $project = shift;
1645         my @list = git_get_projects_list();
1646         return @list && scalar(grep { $_->{'path'} eq $project } @list);
1647 }
1648
1649 ## ----------------------------------------------------------------------
1650 ## HTML aware string manipulation
1651
1652 # Try to chop given string on a word boundary between position
1653 # $len and $len+$add_len. If there is no word boundary there,
1654 # chop at $len+$add_len. Do not chop if chopped part plus ellipsis
1655 # (marking chopped part) would be longer than given string.
1656 sub chop_str {
1657         my $str = shift;
1658         my $len = shift;
1659         my $add_len = shift || 10;
1660         my $where = shift || 'right'; # 'left' | 'center' | 'right'
1661
1662         # Make sure perl knows it is utf8 encoded so we don't
1663         # cut in the middle of a utf8 multibyte char.
1664         $str = to_utf8($str);
1665
1666         # allow only $len chars, but don't cut a word if it would fit in $add_len
1667         # if it doesn't fit, cut it if it's still longer than the dots we would add
1668         # remove chopped character entities entirely
1669
1670         # when chopping in the middle, distribute $len into left and right part
1671         # return early if chopping wouldn't make string shorter
1672         if ($where eq 'center') {
1673                 return $str if ($len + 5 >= length($str)); # filler is length 5
1674                 $len = int($len/2);
1675         } else {
1676                 return $str if ($len + 4 >= length($str)); # filler is length 4
1677         }
1678
1679         # regexps: ending and beginning with word part up to $add_len
1680         my $endre = qr/.{$len}\w{0,$add_len}/;
1681         my $begre = qr/\w{0,$add_len}.{$len}/;
1682
1683         if ($where eq 'left') {
1684                 $str =~ m/^(.*?)($begre)$/;
1685                 my ($lead, $body) = ($1, $2);
1686                 if (length($lead) > 4) {
1687                         $lead = " ...";
1688                 }
1689                 return "$lead$body";
1690
1691         } elsif ($where eq 'center') {
1692                 $str =~ m/^($endre)(.*)$/;
1693                 my ($left, $str)  = ($1, $2);
1694                 $str =~ m/^(.*?)($begre)$/;
1695                 my ($mid, $right) = ($1, $2);
1696                 if (length($mid) > 5) {
1697                         $mid = " ... ";
1698                 }
1699                 return "$left$mid$right";
1700
1701         } else {
1702                 $str =~ m/^($endre)(.*)$/;
1703                 my $body = $1;
1704                 my $tail = $2;
1705                 if (length($tail) > 4) {
1706                         $tail = "... ";
1707                 }
1708                 return "$body$tail";
1709         }
1710 }
1711
1712 # takes the same arguments as chop_str, but also wraps a <span> around the
1713 # result with a title attribute if it does get chopped. Additionally, the
1714 # string is HTML-escaped.
1715 sub chop_and_escape_str {
1716         my ($str) = @_;
1717
1718         my $chopped = chop_str(@_);
1719         $str = to_utf8($str);
1720         if ($chopped eq $str) {
1721                 return esc_html($chopped);
1722         } else {
1723                 $str =~ s/[[:cntrl:]]/?/g;
1724                 return $cgi->span({-title=>$str}, esc_html($chopped));
1725         }
1726 }
1727
1728 # Highlight selected fragments of string, using given CSS class,
1729 # and escape HTML.  It is assumed that fragments do not overlap.
1730 # Regions are passed as list of pairs (array references).
1731 #
1732 # Example: esc_html_hl_regions("foobar", "mark", [ 0, 3 ]) returns
1733 # '<span class="mark">foo</span>bar'
1734 sub esc_html_hl_regions {
1735         my ($str, $css_class, @sel) = @_;
1736         my %opts = grep { ref($_) ne 'ARRAY' } @sel;
1737         @sel     = grep { ref($_) eq 'ARRAY' } @sel;
1738         return esc_html($str, %opts) unless @sel;
1739
1740         my $out = '';
1741         my $pos = 0;
1742
1743         for my $s (@sel) {
1744                 my ($begin, $end) = @$s;
1745
1746                 # Don't create empty <span> elements.
1747                 next if $end <= $begin;
1748
1749                 my $escaped = esc_html(substr($str, $begin, $end - $begin),
1750                                        %opts);
1751
1752                 $out .= esc_html(substr($str, $pos, $begin - $pos), %opts)
1753                         if ($begin - $pos > 0);
1754                 $out .= $cgi->span({-class => $css_class}, $escaped);
1755
1756                 $pos = $end;
1757         }
1758         $out .= esc_html(substr($str, $pos), %opts)
1759                 if ($pos < length($str));
1760
1761         return $out;
1762 }
1763
1764 # return positions of beginning and end of each match
1765 sub matchpos_list {
1766         my ($str, $regexp) = @_;
1767         return unless (defined $str && defined $regexp);
1768
1769         my @matches;
1770         while ($str =~ /$regexp/g) {
1771                 push @matches, [$-[0], $+[0]];
1772         }
1773         return @matches;
1774 }
1775
1776 # highlight match (if any), and escape HTML
1777 sub esc_html_match_hl {
1778         my ($str, $regexp) = @_;
1779         return esc_html($str) unless defined $regexp;
1780
1781         my @matches = matchpos_list($str, $regexp);
1782         return esc_html($str) unless @matches;
1783
1784         return esc_html_hl_regions($str, 'match', @matches);
1785 }
1786
1787
1788 # highlight match (if any) of shortened string, and escape HTML
1789 sub esc_html_match_hl_chopped {
1790         my ($str, $chopped, $regexp) = @_;
1791         return esc_html_match_hl($str, $regexp) unless defined $chopped;
1792
1793         my @matches = matchpos_list($str, $regexp);
1794         return esc_html($chopped) unless @matches;
1795
1796         # filter matches so that we mark chopped string
1797         my $tail = "... "; # see chop_str
1798         unless ($chopped =~ s/\Q$tail\E$//) {
1799                 $tail = '';
1800         }
1801         my $chop_len = length($chopped);
1802         my $tail_len = length($tail);
1803         my @filtered;
1804
1805         for my $m (@matches) {
1806                 if ($m->[0] > $chop_len) {
1807                         push @filtered, [ $chop_len, $chop_len + $tail_len ] if ($tail_len > 0);
1808                         last;
1809                 } elsif ($m->[1] > $chop_len) {
1810                         push @filtered, [ $m->[0], $chop_len + $tail_len ];
1811                         last;
1812                 }
1813                 push @filtered, $m;
1814         }
1815
1816         return esc_html_hl_regions($chopped . $tail, 'match', @filtered);
1817 }
1818
1819 ## ----------------------------------------------------------------------
1820 ## functions returning short strings
1821
1822 # CSS class for given age value (in seconds)
1823 sub age_class {
1824         my $age = shift;
1825
1826         if (!defined $age) {
1827                 return "noage";
1828         } elsif ($age < 60*60*2) {
1829                 return "age0";
1830         } elsif ($age < 60*60*24*2) {
1831                 return "age1";
1832         } else {
1833                 return "age2";
1834         }
1835 }
1836
1837 # convert age in seconds to "nn units ago" string
1838 sub age_string {
1839         my $age = shift;
1840         my $age_str;
1841
1842         if ($age > 60*60*24*365*2) {
1843                 $age_str = (int $age/60/60/24/365);
1844                 $age_str .= " years ago";
1845         } elsif ($age > 60*60*24*(365/12)*2) {
1846                 $age_str = int $age/60/60/24/(365/12);
1847                 $age_str .= " months ago";
1848         } elsif ($age > 60*60*24*7*2) {
1849                 $age_str = int $age/60/60/24/7;
1850                 $age_str .= " weeks ago";
1851         } elsif ($age > 60*60*24*2) {
1852                 $age_str = int $age/60/60/24;
1853                 $age_str .= " days ago";
1854         } elsif ($age > 60*60*2) {
1855                 $age_str = int $age/60/60;
1856                 $age_str .= " hours ago";
1857         } elsif ($age > 60*2) {
1858                 $age_str = int $age/60;
1859                 $age_str .= " min ago";
1860         } elsif ($age > 2) {
1861                 $age_str = int $age;
1862                 $age_str .= " sec ago";
1863         } else {
1864                 $age_str .= " right now";
1865         }
1866         return $age_str;
1867 }
1868
1869 use constant {
1870         S_IFINVALID => 0030000,
1871         S_IFGITLINK => 0160000,
1872 };
1873
1874 # submodule/subproject, a commit object reference
1875 sub S_ISGITLINK {
1876         my $mode = shift;
1877
1878         return (($mode & S_IFMT) == S_IFGITLINK)
1879 }
1880
1881 # convert file mode in octal to symbolic file mode string
1882 sub mode_str {
1883         my $mode = oct shift;
1884
1885         if (S_ISGITLINK($mode)) {
1886                 return 'm---------';
1887         } elsif (S_ISDIR($mode & S_IFMT)) {
1888                 return 'drwxr-xr-x';
1889         } elsif (S_ISLNK($mode)) {
1890                 return 'lrwxrwxrwx';
1891         } elsif (S_ISREG($mode)) {
1892                 # git cares only about the executable bit
1893                 if ($mode & S_IXUSR) {
1894                         return '-rwxr-xr-x';
1895                 } else {
1896                         return '-rw-r--r--';
1897                 };
1898         } else {
1899                 return '----------';
1900         }
1901 }
1902
1903 # convert file mode in octal to file type string
1904 sub file_type {
1905         my $mode = shift;
1906
1907         if ($mode !~ m/^[0-7]+$/) {
1908                 return $mode;
1909         } else {
1910                 $mode = oct $mode;
1911         }
1912
1913         if (S_ISGITLINK($mode)) {
1914                 return "submodule";
1915         } elsif (S_ISDIR($mode & S_IFMT)) {
1916                 return "directory";
1917         } elsif (S_ISLNK($mode)) {
1918                 return "symlink";
1919         } elsif (S_ISREG($mode)) {
1920                 return "file";
1921         } else {
1922                 return "unknown";
1923         }
1924 }
1925
1926 # convert file mode in octal to file type description string
1927 sub file_type_long {
1928         my $mode = shift;
1929
1930         if ($mode !~ m/^[0-7]+$/) {
1931                 return $mode;
1932         } else {
1933                 $mode = oct $mode;
1934         }
1935
1936         if (S_ISGITLINK($mode)) {
1937                 return "submodule";
1938         } elsif (S_ISDIR($mode & S_IFMT)) {
1939                 return "directory";
1940         } elsif (S_ISLNK($mode)) {
1941                 return "symlink";
1942         } elsif (S_ISREG($mode)) {
1943                 if ($mode & S_IXUSR) {
1944                         return "executable";
1945                 } else {
1946                         return "file";
1947                 };
1948         } else {
1949                 return "unknown";
1950         }
1951 }
1952
1953
1954 ## ----------------------------------------------------------------------
1955 ## functions returning short HTML fragments, or transforming HTML fragments
1956 ## which don't belong to other sections
1957
1958 # format line of commit message.
1959 sub format_log_line_html {
1960         my $line = shift;
1961
1962         $line = esc_html($line, -nbsp=>1);
1963         $line =~ s{\b([0-9a-fA-F]{8,40})\b}{
1964                 $cgi->a({-href => href(action=>"object", hash=>$1),
1965                                         -class => "text"}, $1);
1966         }eg;
1967
1968         return $line;
1969 }
1970
1971 # format marker of refs pointing to given object
1972
1973 # the destination action is chosen based on object type and current context:
1974 # - for annotated tags, we choose the tag view unless it's the current view
1975 #   already, in which case we go to shortlog view
1976 # - for other refs, we keep the current view if we're in history, shortlog or
1977 #   log view, and select shortlog otherwise
1978 sub format_ref_marker {
1979         my ($refs, $id) = @_;
1980         my $markers = '';
1981
1982         if (defined $refs->{$id}) {
1983                 foreach my $ref (@{$refs->{$id}}) {
1984                         # this code exploits the fact that non-lightweight tags are the
1985                         # only indirect objects, and that they are the only objects for which
1986                         # we want to use tag instead of shortlog as action
1987                         my ($type, $name) = qw();
1988                         my $indirect = ($ref =~ s/\^\{\}$//);
1989                         # e.g. tags/v2.6.11 or heads/next
1990                         if ($ref =~ m!^(.*?)s?/(.*)$!) {
1991                                 $type = $1;
1992                                 $name = $2;
1993                         } else {
1994                                 $type = "ref";
1995                                 $name = $ref;
1996                         }
1997
1998                         my $class = $type;
1999                         $class .= " indirect" if $indirect;
2000
2001                         my $dest_action = "shortlog";
2002
2003                         if ($indirect) {
2004                                 $dest_action = "tag" unless $action eq "tag";
2005                         } elsif ($action =~ /^(history|(short)?log)$/) {
2006                                 $dest_action = $action;
2007                         }
2008
2009                         my $dest = "";
2010                         $dest .= "refs/" unless $ref =~ m!^refs/!;
2011                         $dest .= $ref;
2012
2013                         my $link = $cgi->a({
2014                                 -href => href(
2015                                         action=>$dest_action,
2016                                         hash=>$dest
2017                                 )}, $name);
2018
2019                         $markers .= " <span class=\"".esc_attr($class)."\" title=\"".esc_attr($ref)."\">" .
2020                                 $link . "</span>";
2021                 }
2022         }
2023
2024         if ($markers) {
2025                 return ' <span class="refs">'. $markers . '</span>';
2026         } else {
2027                 return "";
2028         }
2029 }
2030
2031 # format, perhaps shortened and with markers, title line
2032 sub format_subject_html {
2033         my ($long, $short, $href, $extra) = @_;
2034         $extra = '' unless defined($extra);
2035
2036         if (length($short) < length($long)) {
2037                 $long =~ s/[[:cntrl:]]/?/g;
2038                 return $cgi->a({-href => $href, -class => "list subject",
2039                                 -title => to_utf8($long)},
2040                        esc_html($short)) . $extra;
2041         } else {
2042                 return $cgi->a({-href => $href, -class => "list subject"},
2043                        esc_html($long)) . $extra;
2044         }
2045 }
2046
2047 # Rather than recomputing the url for an email multiple times, we cache it
2048 # after the first hit. This gives a visible benefit in views where the avatar
2049 # for the same email is used repeatedly (e.g. shortlog).
2050 # The cache is shared by all avatar engines (currently gravatar only), which
2051 # are free to use it as preferred. Since only one avatar engine is used for any
2052 # given page, there's no risk for cache conflicts.
2053 our %avatar_cache = ();
2054
2055 # Compute the picon url for a given email, by using the picon search service over at
2056 # http://www.cs.indiana.edu/picons/search.html
2057 sub picon_url {
2058         my $email = lc shift;
2059         if (!$avatar_cache{$email}) {
2060                 my ($user, $domain) = split('@', $email);
2061                 $avatar_cache{$email} =
2062                         "http://www.cs.indiana.edu/cgi-pub/kinzler/piconsearch.cgi/" .
2063                         "$domain/$user/" .
2064                         "users+domains+unknown/up/single";
2065         }
2066         return $avatar_cache{$email};
2067 }
2068
2069 # Compute the gravatar url for a given email, if it's not in the cache already.
2070 # Gravatar stores only the part of the URL before the size, since that's the
2071 # one computationally more expensive. This also allows reuse of the cache for
2072 # different sizes (for this particular engine).
2073 sub gravatar_url {
2074         my $email = lc shift;
2075         my $size = shift;
2076         $avatar_cache{$email} ||=
2077                 "http://www.gravatar.com/avatar/" .
2078                         Digest::MD5::md5_hex($email) . "?s=";
2079         return $avatar_cache{$email} . $size;
2080 }
2081
2082 # Insert an avatar for the given $email at the given $size if the feature
2083 # is enabled.
2084 sub git_get_avatar {
2085         my ($email, %opts) = @_;
2086         my $pre_white  = ($opts{-pad_before} ? "&nbsp;" : "");
2087         my $post_white = ($opts{-pad_after}  ? "&nbsp;" : "");
2088         $opts{-size} ||= 'default';
2089         my $size = $avatar_size{$opts{-size}} || $avatar_size{'default'};
2090         my $url = "";
2091         if ($git_avatar eq 'gravatar') {
2092                 $url = gravatar_url($email, $size);
2093         } elsif ($git_avatar eq 'picon') {
2094                 $url = picon_url($email);
2095         }
2096         # Other providers can be added by extending the if chain, defining $url
2097         # as needed. If no variant puts something in $url, we assume avatars
2098         # are completely disabled/unavailable.
2099         if ($url) {
2100                 return $pre_white .
2101                        "<img width=\"$size\" " .
2102                             "class=\"avatar\" " .
2103                             "src=\"".esc_url($url)."\" " .
2104                             "alt=\"\" " .
2105                        "/>" . $post_white;
2106         } else {
2107                 return "";
2108         }
2109 }
2110
2111 sub format_search_author {
2112         my ($author, $searchtype, $displaytext) = @_;
2113         my $have_search = gitweb_check_feature('search');
2114
2115         if ($have_search) {
2116                 my $performed = "";
2117                 if ($searchtype eq 'author') {
2118                         $performed = "authored";
2119                 } elsif ($searchtype eq 'committer') {
2120                         $performed = "committed";
2121                 }
2122
2123                 return $cgi->a({-href => href(action=>"search", hash=>$hash,
2124                                 searchtext=>$author,
2125                                 searchtype=>$searchtype), class=>"list",
2126                                 title=>"Search for commits $performed by $author"},
2127                                 $displaytext);
2128
2129         } else {
2130                 return $displaytext;
2131         }
2132 }
2133
2134 # format the author name of the given commit with the given tag
2135 # the author name is chopped and escaped according to the other
2136 # optional parameters (see chop_str).
2137 sub format_author_html {
2138         my $tag = shift;
2139         my $co = shift;
2140         my $author = chop_and_escape_str($co->{'author_name'}, @_);
2141         return "<$tag class=\"author\">" .
2142                format_search_author($co->{'author_name'}, "author",
2143                        git_get_avatar($co->{'author_email'}, -pad_after => 1) .
2144                        $author) .
2145                "</$tag>";
2146 }
2147
2148 # format git diff header line, i.e. "diff --(git|combined|cc) ..."
2149 sub format_git_diff_header_line {
2150         my $line = shift;
2151         my $diffinfo = shift;
2152         my ($from, $to) = @_;
2153
2154         if ($diffinfo->{'nparents'}) {
2155                 # combined diff
2156                 $line =~ s!^(diff (.*?) )"?.*$!$1!;
2157                 if ($to->{'href'}) {
2158                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2159                                          esc_path($to->{'file'}));
2160                 } else { # file was deleted (no href)
2161                         $line .= esc_path($to->{'file'});
2162                 }
2163         } else {
2164                 # "ordinary" diff
2165                 $line =~ s!^(diff (.*?) )"?a/.*$!$1!;
2166                 if ($from->{'href'}) {
2167                         $line .= $cgi->a({-href => $from->{'href'}, -class => "path"},
2168                                          'a/' . esc_path($from->{'file'}));
2169                 } else { # file was added (no href)
2170                         $line .= 'a/' . esc_path($from->{'file'});
2171                 }
2172                 $line .= ' ';
2173                 if ($to->{'href'}) {
2174                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2175                                          'b/' . esc_path($to->{'file'}));
2176                 } else { # file was deleted
2177                         $line .= 'b/' . esc_path($to->{'file'});
2178                 }
2179         }
2180
2181         return "<div class=\"diff header\">$line</div>\n";
2182 }
2183
2184 # format extended diff header line, before patch itself
2185 sub format_extended_diff_header_line {
2186         my $line = shift;
2187         my $diffinfo = shift;
2188         my ($from, $to) = @_;
2189
2190         # match <path>
2191         if ($line =~ s!^((copy|rename) from ).*$!$1! && $from->{'href'}) {
2192                 $line .= $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2193                                        esc_path($from->{'file'}));
2194         }
2195         if ($line =~ s!^((copy|rename) to ).*$!$1! && $to->{'href'}) {
2196                 $line .= $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2197                                  esc_path($to->{'file'}));
2198         }
2199         # match single <mode>
2200         if ($line =~ m/\s(\d{6})$/) {
2201                 $line .= '<span class="info"> (' .
2202                          file_type_long($1) .
2203                          ')</span>';
2204         }
2205         # match <hash>
2206         if ($line =~ m/^index [0-9a-fA-F]{40},[0-9a-fA-F]{40}/) {
2207                 # can match only for combined diff
2208                 $line = 'index ';
2209                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2210                         if ($from->{'href'}[$i]) {
2211                                 $line .= $cgi->a({-href=>$from->{'href'}[$i],
2212                                                   -class=>"hash"},
2213                                                  substr($diffinfo->{'from_id'}[$i],0,7));
2214                         } else {
2215                                 $line .= '0' x 7;
2216                         }
2217                         # separator
2218                         $line .= ',' if ($i < $diffinfo->{'nparents'} - 1);
2219                 }
2220                 $line .= '..';
2221                 if ($to->{'href'}) {
2222                         $line .= $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2223                                          substr($diffinfo->{'to_id'},0,7));
2224                 } else {
2225                         $line .= '0' x 7;
2226                 }
2227
2228         } elsif ($line =~ m/^index [0-9a-fA-F]{40}..[0-9a-fA-F]{40}/) {
2229                 # can match only for ordinary diff
2230                 my ($from_link, $to_link);
2231                 if ($from->{'href'}) {
2232                         $from_link = $cgi->a({-href=>$from->{'href'}, -class=>"hash"},
2233                                              substr($diffinfo->{'from_id'},0,7));
2234                 } else {
2235                         $from_link = '0' x 7;
2236                 }
2237                 if ($to->{'href'}) {
2238                         $to_link = $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2239                                            substr($diffinfo->{'to_id'},0,7));
2240                 } else {
2241                         $to_link = '0' x 7;
2242                 }
2243                 my ($from_id, $to_id) = ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
2244                 $line =~ s!$from_id\.\.$to_id!$from_link..$to_link!;
2245         }
2246
2247         return $line . "<br/>\n";
2248 }
2249
2250 # format from-file/to-file diff header
2251 sub format_diff_from_to_header {
2252         my ($from_line, $to_line, $diffinfo, $from, $to, @parents) = @_;
2253         my $line;
2254         my $result = '';
2255
2256         $line = $from_line;
2257         #assert($line =~ m/^---/) if DEBUG;
2258         # no extra formatting for "^--- /dev/null"
2259         if (! $diffinfo->{'nparents'}) {
2260                 # ordinary (single parent) diff
2261                 if ($line =~ m!^--- "?a/!) {
2262                         if ($from->{'href'}) {
2263                                 $line = '--- a/' .
2264                                         $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2265                                                 esc_path($from->{'file'}));
2266                         } else {
2267                                 $line = '--- a/' .
2268                                         esc_path($from->{'file'});
2269                         }
2270                 }
2271                 $result .= qq!<div class="diff from_file">$line</div>\n!;
2272
2273         } else {
2274                 # combined diff (merge commit)
2275                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2276                         if ($from->{'href'}[$i]) {
2277                                 $line = '--- ' .
2278                                         $cgi->a({-href=>href(action=>"blobdiff",
2279                                                              hash_parent=>$diffinfo->{'from_id'}[$i],
2280                                                              hash_parent_base=>$parents[$i],
2281                                                              file_parent=>$from->{'file'}[$i],
2282                                                              hash=>$diffinfo->{'to_id'},
2283                                                              hash_base=>$hash,
2284                                                              file_name=>$to->{'file'}),
2285                                                  -class=>"path",
2286                                                  -title=>"diff" . ($i+1)},
2287                                                 $i+1) .
2288                                         '/' .
2289                                         $cgi->a({-href=>$from->{'href'}[$i], -class=>"path"},
2290                                                 esc_path($from->{'file'}[$i]));
2291                         } else {
2292                                 $line = '--- /dev/null';
2293                         }
2294                         $result .= qq!<div class="diff from_file">$line</div>\n!;
2295                 }
2296         }
2297
2298         $line = $to_line;
2299         #assert($line =~ m/^\+\+\+/) if DEBUG;
2300         # no extra formatting for "^+++ /dev/null"
2301         if ($line =~ m!^\+\+\+ "?b/!) {
2302                 if ($to->{'href'}) {
2303                         $line = '+++ b/' .
2304                                 $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2305                                         esc_path($to->{'file'}));
2306                 } else {
2307                         $line = '+++ b/' .
2308                                 esc_path($to->{'file'});
2309                 }
2310         }
2311         $result .= qq!<div class="diff to_file">$line</div>\n!;
2312
2313         return $result;
2314 }
2315
2316 # create note for patch simplified by combined diff
2317 sub format_diff_cc_simplified {
2318         my ($diffinfo, @parents) = @_;
2319         my $result = '';
2320
2321         $result .= "<div class=\"diff header\">" .
2322                    "diff --cc ";
2323         if (!is_deleted($diffinfo)) {
2324                 $result .= $cgi->a({-href => href(action=>"blob",
2325                                                   hash_base=>$hash,
2326                                                   hash=>$diffinfo->{'to_id'},
2327                                                   file_name=>$diffinfo->{'to_file'}),
2328                                     -class => "path"},
2329                                    esc_path($diffinfo->{'to_file'}));
2330         } else {
2331                 $result .= esc_path($diffinfo->{'to_file'});
2332         }
2333         $result .= "</div>\n" . # class="diff header"
2334                    "<div class=\"diff nodifferences\">" .
2335                    "Simple merge" .
2336                    "</div>\n"; # class="diff nodifferences"
2337
2338         return $result;
2339 }
2340
2341 sub diff_line_class {
2342         my ($line, $from, $to) = @_;
2343
2344         # ordinary diff
2345         my $num_sign = 1;
2346         # combined diff
2347         if ($from && $to && ref($from->{'href'}) eq "ARRAY") {
2348                 $num_sign = scalar @{$from->{'href'}};
2349         }
2350
2351         my @diff_line_classifier = (
2352                 { regexp => qr/^\@\@{$num_sign} /, class => "chunk_header"},
2353                 { regexp => qr/^\\/,               class => "incomplete"  },
2354                 { regexp => qr/^ {$num_sign}/,     class => "ctx" },
2355                 # classifier for context must come before classifier add/rem,
2356                 # or we would have to use more complicated regexp, for example
2357                 # qr/(?= {0,$m}\+)[+ ]{$num_sign}/, where $m = $num_sign - 1;
2358                 { regexp => qr/^[+ ]{$num_sign}/,   class => "add" },
2359                 { regexp => qr/^[- ]{$num_sign}/,   class => "rem" },
2360         );
2361         for my $clsfy (@diff_line_classifier) {
2362                 return $clsfy->{'class'}
2363                         if ($line =~ $clsfy->{'regexp'});
2364         }
2365
2366         # fallback
2367         return "";
2368 }
2369
2370 # assumes that $from and $to are defined and correctly filled,
2371 # and that $line holds a line of chunk header for unified diff
2372 sub format_unidiff_chunk_header {
2373         my ($line, $from, $to) = @_;
2374
2375         my ($from_text, $from_start, $from_lines, $to_text, $to_start, $to_lines, $section) =
2376                 $line =~ m/^\@{2} (-(\d+)(?:,(\d+))?) (\+(\d+)(?:,(\d+))?) \@{2}(.*)$/;
2377
2378         $from_lines = 0 unless defined $from_lines;
2379         $to_lines   = 0 unless defined $to_lines;
2380
2381         if ($from->{'href'}) {
2382                 $from_text = $cgi->a({-href=>"$from->{'href'}#l$from_start",
2383                                      -class=>"list"}, $from_text);
2384         }
2385         if ($to->{'href'}) {
2386                 $to_text   = $cgi->a({-href=>"$to->{'href'}#l$to_start",
2387                                      -class=>"list"}, $to_text);
2388         }
2389         $line = "<span class=\"chunk_info\">@@ $from_text $to_text @@</span>" .
2390                 "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2391         return $line;
2392 }
2393
2394 # assumes that $from and $to are defined and correctly filled,
2395 # and that $line holds a line of chunk header for combined diff
2396 sub format_cc_diff_chunk_header {
2397         my ($line, $from, $to) = @_;
2398
2399         my ($prefix, $ranges, $section) = $line =~ m/^(\@+) (.*?) \@+(.*)$/;
2400         my (@from_text, @from_start, @from_nlines, $to_text, $to_start, $to_nlines);
2401
2402         @from_text = split(' ', $ranges);
2403         for (my $i = 0; $i < @from_text; ++$i) {
2404                 ($from_start[$i], $from_nlines[$i]) =
2405                         (split(',', substr($from_text[$i], 1)), 0);
2406         }
2407
2408         $to_text   = pop @from_text;
2409         $to_start  = pop @from_start;
2410         $to_nlines = pop @from_nlines;
2411
2412         $line = "<span class=\"chunk_info\">$prefix ";
2413         for (my $i = 0; $i < @from_text; ++$i) {
2414                 if ($from->{'href'}[$i]) {
2415                         $line .= $cgi->a({-href=>"$from->{'href'}[$i]#l$from_start[$i]",
2416                                           -class=>"list"}, $from_text[$i]);
2417                 } else {
2418                         $line .= $from_text[$i];
2419                 }
2420                 $line .= " ";
2421         }
2422         if ($to->{'href'}) {
2423                 $line .= $cgi->a({-href=>"$to->{'href'}#l$to_start",
2424                                   -class=>"list"}, $to_text);
2425         } else {
2426                 $line .= $to_text;
2427         }
2428         $line .= " $prefix</span>" .
2429                  "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2430         return $line;
2431 }
2432
2433 # process patch (diff) line (not to be used for diff headers),
2434 # returning HTML-formatted (but not wrapped) line
2435 sub format_diff_line {
2436         my ($line, $diff_class, $from, $to) = @_;
2437
2438         chomp $line;
2439         $line = untabify($line);
2440
2441         if ($from && $to && $line =~ m/^\@{2} /) {
2442                 $line = format_unidiff_chunk_header($line, $from, $to);
2443         } elsif ($from && $to && $line =~ m/^\@{3}/) {
2444                 $line = format_cc_diff_chunk_header($line, $from, $to);
2445         } else {
2446                 $line = esc_html($line, -nbsp=>1);
2447         }
2448
2449         my $diff_classes = "diff";
2450         $diff_classes .= " $diff_class" if ($diff_class);
2451         $line = "<div class=\"$diff_classes\">$line</div>\n";
2452
2453         return $line;
2454 }
2455
2456 # Generates undef or something like "_snapshot_" or "snapshot (_tbz2_ _zip_)",
2457 # linked.  Pass the hash of the tree/commit to snapshot.
2458 sub format_snapshot_links {
2459         my ($hash) = @_;
2460         my $num_fmts = @snapshot_fmts;
2461         if ($num_fmts > 1) {
2462                 # A parenthesized list of links bearing format names.
2463                 # e.g. "snapshot (_tar.gz_ _zip_)"
2464                 return "snapshot (" . join(' ', map
2465                         $cgi->a({
2466                                 -href => href(
2467                                         action=>"snapshot",
2468                                         hash=>$hash,
2469                                         snapshot_format=>$_
2470                                 )
2471                         }, $known_snapshot_formats{$_}{'display'})
2472                 , @snapshot_fmts) . ")";
2473         } elsif ($num_fmts == 1) {
2474                 # A single "snapshot" link whose tooltip bears the format name.
2475                 # i.e. "_snapshot_"
2476                 my ($fmt) = @snapshot_fmts;
2477                 return
2478                         $cgi->a({
2479                                 -href => href(
2480                                         action=>"snapshot",
2481                                         hash=>$hash,
2482                                         snapshot_format=>$fmt
2483                                 ),
2484                                 -title => "in format: $known_snapshot_formats{$fmt}{'display'}"
2485                         }, "snapshot");
2486         } else { # $num_fmts == 0
2487                 return undef;
2488         }
2489 }
2490
2491 ## ......................................................................
2492 ## functions returning values to be passed, perhaps after some
2493 ## transformation, to other functions; e.g. returning arguments to href()
2494
2495 # returns hash to be passed to href to generate gitweb URL
2496 # in -title key it returns description of link
2497 sub get_feed_info {
2498         my $format = shift || 'Atom';
2499         my %res = (action => lc($format));
2500
2501         # feed links are possible only for project views
2502         return unless (defined $project);
2503         # some views should link to OPML, or to generic project feed,
2504         # or don't have specific feed yet (so they should use generic)
2505         return if (!$action || $action =~ /^(?:tags|heads|forks|tag|search)$/x);
2506
2507         my $branch;
2508         # branches refs uses 'refs/heads/' prefix (fullname) to differentiate
2509         # from tag links; this also makes possible to detect branch links
2510         if ((defined $hash_base && $hash_base =~ m!^refs/heads/(.*)$!) ||
2511             (defined $hash      && $hash      =~ m!^refs/heads/(.*)$!)) {
2512                 $branch = $1;
2513         }
2514         # find log type for feed description (title)
2515         my $type = 'log';
2516         if (defined $file_name) {
2517                 $type  = "history of $file_name";
2518                 $type .= "/" if ($action eq 'tree');
2519                 $type .= " on '$branch'" if (defined $branch);
2520         } else {
2521                 $type = "log of $branch" if (defined $branch);
2522         }
2523
2524         $res{-title} = $type;
2525         $res{'hash'} = (defined $branch ? "refs/heads/$branch" : undef);
2526         $res{'file_name'} = $file_name;
2527
2528         return %res;
2529 }
2530
2531 ## ----------------------------------------------------------------------
2532 ## git utility subroutines, invoking git commands
2533
2534 # returns path to the core git executable and the --git-dir parameter as list
2535 sub git_cmd {
2536         $number_of_git_cmds++;
2537         return $GIT, '--git-dir='.$git_dir;
2538 }
2539
2540 # quote the given arguments for passing them to the shell
2541 # quote_command("command", "arg 1", "arg with ' and ! characters")
2542 # => "'command' 'arg 1' 'arg with '\'' and '\!' characters'"
2543 # Try to avoid using this function wherever possible.
2544 sub quote_command {
2545         return join(' ',
2546                 map { my $a = $_; $a =~ s/(['!])/'\\$1'/g; "'$a'" } @_ );
2547 }
2548
2549 # get HEAD ref of given project as hash
2550 sub git_get_head_hash {
2551         return git_get_full_hash(shift, 'HEAD');
2552 }
2553
2554 sub git_get_full_hash {
2555         return git_get_hash(@_);
2556 }
2557
2558 sub git_get_short_hash {
2559         return git_get_hash(@_, '--short=7');
2560 }
2561
2562 sub git_get_hash {
2563         my ($project, $hash, @options) = @_;
2564         my $o_git_dir = $git_dir;
2565         my $retval = undef;
2566         $git_dir = "$projectroot/$project";
2567         if (open my $fd, '-|', git_cmd(), 'rev-parse',
2568             '--verify', '-q', @options, $hash) {
2569                 $retval = <$fd>;
2570                 chomp $retval if defined $retval;
2571                 close $fd;
2572         }
2573         if (defined $o_git_dir) {
2574                 $git_dir = $o_git_dir;
2575         }
2576         return $retval;
2577 }
2578
2579 # get type of given object
2580 sub git_get_type {
2581         my $hash = shift;
2582
2583         open my $fd, "-|", git_cmd(), "cat-file", '-t', $hash or return;
2584         my $type = <$fd>;
2585         close $fd or return;
2586         chomp $type;
2587         return $type;
2588 }
2589
2590 # repository configuration
2591 our $config_file = '';
2592 our %config;
2593
2594 # store multiple values for single key as anonymous array reference
2595 # single values stored directly in the hash, not as [ <value> ]
2596 sub hash_set_multi {
2597         my ($hash, $key, $value) = @_;
2598
2599         if (!exists $hash->{$key}) {
2600                 $hash->{$key} = $value;
2601         } elsif (!ref $hash->{$key}) {
2602                 $hash->{$key} = [ $hash->{$key}, $value ];
2603         } else {
2604                 push @{$hash->{$key}}, $value;
2605         }
2606 }
2607
2608 # return hash of git project configuration
2609 # optionally limited to some section, e.g. 'gitweb'
2610 sub git_parse_project_config {
2611         my $section_regexp = shift;
2612         my %config;
2613
2614         local $/ = "\0";
2615
2616         open my $fh, "-|", git_cmd(), "config", '-z', '-l',
2617                 or return;
2618
2619         while (my $keyval = <$fh>) {
2620                 chomp $keyval;
2621                 my ($key, $value) = split(/\n/, $keyval, 2);
2622
2623                 hash_set_multi(\%config, $key, $value)
2624                         if (!defined $section_regexp || $key =~ /^(?:$section_regexp)\./o);
2625         }
2626         close $fh;
2627
2628         return %config;
2629 }
2630
2631 # convert config value to boolean: 'true' or 'false'
2632 # no value, number > 0, 'true' and 'yes' values are true
2633 # rest of values are treated as false (never as error)
2634 sub config_to_bool {
2635         my $val = shift;
2636
2637         return 1 if !defined $val;             # section.key
2638
2639         # strip leading and trailing whitespace
2640         $val =~ s/^\s+//;
2641         $val =~ s/\s+$//;
2642
2643         return (($val =~ /^\d+$/ && $val) ||   # section.key = 1
2644                 ($val =~ /^(?:true|yes)$/i));  # section.key = true
2645 }
2646
2647 # convert config value to simple decimal number
2648 # an optional value suffix of 'k', 'm', or 'g' will cause the value
2649 # to be multiplied by 1024, 1048576, or 1073741824
2650 sub config_to_int {
2651         my $val = shift;
2652
2653         # strip leading and trailing whitespace
2654         $val =~ s/^\s+//;
2655         $val =~ s/\s+$//;
2656
2657         if (my ($num, $unit) = ($val =~ /^([0-9]*)([kmg])$/i)) {
2658                 $unit = lc($unit);
2659                 # unknown unit is treated as 1
2660                 return $num * ($unit eq 'g' ? 1073741824 :
2661                                $unit eq 'm' ?    1048576 :
2662                                $unit eq 'k' ?       1024 : 1);
2663         }
2664         return $val;
2665 }
2666
2667 # convert config value to array reference, if needed
2668 sub config_to_multi {
2669         my $val = shift;
2670
2671         return ref($val) ? $val : (defined($val) ? [ $val ] : []);
2672 }
2673
2674 sub git_get_project_config {
2675         my ($key, $type) = @_;
2676
2677         return unless defined $git_dir;
2678
2679         # key sanity check
2680         return unless ($key);
2681         # only subsection, if exists, is case sensitive,
2682         # and not lowercased by 'git config -z -l'
2683         if (my ($hi, $mi, $lo) = ($key =~ /^([^.]*)\.(.*)\.([^.]*)$/)) {
2684                 $key = join(".", lc($hi), $mi, lc($lo));
2685         } else {
2686                 $key = lc($key);
2687         }
2688         $key =~ s/^gitweb\.//;
2689         return if ($key =~ m/\W/);
2690
2691         # type sanity check
2692         if (defined $type) {
2693                 $type =~ s/^--//;
2694                 $type = undef
2695                         unless ($type eq 'bool' || $type eq 'int');
2696         }
2697
2698         # get config
2699         if (!defined $config_file ||
2700             $config_file ne "$git_dir/config") {
2701                 %config = git_parse_project_config('gitweb');
2702                 $config_file = "$git_dir/config";
2703         }
2704
2705         # check if config variable (key) exists
2706         return unless exists $config{"gitweb.$key"};
2707
2708         # ensure given type
2709         if (!defined $type) {
2710                 return $config{"gitweb.$key"};
2711         } elsif ($type eq 'bool') {
2712                 # backward compatibility: 'git config --bool' returns true/false
2713                 return config_to_bool($config{"gitweb.$key"}) ? 'true' : 'false';
2714         } elsif ($type eq 'int') {
2715                 return config_to_int($config{"gitweb.$key"});
2716         }
2717         return $config{"gitweb.$key"};
2718 }
2719
2720 # get hash of given path at given ref
2721 sub git_get_hash_by_path {
2722         my $base = shift;
2723         my $path = shift || return undef;
2724         my $type = shift;
2725
2726         $path =~ s,/+$,,;
2727
2728         open my $fd, "-|", git_cmd(), "ls-tree", $base, "--", $path
2729                 or die_error(500, "Open git-ls-tree failed");
2730         my $line = <$fd>;
2731         close $fd or return undef;
2732
2733         if (!defined $line) {
2734                 # there is no tree or hash given by $path at $base
2735                 return undef;
2736         }
2737
2738         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
2739         $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/;
2740         if (defined $type && $type ne $2) {
2741                 # type doesn't match
2742                 return undef;
2743         }
2744         return $3;
2745 }
2746
2747 # get path of entry with given hash at given tree-ish (ref)
2748 # used to get 'from' filename for combined diff (merge commit) for renames
2749 sub git_get_path_by_hash {
2750         my $base = shift || return;
2751         my $hash = shift || return;
2752
2753         local $/ = "\0";
2754
2755         open my $fd, "-|", git_cmd(), "ls-tree", '-r', '-t', '-z', $base
2756                 or return undef;
2757         while (my $line = <$fd>) {
2758                 chomp $line;
2759
2760                 #'040000 tree 595596a6a9117ddba9fe379b6b012b558bac8423  gitweb'
2761                 #'100644 blob e02e90f0429be0d2a69b76571101f20b8f75530f  gitweb/README'
2762                 if ($line =~ m/(?:[0-9]+) (?:.+) $hash\t(.+)$/) {
2763                         close $fd;
2764                         return $1;
2765                 }
2766         }
2767         close $fd;
2768         return undef;
2769 }
2770
2771 ## ......................................................................
2772 ## git utility functions, directly accessing git repository
2773
2774 # get the value of config variable either from file named as the variable
2775 # itself in the repository ($GIT_DIR/$name file), or from gitweb.$name
2776 # configuration variable in the repository config file.
2777 sub git_get_file_or_project_config {
2778         my ($path, $name) = @_;
2779
2780         $git_dir = "$projectroot/$path";
2781         open my $fd, '<', "$git_dir/$name"
2782                 or return git_get_project_config($name);
2783         my $conf = <$fd>;
2784         close $fd;
2785         if (defined $conf) {
2786                 chomp $conf;
2787         }
2788         return $conf;
2789 }
2790
2791 sub git_get_project_description {
2792         my $path = shift;
2793         return git_get_file_or_project_config($path, 'description');
2794 }
2795
2796 sub git_get_project_category {
2797         my $path = shift;
2798         return git_get_file_or_project_config($path, 'category');
2799 }
2800
2801
2802 # supported formats:
2803 # * $GIT_DIR/ctags/<tagname> file (in 'ctags' subdirectory)
2804 #   - if its contents is a number, use it as tag weight,
2805 #   - otherwise add a tag with weight 1
2806 # * $GIT_DIR/ctags file, each line is a tag (with weight 1)
2807 #   the same value multiple times increases tag weight
2808 # * `gitweb.ctag' multi-valued repo config variable
2809 sub git_get_project_ctags {
2810         my $project = shift;
2811         my $ctags = {};
2812
2813         $git_dir = "$projectroot/$project";
2814         if (opendir my $dh, "$git_dir/ctags") {
2815                 my @files = grep { -f $_ } map { "$git_dir/ctags/$_" } readdir($dh);
2816                 foreach my $tagfile (@files) {
2817                         open my $ct, '<', $tagfile
2818                                 or next;
2819                         my $val = <$ct>;
2820                         chomp $val if $val;
2821                         close $ct;
2822
2823                         (my $ctag = $tagfile) =~ s#.*/##;
2824                         if ($val =~ /^\d+$/) {
2825                                 $ctags->{$ctag} = $val;
2826                         } else {
2827                                 $ctags->{$ctag} = 1;
2828                         }
2829                 }
2830                 closedir $dh;
2831
2832         } elsif (open my $fh, '<', "$git_dir/ctags") {
2833                 while (my $line = <$fh>) {
2834                         chomp $line;
2835                         $ctags->{$line}++ if $line;
2836                 }
2837                 close $fh;
2838
2839         } else {
2840                 my $taglist = config_to_multi(git_get_project_config('ctag'));
2841                 foreach my $tag (@$taglist) {
2842                         $ctags->{$tag}++;
2843                 }
2844         }
2845
2846         return $ctags;
2847 }
2848
2849 # return hash, where keys are content tags ('ctags'),
2850 # and values are sum of weights of given tag in every project
2851 sub git_gather_all_ctags {
2852         my $projects = shift;
2853         my $ctags = {};
2854
2855         foreach my $p (@$projects) {
2856                 foreach my $ct (keys %{$p->{'ctags'}}) {
2857                         $ctags->{$ct} += $p->{'ctags'}->{$ct};
2858                 }
2859         }
2860
2861         return $ctags;
2862 }
2863
2864 sub git_populate_project_tagcloud {
2865         my $ctags = shift;
2866
2867         # First, merge different-cased tags; tags vote on casing
2868         my %ctags_lc;
2869         foreach (keys %$ctags) {
2870                 $ctags_lc{lc $_}->{count} += $ctags->{$_};
2871                 if (not $ctags_lc{lc $_}->{topcount}
2872                     or $ctags_lc{lc $_}->{topcount} < $ctags->{$_}) {
2873                         $ctags_lc{lc $_}->{topcount} = $ctags->{$_};
2874                         $ctags_lc{lc $_}->{topname} = $_;
2875                 }
2876         }
2877
2878         my $cloud;
2879         my $matched = $input_params{'ctag'};
2880         if (eval { require HTML::TagCloud; 1; }) {
2881                 $cloud = HTML::TagCloud->new;
2882                 foreach my $ctag (sort keys %ctags_lc) {
2883                         # Pad the title with spaces so that the cloud looks
2884                         # less crammed.
2885                         my $title = esc_html($ctags_lc{$ctag}->{topname});
2886                         $title =~ s/ /&nbsp;/g;
2887                         $title =~ s/^/&nbsp;/g;
2888                         $title =~ s/$/&nbsp;/g;
2889                         if (defined $matched && $matched eq $ctag) {
2890                                 $title = qq(<span class="match">$title</span>);
2891                         }
2892                         $cloud->add($title, href(project=>undef, ctag=>$ctag),
2893                                     $ctags_lc{$ctag}->{count});
2894                 }
2895         } else {
2896                 $cloud = {};
2897                 foreach my $ctag (keys %ctags_lc) {
2898                         my $title = esc_html($ctags_lc{$ctag}->{topname}, -nbsp=>1);
2899                         if (defined $matched && $matched eq $ctag) {
2900                                 $title = qq(<span class="match">$title</span>);
2901                         }
2902                         $cloud->{$ctag}{count} = $ctags_lc{$ctag}->{count};
2903                         $cloud->{$ctag}{ctag} =
2904                                 $cgi->a({-href=>href(project=>undef, ctag=>$ctag)}, $title);
2905                 }
2906         }
2907         return $cloud;
2908 }
2909
2910 sub git_show_project_tagcloud {
2911         my ($cloud, $count) = @_;
2912         if (ref $cloud eq 'HTML::TagCloud') {
2913                 return $cloud->html_and_css($count);
2914         } else {
2915                 my @tags = sort { $cloud->{$a}->{'count'} <=> $cloud->{$b}->{'count'} } keys %$cloud;
2916                 return
2917                         '<div id="htmltagcloud"'.($project ? '' : ' align="center"').'>' .
2918                         join (', ', map {
2919                                 $cloud->{$_}->{'ctag'}
2920                         } splice(@tags, 0, $count)) .
2921                         '</div>';
2922         }
2923 }
2924
2925 sub git_get_project_url_list {
2926         my $path = shift;
2927
2928         $git_dir = "$projectroot/$path";
2929         open my $fd, '<', "$git_dir/cloneurl"
2930                 or return wantarray ?
2931                 @{ config_to_multi(git_get_project_config('url')) } :
2932                    config_to_multi(git_get_project_config('url'));
2933         my @git_project_url_list = map { chomp; $_ } <$fd>;
2934         close $fd;
2935
2936         return wantarray ? @git_project_url_list : \@git_project_url_list;
2937 }
2938
2939 sub git_get_projects_list {
2940         my $filter = shift || '';
2941         my $paranoid = shift;
2942         my @list;
2943
2944         if (-d $projects_list) {
2945                 # search in directory
2946                 my $dir = $projects_list;
2947                 # remove the trailing "/"
2948                 $dir =~ s!/+$!!;
2949                 my $pfxlen = length("$dir");
2950                 my $pfxdepth = ($dir =~ tr!/!!);
2951                 # when filtering, search only given subdirectory
2952                 if ($filter && !$paranoid) {
2953                         $dir .= "/$filter";
2954                         $dir =~ s!/+$!!;
2955                 }
2956
2957                 File::Find::find({
2958                         follow_fast => 1, # follow symbolic links
2959                         follow_skip => 2, # ignore duplicates
2960                         dangling_symlinks => 0, # ignore dangling symlinks, silently
2961                         wanted => sub {
2962                                 # global variables
2963                                 our $project_maxdepth;
2964                                 our $projectroot;
2965                                 # skip project-list toplevel, if we get it.
2966                                 return if (m!^[/.]$!);
2967                                 # only directories can be git repositories
2968                                 return unless (-d $_);
2969                                 # don't traverse too deep (Find is super slow on os x)
2970                                 # $project_maxdepth excludes depth of $projectroot
2971                                 if (($File::Find::name =~ tr!/!!) - $pfxdepth > $project_maxdepth) {
2972                                         $File::Find::prune = 1;
2973                                         return;
2974                                 }
2975
2976                                 my $path = substr($File::Find::name, $pfxlen + 1);
2977                                 # paranoidly only filter here
2978                                 if ($paranoid && $filter && $path !~ m!^\Q$filter\E/!) {
2979                                         next;
2980                                 }
2981                                 # we check related file in $projectroot
2982                                 if (check_export_ok("$projectroot/$path")) {
2983                                         push @list, { path => $path };
2984                                         $File::Find::prune = 1;
2985                                 }
2986                         },
2987                 }, "$dir");
2988
2989         } elsif (-f $projects_list) {
2990                 # read from file(url-encoded):
2991                 # 'git%2Fgit.git Linus+Torvalds'
2992                 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
2993                 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
2994                 open my $fd, '<', $projects_list or return;
2995         PROJECT:
2996                 while (my $line = <$fd>) {
2997                         chomp $line;
2998                         my ($path, $owner) = split ' ', $line;
2999                         $path = unescape($path);
3000                         $owner = unescape($owner);
3001                         if (!defined $path) {
3002                                 next;
3003                         }
3004                         # if $filter is rpovided, check if $path begins with $filter
3005                         if ($filter && $path !~ m!^\Q$filter\E/!) {
3006                                 next;
3007                         }
3008                         if (check_export_ok("$projectroot/$path")) {
3009                                 my $pr = {
3010                                         path => $path,
3011                                         owner => to_utf8($owner),
3012                                 };
3013                                 push @list, $pr;
3014                         }
3015                 }
3016                 close $fd;
3017         }
3018         return @list;
3019 }
3020
3021 # written with help of Tree::Trie module (Perl Artistic License, GPL compatibile)
3022 # as side effects it sets 'forks' field to list of forks for forked projects
3023 sub filter_forks_from_projects_list {
3024         my $projects = shift;
3025
3026         my %trie; # prefix tree of directories (path components)
3027         # generate trie out of those directories that might contain forks
3028         foreach my $pr (@$projects) {
3029                 my $path = $pr->{'path'};
3030                 $path =~ s/\.git$//;      # forks of 'repo.git' are in 'repo/' directory
3031                 next if ($path =~ m!/$!); # skip non-bare repositories, e.g. 'repo/.git'
3032                 next unless ($path);      # skip '.git' repository: tests, git-instaweb
3033                 next unless (-d "$projectroot/$path"); # containing directory exists
3034                 $pr->{'forks'} = [];      # there can be 0 or more forks of project
3035
3036                 # add to trie
3037                 my @dirs = split('/', $path);
3038                 # walk the trie, until either runs out of components or out of trie
3039                 my $ref = \%trie;
3040                 while (scalar @dirs &&
3041                        exists($ref->{$dirs[0]})) {
3042                         $ref = $ref->{shift @dirs};
3043                 }
3044                 # create rest of trie structure from rest of components
3045                 foreach my $dir (@dirs) {
3046                         $ref = $ref->{$dir} = {};
3047                 }
3048                 # create end marker, store $pr as a data
3049                 $ref->{''} = $pr if (!exists $ref->{''});
3050         }
3051
3052         # filter out forks, by finding shortest prefix match for paths
3053         my @filtered;
3054  PROJECT:
3055         foreach my $pr (@$projects) {
3056                 # trie lookup
3057                 my $ref = \%trie;
3058         DIR:
3059                 foreach my $dir (split('/', $pr->{'path'})) {
3060                         if (exists $ref->{''}) {
3061                                 # found [shortest] prefix, is a fork - skip it
3062                                 push @{$ref->{''}{'forks'}}, $pr;
3063                                 next PROJECT;
3064                         }
3065                         if (!exists $ref->{$dir}) {
3066                                 # not in trie, cannot have prefix, not a fork
3067                                 push @filtered, $pr;
3068                                 next PROJECT;
3069                         }
3070                         # If the dir is there, we just walk one step down the trie.
3071                         $ref = $ref->{$dir};
3072                 }
3073                 # we ran out of trie
3074                 # (shouldn't happen: it's either no match, or end marker)
3075                 push @filtered, $pr;
3076         }
3077
3078         return @filtered;
3079 }
3080
3081 # note: fill_project_list_info must be run first,
3082 # for 'descr_long' and 'ctags' to be filled
3083 sub search_projects_list {
3084         my ($projlist, %opts) = @_;
3085         my $tagfilter  = $opts{'tagfilter'};
3086         my $search_re = $opts{'search_regexp'};
3087
3088         return @$projlist
3089                 unless ($tagfilter || $search_re);
3090
3091         # searching projects require filling to be run before it;
3092         fill_project_list_info($projlist,
3093                                $tagfilter  ? 'ctags' : (),
3094                                $search_re ? ('path', 'descr') : ());
3095         my @projects;
3096  PROJECT:
3097         foreach my $pr (@$projlist) {
3098
3099                 if ($tagfilter) {
3100                         next unless ref($pr->{'ctags'}) eq 'HASH';
3101                         next unless
3102                                 grep { lc($_) eq lc($tagfilter) } keys %{$pr->{'ctags'}};
3103                 }
3104
3105                 if ($search_re) {
3106                         next unless
3107                                 $pr->{'path'} =~ /$search_re/ ||
3108                                 $pr->{'descr_long'} =~ /$search_re/;
3109                 }
3110
3111                 push @projects, $pr;
3112         }
3113
3114         return @projects;
3115 }
3116
3117 our $gitweb_project_owner = undef;
3118 sub git_get_project_list_from_file {
3119
3120         return if (defined $gitweb_project_owner);
3121
3122         $gitweb_project_owner = {};
3123         # read from file (url-encoded):
3124         # 'git%2Fgit.git Linus+Torvalds'
3125         # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
3126         # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
3127         if (-f $projects_list) {
3128                 open(my $fd, '<', $projects_list);
3129                 while (my $line = <$fd>) {
3130                         chomp $line;
3131                         my ($pr, $ow) = split ' ', $line;
3132                         $pr = unescape($pr);
3133                         $ow = unescape($ow);
3134                         $gitweb_project_owner->{$pr} = to_utf8($ow);
3135                 }
3136                 close $fd;
3137         }
3138 }
3139
3140 sub git_get_project_owner {
3141         my $project = shift;
3142         my $owner;
3143
3144         return undef unless $project;
3145         $git_dir = "$projectroot/$project";
3146
3147         if (!defined $gitweb_project_owner) {
3148                 git_get_project_list_from_file();
3149         }
3150
3151         if (exists $gitweb_project_owner->{$project}) {
3152                 $owner = $gitweb_project_owner->{$project};
3153         }
3154         if (!defined $owner){
3155                 $owner = git_get_project_config('owner');
3156         }
3157         if (!defined $owner) {
3158                 $owner = get_file_owner("$git_dir");
3159         }
3160
3161         return $owner;
3162 }
3163
3164 sub git_get_last_activity {
3165         my ($path) = @_;
3166         my $fd;
3167
3168         $git_dir = "$projectroot/$path";
3169         open($fd, "-|", git_cmd(), 'for-each-ref',
3170              '--format=%(committer)',
3171              '--sort=-committerdate',
3172              '--count=1',
3173              'refs/heads') or return;
3174         my $most_recent = <$fd>;
3175         close $fd or return;
3176         if (defined $most_recent &&
3177             $most_recent =~ / (\d+) [-+][01]\d\d\d$/) {
3178                 my $timestamp = $1;
3179                 my $age = time - $timestamp;
3180                 return ($age, age_string($age));
3181         }
3182         return (undef, undef);
3183 }
3184
3185 # Implementation note: when a single remote is wanted, we cannot use 'git
3186 # remote show -n' because that command always work (assuming it's a remote URL
3187 # if it's not defined), and we cannot use 'git remote show' because that would
3188 # try to make a network roundtrip. So the only way to find if that particular
3189 # remote is defined is to walk the list provided by 'git remote -v' and stop if
3190 # and when we find what we want.
3191 sub git_get_remotes_list {
3192         my $wanted = shift;
3193         my %remotes = ();
3194
3195         open my $fd, '-|' , git_cmd(), 'remote', '-v';
3196         return unless $fd;
3197         while (my $remote = <$fd>) {
3198                 chomp $remote;
3199                 $remote =~ s!\t(.*?)\s+\((\w+)\)$!!;
3200                 next if $wanted and not $remote eq $wanted;
3201                 my ($url, $key) = ($1, $2);
3202
3203                 $remotes{$remote} ||= { 'heads' => () };
3204                 $remotes{$remote}{$key} = $url;
3205         }
3206         close $fd or return;
3207         return wantarray ? %remotes : \%remotes;
3208 }
3209
3210 # Takes a hash of remotes as first parameter and fills it by adding the
3211 # available remote heads for each of the indicated remotes.
3212 sub fill_remote_heads {
3213         my $remotes = shift;
3214         my @heads = map { "remotes/$_" } keys %$remotes;
3215         my @remoteheads = git_get_heads_list(undef, @heads);
3216         foreach my $remote (keys %$remotes) {
3217                 $remotes->{$remote}{'heads'} = [ grep {
3218                         $_->{'name'} =~ s!^$remote/!!
3219                         } @remoteheads ];
3220         }
3221 }
3222
3223 sub git_get_references {
3224         my $type = shift || "";
3225         my %refs;
3226         # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
3227         # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
3228         open my $fd, "-|", git_cmd(), "show-ref", "--dereference",
3229                 ($type ? ("--", "refs/$type") : ()) # use -- <pattern> if $type
3230                 or return;
3231
3232         while (my $line = <$fd>) {
3233                 chomp $line;
3234                 if ($line =~ m!^([0-9a-fA-F]{40})\srefs/($type.*)$!) {
3235                         if (defined $refs{$1}) {
3236                                 push @{$refs{$1}}, $2;
3237                         } else {
3238                                 $refs{$1} = [ $2 ];
3239                         }
3240                 }
3241         }
3242         close $fd or return;
3243         return \%refs;
3244 }
3245
3246 sub git_get_rev_name_tags {
3247         my $hash = shift || return undef;
3248
3249         open my $fd, "-|", git_cmd(), "name-rev", "--tags", $hash
3250                 or return;
3251         my $name_rev = <$fd>;
3252         close $fd;
3253
3254         if ($name_rev =~ m|^$hash tags/(.*)$|) {
3255                 return $1;
3256         } else {
3257                 # catches also '$hash undefined' output
3258                 return undef;
3259         }
3260 }
3261
3262 ## ----------------------------------------------------------------------
3263 ## parse to hash functions
3264
3265 sub parse_date {
3266         my $epoch = shift;
3267         my $tz = shift || "-0000";
3268
3269         my %date;
3270         my @months = ("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec");
3271         my @days = ("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");
3272         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($epoch);
3273         $date{'hour'} = $hour;
3274         $date{'minute'} = $min;
3275         $date{'mday'} = $mday;
3276         $date{'day'} = $days[$wday];
3277         $date{'month'} = $months[$mon];
3278         $date{'rfc2822'}   = sprintf "%s, %d %s %4d %02d:%02d:%02d +0000",
3279                              $days[$wday], $mday, $months[$mon], 1900+$year, $hour ,$min, $sec;
3280         $date{'mday-time'} = sprintf "%d %s %02d:%02d",
3281                              $mday, $months[$mon], $hour ,$min;
3282         $date{'iso-8601'}  = sprintf "%04d-%02d-%02dT%02d:%02d:%02dZ",
3283                              1900+$year, 1+$mon, $mday, $hour ,$min, $sec;
3284
3285         my ($tz_sign, $tz_hour, $tz_min) =
3286                 ($tz =~ m/^([-+])(\d\d)(\d\d)$/);
3287         $tz_sign = ($tz_sign eq '-' ? -1 : +1);
3288         my $local = $epoch + $tz_sign*((($tz_hour*60) + $tz_min)*60);
3289         ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($local);
3290         $date{'hour_local'} = $hour;
3291         $date{'minute_local'} = $min;
3292         $date{'tz_local'} = $tz;
3293         $date{'iso-tz'} = sprintf("%04d-%02d-%02d %02d:%02d:%02d %s",
3294                                   1900+$year, $mon+1, $mday,
3295                                   $hour, $min, $sec, $tz);
3296         return %date;
3297 }
3298
3299 sub parse_tag {
3300         my $tag_id = shift;
3301         my %tag;
3302         my @comment;
3303
3304         open my $fd, "-|", git_cmd(), "cat-file", "tag", $tag_id or return;
3305         $tag{'id'} = $tag_id;
3306         while (my $line = <$fd>) {
3307                 chomp $line;
3308                 if ($line =~ m/^object ([0-9a-fA-F]{40})$/) {
3309                         $tag{'object'} = $1;
3310                 } elsif ($line =~ m/^type (.+)$/) {
3311                         $tag{'type'} = $1;
3312                 } elsif ($line =~ m/^tag (.+)$/) {
3313                         $tag{'name'} = $1;
3314                 } elsif ($line =~ m/^tagger (.*) ([0-9]+) (.*)$/) {
3315                         $tag{'author'} = $1;
3316                         $tag{'author_epoch'} = $2;
3317                         $tag{'author_tz'} = $3;
3318                         if ($tag{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3319                                 $tag{'author_name'}  = $1;
3320                                 $tag{'author_email'} = $2;
3321                         } else {
3322                                 $tag{'author_name'} = $tag{'author'};
3323                         }
3324                 } elsif ($line =~ m/--BEGIN/) {
3325                         push @comment, $line;
3326                         last;
3327                 } elsif ($line eq "") {
3328                         last;
3329                 }
3330         }
3331         push @comment, <$fd>;
3332         $tag{'comment'} = \@comment;
3333         close $fd or return;
3334         if (!defined $tag{'name'}) {
3335                 return
3336         };
3337         return %tag
3338 }
3339
3340 sub parse_commit_text {
3341         my ($commit_text, $withparents) = @_;
3342         my @commit_lines = split '\n', $commit_text;
3343         my %co;
3344
3345         pop @commit_lines; # Remove '\0'
3346
3347         if (! @commit_lines) {
3348                 return;
3349         }
3350
3351         my $header = shift @commit_lines;
3352         if ($header !~ m/^[0-9a-fA-F]{40}/) {
3353                 return;
3354         }
3355         ($co{'id'}, my @parents) = split ' ', $header;
3356         while (my $line = shift @commit_lines) {
3357                 last if $line eq "\n";
3358                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
3359                         $co{'tree'} = $1;
3360                 } elsif ((!defined $withparents) && ($line =~ m/^parent ([0-9a-fA-F]{40})$/)) {
3361                         push @parents, $1;
3362                 } elsif ($line =~ m/^author (.*) ([0-9]+) (.*)$/) {
3363                         $co{'author'} = to_utf8($1);
3364                         $co{'author_epoch'} = $2;
3365                         $co{'author_tz'} = $3;
3366                         if ($co{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3367                                 $co{'author_name'}  = $1;
3368                                 $co{'author_email'} = $2;
3369                         } else {
3370                                 $co{'author_name'} = $co{'author'};
3371                         }
3372                 } elsif ($line =~ m/^committer (.*) ([0-9]+) (.*)$/) {
3373                         $co{'committer'} = to_utf8($1);
3374                         $co{'committer_epoch'} = $2;
3375                         $co{'committer_tz'} = $3;
3376                         if ($co{'committer'} =~ m/^([^<]+) <([^>]*)>/) {
3377                                 $co{'committer_name'}  = $1;
3378                                 $co{'committer_email'} = $2;
3379                         } else {
3380                                 $co{'committer_name'} = $co{'committer'};
3381                         }
3382                 }
3383         }
3384         if (!defined $co{'tree'}) {
3385                 return;
3386         };
3387         $co{'parents'} = \@parents;
3388         $co{'parent'} = $parents[0];
3389
3390         foreach my $title (@commit_lines) {
3391                 $title =~ s/^    //;
3392                 if ($title ne "") {
3393                         $co{'title'} = chop_str($title, 80, 5);
3394                         # remove leading stuff of merges to make the interesting part visible
3395                         if (length($title) > 50) {
3396                                 $title =~ s/^Automatic //;
3397                                 $title =~ s/^merge (of|with) /Merge ... /i;
3398                                 if (length($title) > 50) {
3399                                         $title =~ s/(http|rsync):\/\///;
3400                                 }
3401                                 if (length($title) > 50) {
3402                                         $title =~ s/(master|www|rsync)\.//;
3403                                 }
3404                                 if (length($title) > 50) {
3405                                         $title =~ s/kernel.org:?//;
3406                                 }
3407                                 if (length($title) > 50) {
3408                                         $title =~ s/\/pub\/scm//;
3409                                 }
3410                         }
3411                         $co{'title_short'} = chop_str($title, 50, 5);
3412                         last;
3413                 }
3414         }
3415         if (! defined $co{'title'} || $co{'title'} eq "") {
3416                 $co{'title'} = $co{'title_short'} = '(no commit message)';
3417         }
3418         # remove added spaces
3419         foreach my $line (@commit_lines) {
3420                 $line =~ s/^    //;
3421         }
3422         $co{'comment'} = \@commit_lines;
3423
3424         my $age = time - $co{'committer_epoch'};
3425         $co{'age'} = $age;
3426         $co{'age_string'} = age_string($age);
3427         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($co{'committer_epoch'});
3428         if ($age > 60*60*24*7*2) {
3429                 $co{'age_string_date'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3430                 $co{'age_string_age'} = $co{'age_string'};
3431         } else {
3432                 $co{'age_string_date'} = $co{'age_string'};
3433                 $co{'age_string_age'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3434         }
3435         return %co;
3436 }
3437
3438 sub parse_commit {
3439         my ($commit_id) = @_;
3440         my %co;
3441
3442         local $/ = "\0";
3443
3444         open my $fd, "-|", git_cmd(), "rev-list",
3445                 "--parents",
3446                 "--header",
3447                 "--max-count=1",
3448                 $commit_id,
3449                 "--",
3450                 or die_error(500, "Open git-rev-list failed");
3451         %co = parse_commit_text(<$fd>, 1);
3452         close $fd;
3453
3454         return %co;
3455 }
3456
3457 sub parse_commits {
3458         my ($commit_id, $maxcount, $skip, $filename, @args) = @_;
3459         my @cos;
3460
3461         $maxcount ||= 1;
3462         $skip ||= 0;
3463
3464         local $/ = "\0";
3465
3466         open my $fd, "-|", git_cmd(), "rev-list",
3467                 "--header",
3468                 @args,
3469                 ("--max-count=" . $maxcount),
3470                 ("--skip=" . $skip),
3471                 @extra_options,
3472                 $commit_id,
3473                 "--",
3474                 ($filename ? ($filename) : ())
3475                 or die_error(500, "Open git-rev-list failed");
3476         while (my $line = <$fd>) {
3477                 my %co = parse_commit_text($line);
3478                 push @cos, \%co;
3479         }
3480         close $fd;
3481
3482         return wantarray ? @cos : \@cos;
3483 }
3484
3485 # parse line of git-diff-tree "raw" output
3486 sub parse_difftree_raw_line {
3487         my $line = shift;
3488         my %res;
3489
3490         # ':100644 100644 03b218260e99b78c6df0ed378e59ed9205ccc96d 3b93d5e7cc7f7dd4ebed13a5cc1a4ad976fc94d8 M   ls-files.c'
3491         # ':100644 100644 7f9281985086971d3877aca27704f2aaf9c448ce bc190ebc71bbd923f2b728e505408f5e54bd073a M   rev-tree.c'
3492         if ($line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)([0-9]{0,3})\t(.*)$/) {
3493                 $res{'from_mode'} = $1;
3494                 $res{'to_mode'} = $2;
3495                 $res{'from_id'} = $3;
3496                 $res{'to_id'} = $4;
3497                 $res{'status'} = $5;
3498                 $res{'similarity'} = $6;
3499                 if ($res{'status'} eq 'R' || $res{'status'} eq 'C') { # renamed or copied
3500                         ($res{'from_file'}, $res{'to_file'}) = map { unquote($_) } split("\t", $7);
3501                 } else {
3502                         $res{'from_file'} = $res{'to_file'} = $res{'file'} = unquote($7);
3503                 }
3504         }
3505         # '::100755 100755 100755 60e79ca1b01bc8b057abe17ddab484699a7f5fdb 94067cc5f73388f33722d52ae02f44692bc07490 94067cc5f73388f33722d52ae02f44692bc07490 MR git-gui/git-gui.sh'
3506         # combined diff (for merge commit)
3507         elsif ($line =~ s/^(::+)((?:[0-7]{6} )+)((?:[0-9a-fA-F]{40} )+)([a-zA-Z]+)\t(.*)$//) {
3508                 $res{'nparents'}  = length($1);
3509                 $res{'from_mode'} = [ split(' ', $2) ];
3510                 $res{'to_mode'} = pop @{$res{'from_mode'}};
3511                 $res{'from_id'} = [ split(' ', $3) ];
3512                 $res{'to_id'} = pop @{$res{'from_id'}};
3513                 $res{'status'} = [ split('', $4) ];
3514                 $res{'to_file'} = unquote($5);
3515         }
3516         # 'c512b523472485aef4fff9e57b229d9d243c967f'
3517         elsif ($line =~ m/^([0-9a-fA-F]{40})$/) {
3518                 $res{'commit'} = $1;
3519         }
3520
3521         return wantarray ? %res : \%res;
3522 }
3523
3524 # wrapper: return parsed line of git-diff-tree "raw" output
3525 # (the argument might be raw line, or parsed info)
3526 sub parsed_difftree_line {
3527         my $line_or_ref = shift;
3528
3529         if (ref($line_or_ref) eq "HASH") {
3530                 # pre-parsed (or generated by hand)
3531                 return $line_or_ref;
3532         } else {
3533                 return parse_difftree_raw_line($line_or_ref);
3534         }
3535 }
3536
3537 # parse line of git-ls-tree output
3538 sub parse_ls_tree_line {
3539         my $line = shift;
3540         my %opts = @_;
3541         my %res;
3542
3543         if ($opts{'-l'}) {
3544                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa   16717  panic.c'
3545                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40}) +(-|[0-9]+)\t(.+)$/s;
3546
3547                 $res{'mode'} = $1;
3548                 $res{'type'} = $2;
3549                 $res{'hash'} = $3;
3550                 $res{'size'} = $4;
3551                 if ($opts{'-z'}) {
3552                         $res{'name'} = $5;
3553                 } else {
3554                         $res{'name'} = unquote($5);
3555                 }
3556         } else {
3557                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
3558                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t(.+)$/s;
3559
3560                 $res{'mode'} = $1;
3561                 $res{'type'} = $2;
3562                 $res{'hash'} = $3;
3563                 if ($opts{'-z'}) {
3564                         $res{'name'} = $4;
3565                 } else {
3566                         $res{'name'} = unquote($4);
3567                 }
3568         }
3569
3570         return wantarray ? %res : \%res;
3571 }
3572
3573 # generates _two_ hashes, references to which are passed as 2 and 3 argument
3574 sub parse_from_to_diffinfo {
3575         my ($diffinfo, $from, $to, @parents) = @_;
3576
3577         if ($diffinfo->{'nparents'}) {
3578                 # combined diff
3579                 $from->{'file'} = [];
3580                 $from->{'href'} = [];
3581                 fill_from_file_info($diffinfo, @parents)
3582                         unless exists $diffinfo->{'from_file'};
3583                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
3584                         $from->{'file'}[$i] =
3585                                 defined $diffinfo->{'from_file'}[$i] ?
3586                                         $diffinfo->{'from_file'}[$i] :
3587                                         $diffinfo->{'to_file'};
3588                         if ($diffinfo->{'status'}[$i] ne "A") { # not new (added) file
3589                                 $from->{'href'}[$i] = href(action=>"blob",
3590                                                            hash_base=>$parents[$i],
3591                                                            hash=>$diffinfo->{'from_id'}[$i],
3592                                                            file_name=>$from->{'file'}[$i]);
3593                         } else {
3594                                 $from->{'href'}[$i] = undef;
3595                         }
3596                 }
3597         } else {
3598                 # ordinary (not combined) diff
3599                 $from->{'file'} = $diffinfo->{'from_file'};
3600                 if ($diffinfo->{'status'} ne "A") { # not new (added) file
3601                         $from->{'href'} = href(action=>"blob", hash_base=>$hash_parent,
3602                                                hash=>$diffinfo->{'from_id'},
3603                                                file_name=>$from->{'file'});
3604                 } else {
3605                         delete $from->{'href'};
3606                 }
3607         }
3608
3609         $to->{'file'} = $diffinfo->{'to_file'};
3610         if (!is_deleted($diffinfo)) { # file exists in result
3611                 $to->{'href'} = href(action=>"blob", hash_base=>$hash,
3612                                      hash=>$diffinfo->{'to_id'},
3613                                      file_name=>$to->{'file'});
3614         } else {
3615                 delete $to->{'href'};
3616         }
3617 }
3618
3619 ## ......................................................................
3620 ## parse to array of hashes functions
3621
3622 sub git_get_heads_list {
3623         my ($limit, @classes) = @_;
3624         @classes = ('heads') unless @classes;
3625         my @patterns = map { "refs/$_" } @classes;
3626         my @headslist;
3627
3628         open my $fd, '-|', git_cmd(), 'for-each-ref',
3629                 ($limit ? '--count='.($limit+1) : ()), '--sort=-committerdate',
3630                 '--format=%(objectname) %(refname) %(subject)%00%(committer)',
3631                 @patterns
3632                 or return;
3633         while (my $line = <$fd>) {
3634                 my %ref_item;
3635
3636                 chomp $line;
3637                 my ($refinfo, $committerinfo) = split(/\0/, $line);
3638                 my ($hash, $name, $title) = split(' ', $refinfo, 3);
3639                 my ($committer, $epoch, $tz) =
3640                         ($committerinfo =~ /^(.*) ([0-9]+) (.*)$/);
3641                 $ref_item{'fullname'}  = $name;
3642                 $name =~ s!^refs/(?:head|remote)s/!!;
3643
3644                 $ref_item{'name'}  = $name;
3645                 $ref_item{'id'}    = $hash;
3646                 $ref_item{'title'} = $title || '(no commit message)';
3647                 $ref_item{'epoch'} = $epoch;
3648                 if ($epoch) {
3649                         $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3650                 } else {
3651                         $ref_item{'age'} = "unknown";
3652                 }
3653
3654                 push @headslist, \%ref_item;
3655         }
3656         close $fd;
3657
3658         return wantarray ? @headslist : \@headslist;
3659 }
3660
3661 sub git_get_tags_list {
3662         my $limit = shift;
3663         my @tagslist;
3664
3665         open my $fd, '-|', git_cmd(), 'for-each-ref',
3666                 ($limit ? '--count='.($limit+1) : ()), '--sort=-creatordate',
3667                 '--format=%(objectname) %(objecttype) %(refname) '.
3668                 '%(*objectname) %(*objecttype) %(subject)%00%(creator)',
3669                 'refs/tags'
3670                 or return;
3671         while (my $line = <$fd>) {
3672                 my %ref_item;
3673
3674                 chomp $line;
3675                 my ($refinfo, $creatorinfo) = split(/\0/, $line);
3676                 my ($id, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
3677                 my ($creator, $epoch, $tz) =
3678                         ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
3679                 $ref_item{'fullname'} = $name;
3680                 $name =~ s!^refs/tags/!!;
3681
3682                 $ref_item{'type'} = $type;
3683                 $ref_item{'id'} = $id;
3684                 $ref_item{'name'} = $name;
3685                 if ($type eq "tag") {
3686                         $ref_item{'subject'} = $title;
3687                         $ref_item{'reftype'} = $reftype;
3688                         $ref_item{'refid'}   = $refid;
3689                 } else {
3690                         $ref_item{'reftype'} = $type;
3691                         $ref_item{'refid'}   = $id;
3692                 }
3693
3694                 if ($type eq "tag" || $type eq "commit") {
3695                         $ref_item{'epoch'} = $epoch;
3696                         if ($epoch) {
3697                                 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3698                         } else {
3699                                 $ref_item{'age'} = "unknown";
3700                         }
3701                 }
3702
3703                 push @tagslist, \%ref_item;
3704         }
3705         close $fd;
3706
3707         return wantarray ? @tagslist : \@tagslist;
3708 }
3709
3710 ## ----------------------------------------------------------------------
3711 ## filesystem-related functions
3712
3713 sub get_file_owner {
3714         my $path = shift;
3715
3716         my ($dev, $ino, $mode, $nlink, $st_uid, $st_gid, $rdev, $size) = stat($path);
3717         my ($name, $passwd, $uid, $gid, $quota, $comment, $gcos, $dir, $shell) = getpwuid($st_uid);
3718         if (!defined $gcos) {
3719                 return undef;
3720         }
3721         my $owner = $gcos;
3722         $owner =~ s/[,;].*$//;
3723         return to_utf8($owner);
3724 }
3725
3726 # assume that file exists
3727 sub insert_file {
3728         my $filename = shift;
3729
3730         open my $fd, '<', $filename;
3731         print map { to_utf8($_) } <$fd>;
3732         close $fd;
3733 }
3734
3735 ## ......................................................................
3736 ## mimetype related functions
3737
3738 sub mimetype_guess_file {
3739         my $filename = shift;
3740         my $mimemap = shift;
3741         -r $mimemap or return undef;
3742
3743         my %mimemap;
3744         open(my $mh, '<', $mimemap) or return undef;
3745         while (<$mh>) {
3746                 next if m/^#/; # skip comments
3747                 my ($mimetype, @exts) = split(/\s+/);
3748                 foreach my $ext (@exts) {
3749                         $mimemap{$ext} = $mimetype;
3750                 }
3751         }
3752         close($mh);
3753
3754         $filename =~ /\.([^.]*)$/;
3755         return $mimemap{$1};
3756 }
3757
3758 sub mimetype_guess {
3759         my $filename = shift;
3760         my $mime;
3761         $filename =~ /\./ or return undef;
3762
3763         if ($mimetypes_file) {
3764                 my $file = $mimetypes_file;
3765                 if ($file !~ m!^/!) { # if it is relative path
3766                         # it is relative to project
3767                         $file = "$projectroot/$project/$file";
3768                 }
3769                 $mime = mimetype_guess_file($filename, $file);
3770         }
3771         $mime ||= mimetype_guess_file($filename, '/etc/mime.types');
3772         return $mime;
3773 }
3774
3775 sub blob_mimetype {
3776         my $fd = shift;
3777         my $filename = shift;
3778
3779         if ($filename) {
3780                 my $mime = mimetype_guess($filename);
3781                 $mime and return $mime;
3782         }
3783
3784         # just in case
3785         return $default_blob_plain_mimetype unless $fd;
3786
3787         if (-T $fd) {
3788                 return 'text/plain';
3789         } elsif (! $filename) {
3790                 return 'application/octet-stream';
3791         } elsif ($filename =~ m/\.png$/i) {
3792                 return 'image/png';
3793         } elsif ($filename =~ m/\.gif$/i) {
3794                 return 'image/gif';
3795         } elsif ($filename =~ m/\.jpe?g$/i) {
3796                 return 'image/jpeg';
3797         } else {
3798                 return 'application/octet-stream';
3799         }
3800 }
3801
3802 sub blob_contenttype {
3803         my ($fd, $file_name, $type) = @_;
3804
3805         $type ||= blob_mimetype($fd, $file_name);
3806         if ($type eq 'text/plain' && defined $default_text_plain_charset) {
3807                 $type .= "; charset=$default_text_plain_charset";
3808         }
3809
3810         return $type;
3811 }
3812
3813 # guess file syntax for syntax highlighting; return undef if no highlighting
3814 # the name of syntax can (in the future) depend on syntax highlighter used
3815 sub guess_file_syntax {
3816         my ($highlight, $mimetype, $file_name) = @_;
3817         return undef unless ($highlight && defined $file_name);
3818         my $basename = basename($file_name, '.in');
3819         return $highlight_basename{$basename}
3820                 if exists $highlight_basename{$basename};
3821
3822         $basename =~ /\.([^.]*)$/;
3823         my $ext = $1 or return undef;
3824         return $highlight_ext{$ext}
3825                 if exists $highlight_ext{$ext};
3826
3827         return undef;
3828 }
3829
3830 # run highlighter and return FD of its output,
3831 # or return original FD if no highlighting
3832 sub run_highlighter {
3833         my ($fd, $highlight, $syntax) = @_;
3834         return $fd unless ($highlight && defined $syntax);
3835
3836         close $fd;
3837         open $fd, quote_command(git_cmd(), "cat-file", "blob", $hash)." | ".
3838                   quote_command($highlight_bin).
3839                   " --replace-tabs=8 --fragment --syntax $syntax |"
3840                 or die_error(500, "Couldn't open file or run syntax highlighter");
3841         return $fd;
3842 }
3843
3844 ## ======================================================================
3845 ## functions printing HTML: header, footer, error page
3846
3847 sub get_page_title {
3848         my $title = to_utf8($site_name);
3849
3850         unless (defined $project) {
3851                 if (defined $project_filter) {
3852                         $title .= " - projects in '" . esc_path($project_filter) . "'";
3853                 }
3854                 return $title;
3855         }
3856         $title .= " - " . to_utf8($project);
3857
3858         return $title unless (defined $action);
3859         $title .= "/$action"; # $action is US-ASCII (7bit ASCII)
3860
3861         return $title unless (defined $file_name);
3862         $title .= " - " . esc_path($file_name);
3863         if ($action eq "tree" && $file_name !~ m|/$|) {
3864                 $title .= "/";
3865         }
3866
3867         return $title;
3868 }
3869
3870 sub get_content_type_html {
3871         # require explicit support from the UA if we are to send the page as
3872         # 'application/xhtml+xml', otherwise send it as plain old 'text/html'.
3873         # we have to do this because MSIE sometimes globs '*/*', pretending to
3874         # support xhtml+xml but choking when it gets what it asked for.
3875         if (defined $cgi->http('HTTP_ACCEPT') &&
3876             $cgi->http('HTTP_ACCEPT') =~ m/(,|;|\s|^)application\/xhtml\+xml(,|;|\s|$)/ &&
3877             $cgi->Accept('application/xhtml+xml') != 0) {
3878                 return 'application/xhtml+xml';
3879         } else {
3880                 return 'text/html';
3881         }
3882 }
3883
3884 sub print_feed_meta {
3885         if (defined $project) {
3886                 my %href_params = get_feed_info();
3887                 if (!exists $href_params{'-title'}) {
3888                         $href_params{'-title'} = 'log';
3889                 }
3890
3891                 foreach my $format (qw(RSS Atom)) {
3892                         my $type = lc($format);
3893                         my %link_attr = (
3894                                 '-rel' => 'alternate',
3895                                 '-title' => esc_attr("$project - $href_params{'-title'} - $format feed"),
3896                                 '-type' => "application/$type+xml"
3897                         );
3898
3899                         $href_params{'extra_options'} = undef;
3900                         $href_params{'action'} = $type;
3901                         $link_attr{'-href'} = href(%href_params);
3902                         print "<link ".
3903                               "rel=\"$link_attr{'-rel'}\" ".
3904                               "title=\"$link_attr{'-title'}\" ".
3905                               "href=\"$link_attr{'-href'}\" ".
3906                               "type=\"$link_attr{'-type'}\" ".
3907                               "/>\n";
3908
3909                         $href_params{'extra_options'} = '--no-merges';
3910                         $link_attr{'-href'} = href(%href_params);
3911                         $link_attr{'-title'} .= ' (no merges)';
3912                         print "<link ".
3913                               "rel=\"$link_attr{'-rel'}\" ".
3914                               "title=\"$link_attr{'-title'}\" ".
3915                               "href=\"$link_attr{'-href'}\" ".
3916                               "type=\"$link_attr{'-type'}\" ".
3917                               "/>\n";
3918                 }
3919
3920         } else {
3921                 printf('<link rel="alternate" title="%s projects list" '.
3922                        'href="%s" type="text/plain; charset=utf-8" />'."\n",
3923                        esc_attr($site_name), href(project=>undef, action=>"project_index"));
3924                 printf('<link rel="alternate" title="%s projects feeds" '.
3925                        'href="%s" type="text/x-opml" />'."\n",
3926                        esc_attr($site_name), href(project=>undef, action=>"opml"));
3927         }
3928 }
3929
3930 sub print_header_links {
3931         my $status = shift;
3932
3933         # print out each stylesheet that exist, providing backwards capability
3934         # for those people who defined $stylesheet in a config file
3935         if (defined $stylesheet) {
3936                 print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
3937         } else {
3938                 foreach my $stylesheet (@stylesheets) {
3939                         next unless $stylesheet;
3940                         print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
3941                 }
3942         }
3943         print_feed_meta()
3944                 if ($status eq '200 OK');
3945         if (defined $favicon) {
3946                 print qq(<link rel="shortcut icon" href=").esc_url($favicon).qq(" type="image/png" />\n);
3947         }
3948 }
3949
3950 sub print_nav_breadcrumbs_path {
3951         my $dirprefix = undef;
3952         while (my $part = shift) {
3953                 $dirprefix .= "/" if defined $dirprefix;
3954                 $dirprefix .= $part;
3955                 print $cgi->a({-href => href(project => undef,
3956                                              project_filter => $dirprefix,
3957                                              action => "project_list")},
3958                               esc_html($part)) . " / ";
3959         }
3960 }
3961
3962 sub print_nav_breadcrumbs {
3963         my %opts = @_;
3964
3965         print $cgi->a({-href => esc_url($home_link)}, $home_link_str) . " / ";
3966         if (defined $project) {
3967                 my @dirname = split '/', $project;
3968                 my $projectbasename = pop @dirname;
3969                 print_nav_breadcrumbs_path(@dirname);
3970                 print $cgi->a({-href => href(action=>"summary")}, esc_html($projectbasename));
3971                 if (defined $action) {
3972                         my $action_print = $action ;
3973                         if (defined $opts{-action_extra}) {
3974                                 $action_print = $cgi->a({-href => href(action=>$action)},
3975                                         $action);
3976                         }
3977                         print " / $action_print";
3978                 }
3979                 if (defined $opts{-action_extra}) {
3980                         print " / $opts{-action_extra}";
3981                 }
3982                 print "\n";
3983         } elsif (defined $project_filter) {
3984                 print_nav_breadcrumbs_path(split '/', $project_filter);
3985         }
3986 }
3987
3988 sub print_search_form {
3989         if (!defined $searchtext) {
3990                 $searchtext = "";
3991         }
3992         my $search_hash;
3993         if (defined $hash_base) {
3994                 $search_hash = $hash_base;
3995         } elsif (defined $hash) {
3996                 $search_hash = $hash;
3997         } else {
3998                 $search_hash = "HEAD";
3999         }
4000         my $action = $my_uri;
4001         my $use_pathinfo = gitweb_check_feature('pathinfo');
4002         if ($use_pathinfo) {
4003                 $action .= "/".esc_url($project);
4004         }
4005         print $cgi->startform(-method => "get", -action => $action) .
4006               "<div class=\"search\">\n" .
4007               (!$use_pathinfo &&
4008               $cgi->input({-name=>"p", -value=>$project, -type=>"hidden"}) . "\n") .
4009               $cgi->input({-name=>"a", -value=>"search", -type=>"hidden"}) . "\n" .
4010               $cgi->input({-name=>"h", -value=>$search_hash, -type=>"hidden"}) . "\n" .
4011               $cgi->popup_menu(-name => 'st', -default => 'commit',
4012                                -values => ['commit', 'grep', 'author', 'committer', 'pickaxe']) .
4013               $cgi->sup($cgi->a({-href => href(action=>"search_help")}, "?")) .
4014               " search:\n",
4015               $cgi->textfield(-name => "s", -value => $searchtext, -override => 1) . "\n" .
4016               "<span title=\"Extended regular expression\">" .
4017               $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
4018                              -checked => $search_use_regexp) .
4019               "</span>" .
4020               "</div>" .
4021               $cgi->end_form() . "\n";
4022 }
4023
4024 sub git_header_html {
4025         my $status = shift || "200 OK";
4026         my $expires = shift;
4027         my %opts = @_;
4028
4029         my $title = get_page_title();
4030         my $content_type = get_content_type_html();
4031         print $cgi->header(-type=>$content_type, -charset => 'utf-8',
4032                            -status=> $status, -expires => $expires)
4033                 unless ($opts{'-no_http_header'});
4034         my $mod_perl_version = $ENV{'MOD_PERL'} ? " $ENV{'MOD_PERL'}" : '';
4035         print <<EOF;
4036 <?xml version="1.0" encoding="utf-8"?>
4037 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
4038 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en-US" lang="en-US">
4039 <!-- git web interface version $version, (C) 2005-2006, Kay Sievers <kay.sievers\@vrfy.org>, Christian Gierke -->
4040 <!-- git core binaries version $git_version -->
4041 <head>
4042 <meta http-equiv="content-type" content="$content_type; charset=utf-8"/>
4043 <meta name="generator" content="gitweb/$version git/$git_version$mod_perl_version"/>
4044 <meta name="robots" content="index, nofollow"/>
4045 <title>$title</title>
4046 EOF
4047         # the stylesheet, favicon etc urls won't work correctly with path_info
4048         # unless we set the appropriate base URL
4049         if ($ENV{'PATH_INFO'}) {
4050                 print "<base href=\"".esc_url($base_url)."\" />\n";
4051         }
4052         print_header_links($status);
4053
4054         if (defined $site_html_head_string) {
4055                 print to_utf8($site_html_head_string);
4056         }
4057
4058         print "</head>\n" .
4059               "<body>\n";
4060
4061         if (defined $site_header && -f $site_header) {
4062                 insert_file($site_header);
4063         }
4064
4065         print "<div class=\"page_header\">\n";
4066         if (defined $logo) {
4067                 print $cgi->a({-href => esc_url($logo_url),
4068                                -title => $logo_label},
4069                               $cgi->img({-src => esc_url($logo),
4070                                          -width => 72, -height => 27,
4071                                          -alt => "git",
4072                                          -class => "logo"}));
4073         }
4074         print_nav_breadcrumbs(%opts);
4075         print "</div>\n";
4076
4077         my $have_search = gitweb_check_feature('search');
4078         if (defined $project && $have_search) {
4079                 print_search_form();
4080         }
4081 }
4082
4083 sub git_footer_html {
4084         my $feed_class = 'rss_logo';
4085
4086         print "<div class=\"page_footer\">\n";
4087         if (defined $project) {
4088                 my $descr = git_get_project_description($project);
4089                 if (defined $descr) {
4090                         print "<div class=\"page_footer_text\">" . esc_html($descr) . "</div>\n";
4091                 }
4092
4093                 my %href_params = get_feed_info();
4094                 if (!%href_params) {
4095                         $feed_class .= ' generic';
4096                 }
4097                 $href_params{'-title'} ||= 'log';
4098
4099                 foreach my $format (qw(RSS Atom)) {
4100                         $href_params{'action'} = lc($format);
4101                         print $cgi->a({-href => href(%href_params),
4102                                       -title => "$href_params{'-title'} $format feed",
4103                                       -class => $feed_class}, $format)."\n";
4104                 }
4105
4106         } else {
4107                 print $cgi->a({-href => href(project=>undef, action=>"opml",
4108                                              project_filter => $project_filter),
4109                               -class => $feed_class}, "OPML") . " ";
4110                 print $cgi->a({-href => href(project=>undef, action=>"project_index",
4111                                              project_filter => $project_filter),
4112                               -class => $feed_class}, "TXT") . "\n";
4113         }
4114         print "</div>\n"; # class="page_footer"
4115
4116         if (defined $t0 && gitweb_check_feature('timed')) {
4117                 print "<div id=\"generating_info\">\n";
4118                 print 'This page took '.
4119                       '<span id="generating_time" class="time_span">'.
4120                       tv_interval($t0, [ gettimeofday() ]).
4121                       ' seconds </span>'.
4122                       ' and '.
4123                       '<span id="generating_cmd">'.
4124                       $number_of_git_cmds.
4125                       '</span> git commands '.
4126                       " to generate.\n";
4127                 print "</div>\n"; # class="page_footer"
4128         }
4129
4130         if (defined $site_footer && -f $site_footer) {
4131                 insert_file($site_footer);
4132         }
4133
4134         print qq!<script type="text/javascript" src="!.esc_url($javascript).qq!"></script>\n!;
4135         if (defined $action &&
4136             $action eq 'blame_incremental') {
4137                 print qq!<script type="text/javascript">\n!.
4138                       qq!startBlame("!. href(action=>"blame_data", -replay=>1) .qq!",\n!.
4139                       qq!           "!. href() .qq!");\n!.
4140                       qq!</script>\n!;
4141         } else {
4142                 my ($jstimezone, $tz_cookie, $datetime_class) =
4143                         gitweb_get_feature('javascript-timezone');
4144
4145                 print qq!<script type="text/javascript">\n!.
4146                       qq!window.onload = function () {\n!;
4147                 if (gitweb_check_feature('javascript-actions')) {
4148                         print qq!       fixLinks();\n!;
4149                 }
4150                 if ($jstimezone && $tz_cookie && $datetime_class) {
4151                         print qq!       var tz_cookie = { name: '$tz_cookie', expires: 14, path: '/' };\n!. # in days
4152                               qq!       onloadTZSetup('$jstimezone', tz_cookie, '$datetime_class');\n!;
4153                 }
4154                 print qq!};\n!.
4155                       qq!</script>\n!;
4156         }
4157
4158         print "</body>\n" .
4159               "</html>";
4160 }
4161
4162 # die_error(<http_status_code>, <error_message>[, <detailed_html_description>])
4163 # Example: die_error(404, 'Hash not found')
4164 # By convention, use the following status codes (as defined in RFC 2616):
4165 # 400: Invalid or missing CGI parameters, or
4166 #      requested object exists but has wrong type.
4167 # 403: Requested feature (like "pickaxe" or "snapshot") not enabled on
4168 #      this server or project.
4169 # 404: Requested object/revision/project doesn't exist.
4170 # 500: The server isn't configured properly, or
4171 #      an internal error occurred (e.g. failed assertions caused by bugs), or
4172 #      an unknown error occurred (e.g. the git binary died unexpectedly).
4173 # 503: The server is currently unavailable (because it is overloaded,
4174 #      or down for maintenance).  Generally, this is a temporary state.
4175 sub die_error {
4176         my $status = shift || 500;
4177         my $error = esc_html(shift) || "Internal Server Error";
4178         my $extra = shift;
4179         my %opts = @_;
4180
4181         my %http_responses = (
4182                 400 => '400 Bad Request',
4183                 403 => '403 Forbidden',
4184                 404 => '404 Not Found',
4185                 500 => '500 Internal Server Error',
4186                 503 => '503 Service Unavailable',
4187         );
4188         git_header_html($http_responses{$status}, undef, %opts);
4189         print <<EOF;
4190 <div class="page_body">
4191 <br /><br />
4192 $status - $error
4193 <br />
4194 EOF
4195         if (defined $extra) {
4196                 print "<hr />\n" .
4197                       "$extra\n";
4198         }
4199         print "</div>\n";
4200
4201         git_footer_html();
4202         goto DONE_GITWEB
4203                 unless ($opts{'-error_handler'});
4204 }
4205
4206 ## ----------------------------------------------------------------------
4207 ## functions printing or outputting HTML: navigation
4208
4209 sub git_print_page_nav {
4210         my ($current, $suppress, $head, $treehead, $treebase, $extra) = @_;
4211         $extra = '' if !defined $extra; # pager or formats
4212
4213         my @navs = qw(summary shortlog log commit commitdiff tree);
4214         if ($suppress) {
4215                 @navs = grep { $_ ne $suppress } @navs;
4216         }
4217
4218         my %arg = map { $_ => {action=>$_} } @navs;
4219         if (defined $head) {
4220                 for (qw(commit commitdiff)) {
4221                         $arg{$_}{'hash'} = $head;
4222                 }
4223                 if ($current =~ m/^(tree | log | shortlog | commit | commitdiff | search)$/x) {
4224                         for (qw(shortlog log)) {
4225                                 $arg{$_}{'hash'} = $head;
4226                         }
4227                 }
4228         }
4229
4230         $arg{'tree'}{'hash'} = $treehead if defined $treehead;
4231         $arg{'tree'}{'hash_base'} = $treebase if defined $treebase;
4232
4233         my @actions = gitweb_get_feature('actions');
4234         my %repl = (
4235                 '%' => '%',
4236                 'n' => $project,         # project name
4237                 'f' => $git_dir,         # project path within filesystem
4238                 'h' => $treehead || '',  # current hash ('h' parameter)
4239                 'b' => $treebase || '',  # hash base ('hb' parameter)
4240         );
4241         while (@actions) {
4242                 my ($label, $link, $pos) = splice(@actions,0,3);
4243                 # insert
4244                 @navs = map { $_ eq $pos ? ($_, $label) : $_ } @navs;
4245                 # munch munch
4246                 $link =~ s/%([%nfhb])/$repl{$1}/g;
4247                 $arg{$label}{'_href'} = $link;
4248         }
4249
4250         print "<div class=\"page_nav\">\n" .
4251                 (join " | ",
4252                  map { $_ eq $current ?
4253                        $_ : $cgi->a({-href => ($arg{$_}{_href} ? $arg{$_}{_href} : href(%{$arg{$_}}))}, "$_")
4254                  } @navs);
4255         print "<br/>\n$extra<br/>\n" .
4256               "</div>\n";
4257 }
4258
4259 # returns a submenu for the nagivation of the refs views (tags, heads,
4260 # remotes) with the current view disabled and the remotes view only
4261 # available if the feature is enabled
4262 sub format_ref_views {
4263         my ($current) = @_;
4264         my @ref_views = qw{tags heads};
4265         push @ref_views, 'remotes' if gitweb_check_feature('remote_heads');
4266         return join " | ", map {
4267                 $_ eq $current ? $_ :
4268                 $cgi->a({-href => href(action=>$_)}, $_)
4269         } @ref_views
4270 }
4271
4272 sub format_paging_nav {
4273         my ($action, $page, $has_next_link) = @_;
4274         my $paging_nav;
4275
4276
4277         if ($page > 0) {
4278                 $paging_nav .=
4279                         $cgi->a({-href => href(-replay=>1, page=>undef)}, "first") .
4280                         " &sdot; " .
4281                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
4282                                  -accesskey => "p", -title => "Alt-p"}, "prev");
4283         } else {
4284                 $paging_nav .= "first &sdot; prev";
4285         }
4286
4287         if ($has_next_link) {
4288                 $paging_nav .= " &sdot; " .
4289                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
4290                                  -accesskey => "n", -title => "Alt-n"}, "next");
4291         } else {
4292                 $paging_nav .= " &sdot; next";
4293         }
4294
4295         return $paging_nav;
4296 }
4297
4298 ## ......................................................................
4299 ## functions printing or outputting HTML: div
4300
4301 sub git_print_header_div {
4302         my ($action, $title, $hash, $hash_base) = @_;
4303         my %args = ();
4304
4305         $args{'action'} = $action;
4306         $args{'hash'} = $hash if $hash;
4307         $args{'hash_base'} = $hash_base if $hash_base;
4308
4309         print "<div class=\"header\">\n" .
4310               $cgi->a({-href => href(%args), -class => "title"},
4311               $title ? $title : $action) .
4312               "\n</div>\n";
4313 }
4314
4315 sub format_repo_url {
4316         my ($name, $url) = @_;
4317         return "<tr class=\"metadata_url\"><td>$name</td><td>$url</td></tr>\n";
4318 }
4319
4320 # Group output by placing it in a DIV element and adding a header.
4321 # Options for start_div() can be provided by passing a hash reference as the
4322 # first parameter to the function.
4323 # Options to git_print_header_div() can be provided by passing an array
4324 # reference. This must follow the options to start_div if they are present.
4325 # The content can be a scalar, which is output as-is, a scalar reference, which
4326 # is output after html escaping, an IO handle passed either as *handle or
4327 # *handle{IO}, or a function reference. In the latter case all following
4328 # parameters will be taken as argument to the content function call.
4329 sub git_print_section {
4330         my ($div_args, $header_args, $content);
4331         my $arg = shift;
4332         if (ref($arg) eq 'HASH') {
4333                 $div_args = $arg;
4334                 $arg = shift;
4335         }
4336         if (ref($arg) eq 'ARRAY') {
4337                 $header_args = $arg;
4338                 $arg = shift;
4339         }
4340         $content = $arg;
4341
4342         print $cgi->start_div($div_args);
4343         git_print_header_div(@$header_args);
4344
4345         if (ref($content) eq 'CODE') {
4346                 $content->(@_);
4347         } elsif (ref($content) eq 'SCALAR') {
4348                 print esc_html($$content);
4349         } elsif (ref($content) eq 'GLOB' or ref($content) eq 'IO::Handle') {
4350                 print <$content>;
4351         } elsif (!ref($content) && defined($content)) {
4352                 print $content;
4353         }
4354
4355         print $cgi->end_div;
4356 }
4357
4358 sub format_timestamp_html {
4359         my $date = shift;
4360         my $strtime = $date->{'rfc2822'};
4361
4362         my (undef, undef, $datetime_class) =
4363                 gitweb_get_feature('javascript-timezone');
4364         if ($datetime_class) {
4365                 $strtime = qq!<span class="$datetime_class">$strtime</span>!;
4366         }
4367
4368         my $localtime_format = '(%02d:%02d %s)';
4369         if ($date->{'hour_local'} < 6) {
4370                 $localtime_format = '(<span class="atnight">%02d:%02d</span> %s)';
4371         }
4372         $strtime .= ' ' .
4373                     sprintf($localtime_format,
4374                             $date->{'hour_local'}, $date->{'minute_local'}, $date->{'tz_local'});
4375
4376         return $strtime;
4377 }
4378
4379 # Outputs the author name and date in long form
4380 sub git_print_authorship {
4381         my $co = shift;
4382         my %opts = @_;
4383         my $tag = $opts{-tag} || 'div';
4384         my $author = $co->{'author_name'};
4385
4386         my %ad = parse_date($co->{'author_epoch'}, $co->{'author_tz'});
4387         print "<$tag class=\"author_date\">" .
4388               format_search_author($author, "author", esc_html($author)) .
4389               " [".format_timestamp_html(\%ad)."]".
4390               git_get_avatar($co->{'author_email'}, -pad_before => 1) .
4391               "</$tag>\n";
4392 }
4393
4394 # Outputs table rows containing the full author or committer information,
4395 # in the format expected for 'commit' view (& similar).
4396 # Parameters are a commit hash reference, followed by the list of people
4397 # to output information for. If the list is empty it defaults to both
4398 # author and committer.
4399 sub git_print_authorship_rows {
4400         my $co = shift;
4401         # too bad we can't use @people = @_ || ('author', 'committer')
4402         my @people = @_;
4403         @people = ('author', 'committer') unless @people;
4404         foreach my $who (@people) {
4405                 my %wd = parse_date($co->{"${who}_epoch"}, $co->{"${who}_tz"});
4406                 print "<tr><td>$who</td><td>" .
4407                       format_search_author($co->{"${who}_name"}, $who,
4408                                            esc_html($co->{"${who}_name"})) . " " .
4409                       format_search_author($co->{"${who}_email"}, $who,
4410                                            esc_html("<" . $co->{"${who}_email"} . ">")) .
4411                       "</td><td rowspan=\"2\">" .
4412                       git_get_avatar($co->{"${who}_email"}, -size => 'double') .
4413                       "</td></tr>\n" .
4414                       "<tr>" .
4415                       "<td></td><td>" .
4416                       format_timestamp_html(\%wd) .
4417                       "</td>" .
4418                       "</tr>\n";
4419         }
4420 }
4421
4422 sub git_print_page_path {
4423         my $name = shift;
4424         my $type = shift;
4425         my $hb = shift;
4426
4427
4428         print "<div class=\"page_path\">";
4429         print $cgi->a({-href => href(action=>"tree", hash_base=>$hb),
4430                       -title => 'tree root'}, to_utf8("[$project]"));
4431         print " / ";
4432         if (defined $name) {
4433                 my @dirname = split '/', $name;
4434                 my $basename = pop @dirname;
4435                 my $fullname = '';
4436
4437                 foreach my $dir (@dirname) {
4438                         $fullname .= ($fullname ? '/' : '') . $dir;
4439                         print $cgi->a({-href => href(action=>"tree", file_name=>$fullname,
4440                                                      hash_base=>$hb),
4441                                       -title => $fullname}, esc_path($dir));
4442                         print " / ";
4443                 }
4444                 if (defined $type && $type eq 'blob') {
4445                         print $cgi->a({-href => href(action=>"blob_plain", file_name=>$file_name,
4446                                                      hash_base=>$hb),
4447                                       -title => $name}, esc_path($basename));
4448                 } elsif (defined $type && $type eq 'tree') {
4449                         print $cgi->a({-href => href(action=>"tree", file_name=>$file_name,
4450                                                      hash_base=>$hb),
4451                                       -title => $name}, esc_path($basename));
4452                         print " / ";
4453                 } else {
4454                         print esc_path($basename);
4455                 }
4456         }
4457         print "<br/></div>\n";
4458 }
4459
4460 sub git_print_log {
4461         my $log = shift;
4462         my %opts = @_;
4463
4464         if ($opts{'-remove_title'}) {
4465                 # remove title, i.e. first line of log
4466                 shift @$log;
4467         }
4468         # remove leading empty lines
4469         while (defined $log->[0] && $log->[0] eq "") {
4470                 shift @$log;
4471         }
4472
4473         # print log
4474         my $signoff = 0;
4475         my $empty = 0;
4476         foreach my $line (@$log) {
4477                 if ($line =~ m/^ *(signed[ \-]off[ \-]by[ :]|acked[ \-]by[ :]|cc[ :])/i) {
4478                         $signoff = 1;
4479                         $empty = 0;
4480                         if (! $opts{'-remove_signoff'}) {
4481                                 print "<span class=\"signoff\">" . esc_html($line) . "</span><br/>\n";
4482                                 next;
4483                         } else {
4484                                 # remove signoff lines
4485                                 next;
4486                         }
4487                 } else {
4488                         $signoff = 0;
4489                 }
4490
4491                 # print only one empty line
4492                 # do not print empty line after signoff
4493                 if ($line eq "") {
4494                         next if ($empty || $signoff);
4495                         $empty = 1;
4496                 } else {
4497                         $empty = 0;
4498                 }
4499
4500                 print format_log_line_html($line) . "<br/>\n";
4501         }
4502
4503         if ($opts{'-final_empty_line'}) {
4504                 # end with single empty line
4505                 print "<br/>\n" unless $empty;
4506         }
4507 }
4508
4509 # return link target (what link points to)
4510 sub git_get_link_target {
4511         my $hash = shift;
4512         my $link_target;
4513
4514         # read link
4515         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
4516                 or return;
4517         {
4518                 local $/ = undef;
4519                 $link_target = <$fd>;
4520         }
4521         close $fd
4522                 or return;
4523
4524         return $link_target;
4525 }
4526
4527 # given link target, and the directory (basedir) the link is in,
4528 # return target of link relative to top directory (top tree);
4529 # return undef if it is not possible (including absolute links).
4530 sub normalize_link_target {
4531         my ($link_target, $basedir) = @_;
4532
4533         # absolute symlinks (beginning with '/') cannot be normalized
4534         return if (substr($link_target, 0, 1) eq '/');
4535
4536         # normalize link target to path from top (root) tree (dir)
4537         my $path;
4538         if ($basedir) {
4539                 $path = $basedir . '/' . $link_target;
4540         } else {
4541                 # we are in top (root) tree (dir)
4542                 $path = $link_target;
4543         }
4544
4545         # remove //, /./, and /../
4546         my @path_parts;
4547         foreach my $part (split('/', $path)) {
4548                 # discard '.' and ''
4549                 next if (!$part || $part eq '.');
4550                 # handle '..'
4551                 if ($part eq '..') {
4552                         if (@path_parts) {
4553                                 pop @path_parts;
4554                         } else {
4555                                 # link leads outside repository (outside top dir)
4556                                 return;
4557                         }
4558                 } else {
4559                         push @path_parts, $part;
4560                 }
4561         }
4562         $path = join('/', @path_parts);
4563
4564         return $path;
4565 }
4566
4567 # print tree entry (row of git_tree), but without encompassing <tr> element
4568 sub git_print_tree_entry {
4569         my ($t, $basedir, $hash_base, $have_blame) = @_;
4570
4571         my %base_key = ();
4572         $base_key{'hash_base'} = $hash_base if defined $hash_base;
4573
4574         # The format of a table row is: mode list link.  Where mode is
4575         # the mode of the entry, list is the name of the entry, an href,
4576         # and link is the action links of the entry.
4577
4578         print "<td class=\"mode\">" . mode_str($t->{'mode'}) . "</td>\n";
4579         if (exists $t->{'size'}) {
4580                 print "<td class=\"size\">$t->{'size'}</td>\n";
4581         }
4582         if ($t->{'type'} eq "blob") {
4583                 print "<td class=\"list\">" .
4584                         $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4585                                                file_name=>"$basedir$t->{'name'}", %base_key),
4586                                 -class => "list"}, esc_path($t->{'name'}));
4587                 if (S_ISLNK(oct $t->{'mode'})) {
4588                         my $link_target = git_get_link_target($t->{'hash'});
4589                         if ($link_target) {
4590                                 my $norm_target = normalize_link_target($link_target, $basedir);
4591                                 if (defined $norm_target) {
4592                                         print " -> " .
4593                                               $cgi->a({-href => href(action=>"object", hash_base=>$hash_base,
4594                                                                      file_name=>$norm_target),
4595                                                        -title => $norm_target}, esc_path($link_target));
4596                                 } else {
4597                                         print " -> " . esc_path($link_target);
4598                                 }
4599                         }
4600                 }
4601                 print "</td>\n";
4602                 print "<td class=\"link\">";
4603                 print $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4604                                              file_name=>"$basedir$t->{'name'}", %base_key)},
4605                               "blob");
4606                 if ($have_blame) {
4607                         print " | " .
4608                               $cgi->a({-href => href(action=>"blame", hash=>$t->{'hash'},
4609                                                      file_name=>"$basedir$t->{'name'}", %base_key)},
4610                                       "blame");
4611                 }
4612                 if (defined $hash_base) {
4613                         print " | " .
4614                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4615                                                      hash=>$t->{'hash'}, file_name=>"$basedir$t->{'name'}")},
4616                                       "history");
4617                 }
4618                 print " | " .
4619                         $cgi->a({-href => href(action=>"blob_plain", hash_base=>$hash_base,
4620                                                file_name=>"$basedir$t->{'name'}")},
4621                                 "raw");
4622                 print "</td>\n";
4623
4624         } elsif ($t->{'type'} eq "tree") {
4625                 print "<td class=\"list\">";
4626                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4627                                              file_name=>"$basedir$t->{'name'}",
4628                                              %base_key)},
4629                               esc_path($t->{'name'}));
4630                 print "</td>\n";
4631                 print "<td class=\"link\">";
4632                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4633                                              file_name=>"$basedir$t->{'name'}",
4634                                              %base_key)},
4635                               "tree");
4636                 if (defined $hash_base) {
4637                         print " | " .
4638                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4639                                                      file_name=>"$basedir$t->{'name'}")},
4640                                       "history");
4641                 }
4642                 print "</td>\n";
4643         } else {
4644                 # unknown object: we can only present history for it
4645                 # (this includes 'commit' object, i.e. submodule support)
4646                 print "<td class=\"list\">" .
4647                       esc_path($t->{'name'}) .
4648                       "</td>\n";
4649                 print "<td class=\"link\">";
4650                 if (defined $hash_base) {
4651                         print $cgi->a({-href => href(action=>"history",
4652                                                      hash_base=>$hash_base,
4653                                                      file_name=>"$basedir$t->{'name'}")},
4654                                       "history");
4655                 }
4656                 print "</td>\n";
4657         }
4658 }
4659
4660 ## ......................................................................
4661 ## functions printing large fragments of HTML
4662
4663 # get pre-image filenames for merge (combined) diff
4664 sub fill_from_file_info {
4665         my ($diff, @parents) = @_;
4666
4667         $diff->{'from_file'} = [ ];
4668         $diff->{'from_file'}[$diff->{'nparents'} - 1] = undef;
4669         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4670                 if ($diff->{'status'}[$i] eq 'R' ||
4671                     $diff->{'status'}[$i] eq 'C') {
4672                         $diff->{'from_file'}[$i] =
4673                                 git_get_path_by_hash($parents[$i], $diff->{'from_id'}[$i]);
4674                 }
4675         }
4676
4677         return $diff;
4678 }
4679
4680 # is current raw difftree line of file deletion
4681 sub is_deleted {
4682         my $diffinfo = shift;
4683
4684         return $diffinfo->{'to_id'} eq ('0' x 40);
4685 }
4686
4687 # does patch correspond to [previous] difftree raw line
4688 # $diffinfo  - hashref of parsed raw diff format
4689 # $patchinfo - hashref of parsed patch diff format
4690 #              (the same keys as in $diffinfo)
4691 sub is_patch_split {
4692         my ($diffinfo, $patchinfo) = @_;
4693
4694         return defined $diffinfo && defined $patchinfo
4695                 && $diffinfo->{'to_file'} eq $patchinfo->{'to_file'};
4696 }
4697
4698
4699 sub git_difftree_body {
4700         my ($difftree, $hash, @parents) = @_;
4701         my ($parent) = $parents[0];
4702         my $have_blame = gitweb_check_feature('blame');
4703         print "<div class=\"list_head\">\n";
4704         if ($#{$difftree} > 10) {
4705                 print(($#{$difftree} + 1) . " files changed:\n");
4706         }
4707         print "</div>\n";
4708
4709         print "<table class=\"" .
4710               (@parents > 1 ? "combined " : "") .
4711               "diff_tree\">\n";
4712
4713         # header only for combined diff in 'commitdiff' view
4714         my $has_header = @$difftree && @parents > 1 && $action eq 'commitdiff';
4715         if ($has_header) {
4716                 # table header
4717                 print "<thead><tr>\n" .
4718                        "<th></th><th></th>\n"; # filename, patchN link
4719                 for (my $i = 0; $i < @parents; $i++) {
4720                         my $par = $parents[$i];
4721                         print "<th>" .
4722                               $cgi->a({-href => href(action=>"commitdiff",
4723                                                      hash=>$hash, hash_parent=>$par),
4724                                        -title => 'commitdiff to parent number ' .
4725                                                   ($i+1) . ': ' . substr($par,0,7)},
4726                                       $i+1) .
4727                               "&nbsp;</th>\n";
4728                 }
4729                 print "</tr></thead>\n<tbody>\n";
4730         }
4731
4732         my $alternate = 1;
4733         my $patchno = 0;
4734         foreach my $line (@{$difftree}) {
4735                 my $diff = parsed_difftree_line($line);
4736
4737                 if ($alternate) {
4738                         print "<tr class=\"dark\">\n";
4739                 } else {
4740                         print "<tr class=\"light\">\n";
4741                 }
4742                 $alternate ^= 1;
4743
4744                 if (exists $diff->{'nparents'}) { # combined diff
4745
4746                         fill_from_file_info($diff, @parents)
4747                                 unless exists $diff->{'from_file'};
4748
4749                         if (!is_deleted($diff)) {
4750                                 # file exists in the result (child) commit
4751                                 print "<td>" .
4752                                       $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4753                                                              file_name=>$diff->{'to_file'},
4754                                                              hash_base=>$hash),
4755                                               -class => "list"}, esc_path($diff->{'to_file'})) .
4756                                       "</td>\n";
4757                         } else {
4758                                 print "<td>" .
4759                                       esc_path($diff->{'to_file'}) .
4760                                       "</td>\n";
4761                         }
4762
4763                         if ($action eq 'commitdiff') {
4764                                 # link to patch
4765                                 $patchno++;
4766                                 print "<td class=\"link\">" .
4767                                       $cgi->a({-href => href(-anchor=>"patch$patchno")},
4768                                               "patch") .
4769                                       " | " .
4770                                       "</td>\n";
4771                         }
4772
4773                         my $has_history = 0;
4774                         my $not_deleted = 0;
4775                         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4776                                 my $hash_parent = $parents[$i];
4777                                 my $from_hash = $diff->{'from_id'}[$i];
4778                                 my $from_path = $diff->{'from_file'}[$i];
4779                                 my $status = $diff->{'status'}[$i];
4780
4781                                 $has_history ||= ($status ne 'A');
4782                                 $not_deleted ||= ($status ne 'D');
4783
4784                                 if ($status eq 'A') {
4785                                         print "<td  class=\"link\" align=\"right\"> | </td>\n";
4786                                 } elsif ($status eq 'D') {
4787                                         print "<td class=\"link\">" .
4788                                               $cgi->a({-href => href(action=>"blob",
4789                                                                      hash_base=>$hash,
4790                                                                      hash=>$from_hash,
4791                                                                      file_name=>$from_path)},
4792                                                       "blob" . ($i+1)) .
4793                                               " | </td>\n";
4794                                 } else {
4795                                         if ($diff->{'to_id'} eq $from_hash) {
4796                                                 print "<td class=\"link nochange\">";
4797                                         } else {
4798                                                 print "<td class=\"link\">";
4799                                         }
4800                                         print $cgi->a({-href => href(action=>"blobdiff",
4801                                                                      hash=>$diff->{'to_id'},
4802                                                                      hash_parent=>$from_hash,
4803                                                                      hash_base=>$hash,
4804                                                                      hash_parent_base=>$hash_parent,
4805                                                                      file_name=>$diff->{'to_file'},
4806                                                                      file_parent=>$from_path)},
4807                                                       "diff" . ($i+1)) .
4808                                               " | </td>\n";
4809                                 }
4810                         }
4811
4812                         print "<td class=\"link\">";
4813                         if ($not_deleted) {
4814                                 print $cgi->a({-href => href(action=>"blob",
4815                                                              hash=>$diff->{'to_id'},
4816                                                              file_name=>$diff->{'to_file'},
4817                                                              hash_base=>$hash)},
4818                                               "blob");
4819                                 print " | " if ($has_history);
4820                         }
4821                         if ($has_history) {
4822                                 print $cgi->a({-href => href(action=>"history",
4823                                                              file_name=>$diff->{'to_file'},
4824                                                              hash_base=>$hash)},
4825                                               "history");
4826                         }
4827                         print "</td>\n";
4828
4829                         print "</tr>\n";
4830                         next; # instead of 'else' clause, to avoid extra indent
4831                 }
4832                 # else ordinary diff
4833
4834                 my ($to_mode_oct, $to_mode_str, $to_file_type);
4835                 my ($from_mode_oct, $from_mode_str, $from_file_type);
4836                 if ($diff->{'to_mode'} ne ('0' x 6)) {
4837                         $to_mode_oct = oct $diff->{'to_mode'};
4838                         if (S_ISREG($to_mode_oct)) { # only for regular file
4839                                 $to_mode_str = sprintf("%04o", $to_mode_oct & 0777); # permission bits
4840                         }
4841                         $to_file_type = file_type($diff->{'to_mode'});
4842                 }
4843                 if ($diff->{'from_mode'} ne ('0' x 6)) {
4844                         $from_mode_oct = oct $diff->{'from_mode'};
4845                         if (S_ISREG($from_mode_oct)) { # only for regular file
4846                                 $from_mode_str = sprintf("%04o", $from_mode_oct & 0777); # permission bits
4847                         }
4848                         $from_file_type = file_type($diff->{'from_mode'});
4849                 }
4850
4851                 if ($diff->{'status'} eq "A") { # created
4852                         my $mode_chng = "<span class=\"file_status new\">[new $to_file_type";
4853                         $mode_chng   .= " with mode: $to_mode_str" if $to_mode_str;
4854                         $mode_chng   .= "]</span>";
4855                         print "<td>";
4856                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4857                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4858                                       -class => "list"}, esc_path($diff->{'file'}));
4859                         print "</td>\n";
4860                         print "<td>$mode_chng</td>\n";
4861                         print "<td class=\"link\">";
4862                         if ($action eq 'commitdiff') {
4863                                 # link to patch
4864                                 $patchno++;
4865                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4866                                               "patch") .
4867                                       " | ";
4868                         }
4869                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4870                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4871                                       "blob");
4872                         print "</td>\n";
4873
4874                 } elsif ($diff->{'status'} eq "D") { # deleted
4875                         my $mode_chng = "<span class=\"file_status deleted\">[deleted $from_file_type]</span>";
4876                         print "<td>";
4877                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4878                                                      hash_base=>$parent, file_name=>$diff->{'file'}),
4879                                        -class => "list"}, esc_path($diff->{'file'}));
4880                         print "</td>\n";
4881                         print "<td>$mode_chng</td>\n";
4882                         print "<td class=\"link\">";
4883                         if ($action eq 'commitdiff') {
4884                                 # link to patch
4885                                 $patchno++;
4886                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4887                                               "patch") .
4888                                       " | ";
4889                         }
4890                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4891                                                      hash_base=>$parent, file_name=>$diff->{'file'})},
4892                                       "blob") . " | ";
4893                         if ($have_blame) {
4894                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$parent,
4895                                                              file_name=>$diff->{'file'})},
4896                                               "blame") . " | ";
4897                         }
4898                         print $cgi->a({-href => href(action=>"history", hash_base=>$parent,
4899                                                      file_name=>$diff->{'file'})},
4900                                       "history");
4901                         print "</td>\n";
4902
4903                 } elsif ($diff->{'status'} eq "M" || $diff->{'status'} eq "T") { # modified, or type changed
4904                         my $mode_chnge = "";
4905                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4906                                 $mode_chnge = "<span class=\"file_status mode_chnge\">[changed";
4907                                 if ($from_file_type ne $to_file_type) {
4908                                         $mode_chnge .= " from $from_file_type to $to_file_type";
4909                                 }
4910                                 if (($from_mode_oct & 0777) != ($to_mode_oct & 0777)) {
4911                                         if ($from_mode_str && $to_mode_str) {
4912                                                 $mode_chnge .= " mode: $from_mode_str->$to_mode_str";
4913                                         } elsif ($to_mode_str) {
4914                                                 $mode_chnge .= " mode: $to_mode_str";
4915                                         }
4916                                 }
4917                                 $mode_chnge .= "]</span>\n";
4918                         }
4919                         print "<td>";
4920                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4921                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4922                                       -class => "list"}, esc_path($diff->{'file'}));
4923                         print "</td>\n";
4924                         print "<td>$mode_chnge</td>\n";
4925                         print "<td class=\"link\">";
4926                         if ($action eq 'commitdiff') {
4927                                 # link to patch
4928                                 $patchno++;
4929                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4930                                               "patch") .
4931                                       " | ";
4932                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4933                                 # "commit" view and modified file (not onlu mode changed)
4934                                 print $cgi->a({-href => href(action=>"blobdiff",
4935                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4936                                                              hash_base=>$hash, hash_parent_base=>$parent,
4937                                                              file_name=>$diff->{'file'})},
4938                                               "diff") .
4939                                       " | ";
4940                         }
4941                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4942                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4943                                        "blob") . " | ";
4944                         if ($have_blame) {
4945                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4946                                                              file_name=>$diff->{'file'})},
4947                                               "blame") . " | ";
4948                         }
4949                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4950                                                      file_name=>$diff->{'file'})},
4951                                       "history");
4952                         print "</td>\n";
4953
4954                 } elsif ($diff->{'status'} eq "R" || $diff->{'status'} eq "C") { # renamed or copied
4955                         my %status_name = ('R' => 'moved', 'C' => 'copied');
4956                         my $nstatus = $status_name{$diff->{'status'}};
4957                         my $mode_chng = "";
4958                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4959                                 # mode also for directories, so we cannot use $to_mode_str
4960                                 $mode_chng = sprintf(", mode: %04o", $to_mode_oct & 0777);
4961                         }
4962                         print "<td>" .
4963                               $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
4964                                                      hash=>$diff->{'to_id'}, file_name=>$diff->{'to_file'}),
4965                                       -class => "list"}, esc_path($diff->{'to_file'})) . "</td>\n" .
4966                               "<td><span class=\"file_status $nstatus\">[$nstatus from " .
4967                               $cgi->a({-href => href(action=>"blob", hash_base=>$parent,
4968                                                      hash=>$diff->{'from_id'}, file_name=>$diff->{'from_file'}),
4969                                       -class => "list"}, esc_path($diff->{'from_file'})) .
4970                               " with " . (int $diff->{'similarity'}) . "% similarity$mode_chng]</span></td>\n" .
4971                               "<td class=\"link\">";
4972                         if ($action eq 'commitdiff') {
4973                                 # link to patch
4974                                 $patchno++;
4975                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4976                                               "patch") .
4977                                       " | ";
4978                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4979                                 # "commit" view and modified file (not only pure rename or copy)
4980                                 print $cgi->a({-href => href(action=>"blobdiff",
4981                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4982                                                              hash_base=>$hash, hash_parent_base=>$parent,
4983                                                              file_name=>$diff->{'to_file'}, file_parent=>$diff->{'from_file'})},
4984                                               "diff") .
4985                                       " | ";
4986                         }
4987                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4988                                                      hash_base=>$parent, file_name=>$diff->{'to_file'})},
4989                                       "blob") . " | ";
4990                         if ($have_blame) {
4991                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4992                                                              file_name=>$diff->{'to_file'})},
4993                                               "blame") . " | ";
4994                         }
4995                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4996                                                     file_name=>$diff->{'to_file'})},
4997                                       "history");
4998                         print "</td>\n";
4999
5000                 } # we should not encounter Unmerged (U) or Unknown (X) status
5001                 print "</tr>\n";
5002         }
5003         print "</tbody>" if $has_header;
5004         print "</table>\n";
5005 }
5006
5007 # Print context lines and then rem/add lines in a side-by-side manner.
5008 sub print_sidebyside_diff_lines {
5009         my ($ctx, $rem, $add) = @_;
5010
5011         # print context block before add/rem block
5012         if (@$ctx) {
5013                 print join '',
5014                         '<div class="chunk_block ctx">',
5015                                 '<div class="old">',
5016                                 @$ctx,
5017                                 '</div>',
5018                                 '<div class="new">',
5019                                 @$ctx,
5020                                 '</div>',
5021                         '</div>';
5022         }
5023
5024         if (!@$add) {
5025                 # pure removal
5026                 print join '',
5027                         '<div class="chunk_block rem">',
5028                                 '<div class="old">',
5029                                 @$rem,
5030                                 '</div>',
5031                         '</div>';
5032         } elsif (!@$rem) {
5033                 # pure addition
5034                 print join '',
5035                         '<div class="chunk_block add">',
5036                                 '<div class="new">',
5037                                 @$add,
5038                                 '</div>',
5039                         '</div>';
5040         } else {
5041                 print join '',
5042                         '<div class="chunk_block chg">',
5043                                 '<div class="old">',
5044                                 @$rem,
5045                                 '</div>',
5046                                 '<div class="new">',
5047                                 @$add,
5048                                 '</div>',
5049                         '</div>';
5050         }
5051 }
5052
5053 # Print context lines and then rem/add lines in inline manner.
5054 sub print_inline_diff_lines {
5055         my ($ctx, $rem, $add) = @_;
5056
5057         print @$ctx, @$rem, @$add;
5058 }
5059
5060 # Print context lines and then rem/add lines.
5061 sub print_diff_lines {
5062         my ($ctx, $rem, $add, $diff_style, $is_combined) = @_;
5063
5064         if ($diff_style eq 'sidebyside' && !$is_combined) {
5065                 print_sidebyside_diff_lines($ctx, $rem, $add);
5066         } else {
5067                 # default 'inline' style and unknown styles
5068                 print_inline_diff_lines($ctx, $rem, $add);
5069         }
5070 }
5071
5072 sub print_diff_chunk {
5073         my ($diff_style, $is_combined, $from, $to, @chunk) = @_;
5074         my (@ctx, @rem, @add);
5075
5076         # The class of the previous line.
5077         my $prev_class = '';
5078
5079         return unless @chunk;
5080
5081         # incomplete last line might be among removed or added lines,
5082         # or both, or among context lines: find which
5083         for (my $i = 1; $i < @chunk; $i++) {
5084                 if ($chunk[$i][0] eq 'incomplete') {
5085                         $chunk[$i][0] = $chunk[$i-1][0];
5086                 }
5087         }
5088
5089         # guardian
5090         push @chunk, ["", ""];
5091
5092         foreach my $line_info (@chunk) {
5093                 my ($class, $line) = @$line_info;
5094
5095                 $line = format_diff_line($line, $class, $from, $to);
5096
5097                 # print chunk headers
5098                 if ($class && $class eq 'chunk_header') {
5099                         print $line;
5100                         next;
5101                 }
5102
5103                 ## print from accumulator when have some add/rem lines or end
5104                 # of chunk (flush context lines), or when have add and rem
5105                 # lines and new block is reached (otherwise add/rem lines could
5106                 # be reordered)
5107                 if (!$class || ((@rem || @add) && $class eq 'ctx') ||
5108                     (@rem && @add && $class ne $prev_class)) {
5109                         print_diff_lines(\@ctx, \@rem, \@add,
5110                                          $diff_style, $is_combined);
5111                         @ctx = @rem = @add = ();
5112                 }
5113
5114                 ## adding lines to accumulator
5115                 # guardian value
5116                 last unless $line;
5117                 # rem, add or change
5118                 if ($class eq 'rem') {
5119                         push @rem, $line;
5120                 } elsif ($class eq 'add') {
5121                         push @add, $line;
5122                 }
5123                 # context line
5124                 if ($class eq 'ctx') {
5125                         push @ctx, $line;
5126                 }
5127
5128                 $prev_class = $class;
5129         }
5130 }
5131
5132 sub git_patchset_body {
5133         my ($fd, $diff_style, $difftree, $hash, @hash_parents) = @_;
5134         my ($hash_parent) = $hash_parents[0];
5135
5136         my $is_combined = (@hash_parents > 1);
5137         my $patch_idx = 0;
5138         my $patch_number = 0;
5139         my $patch_line;
5140         my $diffinfo;
5141         my $to_name;
5142         my (%from, %to);
5143         my @chunk; # for side-by-side diff
5144
5145         print "<div class=\"patchset\">\n";
5146
5147         # skip to first patch
5148         while ($patch_line = <$fd>) {
5149                 chomp $patch_line;
5150
5151                 last if ($patch_line =~ m/^diff /);
5152         }
5153
5154  PATCH:
5155         while ($patch_line) {
5156
5157                 # parse "git diff" header line
5158                 if ($patch_line =~ m/^diff --git (\"(?:[^\\\"]*(?:\\.[^\\\"]*)*)\"|[^ "]*) (.*)$/) {
5159                         # $1 is from_name, which we do not use
5160                         $to_name = unquote($2);
5161                         $to_name =~ s!^b/!!;
5162                 } elsif ($patch_line =~ m/^diff --(cc|combined) ("?.*"?)$/) {
5163                         # $1 is 'cc' or 'combined', which we do not use
5164                         $to_name = unquote($2);
5165                 } else {
5166                         $to_name = undef;
5167                 }
5168
5169                 # check if current patch belong to current raw line
5170                 # and parse raw git-diff line if needed
5171                 if (is_patch_split($diffinfo, { 'to_file' => $to_name })) {
5172                         # this is continuation of a split patch
5173                         print "<div class=\"patch cont\">\n";
5174                 } else {
5175                         # advance raw git-diff output if needed
5176                         $patch_idx++ if defined $diffinfo;
5177
5178                         # read and prepare patch information
5179                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5180
5181                         # compact combined diff output can have some patches skipped
5182                         # find which patch (using pathname of result) we are at now;
5183                         if ($is_combined) {
5184                                 while ($to_name ne $diffinfo->{'to_file'}) {
5185                                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
5186                                               format_diff_cc_simplified($diffinfo, @hash_parents) .
5187                                               "</div>\n";  # class="patch"
5188
5189                                         $patch_idx++;
5190                                         $patch_number++;
5191
5192                                         last if $patch_idx > $#$difftree;
5193                                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5194                                 }
5195                         }
5196
5197                         # modifies %from, %to hashes
5198                         parse_from_to_diffinfo($diffinfo, \%from, \%to, @hash_parents);
5199
5200                         # this is first patch for raw difftree line with $patch_idx index
5201                         # we index @$difftree array from 0, but number patches from 1
5202                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n";
5203                 }
5204
5205                 # git diff header
5206                 #assert($patch_line =~ m/^diff /) if DEBUG;
5207                 #assert($patch_line !~ m!$/$!) if DEBUG; # is chomp-ed
5208                 $patch_number++;
5209                 # print "git diff" header
5210                 print format_git_diff_header_line($patch_line, $diffinfo,
5211                                                   \%from, \%to);
5212
5213                 # print extended diff header
5214                 print "<div class=\"diff extended_header\">\n";
5215         EXTENDED_HEADER:
5216                 while ($patch_line = <$fd>) {
5217                         chomp $patch_line;
5218
5219                         last EXTENDED_HEADER if ($patch_line =~ m/^--- |^diff /);
5220
5221                         print format_extended_diff_header_line($patch_line, $diffinfo,
5222                                                                \%from, \%to);
5223                 }
5224                 print "</div>\n"; # class="diff extended_header"
5225
5226                 # from-file/to-file diff header
5227                 if (! $patch_line) {
5228                         print "</div>\n"; # class="patch"
5229                         last PATCH;
5230                 }
5231                 next PATCH if ($patch_line =~ m/^diff /);
5232                 #assert($patch_line =~ m/^---/) if DEBUG;
5233
5234                 my $last_patch_line = $patch_line;
5235                 $patch_line = <$fd>;
5236                 chomp $patch_line;
5237                 #assert($patch_line =~ m/^\+\+\+/) if DEBUG;
5238
5239                 print format_diff_from_to_header($last_patch_line, $patch_line,
5240                                                  $diffinfo, \%from, \%to,
5241                                                  @hash_parents);
5242
5243                 # the patch itself
5244         LINE:
5245                 while ($patch_line = <$fd>) {
5246                         chomp $patch_line;
5247
5248                         next PATCH if ($patch_line =~ m/^diff /);
5249
5250                         my $class = diff_line_class($patch_line, \%from, \%to);
5251
5252                         if ($class eq 'chunk_header') {
5253                                 print_diff_chunk($diff_style, $is_combined, \%from, \%to, @chunk);
5254                                 @chunk = ();
5255                         }
5256
5257                         push @chunk, [ $class, $patch_line ];
5258                 }
5259
5260         } continue {
5261                 if (@chunk) {
5262                         print_diff_chunk($diff_style, $is_combined, \%from, \%to, @chunk);
5263                         @chunk = ();
5264                 }
5265                 print "</div>\n"; # class="patch"
5266         }
5267
5268         # for compact combined (--cc) format, with chunk and patch simplification
5269         # the patchset might be empty, but there might be unprocessed raw lines
5270         for (++$patch_idx if $patch_number > 0;
5271              $patch_idx < @$difftree;
5272              ++$patch_idx) {
5273                 # read and prepare patch information
5274                 $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5275
5276                 # generate anchor for "patch" links in difftree / whatchanged part
5277                 print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
5278                       format_diff_cc_simplified($diffinfo, @hash_parents) .
5279                       "</div>\n";  # class="patch"
5280
5281                 $patch_number++;
5282         }
5283
5284         if ($patch_number == 0) {
5285                 if (@hash_parents > 1) {
5286                         print "<div class=\"diff nodifferences\">Trivial merge</div>\n";
5287                 } else {
5288                         print "<div class=\"diff nodifferences\">No differences found</div>\n";
5289                 }
5290         }
5291
5292         print "</div>\n"; # class="patchset"
5293 }
5294
5295 # . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
5296
5297 sub git_project_search_form {
5298         my ($searchtext, $search_use_regexp) = @_;
5299
5300         my $limit = '';
5301         if ($project_filter) {
5302                 $limit = " in '$project_filter/'";
5303         }
5304
5305         print "<div class=\"projsearch\">\n";
5306         print $cgi->startform(-method => 'get', -action => $my_uri) .
5307               $cgi->hidden(-name => 'a', -value => 'project_list')  . "\n";
5308         print $cgi->hidden(-name => 'pf', -value => $project_filter). "\n"
5309                 if (defined $project_filter);
5310         print $cgi->textfield(-name => 's', -value => $searchtext,
5311                               -title => "Search project by name and description$limit",
5312                               -size => 60) . "\n" .
5313               "<span title=\"Extended regular expression\">" .
5314               $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
5315                              -checked => $search_use_regexp) .
5316               "</span>\n" .
5317               $cgi->submit(-name => 'btnS', -value => 'Search') .
5318               $cgi->end_form() . "\n" .
5319               $cgi->a({-href => href(project => undef, searchtext => undef,
5320                                      project_filter => $project_filter)},
5321                       esc_html("List all projects$limit")) . "<br />\n";
5322         print "</div>\n";
5323 }
5324
5325 # entry for given @keys needs filling if at least one of keys in list
5326 # is not present in %$project_info
5327 sub project_info_needs_filling {
5328         my ($project_info, @keys) = @_;
5329
5330         # return List::MoreUtils::any { !exists $project_info->{$_} } @keys;
5331         foreach my $key (@keys) {
5332                 if (!exists $project_info->{$key}) {
5333                         return 1;
5334                 }
5335         }
5336         return;
5337 }
5338
5339 # fills project list info (age, description, owner, category, forks, etc.)
5340 # for each project in the list, removing invalid projects from
5341 # returned list, or fill only specified info.
5342 #
5343 # Invalid projects are removed from the returned list if and only if you
5344 # ask 'age' or 'age_string' to be filled, because they are the only fields
5345 # that run unconditionally git command that requires repository, and
5346 # therefore do always check if project repository is invalid.
5347 #
5348 # USAGE:
5349 # * fill_project_list_info(\@project_list, 'descr_long', 'ctags')
5350 #   ensures that 'descr_long' and 'ctags' fields are filled
5351 # * @project_list = fill_project_list_info(\@project_list)
5352 #   ensures that all fields are filled (and invalid projects removed)
5353 #
5354 # NOTE: modifies $projlist, but does not remove entries from it
5355 sub fill_project_list_info {
5356         my ($projlist, @wanted_keys) = @_;
5357         my @projects;
5358         my $filter_set = sub { return @_; };
5359         if (@wanted_keys) {
5360                 my %wanted_keys = map { $_ => 1 } @wanted_keys;
5361                 $filter_set = sub { return grep { $wanted_keys{$_} } @_; };
5362         }
5363
5364         my $show_ctags = gitweb_check_feature('ctags');
5365  PROJECT:
5366         foreach my $pr (@$projlist) {
5367                 if (project_info_needs_filling($pr, $filter_set->('age', 'age_string'))) {
5368                         my (@activity) = git_get_last_activity($pr->{'path'});
5369                         unless (@activity) {
5370                                 next PROJECT;
5371                         }
5372                         ($pr->{'age'}, $pr->{'age_string'}) = @activity;
5373                 }
5374                 if (project_info_needs_filling($pr, $filter_set->('descr', 'descr_long'))) {
5375                         my $descr = git_get_project_description($pr->{'path'}) || "";
5376                         $descr = to_utf8($descr);
5377                         $pr->{'descr_long'} = $descr;
5378                         $pr->{'descr'} = chop_str($descr, $projects_list_description_width, 5);
5379                 }
5380                 if (project_info_needs_filling($pr, $filter_set->('owner'))) {
5381                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}") || "";
5382                 }
5383                 if ($show_ctags &&
5384                     project_info_needs_filling($pr, $filter_set->('ctags'))) {
5385                         $pr->{'ctags'} = git_get_project_ctags($pr->{'path'});
5386                 }
5387                 if ($projects_list_group_categories &&
5388                     project_info_needs_filling($pr, $filter_set->('category'))) {
5389                         my $cat = git_get_project_category($pr->{'path'}) ||
5390                                                            $project_list_default_category;
5391                         $pr->{'category'} = to_utf8($cat);
5392                 }
5393
5394                 push @projects, $pr;
5395         }
5396
5397         return @projects;
5398 }
5399
5400 sub sort_projects_list {
5401         my ($projlist, $order) = @_;
5402         my @projects;
5403
5404         my %order_info = (
5405                 project => { key => 'path', type => 'str' },
5406                 descr => { key => 'descr_long', type => 'str' },
5407                 owner => { key => 'owner', type => 'str' },
5408                 age => { key => 'age', type => 'num' }
5409         );
5410         my $oi = $order_info{$order};
5411         return @$projlist unless defined $oi;
5412         if ($oi->{'type'} eq 'str') {
5413                 @projects = sort {$a->{$oi->{'key'}} cmp $b->{$oi->{'key'}}} @$projlist;
5414         } else {
5415                 @projects = sort {$a->{$oi->{'key'}} <=> $b->{$oi->{'key'}}} @$projlist;
5416         }
5417
5418         return @projects;
5419 }
5420
5421 # returns a hash of categories, containing the list of project
5422 # belonging to each category
5423 sub build_projlist_by_category {
5424         my ($projlist, $from, $to) = @_;
5425         my %categories;
5426
5427         $from = 0 unless defined $from;
5428         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5429
5430         for (my $i = $from; $i <= $to; $i++) {
5431                 my $pr = $projlist->[$i];
5432                 push @{$categories{ $pr->{'category'} }}, $pr;
5433         }
5434
5435         return wantarray ? %categories : \%categories;
5436 }
5437
5438 # print 'sort by' <th> element, generating 'sort by $name' replay link
5439 # if that order is not selected
5440 sub print_sort_th {
5441         print format_sort_th(@_);
5442 }
5443
5444 sub format_sort_th {
5445         my ($name, $order, $header) = @_;
5446         my $sort_th = "";
5447         $header ||= ucfirst($name);
5448
5449         if ($order eq $name) {
5450                 $sort_th .= "<th>$header</th>\n";
5451         } else {
5452                 $sort_th .= "<th>" .
5453                             $cgi->a({-href => href(-replay=>1, order=>$name),
5454                                      -class => "header"}, $header) .
5455                             "</th>\n";
5456         }
5457
5458         return $sort_th;
5459 }
5460
5461 sub git_project_list_rows {
5462         my ($projlist, $from, $to, $check_forks) = @_;
5463
5464         $from = 0 unless defined $from;
5465         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5466
5467         my $alternate = 1;
5468         for (my $i = $from; $i <= $to; $i++) {
5469                 my $pr = $projlist->[$i];
5470
5471                 if ($alternate) {
5472                         print "<tr class=\"dark\">\n";
5473                 } else {
5474                         print "<tr class=\"light\">\n";
5475                 }
5476                 $alternate ^= 1;
5477
5478                 if ($check_forks) {
5479                         print "<td>";
5480                         if ($pr->{'forks'}) {
5481                                 my $nforks = scalar @{$pr->{'forks'}};
5482                                 if ($nforks > 0) {
5483                                         print $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks"),
5484                                                        -title => "$nforks forks"}, "+");
5485                                 } else {
5486                                         print $cgi->span({-title => "$nforks forks"}, "+");
5487                                 }
5488                         }
5489                         print "</td>\n";
5490                 }
5491                 print "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5492                                         -class => "list"},
5493                                        esc_html_match_hl($pr->{'path'}, $search_regexp)) .
5494                       "</td>\n" .
5495                       "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5496                                         -class => "list",
5497                                         -title => $pr->{'descr_long'}},
5498                                         $search_regexp
5499                                         ? esc_html_match_hl_chopped($pr->{'descr_long'},
5500                                                                     $pr->{'descr'}, $search_regexp)
5501                                         : esc_html($pr->{'descr'})) .
5502                       "</td>\n" .
5503                       "<td><i>" . chop_and_escape_str($pr->{'owner'}, 15) . "</i></td>\n";
5504                 print "<td class=\"". age_class($pr->{'age'}) . "\">" .
5505                       (defined $pr->{'age_string'} ? $pr->{'age_string'} : "No commits") . "</td>\n" .
5506                       "<td class=\"link\">" .
5507                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary")}, "summary")   . " | " .
5508                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"shortlog")}, "shortlog") . " | " .
5509                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"log")}, "log") . " | " .
5510                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"tree")}, "tree") .
5511                       ($pr->{'forks'} ? " | " . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "forks") : '') .
5512                       "</td>\n" .
5513                       "</tr>\n";
5514         }
5515 }
5516
5517 sub git_project_list_body {
5518         # actually uses global variable $project
5519         my ($projlist, $order, $from, $to, $extra, $no_header) = @_;
5520         my @projects = @$projlist;
5521
5522         my $check_forks = gitweb_check_feature('forks');
5523         my $show_ctags  = gitweb_check_feature('ctags');
5524         my $tagfilter = $show_ctags ? $input_params{'ctag'} : undef;
5525         $check_forks = undef
5526                 if ($tagfilter || $search_regexp);
5527
5528         # filtering out forks before filling info allows to do less work
5529         @projects = filter_forks_from_projects_list(\@projects)
5530                 if ($check_forks);
5531         # search_projects_list pre-fills required info
5532         @projects = search_projects_list(\@projects,
5533                                          'search_regexp' => $search_regexp,
5534                                          'tagfilter'  => $tagfilter)
5535                 if ($tagfilter || $search_regexp);
5536         # fill the rest
5537         @projects = fill_project_list_info(\@projects);
5538
5539         $order ||= $default_projects_order;
5540         $from = 0 unless defined $from;
5541         $to = $#projects if (!defined $to || $#projects < $to);
5542
5543         # short circuit
5544         if ($from > $to) {
5545                 print "<center>\n".
5546                       "<b>No such projects found</b><br />\n".
5547                       "Click ".$cgi->a({-href=>href(project=>undef)},"here")." to view all projects<br />\n".
5548                       "</center>\n<br />\n";
5549                 return;
5550         }
5551
5552         @projects = sort_projects_list(\@projects, $order);
5553
5554         if ($show_ctags) {
5555                 my $ctags = git_gather_all_ctags(\@projects);
5556                 my $cloud = git_populate_project_tagcloud($ctags);
5557                 print git_show_project_tagcloud($cloud, 64);
5558         }
5559
5560         print "<table class=\"project_list\">\n";
5561         unless ($no_header) {
5562                 print "<tr>\n";
5563                 if ($check_forks) {
5564                         print "<th></th>\n";
5565                 }
5566                 print_sort_th('project', $order, 'Project');
5567                 print_sort_th('descr', $order, 'Description');
5568                 print_sort_th('owner', $order, 'Owner');
5569                 print_sort_th('age', $order, 'Last Change');
5570                 print "<th></th>\n" . # for links
5571                       "</tr>\n";
5572         }
5573
5574         if ($projects_list_group_categories) {
5575                 # only display categories with projects in the $from-$to window
5576                 @projects = sort {$a->{'category'} cmp $b->{'category'}} @projects[$from..$to];
5577                 my %categories = build_projlist_by_category(\@projects, $from, $to);
5578                 foreach my $cat (sort keys %categories) {
5579                         unless ($cat eq "") {
5580                                 print "<tr>\n";
5581                                 if ($check_forks) {
5582                                         print "<td></td>\n";
5583                                 }
5584                                 print "<td class=\"category\" colspan=\"5\">".esc_html($cat)."</td>\n";
5585                                 print "</tr>\n";
5586                         }
5587
5588                         git_project_list_rows($categories{$cat}, undef, undef, $check_forks);
5589                 }
5590         } else {
5591                 git_project_list_rows(\@projects, $from, $to, $check_forks);
5592         }
5593
5594         if (defined $extra) {
5595                 print "<tr>\n";
5596                 if ($check_forks) {
5597                         print "<td></td>\n";
5598                 }
5599                 print "<td colspan=\"5\">$extra</td>\n" .
5600                       "</tr>\n";
5601         }
5602         print "</table>\n";
5603 }
5604
5605 sub git_log_body {
5606         # uses global variable $project
5607         my ($commitlist, $from, $to, $refs, $extra) = @_;
5608
5609         $from = 0 unless defined $from;
5610         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5611
5612         for (my $i = 0; $i <= $to; $i++) {
5613                 my %co = %{$commitlist->[$i]};
5614                 next if !%co;
5615                 my $commit = $co{'id'};
5616                 my $ref = format_ref_marker($refs, $commit);
5617                 git_print_header_div('commit',
5618                                "<span class=\"age\">$co{'age_string'}</span>" .
5619                                esc_html($co{'title'}) . $ref,
5620                                $commit);
5621                 print "<div class=\"title_text\">\n" .
5622                       "<div class=\"log_link\">\n" .
5623                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") .
5624                       " | " .
5625                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") .
5626                       " | " .
5627                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree") .
5628                       "<br/>\n" .
5629                       "</div>\n";
5630                       git_print_authorship(\%co, -tag => 'span');
5631                       print "<br/>\n</div>\n";
5632
5633                 print "<div class=\"log_body\">\n";
5634                 git_print_log($co{'comment'}, -final_empty_line=> 1);
5635                 print "</div>\n";
5636         }
5637         if ($extra) {
5638                 print "<div class=\"page_nav\">\n";
5639                 print "$extra\n";
5640                 print "</div>\n";
5641         }
5642 }
5643
5644 sub git_shortlog_body {
5645         # uses global variable $project
5646         my ($commitlist, $from, $to, $refs, $extra) = @_;
5647
5648         $from = 0 unless defined $from;
5649         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5650
5651         print "<table class=\"shortlog\">\n";
5652         my $alternate = 1;
5653         for (my $i = $from; $i <= $to; $i++) {
5654                 my %co = %{$commitlist->[$i]};
5655                 my $commit = $co{'id'};
5656                 my $ref = format_ref_marker($refs, $commit);
5657                 if ($alternate) {
5658                         print "<tr class=\"dark\">\n";
5659                 } else {
5660                         print "<tr class=\"light\">\n";
5661                 }
5662                 $alternate ^= 1;
5663                 # git_summary() used print "<td><i>$co{'age_string'}</i></td>\n" .
5664                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5665                       format_author_html('td', \%co, 10) . "<td>";
5666                 print format_subject_html($co{'title'}, $co{'title_short'},
5667                                           href(action=>"commit", hash=>$commit), $ref);
5668                 print "</td>\n" .
5669                       "<td class=\"link\">" .
5670                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") . " | " .
5671                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") . " | " .
5672                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree");
5673                 my $snapshot_links = format_snapshot_links($commit);
5674                 if (defined $snapshot_links) {
5675                         print " | " . $snapshot_links;
5676                 }
5677                 print "</td>\n" .
5678                       "</tr>\n";
5679         }
5680         if (defined $extra) {
5681                 print "<tr>\n" .
5682                       "<td colspan=\"4\">$extra</td>\n" .
5683                       "</tr>\n";
5684         }
5685         print "</table>\n";
5686 }
5687
5688 sub git_history_body {
5689         # Warning: assumes constant type (blob or tree) during history
5690         my ($commitlist, $from, $to, $refs, $extra,
5691             $file_name, $file_hash, $ftype) = @_;
5692
5693         $from = 0 unless defined $from;
5694         $to = $#{$commitlist} unless (defined $to && $to <= $#{$commitlist});
5695
5696         print "<table class=\"history\">\n";
5697         my $alternate = 1;
5698         for (my $i = $from; $i <= $to; $i++) {
5699                 my %co = %{$commitlist->[$i]};
5700                 if (!%co) {
5701                         next;
5702                 }
5703                 my $commit = $co{'id'};
5704
5705                 my $ref = format_ref_marker($refs, $commit);
5706
5707                 if ($alternate) {
5708                         print "<tr class=\"dark\">\n";
5709                 } else {
5710                         print "<tr class=\"light\">\n";
5711                 }
5712                 $alternate ^= 1;
5713                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5714         # shortlog:   format_author_html('td', \%co, 10)
5715                       format_author_html('td', \%co, 15, 3) . "<td>";
5716                 # originally git_history used chop_str($co{'title'}, 50)
5717                 print format_subject_html($co{'title'}, $co{'title_short'},
5718                                           href(action=>"commit", hash=>$commit), $ref);
5719                 print "</td>\n" .
5720                       "<td class=\"link\">" .
5721                       $cgi->a({-href => href(action=>$ftype, hash_base=>$commit, file_name=>$file_name)}, $ftype) . " | " .
5722                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff");
5723
5724                 if ($ftype eq 'blob') {
5725                         my $blob_current = $file_hash;
5726                         my $blob_parent  = git_get_hash_by_path($commit, $file_name);
5727                         if (defined $blob_current && defined $blob_parent &&
5728                                         $blob_current ne $blob_parent) {
5729                                 print " | " .
5730                                         $cgi->a({-href => href(action=>"blobdiff",
5731                                                                hash=>$blob_current, hash_parent=>$blob_parent,
5732                                                                hash_base=>$hash_base, hash_parent_base=>$commit,
5733                                                                file_name=>$file_name)},
5734                                                 "diff to current");
5735                         }
5736                 }
5737                 print "</td>\n" .
5738                       "</tr>\n";
5739         }
5740         if (defined $extra) {
5741                 print "<tr>\n" .
5742                       "<td colspan=\"4\">$extra</td>\n" .
5743                       "</tr>\n";
5744         }
5745         print "</table>\n";
5746 }
5747
5748 sub git_tags_body {
5749         # uses global variable $project
5750         my ($taglist, $from, $to, $extra) = @_;
5751         $from = 0 unless defined $from;
5752         $to = $#{$taglist} if (!defined $to || $#{$taglist} < $to);
5753
5754         print "<table class=\"tags\">\n";
5755         my $alternate = 1;
5756         for (my $i = $from; $i <= $to; $i++) {
5757                 my $entry = $taglist->[$i];
5758                 my %tag = %$entry;
5759                 my $comment = $tag{'subject'};
5760                 my $comment_short;
5761                 if (defined $comment) {
5762                         $comment_short = chop_str($comment, 30, 5);
5763                 }
5764                 if ($alternate) {
5765                         print "<tr class=\"dark\">\n";
5766                 } else {
5767                         print "<tr class=\"light\">\n";
5768                 }
5769                 $alternate ^= 1;
5770                 if (defined $tag{'age'}) {
5771                         print "<td><i>$tag{'age'}</i></td>\n";
5772                 } else {
5773                         print "<td></td>\n";
5774                 }
5775                 print "<td>" .
5776                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'}),
5777                                -class => "list name"}, esc_html($tag{'name'})) .
5778                       "</td>\n" .
5779                       "<td>";
5780                 if (defined $comment) {
5781                         print format_subject_html($comment, $comment_short,
5782                                                   href(action=>"tag", hash=>$tag{'id'}));
5783                 }
5784                 print "</td>\n" .
5785                       "<td class=\"selflink\">";
5786                 if ($tag{'type'} eq "tag") {
5787                         print $cgi->a({-href => href(action=>"tag", hash=>$tag{'id'})}, "tag");
5788                 } else {
5789                         print "&nbsp;";
5790                 }
5791                 print "</td>\n" .
5792                       "<td class=\"link\">" . " | " .
5793                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'})}, $tag{'reftype'});
5794                 if ($tag{'reftype'} eq "commit") {
5795                         print " | " . $cgi->a({-href => href(action=>"shortlog", hash=>$tag{'fullname'})}, "shortlog") .
5796                               " | " . $cgi->a({-href => href(action=>"log", hash=>$tag{'fullname'})}, "log");
5797                 } elsif ($tag{'reftype'} eq "blob") {
5798                         print " | " . $cgi->a({-href => href(action=>"blob_plain", hash=>$tag{'refid'})}, "raw");
5799                 }
5800                 print "</td>\n" .
5801                       "</tr>";
5802         }
5803         if (defined $extra) {
5804                 print "<tr>\n" .
5805                       "<td colspan=\"5\">$extra</td>\n" .
5806                       "</tr>\n";
5807         }
5808         print "</table>\n";
5809 }
5810
5811 sub git_heads_body {
5812         # uses global variable $project
5813         my ($headlist, $head_at, $from, $to, $extra) = @_;
5814         $from = 0 unless defined $from;
5815         $to = $#{$headlist} if (!defined $to || $#{$headlist} < $to);
5816
5817         print "<table class=\"heads\">\n";
5818         my $alternate = 1;
5819         for (my $i = $from; $i <= $to; $i++) {
5820                 my $entry = $headlist->[$i];
5821                 my %ref = %$entry;
5822                 my $curr = defined $head_at && $ref{'id'} eq $head_at;
5823                 if ($alternate) {
5824                         print "<tr class=\"dark\">\n";
5825                 } else {
5826                         print "<tr class=\"light\">\n";
5827                 }
5828                 $alternate ^= 1;
5829                 print "<td><i>$ref{'age'}</i></td>\n" .
5830                       ($curr ? "<td class=\"current_head\">" : "<td>") .
5831                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'}),
5832                                -class => "list name"},esc_html($ref{'name'})) .
5833                       "</td>\n" .
5834                       "<td class=\"link\">" .
5835                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'})}, "shortlog") . " | " .
5836                       $cgi->a({-href => href(action=>"log", hash=>$ref{'fullname'})}, "log") . " | " .
5837                       $cgi->a({-href => href(action=>"tree", hash=>$ref{'fullname'}, hash_base=>$ref{'fullname'})}, "tree") .
5838                       "</td>\n" .
5839                       "</tr>";
5840         }
5841         if (defined $extra) {
5842                 print "<tr>\n" .
5843                       "<td colspan=\"3\">$extra</td>\n" .
5844                       "</tr>\n";
5845         }
5846         print "</table>\n";
5847 }
5848
5849 # Display a single remote block
5850 sub git_remote_block {
5851         my ($remote, $rdata, $limit, $head) = @_;
5852
5853         my $heads = $rdata->{'heads'};
5854         my $fetch = $rdata->{'fetch'};
5855         my $push = $rdata->{'push'};
5856
5857         my $urls_table = "<table class=\"projects_list\">\n" ;
5858
5859         if (defined $fetch) {
5860                 if ($fetch eq $push) {
5861                         $urls_table .= format_repo_url("URL", $fetch);
5862                 } else {
5863                         $urls_table .= format_repo_url("Fetch URL", $fetch);
5864                         $urls_table .= format_repo_url("Push URL", $push) if defined $push;
5865                 }
5866         } elsif (defined $push) {
5867                 $urls_table .= format_repo_url("Push URL", $push);
5868         } else {
5869                 $urls_table .= format_repo_url("", "No remote URL");
5870         }
5871
5872         $urls_table .= "</table>\n";
5873
5874         my $dots;
5875         if (defined $limit && $limit < @$heads) {
5876                 $dots = $cgi->a({-href => href(action=>"remotes", hash=>$remote)}, "...");
5877         }
5878
5879         print $urls_table;
5880         git_heads_body($heads, $head, 0, $limit, $dots);
5881 }
5882
5883 # Display a list of remote names with the respective fetch and push URLs
5884 sub git_remotes_list {
5885         my ($remotedata, $limit) = @_;
5886         print "<table class=\"heads\">\n";
5887         my $alternate = 1;
5888         my @remotes = sort keys %$remotedata;
5889
5890         my $limited = $limit && $limit < @remotes;
5891
5892         $#remotes = $limit - 1 if $limited;
5893
5894         while (my $remote = shift @remotes) {
5895                 my $rdata = $remotedata->{$remote};
5896                 my $fetch = $rdata->{'fetch'};
5897                 my $push = $rdata->{'push'};
5898                 if ($alternate) {
5899                         print "<tr class=\"dark\">\n";
5900                 } else {
5901                         print "<tr class=\"light\">\n";
5902                 }
5903                 $alternate ^= 1;
5904                 print "<td>" .
5905                       $cgi->a({-href=> href(action=>'remotes', hash=>$remote),
5906                                -class=> "list name"},esc_html($remote)) .
5907                       "</td>";
5908                 print "<td class=\"link\">" .
5909                       (defined $fetch ? $cgi->a({-href=> $fetch}, "fetch") : "fetch") .
5910                       " | " .
5911                       (defined $push ? $cgi->a({-href=> $push}, "push") : "push") .
5912                       "</td>";
5913
5914                 print "</tr>\n";
5915         }
5916
5917         if ($limited) {
5918                 print "<tr>\n" .
5919                       "<td colspan=\"3\">" .
5920                       $cgi->a({-href => href(action=>"remotes")}, "...") .
5921                       "</td>\n" . "</tr>\n";
5922         }
5923
5924         print "</table>";
5925 }
5926
5927 # Display remote heads grouped by remote, unless there are too many
5928 # remotes, in which case we only display the remote names
5929 sub git_remotes_body {
5930         my ($remotedata, $limit, $head) = @_;
5931         if ($limit and $limit < keys %$remotedata) {
5932                 git_remotes_list($remotedata, $limit);
5933         } else {
5934                 fill_remote_heads($remotedata);
5935                 while (my ($remote, $rdata) = each %$remotedata) {
5936                         git_print_section({-class=>"remote", -id=>$remote},
5937                                 ["remotes", $remote, $remote], sub {
5938                                         git_remote_block($remote, $rdata, $limit, $head);
5939                                 });
5940                 }
5941         }
5942 }
5943
5944 sub git_search_message {
5945         my %co = @_;
5946
5947         my $greptype;
5948         if ($searchtype eq 'commit') {
5949                 $greptype = "--grep=";
5950         } elsif ($searchtype eq 'author') {
5951                 $greptype = "--author=";
5952         } elsif ($searchtype eq 'committer') {
5953                 $greptype = "--committer=";
5954         }
5955         $greptype .= $searchtext;
5956         my @commitlist = parse_commits($hash, 101, (100 * $page), undef,
5957                                        $greptype, '--regexp-ignore-case',
5958                                        $search_use_regexp ? '--extended-regexp' : '--fixed-strings');
5959
5960         my $paging_nav = '';
5961         if ($page > 0) {
5962                 $paging_nav .=
5963                         $cgi->a({-href => href(-replay=>1, page=>undef)},
5964                                 "first") .
5965                         " &sdot; " .
5966                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
5967                                  -accesskey => "p", -title => "Alt-p"}, "prev");
5968         } else {
5969                 $paging_nav .= "first &sdot; prev";
5970         }
5971         my $next_link = '';
5972         if ($#commitlist >= 100) {
5973                 $next_link =
5974                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
5975                                  -accesskey => "n", -title => "Alt-n"}, "next");
5976                 $paging_nav .= " &sdot; $next_link";
5977         } else {
5978                 $paging_nav .= " &sdot; next";
5979         }
5980
5981         git_header_html();
5982
5983         git_print_page_nav('','', $hash,$co{'tree'},$hash, $paging_nav);
5984         git_print_header_div('commit', esc_html($co{'title'}), $hash);
5985         if ($page == 0 && !@commitlist) {
5986                 print "<p>No match.</p>\n";
5987         } else {
5988                 git_search_grep_body(\@commitlist, 0, 99, $next_link);
5989         }
5990
5991         git_footer_html();
5992 }
5993
5994 sub git_search_changes {
5995         my %co = @_;
5996
5997         local $/ = "\n";
5998         open my $fd, '-|', git_cmd(), '--no-pager', 'log', @diff_opts,
5999                 '--pretty=format:%H', '--no-abbrev', '--raw', "-S$searchtext",
6000                 ($search_use_regexp ? '--pickaxe-regex' : ())
6001                         or die_error(500, "Open git-log failed");
6002
6003         git_header_html();
6004
6005         git_print_page_nav('','', $hash,$co{'tree'},$hash);
6006         git_print_header_div('commit', esc_html($co{'title'}), $hash);
6007
6008         print "<table class=\"pickaxe search\">\n";
6009         my $alternate = 1;
6010         undef %co;
6011         my @files;
6012         while (my $line = <$fd>) {
6013                 chomp $line;
6014                 next unless $line;
6015
6016                 my %set = parse_difftree_raw_line($line);
6017                 if (defined $set{'commit'}) {
6018                         # finish previous commit
6019                         if (%co) {
6020                                 print "</td>\n" .
6021                                       "<td class=\"link\">" .
6022                                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
6023                                               "commit") .
6024                                       " | " .
6025                                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
6026                                                              hash_base=>$co{'id'})},
6027                                               "tree") .
6028                                       "</td>\n" .
6029                                       "</tr>\n";
6030                         }
6031
6032                         if ($alternate) {
6033                                 print "<tr class=\"dark\">\n";
6034                         } else {
6035                                 print "<tr class=\"light\">\n";
6036                         }
6037                         $alternate ^= 1;
6038                         %co = parse_commit($set{'commit'});
6039                         my $author = chop_and_escape_str($co{'author_name'}, 15, 5);
6040                         print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6041                               "<td><i>$author</i></td>\n" .
6042                               "<td>" .
6043                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
6044                                       -class => "list subject"},
6045                                       chop_and_escape_str($co{'title'}, 50) . "<br/>");
6046                 } elsif (defined $set{'to_id'}) {
6047                         next if ($set{'to_id'} =~ m/^0{40}$/);
6048
6049                         print $cgi->a({-href => href(action=>"blob", hash_base=>$co{'id'},
6050                                                      hash=>$set{'to_id'}, file_name=>$set{'to_file'}),
6051                                       -class => "list"},
6052                                       "<span class=\"match\">" . esc_path($set{'file'}) . "</span>") .
6053                               "<br/>\n";
6054                 }
6055         }
6056         close $fd;
6057
6058         # finish last commit (warning: repetition!)
6059         if (%co) {
6060                 print "</td>\n" .
6061                       "<td class=\"link\">" .
6062                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
6063                               "commit") .
6064                       " | " .
6065                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
6066                                              hash_base=>$co{'id'})},
6067                               "tree") .
6068                       "</td>\n" .
6069                       "</tr>\n";
6070         }
6071
6072         print "</table>\n";
6073
6074         git_footer_html();
6075 }
6076
6077 sub git_search_files {
6078         my %co = @_;
6079
6080         local $/ = "\n";
6081         open my $fd, "-|", git_cmd(), 'grep', '-n', '-z',
6082                 $search_use_regexp ? ('-E', '-i') : '-F',
6083                 $searchtext, $co{'tree'}
6084                         or die_error(500, "Open git-grep failed");
6085
6086         git_header_html();
6087
6088         git_print_page_nav('','', $hash,$co{'tree'},$hash);
6089         git_print_header_div('commit', esc_html($co{'title'}), $hash);
6090
6091         print "<table class=\"grep_search\">\n";
6092         my $alternate = 1;
6093         my $matches = 0;
6094         my $lastfile = '';
6095         my $file_href;
6096         while (my $line = <$fd>) {
6097                 chomp $line;
6098                 my ($file, $lno, $ltext, $binary);
6099                 last if ($matches++ > 1000);
6100                 if ($line =~ /^Binary file (.+) matches$/) {
6101                         $file = $1;
6102                         $binary = 1;
6103                 } else {
6104                         ($file, $lno, $ltext) = split(/\0/, $line, 3);
6105                         $file =~ s/^$co{'tree'}://;
6106                 }
6107                 if ($file ne $lastfile) {
6108                         $lastfile and print "</td></tr>\n";
6109                         if ($alternate++) {
6110                                 print "<tr class=\"dark\">\n";
6111                         } else {
6112                                 print "<tr class=\"light\">\n";
6113                         }
6114                         $file_href = href(action=>"blob", hash_base=>$co{'id'},
6115                                           file_name=>$file);
6116                         print "<td class=\"list\">".
6117                                 $cgi->a({-href => $file_href, -class => "list"}, esc_path($file));
6118                         print "</td><td>\n";
6119                         $lastfile = $file;
6120                 }
6121                 if ($binary) {
6122                         print "<div class=\"binary\">Binary file</div>\n";
6123                 } else {
6124                         $ltext = untabify($ltext);
6125                         if ($ltext =~ m/^(.*)($search_regexp)(.*)$/i) {
6126                                 $ltext = esc_html($1, -nbsp=>1);
6127                                 $ltext .= '<span class="match">';
6128                                 $ltext .= esc_html($2, -nbsp=>1);
6129                                 $ltext .= '</span>';
6130                                 $ltext .= esc_html($3, -nbsp=>1);
6131                         } else {
6132                                 $ltext = esc_html($ltext, -nbsp=>1);
6133                         }
6134                         print "<div class=\"pre\">" .
6135                                 $cgi->a({-href => $file_href.'#l'.$lno,
6136                                         -class => "linenr"}, sprintf('%4i', $lno)) .
6137                                 ' ' .  $ltext . "</div>\n";
6138                 }
6139         }
6140         if ($lastfile) {
6141                 print "</td></tr>\n";
6142                 if ($matches > 1000) {
6143                         print "<div class=\"diff nodifferences\">Too many matches, listing trimmed</div>\n";
6144                 }
6145         } else {
6146                 print "<div class=\"diff nodifferences\">No matches found</div>\n";
6147         }
6148         close $fd;
6149
6150         print "</table>\n";
6151
6152         git_footer_html();
6153 }
6154
6155 sub git_search_grep_body {
6156         my ($commitlist, $from, $to, $extra) = @_;
6157         $from = 0 unless defined $from;
6158         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
6159
6160         print "<table class=\"commit_search\">\n";
6161         my $alternate = 1;
6162         for (my $i = $from; $i <= $to; $i++) {
6163                 my %co = %{$commitlist->[$i]};
6164                 if (!%co) {
6165                         next;
6166                 }
6167                 my $commit = $co{'id'};
6168                 if ($alternate) {
6169                         print "<tr class=\"dark\">\n";
6170                 } else {
6171                         print "<tr class=\"light\">\n";
6172                 }
6173                 $alternate ^= 1;
6174                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6175                       format_author_html('td', \%co, 15, 5) .
6176                       "<td>" .
6177                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
6178                                -class => "list subject"},
6179                               chop_and_escape_str($co{'title'}, 50) . "<br/>");
6180                 my $comment = $co{'comment'};
6181                 foreach my $line (@$comment) {
6182                         if ($line =~ m/^(.*?)($search_regexp)(.*)$/i) {
6183                                 my ($lead, $match, $trail) = ($1, $2, $3);
6184                                 $match = chop_str($match, 70, 5, 'center');
6185                                 my $contextlen = int((80 - length($match))/2);
6186                                 $contextlen = 30 if ($contextlen > 30);
6187                                 $lead  = chop_str($lead,  $contextlen, 10, 'left');
6188                                 $trail = chop_str($trail, $contextlen, 10, 'right');
6189
6190                                 $lead  = esc_html($lead);
6191                                 $match = esc_html($match);
6192                                 $trail = esc_html($trail);
6193
6194                                 print "$lead<span class=\"match\">$match</span>$trail<br />";
6195                         }
6196                 }
6197                 print "</td>\n" .
6198                       "<td class=\"link\">" .
6199                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
6200                       " | " .
6201                       $cgi->a({-href => href(action=>"commitdiff", hash=>$co{'id'})}, "commitdiff") .
6202                       " | " .
6203                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
6204                 print "</td>\n" .
6205                       "</tr>\n";
6206         }
6207         if (defined $extra) {
6208                 print "<tr>\n" .
6209                       "<td colspan=\"3\">$extra</td>\n" .
6210                       "</tr>\n";
6211         }
6212         print "</table>\n";
6213 }
6214
6215 ## ======================================================================
6216 ## ======================================================================
6217 ## actions
6218
6219 sub git_project_list {
6220         my $order = $input_params{'order'};
6221         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
6222                 die_error(400, "Unknown order parameter");
6223         }
6224
6225         my @list = git_get_projects_list($project_filter, $strict_export);
6226         if (!@list) {
6227                 die_error(404, "No projects found");
6228         }
6229
6230         git_header_html();
6231         if (defined $home_text && -f $home_text) {
6232                 print "<div class=\"index_include\">\n";
6233                 insert_file($home_text);
6234                 print "</div>\n";
6235         }
6236
6237         git_project_search_form($searchtext, $search_use_regexp);
6238         git_project_list_body(\@list, $order);
6239         git_footer_html();
6240 }
6241
6242 sub git_forks {
6243         my $order = $input_params{'order'};
6244         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
6245                 die_error(400, "Unknown order parameter");
6246         }
6247
6248         my $filter = $project;
6249         $filter =~ s/\.git$//;
6250         my @list = git_get_projects_list($filter);
6251         if (!@list) {
6252                 die_error(404, "No forks found");
6253         }
6254
6255         git_header_html();
6256         git_print_page_nav('','');
6257         git_print_header_div('summary', "$project forks");
6258         git_project_list_body(\@list, $order);
6259         git_footer_html();
6260 }
6261
6262 sub git_project_index {
6263         my @projects = git_get_projects_list($project_filter, $strict_export);
6264         if (!@projects) {
6265                 die_error(404, "No projects found");
6266         }
6267
6268         print $cgi->header(
6269                 -type => 'text/plain',
6270                 -charset => 'utf-8',
6271                 -content_disposition => 'inline; filename="index.aux"');
6272
6273         foreach my $pr (@projects) {
6274                 if (!exists $pr->{'owner'}) {
6275                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}");
6276                 }
6277
6278                 my ($path, $owner) = ($pr->{'path'}, $pr->{'owner'});
6279                 # quote as in CGI::Util::encode, but keep the slash, and use '+' for ' '
6280                 $path  =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
6281                 $owner =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
6282                 $path  =~ s/ /\+/g;
6283                 $owner =~ s/ /\+/g;
6284
6285                 print "$path $owner\n";
6286         }
6287 }
6288
6289 sub git_summary {
6290         my $descr = git_get_project_description($project) || "none";
6291         my %co = parse_commit("HEAD");
6292         my %cd = %co ? parse_date($co{'committer_epoch'}, $co{'committer_tz'}) : ();
6293         my $head = $co{'id'};
6294         my $remote_heads = gitweb_check_feature('remote_heads');
6295
6296         my $owner = git_get_project_owner($project);
6297
6298         my $refs = git_get_references();
6299         # These get_*_list functions return one more to allow us to see if
6300         # there are more ...
6301         my @taglist  = git_get_tags_list(16);
6302         my @headlist = git_get_heads_list(16);
6303         my %remotedata = $remote_heads ? git_get_remotes_list() : ();
6304         my @forklist;
6305         my $check_forks = gitweb_check_feature('forks');
6306
6307         if ($check_forks) {
6308                 # find forks of a project
6309                 my $filter = $project;
6310                 $filter =~ s/\.git$//;
6311                 @forklist = git_get_projects_list($filter);
6312                 # filter out forks of forks
6313                 @forklist = filter_forks_from_projects_list(\@forklist)
6314                         if (@forklist);
6315         }
6316
6317         git_header_html();
6318         git_print_page_nav('summary','', $head);
6319
6320         print "<div class=\"title\">&nbsp;</div>\n";
6321         print "<table class=\"projects_list\">\n" .
6322               "<tr id=\"metadata_desc\"><td>description</td><td>" . esc_html($descr) . "</td></tr>\n" .
6323               "<tr id=\"metadata_owner\"><td>owner</td><td>" . esc_html($owner) . "</td></tr>\n";
6324         if (defined $cd{'rfc2822'}) {
6325                 print "<tr id=\"metadata_lchange\"><td>last change</td>" .
6326                       "<td>".format_timestamp_html(\%cd)."</td></tr>\n";
6327         }
6328
6329         # use per project git URL list in $projectroot/$project/cloneurl
6330         # or make project git URL from git base URL and project name
6331         my $url_tag = "URL";
6332         my @url_list = git_get_project_url_list($project);
6333         @url_list = map { "$_/$project" } @git_base_url_list unless @url_list;
6334         foreach my $git_url (@url_list) {
6335                 next unless $git_url;
6336                 print format_repo_url($url_tag, $git_url);
6337                 $url_tag = "";
6338         }
6339
6340         # Tag cloud
6341         my $show_ctags = gitweb_check_feature('ctags');
6342         if ($show_ctags) {
6343                 my $ctags = git_get_project_ctags($project);
6344                 if (%$ctags) {
6345                         # without ability to add tags, don't show if there are none
6346                         my $cloud = git_populate_project_tagcloud($ctags);
6347                         print "<tr id=\"metadata_ctags\">" .
6348                               "<td>content tags</td>" .
6349                               "<td>".git_show_project_tagcloud($cloud, 48)."</td>" .
6350                               "</tr>\n";
6351                 }
6352         }
6353
6354         print "</table>\n";
6355
6356         # If XSS prevention is on, we don't include README.html.
6357         # TODO: Allow a readme in some safe format.
6358         if (!$prevent_xss && -s "$projectroot/$project/README.html") {
6359                 print "<div class=\"title\">readme</div>\n" .
6360                       "<div class=\"readme\">\n";
6361                 insert_file("$projectroot/$project/README.html");
6362                 print "\n</div>\n"; # class="readme"
6363         }
6364
6365         # we need to request one more than 16 (0..15) to check if
6366         # those 16 are all
6367         my @commitlist = $head ? parse_commits($head, 17) : ();
6368         if (@commitlist) {
6369                 git_print_header_div('shortlog');
6370                 git_shortlog_body(\@commitlist, 0, 15, $refs,
6371                                   $#commitlist <=  15 ? undef :
6372                                   $cgi->a({-href => href(action=>"shortlog")}, "..."));
6373         }
6374
6375         if (@taglist) {
6376                 git_print_header_div('tags');
6377                 git_tags_body(\@taglist, 0, 15,
6378                               $#taglist <=  15 ? undef :
6379                               $cgi->a({-href => href(action=>"tags")}, "..."));
6380         }
6381
6382         if (@headlist) {
6383                 git_print_header_div('heads');
6384                 git_heads_body(\@headlist, $head, 0, 15,
6385                                $#headlist <= 15 ? undef :
6386                                $cgi->a({-href => href(action=>"heads")}, "..."));
6387         }
6388
6389         if (%remotedata) {
6390                 git_print_header_div('remotes');
6391                 git_remotes_body(\%remotedata, 15, $head);
6392         }
6393
6394         if (@forklist) {
6395                 git_print_header_div('forks');
6396                 git_project_list_body(\@forklist, 'age', 0, 15,
6397                                       $#forklist <= 15 ? undef :
6398                                       $cgi->a({-href => href(action=>"forks")}, "..."),
6399                                       'no_header');
6400         }
6401
6402         git_footer_html();
6403 }
6404
6405 sub git_tag {
6406         my %tag = parse_tag($hash);
6407
6408         if (! %tag) {
6409                 die_error(404, "Unknown tag object");
6410         }
6411
6412         my $head = git_get_head_hash($project);
6413         git_header_html();
6414         git_print_page_nav('','', $head,undef,$head);
6415         git_print_header_div('commit', esc_html($tag{'name'}), $hash);
6416         print "<div class=\"title_text\">\n" .
6417               "<table class=\"object_header\">\n" .
6418               "<tr>\n" .
6419               "<td>object</td>\n" .
6420               "<td>" . $cgi->a({-class => "list", -href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6421                                $tag{'object'}) . "</td>\n" .
6422               "<td class=\"link\">" . $cgi->a({-href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6423                                               $tag{'type'}) . "</td>\n" .
6424               "</tr>\n";
6425         if (defined($tag{'author'})) {
6426                 git_print_authorship_rows(\%tag, 'author');
6427         }
6428         print "</table>\n\n" .
6429               "</div>\n";
6430         print "<div class=\"page_body\">";
6431         my $comment = $tag{'comment'};
6432         foreach my $line (@$comment) {
6433                 chomp $line;
6434                 print esc_html($line, -nbsp=>1) . "<br/>\n";
6435         }
6436         print "</div>\n";
6437         git_footer_html();
6438 }
6439
6440 sub git_blame_common {
6441         my $format = shift || 'porcelain';
6442         if ($format eq 'porcelain' && $input_params{'javascript'}) {
6443                 $format = 'incremental';
6444                 $action = 'blame_incremental'; # for page title etc
6445         }
6446
6447         # permissions
6448         gitweb_check_feature('blame')
6449                 or die_error(403, "Blame view not allowed");
6450
6451         # error checking
6452         die_error(400, "No file name given") unless $file_name;
6453         $hash_base ||= git_get_head_hash($project);
6454         die_error(404, "Couldn't find base commit") unless $hash_base;
6455         my %co = parse_commit($hash_base)
6456                 or die_error(404, "Commit not found");
6457         my $ftype = "blob";
6458         if (!defined $hash) {
6459                 $hash = git_get_hash_by_path($hash_base, $file_name, "blob")
6460                         or die_error(404, "Error looking up file");
6461         } else {
6462                 $ftype = git_get_type($hash);
6463                 if ($ftype !~ "blob") {
6464                         die_error(400, "Object is not a blob");
6465                 }
6466         }
6467
6468         my $fd;
6469         if ($format eq 'incremental') {
6470                 # get file contents (as base)
6471                 open $fd, "-|", git_cmd(), 'cat-file', 'blob', $hash
6472                         or die_error(500, "Open git-cat-file failed");
6473         } elsif ($format eq 'data') {
6474                 # run git-blame --incremental
6475                 open $fd, "-|", git_cmd(), "blame", "--incremental",
6476                         $hash_base, "--", $file_name
6477                         or die_error(500, "Open git-blame --incremental failed");
6478         } else {
6479                 # run git-blame --porcelain
6480                 open $fd, "-|", git_cmd(), "blame", '-p',
6481                         $hash_base, '--', $file_name
6482                         or die_error(500, "Open git-blame --porcelain failed");
6483         }
6484
6485         # incremental blame data returns early
6486         if ($format eq 'data') {
6487                 print $cgi->header(
6488                         -type=>"text/plain", -charset => "utf-8",
6489                         -status=> "200 OK");
6490                 local $| = 1; # output autoflush
6491                 while (my $line = <$fd>) {
6492                         print to_utf8($line);
6493                 }
6494                 close $fd
6495                         or print "ERROR $!\n";
6496
6497                 print 'END';
6498                 if (defined $t0 && gitweb_check_feature('timed')) {
6499                         print ' '.
6500                               tv_interval($t0, [ gettimeofday() ]).
6501                               ' '.$number_of_git_cmds;
6502                 }
6503                 print "\n";
6504
6505                 return;
6506         }
6507
6508         # page header
6509         git_header_html();
6510         my $formats_nav =
6511                 $cgi->a({-href => href(action=>"blob", -replay=>1)},
6512                         "blob") .
6513                 " | ";
6514         if ($format eq 'incremental') {
6515                 $formats_nav .=
6516                         $cgi->a({-href => href(action=>"blame", javascript=>0, -replay=>1)},
6517                                 "blame") . " (non-incremental)";
6518         } else {
6519                 $formats_nav .=
6520                         $cgi->a({-href => href(action=>"blame_incremental", -replay=>1)},
6521                                 "blame") . " (incremental)";
6522         }
6523         $formats_nav .=
6524                 " | " .
6525                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6526                         "history") .
6527                 " | " .
6528                 $cgi->a({-href => href(action=>$action, file_name=>$file_name)},
6529                         "HEAD");
6530         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6531         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6532         git_print_page_path($file_name, $ftype, $hash_base);
6533
6534         # page body
6535         if ($format eq 'incremental') {
6536                 print "<noscript>\n<div class=\"error\"><center><b>\n".
6537                       "This page requires JavaScript to run.\n Use ".
6538                       $cgi->a({-href => href(action=>'blame',javascript=>0,-replay=>1)},
6539                               'this page').
6540                       " instead.\n".
6541                       "</b></center></div>\n</noscript>\n";
6542
6543                 print qq!<div id="progress_bar" style="width: 100%; background-color: yellow"></div>\n!;
6544         }
6545
6546         print qq!<div class="page_body">\n!;
6547         print qq!<div id="progress_info">... / ...</div>\n!
6548                 if ($format eq 'incremental');
6549         print qq!<table id="blame_table" class="blame" width="100%">\n!.
6550               #qq!<col width="5.5em" /><col width="2.5em" /><col width="*" />\n!.
6551               qq!<thead>\n!.
6552               qq!<tr><th>Commit</th><th>Line</th><th>Data</th></tr>\n!.
6553               qq!</thead>\n!.
6554               qq!<tbody>\n!;
6555
6556         my @rev_color = qw(light dark);
6557         my $num_colors = scalar(@rev_color);
6558         my $current_color = 0;
6559
6560         if ($format eq 'incremental') {
6561                 my $color_class = $rev_color[$current_color];
6562
6563                 #contents of a file
6564                 my $linenr = 0;
6565         LINE:
6566                 while (my $line = <$fd>) {
6567                         chomp $line;
6568                         $linenr++;
6569
6570                         print qq!<tr id="l$linenr" class="$color_class">!.
6571                               qq!<td class="sha1"><a href=""> </a></td>!.
6572                               qq!<td class="linenr">!.
6573                               qq!<a class="linenr" href="">$linenr</a></td>!;
6574                         print qq!<td class="pre">! . esc_html($line) . "</td>\n";
6575                         print qq!</tr>\n!;
6576                 }
6577
6578         } else { # porcelain, i.e. ordinary blame
6579                 my %metainfo = (); # saves information about commits
6580
6581                 # blame data
6582         LINE:
6583                 while (my $line = <$fd>) {
6584                         chomp $line;
6585                         # the header: <SHA-1> <src lineno> <dst lineno> [<lines in group>]
6586                         # no <lines in group> for subsequent lines in group of lines
6587                         my ($full_rev, $orig_lineno, $lineno, $group_size) =
6588                            ($line =~ /^([0-9a-f]{40}) (\d+) (\d+)(?: (\d+))?$/);
6589                         if (!exists $metainfo{$full_rev}) {
6590                                 $metainfo{$full_rev} = { 'nprevious' => 0 };
6591                         }
6592                         my $meta = $metainfo{$full_rev};
6593                         my $data;
6594                         while ($data = <$fd>) {
6595                                 chomp $data;
6596                                 last if ($data =~ s/^\t//); # contents of line
6597                                 if ($data =~ /^(\S+)(?: (.*))?$/) {
6598                                         $meta->{$1} = $2 unless exists $meta->{$1};
6599                                 }
6600                                 if ($data =~ /^previous /) {
6601                                         $meta->{'nprevious'}++;
6602                                 }
6603                         }
6604                         my $short_rev = substr($full_rev, 0, 8);
6605                         my $author = $meta->{'author'};
6606                         my %date =
6607                                 parse_date($meta->{'author-time'}, $meta->{'author-tz'});
6608                         my $date = $date{'iso-tz'};
6609                         if ($group_size) {
6610                                 $current_color = ($current_color + 1) % $num_colors;
6611                         }
6612                         my $tr_class = $rev_color[$current_color];
6613                         $tr_class .= ' boundary' if (exists $meta->{'boundary'});
6614                         $tr_class .= ' no-previous' if ($meta->{'nprevious'} == 0);
6615                         $tr_class .= ' multiple-previous' if ($meta->{'nprevious'} > 1);
6616                         print "<tr id=\"l$lineno\" class=\"$tr_class\">\n";
6617                         if ($group_size) {
6618                                 print "<td class=\"sha1\"";
6619                                 print " title=\"". esc_html($author) . ", $date\"";
6620                                 print " rowspan=\"$group_size\"" if ($group_size > 1);
6621                                 print ">";
6622                                 print $cgi->a({-href => href(action=>"commit",
6623                                                              hash=>$full_rev,
6624                                                              file_name=>$file_name)},
6625                                               esc_html($short_rev));
6626                                 if ($group_size >= 2) {
6627                                         my @author_initials = ($author =~ /\b([[:upper:]])\B/g);
6628                                         if (@author_initials) {
6629                                                 print "<br />" .
6630                                                       esc_html(join('', @author_initials));
6631                                                 #           or join('.', ...)
6632                                         }
6633                                 }
6634                                 print "</td>\n";
6635                         }
6636                         # 'previous' <sha1 of parent commit> <filename at commit>
6637                         if (exists $meta->{'previous'} &&
6638                             $meta->{'previous'} =~ /^([a-fA-F0-9]{40}) (.*)$/) {
6639                                 $meta->{'parent'} = $1;
6640                                 $meta->{'file_parent'} = unquote($2);
6641                         }
6642                         my $linenr_commit =
6643                                 exists($meta->{'parent'}) ?
6644                                 $meta->{'parent'} : $full_rev;
6645                         my $linenr_filename =
6646                                 exists($meta->{'file_parent'}) ?
6647                                 $meta->{'file_parent'} : unquote($meta->{'filename'});
6648                         my $blamed = href(action => 'blame',
6649                                           file_name => $linenr_filename,
6650                                           hash_base => $linenr_commit);
6651                         print "<td class=\"linenr\">";
6652                         print $cgi->a({ -href => "$blamed#l$orig_lineno",
6653                                         -class => "linenr" },
6654                                       esc_html($lineno));
6655                         print "</td>";
6656                         print "<td class=\"pre\">" . esc_html($data) . "</td>\n";
6657                         print "</tr>\n";
6658                 } # end while
6659
6660         }
6661
6662         # footer
6663         print "</tbody>\n".
6664               "</table>\n"; # class="blame"
6665         print "</div>\n";   # class="blame_body"
6666         close $fd
6667                 or print "Reading blob failed\n";
6668
6669         git_footer_html();
6670 }
6671
6672 sub git_blame {
6673         git_blame_common();
6674 }
6675
6676 sub git_blame_incremental {
6677         git_blame_common('incremental');
6678 }
6679
6680 sub git_blame_data {
6681         git_blame_common('data');
6682 }
6683
6684 sub git_tags {
6685         my $head = git_get_head_hash($project);
6686         git_header_html();
6687         git_print_page_nav('','', $head,undef,$head,format_ref_views('tags'));
6688         git_print_header_div('summary', $project);
6689
6690         my @tagslist = git_get_tags_list();
6691         if (@tagslist) {
6692                 git_tags_body(\@tagslist);
6693         }
6694         git_footer_html();
6695 }
6696
6697 sub git_heads {
6698         my $head = git_get_head_hash($project);
6699         git_header_html();
6700         git_print_page_nav('','', $head,undef,$head,format_ref_views('heads'));
6701         git_print_header_div('summary', $project);
6702
6703         my @headslist = git_get_heads_list();
6704         if (@headslist) {
6705                 git_heads_body(\@headslist, $head);
6706         }
6707         git_footer_html();
6708 }
6709
6710 # used both for single remote view and for list of all the remotes
6711 sub git_remotes {
6712         gitweb_check_feature('remote_heads')
6713                 or die_error(403, "Remote heads view is disabled");
6714
6715         my $head = git_get_head_hash($project);
6716         my $remote = $input_params{'hash'};
6717
6718         my $remotedata = git_get_remotes_list($remote);
6719         die_error(500, "Unable to get remote information") unless defined $remotedata;
6720
6721         unless (%$remotedata) {
6722                 die_error(404, defined $remote ?
6723                         "Remote $remote not found" :
6724                         "No remotes found");
6725         }
6726
6727         git_header_html(undef, undef, -action_extra => $remote);
6728         git_print_page_nav('', '',  $head, undef, $head,
6729                 format_ref_views($remote ? '' : 'remotes'));
6730
6731         fill_remote_heads($remotedata);
6732         if (defined $remote) {
6733                 git_print_header_div('remotes', "$remote remote for $project");
6734                 git_remote_block($remote, $remotedata->{$remote}, undef, $head);
6735         } else {
6736                 git_print_header_div('summary', "$project remotes");
6737                 git_remotes_body($remotedata, undef, $head);
6738         }
6739
6740         git_footer_html();
6741 }
6742
6743 sub git_blob_plain {
6744         my $type = shift;
6745         my $expires;
6746
6747         if (!defined $hash) {
6748                 if (defined $file_name) {
6749                         my $base = $hash_base || git_get_head_hash($project);
6750                         $hash = git_get_hash_by_path($base, $file_name, "blob")
6751                                 or die_error(404, "Cannot find file");
6752                 } else {
6753                         die_error(400, "No file name defined");
6754                 }
6755         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6756                 # blobs defined by non-textual hash id's can be cached
6757                 $expires = "+1d";
6758         }
6759
6760         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
6761                 or die_error(500, "Open git-cat-file blob '$hash' failed");
6762
6763         # content-type (can include charset)
6764         $type = blob_contenttype($fd, $file_name, $type);
6765
6766         # "save as" filename, even when no $file_name is given
6767         my $save_as = "$hash";
6768         if (defined $file_name) {
6769                 $save_as = $file_name;
6770         } elsif ($type =~ m/^text\//) {
6771                 $save_as .= '.txt';
6772         }
6773
6774         # With XSS prevention on, blobs of all types except a few known safe
6775         # ones are served with "Content-Disposition: attachment" to make sure
6776         # they don't run in our security domain.  For certain image types,
6777         # blob view writes an <img> tag referring to blob_plain view, and we
6778         # want to be sure not to break that by serving the image as an
6779         # attachment (though Firefox 3 doesn't seem to care).
6780         my $sandbox = $prevent_xss &&
6781                 $type !~ m!^(?:text/[a-z]+|image/(?:gif|png|jpeg))(?:[ ;]|$)!;
6782
6783         # serve text/* as text/plain
6784         if ($prevent_xss &&
6785             ($type =~ m!^text/[a-z]+\b(.*)$! ||
6786              ($type =~ m!^[a-z]+/[a-z]\+xml\b(.*)$! && -T $fd))) {
6787                 my $rest = $1;
6788                 $rest = defined $rest ? $rest : '';
6789                 $type = "text/plain$rest";
6790         }
6791
6792         print $cgi->header(
6793                 -type => $type,
6794                 -expires => $expires,
6795                 -content_disposition =>
6796                         ($sandbox ? 'attachment' : 'inline')
6797                         . '; filename="' . $save_as . '"');
6798         local $/ = undef;
6799         binmode STDOUT, ':raw';
6800         print <$fd>;
6801         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
6802         close $fd;
6803 }
6804
6805 sub git_blob {
6806         my $expires;
6807
6808         if (!defined $hash) {
6809                 if (defined $file_name) {
6810                         my $base = $hash_base || git_get_head_hash($project);
6811                         $hash = git_get_hash_by_path($base, $file_name, "blob")
6812                                 or die_error(404, "Cannot find file");
6813                 } else {
6814                         die_error(400, "No file name defined");
6815                 }
6816         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6817                 # blobs defined by non-textual hash id's can be cached
6818                 $expires = "+1d";
6819         }
6820
6821         my $have_blame = gitweb_check_feature('blame');
6822         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
6823                 or die_error(500, "Couldn't cat $file_name, $hash");
6824         my $mimetype = blob_mimetype($fd, $file_name);
6825         # use 'blob_plain' (aka 'raw') view for files that cannot be displayed
6826         if ($mimetype !~ m!^(?:text/|image/(?:gif|png|jpeg)$)! && -B $fd) {
6827                 close $fd;
6828                 return git_blob_plain($mimetype);
6829         }
6830         # we can have blame only for text/* mimetype
6831         $have_blame &&= ($mimetype =~ m!^text/!);
6832
6833         my $highlight = gitweb_check_feature('highlight');
6834         my $syntax = guess_file_syntax($highlight, $mimetype, $file_name);
6835         $fd = run_highlighter($fd, $highlight, $syntax)
6836                 if $syntax;
6837
6838         git_header_html(undef, $expires);
6839         my $formats_nav = '';
6840         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
6841                 if (defined $file_name) {
6842                         if ($have_blame) {
6843                                 $formats_nav .=
6844                                         $cgi->a({-href => href(action=>"blame", -replay=>1)},
6845                                                 "blame") .
6846                                         " | ";
6847                         }
6848                         $formats_nav .=
6849                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6850                                         "history") .
6851                                 " | " .
6852                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
6853                                         "raw") .
6854                                 " | " .
6855                                 $cgi->a({-href => href(action=>"blob",
6856                                                        hash_base=>"HEAD", file_name=>$file_name)},
6857                                         "HEAD");
6858                 } else {
6859                         $formats_nav .=
6860                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
6861                                         "raw");
6862                 }
6863                 git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6864                 git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6865         } else {
6866                 print "<div class=\"page_nav\">\n" .
6867                       "<br/><br/></div>\n" .
6868                       "<div class=\"title\">".esc_html($hash)."</div>\n";
6869         }
6870         git_print_page_path($file_name, "blob", $hash_base);
6871         print "<div class=\"page_body\">\n";
6872         if ($mimetype =~ m!^image/!) {
6873                 print qq!<img type="!.esc_attr($mimetype).qq!"!;
6874                 if ($file_name) {
6875                         print qq! alt="!.esc_attr($file_name).qq!" title="!.esc_attr($file_name).qq!"!;
6876                 }
6877                 print qq! src="! .
6878                       href(action=>"blob_plain", hash=>$hash,
6879                            hash_base=>$hash_base, file_name=>$file_name) .
6880                       qq!" />\n!;
6881         } else {
6882                 my $nr;
6883                 while (my $line = <$fd>) {
6884                         chomp $line;
6885                         $nr++;
6886                         $line = untabify($line);
6887                         printf qq!<div class="pre"><a id="l%i" href="%s#l%i" class="linenr">%4i</a> %s</div>\n!,
6888                                $nr, esc_attr(href(-replay => 1)), $nr, $nr,
6889                                $syntax ? sanitize($line) : esc_html($line, -nbsp=>1);
6890                 }
6891         }
6892         close $fd
6893                 or print "Reading blob failed.\n";
6894         print "</div>";
6895         git_footer_html();
6896 }
6897
6898 sub git_tree {
6899         if (!defined $hash_base) {
6900                 $hash_base = "HEAD";
6901         }
6902         if (!defined $hash) {
6903                 if (defined $file_name) {
6904                         $hash = git_get_hash_by_path($hash_base, $file_name, "tree");
6905                 } else {
6906                         $hash = $hash_base;
6907                 }
6908         }
6909         die_error(404, "No such tree") unless defined($hash);
6910
6911         my $show_sizes = gitweb_check_feature('show-sizes');
6912         my $have_blame = gitweb_check_feature('blame');
6913
6914         my @entries = ();
6915         {
6916                 local $/ = "\0";
6917                 open my $fd, "-|", git_cmd(), "ls-tree", '-z',
6918                         ($show_sizes ? '-l' : ()), @extra_options, $hash
6919                         or die_error(500, "Open git-ls-tree failed");
6920                 @entries = map { chomp; $_ } <$fd>;
6921                 close $fd
6922                         or die_error(404, "Reading tree failed");
6923         }
6924
6925         my $refs = git_get_references();
6926         my $ref = format_ref_marker($refs, $hash_base);
6927         git_header_html();
6928         my $basedir = '';
6929         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
6930                 my @views_nav = ();
6931                 if (defined $file_name) {
6932                         push @views_nav,
6933                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6934                                         "history"),
6935                                 $cgi->a({-href => href(action=>"tree",
6936                                                        hash_base=>"HEAD", file_name=>$file_name)},
6937                                         "HEAD"),
6938                 }
6939                 my $snapshot_links = format_snapshot_links($hash);
6940                 if (defined $snapshot_links) {
6941                         # FIXME: Should be available when we have no hash base as well.
6942                         push @views_nav, $snapshot_links;
6943                 }
6944                 git_print_page_nav('tree','', $hash_base, undef, undef,
6945                                    join(' | ', @views_nav));
6946                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash_base);
6947         } else {
6948                 undef $hash_base;
6949                 print "<div class=\"page_nav\">\n";
6950                 print "<br/><br/></div>\n";
6951                 print "<div class=\"title\">".esc_html($hash)."</div>\n";
6952         }
6953         if (defined $file_name) {
6954                 $basedir = $file_name;
6955                 if ($basedir ne '' && substr($basedir, -1) ne '/') {
6956                         $basedir .= '/';
6957                 }
6958                 git_print_page_path($file_name, 'tree', $hash_base);
6959         }
6960         print "<div class=\"page_body\">\n";
6961         print "<table class=\"tree\">\n";
6962         my $alternate = 1;
6963         # '..' (top directory) link if possible
6964         if (defined $hash_base &&
6965             defined $file_name && $file_name =~ m![^/]+$!) {
6966                 if ($alternate) {
6967                         print "<tr class=\"dark\">\n";
6968                 } else {
6969                         print "<tr class=\"light\">\n";
6970                 }
6971                 $alternate ^= 1;
6972
6973                 my $up = $file_name;
6974                 $up =~ s!/?[^/]+$!!;
6975                 undef $up unless $up;
6976                 # based on git_print_tree_entry
6977                 print '<td class="mode">' . mode_str('040000') . "</td>\n";
6978                 print '<td class="size">&nbsp;</td>'."\n" if $show_sizes;
6979                 print '<td class="list">';
6980                 print $cgi->a({-href => href(action=>"tree",
6981                                              hash_base=>$hash_base,
6982                                              file_name=>$up)},
6983                               "..");
6984                 print "</td>\n";
6985                 print "<td class=\"link\"></td>\n";
6986
6987                 print "</tr>\n";
6988         }
6989         foreach my $line (@entries) {
6990                 my %t = parse_ls_tree_line($line, -z => 1, -l => $show_sizes);
6991
6992                 if ($alternate) {
6993                         print "<tr class=\"dark\">\n";
6994                 } else {
6995                         print "<tr class=\"light\">\n";
6996                 }
6997                 $alternate ^= 1;
6998
6999                 git_print_tree_entry(\%t, $basedir, $hash_base, $have_blame);
7000
7001                 print "</tr>\n";
7002         }
7003         print "</table>\n" .
7004               "</div>";
7005         git_footer_html();
7006 }
7007
7008 sub snapshot_name {
7009         my ($project, $hash) = @_;
7010
7011         # path/to/project.git  -> project
7012         # path/to/project/.git -> project
7013         my $name = to_utf8($project);
7014         $name =~ s,([^/])/*\.git$,$1,;
7015         $name = basename($name);
7016         # sanitize name
7017         $name =~ s/[[:cntrl:]]/?/g;
7018
7019         my $ver = $hash;
7020         if ($hash =~ /^[0-9a-fA-F]+$/) {
7021                 # shorten SHA-1 hash
7022                 my $full_hash = git_get_full_hash($project, $hash);
7023                 if ($full_hash =~ /^$hash/ && length($hash) > 7) {
7024                         $ver = git_get_short_hash($project, $hash);
7025                 }
7026         } elsif ($hash =~ m!^refs/tags/(.*)$!) {
7027                 # tags don't need shortened SHA-1 hash
7028                 $ver = $1;
7029         } else {
7030                 # branches and other need shortened SHA-1 hash
7031                 if ($hash =~ m!^refs/(?:heads|remotes)/(.*)$!) {
7032                         $ver = $1;
7033                 }
7034                 $ver .= '-' . git_get_short_hash($project, $hash);
7035         }
7036         # in case of hierarchical branch names
7037         $ver =~ s!/!.!g;
7038
7039         # name = project-version_string
7040         $name = "$name-$ver";
7041
7042         return wantarray ? ($name, $name) : $name;
7043 }
7044
7045 sub exit_if_unmodified_since {
7046         my ($latest_epoch) = @_;
7047         our $cgi;
7048
7049         my $if_modified = $cgi->http('IF_MODIFIED_SINCE');
7050         if (defined $if_modified) {
7051                 my $since;
7052                 if (eval { require HTTP::Date; 1; }) {
7053                         $since = HTTP::Date::str2time($if_modified);
7054                 } elsif (eval { require Time::ParseDate; 1; }) {
7055                         $since = Time::ParseDate::parsedate($if_modified, GMT => 1);
7056                 }
7057                 if (defined $since && $latest_epoch <= $since) {
7058                         my %latest_date = parse_date($latest_epoch);
7059                         print $cgi->header(
7060                                 -last_modified => $latest_date{'rfc2822'},
7061                                 -status => '304 Not Modified');
7062                         goto DONE_GITWEB;
7063                 }
7064         }
7065 }
7066
7067 sub git_snapshot {
7068         my $format = $input_params{'snapshot_format'};
7069         if (!@snapshot_fmts) {
7070                 die_error(403, "Snapshots not allowed");
7071         }
7072         # default to first supported snapshot format
7073         $format ||= $snapshot_fmts[0];
7074         if ($format !~ m/^[a-z0-9]+$/) {
7075                 die_error(400, "Invalid snapshot format parameter");
7076         } elsif (!exists($known_snapshot_formats{$format})) {
7077                 die_error(400, "Unknown snapshot format");
7078         } elsif ($known_snapshot_formats{$format}{'disabled'}) {
7079                 die_error(403, "Snapshot format not allowed");
7080         } elsif (!grep($_ eq $format, @snapshot_fmts)) {
7081                 die_error(403, "Unsupported snapshot format");
7082         }
7083
7084         my $type = git_get_type("$hash^{}");
7085         if (!$type) {
7086                 die_error(404, 'Object does not exist');
7087         }  elsif ($type eq 'blob') {
7088                 die_error(400, 'Object is not a tree-ish');
7089         }
7090
7091         my ($name, $prefix) = snapshot_name($project, $hash);
7092         my $filename = "$name$known_snapshot_formats{$format}{'suffix'}";
7093
7094         my %co = parse_commit($hash);
7095         exit_if_unmodified_since($co{'committer_epoch'}) if %co;
7096
7097         my $cmd = quote_command(
7098                 git_cmd(), 'archive',
7099                 "--format=$known_snapshot_formats{$format}{'format'}",
7100                 "--prefix=$prefix/", $hash);
7101         if (exists $known_snapshot_formats{$format}{'compressor'}) {
7102                 $cmd .= ' | ' . quote_command(@{$known_snapshot_formats{$format}{'compressor'}});
7103         }
7104
7105         $filename =~ s/(["\\])/\\$1/g;
7106         my %latest_date;
7107         if (%co) {
7108                 %latest_date = parse_date($co{'committer_epoch'}, $co{'committer_tz'});
7109         }
7110
7111         print $cgi->header(
7112                 -type => $known_snapshot_formats{$format}{'type'},
7113                 -content_disposition => 'inline; filename="' . $filename . '"',
7114                 %co ? (-last_modified => $latest_date{'rfc2822'}) : (),
7115                 -status => '200 OK');
7116
7117         open my $fd, "-|", $cmd
7118                 or die_error(500, "Execute git-archive failed");
7119         binmode STDOUT, ':raw';
7120         print <$fd>;
7121         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
7122         close $fd;
7123 }
7124
7125 sub git_log_generic {
7126         my ($fmt_name, $body_subr, $base, $parent, $file_name, $file_hash) = @_;
7127
7128         my $head = git_get_head_hash($project);
7129         if (!defined $base) {
7130                 $base = $head;
7131         }
7132         if (!defined $page) {
7133                 $page = 0;
7134         }
7135         my $refs = git_get_references();
7136
7137         my $commit_hash = $base;
7138         if (defined $parent) {
7139                 $commit_hash = "$parent..$base";
7140         }
7141         my @commitlist =
7142                 parse_commits($commit_hash, 101, (100 * $page),
7143                               defined $file_name ? ($file_name, "--full-history") : ());
7144
7145         my $ftype;
7146         if (!defined $file_hash && defined $file_name) {
7147                 # some commits could have deleted file in question,
7148                 # and not have it in tree, but one of them has to have it
7149                 for (my $i = 0; $i < @commitlist; $i++) {
7150                         $file_hash = git_get_hash_by_path($commitlist[$i]{'id'}, $file_name);
7151                         last if defined $file_hash;
7152                 }
7153         }
7154         if (defined $file_hash) {
7155                 $ftype = git_get_type($file_hash);
7156         }
7157         if (defined $file_name && !defined $ftype) {
7158                 die_error(500, "Unknown type of object");
7159         }
7160         my %co;
7161         if (defined $file_name) {
7162                 %co = parse_commit($base)
7163                         or die_error(404, "Unknown commit object");
7164         }
7165
7166
7167         my $paging_nav = format_paging_nav($fmt_name, $page, $#commitlist >= 100);
7168         my $next_link = '';
7169         if ($#commitlist >= 100) {
7170                 $next_link =
7171                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
7172                                  -accesskey => "n", -title => "Alt-n"}, "next");
7173         }
7174         my $patch_max = gitweb_get_feature('patches');
7175         if ($patch_max && !defined $file_name) {
7176                 if ($patch_max < 0 || @commitlist <= $patch_max) {
7177                         $paging_nav .= " &sdot; " .
7178                                 $cgi->a({-href => href(action=>"patches", -replay=>1)},
7179                                         "patches");
7180                 }
7181         }
7182
7183         git_header_html();
7184         git_print_page_nav($fmt_name,'', $hash,$hash,$hash, $paging_nav);
7185         if (defined $file_name) {
7186                 git_print_header_div('commit', esc_html($co{'title'}), $base);
7187         } else {
7188                 git_print_header_div('summary', $project)
7189         }
7190         git_print_page_path($file_name, $ftype, $hash_base)
7191                 if (defined $file_name);
7192
7193         $body_subr->(\@commitlist, 0, 99, $refs, $next_link,
7194                      $file_name, $file_hash, $ftype);
7195
7196         git_footer_html();
7197 }
7198
7199 sub git_log {
7200         git_log_generic('log', \&git_log_body,
7201                         $hash, $hash_parent);
7202 }
7203
7204 sub git_commit {
7205         $hash ||= $hash_base || "HEAD";
7206         my %co = parse_commit($hash)
7207             or die_error(404, "Unknown commit object");
7208
7209         my $parent  = $co{'parent'};
7210         my $parents = $co{'parents'}; # listref
7211
7212         # we need to prepare $formats_nav before any parameter munging
7213         my $formats_nav;
7214         if (!defined $parent) {
7215                 # --root commitdiff
7216                 $formats_nav .= '(initial)';
7217         } elsif (@$parents == 1) {
7218                 # single parent commit
7219                 $formats_nav .=
7220                         '(parent: ' .
7221                         $cgi->a({-href => href(action=>"commit",
7222                                                hash=>$parent)},
7223                                 esc_html(substr($parent, 0, 7))) .
7224                         ')';
7225         } else {
7226                 # merge commit
7227                 $formats_nav .=
7228                         '(merge: ' .
7229                         join(' ', map {
7230                                 $cgi->a({-href => href(action=>"commit",
7231                                                        hash=>$_)},
7232                                         esc_html(substr($_, 0, 7)));
7233                         } @$parents ) .
7234                         ')';
7235         }
7236         if (gitweb_check_feature('patches') && @$parents <= 1) {
7237                 $formats_nav .= " | " .
7238                         $cgi->a({-href => href(action=>"patch", -replay=>1)},
7239                                 "patch");
7240         }
7241
7242         if (!defined $parent) {
7243                 $parent = "--root";
7244         }
7245         my @difftree;
7246         open my $fd, "-|", git_cmd(), "diff-tree", '-r', "--no-commit-id",
7247                 @diff_opts,
7248                 (@$parents <= 1 ? $parent : '-c'),
7249                 $hash, "--"
7250                 or die_error(500, "Open git-diff-tree failed");
7251         @difftree = map { chomp; $_ } <$fd>;
7252         close $fd or die_error(404, "Reading git-diff-tree failed");
7253
7254         # non-textual hash id's can be cached
7255         my $expires;
7256         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7257                 $expires = "+1d";
7258         }
7259         my $refs = git_get_references();
7260         my $ref = format_ref_marker($refs, $co{'id'});
7261
7262         git_header_html(undef, $expires);
7263         git_print_page_nav('commit', '',
7264                            $hash, $co{'tree'}, $hash,
7265                            $formats_nav);
7266
7267         if (defined $co{'parent'}) {
7268                 git_print_header_div('commitdiff', esc_html($co{'title'}) . $ref, $hash);
7269         } else {
7270                 git_print_header_div('tree', esc_html($co{'title'}) . $ref, $co{'tree'}, $hash);
7271         }
7272         print "<div class=\"title_text\">\n" .
7273               "<table class=\"object_header\">\n";
7274         git_print_authorship_rows(\%co);
7275         print "<tr><td>commit</td><td class=\"sha1\">$co{'id'}</td></tr>\n";
7276         print "<tr>" .
7277               "<td>tree</td>" .
7278               "<td class=\"sha1\">" .
7279               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash),
7280                        class => "list"}, $co{'tree'}) .
7281               "</td>" .
7282               "<td class=\"link\">" .
7283               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash)},
7284                       "tree");
7285         my $snapshot_links = format_snapshot_links($hash);
7286         if (defined $snapshot_links) {
7287                 print " | " . $snapshot_links;
7288         }
7289         print "</td>" .
7290               "</tr>\n";
7291
7292         foreach my $par (@$parents) {
7293                 print "<tr>" .
7294                       "<td>parent</td>" .
7295                       "<td class=\"sha1\">" .
7296                       $cgi->a({-href => href(action=>"commit", hash=>$par),
7297                                class => "list"}, $par) .
7298                       "</td>" .
7299                       "<td class=\"link\">" .
7300                       $cgi->a({-href => href(action=>"commit", hash=>$par)}, "commit") .
7301                       " | " .
7302                       $cgi->a({-href => href(action=>"commitdiff", hash=>$hash, hash_parent=>$par)}, "diff") .
7303                       "</td>" .
7304                       "</tr>\n";
7305         }
7306         print "</table>".
7307               "</div>\n";
7308
7309         print "<div class=\"page_body\">\n";
7310         git_print_log($co{'comment'});
7311         print "</div>\n";
7312
7313         git_difftree_body(\@difftree, $hash, @$parents);
7314
7315         git_footer_html();
7316 }
7317
7318 sub git_object {
7319         # object is defined by:
7320         # - hash or hash_base alone
7321         # - hash_base and file_name
7322         my $type;
7323
7324         # - hash or hash_base alone
7325         if ($hash || ($hash_base && !defined $file_name)) {
7326                 my $object_id = $hash || $hash_base;
7327
7328                 open my $fd, "-|", quote_command(
7329                         git_cmd(), 'cat-file', '-t', $object_id) . ' 2> /dev/null'
7330                         or die_error(404, "Object does not exist");
7331                 $type = <$fd>;
7332                 chomp $type;
7333                 close $fd
7334                         or die_error(404, "Object does not exist");
7335
7336         # - hash_base and file_name
7337         } elsif ($hash_base && defined $file_name) {
7338                 $file_name =~ s,/+$,,;
7339
7340                 system(git_cmd(), "cat-file", '-e', $hash_base) == 0
7341                         or die_error(404, "Base object does not exist");
7342
7343                 # here errors should not hapen
7344                 open my $fd, "-|", git_cmd(), "ls-tree", $hash_base, "--", $file_name
7345                         or die_error(500, "Open git-ls-tree failed");
7346                 my $line = <$fd>;
7347                 close $fd;
7348
7349                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
7350                 unless ($line && $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/) {
7351                         die_error(404, "File or directory for given base does not exist");
7352                 }
7353                 $type = $2;
7354                 $hash = $3;
7355         } else {
7356                 die_error(400, "Not enough information to find object");
7357         }
7358
7359         print $cgi->redirect(-uri => href(action=>$type, -full=>1,
7360                                           hash=>$hash, hash_base=>$hash_base,
7361                                           file_name=>$file_name),
7362                              -status => '302 Found');
7363 }
7364
7365 sub git_blobdiff {
7366         my $format = shift || 'html';
7367         my $diff_style = $input_params{'diff_style'} || 'inline';
7368
7369         my $fd;
7370         my @difftree;
7371         my %diffinfo;
7372         my $expires;
7373
7374         # preparing $fd and %diffinfo for git_patchset_body
7375         # new style URI
7376         if (defined $hash_base && defined $hash_parent_base) {
7377                 if (defined $file_name) {
7378                         # read raw output
7379                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7380                                 $hash_parent_base, $hash_base,
7381                                 "--", (defined $file_parent ? $file_parent : ()), $file_name
7382                                 or die_error(500, "Open git-diff-tree failed");
7383                         @difftree = map { chomp; $_ } <$fd>;
7384                         close $fd
7385                                 or die_error(404, "Reading git-diff-tree failed");
7386                         @difftree
7387                                 or die_error(404, "Blob diff not found");
7388
7389                 } elsif (defined $hash &&
7390                          $hash =~ /[0-9a-fA-F]{40}/) {
7391                         # try to find filename from $hash
7392
7393                         # read filtered raw output
7394                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7395                                 $hash_parent_base, $hash_base, "--"
7396                                 or die_error(500, "Open git-diff-tree failed");
7397                         @difftree =
7398                                 # ':100644 100644 03b21826... 3b93d5e7... M     ls-files.c'
7399                                 # $hash == to_id
7400                                 grep { /^:[0-7]{6} [0-7]{6} [0-9a-fA-F]{40} $hash/ }
7401                                 map { chomp; $_ } <$fd>;
7402                         close $fd
7403                                 or die_error(404, "Reading git-diff-tree failed");
7404                         @difftree
7405                                 or die_error(404, "Blob diff not found");
7406
7407                 } else {
7408                         die_error(400, "Missing one of the blob diff parameters");
7409                 }
7410
7411                 if (@difftree > 1) {
7412                         die_error(400, "Ambiguous blob diff specification");
7413                 }
7414
7415                 %diffinfo = parse_difftree_raw_line($difftree[0]);
7416                 $file_parent ||= $diffinfo{'from_file'} || $file_name;
7417                 $file_name   ||= $diffinfo{'to_file'};
7418
7419                 $hash_parent ||= $diffinfo{'from_id'};
7420                 $hash        ||= $diffinfo{'to_id'};
7421
7422                 # non-textual hash id's can be cached
7423                 if ($hash_base =~ m/^[0-9a-fA-F]{40}$/ &&
7424                     $hash_parent_base =~ m/^[0-9a-fA-F]{40}$/) {
7425                         $expires = '+1d';
7426                 }
7427
7428                 # open patch output
7429                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7430                         '-p', ($format eq 'html' ? "--full-index" : ()),
7431                         $hash_parent_base, $hash_base,
7432                         "--", (defined $file_parent ? $file_parent : ()), $file_name
7433                         or die_error(500, "Open git-diff-tree failed");
7434         }
7435
7436         # old/legacy style URI -- not generated anymore since 1.4.3.
7437         if (!%diffinfo) {
7438                 die_error('404 Not Found', "Missing one of the blob diff parameters")
7439         }
7440
7441         # header
7442         if ($format eq 'html') {
7443                 my $formats_nav =
7444                         $cgi->a({-href => href(action=>"blobdiff_plain", -replay=>1)},
7445                                 "raw");
7446                 $formats_nav .= diff_style_nav($diff_style);
7447                 git_header_html(undef, $expires);
7448                 if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7449                         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
7450                         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
7451                 } else {
7452                         print "<div class=\"page_nav\"><br/>$formats_nav<br/></div>\n";
7453                         print "<div class=\"title\">".esc_html("$hash vs $hash_parent")."</div>\n";
7454                 }
7455                 if (defined $file_name) {
7456                         git_print_page_path($file_name, "blob", $hash_base);
7457                 } else {
7458                         print "<div class=\"page_path\"></div>\n";
7459                 }
7460
7461         } elsif ($format eq 'plain') {
7462                 print $cgi->header(
7463                         -type => 'text/plain',
7464                         -charset => 'utf-8',
7465                         -expires => $expires,
7466                         -content_disposition => 'inline; filename="' . "$file_name" . '.patch"');
7467
7468                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7469
7470         } else {
7471                 die_error(400, "Unknown blobdiff format");
7472         }
7473
7474         # patch
7475         if ($format eq 'html') {
7476                 print "<div class=\"page_body\">\n";
7477
7478                 git_patchset_body($fd, $diff_style,
7479                                   [ \%diffinfo ], $hash_base, $hash_parent_base);
7480                 close $fd;
7481
7482                 print "</div>\n"; # class="page_body"
7483                 git_footer_html();
7484
7485         } else {
7486                 while (my $line = <$fd>) {
7487                         $line =~ s!a/($hash|$hash_parent)!'a/'.esc_path($diffinfo{'from_file'})!eg;
7488                         $line =~ s!b/($hash|$hash_parent)!'b/'.esc_path($diffinfo{'to_file'})!eg;
7489
7490                         print $line;
7491
7492                         last if $line =~ m!^\+\+\+!;
7493                 }
7494                 local $/ = undef;
7495                 print <$fd>;
7496                 close $fd;
7497         }
7498 }
7499
7500 sub git_blobdiff_plain {
7501         git_blobdiff('plain');
7502 }
7503
7504 # assumes that it is added as later part of already existing navigation,
7505 # so it returns "| foo | bar" rather than just "foo | bar"
7506 sub diff_style_nav {
7507         my ($diff_style, $is_combined) = @_;
7508         $diff_style ||= 'inline';
7509
7510         return "" if ($is_combined);
7511
7512         my @styles = (inline => 'inline', 'sidebyside' => 'side by side');
7513         my %styles = @styles;
7514         @styles =
7515                 @styles[ map { $_ * 2 } 0..$#styles/2 ];
7516
7517         return join '',
7518                 map { " | ".$_ }
7519                 map {
7520                         $_ eq $diff_style ? $styles{$_} :
7521                         $cgi->a({-href => href(-replay=>1, diff_style => $_)}, $styles{$_})
7522                 } @styles;
7523 }
7524
7525 sub git_commitdiff {
7526         my %params = @_;
7527         my $format = $params{-format} || 'html';
7528         my $diff_style = $input_params{'diff_style'} || 'inline';
7529
7530         my ($patch_max) = gitweb_get_feature('patches');
7531         if ($format eq 'patch') {
7532                 die_error(403, "Patch view not allowed") unless $patch_max;
7533         }
7534
7535         $hash ||= $hash_base || "HEAD";
7536         my %co = parse_commit($hash)
7537             or die_error(404, "Unknown commit object");
7538
7539         # choose format for commitdiff for merge
7540         if (! defined $hash_parent && @{$co{'parents'}} > 1) {
7541                 $hash_parent = '--cc';
7542         }
7543         # we need to prepare $formats_nav before almost any parameter munging
7544         my $formats_nav;
7545         if ($format eq 'html') {
7546                 $formats_nav =
7547                         $cgi->a({-href => href(action=>"commitdiff_plain", -replay=>1)},
7548                                 "raw");
7549                 if ($patch_max && @{$co{'parents'}} <= 1) {
7550                         $formats_nav .= " | " .
7551                                 $cgi->a({-href => href(action=>"patch", -replay=>1)},
7552                                         "patch");
7553                 }
7554                 $formats_nav .= diff_style_nav($diff_style, @{$co{'parents'}} > 1);
7555
7556                 if (defined $hash_parent &&
7557                     $hash_parent ne '-c' && $hash_parent ne '--cc') {
7558                         # commitdiff with two commits given
7559                         my $hash_parent_short = $hash_parent;
7560                         if ($hash_parent =~ m/^[0-9a-fA-F]{40}$/) {
7561                                 $hash_parent_short = substr($hash_parent, 0, 7);
7562                         }
7563                         $formats_nav .=
7564                                 ' (from';
7565                         for (my $i = 0; $i < @{$co{'parents'}}; $i++) {
7566                                 if ($co{'parents'}[$i] eq $hash_parent) {
7567                                         $formats_nav .= ' parent ' . ($i+1);
7568                                         last;
7569                                 }
7570                         }
7571                         $formats_nav .= ': ' .
7572                                 $cgi->a({-href => href(-replay=>1,
7573                                                        hash=>$hash_parent, hash_base=>undef)},
7574                                         esc_html($hash_parent_short)) .
7575                                 ')';
7576                 } elsif (!$co{'parent'}) {
7577                         # --root commitdiff
7578                         $formats_nav .= ' (initial)';
7579                 } elsif (scalar @{$co{'parents'}} == 1) {
7580                         # single parent commit
7581                         $formats_nav .=
7582                                 ' (parent: ' .
7583                                 $cgi->a({-href => href(-replay=>1,
7584                                                        hash=>$co{'parent'}, hash_base=>undef)},
7585                                         esc_html(substr($co{'parent'}, 0, 7))) .
7586                                 ')';
7587                 } else {
7588                         # merge commit
7589                         if ($hash_parent eq '--cc') {
7590                                 $formats_nav .= ' | ' .
7591                                         $cgi->a({-href => href(-replay=>1,
7592                                                                hash=>$hash, hash_parent=>'-c')},
7593                                                 'combined');
7594                         } else { # $hash_parent eq '-c'
7595                                 $formats_nav .= ' | ' .
7596                                         $cgi->a({-href => href(-replay=>1,
7597                                                                hash=>$hash, hash_parent=>'--cc')},
7598                                                 'compact');
7599                         }
7600                         $formats_nav .=
7601                                 ' (merge: ' .
7602                                 join(' ', map {
7603                                         $cgi->a({-href => href(-replay=>1,
7604                                                                hash=>$_, hash_base=>undef)},
7605                                                 esc_html(substr($_, 0, 7)));
7606                                 } @{$co{'parents'}} ) .
7607                                 ')';
7608                 }
7609         }
7610
7611         my $hash_parent_param = $hash_parent;
7612         if (!defined $hash_parent_param) {
7613                 # --cc for multiple parents, --root for parentless
7614                 $hash_parent_param =
7615                         @{$co{'parents'}} > 1 ? '--cc' : $co{'parent'} || '--root';
7616         }
7617
7618         # read commitdiff
7619         my $fd;
7620         my @difftree;
7621         if ($format eq 'html') {
7622                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7623                         "--no-commit-id", "--patch-with-raw", "--full-index",
7624                         $hash_parent_param, $hash, "--"
7625                         or die_error(500, "Open git-diff-tree failed");
7626
7627                 while (my $line = <$fd>) {
7628                         chomp $line;
7629                         # empty line ends raw part of diff-tree output
7630                         last unless $line;
7631                         push @difftree, scalar parse_difftree_raw_line($line);
7632                 }
7633
7634         } elsif ($format eq 'plain') {
7635                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7636                         '-p', $hash_parent_param, $hash, "--"
7637                         or die_error(500, "Open git-diff-tree failed");
7638         } elsif ($format eq 'patch') {
7639                 # For commit ranges, we limit the output to the number of
7640                 # patches specified in the 'patches' feature.
7641                 # For single commits, we limit the output to a single patch,
7642                 # diverging from the git-format-patch default.
7643                 my @commit_spec = ();
7644                 if ($hash_parent) {
7645                         if ($patch_max > 0) {
7646                                 push @commit_spec, "-$patch_max";
7647                         }
7648                         push @commit_spec, '-n', "$hash_parent..$hash";
7649                 } else {
7650                         if ($params{-single}) {
7651                                 push @commit_spec, '-1';
7652                         } else {
7653                                 if ($patch_max > 0) {
7654                                         push @commit_spec, "-$patch_max";
7655                                 }
7656                                 push @commit_spec, "-n";
7657                         }
7658                         push @commit_spec, '--root', $hash;
7659                 }
7660                 open $fd, "-|", git_cmd(), "format-patch", @diff_opts,
7661                         '--encoding=utf8', '--stdout', @commit_spec
7662                         or die_error(500, "Open git-format-patch failed");
7663         } else {
7664                 die_error(400, "Unknown commitdiff format");
7665         }
7666
7667         # non-textual hash id's can be cached
7668         my $expires;
7669         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7670                 $expires = "+1d";
7671         }
7672
7673         # write commit message
7674         if ($format eq 'html') {
7675                 my $refs = git_get_references();
7676                 my $ref = format_ref_marker($refs, $co{'id'});
7677
7678                 git_header_html(undef, $expires);
7679                 git_print_page_nav('commitdiff','', $hash,$co{'tree'},$hash, $formats_nav);
7680                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash);
7681                 print "<div class=\"title_text\">\n" .
7682                       "<table class=\"object_header\">\n";
7683                 git_print_authorship_rows(\%co);
7684                 print "</table>".
7685                       "</div>\n";
7686                 print "<div class=\"page_body\">\n";
7687                 if (@{$co{'comment'}} > 1) {
7688                         print "<div class=\"log\">\n";
7689                         git_print_log($co{'comment'}, -final_empty_line=> 1, -remove_title => 1);
7690                         print "</div>\n"; # class="log"
7691                 }
7692
7693         } elsif ($format eq 'plain') {
7694                 my $refs = git_get_references("tags");
7695                 my $tagname = git_get_rev_name_tags($hash);
7696                 my $filename = basename($project) . "-$hash.patch";
7697
7698                 print $cgi->header(
7699                         -type => 'text/plain',
7700                         -charset => 'utf-8',
7701                         -expires => $expires,
7702                         -content_disposition => 'inline; filename="' . "$filename" . '"');
7703                 my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
7704                 print "From: " . to_utf8($co{'author'}) . "\n";
7705                 print "Date: $ad{'rfc2822'} ($ad{'tz_local'})\n";
7706                 print "Subject: " . to_utf8($co{'title'}) . "\n";
7707
7708                 print "X-Git-Tag: $tagname\n" if $tagname;
7709                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7710
7711                 foreach my $line (@{$co{'comment'}}) {
7712                         print to_utf8($line) . "\n";
7713                 }
7714                 print "---\n\n";
7715         } elsif ($format eq 'patch') {
7716                 my $filename = basename($project) . "-$hash.patch";
7717
7718                 print $cgi->header(
7719                         -type => 'text/plain',
7720                         -charset => 'utf-8',
7721                         -expires => $expires,
7722                         -content_disposition => 'inline; filename="' . "$filename" . '"');
7723         }
7724
7725         # write patch
7726         if ($format eq 'html') {
7727                 my $use_parents = !defined $hash_parent ||
7728                         $hash_parent eq '-c' || $hash_parent eq '--cc';
7729                 git_difftree_body(\@difftree, $hash,
7730                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
7731                 print "<br/>\n";
7732
7733                 git_patchset_body($fd, $diff_style,
7734                                   \@difftree, $hash,
7735                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
7736                 close $fd;
7737                 print "</div>\n"; # class="page_body"
7738                 git_footer_html();
7739
7740         } elsif ($format eq 'plain') {
7741                 local $/ = undef;
7742                 print <$fd>;
7743                 close $fd
7744                         or print "Reading git-diff-tree failed\n";
7745         } elsif ($format eq 'patch') {
7746                 local $/ = undef;
7747                 print <$fd>;
7748                 close $fd
7749                         or print "Reading git-format-patch failed\n";
7750         }
7751 }
7752
7753 sub git_commitdiff_plain {
7754         git_commitdiff(-format => 'plain');
7755 }
7756
7757 # format-patch-style patches
7758 sub git_patch {
7759         git_commitdiff(-format => 'patch', -single => 1);
7760 }
7761
7762 sub git_patches {
7763         git_commitdiff(-format => 'patch');
7764 }
7765
7766 sub git_history {
7767         git_log_generic('history', \&git_history_body,
7768                         $hash_base, $hash_parent_base,
7769                         $file_name, $hash);
7770 }
7771
7772 sub git_search {
7773         $searchtype ||= 'commit';
7774
7775         # check if appropriate features are enabled
7776         gitweb_check_feature('search')
7777                 or die_error(403, "Search is disabled");
7778         if ($searchtype eq 'pickaxe') {
7779                 # pickaxe may take all resources of your box and run for several minutes
7780                 # with every query - so decide by yourself how public you make this feature
7781                 gitweb_check_feature('pickaxe')
7782                         or die_error(403, "Pickaxe search is disabled");
7783         }
7784         if ($searchtype eq 'grep') {
7785                 # grep search might be potentially CPU-intensive, too
7786                 gitweb_check_feature('grep')
7787                         or die_error(403, "Grep search is disabled");
7788         }
7789
7790         if (!defined $searchtext) {
7791                 die_error(400, "Text field is empty");
7792         }
7793         if (!defined $hash) {
7794                 $hash = git_get_head_hash($project);
7795         }
7796         my %co = parse_commit($hash);
7797         if (!%co) {
7798                 die_error(404, "Unknown commit object");
7799         }
7800         if (!defined $page) {
7801                 $page = 0;
7802         }
7803
7804         if ($searchtype eq 'commit' ||
7805             $searchtype eq 'author' ||
7806             $searchtype eq 'committer') {
7807                 git_search_message(%co);
7808         } elsif ($searchtype eq 'pickaxe') {
7809                 git_search_changes(%co);
7810         } elsif ($searchtype eq 'grep') {
7811                 git_search_files(%co);
7812         } else {
7813                 die_error(400, "Unknown search type");
7814         }
7815 }
7816
7817 sub git_search_help {
7818         git_header_html();
7819         git_print_page_nav('','', $hash,$hash,$hash);
7820         print <<EOT;
7821 <p><strong>Pattern</strong> is by default a normal string that is matched precisely (but without
7822 regard to case, except in the case of pickaxe). However, when you check the <em>re</em> checkbox,
7823 the pattern entered is recognized as the POSIX extended
7824 <a href="http://en.wikipedia.org/wiki/Regular_expression">regular expression</a> (also case
7825 insensitive).</p>
7826 <dl>
7827 <dt><b>commit</b></dt>
7828 <dd>The commit messages and authorship information will be scanned for the given pattern.</dd>
7829 EOT
7830         my $have_grep = gitweb_check_feature('grep');
7831         if ($have_grep) {
7832                 print <<EOT;
7833 <dt><b>grep</b></dt>
7834 <dd>All files in the currently selected tree (HEAD unless you are explicitly browsing
7835     a different one) are searched for the given pattern. On large trees, this search can take
7836 a while and put some strain on the server, so please use it with some consideration. Note that
7837 due to git-grep peculiarity, currently if regexp mode is turned off, the matches are
7838 case-sensitive.</dd>
7839 EOT
7840         }
7841         print <<EOT;
7842 <dt><b>author</b></dt>
7843 <dd>Name and e-mail of the change author and date of birth of the patch will be scanned for the given pattern.</dd>
7844 <dt><b>committer</b></dt>
7845 <dd>Name and e-mail of the committer and date of commit will be scanned for the given pattern.</dd>
7846 EOT
7847         my $have_pickaxe = gitweb_check_feature('pickaxe');
7848         if ($have_pickaxe) {
7849                 print <<EOT;
7850 <dt><b>pickaxe</b></dt>
7851 <dd>All commits that caused the string to appear or disappear from any file (changes that
7852 added, removed or "modified" the string) will be listed. This search can take a while and
7853 takes a lot of strain on the server, so please use it wisely. Note that since you may be
7854 interested even in changes just changing the case as well, this search is case sensitive.</dd>
7855 EOT
7856         }
7857         print "</dl>\n";
7858         git_footer_html();
7859 }
7860
7861 sub git_shortlog {
7862         git_log_generic('shortlog', \&git_shortlog_body,
7863                         $hash, $hash_parent);
7864 }
7865
7866 ## ......................................................................
7867 ## feeds (RSS, Atom; OPML)
7868
7869 sub git_feed {
7870         my $format = shift || 'atom';
7871         my $have_blame = gitweb_check_feature('blame');
7872
7873         # Atom: http://www.atomenabled.org/developers/syndication/
7874         # RSS:  http://www.notestips.com/80256B3A007F2692/1/NAMO5P9UPQ
7875         if ($format ne 'rss' && $format ne 'atom') {
7876                 die_error(400, "Unknown web feed format");
7877         }
7878
7879         # log/feed of current (HEAD) branch, log of given branch, history of file/directory
7880         my $head = $hash || 'HEAD';
7881         my @commitlist = parse_commits($head, 150, 0, $file_name);
7882
7883         my %latest_commit;
7884         my %latest_date;
7885         my $content_type = "application/$format+xml";
7886         if (defined $cgi->http('HTTP_ACCEPT') &&
7887                  $cgi->Accept('text/xml') > $cgi->Accept($content_type)) {
7888                 # browser (feed reader) prefers text/xml
7889                 $content_type = 'text/xml';
7890         }
7891         if (defined($commitlist[0])) {
7892                 %latest_commit = %{$commitlist[0]};
7893                 my $latest_epoch = $latest_commit{'committer_epoch'};
7894                 exit_if_unmodified_since($latest_epoch);
7895                 %latest_date = parse_date($latest_epoch, $latest_commit{'comitter_tz'});
7896         }
7897         print $cgi->header(
7898                 -type => $content_type,
7899                 -charset => 'utf-8',
7900                 %latest_date ? (-last_modified => $latest_date{'rfc2822'}) : (),
7901                 -status => '200 OK');
7902
7903         # Optimization: skip generating the body if client asks only
7904         # for Last-Modified date.
7905         return if ($cgi->request_method() eq 'HEAD');
7906
7907         # header variables
7908         my $title = "$site_name - $project/$action";
7909         my $feed_type = 'log';
7910         if (defined $hash) {
7911                 $title .= " - '$hash'";
7912                 $feed_type = 'branch log';
7913                 if (defined $file_name) {
7914                         $title .= " :: $file_name";
7915                         $feed_type = 'history';
7916                 }
7917         } elsif (defined $file_name) {
7918                 $title .= " - $file_name";
7919                 $feed_type = 'history';
7920         }
7921         $title .= " $feed_type";
7922         my $descr = git_get_project_description($project);
7923         if (defined $descr) {
7924                 $descr = esc_html($descr);
7925         } else {
7926                 $descr = "$project " .
7927                          ($format eq 'rss' ? 'RSS' : 'Atom') .
7928                          " feed";
7929         }
7930         my $owner = git_get_project_owner($project);
7931         $owner = esc_html($owner);
7932
7933         #header
7934         my $alt_url;
7935         if (defined $file_name) {
7936                 $alt_url = href(-full=>1, action=>"history", hash=>$hash, file_name=>$file_name);
7937         } elsif (defined $hash) {
7938                 $alt_url = href(-full=>1, action=>"log", hash=>$hash);
7939         } else {
7940                 $alt_url = href(-full=>1, action=>"summary");
7941         }
7942         print qq!<?xml version="1.0" encoding="utf-8"?>\n!;
7943         if ($format eq 'rss') {
7944                 print <<XML;
7945 <rss version="2.0" xmlns:content="http://purl.org/rss/1.0/modules/content/">
7946 <channel>
7947 XML
7948                 print "<title>$title</title>\n" .
7949                       "<link>$alt_url</link>\n" .
7950                       "<description>$descr</description>\n" .
7951                       "<language>en</language>\n" .
7952                       # project owner is responsible for 'editorial' content
7953                       "<managingEditor>$owner</managingEditor>\n";
7954                 if (defined $logo || defined $favicon) {
7955                         # prefer the logo to the favicon, since RSS
7956                         # doesn't allow both
7957                         my $img = esc_url($logo || $favicon);
7958                         print "<image>\n" .
7959                               "<url>$img</url>\n" .
7960                               "<title>$title</title>\n" .
7961                               "<link>$alt_url</link>\n" .
7962                               "</image>\n";
7963                 }
7964                 if (%latest_date) {
7965                         print "<pubDate>$latest_date{'rfc2822'}</pubDate>\n";
7966                         print "<lastBuildDate>$latest_date{'rfc2822'}</lastBuildDate>\n";
7967                 }
7968                 print "<generator>gitweb v.$version/$git_version</generator>\n";
7969         } elsif ($format eq 'atom') {
7970                 print <<XML;
7971 <feed xmlns="http://www.w3.org/2005/Atom">
7972 XML
7973                 print "<title>$title</title>\n" .
7974                       "<subtitle>$descr</subtitle>\n" .
7975                       '<link rel="alternate" type="text/html" href="' .
7976                       $alt_url . '" />' . "\n" .
7977                       '<link rel="self" type="' . $content_type . '" href="' .
7978                       $cgi->self_url() . '" />' . "\n" .
7979                       "<id>" . href(-full=>1) . "</id>\n" .
7980                       # use project owner for feed author
7981                       "<author><name>$owner</name></author>\n";
7982                 if (defined $favicon) {
7983                         print "<icon>" . esc_url($favicon) . "</icon>\n";
7984                 }
7985                 if (defined $logo) {
7986                         # not twice as wide as tall: 72 x 27 pixels
7987                         print "<logo>" . esc_url($logo) . "</logo>\n";
7988                 }
7989                 if (! %latest_date) {
7990                         # dummy date to keep the feed valid until commits trickle in:
7991                         print "<updated>1970-01-01T00:00:00Z</updated>\n";
7992                 } else {
7993                         print "<updated>$latest_date{'iso-8601'}</updated>\n";
7994                 }
7995                 print "<generator version='$version/$git_version'>gitweb</generator>\n";
7996         }
7997
7998         # contents
7999         for (my $i = 0; $i <= $#commitlist; $i++) {
8000                 my %co = %{$commitlist[$i]};
8001                 my $commit = $co{'id'};
8002                 # we read 150, we always show 30 and the ones more recent than 48 hours
8003                 if (($i >= 20) && ((time - $co{'author_epoch'}) > 48*60*60)) {
8004                         last;
8005                 }
8006                 my %cd = parse_date($co{'author_epoch'}, $co{'author_tz'});
8007
8008                 # get list of changed files
8009                 open my $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
8010                         $co{'parent'} || "--root",
8011                         $co{'id'}, "--", (defined $file_name ? $file_name : ())
8012                         or next;
8013                 my @difftree = map { chomp; $_ } <$fd>;
8014                 close $fd
8015                         or next;
8016
8017                 # print element (entry, item)
8018                 my $co_url = href(-full=>1, action=>"commitdiff", hash=>$commit);
8019                 if ($format eq 'rss') {
8020                         print "<item>\n" .
8021                               "<title>" . esc_html($co{'title'}) . "</title>\n" .
8022                               "<author>" . esc_html($co{'author'}) . "</author>\n" .
8023                               "<pubDate>$cd{'rfc2822'}</pubDate>\n" .
8024                               "<guid isPermaLink=\"true\">$co_url</guid>\n" .
8025                               "<link>$co_url</link>\n" .
8026                               "<description>" . esc_html($co{'title'}) . "</description>\n" .
8027                               "<content:encoded>" .
8028                               "<![CDATA[\n";
8029                 } elsif ($format eq 'atom') {
8030                         print "<entry>\n" .
8031                               "<title type=\"html\">" . esc_html($co{'title'}) . "</title>\n" .
8032                               "<updated>$cd{'iso-8601'}</updated>\n" .
8033                               "<author>\n" .
8034                               "  <name>" . esc_html($co{'author_name'}) . "</name>\n";
8035                         if ($co{'author_email'}) {
8036                                 print "  <email>" . esc_html($co{'author_email'}) . "</email>\n";
8037                         }
8038                         print "</author>\n" .
8039                               # use committer for contributor
8040                               "<contributor>\n" .
8041                               "  <name>" . esc_html($co{'committer_name'}) . "</name>\n";
8042                         if ($co{'committer_email'}) {
8043                                 print "  <email>" . esc_html($co{'committer_email'}) . "</email>\n";
8044                         }
8045                         print "</contributor>\n" .
8046                               "<published>$cd{'iso-8601'}</published>\n" .
8047                               "<link rel=\"alternate\" type=\"text/html\" href=\"$co_url\" />\n" .
8048                               "<id>$co_url</id>\n" .
8049                               "<content type=\"xhtml\" xml:base=\"" . esc_url($my_url) . "\">\n" .
8050                               "<div xmlns=\"http://www.w3.org/1999/xhtml\">\n";
8051                 }
8052                 my $comment = $co{'comment'};
8053                 print "<pre>\n";
8054                 foreach my $line (@$comment) {
8055                         $line = esc_html($line);
8056                         print "$line\n";
8057                 }
8058                 print "</pre><ul>\n";
8059                 foreach my $difftree_line (@difftree) {
8060                         my %difftree = parse_difftree_raw_line($difftree_line);
8061                         next if !$difftree{'from_id'};
8062
8063                         my $file = $difftree{'file'} || $difftree{'to_file'};
8064
8065                         print "<li>" .
8066                               "[" .
8067                               $cgi->a({-href => href(-full=>1, action=>"blobdiff",
8068                                                      hash=>$difftree{'to_id'}, hash_parent=>$difftree{'from_id'},
8069                                                      hash_base=>$co{'id'}, hash_parent_base=>$co{'parent'},
8070                                                      file_name=>$file, file_parent=>$difftree{'from_file'}),
8071                                       -title => "diff"}, 'D');
8072                         if ($have_blame) {
8073                                 print $cgi->a({-href => href(-full=>1, action=>"blame",
8074                                                              file_name=>$file, hash_base=>$commit),
8075                                               -title => "blame"}, 'B');
8076                         }
8077                         # if this is not a feed of a file history
8078                         if (!defined $file_name || $file_name ne $file) {
8079                                 print $cgi->a({-href => href(-full=>1, action=>"history",
8080                                                              file_name=>$file, hash=>$commit),
8081                                               -title => "history"}, 'H');
8082                         }
8083                         $file = esc_path($file);
8084                         print "] ".
8085                               "$file</li>\n";
8086                 }
8087                 if ($format eq 'rss') {
8088                         print "</ul>]]>\n" .
8089                               "</content:encoded>\n" .
8090                               "</item>\n";
8091                 } elsif ($format eq 'atom') {
8092                         print "</ul>\n</div>\n" .
8093                               "</content>\n" .
8094                               "</entry>\n";
8095                 }
8096         }
8097
8098         # end of feed
8099         if ($format eq 'rss') {
8100                 print "</channel>\n</rss>\n";
8101         } elsif ($format eq 'atom') {
8102                 print "</feed>\n";
8103         }
8104 }
8105
8106 sub git_rss {
8107         git_feed('rss');
8108 }
8109
8110 sub git_atom {
8111         git_feed('atom');
8112 }
8113
8114 sub git_opml {
8115         my @list = git_get_projects_list($project_filter, $strict_export);
8116         if (!@list) {
8117                 die_error(404, "No projects found");
8118         }
8119
8120         print $cgi->header(
8121                 -type => 'text/xml',
8122                 -charset => 'utf-8',
8123                 -content_disposition => 'inline; filename="opml.xml"');
8124
8125         my $title = esc_html($site_name);
8126         my $filter = " within subdirectory ";
8127         if (defined $project_filter) {
8128                 $filter .= esc_html($project_filter);
8129         } else {
8130                 $filter = "";
8131         }
8132         print <<XML;
8133 <?xml version="1.0" encoding="utf-8"?>
8134 <opml version="1.0">
8135 <head>
8136   <title>$title OPML Export$filter</title>
8137 </head>
8138 <body>
8139 <outline text="git RSS feeds">
8140 XML
8141
8142         foreach my $pr (@list) {
8143                 my %proj = %$pr;
8144                 my $head = git_get_head_hash($proj{'path'});
8145                 if (!defined $head) {
8146                         next;
8147                 }
8148                 $git_dir = "$projectroot/$proj{'path'}";
8149                 my %co = parse_commit($head);
8150                 if (!%co) {
8151                         next;
8152                 }
8153
8154                 my $path = esc_html(chop_str($proj{'path'}, 25, 5));
8155                 my $rss  = href('project' => $proj{'path'}, 'action' => 'rss', -full => 1);
8156                 my $html = href('project' => $proj{'path'}, 'action' => 'summary', -full => 1);
8157                 print "<outline type=\"rss\" text=\"$path\" title=\"$path\" xmlUrl=\"$rss\" htmlUrl=\"$html\"/>\n";
8158         }
8159         print <<XML;
8160 </outline>
8161 </body>
8162 </opml>
8163 XML
8164 }