Lady’s Gitweb - Gitweb/blob - gitweb.perl

   1 #!/usr/bin/perl
   2
   3 # gitweb - simple web interface to track changes in git repositories
   4 #
   5 # (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
   6 # (C) 2005, Christian Gierke
   7 #
   8 # This program is licensed under the GPLv2
   9
  10 use 5.008;
  11 use strict;
  12 use warnings;
  13 use CGI qw(:standard :escapeHTML -nosticky);
  14 use CGI::Util qw(unescape);
  15 use CGI::Carp qw(fatalsToBrowser set_message);
  16 use Encode;
  17 use Fcntl ':mode';
  18 use File::Find qw();
  19 use File::Basename qw(basename);
  20 use Time::HiRes qw(gettimeofday tv_interval);
  21 binmode STDOUT, ':utf8';
  22
  23 our $t0 = [ gettimeofday() ];
  24 our $number_of_git_cmds = 0;
  25
  26 BEGIN {
  27         CGI->compile() if $ENV{'MOD_PERL'};
  28 }
  29
  30 our $version = "++GIT_VERSION++";
  31
  32 our ($my_url, $my_uri, $base_url, $path_info, $home_link);
  33 sub evaluate_uri {
  34         our $cgi;
  35
  36         our $my_url = $cgi->url();
  37         our $my_uri = $cgi->url(-absolute => 1);
  38
  39         # Base URL for relative URLs in gitweb ($logo, $favicon, ...),
  40         # needed and used only for URLs with nonempty PATH_INFO
  41         our $base_url = $my_url;
  42
  43         # When the script is used as DirectoryIndex, the URL does not contain the name
  44         # of the script file itself, and $cgi->url() fails to strip PATH_INFO, so we
  45         # have to do it ourselves. We make $path_info global because it's also used
  46         # later on.
  47         #
  48         # Another issue with the script being the DirectoryIndex is that the resulting
  49         # $my_url data is not the full script URL: this is good, because we want
  50         # generated links to keep implying the script name if it wasn't explicitly
  51         # indicated in the URL we're handling, but it means that $my_url cannot be used
  52         # as base URL.
  53         # Therefore, if we needed to strip PATH_INFO, then we know that we have
  54         # to build the base URL ourselves:
  55         our $path_info = $ENV{"PATH_INFO"};
  56         if ($path_info) {
  57                 if ($my_url =~ s,\Q$path_info\E$,, &&
  58                     $my_uri =~ s,\Q$path_info\E$,, &&
  59                     defined $ENV{'SCRIPT_NAME'}) {
  60                         $base_url = $cgi->url(-base => 1) . $ENV{'SCRIPT_NAME'};
  61                 }
  62         }
  63
  64         # target of the home link on top of all pages
  65         our $home_link = $my_uri || "/";
  66 }
  67
  68 # core git executable to use
  69 # this can just be "git" if your webserver has a sensible PATH
  70 our $GIT = "++GIT_BINDIR++/git";
  71
  72 # absolute fs-path which will be prepended to the project path
  73 #our $projectroot = "/pub/scm";
  74 our $projectroot = "++GITWEB_PROJECTROOT++";
  75
  76 # fs traversing limit for getting project list
  77 # the number is relative to the projectroot
  78 our $project_maxdepth = "++GITWEB_PROJECT_MAXDEPTH++";
  79
  80 # string of the home link on top of all pages
  81 our $home_link_str = "++GITWEB_HOME_LINK_STR++";
  82
  83 # name of your site or organization to appear in page titles
  84 # replace this with something more descriptive for clearer bookmarks
  85 our $site_name = "++GITWEB_SITENAME++"
  86                  || ($ENV{'SERVER_NAME'} || "Untitled") . " Git";
  87
  88 # html snippet to include in the <head> section of each page
  89 our $site_html_head_string = "++GITWEB_SITE_HTML_HEAD_STRING++";
  90 # filename of html text to include at top of each page
  91 our $site_header = "++GITWEB_SITE_HEADER++";
  92 # html text to include at home page
  93 our $home_text = "++GITWEB_HOMETEXT++";
  94 # filename of html text to include at bottom of each page
  95 our $site_footer = "++GITWEB_SITE_FOOTER++";
  96
  97 # URI of stylesheets
  98 our @stylesheets = ("++GITWEB_CSS++");
  99 # URI of a single stylesheet, which can be overridden in GITWEB_CONFIG.
 100 our $stylesheet = undef;
 101
 102 # URI of GIT logo (72x27 size)
 103 our $logo = "++GITWEB_LOGO++";
 104 # URI of GIT favicon, assumed to be image/png type
 105 our $favicon = "++GITWEB_FAVICON++";
 106 # URI of gitweb.js (JavaScript code for gitweb)
 107 our $javascript = "++GITWEB_JS++";
 108
 109 # URI and label (title) of GIT logo link
 110 #our $logo_url = "http://www.kernel.org/pub/software/scm/git/docs/";
 111 #our $logo_label = "git documentation";
 112 our $logo_url = "http://git-scm.com/";
 113 our $logo_label = "git homepage";
 114
 115 # source of projects list
 116 our $projects_list = "++GITWEB_LIST++";
 117
 118 # the width (in characters) of the projects list "Description" column
 119 our $projects_list_description_width = 25;
 120
 121 # group projects by category on the projects list
 122 # (enabled if this variable evaluates to true)
 123 our $projects_list_group_categories = 0;
 124
 125 # default category if none specified
 126 # (leave the empty string for no category)
 127 our $project_list_default_category = "";
 128
 129 # default order of projects list
 130 # valid values are none, project, descr, owner, and age
 131 our $default_projects_order = "project";
 132
 133 # show repository only if this file exists
 134 # (only effective if this variable evaluates to true)
 135 our $export_ok = "++GITWEB_EXPORT_OK++";
 136
 137 # show repository only if this subroutine returns true
 138 # when given the path to the project, for example:
 139 #    sub { return -e "$_[0]/git-daemon-export-ok"; }
 140 our $export_auth_hook = undef;
 141
 142 # only allow viewing of repositories also shown on the overview page
 143 our $strict_export = "++GITWEB_STRICT_EXPORT++";
 144
 145 # list of git base URLs used for URL to where fetch project from,
 146 # i.e. full URL is "$git_base_url/$project"
 147 our @git_base_url_list = grep { $_ ne '' } ("++GITWEB_BASE_URL++");
 148
 149 # default blob_plain mimetype and default charset for text/plain blob
 150 our $default_blob_plain_mimetype = 'text/plain';
 151 our $default_text_plain_charset  = undef;
 152
 153 # file to use for guessing MIME types before trying /etc/mime.types
 154 # (relative to the current git repository)
 155 our $mimetypes_file = undef;
 156
 157 # assume this charset if line contains non-UTF-8 characters;
 158 # it should be valid encoding (see Encoding::Supported(3pm) for list),
 159 # for which encoding all byte sequences are valid, for example
 160 # 'iso-8859-1' aka 'latin1' (it is decoded without checking, so it
 161 # could be even 'utf-8' for the old behavior)
 162 our $fallback_encoding = 'latin1';
 163
 164 # rename detection options for git-diff and git-diff-tree
 165 # - default is '-M', with the cost proportional to
 166 #   (number of removed files) * (number of new files).
 167 # - more costly is '-C' (which implies '-M'), with the cost proportional to
 168 #   (number of changed files + number of removed files) * (number of new files)
 169 # - even more costly is '-C', '--find-copies-harder' with cost
 170 #   (number of files in the original tree) * (number of new files)
 171 # - one might want to include '-B' option, e.g. '-B', '-M'
 172 our @diff_opts = ('-M'); # taken from git_commit
 173
 174 # Disables features that would allow repository owners to inject script into
 175 # the gitweb domain.
 176 our $prevent_xss = 0;
 177
 178 # Path to the highlight executable to use (must be the one from
 179 # http://www.andre-simon.de due to assumptions about parameters and output).
 180 # Useful if highlight is not installed on your webserver's PATH.
 181 # [Default: highlight]
 182 our $highlight_bin = "++HIGHLIGHT_BIN++";
 183
 184 # information about snapshot formats that gitweb is capable of serving
 185 our %known_snapshot_formats = (
 186         # name => {
 187         #       'display' => display name,
 188         #       'type' => mime type,
 189         #       'suffix' => filename suffix,
 190         #       'format' => --format for git-archive,
 191         #       'compressor' => [compressor command and arguments]
 192         #                       (array reference, optional)
 193         #       'disabled' => boolean (optional)}
 194         #
 195         'tgz' => {
 196                 'display' => 'tar.gz',
 197                 'type' => 'application/x-gzip',
 198                 'suffix' => '.tar.gz',
 199                 'format' => 'tar',
 200                 'compressor' => ['gzip', '-n']},
 201
 202         'tbz2' => {
 203                 'display' => 'tar.bz2',
 204                 'type' => 'application/x-bzip2',
 205                 'suffix' => '.tar.bz2',
 206                 'format' => 'tar',
 207                 'compressor' => ['bzip2']},
 208
 209         'txz' => {
 210                 'display' => 'tar.xz',
 211                 'type' => 'application/x-xz',
 212                 'suffix' => '.tar.xz',
 213                 'format' => 'tar',
 214                 'compressor' => ['xz'],
 215                 'disabled' => 1},
 216
 217         'zip' => {
 218                 'display' => 'zip',
 219                 'type' => 'application/x-zip',
 220                 'suffix' => '.zip',
 221                 'format' => 'zip'},
 222 );
 223
 224 # Aliases so we understand old gitweb.snapshot values in repository
 225 # configuration.
 226 our %known_snapshot_format_aliases = (
 227         'gzip'  => 'tgz',
 228         'bzip2' => 'tbz2',
 229         'xz'    => 'txz',
 230
 231         # backward compatibility: legacy gitweb config support
 232         'x-gzip' => undef, 'gz' => undef,
 233         'x-bzip2' => undef, 'bz2' => undef,
 234         'x-zip' => undef, '' => undef,
 235 );
 236
 237 # Pixel sizes for icons and avatars. If the default font sizes or lineheights
 238 # are changed, it may be appropriate to change these values too via
 239 # $GITWEB_CONFIG.
 240 our %avatar_size = (
 241         'default' => 16,
 242         'double'  => 32
 243 );
 244
 245 # Used to set the maximum load that we will still respond to gitweb queries.
 246 # If server load exceed this value then return "503 server busy" error.
 247 # If gitweb cannot determined server load, it is taken to be 0.
 248 # Leave it undefined (or set to 'undef') to turn off load checking.
 249 our $maxload = 300;
 250
 251 # configuration for 'highlight' (http://www.andre-simon.de/)
 252 # match by basename
 253 our %highlight_basename = (
 254         #'Program' => 'py',
 255         #'Library' => 'py',
 256         'SConstruct' => 'py', # SCons equivalent of Makefile
 257         'Makefile' => 'make',
 258 );
 259 # match by extension
 260 our %highlight_ext = (
 261         # main extensions, defining name of syntax;
 262         # see files in /usr/share/highlight/langDefs/ directory
 263         map { $_ => $_ }
 264                 qw(py c cpp rb java css php sh pl js tex bib xml awk bat ini spec tcl sql make),
 265         # alternate extensions, see /etc/highlight/filetypes.conf
 266         'h' => 'c',
 267         map { $_ => 'sh'  } qw(bash zsh ksh),
 268         map { $_ => 'cpp' } qw(cxx c++ cc),
 269         map { $_ => 'php' } qw(php3 php4 php5 phps),
 270         map { $_ => 'pl'  } qw(perl pm), # perhaps also 'cgi'
 271         map { $_ => 'make'} qw(mak mk),
 272         map { $_ => 'xml' } qw(xhtml html htm),
 273 );
 274
 275 # You define site-wide feature defaults here; override them with
 276 # $GITWEB_CONFIG as necessary.
 277 our %feature = (
 278         # feature => {
 279         #       'sub' => feature-sub (subroutine),
 280         #       'override' => allow-override (boolean),
 281         #       'default' => [ default options...] (array reference)}
 282         #
 283         # if feature is overridable (it means that allow-override has true value),
 284         # then feature-sub will be called with default options as parameters;
 285         # return value of feature-sub indicates if to enable specified feature
 286         #
 287         # if there is no 'sub' key (no feature-sub), then feature cannot be
 288         # overridden
 289         #
 290         # use gitweb_get_feature(<feature>) to retrieve the <feature> value
 291         # (an array) or gitweb_check_feature(<feature>) to check if <feature>
 292         # is enabled
 293
 294         # Enable the 'blame' blob view, showing the last commit that modified
 295         # each line in the file. This can be very CPU-intensive.
 296
 297         # To enable system wide have in $GITWEB_CONFIG
 298         # $feature{'blame'}{'default'} = [1];
 299         # To have project specific config enable override in $GITWEB_CONFIG
 300         # $feature{'blame'}{'override'} = 1;
 301         # and in project config gitweb.blame = 0|1;
 302         'blame' => {
 303                 'sub' => sub { feature_bool('blame', @_) },
 304                 'override' => 0,
 305                 'default' => [0]},
 306
 307         # Enable the 'snapshot' link, providing a compressed archive of any
 308         # tree. This can potentially generate high traffic if you have large
 309         # project.
 310
 311         # Value is a list of formats defined in %known_snapshot_formats that
 312         # you wish to offer.
 313         # To disable system wide have in $GITWEB_CONFIG
 314         # $feature{'snapshot'}{'default'} = [];
 315         # To have project specific config enable override in $GITWEB_CONFIG
 316         # $feature{'snapshot'}{'override'} = 1;
 317         # and in project config, a comma-separated list of formats or "none"
 318         # to disable.  Example: gitweb.snapshot = tbz2,zip;
 319         'snapshot' => {
 320                 'sub' => \&feature_snapshot,
 321                 'override' => 0,
 322                 'default' => ['tgz']},
 323
 324         # Enable text search, which will list the commits which match author,
 325         # committer or commit text to a given string.  Enabled by default.
 326         # Project specific override is not supported.
 327         #
 328         # Note that this controls all search features, which means that if
 329         # it is disabled, then 'grep' and 'pickaxe' search would also be
 330         # disabled.
 331         'search' => {
 332                 'override' => 0,
 333                 'default' => [1]},
 334
 335         # Enable grep search, which will list the files in currently selected
 336         # tree containing the given string. Enabled by default. This can be
 337         # potentially CPU-intensive, of course.
 338         # Note that you need to have 'search' feature enabled too.
 339
 340         # To enable system wide have in $GITWEB_CONFIG
 341         # $feature{'grep'}{'default'} = [1];
 342         # To have project specific config enable override in $GITWEB_CONFIG
 343         # $feature{'grep'}{'override'} = 1;
 344         # and in project config gitweb.grep = 0|1;
 345         'grep' => {
 346                 'sub' => sub { feature_bool('grep', @_) },
 347                 'override' => 0,
 348                 'default' => [1]},
 349
 350         # Enable the pickaxe search, which will list the commits that modified
 351         # a given string in a file. This can be practical and quite faster
 352         # alternative to 'blame', but still potentially CPU-intensive.
 353         # Note that you need to have 'search' feature enabled too.
 354
 355         # To enable system wide have in $GITWEB_CONFIG
 356         # $feature{'pickaxe'}{'default'} = [1];
 357         # To have project specific config enable override in $GITWEB_CONFIG
 358         # $feature{'pickaxe'}{'override'} = 1;
 359         # and in project config gitweb.pickaxe = 0|1;
 360         'pickaxe' => {
 361                 'sub' => sub { feature_bool('pickaxe', @_) },
 362                 'override' => 0,
 363                 'default' => [1]},
 364
 365         # Enable showing size of blobs in a 'tree' view, in a separate
 366         # column, similar to what 'ls -l' does.  This cost a bit of IO.
 367
 368         # To disable system wide have in $GITWEB_CONFIG
 369         # $feature{'show-sizes'}{'default'} = [0];
 370         # To have project specific config enable override in $GITWEB_CONFIG
 371         # $feature{'show-sizes'}{'override'} = 1;
 372         # and in project config gitweb.showsizes = 0|1;
 373         'show-sizes' => {
 374                 'sub' => sub { feature_bool('showsizes', @_) },
 375                 'override' => 0,
 376                 'default' => [1]},
 377
 378         # Make gitweb use an alternative format of the URLs which can be
 379         # more readable and natural-looking: project name is embedded
 380         # directly in the path and the query string contains other
 381         # auxiliary information. All gitweb installations recognize
 382         # URL in either format; this configures in which formats gitweb
 383         # generates links.
 384
 385         # To enable system wide have in $GITWEB_CONFIG
 386         # $feature{'pathinfo'}{'default'} = [1];
 387         # Project specific override is not supported.
 388
 389         # Note that you will need to change the default location of CSS,
 390         # favicon, logo and possibly other files to an absolute URL. Also,
 391         # if gitweb.cgi serves as your indexfile, you will need to force
 392         # $my_uri to contain the script name in your $GITWEB_CONFIG.
 393         'pathinfo' => {
 394                 'override' => 0,
 395                 'default' => [0]},
 396
 397         # Make gitweb consider projects in project root subdirectories
 398         # to be forks of existing projects. Given project $projname.git,
 399         # projects matching $projname/*.git will not be shown in the main
 400         # projects list, instead a '+' mark will be added to $projname
 401         # there and a 'forks' view will be enabled for the project, listing
 402         # all the forks. If project list is taken from a file, forks have
 403         # to be listed after the main project.
 404
 405         # To enable system wide have in $GITWEB_CONFIG
 406         # $feature{'forks'}{'default'} = [1];
 407         # Project specific override is not supported.
 408         'forks' => {
 409                 'override' => 0,
 410                 'default' => [0]},
 411
 412         # Insert custom links to the action bar of all project pages.
 413         # This enables you mainly to link to third-party scripts integrating
 414         # into gitweb; e.g. git-browser for graphical history representation
 415         # or custom web-based repository administration interface.
 416
 417         # The 'default' value consists of a list of triplets in the form
 418         # (label, link, position) where position is the label after which
 419         # to insert the link and link is a format string where %n expands
 420         # to the project name, %f to the project path within the filesystem,
 421         # %h to the current hash (h gitweb parameter) and %b to the current
 422         # hash base (hb gitweb parameter); %% expands to %.
 423
 424         # To enable system wide have in $GITWEB_CONFIG e.g.
 425         # $feature{'actions'}{'default'} = [('graphiclog',
 426         #       '/git-browser/by-commit.html?r=%n', 'summary')];
 427         # Project specific override is not supported.
 428         'actions' => {
 429                 'override' => 0,
 430                 'default' => []},
 431
 432         # Allow gitweb scan project content tags of project repository,
 433         # and display the popular Web 2.0-ish "tag cloud" near the projects
 434         # list.  Note that this is something COMPLETELY different from the
 435         # normal Git tags.
 436
 437         # gitweb by itself can show existing tags, but it does not handle
 438         # tagging itself; you need to do it externally, outside gitweb.
 439         # The format is described in git_get_project_ctags() subroutine.
 440         # You may want to install the HTML::TagCloud Perl module to get
 441         # a pretty tag cloud instead of just a list of tags.
 442
 443         # To enable system wide have in $GITWEB_CONFIG
 444         # $feature{'ctags'}{'default'} = [1];
 445         # Project specific override is not supported.
 446
 447         # In the future whether ctags editing is enabled might depend
 448         # on the value, but using 1 should always mean no editing of ctags.
 449         'ctags' => {
 450                 'override' => 0,
 451                 'default' => [0]},
 452
 453         # The maximum number of patches in a patchset generated in patch
 454         # view. Set this to 0 or undef to disable patch view, or to a
 455         # negative number to remove any limit.
 456
 457         # To disable system wide have in $GITWEB_CONFIG
 458         # $feature{'patches'}{'default'} = [0];
 459         # To have project specific config enable override in $GITWEB_CONFIG
 460         # $feature{'patches'}{'override'} = 1;
 461         # and in project config gitweb.patches = 0|n;
 462         # where n is the maximum number of patches allowed in a patchset.
 463         'patches' => {
 464                 'sub' => \&feature_patches,
 465                 'override' => 0,
 466                 'default' => [16]},
 467
 468         # Avatar support. When this feature is enabled, views such as
 469         # shortlog or commit will display an avatar associated with
 470         # the email of the committer(s) and/or author(s).
 471
 472         # Currently available providers are gravatar and picon.
 473         # If an unknown provider is specified, the feature is disabled.
 474
 475         # Gravatar depends on Digest::MD5.
 476         # Picon currently relies on the indiana.edu database.
 477
 478         # To enable system wide have in $GITWEB_CONFIG
 479         # $feature{'avatar'}{'default'} = ['<provider>'];
 480         # where <provider> is either gravatar or picon.
 481         # To have project specific config enable override in $GITWEB_CONFIG
 482         # $feature{'avatar'}{'override'} = 1;
 483         # and in project config gitweb.avatar = <provider>;
 484         'avatar' => {
 485                 'sub' => \&feature_avatar,
 486                 'override' => 0,
 487                 'default' => ['']},
 488
 489         # Enable displaying how much time and how many git commands
 490         # it took to generate and display page.  Disabled by default.
 491         # Project specific override is not supported.
 492         'timed' => {
 493                 'override' => 0,
 494                 'default' => [0]},
 495
 496         # Enable turning some links into links to actions which require
 497         # JavaScript to run (like 'blame_incremental').  Not enabled by
 498         # default.  Project specific override is currently not supported.
 499         'javascript-actions' => {
 500                 'override' => 0,
 501                 'default' => [0]},
 502
 503         # Enable and configure ability to change common timezone for dates
 504         # in gitweb output via JavaScript.  Enabled by default.
 505         # Project specific override is not supported.
 506         'javascript-timezone' => {
 507                 'override' => 0,
 508                 'default' => [
 509                         'local',     # default timezone: 'utc', 'local', or '(-|+)HHMM' format,
 510                                      # or undef to turn off this feature
 511                         'gitweb_tz', # name of cookie where to store selected timezone
 512                         'datetime',  # CSS class used to mark up dates for manipulation
 513                 ]},
 514
 515         # Syntax highlighting support. This is based on Daniel Svensson's
 516         # and Sham Chukoury's work in gitweb-xmms2.git.
 517         # It requires the 'highlight' program present in $PATH,
 518         # and therefore is disabled by default.
 519
 520         # To enable system wide have in $GITWEB_CONFIG
 521         # $feature{'highlight'}{'default'} = [1];
 522
 523         'highlight' => {
 524                 'sub' => sub { feature_bool('highlight', @_) },
 525                 'override' => 0,
 526                 'default' => [0]},
 527
 528         # Enable displaying of remote heads in the heads list
 529
 530         # To enable system wide have in $GITWEB_CONFIG
 531         # $feature{'remote_heads'}{'default'} = [1];
 532         # To have project specific config enable override in $GITWEB_CONFIG
 533         # $feature{'remote_heads'}{'override'} = 1;
 534         # and in project config gitweb.remote_heads = 0|1;
 535         'remote_heads' => {
 536                 'sub' => sub { feature_bool('remote_heads', @_) },
 537                 'override' => 0,
 538                 'default' => [0]},
 539 );
 540
 541 sub gitweb_get_feature {
 542         my ($name) = @_;
 543         return unless exists $feature{$name};
 544         my ($sub, $override, @defaults) = (
 545                 $feature{$name}{'sub'},
 546                 $feature{$name}{'override'},
 547                 @{$feature{$name}{'default'}});
 548         # project specific override is possible only if we have project
 549         our $git_dir; # global variable, declared later
 550         if (!$override || !defined $git_dir) {
 551                 return @defaults;
 552         }
 553         if (!defined $sub) {
 554                 warn "feature $name is not overridable";
 555                 return @defaults;
 556         }
 557         return $sub->(@defaults);
 558 }
 559
 560 # A wrapper to check if a given feature is enabled.
 561 # With this, you can say
 562 #
 563 #   my $bool_feat = gitweb_check_feature('bool_feat');
 564 #   gitweb_check_feature('bool_feat') or somecode;
 565 #
 566 # instead of
 567 #
 568 #   my ($bool_feat) = gitweb_get_feature('bool_feat');
 569 #   (gitweb_get_feature('bool_feat'))[0] or somecode;
 570 #
 571 sub gitweb_check_feature {
 572         return (gitweb_get_feature(@_))[0];
 573 }
 574
 575
 576 sub feature_bool {
 577         my $key = shift;
 578         my ($val) = git_get_project_config($key, '--bool');
 579
 580         if (!defined $val) {
 581                 return ($_[0]);
 582         } elsif ($val eq 'true') {
 583                 return (1);
 584         } elsif ($val eq 'false') {
 585                 return (0);
 586         }
 587 }
 588
 589 sub feature_snapshot {
 590         my (@fmts) = @_;
 591
 592         my ($val) = git_get_project_config('snapshot');
 593
 594         if ($val) {
 595                 @fmts = ($val eq 'none' ? () : split /\s*[,\s]\s*/, $val);
 596         }
 597
 598         return @fmts;
 599 }
 600
 601 sub feature_patches {
 602         my @val = (git_get_project_config('patches', '--int'));
 603
 604         if (@val) {
 605                 return @val;
 606         }
 607
 608         return ($_[0]);
 609 }
 610
 611 sub feature_avatar {
 612         my @val = (git_get_project_config('avatar'));
 613
 614         return @val ? @val : @_;
 615 }
 616
 617 # checking HEAD file with -e is fragile if the repository was
 618 # initialized long time ago (i.e. symlink HEAD) and was pack-ref'ed
 619 # and then pruned.
 620 sub check_head_link {
 621         my ($dir) = @_;
 622         my $headfile = "$dir/HEAD";
 623         return ((-e $headfile) ||
 624                 (-l $headfile && readlink($headfile) =~ /^refs\/heads\//));
 625 }
 626
 627 sub check_export_ok {
 628         my ($dir) = @_;
 629         return (check_head_link($dir) &&
 630                 (!$export_ok || -e "$dir/$export_ok") &&
 631                 (!$export_auth_hook || $export_auth_hook->($dir)));
 632 }
 633
 634 # process alternate names for backward compatibility
 635 # filter out unsupported (unknown) snapshot formats
 636 sub filter_snapshot_fmts {
 637         my @fmts = @_;
 638
 639         @fmts = map {
 640                 exists $known_snapshot_format_aliases{$_} ?
 641                        $known_snapshot_format_aliases{$_} : $_} @fmts;
 642         @fmts = grep {
 643                 exists $known_snapshot_formats{$_} &&
 644                 !$known_snapshot_formats{$_}{'disabled'}} @fmts;
 645 }
 646
 647 # If it is set to code reference, it is code that it is to be run once per
 648 # request, allowing updating configurations that change with each request,
 649 # while running other code in config file only once.
 650 #
 651 # Otherwise, if it is false then gitweb would process config file only once;
 652 # if it is true then gitweb config would be run for each request.
 653 our $per_request_config = 1;
 654
 655 # read and parse gitweb config file given by its parameter.
 656 # returns true on success, false on recoverable error, allowing
 657 # to chain this subroutine, using first file that exists.
 658 # dies on errors during parsing config file, as it is unrecoverable.
 659 sub read_config_file {
 660         my $filename = shift;
 661         return unless defined $filename;
 662         # die if there are errors parsing config file
 663         if (-e $filename) {
 664                 do $filename;
 665                 die $@ if $@;
 666                 return 1;
 667         }
 668         return;
 669 }
 670
 671 our ($GITWEB_CONFIG, $GITWEB_CONFIG_SYSTEM, $GITWEB_CONFIG_COMMON);
 672 sub evaluate_gitweb_config {
 673         our $GITWEB_CONFIG = $ENV{'GITWEB_CONFIG'} || "++GITWEB_CONFIG++";
 674         our $GITWEB_CONFIG_SYSTEM = $ENV{'GITWEB_CONFIG_SYSTEM'} || "++GITWEB_CONFIG_SYSTEM++";
 675         our $GITWEB_CONFIG_COMMON = $ENV{'GITWEB_CONFIG_COMMON'} || "++GITWEB_CONFIG_COMMON++";
 676
 677         # Protect agains duplications of file names, to not read config twice.
 678         # Only one of $GITWEB_CONFIG and $GITWEB_CONFIG_SYSTEM is used, so
 679         # there possibility of duplication of filename there doesn't matter.
 680         $GITWEB_CONFIG = ""        if ($GITWEB_CONFIG eq $GITWEB_CONFIG_COMMON);
 681         $GITWEB_CONFIG_SYSTEM = "" if ($GITWEB_CONFIG_SYSTEM eq $GITWEB_CONFIG_COMMON);
 682
 683         # Common system-wide settings for convenience.
 684         # Those settings can be ovverriden by GITWEB_CONFIG or GITWEB_CONFIG_SYSTEM.
 685         read_config_file($GITWEB_CONFIG_COMMON);
 686
 687         # Use first config file that exists.  This means use the per-instance
 688         # GITWEB_CONFIG if exists, otherwise use GITWEB_SYSTEM_CONFIG.
 689         read_config_file($GITWEB_CONFIG) and return;
 690         read_config_file($GITWEB_CONFIG_SYSTEM);
 691 }
 692
 693 # Get loadavg of system, to compare against $maxload.
 694 # Currently it requires '/proc/loadavg' present to get loadavg;
 695 # if it is not present it returns 0, which means no load checking.
 696 sub get_loadavg {
 697         if( -e '/proc/loadavg' ){
 698                 open my $fd, '<', '/proc/loadavg'
 699                         or return 0;
 700                 my @load = split(/\s+/, scalar <$fd>);
 701                 close $fd;
 702
 703                 # The first three columns measure CPU and IO utilization of the last one,
 704                 # five, and 10 minute periods.  The fourth column shows the number of
 705                 # currently running processes and the total number of processes in the m/n
 706                 # format.  The last column displays the last process ID used.
 707                 return $load[0] || 0;
 708         }
 709         # additional checks for load average should go here for things that don't export
 710         # /proc/loadavg
 711
 712         return 0;
 713 }
 714
 715 # version of the core git binary
 716 our $git_version;
 717 sub evaluate_git_version {
 718         our $git_version = qx("$GIT" --version) =~ m/git version (.*)$/ ? $1 : "unknown";
 719         $number_of_git_cmds++;
 720 }
 721
 722 sub check_loadavg {
 723         if (defined $maxload && get_loadavg() > $maxload) {
 724                 die_error(503, "The load average on the server is too high");
 725         }
 726 }
 727
 728 # ======================================================================
 729 # input validation and dispatch
 730
 731 # input parameters can be collected from a variety of sources (presently, CGI
 732 # and PATH_INFO), so we define an %input_params hash that collects them all
 733 # together during validation: this allows subsequent uses (e.g. href()) to be
 734 # agnostic of the parameter origin
 735
 736 our %input_params = ();
 737
 738 # input parameters are stored with the long parameter name as key. This will
 739 # also be used in the href subroutine to convert parameters to their CGI
 740 # equivalent, and since the href() usage is the most frequent one, we store
 741 # the name -> CGI key mapping here, instead of the reverse.
 742 #
 743 # XXX: Warning: If you touch this, check the search form for updating,
 744 # too.
 745
 746 our @cgi_param_mapping = (
 747         project => "p",
 748         action => "a",
 749         file_name => "f",
 750         file_parent => "fp",
 751         hash => "h",
 752         hash_parent => "hp",
 753         hash_base => "hb",
 754         hash_parent_base => "hpb",
 755         page => "pg",
 756         order => "o",
 757         searchtext => "s",
 758         searchtype => "st",
 759         snapshot_format => "sf",
 760         extra_options => "opt",
 761         search_use_regexp => "sr",
 762         ctag => "by_tag",
 763         # this must be last entry (for manipulation from JavaScript)
 764         javascript => "js"
 765 );
 766 our %cgi_param_mapping = @cgi_param_mapping;
 767
 768 # we will also need to know the possible actions, for validation
 769 our %actions = (
 770         "blame" => \&git_blame,
 771         "blame_incremental" => \&git_blame_incremental,
 772         "blame_data" => \&git_blame_data,
 773         "blobdiff" => \&git_blobdiff,
 774         "blobdiff_plain" => \&git_blobdiff_plain,
 775         "blob" => \&git_blob,
 776         "blob_plain" => \&git_blob_plain,
 777         "commitdiff" => \&git_commitdiff,
 778         "commitdiff_plain" => \&git_commitdiff_plain,
 779         "commit" => \&git_commit,
 780         "forks" => \&git_forks,
 781         "heads" => \&git_heads,
 782         "history" => \&git_history,
 783         "log" => \&git_log,
 784         "patch" => \&git_patch,
 785         "patches" => \&git_patches,
 786         "remotes" => \&git_remotes,
 787         "rss" => \&git_rss,
 788         "atom" => \&git_atom,
 789         "search" => \&git_search,
 790         "search_help" => \&git_search_help,
 791         "shortlog" => \&git_shortlog,
 792         "summary" => \&git_summary,
 793         "tag" => \&git_tag,
 794         "tags" => \&git_tags,
 795         "tree" => \&git_tree,
 796         "snapshot" => \&git_snapshot,
 797         "object" => \&git_object,
 798         # those below don't need $project
 799         "opml" => \&git_opml,
 800         "project_list" => \&git_project_list,
 801         "project_index" => \&git_project_index,
 802 );
 803
 804 # finally, we have the hash of allowed extra_options for the commands that
 805 # allow them
 806 our %allowed_options = (
 807         "--no-merges" => [ qw(rss atom log shortlog history) ],
 808 );
 809
 810 # fill %input_params with the CGI parameters. All values except for 'opt'
 811 # should be single values, but opt can be an array. We should probably
 812 # build an array of parameters that can be multi-valued, but since for the time
 813 # being it's only this one, we just single it out
 814 sub evaluate_query_params {
 815         our $cgi;
 816
 817         while (my ($name, $symbol) = each %cgi_param_mapping) {
 818                 if ($symbol eq 'opt') {
 819                         $input_params{$name} = [ $cgi->param($symbol) ];
 820                 } else {
 821                         $input_params{$name} = $cgi->param($symbol);
 822                 }
 823         }
 824 }
 825
 826 # now read PATH_INFO and update the parameter list for missing parameters
 827 sub evaluate_path_info {
 828         return if defined $input_params{'project'};
 829         return if !$path_info;
 830         $path_info =~ s,^/+,,;
 831         return if !$path_info;
 832
 833         # find which part of PATH_INFO is project
 834         my $project = $path_info;
 835         $project =~ s,/+$,,;
 836         while ($project && !check_head_link("$projectroot/$project")) {
 837                 $project =~ s,/*[^/]*$,,;
 838         }
 839         return unless $project;
 840         $input_params{'project'} = $project;
 841
 842         # do not change any parameters if an action is given using the query string
 843         return if $input_params{'action'};
 844         $path_info =~ s,^\Q$project\E/*,,;
 845
 846         # next, check if we have an action
 847         my $action = $path_info;
 848         $action =~ s,/.*$,,;
 849         if (exists $actions{$action}) {
 850                 $path_info =~ s,^$action/*,,;
 851                 $input_params{'action'} = $action;
 852         }
 853
 854         # list of actions that want hash_base instead of hash, but can have no
 855         # pathname (f) parameter
 856         my @wants_base = (
 857                 'tree',
 858                 'history',
 859         );
 860
 861         # we want to catch, among others
 862         # [$hash_parent_base[:$file_parent]..]$hash_parent[:$file_name]
 863         my ($parentrefname, $parentpathname, $refname, $pathname) =
 864                 ($path_info =~ /^(?:(.+?)(?::(.+))?\.\.)?([^:]+?)?(?::(.+))?$/);
 865
 866         # first, analyze the 'current' part
 867         if (defined $pathname) {
 868                 # we got "branch:filename" or "branch:dir/"
 869                 # we could use git_get_type(branch:pathname), but:
 870                 # - it needs $git_dir
 871                 # - it does a git() call
 872                 # - the convention of terminating directories with a slash
 873                 #   makes it superfluous
 874                 # - embedding the action in the PATH_INFO would make it even
 875                 #   more superfluous
 876                 $pathname =~ s,^/+,,;
 877                 if (!$pathname || substr($pathname, -1) eq "/") {
 878                         $input_params{'action'} ||= "tree";
 879                         $pathname =~ s,/$,,;
 880                 } else {
 881                         # the default action depends on whether we had parent info
 882                         # or not
 883                         if ($parentrefname) {
 884                                 $input_params{'action'} ||= "blobdiff_plain";
 885                         } else {
 886                                 $input_params{'action'} ||= "blob_plain";
 887                         }
 888                 }
 889                 $input_params{'hash_base'} ||= $refname;
 890                 $input_params{'file_name'} ||= $pathname;
 891         } elsif (defined $refname) {
 892                 # we got "branch". In this case we have to choose if we have to
 893                 # set hash or hash_base.
 894                 #
 895                 # Most of the actions without a pathname only want hash to be
 896                 # set, except for the ones specified in @wants_base that want
 897                 # hash_base instead. It should also be noted that hand-crafted
 898                 # links having 'history' as an action and no pathname or hash
 899                 # set will fail, but that happens regardless of PATH_INFO.
 900                 if (defined $parentrefname) {
 901                         # if there is parent let the default be 'shortlog' action
 902                         # (for http://git.example.com/repo.git/A..B links); if there
 903                         # is no parent, dispatch will detect type of object and set
 904                         # action appropriately if required (if action is not set)
 905                         $input_params{'action'} ||= "shortlog";
 906                 }
 907                 if ($input_params{'action'} &&
 908                     grep { $_ eq $input_params{'action'} } @wants_base) {
 909                         $input_params{'hash_base'} ||= $refname;
 910                 } else {
 911                         $input_params{'hash'} ||= $refname;
 912                 }
 913         }
 914
 915         # next, handle the 'parent' part, if present
 916         if (defined $parentrefname) {
 917                 # a missing pathspec defaults to the 'current' filename, allowing e.g.
 918                 # someproject/blobdiff/oldrev..newrev:/filename
 919                 if ($parentpathname) {
 920                         $parentpathname =~ s,^/+,,;
 921                         $parentpathname =~ s,/$,,;
 922                         $input_params{'file_parent'} ||= $parentpathname;
 923                 } else {
 924                         $input_params{'file_parent'} ||= $input_params{'file_name'};
 925                 }
 926                 # we assume that hash_parent_base is wanted if a path was specified,
 927                 # or if the action wants hash_base instead of hash
 928                 if (defined $input_params{'file_parent'} ||
 929                         grep { $_ eq $input_params{'action'} } @wants_base) {
 930                         $input_params{'hash_parent_base'} ||= $parentrefname;
 931                 } else {
 932                         $input_params{'hash_parent'} ||= $parentrefname;
 933                 }
 934         }
 935
 936         # for the snapshot action, we allow URLs in the form
 937         # $project/snapshot/$hash.ext
 938         # where .ext determines the snapshot and gets removed from the
 939         # passed $refname to provide the $hash.
 940         #
 941         # To be able to tell that $refname includes the format extension, we
 942         # require the following two conditions to be satisfied:
 943         # - the hash input parameter MUST have been set from the $refname part
 944         #   of the URL (i.e. they must be equal)
 945         # - the snapshot format MUST NOT have been defined already (e.g. from
 946         #   CGI parameter sf)
 947         # It's also useless to try any matching unless $refname has a dot,
 948         # so we check for that too
 949         if (defined $input_params{'action'} &&
 950                 $input_params{'action'} eq 'snapshot' &&
 951                 defined $refname && index($refname, '.') != -1 &&
 952                 $refname eq $input_params{'hash'} &&
 953                 !defined $input_params{'snapshot_format'}) {
 954                 # We loop over the known snapshot formats, checking for
 955                 # extensions. Allowed extensions are both the defined suffix
 956                 # (which includes the initial dot already) and the snapshot
 957                 # format key itself, with a prepended dot
 958                 while (my ($fmt, $opt) = each %known_snapshot_formats) {
 959                         my $hash = $refname;
 960                         unless ($hash =~ s/(\Q$opt->{'suffix'}\E|\Q.$fmt\E)$//) {
 961                                 next;
 962                         }
 963                         my $sfx = $1;
 964                         # a valid suffix was found, so set the snapshot format
 965                         # and reset the hash parameter
 966                         $input_params{'snapshot_format'} = $fmt;
 967                         $input_params{'hash'} = $hash;
 968                         # we also set the format suffix to the one requested
 969                         # in the URL: this way a request for e.g. .tgz returns
 970                         # a .tgz instead of a .tar.gz
 971                         $known_snapshot_formats{$fmt}{'suffix'} = $sfx;
 972                         last;
 973                 }
 974         }
 975 }
 976
 977 our ($action, $project, $file_name, $file_parent, $hash, $hash_parent, $hash_base,
 978      $hash_parent_base, @extra_options, $page, $searchtype, $search_use_regexp,
 979      $searchtext, $search_regexp);
 980 sub evaluate_and_validate_params {
 981         our $action = $input_params{'action'};
 982         if (defined $action) {
 983                 if (!validate_action($action)) {
 984                         die_error(400, "Invalid action parameter");
 985                 }
 986         }
 987
 988         # parameters which are pathnames
 989         our $project = $input_params{'project'};
 990         if (defined $project) {
 991                 if (!validate_project($project)) {
 992                         undef $project;
 993                         die_error(404, "No such project");
 994                 }
 995         }
 996
 997         our $file_name = $input_params{'file_name'};
 998         if (defined $file_name) {
 999                 if (!validate_pathname($file_name)) {
1000                         die_error(400, "Invalid file parameter");
1001                 }
1002         }
1003
1004         our $file_parent = $input_params{'file_parent'};
1005         if (defined $file_parent) {
1006                 if (!validate_pathname($file_parent)) {
1007                         die_error(400, "Invalid file parent parameter");
1008                 }
1009         }
1010
1011         # parameters which are refnames
1012         our $hash = $input_params{'hash'};
1013         if (defined $hash) {
1014                 if (!validate_refname($hash)) {
1015                         die_error(400, "Invalid hash parameter");
1016                 }
1017         }
1018
1019         our $hash_parent = $input_params{'hash_parent'};
1020         if (defined $hash_parent) {
1021                 if (!validate_refname($hash_parent)) {
1022                         die_error(400, "Invalid hash parent parameter");
1023                 }
1024         }
1025
1026         our $hash_base = $input_params{'hash_base'};
1027         if (defined $hash_base) {
1028                 if (!validate_refname($hash_base)) {
1029                         die_error(400, "Invalid hash base parameter");
1030                 }
1031         }
1032
1033         our @extra_options = @{$input_params{'extra_options'}};
1034         # @extra_options is always defined, since it can only be (currently) set from
1035         # CGI, and $cgi->param() returns the empty array in array context if the param
1036         # is not set
1037         foreach my $opt (@extra_options) {
1038                 if (not exists $allowed_options{$opt}) {
1039                         die_error(400, "Invalid option parameter");
1040                 }
1041                 if (not grep(/^$action$/, @{$allowed_options{$opt}})) {
1042                         die_error(400, "Invalid option parameter for this action");
1043                 }
1044         }
1045
1046         our $hash_parent_base = $input_params{'hash_parent_base'};
1047         if (defined $hash_parent_base) {
1048                 if (!validate_refname($hash_parent_base)) {
1049                         die_error(400, "Invalid hash parent base parameter");
1050                 }
1051         }
1052
1053         # other parameters
1054         our $page = $input_params{'page'};
1055         if (defined $page) {
1056                 if ($page =~ m/[^0-9]/) {
1057                         die_error(400, "Invalid page parameter");
1058                 }
1059         }
1060
1061         our $searchtype = $input_params{'searchtype'};
1062         if (defined $searchtype) {
1063                 if ($searchtype =~ m/[^a-z]/) {
1064                         die_error(400, "Invalid searchtype parameter");
1065                 }
1066         }
1067
1068         our $search_use_regexp = $input_params{'search_use_regexp'};
1069
1070         our $searchtext = $input_params{'searchtext'};
1071         our $search_regexp;
1072         if (defined $searchtext) {
1073                 if (length($searchtext) < 2) {
1074                         die_error(403, "At least two characters are required for search parameter");
1075                 }
1076                 $search_regexp = $search_use_regexp ? $searchtext : quotemeta $searchtext;
1077         }
1078 }
1079
1080 # path to the current git repository
1081 our $git_dir;
1082 sub evaluate_git_dir {
1083         our $git_dir = "$projectroot/$project" if $project;
1084 }
1085
1086 our (@snapshot_fmts, $git_avatar);
1087 sub configure_gitweb_features {
1088         # list of supported snapshot formats
1089         our @snapshot_fmts = gitweb_get_feature('snapshot');
1090         @snapshot_fmts = filter_snapshot_fmts(@snapshot_fmts);
1091
1092         # check that the avatar feature is set to a known provider name,
1093         # and for each provider check if the dependencies are satisfied.
1094         # if the provider name is invalid or the dependencies are not met,
1095         # reset $git_avatar to the empty string.
1096         our ($git_avatar) = gitweb_get_feature('avatar');
1097         if ($git_avatar eq 'gravatar') {
1098                 $git_avatar = '' unless (eval { require Digest::MD5; 1; });
1099         } elsif ($git_avatar eq 'picon') {
1100                 # no dependencies
1101         } else {
1102                 $git_avatar = '';
1103         }
1104 }
1105
1106 # custom error handler: 'die <message>' is Internal Server Error
1107 sub handle_errors_html {
1108         my $msg = shift; # it is already HTML escaped
1109
1110         # to avoid infinite loop where error occurs in die_error,
1111         # change handler to default handler, disabling handle_errors_html
1112         set_message("Error occured when inside die_error:\n$msg");
1113
1114         # you cannot jump out of die_error when called as error handler;
1115         # the subroutine set via CGI::Carp::set_message is called _after_
1116         # HTTP headers are already written, so it cannot write them itself
1117         die_error(undef, undef, $msg, -error_handler => 1, -no_http_header => 1);
1118 }
1119 set_message(\&handle_errors_html);
1120
1121 # dispatch
1122 sub dispatch {
1123         if (!defined $action) {
1124                 if (defined $hash) {
1125                         $action = git_get_type($hash);
1126                 } elsif (defined $hash_base && defined $file_name) {
1127                         $action = git_get_type("$hash_base:$file_name");
1128                 } elsif (defined $project) {
1129                         $action = 'summary';
1130                 } else {
1131                         $action = 'project_list';
1132                 }
1133         }
1134         if (!defined($actions{$action})) {
1135                 die_error(400, "Unknown action");
1136         }
1137         if ($action !~ m/^(?:opml|project_list|project_index)$/ &&
1138             !$project) {
1139                 die_error(400, "Project needed");
1140         }
1141         $actions{$action}->();
1142 }
1143
1144 sub reset_timer {
1145         our $t0 = [ gettimeofday() ]
1146                 if defined $t0;
1147         our $number_of_git_cmds = 0;
1148 }
1149
1150 our $first_request = 1;
1151 sub run_request {
1152         reset_timer();
1153
1154         evaluate_uri();
1155         if ($first_request) {
1156                 evaluate_gitweb_config();
1157                 evaluate_git_version();
1158         }
1159         if ($per_request_config) {
1160                 if (ref($per_request_config) eq 'CODE') {
1161                         $per_request_config->();
1162                 } elsif (!$first_request) {
1163                         evaluate_gitweb_config();
1164                 }
1165         }
1166         check_loadavg();
1167
1168         # $projectroot and $projects_list might be set in gitweb config file
1169         $projects_list ||= $projectroot;
1170
1171         evaluate_query_params();
1172         evaluate_path_info();
1173         evaluate_and_validate_params();
1174         evaluate_git_dir();
1175
1176         configure_gitweb_features();
1177
1178         dispatch();
1179 }
1180
1181 our $is_last_request = sub { 1 };
1182 our ($pre_dispatch_hook, $post_dispatch_hook, $pre_listen_hook);
1183 our $CGI = 'CGI';
1184 our $cgi;
1185 sub configure_as_fcgi {
1186         require CGI::Fast;
1187         our $CGI = 'CGI::Fast';
1188
1189         my $request_number = 0;
1190         # let each child service 100 requests
1191         our $is_last_request = sub { ++$request_number > 100 };
1192 }
1193 sub evaluate_argv {
1194         my $script_name = $ENV{'SCRIPT_NAME'} || $ENV{'SCRIPT_FILENAME'} || __FILE__;
1195         configure_as_fcgi()
1196                 if $script_name =~ /\.fcgi$/;
1197
1198         return unless (@ARGV);
1199
1200         require Getopt::Long;
1201         Getopt::Long::GetOptions(
1202                 'fastcgi|fcgi|f' => \&configure_as_fcgi,
1203                 'nproc|n=i' => sub {
1204                         my ($arg, $val) = @_;
1205                         return unless eval { require FCGI::ProcManager; 1; };
1206                         my $proc_manager = FCGI::ProcManager->new({
1207                                 n_processes => $val,
1208                         });
1209                         our $pre_listen_hook    = sub { $proc_manager->pm_manage()        };
1210                         our $pre_dispatch_hook  = sub { $proc_manager->pm_pre_dispatch()  };
1211                         our $post_dispatch_hook = sub { $proc_manager->pm_post_dispatch() };
1212                 },
1213         );
1214 }
1215
1216 sub run {
1217         evaluate_argv();
1218
1219         $first_request = 1;
1220         $pre_listen_hook->()
1221                 if $pre_listen_hook;
1222
1223  REQUEST:
1224         while ($cgi = $CGI->new()) {
1225                 $pre_dispatch_hook->()
1226                         if $pre_dispatch_hook;
1227
1228                 run_request();
1229
1230                 $post_dispatch_hook->()
1231                         if $post_dispatch_hook;
1232                 $first_request = 0;
1233
1234                 last REQUEST if ($is_last_request->());
1235         }
1236
1237  DONE_GITWEB:
1238         1;
1239 }
1240
1241 run();
1242
1243 if (defined caller) {
1244         # wrapped in a subroutine processing requests,
1245         # e.g. mod_perl with ModPerl::Registry, or PSGI with Plack::App::WrapCGI
1246         return;
1247 } else {
1248         # pure CGI script, serving single request
1249         exit;
1250 }
1251
1252 ## ======================================================================
1253 ## action links
1254
1255 # possible values of extra options
1256 # -full => 0|1      - use absolute/full URL ($my_uri/$my_url as base)
1257 # -replay => 1      - start from a current view (replay with modifications)
1258 # -path_info => 0|1 - don't use/use path_info URL (if possible)
1259 # -anchor => ANCHOR - add #ANCHOR to end of URL, implies -replay if used alone
1260 sub href {
1261         my %params = @_;
1262         # default is to use -absolute url() i.e. $my_uri
1263         my $href = $params{-full} ? $my_url : $my_uri;
1264
1265         # implicit -replay, must be first of implicit params
1266         $params{-replay} = 1 if (keys %params == 1 && $params{-anchor});
1267
1268         $params{'project'} = $project unless exists $params{'project'};
1269
1270         if ($params{-replay}) {
1271                 while (my ($name, $symbol) = each %cgi_param_mapping) {
1272                         if (!exists $params{$name}) {
1273                                 $params{$name} = $input_params{$name};
1274                         }
1275                 }
1276         }
1277
1278         my $use_pathinfo = gitweb_check_feature('pathinfo');
1279         if (defined $params{'project'} &&
1280             (exists $params{-path_info} ? $params{-path_info} : $use_pathinfo)) {
1281                 # try to put as many parameters as possible in PATH_INFO:
1282                 #   - project name
1283                 #   - action
1284                 #   - hash_parent or hash_parent_base:/file_parent
1285                 #   - hash or hash_base:/filename
1286                 #   - the snapshot_format as an appropriate suffix
1287
1288                 # When the script is the root DirectoryIndex for the domain,
1289                 # $href here would be something like http://gitweb.example.com/
1290                 # Thus, we strip any trailing / from $href, to spare us double
1291                 # slashes in the final URL
1292                 $href =~ s,/$,,;
1293
1294                 # Then add the project name, if present
1295                 $href .= "/".esc_path_info($params{'project'});
1296                 delete $params{'project'};
1297
1298                 # since we destructively absorb parameters, we keep this
1299                 # boolean that remembers if we're handling a snapshot
1300                 my $is_snapshot = $params{'action'} eq 'snapshot';
1301
1302                 # Summary just uses the project path URL, any other action is
1303                 # added to the URL
1304                 if (defined $params{'action'}) {
1305                         $href .= "/".esc_path_info($params{'action'})
1306                                 unless $params{'action'} eq 'summary';
1307                         delete $params{'action'};
1308                 }
1309
1310                 # Next, we put hash_parent_base:/file_parent..hash_base:/file_name,
1311                 # stripping nonexistent or useless pieces
1312                 $href .= "/" if ($params{'hash_base'} || $params{'hash_parent_base'}
1313                         || $params{'hash_parent'} || $params{'hash'});
1314                 if (defined $params{'hash_base'}) {
1315                         if (defined $params{'hash_parent_base'}) {
1316                                 $href .= esc_path_info($params{'hash_parent_base'});
1317                                 # skip the file_parent if it's the same as the file_name
1318                                 if (defined $params{'file_parent'}) {
1319                                         if (defined $params{'file_name'} && $params{'file_parent'} eq $params{'file_name'}) {
1320                                                 delete $params{'file_parent'};
1321                                         } elsif ($params{'file_parent'} !~ /\.\./) {
1322                                                 $href .= ":/".esc_path_info($params{'file_parent'});
1323                                                 delete $params{'file_parent'};
1324                                         }
1325                                 }
1326                                 $href .= "..";
1327                                 delete $params{'hash_parent'};
1328                                 delete $params{'hash_parent_base'};
1329                         } elsif (defined $params{'hash_parent'}) {
1330                                 $href .= esc_path_info($params{'hash_parent'}). "..";
1331                                 delete $params{'hash_parent'};
1332                         }
1333
1334                         $href .= esc_path_info($params{'hash_base'});
1335                         if (defined $params{'file_name'} && $params{'file_name'} !~ /\.\./) {
1336                                 $href .= ":/".esc_path_info($params{'file_name'});
1337                                 delete $params{'file_name'};
1338                         }
1339                         delete $params{'hash'};
1340                         delete $params{'hash_base'};
1341                 } elsif (defined $params{'hash'}) {
1342                         $href .= esc_path_info($params{'hash'});
1343                         delete $params{'hash'};
1344                 }
1345
1346                 # If the action was a snapshot, we can absorb the
1347                 # snapshot_format parameter too
1348                 if ($is_snapshot) {
1349                         my $fmt = $params{'snapshot_format'};
1350                         # snapshot_format should always be defined when href()
1351                         # is called, but just in case some code forgets, we
1352                         # fall back to the default
1353                         $fmt ||= $snapshot_fmts[0];
1354                         $href .= $known_snapshot_formats{$fmt}{'suffix'};
1355                         delete $params{'snapshot_format'};
1356                 }
1357         }
1358
1359         # now encode the parameters explicitly
1360         my @result = ();
1361         for (my $i = 0; $i < @cgi_param_mapping; $i += 2) {
1362                 my ($name, $symbol) = ($cgi_param_mapping[$i], $cgi_param_mapping[$i+1]);
1363                 if (defined $params{$name}) {
1364                         if (ref($params{$name}) eq "ARRAY") {
1365                                 foreach my $par (@{$params{$name}}) {
1366                                         push @result, $symbol . "=" . esc_param($par);
1367                                 }
1368                         } else {
1369                                 push @result, $symbol . "=" . esc_param($params{$name});
1370                         }
1371                 }
1372         }
1373         $href .= "?" . join(';', @result) if scalar @result;
1374
1375         # final transformation: trailing spaces must be escaped (URI-encoded)
1376         $href =~ s/(\s+)$/CGI::escape($1)/e;
1377
1378         if ($params{-anchor}) {
1379                 $href .= "#".esc_param($params{-anchor});
1380         }
1381
1382         return $href;
1383 }
1384
1385
1386 ## ======================================================================
1387 ## validation, quoting/unquoting and escaping
1388
1389 sub validate_action {
1390         my $input = shift || return undef;
1391         return undef unless exists $actions{$input};
1392         return $input;
1393 }
1394
1395 sub validate_project {
1396         my $input = shift || return undef;
1397         if (!validate_pathname($input) ||
1398                 !(-d "$projectroot/$input") ||
1399                 !check_export_ok("$projectroot/$input") ||
1400                 ($strict_export && !project_in_list($input))) {
1401                 return undef;
1402         } else {
1403                 return $input;
1404         }
1405 }
1406
1407 sub validate_pathname {
1408         my $input = shift || return undef;
1409
1410         # no '.' or '..' as elements of path, i.e. no '.' nor '..'
1411         # at the beginning, at the end, and between slashes.
1412         # also this catches doubled slashes
1413         if ($input =~ m!(^|/)(|\.|\.\.)(/|$)!) {
1414                 return undef;
1415         }
1416         # no null characters
1417         if ($input =~ m!\0!) {
1418                 return undef;
1419         }
1420         return $input;
1421 }
1422
1423 sub validate_refname {
1424         my $input = shift || return undef;
1425
1426         # textual hashes are O.K.
1427         if ($input =~ m/^[0-9a-fA-F]{40}$/) {
1428                 return $input;
1429         }
1430         # it must be correct pathname
1431         $input = validate_pathname($input)
1432                 or return undef;
1433         # restrictions on ref name according to git-check-ref-format
1434         if ($input =~ m!(/\.|\.\.|[\000-\040\177 ~^:?*\[]|/$)!) {
1435                 return undef;
1436         }
1437         return $input;
1438 }
1439
1440 # decode sequences of octets in utf8 into Perl's internal form,
1441 # which is utf-8 with utf8 flag set if needed.  gitweb writes out
1442 # in utf-8 thanks to "binmode STDOUT, ':utf8'" at beginning
1443 sub to_utf8 {
1444         my $str = shift;
1445         return undef unless defined $str;
1446         if (utf8::valid($str)) {
1447                 utf8::decode($str);
1448                 return $str;
1449         } else {
1450                 return decode($fallback_encoding, $str, Encode::FB_DEFAULT);
1451         }
1452 }
1453
1454 # quote unsafe chars, but keep the slash, even when it's not
1455 # correct, but quoted slashes look too horrible in bookmarks
1456 sub esc_param {
1457         my $str = shift;
1458         return undef unless defined $str;
1459         $str =~ s/([^A-Za-z0-9\-_.~()\/:@ ]+)/CGI::escape($1)/eg;
1460         $str =~ s/ /\+/g;
1461         return $str;
1462 }
1463
1464 # the quoting rules for path_info fragment are slightly different
1465 sub esc_path_info {
1466         my $str = shift;
1467         return undef unless defined $str;
1468
1469         # path_info doesn't treat '+' as space (specially), but '?' must be escaped
1470         $str =~ s/([^A-Za-z0-9\-_.~();\/;:@&= +]+)/CGI::escape($1)/eg;
1471
1472         return $str;
1473 }
1474
1475 # quote unsafe chars in whole URL, so some characters cannot be quoted
1476 sub esc_url {
1477         my $str = shift;
1478         return undef unless defined $str;
1479         $str =~ s/([^A-Za-z0-9\-_.~();\/;?:@&= ]+)/CGI::escape($1)/eg;
1480         $str =~ s/ /\+/g;
1481         return $str;
1482 }
1483
1484 # quote unsafe characters in HTML attributes
1485 sub esc_attr {
1486
1487         # for XHTML conformance escaping '"' to '&quot;' is not enough
1488         return esc_html(@_);
1489 }
1490
1491 # replace invalid utf8 character with SUBSTITUTION sequence
1492 sub esc_html {
1493         my $str = shift;
1494         my %opts = @_;
1495
1496         return undef unless defined $str;
1497
1498         $str = to_utf8($str);
1499         $str = $cgi->escapeHTML($str);
1500         if ($opts{'-nbsp'}) {
1501                 $str =~ s/ /&nbsp;/g;
1502         }
1503         $str =~ s|([[:cntrl:]])|(($1 ne "\t") ? quot_cec($1) : $1)|eg;
1504         return $str;
1505 }
1506
1507 # quote control characters and escape filename to HTML
1508 sub esc_path {
1509         my $str = shift;
1510         my %opts = @_;
1511
1512         return undef unless defined $str;
1513
1514         $str = to_utf8($str);
1515         $str = $cgi->escapeHTML($str);
1516         if ($opts{'-nbsp'}) {
1517                 $str =~ s/ /&nbsp;/g;
1518         }
1519         $str =~ s|([[:cntrl:]])|quot_cec($1)|eg;
1520         return $str;
1521 }
1522
1523 # Sanitize for use in XHTML + application/xml+xhtm (valid XML 1.0)
1524 sub sanitize {
1525         my $str = shift;
1526
1527         return undef unless defined $str;
1528
1529         $str = to_utf8($str);
1530         $str =~ s|([[:cntrl:]])|($1 =~ /[\t\n\r]/ ? $1 : quot_cec($1))|eg;
1531         return $str;
1532 }
1533
1534 # Make control characters "printable", using character escape codes (CEC)
1535 sub quot_cec {
1536         my $cntrl = shift;
1537         my %opts = @_;
1538         my %es = ( # character escape codes, aka escape sequences
1539                 "\t" => '\t',   # tab            (HT)
1540                 "\n" => '\n',   # line feed      (LF)
1541                 "\r" => '\r',   # carrige return (CR)
1542                 "\f" => '\f',   # form feed      (FF)
1543                 "\b" => '\b',   # backspace      (BS)
1544                 "\a" => '\a',   # alarm (bell)   (BEL)
1545                 "\e" => '\e',   # escape         (ESC)
1546                 "\013" => '\v', # vertical tab   (VT)
1547                 "\000" => '\0', # nul character  (NUL)
1548         );
1549         my $chr = ( (exists $es{$cntrl})
1550                     ? $es{$cntrl}
1551                     : sprintf('\%2x', ord($cntrl)) );
1552         if ($opts{-nohtml}) {
1553                 return $chr;
1554         } else {
1555                 return "<span class=\"cntrl\">$chr</span>";
1556         }
1557 }
1558
1559 # Alternatively use unicode control pictures codepoints,
1560 # Unicode "printable representation" (PR)
1561 sub quot_upr {
1562         my $cntrl = shift;
1563         my %opts = @_;
1564
1565         my $chr = sprintf('&#%04d;', 0x2400+ord($cntrl));
1566         if ($opts{-nohtml}) {
1567                 return $chr;
1568         } else {
1569                 return "<span class=\"cntrl\">$chr</span>";
1570         }
1571 }
1572
1573 # git may return quoted and escaped filenames
1574 sub unquote {
1575         my $str = shift;
1576
1577         sub unq {
1578                 my $seq = shift;
1579                 my %es = ( # character escape codes, aka escape sequences
1580                         't' => "\t",   # tab            (HT, TAB)
1581                         'n' => "\n",   # newline        (NL)
1582                         'r' => "\r",   # return         (CR)
1583                         'f' => "\f",   # form feed      (FF)
1584                         'b' => "\b",   # backspace      (BS)
1585                         'a' => "\a",   # alarm (bell)   (BEL)
1586                         'e' => "\e",   # escape         (ESC)
1587                         'v' => "\013", # vertical tab   (VT)
1588                 );
1589
1590                 if ($seq =~ m/^[0-7]{1,3}$/) {
1591                         # octal char sequence
1592                         return chr(oct($seq));
1593                 } elsif (exists $es{$seq}) {
1594                         # C escape sequence, aka character escape code
1595                         return $es{$seq};
1596                 }
1597                 # quoted ordinary character
1598                 return $seq;
1599         }
1600
1601         if ($str =~ m/^"(.*)"$/) {
1602                 # needs unquoting
1603                 $str = $1;
1604                 $str =~ s/\\([^0-7]|[0-7]{1,3})/unq($1)/eg;
1605         }
1606         return $str;
1607 }
1608
1609 # escape tabs (convert tabs to spaces)
1610 sub untabify {
1611         my $line = shift;
1612
1613         while ((my $pos = index($line, "\t")) != -1) {
1614                 if (my $count = (8 - ($pos % 8))) {
1615                         my $spaces = ' ' x $count;
1616                         $line =~ s/\t/$spaces/;
1617                 }
1618         }
1619
1620         return $line;
1621 }
1622
1623 sub project_in_list {
1624         my $project = shift;
1625         my @list = git_get_projects_list();
1626         return @list && scalar(grep { $_->{'path'} eq $project } @list);
1627 }
1628
1629 ## ----------------------------------------------------------------------
1630 ## HTML aware string manipulation
1631
1632 # Try to chop given string on a word boundary between position
1633 # $len and $len+$add_len. If there is no word boundary there,
1634 # chop at $len+$add_len. Do not chop if chopped part plus ellipsis
1635 # (marking chopped part) would be longer than given string.
1636 sub chop_str {
1637         my $str = shift;
1638         my $len = shift;
1639         my $add_len = shift || 10;
1640         my $where = shift || 'right'; # 'left' | 'center' | 'right'
1641
1642         # Make sure perl knows it is utf8 encoded so we don't
1643         # cut in the middle of a utf8 multibyte char.
1644         $str = to_utf8($str);
1645
1646         # allow only $len chars, but don't cut a word if it would fit in $add_len
1647         # if it doesn't fit, cut it if it's still longer than the dots we would add
1648         # remove chopped character entities entirely
1649
1650         # when chopping in the middle, distribute $len into left and right part
1651         # return early if chopping wouldn't make string shorter
1652         if ($where eq 'center') {
1653                 return $str if ($len + 5 >= length($str)); # filler is length 5
1654                 $len = int($len/2);
1655         } else {
1656                 return $str if ($len + 4 >= length($str)); # filler is length 4
1657         }
1658
1659         # regexps: ending and beginning with word part up to $add_len
1660         my $endre = qr/.{$len}\w{0,$add_len}/;
1661         my $begre = qr/\w{0,$add_len}.{$len}/;
1662
1663         if ($where eq 'left') {
1664                 $str =~ m/^(.*?)($begre)$/;
1665                 my ($lead, $body) = ($1, $2);
1666                 if (length($lead) > 4) {
1667                         $lead = " ...";
1668                 }
1669                 return "$lead$body";
1670
1671         } elsif ($where eq 'center') {
1672                 $str =~ m/^($endre)(.*)$/;
1673                 my ($left, $str)  = ($1, $2);
1674                 $str =~ m/^(.*?)($begre)$/;
1675                 my ($mid, $right) = ($1, $2);
1676                 if (length($mid) > 5) {
1677                         $mid = " ... ";
1678                 }
1679                 return "$left$mid$right";
1680
1681         } else {
1682                 $str =~ m/^($endre)(.*)$/;
1683                 my $body = $1;
1684                 my $tail = $2;
1685                 if (length($tail) > 4) {
1686                         $tail = "... ";
1687                 }
1688                 return "$body$tail";
1689         }
1690 }
1691
1692 # takes the same arguments as chop_str, but also wraps a <span> around the
1693 # result with a title attribute if it does get chopped. Additionally, the
1694 # string is HTML-escaped.
1695 sub chop_and_escape_str {
1696         my ($str) = @_;
1697
1698         my $chopped = chop_str(@_);
1699         if ($chopped eq $str) {
1700                 return esc_html($chopped);
1701         } else {
1702                 $str =~ s/[[:cntrl:]]/?/g;
1703                 return $cgi->span({-title=>$str}, esc_html($chopped));
1704         }
1705 }
1706
1707 ## ----------------------------------------------------------------------
1708 ## functions returning short strings
1709
1710 # CSS class for given age value (in seconds)
1711 sub age_class {
1712         my $age = shift;
1713
1714         if (!defined $age) {
1715                 return "noage";
1716         } elsif ($age < 60*60*2) {
1717                 return "age0";
1718         } elsif ($age < 60*60*24*2) {
1719                 return "age1";
1720         } else {
1721                 return "age2";
1722         }
1723 }
1724
1725 # convert age in seconds to "nn units ago" string
1726 sub age_string {
1727         my $age = shift;
1728         my $age_str;
1729
1730         if ($age > 60*60*24*365*2) {
1731                 $age_str = (int $age/60/60/24/365);
1732                 $age_str .= " years ago";
1733         } elsif ($age > 60*60*24*(365/12)*2) {
1734                 $age_str = int $age/60/60/24/(365/12);
1735                 $age_str .= " months ago";
1736         } elsif ($age > 60*60*24*7*2) {
1737                 $age_str = int $age/60/60/24/7;
1738                 $age_str .= " weeks ago";
1739         } elsif ($age > 60*60*24*2) {
1740                 $age_str = int $age/60/60/24;
1741                 $age_str .= " days ago";
1742         } elsif ($age > 60*60*2) {
1743                 $age_str = int $age/60/60;
1744                 $age_str .= " hours ago";
1745         } elsif ($age > 60*2) {
1746                 $age_str = int $age/60;
1747                 $age_str .= " min ago";
1748         } elsif ($age > 2) {
1749                 $age_str = int $age;
1750                 $age_str .= " sec ago";
1751         } else {
1752                 $age_str .= " right now";
1753         }
1754         return $age_str;
1755 }
1756
1757 use constant {
1758         S_IFINVALID => 0030000,
1759         S_IFGITLINK => 0160000,
1760 };
1761
1762 # submodule/subproject, a commit object reference
1763 sub S_ISGITLINK {
1764         my $mode = shift;
1765
1766         return (($mode & S_IFMT) == S_IFGITLINK)
1767 }
1768
1769 # convert file mode in octal to symbolic file mode string
1770 sub mode_str {
1771         my $mode = oct shift;
1772
1773         if (S_ISGITLINK($mode)) {
1774                 return 'm---------';
1775         } elsif (S_ISDIR($mode & S_IFMT)) {
1776                 return 'drwxr-xr-x';
1777         } elsif (S_ISLNK($mode)) {
1778                 return 'lrwxrwxrwx';
1779         } elsif (S_ISREG($mode)) {
1780                 # git cares only about the executable bit
1781                 if ($mode & S_IXUSR) {
1782                         return '-rwxr-xr-x';
1783                 } else {
1784                         return '-rw-r--r--';
1785                 };
1786         } else {
1787                 return '----------';
1788         }
1789 }
1790
1791 # convert file mode in octal to file type string
1792 sub file_type {
1793         my $mode = shift;
1794
1795         if ($mode !~ m/^[0-7]+$/) {
1796                 return $mode;
1797         } else {
1798                 $mode = oct $mode;
1799         }
1800
1801         if (S_ISGITLINK($mode)) {
1802                 return "submodule";
1803         } elsif (S_ISDIR($mode & S_IFMT)) {
1804                 return "directory";
1805         } elsif (S_ISLNK($mode)) {
1806                 return "symlink";
1807         } elsif (S_ISREG($mode)) {
1808                 return "file";
1809         } else {
1810                 return "unknown";
1811         }
1812 }
1813
1814 # convert file mode in octal to file type description string
1815 sub file_type_long {
1816         my $mode = shift;
1817
1818         if ($mode !~ m/^[0-7]+$/) {
1819                 return $mode;
1820         } else {
1821                 $mode = oct $mode;
1822         }
1823
1824         if (S_ISGITLINK($mode)) {
1825                 return "submodule";
1826         } elsif (S_ISDIR($mode & S_IFMT)) {
1827                 return "directory";
1828         } elsif (S_ISLNK($mode)) {
1829                 return "symlink";
1830         } elsif (S_ISREG($mode)) {
1831                 if ($mode & S_IXUSR) {
1832                         return "executable";
1833                 } else {
1834                         return "file";
1835                 };
1836         } else {
1837                 return "unknown";
1838         }
1839 }
1840
1841
1842 ## ----------------------------------------------------------------------
1843 ## functions returning short HTML fragments, or transforming HTML fragments
1844 ## which don't belong to other sections
1845
1846 # format line of commit message.
1847 sub format_log_line_html {
1848         my $line = shift;
1849
1850         $line = esc_html($line, -nbsp=>1);
1851         $line =~ s{\b([0-9a-fA-F]{8,40})\b}{
1852                 $cgi->a({-href => href(action=>"object", hash=>$1),
1853                                         -class => "text"}, $1);
1854         }eg;
1855
1856         return $line;
1857 }
1858
1859 # format marker of refs pointing to given object
1860
1861 # the destination action is chosen based on object type and current context:
1862 # - for annotated tags, we choose the tag view unless it's the current view
1863 #   already, in which case we go to shortlog view
1864 # - for other refs, we keep the current view if we're in history, shortlog or
1865 #   log view, and select shortlog otherwise
1866 sub format_ref_marker {
1867         my ($refs, $id) = @_;
1868         my $markers = '';
1869
1870         if (defined $refs->{$id}) {
1871                 foreach my $ref (@{$refs->{$id}}) {
1872                         # this code exploits the fact that non-lightweight tags are the
1873                         # only indirect objects, and that they are the only objects for which
1874                         # we want to use tag instead of shortlog as action
1875                         my ($type, $name) = qw();
1876                         my $indirect = ($ref =~ s/\^\{\}$//);
1877                         # e.g. tags/v2.6.11 or heads/next
1878                         if ($ref =~ m!^(.*?)s?/(.*)$!) {
1879                                 $type = $1;
1880                                 $name = $2;
1881                         } else {
1882                                 $type = "ref";
1883                                 $name = $ref;
1884                         }
1885
1886                         my $class = $type;
1887                         $class .= " indirect" if $indirect;
1888
1889                         my $dest_action = "shortlog";
1890
1891                         if ($indirect) {
1892                                 $dest_action = "tag" unless $action eq "tag";
1893                         } elsif ($action =~ /^(history|(short)?log)$/) {
1894                                 $dest_action = $action;
1895                         }
1896
1897                         my $dest = "";
1898                         $dest .= "refs/" unless $ref =~ m!^refs/!;
1899                         $dest .= $ref;
1900
1901                         my $link = $cgi->a({
1902                                 -href => href(
1903                                         action=>$dest_action,
1904                                         hash=>$dest
1905                                 )}, $name);
1906
1907                         $markers .= " <span class=\"".esc_attr($class)."\" title=\"".esc_attr($ref)."\">" .
1908                                 $link . "</span>";
1909                 }
1910         }
1911
1912         if ($markers) {
1913                 return ' <span class="refs">'. $markers . '</span>';
1914         } else {
1915                 return "";
1916         }
1917 }
1918
1919 # format, perhaps shortened and with markers, title line
1920 sub format_subject_html {
1921         my ($long, $short, $href, $extra) = @_;
1922         $extra = '' unless defined($extra);
1923
1924         if (length($short) < length($long)) {
1925                 $long =~ s/[[:cntrl:]]/?/g;
1926                 return $cgi->a({-href => $href, -class => "list subject",
1927                                 -title => to_utf8($long)},
1928                        esc_html($short)) . $extra;
1929         } else {
1930                 return $cgi->a({-href => $href, -class => "list subject"},
1931                        esc_html($long)) . $extra;
1932         }
1933 }
1934
1935 # Rather than recomputing the url for an email multiple times, we cache it
1936 # after the first hit. This gives a visible benefit in views where the avatar
1937 # for the same email is used repeatedly (e.g. shortlog).
1938 # The cache is shared by all avatar engines (currently gravatar only), which
1939 # are free to use it as preferred. Since only one avatar engine is used for any
1940 # given page, there's no risk for cache conflicts.
1941 our %avatar_cache = ();
1942
1943 # Compute the picon url for a given email, by using the picon search service over at
1944 # http://www.cs.indiana.edu/picons/search.html
1945 sub picon_url {
1946         my $email = lc shift;
1947         if (!$avatar_cache{$email}) {
1948                 my ($user, $domain) = split('@', $email);
1949                 $avatar_cache{$email} =
1950                         "http://www.cs.indiana.edu/cgi-pub/kinzler/piconsearch.cgi/" .
1951                         "$domain/$user/" .
1952                         "users+domains+unknown/up/single";
1953         }
1954         return $avatar_cache{$email};
1955 }
1956
1957 # Compute the gravatar url for a given email, if it's not in the cache already.
1958 # Gravatar stores only the part of the URL before the size, since that's the
1959 # one computationally more expensive. This also allows reuse of the cache for
1960 # different sizes (for this particular engine).
1961 sub gravatar_url {
1962         my $email = lc shift;
1963         my $size = shift;
1964         $avatar_cache{$email} ||=
1965                 "http://www.gravatar.com/avatar/" .
1966                         Digest::MD5::md5_hex($email) . "?s=";
1967         return $avatar_cache{$email} . $size;
1968 }
1969
1970 # Insert an avatar for the given $email at the given $size if the feature
1971 # is enabled.
1972 sub git_get_avatar {
1973         my ($email, %opts) = @_;
1974         my $pre_white  = ($opts{-pad_before} ? "&nbsp;" : "");
1975         my $post_white = ($opts{-pad_after}  ? "&nbsp;" : "");
1976         $opts{-size} ||= 'default';
1977         my $size = $avatar_size{$opts{-size}} || $avatar_size{'default'};
1978         my $url = "";
1979         if ($git_avatar eq 'gravatar') {
1980                 $url = gravatar_url($email, $size);
1981         } elsif ($git_avatar eq 'picon') {
1982                 $url = picon_url($email);
1983         }
1984         # Other providers can be added by extending the if chain, defining $url
1985         # as needed. If no variant puts something in $url, we assume avatars
1986         # are completely disabled/unavailable.
1987         if ($url) {
1988                 return $pre_white .
1989                        "<img width=\"$size\" " .
1990                             "class=\"avatar\" " .
1991                             "src=\"".esc_url($url)."\" " .
1992                             "alt=\"\" " .
1993                        "/>" . $post_white;
1994         } else {
1995                 return "";
1996         }
1997 }
1998
1999 sub format_search_author {
2000         my ($author, $searchtype, $displaytext) = @_;
2001         my $have_search = gitweb_check_feature('search');
2002
2003         if ($have_search) {
2004                 my $performed = "";
2005                 if ($searchtype eq 'author') {
2006                         $performed = "authored";
2007                 } elsif ($searchtype eq 'committer') {
2008                         $performed = "committed";
2009                 }
2010
2011                 return $cgi->a({-href => href(action=>"search", hash=>$hash,
2012                                 searchtext=>$author,
2013                                 searchtype=>$searchtype), class=>"list",
2014                                 title=>"Search for commits $performed by $author"},
2015                                 $displaytext);
2016
2017         } else {
2018                 return $displaytext;
2019         }
2020 }
2021
2022 # format the author name of the given commit with the given tag
2023 # the author name is chopped and escaped according to the other
2024 # optional parameters (see chop_str).
2025 sub format_author_html {
2026         my $tag = shift;
2027         my $co = shift;
2028         my $author = chop_and_escape_str($co->{'author_name'}, @_);
2029         return "<$tag class=\"author\">" .
2030                format_search_author($co->{'author_name'}, "author",
2031                        git_get_avatar($co->{'author_email'}, -pad_after => 1) .
2032                        $author) .
2033                "</$tag>";
2034 }
2035
2036 # format git diff header line, i.e. "diff --(git|combined|cc) ..."
2037 sub format_git_diff_header_line {
2038         my $line = shift;
2039         my $diffinfo = shift;
2040         my ($from, $to) = @_;
2041
2042         if ($diffinfo->{'nparents'}) {
2043                 # combined diff
2044                 $line =~ s!^(diff (.*?) )"?.*$!$1!;
2045                 if ($to->{'href'}) {
2046                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2047                                          esc_path($to->{'file'}));
2048                 } else { # file was deleted (no href)
2049                         $line .= esc_path($to->{'file'});
2050                 }
2051         } else {
2052                 # "ordinary" diff
2053                 $line =~ s!^(diff (.*?) )"?a/.*$!$1!;
2054                 if ($from->{'href'}) {
2055                         $line .= $cgi->a({-href => $from->{'href'}, -class => "path"},
2056                                          'a/' . esc_path($from->{'file'}));
2057                 } else { # file was added (no href)
2058                         $line .= 'a/' . esc_path($from->{'file'});
2059                 }
2060                 $line .= ' ';
2061                 if ($to->{'href'}) {
2062                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2063                                          'b/' . esc_path($to->{'file'}));
2064                 } else { # file was deleted
2065                         $line .= 'b/' . esc_path($to->{'file'});
2066                 }
2067         }
2068
2069         return "<div class=\"diff header\">$line</div>\n";
2070 }
2071
2072 # format extended diff header line, before patch itself
2073 sub format_extended_diff_header_line {
2074         my $line = shift;
2075         my $diffinfo = shift;
2076         my ($from, $to) = @_;
2077
2078         # match <path>
2079         if ($line =~ s!^((copy|rename) from ).*$!$1! && $from->{'href'}) {
2080                 $line .= $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2081                                        esc_path($from->{'file'}));
2082         }
2083         if ($line =~ s!^((copy|rename) to ).*$!$1! && $to->{'href'}) {
2084                 $line .= $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2085                                  esc_path($to->{'file'}));
2086         }
2087         # match single <mode>
2088         if ($line =~ m/\s(\d{6})$/) {
2089                 $line .= '<span class="info"> (' .
2090                          file_type_long($1) .
2091                          ')</span>';
2092         }
2093         # match <hash>
2094         if ($line =~ m/^index [0-9a-fA-F]{40},[0-9a-fA-F]{40}/) {
2095                 # can match only for combined diff
2096                 $line = 'index ';
2097                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2098                         if ($from->{'href'}[$i]) {
2099                                 $line .= $cgi->a({-href=>$from->{'href'}[$i],
2100                                                   -class=>"hash"},
2101                                                  substr($diffinfo->{'from_id'}[$i],0,7));
2102                         } else {
2103                                 $line .= '0' x 7;
2104                         }
2105                         # separator
2106                         $line .= ',' if ($i < $diffinfo->{'nparents'} - 1);
2107                 }
2108                 $line .= '..';
2109                 if ($to->{'href'}) {
2110                         $line .= $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2111                                          substr($diffinfo->{'to_id'},0,7));
2112                 } else {
2113                         $line .= '0' x 7;
2114                 }
2115
2116         } elsif ($line =~ m/^index [0-9a-fA-F]{40}..[0-9a-fA-F]{40}/) {
2117                 # can match only for ordinary diff
2118                 my ($from_link, $to_link);
2119                 if ($from->{'href'}) {
2120                         $from_link = $cgi->a({-href=>$from->{'href'}, -class=>"hash"},
2121                                              substr($diffinfo->{'from_id'},0,7));
2122                 } else {
2123                         $from_link = '0' x 7;
2124                 }
2125                 if ($to->{'href'}) {
2126                         $to_link = $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2127                                            substr($diffinfo->{'to_id'},0,7));
2128                 } else {
2129                         $to_link = '0' x 7;
2130                 }
2131                 my ($from_id, $to_id) = ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
2132                 $line =~ s!$from_id\.\.$to_id!$from_link..$to_link!;
2133         }
2134
2135         return $line . "<br/>\n";
2136 }
2137
2138 # format from-file/to-file diff header
2139 sub format_diff_from_to_header {
2140         my ($from_line, $to_line, $diffinfo, $from, $to, @parents) = @_;
2141         my $line;
2142         my $result = '';
2143
2144         $line = $from_line;
2145         #assert($line =~ m/^---/) if DEBUG;
2146         # no extra formatting for "^--- /dev/null"
2147         if (! $diffinfo->{'nparents'}) {
2148                 # ordinary (single parent) diff
2149                 if ($line =~ m!^--- "?a/!) {
2150                         if ($from->{'href'}) {
2151                                 $line = '--- a/' .
2152                                         $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2153                                                 esc_path($from->{'file'}));
2154                         } else {
2155                                 $line = '--- a/' .
2156                                         esc_path($from->{'file'});
2157                         }
2158                 }
2159                 $result .= qq!<div class="diff from_file">$line</div>\n!;
2160
2161         } else {
2162                 # combined diff (merge commit)
2163                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2164                         if ($from->{'href'}[$i]) {
2165                                 $line = '--- ' .
2166                                         $cgi->a({-href=>href(action=>"blobdiff",
2167                                                              hash_parent=>$diffinfo->{'from_id'}[$i],
2168                                                              hash_parent_base=>$parents[$i],
2169                                                              file_parent=>$from->{'file'}[$i],
2170                                                              hash=>$diffinfo->{'to_id'},
2171                                                              hash_base=>$hash,
2172                                                              file_name=>$to->{'file'}),
2173                                                  -class=>"path",
2174                                                  -title=>"diff" . ($i+1)},
2175                                                 $i+1) .
2176                                         '/' .
2177                                         $cgi->a({-href=>$from->{'href'}[$i], -class=>"path"},
2178                                                 esc_path($from->{'file'}[$i]));
2179                         } else {
2180                                 $line = '--- /dev/null';
2181                         }
2182                         $result .= qq!<div class="diff from_file">$line</div>\n!;
2183                 }
2184         }
2185
2186         $line = $to_line;
2187         #assert($line =~ m/^\+\+\+/) if DEBUG;
2188         # no extra formatting for "^+++ /dev/null"
2189         if ($line =~ m!^\+\+\+ "?b/!) {
2190                 if ($to->{'href'}) {
2191                         $line = '+++ b/' .
2192                                 $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2193                                         esc_path($to->{'file'}));
2194                 } else {
2195                         $line = '+++ b/' .
2196                                 esc_path($to->{'file'});
2197                 }
2198         }
2199         $result .= qq!<div class="diff to_file">$line</div>\n!;
2200
2201         return $result;
2202 }
2203
2204 # create note for patch simplified by combined diff
2205 sub format_diff_cc_simplified {
2206         my ($diffinfo, @parents) = @_;
2207         my $result = '';
2208
2209         $result .= "<div class=\"diff header\">" .
2210                    "diff --cc ";
2211         if (!is_deleted($diffinfo)) {
2212                 $result .= $cgi->a({-href => href(action=>"blob",
2213                                                   hash_base=>$hash,
2214                                                   hash=>$diffinfo->{'to_id'},
2215                                                   file_name=>$diffinfo->{'to_file'}),
2216                                     -class => "path"},
2217                                    esc_path($diffinfo->{'to_file'}));
2218         } else {
2219                 $result .= esc_path($diffinfo->{'to_file'});
2220         }
2221         $result .= "</div>\n" . # class="diff header"
2222                    "<div class=\"diff nodifferences\">" .
2223                    "Simple merge" .
2224                    "</div>\n"; # class="diff nodifferences"
2225
2226         return $result;
2227 }
2228
2229 sub diff_line_class {
2230         my ($line, $from, $to) = @_;
2231
2232         # ordinary diff
2233         my $num_sign = 1;
2234         # combined diff
2235         if ($from && $to && ref($from->{'href'}) eq "ARRAY") {
2236                 $num_sign = scalar @{$from->{'href'}};
2237         }
2238
2239         my @diff_line_classifier = (
2240                 { regexp => qr/^\@\@{$num_sign} /, class => "chunk_header"},
2241                 { regexp => qr/^\\/,               class => "incomplete"  },
2242                 { regexp => qr/^ {$num_sign}/,     class => "ctx" },
2243                 # classifier for context must come before classifier add/rem,
2244                 # or we would have to use more complicated regexp, for example
2245                 # qr/(?= {0,$m}\+)[+ ]{$num_sign}/, where $m = $num_sign - 1;
2246                 { regexp => qr/^[+ ]{$num_sign}/,   class => "add" },
2247                 { regexp => qr/^[- ]{$num_sign}/,   class => "rem" },
2248         );
2249         for my $clsfy (@diff_line_classifier) {
2250                 return $clsfy->{'class'}
2251                         if ($line =~ $clsfy->{'regexp'});
2252         }
2253
2254         # fallback
2255         return "";
2256 }
2257
2258 # format patch (diff) line (not to be used for diff headers)
2259 sub format_diff_line {
2260         my $line = shift;
2261         my ($from, $to) = @_;
2262
2263         my $diff_class = diff_line_class($line, $from, $to);
2264         my $diff_classes = "diff";
2265         $diff_classes .= " $diff_class" if ($diff_class);
2266
2267         chomp $line;
2268         $line = untabify($line);
2269
2270         if ($from && $to && $line =~ m/^\@{2} /) {
2271                 my ($from_text, $from_start, $from_lines, $to_text, $to_start, $to_lines, $section) =
2272                         $line =~ m/^\@{2} (-(\d+)(?:,(\d+))?) (\+(\d+)(?:,(\d+))?) \@{2}(.*)$/;
2273
2274                 $from_lines = 0 unless defined $from_lines;
2275                 $to_lines   = 0 unless defined $to_lines;
2276
2277                 if ($from->{'href'}) {
2278                         $from_text = $cgi->a({-href=>"$from->{'href'}#l$from_start",
2279                                              -class=>"list"}, $from_text);
2280                 }
2281                 if ($to->{'href'}) {
2282                         $to_text   = $cgi->a({-href=>"$to->{'href'}#l$to_start",
2283                                              -class=>"list"}, $to_text);
2284                 }
2285                 $line = "<span class=\"chunk_info\">@@ $from_text $to_text @@</span>" .
2286                         "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2287                 return "<div class=\"$diff_classes\">$line</div>\n";
2288         } elsif ($from && $to && $line =~ m/^\@{3}/) {
2289                 my ($prefix, $ranges, $section) = $line =~ m/^(\@+) (.*?) \@+(.*)$/;
2290                 my (@from_text, @from_start, @from_nlines, $to_text, $to_start, $to_nlines);
2291
2292                 @from_text = split(' ', $ranges);
2293                 for (my $i = 0; $i < @from_text; ++$i) {
2294                         ($from_start[$i], $from_nlines[$i]) =
2295                                 (split(',', substr($from_text[$i], 1)), 0);
2296                 }
2297
2298                 $to_text   = pop @from_text;
2299                 $to_start  = pop @from_start;
2300                 $to_nlines = pop @from_nlines;
2301
2302                 $line = "<span class=\"chunk_info\">$prefix ";
2303                 for (my $i = 0; $i < @from_text; ++$i) {
2304                         if ($from->{'href'}[$i]) {
2305                                 $line .= $cgi->a({-href=>"$from->{'href'}[$i]#l$from_start[$i]",
2306                                                   -class=>"list"}, $from_text[$i]);
2307                         } else {
2308                                 $line .= $from_text[$i];
2309                         }
2310                         $line .= " ";
2311                 }
2312                 if ($to->{'href'}) {
2313                         $line .= $cgi->a({-href=>"$to->{'href'}#l$to_start",
2314                                           -class=>"list"}, $to_text);
2315                 } else {
2316                         $line .= $to_text;
2317                 }
2318                 $line .= " $prefix</span>" .
2319                          "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2320                 return "<div class=\"$diff_classes\">$line</div>\n";
2321         }
2322         return "<div class=\"$diff_classes\">" . esc_html($line, -nbsp=>1) . "</div>\n";
2323 }
2324
2325 # Generates undef or something like "_snapshot_" or "snapshot (_tbz2_ _zip_)",
2326 # linked.  Pass the hash of the tree/commit to snapshot.
2327 sub format_snapshot_links {
2328         my ($hash) = @_;
2329         my $num_fmts = @snapshot_fmts;
2330         if ($num_fmts > 1) {
2331                 # A parenthesized list of links bearing format names.
2332                 # e.g. "snapshot (_tar.gz_ _zip_)"
2333                 return "snapshot (" . join(' ', map
2334                         $cgi->a({
2335                                 -href => href(
2336                                         action=>"snapshot",
2337                                         hash=>$hash,
2338                                         snapshot_format=>$_
2339                                 )
2340                         }, $known_snapshot_formats{$_}{'display'})
2341                 , @snapshot_fmts) . ")";
2342         } elsif ($num_fmts == 1) {
2343                 # A single "snapshot" link whose tooltip bears the format name.
2344                 # i.e. "_snapshot_"
2345                 my ($fmt) = @snapshot_fmts;
2346                 return
2347                         $cgi->a({
2348                                 -href => href(
2349                                         action=>"snapshot",
2350                                         hash=>$hash,
2351                                         snapshot_format=>$fmt
2352                                 ),
2353                                 -title => "in format: $known_snapshot_formats{$fmt}{'display'}"
2354                         }, "snapshot");
2355         } else { # $num_fmts == 0
2356                 return undef;
2357         }
2358 }
2359
2360 ## ......................................................................
2361 ## functions returning values to be passed, perhaps after some
2362 ## transformation, to other functions; e.g. returning arguments to href()
2363
2364 # returns hash to be passed to href to generate gitweb URL
2365 # in -title key it returns description of link
2366 sub get_feed_info {
2367         my $format = shift || 'Atom';
2368         my %res = (action => lc($format));
2369
2370         # feed links are possible only for project views
2371         return unless (defined $project);
2372         # some views should link to OPML, or to generic project feed,
2373         # or don't have specific feed yet (so they should use generic)
2374         return if ($action =~ /^(?:tags|heads|forks|tag|search)$/x);
2375
2376         my $branch;
2377         # branches refs uses 'refs/heads/' prefix (fullname) to differentiate
2378         # from tag links; this also makes possible to detect branch links
2379         if ((defined $hash_base && $hash_base =~ m!^refs/heads/(.*)$!) ||
2380             (defined $hash      && $hash      =~ m!^refs/heads/(.*)$!)) {
2381                 $branch = $1;
2382         }
2383         # find log type for feed description (title)
2384         my $type = 'log';
2385         if (defined $file_name) {
2386                 $type  = "history of $file_name";
2387                 $type .= "/" if ($action eq 'tree');
2388                 $type .= " on '$branch'" if (defined $branch);
2389         } else {
2390                 $type = "log of $branch" if (defined $branch);
2391         }
2392
2393         $res{-title} = $type;
2394         $res{'hash'} = (defined $branch ? "refs/heads/$branch" : undef);
2395         $res{'file_name'} = $file_name;
2396
2397         return %res;
2398 }
2399
2400 ## ----------------------------------------------------------------------
2401 ## git utility subroutines, invoking git commands
2402
2403 # returns path to the core git executable and the --git-dir parameter as list
2404 sub git_cmd {
2405         $number_of_git_cmds++;
2406         return $GIT, '--git-dir='.$git_dir;
2407 }
2408
2409 # quote the given arguments for passing them to the shell
2410 # quote_command("command", "arg 1", "arg with ' and ! characters")
2411 # => "'command' 'arg 1' 'arg with '\'' and '\!' characters'"
2412 # Try to avoid using this function wherever possible.
2413 sub quote_command {
2414         return join(' ',
2415                 map { my $a = $_; $a =~ s/(['!])/'\\$1'/g; "'$a'" } @_ );
2416 }
2417
2418 # get HEAD ref of given project as hash
2419 sub git_get_head_hash {
2420         return git_get_full_hash(shift, 'HEAD');
2421 }
2422
2423 sub git_get_full_hash {
2424         return git_get_hash(@_);
2425 }
2426
2427 sub git_get_short_hash {
2428         return git_get_hash(@_, '--short=7');
2429 }
2430
2431 sub git_get_hash {
2432         my ($project, $hash, @options) = @_;
2433         my $o_git_dir = $git_dir;
2434         my $retval = undef;
2435         $git_dir = "$projectroot/$project";
2436         if (open my $fd, '-|', git_cmd(), 'rev-parse',
2437             '--verify', '-q', @options, $hash) {
2438                 $retval = <$fd>;
2439                 chomp $retval if defined $retval;
2440                 close $fd;
2441         }
2442         if (defined $o_git_dir) {
2443                 $git_dir = $o_git_dir;
2444         }
2445         return $retval;
2446 }
2447
2448 # get type of given object
2449 sub git_get_type {
2450         my $hash = shift;
2451
2452         open my $fd, "-|", git_cmd(), "cat-file", '-t', $hash or return;
2453         my $type = <$fd>;
2454         close $fd or return;
2455         chomp $type;
2456         return $type;
2457 }
2458
2459 # repository configuration
2460 our $config_file = '';
2461 our %config;
2462
2463 # store multiple values for single key as anonymous array reference
2464 # single values stored directly in the hash, not as [ <value> ]
2465 sub hash_set_multi {
2466         my ($hash, $key, $value) = @_;
2467
2468         if (!exists $hash->{$key}) {
2469                 $hash->{$key} = $value;
2470         } elsif (!ref $hash->{$key}) {
2471                 $hash->{$key} = [ $hash->{$key}, $value ];
2472         } else {
2473                 push @{$hash->{$key}}, $value;
2474         }
2475 }
2476
2477 # return hash of git project configuration
2478 # optionally limited to some section, e.g. 'gitweb'
2479 sub git_parse_project_config {
2480         my $section_regexp = shift;
2481         my %config;
2482
2483         local $/ = "\0";
2484
2485         open my $fh, "-|", git_cmd(), "config", '-z', '-l',
2486                 or return;
2487
2488         while (my $keyval = <$fh>) {
2489                 chomp $keyval;
2490                 my ($key, $value) = split(/\n/, $keyval, 2);
2491
2492                 hash_set_multi(\%config, $key, $value)
2493                         if (!defined $section_regexp || $key =~ /^(?:$section_regexp)\./o);
2494         }
2495         close $fh;
2496
2497         return %config;
2498 }
2499
2500 # convert config value to boolean: 'true' or 'false'
2501 # no value, number > 0, 'true' and 'yes' values are true
2502 # rest of values are treated as false (never as error)
2503 sub config_to_bool {
2504         my $val = shift;
2505
2506         return 1 if !defined $val;             # section.key
2507
2508         # strip leading and trailing whitespace
2509         $val =~ s/^\s+//;
2510         $val =~ s/\s+$//;
2511
2512         return (($val =~ /^\d+$/ && $val) ||   # section.key = 1
2513                 ($val =~ /^(?:true|yes)$/i));  # section.key = true
2514 }
2515
2516 # convert config value to simple decimal number
2517 # an optional value suffix of 'k', 'm', or 'g' will cause the value
2518 # to be multiplied by 1024, 1048576, or 1073741824
2519 sub config_to_int {
2520         my $val = shift;
2521
2522         # strip leading and trailing whitespace
2523         $val =~ s/^\s+//;
2524         $val =~ s/\s+$//;
2525
2526         if (my ($num, $unit) = ($val =~ /^([0-9]*)([kmg])$/i)) {
2527                 $unit = lc($unit);
2528                 # unknown unit is treated as 1
2529                 return $num * ($unit eq 'g' ? 1073741824 :
2530                                $unit eq 'm' ?    1048576 :
2531                                $unit eq 'k' ?       1024 : 1);
2532         }
2533         return $val;
2534 }
2535
2536 # convert config value to array reference, if needed
2537 sub config_to_multi {
2538         my $val = shift;
2539
2540         return ref($val) ? $val : (defined($val) ? [ $val ] : []);
2541 }
2542
2543 sub git_get_project_config {
2544         my ($key, $type) = @_;
2545
2546         return unless defined $git_dir;
2547
2548         # key sanity check
2549         return unless ($key);
2550         # only subsection, if exists, is case sensitive,
2551         # and not lowercased by 'git config -z -l'
2552         if (my ($hi, $mi, $lo) = ($key =~ /^([^.]*)\.(.*)\.([^.]*)$/)) {
2553                 $key = join(".", lc($hi), $mi, lc($lo));
2554         } else {
2555                 $key = lc($key);
2556         }
2557         $key =~ s/^gitweb\.//;
2558         return if ($key =~ m/\W/);
2559
2560         # type sanity check
2561         if (defined $type) {
2562                 $type =~ s/^--//;
2563                 $type = undef
2564                         unless ($type eq 'bool' || $type eq 'int');
2565         }
2566
2567         # get config
2568         if (!defined $config_file ||
2569             $config_file ne "$git_dir/config") {
2570                 %config = git_parse_project_config('gitweb');
2571                 $config_file = "$git_dir/config";
2572         }
2573
2574         # check if config variable (key) exists
2575         return unless exists $config{"gitweb.$key"};
2576
2577         # ensure given type
2578         if (!defined $type) {
2579                 return $config{"gitweb.$key"};
2580         } elsif ($type eq 'bool') {
2581                 # backward compatibility: 'git config --bool' returns true/false
2582                 return config_to_bool($config{"gitweb.$key"}) ? 'true' : 'false';
2583         } elsif ($type eq 'int') {
2584                 return config_to_int($config{"gitweb.$key"});
2585         }
2586         return $config{"gitweb.$key"};
2587 }
2588
2589 # get hash of given path at given ref
2590 sub git_get_hash_by_path {
2591         my $base = shift;
2592         my $path = shift || return undef;
2593         my $type = shift;
2594
2595         $path =~ s,/+$,,;
2596
2597         open my $fd, "-|", git_cmd(), "ls-tree", $base, "--", $path
2598                 or die_error(500, "Open git-ls-tree failed");
2599         my $line = <$fd>;
2600         close $fd or return undef;
2601
2602         if (!defined $line) {
2603                 # there is no tree or hash given by $path at $base
2604                 return undef;
2605         }
2606
2607         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
2608         $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/;
2609         if (defined $type && $type ne $2) {
2610                 # type doesn't match
2611                 return undef;
2612         }
2613         return $3;
2614 }
2615
2616 # get path of entry with given hash at given tree-ish (ref)
2617 # used to get 'from' filename for combined diff (merge commit) for renames
2618 sub git_get_path_by_hash {
2619         my $base = shift || return;
2620         my $hash = shift || return;
2621
2622         local $/ = "\0";
2623
2624         open my $fd, "-|", git_cmd(), "ls-tree", '-r', '-t', '-z', $base
2625                 or return undef;
2626         while (my $line = <$fd>) {
2627                 chomp $line;
2628
2629                 #'040000 tree 595596a6a9117ddba9fe379b6b012b558bac8423  gitweb'
2630                 #'100644 blob e02e90f0429be0d2a69b76571101f20b8f75530f  gitweb/README'
2631                 if ($line =~ m/(?:[0-9]+) (?:.+) $hash\t(.+)$/) {
2632                         close $fd;
2633                         return $1;
2634                 }
2635         }
2636         close $fd;
2637         return undef;
2638 }
2639
2640 ## ......................................................................
2641 ## git utility functions, directly accessing git repository
2642
2643 # get the value of config variable either from file named as the variable
2644 # itself in the repository ($GIT_DIR/$name file), or from gitweb.$name
2645 # configuration variable in the repository config file.
2646 sub git_get_file_or_project_config {
2647         my ($path, $name) = @_;
2648
2649         $git_dir = "$projectroot/$path";
2650         open my $fd, '<', "$git_dir/$name"
2651                 or return git_get_project_config($name);
2652         my $conf = <$fd>;
2653         close $fd;
2654         if (defined $conf) {
2655                 chomp $conf;
2656         }
2657         return $conf;
2658 }
2659
2660 sub git_get_project_description {
2661         my $path = shift;
2662         return git_get_file_or_project_config($path, 'description');
2663 }
2664
2665 sub git_get_project_category {
2666         my $path = shift;
2667         return git_get_file_or_project_config($path, 'category');
2668 }
2669
2670
2671 # supported formats:
2672 # * $GIT_DIR/ctags/<tagname> file (in 'ctags' subdirectory)
2673 #   - if its contents is a number, use it as tag weight,
2674 #   - otherwise add a tag with weight 1
2675 # * $GIT_DIR/ctags file, each line is a tag (with weight 1)
2676 #   the same value multiple times increases tag weight
2677 # * `gitweb.ctag' multi-valued repo config variable
2678 sub git_get_project_ctags {
2679         my $project = shift;
2680         my $ctags = {};
2681
2682         $git_dir = "$projectroot/$project";
2683         if (opendir my $dh, "$git_dir/ctags") {
2684                 my @files = grep { -f $_ } map { "$git_dir/ctags/$_" } readdir($dh);
2685                 foreach my $tagfile (@files) {
2686                         open my $ct, '<', $tagfile
2687                                 or next;
2688                         my $val = <$ct>;
2689                         chomp $val if $val;
2690                         close $ct;
2691
2692                         (my $ctag = $tagfile) =~ s#.*/##;
2693                         if ($val =~ /^\d+$/) {
2694                                 $ctags->{$ctag} = $val;
2695                         } else {
2696                                 $ctags->{$ctag} = 1;
2697                         }
2698                 }
2699                 closedir $dh;
2700
2701         } elsif (open my $fh, '<', "$git_dir/ctags") {
2702                 while (my $line = <$fh>) {
2703                         chomp $line;
2704                         $ctags->{$line}++ if $line;
2705                 }
2706                 close $fh;
2707
2708         } else {
2709                 my $taglist = config_to_multi(git_get_project_config('ctag'));
2710                 foreach my $tag (@$taglist) {
2711                         $ctags->{$tag}++;
2712                 }
2713         }
2714
2715         return $ctags;
2716 }
2717
2718 # return hash, where keys are content tags ('ctags'),
2719 # and values are sum of weights of given tag in every project
2720 sub git_gather_all_ctags {
2721         my $projects = shift;
2722         my $ctags = {};
2723
2724         foreach my $p (@$projects) {
2725                 foreach my $ct (keys %{$p->{'ctags'}}) {
2726                         $ctags->{$ct} += $p->{'ctags'}->{$ct};
2727                 }
2728         }
2729
2730         return $ctags;
2731 }
2732
2733 sub git_populate_project_tagcloud {
2734         my $ctags = shift;
2735
2736         # First, merge different-cased tags; tags vote on casing
2737         my %ctags_lc;
2738         foreach (keys %$ctags) {
2739                 $ctags_lc{lc $_}->{count} += $ctags->{$_};
2740                 if (not $ctags_lc{lc $_}->{topcount}
2741                     or $ctags_lc{lc $_}->{topcount} < $ctags->{$_}) {
2742                         $ctags_lc{lc $_}->{topcount} = $ctags->{$_};
2743                         $ctags_lc{lc $_}->{topname} = $_;
2744                 }
2745         }
2746
2747         my $cloud;
2748         my $matched = $cgi->param('by_tag');
2749         if (eval { require HTML::TagCloud; 1; }) {
2750                 $cloud = HTML::TagCloud->new;
2751                 foreach my $ctag (sort keys %ctags_lc) {
2752                         # Pad the title with spaces so that the cloud looks
2753                         # less crammed.
2754                         my $title = esc_html($ctags_lc{$ctag}->{topname});
2755                         $title =~ s/ /&nbsp;/g;
2756                         $title =~ s/^/&nbsp;/g;
2757                         $title =~ s/$/&nbsp;/g;
2758                         if (defined $matched && $matched eq $ctag) {
2759                                 $title = qq(<span class="match">$title</span>);
2760                         }
2761                         $cloud->add($title, href(project=>undef, ctag=>$ctag),
2762                                     $ctags_lc{$ctag}->{count});
2763                 }
2764         } else {
2765                 $cloud = {};
2766                 foreach my $ctag (keys %ctags_lc) {
2767                         my $title = esc_html($ctags_lc{$ctag}->{topname}, -nbsp=>1);
2768                         if (defined $matched && $matched eq $ctag) {
2769                                 $title = qq(<span class="match">$title</span>);
2770                         }
2771                         $cloud->{$ctag}{count} = $ctags_lc{$ctag}->{count};
2772                         $cloud->{$ctag}{ctag} =
2773                                 $cgi->a({-href=>href(project=>undef, ctag=>$ctag)}, $title);
2774                 }
2775         }
2776         return $cloud;
2777 }
2778
2779 sub git_show_project_tagcloud {
2780         my ($cloud, $count) = @_;
2781         if (ref $cloud eq 'HTML::TagCloud') {
2782                 return $cloud->html_and_css($count);
2783         } else {
2784                 my @tags = sort { $cloud->{$a}->{'count'} <=> $cloud->{$b}->{'count'} } keys %$cloud;
2785                 return
2786                         '<div id="htmltagcloud"'.($project ? '' : ' align="center"').'>' .
2787                         join (', ', map {
2788                                 $cloud->{$_}->{'ctag'}
2789                         } splice(@tags, 0, $count)) .
2790                         '</div>';
2791         }
2792 }
2793
2794 sub git_get_project_url_list {
2795         my $path = shift;
2796
2797         $git_dir = "$projectroot/$path";
2798         open my $fd, '<', "$git_dir/cloneurl"
2799                 or return wantarray ?
2800                 @{ config_to_multi(git_get_project_config('url')) } :
2801                    config_to_multi(git_get_project_config('url'));
2802         my @git_project_url_list = map { chomp; $_ } <$fd>;
2803         close $fd;
2804
2805         return wantarray ? @git_project_url_list : \@git_project_url_list;
2806 }
2807
2808 sub git_get_projects_list {
2809         my $filter = shift || '';
2810         my @list;
2811
2812         $filter =~ s/\.git$//;
2813
2814         if (-d $projects_list) {
2815                 # search in directory
2816                 my $dir = $projects_list;
2817                 # remove the trailing "/"
2818                 $dir =~ s!/+$!!;
2819                 my $pfxlen = length("$projects_list");
2820                 my $pfxdepth = ($projects_list =~ tr!/!!);
2821                 # when filtering, search only given subdirectory
2822                 if ($filter) {
2823                         $dir .= "/$filter";
2824                         $dir =~ s!/+$!!;
2825                 }
2826
2827                 File::Find::find({
2828                         follow_fast => 1, # follow symbolic links
2829                         follow_skip => 2, # ignore duplicates
2830                         dangling_symlinks => 0, # ignore dangling symlinks, silently
2831                         wanted => sub {
2832                                 # global variables
2833                                 our $project_maxdepth;
2834                                 our $projectroot;
2835                                 # skip project-list toplevel, if we get it.
2836                                 return if (m!^[/.]$!);
2837                                 # only directories can be git repositories
2838                                 return unless (-d $_);
2839                                 # don't traverse too deep (Find is super slow on os x)
2840                                 # $project_maxdepth excludes depth of $projectroot
2841                                 if (($File::Find::name =~ tr!/!!) - $pfxdepth > $project_maxdepth) {
2842                                         $File::Find::prune = 1;
2843                                         return;
2844                                 }
2845
2846                                 my $path = substr($File::Find::name, $pfxlen + 1);
2847                                 # we check related file in $projectroot
2848                                 if (check_export_ok("$projectroot/$path")) {
2849                                         push @list, { path => $path };
2850                                         $File::Find::prune = 1;
2851                                 }
2852                         },
2853                 }, "$dir");
2854
2855         } elsif (-f $projects_list) {
2856                 # read from file(url-encoded):
2857                 # 'git%2Fgit.git Linus+Torvalds'
2858                 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
2859                 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
2860                 open my $fd, '<', $projects_list or return;
2861         PROJECT:
2862                 while (my $line = <$fd>) {
2863                         chomp $line;
2864                         my ($path, $owner) = split ' ', $line;
2865                         $path = unescape($path);
2866                         $owner = unescape($owner);
2867                         if (!defined $path) {
2868                                 next;
2869                         }
2870                         # if $filter is rpovided, check if $path begins with $filter
2871                         if ($filter && $path !~ m!^\Q$filter\E/!) {
2872                                 next;
2873                         }
2874                         if (check_export_ok("$projectroot/$path")) {
2875                                 my $pr = {
2876                                         path => $path,
2877                                         owner => to_utf8($owner),
2878                                 };
2879                                 push @list, $pr;
2880                         }
2881                 }
2882                 close $fd;
2883         }
2884         return @list;
2885 }
2886
2887 # written with help of Tree::Trie module (Perl Artistic License, GPL compatibile)
2888 # as side effects it sets 'forks' field to list of forks for forked projects
2889 sub filter_forks_from_projects_list {
2890         my $projects = shift;
2891
2892         my %trie; # prefix tree of directories (path components)
2893         # generate trie out of those directories that might contain forks
2894         foreach my $pr (@$projects) {
2895                 my $path = $pr->{'path'};
2896                 $path =~ s/\.git$//;      # forks of 'repo.git' are in 'repo/' directory
2897                 next if ($path =~ m!/$!); # skip non-bare repositories, e.g. 'repo/.git'
2898                 next unless ($path);      # skip '.git' repository: tests, git-instaweb
2899                 next unless (-d "$projectroot/$path"); # containing directory exists
2900                 $pr->{'forks'} = [];      # there can be 0 or more forks of project
2901
2902                 # add to trie
2903                 my @dirs = split('/', $path);
2904                 # walk the trie, until either runs out of components or out of trie
2905                 my $ref = \%trie;
2906                 while (scalar @dirs &&
2907                        exists($ref->{$dirs[0]})) {
2908                         $ref = $ref->{shift @dirs};
2909                 }
2910                 # create rest of trie structure from rest of components
2911                 foreach my $dir (@dirs) {
2912                         $ref = $ref->{$dir} = {};
2913                 }
2914                 # create end marker, store $pr as a data
2915                 $ref->{''} = $pr if (!exists $ref->{''});
2916         }
2917
2918         # filter out forks, by finding shortest prefix match for paths
2919         my @filtered;
2920  PROJECT:
2921         foreach my $pr (@$projects) {
2922                 # trie lookup
2923                 my $ref = \%trie;
2924         DIR:
2925                 foreach my $dir (split('/', $pr->{'path'})) {
2926                         if (exists $ref->{''}) {
2927                                 # found [shortest] prefix, is a fork - skip it
2928                                 push @{$ref->{''}{'forks'}}, $pr;
2929                                 next PROJECT;
2930                         }
2931                         if (!exists $ref->{$dir}) {
2932                                 # not in trie, cannot have prefix, not a fork
2933                                 push @filtered, $pr;
2934                                 next PROJECT;
2935                         }
2936                         # If the dir is there, we just walk one step down the trie.
2937                         $ref = $ref->{$dir};
2938                 }
2939                 # we ran out of trie
2940                 # (shouldn't happen: it's either no match, or end marker)
2941                 push @filtered, $pr;
2942         }
2943
2944         return @filtered;
2945 }
2946
2947 # note: fill_project_list_info must be run first,
2948 # for 'descr_long' and 'ctags' to be filled
2949 sub search_projects_list {
2950         my ($projlist, %opts) = @_;
2951         my $tagfilter  = $opts{'tagfilter'};
2952         my $searchtext = $opts{'searchtext'};
2953
2954         return @$projlist
2955                 unless ($tagfilter || $searchtext);
2956
2957         my @projects;
2958  PROJECT:
2959         foreach my $pr (@$projlist) {
2960
2961                 if ($tagfilter) {
2962                         next unless ref($pr->{'ctags'}) eq 'HASH';
2963                         next unless
2964                                 grep { lc($_) eq lc($tagfilter) } keys %{$pr->{'ctags'}};
2965                 }
2966
2967                 if ($searchtext) {
2968                         next unless
2969                                 $pr->{'path'} =~ /$searchtext/ ||
2970                                 $pr->{'descr_long'} =~ /$searchtext/;
2971                 }
2972
2973                 push @projects, $pr;
2974         }
2975
2976         return @projects;
2977 }
2978
2979 our $gitweb_project_owner = undef;
2980 sub git_get_project_list_from_file {
2981
2982         return if (defined $gitweb_project_owner);
2983
2984         $gitweb_project_owner = {};
2985         # read from file (url-encoded):
2986         # 'git%2Fgit.git Linus+Torvalds'
2987         # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
2988         # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
2989         if (-f $projects_list) {
2990                 open(my $fd, '<', $projects_list);
2991                 while (my $line = <$fd>) {
2992                         chomp $line;
2993                         my ($pr, $ow) = split ' ', $line;
2994                         $pr = unescape($pr);
2995                         $ow = unescape($ow);
2996                         $gitweb_project_owner->{$pr} = to_utf8($ow);
2997                 }
2998                 close $fd;
2999         }
3000 }
3001
3002 sub git_get_project_owner {
3003         my $project = shift;
3004         my $owner;
3005
3006         return undef unless $project;
3007         $git_dir = "$projectroot/$project";
3008
3009         if (!defined $gitweb_project_owner) {
3010                 git_get_project_list_from_file();
3011         }
3012
3013         if (exists $gitweb_project_owner->{$project}) {
3014                 $owner = $gitweb_project_owner->{$project};
3015         }
3016         if (!defined $owner){
3017                 $owner = git_get_project_config('owner');
3018         }
3019         if (!defined $owner) {
3020                 $owner = get_file_owner("$git_dir");
3021         }
3022
3023         return $owner;
3024 }
3025
3026 sub git_get_last_activity {
3027         my ($path) = @_;
3028         my $fd;
3029
3030         $git_dir = "$projectroot/$path";
3031         open($fd, "-|", git_cmd(), 'for-each-ref',
3032              '--format=%(committer)',
3033              '--sort=-committerdate',
3034              '--count=1',
3035              'refs/heads') or return;
3036         my $most_recent = <$fd>;
3037         close $fd or return;
3038         if (defined $most_recent &&
3039             $most_recent =~ / (\d+) [-+][01]\d\d\d$/) {
3040                 my $timestamp = $1;
3041                 my $age = time - $timestamp;
3042                 return ($age, age_string($age));
3043         }
3044         return (undef, undef);
3045 }
3046
3047 # Implementation note: when a single remote is wanted, we cannot use 'git
3048 # remote show -n' because that command always work (assuming it's a remote URL
3049 # if it's not defined), and we cannot use 'git remote show' because that would
3050 # try to make a network roundtrip. So the only way to find if that particular
3051 # remote is defined is to walk the list provided by 'git remote -v' and stop if
3052 # and when we find what we want.
3053 sub git_get_remotes_list {
3054         my $wanted = shift;
3055         my %remotes = ();
3056
3057         open my $fd, '-|' , git_cmd(), 'remote', '-v';
3058         return unless $fd;
3059         while (my $remote = <$fd>) {
3060                 chomp $remote;
3061                 $remote =~ s!\t(.*?)\s+\((\w+)\)$!!;
3062                 next if $wanted and not $remote eq $wanted;
3063                 my ($url, $key) = ($1, $2);
3064
3065                 $remotes{$remote} ||= { 'heads' => () };
3066                 $remotes{$remote}{$key} = $url;
3067         }
3068         close $fd or return;
3069         return wantarray ? %remotes : \%remotes;
3070 }
3071
3072 # Takes a hash of remotes as first parameter and fills it by adding the
3073 # available remote heads for each of the indicated remotes.
3074 sub fill_remote_heads {
3075         my $remotes = shift;
3076         my @heads = map { "remotes/$_" } keys %$remotes;
3077         my @remoteheads = git_get_heads_list(undef, @heads);
3078         foreach my $remote (keys %$remotes) {
3079                 $remotes->{$remote}{'heads'} = [ grep {
3080                         $_->{'name'} =~ s!^$remote/!!
3081                         } @remoteheads ];
3082         }
3083 }
3084
3085 sub git_get_references {
3086         my $type = shift || "";
3087         my %refs;
3088         # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
3089         # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
3090         open my $fd, "-|", git_cmd(), "show-ref", "--dereference",
3091                 ($type ? ("--", "refs/$type") : ()) # use -- <pattern> if $type
3092                 or return;
3093
3094         while (my $line = <$fd>) {
3095                 chomp $line;
3096                 if ($line =~ m!^([0-9a-fA-F]{40})\srefs/($type.*)$!) {
3097                         if (defined $refs{$1}) {
3098                                 push @{$refs{$1}}, $2;
3099                         } else {
3100                                 $refs{$1} = [ $2 ];
3101                         }
3102                 }
3103         }
3104         close $fd or return;
3105         return \%refs;
3106 }
3107
3108 sub git_get_rev_name_tags {
3109         my $hash = shift || return undef;
3110
3111         open my $fd, "-|", git_cmd(), "name-rev", "--tags", $hash
3112                 or return;
3113         my $name_rev = <$fd>;
3114         close $fd;
3115
3116         if ($name_rev =~ m|^$hash tags/(.*)$|) {
3117                 return $1;
3118         } else {
3119                 # catches also '$hash undefined' output
3120                 return undef;
3121         }
3122 }
3123
3124 ## ----------------------------------------------------------------------
3125 ## parse to hash functions
3126
3127 sub parse_date {
3128         my $epoch = shift;
3129         my $tz = shift || "-0000";
3130
3131         my %date;
3132         my @months = ("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec");
3133         my @days = ("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");
3134         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($epoch);
3135         $date{'hour'} = $hour;
3136         $date{'minute'} = $min;
3137         $date{'mday'} = $mday;
3138         $date{'day'} = $days[$wday];
3139         $date{'month'} = $months[$mon];
3140         $date{'rfc2822'}   = sprintf "%s, %d %s %4d %02d:%02d:%02d +0000",
3141                              $days[$wday], $mday, $months[$mon], 1900+$year, $hour ,$min, $sec;
3142         $date{'mday-time'} = sprintf "%d %s %02d:%02d",
3143                              $mday, $months[$mon], $hour ,$min;
3144         $date{'iso-8601'}  = sprintf "%04d-%02d-%02dT%02d:%02d:%02dZ",
3145                              1900+$year, 1+$mon, $mday, $hour ,$min, $sec;
3146
3147         my ($tz_sign, $tz_hour, $tz_min) =
3148                 ($tz =~ m/^([-+])(\d\d)(\d\d)$/);
3149         $tz_sign = ($tz_sign eq '-' ? -1 : +1);
3150         my $local = $epoch + $tz_sign*((($tz_hour*60) + $tz_min)*60);
3151         ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($local);
3152         $date{'hour_local'} = $hour;
3153         $date{'minute_local'} = $min;
3154         $date{'tz_local'} = $tz;
3155         $date{'iso-tz'} = sprintf("%04d-%02d-%02d %02d:%02d:%02d %s",
3156                                   1900+$year, $mon+1, $mday,
3157                                   $hour, $min, $sec, $tz);
3158         return %date;
3159 }
3160
3161 sub parse_tag {
3162         my $tag_id = shift;
3163         my %tag;
3164         my @comment;
3165
3166         open my $fd, "-|", git_cmd(), "cat-file", "tag", $tag_id or return;
3167         $tag{'id'} = $tag_id;
3168         while (my $line = <$fd>) {
3169                 chomp $line;
3170                 if ($line =~ m/^object ([0-9a-fA-F]{40})$/) {
3171                         $tag{'object'} = $1;
3172                 } elsif ($line =~ m/^type (.+)$/) {
3173                         $tag{'type'} = $1;
3174                 } elsif ($line =~ m/^tag (.+)$/) {
3175                         $tag{'name'} = $1;
3176                 } elsif ($line =~ m/^tagger (.*) ([0-9]+) (.*)$/) {
3177                         $tag{'author'} = $1;
3178                         $tag{'author_epoch'} = $2;
3179                         $tag{'author_tz'} = $3;
3180                         if ($tag{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3181                                 $tag{'author_name'}  = $1;
3182                                 $tag{'author_email'} = $2;
3183                         } else {
3184                                 $tag{'author_name'} = $tag{'author'};
3185                         }
3186                 } elsif ($line =~ m/--BEGIN/) {
3187                         push @comment, $line;
3188                         last;
3189                 } elsif ($line eq "") {
3190                         last;
3191                 }
3192         }
3193         push @comment, <$fd>;
3194         $tag{'comment'} = \@comment;
3195         close $fd or return;
3196         if (!defined $tag{'name'}) {
3197                 return
3198         };
3199         return %tag
3200 }
3201
3202 sub parse_commit_text {
3203         my ($commit_text, $withparents) = @_;
3204         my @commit_lines = split '\n', $commit_text;
3205         my %co;
3206
3207         pop @commit_lines; # Remove '\0'
3208
3209         if (! @commit_lines) {
3210                 return;
3211         }
3212
3213         my $header = shift @commit_lines;
3214         if ($header !~ m/^[0-9a-fA-F]{40}/) {
3215                 return;
3216         }
3217         ($co{'id'}, my @parents) = split ' ', $header;
3218         while (my $line = shift @commit_lines) {
3219                 last if $line eq "\n";
3220                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
3221                         $co{'tree'} = $1;
3222                 } elsif ((!defined $withparents) && ($line =~ m/^parent ([0-9a-fA-F]{40})$/)) {
3223                         push @parents, $1;
3224                 } elsif ($line =~ m/^author (.*) ([0-9]+) (.*)$/) {
3225                         $co{'author'} = to_utf8($1);
3226                         $co{'author_epoch'} = $2;
3227                         $co{'author_tz'} = $3;
3228                         if ($co{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3229                                 $co{'author_name'}  = $1;
3230                                 $co{'author_email'} = $2;
3231                         } else {
3232                                 $co{'author_name'} = $co{'author'};
3233                         }
3234                 } elsif ($line =~ m/^committer (.*) ([0-9]+) (.*)$/) {
3235                         $co{'committer'} = to_utf8($1);
3236                         $co{'committer_epoch'} = $2;
3237                         $co{'committer_tz'} = $3;
3238                         if ($co{'committer'} =~ m/^([^<]+) <([^>]*)>/) {
3239                                 $co{'committer_name'}  = $1;
3240                                 $co{'committer_email'} = $2;
3241                         } else {
3242                                 $co{'committer_name'} = $co{'committer'};
3243                         }
3244                 }
3245         }
3246         if (!defined $co{'tree'}) {
3247                 return;
3248         };
3249         $co{'parents'} = \@parents;
3250         $co{'parent'} = $parents[0];
3251
3252         foreach my $title (@commit_lines) {
3253                 $title =~ s/^    //;
3254                 if ($title ne "") {
3255                         $co{'title'} = chop_str($title, 80, 5);
3256                         # remove leading stuff of merges to make the interesting part visible
3257                         if (length($title) > 50) {
3258                                 $title =~ s/^Automatic //;
3259                                 $title =~ s/^merge (of|with) /Merge ... /i;
3260                                 if (length($title) > 50) {
3261                                         $title =~ s/(http|rsync):\/\///;
3262                                 }
3263                                 if (length($title) > 50) {
3264                                         $title =~ s/(master|www|rsync)\.//;
3265                                 }
3266                                 if (length($title) > 50) {
3267                                         $title =~ s/kernel.org:?//;
3268                                 }
3269                                 if (length($title) > 50) {
3270                                         $title =~ s/\/pub\/scm//;
3271                                 }
3272                         }
3273                         $co{'title_short'} = chop_str($title, 50, 5);
3274                         last;
3275                 }
3276         }
3277         if (! defined $co{'title'} || $co{'title'} eq "") {
3278                 $co{'title'} = $co{'title_short'} = '(no commit message)';
3279         }
3280         # remove added spaces
3281         foreach my $line (@commit_lines) {
3282                 $line =~ s/^    //;
3283         }
3284         $co{'comment'} = \@commit_lines;
3285
3286         my $age = time - $co{'committer_epoch'};
3287         $co{'age'} = $age;
3288         $co{'age_string'} = age_string($age);
3289         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($co{'committer_epoch'});
3290         if ($age > 60*60*24*7*2) {
3291                 $co{'age_string_date'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3292                 $co{'age_string_age'} = $co{'age_string'};
3293         } else {
3294                 $co{'age_string_date'} = $co{'age_string'};
3295                 $co{'age_string_age'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3296         }
3297         return %co;
3298 }
3299
3300 sub parse_commit {
3301         my ($commit_id) = @_;
3302         my %co;
3303
3304         local $/ = "\0";
3305
3306         open my $fd, "-|", git_cmd(), "rev-list",
3307                 "--parents",
3308                 "--header",
3309                 "--max-count=1",
3310                 $commit_id,
3311                 "--",
3312                 or die_error(500, "Open git-rev-list failed");
3313         %co = parse_commit_text(<$fd>, 1);
3314         close $fd;
3315
3316         return %co;
3317 }
3318
3319 sub parse_commits {
3320         my ($commit_id, $maxcount, $skip, $filename, @args) = @_;
3321         my @cos;
3322
3323         $maxcount ||= 1;
3324         $skip ||= 0;
3325
3326         local $/ = "\0";
3327
3328         open my $fd, "-|", git_cmd(), "rev-list",
3329                 "--header",
3330                 @args,
3331                 ("--max-count=" . $maxcount),
3332                 ("--skip=" . $skip),
3333                 @extra_options,
3334                 $commit_id,
3335                 "--",
3336                 ($filename ? ($filename) : ())
3337                 or die_error(500, "Open git-rev-list failed");
3338         while (my $line = <$fd>) {
3339                 my %co = parse_commit_text($line);
3340                 push @cos, \%co;
3341         }
3342         close $fd;
3343
3344         return wantarray ? @cos : \@cos;
3345 }
3346
3347 # parse line of git-diff-tree "raw" output
3348 sub parse_difftree_raw_line {
3349         my $line = shift;
3350         my %res;
3351
3352         # ':100644 100644 03b218260e99b78c6df0ed378e59ed9205ccc96d 3b93d5e7cc7f7dd4ebed13a5cc1a4ad976fc94d8 M   ls-files.c'
3353         # ':100644 100644 7f9281985086971d3877aca27704f2aaf9c448ce bc190ebc71bbd923f2b728e505408f5e54bd073a M   rev-tree.c'
3354         if ($line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)([0-9]{0,3})\t(.*)$/) {
3355                 $res{'from_mode'} = $1;
3356                 $res{'to_mode'} = $2;
3357                 $res{'from_id'} = $3;
3358                 $res{'to_id'} = $4;
3359                 $res{'status'} = $5;
3360                 $res{'similarity'} = $6;
3361                 if ($res{'status'} eq 'R' || $res{'status'} eq 'C') { # renamed or copied
3362                         ($res{'from_file'}, $res{'to_file'}) = map { unquote($_) } split("\t", $7);
3363                 } else {
3364                         $res{'from_file'} = $res{'to_file'} = $res{'file'} = unquote($7);
3365                 }
3366         }
3367         # '::100755 100755 100755 60e79ca1b01bc8b057abe17ddab484699a7f5fdb 94067cc5f73388f33722d52ae02f44692bc07490 94067cc5f73388f33722d52ae02f44692bc07490 MR git-gui/git-gui.sh'
3368         # combined diff (for merge commit)
3369         elsif ($line =~ s/^(::+)((?:[0-7]{6} )+)((?:[0-9a-fA-F]{40} )+)([a-zA-Z]+)\t(.*)$//) {
3370                 $res{'nparents'}  = length($1);
3371                 $res{'from_mode'} = [ split(' ', $2) ];
3372                 $res{'to_mode'} = pop @{$res{'from_mode'}};
3373                 $res{'from_id'} = [ split(' ', $3) ];
3374                 $res{'to_id'} = pop @{$res{'from_id'}};
3375                 $res{'status'} = [ split('', $4) ];
3376                 $res{'to_file'} = unquote($5);
3377         }
3378         # 'c512b523472485aef4fff9e57b229d9d243c967f'
3379         elsif ($line =~ m/^([0-9a-fA-F]{40})$/) {
3380                 $res{'commit'} = $1;
3381         }
3382
3383         return wantarray ? %res : \%res;
3384 }
3385
3386 # wrapper: return parsed line of git-diff-tree "raw" output
3387 # (the argument might be raw line, or parsed info)
3388 sub parsed_difftree_line {
3389         my $line_or_ref = shift;
3390
3391         if (ref($line_or_ref) eq "HASH") {
3392                 # pre-parsed (or generated by hand)
3393                 return $line_or_ref;
3394         } else {
3395                 return parse_difftree_raw_line($line_or_ref);
3396         }
3397 }
3398
3399 # parse line of git-ls-tree output
3400 sub parse_ls_tree_line {
3401         my $line = shift;
3402         my %opts = @_;
3403         my %res;
3404
3405         if ($opts{'-l'}) {
3406                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa   16717  panic.c'
3407                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40}) +(-|[0-9]+)\t(.+)$/s;
3408
3409                 $res{'mode'} = $1;
3410                 $res{'type'} = $2;
3411                 $res{'hash'} = $3;
3412                 $res{'size'} = $4;
3413                 if ($opts{'-z'}) {
3414                         $res{'name'} = $5;
3415                 } else {
3416                         $res{'name'} = unquote($5);
3417                 }
3418         } else {
3419                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
3420                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t(.+)$/s;
3421
3422                 $res{'mode'} = $1;
3423                 $res{'type'} = $2;
3424                 $res{'hash'} = $3;
3425                 if ($opts{'-z'}) {
3426                         $res{'name'} = $4;
3427                 } else {
3428                         $res{'name'} = unquote($4);
3429                 }
3430         }
3431
3432         return wantarray ? %res : \%res;
3433 }
3434
3435 # generates _two_ hashes, references to which are passed as 2 and 3 argument
3436 sub parse_from_to_diffinfo {
3437         my ($diffinfo, $from, $to, @parents) = @_;
3438
3439         if ($diffinfo->{'nparents'}) {
3440                 # combined diff
3441                 $from->{'file'} = [];
3442                 $from->{'href'} = [];
3443                 fill_from_file_info($diffinfo, @parents)
3444                         unless exists $diffinfo->{'from_file'};
3445                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
3446                         $from->{'file'}[$i] =
3447                                 defined $diffinfo->{'from_file'}[$i] ?
3448                                         $diffinfo->{'from_file'}[$i] :
3449                                         $diffinfo->{'to_file'};
3450                         if ($diffinfo->{'status'}[$i] ne "A") { # not new (added) file
3451                                 $from->{'href'}[$i] = href(action=>"blob",
3452                                                            hash_base=>$parents[$i],
3453                                                            hash=>$diffinfo->{'from_id'}[$i],
3454                                                            file_name=>$from->{'file'}[$i]);
3455                         } else {
3456                                 $from->{'href'}[$i] = undef;
3457                         }
3458                 }
3459         } else {
3460                 # ordinary (not combined) diff
3461                 $from->{'file'} = $diffinfo->{'from_file'};
3462                 if ($diffinfo->{'status'} ne "A") { # not new (added) file
3463                         $from->{'href'} = href(action=>"blob", hash_base=>$hash_parent,
3464                                                hash=>$diffinfo->{'from_id'},
3465                                                file_name=>$from->{'file'});
3466                 } else {
3467                         delete $from->{'href'};
3468                 }
3469         }
3470
3471         $to->{'file'} = $diffinfo->{'to_file'};
3472         if (!is_deleted($diffinfo)) { # file exists in result
3473                 $to->{'href'} = href(action=>"blob", hash_base=>$hash,
3474                                      hash=>$diffinfo->{'to_id'},
3475                                      file_name=>$to->{'file'});
3476         } else {
3477                 delete $to->{'href'};
3478         }
3479 }
3480
3481 ## ......................................................................
3482 ## parse to array of hashes functions
3483
3484 sub git_get_heads_list {
3485         my ($limit, @classes) = @_;
3486         @classes = ('heads') unless @classes;
3487         my @patterns = map { "refs/$_" } @classes;
3488         my @headslist;
3489
3490         open my $fd, '-|', git_cmd(), 'for-each-ref',
3491                 ($limit ? '--count='.($limit+1) : ()), '--sort=-committerdate',
3492                 '--format=%(objectname) %(refname) %(subject)%00%(committer)',
3493                 @patterns
3494                 or return;
3495         while (my $line = <$fd>) {
3496                 my %ref_item;
3497
3498                 chomp $line;
3499                 my ($refinfo, $committerinfo) = split(/\0/, $line);
3500                 my ($hash, $name, $title) = split(' ', $refinfo, 3);
3501                 my ($committer, $epoch, $tz) =
3502                         ($committerinfo =~ /^(.*) ([0-9]+) (.*)$/);
3503                 $ref_item{'fullname'}  = $name;
3504                 $name =~ s!^refs/(?:head|remote)s/!!;
3505
3506                 $ref_item{'name'}  = $name;
3507                 $ref_item{'id'}    = $hash;
3508                 $ref_item{'title'} = $title || '(no commit message)';
3509                 $ref_item{'epoch'} = $epoch;
3510                 if ($epoch) {
3511                         $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3512                 } else {
3513                         $ref_item{'age'} = "unknown";
3514                 }
3515
3516                 push @headslist, \%ref_item;
3517         }
3518         close $fd;
3519
3520         return wantarray ? @headslist : \@headslist;
3521 }
3522
3523 sub git_get_tags_list {
3524         my $limit = shift;
3525         my @tagslist;
3526
3527         open my $fd, '-|', git_cmd(), 'for-each-ref',
3528                 ($limit ? '--count='.($limit+1) : ()), '--sort=-creatordate',
3529                 '--format=%(objectname) %(objecttype) %(refname) '.
3530                 '%(*objectname) %(*objecttype) %(subject)%00%(creator)',
3531                 'refs/tags'
3532                 or return;
3533         while (my $line = <$fd>) {
3534                 my %ref_item;
3535
3536                 chomp $line;
3537                 my ($refinfo, $creatorinfo) = split(/\0/, $line);
3538                 my ($id, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
3539                 my ($creator, $epoch, $tz) =
3540                         ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
3541                 $ref_item{'fullname'} = $name;
3542                 $name =~ s!^refs/tags/!!;
3543
3544                 $ref_item{'type'} = $type;
3545                 $ref_item{'id'} = $id;
3546                 $ref_item{'name'} = $name;
3547                 if ($type eq "tag") {
3548                         $ref_item{'subject'} = $title;
3549                         $ref_item{'reftype'} = $reftype;
3550                         $ref_item{'refid'}   = $refid;
3551                 } else {
3552                         $ref_item{'reftype'} = $type;
3553                         $ref_item{'refid'}   = $id;
3554                 }
3555
3556                 if ($type eq "tag" || $type eq "commit") {
3557                         $ref_item{'epoch'} = $epoch;
3558                         if ($epoch) {
3559                                 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3560                         } else {
3561                                 $ref_item{'age'} = "unknown";
3562                         }
3563                 }
3564
3565                 push @tagslist, \%ref_item;
3566         }
3567         close $fd;
3568
3569         return wantarray ? @tagslist : \@tagslist;
3570 }
3571
3572 ## ----------------------------------------------------------------------
3573 ## filesystem-related functions
3574
3575 sub get_file_owner {
3576         my $path = shift;
3577
3578         my ($dev, $ino, $mode, $nlink, $st_uid, $st_gid, $rdev, $size) = stat($path);
3579         my ($name, $passwd, $uid, $gid, $quota, $comment, $gcos, $dir, $shell) = getpwuid($st_uid);
3580         if (!defined $gcos) {
3581                 return undef;
3582         }
3583         my $owner = $gcos;
3584         $owner =~ s/[,;].*$//;
3585         return to_utf8($owner);
3586 }
3587
3588 # assume that file exists
3589 sub insert_file {
3590         my $filename = shift;
3591
3592         open my $fd, '<', $filename;
3593         print map { to_utf8($_) } <$fd>;
3594         close $fd;
3595 }
3596
3597 ## ......................................................................
3598 ## mimetype related functions
3599
3600 sub mimetype_guess_file {
3601         my $filename = shift;
3602         my $mimemap = shift;
3603         -r $mimemap or return undef;
3604
3605         my %mimemap;
3606         open(my $mh, '<', $mimemap) or return undef;
3607         while (<$mh>) {
3608                 next if m/^#/; # skip comments
3609                 my ($mimetype, @exts) = split(/\s+/);
3610                 foreach my $ext (@exts) {
3611                         $mimemap{$ext} = $mimetype;
3612                 }
3613         }
3614         close($mh);
3615
3616         $filename =~ /\.([^.]*)$/;
3617         return $mimemap{$1};
3618 }
3619
3620 sub mimetype_guess {
3621         my $filename = shift;
3622         my $mime;
3623         $filename =~ /\./ or return undef;
3624
3625         if ($mimetypes_file) {
3626                 my $file = $mimetypes_file;
3627                 if ($file !~ m!^/!) { # if it is relative path
3628                         # it is relative to project
3629                         $file = "$projectroot/$project/$file";
3630                 }
3631                 $mime = mimetype_guess_file($filename, $file);
3632         }
3633         $mime ||= mimetype_guess_file($filename, '/etc/mime.types');
3634         return $mime;
3635 }
3636
3637 sub blob_mimetype {
3638         my $fd = shift;
3639         my $filename = shift;
3640
3641         if ($filename) {
3642                 my $mime = mimetype_guess($filename);
3643                 $mime and return $mime;
3644         }
3645
3646         # just in case
3647         return $default_blob_plain_mimetype unless $fd;
3648
3649         if (-T $fd) {
3650                 return 'text/plain';
3651         } elsif (! $filename) {
3652                 return 'application/octet-stream';
3653         } elsif ($filename =~ m/\.png$/i) {
3654                 return 'image/png';
3655         } elsif ($filename =~ m/\.gif$/i) {
3656                 return 'image/gif';
3657         } elsif ($filename =~ m/\.jpe?g$/i) {
3658                 return 'image/jpeg';
3659         } else {
3660                 return 'application/octet-stream';
3661         }
3662 }
3663
3664 sub blob_contenttype {
3665         my ($fd, $file_name, $type) = @_;
3666
3667         $type ||= blob_mimetype($fd, $file_name);
3668         if ($type eq 'text/plain' && defined $default_text_plain_charset) {
3669                 $type .= "; charset=$default_text_plain_charset";
3670         }
3671
3672         return $type;
3673 }
3674
3675 # guess file syntax for syntax highlighting; return undef if no highlighting
3676 # the name of syntax can (in the future) depend on syntax highlighter used
3677 sub guess_file_syntax {
3678         my ($highlight, $mimetype, $file_name) = @_;
3679         return undef unless ($highlight && defined $file_name);
3680         my $basename = basename($file_name, '.in');
3681         return $highlight_basename{$basename}
3682                 if exists $highlight_basename{$basename};
3683
3684         $basename =~ /\.([^.]*)$/;
3685         my $ext = $1 or return undef;
3686         return $highlight_ext{$ext}
3687                 if exists $highlight_ext{$ext};
3688
3689         return undef;
3690 }
3691
3692 # run highlighter and return FD of its output,
3693 # or return original FD if no highlighting
3694 sub run_highlighter {
3695         my ($fd, $highlight, $syntax) = @_;
3696         return $fd unless ($highlight && defined $syntax);
3697
3698         close $fd;
3699         open $fd, quote_command(git_cmd(), "cat-file", "blob", $hash)." | ".
3700                   quote_command($highlight_bin).
3701                   " --replace-tabs=8 --fragment --syntax $syntax |"
3702                 or die_error(500, "Couldn't open file or run syntax highlighter");
3703         return $fd;
3704 }
3705
3706 ## ======================================================================
3707 ## functions printing HTML: header, footer, error page
3708
3709 sub get_page_title {
3710         my $title = to_utf8($site_name);
3711
3712         return $title unless (defined $project);
3713         $title .= " - " . to_utf8($project);
3714
3715         return $title unless (defined $action);
3716         $title .= "/$action"; # $action is US-ASCII (7bit ASCII)
3717
3718         return $title unless (defined $file_name);
3719         $title .= " - " . esc_path($file_name);
3720         if ($action eq "tree" && $file_name !~ m|/$|) {
3721                 $title .= "/";
3722         }
3723
3724         return $title;
3725 }
3726
3727 sub get_content_type_html {
3728         # require explicit support from the UA if we are to send the page as
3729         # 'application/xhtml+xml', otherwise send it as plain old 'text/html'.
3730         # we have to do this because MSIE sometimes globs '*/*', pretending to
3731         # support xhtml+xml but choking when it gets what it asked for.
3732         if (defined $cgi->http('HTTP_ACCEPT') &&
3733             $cgi->http('HTTP_ACCEPT') =~ m/(,|;|\s|^)application\/xhtml\+xml(,|;|\s|$)/ &&
3734             $cgi->Accept('application/xhtml+xml') != 0) {
3735                 return 'application/xhtml+xml';
3736         } else {
3737                 return 'text/html';
3738         }
3739 }
3740
3741 sub print_feed_meta {
3742         if (defined $project) {
3743                 my %href_params = get_feed_info();
3744                 if (!exists $href_params{'-title'}) {
3745                         $href_params{'-title'} = 'log';
3746                 }
3747
3748                 foreach my $format (qw(RSS Atom)) {
3749                         my $type = lc($format);
3750                         my %link_attr = (
3751                                 '-rel' => 'alternate',
3752                                 '-title' => esc_attr("$project - $href_params{'-title'} - $format feed"),
3753                                 '-type' => "application/$type+xml"
3754                         );
3755
3756                         $href_params{'action'} = $type;
3757                         $link_attr{'-href'} = href(%href_params);
3758                         print "<link ".
3759                               "rel=\"$link_attr{'-rel'}\" ".
3760                               "title=\"$link_attr{'-title'}\" ".
3761                               "href=\"$link_attr{'-href'}\" ".
3762                               "type=\"$link_attr{'-type'}\" ".
3763                               "/>\n";
3764
3765                         $href_params{'extra_options'} = '--no-merges';
3766                         $link_attr{'-href'} = href(%href_params);
3767                         $link_attr{'-title'} .= ' (no merges)';
3768                         print "<link ".
3769                               "rel=\"$link_attr{'-rel'}\" ".
3770                               "title=\"$link_attr{'-title'}\" ".
3771                               "href=\"$link_attr{'-href'}\" ".
3772                               "type=\"$link_attr{'-type'}\" ".
3773                               "/>\n";
3774                 }
3775
3776         } else {
3777                 printf('<link rel="alternate" title="%s projects list" '.
3778                        'href="%s" type="text/plain; charset=utf-8" />'."\n",
3779                        esc_attr($site_name), href(project=>undef, action=>"project_index"));
3780                 printf('<link rel="alternate" title="%s projects feeds" '.
3781                        'href="%s" type="text/x-opml" />'."\n",
3782                        esc_attr($site_name), href(project=>undef, action=>"opml"));
3783         }
3784 }
3785
3786 sub print_header_links {
3787         my $status = shift;
3788
3789         # print out each stylesheet that exist, providing backwards capability
3790         # for those people who defined $stylesheet in a config file
3791         if (defined $stylesheet) {
3792                 print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
3793         } else {
3794                 foreach my $stylesheet (@stylesheets) {
3795                         next unless $stylesheet;
3796                         print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
3797                 }
3798         }
3799         print_feed_meta()
3800                 if ($status eq '200 OK');
3801         if (defined $favicon) {
3802                 print qq(<link rel="shortcut icon" href=").esc_url($favicon).qq(" type="image/png" />\n);
3803         }
3804 }
3805
3806 sub print_nav_breadcrumbs {
3807         my %opts = @_;
3808
3809         print $cgi->a({-href => esc_url($home_link)}, $home_link_str) . " / ";
3810         if (defined $project) {
3811                 print $cgi->a({-href => href(action=>"summary")}, esc_html($project));
3812                 if (defined $action) {
3813                         my $action_print = $action ;
3814                         if (defined $opts{-action_extra}) {
3815                                 $action_print = $cgi->a({-href => href(action=>$action)},
3816                                         $action);
3817                         }
3818                         print " / $action_print";
3819                 }
3820                 if (defined $opts{-action_extra}) {
3821                         print " / $opts{-action_extra}";
3822                 }
3823                 print "\n";
3824         }
3825 }
3826
3827 sub print_search_form {
3828         if (!defined $searchtext) {
3829                 $searchtext = "";
3830         }
3831         my $search_hash;
3832         if (defined $hash_base) {
3833                 $search_hash = $hash_base;
3834         } elsif (defined $hash) {
3835                 $search_hash = $hash;
3836         } else {
3837                 $search_hash = "HEAD";
3838         }
3839         my $action = $my_uri;
3840         my $use_pathinfo = gitweb_check_feature('pathinfo');
3841         if ($use_pathinfo) {
3842                 $action .= "/".esc_url($project);
3843         }
3844         print $cgi->startform(-method => "get", -action => $action) .
3845               "<div class=\"search\">\n" .
3846               (!$use_pathinfo &&
3847               $cgi->input({-name=>"p", -value=>$project, -type=>"hidden"}) . "\n") .
3848               $cgi->input({-name=>"a", -value=>"search", -type=>"hidden"}) . "\n" .
3849               $cgi->input({-name=>"h", -value=>$search_hash, -type=>"hidden"}) . "\n" .
3850               $cgi->popup_menu(-name => 'st', -default => 'commit',
3851                                -values => ['commit', 'grep', 'author', 'committer', 'pickaxe']) .
3852               $cgi->sup($cgi->a({-href => href(action=>"search_help")}, "?")) .
3853               " search:\n",
3854               $cgi->textfield(-name => "s", -value => $searchtext) . "\n" .
3855               "<span title=\"Extended regular expression\">" .
3856               $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
3857                              -checked => $search_use_regexp) .
3858               "</span>" .
3859               "</div>" .
3860               $cgi->end_form() . "\n";
3861 }
3862
3863 sub git_header_html {
3864         my $status = shift || "200 OK";
3865         my $expires = shift;
3866         my %opts = @_;
3867
3868         my $title = get_page_title();
3869         my $content_type = get_content_type_html();
3870         print $cgi->header(-type=>$content_type, -charset => 'utf-8',
3871                            -status=> $status, -expires => $expires)
3872                 unless ($opts{'-no_http_header'});
3873         my $mod_perl_version = $ENV{'MOD_PERL'} ? " $ENV{'MOD_PERL'}" : '';
3874         print <<EOF;
3875 <?xml version="1.0" encoding="utf-8"?>
3876 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
3877 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en-US" lang="en-US">
3878 <!-- git web interface version $version, (C) 2005-2006, Kay Sievers <kay.sievers\@vrfy.org>, Christian Gierke -->
3879 <!-- git core binaries version $git_version -->
3880 <head>
3881 <meta http-equiv="content-type" content="$content_type; charset=utf-8"/>
3882 <meta name="generator" content="gitweb/$version git/$git_version$mod_perl_version"/>
3883 <meta name="robots" content="index, nofollow"/>
3884 <title>$title</title>
3885 EOF
3886         # the stylesheet, favicon etc urls won't work correctly with path_info
3887         # unless we set the appropriate base URL
3888         if ($ENV{'PATH_INFO'}) {
3889                 print "<base href=\"".esc_url($base_url)."\" />\n";
3890         }
3891         print_header_links($status);
3892
3893         if (defined $site_html_head_string) {
3894                 print to_utf8($site_html_head_string);
3895         }
3896
3897         print "</head>\n" .
3898               "<body>\n";
3899
3900         if (defined $site_header && -f $site_header) {
3901                 insert_file($site_header);
3902         }
3903
3904         print "<div class=\"page_header\">\n";
3905         if (defined $logo) {
3906                 print $cgi->a({-href => esc_url($logo_url),
3907                                -title => $logo_label},
3908                               $cgi->img({-src => esc_url($logo),
3909                                          -width => 72, -height => 27,
3910                                          -alt => "git",
3911                                          -class => "logo"}));
3912         }
3913         print_nav_breadcrumbs(%opts);
3914         print "</div>\n";
3915
3916         my $have_search = gitweb_check_feature('search');
3917         if (defined $project && $have_search) {
3918                 print_search_form();
3919         }
3920 }
3921
3922 sub git_footer_html {
3923         my $feed_class = 'rss_logo';
3924
3925         print "<div class=\"page_footer\">\n";
3926         if (defined $project) {
3927                 my $descr = git_get_project_description($project);
3928                 if (defined $descr) {
3929                         print "<div class=\"page_footer_text\">" . esc_html($descr) . "</div>\n";
3930                 }
3931
3932                 my %href_params = get_feed_info();
3933                 if (!%href_params) {
3934                         $feed_class .= ' generic';
3935                 }
3936                 $href_params{'-title'} ||= 'log';
3937
3938                 foreach my $format (qw(RSS Atom)) {
3939                         $href_params{'action'} = lc($format);
3940                         print $cgi->a({-href => href(%href_params),
3941                                       -title => "$href_params{'-title'} $format feed",
3942                                       -class => $feed_class}, $format)."\n";
3943                 }
3944
3945         } else {
3946                 print $cgi->a({-href => href(project=>undef, action=>"opml"),
3947                               -class => $feed_class}, "OPML") . " ";
3948                 print $cgi->a({-href => href(project=>undef, action=>"project_index"),
3949                               -class => $feed_class}, "TXT") . "\n";
3950         }
3951         print "</div>\n"; # class="page_footer"
3952
3953         if (defined $t0 && gitweb_check_feature('timed')) {
3954                 print "<div id=\"generating_info\">\n";
3955                 print 'This page took '.
3956                       '<span id="generating_time" class="time_span">'.
3957                       tv_interval($t0, [ gettimeofday() ]).
3958                       ' seconds </span>'.
3959                       ' and '.
3960                       '<span id="generating_cmd">'.
3961                       $number_of_git_cmds.
3962                       '</span> git commands '.
3963                       " to generate.\n";
3964                 print "</div>\n"; # class="page_footer"
3965         }
3966
3967         if (defined $site_footer && -f $site_footer) {
3968                 insert_file($site_footer);
3969         }
3970
3971         print qq!<script type="text/javascript" src="!.esc_url($javascript).qq!"></script>\n!;
3972         if (defined $action &&
3973             $action eq 'blame_incremental') {
3974                 print qq!<script type="text/javascript">\n!.
3975                       qq!startBlame("!. href(action=>"blame_data", -replay=>1) .qq!",\n!.
3976                       qq!           "!. href() .qq!");\n!.
3977                       qq!</script>\n!;
3978         } else {
3979                 my ($jstimezone, $tz_cookie, $datetime_class) =
3980                         gitweb_get_feature('javascript-timezone');
3981
3982                 print qq!<script type="text/javascript">\n!.
3983                       qq!window.onload = function () {\n!;
3984                 if (gitweb_check_feature('javascript-actions')) {
3985                         print qq!       fixLinks();\n!;
3986                 }
3987                 if ($jstimezone && $tz_cookie && $datetime_class) {
3988                         print qq!       var tz_cookie = { name: '$tz_cookie', expires: 14, path: '/' };\n!. # in days
3989                               qq!       onloadTZSetup('$jstimezone', tz_cookie, '$datetime_class');\n!;
3990                 }
3991                 print qq!};\n!.
3992                       qq!</script>\n!;
3993         }
3994
3995         print "</body>\n" .
3996               "</html>";
3997 }
3998
3999 # die_error(<http_status_code>, <error_message>[, <detailed_html_description>])
4000 # Example: die_error(404, 'Hash not found')
4001 # By convention, use the following status codes (as defined in RFC 2616):
4002 # 400: Invalid or missing CGI parameters, or
4003 #      requested object exists but has wrong type.
4004 # 403: Requested feature (like "pickaxe" or "snapshot") not enabled on
4005 #      this server or project.
4006 # 404: Requested object/revision/project doesn't exist.
4007 # 500: The server isn't configured properly, or
4008 #      an internal error occurred (e.g. failed assertions caused by bugs), or
4009 #      an unknown error occurred (e.g. the git binary died unexpectedly).
4010 # 503: The server is currently unavailable (because it is overloaded,
4011 #      or down for maintenance).  Generally, this is a temporary state.
4012 sub die_error {
4013         my $status = shift || 500;
4014         my $error = esc_html(shift) || "Internal Server Error";
4015         my $extra = shift;
4016         my %opts = @_;
4017
4018         my %http_responses = (
4019                 400 => '400 Bad Request',
4020                 403 => '403 Forbidden',
4021                 404 => '404 Not Found',
4022                 500 => '500 Internal Server Error',
4023                 503 => '503 Service Unavailable',
4024         );
4025         git_header_html($http_responses{$status}, undef, %opts);
4026         print <<EOF;
4027 <div class="page_body">
4028 <br /><br />
4029 $status - $error
4030 <br />
4031 EOF
4032         if (defined $extra) {
4033                 print "<hr />\n" .
4034                       "$extra\n";
4035         }
4036         print "</div>\n";
4037
4038         git_footer_html();
4039         goto DONE_GITWEB
4040                 unless ($opts{'-error_handler'});
4041 }
4042
4043 ## ----------------------------------------------------------------------
4044 ## functions printing or outputting HTML: navigation
4045
4046 sub git_print_page_nav {
4047         my ($current, $suppress, $head, $treehead, $treebase, $extra) = @_;
4048         $extra = '' if !defined $extra; # pager or formats
4049
4050         my @navs = qw(summary shortlog log commit commitdiff tree);
4051         if ($suppress) {
4052                 @navs = grep { $_ ne $suppress } @navs;
4053         }
4054
4055         my %arg = map { $_ => {action=>$_} } @navs;
4056         if (defined $head) {
4057                 for (qw(commit commitdiff)) {
4058                         $arg{$_}{'hash'} = $head;
4059                 }
4060                 if ($current =~ m/^(tree | log | shortlog | commit | commitdiff | search)$/x) {
4061                         for (qw(shortlog log)) {
4062                                 $arg{$_}{'hash'} = $head;
4063                         }
4064                 }
4065         }
4066
4067         $arg{'tree'}{'hash'} = $treehead if defined $treehead;
4068         $arg{'tree'}{'hash_base'} = $treebase if defined $treebase;
4069
4070         my @actions = gitweb_get_feature('actions');
4071         my %repl = (
4072                 '%' => '%',
4073                 'n' => $project,         # project name
4074                 'f' => $git_dir,         # project path within filesystem
4075                 'h' => $treehead || '',  # current hash ('h' parameter)
4076                 'b' => $treebase || '',  # hash base ('hb' parameter)
4077         );
4078         while (@actions) {
4079                 my ($label, $link, $pos) = splice(@actions,0,3);
4080                 # insert
4081                 @navs = map { $_ eq $pos ? ($_, $label) : $_ } @navs;
4082                 # munch munch
4083                 $link =~ s/%([%nfhb])/$repl{$1}/g;
4084                 $arg{$label}{'_href'} = $link;
4085         }
4086
4087         print "<div class=\"page_nav\">\n" .
4088                 (join " | ",
4089                  map { $_ eq $current ?
4090                        $_ : $cgi->a({-href => ($arg{$_}{_href} ? $arg{$_}{_href} : href(%{$arg{$_}}))}, "$_")
4091                  } @navs);
4092         print "<br/>\n$extra<br/>\n" .
4093               "</div>\n";
4094 }
4095
4096 # returns a submenu for the nagivation of the refs views (tags, heads,
4097 # remotes) with the current view disabled and the remotes view only
4098 # available if the feature is enabled
4099 sub format_ref_views {
4100         my ($current) = @_;
4101         my @ref_views = qw{tags heads};
4102         push @ref_views, 'remotes' if gitweb_check_feature('remote_heads');
4103         return join " | ", map {
4104                 $_ eq $current ? $_ :
4105                 $cgi->a({-href => href(action=>$_)}, $_)
4106         } @ref_views
4107 }
4108
4109 sub format_paging_nav {
4110         my ($action, $page, $has_next_link) = @_;
4111         my $paging_nav;
4112
4113
4114         if ($page > 0) {
4115                 $paging_nav .=
4116                         $cgi->a({-href => href(-replay=>1, page=>undef)}, "first") .
4117                         " &sdot; " .
4118                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
4119                                  -accesskey => "p", -title => "Alt-p"}, "prev");
4120         } else {
4121                 $paging_nav .= "first &sdot; prev";
4122         }
4123
4124         if ($has_next_link) {
4125                 $paging_nav .= " &sdot; " .
4126                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
4127                                  -accesskey => "n", -title => "Alt-n"}, "next");
4128         } else {
4129                 $paging_nav .= " &sdot; next";
4130         }
4131
4132         return $paging_nav;
4133 }
4134
4135 ## ......................................................................
4136 ## functions printing or outputting HTML: div
4137
4138 sub git_print_header_div {
4139         my ($action, $title, $hash, $hash_base) = @_;
4140         my %args = ();
4141
4142         $args{'action'} = $action;
4143         $args{'hash'} = $hash if $hash;
4144         $args{'hash_base'} = $hash_base if $hash_base;
4145
4146         print "<div class=\"header\">\n" .
4147               $cgi->a({-href => href(%args), -class => "title"},
4148               $title ? $title : $action) .
4149               "\n</div>\n";
4150 }
4151
4152 sub format_repo_url {
4153         my ($name, $url) = @_;
4154         return "<tr class=\"metadata_url\"><td>$name</td><td>$url</td></tr>\n";
4155 }
4156
4157 # Group output by placing it in a DIV element and adding a header.
4158 # Options for start_div() can be provided by passing a hash reference as the
4159 # first parameter to the function.
4160 # Options to git_print_header_div() can be provided by passing an array
4161 # reference. This must follow the options to start_div if they are present.
4162 # The content can be a scalar, which is output as-is, a scalar reference, which
4163 # is output after html escaping, an IO handle passed either as *handle or
4164 # *handle{IO}, or a function reference. In the latter case all following
4165 # parameters will be taken as argument to the content function call.
4166 sub git_print_section {
4167         my ($div_args, $header_args, $content);
4168         my $arg = shift;
4169         if (ref($arg) eq 'HASH') {
4170                 $div_args = $arg;
4171                 $arg = shift;
4172         }
4173         if (ref($arg) eq 'ARRAY') {
4174                 $header_args = $arg;
4175                 $arg = shift;
4176         }
4177         $content = $arg;
4178
4179         print $cgi->start_div($div_args);
4180         git_print_header_div(@$header_args);
4181
4182         if (ref($content) eq 'CODE') {
4183                 $content->(@_);
4184         } elsif (ref($content) eq 'SCALAR') {
4185                 print esc_html($$content);
4186         } elsif (ref($content) eq 'GLOB' or ref($content) eq 'IO::Handle') {
4187                 print <$content>;
4188         } elsif (!ref($content) && defined($content)) {
4189                 print $content;
4190         }
4191
4192         print $cgi->end_div;
4193 }
4194
4195 sub format_timestamp_html {
4196         my $date = shift;
4197         my $strtime = $date->{'rfc2822'};
4198
4199         my (undef, undef, $datetime_class) =
4200                 gitweb_get_feature('javascript-timezone');
4201         if ($datetime_class) {
4202                 $strtime = qq!<span class="$datetime_class">$strtime</span>!;
4203         }
4204
4205         my $localtime_format = '(%02d:%02d %s)';
4206         if ($date->{'hour_local'} < 6) {
4207                 $localtime_format = '(<span class="atnight">%02d:%02d</span> %s)';
4208         }
4209         $strtime .= ' ' .
4210                     sprintf($localtime_format,
4211                             $date->{'hour_local'}, $date->{'minute_local'}, $date->{'tz_local'});
4212
4213         return $strtime;
4214 }
4215
4216 # Outputs the author name and date in long form
4217 sub git_print_authorship {
4218         my $co = shift;
4219         my %opts = @_;
4220         my $tag = $opts{-tag} || 'div';
4221         my $author = $co->{'author_name'};
4222
4223         my %ad = parse_date($co->{'author_epoch'}, $co->{'author_tz'});
4224         print "<$tag class=\"author_date\">" .
4225               format_search_author($author, "author", esc_html($author)) .
4226               " [".format_timestamp_html(\%ad)."]".
4227               git_get_avatar($co->{'author_email'}, -pad_before => 1) .
4228               "</$tag>\n";
4229 }
4230
4231 # Outputs table rows containing the full author or committer information,
4232 # in the format expected for 'commit' view (& similar).
4233 # Parameters are a commit hash reference, followed by the list of people
4234 # to output information for. If the list is empty it defaults to both
4235 # author and committer.
4236 sub git_print_authorship_rows {
4237         my $co = shift;
4238         # too bad we can't use @people = @_ || ('author', 'committer')
4239         my @people = @_;
4240         @people = ('author', 'committer') unless @people;
4241         foreach my $who (@people) {
4242                 my %wd = parse_date($co->{"${who}_epoch"}, $co->{"${who}_tz"});
4243                 print "<tr><td>$who</td><td>" .
4244                       format_search_author($co->{"${who}_name"}, $who,
4245                                            esc_html($co->{"${who}_name"})) . " " .
4246                       format_search_author($co->{"${who}_email"}, $who,
4247                                            esc_html("<" . $co->{"${who}_email"} . ">")) .
4248                       "</td><td rowspan=\"2\">" .
4249                       git_get_avatar($co->{"${who}_email"}, -size => 'double') .
4250                       "</td></tr>\n" .
4251                       "<tr>" .
4252                       "<td></td><td>" .
4253                       format_timestamp_html(\%wd) .
4254                       "</td>" .
4255                       "</tr>\n";
4256         }
4257 }
4258
4259 sub git_print_page_path {
4260         my $name = shift;
4261         my $type = shift;
4262         my $hb = shift;
4263
4264
4265         print "<div class=\"page_path\">";
4266         print $cgi->a({-href => href(action=>"tree", hash_base=>$hb),
4267                       -title => 'tree root'}, to_utf8("[$project]"));
4268         print " / ";
4269         if (defined $name) {
4270                 my @dirname = split '/', $name;
4271                 my $basename = pop @dirname;
4272                 my $fullname = '';
4273
4274                 foreach my $dir (@dirname) {
4275                         $fullname .= ($fullname ? '/' : '') . $dir;
4276                         print $cgi->a({-href => href(action=>"tree", file_name=>$fullname,
4277                                                      hash_base=>$hb),
4278                                       -title => $fullname}, esc_path($dir));
4279                         print " / ";
4280                 }
4281                 if (defined $type && $type eq 'blob') {
4282                         print $cgi->a({-href => href(action=>"blob_plain", file_name=>$file_name,
4283                                                      hash_base=>$hb),
4284                                       -title => $name}, esc_path($basename));
4285                 } elsif (defined $type && $type eq 'tree') {
4286                         print $cgi->a({-href => href(action=>"tree", file_name=>$file_name,
4287                                                      hash_base=>$hb),
4288                                       -title => $name}, esc_path($basename));
4289                         print " / ";
4290                 } else {
4291                         print esc_path($basename);
4292                 }
4293         }
4294         print "<br/></div>\n";
4295 }
4296
4297 sub git_print_log {
4298         my $log = shift;
4299         my %opts = @_;
4300
4301         if ($opts{'-remove_title'}) {
4302                 # remove title, i.e. first line of log
4303                 shift @$log;
4304         }
4305         # remove leading empty lines
4306         while (defined $log->[0] && $log->[0] eq "") {
4307                 shift @$log;
4308         }
4309
4310         # print log
4311         my $signoff = 0;
4312         my $empty = 0;
4313         foreach my $line (@$log) {
4314                 if ($line =~ m/^ *(signed[ \-]off[ \-]by[ :]|acked[ \-]by[ :]|cc[ :])/i) {
4315                         $signoff = 1;
4316                         $empty = 0;
4317                         if (! $opts{'-remove_signoff'}) {
4318                                 print "<span class=\"signoff\">" . esc_html($line) . "</span><br/>\n";
4319                                 next;
4320                         } else {
4321                                 # remove signoff lines
4322                                 next;
4323                         }
4324                 } else {
4325                         $signoff = 0;
4326                 }
4327
4328                 # print only one empty line
4329                 # do not print empty line after signoff
4330                 if ($line eq "") {
4331                         next if ($empty || $signoff);
4332                         $empty = 1;
4333                 } else {
4334                         $empty = 0;
4335                 }
4336
4337                 print format_log_line_html($line) . "<br/>\n";
4338         }
4339
4340         if ($opts{'-final_empty_line'}) {
4341                 # end with single empty line
4342                 print "<br/>\n" unless $empty;
4343         }
4344 }
4345
4346 # return link target (what link points to)
4347 sub git_get_link_target {
4348         my $hash = shift;
4349         my $link_target;
4350
4351         # read link
4352         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
4353                 or return;
4354         {
4355                 local $/ = undef;
4356                 $link_target = <$fd>;
4357         }
4358         close $fd
4359                 or return;
4360
4361         return $link_target;
4362 }
4363
4364 # given link target, and the directory (basedir) the link is in,
4365 # return target of link relative to top directory (top tree);
4366 # return undef if it is not possible (including absolute links).
4367 sub normalize_link_target {
4368         my ($link_target, $basedir) = @_;
4369
4370         # absolute symlinks (beginning with '/') cannot be normalized
4371         return if (substr($link_target, 0, 1) eq '/');
4372
4373         # normalize link target to path from top (root) tree (dir)
4374         my $path;
4375         if ($basedir) {
4376                 $path = $basedir . '/' . $link_target;
4377         } else {
4378                 # we are in top (root) tree (dir)
4379                 $path = $link_target;
4380         }
4381
4382         # remove //, /./, and /../
4383         my @path_parts;
4384         foreach my $part (split('/', $path)) {
4385                 # discard '.' and ''
4386                 next if (!$part || $part eq '.');
4387                 # handle '..'
4388                 if ($part eq '..') {
4389                         if (@path_parts) {
4390                                 pop @path_parts;
4391                         } else {
4392                                 # link leads outside repository (outside top dir)
4393                                 return;
4394                         }
4395                 } else {
4396                         push @path_parts, $part;
4397                 }
4398         }
4399         $path = join('/', @path_parts);
4400
4401         return $path;
4402 }
4403
4404 # print tree entry (row of git_tree), but without encompassing <tr> element
4405 sub git_print_tree_entry {
4406         my ($t, $basedir, $hash_base, $have_blame) = @_;
4407
4408         my %base_key = ();
4409         $base_key{'hash_base'} = $hash_base if defined $hash_base;
4410
4411         # The format of a table row is: mode list link.  Where mode is
4412         # the mode of the entry, list is the name of the entry, an href,
4413         # and link is the action links of the entry.
4414
4415         print "<td class=\"mode\">" . mode_str($t->{'mode'}) . "</td>\n";
4416         if (exists $t->{'size'}) {
4417                 print "<td class=\"size\">$t->{'size'}</td>\n";
4418         }
4419         if ($t->{'type'} eq "blob") {
4420                 print "<td class=\"list\">" .
4421                         $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4422                                                file_name=>"$basedir$t->{'name'}", %base_key),
4423                                 -class => "list"}, esc_path($t->{'name'}));
4424                 if (S_ISLNK(oct $t->{'mode'})) {
4425                         my $link_target = git_get_link_target($t->{'hash'});
4426                         if ($link_target) {
4427                                 my $norm_target = normalize_link_target($link_target, $basedir);
4428                                 if (defined $norm_target) {
4429                                         print " -> " .
4430                                               $cgi->a({-href => href(action=>"object", hash_base=>$hash_base,
4431                                                                      file_name=>$norm_target),
4432                                                        -title => $norm_target}, esc_path($link_target));
4433                                 } else {
4434                                         print " -> " . esc_path($link_target);
4435                                 }
4436                         }
4437                 }
4438                 print "</td>\n";
4439                 print "<td class=\"link\">";
4440                 print $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4441                                              file_name=>"$basedir$t->{'name'}", %base_key)},
4442                               "blob");
4443                 if ($have_blame) {
4444                         print " | " .
4445                               $cgi->a({-href => href(action=>"blame", hash=>$t->{'hash'},
4446                                                      file_name=>"$basedir$t->{'name'}", %base_key)},
4447                                       "blame");
4448                 }
4449                 if (defined $hash_base) {
4450                         print " | " .
4451                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4452                                                      hash=>$t->{'hash'}, file_name=>"$basedir$t->{'name'}")},
4453                                       "history");
4454                 }
4455                 print " | " .
4456                         $cgi->a({-href => href(action=>"blob_plain", hash_base=>$hash_base,
4457                                                file_name=>"$basedir$t->{'name'}")},
4458                                 "raw");
4459                 print "</td>\n";
4460
4461         } elsif ($t->{'type'} eq "tree") {
4462                 print "<td class=\"list\">";
4463                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4464                                              file_name=>"$basedir$t->{'name'}",
4465                                              %base_key)},
4466                               esc_path($t->{'name'}));
4467                 print "</td>\n";
4468                 print "<td class=\"link\">";
4469                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4470                                              file_name=>"$basedir$t->{'name'}",
4471                                              %base_key)},
4472                               "tree");
4473                 if (defined $hash_base) {
4474                         print " | " .
4475                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4476                                                      file_name=>"$basedir$t->{'name'}")},
4477                                       "history");
4478                 }
4479                 print "</td>\n";
4480         } else {
4481                 # unknown object: we can only present history for it
4482                 # (this includes 'commit' object, i.e. submodule support)
4483                 print "<td class=\"list\">" .
4484                       esc_path($t->{'name'}) .
4485                       "</td>\n";
4486                 print "<td class=\"link\">";
4487                 if (defined $hash_base) {
4488                         print $cgi->a({-href => href(action=>"history",
4489                                                      hash_base=>$hash_base,
4490                                                      file_name=>"$basedir$t->{'name'}")},
4491                                       "history");
4492                 }
4493                 print "</td>\n";
4494         }
4495 }
4496
4497 ## ......................................................................
4498 ## functions printing large fragments of HTML
4499
4500 # get pre-image filenames for merge (combined) diff
4501 sub fill_from_file_info {
4502         my ($diff, @parents) = @_;
4503
4504         $diff->{'from_file'} = [ ];
4505         $diff->{'from_file'}[$diff->{'nparents'} - 1] = undef;
4506         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4507                 if ($diff->{'status'}[$i] eq 'R' ||
4508                     $diff->{'status'}[$i] eq 'C') {
4509                         $diff->{'from_file'}[$i] =
4510                                 git_get_path_by_hash($parents[$i], $diff->{'from_id'}[$i]);
4511                 }
4512         }
4513
4514         return $diff;
4515 }
4516
4517 # is current raw difftree line of file deletion
4518 sub is_deleted {
4519         my $diffinfo = shift;
4520
4521         return $diffinfo->{'to_id'} eq ('0' x 40);
4522 }
4523
4524 # does patch correspond to [previous] difftree raw line
4525 # $diffinfo  - hashref of parsed raw diff format
4526 # $patchinfo - hashref of parsed patch diff format
4527 #              (the same keys as in $diffinfo)
4528 sub is_patch_split {
4529         my ($diffinfo, $patchinfo) = @_;
4530
4531         return defined $diffinfo && defined $patchinfo
4532                 && $diffinfo->{'to_file'} eq $patchinfo->{'to_file'};
4533 }
4534
4535
4536 sub git_difftree_body {
4537         my ($difftree, $hash, @parents) = @_;
4538         my ($parent) = $parents[0];
4539         my $have_blame = gitweb_check_feature('blame');
4540         print "<div class=\"list_head\">\n";
4541         if ($#{$difftree} > 10) {
4542                 print(($#{$difftree} + 1) . " files changed:\n");
4543         }
4544         print "</div>\n";
4545
4546         print "<table class=\"" .
4547               (@parents > 1 ? "combined " : "") .
4548               "diff_tree\">\n";
4549
4550         # header only for combined diff in 'commitdiff' view
4551         my $has_header = @$difftree && @parents > 1 && $action eq 'commitdiff';
4552         if ($has_header) {
4553                 # table header
4554                 print "<thead><tr>\n" .
4555                        "<th></th><th></th>\n"; # filename, patchN link
4556                 for (my $i = 0; $i < @parents; $i++) {
4557                         my $par = $parents[$i];
4558                         print "<th>" .
4559                               $cgi->a({-href => href(action=>"commitdiff",
4560                                                      hash=>$hash, hash_parent=>$par),
4561                                        -title => 'commitdiff to parent number ' .
4562                                                   ($i+1) . ': ' . substr($par,0,7)},
4563                                       $i+1) .
4564                               "&nbsp;</th>\n";
4565                 }
4566                 print "</tr></thead>\n<tbody>\n";
4567         }
4568
4569         my $alternate = 1;
4570         my $patchno = 0;
4571         foreach my $line (@{$difftree}) {
4572                 my $diff = parsed_difftree_line($line);
4573
4574                 if ($alternate) {
4575                         print "<tr class=\"dark\">\n";
4576                 } else {
4577                         print "<tr class=\"light\">\n";
4578                 }
4579                 $alternate ^= 1;
4580
4581                 if (exists $diff->{'nparents'}) { # combined diff
4582
4583                         fill_from_file_info($diff, @parents)
4584                                 unless exists $diff->{'from_file'};
4585
4586                         if (!is_deleted($diff)) {
4587                                 # file exists in the result (child) commit
4588                                 print "<td>" .
4589                                       $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4590                                                              file_name=>$diff->{'to_file'},
4591                                                              hash_base=>$hash),
4592                                               -class => "list"}, esc_path($diff->{'to_file'})) .
4593                                       "</td>\n";
4594                         } else {
4595                                 print "<td>" .
4596                                       esc_path($diff->{'to_file'}) .
4597                                       "</td>\n";
4598                         }
4599
4600                         if ($action eq 'commitdiff') {
4601                                 # link to patch
4602                                 $patchno++;
4603                                 print "<td class=\"link\">" .
4604                                       $cgi->a({-href => href(-anchor=>"patch$patchno")},
4605                                               "patch") .
4606                                       " | " .
4607                                       "</td>\n";
4608                         }
4609
4610                         my $has_history = 0;
4611                         my $not_deleted = 0;
4612                         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4613                                 my $hash_parent = $parents[$i];
4614                                 my $from_hash = $diff->{'from_id'}[$i];
4615                                 my $from_path = $diff->{'from_file'}[$i];
4616                                 my $status = $diff->{'status'}[$i];
4617
4618                                 $has_history ||= ($status ne 'A');
4619                                 $not_deleted ||= ($status ne 'D');
4620
4621                                 if ($status eq 'A') {
4622                                         print "<td  class=\"link\" align=\"right\"> | </td>\n";
4623                                 } elsif ($status eq 'D') {
4624                                         print "<td class=\"link\">" .
4625                                               $cgi->a({-href => href(action=>"blob",
4626                                                                      hash_base=>$hash,
4627                                                                      hash=>$from_hash,
4628                                                                      file_name=>$from_path)},
4629                                                       "blob" . ($i+1)) .
4630                                               " | </td>\n";
4631                                 } else {
4632                                         if ($diff->{'to_id'} eq $from_hash) {
4633                                                 print "<td class=\"link nochange\">";
4634                                         } else {
4635                                                 print "<td class=\"link\">";
4636                                         }
4637                                         print $cgi->a({-href => href(action=>"blobdiff",
4638                                                                      hash=>$diff->{'to_id'},
4639                                                                      hash_parent=>$from_hash,
4640                                                                      hash_base=>$hash,
4641                                                                      hash_parent_base=>$hash_parent,
4642                                                                      file_name=>$diff->{'to_file'},
4643                                                                      file_parent=>$from_path)},
4644                                                       "diff" . ($i+1)) .
4645                                               " | </td>\n";
4646                                 }
4647                         }
4648
4649                         print "<td class=\"link\">";
4650                         if ($not_deleted) {
4651                                 print $cgi->a({-href => href(action=>"blob",
4652                                                              hash=>$diff->{'to_id'},
4653                                                              file_name=>$diff->{'to_file'},
4654                                                              hash_base=>$hash)},
4655                                               "blob");
4656                                 print " | " if ($has_history);
4657                         }
4658                         if ($has_history) {
4659                                 print $cgi->a({-href => href(action=>"history",
4660                                                              file_name=>$diff->{'to_file'},
4661                                                              hash_base=>$hash)},
4662                                               "history");
4663                         }
4664                         print "</td>\n";
4665
4666                         print "</tr>\n";
4667                         next; # instead of 'else' clause, to avoid extra indent
4668                 }
4669                 # else ordinary diff
4670
4671                 my ($to_mode_oct, $to_mode_str, $to_file_type);
4672                 my ($from_mode_oct, $from_mode_str, $from_file_type);
4673                 if ($diff->{'to_mode'} ne ('0' x 6)) {
4674                         $to_mode_oct = oct $diff->{'to_mode'};
4675                         if (S_ISREG($to_mode_oct)) { # only for regular file
4676                                 $to_mode_str = sprintf("%04o", $to_mode_oct & 0777); # permission bits
4677                         }
4678                         $to_file_type = file_type($diff->{'to_mode'});
4679                 }
4680                 if ($diff->{'from_mode'} ne ('0' x 6)) {
4681                         $from_mode_oct = oct $diff->{'from_mode'};
4682                         if (S_ISREG($from_mode_oct)) { # only for regular file
4683                                 $from_mode_str = sprintf("%04o", $from_mode_oct & 0777); # permission bits
4684                         }
4685                         $from_file_type = file_type($diff->{'from_mode'});
4686                 }
4687
4688                 if ($diff->{'status'} eq "A") { # created
4689                         my $mode_chng = "<span class=\"file_status new\">[new $to_file_type";
4690                         $mode_chng   .= " with mode: $to_mode_str" if $to_mode_str;
4691                         $mode_chng   .= "]</span>";
4692                         print "<td>";
4693                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4694                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4695                                       -class => "list"}, esc_path($diff->{'file'}));
4696                         print "</td>\n";
4697                         print "<td>$mode_chng</td>\n";
4698                         print "<td class=\"link\">";
4699                         if ($action eq 'commitdiff') {
4700                                 # link to patch
4701                                 $patchno++;
4702                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4703                                               "patch") .
4704                                       " | ";
4705                         }
4706                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4707                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4708                                       "blob");
4709                         print "</td>\n";
4710
4711                 } elsif ($diff->{'status'} eq "D") { # deleted
4712                         my $mode_chng = "<span class=\"file_status deleted\">[deleted $from_file_type]</span>";
4713                         print "<td>";
4714                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4715                                                      hash_base=>$parent, file_name=>$diff->{'file'}),
4716                                        -class => "list"}, esc_path($diff->{'file'}));
4717                         print "</td>\n";
4718                         print "<td>$mode_chng</td>\n";
4719                         print "<td class=\"link\">";
4720                         if ($action eq 'commitdiff') {
4721                                 # link to patch
4722                                 $patchno++;
4723                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4724                                               "patch") .
4725                                       " | ";
4726                         }
4727                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4728                                                      hash_base=>$parent, file_name=>$diff->{'file'})},
4729                                       "blob") . " | ";
4730                         if ($have_blame) {
4731                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$parent,
4732                                                              file_name=>$diff->{'file'})},
4733                                               "blame") . " | ";
4734                         }
4735                         print $cgi->a({-href => href(action=>"history", hash_base=>$parent,
4736                                                      file_name=>$diff->{'file'})},
4737                                       "history");
4738                         print "</td>\n";
4739
4740                 } elsif ($diff->{'status'} eq "M" || $diff->{'status'} eq "T") { # modified, or type changed
4741                         my $mode_chnge = "";
4742                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4743                                 $mode_chnge = "<span class=\"file_status mode_chnge\">[changed";
4744                                 if ($from_file_type ne $to_file_type) {
4745                                         $mode_chnge .= " from $from_file_type to $to_file_type";
4746                                 }
4747                                 if (($from_mode_oct & 0777) != ($to_mode_oct & 0777)) {
4748                                         if ($from_mode_str && $to_mode_str) {
4749                                                 $mode_chnge .= " mode: $from_mode_str->$to_mode_str";
4750                                         } elsif ($to_mode_str) {
4751                                                 $mode_chnge .= " mode: $to_mode_str";
4752                                         }
4753                                 }
4754                                 $mode_chnge .= "]</span>\n";
4755                         }
4756                         print "<td>";
4757                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4758                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4759                                       -class => "list"}, esc_path($diff->{'file'}));
4760                         print "</td>\n";
4761                         print "<td>$mode_chnge</td>\n";
4762                         print "<td class=\"link\">";
4763                         if ($action eq 'commitdiff') {
4764                                 # link to patch
4765                                 $patchno++;
4766                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4767                                               "patch") .
4768                                       " | ";
4769                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4770                                 # "commit" view and modified file (not onlu mode changed)
4771                                 print $cgi->a({-href => href(action=>"blobdiff",
4772                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4773                                                              hash_base=>$hash, hash_parent_base=>$parent,
4774                                                              file_name=>$diff->{'file'})},
4775                                               "diff") .
4776                                       " | ";
4777                         }
4778                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4779                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4780                                        "blob") . " | ";
4781                         if ($have_blame) {
4782                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4783                                                              file_name=>$diff->{'file'})},
4784                                               "blame") . " | ";
4785                         }
4786                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4787                                                      file_name=>$diff->{'file'})},
4788                                       "history");
4789                         print "</td>\n";
4790
4791                 } elsif ($diff->{'status'} eq "R" || $diff->{'status'} eq "C") { # renamed or copied
4792                         my %status_name = ('R' => 'moved', 'C' => 'copied');
4793                         my $nstatus = $status_name{$diff->{'status'}};
4794                         my $mode_chng = "";
4795                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4796                                 # mode also for directories, so we cannot use $to_mode_str
4797                                 $mode_chng = sprintf(", mode: %04o", $to_mode_oct & 0777);
4798                         }
4799                         print "<td>" .
4800                               $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
4801                                                      hash=>$diff->{'to_id'}, file_name=>$diff->{'to_file'}),
4802                                       -class => "list"}, esc_path($diff->{'to_file'})) . "</td>\n" .
4803                               "<td><span class=\"file_status $nstatus\">[$nstatus from " .
4804                               $cgi->a({-href => href(action=>"blob", hash_base=>$parent,
4805                                                      hash=>$diff->{'from_id'}, file_name=>$diff->{'from_file'}),
4806                                       -class => "list"}, esc_path($diff->{'from_file'})) .
4807                               " with " . (int $diff->{'similarity'}) . "% similarity$mode_chng]</span></td>\n" .
4808                               "<td class=\"link\">";
4809                         if ($action eq 'commitdiff') {
4810                                 # link to patch
4811                                 $patchno++;
4812                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4813                                               "patch") .
4814                                       " | ";
4815                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4816                                 # "commit" view and modified file (not only pure rename or copy)
4817                                 print $cgi->a({-href => href(action=>"blobdiff",
4818                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4819                                                              hash_base=>$hash, hash_parent_base=>$parent,
4820                                                              file_name=>$diff->{'to_file'}, file_parent=>$diff->{'from_file'})},
4821                                               "diff") .
4822                                       " | ";
4823                         }
4824                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4825                                                      hash_base=>$parent, file_name=>$diff->{'to_file'})},
4826                                       "blob") . " | ";
4827                         if ($have_blame) {
4828                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4829                                                              file_name=>$diff->{'to_file'})},
4830                                               "blame") . " | ";
4831                         }
4832                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4833                                                     file_name=>$diff->{'to_file'})},
4834                                       "history");
4835                         print "</td>\n";
4836
4837                 } # we should not encounter Unmerged (U) or Unknown (X) status
4838                 print "</tr>\n";
4839         }
4840         print "</tbody>" if $has_header;
4841         print "</table>\n";
4842 }
4843
4844 sub git_patchset_body {
4845         my ($fd, $difftree, $hash, @hash_parents) = @_;
4846         my ($hash_parent) = $hash_parents[0];
4847
4848         my $is_combined = (@hash_parents > 1);
4849         my $patch_idx = 0;
4850         my $patch_number = 0;
4851         my $patch_line;
4852         my $diffinfo;
4853         my $to_name;
4854         my (%from, %to);
4855
4856         print "<div class=\"patchset\">\n";
4857
4858         # skip to first patch
4859         while ($patch_line = <$fd>) {
4860                 chomp $patch_line;
4861
4862                 last if ($patch_line =~ m/^diff /);
4863         }
4864
4865  PATCH:
4866         while ($patch_line) {
4867
4868                 # parse "git diff" header line
4869                 if ($patch_line =~ m/^diff --git (\"(?:[^\\\"]*(?:\\.[^\\\"]*)*)\"|[^ "]*) (.*)$/) {
4870                         # $1 is from_name, which we do not use
4871                         $to_name = unquote($2);
4872                         $to_name =~ s!^b/!!;
4873                 } elsif ($patch_line =~ m/^diff --(cc|combined) ("?.*"?)$/) {
4874                         # $1 is 'cc' or 'combined', which we do not use
4875                         $to_name = unquote($2);
4876                 } else {
4877                         $to_name = undef;
4878                 }
4879
4880                 # check if current patch belong to current raw line
4881                 # and parse raw git-diff line if needed
4882                 if (is_patch_split($diffinfo, { 'to_file' => $to_name })) {
4883                         # this is continuation of a split patch
4884                         print "<div class=\"patch cont\">\n";
4885                 } else {
4886                         # advance raw git-diff output if needed
4887                         $patch_idx++ if defined $diffinfo;
4888
4889                         # read and prepare patch information
4890                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
4891
4892                         # compact combined diff output can have some patches skipped
4893                         # find which patch (using pathname of result) we are at now;
4894                         if ($is_combined) {
4895                                 while ($to_name ne $diffinfo->{'to_file'}) {
4896                                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
4897                                               format_diff_cc_simplified($diffinfo, @hash_parents) .
4898                                               "</div>\n";  # class="patch"
4899
4900                                         $patch_idx++;
4901                                         $patch_number++;
4902
4903                                         last if $patch_idx > $#$difftree;
4904                                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
4905                                 }
4906                         }
4907
4908                         # modifies %from, %to hashes
4909                         parse_from_to_diffinfo($diffinfo, \%from, \%to, @hash_parents);
4910
4911                         # this is first patch for raw difftree line with $patch_idx index
4912                         # we index @$difftree array from 0, but number patches from 1
4913                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n";
4914                 }
4915
4916                 # git diff header
4917                 #assert($patch_line =~ m/^diff /) if DEBUG;
4918                 #assert($patch_line !~ m!$/$!) if DEBUG; # is chomp-ed
4919                 $patch_number++;
4920                 # print "git diff" header
4921                 print format_git_diff_header_line($patch_line, $diffinfo,
4922                                                   \%from, \%to);
4923
4924                 # print extended diff header
4925                 print "<div class=\"diff extended_header\">\n";
4926         EXTENDED_HEADER:
4927                 while ($patch_line = <$fd>) {
4928                         chomp $patch_line;
4929
4930                         last EXTENDED_HEADER if ($patch_line =~ m/^--- |^diff /);
4931
4932                         print format_extended_diff_header_line($patch_line, $diffinfo,
4933                                                                \%from, \%to);
4934                 }
4935                 print "</div>\n"; # class="diff extended_header"
4936
4937                 # from-file/to-file diff header
4938                 if (! $patch_line) {
4939                         print "</div>\n"; # class="patch"
4940                         last PATCH;
4941                 }
4942                 next PATCH if ($patch_line =~ m/^diff /);
4943                 #assert($patch_line =~ m/^---/) if DEBUG;
4944
4945                 my $last_patch_line = $patch_line;
4946                 $patch_line = <$fd>;
4947                 chomp $patch_line;
4948                 #assert($patch_line =~ m/^\+\+\+/) if DEBUG;
4949
4950                 print format_diff_from_to_header($last_patch_line, $patch_line,
4951                                                  $diffinfo, \%from, \%to,
4952                                                  @hash_parents);
4953
4954                 # the patch itself
4955         LINE:
4956                 while ($patch_line = <$fd>) {
4957                         chomp $patch_line;
4958
4959                         next PATCH if ($patch_line =~ m/^diff /);
4960
4961                         print format_diff_line($patch_line, \%from, \%to);
4962                 }
4963
4964         } continue {
4965                 print "</div>\n"; # class="patch"
4966         }
4967
4968         # for compact combined (--cc) format, with chunk and patch simplification
4969         # the patchset might be empty, but there might be unprocessed raw lines
4970         for (++$patch_idx if $patch_number > 0;
4971              $patch_idx < @$difftree;
4972              ++$patch_idx) {
4973                 # read and prepare patch information
4974                 $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
4975
4976                 # generate anchor for "patch" links in difftree / whatchanged part
4977                 print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
4978                       format_diff_cc_simplified($diffinfo, @hash_parents) .
4979                       "</div>\n";  # class="patch"
4980
4981                 $patch_number++;
4982         }
4983
4984         if ($patch_number == 0) {
4985                 if (@hash_parents > 1) {
4986                         print "<div class=\"diff nodifferences\">Trivial merge</div>\n";
4987                 } else {
4988                         print "<div class=\"diff nodifferences\">No differences found</div>\n";
4989                 }
4990         }
4991
4992         print "</div>\n"; # class="patchset"
4993 }
4994
4995 # . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
4996
4997 # fills project list info (age, description, owner, category, forks)
4998 # for each project in the list, removing invalid projects from
4999 # returned list
5000 # NOTE: modifies $projlist, but does not remove entries from it
5001 sub fill_project_list_info {
5002         my $projlist = shift;
5003         my @projects;
5004
5005         my $show_ctags = gitweb_check_feature('ctags');
5006  PROJECT:
5007         foreach my $pr (@$projlist) {
5008                 my (@activity) = git_get_last_activity($pr->{'path'});
5009                 unless (@activity) {
5010                         next PROJECT;
5011                 }
5012                 ($pr->{'age'}, $pr->{'age_string'}) = @activity;
5013                 if (!defined $pr->{'descr'}) {
5014                         my $descr = git_get_project_description($pr->{'path'}) || "";
5015                         $descr = to_utf8($descr);
5016                         $pr->{'descr_long'} = $descr;
5017                         $pr->{'descr'} = chop_str($descr, $projects_list_description_width, 5);
5018                 }
5019                 if (!defined $pr->{'owner'}) {
5020                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}") || "";
5021                 }
5022                 if ($show_ctags) {
5023                         $pr->{'ctags'} = git_get_project_ctags($pr->{'path'});
5024                 }
5025                 if ($projects_list_group_categories && !defined $pr->{'category'}) {
5026                         my $cat = git_get_project_category($pr->{'path'}) ||
5027                                                            $project_list_default_category;
5028                         $pr->{'category'} = to_utf8($cat);
5029                 }
5030
5031                 push @projects, $pr;
5032         }
5033
5034         return @projects;
5035 }
5036
5037 sub sort_projects_list {
5038         my ($projlist, $order) = @_;
5039         my @projects;
5040
5041         my %order_info = (
5042                 project => { key => 'path', type => 'str' },
5043                 descr => { key => 'descr_long', type => 'str' },
5044                 owner => { key => 'owner', type => 'str' },
5045                 age => { key => 'age', type => 'num' }
5046         );
5047         my $oi = $order_info{$order};
5048         return @$projlist unless defined $oi;
5049         if ($oi->{'type'} eq 'str') {
5050                 @projects = sort {$a->{$oi->{'key'}} cmp $b->{$oi->{'key'}}} @$projlist;
5051         } else {
5052                 @projects = sort {$a->{$oi->{'key'}} <=> $b->{$oi->{'key'}}} @$projlist;
5053         }
5054
5055         return @projects;
5056 }
5057
5058 # returns a hash of categories, containing the list of project
5059 # belonging to each category
5060 sub build_projlist_by_category {
5061         my ($projlist, $from, $to) = @_;
5062         my %categories;
5063
5064         $from = 0 unless defined $from;
5065         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5066
5067         for (my $i = $from; $i <= $to; $i++) {
5068                 my $pr = $projlist->[$i];
5069                 push @{$categories{ $pr->{'category'} }}, $pr;
5070         }
5071
5072         return wantarray ? %categories : \%categories;
5073 }
5074
5075 # print 'sort by' <th> element, generating 'sort by $name' replay link
5076 # if that order is not selected
5077 sub print_sort_th {
5078         print format_sort_th(@_);
5079 }
5080
5081 sub format_sort_th {
5082         my ($name, $order, $header) = @_;
5083         my $sort_th = "";
5084         $header ||= ucfirst($name);
5085
5086         if ($order eq $name) {
5087                 $sort_th .= "<th>$header</th>\n";
5088         } else {
5089                 $sort_th .= "<th>" .
5090                             $cgi->a({-href => href(-replay=>1, order=>$name),
5091                                      -class => "header"}, $header) .
5092                             "</th>\n";
5093         }
5094
5095         return $sort_th;
5096 }
5097
5098 sub git_project_list_rows {
5099         my ($projlist, $from, $to, $check_forks) = @_;
5100
5101         $from = 0 unless defined $from;
5102         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5103
5104         my $alternate = 1;
5105         for (my $i = $from; $i <= $to; $i++) {
5106                 my $pr = $projlist->[$i];
5107
5108                 if ($alternate) {
5109                         print "<tr class=\"dark\">\n";
5110                 } else {
5111                         print "<tr class=\"light\">\n";
5112                 }
5113                 $alternate ^= 1;
5114
5115                 if ($check_forks) {
5116                         print "<td>";
5117                         if ($pr->{'forks'}) {
5118                                 my $nforks = scalar @{$pr->{'forks'}};
5119                                 if ($nforks > 0) {
5120                                         print $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks"),
5121                                                        -title => "$nforks forks"}, "+");
5122                                 } else {
5123                                         print $cgi->span({-title => "$nforks forks"}, "+");
5124                                 }
5125                         }
5126                         print "</td>\n";
5127                 }
5128                 print "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5129                                         -class => "list"}, esc_html($pr->{'path'})) . "</td>\n" .
5130                       "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5131                                         -class => "list", -title => $pr->{'descr_long'}},
5132                                         esc_html($pr->{'descr'})) . "</td>\n" .
5133                       "<td><i>" . chop_and_escape_str($pr->{'owner'}, 15) . "</i></td>\n";
5134                 print "<td class=\"". age_class($pr->{'age'}) . "\">" .
5135                       (defined $pr->{'age_string'} ? $pr->{'age_string'} : "No commits") . "</td>\n" .
5136                       "<td class=\"link\">" .
5137                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary")}, "summary")   . " | " .
5138                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"shortlog")}, "shortlog") . " | " .
5139                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"log")}, "log") . " | " .
5140                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"tree")}, "tree") .
5141                       ($pr->{'forks'} ? " | " . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "forks") : '') .
5142                       "</td>\n" .
5143                       "</tr>\n";
5144         }
5145 }
5146
5147 sub git_project_list_body {
5148         # actually uses global variable $project
5149         my ($projlist, $order, $from, $to, $extra, $no_header) = @_;
5150         my @projects = @$projlist;
5151
5152         my $check_forks = gitweb_check_feature('forks');
5153         my $show_ctags  = gitweb_check_feature('ctags');
5154         my $tagfilter = $show_ctags ? $cgi->param('by_tag') : undef;
5155         $check_forks = undef
5156                 if ($tagfilter || $searchtext);
5157
5158         # filtering out forks before filling info allows to do less work
5159         @projects = filter_forks_from_projects_list(\@projects)
5160                 if ($check_forks);
5161         @projects = fill_project_list_info(\@projects);
5162         # searching projects require filling to be run before it
5163         @projects = search_projects_list(\@projects,
5164                                          'searchtext' => $searchtext,
5165                                          'tagfilter'  => $tagfilter)
5166                 if ($tagfilter || $searchtext);
5167
5168         $order ||= $default_projects_order;
5169         $from = 0 unless defined $from;
5170         $to = $#projects if (!defined $to || $#projects < $to);
5171
5172         # short circuit
5173         if ($from > $to) {
5174                 print "<center>\n".
5175                       "<b>No such projects found</b><br />\n".
5176                       "Click ".$cgi->a({-href=>href(project=>undef)},"here")." to view all projects<br />\n".
5177                       "</center>\n<br />\n";
5178                 return;
5179         }
5180
5181         @projects = sort_projects_list(\@projects, $order);
5182
5183         if ($show_ctags) {
5184                 my $ctags = git_gather_all_ctags(\@projects);
5185                 my $cloud = git_populate_project_tagcloud($ctags);
5186                 print git_show_project_tagcloud($cloud, 64);
5187         }
5188
5189         print "<table class=\"project_list\">\n";
5190         unless ($no_header) {
5191                 print "<tr>\n";
5192                 if ($check_forks) {
5193                         print "<th></th>\n";
5194                 }
5195                 print_sort_th('project', $order, 'Project');
5196                 print_sort_th('descr', $order, 'Description');
5197                 print_sort_th('owner', $order, 'Owner');
5198                 print_sort_th('age', $order, 'Last Change');
5199                 print "<th></th>\n" . # for links
5200                       "</tr>\n";
5201         }
5202
5203         if ($projects_list_group_categories) {
5204                 # only display categories with projects in the $from-$to window
5205                 @projects = sort {$a->{'category'} cmp $b->{'category'}} @projects[$from..$to];
5206                 my %categories = build_projlist_by_category(\@projects, $from, $to);
5207                 foreach my $cat (sort keys %categories) {
5208                         unless ($cat eq "") {
5209                                 print "<tr>\n";
5210                                 if ($check_forks) {
5211                                         print "<td></td>\n";
5212                                 }
5213                                 print "<td class=\"category\" colspan=\"5\">".esc_html($cat)."</td>\n";
5214                                 print "</tr>\n";
5215                         }
5216
5217                         git_project_list_rows($categories{$cat}, undef, undef, $check_forks);
5218                 }
5219         } else {
5220                 git_project_list_rows(\@projects, $from, $to, $check_forks);
5221         }
5222
5223         if (defined $extra) {
5224                 print "<tr>\n";
5225                 if ($check_forks) {
5226                         print "<td></td>\n";
5227                 }
5228                 print "<td colspan=\"5\">$extra</td>\n" .
5229                       "</tr>\n";
5230         }
5231         print "</table>\n";
5232 }
5233
5234 sub git_log_body {
5235         # uses global variable $project
5236         my ($commitlist, $from, $to, $refs, $extra) = @_;
5237
5238         $from = 0 unless defined $from;
5239         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5240
5241         for (my $i = 0; $i <= $to; $i++) {
5242                 my %co = %{$commitlist->[$i]};
5243                 next if !%co;
5244                 my $commit = $co{'id'};
5245                 my $ref = format_ref_marker($refs, $commit);
5246                 git_print_header_div('commit',
5247                                "<span class=\"age\">$co{'age_string'}</span>" .
5248                                esc_html($co{'title'}) . $ref,
5249                                $commit);
5250                 print "<div class=\"title_text\">\n" .
5251                       "<div class=\"log_link\">\n" .
5252                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") .
5253                       " | " .
5254                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") .
5255                       " | " .
5256                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree") .
5257                       "<br/>\n" .
5258                       "</div>\n";
5259                       git_print_authorship(\%co, -tag => 'span');
5260                       print "<br/>\n</div>\n";
5261
5262                 print "<div class=\"log_body\">\n";
5263                 git_print_log($co{'comment'}, -final_empty_line=> 1);
5264                 print "</div>\n";
5265         }
5266         if ($extra) {
5267                 print "<div class=\"page_nav\">\n";
5268                 print "$extra\n";
5269                 print "</div>\n";
5270         }
5271 }
5272
5273 sub git_shortlog_body {
5274         # uses global variable $project
5275         my ($commitlist, $from, $to, $refs, $extra) = @_;
5276
5277         $from = 0 unless defined $from;
5278         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5279
5280         print "<table class=\"shortlog\">\n";
5281         my $alternate = 1;
5282         for (my $i = $from; $i <= $to; $i++) {
5283                 my %co = %{$commitlist->[$i]};
5284                 my $commit = $co{'id'};
5285                 my $ref = format_ref_marker($refs, $commit);
5286                 if ($alternate) {
5287                         print "<tr class=\"dark\">\n";
5288                 } else {
5289                         print "<tr class=\"light\">\n";
5290                 }
5291                 $alternate ^= 1;
5292                 # git_summary() used print "<td><i>$co{'age_string'}</i></td>\n" .
5293                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5294                       format_author_html('td', \%co, 10) . "<td>";
5295                 print format_subject_html($co{'title'}, $co{'title_short'},
5296                                           href(action=>"commit", hash=>$commit), $ref);
5297                 print "</td>\n" .
5298                       "<td class=\"link\">" .
5299                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") . " | " .
5300                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") . " | " .
5301                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree");
5302                 my $snapshot_links = format_snapshot_links($commit);
5303                 if (defined $snapshot_links) {
5304                         print " | " . $snapshot_links;
5305                 }
5306                 print "</td>\n" .
5307                       "</tr>\n";
5308         }
5309         if (defined $extra) {
5310                 print "<tr>\n" .
5311                       "<td colspan=\"4\">$extra</td>\n" .
5312                       "</tr>\n";
5313         }
5314         print "</table>\n";
5315 }
5316
5317 sub git_history_body {
5318         # Warning: assumes constant type (blob or tree) during history
5319         my ($commitlist, $from, $to, $refs, $extra,
5320             $file_name, $file_hash, $ftype) = @_;
5321
5322         $from = 0 unless defined $from;
5323         $to = $#{$commitlist} unless (defined $to && $to <= $#{$commitlist});
5324
5325         print "<table class=\"history\">\n";
5326         my $alternate = 1;
5327         for (my $i = $from; $i <= $to; $i++) {
5328                 my %co = %{$commitlist->[$i]};
5329                 if (!%co) {
5330                         next;
5331                 }
5332                 my $commit = $co{'id'};
5333
5334                 my $ref = format_ref_marker($refs, $commit);
5335
5336                 if ($alternate) {
5337                         print "<tr class=\"dark\">\n";
5338                 } else {
5339                         print "<tr class=\"light\">\n";
5340                 }
5341                 $alternate ^= 1;
5342                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5343         # shortlog:   format_author_html('td', \%co, 10)
5344                       format_author_html('td', \%co, 15, 3) . "<td>";
5345                 # originally git_history used chop_str($co{'title'}, 50)
5346                 print format_subject_html($co{'title'}, $co{'title_short'},
5347                                           href(action=>"commit", hash=>$commit), $ref);
5348                 print "</td>\n" .
5349                       "<td class=\"link\">" .
5350                       $cgi->a({-href => href(action=>$ftype, hash_base=>$commit, file_name=>$file_name)}, $ftype) . " | " .
5351                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff");
5352
5353                 if ($ftype eq 'blob') {
5354                         my $blob_current = $file_hash;
5355                         my $blob_parent  = git_get_hash_by_path($commit, $file_name);
5356                         if (defined $blob_current && defined $blob_parent &&
5357                                         $blob_current ne $blob_parent) {
5358                                 print " | " .
5359                                         $cgi->a({-href => href(action=>"blobdiff",
5360                                                                hash=>$blob_current, hash_parent=>$blob_parent,
5361                                                                hash_base=>$hash_base, hash_parent_base=>$commit,
5362                                                                file_name=>$file_name)},
5363                                                 "diff to current");
5364                         }
5365                 }
5366                 print "</td>\n" .
5367                       "</tr>\n";
5368         }
5369         if (defined $extra) {
5370                 print "<tr>\n" .
5371                       "<td colspan=\"4\">$extra</td>\n" .
5372                       "</tr>\n";
5373         }
5374         print "</table>\n";
5375 }
5376
5377 sub git_tags_body {
5378         # uses global variable $project
5379         my ($taglist, $from, $to, $extra) = @_;
5380         $from = 0 unless defined $from;
5381         $to = $#{$taglist} if (!defined $to || $#{$taglist} < $to);
5382
5383         print "<table class=\"tags\">\n";
5384         my $alternate = 1;
5385         for (my $i = $from; $i <= $to; $i++) {
5386                 my $entry = $taglist->[$i];
5387                 my %tag = %$entry;
5388                 my $comment = $tag{'subject'};
5389                 my $comment_short;
5390                 if (defined $comment) {
5391                         $comment_short = chop_str($comment, 30, 5);
5392                 }
5393                 if ($alternate) {
5394                         print "<tr class=\"dark\">\n";
5395                 } else {
5396                         print "<tr class=\"light\">\n";
5397                 }
5398                 $alternate ^= 1;
5399                 if (defined $tag{'age'}) {
5400                         print "<td><i>$tag{'age'}</i></td>\n";
5401                 } else {
5402                         print "<td></td>\n";
5403                 }
5404                 print "<td>" .
5405                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'}),
5406                                -class => "list name"}, esc_html($tag{'name'})) .
5407                       "</td>\n" .
5408                       "<td>";
5409                 if (defined $comment) {
5410                         print format_subject_html($comment, $comment_short,
5411                                                   href(action=>"tag", hash=>$tag{'id'}));
5412                 }
5413                 print "</td>\n" .
5414                       "<td class=\"selflink\">";
5415                 if ($tag{'type'} eq "tag") {
5416                         print $cgi->a({-href => href(action=>"tag", hash=>$tag{'id'})}, "tag");
5417                 } else {
5418                         print "&nbsp;";
5419                 }
5420                 print "</td>\n" .
5421                       "<td class=\"link\">" . " | " .
5422                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'})}, $tag{'reftype'});
5423                 if ($tag{'reftype'} eq "commit") {
5424                         print " | " . $cgi->a({-href => href(action=>"shortlog", hash=>$tag{'fullname'})}, "shortlog") .
5425                               " | " . $cgi->a({-href => href(action=>"log", hash=>$tag{'fullname'})}, "log");
5426                 } elsif ($tag{'reftype'} eq "blob") {
5427                         print " | " . $cgi->a({-href => href(action=>"blob_plain", hash=>$tag{'refid'})}, "raw");
5428                 }
5429                 print "</td>\n" .
5430                       "</tr>";
5431         }
5432         if (defined $extra) {
5433                 print "<tr>\n" .
5434                       "<td colspan=\"5\">$extra</td>\n" .
5435                       "</tr>\n";
5436         }
5437         print "</table>\n";
5438 }
5439
5440 sub git_heads_body {
5441         # uses global variable $project
5442         my ($headlist, $head, $from, $to, $extra) = @_;
5443         $from = 0 unless defined $from;
5444         $to = $#{$headlist} if (!defined $to || $#{$headlist} < $to);
5445
5446         print "<table class=\"heads\">\n";
5447         my $alternate = 1;
5448         for (my $i = $from; $i <= $to; $i++) {
5449                 my $entry = $headlist->[$i];
5450                 my %ref = %$entry;
5451                 my $curr = $ref{'id'} eq $head;
5452                 if ($alternate) {
5453                         print "<tr class=\"dark\">\n";
5454                 } else {
5455                         print "<tr class=\"light\">\n";
5456                 }
5457                 $alternate ^= 1;
5458                 print "<td><i>$ref{'age'}</i></td>\n" .
5459                       ($curr ? "<td class=\"current_head\">" : "<td>") .
5460                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'}),
5461                                -class => "list name"},esc_html($ref{'name'})) .
5462                       "</td>\n" .
5463                       "<td class=\"link\">" .
5464                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'})}, "shortlog") . " | " .
5465                       $cgi->a({-href => href(action=>"log", hash=>$ref{'fullname'})}, "log") . " | " .
5466                       $cgi->a({-href => href(action=>"tree", hash=>$ref{'fullname'}, hash_base=>$ref{'fullname'})}, "tree") .
5467                       "</td>\n" .
5468                       "</tr>";
5469         }
5470         if (defined $extra) {
5471                 print "<tr>\n" .
5472                       "<td colspan=\"3\">$extra</td>\n" .
5473                       "</tr>\n";
5474         }
5475         print "</table>\n";
5476 }
5477
5478 # Display a single remote block
5479 sub git_remote_block {
5480         my ($remote, $rdata, $limit, $head) = @_;
5481
5482         my $heads = $rdata->{'heads'};
5483         my $fetch = $rdata->{'fetch'};
5484         my $push = $rdata->{'push'};
5485
5486         my $urls_table = "<table class=\"projects_list\">\n" ;
5487
5488         if (defined $fetch) {
5489                 if ($fetch eq $push) {
5490                         $urls_table .= format_repo_url("URL", $fetch);
5491                 } else {
5492                         $urls_table .= format_repo_url("Fetch URL", $fetch);
5493                         $urls_table .= format_repo_url("Push URL", $push) if defined $push;
5494                 }
5495         } elsif (defined $push) {
5496                 $urls_table .= format_repo_url("Push URL", $push);
5497         } else {
5498                 $urls_table .= format_repo_url("", "No remote URL");
5499         }
5500
5501         $urls_table .= "</table>\n";
5502
5503         my $dots;
5504         if (defined $limit && $limit < @$heads) {
5505                 $dots = $cgi->a({-href => href(action=>"remotes", hash=>$remote)}, "...");
5506         }
5507
5508         print $urls_table;
5509         git_heads_body($heads, $head, 0, $limit, $dots);
5510 }
5511
5512 # Display a list of remote names with the respective fetch and push URLs
5513 sub git_remotes_list {
5514         my ($remotedata, $limit) = @_;
5515         print "<table class=\"heads\">\n";
5516         my $alternate = 1;
5517         my @remotes = sort keys %$remotedata;
5518
5519         my $limited = $limit && $limit < @remotes;
5520
5521         $#remotes = $limit - 1 if $limited;
5522
5523         while (my $remote = shift @remotes) {
5524                 my $rdata = $remotedata->{$remote};
5525                 my $fetch = $rdata->{'fetch'};
5526                 my $push = $rdata->{'push'};
5527                 if ($alternate) {
5528                         print "<tr class=\"dark\">\n";
5529                 } else {
5530                         print "<tr class=\"light\">\n";
5531                 }
5532                 $alternate ^= 1;
5533                 print "<td>" .
5534                       $cgi->a({-href=> href(action=>'remotes', hash=>$remote),
5535                                -class=> "list name"},esc_html($remote)) .
5536                       "</td>";
5537                 print "<td class=\"link\">" .
5538                       (defined $fetch ? $cgi->a({-href=> $fetch}, "fetch") : "fetch") .
5539                       " | " .
5540                       (defined $push ? $cgi->a({-href=> $push}, "push") : "push") .
5541                       "</td>";
5542
5543                 print "</tr>\n";
5544         }
5545
5546         if ($limited) {
5547                 print "<tr>\n" .
5548                       "<td colspan=\"3\">" .
5549                       $cgi->a({-href => href(action=>"remotes")}, "...") .
5550                       "</td>\n" . "</tr>\n";
5551         }
5552
5553         print "</table>";
5554 }
5555
5556 # Display remote heads grouped by remote, unless there are too many
5557 # remotes, in which case we only display the remote names
5558 sub git_remotes_body {
5559         my ($remotedata, $limit, $head) = @_;
5560         if ($limit and $limit < keys %$remotedata) {
5561                 git_remotes_list($remotedata, $limit);
5562         } else {
5563                 fill_remote_heads($remotedata);
5564                 while (my ($remote, $rdata) = each %$remotedata) {
5565                         git_print_section({-class=>"remote", -id=>$remote},
5566                                 ["remotes", $remote, $remote], sub {
5567                                         git_remote_block($remote, $rdata, $limit, $head);
5568                                 });
5569                 }
5570         }
5571 }
5572
5573 sub git_search_message {
5574         my %co = @_;
5575
5576         my $greptype;
5577         if ($searchtype eq 'commit') {
5578                 $greptype = "--grep=";
5579         } elsif ($searchtype eq 'author') {
5580                 $greptype = "--author=";
5581         } elsif ($searchtype eq 'committer') {
5582                 $greptype = "--committer=";
5583         }
5584         $greptype .= $searchtext;
5585         my @commitlist = parse_commits($hash, 101, (100 * $page), undef,
5586                                        $greptype, '--regexp-ignore-case',
5587                                        $search_use_regexp ? '--extended-regexp' : '--fixed-strings');
5588
5589         my $paging_nav = '';
5590         if ($page > 0) {
5591                 $paging_nav .=
5592                         $cgi->a({-href => href(-replay=>1, page=>undef)},
5593                                 "first") .
5594                         " &sdot; " .
5595                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
5596                                  -accesskey => "p", -title => "Alt-p"}, "prev");
5597         } else {
5598                 $paging_nav .= "first &sdot; prev";
5599         }
5600         my $next_link = '';
5601         if ($#commitlist >= 100) {
5602                 $next_link =
5603                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
5604                                  -accesskey => "n", -title => "Alt-n"}, "next");
5605                 $paging_nav .= " &sdot; $next_link";
5606         } else {
5607                 $paging_nav .= " &sdot; next";
5608         }
5609
5610         git_header_html();
5611
5612         git_print_page_nav('','', $hash,$co{'tree'},$hash, $paging_nav);
5613         git_print_header_div('commit', esc_html($co{'title'}), $hash);
5614         if ($page == 0 && !@commitlist) {
5615                 print "<p>No match.</p>\n";
5616         } else {
5617                 git_search_grep_body(\@commitlist, 0, 99, $next_link);
5618         }
5619
5620         git_footer_html();
5621 }
5622
5623 sub git_search_changes {
5624         my %co = @_;
5625
5626         local $/ = "\n";
5627         open my $fd, '-|', git_cmd(), '--no-pager', 'log', @diff_opts,
5628                 '--pretty=format:%H', '--no-abbrev', '--raw', "-S$searchtext",
5629                 ($search_use_regexp ? '--pickaxe-regex' : ())
5630                         or die_error(500, "Open git-log failed");
5631
5632         git_header_html();
5633
5634         git_print_page_nav('','', $hash,$co{'tree'},$hash);
5635         git_print_header_div('commit', esc_html($co{'title'}), $hash);
5636
5637         print "<table class=\"pickaxe search\">\n";
5638         my $alternate = 1;
5639         undef %co;
5640         my @files;
5641         while (my $line = <$fd>) {
5642                 chomp $line;
5643                 next unless $line;
5644
5645                 my %set = parse_difftree_raw_line($line);
5646                 if (defined $set{'commit'}) {
5647                         # finish previous commit
5648                         if (%co) {
5649                                 print "</td>\n" .
5650                                       "<td class=\"link\">" .
5651                                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
5652                                               "commit") .
5653                                       " | " .
5654                                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
5655                                                              hash_base=>$co{'id'})},
5656                                               "tree") .
5657                                       "</td>\n" .
5658                                       "</tr>\n";
5659                         }
5660
5661                         if ($alternate) {
5662                                 print "<tr class=\"dark\">\n";
5663                         } else {
5664                                 print "<tr class=\"light\">\n";
5665                         }
5666                         $alternate ^= 1;
5667                         %co = parse_commit($set{'commit'});
5668                         my $author = chop_and_escape_str($co{'author_name'}, 15, 5);
5669                         print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5670                               "<td><i>$author</i></td>\n" .
5671                               "<td>" .
5672                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
5673                                       -class => "list subject"},
5674                                       chop_and_escape_str($co{'title'}, 50) . "<br/>");
5675                 } elsif (defined $set{'to_id'}) {
5676                         next if ($set{'to_id'} =~ m/^0{40}$/);
5677
5678                         print $cgi->a({-href => href(action=>"blob", hash_base=>$co{'id'},
5679                                                      hash=>$set{'to_id'}, file_name=>$set{'to_file'}),
5680                                       -class => "list"},
5681                                       "<span class=\"match\">" . esc_path($set{'file'}) . "</span>") .
5682                               "<br/>\n";
5683                 }
5684         }
5685         close $fd;
5686
5687         # finish last commit (warning: repetition!)
5688         if (%co) {
5689                 print "</td>\n" .
5690                       "<td class=\"link\">" .
5691                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
5692                               "commit") .
5693                       " | " .
5694                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
5695                                              hash_base=>$co{'id'})},
5696                               "tree") .
5697                       "</td>\n" .
5698                       "</tr>\n";
5699         }
5700
5701         print "</table>\n";
5702
5703         git_footer_html();
5704 }
5705
5706 sub git_search_files {
5707         my %co = @_;
5708
5709         local $/ = "\n";
5710         open my $fd, "-|", git_cmd(), 'grep', '-n',
5711                 $search_use_regexp ? ('-E', '-i') : '-F',
5712                 $searchtext, $co{'tree'}
5713                         or die_error(500, "Open git-grep failed");
5714
5715         git_header_html();
5716
5717         git_print_page_nav('','', $hash,$co{'tree'},$hash);
5718         git_print_header_div('commit', esc_html($co{'title'}), $hash);
5719
5720         print "<table class=\"grep_search\">\n";
5721         my $alternate = 1;
5722         my $matches = 0;
5723         my $lastfile = '';
5724         while (my $line = <$fd>) {
5725                 chomp $line;
5726                 my ($file, $lno, $ltext, $binary);
5727                 last if ($matches++ > 1000);
5728                 if ($line =~ /^Binary file (.+) matches$/) {
5729                         $file = $1;
5730                         $binary = 1;
5731                 } else {
5732                         (undef, $file, $lno, $ltext) = split(/:/, $line, 4);
5733                 }
5734                 if ($file ne $lastfile) {
5735                         $lastfile and print "</td></tr>\n";
5736                         if ($alternate++) {
5737                                 print "<tr class=\"dark\">\n";
5738                         } else {
5739                                 print "<tr class=\"light\">\n";
5740                         }
5741                         print "<td class=\"list\">".
5742                                 $cgi->a({-href => href(action=>"blob", hash=>$co{'hash'},
5743                                                        file_name=>"$file"),
5744                                         -class => "list"}, esc_path($file));
5745                         print "</td><td>\n";
5746                         $lastfile = $file;
5747                 }
5748                 if ($binary) {
5749                         print "<div class=\"binary\">Binary file</div>\n";
5750                 } else {
5751                         $ltext = untabify($ltext);
5752                         if ($ltext =~ m/^(.*)($search_regexp)(.*)$/i) {
5753                                 $ltext = esc_html($1, -nbsp=>1);
5754                                 $ltext .= '<span class="match">';
5755                                 $ltext .= esc_html($2, -nbsp=>1);
5756                                 $ltext .= '</span>';
5757                                 $ltext .= esc_html($3, -nbsp=>1);
5758                         } else {
5759                                 $ltext = esc_html($ltext, -nbsp=>1);
5760                         }
5761                         print "<div class=\"pre\">" .
5762                                 $cgi->a({-href => href(action=>"blob", hash=>$co{'hash'},
5763                                                        file_name=>"$file").'#l'.$lno,
5764                                         -class => "linenr"}, sprintf('%4i', $lno))
5765                                 . ' ' .  $ltext . "</div>\n";
5766                 }
5767         }
5768         if ($lastfile) {
5769                 print "</td></tr>\n";
5770                 if ($matches > 1000) {
5771                         print "<div class=\"diff nodifferences\">Too many matches, listing trimmed</div>\n";
5772                 }
5773         } else {
5774                 print "<div class=\"diff nodifferences\">No matches found</div>\n";
5775         }
5776         close $fd;
5777
5778         print "</table>\n";
5779
5780         git_footer_html();
5781 }
5782
5783 sub git_search_grep_body {
5784         my ($commitlist, $from, $to, $extra) = @_;
5785         $from = 0 unless defined $from;
5786         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5787
5788         print "<table class=\"commit_search\">\n";
5789         my $alternate = 1;
5790         for (my $i = $from; $i <= $to; $i++) {
5791                 my %co = %{$commitlist->[$i]};
5792                 if (!%co) {
5793                         next;
5794                 }
5795                 my $commit = $co{'id'};
5796                 if ($alternate) {
5797                         print "<tr class=\"dark\">\n";
5798                 } else {
5799                         print "<tr class=\"light\">\n";
5800                 }
5801                 $alternate ^= 1;
5802                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5803                       format_author_html('td', \%co, 15, 5) .
5804                       "<td>" .
5805                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
5806                                -class => "list subject"},
5807                               chop_and_escape_str($co{'title'}, 50) . "<br/>");
5808                 my $comment = $co{'comment'};
5809                 foreach my $line (@$comment) {
5810                         if ($line =~ m/^(.*?)($search_regexp)(.*)$/i) {
5811                                 my ($lead, $match, $trail) = ($1, $2, $3);
5812                                 $match = chop_str($match, 70, 5, 'center');
5813                                 my $contextlen = int((80 - length($match))/2);
5814                                 $contextlen = 30 if ($contextlen > 30);
5815                                 $lead  = chop_str($lead,  $contextlen, 10, 'left');
5816                                 $trail = chop_str($trail, $contextlen, 10, 'right');
5817
5818                                 $lead  = esc_html($lead);
5819                                 $match = esc_html($match);
5820                                 $trail = esc_html($trail);
5821
5822                                 print "$lead<span class=\"match\">$match</span>$trail<br />";
5823                         }
5824                 }
5825                 print "</td>\n" .
5826                       "<td class=\"link\">" .
5827                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
5828                       " | " .
5829                       $cgi->a({-href => href(action=>"commitdiff", hash=>$co{'id'})}, "commitdiff") .
5830                       " | " .
5831                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
5832                 print "</td>\n" .
5833                       "</tr>\n";
5834         }
5835         if (defined $extra) {
5836                 print "<tr>\n" .
5837                       "<td colspan=\"3\">$extra</td>\n" .
5838                       "</tr>\n";
5839         }
5840         print "</table>\n";
5841 }
5842
5843 ## ======================================================================
5844 ## ======================================================================
5845 ## actions
5846
5847 sub git_project_list {
5848         my $order = $input_params{'order'};
5849         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
5850                 die_error(400, "Unknown order parameter");
5851         }
5852
5853         my @list = git_get_projects_list();
5854         if (!@list) {
5855                 die_error(404, "No projects found");
5856         }
5857
5858         git_header_html();
5859         if (defined $home_text && -f $home_text) {
5860                 print "<div class=\"index_include\">\n";
5861                 insert_file($home_text);
5862                 print "</div>\n";
5863         }
5864         print $cgi->startform(-method => "get") .
5865               "<p class=\"projsearch\">Search:\n" .
5866               $cgi->textfield(-name => "s", -value => $searchtext) . "\n" .
5867               "</p>" .
5868               $cgi->end_form() . "\n";
5869         git_project_list_body(\@list, $order);
5870         git_footer_html();
5871 }
5872
5873 sub git_forks {
5874         my $order = $input_params{'order'};
5875         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
5876                 die_error(400, "Unknown order parameter");
5877         }
5878
5879         my @list = git_get_projects_list($project);
5880         if (!@list) {
5881                 die_error(404, "No forks found");
5882         }
5883
5884         git_header_html();
5885         git_print_page_nav('','');
5886         git_print_header_div('summary', "$project forks");
5887         git_project_list_body(\@list, $order);
5888         git_footer_html();
5889 }
5890
5891 sub git_project_index {
5892         my @projects = git_get_projects_list();
5893         if (!@projects) {
5894                 die_error(404, "No projects found");
5895         }
5896
5897         print $cgi->header(
5898                 -type => 'text/plain',
5899                 -charset => 'utf-8',
5900                 -content_disposition => 'inline; filename="index.aux"');
5901
5902         foreach my $pr (@projects) {
5903                 if (!exists $pr->{'owner'}) {
5904                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}");
5905                 }
5906
5907                 my ($path, $owner) = ($pr->{'path'}, $pr->{'owner'});
5908                 # quote as in CGI::Util::encode, but keep the slash, and use '+' for ' '
5909                 $path  =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
5910                 $owner =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
5911                 $path  =~ s/ /\+/g;
5912                 $owner =~ s/ /\+/g;
5913
5914                 print "$path $owner\n";
5915         }
5916 }
5917
5918 sub git_summary {
5919         my $descr = git_get_project_description($project) || "none";
5920         my %co = parse_commit("HEAD");
5921         my %cd = %co ? parse_date($co{'committer_epoch'}, $co{'committer_tz'}) : ();
5922         my $head = $co{'id'};
5923         my $remote_heads = gitweb_check_feature('remote_heads');
5924
5925         my $owner = git_get_project_owner($project);
5926
5927         my $refs = git_get_references();
5928         # These get_*_list functions return one more to allow us to see if
5929         # there are more ...
5930         my @taglist  = git_get_tags_list(16);
5931         my @headlist = git_get_heads_list(16);
5932         my %remotedata = $remote_heads ? git_get_remotes_list() : ();
5933         my @forklist;
5934         my $check_forks = gitweb_check_feature('forks');
5935
5936         if ($check_forks) {
5937                 # find forks of a project
5938                 @forklist = git_get_projects_list($project);
5939                 # filter out forks of forks
5940                 @forklist = filter_forks_from_projects_list(\@forklist)
5941                         if (@forklist);
5942         }
5943
5944         git_header_html();
5945         git_print_page_nav('summary','', $head);
5946
5947         print "<div class=\"title\">&nbsp;</div>\n";
5948         print "<table class=\"projects_list\">\n" .
5949               "<tr id=\"metadata_desc\"><td>description</td><td>" . esc_html($descr) . "</td></tr>\n" .
5950               "<tr id=\"metadata_owner\"><td>owner</td><td>" . esc_html($owner) . "</td></tr>\n";
5951         if (defined $cd{'rfc2822'}) {
5952                 print "<tr id=\"metadata_lchange\"><td>last change</td>" .
5953                       "<td>".format_timestamp_html(\%cd)."</td></tr>\n";
5954         }
5955
5956         # use per project git URL list in $projectroot/$project/cloneurl
5957         # or make project git URL from git base URL and project name
5958         my $url_tag = "URL";
5959         my @url_list = git_get_project_url_list($project);
5960         @url_list = map { "$_/$project" } @git_base_url_list unless @url_list;
5961         foreach my $git_url (@url_list) {
5962                 next unless $git_url;
5963                 print format_repo_url($url_tag, $git_url);
5964                 $url_tag = "";
5965         }
5966
5967         # Tag cloud
5968         my $show_ctags = gitweb_check_feature('ctags');
5969         if ($show_ctags) {
5970                 my $ctags = git_get_project_ctags($project);
5971                 if (%$ctags) {
5972                         # without ability to add tags, don't show if there are none
5973                         my $cloud = git_populate_project_tagcloud($ctags);
5974                         print "<tr id=\"metadata_ctags\">" .
5975                               "<td>content tags</td>" .
5976                               "<td>".git_show_project_tagcloud($cloud, 48)."</td>" .
5977                               "</tr>\n";
5978                 }
5979         }
5980
5981         print "</table>\n";
5982
5983         # If XSS prevention is on, we don't include README.html.
5984         # TODO: Allow a readme in some safe format.
5985         if (!$prevent_xss && -s "$projectroot/$project/README.html") {
5986                 print "<div class=\"title\">readme</div>\n" .
5987                       "<div class=\"readme\">\n";
5988                 insert_file("$projectroot/$project/README.html");
5989                 print "\n</div>\n"; # class="readme"
5990         }
5991
5992         # we need to request one more than 16 (0..15) to check if
5993         # those 16 are all
5994         my @commitlist = $head ? parse_commits($head, 17) : ();
5995         if (@commitlist) {
5996                 git_print_header_div('shortlog');
5997                 git_shortlog_body(\@commitlist, 0, 15, $refs,
5998                                   $#commitlist <=  15 ? undef :
5999                                   $cgi->a({-href => href(action=>"shortlog")}, "..."));
6000         }
6001
6002         if (@taglist) {
6003                 git_print_header_div('tags');
6004                 git_tags_body(\@taglist, 0, 15,
6005                               $#taglist <=  15 ? undef :
6006                               $cgi->a({-href => href(action=>"tags")}, "..."));
6007         }
6008
6009         if (@headlist) {
6010                 git_print_header_div('heads');
6011                 git_heads_body(\@headlist, $head, 0, 15,
6012                                $#headlist <= 15 ? undef :
6013                                $cgi->a({-href => href(action=>"heads")}, "..."));
6014         }
6015
6016         if (%remotedata) {
6017                 git_print_header_div('remotes');
6018                 git_remotes_body(\%remotedata, 15, $head);
6019         }
6020
6021         if (@forklist) {
6022                 git_print_header_div('forks');
6023                 git_project_list_body(\@forklist, 'age', 0, 15,
6024                                       $#forklist <= 15 ? undef :
6025                                       $cgi->a({-href => href(action=>"forks")}, "..."),
6026                                       'no_header');
6027         }
6028
6029         git_footer_html();
6030 }
6031
6032 sub git_tag {
6033         my %tag = parse_tag($hash);
6034
6035         if (! %tag) {
6036                 die_error(404, "Unknown tag object");
6037         }
6038
6039         my $head = git_get_head_hash($project);
6040         git_header_html();
6041         git_print_page_nav('','', $head,undef,$head);
6042         git_print_header_div('commit', esc_html($tag{'name'}), $hash);
6043         print "<div class=\"title_text\">\n" .
6044               "<table class=\"object_header\">\n" .
6045               "<tr>\n" .
6046               "<td>object</td>\n" .
6047               "<td>" . $cgi->a({-class => "list", -href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6048                                $tag{'object'}) . "</td>\n" .
6049               "<td class=\"link\">" . $cgi->a({-href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6050                                               $tag{'type'}) . "</td>\n" .
6051               "</tr>\n";
6052         if (defined($tag{'author'})) {
6053                 git_print_authorship_rows(\%tag, 'author');
6054         }
6055         print "</table>\n\n" .
6056               "</div>\n";
6057         print "<div class=\"page_body\">";
6058         my $comment = $tag{'comment'};
6059         foreach my $line (@$comment) {
6060                 chomp $line;
6061                 print esc_html($line, -nbsp=>1) . "<br/>\n";
6062         }
6063         print "</div>\n";
6064         git_footer_html();
6065 }
6066
6067 sub git_blame_common {
6068         my $format = shift || 'porcelain';
6069         if ($format eq 'porcelain' && $cgi->param('js')) {
6070                 $format = 'incremental';
6071                 $action = 'blame_incremental'; # for page title etc
6072         }
6073
6074         # permissions
6075         gitweb_check_feature('blame')
6076                 or die_error(403, "Blame view not allowed");
6077
6078         # error checking
6079         die_error(400, "No file name given") unless $file_name;
6080         $hash_base ||= git_get_head_hash($project);
6081         die_error(404, "Couldn't find base commit") unless $hash_base;
6082         my %co = parse_commit($hash_base)
6083                 or die_error(404, "Commit not found");
6084         my $ftype = "blob";
6085         if (!defined $hash) {
6086                 $hash = git_get_hash_by_path($hash_base, $file_name, "blob")
6087                         or die_error(404, "Error looking up file");
6088         } else {
6089                 $ftype = git_get_type($hash);
6090                 if ($ftype !~ "blob") {
6091                         die_error(400, "Object is not a blob");
6092                 }
6093         }
6094
6095         my $fd;
6096         if ($format eq 'incremental') {
6097                 # get file contents (as base)
6098                 open $fd, "-|", git_cmd(), 'cat-file', 'blob', $hash
6099                         or die_error(500, "Open git-cat-file failed");
6100         } elsif ($format eq 'data') {
6101                 # run git-blame --incremental
6102                 open $fd, "-|", git_cmd(), "blame", "--incremental",
6103                         $hash_base, "--", $file_name
6104                         or die_error(500, "Open git-blame --incremental failed");
6105         } else {
6106                 # run git-blame --porcelain
6107                 open $fd, "-|", git_cmd(), "blame", '-p',
6108                         $hash_base, '--', $file_name
6109                         or die_error(500, "Open git-blame --porcelain failed");
6110         }
6111
6112         # incremental blame data returns early
6113         if ($format eq 'data') {
6114                 print $cgi->header(
6115                         -type=>"text/plain", -charset => "utf-8",
6116                         -status=> "200 OK");
6117                 local $| = 1; # output autoflush
6118                 print while <$fd>;
6119                 close $fd
6120                         or print "ERROR $!\n";
6121
6122                 print 'END';
6123                 if (defined $t0 && gitweb_check_feature('timed')) {
6124                         print ' '.
6125                               tv_interval($t0, [ gettimeofday() ]).
6126                               ' '.$number_of_git_cmds;
6127                 }
6128                 print "\n";
6129
6130                 return;
6131         }
6132
6133         # page header
6134         git_header_html();
6135         my $formats_nav =
6136                 $cgi->a({-href => href(action=>"blob", -replay=>1)},
6137                         "blob") .
6138                 " | ";
6139         if ($format eq 'incremental') {
6140                 $formats_nav .=
6141                         $cgi->a({-href => href(action=>"blame", javascript=>0, -replay=>1)},
6142                                 "blame") . " (non-incremental)";
6143         } else {
6144                 $formats_nav .=
6145                         $cgi->a({-href => href(action=>"blame_incremental", -replay=>1)},
6146                                 "blame") . " (incremental)";
6147         }
6148         $formats_nav .=
6149                 " | " .
6150                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6151                         "history") .
6152                 " | " .
6153                 $cgi->a({-href => href(action=>$action, file_name=>$file_name)},
6154                         "HEAD");
6155         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6156         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6157         git_print_page_path($file_name, $ftype, $hash_base);
6158
6159         # page body
6160         if ($format eq 'incremental') {
6161                 print "<noscript>\n<div class=\"error\"><center><b>\n".
6162                       "This page requires JavaScript to run.\n Use ".
6163                       $cgi->a({-href => href(action=>'blame',javascript=>0,-replay=>1)},
6164                               'this page').
6165                       " instead.\n".
6166                       "</b></center></div>\n</noscript>\n";
6167
6168                 print qq!<div id="progress_bar" style="width: 100%; background-color: yellow"></div>\n!;
6169         }
6170
6171         print qq!<div class="page_body">\n!;
6172         print qq!<div id="progress_info">... / ...</div>\n!
6173                 if ($format eq 'incremental');
6174         print qq!<table id="blame_table" class="blame" width="100%">\n!.
6175               #qq!<col width="5.5em" /><col width="2.5em" /><col width="*" />\n!.
6176               qq!<thead>\n!.
6177               qq!<tr><th>Commit</th><th>Line</th><th>Data</th></tr>\n!.
6178               qq!</thead>\n!.
6179               qq!<tbody>\n!;
6180
6181         my @rev_color = qw(light dark);
6182         my $num_colors = scalar(@rev_color);
6183         my $current_color = 0;
6184
6185         if ($format eq 'incremental') {
6186                 my $color_class = $rev_color[$current_color];
6187
6188                 #contents of a file
6189                 my $linenr = 0;
6190         LINE:
6191                 while (my $line = <$fd>) {
6192                         chomp $line;
6193                         $linenr++;
6194
6195                         print qq!<tr id="l$linenr" class="$color_class">!.
6196                               qq!<td class="sha1"><a href=""> </a></td>!.
6197                               qq!<td class="linenr">!.
6198                               qq!<a class="linenr" href="">$linenr</a></td>!;
6199                         print qq!<td class="pre">! . esc_html($line) . "</td>\n";
6200                         print qq!</tr>\n!;
6201                 }
6202
6203         } else { # porcelain, i.e. ordinary blame
6204                 my %metainfo = (); # saves information about commits
6205
6206                 # blame data
6207         LINE:
6208                 while (my $line = <$fd>) {
6209                         chomp $line;
6210                         # the header: <SHA-1> <src lineno> <dst lineno> [<lines in group>]
6211                         # no <lines in group> for subsequent lines in group of lines
6212                         my ($full_rev, $orig_lineno, $lineno, $group_size) =
6213                            ($line =~ /^([0-9a-f]{40}) (\d+) (\d+)(?: (\d+))?$/);
6214                         if (!exists $metainfo{$full_rev}) {
6215                                 $metainfo{$full_rev} = { 'nprevious' => 0 };
6216                         }
6217                         my $meta = $metainfo{$full_rev};
6218                         my $data;
6219                         while ($data = <$fd>) {
6220                                 chomp $data;
6221                                 last if ($data =~ s/^\t//); # contents of line
6222                                 if ($data =~ /^(\S+)(?: (.*))?$/) {
6223                                         $meta->{$1} = $2 unless exists $meta->{$1};
6224                                 }
6225                                 if ($data =~ /^previous /) {
6226                                         $meta->{'nprevious'}++;
6227                                 }
6228                         }
6229                         my $short_rev = substr($full_rev, 0, 8);
6230                         my $author = $meta->{'author'};
6231                         my %date =
6232                                 parse_date($meta->{'author-time'}, $meta->{'author-tz'});
6233                         my $date = $date{'iso-tz'};
6234                         if ($group_size) {
6235                                 $current_color = ($current_color + 1) % $num_colors;
6236                         }
6237                         my $tr_class = $rev_color[$current_color];
6238                         $tr_class .= ' boundary' if (exists $meta->{'boundary'});
6239                         $tr_class .= ' no-previous' if ($meta->{'nprevious'} == 0);
6240                         $tr_class .= ' multiple-previous' if ($meta->{'nprevious'} > 1);
6241                         print "<tr id=\"l$lineno\" class=\"$tr_class\">\n";
6242                         if ($group_size) {
6243                                 print "<td class=\"sha1\"";
6244                                 print " title=\"". esc_html($author) . ", $date\"";
6245                                 print " rowspan=\"$group_size\"" if ($group_size > 1);
6246                                 print ">";
6247                                 print $cgi->a({-href => href(action=>"commit",
6248                                                              hash=>$full_rev,
6249                                                              file_name=>$file_name)},
6250                                               esc_html($short_rev));
6251                                 if ($group_size >= 2) {
6252                                         my @author_initials = ($author =~ /\b([[:upper:]])\B/g);
6253                                         if (@author_initials) {
6254                                                 print "<br />" .
6255                                                       esc_html(join('', @author_initials));
6256                                                 #           or join('.', ...)
6257                                         }
6258                                 }
6259                                 print "</td>\n";
6260                         }
6261                         # 'previous' <sha1 of parent commit> <filename at commit>
6262                         if (exists $meta->{'previous'} &&
6263                             $meta->{'previous'} =~ /^([a-fA-F0-9]{40}) (.*)$/) {
6264                                 $meta->{'parent'} = $1;
6265                                 $meta->{'file_parent'} = unquote($2);
6266                         }
6267                         my $linenr_commit =
6268                                 exists($meta->{'parent'}) ?
6269                                 $meta->{'parent'} : $full_rev;
6270                         my $linenr_filename =
6271                                 exists($meta->{'file_parent'}) ?
6272                                 $meta->{'file_parent'} : unquote($meta->{'filename'});
6273                         my $blamed = href(action => 'blame',
6274                                           file_name => $linenr_filename,
6275                                           hash_base => $linenr_commit);
6276                         print "<td class=\"linenr\">";
6277                         print $cgi->a({ -href => "$blamed#l$orig_lineno",
6278                                         -class => "linenr" },
6279                                       esc_html($lineno));
6280                         print "</td>";
6281                         print "<td class=\"pre\">" . esc_html($data) . "</td>\n";
6282                         print "</tr>\n";
6283                 } # end while
6284
6285         }
6286
6287         # footer
6288         print "</tbody>\n".
6289               "</table>\n"; # class="blame"
6290         print "</div>\n";   # class="blame_body"
6291         close $fd
6292                 or print "Reading blob failed\n";
6293
6294         git_footer_html();
6295 }
6296
6297 sub git_blame {
6298         git_blame_common();
6299 }
6300
6301 sub git_blame_incremental {
6302         git_blame_common('incremental');
6303 }
6304
6305 sub git_blame_data {
6306         git_blame_common('data');
6307 }
6308
6309 sub git_tags {
6310         my $head = git_get_head_hash($project);
6311         git_header_html();
6312         git_print_page_nav('','', $head,undef,$head,format_ref_views('tags'));
6313         git_print_header_div('summary', $project);
6314
6315         my @tagslist = git_get_tags_list();
6316         if (@tagslist) {
6317                 git_tags_body(\@tagslist);
6318         }
6319         git_footer_html();
6320 }
6321
6322 sub git_heads {
6323         my $head = git_get_head_hash($project);
6324         git_header_html();
6325         git_print_page_nav('','', $head,undef,$head,format_ref_views('heads'));
6326         git_print_header_div('summary', $project);
6327
6328         my @headslist = git_get_heads_list();
6329         if (@headslist) {
6330                 git_heads_body(\@headslist, $head);
6331         }
6332         git_footer_html();
6333 }
6334
6335 # used both for single remote view and for list of all the remotes
6336 sub git_remotes {
6337         gitweb_check_feature('remote_heads')
6338                 or die_error(403, "Remote heads view is disabled");
6339
6340         my $head = git_get_head_hash($project);
6341         my $remote = $input_params{'hash'};
6342
6343         my $remotedata = git_get_remotes_list($remote);
6344         die_error(500, "Unable to get remote information") unless defined $remotedata;
6345
6346         unless (%$remotedata) {
6347                 die_error(404, defined $remote ?
6348                         "Remote $remote not found" :
6349                         "No remotes found");
6350         }
6351
6352         git_header_html(undef, undef, -action_extra => $remote);
6353         git_print_page_nav('', '',  $head, undef, $head,
6354                 format_ref_views($remote ? '' : 'remotes'));
6355
6356         fill_remote_heads($remotedata);
6357         if (defined $remote) {
6358                 git_print_header_div('remotes', "$remote remote for $project");
6359                 git_remote_block($remote, $remotedata->{$remote}, undef, $head);
6360         } else {
6361                 git_print_header_div('summary', "$project remotes");
6362                 git_remotes_body($remotedata, undef, $head);
6363         }
6364
6365         git_footer_html();
6366 }
6367
6368 sub git_blob_plain {
6369         my $type = shift;
6370         my $expires;
6371
6372         if (!defined $hash) {
6373                 if (defined $file_name) {
6374                         my $base = $hash_base || git_get_head_hash($project);
6375                         $hash = git_get_hash_by_path($base, $file_name, "blob")
6376                                 or die_error(404, "Cannot find file");
6377                 } else {
6378                         die_error(400, "No file name defined");
6379                 }
6380         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6381                 # blobs defined by non-textual hash id's can be cached
6382                 $expires = "+1d";
6383         }
6384
6385         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
6386                 or die_error(500, "Open git-cat-file blob '$hash' failed");
6387
6388         # content-type (can include charset)
6389         $type = blob_contenttype($fd, $file_name, $type);
6390
6391         # "save as" filename, even when no $file_name is given
6392         my $save_as = "$hash";
6393         if (defined $file_name) {
6394                 $save_as = $file_name;
6395         } elsif ($type =~ m/^text\//) {
6396                 $save_as .= '.txt';
6397         }
6398
6399         # With XSS prevention on, blobs of all types except a few known safe
6400         # ones are served with "Content-Disposition: attachment" to make sure
6401         # they don't run in our security domain.  For certain image types,
6402         # blob view writes an <img> tag referring to blob_plain view, and we
6403         # want to be sure not to break that by serving the image as an
6404         # attachment (though Firefox 3 doesn't seem to care).
6405         my $sandbox = $prevent_xss &&
6406                 $type !~ m!^(?:text/[a-z]+|image/(?:gif|png|jpeg))(?:[ ;]|$)!;
6407
6408         # serve text/* as text/plain
6409         if ($prevent_xss &&
6410             ($type =~ m!^text/[a-z]+\b(.*)$! ||
6411              ($type =~ m!^[a-z]+/[a-z]\+xml\b(.*)$! && -T $fd))) {
6412                 my $rest = $1;
6413                 $rest = defined $rest ? $rest : '';
6414                 $type = "text/plain$rest";
6415         }
6416
6417         print $cgi->header(
6418                 -type => $type,
6419                 -expires => $expires,
6420                 -content_disposition =>
6421                         ($sandbox ? 'attachment' : 'inline')
6422                         . '; filename="' . $save_as . '"');
6423         local $/ = undef;
6424         binmode STDOUT, ':raw';
6425         print <$fd>;
6426         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
6427         close $fd;
6428 }
6429
6430 sub git_blob {
6431         my $expires;
6432
6433         if (!defined $hash) {
6434                 if (defined $file_name) {
6435                         my $base = $hash_base || git_get_head_hash($project);
6436                         $hash = git_get_hash_by_path($base, $file_name, "blob")
6437                                 or die_error(404, "Cannot find file");
6438                 } else {
6439                         die_error(400, "No file name defined");
6440                 }
6441         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6442                 # blobs defined by non-textual hash id's can be cached
6443                 $expires = "+1d";
6444         }
6445
6446         my $have_blame = gitweb_check_feature('blame');
6447         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
6448                 or die_error(500, "Couldn't cat $file_name, $hash");
6449         my $mimetype = blob_mimetype($fd, $file_name);
6450         # use 'blob_plain' (aka 'raw') view for files that cannot be displayed
6451         if ($mimetype !~ m!^(?:text/|image/(?:gif|png|jpeg)$)! && -B $fd) {
6452                 close $fd;
6453                 return git_blob_plain($mimetype);
6454         }
6455         # we can have blame only for text/* mimetype
6456         $have_blame &&= ($mimetype =~ m!^text/!);
6457
6458         my $highlight = gitweb_check_feature('highlight');
6459         my $syntax = guess_file_syntax($highlight, $mimetype, $file_name);
6460         $fd = run_highlighter($fd, $highlight, $syntax)
6461                 if $syntax;
6462
6463         git_header_html(undef, $expires);
6464         my $formats_nav = '';
6465         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
6466                 if (defined $file_name) {
6467                         if ($have_blame) {
6468                                 $formats_nav .=
6469                                         $cgi->a({-href => href(action=>"blame", -replay=>1)},
6470                                                 "blame") .
6471                                         " | ";
6472                         }
6473                         $formats_nav .=
6474                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6475                                         "history") .
6476                                 " | " .
6477                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
6478                                         "raw") .
6479                                 " | " .
6480                                 $cgi->a({-href => href(action=>"blob",
6481                                                        hash_base=>"HEAD", file_name=>$file_name)},
6482                                         "HEAD");
6483                 } else {
6484                         $formats_nav .=
6485                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
6486                                         "raw");
6487                 }
6488                 git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6489                 git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6490         } else {
6491                 print "<div class=\"page_nav\">\n" .
6492                       "<br/><br/></div>\n" .
6493                       "<div class=\"title\">".esc_html($hash)."</div>\n";
6494         }
6495         git_print_page_path($file_name, "blob", $hash_base);
6496         print "<div class=\"page_body\">\n";
6497         if ($mimetype =~ m!^image/!) {
6498                 print qq!<img type="!.esc_attr($mimetype).qq!"!;
6499                 if ($file_name) {
6500                         print qq! alt="!.esc_attr($file_name).qq!" title="!.esc_attr($file_name).qq!"!;
6501                 }
6502                 print qq! src="! .
6503                       href(action=>"blob_plain", hash=>$hash,
6504                            hash_base=>$hash_base, file_name=>$file_name) .
6505                       qq!" />\n!;
6506         } else {
6507                 my $nr;
6508                 while (my $line = <$fd>) {
6509                         chomp $line;
6510                         $nr++;
6511                         $line = untabify($line);
6512                         printf qq!<div class="pre"><a id="l%i" href="%s#l%i" class="linenr">%4i</a> %s</div>\n!,
6513                                $nr, esc_attr(href(-replay => 1)), $nr, $nr,
6514                                $syntax ? sanitize($line) : esc_html($line, -nbsp=>1);
6515                 }
6516         }
6517         close $fd
6518                 or print "Reading blob failed.\n";
6519         print "</div>";
6520         git_footer_html();
6521 }
6522
6523 sub git_tree {
6524         if (!defined $hash_base) {
6525                 $hash_base = "HEAD";
6526         }
6527         if (!defined $hash) {
6528                 if (defined $file_name) {
6529                         $hash = git_get_hash_by_path($hash_base, $file_name, "tree");
6530                 } else {
6531                         $hash = $hash_base;
6532                 }
6533         }
6534         die_error(404, "No such tree") unless defined($hash);
6535
6536         my $show_sizes = gitweb_check_feature('show-sizes');
6537         my $have_blame = gitweb_check_feature('blame');
6538
6539         my @entries = ();
6540         {
6541                 local $/ = "\0";
6542                 open my $fd, "-|", git_cmd(), "ls-tree", '-z',
6543                         ($show_sizes ? '-l' : ()), @extra_options, $hash
6544                         or die_error(500, "Open git-ls-tree failed");
6545                 @entries = map { chomp; $_ } <$fd>;
6546                 close $fd
6547                         or die_error(404, "Reading tree failed");
6548         }
6549
6550         my $refs = git_get_references();
6551         my $ref = format_ref_marker($refs, $hash_base);
6552         git_header_html();
6553         my $basedir = '';
6554         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
6555                 my @views_nav = ();
6556                 if (defined $file_name) {
6557                         push @views_nav,
6558                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6559                                         "history"),
6560                                 $cgi->a({-href => href(action=>"tree",
6561                                                        hash_base=>"HEAD", file_name=>$file_name)},
6562                                         "HEAD"),
6563                 }
6564                 my $snapshot_links = format_snapshot_links($hash);
6565                 if (defined $snapshot_links) {
6566                         # FIXME: Should be available when we have no hash base as well.
6567                         push @views_nav, $snapshot_links;
6568                 }
6569                 git_print_page_nav('tree','', $hash_base, undef, undef,
6570                                    join(' | ', @views_nav));
6571                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash_base);
6572         } else {
6573                 undef $hash_base;
6574                 print "<div class=\"page_nav\">\n";
6575                 print "<br/><br/></div>\n";
6576                 print "<div class=\"title\">".esc_html($hash)."</div>\n";
6577         }
6578         if (defined $file_name) {
6579                 $basedir = $file_name;
6580                 if ($basedir ne '' && substr($basedir, -1) ne '/') {
6581                         $basedir .= '/';
6582                 }
6583                 git_print_page_path($file_name, 'tree', $hash_base);
6584         }
6585         print "<div class=\"page_body\">\n";
6586         print "<table class=\"tree\">\n";
6587         my $alternate = 1;
6588         # '..' (top directory) link if possible
6589         if (defined $hash_base &&
6590             defined $file_name && $file_name =~ m![^/]+$!) {
6591                 if ($alternate) {
6592                         print "<tr class=\"dark\">\n";
6593                 } else {
6594                         print "<tr class=\"light\">\n";
6595                 }
6596                 $alternate ^= 1;
6597
6598                 my $up = $file_name;
6599                 $up =~ s!/?[^/]+$!!;
6600                 undef $up unless $up;
6601                 # based on git_print_tree_entry
6602                 print '<td class="mode">' . mode_str('040000') . "</td>\n";
6603                 print '<td class="size">&nbsp;</td>'."\n" if $show_sizes;
6604                 print '<td class="list">';
6605                 print $cgi->a({-href => href(action=>"tree",
6606                                              hash_base=>$hash_base,
6607                                              file_name=>$up)},
6608                               "..");
6609                 print "</td>\n";
6610                 print "<td class=\"link\"></td>\n";
6611
6612                 print "</tr>\n";
6613         }
6614         foreach my $line (@entries) {
6615                 my %t = parse_ls_tree_line($line, -z => 1, -l => $show_sizes);
6616
6617                 if ($alternate) {
6618                         print "<tr class=\"dark\">\n";
6619                 } else {
6620                         print "<tr class=\"light\">\n";
6621                 }
6622                 $alternate ^= 1;
6623
6624                 git_print_tree_entry(\%t, $basedir, $hash_base, $have_blame);
6625
6626                 print "</tr>\n";
6627         }
6628         print "</table>\n" .
6629               "</div>";
6630         git_footer_html();
6631 }
6632
6633 sub snapshot_name {
6634         my ($project, $hash) = @_;
6635
6636         # path/to/project.git  -> project
6637         # path/to/project/.git -> project
6638         my $name = to_utf8($project);
6639         $name =~ s,([^/])/*\.git$,$1,;
6640         $name = basename($name);
6641         # sanitize name
6642         $name =~ s/[[:cntrl:]]/?/g;
6643
6644         my $ver = $hash;
6645         if ($hash =~ /^[0-9a-fA-F]+$/) {
6646                 # shorten SHA-1 hash
6647                 my $full_hash = git_get_full_hash($project, $hash);
6648                 if ($full_hash =~ /^$hash/ && length($hash) > 7) {
6649                         $ver = git_get_short_hash($project, $hash);
6650                 }
6651         } elsif ($hash =~ m!^refs/tags/(.*)$!) {
6652                 # tags don't need shortened SHA-1 hash
6653                 $ver = $1;
6654         } else {
6655                 # branches and other need shortened SHA-1 hash
6656                 if ($hash =~ m!^refs/(?:heads|remotes)/(.*)$!) {
6657                         $ver = $1;
6658                 }
6659                 $ver .= '-' . git_get_short_hash($project, $hash);
6660         }
6661         # in case of hierarchical branch names
6662         $ver =~ s!/!.!g;
6663
6664         # name = project-version_string
6665         $name = "$name-$ver";
6666
6667         return wantarray ? ($name, $name) : $name;
6668 }
6669
6670 sub git_snapshot {
6671         my $format = $input_params{'snapshot_format'};
6672         if (!@snapshot_fmts) {
6673                 die_error(403, "Snapshots not allowed");
6674         }
6675         # default to first supported snapshot format
6676         $format ||= $snapshot_fmts[0];
6677         if ($format !~ m/^[a-z0-9]+$/) {
6678                 die_error(400, "Invalid snapshot format parameter");
6679         } elsif (!exists($known_snapshot_formats{$format})) {
6680                 die_error(400, "Unknown snapshot format");
6681         } elsif ($known_snapshot_formats{$format}{'disabled'}) {
6682                 die_error(403, "Snapshot format not allowed");
6683         } elsif (!grep($_ eq $format, @snapshot_fmts)) {
6684                 die_error(403, "Unsupported snapshot format");
6685         }
6686
6687         my $type = git_get_type("$hash^{}");
6688         if (!$type) {
6689                 die_error(404, 'Object does not exist');
6690         }  elsif ($type eq 'blob') {
6691                 die_error(400, 'Object is not a tree-ish');
6692         }
6693
6694         my ($name, $prefix) = snapshot_name($project, $hash);
6695         my $filename = "$name$known_snapshot_formats{$format}{'suffix'}";
6696         my $cmd = quote_command(
6697                 git_cmd(), 'archive',
6698                 "--format=$known_snapshot_formats{$format}{'format'}",
6699                 "--prefix=$prefix/", $hash);
6700         if (exists $known_snapshot_formats{$format}{'compressor'}) {
6701                 $cmd .= ' | ' . quote_command(@{$known_snapshot_formats{$format}{'compressor'}});
6702         }
6703
6704         $filename =~ s/(["\\])/\\$1/g;
6705         print $cgi->header(
6706                 -type => $known_snapshot_formats{$format}{'type'},
6707                 -content_disposition => 'inline; filename="' . $filename . '"',
6708                 -status => '200 OK');
6709
6710         open my $fd, "-|", $cmd
6711                 or die_error(500, "Execute git-archive failed");
6712         binmode STDOUT, ':raw';
6713         print <$fd>;
6714         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
6715         close $fd;
6716 }
6717
6718 sub git_log_generic {
6719         my ($fmt_name, $body_subr, $base, $parent, $file_name, $file_hash) = @_;
6720
6721         my $head = git_get_head_hash($project);
6722         if (!defined $base) {
6723                 $base = $head;
6724         }
6725         if (!defined $page) {
6726                 $page = 0;
6727         }
6728         my $refs = git_get_references();
6729
6730         my $commit_hash = $base;
6731         if (defined $parent) {
6732                 $commit_hash = "$parent..$base";
6733         }
6734         my @commitlist =
6735                 parse_commits($commit_hash, 101, (100 * $page),
6736                               defined $file_name ? ($file_name, "--full-history") : ());
6737
6738         my $ftype;
6739         if (!defined $file_hash && defined $file_name) {
6740                 # some commits could have deleted file in question,
6741                 # and not have it in tree, but one of them has to have it
6742                 for (my $i = 0; $i < @commitlist; $i++) {
6743                         $file_hash = git_get_hash_by_path($commitlist[$i]{'id'}, $file_name);
6744                         last if defined $file_hash;
6745                 }
6746         }
6747         if (defined $file_hash) {
6748                 $ftype = git_get_type($file_hash);
6749         }
6750         if (defined $file_name && !defined $ftype) {
6751                 die_error(500, "Unknown type of object");
6752         }
6753         my %co;
6754         if (defined $file_name) {
6755                 %co = parse_commit($base)
6756                         or die_error(404, "Unknown commit object");
6757         }
6758
6759
6760         my $paging_nav = format_paging_nav($fmt_name, $page, $#commitlist >= 100);
6761         my $next_link = '';
6762         if ($#commitlist >= 100) {
6763                 $next_link =
6764                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
6765                                  -accesskey => "n", -title => "Alt-n"}, "next");
6766         }
6767         my $patch_max = gitweb_get_feature('patches');
6768         if ($patch_max && !defined $file_name) {
6769                 if ($patch_max < 0 || @commitlist <= $patch_max) {
6770                         $paging_nav .= " &sdot; " .
6771                                 $cgi->a({-href => href(action=>"patches", -replay=>1)},
6772                                         "patches");
6773                 }
6774         }
6775
6776         git_header_html();
6777         git_print_page_nav($fmt_name,'', $hash,$hash,$hash, $paging_nav);
6778         if (defined $file_name) {
6779                 git_print_header_div('commit', esc_html($co{'title'}), $base);
6780         } else {
6781                 git_print_header_div('summary', $project)
6782         }
6783         git_print_page_path($file_name, $ftype, $hash_base)
6784                 if (defined $file_name);
6785
6786         $body_subr->(\@commitlist, 0, 99, $refs, $next_link,
6787                      $file_name, $file_hash, $ftype);
6788
6789         git_footer_html();
6790 }
6791
6792 sub git_log {
6793         git_log_generic('log', \&git_log_body,
6794                         $hash, $hash_parent);
6795 }
6796
6797 sub git_commit {
6798         $hash ||= $hash_base || "HEAD";
6799         my %co = parse_commit($hash)
6800             or die_error(404, "Unknown commit object");
6801
6802         my $parent  = $co{'parent'};
6803         my $parents = $co{'parents'}; # listref
6804
6805         # we need to prepare $formats_nav before any parameter munging
6806         my $formats_nav;
6807         if (!defined $parent) {
6808                 # --root commitdiff
6809                 $formats_nav .= '(initial)';
6810         } elsif (@$parents == 1) {
6811                 # single parent commit
6812                 $formats_nav .=
6813                         '(parent: ' .
6814                         $cgi->a({-href => href(action=>"commit",
6815                                                hash=>$parent)},
6816                                 esc_html(substr($parent, 0, 7))) .
6817                         ')';
6818         } else {
6819                 # merge commit
6820                 $formats_nav .=
6821                         '(merge: ' .
6822                         join(' ', map {
6823                                 $cgi->a({-href => href(action=>"commit",
6824                                                        hash=>$_)},
6825                                         esc_html(substr($_, 0, 7)));
6826                         } @$parents ) .
6827                         ')';
6828         }
6829         if (gitweb_check_feature('patches') && @$parents <= 1) {
6830                 $formats_nav .= " | " .
6831                         $cgi->a({-href => href(action=>"patch", -replay=>1)},
6832                                 "patch");
6833         }
6834
6835         if (!defined $parent) {
6836                 $parent = "--root";
6837         }
6838         my @difftree;
6839         open my $fd, "-|", git_cmd(), "diff-tree", '-r', "--no-commit-id",
6840                 @diff_opts,
6841                 (@$parents <= 1 ? $parent : '-c'),
6842                 $hash, "--"
6843                 or die_error(500, "Open git-diff-tree failed");
6844         @difftree = map { chomp; $_ } <$fd>;
6845         close $fd or die_error(404, "Reading git-diff-tree failed");
6846
6847         # non-textual hash id's can be cached
6848         my $expires;
6849         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6850                 $expires = "+1d";
6851         }
6852         my $refs = git_get_references();
6853         my $ref = format_ref_marker($refs, $co{'id'});
6854
6855         git_header_html(undef, $expires);
6856         git_print_page_nav('commit', '',
6857                            $hash, $co{'tree'}, $hash,
6858                            $formats_nav);
6859
6860         if (defined $co{'parent'}) {
6861                 git_print_header_div('commitdiff', esc_html($co{'title'}) . $ref, $hash);
6862         } else {
6863                 git_print_header_div('tree', esc_html($co{'title'}) . $ref, $co{'tree'}, $hash);
6864         }
6865         print "<div class=\"title_text\">\n" .
6866               "<table class=\"object_header\">\n";
6867         git_print_authorship_rows(\%co);
6868         print "<tr><td>commit</td><td class=\"sha1\">$co{'id'}</td></tr>\n";
6869         print "<tr>" .
6870               "<td>tree</td>" .
6871               "<td class=\"sha1\">" .
6872               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash),
6873                        class => "list"}, $co{'tree'}) .
6874               "</td>" .
6875               "<td class=\"link\">" .
6876               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash)},
6877                       "tree");
6878         my $snapshot_links = format_snapshot_links($hash);
6879         if (defined $snapshot_links) {
6880                 print " | " . $snapshot_links;
6881         }
6882         print "</td>" .
6883               "</tr>\n";
6884
6885         foreach my $par (@$parents) {
6886                 print "<tr>" .
6887                       "<td>parent</td>" .
6888                       "<td class=\"sha1\">" .
6889                       $cgi->a({-href => href(action=>"commit", hash=>$par),
6890                                class => "list"}, $par) .
6891                       "</td>" .
6892                       "<td class=\"link\">" .
6893                       $cgi->a({-href => href(action=>"commit", hash=>$par)}, "commit") .
6894                       " | " .
6895                       $cgi->a({-href => href(action=>"commitdiff", hash=>$hash, hash_parent=>$par)}, "diff") .
6896                       "</td>" .
6897                       "</tr>\n";
6898         }
6899         print "</table>".
6900               "</div>\n";
6901
6902         print "<div class=\"page_body\">\n";
6903         git_print_log($co{'comment'});
6904         print "</div>\n";
6905
6906         git_difftree_body(\@difftree, $hash, @$parents);
6907
6908         git_footer_html();
6909 }
6910
6911 sub git_object {
6912         # object is defined by:
6913         # - hash or hash_base alone
6914         # - hash_base and file_name
6915         my $type;
6916
6917         # - hash or hash_base alone
6918         if ($hash || ($hash_base && !defined $file_name)) {
6919                 my $object_id = $hash || $hash_base;
6920
6921                 open my $fd, "-|", quote_command(
6922                         git_cmd(), 'cat-file', '-t', $object_id) . ' 2> /dev/null'
6923                         or die_error(404, "Object does not exist");
6924                 $type = <$fd>;
6925                 chomp $type;
6926                 close $fd
6927                         or die_error(404, "Object does not exist");
6928
6929         # - hash_base and file_name
6930         } elsif ($hash_base && defined $file_name) {
6931                 $file_name =~ s,/+$,,;
6932
6933                 system(git_cmd(), "cat-file", '-e', $hash_base) == 0
6934                         or die_error(404, "Base object does not exist");
6935
6936                 # here errors should not hapen
6937                 open my $fd, "-|", git_cmd(), "ls-tree", $hash_base, "--", $file_name
6938                         or die_error(500, "Open git-ls-tree failed");
6939                 my $line = <$fd>;
6940                 close $fd;
6941
6942                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
6943                 unless ($line && $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/) {
6944                         die_error(404, "File or directory for given base does not exist");
6945                 }
6946                 $type = $2;
6947                 $hash = $3;
6948         } else {
6949                 die_error(400, "Not enough information to find object");
6950         }
6951
6952         print $cgi->redirect(-uri => href(action=>$type, -full=>1,
6953                                           hash=>$hash, hash_base=>$hash_base,
6954                                           file_name=>$file_name),
6955                              -status => '302 Found');
6956 }
6957
6958 sub git_blobdiff {
6959         my $format = shift || 'html';
6960
6961         my $fd;
6962         my @difftree;
6963         my %diffinfo;
6964         my $expires;
6965
6966         # preparing $fd and %diffinfo for git_patchset_body
6967         # new style URI
6968         if (defined $hash_base && defined $hash_parent_base) {
6969                 if (defined $file_name) {
6970                         # read raw output
6971                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6972                                 $hash_parent_base, $hash_base,
6973                                 "--", (defined $file_parent ? $file_parent : ()), $file_name
6974                                 or die_error(500, "Open git-diff-tree failed");
6975                         @difftree = map { chomp; $_ } <$fd>;
6976                         close $fd
6977                                 or die_error(404, "Reading git-diff-tree failed");
6978                         @difftree
6979                                 or die_error(404, "Blob diff not found");
6980
6981                 } elsif (defined $hash &&
6982                          $hash =~ /[0-9a-fA-F]{40}/) {
6983                         # try to find filename from $hash
6984
6985                         # read filtered raw output
6986                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6987                                 $hash_parent_base, $hash_base, "--"
6988                                 or die_error(500, "Open git-diff-tree failed");
6989                         @difftree =
6990                                 # ':100644 100644 03b21826... 3b93d5e7... M     ls-files.c'
6991                                 # $hash == to_id
6992                                 grep { /^:[0-7]{6} [0-7]{6} [0-9a-fA-F]{40} $hash/ }
6993                                 map { chomp; $_ } <$fd>;
6994                         close $fd
6995                                 or die_error(404, "Reading git-diff-tree failed");
6996                         @difftree
6997                                 or die_error(404, "Blob diff not found");
6998
6999                 } else {
7000                         die_error(400, "Missing one of the blob diff parameters");
7001                 }
7002
7003                 if (@difftree > 1) {
7004                         die_error(400, "Ambiguous blob diff specification");
7005                 }
7006
7007                 %diffinfo = parse_difftree_raw_line($difftree[0]);
7008                 $file_parent ||= $diffinfo{'from_file'} || $file_name;
7009                 $file_name   ||= $diffinfo{'to_file'};
7010
7011                 $hash_parent ||= $diffinfo{'from_id'};
7012                 $hash        ||= $diffinfo{'to_id'};
7013
7014                 # non-textual hash id's can be cached
7015                 if ($hash_base =~ m/^[0-9a-fA-F]{40}$/ &&
7016                     $hash_parent_base =~ m/^[0-9a-fA-F]{40}$/) {
7017                         $expires = '+1d';
7018                 }
7019
7020                 # open patch output
7021                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7022                         '-p', ($format eq 'html' ? "--full-index" : ()),
7023                         $hash_parent_base, $hash_base,
7024                         "--", (defined $file_parent ? $file_parent : ()), $file_name
7025                         or die_error(500, "Open git-diff-tree failed");
7026         }
7027
7028         # old/legacy style URI -- not generated anymore since 1.4.3.
7029         if (!%diffinfo) {
7030                 die_error('404 Not Found', "Missing one of the blob diff parameters")
7031         }
7032
7033         # header
7034         if ($format eq 'html') {
7035                 my $formats_nav =
7036                         $cgi->a({-href => href(action=>"blobdiff_plain", -replay=>1)},
7037                                 "raw");
7038                 git_header_html(undef, $expires);
7039                 if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7040                         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
7041                         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
7042                 } else {
7043                         print "<div class=\"page_nav\"><br/>$formats_nav<br/></div>\n";
7044                         print "<div class=\"title\">".esc_html("$hash vs $hash_parent")."</div>\n";
7045                 }
7046                 if (defined $file_name) {
7047                         git_print_page_path($file_name, "blob", $hash_base);
7048                 } else {
7049                         print "<div class=\"page_path\"></div>\n";
7050                 }
7051
7052         } elsif ($format eq 'plain') {
7053                 print $cgi->header(
7054                         -type => 'text/plain',
7055                         -charset => 'utf-8',
7056                         -expires => $expires,
7057                         -content_disposition => 'inline; filename="' . "$file_name" . '.patch"');
7058
7059                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7060
7061         } else {
7062                 die_error(400, "Unknown blobdiff format");
7063         }
7064
7065         # patch
7066         if ($format eq 'html') {
7067                 print "<div class=\"page_body\">\n";
7068
7069                 git_patchset_body($fd, [ \%diffinfo ], $hash_base, $hash_parent_base);
7070                 close $fd;
7071
7072                 print "</div>\n"; # class="page_body"
7073                 git_footer_html();
7074
7075         } else {
7076                 while (my $line = <$fd>) {
7077                         $line =~ s!a/($hash|$hash_parent)!'a/'.esc_path($diffinfo{'from_file'})!eg;
7078                         $line =~ s!b/($hash|$hash_parent)!'b/'.esc_path($diffinfo{'to_file'})!eg;
7079
7080                         print $line;
7081
7082                         last if $line =~ m!^\+\+\+!;
7083                 }
7084                 local $/ = undef;
7085                 print <$fd>;
7086                 close $fd;
7087         }
7088 }
7089
7090 sub git_blobdiff_plain {
7091         git_blobdiff('plain');
7092 }
7093
7094 sub git_commitdiff {
7095         my %params = @_;
7096         my $format = $params{-format} || 'html';
7097
7098         my ($patch_max) = gitweb_get_feature('patches');
7099         if ($format eq 'patch') {
7100                 die_error(403, "Patch view not allowed") unless $patch_max;
7101         }
7102
7103         $hash ||= $hash_base || "HEAD";
7104         my %co = parse_commit($hash)
7105             or die_error(404, "Unknown commit object");
7106
7107         # choose format for commitdiff for merge
7108         if (! defined $hash_parent && @{$co{'parents'}} > 1) {
7109                 $hash_parent = '--cc';
7110         }
7111         # we need to prepare $formats_nav before almost any parameter munging
7112         my $formats_nav;
7113         if ($format eq 'html') {
7114                 $formats_nav =
7115                         $cgi->a({-href => href(action=>"commitdiff_plain", -replay=>1)},
7116                                 "raw");
7117                 if ($patch_max && @{$co{'parents'}} <= 1) {
7118                         $formats_nav .= " | " .
7119                                 $cgi->a({-href => href(action=>"patch", -replay=>1)},
7120                                         "patch");
7121                 }
7122
7123                 if (defined $hash_parent &&
7124                     $hash_parent ne '-c' && $hash_parent ne '--cc') {
7125                         # commitdiff with two commits given
7126                         my $hash_parent_short = $hash_parent;
7127                         if ($hash_parent =~ m/^[0-9a-fA-F]{40}$/) {
7128                                 $hash_parent_short = substr($hash_parent, 0, 7);
7129                         }
7130                         $formats_nav .=
7131                                 ' (from';
7132                         for (my $i = 0; $i < @{$co{'parents'}}; $i++) {
7133                                 if ($co{'parents'}[$i] eq $hash_parent) {
7134                                         $formats_nav .= ' parent ' . ($i+1);
7135                                         last;
7136                                 }
7137                         }
7138                         $formats_nav .= ': ' .
7139                                 $cgi->a({-href => href(action=>"commitdiff",
7140                                                        hash=>$hash_parent)},
7141                                         esc_html($hash_parent_short)) .
7142                                 ')';
7143                 } elsif (!$co{'parent'}) {
7144                         # --root commitdiff
7145                         $formats_nav .= ' (initial)';
7146                 } elsif (scalar @{$co{'parents'}} == 1) {
7147                         # single parent commit
7148                         $formats_nav .=
7149                                 ' (parent: ' .
7150                                 $cgi->a({-href => href(action=>"commitdiff",
7151                                                        hash=>$co{'parent'})},
7152                                         esc_html(substr($co{'parent'}, 0, 7))) .
7153                                 ')';
7154                 } else {
7155                         # merge commit
7156                         if ($hash_parent eq '--cc') {
7157                                 $formats_nav .= ' | ' .
7158                                         $cgi->a({-href => href(action=>"commitdiff",
7159                                                                hash=>$hash, hash_parent=>'-c')},
7160                                                 'combined');
7161                         } else { # $hash_parent eq '-c'
7162                                 $formats_nav .= ' | ' .
7163                                         $cgi->a({-href => href(action=>"commitdiff",
7164                                                                hash=>$hash, hash_parent=>'--cc')},
7165                                                 'compact');
7166                         }
7167                         $formats_nav .=
7168                                 ' (merge: ' .
7169                                 join(' ', map {
7170                                         $cgi->a({-href => href(action=>"commitdiff",
7171                                                                hash=>$_)},
7172                                                 esc_html(substr($_, 0, 7)));
7173                                 } @{$co{'parents'}} ) .
7174                                 ')';
7175                 }
7176         }
7177
7178         my $hash_parent_param = $hash_parent;
7179         if (!defined $hash_parent_param) {
7180                 # --cc for multiple parents, --root for parentless
7181                 $hash_parent_param =
7182                         @{$co{'parents'}} > 1 ? '--cc' : $co{'parent'} || '--root';
7183         }
7184
7185         # read commitdiff
7186         my $fd;
7187         my @difftree;
7188         if ($format eq 'html') {
7189                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7190                         "--no-commit-id", "--patch-with-raw", "--full-index",
7191                         $hash_parent_param, $hash, "--"
7192                         or die_error(500, "Open git-diff-tree failed");
7193
7194                 while (my $line = <$fd>) {
7195                         chomp $line;
7196                         # empty line ends raw part of diff-tree output
7197                         last unless $line;
7198                         push @difftree, scalar parse_difftree_raw_line($line);
7199                 }
7200
7201         } elsif ($format eq 'plain') {
7202                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7203                         '-p', $hash_parent_param, $hash, "--"
7204                         or die_error(500, "Open git-diff-tree failed");
7205         } elsif ($format eq 'patch') {
7206                 # For commit ranges, we limit the output to the number of
7207                 # patches specified in the 'patches' feature.
7208                 # For single commits, we limit the output to a single patch,
7209                 # diverging from the git-format-patch default.
7210                 my @commit_spec = ();
7211                 if ($hash_parent) {
7212                         if ($patch_max > 0) {
7213                                 push @commit_spec, "-$patch_max";
7214                         }
7215                         push @commit_spec, '-n', "$hash_parent..$hash";
7216                 } else {
7217                         if ($params{-single}) {
7218                                 push @commit_spec, '-1';
7219                         } else {
7220                                 if ($patch_max > 0) {
7221                                         push @commit_spec, "-$patch_max";
7222                                 }
7223                                 push @commit_spec, "-n";
7224                         }
7225                         push @commit_spec, '--root', $hash;
7226                 }
7227                 open $fd, "-|", git_cmd(), "format-patch", @diff_opts,
7228                         '--encoding=utf8', '--stdout', @commit_spec
7229                         or die_error(500, "Open git-format-patch failed");
7230         } else {
7231                 die_error(400, "Unknown commitdiff format");
7232         }
7233
7234         # non-textual hash id's can be cached
7235         my $expires;
7236         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7237                 $expires = "+1d";
7238         }
7239
7240         # write commit message
7241         if ($format eq 'html') {
7242                 my $refs = git_get_references();
7243                 my $ref = format_ref_marker($refs, $co{'id'});
7244
7245                 git_header_html(undef, $expires);
7246                 git_print_page_nav('commitdiff','', $hash,$co{'tree'},$hash, $formats_nav);
7247                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash);
7248                 print "<div class=\"title_text\">\n" .
7249                       "<table class=\"object_header\">\n";
7250                 git_print_authorship_rows(\%co);
7251                 print "</table>".
7252                       "</div>\n";
7253                 print "<div class=\"page_body\">\n";
7254                 if (@{$co{'comment'}} > 1) {
7255                         print "<div class=\"log\">\n";
7256                         git_print_log($co{'comment'}, -final_empty_line=> 1, -remove_title => 1);
7257                         print "</div>\n"; # class="log"
7258                 }
7259
7260         } elsif ($format eq 'plain') {
7261                 my $refs = git_get_references("tags");
7262                 my $tagname = git_get_rev_name_tags($hash);
7263                 my $filename = basename($project) . "-$hash.patch";
7264
7265                 print $cgi->header(
7266                         -type => 'text/plain',
7267                         -charset => 'utf-8',
7268                         -expires => $expires,
7269                         -content_disposition => 'inline; filename="' . "$filename" . '"');
7270                 my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
7271                 print "From: " . to_utf8($co{'author'}) . "\n";
7272                 print "Date: $ad{'rfc2822'} ($ad{'tz_local'})\n";
7273                 print "Subject: " . to_utf8($co{'title'}) . "\n";
7274
7275                 print "X-Git-Tag: $tagname\n" if $tagname;
7276                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7277
7278                 foreach my $line (@{$co{'comment'}}) {
7279                         print to_utf8($line) . "\n";
7280                 }
7281                 print "---\n\n";
7282         } elsif ($format eq 'patch') {
7283                 my $filename = basename($project) . "-$hash.patch";
7284
7285                 print $cgi->header(
7286                         -type => 'text/plain',
7287                         -charset => 'utf-8',
7288                         -expires => $expires,
7289                         -content_disposition => 'inline; filename="' . "$filename" . '"');
7290         }
7291
7292         # write patch
7293         if ($format eq 'html') {
7294                 my $use_parents = !defined $hash_parent ||
7295                         $hash_parent eq '-c' || $hash_parent eq '--cc';
7296                 git_difftree_body(\@difftree, $hash,
7297                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
7298                 print "<br/>\n";
7299
7300                 git_patchset_body($fd, \@difftree, $hash,
7301                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
7302                 close $fd;
7303                 print "</div>\n"; # class="page_body"
7304                 git_footer_html();
7305
7306         } elsif ($format eq 'plain') {
7307                 local $/ = undef;
7308                 print <$fd>;
7309                 close $fd
7310                         or print "Reading git-diff-tree failed\n";
7311         } elsif ($format eq 'patch') {
7312                 local $/ = undef;
7313                 print <$fd>;
7314                 close $fd
7315                         or print "Reading git-format-patch failed\n";
7316         }
7317 }
7318
7319 sub git_commitdiff_plain {
7320         git_commitdiff(-format => 'plain');
7321 }
7322
7323 # format-patch-style patches
7324 sub git_patch {
7325         git_commitdiff(-format => 'patch', -single => 1);
7326 }
7327
7328 sub git_patches {
7329         git_commitdiff(-format => 'patch');
7330 }
7331
7332 sub git_history {
7333         git_log_generic('history', \&git_history_body,
7334                         $hash_base, $hash_parent_base,
7335                         $file_name, $hash);
7336 }
7337
7338 sub git_search {
7339         $searchtype ||= 'commit';
7340
7341         # check if appropriate features are enabled
7342         gitweb_check_feature('search')
7343                 or die_error(403, "Search is disabled");
7344         if ($searchtype eq 'pickaxe') {
7345                 # pickaxe may take all resources of your box and run for several minutes
7346                 # with every query - so decide by yourself how public you make this feature
7347                 gitweb_check_feature('pickaxe')
7348                         or die_error(403, "Pickaxe search is disabled");
7349         }
7350         if ($searchtype eq 'grep') {
7351                 # grep search might be potentially CPU-intensive, too
7352                 gitweb_check_feature('grep')
7353                         or die_error(403, "Grep search is disabled");
7354         }
7355
7356         if (!defined $searchtext) {
7357                 die_error(400, "Text field is empty");
7358         }
7359         if (!defined $hash) {
7360                 $hash = git_get_head_hash($project);
7361         }
7362         my %co = parse_commit($hash);
7363         if (!%co) {
7364                 die_error(404, "Unknown commit object");
7365         }
7366         if (!defined $page) {
7367                 $page = 0;
7368         }
7369
7370         if ($searchtype eq 'commit' ||
7371             $searchtype eq 'author' ||
7372             $searchtype eq 'committer') {
7373                 git_search_message(%co);
7374         } elsif ($searchtype eq 'pickaxe') {
7375                 git_search_changes(%co);
7376         } elsif ($searchtype eq 'grep') {
7377                 git_search_files(%co);
7378         } else {
7379                 die_error(400, "Unknown search type");
7380         }
7381 }
7382
7383 sub git_search_help {
7384         git_header_html();
7385         git_print_page_nav('','', $hash,$hash,$hash);
7386         print <<EOT;
7387 <p><strong>Pattern</strong> is by default a normal string that is matched precisely (but without
7388 regard to case, except in the case of pickaxe). However, when you check the <em>re</em> checkbox,
7389 the pattern entered is recognized as the POSIX extended
7390 <a href="http://en.wikipedia.org/wiki/Regular_expression">regular expression</a> (also case
7391 insensitive).</p>
7392 <dl>
7393 <dt><b>commit</b></dt>
7394 <dd>The commit messages and authorship information will be scanned for the given pattern.</dd>
7395 EOT
7396         my $have_grep = gitweb_check_feature('grep');
7397         if ($have_grep) {
7398                 print <<EOT;
7399 <dt><b>grep</b></dt>
7400 <dd>All files in the currently selected tree (HEAD unless you are explicitly browsing
7401     a different one) are searched for the given pattern. On large trees, this search can take
7402 a while and put some strain on the server, so please use it with some consideration. Note that
7403 due to git-grep peculiarity, currently if regexp mode is turned off, the matches are
7404 case-sensitive.</dd>
7405 EOT
7406         }
7407         print <<EOT;
7408 <dt><b>author</b></dt>
7409 <dd>Name and e-mail of the change author and date of birth of the patch will be scanned for the given pattern.</dd>
7410 <dt><b>committer</b></dt>
7411 <dd>Name and e-mail of the committer and date of commit will be scanned for the given pattern.</dd>
7412 EOT
7413         my $have_pickaxe = gitweb_check_feature('pickaxe');
7414         if ($have_pickaxe) {
7415                 print <<EOT;
7416 <dt><b>pickaxe</b></dt>
7417 <dd>All commits that caused the string to appear or disappear from any file (changes that
7418 added, removed or "modified" the string) will be listed. This search can take a while and
7419 takes a lot of strain on the server, so please use it wisely. Note that since you may be
7420 interested even in changes just changing the case as well, this search is case sensitive.</dd>
7421 EOT
7422         }
7423         print "</dl>\n";
7424         git_footer_html();
7425 }
7426
7427 sub git_shortlog {
7428         git_log_generic('shortlog', \&git_shortlog_body,
7429                         $hash, $hash_parent);
7430 }
7431
7432 ## ......................................................................
7433 ## feeds (RSS, Atom; OPML)
7434
7435 sub git_feed {
7436         my $format = shift || 'atom';
7437         my $have_blame = gitweb_check_feature('blame');
7438
7439         # Atom: http://www.atomenabled.org/developers/syndication/
7440         # RSS:  http://www.notestips.com/80256B3A007F2692/1/NAMO5P9UPQ
7441         if ($format ne 'rss' && $format ne 'atom') {
7442                 die_error(400, "Unknown web feed format");
7443         }
7444
7445         # log/feed of current (HEAD) branch, log of given branch, history of file/directory
7446         my $head = $hash || 'HEAD';
7447         my @commitlist = parse_commits($head, 150, 0, $file_name);
7448
7449         my %latest_commit;
7450         my %latest_date;
7451         my $content_type = "application/$format+xml";
7452         if (defined $cgi->http('HTTP_ACCEPT') &&
7453                  $cgi->Accept('text/xml') > $cgi->Accept($content_type)) {
7454                 # browser (feed reader) prefers text/xml
7455                 $content_type = 'text/xml';
7456         }
7457         if (defined($commitlist[0])) {
7458                 %latest_commit = %{$commitlist[0]};
7459                 my $latest_epoch = $latest_commit{'committer_epoch'};
7460                 %latest_date   = parse_date($latest_epoch, $latest_commit{'comitter_tz'});
7461                 my $if_modified = $cgi->http('IF_MODIFIED_SINCE');
7462                 if (defined $if_modified) {
7463                         my $since;
7464                         if (eval { require HTTP::Date; 1; }) {
7465                                 $since = HTTP::Date::str2time($if_modified);
7466                         } elsif (eval { require Time::ParseDate; 1; }) {
7467                                 $since = Time::ParseDate::parsedate($if_modified, GMT => 1);
7468                         }
7469                         if (defined $since && $latest_epoch <= $since) {
7470                                 print $cgi->header(
7471                                         -type => $content_type,
7472                                         -charset => 'utf-8',
7473                                         -last_modified => $latest_date{'rfc2822'},
7474                                         -status => '304 Not Modified');
7475                                 return;
7476                         }
7477                 }
7478                 print $cgi->header(
7479                         -type => $content_type,
7480                         -charset => 'utf-8',
7481                         -last_modified => $latest_date{'rfc2822'});
7482         } else {
7483                 print $cgi->header(
7484                         -type => $content_type,
7485                         -charset => 'utf-8');
7486         }
7487
7488         # Optimization: skip generating the body if client asks only
7489         # for Last-Modified date.
7490         return if ($cgi->request_method() eq 'HEAD');
7491
7492         # header variables
7493         my $title = "$site_name - $project/$action";
7494         my $feed_type = 'log';
7495         if (defined $hash) {
7496                 $title .= " - '$hash'";
7497                 $feed_type = 'branch log';
7498                 if (defined $file_name) {
7499                         $title .= " :: $file_name";
7500                         $feed_type = 'history';
7501                 }
7502         } elsif (defined $file_name) {
7503                 $title .= " - $file_name";
7504                 $feed_type = 'history';
7505         }
7506         $title .= " $feed_type";
7507         my $descr = git_get_project_description($project);
7508         if (defined $descr) {
7509                 $descr = esc_html($descr);
7510         } else {
7511                 $descr = "$project " .
7512                          ($format eq 'rss' ? 'RSS' : 'Atom') .
7513                          " feed";
7514         }
7515         my $owner = git_get_project_owner($project);
7516         $owner = esc_html($owner);
7517
7518         #header
7519         my $alt_url;
7520         if (defined $file_name) {
7521                 $alt_url = href(-full=>1, action=>"history", hash=>$hash, file_name=>$file_name);
7522         } elsif (defined $hash) {
7523                 $alt_url = href(-full=>1, action=>"log", hash=>$hash);
7524         } else {
7525                 $alt_url = href(-full=>1, action=>"summary");
7526         }
7527         print qq!<?xml version="1.0" encoding="utf-8"?>\n!;
7528         if ($format eq 'rss') {
7529                 print <<XML;
7530 <rss version="2.0" xmlns:content="http://purl.org/rss/1.0/modules/content/">
7531 <channel>
7532 XML
7533                 print "<title>$title</title>\n" .
7534                       "<link>$alt_url</link>\n" .
7535                       "<description>$descr</description>\n" .
7536                       "<language>en</language>\n" .
7537                       # project owner is responsible for 'editorial' content
7538                       "<managingEditor>$owner</managingEditor>\n";
7539                 if (defined $logo || defined $favicon) {
7540                         # prefer the logo to the favicon, since RSS
7541                         # doesn't allow both
7542                         my $img = esc_url($logo || $favicon);
7543                         print "<image>\n" .
7544                               "<url>$img</url>\n" .
7545                               "<title>$title</title>\n" .
7546                               "<link>$alt_url</link>\n" .
7547                               "</image>\n";
7548                 }
7549                 if (%latest_date) {
7550                         print "<pubDate>$latest_date{'rfc2822'}</pubDate>\n";
7551                         print "<lastBuildDate>$latest_date{'rfc2822'}</lastBuildDate>\n";
7552                 }
7553                 print "<generator>gitweb v.$version/$git_version</generator>\n";
7554         } elsif ($format eq 'atom') {
7555                 print <<XML;
7556 <feed xmlns="http://www.w3.org/2005/Atom">
7557 XML
7558                 print "<title>$title</title>\n" .
7559                       "<subtitle>$descr</subtitle>\n" .
7560                       '<link rel="alternate" type="text/html" href="' .
7561                       $alt_url . '" />' . "\n" .
7562                       '<link rel="self" type="' . $content_type . '" href="' .
7563                       $cgi->self_url() . '" />' . "\n" .
7564                       "<id>" . href(-full=>1) . "</id>\n" .
7565                       # use project owner for feed author
7566                       "<author><name>$owner</name></author>\n";
7567                 if (defined $favicon) {
7568                         print "<icon>" . esc_url($favicon) . "</icon>\n";
7569                 }
7570                 if (defined $logo) {
7571                         # not twice as wide as tall: 72 x 27 pixels
7572                         print "<logo>" . esc_url($logo) . "</logo>\n";
7573                 }
7574                 if (! %latest_date) {
7575                         # dummy date to keep the feed valid until commits trickle in:
7576                         print "<updated>1970-01-01T00:00:00Z</updated>\n";
7577                 } else {
7578                         print "<updated>$latest_date{'iso-8601'}</updated>\n";
7579                 }
7580                 print "<generator version='$version/$git_version'>gitweb</generator>\n";
7581         }
7582
7583         # contents
7584         for (my $i = 0; $i <= $#commitlist; $i++) {
7585                 my %co = %{$commitlist[$i]};
7586                 my $commit = $co{'id'};
7587                 # we read 150, we always show 30 and the ones more recent than 48 hours
7588                 if (($i >= 20) && ((time - $co{'author_epoch'}) > 48*60*60)) {
7589                         last;
7590                 }
7591                 my %cd = parse_date($co{'author_epoch'}, $co{'author_tz'});
7592
7593                 # get list of changed files
7594                 open my $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7595                         $co{'parent'} || "--root",
7596                         $co{'id'}, "--", (defined $file_name ? $file_name : ())
7597                         or next;
7598                 my @difftree = map { chomp; $_ } <$fd>;
7599                 close $fd
7600                         or next;
7601
7602                 # print element (entry, item)
7603                 my $co_url = href(-full=>1, action=>"commitdiff", hash=>$commit);
7604                 if ($format eq 'rss') {
7605                         print "<item>\n" .
7606                               "<title>" . esc_html($co{'title'}) . "</title>\n" .
7607                               "<author>" . esc_html($co{'author'}) . "</author>\n" .
7608                               "<pubDate>$cd{'rfc2822'}</pubDate>\n" .
7609                               "<guid isPermaLink=\"true\">$co_url</guid>\n" .
7610                               "<link>$co_url</link>\n" .
7611                               "<description>" . esc_html($co{'title'}) . "</description>\n" .
7612                               "<content:encoded>" .
7613                               "<![CDATA[\n";
7614                 } elsif ($format eq 'atom') {
7615                         print "<entry>\n" .
7616                               "<title type=\"html\">" . esc_html($co{'title'}) . "</title>\n" .
7617                               "<updated>$cd{'iso-8601'}</updated>\n" .
7618                               "<author>\n" .
7619                               "  <name>" . esc_html($co{'author_name'}) . "</name>\n";
7620                         if ($co{'author_email'}) {
7621                                 print "  <email>" . esc_html($co{'author_email'}) . "</email>\n";
7622                         }
7623                         print "</author>\n" .
7624                               # use committer for contributor
7625                               "<contributor>\n" .
7626                               "  <name>" . esc_html($co{'committer_name'}) . "</name>\n";
7627                         if ($co{'committer_email'}) {
7628                                 print "  <email>" . esc_html($co{'committer_email'}) . "</email>\n";
7629                         }
7630                         print "</contributor>\n" .
7631                               "<published>$cd{'iso-8601'}</published>\n" .
7632                               "<link rel=\"alternate\" type=\"text/html\" href=\"$co_url\" />\n" .
7633                               "<id>$co_url</id>\n" .
7634                               "<content type=\"xhtml\" xml:base=\"" . esc_url($my_url) . "\">\n" .
7635                               "<div xmlns=\"http://www.w3.org/1999/xhtml\">\n";
7636                 }
7637                 my $comment = $co{'comment'};
7638                 print "<pre>\n";
7639                 foreach my $line (@$comment) {
7640                         $line = esc_html($line);
7641                         print "$line\n";
7642                 }
7643                 print "</pre><ul>\n";
7644                 foreach my $difftree_line (@difftree) {
7645                         my %difftree = parse_difftree_raw_line($difftree_line);
7646                         next if !$difftree{'from_id'};
7647
7648                         my $file = $difftree{'file'} || $difftree{'to_file'};
7649
7650                         print "<li>" .
7651                               "[" .
7652                               $cgi->a({-href => href(-full=>1, action=>"blobdiff",
7653                                                      hash=>$difftree{'to_id'}, hash_parent=>$difftree{'from_id'},
7654                                                      hash_base=>$co{'id'}, hash_parent_base=>$co{'parent'},
7655                                                      file_name=>$file, file_parent=>$difftree{'from_file'}),
7656                                       -title => "diff"}, 'D');
7657                         if ($have_blame) {
7658                                 print $cgi->a({-href => href(-full=>1, action=>"blame",
7659                                                              file_name=>$file, hash_base=>$commit),
7660                                               -title => "blame"}, 'B');
7661                         }
7662                         # if this is not a feed of a file history
7663                         if (!defined $file_name || $file_name ne $file) {
7664                                 print $cgi->a({-href => href(-full=>1, action=>"history",
7665                                                              file_name=>$file, hash=>$commit),
7666                                               -title => "history"}, 'H');
7667                         }
7668                         $file = esc_path($file);
7669                         print "] ".
7670                               "$file</li>\n";
7671                 }
7672                 if ($format eq 'rss') {
7673                         print "</ul>]]>\n" .
7674                               "</content:encoded>\n" .
7675                               "</item>\n";
7676                 } elsif ($format eq 'atom') {
7677                         print "</ul>\n</div>\n" .
7678                               "</content>\n" .
7679                               "</entry>\n";
7680                 }
7681         }
7682
7683         # end of feed
7684         if ($format eq 'rss') {
7685                 print "</channel>\n</rss>\n";
7686         } elsif ($format eq 'atom') {
7687                 print "</feed>\n";
7688         }
7689 }
7690
7691 sub git_rss {
7692         git_feed('rss');
7693 }
7694
7695 sub git_atom {
7696         git_feed('atom');
7697 }
7698
7699 sub git_opml {
7700         my @list = git_get_projects_list();
7701         if (!@list) {
7702                 die_error(404, "No projects found");
7703         }
7704
7705         print $cgi->header(
7706                 -type => 'text/xml',
7707                 -charset => 'utf-8',
7708                 -content_disposition => 'inline; filename="opml.xml"');
7709
7710         print <<XML;
7711 <?xml version="1.0" encoding="utf-8"?>
7712 <opml version="1.0">
7713 <head>
7714   <title>$site_name OPML Export</title>
7715 </head>
7716 <body>
7717 <outline text="git RSS feeds">
7718 XML
7719
7720         foreach my $pr (@list) {
7721                 my %proj = %$pr;
7722                 my $head = git_get_head_hash($proj{'path'});
7723                 if (!defined $head) {
7724                         next;
7725                 }
7726                 $git_dir = "$projectroot/$proj{'path'}";
7727                 my %co = parse_commit($head);
7728                 if (!%co) {
7729                         next;
7730                 }
7731
7732                 my $path = esc_html(chop_str($proj{'path'}, 25, 5));
7733                 my $rss  = href('project' => $proj{'path'}, 'action' => 'rss', -full => 1);
7734                 my $html = href('project' => $proj{'path'}, 'action' => 'summary', -full => 1);
7735                 print "<outline type=\"rss\" text=\"$path\" title=\"$path\" xmlUrl=\"$rss\" htmlUrl=\"$html\"/>\n";
7736         }
7737         print <<XML;
7738 </outline>
7739 </body>
7740 </opml>
7741 XML
7742 }