Lady’s Gitweb - Gitweb/blob - gitweb.perl

   1 #!/usr/bin/perl
   2
   3 # gitweb - simple web interface to track changes in git repositories
   4 #
   5 # (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
   6 # (C) 2005, Christian Gierke
   7 #
   8 # This program is licensed under the GPLv2
   9
  10 use 5.008;
  11 use strict;
  12 use warnings;
  13 use CGI qw(:standard :escapeHTML -nosticky);
  14 use CGI::Util qw(unescape);
  15 use CGI::Carp qw(fatalsToBrowser set_message);
  16 use Encode;
  17 use Fcntl ':mode';
  18 use File::Find qw();
  19 use File::Basename qw(basename);
  20 use Time::HiRes qw(gettimeofday tv_interval);
  21 binmode STDOUT, ':utf8';
  22
  23 our $t0 = [ gettimeofday() ];
  24 our $number_of_git_cmds = 0;
  25
  26 BEGIN {
  27         CGI->compile() if $ENV{'MOD_PERL'};
  28 }
  29
  30 our $version = "++GIT_VERSION++";
  31
  32 our ($my_url, $my_uri, $base_url, $path_info, $home_link);
  33 sub evaluate_uri {
  34         our $cgi;
  35
  36         our $my_url = $cgi->url();
  37         our $my_uri = $cgi->url(-absolute => 1);
  38
  39         # Base URL for relative URLs in gitweb ($logo, $favicon, ...),
  40         # needed and used only for URLs with nonempty PATH_INFO
  41         our $base_url = $my_url;
  42
  43         # When the script is used as DirectoryIndex, the URL does not contain the name
  44         # of the script file itself, and $cgi->url() fails to strip PATH_INFO, so we
  45         # have to do it ourselves. We make $path_info global because it's also used
  46         # later on.
  47         #
  48         # Another issue with the script being the DirectoryIndex is that the resulting
  49         # $my_url data is not the full script URL: this is good, because we want
  50         # generated links to keep implying the script name if it wasn't explicitly
  51         # indicated in the URL we're handling, but it means that $my_url cannot be used
  52         # as base URL.
  53         # Therefore, if we needed to strip PATH_INFO, then we know that we have
  54         # to build the base URL ourselves:
  55         our $path_info = $ENV{"PATH_INFO"};
  56         if ($path_info) {
  57                 if ($my_url =~ s,\Q$path_info\E$,, &&
  58                     $my_uri =~ s,\Q$path_info\E$,, &&
  59                     defined $ENV{'SCRIPT_NAME'}) {
  60                         $base_url = $cgi->url(-base => 1) . $ENV{'SCRIPT_NAME'};
  61                 }
  62         }
  63
  64         # target of the home link on top of all pages
  65         our $home_link = $my_uri || "/";
  66 }
  67
  68 # core git executable to use
  69 # this can just be "git" if your webserver has a sensible PATH
  70 our $GIT = "++GIT_BINDIR++/git";
  71
  72 # absolute fs-path which will be prepended to the project path
  73 #our $projectroot = "/pub/scm";
  74 our $projectroot = "++GITWEB_PROJECTROOT++";
  75
  76 # fs traversing limit for getting project list
  77 # the number is relative to the projectroot
  78 our $project_maxdepth = "++GITWEB_PROJECT_MAXDEPTH++";
  79
  80 # string of the home link on top of all pages
  81 our $home_link_str = "++GITWEB_HOME_LINK_STR++";
  82
  83 # name of your site or organization to appear in page titles
  84 # replace this with something more descriptive for clearer bookmarks
  85 our $site_name = "++GITWEB_SITENAME++"
  86                  || ($ENV{'SERVER_NAME'} || "Untitled") . " Git";
  87
  88 # html snippet to include in the <head> section of each page
  89 our $site_html_head_string = "++GITWEB_SITE_HTML_HEAD_STRING++";
  90 # filename of html text to include at top of each page
  91 our $site_header = "++GITWEB_SITE_HEADER++";
  92 # html text to include at home page
  93 our $home_text = "++GITWEB_HOMETEXT++";
  94 # filename of html text to include at bottom of each page
  95 our $site_footer = "++GITWEB_SITE_FOOTER++";
  96
  97 # URI of stylesheets
  98 our @stylesheets = ("++GITWEB_CSS++");
  99 # URI of a single stylesheet, which can be overridden in GITWEB_CONFIG.
 100 our $stylesheet = undef;
 101
 102 # URI of GIT logo (72x27 size)
 103 our $logo = "++GITWEB_LOGO++";
 104 # URI of GIT favicon, assumed to be image/png type
 105 our $favicon = "++GITWEB_FAVICON++";
 106 # URI of gitweb.js (JavaScript code for gitweb)
 107 our $javascript = "++GITWEB_JS++";
 108
 109 # URI and label (title) of GIT logo link
 110 #our $logo_url = "http://www.kernel.org/pub/software/scm/git/docs/";
 111 #our $logo_label = "git documentation";
 112 our $logo_url = "http://git-scm.com/";
 113 our $logo_label = "git homepage";
 114
 115 # source of projects list
 116 our $projects_list = "++GITWEB_LIST++";
 117
 118 # the width (in characters) of the projects list "Description" column
 119 our $projects_list_description_width = 25;
 120
 121 # group projects by category on the projects list
 122 # (enabled if this variable evaluates to true)
 123 our $projects_list_group_categories = 0;
 124
 125 # default category if none specified
 126 # (leave the empty string for no category)
 127 our $project_list_default_category = "";
 128
 129 # default order of projects list
 130 # valid values are none, project, descr, owner, and age
 131 our $default_projects_order = "project";
 132
 133 # show repository only if this file exists
 134 # (only effective if this variable evaluates to true)
 135 our $export_ok = "++GITWEB_EXPORT_OK++";
 136
 137 # show repository only if this subroutine returns true
 138 # when given the path to the project, for example:
 139 #    sub { return -e "$_[0]/git-daemon-export-ok"; }
 140 our $export_auth_hook = undef;
 141
 142 # only allow viewing of repositories also shown on the overview page
 143 our $strict_export = "++GITWEB_STRICT_EXPORT++";
 144
 145 # list of git base URLs used for URL to where fetch project from,
 146 # i.e. full URL is "$git_base_url/$project"
 147 our @git_base_url_list = grep { $_ ne '' } ("++GITWEB_BASE_URL++");
 148
 149 # default blob_plain mimetype and default charset for text/plain blob
 150 our $default_blob_plain_mimetype = 'text/plain';
 151 our $default_text_plain_charset  = undef;
 152
 153 # file to use for guessing MIME types before trying /etc/mime.types
 154 # (relative to the current git repository)
 155 our $mimetypes_file = undef;
 156
 157 # assume this charset if line contains non-UTF-8 characters;
 158 # it should be valid encoding (see Encoding::Supported(3pm) for list),
 159 # for which encoding all byte sequences are valid, for example
 160 # 'iso-8859-1' aka 'latin1' (it is decoded without checking, so it
 161 # could be even 'utf-8' for the old behavior)
 162 our $fallback_encoding = 'latin1';
 163
 164 # rename detection options for git-diff and git-diff-tree
 165 # - default is '-M', with the cost proportional to
 166 #   (number of removed files) * (number of new files).
 167 # - more costly is '-C' (which implies '-M'), with the cost proportional to
 168 #   (number of changed files + number of removed files) * (number of new files)
 169 # - even more costly is '-C', '--find-copies-harder' with cost
 170 #   (number of files in the original tree) * (number of new files)
 171 # - one might want to include '-B' option, e.g. '-B', '-M'
 172 our @diff_opts = ('-M'); # taken from git_commit
 173
 174 # Disables features that would allow repository owners to inject script into
 175 # the gitweb domain.
 176 our $prevent_xss = 0;
 177
 178 # Path to the highlight executable to use (must be the one from
 179 # http://www.andre-simon.de due to assumptions about parameters and output).
 180 # Useful if highlight is not installed on your webserver's PATH.
 181 # [Default: highlight]
 182 our $highlight_bin = "++HIGHLIGHT_BIN++";
 183
 184 # information about snapshot formats that gitweb is capable of serving
 185 our %known_snapshot_formats = (
 186         # name => {
 187         #       'display' => display name,
 188         #       'type' => mime type,
 189         #       'suffix' => filename suffix,
 190         #       'format' => --format for git-archive,
 191         #       'compressor' => [compressor command and arguments]
 192         #                       (array reference, optional)
 193         #       'disabled' => boolean (optional)}
 194         #
 195         'tgz' => {
 196                 'display' => 'tar.gz',
 197                 'type' => 'application/x-gzip',
 198                 'suffix' => '.tar.gz',
 199                 'format' => 'tar',
 200                 'compressor' => ['gzip', '-n']},
 201
 202         'tbz2' => {
 203                 'display' => 'tar.bz2',
 204                 'type' => 'application/x-bzip2',
 205                 'suffix' => '.tar.bz2',
 206                 'format' => 'tar',
 207                 'compressor' => ['bzip2']},
 208
 209         'txz' => {
 210                 'display' => 'tar.xz',
 211                 'type' => 'application/x-xz',
 212                 'suffix' => '.tar.xz',
 213                 'format' => 'tar',
 214                 'compressor' => ['xz'],
 215                 'disabled' => 1},
 216
 217         'zip' => {
 218                 'display' => 'zip',
 219                 'type' => 'application/x-zip',
 220                 'suffix' => '.zip',
 221                 'format' => 'zip'},
 222 );
 223
 224 # Aliases so we understand old gitweb.snapshot values in repository
 225 # configuration.
 226 our %known_snapshot_format_aliases = (
 227         'gzip'  => 'tgz',
 228         'bzip2' => 'tbz2',
 229         'xz'    => 'txz',
 230
 231         # backward compatibility: legacy gitweb config support
 232         'x-gzip' => undef, 'gz' => undef,
 233         'x-bzip2' => undef, 'bz2' => undef,
 234         'x-zip' => undef, '' => undef,
 235 );
 236
 237 # Pixel sizes for icons and avatars. If the default font sizes or lineheights
 238 # are changed, it may be appropriate to change these values too via
 239 # $GITWEB_CONFIG.
 240 our %avatar_size = (
 241         'default' => 16,
 242         'double'  => 32
 243 );
 244
 245 # Used to set the maximum load that we will still respond to gitweb queries.
 246 # If server load exceed this value then return "503 server busy" error.
 247 # If gitweb cannot determined server load, it is taken to be 0.
 248 # Leave it undefined (or set to 'undef') to turn off load checking.
 249 our $maxload = 300;
 250
 251 # configuration for 'highlight' (http://www.andre-simon.de/)
 252 # match by basename
 253 our %highlight_basename = (
 254         #'Program' => 'py',
 255         #'Library' => 'py',
 256         'SConstruct' => 'py', # SCons equivalent of Makefile
 257         'Makefile' => 'make',
 258 );
 259 # match by extension
 260 our %highlight_ext = (
 261         # main extensions, defining name of syntax;
 262         # see files in /usr/share/highlight/langDefs/ directory
 263         map { $_ => $_ }
 264                 qw(py c cpp rb java css php sh pl js tex bib xml awk bat ini spec tcl sql make),
 265         # alternate extensions, see /etc/highlight/filetypes.conf
 266         'h' => 'c',
 267         map { $_ => 'sh'  } qw(bash zsh ksh),
 268         map { $_ => 'cpp' } qw(cxx c++ cc),
 269         map { $_ => 'php' } qw(php3 php4 php5 phps),
 270         map { $_ => 'pl'  } qw(perl pm), # perhaps also 'cgi'
 271         map { $_ => 'make'} qw(mak mk),
 272         map { $_ => 'xml' } qw(xhtml html htm),
 273 );
 274
 275 # You define site-wide feature defaults here; override them with
 276 # $GITWEB_CONFIG as necessary.
 277 our %feature = (
 278         # feature => {
 279         #       'sub' => feature-sub (subroutine),
 280         #       'override' => allow-override (boolean),
 281         #       'default' => [ default options...] (array reference)}
 282         #
 283         # if feature is overridable (it means that allow-override has true value),
 284         # then feature-sub will be called with default options as parameters;
 285         # return value of feature-sub indicates if to enable specified feature
 286         #
 287         # if there is no 'sub' key (no feature-sub), then feature cannot be
 288         # overridden
 289         #
 290         # use gitweb_get_feature(<feature>) to retrieve the <feature> value
 291         # (an array) or gitweb_check_feature(<feature>) to check if <feature>
 292         # is enabled
 293
 294         # Enable the 'blame' blob view, showing the last commit that modified
 295         # each line in the file. This can be very CPU-intensive.
 296
 297         # To enable system wide have in $GITWEB_CONFIG
 298         # $feature{'blame'}{'default'} = [1];
 299         # To have project specific config enable override in $GITWEB_CONFIG
 300         # $feature{'blame'}{'override'} = 1;
 301         # and in project config gitweb.blame = 0|1;
 302         'blame' => {
 303                 'sub' => sub { feature_bool('blame', @_) },
 304                 'override' => 0,
 305                 'default' => [0]},
 306
 307         # Enable the 'snapshot' link, providing a compressed archive of any
 308         # tree. This can potentially generate high traffic if you have large
 309         # project.
 310
 311         # Value is a list of formats defined in %known_snapshot_formats that
 312         # you wish to offer.
 313         # To disable system wide have in $GITWEB_CONFIG
 314         # $feature{'snapshot'}{'default'} = [];
 315         # To have project specific config enable override in $GITWEB_CONFIG
 316         # $feature{'snapshot'}{'override'} = 1;
 317         # and in project config, a comma-separated list of formats or "none"
 318         # to disable.  Example: gitweb.snapshot = tbz2,zip;
 319         'snapshot' => {
 320                 'sub' => \&feature_snapshot,
 321                 'override' => 0,
 322                 'default' => ['tgz']},
 323
 324         # Enable text search, which will list the commits which match author,
 325         # committer or commit text to a given string.  Enabled by default.
 326         # Project specific override is not supported.
 327         #
 328         # Note that this controls all search features, which means that if
 329         # it is disabled, then 'grep' and 'pickaxe' search would also be
 330         # disabled.
 331         'search' => {
 332                 'override' => 0,
 333                 'default' => [1]},
 334
 335         # Enable grep search, which will list the files in currently selected
 336         # tree containing the given string. Enabled by default. This can be
 337         # potentially CPU-intensive, of course.
 338         # Note that you need to have 'search' feature enabled too.
 339
 340         # To enable system wide have in $GITWEB_CONFIG
 341         # $feature{'grep'}{'default'} = [1];
 342         # To have project specific config enable override in $GITWEB_CONFIG
 343         # $feature{'grep'}{'override'} = 1;
 344         # and in project config gitweb.grep = 0|1;
 345         'grep' => {
 346                 'sub' => sub { feature_bool('grep', @_) },
 347                 'override' => 0,
 348                 'default' => [1]},
 349
 350         # Enable the pickaxe search, which will list the commits that modified
 351         # a given string in a file. This can be practical and quite faster
 352         # alternative to 'blame', but still potentially CPU-intensive.
 353         # Note that you need to have 'search' feature enabled too.
 354
 355         # To enable system wide have in $GITWEB_CONFIG
 356         # $feature{'pickaxe'}{'default'} = [1];
 357         # To have project specific config enable override in $GITWEB_CONFIG
 358         # $feature{'pickaxe'}{'override'} = 1;
 359         # and in project config gitweb.pickaxe = 0|1;
 360         'pickaxe' => {
 361                 'sub' => sub { feature_bool('pickaxe', @_) },
 362                 'override' => 0,
 363                 'default' => [1]},
 364
 365         # Enable showing size of blobs in a 'tree' view, in a separate
 366         # column, similar to what 'ls -l' does.  This cost a bit of IO.
 367
 368         # To disable system wide have in $GITWEB_CONFIG
 369         # $feature{'show-sizes'}{'default'} = [0];
 370         # To have project specific config enable override in $GITWEB_CONFIG
 371         # $feature{'show-sizes'}{'override'} = 1;
 372         # and in project config gitweb.showsizes = 0|1;
 373         'show-sizes' => {
 374                 'sub' => sub { feature_bool('showsizes', @_) },
 375                 'override' => 0,
 376                 'default' => [1]},
 377
 378         # Make gitweb use an alternative format of the URLs which can be
 379         # more readable and natural-looking: project name is embedded
 380         # directly in the path and the query string contains other
 381         # auxiliary information. All gitweb installations recognize
 382         # URL in either format; this configures in which formats gitweb
 383         # generates links.
 384
 385         # To enable system wide have in $GITWEB_CONFIG
 386         # $feature{'pathinfo'}{'default'} = [1];
 387         # Project specific override is not supported.
 388
 389         # Note that you will need to change the default location of CSS,
 390         # favicon, logo and possibly other files to an absolute URL. Also,
 391         # if gitweb.cgi serves as your indexfile, you will need to force
 392         # $my_uri to contain the script name in your $GITWEB_CONFIG.
 393         'pathinfo' => {
 394                 'override' => 0,
 395                 'default' => [0]},
 396
 397         # Make gitweb consider projects in project root subdirectories
 398         # to be forks of existing projects. Given project $projname.git,
 399         # projects matching $projname/*.git will not be shown in the main
 400         # projects list, instead a '+' mark will be added to $projname
 401         # there and a 'forks' view will be enabled for the project, listing
 402         # all the forks. If project list is taken from a file, forks have
 403         # to be listed after the main project.
 404
 405         # To enable system wide have in $GITWEB_CONFIG
 406         # $feature{'forks'}{'default'} = [1];
 407         # Project specific override is not supported.
 408         'forks' => {
 409                 'override' => 0,
 410                 'default' => [0]},
 411
 412         # Insert custom links to the action bar of all project pages.
 413         # This enables you mainly to link to third-party scripts integrating
 414         # into gitweb; e.g. git-browser for graphical history representation
 415         # or custom web-based repository administration interface.
 416
 417         # The 'default' value consists of a list of triplets in the form
 418         # (label, link, position) where position is the label after which
 419         # to insert the link and link is a format string where %n expands
 420         # to the project name, %f to the project path within the filesystem,
 421         # %h to the current hash (h gitweb parameter) and %b to the current
 422         # hash base (hb gitweb parameter); %% expands to %.
 423
 424         # To enable system wide have in $GITWEB_CONFIG e.g.
 425         # $feature{'actions'}{'default'} = [('graphiclog',
 426         #       '/git-browser/by-commit.html?r=%n', 'summary')];
 427         # Project specific override is not supported.
 428         'actions' => {
 429                 'override' => 0,
 430                 'default' => []},
 431
 432         # Allow gitweb scan project content tags of project repository,
 433         # and display the popular Web 2.0-ish "tag cloud" near the projects
 434         # list.  Note that this is something COMPLETELY different from the
 435         # normal Git tags.
 436
 437         # gitweb by itself can show existing tags, but it does not handle
 438         # tagging itself; you need to do it externally, outside gitweb.
 439         # The format is described in git_get_project_ctags() subroutine.
 440         # You may want to install the HTML::TagCloud Perl module to get
 441         # a pretty tag cloud instead of just a list of tags.
 442
 443         # To enable system wide have in $GITWEB_CONFIG
 444         # $feature{'ctags'}{'default'} = [1];
 445         # Project specific override is not supported.
 446
 447         # In the future whether ctags editing is enabled might depend
 448         # on the value, but using 1 should always mean no editing of ctags.
 449         'ctags' => {
 450                 'override' => 0,
 451                 'default' => [0]},
 452
 453         # The maximum number of patches in a patchset generated in patch
 454         # view. Set this to 0 or undef to disable patch view, or to a
 455         # negative number to remove any limit.
 456
 457         # To disable system wide have in $GITWEB_CONFIG
 458         # $feature{'patches'}{'default'} = [0];
 459         # To have project specific config enable override in $GITWEB_CONFIG
 460         # $feature{'patches'}{'override'} = 1;
 461         # and in project config gitweb.patches = 0|n;
 462         # where n is the maximum number of patches allowed in a patchset.
 463         'patches' => {
 464                 'sub' => \&feature_patches,
 465                 'override' => 0,
 466                 'default' => [16]},
 467
 468         # Avatar support. When this feature is enabled, views such as
 469         # shortlog or commit will display an avatar associated with
 470         # the email of the committer(s) and/or author(s).
 471
 472         # Currently available providers are gravatar and picon.
 473         # If an unknown provider is specified, the feature is disabled.
 474
 475         # Gravatar depends on Digest::MD5.
 476         # Picon currently relies on the indiana.edu database.
 477
 478         # To enable system wide have in $GITWEB_CONFIG
 479         # $feature{'avatar'}{'default'} = ['<provider>'];
 480         # where <provider> is either gravatar or picon.
 481         # To have project specific config enable override in $GITWEB_CONFIG
 482         # $feature{'avatar'}{'override'} = 1;
 483         # and in project config gitweb.avatar = <provider>;
 484         'avatar' => {
 485                 'sub' => \&feature_avatar,
 486                 'override' => 0,
 487                 'default' => ['']},
 488
 489         # Enable displaying how much time and how many git commands
 490         # it took to generate and display page.  Disabled by default.
 491         # Project specific override is not supported.
 492         'timed' => {
 493                 'override' => 0,
 494                 'default' => [0]},
 495
 496         # Enable turning some links into links to actions which require
 497         # JavaScript to run (like 'blame_incremental').  Not enabled by
 498         # default.  Project specific override is currently not supported.
 499         'javascript-actions' => {
 500                 'override' => 0,
 501                 'default' => [0]},
 502
 503         # Enable and configure ability to change common timezone for dates
 504         # in gitweb output via JavaScript.  Enabled by default.
 505         # Project specific override is not supported.
 506         'javascript-timezone' => {
 507                 'override' => 0,
 508                 'default' => [
 509                         'local',     # default timezone: 'utc', 'local', or '(-|+)HHMM' format,
 510                                      # or undef to turn off this feature
 511                         'gitweb_tz', # name of cookie where to store selected timezone
 512                         'datetime',  # CSS class used to mark up dates for manipulation
 513                 ]},
 514
 515         # Syntax highlighting support. This is based on Daniel Svensson's
 516         # and Sham Chukoury's work in gitweb-xmms2.git.
 517         # It requires the 'highlight' program present in $PATH,
 518         # and therefore is disabled by default.
 519
 520         # To enable system wide have in $GITWEB_CONFIG
 521         # $feature{'highlight'}{'default'} = [1];
 522
 523         'highlight' => {
 524                 'sub' => sub { feature_bool('highlight', @_) },
 525                 'override' => 0,
 526                 'default' => [0]},
 527
 528         # Enable displaying of remote heads in the heads list
 529
 530         # To enable system wide have in $GITWEB_CONFIG
 531         # $feature{'remote_heads'}{'default'} = [1];
 532         # To have project specific config enable override in $GITWEB_CONFIG
 533         # $feature{'remote_heads'}{'override'} = 1;
 534         # and in project config gitweb.remote_heads = 0|1;
 535         'remote_heads' => {
 536                 'sub' => sub { feature_bool('remote_heads', @_) },
 537                 'override' => 0,
 538                 'default' => [0]},
 539 );
 540
 541 sub gitweb_get_feature {
 542         my ($name) = @_;
 543         return unless exists $feature{$name};
 544         my ($sub, $override, @defaults) = (
 545                 $feature{$name}{'sub'},
 546                 $feature{$name}{'override'},
 547                 @{$feature{$name}{'default'}});
 548         # project specific override is possible only if we have project
 549         our $git_dir; # global variable, declared later
 550         if (!$override || !defined $git_dir) {
 551                 return @defaults;
 552         }
 553         if (!defined $sub) {
 554                 warn "feature $name is not overridable";
 555                 return @defaults;
 556         }
 557         return $sub->(@defaults);
 558 }
 559
 560 # A wrapper to check if a given feature is enabled.
 561 # With this, you can say
 562 #
 563 #   my $bool_feat = gitweb_check_feature('bool_feat');
 564 #   gitweb_check_feature('bool_feat') or somecode;
 565 #
 566 # instead of
 567 #
 568 #   my ($bool_feat) = gitweb_get_feature('bool_feat');
 569 #   (gitweb_get_feature('bool_feat'))[0] or somecode;
 570 #
 571 sub gitweb_check_feature {
 572         return (gitweb_get_feature(@_))[0];
 573 }
 574
 575
 576 sub feature_bool {
 577         my $key = shift;
 578         my ($val) = git_get_project_config($key, '--bool');
 579
 580         if (!defined $val) {
 581                 return ($_[0]);
 582         } elsif ($val eq 'true') {
 583                 return (1);
 584         } elsif ($val eq 'false') {
 585                 return (0);
 586         }
 587 }
 588
 589 sub feature_snapshot {
 590         my (@fmts) = @_;
 591
 592         my ($val) = git_get_project_config('snapshot');
 593
 594         if ($val) {
 595                 @fmts = ($val eq 'none' ? () : split /\s*[,\s]\s*/, $val);
 596         }
 597
 598         return @fmts;
 599 }
 600
 601 sub feature_patches {
 602         my @val = (git_get_project_config('patches', '--int'));
 603
 604         if (@val) {
 605                 return @val;
 606         }
 607
 608         return ($_[0]);
 609 }
 610
 611 sub feature_avatar {
 612         my @val = (git_get_project_config('avatar'));
 613
 614         return @val ? @val : @_;
 615 }
 616
 617 # checking HEAD file with -e is fragile if the repository was
 618 # initialized long time ago (i.e. symlink HEAD) and was pack-ref'ed
 619 # and then pruned.
 620 sub check_head_link {
 621         my ($dir) = @_;
 622         my $headfile = "$dir/HEAD";
 623         return ((-e $headfile) ||
 624                 (-l $headfile && readlink($headfile) =~ /^refs\/heads\//));
 625 }
 626
 627 sub check_export_ok {
 628         my ($dir) = @_;
 629         return (check_head_link($dir) &&
 630                 (!$export_ok || -e "$dir/$export_ok") &&
 631                 (!$export_auth_hook || $export_auth_hook->($dir)));
 632 }
 633
 634 # process alternate names for backward compatibility
 635 # filter out unsupported (unknown) snapshot formats
 636 sub filter_snapshot_fmts {
 637         my @fmts = @_;
 638
 639         @fmts = map {
 640                 exists $known_snapshot_format_aliases{$_} ?
 641                        $known_snapshot_format_aliases{$_} : $_} @fmts;
 642         @fmts = grep {
 643                 exists $known_snapshot_formats{$_} &&
 644                 !$known_snapshot_formats{$_}{'disabled'}} @fmts;
 645 }
 646
 647 # If it is set to code reference, it is code that it is to be run once per
 648 # request, allowing updating configurations that change with each request,
 649 # while running other code in config file only once.
 650 #
 651 # Otherwise, if it is false then gitweb would process config file only once;
 652 # if it is true then gitweb config would be run for each request.
 653 our $per_request_config = 1;
 654
 655 # read and parse gitweb config file given by its parameter.
 656 # returns true on success, false on recoverable error, allowing
 657 # to chain this subroutine, using first file that exists.
 658 # dies on errors during parsing config file, as it is unrecoverable.
 659 sub read_config_file {
 660         my $filename = shift;
 661         return unless defined $filename;
 662         # die if there are errors parsing config file
 663         if (-e $filename) {
 664                 do $filename;
 665                 die $@ if $@;
 666                 return 1;
 667         }
 668         return;
 669 }
 670
 671 our ($GITWEB_CONFIG, $GITWEB_CONFIG_SYSTEM, $GITWEB_CONFIG_COMMON);
 672 sub evaluate_gitweb_config {
 673         our $GITWEB_CONFIG = $ENV{'GITWEB_CONFIG'} || "++GITWEB_CONFIG++";
 674         our $GITWEB_CONFIG_SYSTEM = $ENV{'GITWEB_CONFIG_SYSTEM'} || "++GITWEB_CONFIG_SYSTEM++";
 675         our $GITWEB_CONFIG_COMMON = $ENV{'GITWEB_CONFIG_COMMON'} || "++GITWEB_CONFIG_COMMON++";
 676
 677         # Protect agains duplications of file names, to not read config twice.
 678         # Only one of $GITWEB_CONFIG and $GITWEB_CONFIG_SYSTEM is used, so
 679         # there possibility of duplication of filename there doesn't matter.
 680         $GITWEB_CONFIG = ""        if ($GITWEB_CONFIG eq $GITWEB_CONFIG_COMMON);
 681         $GITWEB_CONFIG_SYSTEM = "" if ($GITWEB_CONFIG_SYSTEM eq $GITWEB_CONFIG_COMMON);
 682
 683         # Common system-wide settings for convenience.
 684         # Those settings can be ovverriden by GITWEB_CONFIG or GITWEB_CONFIG_SYSTEM.
 685         read_config_file($GITWEB_CONFIG_COMMON);
 686
 687         # Use first config file that exists.  This means use the per-instance
 688         # GITWEB_CONFIG if exists, otherwise use GITWEB_SYSTEM_CONFIG.
 689         read_config_file($GITWEB_CONFIG) and return;
 690         read_config_file($GITWEB_CONFIG_SYSTEM);
 691 }
 692
 693 # Get loadavg of system, to compare against $maxload.
 694 # Currently it requires '/proc/loadavg' present to get loadavg;
 695 # if it is not present it returns 0, which means no load checking.
 696 sub get_loadavg {
 697         if( -e '/proc/loadavg' ){
 698                 open my $fd, '<', '/proc/loadavg'
 699                         or return 0;
 700                 my @load = split(/\s+/, scalar <$fd>);
 701                 close $fd;
 702
 703                 # The first three columns measure CPU and IO utilization of the last one,
 704                 # five, and 10 minute periods.  The fourth column shows the number of
 705                 # currently running processes and the total number of processes in the m/n
 706                 # format.  The last column displays the last process ID used.
 707                 return $load[0] || 0;
 708         }
 709         # additional checks for load average should go here for things that don't export
 710         # /proc/loadavg
 711
 712         return 0;
 713 }
 714
 715 # version of the core git binary
 716 our $git_version;
 717 sub evaluate_git_version {
 718         our $git_version = qx("$GIT" --version) =~ m/git version (.*)$/ ? $1 : "unknown";
 719         $number_of_git_cmds++;
 720 }
 721
 722 sub check_loadavg {
 723         if (defined $maxload && get_loadavg() > $maxload) {
 724                 die_error(503, "The load average on the server is too high");
 725         }
 726 }
 727
 728 # ======================================================================
 729 # input validation and dispatch
 730
 731 # input parameters can be collected from a variety of sources (presently, CGI
 732 # and PATH_INFO), so we define an %input_params hash that collects them all
 733 # together during validation: this allows subsequent uses (e.g. href()) to be
 734 # agnostic of the parameter origin
 735
 736 our %input_params = ();
 737
 738 # input parameters are stored with the long parameter name as key. This will
 739 # also be used in the href subroutine to convert parameters to their CGI
 740 # equivalent, and since the href() usage is the most frequent one, we store
 741 # the name -> CGI key mapping here, instead of the reverse.
 742 #
 743 # XXX: Warning: If you touch this, check the search form for updating,
 744 # too.
 745
 746 our @cgi_param_mapping = (
 747         project => "p",
 748         action => "a",
 749         file_name => "f",
 750         file_parent => "fp",
 751         hash => "h",
 752         hash_parent => "hp",
 753         hash_base => "hb",
 754         hash_parent_base => "hpb",
 755         page => "pg",
 756         order => "o",
 757         searchtext => "s",
 758         searchtype => "st",
 759         snapshot_format => "sf",
 760         extra_options => "opt",
 761         search_use_regexp => "sr",
 762         ctag => "by_tag",
 763         diff_style => "ds",
 764         # this must be last entry (for manipulation from JavaScript)
 765         javascript => "js"
 766 );
 767 our %cgi_param_mapping = @cgi_param_mapping;
 768
 769 # we will also need to know the possible actions, for validation
 770 our %actions = (
 771         "blame" => \&git_blame,
 772         "blame_incremental" => \&git_blame_incremental,
 773         "blame_data" => \&git_blame_data,
 774         "blobdiff" => \&git_blobdiff,
 775         "blobdiff_plain" => \&git_blobdiff_plain,
 776         "blob" => \&git_blob,
 777         "blob_plain" => \&git_blob_plain,
 778         "commitdiff" => \&git_commitdiff,
 779         "commitdiff_plain" => \&git_commitdiff_plain,
 780         "commit" => \&git_commit,
 781         "forks" => \&git_forks,
 782         "heads" => \&git_heads,
 783         "history" => \&git_history,
 784         "log" => \&git_log,
 785         "patch" => \&git_patch,
 786         "patches" => \&git_patches,
 787         "remotes" => \&git_remotes,
 788         "rss" => \&git_rss,
 789         "atom" => \&git_atom,
 790         "search" => \&git_search,
 791         "search_help" => \&git_search_help,
 792         "shortlog" => \&git_shortlog,
 793         "summary" => \&git_summary,
 794         "tag" => \&git_tag,
 795         "tags" => \&git_tags,
 796         "tree" => \&git_tree,
 797         "snapshot" => \&git_snapshot,
 798         "object" => \&git_object,
 799         # those below don't need $project
 800         "opml" => \&git_opml,
 801         "project_list" => \&git_project_list,
 802         "project_index" => \&git_project_index,
 803 );
 804
 805 # finally, we have the hash of allowed extra_options for the commands that
 806 # allow them
 807 our %allowed_options = (
 808         "--no-merges" => [ qw(rss atom log shortlog history) ],
 809 );
 810
 811 # fill %input_params with the CGI parameters. All values except for 'opt'
 812 # should be single values, but opt can be an array. We should probably
 813 # build an array of parameters that can be multi-valued, but since for the time
 814 # being it's only this one, we just single it out
 815 sub evaluate_query_params {
 816         our $cgi;
 817
 818         while (my ($name, $symbol) = each %cgi_param_mapping) {
 819                 if ($symbol eq 'opt') {
 820                         $input_params{$name} = [ $cgi->param($symbol) ];
 821                 } else {
 822                         $input_params{$name} = $cgi->param($symbol);
 823                 }
 824         }
 825 }
 826
 827 # now read PATH_INFO and update the parameter list for missing parameters
 828 sub evaluate_path_info {
 829         return if defined $input_params{'project'};
 830         return if !$path_info;
 831         $path_info =~ s,^/+,,;
 832         return if !$path_info;
 833
 834         # find which part of PATH_INFO is project
 835         my $project = $path_info;
 836         $project =~ s,/+$,,;
 837         while ($project && !check_head_link("$projectroot/$project")) {
 838                 $project =~ s,/*[^/]*$,,;
 839         }
 840         return unless $project;
 841         $input_params{'project'} = $project;
 842
 843         # do not change any parameters if an action is given using the query string
 844         return if $input_params{'action'};
 845         $path_info =~ s,^\Q$project\E/*,,;
 846
 847         # next, check if we have an action
 848         my $action = $path_info;
 849         $action =~ s,/.*$,,;
 850         if (exists $actions{$action}) {
 851                 $path_info =~ s,^$action/*,,;
 852                 $input_params{'action'} = $action;
 853         }
 854
 855         # list of actions that want hash_base instead of hash, but can have no
 856         # pathname (f) parameter
 857         my @wants_base = (
 858                 'tree',
 859                 'history',
 860         );
 861
 862         # we want to catch, among others
 863         # [$hash_parent_base[:$file_parent]..]$hash_parent[:$file_name]
 864         my ($parentrefname, $parentpathname, $refname, $pathname) =
 865                 ($path_info =~ /^(?:(.+?)(?::(.+))?\.\.)?([^:]+?)?(?::(.+))?$/);
 866
 867         # first, analyze the 'current' part
 868         if (defined $pathname) {
 869                 # we got "branch:filename" or "branch:dir/"
 870                 # we could use git_get_type(branch:pathname), but:
 871                 # - it needs $git_dir
 872                 # - it does a git() call
 873                 # - the convention of terminating directories with a slash
 874                 #   makes it superfluous
 875                 # - embedding the action in the PATH_INFO would make it even
 876                 #   more superfluous
 877                 $pathname =~ s,^/+,,;
 878                 if (!$pathname || substr($pathname, -1) eq "/") {
 879                         $input_params{'action'} ||= "tree";
 880                         $pathname =~ s,/$,,;
 881                 } else {
 882                         # the default action depends on whether we had parent info
 883                         # or not
 884                         if ($parentrefname) {
 885                                 $input_params{'action'} ||= "blobdiff_plain";
 886                         } else {
 887                                 $input_params{'action'} ||= "blob_plain";
 888                         }
 889                 }
 890                 $input_params{'hash_base'} ||= $refname;
 891                 $input_params{'file_name'} ||= $pathname;
 892         } elsif (defined $refname) {
 893                 # we got "branch". In this case we have to choose if we have to
 894                 # set hash or hash_base.
 895                 #
 896                 # Most of the actions without a pathname only want hash to be
 897                 # set, except for the ones specified in @wants_base that want
 898                 # hash_base instead. It should also be noted that hand-crafted
 899                 # links having 'history' as an action and no pathname or hash
 900                 # set will fail, but that happens regardless of PATH_INFO.
 901                 if (defined $parentrefname) {
 902                         # if there is parent let the default be 'shortlog' action
 903                         # (for http://git.example.com/repo.git/A..B links); if there
 904                         # is no parent, dispatch will detect type of object and set
 905                         # action appropriately if required (if action is not set)
 906                         $input_params{'action'} ||= "shortlog";
 907                 }
 908                 if ($input_params{'action'} &&
 909                     grep { $_ eq $input_params{'action'} } @wants_base) {
 910                         $input_params{'hash_base'} ||= $refname;
 911                 } else {
 912                         $input_params{'hash'} ||= $refname;
 913                 }
 914         }
 915
 916         # next, handle the 'parent' part, if present
 917         if (defined $parentrefname) {
 918                 # a missing pathspec defaults to the 'current' filename, allowing e.g.
 919                 # someproject/blobdiff/oldrev..newrev:/filename
 920                 if ($parentpathname) {
 921                         $parentpathname =~ s,^/+,,;
 922                         $parentpathname =~ s,/$,,;
 923                         $input_params{'file_parent'} ||= $parentpathname;
 924                 } else {
 925                         $input_params{'file_parent'} ||= $input_params{'file_name'};
 926                 }
 927                 # we assume that hash_parent_base is wanted if a path was specified,
 928                 # or if the action wants hash_base instead of hash
 929                 if (defined $input_params{'file_parent'} ||
 930                         grep { $_ eq $input_params{'action'} } @wants_base) {
 931                         $input_params{'hash_parent_base'} ||= $parentrefname;
 932                 } else {
 933                         $input_params{'hash_parent'} ||= $parentrefname;
 934                 }
 935         }
 936
 937         # for the snapshot action, we allow URLs in the form
 938         # $project/snapshot/$hash.ext
 939         # where .ext determines the snapshot and gets removed from the
 940         # passed $refname to provide the $hash.
 941         #
 942         # To be able to tell that $refname includes the format extension, we
 943         # require the following two conditions to be satisfied:
 944         # - the hash input parameter MUST have been set from the $refname part
 945         #   of the URL (i.e. they must be equal)
 946         # - the snapshot format MUST NOT have been defined already (e.g. from
 947         #   CGI parameter sf)
 948         # It's also useless to try any matching unless $refname has a dot,
 949         # so we check for that too
 950         if (defined $input_params{'action'} &&
 951                 $input_params{'action'} eq 'snapshot' &&
 952                 defined $refname && index($refname, '.') != -1 &&
 953                 $refname eq $input_params{'hash'} &&
 954                 !defined $input_params{'snapshot_format'}) {
 955                 # We loop over the known snapshot formats, checking for
 956                 # extensions. Allowed extensions are both the defined suffix
 957                 # (which includes the initial dot already) and the snapshot
 958                 # format key itself, with a prepended dot
 959                 while (my ($fmt, $opt) = each %known_snapshot_formats) {
 960                         my $hash = $refname;
 961                         unless ($hash =~ s/(\Q$opt->{'suffix'}\E|\Q.$fmt\E)$//) {
 962                                 next;
 963                         }
 964                         my $sfx = $1;
 965                         # a valid suffix was found, so set the snapshot format
 966                         # and reset the hash parameter
 967                         $input_params{'snapshot_format'} = $fmt;
 968                         $input_params{'hash'} = $hash;
 969                         # we also set the format suffix to the one requested
 970                         # in the URL: this way a request for e.g. .tgz returns
 971                         # a .tgz instead of a .tar.gz
 972                         $known_snapshot_formats{$fmt}{'suffix'} = $sfx;
 973                         last;
 974                 }
 975         }
 976 }
 977
 978 our ($action, $project, $file_name, $file_parent, $hash, $hash_parent, $hash_base,
 979      $hash_parent_base, @extra_options, $page, $searchtype, $search_use_regexp,
 980      $searchtext, $search_regexp);
 981 sub evaluate_and_validate_params {
 982         our $action = $input_params{'action'};
 983         if (defined $action) {
 984                 if (!validate_action($action)) {
 985                         die_error(400, "Invalid action parameter");
 986                 }
 987         }
 988
 989         # parameters which are pathnames
 990         our $project = $input_params{'project'};
 991         if (defined $project) {
 992                 if (!validate_project($project)) {
 993                         undef $project;
 994                         die_error(404, "No such project");
 995                 }
 996         }
 997
 998         our $file_name = $input_params{'file_name'};
 999         if (defined $file_name) {
1000                 if (!validate_pathname($file_name)) {
1001                         die_error(400, "Invalid file parameter");
1002                 }
1003         }
1004
1005         our $file_parent = $input_params{'file_parent'};
1006         if (defined $file_parent) {
1007                 if (!validate_pathname($file_parent)) {
1008                         die_error(400, "Invalid file parent parameter");
1009                 }
1010         }
1011
1012         # parameters which are refnames
1013         our $hash = $input_params{'hash'};
1014         if (defined $hash) {
1015                 if (!validate_refname($hash)) {
1016                         die_error(400, "Invalid hash parameter");
1017                 }
1018         }
1019
1020         our $hash_parent = $input_params{'hash_parent'};
1021         if (defined $hash_parent) {
1022                 if (!validate_refname($hash_parent)) {
1023                         die_error(400, "Invalid hash parent parameter");
1024                 }
1025         }
1026
1027         our $hash_base = $input_params{'hash_base'};
1028         if (defined $hash_base) {
1029                 if (!validate_refname($hash_base)) {
1030                         die_error(400, "Invalid hash base parameter");
1031                 }
1032         }
1033
1034         our @extra_options = @{$input_params{'extra_options'}};
1035         # @extra_options is always defined, since it can only be (currently) set from
1036         # CGI, and $cgi->param() returns the empty array in array context if the param
1037         # is not set
1038         foreach my $opt (@extra_options) {
1039                 if (not exists $allowed_options{$opt}) {
1040                         die_error(400, "Invalid option parameter");
1041                 }
1042                 if (not grep(/^$action$/, @{$allowed_options{$opt}})) {
1043                         die_error(400, "Invalid option parameter for this action");
1044                 }
1045         }
1046
1047         our $hash_parent_base = $input_params{'hash_parent_base'};
1048         if (defined $hash_parent_base) {
1049                 if (!validate_refname($hash_parent_base)) {
1050                         die_error(400, "Invalid hash parent base parameter");
1051                 }
1052         }
1053
1054         # other parameters
1055         our $page = $input_params{'page'};
1056         if (defined $page) {
1057                 if ($page =~ m/[^0-9]/) {
1058                         die_error(400, "Invalid page parameter");
1059                 }
1060         }
1061
1062         our $searchtype = $input_params{'searchtype'};
1063         if (defined $searchtype) {
1064                 if ($searchtype =~ m/[^a-z]/) {
1065                         die_error(400, "Invalid searchtype parameter");
1066                 }
1067         }
1068
1069         our $search_use_regexp = $input_params{'search_use_regexp'};
1070
1071         our $searchtext = $input_params{'searchtext'};
1072         our $search_regexp;
1073         if (defined $searchtext) {
1074                 if (length($searchtext) < 2) {
1075                         die_error(403, "At least two characters are required for search parameter");
1076                 }
1077                 $search_regexp = $search_use_regexp ? $searchtext : quotemeta $searchtext;
1078         }
1079 }
1080
1081 # path to the current git repository
1082 our $git_dir;
1083 sub evaluate_git_dir {
1084         our $git_dir = "$projectroot/$project" if $project;
1085 }
1086
1087 our (@snapshot_fmts, $git_avatar);
1088 sub configure_gitweb_features {
1089         # list of supported snapshot formats
1090         our @snapshot_fmts = gitweb_get_feature('snapshot');
1091         @snapshot_fmts = filter_snapshot_fmts(@snapshot_fmts);
1092
1093         # check that the avatar feature is set to a known provider name,
1094         # and for each provider check if the dependencies are satisfied.
1095         # if the provider name is invalid or the dependencies are not met,
1096         # reset $git_avatar to the empty string.
1097         our ($git_avatar) = gitweb_get_feature('avatar');
1098         if ($git_avatar eq 'gravatar') {
1099                 $git_avatar = '' unless (eval { require Digest::MD5; 1; });
1100         } elsif ($git_avatar eq 'picon') {
1101                 # no dependencies
1102         } else {
1103                 $git_avatar = '';
1104         }
1105 }
1106
1107 # custom error handler: 'die <message>' is Internal Server Error
1108 sub handle_errors_html {
1109         my $msg = shift; # it is already HTML escaped
1110
1111         # to avoid infinite loop where error occurs in die_error,
1112         # change handler to default handler, disabling handle_errors_html
1113         set_message("Error occured when inside die_error:\n$msg");
1114
1115         # you cannot jump out of die_error when called as error handler;
1116         # the subroutine set via CGI::Carp::set_message is called _after_
1117         # HTTP headers are already written, so it cannot write them itself
1118         die_error(undef, undef, $msg, -error_handler => 1, -no_http_header => 1);
1119 }
1120 set_message(\&handle_errors_html);
1121
1122 # dispatch
1123 sub dispatch {
1124         if (!defined $action) {
1125                 if (defined $hash) {
1126                         $action = git_get_type($hash);
1127                 } elsif (defined $hash_base && defined $file_name) {
1128                         $action = git_get_type("$hash_base:$file_name");
1129                 } elsif (defined $project) {
1130                         $action = 'summary';
1131                 } else {
1132                         $action = 'project_list';
1133                 }
1134         }
1135         if (!defined($actions{$action})) {
1136                 die_error(400, "Unknown action");
1137         }
1138         if ($action !~ m/^(?:opml|project_list|project_index)$/ &&
1139             !$project) {
1140                 die_error(400, "Project needed");
1141         }
1142         $actions{$action}->();
1143 }
1144
1145 sub reset_timer {
1146         our $t0 = [ gettimeofday() ]
1147                 if defined $t0;
1148         our $number_of_git_cmds = 0;
1149 }
1150
1151 our $first_request = 1;
1152 sub run_request {
1153         reset_timer();
1154
1155         evaluate_uri();
1156         if ($first_request) {
1157                 evaluate_gitweb_config();
1158                 evaluate_git_version();
1159         }
1160         if ($per_request_config) {
1161                 if (ref($per_request_config) eq 'CODE') {
1162                         $per_request_config->();
1163                 } elsif (!$first_request) {
1164                         evaluate_gitweb_config();
1165                 }
1166         }
1167         check_loadavg();
1168
1169         # $projectroot and $projects_list might be set in gitweb config file
1170         $projects_list ||= $projectroot;
1171
1172         evaluate_query_params();
1173         evaluate_path_info();
1174         evaluate_and_validate_params();
1175         evaluate_git_dir();
1176
1177         configure_gitweb_features();
1178
1179         dispatch();
1180 }
1181
1182 our $is_last_request = sub { 1 };
1183 our ($pre_dispatch_hook, $post_dispatch_hook, $pre_listen_hook);
1184 our $CGI = 'CGI';
1185 our $cgi;
1186 sub configure_as_fcgi {
1187         require CGI::Fast;
1188         our $CGI = 'CGI::Fast';
1189
1190         my $request_number = 0;
1191         # let each child service 100 requests
1192         our $is_last_request = sub { ++$request_number > 100 };
1193 }
1194 sub evaluate_argv {
1195         my $script_name = $ENV{'SCRIPT_NAME'} || $ENV{'SCRIPT_FILENAME'} || __FILE__;
1196         configure_as_fcgi()
1197                 if $script_name =~ /\.fcgi$/;
1198
1199         return unless (@ARGV);
1200
1201         require Getopt::Long;
1202         Getopt::Long::GetOptions(
1203                 'fastcgi|fcgi|f' => \&configure_as_fcgi,
1204                 'nproc|n=i' => sub {
1205                         my ($arg, $val) = @_;
1206                         return unless eval { require FCGI::ProcManager; 1; };
1207                         my $proc_manager = FCGI::ProcManager->new({
1208                                 n_processes => $val,
1209                         });
1210                         our $pre_listen_hook    = sub { $proc_manager->pm_manage()        };
1211                         our $pre_dispatch_hook  = sub { $proc_manager->pm_pre_dispatch()  };
1212                         our $post_dispatch_hook = sub { $proc_manager->pm_post_dispatch() };
1213                 },
1214         );
1215 }
1216
1217 sub run {
1218         evaluate_argv();
1219
1220         $first_request = 1;
1221         $pre_listen_hook->()
1222                 if $pre_listen_hook;
1223
1224  REQUEST:
1225         while ($cgi = $CGI->new()) {
1226                 $pre_dispatch_hook->()
1227                         if $pre_dispatch_hook;
1228
1229                 run_request();
1230
1231                 $post_dispatch_hook->()
1232                         if $post_dispatch_hook;
1233                 $first_request = 0;
1234
1235                 last REQUEST if ($is_last_request->());
1236         }
1237
1238  DONE_GITWEB:
1239         1;
1240 }
1241
1242 run();
1243
1244 if (defined caller) {
1245         # wrapped in a subroutine processing requests,
1246         # e.g. mod_perl with ModPerl::Registry, or PSGI with Plack::App::WrapCGI
1247         return;
1248 } else {
1249         # pure CGI script, serving single request
1250         exit;
1251 }
1252
1253 ## ======================================================================
1254 ## action links
1255
1256 # possible values of extra options
1257 # -full => 0|1      - use absolute/full URL ($my_uri/$my_url as base)
1258 # -replay => 1      - start from a current view (replay with modifications)
1259 # -path_info => 0|1 - don't use/use path_info URL (if possible)
1260 # -anchor => ANCHOR - add #ANCHOR to end of URL, implies -replay if used alone
1261 sub href {
1262         my %params = @_;
1263         # default is to use -absolute url() i.e. $my_uri
1264         my $href = $params{-full} ? $my_url : $my_uri;
1265
1266         # implicit -replay, must be first of implicit params
1267         $params{-replay} = 1 if (keys %params == 1 && $params{-anchor});
1268
1269         $params{'project'} = $project unless exists $params{'project'};
1270
1271         if ($params{-replay}) {
1272                 while (my ($name, $symbol) = each %cgi_param_mapping) {
1273                         if (!exists $params{$name}) {
1274                                 $params{$name} = $input_params{$name};
1275                         }
1276                 }
1277         }
1278
1279         my $use_pathinfo = gitweb_check_feature('pathinfo');
1280         if (defined $params{'project'} &&
1281             (exists $params{-path_info} ? $params{-path_info} : $use_pathinfo)) {
1282                 # try to put as many parameters as possible in PATH_INFO:
1283                 #   - project name
1284                 #   - action
1285                 #   - hash_parent or hash_parent_base:/file_parent
1286                 #   - hash or hash_base:/filename
1287                 #   - the snapshot_format as an appropriate suffix
1288
1289                 # When the script is the root DirectoryIndex for the domain,
1290                 # $href here would be something like http://gitweb.example.com/
1291                 # Thus, we strip any trailing / from $href, to spare us double
1292                 # slashes in the final URL
1293                 $href =~ s,/$,,;
1294
1295                 # Then add the project name, if present
1296                 $href .= "/".esc_path_info($params{'project'});
1297                 delete $params{'project'};
1298
1299                 # since we destructively absorb parameters, we keep this
1300                 # boolean that remembers if we're handling a snapshot
1301                 my $is_snapshot = $params{'action'} eq 'snapshot';
1302
1303                 # Summary just uses the project path URL, any other action is
1304                 # added to the URL
1305                 if (defined $params{'action'}) {
1306                         $href .= "/".esc_path_info($params{'action'})
1307                                 unless $params{'action'} eq 'summary';
1308                         delete $params{'action'};
1309                 }
1310
1311                 # Next, we put hash_parent_base:/file_parent..hash_base:/file_name,
1312                 # stripping nonexistent or useless pieces
1313                 $href .= "/" if ($params{'hash_base'} || $params{'hash_parent_base'}
1314                         || $params{'hash_parent'} || $params{'hash'});
1315                 if (defined $params{'hash_base'}) {
1316                         if (defined $params{'hash_parent_base'}) {
1317                                 $href .= esc_path_info($params{'hash_parent_base'});
1318                                 # skip the file_parent if it's the same as the file_name
1319                                 if (defined $params{'file_parent'}) {
1320                                         if (defined $params{'file_name'} && $params{'file_parent'} eq $params{'file_name'}) {
1321                                                 delete $params{'file_parent'};
1322                                         } elsif ($params{'file_parent'} !~ /\.\./) {
1323                                                 $href .= ":/".esc_path_info($params{'file_parent'});
1324                                                 delete $params{'file_parent'};
1325                                         }
1326                                 }
1327                                 $href .= "..";
1328                                 delete $params{'hash_parent'};
1329                                 delete $params{'hash_parent_base'};
1330                         } elsif (defined $params{'hash_parent'}) {
1331                                 $href .= esc_path_info($params{'hash_parent'}). "..";
1332                                 delete $params{'hash_parent'};
1333                         }
1334
1335                         $href .= esc_path_info($params{'hash_base'});
1336                         if (defined $params{'file_name'} && $params{'file_name'} !~ /\.\./) {
1337                                 $href .= ":/".esc_path_info($params{'file_name'});
1338                                 delete $params{'file_name'};
1339                         }
1340                         delete $params{'hash'};
1341                         delete $params{'hash_base'};
1342                 } elsif (defined $params{'hash'}) {
1343                         $href .= esc_path_info($params{'hash'});
1344                         delete $params{'hash'};
1345                 }
1346
1347                 # If the action was a snapshot, we can absorb the
1348                 # snapshot_format parameter too
1349                 if ($is_snapshot) {
1350                         my $fmt = $params{'snapshot_format'};
1351                         # snapshot_format should always be defined when href()
1352                         # is called, but just in case some code forgets, we
1353                         # fall back to the default
1354                         $fmt ||= $snapshot_fmts[0];
1355                         $href .= $known_snapshot_formats{$fmt}{'suffix'};
1356                         delete $params{'snapshot_format'};
1357                 }
1358         }
1359
1360         # now encode the parameters explicitly
1361         my @result = ();
1362         for (my $i = 0; $i < @cgi_param_mapping; $i += 2) {
1363                 my ($name, $symbol) = ($cgi_param_mapping[$i], $cgi_param_mapping[$i+1]);
1364                 if (defined $params{$name}) {
1365                         if (ref($params{$name}) eq "ARRAY") {
1366                                 foreach my $par (@{$params{$name}}) {
1367                                         push @result, $symbol . "=" . esc_param($par);
1368                                 }
1369                         } else {
1370                                 push @result, $symbol . "=" . esc_param($params{$name});
1371                         }
1372                 }
1373         }
1374         $href .= "?" . join(';', @result) if scalar @result;
1375
1376         # final transformation: trailing spaces must be escaped (URI-encoded)
1377         $href =~ s/(\s+)$/CGI::escape($1)/e;
1378
1379         if ($params{-anchor}) {
1380                 $href .= "#".esc_param($params{-anchor});
1381         }
1382
1383         return $href;
1384 }
1385
1386
1387 ## ======================================================================
1388 ## validation, quoting/unquoting and escaping
1389
1390 sub validate_action {
1391         my $input = shift || return undef;
1392         return undef unless exists $actions{$input};
1393         return $input;
1394 }
1395
1396 sub validate_project {
1397         my $input = shift || return undef;
1398         if (!validate_pathname($input) ||
1399                 !(-d "$projectroot/$input") ||
1400                 !check_export_ok("$projectroot/$input") ||
1401                 ($strict_export && !project_in_list($input))) {
1402                 return undef;
1403         } else {
1404                 return $input;
1405         }
1406 }
1407
1408 sub validate_pathname {
1409         my $input = shift || return undef;
1410
1411         # no '.' or '..' as elements of path, i.e. no '.' nor '..'
1412         # at the beginning, at the end, and between slashes.
1413         # also this catches doubled slashes
1414         if ($input =~ m!(^|/)(|\.|\.\.)(/|$)!) {
1415                 return undef;
1416         }
1417         # no null characters
1418         if ($input =~ m!\0!) {
1419                 return undef;
1420         }
1421         return $input;
1422 }
1423
1424 sub validate_refname {
1425         my $input = shift || return undef;
1426
1427         # textual hashes are O.K.
1428         if ($input =~ m/^[0-9a-fA-F]{40}$/) {
1429                 return $input;
1430         }
1431         # it must be correct pathname
1432         $input = validate_pathname($input)
1433                 or return undef;
1434         # restrictions on ref name according to git-check-ref-format
1435         if ($input =~ m!(/\.|\.\.|[\000-\040\177 ~^:?*\[]|/$)!) {
1436                 return undef;
1437         }
1438         return $input;
1439 }
1440
1441 # decode sequences of octets in utf8 into Perl's internal form,
1442 # which is utf-8 with utf8 flag set if needed.  gitweb writes out
1443 # in utf-8 thanks to "binmode STDOUT, ':utf8'" at beginning
1444 sub to_utf8 {
1445         my $str = shift;
1446         return undef unless defined $str;
1447         if (utf8::valid($str)) {
1448                 utf8::decode($str);
1449                 return $str;
1450         } else {
1451                 return decode($fallback_encoding, $str, Encode::FB_DEFAULT);
1452         }
1453 }
1454
1455 # quote unsafe chars, but keep the slash, even when it's not
1456 # correct, but quoted slashes look too horrible in bookmarks
1457 sub esc_param {
1458         my $str = shift;
1459         return undef unless defined $str;
1460         $str =~ s/([^A-Za-z0-9\-_.~()\/:@ ]+)/CGI::escape($1)/eg;
1461         $str =~ s/ /\+/g;
1462         return $str;
1463 }
1464
1465 # the quoting rules for path_info fragment are slightly different
1466 sub esc_path_info {
1467         my $str = shift;
1468         return undef unless defined $str;
1469
1470         # path_info doesn't treat '+' as space (specially), but '?' must be escaped
1471         $str =~ s/([^A-Za-z0-9\-_.~();\/;:@&= +]+)/CGI::escape($1)/eg;
1472
1473         return $str;
1474 }
1475
1476 # quote unsafe chars in whole URL, so some characters cannot be quoted
1477 sub esc_url {
1478         my $str = shift;
1479         return undef unless defined $str;
1480         $str =~ s/([^A-Za-z0-9\-_.~();\/;?:@&= ]+)/CGI::escape($1)/eg;
1481         $str =~ s/ /\+/g;
1482         return $str;
1483 }
1484
1485 # quote unsafe characters in HTML attributes
1486 sub esc_attr {
1487
1488         # for XHTML conformance escaping '"' to '&quot;' is not enough
1489         return esc_html(@_);
1490 }
1491
1492 # replace invalid utf8 character with SUBSTITUTION sequence
1493 sub esc_html {
1494         my $str = shift;
1495         my %opts = @_;
1496
1497         return undef unless defined $str;
1498
1499         $str = to_utf8($str);
1500         $str = $cgi->escapeHTML($str);
1501         if ($opts{'-nbsp'}) {
1502                 $str =~ s/ /&nbsp;/g;
1503         }
1504         $str =~ s|([[:cntrl:]])|(($1 ne "\t") ? quot_cec($1) : $1)|eg;
1505         return $str;
1506 }
1507
1508 # quote control characters and escape filename to HTML
1509 sub esc_path {
1510         my $str = shift;
1511         my %opts = @_;
1512
1513         return undef unless defined $str;
1514
1515         $str = to_utf8($str);
1516         $str = $cgi->escapeHTML($str);
1517         if ($opts{'-nbsp'}) {
1518                 $str =~ s/ /&nbsp;/g;
1519         }
1520         $str =~ s|([[:cntrl:]])|quot_cec($1)|eg;
1521         return $str;
1522 }
1523
1524 # Sanitize for use in XHTML + application/xml+xhtm (valid XML 1.0)
1525 sub sanitize {
1526         my $str = shift;
1527
1528         return undef unless defined $str;
1529
1530         $str = to_utf8($str);
1531         $str =~ s|([[:cntrl:]])|($1 =~ /[\t\n\r]/ ? $1 : quot_cec($1))|eg;
1532         return $str;
1533 }
1534
1535 # Make control characters "printable", using character escape codes (CEC)
1536 sub quot_cec {
1537         my $cntrl = shift;
1538         my %opts = @_;
1539         my %es = ( # character escape codes, aka escape sequences
1540                 "\t" => '\t',   # tab            (HT)
1541                 "\n" => '\n',   # line feed      (LF)
1542                 "\r" => '\r',   # carrige return (CR)
1543                 "\f" => '\f',   # form feed      (FF)
1544                 "\b" => '\b',   # backspace      (BS)
1545                 "\a" => '\a',   # alarm (bell)   (BEL)
1546                 "\e" => '\e',   # escape         (ESC)
1547                 "\013" => '\v', # vertical tab   (VT)
1548                 "\000" => '\0', # nul character  (NUL)
1549         );
1550         my $chr = ( (exists $es{$cntrl})
1551                     ? $es{$cntrl}
1552                     : sprintf('\%2x', ord($cntrl)) );
1553         if ($opts{-nohtml}) {
1554                 return $chr;
1555         } else {
1556                 return "<span class=\"cntrl\">$chr</span>";
1557         }
1558 }
1559
1560 # Alternatively use unicode control pictures codepoints,
1561 # Unicode "printable representation" (PR)
1562 sub quot_upr {
1563         my $cntrl = shift;
1564         my %opts = @_;
1565
1566         my $chr = sprintf('&#%04d;', 0x2400+ord($cntrl));
1567         if ($opts{-nohtml}) {
1568                 return $chr;
1569         } else {
1570                 return "<span class=\"cntrl\">$chr</span>";
1571         }
1572 }
1573
1574 # git may return quoted and escaped filenames
1575 sub unquote {
1576         my $str = shift;
1577
1578         sub unq {
1579                 my $seq = shift;
1580                 my %es = ( # character escape codes, aka escape sequences
1581                         't' => "\t",   # tab            (HT, TAB)
1582                         'n' => "\n",   # newline        (NL)
1583                         'r' => "\r",   # return         (CR)
1584                         'f' => "\f",   # form feed      (FF)
1585                         'b' => "\b",   # backspace      (BS)
1586                         'a' => "\a",   # alarm (bell)   (BEL)
1587                         'e' => "\e",   # escape         (ESC)
1588                         'v' => "\013", # vertical tab   (VT)
1589                 );
1590
1591                 if ($seq =~ m/^[0-7]{1,3}$/) {
1592                         # octal char sequence
1593                         return chr(oct($seq));
1594                 } elsif (exists $es{$seq}) {
1595                         # C escape sequence, aka character escape code
1596                         return $es{$seq};
1597                 }
1598                 # quoted ordinary character
1599                 return $seq;
1600         }
1601
1602         if ($str =~ m/^"(.*)"$/) {
1603                 # needs unquoting
1604                 $str = $1;
1605                 $str =~ s/\\([^0-7]|[0-7]{1,3})/unq($1)/eg;
1606         }
1607         return $str;
1608 }
1609
1610 # escape tabs (convert tabs to spaces)
1611 sub untabify {
1612         my $line = shift;
1613
1614         while ((my $pos = index($line, "\t")) != -1) {
1615                 if (my $count = (8 - ($pos % 8))) {
1616                         my $spaces = ' ' x $count;
1617                         $line =~ s/\t/$spaces/;
1618                 }
1619         }
1620
1621         return $line;
1622 }
1623
1624 sub project_in_list {
1625         my $project = shift;
1626         my @list = git_get_projects_list();
1627         return @list && scalar(grep { $_->{'path'} eq $project } @list);
1628 }
1629
1630 ## ----------------------------------------------------------------------
1631 ## HTML aware string manipulation
1632
1633 # Try to chop given string on a word boundary between position
1634 # $len and $len+$add_len. If there is no word boundary there,
1635 # chop at $len+$add_len. Do not chop if chopped part plus ellipsis
1636 # (marking chopped part) would be longer than given string.
1637 sub chop_str {
1638         my $str = shift;
1639         my $len = shift;
1640         my $add_len = shift || 10;
1641         my $where = shift || 'right'; # 'left' | 'center' | 'right'
1642
1643         # Make sure perl knows it is utf8 encoded so we don't
1644         # cut in the middle of a utf8 multibyte char.
1645         $str = to_utf8($str);
1646
1647         # allow only $len chars, but don't cut a word if it would fit in $add_len
1648         # if it doesn't fit, cut it if it's still longer than the dots we would add
1649         # remove chopped character entities entirely
1650
1651         # when chopping in the middle, distribute $len into left and right part
1652         # return early if chopping wouldn't make string shorter
1653         if ($where eq 'center') {
1654                 return $str if ($len + 5 >= length($str)); # filler is length 5
1655                 $len = int($len/2);
1656         } else {
1657                 return $str if ($len + 4 >= length($str)); # filler is length 4
1658         }
1659
1660         # regexps: ending and beginning with word part up to $add_len
1661         my $endre = qr/.{$len}\w{0,$add_len}/;
1662         my $begre = qr/\w{0,$add_len}.{$len}/;
1663
1664         if ($where eq 'left') {
1665                 $str =~ m/^(.*?)($begre)$/;
1666                 my ($lead, $body) = ($1, $2);
1667                 if (length($lead) > 4) {
1668                         $lead = " ...";
1669                 }
1670                 return "$lead$body";
1671
1672         } elsif ($where eq 'center') {
1673                 $str =~ m/^($endre)(.*)$/;
1674                 my ($left, $str)  = ($1, $2);
1675                 $str =~ m/^(.*?)($begre)$/;
1676                 my ($mid, $right) = ($1, $2);
1677                 if (length($mid) > 5) {
1678                         $mid = " ... ";
1679                 }
1680                 return "$left$mid$right";
1681
1682         } else {
1683                 $str =~ m/^($endre)(.*)$/;
1684                 my $body = $1;
1685                 my $tail = $2;
1686                 if (length($tail) > 4) {
1687                         $tail = "... ";
1688                 }
1689                 return "$body$tail";
1690         }
1691 }
1692
1693 # takes the same arguments as chop_str, but also wraps a <span> around the
1694 # result with a title attribute if it does get chopped. Additionally, the
1695 # string is HTML-escaped.
1696 sub chop_and_escape_str {
1697         my ($str) = @_;
1698
1699         my $chopped = chop_str(@_);
1700         $str = to_utf8($str);
1701         if ($chopped eq $str) {
1702                 return esc_html($chopped);
1703         } else {
1704                 $str =~ s/[[:cntrl:]]/?/g;
1705                 return $cgi->span({-title=>$str}, esc_html($chopped));
1706         }
1707 }
1708
1709 ## ----------------------------------------------------------------------
1710 ## functions returning short strings
1711
1712 # CSS class for given age value (in seconds)
1713 sub age_class {
1714         my $age = shift;
1715
1716         if (!defined $age) {
1717                 return "noage";
1718         } elsif ($age < 60*60*2) {
1719                 return "age0";
1720         } elsif ($age < 60*60*24*2) {
1721                 return "age1";
1722         } else {
1723                 return "age2";
1724         }
1725 }
1726
1727 # convert age in seconds to "nn units ago" string
1728 sub age_string {
1729         my $age = shift;
1730         my $age_str;
1731
1732         if ($age > 60*60*24*365*2) {
1733                 $age_str = (int $age/60/60/24/365);
1734                 $age_str .= " years ago";
1735         } elsif ($age > 60*60*24*(365/12)*2) {
1736                 $age_str = int $age/60/60/24/(365/12);
1737                 $age_str .= " months ago";
1738         } elsif ($age > 60*60*24*7*2) {
1739                 $age_str = int $age/60/60/24/7;
1740                 $age_str .= " weeks ago";
1741         } elsif ($age > 60*60*24*2) {
1742                 $age_str = int $age/60/60/24;
1743                 $age_str .= " days ago";
1744         } elsif ($age > 60*60*2) {
1745                 $age_str = int $age/60/60;
1746                 $age_str .= " hours ago";
1747         } elsif ($age > 60*2) {
1748                 $age_str = int $age/60;
1749                 $age_str .= " min ago";
1750         } elsif ($age > 2) {
1751                 $age_str = int $age;
1752                 $age_str .= " sec ago";
1753         } else {
1754                 $age_str .= " right now";
1755         }
1756         return $age_str;
1757 }
1758
1759 use constant {
1760         S_IFINVALID => 0030000,
1761         S_IFGITLINK => 0160000,
1762 };
1763
1764 # submodule/subproject, a commit object reference
1765 sub S_ISGITLINK {
1766         my $mode = shift;
1767
1768         return (($mode & S_IFMT) == S_IFGITLINK)
1769 }
1770
1771 # convert file mode in octal to symbolic file mode string
1772 sub mode_str {
1773         my $mode = oct shift;
1774
1775         if (S_ISGITLINK($mode)) {
1776                 return 'm---------';
1777         } elsif (S_ISDIR($mode & S_IFMT)) {
1778                 return 'drwxr-xr-x';
1779         } elsif (S_ISLNK($mode)) {
1780                 return 'lrwxrwxrwx';
1781         } elsif (S_ISREG($mode)) {
1782                 # git cares only about the executable bit
1783                 if ($mode & S_IXUSR) {
1784                         return '-rwxr-xr-x';
1785                 } else {
1786                         return '-rw-r--r--';
1787                 };
1788         } else {
1789                 return '----------';
1790         }
1791 }
1792
1793 # convert file mode in octal to file type string
1794 sub file_type {
1795         my $mode = shift;
1796
1797         if ($mode !~ m/^[0-7]+$/) {
1798                 return $mode;
1799         } else {
1800                 $mode = oct $mode;
1801         }
1802
1803         if (S_ISGITLINK($mode)) {
1804                 return "submodule";
1805         } elsif (S_ISDIR($mode & S_IFMT)) {
1806                 return "directory";
1807         } elsif (S_ISLNK($mode)) {
1808                 return "symlink";
1809         } elsif (S_ISREG($mode)) {
1810                 return "file";
1811         } else {
1812                 return "unknown";
1813         }
1814 }
1815
1816 # convert file mode in octal to file type description string
1817 sub file_type_long {
1818         my $mode = shift;
1819
1820         if ($mode !~ m/^[0-7]+$/) {
1821                 return $mode;
1822         } else {
1823                 $mode = oct $mode;
1824         }
1825
1826         if (S_ISGITLINK($mode)) {
1827                 return "submodule";
1828         } elsif (S_ISDIR($mode & S_IFMT)) {
1829                 return "directory";
1830         } elsif (S_ISLNK($mode)) {
1831                 return "symlink";
1832         } elsif (S_ISREG($mode)) {
1833                 if ($mode & S_IXUSR) {
1834                         return "executable";
1835                 } else {
1836                         return "file";
1837                 };
1838         } else {
1839                 return "unknown";
1840         }
1841 }
1842
1843
1844 ## ----------------------------------------------------------------------
1845 ## functions returning short HTML fragments, or transforming HTML fragments
1846 ## which don't belong to other sections
1847
1848 # format line of commit message.
1849 sub format_log_line_html {
1850         my $line = shift;
1851
1852         $line = esc_html($line, -nbsp=>1);
1853         $line =~ s{\b([0-9a-fA-F]{8,40})\b}{
1854                 $cgi->a({-href => href(action=>"object", hash=>$1),
1855                                         -class => "text"}, $1);
1856         }eg;
1857
1858         return $line;
1859 }
1860
1861 # format marker of refs pointing to given object
1862
1863 # the destination action is chosen based on object type and current context:
1864 # - for annotated tags, we choose the tag view unless it's the current view
1865 #   already, in which case we go to shortlog view
1866 # - for other refs, we keep the current view if we're in history, shortlog or
1867 #   log view, and select shortlog otherwise
1868 sub format_ref_marker {
1869         my ($refs, $id) = @_;
1870         my $markers = '';
1871
1872         if (defined $refs->{$id}) {
1873                 foreach my $ref (@{$refs->{$id}}) {
1874                         # this code exploits the fact that non-lightweight tags are the
1875                         # only indirect objects, and that they are the only objects for which
1876                         # we want to use tag instead of shortlog as action
1877                         my ($type, $name) = qw();
1878                         my $indirect = ($ref =~ s/\^\{\}$//);
1879                         # e.g. tags/v2.6.11 or heads/next
1880                         if ($ref =~ m!^(.*?)s?/(.*)$!) {
1881                                 $type = $1;
1882                                 $name = $2;
1883                         } else {
1884                                 $type = "ref";
1885                                 $name = $ref;
1886                         }
1887
1888                         my $class = $type;
1889                         $class .= " indirect" if $indirect;
1890
1891                         my $dest_action = "shortlog";
1892
1893                         if ($indirect) {
1894                                 $dest_action = "tag" unless $action eq "tag";
1895                         } elsif ($action =~ /^(history|(short)?log)$/) {
1896                                 $dest_action = $action;
1897                         }
1898
1899                         my $dest = "";
1900                         $dest .= "refs/" unless $ref =~ m!^refs/!;
1901                         $dest .= $ref;
1902
1903                         my $link = $cgi->a({
1904                                 -href => href(
1905                                         action=>$dest_action,
1906                                         hash=>$dest
1907                                 )}, $name);
1908
1909                         $markers .= " <span class=\"".esc_attr($class)."\" title=\"".esc_attr($ref)."\">" .
1910                                 $link . "</span>";
1911                 }
1912         }
1913
1914         if ($markers) {
1915                 return ' <span class="refs">'. $markers . '</span>';
1916         } else {
1917                 return "";
1918         }
1919 }
1920
1921 # format, perhaps shortened and with markers, title line
1922 sub format_subject_html {
1923         my ($long, $short, $href, $extra) = @_;
1924         $extra = '' unless defined($extra);
1925
1926         if (length($short) < length($long)) {
1927                 $long =~ s/[[:cntrl:]]/?/g;
1928                 return $cgi->a({-href => $href, -class => "list subject",
1929                                 -title => to_utf8($long)},
1930                        esc_html($short)) . $extra;
1931         } else {
1932                 return $cgi->a({-href => $href, -class => "list subject"},
1933                        esc_html($long)) . $extra;
1934         }
1935 }
1936
1937 # Rather than recomputing the url for an email multiple times, we cache it
1938 # after the first hit. This gives a visible benefit in views where the avatar
1939 # for the same email is used repeatedly (e.g. shortlog).
1940 # The cache is shared by all avatar engines (currently gravatar only), which
1941 # are free to use it as preferred. Since only one avatar engine is used for any
1942 # given page, there's no risk for cache conflicts.
1943 our %avatar_cache = ();
1944
1945 # Compute the picon url for a given email, by using the picon search service over at
1946 # http://www.cs.indiana.edu/picons/search.html
1947 sub picon_url {
1948         my $email = lc shift;
1949         if (!$avatar_cache{$email}) {
1950                 my ($user, $domain) = split('@', $email);
1951                 $avatar_cache{$email} =
1952                         "http://www.cs.indiana.edu/cgi-pub/kinzler/piconsearch.cgi/" .
1953                         "$domain/$user/" .
1954                         "users+domains+unknown/up/single";
1955         }
1956         return $avatar_cache{$email};
1957 }
1958
1959 # Compute the gravatar url for a given email, if it's not in the cache already.
1960 # Gravatar stores only the part of the URL before the size, since that's the
1961 # one computationally more expensive. This also allows reuse of the cache for
1962 # different sizes (for this particular engine).
1963 sub gravatar_url {
1964         my $email = lc shift;
1965         my $size = shift;
1966         $avatar_cache{$email} ||=
1967                 "http://www.gravatar.com/avatar/" .
1968                         Digest::MD5::md5_hex($email) . "?s=";
1969         return $avatar_cache{$email} . $size;
1970 }
1971
1972 # Insert an avatar for the given $email at the given $size if the feature
1973 # is enabled.
1974 sub git_get_avatar {
1975         my ($email, %opts) = @_;
1976         my $pre_white  = ($opts{-pad_before} ? "&nbsp;" : "");
1977         my $post_white = ($opts{-pad_after}  ? "&nbsp;" : "");
1978         $opts{-size} ||= 'default';
1979         my $size = $avatar_size{$opts{-size}} || $avatar_size{'default'};
1980         my $url = "";
1981         if ($git_avatar eq 'gravatar') {
1982                 $url = gravatar_url($email, $size);
1983         } elsif ($git_avatar eq 'picon') {
1984                 $url = picon_url($email);
1985         }
1986         # Other providers can be added by extending the if chain, defining $url
1987         # as needed. If no variant puts something in $url, we assume avatars
1988         # are completely disabled/unavailable.
1989         if ($url) {
1990                 return $pre_white .
1991                        "<img width=\"$size\" " .
1992                             "class=\"avatar\" " .
1993                             "src=\"".esc_url($url)."\" " .
1994                             "alt=\"\" " .
1995                        "/>" . $post_white;
1996         } else {
1997                 return "";
1998         }
1999 }
2000
2001 sub format_search_author {
2002         my ($author, $searchtype, $displaytext) = @_;
2003         my $have_search = gitweb_check_feature('search');
2004
2005         if ($have_search) {
2006                 my $performed = "";
2007                 if ($searchtype eq 'author') {
2008                         $performed = "authored";
2009                 } elsif ($searchtype eq 'committer') {
2010                         $performed = "committed";
2011                 }
2012
2013                 return $cgi->a({-href => href(action=>"search", hash=>$hash,
2014                                 searchtext=>$author,
2015                                 searchtype=>$searchtype), class=>"list",
2016                                 title=>"Search for commits $performed by $author"},
2017                                 $displaytext);
2018
2019         } else {
2020                 return $displaytext;
2021         }
2022 }
2023
2024 # format the author name of the given commit with the given tag
2025 # the author name is chopped and escaped according to the other
2026 # optional parameters (see chop_str).
2027 sub format_author_html {
2028         my $tag = shift;
2029         my $co = shift;
2030         my $author = chop_and_escape_str($co->{'author_name'}, @_);
2031         return "<$tag class=\"author\">" .
2032                format_search_author($co->{'author_name'}, "author",
2033                        git_get_avatar($co->{'author_email'}, -pad_after => 1) .
2034                        $author) .
2035                "</$tag>";
2036 }
2037
2038 # format git diff header line, i.e. "diff --(git|combined|cc) ..."
2039 sub format_git_diff_header_line {
2040         my $line = shift;
2041         my $diffinfo = shift;
2042         my ($from, $to) = @_;
2043
2044         if ($diffinfo->{'nparents'}) {
2045                 # combined diff
2046                 $line =~ s!^(diff (.*?) )"?.*$!$1!;
2047                 if ($to->{'href'}) {
2048                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2049                                          esc_path($to->{'file'}));
2050                 } else { # file was deleted (no href)
2051                         $line .= esc_path($to->{'file'});
2052                 }
2053         } else {
2054                 # "ordinary" diff
2055                 $line =~ s!^(diff (.*?) )"?a/.*$!$1!;
2056                 if ($from->{'href'}) {
2057                         $line .= $cgi->a({-href => $from->{'href'}, -class => "path"},
2058                                          'a/' . esc_path($from->{'file'}));
2059                 } else { # file was added (no href)
2060                         $line .= 'a/' . esc_path($from->{'file'});
2061                 }
2062                 $line .= ' ';
2063                 if ($to->{'href'}) {
2064                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2065                                          'b/' . esc_path($to->{'file'}));
2066                 } else { # file was deleted
2067                         $line .= 'b/' . esc_path($to->{'file'});
2068                 }
2069         }
2070
2071         return "<div class=\"diff header\">$line</div>\n";
2072 }
2073
2074 # format extended diff header line, before patch itself
2075 sub format_extended_diff_header_line {
2076         my $line = shift;
2077         my $diffinfo = shift;
2078         my ($from, $to) = @_;
2079
2080         # match <path>
2081         if ($line =~ s!^((copy|rename) from ).*$!$1! && $from->{'href'}) {
2082                 $line .= $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2083                                        esc_path($from->{'file'}));
2084         }
2085         if ($line =~ s!^((copy|rename) to ).*$!$1! && $to->{'href'}) {
2086                 $line .= $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2087                                  esc_path($to->{'file'}));
2088         }
2089         # match single <mode>
2090         if ($line =~ m/\s(\d{6})$/) {
2091                 $line .= '<span class="info"> (' .
2092                          file_type_long($1) .
2093                          ')</span>';
2094         }
2095         # match <hash>
2096         if ($line =~ m/^index [0-9a-fA-F]{40},[0-9a-fA-F]{40}/) {
2097                 # can match only for combined diff
2098                 $line = 'index ';
2099                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2100                         if ($from->{'href'}[$i]) {
2101                                 $line .= $cgi->a({-href=>$from->{'href'}[$i],
2102                                                   -class=>"hash"},
2103                                                  substr($diffinfo->{'from_id'}[$i],0,7));
2104                         } else {
2105                                 $line .= '0' x 7;
2106                         }
2107                         # separator
2108                         $line .= ',' if ($i < $diffinfo->{'nparents'} - 1);
2109                 }
2110                 $line .= '..';
2111                 if ($to->{'href'}) {
2112                         $line .= $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2113                                          substr($diffinfo->{'to_id'},0,7));
2114                 } else {
2115                         $line .= '0' x 7;
2116                 }
2117
2118         } elsif ($line =~ m/^index [0-9a-fA-F]{40}..[0-9a-fA-F]{40}/) {
2119                 # can match only for ordinary diff
2120                 my ($from_link, $to_link);
2121                 if ($from->{'href'}) {
2122                         $from_link = $cgi->a({-href=>$from->{'href'}, -class=>"hash"},
2123                                              substr($diffinfo->{'from_id'},0,7));
2124                 } else {
2125                         $from_link = '0' x 7;
2126                 }
2127                 if ($to->{'href'}) {
2128                         $to_link = $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2129                                            substr($diffinfo->{'to_id'},0,7));
2130                 } else {
2131                         $to_link = '0' x 7;
2132                 }
2133                 my ($from_id, $to_id) = ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
2134                 $line =~ s!$from_id\.\.$to_id!$from_link..$to_link!;
2135         }
2136
2137         return $line . "<br/>\n";
2138 }
2139
2140 # format from-file/to-file diff header
2141 sub format_diff_from_to_header {
2142         my ($from_line, $to_line, $diffinfo, $from, $to, @parents) = @_;
2143         my $line;
2144         my $result = '';
2145
2146         $line = $from_line;
2147         #assert($line =~ m/^---/) if DEBUG;
2148         # no extra formatting for "^--- /dev/null"
2149         if (! $diffinfo->{'nparents'}) {
2150                 # ordinary (single parent) diff
2151                 if ($line =~ m!^--- "?a/!) {
2152                         if ($from->{'href'}) {
2153                                 $line = '--- a/' .
2154                                         $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2155                                                 esc_path($from->{'file'}));
2156                         } else {
2157                                 $line = '--- a/' .
2158                                         esc_path($from->{'file'});
2159                         }
2160                 }
2161                 $result .= qq!<div class="diff from_file">$line</div>\n!;
2162
2163         } else {
2164                 # combined diff (merge commit)
2165                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2166                         if ($from->{'href'}[$i]) {
2167                                 $line = '--- ' .
2168                                         $cgi->a({-href=>href(action=>"blobdiff",
2169                                                              hash_parent=>$diffinfo->{'from_id'}[$i],
2170                                                              hash_parent_base=>$parents[$i],
2171                                                              file_parent=>$from->{'file'}[$i],
2172                                                              hash=>$diffinfo->{'to_id'},
2173                                                              hash_base=>$hash,
2174                                                              file_name=>$to->{'file'}),
2175                                                  -class=>"path",
2176                                                  -title=>"diff" . ($i+1)},
2177                                                 $i+1) .
2178                                         '/' .
2179                                         $cgi->a({-href=>$from->{'href'}[$i], -class=>"path"},
2180                                                 esc_path($from->{'file'}[$i]));
2181                         } else {
2182                                 $line = '--- /dev/null';
2183                         }
2184                         $result .= qq!<div class="diff from_file">$line</div>\n!;
2185                 }
2186         }
2187
2188         $line = $to_line;
2189         #assert($line =~ m/^\+\+\+/) if DEBUG;
2190         # no extra formatting for "^+++ /dev/null"
2191         if ($line =~ m!^\+\+\+ "?b/!) {
2192                 if ($to->{'href'}) {
2193                         $line = '+++ b/' .
2194                                 $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2195                                         esc_path($to->{'file'}));
2196                 } else {
2197                         $line = '+++ b/' .
2198                                 esc_path($to->{'file'});
2199                 }
2200         }
2201         $result .= qq!<div class="diff to_file">$line</div>\n!;
2202
2203         return $result;
2204 }
2205
2206 # create note for patch simplified by combined diff
2207 sub format_diff_cc_simplified {
2208         my ($diffinfo, @parents) = @_;
2209         my $result = '';
2210
2211         $result .= "<div class=\"diff header\">" .
2212                    "diff --cc ";
2213         if (!is_deleted($diffinfo)) {
2214                 $result .= $cgi->a({-href => href(action=>"blob",
2215                                                   hash_base=>$hash,
2216                                                   hash=>$diffinfo->{'to_id'},
2217                                                   file_name=>$diffinfo->{'to_file'}),
2218                                     -class => "path"},
2219                                    esc_path($diffinfo->{'to_file'}));
2220         } else {
2221                 $result .= esc_path($diffinfo->{'to_file'});
2222         }
2223         $result .= "</div>\n" . # class="diff header"
2224                    "<div class=\"diff nodifferences\">" .
2225                    "Simple merge" .
2226                    "</div>\n"; # class="diff nodifferences"
2227
2228         return $result;
2229 }
2230
2231 sub diff_line_class {
2232         my ($line, $from, $to) = @_;
2233
2234         # ordinary diff
2235         my $num_sign = 1;
2236         # combined diff
2237         if ($from && $to && ref($from->{'href'}) eq "ARRAY") {
2238                 $num_sign = scalar @{$from->{'href'}};
2239         }
2240
2241         my @diff_line_classifier = (
2242                 { regexp => qr/^\@\@{$num_sign} /, class => "chunk_header"},
2243                 { regexp => qr/^\\/,               class => "incomplete"  },
2244                 { regexp => qr/^ {$num_sign}/,     class => "ctx" },
2245                 # classifier for context must come before classifier add/rem,
2246                 # or we would have to use more complicated regexp, for example
2247                 # qr/(?= {0,$m}\+)[+ ]{$num_sign}/, where $m = $num_sign - 1;
2248                 { regexp => qr/^[+ ]{$num_sign}/,   class => "add" },
2249                 { regexp => qr/^[- ]{$num_sign}/,   class => "rem" },
2250         );
2251         for my $clsfy (@diff_line_classifier) {
2252                 return $clsfy->{'class'}
2253                         if ($line =~ $clsfy->{'regexp'});
2254         }
2255
2256         # fallback
2257         return "";
2258 }
2259
2260 # assumes that $from and $to are defined and correctly filled,
2261 # and that $line holds a line of chunk header for unified diff
2262 sub format_unidiff_chunk_header {
2263         my ($line, $from, $to) = @_;
2264
2265         my ($from_text, $from_start, $from_lines, $to_text, $to_start, $to_lines, $section) =
2266                 $line =~ m/^\@{2} (-(\d+)(?:,(\d+))?) (\+(\d+)(?:,(\d+))?) \@{2}(.*)$/;
2267
2268         $from_lines = 0 unless defined $from_lines;
2269         $to_lines   = 0 unless defined $to_lines;
2270
2271         if ($from->{'href'}) {
2272                 $from_text = $cgi->a({-href=>"$from->{'href'}#l$from_start",
2273                                      -class=>"list"}, $from_text);
2274         }
2275         if ($to->{'href'}) {
2276                 $to_text   = $cgi->a({-href=>"$to->{'href'}#l$to_start",
2277                                      -class=>"list"}, $to_text);
2278         }
2279         $line = "<span class=\"chunk_info\">@@ $from_text $to_text @@</span>" .
2280                 "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2281         return $line;
2282 }
2283
2284 # assumes that $from and $to are defined and correctly filled,
2285 # and that $line holds a line of chunk header for combined diff
2286 sub format_cc_diff_chunk_header {
2287         my ($line, $from, $to) = @_;
2288
2289         my ($prefix, $ranges, $section) = $line =~ m/^(\@+) (.*?) \@+(.*)$/;
2290         my (@from_text, @from_start, @from_nlines, $to_text, $to_start, $to_nlines);
2291
2292         @from_text = split(' ', $ranges);
2293         for (my $i = 0; $i < @from_text; ++$i) {
2294                 ($from_start[$i], $from_nlines[$i]) =
2295                         (split(',', substr($from_text[$i], 1)), 0);
2296         }
2297
2298         $to_text   = pop @from_text;
2299         $to_start  = pop @from_start;
2300         $to_nlines = pop @from_nlines;
2301
2302         $line = "<span class=\"chunk_info\">$prefix ";
2303         for (my $i = 0; $i < @from_text; ++$i) {
2304                 if ($from->{'href'}[$i]) {
2305                         $line .= $cgi->a({-href=>"$from->{'href'}[$i]#l$from_start[$i]",
2306                                           -class=>"list"}, $from_text[$i]);
2307                 } else {
2308                         $line .= $from_text[$i];
2309                 }
2310                 $line .= " ";
2311         }
2312         if ($to->{'href'}) {
2313                 $line .= $cgi->a({-href=>"$to->{'href'}#l$to_start",
2314                                   -class=>"list"}, $to_text);
2315         } else {
2316                 $line .= $to_text;
2317         }
2318         $line .= " $prefix</span>" .
2319                  "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2320         return $line;
2321 }
2322
2323 # process patch (diff) line (not to be used for diff headers),
2324 # returning class and HTML-formatted (but not wrapped) line
2325 sub process_diff_line {
2326         my $line = shift;
2327         my ($from, $to) = @_;
2328
2329         my $diff_class = diff_line_class($line, $from, $to);
2330
2331         chomp $line;
2332         $line = untabify($line);
2333
2334         if ($from && $to && $line =~ m/^\@{2} /) {
2335                 $line = format_unidiff_chunk_header($line, $from, $to);
2336                 return $diff_class, $line;
2337
2338         } elsif ($from && $to && $line =~ m/^\@{3}/) {
2339                 $line = format_cc_diff_chunk_header($line, $from, $to);
2340                 return $diff_class, $line;
2341
2342         }
2343         return $diff_class, esc_html($line, -nbsp=>1);
2344 }
2345
2346 # Generates undef or something like "_snapshot_" or "snapshot (_tbz2_ _zip_)",
2347 # linked.  Pass the hash of the tree/commit to snapshot.
2348 sub format_snapshot_links {
2349         my ($hash) = @_;
2350         my $num_fmts = @snapshot_fmts;
2351         if ($num_fmts > 1) {
2352                 # A parenthesized list of links bearing format names.
2353                 # e.g. "snapshot (_tar.gz_ _zip_)"
2354                 return "snapshot (" . join(' ', map
2355                         $cgi->a({
2356                                 -href => href(
2357                                         action=>"snapshot",
2358                                         hash=>$hash,
2359                                         snapshot_format=>$_
2360                                 )
2361                         }, $known_snapshot_formats{$_}{'display'})
2362                 , @snapshot_fmts) . ")";
2363         } elsif ($num_fmts == 1) {
2364                 # A single "snapshot" link whose tooltip bears the format name.
2365                 # i.e. "_snapshot_"
2366                 my ($fmt) = @snapshot_fmts;
2367                 return
2368                         $cgi->a({
2369                                 -href => href(
2370                                         action=>"snapshot",
2371                                         hash=>$hash,
2372                                         snapshot_format=>$fmt
2373                                 ),
2374                                 -title => "in format: $known_snapshot_formats{$fmt}{'display'}"
2375                         }, "snapshot");
2376         } else { # $num_fmts == 0
2377                 return undef;
2378         }
2379 }
2380
2381 ## ......................................................................
2382 ## functions returning values to be passed, perhaps after some
2383 ## transformation, to other functions; e.g. returning arguments to href()
2384
2385 # returns hash to be passed to href to generate gitweb URL
2386 # in -title key it returns description of link
2387 sub get_feed_info {
2388         my $format = shift || 'Atom';
2389         my %res = (action => lc($format));
2390
2391         # feed links are possible only for project views
2392         return unless (defined $project);
2393         # some views should link to OPML, or to generic project feed,
2394         # or don't have specific feed yet (so they should use generic)
2395         return if ($action =~ /^(?:tags|heads|forks|tag|search)$/x);
2396
2397         my $branch;
2398         # branches refs uses 'refs/heads/' prefix (fullname) to differentiate
2399         # from tag links; this also makes possible to detect branch links
2400         if ((defined $hash_base && $hash_base =~ m!^refs/heads/(.*)$!) ||
2401             (defined $hash      && $hash      =~ m!^refs/heads/(.*)$!)) {
2402                 $branch = $1;
2403         }
2404         # find log type for feed description (title)
2405         my $type = 'log';
2406         if (defined $file_name) {
2407                 $type  = "history of $file_name";
2408                 $type .= "/" if ($action eq 'tree');
2409                 $type .= " on '$branch'" if (defined $branch);
2410         } else {
2411                 $type = "log of $branch" if (defined $branch);
2412         }
2413
2414         $res{-title} = $type;
2415         $res{'hash'} = (defined $branch ? "refs/heads/$branch" : undef);
2416         $res{'file_name'} = $file_name;
2417
2418         return %res;
2419 }
2420
2421 ## ----------------------------------------------------------------------
2422 ## git utility subroutines, invoking git commands
2423
2424 # returns path to the core git executable and the --git-dir parameter as list
2425 sub git_cmd {
2426         $number_of_git_cmds++;
2427         return $GIT, '--git-dir='.$git_dir;
2428 }
2429
2430 # quote the given arguments for passing them to the shell
2431 # quote_command("command", "arg 1", "arg with ' and ! characters")
2432 # => "'command' 'arg 1' 'arg with '\'' and '\!' characters'"
2433 # Try to avoid using this function wherever possible.
2434 sub quote_command {
2435         return join(' ',
2436                 map { my $a = $_; $a =~ s/(['!])/'\\$1'/g; "'$a'" } @_ );
2437 }
2438
2439 # get HEAD ref of given project as hash
2440 sub git_get_head_hash {
2441         return git_get_full_hash(shift, 'HEAD');
2442 }
2443
2444 sub git_get_full_hash {
2445         return git_get_hash(@_);
2446 }
2447
2448 sub git_get_short_hash {
2449         return git_get_hash(@_, '--short=7');
2450 }
2451
2452 sub git_get_hash {
2453         my ($project, $hash, @options) = @_;
2454         my $o_git_dir = $git_dir;
2455         my $retval = undef;
2456         $git_dir = "$projectroot/$project";
2457         if (open my $fd, '-|', git_cmd(), 'rev-parse',
2458             '--verify', '-q', @options, $hash) {
2459                 $retval = <$fd>;
2460                 chomp $retval if defined $retval;
2461                 close $fd;
2462         }
2463         if (defined $o_git_dir) {
2464                 $git_dir = $o_git_dir;
2465         }
2466         return $retval;
2467 }
2468
2469 # get type of given object
2470 sub git_get_type {
2471         my $hash = shift;
2472
2473         open my $fd, "-|", git_cmd(), "cat-file", '-t', $hash or return;
2474         my $type = <$fd>;
2475         close $fd or return;
2476         chomp $type;
2477         return $type;
2478 }
2479
2480 # repository configuration
2481 our $config_file = '';
2482 our %config;
2483
2484 # store multiple values for single key as anonymous array reference
2485 # single values stored directly in the hash, not as [ <value> ]
2486 sub hash_set_multi {
2487         my ($hash, $key, $value) = @_;
2488
2489         if (!exists $hash->{$key}) {
2490                 $hash->{$key} = $value;
2491         } elsif (!ref $hash->{$key}) {
2492                 $hash->{$key} = [ $hash->{$key}, $value ];
2493         } else {
2494                 push @{$hash->{$key}}, $value;
2495         }
2496 }
2497
2498 # return hash of git project configuration
2499 # optionally limited to some section, e.g. 'gitweb'
2500 sub git_parse_project_config {
2501         my $section_regexp = shift;
2502         my %config;
2503
2504         local $/ = "\0";
2505
2506         open my $fh, "-|", git_cmd(), "config", '-z', '-l',
2507                 or return;
2508
2509         while (my $keyval = <$fh>) {
2510                 chomp $keyval;
2511                 my ($key, $value) = split(/\n/, $keyval, 2);
2512
2513                 hash_set_multi(\%config, $key, $value)
2514                         if (!defined $section_regexp || $key =~ /^(?:$section_regexp)\./o);
2515         }
2516         close $fh;
2517
2518         return %config;
2519 }
2520
2521 # convert config value to boolean: 'true' or 'false'
2522 # no value, number > 0, 'true' and 'yes' values are true
2523 # rest of values are treated as false (never as error)
2524 sub config_to_bool {
2525         my $val = shift;
2526
2527         return 1 if !defined $val;             # section.key
2528
2529         # strip leading and trailing whitespace
2530         $val =~ s/^\s+//;
2531         $val =~ s/\s+$//;
2532
2533         return (($val =~ /^\d+$/ && $val) ||   # section.key = 1
2534                 ($val =~ /^(?:true|yes)$/i));  # section.key = true
2535 }
2536
2537 # convert config value to simple decimal number
2538 # an optional value suffix of 'k', 'm', or 'g' will cause the value
2539 # to be multiplied by 1024, 1048576, or 1073741824
2540 sub config_to_int {
2541         my $val = shift;
2542
2543         # strip leading and trailing whitespace
2544         $val =~ s/^\s+//;
2545         $val =~ s/\s+$//;
2546
2547         if (my ($num, $unit) = ($val =~ /^([0-9]*)([kmg])$/i)) {
2548                 $unit = lc($unit);
2549                 # unknown unit is treated as 1
2550                 return $num * ($unit eq 'g' ? 1073741824 :
2551                                $unit eq 'm' ?    1048576 :
2552                                $unit eq 'k' ?       1024 : 1);
2553         }
2554         return $val;
2555 }
2556
2557 # convert config value to array reference, if needed
2558 sub config_to_multi {
2559         my $val = shift;
2560
2561         return ref($val) ? $val : (defined($val) ? [ $val ] : []);
2562 }
2563
2564 sub git_get_project_config {
2565         my ($key, $type) = @_;
2566
2567         return unless defined $git_dir;
2568
2569         # key sanity check
2570         return unless ($key);
2571         # only subsection, if exists, is case sensitive,
2572         # and not lowercased by 'git config -z -l'
2573         if (my ($hi, $mi, $lo) = ($key =~ /^([^.]*)\.(.*)\.([^.]*)$/)) {
2574                 $key = join(".", lc($hi), $mi, lc($lo));
2575         } else {
2576                 $key = lc($key);
2577         }
2578         $key =~ s/^gitweb\.//;
2579         return if ($key =~ m/\W/);
2580
2581         # type sanity check
2582         if (defined $type) {
2583                 $type =~ s/^--//;
2584                 $type = undef
2585                         unless ($type eq 'bool' || $type eq 'int');
2586         }
2587
2588         # get config
2589         if (!defined $config_file ||
2590             $config_file ne "$git_dir/config") {
2591                 %config = git_parse_project_config('gitweb');
2592                 $config_file = "$git_dir/config";
2593         }
2594
2595         # check if config variable (key) exists
2596         return unless exists $config{"gitweb.$key"};
2597
2598         # ensure given type
2599         if (!defined $type) {
2600                 return $config{"gitweb.$key"};
2601         } elsif ($type eq 'bool') {
2602                 # backward compatibility: 'git config --bool' returns true/false
2603                 return config_to_bool($config{"gitweb.$key"}) ? 'true' : 'false';
2604         } elsif ($type eq 'int') {
2605                 return config_to_int($config{"gitweb.$key"});
2606         }
2607         return $config{"gitweb.$key"};
2608 }
2609
2610 # get hash of given path at given ref
2611 sub git_get_hash_by_path {
2612         my $base = shift;
2613         my $path = shift || return undef;
2614         my $type = shift;
2615
2616         $path =~ s,/+$,,;
2617
2618         open my $fd, "-|", git_cmd(), "ls-tree", $base, "--", $path
2619                 or die_error(500, "Open git-ls-tree failed");
2620         my $line = <$fd>;
2621         close $fd or return undef;
2622
2623         if (!defined $line) {
2624                 # there is no tree or hash given by $path at $base
2625                 return undef;
2626         }
2627
2628         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
2629         $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/;
2630         if (defined $type && $type ne $2) {
2631                 # type doesn't match
2632                 return undef;
2633         }
2634         return $3;
2635 }
2636
2637 # get path of entry with given hash at given tree-ish (ref)
2638 # used to get 'from' filename for combined diff (merge commit) for renames
2639 sub git_get_path_by_hash {
2640         my $base = shift || return;
2641         my $hash = shift || return;
2642
2643         local $/ = "\0";
2644
2645         open my $fd, "-|", git_cmd(), "ls-tree", '-r', '-t', '-z', $base
2646                 or return undef;
2647         while (my $line = <$fd>) {
2648                 chomp $line;
2649
2650                 #'040000 tree 595596a6a9117ddba9fe379b6b012b558bac8423  gitweb'
2651                 #'100644 blob e02e90f0429be0d2a69b76571101f20b8f75530f  gitweb/README'
2652                 if ($line =~ m/(?:[0-9]+) (?:.+) $hash\t(.+)$/) {
2653                         close $fd;
2654                         return $1;
2655                 }
2656         }
2657         close $fd;
2658         return undef;
2659 }
2660
2661 ## ......................................................................
2662 ## git utility functions, directly accessing git repository
2663
2664 # get the value of config variable either from file named as the variable
2665 # itself in the repository ($GIT_DIR/$name file), or from gitweb.$name
2666 # configuration variable in the repository config file.
2667 sub git_get_file_or_project_config {
2668         my ($path, $name) = @_;
2669
2670         $git_dir = "$projectroot/$path";
2671         open my $fd, '<', "$git_dir/$name"
2672                 or return git_get_project_config($name);
2673         my $conf = <$fd>;
2674         close $fd;
2675         if (defined $conf) {
2676                 chomp $conf;
2677         }
2678         return $conf;
2679 }
2680
2681 sub git_get_project_description {
2682         my $path = shift;
2683         return git_get_file_or_project_config($path, 'description');
2684 }
2685
2686 sub git_get_project_category {
2687         my $path = shift;
2688         return git_get_file_or_project_config($path, 'category');
2689 }
2690
2691
2692 # supported formats:
2693 # * $GIT_DIR/ctags/<tagname> file (in 'ctags' subdirectory)
2694 #   - if its contents is a number, use it as tag weight,
2695 #   - otherwise add a tag with weight 1
2696 # * $GIT_DIR/ctags file, each line is a tag (with weight 1)
2697 #   the same value multiple times increases tag weight
2698 # * `gitweb.ctag' multi-valued repo config variable
2699 sub git_get_project_ctags {
2700         my $project = shift;
2701         my $ctags = {};
2702
2703         $git_dir = "$projectroot/$project";
2704         if (opendir my $dh, "$git_dir/ctags") {
2705                 my @files = grep { -f $_ } map { "$git_dir/ctags/$_" } readdir($dh);
2706                 foreach my $tagfile (@files) {
2707                         open my $ct, '<', $tagfile
2708                                 or next;
2709                         my $val = <$ct>;
2710                         chomp $val if $val;
2711                         close $ct;
2712
2713                         (my $ctag = $tagfile) =~ s#.*/##;
2714                         if ($val =~ /^\d+$/) {
2715                                 $ctags->{$ctag} = $val;
2716                         } else {
2717                                 $ctags->{$ctag} = 1;
2718                         }
2719                 }
2720                 closedir $dh;
2721
2722         } elsif (open my $fh, '<', "$git_dir/ctags") {
2723                 while (my $line = <$fh>) {
2724                         chomp $line;
2725                         $ctags->{$line}++ if $line;
2726                 }
2727                 close $fh;
2728
2729         } else {
2730                 my $taglist = config_to_multi(git_get_project_config('ctag'));
2731                 foreach my $tag (@$taglist) {
2732                         $ctags->{$tag}++;
2733                 }
2734         }
2735
2736         return $ctags;
2737 }
2738
2739 # return hash, where keys are content tags ('ctags'),
2740 # and values are sum of weights of given tag in every project
2741 sub git_gather_all_ctags {
2742         my $projects = shift;
2743         my $ctags = {};
2744
2745         foreach my $p (@$projects) {
2746                 foreach my $ct (keys %{$p->{'ctags'}}) {
2747                         $ctags->{$ct} += $p->{'ctags'}->{$ct};
2748                 }
2749         }
2750
2751         return $ctags;
2752 }
2753
2754 sub git_populate_project_tagcloud {
2755         my $ctags = shift;
2756
2757         # First, merge different-cased tags; tags vote on casing
2758         my %ctags_lc;
2759         foreach (keys %$ctags) {
2760                 $ctags_lc{lc $_}->{count} += $ctags->{$_};
2761                 if (not $ctags_lc{lc $_}->{topcount}
2762                     or $ctags_lc{lc $_}->{topcount} < $ctags->{$_}) {
2763                         $ctags_lc{lc $_}->{topcount} = $ctags->{$_};
2764                         $ctags_lc{lc $_}->{topname} = $_;
2765                 }
2766         }
2767
2768         my $cloud;
2769         my $matched = $cgi->param('by_tag');
2770         if (eval { require HTML::TagCloud; 1; }) {
2771                 $cloud = HTML::TagCloud->new;
2772                 foreach my $ctag (sort keys %ctags_lc) {
2773                         # Pad the title with spaces so that the cloud looks
2774                         # less crammed.
2775                         my $title = esc_html($ctags_lc{$ctag}->{topname});
2776                         $title =~ s/ /&nbsp;/g;
2777                         $title =~ s/^/&nbsp;/g;
2778                         $title =~ s/$/&nbsp;/g;
2779                         if (defined $matched && $matched eq $ctag) {
2780                                 $title = qq(<span class="match">$title</span>);
2781                         }
2782                         $cloud->add($title, href(project=>undef, ctag=>$ctag),
2783                                     $ctags_lc{$ctag}->{count});
2784                 }
2785         } else {
2786                 $cloud = {};
2787                 foreach my $ctag (keys %ctags_lc) {
2788                         my $title = esc_html($ctags_lc{$ctag}->{topname}, -nbsp=>1);
2789                         if (defined $matched && $matched eq $ctag) {
2790                                 $title = qq(<span class="match">$title</span>);
2791                         }
2792                         $cloud->{$ctag}{count} = $ctags_lc{$ctag}->{count};
2793                         $cloud->{$ctag}{ctag} =
2794                                 $cgi->a({-href=>href(project=>undef, ctag=>$ctag)}, $title);
2795                 }
2796         }
2797         return $cloud;
2798 }
2799
2800 sub git_show_project_tagcloud {
2801         my ($cloud, $count) = @_;
2802         if (ref $cloud eq 'HTML::TagCloud') {
2803                 return $cloud->html_and_css($count);
2804         } else {
2805                 my @tags = sort { $cloud->{$a}->{'count'} <=> $cloud->{$b}->{'count'} } keys %$cloud;
2806                 return
2807                         '<div id="htmltagcloud"'.($project ? '' : ' align="center"').'>' .
2808                         join (', ', map {
2809                                 $cloud->{$_}->{'ctag'}
2810                         } splice(@tags, 0, $count)) .
2811                         '</div>';
2812         }
2813 }
2814
2815 sub git_get_project_url_list {
2816         my $path = shift;
2817
2818         $git_dir = "$projectroot/$path";
2819         open my $fd, '<', "$git_dir/cloneurl"
2820                 or return wantarray ?
2821                 @{ config_to_multi(git_get_project_config('url')) } :
2822                    config_to_multi(git_get_project_config('url'));
2823         my @git_project_url_list = map { chomp; $_ } <$fd>;
2824         close $fd;
2825
2826         return wantarray ? @git_project_url_list : \@git_project_url_list;
2827 }
2828
2829 sub git_get_projects_list {
2830         my $filter = shift || '';
2831         my @list;
2832
2833         $filter =~ s/\.git$//;
2834
2835         if (-d $projects_list) {
2836                 # search in directory
2837                 my $dir = $projects_list;
2838                 # remove the trailing "/"
2839                 $dir =~ s!/+$!!;
2840                 my $pfxlen = length("$projects_list");
2841                 my $pfxdepth = ($projects_list =~ tr!/!!);
2842                 # when filtering, search only given subdirectory
2843                 if ($filter) {
2844                         $dir .= "/$filter";
2845                         $dir =~ s!/+$!!;
2846                 }
2847
2848                 File::Find::find({
2849                         follow_fast => 1, # follow symbolic links
2850                         follow_skip => 2, # ignore duplicates
2851                         dangling_symlinks => 0, # ignore dangling symlinks, silently
2852                         wanted => sub {
2853                                 # global variables
2854                                 our $project_maxdepth;
2855                                 our $projectroot;
2856                                 # skip project-list toplevel, if we get it.
2857                                 return if (m!^[/.]$!);
2858                                 # only directories can be git repositories
2859                                 return unless (-d $_);
2860                                 # don't traverse too deep (Find is super slow on os x)
2861                                 # $project_maxdepth excludes depth of $projectroot
2862                                 if (($File::Find::name =~ tr!/!!) - $pfxdepth > $project_maxdepth) {
2863                                         $File::Find::prune = 1;
2864                                         return;
2865                                 }
2866
2867                                 my $path = substr($File::Find::name, $pfxlen + 1);
2868                                 # we check related file in $projectroot
2869                                 if (check_export_ok("$projectroot/$path")) {
2870                                         push @list, { path => $path };
2871                                         $File::Find::prune = 1;
2872                                 }
2873                         },
2874                 }, "$dir");
2875
2876         } elsif (-f $projects_list) {
2877                 # read from file(url-encoded):
2878                 # 'git%2Fgit.git Linus+Torvalds'
2879                 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
2880                 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
2881                 open my $fd, '<', $projects_list or return;
2882         PROJECT:
2883                 while (my $line = <$fd>) {
2884                         chomp $line;
2885                         my ($path, $owner) = split ' ', $line;
2886                         $path = unescape($path);
2887                         $owner = unescape($owner);
2888                         if (!defined $path) {
2889                                 next;
2890                         }
2891                         # if $filter is rpovided, check if $path begins with $filter
2892                         if ($filter && $path !~ m!^\Q$filter\E/!) {
2893                                 next;
2894                         }
2895                         if (check_export_ok("$projectroot/$path")) {
2896                                 my $pr = {
2897                                         path => $path,
2898                                         owner => to_utf8($owner),
2899                                 };
2900                                 push @list, $pr;
2901                         }
2902                 }
2903                 close $fd;
2904         }
2905         return @list;
2906 }
2907
2908 # written with help of Tree::Trie module (Perl Artistic License, GPL compatibile)
2909 # as side effects it sets 'forks' field to list of forks for forked projects
2910 sub filter_forks_from_projects_list {
2911         my $projects = shift;
2912
2913         my %trie; # prefix tree of directories (path components)
2914         # generate trie out of those directories that might contain forks
2915         foreach my $pr (@$projects) {
2916                 my $path = $pr->{'path'};
2917                 $path =~ s/\.git$//;      # forks of 'repo.git' are in 'repo/' directory
2918                 next if ($path =~ m!/$!); # skip non-bare repositories, e.g. 'repo/.git'
2919                 next unless ($path);      # skip '.git' repository: tests, git-instaweb
2920                 next unless (-d "$projectroot/$path"); # containing directory exists
2921                 $pr->{'forks'} = [];      # there can be 0 or more forks of project
2922
2923                 # add to trie
2924                 my @dirs = split('/', $path);
2925                 # walk the trie, until either runs out of components or out of trie
2926                 my $ref = \%trie;
2927                 while (scalar @dirs &&
2928                        exists($ref->{$dirs[0]})) {
2929                         $ref = $ref->{shift @dirs};
2930                 }
2931                 # create rest of trie structure from rest of components
2932                 foreach my $dir (@dirs) {
2933                         $ref = $ref->{$dir} = {};
2934                 }
2935                 # create end marker, store $pr as a data
2936                 $ref->{''} = $pr if (!exists $ref->{''});
2937         }
2938
2939         # filter out forks, by finding shortest prefix match for paths
2940         my @filtered;
2941  PROJECT:
2942         foreach my $pr (@$projects) {
2943                 # trie lookup
2944                 my $ref = \%trie;
2945         DIR:
2946                 foreach my $dir (split('/', $pr->{'path'})) {
2947                         if (exists $ref->{''}) {
2948                                 # found [shortest] prefix, is a fork - skip it
2949                                 push @{$ref->{''}{'forks'}}, $pr;
2950                                 next PROJECT;
2951                         }
2952                         if (!exists $ref->{$dir}) {
2953                                 # not in trie, cannot have prefix, not a fork
2954                                 push @filtered, $pr;
2955                                 next PROJECT;
2956                         }
2957                         # If the dir is there, we just walk one step down the trie.
2958                         $ref = $ref->{$dir};
2959                 }
2960                 # we ran out of trie
2961                 # (shouldn't happen: it's either no match, or end marker)
2962                 push @filtered, $pr;
2963         }
2964
2965         return @filtered;
2966 }
2967
2968 # note: fill_project_list_info must be run first,
2969 # for 'descr_long' and 'ctags' to be filled
2970 sub search_projects_list {
2971         my ($projlist, %opts) = @_;
2972         my $tagfilter  = $opts{'tagfilter'};
2973         my $searchtext = $opts{'searchtext'};
2974
2975         return @$projlist
2976                 unless ($tagfilter || $searchtext);
2977
2978         my @projects;
2979  PROJECT:
2980         foreach my $pr (@$projlist) {
2981
2982                 if ($tagfilter) {
2983                         next unless ref($pr->{'ctags'}) eq 'HASH';
2984                         next unless
2985                                 grep { lc($_) eq lc($tagfilter) } keys %{$pr->{'ctags'}};
2986                 }
2987
2988                 if ($searchtext) {
2989                         next unless
2990                                 $pr->{'path'} =~ /$searchtext/ ||
2991                                 $pr->{'descr_long'} =~ /$searchtext/;
2992                 }
2993
2994                 push @projects, $pr;
2995         }
2996
2997         return @projects;
2998 }
2999
3000 our $gitweb_project_owner = undef;
3001 sub git_get_project_list_from_file {
3002
3003         return if (defined $gitweb_project_owner);
3004
3005         $gitweb_project_owner = {};
3006         # read from file (url-encoded):
3007         # 'git%2Fgit.git Linus+Torvalds'
3008         # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
3009         # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
3010         if (-f $projects_list) {
3011                 open(my $fd, '<', $projects_list);
3012                 while (my $line = <$fd>) {
3013                         chomp $line;
3014                         my ($pr, $ow) = split ' ', $line;
3015                         $pr = unescape($pr);
3016                         $ow = unescape($ow);
3017                         $gitweb_project_owner->{$pr} = to_utf8($ow);
3018                 }
3019                 close $fd;
3020         }
3021 }
3022
3023 sub git_get_project_owner {
3024         my $project = shift;
3025         my $owner;
3026
3027         return undef unless $project;
3028         $git_dir = "$projectroot/$project";
3029
3030         if (!defined $gitweb_project_owner) {
3031                 git_get_project_list_from_file();
3032         }
3033
3034         if (exists $gitweb_project_owner->{$project}) {
3035                 $owner = $gitweb_project_owner->{$project};
3036         }
3037         if (!defined $owner){
3038                 $owner = git_get_project_config('owner');
3039         }
3040         if (!defined $owner) {
3041                 $owner = get_file_owner("$git_dir");
3042         }
3043
3044         return $owner;
3045 }
3046
3047 sub git_get_last_activity {
3048         my ($path) = @_;
3049         my $fd;
3050
3051         $git_dir = "$projectroot/$path";
3052         open($fd, "-|", git_cmd(), 'for-each-ref',
3053              '--format=%(committer)',
3054              '--sort=-committerdate',
3055              '--count=1',
3056              'refs/heads') or return;
3057         my $most_recent = <$fd>;
3058         close $fd or return;
3059         if (defined $most_recent &&
3060             $most_recent =~ / (\d+) [-+][01]\d\d\d$/) {
3061                 my $timestamp = $1;
3062                 my $age = time - $timestamp;
3063                 return ($age, age_string($age));
3064         }
3065         return (undef, undef);
3066 }
3067
3068 # Implementation note: when a single remote is wanted, we cannot use 'git
3069 # remote show -n' because that command always work (assuming it's a remote URL
3070 # if it's not defined), and we cannot use 'git remote show' because that would
3071 # try to make a network roundtrip. So the only way to find if that particular
3072 # remote is defined is to walk the list provided by 'git remote -v' and stop if
3073 # and when we find what we want.
3074 sub git_get_remotes_list {
3075         my $wanted = shift;
3076         my %remotes = ();
3077
3078         open my $fd, '-|' , git_cmd(), 'remote', '-v';
3079         return unless $fd;
3080         while (my $remote = <$fd>) {
3081                 chomp $remote;
3082                 $remote =~ s!\t(.*?)\s+\((\w+)\)$!!;
3083                 next if $wanted and not $remote eq $wanted;
3084                 my ($url, $key) = ($1, $2);
3085
3086                 $remotes{$remote} ||= { 'heads' => () };
3087                 $remotes{$remote}{$key} = $url;
3088         }
3089         close $fd or return;
3090         return wantarray ? %remotes : \%remotes;
3091 }
3092
3093 # Takes a hash of remotes as first parameter and fills it by adding the
3094 # available remote heads for each of the indicated remotes.
3095 sub fill_remote_heads {
3096         my $remotes = shift;
3097         my @heads = map { "remotes/$_" } keys %$remotes;
3098         my @remoteheads = git_get_heads_list(undef, @heads);
3099         foreach my $remote (keys %$remotes) {
3100                 $remotes->{$remote}{'heads'} = [ grep {
3101                         $_->{'name'} =~ s!^$remote/!!
3102                         } @remoteheads ];
3103         }
3104 }
3105
3106 sub git_get_references {
3107         my $type = shift || "";
3108         my %refs;
3109         # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
3110         # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
3111         open my $fd, "-|", git_cmd(), "show-ref", "--dereference",
3112                 ($type ? ("--", "refs/$type") : ()) # use -- <pattern> if $type
3113                 or return;
3114
3115         while (my $line = <$fd>) {
3116                 chomp $line;
3117                 if ($line =~ m!^([0-9a-fA-F]{40})\srefs/($type.*)$!) {
3118                         if (defined $refs{$1}) {
3119                                 push @{$refs{$1}}, $2;
3120                         } else {
3121                                 $refs{$1} = [ $2 ];
3122                         }
3123                 }
3124         }
3125         close $fd or return;
3126         return \%refs;
3127 }
3128
3129 sub git_get_rev_name_tags {
3130         my $hash = shift || return undef;
3131
3132         open my $fd, "-|", git_cmd(), "name-rev", "--tags", $hash
3133                 or return;
3134         my $name_rev = <$fd>;
3135         close $fd;
3136
3137         if ($name_rev =~ m|^$hash tags/(.*)$|) {
3138                 return $1;
3139         } else {
3140                 # catches also '$hash undefined' output
3141                 return undef;
3142         }
3143 }
3144
3145 ## ----------------------------------------------------------------------
3146 ## parse to hash functions
3147
3148 sub parse_date {
3149         my $epoch = shift;
3150         my $tz = shift || "-0000";
3151
3152         my %date;
3153         my @months = ("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec");
3154         my @days = ("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");
3155         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($epoch);
3156         $date{'hour'} = $hour;
3157         $date{'minute'} = $min;
3158         $date{'mday'} = $mday;
3159         $date{'day'} = $days[$wday];
3160         $date{'month'} = $months[$mon];
3161         $date{'rfc2822'}   = sprintf "%s, %d %s %4d %02d:%02d:%02d +0000",
3162                              $days[$wday], $mday, $months[$mon], 1900+$year, $hour ,$min, $sec;
3163         $date{'mday-time'} = sprintf "%d %s %02d:%02d",
3164                              $mday, $months[$mon], $hour ,$min;
3165         $date{'iso-8601'}  = sprintf "%04d-%02d-%02dT%02d:%02d:%02dZ",
3166                              1900+$year, 1+$mon, $mday, $hour ,$min, $sec;
3167
3168         my ($tz_sign, $tz_hour, $tz_min) =
3169                 ($tz =~ m/^([-+])(\d\d)(\d\d)$/);
3170         $tz_sign = ($tz_sign eq '-' ? -1 : +1);
3171         my $local = $epoch + $tz_sign*((($tz_hour*60) + $tz_min)*60);
3172         ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($local);
3173         $date{'hour_local'} = $hour;
3174         $date{'minute_local'} = $min;
3175         $date{'tz_local'} = $tz;
3176         $date{'iso-tz'} = sprintf("%04d-%02d-%02d %02d:%02d:%02d %s",
3177                                   1900+$year, $mon+1, $mday,
3178                                   $hour, $min, $sec, $tz);
3179         return %date;
3180 }
3181
3182 sub parse_tag {
3183         my $tag_id = shift;
3184         my %tag;
3185         my @comment;
3186
3187         open my $fd, "-|", git_cmd(), "cat-file", "tag", $tag_id or return;
3188         $tag{'id'} = $tag_id;
3189         while (my $line = <$fd>) {
3190                 chomp $line;
3191                 if ($line =~ m/^object ([0-9a-fA-F]{40})$/) {
3192                         $tag{'object'} = $1;
3193                 } elsif ($line =~ m/^type (.+)$/) {
3194                         $tag{'type'} = $1;
3195                 } elsif ($line =~ m/^tag (.+)$/) {
3196                         $tag{'name'} = $1;
3197                 } elsif ($line =~ m/^tagger (.*) ([0-9]+) (.*)$/) {
3198                         $tag{'author'} = $1;
3199                         $tag{'author_epoch'} = $2;
3200                         $tag{'author_tz'} = $3;
3201                         if ($tag{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3202                                 $tag{'author_name'}  = $1;
3203                                 $tag{'author_email'} = $2;
3204                         } else {
3205                                 $tag{'author_name'} = $tag{'author'};
3206                         }
3207                 } elsif ($line =~ m/--BEGIN/) {
3208                         push @comment, $line;
3209                         last;
3210                 } elsif ($line eq "") {
3211                         last;
3212                 }
3213         }
3214         push @comment, <$fd>;
3215         $tag{'comment'} = \@comment;
3216         close $fd or return;
3217         if (!defined $tag{'name'}) {
3218                 return
3219         };
3220         return %tag
3221 }
3222
3223 sub parse_commit_text {
3224         my ($commit_text, $withparents) = @_;
3225         my @commit_lines = split '\n', $commit_text;
3226         my %co;
3227
3228         pop @commit_lines; # Remove '\0'
3229
3230         if (! @commit_lines) {
3231                 return;
3232         }
3233
3234         my $header = shift @commit_lines;
3235         if ($header !~ m/^[0-9a-fA-F]{40}/) {
3236                 return;
3237         }
3238         ($co{'id'}, my @parents) = split ' ', $header;
3239         while (my $line = shift @commit_lines) {
3240                 last if $line eq "\n";
3241                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
3242                         $co{'tree'} = $1;
3243                 } elsif ((!defined $withparents) && ($line =~ m/^parent ([0-9a-fA-F]{40})$/)) {
3244                         push @parents, $1;
3245                 } elsif ($line =~ m/^author (.*) ([0-9]+) (.*)$/) {
3246                         $co{'author'} = to_utf8($1);
3247                         $co{'author_epoch'} = $2;
3248                         $co{'author_tz'} = $3;
3249                         if ($co{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3250                                 $co{'author_name'}  = $1;
3251                                 $co{'author_email'} = $2;
3252                         } else {
3253                                 $co{'author_name'} = $co{'author'};
3254                         }
3255                 } elsif ($line =~ m/^committer (.*) ([0-9]+) (.*)$/) {
3256                         $co{'committer'} = to_utf8($1);
3257                         $co{'committer_epoch'} = $2;
3258                         $co{'committer_tz'} = $3;
3259                         if ($co{'committer'} =~ m/^([^<]+) <([^>]*)>/) {
3260                                 $co{'committer_name'}  = $1;
3261                                 $co{'committer_email'} = $2;
3262                         } else {
3263                                 $co{'committer_name'} = $co{'committer'};
3264                         }
3265                 }
3266         }
3267         if (!defined $co{'tree'}) {
3268                 return;
3269         };
3270         $co{'parents'} = \@parents;
3271         $co{'parent'} = $parents[0];
3272
3273         foreach my $title (@commit_lines) {
3274                 $title =~ s/^    //;
3275                 if ($title ne "") {
3276                         $co{'title'} = chop_str($title, 80, 5);
3277                         # remove leading stuff of merges to make the interesting part visible
3278                         if (length($title) > 50) {
3279                                 $title =~ s/^Automatic //;
3280                                 $title =~ s/^merge (of|with) /Merge ... /i;
3281                                 if (length($title) > 50) {
3282                                         $title =~ s/(http|rsync):\/\///;
3283                                 }
3284                                 if (length($title) > 50) {
3285                                         $title =~ s/(master|www|rsync)\.//;
3286                                 }
3287                                 if (length($title) > 50) {
3288                                         $title =~ s/kernel.org:?//;
3289                                 }
3290                                 if (length($title) > 50) {
3291                                         $title =~ s/\/pub\/scm//;
3292                                 }
3293                         }
3294                         $co{'title_short'} = chop_str($title, 50, 5);
3295                         last;
3296                 }
3297         }
3298         if (! defined $co{'title'} || $co{'title'} eq "") {
3299                 $co{'title'} = $co{'title_short'} = '(no commit message)';
3300         }
3301         # remove added spaces
3302         foreach my $line (@commit_lines) {
3303                 $line =~ s/^    //;
3304         }
3305         $co{'comment'} = \@commit_lines;
3306
3307         my $age = time - $co{'committer_epoch'};
3308         $co{'age'} = $age;
3309         $co{'age_string'} = age_string($age);
3310         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($co{'committer_epoch'});
3311         if ($age > 60*60*24*7*2) {
3312                 $co{'age_string_date'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3313                 $co{'age_string_age'} = $co{'age_string'};
3314         } else {
3315                 $co{'age_string_date'} = $co{'age_string'};
3316                 $co{'age_string_age'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3317         }
3318         return %co;
3319 }
3320
3321 sub parse_commit {
3322         my ($commit_id) = @_;
3323         my %co;
3324
3325         local $/ = "\0";
3326
3327         open my $fd, "-|", git_cmd(), "rev-list",
3328                 "--parents",
3329                 "--header",
3330                 "--max-count=1",
3331                 $commit_id,
3332                 "--",
3333                 or die_error(500, "Open git-rev-list failed");
3334         %co = parse_commit_text(<$fd>, 1);
3335         close $fd;
3336
3337         return %co;
3338 }
3339
3340 sub parse_commits {
3341         my ($commit_id, $maxcount, $skip, $filename, @args) = @_;
3342         my @cos;
3343
3344         $maxcount ||= 1;
3345         $skip ||= 0;
3346
3347         local $/ = "\0";
3348
3349         open my $fd, "-|", git_cmd(), "rev-list",
3350                 "--header",
3351                 @args,
3352                 ("--max-count=" . $maxcount),
3353                 ("--skip=" . $skip),
3354                 @extra_options,
3355                 $commit_id,
3356                 "--",
3357                 ($filename ? ($filename) : ())
3358                 or die_error(500, "Open git-rev-list failed");
3359         while (my $line = <$fd>) {
3360                 my %co = parse_commit_text($line);
3361                 push @cos, \%co;
3362         }
3363         close $fd;
3364
3365         return wantarray ? @cos : \@cos;
3366 }
3367
3368 # parse line of git-diff-tree "raw" output
3369 sub parse_difftree_raw_line {
3370         my $line = shift;
3371         my %res;
3372
3373         # ':100644 100644 03b218260e99b78c6df0ed378e59ed9205ccc96d 3b93d5e7cc7f7dd4ebed13a5cc1a4ad976fc94d8 M   ls-files.c'
3374         # ':100644 100644 7f9281985086971d3877aca27704f2aaf9c448ce bc190ebc71bbd923f2b728e505408f5e54bd073a M   rev-tree.c'
3375         if ($line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)([0-9]{0,3})\t(.*)$/) {
3376                 $res{'from_mode'} = $1;
3377                 $res{'to_mode'} = $2;
3378                 $res{'from_id'} = $3;
3379                 $res{'to_id'} = $4;
3380                 $res{'status'} = $5;
3381                 $res{'similarity'} = $6;
3382                 if ($res{'status'} eq 'R' || $res{'status'} eq 'C') { # renamed or copied
3383                         ($res{'from_file'}, $res{'to_file'}) = map { unquote($_) } split("\t", $7);
3384                 } else {
3385                         $res{'from_file'} = $res{'to_file'} = $res{'file'} = unquote($7);
3386                 }
3387         }
3388         # '::100755 100755 100755 60e79ca1b01bc8b057abe17ddab484699a7f5fdb 94067cc5f73388f33722d52ae02f44692bc07490 94067cc5f73388f33722d52ae02f44692bc07490 MR git-gui/git-gui.sh'
3389         # combined diff (for merge commit)
3390         elsif ($line =~ s/^(::+)((?:[0-7]{6} )+)((?:[0-9a-fA-F]{40} )+)([a-zA-Z]+)\t(.*)$//) {
3391                 $res{'nparents'}  = length($1);
3392                 $res{'from_mode'} = [ split(' ', $2) ];
3393                 $res{'to_mode'} = pop @{$res{'from_mode'}};
3394                 $res{'from_id'} = [ split(' ', $3) ];
3395                 $res{'to_id'} = pop @{$res{'from_id'}};
3396                 $res{'status'} = [ split('', $4) ];
3397                 $res{'to_file'} = unquote($5);
3398         }
3399         # 'c512b523472485aef4fff9e57b229d9d243c967f'
3400         elsif ($line =~ m/^([0-9a-fA-F]{40})$/) {
3401                 $res{'commit'} = $1;
3402         }
3403
3404         return wantarray ? %res : \%res;
3405 }
3406
3407 # wrapper: return parsed line of git-diff-tree "raw" output
3408 # (the argument might be raw line, or parsed info)
3409 sub parsed_difftree_line {
3410         my $line_or_ref = shift;
3411
3412         if (ref($line_or_ref) eq "HASH") {
3413                 # pre-parsed (or generated by hand)
3414                 return $line_or_ref;
3415         } else {
3416                 return parse_difftree_raw_line($line_or_ref);
3417         }
3418 }
3419
3420 # parse line of git-ls-tree output
3421 sub parse_ls_tree_line {
3422         my $line = shift;
3423         my %opts = @_;
3424         my %res;
3425
3426         if ($opts{'-l'}) {
3427                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa   16717  panic.c'
3428                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40}) +(-|[0-9]+)\t(.+)$/s;
3429
3430                 $res{'mode'} = $1;
3431                 $res{'type'} = $2;
3432                 $res{'hash'} = $3;
3433                 $res{'size'} = $4;
3434                 if ($opts{'-z'}) {
3435                         $res{'name'} = $5;
3436                 } else {
3437                         $res{'name'} = unquote($5);
3438                 }
3439         } else {
3440                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
3441                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t(.+)$/s;
3442
3443                 $res{'mode'} = $1;
3444                 $res{'type'} = $2;
3445                 $res{'hash'} = $3;
3446                 if ($opts{'-z'}) {
3447                         $res{'name'} = $4;
3448                 } else {
3449                         $res{'name'} = unquote($4);
3450                 }
3451         }
3452
3453         return wantarray ? %res : \%res;
3454 }
3455
3456 # generates _two_ hashes, references to which are passed as 2 and 3 argument
3457 sub parse_from_to_diffinfo {
3458         my ($diffinfo, $from, $to, @parents) = @_;
3459
3460         if ($diffinfo->{'nparents'}) {
3461                 # combined diff
3462                 $from->{'file'} = [];
3463                 $from->{'href'} = [];
3464                 fill_from_file_info($diffinfo, @parents)
3465                         unless exists $diffinfo->{'from_file'};
3466                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
3467                         $from->{'file'}[$i] =
3468                                 defined $diffinfo->{'from_file'}[$i] ?
3469                                         $diffinfo->{'from_file'}[$i] :
3470                                         $diffinfo->{'to_file'};
3471                         if ($diffinfo->{'status'}[$i] ne "A") { # not new (added) file
3472                                 $from->{'href'}[$i] = href(action=>"blob",
3473                                                            hash_base=>$parents[$i],
3474                                                            hash=>$diffinfo->{'from_id'}[$i],
3475                                                            file_name=>$from->{'file'}[$i]);
3476                         } else {
3477                                 $from->{'href'}[$i] = undef;
3478                         }
3479                 }
3480         } else {
3481                 # ordinary (not combined) diff
3482                 $from->{'file'} = $diffinfo->{'from_file'};
3483                 if ($diffinfo->{'status'} ne "A") { # not new (added) file
3484                         $from->{'href'} = href(action=>"blob", hash_base=>$hash_parent,
3485                                                hash=>$diffinfo->{'from_id'},
3486                                                file_name=>$from->{'file'});
3487                 } else {
3488                         delete $from->{'href'};
3489                 }
3490         }
3491
3492         $to->{'file'} = $diffinfo->{'to_file'};
3493         if (!is_deleted($diffinfo)) { # file exists in result
3494                 $to->{'href'} = href(action=>"blob", hash_base=>$hash,
3495                                      hash=>$diffinfo->{'to_id'},
3496                                      file_name=>$to->{'file'});
3497         } else {
3498                 delete $to->{'href'};
3499         }
3500 }
3501
3502 ## ......................................................................
3503 ## parse to array of hashes functions
3504
3505 sub git_get_heads_list {
3506         my ($limit, @classes) = @_;
3507         @classes = ('heads') unless @classes;
3508         my @patterns = map { "refs/$_" } @classes;
3509         my @headslist;
3510
3511         open my $fd, '-|', git_cmd(), 'for-each-ref',
3512                 ($limit ? '--count='.($limit+1) : ()), '--sort=-committerdate',
3513                 '--format=%(objectname) %(refname) %(subject)%00%(committer)',
3514                 @patterns
3515                 or return;
3516         while (my $line = <$fd>) {
3517                 my %ref_item;
3518
3519                 chomp $line;
3520                 my ($refinfo, $committerinfo) = split(/\0/, $line);
3521                 my ($hash, $name, $title) = split(' ', $refinfo, 3);
3522                 my ($committer, $epoch, $tz) =
3523                         ($committerinfo =~ /^(.*) ([0-9]+) (.*)$/);
3524                 $ref_item{'fullname'}  = $name;
3525                 $name =~ s!^refs/(?:head|remote)s/!!;
3526
3527                 $ref_item{'name'}  = $name;
3528                 $ref_item{'id'}    = $hash;
3529                 $ref_item{'title'} = $title || '(no commit message)';
3530                 $ref_item{'epoch'} = $epoch;
3531                 if ($epoch) {
3532                         $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3533                 } else {
3534                         $ref_item{'age'} = "unknown";
3535                 }
3536
3537                 push @headslist, \%ref_item;
3538         }
3539         close $fd;
3540
3541         return wantarray ? @headslist : \@headslist;
3542 }
3543
3544 sub git_get_tags_list {
3545         my $limit = shift;
3546         my @tagslist;
3547
3548         open my $fd, '-|', git_cmd(), 'for-each-ref',
3549                 ($limit ? '--count='.($limit+1) : ()), '--sort=-creatordate',
3550                 '--format=%(objectname) %(objecttype) %(refname) '.
3551                 '%(*objectname) %(*objecttype) %(subject)%00%(creator)',
3552                 'refs/tags'
3553                 or return;
3554         while (my $line = <$fd>) {
3555                 my %ref_item;
3556
3557                 chomp $line;
3558                 my ($refinfo, $creatorinfo) = split(/\0/, $line);
3559                 my ($id, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
3560                 my ($creator, $epoch, $tz) =
3561                         ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
3562                 $ref_item{'fullname'} = $name;
3563                 $name =~ s!^refs/tags/!!;
3564
3565                 $ref_item{'type'} = $type;
3566                 $ref_item{'id'} = $id;
3567                 $ref_item{'name'} = $name;
3568                 if ($type eq "tag") {
3569                         $ref_item{'subject'} = $title;
3570                         $ref_item{'reftype'} = $reftype;
3571                         $ref_item{'refid'}   = $refid;
3572                 } else {
3573                         $ref_item{'reftype'} = $type;
3574                         $ref_item{'refid'}   = $id;
3575                 }
3576
3577                 if ($type eq "tag" || $type eq "commit") {
3578                         $ref_item{'epoch'} = $epoch;
3579                         if ($epoch) {
3580                                 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3581                         } else {
3582                                 $ref_item{'age'} = "unknown";
3583                         }
3584                 }
3585
3586                 push @tagslist, \%ref_item;
3587         }
3588         close $fd;
3589
3590         return wantarray ? @tagslist : \@tagslist;
3591 }
3592
3593 ## ----------------------------------------------------------------------
3594 ## filesystem-related functions
3595
3596 sub get_file_owner {
3597         my $path = shift;
3598
3599         my ($dev, $ino, $mode, $nlink, $st_uid, $st_gid, $rdev, $size) = stat($path);
3600         my ($name, $passwd, $uid, $gid, $quota, $comment, $gcos, $dir, $shell) = getpwuid($st_uid);
3601         if (!defined $gcos) {
3602                 return undef;
3603         }
3604         my $owner = $gcos;
3605         $owner =~ s/[,;].*$//;
3606         return to_utf8($owner);
3607 }
3608
3609 # assume that file exists
3610 sub insert_file {
3611         my $filename = shift;
3612
3613         open my $fd, '<', $filename;
3614         print map { to_utf8($_) } <$fd>;
3615         close $fd;
3616 }
3617
3618 ## ......................................................................
3619 ## mimetype related functions
3620
3621 sub mimetype_guess_file {
3622         my $filename = shift;
3623         my $mimemap = shift;
3624         -r $mimemap or return undef;
3625
3626         my %mimemap;
3627         open(my $mh, '<', $mimemap) or return undef;
3628         while (<$mh>) {
3629                 next if m/^#/; # skip comments
3630                 my ($mimetype, @exts) = split(/\s+/);
3631                 foreach my $ext (@exts) {
3632                         $mimemap{$ext} = $mimetype;
3633                 }
3634         }
3635         close($mh);
3636
3637         $filename =~ /\.([^.]*)$/;
3638         return $mimemap{$1};
3639 }
3640
3641 sub mimetype_guess {
3642         my $filename = shift;
3643         my $mime;
3644         $filename =~ /\./ or return undef;
3645
3646         if ($mimetypes_file) {
3647                 my $file = $mimetypes_file;
3648                 if ($file !~ m!^/!) { # if it is relative path
3649                         # it is relative to project
3650                         $file = "$projectroot/$project/$file";
3651                 }
3652                 $mime = mimetype_guess_file($filename, $file);
3653         }
3654         $mime ||= mimetype_guess_file($filename, '/etc/mime.types');
3655         return $mime;
3656 }
3657
3658 sub blob_mimetype {
3659         my $fd = shift;
3660         my $filename = shift;
3661
3662         if ($filename) {
3663                 my $mime = mimetype_guess($filename);
3664                 $mime and return $mime;
3665         }
3666
3667         # just in case
3668         return $default_blob_plain_mimetype unless $fd;
3669
3670         if (-T $fd) {
3671                 return 'text/plain';
3672         } elsif (! $filename) {
3673                 return 'application/octet-stream';
3674         } elsif ($filename =~ m/\.png$/i) {
3675                 return 'image/png';
3676         } elsif ($filename =~ m/\.gif$/i) {
3677                 return 'image/gif';
3678         } elsif ($filename =~ m/\.jpe?g$/i) {
3679                 return 'image/jpeg';
3680         } else {
3681                 return 'application/octet-stream';
3682         }
3683 }
3684
3685 sub blob_contenttype {
3686         my ($fd, $file_name, $type) = @_;
3687
3688         $type ||= blob_mimetype($fd, $file_name);
3689         if ($type eq 'text/plain' && defined $default_text_plain_charset) {
3690                 $type .= "; charset=$default_text_plain_charset";
3691         }
3692
3693         return $type;
3694 }
3695
3696 # guess file syntax for syntax highlighting; return undef if no highlighting
3697 # the name of syntax can (in the future) depend on syntax highlighter used
3698 sub guess_file_syntax {
3699         my ($highlight, $mimetype, $file_name) = @_;
3700         return undef unless ($highlight && defined $file_name);
3701         my $basename = basename($file_name, '.in');
3702         return $highlight_basename{$basename}
3703                 if exists $highlight_basename{$basename};
3704
3705         $basename =~ /\.([^.]*)$/;
3706         my $ext = $1 or return undef;
3707         return $highlight_ext{$ext}
3708                 if exists $highlight_ext{$ext};
3709
3710         return undef;
3711 }
3712
3713 # run highlighter and return FD of its output,
3714 # or return original FD if no highlighting
3715 sub run_highlighter {
3716         my ($fd, $highlight, $syntax) = @_;
3717         return $fd unless ($highlight && defined $syntax);
3718
3719         close $fd;
3720         open $fd, quote_command(git_cmd(), "cat-file", "blob", $hash)." | ".
3721                   quote_command($highlight_bin).
3722                   " --replace-tabs=8 --fragment --syntax $syntax |"
3723                 or die_error(500, "Couldn't open file or run syntax highlighter");
3724         return $fd;
3725 }
3726
3727 ## ======================================================================
3728 ## functions printing HTML: header, footer, error page
3729
3730 sub get_page_title {
3731         my $title = to_utf8($site_name);
3732
3733         return $title unless (defined $project);
3734         $title .= " - " . to_utf8($project);
3735
3736         return $title unless (defined $action);
3737         $title .= "/$action"; # $action is US-ASCII (7bit ASCII)
3738
3739         return $title unless (defined $file_name);
3740         $title .= " - " . esc_path($file_name);
3741         if ($action eq "tree" && $file_name !~ m|/$|) {
3742                 $title .= "/";
3743         }
3744
3745         return $title;
3746 }
3747
3748 sub get_content_type_html {
3749         # require explicit support from the UA if we are to send the page as
3750         # 'application/xhtml+xml', otherwise send it as plain old 'text/html'.
3751         # we have to do this because MSIE sometimes globs '*/*', pretending to
3752         # support xhtml+xml but choking when it gets what it asked for.
3753         if (defined $cgi->http('HTTP_ACCEPT') &&
3754             $cgi->http('HTTP_ACCEPT') =~ m/(,|;|\s|^)application\/xhtml\+xml(,|;|\s|$)/ &&
3755             $cgi->Accept('application/xhtml+xml') != 0) {
3756                 return 'application/xhtml+xml';
3757         } else {
3758                 return 'text/html';
3759         }
3760 }
3761
3762 sub print_feed_meta {
3763         if (defined $project) {
3764                 my %href_params = get_feed_info();
3765                 if (!exists $href_params{'-title'}) {
3766                         $href_params{'-title'} = 'log';
3767                 }
3768
3769                 foreach my $format (qw(RSS Atom)) {
3770                         my $type = lc($format);
3771                         my %link_attr = (
3772                                 '-rel' => 'alternate',
3773                                 '-title' => esc_attr("$project - $href_params{'-title'} - $format feed"),
3774                                 '-type' => "application/$type+xml"
3775                         );
3776
3777                         $href_params{'action'} = $type;
3778                         $link_attr{'-href'} = href(%href_params);
3779                         print "<link ".
3780                               "rel=\"$link_attr{'-rel'}\" ".
3781                               "title=\"$link_attr{'-title'}\" ".
3782                               "href=\"$link_attr{'-href'}\" ".
3783                               "type=\"$link_attr{'-type'}\" ".
3784                               "/>\n";
3785
3786                         $href_params{'extra_options'} = '--no-merges';
3787                         $link_attr{'-href'} = href(%href_params);
3788                         $link_attr{'-title'} .= ' (no merges)';
3789                         print "<link ".
3790                               "rel=\"$link_attr{'-rel'}\" ".
3791                               "title=\"$link_attr{'-title'}\" ".
3792                               "href=\"$link_attr{'-href'}\" ".
3793                               "type=\"$link_attr{'-type'}\" ".
3794                               "/>\n";
3795                 }
3796
3797         } else {
3798                 printf('<link rel="alternate" title="%s projects list" '.
3799                        'href="%s" type="text/plain; charset=utf-8" />'."\n",
3800                        esc_attr($site_name), href(project=>undef, action=>"project_index"));
3801                 printf('<link rel="alternate" title="%s projects feeds" '.
3802                        'href="%s" type="text/x-opml" />'."\n",
3803                        esc_attr($site_name), href(project=>undef, action=>"opml"));
3804         }
3805 }
3806
3807 sub print_header_links {
3808         my $status = shift;
3809
3810         # print out each stylesheet that exist, providing backwards capability
3811         # for those people who defined $stylesheet in a config file
3812         if (defined $stylesheet) {
3813                 print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
3814         } else {
3815                 foreach my $stylesheet (@stylesheets) {
3816                         next unless $stylesheet;
3817                         print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
3818                 }
3819         }
3820         print_feed_meta()
3821                 if ($status eq '200 OK');
3822         if (defined $favicon) {
3823                 print qq(<link rel="shortcut icon" href=").esc_url($favicon).qq(" type="image/png" />\n);
3824         }
3825 }
3826
3827 sub print_nav_breadcrumbs {
3828         my %opts = @_;
3829
3830         print $cgi->a({-href => esc_url($home_link)}, $home_link_str) . " / ";
3831         if (defined $project) {
3832                 print $cgi->a({-href => href(action=>"summary")}, esc_html($project));
3833                 if (defined $action) {
3834                         my $action_print = $action ;
3835                         if (defined $opts{-action_extra}) {
3836                                 $action_print = $cgi->a({-href => href(action=>$action)},
3837                                         $action);
3838                         }
3839                         print " / $action_print";
3840                 }
3841                 if (defined $opts{-action_extra}) {
3842                         print " / $opts{-action_extra}";
3843                 }
3844                 print "\n";
3845         }
3846 }
3847
3848 sub print_search_form {
3849         if (!defined $searchtext) {
3850                 $searchtext = "";
3851         }
3852         my $search_hash;
3853         if (defined $hash_base) {
3854                 $search_hash = $hash_base;
3855         } elsif (defined $hash) {
3856                 $search_hash = $hash;
3857         } else {
3858                 $search_hash = "HEAD";
3859         }
3860         my $action = $my_uri;
3861         my $use_pathinfo = gitweb_check_feature('pathinfo');
3862         if ($use_pathinfo) {
3863                 $action .= "/".esc_url($project);
3864         }
3865         print $cgi->startform(-method => "get", -action => $action) .
3866               "<div class=\"search\">\n" .
3867               (!$use_pathinfo &&
3868               $cgi->input({-name=>"p", -value=>$project, -type=>"hidden"}) . "\n") .
3869               $cgi->input({-name=>"a", -value=>"search", -type=>"hidden"}) . "\n" .
3870               $cgi->input({-name=>"h", -value=>$search_hash, -type=>"hidden"}) . "\n" .
3871               $cgi->popup_menu(-name => 'st', -default => 'commit',
3872                                -values => ['commit', 'grep', 'author', 'committer', 'pickaxe']) .
3873               $cgi->sup($cgi->a({-href => href(action=>"search_help")}, "?")) .
3874               " search:\n",
3875               $cgi->textfield(-name => "s", -value => $searchtext) . "\n" .
3876               "<span title=\"Extended regular expression\">" .
3877               $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
3878                              -checked => $search_use_regexp) .
3879               "</span>" .
3880               "</div>" .
3881               $cgi->end_form() . "\n";
3882 }
3883
3884 sub git_header_html {
3885         my $status = shift || "200 OK";
3886         my $expires = shift;
3887         my %opts = @_;
3888
3889         my $title = get_page_title();
3890         my $content_type = get_content_type_html();
3891         print $cgi->header(-type=>$content_type, -charset => 'utf-8',
3892                            -status=> $status, -expires => $expires)
3893                 unless ($opts{'-no_http_header'});
3894         my $mod_perl_version = $ENV{'MOD_PERL'} ? " $ENV{'MOD_PERL'}" : '';
3895         print <<EOF;
3896 <?xml version="1.0" encoding="utf-8"?>
3897 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
3898 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en-US" lang="en-US">
3899 <!-- git web interface version $version, (C) 2005-2006, Kay Sievers <kay.sievers\@vrfy.org>, Christian Gierke -->
3900 <!-- git core binaries version $git_version -->
3901 <head>
3902 <meta http-equiv="content-type" content="$content_type; charset=utf-8"/>
3903 <meta name="generator" content="gitweb/$version git/$git_version$mod_perl_version"/>
3904 <meta name="robots" content="index, nofollow"/>
3905 <title>$title</title>
3906 EOF
3907         # the stylesheet, favicon etc urls won't work correctly with path_info
3908         # unless we set the appropriate base URL
3909         if ($ENV{'PATH_INFO'}) {
3910                 print "<base href=\"".esc_url($base_url)."\" />\n";
3911         }
3912         print_header_links($status);
3913
3914         if (defined $site_html_head_string) {
3915                 print to_utf8($site_html_head_string);
3916         }
3917
3918         print "</head>\n" .
3919               "<body>\n";
3920
3921         if (defined $site_header && -f $site_header) {
3922                 insert_file($site_header);
3923         }
3924
3925         print "<div class=\"page_header\">\n";
3926         if (defined $logo) {
3927                 print $cgi->a({-href => esc_url($logo_url),
3928                                -title => $logo_label},
3929                               $cgi->img({-src => esc_url($logo),
3930                                          -width => 72, -height => 27,
3931                                          -alt => "git",
3932                                          -class => "logo"}));
3933         }
3934         print_nav_breadcrumbs(%opts);
3935         print "</div>\n";
3936
3937         my $have_search = gitweb_check_feature('search');
3938         if (defined $project && $have_search) {
3939                 print_search_form();
3940         }
3941 }
3942
3943 sub git_footer_html {
3944         my $feed_class = 'rss_logo';
3945
3946         print "<div class=\"page_footer\">\n";
3947         if (defined $project) {
3948                 my $descr = git_get_project_description($project);
3949                 if (defined $descr) {
3950                         print "<div class=\"page_footer_text\">" . esc_html($descr) . "</div>\n";
3951                 }
3952
3953                 my %href_params = get_feed_info();
3954                 if (!%href_params) {
3955                         $feed_class .= ' generic';
3956                 }
3957                 $href_params{'-title'} ||= 'log';
3958
3959                 foreach my $format (qw(RSS Atom)) {
3960                         $href_params{'action'} = lc($format);
3961                         print $cgi->a({-href => href(%href_params),
3962                                       -title => "$href_params{'-title'} $format feed",
3963                                       -class => $feed_class}, $format)."\n";
3964                 }
3965
3966         } else {
3967                 print $cgi->a({-href => href(project=>undef, action=>"opml"),
3968                               -class => $feed_class}, "OPML") . " ";
3969                 print $cgi->a({-href => href(project=>undef, action=>"project_index"),
3970                               -class => $feed_class}, "TXT") . "\n";
3971         }
3972         print "</div>\n"; # class="page_footer"
3973
3974         if (defined $t0 && gitweb_check_feature('timed')) {
3975                 print "<div id=\"generating_info\">\n";
3976                 print 'This page took '.
3977                       '<span id="generating_time" class="time_span">'.
3978                       tv_interval($t0, [ gettimeofday() ]).
3979                       ' seconds </span>'.
3980                       ' and '.
3981                       '<span id="generating_cmd">'.
3982                       $number_of_git_cmds.
3983                       '</span> git commands '.
3984                       " to generate.\n";
3985                 print "</div>\n"; # class="page_footer"
3986         }
3987
3988         if (defined $site_footer && -f $site_footer) {
3989                 insert_file($site_footer);
3990         }
3991
3992         print qq!<script type="text/javascript" src="!.esc_url($javascript).qq!"></script>\n!;
3993         if (defined $action &&
3994             $action eq 'blame_incremental') {
3995                 print qq!<script type="text/javascript">\n!.
3996                       qq!startBlame("!. href(action=>"blame_data", -replay=>1) .qq!",\n!.
3997                       qq!           "!. href() .qq!");\n!.
3998                       qq!</script>\n!;
3999         } else {
4000                 my ($jstimezone, $tz_cookie, $datetime_class) =
4001                         gitweb_get_feature('javascript-timezone');
4002
4003                 print qq!<script type="text/javascript">\n!.
4004                       qq!window.onload = function () {\n!;
4005                 if (gitweb_check_feature('javascript-actions')) {
4006                         print qq!       fixLinks();\n!;
4007                 }
4008                 if ($jstimezone && $tz_cookie && $datetime_class) {
4009                         print qq!       var tz_cookie = { name: '$tz_cookie', expires: 14, path: '/' };\n!. # in days
4010                               qq!       onloadTZSetup('$jstimezone', tz_cookie, '$datetime_class');\n!;
4011                 }
4012                 print qq!};\n!.
4013                       qq!</script>\n!;
4014         }
4015
4016         print "</body>\n" .
4017               "</html>";
4018 }
4019
4020 # die_error(<http_status_code>, <error_message>[, <detailed_html_description>])
4021 # Example: die_error(404, 'Hash not found')
4022 # By convention, use the following status codes (as defined in RFC 2616):
4023 # 400: Invalid or missing CGI parameters, or
4024 #      requested object exists but has wrong type.
4025 # 403: Requested feature (like "pickaxe" or "snapshot") not enabled on
4026 #      this server or project.
4027 # 404: Requested object/revision/project doesn't exist.
4028 # 500: The server isn't configured properly, or
4029 #      an internal error occurred (e.g. failed assertions caused by bugs), or
4030 #      an unknown error occurred (e.g. the git binary died unexpectedly).
4031 # 503: The server is currently unavailable (because it is overloaded,
4032 #      or down for maintenance).  Generally, this is a temporary state.
4033 sub die_error {
4034         my $status = shift || 500;
4035         my $error = esc_html(shift) || "Internal Server Error";
4036         my $extra = shift;
4037         my %opts = @_;
4038
4039         my %http_responses = (
4040                 400 => '400 Bad Request',
4041                 403 => '403 Forbidden',
4042                 404 => '404 Not Found',
4043                 500 => '500 Internal Server Error',
4044                 503 => '503 Service Unavailable',
4045         );
4046         git_header_html($http_responses{$status}, undef, %opts);
4047         print <<EOF;
4048 <div class="page_body">
4049 <br /><br />
4050 $status - $error
4051 <br />
4052 EOF
4053         if (defined $extra) {
4054                 print "<hr />\n" .
4055                       "$extra\n";
4056         }
4057         print "</div>\n";
4058
4059         git_footer_html();
4060         goto DONE_GITWEB
4061                 unless ($opts{'-error_handler'});
4062 }
4063
4064 ## ----------------------------------------------------------------------
4065 ## functions printing or outputting HTML: navigation
4066
4067 sub git_print_page_nav {
4068         my ($current, $suppress, $head, $treehead, $treebase, $extra) = @_;
4069         $extra = '' if !defined $extra; # pager or formats
4070
4071         my @navs = qw(summary shortlog log commit commitdiff tree);
4072         if ($suppress) {
4073                 @navs = grep { $_ ne $suppress } @navs;
4074         }
4075
4076         my %arg = map { $_ => {action=>$_} } @navs;
4077         if (defined $head) {
4078                 for (qw(commit commitdiff)) {
4079                         $arg{$_}{'hash'} = $head;
4080                 }
4081                 if ($current =~ m/^(tree | log | shortlog | commit | commitdiff | search)$/x) {
4082                         for (qw(shortlog log)) {
4083                                 $arg{$_}{'hash'} = $head;
4084                         }
4085                 }
4086         }
4087
4088         $arg{'tree'}{'hash'} = $treehead if defined $treehead;
4089         $arg{'tree'}{'hash_base'} = $treebase if defined $treebase;
4090
4091         my @actions = gitweb_get_feature('actions');
4092         my %repl = (
4093                 '%' => '%',
4094                 'n' => $project,         # project name
4095                 'f' => $git_dir,         # project path within filesystem
4096                 'h' => $treehead || '',  # current hash ('h' parameter)
4097                 'b' => $treebase || '',  # hash base ('hb' parameter)
4098         );
4099         while (@actions) {
4100                 my ($label, $link, $pos) = splice(@actions,0,3);
4101                 # insert
4102                 @navs = map { $_ eq $pos ? ($_, $label) : $_ } @navs;
4103                 # munch munch
4104                 $link =~ s/%([%nfhb])/$repl{$1}/g;
4105                 $arg{$label}{'_href'} = $link;
4106         }
4107
4108         print "<div class=\"page_nav\">\n" .
4109                 (join " | ",
4110                  map { $_ eq $current ?
4111                        $_ : $cgi->a({-href => ($arg{$_}{_href} ? $arg{$_}{_href} : href(%{$arg{$_}}))}, "$_")
4112                  } @navs);
4113         print "<br/>\n$extra<br/>\n" .
4114               "</div>\n";
4115 }
4116
4117 # returns a submenu for the nagivation of the refs views (tags, heads,
4118 # remotes) with the current view disabled and the remotes view only
4119 # available if the feature is enabled
4120 sub format_ref_views {
4121         my ($current) = @_;
4122         my @ref_views = qw{tags heads};
4123         push @ref_views, 'remotes' if gitweb_check_feature('remote_heads');
4124         return join " | ", map {
4125                 $_ eq $current ? $_ :
4126                 $cgi->a({-href => href(action=>$_)}, $_)
4127         } @ref_views
4128 }
4129
4130 sub format_paging_nav {
4131         my ($action, $page, $has_next_link) = @_;
4132         my $paging_nav;
4133
4134
4135         if ($page > 0) {
4136                 $paging_nav .=
4137                         $cgi->a({-href => href(-replay=>1, page=>undef)}, "first") .
4138                         " &sdot; " .
4139                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
4140                                  -accesskey => "p", -title => "Alt-p"}, "prev");
4141         } else {
4142                 $paging_nav .= "first &sdot; prev";
4143         }
4144
4145         if ($has_next_link) {
4146                 $paging_nav .= " &sdot; " .
4147                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
4148                                  -accesskey => "n", -title => "Alt-n"}, "next");
4149         } else {
4150                 $paging_nav .= " &sdot; next";
4151         }
4152
4153         return $paging_nav;
4154 }
4155
4156 ## ......................................................................
4157 ## functions printing or outputting HTML: div
4158
4159 sub git_print_header_div {
4160         my ($action, $title, $hash, $hash_base) = @_;
4161         my %args = ();
4162
4163         $args{'action'} = $action;
4164         $args{'hash'} = $hash if $hash;
4165         $args{'hash_base'} = $hash_base if $hash_base;
4166
4167         print "<div class=\"header\">\n" .
4168               $cgi->a({-href => href(%args), -class => "title"},
4169               $title ? $title : $action) .
4170               "\n</div>\n";
4171 }
4172
4173 sub format_repo_url {
4174         my ($name, $url) = @_;
4175         return "<tr class=\"metadata_url\"><td>$name</td><td>$url</td></tr>\n";
4176 }
4177
4178 # Group output by placing it in a DIV element and adding a header.
4179 # Options for start_div() can be provided by passing a hash reference as the
4180 # first parameter to the function.
4181 # Options to git_print_header_div() can be provided by passing an array
4182 # reference. This must follow the options to start_div if they are present.
4183 # The content can be a scalar, which is output as-is, a scalar reference, which
4184 # is output after html escaping, an IO handle passed either as *handle or
4185 # *handle{IO}, or a function reference. In the latter case all following
4186 # parameters will be taken as argument to the content function call.
4187 sub git_print_section {
4188         my ($div_args, $header_args, $content);
4189         my $arg = shift;
4190         if (ref($arg) eq 'HASH') {
4191                 $div_args = $arg;
4192                 $arg = shift;
4193         }
4194         if (ref($arg) eq 'ARRAY') {
4195                 $header_args = $arg;
4196                 $arg = shift;
4197         }
4198         $content = $arg;
4199
4200         print $cgi->start_div($div_args);
4201         git_print_header_div(@$header_args);
4202
4203         if (ref($content) eq 'CODE') {
4204                 $content->(@_);
4205         } elsif (ref($content) eq 'SCALAR') {
4206                 print esc_html($$content);
4207         } elsif (ref($content) eq 'GLOB' or ref($content) eq 'IO::Handle') {
4208                 print <$content>;
4209         } elsif (!ref($content) && defined($content)) {
4210                 print $content;
4211         }
4212
4213         print $cgi->end_div;
4214 }
4215
4216 sub format_timestamp_html {
4217         my $date = shift;
4218         my $strtime = $date->{'rfc2822'};
4219
4220         my (undef, undef, $datetime_class) =
4221                 gitweb_get_feature('javascript-timezone');
4222         if ($datetime_class) {
4223                 $strtime = qq!<span class="$datetime_class">$strtime</span>!;
4224         }
4225
4226         my $localtime_format = '(%02d:%02d %s)';
4227         if ($date->{'hour_local'} < 6) {
4228                 $localtime_format = '(<span class="atnight">%02d:%02d</span> %s)';
4229         }
4230         $strtime .= ' ' .
4231                     sprintf($localtime_format,
4232                             $date->{'hour_local'}, $date->{'minute_local'}, $date->{'tz_local'});
4233
4234         return $strtime;
4235 }
4236
4237 # Outputs the author name and date in long form
4238 sub git_print_authorship {
4239         my $co = shift;
4240         my %opts = @_;
4241         my $tag = $opts{-tag} || 'div';
4242         my $author = $co->{'author_name'};
4243
4244         my %ad = parse_date($co->{'author_epoch'}, $co->{'author_tz'});
4245         print "<$tag class=\"author_date\">" .
4246               format_search_author($author, "author", esc_html($author)) .
4247               " [".format_timestamp_html(\%ad)."]".
4248               git_get_avatar($co->{'author_email'}, -pad_before => 1) .
4249               "</$tag>\n";
4250 }
4251
4252 # Outputs table rows containing the full author or committer information,
4253 # in the format expected for 'commit' view (& similar).
4254 # Parameters are a commit hash reference, followed by the list of people
4255 # to output information for. If the list is empty it defaults to both
4256 # author and committer.
4257 sub git_print_authorship_rows {
4258         my $co = shift;
4259         # too bad we can't use @people = @_ || ('author', 'committer')
4260         my @people = @_;
4261         @people = ('author', 'committer') unless @people;
4262         foreach my $who (@people) {
4263                 my %wd = parse_date($co->{"${who}_epoch"}, $co->{"${who}_tz"});
4264                 print "<tr><td>$who</td><td>" .
4265                       format_search_author($co->{"${who}_name"}, $who,
4266                                            esc_html($co->{"${who}_name"})) . " " .
4267                       format_search_author($co->{"${who}_email"}, $who,
4268                                            esc_html("<" . $co->{"${who}_email"} . ">")) .
4269                       "</td><td rowspan=\"2\">" .
4270                       git_get_avatar($co->{"${who}_email"}, -size => 'double') .
4271                       "</td></tr>\n" .
4272                       "<tr>" .
4273                       "<td></td><td>" .
4274                       format_timestamp_html(\%wd) .
4275                       "</td>" .
4276                       "</tr>\n";
4277         }
4278 }
4279
4280 sub git_print_page_path {
4281         my $name = shift;
4282         my $type = shift;
4283         my $hb = shift;
4284
4285
4286         print "<div class=\"page_path\">";
4287         print $cgi->a({-href => href(action=>"tree", hash_base=>$hb),
4288                       -title => 'tree root'}, to_utf8("[$project]"));
4289         print " / ";
4290         if (defined $name) {
4291                 my @dirname = split '/', $name;
4292                 my $basename = pop @dirname;
4293                 my $fullname = '';
4294
4295                 foreach my $dir (@dirname) {
4296                         $fullname .= ($fullname ? '/' : '') . $dir;
4297                         print $cgi->a({-href => href(action=>"tree", file_name=>$fullname,
4298                                                      hash_base=>$hb),
4299                                       -title => $fullname}, esc_path($dir));
4300                         print " / ";
4301                 }
4302                 if (defined $type && $type eq 'blob') {
4303                         print $cgi->a({-href => href(action=>"blob_plain", file_name=>$file_name,
4304                                                      hash_base=>$hb),
4305                                       -title => $name}, esc_path($basename));
4306                 } elsif (defined $type && $type eq 'tree') {
4307                         print $cgi->a({-href => href(action=>"tree", file_name=>$file_name,
4308                                                      hash_base=>$hb),
4309                                       -title => $name}, esc_path($basename));
4310                         print " / ";
4311                 } else {
4312                         print esc_path($basename);
4313                 }
4314         }
4315         print "<br/></div>\n";
4316 }
4317
4318 sub git_print_log {
4319         my $log = shift;
4320         my %opts = @_;
4321
4322         if ($opts{'-remove_title'}) {
4323                 # remove title, i.e. first line of log
4324                 shift @$log;
4325         }
4326         # remove leading empty lines
4327         while (defined $log->[0] && $log->[0] eq "") {
4328                 shift @$log;
4329         }
4330
4331         # print log
4332         my $signoff = 0;
4333         my $empty = 0;
4334         foreach my $line (@$log) {
4335                 if ($line =~ m/^ *(signed[ \-]off[ \-]by[ :]|acked[ \-]by[ :]|cc[ :])/i) {
4336                         $signoff = 1;
4337                         $empty = 0;
4338                         if (! $opts{'-remove_signoff'}) {
4339                                 print "<span class=\"signoff\">" . esc_html($line) . "</span><br/>\n";
4340                                 next;
4341                         } else {
4342                                 # remove signoff lines
4343                                 next;
4344                         }
4345                 } else {
4346                         $signoff = 0;
4347                 }
4348
4349                 # print only one empty line
4350                 # do not print empty line after signoff
4351                 if ($line eq "") {
4352                         next if ($empty || $signoff);
4353                         $empty = 1;
4354                 } else {
4355                         $empty = 0;
4356                 }
4357
4358                 print format_log_line_html($line) . "<br/>\n";
4359         }
4360
4361         if ($opts{'-final_empty_line'}) {
4362                 # end with single empty line
4363                 print "<br/>\n" unless $empty;
4364         }
4365 }
4366
4367 # return link target (what link points to)
4368 sub git_get_link_target {
4369         my $hash = shift;
4370         my $link_target;
4371
4372         # read link
4373         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
4374                 or return;
4375         {
4376                 local $/ = undef;
4377                 $link_target = <$fd>;
4378         }
4379         close $fd
4380                 or return;
4381
4382         return $link_target;
4383 }
4384
4385 # given link target, and the directory (basedir) the link is in,
4386 # return target of link relative to top directory (top tree);
4387 # return undef if it is not possible (including absolute links).
4388 sub normalize_link_target {
4389         my ($link_target, $basedir) = @_;
4390
4391         # absolute symlinks (beginning with '/') cannot be normalized
4392         return if (substr($link_target, 0, 1) eq '/');
4393
4394         # normalize link target to path from top (root) tree (dir)
4395         my $path;
4396         if ($basedir) {
4397                 $path = $basedir . '/' . $link_target;
4398         } else {
4399                 # we are in top (root) tree (dir)
4400                 $path = $link_target;
4401         }
4402
4403         # remove //, /./, and /../
4404         my @path_parts;
4405         foreach my $part (split('/', $path)) {
4406                 # discard '.' and ''
4407                 next if (!$part || $part eq '.');
4408                 # handle '..'
4409                 if ($part eq '..') {
4410                         if (@path_parts) {
4411                                 pop @path_parts;
4412                         } else {
4413                                 # link leads outside repository (outside top dir)
4414                                 return;
4415                         }
4416                 } else {
4417                         push @path_parts, $part;
4418                 }
4419         }
4420         $path = join('/', @path_parts);
4421
4422         return $path;
4423 }
4424
4425 # print tree entry (row of git_tree), but without encompassing <tr> element
4426 sub git_print_tree_entry {
4427         my ($t, $basedir, $hash_base, $have_blame) = @_;
4428
4429         my %base_key = ();
4430         $base_key{'hash_base'} = $hash_base if defined $hash_base;
4431
4432         # The format of a table row is: mode list link.  Where mode is
4433         # the mode of the entry, list is the name of the entry, an href,
4434         # and link is the action links of the entry.
4435
4436         print "<td class=\"mode\">" . mode_str($t->{'mode'}) . "</td>\n";
4437         if (exists $t->{'size'}) {
4438                 print "<td class=\"size\">$t->{'size'}</td>\n";
4439         }
4440         if ($t->{'type'} eq "blob") {
4441                 print "<td class=\"list\">" .
4442                         $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4443                                                file_name=>"$basedir$t->{'name'}", %base_key),
4444                                 -class => "list"}, esc_path($t->{'name'}));
4445                 if (S_ISLNK(oct $t->{'mode'})) {
4446                         my $link_target = git_get_link_target($t->{'hash'});
4447                         if ($link_target) {
4448                                 my $norm_target = normalize_link_target($link_target, $basedir);
4449                                 if (defined $norm_target) {
4450                                         print " -> " .
4451                                               $cgi->a({-href => href(action=>"object", hash_base=>$hash_base,
4452                                                                      file_name=>$norm_target),
4453                                                        -title => $norm_target}, esc_path($link_target));
4454                                 } else {
4455                                         print " -> " . esc_path($link_target);
4456                                 }
4457                         }
4458                 }
4459                 print "</td>\n";
4460                 print "<td class=\"link\">";
4461                 print $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4462                                              file_name=>"$basedir$t->{'name'}", %base_key)},
4463                               "blob");
4464                 if ($have_blame) {
4465                         print " | " .
4466                               $cgi->a({-href => href(action=>"blame", hash=>$t->{'hash'},
4467                                                      file_name=>"$basedir$t->{'name'}", %base_key)},
4468                                       "blame");
4469                 }
4470                 if (defined $hash_base) {
4471                         print " | " .
4472                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4473                                                      hash=>$t->{'hash'}, file_name=>"$basedir$t->{'name'}")},
4474                                       "history");
4475                 }
4476                 print " | " .
4477                         $cgi->a({-href => href(action=>"blob_plain", hash_base=>$hash_base,
4478                                                file_name=>"$basedir$t->{'name'}")},
4479                                 "raw");
4480                 print "</td>\n";
4481
4482         } elsif ($t->{'type'} eq "tree") {
4483                 print "<td class=\"list\">";
4484                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4485                                              file_name=>"$basedir$t->{'name'}",
4486                                              %base_key)},
4487                               esc_path($t->{'name'}));
4488                 print "</td>\n";
4489                 print "<td class=\"link\">";
4490                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4491                                              file_name=>"$basedir$t->{'name'}",
4492                                              %base_key)},
4493                               "tree");
4494                 if (defined $hash_base) {
4495                         print " | " .
4496                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4497                                                      file_name=>"$basedir$t->{'name'}")},
4498                                       "history");
4499                 }
4500                 print "</td>\n";
4501         } else {
4502                 # unknown object: we can only present history for it
4503                 # (this includes 'commit' object, i.e. submodule support)
4504                 print "<td class=\"list\">" .
4505                       esc_path($t->{'name'}) .
4506                       "</td>\n";
4507                 print "<td class=\"link\">";
4508                 if (defined $hash_base) {
4509                         print $cgi->a({-href => href(action=>"history",
4510                                                      hash_base=>$hash_base,
4511                                                      file_name=>"$basedir$t->{'name'}")},
4512                                       "history");
4513                 }
4514                 print "</td>\n";
4515         }
4516 }
4517
4518 ## ......................................................................
4519 ## functions printing large fragments of HTML
4520
4521 # get pre-image filenames for merge (combined) diff
4522 sub fill_from_file_info {
4523         my ($diff, @parents) = @_;
4524
4525         $diff->{'from_file'} = [ ];
4526         $diff->{'from_file'}[$diff->{'nparents'} - 1] = undef;
4527         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4528                 if ($diff->{'status'}[$i] eq 'R' ||
4529                     $diff->{'status'}[$i] eq 'C') {
4530                         $diff->{'from_file'}[$i] =
4531                                 git_get_path_by_hash($parents[$i], $diff->{'from_id'}[$i]);
4532                 }
4533         }
4534
4535         return $diff;
4536 }
4537
4538 # is current raw difftree line of file deletion
4539 sub is_deleted {
4540         my $diffinfo = shift;
4541
4542         return $diffinfo->{'to_id'} eq ('0' x 40);
4543 }
4544
4545 # does patch correspond to [previous] difftree raw line
4546 # $diffinfo  - hashref of parsed raw diff format
4547 # $patchinfo - hashref of parsed patch diff format
4548 #              (the same keys as in $diffinfo)
4549 sub is_patch_split {
4550         my ($diffinfo, $patchinfo) = @_;
4551
4552         return defined $diffinfo && defined $patchinfo
4553                 && $diffinfo->{'to_file'} eq $patchinfo->{'to_file'};
4554 }
4555
4556
4557 sub git_difftree_body {
4558         my ($difftree, $hash, @parents) = @_;
4559         my ($parent) = $parents[0];
4560         my $have_blame = gitweb_check_feature('blame');
4561         print "<div class=\"list_head\">\n";
4562         if ($#{$difftree} > 10) {
4563                 print(($#{$difftree} + 1) . " files changed:\n");
4564         }
4565         print "</div>\n";
4566
4567         print "<table class=\"" .
4568               (@parents > 1 ? "combined " : "") .
4569               "diff_tree\">\n";
4570
4571         # header only for combined diff in 'commitdiff' view
4572         my $has_header = @$difftree && @parents > 1 && $action eq 'commitdiff';
4573         if ($has_header) {
4574                 # table header
4575                 print "<thead><tr>\n" .
4576                        "<th></th><th></th>\n"; # filename, patchN link
4577                 for (my $i = 0; $i < @parents; $i++) {
4578                         my $par = $parents[$i];
4579                         print "<th>" .
4580                               $cgi->a({-href => href(action=>"commitdiff",
4581                                                      hash=>$hash, hash_parent=>$par),
4582                                        -title => 'commitdiff to parent number ' .
4583                                                   ($i+1) . ': ' . substr($par,0,7)},
4584                                       $i+1) .
4585                               "&nbsp;</th>\n";
4586                 }
4587                 print "</tr></thead>\n<tbody>\n";
4588         }
4589
4590         my $alternate = 1;
4591         my $patchno = 0;
4592         foreach my $line (@{$difftree}) {
4593                 my $diff = parsed_difftree_line($line);
4594
4595                 if ($alternate) {
4596                         print "<tr class=\"dark\">\n";
4597                 } else {
4598                         print "<tr class=\"light\">\n";
4599                 }
4600                 $alternate ^= 1;
4601
4602                 if (exists $diff->{'nparents'}) { # combined diff
4603
4604                         fill_from_file_info($diff, @parents)
4605                                 unless exists $diff->{'from_file'};
4606
4607                         if (!is_deleted($diff)) {
4608                                 # file exists in the result (child) commit
4609                                 print "<td>" .
4610                                       $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4611                                                              file_name=>$diff->{'to_file'},
4612                                                              hash_base=>$hash),
4613                                               -class => "list"}, esc_path($diff->{'to_file'})) .
4614                                       "</td>\n";
4615                         } else {
4616                                 print "<td>" .
4617                                       esc_path($diff->{'to_file'}) .
4618                                       "</td>\n";
4619                         }
4620
4621                         if ($action eq 'commitdiff') {
4622                                 # link to patch
4623                                 $patchno++;
4624                                 print "<td class=\"link\">" .
4625                                       $cgi->a({-href => href(-anchor=>"patch$patchno")},
4626                                               "patch") .
4627                                       " | " .
4628                                       "</td>\n";
4629                         }
4630
4631                         my $has_history = 0;
4632                         my $not_deleted = 0;
4633                         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4634                                 my $hash_parent = $parents[$i];
4635                                 my $from_hash = $diff->{'from_id'}[$i];
4636                                 my $from_path = $diff->{'from_file'}[$i];
4637                                 my $status = $diff->{'status'}[$i];
4638
4639                                 $has_history ||= ($status ne 'A');
4640                                 $not_deleted ||= ($status ne 'D');
4641
4642                                 if ($status eq 'A') {
4643                                         print "<td  class=\"link\" align=\"right\"> | </td>\n";
4644                                 } elsif ($status eq 'D') {
4645                                         print "<td class=\"link\">" .
4646                                               $cgi->a({-href => href(action=>"blob",
4647                                                                      hash_base=>$hash,
4648                                                                      hash=>$from_hash,
4649                                                                      file_name=>$from_path)},
4650                                                       "blob" . ($i+1)) .
4651                                               " | </td>\n";
4652                                 } else {
4653                                         if ($diff->{'to_id'} eq $from_hash) {
4654                                                 print "<td class=\"link nochange\">";
4655                                         } else {
4656                                                 print "<td class=\"link\">";
4657                                         }
4658                                         print $cgi->a({-href => href(action=>"blobdiff",
4659                                                                      hash=>$diff->{'to_id'},
4660                                                                      hash_parent=>$from_hash,
4661                                                                      hash_base=>$hash,
4662                                                                      hash_parent_base=>$hash_parent,
4663                                                                      file_name=>$diff->{'to_file'},
4664                                                                      file_parent=>$from_path)},
4665                                                       "diff" . ($i+1)) .
4666                                               " | </td>\n";
4667                                 }
4668                         }
4669
4670                         print "<td class=\"link\">";
4671                         if ($not_deleted) {
4672                                 print $cgi->a({-href => href(action=>"blob",
4673                                                              hash=>$diff->{'to_id'},
4674                                                              file_name=>$diff->{'to_file'},
4675                                                              hash_base=>$hash)},
4676                                               "blob");
4677                                 print " | " if ($has_history);
4678                         }
4679                         if ($has_history) {
4680                                 print $cgi->a({-href => href(action=>"history",
4681                                                              file_name=>$diff->{'to_file'},
4682                                                              hash_base=>$hash)},
4683                                               "history");
4684                         }
4685                         print "</td>\n";
4686
4687                         print "</tr>\n";
4688                         next; # instead of 'else' clause, to avoid extra indent
4689                 }
4690                 # else ordinary diff
4691
4692                 my ($to_mode_oct, $to_mode_str, $to_file_type);
4693                 my ($from_mode_oct, $from_mode_str, $from_file_type);
4694                 if ($diff->{'to_mode'} ne ('0' x 6)) {
4695                         $to_mode_oct = oct $diff->{'to_mode'};
4696                         if (S_ISREG($to_mode_oct)) { # only for regular file
4697                                 $to_mode_str = sprintf("%04o", $to_mode_oct & 0777); # permission bits
4698                         }
4699                         $to_file_type = file_type($diff->{'to_mode'});
4700                 }
4701                 if ($diff->{'from_mode'} ne ('0' x 6)) {
4702                         $from_mode_oct = oct $diff->{'from_mode'};
4703                         if (S_ISREG($from_mode_oct)) { # only for regular file
4704                                 $from_mode_str = sprintf("%04o", $from_mode_oct & 0777); # permission bits
4705                         }
4706                         $from_file_type = file_type($diff->{'from_mode'});
4707                 }
4708
4709                 if ($diff->{'status'} eq "A") { # created
4710                         my $mode_chng = "<span class=\"file_status new\">[new $to_file_type";
4711                         $mode_chng   .= " with mode: $to_mode_str" if $to_mode_str;
4712                         $mode_chng   .= "]</span>";
4713                         print "<td>";
4714                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4715                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4716                                       -class => "list"}, esc_path($diff->{'file'}));
4717                         print "</td>\n";
4718                         print "<td>$mode_chng</td>\n";
4719                         print "<td class=\"link\">";
4720                         if ($action eq 'commitdiff') {
4721                                 # link to patch
4722                                 $patchno++;
4723                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4724                                               "patch") .
4725                                       " | ";
4726                         }
4727                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4728                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4729                                       "blob");
4730                         print "</td>\n";
4731
4732                 } elsif ($diff->{'status'} eq "D") { # deleted
4733                         my $mode_chng = "<span class=\"file_status deleted\">[deleted $from_file_type]</span>";
4734                         print "<td>";
4735                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4736                                                      hash_base=>$parent, file_name=>$diff->{'file'}),
4737                                        -class => "list"}, esc_path($diff->{'file'}));
4738                         print "</td>\n";
4739                         print "<td>$mode_chng</td>\n";
4740                         print "<td class=\"link\">";
4741                         if ($action eq 'commitdiff') {
4742                                 # link to patch
4743                                 $patchno++;
4744                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4745                                               "patch") .
4746                                       " | ";
4747                         }
4748                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4749                                                      hash_base=>$parent, file_name=>$diff->{'file'})},
4750                                       "blob") . " | ";
4751                         if ($have_blame) {
4752                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$parent,
4753                                                              file_name=>$diff->{'file'})},
4754                                               "blame") . " | ";
4755                         }
4756                         print $cgi->a({-href => href(action=>"history", hash_base=>$parent,
4757                                                      file_name=>$diff->{'file'})},
4758                                       "history");
4759                         print "</td>\n";
4760
4761                 } elsif ($diff->{'status'} eq "M" || $diff->{'status'} eq "T") { # modified, or type changed
4762                         my $mode_chnge = "";
4763                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4764                                 $mode_chnge = "<span class=\"file_status mode_chnge\">[changed";
4765                                 if ($from_file_type ne $to_file_type) {
4766                                         $mode_chnge .= " from $from_file_type to $to_file_type";
4767                                 }
4768                                 if (($from_mode_oct & 0777) != ($to_mode_oct & 0777)) {
4769                                         if ($from_mode_str && $to_mode_str) {
4770                                                 $mode_chnge .= " mode: $from_mode_str->$to_mode_str";
4771                                         } elsif ($to_mode_str) {
4772                                                 $mode_chnge .= " mode: $to_mode_str";
4773                                         }
4774                                 }
4775                                 $mode_chnge .= "]</span>\n";
4776                         }
4777                         print "<td>";
4778                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4779                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4780                                       -class => "list"}, esc_path($diff->{'file'}));
4781                         print "</td>\n";
4782                         print "<td>$mode_chnge</td>\n";
4783                         print "<td class=\"link\">";
4784                         if ($action eq 'commitdiff') {
4785                                 # link to patch
4786                                 $patchno++;
4787                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4788                                               "patch") .
4789                                       " | ";
4790                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4791                                 # "commit" view and modified file (not onlu mode changed)
4792                                 print $cgi->a({-href => href(action=>"blobdiff",
4793                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4794                                                              hash_base=>$hash, hash_parent_base=>$parent,
4795                                                              file_name=>$diff->{'file'})},
4796                                               "diff") .
4797                                       " | ";
4798                         }
4799                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4800                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4801                                        "blob") . " | ";
4802                         if ($have_blame) {
4803                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4804                                                              file_name=>$diff->{'file'})},
4805                                               "blame") . " | ";
4806                         }
4807                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4808                                                      file_name=>$diff->{'file'})},
4809                                       "history");
4810                         print "</td>\n";
4811
4812                 } elsif ($diff->{'status'} eq "R" || $diff->{'status'} eq "C") { # renamed or copied
4813                         my %status_name = ('R' => 'moved', 'C' => 'copied');
4814                         my $nstatus = $status_name{$diff->{'status'}};
4815                         my $mode_chng = "";
4816                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4817                                 # mode also for directories, so we cannot use $to_mode_str
4818                                 $mode_chng = sprintf(", mode: %04o", $to_mode_oct & 0777);
4819                         }
4820                         print "<td>" .
4821                               $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
4822                                                      hash=>$diff->{'to_id'}, file_name=>$diff->{'to_file'}),
4823                                       -class => "list"}, esc_path($diff->{'to_file'})) . "</td>\n" .
4824                               "<td><span class=\"file_status $nstatus\">[$nstatus from " .
4825                               $cgi->a({-href => href(action=>"blob", hash_base=>$parent,
4826                                                      hash=>$diff->{'from_id'}, file_name=>$diff->{'from_file'}),
4827                                       -class => "list"}, esc_path($diff->{'from_file'})) .
4828                               " with " . (int $diff->{'similarity'}) . "% similarity$mode_chng]</span></td>\n" .
4829                               "<td class=\"link\">";
4830                         if ($action eq 'commitdiff') {
4831                                 # link to patch
4832                                 $patchno++;
4833                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4834                                               "patch") .
4835                                       " | ";
4836                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4837                                 # "commit" view and modified file (not only pure rename or copy)
4838                                 print $cgi->a({-href => href(action=>"blobdiff",
4839                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4840                                                              hash_base=>$hash, hash_parent_base=>$parent,
4841                                                              file_name=>$diff->{'to_file'}, file_parent=>$diff->{'from_file'})},
4842                                               "diff") .
4843                                       " | ";
4844                         }
4845                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4846                                                      hash_base=>$parent, file_name=>$diff->{'to_file'})},
4847                                       "blob") . " | ";
4848                         if ($have_blame) {
4849                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4850                                                              file_name=>$diff->{'to_file'})},
4851                                               "blame") . " | ";
4852                         }
4853                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4854                                                     file_name=>$diff->{'to_file'})},
4855                                       "history");
4856                         print "</td>\n";
4857
4858                 } # we should not encounter Unmerged (U) or Unknown (X) status
4859                 print "</tr>\n";
4860         }
4861         print "</tbody>" if $has_header;
4862         print "</table>\n";
4863 }
4864
4865 sub print_sidebyside_diff_chunk {
4866         my @chunk = @_;
4867         my (@ctx, @rem, @add);
4868
4869         return unless @chunk;
4870
4871         # incomplete last line might be among removed or added lines,
4872         # or both, or among context lines: find which
4873         for (my $i = 1; $i < @chunk; $i++) {
4874                 if ($chunk[$i][0] eq 'incomplete') {
4875                         $chunk[$i][0] = $chunk[$i-1][0];
4876                 }
4877         }
4878
4879         # guardian
4880         push @chunk, ["", ""];
4881
4882         foreach my $line_info (@chunk) {
4883                 my ($class, $line) = @$line_info;
4884
4885                 # print chunk headers
4886                 if ($class && $class eq 'chunk_header') {
4887                         print $line;
4888                         next;
4889                 }
4890
4891                 ## print from accumulator when type of class of lines change
4892                 # empty contents block on start rem/add block, or end of chunk
4893                 if (@ctx && (!$class || $class eq 'rem' || $class eq 'add')) {
4894                         print join '',
4895                                 '<div class="chunk_block ctx">',
4896                                         '<div class="old">',
4897                                         @ctx,
4898                                         '</div>',
4899                                         '<div class="new">',
4900                                         @ctx,
4901                                         '</div>',
4902                                 '</div>';
4903                         @ctx = ();
4904                 }
4905                 # empty add/rem block on start context block, or end of chunk
4906                 if ((@rem || @add) && (!$class || $class eq 'ctx')) {
4907                         if (!@add) {
4908                                 # pure removal
4909                                 print join '',
4910                                         '<div class="chunk_block rem">',
4911                                                 '<div class="old">',
4912                                                 @rem,
4913                                                 '</div>',
4914                                         '</div>';
4915                         } elsif (!@rem) {
4916                                 # pure addition
4917                                 print join '',
4918                                         '<div class="chunk_block add">',
4919                                                 '<div class="new">',
4920                                                 @add,
4921                                                 '</div>',
4922                                         '</div>';
4923                         } else {
4924                                 # assume that it is change
4925                                 print join '',
4926                                         '<div class="chunk_block chg">',
4927                                                 '<div class="old">',
4928                                                 @rem,
4929                                                 '</div>',
4930                                                 '<div class="new">',
4931                                                 @add,
4932                                                 '</div>',
4933                                         '</div>';
4934                         }
4935                         @rem = @add = ();
4936                 }
4937
4938                 ## adding lines to accumulator
4939                 # guardian value
4940                 last unless $line;
4941                 # rem, add or change
4942                 if ($class eq 'rem') {
4943                         push @rem, $line;
4944                 } elsif ($class eq 'add') {
4945                         push @add, $line;
4946                 }
4947                 # context line
4948                 if ($class eq 'ctx') {
4949                         push @ctx, $line;
4950                 }
4951         }
4952 }
4953
4954 sub git_patchset_body {
4955         my ($fd, $diff_style, $difftree, $hash, @hash_parents) = @_;
4956         my ($hash_parent) = $hash_parents[0];
4957
4958         my $is_combined = (@hash_parents > 1);
4959         my $patch_idx = 0;
4960         my $patch_number = 0;
4961         my $patch_line;
4962         my $diffinfo;
4963         my $to_name;
4964         my (%from, %to);
4965         my @chunk; # for side-by-side diff
4966
4967         print "<div class=\"patchset\">\n";
4968
4969         # skip to first patch
4970         while ($patch_line = <$fd>) {
4971                 chomp $patch_line;
4972
4973                 last if ($patch_line =~ m/^diff /);
4974         }
4975
4976  PATCH:
4977         while ($patch_line) {
4978
4979                 # parse "git diff" header line
4980                 if ($patch_line =~ m/^diff --git (\"(?:[^\\\"]*(?:\\.[^\\\"]*)*)\"|[^ "]*) (.*)$/) {
4981                         # $1 is from_name, which we do not use
4982                         $to_name = unquote($2);
4983                         $to_name =~ s!^b/!!;
4984                 } elsif ($patch_line =~ m/^diff --(cc|combined) ("?.*"?)$/) {
4985                         # $1 is 'cc' or 'combined', which we do not use
4986                         $to_name = unquote($2);
4987                 } else {
4988                         $to_name = undef;
4989                 }
4990
4991                 # check if current patch belong to current raw line
4992                 # and parse raw git-diff line if needed
4993                 if (is_patch_split($diffinfo, { 'to_file' => $to_name })) {
4994                         # this is continuation of a split patch
4995                         print "<div class=\"patch cont\">\n";
4996                 } else {
4997                         # advance raw git-diff output if needed
4998                         $patch_idx++ if defined $diffinfo;
4999
5000                         # read and prepare patch information
5001                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5002
5003                         # compact combined diff output can have some patches skipped
5004                         # find which patch (using pathname of result) we are at now;
5005                         if ($is_combined) {
5006                                 while ($to_name ne $diffinfo->{'to_file'}) {
5007                                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
5008                                               format_diff_cc_simplified($diffinfo, @hash_parents) .
5009                                               "</div>\n";  # class="patch"
5010
5011                                         $patch_idx++;
5012                                         $patch_number++;
5013
5014                                         last if $patch_idx > $#$difftree;
5015                                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5016                                 }
5017                         }
5018
5019                         # modifies %from, %to hashes
5020                         parse_from_to_diffinfo($diffinfo, \%from, \%to, @hash_parents);
5021
5022                         # this is first patch for raw difftree line with $patch_idx index
5023                         # we index @$difftree array from 0, but number patches from 1
5024                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n";
5025                 }
5026
5027                 # git diff header
5028                 #assert($patch_line =~ m/^diff /) if DEBUG;
5029                 #assert($patch_line !~ m!$/$!) if DEBUG; # is chomp-ed
5030                 $patch_number++;
5031                 # print "git diff" header
5032                 print format_git_diff_header_line($patch_line, $diffinfo,
5033                                                   \%from, \%to);
5034
5035                 # print extended diff header
5036                 print "<div class=\"diff extended_header\">\n";
5037         EXTENDED_HEADER:
5038                 while ($patch_line = <$fd>) {
5039                         chomp $patch_line;
5040
5041                         last EXTENDED_HEADER if ($patch_line =~ m/^--- |^diff /);
5042
5043                         print format_extended_diff_header_line($patch_line, $diffinfo,
5044                                                                \%from, \%to);
5045                 }
5046                 print "</div>\n"; # class="diff extended_header"
5047
5048                 # from-file/to-file diff header
5049                 if (! $patch_line) {
5050                         print "</div>\n"; # class="patch"
5051                         last PATCH;
5052                 }
5053                 next PATCH if ($patch_line =~ m/^diff /);
5054                 #assert($patch_line =~ m/^---/) if DEBUG;
5055
5056                 my $last_patch_line = $patch_line;
5057                 $patch_line = <$fd>;
5058                 chomp $patch_line;
5059                 #assert($patch_line =~ m/^\+\+\+/) if DEBUG;
5060
5061                 print format_diff_from_to_header($last_patch_line, $patch_line,
5062                                                  $diffinfo, \%from, \%to,
5063                                                  @hash_parents);
5064
5065                 # the patch itself
5066         LINE:
5067                 while ($patch_line = <$fd>) {
5068                         chomp $patch_line;
5069
5070                         next PATCH if ($patch_line =~ m/^diff /);
5071
5072                         my ($class, $line) = process_diff_line($patch_line, \%from, \%to);
5073                         my $diff_classes = "diff";
5074                         $diff_classes .= " $class" if ($class);
5075                         $line = "<div class=\"$diff_classes\">$line</div>\n";
5076
5077                         if ($diff_style eq 'sidebyside' && !$is_combined) {
5078                                 if ($class eq 'chunk_header') {
5079                                         print_sidebyside_diff_chunk(@chunk);
5080                                         @chunk = ( [ $class, $line ] );
5081                                 } else {
5082                                         push @chunk, [ $class, $line ];
5083                                 }
5084                         } else {
5085                                 # default 'inline' style and unknown styles
5086                                 print $line;
5087                         }
5088                 }
5089
5090         } continue {
5091                 if (@chunk) {
5092                         print_sidebyside_diff_chunk(@chunk);
5093                         @chunk = ();
5094                 }
5095                 print "</div>\n"; # class="patch"
5096         }
5097
5098         # for compact combined (--cc) format, with chunk and patch simplification
5099         # the patchset might be empty, but there might be unprocessed raw lines
5100         for (++$patch_idx if $patch_number > 0;
5101              $patch_idx < @$difftree;
5102              ++$patch_idx) {
5103                 # read and prepare patch information
5104                 $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5105
5106                 # generate anchor for "patch" links in difftree / whatchanged part
5107                 print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
5108                       format_diff_cc_simplified($diffinfo, @hash_parents) .
5109                       "</div>\n";  # class="patch"
5110
5111                 $patch_number++;
5112         }
5113
5114         if ($patch_number == 0) {
5115                 if (@hash_parents > 1) {
5116                         print "<div class=\"diff nodifferences\">Trivial merge</div>\n";
5117                 } else {
5118                         print "<div class=\"diff nodifferences\">No differences found</div>\n";
5119                 }
5120         }
5121
5122         print "</div>\n"; # class="patchset"
5123 }
5124
5125 # . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
5126
5127 # fills project list info (age, description, owner, category, forks)
5128 # for each project in the list, removing invalid projects from
5129 # returned list
5130 # NOTE: modifies $projlist, but does not remove entries from it
5131 sub fill_project_list_info {
5132         my $projlist = shift;
5133         my @projects;
5134
5135         my $show_ctags = gitweb_check_feature('ctags');
5136  PROJECT:
5137         foreach my $pr (@$projlist) {
5138                 my (@activity) = git_get_last_activity($pr->{'path'});
5139                 unless (@activity) {
5140                         next PROJECT;
5141                 }
5142                 ($pr->{'age'}, $pr->{'age_string'}) = @activity;
5143                 if (!defined $pr->{'descr'}) {
5144                         my $descr = git_get_project_description($pr->{'path'}) || "";
5145                         $descr = to_utf8($descr);
5146                         $pr->{'descr_long'} = $descr;
5147                         $pr->{'descr'} = chop_str($descr, $projects_list_description_width, 5);
5148                 }
5149                 if (!defined $pr->{'owner'}) {
5150                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}") || "";
5151                 }
5152                 if ($show_ctags) {
5153                         $pr->{'ctags'} = git_get_project_ctags($pr->{'path'});
5154                 }
5155                 if ($projects_list_group_categories && !defined $pr->{'category'}) {
5156                         my $cat = git_get_project_category($pr->{'path'}) ||
5157                                                            $project_list_default_category;
5158                         $pr->{'category'} = to_utf8($cat);
5159                 }
5160
5161                 push @projects, $pr;
5162         }
5163
5164         return @projects;
5165 }
5166
5167 sub sort_projects_list {
5168         my ($projlist, $order) = @_;
5169         my @projects;
5170
5171         my %order_info = (
5172                 project => { key => 'path', type => 'str' },
5173                 descr => { key => 'descr_long', type => 'str' },
5174                 owner => { key => 'owner', type => 'str' },
5175                 age => { key => 'age', type => 'num' }
5176         );
5177         my $oi = $order_info{$order};
5178         return @$projlist unless defined $oi;
5179         if ($oi->{'type'} eq 'str') {
5180                 @projects = sort {$a->{$oi->{'key'}} cmp $b->{$oi->{'key'}}} @$projlist;
5181         } else {
5182                 @projects = sort {$a->{$oi->{'key'}} <=> $b->{$oi->{'key'}}} @$projlist;
5183         }
5184
5185         return @projects;
5186 }
5187
5188 # returns a hash of categories, containing the list of project
5189 # belonging to each category
5190 sub build_projlist_by_category {
5191         my ($projlist, $from, $to) = @_;
5192         my %categories;
5193
5194         $from = 0 unless defined $from;
5195         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5196
5197         for (my $i = $from; $i <= $to; $i++) {
5198                 my $pr = $projlist->[$i];
5199                 push @{$categories{ $pr->{'category'} }}, $pr;
5200         }
5201
5202         return wantarray ? %categories : \%categories;
5203 }
5204
5205 # print 'sort by' <th> element, generating 'sort by $name' replay link
5206 # if that order is not selected
5207 sub print_sort_th {
5208         print format_sort_th(@_);
5209 }
5210
5211 sub format_sort_th {
5212         my ($name, $order, $header) = @_;
5213         my $sort_th = "";
5214         $header ||= ucfirst($name);
5215
5216         if ($order eq $name) {
5217                 $sort_th .= "<th>$header</th>\n";
5218         } else {
5219                 $sort_th .= "<th>" .
5220                             $cgi->a({-href => href(-replay=>1, order=>$name),
5221                                      -class => "header"}, $header) .
5222                             "</th>\n";
5223         }
5224
5225         return $sort_th;
5226 }
5227
5228 sub git_project_list_rows {
5229         my ($projlist, $from, $to, $check_forks) = @_;
5230
5231         $from = 0 unless defined $from;
5232         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5233
5234         my $alternate = 1;
5235         for (my $i = $from; $i <= $to; $i++) {
5236                 my $pr = $projlist->[$i];
5237
5238                 if ($alternate) {
5239                         print "<tr class=\"dark\">\n";
5240                 } else {
5241                         print "<tr class=\"light\">\n";
5242                 }
5243                 $alternate ^= 1;
5244
5245                 if ($check_forks) {
5246                         print "<td>";
5247                         if ($pr->{'forks'}) {
5248                                 my $nforks = scalar @{$pr->{'forks'}};
5249                                 if ($nforks > 0) {
5250                                         print $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks"),
5251                                                        -title => "$nforks forks"}, "+");
5252                                 } else {
5253                                         print $cgi->span({-title => "$nforks forks"}, "+");
5254                                 }
5255                         }
5256                         print "</td>\n";
5257                 }
5258                 print "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5259                                         -class => "list"}, esc_html($pr->{'path'})) . "</td>\n" .
5260                       "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5261                                         -class => "list", -title => $pr->{'descr_long'}},
5262                                         esc_html($pr->{'descr'})) . "</td>\n" .
5263                       "<td><i>" . chop_and_escape_str($pr->{'owner'}, 15) . "</i></td>\n";
5264                 print "<td class=\"". age_class($pr->{'age'}) . "\">" .
5265                       (defined $pr->{'age_string'} ? $pr->{'age_string'} : "No commits") . "</td>\n" .
5266                       "<td class=\"link\">" .
5267                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary")}, "summary")   . " | " .
5268                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"shortlog")}, "shortlog") . " | " .
5269                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"log")}, "log") . " | " .
5270                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"tree")}, "tree") .
5271                       ($pr->{'forks'} ? " | " . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "forks") : '') .
5272                       "</td>\n" .
5273                       "</tr>\n";
5274         }
5275 }
5276
5277 sub git_project_list_body {
5278         # actually uses global variable $project
5279         my ($projlist, $order, $from, $to, $extra, $no_header) = @_;
5280         my @projects = @$projlist;
5281
5282         my $check_forks = gitweb_check_feature('forks');
5283         my $show_ctags  = gitweb_check_feature('ctags');
5284         my $tagfilter = $show_ctags ? $cgi->param('by_tag') : undef;
5285         $check_forks = undef
5286                 if ($tagfilter || $searchtext);
5287
5288         # filtering out forks before filling info allows to do less work
5289         @projects = filter_forks_from_projects_list(\@projects)
5290                 if ($check_forks);
5291         @projects = fill_project_list_info(\@projects);
5292         # searching projects require filling to be run before it
5293         @projects = search_projects_list(\@projects,
5294                                          'searchtext' => $searchtext,
5295                                          'tagfilter'  => $tagfilter)
5296                 if ($tagfilter || $searchtext);
5297
5298         $order ||= $default_projects_order;
5299         $from = 0 unless defined $from;
5300         $to = $#projects if (!defined $to || $#projects < $to);
5301
5302         # short circuit
5303         if ($from > $to) {
5304                 print "<center>\n".
5305                       "<b>No such projects found</b><br />\n".
5306                       "Click ".$cgi->a({-href=>href(project=>undef)},"here")." to view all projects<br />\n".
5307                       "</center>\n<br />\n";
5308                 return;
5309         }
5310
5311         @projects = sort_projects_list(\@projects, $order);
5312
5313         if ($show_ctags) {
5314                 my $ctags = git_gather_all_ctags(\@projects);
5315                 my $cloud = git_populate_project_tagcloud($ctags);
5316                 print git_show_project_tagcloud($cloud, 64);
5317         }
5318
5319         print "<table class=\"project_list\">\n";
5320         unless ($no_header) {
5321                 print "<tr>\n";
5322                 if ($check_forks) {
5323                         print "<th></th>\n";
5324                 }
5325                 print_sort_th('project', $order, 'Project');
5326                 print_sort_th('descr', $order, 'Description');
5327                 print_sort_th('owner', $order, 'Owner');
5328                 print_sort_th('age', $order, 'Last Change');
5329                 print "<th></th>\n" . # for links
5330                       "</tr>\n";
5331         }
5332
5333         if ($projects_list_group_categories) {
5334                 # only display categories with projects in the $from-$to window
5335                 @projects = sort {$a->{'category'} cmp $b->{'category'}} @projects[$from..$to];
5336                 my %categories = build_projlist_by_category(\@projects, $from, $to);
5337                 foreach my $cat (sort keys %categories) {
5338                         unless ($cat eq "") {
5339                                 print "<tr>\n";
5340                                 if ($check_forks) {
5341                                         print "<td></td>\n";
5342                                 }
5343                                 print "<td class=\"category\" colspan=\"5\">".esc_html($cat)."</td>\n";
5344                                 print "</tr>\n";
5345                         }
5346
5347                         git_project_list_rows($categories{$cat}, undef, undef, $check_forks);
5348                 }
5349         } else {
5350                 git_project_list_rows(\@projects, $from, $to, $check_forks);
5351         }
5352
5353         if (defined $extra) {
5354                 print "<tr>\n";
5355                 if ($check_forks) {
5356                         print "<td></td>\n";
5357                 }
5358                 print "<td colspan=\"5\">$extra</td>\n" .
5359                       "</tr>\n";
5360         }
5361         print "</table>\n";
5362 }
5363
5364 sub git_log_body {
5365         # uses global variable $project
5366         my ($commitlist, $from, $to, $refs, $extra) = @_;
5367
5368         $from = 0 unless defined $from;
5369         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5370
5371         for (my $i = 0; $i <= $to; $i++) {
5372                 my %co = %{$commitlist->[$i]};
5373                 next if !%co;
5374                 my $commit = $co{'id'};
5375                 my $ref = format_ref_marker($refs, $commit);
5376                 git_print_header_div('commit',
5377                                "<span class=\"age\">$co{'age_string'}</span>" .
5378                                esc_html($co{'title'}) . $ref,
5379                                $commit);
5380                 print "<div class=\"title_text\">\n" .
5381                       "<div class=\"log_link\">\n" .
5382                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") .
5383                       " | " .
5384                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") .
5385                       " | " .
5386                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree") .
5387                       "<br/>\n" .
5388                       "</div>\n";
5389                       git_print_authorship(\%co, -tag => 'span');
5390                       print "<br/>\n</div>\n";
5391
5392                 print "<div class=\"log_body\">\n";
5393                 git_print_log($co{'comment'}, -final_empty_line=> 1);
5394                 print "</div>\n";
5395         }
5396         if ($extra) {
5397                 print "<div class=\"page_nav\">\n";
5398                 print "$extra\n";
5399                 print "</div>\n";
5400         }
5401 }
5402
5403 sub git_shortlog_body {
5404         # uses global variable $project
5405         my ($commitlist, $from, $to, $refs, $extra) = @_;
5406
5407         $from = 0 unless defined $from;
5408         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5409
5410         print "<table class=\"shortlog\">\n";
5411         my $alternate = 1;
5412         for (my $i = $from; $i <= $to; $i++) {
5413                 my %co = %{$commitlist->[$i]};
5414                 my $commit = $co{'id'};
5415                 my $ref = format_ref_marker($refs, $commit);
5416                 if ($alternate) {
5417                         print "<tr class=\"dark\">\n";
5418                 } else {
5419                         print "<tr class=\"light\">\n";
5420                 }
5421                 $alternate ^= 1;
5422                 # git_summary() used print "<td><i>$co{'age_string'}</i></td>\n" .
5423                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5424                       format_author_html('td', \%co, 10) . "<td>";
5425                 print format_subject_html($co{'title'}, $co{'title_short'},
5426                                           href(action=>"commit", hash=>$commit), $ref);
5427                 print "</td>\n" .
5428                       "<td class=\"link\">" .
5429                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") . " | " .
5430                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") . " | " .
5431                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree");
5432                 my $snapshot_links = format_snapshot_links($commit);
5433                 if (defined $snapshot_links) {
5434                         print " | " . $snapshot_links;
5435                 }
5436                 print "</td>\n" .
5437                       "</tr>\n";
5438         }
5439         if (defined $extra) {
5440                 print "<tr>\n" .
5441                       "<td colspan=\"4\">$extra</td>\n" .
5442                       "</tr>\n";
5443         }
5444         print "</table>\n";
5445 }
5446
5447 sub git_history_body {
5448         # Warning: assumes constant type (blob or tree) during history
5449         my ($commitlist, $from, $to, $refs, $extra,
5450             $file_name, $file_hash, $ftype) = @_;
5451
5452         $from = 0 unless defined $from;
5453         $to = $#{$commitlist} unless (defined $to && $to <= $#{$commitlist});
5454
5455         print "<table class=\"history\">\n";
5456         my $alternate = 1;
5457         for (my $i = $from; $i <= $to; $i++) {
5458                 my %co = %{$commitlist->[$i]};
5459                 if (!%co) {
5460                         next;
5461                 }
5462                 my $commit = $co{'id'};
5463
5464                 my $ref = format_ref_marker($refs, $commit);
5465
5466                 if ($alternate) {
5467                         print "<tr class=\"dark\">\n";
5468                 } else {
5469                         print "<tr class=\"light\">\n";
5470                 }
5471                 $alternate ^= 1;
5472                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5473         # shortlog:   format_author_html('td', \%co, 10)
5474                       format_author_html('td', \%co, 15, 3) . "<td>";
5475                 # originally git_history used chop_str($co{'title'}, 50)
5476                 print format_subject_html($co{'title'}, $co{'title_short'},
5477                                           href(action=>"commit", hash=>$commit), $ref);
5478                 print "</td>\n" .
5479                       "<td class=\"link\">" .
5480                       $cgi->a({-href => href(action=>$ftype, hash_base=>$commit, file_name=>$file_name)}, $ftype) . " | " .
5481                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff");
5482
5483                 if ($ftype eq 'blob') {
5484                         my $blob_current = $file_hash;
5485                         my $blob_parent  = git_get_hash_by_path($commit, $file_name);
5486                         if (defined $blob_current && defined $blob_parent &&
5487                                         $blob_current ne $blob_parent) {
5488                                 print " | " .
5489                                         $cgi->a({-href => href(action=>"blobdiff",
5490                                                                hash=>$blob_current, hash_parent=>$blob_parent,
5491                                                                hash_base=>$hash_base, hash_parent_base=>$commit,
5492                                                                file_name=>$file_name)},
5493                                                 "diff to current");
5494                         }
5495                 }
5496                 print "</td>\n" .
5497                       "</tr>\n";
5498         }
5499         if (defined $extra) {
5500                 print "<tr>\n" .
5501                       "<td colspan=\"4\">$extra</td>\n" .
5502                       "</tr>\n";
5503         }
5504         print "</table>\n";
5505 }
5506
5507 sub git_tags_body {
5508         # uses global variable $project
5509         my ($taglist, $from, $to, $extra) = @_;
5510         $from = 0 unless defined $from;
5511         $to = $#{$taglist} if (!defined $to || $#{$taglist} < $to);
5512
5513         print "<table class=\"tags\">\n";
5514         my $alternate = 1;
5515         for (my $i = $from; $i <= $to; $i++) {
5516                 my $entry = $taglist->[$i];
5517                 my %tag = %$entry;
5518                 my $comment = $tag{'subject'};
5519                 my $comment_short;
5520                 if (defined $comment) {
5521                         $comment_short = chop_str($comment, 30, 5);
5522                 }
5523                 if ($alternate) {
5524                         print "<tr class=\"dark\">\n";
5525                 } else {
5526                         print "<tr class=\"light\">\n";
5527                 }
5528                 $alternate ^= 1;
5529                 if (defined $tag{'age'}) {
5530                         print "<td><i>$tag{'age'}</i></td>\n";
5531                 } else {
5532                         print "<td></td>\n";
5533                 }
5534                 print "<td>" .
5535                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'}),
5536                                -class => "list name"}, esc_html($tag{'name'})) .
5537                       "</td>\n" .
5538                       "<td>";
5539                 if (defined $comment) {
5540                         print format_subject_html($comment, $comment_short,
5541                                                   href(action=>"tag", hash=>$tag{'id'}));
5542                 }
5543                 print "</td>\n" .
5544                       "<td class=\"selflink\">";
5545                 if ($tag{'type'} eq "tag") {
5546                         print $cgi->a({-href => href(action=>"tag", hash=>$tag{'id'})}, "tag");
5547                 } else {
5548                         print "&nbsp;";
5549                 }
5550                 print "</td>\n" .
5551                       "<td class=\"link\">" . " | " .
5552                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'})}, $tag{'reftype'});
5553                 if ($tag{'reftype'} eq "commit") {
5554                         print " | " . $cgi->a({-href => href(action=>"shortlog", hash=>$tag{'fullname'})}, "shortlog") .
5555                               " | " . $cgi->a({-href => href(action=>"log", hash=>$tag{'fullname'})}, "log");
5556                 } elsif ($tag{'reftype'} eq "blob") {
5557                         print " | " . $cgi->a({-href => href(action=>"blob_plain", hash=>$tag{'refid'})}, "raw");
5558                 }
5559                 print "</td>\n" .
5560                       "</tr>";
5561         }
5562         if (defined $extra) {
5563                 print "<tr>\n" .
5564                       "<td colspan=\"5\">$extra</td>\n" .
5565                       "</tr>\n";
5566         }
5567         print "</table>\n";
5568 }
5569
5570 sub git_heads_body {
5571         # uses global variable $project
5572         my ($headlist, $head, $from, $to, $extra) = @_;
5573         $from = 0 unless defined $from;
5574         $to = $#{$headlist} if (!defined $to || $#{$headlist} < $to);
5575
5576         print "<table class=\"heads\">\n";
5577         my $alternate = 1;
5578         for (my $i = $from; $i <= $to; $i++) {
5579                 my $entry = $headlist->[$i];
5580                 my %ref = %$entry;
5581                 my $curr = $ref{'id'} eq $head;
5582                 if ($alternate) {
5583                         print "<tr class=\"dark\">\n";
5584                 } else {
5585                         print "<tr class=\"light\">\n";
5586                 }
5587                 $alternate ^= 1;
5588                 print "<td><i>$ref{'age'}</i></td>\n" .
5589                       ($curr ? "<td class=\"current_head\">" : "<td>") .
5590                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'}),
5591                                -class => "list name"},esc_html($ref{'name'})) .
5592                       "</td>\n" .
5593                       "<td class=\"link\">" .
5594                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'})}, "shortlog") . " | " .
5595                       $cgi->a({-href => href(action=>"log", hash=>$ref{'fullname'})}, "log") . " | " .
5596                       $cgi->a({-href => href(action=>"tree", hash=>$ref{'fullname'}, hash_base=>$ref{'fullname'})}, "tree") .
5597                       "</td>\n" .
5598                       "</tr>";
5599         }
5600         if (defined $extra) {
5601                 print "<tr>\n" .
5602                       "<td colspan=\"3\">$extra</td>\n" .
5603                       "</tr>\n";
5604         }
5605         print "</table>\n";
5606 }
5607
5608 # Display a single remote block
5609 sub git_remote_block {
5610         my ($remote, $rdata, $limit, $head) = @_;
5611
5612         my $heads = $rdata->{'heads'};
5613         my $fetch = $rdata->{'fetch'};
5614         my $push = $rdata->{'push'};
5615
5616         my $urls_table = "<table class=\"projects_list\">\n" ;
5617
5618         if (defined $fetch) {
5619                 if ($fetch eq $push) {
5620                         $urls_table .= format_repo_url("URL", $fetch);
5621                 } else {
5622                         $urls_table .= format_repo_url("Fetch URL", $fetch);
5623                         $urls_table .= format_repo_url("Push URL", $push) if defined $push;
5624                 }
5625         } elsif (defined $push) {
5626                 $urls_table .= format_repo_url("Push URL", $push);
5627         } else {
5628                 $urls_table .= format_repo_url("", "No remote URL");
5629         }
5630
5631         $urls_table .= "</table>\n";
5632
5633         my $dots;
5634         if (defined $limit && $limit < @$heads) {
5635                 $dots = $cgi->a({-href => href(action=>"remotes", hash=>$remote)}, "...");
5636         }
5637
5638         print $urls_table;
5639         git_heads_body($heads, $head, 0, $limit, $dots);
5640 }
5641
5642 # Display a list of remote names with the respective fetch and push URLs
5643 sub git_remotes_list {
5644         my ($remotedata, $limit) = @_;
5645         print "<table class=\"heads\">\n";
5646         my $alternate = 1;
5647         my @remotes = sort keys %$remotedata;
5648
5649         my $limited = $limit && $limit < @remotes;
5650
5651         $#remotes = $limit - 1 if $limited;
5652
5653         while (my $remote = shift @remotes) {
5654                 my $rdata = $remotedata->{$remote};
5655                 my $fetch = $rdata->{'fetch'};
5656                 my $push = $rdata->{'push'};
5657                 if ($alternate) {
5658                         print "<tr class=\"dark\">\n";
5659                 } else {
5660                         print "<tr class=\"light\">\n";
5661                 }
5662                 $alternate ^= 1;
5663                 print "<td>" .
5664                       $cgi->a({-href=> href(action=>'remotes', hash=>$remote),
5665                                -class=> "list name"},esc_html($remote)) .
5666                       "</td>";
5667                 print "<td class=\"link\">" .
5668                       (defined $fetch ? $cgi->a({-href=> $fetch}, "fetch") : "fetch") .
5669                       " | " .
5670                       (defined $push ? $cgi->a({-href=> $push}, "push") : "push") .
5671                       "</td>";
5672
5673                 print "</tr>\n";
5674         }
5675
5676         if ($limited) {
5677                 print "<tr>\n" .
5678                       "<td colspan=\"3\">" .
5679                       $cgi->a({-href => href(action=>"remotes")}, "...") .
5680                       "</td>\n" . "</tr>\n";
5681         }
5682
5683         print "</table>";
5684 }
5685
5686 # Display remote heads grouped by remote, unless there are too many
5687 # remotes, in which case we only display the remote names
5688 sub git_remotes_body {
5689         my ($remotedata, $limit, $head) = @_;
5690         if ($limit and $limit < keys %$remotedata) {
5691                 git_remotes_list($remotedata, $limit);
5692         } else {
5693                 fill_remote_heads($remotedata);
5694                 while (my ($remote, $rdata) = each %$remotedata) {
5695                         git_print_section({-class=>"remote", -id=>$remote},
5696                                 ["remotes", $remote, $remote], sub {
5697                                         git_remote_block($remote, $rdata, $limit, $head);
5698                                 });
5699                 }
5700         }
5701 }
5702
5703 sub git_search_message {
5704         my %co = @_;
5705
5706         my $greptype;
5707         if ($searchtype eq 'commit') {
5708                 $greptype = "--grep=";
5709         } elsif ($searchtype eq 'author') {
5710                 $greptype = "--author=";
5711         } elsif ($searchtype eq 'committer') {
5712                 $greptype = "--committer=";
5713         }
5714         $greptype .= $searchtext;
5715         my @commitlist = parse_commits($hash, 101, (100 * $page), undef,
5716                                        $greptype, '--regexp-ignore-case',
5717                                        $search_use_regexp ? '--extended-regexp' : '--fixed-strings');
5718
5719         my $paging_nav = '';
5720         if ($page > 0) {
5721                 $paging_nav .=
5722                         $cgi->a({-href => href(-replay=>1, page=>undef)},
5723                                 "first") .
5724                         " &sdot; " .
5725                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
5726                                  -accesskey => "p", -title => "Alt-p"}, "prev");
5727         } else {
5728                 $paging_nav .= "first &sdot; prev";
5729         }
5730         my $next_link = '';
5731         if ($#commitlist >= 100) {
5732                 $next_link =
5733                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
5734                                  -accesskey => "n", -title => "Alt-n"}, "next");
5735                 $paging_nav .= " &sdot; $next_link";
5736         } else {
5737                 $paging_nav .= " &sdot; next";
5738         }
5739
5740         git_header_html();
5741
5742         git_print_page_nav('','', $hash,$co{'tree'},$hash, $paging_nav);
5743         git_print_header_div('commit', esc_html($co{'title'}), $hash);
5744         if ($page == 0 && !@commitlist) {
5745                 print "<p>No match.</p>\n";
5746         } else {
5747                 git_search_grep_body(\@commitlist, 0, 99, $next_link);
5748         }
5749
5750         git_footer_html();
5751 }
5752
5753 sub git_search_changes {
5754         my %co = @_;
5755
5756         local $/ = "\n";
5757         open my $fd, '-|', git_cmd(), '--no-pager', 'log', @diff_opts,
5758                 '--pretty=format:%H', '--no-abbrev', '--raw', "-S$searchtext",
5759                 ($search_use_regexp ? '--pickaxe-regex' : ())
5760                         or die_error(500, "Open git-log failed");
5761
5762         git_header_html();
5763
5764         git_print_page_nav('','', $hash,$co{'tree'},$hash);
5765         git_print_header_div('commit', esc_html($co{'title'}), $hash);
5766
5767         print "<table class=\"pickaxe search\">\n";
5768         my $alternate = 1;
5769         undef %co;
5770         my @files;
5771         while (my $line = <$fd>) {
5772                 chomp $line;
5773                 next unless $line;
5774
5775                 my %set = parse_difftree_raw_line($line);
5776                 if (defined $set{'commit'}) {
5777                         # finish previous commit
5778                         if (%co) {
5779                                 print "</td>\n" .
5780                                       "<td class=\"link\">" .
5781                                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
5782                                               "commit") .
5783                                       " | " .
5784                                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
5785                                                              hash_base=>$co{'id'})},
5786                                               "tree") .
5787                                       "</td>\n" .
5788                                       "</tr>\n";
5789                         }
5790
5791                         if ($alternate) {
5792                                 print "<tr class=\"dark\">\n";
5793                         } else {
5794                                 print "<tr class=\"light\">\n";
5795                         }
5796                         $alternate ^= 1;
5797                         %co = parse_commit($set{'commit'});
5798                         my $author = chop_and_escape_str($co{'author_name'}, 15, 5);
5799                         print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5800                               "<td><i>$author</i></td>\n" .
5801                               "<td>" .
5802                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
5803                                       -class => "list subject"},
5804                                       chop_and_escape_str($co{'title'}, 50) . "<br/>");
5805                 } elsif (defined $set{'to_id'}) {
5806                         next if ($set{'to_id'} =~ m/^0{40}$/);
5807
5808                         print $cgi->a({-href => href(action=>"blob", hash_base=>$co{'id'},
5809                                                      hash=>$set{'to_id'}, file_name=>$set{'to_file'}),
5810                                       -class => "list"},
5811                                       "<span class=\"match\">" . esc_path($set{'file'}) . "</span>") .
5812                               "<br/>\n";
5813                 }
5814         }
5815         close $fd;
5816
5817         # finish last commit (warning: repetition!)
5818         if (%co) {
5819                 print "</td>\n" .
5820                       "<td class=\"link\">" .
5821                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
5822                               "commit") .
5823                       " | " .
5824                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
5825                                              hash_base=>$co{'id'})},
5826                               "tree") .
5827                       "</td>\n" .
5828                       "</tr>\n";
5829         }
5830
5831         print "</table>\n";
5832
5833         git_footer_html();
5834 }
5835
5836 sub git_search_files {
5837         my %co = @_;
5838
5839         local $/ = "\n";
5840         open my $fd, "-|", git_cmd(), 'grep', '-n',
5841                 $search_use_regexp ? ('-E', '-i') : '-F',
5842                 $searchtext, $co{'tree'}
5843                         or die_error(500, "Open git-grep failed");
5844
5845         git_header_html();
5846
5847         git_print_page_nav('','', $hash,$co{'tree'},$hash);
5848         git_print_header_div('commit', esc_html($co{'title'}), $hash);
5849
5850         print "<table class=\"grep_search\">\n";
5851         my $alternate = 1;
5852         my $matches = 0;
5853         my $lastfile = '';
5854         while (my $line = <$fd>) {
5855                 chomp $line;
5856                 my ($file, $lno, $ltext, $binary);
5857                 last if ($matches++ > 1000);
5858                 if ($line =~ /^Binary file (.+) matches$/) {
5859                         $file = $1;
5860                         $binary = 1;
5861                 } else {
5862                         (undef, $file, $lno, $ltext) = split(/:/, $line, 4);
5863                 }
5864                 if ($file ne $lastfile) {
5865                         $lastfile and print "</td></tr>\n";
5866                         if ($alternate++) {
5867                                 print "<tr class=\"dark\">\n";
5868                         } else {
5869                                 print "<tr class=\"light\">\n";
5870                         }
5871                         print "<td class=\"list\">".
5872                                 $cgi->a({-href => href(action=>"blob", hash=>$co{'hash'},
5873                                                        file_name=>"$file"),
5874                                         -class => "list"}, esc_path($file));
5875                         print "</td><td>\n";
5876                         $lastfile = $file;
5877                 }
5878                 if ($binary) {
5879                         print "<div class=\"binary\">Binary file</div>\n";
5880                 } else {
5881                         $ltext = untabify($ltext);
5882                         if ($ltext =~ m/^(.*)($search_regexp)(.*)$/i) {
5883                                 $ltext = esc_html($1, -nbsp=>1);
5884                                 $ltext .= '<span class="match">';
5885                                 $ltext .= esc_html($2, -nbsp=>1);
5886                                 $ltext .= '</span>';
5887                                 $ltext .= esc_html($3, -nbsp=>1);
5888                         } else {
5889                                 $ltext = esc_html($ltext, -nbsp=>1);
5890                         }
5891                         print "<div class=\"pre\">" .
5892                                 $cgi->a({-href => href(action=>"blob", hash=>$co{'hash'},
5893                                                        file_name=>"$file").'#l'.$lno,
5894                                         -class => "linenr"}, sprintf('%4i', $lno))
5895                                 . ' ' .  $ltext . "</div>\n";
5896                 }
5897         }
5898         if ($lastfile) {
5899                 print "</td></tr>\n";
5900                 if ($matches > 1000) {
5901                         print "<div class=\"diff nodifferences\">Too many matches, listing trimmed</div>\n";
5902                 }
5903         } else {
5904                 print "<div class=\"diff nodifferences\">No matches found</div>\n";
5905         }
5906         close $fd;
5907
5908         print "</table>\n";
5909
5910         git_footer_html();
5911 }
5912
5913 sub git_search_grep_body {
5914         my ($commitlist, $from, $to, $extra) = @_;
5915         $from = 0 unless defined $from;
5916         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5917
5918         print "<table class=\"commit_search\">\n";
5919         my $alternate = 1;
5920         for (my $i = $from; $i <= $to; $i++) {
5921                 my %co = %{$commitlist->[$i]};
5922                 if (!%co) {
5923                         next;
5924                 }
5925                 my $commit = $co{'id'};
5926                 if ($alternate) {
5927                         print "<tr class=\"dark\">\n";
5928                 } else {
5929                         print "<tr class=\"light\">\n";
5930                 }
5931                 $alternate ^= 1;
5932                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5933                       format_author_html('td', \%co, 15, 5) .
5934                       "<td>" .
5935                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
5936                                -class => "list subject"},
5937                               chop_and_escape_str($co{'title'}, 50) . "<br/>");
5938                 my $comment = $co{'comment'};
5939                 foreach my $line (@$comment) {
5940                         if ($line =~ m/^(.*?)($search_regexp)(.*)$/i) {
5941                                 my ($lead, $match, $trail) = ($1, $2, $3);
5942                                 $match = chop_str($match, 70, 5, 'center');
5943                                 my $contextlen = int((80 - length($match))/2);
5944                                 $contextlen = 30 if ($contextlen > 30);
5945                                 $lead  = chop_str($lead,  $contextlen, 10, 'left');
5946                                 $trail = chop_str($trail, $contextlen, 10, 'right');
5947
5948                                 $lead  = esc_html($lead);
5949                                 $match = esc_html($match);
5950                                 $trail = esc_html($trail);
5951
5952                                 print "$lead<span class=\"match\">$match</span>$trail<br />";
5953                         }
5954                 }
5955                 print "</td>\n" .
5956                       "<td class=\"link\">" .
5957                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
5958                       " | " .
5959                       $cgi->a({-href => href(action=>"commitdiff", hash=>$co{'id'})}, "commitdiff") .
5960                       " | " .
5961                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
5962                 print "</td>\n" .
5963                       "</tr>\n";
5964         }
5965         if (defined $extra) {
5966                 print "<tr>\n" .
5967                       "<td colspan=\"3\">$extra</td>\n" .
5968                       "</tr>\n";
5969         }
5970         print "</table>\n";
5971 }
5972
5973 ## ======================================================================
5974 ## ======================================================================
5975 ## actions
5976
5977 sub git_project_list {
5978         my $order = $input_params{'order'};
5979         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
5980                 die_error(400, "Unknown order parameter");
5981         }
5982
5983         my @list = git_get_projects_list();
5984         if (!@list) {
5985                 die_error(404, "No projects found");
5986         }
5987
5988         git_header_html();
5989         if (defined $home_text && -f $home_text) {
5990                 print "<div class=\"index_include\">\n";
5991                 insert_file($home_text);
5992                 print "</div>\n";
5993         }
5994         print $cgi->startform(-method => "get") .
5995               "<p class=\"projsearch\">Search:\n" .
5996               $cgi->textfield(-name => "s", -value => $searchtext) . "\n" .
5997               "</p>" .
5998               $cgi->end_form() . "\n";
5999         git_project_list_body(\@list, $order);
6000         git_footer_html();
6001 }
6002
6003 sub git_forks {
6004         my $order = $input_params{'order'};
6005         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
6006                 die_error(400, "Unknown order parameter");
6007         }
6008
6009         my @list = git_get_projects_list($project);
6010         if (!@list) {
6011                 die_error(404, "No forks found");
6012         }
6013
6014         git_header_html();
6015         git_print_page_nav('','');
6016         git_print_header_div('summary', "$project forks");
6017         git_project_list_body(\@list, $order);
6018         git_footer_html();
6019 }
6020
6021 sub git_project_index {
6022         my @projects = git_get_projects_list();
6023         if (!@projects) {
6024                 die_error(404, "No projects found");
6025         }
6026
6027         print $cgi->header(
6028                 -type => 'text/plain',
6029                 -charset => 'utf-8',
6030                 -content_disposition => 'inline; filename="index.aux"');
6031
6032         foreach my $pr (@projects) {
6033                 if (!exists $pr->{'owner'}) {
6034                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}");
6035                 }
6036
6037                 my ($path, $owner) = ($pr->{'path'}, $pr->{'owner'});
6038                 # quote as in CGI::Util::encode, but keep the slash, and use '+' for ' '
6039                 $path  =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
6040                 $owner =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
6041                 $path  =~ s/ /\+/g;
6042                 $owner =~ s/ /\+/g;
6043
6044                 print "$path $owner\n";
6045         }
6046 }
6047
6048 sub git_summary {
6049         my $descr = git_get_project_description($project) || "none";
6050         my %co = parse_commit("HEAD");
6051         my %cd = %co ? parse_date($co{'committer_epoch'}, $co{'committer_tz'}) : ();
6052         my $head = $co{'id'};
6053         my $remote_heads = gitweb_check_feature('remote_heads');
6054
6055         my $owner = git_get_project_owner($project);
6056
6057         my $refs = git_get_references();
6058         # These get_*_list functions return one more to allow us to see if
6059         # there are more ...
6060         my @taglist  = git_get_tags_list(16);
6061         my @headlist = git_get_heads_list(16);
6062         my %remotedata = $remote_heads ? git_get_remotes_list() : ();
6063         my @forklist;
6064         my $check_forks = gitweb_check_feature('forks');
6065
6066         if ($check_forks) {
6067                 # find forks of a project
6068                 @forklist = git_get_projects_list($project);
6069                 # filter out forks of forks
6070                 @forklist = filter_forks_from_projects_list(\@forklist)
6071                         if (@forklist);
6072         }
6073
6074         git_header_html();
6075         git_print_page_nav('summary','', $head);
6076
6077         print "<div class=\"title\">&nbsp;</div>\n";
6078         print "<table class=\"projects_list\">\n" .
6079               "<tr id=\"metadata_desc\"><td>description</td><td>" . esc_html($descr) . "</td></tr>\n" .
6080               "<tr id=\"metadata_owner\"><td>owner</td><td>" . esc_html($owner) . "</td></tr>\n";
6081         if (defined $cd{'rfc2822'}) {
6082                 print "<tr id=\"metadata_lchange\"><td>last change</td>" .
6083                       "<td>".format_timestamp_html(\%cd)."</td></tr>\n";
6084         }
6085
6086         # use per project git URL list in $projectroot/$project/cloneurl
6087         # or make project git URL from git base URL and project name
6088         my $url_tag = "URL";
6089         my @url_list = git_get_project_url_list($project);
6090         @url_list = map { "$_/$project" } @git_base_url_list unless @url_list;
6091         foreach my $git_url (@url_list) {
6092                 next unless $git_url;
6093                 print format_repo_url($url_tag, $git_url);
6094                 $url_tag = "";
6095         }
6096
6097         # Tag cloud
6098         my $show_ctags = gitweb_check_feature('ctags');
6099         if ($show_ctags) {
6100                 my $ctags = git_get_project_ctags($project);
6101                 if (%$ctags) {
6102                         # without ability to add tags, don't show if there are none
6103                         my $cloud = git_populate_project_tagcloud($ctags);
6104                         print "<tr id=\"metadata_ctags\">" .
6105                               "<td>content tags</td>" .
6106                               "<td>".git_show_project_tagcloud($cloud, 48)."</td>" .
6107                               "</tr>\n";
6108                 }
6109         }
6110
6111         print "</table>\n";
6112
6113         # If XSS prevention is on, we don't include README.html.
6114         # TODO: Allow a readme in some safe format.
6115         if (!$prevent_xss && -s "$projectroot/$project/README.html") {
6116                 print "<div class=\"title\">readme</div>\n" .
6117                       "<div class=\"readme\">\n";
6118                 insert_file("$projectroot/$project/README.html");
6119                 print "\n</div>\n"; # class="readme"
6120         }
6121
6122         # we need to request one more than 16 (0..15) to check if
6123         # those 16 are all
6124         my @commitlist = $head ? parse_commits($head, 17) : ();
6125         if (@commitlist) {
6126                 git_print_header_div('shortlog');
6127                 git_shortlog_body(\@commitlist, 0, 15, $refs,
6128                                   $#commitlist <=  15 ? undef :
6129                                   $cgi->a({-href => href(action=>"shortlog")}, "..."));
6130         }
6131
6132         if (@taglist) {
6133                 git_print_header_div('tags');
6134                 git_tags_body(\@taglist, 0, 15,
6135                               $#taglist <=  15 ? undef :
6136                               $cgi->a({-href => href(action=>"tags")}, "..."));
6137         }
6138
6139         if (@headlist) {
6140                 git_print_header_div('heads');
6141                 git_heads_body(\@headlist, $head, 0, 15,
6142                                $#headlist <= 15 ? undef :
6143                                $cgi->a({-href => href(action=>"heads")}, "..."));
6144         }
6145
6146         if (%remotedata) {
6147                 git_print_header_div('remotes');
6148                 git_remotes_body(\%remotedata, 15, $head);
6149         }
6150
6151         if (@forklist) {
6152                 git_print_header_div('forks');
6153                 git_project_list_body(\@forklist, 'age', 0, 15,
6154                                       $#forklist <= 15 ? undef :
6155                                       $cgi->a({-href => href(action=>"forks")}, "..."),
6156                                       'no_header');
6157         }
6158
6159         git_footer_html();
6160 }
6161
6162 sub git_tag {
6163         my %tag = parse_tag($hash);
6164
6165         if (! %tag) {
6166                 die_error(404, "Unknown tag object");
6167         }
6168
6169         my $head = git_get_head_hash($project);
6170         git_header_html();
6171         git_print_page_nav('','', $head,undef,$head);
6172         git_print_header_div('commit', esc_html($tag{'name'}), $hash);
6173         print "<div class=\"title_text\">\n" .
6174               "<table class=\"object_header\">\n" .
6175               "<tr>\n" .
6176               "<td>object</td>\n" .
6177               "<td>" . $cgi->a({-class => "list", -href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6178                                $tag{'object'}) . "</td>\n" .
6179               "<td class=\"link\">" . $cgi->a({-href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6180                                               $tag{'type'}) . "</td>\n" .
6181               "</tr>\n";
6182         if (defined($tag{'author'})) {
6183                 git_print_authorship_rows(\%tag, 'author');
6184         }
6185         print "</table>\n\n" .
6186               "</div>\n";
6187         print "<div class=\"page_body\">";
6188         my $comment = $tag{'comment'};
6189         foreach my $line (@$comment) {
6190                 chomp $line;
6191                 print esc_html($line, -nbsp=>1) . "<br/>\n";
6192         }
6193         print "</div>\n";
6194         git_footer_html();
6195 }
6196
6197 sub git_blame_common {
6198         my $format = shift || 'porcelain';
6199         if ($format eq 'porcelain' && $cgi->param('js')) {
6200                 $format = 'incremental';
6201                 $action = 'blame_incremental'; # for page title etc
6202         }
6203
6204         # permissions
6205         gitweb_check_feature('blame')
6206                 or die_error(403, "Blame view not allowed");
6207
6208         # error checking
6209         die_error(400, "No file name given") unless $file_name;
6210         $hash_base ||= git_get_head_hash($project);
6211         die_error(404, "Couldn't find base commit") unless $hash_base;
6212         my %co = parse_commit($hash_base)
6213                 or die_error(404, "Commit not found");
6214         my $ftype = "blob";
6215         if (!defined $hash) {
6216                 $hash = git_get_hash_by_path($hash_base, $file_name, "blob")
6217                         or die_error(404, "Error looking up file");
6218         } else {
6219                 $ftype = git_get_type($hash);
6220                 if ($ftype !~ "blob") {
6221                         die_error(400, "Object is not a blob");
6222                 }
6223         }
6224
6225         my $fd;
6226         if ($format eq 'incremental') {
6227                 # get file contents (as base)
6228                 open $fd, "-|", git_cmd(), 'cat-file', 'blob', $hash
6229                         or die_error(500, "Open git-cat-file failed");
6230         } elsif ($format eq 'data') {
6231                 # run git-blame --incremental
6232                 open $fd, "-|", git_cmd(), "blame", "--incremental",
6233                         $hash_base, "--", $file_name
6234                         or die_error(500, "Open git-blame --incremental failed");
6235         } else {
6236                 # run git-blame --porcelain
6237                 open $fd, "-|", git_cmd(), "blame", '-p',
6238                         $hash_base, '--', $file_name
6239                         or die_error(500, "Open git-blame --porcelain failed");
6240         }
6241
6242         # incremental blame data returns early
6243         if ($format eq 'data') {
6244                 print $cgi->header(
6245                         -type=>"text/plain", -charset => "utf-8",
6246                         -status=> "200 OK");
6247                 local $| = 1; # output autoflush
6248                 print while <$fd>;
6249                 close $fd
6250                         or print "ERROR $!\n";
6251
6252                 print 'END';
6253                 if (defined $t0 && gitweb_check_feature('timed')) {
6254                         print ' '.
6255                               tv_interval($t0, [ gettimeofday() ]).
6256                               ' '.$number_of_git_cmds;
6257                 }
6258                 print "\n";
6259
6260                 return;
6261         }
6262
6263         # page header
6264         git_header_html();
6265         my $formats_nav =
6266                 $cgi->a({-href => href(action=>"blob", -replay=>1)},
6267                         "blob") .
6268                 " | ";
6269         if ($format eq 'incremental') {
6270                 $formats_nav .=
6271                         $cgi->a({-href => href(action=>"blame", javascript=>0, -replay=>1)},
6272                                 "blame") . " (non-incremental)";
6273         } else {
6274                 $formats_nav .=
6275                         $cgi->a({-href => href(action=>"blame_incremental", -replay=>1)},
6276                                 "blame") . " (incremental)";
6277         }
6278         $formats_nav .=
6279                 " | " .
6280                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6281                         "history") .
6282                 " | " .
6283                 $cgi->a({-href => href(action=>$action, file_name=>$file_name)},
6284                         "HEAD");
6285         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6286         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6287         git_print_page_path($file_name, $ftype, $hash_base);
6288
6289         # page body
6290         if ($format eq 'incremental') {
6291                 print "<noscript>\n<div class=\"error\"><center><b>\n".
6292                       "This page requires JavaScript to run.\n Use ".
6293                       $cgi->a({-href => href(action=>'blame',javascript=>0,-replay=>1)},
6294                               'this page').
6295                       " instead.\n".
6296                       "</b></center></div>\n</noscript>\n";
6297
6298                 print qq!<div id="progress_bar" style="width: 100%; background-color: yellow"></div>\n!;
6299         }
6300
6301         print qq!<div class="page_body">\n!;
6302         print qq!<div id="progress_info">... / ...</div>\n!
6303                 if ($format eq 'incremental');
6304         print qq!<table id="blame_table" class="blame" width="100%">\n!.
6305               #qq!<col width="5.5em" /><col width="2.5em" /><col width="*" />\n!.
6306               qq!<thead>\n!.
6307               qq!<tr><th>Commit</th><th>Line</th><th>Data</th></tr>\n!.
6308               qq!</thead>\n!.
6309               qq!<tbody>\n!;
6310
6311         my @rev_color = qw(light dark);
6312         my $num_colors = scalar(@rev_color);
6313         my $current_color = 0;
6314
6315         if ($format eq 'incremental') {
6316                 my $color_class = $rev_color[$current_color];
6317
6318                 #contents of a file
6319                 my $linenr = 0;
6320         LINE:
6321                 while (my $line = <$fd>) {
6322                         chomp $line;
6323                         $linenr++;
6324
6325                         print qq!<tr id="l$linenr" class="$color_class">!.
6326                               qq!<td class="sha1"><a href=""> </a></td>!.
6327                               qq!<td class="linenr">!.
6328                               qq!<a class="linenr" href="">$linenr</a></td>!;
6329                         print qq!<td class="pre">! . esc_html($line) . "</td>\n";
6330                         print qq!</tr>\n!;
6331                 }
6332
6333         } else { # porcelain, i.e. ordinary blame
6334                 my %metainfo = (); # saves information about commits
6335
6336                 # blame data
6337         LINE:
6338                 while (my $line = <$fd>) {
6339                         chomp $line;
6340                         # the header: <SHA-1> <src lineno> <dst lineno> [<lines in group>]
6341                         # no <lines in group> for subsequent lines in group of lines
6342                         my ($full_rev, $orig_lineno, $lineno, $group_size) =
6343                            ($line =~ /^([0-9a-f]{40}) (\d+) (\d+)(?: (\d+))?$/);
6344                         if (!exists $metainfo{$full_rev}) {
6345                                 $metainfo{$full_rev} = { 'nprevious' => 0 };
6346                         }
6347                         my $meta = $metainfo{$full_rev};
6348                         my $data;
6349                         while ($data = <$fd>) {
6350                                 chomp $data;
6351                                 last if ($data =~ s/^\t//); # contents of line
6352                                 if ($data =~ /^(\S+)(?: (.*))?$/) {
6353                                         $meta->{$1} = $2 unless exists $meta->{$1};
6354                                 }
6355                                 if ($data =~ /^previous /) {
6356                                         $meta->{'nprevious'}++;
6357                                 }
6358                         }
6359                         my $short_rev = substr($full_rev, 0, 8);
6360                         my $author = $meta->{'author'};
6361                         my %date =
6362                                 parse_date($meta->{'author-time'}, $meta->{'author-tz'});
6363                         my $date = $date{'iso-tz'};
6364                         if ($group_size) {
6365                                 $current_color = ($current_color + 1) % $num_colors;
6366                         }
6367                         my $tr_class = $rev_color[$current_color];
6368                         $tr_class .= ' boundary' if (exists $meta->{'boundary'});
6369                         $tr_class .= ' no-previous' if ($meta->{'nprevious'} == 0);
6370                         $tr_class .= ' multiple-previous' if ($meta->{'nprevious'} > 1);
6371                         print "<tr id=\"l$lineno\" class=\"$tr_class\">\n";
6372                         if ($group_size) {
6373                                 print "<td class=\"sha1\"";
6374                                 print " title=\"". esc_html($author) . ", $date\"";
6375                                 print " rowspan=\"$group_size\"" if ($group_size > 1);
6376                                 print ">";
6377                                 print $cgi->a({-href => href(action=>"commit",
6378                                                              hash=>$full_rev,
6379                                                              file_name=>$file_name)},
6380                                               esc_html($short_rev));
6381                                 if ($group_size >= 2) {
6382                                         my @author_initials = ($author =~ /\b([[:upper:]])\B/g);
6383                                         if (@author_initials) {
6384                                                 print "<br />" .
6385                                                       esc_html(join('', @author_initials));
6386                                                 #           or join('.', ...)
6387                                         }
6388                                 }
6389                                 print "</td>\n";
6390                         }
6391                         # 'previous' <sha1 of parent commit> <filename at commit>
6392                         if (exists $meta->{'previous'} &&
6393                             $meta->{'previous'} =~ /^([a-fA-F0-9]{40}) (.*)$/) {
6394                                 $meta->{'parent'} = $1;
6395                                 $meta->{'file_parent'} = unquote($2);
6396                         }
6397                         my $linenr_commit =
6398                                 exists($meta->{'parent'}) ?
6399                                 $meta->{'parent'} : $full_rev;
6400                         my $linenr_filename =
6401                                 exists($meta->{'file_parent'}) ?
6402                                 $meta->{'file_parent'} : unquote($meta->{'filename'});
6403                         my $blamed = href(action => 'blame',
6404                                           file_name => $linenr_filename,
6405                                           hash_base => $linenr_commit);
6406                         print "<td class=\"linenr\">";
6407                         print $cgi->a({ -href => "$blamed#l$orig_lineno",
6408                                         -class => "linenr" },
6409                                       esc_html($lineno));
6410                         print "</td>";
6411                         print "<td class=\"pre\">" . esc_html($data) . "</td>\n";
6412                         print "</tr>\n";
6413                 } # end while
6414
6415         }
6416
6417         # footer
6418         print "</tbody>\n".
6419               "</table>\n"; # class="blame"
6420         print "</div>\n";   # class="blame_body"
6421         close $fd
6422                 or print "Reading blob failed\n";
6423
6424         git_footer_html();
6425 }
6426
6427 sub git_blame {
6428         git_blame_common();
6429 }
6430
6431 sub git_blame_incremental {
6432         git_blame_common('incremental');
6433 }
6434
6435 sub git_blame_data {
6436         git_blame_common('data');
6437 }
6438
6439 sub git_tags {
6440         my $head = git_get_head_hash($project);
6441         git_header_html();
6442         git_print_page_nav('','', $head,undef,$head,format_ref_views('tags'));
6443         git_print_header_div('summary', $project);
6444
6445         my @tagslist = git_get_tags_list();
6446         if (@tagslist) {
6447                 git_tags_body(\@tagslist);
6448         }
6449         git_footer_html();
6450 }
6451
6452 sub git_heads {
6453         my $head = git_get_head_hash($project);
6454         git_header_html();
6455         git_print_page_nav('','', $head,undef,$head,format_ref_views('heads'));
6456         git_print_header_div('summary', $project);
6457
6458         my @headslist = git_get_heads_list();
6459         if (@headslist) {
6460                 git_heads_body(\@headslist, $head);
6461         }
6462         git_footer_html();
6463 }
6464
6465 # used both for single remote view and for list of all the remotes
6466 sub git_remotes {
6467         gitweb_check_feature('remote_heads')
6468                 or die_error(403, "Remote heads view is disabled");
6469
6470         my $head = git_get_head_hash($project);
6471         my $remote = $input_params{'hash'};
6472
6473         my $remotedata = git_get_remotes_list($remote);
6474         die_error(500, "Unable to get remote information") unless defined $remotedata;
6475
6476         unless (%$remotedata) {
6477                 die_error(404, defined $remote ?
6478                         "Remote $remote not found" :
6479                         "No remotes found");
6480         }
6481
6482         git_header_html(undef, undef, -action_extra => $remote);
6483         git_print_page_nav('', '',  $head, undef, $head,
6484                 format_ref_views($remote ? '' : 'remotes'));
6485
6486         fill_remote_heads($remotedata);
6487         if (defined $remote) {
6488                 git_print_header_div('remotes', "$remote remote for $project");
6489                 git_remote_block($remote, $remotedata->{$remote}, undef, $head);
6490         } else {
6491                 git_print_header_div('summary', "$project remotes");
6492                 git_remotes_body($remotedata, undef, $head);
6493         }
6494
6495         git_footer_html();
6496 }
6497
6498 sub git_blob_plain {
6499         my $type = shift;
6500         my $expires;
6501
6502         if (!defined $hash) {
6503                 if (defined $file_name) {
6504                         my $base = $hash_base || git_get_head_hash($project);
6505                         $hash = git_get_hash_by_path($base, $file_name, "blob")
6506                                 or die_error(404, "Cannot find file");
6507                 } else {
6508                         die_error(400, "No file name defined");
6509                 }
6510         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6511                 # blobs defined by non-textual hash id's can be cached
6512                 $expires = "+1d";
6513         }
6514
6515         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
6516                 or die_error(500, "Open git-cat-file blob '$hash' failed");
6517
6518         # content-type (can include charset)
6519         $type = blob_contenttype($fd, $file_name, $type);
6520
6521         # "save as" filename, even when no $file_name is given
6522         my $save_as = "$hash";
6523         if (defined $file_name) {
6524                 $save_as = $file_name;
6525         } elsif ($type =~ m/^text\//) {
6526                 $save_as .= '.txt';
6527         }
6528
6529         # With XSS prevention on, blobs of all types except a few known safe
6530         # ones are served with "Content-Disposition: attachment" to make sure
6531         # they don't run in our security domain.  For certain image types,
6532         # blob view writes an <img> tag referring to blob_plain view, and we
6533         # want to be sure not to break that by serving the image as an
6534         # attachment (though Firefox 3 doesn't seem to care).
6535         my $sandbox = $prevent_xss &&
6536                 $type !~ m!^(?:text/[a-z]+|image/(?:gif|png|jpeg))(?:[ ;]|$)!;
6537
6538         # serve text/* as text/plain
6539         if ($prevent_xss &&
6540             ($type =~ m!^text/[a-z]+\b(.*)$! ||
6541              ($type =~ m!^[a-z]+/[a-z]\+xml\b(.*)$! && -T $fd))) {
6542                 my $rest = $1;
6543                 $rest = defined $rest ? $rest : '';
6544                 $type = "text/plain$rest";
6545         }
6546
6547         print $cgi->header(
6548                 -type => $type,
6549                 -expires => $expires,
6550                 -content_disposition =>
6551                         ($sandbox ? 'attachment' : 'inline')
6552                         . '; filename="' . $save_as . '"');
6553         local $/ = undef;
6554         binmode STDOUT, ':raw';
6555         print <$fd>;
6556         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
6557         close $fd;
6558 }
6559
6560 sub git_blob {
6561         my $expires;
6562
6563         if (!defined $hash) {
6564                 if (defined $file_name) {
6565                         my $base = $hash_base || git_get_head_hash($project);
6566                         $hash = git_get_hash_by_path($base, $file_name, "blob")
6567                                 or die_error(404, "Cannot find file");
6568                 } else {
6569                         die_error(400, "No file name defined");
6570                 }
6571         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6572                 # blobs defined by non-textual hash id's can be cached
6573                 $expires = "+1d";
6574         }
6575
6576         my $have_blame = gitweb_check_feature('blame');
6577         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
6578                 or die_error(500, "Couldn't cat $file_name, $hash");
6579         my $mimetype = blob_mimetype($fd, $file_name);
6580         # use 'blob_plain' (aka 'raw') view for files that cannot be displayed
6581         if ($mimetype !~ m!^(?:text/|image/(?:gif|png|jpeg)$)! && -B $fd) {
6582                 close $fd;
6583                 return git_blob_plain($mimetype);
6584         }
6585         # we can have blame only for text/* mimetype
6586         $have_blame &&= ($mimetype =~ m!^text/!);
6587
6588         my $highlight = gitweb_check_feature('highlight');
6589         my $syntax = guess_file_syntax($highlight, $mimetype, $file_name);
6590         $fd = run_highlighter($fd, $highlight, $syntax)
6591                 if $syntax;
6592
6593         git_header_html(undef, $expires);
6594         my $formats_nav = '';
6595         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
6596                 if (defined $file_name) {
6597                         if ($have_blame) {
6598                                 $formats_nav .=
6599                                         $cgi->a({-href => href(action=>"blame", -replay=>1)},
6600                                                 "blame") .
6601                                         " | ";
6602                         }
6603                         $formats_nav .=
6604                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6605                                         "history") .
6606                                 " | " .
6607                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
6608                                         "raw") .
6609                                 " | " .
6610                                 $cgi->a({-href => href(action=>"blob",
6611                                                        hash_base=>"HEAD", file_name=>$file_name)},
6612                                         "HEAD");
6613                 } else {
6614                         $formats_nav .=
6615                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
6616                                         "raw");
6617                 }
6618                 git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6619                 git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6620         } else {
6621                 print "<div class=\"page_nav\">\n" .
6622                       "<br/><br/></div>\n" .
6623                       "<div class=\"title\">".esc_html($hash)."</div>\n";
6624         }
6625         git_print_page_path($file_name, "blob", $hash_base);
6626         print "<div class=\"page_body\">\n";
6627         if ($mimetype =~ m!^image/!) {
6628                 print qq!<img type="!.esc_attr($mimetype).qq!"!;
6629                 if ($file_name) {
6630                         print qq! alt="!.esc_attr($file_name).qq!" title="!.esc_attr($file_name).qq!"!;
6631                 }
6632                 print qq! src="! .
6633                       href(action=>"blob_plain", hash=>$hash,
6634                            hash_base=>$hash_base, file_name=>$file_name) .
6635                       qq!" />\n!;
6636         } else {
6637                 my $nr;
6638                 while (my $line = <$fd>) {
6639                         chomp $line;
6640                         $nr++;
6641                         $line = untabify($line);
6642                         printf qq!<div class="pre"><a id="l%i" href="%s#l%i" class="linenr">%4i</a> %s</div>\n!,
6643                                $nr, esc_attr(href(-replay => 1)), $nr, $nr,
6644                                $syntax ? sanitize($line) : esc_html($line, -nbsp=>1);
6645                 }
6646         }
6647         close $fd
6648                 or print "Reading blob failed.\n";
6649         print "</div>";
6650         git_footer_html();
6651 }
6652
6653 sub git_tree {
6654         if (!defined $hash_base) {
6655                 $hash_base = "HEAD";
6656         }
6657         if (!defined $hash) {
6658                 if (defined $file_name) {
6659                         $hash = git_get_hash_by_path($hash_base, $file_name, "tree");
6660                 } else {
6661                         $hash = $hash_base;
6662                 }
6663         }
6664         die_error(404, "No such tree") unless defined($hash);
6665
6666         my $show_sizes = gitweb_check_feature('show-sizes');
6667         my $have_blame = gitweb_check_feature('blame');
6668
6669         my @entries = ();
6670         {
6671                 local $/ = "\0";
6672                 open my $fd, "-|", git_cmd(), "ls-tree", '-z',
6673                         ($show_sizes ? '-l' : ()), @extra_options, $hash
6674                         or die_error(500, "Open git-ls-tree failed");
6675                 @entries = map { chomp; $_ } <$fd>;
6676                 close $fd
6677                         or die_error(404, "Reading tree failed");
6678         }
6679
6680         my $refs = git_get_references();
6681         my $ref = format_ref_marker($refs, $hash_base);
6682         git_header_html();
6683         my $basedir = '';
6684         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
6685                 my @views_nav = ();
6686                 if (defined $file_name) {
6687                         push @views_nav,
6688                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6689                                         "history"),
6690                                 $cgi->a({-href => href(action=>"tree",
6691                                                        hash_base=>"HEAD", file_name=>$file_name)},
6692                                         "HEAD"),
6693                 }
6694                 my $snapshot_links = format_snapshot_links($hash);
6695                 if (defined $snapshot_links) {
6696                         # FIXME: Should be available when we have no hash base as well.
6697                         push @views_nav, $snapshot_links;
6698                 }
6699                 git_print_page_nav('tree','', $hash_base, undef, undef,
6700                                    join(' | ', @views_nav));
6701                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash_base);
6702         } else {
6703                 undef $hash_base;
6704                 print "<div class=\"page_nav\">\n";
6705                 print "<br/><br/></div>\n";
6706                 print "<div class=\"title\">".esc_html($hash)."</div>\n";
6707         }
6708         if (defined $file_name) {
6709                 $basedir = $file_name;
6710                 if ($basedir ne '' && substr($basedir, -1) ne '/') {
6711                         $basedir .= '/';
6712                 }
6713                 git_print_page_path($file_name, 'tree', $hash_base);
6714         }
6715         print "<div class=\"page_body\">\n";
6716         print "<table class=\"tree\">\n";
6717         my $alternate = 1;
6718         # '..' (top directory) link if possible
6719         if (defined $hash_base &&
6720             defined $file_name && $file_name =~ m![^/]+$!) {
6721                 if ($alternate) {
6722                         print "<tr class=\"dark\">\n";
6723                 } else {
6724                         print "<tr class=\"light\">\n";
6725                 }
6726                 $alternate ^= 1;
6727
6728                 my $up = $file_name;
6729                 $up =~ s!/?[^/]+$!!;
6730                 undef $up unless $up;
6731                 # based on git_print_tree_entry
6732                 print '<td class="mode">' . mode_str('040000') . "</td>\n";
6733                 print '<td class="size">&nbsp;</td>'."\n" if $show_sizes;
6734                 print '<td class="list">';
6735                 print $cgi->a({-href => href(action=>"tree",
6736                                              hash_base=>$hash_base,
6737                                              file_name=>$up)},
6738                               "..");
6739                 print "</td>\n";
6740                 print "<td class=\"link\"></td>\n";
6741
6742                 print "</tr>\n";
6743         }
6744         foreach my $line (@entries) {
6745                 my %t = parse_ls_tree_line($line, -z => 1, -l => $show_sizes);
6746
6747                 if ($alternate) {
6748                         print "<tr class=\"dark\">\n";
6749                 } else {
6750                         print "<tr class=\"light\">\n";
6751                 }
6752                 $alternate ^= 1;
6753
6754                 git_print_tree_entry(\%t, $basedir, $hash_base, $have_blame);
6755
6756                 print "</tr>\n";
6757         }
6758         print "</table>\n" .
6759               "</div>";
6760         git_footer_html();
6761 }
6762
6763 sub snapshot_name {
6764         my ($project, $hash) = @_;
6765
6766         # path/to/project.git  -> project
6767         # path/to/project/.git -> project
6768         my $name = to_utf8($project);
6769         $name =~ s,([^/])/*\.git$,$1,;
6770         $name = basename($name);
6771         # sanitize name
6772         $name =~ s/[[:cntrl:]]/?/g;
6773
6774         my $ver = $hash;
6775         if ($hash =~ /^[0-9a-fA-F]+$/) {
6776                 # shorten SHA-1 hash
6777                 my $full_hash = git_get_full_hash($project, $hash);
6778                 if ($full_hash =~ /^$hash/ && length($hash) > 7) {
6779                         $ver = git_get_short_hash($project, $hash);
6780                 }
6781         } elsif ($hash =~ m!^refs/tags/(.*)$!) {
6782                 # tags don't need shortened SHA-1 hash
6783                 $ver = $1;
6784         } else {
6785                 # branches and other need shortened SHA-1 hash
6786                 if ($hash =~ m!^refs/(?:heads|remotes)/(.*)$!) {
6787                         $ver = $1;
6788                 }
6789                 $ver .= '-' . git_get_short_hash($project, $hash);
6790         }
6791         # in case of hierarchical branch names
6792         $ver =~ s!/!.!g;
6793
6794         # name = project-version_string
6795         $name = "$name-$ver";
6796
6797         return wantarray ? ($name, $name) : $name;
6798 }
6799
6800 sub git_snapshot {
6801         my $format = $input_params{'snapshot_format'};
6802         if (!@snapshot_fmts) {
6803                 die_error(403, "Snapshots not allowed");
6804         }
6805         # default to first supported snapshot format
6806         $format ||= $snapshot_fmts[0];
6807         if ($format !~ m/^[a-z0-9]+$/) {
6808                 die_error(400, "Invalid snapshot format parameter");
6809         } elsif (!exists($known_snapshot_formats{$format})) {
6810                 die_error(400, "Unknown snapshot format");
6811         } elsif ($known_snapshot_formats{$format}{'disabled'}) {
6812                 die_error(403, "Snapshot format not allowed");
6813         } elsif (!grep($_ eq $format, @snapshot_fmts)) {
6814                 die_error(403, "Unsupported snapshot format");
6815         }
6816
6817         my $type = git_get_type("$hash^{}");
6818         if (!$type) {
6819                 die_error(404, 'Object does not exist');
6820         }  elsif ($type eq 'blob') {
6821                 die_error(400, 'Object is not a tree-ish');
6822         }
6823
6824         my ($name, $prefix) = snapshot_name($project, $hash);
6825         my $filename = "$name$known_snapshot_formats{$format}{'suffix'}";
6826         my $cmd = quote_command(
6827                 git_cmd(), 'archive',
6828                 "--format=$known_snapshot_formats{$format}{'format'}",
6829                 "--prefix=$prefix/", $hash);
6830         if (exists $known_snapshot_formats{$format}{'compressor'}) {
6831                 $cmd .= ' | ' . quote_command(@{$known_snapshot_formats{$format}{'compressor'}});
6832         }
6833
6834         $filename =~ s/(["\\])/\\$1/g;
6835         print $cgi->header(
6836                 -type => $known_snapshot_formats{$format}{'type'},
6837                 -content_disposition => 'inline; filename="' . $filename . '"',
6838                 -status => '200 OK');
6839
6840         open my $fd, "-|", $cmd
6841                 or die_error(500, "Execute git-archive failed");
6842         binmode STDOUT, ':raw';
6843         print <$fd>;
6844         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
6845         close $fd;
6846 }
6847
6848 sub git_log_generic {
6849         my ($fmt_name, $body_subr, $base, $parent, $file_name, $file_hash) = @_;
6850
6851         my $head = git_get_head_hash($project);
6852         if (!defined $base) {
6853                 $base = $head;
6854         }
6855         if (!defined $page) {
6856                 $page = 0;
6857         }
6858         my $refs = git_get_references();
6859
6860         my $commit_hash = $base;
6861         if (defined $parent) {
6862                 $commit_hash = "$parent..$base";
6863         }
6864         my @commitlist =
6865                 parse_commits($commit_hash, 101, (100 * $page),
6866                               defined $file_name ? ($file_name, "--full-history") : ());
6867
6868         my $ftype;
6869         if (!defined $file_hash && defined $file_name) {
6870                 # some commits could have deleted file in question,
6871                 # and not have it in tree, but one of them has to have it
6872                 for (my $i = 0; $i < @commitlist; $i++) {
6873                         $file_hash = git_get_hash_by_path($commitlist[$i]{'id'}, $file_name);
6874                         last if defined $file_hash;
6875                 }
6876         }
6877         if (defined $file_hash) {
6878                 $ftype = git_get_type($file_hash);
6879         }
6880         if (defined $file_name && !defined $ftype) {
6881                 die_error(500, "Unknown type of object");
6882         }
6883         my %co;
6884         if (defined $file_name) {
6885                 %co = parse_commit($base)
6886                         or die_error(404, "Unknown commit object");
6887         }
6888
6889
6890         my $paging_nav = format_paging_nav($fmt_name, $page, $#commitlist >= 100);
6891         my $next_link = '';
6892         if ($#commitlist >= 100) {
6893                 $next_link =
6894                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
6895                                  -accesskey => "n", -title => "Alt-n"}, "next");
6896         }
6897         my $patch_max = gitweb_get_feature('patches');
6898         if ($patch_max && !defined $file_name) {
6899                 if ($patch_max < 0 || @commitlist <= $patch_max) {
6900                         $paging_nav .= " &sdot; " .
6901                                 $cgi->a({-href => href(action=>"patches", -replay=>1)},
6902                                         "patches");
6903                 }
6904         }
6905
6906         git_header_html();
6907         git_print_page_nav($fmt_name,'', $hash,$hash,$hash, $paging_nav);
6908         if (defined $file_name) {
6909                 git_print_header_div('commit', esc_html($co{'title'}), $base);
6910         } else {
6911                 git_print_header_div('summary', $project)
6912         }
6913         git_print_page_path($file_name, $ftype, $hash_base)
6914                 if (defined $file_name);
6915
6916         $body_subr->(\@commitlist, 0, 99, $refs, $next_link,
6917                      $file_name, $file_hash, $ftype);
6918
6919         git_footer_html();
6920 }
6921
6922 sub git_log {
6923         git_log_generic('log', \&git_log_body,
6924                         $hash, $hash_parent);
6925 }
6926
6927 sub git_commit {
6928         $hash ||= $hash_base || "HEAD";
6929         my %co = parse_commit($hash)
6930             or die_error(404, "Unknown commit object");
6931
6932         my $parent  = $co{'parent'};
6933         my $parents = $co{'parents'}; # listref
6934
6935         # we need to prepare $formats_nav before any parameter munging
6936         my $formats_nav;
6937         if (!defined $parent) {
6938                 # --root commitdiff
6939                 $formats_nav .= '(initial)';
6940         } elsif (@$parents == 1) {
6941                 # single parent commit
6942                 $formats_nav .=
6943                         '(parent: ' .
6944                         $cgi->a({-href => href(action=>"commit",
6945                                                hash=>$parent)},
6946                                 esc_html(substr($parent, 0, 7))) .
6947                         ')';
6948         } else {
6949                 # merge commit
6950                 $formats_nav .=
6951                         '(merge: ' .
6952                         join(' ', map {
6953                                 $cgi->a({-href => href(action=>"commit",
6954                                                        hash=>$_)},
6955                                         esc_html(substr($_, 0, 7)));
6956                         } @$parents ) .
6957                         ')';
6958         }
6959         if (gitweb_check_feature('patches') && @$parents <= 1) {
6960                 $formats_nav .= " | " .
6961                         $cgi->a({-href => href(action=>"patch", -replay=>1)},
6962                                 "patch");
6963         }
6964
6965         if (!defined $parent) {
6966                 $parent = "--root";
6967         }
6968         my @difftree;
6969         open my $fd, "-|", git_cmd(), "diff-tree", '-r', "--no-commit-id",
6970                 @diff_opts,
6971                 (@$parents <= 1 ? $parent : '-c'),
6972                 $hash, "--"
6973                 or die_error(500, "Open git-diff-tree failed");
6974         @difftree = map { chomp; $_ } <$fd>;
6975         close $fd or die_error(404, "Reading git-diff-tree failed");
6976
6977         # non-textual hash id's can be cached
6978         my $expires;
6979         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6980                 $expires = "+1d";
6981         }
6982         my $refs = git_get_references();
6983         my $ref = format_ref_marker($refs, $co{'id'});
6984
6985         git_header_html(undef, $expires);
6986         git_print_page_nav('commit', '',
6987                            $hash, $co{'tree'}, $hash,
6988                            $formats_nav);
6989
6990         if (defined $co{'parent'}) {
6991                 git_print_header_div('commitdiff', esc_html($co{'title'}) . $ref, $hash);
6992         } else {
6993                 git_print_header_div('tree', esc_html($co{'title'}) . $ref, $co{'tree'}, $hash);
6994         }
6995         print "<div class=\"title_text\">\n" .
6996               "<table class=\"object_header\">\n";
6997         git_print_authorship_rows(\%co);
6998         print "<tr><td>commit</td><td class=\"sha1\">$co{'id'}</td></tr>\n";
6999         print "<tr>" .
7000               "<td>tree</td>" .
7001               "<td class=\"sha1\">" .
7002               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash),
7003                        class => "list"}, $co{'tree'}) .
7004               "</td>" .
7005               "<td class=\"link\">" .
7006               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash)},
7007                       "tree");
7008         my $snapshot_links = format_snapshot_links($hash);
7009         if (defined $snapshot_links) {
7010                 print " | " . $snapshot_links;
7011         }
7012         print "</td>" .
7013               "</tr>\n";
7014
7015         foreach my $par (@$parents) {
7016                 print "<tr>" .
7017                       "<td>parent</td>" .
7018                       "<td class=\"sha1\">" .
7019                       $cgi->a({-href => href(action=>"commit", hash=>$par),
7020                                class => "list"}, $par) .
7021                       "</td>" .
7022                       "<td class=\"link\">" .
7023                       $cgi->a({-href => href(action=>"commit", hash=>$par)}, "commit") .
7024                       " | " .
7025                       $cgi->a({-href => href(action=>"commitdiff", hash=>$hash, hash_parent=>$par)}, "diff") .
7026                       "</td>" .
7027                       "</tr>\n";
7028         }
7029         print "</table>".
7030               "</div>\n";
7031
7032         print "<div class=\"page_body\">\n";
7033         git_print_log($co{'comment'});
7034         print "</div>\n";
7035
7036         git_difftree_body(\@difftree, $hash, @$parents);
7037
7038         git_footer_html();
7039 }
7040
7041 sub git_object {
7042         # object is defined by:
7043         # - hash or hash_base alone
7044         # - hash_base and file_name
7045         my $type;
7046
7047         # - hash or hash_base alone
7048         if ($hash || ($hash_base && !defined $file_name)) {
7049                 my $object_id = $hash || $hash_base;
7050
7051                 open my $fd, "-|", quote_command(
7052                         git_cmd(), 'cat-file', '-t', $object_id) . ' 2> /dev/null'
7053                         or die_error(404, "Object does not exist");
7054                 $type = <$fd>;
7055                 chomp $type;
7056                 close $fd
7057                         or die_error(404, "Object does not exist");
7058
7059         # - hash_base and file_name
7060         } elsif ($hash_base && defined $file_name) {
7061                 $file_name =~ s,/+$,,;
7062
7063                 system(git_cmd(), "cat-file", '-e', $hash_base) == 0
7064                         or die_error(404, "Base object does not exist");
7065
7066                 # here errors should not hapen
7067                 open my $fd, "-|", git_cmd(), "ls-tree", $hash_base, "--", $file_name
7068                         or die_error(500, "Open git-ls-tree failed");
7069                 my $line = <$fd>;
7070                 close $fd;
7071
7072                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
7073                 unless ($line && $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/) {
7074                         die_error(404, "File or directory for given base does not exist");
7075                 }
7076                 $type = $2;
7077                 $hash = $3;
7078         } else {
7079                 die_error(400, "Not enough information to find object");
7080         }
7081
7082         print $cgi->redirect(-uri => href(action=>$type, -full=>1,
7083                                           hash=>$hash, hash_base=>$hash_base,
7084                                           file_name=>$file_name),
7085                              -status => '302 Found');
7086 }
7087
7088 sub git_blobdiff {
7089         my $format = shift || 'html';
7090         my $diff_style = $input_params{'diff_style'} || 'inline';
7091
7092         my $fd;
7093         my @difftree;
7094         my %diffinfo;
7095         my $expires;
7096
7097         # preparing $fd and %diffinfo for git_patchset_body
7098         # new style URI
7099         if (defined $hash_base && defined $hash_parent_base) {
7100                 if (defined $file_name) {
7101                         # read raw output
7102                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7103                                 $hash_parent_base, $hash_base,
7104                                 "--", (defined $file_parent ? $file_parent : ()), $file_name
7105                                 or die_error(500, "Open git-diff-tree failed");
7106                         @difftree = map { chomp; $_ } <$fd>;
7107                         close $fd
7108                                 or die_error(404, "Reading git-diff-tree failed");
7109                         @difftree
7110                                 or die_error(404, "Blob diff not found");
7111
7112                 } elsif (defined $hash &&
7113                          $hash =~ /[0-9a-fA-F]{40}/) {
7114                         # try to find filename from $hash
7115
7116                         # read filtered raw output
7117                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7118                                 $hash_parent_base, $hash_base, "--"
7119                                 or die_error(500, "Open git-diff-tree failed");
7120                         @difftree =
7121                                 # ':100644 100644 03b21826... 3b93d5e7... M     ls-files.c'
7122                                 # $hash == to_id
7123                                 grep { /^:[0-7]{6} [0-7]{6} [0-9a-fA-F]{40} $hash/ }
7124                                 map { chomp; $_ } <$fd>;
7125                         close $fd
7126                                 or die_error(404, "Reading git-diff-tree failed");
7127                         @difftree
7128                                 or die_error(404, "Blob diff not found");
7129
7130                 } else {
7131                         die_error(400, "Missing one of the blob diff parameters");
7132                 }
7133
7134                 if (@difftree > 1) {
7135                         die_error(400, "Ambiguous blob diff specification");
7136                 }
7137
7138                 %diffinfo = parse_difftree_raw_line($difftree[0]);
7139                 $file_parent ||= $diffinfo{'from_file'} || $file_name;
7140                 $file_name   ||= $diffinfo{'to_file'};
7141
7142                 $hash_parent ||= $diffinfo{'from_id'};
7143                 $hash        ||= $diffinfo{'to_id'};
7144
7145                 # non-textual hash id's can be cached
7146                 if ($hash_base =~ m/^[0-9a-fA-F]{40}$/ &&
7147                     $hash_parent_base =~ m/^[0-9a-fA-F]{40}$/) {
7148                         $expires = '+1d';
7149                 }
7150
7151                 # open patch output
7152                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7153                         '-p', ($format eq 'html' ? "--full-index" : ()),
7154                         $hash_parent_base, $hash_base,
7155                         "--", (defined $file_parent ? $file_parent : ()), $file_name
7156                         or die_error(500, "Open git-diff-tree failed");
7157         }
7158
7159         # old/legacy style URI -- not generated anymore since 1.4.3.
7160         if (!%diffinfo) {
7161                 die_error('404 Not Found', "Missing one of the blob diff parameters")
7162         }
7163
7164         # header
7165         if ($format eq 'html') {
7166                 my $formats_nav =
7167                         $cgi->a({-href => href(action=>"blobdiff_plain", -replay=>1)},
7168                                 "raw");
7169                 $formats_nav .= diff_style_nav($diff_style);
7170                 git_header_html(undef, $expires);
7171                 if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7172                         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
7173                         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
7174                 } else {
7175                         print "<div class=\"page_nav\"><br/>$formats_nav<br/></div>\n";
7176                         print "<div class=\"title\">".esc_html("$hash vs $hash_parent")."</div>\n";
7177                 }
7178                 if (defined $file_name) {
7179                         git_print_page_path($file_name, "blob", $hash_base);
7180                 } else {
7181                         print "<div class=\"page_path\"></div>\n";
7182                 }
7183
7184         } elsif ($format eq 'plain') {
7185                 print $cgi->header(
7186                         -type => 'text/plain',
7187                         -charset => 'utf-8',
7188                         -expires => $expires,
7189                         -content_disposition => 'inline; filename="' . "$file_name" . '.patch"');
7190
7191                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7192
7193         } else {
7194                 die_error(400, "Unknown blobdiff format");
7195         }
7196
7197         # patch
7198         if ($format eq 'html') {
7199                 print "<div class=\"page_body\">\n";
7200
7201                 git_patchset_body($fd, $diff_style,
7202                                   [ \%diffinfo ], $hash_base, $hash_parent_base);
7203                 close $fd;
7204
7205                 print "</div>\n"; # class="page_body"
7206                 git_footer_html();
7207
7208         } else {
7209                 while (my $line = <$fd>) {
7210                         $line =~ s!a/($hash|$hash_parent)!'a/'.esc_path($diffinfo{'from_file'})!eg;
7211                         $line =~ s!b/($hash|$hash_parent)!'b/'.esc_path($diffinfo{'to_file'})!eg;
7212
7213                         print $line;
7214
7215                         last if $line =~ m!^\+\+\+!;
7216                 }
7217                 local $/ = undef;
7218                 print <$fd>;
7219                 close $fd;
7220         }
7221 }
7222
7223 sub git_blobdiff_plain {
7224         git_blobdiff('plain');
7225 }
7226
7227 # assumes that it is added as later part of already existing navigation,
7228 # so it returns "| foo | bar" rather than just "foo | bar"
7229 sub diff_style_nav {
7230         my ($diff_style, $is_combined) = @_;
7231         $diff_style ||= 'inline';
7232
7233         return "" if ($is_combined);
7234
7235         my @styles = (inline => 'inline', 'sidebyside' => 'side by side');
7236         my %styles = @styles;
7237         @styles =
7238                 @styles[ map { $_ * 2 } 0..$#styles/2 ];
7239
7240         return join '',
7241                 map { " | ".$_ }
7242                 map {
7243                         $_ eq $diff_style ? $styles{$_} :
7244                         $cgi->a({-href => href(-replay=>1, diff_style => $_)}, $styles{$_})
7245                 } @styles;
7246 }
7247
7248 sub git_commitdiff {
7249         my %params = @_;
7250         my $format = $params{-format} || 'html';
7251         my $diff_style = $input_params{'diff_style'} || 'inline';
7252
7253         my ($patch_max) = gitweb_get_feature('patches');
7254         if ($format eq 'patch') {
7255                 die_error(403, "Patch view not allowed") unless $patch_max;
7256         }
7257
7258         $hash ||= $hash_base || "HEAD";
7259         my %co = parse_commit($hash)
7260             or die_error(404, "Unknown commit object");
7261
7262         # choose format for commitdiff for merge
7263         if (! defined $hash_parent && @{$co{'parents'}} > 1) {
7264                 $hash_parent = '--cc';
7265         }
7266         # we need to prepare $formats_nav before almost any parameter munging
7267         my $formats_nav;
7268         if ($format eq 'html') {
7269                 $formats_nav =
7270                         $cgi->a({-href => href(action=>"commitdiff_plain", -replay=>1)},
7271                                 "raw");
7272                 if ($patch_max && @{$co{'parents'}} <= 1) {
7273                         $formats_nav .= " | " .
7274                                 $cgi->a({-href => href(action=>"patch", -replay=>1)},
7275                                         "patch");
7276                 }
7277                 $formats_nav .= diff_style_nav($diff_style, @{$co{'parents'}} > 1);
7278
7279                 if (defined $hash_parent &&
7280                     $hash_parent ne '-c' && $hash_parent ne '--cc') {
7281                         # commitdiff with two commits given
7282                         my $hash_parent_short = $hash_parent;
7283                         if ($hash_parent =~ m/^[0-9a-fA-F]{40}$/) {
7284                                 $hash_parent_short = substr($hash_parent, 0, 7);
7285                         }
7286                         $formats_nav .=
7287                                 ' (from';
7288                         for (my $i = 0; $i < @{$co{'parents'}}; $i++) {
7289                                 if ($co{'parents'}[$i] eq $hash_parent) {
7290                                         $formats_nav .= ' parent ' . ($i+1);
7291                                         last;
7292                                 }
7293                         }
7294                         $formats_nav .= ': ' .
7295                                 $cgi->a({-href => href(-replay=>1,
7296                                                        hash=>$hash_parent, hash_base=>undef)},
7297                                         esc_html($hash_parent_short)) .
7298                                 ')';
7299                 } elsif (!$co{'parent'}) {
7300                         # --root commitdiff
7301                         $formats_nav .= ' (initial)';
7302                 } elsif (scalar @{$co{'parents'}} == 1) {
7303                         # single parent commit
7304                         $formats_nav .=
7305                                 ' (parent: ' .
7306                                 $cgi->a({-href => href(-replay=>1,
7307                                                        hash=>$co{'parent'}, hash_base=>undef)},
7308                                         esc_html(substr($co{'parent'}, 0, 7))) .
7309                                 ')';
7310                 } else {
7311                         # merge commit
7312                         if ($hash_parent eq '--cc') {
7313                                 $formats_nav .= ' | ' .
7314                                         $cgi->a({-href => href(-replay=>1,
7315                                                                hash=>$hash, hash_parent=>'-c')},
7316                                                 'combined');
7317                         } else { # $hash_parent eq '-c'
7318                                 $formats_nav .= ' | ' .
7319                                         $cgi->a({-href => href(-replay=>1,
7320                                                                hash=>$hash, hash_parent=>'--cc')},
7321                                                 'compact');
7322                         }
7323                         $formats_nav .=
7324                                 ' (merge: ' .
7325                                 join(' ', map {
7326                                         $cgi->a({-href => href(-replay=>1,
7327                                                                hash=>$_, hash_base=>undef)},
7328                                                 esc_html(substr($_, 0, 7)));
7329                                 } @{$co{'parents'}} ) .
7330                                 ')';
7331                 }
7332         }
7333
7334         my $hash_parent_param = $hash_parent;
7335         if (!defined $hash_parent_param) {
7336                 # --cc for multiple parents, --root for parentless
7337                 $hash_parent_param =
7338                         @{$co{'parents'}} > 1 ? '--cc' : $co{'parent'} || '--root';
7339         }
7340
7341         # read commitdiff
7342         my $fd;
7343         my @difftree;
7344         if ($format eq 'html') {
7345                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7346                         "--no-commit-id", "--patch-with-raw", "--full-index",
7347                         $hash_parent_param, $hash, "--"
7348                         or die_error(500, "Open git-diff-tree failed");
7349
7350                 while (my $line = <$fd>) {
7351                         chomp $line;
7352                         # empty line ends raw part of diff-tree output
7353                         last unless $line;
7354                         push @difftree, scalar parse_difftree_raw_line($line);
7355                 }
7356
7357         } elsif ($format eq 'plain') {
7358                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7359                         '-p', $hash_parent_param, $hash, "--"
7360                         or die_error(500, "Open git-diff-tree failed");
7361         } elsif ($format eq 'patch') {
7362                 # For commit ranges, we limit the output to the number of
7363                 # patches specified in the 'patches' feature.
7364                 # For single commits, we limit the output to a single patch,
7365                 # diverging from the git-format-patch default.
7366                 my @commit_spec = ();
7367                 if ($hash_parent) {
7368                         if ($patch_max > 0) {
7369                                 push @commit_spec, "-$patch_max";
7370                         }
7371                         push @commit_spec, '-n', "$hash_parent..$hash";
7372                 } else {
7373                         if ($params{-single}) {
7374                                 push @commit_spec, '-1';
7375                         } else {
7376                                 if ($patch_max > 0) {
7377                                         push @commit_spec, "-$patch_max";
7378                                 }
7379                                 push @commit_spec, "-n";
7380                         }
7381                         push @commit_spec, '--root', $hash;
7382                 }
7383                 open $fd, "-|", git_cmd(), "format-patch", @diff_opts,
7384                         '--encoding=utf8', '--stdout', @commit_spec
7385                         or die_error(500, "Open git-format-patch failed");
7386         } else {
7387                 die_error(400, "Unknown commitdiff format");
7388         }
7389
7390         # non-textual hash id's can be cached
7391         my $expires;
7392         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7393                 $expires = "+1d";
7394         }
7395
7396         # write commit message
7397         if ($format eq 'html') {
7398                 my $refs = git_get_references();
7399                 my $ref = format_ref_marker($refs, $co{'id'});
7400
7401                 git_header_html(undef, $expires);
7402                 git_print_page_nav('commitdiff','', $hash,$co{'tree'},$hash, $formats_nav);
7403                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash);
7404                 print "<div class=\"title_text\">\n" .
7405                       "<table class=\"object_header\">\n";
7406                 git_print_authorship_rows(\%co);
7407                 print "</table>".
7408                       "</div>\n";
7409                 print "<div class=\"page_body\">\n";
7410                 if (@{$co{'comment'}} > 1) {
7411                         print "<div class=\"log\">\n";
7412                         git_print_log($co{'comment'}, -final_empty_line=> 1, -remove_title => 1);
7413                         print "</div>\n"; # class="log"
7414                 }
7415
7416         } elsif ($format eq 'plain') {
7417                 my $refs = git_get_references("tags");
7418                 my $tagname = git_get_rev_name_tags($hash);
7419                 my $filename = basename($project) . "-$hash.patch";
7420
7421                 print $cgi->header(
7422                         -type => 'text/plain',
7423                         -charset => 'utf-8',
7424                         -expires => $expires,
7425                         -content_disposition => 'inline; filename="' . "$filename" . '"');
7426                 my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
7427                 print "From: " . to_utf8($co{'author'}) . "\n";
7428                 print "Date: $ad{'rfc2822'} ($ad{'tz_local'})\n";
7429                 print "Subject: " . to_utf8($co{'title'}) . "\n";
7430
7431                 print "X-Git-Tag: $tagname\n" if $tagname;
7432                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7433
7434                 foreach my $line (@{$co{'comment'}}) {
7435                         print to_utf8($line) . "\n";
7436                 }
7437                 print "---\n\n";
7438         } elsif ($format eq 'patch') {
7439                 my $filename = basename($project) . "-$hash.patch";
7440
7441                 print $cgi->header(
7442                         -type => 'text/plain',
7443                         -charset => 'utf-8',
7444                         -expires => $expires,
7445                         -content_disposition => 'inline; filename="' . "$filename" . '"');
7446         }
7447
7448         # write patch
7449         if ($format eq 'html') {
7450                 my $use_parents = !defined $hash_parent ||
7451                         $hash_parent eq '-c' || $hash_parent eq '--cc';
7452                 git_difftree_body(\@difftree, $hash,
7453                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
7454                 print "<br/>\n";
7455
7456                 git_patchset_body($fd, $diff_style,
7457                                   \@difftree, $hash,
7458                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
7459                 close $fd;
7460                 print "</div>\n"; # class="page_body"
7461                 git_footer_html();
7462
7463         } elsif ($format eq 'plain') {
7464                 local $/ = undef;
7465                 print <$fd>;
7466                 close $fd
7467                         or print "Reading git-diff-tree failed\n";
7468         } elsif ($format eq 'patch') {
7469                 local $/ = undef;
7470                 print <$fd>;
7471                 close $fd
7472                         or print "Reading git-format-patch failed\n";
7473         }
7474 }
7475
7476 sub git_commitdiff_plain {
7477         git_commitdiff(-format => 'plain');
7478 }
7479
7480 # format-patch-style patches
7481 sub git_patch {
7482         git_commitdiff(-format => 'patch', -single => 1);
7483 }
7484
7485 sub git_patches {
7486         git_commitdiff(-format => 'patch');
7487 }
7488
7489 sub git_history {
7490         git_log_generic('history', \&git_history_body,
7491                         $hash_base, $hash_parent_base,
7492                         $file_name, $hash);
7493 }
7494
7495 sub git_search {
7496         $searchtype ||= 'commit';
7497
7498         # check if appropriate features are enabled
7499         gitweb_check_feature('search')
7500                 or die_error(403, "Search is disabled");
7501         if ($searchtype eq 'pickaxe') {
7502                 # pickaxe may take all resources of your box and run for several minutes
7503                 # with every query - so decide by yourself how public you make this feature
7504                 gitweb_check_feature('pickaxe')
7505                         or die_error(403, "Pickaxe search is disabled");
7506         }
7507         if ($searchtype eq 'grep') {
7508                 # grep search might be potentially CPU-intensive, too
7509                 gitweb_check_feature('grep')
7510                         or die_error(403, "Grep search is disabled");
7511         }
7512
7513         if (!defined $searchtext) {
7514                 die_error(400, "Text field is empty");
7515         }
7516         if (!defined $hash) {
7517                 $hash = git_get_head_hash($project);
7518         }
7519         my %co = parse_commit($hash);
7520         if (!%co) {
7521                 die_error(404, "Unknown commit object");
7522         }
7523         if (!defined $page) {
7524                 $page = 0;
7525         }
7526
7527         if ($searchtype eq 'commit' ||
7528             $searchtype eq 'author' ||
7529             $searchtype eq 'committer') {
7530                 git_search_message(%co);
7531         } elsif ($searchtype eq 'pickaxe') {
7532                 git_search_changes(%co);
7533         } elsif ($searchtype eq 'grep') {
7534                 git_search_files(%co);
7535         } else {
7536                 die_error(400, "Unknown search type");
7537         }
7538 }
7539
7540 sub git_search_help {
7541         git_header_html();
7542         git_print_page_nav('','', $hash,$hash,$hash);
7543         print <<EOT;
7544 <p><strong>Pattern</strong> is by default a normal string that is matched precisely (but without
7545 regard to case, except in the case of pickaxe). However, when you check the <em>re</em> checkbox,
7546 the pattern entered is recognized as the POSIX extended
7547 <a href="http://en.wikipedia.org/wiki/Regular_expression">regular expression</a> (also case
7548 insensitive).</p>
7549 <dl>
7550 <dt><b>commit</b></dt>
7551 <dd>The commit messages and authorship information will be scanned for the given pattern.</dd>
7552 EOT
7553         my $have_grep = gitweb_check_feature('grep');
7554         if ($have_grep) {
7555                 print <<EOT;
7556 <dt><b>grep</b></dt>
7557 <dd>All files in the currently selected tree (HEAD unless you are explicitly browsing
7558     a different one) are searched for the given pattern. On large trees, this search can take
7559 a while and put some strain on the server, so please use it with some consideration. Note that
7560 due to git-grep peculiarity, currently if regexp mode is turned off, the matches are
7561 case-sensitive.</dd>
7562 EOT
7563         }
7564         print <<EOT;
7565 <dt><b>author</b></dt>
7566 <dd>Name and e-mail of the change author and date of birth of the patch will be scanned for the given pattern.</dd>
7567 <dt><b>committer</b></dt>
7568 <dd>Name and e-mail of the committer and date of commit will be scanned for the given pattern.</dd>
7569 EOT
7570         my $have_pickaxe = gitweb_check_feature('pickaxe');
7571         if ($have_pickaxe) {
7572                 print <<EOT;
7573 <dt><b>pickaxe</b></dt>
7574 <dd>All commits that caused the string to appear or disappear from any file (changes that
7575 added, removed or "modified" the string) will be listed. This search can take a while and
7576 takes a lot of strain on the server, so please use it wisely. Note that since you may be
7577 interested even in changes just changing the case as well, this search is case sensitive.</dd>
7578 EOT
7579         }
7580         print "</dl>\n";
7581         git_footer_html();
7582 }
7583
7584 sub git_shortlog {
7585         git_log_generic('shortlog', \&git_shortlog_body,
7586                         $hash, $hash_parent);
7587 }
7588
7589 ## ......................................................................
7590 ## feeds (RSS, Atom; OPML)
7591
7592 sub git_feed {
7593         my $format = shift || 'atom';
7594         my $have_blame = gitweb_check_feature('blame');
7595
7596         # Atom: http://www.atomenabled.org/developers/syndication/
7597         # RSS:  http://www.notestips.com/80256B3A007F2692/1/NAMO5P9UPQ
7598         if ($format ne 'rss' && $format ne 'atom') {
7599                 die_error(400, "Unknown web feed format");
7600         }
7601
7602         # log/feed of current (HEAD) branch, log of given branch, history of file/directory
7603         my $head = $hash || 'HEAD';
7604         my @commitlist = parse_commits($head, 150, 0, $file_name);
7605
7606         my %latest_commit;
7607         my %latest_date;
7608         my $content_type = "application/$format+xml";
7609         if (defined $cgi->http('HTTP_ACCEPT') &&
7610                  $cgi->Accept('text/xml') > $cgi->Accept($content_type)) {
7611                 # browser (feed reader) prefers text/xml
7612                 $content_type = 'text/xml';
7613         }
7614         if (defined($commitlist[0])) {
7615                 %latest_commit = %{$commitlist[0]};
7616                 my $latest_epoch = $latest_commit{'committer_epoch'};
7617                 %latest_date   = parse_date($latest_epoch, $latest_commit{'comitter_tz'});
7618                 my $if_modified = $cgi->http('IF_MODIFIED_SINCE');
7619                 if (defined $if_modified) {
7620                         my $since;
7621                         if (eval { require HTTP::Date; 1; }) {
7622                                 $since = HTTP::Date::str2time($if_modified);
7623                         } elsif (eval { require Time::ParseDate; 1; }) {
7624                                 $since = Time::ParseDate::parsedate($if_modified, GMT => 1);
7625                         }
7626                         if (defined $since && $latest_epoch <= $since) {
7627                                 print $cgi->header(
7628                                         -type => $content_type,
7629                                         -charset => 'utf-8',
7630                                         -last_modified => $latest_date{'rfc2822'},
7631                                         -status => '304 Not Modified');
7632                                 return;
7633                         }
7634                 }
7635                 print $cgi->header(
7636                         -type => $content_type,
7637                         -charset => 'utf-8',
7638                         -last_modified => $latest_date{'rfc2822'});
7639         } else {
7640                 print $cgi->header(
7641                         -type => $content_type,
7642                         -charset => 'utf-8');
7643         }
7644
7645         # Optimization: skip generating the body if client asks only
7646         # for Last-Modified date.
7647         return if ($cgi->request_method() eq 'HEAD');
7648
7649         # header variables
7650         my $title = "$site_name - $project/$action";
7651         my $feed_type = 'log';
7652         if (defined $hash) {
7653                 $title .= " - '$hash'";
7654                 $feed_type = 'branch log';
7655                 if (defined $file_name) {
7656                         $title .= " :: $file_name";
7657                         $feed_type = 'history';
7658                 }
7659         } elsif (defined $file_name) {
7660                 $title .= " - $file_name";
7661                 $feed_type = 'history';
7662         }
7663         $title .= " $feed_type";
7664         my $descr = git_get_project_description($project);
7665         if (defined $descr) {
7666                 $descr = esc_html($descr);
7667         } else {
7668                 $descr = "$project " .
7669                          ($format eq 'rss' ? 'RSS' : 'Atom') .
7670                          " feed";
7671         }
7672         my $owner = git_get_project_owner($project);
7673         $owner = esc_html($owner);
7674
7675         #header
7676         my $alt_url;
7677         if (defined $file_name) {
7678                 $alt_url = href(-full=>1, action=>"history", hash=>$hash, file_name=>$file_name);
7679         } elsif (defined $hash) {
7680                 $alt_url = href(-full=>1, action=>"log", hash=>$hash);
7681         } else {
7682                 $alt_url = href(-full=>1, action=>"summary");
7683         }
7684         print qq!<?xml version="1.0" encoding="utf-8"?>\n!;
7685         if ($format eq 'rss') {
7686                 print <<XML;
7687 <rss version="2.0" xmlns:content="http://purl.org/rss/1.0/modules/content/">
7688 <channel>
7689 XML
7690                 print "<title>$title</title>\n" .
7691                       "<link>$alt_url</link>\n" .
7692                       "<description>$descr</description>\n" .
7693                       "<language>en</language>\n" .
7694                       # project owner is responsible for 'editorial' content
7695                       "<managingEditor>$owner</managingEditor>\n";
7696                 if (defined $logo || defined $favicon) {
7697                         # prefer the logo to the favicon, since RSS
7698                         # doesn't allow both
7699                         my $img = esc_url($logo || $favicon);
7700                         print "<image>\n" .
7701                               "<url>$img</url>\n" .
7702                               "<title>$title</title>\n" .
7703                               "<link>$alt_url</link>\n" .
7704                               "</image>\n";
7705                 }
7706                 if (%latest_date) {
7707                         print "<pubDate>$latest_date{'rfc2822'}</pubDate>\n";
7708                         print "<lastBuildDate>$latest_date{'rfc2822'}</lastBuildDate>\n";
7709                 }
7710                 print "<generator>gitweb v.$version/$git_version</generator>\n";
7711         } elsif ($format eq 'atom') {
7712                 print <<XML;
7713 <feed xmlns="http://www.w3.org/2005/Atom">
7714 XML
7715                 print "<title>$title</title>\n" .
7716                       "<subtitle>$descr</subtitle>\n" .
7717                       '<link rel="alternate" type="text/html" href="' .
7718                       $alt_url . '" />' . "\n" .
7719                       '<link rel="self" type="' . $content_type . '" href="' .
7720                       $cgi->self_url() . '" />' . "\n" .
7721                       "<id>" . href(-full=>1) . "</id>\n" .
7722                       # use project owner for feed author
7723                       "<author><name>$owner</name></author>\n";
7724                 if (defined $favicon) {
7725                         print "<icon>" . esc_url($favicon) . "</icon>\n";
7726                 }
7727                 if (defined $logo) {
7728                         # not twice as wide as tall: 72 x 27 pixels
7729                         print "<logo>" . esc_url($logo) . "</logo>\n";
7730                 }
7731                 if (! %latest_date) {
7732                         # dummy date to keep the feed valid until commits trickle in:
7733                         print "<updated>1970-01-01T00:00:00Z</updated>\n";
7734                 } else {
7735                         print "<updated>$latest_date{'iso-8601'}</updated>\n";
7736                 }
7737                 print "<generator version='$version/$git_version'>gitweb</generator>\n";
7738         }
7739
7740         # contents
7741         for (my $i = 0; $i <= $#commitlist; $i++) {
7742                 my %co = %{$commitlist[$i]};
7743                 my $commit = $co{'id'};
7744                 # we read 150, we always show 30 and the ones more recent than 48 hours
7745                 if (($i >= 20) && ((time - $co{'author_epoch'}) > 48*60*60)) {
7746                         last;
7747                 }
7748                 my %cd = parse_date($co{'author_epoch'}, $co{'author_tz'});
7749
7750                 # get list of changed files
7751                 open my $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7752                         $co{'parent'} || "--root",
7753                         $co{'id'}, "--", (defined $file_name ? $file_name : ())
7754                         or next;
7755                 my @difftree = map { chomp; $_ } <$fd>;
7756                 close $fd
7757                         or next;
7758
7759                 # print element (entry, item)
7760                 my $co_url = href(-full=>1, action=>"commitdiff", hash=>$commit);
7761                 if ($format eq 'rss') {
7762                         print "<item>\n" .
7763                               "<title>" . esc_html($co{'title'}) . "</title>\n" .
7764                               "<author>" . esc_html($co{'author'}) . "</author>\n" .
7765                               "<pubDate>$cd{'rfc2822'}</pubDate>\n" .
7766                               "<guid isPermaLink=\"true\">$co_url</guid>\n" .
7767                               "<link>$co_url</link>\n" .
7768                               "<description>" . esc_html($co{'title'}) . "</description>\n" .
7769                               "<content:encoded>" .
7770                               "<![CDATA[\n";
7771                 } elsif ($format eq 'atom') {
7772                         print "<entry>\n" .
7773                               "<title type=\"html\">" . esc_html($co{'title'}) . "</title>\n" .
7774                               "<updated>$cd{'iso-8601'}</updated>\n" .
7775                               "<author>\n" .
7776                               "  <name>" . esc_html($co{'author_name'}) . "</name>\n";
7777                         if ($co{'author_email'}) {
7778                                 print "  <email>" . esc_html($co{'author_email'}) . "</email>\n";
7779                         }
7780                         print "</author>\n" .
7781                               # use committer for contributor
7782                               "<contributor>\n" .
7783                               "  <name>" . esc_html($co{'committer_name'}) . "</name>\n";
7784                         if ($co{'committer_email'}) {
7785                                 print "  <email>" . esc_html($co{'committer_email'}) . "</email>\n";
7786                         }
7787                         print "</contributor>\n" .
7788                               "<published>$cd{'iso-8601'}</published>\n" .
7789                               "<link rel=\"alternate\" type=\"text/html\" href=\"$co_url\" />\n" .
7790                               "<id>$co_url</id>\n" .
7791                               "<content type=\"xhtml\" xml:base=\"" . esc_url($my_url) . "\">\n" .
7792                               "<div xmlns=\"http://www.w3.org/1999/xhtml\">\n";
7793                 }
7794                 my $comment = $co{'comment'};
7795                 print "<pre>\n";
7796                 foreach my $line (@$comment) {
7797                         $line = esc_html($line);
7798                         print "$line\n";
7799                 }
7800                 print "</pre><ul>\n";
7801                 foreach my $difftree_line (@difftree) {
7802                         my %difftree = parse_difftree_raw_line($difftree_line);
7803                         next if !$difftree{'from_id'};
7804
7805                         my $file = $difftree{'file'} || $difftree{'to_file'};
7806
7807                         print "<li>" .
7808                               "[" .
7809                               $cgi->a({-href => href(-full=>1, action=>"blobdiff",
7810                                                      hash=>$difftree{'to_id'}, hash_parent=>$difftree{'from_id'},
7811                                                      hash_base=>$co{'id'}, hash_parent_base=>$co{'parent'},
7812                                                      file_name=>$file, file_parent=>$difftree{'from_file'}),
7813                                       -title => "diff"}, 'D');
7814                         if ($have_blame) {
7815                                 print $cgi->a({-href => href(-full=>1, action=>"blame",
7816                                                              file_name=>$file, hash_base=>$commit),
7817                                               -title => "blame"}, 'B');
7818                         }
7819                         # if this is not a feed of a file history
7820                         if (!defined $file_name || $file_name ne $file) {
7821                                 print $cgi->a({-href => href(-full=>1, action=>"history",
7822                                                              file_name=>$file, hash=>$commit),
7823                                               -title => "history"}, 'H');
7824                         }
7825                         $file = esc_path($file);
7826                         print "] ".
7827                               "$file</li>\n";
7828                 }
7829                 if ($format eq 'rss') {
7830                         print "</ul>]]>\n" .
7831                               "</content:encoded>\n" .
7832                               "</item>\n";
7833                 } elsif ($format eq 'atom') {
7834                         print "</ul>\n</div>\n" .
7835                               "</content>\n" .
7836                               "</entry>\n";
7837                 }
7838         }
7839
7840         # end of feed
7841         if ($format eq 'rss') {
7842                 print "</channel>\n</rss>\n";
7843         } elsif ($format eq 'atom') {
7844                 print "</feed>\n";
7845         }
7846 }
7847
7848 sub git_rss {
7849         git_feed('rss');
7850 }
7851
7852 sub git_atom {
7853         git_feed('atom');
7854 }
7855
7856 sub git_opml {
7857         my @list = git_get_projects_list();
7858         if (!@list) {
7859                 die_error(404, "No projects found");
7860         }
7861
7862         print $cgi->header(
7863                 -type => 'text/xml',
7864                 -charset => 'utf-8',
7865                 -content_disposition => 'inline; filename="opml.xml"');
7866
7867         print <<XML;
7868 <?xml version="1.0" encoding="utf-8"?>
7869 <opml version="1.0">
7870 <head>
7871   <title>$site_name OPML Export</title>
7872 </head>
7873 <body>
7874 <outline text="git RSS feeds">
7875 XML
7876
7877         foreach my $pr (@list) {
7878                 my %proj = %$pr;
7879                 my $head = git_get_head_hash($proj{'path'});
7880                 if (!defined $head) {
7881                         next;
7882                 }
7883                 $git_dir = "$projectroot/$proj{'path'}";
7884                 my %co = parse_commit($head);
7885                 if (!%co) {
7886                         next;
7887                 }
7888
7889                 my $path = esc_html(chop_str($proj{'path'}, 25, 5));
7890                 my $rss  = href('project' => $proj{'path'}, 'action' => 'rss', -full => 1);
7891                 my $html = href('project' => $proj{'path'}, 'action' => 'summary', -full => 1);
7892                 print "<outline type=\"rss\" text=\"$path\" title=\"$path\" xmlUrl=\"$rss\" htmlUrl=\"$html\"/>\n";
7893         }
7894         print <<XML;
7895 </outline>
7896 </body>
7897 </opml>
7898 XML
7899 }