Lady’s Gitweb - Gitweb/blob - gitweb.perl

   1 #!/usr/bin/perl
   2
   3 # gitweb - simple web interface to track changes in git repositories
   4 #
   5 # (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
   6 # (C) 2005, Christian Gierke
   7 #
   8 # This program is licensed under the GPLv2
   9
  10 use 5.008;
  11 use strict;
  12 use warnings;
  13 use CGI qw(:standard :escapeHTML -nosticky);
  14 use CGI::Util qw(unescape);
  15 use CGI::Carp qw(fatalsToBrowser set_message);
  16 use Encode;
  17 use Fcntl ':mode';
  18 use File::Find qw();
  19 use File::Basename qw(basename);
  20 use Time::HiRes qw(gettimeofday tv_interval);
  21 binmode STDOUT, ':utf8';
  22
  23 if (!defined($CGI::VERSION) || $CGI::VERSION < 4.08) {
  24         eval 'sub CGI::multi_param { CGI::param(@_) }'
  25 }
  26
  27 our $t0 = [ gettimeofday() ];
  28 our $number_of_git_cmds = 0;
  29
  30 BEGIN {
  31         CGI->compile() if $ENV{'MOD_PERL'};
  32 }
  33
  34 our $version = "++GIT_VERSION++";
  35
  36 our ($my_url, $my_uri, $base_url, $path_info, $home_link);
  37 sub evaluate_uri {
  38         our $cgi;
  39
  40         our $my_url = $cgi->url();
  41         our $my_uri = $cgi->url(-absolute => 1);
  42
  43         # Base URL for relative URLs in gitweb ($logo, $favicon, ...),
  44         # needed and used only for URLs with nonempty PATH_INFO
  45         our $base_url = $my_url;
  46
  47         # When the script is used as DirectoryIndex, the URL does not contain the name
  48         # of the script file itself, and $cgi->url() fails to strip PATH_INFO, so we
  49         # have to do it ourselves. We make $path_info global because it's also used
  50         # later on.
  51         #
  52         # Another issue with the script being the DirectoryIndex is that the resulting
  53         # $my_url data is not the full script URL: this is good, because we want
  54         # generated links to keep implying the script name if it wasn't explicitly
  55         # indicated in the URL we're handling, but it means that $my_url cannot be used
  56         # as base URL.
  57         # Therefore, if we needed to strip PATH_INFO, then we know that we have
  58         # to build the base URL ourselves:
  59         our $path_info = decode_utf8($ENV{"PATH_INFO"});
  60         if ($path_info) {
  61                 # $path_info has already been URL-decoded by the web server, but
  62                 # $my_url and $my_uri have not. URL-decode them so we can properly
  63                 # strip $path_info.
  64                 $my_url = unescape($my_url);
  65                 $my_uri = unescape($my_uri);
  66                 if ($my_url =~ s,\Q$path_info\E$,, &&
  67                     $my_uri =~ s,\Q$path_info\E$,, &&
  68                     defined $ENV{'SCRIPT_NAME'}) {
  69                         $base_url = $cgi->url(-base => 1) . $ENV{'SCRIPT_NAME'};
  70                 }
  71         }
  72
  73         # target of the home link on top of all pages
  74         our $home_link = $my_uri || "/";
  75 }
  76
  77 # core git executable to use
  78 # this can just be "git" if your webserver has a sensible PATH
  79 our $GIT = "++GIT_BINDIR++/git";
  80
  81 # absolute fs-path which will be prepended to the project path
  82 #our $projectroot = "/pub/scm";
  83 our $projectroot = "++GITWEB_PROJECTROOT++";
  84
  85 # fs traversing limit for getting project list
  86 # the number is relative to the projectroot
  87 our $project_maxdepth = "++GITWEB_PROJECT_MAXDEPTH++";
  88
  89 # string of the home link on top of all pages
  90 our $home_link_str = "++GITWEB_HOME_LINK_STR++";
  91
  92 # extra breadcrumbs preceding the home link
  93 our @extra_breadcrumbs = ();
  94
  95 # name of your site or organization to appear in page titles
  96 # replace this with something more descriptive for clearer bookmarks
  97 our $site_name = "++GITWEB_SITENAME++"
  98                  || ($ENV{'SERVER_NAME'} || "Untitled") . " Git";
  99
 100 # html snippet to include in the <head> section of each page
 101 our $site_html_head_string = "++GITWEB_SITE_HTML_HEAD_STRING++";
 102 # filename of html text to include at top of each page
 103 our $site_header = "++GITWEB_SITE_HEADER++";
 104 # html text to include at home page
 105 our $home_text = "++GITWEB_HOMETEXT++";
 106 # filename of html text to include at bottom of each page
 107 our $site_footer = "++GITWEB_SITE_FOOTER++";
 108
 109 # URI of stylesheets
 110 our @stylesheets = ("++GITWEB_CSS++");
 111 # URI of a single stylesheet, which can be overridden in GITWEB_CONFIG.
 112 our $stylesheet = undef;
 113
 114 # URI of GIT logo (72x27 size)
 115 our $logo = "++GITWEB_LOGO++";
 116 # URI of GIT favicon, assumed to be image/png type
 117 our $favicon = "++GITWEB_FAVICON++";
 118 # URI of gitweb.js (JavaScript code for gitweb)
 119 our $javascript = "++GITWEB_JS++";
 120
 121 # URI and label (title) of GIT logo link
 122 #our $logo_url = "http://www.kernel.org/pub/software/scm/git/docs/";
 123 #our $logo_label = "git documentation";
 124 our $logo_url = "http://git-scm.com/";
 125 our $logo_label = "git homepage";
 126
 127 # source of projects list
 128 our $projects_list = "++GITWEB_LIST++";
 129
 130 # the width (in characters) of the projects list "Description" column
 131 our $projects_list_description_width = 25;
 132
 133 # group projects by category on the projects list
 134 # (enabled if this variable evaluates to true)
 135 our $projects_list_group_categories = 0;
 136
 137 # default category if none specified
 138 # (leave the empty string for no category)
 139 our $project_list_default_category = "";
 140
 141 # default order of projects list
 142 # valid values are none, project, descr, owner, and age
 143 our $default_projects_order = "project";
 144
 145 # show repository only if this file exists
 146 # (only effective if this variable evaluates to true)
 147 our $export_ok = "++GITWEB_EXPORT_OK++";
 148
 149 # don't generate age column on the projects list page
 150 our $omit_age_column = 0;
 151
 152 # don't generate information about owners of repositories
 153 our $omit_owner=0;
 154
 155 # show repository only if this subroutine returns true
 156 # when given the path to the project, for example:
 157 #    sub { return -e "$_[0]/git-daemon-export-ok"; }
 158 our $export_auth_hook = undef;
 159
 160 # only allow viewing of repositories also shown on the overview page
 161 our $strict_export = "++GITWEB_STRICT_EXPORT++";
 162
 163 # list of git base URLs used for URL to where fetch project from,
 164 # i.e. full URL is "$git_base_url/$project"
 165 our @git_base_url_list = grep { $_ ne '' } ("++GITWEB_BASE_URL++");
 166
 167 # default blob_plain mimetype and default charset for text/plain blob
 168 our $default_blob_plain_mimetype = 'text/plain';
 169 our $default_text_plain_charset  = undef;
 170
 171 # file to use for guessing MIME types before trying /etc/mime.types
 172 # (relative to the current git repository)
 173 our $mimetypes_file = undef;
 174
 175 # assume this charset if line contains non-UTF-8 characters;
 176 # it should be valid encoding (see Encoding::Supported(3pm) for list),
 177 # for which encoding all byte sequences are valid, for example
 178 # 'iso-8859-1' aka 'latin1' (it is decoded without checking, so it
 179 # could be even 'utf-8' for the old behavior)
 180 our $fallback_encoding = 'latin1';
 181
 182 # rename detection options for git-diff and git-diff-tree
 183 # - default is '-M', with the cost proportional to
 184 #   (number of removed files) * (number of new files).
 185 # - more costly is '-C' (which implies '-M'), with the cost proportional to
 186 #   (number of changed files + number of removed files) * (number of new files)
 187 # - even more costly is '-C', '--find-copies-harder' with cost
 188 #   (number of files in the original tree) * (number of new files)
 189 # - one might want to include '-B' option, e.g. '-B', '-M'
 190 our @diff_opts = ('-M'); # taken from git_commit
 191
 192 # Disables features that would allow repository owners to inject script into
 193 # the gitweb domain.
 194 our $prevent_xss = 0;
 195
 196 # Path to the highlight executable to use (must be the one from
 197 # http://www.andre-simon.de due to assumptions about parameters and output).
 198 # Useful if highlight is not installed on your webserver's PATH.
 199 # [Default: highlight]
 200 our $highlight_bin = "++HIGHLIGHT_BIN++";
 201
 202 # information about snapshot formats that gitweb is capable of serving
 203 our %known_snapshot_formats = (
 204         # name => {
 205         #       'display' => display name,
 206         #       'type' => mime type,
 207         #       'suffix' => filename suffix,
 208         #       'format' => --format for git-archive,
 209         #       'compressor' => [compressor command and arguments]
 210         #                       (array reference, optional)
 211         #       'disabled' => boolean (optional)}
 212         #
 213         'tgz' => {
 214                 'display' => 'tar.gz',
 215                 'type' => 'application/x-gzip',
 216                 'suffix' => '.tar.gz',
 217                 'format' => 'tar',
 218                 'compressor' => ['gzip', '-n']},
 219
 220         'tbz2' => {
 221                 'display' => 'tar.bz2',
 222                 'type' => 'application/x-bzip2',
 223                 'suffix' => '.tar.bz2',
 224                 'format' => 'tar',
 225                 'compressor' => ['bzip2']},
 226
 227         'txz' => {
 228                 'display' => 'tar.xz',
 229                 'type' => 'application/x-xz',
 230                 'suffix' => '.tar.xz',
 231                 'format' => 'tar',
 232                 'compressor' => ['xz'],
 233                 'disabled' => 1},
 234
 235         'zip' => {
 236                 'display' => 'zip',
 237                 'type' => 'application/x-zip',
 238                 'suffix' => '.zip',
 239                 'format' => 'zip'},
 240 );
 241
 242 # Aliases so we understand old gitweb.snapshot values in repository
 243 # configuration.
 244 our %known_snapshot_format_aliases = (
 245         'gzip'  => 'tgz',
 246         'bzip2' => 'tbz2',
 247         'xz'    => 'txz',
 248
 249         # backward compatibility: legacy gitweb config support
 250         'x-gzip' => undef, 'gz' => undef,
 251         'x-bzip2' => undef, 'bz2' => undef,
 252         'x-zip' => undef, '' => undef,
 253 );
 254
 255 # Pixel sizes for icons and avatars. If the default font sizes or lineheights
 256 # are changed, it may be appropriate to change these values too via
 257 # $GITWEB_CONFIG.
 258 our %avatar_size = (
 259         'default' => 16,
 260         'double'  => 32
 261 );
 262
 263 # Used to set the maximum load that we will still respond to gitweb queries.
 264 # If server load exceed this value then return "503 server busy" error.
 265 # If gitweb cannot determined server load, it is taken to be 0.
 266 # Leave it undefined (or set to 'undef') to turn off load checking.
 267 our $maxload = 300;
 268
 269 # configuration for 'highlight' (http://www.andre-simon.de/)
 270 # match by basename
 271 our %highlight_basename = (
 272         #'Program' => 'py',
 273         #'Library' => 'py',
 274         'SConstruct' => 'py', # SCons equivalent of Makefile
 275         'Makefile' => 'make',
 276 );
 277 # match by extension
 278 our %highlight_ext = (
 279         # main extensions, defining name of syntax;
 280         # see files in /usr/share/highlight/langDefs/ directory
 281         (map { $_ => $_ } qw(py rb java css js tex bib xml awk bat ini spec tcl sql)),
 282         # alternate extensions, see /etc/highlight/filetypes.conf
 283         (map { $_ => 'c'   } qw(c h)),
 284         (map { $_ => 'sh'  } qw(sh bash zsh ksh)),
 285         (map { $_ => 'cpp' } qw(cpp cxx c++ cc)),
 286         (map { $_ => 'php' } qw(php php3 php4 php5 phps)),
 287         (map { $_ => 'pl'  } qw(pl perl pm)), # perhaps also 'cgi'
 288         (map { $_ => 'make'} qw(make mak mk)),
 289         (map { $_ => 'xml' } qw(xml xhtml html htm)),
 290 );
 291
 292 # You define site-wide feature defaults here; override them with
 293 # $GITWEB_CONFIG as necessary.
 294 our %feature = (
 295         # feature => {
 296         #       'sub' => feature-sub (subroutine),
 297         #       'override' => allow-override (boolean),
 298         #       'default' => [ default options...] (array reference)}
 299         #
 300         # if feature is overridable (it means that allow-override has true value),
 301         # then feature-sub will be called with default options as parameters;
 302         # return value of feature-sub indicates if to enable specified feature
 303         #
 304         # if there is no 'sub' key (no feature-sub), then feature cannot be
 305         # overridden
 306         #
 307         # use gitweb_get_feature(<feature>) to retrieve the <feature> value
 308         # (an array) or gitweb_check_feature(<feature>) to check if <feature>
 309         # is enabled
 310
 311         # Enable the 'blame' blob view, showing the last commit that modified
 312         # each line in the file. This can be very CPU-intensive.
 313
 314         # To enable system wide have in $GITWEB_CONFIG
 315         # $feature{'blame'}{'default'} = [1];
 316         # To have project specific config enable override in $GITWEB_CONFIG
 317         # $feature{'blame'}{'override'} = 1;
 318         # and in project config gitweb.blame = 0|1;
 319         'blame' => {
 320                 'sub' => sub { feature_bool('blame', @_) },
 321                 'override' => 0,
 322                 'default' => [0]},
 323
 324         # Enable the 'snapshot' link, providing a compressed archive of any
 325         # tree. This can potentially generate high traffic if you have large
 326         # project.
 327
 328         # Value is a list of formats defined in %known_snapshot_formats that
 329         # you wish to offer.
 330         # To disable system wide have in $GITWEB_CONFIG
 331         # $feature{'snapshot'}{'default'} = [];
 332         # To have project specific config enable override in $GITWEB_CONFIG
 333         # $feature{'snapshot'}{'override'} = 1;
 334         # and in project config, a comma-separated list of formats or "none"
 335         # to disable.  Example: gitweb.snapshot = tbz2,zip;
 336         'snapshot' => {
 337                 'sub' => \&feature_snapshot,
 338                 'override' => 0,
 339                 'default' => ['tgz']},
 340
 341         # Enable text search, which will list the commits which match author,
 342         # committer or commit text to a given string.  Enabled by default.
 343         # Project specific override is not supported.
 344         #
 345         # Note that this controls all search features, which means that if
 346         # it is disabled, then 'grep' and 'pickaxe' search would also be
 347         # disabled.
 348         'search' => {
 349                 'override' => 0,
 350                 'default' => [1]},
 351
 352         # Enable grep search, which will list the files in currently selected
 353         # tree containing the given string. Enabled by default. This can be
 354         # potentially CPU-intensive, of course.
 355         # Note that you need to have 'search' feature enabled too.
 356
 357         # To enable system wide have in $GITWEB_CONFIG
 358         # $feature{'grep'}{'default'} = [1];
 359         # To have project specific config enable override in $GITWEB_CONFIG
 360         # $feature{'grep'}{'override'} = 1;
 361         # and in project config gitweb.grep = 0|1;
 362         'grep' => {
 363                 'sub' => sub { feature_bool('grep', @_) },
 364                 'override' => 0,
 365                 'default' => [1]},
 366
 367         # Enable the pickaxe search, which will list the commits that modified
 368         # a given string in a file. This can be practical and quite faster
 369         # alternative to 'blame', but still potentially CPU-intensive.
 370         # Note that you need to have 'search' feature enabled too.
 371
 372         # To enable system wide have in $GITWEB_CONFIG
 373         # $feature{'pickaxe'}{'default'} = [1];
 374         # To have project specific config enable override in $GITWEB_CONFIG
 375         # $feature{'pickaxe'}{'override'} = 1;
 376         # and in project config gitweb.pickaxe = 0|1;
 377         'pickaxe' => {
 378                 'sub' => sub { feature_bool('pickaxe', @_) },
 379                 'override' => 0,
 380                 'default' => [1]},
 381
 382         # Enable showing size of blobs in a 'tree' view, in a separate
 383         # column, similar to what 'ls -l' does.  This cost a bit of IO.
 384
 385         # To disable system wide have in $GITWEB_CONFIG
 386         # $feature{'show-sizes'}{'default'} = [0];
 387         # To have project specific config enable override in $GITWEB_CONFIG
 388         # $feature{'show-sizes'}{'override'} = 1;
 389         # and in project config gitweb.showsizes = 0|1;
 390         'show-sizes' => {
 391                 'sub' => sub { feature_bool('showsizes', @_) },
 392                 'override' => 0,
 393                 'default' => [1]},
 394
 395         # Make gitweb use an alternative format of the URLs which can be
 396         # more readable and natural-looking: project name is embedded
 397         # directly in the path and the query string contains other
 398         # auxiliary information. All gitweb installations recognize
 399         # URL in either format; this configures in which formats gitweb
 400         # generates links.
 401
 402         # To enable system wide have in $GITWEB_CONFIG
 403         # $feature{'pathinfo'}{'default'} = [1];
 404         # Project specific override is not supported.
 405
 406         # Note that you will need to change the default location of CSS,
 407         # favicon, logo and possibly other files to an absolute URL. Also,
 408         # if gitweb.cgi serves as your indexfile, you will need to force
 409         # $my_uri to contain the script name in your $GITWEB_CONFIG.
 410         'pathinfo' => {
 411                 'override' => 0,
 412                 'default' => [0]},
 413
 414         # Make gitweb consider projects in project root subdirectories
 415         # to be forks of existing projects. Given project $projname.git,
 416         # projects matching $projname/*.git will not be shown in the main
 417         # projects list, instead a '+' mark will be added to $projname
 418         # there and a 'forks' view will be enabled for the project, listing
 419         # all the forks. If project list is taken from a file, forks have
 420         # to be listed after the main project.
 421
 422         # To enable system wide have in $GITWEB_CONFIG
 423         # $feature{'forks'}{'default'} = [1];
 424         # Project specific override is not supported.
 425         'forks' => {
 426                 'override' => 0,
 427                 'default' => [0]},
 428
 429         # Insert custom links to the action bar of all project pages.
 430         # This enables you mainly to link to third-party scripts integrating
 431         # into gitweb; e.g. git-browser for graphical history representation
 432         # or custom web-based repository administration interface.
 433
 434         # The 'default' value consists of a list of triplets in the form
 435         # (label, link, position) where position is the label after which
 436         # to insert the link and link is a format string where %n expands
 437         # to the project name, %f to the project path within the filesystem,
 438         # %h to the current hash (h gitweb parameter) and %b to the current
 439         # hash base (hb gitweb parameter); %% expands to %.
 440
 441         # To enable system wide have in $GITWEB_CONFIG e.g.
 442         # $feature{'actions'}{'default'} = [('graphiclog',
 443         #       '/git-browser/by-commit.html?r=%n', 'summary')];
 444         # Project specific override is not supported.
 445         'actions' => {
 446                 'override' => 0,
 447                 'default' => []},
 448
 449         # Allow gitweb scan project content tags of project repository,
 450         # and display the popular Web 2.0-ish "tag cloud" near the projects
 451         # list.  Note that this is something COMPLETELY different from the
 452         # normal Git tags.
 453
 454         # gitweb by itself can show existing tags, but it does not handle
 455         # tagging itself; you need to do it externally, outside gitweb.
 456         # The format is described in git_get_project_ctags() subroutine.
 457         # You may want to install the HTML::TagCloud Perl module to get
 458         # a pretty tag cloud instead of just a list of tags.
 459
 460         # To enable system wide have in $GITWEB_CONFIG
 461         # $feature{'ctags'}{'default'} = [1];
 462         # Project specific override is not supported.
 463
 464         # In the future whether ctags editing is enabled might depend
 465         # on the value, but using 1 should always mean no editing of ctags.
 466         'ctags' => {
 467                 'override' => 0,
 468                 'default' => [0]},
 469
 470         # The maximum number of patches in a patchset generated in patch
 471         # view. Set this to 0 or undef to disable patch view, or to a
 472         # negative number to remove any limit.
 473
 474         # To disable system wide have in $GITWEB_CONFIG
 475         # $feature{'patches'}{'default'} = [0];
 476         # To have project specific config enable override in $GITWEB_CONFIG
 477         # $feature{'patches'}{'override'} = 1;
 478         # and in project config gitweb.patches = 0|n;
 479         # where n is the maximum number of patches allowed in a patchset.
 480         'patches' => {
 481                 'sub' => \&feature_patches,
 482                 'override' => 0,
 483                 'default' => [16]},
 484
 485         # Avatar support. When this feature is enabled, views such as
 486         # shortlog or commit will display an avatar associated with
 487         # the email of the committer(s) and/or author(s).
 488
 489         # Currently available providers are gravatar and picon.
 490         # If an unknown provider is specified, the feature is disabled.
 491
 492         # Gravatar depends on Digest::MD5.
 493         # Picon currently relies on the indiana.edu database.
 494
 495         # To enable system wide have in $GITWEB_CONFIG
 496         # $feature{'avatar'}{'default'} = ['<provider>'];
 497         # where <provider> is either gravatar or picon.
 498         # To have project specific config enable override in $GITWEB_CONFIG
 499         # $feature{'avatar'}{'override'} = 1;
 500         # and in project config gitweb.avatar = <provider>;
 501         'avatar' => {
 502                 'sub' => \&feature_avatar,
 503                 'override' => 0,
 504                 'default' => ['']},
 505
 506         # Enable displaying how much time and how many git commands
 507         # it took to generate and display page.  Disabled by default.
 508         # Project specific override is not supported.
 509         'timed' => {
 510                 'override' => 0,
 511                 'default' => [0]},
 512
 513         # Enable turning some links into links to actions which require
 514         # JavaScript to run (like 'blame_incremental').  Not enabled by
 515         # default.  Project specific override is currently not supported.
 516         'javascript-actions' => {
 517                 'override' => 0,
 518                 'default' => [0]},
 519
 520         # Enable and configure ability to change common timezone for dates
 521         # in gitweb output via JavaScript.  Enabled by default.
 522         # Project specific override is not supported.
 523         'javascript-timezone' => {
 524                 'override' => 0,
 525                 'default' => [
 526                         'local',     # default timezone: 'utc', 'local', or '(-|+)HHMM' format,
 527                                      # or undef to turn off this feature
 528                         'gitweb_tz', # name of cookie where to store selected timezone
 529                         'datetime',  # CSS class used to mark up dates for manipulation
 530                 ]},
 531
 532         # Syntax highlighting support. This is based on Daniel Svensson's
 533         # and Sham Chukoury's work in gitweb-xmms2.git.
 534         # It requires the 'highlight' program present in $PATH,
 535         # and therefore is disabled by default.
 536
 537         # To enable system wide have in $GITWEB_CONFIG
 538         # $feature{'highlight'}{'default'} = [1];
 539
 540         'highlight' => {
 541                 'sub' => sub { feature_bool('highlight', @_) },
 542                 'override' => 0,
 543                 'default' => [0]},
 544
 545         # Enable displaying of remote heads in the heads list
 546
 547         # To enable system wide have in $GITWEB_CONFIG
 548         # $feature{'remote_heads'}{'default'} = [1];
 549         # To have project specific config enable override in $GITWEB_CONFIG
 550         # $feature{'remote_heads'}{'override'} = 1;
 551         # and in project config gitweb.remoteheads = 0|1;
 552         'remote_heads' => {
 553                 'sub' => sub { feature_bool('remote_heads', @_) },
 554                 'override' => 0,
 555                 'default' => [0]},
 556
 557         # Enable showing branches under other refs in addition to heads
 558
 559         # To set system wide extra branch refs have in $GITWEB_CONFIG
 560         # $feature{'extra-branch-refs'}{'default'} = ['dirs', 'of', 'choice'];
 561         # To have project specific config enable override in $GITWEB_CONFIG
 562         # $feature{'extra-branch-refs'}{'override'} = 1;
 563         # and in project config gitweb.extrabranchrefs = dirs of choice
 564         # Every directory is separated with whitespace.
 565
 566         'extra-branch-refs' => {
 567                 'sub' => \&feature_extra_branch_refs,
 568                 'override' => 0,
 569                 'default' => []},
 570 );
 571
 572 sub gitweb_get_feature {
 573         my ($name) = @_;
 574         return unless exists $feature{$name};
 575         my ($sub, $override, @defaults) = (
 576                 $feature{$name}{'sub'},
 577                 $feature{$name}{'override'},
 578                 @{$feature{$name}{'default'}});
 579         # project specific override is possible only if we have project
 580         our $git_dir; # global variable, declared later
 581         if (!$override || !defined $git_dir) {
 582                 return @defaults;
 583         }
 584         if (!defined $sub) {
 585                 warn "feature $name is not overridable";
 586                 return @defaults;
 587         }
 588         return $sub->(@defaults);
 589 }
 590
 591 # A wrapper to check if a given feature is enabled.
 592 # With this, you can say
 593 #
 594 #   my $bool_feat = gitweb_check_feature('bool_feat');
 595 #   gitweb_check_feature('bool_feat') or somecode;
 596 #
 597 # instead of
 598 #
 599 #   my ($bool_feat) = gitweb_get_feature('bool_feat');
 600 #   (gitweb_get_feature('bool_feat'))[0] or somecode;
 601 #
 602 sub gitweb_check_feature {
 603         return (gitweb_get_feature(@_))[0];
 604 }
 605
 606
 607 sub feature_bool {
 608         my $key = shift;
 609         my ($val) = git_get_project_config($key, '--bool');
 610
 611         if (!defined $val) {
 612                 return ($_[0]);
 613         } elsif ($val eq 'true') {
 614                 return (1);
 615         } elsif ($val eq 'false') {
 616                 return (0);
 617         }
 618 }
 619
 620 sub feature_snapshot {
 621         my (@fmts) = @_;
 622
 623         my ($val) = git_get_project_config('snapshot');
 624
 625         if ($val) {
 626                 @fmts = ($val eq 'none' ? () : split /\s*[,\s]\s*/, $val);
 627         }
 628
 629         return @fmts;
 630 }
 631
 632 sub feature_patches {
 633         my @val = (git_get_project_config('patches', '--int'));
 634
 635         if (@val) {
 636                 return @val;
 637         }
 638
 639         return ($_[0]);
 640 }
 641
 642 sub feature_avatar {
 643         my @val = (git_get_project_config('avatar'));
 644
 645         return @val ? @val : @_;
 646 }
 647
 648 sub feature_extra_branch_refs {
 649         my (@branch_refs) = @_;
 650         my $values = git_get_project_config('extrabranchrefs');
 651
 652         if ($values) {
 653                 $values = config_to_multi ($values);
 654                 @branch_refs = ();
 655                 foreach my $value (@{$values}) {
 656                         push @branch_refs, split /\s+/, $value;
 657                 }
 658         }
 659
 660         return @branch_refs;
 661 }
 662
 663 # checking HEAD file with -e is fragile if the repository was
 664 # initialized long time ago (i.e. symlink HEAD) and was pack-ref'ed
 665 # and then pruned.
 666 sub check_head_link {
 667         my ($dir) = @_;
 668         my $headfile = "$dir/HEAD";
 669         return ((-e $headfile) ||
 670                 (-l $headfile && readlink($headfile) =~ /^refs\/heads\//));
 671 }
 672
 673 sub check_export_ok {
 674         my ($dir) = @_;
 675         return (check_head_link($dir) &&
 676                 (!$export_ok || -e "$dir/$export_ok") &&
 677                 (!$export_auth_hook || $export_auth_hook->($dir)));
 678 }
 679
 680 # process alternate names for backward compatibility
 681 # filter out unsupported (unknown) snapshot formats
 682 sub filter_snapshot_fmts {
 683         my @fmts = @_;
 684
 685         @fmts = map {
 686                 exists $known_snapshot_format_aliases{$_} ?
 687                        $known_snapshot_format_aliases{$_} : $_} @fmts;
 688         @fmts = grep {
 689                 exists $known_snapshot_formats{$_} &&
 690                 !$known_snapshot_formats{$_}{'disabled'}} @fmts;
 691 }
 692
 693 sub filter_and_validate_refs {
 694         my @refs = @_;
 695         my %unique_refs = ();
 696
 697         foreach my $ref (@refs) {
 698                 die_error(500, "Invalid ref '$ref' in 'extra-branch-refs' feature") unless (is_valid_ref_format($ref));
 699                 # 'heads' are added implicitly in get_branch_refs().
 700                 $unique_refs{$ref} = 1 if ($ref ne 'heads');
 701         }
 702         return sort keys %unique_refs;
 703 }
 704
 705 # If it is set to code reference, it is code that it is to be run once per
 706 # request, allowing updating configurations that change with each request,
 707 # while running other code in config file only once.
 708 #
 709 # Otherwise, if it is false then gitweb would process config file only once;
 710 # if it is true then gitweb config would be run for each request.
 711 our $per_request_config = 1;
 712
 713 # read and parse gitweb config file given by its parameter.
 714 # returns true on success, false on recoverable error, allowing
 715 # to chain this subroutine, using first file that exists.
 716 # dies on errors during parsing config file, as it is unrecoverable.
 717 sub read_config_file {
 718         my $filename = shift;
 719         return unless defined $filename;
 720         # die if there are errors parsing config file
 721         if (-e $filename) {
 722                 do $filename;
 723                 die $@ if $@;
 724                 return 1;
 725         }
 726         return;
 727 }
 728
 729 our ($GITWEB_CONFIG, $GITWEB_CONFIG_SYSTEM, $GITWEB_CONFIG_COMMON);
 730 sub evaluate_gitweb_config {
 731         our $GITWEB_CONFIG = $ENV{'GITWEB_CONFIG'} || "++GITWEB_CONFIG++";
 732         our $GITWEB_CONFIG_SYSTEM = $ENV{'GITWEB_CONFIG_SYSTEM'} || "++GITWEB_CONFIG_SYSTEM++";
 733         our $GITWEB_CONFIG_COMMON = $ENV{'GITWEB_CONFIG_COMMON'} || "++GITWEB_CONFIG_COMMON++";
 734
 735         # Protect against duplications of file names, to not read config twice.
 736         # Only one of $GITWEB_CONFIG and $GITWEB_CONFIG_SYSTEM is used, so
 737         # there possibility of duplication of filename there doesn't matter.
 738         $GITWEB_CONFIG = ""        if ($GITWEB_CONFIG eq $GITWEB_CONFIG_COMMON);
 739         $GITWEB_CONFIG_SYSTEM = "" if ($GITWEB_CONFIG_SYSTEM eq $GITWEB_CONFIG_COMMON);
 740
 741         # Common system-wide settings for convenience.
 742         # Those settings can be ovverriden by GITWEB_CONFIG or GITWEB_CONFIG_SYSTEM.
 743         read_config_file($GITWEB_CONFIG_COMMON);
 744
 745         # Use first config file that exists.  This means use the per-instance
 746         # GITWEB_CONFIG if exists, otherwise use GITWEB_SYSTEM_CONFIG.
 747         read_config_file($GITWEB_CONFIG) and return;
 748         read_config_file($GITWEB_CONFIG_SYSTEM);
 749 }
 750
 751 # Get loadavg of system, to compare against $maxload.
 752 # Currently it requires '/proc/loadavg' present to get loadavg;
 753 # if it is not present it returns 0, which means no load checking.
 754 sub get_loadavg {
 755         if( -e '/proc/loadavg' ){
 756                 open my $fd, '<', '/proc/loadavg'
 757                         or return 0;
 758                 my @load = split(/\s+/, scalar <$fd>);
 759                 close $fd;
 760
 761                 # The first three columns measure CPU and IO utilization of the last one,
 762                 # five, and 10 minute periods.  The fourth column shows the number of
 763                 # currently running processes and the total number of processes in the m/n
 764                 # format.  The last column displays the last process ID used.
 765                 return $load[0] || 0;
 766         }
 767         # additional checks for load average should go here for things that don't export
 768         # /proc/loadavg
 769
 770         return 0;
 771 }
 772
 773 # version of the core git binary
 774 our $git_version;
 775 sub evaluate_git_version {
 776         our $git_version = qx("$GIT" --version) =~ m/git version (.*)$/ ? $1 : "unknown";
 777         $number_of_git_cmds++;
 778 }
 779
 780 sub check_loadavg {
 781         if (defined $maxload && get_loadavg() > $maxload) {
 782                 die_error(503, "The load average on the server is too high");
 783         }
 784 }
 785
 786 # ======================================================================
 787 # input validation and dispatch
 788
 789 # input parameters can be collected from a variety of sources (presently, CGI
 790 # and PATH_INFO), so we define an %input_params hash that collects them all
 791 # together during validation: this allows subsequent uses (e.g. href()) to be
 792 # agnostic of the parameter origin
 793
 794 our %input_params = ();
 795
 796 # input parameters are stored with the long parameter name as key. This will
 797 # also be used in the href subroutine to convert parameters to their CGI
 798 # equivalent, and since the href() usage is the most frequent one, we store
 799 # the name -> CGI key mapping here, instead of the reverse.
 800 #
 801 # XXX: Warning: If you touch this, check the search form for updating,
 802 # too.
 803
 804 our @cgi_param_mapping = (
 805         project => "p",
 806         action => "a",
 807         file_name => "f",
 808         file_parent => "fp",
 809         hash => "h",
 810         hash_parent => "hp",
 811         hash_base => "hb",
 812         hash_parent_base => "hpb",
 813         page => "pg",
 814         order => "o",
 815         searchtext => "s",
 816         searchtype => "st",
 817         snapshot_format => "sf",
 818         extra_options => "opt",
 819         search_use_regexp => "sr",
 820         ctag => "by_tag",
 821         diff_style => "ds",
 822         project_filter => "pf",
 823         # this must be last entry (for manipulation from JavaScript)
 824         javascript => "js"
 825 );
 826 our %cgi_param_mapping = @cgi_param_mapping;
 827
 828 # we will also need to know the possible actions, for validation
 829 our %actions = (
 830         "blame" => \&git_blame,
 831         "blame_incremental" => \&git_blame_incremental,
 832         "blame_data" => \&git_blame_data,
 833         "blobdiff" => \&git_blobdiff,
 834         "blobdiff_plain" => \&git_blobdiff_plain,
 835         "blob" => \&git_blob,
 836         "blob_plain" => \&git_blob_plain,
 837         "commitdiff" => \&git_commitdiff,
 838         "commitdiff_plain" => \&git_commitdiff_plain,
 839         "commit" => \&git_commit,
 840         "forks" => \&git_forks,
 841         "heads" => \&git_heads,
 842         "history" => \&git_history,
 843         "log" => \&git_log,
 844         "patch" => \&git_patch,
 845         "patches" => \&git_patches,
 846         "remotes" => \&git_remotes,
 847         "rss" => \&git_rss,
 848         "atom" => \&git_atom,
 849         "search" => \&git_search,
 850         "search_help" => \&git_search_help,
 851         "shortlog" => \&git_shortlog,
 852         "summary" => \&git_summary,
 853         "tag" => \&git_tag,
 854         "tags" => \&git_tags,
 855         "tree" => \&git_tree,
 856         "snapshot" => \&git_snapshot,
 857         "object" => \&git_object,
 858         # those below don't need $project
 859         "opml" => \&git_opml,
 860         "project_list" => \&git_project_list,
 861         "project_index" => \&git_project_index,
 862 );
 863
 864 # finally, we have the hash of allowed extra_options for the commands that
 865 # allow them
 866 our %allowed_options = (
 867         "--no-merges" => [ qw(rss atom log shortlog history) ],
 868 );
 869
 870 # fill %input_params with the CGI parameters. All values except for 'opt'
 871 # should be single values, but opt can be an array. We should probably
 872 # build an array of parameters that can be multi-valued, but since for the time
 873 # being it's only this one, we just single it out
 874 sub evaluate_query_params {
 875         our $cgi;
 876
 877         while (my ($name, $symbol) = each %cgi_param_mapping) {
 878                 if ($symbol eq 'opt') {
 879                         $input_params{$name} = [ map { decode_utf8($_) } $cgi->multi_param($symbol) ];
 880                 } else {
 881                         $input_params{$name} = decode_utf8($cgi->param($symbol));
 882                 }
 883         }
 884 }
 885
 886 # now read PATH_INFO and update the parameter list for missing parameters
 887 sub evaluate_path_info {
 888         return if defined $input_params{'project'};
 889         return if !$path_info;
 890         $path_info =~ s,^/+,,;
 891         return if !$path_info;
 892
 893         # find which part of PATH_INFO is project
 894         my $project = $path_info;
 895         $project =~ s,/+$,,;
 896         while ($project && !check_head_link("$projectroot/$project")) {
 897                 $project =~ s,/*[^/]*$,,;
 898         }
 899         return unless $project;
 900         $input_params{'project'} = $project;
 901
 902         # do not change any parameters if an action is given using the query string
 903         return if $input_params{'action'};
 904         $path_info =~ s,^\Q$project\E/*,,;
 905
 906         # next, check if we have an action
 907         my $action = $path_info;
 908         $action =~ s,/.*$,,;
 909         if (exists $actions{$action}) {
 910                 $path_info =~ s,^$action/*,,;
 911                 $input_params{'action'} = $action;
 912         }
 913
 914         # list of actions that want hash_base instead of hash, but can have no
 915         # pathname (f) parameter
 916         my @wants_base = (
 917                 'tree',
 918                 'history',
 919         );
 920
 921         # we want to catch, among others
 922         # [$hash_parent_base[:$file_parent]..]$hash_parent[:$file_name]
 923         my ($parentrefname, $parentpathname, $refname, $pathname) =
 924                 ($path_info =~ /^(?:(.+?)(?::(.+))?\.\.)?([^:]+?)?(?::(.+))?$/);
 925
 926         # first, analyze the 'current' part
 927         if (defined $pathname) {
 928                 # we got "branch:filename" or "branch:dir/"
 929                 # we could use git_get_type(branch:pathname), but:
 930                 # - it needs $git_dir
 931                 # - it does a git() call
 932                 # - the convention of terminating directories with a slash
 933                 #   makes it superfluous
 934                 # - embedding the action in the PATH_INFO would make it even
 935                 #   more superfluous
 936                 $pathname =~ s,^/+,,;
 937                 if (!$pathname || substr($pathname, -1) eq "/") {
 938                         $input_params{'action'} ||= "tree";
 939                         $pathname =~ s,/$,,;
 940                 } else {
 941                         # the default action depends on whether we had parent info
 942                         # or not
 943                         if ($parentrefname) {
 944                                 $input_params{'action'} ||= "blobdiff_plain";
 945                         } else {
 946                                 $input_params{'action'} ||= "blob_plain";
 947                         }
 948                 }
 949                 $input_params{'hash_base'} ||= $refname;
 950                 $input_params{'file_name'} ||= $pathname;
 951         } elsif (defined $refname) {
 952                 # we got "branch". In this case we have to choose if we have to
 953                 # set hash or hash_base.
 954                 #
 955                 # Most of the actions without a pathname only want hash to be
 956                 # set, except for the ones specified in @wants_base that want
 957                 # hash_base instead. It should also be noted that hand-crafted
 958                 # links having 'history' as an action and no pathname or hash
 959                 # set will fail, but that happens regardless of PATH_INFO.
 960                 if (defined $parentrefname) {
 961                         # if there is parent let the default be 'shortlog' action
 962                         # (for http://git.example.com/repo.git/A..B links); if there
 963                         # is no parent, dispatch will detect type of object and set
 964                         # action appropriately if required (if action is not set)
 965                         $input_params{'action'} ||= "shortlog";
 966                 }
 967                 if ($input_params{'action'} &&
 968                     grep { $_ eq $input_params{'action'} } @wants_base) {
 969                         $input_params{'hash_base'} ||= $refname;
 970                 } else {
 971                         $input_params{'hash'} ||= $refname;
 972                 }
 973         }
 974
 975         # next, handle the 'parent' part, if present
 976         if (defined $parentrefname) {
 977                 # a missing pathspec defaults to the 'current' filename, allowing e.g.
 978                 # someproject/blobdiff/oldrev..newrev:/filename
 979                 if ($parentpathname) {
 980                         $parentpathname =~ s,^/+,,;
 981                         $parentpathname =~ s,/$,,;
 982                         $input_params{'file_parent'} ||= $parentpathname;
 983                 } else {
 984                         $input_params{'file_parent'} ||= $input_params{'file_name'};
 985                 }
 986                 # we assume that hash_parent_base is wanted if a path was specified,
 987                 # or if the action wants hash_base instead of hash
 988                 if (defined $input_params{'file_parent'} ||
 989                         grep { $_ eq $input_params{'action'} } @wants_base) {
 990                         $input_params{'hash_parent_base'} ||= $parentrefname;
 991                 } else {
 992                         $input_params{'hash_parent'} ||= $parentrefname;
 993                 }
 994         }
 995
 996         # for the snapshot action, we allow URLs in the form
 997         # $project/snapshot/$hash.ext
 998         # where .ext determines the snapshot and gets removed from the
 999         # passed $refname to provide the $hash.
1000         #
1001         # To be able to tell that $refname includes the format extension, we
1002         # require the following two conditions to be satisfied:
1003         # - the hash input parameter MUST have been set from the $refname part
1004         #   of the URL (i.e. they must be equal)
1005         # - the snapshot format MUST NOT have been defined already (e.g. from
1006         #   CGI parameter sf)
1007         # It's also useless to try any matching unless $refname has a dot,
1008         # so we check for that too
1009         if (defined $input_params{'action'} &&
1010                 $input_params{'action'} eq 'snapshot' &&
1011                 defined $refname && index($refname, '.') != -1 &&
1012                 $refname eq $input_params{'hash'} &&
1013                 !defined $input_params{'snapshot_format'}) {
1014                 # We loop over the known snapshot formats, checking for
1015                 # extensions. Allowed extensions are both the defined suffix
1016                 # (which includes the initial dot already) and the snapshot
1017                 # format key itself, with a prepended dot
1018                 while (my ($fmt, $opt) = each %known_snapshot_formats) {
1019                         my $hash = $refname;
1020                         unless ($hash =~ s/(\Q$opt->{'suffix'}\E|\Q.$fmt\E)$//) {
1021                                 next;
1022                         }
1023                         my $sfx = $1;
1024                         # a valid suffix was found, so set the snapshot format
1025                         # and reset the hash parameter
1026                         $input_params{'snapshot_format'} = $fmt;
1027                         $input_params{'hash'} = $hash;
1028                         # we also set the format suffix to the one requested
1029                         # in the URL: this way a request for e.g. .tgz returns
1030                         # a .tgz instead of a .tar.gz
1031                         $known_snapshot_formats{$fmt}{'suffix'} = $sfx;
1032                         last;
1033                 }
1034         }
1035 }
1036
1037 our ($action, $project, $file_name, $file_parent, $hash, $hash_parent, $hash_base,
1038      $hash_parent_base, @extra_options, $page, $searchtype, $search_use_regexp,
1039      $searchtext, $search_regexp, $project_filter);
1040 sub evaluate_and_validate_params {
1041         our $action = $input_params{'action'};
1042         if (defined $action) {
1043                 if (!is_valid_action($action)) {
1044                         die_error(400, "Invalid action parameter");
1045                 }
1046         }
1047
1048         # parameters which are pathnames
1049         our $project = $input_params{'project'};
1050         if (defined $project) {
1051                 if (!is_valid_project($project)) {
1052                         undef $project;
1053                         die_error(404, "No such project");
1054                 }
1055         }
1056
1057         our $project_filter = $input_params{'project_filter'};
1058         if (defined $project_filter) {
1059                 if (!is_valid_pathname($project_filter)) {
1060                         die_error(404, "Invalid project_filter parameter");
1061                 }
1062         }
1063
1064         our $file_name = $input_params{'file_name'};
1065         if (defined $file_name) {
1066                 if (!is_valid_pathname($file_name)) {
1067                         die_error(400, "Invalid file parameter");
1068                 }
1069         }
1070
1071         our $file_parent = $input_params{'file_parent'};
1072         if (defined $file_parent) {
1073                 if (!is_valid_pathname($file_parent)) {
1074                         die_error(400, "Invalid file parent parameter");
1075                 }
1076         }
1077
1078         # parameters which are refnames
1079         our $hash = $input_params{'hash'};
1080         if (defined $hash) {
1081                 if (!is_valid_refname($hash)) {
1082                         die_error(400, "Invalid hash parameter");
1083                 }
1084         }
1085
1086         our $hash_parent = $input_params{'hash_parent'};
1087         if (defined $hash_parent) {
1088                 if (!is_valid_refname($hash_parent)) {
1089                         die_error(400, "Invalid hash parent parameter");
1090                 }
1091         }
1092
1093         our $hash_base = $input_params{'hash_base'};
1094         if (defined $hash_base) {
1095                 if (!is_valid_refname($hash_base)) {
1096                         die_error(400, "Invalid hash base parameter");
1097                 }
1098         }
1099
1100         our @extra_options = @{$input_params{'extra_options'}};
1101         # @extra_options is always defined, since it can only be (currently) set from
1102         # CGI, and $cgi->param() returns the empty array in array context if the param
1103         # is not set
1104         foreach my $opt (@extra_options) {
1105                 if (not exists $allowed_options{$opt}) {
1106                         die_error(400, "Invalid option parameter");
1107                 }
1108                 if (not grep(/^$action$/, @{$allowed_options{$opt}})) {
1109                         die_error(400, "Invalid option parameter for this action");
1110                 }
1111         }
1112
1113         our $hash_parent_base = $input_params{'hash_parent_base'};
1114         if (defined $hash_parent_base) {
1115                 if (!is_valid_refname($hash_parent_base)) {
1116                         die_error(400, "Invalid hash parent base parameter");
1117                 }
1118         }
1119
1120         # other parameters
1121         our $page = $input_params{'page'};
1122         if (defined $page) {
1123                 if ($page =~ m/[^0-9]/) {
1124                         die_error(400, "Invalid page parameter");
1125                 }
1126         }
1127
1128         our $searchtype = $input_params{'searchtype'};
1129         if (defined $searchtype) {
1130                 if ($searchtype =~ m/[^a-z]/) {
1131                         die_error(400, "Invalid searchtype parameter");
1132                 }
1133         }
1134
1135         our $search_use_regexp = $input_params{'search_use_regexp'};
1136
1137         our $searchtext = $input_params{'searchtext'};
1138         our $search_regexp = undef;
1139         if (defined $searchtext) {
1140                 if (length($searchtext) < 2) {
1141                         die_error(403, "At least two characters are required for search parameter");
1142                 }
1143                 if ($search_use_regexp) {
1144                         $search_regexp = $searchtext;
1145                         if (!eval { qr/$search_regexp/; 1; }) {
1146                                 (my $error = $@) =~ s/ at \S+ line \d+.*\n?//;
1147                                 die_error(400, "Invalid search regexp '$search_regexp'",
1148                                           esc_html($error));
1149                         }
1150                 } else {
1151                         $search_regexp = quotemeta $searchtext;
1152                 }
1153         }
1154 }
1155
1156 # path to the current git repository
1157 our $git_dir;
1158 sub evaluate_git_dir {
1159         our $git_dir = "$projectroot/$project" if $project;
1160 }
1161
1162 our (@snapshot_fmts, $git_avatar, @extra_branch_refs);
1163 sub configure_gitweb_features {
1164         # list of supported snapshot formats
1165         our @snapshot_fmts = gitweb_get_feature('snapshot');
1166         @snapshot_fmts = filter_snapshot_fmts(@snapshot_fmts);
1167
1168         # check that the avatar feature is set to a known provider name,
1169         # and for each provider check if the dependencies are satisfied.
1170         # if the provider name is invalid or the dependencies are not met,
1171         # reset $git_avatar to the empty string.
1172         our ($git_avatar) = gitweb_get_feature('avatar');
1173         if ($git_avatar eq 'gravatar') {
1174                 $git_avatar = '' unless (eval { require Digest::MD5; 1; });
1175         } elsif ($git_avatar eq 'picon') {
1176                 # no dependencies
1177         } else {
1178                 $git_avatar = '';
1179         }
1180
1181         our @extra_branch_refs = gitweb_get_feature('extra-branch-refs');
1182         @extra_branch_refs = filter_and_validate_refs (@extra_branch_refs);
1183 }
1184
1185 sub get_branch_refs {
1186         return ('heads', @extra_branch_refs);
1187 }
1188
1189 # custom error handler: 'die <message>' is Internal Server Error
1190 sub handle_errors_html {
1191         my $msg = shift; # it is already HTML escaped
1192
1193         # to avoid infinite loop where error occurs in die_error,
1194         # change handler to default handler, disabling handle_errors_html
1195         set_message("Error occurred when inside die_error:\n$msg");
1196
1197         # you cannot jump out of die_error when called as error handler;
1198         # the subroutine set via CGI::Carp::set_message is called _after_
1199         # HTTP headers are already written, so it cannot write them itself
1200         die_error(undef, undef, $msg, -error_handler => 1, -no_http_header => 1);
1201 }
1202 set_message(\&handle_errors_html);
1203
1204 # dispatch
1205 sub dispatch {
1206         if (!defined $action) {
1207                 if (defined $hash) {
1208                         $action = git_get_type($hash);
1209                         $action or die_error(404, "Object does not exist");
1210                 } elsif (defined $hash_base && defined $file_name) {
1211                         $action = git_get_type("$hash_base:$file_name");
1212                         $action or die_error(404, "File or directory does not exist");
1213                 } elsif (defined $project) {
1214                         $action = 'summary';
1215                 } else {
1216                         $action = 'project_list';
1217                 }
1218         }
1219         if (!defined($actions{$action})) {
1220                 die_error(400, "Unknown action");
1221         }
1222         if ($action !~ m/^(?:opml|project_list|project_index)$/ &&
1223             !$project) {
1224                 die_error(400, "Project needed");
1225         }
1226         $actions{$action}->();
1227 }
1228
1229 sub reset_timer {
1230         our $t0 = [ gettimeofday() ]
1231                 if defined $t0;
1232         our $number_of_git_cmds = 0;
1233 }
1234
1235 our $first_request = 1;
1236 sub run_request {
1237         reset_timer();
1238
1239         evaluate_uri();
1240         if ($first_request) {
1241                 evaluate_gitweb_config();
1242                 evaluate_git_version();
1243         }
1244         if ($per_request_config) {
1245                 if (ref($per_request_config) eq 'CODE') {
1246                         $per_request_config->();
1247                 } elsif (!$first_request) {
1248                         evaluate_gitweb_config();
1249                 }
1250         }
1251         check_loadavg();
1252
1253         # $projectroot and $projects_list might be set in gitweb config file
1254         $projects_list ||= $projectroot;
1255
1256         evaluate_query_params();
1257         evaluate_path_info();
1258         evaluate_and_validate_params();
1259         evaluate_git_dir();
1260
1261         configure_gitweb_features();
1262
1263         dispatch();
1264 }
1265
1266 our $is_last_request = sub { 1 };
1267 our ($pre_dispatch_hook, $post_dispatch_hook, $pre_listen_hook);
1268 our $CGI = 'CGI';
1269 our $cgi;
1270 sub configure_as_fcgi {
1271         require CGI::Fast;
1272         our $CGI = 'CGI::Fast';
1273
1274         my $request_number = 0;
1275         # let each child service 100 requests
1276         our $is_last_request = sub { ++$request_number > 100 };
1277 }
1278 sub evaluate_argv {
1279         my $script_name = $ENV{'SCRIPT_NAME'} || $ENV{'SCRIPT_FILENAME'} || __FILE__;
1280         configure_as_fcgi()
1281                 if $script_name =~ /\.fcgi$/;
1282
1283         return unless (@ARGV);
1284
1285         require Getopt::Long;
1286         Getopt::Long::GetOptions(
1287                 'fastcgi|fcgi|f' => \&configure_as_fcgi,
1288                 'nproc|n=i' => sub {
1289                         my ($arg, $val) = @_;
1290                         return unless eval { require FCGI::ProcManager; 1; };
1291                         my $proc_manager = FCGI::ProcManager->new({
1292                                 n_processes => $val,
1293                         });
1294                         our $pre_listen_hook    = sub { $proc_manager->pm_manage()        };
1295                         our $pre_dispatch_hook  = sub { $proc_manager->pm_pre_dispatch()  };
1296                         our $post_dispatch_hook = sub { $proc_manager->pm_post_dispatch() };
1297                 },
1298         );
1299 }
1300
1301 sub run {
1302         evaluate_argv();
1303
1304         $first_request = 1;
1305         $pre_listen_hook->()
1306                 if $pre_listen_hook;
1307
1308  REQUEST:
1309         while ($cgi = $CGI->new()) {
1310                 $pre_dispatch_hook->()
1311                         if $pre_dispatch_hook;
1312
1313                 run_request();
1314
1315                 $post_dispatch_hook->()
1316                         if $post_dispatch_hook;
1317                 $first_request = 0;
1318
1319                 last REQUEST if ($is_last_request->());
1320         }
1321
1322  DONE_GITWEB:
1323         1;
1324 }
1325
1326 run();
1327
1328 if (defined caller) {
1329         # wrapped in a subroutine processing requests,
1330         # e.g. mod_perl with ModPerl::Registry, or PSGI with Plack::App::WrapCGI
1331         return;
1332 } else {
1333         # pure CGI script, serving single request
1334         exit;
1335 }
1336
1337 ## ======================================================================
1338 ## action links
1339
1340 # possible values of extra options
1341 # -full => 0|1      - use absolute/full URL ($my_uri/$my_url as base)
1342 # -replay => 1      - start from a current view (replay with modifications)
1343 # -path_info => 0|1 - don't use/use path_info URL (if possible)
1344 # -anchor => ANCHOR - add #ANCHOR to end of URL, implies -replay if used alone
1345 sub href {
1346         my %params = @_;
1347         # default is to use -absolute url() i.e. $my_uri
1348         my $href = $params{-full} ? $my_url : $my_uri;
1349
1350         # implicit -replay, must be first of implicit params
1351         $params{-replay} = 1 if (keys %params == 1 && $params{-anchor});
1352
1353         $params{'project'} = $project unless exists $params{'project'};
1354
1355         if ($params{-replay}) {
1356                 while (my ($name, $symbol) = each %cgi_param_mapping) {
1357                         if (!exists $params{$name}) {
1358                                 $params{$name} = $input_params{$name};
1359                         }
1360                 }
1361         }
1362
1363         my $use_pathinfo = gitweb_check_feature('pathinfo');
1364         if (defined $params{'project'} &&
1365             (exists $params{-path_info} ? $params{-path_info} : $use_pathinfo)) {
1366                 # try to put as many parameters as possible in PATH_INFO:
1367                 #   - project name
1368                 #   - action
1369                 #   - hash_parent or hash_parent_base:/file_parent
1370                 #   - hash or hash_base:/filename
1371                 #   - the snapshot_format as an appropriate suffix
1372
1373                 # When the script is the root DirectoryIndex for the domain,
1374                 # $href here would be something like http://gitweb.example.com/
1375                 # Thus, we strip any trailing / from $href, to spare us double
1376                 # slashes in the final URL
1377                 $href =~ s,/$,,;
1378
1379                 # Then add the project name, if present
1380                 $href .= "/".esc_path_info($params{'project'});
1381                 delete $params{'project'};
1382
1383                 # since we destructively absorb parameters, we keep this
1384                 # boolean that remembers if we're handling a snapshot
1385                 my $is_snapshot = $params{'action'} eq 'snapshot';
1386
1387                 # Summary just uses the project path URL, any other action is
1388                 # added to the URL
1389                 if (defined $params{'action'}) {
1390                         $href .= "/".esc_path_info($params{'action'})
1391                                 unless $params{'action'} eq 'summary';
1392                         delete $params{'action'};
1393                 }
1394
1395                 # Next, we put hash_parent_base:/file_parent..hash_base:/file_name,
1396                 # stripping nonexistent or useless pieces
1397                 $href .= "/" if ($params{'hash_base'} || $params{'hash_parent_base'}
1398                         || $params{'hash_parent'} || $params{'hash'});
1399                 if (defined $params{'hash_base'}) {
1400                         if (defined $params{'hash_parent_base'}) {
1401                                 $href .= esc_path_info($params{'hash_parent_base'});
1402                                 # skip the file_parent if it's the same as the file_name
1403                                 if (defined $params{'file_parent'}) {
1404                                         if (defined $params{'file_name'} && $params{'file_parent'} eq $params{'file_name'}) {
1405                                                 delete $params{'file_parent'};
1406                                         } elsif ($params{'file_parent'} !~ /\.\./) {
1407                                                 $href .= ":/".esc_path_info($params{'file_parent'});
1408                                                 delete $params{'file_parent'};
1409                                         }
1410                                 }
1411                                 $href .= "..";
1412                                 delete $params{'hash_parent'};
1413                                 delete $params{'hash_parent_base'};
1414                         } elsif (defined $params{'hash_parent'}) {
1415                                 $href .= esc_path_info($params{'hash_parent'}). "..";
1416                                 delete $params{'hash_parent'};
1417                         }
1418
1419                         $href .= esc_path_info($params{'hash_base'});
1420                         if (defined $params{'file_name'} && $params{'file_name'} !~ /\.\./) {
1421                                 $href .= ":/".esc_path_info($params{'file_name'});
1422                                 delete $params{'file_name'};
1423                         }
1424                         delete $params{'hash'};
1425                         delete $params{'hash_base'};
1426                 } elsif (defined $params{'hash'}) {
1427                         $href .= esc_path_info($params{'hash'});
1428                         delete $params{'hash'};
1429                 }
1430
1431                 # If the action was a snapshot, we can absorb the
1432                 # snapshot_format parameter too
1433                 if ($is_snapshot) {
1434                         my $fmt = $params{'snapshot_format'};
1435                         # snapshot_format should always be defined when href()
1436                         # is called, but just in case some code forgets, we
1437                         # fall back to the default
1438                         $fmt ||= $snapshot_fmts[0];
1439                         $href .= $known_snapshot_formats{$fmt}{'suffix'};
1440                         delete $params{'snapshot_format'};
1441                 }
1442         }
1443
1444         # now encode the parameters explicitly
1445         my @result = ();
1446         for (my $i = 0; $i < @cgi_param_mapping; $i += 2) {
1447                 my ($name, $symbol) = ($cgi_param_mapping[$i], $cgi_param_mapping[$i+1]);
1448                 if (defined $params{$name}) {
1449                         if (ref($params{$name}) eq "ARRAY") {
1450                                 foreach my $par (@{$params{$name}}) {
1451                                         push @result, $symbol . "=" . esc_param($par);
1452                                 }
1453                         } else {
1454                                 push @result, $symbol . "=" . esc_param($params{$name});
1455                         }
1456                 }
1457         }
1458         $href .= "?" . join(';', @result) if scalar @result;
1459
1460         # final transformation: trailing spaces must be escaped (URI-encoded)
1461         $href =~ s/(\s+)$/CGI::escape($1)/e;
1462
1463         if ($params{-anchor}) {
1464                 $href .= "#".esc_param($params{-anchor});
1465         }
1466
1467         return $href;
1468 }
1469
1470
1471 ## ======================================================================
1472 ## validation, quoting/unquoting and escaping
1473
1474 sub is_valid_action {
1475         my $input = shift;
1476         return undef unless exists $actions{$input};
1477         return 1;
1478 }
1479
1480 sub is_valid_project {
1481         my $input = shift;
1482
1483         return unless defined $input;
1484         if (!is_valid_pathname($input) ||
1485                 !(-d "$projectroot/$input") ||
1486                 !check_export_ok("$projectroot/$input") ||
1487                 ($strict_export && !project_in_list($input))) {
1488                 return undef;
1489         } else {
1490                 return 1;
1491         }
1492 }
1493
1494 sub is_valid_pathname {
1495         my $input = shift;
1496
1497         return undef unless defined $input;
1498         # no '.' or '..' as elements of path, i.e. no '.' or '..'
1499         # at the beginning, at the end, and between slashes.
1500         # also this catches doubled slashes
1501         if ($input =~ m!(^|/)(|\.|\.\.)(/|$)!) {
1502                 return undef;
1503         }
1504         # no null characters
1505         if ($input =~ m!\0!) {
1506                 return undef;
1507         }
1508         return 1;
1509 }
1510
1511 sub is_valid_ref_format {
1512         my $input = shift;
1513
1514         return undef unless defined $input;
1515         # restrictions on ref name according to git-check-ref-format
1516         if ($input =~ m!(/\.|\.\.|[\000-\040\177 ~^:?*\[]|/$)!) {
1517                 return undef;
1518         }
1519         return 1;
1520 }
1521
1522 sub is_valid_refname {
1523         my $input = shift;
1524
1525         return undef unless defined $input;
1526         # textual hashes are O.K.
1527         if ($input =~ m/^[0-9a-fA-F]{40}$/) {
1528                 return 1;
1529         }
1530         # it must be correct pathname
1531         is_valid_pathname($input) or return undef;
1532         # check git-check-ref-format restrictions
1533         is_valid_ref_format($input) or return undef;
1534         return 1;
1535 }
1536
1537 # decode sequences of octets in utf8 into Perl's internal form,
1538 # which is utf-8 with utf8 flag set if needed.  gitweb writes out
1539 # in utf-8 thanks to "binmode STDOUT, ':utf8'" at beginning
1540 sub to_utf8 {
1541         my $str = shift;
1542         return undef unless defined $str;
1543
1544         if (utf8::is_utf8($str) || utf8::decode($str)) {
1545                 return $str;
1546         } else {
1547                 return decode($fallback_encoding, $str, Encode::FB_DEFAULT);
1548         }
1549 }
1550
1551 # quote unsafe chars, but keep the slash, even when it's not
1552 # correct, but quoted slashes look too horrible in bookmarks
1553 sub esc_param {
1554         my $str = shift;
1555         return undef unless defined $str;
1556         $str =~ s/([^A-Za-z0-9\-_.~()\/:@ ]+)/CGI::escape($1)/eg;
1557         $str =~ s/ /\+/g;
1558         return $str;
1559 }
1560
1561 # the quoting rules for path_info fragment are slightly different
1562 sub esc_path_info {
1563         my $str = shift;
1564         return undef unless defined $str;
1565
1566         # path_info doesn't treat '+' as space (specially), but '?' must be escaped
1567         $str =~ s/([^A-Za-z0-9\-_.~();\/;:@&= +]+)/CGI::escape($1)/eg;
1568
1569         return $str;
1570 }
1571
1572 # quote unsafe chars in whole URL, so some characters cannot be quoted
1573 sub esc_url {
1574         my $str = shift;
1575         return undef unless defined $str;
1576         $str =~ s/([^A-Za-z0-9\-_.~();\/;?:@&= ]+)/CGI::escape($1)/eg;
1577         $str =~ s/ /\+/g;
1578         return $str;
1579 }
1580
1581 # quote unsafe characters in HTML attributes
1582 sub esc_attr {
1583
1584         # for XHTML conformance escaping '"' to '&quot;' is not enough
1585         return esc_html(@_);
1586 }
1587
1588 # replace invalid utf8 character with SUBSTITUTION sequence
1589 sub esc_html {
1590         my $str = shift;
1591         my %opts = @_;
1592
1593         return undef unless defined $str;
1594
1595         $str = to_utf8($str);
1596         $str = $cgi->escapeHTML($str);
1597         if ($opts{'-nbsp'}) {
1598                 $str =~ s/ /&nbsp;/g;
1599         }
1600         $str =~ s|([[:cntrl:]])|(($1 ne "\t") ? quot_cec($1) : $1)|eg;
1601         return $str;
1602 }
1603
1604 # quote control characters and escape filename to HTML
1605 sub esc_path {
1606         my $str = shift;
1607         my %opts = @_;
1608
1609         return undef unless defined $str;
1610
1611         $str = to_utf8($str);
1612         $str = $cgi->escapeHTML($str);
1613         if ($opts{'-nbsp'}) {
1614                 $str =~ s/ /&nbsp;/g;
1615         }
1616         $str =~ s|([[:cntrl:]])|quot_cec($1)|eg;
1617         return $str;
1618 }
1619
1620 # Sanitize for use in XHTML + application/xml+xhtml (valid XML 1.0)
1621 sub sanitize {
1622         my $str = shift;
1623
1624         return undef unless defined $str;
1625
1626         $str = to_utf8($str);
1627         $str =~ s|([[:cntrl:]])|(index("\t\n\r", $1) != -1 ? $1 : quot_cec($1))|eg;
1628         return $str;
1629 }
1630
1631 # Make control characters "printable", using character escape codes (CEC)
1632 sub quot_cec {
1633         my $cntrl = shift;
1634         my %opts = @_;
1635         my %es = ( # character escape codes, aka escape sequences
1636                 "\t" => '\t',   # tab            (HT)
1637                 "\n" => '\n',   # line feed      (LF)
1638                 "\r" => '\r',   # carrige return (CR)
1639                 "\f" => '\f',   # form feed      (FF)
1640                 "\b" => '\b',   # backspace      (BS)
1641                 "\a" => '\a',   # alarm (bell)   (BEL)
1642                 "\e" => '\e',   # escape         (ESC)
1643                 "\013" => '\v', # vertical tab   (VT)
1644                 "\000" => '\0', # nul character  (NUL)
1645         );
1646         my $chr = ( (exists $es{$cntrl})
1647                     ? $es{$cntrl}
1648                     : sprintf('\%2x', ord($cntrl)) );
1649         if ($opts{-nohtml}) {
1650                 return $chr;
1651         } else {
1652                 return "<span class=\"cntrl\">$chr</span>";
1653         }
1654 }
1655
1656 # Alternatively use unicode control pictures codepoints,
1657 # Unicode "printable representation" (PR)
1658 sub quot_upr {
1659         my $cntrl = shift;
1660         my %opts = @_;
1661
1662         my $chr = sprintf('&#%04d;', 0x2400+ord($cntrl));
1663         if ($opts{-nohtml}) {
1664                 return $chr;
1665         } else {
1666                 return "<span class=\"cntrl\">$chr</span>";
1667         }
1668 }
1669
1670 # git may return quoted and escaped filenames
1671 sub unquote {
1672         my $str = shift;
1673
1674         sub unq {
1675                 my $seq = shift;
1676                 my %es = ( # character escape codes, aka escape sequences
1677                         't' => "\t",   # tab            (HT, TAB)
1678                         'n' => "\n",   # newline        (NL)
1679                         'r' => "\r",   # return         (CR)
1680                         'f' => "\f",   # form feed      (FF)
1681                         'b' => "\b",   # backspace      (BS)
1682                         'a' => "\a",   # alarm (bell)   (BEL)
1683                         'e' => "\e",   # escape         (ESC)
1684                         'v' => "\013", # vertical tab   (VT)
1685                 );
1686
1687                 if ($seq =~ m/^[0-7]{1,3}$/) {
1688                         # octal char sequence
1689                         return chr(oct($seq));
1690                 } elsif (exists $es{$seq}) {
1691                         # C escape sequence, aka character escape code
1692                         return $es{$seq};
1693                 }
1694                 # quoted ordinary character
1695                 return $seq;
1696         }
1697
1698         if ($str =~ m/^"(.*)"$/) {
1699                 # needs unquoting
1700                 $str = $1;
1701                 $str =~ s/\\([^0-7]|[0-7]{1,3})/unq($1)/eg;
1702         }
1703         return $str;
1704 }
1705
1706 # escape tabs (convert tabs to spaces)
1707 sub untabify {
1708         my $line = shift;
1709
1710         while ((my $pos = index($line, "\t")) != -1) {
1711                 if (my $count = (8 - ($pos % 8))) {
1712                         my $spaces = ' ' x $count;
1713                         $line =~ s/\t/$spaces/;
1714                 }
1715         }
1716
1717         return $line;
1718 }
1719
1720 sub project_in_list {
1721         my $project = shift;
1722         my @list = git_get_projects_list();
1723         return @list && scalar(grep { $_->{'path'} eq $project } @list);
1724 }
1725
1726 ## ----------------------------------------------------------------------
1727 ## HTML aware string manipulation
1728
1729 # Try to chop given string on a word boundary between position
1730 # $len and $len+$add_len. If there is no word boundary there,
1731 # chop at $len+$add_len. Do not chop if chopped part plus ellipsis
1732 # (marking chopped part) would be longer than given string.
1733 sub chop_str {
1734         my $str = shift;
1735         my $len = shift;
1736         my $add_len = shift || 10;
1737         my $where = shift || 'right'; # 'left' | 'center' | 'right'
1738
1739         # Make sure perl knows it is utf8 encoded so we don't
1740         # cut in the middle of a utf8 multibyte char.
1741         $str = to_utf8($str);
1742
1743         # allow only $len chars, but don't cut a word if it would fit in $add_len
1744         # if it doesn't fit, cut it if it's still longer than the dots we would add
1745         # remove chopped character entities entirely
1746
1747         # when chopping in the middle, distribute $len into left and right part
1748         # return early if chopping wouldn't make string shorter
1749         if ($where eq 'center') {
1750                 return $str if ($len + 5 >= length($str)); # filler is length 5
1751                 $len = int($len/2);
1752         } else {
1753                 return $str if ($len + 4 >= length($str)); # filler is length 4
1754         }
1755
1756         # regexps: ending and beginning with word part up to $add_len
1757         my $endre = qr/.{$len}\w{0,$add_len}/;
1758         my $begre = qr/\w{0,$add_len}.{$len}/;
1759
1760         if ($where eq 'left') {
1761                 $str =~ m/^(.*?)($begre)$/;
1762                 my ($lead, $body) = ($1, $2);
1763                 if (length($lead) > 4) {
1764                         $lead = " ...";
1765                 }
1766                 return "$lead$body";
1767
1768         } elsif ($where eq 'center') {
1769                 $str =~ m/^($endre)(.*)$/;
1770                 my ($left, $str)  = ($1, $2);
1771                 $str =~ m/^(.*?)($begre)$/;
1772                 my ($mid, $right) = ($1, $2);
1773                 if (length($mid) > 5) {
1774                         $mid = " ... ";
1775                 }
1776                 return "$left$mid$right";
1777
1778         } else {
1779                 $str =~ m/^($endre)(.*)$/;
1780                 my $body = $1;
1781                 my $tail = $2;
1782                 if (length($tail) > 4) {
1783                         $tail = "... ";
1784                 }
1785                 return "$body$tail";
1786         }
1787 }
1788
1789 # takes the same arguments as chop_str, but also wraps a <span> around the
1790 # result with a title attribute if it does get chopped. Additionally, the
1791 # string is HTML-escaped.
1792 sub chop_and_escape_str {
1793         my ($str) = @_;
1794
1795         my $chopped = chop_str(@_);
1796         $str = to_utf8($str);
1797         if ($chopped eq $str) {
1798                 return esc_html($chopped);
1799         } else {
1800                 $str =~ s/[[:cntrl:]]/?/g;
1801                 return $cgi->span({-title=>$str}, esc_html($chopped));
1802         }
1803 }
1804
1805 # Highlight selected fragments of string, using given CSS class,
1806 # and escape HTML.  It is assumed that fragments do not overlap.
1807 # Regions are passed as list of pairs (array references).
1808 #
1809 # Example: esc_html_hl_regions("foobar", "mark", [ 0, 3 ]) returns
1810 # '<span class="mark">foo</span>bar'
1811 sub esc_html_hl_regions {
1812         my ($str, $css_class, @sel) = @_;
1813         my %opts = grep { ref($_) ne 'ARRAY' } @sel;
1814         @sel     = grep { ref($_) eq 'ARRAY' } @sel;
1815         return esc_html($str, %opts) unless @sel;
1816
1817         my $out = '';
1818         my $pos = 0;
1819
1820         for my $s (@sel) {
1821                 my ($begin, $end) = @$s;
1822
1823                 # Don't create empty <span> elements.
1824                 next if $end <= $begin;
1825
1826                 my $escaped = esc_html(substr($str, $begin, $end - $begin),
1827                                        %opts);
1828
1829                 $out .= esc_html(substr($str, $pos, $begin - $pos), %opts)
1830                         if ($begin - $pos > 0);
1831                 $out .= $cgi->span({-class => $css_class}, $escaped);
1832
1833                 $pos = $end;
1834         }
1835         $out .= esc_html(substr($str, $pos), %opts)
1836                 if ($pos < length($str));
1837
1838         return $out;
1839 }
1840
1841 # return positions of beginning and end of each match
1842 sub matchpos_list {
1843         my ($str, $regexp) = @_;
1844         return unless (defined $str && defined $regexp);
1845
1846         my @matches;
1847         while ($str =~ /$regexp/g) {
1848                 push @matches, [$-[0], $+[0]];
1849         }
1850         return @matches;
1851 }
1852
1853 # highlight match (if any), and escape HTML
1854 sub esc_html_match_hl {
1855         my ($str, $regexp) = @_;
1856         return esc_html($str) unless defined $regexp;
1857
1858         my @matches = matchpos_list($str, $regexp);
1859         return esc_html($str) unless @matches;
1860
1861         return esc_html_hl_regions($str, 'match', @matches);
1862 }
1863
1864
1865 # highlight match (if any) of shortened string, and escape HTML
1866 sub esc_html_match_hl_chopped {
1867         my ($str, $chopped, $regexp) = @_;
1868         return esc_html_match_hl($str, $regexp) unless defined $chopped;
1869
1870         my @matches = matchpos_list($str, $regexp);
1871         return esc_html($chopped) unless @matches;
1872
1873         # filter matches so that we mark chopped string
1874         my $tail = "... "; # see chop_str
1875         unless ($chopped =~ s/\Q$tail\E$//) {
1876                 $tail = '';
1877         }
1878         my $chop_len = length($chopped);
1879         my $tail_len = length($tail);
1880         my @filtered;
1881
1882         for my $m (@matches) {
1883                 if ($m->[0] > $chop_len) {
1884                         push @filtered, [ $chop_len, $chop_len + $tail_len ] if ($tail_len > 0);
1885                         last;
1886                 } elsif ($m->[1] > $chop_len) {
1887                         push @filtered, [ $m->[0], $chop_len + $tail_len ];
1888                         last;
1889                 }
1890                 push @filtered, $m;
1891         }
1892
1893         return esc_html_hl_regions($chopped . $tail, 'match', @filtered);
1894 }
1895
1896 ## ----------------------------------------------------------------------
1897 ## functions returning short strings
1898
1899 # CSS class for given age value (in seconds)
1900 sub age_class {
1901         my $age = shift;
1902
1903         if (!defined $age) {
1904                 return "noage";
1905         } elsif ($age < 60*60*2) {
1906                 return "age0";
1907         } elsif ($age < 60*60*24*2) {
1908                 return "age1";
1909         } else {
1910                 return "age2";
1911         }
1912 }
1913
1914 # convert age in seconds to "nn units ago" string
1915 sub age_string {
1916         my $age = shift;
1917         my $age_str;
1918
1919         if ($age > 60*60*24*365*2) {
1920                 $age_str = (int $age/60/60/24/365);
1921                 $age_str .= " years ago";
1922         } elsif ($age > 60*60*24*(365/12)*2) {
1923                 $age_str = int $age/60/60/24/(365/12);
1924                 $age_str .= " months ago";
1925         } elsif ($age > 60*60*24*7*2) {
1926                 $age_str = int $age/60/60/24/7;
1927                 $age_str .= " weeks ago";
1928         } elsif ($age > 60*60*24*2) {
1929                 $age_str = int $age/60/60/24;
1930                 $age_str .= " days ago";
1931         } elsif ($age > 60*60*2) {
1932                 $age_str = int $age/60/60;
1933                 $age_str .= " hours ago";
1934         } elsif ($age > 60*2) {
1935                 $age_str = int $age/60;
1936                 $age_str .= " min ago";
1937         } elsif ($age > 2) {
1938                 $age_str = int $age;
1939                 $age_str .= " sec ago";
1940         } else {
1941                 $age_str .= " right now";
1942         }
1943         return $age_str;
1944 }
1945
1946 use constant {
1947         S_IFINVALID => 0030000,
1948         S_IFGITLINK => 0160000,
1949 };
1950
1951 # submodule/subproject, a commit object reference
1952 sub S_ISGITLINK {
1953         my $mode = shift;
1954
1955         return (($mode & S_IFMT) == S_IFGITLINK)
1956 }
1957
1958 # convert file mode in octal to symbolic file mode string
1959 sub mode_str {
1960         my $mode = oct shift;
1961
1962         if (S_ISGITLINK($mode)) {
1963                 return 'm---------';
1964         } elsif (S_ISDIR($mode & S_IFMT)) {
1965                 return 'drwxr-xr-x';
1966         } elsif (S_ISLNK($mode)) {
1967                 return 'lrwxrwxrwx';
1968         } elsif (S_ISREG($mode)) {
1969                 # git cares only about the executable bit
1970                 if ($mode & S_IXUSR) {
1971                         return '-rwxr-xr-x';
1972                 } else {
1973                         return '-rw-r--r--';
1974                 };
1975         } else {
1976                 return '----------';
1977         }
1978 }
1979
1980 # convert file mode in octal to file type string
1981 sub file_type {
1982         my $mode = shift;
1983
1984         if ($mode !~ m/^[0-7]+$/) {
1985                 return $mode;
1986         } else {
1987                 $mode = oct $mode;
1988         }
1989
1990         if (S_ISGITLINK($mode)) {
1991                 return "submodule";
1992         } elsif (S_ISDIR($mode & S_IFMT)) {
1993                 return "directory";
1994         } elsif (S_ISLNK($mode)) {
1995                 return "symlink";
1996         } elsif (S_ISREG($mode)) {
1997                 return "file";
1998         } else {
1999                 return "unknown";
2000         }
2001 }
2002
2003 # convert file mode in octal to file type description string
2004 sub file_type_long {
2005         my $mode = shift;
2006
2007         if ($mode !~ m/^[0-7]+$/) {
2008                 return $mode;
2009         } else {
2010                 $mode = oct $mode;
2011         }
2012
2013         if (S_ISGITLINK($mode)) {
2014                 return "submodule";
2015         } elsif (S_ISDIR($mode & S_IFMT)) {
2016                 return "directory";
2017         } elsif (S_ISLNK($mode)) {
2018                 return "symlink";
2019         } elsif (S_ISREG($mode)) {
2020                 if ($mode & S_IXUSR) {
2021                         return "executable";
2022                 } else {
2023                         return "file";
2024                 };
2025         } else {
2026                 return "unknown";
2027         }
2028 }
2029
2030
2031 ## ----------------------------------------------------------------------
2032 ## functions returning short HTML fragments, or transforming HTML fragments
2033 ## which don't belong to other sections
2034
2035 # format line of commit message.
2036 sub format_log_line_html {
2037         my $line = shift;
2038
2039         $line = esc_html($line, -nbsp=>1);
2040         $line =~ s{\b([0-9a-fA-F]{7,40})\b}{
2041                 $cgi->a({-href => href(action=>"object", hash=>$1),
2042                                         -class => "text"}, $1);
2043         }eg;
2044
2045         return $line;
2046 }
2047
2048 # format marker of refs pointing to given object
2049
2050 # the destination action is chosen based on object type and current context:
2051 # - for annotated tags, we choose the tag view unless it's the current view
2052 #   already, in which case we go to shortlog view
2053 # - for other refs, we keep the current view if we're in history, shortlog or
2054 #   log view, and select shortlog otherwise
2055 sub format_ref_marker {
2056         my ($refs, $id) = @_;
2057         my $markers = '';
2058
2059         if (defined $refs->{$id}) {
2060                 foreach my $ref (@{$refs->{$id}}) {
2061                         # this code exploits the fact that non-lightweight tags are the
2062                         # only indirect objects, and that they are the only objects for which
2063                         # we want to use tag instead of shortlog as action
2064                         my ($type, $name) = qw();
2065                         my $indirect = ($ref =~ s/\^\{\}$//);
2066                         # e.g. tags/v2.6.11 or heads/next
2067                         if ($ref =~ m!^(.*?)s?/(.*)$!) {
2068                                 $type = $1;
2069                                 $name = $2;
2070                         } else {
2071                                 $type = "ref";
2072                                 $name = $ref;
2073                         }
2074
2075                         my $class = $type;
2076                         $class .= " indirect" if $indirect;
2077
2078                         my $dest_action = "shortlog";
2079
2080                         if ($indirect) {
2081                                 $dest_action = "tag" unless $action eq "tag";
2082                         } elsif ($action =~ /^(history|(short)?log)$/) {
2083                                 $dest_action = $action;
2084                         }
2085
2086                         my $dest = "";
2087                         $dest .= "refs/" unless $ref =~ m!^refs/!;
2088                         $dest .= $ref;
2089
2090                         my $link = $cgi->a({
2091                                 -href => href(
2092                                         action=>$dest_action,
2093                                         hash=>$dest
2094                                 )}, esc_html($name));
2095
2096                         $markers .= " <span class=\"".esc_attr($class)."\" title=\"".esc_attr($ref)."\">" .
2097                                 $link . "</span>";
2098                 }
2099         }
2100
2101         if ($markers) {
2102                 return ' <span class="refs">'. $markers . '</span>';
2103         } else {
2104                 return "";
2105         }
2106 }
2107
2108 # format, perhaps shortened and with markers, title line
2109 sub format_subject_html {
2110         my ($long, $short, $href, $extra) = @_;
2111         $extra = '' unless defined($extra);
2112
2113         if (length($short) < length($long)) {
2114                 $long =~ s/[[:cntrl:]]/?/g;
2115                 return $cgi->a({-href => $href, -class => "list subject",
2116                                 -title => to_utf8($long)},
2117                        esc_html($short)) . $extra;
2118         } else {
2119                 return $cgi->a({-href => $href, -class => "list subject"},
2120                        esc_html($long)) . $extra;
2121         }
2122 }
2123
2124 # Rather than recomputing the url for an email multiple times, we cache it
2125 # after the first hit. This gives a visible benefit in views where the avatar
2126 # for the same email is used repeatedly (e.g. shortlog).
2127 # The cache is shared by all avatar engines (currently gravatar only), which
2128 # are free to use it as preferred. Since only one avatar engine is used for any
2129 # given page, there's no risk for cache conflicts.
2130 our %avatar_cache = ();
2131
2132 # Compute the picon url for a given email, by using the picon search service over at
2133 # http://www.cs.indiana.edu/picons/search.html
2134 sub picon_url {
2135         my $email = lc shift;
2136         if (!$avatar_cache{$email}) {
2137                 my ($user, $domain) = split('@', $email);
2138                 $avatar_cache{$email} =
2139                         "//www.cs.indiana.edu/cgi-pub/kinzler/piconsearch.cgi/" .
2140                         "$domain/$user/" .
2141                         "users+domains+unknown/up/single";
2142         }
2143         return $avatar_cache{$email};
2144 }
2145
2146 # Compute the gravatar url for a given email, if it's not in the cache already.
2147 # Gravatar stores only the part of the URL before the size, since that's the
2148 # one computationally more expensive. This also allows reuse of the cache for
2149 # different sizes (for this particular engine).
2150 sub gravatar_url {
2151         my $email = lc shift;
2152         my $size = shift;
2153         $avatar_cache{$email} ||=
2154                 "//www.gravatar.com/avatar/" .
2155                         Digest::MD5::md5_hex($email) . "?s=";
2156         return $avatar_cache{$email} . $size;
2157 }
2158
2159 # Insert an avatar for the given $email at the given $size if the feature
2160 # is enabled.
2161 sub git_get_avatar {
2162         my ($email, %opts) = @_;
2163         my $pre_white  = ($opts{-pad_before} ? "&nbsp;" : "");
2164         my $post_white = ($opts{-pad_after}  ? "&nbsp;" : "");
2165         $opts{-size} ||= 'default';
2166         my $size = $avatar_size{$opts{-size}} || $avatar_size{'default'};
2167         my $url = "";
2168         if ($git_avatar eq 'gravatar') {
2169                 $url = gravatar_url($email, $size);
2170         } elsif ($git_avatar eq 'picon') {
2171                 $url = picon_url($email);
2172         }
2173         # Other providers can be added by extending the if chain, defining $url
2174         # as needed. If no variant puts something in $url, we assume avatars
2175         # are completely disabled/unavailable.
2176         if ($url) {
2177                 return $pre_white .
2178                        "<img width=\"$size\" " .
2179                             "class=\"avatar\" " .
2180                             "src=\"".esc_url($url)."\" " .
2181                             "alt=\"\" " .
2182                        "/>" . $post_white;
2183         } else {
2184                 return "";
2185         }
2186 }
2187
2188 sub format_search_author {
2189         my ($author, $searchtype, $displaytext) = @_;
2190         my $have_search = gitweb_check_feature('search');
2191
2192         if ($have_search) {
2193                 my $performed = "";
2194                 if ($searchtype eq 'author') {
2195                         $performed = "authored";
2196                 } elsif ($searchtype eq 'committer') {
2197                         $performed = "committed";
2198                 }
2199
2200                 return $cgi->a({-href => href(action=>"search", hash=>$hash,
2201                                 searchtext=>$author,
2202                                 searchtype=>$searchtype), class=>"list",
2203                                 title=>"Search for commits $performed by $author"},
2204                                 $displaytext);
2205
2206         } else {
2207                 return $displaytext;
2208         }
2209 }
2210
2211 # format the author name of the given commit with the given tag
2212 # the author name is chopped and escaped according to the other
2213 # optional parameters (see chop_str).
2214 sub format_author_html {
2215         my $tag = shift;
2216         my $co = shift;
2217         my $author = chop_and_escape_str($co->{'author_name'}, @_);
2218         return "<$tag class=\"author\">" .
2219                format_search_author($co->{'author_name'}, "author",
2220                        git_get_avatar($co->{'author_email'}, -pad_after => 1) .
2221                        $author) .
2222                "</$tag>";
2223 }
2224
2225 # format git diff header line, i.e. "diff --(git|combined|cc) ..."
2226 sub format_git_diff_header_line {
2227         my $line = shift;
2228         my $diffinfo = shift;
2229         my ($from, $to) = @_;
2230
2231         if ($diffinfo->{'nparents'}) {
2232                 # combined diff
2233                 $line =~ s!^(diff (.*?) )"?.*$!$1!;
2234                 if ($to->{'href'}) {
2235                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2236                                          esc_path($to->{'file'}));
2237                 } else { # file was deleted (no href)
2238                         $line .= esc_path($to->{'file'});
2239                 }
2240         } else {
2241                 # "ordinary" diff
2242                 $line =~ s!^(diff (.*?) )"?a/.*$!$1!;
2243                 if ($from->{'href'}) {
2244                         $line .= $cgi->a({-href => $from->{'href'}, -class => "path"},
2245                                          'a/' . esc_path($from->{'file'}));
2246                 } else { # file was added (no href)
2247                         $line .= 'a/' . esc_path($from->{'file'});
2248                 }
2249                 $line .= ' ';
2250                 if ($to->{'href'}) {
2251                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2252                                          'b/' . esc_path($to->{'file'}));
2253                 } else { # file was deleted
2254                         $line .= 'b/' . esc_path($to->{'file'});
2255                 }
2256         }
2257
2258         return "<div class=\"diff header\">$line</div>\n";
2259 }
2260
2261 # format extended diff header line, before patch itself
2262 sub format_extended_diff_header_line {
2263         my $line = shift;
2264         my $diffinfo = shift;
2265         my ($from, $to) = @_;
2266
2267         # match <path>
2268         if ($line =~ s!^((copy|rename) from ).*$!$1! && $from->{'href'}) {
2269                 $line .= $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2270                                        esc_path($from->{'file'}));
2271         }
2272         if ($line =~ s!^((copy|rename) to ).*$!$1! && $to->{'href'}) {
2273                 $line .= $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2274                                  esc_path($to->{'file'}));
2275         }
2276         # match single <mode>
2277         if ($line =~ m/\s(\d{6})$/) {
2278                 $line .= '<span class="info"> (' .
2279                          file_type_long($1) .
2280                          ')</span>';
2281         }
2282         # match <hash>
2283         if ($line =~ m/^index [0-9a-fA-F]{40},[0-9a-fA-F]{40}/) {
2284                 # can match only for combined diff
2285                 $line = 'index ';
2286                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2287                         if ($from->{'href'}[$i]) {
2288                                 $line .= $cgi->a({-href=>$from->{'href'}[$i],
2289                                                   -class=>"hash"},
2290                                                  substr($diffinfo->{'from_id'}[$i],0,7));
2291                         } else {
2292                                 $line .= '0' x 7;
2293                         }
2294                         # separator
2295                         $line .= ',' if ($i < $diffinfo->{'nparents'} - 1);
2296                 }
2297                 $line .= '..';
2298                 if ($to->{'href'}) {
2299                         $line .= $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2300                                          substr($diffinfo->{'to_id'},0,7));
2301                 } else {
2302                         $line .= '0' x 7;
2303                 }
2304
2305         } elsif ($line =~ m/^index [0-9a-fA-F]{40}..[0-9a-fA-F]{40}/) {
2306                 # can match only for ordinary diff
2307                 my ($from_link, $to_link);
2308                 if ($from->{'href'}) {
2309                         $from_link = $cgi->a({-href=>$from->{'href'}, -class=>"hash"},
2310                                              substr($diffinfo->{'from_id'},0,7));
2311                 } else {
2312                         $from_link = '0' x 7;
2313                 }
2314                 if ($to->{'href'}) {
2315                         $to_link = $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2316                                            substr($diffinfo->{'to_id'},0,7));
2317                 } else {
2318                         $to_link = '0' x 7;
2319                 }
2320                 my ($from_id, $to_id) = ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
2321                 $line =~ s!$from_id\.\.$to_id!$from_link..$to_link!;
2322         }
2323
2324         return $line . "<br/>\n";
2325 }
2326
2327 # format from-file/to-file diff header
2328 sub format_diff_from_to_header {
2329         my ($from_line, $to_line, $diffinfo, $from, $to, @parents) = @_;
2330         my $line;
2331         my $result = '';
2332
2333         $line = $from_line;
2334         #assert($line =~ m/^---/) if DEBUG;
2335         # no extra formatting for "^--- /dev/null"
2336         if (! $diffinfo->{'nparents'}) {
2337                 # ordinary (single parent) diff
2338                 if ($line =~ m!^--- "?a/!) {
2339                         if ($from->{'href'}) {
2340                                 $line = '--- a/' .
2341                                         $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2342                                                 esc_path($from->{'file'}));
2343                         } else {
2344                                 $line = '--- a/' .
2345                                         esc_path($from->{'file'});
2346                         }
2347                 }
2348                 $result .= qq!<div class="diff from_file">$line</div>\n!;
2349
2350         } else {
2351                 # combined diff (merge commit)
2352                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2353                         if ($from->{'href'}[$i]) {
2354                                 $line = '--- ' .
2355                                         $cgi->a({-href=>href(action=>"blobdiff",
2356                                                              hash_parent=>$diffinfo->{'from_id'}[$i],
2357                                                              hash_parent_base=>$parents[$i],
2358                                                              file_parent=>$from->{'file'}[$i],
2359                                                              hash=>$diffinfo->{'to_id'},
2360                                                              hash_base=>$hash,
2361                                                              file_name=>$to->{'file'}),
2362                                                  -class=>"path",
2363                                                  -title=>"diff" . ($i+1)},
2364                                                 $i+1) .
2365                                         '/' .
2366                                         $cgi->a({-href=>$from->{'href'}[$i], -class=>"path"},
2367                                                 esc_path($from->{'file'}[$i]));
2368                         } else {
2369                                 $line = '--- /dev/null';
2370                         }
2371                         $result .= qq!<div class="diff from_file">$line</div>\n!;
2372                 }
2373         }
2374
2375         $line = $to_line;
2376         #assert($line =~ m/^\+\+\+/) if DEBUG;
2377         # no extra formatting for "^+++ /dev/null"
2378         if ($line =~ m!^\+\+\+ "?b/!) {
2379                 if ($to->{'href'}) {
2380                         $line = '+++ b/' .
2381                                 $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2382                                         esc_path($to->{'file'}));
2383                 } else {
2384                         $line = '+++ b/' .
2385                                 esc_path($to->{'file'});
2386                 }
2387         }
2388         $result .= qq!<div class="diff to_file">$line</div>\n!;
2389
2390         return $result;
2391 }
2392
2393 # create note for patch simplified by combined diff
2394 sub format_diff_cc_simplified {
2395         my ($diffinfo, @parents) = @_;
2396         my $result = '';
2397
2398         $result .= "<div class=\"diff header\">" .
2399                    "diff --cc ";
2400         if (!is_deleted($diffinfo)) {
2401                 $result .= $cgi->a({-href => href(action=>"blob",
2402                                                   hash_base=>$hash,
2403                                                   hash=>$diffinfo->{'to_id'},
2404                                                   file_name=>$diffinfo->{'to_file'}),
2405                                     -class => "path"},
2406                                    esc_path($diffinfo->{'to_file'}));
2407         } else {
2408                 $result .= esc_path($diffinfo->{'to_file'});
2409         }
2410         $result .= "</div>\n" . # class="diff header"
2411                    "<div class=\"diff nodifferences\">" .
2412                    "Simple merge" .
2413                    "</div>\n"; # class="diff nodifferences"
2414
2415         return $result;
2416 }
2417
2418 sub diff_line_class {
2419         my ($line, $from, $to) = @_;
2420
2421         # ordinary diff
2422         my $num_sign = 1;
2423         # combined diff
2424         if ($from && $to && ref($from->{'href'}) eq "ARRAY") {
2425                 $num_sign = scalar @{$from->{'href'}};
2426         }
2427
2428         my @diff_line_classifier = (
2429                 { regexp => qr/^\@\@{$num_sign} /, class => "chunk_header"},
2430                 { regexp => qr/^\\/,               class => "incomplete"  },
2431                 { regexp => qr/^ {$num_sign}/,     class => "ctx" },
2432                 # classifier for context must come before classifier add/rem,
2433                 # or we would have to use more complicated regexp, for example
2434                 # qr/(?= {0,$m}\+)[+ ]{$num_sign}/, where $m = $num_sign - 1;
2435                 { regexp => qr/^[+ ]{$num_sign}/,   class => "add" },
2436                 { regexp => qr/^[- ]{$num_sign}/,   class => "rem" },
2437         );
2438         for my $clsfy (@diff_line_classifier) {
2439                 return $clsfy->{'class'}
2440                         if ($line =~ $clsfy->{'regexp'});
2441         }
2442
2443         # fallback
2444         return "";
2445 }
2446
2447 # assumes that $from and $to are defined and correctly filled,
2448 # and that $line holds a line of chunk header for unified diff
2449 sub format_unidiff_chunk_header {
2450         my ($line, $from, $to) = @_;
2451
2452         my ($from_text, $from_start, $from_lines, $to_text, $to_start, $to_lines, $section) =
2453                 $line =~ m/^\@{2} (-(\d+)(?:,(\d+))?) (\+(\d+)(?:,(\d+))?) \@{2}(.*)$/;
2454
2455         $from_lines = 0 unless defined $from_lines;
2456         $to_lines   = 0 unless defined $to_lines;
2457
2458         if ($from->{'href'}) {
2459                 $from_text = $cgi->a({-href=>"$from->{'href'}#l$from_start",
2460                                      -class=>"list"}, $from_text);
2461         }
2462         if ($to->{'href'}) {
2463                 $to_text   = $cgi->a({-href=>"$to->{'href'}#l$to_start",
2464                                      -class=>"list"}, $to_text);
2465         }
2466         $line = "<span class=\"chunk_info\">@@ $from_text $to_text @@</span>" .
2467                 "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2468         return $line;
2469 }
2470
2471 # assumes that $from and $to are defined and correctly filled,
2472 # and that $line holds a line of chunk header for combined diff
2473 sub format_cc_diff_chunk_header {
2474         my ($line, $from, $to) = @_;
2475
2476         my ($prefix, $ranges, $section) = $line =~ m/^(\@+) (.*?) \@+(.*)$/;
2477         my (@from_text, @from_start, @from_nlines, $to_text, $to_start, $to_nlines);
2478
2479         @from_text = split(' ', $ranges);
2480         for (my $i = 0; $i < @from_text; ++$i) {
2481                 ($from_start[$i], $from_nlines[$i]) =
2482                         (split(',', substr($from_text[$i], 1)), 0);
2483         }
2484
2485         $to_text   = pop @from_text;
2486         $to_start  = pop @from_start;
2487         $to_nlines = pop @from_nlines;
2488
2489         $line = "<span class=\"chunk_info\">$prefix ";
2490         for (my $i = 0; $i < @from_text; ++$i) {
2491                 if ($from->{'href'}[$i]) {
2492                         $line .= $cgi->a({-href=>"$from->{'href'}[$i]#l$from_start[$i]",
2493                                           -class=>"list"}, $from_text[$i]);
2494                 } else {
2495                         $line .= $from_text[$i];
2496                 }
2497                 $line .= " ";
2498         }
2499         if ($to->{'href'}) {
2500                 $line .= $cgi->a({-href=>"$to->{'href'}#l$to_start",
2501                                   -class=>"list"}, $to_text);
2502         } else {
2503                 $line .= $to_text;
2504         }
2505         $line .= " $prefix</span>" .
2506                  "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2507         return $line;
2508 }
2509
2510 # process patch (diff) line (not to be used for diff headers),
2511 # returning HTML-formatted (but not wrapped) line.
2512 # If the line is passed as a reference, it is treated as HTML and not
2513 # esc_html()'ed.
2514 sub format_diff_line {
2515         my ($line, $diff_class, $from, $to) = @_;
2516
2517         if (ref($line)) {
2518                 $line = $$line;
2519         } else {
2520                 chomp $line;
2521                 $line = untabify($line);
2522
2523                 if ($from && $to && $line =~ m/^\@{2} /) {
2524                         $line = format_unidiff_chunk_header($line, $from, $to);
2525                 } elsif ($from && $to && $line =~ m/^\@{3}/) {
2526                         $line = format_cc_diff_chunk_header($line, $from, $to);
2527                 } else {
2528                         $line = esc_html($line, -nbsp=>1);
2529                 }
2530         }
2531
2532         my $diff_classes = "diff";
2533         $diff_classes .= " $diff_class" if ($diff_class);
2534         $line = "<div class=\"$diff_classes\">$line</div>\n";
2535
2536         return $line;
2537 }
2538
2539 # Generates undef or something like "_snapshot_" or "snapshot (_tbz2_ _zip_)",
2540 # linked.  Pass the hash of the tree/commit to snapshot.
2541 sub format_snapshot_links {
2542         my ($hash) = @_;
2543         my $num_fmts = @snapshot_fmts;
2544         if ($num_fmts > 1) {
2545                 # A parenthesized list of links bearing format names.
2546                 # e.g. "snapshot (_tar.gz_ _zip_)"
2547                 return "snapshot (" . join(' ', map
2548                         $cgi->a({
2549                                 -href => href(
2550                                         action=>"snapshot",
2551                                         hash=>$hash,
2552                                         snapshot_format=>$_
2553                                 )
2554                         }, $known_snapshot_formats{$_}{'display'})
2555                 , @snapshot_fmts) . ")";
2556         } elsif ($num_fmts == 1) {
2557                 # A single "snapshot" link whose tooltip bears the format name.
2558                 # i.e. "_snapshot_"
2559                 my ($fmt) = @snapshot_fmts;
2560                 return
2561                         $cgi->a({
2562                                 -href => href(
2563                                         action=>"snapshot",
2564                                         hash=>$hash,
2565                                         snapshot_format=>$fmt
2566                                 ),
2567                                 -title => "in format: $known_snapshot_formats{$fmt}{'display'}"
2568                         }, "snapshot");
2569         } else { # $num_fmts == 0
2570                 return undef;
2571         }
2572 }
2573
2574 ## ......................................................................
2575 ## functions returning values to be passed, perhaps after some
2576 ## transformation, to other functions; e.g. returning arguments to href()
2577
2578 # returns hash to be passed to href to generate gitweb URL
2579 # in -title key it returns description of link
2580 sub get_feed_info {
2581         my $format = shift || 'Atom';
2582         my %res = (action => lc($format));
2583         my $matched_ref = 0;
2584
2585         # feed links are possible only for project views
2586         return unless (defined $project);
2587         # some views should link to OPML, or to generic project feed,
2588         # or don't have specific feed yet (so they should use generic)
2589         return if (!$action || $action =~ /^(?:tags|heads|forks|tag|search)$/x);
2590
2591         my $branch = undef;
2592         # branches refs uses 'refs/' + $get_branch_refs()[x] + '/' prefix
2593         # (fullname) to differentiate from tag links; this also makes
2594         # possible to detect branch links
2595         for my $ref (get_branch_refs()) {
2596                 if ((defined $hash_base && $hash_base =~ m!^refs/\Q$ref\E/(.*)$!) ||
2597                     (defined $hash      && $hash      =~ m!^refs/\Q$ref\E/(.*)$!)) {
2598                         $branch = $1;
2599                         $matched_ref = $ref;
2600                         last;
2601                 }
2602         }
2603         # find log type for feed description (title)
2604         my $type = 'log';
2605         if (defined $file_name) {
2606                 $type  = "history of $file_name";
2607                 $type .= "/" if ($action eq 'tree');
2608                 $type .= " on '$branch'" if (defined $branch);
2609         } else {
2610                 $type = "log of $branch" if (defined $branch);
2611         }
2612
2613         $res{-title} = $type;
2614         $res{'hash'} = (defined $branch ? "refs/$matched_ref/$branch" : undef);
2615         $res{'file_name'} = $file_name;
2616
2617         return %res;
2618 }
2619
2620 ## ----------------------------------------------------------------------
2621 ## git utility subroutines, invoking git commands
2622
2623 # returns path to the core git executable and the --git-dir parameter as list
2624 sub git_cmd {
2625         $number_of_git_cmds++;
2626         return $GIT, '--git-dir='.$git_dir;
2627 }
2628
2629 # quote the given arguments for passing them to the shell
2630 # quote_command("command", "arg 1", "arg with ' and ! characters")
2631 # => "'command' 'arg 1' 'arg with '\'' and '\!' characters'"
2632 # Try to avoid using this function wherever possible.
2633 sub quote_command {
2634         return join(' ',
2635                 map { my $a = $_; $a =~ s/(['!])/'\\$1'/g; "'$a'" } @_ );
2636 }
2637
2638 # get HEAD ref of given project as hash
2639 sub git_get_head_hash {
2640         return git_get_full_hash(shift, 'HEAD');
2641 }
2642
2643 sub git_get_full_hash {
2644         return git_get_hash(@_);
2645 }
2646
2647 sub git_get_short_hash {
2648         return git_get_hash(@_, '--short=7');
2649 }
2650
2651 sub git_get_hash {
2652         my ($project, $hash, @options) = @_;
2653         my $o_git_dir = $git_dir;
2654         my $retval = undef;
2655         $git_dir = "$projectroot/$project";
2656         if (open my $fd, '-|', git_cmd(), 'rev-parse',
2657             '--verify', '-q', @options, $hash) {
2658                 $retval = <$fd>;
2659                 chomp $retval if defined $retval;
2660                 close $fd;
2661         }
2662         if (defined $o_git_dir) {
2663                 $git_dir = $o_git_dir;
2664         }
2665         return $retval;
2666 }
2667
2668 # get type of given object
2669 sub git_get_type {
2670         my $hash = shift;
2671
2672         open my $fd, "-|", git_cmd(), "cat-file", '-t', $hash or return;
2673         my $type = <$fd>;
2674         close $fd or return;
2675         chomp $type;
2676         return $type;
2677 }
2678
2679 # repository configuration
2680 our $config_file = '';
2681 our %config;
2682
2683 # store multiple values for single key as anonymous array reference
2684 # single values stored directly in the hash, not as [ <value> ]
2685 sub hash_set_multi {
2686         my ($hash, $key, $value) = @_;
2687
2688         if (!exists $hash->{$key}) {
2689                 $hash->{$key} = $value;
2690         } elsif (!ref $hash->{$key}) {
2691                 $hash->{$key} = [ $hash->{$key}, $value ];
2692         } else {
2693                 push @{$hash->{$key}}, $value;
2694         }
2695 }
2696
2697 # return hash of git project configuration
2698 # optionally limited to some section, e.g. 'gitweb'
2699 sub git_parse_project_config {
2700         my $section_regexp = shift;
2701         my %config;
2702
2703         local $/ = "\0";
2704
2705         open my $fh, "-|", git_cmd(), "config", '-z', '-l',
2706                 or return;
2707
2708         while (my $keyval = <$fh>) {
2709                 chomp $keyval;
2710                 my ($key, $value) = split(/\n/, $keyval, 2);
2711
2712                 hash_set_multi(\%config, $key, $value)
2713                         if (!defined $section_regexp || $key =~ /^(?:$section_regexp)\./o);
2714         }
2715         close $fh;
2716
2717         return %config;
2718 }
2719
2720 # convert config value to boolean: 'true' or 'false'
2721 # no value, number > 0, 'true' and 'yes' values are true
2722 # rest of values are treated as false (never as error)
2723 sub config_to_bool {
2724         my $val = shift;
2725
2726         return 1 if !defined $val;             # section.key
2727
2728         # strip leading and trailing whitespace
2729         $val =~ s/^\s+//;
2730         $val =~ s/\s+$//;
2731
2732         return (($val =~ /^\d+$/ && $val) ||   # section.key = 1
2733                 ($val =~ /^(?:true|yes)$/i));  # section.key = true
2734 }
2735
2736 # convert config value to simple decimal number
2737 # an optional value suffix of 'k', 'm', or 'g' will cause the value
2738 # to be multiplied by 1024, 1048576, or 1073741824
2739 sub config_to_int {
2740         my $val = shift;
2741
2742         # strip leading and trailing whitespace
2743         $val =~ s/^\s+//;
2744         $val =~ s/\s+$//;
2745
2746         if (my ($num, $unit) = ($val =~ /^([0-9]*)([kmg])$/i)) {
2747                 $unit = lc($unit);
2748                 # unknown unit is treated as 1
2749                 return $num * ($unit eq 'g' ? 1073741824 :
2750                                $unit eq 'm' ?    1048576 :
2751                                $unit eq 'k' ?       1024 : 1);
2752         }
2753         return $val;
2754 }
2755
2756 # convert config value to array reference, if needed
2757 sub config_to_multi {
2758         my $val = shift;
2759
2760         return ref($val) ? $val : (defined($val) ? [ $val ] : []);
2761 }
2762
2763 sub git_get_project_config {
2764         my ($key, $type) = @_;
2765
2766         return unless defined $git_dir;
2767
2768         # key sanity check
2769         return unless ($key);
2770         # only subsection, if exists, is case sensitive,
2771         # and not lowercased by 'git config -z -l'
2772         if (my ($hi, $mi, $lo) = ($key =~ /^([^.]*)\.(.*)\.([^.]*)$/)) {
2773                 $lo =~ s/_//g;
2774                 $key = join(".", lc($hi), $mi, lc($lo));
2775                 return if ($lo =~ /\W/ || $hi =~ /\W/);
2776         } else {
2777                 $key = lc($key);
2778                 $key =~ s/_//g;
2779                 return if ($key =~ /\W/);
2780         }
2781         $key =~ s/^gitweb\.//;
2782
2783         # type sanity check
2784         if (defined $type) {
2785                 $type =~ s/^--//;
2786                 $type = undef
2787                         unless ($type eq 'bool' || $type eq 'int');
2788         }
2789
2790         # get config
2791         if (!defined $config_file ||
2792             $config_file ne "$git_dir/config") {
2793                 %config = git_parse_project_config('gitweb');
2794                 $config_file = "$git_dir/config";
2795         }
2796
2797         # check if config variable (key) exists
2798         return unless exists $config{"gitweb.$key"};
2799
2800         # ensure given type
2801         if (!defined $type) {
2802                 return $config{"gitweb.$key"};
2803         } elsif ($type eq 'bool') {
2804                 # backward compatibility: 'git config --bool' returns true/false
2805                 return config_to_bool($config{"gitweb.$key"}) ? 'true' : 'false';
2806         } elsif ($type eq 'int') {
2807                 return config_to_int($config{"gitweb.$key"});
2808         }
2809         return $config{"gitweb.$key"};
2810 }
2811
2812 # get hash of given path at given ref
2813 sub git_get_hash_by_path {
2814         my $base = shift;
2815         my $path = shift || return undef;
2816         my $type = shift;
2817
2818         $path =~ s,/+$,,;
2819
2820         open my $fd, "-|", git_cmd(), "ls-tree", $base, "--", $path
2821                 or die_error(500, "Open git-ls-tree failed");
2822         my $line = <$fd>;
2823         close $fd or return undef;
2824
2825         if (!defined $line) {
2826                 # there is no tree or hash given by $path at $base
2827                 return undef;
2828         }
2829
2830         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
2831         $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/;
2832         if (defined $type && $type ne $2) {
2833                 # type doesn't match
2834                 return undef;
2835         }
2836         return $3;
2837 }
2838
2839 # get path of entry with given hash at given tree-ish (ref)
2840 # used to get 'from' filename for combined diff (merge commit) for renames
2841 sub git_get_path_by_hash {
2842         my $base = shift || return;
2843         my $hash = shift || return;
2844
2845         local $/ = "\0";
2846
2847         open my $fd, "-|", git_cmd(), "ls-tree", '-r', '-t', '-z', $base
2848                 or return undef;
2849         while (my $line = <$fd>) {
2850                 chomp $line;
2851
2852                 #'040000 tree 595596a6a9117ddba9fe379b6b012b558bac8423  gitweb'
2853                 #'100644 blob e02e90f0429be0d2a69b76571101f20b8f75530f  gitweb/README'
2854                 if ($line =~ m/(?:[0-9]+) (?:.+) $hash\t(.+)$/) {
2855                         close $fd;
2856                         return $1;
2857                 }
2858         }
2859         close $fd;
2860         return undef;
2861 }
2862
2863 ## ......................................................................
2864 ## git utility functions, directly accessing git repository
2865
2866 # get the value of config variable either from file named as the variable
2867 # itself in the repository ($GIT_DIR/$name file), or from gitweb.$name
2868 # configuration variable in the repository config file.
2869 sub git_get_file_or_project_config {
2870         my ($path, $name) = @_;
2871
2872         $git_dir = "$projectroot/$path";
2873         open my $fd, '<', "$git_dir/$name"
2874                 or return git_get_project_config($name);
2875         my $conf = <$fd>;
2876         close $fd;
2877         if (defined $conf) {
2878                 chomp $conf;
2879         }
2880         return $conf;
2881 }
2882
2883 sub git_get_project_description {
2884         my $path = shift;
2885         return git_get_file_or_project_config($path, 'description');
2886 }
2887
2888 sub git_get_project_category {
2889         my $path = shift;
2890         return git_get_file_or_project_config($path, 'category');
2891 }
2892
2893
2894 # supported formats:
2895 # * $GIT_DIR/ctags/<tagname> file (in 'ctags' subdirectory)
2896 #   - if its contents is a number, use it as tag weight,
2897 #   - otherwise add a tag with weight 1
2898 # * $GIT_DIR/ctags file, each line is a tag (with weight 1)
2899 #   the same value multiple times increases tag weight
2900 # * `gitweb.ctag' multi-valued repo config variable
2901 sub git_get_project_ctags {
2902         my $project = shift;
2903         my $ctags = {};
2904
2905         $git_dir = "$projectroot/$project";
2906         if (opendir my $dh, "$git_dir/ctags") {
2907                 my @files = grep { -f $_ } map { "$git_dir/ctags/$_" } readdir($dh);
2908                 foreach my $tagfile (@files) {
2909                         open my $ct, '<', $tagfile
2910                                 or next;
2911                         my $val = <$ct>;
2912                         chomp $val if $val;
2913                         close $ct;
2914
2915                         (my $ctag = $tagfile) =~ s#.*/##;
2916                         if ($val =~ /^\d+$/) {
2917                                 $ctags->{$ctag} = $val;
2918                         } else {
2919                                 $ctags->{$ctag} = 1;
2920                         }
2921                 }
2922                 closedir $dh;
2923
2924         } elsif (open my $fh, '<', "$git_dir/ctags") {
2925                 while (my $line = <$fh>) {
2926                         chomp $line;
2927                         $ctags->{$line}++ if $line;
2928                 }
2929                 close $fh;
2930
2931         } else {
2932                 my $taglist = config_to_multi(git_get_project_config('ctag'));
2933                 foreach my $tag (@$taglist) {
2934                         $ctags->{$tag}++;
2935                 }
2936         }
2937
2938         return $ctags;
2939 }
2940
2941 # return hash, where keys are content tags ('ctags'),
2942 # and values are sum of weights of given tag in every project
2943 sub git_gather_all_ctags {
2944         my $projects = shift;
2945         my $ctags = {};
2946
2947         foreach my $p (@$projects) {
2948                 foreach my $ct (keys %{$p->{'ctags'}}) {
2949                         $ctags->{$ct} += $p->{'ctags'}->{$ct};
2950                 }
2951         }
2952
2953         return $ctags;
2954 }
2955
2956 sub git_populate_project_tagcloud {
2957         my $ctags = shift;
2958
2959         # First, merge different-cased tags; tags vote on casing
2960         my %ctags_lc;
2961         foreach (keys %$ctags) {
2962                 $ctags_lc{lc $_}->{count} += $ctags->{$_};
2963                 if (not $ctags_lc{lc $_}->{topcount}
2964                     or $ctags_lc{lc $_}->{topcount} < $ctags->{$_}) {
2965                         $ctags_lc{lc $_}->{topcount} = $ctags->{$_};
2966                         $ctags_lc{lc $_}->{topname} = $_;
2967                 }
2968         }
2969
2970         my $cloud;
2971         my $matched = $input_params{'ctag'};
2972         if (eval { require HTML::TagCloud; 1; }) {
2973                 $cloud = HTML::TagCloud->new;
2974                 foreach my $ctag (sort keys %ctags_lc) {
2975                         # Pad the title with spaces so that the cloud looks
2976                         # less crammed.
2977                         my $title = esc_html($ctags_lc{$ctag}->{topname});
2978                         $title =~ s/ /&nbsp;/g;
2979                         $title =~ s/^/&nbsp;/g;
2980                         $title =~ s/$/&nbsp;/g;
2981                         if (defined $matched && $matched eq $ctag) {
2982                                 $title = qq(<span class="match">$title</span>);
2983                         }
2984                         $cloud->add($title, href(project=>undef, ctag=>$ctag),
2985                                     $ctags_lc{$ctag}->{count});
2986                 }
2987         } else {
2988                 $cloud = {};
2989                 foreach my $ctag (keys %ctags_lc) {
2990                         my $title = esc_html($ctags_lc{$ctag}->{topname}, -nbsp=>1);
2991                         if (defined $matched && $matched eq $ctag) {
2992                                 $title = qq(<span class="match">$title</span>);
2993                         }
2994                         $cloud->{$ctag}{count} = $ctags_lc{$ctag}->{count};
2995                         $cloud->{$ctag}{ctag} =
2996                                 $cgi->a({-href=>href(project=>undef, ctag=>$ctag)}, $title);
2997                 }
2998         }
2999         return $cloud;
3000 }
3001
3002 sub git_show_project_tagcloud {
3003         my ($cloud, $count) = @_;
3004         if (ref $cloud eq 'HTML::TagCloud') {
3005                 return $cloud->html_and_css($count);
3006         } else {
3007                 my @tags = sort { $cloud->{$a}->{'count'} <=> $cloud->{$b}->{'count'} } keys %$cloud;
3008                 return
3009                         '<div id="htmltagcloud"'.($project ? '' : ' align="center"').'>' .
3010                         join (', ', map {
3011                                 $cloud->{$_}->{'ctag'}
3012                         } splice(@tags, 0, $count)) .
3013                         '</div>';
3014         }
3015 }
3016
3017 sub git_get_project_url_list {
3018         my $path = shift;
3019
3020         $git_dir = "$projectroot/$path";
3021         open my $fd, '<', "$git_dir/cloneurl"
3022                 or return wantarray ?
3023                 @{ config_to_multi(git_get_project_config('url')) } :
3024                    config_to_multi(git_get_project_config('url'));
3025         my @git_project_url_list = map { chomp; $_ } <$fd>;
3026         close $fd;
3027
3028         return wantarray ? @git_project_url_list : \@git_project_url_list;
3029 }
3030
3031 sub git_get_projects_list {
3032         my $filter = shift || '';
3033         my $paranoid = shift;
3034         my @list;
3035
3036         if (-d $projects_list) {
3037                 # search in directory
3038                 my $dir = $projects_list;
3039                 # remove the trailing "/"
3040                 $dir =~ s!/+$!!;
3041                 my $pfxlen = length("$dir");
3042                 my $pfxdepth = ($dir =~ tr!/!!);
3043                 # when filtering, search only given subdirectory
3044                 if ($filter && !$paranoid) {
3045                         $dir .= "/$filter";
3046                         $dir =~ s!/+$!!;
3047                 }
3048
3049                 File::Find::find({
3050                         follow_fast => 1, # follow symbolic links
3051                         follow_skip => 2, # ignore duplicates
3052                         dangling_symlinks => 0, # ignore dangling symlinks, silently
3053                         wanted => sub {
3054                                 # global variables
3055                                 our $project_maxdepth;
3056                                 our $projectroot;
3057                                 # skip project-list toplevel, if we get it.
3058                                 return if (m!^[/.]$!);
3059                                 # only directories can be git repositories
3060                                 return unless (-d $_);
3061                                 # don't traverse too deep (Find is super slow on os x)
3062                                 # $project_maxdepth excludes depth of $projectroot
3063                                 if (($File::Find::name =~ tr!/!!) - $pfxdepth > $project_maxdepth) {
3064                                         $File::Find::prune = 1;
3065                                         return;
3066                                 }
3067
3068                                 my $path = substr($File::Find::name, $pfxlen + 1);
3069                                 # paranoidly only filter here
3070                                 if ($paranoid && $filter && $path !~ m!^\Q$filter\E/!) {
3071                                         next;
3072                                 }
3073                                 # we check related file in $projectroot
3074                                 if (check_export_ok("$projectroot/$path")) {
3075                                         push @list, { path => $path };
3076                                         $File::Find::prune = 1;
3077                                 }
3078                         },
3079                 }, "$dir");
3080
3081         } elsif (-f $projects_list) {
3082                 # read from file(url-encoded):
3083                 # 'git%2Fgit.git Linus+Torvalds'
3084                 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
3085                 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
3086                 open my $fd, '<', $projects_list or return;
3087         PROJECT:
3088                 while (my $line = <$fd>) {
3089                         chomp $line;
3090                         my ($path, $owner) = split ' ', $line;
3091                         $path = unescape($path);
3092                         $owner = unescape($owner);
3093                         if (!defined $path) {
3094                                 next;
3095                         }
3096                         # if $filter is rpovided, check if $path begins with $filter
3097                         if ($filter && $path !~ m!^\Q$filter\E/!) {
3098                                 next;
3099                         }
3100                         if (check_export_ok("$projectroot/$path")) {
3101                                 my $pr = {
3102                                         path => $path
3103                                 };
3104                                 if ($owner) {
3105                                         $pr->{'owner'} = to_utf8($owner);
3106                                 }
3107                                 push @list, $pr;
3108                         }
3109                 }
3110                 close $fd;
3111         }
3112         return @list;
3113 }
3114
3115 # written with help of Tree::Trie module (Perl Artistic License, GPL compatibile)
3116 # as side effects it sets 'forks' field to list of forks for forked projects
3117 sub filter_forks_from_projects_list {
3118         my $projects = shift;
3119
3120         my %trie; # prefix tree of directories (path components)
3121         # generate trie out of those directories that might contain forks
3122         foreach my $pr (@$projects) {
3123                 my $path = $pr->{'path'};
3124                 $path =~ s/\.git$//;      # forks of 'repo.git' are in 'repo/' directory
3125                 next if ($path =~ m!/$!); # skip non-bare repositories, e.g. 'repo/.git'
3126                 next unless ($path);      # skip '.git' repository: tests, git-instaweb
3127                 next unless (-d "$projectroot/$path"); # containing directory exists
3128                 $pr->{'forks'} = [];      # there can be 0 or more forks of project
3129
3130                 # add to trie
3131                 my @dirs = split('/', $path);
3132                 # walk the trie, until either runs out of components or out of trie
3133                 my $ref = \%trie;
3134                 while (scalar @dirs &&
3135                        exists($ref->{$dirs[0]})) {
3136                         $ref = $ref->{shift @dirs};
3137                 }
3138                 # create rest of trie structure from rest of components
3139                 foreach my $dir (@dirs) {
3140                         $ref = $ref->{$dir} = {};
3141                 }
3142                 # create end marker, store $pr as a data
3143                 $ref->{''} = $pr if (!exists $ref->{''});
3144         }
3145
3146         # filter out forks, by finding shortest prefix match for paths
3147         my @filtered;
3148  PROJECT:
3149         foreach my $pr (@$projects) {
3150                 # trie lookup
3151                 my $ref = \%trie;
3152         DIR:
3153                 foreach my $dir (split('/', $pr->{'path'})) {
3154                         if (exists $ref->{''}) {
3155                                 # found [shortest] prefix, is a fork - skip it
3156                                 push @{$ref->{''}{'forks'}}, $pr;
3157                                 next PROJECT;
3158                         }
3159                         if (!exists $ref->{$dir}) {
3160                                 # not in trie, cannot have prefix, not a fork
3161                                 push @filtered, $pr;
3162                                 next PROJECT;
3163                         }
3164                         # If the dir is there, we just walk one step down the trie.
3165                         $ref = $ref->{$dir};
3166                 }
3167                 # we ran out of trie
3168                 # (shouldn't happen: it's either no match, or end marker)
3169                 push @filtered, $pr;
3170         }
3171
3172         return @filtered;
3173 }
3174
3175 # note: fill_project_list_info must be run first,
3176 # for 'descr_long' and 'ctags' to be filled
3177 sub search_projects_list {
3178         my ($projlist, %opts) = @_;
3179         my $tagfilter  = $opts{'tagfilter'};
3180         my $search_re = $opts{'search_regexp'};
3181
3182         return @$projlist
3183                 unless ($tagfilter || $search_re);
3184
3185         # searching projects require filling to be run before it;
3186         fill_project_list_info($projlist,
3187                                $tagfilter  ? 'ctags' : (),
3188                                $search_re ? ('path', 'descr') : ());
3189         my @projects;
3190  PROJECT:
3191         foreach my $pr (@$projlist) {
3192
3193                 if ($tagfilter) {
3194                         next unless ref($pr->{'ctags'}) eq 'HASH';
3195                         next unless
3196                                 grep { lc($_) eq lc($tagfilter) } keys %{$pr->{'ctags'}};
3197                 }
3198
3199                 if ($search_re) {
3200                         next unless
3201                                 $pr->{'path'} =~ /$search_re/ ||
3202                                 $pr->{'descr_long'} =~ /$search_re/;
3203                 }
3204
3205                 push @projects, $pr;
3206         }
3207
3208         return @projects;
3209 }
3210
3211 our $gitweb_project_owner = undef;
3212 sub git_get_project_list_from_file {
3213
3214         return if (defined $gitweb_project_owner);
3215
3216         $gitweb_project_owner = {};
3217         # read from file (url-encoded):
3218         # 'git%2Fgit.git Linus+Torvalds'
3219         # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
3220         # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
3221         if (-f $projects_list) {
3222                 open(my $fd, '<', $projects_list);
3223                 while (my $line = <$fd>) {
3224                         chomp $line;
3225                         my ($pr, $ow) = split ' ', $line;
3226                         $pr = unescape($pr);
3227                         $ow = unescape($ow);
3228                         $gitweb_project_owner->{$pr} = to_utf8($ow);
3229                 }
3230                 close $fd;
3231         }
3232 }
3233
3234 sub git_get_project_owner {
3235         my $project = shift;
3236         my $owner;
3237
3238         return undef unless $project;
3239         $git_dir = "$projectroot/$project";
3240
3241         if (!defined $gitweb_project_owner) {
3242                 git_get_project_list_from_file();
3243         }
3244
3245         if (exists $gitweb_project_owner->{$project}) {
3246                 $owner = $gitweb_project_owner->{$project};
3247         }
3248         if (!defined $owner){
3249                 $owner = git_get_project_config('owner');
3250         }
3251         if (!defined $owner) {
3252                 $owner = get_file_owner("$git_dir");
3253         }
3254
3255         return $owner;
3256 }
3257
3258 sub git_get_last_activity {
3259         my ($path) = @_;
3260         my $fd;
3261
3262         $git_dir = "$projectroot/$path";
3263         open($fd, "-|", git_cmd(), 'for-each-ref',
3264              '--format=%(committer)',
3265              '--sort=-committerdate',
3266              '--count=1',
3267              map { "refs/$_" } get_branch_refs ()) or return;
3268         my $most_recent = <$fd>;
3269         close $fd or return;
3270         if (defined $most_recent &&
3271             $most_recent =~ / (\d+) [-+][01]\d\d\d$/) {
3272                 my $timestamp = $1;
3273                 my $age = time - $timestamp;
3274                 return ($age, age_string($age));
3275         }
3276         return (undef, undef);
3277 }
3278
3279 # Implementation note: when a single remote is wanted, we cannot use 'git
3280 # remote show -n' because that command always work (assuming it's a remote URL
3281 # if it's not defined), and we cannot use 'git remote show' because that would
3282 # try to make a network roundtrip. So the only way to find if that particular
3283 # remote is defined is to walk the list provided by 'git remote -v' and stop if
3284 # and when we find what we want.
3285 sub git_get_remotes_list {
3286         my $wanted = shift;
3287         my %remotes = ();
3288
3289         open my $fd, '-|' , git_cmd(), 'remote', '-v';
3290         return unless $fd;
3291         while (my $remote = <$fd>) {
3292                 chomp $remote;
3293                 $remote =~ s!\t(.*?)\s+\((\w+)\)$!!;
3294                 next if $wanted and not $remote eq $wanted;
3295                 my ($url, $key) = ($1, $2);
3296
3297                 $remotes{$remote} ||= { 'heads' => () };
3298                 $remotes{$remote}{$key} = $url;
3299         }
3300         close $fd or return;
3301         return wantarray ? %remotes : \%remotes;
3302 }
3303
3304 # Takes a hash of remotes as first parameter and fills it by adding the
3305 # available remote heads for each of the indicated remotes.
3306 sub fill_remote_heads {
3307         my $remotes = shift;
3308         my @heads = map { "remotes/$_" } keys %$remotes;
3309         my @remoteheads = git_get_heads_list(undef, @heads);
3310         foreach my $remote (keys %$remotes) {
3311                 $remotes->{$remote}{'heads'} = [ grep {
3312                         $_->{'name'} =~ s!^$remote/!!
3313                         } @remoteheads ];
3314         }
3315 }
3316
3317 sub git_get_references {
3318         my $type = shift || "";
3319         my %refs;
3320         # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
3321         # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
3322         open my $fd, "-|", git_cmd(), "show-ref", "--dereference",
3323                 ($type ? ("--", "refs/$type") : ()) # use -- <pattern> if $type
3324                 or return;
3325
3326         while (my $line = <$fd>) {
3327                 chomp $line;
3328                 if ($line =~ m!^([0-9a-fA-F]{40})\srefs/($type.*)$!) {
3329                         if (defined $refs{$1}) {
3330                                 push @{$refs{$1}}, $2;
3331                         } else {
3332                                 $refs{$1} = [ $2 ];
3333                         }
3334                 }
3335         }
3336         close $fd or return;
3337         return \%refs;
3338 }
3339
3340 sub git_get_rev_name_tags {
3341         my $hash = shift || return undef;
3342
3343         open my $fd, "-|", git_cmd(), "name-rev", "--tags", $hash
3344                 or return;
3345         my $name_rev = <$fd>;
3346         close $fd;
3347
3348         if ($name_rev =~ m|^$hash tags/(.*)$|) {
3349                 return $1;
3350         } else {
3351                 # catches also '$hash undefined' output
3352                 return undef;
3353         }
3354 }
3355
3356 ## ----------------------------------------------------------------------
3357 ## parse to hash functions
3358
3359 sub parse_date {
3360         my $epoch = shift;
3361         my $tz = shift || "-0000";
3362
3363         my %date;
3364         my @months = ("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec");
3365         my @days = ("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");
3366         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($epoch);
3367         $date{'hour'} = $hour;
3368         $date{'minute'} = $min;
3369         $date{'mday'} = $mday;
3370         $date{'day'} = $days[$wday];
3371         $date{'month'} = $months[$mon];
3372         $date{'rfc2822'}   = sprintf "%s, %d %s %4d %02d:%02d:%02d +0000",
3373                              $days[$wday], $mday, $months[$mon], 1900+$year, $hour ,$min, $sec;
3374         $date{'mday-time'} = sprintf "%d %s %02d:%02d",
3375                              $mday, $months[$mon], $hour ,$min;
3376         $date{'iso-8601'}  = sprintf "%04d-%02d-%02dT%02d:%02d:%02dZ",
3377                              1900+$year, 1+$mon, $mday, $hour ,$min, $sec;
3378
3379         my ($tz_sign, $tz_hour, $tz_min) =
3380                 ($tz =~ m/^([-+])(\d\d)(\d\d)$/);
3381         $tz_sign = ($tz_sign eq '-' ? -1 : +1);
3382         my $local = $epoch + $tz_sign*((($tz_hour*60) + $tz_min)*60);
3383         ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($local);
3384         $date{'hour_local'} = $hour;
3385         $date{'minute_local'} = $min;
3386         $date{'tz_local'} = $tz;
3387         $date{'iso-tz'} = sprintf("%04d-%02d-%02d %02d:%02d:%02d %s",
3388                                   1900+$year, $mon+1, $mday,
3389                                   $hour, $min, $sec, $tz);
3390         return %date;
3391 }
3392
3393 sub parse_tag {
3394         my $tag_id = shift;
3395         my %tag;
3396         my @comment;
3397
3398         open my $fd, "-|", git_cmd(), "cat-file", "tag", $tag_id or return;
3399         $tag{'id'} = $tag_id;
3400         while (my $line = <$fd>) {
3401                 chomp $line;
3402                 if ($line =~ m/^object ([0-9a-fA-F]{40})$/) {
3403                         $tag{'object'} = $1;
3404                 } elsif ($line =~ m/^type (.+)$/) {
3405                         $tag{'type'} = $1;
3406                 } elsif ($line =~ m/^tag (.+)$/) {
3407                         $tag{'name'} = $1;
3408                 } elsif ($line =~ m/^tagger (.*) ([0-9]+) (.*)$/) {
3409                         $tag{'author'} = $1;
3410                         $tag{'author_epoch'} = $2;
3411                         $tag{'author_tz'} = $3;
3412                         if ($tag{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3413                                 $tag{'author_name'}  = $1;
3414                                 $tag{'author_email'} = $2;
3415                         } else {
3416                                 $tag{'author_name'} = $tag{'author'};
3417                         }
3418                 } elsif ($line =~ m/--BEGIN/) {
3419                         push @comment, $line;
3420                         last;
3421                 } elsif ($line eq "") {
3422                         last;
3423                 }
3424         }
3425         push @comment, <$fd>;
3426         $tag{'comment'} = \@comment;
3427         close $fd or return;
3428         if (!defined $tag{'name'}) {
3429                 return
3430         };
3431         return %tag
3432 }
3433
3434 sub parse_commit_text {
3435         my ($commit_text, $withparents) = @_;
3436         my @commit_lines = split '\n', $commit_text;
3437         my %co;
3438
3439         pop @commit_lines; # Remove '\0'
3440
3441         if (! @commit_lines) {
3442                 return;
3443         }
3444
3445         my $header = shift @commit_lines;
3446         if ($header !~ m/^[0-9a-fA-F]{40}/) {
3447                 return;
3448         }
3449         ($co{'id'}, my @parents) = split ' ', $header;
3450         while (my $line = shift @commit_lines) {
3451                 last if $line eq "\n";
3452                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
3453                         $co{'tree'} = $1;
3454                 } elsif ((!defined $withparents) && ($line =~ m/^parent ([0-9a-fA-F]{40})$/)) {
3455                         push @parents, $1;
3456                 } elsif ($line =~ m/^author (.*) ([0-9]+) (.*)$/) {
3457                         $co{'author'} = to_utf8($1);
3458                         $co{'author_epoch'} = $2;
3459                         $co{'author_tz'} = $3;
3460                         if ($co{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3461                                 $co{'author_name'}  = $1;
3462                                 $co{'author_email'} = $2;
3463                         } else {
3464                                 $co{'author_name'} = $co{'author'};
3465                         }
3466                 } elsif ($line =~ m/^committer (.*) ([0-9]+) (.*)$/) {
3467                         $co{'committer'} = to_utf8($1);
3468                         $co{'committer_epoch'} = $2;
3469                         $co{'committer_tz'} = $3;
3470                         if ($co{'committer'} =~ m/^([^<]+) <([^>]*)>/) {
3471                                 $co{'committer_name'}  = $1;
3472                                 $co{'committer_email'} = $2;
3473                         } else {
3474                                 $co{'committer_name'} = $co{'committer'};
3475                         }
3476                 }
3477         }
3478         if (!defined $co{'tree'}) {
3479                 return;
3480         };
3481         $co{'parents'} = \@parents;
3482         $co{'parent'} = $parents[0];
3483
3484         foreach my $title (@commit_lines) {
3485                 $title =~ s/^    //;
3486                 if ($title ne "") {
3487                         $co{'title'} = chop_str($title, 80, 5);
3488                         # remove leading stuff of merges to make the interesting part visible
3489                         if (length($title) > 50) {
3490                                 $title =~ s/^Automatic //;
3491                                 $title =~ s/^merge (of|with) /Merge ... /i;
3492                                 if (length($title) > 50) {
3493                                         $title =~ s/(http|rsync):\/\///;
3494                                 }
3495                                 if (length($title) > 50) {
3496                                         $title =~ s/(master|www|rsync)\.//;
3497                                 }
3498                                 if (length($title) > 50) {
3499                                         $title =~ s/kernel.org:?//;
3500                                 }
3501                                 if (length($title) > 50) {
3502                                         $title =~ s/\/pub\/scm//;
3503                                 }
3504                         }
3505                         $co{'title_short'} = chop_str($title, 50, 5);
3506                         last;
3507                 }
3508         }
3509         if (! defined $co{'title'} || $co{'title'} eq "") {
3510                 $co{'title'} = $co{'title_short'} = '(no commit message)';
3511         }
3512         # remove added spaces
3513         foreach my $line (@commit_lines) {
3514                 $line =~ s/^    //;
3515         }
3516         $co{'comment'} = \@commit_lines;
3517
3518         my $age = time - $co{'committer_epoch'};
3519         $co{'age'} = $age;
3520         $co{'age_string'} = age_string($age);
3521         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($co{'committer_epoch'});
3522         if ($age > 60*60*24*7*2) {
3523                 $co{'age_string_date'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3524                 $co{'age_string_age'} = $co{'age_string'};
3525         } else {
3526                 $co{'age_string_date'} = $co{'age_string'};
3527                 $co{'age_string_age'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3528         }
3529         return %co;
3530 }
3531
3532 sub parse_commit {
3533         my ($commit_id) = @_;
3534         my %co;
3535
3536         local $/ = "\0";
3537
3538         open my $fd, "-|", git_cmd(), "rev-list",
3539                 "--parents",
3540                 "--header",
3541                 "--max-count=1",
3542                 $commit_id,
3543                 "--",
3544                 or die_error(500, "Open git-rev-list failed");
3545         %co = parse_commit_text(<$fd>, 1);
3546         close $fd;
3547
3548         return %co;
3549 }
3550
3551 sub parse_commits {
3552         my ($commit_id, $maxcount, $skip, $filename, @args) = @_;
3553         my @cos;
3554
3555         $maxcount ||= 1;
3556         $skip ||= 0;
3557
3558         local $/ = "\0";
3559
3560         open my $fd, "-|", git_cmd(), "rev-list",
3561                 "--header",
3562                 @args,
3563                 ("--max-count=" . $maxcount),
3564                 ("--skip=" . $skip),
3565                 @extra_options,
3566                 $commit_id,
3567                 "--",
3568                 ($filename ? ($filename) : ())
3569                 or die_error(500, "Open git-rev-list failed");
3570         while (my $line = <$fd>) {
3571                 my %co = parse_commit_text($line);
3572                 push @cos, \%co;
3573         }
3574         close $fd;
3575
3576         return wantarray ? @cos : \@cos;
3577 }
3578
3579 # parse line of git-diff-tree "raw" output
3580 sub parse_difftree_raw_line {
3581         my $line = shift;
3582         my %res;
3583
3584         # ':100644 100644 03b218260e99b78c6df0ed378e59ed9205ccc96d 3b93d5e7cc7f7dd4ebed13a5cc1a4ad976fc94d8 M   ls-files.c'
3585         # ':100644 100644 7f9281985086971d3877aca27704f2aaf9c448ce bc190ebc71bbd923f2b728e505408f5e54bd073a M   rev-tree.c'
3586         if ($line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)([0-9]{0,3})\t(.*)$/) {
3587                 $res{'from_mode'} = $1;
3588                 $res{'to_mode'} = $2;
3589                 $res{'from_id'} = $3;
3590                 $res{'to_id'} = $4;
3591                 $res{'status'} = $5;
3592                 $res{'similarity'} = $6;
3593                 if ($res{'status'} eq 'R' || $res{'status'} eq 'C') { # renamed or copied
3594                         ($res{'from_file'}, $res{'to_file'}) = map { unquote($_) } split("\t", $7);
3595                 } else {
3596                         $res{'from_file'} = $res{'to_file'} = $res{'file'} = unquote($7);
3597                 }
3598         }
3599         # '::100755 100755 100755 60e79ca1b01bc8b057abe17ddab484699a7f5fdb 94067cc5f73388f33722d52ae02f44692bc07490 94067cc5f73388f33722d52ae02f44692bc07490 MR git-gui/git-gui.sh'
3600         # combined diff (for merge commit)
3601         elsif ($line =~ s/^(::+)((?:[0-7]{6} )+)((?:[0-9a-fA-F]{40} )+)([a-zA-Z]+)\t(.*)$//) {
3602                 $res{'nparents'}  = length($1);
3603                 $res{'from_mode'} = [ split(' ', $2) ];
3604                 $res{'to_mode'} = pop @{$res{'from_mode'}};
3605                 $res{'from_id'} = [ split(' ', $3) ];
3606                 $res{'to_id'} = pop @{$res{'from_id'}};
3607                 $res{'status'} = [ split('', $4) ];
3608                 $res{'to_file'} = unquote($5);
3609         }
3610         # 'c512b523472485aef4fff9e57b229d9d243c967f'
3611         elsif ($line =~ m/^([0-9a-fA-F]{40})$/) {
3612                 $res{'commit'} = $1;
3613         }
3614
3615         return wantarray ? %res : \%res;
3616 }
3617
3618 # wrapper: return parsed line of git-diff-tree "raw" output
3619 # (the argument might be raw line, or parsed info)
3620 sub parsed_difftree_line {
3621         my $line_or_ref = shift;
3622
3623         if (ref($line_or_ref) eq "HASH") {
3624                 # pre-parsed (or generated by hand)
3625                 return $line_or_ref;
3626         } else {
3627                 return parse_difftree_raw_line($line_or_ref);
3628         }
3629 }
3630
3631 # parse line of git-ls-tree output
3632 sub parse_ls_tree_line {
3633         my $line = shift;
3634         my %opts = @_;
3635         my %res;
3636
3637         if ($opts{'-l'}) {
3638                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa   16717  panic.c'
3639                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40}) +(-|[0-9]+)\t(.+)$/s;
3640
3641                 $res{'mode'} = $1;
3642                 $res{'type'} = $2;
3643                 $res{'hash'} = $3;
3644                 $res{'size'} = $4;
3645                 if ($opts{'-z'}) {
3646                         $res{'name'} = $5;
3647                 } else {
3648                         $res{'name'} = unquote($5);
3649                 }
3650         } else {
3651                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
3652                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t(.+)$/s;
3653
3654                 $res{'mode'} = $1;
3655                 $res{'type'} = $2;
3656                 $res{'hash'} = $3;
3657                 if ($opts{'-z'}) {
3658                         $res{'name'} = $4;
3659                 } else {
3660                         $res{'name'} = unquote($4);
3661                 }
3662         }
3663
3664         return wantarray ? %res : \%res;
3665 }
3666
3667 # generates _two_ hashes, references to which are passed as 2 and 3 argument
3668 sub parse_from_to_diffinfo {
3669         my ($diffinfo, $from, $to, @parents) = @_;
3670
3671         if ($diffinfo->{'nparents'}) {
3672                 # combined diff
3673                 $from->{'file'} = [];
3674                 $from->{'href'} = [];
3675                 fill_from_file_info($diffinfo, @parents)
3676                         unless exists $diffinfo->{'from_file'};
3677                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
3678                         $from->{'file'}[$i] =
3679                                 defined $diffinfo->{'from_file'}[$i] ?
3680                                         $diffinfo->{'from_file'}[$i] :
3681                                         $diffinfo->{'to_file'};
3682                         if ($diffinfo->{'status'}[$i] ne "A") { # not new (added) file
3683                                 $from->{'href'}[$i] = href(action=>"blob",
3684                                                            hash_base=>$parents[$i],
3685                                                            hash=>$diffinfo->{'from_id'}[$i],
3686                                                            file_name=>$from->{'file'}[$i]);
3687                         } else {
3688                                 $from->{'href'}[$i] = undef;
3689                         }
3690                 }
3691         } else {
3692                 # ordinary (not combined) diff
3693                 $from->{'file'} = $diffinfo->{'from_file'};
3694                 if ($diffinfo->{'status'} ne "A") { # not new (added) file
3695                         $from->{'href'} = href(action=>"blob", hash_base=>$hash_parent,
3696                                                hash=>$diffinfo->{'from_id'},
3697                                                file_name=>$from->{'file'});
3698                 } else {
3699                         delete $from->{'href'};
3700                 }
3701         }
3702
3703         $to->{'file'} = $diffinfo->{'to_file'};
3704         if (!is_deleted($diffinfo)) { # file exists in result
3705                 $to->{'href'} = href(action=>"blob", hash_base=>$hash,
3706                                      hash=>$diffinfo->{'to_id'},
3707                                      file_name=>$to->{'file'});
3708         } else {
3709                 delete $to->{'href'};
3710         }
3711 }
3712
3713 ## ......................................................................
3714 ## parse to array of hashes functions
3715
3716 sub git_get_heads_list {
3717         my ($limit, @classes) = @_;
3718         @classes = get_branch_refs() unless @classes;
3719         my @patterns = map { "refs/$_" } @classes;
3720         my @headslist;
3721
3722         open my $fd, '-|', git_cmd(), 'for-each-ref',
3723                 ($limit ? '--count='.($limit+1) : ()), '--sort=-committerdate',
3724                 '--format=%(objectname) %(refname) %(subject)%00%(committer)',
3725                 @patterns
3726                 or return;
3727         while (my $line = <$fd>) {
3728                 my %ref_item;
3729
3730                 chomp $line;
3731                 my ($refinfo, $committerinfo) = split(/\0/, $line);
3732                 my ($hash, $name, $title) = split(' ', $refinfo, 3);
3733                 my ($committer, $epoch, $tz) =
3734                         ($committerinfo =~ /^(.*) ([0-9]+) (.*)$/);
3735                 $ref_item{'fullname'}  = $name;
3736                 my $strip_refs = join '|', map { quotemeta } get_branch_refs();
3737                 $name =~ s!^refs/($strip_refs|remotes)/!!;
3738                 $ref_item{'name'} = $name;
3739                 # for refs neither in 'heads' nor 'remotes' we want to
3740                 # show their ref dir
3741                 my $ref_dir = (defined $1) ? $1 : '';
3742                 if ($ref_dir ne '' and $ref_dir ne 'heads' and $ref_dir ne 'remotes') {
3743                     $ref_item{'name'} .= ' (' . $ref_dir . ')';
3744                 }
3745
3746                 $ref_item{'id'}    = $hash;
3747                 $ref_item{'title'} = $title || '(no commit message)';
3748                 $ref_item{'epoch'} = $epoch;
3749                 if ($epoch) {
3750                         $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3751                 } else {
3752                         $ref_item{'age'} = "unknown";
3753                 }
3754
3755                 push @headslist, \%ref_item;
3756         }
3757         close $fd;
3758
3759         return wantarray ? @headslist : \@headslist;
3760 }
3761
3762 sub git_get_tags_list {
3763         my $limit = shift;
3764         my @tagslist;
3765
3766         open my $fd, '-|', git_cmd(), 'for-each-ref',
3767                 ($limit ? '--count='.($limit+1) : ()), '--sort=-creatordate',
3768                 '--format=%(objectname) %(objecttype) %(refname) '.
3769                 '%(*objectname) %(*objecttype) %(subject)%00%(creator)',
3770                 'refs/tags'
3771                 or return;
3772         while (my $line = <$fd>) {
3773                 my %ref_item;
3774
3775                 chomp $line;
3776                 my ($refinfo, $creatorinfo) = split(/\0/, $line);
3777                 my ($id, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
3778                 my ($creator, $epoch, $tz) =
3779                         ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
3780                 $ref_item{'fullname'} = $name;
3781                 $name =~ s!^refs/tags/!!;
3782
3783                 $ref_item{'type'} = $type;
3784                 $ref_item{'id'} = $id;
3785                 $ref_item{'name'} = $name;
3786                 if ($type eq "tag") {
3787                         $ref_item{'subject'} = $title;
3788                         $ref_item{'reftype'} = $reftype;
3789                         $ref_item{'refid'}   = $refid;
3790                 } else {
3791                         $ref_item{'reftype'} = $type;
3792                         $ref_item{'refid'}   = $id;
3793                 }
3794
3795                 if ($type eq "tag" || $type eq "commit") {
3796                         $ref_item{'epoch'} = $epoch;
3797                         if ($epoch) {
3798                                 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3799                         } else {
3800                                 $ref_item{'age'} = "unknown";
3801                         }
3802                 }
3803
3804                 push @tagslist, \%ref_item;
3805         }
3806         close $fd;
3807
3808         return wantarray ? @tagslist : \@tagslist;
3809 }
3810
3811 ## ----------------------------------------------------------------------
3812 ## filesystem-related functions
3813
3814 sub get_file_owner {
3815         my $path = shift;
3816
3817         my ($dev, $ino, $mode, $nlink, $st_uid, $st_gid, $rdev, $size) = stat($path);
3818         my ($name, $passwd, $uid, $gid, $quota, $comment, $gcos, $dir, $shell) = getpwuid($st_uid);
3819         if (!defined $gcos) {
3820                 return undef;
3821         }
3822         my $owner = $gcos;
3823         $owner =~ s/[,;].*$//;
3824         return to_utf8($owner);
3825 }
3826
3827 # assume that file exists
3828 sub insert_file {
3829         my $filename = shift;
3830
3831         open my $fd, '<', $filename;
3832         print map { to_utf8($_) } <$fd>;
3833         close $fd;
3834 }
3835
3836 ## ......................................................................
3837 ## mimetype related functions
3838
3839 sub mimetype_guess_file {
3840         my $filename = shift;
3841         my $mimemap = shift;
3842         -r $mimemap or return undef;
3843
3844         my %mimemap;
3845         open(my $mh, '<', $mimemap) or return undef;
3846         while (<$mh>) {
3847                 next if m/^#/; # skip comments
3848                 my ($mimetype, @exts) = split(/\s+/);
3849                 foreach my $ext (@exts) {
3850                         $mimemap{$ext} = $mimetype;
3851                 }
3852         }
3853         close($mh);
3854
3855         $filename =~ /\.([^.]*)$/;
3856         return $mimemap{$1};
3857 }
3858
3859 sub mimetype_guess {
3860         my $filename = shift;
3861         my $mime;
3862         $filename =~ /\./ or return undef;
3863
3864         if ($mimetypes_file) {
3865                 my $file = $mimetypes_file;
3866                 if ($file !~ m!^/!) { # if it is relative path
3867                         # it is relative to project
3868                         $file = "$projectroot/$project/$file";
3869                 }
3870                 $mime = mimetype_guess_file($filename, $file);
3871         }
3872         $mime ||= mimetype_guess_file($filename, '/etc/mime.types');
3873         return $mime;
3874 }
3875
3876 sub blob_mimetype {
3877         my $fd = shift;
3878         my $filename = shift;
3879
3880         if ($filename) {
3881                 my $mime = mimetype_guess($filename);
3882                 $mime and return $mime;
3883         }
3884
3885         # just in case
3886         return $default_blob_plain_mimetype unless $fd;
3887
3888         if (-T $fd) {
3889                 return 'text/plain';
3890         } elsif (! $filename) {
3891                 return 'application/octet-stream';
3892         } elsif ($filename =~ m/\.png$/i) {
3893                 return 'image/png';
3894         } elsif ($filename =~ m/\.gif$/i) {
3895                 return 'image/gif';
3896         } elsif ($filename =~ m/\.jpe?g$/i) {
3897                 return 'image/jpeg';
3898         } else {
3899                 return 'application/octet-stream';
3900         }
3901 }
3902
3903 sub blob_contenttype {
3904         my ($fd, $file_name, $type) = @_;
3905
3906         $type ||= blob_mimetype($fd, $file_name);
3907         if ($type eq 'text/plain' && defined $default_text_plain_charset) {
3908                 $type .= "; charset=$default_text_plain_charset";
3909         }
3910
3911         return $type;
3912 }
3913
3914 # guess file syntax for syntax highlighting; return undef if no highlighting
3915 # the name of syntax can (in the future) depend on syntax highlighter used
3916 sub guess_file_syntax {
3917         my ($highlight, $file_name) = @_;
3918         return undef unless ($highlight && defined $file_name);
3919         my $basename = basename($file_name, '.in');
3920         return $highlight_basename{$basename}
3921                 if exists $highlight_basename{$basename};
3922
3923         $basename =~ /\.([^.]*)$/;
3924         my $ext = $1 or return undef;
3925         return $highlight_ext{$ext}
3926                 if exists $highlight_ext{$ext};
3927
3928         return undef;
3929 }
3930
3931 # run highlighter and return FD of its output,
3932 # or return original FD if no highlighting
3933 sub run_highlighter {
3934         my ($fd, $highlight, $syntax) = @_;
3935         return $fd unless ($highlight);
3936
3937         close $fd;
3938         my $syntax_arg = (defined $syntax) ? "--syntax $syntax" : "--force";
3939         open $fd, quote_command(git_cmd(), "cat-file", "blob", $hash)." | ".
3940                   quote_command($^X, '-CO', '-MEncode=decode,FB_DEFAULT', '-pse',
3941                     '$_ = decode($fe, $_, FB_DEFAULT) if !utf8::decode($_);',
3942                     '--', "-fe=$fallback_encoding")." | ".
3943                   quote_command($highlight_bin).
3944                   " --replace-tabs=8 --fragment $syntax_arg |"
3945                 or die_error(500, "Couldn't open file or run syntax highlighter");
3946         return $fd;
3947 }
3948
3949 ## ======================================================================
3950 ## functions printing HTML: header, footer, error page
3951
3952 sub get_page_title {
3953         my $title = to_utf8($site_name);
3954
3955         unless (defined $project) {
3956                 if (defined $project_filter) {
3957                         $title .= " - projects in '" . esc_path($project_filter) . "'";
3958                 }
3959                 return $title;
3960         }
3961         $title .= " - " . to_utf8($project);
3962
3963         return $title unless (defined $action);
3964         $title .= "/$action"; # $action is US-ASCII (7bit ASCII)
3965
3966         return $title unless (defined $file_name);
3967         $title .= " - " . esc_path($file_name);
3968         if ($action eq "tree" && $file_name !~ m|/$|) {
3969                 $title .= "/";
3970         }
3971
3972         return $title;
3973 }
3974
3975 sub get_content_type_html {
3976         # require explicit support from the UA if we are to send the page as
3977         # 'application/xhtml+xml', otherwise send it as plain old 'text/html'.
3978         # we have to do this because MSIE sometimes globs '*/*', pretending to
3979         # support xhtml+xml but choking when it gets what it asked for.
3980         if (defined $cgi->http('HTTP_ACCEPT') &&
3981             $cgi->http('HTTP_ACCEPT') =~ m/(,|;|\s|^)application\/xhtml\+xml(,|;|\s|$)/ &&
3982             $cgi->Accept('application/xhtml+xml') != 0) {
3983                 return 'application/xhtml+xml';
3984         } else {
3985                 return 'text/html';
3986         }
3987 }
3988
3989 sub print_feed_meta {
3990         if (defined $project) {
3991                 my %href_params = get_feed_info();
3992                 if (!exists $href_params{'-title'}) {
3993                         $href_params{'-title'} = 'log';
3994                 }
3995
3996                 foreach my $format (qw(RSS Atom)) {
3997                         my $type = lc($format);
3998                         my %link_attr = (
3999                                 '-rel' => 'alternate',
4000                                 '-title' => esc_attr("$project - $href_params{'-title'} - $format feed"),
4001                                 '-type' => "application/$type+xml"
4002                         );
4003
4004                         $href_params{'extra_options'} = undef;
4005                         $href_params{'action'} = $type;
4006                         $link_attr{'-href'} = href(%href_params);
4007                         print "<link ".
4008                               "rel=\"$link_attr{'-rel'}\" ".
4009                               "title=\"$link_attr{'-title'}\" ".
4010                               "href=\"$link_attr{'-href'}\" ".
4011                               "type=\"$link_attr{'-type'}\" ".
4012                               "/>\n";
4013
4014                         $href_params{'extra_options'} = '--no-merges';
4015                         $link_attr{'-href'} = href(%href_params);
4016                         $link_attr{'-title'} .= ' (no merges)';
4017                         print "<link ".
4018                               "rel=\"$link_attr{'-rel'}\" ".
4019                               "title=\"$link_attr{'-title'}\" ".
4020                               "href=\"$link_attr{'-href'}\" ".
4021                               "type=\"$link_attr{'-type'}\" ".
4022                               "/>\n";
4023                 }
4024
4025         } else {
4026                 printf('<link rel="alternate" title="%s projects list" '.
4027                        'href="%s" type="text/plain; charset=utf-8" />'."\n",
4028                        esc_attr($site_name), href(project=>undef, action=>"project_index"));
4029                 printf('<link rel="alternate" title="%s projects feeds" '.
4030                        'href="%s" type="text/x-opml" />'."\n",
4031                        esc_attr($site_name), href(project=>undef, action=>"opml"));
4032         }
4033 }
4034
4035 sub print_header_links {
4036         my $status = shift;
4037
4038         # print out each stylesheet that exist, providing backwards capability
4039         # for those people who defined $stylesheet in a config file
4040         if (defined $stylesheet) {
4041                 print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
4042         } else {
4043                 foreach my $stylesheet (@stylesheets) {
4044                         next unless $stylesheet;
4045                         print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
4046                 }
4047         }
4048         print_feed_meta()
4049                 if ($status eq '200 OK');
4050         if (defined $favicon) {
4051                 print qq(<link rel="shortcut icon" href=").esc_url($favicon).qq(" type="image/png" />\n);
4052         }
4053 }
4054
4055 sub print_nav_breadcrumbs_path {
4056         my $dirprefix = undef;
4057         while (my $part = shift) {
4058                 $dirprefix .= "/" if defined $dirprefix;
4059                 $dirprefix .= $part;
4060                 print $cgi->a({-href => href(project => undef,
4061                                              project_filter => $dirprefix,
4062                                              action => "project_list")},
4063                               esc_html($part)) . " / ";
4064         }
4065 }
4066
4067 sub print_nav_breadcrumbs {
4068         my %opts = @_;
4069
4070         for my $crumb (@extra_breadcrumbs, [ $home_link_str => $home_link ]) {
4071                 print $cgi->a({-href => esc_url($crumb->[1])}, $crumb->[0]) . " / ";
4072         }
4073         if (defined $project) {
4074                 my @dirname = split '/', $project;
4075                 my $projectbasename = pop @dirname;
4076                 print_nav_breadcrumbs_path(@dirname);
4077                 print $cgi->a({-href => href(action=>"summary")}, esc_html($projectbasename));
4078                 if (defined $action) {
4079                         my $action_print = $action ;
4080                         if (defined $opts{-action_extra}) {
4081                                 $action_print = $cgi->a({-href => href(action=>$action)},
4082                                         $action);
4083                         }
4084                         print " / $action_print";
4085                 }
4086                 if (defined $opts{-action_extra}) {
4087                         print " / $opts{-action_extra}";
4088                 }
4089                 print "\n";
4090         } elsif (defined $project_filter) {
4091                 print_nav_breadcrumbs_path(split '/', $project_filter);
4092         }
4093 }
4094
4095 sub print_search_form {
4096         if (!defined $searchtext) {
4097                 $searchtext = "";
4098         }
4099         my $search_hash;
4100         if (defined $hash_base) {
4101                 $search_hash = $hash_base;
4102         } elsif (defined $hash) {
4103                 $search_hash = $hash;
4104         } else {
4105                 $search_hash = "HEAD";
4106         }
4107         my $action = $my_uri;
4108         my $use_pathinfo = gitweb_check_feature('pathinfo');
4109         if ($use_pathinfo) {
4110                 $action .= "/".esc_url($project);
4111         }
4112         print $cgi->start_form(-method => "get", -action => $action) .
4113               "<div class=\"search\">\n" .
4114               (!$use_pathinfo &&
4115               $cgi->input({-name=>"p", -value=>$project, -type=>"hidden"}) . "\n") .
4116               $cgi->input({-name=>"a", -value=>"search", -type=>"hidden"}) . "\n" .
4117               $cgi->input({-name=>"h", -value=>$search_hash, -type=>"hidden"}) . "\n" .
4118               $cgi->popup_menu(-name => 'st', -default => 'commit',
4119                                -values => ['commit', 'grep', 'author', 'committer', 'pickaxe']) .
4120               " " . $cgi->a({-href => href(action=>"search_help"),
4121                              -title => "search help" }, "?") . " search:\n",
4122               $cgi->textfield(-name => "s", -value => $searchtext, -override => 1) . "\n" .
4123               "<span title=\"Extended regular expression\">" .
4124               $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
4125                              -checked => $search_use_regexp) .
4126               "</span>" .
4127               "</div>" .
4128               $cgi->end_form() . "\n";
4129 }
4130
4131 sub git_header_html {
4132         my $status = shift || "200 OK";
4133         my $expires = shift;
4134         my %opts = @_;
4135
4136         my $title = get_page_title();
4137         my $content_type = get_content_type_html();
4138         print $cgi->header(-type=>$content_type, -charset => 'utf-8',
4139                            -status=> $status, -expires => $expires)
4140                 unless ($opts{'-no_http_header'});
4141         my $mod_perl_version = $ENV{'MOD_PERL'} ? " $ENV{'MOD_PERL'}" : '';
4142         print <<EOF;
4143 <?xml version="1.0" encoding="utf-8"?>
4144 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
4145 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en-US" lang="en-US">
4146 <!-- git web interface version $version, (C) 2005-2006, Kay Sievers <kay.sievers\@vrfy.org>, Christian Gierke -->
4147 <!-- git core binaries version $git_version -->
4148 <head>
4149 <meta http-equiv="content-type" content="$content_type; charset=utf-8"/>
4150 <meta name="generator" content="gitweb/$version git/$git_version$mod_perl_version"/>
4151 <meta name="robots" content="index, nofollow"/>
4152 <title>$title</title>
4153 EOF
4154         # the stylesheet, favicon etc urls won't work correctly with path_info
4155         # unless we set the appropriate base URL
4156         if ($ENV{'PATH_INFO'}) {
4157                 print "<base href=\"".esc_url($base_url)."\" />\n";
4158         }
4159         print_header_links($status);
4160
4161         if (defined $site_html_head_string) {
4162                 print to_utf8($site_html_head_string);
4163         }
4164
4165         print "</head>\n" .
4166               "<body>\n";
4167
4168         if (defined $site_header && -f $site_header) {
4169                 insert_file($site_header);
4170         }
4171
4172         print "<div class=\"page_header\">\n";
4173         if (defined $logo) {
4174                 print $cgi->a({-href => esc_url($logo_url),
4175                                -title => $logo_label},
4176                               $cgi->img({-src => esc_url($logo),
4177                                          -width => 72, -height => 27,
4178                                          -alt => "git",
4179                                          -class => "logo"}));
4180         }
4181         print_nav_breadcrumbs(%opts);
4182         print "</div>\n";
4183
4184         my $have_search = gitweb_check_feature('search');
4185         if (defined $project && $have_search) {
4186                 print_search_form();
4187         }
4188 }
4189
4190 sub git_footer_html {
4191         my $feed_class = 'rss_logo';
4192
4193         print "<div class=\"page_footer\">\n";
4194         if (defined $project) {
4195                 my $descr = git_get_project_description($project);
4196                 if (defined $descr) {
4197                         print "<div class=\"page_footer_text\">" . esc_html($descr) . "</div>\n";
4198                 }
4199
4200                 my %href_params = get_feed_info();
4201                 if (!%href_params) {
4202                         $feed_class .= ' generic';
4203                 }
4204                 $href_params{'-title'} ||= 'log';
4205
4206                 foreach my $format (qw(RSS Atom)) {
4207                         $href_params{'action'} = lc($format);
4208                         print $cgi->a({-href => href(%href_params),
4209                                       -title => "$href_params{'-title'} $format feed",
4210                                       -class => $feed_class}, $format)."\n";
4211                 }
4212
4213         } else {
4214                 print $cgi->a({-href => href(project=>undef, action=>"opml",
4215                                              project_filter => $project_filter),
4216                               -class => $feed_class}, "OPML") . " ";
4217                 print $cgi->a({-href => href(project=>undef, action=>"project_index",
4218                                              project_filter => $project_filter),
4219                               -class => $feed_class}, "TXT") . "\n";
4220         }
4221         print "</div>\n"; # class="page_footer"
4222
4223         if (defined $t0 && gitweb_check_feature('timed')) {
4224                 print "<div id=\"generating_info\">\n";
4225                 print 'This page took '.
4226                       '<span id="generating_time" class="time_span">'.
4227                       tv_interval($t0, [ gettimeofday() ]).
4228                       ' seconds </span>'.
4229                       ' and '.
4230                       '<span id="generating_cmd">'.
4231                       $number_of_git_cmds.
4232                       '</span> git commands '.
4233                       " to generate.\n";
4234                 print "</div>\n"; # class="page_footer"
4235         }
4236
4237         if (defined $site_footer && -f $site_footer) {
4238                 insert_file($site_footer);
4239         }
4240
4241         print qq!<script type="text/javascript" src="!.esc_url($javascript).qq!"></script>\n!;
4242         if (defined $action &&
4243             $action eq 'blame_incremental') {
4244                 print qq!<script type="text/javascript">\n!.
4245                       qq!startBlame("!. href(action=>"blame_data", -replay=>1) .qq!",\n!.
4246                       qq!           "!. href() .qq!");\n!.
4247                       qq!</script>\n!;
4248         } else {
4249                 my ($jstimezone, $tz_cookie, $datetime_class) =
4250                         gitweb_get_feature('javascript-timezone');
4251
4252                 print qq!<script type="text/javascript">\n!.
4253                       qq!window.onload = function () {\n!;
4254                 if (gitweb_check_feature('javascript-actions')) {
4255                         print qq!       fixLinks();\n!;
4256                 }
4257                 if ($jstimezone && $tz_cookie && $datetime_class) {
4258                         print qq!       var tz_cookie = { name: '$tz_cookie', expires: 14, path: '/' };\n!. # in days
4259                               qq!       onloadTZSetup('$jstimezone', tz_cookie, '$datetime_class');\n!;
4260                 }
4261                 print qq!};\n!.
4262                       qq!</script>\n!;
4263         }
4264
4265         print "</body>\n" .
4266               "</html>";
4267 }
4268
4269 # die_error(<http_status_code>, <error_message>[, <detailed_html_description>])
4270 # Example: die_error(404, 'Hash not found')
4271 # By convention, use the following status codes (as defined in RFC 2616):
4272 # 400: Invalid or missing CGI parameters, or
4273 #      requested object exists but has wrong type.
4274 # 403: Requested feature (like "pickaxe" or "snapshot") not enabled on
4275 #      this server or project.
4276 # 404: Requested object/revision/project doesn't exist.
4277 # 500: The server isn't configured properly, or
4278 #      an internal error occurred (e.g. failed assertions caused by bugs), or
4279 #      an unknown error occurred (e.g. the git binary died unexpectedly).
4280 # 503: The server is currently unavailable (because it is overloaded,
4281 #      or down for maintenance).  Generally, this is a temporary state.
4282 sub die_error {
4283         my $status = shift || 500;
4284         my $error = esc_html(shift) || "Internal Server Error";
4285         my $extra = shift;
4286         my %opts = @_;
4287
4288         my %http_responses = (
4289                 400 => '400 Bad Request',
4290                 403 => '403 Forbidden',
4291                 404 => '404 Not Found',
4292                 500 => '500 Internal Server Error',
4293                 503 => '503 Service Unavailable',
4294         );
4295         git_header_html($http_responses{$status}, undef, %opts);
4296         print <<EOF;
4297 <div class="page_body">
4298 <br /><br />
4299 $status - $error
4300 <br />
4301 EOF
4302         if (defined $extra) {
4303                 print "<hr />\n" .
4304                       "$extra\n";
4305         }
4306         print "</div>\n";
4307
4308         git_footer_html();
4309         goto DONE_GITWEB
4310                 unless ($opts{'-error_handler'});
4311 }
4312
4313 ## ----------------------------------------------------------------------
4314 ## functions printing or outputting HTML: navigation
4315
4316 sub git_print_page_nav {
4317         my ($current, $suppress, $head, $treehead, $treebase, $extra) = @_;
4318         $extra = '' if !defined $extra; # pager or formats
4319
4320         my @navs = qw(summary shortlog log commit commitdiff tree);
4321         if ($suppress) {
4322                 @navs = grep { $_ ne $suppress } @navs;
4323         }
4324
4325         my %arg = map { $_ => {action=>$_} } @navs;
4326         if (defined $head) {
4327                 for (qw(commit commitdiff)) {
4328                         $arg{$_}{'hash'} = $head;
4329                 }
4330                 if ($current =~ m/^(tree | log | shortlog | commit | commitdiff | search)$/x) {
4331                         for (qw(shortlog log)) {
4332                                 $arg{$_}{'hash'} = $head;
4333                         }
4334                 }
4335         }
4336
4337         $arg{'tree'}{'hash'} = $treehead if defined $treehead;
4338         $arg{'tree'}{'hash_base'} = $treebase if defined $treebase;
4339
4340         my @actions = gitweb_get_feature('actions');
4341         my %repl = (
4342                 '%' => '%',
4343                 'n' => $project,         # project name
4344                 'f' => $git_dir,         # project path within filesystem
4345                 'h' => $treehead || '',  # current hash ('h' parameter)
4346                 'b' => $treebase || '',  # hash base ('hb' parameter)
4347         );
4348         while (@actions) {
4349                 my ($label, $link, $pos) = splice(@actions,0,3);
4350                 # insert
4351                 @navs = map { $_ eq $pos ? ($_, $label) : $_ } @navs;
4352                 # munch munch
4353                 $link =~ s/%([%nfhb])/$repl{$1}/g;
4354                 $arg{$label}{'_href'} = $link;
4355         }
4356
4357         print "<div class=\"page_nav\">\n" .
4358                 (join " | ",
4359                  map { $_ eq $current ?
4360                        $_ : $cgi->a({-href => ($arg{$_}{_href} ? $arg{$_}{_href} : href(%{$arg{$_}}))}, "$_")
4361                  } @navs);
4362         print "<br/>\n$extra<br/>\n" .
4363               "</div>\n";
4364 }
4365
4366 # returns a submenu for the nagivation of the refs views (tags, heads,
4367 # remotes) with the current view disabled and the remotes view only
4368 # available if the feature is enabled
4369 sub format_ref_views {
4370         my ($current) = @_;
4371         my @ref_views = qw{tags heads};
4372         push @ref_views, 'remotes' if gitweb_check_feature('remote_heads');
4373         return join " | ", map {
4374                 $_ eq $current ? $_ :
4375                 $cgi->a({-href => href(action=>$_)}, $_)
4376         } @ref_views
4377 }
4378
4379 sub format_paging_nav {
4380         my ($action, $page, $has_next_link) = @_;
4381         my $paging_nav;
4382
4383
4384         if ($page > 0) {
4385                 $paging_nav .=
4386                         $cgi->a({-href => href(-replay=>1, page=>undef)}, "first") .
4387                         " &sdot; " .
4388                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
4389                                  -accesskey => "p", -title => "Alt-p"}, "prev");
4390         } else {
4391                 $paging_nav .= "first &sdot; prev";
4392         }
4393
4394         if ($has_next_link) {
4395                 $paging_nav .= " &sdot; " .
4396                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
4397                                  -accesskey => "n", -title => "Alt-n"}, "next");
4398         } else {
4399                 $paging_nav .= " &sdot; next";
4400         }
4401
4402         return $paging_nav;
4403 }
4404
4405 ## ......................................................................
4406 ## functions printing or outputting HTML: div
4407
4408 sub git_print_header_div {
4409         my ($action, $title, $hash, $hash_base) = @_;
4410         my %args = ();
4411
4412         $args{'action'} = $action;
4413         $args{'hash'} = $hash if $hash;
4414         $args{'hash_base'} = $hash_base if $hash_base;
4415
4416         print "<div class=\"header\">\n" .
4417               $cgi->a({-href => href(%args), -class => "title"},
4418               $title ? $title : $action) .
4419               "\n</div>\n";
4420 }
4421
4422 sub format_repo_url {
4423         my ($name, $url) = @_;
4424         return "<tr class=\"metadata_url\"><td>$name</td><td>$url</td></tr>\n";
4425 }
4426
4427 # Group output by placing it in a DIV element and adding a header.
4428 # Options for start_div() can be provided by passing a hash reference as the
4429 # first parameter to the function.
4430 # Options to git_print_header_div() can be provided by passing an array
4431 # reference. This must follow the options to start_div if they are present.
4432 # The content can be a scalar, which is output as-is, a scalar reference, which
4433 # is output after html escaping, an IO handle passed either as *handle or
4434 # *handle{IO}, or a function reference. In the latter case all following
4435 # parameters will be taken as argument to the content function call.
4436 sub git_print_section {
4437         my ($div_args, $header_args, $content);
4438         my $arg = shift;
4439         if (ref($arg) eq 'HASH') {
4440                 $div_args = $arg;
4441                 $arg = shift;
4442         }
4443         if (ref($arg) eq 'ARRAY') {
4444                 $header_args = $arg;
4445                 $arg = shift;
4446         }
4447         $content = $arg;
4448
4449         print $cgi->start_div($div_args);
4450         git_print_header_div(@$header_args);
4451
4452         if (ref($content) eq 'CODE') {
4453                 $content->(@_);
4454         } elsif (ref($content) eq 'SCALAR') {
4455                 print esc_html($$content);
4456         } elsif (ref($content) eq 'GLOB' or ref($content) eq 'IO::Handle') {
4457                 print <$content>;
4458         } elsif (!ref($content) && defined($content)) {
4459                 print $content;
4460         }
4461
4462         print $cgi->end_div;
4463 }
4464
4465 sub format_timestamp_html {
4466         my $date = shift;
4467         my $strtime = $date->{'rfc2822'};
4468
4469         my (undef, undef, $datetime_class) =
4470                 gitweb_get_feature('javascript-timezone');
4471         if ($datetime_class) {
4472                 $strtime = qq!<span class="$datetime_class">$strtime</span>!;
4473         }
4474
4475         my $localtime_format = '(%02d:%02d %s)';
4476         if ($date->{'hour_local'} < 6) {
4477                 $localtime_format = '(<span class="atnight">%02d:%02d</span> %s)';
4478         }
4479         $strtime .= ' ' .
4480                     sprintf($localtime_format,
4481                             $date->{'hour_local'}, $date->{'minute_local'}, $date->{'tz_local'});
4482
4483         return $strtime;
4484 }
4485
4486 # Outputs the author name and date in long form
4487 sub git_print_authorship {
4488         my $co = shift;
4489         my %opts = @_;
4490         my $tag = $opts{-tag} || 'div';
4491         my $author = $co->{'author_name'};
4492
4493         my %ad = parse_date($co->{'author_epoch'}, $co->{'author_tz'});
4494         print "<$tag class=\"author_date\">" .
4495               format_search_author($author, "author", esc_html($author)) .
4496               " [".format_timestamp_html(\%ad)."]".
4497               git_get_avatar($co->{'author_email'}, -pad_before => 1) .
4498               "</$tag>\n";
4499 }
4500
4501 # Outputs table rows containing the full author or committer information,
4502 # in the format expected for 'commit' view (& similar).
4503 # Parameters are a commit hash reference, followed by the list of people
4504 # to output information for. If the list is empty it defaults to both
4505 # author and committer.
4506 sub git_print_authorship_rows {
4507         my $co = shift;
4508         # too bad we can't use @people = @_ || ('author', 'committer')
4509         my @people = @_;
4510         @people = ('author', 'committer') unless @people;
4511         foreach my $who (@people) {
4512                 my %wd = parse_date($co->{"${who}_epoch"}, $co->{"${who}_tz"});
4513                 print "<tr><td>$who</td><td>" .
4514                       format_search_author($co->{"${who}_name"}, $who,
4515                                            esc_html($co->{"${who}_name"})) . " " .
4516                       format_search_author($co->{"${who}_email"}, $who,
4517                                            esc_html("<" . $co->{"${who}_email"} . ">")) .
4518                       "</td><td rowspan=\"2\">" .
4519                       git_get_avatar($co->{"${who}_email"}, -size => 'double') .
4520                       "</td></tr>\n" .
4521                       "<tr>" .
4522                       "<td></td><td>" .
4523                       format_timestamp_html(\%wd) .
4524                       "</td>" .
4525                       "</tr>\n";
4526         }
4527 }
4528
4529 sub git_print_page_path {
4530         my $name = shift;
4531         my $type = shift;
4532         my $hb = shift;
4533
4534
4535         print "<div class=\"page_path\">";
4536         print $cgi->a({-href => href(action=>"tree", hash_base=>$hb),
4537                       -title => 'tree root'}, to_utf8("[$project]"));
4538         print " / ";
4539         if (defined $name) {
4540                 my @dirname = split '/', $name;
4541                 my $basename = pop @dirname;
4542                 my $fullname = '';
4543
4544                 foreach my $dir (@dirname) {
4545                         $fullname .= ($fullname ? '/' : '') . $dir;
4546                         print $cgi->a({-href => href(action=>"tree", file_name=>$fullname,
4547                                                      hash_base=>$hb),
4548                                       -title => $fullname}, esc_path($dir));
4549                         print " / ";
4550                 }
4551                 if (defined $type && $type eq 'blob') {
4552                         print $cgi->a({-href => href(action=>"blob_plain", file_name=>$file_name,
4553                                                      hash_base=>$hb),
4554                                       -title => $name}, esc_path($basename));
4555                 } elsif (defined $type && $type eq 'tree') {
4556                         print $cgi->a({-href => href(action=>"tree", file_name=>$file_name,
4557                                                      hash_base=>$hb),
4558                                       -title => $name}, esc_path($basename));
4559                         print " / ";
4560                 } else {
4561                         print esc_path($basename);
4562                 }
4563         }
4564         print "<br/></div>\n";
4565 }
4566
4567 sub git_print_log {
4568         my $log = shift;
4569         my %opts = @_;
4570
4571         if ($opts{'-remove_title'}) {
4572                 # remove title, i.e. first line of log
4573                 shift @$log;
4574         }
4575         # remove leading empty lines
4576         while (defined $log->[0] && $log->[0] eq "") {
4577                 shift @$log;
4578         }
4579
4580         # print log
4581         my $skip_blank_line = 0;
4582         foreach my $line (@$log) {
4583                 if ($line =~ m/^\s*([A-Z][-A-Za-z]*-[Bb]y|C[Cc]): /) {
4584                         if (! $opts{'-remove_signoff'}) {
4585                                 print "<span class=\"signoff\">" . esc_html($line) . "</span><br/>\n";
4586                                 $skip_blank_line = 1;
4587                         }
4588                         next;
4589                 }
4590
4591                 if ($line =~ m,\s*([a-z]*link): (https?://\S+),i) {
4592                         if (! $opts{'-remove_signoff'}) {
4593                                 print "<span class=\"signoff\">" . esc_html($1) . ": " .
4594                                         "<a href=\"" . esc_html($2) . "\">" . esc_html($2) . "</a>" .
4595                                         "</span><br/>\n";
4596                                 $skip_blank_line = 1;
4597                         }
4598                         next;
4599                 }
4600
4601                 # print only one empty line
4602                 # do not print empty line after signoff
4603                 if ($line eq "") {
4604                         next if ($skip_blank_line);
4605                         $skip_blank_line = 1;
4606                 } else {
4607                         $skip_blank_line = 0;
4608                 }
4609
4610                 print format_log_line_html($line) . "<br/>\n";
4611         }
4612
4613         if ($opts{'-final_empty_line'}) {
4614                 # end with single empty line
4615                 print "<br/>\n" unless $skip_blank_line;
4616         }
4617 }
4618
4619 # return link target (what link points to)
4620 sub git_get_link_target {
4621         my $hash = shift;
4622         my $link_target;
4623
4624         # read link
4625         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
4626                 or return;
4627         {
4628                 local $/ = undef;
4629                 $link_target = <$fd>;
4630         }
4631         close $fd
4632                 or return;
4633
4634         return $link_target;
4635 }
4636
4637 # given link target, and the directory (basedir) the link is in,
4638 # return target of link relative to top directory (top tree);
4639 # return undef if it is not possible (including absolute links).
4640 sub normalize_link_target {
4641         my ($link_target, $basedir) = @_;
4642
4643         # absolute symlinks (beginning with '/') cannot be normalized
4644         return if (substr($link_target, 0, 1) eq '/');
4645
4646         # normalize link target to path from top (root) tree (dir)
4647         my $path;
4648         if ($basedir) {
4649                 $path = $basedir . '/' . $link_target;
4650         } else {
4651                 # we are in top (root) tree (dir)
4652                 $path = $link_target;
4653         }
4654
4655         # remove //, /./, and /../
4656         my @path_parts;
4657         foreach my $part (split('/', $path)) {
4658                 # discard '.' and ''
4659                 next if (!$part || $part eq '.');
4660                 # handle '..'
4661                 if ($part eq '..') {
4662                         if (@path_parts) {
4663                                 pop @path_parts;
4664                         } else {
4665                                 # link leads outside repository (outside top dir)
4666                                 return;
4667                         }
4668                 } else {
4669                         push @path_parts, $part;
4670                 }
4671         }
4672         $path = join('/', @path_parts);
4673
4674         return $path;
4675 }
4676
4677 # print tree entry (row of git_tree), but without encompassing <tr> element
4678 sub git_print_tree_entry {
4679         my ($t, $basedir, $hash_base, $have_blame) = @_;
4680
4681         my %base_key = ();
4682         $base_key{'hash_base'} = $hash_base if defined $hash_base;
4683
4684         # The format of a table row is: mode list link.  Where mode is
4685         # the mode of the entry, list is the name of the entry, an href,
4686         # and link is the action links of the entry.
4687
4688         print "<td class=\"mode\">" . mode_str($t->{'mode'}) . "</td>\n";
4689         if (exists $t->{'size'}) {
4690                 print "<td class=\"size\">$t->{'size'}</td>\n";
4691         }
4692         if ($t->{'type'} eq "blob") {
4693                 print "<td class=\"list\">" .
4694                         $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4695                                                file_name=>"$basedir$t->{'name'}", %base_key),
4696                                 -class => "list"}, esc_path($t->{'name'}));
4697                 if (S_ISLNK(oct $t->{'mode'})) {
4698                         my $link_target = git_get_link_target($t->{'hash'});
4699                         if ($link_target) {
4700                                 my $norm_target = normalize_link_target($link_target, $basedir);
4701                                 if (defined $norm_target) {
4702                                         print " -> " .
4703                                               $cgi->a({-href => href(action=>"object", hash_base=>$hash_base,
4704                                                                      file_name=>$norm_target),
4705                                                        -title => $norm_target}, esc_path($link_target));
4706                                 } else {
4707                                         print " -> " . esc_path($link_target);
4708                                 }
4709                         }
4710                 }
4711                 print "</td>\n";
4712                 print "<td class=\"link\">";
4713                 print $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4714                                              file_name=>"$basedir$t->{'name'}", %base_key)},
4715                               "blob");
4716                 if ($have_blame) {
4717                         print " | " .
4718                               $cgi->a({-href => href(action=>"blame", hash=>$t->{'hash'},
4719                                                      file_name=>"$basedir$t->{'name'}", %base_key)},
4720                                       "blame");
4721                 }
4722                 if (defined $hash_base) {
4723                         print " | " .
4724                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4725                                                      hash=>$t->{'hash'}, file_name=>"$basedir$t->{'name'}")},
4726                                       "history");
4727                 }
4728                 print " | " .
4729                         $cgi->a({-href => href(action=>"blob_plain", hash_base=>$hash_base,
4730                                                file_name=>"$basedir$t->{'name'}")},
4731                                 "raw");
4732                 print "</td>\n";
4733
4734         } elsif ($t->{'type'} eq "tree") {
4735                 print "<td class=\"list\">";
4736                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4737                                              file_name=>"$basedir$t->{'name'}",
4738                                              %base_key)},
4739                               esc_path($t->{'name'}));
4740                 print "</td>\n";
4741                 print "<td class=\"link\">";
4742                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4743                                              file_name=>"$basedir$t->{'name'}",
4744                                              %base_key)},
4745                               "tree");
4746                 if (defined $hash_base) {
4747                         print " | " .
4748                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4749                                                      file_name=>"$basedir$t->{'name'}")},
4750                                       "history");
4751                 }
4752                 print "</td>\n";
4753         } else {
4754                 # unknown object: we can only present history for it
4755                 # (this includes 'commit' object, i.e. submodule support)
4756                 print "<td class=\"list\">" .
4757                       esc_path($t->{'name'}) .
4758                       "</td>\n";
4759                 print "<td class=\"link\">";
4760                 if (defined $hash_base) {
4761                         print $cgi->a({-href => href(action=>"history",
4762                                                      hash_base=>$hash_base,
4763                                                      file_name=>"$basedir$t->{'name'}")},
4764                                       "history");
4765                 }
4766                 print "</td>\n";
4767         }
4768 }
4769
4770 ## ......................................................................
4771 ## functions printing large fragments of HTML
4772
4773 # get pre-image filenames for merge (combined) diff
4774 sub fill_from_file_info {
4775         my ($diff, @parents) = @_;
4776
4777         $diff->{'from_file'} = [ ];
4778         $diff->{'from_file'}[$diff->{'nparents'} - 1] = undef;
4779         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4780                 if ($diff->{'status'}[$i] eq 'R' ||
4781                     $diff->{'status'}[$i] eq 'C') {
4782                         $diff->{'from_file'}[$i] =
4783                                 git_get_path_by_hash($parents[$i], $diff->{'from_id'}[$i]);
4784                 }
4785         }
4786
4787         return $diff;
4788 }
4789
4790 # is current raw difftree line of file deletion
4791 sub is_deleted {
4792         my $diffinfo = shift;
4793
4794         return $diffinfo->{'to_id'} eq ('0' x 40);
4795 }
4796
4797 # does patch correspond to [previous] difftree raw line
4798 # $diffinfo  - hashref of parsed raw diff format
4799 # $patchinfo - hashref of parsed patch diff format
4800 #              (the same keys as in $diffinfo)
4801 sub is_patch_split {
4802         my ($diffinfo, $patchinfo) = @_;
4803
4804         return defined $diffinfo && defined $patchinfo
4805                 && $diffinfo->{'to_file'} eq $patchinfo->{'to_file'};
4806 }
4807
4808
4809 sub git_difftree_body {
4810         my ($difftree, $hash, @parents) = @_;
4811         my ($parent) = $parents[0];
4812         my $have_blame = gitweb_check_feature('blame');
4813         print "<div class=\"list_head\">\n";
4814         if ($#{$difftree} > 10) {
4815                 print(($#{$difftree} + 1) . " files changed:\n");
4816         }
4817         print "</div>\n";
4818
4819         print "<table class=\"" .
4820               (@parents > 1 ? "combined " : "") .
4821               "diff_tree\">\n";
4822
4823         # header only for combined diff in 'commitdiff' view
4824         my $has_header = @$difftree && @parents > 1 && $action eq 'commitdiff';
4825         if ($has_header) {
4826                 # table header
4827                 print "<thead><tr>\n" .
4828                        "<th></th><th></th>\n"; # filename, patchN link
4829                 for (my $i = 0; $i < @parents; $i++) {
4830                         my $par = $parents[$i];
4831                         print "<th>" .
4832                               $cgi->a({-href => href(action=>"commitdiff",
4833                                                      hash=>$hash, hash_parent=>$par),
4834                                        -title => 'commitdiff to parent number ' .
4835                                                   ($i+1) . ': ' . substr($par,0,7)},
4836                                       $i+1) .
4837                               "&nbsp;</th>\n";
4838                 }
4839                 print "</tr></thead>\n<tbody>\n";
4840         }
4841
4842         my $alternate = 1;
4843         my $patchno = 0;
4844         foreach my $line (@{$difftree}) {
4845                 my $diff = parsed_difftree_line($line);
4846
4847                 if ($alternate) {
4848                         print "<tr class=\"dark\">\n";
4849                 } else {
4850                         print "<tr class=\"light\">\n";
4851                 }
4852                 $alternate ^= 1;
4853
4854                 if (exists $diff->{'nparents'}) { # combined diff
4855
4856                         fill_from_file_info($diff, @parents)
4857                                 unless exists $diff->{'from_file'};
4858
4859                         if (!is_deleted($diff)) {
4860                                 # file exists in the result (child) commit
4861                                 print "<td>" .
4862                                       $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4863                                                              file_name=>$diff->{'to_file'},
4864                                                              hash_base=>$hash),
4865                                               -class => "list"}, esc_path($diff->{'to_file'})) .
4866                                       "</td>\n";
4867                         } else {
4868                                 print "<td>" .
4869                                       esc_path($diff->{'to_file'}) .
4870                                       "</td>\n";
4871                         }
4872
4873                         if ($action eq 'commitdiff') {
4874                                 # link to patch
4875                                 $patchno++;
4876                                 print "<td class=\"link\">" .
4877                                       $cgi->a({-href => href(-anchor=>"patch$patchno")},
4878                                               "patch") .
4879                                       " | " .
4880                                       "</td>\n";
4881                         }
4882
4883                         my $has_history = 0;
4884                         my $not_deleted = 0;
4885                         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4886                                 my $hash_parent = $parents[$i];
4887                                 my $from_hash = $diff->{'from_id'}[$i];
4888                                 my $from_path = $diff->{'from_file'}[$i];
4889                                 my $status = $diff->{'status'}[$i];
4890
4891                                 $has_history ||= ($status ne 'A');
4892                                 $not_deleted ||= ($status ne 'D');
4893
4894                                 if ($status eq 'A') {
4895                                         print "<td  class=\"link\" align=\"right\"> | </td>\n";
4896                                 } elsif ($status eq 'D') {
4897                                         print "<td class=\"link\">" .
4898                                               $cgi->a({-href => href(action=>"blob",
4899                                                                      hash_base=>$hash,
4900                                                                      hash=>$from_hash,
4901                                                                      file_name=>$from_path)},
4902                                                       "blob" . ($i+1)) .
4903                                               " | </td>\n";
4904                                 } else {
4905                                         if ($diff->{'to_id'} eq $from_hash) {
4906                                                 print "<td class=\"link nochange\">";
4907                                         } else {
4908                                                 print "<td class=\"link\">";
4909                                         }
4910                                         print $cgi->a({-href => href(action=>"blobdiff",
4911                                                                      hash=>$diff->{'to_id'},
4912                                                                      hash_parent=>$from_hash,
4913                                                                      hash_base=>$hash,
4914                                                                      hash_parent_base=>$hash_parent,
4915                                                                      file_name=>$diff->{'to_file'},
4916                                                                      file_parent=>$from_path)},
4917                                                       "diff" . ($i+1)) .
4918                                               " | </td>\n";
4919                                 }
4920                         }
4921
4922                         print "<td class=\"link\">";
4923                         if ($not_deleted) {
4924                                 print $cgi->a({-href => href(action=>"blob",
4925                                                              hash=>$diff->{'to_id'},
4926                                                              file_name=>$diff->{'to_file'},
4927                                                              hash_base=>$hash)},
4928                                               "blob");
4929                                 print " | " if ($has_history);
4930                         }
4931                         if ($has_history) {
4932                                 print $cgi->a({-href => href(action=>"history",
4933                                                              file_name=>$diff->{'to_file'},
4934                                                              hash_base=>$hash)},
4935                                               "history");
4936                         }
4937                         print "</td>\n";
4938
4939                         print "</tr>\n";
4940                         next; # instead of 'else' clause, to avoid extra indent
4941                 }
4942                 # else ordinary diff
4943
4944                 my ($to_mode_oct, $to_mode_str, $to_file_type);
4945                 my ($from_mode_oct, $from_mode_str, $from_file_type);
4946                 if ($diff->{'to_mode'} ne ('0' x 6)) {
4947                         $to_mode_oct = oct $diff->{'to_mode'};
4948                         if (S_ISREG($to_mode_oct)) { # only for regular file
4949                                 $to_mode_str = sprintf("%04o", $to_mode_oct & 0777); # permission bits
4950                         }
4951                         $to_file_type = file_type($diff->{'to_mode'});
4952                 }
4953                 if ($diff->{'from_mode'} ne ('0' x 6)) {
4954                         $from_mode_oct = oct $diff->{'from_mode'};
4955                         if (S_ISREG($from_mode_oct)) { # only for regular file
4956                                 $from_mode_str = sprintf("%04o", $from_mode_oct & 0777); # permission bits
4957                         }
4958                         $from_file_type = file_type($diff->{'from_mode'});
4959                 }
4960
4961                 if ($diff->{'status'} eq "A") { # created
4962                         my $mode_chng = "<span class=\"file_status new\">[new $to_file_type";
4963                         $mode_chng   .= " with mode: $to_mode_str" if $to_mode_str;
4964                         $mode_chng   .= "]</span>";
4965                         print "<td>";
4966                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4967                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4968                                       -class => "list"}, esc_path($diff->{'file'}));
4969                         print "</td>\n";
4970                         print "<td>$mode_chng</td>\n";
4971                         print "<td class=\"link\">";
4972                         if ($action eq 'commitdiff') {
4973                                 # link to patch
4974                                 $patchno++;
4975                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4976                                               "patch") .
4977                                       " | ";
4978                         }
4979                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4980                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4981                                       "blob");
4982                         print "</td>\n";
4983
4984                 } elsif ($diff->{'status'} eq "D") { # deleted
4985                         my $mode_chng = "<span class=\"file_status deleted\">[deleted $from_file_type]</span>";
4986                         print "<td>";
4987                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4988                                                      hash_base=>$parent, file_name=>$diff->{'file'}),
4989                                        -class => "list"}, esc_path($diff->{'file'}));
4990                         print "</td>\n";
4991                         print "<td>$mode_chng</td>\n";
4992                         print "<td class=\"link\">";
4993                         if ($action eq 'commitdiff') {
4994                                 # link to patch
4995                                 $patchno++;
4996                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
4997                                               "patch") .
4998                                       " | ";
4999                         }
5000                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
5001                                                      hash_base=>$parent, file_name=>$diff->{'file'})},
5002                                       "blob") . " | ";
5003                         if ($have_blame) {
5004                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$parent,
5005                                                              file_name=>$diff->{'file'})},
5006                                               "blame") . " | ";
5007                         }
5008                         print $cgi->a({-href => href(action=>"history", hash_base=>$parent,
5009                                                      file_name=>$diff->{'file'})},
5010                                       "history");
5011                         print "</td>\n";
5012
5013                 } elsif ($diff->{'status'} eq "M" || $diff->{'status'} eq "T") { # modified, or type changed
5014                         my $mode_chnge = "";
5015                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
5016                                 $mode_chnge = "<span class=\"file_status mode_chnge\">[changed";
5017                                 if ($from_file_type ne $to_file_type) {
5018                                         $mode_chnge .= " from $from_file_type to $to_file_type";
5019                                 }
5020                                 if (($from_mode_oct & 0777) != ($to_mode_oct & 0777)) {
5021                                         if ($from_mode_str && $to_mode_str) {
5022                                                 $mode_chnge .= " mode: $from_mode_str->$to_mode_str";
5023                                         } elsif ($to_mode_str) {
5024                                                 $mode_chnge .= " mode: $to_mode_str";
5025                                         }
5026                                 }
5027                                 $mode_chnge .= "]</span>\n";
5028                         }
5029                         print "<td>";
5030                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
5031                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
5032                                       -class => "list"}, esc_path($diff->{'file'}));
5033                         print "</td>\n";
5034                         print "<td>$mode_chnge</td>\n";
5035                         print "<td class=\"link\">";
5036                         if ($action eq 'commitdiff') {
5037                                 # link to patch
5038                                 $patchno++;
5039                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
5040                                               "patch") .
5041                                       " | ";
5042                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
5043                                 # "commit" view and modified file (not onlu mode changed)
5044                                 print $cgi->a({-href => href(action=>"blobdiff",
5045                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
5046                                                              hash_base=>$hash, hash_parent_base=>$parent,
5047                                                              file_name=>$diff->{'file'})},
5048                                               "diff") .
5049                                       " | ";
5050                         }
5051                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
5052                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
5053                                        "blob") . " | ";
5054                         if ($have_blame) {
5055                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
5056                                                              file_name=>$diff->{'file'})},
5057                                               "blame") . " | ";
5058                         }
5059                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
5060                                                      file_name=>$diff->{'file'})},
5061                                       "history");
5062                         print "</td>\n";
5063
5064                 } elsif ($diff->{'status'} eq "R" || $diff->{'status'} eq "C") { # renamed or copied
5065                         my %status_name = ('R' => 'moved', 'C' => 'copied');
5066                         my $nstatus = $status_name{$diff->{'status'}};
5067                         my $mode_chng = "";
5068                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
5069                                 # mode also for directories, so we cannot use $to_mode_str
5070                                 $mode_chng = sprintf(", mode: %04o", $to_mode_oct & 0777);
5071                         }
5072                         print "<td>" .
5073                               $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
5074                                                      hash=>$diff->{'to_id'}, file_name=>$diff->{'to_file'}),
5075                                       -class => "list"}, esc_path($diff->{'to_file'})) . "</td>\n" .
5076                               "<td><span class=\"file_status $nstatus\">[$nstatus from " .
5077                               $cgi->a({-href => href(action=>"blob", hash_base=>$parent,
5078                                                      hash=>$diff->{'from_id'}, file_name=>$diff->{'from_file'}),
5079                                       -class => "list"}, esc_path($diff->{'from_file'})) .
5080                               " with " . (int $diff->{'similarity'}) . "% similarity$mode_chng]</span></td>\n" .
5081                               "<td class=\"link\">";
5082                         if ($action eq 'commitdiff') {
5083                                 # link to patch
5084                                 $patchno++;
5085                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
5086                                               "patch") .
5087                                       " | ";
5088                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
5089                                 # "commit" view and modified file (not only pure rename or copy)
5090                                 print $cgi->a({-href => href(action=>"blobdiff",
5091                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
5092                                                              hash_base=>$hash, hash_parent_base=>$parent,
5093                                                              file_name=>$diff->{'to_file'}, file_parent=>$diff->{'from_file'})},
5094                                               "diff") .
5095                                       " | ";
5096                         }
5097                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
5098                                                      hash_base=>$parent, file_name=>$diff->{'to_file'})},
5099                                       "blob") . " | ";
5100                         if ($have_blame) {
5101                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
5102                                                              file_name=>$diff->{'to_file'})},
5103                                               "blame") . " | ";
5104                         }
5105                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
5106                                                     file_name=>$diff->{'to_file'})},
5107                                       "history");
5108                         print "</td>\n";
5109
5110                 } # we should not encounter Unmerged (U) or Unknown (X) status
5111                 print "</tr>\n";
5112         }
5113         print "</tbody>" if $has_header;
5114         print "</table>\n";
5115 }
5116
5117 # Print context lines and then rem/add lines in a side-by-side manner.
5118 sub print_sidebyside_diff_lines {
5119         my ($ctx, $rem, $add) = @_;
5120
5121         # print context block before add/rem block
5122         if (@$ctx) {
5123                 print join '',
5124                         '<div class="chunk_block ctx">',
5125                                 '<div class="old">',
5126                                 @$ctx,
5127                                 '</div>',
5128                                 '<div class="new">',
5129                                 @$ctx,
5130                                 '</div>',
5131                         '</div>';
5132         }
5133
5134         if (!@$add) {
5135                 # pure removal
5136                 print join '',
5137                         '<div class="chunk_block rem">',
5138                                 '<div class="old">',
5139                                 @$rem,
5140                                 '</div>',
5141                         '</div>';
5142         } elsif (!@$rem) {
5143                 # pure addition
5144                 print join '',
5145                         '<div class="chunk_block add">',
5146                                 '<div class="new">',
5147                                 @$add,
5148                                 '</div>',
5149                         '</div>';
5150         } else {
5151                 print join '',
5152                         '<div class="chunk_block chg">',
5153                                 '<div class="old">',
5154                                 @$rem,
5155                                 '</div>',
5156                                 '<div class="new">',
5157                                 @$add,
5158                                 '</div>',
5159                         '</div>';
5160         }
5161 }
5162
5163 # Print context lines and then rem/add lines in inline manner.
5164 sub print_inline_diff_lines {
5165         my ($ctx, $rem, $add) = @_;
5166
5167         print @$ctx, @$rem, @$add;
5168 }
5169
5170 # Format removed and added line, mark changed part and HTML-format them.
5171 # Implementation is based on contrib/diff-highlight
5172 sub format_rem_add_lines_pair {
5173         my ($rem, $add, $num_parents) = @_;
5174
5175         # We need to untabify lines before split()'ing them;
5176         # otherwise offsets would be invalid.
5177         chomp $rem;
5178         chomp $add;
5179         $rem = untabify($rem);
5180         $add = untabify($add);
5181
5182         my @rem = split(//, $rem);
5183         my @add = split(//, $add);
5184         my ($esc_rem, $esc_add);
5185         # Ignore leading +/- characters for each parent.
5186         my ($prefix_len, $suffix_len) = ($num_parents, 0);
5187         my ($prefix_has_nonspace, $suffix_has_nonspace);
5188
5189         my $shorter = (@rem < @add) ? @rem : @add;
5190         while ($prefix_len < $shorter) {
5191                 last if ($rem[$prefix_len] ne $add[$prefix_len]);
5192
5193                 $prefix_has_nonspace = 1 if ($rem[$prefix_len] !~ /\s/);
5194                 $prefix_len++;
5195         }
5196
5197         while ($prefix_len + $suffix_len < $shorter) {
5198                 last if ($rem[-1 - $suffix_len] ne $add[-1 - $suffix_len]);
5199
5200                 $suffix_has_nonspace = 1 if ($rem[-1 - $suffix_len] !~ /\s/);
5201                 $suffix_len++;
5202         }
5203
5204         # Mark lines that are different from each other, but have some common
5205         # part that isn't whitespace.  If lines are completely different, don't
5206         # mark them because that would make output unreadable, especially if
5207         # diff consists of multiple lines.
5208         if ($prefix_has_nonspace || $suffix_has_nonspace) {
5209                 $esc_rem = esc_html_hl_regions($rem, 'marked',
5210                         [$prefix_len, @rem - $suffix_len], -nbsp=>1);
5211                 $esc_add = esc_html_hl_regions($add, 'marked',
5212                         [$prefix_len, @add - $suffix_len], -nbsp=>1);
5213         } else {
5214                 $esc_rem = esc_html($rem, -nbsp=>1);
5215                 $esc_add = esc_html($add, -nbsp=>1);
5216         }
5217
5218         return format_diff_line(\$esc_rem, 'rem'),
5219                format_diff_line(\$esc_add, 'add');
5220 }
5221
5222 # HTML-format diff context, removed and added lines.
5223 sub format_ctx_rem_add_lines {
5224         my ($ctx, $rem, $add, $num_parents) = @_;
5225         my (@new_ctx, @new_rem, @new_add);
5226         my $can_highlight = 0;
5227         my $is_combined = ($num_parents > 1);
5228
5229         # Highlight if every removed line has a corresponding added line.
5230         if (@$add > 0 && @$add == @$rem) {
5231                 $can_highlight = 1;
5232
5233                 # Highlight lines in combined diff only if the chunk contains
5234                 # diff between the same version, e.g.
5235                 #
5236                 #    - a
5237                 #   -  b
5238                 #    + c
5239                 #   +  d
5240                 #
5241                 # Otherwise the highlightling would be confusing.
5242                 if ($is_combined) {
5243                         for (my $i = 0; $i < @$add; $i++) {
5244                                 my $prefix_rem = substr($rem->[$i], 0, $num_parents);
5245                                 my $prefix_add = substr($add->[$i], 0, $num_parents);
5246
5247                                 $prefix_rem =~ s/-/+/g;
5248
5249                                 if ($prefix_rem ne $prefix_add) {
5250                                         $can_highlight = 0;
5251                                         last;
5252                                 }
5253                         }
5254                 }
5255         }
5256
5257         if ($can_highlight) {
5258                 for (my $i = 0; $i < @$add; $i++) {
5259                         my ($line_rem, $line_add) = format_rem_add_lines_pair(
5260                                 $rem->[$i], $add->[$i], $num_parents);
5261                         push @new_rem, $line_rem;
5262                         push @new_add, $line_add;
5263                 }
5264         } else {
5265                 @new_rem = map { format_diff_line($_, 'rem') } @$rem;
5266                 @new_add = map { format_diff_line($_, 'add') } @$add;
5267         }
5268
5269         @new_ctx = map { format_diff_line($_, 'ctx') } @$ctx;
5270
5271         return (\@new_ctx, \@new_rem, \@new_add);
5272 }
5273
5274 # Print context lines and then rem/add lines.
5275 sub print_diff_lines {
5276         my ($ctx, $rem, $add, $diff_style, $num_parents) = @_;
5277         my $is_combined = $num_parents > 1;
5278
5279         ($ctx, $rem, $add) = format_ctx_rem_add_lines($ctx, $rem, $add,
5280                 $num_parents);
5281
5282         if ($diff_style eq 'sidebyside' && !$is_combined) {
5283                 print_sidebyside_diff_lines($ctx, $rem, $add);
5284         } else {
5285                 # default 'inline' style and unknown styles
5286                 print_inline_diff_lines($ctx, $rem, $add);
5287         }
5288 }
5289
5290 sub print_diff_chunk {
5291         my ($diff_style, $num_parents, $from, $to, @chunk) = @_;
5292         my (@ctx, @rem, @add);
5293
5294         # The class of the previous line.
5295         my $prev_class = '';
5296
5297         return unless @chunk;
5298
5299         # incomplete last line might be among removed or added lines,
5300         # or both, or among context lines: find which
5301         for (my $i = 1; $i < @chunk; $i++) {
5302                 if ($chunk[$i][0] eq 'incomplete') {
5303                         $chunk[$i][0] = $chunk[$i-1][0];
5304                 }
5305         }
5306
5307         # guardian
5308         push @chunk, ["", ""];
5309
5310         foreach my $line_info (@chunk) {
5311                 my ($class, $line) = @$line_info;
5312
5313                 # print chunk headers
5314                 if ($class && $class eq 'chunk_header') {
5315                         print format_diff_line($line, $class, $from, $to);
5316                         next;
5317                 }
5318
5319                 ## print from accumulator when have some add/rem lines or end
5320                 # of chunk (flush context lines), or when have add and rem
5321                 # lines and new block is reached (otherwise add/rem lines could
5322                 # be reordered)
5323                 if (!$class || ((@rem || @add) && $class eq 'ctx') ||
5324                     (@rem && @add && $class ne $prev_class)) {
5325                         print_diff_lines(\@ctx, \@rem, \@add,
5326                                          $diff_style, $num_parents);
5327                         @ctx = @rem = @add = ();
5328                 }
5329
5330                 ## adding lines to accumulator
5331                 # guardian value
5332                 last unless $line;
5333                 # rem, add or change
5334                 if ($class eq 'rem') {
5335                         push @rem, $line;
5336                 } elsif ($class eq 'add') {
5337                         push @add, $line;
5338                 }
5339                 # context line
5340                 if ($class eq 'ctx') {
5341                         push @ctx, $line;
5342                 }
5343
5344                 $prev_class = $class;
5345         }
5346 }
5347
5348 sub git_patchset_body {
5349         my ($fd, $diff_style, $difftree, $hash, @hash_parents) = @_;
5350         my ($hash_parent) = $hash_parents[0];
5351
5352         my $is_combined = (@hash_parents > 1);
5353         my $patch_idx = 0;
5354         my $patch_number = 0;
5355         my $patch_line;
5356         my $diffinfo;
5357         my $to_name;
5358         my (%from, %to);
5359         my @chunk; # for side-by-side diff
5360
5361         print "<div class=\"patchset\">\n";
5362
5363         # skip to first patch
5364         while ($patch_line = <$fd>) {
5365                 chomp $patch_line;
5366
5367                 last if ($patch_line =~ m/^diff /);
5368         }
5369
5370  PATCH:
5371         while ($patch_line) {
5372
5373                 # parse "git diff" header line
5374                 if ($patch_line =~ m/^diff --git (\"(?:[^\\\"]*(?:\\.[^\\\"]*)*)\"|[^ "]*) (.*)$/) {
5375                         # $1 is from_name, which we do not use
5376                         $to_name = unquote($2);
5377                         $to_name =~ s!^b/!!;
5378                 } elsif ($patch_line =~ m/^diff --(cc|combined) ("?.*"?)$/) {
5379                         # $1 is 'cc' or 'combined', which we do not use
5380                         $to_name = unquote($2);
5381                 } else {
5382                         $to_name = undef;
5383                 }
5384
5385                 # check if current patch belong to current raw line
5386                 # and parse raw git-diff line if needed
5387                 if (is_patch_split($diffinfo, { 'to_file' => $to_name })) {
5388                         # this is continuation of a split patch
5389                         print "<div class=\"patch cont\">\n";
5390                 } else {
5391                         # advance raw git-diff output if needed
5392                         $patch_idx++ if defined $diffinfo;
5393
5394                         # read and prepare patch information
5395                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5396
5397                         # compact combined diff output can have some patches skipped
5398                         # find which patch (using pathname of result) we are at now;
5399                         if ($is_combined) {
5400                                 while ($to_name ne $diffinfo->{'to_file'}) {
5401                                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
5402                                               format_diff_cc_simplified($diffinfo, @hash_parents) .
5403                                               "</div>\n";  # class="patch"
5404
5405                                         $patch_idx++;
5406                                         $patch_number++;
5407
5408                                         last if $patch_idx > $#$difftree;
5409                                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5410                                 }
5411                         }
5412
5413                         # modifies %from, %to hashes
5414                         parse_from_to_diffinfo($diffinfo, \%from, \%to, @hash_parents);
5415
5416                         # this is first patch for raw difftree line with $patch_idx index
5417                         # we index @$difftree array from 0, but number patches from 1
5418                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n";
5419                 }
5420
5421                 # git diff header
5422                 #assert($patch_line =~ m/^diff /) if DEBUG;
5423                 #assert($patch_line !~ m!$/$!) if DEBUG; # is chomp-ed
5424                 $patch_number++;
5425                 # print "git diff" header
5426                 print format_git_diff_header_line($patch_line, $diffinfo,
5427                                                   \%from, \%to);
5428
5429                 # print extended diff header
5430                 print "<div class=\"diff extended_header\">\n";
5431         EXTENDED_HEADER:
5432                 while ($patch_line = <$fd>) {
5433                         chomp $patch_line;
5434
5435                         last EXTENDED_HEADER if ($patch_line =~ m/^--- |^diff /);
5436
5437                         print format_extended_diff_header_line($patch_line, $diffinfo,
5438                                                                \%from, \%to);
5439                 }
5440                 print "</div>\n"; # class="diff extended_header"
5441
5442                 # from-file/to-file diff header
5443                 if (! $patch_line) {
5444                         print "</div>\n"; # class="patch"
5445                         last PATCH;
5446                 }
5447                 next PATCH if ($patch_line =~ m/^diff /);
5448                 #assert($patch_line =~ m/^---/) if DEBUG;
5449
5450                 my $last_patch_line = $patch_line;
5451                 $patch_line = <$fd>;
5452                 chomp $patch_line;
5453                 #assert($patch_line =~ m/^\+\+\+/) if DEBUG;
5454
5455                 print format_diff_from_to_header($last_patch_line, $patch_line,
5456                                                  $diffinfo, \%from, \%to,
5457                                                  @hash_parents);
5458
5459                 # the patch itself
5460         LINE:
5461                 while ($patch_line = <$fd>) {
5462                         chomp $patch_line;
5463
5464                         next PATCH if ($patch_line =~ m/^diff /);
5465
5466                         my $class = diff_line_class($patch_line, \%from, \%to);
5467
5468                         if ($class eq 'chunk_header') {
5469                                 print_diff_chunk($diff_style, scalar @hash_parents, \%from, \%to, @chunk);
5470                                 @chunk = ();
5471                         }
5472
5473                         push @chunk, [ $class, $patch_line ];
5474                 }
5475
5476         } continue {
5477                 if (@chunk) {
5478                         print_diff_chunk($diff_style, scalar @hash_parents, \%from, \%to, @chunk);
5479                         @chunk = ();
5480                 }
5481                 print "</div>\n"; # class="patch"
5482         }
5483
5484         # for compact combined (--cc) format, with chunk and patch simplification
5485         # the patchset might be empty, but there might be unprocessed raw lines
5486         for (++$patch_idx if $patch_number > 0;
5487              $patch_idx < @$difftree;
5488              ++$patch_idx) {
5489                 # read and prepare patch information
5490                 $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5491
5492                 # generate anchor for "patch" links in difftree / whatchanged part
5493                 print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
5494                       format_diff_cc_simplified($diffinfo, @hash_parents) .
5495                       "</div>\n";  # class="patch"
5496
5497                 $patch_number++;
5498         }
5499
5500         if ($patch_number == 0) {
5501                 if (@hash_parents > 1) {
5502                         print "<div class=\"diff nodifferences\">Trivial merge</div>\n";
5503                 } else {
5504                         print "<div class=\"diff nodifferences\">No differences found</div>\n";
5505                 }
5506         }
5507
5508         print "</div>\n"; # class="patchset"
5509 }
5510
5511 # . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
5512
5513 sub git_project_search_form {
5514         my ($searchtext, $search_use_regexp) = @_;
5515
5516         my $limit = '';
5517         if ($project_filter) {
5518                 $limit = " in '$project_filter/'";
5519         }
5520
5521         print "<div class=\"projsearch\">\n";
5522         print $cgi->start_form(-method => 'get', -action => $my_uri) .
5523               $cgi->hidden(-name => 'a', -value => 'project_list')  . "\n";
5524         print $cgi->hidden(-name => 'pf', -value => $project_filter). "\n"
5525                 if (defined $project_filter);
5526         print $cgi->textfield(-name => 's', -value => $searchtext,
5527                               -title => "Search project by name and description$limit",
5528                               -size => 60) . "\n" .
5529               "<span title=\"Extended regular expression\">" .
5530               $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
5531                              -checked => $search_use_regexp) .
5532               "</span>\n" .
5533               $cgi->submit(-name => 'btnS', -value => 'Search') .
5534               $cgi->end_form() . "\n" .
5535               $cgi->a({-href => href(project => undef, searchtext => undef,
5536                                      project_filter => $project_filter)},
5537                       esc_html("List all projects$limit")) . "<br />\n";
5538         print "</div>\n";
5539 }
5540
5541 # entry for given @keys needs filling if at least one of keys in list
5542 # is not present in %$project_info
5543 sub project_info_needs_filling {
5544         my ($project_info, @keys) = @_;
5545
5546         # return List::MoreUtils::any { !exists $project_info->{$_} } @keys;
5547         foreach my $key (@keys) {
5548                 if (!exists $project_info->{$key}) {
5549                         return 1;
5550                 }
5551         }
5552         return;
5553 }
5554
5555 # fills project list info (age, description, owner, category, forks, etc.)
5556 # for each project in the list, removing invalid projects from
5557 # returned list, or fill only specified info.
5558 #
5559 # Invalid projects are removed from the returned list if and only if you
5560 # ask 'age' or 'age_string' to be filled, because they are the only fields
5561 # that run unconditionally git command that requires repository, and
5562 # therefore do always check if project repository is invalid.
5563 #
5564 # USAGE:
5565 # * fill_project_list_info(\@project_list, 'descr_long', 'ctags')
5566 #   ensures that 'descr_long' and 'ctags' fields are filled
5567 # * @project_list = fill_project_list_info(\@project_list)
5568 #   ensures that all fields are filled (and invalid projects removed)
5569 #
5570 # NOTE: modifies $projlist, but does not remove entries from it
5571 sub fill_project_list_info {
5572         my ($projlist, @wanted_keys) = @_;
5573         my @projects;
5574         my $filter_set = sub { return @_; };
5575         if (@wanted_keys) {
5576                 my %wanted_keys = map { $_ => 1 } @wanted_keys;
5577                 $filter_set = sub { return grep { $wanted_keys{$_} } @_; };
5578         }
5579
5580         my $show_ctags = gitweb_check_feature('ctags');
5581  PROJECT:
5582         foreach my $pr (@$projlist) {
5583                 if (project_info_needs_filling($pr, $filter_set->('age', 'age_string'))) {
5584                         my (@activity) = git_get_last_activity($pr->{'path'});
5585                         unless (@activity) {
5586                                 next PROJECT;
5587                         }
5588                         ($pr->{'age'}, $pr->{'age_string'}) = @activity;
5589                 }
5590                 if (project_info_needs_filling($pr, $filter_set->('descr', 'descr_long'))) {
5591                         my $descr = git_get_project_description($pr->{'path'}) || "";
5592                         $descr = to_utf8($descr);
5593                         $pr->{'descr_long'} = $descr;
5594                         $pr->{'descr'} = chop_str($descr, $projects_list_description_width, 5);
5595                 }
5596                 if (project_info_needs_filling($pr, $filter_set->('owner'))) {
5597                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}") || "";
5598                 }
5599                 if ($show_ctags &&
5600                     project_info_needs_filling($pr, $filter_set->('ctags'))) {
5601                         $pr->{'ctags'} = git_get_project_ctags($pr->{'path'});
5602                 }
5603                 if ($projects_list_group_categories &&
5604                     project_info_needs_filling($pr, $filter_set->('category'))) {
5605                         my $cat = git_get_project_category($pr->{'path'}) ||
5606                                                            $project_list_default_category;
5607                         $pr->{'category'} = to_utf8($cat);
5608                 }
5609
5610                 push @projects, $pr;
5611         }
5612
5613         return @projects;
5614 }
5615
5616 sub sort_projects_list {
5617         my ($projlist, $order) = @_;
5618
5619         sub order_str {
5620                 my $key = shift;
5621                 return sub { $a->{$key} cmp $b->{$key} };
5622         }
5623
5624         sub order_num_then_undef {
5625                 my $key = shift;
5626                 return sub {
5627                         defined $a->{$key} ?
5628                                 (defined $b->{$key} ? $a->{$key} <=> $b->{$key} : -1) :
5629                                 (defined $b->{$key} ? 1 : 0)
5630                 };
5631         }
5632
5633         my %orderings = (
5634                 project => order_str('path'),
5635                 descr => order_str('descr_long'),
5636                 owner => order_str('owner'),
5637                 age => order_num_then_undef('age'),
5638         );
5639
5640         my $ordering = $orderings{$order};
5641         return defined $ordering ? sort $ordering @$projlist : @$projlist;
5642 }
5643
5644 # returns a hash of categories, containing the list of project
5645 # belonging to each category
5646 sub build_projlist_by_category {
5647         my ($projlist, $from, $to) = @_;
5648         my %categories;
5649
5650         $from = 0 unless defined $from;
5651         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5652
5653         for (my $i = $from; $i <= $to; $i++) {
5654                 my $pr = $projlist->[$i];
5655                 push @{$categories{ $pr->{'category'} }}, $pr;
5656         }
5657
5658         return wantarray ? %categories : \%categories;
5659 }
5660
5661 # print 'sort by' <th> element, generating 'sort by $name' replay link
5662 # if that order is not selected
5663 sub print_sort_th {
5664         print format_sort_th(@_);
5665 }
5666
5667 sub format_sort_th {
5668         my ($name, $order, $header) = @_;
5669         my $sort_th = "";
5670         $header ||= ucfirst($name);
5671
5672         if ($order eq $name) {
5673                 $sort_th .= "<th>$header</th>\n";
5674         } else {
5675                 $sort_th .= "<th>" .
5676                             $cgi->a({-href => href(-replay=>1, order=>$name),
5677                                      -class => "header"}, $header) .
5678                             "</th>\n";
5679         }
5680
5681         return $sort_th;
5682 }
5683
5684 sub git_project_list_rows {
5685         my ($projlist, $from, $to, $check_forks) = @_;
5686
5687         $from = 0 unless defined $from;
5688         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5689
5690         my $alternate = 1;
5691         for (my $i = $from; $i <= $to; $i++) {
5692                 my $pr = $projlist->[$i];
5693
5694                 if ($alternate) {
5695                         print "<tr class=\"dark\">\n";
5696                 } else {
5697                         print "<tr class=\"light\">\n";
5698                 }
5699                 $alternate ^= 1;
5700
5701                 if ($check_forks) {
5702                         print "<td>";
5703                         if ($pr->{'forks'}) {
5704                                 my $nforks = scalar @{$pr->{'forks'}};
5705                                 if ($nforks > 0) {
5706                                         print $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks"),
5707                                                        -title => "$nforks forks"}, "+");
5708                                 } else {
5709                                         print $cgi->span({-title => "$nforks forks"}, "+");
5710                                 }
5711                         }
5712                         print "</td>\n";
5713                 }
5714                 print "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5715                                         -class => "list"},
5716                                        esc_html_match_hl($pr->{'path'}, $search_regexp)) .
5717                       "</td>\n" .
5718                       "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5719                                         -class => "list",
5720                                         -title => $pr->{'descr_long'}},
5721                                         $search_regexp
5722                                         ? esc_html_match_hl_chopped($pr->{'descr_long'},
5723                                                                     $pr->{'descr'}, $search_regexp)
5724                                         : esc_html($pr->{'descr'})) .
5725                       "</td>\n";
5726                 unless ($omit_owner) {
5727                         print "<td><i>" . chop_and_escape_str($pr->{'owner'}, 15) . "</i></td>\n";
5728                 }
5729                 unless ($omit_age_column) {
5730                         print "<td class=\"". age_class($pr->{'age'}) . "\">" .
5731                             (defined $pr->{'age_string'} ? $pr->{'age_string'} : "No commits") . "</td>\n";
5732                 }
5733                 print"<td class=\"link\">" .
5734                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary")}, "summary")   . " | " .
5735                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"shortlog")}, "shortlog") . " | " .
5736                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"log")}, "log") . " | " .
5737                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"tree")}, "tree") .
5738                       ($pr->{'forks'} ? " | " . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "forks") : '') .
5739                       "</td>\n" .
5740                       "</tr>\n";
5741         }
5742 }
5743
5744 sub git_project_list_body {
5745         # actually uses global variable $project
5746         my ($projlist, $order, $from, $to, $extra, $no_header) = @_;
5747         my @projects = @$projlist;
5748
5749         my $check_forks = gitweb_check_feature('forks');
5750         my $show_ctags  = gitweb_check_feature('ctags');
5751         my $tagfilter = $show_ctags ? $input_params{'ctag'} : undef;
5752         $check_forks = undef
5753                 if ($tagfilter || $search_regexp);
5754
5755         # filtering out forks before filling info allows to do less work
5756         @projects = filter_forks_from_projects_list(\@projects)
5757                 if ($check_forks);
5758         # search_projects_list pre-fills required info
5759         @projects = search_projects_list(\@projects,
5760                                          'search_regexp' => $search_regexp,
5761                                          'tagfilter'  => $tagfilter)
5762                 if ($tagfilter || $search_regexp);
5763         # fill the rest
5764         my @all_fields = ('descr', 'descr_long', 'ctags', 'category');
5765         push @all_fields, ('age', 'age_string') unless($omit_age_column);
5766         push @all_fields, 'owner' unless($omit_owner);
5767         @projects = fill_project_list_info(\@projects, @all_fields);
5768
5769         $order ||= $default_projects_order;
5770         $from = 0 unless defined $from;
5771         $to = $#projects if (!defined $to || $#projects < $to);
5772
5773         # short circuit
5774         if ($from > $to) {
5775                 print "<center>\n".
5776                       "<b>No such projects found</b><br />\n".
5777                       "Click ".$cgi->a({-href=>href(project=>undef)},"here")." to view all projects<br />\n".
5778                       "</center>\n<br />\n";
5779                 return;
5780         }
5781
5782         @projects = sort_projects_list(\@projects, $order);
5783
5784         if ($show_ctags) {
5785                 my $ctags = git_gather_all_ctags(\@projects);
5786                 my $cloud = git_populate_project_tagcloud($ctags);
5787                 print git_show_project_tagcloud($cloud, 64);
5788         }
5789
5790         print "<table class=\"project_list\">\n";
5791         unless ($no_header) {
5792                 print "<tr>\n";
5793                 if ($check_forks) {
5794                         print "<th></th>\n";
5795                 }
5796                 print_sort_th('project', $order, 'Project');
5797                 print_sort_th('descr', $order, 'Description');
5798                 print_sort_th('owner', $order, 'Owner') unless $omit_owner;
5799                 print_sort_th('age', $order, 'Last Change') unless $omit_age_column;
5800                 print "<th></th>\n" . # for links
5801                       "</tr>\n";
5802         }
5803
5804         if ($projects_list_group_categories) {
5805                 # only display categories with projects in the $from-$to window
5806                 @projects = sort {$a->{'category'} cmp $b->{'category'}} @projects[$from..$to];
5807                 my %categories = build_projlist_by_category(\@projects, $from, $to);
5808                 foreach my $cat (sort keys %categories) {
5809                         unless ($cat eq "") {
5810                                 print "<tr>\n";
5811                                 if ($check_forks) {
5812                                         print "<td></td>\n";
5813                                 }
5814                                 print "<td class=\"category\" colspan=\"5\">".esc_html($cat)."</td>\n";
5815                                 print "</tr>\n";
5816                         }
5817
5818                         git_project_list_rows($categories{$cat}, undef, undef, $check_forks);
5819                 }
5820         } else {
5821                 git_project_list_rows(\@projects, $from, $to, $check_forks);
5822         }
5823
5824         if (defined $extra) {
5825                 print "<tr>\n";
5826                 if ($check_forks) {
5827                         print "<td></td>\n";
5828                 }
5829                 print "<td colspan=\"5\">$extra</td>\n" .
5830                       "</tr>\n";
5831         }
5832         print "</table>\n";
5833 }
5834
5835 sub git_log_body {
5836         # uses global variable $project
5837         my ($commitlist, $from, $to, $refs, $extra) = @_;
5838
5839         $from = 0 unless defined $from;
5840         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5841
5842         for (my $i = 0; $i <= $to; $i++) {
5843                 my %co = %{$commitlist->[$i]};
5844                 next if !%co;
5845                 my $commit = $co{'id'};
5846                 my $ref = format_ref_marker($refs, $commit);
5847                 git_print_header_div('commit',
5848                                "<span class=\"age\">$co{'age_string'}</span>" .
5849                                esc_html($co{'title'}) . $ref,
5850                                $commit);
5851                 print "<div class=\"title_text\">\n" .
5852                       "<div class=\"log_link\">\n" .
5853                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") .
5854                       " | " .
5855                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") .
5856                       " | " .
5857                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree") .
5858                       "<br/>\n" .
5859                       "</div>\n";
5860                       git_print_authorship(\%co, -tag => 'span');
5861                       print "<br/>\n</div>\n";
5862
5863                 print "<div class=\"log_body\">\n";
5864                 git_print_log($co{'comment'}, -final_empty_line=> 1);
5865                 print "</div>\n";
5866         }
5867         if ($extra) {
5868                 print "<div class=\"page_nav\">\n";
5869                 print "$extra\n";
5870                 print "</div>\n";
5871         }
5872 }
5873
5874 sub git_shortlog_body {
5875         # uses global variable $project
5876         my ($commitlist, $from, $to, $refs, $extra) = @_;
5877
5878         $from = 0 unless defined $from;
5879         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5880
5881         print "<table class=\"shortlog\">\n";
5882         my $alternate = 1;
5883         for (my $i = $from; $i <= $to; $i++) {
5884                 my %co = %{$commitlist->[$i]};
5885                 my $commit = $co{'id'};
5886                 my $ref = format_ref_marker($refs, $commit);
5887                 if ($alternate) {
5888                         print "<tr class=\"dark\">\n";
5889                 } else {
5890                         print "<tr class=\"light\">\n";
5891                 }
5892                 $alternate ^= 1;
5893                 # git_summary() used print "<td><i>$co{'age_string'}</i></td>\n" .
5894                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5895                       format_author_html('td', \%co, 10) . "<td>";
5896                 print format_subject_html($co{'title'}, $co{'title_short'},
5897                                           href(action=>"commit", hash=>$commit), $ref);
5898                 print "</td>\n" .
5899                       "<td class=\"link\">" .
5900                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") . " | " .
5901                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") . " | " .
5902                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree");
5903                 my $snapshot_links = format_snapshot_links($commit);
5904                 if (defined $snapshot_links) {
5905                         print " | " . $snapshot_links;
5906                 }
5907                 print "</td>\n" .
5908                       "</tr>\n";
5909         }
5910         if (defined $extra) {
5911                 print "<tr>\n" .
5912                       "<td colspan=\"4\">$extra</td>\n" .
5913                       "</tr>\n";
5914         }
5915         print "</table>\n";
5916 }
5917
5918 sub git_history_body {
5919         # Warning: assumes constant type (blob or tree) during history
5920         my ($commitlist, $from, $to, $refs, $extra,
5921             $file_name, $file_hash, $ftype) = @_;
5922
5923         $from = 0 unless defined $from;
5924         $to = $#{$commitlist} unless (defined $to && $to <= $#{$commitlist});
5925
5926         print "<table class=\"history\">\n";
5927         my $alternate = 1;
5928         for (my $i = $from; $i <= $to; $i++) {
5929                 my %co = %{$commitlist->[$i]};
5930                 if (!%co) {
5931                         next;
5932                 }
5933                 my $commit = $co{'id'};
5934
5935                 my $ref = format_ref_marker($refs, $commit);
5936
5937                 if ($alternate) {
5938                         print "<tr class=\"dark\">\n";
5939                 } else {
5940                         print "<tr class=\"light\">\n";
5941                 }
5942                 $alternate ^= 1;
5943                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5944         # shortlog:   format_author_html('td', \%co, 10)
5945                       format_author_html('td', \%co, 15, 3) . "<td>";
5946                 # originally git_history used chop_str($co{'title'}, 50)
5947                 print format_subject_html($co{'title'}, $co{'title_short'},
5948                                           href(action=>"commit", hash=>$commit), $ref);
5949                 print "</td>\n" .
5950                       "<td class=\"link\">" .
5951                       $cgi->a({-href => href(action=>$ftype, hash_base=>$commit, file_name=>$file_name)}, $ftype) . " | " .
5952                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff");
5953
5954                 if ($ftype eq 'blob') {
5955                         my $blob_current = $file_hash;
5956                         my $blob_parent  = git_get_hash_by_path($commit, $file_name);
5957                         if (defined $blob_current && defined $blob_parent &&
5958                                         $blob_current ne $blob_parent) {
5959                                 print " | " .
5960                                         $cgi->a({-href => href(action=>"blobdiff",
5961                                                                hash=>$blob_current, hash_parent=>$blob_parent,
5962                                                                hash_base=>$hash_base, hash_parent_base=>$commit,
5963                                                                file_name=>$file_name)},
5964                                                 "diff to current");
5965                         }
5966                 }
5967                 print "</td>\n" .
5968                       "</tr>\n";
5969         }
5970         if (defined $extra) {
5971                 print "<tr>\n" .
5972                       "<td colspan=\"4\">$extra</td>\n" .
5973                       "</tr>\n";
5974         }
5975         print "</table>\n";
5976 }
5977
5978 sub git_tags_body {
5979         # uses global variable $project
5980         my ($taglist, $from, $to, $extra) = @_;
5981         $from = 0 unless defined $from;
5982         $to = $#{$taglist} if (!defined $to || $#{$taglist} < $to);
5983
5984         print "<table class=\"tags\">\n";
5985         my $alternate = 1;
5986         for (my $i = $from; $i <= $to; $i++) {
5987                 my $entry = $taglist->[$i];
5988                 my %tag = %$entry;
5989                 my $comment = $tag{'subject'};
5990                 my $comment_short;
5991                 if (defined $comment) {
5992                         $comment_short = chop_str($comment, 30, 5);
5993                 }
5994                 if ($alternate) {
5995                         print "<tr class=\"dark\">\n";
5996                 } else {
5997                         print "<tr class=\"light\">\n";
5998                 }
5999                 $alternate ^= 1;
6000                 if (defined $tag{'age'}) {
6001                         print "<td><i>$tag{'age'}</i></td>\n";
6002                 } else {
6003                         print "<td></td>\n";
6004                 }
6005                 print "<td>" .
6006                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'}),
6007                                -class => "list name"}, esc_html($tag{'name'})) .
6008                       "</td>\n" .
6009                       "<td>";
6010                 if (defined $comment) {
6011                         print format_subject_html($comment, $comment_short,
6012                                                   href(action=>"tag", hash=>$tag{'id'}));
6013                 }
6014                 print "</td>\n" .
6015                       "<td class=\"selflink\">";
6016                 if ($tag{'type'} eq "tag") {
6017                         print $cgi->a({-href => href(action=>"tag", hash=>$tag{'id'})}, "tag");
6018                 } else {
6019                         print "&nbsp;";
6020                 }
6021                 print "</td>\n" .
6022                       "<td class=\"link\">" . " | " .
6023                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'})}, $tag{'reftype'});
6024                 if ($tag{'reftype'} eq "commit") {
6025                         print " | " . $cgi->a({-href => href(action=>"shortlog", hash=>$tag{'fullname'})}, "shortlog") .
6026                               " | " . $cgi->a({-href => href(action=>"log", hash=>$tag{'fullname'})}, "log");
6027                 } elsif ($tag{'reftype'} eq "blob") {
6028                         print " | " . $cgi->a({-href => href(action=>"blob_plain", hash=>$tag{'refid'})}, "raw");
6029                 }
6030                 print "</td>\n" .
6031                       "</tr>";
6032         }
6033         if (defined $extra) {
6034                 print "<tr>\n" .
6035                       "<td colspan=\"5\">$extra</td>\n" .
6036                       "</tr>\n";
6037         }
6038         print "</table>\n";
6039 }
6040
6041 sub git_heads_body {
6042         # uses global variable $project
6043         my ($headlist, $head_at, $from, $to, $extra) = @_;
6044         $from = 0 unless defined $from;
6045         $to = $#{$headlist} if (!defined $to || $#{$headlist} < $to);
6046
6047         print "<table class=\"heads\">\n";
6048         my $alternate = 1;
6049         for (my $i = $from; $i <= $to; $i++) {
6050                 my $entry = $headlist->[$i];
6051                 my %ref = %$entry;
6052                 my $curr = defined $head_at && $ref{'id'} eq $head_at;
6053                 if ($alternate) {
6054                         print "<tr class=\"dark\">\n";
6055                 } else {
6056                         print "<tr class=\"light\">\n";
6057                 }
6058                 $alternate ^= 1;
6059                 print "<td><i>$ref{'age'}</i></td>\n" .
6060                       ($curr ? "<td class=\"current_head\">" : "<td>") .
6061                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'}),
6062                                -class => "list name"},esc_html($ref{'name'})) .
6063                       "</td>\n" .
6064                       "<td class=\"link\">" .
6065                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'})}, "shortlog") . " | " .
6066                       $cgi->a({-href => href(action=>"log", hash=>$ref{'fullname'})}, "log") . " | " .
6067                       $cgi->a({-href => href(action=>"tree", hash=>$ref{'fullname'}, hash_base=>$ref{'fullname'})}, "tree") .
6068                       "</td>\n" .
6069                       "</tr>";
6070         }
6071         if (defined $extra) {
6072                 print "<tr>\n" .
6073                       "<td colspan=\"3\">$extra</td>\n" .
6074                       "</tr>\n";
6075         }
6076         print "</table>\n";
6077 }
6078
6079 # Display a single remote block
6080 sub git_remote_block {
6081         my ($remote, $rdata, $limit, $head) = @_;
6082
6083         my $heads = $rdata->{'heads'};
6084         my $fetch = $rdata->{'fetch'};
6085         my $push = $rdata->{'push'};
6086
6087         my $urls_table = "<table class=\"projects_list\">\n" ;
6088
6089         if (defined $fetch) {
6090                 if ($fetch eq $push) {
6091                         $urls_table .= format_repo_url("URL", $fetch);
6092                 } else {
6093                         $urls_table .= format_repo_url("Fetch URL", $fetch);
6094                         $urls_table .= format_repo_url("Push URL", $push) if defined $push;
6095                 }
6096         } elsif (defined $push) {
6097                 $urls_table .= format_repo_url("Push URL", $push);
6098         } else {
6099                 $urls_table .= format_repo_url("", "No remote URL");
6100         }
6101
6102         $urls_table .= "</table>\n";
6103
6104         my $dots;
6105         if (defined $limit && $limit < @$heads) {
6106                 $dots = $cgi->a({-href => href(action=>"remotes", hash=>$remote)}, "...");
6107         }
6108
6109         print $urls_table;
6110         git_heads_body($heads, $head, 0, $limit, $dots);
6111 }
6112
6113 # Display a list of remote names with the respective fetch and push URLs
6114 sub git_remotes_list {
6115         my ($remotedata, $limit) = @_;
6116         print "<table class=\"heads\">\n";
6117         my $alternate = 1;
6118         my @remotes = sort keys %$remotedata;
6119
6120         my $limited = $limit && $limit < @remotes;
6121
6122         $#remotes = $limit - 1 if $limited;
6123
6124         while (my $remote = shift @remotes) {
6125                 my $rdata = $remotedata->{$remote};
6126                 my $fetch = $rdata->{'fetch'};
6127                 my $push = $rdata->{'push'};
6128                 if ($alternate) {
6129                         print "<tr class=\"dark\">\n";
6130                 } else {
6131                         print "<tr class=\"light\">\n";
6132                 }
6133                 $alternate ^= 1;
6134                 print "<td>" .
6135                       $cgi->a({-href=> href(action=>'remotes', hash=>$remote),
6136                                -class=> "list name"},esc_html($remote)) .
6137                       "</td>";
6138                 print "<td class=\"link\">" .
6139                       (defined $fetch ? $cgi->a({-href=> $fetch}, "fetch") : "fetch") .
6140                       " | " .
6141                       (defined $push ? $cgi->a({-href=> $push}, "push") : "push") .
6142                       "</td>";
6143
6144                 print "</tr>\n";
6145         }
6146
6147         if ($limited) {
6148                 print "<tr>\n" .
6149                       "<td colspan=\"3\">" .
6150                       $cgi->a({-href => href(action=>"remotes")}, "...") .
6151                       "</td>\n" . "</tr>\n";
6152         }
6153
6154         print "</table>";
6155 }
6156
6157 # Display remote heads grouped by remote, unless there are too many
6158 # remotes, in which case we only display the remote names
6159 sub git_remotes_body {
6160         my ($remotedata, $limit, $head) = @_;
6161         if ($limit and $limit < keys %$remotedata) {
6162                 git_remotes_list($remotedata, $limit);
6163         } else {
6164                 fill_remote_heads($remotedata);
6165                 while (my ($remote, $rdata) = each %$remotedata) {
6166                         git_print_section({-class=>"remote", -id=>$remote},
6167                                 ["remotes", $remote, $remote], sub {
6168                                         git_remote_block($remote, $rdata, $limit, $head);
6169                                 });
6170                 }
6171         }
6172 }
6173
6174 sub git_search_message {
6175         my %co = @_;
6176
6177         my $greptype;
6178         if ($searchtype eq 'commit') {
6179                 $greptype = "--grep=";
6180         } elsif ($searchtype eq 'author') {
6181                 $greptype = "--author=";
6182         } elsif ($searchtype eq 'committer') {
6183                 $greptype = "--committer=";
6184         }
6185         $greptype .= $searchtext;
6186         my @commitlist = parse_commits($hash, 101, (100 * $page), undef,
6187                                        $greptype, '--regexp-ignore-case',
6188                                        $search_use_regexp ? '--extended-regexp' : '--fixed-strings');
6189
6190         my $paging_nav = '';
6191         if ($page > 0) {
6192                 $paging_nav .=
6193                         $cgi->a({-href => href(-replay=>1, page=>undef)},
6194                                 "first") .
6195                         " &sdot; " .
6196                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
6197                                  -accesskey => "p", -title => "Alt-p"}, "prev");
6198         } else {
6199                 $paging_nav .= "first &sdot; prev";
6200         }
6201         my $next_link = '';
6202         if ($#commitlist >= 100) {
6203                 $next_link =
6204                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
6205                                  -accesskey => "n", -title => "Alt-n"}, "next");
6206                 $paging_nav .= " &sdot; $next_link";
6207         } else {
6208                 $paging_nav .= " &sdot; next";
6209         }
6210
6211         git_header_html();
6212
6213         git_print_page_nav('','', $hash,$co{'tree'},$hash, $paging_nav);
6214         git_print_header_div('commit', esc_html($co{'title'}), $hash);
6215         if ($page == 0 && !@commitlist) {
6216                 print "<p>No match.</p>\n";
6217         } else {
6218                 git_search_grep_body(\@commitlist, 0, 99, $next_link);
6219         }
6220
6221         git_footer_html();
6222 }
6223
6224 sub git_search_changes {
6225         my %co = @_;
6226
6227         local $/ = "\n";
6228         open my $fd, '-|', git_cmd(), '--no-pager', 'log', @diff_opts,
6229                 '--pretty=format:%H', '--no-abbrev', '--raw', "-S$searchtext",
6230                 ($search_use_regexp ? '--pickaxe-regex' : ())
6231                         or die_error(500, "Open git-log failed");
6232
6233         git_header_html();
6234
6235         git_print_page_nav('','', $hash,$co{'tree'},$hash);
6236         git_print_header_div('commit', esc_html($co{'title'}), $hash);
6237
6238         print "<table class=\"pickaxe search\">\n";
6239         my $alternate = 1;
6240         undef %co;
6241         my @files;
6242         while (my $line = <$fd>) {
6243                 chomp $line;
6244                 next unless $line;
6245
6246                 my %set = parse_difftree_raw_line($line);
6247                 if (defined $set{'commit'}) {
6248                         # finish previous commit
6249                         if (%co) {
6250                                 print "</td>\n" .
6251                                       "<td class=\"link\">" .
6252                                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
6253                                               "commit") .
6254                                       " | " .
6255                                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
6256                                                              hash_base=>$co{'id'})},
6257                                               "tree") .
6258                                       "</td>\n" .
6259                                       "</tr>\n";
6260                         }
6261
6262                         if ($alternate) {
6263                                 print "<tr class=\"dark\">\n";
6264                         } else {
6265                                 print "<tr class=\"light\">\n";
6266                         }
6267                         $alternate ^= 1;
6268                         %co = parse_commit($set{'commit'});
6269                         my $author = chop_and_escape_str($co{'author_name'}, 15, 5);
6270                         print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6271                               "<td><i>$author</i></td>\n" .
6272                               "<td>" .
6273                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
6274                                       -class => "list subject"},
6275                                       chop_and_escape_str($co{'title'}, 50) . "<br/>");
6276                 } elsif (defined $set{'to_id'}) {
6277                         next if ($set{'to_id'} =~ m/^0{40}$/);
6278
6279                         print $cgi->a({-href => href(action=>"blob", hash_base=>$co{'id'},
6280                                                      hash=>$set{'to_id'}, file_name=>$set{'to_file'}),
6281                                       -class => "list"},
6282                                       "<span class=\"match\">" . esc_path($set{'file'}) . "</span>") .
6283                               "<br/>\n";
6284                 }
6285         }
6286         close $fd;
6287
6288         # finish last commit (warning: repetition!)
6289         if (%co) {
6290                 print "</td>\n" .
6291                       "<td class=\"link\">" .
6292                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
6293                               "commit") .
6294                       " | " .
6295                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
6296                                              hash_base=>$co{'id'})},
6297                               "tree") .
6298                       "</td>\n" .
6299                       "</tr>\n";
6300         }
6301
6302         print "</table>\n";
6303
6304         git_footer_html();
6305 }
6306
6307 sub git_search_files {
6308         my %co = @_;
6309
6310         local $/ = "\n";
6311         open my $fd, "-|", git_cmd(), 'grep', '-n', '-z',
6312                 $search_use_regexp ? ('-E', '-i') : '-F',
6313                 $searchtext, $co{'tree'}
6314                         or die_error(500, "Open git-grep failed");
6315
6316         git_header_html();
6317
6318         git_print_page_nav('','', $hash,$co{'tree'},$hash);
6319         git_print_header_div('commit', esc_html($co{'title'}), $hash);
6320
6321         print "<table class=\"grep_search\">\n";
6322         my $alternate = 1;
6323         my $matches = 0;
6324         my $lastfile = '';
6325         my $file_href;
6326         while (my $line = <$fd>) {
6327                 chomp $line;
6328                 my ($file, $lno, $ltext, $binary);
6329                 last if ($matches++ > 1000);
6330                 if ($line =~ /^Binary file (.+) matches$/) {
6331                         $file = $1;
6332                         $binary = 1;
6333                 } else {
6334                         ($file, $lno, $ltext) = split(/\0/, $line, 3);
6335                         $file =~ s/^$co{'tree'}://;
6336                 }
6337                 if ($file ne $lastfile) {
6338                         $lastfile and print "</td></tr>\n";
6339                         if ($alternate++) {
6340                                 print "<tr class=\"dark\">\n";
6341                         } else {
6342                                 print "<tr class=\"light\">\n";
6343                         }
6344                         $file_href = href(action=>"blob", hash_base=>$co{'id'},
6345                                           file_name=>$file);
6346                         print "<td class=\"list\">".
6347                                 $cgi->a({-href => $file_href, -class => "list"}, esc_path($file));
6348                         print "</td><td>\n";
6349                         $lastfile = $file;
6350                 }
6351                 if ($binary) {
6352                         print "<div class=\"binary\">Binary file</div>\n";
6353                 } else {
6354                         $ltext = untabify($ltext);
6355                         if ($ltext =~ m/^(.*)($search_regexp)(.*)$/i) {
6356                                 $ltext = esc_html($1, -nbsp=>1);
6357                                 $ltext .= '<span class="match">';
6358                                 $ltext .= esc_html($2, -nbsp=>1);
6359                                 $ltext .= '</span>';
6360                                 $ltext .= esc_html($3, -nbsp=>1);
6361                         } else {
6362                                 $ltext = esc_html($ltext, -nbsp=>1);
6363                         }
6364                         print "<div class=\"pre\">" .
6365                                 $cgi->a({-href => $file_href.'#l'.$lno,
6366                                         -class => "linenr"}, sprintf('%4i', $lno)) .
6367                                 ' ' .  $ltext . "</div>\n";
6368                 }
6369         }
6370         if ($lastfile) {
6371                 print "</td></tr>\n";
6372                 if ($matches > 1000) {
6373                         print "<div class=\"diff nodifferences\">Too many matches, listing trimmed</div>\n";
6374                 }
6375         } else {
6376                 print "<div class=\"diff nodifferences\">No matches found</div>\n";
6377         }
6378         close $fd;
6379
6380         print "</table>\n";
6381
6382         git_footer_html();
6383 }
6384
6385 sub git_search_grep_body {
6386         my ($commitlist, $from, $to, $extra) = @_;
6387         $from = 0 unless defined $from;
6388         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
6389
6390         print "<table class=\"commit_search\">\n";
6391         my $alternate = 1;
6392         for (my $i = $from; $i <= $to; $i++) {
6393                 my %co = %{$commitlist->[$i]};
6394                 if (!%co) {
6395                         next;
6396                 }
6397                 my $commit = $co{'id'};
6398                 if ($alternate) {
6399                         print "<tr class=\"dark\">\n";
6400                 } else {
6401                         print "<tr class=\"light\">\n";
6402                 }
6403                 $alternate ^= 1;
6404                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6405                       format_author_html('td', \%co, 15, 5) .
6406                       "<td>" .
6407                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
6408                                -class => "list subject"},
6409                               chop_and_escape_str($co{'title'}, 50) . "<br/>");
6410                 my $comment = $co{'comment'};
6411                 foreach my $line (@$comment) {
6412                         if ($line =~ m/^(.*?)($search_regexp)(.*)$/i) {
6413                                 my ($lead, $match, $trail) = ($1, $2, $3);
6414                                 $match = chop_str($match, 70, 5, 'center');
6415                                 my $contextlen = int((80 - length($match))/2);
6416                                 $contextlen = 30 if ($contextlen > 30);
6417                                 $lead  = chop_str($lead,  $contextlen, 10, 'left');
6418                                 $trail = chop_str($trail, $contextlen, 10, 'right');
6419
6420                                 $lead  = esc_html($lead);
6421                                 $match = esc_html($match);
6422                                 $trail = esc_html($trail);
6423
6424                                 print "$lead<span class=\"match\">$match</span>$trail<br />";
6425                         }
6426                 }
6427                 print "</td>\n" .
6428                       "<td class=\"link\">" .
6429                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
6430                       " | " .
6431                       $cgi->a({-href => href(action=>"commitdiff", hash=>$co{'id'})}, "commitdiff") .
6432                       " | " .
6433                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
6434                 print "</td>\n" .
6435                       "</tr>\n";
6436         }
6437         if (defined $extra) {
6438                 print "<tr>\n" .
6439                       "<td colspan=\"3\">$extra</td>\n" .
6440                       "</tr>\n";
6441         }
6442         print "</table>\n";
6443 }
6444
6445 ## ======================================================================
6446 ## ======================================================================
6447 ## actions
6448
6449 sub git_project_list {
6450         my $order = $input_params{'order'};
6451         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
6452                 die_error(400, "Unknown order parameter");
6453         }
6454
6455         my @list = git_get_projects_list($project_filter, $strict_export);
6456         if (!@list) {
6457                 die_error(404, "No projects found");
6458         }
6459
6460         git_header_html();
6461         if (defined $home_text && -f $home_text) {
6462                 print "<div class=\"index_include\">\n";
6463                 insert_file($home_text);
6464                 print "</div>\n";
6465         }
6466
6467         git_project_search_form($searchtext, $search_use_regexp);
6468         git_project_list_body(\@list, $order);
6469         git_footer_html();
6470 }
6471
6472 sub git_forks {
6473         my $order = $input_params{'order'};
6474         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
6475                 die_error(400, "Unknown order parameter");
6476         }
6477
6478         my $filter = $project;
6479         $filter =~ s/\.git$//;
6480         my @list = git_get_projects_list($filter);
6481         if (!@list) {
6482                 die_error(404, "No forks found");
6483         }
6484
6485         git_header_html();
6486         git_print_page_nav('','');
6487         git_print_header_div('summary', "$project forks");
6488         git_project_list_body(\@list, $order);
6489         git_footer_html();
6490 }
6491
6492 sub git_project_index {
6493         my @projects = git_get_projects_list($project_filter, $strict_export);
6494         if (!@projects) {
6495                 die_error(404, "No projects found");
6496         }
6497
6498         print $cgi->header(
6499                 -type => 'text/plain',
6500                 -charset => 'utf-8',
6501                 -content_disposition => 'inline; filename="index.aux"');
6502
6503         foreach my $pr (@projects) {
6504                 if (!exists $pr->{'owner'}) {
6505                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}");
6506                 }
6507
6508                 my ($path, $owner) = ($pr->{'path'}, $pr->{'owner'});
6509                 # quote as in CGI::Util::encode, but keep the slash, and use '+' for ' '
6510                 $path  =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
6511                 $owner =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
6512                 $path  =~ s/ /\+/g;
6513                 $owner =~ s/ /\+/g;
6514
6515                 print "$path $owner\n";
6516         }
6517 }
6518
6519 sub git_summary {
6520         my $descr = git_get_project_description($project) || "none";
6521         my %co = parse_commit("HEAD");
6522         my %cd = %co ? parse_date($co{'committer_epoch'}, $co{'committer_tz'}) : ();
6523         my $head = $co{'id'};
6524         my $remote_heads = gitweb_check_feature('remote_heads');
6525
6526         my $owner = git_get_project_owner($project);
6527
6528         my $refs = git_get_references();
6529         # These get_*_list functions return one more to allow us to see if
6530         # there are more ...
6531         my @taglist  = git_get_tags_list(16);
6532         my @headlist = git_get_heads_list(16);
6533         my %remotedata = $remote_heads ? git_get_remotes_list() : ();
6534         my @forklist;
6535         my $check_forks = gitweb_check_feature('forks');
6536
6537         if ($check_forks) {
6538                 # find forks of a project
6539                 my $filter = $project;
6540                 $filter =~ s/\.git$//;
6541                 @forklist = git_get_projects_list($filter);
6542                 # filter out forks of forks
6543                 @forklist = filter_forks_from_projects_list(\@forklist)
6544                         if (@forklist);
6545         }
6546
6547         git_header_html();
6548         git_print_page_nav('summary','', $head);
6549
6550         print "<div class=\"title\">&nbsp;</div>\n";
6551         print "<table class=\"projects_list\">\n" .
6552               "<tr id=\"metadata_desc\"><td>description</td><td>" . esc_html($descr) . "</td></tr>\n";
6553         if ($owner and not $omit_owner) {
6554                 print  "<tr id=\"metadata_owner\"><td>owner</td><td>" . esc_html($owner) . "</td></tr>\n";
6555         }
6556         if (defined $cd{'rfc2822'}) {
6557                 print "<tr id=\"metadata_lchange\"><td>last change</td>" .
6558                       "<td>".format_timestamp_html(\%cd)."</td></tr>\n";
6559         }
6560
6561         # use per project git URL list in $projectroot/$project/cloneurl
6562         # or make project git URL from git base URL and project name
6563         my $url_tag = "URL";
6564         my @url_list = git_get_project_url_list($project);
6565         @url_list = map { "$_/$project" } @git_base_url_list unless @url_list;
6566         foreach my $git_url (@url_list) {
6567                 next unless $git_url;
6568                 print format_repo_url($url_tag, $git_url);
6569                 $url_tag = "";
6570         }
6571
6572         # Tag cloud
6573         my $show_ctags = gitweb_check_feature('ctags');
6574         if ($show_ctags) {
6575                 my $ctags = git_get_project_ctags($project);
6576                 if (%$ctags) {
6577                         # without ability to add tags, don't show if there are none
6578                         my $cloud = git_populate_project_tagcloud($ctags);
6579                         print "<tr id=\"metadata_ctags\">" .
6580                               "<td>content tags</td>" .
6581                               "<td>".git_show_project_tagcloud($cloud, 48)."</td>" .
6582                               "</tr>\n";
6583                 }
6584         }
6585
6586         print "</table>\n";
6587
6588         # If XSS prevention is on, we don't include README.html.
6589         # TODO: Allow a readme in some safe format.
6590         if (!$prevent_xss && -s "$projectroot/$project/README.html") {
6591                 print "<div class=\"title\">readme</div>\n" .
6592                       "<div class=\"readme\">\n";
6593                 insert_file("$projectroot/$project/README.html");
6594                 print "\n</div>\n"; # class="readme"
6595         }
6596
6597         # we need to request one more than 16 (0..15) to check if
6598         # those 16 are all
6599         my @commitlist = $head ? parse_commits($head, 17) : ();
6600         if (@commitlist) {
6601                 git_print_header_div('shortlog');
6602                 git_shortlog_body(\@commitlist, 0, 15, $refs,
6603                                   $#commitlist <=  15 ? undef :
6604                                   $cgi->a({-href => href(action=>"shortlog")}, "..."));
6605         }
6606
6607         if (@taglist) {
6608                 git_print_header_div('tags');
6609                 git_tags_body(\@taglist, 0, 15,
6610                               $#taglist <=  15 ? undef :
6611                               $cgi->a({-href => href(action=>"tags")}, "..."));
6612         }
6613
6614         if (@headlist) {
6615                 git_print_header_div('heads');
6616                 git_heads_body(\@headlist, $head, 0, 15,
6617                                $#headlist <= 15 ? undef :
6618                                $cgi->a({-href => href(action=>"heads")}, "..."));
6619         }
6620
6621         if (%remotedata) {
6622                 git_print_header_div('remotes');
6623                 git_remotes_body(\%remotedata, 15, $head);
6624         }
6625
6626         if (@forklist) {
6627                 git_print_header_div('forks');
6628                 git_project_list_body(\@forklist, 'age', 0, 15,
6629                                       $#forklist <= 15 ? undef :
6630                                       $cgi->a({-href => href(action=>"forks")}, "..."),
6631                                       'no_header');
6632         }
6633
6634         git_footer_html();
6635 }
6636
6637 sub git_tag {
6638         my %tag = parse_tag($hash);
6639
6640         if (! %tag) {
6641                 die_error(404, "Unknown tag object");
6642         }
6643
6644         my $head = git_get_head_hash($project);
6645         git_header_html();
6646         git_print_page_nav('','', $head,undef,$head);
6647         git_print_header_div('commit', esc_html($tag{'name'}), $hash);
6648         print "<div class=\"title_text\">\n" .
6649               "<table class=\"object_header\">\n" .
6650               "<tr>\n" .
6651               "<td>object</td>\n" .
6652               "<td>" . $cgi->a({-class => "list", -href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6653                                $tag{'object'}) . "</td>\n" .
6654               "<td class=\"link\">" . $cgi->a({-href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6655                                               $tag{'type'}) . "</td>\n" .
6656               "</tr>\n";
6657         if (defined($tag{'author'})) {
6658                 git_print_authorship_rows(\%tag, 'author');
6659         }
6660         print "</table>\n\n" .
6661               "</div>\n";
6662         print "<div class=\"page_body\">";
6663         my $comment = $tag{'comment'};
6664         foreach my $line (@$comment) {
6665                 chomp $line;
6666                 print esc_html($line, -nbsp=>1) . "<br/>\n";
6667         }
6668         print "</div>\n";
6669         git_footer_html();
6670 }
6671
6672 sub git_blame_common {
6673         my $format = shift || 'porcelain';
6674         if ($format eq 'porcelain' && $input_params{'javascript'}) {
6675                 $format = 'incremental';
6676                 $action = 'blame_incremental'; # for page title etc
6677         }
6678
6679         # permissions
6680         gitweb_check_feature('blame')
6681                 or die_error(403, "Blame view not allowed");
6682
6683         # error checking
6684         die_error(400, "No file name given") unless $file_name;
6685         $hash_base ||= git_get_head_hash($project);
6686         die_error(404, "Couldn't find base commit") unless $hash_base;
6687         my %co = parse_commit($hash_base)
6688                 or die_error(404, "Commit not found");
6689         my $ftype = "blob";
6690         if (!defined $hash) {
6691                 $hash = git_get_hash_by_path($hash_base, $file_name, "blob")
6692                         or die_error(404, "Error looking up file");
6693         } else {
6694                 $ftype = git_get_type($hash);
6695                 if ($ftype !~ "blob") {
6696                         die_error(400, "Object is not a blob");
6697                 }
6698         }
6699
6700         my $fd;
6701         if ($format eq 'incremental') {
6702                 # get file contents (as base)
6703                 open $fd, "-|", git_cmd(), 'cat-file', 'blob', $hash
6704                         or die_error(500, "Open git-cat-file failed");
6705         } elsif ($format eq 'data') {
6706                 # run git-blame --incremental
6707                 open $fd, "-|", git_cmd(), "blame", "--incremental",
6708                         $hash_base, "--", $file_name
6709                         or die_error(500, "Open git-blame --incremental failed");
6710         } else {
6711                 # run git-blame --porcelain
6712                 open $fd, "-|", git_cmd(), "blame", '-p',
6713                         $hash_base, '--', $file_name
6714                         or die_error(500, "Open git-blame --porcelain failed");
6715         }
6716         binmode $fd, ':utf8';
6717
6718         # incremental blame data returns early
6719         if ($format eq 'data') {
6720                 print $cgi->header(
6721                         -type=>"text/plain", -charset => "utf-8",
6722                         -status=> "200 OK");
6723                 local $| = 1; # output autoflush
6724                 while (my $line = <$fd>) {
6725                         print to_utf8($line);
6726                 }
6727                 close $fd
6728                         or print "ERROR $!\n";
6729
6730                 print 'END';
6731                 if (defined $t0 && gitweb_check_feature('timed')) {
6732                         print ' '.
6733                               tv_interval($t0, [ gettimeofday() ]).
6734                               ' '.$number_of_git_cmds;
6735                 }
6736                 print "\n";
6737
6738                 return;
6739         }
6740
6741         # page header
6742         git_header_html();
6743         my $formats_nav =
6744                 $cgi->a({-href => href(action=>"blob", -replay=>1)},
6745                         "blob") .
6746                 " | ";
6747         if ($format eq 'incremental') {
6748                 $formats_nav .=
6749                         $cgi->a({-href => href(action=>"blame", javascript=>0, -replay=>1)},
6750                                 "blame") . " (non-incremental)";
6751         } else {
6752                 $formats_nav .=
6753                         $cgi->a({-href => href(action=>"blame_incremental", -replay=>1)},
6754                                 "blame") . " (incremental)";
6755         }
6756         $formats_nav .=
6757                 " | " .
6758                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6759                         "history") .
6760                 " | " .
6761                 $cgi->a({-href => href(action=>$action, file_name=>$file_name)},
6762                         "HEAD");
6763         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6764         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6765         git_print_page_path($file_name, $ftype, $hash_base);
6766
6767         # page body
6768         if ($format eq 'incremental') {
6769                 print "<noscript>\n<div class=\"error\"><center><b>\n".
6770                       "This page requires JavaScript to run.\n Use ".
6771                       $cgi->a({-href => href(action=>'blame',javascript=>0,-replay=>1)},
6772                               'this page').
6773                       " instead.\n".
6774                       "</b></center></div>\n</noscript>\n";
6775
6776                 print qq!<div id="progress_bar" style="width: 100%; background-color: yellow"></div>\n!;
6777         }
6778
6779         print qq!<div class="page_body">\n!;
6780         print qq!<div id="progress_info">... / ...</div>\n!
6781                 if ($format eq 'incremental');
6782         print qq!<table id="blame_table" class="blame" width="100%">\n!.
6783               #qq!<col width="5.5em" /><col width="2.5em" /><col width="*" />\n!.
6784               qq!<thead>\n!.
6785               qq!<tr><th>Commit</th><th>Line</th><th>Data</th></tr>\n!.
6786               qq!</thead>\n!.
6787               qq!<tbody>\n!;
6788
6789         my @rev_color = qw(light dark);
6790         my $num_colors = scalar(@rev_color);
6791         my $current_color = 0;
6792
6793         if ($format eq 'incremental') {
6794                 my $color_class = $rev_color[$current_color];
6795
6796                 #contents of a file
6797                 my $linenr = 0;
6798         LINE:
6799                 while (my $line = <$fd>) {
6800                         chomp $line;
6801                         $linenr++;
6802
6803                         print qq!<tr id="l$linenr" class="$color_class">!.
6804                               qq!<td class="sha1"><a href=""> </a></td>!.
6805                               qq!<td class="linenr">!.
6806                               qq!<a class="linenr" href="">$linenr</a></td>!;
6807                         print qq!<td class="pre">! . esc_html($line) . "</td>\n";
6808                         print qq!</tr>\n!;
6809                 }
6810
6811         } else { # porcelain, i.e. ordinary blame
6812                 my %metainfo = (); # saves information about commits
6813
6814                 # blame data
6815         LINE:
6816                 while (my $line = <$fd>) {
6817                         chomp $line;
6818                         # the header: <SHA-1> <src lineno> <dst lineno> [<lines in group>]
6819                         # no <lines in group> for subsequent lines in group of lines
6820                         my ($full_rev, $orig_lineno, $lineno, $group_size) =
6821                            ($line =~ /^([0-9a-f]{40}) (\d+) (\d+)(?: (\d+))?$/);
6822                         if (!exists $metainfo{$full_rev}) {
6823                                 $metainfo{$full_rev} = { 'nprevious' => 0 };
6824                         }
6825                         my $meta = $metainfo{$full_rev};
6826                         my $data;
6827                         while ($data = <$fd>) {
6828                                 chomp $data;
6829                                 last if ($data =~ s/^\t//); # contents of line
6830                                 if ($data =~ /^(\S+)(?: (.*))?$/) {
6831                                         $meta->{$1} = $2 unless exists $meta->{$1};
6832                                 }
6833                                 if ($data =~ /^previous /) {
6834                                         $meta->{'nprevious'}++;
6835                                 }
6836                         }
6837                         my $short_rev = substr($full_rev, 0, 8);
6838                         my $author = $meta->{'author'};
6839                         my %date =
6840                                 parse_date($meta->{'author-time'}, $meta->{'author-tz'});
6841                         my $date = $date{'iso-tz'};
6842                         if ($group_size) {
6843                                 $current_color = ($current_color + 1) % $num_colors;
6844                         }
6845                         my $tr_class = $rev_color[$current_color];
6846                         $tr_class .= ' boundary' if (exists $meta->{'boundary'});
6847                         $tr_class .= ' no-previous' if ($meta->{'nprevious'} == 0);
6848                         $tr_class .= ' multiple-previous' if ($meta->{'nprevious'} > 1);
6849                         print "<tr id=\"l$lineno\" class=\"$tr_class\">\n";
6850                         if ($group_size) {
6851                                 print "<td class=\"sha1\"";
6852                                 print " title=\"". esc_html($author) . ", $date\"";
6853                                 print " rowspan=\"$group_size\"" if ($group_size > 1);
6854                                 print ">";
6855                                 print $cgi->a({-href => href(action=>"commit",
6856                                                              hash=>$full_rev,
6857                                                              file_name=>$file_name)},
6858                                               esc_html($short_rev));
6859                                 if ($group_size >= 2) {
6860                                         my @author_initials = ($author =~ /\b([[:upper:]])\B/g);
6861                                         if (@author_initials) {
6862                                                 print "<br />" .
6863                                                       esc_html(join('', @author_initials));
6864                                                 #           or join('.', ...)
6865                                         }
6866                                 }
6867                                 print "</td>\n";
6868                         }
6869                         # 'previous' <sha1 of parent commit> <filename at commit>
6870                         if (exists $meta->{'previous'} &&
6871                             $meta->{'previous'} =~ /^([a-fA-F0-9]{40}) (.*)$/) {
6872                                 $meta->{'parent'} = $1;
6873                                 $meta->{'file_parent'} = unquote($2);
6874                         }
6875                         my $linenr_commit =
6876                                 exists($meta->{'parent'}) ?
6877                                 $meta->{'parent'} : $full_rev;
6878                         my $linenr_filename =
6879                                 exists($meta->{'file_parent'}) ?
6880                                 $meta->{'file_parent'} : unquote($meta->{'filename'});
6881                         my $blamed = href(action => 'blame',
6882                                           file_name => $linenr_filename,
6883                                           hash_base => $linenr_commit);
6884                         print "<td class=\"linenr\">";
6885                         print $cgi->a({ -href => "$blamed#l$orig_lineno",
6886                                         -class => "linenr" },
6887                                       esc_html($lineno));
6888                         print "</td>";
6889                         print "<td class=\"pre\">" . esc_html($data) . "</td>\n";
6890                         print "</tr>\n";
6891                 } # end while
6892
6893         }
6894
6895         # footer
6896         print "</tbody>\n".
6897               "</table>\n"; # class="blame"
6898         print "</div>\n";   # class="blame_body"
6899         close $fd
6900                 or print "Reading blob failed\n";
6901
6902         git_footer_html();
6903 }
6904
6905 sub git_blame {
6906         git_blame_common();
6907 }
6908
6909 sub git_blame_incremental {
6910         git_blame_common('incremental');
6911 }
6912
6913 sub git_blame_data {
6914         git_blame_common('data');
6915 }
6916
6917 sub git_tags {
6918         my $head = git_get_head_hash($project);
6919         git_header_html();
6920         git_print_page_nav('','', $head,undef,$head,format_ref_views('tags'));
6921         git_print_header_div('summary', $project);
6922
6923         my @tagslist = git_get_tags_list();
6924         if (@tagslist) {
6925                 git_tags_body(\@tagslist);
6926         }
6927         git_footer_html();
6928 }
6929
6930 sub git_heads {
6931         my $head = git_get_head_hash($project);
6932         git_header_html();
6933         git_print_page_nav('','', $head,undef,$head,format_ref_views('heads'));
6934         git_print_header_div('summary', $project);
6935
6936         my @headslist = git_get_heads_list();
6937         if (@headslist) {
6938                 git_heads_body(\@headslist, $head);
6939         }
6940         git_footer_html();
6941 }
6942
6943 # used both for single remote view and for list of all the remotes
6944 sub git_remotes {
6945         gitweb_check_feature('remote_heads')
6946                 or die_error(403, "Remote heads view is disabled");
6947
6948         my $head = git_get_head_hash($project);
6949         my $remote = $input_params{'hash'};
6950
6951         my $remotedata = git_get_remotes_list($remote);
6952         die_error(500, "Unable to get remote information") unless defined $remotedata;
6953
6954         unless (%$remotedata) {
6955                 die_error(404, defined $remote ?
6956                         "Remote $remote not found" :
6957                         "No remotes found");
6958         }
6959
6960         git_header_html(undef, undef, -action_extra => $remote);
6961         git_print_page_nav('', '',  $head, undef, $head,
6962                 format_ref_views($remote ? '' : 'remotes'));
6963
6964         fill_remote_heads($remotedata);
6965         if (defined $remote) {
6966                 git_print_header_div('remotes', "$remote remote for $project");
6967                 git_remote_block($remote, $remotedata->{$remote}, undef, $head);
6968         } else {
6969                 git_print_header_div('summary', "$project remotes");
6970                 git_remotes_body($remotedata, undef, $head);
6971         }
6972
6973         git_footer_html();
6974 }
6975
6976 sub git_blob_plain {
6977         my $type = shift;
6978         my $expires;
6979
6980         if (!defined $hash) {
6981                 if (defined $file_name) {
6982                         my $base = $hash_base || git_get_head_hash($project);
6983                         $hash = git_get_hash_by_path($base, $file_name, "blob")
6984                                 or die_error(404, "Cannot find file");
6985                 } else {
6986                         die_error(400, "No file name defined");
6987                 }
6988         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6989                 # blobs defined by non-textual hash id's can be cached
6990                 $expires = "+1d";
6991         }
6992
6993         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
6994                 or die_error(500, "Open git-cat-file blob '$hash' failed");
6995
6996         # content-type (can include charset)
6997         $type = blob_contenttype($fd, $file_name, $type);
6998
6999         # "save as" filename, even when no $file_name is given
7000         my $save_as = "$hash";
7001         if (defined $file_name) {
7002                 $save_as = $file_name;
7003         } elsif ($type =~ m/^text\//) {
7004                 $save_as .= '.txt';
7005         }
7006
7007         # With XSS prevention on, blobs of all types except a few known safe
7008         # ones are served with "Content-Disposition: attachment" to make sure
7009         # they don't run in our security domain.  For certain image types,
7010         # blob view writes an <img> tag referring to blob_plain view, and we
7011         # want to be sure not to break that by serving the image as an
7012         # attachment (though Firefox 3 doesn't seem to care).
7013         my $sandbox = $prevent_xss &&
7014                 $type !~ m!^(?:text/[a-z]+|image/(?:gif|png|jpeg))(?:[ ;]|$)!;
7015
7016         # serve text/* as text/plain
7017         if ($prevent_xss &&
7018             ($type =~ m!^text/[a-z]+\b(.*)$! ||
7019              ($type =~ m!^[a-z]+/[a-z]\+xml\b(.*)$! && -T $fd))) {
7020                 my $rest = $1;
7021                 $rest = defined $rest ? $rest : '';
7022                 $type = "text/plain$rest";
7023         }
7024
7025         print $cgi->header(
7026                 -type => $type,
7027                 -expires => $expires,
7028                 -content_disposition =>
7029                         ($sandbox ? 'attachment' : 'inline')
7030                         . '; filename="' . $save_as . '"');
7031         local $/ = undef;
7032         binmode STDOUT, ':raw';
7033         print <$fd>;
7034         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
7035         close $fd;
7036 }
7037
7038 sub git_blob {
7039         my $expires;
7040
7041         if (!defined $hash) {
7042                 if (defined $file_name) {
7043                         my $base = $hash_base || git_get_head_hash($project);
7044                         $hash = git_get_hash_by_path($base, $file_name, "blob")
7045                                 or die_error(404, "Cannot find file");
7046                 } else {
7047                         die_error(400, "No file name defined");
7048                 }
7049         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7050                 # blobs defined by non-textual hash id's can be cached
7051                 $expires = "+1d";
7052         }
7053
7054         my $have_blame = gitweb_check_feature('blame');
7055         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
7056                 or die_error(500, "Couldn't cat $file_name, $hash");
7057         my $mimetype = blob_mimetype($fd, $file_name);
7058         # use 'blob_plain' (aka 'raw') view for files that cannot be displayed
7059         if ($mimetype !~ m!^(?:text/|image/(?:gif|png|jpeg)$)! && -B $fd) {
7060                 close $fd;
7061                 return git_blob_plain($mimetype);
7062         }
7063         # we can have blame only for text/* mimetype
7064         $have_blame &&= ($mimetype =~ m!^text/!);
7065
7066         my $highlight = gitweb_check_feature('highlight');
7067         my $syntax = guess_file_syntax($highlight, $file_name);
7068         $fd = run_highlighter($fd, $highlight, $syntax);
7069
7070         git_header_html(undef, $expires);
7071         my $formats_nav = '';
7072         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7073                 if (defined $file_name) {
7074                         if ($have_blame) {
7075                                 $formats_nav .=
7076                                         $cgi->a({-href => href(action=>"blame", -replay=>1)},
7077                                                 "blame") .
7078                                         " | ";
7079                         }
7080                         $formats_nav .=
7081                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
7082                                         "history") .
7083                                 " | " .
7084                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
7085                                         "raw") .
7086                                 " | " .
7087                                 $cgi->a({-href => href(action=>"blob",
7088                                                        hash_base=>"HEAD", file_name=>$file_name)},
7089                                         "HEAD");
7090                 } else {
7091                         $formats_nav .=
7092                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
7093                                         "raw");
7094                 }
7095                 git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
7096                 git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
7097         } else {
7098                 print "<div class=\"page_nav\">\n" .
7099                       "<br/><br/></div>\n" .
7100                       "<div class=\"title\">".esc_html($hash)."</div>\n";
7101         }
7102         git_print_page_path($file_name, "blob", $hash_base);
7103         print "<div class=\"page_body\">\n";
7104         if ($mimetype =~ m!^image/!) {
7105                 print qq!<img class="blob" type="!.esc_attr($mimetype).qq!"!;
7106                 if ($file_name) {
7107                         print qq! alt="!.esc_attr($file_name).qq!" title="!.esc_attr($file_name).qq!"!;
7108                 }
7109                 print qq! src="! .
7110                       href(action=>"blob_plain", hash=>$hash,
7111                            hash_base=>$hash_base, file_name=>$file_name) .
7112                       qq!" />\n!;
7113         } else {
7114                 my $nr;
7115                 while (my $line = <$fd>) {
7116                         chomp $line;
7117                         $nr++;
7118                         $line = untabify($line);
7119                         printf qq!<div class="pre"><a id="l%i" href="%s#l%i" class="linenr">%4i</a> %s</div>\n!,
7120                                $nr, esc_attr(href(-replay => 1)), $nr, $nr,
7121                                $highlight ? sanitize($line) : esc_html($line, -nbsp=>1);
7122                 }
7123         }
7124         close $fd
7125                 or print "Reading blob failed.\n";
7126         print "</div>";
7127         git_footer_html();
7128 }
7129
7130 sub git_tree {
7131         if (!defined $hash_base) {
7132                 $hash_base = "HEAD";
7133         }
7134         if (!defined $hash) {
7135                 if (defined $file_name) {
7136                         $hash = git_get_hash_by_path($hash_base, $file_name, "tree");
7137                 } else {
7138                         $hash = $hash_base;
7139                 }
7140         }
7141         die_error(404, "No such tree") unless defined($hash);
7142
7143         my $show_sizes = gitweb_check_feature('show-sizes');
7144         my $have_blame = gitweb_check_feature('blame');
7145
7146         my @entries = ();
7147         {
7148                 local $/ = "\0";
7149                 open my $fd, "-|", git_cmd(), "ls-tree", '-z',
7150                         ($show_sizes ? '-l' : ()), @extra_options, $hash
7151                         or die_error(500, "Open git-ls-tree failed");
7152                 @entries = map { chomp; $_ } <$fd>;
7153                 close $fd
7154                         or die_error(404, "Reading tree failed");
7155         }
7156
7157         my $refs = git_get_references();
7158         my $ref = format_ref_marker($refs, $hash_base);
7159         git_header_html();
7160         my $basedir = '';
7161         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7162                 my @views_nav = ();
7163                 if (defined $file_name) {
7164                         push @views_nav,
7165                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
7166                                         "history"),
7167                                 $cgi->a({-href => href(action=>"tree",
7168                                                        hash_base=>"HEAD", file_name=>$file_name)},
7169                                         "HEAD"),
7170                 }
7171                 my $snapshot_links = format_snapshot_links($hash);
7172                 if (defined $snapshot_links) {
7173                         # FIXME: Should be available when we have no hash base as well.
7174                         push @views_nav, $snapshot_links;
7175                 }
7176                 git_print_page_nav('tree','', $hash_base, undef, undef,
7177                                    join(' | ', @views_nav));
7178                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash_base);
7179         } else {
7180                 undef $hash_base;
7181                 print "<div class=\"page_nav\">\n";
7182                 print "<br/><br/></div>\n";
7183                 print "<div class=\"title\">".esc_html($hash)."</div>\n";
7184         }
7185         if (defined $file_name) {
7186                 $basedir = $file_name;
7187                 if ($basedir ne '' && substr($basedir, -1) ne '/') {
7188                         $basedir .= '/';
7189                 }
7190                 git_print_page_path($file_name, 'tree', $hash_base);
7191         }
7192         print "<div class=\"page_body\">\n";
7193         print "<table class=\"tree\">\n";
7194         my $alternate = 1;
7195         # '..' (top directory) link if possible
7196         if (defined $hash_base &&
7197             defined $file_name && $file_name =~ m![^/]+$!) {
7198                 if ($alternate) {
7199                         print "<tr class=\"dark\">\n";
7200                 } else {
7201                         print "<tr class=\"light\">\n";
7202                 }
7203                 $alternate ^= 1;
7204
7205                 my $up = $file_name;
7206                 $up =~ s!/?[^/]+$!!;
7207                 undef $up unless $up;
7208                 # based on git_print_tree_entry
7209                 print '<td class="mode">' . mode_str('040000') . "</td>\n";
7210                 print '<td class="size">&nbsp;</td>'."\n" if $show_sizes;
7211                 print '<td class="list">';
7212                 print $cgi->a({-href => href(action=>"tree",
7213                                              hash_base=>$hash_base,
7214                                              file_name=>$up)},
7215                               "..");
7216                 print "</td>\n";
7217                 print "<td class=\"link\"></td>\n";
7218
7219                 print "</tr>\n";
7220         }
7221         foreach my $line (@entries) {
7222                 my %t = parse_ls_tree_line($line, -z => 1, -l => $show_sizes);
7223
7224                 if ($alternate) {
7225                         print "<tr class=\"dark\">\n";
7226                 } else {
7227                         print "<tr class=\"light\">\n";
7228                 }
7229                 $alternate ^= 1;
7230
7231                 git_print_tree_entry(\%t, $basedir, $hash_base, $have_blame);
7232
7233                 print "</tr>\n";
7234         }
7235         print "</table>\n" .
7236               "</div>";
7237         git_footer_html();
7238 }
7239
7240 sub sanitize_for_filename {
7241     my $name = shift;
7242
7243     $name =~ s!/!-!g;
7244     $name =~ s/[^[:alnum:]_.-]//g;
7245
7246     return $name;
7247 }
7248
7249 sub snapshot_name {
7250         my ($project, $hash) = @_;
7251
7252         # path/to/project.git  -> project
7253         # path/to/project/.git -> project
7254         my $name = to_utf8($project);
7255         $name =~ s,([^/])/*\.git$,$1,;
7256         $name = sanitize_for_filename(basename($name));
7257
7258         my $ver = $hash;
7259         if ($hash =~ /^[0-9a-fA-F]+$/) {
7260                 # shorten SHA-1 hash
7261                 my $full_hash = git_get_full_hash($project, $hash);
7262                 if ($full_hash =~ /^$hash/ && length($hash) > 7) {
7263                         $ver = git_get_short_hash($project, $hash);
7264                 }
7265         } elsif ($hash =~ m!^refs/tags/(.*)$!) {
7266                 # tags don't need shortened SHA-1 hash
7267                 $ver = $1;
7268         } else {
7269                 # branches and other need shortened SHA-1 hash
7270                 my $strip_refs = join '|', map { quotemeta } get_branch_refs();
7271                 if ($hash =~ m!^refs/($strip_refs|remotes)/(.*)$!) {
7272                         my $ref_dir = (defined $1) ? $1 : '';
7273                         $ver = $2;
7274
7275                         $ref_dir = sanitize_for_filename($ref_dir);
7276                         # for refs neither in heads nor remotes we want to
7277                         # add a ref dir to archive name
7278                         if ($ref_dir ne '' and $ref_dir ne 'heads' and $ref_dir ne 'remotes') {
7279                                 $ver = $ref_dir . '-' . $ver;
7280                         }
7281                 }
7282                 $ver .= '-' . git_get_short_hash($project, $hash);
7283         }
7284         # special case of sanitization for filename - we change
7285         # slashes to dots instead of dashes
7286         # in case of hierarchical branch names
7287         $ver =~ s!/!.!g;
7288         $ver =~ s/[^[:alnum:]_.-]//g;
7289
7290         # name = project-version_string
7291         $name = "$name-$ver";
7292
7293         return wantarray ? ($name, $name) : $name;
7294 }
7295
7296 sub exit_if_unmodified_since {
7297         my ($latest_epoch) = @_;
7298         our $cgi;
7299
7300         my $if_modified = $cgi->http('IF_MODIFIED_SINCE');
7301         if (defined $if_modified) {
7302                 my $since;
7303                 if (eval { require HTTP::Date; 1; }) {
7304                         $since = HTTP::Date::str2time($if_modified);
7305                 } elsif (eval { require Time::ParseDate; 1; }) {
7306                         $since = Time::ParseDate::parsedate($if_modified, GMT => 1);
7307                 }
7308                 if (defined $since && $latest_epoch <= $since) {
7309                         my %latest_date = parse_date($latest_epoch);
7310                         print $cgi->header(
7311                                 -last_modified => $latest_date{'rfc2822'},
7312                                 -status => '304 Not Modified');
7313                         goto DONE_GITWEB;
7314                 }
7315         }
7316 }
7317
7318 sub git_snapshot {
7319         my $format = $input_params{'snapshot_format'};
7320         if (!@snapshot_fmts) {
7321                 die_error(403, "Snapshots not allowed");
7322         }
7323         # default to first supported snapshot format
7324         $format ||= $snapshot_fmts[0];
7325         if ($format !~ m/^[a-z0-9]+$/) {
7326                 die_error(400, "Invalid snapshot format parameter");
7327         } elsif (!exists($known_snapshot_formats{$format})) {
7328                 die_error(400, "Unknown snapshot format");
7329         } elsif ($known_snapshot_formats{$format}{'disabled'}) {
7330                 die_error(403, "Snapshot format not allowed");
7331         } elsif (!grep($_ eq $format, @snapshot_fmts)) {
7332                 die_error(403, "Unsupported snapshot format");
7333         }
7334
7335         my $type = git_get_type("$hash^{}");
7336         if (!$type) {
7337                 die_error(404, 'Object does not exist');
7338         }  elsif ($type eq 'blob') {
7339                 die_error(400, 'Object is not a tree-ish');
7340         }
7341
7342         my ($name, $prefix) = snapshot_name($project, $hash);
7343         my $filename = "$name$known_snapshot_formats{$format}{'suffix'}";
7344
7345         my %co = parse_commit($hash);
7346         exit_if_unmodified_since($co{'committer_epoch'}) if %co;
7347
7348         my $cmd = quote_command(
7349                 git_cmd(), 'archive',
7350                 "--format=$known_snapshot_formats{$format}{'format'}",
7351                 "--prefix=$prefix/", $hash);
7352         if (exists $known_snapshot_formats{$format}{'compressor'}) {
7353                 $cmd .= ' | ' . quote_command(@{$known_snapshot_formats{$format}{'compressor'}});
7354         }
7355
7356         $filename =~ s/(["\\])/\\$1/g;
7357         my %latest_date;
7358         if (%co) {
7359                 %latest_date = parse_date($co{'committer_epoch'}, $co{'committer_tz'});
7360         }
7361
7362         print $cgi->header(
7363                 -type => $known_snapshot_formats{$format}{'type'},
7364                 -content_disposition => 'inline; filename="' . $filename . '"',
7365                 %co ? (-last_modified => $latest_date{'rfc2822'}) : (),
7366                 -status => '200 OK');
7367
7368         open my $fd, "-|", $cmd
7369                 or die_error(500, "Execute git-archive failed");
7370         binmode STDOUT, ':raw';
7371         print <$fd>;
7372         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
7373         close $fd;
7374 }
7375
7376 sub git_log_generic {
7377         my ($fmt_name, $body_subr, $base, $parent, $file_name, $file_hash) = @_;
7378
7379         my $head = git_get_head_hash($project);
7380         if (!defined $base) {
7381                 $base = $head;
7382         }
7383         if (!defined $page) {
7384                 $page = 0;
7385         }
7386         my $refs = git_get_references();
7387
7388         my $commit_hash = $base;
7389         if (defined $parent) {
7390                 $commit_hash = "$parent..$base";
7391         }
7392         my @commitlist =
7393                 parse_commits($commit_hash, 101, (100 * $page),
7394                               defined $file_name ? ($file_name, "--full-history") : ());
7395
7396         my $ftype;
7397         if (!defined $file_hash && defined $file_name) {
7398                 # some commits could have deleted file in question,
7399                 # and not have it in tree, but one of them has to have it
7400                 for (my $i = 0; $i < @commitlist; $i++) {
7401                         $file_hash = git_get_hash_by_path($commitlist[$i]{'id'}, $file_name);
7402                         last if defined $file_hash;
7403                 }
7404         }
7405         if (defined $file_hash) {
7406                 $ftype = git_get_type($file_hash);
7407         }
7408         if (defined $file_name && !defined $ftype) {
7409                 die_error(500, "Unknown type of object");
7410         }
7411         my %co;
7412         if (defined $file_name) {
7413                 %co = parse_commit($base)
7414                         or die_error(404, "Unknown commit object");
7415         }
7416
7417
7418         my $paging_nav = format_paging_nav($fmt_name, $page, $#commitlist >= 100);
7419         my $next_link = '';
7420         if ($#commitlist >= 100) {
7421                 $next_link =
7422                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
7423                                  -accesskey => "n", -title => "Alt-n"}, "next");
7424         }
7425         my $patch_max = gitweb_get_feature('patches');
7426         if ($patch_max && !defined $file_name) {
7427                 if ($patch_max < 0 || @commitlist <= $patch_max) {
7428                         $paging_nav .= " &sdot; " .
7429                                 $cgi->a({-href => href(action=>"patches", -replay=>1)},
7430                                         "patches");
7431                 }
7432         }
7433
7434         git_header_html();
7435         git_print_page_nav($fmt_name,'', $hash,$hash,$hash, $paging_nav);
7436         if (defined $file_name) {
7437                 git_print_header_div('commit', esc_html($co{'title'}), $base);
7438         } else {
7439                 git_print_header_div('summary', $project)
7440         }
7441         git_print_page_path($file_name, $ftype, $hash_base)
7442                 if (defined $file_name);
7443
7444         $body_subr->(\@commitlist, 0, 99, $refs, $next_link,
7445                      $file_name, $file_hash, $ftype);
7446
7447         git_footer_html();
7448 }
7449
7450 sub git_log {
7451         git_log_generic('log', \&git_log_body,
7452                         $hash, $hash_parent);
7453 }
7454
7455 sub git_commit {
7456         $hash ||= $hash_base || "HEAD";
7457         my %co = parse_commit($hash)
7458             or die_error(404, "Unknown commit object");
7459
7460         my $parent  = $co{'parent'};
7461         my $parents = $co{'parents'}; # listref
7462
7463         # we need to prepare $formats_nav before any parameter munging
7464         my $formats_nav;
7465         if (!defined $parent) {
7466                 # --root commitdiff
7467                 $formats_nav .= '(initial)';
7468         } elsif (@$parents == 1) {
7469                 # single parent commit
7470                 $formats_nav .=
7471                         '(parent: ' .
7472                         $cgi->a({-href => href(action=>"commit",
7473                                                hash=>$parent)},
7474                                 esc_html(substr($parent, 0, 7))) .
7475                         ')';
7476         } else {
7477                 # merge commit
7478                 $formats_nav .=
7479                         '(merge: ' .
7480                         join(' ', map {
7481                                 $cgi->a({-href => href(action=>"commit",
7482                                                        hash=>$_)},
7483                                         esc_html(substr($_, 0, 7)));
7484                         } @$parents ) .
7485                         ')';
7486         }
7487         if (gitweb_check_feature('patches') && @$parents <= 1) {
7488                 $formats_nav .= " | " .
7489                         $cgi->a({-href => href(action=>"patch", -replay=>1)},
7490                                 "patch");
7491         }
7492
7493         if (!defined $parent) {
7494                 $parent = "--root";
7495         }
7496         my @difftree;
7497         open my $fd, "-|", git_cmd(), "diff-tree", '-r', "--no-commit-id",
7498                 @diff_opts,
7499                 (@$parents <= 1 ? $parent : '-c'),
7500                 $hash, "--"
7501                 or die_error(500, "Open git-diff-tree failed");
7502         @difftree = map { chomp; $_ } <$fd>;
7503         close $fd or die_error(404, "Reading git-diff-tree failed");
7504
7505         # non-textual hash id's can be cached
7506         my $expires;
7507         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7508                 $expires = "+1d";
7509         }
7510         my $refs = git_get_references();
7511         my $ref = format_ref_marker($refs, $co{'id'});
7512
7513         git_header_html(undef, $expires);
7514         git_print_page_nav('commit', '',
7515                            $hash, $co{'tree'}, $hash,
7516                            $formats_nav);
7517
7518         if (defined $co{'parent'}) {
7519                 git_print_header_div('commitdiff', esc_html($co{'title'}) . $ref, $hash);
7520         } else {
7521                 git_print_header_div('tree', esc_html($co{'title'}) . $ref, $co{'tree'}, $hash);
7522         }
7523         print "<div class=\"title_text\">\n" .
7524               "<table class=\"object_header\">\n";
7525         git_print_authorship_rows(\%co);
7526         print "<tr><td>commit</td><td class=\"sha1\">$co{'id'}</td></tr>\n";
7527         print "<tr>" .
7528               "<td>tree</td>" .
7529               "<td class=\"sha1\">" .
7530               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash),
7531                        class => "list"}, $co{'tree'}) .
7532               "</td>" .
7533               "<td class=\"link\">" .
7534               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash)},
7535                       "tree");
7536         my $snapshot_links = format_snapshot_links($hash);
7537         if (defined $snapshot_links) {
7538                 print " | " . $snapshot_links;
7539         }
7540         print "</td>" .
7541               "</tr>\n";
7542
7543         foreach my $par (@$parents) {
7544                 print "<tr>" .
7545                       "<td>parent</td>" .
7546                       "<td class=\"sha1\">" .
7547                       $cgi->a({-href => href(action=>"commit", hash=>$par),
7548                                class => "list"}, $par) .
7549                       "</td>" .
7550                       "<td class=\"link\">" .
7551                       $cgi->a({-href => href(action=>"commit", hash=>$par)}, "commit") .
7552                       " | " .
7553                       $cgi->a({-href => href(action=>"commitdiff", hash=>$hash, hash_parent=>$par)}, "diff") .
7554                       "</td>" .
7555                       "</tr>\n";
7556         }
7557         print "</table>".
7558               "</div>\n";
7559
7560         print "<div class=\"page_body\">\n";
7561         git_print_log($co{'comment'});
7562         print "</div>\n";
7563
7564         git_difftree_body(\@difftree, $hash, @$parents);
7565
7566         git_footer_html();
7567 }
7568
7569 sub git_object {
7570         # object is defined by:
7571         # - hash or hash_base alone
7572         # - hash_base and file_name
7573         my $type;
7574
7575         # - hash or hash_base alone
7576         if ($hash || ($hash_base && !defined $file_name)) {
7577                 my $object_id = $hash || $hash_base;
7578
7579                 open my $fd, "-|", quote_command(
7580                         git_cmd(), 'cat-file', '-t', $object_id) . ' 2> /dev/null'
7581                         or die_error(404, "Object does not exist");
7582                 $type = <$fd>;
7583                 defined $type && chomp $type;
7584                 close $fd
7585                         or die_error(404, "Object does not exist");
7586
7587         # - hash_base and file_name
7588         } elsif ($hash_base && defined $file_name) {
7589                 $file_name =~ s,/+$,,;
7590
7591                 system(git_cmd(), "cat-file", '-e', $hash_base) == 0
7592                         or die_error(404, "Base object does not exist");
7593
7594                 # here errors should not happen
7595                 open my $fd, "-|", git_cmd(), "ls-tree", $hash_base, "--", $file_name
7596                         or die_error(500, "Open git-ls-tree failed");
7597                 my $line = <$fd>;
7598                 close $fd;
7599
7600                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
7601                 unless ($line && $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/) {
7602                         die_error(404, "File or directory for given base does not exist");
7603                 }
7604                 $type = $2;
7605                 $hash = $3;
7606         } else {
7607                 die_error(400, "Not enough information to find object");
7608         }
7609
7610         print $cgi->redirect(-uri => href(action=>$type, -full=>1,
7611                                           hash=>$hash, hash_base=>$hash_base,
7612                                           file_name=>$file_name),
7613                              -status => '302 Found');
7614 }
7615
7616 sub git_blobdiff {
7617         my $format = shift || 'html';
7618         my $diff_style = $input_params{'diff_style'} || 'inline';
7619
7620         my $fd;
7621         my @difftree;
7622         my %diffinfo;
7623         my $expires;
7624
7625         # preparing $fd and %diffinfo for git_patchset_body
7626         # new style URI
7627         if (defined $hash_base && defined $hash_parent_base) {
7628                 if (defined $file_name) {
7629                         # read raw output
7630                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7631                                 $hash_parent_base, $hash_base,
7632                                 "--", (defined $file_parent ? $file_parent : ()), $file_name
7633                                 or die_error(500, "Open git-diff-tree failed");
7634                         @difftree = map { chomp; $_ } <$fd>;
7635                         close $fd
7636                                 or die_error(404, "Reading git-diff-tree failed");
7637                         @difftree
7638                                 or die_error(404, "Blob diff not found");
7639
7640                 } elsif (defined $hash &&
7641                          $hash =~ /[0-9a-fA-F]{40}/) {
7642                         # try to find filename from $hash
7643
7644                         # read filtered raw output
7645                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7646                                 $hash_parent_base, $hash_base, "--"
7647                                 or die_error(500, "Open git-diff-tree failed");
7648                         @difftree =
7649                                 # ':100644 100644 03b21826... 3b93d5e7... M     ls-files.c'
7650                                 # $hash == to_id
7651                                 grep { /^:[0-7]{6} [0-7]{6} [0-9a-fA-F]{40} $hash/ }
7652                                 map { chomp; $_ } <$fd>;
7653                         close $fd
7654                                 or die_error(404, "Reading git-diff-tree failed");
7655                         @difftree
7656                                 or die_error(404, "Blob diff not found");
7657
7658                 } else {
7659                         die_error(400, "Missing one of the blob diff parameters");
7660                 }
7661
7662                 if (@difftree > 1) {
7663                         die_error(400, "Ambiguous blob diff specification");
7664                 }
7665
7666                 %diffinfo = parse_difftree_raw_line($difftree[0]);
7667                 $file_parent ||= $diffinfo{'from_file'} || $file_name;
7668                 $file_name   ||= $diffinfo{'to_file'};
7669
7670                 $hash_parent ||= $diffinfo{'from_id'};
7671                 $hash        ||= $diffinfo{'to_id'};
7672
7673                 # non-textual hash id's can be cached
7674                 if ($hash_base =~ m/^[0-9a-fA-F]{40}$/ &&
7675                     $hash_parent_base =~ m/^[0-9a-fA-F]{40}$/) {
7676                         $expires = '+1d';
7677                 }
7678
7679                 # open patch output
7680                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7681                         '-p', ($format eq 'html' ? "--full-index" : ()),
7682                         $hash_parent_base, $hash_base,
7683                         "--", (defined $file_parent ? $file_parent : ()), $file_name
7684                         or die_error(500, "Open git-diff-tree failed");
7685         }
7686
7687         # old/legacy style URI -- not generated anymore since 1.4.3.
7688         if (!%diffinfo) {
7689                 die_error('404 Not Found', "Missing one of the blob diff parameters")
7690         }
7691
7692         # header
7693         if ($format eq 'html') {
7694                 my $formats_nav =
7695                         $cgi->a({-href => href(action=>"blobdiff_plain", -replay=>1)},
7696                                 "raw");
7697                 $formats_nav .= diff_style_nav($diff_style);
7698                 git_header_html(undef, $expires);
7699                 if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7700                         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
7701                         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
7702                 } else {
7703                         print "<div class=\"page_nav\"><br/>$formats_nav<br/></div>\n";
7704                         print "<div class=\"title\">".esc_html("$hash vs $hash_parent")."</div>\n";
7705                 }
7706                 if (defined $file_name) {
7707                         git_print_page_path($file_name, "blob", $hash_base);
7708                 } else {
7709                         print "<div class=\"page_path\"></div>\n";
7710                 }
7711
7712         } elsif ($format eq 'plain') {
7713                 print $cgi->header(
7714                         -type => 'text/plain',
7715                         -charset => 'utf-8',
7716                         -expires => $expires,
7717                         -content_disposition => 'inline; filename="' . "$file_name" . '.patch"');
7718
7719                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7720
7721         } else {
7722                 die_error(400, "Unknown blobdiff format");
7723         }
7724
7725         # patch
7726         if ($format eq 'html') {
7727                 print "<div class=\"page_body\">\n";
7728
7729                 git_patchset_body($fd, $diff_style,
7730                                   [ \%diffinfo ], $hash_base, $hash_parent_base);
7731                 close $fd;
7732
7733                 print "</div>\n"; # class="page_body"
7734                 git_footer_html();
7735
7736         } else {
7737                 while (my $line = <$fd>) {
7738                         $line =~ s!a/($hash|$hash_parent)!'a/'.esc_path($diffinfo{'from_file'})!eg;
7739                         $line =~ s!b/($hash|$hash_parent)!'b/'.esc_path($diffinfo{'to_file'})!eg;
7740
7741                         print $line;
7742
7743                         last if $line =~ m!^\+\+\+!;
7744                 }
7745                 local $/ = undef;
7746                 print <$fd>;
7747                 close $fd;
7748         }
7749 }
7750
7751 sub git_blobdiff_plain {
7752         git_blobdiff('plain');
7753 }
7754
7755 # assumes that it is added as later part of already existing navigation,
7756 # so it returns "| foo | bar" rather than just "foo | bar"
7757 sub diff_style_nav {
7758         my ($diff_style, $is_combined) = @_;
7759         $diff_style ||= 'inline';
7760
7761         return "" if ($is_combined);
7762
7763         my @styles = (inline => 'inline', 'sidebyside' => 'side by side');
7764         my %styles = @styles;
7765         @styles =
7766                 @styles[ map { $_ * 2 } 0..$#styles/2 ];
7767
7768         return join '',
7769                 map { " | ".$_ }
7770                 map {
7771                         $_ eq $diff_style ? $styles{$_} :
7772                         $cgi->a({-href => href(-replay=>1, diff_style => $_)}, $styles{$_})
7773                 } @styles;
7774 }
7775
7776 sub git_commitdiff {
7777         my %params = @_;
7778         my $format = $params{-format} || 'html';
7779         my $diff_style = $input_params{'diff_style'} || 'inline';
7780
7781         my ($patch_max) = gitweb_get_feature('patches');
7782         if ($format eq 'patch') {
7783                 die_error(403, "Patch view not allowed") unless $patch_max;
7784         }
7785
7786         $hash ||= $hash_base || "HEAD";
7787         my %co = parse_commit($hash)
7788             or die_error(404, "Unknown commit object");
7789
7790         # choose format for commitdiff for merge
7791         if (! defined $hash_parent && @{$co{'parents'}} > 1) {
7792                 $hash_parent = '--cc';
7793         }
7794         # we need to prepare $formats_nav before almost any parameter munging
7795         my $formats_nav;
7796         if ($format eq 'html') {
7797                 $formats_nav =
7798                         $cgi->a({-href => href(action=>"commitdiff_plain", -replay=>1)},
7799                                 "raw");
7800                 if ($patch_max && @{$co{'parents'}} <= 1) {
7801                         $formats_nav .= " | " .
7802                                 $cgi->a({-href => href(action=>"patch", -replay=>1)},
7803                                         "patch");
7804                 }
7805                 $formats_nav .= diff_style_nav($diff_style, @{$co{'parents'}} > 1);
7806
7807                 if (defined $hash_parent &&
7808                     $hash_parent ne '-c' && $hash_parent ne '--cc') {
7809                         # commitdiff with two commits given
7810                         my $hash_parent_short = $hash_parent;
7811                         if ($hash_parent =~ m/^[0-9a-fA-F]{40}$/) {
7812                                 $hash_parent_short = substr($hash_parent, 0, 7);
7813                         }
7814                         $formats_nav .=
7815                                 ' (from';
7816                         for (my $i = 0; $i < @{$co{'parents'}}; $i++) {
7817                                 if ($co{'parents'}[$i] eq $hash_parent) {
7818                                         $formats_nav .= ' parent ' . ($i+1);
7819                                         last;
7820                                 }
7821                         }
7822                         $formats_nav .= ': ' .
7823                                 $cgi->a({-href => href(-replay=>1,
7824                                                        hash=>$hash_parent, hash_base=>undef)},
7825                                         esc_html($hash_parent_short)) .
7826                                 ')';
7827                 } elsif (!$co{'parent'}) {
7828                         # --root commitdiff
7829                         $formats_nav .= ' (initial)';
7830                 } elsif (scalar @{$co{'parents'}} == 1) {
7831                         # single parent commit
7832                         $formats_nav .=
7833                                 ' (parent: ' .
7834                                 $cgi->a({-href => href(-replay=>1,
7835                                                        hash=>$co{'parent'}, hash_base=>undef)},
7836                                         esc_html(substr($co{'parent'}, 0, 7))) .
7837                                 ')';
7838                 } else {
7839                         # merge commit
7840                         if ($hash_parent eq '--cc') {
7841                                 $formats_nav .= ' | ' .
7842                                         $cgi->a({-href => href(-replay=>1,
7843                                                                hash=>$hash, hash_parent=>'-c')},
7844                                                 'combined');
7845                         } else { # $hash_parent eq '-c'
7846                                 $formats_nav .= ' | ' .
7847                                         $cgi->a({-href => href(-replay=>1,
7848                                                                hash=>$hash, hash_parent=>'--cc')},
7849                                                 'compact');
7850                         }
7851                         $formats_nav .=
7852                                 ' (merge: ' .
7853                                 join(' ', map {
7854                                         $cgi->a({-href => href(-replay=>1,
7855                                                                hash=>$_, hash_base=>undef)},
7856                                                 esc_html(substr($_, 0, 7)));
7857                                 } @{$co{'parents'}} ) .
7858                                 ')';
7859                 }
7860         }
7861
7862         my $hash_parent_param = $hash_parent;
7863         if (!defined $hash_parent_param) {
7864                 # --cc for multiple parents, --root for parentless
7865                 $hash_parent_param =
7866                         @{$co{'parents'}} > 1 ? '--cc' : $co{'parent'} || '--root';
7867         }
7868
7869         # read commitdiff
7870         my $fd;
7871         my @difftree;
7872         if ($format eq 'html') {
7873                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7874                         "--no-commit-id", "--patch-with-raw", "--full-index",
7875                         $hash_parent_param, $hash, "--"
7876                         or die_error(500, "Open git-diff-tree failed");
7877
7878                 while (my $line = <$fd>) {
7879                         chomp $line;
7880                         # empty line ends raw part of diff-tree output
7881                         last unless $line;
7882                         push @difftree, scalar parse_difftree_raw_line($line);
7883                 }
7884
7885         } elsif ($format eq 'plain') {
7886                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7887                         '-p', $hash_parent_param, $hash, "--"
7888                         or die_error(500, "Open git-diff-tree failed");
7889         } elsif ($format eq 'patch') {
7890                 # For commit ranges, we limit the output to the number of
7891                 # patches specified in the 'patches' feature.
7892                 # For single commits, we limit the output to a single patch,
7893                 # diverging from the git-format-patch default.
7894                 my @commit_spec = ();
7895                 if ($hash_parent) {
7896                         if ($patch_max > 0) {
7897                                 push @commit_spec, "-$patch_max";
7898                         }
7899                         push @commit_spec, '-n', "$hash_parent..$hash";
7900                 } else {
7901                         if ($params{-single}) {
7902                                 push @commit_spec, '-1';
7903                         } else {
7904                                 if ($patch_max > 0) {
7905                                         push @commit_spec, "-$patch_max";
7906                                 }
7907                                 push @commit_spec, "-n";
7908                         }
7909                         push @commit_spec, '--root', $hash;
7910                 }
7911                 open $fd, "-|", git_cmd(), "format-patch", @diff_opts,
7912                         '--encoding=utf8', '--stdout', @commit_spec
7913                         or die_error(500, "Open git-format-patch failed");
7914         } else {
7915                 die_error(400, "Unknown commitdiff format");
7916         }
7917
7918         # non-textual hash id's can be cached
7919         my $expires;
7920         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
7921                 $expires = "+1d";
7922         }
7923
7924         # write commit message
7925         if ($format eq 'html') {
7926                 my $refs = git_get_references();
7927                 my $ref = format_ref_marker($refs, $co{'id'});
7928
7929                 git_header_html(undef, $expires);
7930                 git_print_page_nav('commitdiff','', $hash,$co{'tree'},$hash, $formats_nav);
7931                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash);
7932                 print "<div class=\"title_text\">\n" .
7933                       "<table class=\"object_header\">\n";
7934                 git_print_authorship_rows(\%co);
7935                 print "</table>".
7936                       "</div>\n";
7937                 print "<div class=\"page_body\">\n";
7938                 if (@{$co{'comment'}} > 1) {
7939                         print "<div class=\"log\">\n";
7940                         git_print_log($co{'comment'}, -final_empty_line=> 1, -remove_title => 1);
7941                         print "</div>\n"; # class="log"
7942                 }
7943
7944         } elsif ($format eq 'plain') {
7945                 my $refs = git_get_references("tags");
7946                 my $tagname = git_get_rev_name_tags($hash);
7947                 my $filename = basename($project) . "-$hash.patch";
7948
7949                 print $cgi->header(
7950                         -type => 'text/plain',
7951                         -charset => 'utf-8',
7952                         -expires => $expires,
7953                         -content_disposition => 'inline; filename="' . "$filename" . '"');
7954                 my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
7955                 print "From: " . to_utf8($co{'author'}) . "\n";
7956                 print "Date: $ad{'rfc2822'} ($ad{'tz_local'})\n";
7957                 print "Subject: " . to_utf8($co{'title'}) . "\n";
7958
7959                 print "X-Git-Tag: $tagname\n" if $tagname;
7960                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7961
7962                 foreach my $line (@{$co{'comment'}}) {
7963                         print to_utf8($line) . "\n";
7964                 }
7965                 print "---\n\n";
7966         } elsif ($format eq 'patch') {
7967                 my $filename = basename($project) . "-$hash.patch";
7968
7969                 print $cgi->header(
7970                         -type => 'text/plain',
7971                         -charset => 'utf-8',
7972                         -expires => $expires,
7973                         -content_disposition => 'inline; filename="' . "$filename" . '"');
7974         }
7975
7976         # write patch
7977         if ($format eq 'html') {
7978                 my $use_parents = !defined $hash_parent ||
7979                         $hash_parent eq '-c' || $hash_parent eq '--cc';
7980                 git_difftree_body(\@difftree, $hash,
7981                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
7982                 print "<br/>\n";
7983
7984                 git_patchset_body($fd, $diff_style,
7985                                   \@difftree, $hash,
7986                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
7987                 close $fd;
7988                 print "</div>\n"; # class="page_body"
7989                 git_footer_html();
7990
7991         } elsif ($format eq 'plain') {
7992                 local $/ = undef;
7993                 print <$fd>;
7994                 close $fd
7995                         or print "Reading git-diff-tree failed\n";
7996         } elsif ($format eq 'patch') {
7997                 local $/ = undef;
7998                 print <$fd>;
7999                 close $fd
8000                         or print "Reading git-format-patch failed\n";
8001         }
8002 }
8003
8004 sub git_commitdiff_plain {
8005         git_commitdiff(-format => 'plain');
8006 }
8007
8008 # format-patch-style patches
8009 sub git_patch {
8010         git_commitdiff(-format => 'patch', -single => 1);
8011 }
8012
8013 sub git_patches {
8014         git_commitdiff(-format => 'patch');
8015 }
8016
8017 sub git_history {
8018         git_log_generic('history', \&git_history_body,
8019                         $hash_base, $hash_parent_base,
8020                         $file_name, $hash);
8021 }
8022
8023 sub git_search {
8024         $searchtype ||= 'commit';
8025
8026         # check if appropriate features are enabled
8027         gitweb_check_feature('search')
8028                 or die_error(403, "Search is disabled");
8029         if ($searchtype eq 'pickaxe') {
8030                 # pickaxe may take all resources of your box and run for several minutes
8031                 # with every query - so decide by yourself how public you make this feature
8032                 gitweb_check_feature('pickaxe')
8033                         or die_error(403, "Pickaxe search is disabled");
8034         }
8035         if ($searchtype eq 'grep') {
8036                 # grep search might be potentially CPU-intensive, too
8037                 gitweb_check_feature('grep')
8038                         or die_error(403, "Grep search is disabled");
8039         }
8040
8041         if (!defined $searchtext) {
8042                 die_error(400, "Text field is empty");
8043         }
8044         if (!defined $hash) {
8045                 $hash = git_get_head_hash($project);
8046         }
8047         my %co = parse_commit($hash);
8048         if (!%co) {
8049                 die_error(404, "Unknown commit object");
8050         }
8051         if (!defined $page) {
8052                 $page = 0;
8053         }
8054
8055         if ($searchtype eq 'commit' ||
8056             $searchtype eq 'author' ||
8057             $searchtype eq 'committer') {
8058                 git_search_message(%co);
8059         } elsif ($searchtype eq 'pickaxe') {
8060                 git_search_changes(%co);
8061         } elsif ($searchtype eq 'grep') {
8062                 git_search_files(%co);
8063         } else {
8064                 die_error(400, "Unknown search type");
8065         }
8066 }
8067
8068 sub git_search_help {
8069         git_header_html();
8070         git_print_page_nav('','', $hash,$hash,$hash);
8071         print <<EOT;
8072 <p><strong>Pattern</strong> is by default a normal string that is matched precisely (but without
8073 regard to case, except in the case of pickaxe). However, when you check the <em>re</em> checkbox,
8074 the pattern entered is recognized as the POSIX extended
8075 <a href="http://en.wikipedia.org/wiki/Regular_expression">regular expression</a> (also case
8076 insensitive).</p>
8077 <dl>
8078 <dt><b>commit</b></dt>
8079 <dd>The commit messages and authorship information will be scanned for the given pattern.</dd>
8080 EOT
8081         my $have_grep = gitweb_check_feature('grep');
8082         if ($have_grep) {
8083                 print <<EOT;
8084 <dt><b>grep</b></dt>
8085 <dd>All files in the currently selected tree (HEAD unless you are explicitly browsing
8086     a different one) are searched for the given pattern. On large trees, this search can take
8087 a while and put some strain on the server, so please use it with some consideration. Note that
8088 due to git-grep peculiarity, currently if regexp mode is turned off, the matches are
8089 case-sensitive.</dd>
8090 EOT
8091         }
8092         print <<EOT;
8093 <dt><b>author</b></dt>
8094 <dd>Name and e-mail of the change author and date of birth of the patch will be scanned for the given pattern.</dd>
8095 <dt><b>committer</b></dt>
8096 <dd>Name and e-mail of the committer and date of commit will be scanned for the given pattern.</dd>
8097 EOT
8098         my $have_pickaxe = gitweb_check_feature('pickaxe');
8099         if ($have_pickaxe) {
8100                 print <<EOT;
8101 <dt><b>pickaxe</b></dt>
8102 <dd>All commits that caused the string to appear or disappear from any file (changes that
8103 added, removed or "modified" the string) will be listed. This search can take a while and
8104 takes a lot of strain on the server, so please use it wisely. Note that since you may be
8105 interested even in changes just changing the case as well, this search is case sensitive.</dd>
8106 EOT
8107         }
8108         print "</dl>\n";
8109         git_footer_html();
8110 }
8111
8112 sub git_shortlog {
8113         git_log_generic('shortlog', \&git_shortlog_body,
8114                         $hash, $hash_parent);
8115 }
8116
8117 ## ......................................................................
8118 ## feeds (RSS, Atom; OPML)
8119
8120 sub git_feed {
8121         my $format = shift || 'atom';
8122         my $have_blame = gitweb_check_feature('blame');
8123
8124         # Atom: http://www.atomenabled.org/developers/syndication/
8125         # RSS:  http://www.notestips.com/80256B3A007F2692/1/NAMO5P9UPQ
8126         if ($format ne 'rss' && $format ne 'atom') {
8127                 die_error(400, "Unknown web feed format");
8128         }
8129
8130         # log/feed of current (HEAD) branch, log of given branch, history of file/directory
8131         my $head = $hash || 'HEAD';
8132         my @commitlist = parse_commits($head, 150, 0, $file_name);
8133
8134         my %latest_commit;
8135         my %latest_date;
8136         my $content_type = "application/$format+xml";
8137         if (defined $cgi->http('HTTP_ACCEPT') &&
8138                  $cgi->Accept('text/xml') > $cgi->Accept($content_type)) {
8139                 # browser (feed reader) prefers text/xml
8140                 $content_type = 'text/xml';
8141         }
8142         if (defined($commitlist[0])) {
8143                 %latest_commit = %{$commitlist[0]};
8144                 my $latest_epoch = $latest_commit{'committer_epoch'};
8145                 exit_if_unmodified_since($latest_epoch);
8146                 %latest_date = parse_date($latest_epoch, $latest_commit{'committer_tz'});
8147         }
8148         print $cgi->header(
8149                 -type => $content_type,
8150                 -charset => 'utf-8',
8151                 %latest_date ? (-last_modified => $latest_date{'rfc2822'}) : (),
8152                 -status => '200 OK');
8153
8154         # Optimization: skip generating the body if client asks only
8155         # for Last-Modified date.
8156         return if ($cgi->request_method() eq 'HEAD');
8157
8158         # header variables
8159         my $title = "$site_name - $project/$action";
8160         my $feed_type = 'log';
8161         if (defined $hash) {
8162                 $title .= " - '$hash'";
8163                 $feed_type = 'branch log';
8164                 if (defined $file_name) {
8165                         $title .= " :: $file_name";
8166                         $feed_type = 'history';
8167                 }
8168         } elsif (defined $file_name) {
8169                 $title .= " - $file_name";
8170                 $feed_type = 'history';
8171         }
8172         $title .= " $feed_type";
8173         $title = esc_html($title);
8174         my $descr = git_get_project_description($project);
8175         if (defined $descr) {
8176                 $descr = esc_html($descr);
8177         } else {
8178                 $descr = "$project " .
8179                          ($format eq 'rss' ? 'RSS' : 'Atom') .
8180                          " feed";
8181         }
8182         my $owner = git_get_project_owner($project);
8183         $owner = esc_html($owner);
8184
8185         #header
8186         my $alt_url;
8187         if (defined $file_name) {
8188                 $alt_url = href(-full=>1, action=>"history", hash=>$hash, file_name=>$file_name);
8189         } elsif (defined $hash) {
8190                 $alt_url = href(-full=>1, action=>"log", hash=>$hash);
8191         } else {
8192                 $alt_url = href(-full=>1, action=>"summary");
8193         }
8194         print qq!<?xml version="1.0" encoding="utf-8"?>\n!;
8195         if ($format eq 'rss') {
8196                 print <<XML;
8197 <rss version="2.0" xmlns:content="http://purl.org/rss/1.0/modules/content/">
8198 <channel>
8199 XML
8200                 print "<title>$title</title>\n" .
8201                       "<link>$alt_url</link>\n" .
8202                       "<description>$descr</description>\n" .
8203                       "<language>en</language>\n" .
8204                       # project owner is responsible for 'editorial' content
8205                       "<managingEditor>$owner</managingEditor>\n";
8206                 if (defined $logo || defined $favicon) {
8207                         # prefer the logo to the favicon, since RSS
8208                         # doesn't allow both
8209                         my $img = esc_url($logo || $favicon);
8210                         print "<image>\n" .
8211                               "<url>$img</url>\n" .
8212                               "<title>$title</title>\n" .
8213                               "<link>$alt_url</link>\n" .
8214                               "</image>\n";
8215                 }
8216                 if (%latest_date) {
8217                         print "<pubDate>$latest_date{'rfc2822'}</pubDate>\n";
8218                         print "<lastBuildDate>$latest_date{'rfc2822'}</lastBuildDate>\n";
8219                 }
8220                 print "<generator>gitweb v.$version/$git_version</generator>\n";
8221         } elsif ($format eq 'atom') {
8222                 print <<XML;
8223 <feed xmlns="http://www.w3.org/2005/Atom">
8224 XML
8225                 print "<title>$title</title>\n" .
8226                       "<subtitle>$descr</subtitle>\n" .
8227                       '<link rel="alternate" type="text/html" href="' .
8228                       $alt_url . '" />' . "\n" .
8229                       '<link rel="self" type="' . $content_type . '" href="' .
8230                       $cgi->self_url() . '" />' . "\n" .
8231                       "<id>" . href(-full=>1) . "</id>\n" .
8232                       # use project owner for feed author
8233                       "<author><name>$owner</name></author>\n";
8234                 if (defined $favicon) {
8235                         print "<icon>" . esc_url($favicon) . "</icon>\n";
8236                 }
8237                 if (defined $logo) {
8238                         # not twice as wide as tall: 72 x 27 pixels
8239                         print "<logo>" . esc_url($logo) . "</logo>\n";
8240                 }
8241                 if (! %latest_date) {
8242                         # dummy date to keep the feed valid until commits trickle in:
8243                         print "<updated>1970-01-01T00:00:00Z</updated>\n";
8244                 } else {
8245                         print "<updated>$latest_date{'iso-8601'}</updated>\n";
8246                 }
8247                 print "<generator version='$version/$git_version'>gitweb</generator>\n";
8248         }
8249
8250         # contents
8251         for (my $i = 0; $i <= $#commitlist; $i++) {
8252                 my %co = %{$commitlist[$i]};
8253                 my $commit = $co{'id'};
8254                 # we read 150, we always show 30 and the ones more recent than 48 hours
8255                 if (($i >= 20) && ((time - $co{'author_epoch'}) > 48*60*60)) {
8256                         last;
8257                 }
8258                 my %cd = parse_date($co{'author_epoch'}, $co{'author_tz'});
8259
8260                 # get list of changed files
8261                 open my $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
8262                         $co{'parent'} || "--root",
8263                         $co{'id'}, "--", (defined $file_name ? $file_name : ())
8264                         or next;
8265                 my @difftree = map { chomp; $_ } <$fd>;
8266                 close $fd
8267                         or next;
8268
8269                 # print element (entry, item)
8270                 my $co_url = href(-full=>1, action=>"commitdiff", hash=>$commit);
8271                 if ($format eq 'rss') {
8272                         print "<item>\n" .
8273                               "<title>" . esc_html($co{'title'}) . "</title>\n" .
8274                               "<author>" . esc_html($co{'author'}) . "</author>\n" .
8275                               "<pubDate>$cd{'rfc2822'}</pubDate>\n" .
8276                               "<guid isPermaLink=\"true\">$co_url</guid>\n" .
8277                               "<link>$co_url</link>\n" .
8278                               "<description>" . esc_html($co{'title'}) . "</description>\n" .
8279                               "<content:encoded>" .
8280                               "<![CDATA[\n";
8281                 } elsif ($format eq 'atom') {
8282                         print "<entry>\n" .
8283                               "<title type=\"html\">" . esc_html($co{'title'}) . "</title>\n" .
8284                               "<updated>$cd{'iso-8601'}</updated>\n" .
8285                               "<author>\n" .
8286                               "  <name>" . esc_html($co{'author_name'}) . "</name>\n";
8287                         if ($co{'author_email'}) {
8288                                 print "  <email>" . esc_html($co{'author_email'}) . "</email>\n";
8289                         }
8290                         print "</author>\n" .
8291                               # use committer for contributor
8292                               "<contributor>\n" .
8293                               "  <name>" . esc_html($co{'committer_name'}) . "</name>\n";
8294                         if ($co{'committer_email'}) {
8295                                 print "  <email>" . esc_html($co{'committer_email'}) . "</email>\n";
8296                         }
8297                         print "</contributor>\n" .
8298                               "<published>$cd{'iso-8601'}</published>\n" .
8299                               "<link rel=\"alternate\" type=\"text/html\" href=\"$co_url\" />\n" .
8300                               "<id>$co_url</id>\n" .
8301                               "<content type=\"xhtml\" xml:base=\"" . esc_url($my_url) . "\">\n" .
8302                               "<div xmlns=\"http://www.w3.org/1999/xhtml\">\n";
8303                 }
8304                 my $comment = $co{'comment'};
8305                 print "<pre>\n";
8306                 foreach my $line (@$comment) {
8307                         $line = esc_html($line);
8308                         print "$line\n";
8309                 }
8310                 print "</pre><ul>\n";
8311                 foreach my $difftree_line (@difftree) {
8312                         my %difftree = parse_difftree_raw_line($difftree_line);
8313                         next if !$difftree{'from_id'};
8314
8315                         my $file = $difftree{'file'} || $difftree{'to_file'};
8316
8317                         print "<li>" .
8318                               "[" .
8319                               $cgi->a({-href => href(-full=>1, action=>"blobdiff",
8320                                                      hash=>$difftree{'to_id'}, hash_parent=>$difftree{'from_id'},
8321                                                      hash_base=>$co{'id'}, hash_parent_base=>$co{'parent'},
8322                                                      file_name=>$file, file_parent=>$difftree{'from_file'}),
8323                                       -title => "diff"}, 'D');
8324                         if ($have_blame) {
8325                                 print $cgi->a({-href => href(-full=>1, action=>"blame",
8326                                                              file_name=>$file, hash_base=>$commit),
8327                                               -title => "blame"}, 'B');
8328                         }
8329                         # if this is not a feed of a file history
8330                         if (!defined $file_name || $file_name ne $file) {
8331                                 print $cgi->a({-href => href(-full=>1, action=>"history",
8332                                                              file_name=>$file, hash=>$commit),
8333                                               -title => "history"}, 'H');
8334                         }
8335                         $file = esc_path($file);
8336                         print "] ".
8337                               "$file</li>\n";
8338                 }
8339                 if ($format eq 'rss') {
8340                         print "</ul>]]>\n" .
8341                               "</content:encoded>\n" .
8342                               "</item>\n";
8343                 } elsif ($format eq 'atom') {
8344                         print "</ul>\n</div>\n" .
8345                               "</content>\n" .
8346                               "</entry>\n";
8347                 }
8348         }
8349
8350         # end of feed
8351         if ($format eq 'rss') {
8352                 print "</channel>\n</rss>\n";
8353         } elsif ($format eq 'atom') {
8354                 print "</feed>\n";
8355         }
8356 }
8357
8358 sub git_rss {
8359         git_feed('rss');
8360 }
8361
8362 sub git_atom {
8363         git_feed('atom');
8364 }
8365
8366 sub git_opml {
8367         my @list = git_get_projects_list($project_filter, $strict_export);
8368         if (!@list) {
8369                 die_error(404, "No projects found");
8370         }
8371
8372         print $cgi->header(
8373                 -type => 'text/xml',
8374                 -charset => 'utf-8',
8375                 -content_disposition => 'inline; filename="opml.xml"');
8376
8377         my $title = esc_html($site_name);
8378         my $filter = " within subdirectory ";
8379         if (defined $project_filter) {
8380                 $filter .= esc_html($project_filter);
8381         } else {
8382                 $filter = "";
8383         }
8384         print <<XML;
8385 <?xml version="1.0" encoding="utf-8"?>
8386 <opml version="1.0">
8387 <head>
8388   <title>$title OPML Export$filter</title>
8389 </head>
8390 <body>
8391 <outline text="git RSS feeds">
8392 XML
8393
8394         foreach my $pr (@list) {
8395                 my %proj = %$pr;
8396                 my $head = git_get_head_hash($proj{'path'});
8397                 if (!defined $head) {
8398                         next;
8399                 }
8400                 $git_dir = "$projectroot/$proj{'path'}";
8401                 my %co = parse_commit($head);
8402                 if (!%co) {
8403                         next;
8404                 }
8405
8406                 my $path = esc_html(chop_str($proj{'path'}, 25, 5));
8407                 my $rss  = href('project' => $proj{'path'}, 'action' => 'rss', -full => 1);
8408                 my $html = href('project' => $proj{'path'}, 'action' => 'summary', -full => 1);
8409                 print "<outline type=\"rss\" text=\"$path\" title=\"$path\" xmlUrl=\"$rss\" htmlUrl=\"$html\"/>\n";
8410         }
8411         print <<XML;
8412 </outline>
8413 </body>
8414 </opml>
8415 XML
8416 }