Lady’s Gitweb - Gitweb/blob - gitweb.perl

   1 #!/usr/bin/perl
   2
   3 # gitweb - simple web interface to track changes in git repositories
   4 #
   5 # (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
   6 # (C) 2005, Christian Gierke
   7 #
   8 # This program is licensed under the GPLv2
   9
  10 use 5.008;
  11 use strict;
  12 use warnings;
  13 use CGI qw(:standard :escapeHTML -nosticky);
  14 use CGI::Util qw(unescape);
  15 use CGI::Carp qw(fatalsToBrowser set_message);
  16 use Encode;
  17 use Fcntl ':mode';
  18 use File::Find qw();
  19 use File::Basename qw(basename);
  20 use Time::HiRes qw(gettimeofday tv_interval);
  21 binmode STDOUT, ':utf8';
  22
  23 our $t0 = [ gettimeofday() ];
  24 our $number_of_git_cmds = 0;
  25
  26 BEGIN {
  27         CGI->compile() if $ENV{'MOD_PERL'};
  28 }
  29
  30 our $version = "++GIT_VERSION++";
  31
  32 our ($my_url, $my_uri, $base_url, $path_info, $home_link);
  33 sub evaluate_uri {
  34         our $cgi;
  35
  36         our $my_url = $cgi->url();
  37         our $my_uri = $cgi->url(-absolute => 1);
  38
  39         # Base URL for relative URLs in gitweb ($logo, $favicon, ...),
  40         # needed and used only for URLs with nonempty PATH_INFO
  41         our $base_url = $my_url;
  42
  43         # When the script is used as DirectoryIndex, the URL does not contain the name
  44         # of the script file itself, and $cgi->url() fails to strip PATH_INFO, so we
  45         # have to do it ourselves. We make $path_info global because it's also used
  46         # later on.
  47         #
  48         # Another issue with the script being the DirectoryIndex is that the resulting
  49         # $my_url data is not the full script URL: this is good, because we want
  50         # generated links to keep implying the script name if it wasn't explicitly
  51         # indicated in the URL we're handling, but it means that $my_url cannot be used
  52         # as base URL.
  53         # Therefore, if we needed to strip PATH_INFO, then we know that we have
  54         # to build the base URL ourselves:
  55         our $path_info = decode_utf8($ENV{"PATH_INFO"});
  56         if ($path_info) {
  57                 if ($my_url =~ s,\Q$path_info\E$,, &&
  58                     $my_uri =~ s,\Q$path_info\E$,, &&
  59                     defined $ENV{'SCRIPT_NAME'}) {
  60                         $base_url = $cgi->url(-base => 1) . $ENV{'SCRIPT_NAME'};
  61                 }
  62         }
  63
  64         # target of the home link on top of all pages
  65         our $home_link = $my_uri || "/";
  66 }
  67
  68 # core git executable to use
  69 # this can just be "git" if your webserver has a sensible PATH
  70 our $GIT = "++GIT_BINDIR++/git";
  71
  72 # absolute fs-path which will be prepended to the project path
  73 #our $projectroot = "/pub/scm";
  74 our $projectroot = "++GITWEB_PROJECTROOT++";
  75
  76 # fs traversing limit for getting project list
  77 # the number is relative to the projectroot
  78 our $project_maxdepth = "++GITWEB_PROJECT_MAXDEPTH++";
  79
  80 # string of the home link on top of all pages
  81 our $home_link_str = "++GITWEB_HOME_LINK_STR++";
  82
  83 # name of your site or organization to appear in page titles
  84 # replace this with something more descriptive for clearer bookmarks
  85 our $site_name = "++GITWEB_SITENAME++"
  86                  || ($ENV{'SERVER_NAME'} || "Untitled") . " Git";
  87
  88 # html snippet to include in the <head> section of each page
  89 our $site_html_head_string = "++GITWEB_SITE_HTML_HEAD_STRING++";
  90 # filename of html text to include at top of each page
  91 our $site_header = "++GITWEB_SITE_HEADER++";
  92 # html text to include at home page
  93 our $home_text = "++GITWEB_HOMETEXT++";
  94 # filename of html text to include at bottom of each page
  95 our $site_footer = "++GITWEB_SITE_FOOTER++";
  96
  97 # URI of stylesheets
  98 our @stylesheets = ("++GITWEB_CSS++");
  99 # URI of a single stylesheet, which can be overridden in GITWEB_CONFIG.
 100 our $stylesheet = undef;
 101
 102 # URI of GIT logo (72x27 size)
 103 our $logo = "++GITWEB_LOGO++";
 104 # URI of GIT favicon, assumed to be image/png type
 105 our $favicon = "++GITWEB_FAVICON++";
 106 # URI of gitweb.js (JavaScript code for gitweb)
 107 our $javascript = "++GITWEB_JS++";
 108
 109 # URI and label (title) of GIT logo link
 110 #our $logo_url = "http://www.kernel.org/pub/software/scm/git/docs/";
 111 #our $logo_label = "git documentation";
 112 our $logo_url = "http://git-scm.com/";
 113 our $logo_label = "git homepage";
 114
 115 # source of projects list
 116 our $projects_list = "++GITWEB_LIST++";
 117
 118 # the width (in characters) of the projects list "Description" column
 119 our $projects_list_description_width = 25;
 120
 121 # group projects by category on the projects list
 122 # (enabled if this variable evaluates to true)
 123 our $projects_list_group_categories = 0;
 124
 125 # default category if none specified
 126 # (leave the empty string for no category)
 127 our $project_list_default_category = "";
 128
 129 # default order of projects list
 130 # valid values are none, project, descr, owner, and age
 131 our $default_projects_order = "project";
 132
 133 # show repository only if this file exists
 134 # (only effective if this variable evaluates to true)
 135 our $export_ok = "++GITWEB_EXPORT_OK++";
 136
 137 # show repository only if this subroutine returns true
 138 # when given the path to the project, for example:
 139 #    sub { return -e "$_[0]/git-daemon-export-ok"; }
 140 our $export_auth_hook = undef;
 141
 142 # only allow viewing of repositories also shown on the overview page
 143 our $strict_export = "++GITWEB_STRICT_EXPORT++";
 144
 145 # list of git base URLs used for URL to where fetch project from,
 146 # i.e. full URL is "$git_base_url/$project"
 147 our @git_base_url_list = grep { $_ ne '' } ("++GITWEB_BASE_URL++");
 148
 149 # default blob_plain mimetype and default charset for text/plain blob
 150 our $default_blob_plain_mimetype = 'text/plain';
 151 our $default_text_plain_charset  = undef;
 152
 153 # file to use for guessing MIME types before trying /etc/mime.types
 154 # (relative to the current git repository)
 155 our $mimetypes_file = undef;
 156
 157 # assume this charset if line contains non-UTF-8 characters;
 158 # it should be valid encoding (see Encoding::Supported(3pm) for list),
 159 # for which encoding all byte sequences are valid, for example
 160 # 'iso-8859-1' aka 'latin1' (it is decoded without checking, so it
 161 # could be even 'utf-8' for the old behavior)
 162 our $fallback_encoding = 'latin1';
 163
 164 # rename detection options for git-diff and git-diff-tree
 165 # - default is '-M', with the cost proportional to
 166 #   (number of removed files) * (number of new files).
 167 # - more costly is '-C' (which implies '-M'), with the cost proportional to
 168 #   (number of changed files + number of removed files) * (number of new files)
 169 # - even more costly is '-C', '--find-copies-harder' with cost
 170 #   (number of files in the original tree) * (number of new files)
 171 # - one might want to include '-B' option, e.g. '-B', '-M'
 172 our @diff_opts = ('-M'); # taken from git_commit
 173
 174 # Disables features that would allow repository owners to inject script into
 175 # the gitweb domain.
 176 our $prevent_xss = 0;
 177
 178 # Path to the highlight executable to use (must be the one from
 179 # http://www.andre-simon.de due to assumptions about parameters and output).
 180 # Useful if highlight is not installed on your webserver's PATH.
 181 # [Default: highlight]
 182 our $highlight_bin = "++HIGHLIGHT_BIN++";
 183
 184 # information about snapshot formats that gitweb is capable of serving
 185 our %known_snapshot_formats = (
 186         # name => {
 187         #       'display' => display name,
 188         #       'type' => mime type,
 189         #       'suffix' => filename suffix,
 190         #       'format' => --format for git-archive,
 191         #       'compressor' => [compressor command and arguments]
 192         #                       (array reference, optional)
 193         #       'disabled' => boolean (optional)}
 194         #
 195         'tgz' => {
 196                 'display' => 'tar.gz',
 197                 'type' => 'application/x-gzip',
 198                 'suffix' => '.tar.gz',
 199                 'format' => 'tar',
 200                 'compressor' => ['gzip', '-n']},
 201
 202         'tbz2' => {
 203                 'display' => 'tar.bz2',
 204                 'type' => 'application/x-bzip2',
 205                 'suffix' => '.tar.bz2',
 206                 'format' => 'tar',
 207                 'compressor' => ['bzip2']},
 208
 209         'txz' => {
 210                 'display' => 'tar.xz',
 211                 'type' => 'application/x-xz',
 212                 'suffix' => '.tar.xz',
 213                 'format' => 'tar',
 214                 'compressor' => ['xz'],
 215                 'disabled' => 1},
 216
 217         'zip' => {
 218                 'display' => 'zip',
 219                 'type' => 'application/x-zip',
 220                 'suffix' => '.zip',
 221                 'format' => 'zip'},
 222 );
 223
 224 # Aliases so we understand old gitweb.snapshot values in repository
 225 # configuration.
 226 our %known_snapshot_format_aliases = (
 227         'gzip'  => 'tgz',
 228         'bzip2' => 'tbz2',
 229         'xz'    => 'txz',
 230
 231         # backward compatibility: legacy gitweb config support
 232         'x-gzip' => undef, 'gz' => undef,
 233         'x-bzip2' => undef, 'bz2' => undef,
 234         'x-zip' => undef, '' => undef,
 235 );
 236
 237 # Pixel sizes for icons and avatars. If the default font sizes or lineheights
 238 # are changed, it may be appropriate to change these values too via
 239 # $GITWEB_CONFIG.
 240 our %avatar_size = (
 241         'default' => 16,
 242         'double'  => 32
 243 );
 244
 245 # Used to set the maximum load that we will still respond to gitweb queries.
 246 # If server load exceed this value then return "503 server busy" error.
 247 # If gitweb cannot determined server load, it is taken to be 0.
 248 # Leave it undefined (or set to 'undef') to turn off load checking.
 249 our $maxload = 300;
 250
 251 # configuration for 'highlight' (http://www.andre-simon.de/)
 252 # match by basename
 253 our %highlight_basename = (
 254         #'Program' => 'py',
 255         #'Library' => 'py',
 256         'SConstruct' => 'py', # SCons equivalent of Makefile
 257         'Makefile' => 'make',
 258 );
 259 # match by extension
 260 our %highlight_ext = (
 261         # main extensions, defining name of syntax;
 262         # see files in /usr/share/highlight/langDefs/ directory
 263         map { $_ => $_ }
 264                 qw(py c cpp rb java css php sh pl js tex bib xml awk bat ini spec tcl sql make),
 265         # alternate extensions, see /etc/highlight/filetypes.conf
 266         'h' => 'c',
 267         map { $_ => 'sh'  } qw(bash zsh ksh),
 268         map { $_ => 'cpp' } qw(cxx c++ cc),
 269         map { $_ => 'php' } qw(php3 php4 php5 phps),
 270         map { $_ => 'pl'  } qw(perl pm), # perhaps also 'cgi'
 271         map { $_ => 'make'} qw(mak mk),
 272         map { $_ => 'xml' } qw(xhtml html htm),
 273 );
 274
 275 # You define site-wide feature defaults here; override them with
 276 # $GITWEB_CONFIG as necessary.
 277 our %feature = (
 278         # feature => {
 279         #       'sub' => feature-sub (subroutine),
 280         #       'override' => allow-override (boolean),
 281         #       'default' => [ default options...] (array reference)}
 282         #
 283         # if feature is overridable (it means that allow-override has true value),
 284         # then feature-sub will be called with default options as parameters;
 285         # return value of feature-sub indicates if to enable specified feature
 286         #
 287         # if there is no 'sub' key (no feature-sub), then feature cannot be
 288         # overridden
 289         #
 290         # use gitweb_get_feature(<feature>) to retrieve the <feature> value
 291         # (an array) or gitweb_check_feature(<feature>) to check if <feature>
 292         # is enabled
 293
 294         # Enable the 'blame' blob view, showing the last commit that modified
 295         # each line in the file. This can be very CPU-intensive.
 296
 297         # To enable system wide have in $GITWEB_CONFIG
 298         # $feature{'blame'}{'default'} = [1];
 299         # To have project specific config enable override in $GITWEB_CONFIG
 300         # $feature{'blame'}{'override'} = 1;
 301         # and in project config gitweb.blame = 0|1;
 302         'blame' => {
 303                 'sub' => sub { feature_bool('blame', @_) },
 304                 'override' => 0,
 305                 'default' => [0]},
 306
 307         # Enable the 'snapshot' link, providing a compressed archive of any
 308         # tree. This can potentially generate high traffic if you have large
 309         # project.
 310
 311         # Value is a list of formats defined in %known_snapshot_formats that
 312         # you wish to offer.
 313         # To disable system wide have in $GITWEB_CONFIG
 314         # $feature{'snapshot'}{'default'} = [];
 315         # To have project specific config enable override in $GITWEB_CONFIG
 316         # $feature{'snapshot'}{'override'} = 1;
 317         # and in project config, a comma-separated list of formats or "none"
 318         # to disable.  Example: gitweb.snapshot = tbz2,zip;
 319         'snapshot' => {
 320                 'sub' => \&feature_snapshot,
 321                 'override' => 0,
 322                 'default' => ['tgz']},
 323
 324         # Enable text search, which will list the commits which match author,
 325         # committer or commit text to a given string.  Enabled by default.
 326         # Project specific override is not supported.
 327         #
 328         # Note that this controls all search features, which means that if
 329         # it is disabled, then 'grep' and 'pickaxe' search would also be
 330         # disabled.
 331         'search' => {
 332                 'override' => 0,
 333                 'default' => [1]},
 334
 335         # Enable grep search, which will list the files in currently selected
 336         # tree containing the given string. Enabled by default. This can be
 337         # potentially CPU-intensive, of course.
 338         # Note that you need to have 'search' feature enabled too.
 339
 340         # To enable system wide have in $GITWEB_CONFIG
 341         # $feature{'grep'}{'default'} = [1];
 342         # To have project specific config enable override in $GITWEB_CONFIG
 343         # $feature{'grep'}{'override'} = 1;
 344         # and in project config gitweb.grep = 0|1;
 345         'grep' => {
 346                 'sub' => sub { feature_bool('grep', @_) },
 347                 'override' => 0,
 348                 'default' => [1]},
 349
 350         # Enable the pickaxe search, which will list the commits that modified
 351         # a given string in a file. This can be practical and quite faster
 352         # alternative to 'blame', but still potentially CPU-intensive.
 353         # Note that you need to have 'search' feature enabled too.
 354
 355         # To enable system wide have in $GITWEB_CONFIG
 356         # $feature{'pickaxe'}{'default'} = [1];
 357         # To have project specific config enable override in $GITWEB_CONFIG
 358         # $feature{'pickaxe'}{'override'} = 1;
 359         # and in project config gitweb.pickaxe = 0|1;
 360         'pickaxe' => {
 361                 'sub' => sub { feature_bool('pickaxe', @_) },
 362                 'override' => 0,
 363                 'default' => [1]},
 364
 365         # Enable showing size of blobs in a 'tree' view, in a separate
 366         # column, similar to what 'ls -l' does.  This cost a bit of IO.
 367
 368         # To disable system wide have in $GITWEB_CONFIG
 369         # $feature{'show-sizes'}{'default'} = [0];
 370         # To have project specific config enable override in $GITWEB_CONFIG
 371         # $feature{'show-sizes'}{'override'} = 1;
 372         # and in project config gitweb.showsizes = 0|1;
 373         'show-sizes' => {
 374                 'sub' => sub { feature_bool('showsizes', @_) },
 375                 'override' => 0,
 376                 'default' => [1]},
 377
 378         # Make gitweb use an alternative format of the URLs which can be
 379         # more readable and natural-looking: project name is embedded
 380         # directly in the path and the query string contains other
 381         # auxiliary information. All gitweb installations recognize
 382         # URL in either format; this configures in which formats gitweb
 383         # generates links.
 384
 385         # To enable system wide have in $GITWEB_CONFIG
 386         # $feature{'pathinfo'}{'default'} = [1];
 387         # Project specific override is not supported.
 388
 389         # Note that you will need to change the default location of CSS,
 390         # favicon, logo and possibly other files to an absolute URL. Also,
 391         # if gitweb.cgi serves as your indexfile, you will need to force
 392         # $my_uri to contain the script name in your $GITWEB_CONFIG.
 393         'pathinfo' => {
 394                 'override' => 0,
 395                 'default' => [0]},
 396
 397         # Make gitweb consider projects in project root subdirectories
 398         # to be forks of existing projects. Given project $projname.git,
 399         # projects matching $projname/*.git will not be shown in the main
 400         # projects list, instead a '+' mark will be added to $projname
 401         # there and a 'forks' view will be enabled for the project, listing
 402         # all the forks. If project list is taken from a file, forks have
 403         # to be listed after the main project.
 404
 405         # To enable system wide have in $GITWEB_CONFIG
 406         # $feature{'forks'}{'default'} = [1];
 407         # Project specific override is not supported.
 408         'forks' => {
 409                 'override' => 0,
 410                 'default' => [0]},
 411
 412         # Insert custom links to the action bar of all project pages.
 413         # This enables you mainly to link to third-party scripts integrating
 414         # into gitweb; e.g. git-browser for graphical history representation
 415         # or custom web-based repository administration interface.
 416
 417         # The 'default' value consists of a list of triplets in the form
 418         # (label, link, position) where position is the label after which
 419         # to insert the link and link is a format string where %n expands
 420         # to the project name, %f to the project path within the filesystem,
 421         # %h to the current hash (h gitweb parameter) and %b to the current
 422         # hash base (hb gitweb parameter); %% expands to %.
 423
 424         # To enable system wide have in $GITWEB_CONFIG e.g.
 425         # $feature{'actions'}{'default'} = [('graphiclog',
 426         #       '/git-browser/by-commit.html?r=%n', 'summary')];
 427         # Project specific override is not supported.
 428         'actions' => {
 429                 'override' => 0,
 430                 'default' => []},
 431
 432         # Allow gitweb scan project content tags of project repository,
 433         # and display the popular Web 2.0-ish "tag cloud" near the projects
 434         # list.  Note that this is something COMPLETELY different from the
 435         # normal Git tags.
 436
 437         # gitweb by itself can show existing tags, but it does not handle
 438         # tagging itself; you need to do it externally, outside gitweb.
 439         # The format is described in git_get_project_ctags() subroutine.
 440         # You may want to install the HTML::TagCloud Perl module to get
 441         # a pretty tag cloud instead of just a list of tags.
 442
 443         # To enable system wide have in $GITWEB_CONFIG
 444         # $feature{'ctags'}{'default'} = [1];
 445         # Project specific override is not supported.
 446
 447         # In the future whether ctags editing is enabled might depend
 448         # on the value, but using 1 should always mean no editing of ctags.
 449         'ctags' => {
 450                 'override' => 0,
 451                 'default' => [0]},
 452
 453         # The maximum number of patches in a patchset generated in patch
 454         # view. Set this to 0 or undef to disable patch view, or to a
 455         # negative number to remove any limit.
 456
 457         # To disable system wide have in $GITWEB_CONFIG
 458         # $feature{'patches'}{'default'} = [0];
 459         # To have project specific config enable override in $GITWEB_CONFIG
 460         # $feature{'patches'}{'override'} = 1;
 461         # and in project config gitweb.patches = 0|n;
 462         # where n is the maximum number of patches allowed in a patchset.
 463         'patches' => {
 464                 'sub' => \&feature_patches,
 465                 'override' => 0,
 466                 'default' => [16]},
 467
 468         # Avatar support. When this feature is enabled, views such as
 469         # shortlog or commit will display an avatar associated with
 470         # the email of the committer(s) and/or author(s).
 471
 472         # Currently available providers are gravatar and picon.
 473         # If an unknown provider is specified, the feature is disabled.
 474
 475         # Gravatar depends on Digest::MD5.
 476         # Picon currently relies on the indiana.edu database.
 477
 478         # To enable system wide have in $GITWEB_CONFIG
 479         # $feature{'avatar'}{'default'} = ['<provider>'];
 480         # where <provider> is either gravatar or picon.
 481         # To have project specific config enable override in $GITWEB_CONFIG
 482         # $feature{'avatar'}{'override'} = 1;
 483         # and in project config gitweb.avatar = <provider>;
 484         'avatar' => {
 485                 'sub' => \&feature_avatar,
 486                 'override' => 0,
 487                 'default' => ['']},
 488
 489         # Enable displaying how much time and how many git commands
 490         # it took to generate and display page.  Disabled by default.
 491         # Project specific override is not supported.
 492         'timed' => {
 493                 'override' => 0,
 494                 'default' => [0]},
 495
 496         # Enable turning some links into links to actions which require
 497         # JavaScript to run (like 'blame_incremental').  Not enabled by
 498         # default.  Project specific override is currently not supported.
 499         'javascript-actions' => {
 500                 'override' => 0,
 501                 'default' => [0]},
 502
 503         # Enable and configure ability to change common timezone for dates
 504         # in gitweb output via JavaScript.  Enabled by default.
 505         # Project specific override is not supported.
 506         'javascript-timezone' => {
 507                 'override' => 0,
 508                 'default' => [
 509                         'local',     # default timezone: 'utc', 'local', or '(-|+)HHMM' format,
 510                                      # or undef to turn off this feature
 511                         'gitweb_tz', # name of cookie where to store selected timezone
 512                         'datetime',  # CSS class used to mark up dates for manipulation
 513                 ]},
 514
 515         # Syntax highlighting support. This is based on Daniel Svensson's
 516         # and Sham Chukoury's work in gitweb-xmms2.git.
 517         # It requires the 'highlight' program present in $PATH,
 518         # and therefore is disabled by default.
 519
 520         # To enable system wide have in $GITWEB_CONFIG
 521         # $feature{'highlight'}{'default'} = [1];
 522
 523         'highlight' => {
 524                 'sub' => sub { feature_bool('highlight', @_) },
 525                 'override' => 0,
 526                 'default' => [0]},
 527
 528         # Enable displaying of remote heads in the heads list
 529
 530         # To enable system wide have in $GITWEB_CONFIG
 531         # $feature{'remote_heads'}{'default'} = [1];
 532         # To have project specific config enable override in $GITWEB_CONFIG
 533         # $feature{'remote_heads'}{'override'} = 1;
 534         # and in project config gitweb.remote_heads = 0|1;
 535         'remote_heads' => {
 536                 'sub' => sub { feature_bool('remote_heads', @_) },
 537                 'override' => 0,
 538                 'default' => [0]},
 539 );
 540
 541 sub gitweb_get_feature {
 542         my ($name) = @_;
 543         return unless exists $feature{$name};
 544         my ($sub, $override, @defaults) = (
 545                 $feature{$name}{'sub'},
 546                 $feature{$name}{'override'},
 547                 @{$feature{$name}{'default'}});
 548         # project specific override is possible only if we have project
 549         our $git_dir; # global variable, declared later
 550         if (!$override || !defined $git_dir) {
 551                 return @defaults;
 552         }
 553         if (!defined $sub) {
 554                 warn "feature $name is not overridable";
 555                 return @defaults;
 556         }
 557         return $sub->(@defaults);
 558 }
 559
 560 # A wrapper to check if a given feature is enabled.
 561 # With this, you can say
 562 #
 563 #   my $bool_feat = gitweb_check_feature('bool_feat');
 564 #   gitweb_check_feature('bool_feat') or somecode;
 565 #
 566 # instead of
 567 #
 568 #   my ($bool_feat) = gitweb_get_feature('bool_feat');
 569 #   (gitweb_get_feature('bool_feat'))[0] or somecode;
 570 #
 571 sub gitweb_check_feature {
 572         return (gitweb_get_feature(@_))[0];
 573 }
 574
 575
 576 sub feature_bool {
 577         my $key = shift;
 578         my ($val) = git_get_project_config($key, '--bool');
 579
 580         if (!defined $val) {
 581                 return ($_[0]);
 582         } elsif ($val eq 'true') {
 583                 return (1);
 584         } elsif ($val eq 'false') {
 585                 return (0);
 586         }
 587 }
 588
 589 sub feature_snapshot {
 590         my (@fmts) = @_;
 591
 592         my ($val) = git_get_project_config('snapshot');
 593
 594         if ($val) {
 595                 @fmts = ($val eq 'none' ? () : split /\s*[,\s]\s*/, $val);
 596         }
 597
 598         return @fmts;
 599 }
 600
 601 sub feature_patches {
 602         my @val = (git_get_project_config('patches', '--int'));
 603
 604         if (@val) {
 605                 return @val;
 606         }
 607
 608         return ($_[0]);
 609 }
 610
 611 sub feature_avatar {
 612         my @val = (git_get_project_config('avatar'));
 613
 614         return @val ? @val : @_;
 615 }
 616
 617 # checking HEAD file with -e is fragile if the repository was
 618 # initialized long time ago (i.e. symlink HEAD) and was pack-ref'ed
 619 # and then pruned.
 620 sub check_head_link {
 621         my ($dir) = @_;
 622         my $headfile = "$dir/HEAD";
 623         return ((-e $headfile) ||
 624                 (-l $headfile && readlink($headfile) =~ /^refs\/heads\//));
 625 }
 626
 627 sub check_export_ok {
 628         my ($dir) = @_;
 629         return (check_head_link($dir) &&
 630                 (!$export_ok || -e "$dir/$export_ok") &&
 631                 (!$export_auth_hook || $export_auth_hook->($dir)));
 632 }
 633
 634 # process alternate names for backward compatibility
 635 # filter out unsupported (unknown) snapshot formats
 636 sub filter_snapshot_fmts {
 637         my @fmts = @_;
 638
 639         @fmts = map {
 640                 exists $known_snapshot_format_aliases{$_} ?
 641                        $known_snapshot_format_aliases{$_} : $_} @fmts;
 642         @fmts = grep {
 643                 exists $known_snapshot_formats{$_} &&
 644                 !$known_snapshot_formats{$_}{'disabled'}} @fmts;
 645 }
 646
 647 # If it is set to code reference, it is code that it is to be run once per
 648 # request, allowing updating configurations that change with each request,
 649 # while running other code in config file only once.
 650 #
 651 # Otherwise, if it is false then gitweb would process config file only once;
 652 # if it is true then gitweb config would be run for each request.
 653 our $per_request_config = 1;
 654
 655 # read and parse gitweb config file given by its parameter.
 656 # returns true on success, false on recoverable error, allowing
 657 # to chain this subroutine, using first file that exists.
 658 # dies on errors during parsing config file, as it is unrecoverable.
 659 sub read_config_file {
 660         my $filename = shift;
 661         return unless defined $filename;
 662         # die if there are errors parsing config file
 663         if (-e $filename) {
 664                 do $filename;
 665                 die $@ if $@;
 666                 return 1;
 667         }
 668         return;
 669 }
 670
 671 our ($GITWEB_CONFIG, $GITWEB_CONFIG_SYSTEM, $GITWEB_CONFIG_COMMON);
 672 sub evaluate_gitweb_config {
 673         our $GITWEB_CONFIG = $ENV{'GITWEB_CONFIG'} || "++GITWEB_CONFIG++";
 674         our $GITWEB_CONFIG_SYSTEM = $ENV{'GITWEB_CONFIG_SYSTEM'} || "++GITWEB_CONFIG_SYSTEM++";
 675         our $GITWEB_CONFIG_COMMON = $ENV{'GITWEB_CONFIG_COMMON'} || "++GITWEB_CONFIG_COMMON++";
 676
 677         # Protect agains duplications of file names, to not read config twice.
 678         # Only one of $GITWEB_CONFIG and $GITWEB_CONFIG_SYSTEM is used, so
 679         # there possibility of duplication of filename there doesn't matter.
 680         $GITWEB_CONFIG = ""        if ($GITWEB_CONFIG eq $GITWEB_CONFIG_COMMON);
 681         $GITWEB_CONFIG_SYSTEM = "" if ($GITWEB_CONFIG_SYSTEM eq $GITWEB_CONFIG_COMMON);
 682
 683         # Common system-wide settings for convenience.
 684         # Those settings can be ovverriden by GITWEB_CONFIG or GITWEB_CONFIG_SYSTEM.
 685         read_config_file($GITWEB_CONFIG_COMMON);
 686
 687         # Use first config file that exists.  This means use the per-instance
 688         # GITWEB_CONFIG if exists, otherwise use GITWEB_SYSTEM_CONFIG.
 689         read_config_file($GITWEB_CONFIG) and return;
 690         read_config_file($GITWEB_CONFIG_SYSTEM);
 691 }
 692
 693 # Get loadavg of system, to compare against $maxload.
 694 # Currently it requires '/proc/loadavg' present to get loadavg;
 695 # if it is not present it returns 0, which means no load checking.
 696 sub get_loadavg {
 697         if( -e '/proc/loadavg' ){
 698                 open my $fd, '<', '/proc/loadavg'
 699                         or return 0;
 700                 my @load = split(/\s+/, scalar <$fd>);
 701                 close $fd;
 702
 703                 # The first three columns measure CPU and IO utilization of the last one,
 704                 # five, and 10 minute periods.  The fourth column shows the number of
 705                 # currently running processes and the total number of processes in the m/n
 706                 # format.  The last column displays the last process ID used.
 707                 return $load[0] || 0;
 708         }
 709         # additional checks for load average should go here for things that don't export
 710         # /proc/loadavg
 711
 712         return 0;
 713 }
 714
 715 # version of the core git binary
 716 our $git_version;
 717 sub evaluate_git_version {
 718         our $git_version = qx("$GIT" --version) =~ m/git version (.*)$/ ? $1 : "unknown";
 719         $number_of_git_cmds++;
 720 }
 721
 722 sub check_loadavg {
 723         if (defined $maxload && get_loadavg() > $maxload) {
 724                 die_error(503, "The load average on the server is too high");
 725         }
 726 }
 727
 728 # ======================================================================
 729 # input validation and dispatch
 730
 731 # input parameters can be collected from a variety of sources (presently, CGI
 732 # and PATH_INFO), so we define an %input_params hash that collects them all
 733 # together during validation: this allows subsequent uses (e.g. href()) to be
 734 # agnostic of the parameter origin
 735
 736 our %input_params = ();
 737
 738 # input parameters are stored with the long parameter name as key. This will
 739 # also be used in the href subroutine to convert parameters to their CGI
 740 # equivalent, and since the href() usage is the most frequent one, we store
 741 # the name -> CGI key mapping here, instead of the reverse.
 742 #
 743 # XXX: Warning: If you touch this, check the search form for updating,
 744 # too.
 745
 746 our @cgi_param_mapping = (
 747         project => "p",
 748         action => "a",
 749         file_name => "f",
 750         file_parent => "fp",
 751         hash => "h",
 752         hash_parent => "hp",
 753         hash_base => "hb",
 754         hash_parent_base => "hpb",
 755         page => "pg",
 756         order => "o",
 757         searchtext => "s",
 758         searchtype => "st",
 759         snapshot_format => "sf",
 760         extra_options => "opt",
 761         search_use_regexp => "sr",
 762         ctag => "by_tag",
 763         diff_style => "ds",
 764         project_filter => "pf",
 765         # this must be last entry (for manipulation from JavaScript)
 766         javascript => "js"
 767 );
 768 our %cgi_param_mapping = @cgi_param_mapping;
 769
 770 # we will also need to know the possible actions, for validation
 771 our %actions = (
 772         "blame" => \&git_blame,
 773         "blame_incremental" => \&git_blame_incremental,
 774         "blame_data" => \&git_blame_data,
 775         "blobdiff" => \&git_blobdiff,
 776         "blobdiff_plain" => \&git_blobdiff_plain,
 777         "blob" => \&git_blob,
 778         "blob_plain" => \&git_blob_plain,
 779         "commitdiff" => \&git_commitdiff,
 780         "commitdiff_plain" => \&git_commitdiff_plain,
 781         "commit" => \&git_commit,
 782         "forks" => \&git_forks,
 783         "heads" => \&git_heads,
 784         "history" => \&git_history,
 785         "log" => \&git_log,
 786         "patch" => \&git_patch,
 787         "patches" => \&git_patches,
 788         "remotes" => \&git_remotes,
 789         "rss" => \&git_rss,
 790         "atom" => \&git_atom,
 791         "search" => \&git_search,
 792         "search_help" => \&git_search_help,
 793         "shortlog" => \&git_shortlog,
 794         "summary" => \&git_summary,
 795         "tag" => \&git_tag,
 796         "tags" => \&git_tags,
 797         "tree" => \&git_tree,
 798         "snapshot" => \&git_snapshot,
 799         "object" => \&git_object,
 800         # those below don't need $project
 801         "opml" => \&git_opml,
 802         "project_list" => \&git_project_list,
 803         "project_index" => \&git_project_index,
 804 );
 805
 806 # finally, we have the hash of allowed extra_options for the commands that
 807 # allow them
 808 our %allowed_options = (
 809         "--no-merges" => [ qw(rss atom log shortlog history) ],
 810 );
 811
 812 # fill %input_params with the CGI parameters. All values except for 'opt'
 813 # should be single values, but opt can be an array. We should probably
 814 # build an array of parameters that can be multi-valued, but since for the time
 815 # being it's only this one, we just single it out
 816 sub evaluate_query_params {
 817         our $cgi;
 818
 819         while (my ($name, $symbol) = each %cgi_param_mapping) {
 820                 if ($symbol eq 'opt') {
 821                         $input_params{$name} = [ map { decode_utf8($_) } $cgi->param($symbol) ];
 822                 } else {
 823                         $input_params{$name} = decode_utf8($cgi->param($symbol));
 824                 }
 825         }
 826 }
 827
 828 # now read PATH_INFO and update the parameter list for missing parameters
 829 sub evaluate_path_info {
 830         return if defined $input_params{'project'};
 831         return if !$path_info;
 832         $path_info =~ s,^/+,,;
 833         return if !$path_info;
 834
 835         # find which part of PATH_INFO is project
 836         my $project = $path_info;
 837         $project =~ s,/+$,,;
 838         while ($project && !check_head_link("$projectroot/$project")) {
 839                 $project =~ s,/*[^/]*$,,;
 840         }
 841         return unless $project;
 842         $input_params{'project'} = $project;
 843
 844         # do not change any parameters if an action is given using the query string
 845         return if $input_params{'action'};
 846         $path_info =~ s,^\Q$project\E/*,,;
 847
 848         # next, check if we have an action
 849         my $action = $path_info;
 850         $action =~ s,/.*$,,;
 851         if (exists $actions{$action}) {
 852                 $path_info =~ s,^$action/*,,;
 853                 $input_params{'action'} = $action;
 854         }
 855
 856         # list of actions that want hash_base instead of hash, but can have no
 857         # pathname (f) parameter
 858         my @wants_base = (
 859                 'tree',
 860                 'history',
 861         );
 862
 863         # we want to catch, among others
 864         # [$hash_parent_base[:$file_parent]..]$hash_parent[:$file_name]
 865         my ($parentrefname, $parentpathname, $refname, $pathname) =
 866                 ($path_info =~ /^(?:(.+?)(?::(.+))?\.\.)?([^:]+?)?(?::(.+))?$/);
 867
 868         # first, analyze the 'current' part
 869         if (defined $pathname) {
 870                 # we got "branch:filename" or "branch:dir/"
 871                 # we could use git_get_type(branch:pathname), but:
 872                 # - it needs $git_dir
 873                 # - it does a git() call
 874                 # - the convention of terminating directories with a slash
 875                 #   makes it superfluous
 876                 # - embedding the action in the PATH_INFO would make it even
 877                 #   more superfluous
 878                 $pathname =~ s,^/+,,;
 879                 if (!$pathname || substr($pathname, -1) eq "/") {
 880                         $input_params{'action'} ||= "tree";
 881                         $pathname =~ s,/$,,;
 882                 } else {
 883                         # the default action depends on whether we had parent info
 884                         # or not
 885                         if ($parentrefname) {
 886                                 $input_params{'action'} ||= "blobdiff_plain";
 887                         } else {
 888                                 $input_params{'action'} ||= "blob_plain";
 889                         }
 890                 }
 891                 $input_params{'hash_base'} ||= $refname;
 892                 $input_params{'file_name'} ||= $pathname;
 893         } elsif (defined $refname) {
 894                 # we got "branch". In this case we have to choose if we have to
 895                 # set hash or hash_base.
 896                 #
 897                 # Most of the actions without a pathname only want hash to be
 898                 # set, except for the ones specified in @wants_base that want
 899                 # hash_base instead. It should also be noted that hand-crafted
 900                 # links having 'history' as an action and no pathname or hash
 901                 # set will fail, but that happens regardless of PATH_INFO.
 902                 if (defined $parentrefname) {
 903                         # if there is parent let the default be 'shortlog' action
 904                         # (for http://git.example.com/repo.git/A..B links); if there
 905                         # is no parent, dispatch will detect type of object and set
 906                         # action appropriately if required (if action is not set)
 907                         $input_params{'action'} ||= "shortlog";
 908                 }
 909                 if ($input_params{'action'} &&
 910                     grep { $_ eq $input_params{'action'} } @wants_base) {
 911                         $input_params{'hash_base'} ||= $refname;
 912                 } else {
 913                         $input_params{'hash'} ||= $refname;
 914                 }
 915         }
 916
 917         # next, handle the 'parent' part, if present
 918         if (defined $parentrefname) {
 919                 # a missing pathspec defaults to the 'current' filename, allowing e.g.
 920                 # someproject/blobdiff/oldrev..newrev:/filename
 921                 if ($parentpathname) {
 922                         $parentpathname =~ s,^/+,,;
 923                         $parentpathname =~ s,/$,,;
 924                         $input_params{'file_parent'} ||= $parentpathname;
 925                 } else {
 926                         $input_params{'file_parent'} ||= $input_params{'file_name'};
 927                 }
 928                 # we assume that hash_parent_base is wanted if a path was specified,
 929                 # or if the action wants hash_base instead of hash
 930                 if (defined $input_params{'file_parent'} ||
 931                         grep { $_ eq $input_params{'action'} } @wants_base) {
 932                         $input_params{'hash_parent_base'} ||= $parentrefname;
 933                 } else {
 934                         $input_params{'hash_parent'} ||= $parentrefname;
 935                 }
 936         }
 937
 938         # for the snapshot action, we allow URLs in the form
 939         # $project/snapshot/$hash.ext
 940         # where .ext determines the snapshot and gets removed from the
 941         # passed $refname to provide the $hash.
 942         #
 943         # To be able to tell that $refname includes the format extension, we
 944         # require the following two conditions to be satisfied:
 945         # - the hash input parameter MUST have been set from the $refname part
 946         #   of the URL (i.e. they must be equal)
 947         # - the snapshot format MUST NOT have been defined already (e.g. from
 948         #   CGI parameter sf)
 949         # It's also useless to try any matching unless $refname has a dot,
 950         # so we check for that too
 951         if (defined $input_params{'action'} &&
 952                 $input_params{'action'} eq 'snapshot' &&
 953                 defined $refname && index($refname, '.') != -1 &&
 954                 $refname eq $input_params{'hash'} &&
 955                 !defined $input_params{'snapshot_format'}) {
 956                 # We loop over the known snapshot formats, checking for
 957                 # extensions. Allowed extensions are both the defined suffix
 958                 # (which includes the initial dot already) and the snapshot
 959                 # format key itself, with a prepended dot
 960                 while (my ($fmt, $opt) = each %known_snapshot_formats) {
 961                         my $hash = $refname;
 962                         unless ($hash =~ s/(\Q$opt->{'suffix'}\E|\Q.$fmt\E)$//) {
 963                                 next;
 964                         }
 965                         my $sfx = $1;
 966                         # a valid suffix was found, so set the snapshot format
 967                         # and reset the hash parameter
 968                         $input_params{'snapshot_format'} = $fmt;
 969                         $input_params{'hash'} = $hash;
 970                         # we also set the format suffix to the one requested
 971                         # in the URL: this way a request for e.g. .tgz returns
 972                         # a .tgz instead of a .tar.gz
 973                         $known_snapshot_formats{$fmt}{'suffix'} = $sfx;
 974                         last;
 975                 }
 976         }
 977 }
 978
 979 our ($action, $project, $file_name, $file_parent, $hash, $hash_parent, $hash_base,
 980      $hash_parent_base, @extra_options, $page, $searchtype, $search_use_regexp,
 981      $searchtext, $search_regexp, $project_filter);
 982 sub evaluate_and_validate_params {
 983         our $action = $input_params{'action'};
 984         if (defined $action) {
 985                 if (!validate_action($action)) {
 986                         die_error(400, "Invalid action parameter");
 987                 }
 988         }
 989
 990         # parameters which are pathnames
 991         our $project = $input_params{'project'};
 992         if (defined $project) {
 993                 if (!validate_project($project)) {
 994                         undef $project;
 995                         die_error(404, "No such project");
 996                 }
 997         }
 998
 999         our $project_filter = $input_params{'project_filter'};
1000         if (defined $project_filter) {
1001                 if (!validate_pathname($project_filter)) {
1002                         die_error(404, "Invalid project_filter parameter");
1003                 }
1004         }
1005
1006         our $file_name = $input_params{'file_name'};
1007         if (defined $file_name) {
1008                 if (!validate_pathname($file_name)) {
1009                         die_error(400, "Invalid file parameter");
1010                 }
1011         }
1012
1013         our $file_parent = $input_params{'file_parent'};
1014         if (defined $file_parent) {
1015                 if (!validate_pathname($file_parent)) {
1016                         die_error(400, "Invalid file parent parameter");
1017                 }
1018         }
1019
1020         # parameters which are refnames
1021         our $hash = $input_params{'hash'};
1022         if (defined $hash) {
1023                 if (!validate_refname($hash)) {
1024                         die_error(400, "Invalid hash parameter");
1025                 }
1026         }
1027
1028         our $hash_parent = $input_params{'hash_parent'};
1029         if (defined $hash_parent) {
1030                 if (!validate_refname($hash_parent)) {
1031                         die_error(400, "Invalid hash parent parameter");
1032                 }
1033         }
1034
1035         our $hash_base = $input_params{'hash_base'};
1036         if (defined $hash_base) {
1037                 if (!validate_refname($hash_base)) {
1038                         die_error(400, "Invalid hash base parameter");
1039                 }
1040         }
1041
1042         our @extra_options = @{$input_params{'extra_options'}};
1043         # @extra_options is always defined, since it can only be (currently) set from
1044         # CGI, and $cgi->param() returns the empty array in array context if the param
1045         # is not set
1046         foreach my $opt (@extra_options) {
1047                 if (not exists $allowed_options{$opt}) {
1048                         die_error(400, "Invalid option parameter");
1049                 }
1050                 if (not grep(/^$action$/, @{$allowed_options{$opt}})) {
1051                         die_error(400, "Invalid option parameter for this action");
1052                 }
1053         }
1054
1055         our $hash_parent_base = $input_params{'hash_parent_base'};
1056         if (defined $hash_parent_base) {
1057                 if (!validate_refname($hash_parent_base)) {
1058                         die_error(400, "Invalid hash parent base parameter");
1059                 }
1060         }
1061
1062         # other parameters
1063         our $page = $input_params{'page'};
1064         if (defined $page) {
1065                 if ($page =~ m/[^0-9]/) {
1066                         die_error(400, "Invalid page parameter");
1067                 }
1068         }
1069
1070         our $searchtype = $input_params{'searchtype'};
1071         if (defined $searchtype) {
1072                 if ($searchtype =~ m/[^a-z]/) {
1073                         die_error(400, "Invalid searchtype parameter");
1074                 }
1075         }
1076
1077         our $search_use_regexp = $input_params{'search_use_regexp'};
1078
1079         our $searchtext = $input_params{'searchtext'};
1080         our $search_regexp;
1081         if (defined $searchtext) {
1082                 if (length($searchtext) < 2) {
1083                         die_error(403, "At least two characters are required for search parameter");
1084                 }
1085                 $search_regexp = $search_use_regexp ? $searchtext : quotemeta $searchtext;
1086         }
1087 }
1088
1089 # path to the current git repository
1090 our $git_dir;
1091 sub evaluate_git_dir {
1092         our $git_dir = "$projectroot/$project" if $project;
1093 }
1094
1095 our (@snapshot_fmts, $git_avatar);
1096 sub configure_gitweb_features {
1097         # list of supported snapshot formats
1098         our @snapshot_fmts = gitweb_get_feature('snapshot');
1099         @snapshot_fmts = filter_snapshot_fmts(@snapshot_fmts);
1100
1101         # check that the avatar feature is set to a known provider name,
1102         # and for each provider check if the dependencies are satisfied.
1103         # if the provider name is invalid or the dependencies are not met,
1104         # reset $git_avatar to the empty string.
1105         our ($git_avatar) = gitweb_get_feature('avatar');
1106         if ($git_avatar eq 'gravatar') {
1107                 $git_avatar = '' unless (eval { require Digest::MD5; 1; });
1108         } elsif ($git_avatar eq 'picon') {
1109                 # no dependencies
1110         } else {
1111                 $git_avatar = '';
1112         }
1113 }
1114
1115 # custom error handler: 'die <message>' is Internal Server Error
1116 sub handle_errors_html {
1117         my $msg = shift; # it is already HTML escaped
1118
1119         # to avoid infinite loop where error occurs in die_error,
1120         # change handler to default handler, disabling handle_errors_html
1121         set_message("Error occured when inside die_error:\n$msg");
1122
1123         # you cannot jump out of die_error when called as error handler;
1124         # the subroutine set via CGI::Carp::set_message is called _after_
1125         # HTTP headers are already written, so it cannot write them itself
1126         die_error(undef, undef, $msg, -error_handler => 1, -no_http_header => 1);
1127 }
1128 set_message(\&handle_errors_html);
1129
1130 # dispatch
1131 sub dispatch {
1132         if (!defined $action) {
1133                 if (defined $hash) {
1134                         $action = git_get_type($hash);
1135                         $action or die_error(404, "Object does not exist");
1136                 } elsif (defined $hash_base && defined $file_name) {
1137                         $action = git_get_type("$hash_base:$file_name");
1138                         $action or die_error(404, "File or directory does not exist");
1139                 } elsif (defined $project) {
1140                         $action = 'summary';
1141                 } else {
1142                         $action = 'project_list';
1143                 }
1144         }
1145         if (!defined($actions{$action})) {
1146                 die_error(400, "Unknown action");
1147         }
1148         if ($action !~ m/^(?:opml|project_list|project_index)$/ &&
1149             !$project) {
1150                 die_error(400, "Project needed");
1151         }
1152         $actions{$action}->();
1153 }
1154
1155 sub reset_timer {
1156         our $t0 = [ gettimeofday() ]
1157                 if defined $t0;
1158         our $number_of_git_cmds = 0;
1159 }
1160
1161 our $first_request = 1;
1162 sub run_request {
1163         reset_timer();
1164
1165         evaluate_uri();
1166         if ($first_request) {
1167                 evaluate_gitweb_config();
1168                 evaluate_git_version();
1169         }
1170         if ($per_request_config) {
1171                 if (ref($per_request_config) eq 'CODE') {
1172                         $per_request_config->();
1173                 } elsif (!$first_request) {
1174                         evaluate_gitweb_config();
1175                 }
1176         }
1177         check_loadavg();
1178
1179         # $projectroot and $projects_list might be set in gitweb config file
1180         $projects_list ||= $projectroot;
1181
1182         evaluate_query_params();
1183         evaluate_path_info();
1184         evaluate_and_validate_params();
1185         evaluate_git_dir();
1186
1187         configure_gitweb_features();
1188
1189         dispatch();
1190 }
1191
1192 our $is_last_request = sub { 1 };
1193 our ($pre_dispatch_hook, $post_dispatch_hook, $pre_listen_hook);
1194 our $CGI = 'CGI';
1195 our $cgi;
1196 sub configure_as_fcgi {
1197         require CGI::Fast;
1198         our $CGI = 'CGI::Fast';
1199
1200         my $request_number = 0;
1201         # let each child service 100 requests
1202         our $is_last_request = sub { ++$request_number > 100 };
1203 }
1204 sub evaluate_argv {
1205         my $script_name = $ENV{'SCRIPT_NAME'} || $ENV{'SCRIPT_FILENAME'} || __FILE__;
1206         configure_as_fcgi()
1207                 if $script_name =~ /\.fcgi$/;
1208
1209         return unless (@ARGV);
1210
1211         require Getopt::Long;
1212         Getopt::Long::GetOptions(
1213                 'fastcgi|fcgi|f' => \&configure_as_fcgi,
1214                 'nproc|n=i' => sub {
1215                         my ($arg, $val) = @_;
1216                         return unless eval { require FCGI::ProcManager; 1; };
1217                         my $proc_manager = FCGI::ProcManager->new({
1218                                 n_processes => $val,
1219                         });
1220                         our $pre_listen_hook    = sub { $proc_manager->pm_manage()        };
1221                         our $pre_dispatch_hook  = sub { $proc_manager->pm_pre_dispatch()  };
1222                         our $post_dispatch_hook = sub { $proc_manager->pm_post_dispatch() };
1223                 },
1224         );
1225 }
1226
1227 sub run {
1228         evaluate_argv();
1229
1230         $first_request = 1;
1231         $pre_listen_hook->()
1232                 if $pre_listen_hook;
1233
1234  REQUEST:
1235         while ($cgi = $CGI->new()) {
1236                 $pre_dispatch_hook->()
1237                         if $pre_dispatch_hook;
1238
1239                 run_request();
1240
1241                 $post_dispatch_hook->()
1242                         if $post_dispatch_hook;
1243                 $first_request = 0;
1244
1245                 last REQUEST if ($is_last_request->());
1246         }
1247
1248  DONE_GITWEB:
1249         1;
1250 }
1251
1252 run();
1253
1254 if (defined caller) {
1255         # wrapped in a subroutine processing requests,
1256         # e.g. mod_perl with ModPerl::Registry, or PSGI with Plack::App::WrapCGI
1257         return;
1258 } else {
1259         # pure CGI script, serving single request
1260         exit;
1261 }
1262
1263 ## ======================================================================
1264 ## action links
1265
1266 # possible values of extra options
1267 # -full => 0|1      - use absolute/full URL ($my_uri/$my_url as base)
1268 # -replay => 1      - start from a current view (replay with modifications)
1269 # -path_info => 0|1 - don't use/use path_info URL (if possible)
1270 # -anchor => ANCHOR - add #ANCHOR to end of URL, implies -replay if used alone
1271 sub href {
1272         my %params = @_;
1273         # default is to use -absolute url() i.e. $my_uri
1274         my $href = $params{-full} ? $my_url : $my_uri;
1275
1276         # implicit -replay, must be first of implicit params
1277         $params{-replay} = 1 if (keys %params == 1 && $params{-anchor});
1278
1279         $params{'project'} = $project unless exists $params{'project'};
1280
1281         if ($params{-replay}) {
1282                 while (my ($name, $symbol) = each %cgi_param_mapping) {
1283                         if (!exists $params{$name}) {
1284                                 $params{$name} = $input_params{$name};
1285                         }
1286                 }
1287         }
1288
1289         my $use_pathinfo = gitweb_check_feature('pathinfo');
1290         if (defined $params{'project'} &&
1291             (exists $params{-path_info} ? $params{-path_info} : $use_pathinfo)) {
1292                 # try to put as many parameters as possible in PATH_INFO:
1293                 #   - project name
1294                 #   - action
1295                 #   - hash_parent or hash_parent_base:/file_parent
1296                 #   - hash or hash_base:/filename
1297                 #   - the snapshot_format as an appropriate suffix
1298
1299                 # When the script is the root DirectoryIndex for the domain,
1300                 # $href here would be something like http://gitweb.example.com/
1301                 # Thus, we strip any trailing / from $href, to spare us double
1302                 # slashes in the final URL
1303                 $href =~ s,/$,,;
1304
1305                 # Then add the project name, if present
1306                 $href .= "/".esc_path_info($params{'project'});
1307                 delete $params{'project'};
1308
1309                 # since we destructively absorb parameters, we keep this
1310                 # boolean that remembers if we're handling a snapshot
1311                 my $is_snapshot = $params{'action'} eq 'snapshot';
1312
1313                 # Summary just uses the project path URL, any other action is
1314                 # added to the URL
1315                 if (defined $params{'action'}) {
1316                         $href .= "/".esc_path_info($params{'action'})
1317                                 unless $params{'action'} eq 'summary';
1318                         delete $params{'action'};
1319                 }
1320
1321                 # Next, we put hash_parent_base:/file_parent..hash_base:/file_name,
1322                 # stripping nonexistent or useless pieces
1323                 $href .= "/" if ($params{'hash_base'} || $params{'hash_parent_base'}
1324                         || $params{'hash_parent'} || $params{'hash'});
1325                 if (defined $params{'hash_base'}) {
1326                         if (defined $params{'hash_parent_base'}) {
1327                                 $href .= esc_path_info($params{'hash_parent_base'});
1328                                 # skip the file_parent if it's the same as the file_name
1329                                 if (defined $params{'file_parent'}) {
1330                                         if (defined $params{'file_name'} && $params{'file_parent'} eq $params{'file_name'}) {
1331                                                 delete $params{'file_parent'};
1332                                         } elsif ($params{'file_parent'} !~ /\.\./) {
1333                                                 $href .= ":/".esc_path_info($params{'file_parent'});
1334                                                 delete $params{'file_parent'};
1335                                         }
1336                                 }
1337                                 $href .= "..";
1338                                 delete $params{'hash_parent'};
1339                                 delete $params{'hash_parent_base'};
1340                         } elsif (defined $params{'hash_parent'}) {
1341                                 $href .= esc_path_info($params{'hash_parent'}). "..";
1342                                 delete $params{'hash_parent'};
1343                         }
1344
1345                         $href .= esc_path_info($params{'hash_base'});
1346                         if (defined $params{'file_name'} && $params{'file_name'} !~ /\.\./) {
1347                                 $href .= ":/".esc_path_info($params{'file_name'});
1348                                 delete $params{'file_name'};
1349                         }
1350                         delete $params{'hash'};
1351                         delete $params{'hash_base'};
1352                 } elsif (defined $params{'hash'}) {
1353                         $href .= esc_path_info($params{'hash'});
1354                         delete $params{'hash'};
1355                 }
1356
1357                 # If the action was a snapshot, we can absorb the
1358                 # snapshot_format parameter too
1359                 if ($is_snapshot) {
1360                         my $fmt = $params{'snapshot_format'};
1361                         # snapshot_format should always be defined when href()
1362                         # is called, but just in case some code forgets, we
1363                         # fall back to the default
1364                         $fmt ||= $snapshot_fmts[0];
1365                         $href .= $known_snapshot_formats{$fmt}{'suffix'};
1366                         delete $params{'snapshot_format'};
1367                 }
1368         }
1369
1370         # now encode the parameters explicitly
1371         my @result = ();
1372         for (my $i = 0; $i < @cgi_param_mapping; $i += 2) {
1373                 my ($name, $symbol) = ($cgi_param_mapping[$i], $cgi_param_mapping[$i+1]);
1374                 if (defined $params{$name}) {
1375                         if (ref($params{$name}) eq "ARRAY") {
1376                                 foreach my $par (@{$params{$name}}) {
1377                                         push @result, $symbol . "=" . esc_param($par);
1378                                 }
1379                         } else {
1380                                 push @result, $symbol . "=" . esc_param($params{$name});
1381                         }
1382                 }
1383         }
1384         $href .= "?" . join(';', @result) if scalar @result;
1385
1386         # final transformation: trailing spaces must be escaped (URI-encoded)
1387         $href =~ s/(\s+)$/CGI::escape($1)/e;
1388
1389         if ($params{-anchor}) {
1390                 $href .= "#".esc_param($params{-anchor});
1391         }
1392
1393         return $href;
1394 }
1395
1396
1397 ## ======================================================================
1398 ## validation, quoting/unquoting and escaping
1399
1400 sub validate_action {
1401         my $input = shift || return undef;
1402         return undef unless exists $actions{$input};
1403         return $input;
1404 }
1405
1406 sub validate_project {
1407         my $input = shift || return undef;
1408         if (!validate_pathname($input) ||
1409                 !(-d "$projectroot/$input") ||
1410                 !check_export_ok("$projectroot/$input") ||
1411                 ($strict_export && !project_in_list($input))) {
1412                 return undef;
1413         } else {
1414                 return $input;
1415         }
1416 }
1417
1418 sub validate_pathname {
1419         my $input = shift || return undef;
1420
1421         # no '.' or '..' as elements of path, i.e. no '.' nor '..'
1422         # at the beginning, at the end, and between slashes.
1423         # also this catches doubled slashes
1424         if ($input =~ m!(^|/)(|\.|\.\.)(/|$)!) {
1425                 return undef;
1426         }
1427         # no null characters
1428         if ($input =~ m!\0!) {
1429                 return undef;
1430         }
1431         return $input;
1432 }
1433
1434 sub validate_refname {
1435         my $input = shift || return undef;
1436
1437         # textual hashes are O.K.
1438         if ($input =~ m/^[0-9a-fA-F]{40}$/) {
1439                 return $input;
1440         }
1441         # it must be correct pathname
1442         $input = validate_pathname($input)
1443                 or return undef;
1444         # restrictions on ref name according to git-check-ref-format
1445         if ($input =~ m!(/\.|\.\.|[\000-\040\177 ~^:?*\[]|/$)!) {
1446                 return undef;
1447         }
1448         return $input;
1449 }
1450
1451 # decode sequences of octets in utf8 into Perl's internal form,
1452 # which is utf-8 with utf8 flag set if needed.  gitweb writes out
1453 # in utf-8 thanks to "binmode STDOUT, ':utf8'" at beginning
1454 sub to_utf8 {
1455         my $str = shift;
1456         return undef unless defined $str;
1457
1458         if (utf8::is_utf8($str) || utf8::decode($str)) {
1459                 return $str;
1460         } else {
1461                 return decode($fallback_encoding, $str, Encode::FB_DEFAULT);
1462         }
1463 }
1464
1465 # quote unsafe chars, but keep the slash, even when it's not
1466 # correct, but quoted slashes look too horrible in bookmarks
1467 sub esc_param {
1468         my $str = shift;
1469         return undef unless defined $str;
1470         $str =~ s/([^A-Za-z0-9\-_.~()\/:@ ]+)/CGI::escape($1)/eg;
1471         $str =~ s/ /\+/g;
1472         return $str;
1473 }
1474
1475 # the quoting rules for path_info fragment are slightly different
1476 sub esc_path_info {
1477         my $str = shift;
1478         return undef unless defined $str;
1479
1480         # path_info doesn't treat '+' as space (specially), but '?' must be escaped
1481         $str =~ s/([^A-Za-z0-9\-_.~();\/;:@&= +]+)/CGI::escape($1)/eg;
1482
1483         return $str;
1484 }
1485
1486 # quote unsafe chars in whole URL, so some characters cannot be quoted
1487 sub esc_url {
1488         my $str = shift;
1489         return undef unless defined $str;
1490         $str =~ s/([^A-Za-z0-9\-_.~();\/;?:@&= ]+)/CGI::escape($1)/eg;
1491         $str =~ s/ /\+/g;
1492         return $str;
1493 }
1494
1495 # quote unsafe characters in HTML attributes
1496 sub esc_attr {
1497
1498         # for XHTML conformance escaping '"' to '&quot;' is not enough
1499         return esc_html(@_);
1500 }
1501
1502 # replace invalid utf8 character with SUBSTITUTION sequence
1503 sub esc_html {
1504         my $str = shift;
1505         my %opts = @_;
1506
1507         return undef unless defined $str;
1508
1509         $str = to_utf8($str);
1510         $str = $cgi->escapeHTML($str);
1511         if ($opts{'-nbsp'}) {
1512                 $str =~ s/ /&nbsp;/g;
1513         }
1514         $str =~ s|([[:cntrl:]])|(($1 ne "\t") ? quot_cec($1) : $1)|eg;
1515         return $str;
1516 }
1517
1518 # quote control characters and escape filename to HTML
1519 sub esc_path {
1520         my $str = shift;
1521         my %opts = @_;
1522
1523         return undef unless defined $str;
1524
1525         $str = to_utf8($str);
1526         $str = $cgi->escapeHTML($str);
1527         if ($opts{'-nbsp'}) {
1528                 $str =~ s/ /&nbsp;/g;
1529         }
1530         $str =~ s|([[:cntrl:]])|quot_cec($1)|eg;
1531         return $str;
1532 }
1533
1534 # Sanitize for use in XHTML + application/xml+xhtm (valid XML 1.0)
1535 sub sanitize {
1536         my $str = shift;
1537
1538         return undef unless defined $str;
1539
1540         $str = to_utf8($str);
1541         $str =~ s|([[:cntrl:]])|($1 =~ /[\t\n\r]/ ? $1 : quot_cec($1))|eg;
1542         return $str;
1543 }
1544
1545 # Make control characters "printable", using character escape codes (CEC)
1546 sub quot_cec {
1547         my $cntrl = shift;
1548         my %opts = @_;
1549         my %es = ( # character escape codes, aka escape sequences
1550                 "\t" => '\t',   # tab            (HT)
1551                 "\n" => '\n',   # line feed      (LF)
1552                 "\r" => '\r',   # carrige return (CR)
1553                 "\f" => '\f',   # form feed      (FF)
1554                 "\b" => '\b',   # backspace      (BS)
1555                 "\a" => '\a',   # alarm (bell)   (BEL)
1556                 "\e" => '\e',   # escape         (ESC)
1557                 "\013" => '\v', # vertical tab   (VT)
1558                 "\000" => '\0', # nul character  (NUL)
1559         );
1560         my $chr = ( (exists $es{$cntrl})
1561                     ? $es{$cntrl}
1562                     : sprintf('\%2x', ord($cntrl)) );
1563         if ($opts{-nohtml}) {
1564                 return $chr;
1565         } else {
1566                 return "<span class=\"cntrl\">$chr</span>";
1567         }
1568 }
1569
1570 # Alternatively use unicode control pictures codepoints,
1571 # Unicode "printable representation" (PR)
1572 sub quot_upr {
1573         my $cntrl = shift;
1574         my %opts = @_;
1575
1576         my $chr = sprintf('&#%04d;', 0x2400+ord($cntrl));
1577         if ($opts{-nohtml}) {
1578                 return $chr;
1579         } else {
1580                 return "<span class=\"cntrl\">$chr</span>";
1581         }
1582 }
1583
1584 # git may return quoted and escaped filenames
1585 sub unquote {
1586         my $str = shift;
1587
1588         sub unq {
1589                 my $seq = shift;
1590                 my %es = ( # character escape codes, aka escape sequences
1591                         't' => "\t",   # tab            (HT, TAB)
1592                         'n' => "\n",   # newline        (NL)
1593                         'r' => "\r",   # return         (CR)
1594                         'f' => "\f",   # form feed      (FF)
1595                         'b' => "\b",   # backspace      (BS)
1596                         'a' => "\a",   # alarm (bell)   (BEL)
1597                         'e' => "\e",   # escape         (ESC)
1598                         'v' => "\013", # vertical tab   (VT)
1599                 );
1600
1601                 if ($seq =~ m/^[0-7]{1,3}$/) {
1602                         # octal char sequence
1603                         return chr(oct($seq));
1604                 } elsif (exists $es{$seq}) {
1605                         # C escape sequence, aka character escape code
1606                         return $es{$seq};
1607                 }
1608                 # quoted ordinary character
1609                 return $seq;
1610         }
1611
1612         if ($str =~ m/^"(.*)"$/) {
1613                 # needs unquoting
1614                 $str = $1;
1615                 $str =~ s/\\([^0-7]|[0-7]{1,3})/unq($1)/eg;
1616         }
1617         return $str;
1618 }
1619
1620 # escape tabs (convert tabs to spaces)
1621 sub untabify {
1622         my $line = shift;
1623
1624         while ((my $pos = index($line, "\t")) != -1) {
1625                 if (my $count = (8 - ($pos % 8))) {
1626                         my $spaces = ' ' x $count;
1627                         $line =~ s/\t/$spaces/;
1628                 }
1629         }
1630
1631         return $line;
1632 }
1633
1634 sub project_in_list {
1635         my $project = shift;
1636         my @list = git_get_projects_list();
1637         return @list && scalar(grep { $_->{'path'} eq $project } @list);
1638 }
1639
1640 ## ----------------------------------------------------------------------
1641 ## HTML aware string manipulation
1642
1643 # Try to chop given string on a word boundary between position
1644 # $len and $len+$add_len. If there is no word boundary there,
1645 # chop at $len+$add_len. Do not chop if chopped part plus ellipsis
1646 # (marking chopped part) would be longer than given string.
1647 sub chop_str {
1648         my $str = shift;
1649         my $len = shift;
1650         my $add_len = shift || 10;
1651         my $where = shift || 'right'; # 'left' | 'center' | 'right'
1652
1653         # Make sure perl knows it is utf8 encoded so we don't
1654         # cut in the middle of a utf8 multibyte char.
1655         $str = to_utf8($str);
1656
1657         # allow only $len chars, but don't cut a word if it would fit in $add_len
1658         # if it doesn't fit, cut it if it's still longer than the dots we would add
1659         # remove chopped character entities entirely
1660
1661         # when chopping in the middle, distribute $len into left and right part
1662         # return early if chopping wouldn't make string shorter
1663         if ($where eq 'center') {
1664                 return $str if ($len + 5 >= length($str)); # filler is length 5
1665                 $len = int($len/2);
1666         } else {
1667                 return $str if ($len + 4 >= length($str)); # filler is length 4
1668         }
1669
1670         # regexps: ending and beginning with word part up to $add_len
1671         my $endre = qr/.{$len}\w{0,$add_len}/;
1672         my $begre = qr/\w{0,$add_len}.{$len}/;
1673
1674         if ($where eq 'left') {
1675                 $str =~ m/^(.*?)($begre)$/;
1676                 my ($lead, $body) = ($1, $2);
1677                 if (length($lead) > 4) {
1678                         $lead = " ...";
1679                 }
1680                 return "$lead$body";
1681
1682         } elsif ($where eq 'center') {
1683                 $str =~ m/^($endre)(.*)$/;
1684                 my ($left, $str)  = ($1, $2);
1685                 $str =~ m/^(.*?)($begre)$/;
1686                 my ($mid, $right) = ($1, $2);
1687                 if (length($mid) > 5) {
1688                         $mid = " ... ";
1689                 }
1690                 return "$left$mid$right";
1691
1692         } else {
1693                 $str =~ m/^($endre)(.*)$/;
1694                 my $body = $1;
1695                 my $tail = $2;
1696                 if (length($tail) > 4) {
1697                         $tail = "... ";
1698                 }
1699                 return "$body$tail";
1700         }
1701 }
1702
1703 # takes the same arguments as chop_str, but also wraps a <span> around the
1704 # result with a title attribute if it does get chopped. Additionally, the
1705 # string is HTML-escaped.
1706 sub chop_and_escape_str {
1707         my ($str) = @_;
1708
1709         my $chopped = chop_str(@_);
1710         $str = to_utf8($str);
1711         if ($chopped eq $str) {
1712                 return esc_html($chopped);
1713         } else {
1714                 $str =~ s/[[:cntrl:]]/?/g;
1715                 return $cgi->span({-title=>$str}, esc_html($chopped));
1716         }
1717 }
1718
1719 # Highlight selected fragments of string, using given CSS class,
1720 # and escape HTML.  It is assumed that fragments do not overlap.
1721 # Regions are passed as list of pairs (array references).
1722 #
1723 # Example: esc_html_hl_regions("foobar", "mark", [ 0, 3 ]) returns
1724 # '<span class="mark">foo</span>bar'
1725 sub esc_html_hl_regions {
1726         my ($str, $css_class, @sel) = @_;
1727         return esc_html($str) unless @sel;
1728
1729         my $out = '';
1730         my $pos = 0;
1731
1732         for my $s (@sel) {
1733                 $out .= esc_html(substr($str, $pos, $s->[0] - $pos))
1734                         if ($s->[0] - $pos > 0);
1735                 $out .= $cgi->span({-class => $css_class},
1736                                    esc_html(substr($str, $s->[0], $s->[1] - $s->[0])));
1737
1738                 $pos = $s->[1];
1739         }
1740         $out .= esc_html(substr($str, $pos))
1741                 if ($pos < length($str));
1742
1743         return $out;
1744 }
1745
1746 # highlight match (if any), and escape HTML
1747 sub esc_html_match_hl {
1748         my ($str, $regexp) = @_;
1749         return esc_html($str) unless defined $regexp;
1750
1751         my @matches;
1752         while ($str =~ /$regexp/g) {
1753                 push @matches, [$-[0], $+[0]];
1754         }
1755         return esc_html($str) unless @matches;
1756
1757         return esc_html_hl_regions($str, 'match', @matches);
1758 }
1759
1760 ## ----------------------------------------------------------------------
1761 ## functions returning short strings
1762
1763 # CSS class for given age value (in seconds)
1764 sub age_class {
1765         my $age = shift;
1766
1767         if (!defined $age) {
1768                 return "noage";
1769         } elsif ($age < 60*60*2) {
1770                 return "age0";
1771         } elsif ($age < 60*60*24*2) {
1772                 return "age1";
1773         } else {
1774                 return "age2";
1775         }
1776 }
1777
1778 # convert age in seconds to "nn units ago" string
1779 sub age_string {
1780         my $age = shift;
1781         my $age_str;
1782
1783         if ($age > 60*60*24*365*2) {
1784                 $age_str = (int $age/60/60/24/365);
1785                 $age_str .= " years ago";
1786         } elsif ($age > 60*60*24*(365/12)*2) {
1787                 $age_str = int $age/60/60/24/(365/12);
1788                 $age_str .= " months ago";
1789         } elsif ($age > 60*60*24*7*2) {
1790                 $age_str = int $age/60/60/24/7;
1791                 $age_str .= " weeks ago";
1792         } elsif ($age > 60*60*24*2) {
1793                 $age_str = int $age/60/60/24;
1794                 $age_str .= " days ago";
1795         } elsif ($age > 60*60*2) {
1796                 $age_str = int $age/60/60;
1797                 $age_str .= " hours ago";
1798         } elsif ($age > 60*2) {
1799                 $age_str = int $age/60;
1800                 $age_str .= " min ago";
1801         } elsif ($age > 2) {
1802                 $age_str = int $age;
1803                 $age_str .= " sec ago";
1804         } else {
1805                 $age_str .= " right now";
1806         }
1807         return $age_str;
1808 }
1809
1810 use constant {
1811         S_IFINVALID => 0030000,
1812         S_IFGITLINK => 0160000,
1813 };
1814
1815 # submodule/subproject, a commit object reference
1816 sub S_ISGITLINK {
1817         my $mode = shift;
1818
1819         return (($mode & S_IFMT) == S_IFGITLINK)
1820 }
1821
1822 # convert file mode in octal to symbolic file mode string
1823 sub mode_str {
1824         my $mode = oct shift;
1825
1826         if (S_ISGITLINK($mode)) {
1827                 return 'm---------';
1828         } elsif (S_ISDIR($mode & S_IFMT)) {
1829                 return 'drwxr-xr-x';
1830         } elsif (S_ISLNK($mode)) {
1831                 return 'lrwxrwxrwx';
1832         } elsif (S_ISREG($mode)) {
1833                 # git cares only about the executable bit
1834                 if ($mode & S_IXUSR) {
1835                         return '-rwxr-xr-x';
1836                 } else {
1837                         return '-rw-r--r--';
1838                 };
1839         } else {
1840                 return '----------';
1841         }
1842 }
1843
1844 # convert file mode in octal to file type string
1845 sub file_type {
1846         my $mode = shift;
1847
1848         if ($mode !~ m/^[0-7]+$/) {
1849                 return $mode;
1850         } else {
1851                 $mode = oct $mode;
1852         }
1853
1854         if (S_ISGITLINK($mode)) {
1855                 return "submodule";
1856         } elsif (S_ISDIR($mode & S_IFMT)) {
1857                 return "directory";
1858         } elsif (S_ISLNK($mode)) {
1859                 return "symlink";
1860         } elsif (S_ISREG($mode)) {
1861                 return "file";
1862         } else {
1863                 return "unknown";
1864         }
1865 }
1866
1867 # convert file mode in octal to file type description string
1868 sub file_type_long {
1869         my $mode = shift;
1870
1871         if ($mode !~ m/^[0-7]+$/) {
1872                 return $mode;
1873         } else {
1874                 $mode = oct $mode;
1875         }
1876
1877         if (S_ISGITLINK($mode)) {
1878                 return "submodule";
1879         } elsif (S_ISDIR($mode & S_IFMT)) {
1880                 return "directory";
1881         } elsif (S_ISLNK($mode)) {
1882                 return "symlink";
1883         } elsif (S_ISREG($mode)) {
1884                 if ($mode & S_IXUSR) {
1885                         return "executable";
1886                 } else {
1887                         return "file";
1888                 };
1889         } else {
1890                 return "unknown";
1891         }
1892 }
1893
1894
1895 ## ----------------------------------------------------------------------
1896 ## functions returning short HTML fragments, or transforming HTML fragments
1897 ## which don't belong to other sections
1898
1899 # format line of commit message.
1900 sub format_log_line_html {
1901         my $line = shift;
1902
1903         $line = esc_html($line, -nbsp=>1);
1904         $line =~ s{\b([0-9a-fA-F]{8,40})\b}{
1905                 $cgi->a({-href => href(action=>"object", hash=>$1),
1906                                         -class => "text"}, $1);
1907         }eg;
1908
1909         return $line;
1910 }
1911
1912 # format marker of refs pointing to given object
1913
1914 # the destination action is chosen based on object type and current context:
1915 # - for annotated tags, we choose the tag view unless it's the current view
1916 #   already, in which case we go to shortlog view
1917 # - for other refs, we keep the current view if we're in history, shortlog or
1918 #   log view, and select shortlog otherwise
1919 sub format_ref_marker {
1920         my ($refs, $id) = @_;
1921         my $markers = '';
1922
1923         if (defined $refs->{$id}) {
1924                 foreach my $ref (@{$refs->{$id}}) {
1925                         # this code exploits the fact that non-lightweight tags are the
1926                         # only indirect objects, and that they are the only objects for which
1927                         # we want to use tag instead of shortlog as action
1928                         my ($type, $name) = qw();
1929                         my $indirect = ($ref =~ s/\^\{\}$//);
1930                         # e.g. tags/v2.6.11 or heads/next
1931                         if ($ref =~ m!^(.*?)s?/(.*)$!) {
1932                                 $type = $1;
1933                                 $name = $2;
1934                         } else {
1935                                 $type = "ref";
1936                                 $name = $ref;
1937                         }
1938
1939                         my $class = $type;
1940                         $class .= " indirect" if $indirect;
1941
1942                         my $dest_action = "shortlog";
1943
1944                         if ($indirect) {
1945                                 $dest_action = "tag" unless $action eq "tag";
1946                         } elsif ($action =~ /^(history|(short)?log)$/) {
1947                                 $dest_action = $action;
1948                         }
1949
1950                         my $dest = "";
1951                         $dest .= "refs/" unless $ref =~ m!^refs/!;
1952                         $dest .= $ref;
1953
1954                         my $link = $cgi->a({
1955                                 -href => href(
1956                                         action=>$dest_action,
1957                                         hash=>$dest
1958                                 )}, $name);
1959
1960                         $markers .= " <span class=\"".esc_attr($class)."\" title=\"".esc_attr($ref)."\">" .
1961                                 $link . "</span>";
1962                 }
1963         }
1964
1965         if ($markers) {
1966                 return ' <span class="refs">'. $markers . '</span>';
1967         } else {
1968                 return "";
1969         }
1970 }
1971
1972 # format, perhaps shortened and with markers, title line
1973 sub format_subject_html {
1974         my ($long, $short, $href, $extra) = @_;
1975         $extra = '' unless defined($extra);
1976
1977         if (length($short) < length($long)) {
1978                 $long =~ s/[[:cntrl:]]/?/g;
1979                 return $cgi->a({-href => $href, -class => "list subject",
1980                                 -title => to_utf8($long)},
1981                        esc_html($short)) . $extra;
1982         } else {
1983                 return $cgi->a({-href => $href, -class => "list subject"},
1984                        esc_html($long)) . $extra;
1985         }
1986 }
1987
1988 # Rather than recomputing the url for an email multiple times, we cache it
1989 # after the first hit. This gives a visible benefit in views where the avatar
1990 # for the same email is used repeatedly (e.g. shortlog).
1991 # The cache is shared by all avatar engines (currently gravatar only), which
1992 # are free to use it as preferred. Since only one avatar engine is used for any
1993 # given page, there's no risk for cache conflicts.
1994 our %avatar_cache = ();
1995
1996 # Compute the picon url for a given email, by using the picon search service over at
1997 # http://www.cs.indiana.edu/picons/search.html
1998 sub picon_url {
1999         my $email = lc shift;
2000         if (!$avatar_cache{$email}) {
2001                 my ($user, $domain) = split('@', $email);
2002                 $avatar_cache{$email} =
2003                         "http://www.cs.indiana.edu/cgi-pub/kinzler/piconsearch.cgi/" .
2004                         "$domain/$user/" .
2005                         "users+domains+unknown/up/single";
2006         }
2007         return $avatar_cache{$email};
2008 }
2009
2010 # Compute the gravatar url for a given email, if it's not in the cache already.
2011 # Gravatar stores only the part of the URL before the size, since that's the
2012 # one computationally more expensive. This also allows reuse of the cache for
2013 # different sizes (for this particular engine).
2014 sub gravatar_url {
2015         my $email = lc shift;
2016         my $size = shift;
2017         $avatar_cache{$email} ||=
2018                 "http://www.gravatar.com/avatar/" .
2019                         Digest::MD5::md5_hex($email) . "?s=";
2020         return $avatar_cache{$email} . $size;
2021 }
2022
2023 # Insert an avatar for the given $email at the given $size if the feature
2024 # is enabled.
2025 sub git_get_avatar {
2026         my ($email, %opts) = @_;
2027         my $pre_white  = ($opts{-pad_before} ? "&nbsp;" : "");
2028         my $post_white = ($opts{-pad_after}  ? "&nbsp;" : "");
2029         $opts{-size} ||= 'default';
2030         my $size = $avatar_size{$opts{-size}} || $avatar_size{'default'};
2031         my $url = "";
2032         if ($git_avatar eq 'gravatar') {
2033                 $url = gravatar_url($email, $size);
2034         } elsif ($git_avatar eq 'picon') {
2035                 $url = picon_url($email);
2036         }
2037         # Other providers can be added by extending the if chain, defining $url
2038         # as needed. If no variant puts something in $url, we assume avatars
2039         # are completely disabled/unavailable.
2040         if ($url) {
2041                 return $pre_white .
2042                        "<img width=\"$size\" " .
2043                             "class=\"avatar\" " .
2044                             "src=\"".esc_url($url)."\" " .
2045                             "alt=\"\" " .
2046                        "/>" . $post_white;
2047         } else {
2048                 return "";
2049         }
2050 }
2051
2052 sub format_search_author {
2053         my ($author, $searchtype, $displaytext) = @_;
2054         my $have_search = gitweb_check_feature('search');
2055
2056         if ($have_search) {
2057                 my $performed = "";
2058                 if ($searchtype eq 'author') {
2059                         $performed = "authored";
2060                 } elsif ($searchtype eq 'committer') {
2061                         $performed = "committed";
2062                 }
2063
2064                 return $cgi->a({-href => href(action=>"search", hash=>$hash,
2065                                 searchtext=>$author,
2066                                 searchtype=>$searchtype), class=>"list",
2067                                 title=>"Search for commits $performed by $author"},
2068                                 $displaytext);
2069
2070         } else {
2071                 return $displaytext;
2072         }
2073 }
2074
2075 # format the author name of the given commit with the given tag
2076 # the author name is chopped and escaped according to the other
2077 # optional parameters (see chop_str).
2078 sub format_author_html {
2079         my $tag = shift;
2080         my $co = shift;
2081         my $author = chop_and_escape_str($co->{'author_name'}, @_);
2082         return "<$tag class=\"author\">" .
2083                format_search_author($co->{'author_name'}, "author",
2084                        git_get_avatar($co->{'author_email'}, -pad_after => 1) .
2085                        $author) .
2086                "</$tag>";
2087 }
2088
2089 # format git diff header line, i.e. "diff --(git|combined|cc) ..."
2090 sub format_git_diff_header_line {
2091         my $line = shift;
2092         my $diffinfo = shift;
2093         my ($from, $to) = @_;
2094
2095         if ($diffinfo->{'nparents'}) {
2096                 # combined diff
2097                 $line =~ s!^(diff (.*?) )"?.*$!$1!;
2098                 if ($to->{'href'}) {
2099                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2100                                          esc_path($to->{'file'}));
2101                 } else { # file was deleted (no href)
2102                         $line .= esc_path($to->{'file'});
2103                 }
2104         } else {
2105                 # "ordinary" diff
2106                 $line =~ s!^(diff (.*?) )"?a/.*$!$1!;
2107                 if ($from->{'href'}) {
2108                         $line .= $cgi->a({-href => $from->{'href'}, -class => "path"},
2109                                          'a/' . esc_path($from->{'file'}));
2110                 } else { # file was added (no href)
2111                         $line .= 'a/' . esc_path($from->{'file'});
2112                 }
2113                 $line .= ' ';
2114                 if ($to->{'href'}) {
2115                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2116                                          'b/' . esc_path($to->{'file'}));
2117                 } else { # file was deleted
2118                         $line .= 'b/' . esc_path($to->{'file'});
2119                 }
2120         }
2121
2122         return "<div class=\"diff header\">$line</div>\n";
2123 }
2124
2125 # format extended diff header line, before patch itself
2126 sub format_extended_diff_header_line {
2127         my $line = shift;
2128         my $diffinfo = shift;
2129         my ($from, $to) = @_;
2130
2131         # match <path>
2132         if ($line =~ s!^((copy|rename) from ).*$!$1! && $from->{'href'}) {
2133                 $line .= $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2134                                        esc_path($from->{'file'}));
2135         }
2136         if ($line =~ s!^((copy|rename) to ).*$!$1! && $to->{'href'}) {
2137                 $line .= $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2138                                  esc_path($to->{'file'}));
2139         }
2140         # match single <mode>
2141         if ($line =~ m/\s(\d{6})$/) {
2142                 $line .= '<span class="info"> (' .
2143                          file_type_long($1) .
2144                          ')</span>';
2145         }
2146         # match <hash>
2147         if ($line =~ m/^index [0-9a-fA-F]{40},[0-9a-fA-F]{40}/) {
2148                 # can match only for combined diff
2149                 $line = 'index ';
2150                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2151                         if ($from->{'href'}[$i]) {
2152                                 $line .= $cgi->a({-href=>$from->{'href'}[$i],
2153                                                   -class=>"hash"},
2154                                                  substr($diffinfo->{'from_id'}[$i],0,7));
2155                         } else {
2156                                 $line .= '0' x 7;
2157                         }
2158                         # separator
2159                         $line .= ',' if ($i < $diffinfo->{'nparents'} - 1);
2160                 }
2161                 $line .= '..';
2162                 if ($to->{'href'}) {
2163                         $line .= $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2164                                          substr($diffinfo->{'to_id'},0,7));
2165                 } else {
2166                         $line .= '0' x 7;
2167                 }
2168
2169         } elsif ($line =~ m/^index [0-9a-fA-F]{40}..[0-9a-fA-F]{40}/) {
2170                 # can match only for ordinary diff
2171                 my ($from_link, $to_link);
2172                 if ($from->{'href'}) {
2173                         $from_link = $cgi->a({-href=>$from->{'href'}, -class=>"hash"},
2174                                              substr($diffinfo->{'from_id'},0,7));
2175                 } else {
2176                         $from_link = '0' x 7;
2177                 }
2178                 if ($to->{'href'}) {
2179                         $to_link = $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2180                                            substr($diffinfo->{'to_id'},0,7));
2181                 } else {
2182                         $to_link = '0' x 7;
2183                 }
2184                 my ($from_id, $to_id) = ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
2185                 $line =~ s!$from_id\.\.$to_id!$from_link..$to_link!;
2186         }
2187
2188         return $line . "<br/>\n";
2189 }
2190
2191 # format from-file/to-file diff header
2192 sub format_diff_from_to_header {
2193         my ($from_line, $to_line, $diffinfo, $from, $to, @parents) = @_;
2194         my $line;
2195         my $result = '';
2196
2197         $line = $from_line;
2198         #assert($line =~ m/^---/) if DEBUG;
2199         # no extra formatting for "^--- /dev/null"
2200         if (! $diffinfo->{'nparents'}) {
2201                 # ordinary (single parent) diff
2202                 if ($line =~ m!^--- "?a/!) {
2203                         if ($from->{'href'}) {
2204                                 $line = '--- a/' .
2205                                         $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2206                                                 esc_path($from->{'file'}));
2207                         } else {
2208                                 $line = '--- a/' .
2209                                         esc_path($from->{'file'});
2210                         }
2211                 }
2212                 $result .= qq!<div class="diff from_file">$line</div>\n!;
2213
2214         } else {
2215                 # combined diff (merge commit)
2216                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2217                         if ($from->{'href'}[$i]) {
2218                                 $line = '--- ' .
2219                                         $cgi->a({-href=>href(action=>"blobdiff",
2220                                                              hash_parent=>$diffinfo->{'from_id'}[$i],
2221                                                              hash_parent_base=>$parents[$i],
2222                                                              file_parent=>$from->{'file'}[$i],
2223                                                              hash=>$diffinfo->{'to_id'},
2224                                                              hash_base=>$hash,
2225                                                              file_name=>$to->{'file'}),
2226                                                  -class=>"path",
2227                                                  -title=>"diff" . ($i+1)},
2228                                                 $i+1) .
2229                                         '/' .
2230                                         $cgi->a({-href=>$from->{'href'}[$i], -class=>"path"},
2231                                                 esc_path($from->{'file'}[$i]));
2232                         } else {
2233                                 $line = '--- /dev/null';
2234                         }
2235                         $result .= qq!<div class="diff from_file">$line</div>\n!;
2236                 }
2237         }
2238
2239         $line = $to_line;
2240         #assert($line =~ m/^\+\+\+/) if DEBUG;
2241         # no extra formatting for "^+++ /dev/null"
2242         if ($line =~ m!^\+\+\+ "?b/!) {
2243                 if ($to->{'href'}) {
2244                         $line = '+++ b/' .
2245                                 $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2246                                         esc_path($to->{'file'}));
2247                 } else {
2248                         $line = '+++ b/' .
2249                                 esc_path($to->{'file'});
2250                 }
2251         }
2252         $result .= qq!<div class="diff to_file">$line</div>\n!;
2253
2254         return $result;
2255 }
2256
2257 # create note for patch simplified by combined diff
2258 sub format_diff_cc_simplified {
2259         my ($diffinfo, @parents) = @_;
2260         my $result = '';
2261
2262         $result .= "<div class=\"diff header\">" .
2263                    "diff --cc ";
2264         if (!is_deleted($diffinfo)) {
2265                 $result .= $cgi->a({-href => href(action=>"blob",
2266                                                   hash_base=>$hash,
2267                                                   hash=>$diffinfo->{'to_id'},
2268                                                   file_name=>$diffinfo->{'to_file'}),
2269                                     -class => "path"},
2270                                    esc_path($diffinfo->{'to_file'}));
2271         } else {
2272                 $result .= esc_path($diffinfo->{'to_file'});
2273         }
2274         $result .= "</div>\n" . # class="diff header"
2275                    "<div class=\"diff nodifferences\">" .
2276                    "Simple merge" .
2277                    "</div>\n"; # class="diff nodifferences"
2278
2279         return $result;
2280 }
2281
2282 sub diff_line_class {
2283         my ($line, $from, $to) = @_;
2284
2285         # ordinary diff
2286         my $num_sign = 1;
2287         # combined diff
2288         if ($from && $to && ref($from->{'href'}) eq "ARRAY") {
2289                 $num_sign = scalar @{$from->{'href'}};
2290         }
2291
2292         my @diff_line_classifier = (
2293                 { regexp => qr/^\@\@{$num_sign} /, class => "chunk_header"},
2294                 { regexp => qr/^\\/,               class => "incomplete"  },
2295                 { regexp => qr/^ {$num_sign}/,     class => "ctx" },
2296                 # classifier for context must come before classifier add/rem,
2297                 # or we would have to use more complicated regexp, for example
2298                 # qr/(?= {0,$m}\+)[+ ]{$num_sign}/, where $m = $num_sign - 1;
2299                 { regexp => qr/^[+ ]{$num_sign}/,   class => "add" },
2300                 { regexp => qr/^[- ]{$num_sign}/,   class => "rem" },
2301         );
2302         for my $clsfy (@diff_line_classifier) {
2303                 return $clsfy->{'class'}
2304                         if ($line =~ $clsfy->{'regexp'});
2305         }
2306
2307         # fallback
2308         return "";
2309 }
2310
2311 # assumes that $from and $to are defined and correctly filled,
2312 # and that $line holds a line of chunk header for unified diff
2313 sub format_unidiff_chunk_header {
2314         my ($line, $from, $to) = @_;
2315
2316         my ($from_text, $from_start, $from_lines, $to_text, $to_start, $to_lines, $section) =
2317                 $line =~ m/^\@{2} (-(\d+)(?:,(\d+))?) (\+(\d+)(?:,(\d+))?) \@{2}(.*)$/;
2318
2319         $from_lines = 0 unless defined $from_lines;
2320         $to_lines   = 0 unless defined $to_lines;
2321
2322         if ($from->{'href'}) {
2323                 $from_text = $cgi->a({-href=>"$from->{'href'}#l$from_start",
2324                                      -class=>"list"}, $from_text);
2325         }
2326         if ($to->{'href'}) {
2327                 $to_text   = $cgi->a({-href=>"$to->{'href'}#l$to_start",
2328                                      -class=>"list"}, $to_text);
2329         }
2330         $line = "<span class=\"chunk_info\">@@ $from_text $to_text @@</span>" .
2331                 "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2332         return $line;
2333 }
2334
2335 # assumes that $from and $to are defined and correctly filled,
2336 # and that $line holds a line of chunk header for combined diff
2337 sub format_cc_diff_chunk_header {
2338         my ($line, $from, $to) = @_;
2339
2340         my ($prefix, $ranges, $section) = $line =~ m/^(\@+) (.*?) \@+(.*)$/;
2341         my (@from_text, @from_start, @from_nlines, $to_text, $to_start, $to_nlines);
2342
2343         @from_text = split(' ', $ranges);
2344         for (my $i = 0; $i < @from_text; ++$i) {
2345                 ($from_start[$i], $from_nlines[$i]) =
2346                         (split(',', substr($from_text[$i], 1)), 0);
2347         }
2348
2349         $to_text   = pop @from_text;
2350         $to_start  = pop @from_start;
2351         $to_nlines = pop @from_nlines;
2352
2353         $line = "<span class=\"chunk_info\">$prefix ";
2354         for (my $i = 0; $i < @from_text; ++$i) {
2355                 if ($from->{'href'}[$i]) {
2356                         $line .= $cgi->a({-href=>"$from->{'href'}[$i]#l$from_start[$i]",
2357                                           -class=>"list"}, $from_text[$i]);
2358                 } else {
2359                         $line .= $from_text[$i];
2360                 }
2361                 $line .= " ";
2362         }
2363         if ($to->{'href'}) {
2364                 $line .= $cgi->a({-href=>"$to->{'href'}#l$to_start",
2365                                   -class=>"list"}, $to_text);
2366         } else {
2367                 $line .= $to_text;
2368         }
2369         $line .= " $prefix</span>" .
2370                  "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2371         return $line;
2372 }
2373
2374 # process patch (diff) line (not to be used for diff headers),
2375 # returning class and HTML-formatted (but not wrapped) line
2376 sub process_diff_line {
2377         my $line = shift;
2378         my ($from, $to) = @_;
2379
2380         my $diff_class = diff_line_class($line, $from, $to);
2381
2382         chomp $line;
2383         $line = untabify($line);
2384
2385         if ($from && $to && $line =~ m/^\@{2} /) {
2386                 $line = format_unidiff_chunk_header($line, $from, $to);
2387                 return $diff_class, $line;
2388
2389         } elsif ($from && $to && $line =~ m/^\@{3}/) {
2390                 $line = format_cc_diff_chunk_header($line, $from, $to);
2391                 return $diff_class, $line;
2392
2393         }
2394         return $diff_class, esc_html($line, -nbsp=>1);
2395 }
2396
2397 # Generates undef or something like "_snapshot_" or "snapshot (_tbz2_ _zip_)",
2398 # linked.  Pass the hash of the tree/commit to snapshot.
2399 sub format_snapshot_links {
2400         my ($hash) = @_;
2401         my $num_fmts = @snapshot_fmts;
2402         if ($num_fmts > 1) {
2403                 # A parenthesized list of links bearing format names.
2404                 # e.g. "snapshot (_tar.gz_ _zip_)"
2405                 return "snapshot (" . join(' ', map
2406                         $cgi->a({
2407                                 -href => href(
2408                                         action=>"snapshot",
2409                                         hash=>$hash,
2410                                         snapshot_format=>$_
2411                                 )
2412                         }, $known_snapshot_formats{$_}{'display'})
2413                 , @snapshot_fmts) . ")";
2414         } elsif ($num_fmts == 1) {
2415                 # A single "snapshot" link whose tooltip bears the format name.
2416                 # i.e. "_snapshot_"
2417                 my ($fmt) = @snapshot_fmts;
2418                 return
2419                         $cgi->a({
2420                                 -href => href(
2421                                         action=>"snapshot",
2422                                         hash=>$hash,
2423                                         snapshot_format=>$fmt
2424                                 ),
2425                                 -title => "in format: $known_snapshot_formats{$fmt}{'display'}"
2426                         }, "snapshot");
2427         } else { # $num_fmts == 0
2428                 return undef;
2429         }
2430 }
2431
2432 ## ......................................................................
2433 ## functions returning values to be passed, perhaps after some
2434 ## transformation, to other functions; e.g. returning arguments to href()
2435
2436 # returns hash to be passed to href to generate gitweb URL
2437 # in -title key it returns description of link
2438 sub get_feed_info {
2439         my $format = shift || 'Atom';
2440         my %res = (action => lc($format));
2441
2442         # feed links are possible only for project views
2443         return unless (defined $project);
2444         # some views should link to OPML, or to generic project feed,
2445         # or don't have specific feed yet (so they should use generic)
2446         return if (!$action || $action =~ /^(?:tags|heads|forks|tag|search)$/x);
2447
2448         my $branch;
2449         # branches refs uses 'refs/heads/' prefix (fullname) to differentiate
2450         # from tag links; this also makes possible to detect branch links
2451         if ((defined $hash_base && $hash_base =~ m!^refs/heads/(.*)$!) ||
2452             (defined $hash      && $hash      =~ m!^refs/heads/(.*)$!)) {
2453                 $branch = $1;
2454         }
2455         # find log type for feed description (title)
2456         my $type = 'log';
2457         if (defined $file_name) {
2458                 $type  = "history of $file_name";
2459                 $type .= "/" if ($action eq 'tree');
2460                 $type .= " on '$branch'" if (defined $branch);
2461         } else {
2462                 $type = "log of $branch" if (defined $branch);
2463         }
2464
2465         $res{-title} = $type;
2466         $res{'hash'} = (defined $branch ? "refs/heads/$branch" : undef);
2467         $res{'file_name'} = $file_name;
2468
2469         return %res;
2470 }
2471
2472 ## ----------------------------------------------------------------------
2473 ## git utility subroutines, invoking git commands
2474
2475 # returns path to the core git executable and the --git-dir parameter as list
2476 sub git_cmd {
2477         $number_of_git_cmds++;
2478         return $GIT, '--git-dir='.$git_dir;
2479 }
2480
2481 # quote the given arguments for passing them to the shell
2482 # quote_command("command", "arg 1", "arg with ' and ! characters")
2483 # => "'command' 'arg 1' 'arg with '\'' and '\!' characters'"
2484 # Try to avoid using this function wherever possible.
2485 sub quote_command {
2486         return join(' ',
2487                 map { my $a = $_; $a =~ s/(['!])/'\\$1'/g; "'$a'" } @_ );
2488 }
2489
2490 # get HEAD ref of given project as hash
2491 sub git_get_head_hash {
2492         return git_get_full_hash(shift, 'HEAD');
2493 }
2494
2495 sub git_get_full_hash {
2496         return git_get_hash(@_);
2497 }
2498
2499 sub git_get_short_hash {
2500         return git_get_hash(@_, '--short=7');
2501 }
2502
2503 sub git_get_hash {
2504         my ($project, $hash, @options) = @_;
2505         my $o_git_dir = $git_dir;
2506         my $retval = undef;
2507         $git_dir = "$projectroot/$project";
2508         if (open my $fd, '-|', git_cmd(), 'rev-parse',
2509             '--verify', '-q', @options, $hash) {
2510                 $retval = <$fd>;
2511                 chomp $retval if defined $retval;
2512                 close $fd;
2513         }
2514         if (defined $o_git_dir) {
2515                 $git_dir = $o_git_dir;
2516         }
2517         return $retval;
2518 }
2519
2520 # get type of given object
2521 sub git_get_type {
2522         my $hash = shift;
2523
2524         open my $fd, "-|", git_cmd(), "cat-file", '-t', $hash or return;
2525         my $type = <$fd>;
2526         close $fd or return;
2527         chomp $type;
2528         return $type;
2529 }
2530
2531 # repository configuration
2532 our $config_file = '';
2533 our %config;
2534
2535 # store multiple values for single key as anonymous array reference
2536 # single values stored directly in the hash, not as [ <value> ]
2537 sub hash_set_multi {
2538         my ($hash, $key, $value) = @_;
2539
2540         if (!exists $hash->{$key}) {
2541                 $hash->{$key} = $value;
2542         } elsif (!ref $hash->{$key}) {
2543                 $hash->{$key} = [ $hash->{$key}, $value ];
2544         } else {
2545                 push @{$hash->{$key}}, $value;
2546         }
2547 }
2548
2549 # return hash of git project configuration
2550 # optionally limited to some section, e.g. 'gitweb'
2551 sub git_parse_project_config {
2552         my $section_regexp = shift;
2553         my %config;
2554
2555         local $/ = "\0";
2556
2557         open my $fh, "-|", git_cmd(), "config", '-z', '-l',
2558                 or return;
2559
2560         while (my $keyval = <$fh>) {
2561                 chomp $keyval;
2562                 my ($key, $value) = split(/\n/, $keyval, 2);
2563
2564                 hash_set_multi(\%config, $key, $value)
2565                         if (!defined $section_regexp || $key =~ /^(?:$section_regexp)\./o);
2566         }
2567         close $fh;
2568
2569         return %config;
2570 }
2571
2572 # convert config value to boolean: 'true' or 'false'
2573 # no value, number > 0, 'true' and 'yes' values are true
2574 # rest of values are treated as false (never as error)
2575 sub config_to_bool {
2576         my $val = shift;
2577
2578         return 1 if !defined $val;             # section.key
2579
2580         # strip leading and trailing whitespace
2581         $val =~ s/^\s+//;
2582         $val =~ s/\s+$//;
2583
2584         return (($val =~ /^\d+$/ && $val) ||   # section.key = 1
2585                 ($val =~ /^(?:true|yes)$/i));  # section.key = true
2586 }
2587
2588 # convert config value to simple decimal number
2589 # an optional value suffix of 'k', 'm', or 'g' will cause the value
2590 # to be multiplied by 1024, 1048576, or 1073741824
2591 sub config_to_int {
2592         my $val = shift;
2593
2594         # strip leading and trailing whitespace
2595         $val =~ s/^\s+//;
2596         $val =~ s/\s+$//;
2597
2598         if (my ($num, $unit) = ($val =~ /^([0-9]*)([kmg])$/i)) {
2599                 $unit = lc($unit);
2600                 # unknown unit is treated as 1
2601                 return $num * ($unit eq 'g' ? 1073741824 :
2602                                $unit eq 'm' ?    1048576 :
2603                                $unit eq 'k' ?       1024 : 1);
2604         }
2605         return $val;
2606 }
2607
2608 # convert config value to array reference, if needed
2609 sub config_to_multi {
2610         my $val = shift;
2611
2612         return ref($val) ? $val : (defined($val) ? [ $val ] : []);
2613 }
2614
2615 sub git_get_project_config {
2616         my ($key, $type) = @_;
2617
2618         return unless defined $git_dir;
2619
2620         # key sanity check
2621         return unless ($key);
2622         # only subsection, if exists, is case sensitive,
2623         # and not lowercased by 'git config -z -l'
2624         if (my ($hi, $mi, $lo) = ($key =~ /^([^.]*)\.(.*)\.([^.]*)$/)) {
2625                 $key = join(".", lc($hi), $mi, lc($lo));
2626         } else {
2627                 $key = lc($key);
2628         }
2629         $key =~ s/^gitweb\.//;
2630         return if ($key =~ m/\W/);
2631
2632         # type sanity check
2633         if (defined $type) {
2634                 $type =~ s/^--//;
2635                 $type = undef
2636                         unless ($type eq 'bool' || $type eq 'int');
2637         }
2638
2639         # get config
2640         if (!defined $config_file ||
2641             $config_file ne "$git_dir/config") {
2642                 %config = git_parse_project_config('gitweb');
2643                 $config_file = "$git_dir/config";
2644         }
2645
2646         # check if config variable (key) exists
2647         return unless exists $config{"gitweb.$key"};
2648
2649         # ensure given type
2650         if (!defined $type) {
2651                 return $config{"gitweb.$key"};
2652         } elsif ($type eq 'bool') {
2653                 # backward compatibility: 'git config --bool' returns true/false
2654                 return config_to_bool($config{"gitweb.$key"}) ? 'true' : 'false';
2655         } elsif ($type eq 'int') {
2656                 return config_to_int($config{"gitweb.$key"});
2657         }
2658         return $config{"gitweb.$key"};
2659 }
2660
2661 # get hash of given path at given ref
2662 sub git_get_hash_by_path {
2663         my $base = shift;
2664         my $path = shift || return undef;
2665         my $type = shift;
2666
2667         $path =~ s,/+$,,;
2668
2669         open my $fd, "-|", git_cmd(), "ls-tree", $base, "--", $path
2670                 or die_error(500, "Open git-ls-tree failed");
2671         my $line = <$fd>;
2672         close $fd or return undef;
2673
2674         if (!defined $line) {
2675                 # there is no tree or hash given by $path at $base
2676                 return undef;
2677         }
2678
2679         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
2680         $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/;
2681         if (defined $type && $type ne $2) {
2682                 # type doesn't match
2683                 return undef;
2684         }
2685         return $3;
2686 }
2687
2688 # get path of entry with given hash at given tree-ish (ref)
2689 # used to get 'from' filename for combined diff (merge commit) for renames
2690 sub git_get_path_by_hash {
2691         my $base = shift || return;
2692         my $hash = shift || return;
2693
2694         local $/ = "\0";
2695
2696         open my $fd, "-|", git_cmd(), "ls-tree", '-r', '-t', '-z', $base
2697                 or return undef;
2698         while (my $line = <$fd>) {
2699                 chomp $line;
2700
2701                 #'040000 tree 595596a6a9117ddba9fe379b6b012b558bac8423  gitweb'
2702                 #'100644 blob e02e90f0429be0d2a69b76571101f20b8f75530f  gitweb/README'
2703                 if ($line =~ m/(?:[0-9]+) (?:.+) $hash\t(.+)$/) {
2704                         close $fd;
2705                         return $1;
2706                 }
2707         }
2708         close $fd;
2709         return undef;
2710 }
2711
2712 ## ......................................................................
2713 ## git utility functions, directly accessing git repository
2714
2715 # get the value of config variable either from file named as the variable
2716 # itself in the repository ($GIT_DIR/$name file), or from gitweb.$name
2717 # configuration variable in the repository config file.
2718 sub git_get_file_or_project_config {
2719         my ($path, $name) = @_;
2720
2721         $git_dir = "$projectroot/$path";
2722         open my $fd, '<', "$git_dir/$name"
2723                 or return git_get_project_config($name);
2724         my $conf = <$fd>;
2725         close $fd;
2726         if (defined $conf) {
2727                 chomp $conf;
2728         }
2729         return $conf;
2730 }
2731
2732 sub git_get_project_description {
2733         my $path = shift;
2734         return git_get_file_or_project_config($path, 'description');
2735 }
2736
2737 sub git_get_project_category {
2738         my $path = shift;
2739         return git_get_file_or_project_config($path, 'category');
2740 }
2741
2742
2743 # supported formats:
2744 # * $GIT_DIR/ctags/<tagname> file (in 'ctags' subdirectory)
2745 #   - if its contents is a number, use it as tag weight,
2746 #   - otherwise add a tag with weight 1
2747 # * $GIT_DIR/ctags file, each line is a tag (with weight 1)
2748 #   the same value multiple times increases tag weight
2749 # * `gitweb.ctag' multi-valued repo config variable
2750 sub git_get_project_ctags {
2751         my $project = shift;
2752         my $ctags = {};
2753
2754         $git_dir = "$projectroot/$project";
2755         if (opendir my $dh, "$git_dir/ctags") {
2756                 my @files = grep { -f $_ } map { "$git_dir/ctags/$_" } readdir($dh);
2757                 foreach my $tagfile (@files) {
2758                         open my $ct, '<', $tagfile
2759                                 or next;
2760                         my $val = <$ct>;
2761                         chomp $val if $val;
2762                         close $ct;
2763
2764                         (my $ctag = $tagfile) =~ s#.*/##;
2765                         if ($val =~ /^\d+$/) {
2766                                 $ctags->{$ctag} = $val;
2767                         } else {
2768                                 $ctags->{$ctag} = 1;
2769                         }
2770                 }
2771                 closedir $dh;
2772
2773         } elsif (open my $fh, '<', "$git_dir/ctags") {
2774                 while (my $line = <$fh>) {
2775                         chomp $line;
2776                         $ctags->{$line}++ if $line;
2777                 }
2778                 close $fh;
2779
2780         } else {
2781                 my $taglist = config_to_multi(git_get_project_config('ctag'));
2782                 foreach my $tag (@$taglist) {
2783                         $ctags->{$tag}++;
2784                 }
2785         }
2786
2787         return $ctags;
2788 }
2789
2790 # return hash, where keys are content tags ('ctags'),
2791 # and values are sum of weights of given tag in every project
2792 sub git_gather_all_ctags {
2793         my $projects = shift;
2794         my $ctags = {};
2795
2796         foreach my $p (@$projects) {
2797                 foreach my $ct (keys %{$p->{'ctags'}}) {
2798                         $ctags->{$ct} += $p->{'ctags'}->{$ct};
2799                 }
2800         }
2801
2802         return $ctags;
2803 }
2804
2805 sub git_populate_project_tagcloud {
2806         my $ctags = shift;
2807
2808         # First, merge different-cased tags; tags vote on casing
2809         my %ctags_lc;
2810         foreach (keys %$ctags) {
2811                 $ctags_lc{lc $_}->{count} += $ctags->{$_};
2812                 if (not $ctags_lc{lc $_}->{topcount}
2813                     or $ctags_lc{lc $_}->{topcount} < $ctags->{$_}) {
2814                         $ctags_lc{lc $_}->{topcount} = $ctags->{$_};
2815                         $ctags_lc{lc $_}->{topname} = $_;
2816                 }
2817         }
2818
2819         my $cloud;
2820         my $matched = $input_params{'ctag'};
2821         if (eval { require HTML::TagCloud; 1; }) {
2822                 $cloud = HTML::TagCloud->new;
2823                 foreach my $ctag (sort keys %ctags_lc) {
2824                         # Pad the title with spaces so that the cloud looks
2825                         # less crammed.
2826                         my $title = esc_html($ctags_lc{$ctag}->{topname});
2827                         $title =~ s/ /&nbsp;/g;
2828                         $title =~ s/^/&nbsp;/g;
2829                         $title =~ s/$/&nbsp;/g;
2830                         if (defined $matched && $matched eq $ctag) {
2831                                 $title = qq(<span class="match">$title</span>);
2832                         }
2833                         $cloud->add($title, href(project=>undef, ctag=>$ctag),
2834                                     $ctags_lc{$ctag}->{count});
2835                 }
2836         } else {
2837                 $cloud = {};
2838                 foreach my $ctag (keys %ctags_lc) {
2839                         my $title = esc_html($ctags_lc{$ctag}->{topname}, -nbsp=>1);
2840                         if (defined $matched && $matched eq $ctag) {
2841                                 $title = qq(<span class="match">$title</span>);
2842                         }
2843                         $cloud->{$ctag}{count} = $ctags_lc{$ctag}->{count};
2844                         $cloud->{$ctag}{ctag} =
2845                                 $cgi->a({-href=>href(project=>undef, ctag=>$ctag)}, $title);
2846                 }
2847         }
2848         return $cloud;
2849 }
2850
2851 sub git_show_project_tagcloud {
2852         my ($cloud, $count) = @_;
2853         if (ref $cloud eq 'HTML::TagCloud') {
2854                 return $cloud->html_and_css($count);
2855         } else {
2856                 my @tags = sort { $cloud->{$a}->{'count'} <=> $cloud->{$b}->{'count'} } keys %$cloud;
2857                 return
2858                         '<div id="htmltagcloud"'.($project ? '' : ' align="center"').'>' .
2859                         join (', ', map {
2860                                 $cloud->{$_}->{'ctag'}
2861                         } splice(@tags, 0, $count)) .
2862                         '</div>';
2863         }
2864 }
2865
2866 sub git_get_project_url_list {
2867         my $path = shift;
2868
2869         $git_dir = "$projectroot/$path";
2870         open my $fd, '<', "$git_dir/cloneurl"
2871                 or return wantarray ?
2872                 @{ config_to_multi(git_get_project_config('url')) } :
2873                    config_to_multi(git_get_project_config('url'));
2874         my @git_project_url_list = map { chomp; $_ } <$fd>;
2875         close $fd;
2876
2877         return wantarray ? @git_project_url_list : \@git_project_url_list;
2878 }
2879
2880 sub git_get_projects_list {
2881         my $filter = shift || '';
2882         my $paranoid = shift;
2883         my @list;
2884
2885         if (-d $projects_list) {
2886                 # search in directory
2887                 my $dir = $projects_list;
2888                 # remove the trailing "/"
2889                 $dir =~ s!/+$!!;
2890                 my $pfxlen = length("$dir");
2891                 my $pfxdepth = ($dir =~ tr!/!!);
2892                 # when filtering, search only given subdirectory
2893                 if ($filter && !$paranoid) {
2894                         $dir .= "/$filter";
2895                         $dir =~ s!/+$!!;
2896                 }
2897
2898                 File::Find::find({
2899                         follow_fast => 1, # follow symbolic links
2900                         follow_skip => 2, # ignore duplicates
2901                         dangling_symlinks => 0, # ignore dangling symlinks, silently
2902                         wanted => sub {
2903                                 # global variables
2904                                 our $project_maxdepth;
2905                                 our $projectroot;
2906                                 # skip project-list toplevel, if we get it.
2907                                 return if (m!^[/.]$!);
2908                                 # only directories can be git repositories
2909                                 return unless (-d $_);
2910                                 # don't traverse too deep (Find is super slow on os x)
2911                                 # $project_maxdepth excludes depth of $projectroot
2912                                 if (($File::Find::name =~ tr!/!!) - $pfxdepth > $project_maxdepth) {
2913                                         $File::Find::prune = 1;
2914                                         return;
2915                                 }
2916
2917                                 my $path = substr($File::Find::name, $pfxlen + 1);
2918                                 # paranoidly only filter here
2919                                 if ($paranoid && $filter && $path !~ m!^\Q$filter\E/!) {
2920                                         next;
2921                                 }
2922                                 # we check related file in $projectroot
2923                                 if (check_export_ok("$projectroot/$path")) {
2924                                         push @list, { path => $path };
2925                                         $File::Find::prune = 1;
2926                                 }
2927                         },
2928                 }, "$dir");
2929
2930         } elsif (-f $projects_list) {
2931                 # read from file(url-encoded):
2932                 # 'git%2Fgit.git Linus+Torvalds'
2933                 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
2934                 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
2935                 open my $fd, '<', $projects_list or return;
2936         PROJECT:
2937                 while (my $line = <$fd>) {
2938                         chomp $line;
2939                         my ($path, $owner) = split ' ', $line;
2940                         $path = unescape($path);
2941                         $owner = unescape($owner);
2942                         if (!defined $path) {
2943                                 next;
2944                         }
2945                         # if $filter is rpovided, check if $path begins with $filter
2946                         if ($filter && $path !~ m!^\Q$filter\E/!) {
2947                                 next;
2948                         }
2949                         if (check_export_ok("$projectroot/$path")) {
2950                                 my $pr = {
2951                                         path => $path,
2952                                         owner => to_utf8($owner),
2953                                 };
2954                                 push @list, $pr;
2955                         }
2956                 }
2957                 close $fd;
2958         }
2959         return @list;
2960 }
2961
2962 # written with help of Tree::Trie module (Perl Artistic License, GPL compatibile)
2963 # as side effects it sets 'forks' field to list of forks for forked projects
2964 sub filter_forks_from_projects_list {
2965         my $projects = shift;
2966
2967         my %trie; # prefix tree of directories (path components)
2968         # generate trie out of those directories that might contain forks
2969         foreach my $pr (@$projects) {
2970                 my $path = $pr->{'path'};
2971                 $path =~ s/\.git$//;      # forks of 'repo.git' are in 'repo/' directory
2972                 next if ($path =~ m!/$!); # skip non-bare repositories, e.g. 'repo/.git'
2973                 next unless ($path);      # skip '.git' repository: tests, git-instaweb
2974                 next unless (-d "$projectroot/$path"); # containing directory exists
2975                 $pr->{'forks'} = [];      # there can be 0 or more forks of project
2976
2977                 # add to trie
2978                 my @dirs = split('/', $path);
2979                 # walk the trie, until either runs out of components or out of trie
2980                 my $ref = \%trie;
2981                 while (scalar @dirs &&
2982                        exists($ref->{$dirs[0]})) {
2983                         $ref = $ref->{shift @dirs};
2984                 }
2985                 # create rest of trie structure from rest of components
2986                 foreach my $dir (@dirs) {
2987                         $ref = $ref->{$dir} = {};
2988                 }
2989                 # create end marker, store $pr as a data
2990                 $ref->{''} = $pr if (!exists $ref->{''});
2991         }
2992
2993         # filter out forks, by finding shortest prefix match for paths
2994         my @filtered;
2995  PROJECT:
2996         foreach my $pr (@$projects) {
2997                 # trie lookup
2998                 my $ref = \%trie;
2999         DIR:
3000                 foreach my $dir (split('/', $pr->{'path'})) {
3001                         if (exists $ref->{''}) {
3002                                 # found [shortest] prefix, is a fork - skip it
3003                                 push @{$ref->{''}{'forks'}}, $pr;
3004                                 next PROJECT;
3005                         }
3006                         if (!exists $ref->{$dir}) {
3007                                 # not in trie, cannot have prefix, not a fork
3008                                 push @filtered, $pr;
3009                                 next PROJECT;
3010                         }
3011                         # If the dir is there, we just walk one step down the trie.
3012                         $ref = $ref->{$dir};
3013                 }
3014                 # we ran out of trie
3015                 # (shouldn't happen: it's either no match, or end marker)
3016                 push @filtered, $pr;
3017         }
3018
3019         return @filtered;
3020 }
3021
3022 # note: fill_project_list_info must be run first,
3023 # for 'descr_long' and 'ctags' to be filled
3024 sub search_projects_list {
3025         my ($projlist, %opts) = @_;
3026         my $tagfilter  = $opts{'tagfilter'};
3027         my $searchtext = $opts{'searchtext'};
3028
3029         return @$projlist
3030                 unless ($tagfilter || $searchtext);
3031
3032         # searching projects require filling to be run before it;
3033         fill_project_list_info($projlist,
3034                                $tagfilter  ? 'ctags' : (),
3035                                $searchtext ? ('path', 'descr') : ());
3036         my @projects;
3037  PROJECT:
3038         foreach my $pr (@$projlist) {
3039
3040                 if ($tagfilter) {
3041                         next unless ref($pr->{'ctags'}) eq 'HASH';
3042                         next unless
3043                                 grep { lc($_) eq lc($tagfilter) } keys %{$pr->{'ctags'}};
3044                 }
3045
3046                 if ($searchtext) {
3047                         next unless
3048                                 $pr->{'path'} =~ /$searchtext/ ||
3049                                 $pr->{'descr_long'} =~ /$searchtext/;
3050                 }
3051
3052                 push @projects, $pr;
3053         }
3054
3055         return @projects;
3056 }
3057
3058 our $gitweb_project_owner = undef;
3059 sub git_get_project_list_from_file {
3060
3061         return if (defined $gitweb_project_owner);
3062
3063         $gitweb_project_owner = {};
3064         # read from file (url-encoded):
3065         # 'git%2Fgit.git Linus+Torvalds'
3066         # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
3067         # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
3068         if (-f $projects_list) {
3069                 open(my $fd, '<', $projects_list);
3070                 while (my $line = <$fd>) {
3071                         chomp $line;
3072                         my ($pr, $ow) = split ' ', $line;
3073                         $pr = unescape($pr);
3074                         $ow = unescape($ow);
3075                         $gitweb_project_owner->{$pr} = to_utf8($ow);
3076                 }
3077                 close $fd;
3078         }
3079 }
3080
3081 sub git_get_project_owner {
3082         my $project = shift;
3083         my $owner;
3084
3085         return undef unless $project;
3086         $git_dir = "$projectroot/$project";
3087
3088         if (!defined $gitweb_project_owner) {
3089                 git_get_project_list_from_file();
3090         }
3091
3092         if (exists $gitweb_project_owner->{$project}) {
3093                 $owner = $gitweb_project_owner->{$project};
3094         }
3095         if (!defined $owner){
3096                 $owner = git_get_project_config('owner');
3097         }
3098         if (!defined $owner) {
3099                 $owner = get_file_owner("$git_dir");
3100         }
3101
3102         return $owner;
3103 }
3104
3105 sub git_get_last_activity {
3106         my ($path) = @_;
3107         my $fd;
3108
3109         $git_dir = "$projectroot/$path";
3110         open($fd, "-|", git_cmd(), 'for-each-ref',
3111              '--format=%(committer)',
3112              '--sort=-committerdate',
3113              '--count=1',
3114              'refs/heads') or return;
3115         my $most_recent = <$fd>;
3116         close $fd or return;
3117         if (defined $most_recent &&
3118             $most_recent =~ / (\d+) [-+][01]\d\d\d$/) {
3119                 my $timestamp = $1;
3120                 my $age = time - $timestamp;
3121                 return ($age, age_string($age));
3122         }
3123         return (undef, undef);
3124 }
3125
3126 # Implementation note: when a single remote is wanted, we cannot use 'git
3127 # remote show -n' because that command always work (assuming it's a remote URL
3128 # if it's not defined), and we cannot use 'git remote show' because that would
3129 # try to make a network roundtrip. So the only way to find if that particular
3130 # remote is defined is to walk the list provided by 'git remote -v' and stop if
3131 # and when we find what we want.
3132 sub git_get_remotes_list {
3133         my $wanted = shift;
3134         my %remotes = ();
3135
3136         open my $fd, '-|' , git_cmd(), 'remote', '-v';
3137         return unless $fd;
3138         while (my $remote = <$fd>) {
3139                 chomp $remote;
3140                 $remote =~ s!\t(.*?)\s+\((\w+)\)$!!;
3141                 next if $wanted and not $remote eq $wanted;
3142                 my ($url, $key) = ($1, $2);
3143
3144                 $remotes{$remote} ||= { 'heads' => () };
3145                 $remotes{$remote}{$key} = $url;
3146         }
3147         close $fd or return;
3148         return wantarray ? %remotes : \%remotes;
3149 }
3150
3151 # Takes a hash of remotes as first parameter and fills it by adding the
3152 # available remote heads for each of the indicated remotes.
3153 sub fill_remote_heads {
3154         my $remotes = shift;
3155         my @heads = map { "remotes/$_" } keys %$remotes;
3156         my @remoteheads = git_get_heads_list(undef, @heads);
3157         foreach my $remote (keys %$remotes) {
3158                 $remotes->{$remote}{'heads'} = [ grep {
3159                         $_->{'name'} =~ s!^$remote/!!
3160                         } @remoteheads ];
3161         }
3162 }
3163
3164 sub git_get_references {
3165         my $type = shift || "";
3166         my %refs;
3167         # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
3168         # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
3169         open my $fd, "-|", git_cmd(), "show-ref", "--dereference",
3170                 ($type ? ("--", "refs/$type") : ()) # use -- <pattern> if $type
3171                 or return;
3172
3173         while (my $line = <$fd>) {
3174                 chomp $line;
3175                 if ($line =~ m!^([0-9a-fA-F]{40})\srefs/($type.*)$!) {
3176                         if (defined $refs{$1}) {
3177                                 push @{$refs{$1}}, $2;
3178                         } else {
3179                                 $refs{$1} = [ $2 ];
3180                         }
3181                 }
3182         }
3183         close $fd or return;
3184         return \%refs;
3185 }
3186
3187 sub git_get_rev_name_tags {
3188         my $hash = shift || return undef;
3189
3190         open my $fd, "-|", git_cmd(), "name-rev", "--tags", $hash
3191                 or return;
3192         my $name_rev = <$fd>;
3193         close $fd;
3194
3195         if ($name_rev =~ m|^$hash tags/(.*)$|) {
3196                 return $1;
3197         } else {
3198                 # catches also '$hash undefined' output
3199                 return undef;
3200         }
3201 }
3202
3203 ## ----------------------------------------------------------------------
3204 ## parse to hash functions
3205
3206 sub parse_date {
3207         my $epoch = shift;
3208         my $tz = shift || "-0000";
3209
3210         my %date;
3211         my @months = ("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec");
3212         my @days = ("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");
3213         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($epoch);
3214         $date{'hour'} = $hour;
3215         $date{'minute'} = $min;
3216         $date{'mday'} = $mday;
3217         $date{'day'} = $days[$wday];
3218         $date{'month'} = $months[$mon];
3219         $date{'rfc2822'}   = sprintf "%s, %d %s %4d %02d:%02d:%02d +0000",
3220                              $days[$wday], $mday, $months[$mon], 1900+$year, $hour ,$min, $sec;
3221         $date{'mday-time'} = sprintf "%d %s %02d:%02d",
3222                              $mday, $months[$mon], $hour ,$min;
3223         $date{'iso-8601'}  = sprintf "%04d-%02d-%02dT%02d:%02d:%02dZ",
3224                              1900+$year, 1+$mon, $mday, $hour ,$min, $sec;
3225
3226         my ($tz_sign, $tz_hour, $tz_min) =
3227                 ($tz =~ m/^([-+])(\d\d)(\d\d)$/);
3228         $tz_sign = ($tz_sign eq '-' ? -1 : +1);
3229         my $local = $epoch + $tz_sign*((($tz_hour*60) + $tz_min)*60);
3230         ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($local);
3231         $date{'hour_local'} = $hour;
3232         $date{'minute_local'} = $min;
3233         $date{'tz_local'} = $tz;
3234         $date{'iso-tz'} = sprintf("%04d-%02d-%02d %02d:%02d:%02d %s",
3235                                   1900+$year, $mon+1, $mday,
3236                                   $hour, $min, $sec, $tz);
3237         return %date;
3238 }
3239
3240 sub parse_tag {
3241         my $tag_id = shift;
3242         my %tag;
3243         my @comment;
3244
3245         open my $fd, "-|", git_cmd(), "cat-file", "tag", $tag_id or return;
3246         $tag{'id'} = $tag_id;
3247         while (my $line = <$fd>) {
3248                 chomp $line;
3249                 if ($line =~ m/^object ([0-9a-fA-F]{40})$/) {
3250                         $tag{'object'} = $1;
3251                 } elsif ($line =~ m/^type (.+)$/) {
3252                         $tag{'type'} = $1;
3253                 } elsif ($line =~ m/^tag (.+)$/) {
3254                         $tag{'name'} = $1;
3255                 } elsif ($line =~ m/^tagger (.*) ([0-9]+) (.*)$/) {
3256                         $tag{'author'} = $1;
3257                         $tag{'author_epoch'} = $2;
3258                         $tag{'author_tz'} = $3;
3259                         if ($tag{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3260                                 $tag{'author_name'}  = $1;
3261                                 $tag{'author_email'} = $2;
3262                         } else {
3263                                 $tag{'author_name'} = $tag{'author'};
3264                         }
3265                 } elsif ($line =~ m/--BEGIN/) {
3266                         push @comment, $line;
3267                         last;
3268                 } elsif ($line eq "") {
3269                         last;
3270                 }
3271         }
3272         push @comment, <$fd>;
3273         $tag{'comment'} = \@comment;
3274         close $fd or return;
3275         if (!defined $tag{'name'}) {
3276                 return
3277         };
3278         return %tag
3279 }
3280
3281 sub parse_commit_text {
3282         my ($commit_text, $withparents) = @_;
3283         my @commit_lines = split '\n', $commit_text;
3284         my %co;
3285
3286         pop @commit_lines; # Remove '\0'
3287
3288         if (! @commit_lines) {
3289                 return;
3290         }
3291
3292         my $header = shift @commit_lines;
3293         if ($header !~ m/^[0-9a-fA-F]{40}/) {
3294                 return;
3295         }
3296         ($co{'id'}, my @parents) = split ' ', $header;
3297         while (my $line = shift @commit_lines) {
3298                 last if $line eq "\n";
3299                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
3300                         $co{'tree'} = $1;
3301                 } elsif ((!defined $withparents) && ($line =~ m/^parent ([0-9a-fA-F]{40})$/)) {
3302                         push @parents, $1;
3303                 } elsif ($line =~ m/^author (.*) ([0-9]+) (.*)$/) {
3304                         $co{'author'} = to_utf8($1);
3305                         $co{'author_epoch'} = $2;
3306                         $co{'author_tz'} = $3;
3307                         if ($co{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3308                                 $co{'author_name'}  = $1;
3309                                 $co{'author_email'} = $2;
3310                         } else {
3311                                 $co{'author_name'} = $co{'author'};
3312                         }
3313                 } elsif ($line =~ m/^committer (.*) ([0-9]+) (.*)$/) {
3314                         $co{'committer'} = to_utf8($1);
3315                         $co{'committer_epoch'} = $2;
3316                         $co{'committer_tz'} = $3;
3317                         if ($co{'committer'} =~ m/^([^<]+) <([^>]*)>/) {
3318                                 $co{'committer_name'}  = $1;
3319                                 $co{'committer_email'} = $2;
3320                         } else {
3321                                 $co{'committer_name'} = $co{'committer'};
3322                         }
3323                 }
3324         }
3325         if (!defined $co{'tree'}) {
3326                 return;
3327         };
3328         $co{'parents'} = \@parents;
3329         $co{'parent'} = $parents[0];
3330
3331         foreach my $title (@commit_lines) {
3332                 $title =~ s/^    //;
3333                 if ($title ne "") {
3334                         $co{'title'} = chop_str($title, 80, 5);
3335                         # remove leading stuff of merges to make the interesting part visible
3336                         if (length($title) > 50) {
3337                                 $title =~ s/^Automatic //;
3338                                 $title =~ s/^merge (of|with) /Merge ... /i;
3339                                 if (length($title) > 50) {
3340                                         $title =~ s/(http|rsync):\/\///;
3341                                 }
3342                                 if (length($title) > 50) {
3343                                         $title =~ s/(master|www|rsync)\.//;
3344                                 }
3345                                 if (length($title) > 50) {
3346                                         $title =~ s/kernel.org:?//;
3347                                 }
3348                                 if (length($title) > 50) {
3349                                         $title =~ s/\/pub\/scm//;
3350                                 }
3351                         }
3352                         $co{'title_short'} = chop_str($title, 50, 5);
3353                         last;
3354                 }
3355         }
3356         if (! defined $co{'title'} || $co{'title'} eq "") {
3357                 $co{'title'} = $co{'title_short'} = '(no commit message)';
3358         }
3359         # remove added spaces
3360         foreach my $line (@commit_lines) {
3361                 $line =~ s/^    //;
3362         }
3363         $co{'comment'} = \@commit_lines;
3364
3365         my $age = time - $co{'committer_epoch'};
3366         $co{'age'} = $age;
3367         $co{'age_string'} = age_string($age);
3368         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($co{'committer_epoch'});
3369         if ($age > 60*60*24*7*2) {
3370                 $co{'age_string_date'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3371                 $co{'age_string_age'} = $co{'age_string'};
3372         } else {
3373                 $co{'age_string_date'} = $co{'age_string'};
3374                 $co{'age_string_age'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3375         }
3376         return %co;
3377 }
3378
3379 sub parse_commit {
3380         my ($commit_id) = @_;
3381         my %co;
3382
3383         local $/ = "\0";
3384
3385         open my $fd, "-|", git_cmd(), "rev-list",
3386                 "--parents",
3387                 "--header",
3388                 "--max-count=1",
3389                 $commit_id,
3390                 "--",
3391                 or die_error(500, "Open git-rev-list failed");
3392         %co = parse_commit_text(<$fd>, 1);
3393         close $fd;
3394
3395         return %co;
3396 }
3397
3398 sub parse_commits {
3399         my ($commit_id, $maxcount, $skip, $filename, @args) = @_;
3400         my @cos;
3401
3402         $maxcount ||= 1;
3403         $skip ||= 0;
3404
3405         local $/ = "\0";
3406
3407         open my $fd, "-|", git_cmd(), "rev-list",
3408                 "--header",
3409                 @args,
3410                 ("--max-count=" . $maxcount),
3411                 ("--skip=" . $skip),
3412                 @extra_options,
3413                 $commit_id,
3414                 "--",
3415                 ($filename ? ($filename) : ())
3416                 or die_error(500, "Open git-rev-list failed");
3417         while (my $line = <$fd>) {
3418                 my %co = parse_commit_text($line);
3419                 push @cos, \%co;
3420         }
3421         close $fd;
3422
3423         return wantarray ? @cos : \@cos;
3424 }
3425
3426 # parse line of git-diff-tree "raw" output
3427 sub parse_difftree_raw_line {
3428         my $line = shift;
3429         my %res;
3430
3431         # ':100644 100644 03b218260e99b78c6df0ed378e59ed9205ccc96d 3b93d5e7cc7f7dd4ebed13a5cc1a4ad976fc94d8 M   ls-files.c'
3432         # ':100644 100644 7f9281985086971d3877aca27704f2aaf9c448ce bc190ebc71bbd923f2b728e505408f5e54bd073a M   rev-tree.c'
3433         if ($line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)([0-9]{0,3})\t(.*)$/) {
3434                 $res{'from_mode'} = $1;
3435                 $res{'to_mode'} = $2;
3436                 $res{'from_id'} = $3;
3437                 $res{'to_id'} = $4;
3438                 $res{'status'} = $5;
3439                 $res{'similarity'} = $6;
3440                 if ($res{'status'} eq 'R' || $res{'status'} eq 'C') { # renamed or copied
3441                         ($res{'from_file'}, $res{'to_file'}) = map { unquote($_) } split("\t", $7);
3442                 } else {
3443                         $res{'from_file'} = $res{'to_file'} = $res{'file'} = unquote($7);
3444                 }
3445         }
3446         # '::100755 100755 100755 60e79ca1b01bc8b057abe17ddab484699a7f5fdb 94067cc5f73388f33722d52ae02f44692bc07490 94067cc5f73388f33722d52ae02f44692bc07490 MR git-gui/git-gui.sh'
3447         # combined diff (for merge commit)
3448         elsif ($line =~ s/^(::+)((?:[0-7]{6} )+)((?:[0-9a-fA-F]{40} )+)([a-zA-Z]+)\t(.*)$//) {
3449                 $res{'nparents'}  = length($1);
3450                 $res{'from_mode'} = [ split(' ', $2) ];
3451                 $res{'to_mode'} = pop @{$res{'from_mode'}};
3452                 $res{'from_id'} = [ split(' ', $3) ];
3453                 $res{'to_id'} = pop @{$res{'from_id'}};
3454                 $res{'status'} = [ split('', $4) ];
3455                 $res{'to_file'} = unquote($5);
3456         }
3457         # 'c512b523472485aef4fff9e57b229d9d243c967f'
3458         elsif ($line =~ m/^([0-9a-fA-F]{40})$/) {
3459                 $res{'commit'} = $1;
3460         }
3461
3462         return wantarray ? %res : \%res;
3463 }
3464
3465 # wrapper: return parsed line of git-diff-tree "raw" output
3466 # (the argument might be raw line, or parsed info)
3467 sub parsed_difftree_line {
3468         my $line_or_ref = shift;
3469
3470         if (ref($line_or_ref) eq "HASH") {
3471                 # pre-parsed (or generated by hand)
3472                 return $line_or_ref;
3473         } else {
3474                 return parse_difftree_raw_line($line_or_ref);
3475         }
3476 }
3477
3478 # parse line of git-ls-tree output
3479 sub parse_ls_tree_line {
3480         my $line = shift;
3481         my %opts = @_;
3482         my %res;
3483
3484         if ($opts{'-l'}) {
3485                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa   16717  panic.c'
3486                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40}) +(-|[0-9]+)\t(.+)$/s;
3487
3488                 $res{'mode'} = $1;
3489                 $res{'type'} = $2;
3490                 $res{'hash'} = $3;
3491                 $res{'size'} = $4;
3492                 if ($opts{'-z'}) {
3493                         $res{'name'} = $5;
3494                 } else {
3495                         $res{'name'} = unquote($5);
3496                 }
3497         } else {
3498                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
3499                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t(.+)$/s;
3500
3501                 $res{'mode'} = $1;
3502                 $res{'type'} = $2;
3503                 $res{'hash'} = $3;
3504                 if ($opts{'-z'}) {
3505                         $res{'name'} = $4;
3506                 } else {
3507                         $res{'name'} = unquote($4);
3508                 }
3509         }
3510
3511         return wantarray ? %res : \%res;
3512 }
3513
3514 # generates _two_ hashes, references to which are passed as 2 and 3 argument
3515 sub parse_from_to_diffinfo {
3516         my ($diffinfo, $from, $to, @parents) = @_;
3517
3518         if ($diffinfo->{'nparents'}) {
3519                 # combined diff
3520                 $from->{'file'} = [];
3521                 $from->{'href'} = [];
3522                 fill_from_file_info($diffinfo, @parents)
3523                         unless exists $diffinfo->{'from_file'};
3524                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
3525                         $from->{'file'}[$i] =
3526                                 defined $diffinfo->{'from_file'}[$i] ?
3527                                         $diffinfo->{'from_file'}[$i] :
3528                                         $diffinfo->{'to_file'};
3529                         if ($diffinfo->{'status'}[$i] ne "A") { # not new (added) file
3530                                 $from->{'href'}[$i] = href(action=>"blob",
3531                                                            hash_base=>$parents[$i],
3532                                                            hash=>$diffinfo->{'from_id'}[$i],
3533                                                            file_name=>$from->{'file'}[$i]);
3534                         } else {
3535                                 $from->{'href'}[$i] = undef;
3536                         }
3537                 }
3538         } else {
3539                 # ordinary (not combined) diff
3540                 $from->{'file'} = $diffinfo->{'from_file'};
3541                 if ($diffinfo->{'status'} ne "A") { # not new (added) file
3542                         $from->{'href'} = href(action=>"blob", hash_base=>$hash_parent,
3543                                                hash=>$diffinfo->{'from_id'},
3544                                                file_name=>$from->{'file'});
3545                 } else {
3546                         delete $from->{'href'};
3547                 }
3548         }
3549
3550         $to->{'file'} = $diffinfo->{'to_file'};
3551         if (!is_deleted($diffinfo)) { # file exists in result
3552                 $to->{'href'} = href(action=>"blob", hash_base=>$hash,
3553                                      hash=>$diffinfo->{'to_id'},
3554                                      file_name=>$to->{'file'});
3555         } else {
3556                 delete $to->{'href'};
3557         }
3558 }
3559
3560 ## ......................................................................
3561 ## parse to array of hashes functions
3562
3563 sub git_get_heads_list {
3564         my ($limit, @classes) = @_;
3565         @classes = ('heads') unless @classes;
3566         my @patterns = map { "refs/$_" } @classes;
3567         my @headslist;
3568
3569         open my $fd, '-|', git_cmd(), 'for-each-ref',
3570                 ($limit ? '--count='.($limit+1) : ()), '--sort=-committerdate',
3571                 '--format=%(objectname) %(refname) %(subject)%00%(committer)',
3572                 @patterns
3573                 or return;
3574         while (my $line = <$fd>) {
3575                 my %ref_item;
3576
3577                 chomp $line;
3578                 my ($refinfo, $committerinfo) = split(/\0/, $line);
3579                 my ($hash, $name, $title) = split(' ', $refinfo, 3);
3580                 my ($committer, $epoch, $tz) =
3581                         ($committerinfo =~ /^(.*) ([0-9]+) (.*)$/);
3582                 $ref_item{'fullname'}  = $name;
3583                 $name =~ s!^refs/(?:head|remote)s/!!;
3584
3585                 $ref_item{'name'}  = $name;
3586                 $ref_item{'id'}    = $hash;
3587                 $ref_item{'title'} = $title || '(no commit message)';
3588                 $ref_item{'epoch'} = $epoch;
3589                 if ($epoch) {
3590                         $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3591                 } else {
3592                         $ref_item{'age'} = "unknown";
3593                 }
3594
3595                 push @headslist, \%ref_item;
3596         }
3597         close $fd;
3598
3599         return wantarray ? @headslist : \@headslist;
3600 }
3601
3602 sub git_get_tags_list {
3603         my $limit = shift;
3604         my @tagslist;
3605
3606         open my $fd, '-|', git_cmd(), 'for-each-ref',
3607                 ($limit ? '--count='.($limit+1) : ()), '--sort=-creatordate',
3608                 '--format=%(objectname) %(objecttype) %(refname) '.
3609                 '%(*objectname) %(*objecttype) %(subject)%00%(creator)',
3610                 'refs/tags'
3611                 or return;
3612         while (my $line = <$fd>) {
3613                 my %ref_item;
3614
3615                 chomp $line;
3616                 my ($refinfo, $creatorinfo) = split(/\0/, $line);
3617                 my ($id, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
3618                 my ($creator, $epoch, $tz) =
3619                         ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
3620                 $ref_item{'fullname'} = $name;
3621                 $name =~ s!^refs/tags/!!;
3622
3623                 $ref_item{'type'} = $type;
3624                 $ref_item{'id'} = $id;
3625                 $ref_item{'name'} = $name;
3626                 if ($type eq "tag") {
3627                         $ref_item{'subject'} = $title;
3628                         $ref_item{'reftype'} = $reftype;
3629                         $ref_item{'refid'}   = $refid;
3630                 } else {
3631                         $ref_item{'reftype'} = $type;
3632                         $ref_item{'refid'}   = $id;
3633                 }
3634
3635                 if ($type eq "tag" || $type eq "commit") {
3636                         $ref_item{'epoch'} = $epoch;
3637                         if ($epoch) {
3638                                 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3639                         } else {
3640                                 $ref_item{'age'} = "unknown";
3641                         }
3642                 }
3643
3644                 push @tagslist, \%ref_item;
3645         }
3646         close $fd;
3647
3648         return wantarray ? @tagslist : \@tagslist;
3649 }
3650
3651 ## ----------------------------------------------------------------------
3652 ## filesystem-related functions
3653
3654 sub get_file_owner {
3655         my $path = shift;
3656
3657         my ($dev, $ino, $mode, $nlink, $st_uid, $st_gid, $rdev, $size) = stat($path);
3658         my ($name, $passwd, $uid, $gid, $quota, $comment, $gcos, $dir, $shell) = getpwuid($st_uid);
3659         if (!defined $gcos) {
3660                 return undef;
3661         }
3662         my $owner = $gcos;
3663         $owner =~ s/[,;].*$//;
3664         return to_utf8($owner);
3665 }
3666
3667 # assume that file exists
3668 sub insert_file {
3669         my $filename = shift;
3670
3671         open my $fd, '<', $filename;
3672         print map { to_utf8($_) } <$fd>;
3673         close $fd;
3674 }
3675
3676 ## ......................................................................
3677 ## mimetype related functions
3678
3679 sub mimetype_guess_file {
3680         my $filename = shift;
3681         my $mimemap = shift;
3682         -r $mimemap or return undef;
3683
3684         my %mimemap;
3685         open(my $mh, '<', $mimemap) or return undef;
3686         while (<$mh>) {
3687                 next if m/^#/; # skip comments
3688                 my ($mimetype, @exts) = split(/\s+/);
3689                 foreach my $ext (@exts) {
3690                         $mimemap{$ext} = $mimetype;
3691                 }
3692         }
3693         close($mh);
3694
3695         $filename =~ /\.([^.]*)$/;
3696         return $mimemap{$1};
3697 }
3698
3699 sub mimetype_guess {
3700         my $filename = shift;
3701         my $mime;
3702         $filename =~ /\./ or return undef;
3703
3704         if ($mimetypes_file) {
3705                 my $file = $mimetypes_file;
3706                 if ($file !~ m!^/!) { # if it is relative path
3707                         # it is relative to project
3708                         $file = "$projectroot/$project/$file";
3709                 }
3710                 $mime = mimetype_guess_file($filename, $file);
3711         }
3712         $mime ||= mimetype_guess_file($filename, '/etc/mime.types');
3713         return $mime;
3714 }
3715
3716 sub blob_mimetype {
3717         my $fd = shift;
3718         my $filename = shift;
3719
3720         if ($filename) {
3721                 my $mime = mimetype_guess($filename);
3722                 $mime and return $mime;
3723         }
3724
3725         # just in case
3726         return $default_blob_plain_mimetype unless $fd;
3727
3728         if (-T $fd) {
3729                 return 'text/plain';
3730         } elsif (! $filename) {
3731                 return 'application/octet-stream';
3732         } elsif ($filename =~ m/\.png$/i) {
3733                 return 'image/png';
3734         } elsif ($filename =~ m/\.gif$/i) {
3735                 return 'image/gif';
3736         } elsif ($filename =~ m/\.jpe?g$/i) {
3737                 return 'image/jpeg';
3738         } else {
3739                 return 'application/octet-stream';
3740         }
3741 }
3742
3743 sub blob_contenttype {
3744         my ($fd, $file_name, $type) = @_;
3745
3746         $type ||= blob_mimetype($fd, $file_name);
3747         if ($type eq 'text/plain' && defined $default_text_plain_charset) {
3748                 $type .= "; charset=$default_text_plain_charset";
3749         }
3750
3751         return $type;
3752 }
3753
3754 # guess file syntax for syntax highlighting; return undef if no highlighting
3755 # the name of syntax can (in the future) depend on syntax highlighter used
3756 sub guess_file_syntax {
3757         my ($highlight, $mimetype, $file_name) = @_;
3758         return undef unless ($highlight && defined $file_name);
3759         my $basename = basename($file_name, '.in');
3760         return $highlight_basename{$basename}
3761                 if exists $highlight_basename{$basename};
3762
3763         $basename =~ /\.([^.]*)$/;
3764         my $ext = $1 or return undef;
3765         return $highlight_ext{$ext}
3766                 if exists $highlight_ext{$ext};
3767
3768         return undef;
3769 }
3770
3771 # run highlighter and return FD of its output,
3772 # or return original FD if no highlighting
3773 sub run_highlighter {
3774         my ($fd, $highlight, $syntax) = @_;
3775         return $fd unless ($highlight && defined $syntax);
3776
3777         close $fd;
3778         open $fd, quote_command(git_cmd(), "cat-file", "blob", $hash)." | ".
3779                   quote_command($highlight_bin).
3780                   " --replace-tabs=8 --fragment --syntax $syntax |"
3781                 or die_error(500, "Couldn't open file or run syntax highlighter");
3782         return $fd;
3783 }
3784
3785 ## ======================================================================
3786 ## functions printing HTML: header, footer, error page
3787
3788 sub get_page_title {
3789         my $title = to_utf8($site_name);
3790
3791         unless (defined $project) {
3792                 if (defined $project_filter) {
3793                         $title .= " - projects in '" . esc_path($project_filter) . "'";
3794                 }
3795                 return $title;
3796         }
3797         $title .= " - " . to_utf8($project);
3798
3799         return $title unless (defined $action);
3800         $title .= "/$action"; # $action is US-ASCII (7bit ASCII)
3801
3802         return $title unless (defined $file_name);
3803         $title .= " - " . esc_path($file_name);
3804         if ($action eq "tree" && $file_name !~ m|/$|) {
3805                 $title .= "/";
3806         }
3807
3808         return $title;
3809 }
3810
3811 sub get_content_type_html {
3812         # require explicit support from the UA if we are to send the page as
3813         # 'application/xhtml+xml', otherwise send it as plain old 'text/html'.
3814         # we have to do this because MSIE sometimes globs '*/*', pretending to
3815         # support xhtml+xml but choking when it gets what it asked for.
3816         if (defined $cgi->http('HTTP_ACCEPT') &&
3817             $cgi->http('HTTP_ACCEPT') =~ m/(,|;|\s|^)application\/xhtml\+xml(,|;|\s|$)/ &&
3818             $cgi->Accept('application/xhtml+xml') != 0) {
3819                 return 'application/xhtml+xml';
3820         } else {
3821                 return 'text/html';
3822         }
3823 }
3824
3825 sub print_feed_meta {
3826         if (defined $project) {
3827                 my %href_params = get_feed_info();
3828                 if (!exists $href_params{'-title'}) {
3829                         $href_params{'-title'} = 'log';
3830                 }
3831
3832                 foreach my $format (qw(RSS Atom)) {
3833                         my $type = lc($format);
3834                         my %link_attr = (
3835                                 '-rel' => 'alternate',
3836                                 '-title' => esc_attr("$project - $href_params{'-title'} - $format feed"),
3837                                 '-type' => "application/$type+xml"
3838                         );
3839
3840                         $href_params{'action'} = $type;
3841                         $link_attr{'-href'} = href(%href_params);
3842                         print "<link ".
3843                               "rel=\"$link_attr{'-rel'}\" ".
3844                               "title=\"$link_attr{'-title'}\" ".
3845                               "href=\"$link_attr{'-href'}\" ".
3846                               "type=\"$link_attr{'-type'}\" ".
3847                               "/>\n";
3848
3849                         $href_params{'extra_options'} = '--no-merges';
3850                         $link_attr{'-href'} = href(%href_params);
3851                         $link_attr{'-title'} .= ' (no merges)';
3852                         print "<link ".
3853                               "rel=\"$link_attr{'-rel'}\" ".
3854                               "title=\"$link_attr{'-title'}\" ".
3855                               "href=\"$link_attr{'-href'}\" ".
3856                               "type=\"$link_attr{'-type'}\" ".
3857                               "/>\n";
3858                 }
3859
3860         } else {
3861                 printf('<link rel="alternate" title="%s projects list" '.
3862                        'href="%s" type="text/plain; charset=utf-8" />'."\n",
3863                        esc_attr($site_name), href(project=>undef, action=>"project_index"));
3864                 printf('<link rel="alternate" title="%s projects feeds" '.
3865                        'href="%s" type="text/x-opml" />'."\n",
3866                        esc_attr($site_name), href(project=>undef, action=>"opml"));
3867         }
3868 }
3869
3870 sub print_header_links {
3871         my $status = shift;
3872
3873         # print out each stylesheet that exist, providing backwards capability
3874         # for those people who defined $stylesheet in a config file
3875         if (defined $stylesheet) {
3876                 print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
3877         } else {
3878                 foreach my $stylesheet (@stylesheets) {
3879                         next unless $stylesheet;
3880                         print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
3881                 }
3882         }
3883         print_feed_meta()
3884                 if ($status eq '200 OK');
3885         if (defined $favicon) {
3886                 print qq(<link rel="shortcut icon" href=").esc_url($favicon).qq(" type="image/png" />\n);
3887         }
3888 }
3889
3890 sub print_nav_breadcrumbs_path {
3891         my $dirprefix = undef;
3892         while (my $part = shift) {
3893                 $dirprefix .= "/" if defined $dirprefix;
3894                 $dirprefix .= $part;
3895                 print $cgi->a({-href => href(project => undef,
3896                                              project_filter => $dirprefix,
3897                                              action => "project_list")},
3898                               esc_html($part)) . " / ";
3899         }
3900 }
3901
3902 sub print_nav_breadcrumbs {
3903         my %opts = @_;
3904
3905         print $cgi->a({-href => esc_url($home_link)}, $home_link_str) . " / ";
3906         if (defined $project) {
3907                 my @dirname = split '/', $project;
3908                 my $projectbasename = pop @dirname;
3909                 print_nav_breadcrumbs_path(@dirname);
3910                 print $cgi->a({-href => href(action=>"summary")}, esc_html($projectbasename));
3911                 if (defined $action) {
3912                         my $action_print = $action ;
3913                         if (defined $opts{-action_extra}) {
3914                                 $action_print = $cgi->a({-href => href(action=>$action)},
3915                                         $action);
3916                         }
3917                         print " / $action_print";
3918                 }
3919                 if (defined $opts{-action_extra}) {
3920                         print " / $opts{-action_extra}";
3921                 }
3922                 print "\n";
3923         } elsif (defined $project_filter) {
3924                 print_nav_breadcrumbs_path(split '/', $project_filter);
3925         }
3926 }
3927
3928 sub print_search_form {
3929         if (!defined $searchtext) {
3930                 $searchtext = "";
3931         }
3932         my $search_hash;
3933         if (defined $hash_base) {
3934                 $search_hash = $hash_base;
3935         } elsif (defined $hash) {
3936                 $search_hash = $hash;
3937         } else {
3938                 $search_hash = "HEAD";
3939         }
3940         my $action = $my_uri;
3941         my $use_pathinfo = gitweb_check_feature('pathinfo');
3942         if ($use_pathinfo) {
3943                 $action .= "/".esc_url($project);
3944         }
3945         print $cgi->startform(-method => "get", -action => $action) .
3946               "<div class=\"search\">\n" .
3947               (!$use_pathinfo &&
3948               $cgi->input({-name=>"p", -value=>$project, -type=>"hidden"}) . "\n") .
3949               $cgi->input({-name=>"a", -value=>"search", -type=>"hidden"}) . "\n" .
3950               $cgi->input({-name=>"h", -value=>$search_hash, -type=>"hidden"}) . "\n" .
3951               $cgi->popup_menu(-name => 'st', -default => 'commit',
3952                                -values => ['commit', 'grep', 'author', 'committer', 'pickaxe']) .
3953               $cgi->sup($cgi->a({-href => href(action=>"search_help")}, "?")) .
3954               " search:\n",
3955               $cgi->textfield(-name => "s", -value => $searchtext, -override => 1) . "\n" .
3956               "<span title=\"Extended regular expression\">" .
3957               $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
3958                              -checked => $search_use_regexp) .
3959               "</span>" .
3960               "</div>" .
3961               $cgi->end_form() . "\n";
3962 }
3963
3964 sub git_header_html {
3965         my $status = shift || "200 OK";
3966         my $expires = shift;
3967         my %opts = @_;
3968
3969         my $title = get_page_title();
3970         my $content_type = get_content_type_html();
3971         print $cgi->header(-type=>$content_type, -charset => 'utf-8',
3972                            -status=> $status, -expires => $expires)
3973                 unless ($opts{'-no_http_header'});
3974         my $mod_perl_version = $ENV{'MOD_PERL'} ? " $ENV{'MOD_PERL'}" : '';
3975         print <<EOF;
3976 <?xml version="1.0" encoding="utf-8"?>
3977 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
3978 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en-US" lang="en-US">
3979 <!-- git web interface version $version, (C) 2005-2006, Kay Sievers <kay.sievers\@vrfy.org>, Christian Gierke -->
3980 <!-- git core binaries version $git_version -->
3981 <head>
3982 <meta http-equiv="content-type" content="$content_type; charset=utf-8"/>
3983 <meta name="generator" content="gitweb/$version git/$git_version$mod_perl_version"/>
3984 <meta name="robots" content="index, nofollow"/>
3985 <title>$title</title>
3986 EOF
3987         # the stylesheet, favicon etc urls won't work correctly with path_info
3988         # unless we set the appropriate base URL
3989         if ($ENV{'PATH_INFO'}) {
3990                 print "<base href=\"".esc_url($base_url)."\" />\n";
3991         }
3992         print_header_links($status);
3993
3994         if (defined $site_html_head_string) {
3995                 print to_utf8($site_html_head_string);
3996         }
3997
3998         print "</head>\n" .
3999               "<body>\n";
4000
4001         if (defined $site_header && -f $site_header) {
4002                 insert_file($site_header);
4003         }
4004
4005         print "<div class=\"page_header\">\n";
4006         if (defined $logo) {
4007                 print $cgi->a({-href => esc_url($logo_url),
4008                                -title => $logo_label},
4009                               $cgi->img({-src => esc_url($logo),
4010                                          -width => 72, -height => 27,
4011                                          -alt => "git",
4012                                          -class => "logo"}));
4013         }
4014         print_nav_breadcrumbs(%opts);
4015         print "</div>\n";
4016
4017         my $have_search = gitweb_check_feature('search');
4018         if (defined $project && $have_search) {
4019                 print_search_form();
4020         }
4021 }
4022
4023 sub git_footer_html {
4024         my $feed_class = 'rss_logo';
4025
4026         print "<div class=\"page_footer\">\n";
4027         if (defined $project) {
4028                 my $descr = git_get_project_description($project);
4029                 if (defined $descr) {
4030                         print "<div class=\"page_footer_text\">" . esc_html($descr) . "</div>\n";
4031                 }
4032
4033                 my %href_params = get_feed_info();
4034                 if (!%href_params) {
4035                         $feed_class .= ' generic';
4036                 }
4037                 $href_params{'-title'} ||= 'log';
4038
4039                 foreach my $format (qw(RSS Atom)) {
4040                         $href_params{'action'} = lc($format);
4041                         print $cgi->a({-href => href(%href_params),
4042                                       -title => "$href_params{'-title'} $format feed",
4043                                       -class => $feed_class}, $format)."\n";
4044                 }
4045
4046         } else {
4047                 print $cgi->a({-href => href(project=>undef, action=>"opml",
4048                                              project_filter => $project_filter),
4049                               -class => $feed_class}, "OPML") . " ";
4050                 print $cgi->a({-href => href(project=>undef, action=>"project_index",
4051                                              project_filter => $project_filter),
4052                               -class => $feed_class}, "TXT") . "\n";
4053         }
4054         print "</div>\n"; # class="page_footer"
4055
4056         if (defined $t0 && gitweb_check_feature('timed')) {
4057                 print "<div id=\"generating_info\">\n";
4058                 print 'This page took '.
4059                       '<span id="generating_time" class="time_span">'.
4060                       tv_interval($t0, [ gettimeofday() ]).
4061                       ' seconds </span>'.
4062                       ' and '.
4063                       '<span id="generating_cmd">'.
4064                       $number_of_git_cmds.
4065                       '</span> git commands '.
4066                       " to generate.\n";
4067                 print "</div>\n"; # class="page_footer"
4068         }
4069
4070         if (defined $site_footer && -f $site_footer) {
4071                 insert_file($site_footer);
4072         }
4073
4074         print qq!<script type="text/javascript" src="!.esc_url($javascript).qq!"></script>\n!;
4075         if (defined $action &&
4076             $action eq 'blame_incremental') {
4077                 print qq!<script type="text/javascript">\n!.
4078                       qq!startBlame("!. href(action=>"blame_data", -replay=>1) .qq!",\n!.
4079                       qq!           "!. href() .qq!");\n!.
4080                       qq!</script>\n!;
4081         } else {
4082                 my ($jstimezone, $tz_cookie, $datetime_class) =
4083                         gitweb_get_feature('javascript-timezone');
4084
4085                 print qq!<script type="text/javascript">\n!.
4086                       qq!window.onload = function () {\n!;
4087                 if (gitweb_check_feature('javascript-actions')) {
4088                         print qq!       fixLinks();\n!;
4089                 }
4090                 if ($jstimezone && $tz_cookie && $datetime_class) {
4091                         print qq!       var tz_cookie = { name: '$tz_cookie', expires: 14, path: '/' };\n!. # in days
4092                               qq!       onloadTZSetup('$jstimezone', tz_cookie, '$datetime_class');\n!;
4093                 }
4094                 print qq!};\n!.
4095                       qq!</script>\n!;
4096         }
4097
4098         print "</body>\n" .
4099               "</html>";
4100 }
4101
4102 # die_error(<http_status_code>, <error_message>[, <detailed_html_description>])
4103 # Example: die_error(404, 'Hash not found')
4104 # By convention, use the following status codes (as defined in RFC 2616):
4105 # 400: Invalid or missing CGI parameters, or
4106 #      requested object exists but has wrong type.
4107 # 403: Requested feature (like "pickaxe" or "snapshot") not enabled on
4108 #      this server or project.
4109 # 404: Requested object/revision/project doesn't exist.
4110 # 500: The server isn't configured properly, or
4111 #      an internal error occurred (e.g. failed assertions caused by bugs), or
4112 #      an unknown error occurred (e.g. the git binary died unexpectedly).
4113 # 503: The server is currently unavailable (because it is overloaded,
4114 #      or down for maintenance).  Generally, this is a temporary state.
4115 sub die_error {
4116         my $status = shift || 500;
4117         my $error = esc_html(shift) || "Internal Server Error";
4118         my $extra = shift;
4119         my %opts = @_;
4120
4121         my %http_responses = (
4122                 400 => '400 Bad Request',
4123                 403 => '403 Forbidden',
4124                 404 => '404 Not Found',
4125                 500 => '500 Internal Server Error',
4126                 503 => '503 Service Unavailable',
4127         );
4128         git_header_html($http_responses{$status}, undef, %opts);
4129         print <<EOF;
4130 <div class="page_body">
4131 <br /><br />
4132 $status - $error
4133 <br />
4134 EOF
4135         if (defined $extra) {
4136                 print "<hr />\n" .
4137                       "$extra\n";
4138         }
4139         print "</div>\n";
4140
4141         git_footer_html();
4142         goto DONE_GITWEB
4143                 unless ($opts{'-error_handler'});
4144 }
4145
4146 ## ----------------------------------------------------------------------
4147 ## functions printing or outputting HTML: navigation
4148
4149 sub git_print_page_nav {
4150         my ($current, $suppress, $head, $treehead, $treebase, $extra) = @_;
4151         $extra = '' if !defined $extra; # pager or formats
4152
4153         my @navs = qw(summary shortlog log commit commitdiff tree);
4154         if ($suppress) {
4155                 @navs = grep { $_ ne $suppress } @navs;
4156         }
4157
4158         my %arg = map { $_ => {action=>$_} } @navs;
4159         if (defined $head) {
4160                 for (qw(commit commitdiff)) {
4161                         $arg{$_}{'hash'} = $head;
4162                 }
4163                 if ($current =~ m/^(tree | log | shortlog | commit | commitdiff | search)$/x) {
4164                         for (qw(shortlog log)) {
4165                                 $arg{$_}{'hash'} = $head;
4166                         }
4167                 }
4168         }
4169
4170         $arg{'tree'}{'hash'} = $treehead if defined $treehead;
4171         $arg{'tree'}{'hash_base'} = $treebase if defined $treebase;
4172
4173         my @actions = gitweb_get_feature('actions');
4174         my %repl = (
4175                 '%' => '%',
4176                 'n' => $project,         # project name
4177                 'f' => $git_dir,         # project path within filesystem
4178                 'h' => $treehead || '',  # current hash ('h' parameter)
4179                 'b' => $treebase || '',  # hash base ('hb' parameter)
4180         );
4181         while (@actions) {
4182                 my ($label, $link, $pos) = splice(@actions,0,3);
4183                 # insert
4184                 @navs = map { $_ eq $pos ? ($_, $label) : $_ } @navs;
4185                 # munch munch
4186                 $link =~ s/%([%nfhb])/$repl{$1}/g;
4187                 $arg{$label}{'_href'} = $link;
4188         }
4189
4190         print "<div class=\"page_nav\">\n" .
4191                 (join " | ",
4192                  map { $_ eq $current ?
4193                        $_ : $cgi->a({-href => ($arg{$_}{_href} ? $arg{$_}{_href} : href(%{$arg{$_}}))}, "$_")
4194                  } @navs);
4195         print "<br/>\n$extra<br/>\n" .
4196               "</div>\n";
4197 }
4198
4199 # returns a submenu for the nagivation of the refs views (tags, heads,
4200 # remotes) with the current view disabled and the remotes view only
4201 # available if the feature is enabled
4202 sub format_ref_views {
4203         my ($current) = @_;
4204         my @ref_views = qw{tags heads};
4205         push @ref_views, 'remotes' if gitweb_check_feature('remote_heads');
4206         return join " | ", map {
4207                 $_ eq $current ? $_ :
4208                 $cgi->a({-href => href(action=>$_)}, $_)
4209         } @ref_views
4210 }
4211
4212 sub format_paging_nav {
4213         my ($action, $page, $has_next_link) = @_;
4214         my $paging_nav;
4215
4216
4217         if ($page > 0) {
4218                 $paging_nav .=
4219                         $cgi->a({-href => href(-replay=>1, page=>undef)}, "first") .
4220                         " &sdot; " .
4221                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
4222                                  -accesskey => "p", -title => "Alt-p"}, "prev");
4223         } else {
4224                 $paging_nav .= "first &sdot; prev";
4225         }
4226
4227         if ($has_next_link) {
4228                 $paging_nav .= " &sdot; " .
4229                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
4230                                  -accesskey => "n", -title => "Alt-n"}, "next");
4231         } else {
4232                 $paging_nav .= " &sdot; next";
4233         }
4234
4235         return $paging_nav;
4236 }
4237
4238 ## ......................................................................
4239 ## functions printing or outputting HTML: div
4240
4241 sub git_print_header_div {
4242         my ($action, $title, $hash, $hash_base) = @_;
4243         my %args = ();
4244
4245         $args{'action'} = $action;
4246         $args{'hash'} = $hash if $hash;
4247         $args{'hash_base'} = $hash_base if $hash_base;
4248
4249         print "<div class=\"header\">\n" .
4250               $cgi->a({-href => href(%args), -class => "title"},
4251               $title ? $title : $action) .
4252               "\n</div>\n";
4253 }
4254
4255 sub format_repo_url {
4256         my ($name, $url) = @_;
4257         return "<tr class=\"metadata_url\"><td>$name</td><td>$url</td></tr>\n";
4258 }
4259
4260 # Group output by placing it in a DIV element and adding a header.
4261 # Options for start_div() can be provided by passing a hash reference as the
4262 # first parameter to the function.
4263 # Options to git_print_header_div() can be provided by passing an array
4264 # reference. This must follow the options to start_div if they are present.
4265 # The content can be a scalar, which is output as-is, a scalar reference, which
4266 # is output after html escaping, an IO handle passed either as *handle or
4267 # *handle{IO}, or a function reference. In the latter case all following
4268 # parameters will be taken as argument to the content function call.
4269 sub git_print_section {
4270         my ($div_args, $header_args, $content);
4271         my $arg = shift;
4272         if (ref($arg) eq 'HASH') {
4273                 $div_args = $arg;
4274                 $arg = shift;
4275         }
4276         if (ref($arg) eq 'ARRAY') {
4277                 $header_args = $arg;
4278                 $arg = shift;
4279         }
4280         $content = $arg;
4281
4282         print $cgi->start_div($div_args);
4283         git_print_header_div(@$header_args);
4284
4285         if (ref($content) eq 'CODE') {
4286                 $content->(@_);
4287         } elsif (ref($content) eq 'SCALAR') {
4288                 print esc_html($$content);
4289         } elsif (ref($content) eq 'GLOB' or ref($content) eq 'IO::Handle') {
4290                 print <$content>;
4291         } elsif (!ref($content) && defined($content)) {
4292                 print $content;
4293         }
4294
4295         print $cgi->end_div;
4296 }
4297
4298 sub format_timestamp_html {
4299         my $date = shift;
4300         my $strtime = $date->{'rfc2822'};
4301
4302         my (undef, undef, $datetime_class) =
4303                 gitweb_get_feature('javascript-timezone');
4304         if ($datetime_class) {
4305                 $strtime = qq!<span class="$datetime_class">$strtime</span>!;
4306         }
4307
4308         my $localtime_format = '(%02d:%02d %s)';
4309         if ($date->{'hour_local'} < 6) {
4310                 $localtime_format = '(<span class="atnight">%02d:%02d</span> %s)';
4311         }
4312         $strtime .= ' ' .
4313                     sprintf($localtime_format,
4314                             $date->{'hour_local'}, $date->{'minute_local'}, $date->{'tz_local'});
4315
4316         return $strtime;
4317 }
4318
4319 # Outputs the author name and date in long form
4320 sub git_print_authorship {
4321         my $co = shift;
4322         my %opts = @_;
4323         my $tag = $opts{-tag} || 'div';
4324         my $author = $co->{'author_name'};
4325
4326         my %ad = parse_date($co->{'author_epoch'}, $co->{'author_tz'});
4327         print "<$tag class=\"author_date\">" .
4328               format_search_author($author, "author", esc_html($author)) .
4329               " [".format_timestamp_html(\%ad)."]".
4330               git_get_avatar($co->{'author_email'}, -pad_before => 1) .
4331               "</$tag>\n";
4332 }
4333
4334 # Outputs table rows containing the full author or committer information,
4335 # in the format expected for 'commit' view (& similar).
4336 # Parameters are a commit hash reference, followed by the list of people
4337 # to output information for. If the list is empty it defaults to both
4338 # author and committer.
4339 sub git_print_authorship_rows {
4340         my $co = shift;
4341         # too bad we can't use @people = @_ || ('author', 'committer')
4342         my @people = @_;
4343         @people = ('author', 'committer') unless @people;
4344         foreach my $who (@people) {
4345                 my %wd = parse_date($co->{"${who}_epoch"}, $co->{"${who}_tz"});
4346                 print "<tr><td>$who</td><td>" .
4347                       format_search_author($co->{"${who}_name"}, $who,
4348                                            esc_html($co->{"${who}_name"})) . " " .
4349                       format_search_author($co->{"${who}_email"}, $who,
4350                                            esc_html("<" . $co->{"${who}_email"} . ">")) .
4351                       "</td><td rowspan=\"2\">" .
4352                       git_get_avatar($co->{"${who}_email"}, -size => 'double') .
4353                       "</td></tr>\n" .
4354                       "<tr>" .
4355                       "<td></td><td>" .
4356                       format_timestamp_html(\%wd) .
4357                       "</td>" .
4358                       "</tr>\n";
4359         }
4360 }
4361
4362 sub git_print_page_path {
4363         my $name = shift;
4364         my $type = shift;
4365         my $hb = shift;
4366
4367
4368         print "<div class=\"page_path\">";
4369         print $cgi->a({-href => href(action=>"tree", hash_base=>$hb),
4370                       -title => 'tree root'}, to_utf8("[$project]"));
4371         print " / ";
4372         if (defined $name) {
4373                 my @dirname = split '/', $name;
4374                 my $basename = pop @dirname;
4375                 my $fullname = '';
4376
4377                 foreach my $dir (@dirname) {
4378                         $fullname .= ($fullname ? '/' : '') . $dir;
4379                         print $cgi->a({-href => href(action=>"tree", file_name=>$fullname,
4380                                                      hash_base=>$hb),
4381                                       -title => $fullname}, esc_path($dir));
4382                         print " / ";
4383                 }
4384                 if (defined $type && $type eq 'blob') {
4385                         print $cgi->a({-href => href(action=>"blob_plain", file_name=>$file_name,
4386                                                      hash_base=>$hb),
4387                                       -title => $name}, esc_path($basename));
4388                 } elsif (defined $type && $type eq 'tree') {
4389                         print $cgi->a({-href => href(action=>"tree", file_name=>$file_name,
4390                                                      hash_base=>$hb),
4391                                       -title => $name}, esc_path($basename));
4392                         print " / ";
4393                 } else {
4394                         print esc_path($basename);
4395                 }
4396         }
4397         print "<br/></div>\n";
4398 }
4399
4400 sub git_print_log {
4401         my $log = shift;
4402         my %opts = @_;
4403
4404         if ($opts{'-remove_title'}) {
4405                 # remove title, i.e. first line of log
4406                 shift @$log;
4407         }
4408         # remove leading empty lines
4409         while (defined $log->[0] && $log->[0] eq "") {
4410                 shift @$log;
4411         }
4412
4413         # print log
4414         my $signoff = 0;
4415         my $empty = 0;
4416         foreach my $line (@$log) {
4417                 if ($line =~ m/^ *(signed[ \-]off[ \-]by[ :]|acked[ \-]by[ :]|cc[ :])/i) {
4418                         $signoff = 1;
4419                         $empty = 0;
4420                         if (! $opts{'-remove_signoff'}) {
4421                                 print "<span class=\"signoff\">" . esc_html($line) . "</span><br/>\n";
4422                                 next;
4423                         } else {
4424                                 # remove signoff lines
4425                                 next;
4426                         }
4427                 } else {
4428                         $signoff = 0;
4429                 }
4430
4431                 # print only one empty line
4432                 # do not print empty line after signoff
4433                 if ($line eq "") {
4434                         next if ($empty || $signoff);
4435                         $empty = 1;
4436                 } else {
4437                         $empty = 0;
4438                 }
4439
4440                 print format_log_line_html($line) . "<br/>\n";
4441         }
4442
4443         if ($opts{'-final_empty_line'}) {
4444                 # end with single empty line
4445                 print "<br/>\n" unless $empty;
4446         }
4447 }
4448
4449 # return link target (what link points to)
4450 sub git_get_link_target {
4451         my $hash = shift;
4452         my $link_target;
4453
4454         # read link
4455         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
4456                 or return;
4457         {
4458                 local $/ = undef;
4459                 $link_target = <$fd>;
4460         }
4461         close $fd
4462                 or return;
4463
4464         return $link_target;
4465 }
4466
4467 # given link target, and the directory (basedir) the link is in,
4468 # return target of link relative to top directory (top tree);
4469 # return undef if it is not possible (including absolute links).
4470 sub normalize_link_target {
4471         my ($link_target, $basedir) = @_;
4472
4473         # absolute symlinks (beginning with '/') cannot be normalized
4474         return if (substr($link_target, 0, 1) eq '/');
4475
4476         # normalize link target to path from top (root) tree (dir)
4477         my $path;
4478         if ($basedir) {
4479                 $path = $basedir . '/' . $link_target;
4480         } else {
4481                 # we are in top (root) tree (dir)
4482                 $path = $link_target;
4483         }
4484
4485         # remove //, /./, and /../
4486         my @path_parts;
4487         foreach my $part (split('/', $path)) {
4488                 # discard '.' and ''
4489                 next if (!$part || $part eq '.');
4490                 # handle '..'
4491                 if ($part eq '..') {
4492                         if (@path_parts) {
4493                                 pop @path_parts;
4494                         } else {
4495                                 # link leads outside repository (outside top dir)
4496                                 return;
4497                         }
4498                 } else {
4499                         push @path_parts, $part;
4500                 }
4501         }
4502         $path = join('/', @path_parts);
4503
4504         return $path;
4505 }
4506
4507 # print tree entry (row of git_tree), but without encompassing <tr> element
4508 sub git_print_tree_entry {
4509         my ($t, $basedir, $hash_base, $have_blame) = @_;
4510
4511         my %base_key = ();
4512         $base_key{'hash_base'} = $hash_base if defined $hash_base;
4513
4514         # The format of a table row is: mode list link.  Where mode is
4515         # the mode of the entry, list is the name of the entry, an href,
4516         # and link is the action links of the entry.
4517
4518         print "<td class=\"mode\">" . mode_str($t->{'mode'}) . "</td>\n";
4519         if (exists $t->{'size'}) {
4520                 print "<td class=\"size\">$t->{'size'}</td>\n";
4521         }
4522         if ($t->{'type'} eq "blob") {
4523                 print "<td class=\"list\">" .
4524                         $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4525                                                file_name=>"$basedir$t->{'name'}", %base_key),
4526                                 -class => "list"}, esc_path($t->{'name'}));
4527                 if (S_ISLNK(oct $t->{'mode'})) {
4528                         my $link_target = git_get_link_target($t->{'hash'});
4529                         if ($link_target) {
4530                                 my $norm_target = normalize_link_target($link_target, $basedir);
4531                                 if (defined $norm_target) {
4532                                         print " -> " .
4533                                               $cgi->a({-href => href(action=>"object", hash_base=>$hash_base,
4534                                                                      file_name=>$norm_target),
4535                                                        -title => $norm_target}, esc_path($link_target));
4536                                 } else {
4537                                         print " -> " . esc_path($link_target);
4538                                 }
4539                         }
4540                 }
4541                 print "</td>\n";
4542                 print "<td class=\"link\">";
4543                 print $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4544                                              file_name=>"$basedir$t->{'name'}", %base_key)},
4545                               "blob");
4546                 if ($have_blame) {
4547                         print " | " .
4548                               $cgi->a({-href => href(action=>"blame", hash=>$t->{'hash'},
4549                                                      file_name=>"$basedir$t->{'name'}", %base_key)},
4550                                       "blame");
4551                 }
4552                 if (defined $hash_base) {
4553                         print " | " .
4554                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4555                                                      hash=>$t->{'hash'}, file_name=>"$basedir$t->{'name'}")},
4556                                       "history");
4557                 }
4558                 print " | " .
4559                         $cgi->a({-href => href(action=>"blob_plain", hash_base=>$hash_base,
4560                                                file_name=>"$basedir$t->{'name'}")},
4561                                 "raw");
4562                 print "</td>\n";
4563
4564         } elsif ($t->{'type'} eq "tree") {
4565                 print "<td class=\"list\">";
4566                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4567                                              file_name=>"$basedir$t->{'name'}",
4568                                              %base_key)},
4569                               esc_path($t->{'name'}));
4570                 print "</td>\n";
4571                 print "<td class=\"link\">";
4572                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4573                                              file_name=>"$basedir$t->{'name'}",
4574                                              %base_key)},
4575                               "tree");
4576                 if (defined $hash_base) {
4577                         print " | " .
4578                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4579                                                      file_name=>"$basedir$t->{'name'}")},
4580                                       "history");
4581                 }
4582                 print "</td>\n";
4583         } else {
4584                 # unknown object: we can only present history for it
4585                 # (this includes 'commit' object, i.e. submodule support)
4586                 print "<td class=\"list\">" .
4587                       esc_path($t->{'name'}) .
4588                       "</td>\n";
4589                 print "<td class=\"link\">";
4590                 if (defined $hash_base) {
4591                         print $cgi->a({-href => href(action=>"history",
4592                                                      hash_base=>$hash_base,
4593                                                      file_name=>"$basedir$t->{'name'}")},
4594                                       "history");
4595                 }
4596                 print "</td>\n";
4597         }
4598 }
4599
4600 ## ......................................................................
4601 ## functions printing large fragments of HTML
4602
4603 # get pre-image filenames for merge (combined) diff
4604 sub fill_from_file_info {
4605         my ($diff, @parents) = @_;
4606
4607         $diff->{'from_file'} = [ ];
4608         $diff->{'from_file'}[$diff->{'nparents'} - 1] = undef;
4609         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4610                 if ($diff->{'status'}[$i] eq 'R' ||
4611                     $diff->{'status'}[$i] eq 'C') {
4612                         $diff->{'from_file'}[$i] =
4613                                 git_get_path_by_hash($parents[$i], $diff->{'from_id'}[$i]);
4614                 }
4615         }
4616
4617         return $diff;
4618 }
4619
4620 # is current raw difftree line of file deletion
4621 sub is_deleted {
4622         my $diffinfo = shift;
4623
4624         return $diffinfo->{'to_id'} eq ('0' x 40);
4625 }
4626
4627 # does patch correspond to [previous] difftree raw line
4628 # $diffinfo  - hashref of parsed raw diff format
4629 # $patchinfo - hashref of parsed patch diff format
4630 #              (the same keys as in $diffinfo)
4631 sub is_patch_split {
4632         my ($diffinfo, $patchinfo) = @_;
4633
4634         return defined $diffinfo && defined $patchinfo
4635                 && $diffinfo->{'to_file'} eq $patchinfo->{'to_file'};
4636 }
4637
4638
4639 sub git_difftree_body {
4640         my ($difftree, $hash, @parents) = @_;
4641         my ($parent) = $parents[0];
4642         my $have_blame = gitweb_check_feature('blame');
4643         print "<div class=\"list_head\">\n";
4644         if ($#{$difftree} > 10) {
4645                 print(($#{$difftree} + 1) . " files changed:\n");
4646         }
4647         print "</div>\n";
4648
4649         print "<table class=\"" .
4650               (@parents > 1 ? "combined " : "") .
4651               "diff_tree\">\n";
4652
4653         # header only for combined diff in 'commitdiff' view
4654         my $has_header = @$difftree && @parents > 1 && $action eq 'commitdiff';
4655         if ($has_header) {
4656                 # table header
4657                 print "<thead><tr>\n" .
4658                        "<th></th><th></th>\n"; # filename, patchN link
4659                 for (my $i = 0; $i < @parents; $i++) {
4660                         my $par = $parents[$i];
4661                         print "<th>" .
4662                               $cgi->a({-href => href(action=>"commitdiff",
4663                                                      hash=>$hash, hash_parent=>$par),
4664                                        -title => 'commitdiff to parent number ' .
4665                                                   ($i+1) . ': ' . substr($par,0,7)},
4666                                       $i+1) .
4667                               "&nbsp;</th>\n";
4668                 }
4669                 print "</tr></thead>\n<tbody>\n";
4670         }
4671
4672         my $alternate = 1;
4673         my $patchno = 0;
4674         foreach my $line (@{$difftree}) {
4675                 my $diff = parsed_difftree_line($line);
4676
4677                 if ($alternate) {
4678                         print "<tr class=\"dark\">\n";
4679                 } else {
4680                         print "<tr class=\"light\">\n";
4681                 }
4682                 $alternate ^= 1;
4683
4684                 if (exists $diff->{'nparents'}) { # combined diff
4685
4686                         fill_from_file_info($diff, @parents)
4687                                 unless exists $diff->{'from_file'};
4688
4689                         if (!is_deleted($diff)) {
4690                                 # file exists in the result (child) commit
4691                                 print "<td>" .
4692                                       $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4693                                                              file_name=>$diff->{'to_file'},
4694                                                              hash_base=>$hash),
4695                                               -class => "list"}, esc_path($diff->{'to_file'})) .
4696                                       "</td>\n";
4697                         } else {
4698                                 print "<td>" .
4699                                       esc_path($diff->{'to_file'}) .
4700                                       "</td>\n";
4701                         }
4702
4703                         if ($action eq 'commitdiff') {
4704                                 # link to patch
4705                                 $patchno++;
4706                                 print "<td class=\"link\">" .
4707                                       $cgi->a({-href => href(-anchor=>"patch$patchno")},
4708                                               "patch") .
4709                                       " | " .
4710                                       "</td>\n";
4711                         }
4712
4713                         my $has_history = 0;
4714                         my $not_deleted = 0;
4715                         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4716                                 my $hash_parent = $parents[$i];
4717                                 my $from_hash = $diff->{'from_id'}[$i];
4718                                 my $from_path = $diff->{'from_file'}[$i];
4719                                 my $status = $diff->{'status'}[$i];
4720
4721                                 $has_history ||= ($status ne 'A');
4722                                 $not_deleted ||= ($status ne 'D');
4723
4724                                 if ($status eq 'A') {
4725                                         print "<td  class=\"link\" align=\"right\"> | </td>\n";
4726                                 } elsif ($status eq 'D') {
4727                                         print "<td class=\"link\">" .
4728                                               $cgi->a({-href => href(action=>"blob",
4729                                                                      hash_base=>$hash,
4730                                                                      hash=>$from_hash,
4731                                                                      file_name=>$from_path)},
4732                                                       "blob" . ($i+1)) .
4733                                               " | </td>\n";
4734                                 } else {
4735                                         if ($diff->{'to_id'} eq $from_hash) {
4736                                                 print "<td class=\"link nochange\">";
4737                                         } else {
4738                                                 print "<td class=\"link\">";
4739                                         }
4740                                         print $cgi->a({-href => href(action=>"blobdiff",
4741                                                                      hash=>$diff->{'to_id'},
4742                                                                      hash_parent=>$from_hash,
4743                                                                      hash_base=>$hash,
4744                                                                      hash_parent_base=>$hash_parent,
4745                                                                      file_name=>$diff->{'to_file'},
4746                                                                      file_parent=>$from_path)},
4747                                                       "diff" . ($i+1)) .
4748                                               " | </td>\n";
4749                                 }
4750                         }
4751
4752                         print "<td class=\"link\">";
4753                         if ($not_deleted) {
4754                                 print $cgi->a({-href => href(action=>"blob",
4755                                                              hash=>$diff->{'to_id'},
4756                                                              file_name=>$diff->{'to_file'},
4757                                                              hash_base=>$hash)},
4758                                               "blob");
4759                                 print " | " if ($has_history);
4760                         }
4761                         if ($has_history) {
4762                                 print $cgi->a({-href => href(action=>"history",
4763                                                              file_name=>$diff->{'to_file'},
4764                                                              hash_base=>$hash)},
4765                                               "history");
4766                         }
4767                         print "</td>\n";
4768
4769                         print "</tr>\n";
4770                         next; # instead of 'else' clause, to avoid extra indent
4771                 }
4772                 # else ordinary diff
4773
4774                 my ($to_mode_oct, $to_mode_str, $to_file_type);
4775                 my ($from_mode_oct, $from_mode_str, $from_file_type);
4776                 if ($diff->{'to_mode'} ne ('0' x 6)) {
4777                         $to_mode_oct = oct $diff->{'to_mode'};
4778                         if (S_ISREG($to_mode_oct)) { # only for regular file
4779                                 $to_mode_str = sprintf("%04o", $to_mode_oct & 0777); # permission bits
4780                         }
4781                         $to_file_type = file_type($diff->{'to_mode'});
4782                 }
4783                 if ($diff->{'from_mode'} ne ('0' x 6)) {
4784                         $from_mode_oct = oct $diff->{'from_mode'};
4785                         if (S_ISREG($from_mode_oct)) { # only for regular file
4786                                 $from_mode_str = sprintf("%04o", $from_mode_oct & 0777); # permission bits
4787                         }
4788                         $from_file_type = file_type($diff->{'from_mode'});
4789                 }
4790
4791                 if ($diff->{'status'} eq "A") { # created
4792                         my $mode_chng = "<span class=\"file_status new\">[new $to_file_type";
4793                         $mode_chng   .= " with mode: $to_mode_str" if $to_mode_str;
4794                         $mode_chng   .= "]</span>";
4795                         print "<td>";
4796                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4797                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4798                                       -class => "list"}, esc_path($diff->{'file'}));
4799                         print "</td>\n";
4800                         print "<td>$mode_chng</td>\n";
4801                         print "<td class=\"link\">";
4802                         if ($action eq 'commitdiff') {
4803                                 # link to patch
4804                                 $patchno++;
4805                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4806                                               "patch") .
4807                                       " | ";
4808                         }
4809                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4810                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4811                                       "blob");
4812                         print "</td>\n";
4813
4814                 } elsif ($diff->{'status'} eq "D") { # deleted
4815                         my $mode_chng = "<span class=\"file_status deleted\">[deleted $from_file_type]</span>";
4816                         print "<td>";
4817                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4818                                                      hash_base=>$parent, file_name=>$diff->{'file'}),
4819                                        -class => "list"}, esc_path($diff->{'file'}));
4820                         print "</td>\n";
4821                         print "<td>$mode_chng</td>\n";
4822                         print "<td class=\"link\">";
4823                         if ($action eq 'commitdiff') {
4824                                 # link to patch
4825                                 $patchno++;
4826                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4827                                               "patch") .
4828                                       " | ";
4829                         }
4830                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4831                                                      hash_base=>$parent, file_name=>$diff->{'file'})},
4832                                       "blob") . " | ";
4833                         if ($have_blame) {
4834                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$parent,
4835                                                              file_name=>$diff->{'file'})},
4836                                               "blame") . " | ";
4837                         }
4838                         print $cgi->a({-href => href(action=>"history", hash_base=>$parent,
4839                                                      file_name=>$diff->{'file'})},
4840                                       "history");
4841                         print "</td>\n";
4842
4843                 } elsif ($diff->{'status'} eq "M" || $diff->{'status'} eq "T") { # modified, or type changed
4844                         my $mode_chnge = "";
4845                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4846                                 $mode_chnge = "<span class=\"file_status mode_chnge\">[changed";
4847                                 if ($from_file_type ne $to_file_type) {
4848                                         $mode_chnge .= " from $from_file_type to $to_file_type";
4849                                 }
4850                                 if (($from_mode_oct & 0777) != ($to_mode_oct & 0777)) {
4851                                         if ($from_mode_str && $to_mode_str) {
4852                                                 $mode_chnge .= " mode: $from_mode_str->$to_mode_str";
4853                                         } elsif ($to_mode_str) {
4854                                                 $mode_chnge .= " mode: $to_mode_str";
4855                                         }
4856                                 }
4857                                 $mode_chnge .= "]</span>\n";
4858                         }
4859                         print "<td>";
4860                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4861                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4862                                       -class => "list"}, esc_path($diff->{'file'}));
4863                         print "</td>\n";
4864                         print "<td>$mode_chnge</td>\n";
4865                         print "<td class=\"link\">";
4866                         if ($action eq 'commitdiff') {
4867                                 # link to patch
4868                                 $patchno++;
4869                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4870                                               "patch") .
4871                                       " | ";
4872                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4873                                 # "commit" view and modified file (not onlu mode changed)
4874                                 print $cgi->a({-href => href(action=>"blobdiff",
4875                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4876                                                              hash_base=>$hash, hash_parent_base=>$parent,
4877                                                              file_name=>$diff->{'file'})},
4878                                               "diff") .
4879                                       " | ";
4880                         }
4881                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4882                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4883                                        "blob") . " | ";
4884                         if ($have_blame) {
4885                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4886                                                              file_name=>$diff->{'file'})},
4887                                               "blame") . " | ";
4888                         }
4889                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4890                                                      file_name=>$diff->{'file'})},
4891                                       "history");
4892                         print "</td>\n";
4893
4894                 } elsif ($diff->{'status'} eq "R" || $diff->{'status'} eq "C") { # renamed or copied
4895                         my %status_name = ('R' => 'moved', 'C' => 'copied');
4896                         my $nstatus = $status_name{$diff->{'status'}};
4897                         my $mode_chng = "";
4898                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4899                                 # mode also for directories, so we cannot use $to_mode_str
4900                                 $mode_chng = sprintf(", mode: %04o", $to_mode_oct & 0777);
4901                         }
4902                         print "<td>" .
4903                               $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
4904                                                      hash=>$diff->{'to_id'}, file_name=>$diff->{'to_file'}),
4905                                       -class => "list"}, esc_path($diff->{'to_file'})) . "</td>\n" .
4906                               "<td><span class=\"file_status $nstatus\">[$nstatus from " .
4907                               $cgi->a({-href => href(action=>"blob", hash_base=>$parent,
4908                                                      hash=>$diff->{'from_id'}, file_name=>$diff->{'from_file'}),
4909                                       -class => "list"}, esc_path($diff->{'from_file'})) .
4910                               " with " . (int $diff->{'similarity'}) . "% similarity$mode_chng]</span></td>\n" .
4911                               "<td class=\"link\">";
4912                         if ($action eq 'commitdiff') {
4913                                 # link to patch
4914                                 $patchno++;
4915                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4916                                               "patch") .
4917                                       " | ";
4918                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4919                                 # "commit" view and modified file (not only pure rename or copy)
4920                                 print $cgi->a({-href => href(action=>"blobdiff",
4921                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4922                                                              hash_base=>$hash, hash_parent_base=>$parent,
4923                                                              file_name=>$diff->{'to_file'}, file_parent=>$diff->{'from_file'})},
4924                                               "diff") .
4925                                       " | ";
4926                         }
4927                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4928                                                      hash_base=>$parent, file_name=>$diff->{'to_file'})},
4929                                       "blob") . " | ";
4930                         if ($have_blame) {
4931                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4932                                                              file_name=>$diff->{'to_file'})},
4933                                               "blame") . " | ";
4934                         }
4935                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4936                                                     file_name=>$diff->{'to_file'})},
4937                                       "history");
4938                         print "</td>\n";
4939
4940                 } # we should not encounter Unmerged (U) or Unknown (X) status
4941                 print "</tr>\n";
4942         }
4943         print "</tbody>" if $has_header;
4944         print "</table>\n";
4945 }
4946
4947 sub print_sidebyside_diff_chunk {
4948         my @chunk = @_;
4949         my (@ctx, @rem, @add);
4950
4951         return unless @chunk;
4952
4953         # incomplete last line might be among removed or added lines,
4954         # or both, or among context lines: find which
4955         for (my $i = 1; $i < @chunk; $i++) {
4956                 if ($chunk[$i][0] eq 'incomplete') {
4957                         $chunk[$i][0] = $chunk[$i-1][0];
4958                 }
4959         }
4960
4961         # guardian
4962         push @chunk, ["", ""];
4963
4964         foreach my $line_info (@chunk) {
4965                 my ($class, $line) = @$line_info;
4966
4967                 # print chunk headers
4968                 if ($class && $class eq 'chunk_header') {
4969                         print $line;
4970                         next;
4971                 }
4972
4973                 ## print from accumulator when type of class of lines change
4974                 # empty contents block on start rem/add block, or end of chunk
4975                 if (@ctx && (!$class || $class eq 'rem' || $class eq 'add')) {
4976                         print join '',
4977                                 '<div class="chunk_block ctx">',
4978                                         '<div class="old">',
4979                                         @ctx,
4980                                         '</div>',
4981                                         '<div class="new">',
4982                                         @ctx,
4983                                         '</div>',
4984                                 '</div>';
4985                         @ctx = ();
4986                 }
4987                 # empty add/rem block on start context block, or end of chunk
4988                 if ((@rem || @add) && (!$class || $class eq 'ctx')) {
4989                         if (!@add) {
4990                                 # pure removal
4991                                 print join '',
4992                                         '<div class="chunk_block rem">',
4993                                                 '<div class="old">',
4994                                                 @rem,
4995                                                 '</div>',
4996                                         '</div>';
4997                         } elsif (!@rem) {
4998                                 # pure addition
4999                                 print join '',
5000                                         '<div class="chunk_block add">',
5001                                                 '<div class="new">',
5002                                                 @add,
5003                                                 '</div>',
5004                                         '</div>';
5005                         } else {
5006                                 # assume that it is change
5007                                 print join '',
5008                                         '<div class="chunk_block chg">',
5009                                                 '<div class="old">',
5010                                                 @rem,
5011                                                 '</div>',
5012                                                 '<div class="new">',
5013                                                 @add,
5014                                                 '</div>',
5015                                         '</div>';
5016                         }
5017                         @rem = @add = ();
5018                 }
5019
5020                 ## adding lines to accumulator
5021                 # guardian value
5022                 last unless $line;
5023                 # rem, add or change
5024                 if ($class eq 'rem') {
5025                         push @rem, $line;
5026                 } elsif ($class eq 'add') {
5027                         push @add, $line;
5028                 }
5029                 # context line
5030                 if ($class eq 'ctx') {
5031                         push @ctx, $line;
5032                 }
5033         }
5034 }
5035
5036 sub git_patchset_body {
5037         my ($fd, $diff_style, $difftree, $hash, @hash_parents) = @_;
5038         my ($hash_parent) = $hash_parents[0];
5039
5040         my $is_combined = (@hash_parents > 1);
5041         my $patch_idx = 0;
5042         my $patch_number = 0;
5043         my $patch_line;
5044         my $diffinfo;
5045         my $to_name;
5046         my (%from, %to);
5047         my @chunk; # for side-by-side diff
5048
5049         print "<div class=\"patchset\">\n";
5050
5051         # skip to first patch
5052         while ($patch_line = <$fd>) {
5053                 chomp $patch_line;
5054
5055                 last if ($patch_line =~ m/^diff /);
5056         }
5057
5058  PATCH:
5059         while ($patch_line) {
5060
5061                 # parse "git diff" header line
5062                 if ($patch_line =~ m/^diff --git (\"(?:[^\\\"]*(?:\\.[^\\\"]*)*)\"|[^ "]*) (.*)$/) {
5063                         # $1 is from_name, which we do not use
5064                         $to_name = unquote($2);
5065                         $to_name =~ s!^b/!!;
5066                 } elsif ($patch_line =~ m/^diff --(cc|combined) ("?.*"?)$/) {
5067                         # $1 is 'cc' or 'combined', which we do not use
5068                         $to_name = unquote($2);
5069                 } else {
5070                         $to_name = undef;
5071                 }
5072
5073                 # check if current patch belong to current raw line
5074                 # and parse raw git-diff line if needed
5075                 if (is_patch_split($diffinfo, { 'to_file' => $to_name })) {
5076                         # this is continuation of a split patch
5077                         print "<div class=\"patch cont\">\n";
5078                 } else {
5079                         # advance raw git-diff output if needed
5080                         $patch_idx++ if defined $diffinfo;
5081
5082                         # read and prepare patch information
5083                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5084
5085                         # compact combined diff output can have some patches skipped
5086                         # find which patch (using pathname of result) we are at now;
5087                         if ($is_combined) {
5088                                 while ($to_name ne $diffinfo->{'to_file'}) {
5089                                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
5090                                               format_diff_cc_simplified($diffinfo, @hash_parents) .
5091                                               "</div>\n";  # class="patch"
5092
5093                                         $patch_idx++;
5094                                         $patch_number++;
5095
5096                                         last if $patch_idx > $#$difftree;
5097                                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5098                                 }
5099                         }
5100
5101                         # modifies %from, %to hashes
5102                         parse_from_to_diffinfo($diffinfo, \%from, \%to, @hash_parents);
5103
5104                         # this is first patch for raw difftree line with $patch_idx index
5105                         # we index @$difftree array from 0, but number patches from 1
5106                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n";
5107                 }
5108
5109                 # git diff header
5110                 #assert($patch_line =~ m/^diff /) if DEBUG;
5111                 #assert($patch_line !~ m!$/$!) if DEBUG; # is chomp-ed
5112                 $patch_number++;
5113                 # print "git diff" header
5114                 print format_git_diff_header_line($patch_line, $diffinfo,
5115                                                   \%from, \%to);
5116
5117                 # print extended diff header
5118                 print "<div class=\"diff extended_header\">\n";
5119         EXTENDED_HEADER:
5120                 while ($patch_line = <$fd>) {
5121                         chomp $patch_line;
5122
5123                         last EXTENDED_HEADER if ($patch_line =~ m/^--- |^diff /);
5124
5125                         print format_extended_diff_header_line($patch_line, $diffinfo,
5126                                                                \%from, \%to);
5127                 }
5128                 print "</div>\n"; # class="diff extended_header"
5129
5130                 # from-file/to-file diff header
5131                 if (! $patch_line) {
5132                         print "</div>\n"; # class="patch"
5133                         last PATCH;
5134                 }
5135                 next PATCH if ($patch_line =~ m/^diff /);
5136                 #assert($patch_line =~ m/^---/) if DEBUG;
5137
5138                 my $last_patch_line = $patch_line;
5139                 $patch_line = <$fd>;
5140                 chomp $patch_line;
5141                 #assert($patch_line =~ m/^\+\+\+/) if DEBUG;
5142
5143                 print format_diff_from_to_header($last_patch_line, $patch_line,
5144                                                  $diffinfo, \%from, \%to,
5145                                                  @hash_parents);
5146
5147                 # the patch itself
5148         LINE:
5149                 while ($patch_line = <$fd>) {
5150                         chomp $patch_line;
5151
5152                         next PATCH if ($patch_line =~ m/^diff /);
5153
5154                         my ($class, $line) = process_diff_line($patch_line, \%from, \%to);
5155                         my $diff_classes = "diff";
5156                         $diff_classes .= " $class" if ($class);
5157                         $line = "<div class=\"$diff_classes\">$line</div>\n";
5158
5159                         if ($diff_style eq 'sidebyside' && !$is_combined) {
5160                                 if ($class eq 'chunk_header') {
5161                                         print_sidebyside_diff_chunk(@chunk);
5162                                         @chunk = ( [ $class, $line ] );
5163                                 } else {
5164                                         push @chunk, [ $class, $line ];
5165                                 }
5166                         } else {
5167                                 # default 'inline' style and unknown styles
5168                                 print $line;
5169                         }
5170                 }
5171
5172         } continue {
5173                 if (@chunk) {
5174                         print_sidebyside_diff_chunk(@chunk);
5175                         @chunk = ();
5176                 }
5177                 print "</div>\n"; # class="patch"
5178         }
5179
5180         # for compact combined (--cc) format, with chunk and patch simplification
5181         # the patchset might be empty, but there might be unprocessed raw lines
5182         for (++$patch_idx if $patch_number > 0;
5183              $patch_idx < @$difftree;
5184              ++$patch_idx) {
5185                 # read and prepare patch information
5186                 $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5187
5188                 # generate anchor for "patch" links in difftree / whatchanged part
5189                 print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
5190                       format_diff_cc_simplified($diffinfo, @hash_parents) .
5191                       "</div>\n";  # class="patch"
5192
5193                 $patch_number++;
5194         }
5195
5196         if ($patch_number == 0) {
5197                 if (@hash_parents > 1) {
5198                         print "<div class=\"diff nodifferences\">Trivial merge</div>\n";
5199                 } else {
5200                         print "<div class=\"diff nodifferences\">No differences found</div>\n";
5201                 }
5202         }
5203
5204         print "</div>\n"; # class="patchset"
5205 }
5206
5207 # . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
5208
5209 sub git_project_search_form {
5210         my ($searchtext, $search_use_regexp);
5211
5212         my $limit = '';
5213         if ($project_filter) {
5214                 $limit = " in '$project_filter/'";
5215         }
5216
5217         print "<div class=\"projsearch\">\n";
5218         print $cgi->startform(-method => 'get', -action => $my_uri) .
5219               $cgi->hidden(-name => 'a', -value => 'project_list')  . "\n";
5220         print $cgi->hidden(-name => 'pf', -value => $project_filter). "\n"
5221                 if (defined $project_filter);
5222         print $cgi->textfield(-name => 's', -value => $searchtext,
5223                               -title => "Search project by name and description$limit",
5224                               -size => 60) . "\n" .
5225               "<span title=\"Extended regular expression\">" .
5226               $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
5227                              -checked => $search_use_regexp) .
5228               "</span>\n" .
5229               $cgi->submit(-name => 'btnS', -value => 'Search') .
5230               $cgi->end_form() . "\n" .
5231               $cgi->a({-href => href(project => undef, searchtext => undef,
5232                                      project_filter => $project_filter)},
5233                       esc_html("List all projects$limit")) . "<br />\n";
5234         print "</div>\n";
5235 }
5236
5237 # entry for given @keys needs filling if at least one of keys in list
5238 # is not present in %$project_info
5239 sub project_info_needs_filling {
5240         my ($project_info, @keys) = @_;
5241
5242         # return List::MoreUtils::any { !exists $project_info->{$_} } @keys;
5243         foreach my $key (@keys) {
5244                 if (!exists $project_info->{$key}) {
5245                         return 1;
5246                 }
5247         }
5248         return;
5249 }
5250
5251 # fills project list info (age, description, owner, category, forks, etc.)
5252 # for each project in the list, removing invalid projects from
5253 # returned list, or fill only specified info.
5254 #
5255 # Invalid projects are removed from the returned list if and only if you
5256 # ask 'age' or 'age_string' to be filled, because they are the only fields
5257 # that run unconditionally git command that requires repository, and
5258 # therefore do always check if project repository is invalid.
5259 #
5260 # USAGE:
5261 # * fill_project_list_info(\@project_list, 'descr_long', 'ctags')
5262 #   ensures that 'descr_long' and 'ctags' fields are filled
5263 # * @project_list = fill_project_list_info(\@project_list)
5264 #   ensures that all fields are filled (and invalid projects removed)
5265 #
5266 # NOTE: modifies $projlist, but does not remove entries from it
5267 sub fill_project_list_info {
5268         my ($projlist, @wanted_keys) = @_;
5269         my @projects;
5270         my $filter_set = sub { return @_; };
5271         if (@wanted_keys) {
5272                 my %wanted_keys = map { $_ => 1 } @wanted_keys;
5273                 $filter_set = sub { return grep { $wanted_keys{$_} } @_; };
5274         }
5275
5276         my $show_ctags = gitweb_check_feature('ctags');
5277  PROJECT:
5278         foreach my $pr (@$projlist) {
5279                 if (project_info_needs_filling($pr, $filter_set->('age', 'age_string'))) {
5280                         my (@activity) = git_get_last_activity($pr->{'path'});
5281                         unless (@activity) {
5282                                 next PROJECT;
5283                         }
5284                         ($pr->{'age'}, $pr->{'age_string'}) = @activity;
5285                 }
5286                 if (project_info_needs_filling($pr, $filter_set->('descr', 'descr_long'))) {
5287                         my $descr = git_get_project_description($pr->{'path'}) || "";
5288                         $descr = to_utf8($descr);
5289                         $pr->{'descr_long'} = $descr;
5290                         $pr->{'descr'} = chop_str($descr, $projects_list_description_width, 5);
5291                 }
5292                 if (project_info_needs_filling($pr, $filter_set->('owner'))) {
5293                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}") || "";
5294                 }
5295                 if ($show_ctags &&
5296                     project_info_needs_filling($pr, $filter_set->('ctags'))) {
5297                         $pr->{'ctags'} = git_get_project_ctags($pr->{'path'});
5298                 }
5299                 if ($projects_list_group_categories &&
5300                     project_info_needs_filling($pr, $filter_set->('category'))) {
5301                         my $cat = git_get_project_category($pr->{'path'}) ||
5302                                                            $project_list_default_category;
5303                         $pr->{'category'} = to_utf8($cat);
5304                 }
5305
5306                 push @projects, $pr;
5307         }
5308
5309         return @projects;
5310 }
5311
5312 sub sort_projects_list {
5313         my ($projlist, $order) = @_;
5314         my @projects;
5315
5316         my %order_info = (
5317                 project => { key => 'path', type => 'str' },
5318                 descr => { key => 'descr_long', type => 'str' },
5319                 owner => { key => 'owner', type => 'str' },
5320                 age => { key => 'age', type => 'num' }
5321         );
5322         my $oi = $order_info{$order};
5323         return @$projlist unless defined $oi;
5324         if ($oi->{'type'} eq 'str') {
5325                 @projects = sort {$a->{$oi->{'key'}} cmp $b->{$oi->{'key'}}} @$projlist;
5326         } else {
5327                 @projects = sort {$a->{$oi->{'key'}} <=> $b->{$oi->{'key'}}} @$projlist;
5328         }
5329
5330         return @projects;
5331 }
5332
5333 # returns a hash of categories, containing the list of project
5334 # belonging to each category
5335 sub build_projlist_by_category {
5336         my ($projlist, $from, $to) = @_;
5337         my %categories;
5338
5339         $from = 0 unless defined $from;
5340         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5341
5342         for (my $i = $from; $i <= $to; $i++) {
5343                 my $pr = $projlist->[$i];
5344                 push @{$categories{ $pr->{'category'} }}, $pr;
5345         }
5346
5347         return wantarray ? %categories : \%categories;
5348 }
5349
5350 # print 'sort by' <th> element, generating 'sort by $name' replay link
5351 # if that order is not selected
5352 sub print_sort_th {
5353         print format_sort_th(@_);
5354 }
5355
5356 sub format_sort_th {
5357         my ($name, $order, $header) = @_;
5358         my $sort_th = "";
5359         $header ||= ucfirst($name);
5360
5361         if ($order eq $name) {
5362                 $sort_th .= "<th>$header</th>\n";
5363         } else {
5364                 $sort_th .= "<th>" .
5365                             $cgi->a({-href => href(-replay=>1, order=>$name),
5366                                      -class => "header"}, $header) .
5367                             "</th>\n";
5368         }
5369
5370         return $sort_th;
5371 }
5372
5373 sub git_project_list_rows {
5374         my ($projlist, $from, $to, $check_forks) = @_;
5375
5376         $from = 0 unless defined $from;
5377         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5378
5379         my $alternate = 1;
5380         for (my $i = $from; $i <= $to; $i++) {
5381                 my $pr = $projlist->[$i];
5382
5383                 if ($alternate) {
5384                         print "<tr class=\"dark\">\n";
5385                 } else {
5386                         print "<tr class=\"light\">\n";
5387                 }
5388                 $alternate ^= 1;
5389
5390                 if ($check_forks) {
5391                         print "<td>";
5392                         if ($pr->{'forks'}) {
5393                                 my $nforks = scalar @{$pr->{'forks'}};
5394                                 if ($nforks > 0) {
5395                                         print $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks"),
5396                                                        -title => "$nforks forks"}, "+");
5397                                 } else {
5398                                         print $cgi->span({-title => "$nforks forks"}, "+");
5399                                 }
5400                         }
5401                         print "</td>\n";
5402                 }
5403                 print "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5404                                         -class => "list"}, esc_html($pr->{'path'})) . "</td>\n" .
5405                       "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5406                                         -class => "list", -title => $pr->{'descr_long'}},
5407                                         esc_html($pr->{'descr'})) . "</td>\n" .
5408                       "<td><i>" . chop_and_escape_str($pr->{'owner'}, 15) . "</i></td>\n";
5409                 print "<td class=\"". age_class($pr->{'age'}) . "\">" .
5410                       (defined $pr->{'age_string'} ? $pr->{'age_string'} : "No commits") . "</td>\n" .
5411                       "<td class=\"link\">" .
5412                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary")}, "summary")   . " | " .
5413                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"shortlog")}, "shortlog") . " | " .
5414                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"log")}, "log") . " | " .
5415                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"tree")}, "tree") .
5416                       ($pr->{'forks'} ? " | " . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "forks") : '') .
5417                       "</td>\n" .
5418                       "</tr>\n";
5419         }
5420 }
5421
5422 sub git_project_list_body {
5423         # actually uses global variable $project
5424         my ($projlist, $order, $from, $to, $extra, $no_header) = @_;
5425         my @projects = @$projlist;
5426
5427         my $check_forks = gitweb_check_feature('forks');
5428         my $show_ctags  = gitweb_check_feature('ctags');
5429         my $tagfilter = $show_ctags ? $input_params{'ctag'} : undef;
5430         $check_forks = undef
5431                 if ($tagfilter || $searchtext);
5432
5433         # filtering out forks before filling info allows to do less work
5434         @projects = filter_forks_from_projects_list(\@projects)
5435                 if ($check_forks);
5436         # search_projects_list pre-fills required info
5437         @projects = search_projects_list(\@projects,
5438                                          'searchtext' => $searchtext,
5439                                          'tagfilter'  => $tagfilter)
5440                 if ($tagfilter || $searchtext);
5441         # fill the rest
5442         @projects = fill_project_list_info(\@projects);
5443
5444         $order ||= $default_projects_order;
5445         $from = 0 unless defined $from;
5446         $to = $#projects if (!defined $to || $#projects < $to);
5447
5448         # short circuit
5449         if ($from > $to) {
5450                 print "<center>\n".
5451                       "<b>No such projects found</b><br />\n".
5452                       "Click ".$cgi->a({-href=>href(project=>undef)},"here")." to view all projects<br />\n".
5453                       "</center>\n<br />\n";
5454                 return;
5455         }
5456
5457         @projects = sort_projects_list(\@projects, $order);
5458
5459         if ($show_ctags) {
5460                 my $ctags = git_gather_all_ctags(\@projects);
5461                 my $cloud = git_populate_project_tagcloud($ctags);
5462                 print git_show_project_tagcloud($cloud, 64);
5463         }
5464
5465         print "<table class=\"project_list\">\n";
5466         unless ($no_header) {
5467                 print "<tr>\n";
5468                 if ($check_forks) {
5469                         print "<th></th>\n";
5470                 }
5471                 print_sort_th('project', $order, 'Project');
5472                 print_sort_th('descr', $order, 'Description');
5473                 print_sort_th('owner', $order, 'Owner');
5474                 print_sort_th('age', $order, 'Last Change');
5475                 print "<th></th>\n" . # for links
5476                       "</tr>\n";
5477         }
5478
5479         if ($projects_list_group_categories) {
5480                 # only display categories with projects in the $from-$to window
5481                 @projects = sort {$a->{'category'} cmp $b->{'category'}} @projects[$from..$to];
5482                 my %categories = build_projlist_by_category(\@projects, $from, $to);
5483                 foreach my $cat (sort keys %categories) {
5484                         unless ($cat eq "") {
5485                                 print "<tr>\n";
5486                                 if ($check_forks) {
5487                                         print "<td></td>\n";
5488                                 }
5489                                 print "<td class=\"category\" colspan=\"5\">".esc_html($cat)."</td>\n";
5490                                 print "</tr>\n";
5491                         }
5492
5493                         git_project_list_rows($categories{$cat}, undef, undef, $check_forks);
5494                 }
5495         } else {
5496                 git_project_list_rows(\@projects, $from, $to, $check_forks);
5497         }
5498
5499         if (defined $extra) {
5500                 print "<tr>\n";
5501                 if ($check_forks) {
5502                         print "<td></td>\n";
5503                 }
5504                 print "<td colspan=\"5\">$extra</td>\n" .
5505                       "</tr>\n";
5506         }
5507         print "</table>\n";
5508 }
5509
5510 sub git_log_body {
5511         # uses global variable $project
5512         my ($commitlist, $from, $to, $refs, $extra) = @_;
5513
5514         $from = 0 unless defined $from;
5515         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5516
5517         for (my $i = 0; $i <= $to; $i++) {
5518                 my %co = %{$commitlist->[$i]};
5519                 next if !%co;
5520                 my $commit = $co{'id'};
5521                 my $ref = format_ref_marker($refs, $commit);
5522                 git_print_header_div('commit',
5523                                "<span class=\"age\">$co{'age_string'}</span>" .
5524                                esc_html($co{'title'}) . $ref,
5525                                $commit);
5526                 print "<div class=\"title_text\">\n" .
5527                       "<div class=\"log_link\">\n" .
5528                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") .
5529                       " | " .
5530                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") .
5531                       " | " .
5532                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree") .
5533                       "<br/>\n" .
5534                       "</div>\n";
5535                       git_print_authorship(\%co, -tag => 'span');
5536                       print "<br/>\n</div>\n";
5537
5538                 print "<div class=\"log_body\">\n";
5539                 git_print_log($co{'comment'}, -final_empty_line=> 1);
5540                 print "</div>\n";
5541         }
5542         if ($extra) {
5543                 print "<div class=\"page_nav\">\n";
5544                 print "$extra\n";
5545                 print "</div>\n";
5546         }
5547 }
5548
5549 sub git_shortlog_body {
5550         # uses global variable $project
5551         my ($commitlist, $from, $to, $refs, $extra) = @_;
5552
5553         $from = 0 unless defined $from;
5554         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5555
5556         print "<table class=\"shortlog\">\n";
5557         my $alternate = 1;
5558         for (my $i = $from; $i <= $to; $i++) {
5559                 my %co = %{$commitlist->[$i]};
5560                 my $commit = $co{'id'};
5561                 my $ref = format_ref_marker($refs, $commit);
5562                 if ($alternate) {
5563                         print "<tr class=\"dark\">\n";
5564                 } else {
5565                         print "<tr class=\"light\">\n";
5566                 }
5567                 $alternate ^= 1;
5568                 # git_summary() used print "<td><i>$co{'age_string'}</i></td>\n" .
5569                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5570                       format_author_html('td', \%co, 10) . "<td>";
5571                 print format_subject_html($co{'title'}, $co{'title_short'},
5572                                           href(action=>"commit", hash=>$commit), $ref);
5573                 print "</td>\n" .
5574                       "<td class=\"link\">" .
5575                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") . " | " .
5576                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") . " | " .
5577                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree");
5578                 my $snapshot_links = format_snapshot_links($commit);
5579                 if (defined $snapshot_links) {
5580                         print " | " . $snapshot_links;
5581                 }
5582                 print "</td>\n" .
5583                       "</tr>\n";
5584         }
5585         if (defined $extra) {
5586                 print "<tr>\n" .
5587                       "<td colspan=\"4\">$extra</td>\n" .
5588                       "</tr>\n";
5589         }
5590         print "</table>\n";
5591 }
5592
5593 sub git_history_body {
5594         # Warning: assumes constant type (blob or tree) during history
5595         my ($commitlist, $from, $to, $refs, $extra,
5596             $file_name, $file_hash, $ftype) = @_;
5597
5598         $from = 0 unless defined $from;
5599         $to = $#{$commitlist} unless (defined $to && $to <= $#{$commitlist});
5600
5601         print "<table class=\"history\">\n";
5602         my $alternate = 1;
5603         for (my $i = $from; $i <= $to; $i++) {
5604                 my %co = %{$commitlist->[$i]};
5605                 if (!%co) {
5606                         next;
5607                 }
5608                 my $commit = $co{'id'};
5609
5610                 my $ref = format_ref_marker($refs, $commit);
5611
5612                 if ($alternate) {
5613                         print "<tr class=\"dark\">\n";
5614                 } else {
5615                         print "<tr class=\"light\">\n";
5616                 }
5617                 $alternate ^= 1;
5618                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5619         # shortlog:   format_author_html('td', \%co, 10)
5620                       format_author_html('td', \%co, 15, 3) . "<td>";
5621                 # originally git_history used chop_str($co{'title'}, 50)
5622                 print format_subject_html($co{'title'}, $co{'title_short'},
5623                                           href(action=>"commit", hash=>$commit), $ref);
5624                 print "</td>\n" .
5625                       "<td class=\"link\">" .
5626                       $cgi->a({-href => href(action=>$ftype, hash_base=>$commit, file_name=>$file_name)}, $ftype) . " | " .
5627                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff");
5628
5629                 if ($ftype eq 'blob') {
5630                         my $blob_current = $file_hash;
5631                         my $blob_parent  = git_get_hash_by_path($commit, $file_name);
5632                         if (defined $blob_current && defined $blob_parent &&
5633                                         $blob_current ne $blob_parent) {
5634                                 print " | " .
5635                                         $cgi->a({-href => href(action=>"blobdiff",
5636                                                                hash=>$blob_current, hash_parent=>$blob_parent,
5637                                                                hash_base=>$hash_base, hash_parent_base=>$commit,
5638                                                                file_name=>$file_name)},
5639                                                 "diff to current");
5640                         }
5641                 }
5642                 print "</td>\n" .
5643                       "</tr>\n";
5644         }
5645         if (defined $extra) {
5646                 print "<tr>\n" .
5647                       "<td colspan=\"4\">$extra</td>\n" .
5648                       "</tr>\n";
5649         }
5650         print "</table>\n";
5651 }
5652
5653 sub git_tags_body {
5654         # uses global variable $project
5655         my ($taglist, $from, $to, $extra) = @_;
5656         $from = 0 unless defined $from;
5657         $to = $#{$taglist} if (!defined $to || $#{$taglist} < $to);
5658
5659         print "<table class=\"tags\">\n";
5660         my $alternate = 1;
5661         for (my $i = $from; $i <= $to; $i++) {
5662                 my $entry = $taglist->[$i];
5663                 my %tag = %$entry;
5664                 my $comment = $tag{'subject'};
5665                 my $comment_short;
5666                 if (defined $comment) {
5667                         $comment_short = chop_str($comment, 30, 5);
5668                 }
5669                 if ($alternate) {
5670                         print "<tr class=\"dark\">\n";
5671                 } else {
5672                         print "<tr class=\"light\">\n";
5673                 }
5674                 $alternate ^= 1;
5675                 if (defined $tag{'age'}) {
5676                         print "<td><i>$tag{'age'}</i></td>\n";
5677                 } else {
5678                         print "<td></td>\n";
5679                 }
5680                 print "<td>" .
5681                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'}),
5682                                -class => "list name"}, esc_html($tag{'name'})) .
5683                       "</td>\n" .
5684                       "<td>";
5685                 if (defined $comment) {
5686                         print format_subject_html($comment, $comment_short,
5687                                                   href(action=>"tag", hash=>$tag{'id'}));
5688                 }
5689                 print "</td>\n" .
5690                       "<td class=\"selflink\">";
5691                 if ($tag{'type'} eq "tag") {
5692                         print $cgi->a({-href => href(action=>"tag", hash=>$tag{'id'})}, "tag");
5693                 } else {
5694                         print "&nbsp;";
5695                 }
5696                 print "</td>\n" .
5697                       "<td class=\"link\">" . " | " .
5698                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'})}, $tag{'reftype'});
5699                 if ($tag{'reftype'} eq "commit") {
5700                         print " | " . $cgi->a({-href => href(action=>"shortlog", hash=>$tag{'fullname'})}, "shortlog") .
5701                               " | " . $cgi->a({-href => href(action=>"log", hash=>$tag{'fullname'})}, "log");
5702                 } elsif ($tag{'reftype'} eq "blob") {
5703                         print " | " . $cgi->a({-href => href(action=>"blob_plain", hash=>$tag{'refid'})}, "raw");
5704                 }
5705                 print "</td>\n" .
5706                       "</tr>";
5707         }
5708         if (defined $extra) {
5709                 print "<tr>\n" .
5710                       "<td colspan=\"5\">$extra</td>\n" .
5711                       "</tr>\n";
5712         }
5713         print "</table>\n";
5714 }
5715
5716 sub git_heads_body {
5717         # uses global variable $project
5718         my ($headlist, $head_at, $from, $to, $extra) = @_;
5719         $from = 0 unless defined $from;
5720         $to = $#{$headlist} if (!defined $to || $#{$headlist} < $to);
5721
5722         print "<table class=\"heads\">\n";
5723         my $alternate = 1;
5724         for (my $i = $from; $i <= $to; $i++) {
5725                 my $entry = $headlist->[$i];
5726                 my %ref = %$entry;
5727                 my $curr = defined $head_at && $ref{'id'} eq $head_at;
5728                 if ($alternate) {
5729                         print "<tr class=\"dark\">\n";
5730                 } else {
5731                         print "<tr class=\"light\">\n";
5732                 }
5733                 $alternate ^= 1;
5734                 print "<td><i>$ref{'age'}</i></td>\n" .
5735                       ($curr ? "<td class=\"current_head\">" : "<td>") .
5736                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'}),
5737                                -class => "list name"},esc_html($ref{'name'})) .
5738                       "</td>\n" .
5739                       "<td class=\"link\">" .
5740                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'})}, "shortlog") . " | " .
5741                       $cgi->a({-href => href(action=>"log", hash=>$ref{'fullname'})}, "log") . " | " .
5742                       $cgi->a({-href => href(action=>"tree", hash=>$ref{'fullname'}, hash_base=>$ref{'fullname'})}, "tree") .
5743                       "</td>\n" .
5744                       "</tr>";
5745         }
5746         if (defined $extra) {
5747                 print "<tr>\n" .
5748                       "<td colspan=\"3\">$extra</td>\n" .
5749                       "</tr>\n";
5750         }
5751         print "</table>\n";
5752 }
5753
5754 # Display a single remote block
5755 sub git_remote_block {
5756         my ($remote, $rdata, $limit, $head) = @_;
5757
5758         my $heads = $rdata->{'heads'};
5759         my $fetch = $rdata->{'fetch'};
5760         my $push = $rdata->{'push'};
5761
5762         my $urls_table = "<table class=\"projects_list\">\n" ;
5763
5764         if (defined $fetch) {
5765                 if ($fetch eq $push) {
5766                         $urls_table .= format_repo_url("URL", $fetch);
5767                 } else {
5768                         $urls_table .= format_repo_url("Fetch URL", $fetch);
5769                         $urls_table .= format_repo_url("Push URL", $push) if defined $push;
5770                 }
5771         } elsif (defined $push) {
5772                 $urls_table .= format_repo_url("Push URL", $push);
5773         } else {
5774                 $urls_table .= format_repo_url("", "No remote URL");
5775         }
5776
5777         $urls_table .= "</table>\n";
5778
5779         my $dots;
5780         if (defined $limit && $limit < @$heads) {
5781                 $dots = $cgi->a({-href => href(action=>"remotes", hash=>$remote)}, "...");
5782         }
5783
5784         print $urls_table;
5785         git_heads_body($heads, $head, 0, $limit, $dots);
5786 }
5787
5788 # Display a list of remote names with the respective fetch and push URLs
5789 sub git_remotes_list {
5790         my ($remotedata, $limit) = @_;
5791         print "<table class=\"heads\">\n";
5792         my $alternate = 1;
5793         my @remotes = sort keys %$remotedata;
5794
5795         my $limited = $limit && $limit < @remotes;
5796
5797         $#remotes = $limit - 1 if $limited;
5798
5799         while (my $remote = shift @remotes) {
5800                 my $rdata = $remotedata->{$remote};
5801                 my $fetch = $rdata->{'fetch'};
5802                 my $push = $rdata->{'push'};
5803                 if ($alternate) {
5804                         print "<tr class=\"dark\">\n";
5805                 } else {
5806                         print "<tr class=\"light\">\n";
5807                 }
5808                 $alternate ^= 1;
5809                 print "<td>" .
5810                       $cgi->a({-href=> href(action=>'remotes', hash=>$remote),
5811                                -class=> "list name"},esc_html($remote)) .
5812                       "</td>";
5813                 print "<td class=\"link\">" .
5814                       (defined $fetch ? $cgi->a({-href=> $fetch}, "fetch") : "fetch") .
5815                       " | " .
5816                       (defined $push ? $cgi->a({-href=> $push}, "push") : "push") .
5817                       "</td>";
5818
5819                 print "</tr>\n";
5820         }
5821
5822         if ($limited) {
5823                 print "<tr>\n" .
5824                       "<td colspan=\"3\">" .
5825                       $cgi->a({-href => href(action=>"remotes")}, "...") .
5826                       "</td>\n" . "</tr>\n";
5827         }
5828
5829         print "</table>";
5830 }
5831
5832 # Display remote heads grouped by remote, unless there are too many
5833 # remotes, in which case we only display the remote names
5834 sub git_remotes_body {
5835         my ($remotedata, $limit, $head) = @_;
5836         if ($limit and $limit < keys %$remotedata) {
5837                 git_remotes_list($remotedata, $limit);
5838         } else {
5839                 fill_remote_heads($remotedata);
5840                 while (my ($remote, $rdata) = each %$remotedata) {
5841                         git_print_section({-class=>"remote", -id=>$remote},
5842                                 ["remotes", $remote, $remote], sub {
5843                                         git_remote_block($remote, $rdata, $limit, $head);
5844                                 });
5845                 }
5846         }
5847 }
5848
5849 sub git_search_message {
5850         my %co = @_;
5851
5852         my $greptype;
5853         if ($searchtype eq 'commit') {
5854                 $greptype = "--grep=";
5855         } elsif ($searchtype eq 'author') {
5856                 $greptype = "--author=";
5857         } elsif ($searchtype eq 'committer') {
5858                 $greptype = "--committer=";
5859         }
5860         $greptype .= $searchtext;
5861         my @commitlist = parse_commits($hash, 101, (100 * $page), undef,
5862                                        $greptype, '--regexp-ignore-case',
5863                                        $search_use_regexp ? '--extended-regexp' : '--fixed-strings');
5864
5865         my $paging_nav = '';
5866         if ($page > 0) {
5867                 $paging_nav .=
5868                         $cgi->a({-href => href(-replay=>1, page=>undef)},
5869                                 "first") .
5870                         " &sdot; " .
5871                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
5872                                  -accesskey => "p", -title => "Alt-p"}, "prev");
5873         } else {
5874                 $paging_nav .= "first &sdot; prev";
5875         }
5876         my $next_link = '';
5877         if ($#commitlist >= 100) {
5878                 $next_link =
5879                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
5880                                  -accesskey => "n", -title => "Alt-n"}, "next");
5881                 $paging_nav .= " &sdot; $next_link";
5882         } else {
5883                 $paging_nav .= " &sdot; next";
5884         }
5885
5886         git_header_html();
5887
5888         git_print_page_nav('','', $hash,$co{'tree'},$hash, $paging_nav);
5889         git_print_header_div('commit', esc_html($co{'title'}), $hash);
5890         if ($page == 0 && !@commitlist) {
5891                 print "<p>No match.</p>\n";
5892         } else {
5893                 git_search_grep_body(\@commitlist, 0, 99, $next_link);
5894         }
5895
5896         git_footer_html();
5897 }
5898
5899 sub git_search_changes {
5900         my %co = @_;
5901
5902         local $/ = "\n";
5903         open my $fd, '-|', git_cmd(), '--no-pager', 'log', @diff_opts,
5904                 '--pretty=format:%H', '--no-abbrev', '--raw', "-S$searchtext",
5905                 ($search_use_regexp ? '--pickaxe-regex' : ())
5906                         or die_error(500, "Open git-log failed");
5907
5908         git_header_html();
5909
5910         git_print_page_nav('','', $hash,$co{'tree'},$hash);
5911         git_print_header_div('commit', esc_html($co{'title'}), $hash);
5912
5913         print "<table class=\"pickaxe search\">\n";
5914         my $alternate = 1;
5915         undef %co;
5916         my @files;
5917         while (my $line = <$fd>) {
5918                 chomp $line;
5919                 next unless $line;
5920
5921                 my %set = parse_difftree_raw_line($line);
5922                 if (defined $set{'commit'}) {
5923                         # finish previous commit
5924                         if (%co) {
5925                                 print "</td>\n" .
5926                                       "<td class=\"link\">" .
5927                                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
5928                                               "commit") .
5929                                       " | " .
5930                                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
5931                                                              hash_base=>$co{'id'})},
5932                                               "tree") .
5933                                       "</td>\n" .
5934                                       "</tr>\n";
5935                         }
5936
5937                         if ($alternate) {
5938                                 print "<tr class=\"dark\">\n";
5939                         } else {
5940                                 print "<tr class=\"light\">\n";
5941                         }
5942                         $alternate ^= 1;
5943                         %co = parse_commit($set{'commit'});
5944                         my $author = chop_and_escape_str($co{'author_name'}, 15, 5);
5945                         print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5946                               "<td><i>$author</i></td>\n" .
5947                               "<td>" .
5948                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
5949                                       -class => "list subject"},
5950                                       chop_and_escape_str($co{'title'}, 50) . "<br/>");
5951                 } elsif (defined $set{'to_id'}) {
5952                         next if ($set{'to_id'} =~ m/^0{40}$/);
5953
5954                         print $cgi->a({-href => href(action=>"blob", hash_base=>$co{'id'},
5955                                                      hash=>$set{'to_id'}, file_name=>$set{'to_file'}),
5956                                       -class => "list"},
5957                                       "<span class=\"match\">" . esc_path($set{'file'}) . "</span>") .
5958                               "<br/>\n";
5959                 }
5960         }
5961         close $fd;
5962
5963         # finish last commit (warning: repetition!)
5964         if (%co) {
5965                 print "</td>\n" .
5966                       "<td class=\"link\">" .
5967                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
5968                               "commit") .
5969                       " | " .
5970                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
5971                                              hash_base=>$co{'id'})},
5972                               "tree") .
5973                       "</td>\n" .
5974                       "</tr>\n";
5975         }
5976
5977         print "</table>\n";
5978
5979         git_footer_html();
5980 }
5981
5982 sub git_search_files {
5983         my %co = @_;
5984
5985         local $/ = "\n";
5986         open my $fd, "-|", git_cmd(), 'grep', '-n', '-z',
5987                 $search_use_regexp ? ('-E', '-i') : '-F',
5988                 $searchtext, $co{'tree'}
5989                         or die_error(500, "Open git-grep failed");
5990
5991         git_header_html();
5992
5993         git_print_page_nav('','', $hash,$co{'tree'},$hash);
5994         git_print_header_div('commit', esc_html($co{'title'}), $hash);
5995
5996         print "<table class=\"grep_search\">\n";
5997         my $alternate = 1;
5998         my $matches = 0;
5999         my $lastfile = '';
6000         my $file_href;
6001         while (my $line = <$fd>) {
6002                 chomp $line;
6003                 my ($file, $lno, $ltext, $binary);
6004                 last if ($matches++ > 1000);
6005                 if ($line =~ /^Binary file (.+) matches$/) {
6006                         $file = $1;
6007                         $binary = 1;
6008                 } else {
6009                         ($file, $lno, $ltext) = split(/\0/, $line, 3);
6010                         $file =~ s/^$co{'tree'}://;
6011                 }
6012                 if ($file ne $lastfile) {
6013                         $lastfile and print "</td></tr>\n";
6014                         if ($alternate++) {
6015                                 print "<tr class=\"dark\">\n";
6016                         } else {
6017                                 print "<tr class=\"light\">\n";
6018                         }
6019                         $file_href = href(action=>"blob", hash_base=>$co{'id'},
6020                                           file_name=>$file);
6021                         print "<td class=\"list\">".
6022                                 $cgi->a({-href => $file_href, -class => "list"}, esc_path($file));
6023                         print "</td><td>\n";
6024                         $lastfile = $file;
6025                 }
6026                 if ($binary) {
6027                         print "<div class=\"binary\">Binary file</div>\n";
6028                 } else {
6029                         $ltext = untabify($ltext);
6030                         if ($ltext =~ m/^(.*)($search_regexp)(.*)$/i) {
6031                                 $ltext = esc_html($1, -nbsp=>1);
6032                                 $ltext .= '<span class="match">';
6033                                 $ltext .= esc_html($2, -nbsp=>1);
6034                                 $ltext .= '</span>';
6035                                 $ltext .= esc_html($3, -nbsp=>1);
6036                         } else {
6037                                 $ltext = esc_html($ltext, -nbsp=>1);
6038                         }
6039                         print "<div class=\"pre\">" .
6040                                 $cgi->a({-href => $file_href.'#l'.$lno,
6041                                         -class => "linenr"}, sprintf('%4i', $lno)) .
6042                                 ' ' .  $ltext . "</div>\n";
6043                 }
6044         }
6045         if ($lastfile) {
6046                 print "</td></tr>\n";
6047                 if ($matches > 1000) {
6048                         print "<div class=\"diff nodifferences\">Too many matches, listing trimmed</div>\n";
6049                 }
6050         } else {
6051                 print "<div class=\"diff nodifferences\">No matches found</div>\n";
6052         }
6053         close $fd;
6054
6055         print "</table>\n";
6056
6057         git_footer_html();
6058 }
6059
6060 sub git_search_grep_body {
6061         my ($commitlist, $from, $to, $extra) = @_;
6062         $from = 0 unless defined $from;
6063         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
6064
6065         print "<table class=\"commit_search\">\n";
6066         my $alternate = 1;
6067         for (my $i = $from; $i <= $to; $i++) {
6068                 my %co = %{$commitlist->[$i]};
6069                 if (!%co) {
6070                         next;
6071                 }
6072                 my $commit = $co{'id'};
6073                 if ($alternate) {
6074                         print "<tr class=\"dark\">\n";
6075                 } else {
6076                         print "<tr class=\"light\">\n";
6077                 }
6078                 $alternate ^= 1;
6079                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6080                       format_author_html('td', \%co, 15, 5) .
6081                       "<td>" .
6082                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
6083                                -class => "list subject"},
6084                               chop_and_escape_str($co{'title'}, 50) . "<br/>");
6085                 my $comment = $co{'comment'};
6086                 foreach my $line (@$comment) {
6087                         if ($line =~ m/^(.*?)($search_regexp)(.*)$/i) {
6088                                 my ($lead, $match, $trail) = ($1, $2, $3);
6089                                 $match = chop_str($match, 70, 5, 'center');
6090                                 my $contextlen = int((80 - length($match))/2);
6091                                 $contextlen = 30 if ($contextlen > 30);
6092                                 $lead  = chop_str($lead,  $contextlen, 10, 'left');
6093                                 $trail = chop_str($trail, $contextlen, 10, 'right');
6094
6095                                 $lead  = esc_html($lead);
6096                                 $match = esc_html($match);
6097                                 $trail = esc_html($trail);
6098
6099                                 print "$lead<span class=\"match\">$match</span>$trail<br />";
6100                         }
6101                 }
6102                 print "</td>\n" .
6103                       "<td class=\"link\">" .
6104                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
6105                       " | " .
6106                       $cgi->a({-href => href(action=>"commitdiff", hash=>$co{'id'})}, "commitdiff") .
6107                       " | " .
6108                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
6109                 print "</td>\n" .
6110                       "</tr>\n";
6111         }
6112         if (defined $extra) {
6113                 print "<tr>\n" .
6114                       "<td colspan=\"3\">$extra</td>\n" .
6115                       "</tr>\n";
6116         }
6117         print "</table>\n";
6118 }
6119
6120 ## ======================================================================
6121 ## ======================================================================
6122 ## actions
6123
6124 sub git_project_list {
6125         my $order = $input_params{'order'};
6126         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
6127                 die_error(400, "Unknown order parameter");
6128         }
6129
6130         my @list = git_get_projects_list($project_filter, $strict_export);
6131         if (!@list) {
6132                 die_error(404, "No projects found");
6133         }
6134
6135         git_header_html();
6136         if (defined $home_text && -f $home_text) {
6137                 print "<div class=\"index_include\">\n";
6138                 insert_file($home_text);
6139                 print "</div>\n";
6140         }
6141
6142         git_project_search_form($searchtext, $search_use_regexp);
6143         git_project_list_body(\@list, $order);
6144         git_footer_html();
6145 }
6146
6147 sub git_forks {
6148         my $order = $input_params{'order'};
6149         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
6150                 die_error(400, "Unknown order parameter");
6151         }
6152
6153         my $filter = $project;
6154         $filter =~ s/\.git$//;
6155         my @list = git_get_projects_list($filter);
6156         if (!@list) {
6157                 die_error(404, "No forks found");
6158         }
6159
6160         git_header_html();
6161         git_print_page_nav('','');
6162         git_print_header_div('summary', "$project forks");
6163         git_project_list_body(\@list, $order);
6164         git_footer_html();
6165 }
6166
6167 sub git_project_index {
6168         my @projects = git_get_projects_list($project_filter, $strict_export);
6169         if (!@projects) {
6170                 die_error(404, "No projects found");
6171         }
6172
6173         print $cgi->header(
6174                 -type => 'text/plain',
6175                 -charset => 'utf-8',
6176                 -content_disposition => 'inline; filename="index.aux"');
6177
6178         foreach my $pr (@projects) {
6179                 if (!exists $pr->{'owner'}) {
6180                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}");
6181                 }
6182
6183                 my ($path, $owner) = ($pr->{'path'}, $pr->{'owner'});
6184                 # quote as in CGI::Util::encode, but keep the slash, and use '+' for ' '
6185                 $path  =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
6186                 $owner =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
6187                 $path  =~ s/ /\+/g;
6188                 $owner =~ s/ /\+/g;
6189
6190                 print "$path $owner\n";
6191         }
6192 }
6193
6194 sub git_summary {
6195         my $descr = git_get_project_description($project) || "none";
6196         my %co = parse_commit("HEAD");
6197         my %cd = %co ? parse_date($co{'committer_epoch'}, $co{'committer_tz'}) : ();
6198         my $head = $co{'id'};
6199         my $remote_heads = gitweb_check_feature('remote_heads');
6200
6201         my $owner = git_get_project_owner($project);
6202
6203         my $refs = git_get_references();
6204         # These get_*_list functions return one more to allow us to see if
6205         # there are more ...
6206         my @taglist  = git_get_tags_list(16);
6207         my @headlist = git_get_heads_list(16);
6208         my %remotedata = $remote_heads ? git_get_remotes_list() : ();
6209         my @forklist;
6210         my $check_forks = gitweb_check_feature('forks');
6211
6212         if ($check_forks) {
6213                 # find forks of a project
6214                 my $filter = $project;
6215                 $filter =~ s/\.git$//;
6216                 @forklist = git_get_projects_list($filter);
6217                 # filter out forks of forks
6218                 @forklist = filter_forks_from_projects_list(\@forklist)
6219                         if (@forklist);
6220         }
6221
6222         git_header_html();
6223         git_print_page_nav('summary','', $head);
6224
6225         print "<div class=\"title\">&nbsp;</div>\n";
6226         print "<table class=\"projects_list\">\n" .
6227               "<tr id=\"metadata_desc\"><td>description</td><td>" . esc_html($descr) . "</td></tr>\n" .
6228               "<tr id=\"metadata_owner\"><td>owner</td><td>" . esc_html($owner) . "</td></tr>\n";
6229         if (defined $cd{'rfc2822'}) {
6230                 print "<tr id=\"metadata_lchange\"><td>last change</td>" .
6231                       "<td>".format_timestamp_html(\%cd)."</td></tr>\n";
6232         }
6233
6234         # use per project git URL list in $projectroot/$project/cloneurl
6235         # or make project git URL from git base URL and project name
6236         my $url_tag = "URL";
6237         my @url_list = git_get_project_url_list($project);
6238         @url_list = map { "$_/$project" } @git_base_url_list unless @url_list;
6239         foreach my $git_url (@url_list) {
6240                 next unless $git_url;
6241                 print format_repo_url($url_tag, $git_url);
6242                 $url_tag = "";
6243         }
6244
6245         # Tag cloud
6246         my $show_ctags = gitweb_check_feature('ctags');
6247         if ($show_ctags) {
6248                 my $ctags = git_get_project_ctags($project);
6249                 if (%$ctags) {
6250                         # without ability to add tags, don't show if there are none
6251                         my $cloud = git_populate_project_tagcloud($ctags);
6252                         print "<tr id=\"metadata_ctags\">" .
6253                               "<td>content tags</td>" .
6254                               "<td>".git_show_project_tagcloud($cloud, 48)."</td>" .
6255                               "</tr>\n";
6256                 }
6257         }
6258
6259         print "</table>\n";
6260
6261         # If XSS prevention is on, we don't include README.html.
6262         # TODO: Allow a readme in some safe format.
6263         if (!$prevent_xss && -s "$projectroot/$project/README.html") {
6264                 print "<div class=\"title\">readme</div>\n" .
6265                       "<div class=\"readme\">\n";
6266                 insert_file("$projectroot/$project/README.html");
6267                 print "\n</div>\n"; # class="readme"
6268         }
6269
6270         # we need to request one more than 16 (0..15) to check if
6271         # those 16 are all
6272         my @commitlist = $head ? parse_commits($head, 17) : ();
6273         if (@commitlist) {
6274                 git_print_header_div('shortlog');
6275                 git_shortlog_body(\@commitlist, 0, 15, $refs,
6276                                   $#commitlist <=  15 ? undef :
6277                                   $cgi->a({-href => href(action=>"shortlog")}, "..."));
6278         }
6279
6280         if (@taglist) {
6281                 git_print_header_div('tags');
6282                 git_tags_body(\@taglist, 0, 15,
6283                               $#taglist <=  15 ? undef :
6284                               $cgi->a({-href => href(action=>"tags")}, "..."));
6285         }
6286
6287         if (@headlist) {
6288                 git_print_header_div('heads');
6289                 git_heads_body(\@headlist, $head, 0, 15,
6290                                $#headlist <= 15 ? undef :
6291                                $cgi->a({-href => href(action=>"heads")}, "..."));
6292         }
6293
6294         if (%remotedata) {
6295                 git_print_header_div('remotes');
6296                 git_remotes_body(\%remotedata, 15, $head);
6297         }
6298
6299         if (@forklist) {
6300                 git_print_header_div('forks');
6301                 git_project_list_body(\@forklist, 'age', 0, 15,
6302                                       $#forklist <= 15 ? undef :
6303                                       $cgi->a({-href => href(action=>"forks")}, "..."),
6304                                       'no_header');
6305         }
6306
6307         git_footer_html();
6308 }
6309
6310 sub git_tag {
6311         my %tag = parse_tag($hash);
6312
6313         if (! %tag) {
6314                 die_error(404, "Unknown tag object");
6315         }
6316
6317         my $head = git_get_head_hash($project);
6318         git_header_html();
6319         git_print_page_nav('','', $head,undef,$head);
6320         git_print_header_div('commit', esc_html($tag{'name'}), $hash);
6321         print "<div class=\"title_text\">\n" .
6322               "<table class=\"object_header\">\n" .
6323               "<tr>\n" .
6324               "<td>object</td>\n" .
6325               "<td>" . $cgi->a({-class => "list", -href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6326                                $tag{'object'}) . "</td>\n" .
6327               "<td class=\"link\">" . $cgi->a({-href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6328                                               $tag{'type'}) . "</td>\n" .
6329               "</tr>\n";
6330         if (defined($tag{'author'})) {
6331                 git_print_authorship_rows(\%tag, 'author');
6332         }
6333         print "</table>\n\n" .
6334               "</div>\n";
6335         print "<div class=\"page_body\">";
6336         my $comment = $tag{'comment'};
6337         foreach my $line (@$comment) {
6338                 chomp $line;
6339                 print esc_html($line, -nbsp=>1) . "<br/>\n";
6340         }
6341         print "</div>\n";
6342         git_footer_html();
6343 }
6344
6345 sub git_blame_common {
6346         my $format = shift || 'porcelain';
6347         if ($format eq 'porcelain' && $input_params{'javascript'}) {
6348                 $format = 'incremental';
6349                 $action = 'blame_incremental'; # for page title etc
6350         }
6351
6352         # permissions
6353         gitweb_check_feature('blame')
6354                 or die_error(403, "Blame view not allowed");
6355
6356         # error checking
6357         die_error(400, "No file name given") unless $file_name;
6358         $hash_base ||= git_get_head_hash($project);
6359         die_error(404, "Couldn't find base commit") unless $hash_base;
6360         my %co = parse_commit($hash_base)
6361                 or die_error(404, "Commit not found");
6362         my $ftype = "blob";
6363         if (!defined $hash) {
6364                 $hash = git_get_hash_by_path($hash_base, $file_name, "blob")
6365                         or die_error(404, "Error looking up file");
6366         } else {
6367                 $ftype = git_get_type($hash);
6368                 if ($ftype !~ "blob") {
6369                         die_error(400, "Object is not a blob");
6370                 }
6371         }
6372
6373         my $fd;
6374         if ($format eq 'incremental') {
6375                 # get file contents (as base)
6376                 open $fd, "-|", git_cmd(), 'cat-file', 'blob', $hash
6377                         or die_error(500, "Open git-cat-file failed");
6378         } elsif ($format eq 'data') {
6379                 # run git-blame --incremental
6380                 open $fd, "-|", git_cmd(), "blame", "--incremental",
6381                         $hash_base, "--", $file_name
6382                         or die_error(500, "Open git-blame --incremental failed");
6383         } else {
6384                 # run git-blame --porcelain
6385                 open $fd, "-|", git_cmd(), "blame", '-p',
6386                         $hash_base, '--', $file_name
6387                         or die_error(500, "Open git-blame --porcelain failed");
6388         }
6389
6390         # incremental blame data returns early
6391         if ($format eq 'data') {
6392                 print $cgi->header(
6393                         -type=>"text/plain", -charset => "utf-8",
6394                         -status=> "200 OK");
6395                 local $| = 1; # output autoflush
6396                 while (my $line = <$fd>) {
6397                         print to_utf8($line);
6398                 }
6399                 close $fd
6400                         or print "ERROR $!\n";
6401
6402                 print 'END';
6403                 if (defined $t0 && gitweb_check_feature('timed')) {
6404                         print ' '.
6405                               tv_interval($t0, [ gettimeofday() ]).
6406                               ' '.$number_of_git_cmds;
6407                 }
6408                 print "\n";
6409
6410                 return;
6411         }
6412
6413         # page header
6414         git_header_html();
6415         my $formats_nav =
6416                 $cgi->a({-href => href(action=>"blob", -replay=>1)},
6417                         "blob") .
6418                 " | ";
6419         if ($format eq 'incremental') {
6420                 $formats_nav .=
6421                         $cgi->a({-href => href(action=>"blame", javascript=>0, -replay=>1)},
6422                                 "blame") . " (non-incremental)";
6423         } else {
6424                 $formats_nav .=
6425                         $cgi->a({-href => href(action=>"blame_incremental", -replay=>1)},
6426                                 "blame") . " (incremental)";
6427         }
6428         $formats_nav .=
6429                 " | " .
6430                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6431                         "history") .
6432                 " | " .
6433                 $cgi->a({-href => href(action=>$action, file_name=>$file_name)},
6434                         "HEAD");
6435         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6436         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6437         git_print_page_path($file_name, $ftype, $hash_base);
6438
6439         # page body
6440         if ($format eq 'incremental') {
6441                 print "<noscript>\n<div class=\"error\"><center><b>\n".
6442                       "This page requires JavaScript to run.\n Use ".
6443                       $cgi->a({-href => href(action=>'blame',javascript=>0,-replay=>1)},
6444                               'this page').
6445                       " instead.\n".
6446                       "</b></center></div>\n</noscript>\n";
6447
6448                 print qq!<div id="progress_bar" style="width: 100%; background-color: yellow"></div>\n!;
6449         }
6450
6451         print qq!<div class="page_body">\n!;
6452         print qq!<div id="progress_info">... / ...</div>\n!
6453                 if ($format eq 'incremental');
6454         print qq!<table id="blame_table" class="blame" width="100%">\n!.
6455               #qq!<col width="5.5em" /><col width="2.5em" /><col width="*" />\n!.
6456               qq!<thead>\n!.
6457               qq!<tr><th>Commit</th><th>Line</th><th>Data</th></tr>\n!.
6458               qq!</thead>\n!.
6459               qq!<tbody>\n!;
6460
6461         my @rev_color = qw(light dark);
6462         my $num_colors = scalar(@rev_color);
6463         my $current_color = 0;
6464
6465         if ($format eq 'incremental') {
6466                 my $color_class = $rev_color[$current_color];
6467
6468                 #contents of a file
6469                 my $linenr = 0;
6470         LINE:
6471                 while (my $line = <$fd>) {
6472                         chomp $line;
6473                         $linenr++;
6474
6475                         print qq!<tr id="l$linenr" class="$color_class">!.
6476                               qq!<td class="sha1"><a href=""> </a></td>!.
6477                               qq!<td class="linenr">!.
6478                               qq!<a class="linenr" href="">$linenr</a></td>!;
6479                         print qq!<td class="pre">! . esc_html($line) . "</td>\n";
6480                         print qq!</tr>\n!;
6481                 }
6482
6483         } else { # porcelain, i.e. ordinary blame
6484                 my %metainfo = (); # saves information about commits
6485
6486                 # blame data
6487         LINE:
6488                 while (my $line = <$fd>) {
6489                         chomp $line;
6490                         # the header: <SHA-1> <src lineno> <dst lineno> [<lines in group>]
6491                         # no <lines in group> for subsequent lines in group of lines
6492                         my ($full_rev, $orig_lineno, $lineno, $group_size) =
6493                            ($line =~ /^([0-9a-f]{40}) (\d+) (\d+)(?: (\d+))?$/);
6494                         if (!exists $metainfo{$full_rev}) {
6495                                 $metainfo{$full_rev} = { 'nprevious' => 0 };
6496                         }
6497                         my $meta = $metainfo{$full_rev};
6498                         my $data;
6499                         while ($data = <$fd>) {
6500                                 chomp $data;
6501                                 last if ($data =~ s/^\t//); # contents of line
6502                                 if ($data =~ /^(\S+)(?: (.*))?$/) {
6503                                         $meta->{$1} = $2 unless exists $meta->{$1};
6504                                 }
6505                                 if ($data =~ /^previous /) {
6506                                         $meta->{'nprevious'}++;
6507                                 }
6508                         }
6509                         my $short_rev = substr($full_rev, 0, 8);
6510                         my $author = $meta->{'author'};
6511                         my %date =
6512                                 parse_date($meta->{'author-time'}, $meta->{'author-tz'});
6513                         my $date = $date{'iso-tz'};
6514                         if ($group_size) {
6515                                 $current_color = ($current_color + 1) % $num_colors;
6516                         }
6517                         my $tr_class = $rev_color[$current_color];
6518                         $tr_class .= ' boundary' if (exists $meta->{'boundary'});
6519                         $tr_class .= ' no-previous' if ($meta->{'nprevious'} == 0);
6520                         $tr_class .= ' multiple-previous' if ($meta->{'nprevious'} > 1);
6521                         print "<tr id=\"l$lineno\" class=\"$tr_class\">\n";
6522                         if ($group_size) {
6523                                 print "<td class=\"sha1\"";
6524                                 print " title=\"". esc_html($author) . ", $date\"";
6525                                 print " rowspan=\"$group_size\"" if ($group_size > 1);
6526                                 print ">";
6527                                 print $cgi->a({-href => href(action=>"commit",
6528                                                              hash=>$full_rev,
6529                                                              file_name=>$file_name)},
6530                                               esc_html($short_rev));
6531                                 if ($group_size >= 2) {
6532                                         my @author_initials = ($author =~ /\b([[:upper:]])\B/g);
6533                                         if (@author_initials) {
6534                                                 print "<br />" .
6535                                                       esc_html(join('', @author_initials));
6536                                                 #           or join('.', ...)
6537                                         }
6538                                 }
6539                                 print "</td>\n";
6540                         }
6541                         # 'previous' <sha1 of parent commit> <filename at commit>
6542                         if (exists $meta->{'previous'} &&
6543                             $meta->{'previous'} =~ /^([a-fA-F0-9]{40}) (.*)$/) {
6544                                 $meta->{'parent'} = $1;
6545                                 $meta->{'file_parent'} = unquote($2);
6546                         }
6547                         my $linenr_commit =
6548                                 exists($meta->{'parent'}) ?
6549                                 $meta->{'parent'} : $full_rev;
6550                         my $linenr_filename =
6551                                 exists($meta->{'file_parent'}) ?
6552                                 $meta->{'file_parent'} : unquote($meta->{'filename'});
6553                         my $blamed = href(action => 'blame',
6554                                           file_name => $linenr_filename,
6555                                           hash_base => $linenr_commit);
6556                         print "<td class=\"linenr\">";
6557                         print $cgi->a({ -href => "$blamed#l$orig_lineno",
6558                                         -class => "linenr" },
6559                                       esc_html($lineno));
6560                         print "</td>";
6561                         print "<td class=\"pre\">" . esc_html($data) . "</td>\n";
6562                         print "</tr>\n";
6563                 } # end while
6564
6565         }
6566
6567         # footer
6568         print "</tbody>\n".
6569               "</table>\n"; # class="blame"
6570         print "</div>\n";   # class="blame_body"
6571         close $fd
6572                 or print "Reading blob failed\n";
6573
6574         git_footer_html();
6575 }
6576
6577 sub git_blame {
6578         git_blame_common();
6579 }
6580
6581 sub git_blame_incremental {
6582         git_blame_common('incremental');
6583 }
6584
6585 sub git_blame_data {
6586         git_blame_common('data');
6587 }
6588
6589 sub git_tags {
6590         my $head = git_get_head_hash($project);
6591         git_header_html();
6592         git_print_page_nav('','', $head,undef,$head,format_ref_views('tags'));
6593         git_print_header_div('summary', $project);
6594
6595         my @tagslist = git_get_tags_list();
6596         if (@tagslist) {
6597                 git_tags_body(\@tagslist);
6598         }
6599         git_footer_html();
6600 }
6601
6602 sub git_heads {
6603         my $head = git_get_head_hash($project);
6604         git_header_html();
6605         git_print_page_nav('','', $head,undef,$head,format_ref_views('heads'));
6606         git_print_header_div('summary', $project);
6607
6608         my @headslist = git_get_heads_list();
6609         if (@headslist) {
6610                 git_heads_body(\@headslist, $head);
6611         }
6612         git_footer_html();
6613 }
6614
6615 # used both for single remote view and for list of all the remotes
6616 sub git_remotes {
6617         gitweb_check_feature('remote_heads')
6618                 or die_error(403, "Remote heads view is disabled");
6619
6620         my $head = git_get_head_hash($project);
6621         my $remote = $input_params{'hash'};
6622
6623         my $remotedata = git_get_remotes_list($remote);
6624         die_error(500, "Unable to get remote information") unless defined $remotedata;
6625
6626         unless (%$remotedata) {
6627                 die_error(404, defined $remote ?
6628                         "Remote $remote not found" :
6629                         "No remotes found");
6630         }
6631
6632         git_header_html(undef, undef, -action_extra => $remote);
6633         git_print_page_nav('', '',  $head, undef, $head,
6634                 format_ref_views($remote ? '' : 'remotes'));
6635
6636         fill_remote_heads($remotedata);
6637         if (defined $remote) {
6638                 git_print_header_div('remotes', "$remote remote for $project");
6639                 git_remote_block($remote, $remotedata->{$remote}, undef, $head);
6640         } else {
6641                 git_print_header_div('summary', "$project remotes");
6642                 git_remotes_body($remotedata, undef, $head);
6643         }
6644
6645         git_footer_html();
6646 }
6647
6648 sub git_blob_plain {
6649         my $type = shift;
6650         my $expires;
6651
6652         if (!defined $hash) {
6653                 if (defined $file_name) {
6654                         my $base = $hash_base || git_get_head_hash($project);
6655                         $hash = git_get_hash_by_path($base, $file_name, "blob")
6656                                 or die_error(404, "Cannot find file");
6657                 } else {
6658                         die_error(400, "No file name defined");
6659                 }
6660         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6661                 # blobs defined by non-textual hash id's can be cached
6662                 $expires = "+1d";
6663         }
6664
6665         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
6666                 or die_error(500, "Open git-cat-file blob '$hash' failed");
6667
6668         # content-type (can include charset)
6669         $type = blob_contenttype($fd, $file_name, $type);
6670
6671         # "save as" filename, even when no $file_name is given
6672         my $save_as = "$hash";
6673         if (defined $file_name) {
6674                 $save_as = $file_name;
6675         } elsif ($type =~ m/^text\//) {
6676                 $save_as .= '.txt';
6677         }
6678
6679         # With XSS prevention on, blobs of all types except a few known safe
6680         # ones are served with "Content-Disposition: attachment" to make sure
6681         # they don't run in our security domain.  For certain image types,
6682         # blob view writes an <img> tag referring to blob_plain view, and we
6683         # want to be sure not to break that by serving the image as an
6684         # attachment (though Firefox 3 doesn't seem to care).
6685         my $sandbox = $prevent_xss &&
6686                 $type !~ m!^(?:text/[a-z]+|image/(?:gif|png|jpeg))(?:[ ;]|$)!;
6687
6688         # serve text/* as text/plain
6689         if ($prevent_xss &&
6690             ($type =~ m!^text/[a-z]+\b(.*)$! ||
6691              ($type =~ m!^[a-z]+/[a-z]\+xml\b(.*)$! && -T $fd))) {
6692                 my $rest = $1;
6693                 $rest = defined $rest ? $rest : '';
6694                 $type = "text/plain$rest";
6695         }
6696
6697         print $cgi->header(
6698                 -type => $type,
6699                 -expires => $expires,
6700                 -content_disposition =>
6701                         ($sandbox ? 'attachment' : 'inline')
6702                         . '; filename="' . $save_as . '"');
6703         local $/ = undef;
6704         binmode STDOUT, ':raw';
6705         print <$fd>;
6706         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
6707         close $fd;
6708 }
6709
6710 sub git_blob {
6711         my $expires;
6712
6713         if (!defined $hash) {
6714                 if (defined $file_name) {
6715                         my $base = $hash_base || git_get_head_hash($project);
6716                         $hash = git_get_hash_by_path($base, $file_name, "blob")
6717                                 or die_error(404, "Cannot find file");
6718                 } else {
6719                         die_error(400, "No file name defined");
6720                 }
6721         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6722                 # blobs defined by non-textual hash id's can be cached
6723                 $expires = "+1d";
6724         }
6725
6726         my $have_blame = gitweb_check_feature('blame');
6727         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
6728                 or die_error(500, "Couldn't cat $file_name, $hash");
6729         my $mimetype = blob_mimetype($fd, $file_name);
6730         # use 'blob_plain' (aka 'raw') view for files that cannot be displayed
6731         if ($mimetype !~ m!^(?:text/|image/(?:gif|png|jpeg)$)! && -B $fd) {
6732                 close $fd;
6733                 return git_blob_plain($mimetype);
6734         }
6735         # we can have blame only for text/* mimetype
6736         $have_blame &&= ($mimetype =~ m!^text/!);
6737
6738         my $highlight = gitweb_check_feature('highlight');
6739         my $syntax = guess_file_syntax($highlight, $mimetype, $file_name);
6740         $fd = run_highlighter($fd, $highlight, $syntax)
6741                 if $syntax;
6742
6743         git_header_html(undef, $expires);
6744         my $formats_nav = '';
6745         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
6746                 if (defined $file_name) {
6747                         if ($have_blame) {
6748                                 $formats_nav .=
6749                                         $cgi->a({-href => href(action=>"blame", -replay=>1)},
6750                                                 "blame") .
6751                                         " | ";
6752                         }
6753                         $formats_nav .=
6754                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6755                                         "history") .
6756                                 " | " .
6757                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
6758                                         "raw") .
6759                                 " | " .
6760                                 $cgi->a({-href => href(action=>"blob",
6761                                                        hash_base=>"HEAD", file_name=>$file_name)},
6762                                         "HEAD");
6763                 } else {
6764                         $formats_nav .=
6765                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
6766                                         "raw");
6767                 }
6768                 git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6769                 git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6770         } else {
6771                 print "<div class=\"page_nav\">\n" .
6772                       "<br/><br/></div>\n" .
6773                       "<div class=\"title\">".esc_html($hash)."</div>\n";
6774         }
6775         git_print_page_path($file_name, "blob", $hash_base);
6776         print "<div class=\"page_body\">\n";
6777         if ($mimetype =~ m!^image/!) {
6778                 print qq!<img type="!.esc_attr($mimetype).qq!"!;
6779                 if ($file_name) {
6780                         print qq! alt="!.esc_attr($file_name).qq!" title="!.esc_attr($file_name).qq!"!;
6781                 }
6782                 print qq! src="! .
6783                       href(action=>"blob_plain", hash=>$hash,
6784                            hash_base=>$hash_base, file_name=>$file_name) .
6785                       qq!" />\n!;
6786         } else {
6787                 my $nr;
6788                 while (my $line = <$fd>) {
6789                         chomp $line;
6790                         $nr++;
6791                         $line = untabify($line);
6792                         printf qq!<div class="pre"><a id="l%i" href="%s#l%i" class="linenr">%4i</a> %s</div>\n!,
6793                                $nr, esc_attr(href(-replay => 1)), $nr, $nr,
6794                                $syntax ? sanitize($line) : esc_html($line, -nbsp=>1);
6795                 }
6796         }
6797         close $fd
6798                 or print "Reading blob failed.\n";
6799         print "</div>";
6800         git_footer_html();
6801 }
6802
6803 sub git_tree {
6804         if (!defined $hash_base) {
6805                 $hash_base = "HEAD";
6806         }
6807         if (!defined $hash) {
6808                 if (defined $file_name) {
6809                         $hash = git_get_hash_by_path($hash_base, $file_name, "tree");
6810                 } else {
6811                         $hash = $hash_base;
6812                 }
6813         }
6814         die_error(404, "No such tree") unless defined($hash);
6815
6816         my $show_sizes = gitweb_check_feature('show-sizes');
6817         my $have_blame = gitweb_check_feature('blame');
6818
6819         my @entries = ();
6820         {
6821                 local $/ = "\0";
6822                 open my $fd, "-|", git_cmd(), "ls-tree", '-z',
6823                         ($show_sizes ? '-l' : ()), @extra_options, $hash
6824                         or die_error(500, "Open git-ls-tree failed");
6825                 @entries = map { chomp; $_ } <$fd>;
6826                 close $fd
6827                         or die_error(404, "Reading tree failed");
6828         }
6829
6830         my $refs = git_get_references();
6831         my $ref = format_ref_marker($refs, $hash_base);
6832         git_header_html();
6833         my $basedir = '';
6834         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
6835                 my @views_nav = ();
6836                 if (defined $file_name) {
6837                         push @views_nav,
6838                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6839                                         "history"),
6840                                 $cgi->a({-href => href(action=>"tree",
6841                                                        hash_base=>"HEAD", file_name=>$file_name)},
6842                                         "HEAD"),
6843                 }
6844                 my $snapshot_links = format_snapshot_links($hash);
6845                 if (defined $snapshot_links) {
6846                         # FIXME: Should be available when we have no hash base as well.
6847                         push @views_nav, $snapshot_links;
6848                 }
6849                 git_print_page_nav('tree','', $hash_base, undef, undef,
6850                                    join(' | ', @views_nav));
6851                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash_base);
6852         } else {
6853                 undef $hash_base;
6854                 print "<div class=\"page_nav\">\n";
6855                 print "<br/><br/></div>\n";
6856                 print "<div class=\"title\">".esc_html($hash)."</div>\n";
6857         }
6858         if (defined $file_name) {
6859                 $basedir = $file_name;
6860                 if ($basedir ne '' && substr($basedir, -1) ne '/') {
6861                         $basedir .= '/';
6862                 }
6863                 git_print_page_path($file_name, 'tree', $hash_base);
6864         }
6865         print "<div class=\"page_body\">\n";
6866         print "<table class=\"tree\">\n";
6867         my $alternate = 1;
6868         # '..' (top directory) link if possible
6869         if (defined $hash_base &&
6870             defined $file_name && $file_name =~ m![^/]+$!) {
6871                 if ($alternate) {
6872                         print "<tr class=\"dark\">\n";
6873                 } else {
6874                         print "<tr class=\"light\">\n";
6875                 }
6876                 $alternate ^= 1;
6877
6878                 my $up = $file_name;
6879                 $up =~ s!/?[^/]+$!!;
6880                 undef $up unless $up;
6881                 # based on git_print_tree_entry
6882                 print '<td class="mode">' . mode_str('040000') . "</td>\n";
6883                 print '<td class="size">&nbsp;</td>'."\n" if $show_sizes;
6884                 print '<td class="list">';
6885                 print $cgi->a({-href => href(action=>"tree",
6886                                              hash_base=>$hash_base,
6887                                              file_name=>$up)},
6888                               "..");
6889                 print "</td>\n";
6890                 print "<td class=\"link\"></td>\n";
6891
6892                 print "</tr>\n";
6893         }
6894         foreach my $line (@entries) {
6895                 my %t = parse_ls_tree_line($line, -z => 1, -l => $show_sizes);
6896
6897                 if ($alternate) {
6898                         print "<tr class=\"dark\">\n";
6899                 } else {
6900                         print "<tr class=\"light\">\n";
6901                 }
6902                 $alternate ^= 1;
6903
6904                 git_print_tree_entry(\%t, $basedir, $hash_base, $have_blame);
6905
6906                 print "</tr>\n";
6907         }
6908         print "</table>\n" .
6909               "</div>";
6910         git_footer_html();
6911 }
6912
6913 sub snapshot_name {
6914         my ($project, $hash) = @_;
6915
6916         # path/to/project.git  -> project
6917         # path/to/project/.git -> project
6918         my $name = to_utf8($project);
6919         $name =~ s,([^/])/*\.git$,$1,;
6920         $name = basename($name);
6921         # sanitize name
6922         $name =~ s/[[:cntrl:]]/?/g;
6923
6924         my $ver = $hash;
6925         if ($hash =~ /^[0-9a-fA-F]+$/) {
6926                 # shorten SHA-1 hash
6927                 my $full_hash = git_get_full_hash($project, $hash);
6928                 if ($full_hash =~ /^$hash/ && length($hash) > 7) {
6929                         $ver = git_get_short_hash($project, $hash);
6930                 }
6931         } elsif ($hash =~ m!^refs/tags/(.*)$!) {
6932                 # tags don't need shortened SHA-1 hash
6933                 $ver = $1;
6934         } else {
6935                 # branches and other need shortened SHA-1 hash
6936                 if ($hash =~ m!^refs/(?:heads|remotes)/(.*)$!) {
6937                         $ver = $1;
6938                 }
6939                 $ver .= '-' . git_get_short_hash($project, $hash);
6940         }
6941         # in case of hierarchical branch names
6942         $ver =~ s!/!.!g;
6943
6944         # name = project-version_string
6945         $name = "$name-$ver";
6946
6947         return wantarray ? ($name, $name) : $name;
6948 }
6949
6950 sub git_snapshot {
6951         my $format = $input_params{'snapshot_format'};
6952         if (!@snapshot_fmts) {
6953                 die_error(403, "Snapshots not allowed");
6954         }
6955         # default to first supported snapshot format
6956         $format ||= $snapshot_fmts[0];
6957         if ($format !~ m/^[a-z0-9]+$/) {
6958                 die_error(400, "Invalid snapshot format parameter");
6959         } elsif (!exists($known_snapshot_formats{$format})) {
6960                 die_error(400, "Unknown snapshot format");
6961         } elsif ($known_snapshot_formats{$format}{'disabled'}) {
6962                 die_error(403, "Snapshot format not allowed");
6963         } elsif (!grep($_ eq $format, @snapshot_fmts)) {
6964                 die_error(403, "Unsupported snapshot format");
6965         }
6966
6967         my $type = git_get_type("$hash^{}");
6968         if (!$type) {
6969                 die_error(404, 'Object does not exist');
6970         }  elsif ($type eq 'blob') {
6971                 die_error(400, 'Object is not a tree-ish');
6972         }
6973
6974         my ($name, $prefix) = snapshot_name($project, $hash);
6975         my $filename = "$name$known_snapshot_formats{$format}{'suffix'}";
6976         my $cmd = quote_command(
6977                 git_cmd(), 'archive',
6978                 "--format=$known_snapshot_formats{$format}{'format'}",
6979                 "--prefix=$prefix/", $hash);
6980         if (exists $known_snapshot_formats{$format}{'compressor'}) {
6981                 $cmd .= ' | ' . quote_command(@{$known_snapshot_formats{$format}{'compressor'}});
6982         }
6983
6984         $filename =~ s/(["\\])/\\$1/g;
6985         print $cgi->header(
6986                 -type => $known_snapshot_formats{$format}{'type'},
6987                 -content_disposition => 'inline; filename="' . $filename . '"',
6988                 -status => '200 OK');
6989
6990         open my $fd, "-|", $cmd
6991                 or die_error(500, "Execute git-archive failed");
6992         binmode STDOUT, ':raw';
6993         print <$fd>;
6994         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
6995         close $fd;
6996 }
6997
6998 sub git_log_generic {
6999         my ($fmt_name, $body_subr, $base, $parent, $file_name, $file_hash) = @_;
7000
7001         my $head = git_get_head_hash($project);
7002         if (!defined $base) {
7003                 $base = $head;
7004         }
7005         if (!defined $page) {
7006                 $page = 0;
7007         }
7008         my $refs = git_get_references();
7009
7010         my $commit_hash = $base;
7011         if (defined $parent) {
7012                 $commit_hash = "$parent..$base";
7013         }
7014         my @commitlist =
7015                 parse_commits($commit_hash, 101, (100 * $page),
7016                               defined $file_name ? ($file_name, "--full-history") : ());
7017
7018         my $ftype;
7019         if (!defined $file_hash && defined $file_name) {
7020                 # some commits could have deleted file in question,
7021                 # and not have it in tree, but one of them has to have it
7022                 for (my $i = 0; $i < @commitlist; $i++) {
7023                         $file_hash = git_get_hash_by_path($commitlist[$i]{'id'}, $file_name);
7024                         last if defined $file_hash;
7025                 }
7026         }
7027         if (defined $file_hash) {
7028                 $ftype = git_get_type($file_hash);
7029         }
7030         if (defined $file_name && !defined $ftype) {
7031                 die_error(500, "Unknown type of object");
7032         }
7033         my %co;
7034         if (defined $file_name) {
7035                 %co = parse_commit($base)
7036                         or die_error(404, "Unknown commit object");
7037         }
7038
7039
7040         my $paging_nav = format_paging_nav($fmt_name, $page, $#commitlist >= 100);
7041         my $next_link = '';
7042         if ($#commitlist >= 100) {
7043                 $next_link =
7044                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
7045                                  -accesskey => "n", -title => "Alt-n"}, "next");
7046         }
7047         my $patch_max = gitweb_get_feature('patches');
7048         if ($patch_max && !defined $file_name) {
7049                 if ($patch_max < 0 || @commitlist <= $patch_max) {
7050                         $paging_nav .= " &sdot; " .
7051                                 $cgi->a({-href => href(action=>"patches", -replay=>1)},
7052                                         "patches");
7053                 }
7054         }
7055
7056         git_header_html();
7057         git_print_page_nav($fmt_name,'', $hash,$hash,$hash, $paging_nav);
7058         if (defined $file_name) {
7059                 git_print_header_div('commit', esc_html($co{'title'}), $base);
7060         } else {
7061                 git_print_header_div('summary', $project)
7062         }
7063         git_print_page_path($file_name, $ftype, $hash_base)
7064                 if (defined $file_name);
7065
7066         $body_subr->(\@commitlist, 0, 99, $refs, $next_link,
7067                      $file_name, $file_hash, $ftype);
7068
7069         git_footer_html();
7070 }
7071
7072 sub git_log {
7073         git_log_generic('log', \&git_log_body,
7074                         $hash, $hash_parent);
7075 }
7076
7077 sub git_commit {
7078         $hash ||= $hash_base || "HEAD";
7079         my %co = parse_commit($hash)
7080             or die_error(404, "Unknown commit object");
7081
7082         my $parent  = $co{'parent'};
7083         my $parents = $co{'parents'}; # listref
7084
7085         # we need to prepare $formats_nav before any parameter munging
7086         my $formats_nav;
7087         if (!defined $parent) {
7088                 # --root commitdiff
7089                 $formats_nav .= '(initial)';
7090         } elsif (@$parents == 1) {
7091                 # single parent commit
7092                 $formats_nav .=
7093                         '(parent: ' .
7094                         $cgi->a({-href => href(action=>"commit",
7095                                                hash=>$parent)},
7096                                 esc_html(substr($parent, 0, 7))) .
7097                         ')';
7098         } else {
7099                 # merge commit
7100                 $formats_nav .=
7101                         '(merge: ' .
7102                         join(' ', map {
7103                                 $cgi->a({-href => href(action=>"commit",
7104                                                        hash=>$_)},
7105                                         esc_html(substr($_, 0, 7)));
7106                         } @$parents ) .
7107                         ')';
7108         }
7109         if (gitweb_check_feature('patches') && @$parents <= 1) {
7110                 $formats_nav .= " | " .
7111                         $cgi->a({-href => href(action=>"patch", -replay=>1)},
7112                                 "patch");
7113         }
7114
7115         if (!defined $parent) {
7116                 $parent = "--root";
7117         }
7118         my @difftree;
7119         open my $fd, "-|", git_cmd(), "diff-tree", '-r', "--no-commit-id",
7120                 @diff_opts,
7121                 (@$parents <= 1 ? $parent : '-c'),
7122                 $hash, "--"
7123                 or die_error(500, "Open git-diff-tree failed");
7124         @difftree = map { chomp; $_ } <$fd>;
7125         close $fd or die_error(404, "Reading git-diff-tree failed");
7126
7127         # non-textual hash id's can be cached
7128         my $expires;
7129         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7130                 $expires = "+1d";
7131         }
7132         my $refs = git_get_references();
7133         my $ref = format_ref_marker($refs, $co{'id'});
7134
7135         git_header_html(undef, $expires);
7136         git_print_page_nav('commit', '',
7137                            $hash, $co{'tree'}, $hash,
7138                            $formats_nav);
7139
7140         if (defined $co{'parent'}) {
7141                 git_print_header_div('commitdiff', esc_html($co{'title'}) . $ref, $hash);
7142         } else {
7143                 git_print_header_div('tree', esc_html($co{'title'}) . $ref, $co{'tree'}, $hash);
7144         }
7145         print "<div class=\"title_text\">\n" .
7146               "<table class=\"object_header\">\n";
7147         git_print_authorship_rows(\%co);
7148         print "<tr><td>commit</td><td class=\"sha1\">$co{'id'}</td></tr>\n";
7149         print "<tr>" .
7150               "<td>tree</td>" .
7151               "<td class=\"sha1\">" .
7152               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash),
7153                        class => "list"}, $co{'tree'}) .
7154               "</td>" .
7155               "<td class=\"link\">" .
7156               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash)},
7157                       "tree");
7158         my $snapshot_links = format_snapshot_links($hash);
7159         if (defined $snapshot_links) {
7160                 print " | " . $snapshot_links;
7161         }
7162         print "</td>" .
7163               "</tr>\n";
7164
7165         foreach my $par (@$parents) {
7166                 print "<tr>" .
7167                       "<td>parent</td>" .
7168                       "<td class=\"sha1\">" .
7169                       $cgi->a({-href => href(action=>"commit", hash=>$par),
7170                                class => "list"}, $par) .
7171                       "</td>" .
7172                       "<td class=\"link\">" .
7173                       $cgi->a({-href => href(action=>"commit", hash=>$par)}, "commit") .
7174                       " | " .
7175                       $cgi->a({-href => href(action=>"commitdiff", hash=>$hash, hash_parent=>$par)}, "diff") .
7176                       "</td>" .
7177                       "</tr>\n";
7178         }
7179         print "</table>".
7180               "</div>\n";
7181
7182         print "<div class=\"page_body\">\n";
7183         git_print_log($co{'comment'});
7184         print "</div>\n";
7185
7186         git_difftree_body(\@difftree, $hash, @$parents);
7187
7188         git_footer_html();
7189 }
7190
7191 sub git_object {
7192         # object is defined by:
7193         # - hash or hash_base alone
7194         # - hash_base and file_name
7195         my $type;
7196
7197         # - hash or hash_base alone
7198         if ($hash || ($hash_base && !defined $file_name)) {
7199                 my $object_id = $hash || $hash_base;
7200
7201                 open my $fd, "-|", quote_command(
7202                         git_cmd(), 'cat-file', '-t', $object_id) . ' 2> /dev/null'
7203                         or die_error(404, "Object does not exist");
7204                 $type = <$fd>;
7205                 chomp $type;
7206                 close $fd
7207                         or die_error(404, "Object does not exist");
7208
7209         # - hash_base and file_name
7210         } elsif ($hash_base && defined $file_name) {
7211                 $file_name =~ s,/+$,,;
7212
7213                 system(git_cmd(), "cat-file", '-e', $hash_base) == 0
7214                         or die_error(404, "Base object does not exist");
7215
7216                 # here errors should not hapen
7217                 open my $fd, "-|", git_cmd(), "ls-tree", $hash_base, "--", $file_name
7218                         or die_error(500, "Open git-ls-tree failed");
7219                 my $line = <$fd>;
7220                 close $fd;
7221
7222                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
7223                 unless ($line && $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/) {
7224                         die_error(404, "File or directory for given base does not exist");
7225                 }
7226                 $type = $2;
7227                 $hash = $3;
7228         } else {
7229                 die_error(400, "Not enough information to find object");
7230         }
7231
7232         print $cgi->redirect(-uri => href(action=>$type, -full=>1,
7233                                           hash=>$hash, hash_base=>$hash_base,
7234                                           file_name=>$file_name),
7235                              -status => '302 Found');
7236 }
7237
7238 sub git_blobdiff {
7239         my $format = shift || 'html';
7240         my $diff_style = $input_params{'diff_style'} || 'inline';
7241
7242         my $fd;
7243         my @difftree;
7244         my %diffinfo;
7245         my $expires;
7246
7247         # preparing $fd and %diffinfo for git_patchset_body
7248         # new style URI
7249         if (defined $hash_base && defined $hash_parent_base) {
7250                 if (defined $file_name) {
7251                         # read raw output
7252                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7253                                 $hash_parent_base, $hash_base,
7254                                 "--", (defined $file_parent ? $file_parent : ()), $file_name
7255                                 or die_error(500, "Open git-diff-tree failed");
7256                         @difftree = map { chomp; $_ } <$fd>;
7257                         close $fd
7258                                 or die_error(404, "Reading git-diff-tree failed");
7259                         @difftree
7260                                 or die_error(404, "Blob diff not found");
7261
7262                 } elsif (defined $hash &&
7263                          $hash =~ /[0-9a-fA-F]{40}/) {
7264                         # try to find filename from $hash
7265
7266                         # read filtered raw output
7267                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7268                                 $hash_parent_base, $hash_base, "--"
7269                                 or die_error(500, "Open git-diff-tree failed");
7270                         @difftree =
7271                                 # ':100644 100644 03b21826... 3b93d5e7... M     ls-files.c'
7272                                 # $hash == to_id
7273                                 grep { /^:[0-7]{6} [0-7]{6} [0-9a-fA-F]{40} $hash/ }
7274                                 map { chomp; $_ } <$fd>;
7275                         close $fd
7276                                 or die_error(404, "Reading git-diff-tree failed");
7277                         @difftree
7278                                 or die_error(404, "Blob diff not found");
7279
7280                 } else {
7281                         die_error(400, "Missing one of the blob diff parameters");
7282                 }
7283
7284                 if (@difftree > 1) {
7285                         die_error(400, "Ambiguous blob diff specification");
7286                 }
7287
7288                 %diffinfo = parse_difftree_raw_line($difftree[0]);
7289                 $file_parent ||= $diffinfo{'from_file'} || $file_name;
7290                 $file_name   ||= $diffinfo{'to_file'};
7291
7292                 $hash_parent ||= $diffinfo{'from_id'};
7293                 $hash        ||= $diffinfo{'to_id'};
7294
7295                 # non-textual hash id's can be cached
7296                 if ($hash_base =~ m/^[0-9a-fA-F]{40}$/ &&
7297                     $hash_parent_base =~ m/^[0-9a-fA-F]{40}$/) {
7298                         $expires = '+1d';
7299                 }
7300
7301                 # open patch output
7302                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7303                         '-p', ($format eq 'html' ? "--full-index" : ()),
7304                         $hash_parent_base, $hash_base,
7305                         "--", (defined $file_parent ? $file_parent : ()), $file_name
7306                         or die_error(500, "Open git-diff-tree failed");
7307         }
7308
7309         # old/legacy style URI -- not generated anymore since 1.4.3.
7310         if (!%diffinfo) {
7311                 die_error('404 Not Found', "Missing one of the blob diff parameters")
7312         }
7313
7314         # header
7315         if ($format eq 'html') {
7316                 my $formats_nav =
7317                         $cgi->a({-href => href(action=>"blobdiff_plain", -replay=>1)},
7318                                 "raw");
7319                 $formats_nav .= diff_style_nav($diff_style);
7320                 git_header_html(undef, $expires);
7321                 if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7322                         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
7323                         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
7324                 } else {
7325                         print "<div class=\"page_nav\"><br/>$formats_nav<br/></div>\n";
7326                         print "<div class=\"title\">".esc_html("$hash vs $hash_parent")."</div>\n";
7327                 }
7328                 if (defined $file_name) {
7329                         git_print_page_path($file_name, "blob", $hash_base);
7330                 } else {
7331                         print "<div class=\"page_path\"></div>\n";
7332                 }
7333
7334         } elsif ($format eq 'plain') {
7335                 print $cgi->header(
7336                         -type => 'text/plain',
7337                         -charset => 'utf-8',
7338                         -expires => $expires,
7339                         -content_disposition => 'inline; filename="' . "$file_name" . '.patch"');
7340
7341                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7342
7343         } else {
7344                 die_error(400, "Unknown blobdiff format");
7345         }
7346
7347         # patch
7348         if ($format eq 'html') {
7349                 print "<div class=\"page_body\">\n";
7350
7351                 git_patchset_body($fd, $diff_style,
7352                                   [ \%diffinfo ], $hash_base, $hash_parent_base);
7353                 close $fd;
7354
7355                 print "</div>\n"; # class="page_body"
7356                 git_footer_html();
7357
7358         } else {
7359                 while (my $line = <$fd>) {
7360                         $line =~ s!a/($hash|$hash_parent)!'a/'.esc_path($diffinfo{'from_file'})!eg;
7361                         $line =~ s!b/($hash|$hash_parent)!'b/'.esc_path($diffinfo{'to_file'})!eg;
7362
7363                         print $line;
7364
7365                         last if $line =~ m!^\+\+\+!;
7366                 }
7367                 local $/ = undef;
7368                 print <$fd>;
7369                 close $fd;
7370         }
7371 }
7372
7373 sub git_blobdiff_plain {
7374         git_blobdiff('plain');
7375 }
7376
7377 # assumes that it is added as later part of already existing navigation,
7378 # so it returns "| foo | bar" rather than just "foo | bar"
7379 sub diff_style_nav {
7380         my ($diff_style, $is_combined) = @_;
7381         $diff_style ||= 'inline';
7382
7383         return "" if ($is_combined);
7384
7385         my @styles = (inline => 'inline', 'sidebyside' => 'side by side');
7386         my %styles = @styles;
7387         @styles =
7388                 @styles[ map { $_ * 2 } 0..$#styles/2 ];
7389
7390         return join '',
7391                 map { " | ".$_ }
7392                 map {
7393                         $_ eq $diff_style ? $styles{$_} :
7394                         $cgi->a({-href => href(-replay=>1, diff_style => $_)}, $styles{$_})
7395                 } @styles;
7396 }
7397
7398 sub git_commitdiff {
7399         my %params = @_;
7400         my $format = $params{-format} || 'html';
7401         my $diff_style = $input_params{'diff_style'} || 'inline';
7402
7403         my ($patch_max) = gitweb_get_feature('patches');
7404         if ($format eq 'patch') {
7405                 die_error(403, "Patch view not allowed") unless $patch_max;
7406         }
7407
7408         $hash ||= $hash_base || "HEAD";
7409         my %co = parse_commit($hash)
7410             or die_error(404, "Unknown commit object");
7411
7412         # choose format for commitdiff for merge
7413         if (! defined $hash_parent && @{$co{'parents'}} > 1) {
7414                 $hash_parent = '--cc';
7415         }
7416         # we need to prepare $formats_nav before almost any parameter munging
7417         my $formats_nav;
7418         if ($format eq 'html') {
7419                 $formats_nav =
7420                         $cgi->a({-href => href(action=>"commitdiff_plain", -replay=>1)},
7421                                 "raw");
7422                 if ($patch_max && @{$co{'parents'}} <= 1) {
7423                         $formats_nav .= " | " .
7424                                 $cgi->a({-href => href(action=>"patch", -replay=>1)},
7425                                         "patch");
7426                 }
7427                 $formats_nav .= diff_style_nav($diff_style, @{$co{'parents'}} > 1);
7428
7429                 if (defined $hash_parent &&
7430                     $hash_parent ne '-c' && $hash_parent ne '--cc') {
7431                         # commitdiff with two commits given
7432                         my $hash_parent_short = $hash_parent;
7433                         if ($hash_parent =~ m/^[0-9a-fA-F]{40}$/) {
7434                                 $hash_parent_short = substr($hash_parent, 0, 7);
7435                         }
7436                         $formats_nav .=
7437                                 ' (from';
7438                         for (my $i = 0; $i < @{$co{'parents'}}; $i++) {
7439                                 if ($co{'parents'}[$i] eq $hash_parent) {
7440                                         $formats_nav .= ' parent ' . ($i+1);
7441                                         last;
7442                                 }
7443                         }
7444                         $formats_nav .= ': ' .
7445                                 $cgi->a({-href => href(-replay=>1,
7446                                                        hash=>$hash_parent, hash_base=>undef)},
7447                                         esc_html($hash_parent_short)) .
7448                                 ')';
7449                 } elsif (!$co{'parent'}) {
7450                         # --root commitdiff
7451                         $formats_nav .= ' (initial)';
7452                 } elsif (scalar @{$co{'parents'}} == 1) {
7453                         # single parent commit
7454                         $formats_nav .=
7455                                 ' (parent: ' .
7456                                 $cgi->a({-href => href(-replay=>1,
7457                                                        hash=>$co{'parent'}, hash_base=>undef)},
7458                                         esc_html(substr($co{'parent'}, 0, 7))) .
7459                                 ')';
7460                 } else {
7461                         # merge commit
7462                         if ($hash_parent eq '--cc') {
7463                                 $formats_nav .= ' | ' .
7464                                         $cgi->a({-href => href(-replay=>1,
7465                                                                hash=>$hash, hash_parent=>'-c')},
7466                                                 'combined');
7467                         } else { # $hash_parent eq '-c'
7468                                 $formats_nav .= ' | ' .
7469                                         $cgi->a({-href => href(-replay=>1,
7470                                                                hash=>$hash, hash_parent=>'--cc')},
7471                                                 'compact');
7472                         }
7473                         $formats_nav .=
7474                                 ' (merge: ' .
7475                                 join(' ', map {
7476                                         $cgi->a({-href => href(-replay=>1,
7477                                                                hash=>$_, hash_base=>undef)},
7478                                                 esc_html(substr($_, 0, 7)));
7479                                 } @{$co{'parents'}} ) .
7480                                 ')';
7481                 }
7482         }
7483
7484         my $hash_parent_param = $hash_parent;
7485         if (!defined $hash_parent_param) {
7486                 # --cc for multiple parents, --root for parentless
7487                 $hash_parent_param =
7488                         @{$co{'parents'}} > 1 ? '--cc' : $co{'parent'} || '--root';
7489         }
7490
7491         # read commitdiff
7492         my $fd;
7493         my @difftree;
7494         if ($format eq 'html') {
7495                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7496                         "--no-commit-id", "--patch-with-raw", "--full-index",
7497                         $hash_parent_param, $hash, "--"
7498                         or die_error(500, "Open git-diff-tree failed");
7499
7500                 while (my $line = <$fd>) {
7501                         chomp $line;
7502                         # empty line ends raw part of diff-tree output
7503                         last unless $line;
7504                         push @difftree, scalar parse_difftree_raw_line($line);
7505                 }
7506
7507         } elsif ($format eq 'plain') {
7508                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7509                         '-p', $hash_parent_param, $hash, "--"
7510                         or die_error(500, "Open git-diff-tree failed");
7511         } elsif ($format eq 'patch') {
7512                 # For commit ranges, we limit the output to the number of
7513                 # patches specified in the 'patches' feature.
7514                 # For single commits, we limit the output to a single patch,
7515                 # diverging from the git-format-patch default.
7516                 my @commit_spec = ();
7517                 if ($hash_parent) {
7518                         if ($patch_max > 0) {
7519                                 push @commit_spec, "-$patch_max";
7520                         }
7521                         push @commit_spec, '-n', "$hash_parent..$hash";
7522                 } else {
7523                         if ($params{-single}) {
7524                                 push @commit_spec, '-1';
7525                         } else {
7526                                 if ($patch_max > 0) {
7527                                         push @commit_spec, "-$patch_max";
7528                                 }
7529                                 push @commit_spec, "-n";
7530                         }
7531                         push @commit_spec, '--root', $hash;
7532                 }
7533                 open $fd, "-|", git_cmd(), "format-patch", @diff_opts,
7534                         '--encoding=utf8', '--stdout', @commit_spec
7535                         or die_error(500, "Open git-format-patch failed");
7536         } else {
7537                 die_error(400, "Unknown commitdiff format");
7538         }
7539
7540         # non-textual hash id's can be cached
7541         my $expires;
7542         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7543                 $expires = "+1d";
7544         }
7545
7546         # write commit message
7547         if ($format eq 'html') {
7548                 my $refs = git_get_references();
7549                 my $ref = format_ref_marker($refs, $co{'id'});
7550
7551                 git_header_html(undef, $expires);
7552                 git_print_page_nav('commitdiff','', $hash,$co{'tree'},$hash, $formats_nav);
7553                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash);
7554                 print "<div class=\"title_text\">\n" .
7555                       "<table class=\"object_header\">\n";
7556                 git_print_authorship_rows(\%co);
7557                 print "</table>".
7558                       "</div>\n";
7559                 print "<div class=\"page_body\">\n";
7560                 if (@{$co{'comment'}} > 1) {
7561                         print "<div class=\"log\">\n";
7562                         git_print_log($co{'comment'}, -final_empty_line=> 1, -remove_title => 1);
7563                         print "</div>\n"; # class="log"
7564                 }
7565
7566         } elsif ($format eq 'plain') {
7567                 my $refs = git_get_references("tags");
7568                 my $tagname = git_get_rev_name_tags($hash);
7569                 my $filename = basename($project) . "-$hash.patch";
7570
7571                 print $cgi->header(
7572                         -type => 'text/plain',
7573                         -charset => 'utf-8',
7574                         -expires => $expires,
7575                         -content_disposition => 'inline; filename="' . "$filename" . '"');
7576                 my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
7577                 print "From: " . to_utf8($co{'author'}) . "\n";
7578                 print "Date: $ad{'rfc2822'} ($ad{'tz_local'})\n";
7579                 print "Subject: " . to_utf8($co{'title'}) . "\n";
7580
7581                 print "X-Git-Tag: $tagname\n" if $tagname;
7582                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7583
7584                 foreach my $line (@{$co{'comment'}}) {
7585                         print to_utf8($line) . "\n";
7586                 }
7587                 print "---\n\n";
7588         } elsif ($format eq 'patch') {
7589                 my $filename = basename($project) . "-$hash.patch";
7590
7591                 print $cgi->header(
7592                         -type => 'text/plain',
7593                         -charset => 'utf-8',
7594                         -expires => $expires,
7595                         -content_disposition => 'inline; filename="' . "$filename" . '"');
7596         }
7597
7598         # write patch
7599         if ($format eq 'html') {
7600                 my $use_parents = !defined $hash_parent ||
7601                         $hash_parent eq '-c' || $hash_parent eq '--cc';
7602                 git_difftree_body(\@difftree, $hash,
7603                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
7604                 print "<br/>\n";
7605
7606                 git_patchset_body($fd, $diff_style,
7607                                   \@difftree, $hash,
7608                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
7609                 close $fd;
7610                 print "</div>\n"; # class="page_body"
7611                 git_footer_html();
7612
7613         } elsif ($format eq 'plain') {
7614                 local $/ = undef;
7615                 print <$fd>;
7616                 close $fd
7617                         or print "Reading git-diff-tree failed\n";
7618         } elsif ($format eq 'patch') {
7619                 local $/ = undef;
7620                 print <$fd>;
7621                 close $fd
7622                         or print "Reading git-format-patch failed\n";
7623         }
7624 }
7625
7626 sub git_commitdiff_plain {
7627         git_commitdiff(-format => 'plain');
7628 }
7629
7630 # format-patch-style patches
7631 sub git_patch {
7632         git_commitdiff(-format => 'patch', -single => 1);
7633 }
7634
7635 sub git_patches {
7636         git_commitdiff(-format => 'patch');
7637 }
7638
7639 sub git_history {
7640         git_log_generic('history', \&git_history_body,
7641                         $hash_base, $hash_parent_base,
7642                         $file_name, $hash);
7643 }
7644
7645 sub git_search {
7646         $searchtype ||= 'commit';
7647
7648         # check if appropriate features are enabled
7649         gitweb_check_feature('search')
7650                 or die_error(403, "Search is disabled");
7651         if ($searchtype eq 'pickaxe') {
7652                 # pickaxe may take all resources of your box and run for several minutes
7653                 # with every query - so decide by yourself how public you make this feature
7654                 gitweb_check_feature('pickaxe')
7655                         or die_error(403, "Pickaxe search is disabled");
7656         }
7657         if ($searchtype eq 'grep') {
7658                 # grep search might be potentially CPU-intensive, too
7659                 gitweb_check_feature('grep')
7660                         or die_error(403, "Grep search is disabled");
7661         }
7662
7663         if (!defined $searchtext) {
7664                 die_error(400, "Text field is empty");
7665         }
7666         if (!defined $hash) {
7667                 $hash = git_get_head_hash($project);
7668         }
7669         my %co = parse_commit($hash);
7670         if (!%co) {
7671                 die_error(404, "Unknown commit object");
7672         }
7673         if (!defined $page) {
7674                 $page = 0;
7675         }
7676
7677         if ($searchtype eq 'commit' ||
7678             $searchtype eq 'author' ||
7679             $searchtype eq 'committer') {
7680                 git_search_message(%co);
7681         } elsif ($searchtype eq 'pickaxe') {
7682                 git_search_changes(%co);
7683         } elsif ($searchtype eq 'grep') {
7684                 git_search_files(%co);
7685         } else {
7686                 die_error(400, "Unknown search type");
7687         }
7688 }
7689
7690 sub git_search_help {
7691         git_header_html();
7692         git_print_page_nav('','', $hash,$hash,$hash);
7693         print <<EOT;
7694 <p><strong>Pattern</strong> is by default a normal string that is matched precisely (but without
7695 regard to case, except in the case of pickaxe). However, when you check the <em>re</em> checkbox,
7696 the pattern entered is recognized as the POSIX extended
7697 <a href="http://en.wikipedia.org/wiki/Regular_expression">regular expression</a> (also case
7698 insensitive).</p>
7699 <dl>
7700 <dt><b>commit</b></dt>
7701 <dd>The commit messages and authorship information will be scanned for the given pattern.</dd>
7702 EOT
7703         my $have_grep = gitweb_check_feature('grep');
7704         if ($have_grep) {
7705                 print <<EOT;
7706 <dt><b>grep</b></dt>
7707 <dd>All files in the currently selected tree (HEAD unless you are explicitly browsing
7708     a different one) are searched for the given pattern. On large trees, this search can take
7709 a while and put some strain on the server, so please use it with some consideration. Note that
7710 due to git-grep peculiarity, currently if regexp mode is turned off, the matches are
7711 case-sensitive.</dd>
7712 EOT
7713         }
7714         print <<EOT;
7715 <dt><b>author</b></dt>
7716 <dd>Name and e-mail of the change author and date of birth of the patch will be scanned for the given pattern.</dd>
7717 <dt><b>committer</b></dt>
7718 <dd>Name and e-mail of the committer and date of commit will be scanned for the given pattern.</dd>
7719 EOT
7720         my $have_pickaxe = gitweb_check_feature('pickaxe');
7721         if ($have_pickaxe) {
7722                 print <<EOT;
7723 <dt><b>pickaxe</b></dt>
7724 <dd>All commits that caused the string to appear or disappear from any file (changes that
7725 added, removed or "modified" the string) will be listed. This search can take a while and
7726 takes a lot of strain on the server, so please use it wisely. Note that since you may be
7727 interested even in changes just changing the case as well, this search is case sensitive.</dd>
7728 EOT
7729         }
7730         print "</dl>\n";
7731         git_footer_html();
7732 }
7733
7734 sub git_shortlog {
7735         git_log_generic('shortlog', \&git_shortlog_body,
7736                         $hash, $hash_parent);
7737 }
7738
7739 ## ......................................................................
7740 ## feeds (RSS, Atom; OPML)
7741
7742 sub git_feed {
7743         my $format = shift || 'atom';
7744         my $have_blame = gitweb_check_feature('blame');
7745
7746         # Atom: http://www.atomenabled.org/developers/syndication/
7747         # RSS:  http://www.notestips.com/80256B3A007F2692/1/NAMO5P9UPQ
7748         if ($format ne 'rss' && $format ne 'atom') {
7749                 die_error(400, "Unknown web feed format");
7750         }
7751
7752         # log/feed of current (HEAD) branch, log of given branch, history of file/directory
7753         my $head = $hash || 'HEAD';
7754         my @commitlist = parse_commits($head, 150, 0, $file_name);
7755
7756         my %latest_commit;
7757         my %latest_date;
7758         my $content_type = "application/$format+xml";
7759         if (defined $cgi->http('HTTP_ACCEPT') &&
7760                  $cgi->Accept('text/xml') > $cgi->Accept($content_type)) {
7761                 # browser (feed reader) prefers text/xml
7762                 $content_type = 'text/xml';
7763         }
7764         if (defined($commitlist[0])) {
7765                 %latest_commit = %{$commitlist[0]};
7766                 my $latest_epoch = $latest_commit{'committer_epoch'};
7767                 %latest_date   = parse_date($latest_epoch, $latest_commit{'comitter_tz'});
7768                 my $if_modified = $cgi->http('IF_MODIFIED_SINCE');
7769                 if (defined $if_modified) {
7770                         my $since;
7771                         if (eval { require HTTP::Date; 1; }) {
7772                                 $since = HTTP::Date::str2time($if_modified);
7773                         } elsif (eval { require Time::ParseDate; 1; }) {
7774                                 $since = Time::ParseDate::parsedate($if_modified, GMT => 1);
7775                         }
7776                         if (defined $since && $latest_epoch <= $since) {
7777                                 print $cgi->header(
7778                                         -type => $content_type,
7779                                         -charset => 'utf-8',
7780                                         -last_modified => $latest_date{'rfc2822'},
7781                                         -status => '304 Not Modified');
7782                                 return;
7783                         }
7784                 }
7785                 print $cgi->header(
7786                         -type => $content_type,
7787                         -charset => 'utf-8',
7788                         -last_modified => $latest_date{'rfc2822'});
7789         } else {
7790                 print $cgi->header(
7791                         -type => $content_type,
7792                         -charset => 'utf-8');
7793         }
7794
7795         # Optimization: skip generating the body if client asks only
7796         # for Last-Modified date.
7797         return if ($cgi->request_method() eq 'HEAD');
7798
7799         # header variables
7800         my $title = "$site_name - $project/$action";
7801         my $feed_type = 'log';
7802         if (defined $hash) {
7803                 $title .= " - '$hash'";
7804                 $feed_type = 'branch log';
7805                 if (defined $file_name) {
7806                         $title .= " :: $file_name";
7807                         $feed_type = 'history';
7808                 }
7809         } elsif (defined $file_name) {
7810                 $title .= " - $file_name";
7811                 $feed_type = 'history';
7812         }
7813         $title .= " $feed_type";
7814         my $descr = git_get_project_description($project);
7815         if (defined $descr) {
7816                 $descr = esc_html($descr);
7817         } else {
7818                 $descr = "$project " .
7819                          ($format eq 'rss' ? 'RSS' : 'Atom') .
7820                          " feed";
7821         }
7822         my $owner = git_get_project_owner($project);
7823         $owner = esc_html($owner);
7824
7825         #header
7826         my $alt_url;
7827         if (defined $file_name) {
7828                 $alt_url = href(-full=>1, action=>"history", hash=>$hash, file_name=>$file_name);
7829         } elsif (defined $hash) {
7830                 $alt_url = href(-full=>1, action=>"log", hash=>$hash);
7831         } else {
7832                 $alt_url = href(-full=>1, action=>"summary");
7833         }
7834         print qq!<?xml version="1.0" encoding="utf-8"?>\n!;
7835         if ($format eq 'rss') {
7836                 print <<XML;
7837 <rss version="2.0" xmlns:content="http://purl.org/rss/1.0/modules/content/">
7838 <channel>
7839 XML
7840                 print "<title>$title</title>\n" .
7841                       "<link>$alt_url</link>\n" .
7842                       "<description>$descr</description>\n" .
7843                       "<language>en</language>\n" .
7844                       # project owner is responsible for 'editorial' content
7845                       "<managingEditor>$owner</managingEditor>\n";
7846                 if (defined $logo || defined $favicon) {
7847                         # prefer the logo to the favicon, since RSS
7848                         # doesn't allow both
7849                         my $img = esc_url($logo || $favicon);
7850                         print "<image>\n" .
7851                               "<url>$img</url>\n" .
7852                               "<title>$title</title>\n" .
7853                               "<link>$alt_url</link>\n" .
7854                               "</image>\n";
7855                 }
7856                 if (%latest_date) {
7857                         print "<pubDate>$latest_date{'rfc2822'}</pubDate>\n";
7858                         print "<lastBuildDate>$latest_date{'rfc2822'}</lastBuildDate>\n";
7859                 }
7860                 print "<generator>gitweb v.$version/$git_version</generator>\n";
7861         } elsif ($format eq 'atom') {
7862                 print <<XML;
7863 <feed xmlns="http://www.w3.org/2005/Atom">
7864 XML
7865                 print "<title>$title</title>\n" .
7866                       "<subtitle>$descr</subtitle>\n" .
7867                       '<link rel="alternate" type="text/html" href="' .
7868                       $alt_url . '" />' . "\n" .
7869                       '<link rel="self" type="' . $content_type . '" href="' .
7870                       $cgi->self_url() . '" />' . "\n" .
7871                       "<id>" . href(-full=>1) . "</id>\n" .
7872                       # use project owner for feed author
7873                       "<author><name>$owner</name></author>\n";
7874                 if (defined $favicon) {
7875                         print "<icon>" . esc_url($favicon) . "</icon>\n";
7876                 }
7877                 if (defined $logo) {
7878                         # not twice as wide as tall: 72 x 27 pixels
7879                         print "<logo>" . esc_url($logo) . "</logo>\n";
7880                 }
7881                 if (! %latest_date) {
7882                         # dummy date to keep the feed valid until commits trickle in:
7883                         print "<updated>1970-01-01T00:00:00Z</updated>\n";
7884                 } else {
7885                         print "<updated>$latest_date{'iso-8601'}</updated>\n";
7886                 }
7887                 print "<generator version='$version/$git_version'>gitweb</generator>\n";
7888         }
7889
7890         # contents
7891         for (my $i = 0; $i <= $#commitlist; $i++) {
7892                 my %co = %{$commitlist[$i]};
7893                 my $commit = $co{'id'};
7894                 # we read 150, we always show 30 and the ones more recent than 48 hours
7895                 if (($i >= 20) && ((time - $co{'author_epoch'}) > 48*60*60)) {
7896                         last;
7897                 }
7898                 my %cd = parse_date($co{'author_epoch'}, $co{'author_tz'});
7899
7900                 # get list of changed files
7901                 open my $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7902                         $co{'parent'} || "--root",
7903                         $co{'id'}, "--", (defined $file_name ? $file_name : ())
7904                         or next;
7905                 my @difftree = map { chomp; $_ } <$fd>;
7906                 close $fd
7907                         or next;
7908
7909                 # print element (entry, item)
7910                 my $co_url = href(-full=>1, action=>"commitdiff", hash=>$commit);
7911                 if ($format eq 'rss') {
7912                         print "<item>\n" .
7913                               "<title>" . esc_html($co{'title'}) . "</title>\n" .
7914                               "<author>" . esc_html($co{'author'}) . "</author>\n" .
7915                               "<pubDate>$cd{'rfc2822'}</pubDate>\n" .
7916                               "<guid isPermaLink=\"true\">$co_url</guid>\n" .
7917                               "<link>$co_url</link>\n" .
7918                               "<description>" . esc_html($co{'title'}) . "</description>\n" .
7919                               "<content:encoded>" .
7920                               "<![CDATA[\n";
7921                 } elsif ($format eq 'atom') {
7922                         print "<entry>\n" .
7923                               "<title type=\"html\">" . esc_html($co{'title'}) . "</title>\n" .
7924                               "<updated>$cd{'iso-8601'}</updated>\n" .
7925                               "<author>\n" .
7926                               "  <name>" . esc_html($co{'author_name'}) . "</name>\n";
7927                         if ($co{'author_email'}) {
7928                                 print "  <email>" . esc_html($co{'author_email'}) . "</email>\n";
7929                         }
7930                         print "</author>\n" .
7931                               # use committer for contributor
7932                               "<contributor>\n" .
7933                               "  <name>" . esc_html($co{'committer_name'}) . "</name>\n";
7934                         if ($co{'committer_email'}) {
7935                                 print "  <email>" . esc_html($co{'committer_email'}) . "</email>\n";
7936                         }
7937                         print "</contributor>\n" .
7938                               "<published>$cd{'iso-8601'}</published>\n" .
7939                               "<link rel=\"alternate\" type=\"text/html\" href=\"$co_url\" />\n" .
7940                               "<id>$co_url</id>\n" .
7941                               "<content type=\"xhtml\" xml:base=\"" . esc_url($my_url) . "\">\n" .
7942                               "<div xmlns=\"http://www.w3.org/1999/xhtml\">\n";
7943                 }
7944                 my $comment = $co{'comment'};
7945                 print "<pre>\n";
7946                 foreach my $line (@$comment) {
7947                         $line = esc_html($line);
7948                         print "$line\n";
7949                 }
7950                 print "</pre><ul>\n";
7951                 foreach my $difftree_line (@difftree) {
7952                         my %difftree = parse_difftree_raw_line($difftree_line);
7953                         next if !$difftree{'from_id'};
7954
7955                         my $file = $difftree{'file'} || $difftree{'to_file'};
7956
7957                         print "<li>" .
7958                               "[" .
7959                               $cgi->a({-href => href(-full=>1, action=>"blobdiff",
7960                                                      hash=>$difftree{'to_id'}, hash_parent=>$difftree{'from_id'},
7961                                                      hash_base=>$co{'id'}, hash_parent_base=>$co{'parent'},
7962                                                      file_name=>$file, file_parent=>$difftree{'from_file'}),
7963                                       -title => "diff"}, 'D');
7964                         if ($have_blame) {
7965                                 print $cgi->a({-href => href(-full=>1, action=>"blame",
7966                                                              file_name=>$file, hash_base=>$commit),
7967                                               -title => "blame"}, 'B');
7968                         }
7969                         # if this is not a feed of a file history
7970                         if (!defined $file_name || $file_name ne $file) {
7971                                 print $cgi->a({-href => href(-full=>1, action=>"history",
7972                                                              file_name=>$file, hash=>$commit),
7973                                               -title => "history"}, 'H');
7974                         }
7975                         $file = esc_path($file);
7976                         print "] ".
7977                               "$file</li>\n";
7978                 }
7979                 if ($format eq 'rss') {
7980                         print "</ul>]]>\n" .
7981                               "</content:encoded>\n" .
7982                               "</item>\n";
7983                 } elsif ($format eq 'atom') {
7984                         print "</ul>\n</div>\n" .
7985                               "</content>\n" .
7986                               "</entry>\n";
7987                 }
7988         }
7989
7990         # end of feed
7991         if ($format eq 'rss') {
7992                 print "</channel>\n</rss>\n";
7993         } elsif ($format eq 'atom') {
7994                 print "</feed>\n";
7995         }
7996 }
7997
7998 sub git_rss {
7999         git_feed('rss');
8000 }
8001
8002 sub git_atom {
8003         git_feed('atom');
8004 }
8005
8006 sub git_opml {
8007         my @list = git_get_projects_list($project_filter, $strict_export);
8008         if (!@list) {
8009                 die_error(404, "No projects found");
8010         }
8011
8012         print $cgi->header(
8013                 -type => 'text/xml',
8014                 -charset => 'utf-8',
8015                 -content_disposition => 'inline; filename="opml.xml"');
8016
8017         my $title = esc_html($site_name);
8018         my $filter = " within subdirectory ";
8019         if (defined $project_filter) {
8020                 $filter .= esc_html($project_filter);
8021         } else {
8022                 $filter = "";
8023         }
8024         print <<XML;
8025 <?xml version="1.0" encoding="utf-8"?>
8026 <opml version="1.0">
8027 <head>
8028   <title>$title OPML Export$filter</title>
8029 </head>
8030 <body>
8031 <outline text="git RSS feeds">
8032 XML
8033
8034         foreach my $pr (@list) {
8035                 my %proj = %$pr;
8036                 my $head = git_get_head_hash($proj{'path'});
8037                 if (!defined $head) {
8038                         next;
8039                 }
8040                 $git_dir = "$projectroot/$proj{'path'}";
8041                 my %co = parse_commit($head);
8042                 if (!%co) {
8043                         next;
8044                 }
8045
8046                 my $path = esc_html(chop_str($proj{'path'}, 25, 5));
8047                 my $rss  = href('project' => $proj{'path'}, 'action' => 'rss', -full => 1);
8048                 my $html = href('project' => $proj{'path'}, 'action' => 'summary', -full => 1);
8049                 print "<outline type=\"rss\" text=\"$path\" title=\"$path\" xmlUrl=\"$rss\" htmlUrl=\"$html\"/>\n";
8050         }
8051         print <<XML;
8052 </outline>
8053 </body>
8054 </opml>
8055 XML
8056 }