Lady’s Gitweb - Gitweb/blob - gitweb.perl

   1 #!/usr/bin/perl
   2
   3 # gitweb - simple web interface to track changes in git repositories
   4 #
   5 # (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
   6 # (C) 2005, Christian Gierke
   7 #
   8 # This program is licensed under the GPLv2
   9
  10 use 5.008;
  11 use strict;
  12 use warnings;
  13 use CGI qw(:standard :escapeHTML -nosticky);
  14 use CGI::Util qw(unescape);
  15 use CGI::Carp qw(fatalsToBrowser set_message);
  16 use Encode;
  17 use Fcntl ':mode';
  18 use File::Find qw();
  19 use File::Basename qw(basename);
  20 use Time::HiRes qw(gettimeofday tv_interval);
  21 binmode STDOUT, ':utf8';
  22
  23 our $t0 = [ gettimeofday() ];
  24 our $number_of_git_cmds = 0;
  25
  26 BEGIN {
  27         CGI->compile() if $ENV{'MOD_PERL'};
  28 }
  29
  30 our $version = "++GIT_VERSION++";
  31
  32 our ($my_url, $my_uri, $base_url, $path_info, $home_link);
  33 sub evaluate_uri {
  34         our $cgi;
  35
  36         our $my_url = $cgi->url();
  37         our $my_uri = $cgi->url(-absolute => 1);
  38
  39         # Base URL for relative URLs in gitweb ($logo, $favicon, ...),
  40         # needed and used only for URLs with nonempty PATH_INFO
  41         our $base_url = $my_url;
  42
  43         # When the script is used as DirectoryIndex, the URL does not contain the name
  44         # of the script file itself, and $cgi->url() fails to strip PATH_INFO, so we
  45         # have to do it ourselves. We make $path_info global because it's also used
  46         # later on.
  47         #
  48         # Another issue with the script being the DirectoryIndex is that the resulting
  49         # $my_url data is not the full script URL: this is good, because we want
  50         # generated links to keep implying the script name if it wasn't explicitly
  51         # indicated in the URL we're handling, but it means that $my_url cannot be used
  52         # as base URL.
  53         # Therefore, if we needed to strip PATH_INFO, then we know that we have
  54         # to build the base URL ourselves:
  55         our $path_info = $ENV{"PATH_INFO"};
  56         if ($path_info) {
  57                 if ($my_url =~ s,\Q$path_info\E$,, &&
  58                     $my_uri =~ s,\Q$path_info\E$,, &&
  59                     defined $ENV{'SCRIPT_NAME'}) {
  60                         $base_url = $cgi->url(-base => 1) . $ENV{'SCRIPT_NAME'};
  61                 }
  62         }
  63
  64         # target of the home link on top of all pages
  65         our $home_link = $my_uri || "/";
  66 }
  67
  68 # core git executable to use
  69 # this can just be "git" if your webserver has a sensible PATH
  70 our $GIT = "++GIT_BINDIR++/git";
  71
  72 # absolute fs-path which will be prepended to the project path
  73 #our $projectroot = "/pub/scm";
  74 our $projectroot = "++GITWEB_PROJECTROOT++";
  75
  76 # fs traversing limit for getting project list
  77 # the number is relative to the projectroot
  78 our $project_maxdepth = "++GITWEB_PROJECT_MAXDEPTH++";
  79
  80 # string of the home link on top of all pages
  81 our $home_link_str = "++GITWEB_HOME_LINK_STR++";
  82
  83 # name of your site or organization to appear in page titles
  84 # replace this with something more descriptive for clearer bookmarks
  85 our $site_name = "++GITWEB_SITENAME++"
  86                  || ($ENV{'SERVER_NAME'} || "Untitled") . " Git";
  87
  88 # filename of html text to include at top of each page
  89 our $site_header = "++GITWEB_SITE_HEADER++";
  90 # html text to include at home page
  91 our $home_text = "++GITWEB_HOMETEXT++";
  92 # filename of html text to include at bottom of each page
  93 our $site_footer = "++GITWEB_SITE_FOOTER++";
  94
  95 # URI of stylesheets
  96 our @stylesheets = ("++GITWEB_CSS++");
  97 # URI of a single stylesheet, which can be overridden in GITWEB_CONFIG.
  98 our $stylesheet = undef;
  99
 100 # URI of GIT logo (72x27 size)
 101 our $logo = "++GITWEB_LOGO++";
 102 # URI of GIT favicon, assumed to be image/png type
 103 our $favicon = "++GITWEB_FAVICON++";
 104 # URI of gitweb.js (JavaScript code for gitweb)
 105 our $javascript = "++GITWEB_JS++";
 106
 107 # URI and label (title) of GIT logo link
 108 #our $logo_url = "http://www.kernel.org/pub/software/scm/git/docs/";
 109 #our $logo_label = "git documentation";
 110 our $logo_url = "http://git-scm.com/";
 111 our $logo_label = "git homepage";
 112
 113 # source of projects list
 114 our $projects_list = "++GITWEB_LIST++";
 115
 116 # the width (in characters) of the projects list "Description" column
 117 our $projects_list_description_width = 25;
 118
 119 # default order of projects list
 120 # valid values are none, project, descr, owner, and age
 121 our $default_projects_order = "project";
 122
 123 # show repository only if this file exists
 124 # (only effective if this variable evaluates to true)
 125 our $export_ok = "++GITWEB_EXPORT_OK++";
 126
 127 # show repository only if this subroutine returns true
 128 # when given the path to the project, for example:
 129 #    sub { return -e "$_[0]/git-daemon-export-ok"; }
 130 our $export_auth_hook = undef;
 131
 132 # only allow viewing of repositories also shown on the overview page
 133 our $strict_export = "++GITWEB_STRICT_EXPORT++";
 134
 135 # list of git base URLs used for URL to where fetch project from,
 136 # i.e. full URL is "$git_base_url/$project"
 137 our @git_base_url_list = grep { $_ ne '' } ("++GITWEB_BASE_URL++");
 138
 139 # default blob_plain mimetype and default charset for text/plain blob
 140 our $default_blob_plain_mimetype = 'text/plain';
 141 our $default_text_plain_charset  = undef;
 142
 143 # file to use for guessing MIME types before trying /etc/mime.types
 144 # (relative to the current git repository)
 145 our $mimetypes_file = undef;
 146
 147 # assume this charset if line contains non-UTF-8 characters;
 148 # it should be valid encoding (see Encoding::Supported(3pm) for list),
 149 # for which encoding all byte sequences are valid, for example
 150 # 'iso-8859-1' aka 'latin1' (it is decoded without checking, so it
 151 # could be even 'utf-8' for the old behavior)
 152 our $fallback_encoding = 'latin1';
 153
 154 # rename detection options for git-diff and git-diff-tree
 155 # - default is '-M', with the cost proportional to
 156 #   (number of removed files) * (number of new files).
 157 # - more costly is '-C' (which implies '-M'), with the cost proportional to
 158 #   (number of changed files + number of removed files) * (number of new files)
 159 # - even more costly is '-C', '--find-copies-harder' with cost
 160 #   (number of files in the original tree) * (number of new files)
 161 # - one might want to include '-B' option, e.g. '-B', '-M'
 162 our @diff_opts = ('-M'); # taken from git_commit
 163
 164 # Disables features that would allow repository owners to inject script into
 165 # the gitweb domain.
 166 our $prevent_xss = 0;
 167
 168 # Path to the highlight executable to use (must be the one from
 169 # http://www.andre-simon.de due to assumptions about parameters and output).
 170 # Useful if highlight is not installed on your webserver's PATH.
 171 # [Default: highlight]
 172 our $highlight_bin = "++HIGHLIGHT_BIN++";
 173
 174 # information about snapshot formats that gitweb is capable of serving
 175 our %known_snapshot_formats = (
 176         # name => {
 177         #       'display' => display name,
 178         #       'type' => mime type,
 179         #       'suffix' => filename suffix,
 180         #       'format' => --format for git-archive,
 181         #       'compressor' => [compressor command and arguments]
 182         #                       (array reference, optional)
 183         #       'disabled' => boolean (optional)}
 184         #
 185         'tgz' => {
 186                 'display' => 'tar.gz',
 187                 'type' => 'application/x-gzip',
 188                 'suffix' => '.tar.gz',
 189                 'format' => 'tar',
 190                 'compressor' => ['gzip']},
 191
 192         'tbz2' => {
 193                 'display' => 'tar.bz2',
 194                 'type' => 'application/x-bzip2',
 195                 'suffix' => '.tar.bz2',
 196                 'format' => 'tar',
 197                 'compressor' => ['bzip2']},
 198
 199         'txz' => {
 200                 'display' => 'tar.xz',
 201                 'type' => 'application/x-xz',
 202                 'suffix' => '.tar.xz',
 203                 'format' => 'tar',
 204                 'compressor' => ['xz'],
 205                 'disabled' => 1},
 206
 207         'zip' => {
 208                 'display' => 'zip',
 209                 'type' => 'application/x-zip',
 210                 'suffix' => '.zip',
 211                 'format' => 'zip'},
 212 );
 213
 214 # Aliases so we understand old gitweb.snapshot values in repository
 215 # configuration.
 216 our %known_snapshot_format_aliases = (
 217         'gzip'  => 'tgz',
 218         'bzip2' => 'tbz2',
 219         'xz'    => 'txz',
 220
 221         # backward compatibility: legacy gitweb config support
 222         'x-gzip' => undef, 'gz' => undef,
 223         'x-bzip2' => undef, 'bz2' => undef,
 224         'x-zip' => undef, '' => undef,
 225 );
 226
 227 # Pixel sizes for icons and avatars. If the default font sizes or lineheights
 228 # are changed, it may be appropriate to change these values too via
 229 # $GITWEB_CONFIG.
 230 our %avatar_size = (
 231         'default' => 16,
 232         'double'  => 32
 233 );
 234
 235 # Used to set the maximum load that we will still respond to gitweb queries.
 236 # If server load exceed this value then return "503 server busy" error.
 237 # If gitweb cannot determined server load, it is taken to be 0.
 238 # Leave it undefined (or set to 'undef') to turn off load checking.
 239 our $maxload = 300;
 240
 241 # configuration for 'highlight' (http://www.andre-simon.de/)
 242 # match by basename
 243 our %highlight_basename = (
 244         #'Program' => 'py',
 245         #'Library' => 'py',
 246         'SConstruct' => 'py', # SCons equivalent of Makefile
 247         'Makefile' => 'make',
 248 );
 249 # match by extension
 250 our %highlight_ext = (
 251         # main extensions, defining name of syntax;
 252         # see files in /usr/share/highlight/langDefs/ directory
 253         map { $_ => $_ }
 254                 qw(py c cpp rb java css php sh pl js tex bib xml awk bat ini spec tcl sql make),
 255         # alternate extensions, see /etc/highlight/filetypes.conf
 256         'h' => 'c',
 257         map { $_ => 'sh'  } qw(bash zsh ksh),
 258         map { $_ => 'cpp' } qw(cxx c++ cc),
 259         map { $_ => 'php' } qw(php3 php4 php5 phps),
 260         map { $_ => 'pl'  } qw(perl pm), # perhaps also 'cgi'
 261         map { $_ => 'make'} qw(mak mk),
 262         map { $_ => 'xml' } qw(xhtml html htm),
 263 );
 264
 265 # You define site-wide feature defaults here; override them with
 266 # $GITWEB_CONFIG as necessary.
 267 our %feature = (
 268         # feature => {
 269         #       'sub' => feature-sub (subroutine),
 270         #       'override' => allow-override (boolean),
 271         #       'default' => [ default options...] (array reference)}
 272         #
 273         # if feature is overridable (it means that allow-override has true value),
 274         # then feature-sub will be called with default options as parameters;
 275         # return value of feature-sub indicates if to enable specified feature
 276         #
 277         # if there is no 'sub' key (no feature-sub), then feature cannot be
 278         # overridden
 279         #
 280         # use gitweb_get_feature(<feature>) to retrieve the <feature> value
 281         # (an array) or gitweb_check_feature(<feature>) to check if <feature>
 282         # is enabled
 283
 284         # Enable the 'blame' blob view, showing the last commit that modified
 285         # each line in the file. This can be very CPU-intensive.
 286
 287         # To enable system wide have in $GITWEB_CONFIG
 288         # $feature{'blame'}{'default'} = [1];
 289         # To have project specific config enable override in $GITWEB_CONFIG
 290         # $feature{'blame'}{'override'} = 1;
 291         # and in project config gitweb.blame = 0|1;
 292         'blame' => {
 293                 'sub' => sub { feature_bool('blame', @_) },
 294                 'override' => 0,
 295                 'default' => [0]},
 296
 297         # Enable the 'snapshot' link, providing a compressed archive of any
 298         # tree. This can potentially generate high traffic if you have large
 299         # project.
 300
 301         # Value is a list of formats defined in %known_snapshot_formats that
 302         # you wish to offer.
 303         # To disable system wide have in $GITWEB_CONFIG
 304         # $feature{'snapshot'}{'default'} = [];
 305         # To have project specific config enable override in $GITWEB_CONFIG
 306         # $feature{'snapshot'}{'override'} = 1;
 307         # and in project config, a comma-separated list of formats or "none"
 308         # to disable.  Example: gitweb.snapshot = tbz2,zip;
 309         'snapshot' => {
 310                 'sub' => \&feature_snapshot,
 311                 'override' => 0,
 312                 'default' => ['tgz']},
 313
 314         # Enable text search, which will list the commits which match author,
 315         # committer or commit text to a given string.  Enabled by default.
 316         # Project specific override is not supported.
 317         'search' => {
 318                 'override' => 0,
 319                 'default' => [1]},
 320
 321         # Enable grep search, which will list the files in currently selected
 322         # tree containing the given string. Enabled by default. This can be
 323         # potentially CPU-intensive, of course.
 324
 325         # To enable system wide have in $GITWEB_CONFIG
 326         # $feature{'grep'}{'default'} = [1];
 327         # To have project specific config enable override in $GITWEB_CONFIG
 328         # $feature{'grep'}{'override'} = 1;
 329         # and in project config gitweb.grep = 0|1;
 330         'grep' => {
 331                 'sub' => sub { feature_bool('grep', @_) },
 332                 'override' => 0,
 333                 'default' => [1]},
 334
 335         # Enable the pickaxe search, which will list the commits that modified
 336         # a given string in a file. This can be practical and quite faster
 337         # alternative to 'blame', but still potentially CPU-intensive.
 338
 339         # To enable system wide have in $GITWEB_CONFIG
 340         # $feature{'pickaxe'}{'default'} = [1];
 341         # To have project specific config enable override in $GITWEB_CONFIG
 342         # $feature{'pickaxe'}{'override'} = 1;
 343         # and in project config gitweb.pickaxe = 0|1;
 344         'pickaxe' => {
 345                 'sub' => sub { feature_bool('pickaxe', @_) },
 346                 'override' => 0,
 347                 'default' => [1]},
 348
 349         # Enable showing size of blobs in a 'tree' view, in a separate
 350         # column, similar to what 'ls -l' does.  This cost a bit of IO.
 351
 352         # To disable system wide have in $GITWEB_CONFIG
 353         # $feature{'show-sizes'}{'default'} = [0];
 354         # To have project specific config enable override in $GITWEB_CONFIG
 355         # $feature{'show-sizes'}{'override'} = 1;
 356         # and in project config gitweb.showsizes = 0|1;
 357         'show-sizes' => {
 358                 'sub' => sub { feature_bool('showsizes', @_) },
 359                 'override' => 0,
 360                 'default' => [1]},
 361
 362         # Make gitweb use an alternative format of the URLs which can be
 363         # more readable and natural-looking: project name is embedded
 364         # directly in the path and the query string contains other
 365         # auxiliary information. All gitweb installations recognize
 366         # URL in either format; this configures in which formats gitweb
 367         # generates links.
 368
 369         # To enable system wide have in $GITWEB_CONFIG
 370         # $feature{'pathinfo'}{'default'} = [1];
 371         # Project specific override is not supported.
 372
 373         # Note that you will need to change the default location of CSS,
 374         # favicon, logo and possibly other files to an absolute URL. Also,
 375         # if gitweb.cgi serves as your indexfile, you will need to force
 376         # $my_uri to contain the script name in your $GITWEB_CONFIG.
 377         'pathinfo' => {
 378                 'override' => 0,
 379                 'default' => [0]},
 380
 381         # Make gitweb consider projects in project root subdirectories
 382         # to be forks of existing projects. Given project $projname.git,
 383         # projects matching $projname/*.git will not be shown in the main
 384         # projects list, instead a '+' mark will be added to $projname
 385         # there and a 'forks' view will be enabled for the project, listing
 386         # all the forks. If project list is taken from a file, forks have
 387         # to be listed after the main project.
 388
 389         # To enable system wide have in $GITWEB_CONFIG
 390         # $feature{'forks'}{'default'} = [1];
 391         # Project specific override is not supported.
 392         'forks' => {
 393                 'override' => 0,
 394                 'default' => [0]},
 395
 396         # Insert custom links to the action bar of all project pages.
 397         # This enables you mainly to link to third-party scripts integrating
 398         # into gitweb; e.g. git-browser for graphical history representation
 399         # or custom web-based repository administration interface.
 400
 401         # The 'default' value consists of a list of triplets in the form
 402         # (label, link, position) where position is the label after which
 403         # to insert the link and link is a format string where %n expands
 404         # to the project name, %f to the project path within the filesystem,
 405         # %h to the current hash (h gitweb parameter) and %b to the current
 406         # hash base (hb gitweb parameter); %% expands to %.
 407
 408         # To enable system wide have in $GITWEB_CONFIG e.g.
 409         # $feature{'actions'}{'default'} = [('graphiclog',
 410         #       '/git-browser/by-commit.html?r=%n', 'summary')];
 411         # Project specific override is not supported.
 412         'actions' => {
 413                 'override' => 0,
 414                 'default' => []},
 415
 416         # Allow gitweb scan project content tags described in ctags/
 417         # of project repository, and display the popular Web 2.0-ish
 418         # "tag cloud" near the project list. Note that this is something
 419         # COMPLETELY different from the normal Git tags.
 420
 421         # gitweb by itself can show existing tags, but it does not handle
 422         # tagging itself; you need an external application for that.
 423         # For an example script, check Girocco's cgi/tagproj.cgi.
 424         # You may want to install the HTML::TagCloud Perl module to get
 425         # a pretty tag cloud instead of just a list of tags.
 426
 427         # To enable system wide have in $GITWEB_CONFIG
 428         # $feature{'ctags'}{'default'} = ['path_to_tag_script'];
 429         # Project specific override is not supported.
 430         'ctags' => {
 431                 'override' => 0,
 432                 'default' => [0]},
 433
 434         # The maximum number of patches in a patchset generated in patch
 435         # view. Set this to 0 or undef to disable patch view, or to a
 436         # negative number to remove any limit.
 437
 438         # To disable system wide have in $GITWEB_CONFIG
 439         # $feature{'patches'}{'default'} = [0];
 440         # To have project specific config enable override in $GITWEB_CONFIG
 441         # $feature{'patches'}{'override'} = 1;
 442         # and in project config gitweb.patches = 0|n;
 443         # where n is the maximum number of patches allowed in a patchset.
 444         'patches' => {
 445                 'sub' => \&feature_patches,
 446                 'override' => 0,
 447                 'default' => [16]},
 448
 449         # Avatar support. When this feature is enabled, views such as
 450         # shortlog or commit will display an avatar associated with
 451         # the email of the committer(s) and/or author(s).
 452
 453         # Currently available providers are gravatar and picon.
 454         # If an unknown provider is specified, the feature is disabled.
 455
 456         # Gravatar depends on Digest::MD5.
 457         # Picon currently relies on the indiana.edu database.
 458
 459         # To enable system wide have in $GITWEB_CONFIG
 460         # $feature{'avatar'}{'default'} = ['<provider>'];
 461         # where <provider> is either gravatar or picon.
 462         # To have project specific config enable override in $GITWEB_CONFIG
 463         # $feature{'avatar'}{'override'} = 1;
 464         # and in project config gitweb.avatar = <provider>;
 465         'avatar' => {
 466                 'sub' => \&feature_avatar,
 467                 'override' => 0,
 468                 'default' => ['']},
 469
 470         # Enable displaying how much time and how many git commands
 471         # it took to generate and display page.  Disabled by default.
 472         # Project specific override is not supported.
 473         'timed' => {
 474                 'override' => 0,
 475                 'default' => [0]},
 476
 477         # Enable turning some links into links to actions which require
 478         # JavaScript to run (like 'blame_incremental').  Not enabled by
 479         # default.  Project specific override is currently not supported.
 480         'javascript-actions' => {
 481                 'override' => 0,
 482                 'default' => [0]},
 483
 484         # Syntax highlighting support. This is based on Daniel Svensson's
 485         # and Sham Chukoury's work in gitweb-xmms2.git.
 486         # It requires the 'highlight' program present in $PATH,
 487         # and therefore is disabled by default.
 488
 489         # To enable system wide have in $GITWEB_CONFIG
 490         # $feature{'highlight'}{'default'} = [1];
 491
 492         'highlight' => {
 493                 'sub' => sub { feature_bool('highlight', @_) },
 494                 'override' => 0,
 495                 'default' => [0]},
 496
 497         # Enable displaying of remote heads in the heads list
 498
 499         # To enable system wide have in $GITWEB_CONFIG
 500         # $feature{'remote_heads'}{'default'} = [1];
 501         # To have project specific config enable override in $GITWEB_CONFIG
 502         # $feature{'remote_heads'}{'override'} = 1;
 503         # and in project config gitweb.remote_heads = 0|1;
 504         'remote_heads' => {
 505                 'sub' => sub { feature_bool('remote_heads', @_) },
 506                 'override' => 0,
 507                 'default' => [0]},
 508 );
 509
 510 sub gitweb_get_feature {
 511         my ($name) = @_;
 512         return unless exists $feature{$name};
 513         my ($sub, $override, @defaults) = (
 514                 $feature{$name}{'sub'},
 515                 $feature{$name}{'override'},
 516                 @{$feature{$name}{'default'}});
 517         # project specific override is possible only if we have project
 518         our $git_dir; # global variable, declared later
 519         if (!$override || !defined $git_dir) {
 520                 return @defaults;
 521         }
 522         if (!defined $sub) {
 523                 warn "feature $name is not overridable";
 524                 return @defaults;
 525         }
 526         return $sub->(@defaults);
 527 }
 528
 529 # A wrapper to check if a given feature is enabled.
 530 # With this, you can say
 531 #
 532 #   my $bool_feat = gitweb_check_feature('bool_feat');
 533 #   gitweb_check_feature('bool_feat') or somecode;
 534 #
 535 # instead of
 536 #
 537 #   my ($bool_feat) = gitweb_get_feature('bool_feat');
 538 #   (gitweb_get_feature('bool_feat'))[0] or somecode;
 539 #
 540 sub gitweb_check_feature {
 541         return (gitweb_get_feature(@_))[0];
 542 }
 543
 544
 545 sub feature_bool {
 546         my $key = shift;
 547         my ($val) = git_get_project_config($key, '--bool');
 548
 549         if (!defined $val) {
 550                 return ($_[0]);
 551         } elsif ($val eq 'true') {
 552                 return (1);
 553         } elsif ($val eq 'false') {
 554                 return (0);
 555         }
 556 }
 557
 558 sub feature_snapshot {
 559         my (@fmts) = @_;
 560
 561         my ($val) = git_get_project_config('snapshot');
 562
 563         if ($val) {
 564                 @fmts = ($val eq 'none' ? () : split /\s*[,\s]\s*/, $val);
 565         }
 566
 567         return @fmts;
 568 }
 569
 570 sub feature_patches {
 571         my @val = (git_get_project_config('patches', '--int'));
 572
 573         if (@val) {
 574                 return @val;
 575         }
 576
 577         return ($_[0]);
 578 }
 579
 580 sub feature_avatar {
 581         my @val = (git_get_project_config('avatar'));
 582
 583         return @val ? @val : @_;
 584 }
 585
 586 # checking HEAD file with -e is fragile if the repository was
 587 # initialized long time ago (i.e. symlink HEAD) and was pack-ref'ed
 588 # and then pruned.
 589 sub check_head_link {
 590         my ($dir) = @_;
 591         my $headfile = "$dir/HEAD";
 592         return ((-e $headfile) ||
 593                 (-l $headfile && readlink($headfile) =~ /^refs\/heads\//));
 594 }
 595
 596 sub check_export_ok {
 597         my ($dir) = @_;
 598         return (check_head_link($dir) &&
 599                 (!$export_ok || -e "$dir/$export_ok") &&
 600                 (!$export_auth_hook || $export_auth_hook->($dir)));
 601 }
 602
 603 # process alternate names for backward compatibility
 604 # filter out unsupported (unknown) snapshot formats
 605 sub filter_snapshot_fmts {
 606         my @fmts = @_;
 607
 608         @fmts = map {
 609                 exists $known_snapshot_format_aliases{$_} ?
 610                        $known_snapshot_format_aliases{$_} : $_} @fmts;
 611         @fmts = grep {
 612                 exists $known_snapshot_formats{$_} &&
 613                 !$known_snapshot_formats{$_}{'disabled'}} @fmts;
 614 }
 615
 616 # If it is set to code reference, it is code that it is to be run once per
 617 # request, allowing updating configurations that change with each request,
 618 # while running other code in config file only once.
 619 #
 620 # Otherwise, if it is false then gitweb would process config file only once;
 621 # if it is true then gitweb config would be run for each request.
 622 our $per_request_config = 1;
 623
 624 our ($GITWEB_CONFIG, $GITWEB_CONFIG_SYSTEM);
 625 sub evaluate_gitweb_config {
 626         our $GITWEB_CONFIG = $ENV{'GITWEB_CONFIG'} || "++GITWEB_CONFIG++";
 627         our $GITWEB_CONFIG_SYSTEM = $ENV{'GITWEB_CONFIG_SYSTEM'} || "++GITWEB_CONFIG_SYSTEM++";
 628         # die if there are errors parsing config file
 629         if (-e $GITWEB_CONFIG) {
 630                 do $GITWEB_CONFIG;
 631                 die $@ if $@;
 632         } elsif (-e $GITWEB_CONFIG_SYSTEM) {
 633                 do $GITWEB_CONFIG_SYSTEM;
 634                 die $@ if $@;
 635         }
 636 }
 637
 638 # Get loadavg of system, to compare against $maxload.
 639 # Currently it requires '/proc/loadavg' present to get loadavg;
 640 # if it is not present it returns 0, which means no load checking.
 641 sub get_loadavg {
 642         if( -e '/proc/loadavg' ){
 643                 open my $fd, '<', '/proc/loadavg'
 644                         or return 0;
 645                 my @load = split(/\s+/, scalar <$fd>);
 646                 close $fd;
 647
 648                 # The first three columns measure CPU and IO utilization of the last one,
 649                 # five, and 10 minute periods.  The fourth column shows the number of
 650                 # currently running processes and the total number of processes in the m/n
 651                 # format.  The last column displays the last process ID used.
 652                 return $load[0] || 0;
 653         }
 654         # additional checks for load average should go here for things that don't export
 655         # /proc/loadavg
 656
 657         return 0;
 658 }
 659
 660 # version of the core git binary
 661 our $git_version;
 662 sub evaluate_git_version {
 663         our $git_version = qx("$GIT" --version) =~ m/git version (.*)$/ ? $1 : "unknown";
 664         $number_of_git_cmds++;
 665 }
 666
 667 sub check_loadavg {
 668         if (defined $maxload && get_loadavg() > $maxload) {
 669                 die_error(503, "The load average on the server is too high");
 670         }
 671 }
 672
 673 # ======================================================================
 674 # input validation and dispatch
 675
 676 # input parameters can be collected from a variety of sources (presently, CGI
 677 # and PATH_INFO), so we define an %input_params hash that collects them all
 678 # together during validation: this allows subsequent uses (e.g. href()) to be
 679 # agnostic of the parameter origin
 680
 681 our %input_params = ();
 682
 683 # input parameters are stored with the long parameter name as key. This will
 684 # also be used in the href subroutine to convert parameters to their CGI
 685 # equivalent, and since the href() usage is the most frequent one, we store
 686 # the name -> CGI key mapping here, instead of the reverse.
 687 #
 688 # XXX: Warning: If you touch this, check the search form for updating,
 689 # too.
 690
 691 our @cgi_param_mapping = (
 692         project => "p",
 693         action => "a",
 694         file_name => "f",
 695         file_parent => "fp",
 696         hash => "h",
 697         hash_parent => "hp",
 698         hash_base => "hb",
 699         hash_parent_base => "hpb",
 700         page => "pg",
 701         order => "o",
 702         searchtext => "s",
 703         searchtype => "st",
 704         snapshot_format => "sf",
 705         extra_options => "opt",
 706         search_use_regexp => "sr",
 707         # this must be last entry (for manipulation from JavaScript)
 708         javascript => "js"
 709 );
 710 our %cgi_param_mapping = @cgi_param_mapping;
 711
 712 # we will also need to know the possible actions, for validation
 713 our %actions = (
 714         "blame" => \&git_blame,
 715         "blame_incremental" => \&git_blame_incremental,
 716         "blame_data" => \&git_blame_data,
 717         "blobdiff" => \&git_blobdiff,
 718         "blobdiff_plain" => \&git_blobdiff_plain,
 719         "blob" => \&git_blob,
 720         "blob_plain" => \&git_blob_plain,
 721         "commitdiff" => \&git_commitdiff,
 722         "commitdiff_plain" => \&git_commitdiff_plain,
 723         "commit" => \&git_commit,
 724         "forks" => \&git_forks,
 725         "heads" => \&git_heads,
 726         "history" => \&git_history,
 727         "log" => \&git_log,
 728         "patch" => \&git_patch,
 729         "patches" => \&git_patches,
 730         "remotes" => \&git_remotes,
 731         "rss" => \&git_rss,
 732         "atom" => \&git_atom,
 733         "search" => \&git_search,
 734         "search_help" => \&git_search_help,
 735         "shortlog" => \&git_shortlog,
 736         "summary" => \&git_summary,
 737         "tag" => \&git_tag,
 738         "tags" => \&git_tags,
 739         "tree" => \&git_tree,
 740         "snapshot" => \&git_snapshot,
 741         "object" => \&git_object,
 742         # those below don't need $project
 743         "opml" => \&git_opml,
 744         "project_list" => \&git_project_list,
 745         "project_index" => \&git_project_index,
 746 );
 747
 748 # finally, we have the hash of allowed extra_options for the commands that
 749 # allow them
 750 our %allowed_options = (
 751         "--no-merges" => [ qw(rss atom log shortlog history) ],
 752 );
 753
 754 # fill %input_params with the CGI parameters. All values except for 'opt'
 755 # should be single values, but opt can be an array. We should probably
 756 # build an array of parameters that can be multi-valued, but since for the time
 757 # being it's only this one, we just single it out
 758 sub evaluate_query_params {
 759         our $cgi;
 760
 761         while (my ($name, $symbol) = each %cgi_param_mapping) {
 762                 if ($symbol eq 'opt') {
 763                         $input_params{$name} = [ $cgi->param($symbol) ];
 764                 } else {
 765                         $input_params{$name} = $cgi->param($symbol);
 766                 }
 767         }
 768 }
 769
 770 # now read PATH_INFO and update the parameter list for missing parameters
 771 sub evaluate_path_info {
 772         return if defined $input_params{'project'};
 773         return if !$path_info;
 774         $path_info =~ s,^/+,,;
 775         return if !$path_info;
 776
 777         # find which part of PATH_INFO is project
 778         my $project = $path_info;
 779         $project =~ s,/+$,,;
 780         while ($project && !check_head_link("$projectroot/$project")) {
 781                 $project =~ s,/*[^/]*$,,;
 782         }
 783         return unless $project;
 784         $input_params{'project'} = $project;
 785
 786         # do not change any parameters if an action is given using the query string
 787         return if $input_params{'action'};
 788         $path_info =~ s,^\Q$project\E/*,,;
 789
 790         # next, check if we have an action
 791         my $action = $path_info;
 792         $action =~ s,/.*$,,;
 793         if (exists $actions{$action}) {
 794                 $path_info =~ s,^$action/*,,;
 795                 $input_params{'action'} = $action;
 796         }
 797
 798         # list of actions that want hash_base instead of hash, but can have no
 799         # pathname (f) parameter
 800         my @wants_base = (
 801                 'tree',
 802                 'history',
 803         );
 804
 805         # we want to catch, among others
 806         # [$hash_parent_base[:$file_parent]..]$hash_parent[:$file_name]
 807         my ($parentrefname, $parentpathname, $refname, $pathname) =
 808                 ($path_info =~ /^(?:(.+?)(?::(.+))?\.\.)?([^:]+?)?(?::(.+))?$/);
 809
 810         # first, analyze the 'current' part
 811         if (defined $pathname) {
 812                 # we got "branch:filename" or "branch:dir/"
 813                 # we could use git_get_type(branch:pathname), but:
 814                 # - it needs $git_dir
 815                 # - it does a git() call
 816                 # - the convention of terminating directories with a slash
 817                 #   makes it superfluous
 818                 # - embedding the action in the PATH_INFO would make it even
 819                 #   more superfluous
 820                 $pathname =~ s,^/+,,;
 821                 if (!$pathname || substr($pathname, -1) eq "/") {
 822                         $input_params{'action'} ||= "tree";
 823                         $pathname =~ s,/$,,;
 824                 } else {
 825                         # the default action depends on whether we had parent info
 826                         # or not
 827                         if ($parentrefname) {
 828                                 $input_params{'action'} ||= "blobdiff_plain";
 829                         } else {
 830                                 $input_params{'action'} ||= "blob_plain";
 831                         }
 832                 }
 833                 $input_params{'hash_base'} ||= $refname;
 834                 $input_params{'file_name'} ||= $pathname;
 835         } elsif (defined $refname) {
 836                 # we got "branch". In this case we have to choose if we have to
 837                 # set hash or hash_base.
 838                 #
 839                 # Most of the actions without a pathname only want hash to be
 840                 # set, except for the ones specified in @wants_base that want
 841                 # hash_base instead. It should also be noted that hand-crafted
 842                 # links having 'history' as an action and no pathname or hash
 843                 # set will fail, but that happens regardless of PATH_INFO.
 844                 if (defined $parentrefname) {
 845                         # if there is parent let the default be 'shortlog' action
 846                         # (for http://git.example.com/repo.git/A..B links); if there
 847                         # is no parent, dispatch will detect type of object and set
 848                         # action appropriately if required (if action is not set)
 849                         $input_params{'action'} ||= "shortlog";
 850                 }
 851                 if ($input_params{'action'} &&
 852                     grep { $_ eq $input_params{'action'} } @wants_base) {
 853                         $input_params{'hash_base'} ||= $refname;
 854                 } else {
 855                         $input_params{'hash'} ||= $refname;
 856                 }
 857         }
 858
 859         # next, handle the 'parent' part, if present
 860         if (defined $parentrefname) {
 861                 # a missing pathspec defaults to the 'current' filename, allowing e.g.
 862                 # someproject/blobdiff/oldrev..newrev:/filename
 863                 if ($parentpathname) {
 864                         $parentpathname =~ s,^/+,,;
 865                         $parentpathname =~ s,/$,,;
 866                         $input_params{'file_parent'} ||= $parentpathname;
 867                 } else {
 868                         $input_params{'file_parent'} ||= $input_params{'file_name'};
 869                 }
 870                 # we assume that hash_parent_base is wanted if a path was specified,
 871                 # or if the action wants hash_base instead of hash
 872                 if (defined $input_params{'file_parent'} ||
 873                         grep { $_ eq $input_params{'action'} } @wants_base) {
 874                         $input_params{'hash_parent_base'} ||= $parentrefname;
 875                 } else {
 876                         $input_params{'hash_parent'} ||= $parentrefname;
 877                 }
 878         }
 879
 880         # for the snapshot action, we allow URLs in the form
 881         # $project/snapshot/$hash.ext
 882         # where .ext determines the snapshot and gets removed from the
 883         # passed $refname to provide the $hash.
 884         #
 885         # To be able to tell that $refname includes the format extension, we
 886         # require the following two conditions to be satisfied:
 887         # - the hash input parameter MUST have been set from the $refname part
 888         #   of the URL (i.e. they must be equal)
 889         # - the snapshot format MUST NOT have been defined already (e.g. from
 890         #   CGI parameter sf)
 891         # It's also useless to try any matching unless $refname has a dot,
 892         # so we check for that too
 893         if (defined $input_params{'action'} &&
 894                 $input_params{'action'} eq 'snapshot' &&
 895                 defined $refname && index($refname, '.') != -1 &&
 896                 $refname eq $input_params{'hash'} &&
 897                 !defined $input_params{'snapshot_format'}) {
 898                 # We loop over the known snapshot formats, checking for
 899                 # extensions. Allowed extensions are both the defined suffix
 900                 # (which includes the initial dot already) and the snapshot
 901                 # format key itself, with a prepended dot
 902                 while (my ($fmt, $opt) = each %known_snapshot_formats) {
 903                         my $hash = $refname;
 904                         unless ($hash =~ s/(\Q$opt->{'suffix'}\E|\Q.$fmt\E)$//) {
 905                                 next;
 906                         }
 907                         my $sfx = $1;
 908                         # a valid suffix was found, so set the snapshot format
 909                         # and reset the hash parameter
 910                         $input_params{'snapshot_format'} = $fmt;
 911                         $input_params{'hash'} = $hash;
 912                         # we also set the format suffix to the one requested
 913                         # in the URL: this way a request for e.g. .tgz returns
 914                         # a .tgz instead of a .tar.gz
 915                         $known_snapshot_formats{$fmt}{'suffix'} = $sfx;
 916                         last;
 917                 }
 918         }
 919 }
 920
 921 our ($action, $project, $file_name, $file_parent, $hash, $hash_parent, $hash_base,
 922      $hash_parent_base, @extra_options, $page, $searchtype, $search_use_regexp,
 923      $searchtext, $search_regexp);
 924 sub evaluate_and_validate_params {
 925         our $action = $input_params{'action'};
 926         if (defined $action) {
 927                 if (!validate_action($action)) {
 928                         die_error(400, "Invalid action parameter");
 929                 }
 930         }
 931
 932         # parameters which are pathnames
 933         our $project = $input_params{'project'};
 934         if (defined $project) {
 935                 if (!validate_project($project)) {
 936                         undef $project;
 937                         die_error(404, "No such project");
 938                 }
 939         }
 940
 941         our $file_name = $input_params{'file_name'};
 942         if (defined $file_name) {
 943                 if (!validate_pathname($file_name)) {
 944                         die_error(400, "Invalid file parameter");
 945                 }
 946         }
 947
 948         our $file_parent = $input_params{'file_parent'};
 949         if (defined $file_parent) {
 950                 if (!validate_pathname($file_parent)) {
 951                         die_error(400, "Invalid file parent parameter");
 952                 }
 953         }
 954
 955         # parameters which are refnames
 956         our $hash = $input_params{'hash'};
 957         if (defined $hash) {
 958                 if (!validate_refname($hash)) {
 959                         die_error(400, "Invalid hash parameter");
 960                 }
 961         }
 962
 963         our $hash_parent = $input_params{'hash_parent'};
 964         if (defined $hash_parent) {
 965                 if (!validate_refname($hash_parent)) {
 966                         die_error(400, "Invalid hash parent parameter");
 967                 }
 968         }
 969
 970         our $hash_base = $input_params{'hash_base'};
 971         if (defined $hash_base) {
 972                 if (!validate_refname($hash_base)) {
 973                         die_error(400, "Invalid hash base parameter");
 974                 }
 975         }
 976
 977         our @extra_options = @{$input_params{'extra_options'}};
 978         # @extra_options is always defined, since it can only be (currently) set from
 979         # CGI, and $cgi->param() returns the empty array in array context if the param
 980         # is not set
 981         foreach my $opt (@extra_options) {
 982                 if (not exists $allowed_options{$opt}) {
 983                         die_error(400, "Invalid option parameter");
 984                 }
 985                 if (not grep(/^$action$/, @{$allowed_options{$opt}})) {
 986                         die_error(400, "Invalid option parameter for this action");
 987                 }
 988         }
 989
 990         our $hash_parent_base = $input_params{'hash_parent_base'};
 991         if (defined $hash_parent_base) {
 992                 if (!validate_refname($hash_parent_base)) {
 993                         die_error(400, "Invalid hash parent base parameter");
 994                 }
 995         }
 996
 997         # other parameters
 998         our $page = $input_params{'page'};
 999         if (defined $page) {
1000                 if ($page =~ m/[^0-9]/) {
1001                         die_error(400, "Invalid page parameter");
1002                 }
1003         }
1004
1005         our $searchtype = $input_params{'searchtype'};
1006         if (defined $searchtype) {
1007                 if ($searchtype =~ m/[^a-z]/) {
1008                         die_error(400, "Invalid searchtype parameter");
1009                 }
1010         }
1011
1012         our $search_use_regexp = $input_params{'search_use_regexp'};
1013
1014         our $searchtext = $input_params{'searchtext'};
1015         our $search_regexp;
1016         if (defined $searchtext) {
1017                 if (length($searchtext) < 2) {
1018                         die_error(403, "At least two characters are required for search parameter");
1019                 }
1020                 $search_regexp = $search_use_regexp ? $searchtext : quotemeta $searchtext;
1021         }
1022 }
1023
1024 # path to the current git repository
1025 our $git_dir;
1026 sub evaluate_git_dir {
1027         our $git_dir = "$projectroot/$project" if $project;
1028 }
1029
1030 our (@snapshot_fmts, $git_avatar);
1031 sub configure_gitweb_features {
1032         # list of supported snapshot formats
1033         our @snapshot_fmts = gitweb_get_feature('snapshot');
1034         @snapshot_fmts = filter_snapshot_fmts(@snapshot_fmts);
1035
1036         # check that the avatar feature is set to a known provider name,
1037         # and for each provider check if the dependencies are satisfied.
1038         # if the provider name is invalid or the dependencies are not met,
1039         # reset $git_avatar to the empty string.
1040         our ($git_avatar) = gitweb_get_feature('avatar');
1041         if ($git_avatar eq 'gravatar') {
1042                 $git_avatar = '' unless (eval { require Digest::MD5; 1; });
1043         } elsif ($git_avatar eq 'picon') {
1044                 # no dependencies
1045         } else {
1046                 $git_avatar = '';
1047         }
1048 }
1049
1050 # custom error handler: 'die <message>' is Internal Server Error
1051 sub handle_errors_html {
1052         my $msg = shift; # it is already HTML escaped
1053
1054         # to avoid infinite loop where error occurs in die_error,
1055         # change handler to default handler, disabling handle_errors_html
1056         set_message("Error occured when inside die_error:\n$msg");
1057
1058         # you cannot jump out of die_error when called as error handler;
1059         # the subroutine set via CGI::Carp::set_message is called _after_
1060         # HTTP headers are already written, so it cannot write them itself
1061         die_error(undef, undef, $msg, -error_handler => 1, -no_http_header => 1);
1062 }
1063 set_message(\&handle_errors_html);
1064
1065 # dispatch
1066 sub dispatch {
1067         if (!defined $action) {
1068                 if (defined $hash) {
1069                         $action = git_get_type($hash);
1070                 } elsif (defined $hash_base && defined $file_name) {
1071                         $action = git_get_type("$hash_base:$file_name");
1072                 } elsif (defined $project) {
1073                         $action = 'summary';
1074                 } else {
1075                         $action = 'project_list';
1076                 }
1077         }
1078         if (!defined($actions{$action})) {
1079                 die_error(400, "Unknown action");
1080         }
1081         if ($action !~ m/^(?:opml|project_list|project_index)$/ &&
1082             !$project) {
1083                 die_error(400, "Project needed");
1084         }
1085         $actions{$action}->();
1086 }
1087
1088 sub reset_timer {
1089         our $t0 = [ gettimeofday() ]
1090                 if defined $t0;
1091         our $number_of_git_cmds = 0;
1092 }
1093
1094 our $first_request = 1;
1095 sub run_request {
1096         reset_timer();
1097
1098         evaluate_uri();
1099         if ($first_request) {
1100                 evaluate_gitweb_config();
1101                 evaluate_git_version();
1102         }
1103         if ($per_request_config) {
1104                 if (ref($per_request_config) eq 'CODE') {
1105                         $per_request_config->();
1106                 } elsif (!$first_request) {
1107                         evaluate_gitweb_config();
1108                 }
1109         }
1110         check_loadavg();
1111
1112         # $projectroot and $projects_list might be set in gitweb config file
1113         $projects_list ||= $projectroot;
1114
1115         evaluate_query_params();
1116         evaluate_path_info();
1117         evaluate_and_validate_params();
1118         evaluate_git_dir();
1119
1120         configure_gitweb_features();
1121
1122         dispatch();
1123 }
1124
1125 our $is_last_request = sub { 1 };
1126 our ($pre_dispatch_hook, $post_dispatch_hook, $pre_listen_hook);
1127 our $CGI = 'CGI';
1128 our $cgi;
1129 sub configure_as_fcgi {
1130         require CGI::Fast;
1131         our $CGI = 'CGI::Fast';
1132
1133         my $request_number = 0;
1134         # let each child service 100 requests
1135         our $is_last_request = sub { ++$request_number > 100 };
1136 }
1137 sub evaluate_argv {
1138         my $script_name = $ENV{'SCRIPT_NAME'} || $ENV{'SCRIPT_FILENAME'} || __FILE__;
1139         configure_as_fcgi()
1140                 if $script_name =~ /\.fcgi$/;
1141
1142         return unless (@ARGV);
1143
1144         require Getopt::Long;
1145         Getopt::Long::GetOptions(
1146                 'fastcgi|fcgi|f' => \&configure_as_fcgi,
1147                 'nproc|n=i' => sub {
1148                         my ($arg, $val) = @_;
1149                         return unless eval { require FCGI::ProcManager; 1; };
1150                         my $proc_manager = FCGI::ProcManager->new({
1151                                 n_processes => $val,
1152                         });
1153                         our $pre_listen_hook    = sub { $proc_manager->pm_manage()        };
1154                         our $pre_dispatch_hook  = sub { $proc_manager->pm_pre_dispatch()  };
1155                         our $post_dispatch_hook = sub { $proc_manager->pm_post_dispatch() };
1156                 },
1157         );
1158 }
1159
1160 sub run {
1161         evaluate_argv();
1162
1163         $first_request = 1;
1164         $pre_listen_hook->()
1165                 if $pre_listen_hook;
1166
1167  REQUEST:
1168         while ($cgi = $CGI->new()) {
1169                 $pre_dispatch_hook->()
1170                         if $pre_dispatch_hook;
1171
1172                 run_request();
1173
1174                 $post_dispatch_hook->()
1175                         if $post_dispatch_hook;
1176                 $first_request = 0;
1177
1178                 last REQUEST if ($is_last_request->());
1179         }
1180
1181  DONE_GITWEB:
1182         1;
1183 }
1184
1185 run();
1186
1187 if (defined caller) {
1188         # wrapped in a subroutine processing requests,
1189         # e.g. mod_perl with ModPerl::Registry, or PSGI with Plack::App::WrapCGI
1190         return;
1191 } else {
1192         # pure CGI script, serving single request
1193         exit;
1194 }
1195
1196 ## ======================================================================
1197 ## action links
1198
1199 # possible values of extra options
1200 # -full => 0|1      - use absolute/full URL ($my_uri/$my_url as base)
1201 # -replay => 1      - start from a current view (replay with modifications)
1202 # -path_info => 0|1 - don't use/use path_info URL (if possible)
1203 sub href {
1204         my %params = @_;
1205         # default is to use -absolute url() i.e. $my_uri
1206         my $href = $params{-full} ? $my_url : $my_uri;
1207
1208         $params{'project'} = $project unless exists $params{'project'};
1209
1210         if ($params{-replay}) {
1211                 while (my ($name, $symbol) = each %cgi_param_mapping) {
1212                         if (!exists $params{$name}) {
1213                                 $params{$name} = $input_params{$name};
1214                         }
1215                 }
1216         }
1217
1218         my $use_pathinfo = gitweb_check_feature('pathinfo');
1219         if (defined $params{'project'} &&
1220             (exists $params{-path_info} ? $params{-path_info} : $use_pathinfo)) {
1221                 # try to put as many parameters as possible in PATH_INFO:
1222                 #   - project name
1223                 #   - action
1224                 #   - hash_parent or hash_parent_base:/file_parent
1225                 #   - hash or hash_base:/filename
1226                 #   - the snapshot_format as an appropriate suffix
1227
1228                 # When the script is the root DirectoryIndex for the domain,
1229                 # $href here would be something like http://gitweb.example.com/
1230                 # Thus, we strip any trailing / from $href, to spare us double
1231                 # slashes in the final URL
1232                 $href =~ s,/$,,;
1233
1234                 # Then add the project name, if present
1235                 $href .= "/".esc_path_info($params{'project'});
1236                 delete $params{'project'};
1237
1238                 # since we destructively absorb parameters, we keep this
1239                 # boolean that remembers if we're handling a snapshot
1240                 my $is_snapshot = $params{'action'} eq 'snapshot';
1241
1242                 # Summary just uses the project path URL, any other action is
1243                 # added to the URL
1244                 if (defined $params{'action'}) {
1245                         $href .= "/".esc_path_info($params{'action'})
1246                                 unless $params{'action'} eq 'summary';
1247                         delete $params{'action'};
1248                 }
1249
1250                 # Next, we put hash_parent_base:/file_parent..hash_base:/file_name,
1251                 # stripping nonexistent or useless pieces
1252                 $href .= "/" if ($params{'hash_base'} || $params{'hash_parent_base'}
1253                         || $params{'hash_parent'} || $params{'hash'});
1254                 if (defined $params{'hash_base'}) {
1255                         if (defined $params{'hash_parent_base'}) {
1256                                 $href .= esc_path_info($params{'hash_parent_base'});
1257                                 # skip the file_parent if it's the same as the file_name
1258                                 if (defined $params{'file_parent'}) {
1259                                         if (defined $params{'file_name'} && $params{'file_parent'} eq $params{'file_name'}) {
1260                                                 delete $params{'file_parent'};
1261                                         } elsif ($params{'file_parent'} !~ /\.\./) {
1262                                                 $href .= ":/".esc_path_info($params{'file_parent'});
1263                                                 delete $params{'file_parent'};
1264                                         }
1265                                 }
1266                                 $href .= "..";
1267                                 delete $params{'hash_parent'};
1268                                 delete $params{'hash_parent_base'};
1269                         } elsif (defined $params{'hash_parent'}) {
1270                                 $href .= esc_path_info($params{'hash_parent'}). "..";
1271                                 delete $params{'hash_parent'};
1272                         }
1273
1274                         $href .= esc_path_info($params{'hash_base'});
1275                         if (defined $params{'file_name'} && $params{'file_name'} !~ /\.\./) {
1276                                 $href .= ":/".esc_path_info($params{'file_name'});
1277                                 delete $params{'file_name'};
1278                         }
1279                         delete $params{'hash'};
1280                         delete $params{'hash_base'};
1281                 } elsif (defined $params{'hash'}) {
1282                         $href .= esc_path_info($params{'hash'});
1283                         delete $params{'hash'};
1284                 }
1285
1286                 # If the action was a snapshot, we can absorb the
1287                 # snapshot_format parameter too
1288                 if ($is_snapshot) {
1289                         my $fmt = $params{'snapshot_format'};
1290                         # snapshot_format should always be defined when href()
1291                         # is called, but just in case some code forgets, we
1292                         # fall back to the default
1293                         $fmt ||= $snapshot_fmts[0];
1294                         $href .= $known_snapshot_formats{$fmt}{'suffix'};
1295                         delete $params{'snapshot_format'};
1296                 }
1297         }
1298
1299         # now encode the parameters explicitly
1300         my @result = ();
1301         for (my $i = 0; $i < @cgi_param_mapping; $i += 2) {
1302                 my ($name, $symbol) = ($cgi_param_mapping[$i], $cgi_param_mapping[$i+1]);
1303                 if (defined $params{$name}) {
1304                         if (ref($params{$name}) eq "ARRAY") {
1305                                 foreach my $par (@{$params{$name}}) {
1306                                         push @result, $symbol . "=" . esc_param($par);
1307                                 }
1308                         } else {
1309                                 push @result, $symbol . "=" . esc_param($params{$name});
1310                         }
1311                 }
1312         }
1313         $href .= "?" . join(';', @result) if scalar @result;
1314
1315         # final transformation: trailing spaces must be escaped (URI-encoded)
1316         $href =~ s/(\s+)$/CGI::escape($1)/e;
1317
1318         return $href;
1319 }
1320
1321
1322 ## ======================================================================
1323 ## validation, quoting/unquoting and escaping
1324
1325 sub validate_action {
1326         my $input = shift || return undef;
1327         return undef unless exists $actions{$input};
1328         return $input;
1329 }
1330
1331 sub validate_project {
1332         my $input = shift || return undef;
1333         if (!validate_pathname($input) ||
1334                 !(-d "$projectroot/$input") ||
1335                 !check_export_ok("$projectroot/$input") ||
1336                 ($strict_export && !project_in_list($input))) {
1337                 return undef;
1338         } else {
1339                 return $input;
1340         }
1341 }
1342
1343 sub validate_pathname {
1344         my $input = shift || return undef;
1345
1346         # no '.' or '..' as elements of path, i.e. no '.' nor '..'
1347         # at the beginning, at the end, and between slashes.
1348         # also this catches doubled slashes
1349         if ($input =~ m!(^|/)(|\.|\.\.)(/|$)!) {
1350                 return undef;
1351         }
1352         # no null characters
1353         if ($input =~ m!\0!) {
1354                 return undef;
1355         }
1356         return $input;
1357 }
1358
1359 sub validate_refname {
1360         my $input = shift || return undef;
1361
1362         # textual hashes are O.K.
1363         if ($input =~ m/^[0-9a-fA-F]{40}$/) {
1364                 return $input;
1365         }
1366         # it must be correct pathname
1367         $input = validate_pathname($input)
1368                 or return undef;
1369         # restrictions on ref name according to git-check-ref-format
1370         if ($input =~ m!(/\.|\.\.|[\000-\040\177 ~^:?*\[]|/$)!) {
1371                 return undef;
1372         }
1373         return $input;
1374 }
1375
1376 # decode sequences of octets in utf8 into Perl's internal form,
1377 # which is utf-8 with utf8 flag set if needed.  gitweb writes out
1378 # in utf-8 thanks to "binmode STDOUT, ':utf8'" at beginning
1379 sub to_utf8 {
1380         my $str = shift;
1381         return undef unless defined $str;
1382         if (utf8::valid($str)) {
1383                 utf8::decode($str);
1384                 return $str;
1385         } else {
1386                 return decode($fallback_encoding, $str, Encode::FB_DEFAULT);
1387         }
1388 }
1389
1390 # quote unsafe chars, but keep the slash, even when it's not
1391 # correct, but quoted slashes look too horrible in bookmarks
1392 sub esc_param {
1393         my $str = shift;
1394         return undef unless defined $str;
1395         $str =~ s/([^A-Za-z0-9\-_.~()\/:@ ]+)/CGI::escape($1)/eg;
1396         $str =~ s/ /\+/g;
1397         return $str;
1398 }
1399
1400 # the quoting rules for path_info fragment are slightly different
1401 sub esc_path_info {
1402         my $str = shift;
1403         return undef unless defined $str;
1404
1405         # path_info doesn't treat '+' as space (specially), but '?' must be escaped
1406         $str =~ s/([^A-Za-z0-9\-_.~();\/;:@&= +]+)/CGI::escape($1)/eg;
1407
1408         return $str;
1409 }
1410
1411 # quote unsafe chars in whole URL, so some characters cannot be quoted
1412 sub esc_url {
1413         my $str = shift;
1414         return undef unless defined $str;
1415         $str =~ s/([^A-Za-z0-9\-_.~();\/;?:@&= ]+)/CGI::escape($1)/eg;
1416         $str =~ s/ /\+/g;
1417         return $str;
1418 }
1419
1420 # quote unsafe characters in HTML attributes
1421 sub esc_attr {
1422
1423         # for XHTML conformance escaping '"' to '&quot;' is not enough
1424         return esc_html(@_);
1425 }
1426
1427 # replace invalid utf8 character with SUBSTITUTION sequence
1428 sub esc_html {
1429         my $str = shift;
1430         my %opts = @_;
1431
1432         return undef unless defined $str;
1433
1434         $str = to_utf8($str);
1435         $str = $cgi->escapeHTML($str);
1436         if ($opts{'-nbsp'}) {
1437                 $str =~ s/ /&nbsp;/g;
1438         }
1439         $str =~ s|([[:cntrl:]])|(($1 ne "\t") ? quot_cec($1) : $1)|eg;
1440         return $str;
1441 }
1442
1443 # quote control characters and escape filename to HTML
1444 sub esc_path {
1445         my $str = shift;
1446         my %opts = @_;
1447
1448         return undef unless defined $str;
1449
1450         $str = to_utf8($str);
1451         $str = $cgi->escapeHTML($str);
1452         if ($opts{'-nbsp'}) {
1453                 $str =~ s/ /&nbsp;/g;
1454         }
1455         $str =~ s|([[:cntrl:]])|quot_cec($1)|eg;
1456         return $str;
1457 }
1458
1459 # Make control characters "printable", using character escape codes (CEC)
1460 sub quot_cec {
1461         my $cntrl = shift;
1462         my %opts = @_;
1463         my %es = ( # character escape codes, aka escape sequences
1464                 "\t" => '\t',   # tab            (HT)
1465                 "\n" => '\n',   # line feed      (LF)
1466                 "\r" => '\r',   # carrige return (CR)
1467                 "\f" => '\f',   # form feed      (FF)
1468                 "\b" => '\b',   # backspace      (BS)
1469                 "\a" => '\a',   # alarm (bell)   (BEL)
1470                 "\e" => '\e',   # escape         (ESC)
1471                 "\013" => '\v', # vertical tab   (VT)
1472                 "\000" => '\0', # nul character  (NUL)
1473         );
1474         my $chr = ( (exists $es{$cntrl})
1475                     ? $es{$cntrl}
1476                     : sprintf('\%2x', ord($cntrl)) );
1477         if ($opts{-nohtml}) {
1478                 return $chr;
1479         } else {
1480                 return "<span class=\"cntrl\">$chr</span>";
1481         }
1482 }
1483
1484 # Alternatively use unicode control pictures codepoints,
1485 # Unicode "printable representation" (PR)
1486 sub quot_upr {
1487         my $cntrl = shift;
1488         my %opts = @_;
1489
1490         my $chr = sprintf('&#%04d;', 0x2400+ord($cntrl));
1491         if ($opts{-nohtml}) {
1492                 return $chr;
1493         } else {
1494                 return "<span class=\"cntrl\">$chr</span>";
1495         }
1496 }
1497
1498 # git may return quoted and escaped filenames
1499 sub unquote {
1500         my $str = shift;
1501
1502         sub unq {
1503                 my $seq = shift;
1504                 my %es = ( # character escape codes, aka escape sequences
1505                         't' => "\t",   # tab            (HT, TAB)
1506                         'n' => "\n",   # newline        (NL)
1507                         'r' => "\r",   # return         (CR)
1508                         'f' => "\f",   # form feed      (FF)
1509                         'b' => "\b",   # backspace      (BS)
1510                         'a' => "\a",   # alarm (bell)   (BEL)
1511                         'e' => "\e",   # escape         (ESC)
1512                         'v' => "\013", # vertical tab   (VT)
1513                 );
1514
1515                 if ($seq =~ m/^[0-7]{1,3}$/) {
1516                         # octal char sequence
1517                         return chr(oct($seq));
1518                 } elsif (exists $es{$seq}) {
1519                         # C escape sequence, aka character escape code
1520                         return $es{$seq};
1521                 }
1522                 # quoted ordinary character
1523                 return $seq;
1524         }
1525
1526         if ($str =~ m/^"(.*)"$/) {
1527                 # needs unquoting
1528                 $str = $1;
1529                 $str =~ s/\\([^0-7]|[0-7]{1,3})/unq($1)/eg;
1530         }
1531         return $str;
1532 }
1533
1534 # escape tabs (convert tabs to spaces)
1535 sub untabify {
1536         my $line = shift;
1537
1538         while ((my $pos = index($line, "\t")) != -1) {
1539                 if (my $count = (8 - ($pos % 8))) {
1540                         my $spaces = ' ' x $count;
1541                         $line =~ s/\t/$spaces/;
1542                 }
1543         }
1544
1545         return $line;
1546 }
1547
1548 sub project_in_list {
1549         my $project = shift;
1550         my @list = git_get_projects_list();
1551         return @list && scalar(grep { $_->{'path'} eq $project } @list);
1552 }
1553
1554 ## ----------------------------------------------------------------------
1555 ## HTML aware string manipulation
1556
1557 # Try to chop given string on a word boundary between position
1558 # $len and $len+$add_len. If there is no word boundary there,
1559 # chop at $len+$add_len. Do not chop if chopped part plus ellipsis
1560 # (marking chopped part) would be longer than given string.
1561 sub chop_str {
1562         my $str = shift;
1563         my $len = shift;
1564         my $add_len = shift || 10;
1565         my $where = shift || 'right'; # 'left' | 'center' | 'right'
1566
1567         # Make sure perl knows it is utf8 encoded so we don't
1568         # cut in the middle of a utf8 multibyte char.
1569         $str = to_utf8($str);
1570
1571         # allow only $len chars, but don't cut a word if it would fit in $add_len
1572         # if it doesn't fit, cut it if it's still longer than the dots we would add
1573         # remove chopped character entities entirely
1574
1575         # when chopping in the middle, distribute $len into left and right part
1576         # return early if chopping wouldn't make string shorter
1577         if ($where eq 'center') {
1578                 return $str if ($len + 5 >= length($str)); # filler is length 5
1579                 $len = int($len/2);
1580         } else {
1581                 return $str if ($len + 4 >= length($str)); # filler is length 4
1582         }
1583
1584         # regexps: ending and beginning with word part up to $add_len
1585         my $endre = qr/.{$len}\w{0,$add_len}/;
1586         my $begre = qr/\w{0,$add_len}.{$len}/;
1587
1588         if ($where eq 'left') {
1589                 $str =~ m/^(.*?)($begre)$/;
1590                 my ($lead, $body) = ($1, $2);
1591                 if (length($lead) > 4) {
1592                         $lead = " ...";
1593                 }
1594                 return "$lead$body";
1595
1596         } elsif ($where eq 'center') {
1597                 $str =~ m/^($endre)(.*)$/;
1598                 my ($left, $str)  = ($1, $2);
1599                 $str =~ m/^(.*?)($begre)$/;
1600                 my ($mid, $right) = ($1, $2);
1601                 if (length($mid) > 5) {
1602                         $mid = " ... ";
1603                 }
1604                 return "$left$mid$right";
1605
1606         } else {
1607                 $str =~ m/^($endre)(.*)$/;
1608                 my $body = $1;
1609                 my $tail = $2;
1610                 if (length($tail) > 4) {
1611                         $tail = "... ";
1612                 }
1613                 return "$body$tail";
1614         }
1615 }
1616
1617 # takes the same arguments as chop_str, but also wraps a <span> around the
1618 # result with a title attribute if it does get chopped. Additionally, the
1619 # string is HTML-escaped.
1620 sub chop_and_escape_str {
1621         my ($str) = @_;
1622
1623         my $chopped = chop_str(@_);
1624         if ($chopped eq $str) {
1625                 return esc_html($chopped);
1626         } else {
1627                 $str =~ s/[[:cntrl:]]/?/g;
1628                 return $cgi->span({-title=>$str}, esc_html($chopped));
1629         }
1630 }
1631
1632 ## ----------------------------------------------------------------------
1633 ## functions returning short strings
1634
1635 # CSS class for given age value (in seconds)
1636 sub age_class {
1637         my $age = shift;
1638
1639         if (!defined $age) {
1640                 return "noage";
1641         } elsif ($age < 60*60*2) {
1642                 return "age0";
1643         } elsif ($age < 60*60*24*2) {
1644                 return "age1";
1645         } else {
1646                 return "age2";
1647         }
1648 }
1649
1650 # convert age in seconds to "nn units ago" string
1651 sub age_string {
1652         my $age = shift;
1653         my $age_str;
1654
1655         if ($age > 60*60*24*365*2) {
1656                 $age_str = (int $age/60/60/24/365);
1657                 $age_str .= " years ago";
1658         } elsif ($age > 60*60*24*(365/12)*2) {
1659                 $age_str = int $age/60/60/24/(365/12);
1660                 $age_str .= " months ago";
1661         } elsif ($age > 60*60*24*7*2) {
1662                 $age_str = int $age/60/60/24/7;
1663                 $age_str .= " weeks ago";
1664         } elsif ($age > 60*60*24*2) {
1665                 $age_str = int $age/60/60/24;
1666                 $age_str .= " days ago";
1667         } elsif ($age > 60*60*2) {
1668                 $age_str = int $age/60/60;
1669                 $age_str .= " hours ago";
1670         } elsif ($age > 60*2) {
1671                 $age_str = int $age/60;
1672                 $age_str .= " min ago";
1673         } elsif ($age > 2) {
1674                 $age_str = int $age;
1675                 $age_str .= " sec ago";
1676         } else {
1677                 $age_str .= " right now";
1678         }
1679         return $age_str;
1680 }
1681
1682 use constant {
1683         S_IFINVALID => 0030000,
1684         S_IFGITLINK => 0160000,
1685 };
1686
1687 # submodule/subproject, a commit object reference
1688 sub S_ISGITLINK {
1689         my $mode = shift;
1690
1691         return (($mode & S_IFMT) == S_IFGITLINK)
1692 }
1693
1694 # convert file mode in octal to symbolic file mode string
1695 sub mode_str {
1696         my $mode = oct shift;
1697
1698         if (S_ISGITLINK($mode)) {
1699                 return 'm---------';
1700         } elsif (S_ISDIR($mode & S_IFMT)) {
1701                 return 'drwxr-xr-x';
1702         } elsif (S_ISLNK($mode)) {
1703                 return 'lrwxrwxrwx';
1704         } elsif (S_ISREG($mode)) {
1705                 # git cares only about the executable bit
1706                 if ($mode & S_IXUSR) {
1707                         return '-rwxr-xr-x';
1708                 } else {
1709                         return '-rw-r--r--';
1710                 };
1711         } else {
1712                 return '----------';
1713         }
1714 }
1715
1716 # convert file mode in octal to file type string
1717 sub file_type {
1718         my $mode = shift;
1719
1720         if ($mode !~ m/^[0-7]+$/) {
1721                 return $mode;
1722         } else {
1723                 $mode = oct $mode;
1724         }
1725
1726         if (S_ISGITLINK($mode)) {
1727                 return "submodule";
1728         } elsif (S_ISDIR($mode & S_IFMT)) {
1729                 return "directory";
1730         } elsif (S_ISLNK($mode)) {
1731                 return "symlink";
1732         } elsif (S_ISREG($mode)) {
1733                 return "file";
1734         } else {
1735                 return "unknown";
1736         }
1737 }
1738
1739 # convert file mode in octal to file type description string
1740 sub file_type_long {
1741         my $mode = shift;
1742
1743         if ($mode !~ m/^[0-7]+$/) {
1744                 return $mode;
1745         } else {
1746                 $mode = oct $mode;
1747         }
1748
1749         if (S_ISGITLINK($mode)) {
1750                 return "submodule";
1751         } elsif (S_ISDIR($mode & S_IFMT)) {
1752                 return "directory";
1753         } elsif (S_ISLNK($mode)) {
1754                 return "symlink";
1755         } elsif (S_ISREG($mode)) {
1756                 if ($mode & S_IXUSR) {
1757                         return "executable";
1758                 } else {
1759                         return "file";
1760                 };
1761         } else {
1762                 return "unknown";
1763         }
1764 }
1765
1766
1767 ## ----------------------------------------------------------------------
1768 ## functions returning short HTML fragments, or transforming HTML fragments
1769 ## which don't belong to other sections
1770
1771 # format line of commit message.
1772 sub format_log_line_html {
1773         my $line = shift;
1774
1775         $line = esc_html($line, -nbsp=>1);
1776         $line =~ s{\b([0-9a-fA-F]{8,40})\b}{
1777                 $cgi->a({-href => href(action=>"object", hash=>$1),
1778                                         -class => "text"}, $1);
1779         }eg;
1780
1781         return $line;
1782 }
1783
1784 # format marker of refs pointing to given object
1785
1786 # the destination action is chosen based on object type and current context:
1787 # - for annotated tags, we choose the tag view unless it's the current view
1788 #   already, in which case we go to shortlog view
1789 # - for other refs, we keep the current view if we're in history, shortlog or
1790 #   log view, and select shortlog otherwise
1791 sub format_ref_marker {
1792         my ($refs, $id) = @_;
1793         my $markers = '';
1794
1795         if (defined $refs->{$id}) {
1796                 foreach my $ref (@{$refs->{$id}}) {
1797                         # this code exploits the fact that non-lightweight tags are the
1798                         # only indirect objects, and that they are the only objects for which
1799                         # we want to use tag instead of shortlog as action
1800                         my ($type, $name) = qw();
1801                         my $indirect = ($ref =~ s/\^\{\}$//);
1802                         # e.g. tags/v2.6.11 or heads/next
1803                         if ($ref =~ m!^(.*?)s?/(.*)$!) {
1804                                 $type = $1;
1805                                 $name = $2;
1806                         } else {
1807                                 $type = "ref";
1808                                 $name = $ref;
1809                         }
1810
1811                         my $class = $type;
1812                         $class .= " indirect" if $indirect;
1813
1814                         my $dest_action = "shortlog";
1815
1816                         if ($indirect) {
1817                                 $dest_action = "tag" unless $action eq "tag";
1818                         } elsif ($action =~ /^(history|(short)?log)$/) {
1819                                 $dest_action = $action;
1820                         }
1821
1822                         my $dest = "";
1823                         $dest .= "refs/" unless $ref =~ m!^refs/!;
1824                         $dest .= $ref;
1825
1826                         my $link = $cgi->a({
1827                                 -href => href(
1828                                         action=>$dest_action,
1829                                         hash=>$dest
1830                                 )}, $name);
1831
1832                         $markers .= " <span class=\"".esc_attr($class)."\" title=\"".esc_attr($ref)."\">" .
1833                                 $link . "</span>";
1834                 }
1835         }
1836
1837         if ($markers) {
1838                 return ' <span class="refs">'. $markers . '</span>';
1839         } else {
1840                 return "";
1841         }
1842 }
1843
1844 # format, perhaps shortened and with markers, title line
1845 sub format_subject_html {
1846         my ($long, $short, $href, $extra) = @_;
1847         $extra = '' unless defined($extra);
1848
1849         if (length($short) < length($long)) {
1850                 $long =~ s/[[:cntrl:]]/?/g;
1851                 return $cgi->a({-href => $href, -class => "list subject",
1852                                 -title => to_utf8($long)},
1853                        esc_html($short)) . $extra;
1854         } else {
1855                 return $cgi->a({-href => $href, -class => "list subject"},
1856                        esc_html($long)) . $extra;
1857         }
1858 }
1859
1860 # Rather than recomputing the url for an email multiple times, we cache it
1861 # after the first hit. This gives a visible benefit in views where the avatar
1862 # for the same email is used repeatedly (e.g. shortlog).
1863 # The cache is shared by all avatar engines (currently gravatar only), which
1864 # are free to use it as preferred. Since only one avatar engine is used for any
1865 # given page, there's no risk for cache conflicts.
1866 our %avatar_cache = ();
1867
1868 # Compute the picon url for a given email, by using the picon search service over at
1869 # http://www.cs.indiana.edu/picons/search.html
1870 sub picon_url {
1871         my $email = lc shift;
1872         if (!$avatar_cache{$email}) {
1873                 my ($user, $domain) = split('@', $email);
1874                 $avatar_cache{$email} =
1875                         "http://www.cs.indiana.edu/cgi-pub/kinzler/piconsearch.cgi/" .
1876                         "$domain/$user/" .
1877                         "users+domains+unknown/up/single";
1878         }
1879         return $avatar_cache{$email};
1880 }
1881
1882 # Compute the gravatar url for a given email, if it's not in the cache already.
1883 # Gravatar stores only the part of the URL before the size, since that's the
1884 # one computationally more expensive. This also allows reuse of the cache for
1885 # different sizes (for this particular engine).
1886 sub gravatar_url {
1887         my $email = lc shift;
1888         my $size = shift;
1889         $avatar_cache{$email} ||=
1890                 "http://www.gravatar.com/avatar/" .
1891                         Digest::MD5::md5_hex($email) . "?s=";
1892         return $avatar_cache{$email} . $size;
1893 }
1894
1895 # Insert an avatar for the given $email at the given $size if the feature
1896 # is enabled.
1897 sub git_get_avatar {
1898         my ($email, %opts) = @_;
1899         my $pre_white  = ($opts{-pad_before} ? "&nbsp;" : "");
1900         my $post_white = ($opts{-pad_after}  ? "&nbsp;" : "");
1901         $opts{-size} ||= 'default';
1902         my $size = $avatar_size{$opts{-size}} || $avatar_size{'default'};
1903         my $url = "";
1904         if ($git_avatar eq 'gravatar') {
1905                 $url = gravatar_url($email, $size);
1906         } elsif ($git_avatar eq 'picon') {
1907                 $url = picon_url($email);
1908         }
1909         # Other providers can be added by extending the if chain, defining $url
1910         # as needed. If no variant puts something in $url, we assume avatars
1911         # are completely disabled/unavailable.
1912         if ($url) {
1913                 return $pre_white .
1914                        "<img width=\"$size\" " .
1915                             "class=\"avatar\" " .
1916                             "src=\"".esc_url($url)."\" " .
1917                             "alt=\"\" " .
1918                        "/>" . $post_white;
1919         } else {
1920                 return "";
1921         }
1922 }
1923
1924 sub format_search_author {
1925         my ($author, $searchtype, $displaytext) = @_;
1926         my $have_search = gitweb_check_feature('search');
1927
1928         if ($have_search) {
1929                 my $performed = "";
1930                 if ($searchtype eq 'author') {
1931                         $performed = "authored";
1932                 } elsif ($searchtype eq 'committer') {
1933                         $performed = "committed";
1934                 }
1935
1936                 return $cgi->a({-href => href(action=>"search", hash=>$hash,
1937                                 searchtext=>$author,
1938                                 searchtype=>$searchtype), class=>"list",
1939                                 title=>"Search for commits $performed by $author"},
1940                                 $displaytext);
1941
1942         } else {
1943                 return $displaytext;
1944         }
1945 }
1946
1947 # format the author name of the given commit with the given tag
1948 # the author name is chopped and escaped according to the other
1949 # optional parameters (see chop_str).
1950 sub format_author_html {
1951         my $tag = shift;
1952         my $co = shift;
1953         my $author = chop_and_escape_str($co->{'author_name'}, @_);
1954         return "<$tag class=\"author\">" .
1955                format_search_author($co->{'author_name'}, "author",
1956                        git_get_avatar($co->{'author_email'}, -pad_after => 1) .
1957                        $author) .
1958                "</$tag>";
1959 }
1960
1961 # format git diff header line, i.e. "diff --(git|combined|cc) ..."
1962 sub format_git_diff_header_line {
1963         my $line = shift;
1964         my $diffinfo = shift;
1965         my ($from, $to) = @_;
1966
1967         if ($diffinfo->{'nparents'}) {
1968                 # combined diff
1969                 $line =~ s!^(diff (.*?) )"?.*$!$1!;
1970                 if ($to->{'href'}) {
1971                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
1972                                          esc_path($to->{'file'}));
1973                 } else { # file was deleted (no href)
1974                         $line .= esc_path($to->{'file'});
1975                 }
1976         } else {
1977                 # "ordinary" diff
1978                 $line =~ s!^(diff (.*?) )"?a/.*$!$1!;
1979                 if ($from->{'href'}) {
1980                         $line .= $cgi->a({-href => $from->{'href'}, -class => "path"},
1981                                          'a/' . esc_path($from->{'file'}));
1982                 } else { # file was added (no href)
1983                         $line .= 'a/' . esc_path($from->{'file'});
1984                 }
1985                 $line .= ' ';
1986                 if ($to->{'href'}) {
1987                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
1988                                          'b/' . esc_path($to->{'file'}));
1989                 } else { # file was deleted
1990                         $line .= 'b/' . esc_path($to->{'file'});
1991                 }
1992         }
1993
1994         return "<div class=\"diff header\">$line</div>\n";
1995 }
1996
1997 # format extended diff header line, before patch itself
1998 sub format_extended_diff_header_line {
1999         my $line = shift;
2000         my $diffinfo = shift;
2001         my ($from, $to) = @_;
2002
2003         # match <path>
2004         if ($line =~ s!^((copy|rename) from ).*$!$1! && $from->{'href'}) {
2005                 $line .= $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2006                                        esc_path($from->{'file'}));
2007         }
2008         if ($line =~ s!^((copy|rename) to ).*$!$1! && $to->{'href'}) {
2009                 $line .= $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2010                                  esc_path($to->{'file'}));
2011         }
2012         # match single <mode>
2013         if ($line =~ m/\s(\d{6})$/) {
2014                 $line .= '<span class="info"> (' .
2015                          file_type_long($1) .
2016                          ')</span>';
2017         }
2018         # match <hash>
2019         if ($line =~ m/^index [0-9a-fA-F]{40},[0-9a-fA-F]{40}/) {
2020                 # can match only for combined diff
2021                 $line = 'index ';
2022                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2023                         if ($from->{'href'}[$i]) {
2024                                 $line .= $cgi->a({-href=>$from->{'href'}[$i],
2025                                                   -class=>"hash"},
2026                                                  substr($diffinfo->{'from_id'}[$i],0,7));
2027                         } else {
2028                                 $line .= '0' x 7;
2029                         }
2030                         # separator
2031                         $line .= ',' if ($i < $diffinfo->{'nparents'} - 1);
2032                 }
2033                 $line .= '..';
2034                 if ($to->{'href'}) {
2035                         $line .= $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2036                                          substr($diffinfo->{'to_id'},0,7));
2037                 } else {
2038                         $line .= '0' x 7;
2039                 }
2040
2041         } elsif ($line =~ m/^index [0-9a-fA-F]{40}..[0-9a-fA-F]{40}/) {
2042                 # can match only for ordinary diff
2043                 my ($from_link, $to_link);
2044                 if ($from->{'href'}) {
2045                         $from_link = $cgi->a({-href=>$from->{'href'}, -class=>"hash"},
2046                                              substr($diffinfo->{'from_id'},0,7));
2047                 } else {
2048                         $from_link = '0' x 7;
2049                 }
2050                 if ($to->{'href'}) {
2051                         $to_link = $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2052                                            substr($diffinfo->{'to_id'},0,7));
2053                 } else {
2054                         $to_link = '0' x 7;
2055                 }
2056                 my ($from_id, $to_id) = ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
2057                 $line =~ s!$from_id\.\.$to_id!$from_link..$to_link!;
2058         }
2059
2060         return $line . "<br/>\n";
2061 }
2062
2063 # format from-file/to-file diff header
2064 sub format_diff_from_to_header {
2065         my ($from_line, $to_line, $diffinfo, $from, $to, @parents) = @_;
2066         my $line;
2067         my $result = '';
2068
2069         $line = $from_line;
2070         #assert($line =~ m/^---/) if DEBUG;
2071         # no extra formatting for "^--- /dev/null"
2072         if (! $diffinfo->{'nparents'}) {
2073                 # ordinary (single parent) diff
2074                 if ($line =~ m!^--- "?a/!) {
2075                         if ($from->{'href'}) {
2076                                 $line = '--- a/' .
2077                                         $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2078                                                 esc_path($from->{'file'}));
2079                         } else {
2080                                 $line = '--- a/' .
2081                                         esc_path($from->{'file'});
2082                         }
2083                 }
2084                 $result .= qq!<div class="diff from_file">$line</div>\n!;
2085
2086         } else {
2087                 # combined diff (merge commit)
2088                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2089                         if ($from->{'href'}[$i]) {
2090                                 $line = '--- ' .
2091                                         $cgi->a({-href=>href(action=>"blobdiff",
2092                                                              hash_parent=>$diffinfo->{'from_id'}[$i],
2093                                                              hash_parent_base=>$parents[$i],
2094                                                              file_parent=>$from->{'file'}[$i],
2095                                                              hash=>$diffinfo->{'to_id'},
2096                                                              hash_base=>$hash,
2097                                                              file_name=>$to->{'file'}),
2098                                                  -class=>"path",
2099                                                  -title=>"diff" . ($i+1)},
2100                                                 $i+1) .
2101                                         '/' .
2102                                         $cgi->a({-href=>$from->{'href'}[$i], -class=>"path"},
2103                                                 esc_path($from->{'file'}[$i]));
2104                         } else {
2105                                 $line = '--- /dev/null';
2106                         }
2107                         $result .= qq!<div class="diff from_file">$line</div>\n!;
2108                 }
2109         }
2110
2111         $line = $to_line;
2112         #assert($line =~ m/^\+\+\+/) if DEBUG;
2113         # no extra formatting for "^+++ /dev/null"
2114         if ($line =~ m!^\+\+\+ "?b/!) {
2115                 if ($to->{'href'}) {
2116                         $line = '+++ b/' .
2117                                 $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2118                                         esc_path($to->{'file'}));
2119                 } else {
2120                         $line = '+++ b/' .
2121                                 esc_path($to->{'file'});
2122                 }
2123         }
2124         $result .= qq!<div class="diff to_file">$line</div>\n!;
2125
2126         return $result;
2127 }
2128
2129 # create note for patch simplified by combined diff
2130 sub format_diff_cc_simplified {
2131         my ($diffinfo, @parents) = @_;
2132         my $result = '';
2133
2134         $result .= "<div class=\"diff header\">" .
2135                    "diff --cc ";
2136         if (!is_deleted($diffinfo)) {
2137                 $result .= $cgi->a({-href => href(action=>"blob",
2138                                                   hash_base=>$hash,
2139                                                   hash=>$diffinfo->{'to_id'},
2140                                                   file_name=>$diffinfo->{'to_file'}),
2141                                     -class => "path"},
2142                                    esc_path($diffinfo->{'to_file'}));
2143         } else {
2144                 $result .= esc_path($diffinfo->{'to_file'});
2145         }
2146         $result .= "</div>\n" . # class="diff header"
2147                    "<div class=\"diff nodifferences\">" .
2148                    "Simple merge" .
2149                    "</div>\n"; # class="diff nodifferences"
2150
2151         return $result;
2152 }
2153
2154 # format patch (diff) line (not to be used for diff headers)
2155 sub format_diff_line {
2156         my $line = shift;
2157         my ($from, $to) = @_;
2158         my $diff_class = "";
2159
2160         chomp $line;
2161
2162         if ($from && $to && ref($from->{'href'}) eq "ARRAY") {
2163                 # combined diff
2164                 my $prefix = substr($line, 0, scalar @{$from->{'href'}});
2165                 if ($line =~ m/^\@{3}/) {
2166                         $diff_class = " chunk_header";
2167                 } elsif ($line =~ m/^\\/) {
2168                         $diff_class = " incomplete";
2169                 } elsif ($prefix =~ tr/+/+/) {
2170                         $diff_class = " add";
2171                 } elsif ($prefix =~ tr/-/-/) {
2172                         $diff_class = " rem";
2173                 }
2174         } else {
2175                 # assume ordinary diff
2176                 my $char = substr($line, 0, 1);
2177                 if ($char eq '+') {
2178                         $diff_class = " add";
2179                 } elsif ($char eq '-') {
2180                         $diff_class = " rem";
2181                 } elsif ($char eq '@') {
2182                         $diff_class = " chunk_header";
2183                 } elsif ($char eq "\\") {
2184                         $diff_class = " incomplete";
2185                 }
2186         }
2187         $line = untabify($line);
2188         if ($from && $to && $line =~ m/^\@{2} /) {
2189                 my ($from_text, $from_start, $from_lines, $to_text, $to_start, $to_lines, $section) =
2190                         $line =~ m/^\@{2} (-(\d+)(?:,(\d+))?) (\+(\d+)(?:,(\d+))?) \@{2}(.*)$/;
2191
2192                 $from_lines = 0 unless defined $from_lines;
2193                 $to_lines   = 0 unless defined $to_lines;
2194
2195                 if ($from->{'href'}) {
2196                         $from_text = $cgi->a({-href=>"$from->{'href'}#l$from_start",
2197                                              -class=>"list"}, $from_text);
2198                 }
2199                 if ($to->{'href'}) {
2200                         $to_text   = $cgi->a({-href=>"$to->{'href'}#l$to_start",
2201                                              -class=>"list"}, $to_text);
2202                 }
2203                 $line = "<span class=\"chunk_info\">@@ $from_text $to_text @@</span>" .
2204                         "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2205                 return "<div class=\"diff$diff_class\">$line</div>\n";
2206         } elsif ($from && $to && $line =~ m/^\@{3}/) {
2207                 my ($prefix, $ranges, $section) = $line =~ m/^(\@+) (.*?) \@+(.*)$/;
2208                 my (@from_text, @from_start, @from_nlines, $to_text, $to_start, $to_nlines);
2209
2210                 @from_text = split(' ', $ranges);
2211                 for (my $i = 0; $i < @from_text; ++$i) {
2212                         ($from_start[$i], $from_nlines[$i]) =
2213                                 (split(',', substr($from_text[$i], 1)), 0);
2214                 }
2215
2216                 $to_text   = pop @from_text;
2217                 $to_start  = pop @from_start;
2218                 $to_nlines = pop @from_nlines;
2219
2220                 $line = "<span class=\"chunk_info\">$prefix ";
2221                 for (my $i = 0; $i < @from_text; ++$i) {
2222                         if ($from->{'href'}[$i]) {
2223                                 $line .= $cgi->a({-href=>"$from->{'href'}[$i]#l$from_start[$i]",
2224                                                   -class=>"list"}, $from_text[$i]);
2225                         } else {
2226                                 $line .= $from_text[$i];
2227                         }
2228                         $line .= " ";
2229                 }
2230                 if ($to->{'href'}) {
2231                         $line .= $cgi->a({-href=>"$to->{'href'}#l$to_start",
2232                                           -class=>"list"}, $to_text);
2233                 } else {
2234                         $line .= $to_text;
2235                 }
2236                 $line .= " $prefix</span>" .
2237                          "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2238                 return "<div class=\"diff$diff_class\">$line</div>\n";
2239         }
2240         return "<div class=\"diff$diff_class\">" . esc_html($line, -nbsp=>1) . "</div>\n";
2241 }
2242
2243 # Generates undef or something like "_snapshot_" or "snapshot (_tbz2_ _zip_)",
2244 # linked.  Pass the hash of the tree/commit to snapshot.
2245 sub format_snapshot_links {
2246         my ($hash) = @_;
2247         my $num_fmts = @snapshot_fmts;
2248         if ($num_fmts > 1) {
2249                 # A parenthesized list of links bearing format names.
2250                 # e.g. "snapshot (_tar.gz_ _zip_)"
2251                 return "snapshot (" . join(' ', map
2252                         $cgi->a({
2253                                 -href => href(
2254                                         action=>"snapshot",
2255                                         hash=>$hash,
2256                                         snapshot_format=>$_
2257                                 )
2258                         }, $known_snapshot_formats{$_}{'display'})
2259                 , @snapshot_fmts) . ")";
2260         } elsif ($num_fmts == 1) {
2261                 # A single "snapshot" link whose tooltip bears the format name.
2262                 # i.e. "_snapshot_"
2263                 my ($fmt) = @snapshot_fmts;
2264                 return
2265                         $cgi->a({
2266                                 -href => href(
2267                                         action=>"snapshot",
2268                                         hash=>$hash,
2269                                         snapshot_format=>$fmt
2270                                 ),
2271                                 -title => "in format: $known_snapshot_formats{$fmt}{'display'}"
2272                         }, "snapshot");
2273         } else { # $num_fmts == 0
2274                 return undef;
2275         }
2276 }
2277
2278 ## ......................................................................
2279 ## functions returning values to be passed, perhaps after some
2280 ## transformation, to other functions; e.g. returning arguments to href()
2281
2282 # returns hash to be passed to href to generate gitweb URL
2283 # in -title key it returns description of link
2284 sub get_feed_info {
2285         my $format = shift || 'Atom';
2286         my %res = (action => lc($format));
2287
2288         # feed links are possible only for project views
2289         return unless (defined $project);
2290         # some views should link to OPML, or to generic project feed,
2291         # or don't have specific feed yet (so they should use generic)
2292         return if ($action =~ /^(?:tags|heads|forks|tag|search)$/x);
2293
2294         my $branch;
2295         # branches refs uses 'refs/heads/' prefix (fullname) to differentiate
2296         # from tag links; this also makes possible to detect branch links
2297         if ((defined $hash_base && $hash_base =~ m!^refs/heads/(.*)$!) ||
2298             (defined $hash      && $hash      =~ m!^refs/heads/(.*)$!)) {
2299                 $branch = $1;
2300         }
2301         # find log type for feed description (title)
2302         my $type = 'log';
2303         if (defined $file_name) {
2304                 $type  = "history of $file_name";
2305                 $type .= "/" if ($action eq 'tree');
2306                 $type .= " on '$branch'" if (defined $branch);
2307         } else {
2308                 $type = "log of $branch" if (defined $branch);
2309         }
2310
2311         $res{-title} = $type;
2312         $res{'hash'} = (defined $branch ? "refs/heads/$branch" : undef);
2313         $res{'file_name'} = $file_name;
2314
2315         return %res;
2316 }
2317
2318 ## ----------------------------------------------------------------------
2319 ## git utility subroutines, invoking git commands
2320
2321 # returns path to the core git executable and the --git-dir parameter as list
2322 sub git_cmd {
2323         $number_of_git_cmds++;
2324         return $GIT, '--git-dir='.$git_dir;
2325 }
2326
2327 # quote the given arguments for passing them to the shell
2328 # quote_command("command", "arg 1", "arg with ' and ! characters")
2329 # => "'command' 'arg 1' 'arg with '\'' and '\!' characters'"
2330 # Try to avoid using this function wherever possible.
2331 sub quote_command {
2332         return join(' ',
2333                 map { my $a = $_; $a =~ s/(['!])/'\\$1'/g; "'$a'" } @_ );
2334 }
2335
2336 # get HEAD ref of given project as hash
2337 sub git_get_head_hash {
2338         return git_get_full_hash(shift, 'HEAD');
2339 }
2340
2341 sub git_get_full_hash {
2342         return git_get_hash(@_);
2343 }
2344
2345 sub git_get_short_hash {
2346         return git_get_hash(@_, '--short=7');
2347 }
2348
2349 sub git_get_hash {
2350         my ($project, $hash, @options) = @_;
2351         my $o_git_dir = $git_dir;
2352         my $retval = undef;
2353         $git_dir = "$projectroot/$project";
2354         if (open my $fd, '-|', git_cmd(), 'rev-parse',
2355             '--verify', '-q', @options, $hash) {
2356                 $retval = <$fd>;
2357                 chomp $retval if defined $retval;
2358                 close $fd;
2359         }
2360         if (defined $o_git_dir) {
2361                 $git_dir = $o_git_dir;
2362         }
2363         return $retval;
2364 }
2365
2366 # get type of given object
2367 sub git_get_type {
2368         my $hash = shift;
2369
2370         open my $fd, "-|", git_cmd(), "cat-file", '-t', $hash or return;
2371         my $type = <$fd>;
2372         close $fd or return;
2373         chomp $type;
2374         return $type;
2375 }
2376
2377 # repository configuration
2378 our $config_file = '';
2379 our %config;
2380
2381 # store multiple values for single key as anonymous array reference
2382 # single values stored directly in the hash, not as [ <value> ]
2383 sub hash_set_multi {
2384         my ($hash, $key, $value) = @_;
2385
2386         if (!exists $hash->{$key}) {
2387                 $hash->{$key} = $value;
2388         } elsif (!ref $hash->{$key}) {
2389                 $hash->{$key} = [ $hash->{$key}, $value ];
2390         } else {
2391                 push @{$hash->{$key}}, $value;
2392         }
2393 }
2394
2395 # return hash of git project configuration
2396 # optionally limited to some section, e.g. 'gitweb'
2397 sub git_parse_project_config {
2398         my $section_regexp = shift;
2399         my %config;
2400
2401         local $/ = "\0";
2402
2403         open my $fh, "-|", git_cmd(), "config", '-z', '-l',
2404                 or return;
2405
2406         while (my $keyval = <$fh>) {
2407                 chomp $keyval;
2408                 my ($key, $value) = split(/\n/, $keyval, 2);
2409
2410                 hash_set_multi(\%config, $key, $value)
2411                         if (!defined $section_regexp || $key =~ /^(?:$section_regexp)\./o);
2412         }
2413         close $fh;
2414
2415         return %config;
2416 }
2417
2418 # convert config value to boolean: 'true' or 'false'
2419 # no value, number > 0, 'true' and 'yes' values are true
2420 # rest of values are treated as false (never as error)
2421 sub config_to_bool {
2422         my $val = shift;
2423
2424         return 1 if !defined $val;             # section.key
2425
2426         # strip leading and trailing whitespace
2427         $val =~ s/^\s+//;
2428         $val =~ s/\s+$//;
2429
2430         return (($val =~ /^\d+$/ && $val) ||   # section.key = 1
2431                 ($val =~ /^(?:true|yes)$/i));  # section.key = true
2432 }
2433
2434 # convert config value to simple decimal number
2435 # an optional value suffix of 'k', 'm', or 'g' will cause the value
2436 # to be multiplied by 1024, 1048576, or 1073741824
2437 sub config_to_int {
2438         my $val = shift;
2439
2440         # strip leading and trailing whitespace
2441         $val =~ s/^\s+//;
2442         $val =~ s/\s+$//;
2443
2444         if (my ($num, $unit) = ($val =~ /^([0-9]*)([kmg])$/i)) {
2445                 $unit = lc($unit);
2446                 # unknown unit is treated as 1
2447                 return $num * ($unit eq 'g' ? 1073741824 :
2448                                $unit eq 'm' ?    1048576 :
2449                                $unit eq 'k' ?       1024 : 1);
2450         }
2451         return $val;
2452 }
2453
2454 # convert config value to array reference, if needed
2455 sub config_to_multi {
2456         my $val = shift;
2457
2458         return ref($val) ? $val : (defined($val) ? [ $val ] : []);
2459 }
2460
2461 sub git_get_project_config {
2462         my ($key, $type) = @_;
2463
2464         return unless defined $git_dir;
2465
2466         # key sanity check
2467         return unless ($key);
2468         $key =~ s/^gitweb\.//;
2469         return if ($key =~ m/\W/);
2470
2471         # type sanity check
2472         if (defined $type) {
2473                 $type =~ s/^--//;
2474                 $type = undef
2475                         unless ($type eq 'bool' || $type eq 'int');
2476         }
2477
2478         # get config
2479         if (!defined $config_file ||
2480             $config_file ne "$git_dir/config") {
2481                 %config = git_parse_project_config('gitweb');
2482                 $config_file = "$git_dir/config";
2483         }
2484
2485         # check if config variable (key) exists
2486         return unless exists $config{"gitweb.$key"};
2487
2488         # ensure given type
2489         if (!defined $type) {
2490                 return $config{"gitweb.$key"};
2491         } elsif ($type eq 'bool') {
2492                 # backward compatibility: 'git config --bool' returns true/false
2493                 return config_to_bool($config{"gitweb.$key"}) ? 'true' : 'false';
2494         } elsif ($type eq 'int') {
2495                 return config_to_int($config{"gitweb.$key"});
2496         }
2497         return $config{"gitweb.$key"};
2498 }
2499
2500 # get hash of given path at given ref
2501 sub git_get_hash_by_path {
2502         my $base = shift;
2503         my $path = shift || return undef;
2504         my $type = shift;
2505
2506         $path =~ s,/+$,,;
2507
2508         open my $fd, "-|", git_cmd(), "ls-tree", $base, "--", $path
2509                 or die_error(500, "Open git-ls-tree failed");
2510         my $line = <$fd>;
2511         close $fd or return undef;
2512
2513         if (!defined $line) {
2514                 # there is no tree or hash given by $path at $base
2515                 return undef;
2516         }
2517
2518         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
2519         $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/;
2520         if (defined $type && $type ne $2) {
2521                 # type doesn't match
2522                 return undef;
2523         }
2524         return $3;
2525 }
2526
2527 # get path of entry with given hash at given tree-ish (ref)
2528 # used to get 'from' filename for combined diff (merge commit) for renames
2529 sub git_get_path_by_hash {
2530         my $base = shift || return;
2531         my $hash = shift || return;
2532
2533         local $/ = "\0";
2534
2535         open my $fd, "-|", git_cmd(), "ls-tree", '-r', '-t', '-z', $base
2536                 or return undef;
2537         while (my $line = <$fd>) {
2538                 chomp $line;
2539
2540                 #'040000 tree 595596a6a9117ddba9fe379b6b012b558bac8423  gitweb'
2541                 #'100644 blob e02e90f0429be0d2a69b76571101f20b8f75530f  gitweb/README'
2542                 if ($line =~ m/(?:[0-9]+) (?:.+) $hash\t(.+)$/) {
2543                         close $fd;
2544                         return $1;
2545                 }
2546         }
2547         close $fd;
2548         return undef;
2549 }
2550
2551 ## ......................................................................
2552 ## git utility functions, directly accessing git repository
2553
2554 sub git_get_project_description {
2555         my $path = shift;
2556
2557         $git_dir = "$projectroot/$path";
2558         open my $fd, '<', "$git_dir/description"
2559                 or return git_get_project_config('description');
2560         my $descr = <$fd>;
2561         close $fd;
2562         if (defined $descr) {
2563                 chomp $descr;
2564         }
2565         return $descr;
2566 }
2567
2568 sub git_get_project_ctags {
2569         my $path = shift;
2570         my $ctags = {};
2571
2572         $git_dir = "$projectroot/$path";
2573         opendir my $dh, "$git_dir/ctags"
2574                 or return $ctags;
2575         foreach (grep { -f $_ } map { "$git_dir/ctags/$_" } readdir($dh)) {
2576                 open my $ct, '<', $_ or next;
2577                 my $val = <$ct>;
2578                 chomp $val;
2579                 close $ct;
2580                 my $ctag = $_; $ctag =~ s#.*/##;
2581                 $ctags->{$ctag} = $val;
2582         }
2583         closedir $dh;
2584         $ctags;
2585 }
2586
2587 sub git_populate_project_tagcloud {
2588         my $ctags = shift;
2589
2590         # First, merge different-cased tags; tags vote on casing
2591         my %ctags_lc;
2592         foreach (keys %$ctags) {
2593                 $ctags_lc{lc $_}->{count} += $ctags->{$_};
2594                 if (not $ctags_lc{lc $_}->{topcount}
2595                     or $ctags_lc{lc $_}->{topcount} < $ctags->{$_}) {
2596                         $ctags_lc{lc $_}->{topcount} = $ctags->{$_};
2597                         $ctags_lc{lc $_}->{topname} = $_;
2598                 }
2599         }
2600
2601         my $cloud;
2602         if (eval { require HTML::TagCloud; 1; }) {
2603                 $cloud = HTML::TagCloud->new;
2604                 foreach (sort keys %ctags_lc) {
2605                         # Pad the title with spaces so that the cloud looks
2606                         # less crammed.
2607                         my $title = $ctags_lc{$_}->{topname};
2608                         $title =~ s/ /&nbsp;/g;
2609                         $title =~ s/^/&nbsp;/g;
2610                         $title =~ s/$/&nbsp;/g;
2611                         $cloud->add($title, $home_link."?by_tag=".$_, $ctags_lc{$_}->{count});
2612                 }
2613         } else {
2614                 $cloud = \%ctags_lc;
2615         }
2616         $cloud;
2617 }
2618
2619 sub git_show_project_tagcloud {
2620         my ($cloud, $count) = @_;
2621         print STDERR ref($cloud)."..\n";
2622         if (ref $cloud eq 'HTML::TagCloud') {
2623                 return $cloud->html_and_css($count);
2624         } else {
2625                 my @tags = sort { $cloud->{$a}->{count} <=> $cloud->{$b}->{count} } keys %$cloud;
2626                 return '<p align="center">' . join (', ', map {
2627                         $cgi->a({-href=>"$home_link?by_tag=$_"}, $cloud->{$_}->{topname})
2628                 } splice(@tags, 0, $count)) . '</p>';
2629         }
2630 }
2631
2632 sub git_get_project_url_list {
2633         my $path = shift;
2634
2635         $git_dir = "$projectroot/$path";
2636         open my $fd, '<', "$git_dir/cloneurl"
2637                 or return wantarray ?
2638                 @{ config_to_multi(git_get_project_config('url')) } :
2639                    config_to_multi(git_get_project_config('url'));
2640         my @git_project_url_list = map { chomp; $_ } <$fd>;
2641         close $fd;
2642
2643         return wantarray ? @git_project_url_list : \@git_project_url_list;
2644 }
2645
2646 sub git_get_projects_list {
2647         my ($filter) = @_;
2648         my @list;
2649
2650         $filter ||= '';
2651         $filter =~ s/\.git$//;
2652
2653         my $check_forks = gitweb_check_feature('forks');
2654
2655         if (-d $projects_list) {
2656                 # search in directory
2657                 my $dir = $projects_list . ($filter ? "/$filter" : '');
2658                 # remove the trailing "/"
2659                 $dir =~ s!/+$!!;
2660                 my $pfxlen = length("$dir");
2661                 my $pfxdepth = ($dir =~ tr!/!!);
2662
2663                 File::Find::find({
2664                         follow_fast => 1, # follow symbolic links
2665                         follow_skip => 2, # ignore duplicates
2666                         dangling_symlinks => 0, # ignore dangling symlinks, silently
2667                         wanted => sub {
2668                                 # global variables
2669                                 our $project_maxdepth;
2670                                 our $projectroot;
2671                                 # skip project-list toplevel, if we get it.
2672                                 return if (m!^[/.]$!);
2673                                 # only directories can be git repositories
2674                                 return unless (-d $_);
2675                                 # don't traverse too deep (Find is super slow on os x)
2676                                 if (($File::Find::name =~ tr!/!!) - $pfxdepth > $project_maxdepth) {
2677                                         $File::Find::prune = 1;
2678                                         return;
2679                                 }
2680
2681                                 my $subdir = substr($File::Find::name, $pfxlen + 1);
2682                                 # we check related file in $projectroot
2683                                 my $path = ($filter ? "$filter/" : '') . $subdir;
2684                                 if (check_export_ok("$projectroot/$path")) {
2685                                         push @list, { path => $path };
2686                                         $File::Find::prune = 1;
2687                                 }
2688                         },
2689                 }, "$dir");
2690
2691         } elsif (-f $projects_list) {
2692                 # read from file(url-encoded):
2693                 # 'git%2Fgit.git Linus+Torvalds'
2694                 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
2695                 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
2696                 my %paths;
2697                 open my $fd, '<', $projects_list or return;
2698         PROJECT:
2699                 while (my $line = <$fd>) {
2700                         chomp $line;
2701                         my ($path, $owner) = split ' ', $line;
2702                         $path = unescape($path);
2703                         $owner = unescape($owner);
2704                         if (!defined $path) {
2705                                 next;
2706                         }
2707                         if ($filter ne '') {
2708                                 # looking for forks;
2709                                 my $pfx = substr($path, 0, length($filter));
2710                                 if ($pfx ne $filter) {
2711                                         next PROJECT;
2712                                 }
2713                                 my $sfx = substr($path, length($filter));
2714                                 if ($sfx !~ /^\/.*\.git$/) {
2715                                         next PROJECT;
2716                                 }
2717                         } elsif ($check_forks) {
2718                         PATH:
2719                                 foreach my $filter (keys %paths) {
2720                                         # looking for forks;
2721                                         my $pfx = substr($path, 0, length($filter));
2722                                         if ($pfx ne $filter) {
2723                                                 next PATH;
2724                                         }
2725                                         my $sfx = substr($path, length($filter));
2726                                         if ($sfx !~ /^\/.*\.git$/) {
2727                                                 next PATH;
2728                                         }
2729                                         # is a fork, don't include it in
2730                                         # the list
2731                                         next PROJECT;
2732                                 }
2733                         }
2734                         if (check_export_ok("$projectroot/$path")) {
2735                                 my $pr = {
2736                                         path => $path,
2737                                         owner => to_utf8($owner),
2738                                 };
2739                                 push @list, $pr;
2740                                 (my $forks_path = $path) =~ s/\.git$//;
2741                                 $paths{$forks_path}++;
2742                         }
2743                 }
2744                 close $fd;
2745         }
2746         return @list;
2747 }
2748
2749 our $gitweb_project_owner = undef;
2750 sub git_get_project_list_from_file {
2751
2752         return if (defined $gitweb_project_owner);
2753
2754         $gitweb_project_owner = {};
2755         # read from file (url-encoded):
2756         # 'git%2Fgit.git Linus+Torvalds'
2757         # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
2758         # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
2759         if (-f $projects_list) {
2760                 open(my $fd, '<', $projects_list);
2761                 while (my $line = <$fd>) {
2762                         chomp $line;
2763                         my ($pr, $ow) = split ' ', $line;
2764                         $pr = unescape($pr);
2765                         $ow = unescape($ow);
2766                         $gitweb_project_owner->{$pr} = to_utf8($ow);
2767                 }
2768                 close $fd;
2769         }
2770 }
2771
2772 sub git_get_project_owner {
2773         my $project = shift;
2774         my $owner;
2775
2776         return undef unless $project;
2777         $git_dir = "$projectroot/$project";
2778
2779         if (!defined $gitweb_project_owner) {
2780                 git_get_project_list_from_file();
2781         }
2782
2783         if (exists $gitweb_project_owner->{$project}) {
2784                 $owner = $gitweb_project_owner->{$project};
2785         }
2786         if (!defined $owner){
2787                 $owner = git_get_project_config('owner');
2788         }
2789         if (!defined $owner) {
2790                 $owner = get_file_owner("$git_dir");
2791         }
2792
2793         return $owner;
2794 }
2795
2796 sub git_get_last_activity {
2797         my ($path) = @_;
2798         my $fd;
2799
2800         $git_dir = "$projectroot/$path";
2801         open($fd, "-|", git_cmd(), 'for-each-ref',
2802              '--format=%(committer)',
2803              '--sort=-committerdate',
2804              '--count=1',
2805              'refs/heads') or return;
2806         my $most_recent = <$fd>;
2807         close $fd or return;
2808         if (defined $most_recent &&
2809             $most_recent =~ / (\d+) [-+][01]\d\d\d$/) {
2810                 my $timestamp = $1;
2811                 my $age = time - $timestamp;
2812                 return ($age, age_string($age));
2813         }
2814         return (undef, undef);
2815 }
2816
2817 # Implementation note: when a single remote is wanted, we cannot use 'git
2818 # remote show -n' because that command always work (assuming it's a remote URL
2819 # if it's not defined), and we cannot use 'git remote show' because that would
2820 # try to make a network roundtrip. So the only way to find if that particular
2821 # remote is defined is to walk the list provided by 'git remote -v' and stop if
2822 # and when we find what we want.
2823 sub git_get_remotes_list {
2824         my $wanted = shift;
2825         my %remotes = ();
2826
2827         open my $fd, '-|' , git_cmd(), 'remote', '-v';
2828         return unless $fd;
2829         while (my $remote = <$fd>) {
2830                 chomp $remote;
2831                 $remote =~ s!\t(.*?)\s+\((\w+)\)$!!;
2832                 next if $wanted and not $remote eq $wanted;
2833                 my ($url, $key) = ($1, $2);
2834
2835                 $remotes{$remote} ||= { 'heads' => () };
2836                 $remotes{$remote}{$key} = $url;
2837         }
2838         close $fd or return;
2839         return wantarray ? %remotes : \%remotes;
2840 }
2841
2842 # Takes a hash of remotes as first parameter and fills it by adding the
2843 # available remote heads for each of the indicated remotes.
2844 sub fill_remote_heads {
2845         my $remotes = shift;
2846         my @heads = map { "remotes/$_" } keys %$remotes;
2847         my @remoteheads = git_get_heads_list(undef, @heads);
2848         foreach my $remote (keys %$remotes) {
2849                 $remotes->{$remote}{'heads'} = [ grep {
2850                         $_->{'name'} =~ s!^$remote/!!
2851                         } @remoteheads ];
2852         }
2853 }
2854
2855 sub git_get_references {
2856         my $type = shift || "";
2857         my %refs;
2858         # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
2859         # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
2860         open my $fd, "-|", git_cmd(), "show-ref", "--dereference",
2861                 ($type ? ("--", "refs/$type") : ()) # use -- <pattern> if $type
2862                 or return;
2863
2864         while (my $line = <$fd>) {
2865                 chomp $line;
2866                 if ($line =~ m!^([0-9a-fA-F]{40})\srefs/($type.*)$!) {
2867                         if (defined $refs{$1}) {
2868                                 push @{$refs{$1}}, $2;
2869                         } else {
2870                                 $refs{$1} = [ $2 ];
2871                         }
2872                 }
2873         }
2874         close $fd or return;
2875         return \%refs;
2876 }
2877
2878 sub git_get_rev_name_tags {
2879         my $hash = shift || return undef;
2880
2881         open my $fd, "-|", git_cmd(), "name-rev", "--tags", $hash
2882                 or return;
2883         my $name_rev = <$fd>;
2884         close $fd;
2885
2886         if ($name_rev =~ m|^$hash tags/(.*)$|) {
2887                 return $1;
2888         } else {
2889                 # catches also '$hash undefined' output
2890                 return undef;
2891         }
2892 }
2893
2894 ## ----------------------------------------------------------------------
2895 ## parse to hash functions
2896
2897 sub parse_date {
2898         my $epoch = shift;
2899         my $tz = shift || "-0000";
2900
2901         my %date;
2902         my @months = ("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec");
2903         my @days = ("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");
2904         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($epoch);
2905         $date{'hour'} = $hour;
2906         $date{'minute'} = $min;
2907         $date{'mday'} = $mday;
2908         $date{'day'} = $days[$wday];
2909         $date{'month'} = $months[$mon];
2910         $date{'rfc2822'}   = sprintf "%s, %d %s %4d %02d:%02d:%02d +0000",
2911                              $days[$wday], $mday, $months[$mon], 1900+$year, $hour ,$min, $sec;
2912         $date{'mday-time'} = sprintf "%d %s %02d:%02d",
2913                              $mday, $months[$mon], $hour ,$min;
2914         $date{'iso-8601'}  = sprintf "%04d-%02d-%02dT%02d:%02d:%02dZ",
2915                              1900+$year, 1+$mon, $mday, $hour ,$min, $sec;
2916
2917         $tz =~ m/^([+\-][0-9][0-9])([0-9][0-9])$/;
2918         my $local = $epoch + ((int $1 + ($2/60)) * 3600);
2919         ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($local);
2920         $date{'hour_local'} = $hour;
2921         $date{'minute_local'} = $min;
2922         $date{'tz_local'} = $tz;
2923         $date{'iso-tz'} = sprintf("%04d-%02d-%02d %02d:%02d:%02d %s",
2924                                   1900+$year, $mon+1, $mday,
2925                                   $hour, $min, $sec, $tz);
2926         return %date;
2927 }
2928
2929 sub parse_tag {
2930         my $tag_id = shift;
2931         my %tag;
2932         my @comment;
2933
2934         open my $fd, "-|", git_cmd(), "cat-file", "tag", $tag_id or return;
2935         $tag{'id'} = $tag_id;
2936         while (my $line = <$fd>) {
2937                 chomp $line;
2938                 if ($line =~ m/^object ([0-9a-fA-F]{40})$/) {
2939                         $tag{'object'} = $1;
2940                 } elsif ($line =~ m/^type (.+)$/) {
2941                         $tag{'type'} = $1;
2942                 } elsif ($line =~ m/^tag (.+)$/) {
2943                         $tag{'name'} = $1;
2944                 } elsif ($line =~ m/^tagger (.*) ([0-9]+) (.*)$/) {
2945                         $tag{'author'} = $1;
2946                         $tag{'author_epoch'} = $2;
2947                         $tag{'author_tz'} = $3;
2948                         if ($tag{'author'} =~ m/^([^<]+) <([^>]*)>/) {
2949                                 $tag{'author_name'}  = $1;
2950                                 $tag{'author_email'} = $2;
2951                         } else {
2952                                 $tag{'author_name'} = $tag{'author'};
2953                         }
2954                 } elsif ($line =~ m/--BEGIN/) {
2955                         push @comment, $line;
2956                         last;
2957                 } elsif ($line eq "") {
2958                         last;
2959                 }
2960         }
2961         push @comment, <$fd>;
2962         $tag{'comment'} = \@comment;
2963         close $fd or return;
2964         if (!defined $tag{'name'}) {
2965                 return
2966         };
2967         return %tag
2968 }
2969
2970 sub parse_commit_text {
2971         my ($commit_text, $withparents) = @_;
2972         my @commit_lines = split '\n', $commit_text;
2973         my %co;
2974
2975         pop @commit_lines; # Remove '\0'
2976
2977         if (! @commit_lines) {
2978                 return;
2979         }
2980
2981         my $header = shift @commit_lines;
2982         if ($header !~ m/^[0-9a-fA-F]{40}/) {
2983                 return;
2984         }
2985         ($co{'id'}, my @parents) = split ' ', $header;
2986         while (my $line = shift @commit_lines) {
2987                 last if $line eq "\n";
2988                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
2989                         $co{'tree'} = $1;
2990                 } elsif ((!defined $withparents) && ($line =~ m/^parent ([0-9a-fA-F]{40})$/)) {
2991                         push @parents, $1;
2992                 } elsif ($line =~ m/^author (.*) ([0-9]+) (.*)$/) {
2993                         $co{'author'} = to_utf8($1);
2994                         $co{'author_epoch'} = $2;
2995                         $co{'author_tz'} = $3;
2996                         if ($co{'author'} =~ m/^([^<]+) <([^>]*)>/) {
2997                                 $co{'author_name'}  = $1;
2998                                 $co{'author_email'} = $2;
2999                         } else {
3000                                 $co{'author_name'} = $co{'author'};
3001                         }
3002                 } elsif ($line =~ m/^committer (.*) ([0-9]+) (.*)$/) {
3003                         $co{'committer'} = to_utf8($1);
3004                         $co{'committer_epoch'} = $2;
3005                         $co{'committer_tz'} = $3;
3006                         if ($co{'committer'} =~ m/^([^<]+) <([^>]*)>/) {
3007                                 $co{'committer_name'}  = $1;
3008                                 $co{'committer_email'} = $2;
3009                         } else {
3010                                 $co{'committer_name'} = $co{'committer'};
3011                         }
3012                 }
3013         }
3014         if (!defined $co{'tree'}) {
3015                 return;
3016         };
3017         $co{'parents'} = \@parents;
3018         $co{'parent'} = $parents[0];
3019
3020         foreach my $title (@commit_lines) {
3021                 $title =~ s/^    //;
3022                 if ($title ne "") {
3023                         $co{'title'} = chop_str($title, 80, 5);
3024                         # remove leading stuff of merges to make the interesting part visible
3025                         if (length($title) > 50) {
3026                                 $title =~ s/^Automatic //;
3027                                 $title =~ s/^merge (of|with) /Merge ... /i;
3028                                 if (length($title) > 50) {
3029                                         $title =~ s/(http|rsync):\/\///;
3030                                 }
3031                                 if (length($title) > 50) {
3032                                         $title =~ s/(master|www|rsync)\.//;
3033                                 }
3034                                 if (length($title) > 50) {
3035                                         $title =~ s/kernel.org:?//;
3036                                 }
3037                                 if (length($title) > 50) {
3038                                         $title =~ s/\/pub\/scm//;
3039                                 }
3040                         }
3041                         $co{'title_short'} = chop_str($title, 50, 5);
3042                         last;
3043                 }
3044         }
3045         if (! defined $co{'title'} || $co{'title'} eq "") {
3046                 $co{'title'} = $co{'title_short'} = '(no commit message)';
3047         }
3048         # remove added spaces
3049         foreach my $line (@commit_lines) {
3050                 $line =~ s/^    //;
3051         }
3052         $co{'comment'} = \@commit_lines;
3053
3054         my $age = time - $co{'committer_epoch'};
3055         $co{'age'} = $age;
3056         $co{'age_string'} = age_string($age);
3057         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($co{'committer_epoch'});
3058         if ($age > 60*60*24*7*2) {
3059                 $co{'age_string_date'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3060                 $co{'age_string_age'} = $co{'age_string'};
3061         } else {
3062                 $co{'age_string_date'} = $co{'age_string'};
3063                 $co{'age_string_age'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3064         }
3065         return %co;
3066 }
3067
3068 sub parse_commit {
3069         my ($commit_id) = @_;
3070         my %co;
3071
3072         local $/ = "\0";
3073
3074         open my $fd, "-|", git_cmd(), "rev-list",
3075                 "--parents",
3076                 "--header",
3077                 "--max-count=1",
3078                 $commit_id,
3079                 "--",
3080                 or die_error(500, "Open git-rev-list failed");
3081         %co = parse_commit_text(<$fd>, 1);
3082         close $fd;
3083
3084         return %co;
3085 }
3086
3087 sub parse_commits {
3088         my ($commit_id, $maxcount, $skip, $filename, @args) = @_;
3089         my @cos;
3090
3091         $maxcount ||= 1;
3092         $skip ||= 0;
3093
3094         local $/ = "\0";
3095
3096         open my $fd, "-|", git_cmd(), "rev-list",
3097                 "--header",
3098                 @args,
3099                 ("--max-count=" . $maxcount),
3100                 ("--skip=" . $skip),
3101                 @extra_options,
3102                 $commit_id,
3103                 "--",
3104                 ($filename ? ($filename) : ())
3105                 or die_error(500, "Open git-rev-list failed");
3106         while (my $line = <$fd>) {
3107                 my %co = parse_commit_text($line);
3108                 push @cos, \%co;
3109         }
3110         close $fd;
3111
3112         return wantarray ? @cos : \@cos;
3113 }
3114
3115 # parse line of git-diff-tree "raw" output
3116 sub parse_difftree_raw_line {
3117         my $line = shift;
3118         my %res;
3119
3120         # ':100644 100644 03b218260e99b78c6df0ed378e59ed9205ccc96d 3b93d5e7cc7f7dd4ebed13a5cc1a4ad976fc94d8 M   ls-files.c'
3121         # ':100644 100644 7f9281985086971d3877aca27704f2aaf9c448ce bc190ebc71bbd923f2b728e505408f5e54bd073a M   rev-tree.c'
3122         if ($line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)([0-9]{0,3})\t(.*)$/) {
3123                 $res{'from_mode'} = $1;
3124                 $res{'to_mode'} = $2;
3125                 $res{'from_id'} = $3;
3126                 $res{'to_id'} = $4;
3127                 $res{'status'} = $5;
3128                 $res{'similarity'} = $6;
3129                 if ($res{'status'} eq 'R' || $res{'status'} eq 'C') { # renamed or copied
3130                         ($res{'from_file'}, $res{'to_file'}) = map { unquote($_) } split("\t", $7);
3131                 } else {
3132                         $res{'from_file'} = $res{'to_file'} = $res{'file'} = unquote($7);
3133                 }
3134         }
3135         # '::100755 100755 100755 60e79ca1b01bc8b057abe17ddab484699a7f5fdb 94067cc5f73388f33722d52ae02f44692bc07490 94067cc5f73388f33722d52ae02f44692bc07490 MR git-gui/git-gui.sh'
3136         # combined diff (for merge commit)
3137         elsif ($line =~ s/^(::+)((?:[0-7]{6} )+)((?:[0-9a-fA-F]{40} )+)([a-zA-Z]+)\t(.*)$//) {
3138                 $res{'nparents'}  = length($1);
3139                 $res{'from_mode'} = [ split(' ', $2) ];
3140                 $res{'to_mode'} = pop @{$res{'from_mode'}};
3141                 $res{'from_id'} = [ split(' ', $3) ];
3142                 $res{'to_id'} = pop @{$res{'from_id'}};
3143                 $res{'status'} = [ split('', $4) ];
3144                 $res{'to_file'} = unquote($5);
3145         }
3146         # 'c512b523472485aef4fff9e57b229d9d243c967f'
3147         elsif ($line =~ m/^([0-9a-fA-F]{40})$/) {
3148                 $res{'commit'} = $1;
3149         }
3150
3151         return wantarray ? %res : \%res;
3152 }
3153
3154 # wrapper: return parsed line of git-diff-tree "raw" output
3155 # (the argument might be raw line, or parsed info)
3156 sub parsed_difftree_line {
3157         my $line_or_ref = shift;
3158
3159         if (ref($line_or_ref) eq "HASH") {
3160                 # pre-parsed (or generated by hand)
3161                 return $line_or_ref;
3162         } else {
3163                 return parse_difftree_raw_line($line_or_ref);
3164         }
3165 }
3166
3167 # parse line of git-ls-tree output
3168 sub parse_ls_tree_line {
3169         my $line = shift;
3170         my %opts = @_;
3171         my %res;
3172
3173         if ($opts{'-l'}) {
3174                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa   16717  panic.c'
3175                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40}) +(-|[0-9]+)\t(.+)$/s;
3176
3177                 $res{'mode'} = $1;
3178                 $res{'type'} = $2;
3179                 $res{'hash'} = $3;
3180                 $res{'size'} = $4;
3181                 if ($opts{'-z'}) {
3182                         $res{'name'} = $5;
3183                 } else {
3184                         $res{'name'} = unquote($5);
3185                 }
3186         } else {
3187                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
3188                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t(.+)$/s;
3189
3190                 $res{'mode'} = $1;
3191                 $res{'type'} = $2;
3192                 $res{'hash'} = $3;
3193                 if ($opts{'-z'}) {
3194                         $res{'name'} = $4;
3195                 } else {
3196                         $res{'name'} = unquote($4);
3197                 }
3198         }
3199
3200         return wantarray ? %res : \%res;
3201 }
3202
3203 # generates _two_ hashes, references to which are passed as 2 and 3 argument
3204 sub parse_from_to_diffinfo {
3205         my ($diffinfo, $from, $to, @parents) = @_;
3206
3207         if ($diffinfo->{'nparents'}) {
3208                 # combined diff
3209                 $from->{'file'} = [];
3210                 $from->{'href'} = [];
3211                 fill_from_file_info($diffinfo, @parents)
3212                         unless exists $diffinfo->{'from_file'};
3213                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
3214                         $from->{'file'}[$i] =
3215                                 defined $diffinfo->{'from_file'}[$i] ?
3216                                         $diffinfo->{'from_file'}[$i] :
3217                                         $diffinfo->{'to_file'};
3218                         if ($diffinfo->{'status'}[$i] ne "A") { # not new (added) file
3219                                 $from->{'href'}[$i] = href(action=>"blob",
3220                                                            hash_base=>$parents[$i],
3221                                                            hash=>$diffinfo->{'from_id'}[$i],
3222                                                            file_name=>$from->{'file'}[$i]);
3223                         } else {
3224                                 $from->{'href'}[$i] = undef;
3225                         }
3226                 }
3227         } else {
3228                 # ordinary (not combined) diff
3229                 $from->{'file'} = $diffinfo->{'from_file'};
3230                 if ($diffinfo->{'status'} ne "A") { # not new (added) file
3231                         $from->{'href'} = href(action=>"blob", hash_base=>$hash_parent,
3232                                                hash=>$diffinfo->{'from_id'},
3233                                                file_name=>$from->{'file'});
3234                 } else {
3235                         delete $from->{'href'};
3236                 }
3237         }
3238
3239         $to->{'file'} = $diffinfo->{'to_file'};
3240         if (!is_deleted($diffinfo)) { # file exists in result
3241                 $to->{'href'} = href(action=>"blob", hash_base=>$hash,
3242                                      hash=>$diffinfo->{'to_id'},
3243                                      file_name=>$to->{'file'});
3244         } else {
3245                 delete $to->{'href'};
3246         }
3247 }
3248
3249 ## ......................................................................
3250 ## parse to array of hashes functions
3251
3252 sub git_get_heads_list {
3253         my ($limit, @classes) = @_;
3254         @classes = ('heads') unless @classes;
3255         my @patterns = map { "refs/$_" } @classes;
3256         my @headslist;
3257
3258         open my $fd, '-|', git_cmd(), 'for-each-ref',
3259                 ($limit ? '--count='.($limit+1) : ()), '--sort=-committerdate',
3260                 '--format=%(objectname) %(refname) %(subject)%00%(committer)',
3261                 @patterns
3262                 or return;
3263         while (my $line = <$fd>) {
3264                 my %ref_item;
3265
3266                 chomp $line;
3267                 my ($refinfo, $committerinfo) = split(/\0/, $line);
3268                 my ($hash, $name, $title) = split(' ', $refinfo, 3);
3269                 my ($committer, $epoch, $tz) =
3270                         ($committerinfo =~ /^(.*) ([0-9]+) (.*)$/);
3271                 $ref_item{'fullname'}  = $name;
3272                 $name =~ s!^refs/(?:head|remote)s/!!;
3273
3274                 $ref_item{'name'}  = $name;
3275                 $ref_item{'id'}    = $hash;
3276                 $ref_item{'title'} = $title || '(no commit message)';
3277                 $ref_item{'epoch'} = $epoch;
3278                 if ($epoch) {
3279                         $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3280                 } else {
3281                         $ref_item{'age'} = "unknown";
3282                 }
3283
3284                 push @headslist, \%ref_item;
3285         }
3286         close $fd;
3287
3288         return wantarray ? @headslist : \@headslist;
3289 }
3290
3291 sub git_get_tags_list {
3292         my $limit = shift;
3293         my @tagslist;
3294
3295         open my $fd, '-|', git_cmd(), 'for-each-ref',
3296                 ($limit ? '--count='.($limit+1) : ()), '--sort=-creatordate',
3297                 '--format=%(objectname) %(objecttype) %(refname) '.
3298                 '%(*objectname) %(*objecttype) %(subject)%00%(creator)',
3299                 'refs/tags'
3300                 or return;
3301         while (my $line = <$fd>) {
3302                 my %ref_item;
3303
3304                 chomp $line;
3305                 my ($refinfo, $creatorinfo) = split(/\0/, $line);
3306                 my ($id, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
3307                 my ($creator, $epoch, $tz) =
3308                         ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
3309                 $ref_item{'fullname'} = $name;
3310                 $name =~ s!^refs/tags/!!;
3311
3312                 $ref_item{'type'} = $type;
3313                 $ref_item{'id'} = $id;
3314                 $ref_item{'name'} = $name;
3315                 if ($type eq "tag") {
3316                         $ref_item{'subject'} = $title;
3317                         $ref_item{'reftype'} = $reftype;
3318                         $ref_item{'refid'}   = $refid;
3319                 } else {
3320                         $ref_item{'reftype'} = $type;
3321                         $ref_item{'refid'}   = $id;
3322                 }
3323
3324                 if ($type eq "tag" || $type eq "commit") {
3325                         $ref_item{'epoch'} = $epoch;
3326                         if ($epoch) {
3327                                 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3328                         } else {
3329                                 $ref_item{'age'} = "unknown";
3330                         }
3331                 }
3332
3333                 push @tagslist, \%ref_item;
3334         }
3335         close $fd;
3336
3337         return wantarray ? @tagslist : \@tagslist;
3338 }
3339
3340 ## ----------------------------------------------------------------------
3341 ## filesystem-related functions
3342
3343 sub get_file_owner {
3344         my $path = shift;
3345
3346         my ($dev, $ino, $mode, $nlink, $st_uid, $st_gid, $rdev, $size) = stat($path);
3347         my ($name, $passwd, $uid, $gid, $quota, $comment, $gcos, $dir, $shell) = getpwuid($st_uid);
3348         if (!defined $gcos) {
3349                 return undef;
3350         }
3351         my $owner = $gcos;
3352         $owner =~ s/[,;].*$//;
3353         return to_utf8($owner);
3354 }
3355
3356 # assume that file exists
3357 sub insert_file {
3358         my $filename = shift;
3359
3360         open my $fd, '<', $filename;
3361         print map { to_utf8($_) } <$fd>;
3362         close $fd;
3363 }
3364
3365 ## ......................................................................
3366 ## mimetype related functions
3367
3368 sub mimetype_guess_file {
3369         my $filename = shift;
3370         my $mimemap = shift;
3371         -r $mimemap or return undef;
3372
3373         my %mimemap;
3374         open(my $mh, '<', $mimemap) or return undef;
3375         while (<$mh>) {
3376                 next if m/^#/; # skip comments
3377                 my ($mimetype, $exts) = split(/\t+/);
3378                 if (defined $exts) {
3379                         my @exts = split(/\s+/, $exts);
3380                         foreach my $ext (@exts) {
3381                                 $mimemap{$ext} = $mimetype;
3382                         }
3383                 }
3384         }
3385         close($mh);
3386
3387         $filename =~ /\.([^.]*)$/;
3388         return $mimemap{$1};
3389 }
3390
3391 sub mimetype_guess {
3392         my $filename = shift;
3393         my $mime;
3394         $filename =~ /\./ or return undef;
3395
3396         if ($mimetypes_file) {
3397                 my $file = $mimetypes_file;
3398                 if ($file !~ m!^/!) { # if it is relative path
3399                         # it is relative to project
3400                         $file = "$projectroot/$project/$file";
3401                 }
3402                 $mime = mimetype_guess_file($filename, $file);
3403         }
3404         $mime ||= mimetype_guess_file($filename, '/etc/mime.types');
3405         return $mime;
3406 }
3407
3408 sub blob_mimetype {
3409         my $fd = shift;
3410         my $filename = shift;
3411
3412         if ($filename) {
3413                 my $mime = mimetype_guess($filename);
3414                 $mime and return $mime;
3415         }
3416
3417         # just in case
3418         return $default_blob_plain_mimetype unless $fd;
3419
3420         if (-T $fd) {
3421                 return 'text/plain';
3422         } elsif (! $filename) {
3423                 return 'application/octet-stream';
3424         } elsif ($filename =~ m/\.png$/i) {
3425                 return 'image/png';
3426         } elsif ($filename =~ m/\.gif$/i) {
3427                 return 'image/gif';
3428         } elsif ($filename =~ m/\.jpe?g$/i) {
3429                 return 'image/jpeg';
3430         } else {
3431                 return 'application/octet-stream';
3432         }
3433 }
3434
3435 sub blob_contenttype {
3436         my ($fd, $file_name, $type) = @_;
3437
3438         $type ||= blob_mimetype($fd, $file_name);
3439         if ($type eq 'text/plain' && defined $default_text_plain_charset) {
3440                 $type .= "; charset=$default_text_plain_charset";
3441         }
3442
3443         return $type;
3444 }
3445
3446 # guess file syntax for syntax highlighting; return undef if no highlighting
3447 # the name of syntax can (in the future) depend on syntax highlighter used
3448 sub guess_file_syntax {
3449         my ($highlight, $mimetype, $file_name) = @_;
3450         return undef unless ($highlight && defined $file_name);
3451         my $basename = basename($file_name, '.in');
3452         return $highlight_basename{$basename}
3453                 if exists $highlight_basename{$basename};
3454
3455         $basename =~ /\.([^.]*)$/;
3456         my $ext = $1 or return undef;
3457         return $highlight_ext{$ext}
3458                 if exists $highlight_ext{$ext};
3459
3460         return undef;
3461 }
3462
3463 # run highlighter and return FD of its output,
3464 # or return original FD if no highlighting
3465 sub run_highlighter {
3466         my ($fd, $highlight, $syntax) = @_;
3467         return $fd unless ($highlight && defined $syntax);
3468
3469         close $fd;
3470         open $fd, quote_command(git_cmd(), "cat-file", "blob", $hash)." | ".
3471                   quote_command($highlight_bin).
3472                   " --fragment --syntax $syntax |"
3473                 or die_error(500, "Couldn't open file or run syntax highlighter");
3474         return $fd;
3475 }
3476
3477 ## ======================================================================
3478 ## functions printing HTML: header, footer, error page
3479
3480 sub get_page_title {
3481         my $title = to_utf8($site_name);
3482
3483         return $title unless (defined $project);
3484         $title .= " - " . to_utf8($project);
3485
3486         return $title unless (defined $action);
3487         $title .= "/$action"; # $action is US-ASCII (7bit ASCII)
3488
3489         return $title unless (defined $file_name);
3490         $title .= " - " . esc_path($file_name);
3491         if ($action eq "tree" && $file_name !~ m|/$|) {
3492                 $title .= "/";
3493         }
3494
3495         return $title;
3496 }
3497
3498 sub print_feed_meta {
3499         if (defined $project) {
3500                 my %href_params = get_feed_info();
3501                 if (!exists $href_params{'-title'}) {
3502                         $href_params{'-title'} = 'log';
3503                 }
3504
3505                 foreach my $format qw(RSS Atom) {
3506                         my $type = lc($format);
3507                         my %link_attr = (
3508                                 '-rel' => 'alternate',
3509                                 '-title' => esc_attr("$project - $href_params{'-title'} - $format feed"),
3510                                 '-type' => "application/$type+xml"
3511                         );
3512
3513                         $href_params{'action'} = $type;
3514                         $link_attr{'-href'} = href(%href_params);
3515                         print "<link ".
3516                               "rel=\"$link_attr{'-rel'}\" ".
3517                               "title=\"$link_attr{'-title'}\" ".
3518                               "href=\"$link_attr{'-href'}\" ".
3519                               "type=\"$link_attr{'-type'}\" ".
3520                               "/>\n";
3521
3522                         $href_params{'extra_options'} = '--no-merges';
3523                         $link_attr{'-href'} = href(%href_params);
3524                         $link_attr{'-title'} .= ' (no merges)';
3525                         print "<link ".
3526                               "rel=\"$link_attr{'-rel'}\" ".
3527                               "title=\"$link_attr{'-title'}\" ".
3528                               "href=\"$link_attr{'-href'}\" ".
3529                               "type=\"$link_attr{'-type'}\" ".
3530                               "/>\n";
3531                 }
3532
3533         } else {
3534                 printf('<link rel="alternate" title="%s projects list" '.
3535                        'href="%s" type="text/plain; charset=utf-8" />'."\n",
3536                        esc_attr($site_name), href(project=>undef, action=>"project_index"));
3537                 printf('<link rel="alternate" title="%s projects feeds" '.
3538                        'href="%s" type="text/x-opml" />'."\n",
3539                        esc_attr($site_name), href(project=>undef, action=>"opml"));
3540         }
3541 }
3542
3543 sub git_header_html {
3544         my $status = shift || "200 OK";
3545         my $expires = shift;
3546         my %opts = @_;
3547
3548         my $title = get_page_title();
3549         my $content_type;
3550         # require explicit support from the UA if we are to send the page as
3551         # 'application/xhtml+xml', otherwise send it as plain old 'text/html'.
3552         # we have to do this because MSIE sometimes globs '*/*', pretending to
3553         # support xhtml+xml but choking when it gets what it asked for.
3554         if (defined $cgi->http('HTTP_ACCEPT') &&
3555             $cgi->http('HTTP_ACCEPT') =~ m/(,|;|\s|^)application\/xhtml\+xml(,|;|\s|$)/ &&
3556             $cgi->Accept('application/xhtml+xml') != 0) {
3557                 $content_type = 'application/xhtml+xml';
3558         } else {
3559                 $content_type = 'text/html';
3560         }
3561         print $cgi->header(-type=>$content_type, -charset => 'utf-8',
3562                            -status=> $status, -expires => $expires)
3563                 unless ($opts{'-no_http_header'});
3564         my $mod_perl_version = $ENV{'MOD_PERL'} ? " $ENV{'MOD_PERL'}" : '';
3565         print <<EOF;
3566 <?xml version="1.0" encoding="utf-8"?>
3567 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
3568 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en-US" lang="en-US">
3569 <!-- git web interface version $version, (C) 2005-2006, Kay Sievers <kay.sievers\@vrfy.org>, Christian Gierke -->
3570 <!-- git core binaries version $git_version -->
3571 <head>
3572 <meta http-equiv="content-type" content="$content_type; charset=utf-8"/>
3573 <meta name="generator" content="gitweb/$version git/$git_version$mod_perl_version"/>
3574 <meta name="robots" content="index, nofollow"/>
3575 <title>$title</title>
3576 EOF
3577         # the stylesheet, favicon etc urls won't work correctly with path_info
3578         # unless we set the appropriate base URL
3579         if ($ENV{'PATH_INFO'}) {
3580                 print "<base href=\"".esc_url($base_url)."\" />\n";
3581         }
3582         # print out each stylesheet that exist, providing backwards capability
3583         # for those people who defined $stylesheet in a config file
3584         if (defined $stylesheet) {
3585                 print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
3586         } else {
3587                 foreach my $stylesheet (@stylesheets) {
3588                         next unless $stylesheet;
3589                         print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
3590                 }
3591         }
3592         print_feed_meta()
3593                 if ($status eq '200 OK');
3594         if (defined $favicon) {
3595                 print qq(<link rel="shortcut icon" href=").esc_url($favicon).qq(" type="image/png" />\n);
3596         }
3597
3598         print "</head>\n" .
3599               "<body>\n";
3600
3601         if (defined $site_header && -f $site_header) {
3602                 insert_file($site_header);
3603         }
3604
3605         print "<div class=\"page_header\">\n";
3606         if (defined $logo) {
3607                 print $cgi->a({-href => esc_url($logo_url),
3608                                -title => $logo_label},
3609                               $cgi->img({-src => esc_url($logo),
3610                                          -width => 72, -height => 27,
3611                                          -alt => "git",
3612                                          -class => "logo"}));
3613         }
3614         print $cgi->a({-href => esc_url($home_link)}, $home_link_str) . " / ";
3615         if (defined $project) {
3616                 print $cgi->a({-href => href(action=>"summary")}, esc_html($project));
3617                 if (defined $action) {
3618                         my $action_print = $action ;
3619                         if (defined $opts{-action_extra}) {
3620                                 $action_print = $cgi->a({-href => href(action=>$action)},
3621                                         $action);
3622                         }
3623                         print " / $action_print";
3624                 }
3625                 if (defined $opts{-action_extra}) {
3626                         print " / $opts{-action_extra}";
3627                 }
3628                 print "\n";
3629         }
3630         print "</div>\n";
3631
3632         my $have_search = gitweb_check_feature('search');
3633         if (defined $project && $have_search) {
3634                 if (!defined $searchtext) {
3635                         $searchtext = "";
3636                 }
3637                 my $search_hash;
3638                 if (defined $hash_base) {
3639                         $search_hash = $hash_base;
3640                 } elsif (defined $hash) {
3641                         $search_hash = $hash;
3642                 } else {
3643                         $search_hash = "HEAD";
3644                 }
3645                 my $action = $my_uri;
3646                 my $use_pathinfo = gitweb_check_feature('pathinfo');
3647                 if ($use_pathinfo) {
3648                         $action .= "/".esc_url($project);
3649                 }
3650                 print $cgi->startform(-method => "get", -action => $action) .
3651                       "<div class=\"search\">\n" .
3652                       (!$use_pathinfo &&
3653                       $cgi->input({-name=>"p", -value=>$project, -type=>"hidden"}) . "\n") .
3654                       $cgi->input({-name=>"a", -value=>"search", -type=>"hidden"}) . "\n" .
3655                       $cgi->input({-name=>"h", -value=>$search_hash, -type=>"hidden"}) . "\n" .
3656                       $cgi->popup_menu(-name => 'st', -default => 'commit',
3657                                        -values => ['commit', 'grep', 'author', 'committer', 'pickaxe']) .
3658                       $cgi->sup($cgi->a({-href => href(action=>"search_help")}, "?")) .
3659                       " search:\n",
3660                       $cgi->textfield(-name => "s", -value => $searchtext) . "\n" .
3661                       "<span title=\"Extended regular expression\">" .
3662                       $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
3663                                      -checked => $search_use_regexp) .
3664                       "</span>" .
3665                       "</div>" .
3666                       $cgi->end_form() . "\n";
3667         }
3668 }
3669
3670 sub git_footer_html {
3671         my $feed_class = 'rss_logo';
3672
3673         print "<div class=\"page_footer\">\n";
3674         if (defined $project) {
3675                 my $descr = git_get_project_description($project);
3676                 if (defined $descr) {
3677                         print "<div class=\"page_footer_text\">" . esc_html($descr) . "</div>\n";
3678                 }
3679
3680                 my %href_params = get_feed_info();
3681                 if (!%href_params) {
3682                         $feed_class .= ' generic';
3683                 }
3684                 $href_params{'-title'} ||= 'log';
3685
3686                 foreach my $format qw(RSS Atom) {
3687                         $href_params{'action'} = lc($format);
3688                         print $cgi->a({-href => href(%href_params),
3689                                       -title => "$href_params{'-title'} $format feed",
3690                                       -class => $feed_class}, $format)."\n";
3691                 }
3692
3693         } else {
3694                 print $cgi->a({-href => href(project=>undef, action=>"opml"),
3695                               -class => $feed_class}, "OPML") . " ";
3696                 print $cgi->a({-href => href(project=>undef, action=>"project_index"),
3697                               -class => $feed_class}, "TXT") . "\n";
3698         }
3699         print "</div>\n"; # class="page_footer"
3700
3701         if (defined $t0 && gitweb_check_feature('timed')) {
3702                 print "<div id=\"generating_info\">\n";
3703                 print 'This page took '.
3704                       '<span id="generating_time" class="time_span">'.
3705                       tv_interval($t0, [ gettimeofday() ]).
3706                       ' seconds </span>'.
3707                       ' and '.
3708                       '<span id="generating_cmd">'.
3709                       $number_of_git_cmds.
3710                       '</span> git commands '.
3711                       " to generate.\n";
3712                 print "</div>\n"; # class="page_footer"
3713         }
3714
3715         if (defined $site_footer && -f $site_footer) {
3716                 insert_file($site_footer);
3717         }
3718
3719         print qq!<script type="text/javascript" src="!.esc_url($javascript).qq!"></script>\n!;
3720         if (defined $action &&
3721             $action eq 'blame_incremental') {
3722                 print qq!<script type="text/javascript">\n!.
3723                       qq!startBlame("!. href(action=>"blame_data", -replay=>1) .qq!",\n!.
3724                       qq!           "!. href() .qq!");\n!.
3725                       qq!</script>\n!;
3726         } elsif (gitweb_check_feature('javascript-actions')) {
3727                 print qq!<script type="text/javascript">\n!.
3728                       qq!window.onload = fixLinks;\n!.
3729                       qq!</script>\n!;
3730         }
3731
3732         print "</body>\n" .
3733               "</html>";
3734 }
3735
3736 # die_error(<http_status_code>, <error_message>[, <detailed_html_description>])
3737 # Example: die_error(404, 'Hash not found')
3738 # By convention, use the following status codes (as defined in RFC 2616):
3739 # 400: Invalid or missing CGI parameters, or
3740 #      requested object exists but has wrong type.
3741 # 403: Requested feature (like "pickaxe" or "snapshot") not enabled on
3742 #      this server or project.
3743 # 404: Requested object/revision/project doesn't exist.
3744 # 500: The server isn't configured properly, or
3745 #      an internal error occurred (e.g. failed assertions caused by bugs), or
3746 #      an unknown error occurred (e.g. the git binary died unexpectedly).
3747 # 503: The server is currently unavailable (because it is overloaded,
3748 #      or down for maintenance).  Generally, this is a temporary state.
3749 sub die_error {
3750         my $status = shift || 500;
3751         my $error = esc_html(shift) || "Internal Server Error";
3752         my $extra = shift;
3753         my %opts = @_;
3754
3755         my %http_responses = (
3756                 400 => '400 Bad Request',
3757                 403 => '403 Forbidden',
3758                 404 => '404 Not Found',
3759                 500 => '500 Internal Server Error',
3760                 503 => '503 Service Unavailable',
3761         );
3762         git_header_html($http_responses{$status}, undef, %opts);
3763         print <<EOF;
3764 <div class="page_body">
3765 <br /><br />
3766 $status - $error
3767 <br />
3768 EOF
3769         if (defined $extra) {
3770                 print "<hr />\n" .
3771                       "$extra\n";
3772         }
3773         print "</div>\n";
3774
3775         git_footer_html();
3776         goto DONE_GITWEB
3777                 unless ($opts{'-error_handler'});
3778 }
3779
3780 ## ----------------------------------------------------------------------
3781 ## functions printing or outputting HTML: navigation
3782
3783 sub git_print_page_nav {
3784         my ($current, $suppress, $head, $treehead, $treebase, $extra) = @_;
3785         $extra = '' if !defined $extra; # pager or formats
3786
3787         my @navs = qw(summary shortlog log commit commitdiff tree);
3788         if ($suppress) {
3789                 @navs = grep { $_ ne $suppress } @navs;
3790         }
3791
3792         my %arg = map { $_ => {action=>$_} } @navs;
3793         if (defined $head) {
3794                 for (qw(commit commitdiff)) {
3795                         $arg{$_}{'hash'} = $head;
3796                 }
3797                 if ($current =~ m/^(tree | log | shortlog | commit | commitdiff | search)$/x) {
3798                         for (qw(shortlog log)) {
3799                                 $arg{$_}{'hash'} = $head;
3800                         }
3801                 }
3802         }
3803
3804         $arg{'tree'}{'hash'} = $treehead if defined $treehead;
3805         $arg{'tree'}{'hash_base'} = $treebase if defined $treebase;
3806
3807         my @actions = gitweb_get_feature('actions');
3808         my %repl = (
3809                 '%' => '%',
3810                 'n' => $project,         # project name
3811                 'f' => $git_dir,         # project path within filesystem
3812                 'h' => $treehead || '',  # current hash ('h' parameter)
3813                 'b' => $treebase || '',  # hash base ('hb' parameter)
3814         );
3815         while (@actions) {
3816                 my ($label, $link, $pos) = splice(@actions,0,3);
3817                 # insert
3818                 @navs = map { $_ eq $pos ? ($_, $label) : $_ } @navs;
3819                 # munch munch
3820                 $link =~ s/%([%nfhb])/$repl{$1}/g;
3821                 $arg{$label}{'_href'} = $link;
3822         }
3823
3824         print "<div class=\"page_nav\">\n" .
3825                 (join " | ",
3826                  map { $_ eq $current ?
3827                        $_ : $cgi->a({-href => ($arg{$_}{_href} ? $arg{$_}{_href} : href(%{$arg{$_}}))}, "$_")
3828                  } @navs);
3829         print "<br/>\n$extra<br/>\n" .
3830               "</div>\n";
3831 }
3832
3833 # returns a submenu for the nagivation of the refs views (tags, heads,
3834 # remotes) with the current view disabled and the remotes view only
3835 # available if the feature is enabled
3836 sub format_ref_views {
3837         my ($current) = @_;
3838         my @ref_views = qw{tags heads};
3839         push @ref_views, 'remotes' if gitweb_check_feature('remote_heads');
3840         return join " | ", map {
3841                 $_ eq $current ? $_ :
3842                 $cgi->a({-href => href(action=>$_)}, $_)
3843         } @ref_views
3844 }
3845
3846 sub format_paging_nav {
3847         my ($action, $page, $has_next_link) = @_;
3848         my $paging_nav;
3849
3850
3851         if ($page > 0) {
3852                 $paging_nav .=
3853                         $cgi->a({-href => href(-replay=>1, page=>undef)}, "first") .
3854                         " &sdot; " .
3855                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
3856                                  -accesskey => "p", -title => "Alt-p"}, "prev");
3857         } else {
3858                 $paging_nav .= "first &sdot; prev";
3859         }
3860
3861         if ($has_next_link) {
3862                 $paging_nav .= " &sdot; " .
3863                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
3864                                  -accesskey => "n", -title => "Alt-n"}, "next");
3865         } else {
3866                 $paging_nav .= " &sdot; next";
3867         }
3868
3869         return $paging_nav;
3870 }
3871
3872 ## ......................................................................
3873 ## functions printing or outputting HTML: div
3874
3875 sub git_print_header_div {
3876         my ($action, $title, $hash, $hash_base) = @_;
3877         my %args = ();
3878
3879         $args{'action'} = $action;
3880         $args{'hash'} = $hash if $hash;
3881         $args{'hash_base'} = $hash_base if $hash_base;
3882
3883         print "<div class=\"header\">\n" .
3884               $cgi->a({-href => href(%args), -class => "title"},
3885               $title ? $title : $action) .
3886               "\n</div>\n";
3887 }
3888
3889 sub format_repo_url {
3890         my ($name, $url) = @_;
3891         return "<tr class=\"metadata_url\"><td>$name</td><td>$url</td></tr>\n";
3892 }
3893
3894 # Group output by placing it in a DIV element and adding a header.
3895 # Options for start_div() can be provided by passing a hash reference as the
3896 # first parameter to the function.
3897 # Options to git_print_header_div() can be provided by passing an array
3898 # reference. This must follow the options to start_div if they are present.
3899 # The content can be a scalar, which is output as-is, a scalar reference, which
3900 # is output after html escaping, an IO handle passed either as *handle or
3901 # *handle{IO}, or a function reference. In the latter case all following
3902 # parameters will be taken as argument to the content function call.
3903 sub git_print_section {
3904         my ($div_args, $header_args, $content);
3905         my $arg = shift;
3906         if (ref($arg) eq 'HASH') {
3907                 $div_args = $arg;
3908                 $arg = shift;
3909         }
3910         if (ref($arg) eq 'ARRAY') {
3911                 $header_args = $arg;
3912                 $arg = shift;
3913         }
3914         $content = $arg;
3915
3916         print $cgi->start_div($div_args);
3917         git_print_header_div(@$header_args);
3918
3919         if (ref($content) eq 'CODE') {
3920                 $content->(@_);
3921         } elsif (ref($content) eq 'SCALAR') {
3922                 print esc_html($$content);
3923         } elsif (ref($content) eq 'GLOB' or ref($content) eq 'IO::Handle') {
3924                 print <$content>;
3925         } elsif (!ref($content) && defined($content)) {
3926                 print $content;
3927         }
3928
3929         print $cgi->end_div;
3930 }
3931
3932 sub print_local_time {
3933         print format_local_time(@_);
3934 }
3935
3936 sub format_local_time {
3937         my $localtime = '';
3938         my %date = @_;
3939         if ($date{'hour_local'} < 6) {
3940                 $localtime .= sprintf(" (<span class=\"atnight\">%02d:%02d</span> %s)",
3941                         $date{'hour_local'}, $date{'minute_local'}, $date{'tz_local'});
3942         } else {
3943                 $localtime .= sprintf(" (%02d:%02d %s)",
3944                         $date{'hour_local'}, $date{'minute_local'}, $date{'tz_local'});
3945         }
3946
3947         return $localtime;
3948 }
3949
3950 # Outputs the author name and date in long form
3951 sub git_print_authorship {
3952         my $co = shift;
3953         my %opts = @_;
3954         my $tag = $opts{-tag} || 'div';
3955         my $author = $co->{'author_name'};
3956
3957         my %ad = parse_date($co->{'author_epoch'}, $co->{'author_tz'});
3958         print "<$tag class=\"author_date\">" .
3959               format_search_author($author, "author", esc_html($author)) .
3960               " [$ad{'rfc2822'}";
3961         print_local_time(%ad) if ($opts{-localtime});
3962         print "]" . git_get_avatar($co->{'author_email'}, -pad_before => 1)
3963                   . "</$tag>\n";
3964 }
3965
3966 # Outputs table rows containing the full author or committer information,
3967 # in the format expected for 'commit' view (& similar).
3968 # Parameters are a commit hash reference, followed by the list of people
3969 # to output information for. If the list is empty it defaults to both
3970 # author and committer.
3971 sub git_print_authorship_rows {
3972         my $co = shift;
3973         # too bad we can't use @people = @_ || ('author', 'committer')
3974         my @people = @_;
3975         @people = ('author', 'committer') unless @people;
3976         foreach my $who (@people) {
3977                 my %wd = parse_date($co->{"${who}_epoch"}, $co->{"${who}_tz"});
3978                 print "<tr><td>$who</td><td>" .
3979                       format_search_author($co->{"${who}_name"}, $who,
3980                                esc_html($co->{"${who}_name"})) . " " .
3981                       format_search_author($co->{"${who}_email"}, $who,
3982                                esc_html("<" . $co->{"${who}_email"} . ">")) .
3983                       "</td><td rowspan=\"2\">" .
3984                       git_get_avatar($co->{"${who}_email"}, -size => 'double') .
3985                       "</td></tr>\n" .
3986                       "<tr>" .
3987                       "<td></td><td> $wd{'rfc2822'}";
3988                 print_local_time(%wd);
3989                 print "</td>" .
3990                       "</tr>\n";
3991         }
3992 }
3993
3994 sub git_print_page_path {
3995         my $name = shift;
3996         my $type = shift;
3997         my $hb = shift;
3998
3999
4000         print "<div class=\"page_path\">";
4001         print $cgi->a({-href => href(action=>"tree", hash_base=>$hb),
4002                       -title => 'tree root'}, to_utf8("[$project]"));
4003         print " / ";
4004         if (defined $name) {
4005                 my @dirname = split '/', $name;
4006                 my $basename = pop @dirname;
4007                 my $fullname = '';
4008
4009                 foreach my $dir (@dirname) {
4010                         $fullname .= ($fullname ? '/' : '') . $dir;
4011                         print $cgi->a({-href => href(action=>"tree", file_name=>$fullname,
4012                                                      hash_base=>$hb),
4013                                       -title => $fullname}, esc_path($dir));
4014                         print " / ";
4015                 }
4016                 if (defined $type && $type eq 'blob') {
4017                         print $cgi->a({-href => href(action=>"blob_plain", file_name=>$file_name,
4018                                                      hash_base=>$hb),
4019                                       -title => $name}, esc_path($basename));
4020                 } elsif (defined $type && $type eq 'tree') {
4021                         print $cgi->a({-href => href(action=>"tree", file_name=>$file_name,
4022                                                      hash_base=>$hb),
4023                                       -title => $name}, esc_path($basename));
4024                         print " / ";
4025                 } else {
4026                         print esc_path($basename);
4027                 }
4028         }
4029         print "<br/></div>\n";
4030 }
4031
4032 sub git_print_log {
4033         my $log = shift;
4034         my %opts = @_;
4035
4036         if ($opts{'-remove_title'}) {
4037                 # remove title, i.e. first line of log
4038                 shift @$log;
4039         }
4040         # remove leading empty lines
4041         while (defined $log->[0] && $log->[0] eq "") {
4042                 shift @$log;
4043         }
4044
4045         # print log
4046         my $signoff = 0;
4047         my $empty = 0;
4048         foreach my $line (@$log) {
4049                 if ($line =~ m/^ *(signed[ \-]off[ \-]by[ :]|acked[ \-]by[ :]|cc[ :])/i) {
4050                         $signoff = 1;
4051                         $empty = 0;
4052                         if (! $opts{'-remove_signoff'}) {
4053                                 print "<span class=\"signoff\">" . esc_html($line) . "</span><br/>\n";
4054                                 next;
4055                         } else {
4056                                 # remove signoff lines
4057                                 next;
4058                         }
4059                 } else {
4060                         $signoff = 0;
4061                 }
4062
4063                 # print only one empty line
4064                 # do not print empty line after signoff
4065                 if ($line eq "") {
4066                         next if ($empty || $signoff);
4067                         $empty = 1;
4068                 } else {
4069                         $empty = 0;
4070                 }
4071
4072                 print format_log_line_html($line) . "<br/>\n";
4073         }
4074
4075         if ($opts{'-final_empty_line'}) {
4076                 # end with single empty line
4077                 print "<br/>\n" unless $empty;
4078         }
4079 }
4080
4081 # return link target (what link points to)
4082 sub git_get_link_target {
4083         my $hash = shift;
4084         my $link_target;
4085
4086         # read link
4087         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
4088                 or return;
4089         {
4090                 local $/ = undef;
4091                 $link_target = <$fd>;
4092         }
4093         close $fd
4094                 or return;
4095
4096         return $link_target;
4097 }
4098
4099 # given link target, and the directory (basedir) the link is in,
4100 # return target of link relative to top directory (top tree);
4101 # return undef if it is not possible (including absolute links).
4102 sub normalize_link_target {
4103         my ($link_target, $basedir) = @_;
4104
4105         # absolute symlinks (beginning with '/') cannot be normalized
4106         return if (substr($link_target, 0, 1) eq '/');
4107
4108         # normalize link target to path from top (root) tree (dir)
4109         my $path;
4110         if ($basedir) {
4111                 $path = $basedir . '/' . $link_target;
4112         } else {
4113                 # we are in top (root) tree (dir)
4114                 $path = $link_target;
4115         }
4116
4117         # remove //, /./, and /../
4118         my @path_parts;
4119         foreach my $part (split('/', $path)) {
4120                 # discard '.' and ''
4121                 next if (!$part || $part eq '.');
4122                 # handle '..'
4123                 if ($part eq '..') {
4124                         if (@path_parts) {
4125                                 pop @path_parts;
4126                         } else {
4127                                 # link leads outside repository (outside top dir)
4128                                 return;
4129                         }
4130                 } else {
4131                         push @path_parts, $part;
4132                 }
4133         }
4134         $path = join('/', @path_parts);
4135
4136         return $path;
4137 }
4138
4139 # print tree entry (row of git_tree), but without encompassing <tr> element
4140 sub git_print_tree_entry {
4141         my ($t, $basedir, $hash_base, $have_blame) = @_;
4142
4143         my %base_key = ();
4144         $base_key{'hash_base'} = $hash_base if defined $hash_base;
4145
4146         # The format of a table row is: mode list link.  Where mode is
4147         # the mode of the entry, list is the name of the entry, an href,
4148         # and link is the action links of the entry.
4149
4150         print "<td class=\"mode\">" . mode_str($t->{'mode'}) . "</td>\n";
4151         if (exists $t->{'size'}) {
4152                 print "<td class=\"size\">$t->{'size'}</td>\n";
4153         }
4154         if ($t->{'type'} eq "blob") {
4155                 print "<td class=\"list\">" .
4156                         $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4157                                                file_name=>"$basedir$t->{'name'}", %base_key),
4158                                 -class => "list"}, esc_path($t->{'name'}));
4159                 if (S_ISLNK(oct $t->{'mode'})) {
4160                         my $link_target = git_get_link_target($t->{'hash'});
4161                         if ($link_target) {
4162                                 my $norm_target = normalize_link_target($link_target, $basedir);
4163                                 if (defined $norm_target) {
4164                                         print " -> " .
4165                                               $cgi->a({-href => href(action=>"object", hash_base=>$hash_base,
4166                                                                      file_name=>$norm_target),
4167                                                        -title => $norm_target}, esc_path($link_target));
4168                                 } else {
4169                                         print " -> " . esc_path($link_target);
4170                                 }
4171                         }
4172                 }
4173                 print "</td>\n";
4174                 print "<td class=\"link\">";
4175                 print $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4176                                              file_name=>"$basedir$t->{'name'}", %base_key)},
4177                               "blob");
4178                 if ($have_blame) {
4179                         print " | " .
4180                               $cgi->a({-href => href(action=>"blame", hash=>$t->{'hash'},
4181                                                      file_name=>"$basedir$t->{'name'}", %base_key)},
4182                                       "blame");
4183                 }
4184                 if (defined $hash_base) {
4185                         print " | " .
4186                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4187                                                      hash=>$t->{'hash'}, file_name=>"$basedir$t->{'name'}")},
4188                                       "history");
4189                 }
4190                 print " | " .
4191                         $cgi->a({-href => href(action=>"blob_plain", hash_base=>$hash_base,
4192                                                file_name=>"$basedir$t->{'name'}")},
4193                                 "raw");
4194                 print "</td>\n";
4195
4196         } elsif ($t->{'type'} eq "tree") {
4197                 print "<td class=\"list\">";
4198                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4199                                              file_name=>"$basedir$t->{'name'}",
4200                                              %base_key)},
4201                               esc_path($t->{'name'}));
4202                 print "</td>\n";
4203                 print "<td class=\"link\">";
4204                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4205                                              file_name=>"$basedir$t->{'name'}",
4206                                              %base_key)},
4207                               "tree");
4208                 if (defined $hash_base) {
4209                         print " | " .
4210                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4211                                                      file_name=>"$basedir$t->{'name'}")},
4212                                       "history");
4213                 }
4214                 print "</td>\n";
4215         } else {
4216                 # unknown object: we can only present history for it
4217                 # (this includes 'commit' object, i.e. submodule support)
4218                 print "<td class=\"list\">" .
4219                       esc_path($t->{'name'}) .
4220                       "</td>\n";
4221                 print "<td class=\"link\">";
4222                 if (defined $hash_base) {
4223                         print $cgi->a({-href => href(action=>"history",
4224                                                      hash_base=>$hash_base,
4225                                                      file_name=>"$basedir$t->{'name'}")},
4226                                       "history");
4227                 }
4228                 print "</td>\n";
4229         }
4230 }
4231
4232 ## ......................................................................
4233 ## functions printing large fragments of HTML
4234
4235 # get pre-image filenames for merge (combined) diff
4236 sub fill_from_file_info {
4237         my ($diff, @parents) = @_;
4238
4239         $diff->{'from_file'} = [ ];
4240         $diff->{'from_file'}[$diff->{'nparents'} - 1] = undef;
4241         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4242                 if ($diff->{'status'}[$i] eq 'R' ||
4243                     $diff->{'status'}[$i] eq 'C') {
4244                         $diff->{'from_file'}[$i] =
4245                                 git_get_path_by_hash($parents[$i], $diff->{'from_id'}[$i]);
4246                 }
4247         }
4248
4249         return $diff;
4250 }
4251
4252 # is current raw difftree line of file deletion
4253 sub is_deleted {
4254         my $diffinfo = shift;
4255
4256         return $diffinfo->{'to_id'} eq ('0' x 40);
4257 }
4258
4259 # does patch correspond to [previous] difftree raw line
4260 # $diffinfo  - hashref of parsed raw diff format
4261 # $patchinfo - hashref of parsed patch diff format
4262 #              (the same keys as in $diffinfo)
4263 sub is_patch_split {
4264         my ($diffinfo, $patchinfo) = @_;
4265
4266         return defined $diffinfo && defined $patchinfo
4267                 && $diffinfo->{'to_file'} eq $patchinfo->{'to_file'};
4268 }
4269
4270
4271 sub git_difftree_body {
4272         my ($difftree, $hash, @parents) = @_;
4273         my ($parent) = $parents[0];
4274         my $have_blame = gitweb_check_feature('blame');
4275         print "<div class=\"list_head\">\n";
4276         if ($#{$difftree} > 10) {
4277                 print(($#{$difftree} + 1) . " files changed:\n");
4278         }
4279         print "</div>\n";
4280
4281         print "<table class=\"" .
4282               (@parents > 1 ? "combined " : "") .
4283               "diff_tree\">\n";
4284
4285         # header only for combined diff in 'commitdiff' view
4286         my $has_header = @$difftree && @parents > 1 && $action eq 'commitdiff';
4287         if ($has_header) {
4288                 # table header
4289                 print "<thead><tr>\n" .
4290                        "<th></th><th></th>\n"; # filename, patchN link
4291                 for (my $i = 0; $i < @parents; $i++) {
4292                         my $par = $parents[$i];
4293                         print "<th>" .
4294                               $cgi->a({-href => href(action=>"commitdiff",
4295                                                      hash=>$hash, hash_parent=>$par),
4296                                        -title => 'commitdiff to parent number ' .
4297                                                   ($i+1) . ': ' . substr($par,0,7)},
4298                                       $i+1) .
4299                               "&nbsp;</th>\n";
4300                 }
4301                 print "</tr></thead>\n<tbody>\n";
4302         }
4303
4304         my $alternate = 1;
4305         my $patchno = 0;
4306         foreach my $line (@{$difftree}) {
4307                 my $diff = parsed_difftree_line($line);
4308
4309                 if ($alternate) {
4310                         print "<tr class=\"dark\">\n";
4311                 } else {
4312                         print "<tr class=\"light\">\n";
4313                 }
4314                 $alternate ^= 1;
4315
4316                 if (exists $diff->{'nparents'}) { # combined diff
4317
4318                         fill_from_file_info($diff, @parents)
4319                                 unless exists $diff->{'from_file'};
4320
4321                         if (!is_deleted($diff)) {
4322                                 # file exists in the result (child) commit
4323                                 print "<td>" .
4324                                       $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4325                                                              file_name=>$diff->{'to_file'},
4326                                                              hash_base=>$hash),
4327                                               -class => "list"}, esc_path($diff->{'to_file'})) .
4328                                       "</td>\n";
4329                         } else {
4330                                 print "<td>" .
4331                                       esc_path($diff->{'to_file'}) .
4332                                       "</td>\n";
4333                         }
4334
4335                         if ($action eq 'commitdiff') {
4336                                 # link to patch
4337                                 $patchno++;
4338                                 print "<td class=\"link\">" .
4339                                       $cgi->a({-href => "#patch$patchno"}, "patch") .
4340                                       " | " .
4341                                       "</td>\n";
4342                         }
4343
4344                         my $has_history = 0;
4345                         my $not_deleted = 0;
4346                         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4347                                 my $hash_parent = $parents[$i];
4348                                 my $from_hash = $diff->{'from_id'}[$i];
4349                                 my $from_path = $diff->{'from_file'}[$i];
4350                                 my $status = $diff->{'status'}[$i];
4351
4352                                 $has_history ||= ($status ne 'A');
4353                                 $not_deleted ||= ($status ne 'D');
4354
4355                                 if ($status eq 'A') {
4356                                         print "<td  class=\"link\" align=\"right\"> | </td>\n";
4357                                 } elsif ($status eq 'D') {
4358                                         print "<td class=\"link\">" .
4359                                               $cgi->a({-href => href(action=>"blob",
4360                                                                      hash_base=>$hash,
4361                                                                      hash=>$from_hash,
4362                                                                      file_name=>$from_path)},
4363                                                       "blob" . ($i+1)) .
4364                                               " | </td>\n";
4365                                 } else {
4366                                         if ($diff->{'to_id'} eq $from_hash) {
4367                                                 print "<td class=\"link nochange\">";
4368                                         } else {
4369                                                 print "<td class=\"link\">";
4370                                         }
4371                                         print $cgi->a({-href => href(action=>"blobdiff",
4372                                                                      hash=>$diff->{'to_id'},
4373                                                                      hash_parent=>$from_hash,
4374                                                                      hash_base=>$hash,
4375                                                                      hash_parent_base=>$hash_parent,
4376                                                                      file_name=>$diff->{'to_file'},
4377                                                                      file_parent=>$from_path)},
4378                                                       "diff" . ($i+1)) .
4379                                               " | </td>\n";
4380                                 }
4381                         }
4382
4383                         print "<td class=\"link\">";
4384                         if ($not_deleted) {
4385                                 print $cgi->a({-href => href(action=>"blob",
4386                                                              hash=>$diff->{'to_id'},
4387                                                              file_name=>$diff->{'to_file'},
4388                                                              hash_base=>$hash)},
4389                                               "blob");
4390                                 print " | " if ($has_history);
4391                         }
4392                         if ($has_history) {
4393                                 print $cgi->a({-href => href(action=>"history",
4394                                                              file_name=>$diff->{'to_file'},
4395                                                              hash_base=>$hash)},
4396                                               "history");
4397                         }
4398                         print "</td>\n";
4399
4400                         print "</tr>\n";
4401                         next; # instead of 'else' clause, to avoid extra indent
4402                 }
4403                 # else ordinary diff
4404
4405                 my ($to_mode_oct, $to_mode_str, $to_file_type);
4406                 my ($from_mode_oct, $from_mode_str, $from_file_type);
4407                 if ($diff->{'to_mode'} ne ('0' x 6)) {
4408                         $to_mode_oct = oct $diff->{'to_mode'};
4409                         if (S_ISREG($to_mode_oct)) { # only for regular file
4410                                 $to_mode_str = sprintf("%04o", $to_mode_oct & 0777); # permission bits
4411                         }
4412                         $to_file_type = file_type($diff->{'to_mode'});
4413                 }
4414                 if ($diff->{'from_mode'} ne ('0' x 6)) {
4415                         $from_mode_oct = oct $diff->{'from_mode'};
4416                         if (S_ISREG($to_mode_oct)) { # only for regular file
4417                                 $from_mode_str = sprintf("%04o", $from_mode_oct & 0777); # permission bits
4418                         }
4419                         $from_file_type = file_type($diff->{'from_mode'});
4420                 }
4421
4422                 if ($diff->{'status'} eq "A") { # created
4423                         my $mode_chng = "<span class=\"file_status new\">[new $to_file_type";
4424                         $mode_chng   .= " with mode: $to_mode_str" if $to_mode_str;
4425                         $mode_chng   .= "]</span>";
4426                         print "<td>";
4427                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4428                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4429                                       -class => "list"}, esc_path($diff->{'file'}));
4430                         print "</td>\n";
4431                         print "<td>$mode_chng</td>\n";
4432                         print "<td class=\"link\">";
4433                         if ($action eq 'commitdiff') {
4434                                 # link to patch
4435                                 $patchno++;
4436                                 print $cgi->a({-href => "#patch$patchno"}, "patch");
4437                                 print " | ";
4438                         }
4439                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4440                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4441                                       "blob");
4442                         print "</td>\n";
4443
4444                 } elsif ($diff->{'status'} eq "D") { # deleted
4445                         my $mode_chng = "<span class=\"file_status deleted\">[deleted $from_file_type]</span>";
4446                         print "<td>";
4447                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4448                                                      hash_base=>$parent, file_name=>$diff->{'file'}),
4449                                        -class => "list"}, esc_path($diff->{'file'}));
4450                         print "</td>\n";
4451                         print "<td>$mode_chng</td>\n";
4452                         print "<td class=\"link\">";
4453                         if ($action eq 'commitdiff') {
4454                                 # link to patch
4455                                 $patchno++;
4456                                 print $cgi->a({-href => "#patch$patchno"}, "patch");
4457                                 print " | ";
4458                         }
4459                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4460                                                      hash_base=>$parent, file_name=>$diff->{'file'})},
4461                                       "blob") . " | ";
4462                         if ($have_blame) {
4463                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$parent,
4464                                                              file_name=>$diff->{'file'})},
4465                                               "blame") . " | ";
4466                         }
4467                         print $cgi->a({-href => href(action=>"history", hash_base=>$parent,
4468                                                      file_name=>$diff->{'file'})},
4469                                       "history");
4470                         print "</td>\n";
4471
4472                 } elsif ($diff->{'status'} eq "M" || $diff->{'status'} eq "T") { # modified, or type changed
4473                         my $mode_chnge = "";
4474                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4475                                 $mode_chnge = "<span class=\"file_status mode_chnge\">[changed";
4476                                 if ($from_file_type ne $to_file_type) {
4477                                         $mode_chnge .= " from $from_file_type to $to_file_type";
4478                                 }
4479                                 if (($from_mode_oct & 0777) != ($to_mode_oct & 0777)) {
4480                                         if ($from_mode_str && $to_mode_str) {
4481                                                 $mode_chnge .= " mode: $from_mode_str->$to_mode_str";
4482                                         } elsif ($to_mode_str) {
4483                                                 $mode_chnge .= " mode: $to_mode_str";
4484                                         }
4485                                 }
4486                                 $mode_chnge .= "]</span>\n";
4487                         }
4488                         print "<td>";
4489                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4490                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4491                                       -class => "list"}, esc_path($diff->{'file'}));
4492                         print "</td>\n";
4493                         print "<td>$mode_chnge</td>\n";
4494                         print "<td class=\"link\">";
4495                         if ($action eq 'commitdiff') {
4496                                 # link to patch
4497                                 $patchno++;
4498                                 print $cgi->a({-href => "#patch$patchno"}, "patch") .
4499                                       " | ";
4500                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4501                                 # "commit" view and modified file (not onlu mode changed)
4502                                 print $cgi->a({-href => href(action=>"blobdiff",
4503                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4504                                                              hash_base=>$hash, hash_parent_base=>$parent,
4505                                                              file_name=>$diff->{'file'})},
4506                                               "diff") .
4507                                       " | ";
4508                         }
4509                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4510                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4511                                        "blob") . " | ";
4512                         if ($have_blame) {
4513                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4514                                                              file_name=>$diff->{'file'})},
4515                                               "blame") . " | ";
4516                         }
4517                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4518                                                      file_name=>$diff->{'file'})},
4519                                       "history");
4520                         print "</td>\n";
4521
4522                 } elsif ($diff->{'status'} eq "R" || $diff->{'status'} eq "C") { # renamed or copied
4523                         my %status_name = ('R' => 'moved', 'C' => 'copied');
4524                         my $nstatus = $status_name{$diff->{'status'}};
4525                         my $mode_chng = "";
4526                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4527                                 # mode also for directories, so we cannot use $to_mode_str
4528                                 $mode_chng = sprintf(", mode: %04o", $to_mode_oct & 0777);
4529                         }
4530                         print "<td>" .
4531                               $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
4532                                                      hash=>$diff->{'to_id'}, file_name=>$diff->{'to_file'}),
4533                                       -class => "list"}, esc_path($diff->{'to_file'})) . "</td>\n" .
4534                               "<td><span class=\"file_status $nstatus\">[$nstatus from " .
4535                               $cgi->a({-href => href(action=>"blob", hash_base=>$parent,
4536                                                      hash=>$diff->{'from_id'}, file_name=>$diff->{'from_file'}),
4537                                       -class => "list"}, esc_path($diff->{'from_file'})) .
4538                               " with " . (int $diff->{'similarity'}) . "% similarity$mode_chng]</span></td>\n" .
4539                               "<td class=\"link\">";
4540                         if ($action eq 'commitdiff') {
4541                                 # link to patch
4542                                 $patchno++;
4543                                 print $cgi->a({-href => "#patch$patchno"}, "patch") .
4544                                       " | ";
4545                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4546                                 # "commit" view and modified file (not only pure rename or copy)
4547                                 print $cgi->a({-href => href(action=>"blobdiff",
4548                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4549                                                              hash_base=>$hash, hash_parent_base=>$parent,
4550                                                              file_name=>$diff->{'to_file'}, file_parent=>$diff->{'from_file'})},
4551                                               "diff") .
4552                                       " | ";
4553                         }
4554                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4555                                                      hash_base=>$parent, file_name=>$diff->{'to_file'})},
4556                                       "blob") . " | ";
4557                         if ($have_blame) {
4558                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4559                                                              file_name=>$diff->{'to_file'})},
4560                                               "blame") . " | ";
4561                         }
4562                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4563                                                     file_name=>$diff->{'to_file'})},
4564                                       "history");
4565                         print "</td>\n";
4566
4567                 } # we should not encounter Unmerged (U) or Unknown (X) status
4568                 print "</tr>\n";
4569         }
4570         print "</tbody>" if $has_header;
4571         print "</table>\n";
4572 }
4573
4574 sub git_patchset_body {
4575         my ($fd, $difftree, $hash, @hash_parents) = @_;
4576         my ($hash_parent) = $hash_parents[0];
4577
4578         my $is_combined = (@hash_parents > 1);
4579         my $patch_idx = 0;
4580         my $patch_number = 0;
4581         my $patch_line;
4582         my $diffinfo;
4583         my $to_name;
4584         my (%from, %to);
4585
4586         print "<div class=\"patchset\">\n";
4587
4588         # skip to first patch
4589         while ($patch_line = <$fd>) {
4590                 chomp $patch_line;
4591
4592                 last if ($patch_line =~ m/^diff /);
4593         }
4594
4595  PATCH:
4596         while ($patch_line) {
4597
4598                 # parse "git diff" header line
4599                 if ($patch_line =~ m/^diff --git (\"(?:[^\\\"]*(?:\\.[^\\\"]*)*)\"|[^ "]*) (.*)$/) {
4600                         # $1 is from_name, which we do not use
4601                         $to_name = unquote($2);
4602                         $to_name =~ s!^b/!!;
4603                 } elsif ($patch_line =~ m/^diff --(cc|combined) ("?.*"?)$/) {
4604                         # $1 is 'cc' or 'combined', which we do not use
4605                         $to_name = unquote($2);
4606                 } else {
4607                         $to_name = undef;
4608                 }
4609
4610                 # check if current patch belong to current raw line
4611                 # and parse raw git-diff line if needed
4612                 if (is_patch_split($diffinfo, { 'to_file' => $to_name })) {
4613                         # this is continuation of a split patch
4614                         print "<div class=\"patch cont\">\n";
4615                 } else {
4616                         # advance raw git-diff output if needed
4617                         $patch_idx++ if defined $diffinfo;
4618
4619                         # read and prepare patch information
4620                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
4621
4622                         # compact combined diff output can have some patches skipped
4623                         # find which patch (using pathname of result) we are at now;
4624                         if ($is_combined) {
4625                                 while ($to_name ne $diffinfo->{'to_file'}) {
4626                                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
4627                                               format_diff_cc_simplified($diffinfo, @hash_parents) .
4628                                               "</div>\n";  # class="patch"
4629
4630                                         $patch_idx++;
4631                                         $patch_number++;
4632
4633                                         last if $patch_idx > $#$difftree;
4634                                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
4635                                 }
4636                         }
4637
4638                         # modifies %from, %to hashes
4639                         parse_from_to_diffinfo($diffinfo, \%from, \%to, @hash_parents);
4640
4641                         # this is first patch for raw difftree line with $patch_idx index
4642                         # we index @$difftree array from 0, but number patches from 1
4643                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n";
4644                 }
4645
4646                 # git diff header
4647                 #assert($patch_line =~ m/^diff /) if DEBUG;
4648                 #assert($patch_line !~ m!$/$!) if DEBUG; # is chomp-ed
4649                 $patch_number++;
4650                 # print "git diff" header
4651                 print format_git_diff_header_line($patch_line, $diffinfo,
4652                                                   \%from, \%to);
4653
4654                 # print extended diff header
4655                 print "<div class=\"diff extended_header\">\n";
4656         EXTENDED_HEADER:
4657                 while ($patch_line = <$fd>) {
4658                         chomp $patch_line;
4659
4660                         last EXTENDED_HEADER if ($patch_line =~ m/^--- |^diff /);
4661
4662                         print format_extended_diff_header_line($patch_line, $diffinfo,
4663                                                                \%from, \%to);
4664                 }
4665                 print "</div>\n"; # class="diff extended_header"
4666
4667                 # from-file/to-file diff header
4668                 if (! $patch_line) {
4669                         print "</div>\n"; # class="patch"
4670                         last PATCH;
4671                 }
4672                 next PATCH if ($patch_line =~ m/^diff /);
4673                 #assert($patch_line =~ m/^---/) if DEBUG;
4674
4675                 my $last_patch_line = $patch_line;
4676                 $patch_line = <$fd>;
4677                 chomp $patch_line;
4678                 #assert($patch_line =~ m/^\+\+\+/) if DEBUG;
4679
4680                 print format_diff_from_to_header($last_patch_line, $patch_line,
4681                                                  $diffinfo, \%from, \%to,
4682                                                  @hash_parents);
4683
4684                 # the patch itself
4685         LINE:
4686                 while ($patch_line = <$fd>) {
4687                         chomp $patch_line;
4688
4689                         next PATCH if ($patch_line =~ m/^diff /);
4690
4691                         print format_diff_line($patch_line, \%from, \%to);
4692                 }
4693
4694         } continue {
4695                 print "</div>\n"; # class="patch"
4696         }
4697
4698         # for compact combined (--cc) format, with chunk and patch simplification
4699         # the patchset might be empty, but there might be unprocessed raw lines
4700         for (++$patch_idx if $patch_number > 0;
4701              $patch_idx < @$difftree;
4702              ++$patch_idx) {
4703                 # read and prepare patch information
4704                 $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
4705
4706                 # generate anchor for "patch" links in difftree / whatchanged part
4707                 print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
4708                       format_diff_cc_simplified($diffinfo, @hash_parents) .
4709                       "</div>\n";  # class="patch"
4710
4711                 $patch_number++;
4712         }
4713
4714         if ($patch_number == 0) {
4715                 if (@hash_parents > 1) {
4716                         print "<div class=\"diff nodifferences\">Trivial merge</div>\n";
4717                 } else {
4718                         print "<div class=\"diff nodifferences\">No differences found</div>\n";
4719                 }
4720         }
4721
4722         print "</div>\n"; # class="patchset"
4723 }
4724
4725 # . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
4726
4727 # fills project list info (age, description, owner, forks) for each
4728 # project in the list, removing invalid projects from returned list
4729 # NOTE: modifies $projlist, but does not remove entries from it
4730 sub fill_project_list_info {
4731         my ($projlist, $check_forks) = @_;
4732         my @projects;
4733
4734         my $show_ctags = gitweb_check_feature('ctags');
4735  PROJECT:
4736         foreach my $pr (@$projlist) {
4737                 my (@activity) = git_get_last_activity($pr->{'path'});
4738                 unless (@activity) {
4739                         next PROJECT;
4740                 }
4741                 ($pr->{'age'}, $pr->{'age_string'}) = @activity;
4742                 if (!defined $pr->{'descr'}) {
4743                         my $descr = git_get_project_description($pr->{'path'}) || "";
4744                         $descr = to_utf8($descr);
4745                         $pr->{'descr_long'} = $descr;
4746                         $pr->{'descr'} = chop_str($descr, $projects_list_description_width, 5);
4747                 }
4748                 if (!defined $pr->{'owner'}) {
4749                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}") || "";
4750                 }
4751                 if ($check_forks) {
4752                         my $pname = $pr->{'path'};
4753                         if (($pname =~ s/\.git$//) &&
4754                             ($pname !~ /\/$/) &&
4755                             (-d "$projectroot/$pname")) {
4756                                 $pr->{'forks'} = "-d $projectroot/$pname";
4757                         } else {
4758                                 $pr->{'forks'} = 0;
4759                         }
4760                 }
4761                 $show_ctags and $pr->{'ctags'} = git_get_project_ctags($pr->{'path'});
4762                 push @projects, $pr;
4763         }
4764
4765         return @projects;
4766 }
4767
4768 # print 'sort by' <th> element, generating 'sort by $name' replay link
4769 # if that order is not selected
4770 sub print_sort_th {
4771         print format_sort_th(@_);
4772 }
4773
4774 sub format_sort_th {
4775         my ($name, $order, $header) = @_;
4776         my $sort_th = "";
4777         $header ||= ucfirst($name);
4778
4779         if ($order eq $name) {
4780                 $sort_th .= "<th>$header</th>\n";
4781         } else {
4782                 $sort_th .= "<th>" .
4783                             $cgi->a({-href => href(-replay=>1, order=>$name),
4784                                      -class => "header"}, $header) .
4785                             "</th>\n";
4786         }
4787
4788         return $sort_th;
4789 }
4790
4791 sub git_project_list_body {
4792         # actually uses global variable $project
4793         my ($projlist, $order, $from, $to, $extra, $no_header) = @_;
4794
4795         my $check_forks = gitweb_check_feature('forks');
4796         my @projects = fill_project_list_info($projlist, $check_forks);
4797
4798         $order ||= $default_projects_order;
4799         $from = 0 unless defined $from;
4800         $to = $#projects if (!defined $to || $#projects < $to);
4801
4802         my %order_info = (
4803                 project => { key => 'path', type => 'str' },
4804                 descr => { key => 'descr_long', type => 'str' },
4805                 owner => { key => 'owner', type => 'str' },
4806                 age => { key => 'age', type => 'num' }
4807         );
4808         my $oi = $order_info{$order};
4809         if ($oi->{'type'} eq 'str') {
4810                 @projects = sort {$a->{$oi->{'key'}} cmp $b->{$oi->{'key'}}} @projects;
4811         } else {
4812                 @projects = sort {$a->{$oi->{'key'}} <=> $b->{$oi->{'key'}}} @projects;
4813         }
4814
4815         my $show_ctags = gitweb_check_feature('ctags');
4816         if ($show_ctags) {
4817                 my %ctags;
4818                 foreach my $p (@projects) {
4819                         foreach my $ct (keys %{$p->{'ctags'}}) {
4820                                 $ctags{$ct} += $p->{'ctags'}->{$ct};
4821                         }
4822                 }
4823                 my $cloud = git_populate_project_tagcloud(\%ctags);
4824                 print git_show_project_tagcloud($cloud, 64);
4825         }
4826
4827         print "<table class=\"project_list\">\n";
4828         unless ($no_header) {
4829                 print "<tr>\n";
4830                 if ($check_forks) {
4831                         print "<th></th>\n";
4832                 }
4833                 print_sort_th('project', $order, 'Project');
4834                 print_sort_th('descr', $order, 'Description');
4835                 print_sort_th('owner', $order, 'Owner');
4836                 print_sort_th('age', $order, 'Last Change');
4837                 print "<th></th>\n" . # for links
4838                       "</tr>\n";
4839         }
4840         my $alternate = 1;
4841         my $tagfilter = $cgi->param('by_tag');
4842         for (my $i = $from; $i <= $to; $i++) {
4843                 my $pr = $projects[$i];
4844
4845                 next if $tagfilter and $show_ctags and not grep { lc $_ eq lc $tagfilter } keys %{$pr->{'ctags'}};
4846                 next if $searchtext and not $pr->{'path'} =~ /$searchtext/
4847                         and not $pr->{'descr_long'} =~ /$searchtext/;
4848                 # Weed out forks or non-matching entries of search
4849                 if ($check_forks) {
4850                         my $forkbase = $project; $forkbase ||= ''; $forkbase =~ s#\.git$#/#;
4851                         $forkbase="^$forkbase" if $forkbase;
4852                         next if not $searchtext and not $tagfilter and $show_ctags
4853                                 and $pr->{'path'} =~ m#$forkbase.*/.*#; # regexp-safe
4854                 }
4855
4856                 if ($alternate) {
4857                         print "<tr class=\"dark\">\n";
4858                 } else {
4859                         print "<tr class=\"light\">\n";
4860                 }
4861                 $alternate ^= 1;
4862                 if ($check_forks) {
4863                         print "<td>";
4864                         if ($pr->{'forks'}) {
4865                                 print "<!-- $pr->{'forks'} -->\n";
4866                                 print $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "+");
4867                         }
4868                         print "</td>\n";
4869                 }
4870                 print "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
4871                                         -class => "list"}, esc_html($pr->{'path'})) . "</td>\n" .
4872                       "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
4873                                         -class => "list", -title => $pr->{'descr_long'}},
4874                                         esc_html($pr->{'descr'})) . "</td>\n" .
4875                       "<td><i>" . chop_and_escape_str($pr->{'owner'}, 15) . "</i></td>\n";
4876                 print "<td class=\"". age_class($pr->{'age'}) . "\">" .
4877                       (defined $pr->{'age_string'} ? $pr->{'age_string'} : "No commits") . "</td>\n" .
4878                       "<td class=\"link\">" .
4879                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary")}, "summary")   . " | " .
4880                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"shortlog")}, "shortlog") . " | " .
4881                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"log")}, "log") . " | " .
4882                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"tree")}, "tree") .
4883                       ($pr->{'forks'} ? " | " . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "forks") : '') .
4884                       "</td>\n" .
4885                       "</tr>\n";
4886         }
4887         if (defined $extra) {
4888                 print "<tr>\n";
4889                 if ($check_forks) {
4890                         print "<td></td>\n";
4891                 }
4892                 print "<td colspan=\"5\">$extra</td>\n" .
4893                       "</tr>\n";
4894         }
4895         print "</table>\n";
4896 }
4897
4898 sub git_log_body {
4899         # uses global variable $project
4900         my ($commitlist, $from, $to, $refs, $extra) = @_;
4901
4902         $from = 0 unless defined $from;
4903         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
4904
4905         for (my $i = 0; $i <= $to; $i++) {
4906                 my %co = %{$commitlist->[$i]};
4907                 next if !%co;
4908                 my $commit = $co{'id'};
4909                 my $ref = format_ref_marker($refs, $commit);
4910                 my %ad = parse_date($co{'author_epoch'});
4911                 git_print_header_div('commit',
4912                                "<span class=\"age\">$co{'age_string'}</span>" .
4913                                esc_html($co{'title'}) . $ref,
4914                                $commit);
4915                 print "<div class=\"title_text\">\n" .
4916                       "<div class=\"log_link\">\n" .
4917                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") .
4918                       " | " .
4919                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") .
4920                       " | " .
4921                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree") .
4922                       "<br/>\n" .
4923                       "</div>\n";
4924                       git_print_authorship(\%co, -tag => 'span');
4925                       print "<br/>\n</div>\n";
4926
4927                 print "<div class=\"log_body\">\n";
4928                 git_print_log($co{'comment'}, -final_empty_line=> 1);
4929                 print "</div>\n";
4930         }
4931         if ($extra) {
4932                 print "<div class=\"page_nav\">\n";
4933                 print "$extra\n";
4934                 print "</div>\n";
4935         }
4936 }
4937
4938 sub git_shortlog_body {
4939         # uses global variable $project
4940         my ($commitlist, $from, $to, $refs, $extra) = @_;
4941
4942         $from = 0 unless defined $from;
4943         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
4944
4945         print "<table class=\"shortlog\">\n";
4946         my $alternate = 1;
4947         for (my $i = $from; $i <= $to; $i++) {
4948                 my %co = %{$commitlist->[$i]};
4949                 my $commit = $co{'id'};
4950                 my $ref = format_ref_marker($refs, $commit);
4951                 if ($alternate) {
4952                         print "<tr class=\"dark\">\n";
4953                 } else {
4954                         print "<tr class=\"light\">\n";
4955                 }
4956                 $alternate ^= 1;
4957                 # git_summary() used print "<td><i>$co{'age_string'}</i></td>\n" .
4958                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
4959                       format_author_html('td', \%co, 10) . "<td>";
4960                 print format_subject_html($co{'title'}, $co{'title_short'},
4961                                           href(action=>"commit", hash=>$commit), $ref);
4962                 print "</td>\n" .
4963                       "<td class=\"link\">" .
4964                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") . " | " .
4965                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") . " | " .
4966                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree");
4967                 my $snapshot_links = format_snapshot_links($commit);
4968                 if (defined $snapshot_links) {
4969                         print " | " . $snapshot_links;
4970                 }
4971                 print "</td>\n" .
4972                       "</tr>\n";
4973         }
4974         if (defined $extra) {
4975                 print "<tr>\n" .
4976                       "<td colspan=\"4\">$extra</td>\n" .
4977                       "</tr>\n";
4978         }
4979         print "</table>\n";
4980 }
4981
4982 sub git_history_body {
4983         # Warning: assumes constant type (blob or tree) during history
4984         my ($commitlist, $from, $to, $refs, $extra,
4985             $file_name, $file_hash, $ftype) = @_;
4986
4987         $from = 0 unless defined $from;
4988         $to = $#{$commitlist} unless (defined $to && $to <= $#{$commitlist});
4989
4990         print "<table class=\"history\">\n";
4991         my $alternate = 1;
4992         for (my $i = $from; $i <= $to; $i++) {
4993                 my %co = %{$commitlist->[$i]};
4994                 if (!%co) {
4995                         next;
4996                 }
4997                 my $commit = $co{'id'};
4998
4999                 my $ref = format_ref_marker($refs, $commit);
5000
5001                 if ($alternate) {
5002                         print "<tr class=\"dark\">\n";
5003                 } else {
5004                         print "<tr class=\"light\">\n";
5005                 }
5006                 $alternate ^= 1;
5007                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5008         # shortlog:   format_author_html('td', \%co, 10)
5009                       format_author_html('td', \%co, 15, 3) . "<td>";
5010                 # originally git_history used chop_str($co{'title'}, 50)
5011                 print format_subject_html($co{'title'}, $co{'title_short'},
5012                                           href(action=>"commit", hash=>$commit), $ref);
5013                 print "</td>\n" .
5014                       "<td class=\"link\">" .
5015                       $cgi->a({-href => href(action=>$ftype, hash_base=>$commit, file_name=>$file_name)}, $ftype) . " | " .
5016                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff");
5017
5018                 if ($ftype eq 'blob') {
5019                         my $blob_current = $file_hash;
5020                         my $blob_parent  = git_get_hash_by_path($commit, $file_name);
5021                         if (defined $blob_current && defined $blob_parent &&
5022                                         $blob_current ne $blob_parent) {
5023                                 print " | " .
5024                                         $cgi->a({-href => href(action=>"blobdiff",
5025                                                                hash=>$blob_current, hash_parent=>$blob_parent,
5026                                                                hash_base=>$hash_base, hash_parent_base=>$commit,
5027                                                                file_name=>$file_name)},
5028                                                 "diff to current");
5029                         }
5030                 }
5031                 print "</td>\n" .
5032                       "</tr>\n";
5033         }
5034         if (defined $extra) {
5035                 print "<tr>\n" .
5036                       "<td colspan=\"4\">$extra</td>\n" .
5037                       "</tr>\n";
5038         }
5039         print "</table>\n";
5040 }
5041
5042 sub git_tags_body {
5043         # uses global variable $project
5044         my ($taglist, $from, $to, $extra) = @_;
5045         $from = 0 unless defined $from;
5046         $to = $#{$taglist} if (!defined $to || $#{$taglist} < $to);
5047
5048         print "<table class=\"tags\">\n";
5049         my $alternate = 1;
5050         for (my $i = $from; $i <= $to; $i++) {
5051                 my $entry = $taglist->[$i];
5052                 my %tag = %$entry;
5053                 my $comment = $tag{'subject'};
5054                 my $comment_short;
5055                 if (defined $comment) {
5056                         $comment_short = chop_str($comment, 30, 5);
5057                 }
5058                 if ($alternate) {
5059                         print "<tr class=\"dark\">\n";
5060                 } else {
5061                         print "<tr class=\"light\">\n";
5062                 }
5063                 $alternate ^= 1;
5064                 if (defined $tag{'age'}) {
5065                         print "<td><i>$tag{'age'}</i></td>\n";
5066                 } else {
5067                         print "<td></td>\n";
5068                 }
5069                 print "<td>" .
5070                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'}),
5071                                -class => "list name"}, esc_html($tag{'name'})) .
5072                       "</td>\n" .
5073                       "<td>";
5074                 if (defined $comment) {
5075                         print format_subject_html($comment, $comment_short,
5076                                                   href(action=>"tag", hash=>$tag{'id'}));
5077                 }
5078                 print "</td>\n" .
5079                       "<td class=\"selflink\">";
5080                 if ($tag{'type'} eq "tag") {
5081                         print $cgi->a({-href => href(action=>"tag", hash=>$tag{'id'})}, "tag");
5082                 } else {
5083                         print "&nbsp;";
5084                 }
5085                 print "</td>\n" .
5086                       "<td class=\"link\">" . " | " .
5087                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'})}, $tag{'reftype'});
5088                 if ($tag{'reftype'} eq "commit") {
5089                         print " | " . $cgi->a({-href => href(action=>"shortlog", hash=>$tag{'fullname'})}, "shortlog") .
5090                               " | " . $cgi->a({-href => href(action=>"log", hash=>$tag{'fullname'})}, "log");
5091                 } elsif ($tag{'reftype'} eq "blob") {
5092                         print " | " . $cgi->a({-href => href(action=>"blob_plain", hash=>$tag{'refid'})}, "raw");
5093                 }
5094                 print "</td>\n" .
5095                       "</tr>";
5096         }
5097         if (defined $extra) {
5098                 print "<tr>\n" .
5099                       "<td colspan=\"5\">$extra</td>\n" .
5100                       "</tr>\n";
5101         }
5102         print "</table>\n";
5103 }
5104
5105 sub git_heads_body {
5106         # uses global variable $project
5107         my ($headlist, $head, $from, $to, $extra) = @_;
5108         $from = 0 unless defined $from;
5109         $to = $#{$headlist} if (!defined $to || $#{$headlist} < $to);
5110
5111         print "<table class=\"heads\">\n";
5112         my $alternate = 1;
5113         for (my $i = $from; $i <= $to; $i++) {
5114                 my $entry = $headlist->[$i];
5115                 my %ref = %$entry;
5116                 my $curr = $ref{'id'} eq $head;
5117                 if ($alternate) {
5118                         print "<tr class=\"dark\">\n";
5119                 } else {
5120                         print "<tr class=\"light\">\n";
5121                 }
5122                 $alternate ^= 1;
5123                 print "<td><i>$ref{'age'}</i></td>\n" .
5124                       ($curr ? "<td class=\"current_head\">" : "<td>") .
5125                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'}),
5126                                -class => "list name"},esc_html($ref{'name'})) .
5127                       "</td>\n" .
5128                       "<td class=\"link\">" .
5129                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'})}, "shortlog") . " | " .
5130                       $cgi->a({-href => href(action=>"log", hash=>$ref{'fullname'})}, "log") . " | " .
5131                       $cgi->a({-href => href(action=>"tree", hash=>$ref{'fullname'}, hash_base=>$ref{'fullname'})}, "tree") .
5132                       "</td>\n" .
5133                       "</tr>";
5134         }
5135         if (defined $extra) {
5136                 print "<tr>\n" .
5137                       "<td colspan=\"3\">$extra</td>\n" .
5138                       "</tr>\n";
5139         }
5140         print "</table>\n";
5141 }
5142
5143 # Display a single remote block
5144 sub git_remote_block {
5145         my ($remote, $rdata, $limit, $head) = @_;
5146
5147         my $heads = $rdata->{'heads'};
5148         my $fetch = $rdata->{'fetch'};
5149         my $push = $rdata->{'push'};
5150
5151         my $urls_table = "<table class=\"projects_list\">\n" ;
5152
5153         if (defined $fetch) {
5154                 if ($fetch eq $push) {
5155                         $urls_table .= format_repo_url("URL", $fetch);
5156                 } else {
5157                         $urls_table .= format_repo_url("Fetch URL", $fetch);
5158                         $urls_table .= format_repo_url("Push URL", $push) if defined $push;
5159                 }
5160         } elsif (defined $push) {
5161                 $urls_table .= format_repo_url("Push URL", $push);
5162         } else {
5163                 $urls_table .= format_repo_url("", "No remote URL");
5164         }
5165
5166         $urls_table .= "</table>\n";
5167
5168         my $dots;
5169         if (defined $limit && $limit < @$heads) {
5170                 $dots = $cgi->a({-href => href(action=>"remotes", hash=>$remote)}, "...");
5171         }
5172
5173         print $urls_table;
5174         git_heads_body($heads, $head, 0, $limit, $dots);
5175 }
5176
5177 # Display a list of remote names with the respective fetch and push URLs
5178 sub git_remotes_list {
5179         my ($remotedata, $limit) = @_;
5180         print "<table class=\"heads\">\n";
5181         my $alternate = 1;
5182         my @remotes = sort keys %$remotedata;
5183
5184         my $limited = $limit && $limit < @remotes;
5185
5186         $#remotes = $limit - 1 if $limited;
5187
5188         while (my $remote = shift @remotes) {
5189                 my $rdata = $remotedata->{$remote};
5190                 my $fetch = $rdata->{'fetch'};
5191                 my $push = $rdata->{'push'};
5192                 if ($alternate) {
5193                         print "<tr class=\"dark\">\n";
5194                 } else {
5195                         print "<tr class=\"light\">\n";
5196                 }
5197                 $alternate ^= 1;
5198                 print "<td>" .
5199                       $cgi->a({-href=> href(action=>'remotes', hash=>$remote),
5200                                -class=> "list name"},esc_html($remote)) .
5201                       "</td>";
5202                 print "<td class=\"link\">" .
5203                       (defined $fetch ? $cgi->a({-href=> $fetch}, "fetch") : "fetch") .
5204                       " | " .
5205                       (defined $push ? $cgi->a({-href=> $push}, "push") : "push") .
5206                       "</td>";
5207
5208                 print "</tr>\n";
5209         }
5210
5211         if ($limited) {
5212                 print "<tr>\n" .
5213                       "<td colspan=\"3\">" .
5214                       $cgi->a({-href => href(action=>"remotes")}, "...") .
5215                       "</td>\n" . "</tr>\n";
5216         }
5217
5218         print "</table>";
5219 }
5220
5221 # Display remote heads grouped by remote, unless there are too many
5222 # remotes, in which case we only display the remote names
5223 sub git_remotes_body {
5224         my ($remotedata, $limit, $head) = @_;
5225         if ($limit and $limit < keys %$remotedata) {
5226                 git_remotes_list($remotedata, $limit);
5227         } else {
5228                 fill_remote_heads($remotedata);
5229                 while (my ($remote, $rdata) = each %$remotedata) {
5230                         git_print_section({-class=>"remote", -id=>$remote},
5231                                 ["remotes", $remote, $remote], sub {
5232                                         git_remote_block($remote, $rdata, $limit, $head);
5233                                 });
5234                 }
5235         }
5236 }
5237
5238 sub git_search_grep_body {
5239         my ($commitlist, $from, $to, $extra) = @_;
5240         $from = 0 unless defined $from;
5241         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5242
5243         print "<table class=\"commit_search\">\n";
5244         my $alternate = 1;
5245         for (my $i = $from; $i <= $to; $i++) {
5246                 my %co = %{$commitlist->[$i]};
5247                 if (!%co) {
5248                         next;
5249                 }
5250                 my $commit = $co{'id'};
5251                 if ($alternate) {
5252                         print "<tr class=\"dark\">\n";
5253                 } else {
5254                         print "<tr class=\"light\">\n";
5255                 }
5256                 $alternate ^= 1;
5257                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5258                       format_author_html('td', \%co, 15, 5) .
5259                       "<td>" .
5260                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
5261                                -class => "list subject"},
5262                               chop_and_escape_str($co{'title'}, 50) . "<br/>");
5263                 my $comment = $co{'comment'};
5264                 foreach my $line (@$comment) {
5265                         if ($line =~ m/^(.*?)($search_regexp)(.*)$/i) {
5266                                 my ($lead, $match, $trail) = ($1, $2, $3);
5267                                 $match = chop_str($match, 70, 5, 'center');
5268                                 my $contextlen = int((80 - length($match))/2);
5269                                 $contextlen = 30 if ($contextlen > 30);
5270                                 $lead  = chop_str($lead,  $contextlen, 10, 'left');
5271                                 $trail = chop_str($trail, $contextlen, 10, 'right');
5272
5273                                 $lead  = esc_html($lead);
5274                                 $match = esc_html($match);
5275                                 $trail = esc_html($trail);
5276
5277                                 print "$lead<span class=\"match\">$match</span>$trail<br />";
5278                         }
5279                 }
5280                 print "</td>\n" .
5281                       "<td class=\"link\">" .
5282                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
5283                       " | " .
5284                       $cgi->a({-href => href(action=>"commitdiff", hash=>$co{'id'})}, "commitdiff") .
5285                       " | " .
5286                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
5287                 print "</td>\n" .
5288                       "</tr>\n";
5289         }
5290         if (defined $extra) {
5291                 print "<tr>\n" .
5292                       "<td colspan=\"3\">$extra</td>\n" .
5293                       "</tr>\n";
5294         }
5295         print "</table>\n";
5296 }
5297
5298 ## ======================================================================
5299 ## ======================================================================
5300 ## actions
5301
5302 sub git_project_list {
5303         my $order = $input_params{'order'};
5304         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
5305                 die_error(400, "Unknown order parameter");
5306         }
5307
5308         my @list = git_get_projects_list();
5309         if (!@list) {
5310                 die_error(404, "No projects found");
5311         }
5312
5313         git_header_html();
5314         if (defined $home_text && -f $home_text) {
5315                 print "<div class=\"index_include\">\n";
5316                 insert_file($home_text);
5317                 print "</div>\n";
5318         }
5319         print $cgi->startform(-method => "get") .
5320               "<p class=\"projsearch\">Search:\n" .
5321               $cgi->textfield(-name => "s", -value => $searchtext) . "\n" .
5322               "</p>" .
5323               $cgi->end_form() . "\n";
5324         git_project_list_body(\@list, $order);
5325         git_footer_html();
5326 }
5327
5328 sub git_forks {
5329         my $order = $input_params{'order'};
5330         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
5331                 die_error(400, "Unknown order parameter");
5332         }
5333
5334         my @list = git_get_projects_list($project);
5335         if (!@list) {
5336                 die_error(404, "No forks found");
5337         }
5338
5339         git_header_html();
5340         git_print_page_nav('','');
5341         git_print_header_div('summary', "$project forks");
5342         git_project_list_body(\@list, $order);
5343         git_footer_html();
5344 }
5345
5346 sub git_project_index {
5347         my @projects = git_get_projects_list($project);
5348
5349         print $cgi->header(
5350                 -type => 'text/plain',
5351                 -charset => 'utf-8',
5352                 -content_disposition => 'inline; filename="index.aux"');
5353
5354         foreach my $pr (@projects) {
5355                 if (!exists $pr->{'owner'}) {
5356                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}");
5357                 }
5358
5359                 my ($path, $owner) = ($pr->{'path'}, $pr->{'owner'});
5360                 # quote as in CGI::Util::encode, but keep the slash, and use '+' for ' '
5361                 $path  =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
5362                 $owner =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
5363                 $path  =~ s/ /\+/g;
5364                 $owner =~ s/ /\+/g;
5365
5366                 print "$path $owner\n";
5367         }
5368 }
5369
5370 sub git_summary {
5371         my $descr = git_get_project_description($project) || "none";
5372         my %co = parse_commit("HEAD");
5373         my %cd = %co ? parse_date($co{'committer_epoch'}, $co{'committer_tz'}) : ();
5374         my $head = $co{'id'};
5375         my $remote_heads = gitweb_check_feature('remote_heads');
5376
5377         my $owner = git_get_project_owner($project);
5378
5379         my $refs = git_get_references();
5380         # These get_*_list functions return one more to allow us to see if
5381         # there are more ...
5382         my @taglist  = git_get_tags_list(16);
5383         my @headlist = git_get_heads_list(16);
5384         my %remotedata = $remote_heads ? git_get_remotes_list() : ();
5385         my @forklist;
5386         my $check_forks = gitweb_check_feature('forks');
5387
5388         if ($check_forks) {
5389                 @forklist = git_get_projects_list($project);
5390         }
5391
5392         git_header_html();
5393         git_print_page_nav('summary','', $head);
5394
5395         print "<div class=\"title\">&nbsp;</div>\n";
5396         print "<table class=\"projects_list\">\n" .
5397               "<tr id=\"metadata_desc\"><td>description</td><td>" . esc_html($descr) . "</td></tr>\n" .
5398               "<tr id=\"metadata_owner\"><td>owner</td><td>" . esc_html($owner) . "</td></tr>\n";
5399         if (defined $cd{'rfc2822'}) {
5400                 print "<tr id=\"metadata_lchange\"><td>last change</td><td>$cd{'rfc2822'}</td></tr>\n";
5401         }
5402
5403         # use per project git URL list in $projectroot/$project/cloneurl
5404         # or make project git URL from git base URL and project name
5405         my $url_tag = "URL";
5406         my @url_list = git_get_project_url_list($project);
5407         @url_list = map { "$_/$project" } @git_base_url_list unless @url_list;
5408         foreach my $git_url (@url_list) {
5409                 next unless $git_url;
5410                 print format_repo_url($url_tag, $git_url);
5411                 $url_tag = "";
5412         }
5413
5414         # Tag cloud
5415         my $show_ctags = gitweb_check_feature('ctags');
5416         if ($show_ctags) {
5417                 my $ctags = git_get_project_ctags($project);
5418                 my $cloud = git_populate_project_tagcloud($ctags);
5419                 print "<tr id=\"metadata_ctags\"><td>Content tags:<br />";
5420                 print "</td>\n<td>" unless %$ctags;
5421                 print "<form action=\"$show_ctags\" method=\"post\"><input type=\"hidden\" name=\"p\" value=\"$project\" />Add: <input type=\"text\" name=\"t\" size=\"8\" /></form>";
5422                 print "</td>\n<td>" if %$ctags;
5423                 print git_show_project_tagcloud($cloud, 48);
5424                 print "</td></tr>";
5425         }
5426
5427         print "</table>\n";
5428
5429         # If XSS prevention is on, we don't include README.html.
5430         # TODO: Allow a readme in some safe format.
5431         if (!$prevent_xss && -s "$projectroot/$project/README.html") {
5432                 print "<div class=\"title\">readme</div>\n" .
5433                       "<div class=\"readme\">\n";
5434                 insert_file("$projectroot/$project/README.html");
5435                 print "\n</div>\n"; # class="readme"
5436         }
5437
5438         # we need to request one more than 16 (0..15) to check if
5439         # those 16 are all
5440         my @commitlist = $head ? parse_commits($head, 17) : ();
5441         if (@commitlist) {
5442                 git_print_header_div('shortlog');
5443                 git_shortlog_body(\@commitlist, 0, 15, $refs,
5444                                   $#commitlist <=  15 ? undef :
5445                                   $cgi->a({-href => href(action=>"shortlog")}, "..."));
5446         }
5447
5448         if (@taglist) {
5449                 git_print_header_div('tags');
5450                 git_tags_body(\@taglist, 0, 15,
5451                               $#taglist <=  15 ? undef :
5452                               $cgi->a({-href => href(action=>"tags")}, "..."));
5453         }
5454
5455         if (@headlist) {
5456                 git_print_header_div('heads');
5457                 git_heads_body(\@headlist, $head, 0, 15,
5458                                $#headlist <= 15 ? undef :
5459                                $cgi->a({-href => href(action=>"heads")}, "..."));
5460         }
5461
5462         if (%remotedata) {
5463                 git_print_header_div('remotes');
5464                 git_remotes_body(\%remotedata, 15, $head);
5465         }
5466
5467         if (@forklist) {
5468                 git_print_header_div('forks');
5469                 git_project_list_body(\@forklist, 'age', 0, 15,
5470                                       $#forklist <= 15 ? undef :
5471                                       $cgi->a({-href => href(action=>"forks")}, "..."),
5472                                       'no_header');
5473         }
5474
5475         git_footer_html();
5476 }
5477
5478 sub git_tag {
5479         my %tag = parse_tag($hash);
5480
5481         if (! %tag) {
5482                 die_error(404, "Unknown tag object");
5483         }
5484
5485         my $head = git_get_head_hash($project);
5486         git_header_html();
5487         git_print_page_nav('','', $head,undef,$head);
5488         git_print_header_div('commit', esc_html($tag{'name'}), $hash);
5489         print "<div class=\"title_text\">\n" .
5490               "<table class=\"object_header\">\n" .
5491               "<tr>\n" .
5492               "<td>object</td>\n" .
5493               "<td>" . $cgi->a({-class => "list", -href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
5494                                $tag{'object'}) . "</td>\n" .
5495               "<td class=\"link\">" . $cgi->a({-href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
5496                                               $tag{'type'}) . "</td>\n" .
5497               "</tr>\n";
5498         if (defined($tag{'author'})) {
5499                 git_print_authorship_rows(\%tag, 'author');
5500         }
5501         print "</table>\n\n" .
5502               "</div>\n";
5503         print "<div class=\"page_body\">";
5504         my $comment = $tag{'comment'};
5505         foreach my $line (@$comment) {
5506                 chomp $line;
5507                 print esc_html($line, -nbsp=>1) . "<br/>\n";
5508         }
5509         print "</div>\n";
5510         git_footer_html();
5511 }
5512
5513 sub git_blame_common {
5514         my $format = shift || 'porcelain';
5515         if ($format eq 'porcelain' && $cgi->param('js')) {
5516                 $format = 'incremental';
5517                 $action = 'blame_incremental'; # for page title etc
5518         }
5519
5520         # permissions
5521         gitweb_check_feature('blame')
5522                 or die_error(403, "Blame view not allowed");
5523
5524         # error checking
5525         die_error(400, "No file name given") unless $file_name;
5526         $hash_base ||= git_get_head_hash($project);
5527         die_error(404, "Couldn't find base commit") unless $hash_base;
5528         my %co = parse_commit($hash_base)
5529                 or die_error(404, "Commit not found");
5530         my $ftype = "blob";
5531         if (!defined $hash) {
5532                 $hash = git_get_hash_by_path($hash_base, $file_name, "blob")
5533                         or die_error(404, "Error looking up file");
5534         } else {
5535                 $ftype = git_get_type($hash);
5536                 if ($ftype !~ "blob") {
5537                         die_error(400, "Object is not a blob");
5538                 }
5539         }
5540
5541         my $fd;
5542         if ($format eq 'incremental') {
5543                 # get file contents (as base)
5544                 open $fd, "-|", git_cmd(), 'cat-file', 'blob', $hash
5545                         or die_error(500, "Open git-cat-file failed");
5546         } elsif ($format eq 'data') {
5547                 # run git-blame --incremental
5548                 open $fd, "-|", git_cmd(), "blame", "--incremental",
5549                         $hash_base, "--", $file_name
5550                         or die_error(500, "Open git-blame --incremental failed");
5551         } else {
5552                 # run git-blame --porcelain
5553                 open $fd, "-|", git_cmd(), "blame", '-p',
5554                         $hash_base, '--', $file_name
5555                         or die_error(500, "Open git-blame --porcelain failed");
5556         }
5557
5558         # incremental blame data returns early
5559         if ($format eq 'data') {
5560                 print $cgi->header(
5561                         -type=>"text/plain", -charset => "utf-8",
5562                         -status=> "200 OK");
5563                 local $| = 1; # output autoflush
5564                 print while <$fd>;
5565                 close $fd
5566                         or print "ERROR $!\n";
5567
5568                 print 'END';
5569                 if (defined $t0 && gitweb_check_feature('timed')) {
5570                         print ' '.
5571                               tv_interval($t0, [ gettimeofday() ]).
5572                               ' '.$number_of_git_cmds;
5573                 }
5574                 print "\n";
5575
5576                 return;
5577         }
5578
5579         # page header
5580         git_header_html();
5581         my $formats_nav =
5582                 $cgi->a({-href => href(action=>"blob", -replay=>1)},
5583                         "blob") .
5584                 " | ";
5585         if ($format eq 'incremental') {
5586                 $formats_nav .=
5587                         $cgi->a({-href => href(action=>"blame", javascript=>0, -replay=>1)},
5588                                 "blame") . " (non-incremental)";
5589         } else {
5590                 $formats_nav .=
5591                         $cgi->a({-href => href(action=>"blame_incremental", -replay=>1)},
5592                                 "blame") . " (incremental)";
5593         }
5594         $formats_nav .=
5595                 " | " .
5596                 $cgi->a({-href => href(action=>"history", -replay=>1)},
5597                         "history") .
5598                 " | " .
5599                 $cgi->a({-href => href(action=>$action, file_name=>$file_name)},
5600                         "HEAD");
5601         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
5602         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
5603         git_print_page_path($file_name, $ftype, $hash_base);
5604
5605         # page body
5606         if ($format eq 'incremental') {
5607                 print "<noscript>\n<div class=\"error\"><center><b>\n".
5608                       "This page requires JavaScript to run.\n Use ".
5609                       $cgi->a({-href => href(action=>'blame',javascript=>0,-replay=>1)},
5610                               'this page').
5611                       " instead.\n".
5612                       "</b></center></div>\n</noscript>\n";
5613
5614                 print qq!<div id="progress_bar" style="width: 100%; background-color: yellow"></div>\n!;
5615         }
5616
5617         print qq!<div class="page_body">\n!;
5618         print qq!<div id="progress_info">... / ...</div>\n!
5619                 if ($format eq 'incremental');
5620         print qq!<table id="blame_table" class="blame" width="100%">\n!.
5621               #qq!<col width="5.5em" /><col width="2.5em" /><col width="*" />\n!.
5622               qq!<thead>\n!.
5623               qq!<tr><th>Commit</th><th>Line</th><th>Data</th></tr>\n!.
5624               qq!</thead>\n!.
5625               qq!<tbody>\n!;
5626
5627         my @rev_color = qw(light dark);
5628         my $num_colors = scalar(@rev_color);
5629         my $current_color = 0;
5630
5631         if ($format eq 'incremental') {
5632                 my $color_class = $rev_color[$current_color];
5633
5634                 #contents of a file
5635                 my $linenr = 0;
5636         LINE:
5637                 while (my $line = <$fd>) {
5638                         chomp $line;
5639                         $linenr++;
5640
5641                         print qq!<tr id="l$linenr" class="$color_class">!.
5642                               qq!<td class="sha1"><a href=""> </a></td>!.
5643                               qq!<td class="linenr">!.
5644                               qq!<a class="linenr" href="">$linenr</a></td>!;
5645                         print qq!<td class="pre">! . esc_html($line) . "</td>\n";
5646                         print qq!</tr>\n!;
5647                 }
5648
5649         } else { # porcelain, i.e. ordinary blame
5650                 my %metainfo = (); # saves information about commits
5651
5652                 # blame data
5653         LINE:
5654                 while (my $line = <$fd>) {
5655                         chomp $line;
5656                         # the header: <SHA-1> <src lineno> <dst lineno> [<lines in group>]
5657                         # no <lines in group> for subsequent lines in group of lines
5658                         my ($full_rev, $orig_lineno, $lineno, $group_size) =
5659                            ($line =~ /^([0-9a-f]{40}) (\d+) (\d+)(?: (\d+))?$/);
5660                         if (!exists $metainfo{$full_rev}) {
5661                                 $metainfo{$full_rev} = { 'nprevious' => 0 };
5662                         }
5663                         my $meta = $metainfo{$full_rev};
5664                         my $data;
5665                         while ($data = <$fd>) {
5666                                 chomp $data;
5667                                 last if ($data =~ s/^\t//); # contents of line
5668                                 if ($data =~ /^(\S+)(?: (.*))?$/) {
5669                                         $meta->{$1} = $2 unless exists $meta->{$1};
5670                                 }
5671                                 if ($data =~ /^previous /) {
5672                                         $meta->{'nprevious'}++;
5673                                 }
5674                         }
5675                         my $short_rev = substr($full_rev, 0, 8);
5676                         my $author = $meta->{'author'};
5677                         my %date =
5678                                 parse_date($meta->{'author-time'}, $meta->{'author-tz'});
5679                         my $date = $date{'iso-tz'};
5680                         if ($group_size) {
5681                                 $current_color = ($current_color + 1) % $num_colors;
5682                         }
5683                         my $tr_class = $rev_color[$current_color];
5684                         $tr_class .= ' boundary' if (exists $meta->{'boundary'});
5685                         $tr_class .= ' no-previous' if ($meta->{'nprevious'} == 0);
5686                         $tr_class .= ' multiple-previous' if ($meta->{'nprevious'} > 1);
5687                         print "<tr id=\"l$lineno\" class=\"$tr_class\">\n";
5688                         if ($group_size) {
5689                                 print "<td class=\"sha1\"";
5690                                 print " title=\"". esc_html($author) . ", $date\"";
5691                                 print " rowspan=\"$group_size\"" if ($group_size > 1);
5692                                 print ">";
5693                                 print $cgi->a({-href => href(action=>"commit",
5694                                                              hash=>$full_rev,
5695                                                              file_name=>$file_name)},
5696                                               esc_html($short_rev));
5697                                 if ($group_size >= 2) {
5698                                         my @author_initials = ($author =~ /\b([[:upper:]])\B/g);
5699                                         if (@author_initials) {
5700                                                 print "<br />" .
5701                                                       esc_html(join('', @author_initials));
5702                                                 #           or join('.', ...)
5703                                         }
5704                                 }
5705                                 print "</td>\n";
5706                         }
5707                         # 'previous' <sha1 of parent commit> <filename at commit>
5708                         if (exists $meta->{'previous'} &&
5709                             $meta->{'previous'} =~ /^([a-fA-F0-9]{40}) (.*)$/) {
5710                                 $meta->{'parent'} = $1;
5711                                 $meta->{'file_parent'} = unquote($2);
5712                         }
5713                         my $linenr_commit =
5714                                 exists($meta->{'parent'}) ?
5715                                 $meta->{'parent'} : $full_rev;
5716                         my $linenr_filename =
5717                                 exists($meta->{'file_parent'}) ?
5718                                 $meta->{'file_parent'} : unquote($meta->{'filename'});
5719                         my $blamed = href(action => 'blame',
5720                                           file_name => $linenr_filename,
5721                                           hash_base => $linenr_commit);
5722                         print "<td class=\"linenr\">";
5723                         print $cgi->a({ -href => "$blamed#l$orig_lineno",
5724                                         -class => "linenr" },
5725                                       esc_html($lineno));
5726                         print "</td>";
5727                         print "<td class=\"pre\">" . esc_html($data) . "</td>\n";
5728                         print "</tr>\n";
5729                 } # end while
5730
5731         }
5732
5733         # footer
5734         print "</tbody>\n".
5735               "</table>\n"; # class="blame"
5736         print "</div>\n";   # class="blame_body"
5737         close $fd
5738                 or print "Reading blob failed\n";
5739
5740         git_footer_html();
5741 }
5742
5743 sub git_blame {
5744         git_blame_common();
5745 }
5746
5747 sub git_blame_incremental {
5748         git_blame_common('incremental');
5749 }
5750
5751 sub git_blame_data {
5752         git_blame_common('data');
5753 }
5754
5755 sub git_tags {
5756         my $head = git_get_head_hash($project);
5757         git_header_html();
5758         git_print_page_nav('','', $head,undef,$head,format_ref_views('tags'));
5759         git_print_header_div('summary', $project);
5760
5761         my @tagslist = git_get_tags_list();
5762         if (@tagslist) {
5763                 git_tags_body(\@tagslist);
5764         }
5765         git_footer_html();
5766 }
5767
5768 sub git_heads {
5769         my $head = git_get_head_hash($project);
5770         git_header_html();
5771         git_print_page_nav('','', $head,undef,$head,format_ref_views('heads'));
5772         git_print_header_div('summary', $project);
5773
5774         my @headslist = git_get_heads_list();
5775         if (@headslist) {
5776                 git_heads_body(\@headslist, $head);
5777         }
5778         git_footer_html();
5779 }
5780
5781 # used both for single remote view and for list of all the remotes
5782 sub git_remotes {
5783         gitweb_check_feature('remote_heads')
5784                 or die_error(403, "Remote heads view is disabled");
5785
5786         my $head = git_get_head_hash($project);
5787         my $remote = $input_params{'hash'};
5788
5789         my $remotedata = git_get_remotes_list($remote);
5790         die_error(500, "Unable to get remote information") unless defined $remotedata;
5791
5792         unless (%$remotedata) {
5793                 die_error(404, defined $remote ?
5794                         "Remote $remote not found" :
5795                         "No remotes found");
5796         }
5797
5798         git_header_html(undef, undef, -action_extra => $remote);
5799         git_print_page_nav('', '',  $head, undef, $head,
5800                 format_ref_views($remote ? '' : 'remotes'));
5801
5802         fill_remote_heads($remotedata);
5803         if (defined $remote) {
5804                 git_print_header_div('remotes', "$remote remote for $project");
5805                 git_remote_block($remote, $remotedata->{$remote}, undef, $head);
5806         } else {
5807                 git_print_header_div('summary', "$project remotes");
5808                 git_remotes_body($remotedata, undef, $head);
5809         }
5810
5811         git_footer_html();
5812 }
5813
5814 sub git_blob_plain {
5815         my $type = shift;
5816         my $expires;
5817
5818         if (!defined $hash) {
5819                 if (defined $file_name) {
5820                         my $base = $hash_base || git_get_head_hash($project);
5821                         $hash = git_get_hash_by_path($base, $file_name, "blob")
5822                                 or die_error(404, "Cannot find file");
5823                 } else {
5824                         die_error(400, "No file name defined");
5825                 }
5826         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
5827                 # blobs defined by non-textual hash id's can be cached
5828                 $expires = "+1d";
5829         }
5830
5831         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
5832                 or die_error(500, "Open git-cat-file blob '$hash' failed");
5833
5834         # content-type (can include charset)
5835         $type = blob_contenttype($fd, $file_name, $type);
5836
5837         # "save as" filename, even when no $file_name is given
5838         my $save_as = "$hash";
5839         if (defined $file_name) {
5840                 $save_as = $file_name;
5841         } elsif ($type =~ m/^text\//) {
5842                 $save_as .= '.txt';
5843         }
5844
5845         # With XSS prevention on, blobs of all types except a few known safe
5846         # ones are served with "Content-Disposition: attachment" to make sure
5847         # they don't run in our security domain.  For certain image types,
5848         # blob view writes an <img> tag referring to blob_plain view, and we
5849         # want to be sure not to break that by serving the image as an
5850         # attachment (though Firefox 3 doesn't seem to care).
5851         my $sandbox = $prevent_xss &&
5852                 $type !~ m!^(?:text/plain|image/(?:gif|png|jpeg))$!;
5853
5854         print $cgi->header(
5855                 -type => $type,
5856                 -expires => $expires,
5857                 -content_disposition =>
5858                         ($sandbox ? 'attachment' : 'inline')
5859                         . '; filename="' . $save_as . '"');
5860         local $/ = undef;
5861         binmode STDOUT, ':raw';
5862         print <$fd>;
5863         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
5864         close $fd;
5865 }
5866
5867 sub git_blob {
5868         my $expires;
5869
5870         if (!defined $hash) {
5871                 if (defined $file_name) {
5872                         my $base = $hash_base || git_get_head_hash($project);
5873                         $hash = git_get_hash_by_path($base, $file_name, "blob")
5874                                 or die_error(404, "Cannot find file");
5875                 } else {
5876                         die_error(400, "No file name defined");
5877                 }
5878         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
5879                 # blobs defined by non-textual hash id's can be cached
5880                 $expires = "+1d";
5881         }
5882
5883         my $have_blame = gitweb_check_feature('blame');
5884         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
5885                 or die_error(500, "Couldn't cat $file_name, $hash");
5886         my $mimetype = blob_mimetype($fd, $file_name);
5887         # use 'blob_plain' (aka 'raw') view for files that cannot be displayed
5888         if ($mimetype !~ m!^(?:text/|image/(?:gif|png|jpeg)$)! && -B $fd) {
5889                 close $fd;
5890                 return git_blob_plain($mimetype);
5891         }
5892         # we can have blame only for text/* mimetype
5893         $have_blame &&= ($mimetype =~ m!^text/!);
5894
5895         my $highlight = gitweb_check_feature('highlight');
5896         my $syntax = guess_file_syntax($highlight, $mimetype, $file_name);
5897         $fd = run_highlighter($fd, $highlight, $syntax)
5898                 if $syntax;
5899
5900         git_header_html(undef, $expires);
5901         my $formats_nav = '';
5902         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
5903                 if (defined $file_name) {
5904                         if ($have_blame) {
5905                                 $formats_nav .=
5906                                         $cgi->a({-href => href(action=>"blame", -replay=>1)},
5907                                                 "blame") .
5908                                         " | ";
5909                         }
5910                         $formats_nav .=
5911                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
5912                                         "history") .
5913                                 " | " .
5914                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
5915                                         "raw") .
5916                                 " | " .
5917                                 $cgi->a({-href => href(action=>"blob",
5918                                                        hash_base=>"HEAD", file_name=>$file_name)},
5919                                         "HEAD");
5920                 } else {
5921                         $formats_nav .=
5922                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
5923                                         "raw");
5924                 }
5925                 git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
5926                 git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
5927         } else {
5928                 print "<div class=\"page_nav\">\n" .
5929                       "<br/><br/></div>\n" .
5930                       "<div class=\"title\">".esc_html($hash)."</div>\n";
5931         }
5932         git_print_page_path($file_name, "blob", $hash_base);
5933         print "<div class=\"page_body\">\n";
5934         if ($mimetype =~ m!^image/!) {
5935                 print qq!<img type="!.esc_attr($mimetype).qq!"!;
5936                 if ($file_name) {
5937                         print qq! alt="!.esc_attr($file_name).qq!" title="!.esc_attr($file_name).qq!"!;
5938                 }
5939                 print qq! src="! .
5940                       href(action=>"blob_plain", hash=>$hash,
5941                            hash_base=>$hash_base, file_name=>$file_name) .
5942                       qq!" />\n!;
5943         } else {
5944                 my $nr;
5945                 while (my $line = <$fd>) {
5946                         chomp $line;
5947                         $nr++;
5948                         $line = untabify($line);
5949                         printf qq!<div class="pre"><a id="l%i" href="%s#l%i" class="linenr">%4i</a> %s</div>\n!,
5950                                $nr, href(-replay => 1), $nr, $nr, $syntax ? $line : esc_html($line, -nbsp=>1);
5951                 }
5952         }
5953         close $fd
5954                 or print "Reading blob failed.\n";
5955         print "</div>";
5956         git_footer_html();
5957 }
5958
5959 sub git_tree {
5960         if (!defined $hash_base) {
5961                 $hash_base = "HEAD";
5962         }
5963         if (!defined $hash) {
5964                 if (defined $file_name) {
5965                         $hash = git_get_hash_by_path($hash_base, $file_name, "tree");
5966                 } else {
5967                         $hash = $hash_base;
5968                 }
5969         }
5970         die_error(404, "No such tree") unless defined($hash);
5971
5972         my $show_sizes = gitweb_check_feature('show-sizes');
5973         my $have_blame = gitweb_check_feature('blame');
5974
5975         my @entries = ();
5976         {
5977                 local $/ = "\0";
5978                 open my $fd, "-|", git_cmd(), "ls-tree", '-z',
5979                         ($show_sizes ? '-l' : ()), @extra_options, $hash
5980                         or die_error(500, "Open git-ls-tree failed");
5981                 @entries = map { chomp; $_ } <$fd>;
5982                 close $fd
5983                         or die_error(404, "Reading tree failed");
5984         }
5985
5986         my $refs = git_get_references();
5987         my $ref = format_ref_marker($refs, $hash_base);
5988         git_header_html();
5989         my $basedir = '';
5990         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
5991                 my @views_nav = ();
5992                 if (defined $file_name) {
5993                         push @views_nav,
5994                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
5995                                         "history"),
5996                                 $cgi->a({-href => href(action=>"tree",
5997                                                        hash_base=>"HEAD", file_name=>$file_name)},
5998                                         "HEAD"),
5999                 }
6000                 my $snapshot_links = format_snapshot_links($hash);
6001                 if (defined $snapshot_links) {
6002                         # FIXME: Should be available when we have no hash base as well.
6003                         push @views_nav, $snapshot_links;
6004                 }
6005                 git_print_page_nav('tree','', $hash_base, undef, undef,
6006                                    join(' | ', @views_nav));
6007                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash_base);
6008         } else {
6009                 undef $hash_base;
6010                 print "<div class=\"page_nav\">\n";
6011                 print "<br/><br/></div>\n";
6012                 print "<div class=\"title\">".esc_html($hash)."</div>\n";
6013         }
6014         if (defined $file_name) {
6015                 $basedir = $file_name;
6016                 if ($basedir ne '' && substr($basedir, -1) ne '/') {
6017                         $basedir .= '/';
6018                 }
6019                 git_print_page_path($file_name, 'tree', $hash_base);
6020         }
6021         print "<div class=\"page_body\">\n";
6022         print "<table class=\"tree\">\n";
6023         my $alternate = 1;
6024         # '..' (top directory) link if possible
6025         if (defined $hash_base &&
6026             defined $file_name && $file_name =~ m![^/]+$!) {
6027                 if ($alternate) {
6028                         print "<tr class=\"dark\">\n";
6029                 } else {
6030                         print "<tr class=\"light\">\n";
6031                 }
6032                 $alternate ^= 1;
6033
6034                 my $up = $file_name;
6035                 $up =~ s!/?[^/]+$!!;
6036                 undef $up unless $up;
6037                 # based on git_print_tree_entry
6038                 print '<td class="mode">' . mode_str('040000') . "</td>\n";
6039                 print '<td class="size">&nbsp;</td>'."\n" if $show_sizes;
6040                 print '<td class="list">';
6041                 print $cgi->a({-href => href(action=>"tree",
6042                                              hash_base=>$hash_base,
6043                                              file_name=>$up)},
6044                               "..");
6045                 print "</td>\n";
6046                 print "<td class=\"link\"></td>\n";
6047
6048                 print "</tr>\n";
6049         }
6050         foreach my $line (@entries) {
6051                 my %t = parse_ls_tree_line($line, -z => 1, -l => $show_sizes);
6052
6053                 if ($alternate) {
6054                         print "<tr class=\"dark\">\n";
6055                 } else {
6056                         print "<tr class=\"light\">\n";
6057                 }
6058                 $alternate ^= 1;
6059
6060                 git_print_tree_entry(\%t, $basedir, $hash_base, $have_blame);
6061
6062                 print "</tr>\n";
6063         }
6064         print "</table>\n" .
6065               "</div>";
6066         git_footer_html();
6067 }
6068
6069 sub snapshot_name {
6070         my ($project, $hash) = @_;
6071
6072         # path/to/project.git  -> project
6073         # path/to/project/.git -> project
6074         my $name = to_utf8($project);
6075         $name =~ s,([^/])/*\.git$,$1,;
6076         $name = basename($name);
6077         # sanitize name
6078         $name =~ s/[[:cntrl:]]/?/g;
6079
6080         my $ver = $hash;
6081         if ($hash =~ /^[0-9a-fA-F]+$/) {
6082                 # shorten SHA-1 hash
6083                 my $full_hash = git_get_full_hash($project, $hash);
6084                 if ($full_hash =~ /^$hash/ && length($hash) > 7) {
6085                         $ver = git_get_short_hash($project, $hash);
6086                 }
6087         } elsif ($hash =~ m!^refs/tags/(.*)$!) {
6088                 # tags don't need shortened SHA-1 hash
6089                 $ver = $1;
6090         } else {
6091                 # branches and other need shortened SHA-1 hash
6092                 if ($hash =~ m!^refs/(?:heads|remotes)/(.*)$!) {
6093                         $ver = $1;
6094                 }
6095                 $ver .= '-' . git_get_short_hash($project, $hash);
6096         }
6097         # in case of hierarchical branch names
6098         $ver =~ s!/!.!g;
6099
6100         # name = project-version_string
6101         $name = "$name-$ver";
6102
6103         return wantarray ? ($name, $name) : $name;
6104 }
6105
6106 sub git_snapshot {
6107         my $format = $input_params{'snapshot_format'};
6108         if (!@snapshot_fmts) {
6109                 die_error(403, "Snapshots not allowed");
6110         }
6111         # default to first supported snapshot format
6112         $format ||= $snapshot_fmts[0];
6113         if ($format !~ m/^[a-z0-9]+$/) {
6114                 die_error(400, "Invalid snapshot format parameter");
6115         } elsif (!exists($known_snapshot_formats{$format})) {
6116                 die_error(400, "Unknown snapshot format");
6117         } elsif ($known_snapshot_formats{$format}{'disabled'}) {
6118                 die_error(403, "Snapshot format not allowed");
6119         } elsif (!grep($_ eq $format, @snapshot_fmts)) {
6120                 die_error(403, "Unsupported snapshot format");
6121         }
6122
6123         my $type = git_get_type("$hash^{}");
6124         if (!$type) {
6125                 die_error(404, 'Object does not exist');
6126         }  elsif ($type eq 'blob') {
6127                 die_error(400, 'Object is not a tree-ish');
6128         }
6129
6130         my ($name, $prefix) = snapshot_name($project, $hash);
6131         my $filename = "$name$known_snapshot_formats{$format}{'suffix'}";
6132         my $cmd = quote_command(
6133                 git_cmd(), 'archive',
6134                 "--format=$known_snapshot_formats{$format}{'format'}",
6135                 "--prefix=$prefix/", $hash);
6136         if (exists $known_snapshot_formats{$format}{'compressor'}) {
6137                 $cmd .= ' | ' . quote_command(@{$known_snapshot_formats{$format}{'compressor'}});
6138         }
6139
6140         $filename =~ s/(["\\])/\\$1/g;
6141         print $cgi->header(
6142                 -type => $known_snapshot_formats{$format}{'type'},
6143                 -content_disposition => 'inline; filename="' . $filename . '"',
6144                 -status => '200 OK');
6145
6146         open my $fd, "-|", $cmd
6147                 or die_error(500, "Execute git-archive failed");
6148         binmode STDOUT, ':raw';
6149         print <$fd>;
6150         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
6151         close $fd;
6152 }
6153
6154 sub git_log_generic {
6155         my ($fmt_name, $body_subr, $base, $parent, $file_name, $file_hash) = @_;
6156
6157         my $head = git_get_head_hash($project);
6158         if (!defined $base) {
6159                 $base = $head;
6160         }
6161         if (!defined $page) {
6162                 $page = 0;
6163         }
6164         my $refs = git_get_references();
6165
6166         my $commit_hash = $base;
6167         if (defined $parent) {
6168                 $commit_hash = "$parent..$base";
6169         }
6170         my @commitlist =
6171                 parse_commits($commit_hash, 101, (100 * $page),
6172                               defined $file_name ? ($file_name, "--full-history") : ());
6173
6174         my $ftype;
6175         if (!defined $file_hash && defined $file_name) {
6176                 # some commits could have deleted file in question,
6177                 # and not have it in tree, but one of them has to have it
6178                 for (my $i = 0; $i < @commitlist; $i++) {
6179                         $file_hash = git_get_hash_by_path($commitlist[$i]{'id'}, $file_name);
6180                         last if defined $file_hash;
6181                 }
6182         }
6183         if (defined $file_hash) {
6184                 $ftype = git_get_type($file_hash);
6185         }
6186         if (defined $file_name && !defined $ftype) {
6187                 die_error(500, "Unknown type of object");
6188         }
6189         my %co;
6190         if (defined $file_name) {
6191                 %co = parse_commit($base)
6192                         or die_error(404, "Unknown commit object");
6193         }
6194
6195
6196         my $paging_nav = format_paging_nav($fmt_name, $page, $#commitlist >= 100);
6197         my $next_link = '';
6198         if ($#commitlist >= 100) {
6199                 $next_link =
6200                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
6201                                  -accesskey => "n", -title => "Alt-n"}, "next");
6202         }
6203         my $patch_max = gitweb_get_feature('patches');
6204         if ($patch_max && !defined $file_name) {
6205                 if ($patch_max < 0 || @commitlist <= $patch_max) {
6206                         $paging_nav .= " &sdot; " .
6207                                 $cgi->a({-href => href(action=>"patches", -replay=>1)},
6208                                         "patches");
6209                 }
6210         }
6211
6212         git_header_html();
6213         git_print_page_nav($fmt_name,'', $hash,$hash,$hash, $paging_nav);
6214         if (defined $file_name) {
6215                 git_print_header_div('commit', esc_html($co{'title'}), $base);
6216         } else {
6217                 git_print_header_div('summary', $project)
6218         }
6219         git_print_page_path($file_name, $ftype, $hash_base)
6220                 if (defined $file_name);
6221
6222         $body_subr->(\@commitlist, 0, 99, $refs, $next_link,
6223                      $file_name, $file_hash, $ftype);
6224
6225         git_footer_html();
6226 }
6227
6228 sub git_log {
6229         git_log_generic('log', \&git_log_body,
6230                         $hash, $hash_parent);
6231 }
6232
6233 sub git_commit {
6234         $hash ||= $hash_base || "HEAD";
6235         my %co = parse_commit($hash)
6236             or die_error(404, "Unknown commit object");
6237
6238         my $parent  = $co{'parent'};
6239         my $parents = $co{'parents'}; # listref
6240
6241         # we need to prepare $formats_nav before any parameter munging
6242         my $formats_nav;
6243         if (!defined $parent) {
6244                 # --root commitdiff
6245                 $formats_nav .= '(initial)';
6246         } elsif (@$parents == 1) {
6247                 # single parent commit
6248                 $formats_nav .=
6249                         '(parent: ' .
6250                         $cgi->a({-href => href(action=>"commit",
6251                                                hash=>$parent)},
6252                                 esc_html(substr($parent, 0, 7))) .
6253                         ')';
6254         } else {
6255                 # merge commit
6256                 $formats_nav .=
6257                         '(merge: ' .
6258                         join(' ', map {
6259                                 $cgi->a({-href => href(action=>"commit",
6260                                                        hash=>$_)},
6261                                         esc_html(substr($_, 0, 7)));
6262                         } @$parents ) .
6263                         ')';
6264         }
6265         if (gitweb_check_feature('patches') && @$parents <= 1) {
6266                 $formats_nav .= " | " .
6267                         $cgi->a({-href => href(action=>"patch", -replay=>1)},
6268                                 "patch");
6269         }
6270
6271         if (!defined $parent) {
6272                 $parent = "--root";
6273         }
6274         my @difftree;
6275         open my $fd, "-|", git_cmd(), "diff-tree", '-r', "--no-commit-id",
6276                 @diff_opts,
6277                 (@$parents <= 1 ? $parent : '-c'),
6278                 $hash, "--"
6279                 or die_error(500, "Open git-diff-tree failed");
6280         @difftree = map { chomp; $_ } <$fd>;
6281         close $fd or die_error(404, "Reading git-diff-tree failed");
6282
6283         # non-textual hash id's can be cached
6284         my $expires;
6285         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6286                 $expires = "+1d";
6287         }
6288         my $refs = git_get_references();
6289         my $ref = format_ref_marker($refs, $co{'id'});
6290
6291         git_header_html(undef, $expires);
6292         git_print_page_nav('commit', '',
6293                            $hash, $co{'tree'}, $hash,
6294                            $formats_nav);
6295
6296         if (defined $co{'parent'}) {
6297                 git_print_header_div('commitdiff', esc_html($co{'title'}) . $ref, $hash);
6298         } else {
6299                 git_print_header_div('tree', esc_html($co{'title'}) . $ref, $co{'tree'}, $hash);
6300         }
6301         print "<div class=\"title_text\">\n" .
6302               "<table class=\"object_header\">\n";
6303         git_print_authorship_rows(\%co);
6304         print "<tr><td>commit</td><td class=\"sha1\">$co{'id'}</td></tr>\n";
6305         print "<tr>" .
6306               "<td>tree</td>" .
6307               "<td class=\"sha1\">" .
6308               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash),
6309                        class => "list"}, $co{'tree'}) .
6310               "</td>" .
6311               "<td class=\"link\">" .
6312               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash)},
6313                       "tree");
6314         my $snapshot_links = format_snapshot_links($hash);
6315         if (defined $snapshot_links) {
6316                 print " | " . $snapshot_links;
6317         }
6318         print "</td>" .
6319               "</tr>\n";
6320
6321         foreach my $par (@$parents) {
6322                 print "<tr>" .
6323                       "<td>parent</td>" .
6324                       "<td class=\"sha1\">" .
6325                       $cgi->a({-href => href(action=>"commit", hash=>$par),
6326                                class => "list"}, $par) .
6327                       "</td>" .
6328                       "<td class=\"link\">" .
6329                       $cgi->a({-href => href(action=>"commit", hash=>$par)}, "commit") .
6330                       " | " .
6331                       $cgi->a({-href => href(action=>"commitdiff", hash=>$hash, hash_parent=>$par)}, "diff") .
6332                       "</td>" .
6333                       "</tr>\n";
6334         }
6335         print "</table>".
6336               "</div>\n";
6337
6338         print "<div class=\"page_body\">\n";
6339         git_print_log($co{'comment'});
6340         print "</div>\n";
6341
6342         git_difftree_body(\@difftree, $hash, @$parents);
6343
6344         git_footer_html();
6345 }
6346
6347 sub git_object {
6348         # object is defined by:
6349         # - hash or hash_base alone
6350         # - hash_base and file_name
6351         my $type;
6352
6353         # - hash or hash_base alone
6354         if ($hash || ($hash_base && !defined $file_name)) {
6355                 my $object_id = $hash || $hash_base;
6356
6357                 open my $fd, "-|", quote_command(
6358                         git_cmd(), 'cat-file', '-t', $object_id) . ' 2> /dev/null'
6359                         or die_error(404, "Object does not exist");
6360                 $type = <$fd>;
6361                 chomp $type;
6362                 close $fd
6363                         or die_error(404, "Object does not exist");
6364
6365         # - hash_base and file_name
6366         } elsif ($hash_base && defined $file_name) {
6367                 $file_name =~ s,/+$,,;
6368
6369                 system(git_cmd(), "cat-file", '-e', $hash_base) == 0
6370                         or die_error(404, "Base object does not exist");
6371
6372                 # here errors should not hapen
6373                 open my $fd, "-|", git_cmd(), "ls-tree", $hash_base, "--", $file_name
6374                         or die_error(500, "Open git-ls-tree failed");
6375                 my $line = <$fd>;
6376                 close $fd;
6377
6378                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
6379                 unless ($line && $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/) {
6380                         die_error(404, "File or directory for given base does not exist");
6381                 }
6382                 $type = $2;
6383                 $hash = $3;
6384         } else {
6385                 die_error(400, "Not enough information to find object");
6386         }
6387
6388         print $cgi->redirect(-uri => href(action=>$type, -full=>1,
6389                                           hash=>$hash, hash_base=>$hash_base,
6390                                           file_name=>$file_name),
6391                              -status => '302 Found');
6392 }
6393
6394 sub git_blobdiff {
6395         my $format = shift || 'html';
6396
6397         my $fd;
6398         my @difftree;
6399         my %diffinfo;
6400         my $expires;
6401
6402         # preparing $fd and %diffinfo for git_patchset_body
6403         # new style URI
6404         if (defined $hash_base && defined $hash_parent_base) {
6405                 if (defined $file_name) {
6406                         # read raw output
6407                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6408                                 $hash_parent_base, $hash_base,
6409                                 "--", (defined $file_parent ? $file_parent : ()), $file_name
6410                                 or die_error(500, "Open git-diff-tree failed");
6411                         @difftree = map { chomp; $_ } <$fd>;
6412                         close $fd
6413                                 or die_error(404, "Reading git-diff-tree failed");
6414                         @difftree
6415                                 or die_error(404, "Blob diff not found");
6416
6417                 } elsif (defined $hash &&
6418                          $hash =~ /[0-9a-fA-F]{40}/) {
6419                         # try to find filename from $hash
6420
6421                         # read filtered raw output
6422                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6423                                 $hash_parent_base, $hash_base, "--"
6424                                 or die_error(500, "Open git-diff-tree failed");
6425                         @difftree =
6426                                 # ':100644 100644 03b21826... 3b93d5e7... M     ls-files.c'
6427                                 # $hash == to_id
6428                                 grep { /^:[0-7]{6} [0-7]{6} [0-9a-fA-F]{40} $hash/ }
6429                                 map { chomp; $_ } <$fd>;
6430                         close $fd
6431                                 or die_error(404, "Reading git-diff-tree failed");
6432                         @difftree
6433                                 or die_error(404, "Blob diff not found");
6434
6435                 } else {
6436                         die_error(400, "Missing one of the blob diff parameters");
6437                 }
6438
6439                 if (@difftree > 1) {
6440                         die_error(400, "Ambiguous blob diff specification");
6441                 }
6442
6443                 %diffinfo = parse_difftree_raw_line($difftree[0]);
6444                 $file_parent ||= $diffinfo{'from_file'} || $file_name;
6445                 $file_name   ||= $diffinfo{'to_file'};
6446
6447                 $hash_parent ||= $diffinfo{'from_id'};
6448                 $hash        ||= $diffinfo{'to_id'};
6449
6450                 # non-textual hash id's can be cached
6451                 if ($hash_base =~ m/^[0-9a-fA-F]{40}$/ &&
6452                     $hash_parent_base =~ m/^[0-9a-fA-F]{40}$/) {
6453                         $expires = '+1d';
6454                 }
6455
6456                 # open patch output
6457                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6458                         '-p', ($format eq 'html' ? "--full-index" : ()),
6459                         $hash_parent_base, $hash_base,
6460                         "--", (defined $file_parent ? $file_parent : ()), $file_name
6461                         or die_error(500, "Open git-diff-tree failed");
6462         }
6463
6464         # old/legacy style URI -- not generated anymore since 1.4.3.
6465         if (!%diffinfo) {
6466                 die_error('404 Not Found', "Missing one of the blob diff parameters")
6467         }
6468
6469         # header
6470         if ($format eq 'html') {
6471                 my $formats_nav =
6472                         $cgi->a({-href => href(action=>"blobdiff_plain", -replay=>1)},
6473                                 "raw");
6474                 git_header_html(undef, $expires);
6475                 if (defined $hash_base && (my %co = parse_commit($hash_base))) {
6476                         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6477                         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6478                 } else {
6479                         print "<div class=\"page_nav\"><br/>$formats_nav<br/></div>\n";
6480                         print "<div class=\"title\">".esc_html("$hash vs $hash_parent")."</div>\n";
6481                 }
6482                 if (defined $file_name) {
6483                         git_print_page_path($file_name, "blob", $hash_base);
6484                 } else {
6485                         print "<div class=\"page_path\"></div>\n";
6486                 }
6487
6488         } elsif ($format eq 'plain') {
6489                 print $cgi->header(
6490                         -type => 'text/plain',
6491                         -charset => 'utf-8',
6492                         -expires => $expires,
6493                         -content_disposition => 'inline; filename="' . "$file_name" . '.patch"');
6494
6495                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
6496
6497         } else {
6498                 die_error(400, "Unknown blobdiff format");
6499         }
6500
6501         # patch
6502         if ($format eq 'html') {
6503                 print "<div class=\"page_body\">\n";
6504
6505                 git_patchset_body($fd, [ \%diffinfo ], $hash_base, $hash_parent_base);
6506                 close $fd;
6507
6508                 print "</div>\n"; # class="page_body"
6509                 git_footer_html();
6510
6511         } else {
6512                 while (my $line = <$fd>) {
6513                         $line =~ s!a/($hash|$hash_parent)!'a/'.esc_path($diffinfo{'from_file'})!eg;
6514                         $line =~ s!b/($hash|$hash_parent)!'b/'.esc_path($diffinfo{'to_file'})!eg;
6515
6516                         print $line;
6517
6518                         last if $line =~ m!^\+\+\+!;
6519                 }
6520                 local $/ = undef;
6521                 print <$fd>;
6522                 close $fd;
6523         }
6524 }
6525
6526 sub git_blobdiff_plain {
6527         git_blobdiff('plain');
6528 }
6529
6530 sub git_commitdiff {
6531         my %params = @_;
6532         my $format = $params{-format} || 'html';
6533
6534         my ($patch_max) = gitweb_get_feature('patches');
6535         if ($format eq 'patch') {
6536                 die_error(403, "Patch view not allowed") unless $patch_max;
6537         }
6538
6539         $hash ||= $hash_base || "HEAD";
6540         my %co = parse_commit($hash)
6541             or die_error(404, "Unknown commit object");
6542
6543         # choose format for commitdiff for merge
6544         if (! defined $hash_parent && @{$co{'parents'}} > 1) {
6545                 $hash_parent = '--cc';
6546         }
6547         # we need to prepare $formats_nav before almost any parameter munging
6548         my $formats_nav;
6549         if ($format eq 'html') {
6550                 $formats_nav =
6551                         $cgi->a({-href => href(action=>"commitdiff_plain", -replay=>1)},
6552                                 "raw");
6553                 if ($patch_max && @{$co{'parents'}} <= 1) {
6554                         $formats_nav .= " | " .
6555                                 $cgi->a({-href => href(action=>"patch", -replay=>1)},
6556                                         "patch");
6557                 }
6558
6559                 if (defined $hash_parent &&
6560                     $hash_parent ne '-c' && $hash_parent ne '--cc') {
6561                         # commitdiff with two commits given
6562                         my $hash_parent_short = $hash_parent;
6563                         if ($hash_parent =~ m/^[0-9a-fA-F]{40}$/) {
6564                                 $hash_parent_short = substr($hash_parent, 0, 7);
6565                         }
6566                         $formats_nav .=
6567                                 ' (from';
6568                         for (my $i = 0; $i < @{$co{'parents'}}; $i++) {
6569                                 if ($co{'parents'}[$i] eq $hash_parent) {
6570                                         $formats_nav .= ' parent ' . ($i+1);
6571                                         last;
6572                                 }
6573                         }
6574                         $formats_nav .= ': ' .
6575                                 $cgi->a({-href => href(action=>"commitdiff",
6576                                                        hash=>$hash_parent)},
6577                                         esc_html($hash_parent_short)) .
6578                                 ')';
6579                 } elsif (!$co{'parent'}) {
6580                         # --root commitdiff
6581                         $formats_nav .= ' (initial)';
6582                 } elsif (scalar @{$co{'parents'}} == 1) {
6583                         # single parent commit
6584                         $formats_nav .=
6585                                 ' (parent: ' .
6586                                 $cgi->a({-href => href(action=>"commitdiff",
6587                                                        hash=>$co{'parent'})},
6588                                         esc_html(substr($co{'parent'}, 0, 7))) .
6589                                 ')';
6590                 } else {
6591                         # merge commit
6592                         if ($hash_parent eq '--cc') {
6593                                 $formats_nav .= ' | ' .
6594                                         $cgi->a({-href => href(action=>"commitdiff",
6595                                                                hash=>$hash, hash_parent=>'-c')},
6596                                                 'combined');
6597                         } else { # $hash_parent eq '-c'
6598                                 $formats_nav .= ' | ' .
6599                                         $cgi->a({-href => href(action=>"commitdiff",
6600                                                                hash=>$hash, hash_parent=>'--cc')},
6601                                                 'compact');
6602                         }
6603                         $formats_nav .=
6604                                 ' (merge: ' .
6605                                 join(' ', map {
6606                                         $cgi->a({-href => href(action=>"commitdiff",
6607                                                                hash=>$_)},
6608                                                 esc_html(substr($_, 0, 7)));
6609                                 } @{$co{'parents'}} ) .
6610                                 ')';
6611                 }
6612         }
6613
6614         my $hash_parent_param = $hash_parent;
6615         if (!defined $hash_parent_param) {
6616                 # --cc for multiple parents, --root for parentless
6617                 $hash_parent_param =
6618                         @{$co{'parents'}} > 1 ? '--cc' : $co{'parent'} || '--root';
6619         }
6620
6621         # read commitdiff
6622         my $fd;
6623         my @difftree;
6624         if ($format eq 'html') {
6625                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6626                         "--no-commit-id", "--patch-with-raw", "--full-index",
6627                         $hash_parent_param, $hash, "--"
6628                         or die_error(500, "Open git-diff-tree failed");
6629
6630                 while (my $line = <$fd>) {
6631                         chomp $line;
6632                         # empty line ends raw part of diff-tree output
6633                         last unless $line;
6634                         push @difftree, scalar parse_difftree_raw_line($line);
6635                 }
6636
6637         } elsif ($format eq 'plain') {
6638                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6639                         '-p', $hash_parent_param, $hash, "--"
6640                         or die_error(500, "Open git-diff-tree failed");
6641         } elsif ($format eq 'patch') {
6642                 # For commit ranges, we limit the output to the number of
6643                 # patches specified in the 'patches' feature.
6644                 # For single commits, we limit the output to a single patch,
6645                 # diverging from the git-format-patch default.
6646                 my @commit_spec = ();
6647                 if ($hash_parent) {
6648                         if ($patch_max > 0) {
6649                                 push @commit_spec, "-$patch_max";
6650                         }
6651                         push @commit_spec, '-n', "$hash_parent..$hash";
6652                 } else {
6653                         if ($params{-single}) {
6654                                 push @commit_spec, '-1';
6655                         } else {
6656                                 if ($patch_max > 0) {
6657                                         push @commit_spec, "-$patch_max";
6658                                 }
6659                                 push @commit_spec, "-n";
6660                         }
6661                         push @commit_spec, '--root', $hash;
6662                 }
6663                 open $fd, "-|", git_cmd(), "format-patch", @diff_opts,
6664                         '--encoding=utf8', '--stdout', @commit_spec
6665                         or die_error(500, "Open git-format-patch failed");
6666         } else {
6667                 die_error(400, "Unknown commitdiff format");
6668         }
6669
6670         # non-textual hash id's can be cached
6671         my $expires;
6672         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6673                 $expires = "+1d";
6674         }
6675
6676         # write commit message
6677         if ($format eq 'html') {
6678                 my $refs = git_get_references();
6679                 my $ref = format_ref_marker($refs, $co{'id'});
6680
6681                 git_header_html(undef, $expires);
6682                 git_print_page_nav('commitdiff','', $hash,$co{'tree'},$hash, $formats_nav);
6683                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash);
6684                 print "<div class=\"title_text\">\n" .
6685                       "<table class=\"object_header\">\n";
6686                 git_print_authorship_rows(\%co);
6687                 print "</table>".
6688                       "</div>\n";
6689                 print "<div class=\"page_body\">\n";
6690                 if (@{$co{'comment'}} > 1) {
6691                         print "<div class=\"log\">\n";
6692                         git_print_log($co{'comment'}, -final_empty_line=> 1, -remove_title => 1);
6693                         print "</div>\n"; # class="log"
6694                 }
6695
6696         } elsif ($format eq 'plain') {
6697                 my $refs = git_get_references("tags");
6698                 my $tagname = git_get_rev_name_tags($hash);
6699                 my $filename = basename($project) . "-$hash.patch";
6700
6701                 print $cgi->header(
6702                         -type => 'text/plain',
6703                         -charset => 'utf-8',
6704                         -expires => $expires,
6705                         -content_disposition => 'inline; filename="' . "$filename" . '"');
6706                 my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
6707                 print "From: " . to_utf8($co{'author'}) . "\n";
6708                 print "Date: $ad{'rfc2822'} ($ad{'tz_local'})\n";
6709                 print "Subject: " . to_utf8($co{'title'}) . "\n";
6710
6711                 print "X-Git-Tag: $tagname\n" if $tagname;
6712                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
6713
6714                 foreach my $line (@{$co{'comment'}}) {
6715                         print to_utf8($line) . "\n";
6716                 }
6717                 print "---\n\n";
6718         } elsif ($format eq 'patch') {
6719                 my $filename = basename($project) . "-$hash.patch";
6720
6721                 print $cgi->header(
6722                         -type => 'text/plain',
6723                         -charset => 'utf-8',
6724                         -expires => $expires,
6725                         -content_disposition => 'inline; filename="' . "$filename" . '"');
6726         }
6727
6728         # write patch
6729         if ($format eq 'html') {
6730                 my $use_parents = !defined $hash_parent ||
6731                         $hash_parent eq '-c' || $hash_parent eq '--cc';
6732                 git_difftree_body(\@difftree, $hash,
6733                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
6734                 print "<br/>\n";
6735
6736                 git_patchset_body($fd, \@difftree, $hash,
6737                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
6738                 close $fd;
6739                 print "</div>\n"; # class="page_body"
6740                 git_footer_html();
6741
6742         } elsif ($format eq 'plain') {
6743                 local $/ = undef;
6744                 print <$fd>;
6745                 close $fd
6746                         or print "Reading git-diff-tree failed\n";
6747         } elsif ($format eq 'patch') {
6748                 local $/ = undef;
6749                 print <$fd>;
6750                 close $fd
6751                         or print "Reading git-format-patch failed\n";
6752         }
6753 }
6754
6755 sub git_commitdiff_plain {
6756         git_commitdiff(-format => 'plain');
6757 }
6758
6759 # format-patch-style patches
6760 sub git_patch {
6761         git_commitdiff(-format => 'patch', -single => 1);
6762 }
6763
6764 sub git_patches {
6765         git_commitdiff(-format => 'patch');
6766 }
6767
6768 sub git_history {
6769         git_log_generic('history', \&git_history_body,
6770                         $hash_base, $hash_parent_base,
6771                         $file_name, $hash);
6772 }
6773
6774 sub git_search {
6775         gitweb_check_feature('search') or die_error(403, "Search is disabled");
6776         if (!defined $searchtext) {
6777                 die_error(400, "Text field is empty");
6778         }
6779         if (!defined $hash) {
6780                 $hash = git_get_head_hash($project);
6781         }
6782         my %co = parse_commit($hash);
6783         if (!%co) {
6784                 die_error(404, "Unknown commit object");
6785         }
6786         if (!defined $page) {
6787                 $page = 0;
6788         }
6789
6790         $searchtype ||= 'commit';
6791         if ($searchtype eq 'pickaxe') {
6792                 # pickaxe may take all resources of your box and run for several minutes
6793                 # with every query - so decide by yourself how public you make this feature
6794                 gitweb_check_feature('pickaxe')
6795                     or die_error(403, "Pickaxe is disabled");
6796         }
6797         if ($searchtype eq 'grep') {
6798                 gitweb_check_feature('grep')[0]
6799                     or die_error(403, "Grep is disabled");
6800         }
6801
6802         git_header_html();
6803
6804         if ($searchtype eq 'commit' or $searchtype eq 'author' or $searchtype eq 'committer') {
6805                 my $greptype;
6806                 if ($searchtype eq 'commit') {
6807                         $greptype = "--grep=";
6808                 } elsif ($searchtype eq 'author') {
6809                         $greptype = "--author=";
6810                 } elsif ($searchtype eq 'committer') {
6811                         $greptype = "--committer=";
6812                 }
6813                 $greptype .= $searchtext;
6814                 my @commitlist = parse_commits($hash, 101, (100 * $page), undef,
6815                                                $greptype, '--regexp-ignore-case',
6816                                                $search_use_regexp ? '--extended-regexp' : '--fixed-strings');
6817
6818                 my $paging_nav = '';
6819                 if ($page > 0) {
6820                         $paging_nav .=
6821                                 $cgi->a({-href => href(action=>"search", hash=>$hash,
6822                                                        searchtext=>$searchtext,
6823                                                        searchtype=>$searchtype)},
6824                                         "first");
6825                         $paging_nav .= " &sdot; " .
6826                                 $cgi->a({-href => href(-replay=>1, page=>$page-1),
6827                                          -accesskey => "p", -title => "Alt-p"}, "prev");
6828                 } else {
6829                         $paging_nav .= "first";
6830                         $paging_nav .= " &sdot; prev";
6831                 }
6832                 my $next_link = '';
6833                 if ($#commitlist >= 100) {
6834                         $next_link =
6835                                 $cgi->a({-href => href(-replay=>1, page=>$page+1),
6836                                          -accesskey => "n", -title => "Alt-n"}, "next");
6837                         $paging_nav .= " &sdot; $next_link";
6838                 } else {
6839                         $paging_nav .= " &sdot; next";
6840                 }
6841
6842                 git_print_page_nav('','', $hash,$co{'tree'},$hash, $paging_nav);
6843                 git_print_header_div('commit', esc_html($co{'title'}), $hash);
6844                 if ($page == 0 && !@commitlist) {
6845                         print "<p>No match.</p>\n";
6846                 } else {
6847                         git_search_grep_body(\@commitlist, 0, 99, $next_link);
6848                 }
6849         }
6850
6851         if ($searchtype eq 'pickaxe') {
6852                 git_print_page_nav('','', $hash,$co{'tree'},$hash);
6853                 git_print_header_div('commit', esc_html($co{'title'}), $hash);
6854
6855                 print "<table class=\"pickaxe search\">\n";
6856                 my $alternate = 1;
6857                 local $/ = "\n";
6858                 open my $fd, '-|', git_cmd(), '--no-pager', 'log', @diff_opts,
6859                         '--pretty=format:%H', '--no-abbrev', '--raw', "-S$searchtext",
6860                         ($search_use_regexp ? '--pickaxe-regex' : ());
6861                 undef %co;
6862                 my @files;
6863                 while (my $line = <$fd>) {
6864                         chomp $line;
6865                         next unless $line;
6866
6867                         my %set = parse_difftree_raw_line($line);
6868                         if (defined $set{'commit'}) {
6869                                 # finish previous commit
6870                                 if (%co) {
6871                                         print "</td>\n" .
6872                                               "<td class=\"link\">" .
6873                                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
6874                                               " | " .
6875                                               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
6876                                         print "</td>\n" .
6877                                               "</tr>\n";
6878                                 }
6879
6880                                 if ($alternate) {
6881                                         print "<tr class=\"dark\">\n";
6882                                 } else {
6883                                         print "<tr class=\"light\">\n";
6884                                 }
6885                                 $alternate ^= 1;
6886                                 %co = parse_commit($set{'commit'});
6887                                 my $author = chop_and_escape_str($co{'author_name'}, 15, 5);
6888                                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6889                                       "<td><i>$author</i></td>\n" .
6890                                       "<td>" .
6891                                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
6892                                               -class => "list subject"},
6893                                               chop_and_escape_str($co{'title'}, 50) . "<br/>");
6894                         } elsif (defined $set{'to_id'}) {
6895                                 next if ($set{'to_id'} =~ m/^0{40}$/);
6896
6897                                 print $cgi->a({-href => href(action=>"blob", hash_base=>$co{'id'},
6898                                                              hash=>$set{'to_id'}, file_name=>$set{'to_file'}),
6899                                               -class => "list"},
6900                                               "<span class=\"match\">" . esc_path($set{'file'}) . "</span>") .
6901                                       "<br/>\n";
6902                         }
6903                 }
6904                 close $fd;
6905
6906                 # finish last commit (warning: repetition!)
6907                 if (%co) {
6908                         print "</td>\n" .
6909                               "<td class=\"link\">" .
6910                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
6911                               " | " .
6912                               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
6913                         print "</td>\n" .
6914                               "</tr>\n";
6915                 }
6916
6917                 print "</table>\n";
6918         }
6919
6920         if ($searchtype eq 'grep') {
6921                 git_print_page_nav('','', $hash,$co{'tree'},$hash);
6922                 git_print_header_div('commit', esc_html($co{'title'}), $hash);
6923
6924                 print "<table class=\"grep_search\">\n";
6925                 my $alternate = 1;
6926                 my $matches = 0;
6927                 local $/ = "\n";
6928                 open my $fd, "-|", git_cmd(), 'grep', '-n',
6929                         $search_use_regexp ? ('-E', '-i') : '-F',
6930                         $searchtext, $co{'tree'};
6931                 my $lastfile = '';
6932                 while (my $line = <$fd>) {
6933                         chomp $line;
6934                         my ($file, $lno, $ltext, $binary);
6935                         last if ($matches++ > 1000);
6936                         if ($line =~ /^Binary file (.+) matches$/) {
6937                                 $file = $1;
6938                                 $binary = 1;
6939                         } else {
6940                                 (undef, $file, $lno, $ltext) = split(/:/, $line, 4);
6941                         }
6942                         if ($file ne $lastfile) {
6943                                 $lastfile and print "</td></tr>\n";
6944                                 if ($alternate++) {
6945                                         print "<tr class=\"dark\">\n";
6946                                 } else {
6947                                         print "<tr class=\"light\">\n";
6948                                 }
6949                                 print "<td class=\"list\">".
6950                                         $cgi->a({-href => href(action=>"blob", hash=>$co{'hash'},
6951                                                                file_name=>"$file"),
6952                                                 -class => "list"}, esc_path($file));
6953                                 print "</td><td>\n";
6954                                 $lastfile = $file;
6955                         }
6956                         if ($binary) {
6957                                 print "<div class=\"binary\">Binary file</div>\n";
6958                         } else {
6959                                 $ltext = untabify($ltext);
6960                                 if ($ltext =~ m/^(.*)($search_regexp)(.*)$/i) {
6961                                         $ltext = esc_html($1, -nbsp=>1);
6962                                         $ltext .= '<span class="match">';
6963                                         $ltext .= esc_html($2, -nbsp=>1);
6964                                         $ltext .= '</span>';
6965                                         $ltext .= esc_html($3, -nbsp=>1);
6966                                 } else {
6967                                         $ltext = esc_html($ltext, -nbsp=>1);
6968                                 }
6969                                 print "<div class=\"pre\">" .
6970                                         $cgi->a({-href => href(action=>"blob", hash=>$co{'hash'},
6971                                                                file_name=>"$file").'#l'.$lno,
6972                                                 -class => "linenr"}, sprintf('%4i', $lno))
6973                                         . ' ' .  $ltext . "</div>\n";
6974                         }
6975                 }
6976                 if ($lastfile) {
6977                         print "</td></tr>\n";
6978                         if ($matches > 1000) {
6979                                 print "<div class=\"diff nodifferences\">Too many matches, listing trimmed</div>\n";
6980                         }
6981                 } else {
6982                         print "<div class=\"diff nodifferences\">No matches found</div>\n";
6983                 }
6984                 close $fd;
6985
6986                 print "</table>\n";
6987         }
6988         git_footer_html();
6989 }
6990
6991 sub git_search_help {
6992         git_header_html();
6993         git_print_page_nav('','', $hash,$hash,$hash);
6994         print <<EOT;
6995 <p><strong>Pattern</strong> is by default a normal string that is matched precisely (but without
6996 regard to case, except in the case of pickaxe). However, when you check the <em>re</em> checkbox,
6997 the pattern entered is recognized as the POSIX extended
6998 <a href="http://en.wikipedia.org/wiki/Regular_expression">regular expression</a> (also case
6999 insensitive).</p>
7000 <dl>
7001 <dt><b>commit</b></dt>
7002 <dd>The commit messages and authorship information will be scanned for the given pattern.</dd>
7003 EOT
7004         my $have_grep = gitweb_check_feature('grep');
7005         if ($have_grep) {
7006                 print <<EOT;
7007 <dt><b>grep</b></dt>
7008 <dd>All files in the currently selected tree (HEAD unless you are explicitly browsing
7009     a different one) are searched for the given pattern. On large trees, this search can take
7010 a while and put some strain on the server, so please use it with some consideration. Note that
7011 due to git-grep peculiarity, currently if regexp mode is turned off, the matches are
7012 case-sensitive.</dd>
7013 EOT
7014         }
7015         print <<EOT;
7016 <dt><b>author</b></dt>
7017 <dd>Name and e-mail of the change author and date of birth of the patch will be scanned for the given pattern.</dd>
7018 <dt><b>committer</b></dt>
7019 <dd>Name and e-mail of the committer and date of commit will be scanned for the given pattern.</dd>
7020 EOT
7021         my $have_pickaxe = gitweb_check_feature('pickaxe');
7022         if ($have_pickaxe) {
7023                 print <<EOT;
7024 <dt><b>pickaxe</b></dt>
7025 <dd>All commits that caused the string to appear or disappear from any file (changes that
7026 added, removed or "modified" the string) will be listed. This search can take a while and
7027 takes a lot of strain on the server, so please use it wisely. Note that since you may be
7028 interested even in changes just changing the case as well, this search is case sensitive.</dd>
7029 EOT
7030         }
7031         print "</dl>\n";
7032         git_footer_html();
7033 }
7034
7035 sub git_shortlog {
7036         git_log_generic('shortlog', \&git_shortlog_body,
7037                         $hash, $hash_parent);
7038 }
7039
7040 ## ......................................................................
7041 ## feeds (RSS, Atom; OPML)
7042
7043 sub git_feed {
7044         my $format = shift || 'atom';
7045         my $have_blame = gitweb_check_feature('blame');
7046
7047         # Atom: http://www.atomenabled.org/developers/syndication/
7048         # RSS:  http://www.notestips.com/80256B3A007F2692/1/NAMO5P9UPQ
7049         if ($format ne 'rss' && $format ne 'atom') {
7050                 die_error(400, "Unknown web feed format");
7051         }
7052
7053         # log/feed of current (HEAD) branch, log of given branch, history of file/directory
7054         my $head = $hash || 'HEAD';
7055         my @commitlist = parse_commits($head, 150, 0, $file_name);
7056
7057         my %latest_commit;
7058         my %latest_date;
7059         my $content_type = "application/$format+xml";
7060         if (defined $cgi->http('HTTP_ACCEPT') &&
7061                  $cgi->Accept('text/xml') > $cgi->Accept($content_type)) {
7062                 # browser (feed reader) prefers text/xml
7063                 $content_type = 'text/xml';
7064         }
7065         if (defined($commitlist[0])) {
7066                 %latest_commit = %{$commitlist[0]};
7067                 my $latest_epoch = $latest_commit{'committer_epoch'};
7068                 %latest_date   = parse_date($latest_epoch);
7069                 my $if_modified = $cgi->http('IF_MODIFIED_SINCE');
7070                 if (defined $if_modified) {
7071                         my $since;
7072                         if (eval { require HTTP::Date; 1; }) {
7073                                 $since = HTTP::Date::str2time($if_modified);
7074                         } elsif (eval { require Time::ParseDate; 1; }) {
7075                                 $since = Time::ParseDate::parsedate($if_modified, GMT => 1);
7076                         }
7077                         if (defined $since && $latest_epoch <= $since) {
7078                                 print $cgi->header(
7079                                         -type => $content_type,
7080                                         -charset => 'utf-8',
7081                                         -last_modified => $latest_date{'rfc2822'},
7082                                         -status => '304 Not Modified');
7083                                 return;
7084                         }
7085                 }
7086                 print $cgi->header(
7087                         -type => $content_type,
7088                         -charset => 'utf-8',
7089                         -last_modified => $latest_date{'rfc2822'});
7090         } else {
7091                 print $cgi->header(
7092                         -type => $content_type,
7093                         -charset => 'utf-8');
7094         }
7095
7096         # Optimization: skip generating the body if client asks only
7097         # for Last-Modified date.
7098         return if ($cgi->request_method() eq 'HEAD');
7099
7100         # header variables
7101         my $title = "$site_name - $project/$action";
7102         my $feed_type = 'log';
7103         if (defined $hash) {
7104                 $title .= " - '$hash'";
7105                 $feed_type = 'branch log';
7106                 if (defined $file_name) {
7107                         $title .= " :: $file_name";
7108                         $feed_type = 'history';
7109                 }
7110         } elsif (defined $file_name) {
7111                 $title .= " - $file_name";
7112                 $feed_type = 'history';
7113         }
7114         $title .= " $feed_type";
7115         my $descr = git_get_project_description($project);
7116         if (defined $descr) {
7117                 $descr = esc_html($descr);
7118         } else {
7119                 $descr = "$project " .
7120                          ($format eq 'rss' ? 'RSS' : 'Atom') .
7121                          " feed";
7122         }
7123         my $owner = git_get_project_owner($project);
7124         $owner = esc_html($owner);
7125
7126         #header
7127         my $alt_url;
7128         if (defined $file_name) {
7129                 $alt_url = href(-full=>1, action=>"history", hash=>$hash, file_name=>$file_name);
7130         } elsif (defined $hash) {
7131                 $alt_url = href(-full=>1, action=>"log", hash=>$hash);
7132         } else {
7133                 $alt_url = href(-full=>1, action=>"summary");
7134         }
7135         print qq!<?xml version="1.0" encoding="utf-8"?>\n!;
7136         if ($format eq 'rss') {
7137                 print <<XML;
7138 <rss version="2.0" xmlns:content="http://purl.org/rss/1.0/modules/content/">
7139 <channel>
7140 XML
7141                 print "<title>$title</title>\n" .
7142                       "<link>$alt_url</link>\n" .
7143                       "<description>$descr</description>\n" .
7144                       "<language>en</language>\n" .
7145                       # project owner is responsible for 'editorial' content
7146                       "<managingEditor>$owner</managingEditor>\n";
7147                 if (defined $logo || defined $favicon) {
7148                         # prefer the logo to the favicon, since RSS
7149                         # doesn't allow both
7150                         my $img = esc_url($logo || $favicon);
7151                         print "<image>\n" .
7152                               "<url>$img</url>\n" .
7153                               "<title>$title</title>\n" .
7154                               "<link>$alt_url</link>\n" .
7155                               "</image>\n";
7156                 }
7157                 if (%latest_date) {
7158                         print "<pubDate>$latest_date{'rfc2822'}</pubDate>\n";
7159                         print "<lastBuildDate>$latest_date{'rfc2822'}</lastBuildDate>\n";
7160                 }
7161                 print "<generator>gitweb v.$version/$git_version</generator>\n";
7162         } elsif ($format eq 'atom') {
7163                 print <<XML;
7164 <feed xmlns="http://www.w3.org/2005/Atom">
7165 XML
7166                 print "<title>$title</title>\n" .
7167                       "<subtitle>$descr</subtitle>\n" .
7168                       '<link rel="alternate" type="text/html" href="' .
7169                       $alt_url . '" />' . "\n" .
7170                       '<link rel="self" type="' . $content_type . '" href="' .
7171                       $cgi->self_url() . '" />' . "\n" .
7172                       "<id>" . href(-full=>1) . "</id>\n" .
7173                       # use project owner for feed author
7174                       "<author><name>$owner</name></author>\n";
7175                 if (defined $favicon) {
7176                         print "<icon>" . esc_url($favicon) . "</icon>\n";
7177                 }
7178                 if (defined $logo) {
7179                         # not twice as wide as tall: 72 x 27 pixels
7180                         print "<logo>" . esc_url($logo) . "</logo>\n";
7181                 }
7182                 if (! %latest_date) {
7183                         # dummy date to keep the feed valid until commits trickle in:
7184                         print "<updated>1970-01-01T00:00:00Z</updated>\n";
7185                 } else {
7186                         print "<updated>$latest_date{'iso-8601'}</updated>\n";
7187                 }
7188                 print "<generator version='$version/$git_version'>gitweb</generator>\n";
7189         }
7190
7191         # contents
7192         for (my $i = 0; $i <= $#commitlist; $i++) {
7193                 my %co = %{$commitlist[$i]};
7194                 my $commit = $co{'id'};
7195                 # we read 150, we always show 30 and the ones more recent than 48 hours
7196                 if (($i >= 20) && ((time - $co{'author_epoch'}) > 48*60*60)) {
7197                         last;
7198                 }
7199                 my %cd = parse_date($co{'author_epoch'});
7200
7201                 # get list of changed files
7202                 open my $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7203                         $co{'parent'} || "--root",
7204                         $co{'id'}, "--", (defined $file_name ? $file_name : ())
7205                         or next;
7206                 my @difftree = map { chomp; $_ } <$fd>;
7207                 close $fd
7208                         or next;
7209
7210                 # print element (entry, item)
7211                 my $co_url = href(-full=>1, action=>"commitdiff", hash=>$commit);
7212                 if ($format eq 'rss') {
7213                         print "<item>\n" .
7214                               "<title>" . esc_html($co{'title'}) . "</title>\n" .
7215                               "<author>" . esc_html($co{'author'}) . "</author>\n" .
7216                               "<pubDate>$cd{'rfc2822'}</pubDate>\n" .
7217                               "<guid isPermaLink=\"true\">$co_url</guid>\n" .
7218                               "<link>$co_url</link>\n" .
7219                               "<description>" . esc_html($co{'title'}) . "</description>\n" .
7220                               "<content:encoded>" .
7221                               "<![CDATA[\n";
7222                 } elsif ($format eq 'atom') {
7223                         print "<entry>\n" .
7224                               "<title type=\"html\">" . esc_html($co{'title'}) . "</title>\n" .
7225                               "<updated>$cd{'iso-8601'}</updated>\n" .
7226                               "<author>\n" .
7227                               "  <name>" . esc_html($co{'author_name'}) . "</name>\n";
7228                         if ($co{'author_email'}) {
7229                                 print "  <email>" . esc_html($co{'author_email'}) . "</email>\n";
7230                         }
7231                         print "</author>\n" .
7232                               # use committer for contributor
7233                               "<contributor>\n" .
7234                               "  <name>" . esc_html($co{'committer_name'}) . "</name>\n";
7235                         if ($co{'committer_email'}) {
7236                                 print "  <email>" . esc_html($co{'committer_email'}) . "</email>\n";
7237                         }
7238                         print "</contributor>\n" .
7239                               "<published>$cd{'iso-8601'}</published>\n" .
7240                               "<link rel=\"alternate\" type=\"text/html\" href=\"$co_url\" />\n" .
7241                               "<id>$co_url</id>\n" .
7242                               "<content type=\"xhtml\" xml:base=\"" . esc_url($my_url) . "\">\n" .
7243                               "<div xmlns=\"http://www.w3.org/1999/xhtml\">\n";
7244                 }
7245                 my $comment = $co{'comment'};
7246                 print "<pre>\n";
7247                 foreach my $line (@$comment) {
7248                         $line = esc_html($line);
7249                         print "$line\n";
7250                 }
7251                 print "</pre><ul>\n";
7252                 foreach my $difftree_line (@difftree) {
7253                         my %difftree = parse_difftree_raw_line($difftree_line);
7254                         next if !$difftree{'from_id'};
7255
7256                         my $file = $difftree{'file'} || $difftree{'to_file'};
7257
7258                         print "<li>" .
7259                               "[" .
7260                               $cgi->a({-href => href(-full=>1, action=>"blobdiff",
7261                                                      hash=>$difftree{'to_id'}, hash_parent=>$difftree{'from_id'},
7262                                                      hash_base=>$co{'id'}, hash_parent_base=>$co{'parent'},
7263                                                      file_name=>$file, file_parent=>$difftree{'from_file'}),
7264                                       -title => "diff"}, 'D');
7265                         if ($have_blame) {
7266                                 print $cgi->a({-href => href(-full=>1, action=>"blame",
7267                                                              file_name=>$file, hash_base=>$commit),
7268                                               -title => "blame"}, 'B');
7269                         }
7270                         # if this is not a feed of a file history
7271                         if (!defined $file_name || $file_name ne $file) {
7272                                 print $cgi->a({-href => href(-full=>1, action=>"history",
7273                                                              file_name=>$file, hash=>$commit),
7274                                               -title => "history"}, 'H');
7275                         }
7276                         $file = esc_path($file);
7277                         print "] ".
7278                               "$file</li>\n";
7279                 }
7280                 if ($format eq 'rss') {
7281                         print "</ul>]]>\n" .
7282                               "</content:encoded>\n" .
7283                               "</item>\n";
7284                 } elsif ($format eq 'atom') {
7285                         print "</ul>\n</div>\n" .
7286                               "</content>\n" .
7287                               "</entry>\n";
7288                 }
7289         }
7290
7291         # end of feed
7292         if ($format eq 'rss') {
7293                 print "</channel>\n</rss>\n";
7294         } elsif ($format eq 'atom') {
7295                 print "</feed>\n";
7296         }
7297 }
7298
7299 sub git_rss {
7300         git_feed('rss');
7301 }
7302
7303 sub git_atom {
7304         git_feed('atom');
7305 }
7306
7307 sub git_opml {
7308         my @list = git_get_projects_list();
7309
7310         print $cgi->header(
7311                 -type => 'text/xml',
7312                 -charset => 'utf-8',
7313                 -content_disposition => 'inline; filename="opml.xml"');
7314
7315         print <<XML;
7316 <?xml version="1.0" encoding="utf-8"?>
7317 <opml version="1.0">
7318 <head>
7319   <title>$site_name OPML Export</title>
7320 </head>
7321 <body>
7322 <outline text="git RSS feeds">
7323 XML
7324
7325         foreach my $pr (@list) {
7326                 my %proj = %$pr;
7327                 my $head = git_get_head_hash($proj{'path'});
7328                 if (!defined $head) {
7329                         next;
7330                 }
7331                 $git_dir = "$projectroot/$proj{'path'}";
7332                 my %co = parse_commit($head);
7333                 if (!%co) {
7334                         next;
7335                 }
7336
7337                 my $path = esc_html(chop_str($proj{'path'}, 25, 5));
7338                 my $rss  = href('project' => $proj{'path'}, 'action' => 'rss', -full => 1);
7339                 my $html = href('project' => $proj{'path'}, 'action' => 'summary', -full => 1);
7340                 print "<outline type=\"rss\" text=\"$path\" title=\"$path\" xmlUrl=\"$rss\" htmlUrl=\"$html\"/>\n";
7341         }
7342         print <<XML;
7343 </outline>
7344 </body>
7345 </opml>
7346 XML
7347 }