Lady’s Gitweb - Gitweb/blob - gitweb.perl

   1 #!/usr/bin/perl
   2
   3 # gitweb - simple web interface to track changes in git repositories
   4 #
   5 # (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
   6 # (C) 2005, Christian Gierke
   7 #
   8 # This program is licensed under the GPLv2
   9
  10 use 5.008;
  11 use strict;
  12 use warnings;
  13 use CGI qw(:standard :escapeHTML -nosticky);
  14 use CGI::Util qw(unescape);
  15 use CGI::Carp qw(fatalsToBrowser set_message);
  16 use Encode;
  17 use Fcntl ':mode';
  18 use File::Find qw();
  19 use File::Basename qw(basename);
  20 use Time::HiRes qw(gettimeofday tv_interval);
  21 binmode STDOUT, ':utf8';
  22
  23 our $t0 = [ gettimeofday() ];
  24 our $number_of_git_cmds = 0;
  25
  26 BEGIN {
  27         CGI->compile() if $ENV{'MOD_PERL'};
  28 }
  29
  30 our $version = "++GIT_VERSION++";
  31
  32 our ($my_url, $my_uri, $base_url, $path_info, $home_link);
  33 sub evaluate_uri {
  34         our $cgi;
  35
  36         our $my_url = $cgi->url();
  37         our $my_uri = $cgi->url(-absolute => 1);
  38
  39         # Base URL for relative URLs in gitweb ($logo, $favicon, ...),
  40         # needed and used only for URLs with nonempty PATH_INFO
  41         our $base_url = $my_url;
  42
  43         # When the script is used as DirectoryIndex, the URL does not contain the name
  44         # of the script file itself, and $cgi->url() fails to strip PATH_INFO, so we
  45         # have to do it ourselves. We make $path_info global because it's also used
  46         # later on.
  47         #
  48         # Another issue with the script being the DirectoryIndex is that the resulting
  49         # $my_url data is not the full script URL: this is good, because we want
  50         # generated links to keep implying the script name if it wasn't explicitly
  51         # indicated in the URL we're handling, but it means that $my_url cannot be used
  52         # as base URL.
  53         # Therefore, if we needed to strip PATH_INFO, then we know that we have
  54         # to build the base URL ourselves:
  55         our $path_info = decode_utf8($ENV{"PATH_INFO"});
  56         if ($path_info) {
  57                 # $path_info has already been URL-decoded by the web server, but
  58                 # $my_url and $my_uri have not. URL-decode them so we can properly
  59                 # strip $path_info.
  60                 $my_url = unescape($my_url);
  61                 $my_uri = unescape($my_uri);
  62                 if ($my_url =~ s,\Q$path_info\E$,, &&
  63                     $my_uri =~ s,\Q$path_info\E$,, &&
  64                     defined $ENV{'SCRIPT_NAME'}) {
  65                         $base_url = $cgi->url(-base => 1) . $ENV{'SCRIPT_NAME'};
  66                 }
  67         }
  68
  69         # target of the home link on top of all pages
  70         our $home_link = $my_uri || "/";
  71 }
  72
  73 # core git executable to use
  74 # this can just be "git" if your webserver has a sensible PATH
  75 our $GIT = "++GIT_BINDIR++/git";
  76
  77 # absolute fs-path which will be prepended to the project path
  78 #our $projectroot = "/pub/scm";
  79 our $projectroot = "++GITWEB_PROJECTROOT++";
  80
  81 # fs traversing limit for getting project list
  82 # the number is relative to the projectroot
  83 our $project_maxdepth = "++GITWEB_PROJECT_MAXDEPTH++";
  84
  85 # string of the home link on top of all pages
  86 our $home_link_str = "++GITWEB_HOME_LINK_STR++";
  87
  88 # extra breadcrumbs preceding the home link
  89 our @extra_breadcrumbs = ();
  90
  91 # name of your site or organization to appear in page titles
  92 # replace this with something more descriptive for clearer bookmarks
  93 our $site_name = "++GITWEB_SITENAME++"
  94                  || ($ENV{'SERVER_NAME'} || "Untitled") . " Git";
  95
  96 # html snippet to include in the <head> section of each page
  97 our $site_html_head_string = "++GITWEB_SITE_HTML_HEAD_STRING++";
  98 # filename of html text to include at top of each page
  99 our $site_header = "++GITWEB_SITE_HEADER++";
 100 # html text to include at home page
 101 our $home_text = "++GITWEB_HOMETEXT++";
 102 # filename of html text to include at bottom of each page
 103 our $site_footer = "++GITWEB_SITE_FOOTER++";
 104
 105 # URI of stylesheets
 106 our @stylesheets = ("++GITWEB_CSS++");
 107 # URI of a single stylesheet, which can be overridden in GITWEB_CONFIG.
 108 our $stylesheet = undef;
 109
 110 # URI of GIT logo (72x27 size)
 111 our $logo = "++GITWEB_LOGO++";
 112 # URI of GIT favicon, assumed to be image/png type
 113 our $favicon = "++GITWEB_FAVICON++";
 114 # URI of gitweb.js (JavaScript code for gitweb)
 115 our $javascript = "++GITWEB_JS++";
 116
 117 # URI and label (title) of GIT logo link
 118 #our $logo_url = "http://www.kernel.org/pub/software/scm/git/docs/";
 119 #our $logo_label = "git documentation";
 120 our $logo_url = "http://git-scm.com/";
 121 our $logo_label = "git homepage";
 122
 123 # source of projects list
 124 our $projects_list = "++GITWEB_LIST++";
 125
 126 # the width (in characters) of the projects list "Description" column
 127 our $projects_list_description_width = 25;
 128
 129 # group projects by category on the projects list
 130 # (enabled if this variable evaluates to true)
 131 our $projects_list_group_categories = 0;
 132
 133 # default category if none specified
 134 # (leave the empty string for no category)
 135 our $project_list_default_category = "";
 136
 137 # default order of projects list
 138 # valid values are none, project, descr, owner, and age
 139 our $default_projects_order = "project";
 140
 141 # show repository only if this file exists
 142 # (only effective if this variable evaluates to true)
 143 our $export_ok = "++GITWEB_EXPORT_OK++";
 144
 145 # don't generate age column on the projects list page
 146 our $omit_age_column = 0;
 147
 148 # don't generate information about owners of repositories
 149 our $omit_owner=0;
 150
 151 # show repository only if this subroutine returns true
 152 # when given the path to the project, for example:
 153 #    sub { return -e "$_[0]/git-daemon-export-ok"; }
 154 our $export_auth_hook = undef;
 155
 156 # only allow viewing of repositories also shown on the overview page
 157 our $strict_export = "++GITWEB_STRICT_EXPORT++";
 158
 159 # list of git base URLs used for URL to where fetch project from,
 160 # i.e. full URL is "$git_base_url/$project"
 161 our @git_base_url_list = grep { $_ ne '' } ("++GITWEB_BASE_URL++");
 162
 163 # default blob_plain mimetype and default charset for text/plain blob
 164 our $default_blob_plain_mimetype = 'text/plain';
 165 our $default_text_plain_charset  = undef;
 166
 167 # file to use for guessing MIME types before trying /etc/mime.types
 168 # (relative to the current git repository)
 169 our $mimetypes_file = undef;
 170
 171 # assume this charset if line contains non-UTF-8 characters;
 172 # it should be valid encoding (see Encoding::Supported(3pm) for list),
 173 # for which encoding all byte sequences are valid, for example
 174 # 'iso-8859-1' aka 'latin1' (it is decoded without checking, so it
 175 # could be even 'utf-8' for the old behavior)
 176 our $fallback_encoding = 'latin1';
 177
 178 # rename detection options for git-diff and git-diff-tree
 179 # - default is '-M', with the cost proportional to
 180 #   (number of removed files) * (number of new files).
 181 # - more costly is '-C' (which implies '-M'), with the cost proportional to
 182 #   (number of changed files + number of removed files) * (number of new files)
 183 # - even more costly is '-C', '--find-copies-harder' with cost
 184 #   (number of files in the original tree) * (number of new files)
 185 # - one might want to include '-B' option, e.g. '-B', '-M'
 186 our @diff_opts = ('-M'); # taken from git_commit
 187
 188 # Disables features that would allow repository owners to inject script into
 189 # the gitweb domain.
 190 our $prevent_xss = 0;
 191
 192 # Path to the highlight executable to use (must be the one from
 193 # http://www.andre-simon.de due to assumptions about parameters and output).
 194 # Useful if highlight is not installed on your webserver's PATH.
 195 # [Default: highlight]
 196 our $highlight_bin = "++HIGHLIGHT_BIN++";
 197
 198 # information about snapshot formats that gitweb is capable of serving
 199 our %known_snapshot_formats = (
 200         # name => {
 201         #       'display' => display name,
 202         #       'type' => mime type,
 203         #       'suffix' => filename suffix,
 204         #       'format' => --format for git-archive,
 205         #       'compressor' => [compressor command and arguments]
 206         #                       (array reference, optional)
 207         #       'disabled' => boolean (optional)}
 208         #
 209         'tgz' => {
 210                 'display' => 'tar.gz',
 211                 'type' => 'application/x-gzip',
 212                 'suffix' => '.tar.gz',
 213                 'format' => 'tar',
 214                 'compressor' => ['gzip', '-n']},
 215
 216         'tbz2' => {
 217                 'display' => 'tar.bz2',
 218                 'type' => 'application/x-bzip2',
 219                 'suffix' => '.tar.bz2',
 220                 'format' => 'tar',
 221                 'compressor' => ['bzip2']},
 222
 223         'txz' => {
 224                 'display' => 'tar.xz',
 225                 'type' => 'application/x-xz',
 226                 'suffix' => '.tar.xz',
 227                 'format' => 'tar',
 228                 'compressor' => ['xz'],
 229                 'disabled' => 1},
 230
 231         'zip' => {
 232                 'display' => 'zip',
 233                 'type' => 'application/x-zip',
 234                 'suffix' => '.zip',
 235                 'format' => 'zip'},
 236 );
 237
 238 # Aliases so we understand old gitweb.snapshot values in repository
 239 # configuration.
 240 our %known_snapshot_format_aliases = (
 241         'gzip'  => 'tgz',
 242         'bzip2' => 'tbz2',
 243         'xz'    => 'txz',
 244
 245         # backward compatibility: legacy gitweb config support
 246         'x-gzip' => undef, 'gz' => undef,
 247         'x-bzip2' => undef, 'bz2' => undef,
 248         'x-zip' => undef, '' => undef,
 249 );
 250
 251 # Pixel sizes for icons and avatars. If the default font sizes or lineheights
 252 # are changed, it may be appropriate to change these values too via
 253 # $GITWEB_CONFIG.
 254 our %avatar_size = (
 255         'default' => 16,
 256         'double'  => 32
 257 );
 258
 259 # Used to set the maximum load that we will still respond to gitweb queries.
 260 # If server load exceed this value then return "503 server busy" error.
 261 # If gitweb cannot determined server load, it is taken to be 0.
 262 # Leave it undefined (or set to 'undef') to turn off load checking.
 263 our $maxload = 300;
 264
 265 # configuration for 'highlight' (http://www.andre-simon.de/)
 266 # match by basename
 267 our %highlight_basename = (
 268         #'Program' => 'py',
 269         #'Library' => 'py',
 270         'SConstruct' => 'py', # SCons equivalent of Makefile
 271         'Makefile' => 'make',
 272 );
 273 # match by extension
 274 our %highlight_ext = (
 275         # main extensions, defining name of syntax;
 276         # see files in /usr/share/highlight/langDefs/ directory
 277         (map { $_ => $_ } qw(py rb java css js tex bib xml awk bat ini spec tcl sql)),
 278         # alternate extensions, see /etc/highlight/filetypes.conf
 279         (map { $_ => 'c'   } qw(c h)),
 280         (map { $_ => 'sh'  } qw(sh bash zsh ksh)),
 281         (map { $_ => 'cpp' } qw(cpp cxx c++ cc)),
 282         (map { $_ => 'php' } qw(php php3 php4 php5 phps)),
 283         (map { $_ => 'pl'  } qw(pl perl pm)), # perhaps also 'cgi'
 284         (map { $_ => 'make'} qw(make mak mk)),
 285         (map { $_ => 'xml' } qw(xml xhtml html htm)),
 286 );
 287
 288 # You define site-wide feature defaults here; override them with
 289 # $GITWEB_CONFIG as necessary.
 290 our %feature = (
 291         # feature => {
 292         #       'sub' => feature-sub (subroutine),
 293         #       'override' => allow-override (boolean),
 294         #       'default' => [ default options...] (array reference)}
 295         #
 296         # if feature is overridable (it means that allow-override has true value),
 297         # then feature-sub will be called with default options as parameters;
 298         # return value of feature-sub indicates if to enable specified feature
 299         #
 300         # if there is no 'sub' key (no feature-sub), then feature cannot be
 301         # overridden
 302         #
 303         # use gitweb_get_feature(<feature>) to retrieve the <feature> value
 304         # (an array) or gitweb_check_feature(<feature>) to check if <feature>
 305         # is enabled
 306
 307         # Enable the 'blame' blob view, showing the last commit that modified
 308         # each line in the file. This can be very CPU-intensive.
 309
 310         # To enable system wide have in $GITWEB_CONFIG
 311         # $feature{'blame'}{'default'} = [1];
 312         # To have project specific config enable override in $GITWEB_CONFIG
 313         # $feature{'blame'}{'override'} = 1;
 314         # and in project config gitweb.blame = 0|1;
 315         'blame' => {
 316                 'sub' => sub { feature_bool('blame', @_) },
 317                 'override' => 0,
 318                 'default' => [0]},
 319
 320         # Enable the 'snapshot' link, providing a compressed archive of any
 321         # tree. This can potentially generate high traffic if you have large
 322         # project.
 323
 324         # Value is a list of formats defined in %known_snapshot_formats that
 325         # you wish to offer.
 326         # To disable system wide have in $GITWEB_CONFIG
 327         # $feature{'snapshot'}{'default'} = [];
 328         # To have project specific config enable override in $GITWEB_CONFIG
 329         # $feature{'snapshot'}{'override'} = 1;
 330         # and in project config, a comma-separated list of formats or "none"
 331         # to disable.  Example: gitweb.snapshot = tbz2,zip;
 332         'snapshot' => {
 333                 'sub' => \&feature_snapshot,
 334                 'override' => 0,
 335                 'default' => ['tgz']},
 336
 337         # Enable text search, which will list the commits which match author,
 338         # committer or commit text to a given string.  Enabled by default.
 339         # Project specific override is not supported.
 340         #
 341         # Note that this controls all search features, which means that if
 342         # it is disabled, then 'grep' and 'pickaxe' search would also be
 343         # disabled.
 344         'search' => {
 345                 'override' => 0,
 346                 'default' => [1]},
 347
 348         # Enable grep search, which will list the files in currently selected
 349         # tree containing the given string. Enabled by default. This can be
 350         # potentially CPU-intensive, of course.
 351         # Note that you need to have 'search' feature enabled too.
 352
 353         # To enable system wide have in $GITWEB_CONFIG
 354         # $feature{'grep'}{'default'} = [1];
 355         # To have project specific config enable override in $GITWEB_CONFIG
 356         # $feature{'grep'}{'override'} = 1;
 357         # and in project config gitweb.grep = 0|1;
 358         'grep' => {
 359                 'sub' => sub { feature_bool('grep', @_) },
 360                 'override' => 0,
 361                 'default' => [1]},
 362
 363         # Enable the pickaxe search, which will list the commits that modified
 364         # a given string in a file. This can be practical and quite faster
 365         # alternative to 'blame', but still potentially CPU-intensive.
 366         # Note that you need to have 'search' feature enabled too.
 367
 368         # To enable system wide have in $GITWEB_CONFIG
 369         # $feature{'pickaxe'}{'default'} = [1];
 370         # To have project specific config enable override in $GITWEB_CONFIG
 371         # $feature{'pickaxe'}{'override'} = 1;
 372         # and in project config gitweb.pickaxe = 0|1;
 373         'pickaxe' => {
 374                 'sub' => sub { feature_bool('pickaxe', @_) },
 375                 'override' => 0,
 376                 'default' => [1]},
 377
 378         # Enable showing size of blobs in a 'tree' view, in a separate
 379         # column, similar to what 'ls -l' does.  This cost a bit of IO.
 380
 381         # To disable system wide have in $GITWEB_CONFIG
 382         # $feature{'show-sizes'}{'default'} = [0];
 383         # To have project specific config enable override in $GITWEB_CONFIG
 384         # $feature{'show-sizes'}{'override'} = 1;
 385         # and in project config gitweb.showsizes = 0|1;
 386         'show-sizes' => {
 387                 'sub' => sub { feature_bool('showsizes', @_) },
 388                 'override' => 0,
 389                 'default' => [1]},
 390
 391         # Make gitweb use an alternative format of the URLs which can be
 392         # more readable and natural-looking: project name is embedded
 393         # directly in the path and the query string contains other
 394         # auxiliary information. All gitweb installations recognize
 395         # URL in either format; this configures in which formats gitweb
 396         # generates links.
 397
 398         # To enable system wide have in $GITWEB_CONFIG
 399         # $feature{'pathinfo'}{'default'} = [1];
 400         # Project specific override is not supported.
 401
 402         # Note that you will need to change the default location of CSS,
 403         # favicon, logo and possibly other files to an absolute URL. Also,
 404         # if gitweb.cgi serves as your indexfile, you will need to force
 405         # $my_uri to contain the script name in your $GITWEB_CONFIG.
 406         'pathinfo' => {
 407                 'override' => 0,
 408                 'default' => [0]},
 409
 410         # Make gitweb consider projects in project root subdirectories
 411         # to be forks of existing projects. Given project $projname.git,
 412         # projects matching $projname/*.git will not be shown in the main
 413         # projects list, instead a '+' mark will be added to $projname
 414         # there and a 'forks' view will be enabled for the project, listing
 415         # all the forks. If project list is taken from a file, forks have
 416         # to be listed after the main project.
 417
 418         # To enable system wide have in $GITWEB_CONFIG
 419         # $feature{'forks'}{'default'} = [1];
 420         # Project specific override is not supported.
 421         'forks' => {
 422                 'override' => 0,
 423                 'default' => [0]},
 424
 425         # Insert custom links to the action bar of all project pages.
 426         # This enables you mainly to link to third-party scripts integrating
 427         # into gitweb; e.g. git-browser for graphical history representation
 428         # or custom web-based repository administration interface.
 429
 430         # The 'default' value consists of a list of triplets in the form
 431         # (label, link, position) where position is the label after which
 432         # to insert the link and link is a format string where %n expands
 433         # to the project name, %f to the project path within the filesystem,
 434         # %h to the current hash (h gitweb parameter) and %b to the current
 435         # hash base (hb gitweb parameter); %% expands to %.
 436
 437         # To enable system wide have in $GITWEB_CONFIG e.g.
 438         # $feature{'actions'}{'default'} = [('graphiclog',
 439         #       '/git-browser/by-commit.html?r=%n', 'summary')];
 440         # Project specific override is not supported.
 441         'actions' => {
 442                 'override' => 0,
 443                 'default' => []},
 444
 445         # Allow gitweb scan project content tags of project repository,
 446         # and display the popular Web 2.0-ish "tag cloud" near the projects
 447         # list.  Note that this is something COMPLETELY different from the
 448         # normal Git tags.
 449
 450         # gitweb by itself can show existing tags, but it does not handle
 451         # tagging itself; you need to do it externally, outside gitweb.
 452         # The format is described in git_get_project_ctags() subroutine.
 453         # You may want to install the HTML::TagCloud Perl module to get
 454         # a pretty tag cloud instead of just a list of tags.
 455
 456         # To enable system wide have in $GITWEB_CONFIG
 457         # $feature{'ctags'}{'default'} = [1];
 458         # Project specific override is not supported.
 459
 460         # In the future whether ctags editing is enabled might depend
 461         # on the value, but using 1 should always mean no editing of ctags.
 462         'ctags' => {
 463                 'override' => 0,
 464                 'default' => [0]},
 465
 466         # The maximum number of patches in a patchset generated in patch
 467         # view. Set this to 0 or undef to disable patch view, or to a
 468         # negative number to remove any limit.
 469
 470         # To disable system wide have in $GITWEB_CONFIG
 471         # $feature{'patches'}{'default'} = [0];
 472         # To have project specific config enable override in $GITWEB_CONFIG
 473         # $feature{'patches'}{'override'} = 1;
 474         # and in project config gitweb.patches = 0|n;
 475         # where n is the maximum number of patches allowed in a patchset.
 476         'patches' => {
 477                 'sub' => \&feature_patches,
 478                 'override' => 0,
 479                 'default' => [16]},
 480
 481         # Avatar support. When this feature is enabled, views such as
 482         # shortlog or commit will display an avatar associated with
 483         # the email of the committer(s) and/or author(s).
 484
 485         # Currently available providers are gravatar and picon.
 486         # If an unknown provider is specified, the feature is disabled.
 487
 488         # Gravatar depends on Digest::MD5.
 489         # Picon currently relies on the indiana.edu database.
 490
 491         # To enable system wide have in $GITWEB_CONFIG
 492         # $feature{'avatar'}{'default'} = ['<provider>'];
 493         # where <provider> is either gravatar or picon.
 494         # To have project specific config enable override in $GITWEB_CONFIG
 495         # $feature{'avatar'}{'override'} = 1;
 496         # and in project config gitweb.avatar = <provider>;
 497         'avatar' => {
 498                 'sub' => \&feature_avatar,
 499                 'override' => 0,
 500                 'default' => ['']},
 501
 502         # Enable displaying how much time and how many git commands
 503         # it took to generate and display page.  Disabled by default.
 504         # Project specific override is not supported.
 505         'timed' => {
 506                 'override' => 0,
 507                 'default' => [0]},
 508
 509         # Enable turning some links into links to actions which require
 510         # JavaScript to run (like 'blame_incremental').  Not enabled by
 511         # default.  Project specific override is currently not supported.
 512         'javascript-actions' => {
 513                 'override' => 0,
 514                 'default' => [0]},
 515
 516         # Enable and configure ability to change common timezone for dates
 517         # in gitweb output via JavaScript.  Enabled by default.
 518         # Project specific override is not supported.
 519         'javascript-timezone' => {
 520                 'override' => 0,
 521                 'default' => [
 522                         'local',     # default timezone: 'utc', 'local', or '(-|+)HHMM' format,
 523                                      # or undef to turn off this feature
 524                         'gitweb_tz', # name of cookie where to store selected timezone
 525                         'datetime',  # CSS class used to mark up dates for manipulation
 526                 ]},
 527
 528         # Syntax highlighting support. This is based on Daniel Svensson's
 529         # and Sham Chukoury's work in gitweb-xmms2.git.
 530         # It requires the 'highlight' program present in $PATH,
 531         # and therefore is disabled by default.
 532
 533         # To enable system wide have in $GITWEB_CONFIG
 534         # $feature{'highlight'}{'default'} = [1];
 535
 536         'highlight' => {
 537                 'sub' => sub { feature_bool('highlight', @_) },
 538                 'override' => 0,
 539                 'default' => [0]},
 540
 541         # Enable displaying of remote heads in the heads list
 542
 543         # To enable system wide have in $GITWEB_CONFIG
 544         # $feature{'remote_heads'}{'default'} = [1];
 545         # To have project specific config enable override in $GITWEB_CONFIG
 546         # $feature{'remote_heads'}{'override'} = 1;
 547         # and in project config gitweb.remoteheads = 0|1;
 548         'remote_heads' => {
 549                 'sub' => sub { feature_bool('remote_heads', @_) },
 550                 'override' => 0,
 551                 'default' => [0]},
 552 );
 553
 554 sub gitweb_get_feature {
 555         my ($name) = @_;
 556         return unless exists $feature{$name};
 557         my ($sub, $override, @defaults) = (
 558                 $feature{$name}{'sub'},
 559                 $feature{$name}{'override'},
 560                 @{$feature{$name}{'default'}});
 561         # project specific override is possible only if we have project
 562         our $git_dir; # global variable, declared later
 563         if (!$override || !defined $git_dir) {
 564                 return @defaults;
 565         }
 566         if (!defined $sub) {
 567                 warn "feature $name is not overridable";
 568                 return @defaults;
 569         }
 570         return $sub->(@defaults);
 571 }
 572
 573 # A wrapper to check if a given feature is enabled.
 574 # With this, you can say
 575 #
 576 #   my $bool_feat = gitweb_check_feature('bool_feat');
 577 #   gitweb_check_feature('bool_feat') or somecode;
 578 #
 579 # instead of
 580 #
 581 #   my ($bool_feat) = gitweb_get_feature('bool_feat');
 582 #   (gitweb_get_feature('bool_feat'))[0] or somecode;
 583 #
 584 sub gitweb_check_feature {
 585         return (gitweb_get_feature(@_))[0];
 586 }
 587
 588
 589 sub feature_bool {
 590         my $key = shift;
 591         my ($val) = git_get_project_config($key, '--bool');
 592
 593         if (!defined $val) {
 594                 return ($_[0]);
 595         } elsif ($val eq 'true') {
 596                 return (1);
 597         } elsif ($val eq 'false') {
 598                 return (0);
 599         }
 600 }
 601
 602 sub feature_snapshot {
 603         my (@fmts) = @_;
 604
 605         my ($val) = git_get_project_config('snapshot');
 606
 607         if ($val) {
 608                 @fmts = ($val eq 'none' ? () : split /\s*[,\s]\s*/, $val);
 609         }
 610
 611         return @fmts;
 612 }
 613
 614 sub feature_patches {
 615         my @val = (git_get_project_config('patches', '--int'));
 616
 617         if (@val) {
 618                 return @val;
 619         }
 620
 621         return ($_[0]);
 622 }
 623
 624 sub feature_avatar {
 625         my @val = (git_get_project_config('avatar'));
 626
 627         return @val ? @val : @_;
 628 }
 629
 630 # checking HEAD file with -e is fragile if the repository was
 631 # initialized long time ago (i.e. symlink HEAD) and was pack-ref'ed
 632 # and then pruned.
 633 sub check_head_link {
 634         my ($dir) = @_;
 635         my $headfile = "$dir/HEAD";
 636         return ((-e $headfile) ||
 637                 (-l $headfile && readlink($headfile) =~ /^refs\/heads\//));
 638 }
 639
 640 sub check_export_ok {
 641         my ($dir) = @_;
 642         return (check_head_link($dir) &&
 643                 (!$export_ok || -e "$dir/$export_ok") &&
 644                 (!$export_auth_hook || $export_auth_hook->($dir)));
 645 }
 646
 647 # process alternate names for backward compatibility
 648 # filter out unsupported (unknown) snapshot formats
 649 sub filter_snapshot_fmts {
 650         my @fmts = @_;
 651
 652         @fmts = map {
 653                 exists $known_snapshot_format_aliases{$_} ?
 654                        $known_snapshot_format_aliases{$_} : $_} @fmts;
 655         @fmts = grep {
 656                 exists $known_snapshot_formats{$_} &&
 657                 !$known_snapshot_formats{$_}{'disabled'}} @fmts;
 658 }
 659
 660 # If it is set to code reference, it is code that it is to be run once per
 661 # request, allowing updating configurations that change with each request,
 662 # while running other code in config file only once.
 663 #
 664 # Otherwise, if it is false then gitweb would process config file only once;
 665 # if it is true then gitweb config would be run for each request.
 666 our $per_request_config = 1;
 667
 668 # read and parse gitweb config file given by its parameter.
 669 # returns true on success, false on recoverable error, allowing
 670 # to chain this subroutine, using first file that exists.
 671 # dies on errors during parsing config file, as it is unrecoverable.
 672 sub read_config_file {
 673         my $filename = shift;
 674         return unless defined $filename;
 675         # die if there are errors parsing config file
 676         if (-e $filename) {
 677                 do $filename;
 678                 die $@ if $@;
 679                 return 1;
 680         }
 681         return;
 682 }
 683
 684 our ($GITWEB_CONFIG, $GITWEB_CONFIG_SYSTEM, $GITWEB_CONFIG_COMMON);
 685 sub evaluate_gitweb_config {
 686         our $GITWEB_CONFIG = $ENV{'GITWEB_CONFIG'} || "++GITWEB_CONFIG++";
 687         our $GITWEB_CONFIG_SYSTEM = $ENV{'GITWEB_CONFIG_SYSTEM'} || "++GITWEB_CONFIG_SYSTEM++";
 688         our $GITWEB_CONFIG_COMMON = $ENV{'GITWEB_CONFIG_COMMON'} || "++GITWEB_CONFIG_COMMON++";
 689
 690         # Protect against duplications of file names, to not read config twice.
 691         # Only one of $GITWEB_CONFIG and $GITWEB_CONFIG_SYSTEM is used, so
 692         # there possibility of duplication of filename there doesn't matter.
 693         $GITWEB_CONFIG = ""        if ($GITWEB_CONFIG eq $GITWEB_CONFIG_COMMON);
 694         $GITWEB_CONFIG_SYSTEM = "" if ($GITWEB_CONFIG_SYSTEM eq $GITWEB_CONFIG_COMMON);
 695
 696         # Common system-wide settings for convenience.
 697         # Those settings can be ovverriden by GITWEB_CONFIG or GITWEB_CONFIG_SYSTEM.
 698         read_config_file($GITWEB_CONFIG_COMMON);
 699
 700         # Use first config file that exists.  This means use the per-instance
 701         # GITWEB_CONFIG if exists, otherwise use GITWEB_SYSTEM_CONFIG.
 702         read_config_file($GITWEB_CONFIG) and return;
 703         read_config_file($GITWEB_CONFIG_SYSTEM);
 704 }
 705
 706 # Get loadavg of system, to compare against $maxload.
 707 # Currently it requires '/proc/loadavg' present to get loadavg;
 708 # if it is not present it returns 0, which means no load checking.
 709 sub get_loadavg {
 710         if( -e '/proc/loadavg' ){
 711                 open my $fd, '<', '/proc/loadavg'
 712                         or return 0;
 713                 my @load = split(/\s+/, scalar <$fd>);
 714                 close $fd;
 715
 716                 # The first three columns measure CPU and IO utilization of the last one,
 717                 # five, and 10 minute periods.  The fourth column shows the number of
 718                 # currently running processes and the total number of processes in the m/n
 719                 # format.  The last column displays the last process ID used.
 720                 return $load[0] || 0;
 721         }
 722         # additional checks for load average should go here for things that don't export
 723         # /proc/loadavg
 724
 725         return 0;
 726 }
 727
 728 # version of the core git binary
 729 our $git_version;
 730 sub evaluate_git_version {
 731         our $git_version = qx("$GIT" --version) =~ m/git version (.*)$/ ? $1 : "unknown";
 732         $number_of_git_cmds++;
 733 }
 734
 735 sub check_loadavg {
 736         if (defined $maxload && get_loadavg() > $maxload) {
 737                 die_error(503, "The load average on the server is too high");
 738         }
 739 }
 740
 741 # ======================================================================
 742 # input validation and dispatch
 743
 744 # input parameters can be collected from a variety of sources (presently, CGI
 745 # and PATH_INFO), so we define an %input_params hash that collects them all
 746 # together during validation: this allows subsequent uses (e.g. href()) to be
 747 # agnostic of the parameter origin
 748
 749 our %input_params = ();
 750
 751 # input parameters are stored with the long parameter name as key. This will
 752 # also be used in the href subroutine to convert parameters to their CGI
 753 # equivalent, and since the href() usage is the most frequent one, we store
 754 # the name -> CGI key mapping here, instead of the reverse.
 755 #
 756 # XXX: Warning: If you touch this, check the search form for updating,
 757 # too.
 758
 759 our @cgi_param_mapping = (
 760         project => "p",
 761         action => "a",
 762         file_name => "f",
 763         file_parent => "fp",
 764         hash => "h",
 765         hash_parent => "hp",
 766         hash_base => "hb",
 767         hash_parent_base => "hpb",
 768         page => "pg",
 769         order => "o",
 770         searchtext => "s",
 771         searchtype => "st",
 772         snapshot_format => "sf",
 773         extra_options => "opt",
 774         search_use_regexp => "sr",
 775         ctag => "by_tag",
 776         diff_style => "ds",
 777         project_filter => "pf",
 778         # this must be last entry (for manipulation from JavaScript)
 779         javascript => "js"
 780 );
 781 our %cgi_param_mapping = @cgi_param_mapping;
 782
 783 # we will also need to know the possible actions, for validation
 784 our %actions = (
 785         "blame" => \&git_blame,
 786         "blame_incremental" => \&git_blame_incremental,
 787         "blame_data" => \&git_blame_data,
 788         "blobdiff" => \&git_blobdiff,
 789         "blobdiff_plain" => \&git_blobdiff_plain,
 790         "blob" => \&git_blob,
 791         "blob_plain" => \&git_blob_plain,
 792         "commitdiff" => \&git_commitdiff,
 793         "commitdiff_plain" => \&git_commitdiff_plain,
 794         "commit" => \&git_commit,
 795         "forks" => \&git_forks,
 796         "heads" => \&git_heads,
 797         "history" => \&git_history,
 798         "log" => \&git_log,
 799         "patch" => \&git_patch,
 800         "patches" => \&git_patches,
 801         "remotes" => \&git_remotes,
 802         "rss" => \&git_rss,
 803         "atom" => \&git_atom,
 804         "search" => \&git_search,
 805         "search_help" => \&git_search_help,
 806         "shortlog" => \&git_shortlog,
 807         "summary" => \&git_summary,
 808         "tag" => \&git_tag,
 809         "tags" => \&git_tags,
 810         "tree" => \&git_tree,
 811         "snapshot" => \&git_snapshot,
 812         "object" => \&git_object,
 813         # those below don't need $project
 814         "opml" => \&git_opml,
 815         "project_list" => \&git_project_list,
 816         "project_index" => \&git_project_index,
 817 );
 818
 819 # finally, we have the hash of allowed extra_options for the commands that
 820 # allow them
 821 our %allowed_options = (
 822         "--no-merges" => [ qw(rss atom log shortlog history) ],
 823 );
 824
 825 # fill %input_params with the CGI parameters. All values except for 'opt'
 826 # should be single values, but opt can be an array. We should probably
 827 # build an array of parameters that can be multi-valued, but since for the time
 828 # being it's only this one, we just single it out
 829 sub evaluate_query_params {
 830         our $cgi;
 831
 832         while (my ($name, $symbol) = each %cgi_param_mapping) {
 833                 if ($symbol eq 'opt') {
 834                         $input_params{$name} = [ map { decode_utf8($_) } $cgi->param($symbol) ];
 835                 } else {
 836                         $input_params{$name} = decode_utf8($cgi->param($symbol));
 837                 }
 838         }
 839 }
 840
 841 # now read PATH_INFO and update the parameter list for missing parameters
 842 sub evaluate_path_info {
 843         return if defined $input_params{'project'};
 844         return if !$path_info;
 845         $path_info =~ s,^/+,,;
 846         return if !$path_info;
 847
 848         # find which part of PATH_INFO is project
 849         my $project = $path_info;
 850         $project =~ s,/+$,,;
 851         while ($project && !check_head_link("$projectroot/$project")) {
 852                 $project =~ s,/*[^/]*$,,;
 853         }
 854         return unless $project;
 855         $input_params{'project'} = $project;
 856
 857         # do not change any parameters if an action is given using the query string
 858         return if $input_params{'action'};
 859         $path_info =~ s,^\Q$project\E/*,,;
 860
 861         # next, check if we have an action
 862         my $action = $path_info;
 863         $action =~ s,/.*$,,;
 864         if (exists $actions{$action}) {
 865                 $path_info =~ s,^$action/*,,;
 866                 $input_params{'action'} = $action;
 867         }
 868
 869         # list of actions that want hash_base instead of hash, but can have no
 870         # pathname (f) parameter
 871         my @wants_base = (
 872                 'tree',
 873                 'history',
 874         );
 875
 876         # we want to catch, among others
 877         # [$hash_parent_base[:$file_parent]..]$hash_parent[:$file_name]
 878         my ($parentrefname, $parentpathname, $refname, $pathname) =
 879                 ($path_info =~ /^(?:(.+?)(?::(.+))?\.\.)?([^:]+?)?(?::(.+))?$/);
 880
 881         # first, analyze the 'current' part
 882         if (defined $pathname) {
 883                 # we got "branch:filename" or "branch:dir/"
 884                 # we could use git_get_type(branch:pathname), but:
 885                 # - it needs $git_dir
 886                 # - it does a git() call
 887                 # - the convention of terminating directories with a slash
 888                 #   makes it superfluous
 889                 # - embedding the action in the PATH_INFO would make it even
 890                 #   more superfluous
 891                 $pathname =~ s,^/+,,;
 892                 if (!$pathname || substr($pathname, -1) eq "/") {
 893                         $input_params{'action'} ||= "tree";
 894                         $pathname =~ s,/$,,;
 895                 } else {
 896                         # the default action depends on whether we had parent info
 897                         # or not
 898                         if ($parentrefname) {
 899                                 $input_params{'action'} ||= "blobdiff_plain";
 900                         } else {
 901                                 $input_params{'action'} ||= "blob_plain";
 902                         }
 903                 }
 904                 $input_params{'hash_base'} ||= $refname;
 905                 $input_params{'file_name'} ||= $pathname;
 906         } elsif (defined $refname) {
 907                 # we got "branch". In this case we have to choose if we have to
 908                 # set hash or hash_base.
 909                 #
 910                 # Most of the actions without a pathname only want hash to be
 911                 # set, except for the ones specified in @wants_base that want
 912                 # hash_base instead. It should also be noted that hand-crafted
 913                 # links having 'history' as an action and no pathname or hash
 914                 # set will fail, but that happens regardless of PATH_INFO.
 915                 if (defined $parentrefname) {
 916                         # if there is parent let the default be 'shortlog' action
 917                         # (for http://git.example.com/repo.git/A..B links); if there
 918                         # is no parent, dispatch will detect type of object and set
 919                         # action appropriately if required (if action is not set)
 920                         $input_params{'action'} ||= "shortlog";
 921                 }
 922                 if ($input_params{'action'} &&
 923                     grep { $_ eq $input_params{'action'} } @wants_base) {
 924                         $input_params{'hash_base'} ||= $refname;
 925                 } else {
 926                         $input_params{'hash'} ||= $refname;
 927                 }
 928         }
 929
 930         # next, handle the 'parent' part, if present
 931         if (defined $parentrefname) {
 932                 # a missing pathspec defaults to the 'current' filename, allowing e.g.
 933                 # someproject/blobdiff/oldrev..newrev:/filename
 934                 if ($parentpathname) {
 935                         $parentpathname =~ s,^/+,,;
 936                         $parentpathname =~ s,/$,,;
 937                         $input_params{'file_parent'} ||= $parentpathname;
 938                 } else {
 939                         $input_params{'file_parent'} ||= $input_params{'file_name'};
 940                 }
 941                 # we assume that hash_parent_base is wanted if a path was specified,
 942                 # or if the action wants hash_base instead of hash
 943                 if (defined $input_params{'file_parent'} ||
 944                         grep { $_ eq $input_params{'action'} } @wants_base) {
 945                         $input_params{'hash_parent_base'} ||= $parentrefname;
 946                 } else {
 947                         $input_params{'hash_parent'} ||= $parentrefname;
 948                 }
 949         }
 950
 951         # for the snapshot action, we allow URLs in the form
 952         # $project/snapshot/$hash.ext
 953         # where .ext determines the snapshot and gets removed from the
 954         # passed $refname to provide the $hash.
 955         #
 956         # To be able to tell that $refname includes the format extension, we
 957         # require the following two conditions to be satisfied:
 958         # - the hash input parameter MUST have been set from the $refname part
 959         #   of the URL (i.e. they must be equal)
 960         # - the snapshot format MUST NOT have been defined already (e.g. from
 961         #   CGI parameter sf)
 962         # It's also useless to try any matching unless $refname has a dot,
 963         # so we check for that too
 964         if (defined $input_params{'action'} &&
 965                 $input_params{'action'} eq 'snapshot' &&
 966                 defined $refname && index($refname, '.') != -1 &&
 967                 $refname eq $input_params{'hash'} &&
 968                 !defined $input_params{'snapshot_format'}) {
 969                 # We loop over the known snapshot formats, checking for
 970                 # extensions. Allowed extensions are both the defined suffix
 971                 # (which includes the initial dot already) and the snapshot
 972                 # format key itself, with a prepended dot
 973                 while (my ($fmt, $opt) = each %known_snapshot_formats) {
 974                         my $hash = $refname;
 975                         unless ($hash =~ s/(\Q$opt->{'suffix'}\E|\Q.$fmt\E)$//) {
 976                                 next;
 977                         }
 978                         my $sfx = $1;
 979                         # a valid suffix was found, so set the snapshot format
 980                         # and reset the hash parameter
 981                         $input_params{'snapshot_format'} = $fmt;
 982                         $input_params{'hash'} = $hash;
 983                         # we also set the format suffix to the one requested
 984                         # in the URL: this way a request for e.g. .tgz returns
 985                         # a .tgz instead of a .tar.gz
 986                         $known_snapshot_formats{$fmt}{'suffix'} = $sfx;
 987                         last;
 988                 }
 989         }
 990 }
 991
 992 our ($action, $project, $file_name, $file_parent, $hash, $hash_parent, $hash_base,
 993      $hash_parent_base, @extra_options, $page, $searchtype, $search_use_regexp,
 994      $searchtext, $search_regexp, $project_filter);
 995 sub evaluate_and_validate_params {
 996         our $action = $input_params{'action'};
 997         if (defined $action) {
 998                 if (!validate_action($action)) {
 999                         die_error(400, "Invalid action parameter");
1000                 }
1001         }
1002
1003         # parameters which are pathnames
1004         our $project = $input_params{'project'};
1005         if (defined $project) {
1006                 if (!validate_project($project)) {
1007                         undef $project;
1008                         die_error(404, "No such project");
1009                 }
1010         }
1011
1012         our $project_filter = $input_params{'project_filter'};
1013         if (defined $project_filter) {
1014                 if (!validate_pathname($project_filter)) {
1015                         die_error(404, "Invalid project_filter parameter");
1016                 }
1017         }
1018
1019         our $file_name = $input_params{'file_name'};
1020         if (defined $file_name) {
1021                 if (!validate_pathname($file_name)) {
1022                         die_error(400, "Invalid file parameter");
1023                 }
1024         }
1025
1026         our $file_parent = $input_params{'file_parent'};
1027         if (defined $file_parent) {
1028                 if (!validate_pathname($file_parent)) {
1029                         die_error(400, "Invalid file parent parameter");
1030                 }
1031         }
1032
1033         # parameters which are refnames
1034         our $hash = $input_params{'hash'};
1035         if (defined $hash) {
1036                 if (!validate_refname($hash)) {
1037                         die_error(400, "Invalid hash parameter");
1038                 }
1039         }
1040
1041         our $hash_parent = $input_params{'hash_parent'};
1042         if (defined $hash_parent) {
1043                 if (!validate_refname($hash_parent)) {
1044                         die_error(400, "Invalid hash parent parameter");
1045                 }
1046         }
1047
1048         our $hash_base = $input_params{'hash_base'};
1049         if (defined $hash_base) {
1050                 if (!validate_refname($hash_base)) {
1051                         die_error(400, "Invalid hash base parameter");
1052                 }
1053         }
1054
1055         our @extra_options = @{$input_params{'extra_options'}};
1056         # @extra_options is always defined, since it can only be (currently) set from
1057         # CGI, and $cgi->param() returns the empty array in array context if the param
1058         # is not set
1059         foreach my $opt (@extra_options) {
1060                 if (not exists $allowed_options{$opt}) {
1061                         die_error(400, "Invalid option parameter");
1062                 }
1063                 if (not grep(/^$action$/, @{$allowed_options{$opt}})) {
1064                         die_error(400, "Invalid option parameter for this action");
1065                 }
1066         }
1067
1068         our $hash_parent_base = $input_params{'hash_parent_base'};
1069         if (defined $hash_parent_base) {
1070                 if (!validate_refname($hash_parent_base)) {
1071                         die_error(400, "Invalid hash parent base parameter");
1072                 }
1073         }
1074
1075         # other parameters
1076         our $page = $input_params{'page'};
1077         if (defined $page) {
1078                 if ($page =~ m/[^0-9]/) {
1079                         die_error(400, "Invalid page parameter");
1080                 }
1081         }
1082
1083         our $searchtype = $input_params{'searchtype'};
1084         if (defined $searchtype) {
1085                 if ($searchtype =~ m/[^a-z]/) {
1086                         die_error(400, "Invalid searchtype parameter");
1087                 }
1088         }
1089
1090         our $search_use_regexp = $input_params{'search_use_regexp'};
1091
1092         our $searchtext = $input_params{'searchtext'};
1093         our $search_regexp = undef;
1094         if (defined $searchtext) {
1095                 if (length($searchtext) < 2) {
1096                         die_error(403, "At least two characters are required for search parameter");
1097                 }
1098                 if ($search_use_regexp) {
1099                         $search_regexp = $searchtext;
1100                         if (!eval { qr/$search_regexp/; 1; }) {
1101                                 (my $error = $@) =~ s/ at \S+ line \d+.*\n?//;
1102                                 die_error(400, "Invalid search regexp '$search_regexp'",
1103                                           esc_html($error));
1104                         }
1105                 } else {
1106                         $search_regexp = quotemeta $searchtext;
1107                 }
1108         }
1109 }
1110
1111 # path to the current git repository
1112 our $git_dir;
1113 sub evaluate_git_dir {
1114         our $git_dir = "$projectroot/$project" if $project;
1115 }
1116
1117 our (@snapshot_fmts, $git_avatar);
1118 sub configure_gitweb_features {
1119         # list of supported snapshot formats
1120         our @snapshot_fmts = gitweb_get_feature('snapshot');
1121         @snapshot_fmts = filter_snapshot_fmts(@snapshot_fmts);
1122
1123         # check that the avatar feature is set to a known provider name,
1124         # and for each provider check if the dependencies are satisfied.
1125         # if the provider name is invalid or the dependencies are not met,
1126         # reset $git_avatar to the empty string.
1127         our ($git_avatar) = gitweb_get_feature('avatar');
1128         if ($git_avatar eq 'gravatar') {
1129                 $git_avatar = '' unless (eval { require Digest::MD5; 1; });
1130         } elsif ($git_avatar eq 'picon') {
1131                 # no dependencies
1132         } else {
1133                 $git_avatar = '';
1134         }
1135 }
1136
1137 # custom error handler: 'die <message>' is Internal Server Error
1138 sub handle_errors_html {
1139         my $msg = shift; # it is already HTML escaped
1140
1141         # to avoid infinite loop where error occurs in die_error,
1142         # change handler to default handler, disabling handle_errors_html
1143         set_message("Error occurred when inside die_error:\n$msg");
1144
1145         # you cannot jump out of die_error when called as error handler;
1146         # the subroutine set via CGI::Carp::set_message is called _after_
1147         # HTTP headers are already written, so it cannot write them itself
1148         die_error(undef, undef, $msg, -error_handler => 1, -no_http_header => 1);
1149 }
1150 set_message(\&handle_errors_html);
1151
1152 # dispatch
1153 sub dispatch {
1154         if (!defined $action) {
1155                 if (defined $hash) {
1156                         $action = git_get_type($hash);
1157                         $action or die_error(404, "Object does not exist");
1158                 } elsif (defined $hash_base && defined $file_name) {
1159                         $action = git_get_type("$hash_base:$file_name");
1160                         $action or die_error(404, "File or directory does not exist");
1161                 } elsif (defined $project) {
1162                         $action = 'summary';
1163                 } else {
1164                         $action = 'project_list';
1165                 }
1166         }
1167         if (!defined($actions{$action})) {
1168                 die_error(400, "Unknown action");
1169         }
1170         if ($action !~ m/^(?:opml|project_list|project_index)$/ &&
1171             !$project) {
1172                 die_error(400, "Project needed");
1173         }
1174         $actions{$action}->();
1175 }
1176
1177 sub reset_timer {
1178         our $t0 = [ gettimeofday() ]
1179                 if defined $t0;
1180         our $number_of_git_cmds = 0;
1181 }
1182
1183 our $first_request = 1;
1184 sub run_request {
1185         reset_timer();
1186
1187         evaluate_uri();
1188         if ($first_request) {
1189                 evaluate_gitweb_config();
1190                 evaluate_git_version();
1191         }
1192         if ($per_request_config) {
1193                 if (ref($per_request_config) eq 'CODE') {
1194                         $per_request_config->();
1195                 } elsif (!$first_request) {
1196                         evaluate_gitweb_config();
1197                 }
1198         }
1199         check_loadavg();
1200
1201         # $projectroot and $projects_list might be set in gitweb config file
1202         $projects_list ||= $projectroot;
1203
1204         evaluate_query_params();
1205         evaluate_path_info();
1206         evaluate_and_validate_params();
1207         evaluate_git_dir();
1208
1209         configure_gitweb_features();
1210
1211         dispatch();
1212 }
1213
1214 our $is_last_request = sub { 1 };
1215 our ($pre_dispatch_hook, $post_dispatch_hook, $pre_listen_hook);
1216 our $CGI = 'CGI';
1217 our $cgi;
1218 sub configure_as_fcgi {
1219         require CGI::Fast;
1220         our $CGI = 'CGI::Fast';
1221
1222         my $request_number = 0;
1223         # let each child service 100 requests
1224         our $is_last_request = sub { ++$request_number > 100 };
1225 }
1226 sub evaluate_argv {
1227         my $script_name = $ENV{'SCRIPT_NAME'} || $ENV{'SCRIPT_FILENAME'} || __FILE__;
1228         configure_as_fcgi()
1229                 if $script_name =~ /\.fcgi$/;
1230
1231         return unless (@ARGV);
1232
1233         require Getopt::Long;
1234         Getopt::Long::GetOptions(
1235                 'fastcgi|fcgi|f' => \&configure_as_fcgi,
1236                 'nproc|n=i' => sub {
1237                         my ($arg, $val) = @_;
1238                         return unless eval { require FCGI::ProcManager; 1; };
1239                         my $proc_manager = FCGI::ProcManager->new({
1240                                 n_processes => $val,
1241                         });
1242                         our $pre_listen_hook    = sub { $proc_manager->pm_manage()        };
1243                         our $pre_dispatch_hook  = sub { $proc_manager->pm_pre_dispatch()  };
1244                         our $post_dispatch_hook = sub { $proc_manager->pm_post_dispatch() };
1245                 },
1246         );
1247 }
1248
1249 sub run {
1250         evaluate_argv();
1251
1252         $first_request = 1;
1253         $pre_listen_hook->()
1254                 if $pre_listen_hook;
1255
1256  REQUEST:
1257         while ($cgi = $CGI->new()) {
1258                 $pre_dispatch_hook->()
1259                         if $pre_dispatch_hook;
1260
1261                 run_request();
1262
1263                 $post_dispatch_hook->()
1264                         if $post_dispatch_hook;
1265                 $first_request = 0;
1266
1267                 last REQUEST if ($is_last_request->());
1268         }
1269
1270  DONE_GITWEB:
1271         1;
1272 }
1273
1274 run();
1275
1276 if (defined caller) {
1277         # wrapped in a subroutine processing requests,
1278         # e.g. mod_perl with ModPerl::Registry, or PSGI with Plack::App::WrapCGI
1279         return;
1280 } else {
1281         # pure CGI script, serving single request
1282         exit;
1283 }
1284
1285 ## ======================================================================
1286 ## action links
1287
1288 # possible values of extra options
1289 # -full => 0|1      - use absolute/full URL ($my_uri/$my_url as base)
1290 # -replay => 1      - start from a current view (replay with modifications)
1291 # -path_info => 0|1 - don't use/use path_info URL (if possible)
1292 # -anchor => ANCHOR - add #ANCHOR to end of URL, implies -replay if used alone
1293 sub href {
1294         my %params = @_;
1295         # default is to use -absolute url() i.e. $my_uri
1296         my $href = $params{-full} ? $my_url : $my_uri;
1297
1298         # implicit -replay, must be first of implicit params
1299         $params{-replay} = 1 if (keys %params == 1 && $params{-anchor});
1300
1301         $params{'project'} = $project unless exists $params{'project'};
1302
1303         if ($params{-replay}) {
1304                 while (my ($name, $symbol) = each %cgi_param_mapping) {
1305                         if (!exists $params{$name}) {
1306                                 $params{$name} = $input_params{$name};
1307                         }
1308                 }
1309         }
1310
1311         my $use_pathinfo = gitweb_check_feature('pathinfo');
1312         if (defined $params{'project'} &&
1313             (exists $params{-path_info} ? $params{-path_info} : $use_pathinfo)) {
1314                 # try to put as many parameters as possible in PATH_INFO:
1315                 #   - project name
1316                 #   - action
1317                 #   - hash_parent or hash_parent_base:/file_parent
1318                 #   - hash or hash_base:/filename
1319                 #   - the snapshot_format as an appropriate suffix
1320
1321                 # When the script is the root DirectoryIndex for the domain,
1322                 # $href here would be something like http://gitweb.example.com/
1323                 # Thus, we strip any trailing / from $href, to spare us double
1324                 # slashes in the final URL
1325                 $href =~ s,/$,,;
1326
1327                 # Then add the project name, if present
1328                 $href .= "/".esc_path_info($params{'project'});
1329                 delete $params{'project'};
1330
1331                 # since we destructively absorb parameters, we keep this
1332                 # boolean that remembers if we're handling a snapshot
1333                 my $is_snapshot = $params{'action'} eq 'snapshot';
1334
1335                 # Summary just uses the project path URL, any other action is
1336                 # added to the URL
1337                 if (defined $params{'action'}) {
1338                         $href .= "/".esc_path_info($params{'action'})
1339                                 unless $params{'action'} eq 'summary';
1340                         delete $params{'action'};
1341                 }
1342
1343                 # Next, we put hash_parent_base:/file_parent..hash_base:/file_name,
1344                 # stripping nonexistent or useless pieces
1345                 $href .= "/" if ($params{'hash_base'} || $params{'hash_parent_base'}
1346                         || $params{'hash_parent'} || $params{'hash'});
1347                 if (defined $params{'hash_base'}) {
1348                         if (defined $params{'hash_parent_base'}) {
1349                                 $href .= esc_path_info($params{'hash_parent_base'});
1350                                 # skip the file_parent if it's the same as the file_name
1351                                 if (defined $params{'file_parent'}) {
1352                                         if (defined $params{'file_name'} && $params{'file_parent'} eq $params{'file_name'}) {
1353                                                 delete $params{'file_parent'};
1354                                         } elsif ($params{'file_parent'} !~ /\.\./) {
1355                                                 $href .= ":/".esc_path_info($params{'file_parent'});
1356                                                 delete $params{'file_parent'};
1357                                         }
1358                                 }
1359                                 $href .= "..";
1360                                 delete $params{'hash_parent'};
1361                                 delete $params{'hash_parent_base'};
1362                         } elsif (defined $params{'hash_parent'}) {
1363                                 $href .= esc_path_info($params{'hash_parent'}). "..";
1364                                 delete $params{'hash_parent'};
1365                         }
1366
1367                         $href .= esc_path_info($params{'hash_base'});
1368                         if (defined $params{'file_name'} && $params{'file_name'} !~ /\.\./) {
1369                                 $href .= ":/".esc_path_info($params{'file_name'});
1370                                 delete $params{'file_name'};
1371                         }
1372                         delete $params{'hash'};
1373                         delete $params{'hash_base'};
1374                 } elsif (defined $params{'hash'}) {
1375                         $href .= esc_path_info($params{'hash'});
1376                         delete $params{'hash'};
1377                 }
1378
1379                 # If the action was a snapshot, we can absorb the
1380                 # snapshot_format parameter too
1381                 if ($is_snapshot) {
1382                         my $fmt = $params{'snapshot_format'};
1383                         # snapshot_format should always be defined when href()
1384                         # is called, but just in case some code forgets, we
1385                         # fall back to the default
1386                         $fmt ||= $snapshot_fmts[0];
1387                         $href .= $known_snapshot_formats{$fmt}{'suffix'};
1388                         delete $params{'snapshot_format'};
1389                 }
1390         }
1391
1392         # now encode the parameters explicitly
1393         my @result = ();
1394         for (my $i = 0; $i < @cgi_param_mapping; $i += 2) {
1395                 my ($name, $symbol) = ($cgi_param_mapping[$i], $cgi_param_mapping[$i+1]);
1396                 if (defined $params{$name}) {
1397                         if (ref($params{$name}) eq "ARRAY") {
1398                                 foreach my $par (@{$params{$name}}) {
1399                                         push @result, $symbol . "=" . esc_param($par);
1400                                 }
1401                         } else {
1402                                 push @result, $symbol . "=" . esc_param($params{$name});
1403                         }
1404                 }
1405         }
1406         $href .= "?" . join(';', @result) if scalar @result;
1407
1408         # final transformation: trailing spaces must be escaped (URI-encoded)
1409         $href =~ s/(\s+)$/CGI::escape($1)/e;
1410
1411         if ($params{-anchor}) {
1412                 $href .= "#".esc_param($params{-anchor});
1413         }
1414
1415         return $href;
1416 }
1417
1418
1419 ## ======================================================================
1420 ## validation, quoting/unquoting and escaping
1421
1422 sub validate_action {
1423         my $input = shift || return undef;
1424         return undef unless exists $actions{$input};
1425         return $input;
1426 }
1427
1428 sub validate_project {
1429         my $input = shift || return undef;
1430         if (!validate_pathname($input) ||
1431                 !(-d "$projectroot/$input") ||
1432                 !check_export_ok("$projectroot/$input") ||
1433                 ($strict_export && !project_in_list($input))) {
1434                 return undef;
1435         } else {
1436                 return $input;
1437         }
1438 }
1439
1440 sub validate_pathname {
1441         my $input = shift || return undef;
1442
1443         # no '.' or '..' as elements of path, i.e. no '.' nor '..'
1444         # at the beginning, at the end, and between slashes.
1445         # also this catches doubled slashes
1446         if ($input =~ m!(^|/)(|\.|\.\.)(/|$)!) {
1447                 return undef;
1448         }
1449         # no null characters
1450         if ($input =~ m!\0!) {
1451                 return undef;
1452         }
1453         return $input;
1454 }
1455
1456 sub validate_refname {
1457         my $input = shift || return undef;
1458
1459         # textual hashes are O.K.
1460         if ($input =~ m/^[0-9a-fA-F]{40}$/) {
1461                 return $input;
1462         }
1463         # it must be correct pathname
1464         $input = validate_pathname($input)
1465                 or return undef;
1466         # restrictions on ref name according to git-check-ref-format
1467         if ($input =~ m!(/\.|\.\.|[\000-\040\177 ~^:?*\[]|/$)!) {
1468                 return undef;
1469         }
1470         return $input;
1471 }
1472
1473 # decode sequences of octets in utf8 into Perl's internal form,
1474 # which is utf-8 with utf8 flag set if needed.  gitweb writes out
1475 # in utf-8 thanks to "binmode STDOUT, ':utf8'" at beginning
1476 sub to_utf8 {
1477         my $str = shift;
1478         return undef unless defined $str;
1479
1480         if (utf8::is_utf8($str) || utf8::decode($str)) {
1481                 return $str;
1482         } else {
1483                 return decode($fallback_encoding, $str, Encode::FB_DEFAULT);
1484         }
1485 }
1486
1487 # quote unsafe chars, but keep the slash, even when it's not
1488 # correct, but quoted slashes look too horrible in bookmarks
1489 sub esc_param {
1490         my $str = shift;
1491         return undef unless defined $str;
1492         $str =~ s/([^A-Za-z0-9\-_.~()\/:@ ]+)/CGI::escape($1)/eg;
1493         $str =~ s/ /\+/g;
1494         return $str;
1495 }
1496
1497 # the quoting rules for path_info fragment are slightly different
1498 sub esc_path_info {
1499         my $str = shift;
1500         return undef unless defined $str;
1501
1502         # path_info doesn't treat '+' as space (specially), but '?' must be escaped
1503         $str =~ s/([^A-Za-z0-9\-_.~();\/;:@&= +]+)/CGI::escape($1)/eg;
1504
1505         return $str;
1506 }
1507
1508 # quote unsafe chars in whole URL, so some characters cannot be quoted
1509 sub esc_url {
1510         my $str = shift;
1511         return undef unless defined $str;
1512         $str =~ s/([^A-Za-z0-9\-_.~();\/;?:@&= ]+)/CGI::escape($1)/eg;
1513         $str =~ s/ /\+/g;
1514         return $str;
1515 }
1516
1517 # quote unsafe characters in HTML attributes
1518 sub esc_attr {
1519
1520         # for XHTML conformance escaping '"' to '&quot;' is not enough
1521         return esc_html(@_);
1522 }
1523
1524 # replace invalid utf8 character with SUBSTITUTION sequence
1525 sub esc_html {
1526         my $str = shift;
1527         my %opts = @_;
1528
1529         return undef unless defined $str;
1530
1531         $str = to_utf8($str);
1532         $str = $cgi->escapeHTML($str);
1533         if ($opts{'-nbsp'}) {
1534                 $str =~ s/ /&nbsp;/g;
1535         }
1536         $str =~ s|([[:cntrl:]])|(($1 ne "\t") ? quot_cec($1) : $1)|eg;
1537         return $str;
1538 }
1539
1540 # quote control characters and escape filename to HTML
1541 sub esc_path {
1542         my $str = shift;
1543         my %opts = @_;
1544
1545         return undef unless defined $str;
1546
1547         $str = to_utf8($str);
1548         $str = $cgi->escapeHTML($str);
1549         if ($opts{'-nbsp'}) {
1550                 $str =~ s/ /&nbsp;/g;
1551         }
1552         $str =~ s|([[:cntrl:]])|quot_cec($1)|eg;
1553         return $str;
1554 }
1555
1556 # Sanitize for use in XHTML + application/xml+xhtm (valid XML 1.0)
1557 sub sanitize {
1558         my $str = shift;
1559
1560         return undef unless defined $str;
1561
1562         $str = to_utf8($str);
1563         $str =~ s|([[:cntrl:]])|(index("\t\n\r", $1) != -1 ? $1 : quot_cec($1))|eg;
1564         return $str;
1565 }
1566
1567 # Make control characters "printable", using character escape codes (CEC)
1568 sub quot_cec {
1569         my $cntrl = shift;
1570         my %opts = @_;
1571         my %es = ( # character escape codes, aka escape sequences
1572                 "\t" => '\t',   # tab            (HT)
1573                 "\n" => '\n',   # line feed      (LF)
1574                 "\r" => '\r',   # carrige return (CR)
1575                 "\f" => '\f',   # form feed      (FF)
1576                 "\b" => '\b',   # backspace      (BS)
1577                 "\a" => '\a',   # alarm (bell)   (BEL)
1578                 "\e" => '\e',   # escape         (ESC)
1579                 "\013" => '\v', # vertical tab   (VT)
1580                 "\000" => '\0', # nul character  (NUL)
1581         );
1582         my $chr = ( (exists $es{$cntrl})
1583                     ? $es{$cntrl}
1584                     : sprintf('\%2x', ord($cntrl)) );
1585         if ($opts{-nohtml}) {
1586                 return $chr;
1587         } else {
1588                 return "<span class=\"cntrl\">$chr</span>";
1589         }
1590 }
1591
1592 # Alternatively use unicode control pictures codepoints,
1593 # Unicode "printable representation" (PR)
1594 sub quot_upr {
1595         my $cntrl = shift;
1596         my %opts = @_;
1597
1598         my $chr = sprintf('&#%04d;', 0x2400+ord($cntrl));
1599         if ($opts{-nohtml}) {
1600                 return $chr;
1601         } else {
1602                 return "<span class=\"cntrl\">$chr</span>";
1603         }
1604 }
1605
1606 # git may return quoted and escaped filenames
1607 sub unquote {
1608         my $str = shift;
1609
1610         sub unq {
1611                 my $seq = shift;
1612                 my %es = ( # character escape codes, aka escape sequences
1613                         't' => "\t",   # tab            (HT, TAB)
1614                         'n' => "\n",   # newline        (NL)
1615                         'r' => "\r",   # return         (CR)
1616                         'f' => "\f",   # form feed      (FF)
1617                         'b' => "\b",   # backspace      (BS)
1618                         'a' => "\a",   # alarm (bell)   (BEL)
1619                         'e' => "\e",   # escape         (ESC)
1620                         'v' => "\013", # vertical tab   (VT)
1621                 );
1622
1623                 if ($seq =~ m/^[0-7]{1,3}$/) {
1624                         # octal char sequence
1625                         return chr(oct($seq));
1626                 } elsif (exists $es{$seq}) {
1627                         # C escape sequence, aka character escape code
1628                         return $es{$seq};
1629                 }
1630                 # quoted ordinary character
1631                 return $seq;
1632         }
1633
1634         if ($str =~ m/^"(.*)"$/) {
1635                 # needs unquoting
1636                 $str = $1;
1637                 $str =~ s/\\([^0-7]|[0-7]{1,3})/unq($1)/eg;
1638         }
1639         return $str;
1640 }
1641
1642 # escape tabs (convert tabs to spaces)
1643 sub untabify {
1644         my $line = shift;
1645
1646         while ((my $pos = index($line, "\t")) != -1) {
1647                 if (my $count = (8 - ($pos % 8))) {
1648                         my $spaces = ' ' x $count;
1649                         $line =~ s/\t/$spaces/;
1650                 }
1651         }
1652
1653         return $line;
1654 }
1655
1656 sub project_in_list {
1657         my $project = shift;
1658         my @list = git_get_projects_list();
1659         return @list && scalar(grep { $_->{'path'} eq $project } @list);
1660 }
1661
1662 ## ----------------------------------------------------------------------
1663 ## HTML aware string manipulation
1664
1665 # Try to chop given string on a word boundary between position
1666 # $len and $len+$add_len. If there is no word boundary there,
1667 # chop at $len+$add_len. Do not chop if chopped part plus ellipsis
1668 # (marking chopped part) would be longer than given string.
1669 sub chop_str {
1670         my $str = shift;
1671         my $len = shift;
1672         my $add_len = shift || 10;
1673         my $where = shift || 'right'; # 'left' | 'center' | 'right'
1674
1675         # Make sure perl knows it is utf8 encoded so we don't
1676         # cut in the middle of a utf8 multibyte char.
1677         $str = to_utf8($str);
1678
1679         # allow only $len chars, but don't cut a word if it would fit in $add_len
1680         # if it doesn't fit, cut it if it's still longer than the dots we would add
1681         # remove chopped character entities entirely
1682
1683         # when chopping in the middle, distribute $len into left and right part
1684         # return early if chopping wouldn't make string shorter
1685         if ($where eq 'center') {
1686                 return $str if ($len + 5 >= length($str)); # filler is length 5
1687                 $len = int($len/2);
1688         } else {
1689                 return $str if ($len + 4 >= length($str)); # filler is length 4
1690         }
1691
1692         # regexps: ending and beginning with word part up to $add_len
1693         my $endre = qr/.{$len}\w{0,$add_len}/;
1694         my $begre = qr/\w{0,$add_len}.{$len}/;
1695
1696         if ($where eq 'left') {
1697                 $str =~ m/^(.*?)($begre)$/;
1698                 my ($lead, $body) = ($1, $2);
1699                 if (length($lead) > 4) {
1700                         $lead = " ...";
1701                 }
1702                 return "$lead$body";
1703
1704         } elsif ($where eq 'center') {
1705                 $str =~ m/^($endre)(.*)$/;
1706                 my ($left, $str)  = ($1, $2);
1707                 $str =~ m/^(.*?)($begre)$/;
1708                 my ($mid, $right) = ($1, $2);
1709                 if (length($mid) > 5) {
1710                         $mid = " ... ";
1711                 }
1712                 return "$left$mid$right";
1713
1714         } else {
1715                 $str =~ m/^($endre)(.*)$/;
1716                 my $body = $1;
1717                 my $tail = $2;
1718                 if (length($tail) > 4) {
1719                         $tail = "... ";
1720                 }
1721                 return "$body$tail";
1722         }
1723 }
1724
1725 # takes the same arguments as chop_str, but also wraps a <span> around the
1726 # result with a title attribute if it does get chopped. Additionally, the
1727 # string is HTML-escaped.
1728 sub chop_and_escape_str {
1729         my ($str) = @_;
1730
1731         my $chopped = chop_str(@_);
1732         $str = to_utf8($str);
1733         if ($chopped eq $str) {
1734                 return esc_html($chopped);
1735         } else {
1736                 $str =~ s/[[:cntrl:]]/?/g;
1737                 return $cgi->span({-title=>$str}, esc_html($chopped));
1738         }
1739 }
1740
1741 # Highlight selected fragments of string, using given CSS class,
1742 # and escape HTML.  It is assumed that fragments do not overlap.
1743 # Regions are passed as list of pairs (array references).
1744 #
1745 # Example: esc_html_hl_regions("foobar", "mark", [ 0, 3 ]) returns
1746 # '<span class="mark">foo</span>bar'
1747 sub esc_html_hl_regions {
1748         my ($str, $css_class, @sel) = @_;
1749         my %opts = grep { ref($_) ne 'ARRAY' } @sel;
1750         @sel     = grep { ref($_) eq 'ARRAY' } @sel;
1751         return esc_html($str, %opts) unless @sel;
1752
1753         my $out = '';
1754         my $pos = 0;
1755
1756         for my $s (@sel) {
1757                 my ($begin, $end) = @$s;
1758
1759                 # Don't create empty <span> elements.
1760                 next if $end <= $begin;
1761
1762                 my $escaped = esc_html(substr($str, $begin, $end - $begin),
1763                                        %opts);
1764
1765                 $out .= esc_html(substr($str, $pos, $begin - $pos), %opts)
1766                         if ($begin - $pos > 0);
1767                 $out .= $cgi->span({-class => $css_class}, $escaped);
1768
1769                 $pos = $end;
1770         }
1771         $out .= esc_html(substr($str, $pos), %opts)
1772                 if ($pos < length($str));
1773
1774         return $out;
1775 }
1776
1777 # return positions of beginning and end of each match
1778 sub matchpos_list {
1779         my ($str, $regexp) = @_;
1780         return unless (defined $str && defined $regexp);
1781
1782         my @matches;
1783         while ($str =~ /$regexp/g) {
1784                 push @matches, [$-[0], $+[0]];
1785         }
1786         return @matches;
1787 }
1788
1789 # highlight match (if any), and escape HTML
1790 sub esc_html_match_hl {
1791         my ($str, $regexp) = @_;
1792         return esc_html($str) unless defined $regexp;
1793
1794         my @matches = matchpos_list($str, $regexp);
1795         return esc_html($str) unless @matches;
1796
1797         return esc_html_hl_regions($str, 'match', @matches);
1798 }
1799
1800
1801 # highlight match (if any) of shortened string, and escape HTML
1802 sub esc_html_match_hl_chopped {
1803         my ($str, $chopped, $regexp) = @_;
1804         return esc_html_match_hl($str, $regexp) unless defined $chopped;
1805
1806         my @matches = matchpos_list($str, $regexp);
1807         return esc_html($chopped) unless @matches;
1808
1809         # filter matches so that we mark chopped string
1810         my $tail = "... "; # see chop_str
1811         unless ($chopped =~ s/\Q$tail\E$//) {
1812                 $tail = '';
1813         }
1814         my $chop_len = length($chopped);
1815         my $tail_len = length($tail);
1816         my @filtered;
1817
1818         for my $m (@matches) {
1819                 if ($m->[0] > $chop_len) {
1820                         push @filtered, [ $chop_len, $chop_len + $tail_len ] if ($tail_len > 0);
1821                         last;
1822                 } elsif ($m->[1] > $chop_len) {
1823                         push @filtered, [ $m->[0], $chop_len + $tail_len ];
1824                         last;
1825                 }
1826                 push @filtered, $m;
1827         }
1828
1829         return esc_html_hl_regions($chopped . $tail, 'match', @filtered);
1830 }
1831
1832 ## ----------------------------------------------------------------------
1833 ## functions returning short strings
1834
1835 # CSS class for given age value (in seconds)
1836 sub age_class {
1837         my $age = shift;
1838
1839         if (!defined $age) {
1840                 return "noage";
1841         } elsif ($age < 60*60*2) {
1842                 return "age0";
1843         } elsif ($age < 60*60*24*2) {
1844                 return "age1";
1845         } else {
1846                 return "age2";
1847         }
1848 }
1849
1850 # convert age in seconds to "nn units ago" string
1851 sub age_string {
1852         my $age = shift;
1853         my $age_str;
1854
1855         if ($age > 60*60*24*365*2) {
1856                 $age_str = (int $age/60/60/24/365);
1857                 $age_str .= " years ago";
1858         } elsif ($age > 60*60*24*(365/12)*2) {
1859                 $age_str = int $age/60/60/24/(365/12);
1860                 $age_str .= " months ago";
1861         } elsif ($age > 60*60*24*7*2) {
1862                 $age_str = int $age/60/60/24/7;
1863                 $age_str .= " weeks ago";
1864         } elsif ($age > 60*60*24*2) {
1865                 $age_str = int $age/60/60/24;
1866                 $age_str .= " days ago";
1867         } elsif ($age > 60*60*2) {
1868                 $age_str = int $age/60/60;
1869                 $age_str .= " hours ago";
1870         } elsif ($age > 60*2) {
1871                 $age_str = int $age/60;
1872                 $age_str .= " min ago";
1873         } elsif ($age > 2) {
1874                 $age_str = int $age;
1875                 $age_str .= " sec ago";
1876         } else {
1877                 $age_str .= " right now";
1878         }
1879         return $age_str;
1880 }
1881
1882 use constant {
1883         S_IFINVALID => 0030000,
1884         S_IFGITLINK => 0160000,
1885 };
1886
1887 # submodule/subproject, a commit object reference
1888 sub S_ISGITLINK {
1889         my $mode = shift;
1890
1891         return (($mode & S_IFMT) == S_IFGITLINK)
1892 }
1893
1894 # convert file mode in octal to symbolic file mode string
1895 sub mode_str {
1896         my $mode = oct shift;
1897
1898         if (S_ISGITLINK($mode)) {
1899                 return 'm---------';
1900         } elsif (S_ISDIR($mode & S_IFMT)) {
1901                 return 'drwxr-xr-x';
1902         } elsif (S_ISLNK($mode)) {
1903                 return 'lrwxrwxrwx';
1904         } elsif (S_ISREG($mode)) {
1905                 # git cares only about the executable bit
1906                 if ($mode & S_IXUSR) {
1907                         return '-rwxr-xr-x';
1908                 } else {
1909                         return '-rw-r--r--';
1910                 };
1911         } else {
1912                 return '----------';
1913         }
1914 }
1915
1916 # convert file mode in octal to file type string
1917 sub file_type {
1918         my $mode = shift;
1919
1920         if ($mode !~ m/^[0-7]+$/) {
1921                 return $mode;
1922         } else {
1923                 $mode = oct $mode;
1924         }
1925
1926         if (S_ISGITLINK($mode)) {
1927                 return "submodule";
1928         } elsif (S_ISDIR($mode & S_IFMT)) {
1929                 return "directory";
1930         } elsif (S_ISLNK($mode)) {
1931                 return "symlink";
1932         } elsif (S_ISREG($mode)) {
1933                 return "file";
1934         } else {
1935                 return "unknown";
1936         }
1937 }
1938
1939 # convert file mode in octal to file type description string
1940 sub file_type_long {
1941         my $mode = shift;
1942
1943         if ($mode !~ m/^[0-7]+$/) {
1944                 return $mode;
1945         } else {
1946                 $mode = oct $mode;
1947         }
1948
1949         if (S_ISGITLINK($mode)) {
1950                 return "submodule";
1951         } elsif (S_ISDIR($mode & S_IFMT)) {
1952                 return "directory";
1953         } elsif (S_ISLNK($mode)) {
1954                 return "symlink";
1955         } elsif (S_ISREG($mode)) {
1956                 if ($mode & S_IXUSR) {
1957                         return "executable";
1958                 } else {
1959                         return "file";
1960                 };
1961         } else {
1962                 return "unknown";
1963         }
1964 }
1965
1966
1967 ## ----------------------------------------------------------------------
1968 ## functions returning short HTML fragments, or transforming HTML fragments
1969 ## which don't belong to other sections
1970
1971 # format line of commit message.
1972 sub format_log_line_html {
1973         my $line = shift;
1974
1975         $line = esc_html($line, -nbsp=>1);
1976         $line =~ s{\b([0-9a-fA-F]{8,40})\b}{
1977                 $cgi->a({-href => href(action=>"object", hash=>$1),
1978                                         -class => "text"}, $1);
1979         }eg;
1980
1981         return $line;
1982 }
1983
1984 # format marker of refs pointing to given object
1985
1986 # the destination action is chosen based on object type and current context:
1987 # - for annotated tags, we choose the tag view unless it's the current view
1988 #   already, in which case we go to shortlog view
1989 # - for other refs, we keep the current view if we're in history, shortlog or
1990 #   log view, and select shortlog otherwise
1991 sub format_ref_marker {
1992         my ($refs, $id) = @_;
1993         my $markers = '';
1994
1995         if (defined $refs->{$id}) {
1996                 foreach my $ref (@{$refs->{$id}}) {
1997                         # this code exploits the fact that non-lightweight tags are the
1998                         # only indirect objects, and that they are the only objects for which
1999                         # we want to use tag instead of shortlog as action
2000                         my ($type, $name) = qw();
2001                         my $indirect = ($ref =~ s/\^\{\}$//);
2002                         # e.g. tags/v2.6.11 or heads/next
2003                         if ($ref =~ m!^(.*?)s?/(.*)$!) {
2004                                 $type = $1;
2005                                 $name = $2;
2006                         } else {
2007                                 $type = "ref";
2008                                 $name = $ref;
2009                         }
2010
2011                         my $class = $type;
2012                         $class .= " indirect" if $indirect;
2013
2014                         my $dest_action = "shortlog";
2015
2016                         if ($indirect) {
2017                                 $dest_action = "tag" unless $action eq "tag";
2018                         } elsif ($action =~ /^(history|(short)?log)$/) {
2019                                 $dest_action = $action;
2020                         }
2021
2022                         my $dest = "";
2023                         $dest .= "refs/" unless $ref =~ m!^refs/!;
2024                         $dest .= $ref;
2025
2026                         my $link = $cgi->a({
2027                                 -href => href(
2028                                         action=>$dest_action,
2029                                         hash=>$dest
2030                                 )}, $name);
2031
2032                         $markers .= " <span class=\"".esc_attr($class)."\" title=\"".esc_attr($ref)."\">" .
2033                                 $link . "</span>";
2034                 }
2035         }
2036
2037         if ($markers) {
2038                 return ' <span class="refs">'. $markers . '</span>';
2039         } else {
2040                 return "";
2041         }
2042 }
2043
2044 # format, perhaps shortened and with markers, title line
2045 sub format_subject_html {
2046         my ($long, $short, $href, $extra) = @_;
2047         $extra = '' unless defined($extra);
2048
2049         if (length($short) < length($long)) {
2050                 $long =~ s/[[:cntrl:]]/?/g;
2051                 return $cgi->a({-href => $href, -class => "list subject",
2052                                 -title => to_utf8($long)},
2053                        esc_html($short)) . $extra;
2054         } else {
2055                 return $cgi->a({-href => $href, -class => "list subject"},
2056                        esc_html($long)) . $extra;
2057         }
2058 }
2059
2060 # Rather than recomputing the url for an email multiple times, we cache it
2061 # after the first hit. This gives a visible benefit in views where the avatar
2062 # for the same email is used repeatedly (e.g. shortlog).
2063 # The cache is shared by all avatar engines (currently gravatar only), which
2064 # are free to use it as preferred. Since only one avatar engine is used for any
2065 # given page, there's no risk for cache conflicts.
2066 our %avatar_cache = ();
2067
2068 # Compute the picon url for a given email, by using the picon search service over at
2069 # http://www.cs.indiana.edu/picons/search.html
2070 sub picon_url {
2071         my $email = lc shift;
2072         if (!$avatar_cache{$email}) {
2073                 my ($user, $domain) = split('@', $email);
2074                 $avatar_cache{$email} =
2075                         "//www.cs.indiana.edu/cgi-pub/kinzler/piconsearch.cgi/" .
2076                         "$domain/$user/" .
2077                         "users+domains+unknown/up/single";
2078         }
2079         return $avatar_cache{$email};
2080 }
2081
2082 # Compute the gravatar url for a given email, if it's not in the cache already.
2083 # Gravatar stores only the part of the URL before the size, since that's the
2084 # one computationally more expensive. This also allows reuse of the cache for
2085 # different sizes (for this particular engine).
2086 sub gravatar_url {
2087         my $email = lc shift;
2088         my $size = shift;
2089         $avatar_cache{$email} ||=
2090                 "//www.gravatar.com/avatar/" .
2091                         Digest::MD5::md5_hex($email) . "?s=";
2092         return $avatar_cache{$email} . $size;
2093 }
2094
2095 # Insert an avatar for the given $email at the given $size if the feature
2096 # is enabled.
2097 sub git_get_avatar {
2098         my ($email, %opts) = @_;
2099         my $pre_white  = ($opts{-pad_before} ? "&nbsp;" : "");
2100         my $post_white = ($opts{-pad_after}  ? "&nbsp;" : "");
2101         $opts{-size} ||= 'default';
2102         my $size = $avatar_size{$opts{-size}} || $avatar_size{'default'};
2103         my $url = "";
2104         if ($git_avatar eq 'gravatar') {
2105                 $url = gravatar_url($email, $size);
2106         } elsif ($git_avatar eq 'picon') {
2107                 $url = picon_url($email);
2108         }
2109         # Other providers can be added by extending the if chain, defining $url
2110         # as needed. If no variant puts something in $url, we assume avatars
2111         # are completely disabled/unavailable.
2112         if ($url) {
2113                 return $pre_white .
2114                        "<img width=\"$size\" " .
2115                             "class=\"avatar\" " .
2116                             "src=\"".esc_url($url)."\" " .
2117                             "alt=\"\" " .
2118                        "/>" . $post_white;
2119         } else {
2120                 return "";
2121         }
2122 }
2123
2124 sub format_search_author {
2125         my ($author, $searchtype, $displaytext) = @_;
2126         my $have_search = gitweb_check_feature('search');
2127
2128         if ($have_search) {
2129                 my $performed = "";
2130                 if ($searchtype eq 'author') {
2131                         $performed = "authored";
2132                 } elsif ($searchtype eq 'committer') {
2133                         $performed = "committed";
2134                 }
2135
2136                 return $cgi->a({-href => href(action=>"search", hash=>$hash,
2137                                 searchtext=>$author,
2138                                 searchtype=>$searchtype), class=>"list",
2139                                 title=>"Search for commits $performed by $author"},
2140                                 $displaytext);
2141
2142         } else {
2143                 return $displaytext;
2144         }
2145 }
2146
2147 # format the author name of the given commit with the given tag
2148 # the author name is chopped and escaped according to the other
2149 # optional parameters (see chop_str).
2150 sub format_author_html {
2151         my $tag = shift;
2152         my $co = shift;
2153         my $author = chop_and_escape_str($co->{'author_name'}, @_);
2154         return "<$tag class=\"author\">" .
2155                format_search_author($co->{'author_name'}, "author",
2156                        git_get_avatar($co->{'author_email'}, -pad_after => 1) .
2157                        $author) .
2158                "</$tag>";
2159 }
2160
2161 # format git diff header line, i.e. "diff --(git|combined|cc) ..."
2162 sub format_git_diff_header_line {
2163         my $line = shift;
2164         my $diffinfo = shift;
2165         my ($from, $to) = @_;
2166
2167         if ($diffinfo->{'nparents'}) {
2168                 # combined diff
2169                 $line =~ s!^(diff (.*?) )"?.*$!$1!;
2170                 if ($to->{'href'}) {
2171                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2172                                          esc_path($to->{'file'}));
2173                 } else { # file was deleted (no href)
2174                         $line .= esc_path($to->{'file'});
2175                 }
2176         } else {
2177                 # "ordinary" diff
2178                 $line =~ s!^(diff (.*?) )"?a/.*$!$1!;
2179                 if ($from->{'href'}) {
2180                         $line .= $cgi->a({-href => $from->{'href'}, -class => "path"},
2181                                          'a/' . esc_path($from->{'file'}));
2182                 } else { # file was added (no href)
2183                         $line .= 'a/' . esc_path($from->{'file'});
2184                 }
2185                 $line .= ' ';
2186                 if ($to->{'href'}) {
2187                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2188                                          'b/' . esc_path($to->{'file'}));
2189                 } else { # file was deleted
2190                         $line .= 'b/' . esc_path($to->{'file'});
2191                 }
2192         }
2193
2194         return "<div class=\"diff header\">$line</div>\n";
2195 }
2196
2197 # format extended diff header line, before patch itself
2198 sub format_extended_diff_header_line {
2199         my $line = shift;
2200         my $diffinfo = shift;
2201         my ($from, $to) = @_;
2202
2203         # match <path>
2204         if ($line =~ s!^((copy|rename) from ).*$!$1! && $from->{'href'}) {
2205                 $line .= $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2206                                        esc_path($from->{'file'}));
2207         }
2208         if ($line =~ s!^((copy|rename) to ).*$!$1! && $to->{'href'}) {
2209                 $line .= $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2210                                  esc_path($to->{'file'}));
2211         }
2212         # match single <mode>
2213         if ($line =~ m/\s(\d{6})$/) {
2214                 $line .= '<span class="info"> (' .
2215                          file_type_long($1) .
2216                          ')</span>';
2217         }
2218         # match <hash>
2219         if ($line =~ m/^index [0-9a-fA-F]{40},[0-9a-fA-F]{40}/) {
2220                 # can match only for combined diff
2221                 $line = 'index ';
2222                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2223                         if ($from->{'href'}[$i]) {
2224                                 $line .= $cgi->a({-href=>$from->{'href'}[$i],
2225                                                   -class=>"hash"},
2226                                                  substr($diffinfo->{'from_id'}[$i],0,7));
2227                         } else {
2228                                 $line .= '0' x 7;
2229                         }
2230                         # separator
2231                         $line .= ',' if ($i < $diffinfo->{'nparents'} - 1);
2232                 }
2233                 $line .= '..';
2234                 if ($to->{'href'}) {
2235                         $line .= $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2236                                          substr($diffinfo->{'to_id'},0,7));
2237                 } else {
2238                         $line .= '0' x 7;
2239                 }
2240
2241         } elsif ($line =~ m/^index [0-9a-fA-F]{40}..[0-9a-fA-F]{40}/) {
2242                 # can match only for ordinary diff
2243                 my ($from_link, $to_link);
2244                 if ($from->{'href'}) {
2245                         $from_link = $cgi->a({-href=>$from->{'href'}, -class=>"hash"},
2246                                              substr($diffinfo->{'from_id'},0,7));
2247                 } else {
2248                         $from_link = '0' x 7;
2249                 }
2250                 if ($to->{'href'}) {
2251                         $to_link = $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2252                                            substr($diffinfo->{'to_id'},0,7));
2253                 } else {
2254                         $to_link = '0' x 7;
2255                 }
2256                 my ($from_id, $to_id) = ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
2257                 $line =~ s!$from_id\.\.$to_id!$from_link..$to_link!;
2258         }
2259
2260         return $line . "<br/>\n";
2261 }
2262
2263 # format from-file/to-file diff header
2264 sub format_diff_from_to_header {
2265         my ($from_line, $to_line, $diffinfo, $from, $to, @parents) = @_;
2266         my $line;
2267         my $result = '';
2268
2269         $line = $from_line;
2270         #assert($line =~ m/^---/) if DEBUG;
2271         # no extra formatting for "^--- /dev/null"
2272         if (! $diffinfo->{'nparents'}) {
2273                 # ordinary (single parent) diff
2274                 if ($line =~ m!^--- "?a/!) {
2275                         if ($from->{'href'}) {
2276                                 $line = '--- a/' .
2277                                         $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2278                                                 esc_path($from->{'file'}));
2279                         } else {
2280                                 $line = '--- a/' .
2281                                         esc_path($from->{'file'});
2282                         }
2283                 }
2284                 $result .= qq!<div class="diff from_file">$line</div>\n!;
2285
2286         } else {
2287                 # combined diff (merge commit)
2288                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2289                         if ($from->{'href'}[$i]) {
2290                                 $line = '--- ' .
2291                                         $cgi->a({-href=>href(action=>"blobdiff",
2292                                                              hash_parent=>$diffinfo->{'from_id'}[$i],
2293                                                              hash_parent_base=>$parents[$i],
2294                                                              file_parent=>$from->{'file'}[$i],
2295                                                              hash=>$diffinfo->{'to_id'},
2296                                                              hash_base=>$hash,
2297                                                              file_name=>$to->{'file'}),
2298                                                  -class=>"path",
2299                                                  -title=>"diff" . ($i+1)},
2300                                                 $i+1) .
2301                                         '/' .
2302                                         $cgi->a({-href=>$from->{'href'}[$i], -class=>"path"},
2303                                                 esc_path($from->{'file'}[$i]));
2304                         } else {
2305                                 $line = '--- /dev/null';
2306                         }
2307                         $result .= qq!<div class="diff from_file">$line</div>\n!;
2308                 }
2309         }
2310
2311         $line = $to_line;
2312         #assert($line =~ m/^\+\+\+/) if DEBUG;
2313         # no extra formatting for "^+++ /dev/null"
2314         if ($line =~ m!^\+\+\+ "?b/!) {
2315                 if ($to->{'href'}) {
2316                         $line = '+++ b/' .
2317                                 $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2318                                         esc_path($to->{'file'}));
2319                 } else {
2320                         $line = '+++ b/' .
2321                                 esc_path($to->{'file'});
2322                 }
2323         }
2324         $result .= qq!<div class="diff to_file">$line</div>\n!;
2325
2326         return $result;
2327 }
2328
2329 # create note for patch simplified by combined diff
2330 sub format_diff_cc_simplified {
2331         my ($diffinfo, @parents) = @_;
2332         my $result = '';
2333
2334         $result .= "<div class=\"diff header\">" .
2335                    "diff --cc ";
2336         if (!is_deleted($diffinfo)) {
2337                 $result .= $cgi->a({-href => href(action=>"blob",
2338                                                   hash_base=>$hash,
2339                                                   hash=>$diffinfo->{'to_id'},
2340                                                   file_name=>$diffinfo->{'to_file'}),
2341                                     -class => "path"},
2342                                    esc_path($diffinfo->{'to_file'}));
2343         } else {
2344                 $result .= esc_path($diffinfo->{'to_file'});
2345         }
2346         $result .= "</div>\n" . # class="diff header"
2347                    "<div class=\"diff nodifferences\">" .
2348                    "Simple merge" .
2349                    "</div>\n"; # class="diff nodifferences"
2350
2351         return $result;
2352 }
2353
2354 sub diff_line_class {
2355         my ($line, $from, $to) = @_;
2356
2357         # ordinary diff
2358         my $num_sign = 1;
2359         # combined diff
2360         if ($from && $to && ref($from->{'href'}) eq "ARRAY") {
2361                 $num_sign = scalar @{$from->{'href'}};
2362         }
2363
2364         my @diff_line_classifier = (
2365                 { regexp => qr/^\@\@{$num_sign} /, class => "chunk_header"},
2366                 { regexp => qr/^\\/,               class => "incomplete"  },
2367                 { regexp => qr/^ {$num_sign}/,     class => "ctx" },
2368                 # classifier for context must come before classifier add/rem,
2369                 # or we would have to use more complicated regexp, for example
2370                 # qr/(?= {0,$m}\+)[+ ]{$num_sign}/, where $m = $num_sign - 1;
2371                 { regexp => qr/^[+ ]{$num_sign}/,   class => "add" },
2372                 { regexp => qr/^[- ]{$num_sign}/,   class => "rem" },
2373         );
2374         for my $clsfy (@diff_line_classifier) {
2375                 return $clsfy->{'class'}
2376                         if ($line =~ $clsfy->{'regexp'});
2377         }
2378
2379         # fallback
2380         return "";
2381 }
2382
2383 # assumes that $from and $to are defined and correctly filled,
2384 # and that $line holds a line of chunk header for unified diff
2385 sub format_unidiff_chunk_header {
2386         my ($line, $from, $to) = @_;
2387
2388         my ($from_text, $from_start, $from_lines, $to_text, $to_start, $to_lines, $section) =
2389                 $line =~ m/^\@{2} (-(\d+)(?:,(\d+))?) (\+(\d+)(?:,(\d+))?) \@{2}(.*)$/;
2390
2391         $from_lines = 0 unless defined $from_lines;
2392         $to_lines   = 0 unless defined $to_lines;
2393
2394         if ($from->{'href'}) {
2395                 $from_text = $cgi->a({-href=>"$from->{'href'}#l$from_start",
2396                                      -class=>"list"}, $from_text);
2397         }
2398         if ($to->{'href'}) {
2399                 $to_text   = $cgi->a({-href=>"$to->{'href'}#l$to_start",
2400                                      -class=>"list"}, $to_text);
2401         }
2402         $line = "<span class=\"chunk_info\">@@ $from_text $to_text @@</span>" .
2403                 "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2404         return $line;
2405 }
2406
2407 # assumes that $from and $to are defined and correctly filled,
2408 # and that $line holds a line of chunk header for combined diff
2409 sub format_cc_diff_chunk_header {
2410         my ($line, $from, $to) = @_;
2411
2412         my ($prefix, $ranges, $section) = $line =~ m/^(\@+) (.*?) \@+(.*)$/;
2413         my (@from_text, @from_start, @from_nlines, $to_text, $to_start, $to_nlines);
2414
2415         @from_text = split(' ', $ranges);
2416         for (my $i = 0; $i < @from_text; ++$i) {
2417                 ($from_start[$i], $from_nlines[$i]) =
2418                         (split(',', substr($from_text[$i], 1)), 0);
2419         }
2420
2421         $to_text   = pop @from_text;
2422         $to_start  = pop @from_start;
2423         $to_nlines = pop @from_nlines;
2424
2425         $line = "<span class=\"chunk_info\">$prefix ";
2426         for (my $i = 0; $i < @from_text; ++$i) {
2427                 if ($from->{'href'}[$i]) {
2428                         $line .= $cgi->a({-href=>"$from->{'href'}[$i]#l$from_start[$i]",
2429                                           -class=>"list"}, $from_text[$i]);
2430                 } else {
2431                         $line .= $from_text[$i];
2432                 }
2433                 $line .= " ";
2434         }
2435         if ($to->{'href'}) {
2436                 $line .= $cgi->a({-href=>"$to->{'href'}#l$to_start",
2437                                   -class=>"list"}, $to_text);
2438         } else {
2439                 $line .= $to_text;
2440         }
2441         $line .= " $prefix</span>" .
2442                  "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2443         return $line;
2444 }
2445
2446 # process patch (diff) line (not to be used for diff headers),
2447 # returning HTML-formatted (but not wrapped) line.
2448 # If the line is passed as a reference, it is treated as HTML and not
2449 # esc_html()'ed.
2450 sub format_diff_line {
2451         my ($line, $diff_class, $from, $to) = @_;
2452
2453         if (ref($line)) {
2454                 $line = $$line;
2455         } else {
2456                 chomp $line;
2457                 $line = untabify($line);
2458
2459                 if ($from && $to && $line =~ m/^\@{2} /) {
2460                         $line = format_unidiff_chunk_header($line, $from, $to);
2461                 } elsif ($from && $to && $line =~ m/^\@{3}/) {
2462                         $line = format_cc_diff_chunk_header($line, $from, $to);
2463                 } else {
2464                         $line = esc_html($line, -nbsp=>1);
2465                 }
2466         }
2467
2468         my $diff_classes = "diff";
2469         $diff_classes .= " $diff_class" if ($diff_class);
2470         $line = "<div class=\"$diff_classes\">$line</div>\n";
2471
2472         return $line;
2473 }
2474
2475 # Generates undef or something like "_snapshot_" or "snapshot (_tbz2_ _zip_)",
2476 # linked.  Pass the hash of the tree/commit to snapshot.
2477 sub format_snapshot_links {
2478         my ($hash) = @_;
2479         my $num_fmts = @snapshot_fmts;
2480         if ($num_fmts > 1) {
2481                 # A parenthesized list of links bearing format names.
2482                 # e.g. "snapshot (_tar.gz_ _zip_)"
2483                 return "snapshot (" . join(' ', map
2484                         $cgi->a({
2485                                 -href => href(
2486                                         action=>"snapshot",
2487                                         hash=>$hash,
2488                                         snapshot_format=>$_
2489                                 )
2490                         }, $known_snapshot_formats{$_}{'display'})
2491                 , @snapshot_fmts) . ")";
2492         } elsif ($num_fmts == 1) {
2493                 # A single "snapshot" link whose tooltip bears the format name.
2494                 # i.e. "_snapshot_"
2495                 my ($fmt) = @snapshot_fmts;
2496                 return
2497                         $cgi->a({
2498                                 -href => href(
2499                                         action=>"snapshot",
2500                                         hash=>$hash,
2501                                         snapshot_format=>$fmt
2502                                 ),
2503                                 -title => "in format: $known_snapshot_formats{$fmt}{'display'}"
2504                         }, "snapshot");
2505         } else { # $num_fmts == 0
2506                 return undef;
2507         }
2508 }
2509
2510 ## ......................................................................
2511 ## functions returning values to be passed, perhaps after some
2512 ## transformation, to other functions; e.g. returning arguments to href()
2513
2514 # returns hash to be passed to href to generate gitweb URL
2515 # in -title key it returns description of link
2516 sub get_feed_info {
2517         my $format = shift || 'Atom';
2518         my %res = (action => lc($format));
2519
2520         # feed links are possible only for project views
2521         return unless (defined $project);
2522         # some views should link to OPML, or to generic project feed,
2523         # or don't have specific feed yet (so they should use generic)
2524         return if (!$action || $action =~ /^(?:tags|heads|forks|tag|search)$/x);
2525
2526         my $branch;
2527         # branches refs uses 'refs/heads/' prefix (fullname) to differentiate
2528         # from tag links; this also makes possible to detect branch links
2529         if ((defined $hash_base && $hash_base =~ m!^refs/heads/(.*)$!) ||
2530             (defined $hash      && $hash      =~ m!^refs/heads/(.*)$!)) {
2531                 $branch = $1;
2532         }
2533         # find log type for feed description (title)
2534         my $type = 'log';
2535         if (defined $file_name) {
2536                 $type  = "history of $file_name";
2537                 $type .= "/" if ($action eq 'tree');
2538                 $type .= " on '$branch'" if (defined $branch);
2539         } else {
2540                 $type = "log of $branch" if (defined $branch);
2541         }
2542
2543         $res{-title} = $type;
2544         $res{'hash'} = (defined $branch ? "refs/heads/$branch" : undef);
2545         $res{'file_name'} = $file_name;
2546
2547         return %res;
2548 }
2549
2550 ## ----------------------------------------------------------------------
2551 ## git utility subroutines, invoking git commands
2552
2553 # returns path to the core git executable and the --git-dir parameter as list
2554 sub git_cmd {
2555         $number_of_git_cmds++;
2556         return $GIT, '--git-dir='.$git_dir;
2557 }
2558
2559 # quote the given arguments for passing them to the shell
2560 # quote_command("command", "arg 1", "arg with ' and ! characters")
2561 # => "'command' 'arg 1' 'arg with '\'' and '\!' characters'"
2562 # Try to avoid using this function wherever possible.
2563 sub quote_command {
2564         return join(' ',
2565                 map { my $a = $_; $a =~ s/(['!])/'\\$1'/g; "'$a'" } @_ );
2566 }
2567
2568 # get HEAD ref of given project as hash
2569 sub git_get_head_hash {
2570         return git_get_full_hash(shift, 'HEAD');
2571 }
2572
2573 sub git_get_full_hash {
2574         return git_get_hash(@_);
2575 }
2576
2577 sub git_get_short_hash {
2578         return git_get_hash(@_, '--short=7');
2579 }
2580
2581 sub git_get_hash {
2582         my ($project, $hash, @options) = @_;
2583         my $o_git_dir = $git_dir;
2584         my $retval = undef;
2585         $git_dir = "$projectroot/$project";
2586         if (open my $fd, '-|', git_cmd(), 'rev-parse',
2587             '--verify', '-q', @options, $hash) {
2588                 $retval = <$fd>;
2589                 chomp $retval if defined $retval;
2590                 close $fd;
2591         }
2592         if (defined $o_git_dir) {
2593                 $git_dir = $o_git_dir;
2594         }
2595         return $retval;
2596 }
2597
2598 # get type of given object
2599 sub git_get_type {
2600         my $hash = shift;
2601
2602         open my $fd, "-|", git_cmd(), "cat-file", '-t', $hash or return;
2603         my $type = <$fd>;
2604         close $fd or return;
2605         chomp $type;
2606         return $type;
2607 }
2608
2609 # repository configuration
2610 our $config_file = '';
2611 our %config;
2612
2613 # store multiple values for single key as anonymous array reference
2614 # single values stored directly in the hash, not as [ <value> ]
2615 sub hash_set_multi {
2616         my ($hash, $key, $value) = @_;
2617
2618         if (!exists $hash->{$key}) {
2619                 $hash->{$key} = $value;
2620         } elsif (!ref $hash->{$key}) {
2621                 $hash->{$key} = [ $hash->{$key}, $value ];
2622         } else {
2623                 push @{$hash->{$key}}, $value;
2624         }
2625 }
2626
2627 # return hash of git project configuration
2628 # optionally limited to some section, e.g. 'gitweb'
2629 sub git_parse_project_config {
2630         my $section_regexp = shift;
2631         my %config;
2632
2633         local $/ = "\0";
2634
2635         open my $fh, "-|", git_cmd(), "config", '-z', '-l',
2636                 or return;
2637
2638         while (my $keyval = <$fh>) {
2639                 chomp $keyval;
2640                 my ($key, $value) = split(/\n/, $keyval, 2);
2641
2642                 hash_set_multi(\%config, $key, $value)
2643                         if (!defined $section_regexp || $key =~ /^(?:$section_regexp)\./o);
2644         }
2645         close $fh;
2646
2647         return %config;
2648 }
2649
2650 # convert config value to boolean: 'true' or 'false'
2651 # no value, number > 0, 'true' and 'yes' values are true
2652 # rest of values are treated as false (never as error)
2653 sub config_to_bool {
2654         my $val = shift;
2655
2656         return 1 if !defined $val;             # section.key
2657
2658         # strip leading and trailing whitespace
2659         $val =~ s/^\s+//;
2660         $val =~ s/\s+$//;
2661
2662         return (($val =~ /^\d+$/ && $val) ||   # section.key = 1
2663                 ($val =~ /^(?:true|yes)$/i));  # section.key = true
2664 }
2665
2666 # convert config value to simple decimal number
2667 # an optional value suffix of 'k', 'm', or 'g' will cause the value
2668 # to be multiplied by 1024, 1048576, or 1073741824
2669 sub config_to_int {
2670         my $val = shift;
2671
2672         # strip leading and trailing whitespace
2673         $val =~ s/^\s+//;
2674         $val =~ s/\s+$//;
2675
2676         if (my ($num, $unit) = ($val =~ /^([0-9]*)([kmg])$/i)) {
2677                 $unit = lc($unit);
2678                 # unknown unit is treated as 1
2679                 return $num * ($unit eq 'g' ? 1073741824 :
2680                                $unit eq 'm' ?    1048576 :
2681                                $unit eq 'k' ?       1024 : 1);
2682         }
2683         return $val;
2684 }
2685
2686 # convert config value to array reference, if needed
2687 sub config_to_multi {
2688         my $val = shift;
2689
2690         return ref($val) ? $val : (defined($val) ? [ $val ] : []);
2691 }
2692
2693 sub git_get_project_config {
2694         my ($key, $type) = @_;
2695
2696         return unless defined $git_dir;
2697
2698         # key sanity check
2699         return unless ($key);
2700         # only subsection, if exists, is case sensitive,
2701         # and not lowercased by 'git config -z -l'
2702         if (my ($hi, $mi, $lo) = ($key =~ /^([^.]*)\.(.*)\.([^.]*)$/)) {
2703                 $lo =~ s/_//g;
2704                 $key = join(".", lc($hi), $mi, lc($lo));
2705                 return if ($lo =~ /\W/ || $hi =~ /\W/);
2706         } else {
2707                 $key = lc($key);
2708                 $key =~ s/_//g;
2709                 return if ($key =~ /\W/);
2710         }
2711         $key =~ s/^gitweb\.//;
2712
2713         # type sanity check
2714         if (defined $type) {
2715                 $type =~ s/^--//;
2716                 $type = undef
2717                         unless ($type eq 'bool' || $type eq 'int');
2718         }
2719
2720         # get config
2721         if (!defined $config_file ||
2722             $config_file ne "$git_dir/config") {
2723                 %config = git_parse_project_config('gitweb');
2724                 $config_file = "$git_dir/config";
2725         }
2726
2727         # check if config variable (key) exists
2728         return unless exists $config{"gitweb.$key"};
2729
2730         # ensure given type
2731         if (!defined $type) {
2732                 return $config{"gitweb.$key"};
2733         } elsif ($type eq 'bool') {
2734                 # backward compatibility: 'git config --bool' returns true/false
2735                 return config_to_bool($config{"gitweb.$key"}) ? 'true' : 'false';
2736         } elsif ($type eq 'int') {
2737                 return config_to_int($config{"gitweb.$key"});
2738         }
2739         return $config{"gitweb.$key"};
2740 }
2741
2742 # get hash of given path at given ref
2743 sub git_get_hash_by_path {
2744         my $base = shift;
2745         my $path = shift || return undef;
2746         my $type = shift;
2747
2748         $path =~ s,/+$,,;
2749
2750         open my $fd, "-|", git_cmd(), "ls-tree", $base, "--", $path
2751                 or die_error(500, "Open git-ls-tree failed");
2752         my $line = <$fd>;
2753         close $fd or return undef;
2754
2755         if (!defined $line) {
2756                 # there is no tree or hash given by $path at $base
2757                 return undef;
2758         }
2759
2760         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
2761         $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/;
2762         if (defined $type && $type ne $2) {
2763                 # type doesn't match
2764                 return undef;
2765         }
2766         return $3;
2767 }
2768
2769 # get path of entry with given hash at given tree-ish (ref)
2770 # used to get 'from' filename for combined diff (merge commit) for renames
2771 sub git_get_path_by_hash {
2772         my $base = shift || return;
2773         my $hash = shift || return;
2774
2775         local $/ = "\0";
2776
2777         open my $fd, "-|", git_cmd(), "ls-tree", '-r', '-t', '-z', $base
2778                 or return undef;
2779         while (my $line = <$fd>) {
2780                 chomp $line;
2781
2782                 #'040000 tree 595596a6a9117ddba9fe379b6b012b558bac8423  gitweb'
2783                 #'100644 blob e02e90f0429be0d2a69b76571101f20b8f75530f  gitweb/README'
2784                 if ($line =~ m/(?:[0-9]+) (?:.+) $hash\t(.+)$/) {
2785                         close $fd;
2786                         return $1;
2787                 }
2788         }
2789         close $fd;
2790         return undef;
2791 }
2792
2793 ## ......................................................................
2794 ## git utility functions, directly accessing git repository
2795
2796 # get the value of config variable either from file named as the variable
2797 # itself in the repository ($GIT_DIR/$name file), or from gitweb.$name
2798 # configuration variable in the repository config file.
2799 sub git_get_file_or_project_config {
2800         my ($path, $name) = @_;
2801
2802         $git_dir = "$projectroot/$path";
2803         open my $fd, '<', "$git_dir/$name"
2804                 or return git_get_project_config($name);
2805         my $conf = <$fd>;
2806         close $fd;
2807         if (defined $conf) {
2808                 chomp $conf;
2809         }
2810         return $conf;
2811 }
2812
2813 sub git_get_project_description {
2814         my $path = shift;
2815         return git_get_file_or_project_config($path, 'description');
2816 }
2817
2818 sub git_get_project_category {
2819         my $path = shift;
2820         return git_get_file_or_project_config($path, 'category');
2821 }
2822
2823
2824 # supported formats:
2825 # * $GIT_DIR/ctags/<tagname> file (in 'ctags' subdirectory)
2826 #   - if its contents is a number, use it as tag weight,
2827 #   - otherwise add a tag with weight 1
2828 # * $GIT_DIR/ctags file, each line is a tag (with weight 1)
2829 #   the same value multiple times increases tag weight
2830 # * `gitweb.ctag' multi-valued repo config variable
2831 sub git_get_project_ctags {
2832         my $project = shift;
2833         my $ctags = {};
2834
2835         $git_dir = "$projectroot/$project";
2836         if (opendir my $dh, "$git_dir/ctags") {
2837                 my @files = grep { -f $_ } map { "$git_dir/ctags/$_" } readdir($dh);
2838                 foreach my $tagfile (@files) {
2839                         open my $ct, '<', $tagfile
2840                                 or next;
2841                         my $val = <$ct>;
2842                         chomp $val if $val;
2843                         close $ct;
2844
2845                         (my $ctag = $tagfile) =~ s#.*/##;
2846                         if ($val =~ /^\d+$/) {
2847                                 $ctags->{$ctag} = $val;
2848                         } else {
2849                                 $ctags->{$ctag} = 1;
2850                         }
2851                 }
2852                 closedir $dh;
2853
2854         } elsif (open my $fh, '<', "$git_dir/ctags") {
2855                 while (my $line = <$fh>) {
2856                         chomp $line;
2857                         $ctags->{$line}++ if $line;
2858                 }
2859                 close $fh;
2860
2861         } else {
2862                 my $taglist = config_to_multi(git_get_project_config('ctag'));
2863                 foreach my $tag (@$taglist) {
2864                         $ctags->{$tag}++;
2865                 }
2866         }
2867
2868         return $ctags;
2869 }
2870
2871 # return hash, where keys are content tags ('ctags'),
2872 # and values are sum of weights of given tag in every project
2873 sub git_gather_all_ctags {
2874         my $projects = shift;
2875         my $ctags = {};
2876
2877         foreach my $p (@$projects) {
2878                 foreach my $ct (keys %{$p->{'ctags'}}) {
2879                         $ctags->{$ct} += $p->{'ctags'}->{$ct};
2880                 }
2881         }
2882
2883         return $ctags;
2884 }
2885
2886 sub git_populate_project_tagcloud {
2887         my $ctags = shift;
2888
2889         # First, merge different-cased tags; tags vote on casing
2890         my %ctags_lc;
2891         foreach (keys %$ctags) {
2892                 $ctags_lc{lc $_}->{count} += $ctags->{$_};
2893                 if (not $ctags_lc{lc $_}->{topcount}
2894                     or $ctags_lc{lc $_}->{topcount} < $ctags->{$_}) {
2895                         $ctags_lc{lc $_}->{topcount} = $ctags->{$_};
2896                         $ctags_lc{lc $_}->{topname} = $_;
2897                 }
2898         }
2899
2900         my $cloud;
2901         my $matched = $input_params{'ctag'};
2902         if (eval { require HTML::TagCloud; 1; }) {
2903                 $cloud = HTML::TagCloud->new;
2904                 foreach my $ctag (sort keys %ctags_lc) {
2905                         # Pad the title with spaces so that the cloud looks
2906                         # less crammed.
2907                         my $title = esc_html($ctags_lc{$ctag}->{topname});
2908                         $title =~ s/ /&nbsp;/g;
2909                         $title =~ s/^/&nbsp;/g;
2910                         $title =~ s/$/&nbsp;/g;
2911                         if (defined $matched && $matched eq $ctag) {
2912                                 $title = qq(<span class="match">$title</span>);
2913                         }
2914                         $cloud->add($title, href(project=>undef, ctag=>$ctag),
2915                                     $ctags_lc{$ctag}->{count});
2916                 }
2917         } else {
2918                 $cloud = {};
2919                 foreach my $ctag (keys %ctags_lc) {
2920                         my $title = esc_html($ctags_lc{$ctag}->{topname}, -nbsp=>1);
2921                         if (defined $matched && $matched eq $ctag) {
2922                                 $title = qq(<span class="match">$title</span>);
2923                         }
2924                         $cloud->{$ctag}{count} = $ctags_lc{$ctag}->{count};
2925                         $cloud->{$ctag}{ctag} =
2926                                 $cgi->a({-href=>href(project=>undef, ctag=>$ctag)}, $title);
2927                 }
2928         }
2929         return $cloud;
2930 }
2931
2932 sub git_show_project_tagcloud {
2933         my ($cloud, $count) = @_;
2934         if (ref $cloud eq 'HTML::TagCloud') {
2935                 return $cloud->html_and_css($count);
2936         } else {
2937                 my @tags = sort { $cloud->{$a}->{'count'} <=> $cloud->{$b}->{'count'} } keys %$cloud;
2938                 return
2939                         '<div id="htmltagcloud"'.($project ? '' : ' align="center"').'>' .
2940                         join (', ', map {
2941                                 $cloud->{$_}->{'ctag'}
2942                         } splice(@tags, 0, $count)) .
2943                         '</div>';
2944         }
2945 }
2946
2947 sub git_get_project_url_list {
2948         my $path = shift;
2949
2950         $git_dir = "$projectroot/$path";
2951         open my $fd, '<', "$git_dir/cloneurl"
2952                 or return wantarray ?
2953                 @{ config_to_multi(git_get_project_config('url')) } :
2954                    config_to_multi(git_get_project_config('url'));
2955         my @git_project_url_list = map { chomp; $_ } <$fd>;
2956         close $fd;
2957
2958         return wantarray ? @git_project_url_list : \@git_project_url_list;
2959 }
2960
2961 sub git_get_projects_list {
2962         my $filter = shift || '';
2963         my $paranoid = shift;
2964         my @list;
2965
2966         if (-d $projects_list) {
2967                 # search in directory
2968                 my $dir = $projects_list;
2969                 # remove the trailing "/"
2970                 $dir =~ s!/+$!!;
2971                 my $pfxlen = length("$dir");
2972                 my $pfxdepth = ($dir =~ tr!/!!);
2973                 # when filtering, search only given subdirectory
2974                 if ($filter && !$paranoid) {
2975                         $dir .= "/$filter";
2976                         $dir =~ s!/+$!!;
2977                 }
2978
2979                 File::Find::find({
2980                         follow_fast => 1, # follow symbolic links
2981                         follow_skip => 2, # ignore duplicates
2982                         dangling_symlinks => 0, # ignore dangling symlinks, silently
2983                         wanted => sub {
2984                                 # global variables
2985                                 our $project_maxdepth;
2986                                 our $projectroot;
2987                                 # skip project-list toplevel, if we get it.
2988                                 return if (m!^[/.]$!);
2989                                 # only directories can be git repositories
2990                                 return unless (-d $_);
2991                                 # don't traverse too deep (Find is super slow on os x)
2992                                 # $project_maxdepth excludes depth of $projectroot
2993                                 if (($File::Find::name =~ tr!/!!) - $pfxdepth > $project_maxdepth) {
2994                                         $File::Find::prune = 1;
2995                                         return;
2996                                 }
2997
2998                                 my $path = substr($File::Find::name, $pfxlen + 1);
2999                                 # paranoidly only filter here
3000                                 if ($paranoid && $filter && $path !~ m!^\Q$filter\E/!) {
3001                                         next;
3002                                 }
3003                                 # we check related file in $projectroot
3004                                 if (check_export_ok("$projectroot/$path")) {
3005                                         push @list, { path => $path };
3006                                         $File::Find::prune = 1;
3007                                 }
3008                         },
3009                 }, "$dir");
3010
3011         } elsif (-f $projects_list) {
3012                 # read from file(url-encoded):
3013                 # 'git%2Fgit.git Linus+Torvalds'
3014                 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
3015                 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
3016                 open my $fd, '<', $projects_list or return;
3017         PROJECT:
3018                 while (my $line = <$fd>) {
3019                         chomp $line;
3020                         my ($path, $owner) = split ' ', $line;
3021                         $path = unescape($path);
3022                         $owner = unescape($owner);
3023                         if (!defined $path) {
3024                                 next;
3025                         }
3026                         # if $filter is rpovided, check if $path begins with $filter
3027                         if ($filter && $path !~ m!^\Q$filter\E/!) {
3028                                 next;
3029                         }
3030                         if (check_export_ok("$projectroot/$path")) {
3031                                 my $pr = {
3032                                         path => $path
3033                                 };
3034                                 if ($owner) {
3035                                         $pr->{'owner'} = to_utf8($owner);
3036                                 }
3037                                 push @list, $pr;
3038                         }
3039                 }
3040                 close $fd;
3041         }
3042         return @list;
3043 }
3044
3045 # written with help of Tree::Trie module (Perl Artistic License, GPL compatibile)
3046 # as side effects it sets 'forks' field to list of forks for forked projects
3047 sub filter_forks_from_projects_list {
3048         my $projects = shift;
3049
3050         my %trie; # prefix tree of directories (path components)
3051         # generate trie out of those directories that might contain forks
3052         foreach my $pr (@$projects) {
3053                 my $path = $pr->{'path'};
3054                 $path =~ s/\.git$//;      # forks of 'repo.git' are in 'repo/' directory
3055                 next if ($path =~ m!/$!); # skip non-bare repositories, e.g. 'repo/.git'
3056                 next unless ($path);      # skip '.git' repository: tests, git-instaweb
3057                 next unless (-d "$projectroot/$path"); # containing directory exists
3058                 $pr->{'forks'} = [];      # there can be 0 or more forks of project
3059
3060                 # add to trie
3061                 my @dirs = split('/', $path);
3062                 # walk the trie, until either runs out of components or out of trie
3063                 my $ref = \%trie;
3064                 while (scalar @dirs &&
3065                        exists($ref->{$dirs[0]})) {
3066                         $ref = $ref->{shift @dirs};
3067                 }
3068                 # create rest of trie structure from rest of components
3069                 foreach my $dir (@dirs) {
3070                         $ref = $ref->{$dir} = {};
3071                 }
3072                 # create end marker, store $pr as a data
3073                 $ref->{''} = $pr if (!exists $ref->{''});
3074         }
3075
3076         # filter out forks, by finding shortest prefix match for paths
3077         my @filtered;
3078  PROJECT:
3079         foreach my $pr (@$projects) {
3080                 # trie lookup
3081                 my $ref = \%trie;
3082         DIR:
3083                 foreach my $dir (split('/', $pr->{'path'})) {
3084                         if (exists $ref->{''}) {
3085                                 # found [shortest] prefix, is a fork - skip it
3086                                 push @{$ref->{''}{'forks'}}, $pr;
3087                                 next PROJECT;
3088                         }
3089                         if (!exists $ref->{$dir}) {
3090                                 # not in trie, cannot have prefix, not a fork
3091                                 push @filtered, $pr;
3092                                 next PROJECT;
3093                         }
3094                         # If the dir is there, we just walk one step down the trie.
3095                         $ref = $ref->{$dir};
3096                 }
3097                 # we ran out of trie
3098                 # (shouldn't happen: it's either no match, or end marker)
3099                 push @filtered, $pr;
3100         }
3101
3102         return @filtered;
3103 }
3104
3105 # note: fill_project_list_info must be run first,
3106 # for 'descr_long' and 'ctags' to be filled
3107 sub search_projects_list {
3108         my ($projlist, %opts) = @_;
3109         my $tagfilter  = $opts{'tagfilter'};
3110         my $search_re = $opts{'search_regexp'};
3111
3112         return @$projlist
3113                 unless ($tagfilter || $search_re);
3114
3115         # searching projects require filling to be run before it;
3116         fill_project_list_info($projlist,
3117                                $tagfilter  ? 'ctags' : (),
3118                                $search_re ? ('path', 'descr') : ());
3119         my @projects;
3120  PROJECT:
3121         foreach my $pr (@$projlist) {
3122
3123                 if ($tagfilter) {
3124                         next unless ref($pr->{'ctags'}) eq 'HASH';
3125                         next unless
3126                                 grep { lc($_) eq lc($tagfilter) } keys %{$pr->{'ctags'}};
3127                 }
3128
3129                 if ($search_re) {
3130                         next unless
3131                                 $pr->{'path'} =~ /$search_re/ ||
3132                                 $pr->{'descr_long'} =~ /$search_re/;
3133                 }
3134
3135                 push @projects, $pr;
3136         }
3137
3138         return @projects;
3139 }
3140
3141 our $gitweb_project_owner = undef;
3142 sub git_get_project_list_from_file {
3143
3144         return if (defined $gitweb_project_owner);
3145
3146         $gitweb_project_owner = {};
3147         # read from file (url-encoded):
3148         # 'git%2Fgit.git Linus+Torvalds'
3149         # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
3150         # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
3151         if (-f $projects_list) {
3152                 open(my $fd, '<', $projects_list);
3153                 while (my $line = <$fd>) {
3154                         chomp $line;
3155                         my ($pr, $ow) = split ' ', $line;
3156                         $pr = unescape($pr);
3157                         $ow = unescape($ow);
3158                         $gitweb_project_owner->{$pr} = to_utf8($ow);
3159                 }
3160                 close $fd;
3161         }
3162 }
3163
3164 sub git_get_project_owner {
3165         my $project = shift;
3166         my $owner;
3167
3168         return undef unless $project;
3169         $git_dir = "$projectroot/$project";
3170
3171         if (!defined $gitweb_project_owner) {
3172                 git_get_project_list_from_file();
3173         }
3174
3175         if (exists $gitweb_project_owner->{$project}) {
3176                 $owner = $gitweb_project_owner->{$project};
3177         }
3178         if (!defined $owner){
3179                 $owner = git_get_project_config('owner');
3180         }
3181         if (!defined $owner) {
3182                 $owner = get_file_owner("$git_dir");
3183         }
3184
3185         return $owner;
3186 }
3187
3188 sub git_get_last_activity {
3189         my ($path) = @_;
3190         my $fd;
3191
3192         $git_dir = "$projectroot/$path";
3193         open($fd, "-|", git_cmd(), 'for-each-ref',
3194              '--format=%(committer)',
3195              '--sort=-committerdate',
3196              '--count=1',
3197              'refs/heads') or return;
3198         my $most_recent = <$fd>;
3199         close $fd or return;
3200         if (defined $most_recent &&
3201             $most_recent =~ / (\d+) [-+][01]\d\d\d$/) {
3202                 my $timestamp = $1;
3203                 my $age = time - $timestamp;
3204                 return ($age, age_string($age));
3205         }
3206         return (undef, undef);
3207 }
3208
3209 # Implementation note: when a single remote is wanted, we cannot use 'git
3210 # remote show -n' because that command always work (assuming it's a remote URL
3211 # if it's not defined), and we cannot use 'git remote show' because that would
3212 # try to make a network roundtrip. So the only way to find if that particular
3213 # remote is defined is to walk the list provided by 'git remote -v' and stop if
3214 # and when we find what we want.
3215 sub git_get_remotes_list {
3216         my $wanted = shift;
3217         my %remotes = ();
3218
3219         open my $fd, '-|' , git_cmd(), 'remote', '-v';
3220         return unless $fd;
3221         while (my $remote = <$fd>) {
3222                 chomp $remote;
3223                 $remote =~ s!\t(.*?)\s+\((\w+)\)$!!;
3224                 next if $wanted and not $remote eq $wanted;
3225                 my ($url, $key) = ($1, $2);
3226
3227                 $remotes{$remote} ||= { 'heads' => () };
3228                 $remotes{$remote}{$key} = $url;
3229         }
3230         close $fd or return;
3231         return wantarray ? %remotes : \%remotes;
3232 }
3233
3234 # Takes a hash of remotes as first parameter and fills it by adding the
3235 # available remote heads for each of the indicated remotes.
3236 sub fill_remote_heads {
3237         my $remotes = shift;
3238         my @heads = map { "remotes/$_" } keys %$remotes;
3239         my @remoteheads = git_get_heads_list(undef, @heads);
3240         foreach my $remote (keys %$remotes) {
3241                 $remotes->{$remote}{'heads'} = [ grep {
3242                         $_->{'name'} =~ s!^$remote/!!
3243                         } @remoteheads ];
3244         }
3245 }
3246
3247 sub git_get_references {
3248         my $type = shift || "";
3249         my %refs;
3250         # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
3251         # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
3252         open my $fd, "-|", git_cmd(), "show-ref", "--dereference",
3253                 ($type ? ("--", "refs/$type") : ()) # use -- <pattern> if $type
3254                 or return;
3255
3256         while (my $line = <$fd>) {
3257                 chomp $line;
3258                 if ($line =~ m!^([0-9a-fA-F]{40})\srefs/($type.*)$!) {
3259                         if (defined $refs{$1}) {
3260                                 push @{$refs{$1}}, $2;
3261                         } else {
3262                                 $refs{$1} = [ $2 ];
3263                         }
3264                 }
3265         }
3266         close $fd or return;
3267         return \%refs;
3268 }
3269
3270 sub git_get_rev_name_tags {
3271         my $hash = shift || return undef;
3272
3273         open my $fd, "-|", git_cmd(), "name-rev", "--tags", $hash
3274                 or return;
3275         my $name_rev = <$fd>;
3276         close $fd;
3277
3278         if ($name_rev =~ m|^$hash tags/(.*)$|) {
3279                 return $1;
3280         } else {
3281                 # catches also '$hash undefined' output
3282                 return undef;
3283         }
3284 }
3285
3286 ## ----------------------------------------------------------------------
3287 ## parse to hash functions
3288
3289 sub parse_date {
3290         my $epoch = shift;
3291         my $tz = shift || "-0000";
3292
3293         my %date;
3294         my @months = ("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec");
3295         my @days = ("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");
3296         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($epoch);
3297         $date{'hour'} = $hour;
3298         $date{'minute'} = $min;
3299         $date{'mday'} = $mday;
3300         $date{'day'} = $days[$wday];
3301         $date{'month'} = $months[$mon];
3302         $date{'rfc2822'}   = sprintf "%s, %d %s %4d %02d:%02d:%02d +0000",
3303                              $days[$wday], $mday, $months[$mon], 1900+$year, $hour ,$min, $sec;
3304         $date{'mday-time'} = sprintf "%d %s %02d:%02d",
3305                              $mday, $months[$mon], $hour ,$min;
3306         $date{'iso-8601'}  = sprintf "%04d-%02d-%02dT%02d:%02d:%02dZ",
3307                              1900+$year, 1+$mon, $mday, $hour ,$min, $sec;
3308
3309         my ($tz_sign, $tz_hour, $tz_min) =
3310                 ($tz =~ m/^([-+])(\d\d)(\d\d)$/);
3311         $tz_sign = ($tz_sign eq '-' ? -1 : +1);
3312         my $local = $epoch + $tz_sign*((($tz_hour*60) + $tz_min)*60);
3313         ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($local);
3314         $date{'hour_local'} = $hour;
3315         $date{'minute_local'} = $min;
3316         $date{'tz_local'} = $tz;
3317         $date{'iso-tz'} = sprintf("%04d-%02d-%02d %02d:%02d:%02d %s",
3318                                   1900+$year, $mon+1, $mday,
3319                                   $hour, $min, $sec, $tz);
3320         return %date;
3321 }
3322
3323 sub parse_tag {
3324         my $tag_id = shift;
3325         my %tag;
3326         my @comment;
3327
3328         open my $fd, "-|", git_cmd(), "cat-file", "tag", $tag_id or return;
3329         $tag{'id'} = $tag_id;
3330         while (my $line = <$fd>) {
3331                 chomp $line;
3332                 if ($line =~ m/^object ([0-9a-fA-F]{40})$/) {
3333                         $tag{'object'} = $1;
3334                 } elsif ($line =~ m/^type (.+)$/) {
3335                         $tag{'type'} = $1;
3336                 } elsif ($line =~ m/^tag (.+)$/) {
3337                         $tag{'name'} = $1;
3338                 } elsif ($line =~ m/^tagger (.*) ([0-9]+) (.*)$/) {
3339                         $tag{'author'} = $1;
3340                         $tag{'author_epoch'} = $2;
3341                         $tag{'author_tz'} = $3;
3342                         if ($tag{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3343                                 $tag{'author_name'}  = $1;
3344                                 $tag{'author_email'} = $2;
3345                         } else {
3346                                 $tag{'author_name'} = $tag{'author'};
3347                         }
3348                 } elsif ($line =~ m/--BEGIN/) {
3349                         push @comment, $line;
3350                         last;
3351                 } elsif ($line eq "") {
3352                         last;
3353                 }
3354         }
3355         push @comment, <$fd>;
3356         $tag{'comment'} = \@comment;
3357         close $fd or return;
3358         if (!defined $tag{'name'}) {
3359                 return
3360         };
3361         return %tag
3362 }
3363
3364 sub parse_commit_text {
3365         my ($commit_text, $withparents) = @_;
3366         my @commit_lines = split '\n', $commit_text;
3367         my %co;
3368
3369         pop @commit_lines; # Remove '\0'
3370
3371         if (! @commit_lines) {
3372                 return;
3373         }
3374
3375         my $header = shift @commit_lines;
3376         if ($header !~ m/^[0-9a-fA-F]{40}/) {
3377                 return;
3378         }
3379         ($co{'id'}, my @parents) = split ' ', $header;
3380         while (my $line = shift @commit_lines) {
3381                 last if $line eq "\n";
3382                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
3383                         $co{'tree'} = $1;
3384                 } elsif ((!defined $withparents) && ($line =~ m/^parent ([0-9a-fA-F]{40})$/)) {
3385                         push @parents, $1;
3386                 } elsif ($line =~ m/^author (.*) ([0-9]+) (.*)$/) {
3387                         $co{'author'} = to_utf8($1);
3388                         $co{'author_epoch'} = $2;
3389                         $co{'author_tz'} = $3;
3390                         if ($co{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3391                                 $co{'author_name'}  = $1;
3392                                 $co{'author_email'} = $2;
3393                         } else {
3394                                 $co{'author_name'} = $co{'author'};
3395                         }
3396                 } elsif ($line =~ m/^committer (.*) ([0-9]+) (.*)$/) {
3397                         $co{'committer'} = to_utf8($1);
3398                         $co{'committer_epoch'} = $2;
3399                         $co{'committer_tz'} = $3;
3400                         if ($co{'committer'} =~ m/^([^<]+) <([^>]*)>/) {
3401                                 $co{'committer_name'}  = $1;
3402                                 $co{'committer_email'} = $2;
3403                         } else {
3404                                 $co{'committer_name'} = $co{'committer'};
3405                         }
3406                 }
3407         }
3408         if (!defined $co{'tree'}) {
3409                 return;
3410         };
3411         $co{'parents'} = \@parents;
3412         $co{'parent'} = $parents[0];
3413
3414         foreach my $title (@commit_lines) {
3415                 $title =~ s/^    //;
3416                 if ($title ne "") {
3417                         $co{'title'} = chop_str($title, 80, 5);
3418                         # remove leading stuff of merges to make the interesting part visible
3419                         if (length($title) > 50) {
3420                                 $title =~ s/^Automatic //;
3421                                 $title =~ s/^merge (of|with) /Merge ... /i;
3422                                 if (length($title) > 50) {
3423                                         $title =~ s/(http|rsync):\/\///;
3424                                 }
3425                                 if (length($title) > 50) {
3426                                         $title =~ s/(master|www|rsync)\.//;
3427                                 }
3428                                 if (length($title) > 50) {
3429                                         $title =~ s/kernel.org:?//;
3430                                 }
3431                                 if (length($title) > 50) {
3432                                         $title =~ s/\/pub\/scm//;
3433                                 }
3434                         }
3435                         $co{'title_short'} = chop_str($title, 50, 5);
3436                         last;
3437                 }
3438         }
3439         if (! defined $co{'title'} || $co{'title'} eq "") {
3440                 $co{'title'} = $co{'title_short'} = '(no commit message)';
3441         }
3442         # remove added spaces
3443         foreach my $line (@commit_lines) {
3444                 $line =~ s/^    //;
3445         }
3446         $co{'comment'} = \@commit_lines;
3447
3448         my $age = time - $co{'committer_epoch'};
3449         $co{'age'} = $age;
3450         $co{'age_string'} = age_string($age);
3451         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($co{'committer_epoch'});
3452         if ($age > 60*60*24*7*2) {
3453                 $co{'age_string_date'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3454                 $co{'age_string_age'} = $co{'age_string'};
3455         } else {
3456                 $co{'age_string_date'} = $co{'age_string'};
3457                 $co{'age_string_age'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3458         }
3459         return %co;
3460 }
3461
3462 sub parse_commit {
3463         my ($commit_id) = @_;
3464         my %co;
3465
3466         local $/ = "\0";
3467
3468         open my $fd, "-|", git_cmd(), "rev-list",
3469                 "--parents",
3470                 "--header",
3471                 "--max-count=1",
3472                 $commit_id,
3473                 "--",
3474                 or die_error(500, "Open git-rev-list failed");
3475         %co = parse_commit_text(<$fd>, 1);
3476         close $fd;
3477
3478         return %co;
3479 }
3480
3481 sub parse_commits {
3482         my ($commit_id, $maxcount, $skip, $filename, @args) = @_;
3483         my @cos;
3484
3485         $maxcount ||= 1;
3486         $skip ||= 0;
3487
3488         local $/ = "\0";
3489
3490         open my $fd, "-|", git_cmd(), "rev-list",
3491                 "--header",
3492                 @args,
3493                 ("--max-count=" . $maxcount),
3494                 ("--skip=" . $skip),
3495                 @extra_options,
3496                 $commit_id,
3497                 "--",
3498                 ($filename ? ($filename) : ())
3499                 or die_error(500, "Open git-rev-list failed");
3500         while (my $line = <$fd>) {
3501                 my %co = parse_commit_text($line);
3502                 push @cos, \%co;
3503         }
3504         close $fd;
3505
3506         return wantarray ? @cos : \@cos;
3507 }
3508
3509 # parse line of git-diff-tree "raw" output
3510 sub parse_difftree_raw_line {
3511         my $line = shift;
3512         my %res;
3513
3514         # ':100644 100644 03b218260e99b78c6df0ed378e59ed9205ccc96d 3b93d5e7cc7f7dd4ebed13a5cc1a4ad976fc94d8 M   ls-files.c'
3515         # ':100644 100644 7f9281985086971d3877aca27704f2aaf9c448ce bc190ebc71bbd923f2b728e505408f5e54bd073a M   rev-tree.c'
3516         if ($line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)([0-9]{0,3})\t(.*)$/) {
3517                 $res{'from_mode'} = $1;
3518                 $res{'to_mode'} = $2;
3519                 $res{'from_id'} = $3;
3520                 $res{'to_id'} = $4;
3521                 $res{'status'} = $5;
3522                 $res{'similarity'} = $6;
3523                 if ($res{'status'} eq 'R' || $res{'status'} eq 'C') { # renamed or copied
3524                         ($res{'from_file'}, $res{'to_file'}) = map { unquote($_) } split("\t", $7);
3525                 } else {
3526                         $res{'from_file'} = $res{'to_file'} = $res{'file'} = unquote($7);
3527                 }
3528         }
3529         # '::100755 100755 100755 60e79ca1b01bc8b057abe17ddab484699a7f5fdb 94067cc5f73388f33722d52ae02f44692bc07490 94067cc5f73388f33722d52ae02f44692bc07490 MR git-gui/git-gui.sh'
3530         # combined diff (for merge commit)
3531         elsif ($line =~ s/^(::+)((?:[0-7]{6} )+)((?:[0-9a-fA-F]{40} )+)([a-zA-Z]+)\t(.*)$//) {
3532                 $res{'nparents'}  = length($1);
3533                 $res{'from_mode'} = [ split(' ', $2) ];
3534                 $res{'to_mode'} = pop @{$res{'from_mode'}};
3535                 $res{'from_id'} = [ split(' ', $3) ];
3536                 $res{'to_id'} = pop @{$res{'from_id'}};
3537                 $res{'status'} = [ split('', $4) ];
3538                 $res{'to_file'} = unquote($5);
3539         }
3540         # 'c512b523472485aef4fff9e57b229d9d243c967f'
3541         elsif ($line =~ m/^([0-9a-fA-F]{40})$/) {
3542                 $res{'commit'} = $1;
3543         }
3544
3545         return wantarray ? %res : \%res;
3546 }
3547
3548 # wrapper: return parsed line of git-diff-tree "raw" output
3549 # (the argument might be raw line, or parsed info)
3550 sub parsed_difftree_line {
3551         my $line_or_ref = shift;
3552
3553         if (ref($line_or_ref) eq "HASH") {
3554                 # pre-parsed (or generated by hand)
3555                 return $line_or_ref;
3556         } else {
3557                 return parse_difftree_raw_line($line_or_ref);
3558         }
3559 }
3560
3561 # parse line of git-ls-tree output
3562 sub parse_ls_tree_line {
3563         my $line = shift;
3564         my %opts = @_;
3565         my %res;
3566
3567         if ($opts{'-l'}) {
3568                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa   16717  panic.c'
3569                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40}) +(-|[0-9]+)\t(.+)$/s;
3570
3571                 $res{'mode'} = $1;
3572                 $res{'type'} = $2;
3573                 $res{'hash'} = $3;
3574                 $res{'size'} = $4;
3575                 if ($opts{'-z'}) {
3576                         $res{'name'} = $5;
3577                 } else {
3578                         $res{'name'} = unquote($5);
3579                 }
3580         } else {
3581                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
3582                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t(.+)$/s;
3583
3584                 $res{'mode'} = $1;
3585                 $res{'type'} = $2;
3586                 $res{'hash'} = $3;
3587                 if ($opts{'-z'}) {
3588                         $res{'name'} = $4;
3589                 } else {
3590                         $res{'name'} = unquote($4);
3591                 }
3592         }
3593
3594         return wantarray ? %res : \%res;
3595 }
3596
3597 # generates _two_ hashes, references to which are passed as 2 and 3 argument
3598 sub parse_from_to_diffinfo {
3599         my ($diffinfo, $from, $to, @parents) = @_;
3600
3601         if ($diffinfo->{'nparents'}) {
3602                 # combined diff
3603                 $from->{'file'} = [];
3604                 $from->{'href'} = [];
3605                 fill_from_file_info($diffinfo, @parents)
3606                         unless exists $diffinfo->{'from_file'};
3607                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
3608                         $from->{'file'}[$i] =
3609                                 defined $diffinfo->{'from_file'}[$i] ?
3610                                         $diffinfo->{'from_file'}[$i] :
3611                                         $diffinfo->{'to_file'};
3612                         if ($diffinfo->{'status'}[$i] ne "A") { # not new (added) file
3613                                 $from->{'href'}[$i] = href(action=>"blob",
3614                                                            hash_base=>$parents[$i],
3615                                                            hash=>$diffinfo->{'from_id'}[$i],
3616                                                            file_name=>$from->{'file'}[$i]);
3617                         } else {
3618                                 $from->{'href'}[$i] = undef;
3619                         }
3620                 }
3621         } else {
3622                 # ordinary (not combined) diff
3623                 $from->{'file'} = $diffinfo->{'from_file'};
3624                 if ($diffinfo->{'status'} ne "A") { # not new (added) file
3625                         $from->{'href'} = href(action=>"blob", hash_base=>$hash_parent,
3626                                                hash=>$diffinfo->{'from_id'},
3627                                                file_name=>$from->{'file'});
3628                 } else {
3629                         delete $from->{'href'};
3630                 }
3631         }
3632
3633         $to->{'file'} = $diffinfo->{'to_file'};
3634         if (!is_deleted($diffinfo)) { # file exists in result
3635                 $to->{'href'} = href(action=>"blob", hash_base=>$hash,
3636                                      hash=>$diffinfo->{'to_id'},
3637                                      file_name=>$to->{'file'});
3638         } else {
3639                 delete $to->{'href'};
3640         }
3641 }
3642
3643 ## ......................................................................
3644 ## parse to array of hashes functions
3645
3646 sub git_get_heads_list {
3647         my ($limit, @classes) = @_;
3648         @classes = ('heads') unless @classes;
3649         my @patterns = map { "refs/$_" } @classes;
3650         my @headslist;
3651
3652         open my $fd, '-|', git_cmd(), 'for-each-ref',
3653                 ($limit ? '--count='.($limit+1) : ()), '--sort=-committerdate',
3654                 '--format=%(objectname) %(refname) %(subject)%00%(committer)',
3655                 @patterns
3656                 or return;
3657         while (my $line = <$fd>) {
3658                 my %ref_item;
3659
3660                 chomp $line;
3661                 my ($refinfo, $committerinfo) = split(/\0/, $line);
3662                 my ($hash, $name, $title) = split(' ', $refinfo, 3);
3663                 my ($committer, $epoch, $tz) =
3664                         ($committerinfo =~ /^(.*) ([0-9]+) (.*)$/);
3665                 $ref_item{'fullname'}  = $name;
3666                 $name =~ s!^refs/(?:head|remote)s/!!;
3667
3668                 $ref_item{'name'}  = $name;
3669                 $ref_item{'id'}    = $hash;
3670                 $ref_item{'title'} = $title || '(no commit message)';
3671                 $ref_item{'epoch'} = $epoch;
3672                 if ($epoch) {
3673                         $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3674                 } else {
3675                         $ref_item{'age'} = "unknown";
3676                 }
3677
3678                 push @headslist, \%ref_item;
3679         }
3680         close $fd;
3681
3682         return wantarray ? @headslist : \@headslist;
3683 }
3684
3685 sub git_get_tags_list {
3686         my $limit = shift;
3687         my @tagslist;
3688
3689         open my $fd, '-|', git_cmd(), 'for-each-ref',
3690                 ($limit ? '--count='.($limit+1) : ()), '--sort=-creatordate',
3691                 '--format=%(objectname) %(objecttype) %(refname) '.
3692                 '%(*objectname) %(*objecttype) %(subject)%00%(creator)',
3693                 'refs/tags'
3694                 or return;
3695         while (my $line = <$fd>) {
3696                 my %ref_item;
3697
3698                 chomp $line;
3699                 my ($refinfo, $creatorinfo) = split(/\0/, $line);
3700                 my ($id, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
3701                 my ($creator, $epoch, $tz) =
3702                         ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
3703                 $ref_item{'fullname'} = $name;
3704                 $name =~ s!^refs/tags/!!;
3705
3706                 $ref_item{'type'} = $type;
3707                 $ref_item{'id'} = $id;
3708                 $ref_item{'name'} = $name;
3709                 if ($type eq "tag") {
3710                         $ref_item{'subject'} = $title;
3711                         $ref_item{'reftype'} = $reftype;
3712                         $ref_item{'refid'}   = $refid;
3713                 } else {
3714                         $ref_item{'reftype'} = $type;
3715                         $ref_item{'refid'}   = $id;
3716                 }
3717
3718                 if ($type eq "tag" || $type eq "commit") {
3719                         $ref_item{'epoch'} = $epoch;
3720                         if ($epoch) {
3721                                 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3722                         } else {
3723                                 $ref_item{'age'} = "unknown";
3724                         }
3725                 }
3726
3727                 push @tagslist, \%ref_item;
3728         }
3729         close $fd;
3730
3731         return wantarray ? @tagslist : \@tagslist;
3732 }
3733
3734 ## ----------------------------------------------------------------------
3735 ## filesystem-related functions
3736
3737 sub get_file_owner {
3738         my $path = shift;
3739
3740         my ($dev, $ino, $mode, $nlink, $st_uid, $st_gid, $rdev, $size) = stat($path);
3741         my ($name, $passwd, $uid, $gid, $quota, $comment, $gcos, $dir, $shell) = getpwuid($st_uid);
3742         if (!defined $gcos) {
3743                 return undef;
3744         }
3745         my $owner = $gcos;
3746         $owner =~ s/[,;].*$//;
3747         return to_utf8($owner);
3748 }
3749
3750 # assume that file exists
3751 sub insert_file {
3752         my $filename = shift;
3753
3754         open my $fd, '<', $filename;
3755         print map { to_utf8($_) } <$fd>;
3756         close $fd;
3757 }
3758
3759 ## ......................................................................
3760 ## mimetype related functions
3761
3762 sub mimetype_guess_file {
3763         my $filename = shift;
3764         my $mimemap = shift;
3765         -r $mimemap or return undef;
3766
3767         my %mimemap;
3768         open(my $mh, '<', $mimemap) or return undef;
3769         while (<$mh>) {
3770                 next if m/^#/; # skip comments
3771                 my ($mimetype, @exts) = split(/\s+/);
3772                 foreach my $ext (@exts) {
3773                         $mimemap{$ext} = $mimetype;
3774                 }
3775         }
3776         close($mh);
3777
3778         $filename =~ /\.([^.]*)$/;
3779         return $mimemap{$1};
3780 }
3781
3782 sub mimetype_guess {
3783         my $filename = shift;
3784         my $mime;
3785         $filename =~ /\./ or return undef;
3786
3787         if ($mimetypes_file) {
3788                 my $file = $mimetypes_file;
3789                 if ($file !~ m!^/!) { # if it is relative path
3790                         # it is relative to project
3791                         $file = "$projectroot/$project/$file";
3792                 }
3793                 $mime = mimetype_guess_file($filename, $file);
3794         }
3795         $mime ||= mimetype_guess_file($filename, '/etc/mime.types');
3796         return $mime;
3797 }
3798
3799 sub blob_mimetype {
3800         my $fd = shift;
3801         my $filename = shift;
3802
3803         if ($filename) {
3804                 my $mime = mimetype_guess($filename);
3805                 $mime and return $mime;
3806         }
3807
3808         # just in case
3809         return $default_blob_plain_mimetype unless $fd;
3810
3811         if (-T $fd) {
3812                 return 'text/plain';
3813         } elsif (! $filename) {
3814                 return 'application/octet-stream';
3815         } elsif ($filename =~ m/\.png$/i) {
3816                 return 'image/png';
3817         } elsif ($filename =~ m/\.gif$/i) {
3818                 return 'image/gif';
3819         } elsif ($filename =~ m/\.jpe?g$/i) {
3820                 return 'image/jpeg';
3821         } else {
3822                 return 'application/octet-stream';
3823         }
3824 }
3825
3826 sub blob_contenttype {
3827         my ($fd, $file_name, $type) = @_;
3828
3829         $type ||= blob_mimetype($fd, $file_name);
3830         if ($type eq 'text/plain' && defined $default_text_plain_charset) {
3831                 $type .= "; charset=$default_text_plain_charset";
3832         }
3833
3834         return $type;
3835 }
3836
3837 # guess file syntax for syntax highlighting; return undef if no highlighting
3838 # the name of syntax can (in the future) depend on syntax highlighter used
3839 sub guess_file_syntax {
3840         my ($highlight, $mimetype, $file_name) = @_;
3841         return undef unless ($highlight && defined $file_name);
3842         my $basename = basename($file_name, '.in');
3843         return $highlight_basename{$basename}
3844                 if exists $highlight_basename{$basename};
3845
3846         $basename =~ /\.([^.]*)$/;
3847         my $ext = $1 or return undef;
3848         return $highlight_ext{$ext}
3849                 if exists $highlight_ext{$ext};
3850
3851         return undef;
3852 }
3853
3854 # run highlighter and return FD of its output,
3855 # or return original FD if no highlighting
3856 sub run_highlighter {
3857         my ($fd, $highlight, $syntax) = @_;
3858         return $fd unless ($highlight && defined $syntax);
3859
3860         close $fd;
3861         open $fd, quote_command(git_cmd(), "cat-file", "blob", $hash)." | ".
3862                   quote_command($highlight_bin).
3863                   " --replace-tabs=8 --fragment --syntax $syntax |"
3864                 or die_error(500, "Couldn't open file or run syntax highlighter");
3865         return $fd;
3866 }
3867
3868 ## ======================================================================
3869 ## functions printing HTML: header, footer, error page
3870
3871 sub get_page_title {
3872         my $title = to_utf8($site_name);
3873
3874         unless (defined $project) {
3875                 if (defined $project_filter) {
3876                         $title .= " - projects in '" . esc_path($project_filter) . "'";
3877                 }
3878                 return $title;
3879         }
3880         $title .= " - " . to_utf8($project);
3881
3882         return $title unless (defined $action);
3883         $title .= "/$action"; # $action is US-ASCII (7bit ASCII)
3884
3885         return $title unless (defined $file_name);
3886         $title .= " - " . esc_path($file_name);
3887         if ($action eq "tree" && $file_name !~ m|/$|) {
3888                 $title .= "/";
3889         }
3890
3891         return $title;
3892 }
3893
3894 sub get_content_type_html {
3895         # require explicit support from the UA if we are to send the page as
3896         # 'application/xhtml+xml', otherwise send it as plain old 'text/html'.
3897         # we have to do this because MSIE sometimes globs '*/*', pretending to
3898         # support xhtml+xml but choking when it gets what it asked for.
3899         if (defined $cgi->http('HTTP_ACCEPT') &&
3900             $cgi->http('HTTP_ACCEPT') =~ m/(,|;|\s|^)application\/xhtml\+xml(,|;|\s|$)/ &&
3901             $cgi->Accept('application/xhtml+xml') != 0) {
3902                 return 'application/xhtml+xml';
3903         } else {
3904                 return 'text/html';
3905         }
3906 }
3907
3908 sub print_feed_meta {
3909         if (defined $project) {
3910                 my %href_params = get_feed_info();
3911                 if (!exists $href_params{'-title'}) {
3912                         $href_params{'-title'} = 'log';
3913                 }
3914
3915                 foreach my $format (qw(RSS Atom)) {
3916                         my $type = lc($format);
3917                         my %link_attr = (
3918                                 '-rel' => 'alternate',
3919                                 '-title' => esc_attr("$project - $href_params{'-title'} - $format feed"),
3920                                 '-type' => "application/$type+xml"
3921                         );
3922
3923                         $href_params{'extra_options'} = undef;
3924                         $href_params{'action'} = $type;
3925                         $link_attr{'-href'} = href(%href_params);
3926                         print "<link ".
3927                               "rel=\"$link_attr{'-rel'}\" ".
3928                               "title=\"$link_attr{'-title'}\" ".
3929                               "href=\"$link_attr{'-href'}\" ".
3930                               "type=\"$link_attr{'-type'}\" ".
3931                               "/>\n";
3932
3933                         $href_params{'extra_options'} = '--no-merges';
3934                         $link_attr{'-href'} = href(%href_params);
3935                         $link_attr{'-title'} .= ' (no merges)';
3936                         print "<link ".
3937                               "rel=\"$link_attr{'-rel'}\" ".
3938                               "title=\"$link_attr{'-title'}\" ".
3939                               "href=\"$link_attr{'-href'}\" ".
3940                               "type=\"$link_attr{'-type'}\" ".
3941                               "/>\n";
3942                 }
3943
3944         } else {
3945                 printf('<link rel="alternate" title="%s projects list" '.
3946                        'href="%s" type="text/plain; charset=utf-8" />'."\n",
3947                        esc_attr($site_name), href(project=>undef, action=>"project_index"));
3948                 printf('<link rel="alternate" title="%s projects feeds" '.
3949                        'href="%s" type="text/x-opml" />'."\n",
3950                        esc_attr($site_name), href(project=>undef, action=>"opml"));
3951         }
3952 }
3953
3954 sub print_header_links {
3955         my $status = shift;
3956
3957         # print out each stylesheet that exist, providing backwards capability
3958         # for those people who defined $stylesheet in a config file
3959         if (defined $stylesheet) {
3960                 print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
3961         } else {
3962                 foreach my $stylesheet (@stylesheets) {
3963                         next unless $stylesheet;
3964                         print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
3965                 }
3966         }
3967         print_feed_meta()
3968                 if ($status eq '200 OK');
3969         if (defined $favicon) {
3970                 print qq(<link rel="shortcut icon" href=").esc_url($favicon).qq(" type="image/png" />\n);
3971         }
3972 }
3973
3974 sub print_nav_breadcrumbs_path {
3975         my $dirprefix = undef;
3976         while (my $part = shift) {
3977                 $dirprefix .= "/" if defined $dirprefix;
3978                 $dirprefix .= $part;
3979                 print $cgi->a({-href => href(project => undef,
3980                                              project_filter => $dirprefix,
3981                                              action => "project_list")},
3982                               esc_html($part)) . " / ";
3983         }
3984 }
3985
3986 sub print_nav_breadcrumbs {
3987         my %opts = @_;
3988
3989         for my $crumb (@extra_breadcrumbs, [ $home_link_str => $home_link ]) {
3990                 print $cgi->a({-href => esc_url($crumb->[1])}, $crumb->[0]) . " / ";
3991         }
3992         if (defined $project) {
3993                 my @dirname = split '/', $project;
3994                 my $projectbasename = pop @dirname;
3995                 print_nav_breadcrumbs_path(@dirname);
3996                 print $cgi->a({-href => href(action=>"summary")}, esc_html($projectbasename));
3997                 if (defined $action) {
3998                         my $action_print = $action ;
3999                         if (defined $opts{-action_extra}) {
4000                                 $action_print = $cgi->a({-href => href(action=>$action)},
4001                                         $action);
4002                         }
4003                         print " / $action_print";
4004                 }
4005                 if (defined $opts{-action_extra}) {
4006                         print " / $opts{-action_extra}";
4007                 }
4008                 print "\n";
4009         } elsif (defined $project_filter) {
4010                 print_nav_breadcrumbs_path(split '/', $project_filter);
4011         }
4012 }
4013
4014 sub print_search_form {
4015         if (!defined $searchtext) {
4016                 $searchtext = "";
4017         }
4018         my $search_hash;
4019         if (defined $hash_base) {
4020                 $search_hash = $hash_base;
4021         } elsif (defined $hash) {
4022                 $search_hash = $hash;
4023         } else {
4024                 $search_hash = "HEAD";
4025         }
4026         my $action = $my_uri;
4027         my $use_pathinfo = gitweb_check_feature('pathinfo');
4028         if ($use_pathinfo) {
4029                 $action .= "/".esc_url($project);
4030         }
4031         print $cgi->startform(-method => "get", -action => $action) .
4032               "<div class=\"search\">\n" .
4033               (!$use_pathinfo &&
4034               $cgi->input({-name=>"p", -value=>$project, -type=>"hidden"}) . "\n") .
4035               $cgi->input({-name=>"a", -value=>"search", -type=>"hidden"}) . "\n" .
4036               $cgi->input({-name=>"h", -value=>$search_hash, -type=>"hidden"}) . "\n" .
4037               $cgi->popup_menu(-name => 'st', -default => 'commit',
4038                                -values => ['commit', 'grep', 'author', 'committer', 'pickaxe']) .
4039               $cgi->sup($cgi->a({-href => href(action=>"search_help")}, "?")) .
4040               " search:\n",
4041               $cgi->textfield(-name => "s", -value => $searchtext, -override => 1) . "\n" .
4042               "<span title=\"Extended regular expression\">" .
4043               $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
4044                              -checked => $search_use_regexp) .
4045               "</span>" .
4046               "</div>" .
4047               $cgi->end_form() . "\n";
4048 }
4049
4050 sub git_header_html {
4051         my $status = shift || "200 OK";
4052         my $expires = shift;
4053         my %opts = @_;
4054
4055         my $title = get_page_title();
4056         my $content_type = get_content_type_html();
4057         print $cgi->header(-type=>$content_type, -charset => 'utf-8',
4058                            -status=> $status, -expires => $expires)
4059                 unless ($opts{'-no_http_header'});
4060         my $mod_perl_version = $ENV{'MOD_PERL'} ? " $ENV{'MOD_PERL'}" : '';
4061         print <<EOF;
4062 <?xml version="1.0" encoding="utf-8"?>
4063 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
4064 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en-US" lang="en-US">
4065 <!-- git web interface version $version, (C) 2005-2006, Kay Sievers <kay.sievers\@vrfy.org>, Christian Gierke -->
4066 <!-- git core binaries version $git_version -->
4067 <head>
4068 <meta http-equiv="content-type" content="$content_type; charset=utf-8"/>
4069 <meta name="generator" content="gitweb/$version git/$git_version$mod_perl_version"/>
4070 <meta name="robots" content="index, nofollow"/>
4071 <title>$title</title>
4072 EOF
4073         # the stylesheet, favicon etc urls won't work correctly with path_info
4074         # unless we set the appropriate base URL
4075         if ($ENV{'PATH_INFO'}) {
4076                 print "<base href=\"".esc_url($base_url)."\" />\n";
4077         }
4078         print_header_links($status);
4079
4080         if (defined $site_html_head_string) {
4081                 print to_utf8($site_html_head_string);
4082         }
4083
4084         print "</head>\n" .
4085               "<body>\n";
4086
4087         if (defined $site_header && -f $site_header) {
4088                 insert_file($site_header);
4089         }
4090
4091         print "<div class=\"page_header\">\n";
4092         if (defined $logo) {
4093                 print $cgi->a({-href => esc_url($logo_url),
4094                                -title => $logo_label},
4095                               $cgi->img({-src => esc_url($logo),
4096                                          -width => 72, -height => 27,
4097                                          -alt => "git",
4098                                          -class => "logo"}));
4099         }
4100         print_nav_breadcrumbs(%opts);
4101         print "</div>\n";
4102
4103         my $have_search = gitweb_check_feature('search');
4104         if (defined $project && $have_search) {
4105                 print_search_form();
4106         }
4107 }
4108
4109 sub git_footer_html {
4110         my $feed_class = 'rss_logo';
4111
4112         print "<div class=\"page_footer\">\n";
4113         if (defined $project) {
4114                 my $descr = git_get_project_description($project);
4115                 if (defined $descr) {
4116                         print "<div class=\"page_footer_text\">" . esc_html($descr) . "</div>\n";
4117                 }
4118
4119                 my %href_params = get_feed_info();
4120                 if (!%href_params) {
4121                         $feed_class .= ' generic';
4122                 }
4123                 $href_params{'-title'} ||= 'log';
4124
4125                 foreach my $format (qw(RSS Atom)) {
4126                         $href_params{'action'} = lc($format);
4127                         print $cgi->a({-href => href(%href_params),
4128                                       -title => "$href_params{'-title'} $format feed",
4129                                       -class => $feed_class}, $format)."\n";
4130                 }
4131
4132         } else {
4133                 print $cgi->a({-href => href(project=>undef, action=>"opml",
4134                                              project_filter => $project_filter),
4135                               -class => $feed_class}, "OPML") . " ";
4136                 print $cgi->a({-href => href(project=>undef, action=>"project_index",
4137                                              project_filter => $project_filter),
4138                               -class => $feed_class}, "TXT") . "\n";
4139         }
4140         print "</div>\n"; # class="page_footer"
4141
4142         if (defined $t0 && gitweb_check_feature('timed')) {
4143                 print "<div id=\"generating_info\">\n";
4144                 print 'This page took '.
4145                       '<span id="generating_time" class="time_span">'.
4146                       tv_interval($t0, [ gettimeofday() ]).
4147                       ' seconds </span>'.
4148                       ' and '.
4149                       '<span id="generating_cmd">'.
4150                       $number_of_git_cmds.
4151                       '</span> git commands '.
4152                       " to generate.\n";
4153                 print "</div>\n"; # class="page_footer"
4154         }
4155
4156         if (defined $site_footer && -f $site_footer) {
4157                 insert_file($site_footer);
4158         }
4159
4160         print qq!<script type="text/javascript" src="!.esc_url($javascript).qq!"></script>\n!;
4161         if (defined $action &&
4162             $action eq 'blame_incremental') {
4163                 print qq!<script type="text/javascript">\n!.
4164                       qq!startBlame("!. href(action=>"blame_data", -replay=>1) .qq!",\n!.
4165                       qq!           "!. href() .qq!");\n!.
4166                       qq!</script>\n!;
4167         } else {
4168                 my ($jstimezone, $tz_cookie, $datetime_class) =
4169                         gitweb_get_feature('javascript-timezone');
4170
4171                 print qq!<script type="text/javascript">\n!.
4172                       qq!window.onload = function () {\n!;
4173                 if (gitweb_check_feature('javascript-actions')) {
4174                         print qq!       fixLinks();\n!;
4175                 }
4176                 if ($jstimezone && $tz_cookie && $datetime_class) {
4177                         print qq!       var tz_cookie = { name: '$tz_cookie', expires: 14, path: '/' };\n!. # in days
4178                               qq!       onloadTZSetup('$jstimezone', tz_cookie, '$datetime_class');\n!;
4179                 }
4180                 print qq!};\n!.
4181                       qq!</script>\n!;
4182         }
4183
4184         print "</body>\n" .
4185               "</html>";
4186 }
4187
4188 # die_error(<http_status_code>, <error_message>[, <detailed_html_description>])
4189 # Example: die_error(404, 'Hash not found')
4190 # By convention, use the following status codes (as defined in RFC 2616):
4191 # 400: Invalid or missing CGI parameters, or
4192 #      requested object exists but has wrong type.
4193 # 403: Requested feature (like "pickaxe" or "snapshot") not enabled on
4194 #      this server or project.
4195 # 404: Requested object/revision/project doesn't exist.
4196 # 500: The server isn't configured properly, or
4197 #      an internal error occurred (e.g. failed assertions caused by bugs), or
4198 #      an unknown error occurred (e.g. the git binary died unexpectedly).
4199 # 503: The server is currently unavailable (because it is overloaded,
4200 #      or down for maintenance).  Generally, this is a temporary state.
4201 sub die_error {
4202         my $status = shift || 500;
4203         my $error = esc_html(shift) || "Internal Server Error";
4204         my $extra = shift;
4205         my %opts = @_;
4206
4207         my %http_responses = (
4208                 400 => '400 Bad Request',
4209                 403 => '403 Forbidden',
4210                 404 => '404 Not Found',
4211                 500 => '500 Internal Server Error',
4212                 503 => '503 Service Unavailable',
4213         );
4214         git_header_html($http_responses{$status}, undef, %opts);
4215         print <<EOF;
4216 <div class="page_body">
4217 <br /><br />
4218 $status - $error
4219 <br />
4220 EOF
4221         if (defined $extra) {
4222                 print "<hr />\n" .
4223                       "$extra\n";
4224         }
4225         print "</div>\n";
4226
4227         git_footer_html();
4228         goto DONE_GITWEB
4229                 unless ($opts{'-error_handler'});
4230 }
4231
4232 ## ----------------------------------------------------------------------
4233 ## functions printing or outputting HTML: navigation
4234
4235 sub git_print_page_nav {
4236         my ($current, $suppress, $head, $treehead, $treebase, $extra) = @_;
4237         $extra = '' if !defined $extra; # pager or formats
4238
4239         my @navs = qw(summary shortlog log commit commitdiff tree);
4240         if ($suppress) {
4241                 @navs = grep { $_ ne $suppress } @navs;
4242         }
4243
4244         my %arg = map { $_ => {action=>$_} } @navs;
4245         if (defined $head) {
4246                 for (qw(commit commitdiff)) {
4247                         $arg{$_}{'hash'} = $head;
4248                 }
4249                 if ($current =~ m/^(tree | log | shortlog | commit | commitdiff | search)$/x) {
4250                         for (qw(shortlog log)) {
4251                                 $arg{$_}{'hash'} = $head;
4252                         }
4253                 }
4254         }
4255
4256         $arg{'tree'}{'hash'} = $treehead if defined $treehead;
4257         $arg{'tree'}{'hash_base'} = $treebase if defined $treebase;
4258
4259         my @actions = gitweb_get_feature('actions');
4260         my %repl = (
4261                 '%' => '%',
4262                 'n' => $project,         # project name
4263                 'f' => $git_dir,         # project path within filesystem
4264                 'h' => $treehead || '',  # current hash ('h' parameter)
4265                 'b' => $treebase || '',  # hash base ('hb' parameter)
4266         );
4267         while (@actions) {
4268                 my ($label, $link, $pos) = splice(@actions,0,3);
4269                 # insert
4270                 @navs = map { $_ eq $pos ? ($_, $label) : $_ } @navs;
4271                 # munch munch
4272                 $link =~ s/%([%nfhb])/$repl{$1}/g;
4273                 $arg{$label}{'_href'} = $link;
4274         }
4275
4276         print "<div class=\"page_nav\">\n" .
4277                 (join " | ",
4278                  map { $_ eq $current ?
4279                        $_ : $cgi->a({-href => ($arg{$_}{_href} ? $arg{$_}{_href} : href(%{$arg{$_}}))}, "$_")
4280                  } @navs);
4281         print "<br/>\n$extra<br/>\n" .
4282               "</div>\n";
4283 }
4284
4285 # returns a submenu for the nagivation of the refs views (tags, heads,
4286 # remotes) with the current view disabled and the remotes view only
4287 # available if the feature is enabled
4288 sub format_ref_views {
4289         my ($current) = @_;
4290         my @ref_views = qw{tags heads};
4291         push @ref_views, 'remotes' if gitweb_check_feature('remote_heads');
4292         return join " | ", map {
4293                 $_ eq $current ? $_ :
4294                 $cgi->a({-href => href(action=>$_)}, $_)
4295         } @ref_views
4296 }
4297
4298 sub format_paging_nav {
4299         my ($action, $page, $has_next_link) = @_;
4300         my $paging_nav;
4301
4302
4303         if ($page > 0) {
4304                 $paging_nav .=
4305                         $cgi->a({-href => href(-replay=>1, page=>undef)}, "first") .
4306                         " &sdot; " .
4307                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
4308                                  -accesskey => "p", -title => "Alt-p"}, "prev");
4309         } else {
4310                 $paging_nav .= "first &sdot; prev";
4311         }
4312
4313         if ($has_next_link) {
4314                 $paging_nav .= " &sdot; " .
4315                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
4316                                  -accesskey => "n", -title => "Alt-n"}, "next");
4317         } else {
4318                 $paging_nav .= " &sdot; next";
4319         }
4320
4321         return $paging_nav;
4322 }
4323
4324 ## ......................................................................
4325 ## functions printing or outputting HTML: div
4326
4327 sub git_print_header_div {
4328         my ($action, $title, $hash, $hash_base) = @_;
4329         my %args = ();
4330
4331         $args{'action'} = $action;
4332         $args{'hash'} = $hash if $hash;
4333         $args{'hash_base'} = $hash_base if $hash_base;
4334
4335         print "<div class=\"header\">\n" .
4336               $cgi->a({-href => href(%args), -class => "title"},
4337               $title ? $title : $action) .
4338               "\n</div>\n";
4339 }
4340
4341 sub format_repo_url {
4342         my ($name, $url) = @_;
4343         return "<tr class=\"metadata_url\"><td>$name</td><td>$url</td></tr>\n";
4344 }
4345
4346 # Group output by placing it in a DIV element and adding a header.
4347 # Options for start_div() can be provided by passing a hash reference as the
4348 # first parameter to the function.
4349 # Options to git_print_header_div() can be provided by passing an array
4350 # reference. This must follow the options to start_div if they are present.
4351 # The content can be a scalar, which is output as-is, a scalar reference, which
4352 # is output after html escaping, an IO handle passed either as *handle or
4353 # *handle{IO}, or a function reference. In the latter case all following
4354 # parameters will be taken as argument to the content function call.
4355 sub git_print_section {
4356         my ($div_args, $header_args, $content);
4357         my $arg = shift;
4358         if (ref($arg) eq 'HASH') {
4359                 $div_args = $arg;
4360                 $arg = shift;
4361         }
4362         if (ref($arg) eq 'ARRAY') {
4363                 $header_args = $arg;
4364                 $arg = shift;
4365         }
4366         $content = $arg;
4367
4368         print $cgi->start_div($div_args);
4369         git_print_header_div(@$header_args);
4370
4371         if (ref($content) eq 'CODE') {
4372                 $content->(@_);
4373         } elsif (ref($content) eq 'SCALAR') {
4374                 print esc_html($$content);
4375         } elsif (ref($content) eq 'GLOB' or ref($content) eq 'IO::Handle') {
4376                 print <$content>;
4377         } elsif (!ref($content) && defined($content)) {
4378                 print $content;
4379         }
4380
4381         print $cgi->end_div;
4382 }
4383
4384 sub format_timestamp_html {
4385         my $date = shift;
4386         my $strtime = $date->{'rfc2822'};
4387
4388         my (undef, undef, $datetime_class) =
4389                 gitweb_get_feature('javascript-timezone');
4390         if ($datetime_class) {
4391                 $strtime = qq!<span class="$datetime_class">$strtime</span>!;
4392         }
4393
4394         my $localtime_format = '(%02d:%02d %s)';
4395         if ($date->{'hour_local'} < 6) {
4396                 $localtime_format = '(<span class="atnight">%02d:%02d</span> %s)';
4397         }
4398         $strtime .= ' ' .
4399                     sprintf($localtime_format,
4400                             $date->{'hour_local'}, $date->{'minute_local'}, $date->{'tz_local'});
4401
4402         return $strtime;
4403 }
4404
4405 # Outputs the author name and date in long form
4406 sub git_print_authorship {
4407         my $co = shift;
4408         my %opts = @_;
4409         my $tag = $opts{-tag} || 'div';
4410         my $author = $co->{'author_name'};
4411
4412         my %ad = parse_date($co->{'author_epoch'}, $co->{'author_tz'});
4413         print "<$tag class=\"author_date\">" .
4414               format_search_author($author, "author", esc_html($author)) .
4415               " [".format_timestamp_html(\%ad)."]".
4416               git_get_avatar($co->{'author_email'}, -pad_before => 1) .
4417               "</$tag>\n";
4418 }
4419
4420 # Outputs table rows containing the full author or committer information,
4421 # in the format expected for 'commit' view (& similar).
4422 # Parameters are a commit hash reference, followed by the list of people
4423 # to output information for. If the list is empty it defaults to both
4424 # author and committer.
4425 sub git_print_authorship_rows {
4426         my $co = shift;
4427         # too bad we can't use @people = @_ || ('author', 'committer')
4428         my @people = @_;
4429         @people = ('author', 'committer') unless @people;
4430         foreach my $who (@people) {
4431                 my %wd = parse_date($co->{"${who}_epoch"}, $co->{"${who}_tz"});
4432                 print "<tr><td>$who</td><td>" .
4433                       format_search_author($co->{"${who}_name"}, $who,
4434                                            esc_html($co->{"${who}_name"})) . " " .
4435                       format_search_author($co->{"${who}_email"}, $who,
4436                                            esc_html("<" . $co->{"${who}_email"} . ">")) .
4437                       "</td><td rowspan=\"2\">" .
4438                       git_get_avatar($co->{"${who}_email"}, -size => 'double') .
4439                       "</td></tr>\n" .
4440                       "<tr>" .
4441                       "<td></td><td>" .
4442                       format_timestamp_html(\%wd) .
4443                       "</td>" .
4444                       "</tr>\n";
4445         }
4446 }
4447
4448 sub git_print_page_path {
4449         my $name = shift;
4450         my $type = shift;
4451         my $hb = shift;
4452
4453
4454         print "<div class=\"page_path\">";
4455         print $cgi->a({-href => href(action=>"tree", hash_base=>$hb),
4456                       -title => 'tree root'}, to_utf8("[$project]"));
4457         print " / ";
4458         if (defined $name) {
4459                 my @dirname = split '/', $name;
4460                 my $basename = pop @dirname;
4461                 my $fullname = '';
4462
4463                 foreach my $dir (@dirname) {
4464                         $fullname .= ($fullname ? '/' : '') . $dir;
4465                         print $cgi->a({-href => href(action=>"tree", file_name=>$fullname,
4466                                                      hash_base=>$hb),
4467                                       -title => $fullname}, esc_path($dir));
4468                         print " / ";
4469                 }
4470                 if (defined $type && $type eq 'blob') {
4471                         print $cgi->a({-href => href(action=>"blob_plain", file_name=>$file_name,
4472                                                      hash_base=>$hb),
4473                                       -title => $name}, esc_path($basename));
4474                 } elsif (defined $type && $type eq 'tree') {
4475                         print $cgi->a({-href => href(action=>"tree", file_name=>$file_name,
4476                                                      hash_base=>$hb),
4477                                       -title => $name}, esc_path($basename));
4478                         print " / ";
4479                 } else {
4480                         print esc_path($basename);
4481                 }
4482         }
4483         print "<br/></div>\n";
4484 }
4485
4486 sub git_print_log {
4487         my $log = shift;
4488         my %opts = @_;
4489
4490         if ($opts{'-remove_title'}) {
4491                 # remove title, i.e. first line of log
4492                 shift @$log;
4493         }
4494         # remove leading empty lines
4495         while (defined $log->[0] && $log->[0] eq "") {
4496                 shift @$log;
4497         }
4498
4499         # print log
4500         my $skip_blank_line = 0;
4501         foreach my $line (@$log) {
4502                 if ($line =~ m/^\s*([A-Z][-A-Za-z]*-[Bb]y|C[Cc]): /) {
4503                         if (! $opts{'-remove_signoff'}) {
4504                                 print "<span class=\"signoff\">" . esc_html($line) . "</span><br/>\n";
4505                                 $skip_blank_line = 1;
4506                         }
4507                         next;
4508                 }
4509
4510                 if ($line =~ m,\s*([a-z]*link): (https?://\S+),i) {
4511                         if (! $opts{'-remove_signoff'}) {
4512                                 print "<span class=\"signoff\">" . esc_html($1) . ": " .
4513                                         "<a href=\"" . esc_html($2) . "\">" . esc_html($2) . "</a>" .
4514                                         "</span><br/>\n";
4515                                 $skip_blank_line = 1;
4516                         }
4517                         next;
4518                 }
4519
4520                 # print only one empty line
4521                 # do not print empty line after signoff
4522                 if ($line eq "") {
4523                         next if ($skip_blank_line);
4524                         $skip_blank_line = 1;
4525                 } else {
4526                         $skip_blank_line = 0;
4527                 }
4528
4529                 print format_log_line_html($line) . "<br/>\n";
4530         }
4531
4532         if ($opts{'-final_empty_line'}) {
4533                 # end with single empty line
4534                 print "<br/>\n" unless $skip_blank_line;
4535         }
4536 }
4537
4538 # return link target (what link points to)
4539 sub git_get_link_target {
4540         my $hash = shift;
4541         my $link_target;
4542
4543         # read link
4544         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
4545                 or return;
4546         {
4547                 local $/ = undef;
4548                 $link_target = <$fd>;
4549         }
4550         close $fd
4551                 or return;
4552
4553         return $link_target;
4554 }
4555
4556 # given link target, and the directory (basedir) the link is in,
4557 # return target of link relative to top directory (top tree);
4558 # return undef if it is not possible (including absolute links).
4559 sub normalize_link_target {
4560         my ($link_target, $basedir) = @_;
4561
4562         # absolute symlinks (beginning with '/') cannot be normalized
4563         return if (substr($link_target, 0, 1) eq '/');
4564
4565         # normalize link target to path from top (root) tree (dir)
4566         my $path;
4567         if ($basedir) {
4568                 $path = $basedir . '/' . $link_target;
4569         } else {
4570                 # we are in top (root) tree (dir)
4571                 $path = $link_target;
4572         }
4573
4574         # remove //, /./, and /../
4575         my @path_parts;
4576         foreach my $part (split('/', $path)) {
4577                 # discard '.' and ''
4578                 next if (!$part || $part eq '.');
4579                 # handle '..'
4580                 if ($part eq '..') {
4581                         if (@path_parts) {
4582                                 pop @path_parts;
4583                         } else {
4584                                 # link leads outside repository (outside top dir)
4585                                 return;
4586                         }
4587                 } else {
4588                         push @path_parts, $part;
4589                 }
4590         }
4591         $path = join('/', @path_parts);
4592
4593         return $path;
4594 }
4595
4596 # print tree entry (row of git_tree), but without encompassing <tr> element
4597 sub git_print_tree_entry {
4598         my ($t, $basedir, $hash_base, $have_blame) = @_;
4599
4600         my %base_key = ();
4601         $base_key{'hash_base'} = $hash_base if defined $hash_base;
4602
4603         # The format of a table row is: mode list link.  Where mode is
4604         # the mode of the entry, list is the name of the entry, an href,
4605         # and link is the action links of the entry.
4606
4607         print "<td class=\"mode\">" . mode_str($t->{'mode'}) . "</td>\n";
4608         if (exists $t->{'size'}) {
4609                 print "<td class=\"size\">$t->{'size'}</td>\n";
4610         }
4611         if ($t->{'type'} eq "blob") {
4612                 print "<td class=\"list\">" .
4613                         $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4614                                                file_name=>"$basedir$t->{'name'}", %base_key),
4615                                 -class => "list"}, esc_path($t->{'name'}));
4616                 if (S_ISLNK(oct $t->{'mode'})) {
4617                         my $link_target = git_get_link_target($t->{'hash'});
4618                         if ($link_target) {
4619                                 my $norm_target = normalize_link_target($link_target, $basedir);
4620                                 if (defined $norm_target) {
4621                                         print " -> " .
4622                                               $cgi->a({-href => href(action=>"object", hash_base=>$hash_base,
4623                                                                      file_name=>$norm_target),
4624                                                        -title => $norm_target}, esc_path($link_target));
4625                                 } else {
4626                                         print " -> " . esc_path($link_target);
4627                                 }
4628                         }
4629                 }
4630                 print "</td>\n";
4631                 print "<td class=\"link\">";
4632                 print $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4633                                              file_name=>"$basedir$t->{'name'}", %base_key)},
4634                               "blob");
4635                 if ($have_blame) {
4636                         print " | " .
4637                               $cgi->a({-href => href(action=>"blame", hash=>$t->{'hash'},
4638                                                      file_name=>"$basedir$t->{'name'}", %base_key)},
4639                                       "blame");
4640                 }
4641                 if (defined $hash_base) {
4642                         print " | " .
4643                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4644                                                      hash=>$t->{'hash'}, file_name=>"$basedir$t->{'name'}")},
4645                                       "history");
4646                 }
4647                 print " | " .
4648                         $cgi->a({-href => href(action=>"blob_plain", hash_base=>$hash_base,
4649                                                file_name=>"$basedir$t->{'name'}")},
4650                                 "raw");
4651                 print "</td>\n";
4652
4653         } elsif ($t->{'type'} eq "tree") {
4654                 print "<td class=\"list\">";
4655                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4656                                              file_name=>"$basedir$t->{'name'}",
4657                                              %base_key)},
4658                               esc_path($t->{'name'}));
4659                 print "</td>\n";
4660                 print "<td class=\"link\">";
4661                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4662                                              file_name=>"$basedir$t->{'name'}",
4663                                              %base_key)},
4664                               "tree");
4665                 if (defined $hash_base) {
4666                         print " | " .
4667                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4668                                                      file_name=>"$basedir$t->{'name'}")},
4669                                       "history");
4670                 }
4671                 print "</td>\n";
4672         } else {
4673                 # unknown object: we can only present history for it
4674                 # (this includes 'commit' object, i.e. submodule support)
4675                 print "<td class=\"list\">" .
4676                       esc_path($t->{'name'}) .
4677                       "</td>\n";
4678                 print "<td class=\"link\">";
4679                 if (defined $hash_base) {
4680                         print $cgi->a({-href => href(action=>"history",
4681                                                      hash_base=>$hash_base,
4682                                                      file_name=>"$basedir$t->{'name'}")},
4683                                       "history");
4684                 }
4685                 print "</td>\n";
4686         }
4687 }
4688
4689 ## ......................................................................
4690 ## functions printing large fragments of HTML
4691
4692 # get pre-image filenames for merge (combined) diff
4693 sub fill_from_file_info {
4694         my ($diff, @parents) = @_;
4695
4696         $diff->{'from_file'} = [ ];
4697         $diff->{'from_file'}[$diff->{'nparents'} - 1] = undef;
4698         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4699                 if ($diff->{'status'}[$i] eq 'R' ||
4700                     $diff->{'status'}[$i] eq 'C') {
4701                         $diff->{'from_file'}[$i] =
4702                                 git_get_path_by_hash($parents[$i], $diff->{'from_id'}[$i]);
4703                 }
4704         }
4705
4706         return $diff;
4707 }
4708
4709 # is current raw difftree line of file deletion
4710 sub is_deleted {
4711         my $diffinfo = shift;
4712
4713         return $diffinfo->{'to_id'} eq ('0' x 40);
4714 }
4715
4716 # does patch correspond to [previous] difftree raw line
4717 # $diffinfo  - hashref of parsed raw diff format
4718 # $patchinfo - hashref of parsed patch diff format
4719 #              (the same keys as in $diffinfo)
4720 sub is_patch_split {
4721         my ($diffinfo, $patchinfo) = @_;
4722
4723         return defined $diffinfo && defined $patchinfo
4724                 && $diffinfo->{'to_file'} eq $patchinfo->{'to_file'};
4725 }
4726
4727
4728 sub git_difftree_body {
4729         my ($difftree, $hash, @parents) = @_;
4730         my ($parent) = $parents[0];
4731         my $have_blame = gitweb_check_feature('blame');
4732         print "<div class=\"list_head\">\n";
4733         if ($#{$difftree} > 10) {
4734                 print(($#{$difftree} + 1) . " files changed:\n");
4735         }
4736         print "</div>\n";
4737
4738         print "<table class=\"" .
4739               (@parents > 1 ? "combined " : "") .
4740               "diff_tree\">\n";
4741
4742         # header only for combined diff in 'commitdiff' view
4743         my $has_header = @$difftree && @parents > 1 && $action eq 'commitdiff';
4744         if ($has_header) {
4745                 # table header
4746                 print "<thead><tr>\n" .
4747                        "<th></th><th></th>\n"; # filename, patchN link
4748                 for (my $i = 0; $i < @parents; $i++) {
4749                         my $par = $parents[$i];
4750                         print "<th>" .
4751                               $cgi->a({-href => href(action=>"commitdiff",
4752                                                      hash=>$hash, hash_parent=>$par),
4753                                        -title => 'commitdiff to parent number ' .
4754                                                   ($i+1) . ': ' . substr($par,0,7)},
4755                                       $i+1) .
4756                               "&nbsp;</th>\n";
4757                 }
4758                 print "</tr></thead>\n<tbody>\n";
4759         }
4760
4761         my $alternate = 1;
4762         my $patchno = 0;
4763         foreach my $line (@{$difftree}) {
4764                 my $diff = parsed_difftree_line($line);
4765
4766                 if ($alternate) {
4767                         print "<tr class=\"dark\">\n";
4768                 } else {
4769                         print "<tr class=\"light\">\n";
4770                 }
4771                 $alternate ^= 1;
4772
4773                 if (exists $diff->{'nparents'}) { # combined diff
4774
4775                         fill_from_file_info($diff, @parents)
4776                                 unless exists $diff->{'from_file'};
4777
4778                         if (!is_deleted($diff)) {
4779                                 # file exists in the result (child) commit
4780                                 print "<td>" .
4781                                       $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4782                                                              file_name=>$diff->{'to_file'},
4783                                                              hash_base=>$hash),
4784                                               -class => "list"}, esc_path($diff->{'to_file'})) .
4785                                       "</td>\n";
4786                         } else {
4787                                 print "<td>" .
4788                                       esc_path($diff->{'to_file'}) .
4789                                       "</td>\n";
4790                         }
4791
4792                         if ($action eq 'commitdiff') {
4793                                 # link to patch
4794                                 $patchno++;
4795                                 print "<td class=\"link\">" .
4796                                       $cgi->a({-href => href(-anchor=>"patch$patchno")},
4797                                               "patch") .
4798                                       " | " .
4799                                       "</td>\n";
4800                         }
4801
4802                         my $has_history = 0;
4803                         my $not_deleted = 0;
4804                         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4805                                 my $hash_parent = $parents[$i];
4806                                 my $from_hash = $diff->{'from_id'}[$i];
4807                                 my $from_path = $diff->{'from_file'}[$i];
4808                                 my $status = $diff->{'status'}[$i];
4809
4810                                 $has_history ||= ($status ne 'A');
4811                                 $not_deleted ||= ($status ne 'D');
4812
4813                                 if ($status eq 'A') {
4814                                         print "<td  class=\"link\" align=\"right\"> | </td>\n";
4815                                 } elsif ($status eq 'D') {
4816                                         print "<td class=\"link\">" .
4817                                               $cgi->a({-href => href(action=>"blob",
4818                                                                      hash_base=>$hash,
4819                                                                      hash=>$from_hash,
4820                                                                      file_name=>$from_path)},
4821                                                       "blob" . ($i+1)) .
4822                                               " | </td>\n";
4823                                 } else {
4824                                         if ($diff->{'to_id'} eq $from_hash) {
4825                                                 print "<td class=\"link nochange\">";
4826                                         } else {
4827                                                 print "<td class=\"link\">";
4828                                         }
4829                                         print $cgi->a({-href => href(action=>"blobdiff",
4830                                                                      hash=>$diff->{'to_id'},
4831                                                                      hash_parent=>$from_hash,
4832                                                                      hash_base=>$hash,
4833                                                                      hash_parent_base=>$hash_parent,
4834                                                                      file_name=>$diff->{'to_file'},
4835                                                                      file_parent=>$from_path)},
4836                                                       "diff" . ($i+1)) .
4837                                               " | </td>\n";
4838                                 }
4839                         }
4840
4841                         print "<td class=\"link\">";
4842                         if ($not_deleted) {
4843                                 print $cgi->a({-href => href(action=>"blob",
4844                                                              hash=>$diff->{'to_id'},
4845                                                              file_name=>$diff->{'to_file'},
4846                                                              hash_base=>$hash)},
4847                                               "blob");
4848                                 print " | " if ($has_history);
4849                         }
4850                         if ($has_history) {
4851                                 print $cgi->a({-href => href(action=>"history",
4852                                                              file_name=>$diff->{'to_file'},
4853                                                              hash_base=>$hash)},
4854                                               "history");
4855                         }
4856                         print "</td>\n";
4857
4858                         print "</tr>\n";
4859                         next; # instead of 'else' clause, to avoid extra indent
4860                 }
4861                 # else ordinary diff
4862
4863                 my ($to_mode_oct, $to_mode_str, $to_file_type);
4864                 my ($from_mode_oct, $from_mode_str, $from_file_type);
4865                 if ($diff->{'to_mode'} ne ('0' x 6)) {
4866                         $to_mode_oct = oct $diff->{'to_mode'};
4867                         if (S_ISREG($to_mode_oct)) { # only for regular file
4868                                 $to_mode_str = sprintf("%04o", $to_mode_oct & 0777); # permission bits
4869                         }
4870                         $to_file_type = file_type($diff->{'to_mode'});
4871                 }
4872                 if ($diff->{'from_mode'} ne ('0' x 6)) {
4873                         $from_mode_oct = oct $diff->{'from_mode'};
4874                         if (S_ISREG($from_mode_oct)) { # only for regular file
4875                                 $from_mode_str = sprintf("%04o", $from_mode_oct & 0777); # permission bits
4876                         }
4877                         $from_file_type = file_type($diff->{'from_mode'});
4878                 }
4879
4880                 if ($diff->{'status'} eq "A") { # created
4881                         my $mode_chng = "<span class=\"file_status new\">[new $to_file_type";
4882                         $mode_chng   .= " with mode: $to_mode_str" if $to_mode_str;
4883                         $mode_chng   .= "]</span>";
4884                         print "<td>";
4885                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4886                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4887                                       -class => "list"}, esc_path($diff->{'file'}));
4888                         print "</td>\n";
4889                         print "<td>$mode_chng</td>\n";
4890                         print "<td class=\"link\">";
4891                         if ($action eq 'commitdiff') {
4892                                 # link to patch
4893                                 $patchno++;
4894                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4895                                               "patch") .
4896                                       " | ";
4897                         }
4898                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4899                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4900                                       "blob");
4901                         print "</td>\n";
4902
4903                 } elsif ($diff->{'status'} eq "D") { # deleted
4904                         my $mode_chng = "<span class=\"file_status deleted\">[deleted $from_file_type]</span>";
4905                         print "<td>";
4906                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4907                                                      hash_base=>$parent, file_name=>$diff->{'file'}),
4908                                        -class => "list"}, esc_path($diff->{'file'}));
4909                         print "</td>\n";
4910                         print "<td>$mode_chng</td>\n";
4911                         print "<td class=\"link\">";
4912                         if ($action eq 'commitdiff') {
4913                                 # link to patch
4914                                 $patchno++;
4915                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4916                                               "patch") .
4917                                       " | ";
4918                         }
4919                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4920                                                      hash_base=>$parent, file_name=>$diff->{'file'})},
4921                                       "blob") . " | ";
4922                         if ($have_blame) {
4923                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$parent,
4924                                                              file_name=>$diff->{'file'})},
4925                                               "blame") . " | ";
4926                         }
4927                         print $cgi->a({-href => href(action=>"history", hash_base=>$parent,
4928                                                      file_name=>$diff->{'file'})},
4929                                       "history");
4930                         print "</td>\n";
4931
4932                 } elsif ($diff->{'status'} eq "M" || $diff->{'status'} eq "T") { # modified, or type changed
4933                         my $mode_chnge = "";
4934                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4935                                 $mode_chnge = "<span class=\"file_status mode_chnge\">[changed";
4936                                 if ($from_file_type ne $to_file_type) {
4937                                         $mode_chnge .= " from $from_file_type to $to_file_type";
4938                                 }
4939                                 if (($from_mode_oct & 0777) != ($to_mode_oct & 0777)) {
4940                                         if ($from_mode_str && $to_mode_str) {
4941                                                 $mode_chnge .= " mode: $from_mode_str->$to_mode_str";
4942                                         } elsif ($to_mode_str) {
4943                                                 $mode_chnge .= " mode: $to_mode_str";
4944                                         }
4945                                 }
4946                                 $mode_chnge .= "]</span>\n";
4947                         }
4948                         print "<td>";
4949                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4950                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4951                                       -class => "list"}, esc_path($diff->{'file'}));
4952                         print "</td>\n";
4953                         print "<td>$mode_chnge</td>\n";
4954                         print "<td class=\"link\">";
4955                         if ($action eq 'commitdiff') {
4956                                 # link to patch
4957                                 $patchno++;
4958                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4959                                               "patch") .
4960                                       " | ";
4961                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4962                                 # "commit" view and modified file (not onlu mode changed)
4963                                 print $cgi->a({-href => href(action=>"blobdiff",
4964                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4965                                                              hash_base=>$hash, hash_parent_base=>$parent,
4966                                                              file_name=>$diff->{'file'})},
4967                                               "diff") .
4968                                       " | ";
4969                         }
4970                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4971                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4972                                        "blob") . " | ";
4973                         if ($have_blame) {
4974                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4975                                                              file_name=>$diff->{'file'})},
4976                                               "blame") . " | ";
4977                         }
4978                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4979                                                      file_name=>$diff->{'file'})},
4980                                       "history");
4981                         print "</td>\n";
4982
4983                 } elsif ($diff->{'status'} eq "R" || $diff->{'status'} eq "C") { # renamed or copied
4984                         my %status_name = ('R' => 'moved', 'C' => 'copied');
4985                         my $nstatus = $status_name{$diff->{'status'}};
4986                         my $mode_chng = "";
4987                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4988                                 # mode also for directories, so we cannot use $to_mode_str
4989                                 $mode_chng = sprintf(", mode: %04o", $to_mode_oct & 0777);
4990                         }
4991                         print "<td>" .
4992                               $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
4993                                                      hash=>$diff->{'to_id'}, file_name=>$diff->{'to_file'}),
4994                                       -class => "list"}, esc_path($diff->{'to_file'})) . "</td>\n" .
4995                               "<td><span class=\"file_status $nstatus\">[$nstatus from " .
4996                               $cgi->a({-href => href(action=>"blob", hash_base=>$parent,
4997                                                      hash=>$diff->{'from_id'}, file_name=>$diff->{'from_file'}),
4998                                       -class => "list"}, esc_path($diff->{'from_file'})) .
4999                               " with " . (int $diff->{'similarity'}) . "% similarity$mode_chng]</span></td>\n" .
5000                               "<td class=\"link\">";
5001                         if ($action eq 'commitdiff') {
5002                                 # link to patch
5003                                 $patchno++;
5004                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
5005                                               "patch") .
5006                                       " | ";
5007                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
5008                                 # "commit" view and modified file (not only pure rename or copy)
5009                                 print $cgi->a({-href => href(action=>"blobdiff",
5010                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
5011                                                              hash_base=>$hash, hash_parent_base=>$parent,
5012                                                              file_name=>$diff->{'to_file'}, file_parent=>$diff->{'from_file'})},
5013                                               "diff") .
5014                                       " | ";
5015                         }
5016                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
5017                                                      hash_base=>$parent, file_name=>$diff->{'to_file'})},
5018                                       "blob") . " | ";
5019                         if ($have_blame) {
5020                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
5021                                                              file_name=>$diff->{'to_file'})},
5022                                               "blame") . " | ";
5023                         }
5024                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
5025                                                     file_name=>$diff->{'to_file'})},
5026                                       "history");
5027                         print "</td>\n";
5028
5029                 } # we should not encounter Unmerged (U) or Unknown (X) status
5030                 print "</tr>\n";
5031         }
5032         print "</tbody>" if $has_header;
5033         print "</table>\n";
5034 }
5035
5036 # Print context lines and then rem/add lines in a side-by-side manner.
5037 sub print_sidebyside_diff_lines {
5038         my ($ctx, $rem, $add) = @_;
5039
5040         # print context block before add/rem block
5041         if (@$ctx) {
5042                 print join '',
5043                         '<div class="chunk_block ctx">',
5044                                 '<div class="old">',
5045                                 @$ctx,
5046                                 '</div>',
5047                                 '<div class="new">',
5048                                 @$ctx,
5049                                 '</div>',
5050                         '</div>';
5051         }
5052
5053         if (!@$add) {
5054                 # pure removal
5055                 print join '',
5056                         '<div class="chunk_block rem">',
5057                                 '<div class="old">',
5058                                 @$rem,
5059                                 '</div>',
5060                         '</div>';
5061         } elsif (!@$rem) {
5062                 # pure addition
5063                 print join '',
5064                         '<div class="chunk_block add">',
5065                                 '<div class="new">',
5066                                 @$add,
5067                                 '</div>',
5068                         '</div>';
5069         } else {
5070                 print join '',
5071                         '<div class="chunk_block chg">',
5072                                 '<div class="old">',
5073                                 @$rem,
5074                                 '</div>',
5075                                 '<div class="new">',
5076                                 @$add,
5077                                 '</div>',
5078                         '</div>';
5079         }
5080 }
5081
5082 # Print context lines and then rem/add lines in inline manner.
5083 sub print_inline_diff_lines {
5084         my ($ctx, $rem, $add) = @_;
5085
5086         print @$ctx, @$rem, @$add;
5087 }
5088
5089 # Format removed and added line, mark changed part and HTML-format them.
5090 # Implementation is based on contrib/diff-highlight
5091 sub format_rem_add_lines_pair {
5092         my ($rem, $add, $num_parents) = @_;
5093
5094         # We need to untabify lines before split()'ing them;
5095         # otherwise offsets would be invalid.
5096         chomp $rem;
5097         chomp $add;
5098         $rem = untabify($rem);
5099         $add = untabify($add);
5100
5101         my @rem = split(//, $rem);
5102         my @add = split(//, $add);
5103         my ($esc_rem, $esc_add);
5104         # Ignore leading +/- characters for each parent.
5105         my ($prefix_len, $suffix_len) = ($num_parents, 0);
5106         my ($prefix_has_nonspace, $suffix_has_nonspace);
5107
5108         my $shorter = (@rem < @add) ? @rem : @add;
5109         while ($prefix_len < $shorter) {
5110                 last if ($rem[$prefix_len] ne $add[$prefix_len]);
5111
5112                 $prefix_has_nonspace = 1 if ($rem[$prefix_len] !~ /\s/);
5113                 $prefix_len++;
5114         }
5115
5116         while ($prefix_len + $suffix_len < $shorter) {
5117                 last if ($rem[-1 - $suffix_len] ne $add[-1 - $suffix_len]);
5118
5119                 $suffix_has_nonspace = 1 if ($rem[-1 - $suffix_len] !~ /\s/);
5120                 $suffix_len++;
5121         }
5122
5123         # Mark lines that are different from each other, but have some common
5124         # part that isn't whitespace.  If lines are completely different, don't
5125         # mark them because that would make output unreadable, especially if
5126         # diff consists of multiple lines.
5127         if ($prefix_has_nonspace || $suffix_has_nonspace) {
5128                 $esc_rem = esc_html_hl_regions($rem, 'marked',
5129                         [$prefix_len, @rem - $suffix_len], -nbsp=>1);
5130                 $esc_add = esc_html_hl_regions($add, 'marked',
5131                         [$prefix_len, @add - $suffix_len], -nbsp=>1);
5132         } else {
5133                 $esc_rem = esc_html($rem, -nbsp=>1);
5134                 $esc_add = esc_html($add, -nbsp=>1);
5135         }
5136
5137         return format_diff_line(\$esc_rem, 'rem'),
5138                format_diff_line(\$esc_add, 'add');
5139 }
5140
5141 # HTML-format diff context, removed and added lines.
5142 sub format_ctx_rem_add_lines {
5143         my ($ctx, $rem, $add, $num_parents) = @_;
5144         my (@new_ctx, @new_rem, @new_add);
5145         my $can_highlight = 0;
5146         my $is_combined = ($num_parents > 1);
5147
5148         # Highlight if every removed line has a corresponding added line.
5149         if (@$add > 0 && @$add == @$rem) {
5150                 $can_highlight = 1;
5151
5152                 # Highlight lines in combined diff only if the chunk contains
5153                 # diff between the same version, e.g.
5154                 #
5155                 #    - a
5156                 #   -  b
5157                 #    + c
5158                 #   +  d
5159                 #
5160                 # Otherwise the highlightling would be confusing.
5161                 if ($is_combined) {
5162                         for (my $i = 0; $i < @$add; $i++) {
5163                                 my $prefix_rem = substr($rem->[$i], 0, $num_parents);
5164                                 my $prefix_add = substr($add->[$i], 0, $num_parents);
5165
5166                                 $prefix_rem =~ s/-/+/g;
5167
5168                                 if ($prefix_rem ne $prefix_add) {
5169                                         $can_highlight = 0;
5170                                         last;
5171                                 }
5172                         }
5173                 }
5174         }
5175
5176         if ($can_highlight) {
5177                 for (my $i = 0; $i < @$add; $i++) {
5178                         my ($line_rem, $line_add) = format_rem_add_lines_pair(
5179                                 $rem->[$i], $add->[$i], $num_parents);
5180                         push @new_rem, $line_rem;
5181                         push @new_add, $line_add;
5182                 }
5183         } else {
5184                 @new_rem = map { format_diff_line($_, 'rem') } @$rem;
5185                 @new_add = map { format_diff_line($_, 'add') } @$add;
5186         }
5187
5188         @new_ctx = map { format_diff_line($_, 'ctx') } @$ctx;
5189
5190         return (\@new_ctx, \@new_rem, \@new_add);
5191 }
5192
5193 # Print context lines and then rem/add lines.
5194 sub print_diff_lines {
5195         my ($ctx, $rem, $add, $diff_style, $num_parents) = @_;
5196         my $is_combined = $num_parents > 1;
5197
5198         ($ctx, $rem, $add) = format_ctx_rem_add_lines($ctx, $rem, $add,
5199                 $num_parents);
5200
5201         if ($diff_style eq 'sidebyside' && !$is_combined) {
5202                 print_sidebyside_diff_lines($ctx, $rem, $add);
5203         } else {
5204                 # default 'inline' style and unknown styles
5205                 print_inline_diff_lines($ctx, $rem, $add);
5206         }
5207 }
5208
5209 sub print_diff_chunk {
5210         my ($diff_style, $num_parents, $from, $to, @chunk) = @_;
5211         my (@ctx, @rem, @add);
5212
5213         # The class of the previous line.
5214         my $prev_class = '';
5215
5216         return unless @chunk;
5217
5218         # incomplete last line might be among removed or added lines,
5219         # or both, or among context lines: find which
5220         for (my $i = 1; $i < @chunk; $i++) {
5221                 if ($chunk[$i][0] eq 'incomplete') {
5222                         $chunk[$i][0] = $chunk[$i-1][0];
5223                 }
5224         }
5225
5226         # guardian
5227         push @chunk, ["", ""];
5228
5229         foreach my $line_info (@chunk) {
5230                 my ($class, $line) = @$line_info;
5231
5232                 # print chunk headers
5233                 if ($class && $class eq 'chunk_header') {
5234                         print format_diff_line($line, $class, $from, $to);
5235                         next;
5236                 }
5237
5238                 ## print from accumulator when have some add/rem lines or end
5239                 # of chunk (flush context lines), or when have add and rem
5240                 # lines and new block is reached (otherwise add/rem lines could
5241                 # be reordered)
5242                 if (!$class || ((@rem || @add) && $class eq 'ctx') ||
5243                     (@rem && @add && $class ne $prev_class)) {
5244                         print_diff_lines(\@ctx, \@rem, \@add,
5245                                          $diff_style, $num_parents);
5246                         @ctx = @rem = @add = ();
5247                 }
5248
5249                 ## adding lines to accumulator
5250                 # guardian value
5251                 last unless $line;
5252                 # rem, add or change
5253                 if ($class eq 'rem') {
5254                         push @rem, $line;
5255                 } elsif ($class eq 'add') {
5256                         push @add, $line;
5257                 }
5258                 # context line
5259                 if ($class eq 'ctx') {
5260                         push @ctx, $line;
5261                 }
5262
5263                 $prev_class = $class;
5264         }
5265 }
5266
5267 sub git_patchset_body {
5268         my ($fd, $diff_style, $difftree, $hash, @hash_parents) = @_;
5269         my ($hash_parent) = $hash_parents[0];
5270
5271         my $is_combined = (@hash_parents > 1);
5272         my $patch_idx = 0;
5273         my $patch_number = 0;
5274         my $patch_line;
5275         my $diffinfo;
5276         my $to_name;
5277         my (%from, %to);
5278         my @chunk; # for side-by-side diff
5279
5280         print "<div class=\"patchset\">\n";
5281
5282         # skip to first patch
5283         while ($patch_line = <$fd>) {
5284                 chomp $patch_line;
5285
5286                 last if ($patch_line =~ m/^diff /);
5287         }
5288
5289  PATCH:
5290         while ($patch_line) {
5291
5292                 # parse "git diff" header line
5293                 if ($patch_line =~ m/^diff --git (\"(?:[^\\\"]*(?:\\.[^\\\"]*)*)\"|[^ "]*) (.*)$/) {
5294                         # $1 is from_name, which we do not use
5295                         $to_name = unquote($2);
5296                         $to_name =~ s!^b/!!;
5297                 } elsif ($patch_line =~ m/^diff --(cc|combined) ("?.*"?)$/) {
5298                         # $1 is 'cc' or 'combined', which we do not use
5299                         $to_name = unquote($2);
5300                 } else {
5301                         $to_name = undef;
5302                 }
5303
5304                 # check if current patch belong to current raw line
5305                 # and parse raw git-diff line if needed
5306                 if (is_patch_split($diffinfo, { 'to_file' => $to_name })) {
5307                         # this is continuation of a split patch
5308                         print "<div class=\"patch cont\">\n";
5309                 } else {
5310                         # advance raw git-diff output if needed
5311                         $patch_idx++ if defined $diffinfo;
5312
5313                         # read and prepare patch information
5314                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5315
5316                         # compact combined diff output can have some patches skipped
5317                         # find which patch (using pathname of result) we are at now;
5318                         if ($is_combined) {
5319                                 while ($to_name ne $diffinfo->{'to_file'}) {
5320                                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
5321                                               format_diff_cc_simplified($diffinfo, @hash_parents) .
5322                                               "</div>\n";  # class="patch"
5323
5324                                         $patch_idx++;
5325                                         $patch_number++;
5326
5327                                         last if $patch_idx > $#$difftree;
5328                                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5329                                 }
5330                         }
5331
5332                         # modifies %from, %to hashes
5333                         parse_from_to_diffinfo($diffinfo, \%from, \%to, @hash_parents);
5334
5335                         # this is first patch for raw difftree line with $patch_idx index
5336                         # we index @$difftree array from 0, but number patches from 1
5337                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n";
5338                 }
5339
5340                 # git diff header
5341                 #assert($patch_line =~ m/^diff /) if DEBUG;
5342                 #assert($patch_line !~ m!$/$!) if DEBUG; # is chomp-ed
5343                 $patch_number++;
5344                 # print "git diff" header
5345                 print format_git_diff_header_line($patch_line, $diffinfo,
5346                                                   \%from, \%to);
5347
5348                 # print extended diff header
5349                 print "<div class=\"diff extended_header\">\n";
5350         EXTENDED_HEADER:
5351                 while ($patch_line = <$fd>) {
5352                         chomp $patch_line;
5353
5354                         last EXTENDED_HEADER if ($patch_line =~ m/^--- |^diff /);
5355
5356                         print format_extended_diff_header_line($patch_line, $diffinfo,
5357                                                                \%from, \%to);
5358                 }
5359                 print "</div>\n"; # class="diff extended_header"
5360
5361                 # from-file/to-file diff header
5362                 if (! $patch_line) {
5363                         print "</div>\n"; # class="patch"
5364                         last PATCH;
5365                 }
5366                 next PATCH if ($patch_line =~ m/^diff /);
5367                 #assert($patch_line =~ m/^---/) if DEBUG;
5368
5369                 my $last_patch_line = $patch_line;
5370                 $patch_line = <$fd>;
5371                 chomp $patch_line;
5372                 #assert($patch_line =~ m/^\+\+\+/) if DEBUG;
5373
5374                 print format_diff_from_to_header($last_patch_line, $patch_line,
5375                                                  $diffinfo, \%from, \%to,
5376                                                  @hash_parents);
5377
5378                 # the patch itself
5379         LINE:
5380                 while ($patch_line = <$fd>) {
5381                         chomp $patch_line;
5382
5383                         next PATCH if ($patch_line =~ m/^diff /);
5384
5385                         my $class = diff_line_class($patch_line, \%from, \%to);
5386
5387                         if ($class eq 'chunk_header') {
5388                                 print_diff_chunk($diff_style, scalar @hash_parents, \%from, \%to, @chunk);
5389                                 @chunk = ();
5390                         }
5391
5392                         push @chunk, [ $class, $patch_line ];
5393                 }
5394
5395         } continue {
5396                 if (@chunk) {
5397                         print_diff_chunk($diff_style, scalar @hash_parents, \%from, \%to, @chunk);
5398                         @chunk = ();
5399                 }
5400                 print "</div>\n"; # class="patch"
5401         }
5402
5403         # for compact combined (--cc) format, with chunk and patch simplification
5404         # the patchset might be empty, but there might be unprocessed raw lines
5405         for (++$patch_idx if $patch_number > 0;
5406              $patch_idx < @$difftree;
5407              ++$patch_idx) {
5408                 # read and prepare patch information
5409                 $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5410
5411                 # generate anchor for "patch" links in difftree / whatchanged part
5412                 print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
5413                       format_diff_cc_simplified($diffinfo, @hash_parents) .
5414                       "</div>\n";  # class="patch"
5415
5416                 $patch_number++;
5417         }
5418
5419         if ($patch_number == 0) {
5420                 if (@hash_parents > 1) {
5421                         print "<div class=\"diff nodifferences\">Trivial merge</div>\n";
5422                 } else {
5423                         print "<div class=\"diff nodifferences\">No differences found</div>\n";
5424                 }
5425         }
5426
5427         print "</div>\n"; # class="patchset"
5428 }
5429
5430 # . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
5431
5432 sub git_project_search_form {
5433         my ($searchtext, $search_use_regexp) = @_;
5434
5435         my $limit = '';
5436         if ($project_filter) {
5437                 $limit = " in '$project_filter/'";
5438         }
5439
5440         print "<div class=\"projsearch\">\n";
5441         print $cgi->startform(-method => 'get', -action => $my_uri) .
5442               $cgi->hidden(-name => 'a', -value => 'project_list')  . "\n";
5443         print $cgi->hidden(-name => 'pf', -value => $project_filter). "\n"
5444                 if (defined $project_filter);
5445         print $cgi->textfield(-name => 's', -value => $searchtext,
5446                               -title => "Search project by name and description$limit",
5447                               -size => 60) . "\n" .
5448               "<span title=\"Extended regular expression\">" .
5449               $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
5450                              -checked => $search_use_regexp) .
5451               "</span>\n" .
5452               $cgi->submit(-name => 'btnS', -value => 'Search') .
5453               $cgi->end_form() . "\n" .
5454               $cgi->a({-href => href(project => undef, searchtext => undef,
5455                                      project_filter => $project_filter)},
5456                       esc_html("List all projects$limit")) . "<br />\n";
5457         print "</div>\n";
5458 }
5459
5460 # entry for given @keys needs filling if at least one of keys in list
5461 # is not present in %$project_info
5462 sub project_info_needs_filling {
5463         my ($project_info, @keys) = @_;
5464
5465         # return List::MoreUtils::any { !exists $project_info->{$_} } @keys;
5466         foreach my $key (@keys) {
5467                 if (!exists $project_info->{$key}) {
5468                         return 1;
5469                 }
5470         }
5471         return;
5472 }
5473
5474 # fills project list info (age, description, owner, category, forks, etc.)
5475 # for each project in the list, removing invalid projects from
5476 # returned list, or fill only specified info.
5477 #
5478 # Invalid projects are removed from the returned list if and only if you
5479 # ask 'age' or 'age_string' to be filled, because they are the only fields
5480 # that run unconditionally git command that requires repository, and
5481 # therefore do always check if project repository is invalid.
5482 #
5483 # USAGE:
5484 # * fill_project_list_info(\@project_list, 'descr_long', 'ctags')
5485 #   ensures that 'descr_long' and 'ctags' fields are filled
5486 # * @project_list = fill_project_list_info(\@project_list)
5487 #   ensures that all fields are filled (and invalid projects removed)
5488 #
5489 # NOTE: modifies $projlist, but does not remove entries from it
5490 sub fill_project_list_info {
5491         my ($projlist, @wanted_keys) = @_;
5492         my @projects;
5493         my $filter_set = sub { return @_; };
5494         if (@wanted_keys) {
5495                 my %wanted_keys = map { $_ => 1 } @wanted_keys;
5496                 $filter_set = sub { return grep { $wanted_keys{$_} } @_; };
5497         }
5498
5499         my $show_ctags = gitweb_check_feature('ctags');
5500  PROJECT:
5501         foreach my $pr (@$projlist) {
5502                 if (project_info_needs_filling($pr, $filter_set->('age', 'age_string'))) {
5503                         my (@activity) = git_get_last_activity($pr->{'path'});
5504                         unless (@activity) {
5505                                 next PROJECT;
5506                         }
5507                         ($pr->{'age'}, $pr->{'age_string'}) = @activity;
5508                 }
5509                 if (project_info_needs_filling($pr, $filter_set->('descr', 'descr_long'))) {
5510                         my $descr = git_get_project_description($pr->{'path'}) || "";
5511                         $descr = to_utf8($descr);
5512                         $pr->{'descr_long'} = $descr;
5513                         $pr->{'descr'} = chop_str($descr, $projects_list_description_width, 5);
5514                 }
5515                 if (project_info_needs_filling($pr, $filter_set->('owner'))) {
5516                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}") || "";
5517                 }
5518                 if ($show_ctags &&
5519                     project_info_needs_filling($pr, $filter_set->('ctags'))) {
5520                         $pr->{'ctags'} = git_get_project_ctags($pr->{'path'});
5521                 }
5522                 if ($projects_list_group_categories &&
5523                     project_info_needs_filling($pr, $filter_set->('category'))) {
5524                         my $cat = git_get_project_category($pr->{'path'}) ||
5525                                                            $project_list_default_category;
5526                         $pr->{'category'} = to_utf8($cat);
5527                 }
5528
5529                 push @projects, $pr;
5530         }
5531
5532         return @projects;
5533 }
5534
5535 sub sort_projects_list {
5536         my ($projlist, $order) = @_;
5537
5538         sub order_str {
5539                 my $key = shift;
5540                 return sub { $a->{$key} cmp $b->{$key} };
5541         }
5542
5543         sub order_num_then_undef {
5544                 my $key = shift;
5545                 return sub {
5546                         defined $a->{$key} ?
5547                                 (defined $b->{$key} ? $a->{$key} <=> $b->{$key} : -1) :
5548                                 (defined $b->{$key} ? 1 : 0)
5549                 };
5550         }
5551
5552         my %orderings = (
5553                 project => order_str('path'),
5554                 descr => order_str('descr_long'),
5555                 owner => order_str('owner'),
5556                 age => order_num_then_undef('age'),
5557         );
5558
5559         my $ordering = $orderings{$order};
5560         return defined $ordering ? sort $ordering @$projlist : @$projlist;
5561 }
5562
5563 # returns a hash of categories, containing the list of project
5564 # belonging to each category
5565 sub build_projlist_by_category {
5566         my ($projlist, $from, $to) = @_;
5567         my %categories;
5568
5569         $from = 0 unless defined $from;
5570         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5571
5572         for (my $i = $from; $i <= $to; $i++) {
5573                 my $pr = $projlist->[$i];
5574                 push @{$categories{ $pr->{'category'} }}, $pr;
5575         }
5576
5577         return wantarray ? %categories : \%categories;
5578 }
5579
5580 # print 'sort by' <th> element, generating 'sort by $name' replay link
5581 # if that order is not selected
5582 sub print_sort_th {
5583         print format_sort_th(@_);
5584 }
5585
5586 sub format_sort_th {
5587         my ($name, $order, $header) = @_;
5588         my $sort_th = "";
5589         $header ||= ucfirst($name);
5590
5591         if ($order eq $name) {
5592                 $sort_th .= "<th>$header</th>\n";
5593         } else {
5594                 $sort_th .= "<th>" .
5595                             $cgi->a({-href => href(-replay=>1, order=>$name),
5596                                      -class => "header"}, $header) .
5597                             "</th>\n";
5598         }
5599
5600         return $sort_th;
5601 }
5602
5603 sub git_project_list_rows {
5604         my ($projlist, $from, $to, $check_forks) = @_;
5605
5606         $from = 0 unless defined $from;
5607         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5608
5609         my $alternate = 1;
5610         for (my $i = $from; $i <= $to; $i++) {
5611                 my $pr = $projlist->[$i];
5612
5613                 if ($alternate) {
5614                         print "<tr class=\"dark\">\n";
5615                 } else {
5616                         print "<tr class=\"light\">\n";
5617                 }
5618                 $alternate ^= 1;
5619
5620                 if ($check_forks) {
5621                         print "<td>";
5622                         if ($pr->{'forks'}) {
5623                                 my $nforks = scalar @{$pr->{'forks'}};
5624                                 if ($nforks > 0) {
5625                                         print $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks"),
5626                                                        -title => "$nforks forks"}, "+");
5627                                 } else {
5628                                         print $cgi->span({-title => "$nforks forks"}, "+");
5629                                 }
5630                         }
5631                         print "</td>\n";
5632                 }
5633                 print "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5634                                         -class => "list"},
5635                                        esc_html_match_hl($pr->{'path'}, $search_regexp)) .
5636                       "</td>\n" .
5637                       "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5638                                         -class => "list",
5639                                         -title => $pr->{'descr_long'}},
5640                                         $search_regexp
5641                                         ? esc_html_match_hl_chopped($pr->{'descr_long'},
5642                                                                     $pr->{'descr'}, $search_regexp)
5643                                         : esc_html($pr->{'descr'})) .
5644                       "</td>\n";
5645                 unless ($omit_owner) {
5646                         print "<td><i>" . chop_and_escape_str($pr->{'owner'}, 15) . "</i></td>\n";
5647                 }
5648                 unless ($omit_age_column) {
5649                         print "<td class=\"". age_class($pr->{'age'}) . "\">" .
5650                             (defined $pr->{'age_string'} ? $pr->{'age_string'} : "No commits") . "</td>\n";
5651                 }
5652                 print"<td class=\"link\">" .
5653                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary")}, "summary")   . " | " .
5654                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"shortlog")}, "shortlog") . " | " .
5655                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"log")}, "log") . " | " .
5656                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"tree")}, "tree") .
5657                       ($pr->{'forks'} ? " | " . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "forks") : '') .
5658                       "</td>\n" .
5659                       "</tr>\n";
5660         }
5661 }
5662
5663 sub git_project_list_body {
5664         # actually uses global variable $project
5665         my ($projlist, $order, $from, $to, $extra, $no_header) = @_;
5666         my @projects = @$projlist;
5667
5668         my $check_forks = gitweb_check_feature('forks');
5669         my $show_ctags  = gitweb_check_feature('ctags');
5670         my $tagfilter = $show_ctags ? $input_params{'ctag'} : undef;
5671         $check_forks = undef
5672                 if ($tagfilter || $search_regexp);
5673
5674         # filtering out forks before filling info allows to do less work
5675         @projects = filter_forks_from_projects_list(\@projects)
5676                 if ($check_forks);
5677         # search_projects_list pre-fills required info
5678         @projects = search_projects_list(\@projects,
5679                                          'search_regexp' => $search_regexp,
5680                                          'tagfilter'  => $tagfilter)
5681                 if ($tagfilter || $search_regexp);
5682         # fill the rest
5683         my @all_fields = ('descr', 'descr_long', 'ctags', 'category');
5684         push @all_fields, ('age', 'age_string') unless($omit_age_column);
5685         push @all_fields, 'owner' unless($omit_owner);
5686         @projects = fill_project_list_info(\@projects, @all_fields);
5687
5688         $order ||= $default_projects_order;
5689         $from = 0 unless defined $from;
5690         $to = $#projects if (!defined $to || $#projects < $to);
5691
5692         # short circuit
5693         if ($from > $to) {
5694                 print "<center>\n".
5695                       "<b>No such projects found</b><br />\n".
5696                       "Click ".$cgi->a({-href=>href(project=>undef)},"here")." to view all projects<br />\n".
5697                       "</center>\n<br />\n";
5698                 return;
5699         }
5700
5701         @projects = sort_projects_list(\@projects, $order);
5702
5703         if ($show_ctags) {
5704                 my $ctags = git_gather_all_ctags(\@projects);
5705                 my $cloud = git_populate_project_tagcloud($ctags);
5706                 print git_show_project_tagcloud($cloud, 64);
5707         }
5708
5709         print "<table class=\"project_list\">\n";
5710         unless ($no_header) {
5711                 print "<tr>\n";
5712                 if ($check_forks) {
5713                         print "<th></th>\n";
5714                 }
5715                 print_sort_th('project', $order, 'Project');
5716                 print_sort_th('descr', $order, 'Description');
5717                 print_sort_th('owner', $order, 'Owner') unless $omit_owner;
5718                 print_sort_th('age', $order, 'Last Change') unless $omit_age_column;
5719                 print "<th></th>\n" . # for links
5720                       "</tr>\n";
5721         }
5722
5723         if ($projects_list_group_categories) {
5724                 # only display categories with projects in the $from-$to window
5725                 @projects = sort {$a->{'category'} cmp $b->{'category'}} @projects[$from..$to];
5726                 my %categories = build_projlist_by_category(\@projects, $from, $to);
5727                 foreach my $cat (sort keys %categories) {
5728                         unless ($cat eq "") {
5729                                 print "<tr>\n";
5730                                 if ($check_forks) {
5731                                         print "<td></td>\n";
5732                                 }
5733                                 print "<td class=\"category\" colspan=\"5\">".esc_html($cat)."</td>\n";
5734                                 print "</tr>\n";
5735                         }
5736
5737                         git_project_list_rows($categories{$cat}, undef, undef, $check_forks);
5738                 }
5739         } else {
5740                 git_project_list_rows(\@projects, $from, $to, $check_forks);
5741         }
5742
5743         if (defined $extra) {
5744                 print "<tr>\n";
5745                 if ($check_forks) {
5746                         print "<td></td>\n";
5747                 }
5748                 print "<td colspan=\"5\">$extra</td>\n" .
5749                       "</tr>\n";
5750         }
5751         print "</table>\n";
5752 }
5753
5754 sub git_log_body {
5755         # uses global variable $project
5756         my ($commitlist, $from, $to, $refs, $extra) = @_;
5757
5758         $from = 0 unless defined $from;
5759         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5760
5761         for (my $i = 0; $i <= $to; $i++) {
5762                 my %co = %{$commitlist->[$i]};
5763                 next if !%co;
5764                 my $commit = $co{'id'};
5765                 my $ref = format_ref_marker($refs, $commit);
5766                 git_print_header_div('commit',
5767                                "<span class=\"age\">$co{'age_string'}</span>" .
5768                                esc_html($co{'title'}) . $ref,
5769                                $commit);
5770                 print "<div class=\"title_text\">\n" .
5771                       "<div class=\"log_link\">\n" .
5772                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") .
5773                       " | " .
5774                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") .
5775                       " | " .
5776                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree") .
5777                       "<br/>\n" .
5778                       "</div>\n";
5779                       git_print_authorship(\%co, -tag => 'span');
5780                       print "<br/>\n</div>\n";
5781
5782                 print "<div class=\"log_body\">\n";
5783                 git_print_log($co{'comment'}, -final_empty_line=> 1);
5784                 print "</div>\n";
5785         }
5786         if ($extra) {
5787                 print "<div class=\"page_nav\">\n";
5788                 print "$extra\n";
5789                 print "</div>\n";
5790         }
5791 }
5792
5793 sub git_shortlog_body {
5794         # uses global variable $project
5795         my ($commitlist, $from, $to, $refs, $extra) = @_;
5796
5797         $from = 0 unless defined $from;
5798         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5799
5800         print "<table class=\"shortlog\">\n";
5801         my $alternate = 1;
5802         for (my $i = $from; $i <= $to; $i++) {
5803                 my %co = %{$commitlist->[$i]};
5804                 my $commit = $co{'id'};
5805                 my $ref = format_ref_marker($refs, $commit);
5806                 if ($alternate) {
5807                         print "<tr class=\"dark\">\n";
5808                 } else {
5809                         print "<tr class=\"light\">\n";
5810                 }
5811                 $alternate ^= 1;
5812                 # git_summary() used print "<td><i>$co{'age_string'}</i></td>\n" .
5813                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5814                       format_author_html('td', \%co, 10) . "<td>";
5815                 print format_subject_html($co{'title'}, $co{'title_short'},
5816                                           href(action=>"commit", hash=>$commit), $ref);
5817                 print "</td>\n" .
5818                       "<td class=\"link\">" .
5819                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") . " | " .
5820                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") . " | " .
5821                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree");
5822                 my $snapshot_links = format_snapshot_links($commit);
5823                 if (defined $snapshot_links) {
5824                         print " | " . $snapshot_links;
5825                 }
5826                 print "</td>\n" .
5827                       "</tr>\n";
5828         }
5829         if (defined $extra) {
5830                 print "<tr>\n" .
5831                       "<td colspan=\"4\">$extra</td>\n" .
5832                       "</tr>\n";
5833         }
5834         print "</table>\n";
5835 }
5836
5837 sub git_history_body {
5838         # Warning: assumes constant type (blob or tree) during history
5839         my ($commitlist, $from, $to, $refs, $extra,
5840             $file_name, $file_hash, $ftype) = @_;
5841
5842         $from = 0 unless defined $from;
5843         $to = $#{$commitlist} unless (defined $to && $to <= $#{$commitlist});
5844
5845         print "<table class=\"history\">\n";
5846         my $alternate = 1;
5847         for (my $i = $from; $i <= $to; $i++) {
5848                 my %co = %{$commitlist->[$i]};
5849                 if (!%co) {
5850                         next;
5851                 }
5852                 my $commit = $co{'id'};
5853
5854                 my $ref = format_ref_marker($refs, $commit);
5855
5856                 if ($alternate) {
5857                         print "<tr class=\"dark\">\n";
5858                 } else {
5859                         print "<tr class=\"light\">\n";
5860                 }
5861                 $alternate ^= 1;
5862                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5863         # shortlog:   format_author_html('td', \%co, 10)
5864                       format_author_html('td', \%co, 15, 3) . "<td>";
5865                 # originally git_history used chop_str($co{'title'}, 50)
5866                 print format_subject_html($co{'title'}, $co{'title_short'},
5867                                           href(action=>"commit", hash=>$commit), $ref);
5868                 print "</td>\n" .
5869                       "<td class=\"link\">" .
5870                       $cgi->a({-href => href(action=>$ftype, hash_base=>$commit, file_name=>$file_name)}, $ftype) . " | " .
5871                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff");
5872
5873                 if ($ftype eq 'blob') {
5874                         my $blob_current = $file_hash;
5875                         my $blob_parent  = git_get_hash_by_path($commit, $file_name);
5876                         if (defined $blob_current && defined $blob_parent &&
5877                                         $blob_current ne $blob_parent) {
5878                                 print " | " .
5879                                         $cgi->a({-href => href(action=>"blobdiff",
5880                                                                hash=>$blob_current, hash_parent=>$blob_parent,
5881                                                                hash_base=>$hash_base, hash_parent_base=>$commit,
5882                                                                file_name=>$file_name)},
5883                                                 "diff to current");
5884                         }
5885                 }
5886                 print "</td>\n" .
5887                       "</tr>\n";
5888         }
5889         if (defined $extra) {
5890                 print "<tr>\n" .
5891                       "<td colspan=\"4\">$extra</td>\n" .
5892                       "</tr>\n";
5893         }
5894         print "</table>\n";
5895 }
5896
5897 sub git_tags_body {
5898         # uses global variable $project
5899         my ($taglist, $from, $to, $extra) = @_;
5900         $from = 0 unless defined $from;
5901         $to = $#{$taglist} if (!defined $to || $#{$taglist} < $to);
5902
5903         print "<table class=\"tags\">\n";
5904         my $alternate = 1;
5905         for (my $i = $from; $i <= $to; $i++) {
5906                 my $entry = $taglist->[$i];
5907                 my %tag = %$entry;
5908                 my $comment = $tag{'subject'};
5909                 my $comment_short;
5910                 if (defined $comment) {
5911                         $comment_short = chop_str($comment, 30, 5);
5912                 }
5913                 if ($alternate) {
5914                         print "<tr class=\"dark\">\n";
5915                 } else {
5916                         print "<tr class=\"light\">\n";
5917                 }
5918                 $alternate ^= 1;
5919                 if (defined $tag{'age'}) {
5920                         print "<td><i>$tag{'age'}</i></td>\n";
5921                 } else {
5922                         print "<td></td>\n";
5923                 }
5924                 print "<td>" .
5925                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'}),
5926                                -class => "list name"}, esc_html($tag{'name'})) .
5927                       "</td>\n" .
5928                       "<td>";
5929                 if (defined $comment) {
5930                         print format_subject_html($comment, $comment_short,
5931                                                   href(action=>"tag", hash=>$tag{'id'}));
5932                 }
5933                 print "</td>\n" .
5934                       "<td class=\"selflink\">";
5935                 if ($tag{'type'} eq "tag") {
5936                         print $cgi->a({-href => href(action=>"tag", hash=>$tag{'id'})}, "tag");
5937                 } else {
5938                         print "&nbsp;";
5939                 }
5940                 print "</td>\n" .
5941                       "<td class=\"link\">" . " | " .
5942                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'})}, $tag{'reftype'});
5943                 if ($tag{'reftype'} eq "commit") {
5944                         print " | " . $cgi->a({-href => href(action=>"shortlog", hash=>$tag{'fullname'})}, "shortlog") .
5945                               " | " . $cgi->a({-href => href(action=>"log", hash=>$tag{'fullname'})}, "log");
5946                 } elsif ($tag{'reftype'} eq "blob") {
5947                         print " | " . $cgi->a({-href => href(action=>"blob_plain", hash=>$tag{'refid'})}, "raw");
5948                 }
5949                 print "</td>\n" .
5950                       "</tr>";
5951         }
5952         if (defined $extra) {
5953                 print "<tr>\n" .
5954                       "<td colspan=\"5\">$extra</td>\n" .
5955                       "</tr>\n";
5956         }
5957         print "</table>\n";
5958 }
5959
5960 sub git_heads_body {
5961         # uses global variable $project
5962         my ($headlist, $head_at, $from, $to, $extra) = @_;
5963         $from = 0 unless defined $from;
5964         $to = $#{$headlist} if (!defined $to || $#{$headlist} < $to);
5965
5966         print "<table class=\"heads\">\n";
5967         my $alternate = 1;
5968         for (my $i = $from; $i <= $to; $i++) {
5969                 my $entry = $headlist->[$i];
5970                 my %ref = %$entry;
5971                 my $curr = defined $head_at && $ref{'id'} eq $head_at;
5972                 if ($alternate) {
5973                         print "<tr class=\"dark\">\n";
5974                 } else {
5975                         print "<tr class=\"light\">\n";
5976                 }
5977                 $alternate ^= 1;
5978                 print "<td><i>$ref{'age'}</i></td>\n" .
5979                       ($curr ? "<td class=\"current_head\">" : "<td>") .
5980                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'}),
5981                                -class => "list name"},esc_html($ref{'name'})) .
5982                       "</td>\n" .
5983                       "<td class=\"link\">" .
5984                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'})}, "shortlog") . " | " .
5985                       $cgi->a({-href => href(action=>"log", hash=>$ref{'fullname'})}, "log") . " | " .
5986                       $cgi->a({-href => href(action=>"tree", hash=>$ref{'fullname'}, hash_base=>$ref{'fullname'})}, "tree") .
5987                       "</td>\n" .
5988                       "</tr>";
5989         }
5990         if (defined $extra) {
5991                 print "<tr>\n" .
5992                       "<td colspan=\"3\">$extra</td>\n" .
5993                       "</tr>\n";
5994         }
5995         print "</table>\n";
5996 }
5997
5998 # Display a single remote block
5999 sub git_remote_block {
6000         my ($remote, $rdata, $limit, $head) = @_;
6001
6002         my $heads = $rdata->{'heads'};
6003         my $fetch = $rdata->{'fetch'};
6004         my $push = $rdata->{'push'};
6005
6006         my $urls_table = "<table class=\"projects_list\">\n" ;
6007
6008         if (defined $fetch) {
6009                 if ($fetch eq $push) {
6010                         $urls_table .= format_repo_url("URL", $fetch);
6011                 } else {
6012                         $urls_table .= format_repo_url("Fetch URL", $fetch);
6013                         $urls_table .= format_repo_url("Push URL", $push) if defined $push;
6014                 }
6015         } elsif (defined $push) {
6016                 $urls_table .= format_repo_url("Push URL", $push);
6017         } else {
6018                 $urls_table .= format_repo_url("", "No remote URL");
6019         }
6020
6021         $urls_table .= "</table>\n";
6022
6023         my $dots;
6024         if (defined $limit && $limit < @$heads) {
6025                 $dots = $cgi->a({-href => href(action=>"remotes", hash=>$remote)}, "...");
6026         }
6027
6028         print $urls_table;
6029         git_heads_body($heads, $head, 0, $limit, $dots);
6030 }
6031
6032 # Display a list of remote names with the respective fetch and push URLs
6033 sub git_remotes_list {
6034         my ($remotedata, $limit) = @_;
6035         print "<table class=\"heads\">\n";
6036         my $alternate = 1;
6037         my @remotes = sort keys %$remotedata;
6038
6039         my $limited = $limit && $limit < @remotes;
6040
6041         $#remotes = $limit - 1 if $limited;
6042
6043         while (my $remote = shift @remotes) {
6044                 my $rdata = $remotedata->{$remote};
6045                 my $fetch = $rdata->{'fetch'};
6046                 my $push = $rdata->{'push'};
6047                 if ($alternate) {
6048                         print "<tr class=\"dark\">\n";
6049                 } else {
6050                         print "<tr class=\"light\">\n";
6051                 }
6052                 $alternate ^= 1;
6053                 print "<td>" .
6054                       $cgi->a({-href=> href(action=>'remotes', hash=>$remote),
6055                                -class=> "list name"},esc_html($remote)) .
6056                       "</td>";
6057                 print "<td class=\"link\">" .
6058                       (defined $fetch ? $cgi->a({-href=> $fetch}, "fetch") : "fetch") .
6059                       " | " .
6060                       (defined $push ? $cgi->a({-href=> $push}, "push") : "push") .
6061                       "</td>";
6062
6063                 print "</tr>\n";
6064         }
6065
6066         if ($limited) {
6067                 print "<tr>\n" .
6068                       "<td colspan=\"3\">" .
6069                       $cgi->a({-href => href(action=>"remotes")}, "...") .
6070                       "</td>\n" . "</tr>\n";
6071         }
6072
6073         print "</table>";
6074 }
6075
6076 # Display remote heads grouped by remote, unless there are too many
6077 # remotes, in which case we only display the remote names
6078 sub git_remotes_body {
6079         my ($remotedata, $limit, $head) = @_;
6080         if ($limit and $limit < keys %$remotedata) {
6081                 git_remotes_list($remotedata, $limit);
6082         } else {
6083                 fill_remote_heads($remotedata);
6084                 while (my ($remote, $rdata) = each %$remotedata) {
6085                         git_print_section({-class=>"remote", -id=>$remote},
6086                                 ["remotes", $remote, $remote], sub {
6087                                         git_remote_block($remote, $rdata, $limit, $head);
6088                                 });
6089                 }
6090         }
6091 }
6092
6093 sub git_search_message {
6094         my %co = @_;
6095
6096         my $greptype;
6097         if ($searchtype eq 'commit') {
6098                 $greptype = "--grep=";
6099         } elsif ($searchtype eq 'author') {
6100                 $greptype = "--author=";
6101         } elsif ($searchtype eq 'committer') {
6102                 $greptype = "--committer=";
6103         }
6104         $greptype .= $searchtext;
6105         my @commitlist = parse_commits($hash, 101, (100 * $page), undef,
6106                                        $greptype, '--regexp-ignore-case',
6107                                        $search_use_regexp ? '--extended-regexp' : '--fixed-strings');
6108
6109         my $paging_nav = '';
6110         if ($page > 0) {
6111                 $paging_nav .=
6112                         $cgi->a({-href => href(-replay=>1, page=>undef)},
6113                                 "first") .
6114                         " &sdot; " .
6115                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
6116                                  -accesskey => "p", -title => "Alt-p"}, "prev");
6117         } else {
6118                 $paging_nav .= "first &sdot; prev";
6119         }
6120         my $next_link = '';
6121         if ($#commitlist >= 100) {
6122                 $next_link =
6123                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
6124                                  -accesskey => "n", -title => "Alt-n"}, "next");
6125                 $paging_nav .= " &sdot; $next_link";
6126         } else {
6127                 $paging_nav .= " &sdot; next";
6128         }
6129
6130         git_header_html();
6131
6132         git_print_page_nav('','', $hash,$co{'tree'},$hash, $paging_nav);
6133         git_print_header_div('commit', esc_html($co{'title'}), $hash);
6134         if ($page == 0 && !@commitlist) {
6135                 print "<p>No match.</p>\n";
6136         } else {
6137                 git_search_grep_body(\@commitlist, 0, 99, $next_link);
6138         }
6139
6140         git_footer_html();
6141 }
6142
6143 sub git_search_changes {
6144         my %co = @_;
6145
6146         local $/ = "\n";
6147         open my $fd, '-|', git_cmd(), '--no-pager', 'log', @diff_opts,
6148                 '--pretty=format:%H', '--no-abbrev', '--raw', "-S$searchtext",
6149                 ($search_use_regexp ? '--pickaxe-regex' : ())
6150                         or die_error(500, "Open git-log failed");
6151
6152         git_header_html();
6153
6154         git_print_page_nav('','', $hash,$co{'tree'},$hash);
6155         git_print_header_div('commit', esc_html($co{'title'}), $hash);
6156
6157         print "<table class=\"pickaxe search\">\n";
6158         my $alternate = 1;
6159         undef %co;
6160         my @files;
6161         while (my $line = <$fd>) {
6162                 chomp $line;
6163                 next unless $line;
6164
6165                 my %set = parse_difftree_raw_line($line);
6166                 if (defined $set{'commit'}) {
6167                         # finish previous commit
6168                         if (%co) {
6169                                 print "</td>\n" .
6170                                       "<td class=\"link\">" .
6171                                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
6172                                               "commit") .
6173                                       " | " .
6174                                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
6175                                                              hash_base=>$co{'id'})},
6176                                               "tree") .
6177                                       "</td>\n" .
6178                                       "</tr>\n";
6179                         }
6180
6181                         if ($alternate) {
6182                                 print "<tr class=\"dark\">\n";
6183                         } else {
6184                                 print "<tr class=\"light\">\n";
6185                         }
6186                         $alternate ^= 1;
6187                         %co = parse_commit($set{'commit'});
6188                         my $author = chop_and_escape_str($co{'author_name'}, 15, 5);
6189                         print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6190                               "<td><i>$author</i></td>\n" .
6191                               "<td>" .
6192                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
6193                                       -class => "list subject"},
6194                                       chop_and_escape_str($co{'title'}, 50) . "<br/>");
6195                 } elsif (defined $set{'to_id'}) {
6196                         next if ($set{'to_id'} =~ m/^0{40}$/);
6197
6198                         print $cgi->a({-href => href(action=>"blob", hash_base=>$co{'id'},
6199                                                      hash=>$set{'to_id'}, file_name=>$set{'to_file'}),
6200                                       -class => "list"},
6201                                       "<span class=\"match\">" . esc_path($set{'file'}) . "</span>") .
6202                               "<br/>\n";
6203                 }
6204         }
6205         close $fd;
6206
6207         # finish last commit (warning: repetition!)
6208         if (%co) {
6209                 print "</td>\n" .
6210                       "<td class=\"link\">" .
6211                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
6212                               "commit") .
6213                       " | " .
6214                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
6215                                              hash_base=>$co{'id'})},
6216                               "tree") .
6217                       "</td>\n" .
6218                       "</tr>\n";
6219         }
6220
6221         print "</table>\n";
6222
6223         git_footer_html();
6224 }
6225
6226 sub git_search_files {
6227         my %co = @_;
6228
6229         local $/ = "\n";
6230         open my $fd, "-|", git_cmd(), 'grep', '-n', '-z',
6231                 $search_use_regexp ? ('-E', '-i') : '-F',
6232                 $searchtext, $co{'tree'}
6233                         or die_error(500, "Open git-grep failed");
6234
6235         git_header_html();
6236
6237         git_print_page_nav('','', $hash,$co{'tree'},$hash);
6238         git_print_header_div('commit', esc_html($co{'title'}), $hash);
6239
6240         print "<table class=\"grep_search\">\n";
6241         my $alternate = 1;
6242         my $matches = 0;
6243         my $lastfile = '';
6244         my $file_href;
6245         while (my $line = <$fd>) {
6246                 chomp $line;
6247                 my ($file, $lno, $ltext, $binary);
6248                 last if ($matches++ > 1000);
6249                 if ($line =~ /^Binary file (.+) matches$/) {
6250                         $file = $1;
6251                         $binary = 1;
6252                 } else {
6253                         ($file, $lno, $ltext) = split(/\0/, $line, 3);
6254                         $file =~ s/^$co{'tree'}://;
6255                 }
6256                 if ($file ne $lastfile) {
6257                         $lastfile and print "</td></tr>\n";
6258                         if ($alternate++) {
6259                                 print "<tr class=\"dark\">\n";
6260                         } else {
6261                                 print "<tr class=\"light\">\n";
6262                         }
6263                         $file_href = href(action=>"blob", hash_base=>$co{'id'},
6264                                           file_name=>$file);
6265                         print "<td class=\"list\">".
6266                                 $cgi->a({-href => $file_href, -class => "list"}, esc_path($file));
6267                         print "</td><td>\n";
6268                         $lastfile = $file;
6269                 }
6270                 if ($binary) {
6271                         print "<div class=\"binary\">Binary file</div>\n";
6272                 } else {
6273                         $ltext = untabify($ltext);
6274                         if ($ltext =~ m/^(.*)($search_regexp)(.*)$/i) {
6275                                 $ltext = esc_html($1, -nbsp=>1);
6276                                 $ltext .= '<span class="match">';
6277                                 $ltext .= esc_html($2, -nbsp=>1);
6278                                 $ltext .= '</span>';
6279                                 $ltext .= esc_html($3, -nbsp=>1);
6280                         } else {
6281                                 $ltext = esc_html($ltext, -nbsp=>1);
6282                         }
6283                         print "<div class=\"pre\">" .
6284                                 $cgi->a({-href => $file_href.'#l'.$lno,
6285                                         -class => "linenr"}, sprintf('%4i', $lno)) .
6286                                 ' ' .  $ltext . "</div>\n";
6287                 }
6288         }
6289         if ($lastfile) {
6290                 print "</td></tr>\n";
6291                 if ($matches > 1000) {
6292                         print "<div class=\"diff nodifferences\">Too many matches, listing trimmed</div>\n";
6293                 }
6294         } else {
6295                 print "<div class=\"diff nodifferences\">No matches found</div>\n";
6296         }
6297         close $fd;
6298
6299         print "</table>\n";
6300
6301         git_footer_html();
6302 }
6303
6304 sub git_search_grep_body {
6305         my ($commitlist, $from, $to, $extra) = @_;
6306         $from = 0 unless defined $from;
6307         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
6308
6309         print "<table class=\"commit_search\">\n";
6310         my $alternate = 1;
6311         for (my $i = $from; $i <= $to; $i++) {
6312                 my %co = %{$commitlist->[$i]};
6313                 if (!%co) {
6314                         next;
6315                 }
6316                 my $commit = $co{'id'};
6317                 if ($alternate) {
6318                         print "<tr class=\"dark\">\n";
6319                 } else {
6320                         print "<tr class=\"light\">\n";
6321                 }
6322                 $alternate ^= 1;
6323                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6324                       format_author_html('td', \%co, 15, 5) .
6325                       "<td>" .
6326                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
6327                                -class => "list subject"},
6328                               chop_and_escape_str($co{'title'}, 50) . "<br/>");
6329                 my $comment = $co{'comment'};
6330                 foreach my $line (@$comment) {
6331                         if ($line =~ m/^(.*?)($search_regexp)(.*)$/i) {
6332                                 my ($lead, $match, $trail) = ($1, $2, $3);
6333                                 $match = chop_str($match, 70, 5, 'center');
6334                                 my $contextlen = int((80 - length($match))/2);
6335                                 $contextlen = 30 if ($contextlen > 30);
6336                                 $lead  = chop_str($lead,  $contextlen, 10, 'left');
6337                                 $trail = chop_str($trail, $contextlen, 10, 'right');
6338
6339                                 $lead  = esc_html($lead);
6340                                 $match = esc_html($match);
6341                                 $trail = esc_html($trail);
6342
6343                                 print "$lead<span class=\"match\">$match</span>$trail<br />";
6344                         }
6345                 }
6346                 print "</td>\n" .
6347                       "<td class=\"link\">" .
6348                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
6349                       " | " .
6350                       $cgi->a({-href => href(action=>"commitdiff", hash=>$co{'id'})}, "commitdiff") .
6351                       " | " .
6352                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
6353                 print "</td>\n" .
6354                       "</tr>\n";
6355         }
6356         if (defined $extra) {
6357                 print "<tr>\n" .
6358                       "<td colspan=\"3\">$extra</td>\n" .
6359                       "</tr>\n";
6360         }
6361         print "</table>\n";
6362 }
6363
6364 ## ======================================================================
6365 ## ======================================================================
6366 ## actions
6367
6368 sub git_project_list {
6369         my $order = $input_params{'order'};
6370         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
6371                 die_error(400, "Unknown order parameter");
6372         }
6373
6374         my @list = git_get_projects_list($project_filter, $strict_export);
6375         if (!@list) {
6376                 die_error(404, "No projects found");
6377         }
6378
6379         git_header_html();
6380         if (defined $home_text && -f $home_text) {
6381                 print "<div class=\"index_include\">\n";
6382                 insert_file($home_text);
6383                 print "</div>\n";
6384         }
6385
6386         git_project_search_form($searchtext, $search_use_regexp);
6387         git_project_list_body(\@list, $order);
6388         git_footer_html();
6389 }
6390
6391 sub git_forks {
6392         my $order = $input_params{'order'};
6393         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
6394                 die_error(400, "Unknown order parameter");
6395         }
6396
6397         my $filter = $project;
6398         $filter =~ s/\.git$//;
6399         my @list = git_get_projects_list($filter);
6400         if (!@list) {
6401                 die_error(404, "No forks found");
6402         }
6403
6404         git_header_html();
6405         git_print_page_nav('','');
6406         git_print_header_div('summary', "$project forks");
6407         git_project_list_body(\@list, $order);
6408         git_footer_html();
6409 }
6410
6411 sub git_project_index {
6412         my @projects = git_get_projects_list($project_filter, $strict_export);
6413         if (!@projects) {
6414                 die_error(404, "No projects found");
6415         }
6416
6417         print $cgi->header(
6418                 -type => 'text/plain',
6419                 -charset => 'utf-8',
6420                 -content_disposition => 'inline; filename="index.aux"');
6421
6422         foreach my $pr (@projects) {
6423                 if (!exists $pr->{'owner'}) {
6424                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}");
6425                 }
6426
6427                 my ($path, $owner) = ($pr->{'path'}, $pr->{'owner'});
6428                 # quote as in CGI::Util::encode, but keep the slash, and use '+' for ' '
6429                 $path  =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
6430                 $owner =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
6431                 $path  =~ s/ /\+/g;
6432                 $owner =~ s/ /\+/g;
6433
6434                 print "$path $owner\n";
6435         }
6436 }
6437
6438 sub git_summary {
6439         my $descr = git_get_project_description($project) || "none";
6440         my %co = parse_commit("HEAD");
6441         my %cd = %co ? parse_date($co{'committer_epoch'}, $co{'committer_tz'}) : ();
6442         my $head = $co{'id'};
6443         my $remote_heads = gitweb_check_feature('remote_heads');
6444
6445         my $owner = git_get_project_owner($project);
6446
6447         my $refs = git_get_references();
6448         # These get_*_list functions return one more to allow us to see if
6449         # there are more ...
6450         my @taglist  = git_get_tags_list(16);
6451         my @headlist = git_get_heads_list(16);
6452         my %remotedata = $remote_heads ? git_get_remotes_list() : ();
6453         my @forklist;
6454         my $check_forks = gitweb_check_feature('forks');
6455
6456         if ($check_forks) {
6457                 # find forks of a project
6458                 my $filter = $project;
6459                 $filter =~ s/\.git$//;
6460                 @forklist = git_get_projects_list($filter);
6461                 # filter out forks of forks
6462                 @forklist = filter_forks_from_projects_list(\@forklist)
6463                         if (@forklist);
6464         }
6465
6466         git_header_html();
6467         git_print_page_nav('summary','', $head);
6468
6469         print "<div class=\"title\">&nbsp;</div>\n";
6470         print "<table class=\"projects_list\">\n" .
6471               "<tr id=\"metadata_desc\"><td>description</td><td>" . esc_html($descr) . "</td></tr>\n";
6472         unless ($omit_owner) {
6473                 print  "<tr id=\"metadata_owner\"><td>owner</td><td>" . esc_html($owner) . "</td></tr>\n";
6474         }
6475         if (defined $cd{'rfc2822'}) {
6476                 print "<tr id=\"metadata_lchange\"><td>last change</td>" .
6477                       "<td>".format_timestamp_html(\%cd)."</td></tr>\n";
6478         }
6479
6480         # use per project git URL list in $projectroot/$project/cloneurl
6481         # or make project git URL from git base URL and project name
6482         my $url_tag = "URL";
6483         my @url_list = git_get_project_url_list($project);
6484         @url_list = map { "$_/$project" } @git_base_url_list unless @url_list;
6485         foreach my $git_url (@url_list) {
6486                 next unless $git_url;
6487                 print format_repo_url($url_tag, $git_url);
6488                 $url_tag = "";
6489         }
6490
6491         # Tag cloud
6492         my $show_ctags = gitweb_check_feature('ctags');
6493         if ($show_ctags) {
6494                 my $ctags = git_get_project_ctags($project);
6495                 if (%$ctags) {
6496                         # without ability to add tags, don't show if there are none
6497                         my $cloud = git_populate_project_tagcloud($ctags);
6498                         print "<tr id=\"metadata_ctags\">" .
6499                               "<td>content tags</td>" .
6500                               "<td>".git_show_project_tagcloud($cloud, 48)."</td>" .
6501                               "</tr>\n";
6502                 }
6503         }
6504
6505         print "</table>\n";
6506
6507         # If XSS prevention is on, we don't include README.html.
6508         # TODO: Allow a readme in some safe format.
6509         if (!$prevent_xss && -s "$projectroot/$project/README.html") {
6510                 print "<div class=\"title\">readme</div>\n" .
6511                       "<div class=\"readme\">\n";
6512                 insert_file("$projectroot/$project/README.html");
6513                 print "\n</div>\n"; # class="readme"
6514         }
6515
6516         # we need to request one more than 16 (0..15) to check if
6517         # those 16 are all
6518         my @commitlist = $head ? parse_commits($head, 17) : ();
6519         if (@commitlist) {
6520                 git_print_header_div('shortlog');
6521                 git_shortlog_body(\@commitlist, 0, 15, $refs,
6522                                   $#commitlist <=  15 ? undef :
6523                                   $cgi->a({-href => href(action=>"shortlog")}, "..."));
6524         }
6525
6526         if (@taglist) {
6527                 git_print_header_div('tags');
6528                 git_tags_body(\@taglist, 0, 15,
6529                               $#taglist <=  15 ? undef :
6530                               $cgi->a({-href => href(action=>"tags")}, "..."));
6531         }
6532
6533         if (@headlist) {
6534                 git_print_header_div('heads');
6535                 git_heads_body(\@headlist, $head, 0, 15,
6536                                $#headlist <= 15 ? undef :
6537                                $cgi->a({-href => href(action=>"heads")}, "..."));
6538         }
6539
6540         if (%remotedata) {
6541                 git_print_header_div('remotes');
6542                 git_remotes_body(\%remotedata, 15, $head);
6543         }
6544
6545         if (@forklist) {
6546                 git_print_header_div('forks');
6547                 git_project_list_body(\@forklist, 'age', 0, 15,
6548                                       $#forklist <= 15 ? undef :
6549                                       $cgi->a({-href => href(action=>"forks")}, "..."),
6550                                       'no_header');
6551         }
6552
6553         git_footer_html();
6554 }
6555
6556 sub git_tag {
6557         my %tag = parse_tag($hash);
6558
6559         if (! %tag) {
6560                 die_error(404, "Unknown tag object");
6561         }
6562
6563         my $head = git_get_head_hash($project);
6564         git_header_html();
6565         git_print_page_nav('','', $head,undef,$head);
6566         git_print_header_div('commit', esc_html($tag{'name'}), $hash);
6567         print "<div class=\"title_text\">\n" .
6568               "<table class=\"object_header\">\n" .
6569               "<tr>\n" .
6570               "<td>object</td>\n" .
6571               "<td>" . $cgi->a({-class => "list", -href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6572                                $tag{'object'}) . "</td>\n" .
6573               "<td class=\"link\">" . $cgi->a({-href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6574                                               $tag{'type'}) . "</td>\n" .
6575               "</tr>\n";
6576         if (defined($tag{'author'})) {
6577                 git_print_authorship_rows(\%tag, 'author');
6578         }
6579         print "</table>\n\n" .
6580               "</div>\n";
6581         print "<div class=\"page_body\">";
6582         my $comment = $tag{'comment'};
6583         foreach my $line (@$comment) {
6584                 chomp $line;
6585                 print esc_html($line, -nbsp=>1) . "<br/>\n";
6586         }
6587         print "</div>\n";
6588         git_footer_html();
6589 }
6590
6591 sub git_blame_common {
6592         my $format = shift || 'porcelain';
6593         if ($format eq 'porcelain' && $input_params{'javascript'}) {
6594                 $format = 'incremental';
6595                 $action = 'blame_incremental'; # for page title etc
6596         }
6597
6598         # permissions
6599         gitweb_check_feature('blame')
6600                 or die_error(403, "Blame view not allowed");
6601
6602         # error checking
6603         die_error(400, "No file name given") unless $file_name;
6604         $hash_base ||= git_get_head_hash($project);
6605         die_error(404, "Couldn't find base commit") unless $hash_base;
6606         my %co = parse_commit($hash_base)
6607                 or die_error(404, "Commit not found");
6608         my $ftype = "blob";
6609         if (!defined $hash) {
6610                 $hash = git_get_hash_by_path($hash_base, $file_name, "blob")
6611                         or die_error(404, "Error looking up file");
6612         } else {
6613                 $ftype = git_get_type($hash);
6614                 if ($ftype !~ "blob") {
6615                         die_error(400, "Object is not a blob");
6616                 }
6617         }
6618
6619         my $fd;
6620         if ($format eq 'incremental') {
6621                 # get file contents (as base)
6622                 open $fd, "-|", git_cmd(), 'cat-file', 'blob', $hash
6623                         or die_error(500, "Open git-cat-file failed");
6624         } elsif ($format eq 'data') {
6625                 # run git-blame --incremental
6626                 open $fd, "-|", git_cmd(), "blame", "--incremental",
6627                         $hash_base, "--", $file_name
6628                         or die_error(500, "Open git-blame --incremental failed");
6629         } else {
6630                 # run git-blame --porcelain
6631                 open $fd, "-|", git_cmd(), "blame", '-p',
6632                         $hash_base, '--', $file_name
6633                         or die_error(500, "Open git-blame --porcelain failed");
6634         }
6635
6636         # incremental blame data returns early
6637         if ($format eq 'data') {
6638                 print $cgi->header(
6639                         -type=>"text/plain", -charset => "utf-8",
6640                         -status=> "200 OK");
6641                 local $| = 1; # output autoflush
6642                 while (my $line = <$fd>) {
6643                         print to_utf8($line);
6644                 }
6645                 close $fd
6646                         or print "ERROR $!\n";
6647
6648                 print 'END';
6649                 if (defined $t0 && gitweb_check_feature('timed')) {
6650                         print ' '.
6651                               tv_interval($t0, [ gettimeofday() ]).
6652                               ' '.$number_of_git_cmds;
6653                 }
6654                 print "\n";
6655
6656                 return;
6657         }
6658
6659         # page header
6660         git_header_html();
6661         my $formats_nav =
6662                 $cgi->a({-href => href(action=>"blob", -replay=>1)},
6663                         "blob") .
6664                 " | ";
6665         if ($format eq 'incremental') {
6666                 $formats_nav .=
6667                         $cgi->a({-href => href(action=>"blame", javascript=>0, -replay=>1)},
6668                                 "blame") . " (non-incremental)";
6669         } else {
6670                 $formats_nav .=
6671                         $cgi->a({-href => href(action=>"blame_incremental", -replay=>1)},
6672                                 "blame") . " (incremental)";
6673         }
6674         $formats_nav .=
6675                 " | " .
6676                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6677                         "history") .
6678                 " | " .
6679                 $cgi->a({-href => href(action=>$action, file_name=>$file_name)},
6680                         "HEAD");
6681         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6682         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6683         git_print_page_path($file_name, $ftype, $hash_base);
6684
6685         # page body
6686         if ($format eq 'incremental') {
6687                 print "<noscript>\n<div class=\"error\"><center><b>\n".
6688                       "This page requires JavaScript to run.\n Use ".
6689                       $cgi->a({-href => href(action=>'blame',javascript=>0,-replay=>1)},
6690                               'this page').
6691                       " instead.\n".
6692                       "</b></center></div>\n</noscript>\n";
6693
6694                 print qq!<div id="progress_bar" style="width: 100%; background-color: yellow"></div>\n!;
6695         }
6696
6697         print qq!<div class="page_body">\n!;
6698         print qq!<div id="progress_info">... / ...</div>\n!
6699                 if ($format eq 'incremental');
6700         print qq!<table id="blame_table" class="blame" width="100%">\n!.
6701               #qq!<col width="5.5em" /><col width="2.5em" /><col width="*" />\n!.
6702               qq!<thead>\n!.
6703               qq!<tr><th>Commit</th><th>Line</th><th>Data</th></tr>\n!.
6704               qq!</thead>\n!.
6705               qq!<tbody>\n!;
6706
6707         my @rev_color = qw(light dark);
6708         my $num_colors = scalar(@rev_color);
6709         my $current_color = 0;
6710
6711         if ($format eq 'incremental') {
6712                 my $color_class = $rev_color[$current_color];
6713
6714                 #contents of a file
6715                 my $linenr = 0;
6716         LINE:
6717                 while (my $line = <$fd>) {
6718                         chomp $line;
6719                         $linenr++;
6720
6721                         print qq!<tr id="l$linenr" class="$color_class">!.
6722                               qq!<td class="sha1"><a href=""> </a></td>!.
6723                               qq!<td class="linenr">!.
6724                               qq!<a class="linenr" href="">$linenr</a></td>!;
6725                         print qq!<td class="pre">! . esc_html($line) . "</td>\n";
6726                         print qq!</tr>\n!;
6727                 }
6728
6729         } else { # porcelain, i.e. ordinary blame
6730                 my %metainfo = (); # saves information about commits
6731
6732                 # blame data
6733         LINE:
6734                 while (my $line = <$fd>) {
6735                         chomp $line;
6736                         # the header: <SHA-1> <src lineno> <dst lineno> [<lines in group>]
6737                         # no <lines in group> for subsequent lines in group of lines
6738                         my ($full_rev, $orig_lineno, $lineno, $group_size) =
6739                            ($line =~ /^([0-9a-f]{40}) (\d+) (\d+)(?: (\d+))?$/);
6740                         if (!exists $metainfo{$full_rev}) {
6741                                 $metainfo{$full_rev} = { 'nprevious' => 0 };
6742                         }
6743                         my $meta = $metainfo{$full_rev};
6744                         my $data;
6745                         while ($data = <$fd>) {
6746                                 chomp $data;
6747                                 last if ($data =~ s/^\t//); # contents of line
6748                                 if ($data =~ /^(\S+)(?: (.*))?$/) {
6749                                         $meta->{$1} = $2 unless exists $meta->{$1};
6750                                 }
6751                                 if ($data =~ /^previous /) {
6752                                         $meta->{'nprevious'}++;
6753                                 }
6754                         }
6755                         my $short_rev = substr($full_rev, 0, 8);
6756                         my $author = $meta->{'author'};
6757                         my %date =
6758                                 parse_date($meta->{'author-time'}, $meta->{'author-tz'});
6759                         my $date = $date{'iso-tz'};
6760                         if ($group_size) {
6761                                 $current_color = ($current_color + 1) % $num_colors;
6762                         }
6763                         my $tr_class = $rev_color[$current_color];
6764                         $tr_class .= ' boundary' if (exists $meta->{'boundary'});
6765                         $tr_class .= ' no-previous' if ($meta->{'nprevious'} == 0);
6766                         $tr_class .= ' multiple-previous' if ($meta->{'nprevious'} > 1);
6767                         print "<tr id=\"l$lineno\" class=\"$tr_class\">\n";
6768                         if ($group_size) {
6769                                 print "<td class=\"sha1\"";
6770                                 print " title=\"". esc_html($author) . ", $date\"";
6771                                 print " rowspan=\"$group_size\"" if ($group_size > 1);
6772                                 print ">";
6773                                 print $cgi->a({-href => href(action=>"commit",
6774                                                              hash=>$full_rev,
6775                                                              file_name=>$file_name)},
6776                                               esc_html($short_rev));
6777                                 if ($group_size >= 2) {
6778                                         my @author_initials = ($author =~ /\b([[:upper:]])\B/g);
6779                                         if (@author_initials) {
6780                                                 print "<br />" .
6781                                                       esc_html(join('', @author_initials));
6782                                                 #           or join('.', ...)
6783                                         }
6784                                 }
6785                                 print "</td>\n";
6786                         }
6787                         # 'previous' <sha1 of parent commit> <filename at commit>
6788                         if (exists $meta->{'previous'} &&
6789                             $meta->{'previous'} =~ /^([a-fA-F0-9]{40}) (.*)$/) {
6790                                 $meta->{'parent'} = $1;
6791                                 $meta->{'file_parent'} = unquote($2);
6792                         }
6793                         my $linenr_commit =
6794                                 exists($meta->{'parent'}) ?
6795                                 $meta->{'parent'} : $full_rev;
6796                         my $linenr_filename =
6797                                 exists($meta->{'file_parent'}) ?
6798                                 $meta->{'file_parent'} : unquote($meta->{'filename'});
6799                         my $blamed = href(action => 'blame',
6800                                           file_name => $linenr_filename,
6801                                           hash_base => $linenr_commit);
6802                         print "<td class=\"linenr\">";
6803                         print $cgi->a({ -href => "$blamed#l$orig_lineno",
6804                                         -class => "linenr" },
6805                                       esc_html($lineno));
6806                         print "</td>";
6807                         print "<td class=\"pre\">" . esc_html($data) . "</td>\n";
6808                         print "</tr>\n";
6809                 } # end while
6810
6811         }
6812
6813         # footer
6814         print "</tbody>\n".
6815               "</table>\n"; # class="blame"
6816         print "</div>\n";   # class="blame_body"
6817         close $fd
6818                 or print "Reading blob failed\n";
6819
6820         git_footer_html();
6821 }
6822
6823 sub git_blame {
6824         git_blame_common();
6825 }
6826
6827 sub git_blame_incremental {
6828         git_blame_common('incremental');
6829 }
6830
6831 sub git_blame_data {
6832         git_blame_common('data');
6833 }
6834
6835 sub git_tags {
6836         my $head = git_get_head_hash($project);
6837         git_header_html();
6838         git_print_page_nav('','', $head,undef,$head,format_ref_views('tags'));
6839         git_print_header_div('summary', $project);
6840
6841         my @tagslist = git_get_tags_list();
6842         if (@tagslist) {
6843                 git_tags_body(\@tagslist);
6844         }
6845         git_footer_html();
6846 }
6847
6848 sub git_heads {
6849         my $head = git_get_head_hash($project);
6850         git_header_html();
6851         git_print_page_nav('','', $head,undef,$head,format_ref_views('heads'));
6852         git_print_header_div('summary', $project);
6853
6854         my @headslist = git_get_heads_list();
6855         if (@headslist) {
6856                 git_heads_body(\@headslist, $head);
6857         }
6858         git_footer_html();
6859 }
6860
6861 # used both for single remote view and for list of all the remotes
6862 sub git_remotes {
6863         gitweb_check_feature('remote_heads')
6864                 or die_error(403, "Remote heads view is disabled");
6865
6866         my $head = git_get_head_hash($project);
6867         my $remote = $input_params{'hash'};
6868
6869         my $remotedata = git_get_remotes_list($remote);
6870         die_error(500, "Unable to get remote information") unless defined $remotedata;
6871
6872         unless (%$remotedata) {
6873                 die_error(404, defined $remote ?
6874                         "Remote $remote not found" :
6875                         "No remotes found");
6876         }
6877
6878         git_header_html(undef, undef, -action_extra => $remote);
6879         git_print_page_nav('', '',  $head, undef, $head,
6880                 format_ref_views($remote ? '' : 'remotes'));
6881
6882         fill_remote_heads($remotedata);
6883         if (defined $remote) {
6884                 git_print_header_div('remotes', "$remote remote for $project");
6885                 git_remote_block($remote, $remotedata->{$remote}, undef, $head);
6886         } else {
6887                 git_print_header_div('summary', "$project remotes");
6888                 git_remotes_body($remotedata, undef, $head);
6889         }
6890
6891         git_footer_html();
6892 }
6893
6894 sub git_blob_plain {
6895         my $type = shift;
6896         my $expires;
6897
6898         if (!defined $hash) {
6899                 if (defined $file_name) {
6900                         my $base = $hash_base || git_get_head_hash($project);
6901                         $hash = git_get_hash_by_path($base, $file_name, "blob")
6902                                 or die_error(404, "Cannot find file");
6903                 } else {
6904                         die_error(400, "No file name defined");
6905                 }
6906         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6907                 # blobs defined by non-textual hash id's can be cached
6908                 $expires = "+1d";
6909         }
6910
6911         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
6912                 or die_error(500, "Open git-cat-file blob '$hash' failed");
6913
6914         # content-type (can include charset)
6915         $type = blob_contenttype($fd, $file_name, $type);
6916
6917         # "save as" filename, even when no $file_name is given
6918         my $save_as = "$hash";
6919         if (defined $file_name) {
6920                 $save_as = $file_name;
6921         } elsif ($type =~ m/^text\//) {
6922                 $save_as .= '.txt';
6923         }
6924
6925         # With XSS prevention on, blobs of all types except a few known safe
6926         # ones are served with "Content-Disposition: attachment" to make sure
6927         # they don't run in our security domain.  For certain image types,
6928         # blob view writes an <img> tag referring to blob_plain view, and we
6929         # want to be sure not to break that by serving the image as an
6930         # attachment (though Firefox 3 doesn't seem to care).
6931         my $sandbox = $prevent_xss &&
6932                 $type !~ m!^(?:text/[a-z]+|image/(?:gif|png|jpeg))(?:[ ;]|$)!;
6933
6934         # serve text/* as text/plain
6935         if ($prevent_xss &&
6936             ($type =~ m!^text/[a-z]+\b(.*)$! ||
6937              ($type =~ m!^[a-z]+/[a-z]\+xml\b(.*)$! && -T $fd))) {
6938                 my $rest = $1;
6939                 $rest = defined $rest ? $rest : '';
6940                 $type = "text/plain$rest";
6941         }
6942
6943         print $cgi->header(
6944                 -type => $type,
6945                 -expires => $expires,
6946                 -content_disposition =>
6947                         ($sandbox ? 'attachment' : 'inline')
6948                         . '; filename="' . $save_as . '"');
6949         local $/ = undef;
6950         binmode STDOUT, ':raw';
6951         print <$fd>;
6952         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
6953         close $fd;
6954 }
6955
6956 sub git_blob {
6957         my $expires;
6958
6959         if (!defined $hash) {
6960                 if (defined $file_name) {
6961                         my $base = $hash_base || git_get_head_hash($project);
6962                         $hash = git_get_hash_by_path($base, $file_name, "blob")
6963                                 or die_error(404, "Cannot find file");
6964                 } else {
6965                         die_error(400, "No file name defined");
6966                 }
6967         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6968                 # blobs defined by non-textual hash id's can be cached
6969                 $expires = "+1d";
6970         }
6971
6972         my $have_blame = gitweb_check_feature('blame');
6973         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
6974                 or die_error(500, "Couldn't cat $file_name, $hash");
6975         my $mimetype = blob_mimetype($fd, $file_name);
6976         # use 'blob_plain' (aka 'raw') view for files that cannot be displayed
6977         if ($mimetype !~ m!^(?:text/|image/(?:gif|png|jpeg)$)! && -B $fd) {
6978                 close $fd;
6979                 return git_blob_plain($mimetype);
6980         }
6981         # we can have blame only for text/* mimetype
6982         $have_blame &&= ($mimetype =~ m!^text/!);
6983
6984         my $highlight = gitweb_check_feature('highlight');
6985         my $syntax = guess_file_syntax($highlight, $mimetype, $file_name);
6986         $fd = run_highlighter($fd, $highlight, $syntax)
6987                 if $syntax;
6988
6989         git_header_html(undef, $expires);
6990         my $formats_nav = '';
6991         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
6992                 if (defined $file_name) {
6993                         if ($have_blame) {
6994                                 $formats_nav .=
6995                                         $cgi->a({-href => href(action=>"blame", -replay=>1)},
6996                                                 "blame") .
6997                                         " | ";
6998                         }
6999                         $formats_nav .=
7000                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
7001                                         "history") .
7002                                 " | " .
7003                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
7004                                         "raw") .
7005                                 " | " .
7006                                 $cgi->a({-href => href(action=>"blob",
7007                                                        hash_base=>"HEAD", file_name=>$file_name)},
7008                                         "HEAD");
7009                 } else {
7010                         $formats_nav .=
7011                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
7012                                         "raw");
7013                 }
7014                 git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
7015                 git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
7016         } else {
7017                 print "<div class=\"page_nav\">\n" .
7018                       "<br/><br/></div>\n" .
7019                       "<div class=\"title\">".esc_html($hash)."</div>\n";
7020         }
7021         git_print_page_path($file_name, "blob", $hash_base);
7022         print "<div class=\"page_body\">\n";
7023         if ($mimetype =~ m!^image/!) {
7024                 print qq!<img type="!.esc_attr($mimetype).qq!"!;
7025                 if ($file_name) {
7026                         print qq! alt="!.esc_attr($file_name).qq!" title="!.esc_attr($file_name).qq!"!;
7027                 }
7028                 print qq! src="! .
7029                       href(action=>"blob_plain", hash=>$hash,
7030                            hash_base=>$hash_base, file_name=>$file_name) .
7031                       qq!" />\n!;
7032         } else {
7033                 my $nr;
7034                 while (my $line = <$fd>) {
7035                         chomp $line;
7036                         $nr++;
7037                         $line = untabify($line);
7038                         printf qq!<div class="pre"><a id="l%i" href="%s#l%i" class="linenr">%4i</a> %s</div>\n!,
7039                                $nr, esc_attr(href(-replay => 1)), $nr, $nr,
7040                                $syntax ? sanitize($line) : esc_html($line, -nbsp=>1);
7041                 }
7042         }
7043         close $fd
7044                 or print "Reading blob failed.\n";
7045         print "</div>";
7046         git_footer_html();
7047 }
7048
7049 sub git_tree {
7050         if (!defined $hash_base) {
7051                 $hash_base = "HEAD";
7052         }
7053         if (!defined $hash) {
7054                 if (defined $file_name) {
7055                         $hash = git_get_hash_by_path($hash_base, $file_name, "tree");
7056                 } else {
7057                         $hash = $hash_base;
7058                 }
7059         }
7060         die_error(404, "No such tree") unless defined($hash);
7061
7062         my $show_sizes = gitweb_check_feature('show-sizes');
7063         my $have_blame = gitweb_check_feature('blame');
7064
7065         my @entries = ();
7066         {
7067                 local $/ = "\0";
7068                 open my $fd, "-|", git_cmd(), "ls-tree", '-z',
7069                         ($show_sizes ? '-l' : ()), @extra_options, $hash
7070                         or die_error(500, "Open git-ls-tree failed");
7071                 @entries = map { chomp; $_ } <$fd>;
7072                 close $fd
7073                         or die_error(404, "Reading tree failed");
7074         }
7075
7076         my $refs = git_get_references();
7077         my $ref = format_ref_marker($refs, $hash_base);
7078         git_header_html();
7079         my $basedir = '';
7080         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7081                 my @views_nav = ();
7082                 if (defined $file_name) {
7083                         push @views_nav,
7084                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
7085                                         "history"),
7086                                 $cgi->a({-href => href(action=>"tree",
7087                                                        hash_base=>"HEAD", file_name=>$file_name)},
7088                                         "HEAD"),
7089                 }
7090                 my $snapshot_links = format_snapshot_links($hash);
7091                 if (defined $snapshot_links) {
7092                         # FIXME: Should be available when we have no hash base as well.
7093                         push @views_nav, $snapshot_links;
7094                 }
7095                 git_print_page_nav('tree','', $hash_base, undef, undef,
7096                                    join(' | ', @views_nav));
7097                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash_base);
7098         } else {
7099                 undef $hash_base;
7100                 print "<div class=\"page_nav\">\n";
7101                 print "<br/><br/></div>\n";
7102                 print "<div class=\"title\">".esc_html($hash)."</div>\n";
7103         }
7104         if (defined $file_name) {
7105                 $basedir = $file_name;
7106                 if ($basedir ne '' && substr($basedir, -1) ne '/') {
7107                         $basedir .= '/';
7108                 }
7109                 git_print_page_path($file_name, 'tree', $hash_base);
7110         }
7111         print "<div class=\"page_body\">\n";
7112         print "<table class=\"tree\">\n";
7113         my $alternate = 1;
7114         # '..' (top directory) link if possible
7115         if (defined $hash_base &&
7116             defined $file_name && $file_name =~ m![^/]+$!) {
7117                 if ($alternate) {
7118                         print "<tr class=\"dark\">\n";
7119                 } else {
7120                         print "<tr class=\"light\">\n";
7121                 }
7122                 $alternate ^= 1;
7123
7124                 my $up = $file_name;
7125                 $up =~ s!/?[^/]+$!!;
7126                 undef $up unless $up;
7127                 # based on git_print_tree_entry
7128                 print '<td class="mode">' . mode_str('040000') . "</td>\n";
7129                 print '<td class="size">&nbsp;</td>'."\n" if $show_sizes;
7130                 print '<td class="list">';
7131                 print $cgi->a({-href => href(action=>"tree",
7132                                              hash_base=>$hash_base,
7133                                              file_name=>$up)},
7134                               "..");
7135                 print "</td>\n";
7136                 print "<td class=\"link\"></td>\n";
7137
7138                 print "</tr>\n";
7139         }
7140         foreach my $line (@entries) {
7141                 my %t = parse_ls_tree_line($line, -z => 1, -l => $show_sizes);
7142
7143                 if ($alternate) {
7144                         print "<tr class=\"dark\">\n";
7145                 } else {
7146                         print "<tr class=\"light\">\n";
7147                 }
7148                 $alternate ^= 1;
7149
7150                 git_print_tree_entry(\%t, $basedir, $hash_base, $have_blame);
7151
7152                 print "</tr>\n";
7153         }
7154         print "</table>\n" .
7155               "</div>";
7156         git_footer_html();
7157 }
7158
7159 sub snapshot_name {
7160         my ($project, $hash) = @_;
7161
7162         # path/to/project.git  -> project
7163         # path/to/project/.git -> project
7164         my $name = to_utf8($project);
7165         $name =~ s,([^/])/*\.git$,$1,;
7166         $name = basename($name);
7167         # sanitize name
7168         $name =~ s/[[:cntrl:]]/?/g;
7169
7170         my $ver = $hash;
7171         if ($hash =~ /^[0-9a-fA-F]+$/) {
7172                 # shorten SHA-1 hash
7173                 my $full_hash = git_get_full_hash($project, $hash);
7174                 if ($full_hash =~ /^$hash/ && length($hash) > 7) {
7175                         $ver = git_get_short_hash($project, $hash);
7176                 }
7177         } elsif ($hash =~ m!^refs/tags/(.*)$!) {
7178                 # tags don't need shortened SHA-1 hash
7179                 $ver = $1;
7180         } else {
7181                 # branches and other need shortened SHA-1 hash
7182                 if ($hash =~ m!^refs/(?:heads|remotes)/(.*)$!) {
7183                         $ver = $1;
7184                 }
7185                 $ver .= '-' . git_get_short_hash($project, $hash);
7186         }
7187         # in case of hierarchical branch names
7188         $ver =~ s!/!.!g;
7189
7190         # name = project-version_string
7191         $name = "$name-$ver";
7192
7193         return wantarray ? ($name, $name) : $name;
7194 }
7195
7196 sub exit_if_unmodified_since {
7197         my ($latest_epoch) = @_;
7198         our $cgi;
7199
7200         my $if_modified = $cgi->http('IF_MODIFIED_SINCE');
7201         if (defined $if_modified) {
7202                 my $since;
7203                 if (eval { require HTTP::Date; 1; }) {
7204                         $since = HTTP::Date::str2time($if_modified);
7205                 } elsif (eval { require Time::ParseDate; 1; }) {
7206                         $since = Time::ParseDate::parsedate($if_modified, GMT => 1);
7207                 }
7208                 if (defined $since && $latest_epoch <= $since) {
7209                         my %latest_date = parse_date($latest_epoch);
7210                         print $cgi->header(
7211                                 -last_modified => $latest_date{'rfc2822'},
7212                                 -status => '304 Not Modified');
7213                         goto DONE_GITWEB;
7214                 }
7215         }
7216 }
7217
7218 sub git_snapshot {
7219         my $format = $input_params{'snapshot_format'};
7220         if (!@snapshot_fmts) {
7221                 die_error(403, "Snapshots not allowed");
7222         }
7223         # default to first supported snapshot format
7224         $format ||= $snapshot_fmts[0];
7225         if ($format !~ m/^[a-z0-9]+$/) {
7226                 die_error(400, "Invalid snapshot format parameter");
7227         } elsif (!exists($known_snapshot_formats{$format})) {
7228                 die_error(400, "Unknown snapshot format");
7229         } elsif ($known_snapshot_formats{$format}{'disabled'}) {
7230                 die_error(403, "Snapshot format not allowed");
7231         } elsif (!grep($_ eq $format, @snapshot_fmts)) {
7232                 die_error(403, "Unsupported snapshot format");
7233         }
7234
7235         my $type = git_get_type("$hash^{}");
7236         if (!$type) {
7237                 die_error(404, 'Object does not exist');
7238         }  elsif ($type eq 'blob') {
7239                 die_error(400, 'Object is not a tree-ish');
7240         }
7241
7242         my ($name, $prefix) = snapshot_name($project, $hash);
7243         my $filename = "$name$known_snapshot_formats{$format}{'suffix'}";
7244
7245         my %co = parse_commit($hash);
7246         exit_if_unmodified_since($co{'committer_epoch'}) if %co;
7247
7248         my $cmd = quote_command(
7249                 git_cmd(), 'archive',
7250                 "--format=$known_snapshot_formats{$format}{'format'}",
7251                 "--prefix=$prefix/", $hash);
7252         if (exists $known_snapshot_formats{$format}{'compressor'}) {
7253                 $cmd .= ' | ' . quote_command(@{$known_snapshot_formats{$format}{'compressor'}});
7254         }
7255
7256         $filename =~ s/(["\\])/\\$1/g;
7257         my %latest_date;
7258         if (%co) {
7259                 %latest_date = parse_date($co{'committer_epoch'}, $co{'committer_tz'});
7260         }
7261
7262         print $cgi->header(
7263                 -type => $known_snapshot_formats{$format}{'type'},
7264                 -content_disposition => 'inline; filename="' . $filename . '"',
7265                 %co ? (-last_modified => $latest_date{'rfc2822'}) : (),
7266                 -status => '200 OK');
7267
7268         open my $fd, "-|", $cmd
7269                 or die_error(500, "Execute git-archive failed");
7270         binmode STDOUT, ':raw';
7271         print <$fd>;
7272         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
7273         close $fd;
7274 }
7275
7276 sub git_log_generic {
7277         my ($fmt_name, $body_subr, $base, $parent, $file_name, $file_hash) = @_;
7278
7279         my $head = git_get_head_hash($project);
7280         if (!defined $base) {
7281                 $base = $head;
7282         }
7283         if (!defined $page) {
7284                 $page = 0;
7285         }
7286         my $refs = git_get_references();
7287
7288         my $commit_hash = $base;
7289         if (defined $parent) {
7290                 $commit_hash = "$parent..$base";
7291         }
7292         my @commitlist =
7293                 parse_commits($commit_hash, 101, (100 * $page),
7294                               defined $file_name ? ($file_name, "--full-history") : ());
7295
7296         my $ftype;
7297         if (!defined $file_hash && defined $file_name) {
7298                 # some commits could have deleted file in question,
7299                 # and not have it in tree, but one of them has to have it
7300                 for (my $i = 0; $i < @commitlist; $i++) {
7301                         $file_hash = git_get_hash_by_path($commitlist[$i]{'id'}, $file_name);
7302                         last if defined $file_hash;
7303                 }
7304         }
7305         if (defined $file_hash) {
7306                 $ftype = git_get_type($file_hash);
7307         }
7308         if (defined $file_name && !defined $ftype) {
7309                 die_error(500, "Unknown type of object");
7310         }
7311         my %co;
7312         if (defined $file_name) {
7313                 %co = parse_commit($base)
7314                         or die_error(404, "Unknown commit object");
7315         }
7316
7317
7318         my $paging_nav = format_paging_nav($fmt_name, $page, $#commitlist >= 100);
7319         my $next_link = '';
7320         if ($#commitlist >= 100) {
7321                 $next_link =
7322                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
7323                                  -accesskey => "n", -title => "Alt-n"}, "next");
7324         }
7325         my $patch_max = gitweb_get_feature('patches');
7326         if ($patch_max && !defined $file_name) {
7327                 if ($patch_max < 0 || @commitlist <= $patch_max) {
7328                         $paging_nav .= " &sdot; " .
7329                                 $cgi->a({-href => href(action=>"patches", -replay=>1)},
7330                                         "patches");
7331                 }
7332         }
7333
7334         git_header_html();
7335         git_print_page_nav($fmt_name,'', $hash,$hash,$hash, $paging_nav);
7336         if (defined $file_name) {
7337                 git_print_header_div('commit', esc_html($co{'title'}), $base);
7338         } else {
7339                 git_print_header_div('summary', $project)
7340         }
7341         git_print_page_path($file_name, $ftype, $hash_base)
7342                 if (defined $file_name);
7343
7344         $body_subr->(\@commitlist, 0, 99, $refs, $next_link,
7345                      $file_name, $file_hash, $ftype);
7346
7347         git_footer_html();
7348 }
7349
7350 sub git_log {
7351         git_log_generic('log', \&git_log_body,
7352                         $hash, $hash_parent);
7353 }
7354
7355 sub git_commit {
7356         $hash ||= $hash_base || "HEAD";
7357         my %co = parse_commit($hash)
7358             or die_error(404, "Unknown commit object");
7359
7360         my $parent  = $co{'parent'};
7361         my $parents = $co{'parents'}; # listref
7362
7363         # we need to prepare $formats_nav before any parameter munging
7364         my $formats_nav;
7365         if (!defined $parent) {
7366                 # --root commitdiff
7367                 $formats_nav .= '(initial)';
7368         } elsif (@$parents == 1) {
7369                 # single parent commit
7370                 $formats_nav .=
7371                         '(parent: ' .
7372                         $cgi->a({-href => href(action=>"commit",
7373                                                hash=>$parent)},
7374                                 esc_html(substr($parent, 0, 7))) .
7375                         ')';
7376         } else {
7377                 # merge commit
7378                 $formats_nav .=
7379                         '(merge: ' .
7380                         join(' ', map {
7381                                 $cgi->a({-href => href(action=>"commit",
7382                                                        hash=>$_)},
7383                                         esc_html(substr($_, 0, 7)));
7384                         } @$parents ) .
7385                         ')';
7386         }
7387         if (gitweb_check_feature('patches') && @$parents <= 1) {
7388                 $formats_nav .= " | " .
7389                         $cgi->a({-href => href(action=>"patch", -replay=>1)},
7390                                 "patch");
7391         }
7392
7393         if (!defined $parent) {
7394                 $parent = "--root";
7395         }
7396         my @difftree;
7397         open my $fd, "-|", git_cmd(), "diff-tree", '-r', "--no-commit-id",
7398                 @diff_opts,
7399                 (@$parents <= 1 ? $parent : '-c'),
7400                 $hash, "--"
7401                 or die_error(500, "Open git-diff-tree failed");
7402         @difftree = map { chomp; $_ } <$fd>;
7403         close $fd or die_error(404, "Reading git-diff-tree failed");
7404
7405         # non-textual hash id's can be cached
7406         my $expires;
7407         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7408                 $expires = "+1d";
7409         }
7410         my $refs = git_get_references();
7411         my $ref = format_ref_marker($refs, $co{'id'});
7412
7413         git_header_html(undef, $expires);
7414         git_print_page_nav('commit', '',
7415                            $hash, $co{'tree'}, $hash,
7416                            $formats_nav);
7417
7418         if (defined $co{'parent'}) {
7419                 git_print_header_div('commitdiff', esc_html($co{'title'}) . $ref, $hash);
7420         } else {
7421                 git_print_header_div('tree', esc_html($co{'title'}) . $ref, $co{'tree'}, $hash);
7422         }
7423         print "<div class=\"title_text\">\n" .
7424               "<table class=\"object_header\">\n";
7425         git_print_authorship_rows(\%co);
7426         print "<tr><td>commit</td><td class=\"sha1\">$co{'id'}</td></tr>\n";
7427         print "<tr>" .
7428               "<td>tree</td>" .
7429               "<td class=\"sha1\">" .
7430               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash),
7431                        class => "list"}, $co{'tree'}) .
7432               "</td>" .
7433               "<td class=\"link\">" .
7434               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash)},
7435                       "tree");
7436         my $snapshot_links = format_snapshot_links($hash);
7437         if (defined $snapshot_links) {
7438                 print " | " . $snapshot_links;
7439         }
7440         print "</td>" .
7441               "</tr>\n";
7442
7443         foreach my $par (@$parents) {
7444                 print "<tr>" .
7445                       "<td>parent</td>" .
7446                       "<td class=\"sha1\">" .
7447                       $cgi->a({-href => href(action=>"commit", hash=>$par),
7448                                class => "list"}, $par) .
7449                       "</td>" .
7450                       "<td class=\"link\">" .
7451                       $cgi->a({-href => href(action=>"commit", hash=>$par)}, "commit") .
7452                       " | " .
7453                       $cgi->a({-href => href(action=>"commitdiff", hash=>$hash, hash_parent=>$par)}, "diff") .
7454                       "</td>" .
7455                       "</tr>\n";
7456         }
7457         print "</table>".
7458               "</div>\n";
7459
7460         print "<div class=\"page_body\">\n";
7461         git_print_log($co{'comment'});
7462         print "</div>\n";
7463
7464         git_difftree_body(\@difftree, $hash, @$parents);
7465
7466         git_footer_html();
7467 }
7468
7469 sub git_object {
7470         # object is defined by:
7471         # - hash or hash_base alone
7472         # - hash_base and file_name
7473         my $type;
7474
7475         # - hash or hash_base alone
7476         if ($hash || ($hash_base && !defined $file_name)) {
7477                 my $object_id = $hash || $hash_base;
7478
7479                 open my $fd, "-|", quote_command(
7480                         git_cmd(), 'cat-file', '-t', $object_id) . ' 2> /dev/null'
7481                         or die_error(404, "Object does not exist");
7482                 $type = <$fd>;
7483                 chomp $type;
7484                 close $fd
7485                         or die_error(404, "Object does not exist");
7486
7487         # - hash_base and file_name
7488         } elsif ($hash_base && defined $file_name) {
7489                 $file_name =~ s,/+$,,;
7490
7491                 system(git_cmd(), "cat-file", '-e', $hash_base) == 0
7492                         or die_error(404, "Base object does not exist");
7493
7494                 # here errors should not happen
7495                 open my $fd, "-|", git_cmd(), "ls-tree", $hash_base, "--", $file_name
7496                         or die_error(500, "Open git-ls-tree failed");
7497                 my $line = <$fd>;
7498                 close $fd;
7499
7500                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
7501                 unless ($line && $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/) {
7502                         die_error(404, "File or directory for given base does not exist");
7503                 }
7504                 $type = $2;
7505                 $hash = $3;
7506         } else {
7507                 die_error(400, "Not enough information to find object");
7508         }
7509
7510         print $cgi->redirect(-uri => href(action=>$type, -full=>1,
7511                                           hash=>$hash, hash_base=>$hash_base,
7512                                           file_name=>$file_name),
7513                              -status => '302 Found');
7514 }
7515
7516 sub git_blobdiff {
7517         my $format = shift || 'html';
7518         my $diff_style = $input_params{'diff_style'} || 'inline';
7519
7520         my $fd;
7521         my @difftree;
7522         my %diffinfo;
7523         my $expires;
7524
7525         # preparing $fd and %diffinfo for git_patchset_body
7526         # new style URI
7527         if (defined $hash_base && defined $hash_parent_base) {
7528                 if (defined $file_name) {
7529                         # read raw output
7530                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7531                                 $hash_parent_base, $hash_base,
7532                                 "--", (defined $file_parent ? $file_parent : ()), $file_name
7533                                 or die_error(500, "Open git-diff-tree failed");
7534                         @difftree = map { chomp; $_ } <$fd>;
7535                         close $fd
7536                                 or die_error(404, "Reading git-diff-tree failed");
7537                         @difftree
7538                                 or die_error(404, "Blob diff not found");
7539
7540                 } elsif (defined $hash &&
7541                          $hash =~ /[0-9a-fA-F]{40}/) {
7542                         # try to find filename from $hash
7543
7544                         # read filtered raw output
7545                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7546                                 $hash_parent_base, $hash_base, "--"
7547                                 or die_error(500, "Open git-diff-tree failed");
7548                         @difftree =
7549                                 # ':100644 100644 03b21826... 3b93d5e7... M     ls-files.c'
7550                                 # $hash == to_id
7551                                 grep { /^:[0-7]{6} [0-7]{6} [0-9a-fA-F]{40} $hash/ }
7552                                 map { chomp; $_ } <$fd>;
7553                         close $fd
7554                                 or die_error(404, "Reading git-diff-tree failed");
7555                         @difftree
7556                                 or die_error(404, "Blob diff not found");
7557
7558                 } else {
7559                         die_error(400, "Missing one of the blob diff parameters");
7560                 }
7561
7562                 if (@difftree > 1) {
7563                         die_error(400, "Ambiguous blob diff specification");
7564                 }
7565
7566                 %diffinfo = parse_difftree_raw_line($difftree[0]);
7567                 $file_parent ||= $diffinfo{'from_file'} || $file_name;
7568                 $file_name   ||= $diffinfo{'to_file'};
7569
7570                 $hash_parent ||= $diffinfo{'from_id'};
7571                 $hash        ||= $diffinfo{'to_id'};
7572
7573                 # non-textual hash id's can be cached
7574                 if ($hash_base =~ m/^[0-9a-fA-F]{40}$/ &&
7575                     $hash_parent_base =~ m/^[0-9a-fA-F]{40}$/) {
7576                         $expires = '+1d';
7577                 }
7578
7579                 # open patch output
7580                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7581                         '-p', ($format eq 'html' ? "--full-index" : ()),
7582                         $hash_parent_base, $hash_base,
7583                         "--", (defined $file_parent ? $file_parent : ()), $file_name
7584                         or die_error(500, "Open git-diff-tree failed");
7585         }
7586
7587         # old/legacy style URI -- not generated anymore since 1.4.3.
7588         if (!%diffinfo) {
7589                 die_error('404 Not Found', "Missing one of the blob diff parameters")
7590         }
7591
7592         # header
7593         if ($format eq 'html') {
7594                 my $formats_nav =
7595                         $cgi->a({-href => href(action=>"blobdiff_plain", -replay=>1)},
7596                                 "raw");
7597                 $formats_nav .= diff_style_nav($diff_style);
7598                 git_header_html(undef, $expires);
7599                 if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7600                         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
7601                         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
7602                 } else {
7603                         print "<div class=\"page_nav\"><br/>$formats_nav<br/></div>\n";
7604                         print "<div class=\"title\">".esc_html("$hash vs $hash_parent")."</div>\n";
7605                 }
7606                 if (defined $file_name) {
7607                         git_print_page_path($file_name, "blob", $hash_base);
7608                 } else {
7609                         print "<div class=\"page_path\"></div>\n";
7610                 }
7611
7612         } elsif ($format eq 'plain') {
7613                 print $cgi->header(
7614                         -type => 'text/plain',
7615                         -charset => 'utf-8',
7616                         -expires => $expires,
7617                         -content_disposition => 'inline; filename="' . "$file_name" . '.patch"');
7618
7619                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7620
7621         } else {
7622                 die_error(400, "Unknown blobdiff format");
7623         }
7624
7625         # patch
7626         if ($format eq 'html') {
7627                 print "<div class=\"page_body\">\n";
7628
7629                 git_patchset_body($fd, $diff_style,
7630                                   [ \%diffinfo ], $hash_base, $hash_parent_base);
7631                 close $fd;
7632
7633                 print "</div>\n"; # class="page_body"
7634                 git_footer_html();
7635
7636         } else {
7637                 while (my $line = <$fd>) {
7638                         $line =~ s!a/($hash|$hash_parent)!'a/'.esc_path($diffinfo{'from_file'})!eg;
7639                         $line =~ s!b/($hash|$hash_parent)!'b/'.esc_path($diffinfo{'to_file'})!eg;
7640
7641                         print $line;
7642
7643                         last if $line =~ m!^\+\+\+!;
7644                 }
7645                 local $/ = undef;
7646                 print <$fd>;
7647                 close $fd;
7648         }
7649 }
7650
7651 sub git_blobdiff_plain {
7652         git_blobdiff('plain');
7653 }
7654
7655 # assumes that it is added as later part of already existing navigation,
7656 # so it returns "| foo | bar" rather than just "foo | bar"
7657 sub diff_style_nav {
7658         my ($diff_style, $is_combined) = @_;
7659         $diff_style ||= 'inline';
7660
7661         return "" if ($is_combined);
7662
7663         my @styles = (inline => 'inline', 'sidebyside' => 'side by side');
7664         my %styles = @styles;
7665         @styles =
7666                 @styles[ map { $_ * 2 } 0..$#styles/2 ];
7667
7668         return join '',
7669                 map { " | ".$_ }
7670                 map {
7671                         $_ eq $diff_style ? $styles{$_} :
7672                         $cgi->a({-href => href(-replay=>1, diff_style => $_)}, $styles{$_})
7673                 } @styles;
7674 }
7675
7676 sub git_commitdiff {
7677         my %params = @_;
7678         my $format = $params{-format} || 'html';
7679         my $diff_style = $input_params{'diff_style'} || 'inline';
7680
7681         my ($patch_max) = gitweb_get_feature('patches');
7682         if ($format eq 'patch') {
7683                 die_error(403, "Patch view not allowed") unless $patch_max;
7684         }
7685
7686         $hash ||= $hash_base || "HEAD";
7687         my %co = parse_commit($hash)
7688             or die_error(404, "Unknown commit object");
7689
7690         # choose format for commitdiff for merge
7691         if (! defined $hash_parent && @{$co{'parents'}} > 1) {
7692                 $hash_parent = '--cc';
7693         }
7694         # we need to prepare $formats_nav before almost any parameter munging
7695         my $formats_nav;
7696         if ($format eq 'html') {
7697                 $formats_nav =
7698                         $cgi->a({-href => href(action=>"commitdiff_plain", -replay=>1)},
7699                                 "raw");
7700                 if ($patch_max && @{$co{'parents'}} <= 1) {
7701                         $formats_nav .= " | " .
7702                                 $cgi->a({-href => href(action=>"patch", -replay=>1)},
7703                                         "patch");
7704                 }
7705                 $formats_nav .= diff_style_nav($diff_style, @{$co{'parents'}} > 1);
7706
7707                 if (defined $hash_parent &&
7708                     $hash_parent ne '-c' && $hash_parent ne '--cc') {
7709                         # commitdiff with two commits given
7710                         my $hash_parent_short = $hash_parent;
7711                         if ($hash_parent =~ m/^[0-9a-fA-F]{40}$/) {
7712                                 $hash_parent_short = substr($hash_parent, 0, 7);
7713                         }
7714                         $formats_nav .=
7715                                 ' (from';
7716                         for (my $i = 0; $i < @{$co{'parents'}}; $i++) {
7717                                 if ($co{'parents'}[$i] eq $hash_parent) {
7718                                         $formats_nav .= ' parent ' . ($i+1);
7719                                         last;
7720                                 }
7721                         }
7722                         $formats_nav .= ': ' .
7723                                 $cgi->a({-href => href(-replay=>1,
7724                                                        hash=>$hash_parent, hash_base=>undef)},
7725                                         esc_html($hash_parent_short)) .
7726                                 ')';
7727                 } elsif (!$co{'parent'}) {
7728                         # --root commitdiff
7729                         $formats_nav .= ' (initial)';
7730                 } elsif (scalar @{$co{'parents'}} == 1) {
7731                         # single parent commit
7732                         $formats_nav .=
7733                                 ' (parent: ' .
7734                                 $cgi->a({-href => href(-replay=>1,
7735                                                        hash=>$co{'parent'}, hash_base=>undef)},
7736                                         esc_html(substr($co{'parent'}, 0, 7))) .
7737                                 ')';
7738                 } else {
7739                         # merge commit
7740                         if ($hash_parent eq '--cc') {
7741                                 $formats_nav .= ' | ' .
7742                                         $cgi->a({-href => href(-replay=>1,
7743                                                                hash=>$hash, hash_parent=>'-c')},
7744                                                 'combined');
7745                         } else { # $hash_parent eq '-c'
7746                                 $formats_nav .= ' | ' .
7747                                         $cgi->a({-href => href(-replay=>1,
7748                                                                hash=>$hash, hash_parent=>'--cc')},
7749                                                 'compact');
7750                         }
7751                         $formats_nav .=
7752                                 ' (merge: ' .
7753                                 join(' ', map {
7754                                         $cgi->a({-href => href(-replay=>1,
7755                                                                hash=>$_, hash_base=>undef)},
7756                                                 esc_html(substr($_, 0, 7)));
7757                                 } @{$co{'parents'}} ) .
7758                                 ')';
7759                 }
7760         }
7761
7762         my $hash_parent_param = $hash_parent;
7763         if (!defined $hash_parent_param) {
7764                 # --cc for multiple parents, --root for parentless
7765                 $hash_parent_param =
7766                         @{$co{'parents'}} > 1 ? '--cc' : $co{'parent'} || '--root';
7767         }
7768
7769         # read commitdiff
7770         my $fd;
7771         my @difftree;
7772         if ($format eq 'html') {
7773                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7774                         "--no-commit-id", "--patch-with-raw", "--full-index",
7775                         $hash_parent_param, $hash, "--"
7776                         or die_error(500, "Open git-diff-tree failed");
7777
7778                 while (my $line = <$fd>) {
7779                         chomp $line;
7780                         # empty line ends raw part of diff-tree output
7781                         last unless $line;
7782                         push @difftree, scalar parse_difftree_raw_line($line);
7783                 }
7784
7785         } elsif ($format eq 'plain') {
7786                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7787                         '-p', $hash_parent_param, $hash, "--"
7788                         or die_error(500, "Open git-diff-tree failed");
7789         } elsif ($format eq 'patch') {
7790                 # For commit ranges, we limit the output to the number of
7791                 # patches specified in the 'patches' feature.
7792                 # For single commits, we limit the output to a single patch,
7793                 # diverging from the git-format-patch default.
7794                 my @commit_spec = ();
7795                 if ($hash_parent) {
7796                         if ($patch_max > 0) {
7797                                 push @commit_spec, "-$patch_max";
7798                         }
7799                         push @commit_spec, '-n', "$hash_parent..$hash";
7800                 } else {
7801                         if ($params{-single}) {
7802                                 push @commit_spec, '-1';
7803                         } else {
7804                                 if ($patch_max > 0) {
7805                                         push @commit_spec, "-$patch_max";
7806                                 }
7807                                 push @commit_spec, "-n";
7808                         }
7809                         push @commit_spec, '--root', $hash;
7810                 }
7811                 open $fd, "-|", git_cmd(), "format-patch", @diff_opts,
7812                         '--encoding=utf8', '--stdout', @commit_spec
7813                         or die_error(500, "Open git-format-patch failed");
7814         } else {
7815                 die_error(400, "Unknown commitdiff format");
7816         }
7817
7818         # non-textual hash id's can be cached
7819         my $expires;
7820         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7821                 $expires = "+1d";
7822         }
7823
7824         # write commit message
7825         if ($format eq 'html') {
7826                 my $refs = git_get_references();
7827                 my $ref = format_ref_marker($refs, $co{'id'});
7828
7829                 git_header_html(undef, $expires);
7830                 git_print_page_nav('commitdiff','', $hash,$co{'tree'},$hash, $formats_nav);
7831                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash);
7832                 print "<div class=\"title_text\">\n" .
7833                       "<table class=\"object_header\">\n";
7834                 git_print_authorship_rows(\%co);
7835                 print "</table>".
7836                       "</div>\n";
7837                 print "<div class=\"page_body\">\n";
7838                 if (@{$co{'comment'}} > 1) {
7839                         print "<div class=\"log\">\n";
7840                         git_print_log($co{'comment'}, -final_empty_line=> 1, -remove_title => 1);
7841                         print "</div>\n"; # class="log"
7842                 }
7843
7844         } elsif ($format eq 'plain') {
7845                 my $refs = git_get_references("tags");
7846                 my $tagname = git_get_rev_name_tags($hash);
7847                 my $filename = basename($project) . "-$hash.patch";
7848
7849                 print $cgi->header(
7850                         -type => 'text/plain',
7851                         -charset => 'utf-8',
7852                         -expires => $expires,
7853                         -content_disposition => 'inline; filename="' . "$filename" . '"');
7854                 my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
7855                 print "From: " . to_utf8($co{'author'}) . "\n";
7856                 print "Date: $ad{'rfc2822'} ($ad{'tz_local'})\n";
7857                 print "Subject: " . to_utf8($co{'title'}) . "\n";
7858
7859                 print "X-Git-Tag: $tagname\n" if $tagname;
7860                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7861
7862                 foreach my $line (@{$co{'comment'}}) {
7863                         print to_utf8($line) . "\n";
7864                 }
7865                 print "---\n\n";
7866         } elsif ($format eq 'patch') {
7867                 my $filename = basename($project) . "-$hash.patch";
7868
7869                 print $cgi->header(
7870                         -type => 'text/plain',
7871                         -charset => 'utf-8',
7872                         -expires => $expires,
7873                         -content_disposition => 'inline; filename="' . "$filename" . '"');
7874         }
7875
7876         # write patch
7877         if ($format eq 'html') {
7878                 my $use_parents = !defined $hash_parent ||
7879                         $hash_parent eq '-c' || $hash_parent eq '--cc';
7880                 git_difftree_body(\@difftree, $hash,
7881                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
7882                 print "<br/>\n";
7883
7884                 git_patchset_body($fd, $diff_style,
7885                                   \@difftree, $hash,
7886                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
7887                 close $fd;
7888                 print "</div>\n"; # class="page_body"
7889                 git_footer_html();
7890
7891         } elsif ($format eq 'plain') {
7892                 local $/ = undef;
7893                 print <$fd>;
7894                 close $fd
7895                         or print "Reading git-diff-tree failed\n";
7896         } elsif ($format eq 'patch') {
7897                 local $/ = undef;
7898                 print <$fd>;
7899                 close $fd
7900                         or print "Reading git-format-patch failed\n";
7901         }
7902 }
7903
7904 sub git_commitdiff_plain {
7905         git_commitdiff(-format => 'plain');
7906 }
7907
7908 # format-patch-style patches
7909 sub git_patch {
7910         git_commitdiff(-format => 'patch', -single => 1);
7911 }
7912
7913 sub git_patches {
7914         git_commitdiff(-format => 'patch');
7915 }
7916
7917 sub git_history {
7918         git_log_generic('history', \&git_history_body,
7919                         $hash_base, $hash_parent_base,
7920                         $file_name, $hash);
7921 }
7922
7923 sub git_search {
7924         $searchtype ||= 'commit';
7925
7926         # check if appropriate features are enabled
7927         gitweb_check_feature('search')
7928                 or die_error(403, "Search is disabled");
7929         if ($searchtype eq 'pickaxe') {
7930                 # pickaxe may take all resources of your box and run for several minutes
7931                 # with every query - so decide by yourself how public you make this feature
7932                 gitweb_check_feature('pickaxe')
7933                         or die_error(403, "Pickaxe search is disabled");
7934         }
7935         if ($searchtype eq 'grep') {
7936                 # grep search might be potentially CPU-intensive, too
7937                 gitweb_check_feature('grep')
7938                         or die_error(403, "Grep search is disabled");
7939         }
7940
7941         if (!defined $searchtext) {
7942                 die_error(400, "Text field is empty");
7943         }
7944         if (!defined $hash) {
7945                 $hash = git_get_head_hash($project);
7946         }
7947         my %co = parse_commit($hash);
7948         if (!%co) {
7949                 die_error(404, "Unknown commit object");
7950         }
7951         if (!defined $page) {
7952                 $page = 0;
7953         }
7954
7955         if ($searchtype eq 'commit' ||
7956             $searchtype eq 'author' ||
7957             $searchtype eq 'committer') {
7958                 git_search_message(%co);
7959         } elsif ($searchtype eq 'pickaxe') {
7960                 git_search_changes(%co);
7961         } elsif ($searchtype eq 'grep') {
7962                 git_search_files(%co);
7963         } else {
7964                 die_error(400, "Unknown search type");
7965         }
7966 }
7967
7968 sub git_search_help {
7969         git_header_html();
7970         git_print_page_nav('','', $hash,$hash,$hash);
7971         print <<EOT;
7972 <p><strong>Pattern</strong> is by default a normal string that is matched precisely (but without
7973 regard to case, except in the case of pickaxe). However, when you check the <em>re</em> checkbox,
7974 the pattern entered is recognized as the POSIX extended
7975 <a href="http://en.wikipedia.org/wiki/Regular_expression">regular expression</a> (also case
7976 insensitive).</p>
7977 <dl>
7978 <dt><b>commit</b></dt>
7979 <dd>The commit messages and authorship information will be scanned for the given pattern.</dd>
7980 EOT
7981         my $have_grep = gitweb_check_feature('grep');
7982         if ($have_grep) {
7983                 print <<EOT;
7984 <dt><b>grep</b></dt>
7985 <dd>All files in the currently selected tree (HEAD unless you are explicitly browsing
7986     a different one) are searched for the given pattern. On large trees, this search can take
7987 a while and put some strain on the server, so please use it with some consideration. Note that
7988 due to git-grep peculiarity, currently if regexp mode is turned off, the matches are
7989 case-sensitive.</dd>
7990 EOT
7991         }
7992         print <<EOT;
7993 <dt><b>author</b></dt>
7994 <dd>Name and e-mail of the change author and date of birth of the patch will be scanned for the given pattern.</dd>
7995 <dt><b>committer</b></dt>
7996 <dd>Name and e-mail of the committer and date of commit will be scanned for the given pattern.</dd>
7997 EOT
7998         my $have_pickaxe = gitweb_check_feature('pickaxe');
7999         if ($have_pickaxe) {
8000                 print <<EOT;
8001 <dt><b>pickaxe</b></dt>
8002 <dd>All commits that caused the string to appear or disappear from any file (changes that
8003 added, removed or "modified" the string) will be listed. This search can take a while and
8004 takes a lot of strain on the server, so please use it wisely. Note that since you may be
8005 interested even in changes just changing the case as well, this search is case sensitive.</dd>
8006 EOT
8007         }
8008         print "</dl>\n";
8009         git_footer_html();
8010 }
8011
8012 sub git_shortlog {
8013         git_log_generic('shortlog', \&git_shortlog_body,
8014                         $hash, $hash_parent);
8015 }
8016
8017 ## ......................................................................
8018 ## feeds (RSS, Atom; OPML)
8019
8020 sub git_feed {
8021         my $format = shift || 'atom';
8022         my $have_blame = gitweb_check_feature('blame');
8023
8024         # Atom: http://www.atomenabled.org/developers/syndication/
8025         # RSS:  http://www.notestips.com/80256B3A007F2692/1/NAMO5P9UPQ
8026         if ($format ne 'rss' && $format ne 'atom') {
8027                 die_error(400, "Unknown web feed format");
8028         }
8029
8030         # log/feed of current (HEAD) branch, log of given branch, history of file/directory
8031         my $head = $hash || 'HEAD';
8032         my @commitlist = parse_commits($head, 150, 0, $file_name);
8033
8034         my %latest_commit;
8035         my %latest_date;
8036         my $content_type = "application/$format+xml";
8037         if (defined $cgi->http('HTTP_ACCEPT') &&
8038                  $cgi->Accept('text/xml') > $cgi->Accept($content_type)) {
8039                 # browser (feed reader) prefers text/xml
8040                 $content_type = 'text/xml';
8041         }
8042         if (defined($commitlist[0])) {
8043                 %latest_commit = %{$commitlist[0]};
8044                 my $latest_epoch = $latest_commit{'committer_epoch'};
8045                 exit_if_unmodified_since($latest_epoch);
8046                 %latest_date = parse_date($latest_epoch, $latest_commit{'committer_tz'});
8047         }
8048         print $cgi->header(
8049                 -type => $content_type,
8050                 -charset => 'utf-8',
8051                 %latest_date ? (-last_modified => $latest_date{'rfc2822'}) : (),
8052                 -status => '200 OK');
8053
8054         # Optimization: skip generating the body if client asks only
8055         # for Last-Modified date.
8056         return if ($cgi->request_method() eq 'HEAD');
8057
8058         # header variables
8059         my $title = "$site_name - $project/$action";
8060         my $feed_type = 'log';
8061         if (defined $hash) {
8062                 $title .= " - '$hash'";
8063                 $feed_type = 'branch log';
8064                 if (defined $file_name) {
8065                         $title .= " :: $file_name";
8066                         $feed_type = 'history';
8067                 }
8068         } elsif (defined $file_name) {
8069                 $title .= " - $file_name";
8070                 $feed_type = 'history';
8071         }
8072         $title .= " $feed_type";
8073         $title = esc_html($title);
8074         my $descr = git_get_project_description($project);
8075         if (defined $descr) {
8076                 $descr = esc_html($descr);
8077         } else {
8078                 $descr = "$project " .
8079                          ($format eq 'rss' ? 'RSS' : 'Atom') .
8080                          " feed";
8081         }
8082         my $owner = git_get_project_owner($project);
8083         $owner = esc_html($owner);
8084
8085         #header
8086         my $alt_url;
8087         if (defined $file_name) {
8088                 $alt_url = href(-full=>1, action=>"history", hash=>$hash, file_name=>$file_name);
8089         } elsif (defined $hash) {
8090                 $alt_url = href(-full=>1, action=>"log", hash=>$hash);
8091         } else {
8092                 $alt_url = href(-full=>1, action=>"summary");
8093         }
8094         print qq!<?xml version="1.0" encoding="utf-8"?>\n!;
8095         if ($format eq 'rss') {
8096                 print <<XML;
8097 <rss version="2.0" xmlns:content="http://purl.org/rss/1.0/modules/content/">
8098 <channel>
8099 XML
8100                 print "<title>$title</title>\n" .
8101                       "<link>$alt_url</link>\n" .
8102                       "<description>$descr</description>\n" .
8103                       "<language>en</language>\n" .
8104                       # project owner is responsible for 'editorial' content
8105                       "<managingEditor>$owner</managingEditor>\n";
8106                 if (defined $logo || defined $favicon) {
8107                         # prefer the logo to the favicon, since RSS
8108                         # doesn't allow both
8109                         my $img = esc_url($logo || $favicon);
8110                         print "<image>\n" .
8111                               "<url>$img</url>\n" .
8112                               "<title>$title</title>\n" .
8113                               "<link>$alt_url</link>\n" .
8114                               "</image>\n";
8115                 }
8116                 if (%latest_date) {
8117                         print "<pubDate>$latest_date{'rfc2822'}</pubDate>\n";
8118                         print "<lastBuildDate>$latest_date{'rfc2822'}</lastBuildDate>\n";
8119                 }
8120                 print "<generator>gitweb v.$version/$git_version</generator>\n";
8121         } elsif ($format eq 'atom') {
8122                 print <<XML;
8123 <feed xmlns="http://www.w3.org/2005/Atom">
8124 XML
8125                 print "<title>$title</title>\n" .
8126                       "<subtitle>$descr</subtitle>\n" .
8127                       '<link rel="alternate" type="text/html" href="' .
8128                       $alt_url . '" />' . "\n" .
8129                       '<link rel="self" type="' . $content_type . '" href="' .
8130                       $cgi->self_url() . '" />' . "\n" .
8131                       "<id>" . href(-full=>1) . "</id>\n" .
8132                       # use project owner for feed author
8133                       "<author><name>$owner</name></author>\n";
8134                 if (defined $favicon) {
8135                         print "<icon>" . esc_url($favicon) . "</icon>\n";
8136                 }
8137                 if (defined $logo) {
8138                         # not twice as wide as tall: 72 x 27 pixels
8139                         print "<logo>" . esc_url($logo) . "</logo>\n";
8140                 }
8141                 if (! %latest_date) {
8142                         # dummy date to keep the feed valid until commits trickle in:
8143                         print "<updated>1970-01-01T00:00:00Z</updated>\n";
8144                 } else {
8145                         print "<updated>$latest_date{'iso-8601'}</updated>\n";
8146                 }
8147                 print "<generator version='$version/$git_version'>gitweb</generator>\n";
8148         }
8149
8150         # contents
8151         for (my $i = 0; $i <= $#commitlist; $i++) {
8152                 my %co = %{$commitlist[$i]};
8153                 my $commit = $co{'id'};
8154                 # we read 150, we always show 30 and the ones more recent than 48 hours
8155                 if (($i >= 20) && ((time - $co{'author_epoch'}) > 48*60*60)) {
8156                         last;
8157                 }
8158                 my %cd = parse_date($co{'author_epoch'}, $co{'author_tz'});
8159
8160                 # get list of changed files
8161                 open my $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
8162                         $co{'parent'} || "--root",
8163                         $co{'id'}, "--", (defined $file_name ? $file_name : ())
8164                         or next;
8165                 my @difftree = map { chomp; $_ } <$fd>;
8166                 close $fd
8167                         or next;
8168
8169                 # print element (entry, item)
8170                 my $co_url = href(-full=>1, action=>"commitdiff", hash=>$commit);
8171                 if ($format eq 'rss') {
8172                         print "<item>\n" .
8173                               "<title>" . esc_html($co{'title'}) . "</title>\n" .
8174                               "<author>" . esc_html($co{'author'}) . "</author>\n" .
8175                               "<pubDate>$cd{'rfc2822'}</pubDate>\n" .
8176                               "<guid isPermaLink=\"true\">$co_url</guid>\n" .
8177                               "<link>$co_url</link>\n" .
8178                               "<description>" . esc_html($co{'title'}) . "</description>\n" .
8179                               "<content:encoded>" .
8180                               "<![CDATA[\n";
8181                 } elsif ($format eq 'atom') {
8182                         print "<entry>\n" .
8183                               "<title type=\"html\">" . esc_html($co{'title'}) . "</title>\n" .
8184                               "<updated>$cd{'iso-8601'}</updated>\n" .
8185                               "<author>\n" .
8186                               "  <name>" . esc_html($co{'author_name'}) . "</name>\n";
8187                         if ($co{'author_email'}) {
8188                                 print "  <email>" . esc_html($co{'author_email'}) . "</email>\n";
8189                         }
8190                         print "</author>\n" .
8191                               # use committer for contributor
8192                               "<contributor>\n" .
8193                               "  <name>" . esc_html($co{'committer_name'}) . "</name>\n";
8194                         if ($co{'committer_email'}) {
8195                                 print "  <email>" . esc_html($co{'committer_email'}) . "</email>\n";
8196                         }
8197                         print "</contributor>\n" .
8198                               "<published>$cd{'iso-8601'}</published>\n" .
8199                               "<link rel=\"alternate\" type=\"text/html\" href=\"$co_url\" />\n" .
8200                               "<id>$co_url</id>\n" .
8201                               "<content type=\"xhtml\" xml:base=\"" . esc_url($my_url) . "\">\n" .
8202                               "<div xmlns=\"http://www.w3.org/1999/xhtml\">\n";
8203                 }
8204                 my $comment = $co{'comment'};
8205                 print "<pre>\n";
8206                 foreach my $line (@$comment) {
8207                         $line = esc_html($line);
8208                         print "$line\n";
8209                 }
8210                 print "</pre><ul>\n";
8211                 foreach my $difftree_line (@difftree) {
8212                         my %difftree = parse_difftree_raw_line($difftree_line);
8213                         next if !$difftree{'from_id'};
8214
8215                         my $file = $difftree{'file'} || $difftree{'to_file'};
8216
8217                         print "<li>" .
8218                               "[" .
8219                               $cgi->a({-href => href(-full=>1, action=>"blobdiff",
8220                                                      hash=>$difftree{'to_id'}, hash_parent=>$difftree{'from_id'},
8221                                                      hash_base=>$co{'id'}, hash_parent_base=>$co{'parent'},
8222                                                      file_name=>$file, file_parent=>$difftree{'from_file'}),
8223                                       -title => "diff"}, 'D');
8224                         if ($have_blame) {
8225                                 print $cgi->a({-href => href(-full=>1, action=>"blame",
8226                                                              file_name=>$file, hash_base=>$commit),
8227                                               -title => "blame"}, 'B');
8228                         }
8229                         # if this is not a feed of a file history
8230                         if (!defined $file_name || $file_name ne $file) {
8231                                 print $cgi->a({-href => href(-full=>1, action=>"history",
8232                                                              file_name=>$file, hash=>$commit),
8233                                               -title => "history"}, 'H');
8234                         }
8235                         $file = esc_path($file);
8236                         print "] ".
8237                               "$file</li>\n";
8238                 }
8239                 if ($format eq 'rss') {
8240                         print "</ul>]]>\n" .
8241                               "</content:encoded>\n" .
8242                               "</item>\n";
8243                 } elsif ($format eq 'atom') {
8244                         print "</ul>\n</div>\n" .
8245                               "</content>\n" .
8246                               "</entry>\n";
8247                 }
8248         }
8249
8250         # end of feed
8251         if ($format eq 'rss') {
8252                 print "</channel>\n</rss>\n";
8253         } elsif ($format eq 'atom') {
8254                 print "</feed>\n";
8255         }
8256 }
8257
8258 sub git_rss {
8259         git_feed('rss');
8260 }
8261
8262 sub git_atom {
8263         git_feed('atom');
8264 }
8265
8266 sub git_opml {
8267         my @list = git_get_projects_list($project_filter, $strict_export);
8268         if (!@list) {
8269                 die_error(404, "No projects found");
8270         }
8271
8272         print $cgi->header(
8273                 -type => 'text/xml',
8274                 -charset => 'utf-8',
8275                 -content_disposition => 'inline; filename="opml.xml"');
8276
8277         my $title = esc_html($site_name);
8278         my $filter = " within subdirectory ";
8279         if (defined $project_filter) {
8280                 $filter .= esc_html($project_filter);
8281         } else {
8282                 $filter = "";
8283         }
8284         print <<XML;
8285 <?xml version="1.0" encoding="utf-8"?>
8286 <opml version="1.0">
8287 <head>
8288   <title>$title OPML Export$filter</title>
8289 </head>
8290 <body>
8291 <outline text="git RSS feeds">
8292 XML
8293
8294         foreach my $pr (@list) {
8295                 my %proj = %$pr;
8296                 my $head = git_get_head_hash($proj{'path'});
8297                 if (!defined $head) {
8298                         next;
8299                 }
8300                 $git_dir = "$projectroot/$proj{'path'}";
8301                 my %co = parse_commit($head);
8302                 if (!%co) {
8303                         next;
8304                 }
8305
8306                 my $path = esc_html(chop_str($proj{'path'}, 25, 5));
8307                 my $rss  = href('project' => $proj{'path'}, 'action' => 'rss', -full => 1);
8308                 my $html = href('project' => $proj{'path'}, 'action' => 'summary', -full => 1);
8309                 print "<outline type=\"rss\" text=\"$path\" title=\"$path\" xmlUrl=\"$rss\" htmlUrl=\"$html\"/>\n";
8310         }
8311         print <<XML;
8312 </outline>
8313 </body>
8314 </opml>
8315 XML
8316 }