Lady’s Gitweb - Gitweb/blob - gitweb.perl

   1 #!/usr/bin/perl
   2
   3 # gitweb - simple web interface to track changes in git repositories
   4 #
   5 # (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
   6 # (C) 2005, Christian Gierke
   7 #
   8 # This program is licensed under the GPLv2
   9
  10 use 5.008;
  11 use strict;
  12 use warnings;
  13 use CGI qw(:standard :escapeHTML -nosticky);
  14 use CGI::Util qw(unescape);
  15 use CGI::Carp qw(fatalsToBrowser set_message);
  16 use Encode;
  17 use Fcntl ':mode';
  18 use File::Find qw();
  19 use File::Basename qw(basename);
  20 use Time::HiRes qw(gettimeofday tv_interval);
  21 binmode STDOUT, ':utf8';
  22
  23 our $t0 = [ gettimeofday() ];
  24 our $number_of_git_cmds = 0;
  25
  26 BEGIN {
  27         CGI->compile() if $ENV{'MOD_PERL'};
  28 }
  29
  30 our $version = "++GIT_VERSION++";
  31
  32 our ($my_url, $my_uri, $base_url, $path_info, $home_link);
  33 sub evaluate_uri {
  34         our $cgi;
  35
  36         our $my_url = $cgi->url();
  37         our $my_uri = $cgi->url(-absolute => 1);
  38
  39         # Base URL for relative URLs in gitweb ($logo, $favicon, ...),
  40         # needed and used only for URLs with nonempty PATH_INFO
  41         our $base_url = $my_url;
  42
  43         # When the script is used as DirectoryIndex, the URL does not contain the name
  44         # of the script file itself, and $cgi->url() fails to strip PATH_INFO, so we
  45         # have to do it ourselves. We make $path_info global because it's also used
  46         # later on.
  47         #
  48         # Another issue with the script being the DirectoryIndex is that the resulting
  49         # $my_url data is not the full script URL: this is good, because we want
  50         # generated links to keep implying the script name if it wasn't explicitly
  51         # indicated in the URL we're handling, but it means that $my_url cannot be used
  52         # as base URL.
  53         # Therefore, if we needed to strip PATH_INFO, then we know that we have
  54         # to build the base URL ourselves:
  55         our $path_info = $ENV{"PATH_INFO"};
  56         if ($path_info) {
  57                 if ($my_url =~ s,\Q$path_info\E$,, &&
  58                     $my_uri =~ s,\Q$path_info\E$,, &&
  59                     defined $ENV{'SCRIPT_NAME'}) {
  60                         $base_url = $cgi->url(-base => 1) . $ENV{'SCRIPT_NAME'};
  61                 }
  62         }
  63
  64         # target of the home link on top of all pages
  65         our $home_link = $my_uri || "/";
  66 }
  67
  68 # core git executable to use
  69 # this can just be "git" if your webserver has a sensible PATH
  70 our $GIT = "++GIT_BINDIR++/git";
  71
  72 # absolute fs-path which will be prepended to the project path
  73 #our $projectroot = "/pub/scm";
  74 our $projectroot = "++GITWEB_PROJECTROOT++";
  75
  76 # fs traversing limit for getting project list
  77 # the number is relative to the projectroot
  78 our $project_maxdepth = "++GITWEB_PROJECT_MAXDEPTH++";
  79
  80 # string of the home link on top of all pages
  81 our $home_link_str = "++GITWEB_HOME_LINK_STR++";
  82
  83 # name of your site or organization to appear in page titles
  84 # replace this with something more descriptive for clearer bookmarks
  85 our $site_name = "++GITWEB_SITENAME++"
  86                  || ($ENV{'SERVER_NAME'} || "Untitled") . " Git";
  87
  88 # filename of html text to include at top of each page
  89 our $site_header = "++GITWEB_SITE_HEADER++";
  90 # html text to include at home page
  91 our $home_text = "++GITWEB_HOMETEXT++";
  92 # filename of html text to include at bottom of each page
  93 our $site_footer = "++GITWEB_SITE_FOOTER++";
  94
  95 # URI of stylesheets
  96 our @stylesheets = ("++GITWEB_CSS++");
  97 # URI of a single stylesheet, which can be overridden in GITWEB_CONFIG.
  98 our $stylesheet = undef;
  99
 100 # URI of GIT logo (72x27 size)
 101 our $logo = "++GITWEB_LOGO++";
 102 # URI of GIT favicon, assumed to be image/png type
 103 our $favicon = "++GITWEB_FAVICON++";
 104 # URI of gitweb.js (JavaScript code for gitweb)
 105 our $javascript = "++GITWEB_JS++";
 106
 107 # URI and label (title) of GIT logo link
 108 #our $logo_url = "http://www.kernel.org/pub/software/scm/git/docs/";
 109 #our $logo_label = "git documentation";
 110 our $logo_url = "http://git-scm.com/";
 111 our $logo_label = "git homepage";
 112
 113 # source of projects list
 114 our $projects_list = "++GITWEB_LIST++";
 115
 116 # the width (in characters) of the projects list "Description" column
 117 our $projects_list_description_width = 25;
 118
 119 # default order of projects list
 120 # valid values are none, project, descr, owner, and age
 121 our $default_projects_order = "project";
 122
 123 # show repository only if this file exists
 124 # (only effective if this variable evaluates to true)
 125 our $export_ok = "++GITWEB_EXPORT_OK++";
 126
 127 # show repository only if this subroutine returns true
 128 # when given the path to the project, for example:
 129 #    sub { return -e "$_[0]/git-daemon-export-ok"; }
 130 our $export_auth_hook = undef;
 131
 132 # only allow viewing of repositories also shown on the overview page
 133 our $strict_export = "++GITWEB_STRICT_EXPORT++";
 134
 135 # list of git base URLs used for URL to where fetch project from,
 136 # i.e. full URL is "$git_base_url/$project"
 137 our @git_base_url_list = grep { $_ ne '' } ("++GITWEB_BASE_URL++");
 138
 139 # default blob_plain mimetype and default charset for text/plain blob
 140 our $default_blob_plain_mimetype = 'text/plain';
 141 our $default_text_plain_charset  = undef;
 142
 143 # file to use for guessing MIME types before trying /etc/mime.types
 144 # (relative to the current git repository)
 145 our $mimetypes_file = undef;
 146
 147 # assume this charset if line contains non-UTF-8 characters;
 148 # it should be valid encoding (see Encoding::Supported(3pm) for list),
 149 # for which encoding all byte sequences are valid, for example
 150 # 'iso-8859-1' aka 'latin1' (it is decoded without checking, so it
 151 # could be even 'utf-8' for the old behavior)
 152 our $fallback_encoding = 'latin1';
 153
 154 # rename detection options for git-diff and git-diff-tree
 155 # - default is '-M', with the cost proportional to
 156 #   (number of removed files) * (number of new files).
 157 # - more costly is '-C' (which implies '-M'), with the cost proportional to
 158 #   (number of changed files + number of removed files) * (number of new files)
 159 # - even more costly is '-C', '--find-copies-harder' with cost
 160 #   (number of files in the original tree) * (number of new files)
 161 # - one might want to include '-B' option, e.g. '-B', '-M'
 162 our @diff_opts = ('-M'); # taken from git_commit
 163
 164 # Disables features that would allow repository owners to inject script into
 165 # the gitweb domain.
 166 our $prevent_xss = 0;
 167
 168 # Path to the highlight executable to use (must be the one from
 169 # http://www.andre-simon.de due to assumptions about parameters and output).
 170 # Useful if highlight is not installed on your webserver's PATH.
 171 # [Default: highlight]
 172 our $highlight_bin = "++HIGHLIGHT_BIN++";
 173
 174 # information about snapshot formats that gitweb is capable of serving
 175 our %known_snapshot_formats = (
 176         # name => {
 177         #       'display' => display name,
 178         #       'type' => mime type,
 179         #       'suffix' => filename suffix,
 180         #       'format' => --format for git-archive,
 181         #       'compressor' => [compressor command and arguments]
 182         #                       (array reference, optional)
 183         #       'disabled' => boolean (optional)}
 184         #
 185         'tgz' => {
 186                 'display' => 'tar.gz',
 187                 'type' => 'application/x-gzip',
 188                 'suffix' => '.tar.gz',
 189                 'format' => 'tar',
 190                 'compressor' => ['gzip']},
 191
 192         'tbz2' => {
 193                 'display' => 'tar.bz2',
 194                 'type' => 'application/x-bzip2',
 195                 'suffix' => '.tar.bz2',
 196                 'format' => 'tar',
 197                 'compressor' => ['bzip2']},
 198
 199         'txz' => {
 200                 'display' => 'tar.xz',
 201                 'type' => 'application/x-xz',
 202                 'suffix' => '.tar.xz',
 203                 'format' => 'tar',
 204                 'compressor' => ['xz'],
 205                 'disabled' => 1},
 206
 207         'zip' => {
 208                 'display' => 'zip',
 209                 'type' => 'application/x-zip',
 210                 'suffix' => '.zip',
 211                 'format' => 'zip'},
 212 );
 213
 214 # Aliases so we understand old gitweb.snapshot values in repository
 215 # configuration.
 216 our %known_snapshot_format_aliases = (
 217         'gzip'  => 'tgz',
 218         'bzip2' => 'tbz2',
 219         'xz'    => 'txz',
 220
 221         # backward compatibility: legacy gitweb config support
 222         'x-gzip' => undef, 'gz' => undef,
 223         'x-bzip2' => undef, 'bz2' => undef,
 224         'x-zip' => undef, '' => undef,
 225 );
 226
 227 # Pixel sizes for icons and avatars. If the default font sizes or lineheights
 228 # are changed, it may be appropriate to change these values too via
 229 # $GITWEB_CONFIG.
 230 our %avatar_size = (
 231         'default' => 16,
 232         'double'  => 32
 233 );
 234
 235 # Used to set the maximum load that we will still respond to gitweb queries.
 236 # If server load exceed this value then return "503 server busy" error.
 237 # If gitweb cannot determined server load, it is taken to be 0.
 238 # Leave it undefined (or set to 'undef') to turn off load checking.
 239 our $maxload = 300;
 240
 241 # configuration for 'highlight' (http://www.andre-simon.de/)
 242 # match by basename
 243 our %highlight_basename = (
 244         #'Program' => 'py',
 245         #'Library' => 'py',
 246         'SConstruct' => 'py', # SCons equivalent of Makefile
 247         'Makefile' => 'make',
 248 );
 249 # match by extension
 250 our %highlight_ext = (
 251         # main extensions, defining name of syntax;
 252         # see files in /usr/share/highlight/langDefs/ directory
 253         map { $_ => $_ }
 254                 qw(py c cpp rb java css php sh pl js tex bib xml awk bat ini spec tcl),
 255         # alternate extensions, see /etc/highlight/filetypes.conf
 256         'h' => 'c',
 257         map { $_ => 'cpp' } qw(cxx c++ cc),
 258         map { $_ => 'php' } qw(php3 php4),
 259         map { $_ => 'pl'  } qw(perl pm), # perhaps also 'cgi'
 260         'mak' => 'make',
 261         map { $_ => 'xml' } qw(xhtml html htm),
 262 );
 263
 264 # You define site-wide feature defaults here; override them with
 265 # $GITWEB_CONFIG as necessary.
 266 our %feature = (
 267         # feature => {
 268         #       'sub' => feature-sub (subroutine),
 269         #       'override' => allow-override (boolean),
 270         #       'default' => [ default options...] (array reference)}
 271         #
 272         # if feature is overridable (it means that allow-override has true value),
 273         # then feature-sub will be called with default options as parameters;
 274         # return value of feature-sub indicates if to enable specified feature
 275         #
 276         # if there is no 'sub' key (no feature-sub), then feature cannot be
 277         # overridden
 278         #
 279         # use gitweb_get_feature(<feature>) to retrieve the <feature> value
 280         # (an array) or gitweb_check_feature(<feature>) to check if <feature>
 281         # is enabled
 282
 283         # Enable the 'blame' blob view, showing the last commit that modified
 284         # each line in the file. This can be very CPU-intensive.
 285
 286         # To enable system wide have in $GITWEB_CONFIG
 287         # $feature{'blame'}{'default'} = [1];
 288         # To have project specific config enable override in $GITWEB_CONFIG
 289         # $feature{'blame'}{'override'} = 1;
 290         # and in project config gitweb.blame = 0|1;
 291         'blame' => {
 292                 'sub' => sub { feature_bool('blame', @_) },
 293                 'override' => 0,
 294                 'default' => [0]},
 295
 296         # Enable the 'snapshot' link, providing a compressed archive of any
 297         # tree. This can potentially generate high traffic if you have large
 298         # project.
 299
 300         # Value is a list of formats defined in %known_snapshot_formats that
 301         # you wish to offer.
 302         # To disable system wide have in $GITWEB_CONFIG
 303         # $feature{'snapshot'}{'default'} = [];
 304         # To have project specific config enable override in $GITWEB_CONFIG
 305         # $feature{'snapshot'}{'override'} = 1;
 306         # and in project config, a comma-separated list of formats or "none"
 307         # to disable.  Example: gitweb.snapshot = tbz2,zip;
 308         'snapshot' => {
 309                 'sub' => \&feature_snapshot,
 310                 'override' => 0,
 311                 'default' => ['tgz']},
 312
 313         # Enable text search, which will list the commits which match author,
 314         # committer or commit text to a given string.  Enabled by default.
 315         # Project specific override is not supported.
 316         'search' => {
 317                 'override' => 0,
 318                 'default' => [1]},
 319
 320         # Enable grep search, which will list the files in currently selected
 321         # tree containing the given string. Enabled by default. This can be
 322         # potentially CPU-intensive, of course.
 323
 324         # To enable system wide have in $GITWEB_CONFIG
 325         # $feature{'grep'}{'default'} = [1];
 326         # To have project specific config enable override in $GITWEB_CONFIG
 327         # $feature{'grep'}{'override'} = 1;
 328         # and in project config gitweb.grep = 0|1;
 329         'grep' => {
 330                 'sub' => sub { feature_bool('grep', @_) },
 331                 'override' => 0,
 332                 'default' => [1]},
 333
 334         # Enable the pickaxe search, which will list the commits that modified
 335         # a given string in a file. This can be practical and quite faster
 336         # alternative to 'blame', but still potentially CPU-intensive.
 337
 338         # To enable system wide have in $GITWEB_CONFIG
 339         # $feature{'pickaxe'}{'default'} = [1];
 340         # To have project specific config enable override in $GITWEB_CONFIG
 341         # $feature{'pickaxe'}{'override'} = 1;
 342         # and in project config gitweb.pickaxe = 0|1;
 343         'pickaxe' => {
 344                 'sub' => sub { feature_bool('pickaxe', @_) },
 345                 'override' => 0,
 346                 'default' => [1]},
 347
 348         # Enable showing size of blobs in a 'tree' view, in a separate
 349         # column, similar to what 'ls -l' does.  This cost a bit of IO.
 350
 351         # To disable system wide have in $GITWEB_CONFIG
 352         # $feature{'show-sizes'}{'default'} = [0];
 353         # To have project specific config enable override in $GITWEB_CONFIG
 354         # $feature{'show-sizes'}{'override'} = 1;
 355         # and in project config gitweb.showsizes = 0|1;
 356         'show-sizes' => {
 357                 'sub' => sub { feature_bool('showsizes', @_) },
 358                 'override' => 0,
 359                 'default' => [1]},
 360
 361         # Make gitweb use an alternative format of the URLs which can be
 362         # more readable and natural-looking: project name is embedded
 363         # directly in the path and the query string contains other
 364         # auxiliary information. All gitweb installations recognize
 365         # URL in either format; this configures in which formats gitweb
 366         # generates links.
 367
 368         # To enable system wide have in $GITWEB_CONFIG
 369         # $feature{'pathinfo'}{'default'} = [1];
 370         # Project specific override is not supported.
 371
 372         # Note that you will need to change the default location of CSS,
 373         # favicon, logo and possibly other files to an absolute URL. Also,
 374         # if gitweb.cgi serves as your indexfile, you will need to force
 375         # $my_uri to contain the script name in your $GITWEB_CONFIG.
 376         'pathinfo' => {
 377                 'override' => 0,
 378                 'default' => [0]},
 379
 380         # Make gitweb consider projects in project root subdirectories
 381         # to be forks of existing projects. Given project $projname.git,
 382         # projects matching $projname/*.git will not be shown in the main
 383         # projects list, instead a '+' mark will be added to $projname
 384         # there and a 'forks' view will be enabled for the project, listing
 385         # all the forks. If project list is taken from a file, forks have
 386         # to be listed after the main project.
 387
 388         # To enable system wide have in $GITWEB_CONFIG
 389         # $feature{'forks'}{'default'} = [1];
 390         # Project specific override is not supported.
 391         'forks' => {
 392                 'override' => 0,
 393                 'default' => [0]},
 394
 395         # Insert custom links to the action bar of all project pages.
 396         # This enables you mainly to link to third-party scripts integrating
 397         # into gitweb; e.g. git-browser for graphical history representation
 398         # or custom web-based repository administration interface.
 399
 400         # The 'default' value consists of a list of triplets in the form
 401         # (label, link, position) where position is the label after which
 402         # to insert the link and link is a format string where %n expands
 403         # to the project name, %f to the project path within the filesystem,
 404         # %h to the current hash (h gitweb parameter) and %b to the current
 405         # hash base (hb gitweb parameter); %% expands to %.
 406
 407         # To enable system wide have in $GITWEB_CONFIG e.g.
 408         # $feature{'actions'}{'default'} = [('graphiclog',
 409         #       '/git-browser/by-commit.html?r=%n', 'summary')];
 410         # Project specific override is not supported.
 411         'actions' => {
 412                 'override' => 0,
 413                 'default' => []},
 414
 415         # Allow gitweb scan project content tags described in ctags/
 416         # of project repository, and display the popular Web 2.0-ish
 417         # "tag cloud" near the project list. Note that this is something
 418         # COMPLETELY different from the normal Git tags.
 419
 420         # gitweb by itself can show existing tags, but it does not handle
 421         # tagging itself; you need an external application for that.
 422         # For an example script, check Girocco's cgi/tagproj.cgi.
 423         # You may want to install the HTML::TagCloud Perl module to get
 424         # a pretty tag cloud instead of just a list of tags.
 425
 426         # To enable system wide have in $GITWEB_CONFIG
 427         # $feature{'ctags'}{'default'} = ['path_to_tag_script'];
 428         # Project specific override is not supported.
 429         'ctags' => {
 430                 'override' => 0,
 431                 'default' => [0]},
 432
 433         # The maximum number of patches in a patchset generated in patch
 434         # view. Set this to 0 or undef to disable patch view, or to a
 435         # negative number to remove any limit.
 436
 437         # To disable system wide have in $GITWEB_CONFIG
 438         # $feature{'patches'}{'default'} = [0];
 439         # To have project specific config enable override in $GITWEB_CONFIG
 440         # $feature{'patches'}{'override'} = 1;
 441         # and in project config gitweb.patches = 0|n;
 442         # where n is the maximum number of patches allowed in a patchset.
 443         'patches' => {
 444                 'sub' => \&feature_patches,
 445                 'override' => 0,
 446                 'default' => [16]},
 447
 448         # Avatar support. When this feature is enabled, views such as
 449         # shortlog or commit will display an avatar associated with
 450         # the email of the committer(s) and/or author(s).
 451
 452         # Currently available providers are gravatar and picon.
 453         # If an unknown provider is specified, the feature is disabled.
 454
 455         # Gravatar depends on Digest::MD5.
 456         # Picon currently relies on the indiana.edu database.
 457
 458         # To enable system wide have in $GITWEB_CONFIG
 459         # $feature{'avatar'}{'default'} = ['<provider>'];
 460         # where <provider> is either gravatar or picon.
 461         # To have project specific config enable override in $GITWEB_CONFIG
 462         # $feature{'avatar'}{'override'} = 1;
 463         # and in project config gitweb.avatar = <provider>;
 464         'avatar' => {
 465                 'sub' => \&feature_avatar,
 466                 'override' => 0,
 467                 'default' => ['']},
 468
 469         # Enable displaying how much time and how many git commands
 470         # it took to generate and display page.  Disabled by default.
 471         # Project specific override is not supported.
 472         'timed' => {
 473                 'override' => 0,
 474                 'default' => [0]},
 475
 476         # Enable turning some links into links to actions which require
 477         # JavaScript to run (like 'blame_incremental').  Not enabled by
 478         # default.  Project specific override is currently not supported.
 479         'javascript-actions' => {
 480                 'override' => 0,
 481                 'default' => [0]},
 482
 483         # Syntax highlighting support. This is based on Daniel Svensson's
 484         # and Sham Chukoury's work in gitweb-xmms2.git.
 485         # It requires the 'highlight' program present in $PATH,
 486         # and therefore is disabled by default.
 487
 488         # To enable system wide have in $GITWEB_CONFIG
 489         # $feature{'highlight'}{'default'} = [1];
 490
 491         'highlight' => {
 492                 'sub' => sub { feature_bool('highlight', @_) },
 493                 'override' => 0,
 494                 'default' => [0]},
 495
 496         # Enable displaying of remote heads in the heads list
 497
 498         # To enable system wide have in $GITWEB_CONFIG
 499         # $feature{'remote_heads'}{'default'} = [1];
 500         # To have project specific config enable override in $GITWEB_CONFIG
 501         # $feature{'remote_heads'}{'override'} = 1;
 502         # and in project config gitweb.remote_heads = 0|1;
 503         'remote_heads' => {
 504                 'sub' => sub { feature_bool('remote_heads', @_) },
 505                 'override' => 0,
 506                 'default' => [0]},
 507 );
 508
 509 sub gitweb_get_feature {
 510         my ($name) = @_;
 511         return unless exists $feature{$name};
 512         my ($sub, $override, @defaults) = (
 513                 $feature{$name}{'sub'},
 514                 $feature{$name}{'override'},
 515                 @{$feature{$name}{'default'}});
 516         # project specific override is possible only if we have project
 517         our $git_dir; # global variable, declared later
 518         if (!$override || !defined $git_dir) {
 519                 return @defaults;
 520         }
 521         if (!defined $sub) {
 522                 warn "feature $name is not overridable";
 523                 return @defaults;
 524         }
 525         return $sub->(@defaults);
 526 }
 527
 528 # A wrapper to check if a given feature is enabled.
 529 # With this, you can say
 530 #
 531 #   my $bool_feat = gitweb_check_feature('bool_feat');
 532 #   gitweb_check_feature('bool_feat') or somecode;
 533 #
 534 # instead of
 535 #
 536 #   my ($bool_feat) = gitweb_get_feature('bool_feat');
 537 #   (gitweb_get_feature('bool_feat'))[0] or somecode;
 538 #
 539 sub gitweb_check_feature {
 540         return (gitweb_get_feature(@_))[0];
 541 }
 542
 543
 544 sub feature_bool {
 545         my $key = shift;
 546         my ($val) = git_get_project_config($key, '--bool');
 547
 548         if (!defined $val) {
 549                 return ($_[0]);
 550         } elsif ($val eq 'true') {
 551                 return (1);
 552         } elsif ($val eq 'false') {
 553                 return (0);
 554         }
 555 }
 556
 557 sub feature_snapshot {
 558         my (@fmts) = @_;
 559
 560         my ($val) = git_get_project_config('snapshot');
 561
 562         if ($val) {
 563                 @fmts = ($val eq 'none' ? () : split /\s*[,\s]\s*/, $val);
 564         }
 565
 566         return @fmts;
 567 }
 568
 569 sub feature_patches {
 570         my @val = (git_get_project_config('patches', '--int'));
 571
 572         if (@val) {
 573                 return @val;
 574         }
 575
 576         return ($_[0]);
 577 }
 578
 579 sub feature_avatar {
 580         my @val = (git_get_project_config('avatar'));
 581
 582         return @val ? @val : @_;
 583 }
 584
 585 # checking HEAD file with -e is fragile if the repository was
 586 # initialized long time ago (i.e. symlink HEAD) and was pack-ref'ed
 587 # and then pruned.
 588 sub check_head_link {
 589         my ($dir) = @_;
 590         my $headfile = "$dir/HEAD";
 591         return ((-e $headfile) ||
 592                 (-l $headfile && readlink($headfile) =~ /^refs\/heads\//));
 593 }
 594
 595 sub check_export_ok {
 596         my ($dir) = @_;
 597         return (check_head_link($dir) &&
 598                 (!$export_ok || -e "$dir/$export_ok") &&
 599                 (!$export_auth_hook || $export_auth_hook->($dir)));
 600 }
 601
 602 # process alternate names for backward compatibility
 603 # filter out unsupported (unknown) snapshot formats
 604 sub filter_snapshot_fmts {
 605         my @fmts = @_;
 606
 607         @fmts = map {
 608                 exists $known_snapshot_format_aliases{$_} ?
 609                        $known_snapshot_format_aliases{$_} : $_} @fmts;
 610         @fmts = grep {
 611                 exists $known_snapshot_formats{$_} &&
 612                 !$known_snapshot_formats{$_}{'disabled'}} @fmts;
 613 }
 614
 615 our ($GITWEB_CONFIG, $GITWEB_CONFIG_SYSTEM);
 616 sub evaluate_gitweb_config {
 617         our $GITWEB_CONFIG = $ENV{'GITWEB_CONFIG'} || "++GITWEB_CONFIG++";
 618         our $GITWEB_CONFIG_SYSTEM = $ENV{'GITWEB_CONFIG_SYSTEM'} || "++GITWEB_CONFIG_SYSTEM++";
 619         # die if there are errors parsing config file
 620         if (-e $GITWEB_CONFIG) {
 621                 do $GITWEB_CONFIG;
 622                 die $@ if $@;
 623         } elsif (-e $GITWEB_CONFIG_SYSTEM) {
 624                 do $GITWEB_CONFIG_SYSTEM;
 625                 die $@ if $@;
 626         }
 627 }
 628
 629 # Get loadavg of system, to compare against $maxload.
 630 # Currently it requires '/proc/loadavg' present to get loadavg;
 631 # if it is not present it returns 0, which means no load checking.
 632 sub get_loadavg {
 633         if( -e '/proc/loadavg' ){
 634                 open my $fd, '<', '/proc/loadavg'
 635                         or return 0;
 636                 my @load = split(/\s+/, scalar <$fd>);
 637                 close $fd;
 638
 639                 # The first three columns measure CPU and IO utilization of the last one,
 640                 # five, and 10 minute periods.  The fourth column shows the number of
 641                 # currently running processes and the total number of processes in the m/n
 642                 # format.  The last column displays the last process ID used.
 643                 return $load[0] || 0;
 644         }
 645         # additional checks for load average should go here for things that don't export
 646         # /proc/loadavg
 647
 648         return 0;
 649 }
 650
 651 # version of the core git binary
 652 our $git_version;
 653 sub evaluate_git_version {
 654         our $git_version = qx("$GIT" --version) =~ m/git version (.*)$/ ? $1 : "unknown";
 655         $number_of_git_cmds++;
 656 }
 657
 658 sub check_loadavg {
 659         if (defined $maxload && get_loadavg() > $maxload) {
 660                 die_error(503, "The load average on the server is too high");
 661         }
 662 }
 663
 664 # ======================================================================
 665 # input validation and dispatch
 666
 667 # input parameters can be collected from a variety of sources (presently, CGI
 668 # and PATH_INFO), so we define an %input_params hash that collects them all
 669 # together during validation: this allows subsequent uses (e.g. href()) to be
 670 # agnostic of the parameter origin
 671
 672 our %input_params = ();
 673
 674 # input parameters are stored with the long parameter name as key. This will
 675 # also be used in the href subroutine to convert parameters to their CGI
 676 # equivalent, and since the href() usage is the most frequent one, we store
 677 # the name -> CGI key mapping here, instead of the reverse.
 678 #
 679 # XXX: Warning: If you touch this, check the search form for updating,
 680 # too.
 681
 682 our @cgi_param_mapping = (
 683         project => "p",
 684         action => "a",
 685         file_name => "f",
 686         file_parent => "fp",
 687         hash => "h",
 688         hash_parent => "hp",
 689         hash_base => "hb",
 690         hash_parent_base => "hpb",
 691         page => "pg",
 692         order => "o",
 693         searchtext => "s",
 694         searchtype => "st",
 695         snapshot_format => "sf",
 696         extra_options => "opt",
 697         search_use_regexp => "sr",
 698         # this must be last entry (for manipulation from JavaScript)
 699         javascript => "js"
 700 );
 701 our %cgi_param_mapping = @cgi_param_mapping;
 702
 703 # we will also need to know the possible actions, for validation
 704 our %actions = (
 705         "blame" => \&git_blame,
 706         "blame_incremental" => \&git_blame_incremental,
 707         "blame_data" => \&git_blame_data,
 708         "blobdiff" => \&git_blobdiff,
 709         "blobdiff_plain" => \&git_blobdiff_plain,
 710         "blob" => \&git_blob,
 711         "blob_plain" => \&git_blob_plain,
 712         "commitdiff" => \&git_commitdiff,
 713         "commitdiff_plain" => \&git_commitdiff_plain,
 714         "commit" => \&git_commit,
 715         "forks" => \&git_forks,
 716         "heads" => \&git_heads,
 717         "history" => \&git_history,
 718         "log" => \&git_log,
 719         "patch" => \&git_patch,
 720         "patches" => \&git_patches,
 721         "remotes" => \&git_remotes,
 722         "rss" => \&git_rss,
 723         "atom" => \&git_atom,
 724         "search" => \&git_search,
 725         "search_help" => \&git_search_help,
 726         "shortlog" => \&git_shortlog,
 727         "summary" => \&git_summary,
 728         "tag" => \&git_tag,
 729         "tags" => \&git_tags,
 730         "tree" => \&git_tree,
 731         "snapshot" => \&git_snapshot,
 732         "object" => \&git_object,
 733         # those below don't need $project
 734         "opml" => \&git_opml,
 735         "project_list" => \&git_project_list,
 736         "project_index" => \&git_project_index,
 737 );
 738
 739 # finally, we have the hash of allowed extra_options for the commands that
 740 # allow them
 741 our %allowed_options = (
 742         "--no-merges" => [ qw(rss atom log shortlog history) ],
 743 );
 744
 745 # fill %input_params with the CGI parameters. All values except for 'opt'
 746 # should be single values, but opt can be an array. We should probably
 747 # build an array of parameters that can be multi-valued, but since for the time
 748 # being it's only this one, we just single it out
 749 sub evaluate_query_params {
 750         our $cgi;
 751
 752         while (my ($name, $symbol) = each %cgi_param_mapping) {
 753                 if ($symbol eq 'opt') {
 754                         $input_params{$name} = [ $cgi->param($symbol) ];
 755                 } else {
 756                         $input_params{$name} = $cgi->param($symbol);
 757                 }
 758         }
 759 }
 760
 761 # now read PATH_INFO and update the parameter list for missing parameters
 762 sub evaluate_path_info {
 763         return if defined $input_params{'project'};
 764         return if !$path_info;
 765         $path_info =~ s,^/+,,;
 766         return if !$path_info;
 767
 768         # find which part of PATH_INFO is project
 769         my $project = $path_info;
 770         $project =~ s,/+$,,;
 771         while ($project && !check_head_link("$projectroot/$project")) {
 772                 $project =~ s,/*[^/]*$,,;
 773         }
 774         return unless $project;
 775         $input_params{'project'} = $project;
 776
 777         # do not change any parameters if an action is given using the query string
 778         return if $input_params{'action'};
 779         $path_info =~ s,^\Q$project\E/*,,;
 780
 781         # next, check if we have an action
 782         my $action = $path_info;
 783         $action =~ s,/.*$,,;
 784         if (exists $actions{$action}) {
 785                 $path_info =~ s,^$action/*,,;
 786                 $input_params{'action'} = $action;
 787         }
 788
 789         # list of actions that want hash_base instead of hash, but can have no
 790         # pathname (f) parameter
 791         my @wants_base = (
 792                 'tree',
 793                 'history',
 794         );
 795
 796         # we want to catch, among others
 797         # [$hash_parent_base[:$file_parent]..]$hash_parent[:$file_name]
 798         my ($parentrefname, $parentpathname, $refname, $pathname) =
 799                 ($path_info =~ /^(?:(.+?)(?::(.+))?\.\.)?([^:]+?)?(?::(.+))?$/);
 800
 801         # first, analyze the 'current' part
 802         if (defined $pathname) {
 803                 # we got "branch:filename" or "branch:dir/"
 804                 # we could use git_get_type(branch:pathname), but:
 805                 # - it needs $git_dir
 806                 # - it does a git() call
 807                 # - the convention of terminating directories with a slash
 808                 #   makes it superfluous
 809                 # - embedding the action in the PATH_INFO would make it even
 810                 #   more superfluous
 811                 $pathname =~ s,^/+,,;
 812                 if (!$pathname || substr($pathname, -1) eq "/") {
 813                         $input_params{'action'} ||= "tree";
 814                         $pathname =~ s,/$,,;
 815                 } else {
 816                         # the default action depends on whether we had parent info
 817                         # or not
 818                         if ($parentrefname) {
 819                                 $input_params{'action'} ||= "blobdiff_plain";
 820                         } else {
 821                                 $input_params{'action'} ||= "blob_plain";
 822                         }
 823                 }
 824                 $input_params{'hash_base'} ||= $refname;
 825                 $input_params{'file_name'} ||= $pathname;
 826         } elsif (defined $refname) {
 827                 # we got "branch". In this case we have to choose if we have to
 828                 # set hash or hash_base.
 829                 #
 830                 # Most of the actions without a pathname only want hash to be
 831                 # set, except for the ones specified in @wants_base that want
 832                 # hash_base instead. It should also be noted that hand-crafted
 833                 # links having 'history' as an action and no pathname or hash
 834                 # set will fail, but that happens regardless of PATH_INFO.
 835                 if (defined $parentrefname) {
 836                         # if there is parent let the default be 'shortlog' action
 837                         # (for http://git.example.com/repo.git/A..B links); if there
 838                         # is no parent, dispatch will detect type of object and set
 839                         # action appropriately if required (if action is not set)
 840                         $input_params{'action'} ||= "shortlog";
 841                 }
 842                 if ($input_params{'action'} &&
 843                     grep { $_ eq $input_params{'action'} } @wants_base) {
 844                         $input_params{'hash_base'} ||= $refname;
 845                 } else {
 846                         $input_params{'hash'} ||= $refname;
 847                 }
 848         }
 849
 850         # next, handle the 'parent' part, if present
 851         if (defined $parentrefname) {
 852                 # a missing pathspec defaults to the 'current' filename, allowing e.g.
 853                 # someproject/blobdiff/oldrev..newrev:/filename
 854                 if ($parentpathname) {
 855                         $parentpathname =~ s,^/+,,;
 856                         $parentpathname =~ s,/$,,;
 857                         $input_params{'file_parent'} ||= $parentpathname;
 858                 } else {
 859                         $input_params{'file_parent'} ||= $input_params{'file_name'};
 860                 }
 861                 # we assume that hash_parent_base is wanted if a path was specified,
 862                 # or if the action wants hash_base instead of hash
 863                 if (defined $input_params{'file_parent'} ||
 864                         grep { $_ eq $input_params{'action'} } @wants_base) {
 865                         $input_params{'hash_parent_base'} ||= $parentrefname;
 866                 } else {
 867                         $input_params{'hash_parent'} ||= $parentrefname;
 868                 }
 869         }
 870
 871         # for the snapshot action, we allow URLs in the form
 872         # $project/snapshot/$hash.ext
 873         # where .ext determines the snapshot and gets removed from the
 874         # passed $refname to provide the $hash.
 875         #
 876         # To be able to tell that $refname includes the format extension, we
 877         # require the following two conditions to be satisfied:
 878         # - the hash input parameter MUST have been set from the $refname part
 879         #   of the URL (i.e. they must be equal)
 880         # - the snapshot format MUST NOT have been defined already (e.g. from
 881         #   CGI parameter sf)
 882         # It's also useless to try any matching unless $refname has a dot,
 883         # so we check for that too
 884         if (defined $input_params{'action'} &&
 885                 $input_params{'action'} eq 'snapshot' &&
 886                 defined $refname && index($refname, '.') != -1 &&
 887                 $refname eq $input_params{'hash'} &&
 888                 !defined $input_params{'snapshot_format'}) {
 889                 # We loop over the known snapshot formats, checking for
 890                 # extensions. Allowed extensions are both the defined suffix
 891                 # (which includes the initial dot already) and the snapshot
 892                 # format key itself, with a prepended dot
 893                 while (my ($fmt, $opt) = each %known_snapshot_formats) {
 894                         my $hash = $refname;
 895                         unless ($hash =~ s/(\Q$opt->{'suffix'}\E|\Q.$fmt\E)$//) {
 896                                 next;
 897                         }
 898                         my $sfx = $1;
 899                         # a valid suffix was found, so set the snapshot format
 900                         # and reset the hash parameter
 901                         $input_params{'snapshot_format'} = $fmt;
 902                         $input_params{'hash'} = $hash;
 903                         # we also set the format suffix to the one requested
 904                         # in the URL: this way a request for e.g. .tgz returns
 905                         # a .tgz instead of a .tar.gz
 906                         $known_snapshot_formats{$fmt}{'suffix'} = $sfx;
 907                         last;
 908                 }
 909         }
 910 }
 911
 912 our ($action, $project, $file_name, $file_parent, $hash, $hash_parent, $hash_base,
 913      $hash_parent_base, @extra_options, $page, $searchtype, $search_use_regexp,
 914      $searchtext, $search_regexp);
 915 sub evaluate_and_validate_params {
 916         our $action = $input_params{'action'};
 917         if (defined $action) {
 918                 if (!validate_action($action)) {
 919                         die_error(400, "Invalid action parameter");
 920                 }
 921         }
 922
 923         # parameters which are pathnames
 924         our $project = $input_params{'project'};
 925         if (defined $project) {
 926                 if (!validate_project($project)) {
 927                         undef $project;
 928                         die_error(404, "No such project");
 929                 }
 930         }
 931
 932         our $file_name = $input_params{'file_name'};
 933         if (defined $file_name) {
 934                 if (!validate_pathname($file_name)) {
 935                         die_error(400, "Invalid file parameter");
 936                 }
 937         }
 938
 939         our $file_parent = $input_params{'file_parent'};
 940         if (defined $file_parent) {
 941                 if (!validate_pathname($file_parent)) {
 942                         die_error(400, "Invalid file parent parameter");
 943                 }
 944         }
 945
 946         # parameters which are refnames
 947         our $hash = $input_params{'hash'};
 948         if (defined $hash) {
 949                 if (!validate_refname($hash)) {
 950                         die_error(400, "Invalid hash parameter");
 951                 }
 952         }
 953
 954         our $hash_parent = $input_params{'hash_parent'};
 955         if (defined $hash_parent) {
 956                 if (!validate_refname($hash_parent)) {
 957                         die_error(400, "Invalid hash parent parameter");
 958                 }
 959         }
 960
 961         our $hash_base = $input_params{'hash_base'};
 962         if (defined $hash_base) {
 963                 if (!validate_refname($hash_base)) {
 964                         die_error(400, "Invalid hash base parameter");
 965                 }
 966         }
 967
 968         our @extra_options = @{$input_params{'extra_options'}};
 969         # @extra_options is always defined, since it can only be (currently) set from
 970         # CGI, and $cgi->param() returns the empty array in array context if the param
 971         # is not set
 972         foreach my $opt (@extra_options) {
 973                 if (not exists $allowed_options{$opt}) {
 974                         die_error(400, "Invalid option parameter");
 975                 }
 976                 if (not grep(/^$action$/, @{$allowed_options{$opt}})) {
 977                         die_error(400, "Invalid option parameter for this action");
 978                 }
 979         }
 980
 981         our $hash_parent_base = $input_params{'hash_parent_base'};
 982         if (defined $hash_parent_base) {
 983                 if (!validate_refname($hash_parent_base)) {
 984                         die_error(400, "Invalid hash parent base parameter");
 985                 }
 986         }
 987
 988         # other parameters
 989         our $page = $input_params{'page'};
 990         if (defined $page) {
 991                 if ($page =~ m/[^0-9]/) {
 992                         die_error(400, "Invalid page parameter");
 993                 }
 994         }
 995
 996         our $searchtype = $input_params{'searchtype'};
 997         if (defined $searchtype) {
 998                 if ($searchtype =~ m/[^a-z]/) {
 999                         die_error(400, "Invalid searchtype parameter");
1000                 }
1001         }
1002
1003         our $search_use_regexp = $input_params{'search_use_regexp'};
1004
1005         our $searchtext = $input_params{'searchtext'};
1006         our $search_regexp;
1007         if (defined $searchtext) {
1008                 if (length($searchtext) < 2) {
1009                         die_error(403, "At least two characters are required for search parameter");
1010                 }
1011                 $search_regexp = $search_use_regexp ? $searchtext : quotemeta $searchtext;
1012         }
1013 }
1014
1015 # path to the current git repository
1016 our $git_dir;
1017 sub evaluate_git_dir {
1018         our $git_dir = "$projectroot/$project" if $project;
1019 }
1020
1021 our (@snapshot_fmts, $git_avatar);
1022 sub configure_gitweb_features {
1023         # list of supported snapshot formats
1024         our @snapshot_fmts = gitweb_get_feature('snapshot');
1025         @snapshot_fmts = filter_snapshot_fmts(@snapshot_fmts);
1026
1027         # check that the avatar feature is set to a known provider name,
1028         # and for each provider check if the dependencies are satisfied.
1029         # if the provider name is invalid or the dependencies are not met,
1030         # reset $git_avatar to the empty string.
1031         our ($git_avatar) = gitweb_get_feature('avatar');
1032         if ($git_avatar eq 'gravatar') {
1033                 $git_avatar = '' unless (eval { require Digest::MD5; 1; });
1034         } elsif ($git_avatar eq 'picon') {
1035                 # no dependencies
1036         } else {
1037                 $git_avatar = '';
1038         }
1039 }
1040
1041 # custom error handler: 'die <message>' is Internal Server Error
1042 sub handle_errors_html {
1043         my $msg = shift; # it is already HTML escaped
1044
1045         # to avoid infinite loop where error occurs in die_error,
1046         # change handler to default handler, disabling handle_errors_html
1047         set_message("Error occured when inside die_error:\n$msg");
1048
1049         # you cannot jump out of die_error when called as error handler;
1050         # the subroutine set via CGI::Carp::set_message is called _after_
1051         # HTTP headers are already written, so it cannot write them itself
1052         die_error(undef, undef, $msg, -error_handler => 1, -no_http_header => 1);
1053 }
1054 set_message(\&handle_errors_html);
1055
1056 # dispatch
1057 sub dispatch {
1058         if (!defined $action) {
1059                 if (defined $hash) {
1060                         $action = git_get_type($hash);
1061                 } elsif (defined $hash_base && defined $file_name) {
1062                         $action = git_get_type("$hash_base:$file_name");
1063                 } elsif (defined $project) {
1064                         $action = 'summary';
1065                 } else {
1066                         $action = 'project_list';
1067                 }
1068         }
1069         if (!defined($actions{$action})) {
1070                 die_error(400, "Unknown action");
1071         }
1072         if ($action !~ m/^(?:opml|project_list|project_index)$/ &&
1073             !$project) {
1074                 die_error(400, "Project needed");
1075         }
1076         $actions{$action}->();
1077 }
1078
1079 sub reset_timer {
1080         our $t0 = [ gettimeofday() ]
1081                 if defined $t0;
1082         our $number_of_git_cmds = 0;
1083 }
1084
1085 sub run_request {
1086         reset_timer();
1087
1088         evaluate_uri();
1089         evaluate_gitweb_config();
1090         evaluate_git_version();
1091         check_loadavg();
1092
1093         # $projectroot and $projects_list might be set in gitweb config file
1094         $projects_list ||= $projectroot;
1095
1096         evaluate_query_params();
1097         evaluate_path_info();
1098         evaluate_and_validate_params();
1099         evaluate_git_dir();
1100
1101         configure_gitweb_features();
1102
1103         dispatch();
1104 }
1105
1106 our $is_last_request = sub { 1 };
1107 our ($pre_dispatch_hook, $post_dispatch_hook, $pre_listen_hook);
1108 our $CGI = 'CGI';
1109 our $cgi;
1110 sub configure_as_fcgi {
1111         require CGI::Fast;
1112         our $CGI = 'CGI::Fast';
1113
1114         my $request_number = 0;
1115         # let each child service 100 requests
1116         our $is_last_request = sub { ++$request_number > 100 };
1117 }
1118 sub evaluate_argv {
1119         my $script_name = $ENV{'SCRIPT_NAME'} || $ENV{'SCRIPT_FILENAME'} || __FILE__;
1120         configure_as_fcgi()
1121                 if $script_name =~ /\.fcgi$/;
1122
1123         return unless (@ARGV);
1124
1125         require Getopt::Long;
1126         Getopt::Long::GetOptions(
1127                 'fastcgi|fcgi|f' => \&configure_as_fcgi,
1128                 'nproc|n=i' => sub {
1129                         my ($arg, $val) = @_;
1130                         return unless eval { require FCGI::ProcManager; 1; };
1131                         my $proc_manager = FCGI::ProcManager->new({
1132                                 n_processes => $val,
1133                         });
1134                         our $pre_listen_hook    = sub { $proc_manager->pm_manage()        };
1135                         our $pre_dispatch_hook  = sub { $proc_manager->pm_pre_dispatch()  };
1136                         our $post_dispatch_hook = sub { $proc_manager->pm_post_dispatch() };
1137                 },
1138         );
1139 }
1140
1141 sub run {
1142         evaluate_argv();
1143
1144         $pre_listen_hook->()
1145                 if $pre_listen_hook;
1146
1147  REQUEST:
1148         while ($cgi = $CGI->new()) {
1149                 $pre_dispatch_hook->()
1150                         if $pre_dispatch_hook;
1151
1152                 run_request();
1153
1154                 $post_dispatch_hook->()
1155                         if $post_dispatch_hook;
1156
1157                 last REQUEST if ($is_last_request->());
1158         }
1159
1160  DONE_GITWEB:
1161         1;
1162 }
1163
1164 run();
1165
1166 if (defined caller) {
1167         # wrapped in a subroutine processing requests,
1168         # e.g. mod_perl with ModPerl::Registry, or PSGI with Plack::App::WrapCGI
1169         return;
1170 } else {
1171         # pure CGI script, serving single request
1172         exit;
1173 }
1174
1175 ## ======================================================================
1176 ## action links
1177
1178 # possible values of extra options
1179 # -full => 0|1      - use absolute/full URL ($my_uri/$my_url as base)
1180 # -replay => 1      - start from a current view (replay with modifications)
1181 # -path_info => 0|1 - don't use/use path_info URL (if possible)
1182 sub href {
1183         my %params = @_;
1184         # default is to use -absolute url() i.e. $my_uri
1185         my $href = $params{-full} ? $my_url : $my_uri;
1186
1187         $params{'project'} = $project unless exists $params{'project'};
1188
1189         if ($params{-replay}) {
1190                 while (my ($name, $symbol) = each %cgi_param_mapping) {
1191                         if (!exists $params{$name}) {
1192                                 $params{$name} = $input_params{$name};
1193                         }
1194                 }
1195         }
1196
1197         my $use_pathinfo = gitweb_check_feature('pathinfo');
1198         if (defined $params{'project'} &&
1199             (exists $params{-path_info} ? $params{-path_info} : $use_pathinfo)) {
1200                 # try to put as many parameters as possible in PATH_INFO:
1201                 #   - project name
1202                 #   - action
1203                 #   - hash_parent or hash_parent_base:/file_parent
1204                 #   - hash or hash_base:/filename
1205                 #   - the snapshot_format as an appropriate suffix
1206
1207                 # When the script is the root DirectoryIndex for the domain,
1208                 # $href here would be something like http://gitweb.example.com/
1209                 # Thus, we strip any trailing / from $href, to spare us double
1210                 # slashes in the final URL
1211                 $href =~ s,/$,,;
1212
1213                 # Then add the project name, if present
1214                 $href .= "/".esc_url($params{'project'});
1215                 delete $params{'project'};
1216
1217                 # since we destructively absorb parameters, we keep this
1218                 # boolean that remembers if we're handling a snapshot
1219                 my $is_snapshot = $params{'action'} eq 'snapshot';
1220
1221                 # Summary just uses the project path URL, any other action is
1222                 # added to the URL
1223                 if (defined $params{'action'}) {
1224                         $href .= "/".esc_url($params{'action'}) unless $params{'action'} eq 'summary';
1225                         delete $params{'action'};
1226                 }
1227
1228                 # Next, we put hash_parent_base:/file_parent..hash_base:/file_name,
1229                 # stripping nonexistent or useless pieces
1230                 $href .= "/" if ($params{'hash_base'} || $params{'hash_parent_base'}
1231                         || $params{'hash_parent'} || $params{'hash'});
1232                 if (defined $params{'hash_base'}) {
1233                         if (defined $params{'hash_parent_base'}) {
1234                                 $href .= esc_url($params{'hash_parent_base'});
1235                                 # skip the file_parent if it's the same as the file_name
1236                                 if (defined $params{'file_parent'}) {
1237                                         if (defined $params{'file_name'} && $params{'file_parent'} eq $params{'file_name'}) {
1238                                                 delete $params{'file_parent'};
1239                                         } elsif ($params{'file_parent'} !~ /\.\./) {
1240                                                 $href .= ":/".esc_url($params{'file_parent'});
1241                                                 delete $params{'file_parent'};
1242                                         }
1243                                 }
1244                                 $href .= "..";
1245                                 delete $params{'hash_parent'};
1246                                 delete $params{'hash_parent_base'};
1247                         } elsif (defined $params{'hash_parent'}) {
1248                                 $href .= esc_url($params{'hash_parent'}). "..";
1249                                 delete $params{'hash_parent'};
1250                         }
1251
1252                         $href .= esc_url($params{'hash_base'});
1253                         if (defined $params{'file_name'} && $params{'file_name'} !~ /\.\./) {
1254                                 $href .= ":/".esc_url($params{'file_name'});
1255                                 delete $params{'file_name'};
1256                         }
1257                         delete $params{'hash'};
1258                         delete $params{'hash_base'};
1259                 } elsif (defined $params{'hash'}) {
1260                         $href .= esc_url($params{'hash'});
1261                         delete $params{'hash'};
1262                 }
1263
1264                 # If the action was a snapshot, we can absorb the
1265                 # snapshot_format parameter too
1266                 if ($is_snapshot) {
1267                         my $fmt = $params{'snapshot_format'};
1268                         # snapshot_format should always be defined when href()
1269                         # is called, but just in case some code forgets, we
1270                         # fall back to the default
1271                         $fmt ||= $snapshot_fmts[0];
1272                         $href .= $known_snapshot_formats{$fmt}{'suffix'};
1273                         delete $params{'snapshot_format'};
1274                 }
1275         }
1276
1277         # now encode the parameters explicitly
1278         my @result = ();
1279         for (my $i = 0; $i < @cgi_param_mapping; $i += 2) {
1280                 my ($name, $symbol) = ($cgi_param_mapping[$i], $cgi_param_mapping[$i+1]);
1281                 if (defined $params{$name}) {
1282                         if (ref($params{$name}) eq "ARRAY") {
1283                                 foreach my $par (@{$params{$name}}) {
1284                                         push @result, $symbol . "=" . esc_param($par);
1285                                 }
1286                         } else {
1287                                 push @result, $symbol . "=" . esc_param($params{$name});
1288                         }
1289                 }
1290         }
1291         $href .= "?" . join(';', @result) if scalar @result;
1292
1293         return $href;
1294 }
1295
1296
1297 ## ======================================================================
1298 ## validation, quoting/unquoting and escaping
1299
1300 sub validate_action {
1301         my $input = shift || return undef;
1302         return undef unless exists $actions{$input};
1303         return $input;
1304 }
1305
1306 sub validate_project {
1307         my $input = shift || return undef;
1308         if (!validate_pathname($input) ||
1309                 !(-d "$projectroot/$input") ||
1310                 !check_export_ok("$projectroot/$input") ||
1311                 ($strict_export && !project_in_list($input))) {
1312                 return undef;
1313         } else {
1314                 return $input;
1315         }
1316 }
1317
1318 sub validate_pathname {
1319         my $input = shift || return undef;
1320
1321         # no '.' or '..' as elements of path, i.e. no '.' nor '..'
1322         # at the beginning, at the end, and between slashes.
1323         # also this catches doubled slashes
1324         if ($input =~ m!(^|/)(|\.|\.\.)(/|$)!) {
1325                 return undef;
1326         }
1327         # no null characters
1328         if ($input =~ m!\0!) {
1329                 return undef;
1330         }
1331         return $input;
1332 }
1333
1334 sub validate_refname {
1335         my $input = shift || return undef;
1336
1337         # textual hashes are O.K.
1338         if ($input =~ m/^[0-9a-fA-F]{40}$/) {
1339                 return $input;
1340         }
1341         # it must be correct pathname
1342         $input = validate_pathname($input)
1343                 or return undef;
1344         # restrictions on ref name according to git-check-ref-format
1345         if ($input =~ m!(/\.|\.\.|[\000-\040\177 ~^:?*\[]|/$)!) {
1346                 return undef;
1347         }
1348         return $input;
1349 }
1350
1351 # decode sequences of octets in utf8 into Perl's internal form,
1352 # which is utf-8 with utf8 flag set if needed.  gitweb writes out
1353 # in utf-8 thanks to "binmode STDOUT, ':utf8'" at beginning
1354 sub to_utf8 {
1355         my $str = shift;
1356         return undef unless defined $str;
1357         if (utf8::valid($str)) {
1358                 utf8::decode($str);
1359                 return $str;
1360         } else {
1361                 return decode($fallback_encoding, $str, Encode::FB_DEFAULT);
1362         }
1363 }
1364
1365 # quote unsafe chars, but keep the slash, even when it's not
1366 # correct, but quoted slashes look too horrible in bookmarks
1367 sub esc_param {
1368         my $str = shift;
1369         return undef unless defined $str;
1370         $str =~ s/([^A-Za-z0-9\-_.~()\/:@ ]+)/CGI::escape($1)/eg;
1371         $str =~ s/ /\+/g;
1372         return $str;
1373 }
1374
1375 # quote unsafe chars in whole URL, so some characters cannot be quoted
1376 sub esc_url {
1377         my $str = shift;
1378         return undef unless defined $str;
1379         $str =~ s/([^A-Za-z0-9\-_.~();\/;?:@&= ]+)/CGI::escape($1)/eg;
1380         $str =~ s/ /\+/g;
1381         return $str;
1382 }
1383
1384 # replace invalid utf8 character with SUBSTITUTION sequence
1385 sub esc_html {
1386         my $str = shift;
1387         my %opts = @_;
1388
1389         return undef unless defined $str;
1390
1391         $str = to_utf8($str);
1392         $str = $cgi->escapeHTML($str);
1393         if ($opts{'-nbsp'}) {
1394                 $str =~ s/ /&nbsp;/g;
1395         }
1396         $str =~ s|([[:cntrl:]])|(($1 ne "\t") ? quot_cec($1) : $1)|eg;
1397         return $str;
1398 }
1399
1400 # quote control characters and escape filename to HTML
1401 sub esc_path {
1402         my $str = shift;
1403         my %opts = @_;
1404
1405         return undef unless defined $str;
1406
1407         $str = to_utf8($str);
1408         $str = $cgi->escapeHTML($str);
1409         if ($opts{'-nbsp'}) {
1410                 $str =~ s/ /&nbsp;/g;
1411         }
1412         $str =~ s|([[:cntrl:]])|quot_cec($1)|eg;
1413         return $str;
1414 }
1415
1416 # Make control characters "printable", using character escape codes (CEC)
1417 sub quot_cec {
1418         my $cntrl = shift;
1419         my %opts = @_;
1420         my %es = ( # character escape codes, aka escape sequences
1421                 "\t" => '\t',   # tab            (HT)
1422                 "\n" => '\n',   # line feed      (LF)
1423                 "\r" => '\r',   # carrige return (CR)
1424                 "\f" => '\f',   # form feed      (FF)
1425                 "\b" => '\b',   # backspace      (BS)
1426                 "\a" => '\a',   # alarm (bell)   (BEL)
1427                 "\e" => '\e',   # escape         (ESC)
1428                 "\013" => '\v', # vertical tab   (VT)
1429                 "\000" => '\0', # nul character  (NUL)
1430         );
1431         my $chr = ( (exists $es{$cntrl})
1432                     ? $es{$cntrl}
1433                     : sprintf('\%2x', ord($cntrl)) );
1434         if ($opts{-nohtml}) {
1435                 return $chr;
1436         } else {
1437                 return "<span class=\"cntrl\">$chr</span>";
1438         }
1439 }
1440
1441 # Alternatively use unicode control pictures codepoints,
1442 # Unicode "printable representation" (PR)
1443 sub quot_upr {
1444         my $cntrl = shift;
1445         my %opts = @_;
1446
1447         my $chr = sprintf('&#%04d;', 0x2400+ord($cntrl));
1448         if ($opts{-nohtml}) {
1449                 return $chr;
1450         } else {
1451                 return "<span class=\"cntrl\">$chr</span>";
1452         }
1453 }
1454
1455 # git may return quoted and escaped filenames
1456 sub unquote {
1457         my $str = shift;
1458
1459         sub unq {
1460                 my $seq = shift;
1461                 my %es = ( # character escape codes, aka escape sequences
1462                         't' => "\t",   # tab            (HT, TAB)
1463                         'n' => "\n",   # newline        (NL)
1464                         'r' => "\r",   # return         (CR)
1465                         'f' => "\f",   # form feed      (FF)
1466                         'b' => "\b",   # backspace      (BS)
1467                         'a' => "\a",   # alarm (bell)   (BEL)
1468                         'e' => "\e",   # escape         (ESC)
1469                         'v' => "\013", # vertical tab   (VT)
1470                 );
1471
1472                 if ($seq =~ m/^[0-7]{1,3}$/) {
1473                         # octal char sequence
1474                         return chr(oct($seq));
1475                 } elsif (exists $es{$seq}) {
1476                         # C escape sequence, aka character escape code
1477                         return $es{$seq};
1478                 }
1479                 # quoted ordinary character
1480                 return $seq;
1481         }
1482
1483         if ($str =~ m/^"(.*)"$/) {
1484                 # needs unquoting
1485                 $str = $1;
1486                 $str =~ s/\\([^0-7]|[0-7]{1,3})/unq($1)/eg;
1487         }
1488         return $str;
1489 }
1490
1491 # escape tabs (convert tabs to spaces)
1492 sub untabify {
1493         my $line = shift;
1494
1495         while ((my $pos = index($line, "\t")) != -1) {
1496                 if (my $count = (8 - ($pos % 8))) {
1497                         my $spaces = ' ' x $count;
1498                         $line =~ s/\t/$spaces/;
1499                 }
1500         }
1501
1502         return $line;
1503 }
1504
1505 sub project_in_list {
1506         my $project = shift;
1507         my @list = git_get_projects_list();
1508         return @list && scalar(grep { $_->{'path'} eq $project } @list);
1509 }
1510
1511 ## ----------------------------------------------------------------------
1512 ## HTML aware string manipulation
1513
1514 # Try to chop given string on a word boundary between position
1515 # $len and $len+$add_len. If there is no word boundary there,
1516 # chop at $len+$add_len. Do not chop if chopped part plus ellipsis
1517 # (marking chopped part) would be longer than given string.
1518 sub chop_str {
1519         my $str = shift;
1520         my $len = shift;
1521         my $add_len = shift || 10;
1522         my $where = shift || 'right'; # 'left' | 'center' | 'right'
1523
1524         # Make sure perl knows it is utf8 encoded so we don't
1525         # cut in the middle of a utf8 multibyte char.
1526         $str = to_utf8($str);
1527
1528         # allow only $len chars, but don't cut a word if it would fit in $add_len
1529         # if it doesn't fit, cut it if it's still longer than the dots we would add
1530         # remove chopped character entities entirely
1531
1532         # when chopping in the middle, distribute $len into left and right part
1533         # return early if chopping wouldn't make string shorter
1534         if ($where eq 'center') {
1535                 return $str if ($len + 5 >= length($str)); # filler is length 5
1536                 $len = int($len/2);
1537         } else {
1538                 return $str if ($len + 4 >= length($str)); # filler is length 4
1539         }
1540
1541         # regexps: ending and beginning with word part up to $add_len
1542         my $endre = qr/.{$len}\w{0,$add_len}/;
1543         my $begre = qr/\w{0,$add_len}.{$len}/;
1544
1545         if ($where eq 'left') {
1546                 $str =~ m/^(.*?)($begre)$/;
1547                 my ($lead, $body) = ($1, $2);
1548                 if (length($lead) > 4) {
1549                         $lead = " ...";
1550                 }
1551                 return "$lead$body";
1552
1553         } elsif ($where eq 'center') {
1554                 $str =~ m/^($endre)(.*)$/;
1555                 my ($left, $str)  = ($1, $2);
1556                 $str =~ m/^(.*?)($begre)$/;
1557                 my ($mid, $right) = ($1, $2);
1558                 if (length($mid) > 5) {
1559                         $mid = " ... ";
1560                 }
1561                 return "$left$mid$right";
1562
1563         } else {
1564                 $str =~ m/^($endre)(.*)$/;
1565                 my $body = $1;
1566                 my $tail = $2;
1567                 if (length($tail) > 4) {
1568                         $tail = "... ";
1569                 }
1570                 return "$body$tail";
1571         }
1572 }
1573
1574 # takes the same arguments as chop_str, but also wraps a <span> around the
1575 # result with a title attribute if it does get chopped. Additionally, the
1576 # string is HTML-escaped.
1577 sub chop_and_escape_str {
1578         my ($str) = @_;
1579
1580         my $chopped = chop_str(@_);
1581         if ($chopped eq $str) {
1582                 return esc_html($chopped);
1583         } else {
1584                 $str =~ s/[[:cntrl:]]/?/g;
1585                 return $cgi->span({-title=>$str}, esc_html($chopped));
1586         }
1587 }
1588
1589 ## ----------------------------------------------------------------------
1590 ## functions returning short strings
1591
1592 # CSS class for given age value (in seconds)
1593 sub age_class {
1594         my $age = shift;
1595
1596         if (!defined $age) {
1597                 return "noage";
1598         } elsif ($age < 60*60*2) {
1599                 return "age0";
1600         } elsif ($age < 60*60*24*2) {
1601                 return "age1";
1602         } else {
1603                 return "age2";
1604         }
1605 }
1606
1607 # convert age in seconds to "nn units ago" string
1608 sub age_string {
1609         my $age = shift;
1610         my $age_str;
1611
1612         if ($age > 60*60*24*365*2) {
1613                 $age_str = (int $age/60/60/24/365);
1614                 $age_str .= " years ago";
1615         } elsif ($age > 60*60*24*(365/12)*2) {
1616                 $age_str = int $age/60/60/24/(365/12);
1617                 $age_str .= " months ago";
1618         } elsif ($age > 60*60*24*7*2) {
1619                 $age_str = int $age/60/60/24/7;
1620                 $age_str .= " weeks ago";
1621         } elsif ($age > 60*60*24*2) {
1622                 $age_str = int $age/60/60/24;
1623                 $age_str .= " days ago";
1624         } elsif ($age > 60*60*2) {
1625                 $age_str = int $age/60/60;
1626                 $age_str .= " hours ago";
1627         } elsif ($age > 60*2) {
1628                 $age_str = int $age/60;
1629                 $age_str .= " min ago";
1630         } elsif ($age > 2) {
1631                 $age_str = int $age;
1632                 $age_str .= " sec ago";
1633         } else {
1634                 $age_str .= " right now";
1635         }
1636         return $age_str;
1637 }
1638
1639 use constant {
1640         S_IFINVALID => 0030000,
1641         S_IFGITLINK => 0160000,
1642 };
1643
1644 # submodule/subproject, a commit object reference
1645 sub S_ISGITLINK {
1646         my $mode = shift;
1647
1648         return (($mode & S_IFMT) == S_IFGITLINK)
1649 }
1650
1651 # convert file mode in octal to symbolic file mode string
1652 sub mode_str {
1653         my $mode = oct shift;
1654
1655         if (S_ISGITLINK($mode)) {
1656                 return 'm---------';
1657         } elsif (S_ISDIR($mode & S_IFMT)) {
1658                 return 'drwxr-xr-x';
1659         } elsif (S_ISLNK($mode)) {
1660                 return 'lrwxrwxrwx';
1661         } elsif (S_ISREG($mode)) {
1662                 # git cares only about the executable bit
1663                 if ($mode & S_IXUSR) {
1664                         return '-rwxr-xr-x';
1665                 } else {
1666                         return '-rw-r--r--';
1667                 };
1668         } else {
1669                 return '----------';
1670         }
1671 }
1672
1673 # convert file mode in octal to file type string
1674 sub file_type {
1675         my $mode = shift;
1676
1677         if ($mode !~ m/^[0-7]+$/) {
1678                 return $mode;
1679         } else {
1680                 $mode = oct $mode;
1681         }
1682
1683         if (S_ISGITLINK($mode)) {
1684                 return "submodule";
1685         } elsif (S_ISDIR($mode & S_IFMT)) {
1686                 return "directory";
1687         } elsif (S_ISLNK($mode)) {
1688                 return "symlink";
1689         } elsif (S_ISREG($mode)) {
1690                 return "file";
1691         } else {
1692                 return "unknown";
1693         }
1694 }
1695
1696 # convert file mode in octal to file type description string
1697 sub file_type_long {
1698         my $mode = shift;
1699
1700         if ($mode !~ m/^[0-7]+$/) {
1701                 return $mode;
1702         } else {
1703                 $mode = oct $mode;
1704         }
1705
1706         if (S_ISGITLINK($mode)) {
1707                 return "submodule";
1708         } elsif (S_ISDIR($mode & S_IFMT)) {
1709                 return "directory";
1710         } elsif (S_ISLNK($mode)) {
1711                 return "symlink";
1712         } elsif (S_ISREG($mode)) {
1713                 if ($mode & S_IXUSR) {
1714                         return "executable";
1715                 } else {
1716                         return "file";
1717                 };
1718         } else {
1719                 return "unknown";
1720         }
1721 }
1722
1723
1724 ## ----------------------------------------------------------------------
1725 ## functions returning short HTML fragments, or transforming HTML fragments
1726 ## which don't belong to other sections
1727
1728 # format line of commit message.
1729 sub format_log_line_html {
1730         my $line = shift;
1731
1732         $line = esc_html($line, -nbsp=>1);
1733         $line =~ s{\b([0-9a-fA-F]{8,40})\b}{
1734                 $cgi->a({-href => href(action=>"object", hash=>$1),
1735                                         -class => "text"}, $1);
1736         }eg;
1737
1738         return $line;
1739 }
1740
1741 # format marker of refs pointing to given object
1742
1743 # the destination action is chosen based on object type and current context:
1744 # - for annotated tags, we choose the tag view unless it's the current view
1745 #   already, in which case we go to shortlog view
1746 # - for other refs, we keep the current view if we're in history, shortlog or
1747 #   log view, and select shortlog otherwise
1748 sub format_ref_marker {
1749         my ($refs, $id) = @_;
1750         my $markers = '';
1751
1752         if (defined $refs->{$id}) {
1753                 foreach my $ref (@{$refs->{$id}}) {
1754                         # this code exploits the fact that non-lightweight tags are the
1755                         # only indirect objects, and that they are the only objects for which
1756                         # we want to use tag instead of shortlog as action
1757                         my ($type, $name) = qw();
1758                         my $indirect = ($ref =~ s/\^\{\}$//);
1759                         # e.g. tags/v2.6.11 or heads/next
1760                         if ($ref =~ m!^(.*?)s?/(.*)$!) {
1761                                 $type = $1;
1762                                 $name = $2;
1763                         } else {
1764                                 $type = "ref";
1765                                 $name = $ref;
1766                         }
1767
1768                         my $class = $type;
1769                         $class .= " indirect" if $indirect;
1770
1771                         my $dest_action = "shortlog";
1772
1773                         if ($indirect) {
1774                                 $dest_action = "tag" unless $action eq "tag";
1775                         } elsif ($action =~ /^(history|(short)?log)$/) {
1776                                 $dest_action = $action;
1777                         }
1778
1779                         my $dest = "";
1780                         $dest .= "refs/" unless $ref =~ m!^refs/!;
1781                         $dest .= $ref;
1782
1783                         my $link = $cgi->a({
1784                                 -href => href(
1785                                         action=>$dest_action,
1786                                         hash=>$dest
1787                                 )}, $name);
1788
1789                         $markers .= " <span class=\"$class\" title=\"$ref\">" .
1790                                 $link . "</span>";
1791                 }
1792         }
1793
1794         if ($markers) {
1795                 return ' <span class="refs">'. $markers . '</span>';
1796         } else {
1797                 return "";
1798         }
1799 }
1800
1801 # format, perhaps shortened and with markers, title line
1802 sub format_subject_html {
1803         my ($long, $short, $href, $extra) = @_;
1804         $extra = '' unless defined($extra);
1805
1806         if (length($short) < length($long)) {
1807                 $long =~ s/[[:cntrl:]]/?/g;
1808                 return $cgi->a({-href => $href, -class => "list subject",
1809                                 -title => to_utf8($long)},
1810                        esc_html($short)) . $extra;
1811         } else {
1812                 return $cgi->a({-href => $href, -class => "list subject"},
1813                        esc_html($long)) . $extra;
1814         }
1815 }
1816
1817 # Rather than recomputing the url for an email multiple times, we cache it
1818 # after the first hit. This gives a visible benefit in views where the avatar
1819 # for the same email is used repeatedly (e.g. shortlog).
1820 # The cache is shared by all avatar engines (currently gravatar only), which
1821 # are free to use it as preferred. Since only one avatar engine is used for any
1822 # given page, there's no risk for cache conflicts.
1823 our %avatar_cache = ();
1824
1825 # Compute the picon url for a given email, by using the picon search service over at
1826 # http://www.cs.indiana.edu/picons/search.html
1827 sub picon_url {
1828         my $email = lc shift;
1829         if (!$avatar_cache{$email}) {
1830                 my ($user, $domain) = split('@', $email);
1831                 $avatar_cache{$email} =
1832                         "http://www.cs.indiana.edu/cgi-pub/kinzler/piconsearch.cgi/" .
1833                         "$domain/$user/" .
1834                         "users+domains+unknown/up/single";
1835         }
1836         return $avatar_cache{$email};
1837 }
1838
1839 # Compute the gravatar url for a given email, if it's not in the cache already.
1840 # Gravatar stores only the part of the URL before the size, since that's the
1841 # one computationally more expensive. This also allows reuse of the cache for
1842 # different sizes (for this particular engine).
1843 sub gravatar_url {
1844         my $email = lc shift;
1845         my $size = shift;
1846         $avatar_cache{$email} ||=
1847                 "http://www.gravatar.com/avatar/" .
1848                         Digest::MD5::md5_hex($email) . "?s=";
1849         return $avatar_cache{$email} . $size;
1850 }
1851
1852 # Insert an avatar for the given $email at the given $size if the feature
1853 # is enabled.
1854 sub git_get_avatar {
1855         my ($email, %opts) = @_;
1856         my $pre_white  = ($opts{-pad_before} ? "&nbsp;" : "");
1857         my $post_white = ($opts{-pad_after}  ? "&nbsp;" : "");
1858         $opts{-size} ||= 'default';
1859         my $size = $avatar_size{$opts{-size}} || $avatar_size{'default'};
1860         my $url = "";
1861         if ($git_avatar eq 'gravatar') {
1862                 $url = gravatar_url($email, $size);
1863         } elsif ($git_avatar eq 'picon') {
1864                 $url = picon_url($email);
1865         }
1866         # Other providers can be added by extending the if chain, defining $url
1867         # as needed. If no variant puts something in $url, we assume avatars
1868         # are completely disabled/unavailable.
1869         if ($url) {
1870                 return $pre_white .
1871                        "<img width=\"$size\" " .
1872                             "class=\"avatar\" " .
1873                             "src=\"$url\" " .
1874                             "alt=\"\" " .
1875                        "/>" . $post_white;
1876         } else {
1877                 return "";
1878         }
1879 }
1880
1881 sub format_search_author {
1882         my ($author, $searchtype, $displaytext) = @_;
1883         my $have_search = gitweb_check_feature('search');
1884
1885         if ($have_search) {
1886                 my $performed = "";
1887                 if ($searchtype eq 'author') {
1888                         $performed = "authored";
1889                 } elsif ($searchtype eq 'committer') {
1890                         $performed = "committed";
1891                 }
1892
1893                 return $cgi->a({-href => href(action=>"search", hash=>$hash,
1894                                 searchtext=>$author,
1895                                 searchtype=>$searchtype), class=>"list",
1896                                 title=>"Search for commits $performed by $author"},
1897                                 $displaytext);
1898
1899         } else {
1900                 return $displaytext;
1901         }
1902 }
1903
1904 # format the author name of the given commit with the given tag
1905 # the author name is chopped and escaped according to the other
1906 # optional parameters (see chop_str).
1907 sub format_author_html {
1908         my $tag = shift;
1909         my $co = shift;
1910         my $author = chop_and_escape_str($co->{'author_name'}, @_);
1911         return "<$tag class=\"author\">" .
1912                format_search_author($co->{'author_name'}, "author",
1913                        git_get_avatar($co->{'author_email'}, -pad_after => 1) .
1914                        $author) .
1915                "</$tag>";
1916 }
1917
1918 # format git diff header line, i.e. "diff --(git|combined|cc) ..."
1919 sub format_git_diff_header_line {
1920         my $line = shift;
1921         my $diffinfo = shift;
1922         my ($from, $to) = @_;
1923
1924         if ($diffinfo->{'nparents'}) {
1925                 # combined diff
1926                 $line =~ s!^(diff (.*?) )"?.*$!$1!;
1927                 if ($to->{'href'}) {
1928                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
1929                                          esc_path($to->{'file'}));
1930                 } else { # file was deleted (no href)
1931                         $line .= esc_path($to->{'file'});
1932                 }
1933         } else {
1934                 # "ordinary" diff
1935                 $line =~ s!^(diff (.*?) )"?a/.*$!$1!;
1936                 if ($from->{'href'}) {
1937                         $line .= $cgi->a({-href => $from->{'href'}, -class => "path"},
1938                                          'a/' . esc_path($from->{'file'}));
1939                 } else { # file was added (no href)
1940                         $line .= 'a/' . esc_path($from->{'file'});
1941                 }
1942                 $line .= ' ';
1943                 if ($to->{'href'}) {
1944                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
1945                                          'b/' . esc_path($to->{'file'}));
1946                 } else { # file was deleted
1947                         $line .= 'b/' . esc_path($to->{'file'});
1948                 }
1949         }
1950
1951         return "<div class=\"diff header\">$line</div>\n";
1952 }
1953
1954 # format extended diff header line, before patch itself
1955 sub format_extended_diff_header_line {
1956         my $line = shift;
1957         my $diffinfo = shift;
1958         my ($from, $to) = @_;
1959
1960         # match <path>
1961         if ($line =~ s!^((copy|rename) from ).*$!$1! && $from->{'href'}) {
1962                 $line .= $cgi->a({-href=>$from->{'href'}, -class=>"path"},
1963                                        esc_path($from->{'file'}));
1964         }
1965         if ($line =~ s!^((copy|rename) to ).*$!$1! && $to->{'href'}) {
1966                 $line .= $cgi->a({-href=>$to->{'href'}, -class=>"path"},
1967                                  esc_path($to->{'file'}));
1968         }
1969         # match single <mode>
1970         if ($line =~ m/\s(\d{6})$/) {
1971                 $line .= '<span class="info"> (' .
1972                          file_type_long($1) .
1973                          ')</span>';
1974         }
1975         # match <hash>
1976         if ($line =~ m/^index [0-9a-fA-F]{40},[0-9a-fA-F]{40}/) {
1977                 # can match only for combined diff
1978                 $line = 'index ';
1979                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
1980                         if ($from->{'href'}[$i]) {
1981                                 $line .= $cgi->a({-href=>$from->{'href'}[$i],
1982                                                   -class=>"hash"},
1983                                                  substr($diffinfo->{'from_id'}[$i],0,7));
1984                         } else {
1985                                 $line .= '0' x 7;
1986                         }
1987                         # separator
1988                         $line .= ',' if ($i < $diffinfo->{'nparents'} - 1);
1989                 }
1990                 $line .= '..';
1991                 if ($to->{'href'}) {
1992                         $line .= $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
1993                                          substr($diffinfo->{'to_id'},0,7));
1994                 } else {
1995                         $line .= '0' x 7;
1996                 }
1997
1998         } elsif ($line =~ m/^index [0-9a-fA-F]{40}..[0-9a-fA-F]{40}/) {
1999                 # can match only for ordinary diff
2000                 my ($from_link, $to_link);
2001                 if ($from->{'href'}) {
2002                         $from_link = $cgi->a({-href=>$from->{'href'}, -class=>"hash"},
2003                                              substr($diffinfo->{'from_id'},0,7));
2004                 } else {
2005                         $from_link = '0' x 7;
2006                 }
2007                 if ($to->{'href'}) {
2008                         $to_link = $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2009                                            substr($diffinfo->{'to_id'},0,7));
2010                 } else {
2011                         $to_link = '0' x 7;
2012                 }
2013                 my ($from_id, $to_id) = ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
2014                 $line =~ s!$from_id\.\.$to_id!$from_link..$to_link!;
2015         }
2016
2017         return $line . "<br/>\n";
2018 }
2019
2020 # format from-file/to-file diff header
2021 sub format_diff_from_to_header {
2022         my ($from_line, $to_line, $diffinfo, $from, $to, @parents) = @_;
2023         my $line;
2024         my $result = '';
2025
2026         $line = $from_line;
2027         #assert($line =~ m/^---/) if DEBUG;
2028         # no extra formatting for "^--- /dev/null"
2029         if (! $diffinfo->{'nparents'}) {
2030                 # ordinary (single parent) diff
2031                 if ($line =~ m!^--- "?a/!) {
2032                         if ($from->{'href'}) {
2033                                 $line = '--- a/' .
2034                                         $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2035                                                 esc_path($from->{'file'}));
2036                         } else {
2037                                 $line = '--- a/' .
2038                                         esc_path($from->{'file'});
2039                         }
2040                 }
2041                 $result .= qq!<div class="diff from_file">$line</div>\n!;
2042
2043         } else {
2044                 # combined diff (merge commit)
2045                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2046                         if ($from->{'href'}[$i]) {
2047                                 $line = '--- ' .
2048                                         $cgi->a({-href=>href(action=>"blobdiff",
2049                                                              hash_parent=>$diffinfo->{'from_id'}[$i],
2050                                                              hash_parent_base=>$parents[$i],
2051                                                              file_parent=>$from->{'file'}[$i],
2052                                                              hash=>$diffinfo->{'to_id'},
2053                                                              hash_base=>$hash,
2054                                                              file_name=>$to->{'file'}),
2055                                                  -class=>"path",
2056                                                  -title=>"diff" . ($i+1)},
2057                                                 $i+1) .
2058                                         '/' .
2059                                         $cgi->a({-href=>$from->{'href'}[$i], -class=>"path"},
2060                                                 esc_path($from->{'file'}[$i]));
2061                         } else {
2062                                 $line = '--- /dev/null';
2063                         }
2064                         $result .= qq!<div class="diff from_file">$line</div>\n!;
2065                 }
2066         }
2067
2068         $line = $to_line;
2069         #assert($line =~ m/^\+\+\+/) if DEBUG;
2070         # no extra formatting for "^+++ /dev/null"
2071         if ($line =~ m!^\+\+\+ "?b/!) {
2072                 if ($to->{'href'}) {
2073                         $line = '+++ b/' .
2074                                 $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2075                                         esc_path($to->{'file'}));
2076                 } else {
2077                         $line = '+++ b/' .
2078                                 esc_path($to->{'file'});
2079                 }
2080         }
2081         $result .= qq!<div class="diff to_file">$line</div>\n!;
2082
2083         return $result;
2084 }
2085
2086 # create note for patch simplified by combined diff
2087 sub format_diff_cc_simplified {
2088         my ($diffinfo, @parents) = @_;
2089         my $result = '';
2090
2091         $result .= "<div class=\"diff header\">" .
2092                    "diff --cc ";
2093         if (!is_deleted($diffinfo)) {
2094                 $result .= $cgi->a({-href => href(action=>"blob",
2095                                                   hash_base=>$hash,
2096                                                   hash=>$diffinfo->{'to_id'},
2097                                                   file_name=>$diffinfo->{'to_file'}),
2098                                     -class => "path"},
2099                                    esc_path($diffinfo->{'to_file'}));
2100         } else {
2101                 $result .= esc_path($diffinfo->{'to_file'});
2102         }
2103         $result .= "</div>\n" . # class="diff header"
2104                    "<div class=\"diff nodifferences\">" .
2105                    "Simple merge" .
2106                    "</div>\n"; # class="diff nodifferences"
2107
2108         return $result;
2109 }
2110
2111 # format patch (diff) line (not to be used for diff headers)
2112 sub format_diff_line {
2113         my $line = shift;
2114         my ($from, $to) = @_;
2115         my $diff_class = "";
2116
2117         chomp $line;
2118
2119         if ($from && $to && ref($from->{'href'}) eq "ARRAY") {
2120                 # combined diff
2121                 my $prefix = substr($line, 0, scalar @{$from->{'href'}});
2122                 if ($line =~ m/^\@{3}/) {
2123                         $diff_class = " chunk_header";
2124                 } elsif ($line =~ m/^\\/) {
2125                         $diff_class = " incomplete";
2126                 } elsif ($prefix =~ tr/+/+/) {
2127                         $diff_class = " add";
2128                 } elsif ($prefix =~ tr/-/-/) {
2129                         $diff_class = " rem";
2130                 }
2131         } else {
2132                 # assume ordinary diff
2133                 my $char = substr($line, 0, 1);
2134                 if ($char eq '+') {
2135                         $diff_class = " add";
2136                 } elsif ($char eq '-') {
2137                         $diff_class = " rem";
2138                 } elsif ($char eq '@') {
2139                         $diff_class = " chunk_header";
2140                 } elsif ($char eq "\\") {
2141                         $diff_class = " incomplete";
2142                 }
2143         }
2144         $line = untabify($line);
2145         if ($from && $to && $line =~ m/^\@{2} /) {
2146                 my ($from_text, $from_start, $from_lines, $to_text, $to_start, $to_lines, $section) =
2147                         $line =~ m/^\@{2} (-(\d+)(?:,(\d+))?) (\+(\d+)(?:,(\d+))?) \@{2}(.*)$/;
2148
2149                 $from_lines = 0 unless defined $from_lines;
2150                 $to_lines   = 0 unless defined $to_lines;
2151
2152                 if ($from->{'href'}) {
2153                         $from_text = $cgi->a({-href=>"$from->{'href'}#l$from_start",
2154                                              -class=>"list"}, $from_text);
2155                 }
2156                 if ($to->{'href'}) {
2157                         $to_text   = $cgi->a({-href=>"$to->{'href'}#l$to_start",
2158                                              -class=>"list"}, $to_text);
2159                 }
2160                 $line = "<span class=\"chunk_info\">@@ $from_text $to_text @@</span>" .
2161                         "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2162                 return "<div class=\"diff$diff_class\">$line</div>\n";
2163         } elsif ($from && $to && $line =~ m/^\@{3}/) {
2164                 my ($prefix, $ranges, $section) = $line =~ m/^(\@+) (.*?) \@+(.*)$/;
2165                 my (@from_text, @from_start, @from_nlines, $to_text, $to_start, $to_nlines);
2166
2167                 @from_text = split(' ', $ranges);
2168                 for (my $i = 0; $i < @from_text; ++$i) {
2169                         ($from_start[$i], $from_nlines[$i]) =
2170                                 (split(',', substr($from_text[$i], 1)), 0);
2171                 }
2172
2173                 $to_text   = pop @from_text;
2174                 $to_start  = pop @from_start;
2175                 $to_nlines = pop @from_nlines;
2176
2177                 $line = "<span class=\"chunk_info\">$prefix ";
2178                 for (my $i = 0; $i < @from_text; ++$i) {
2179                         if ($from->{'href'}[$i]) {
2180                                 $line .= $cgi->a({-href=>"$from->{'href'}[$i]#l$from_start[$i]",
2181                                                   -class=>"list"}, $from_text[$i]);
2182                         } else {
2183                                 $line .= $from_text[$i];
2184                         }
2185                         $line .= " ";
2186                 }
2187                 if ($to->{'href'}) {
2188                         $line .= $cgi->a({-href=>"$to->{'href'}#l$to_start",
2189                                           -class=>"list"}, $to_text);
2190                 } else {
2191                         $line .= $to_text;
2192                 }
2193                 $line .= " $prefix</span>" .
2194                          "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2195                 return "<div class=\"diff$diff_class\">$line</div>\n";
2196         }
2197         return "<div class=\"diff$diff_class\">" . esc_html($line, -nbsp=>1) . "</div>\n";
2198 }
2199
2200 # Generates undef or something like "_snapshot_" or "snapshot (_tbz2_ _zip_)",
2201 # linked.  Pass the hash of the tree/commit to snapshot.
2202 sub format_snapshot_links {
2203         my ($hash) = @_;
2204         my $num_fmts = @snapshot_fmts;
2205         if ($num_fmts > 1) {
2206                 # A parenthesized list of links bearing format names.
2207                 # e.g. "snapshot (_tar.gz_ _zip_)"
2208                 return "snapshot (" . join(' ', map
2209                         $cgi->a({
2210                                 -href => href(
2211                                         action=>"snapshot",
2212                                         hash=>$hash,
2213                                         snapshot_format=>$_
2214                                 )
2215                         }, $known_snapshot_formats{$_}{'display'})
2216                 , @snapshot_fmts) . ")";
2217         } elsif ($num_fmts == 1) {
2218                 # A single "snapshot" link whose tooltip bears the format name.
2219                 # i.e. "_snapshot_"
2220                 my ($fmt) = @snapshot_fmts;
2221                 return
2222                         $cgi->a({
2223                                 -href => href(
2224                                         action=>"snapshot",
2225                                         hash=>$hash,
2226                                         snapshot_format=>$fmt
2227                                 ),
2228                                 -title => "in format: $known_snapshot_formats{$fmt}{'display'}"
2229                         }, "snapshot");
2230         } else { # $num_fmts == 0
2231                 return undef;
2232         }
2233 }
2234
2235 ## ......................................................................
2236 ## functions returning values to be passed, perhaps after some
2237 ## transformation, to other functions; e.g. returning arguments to href()
2238
2239 # returns hash to be passed to href to generate gitweb URL
2240 # in -title key it returns description of link
2241 sub get_feed_info {
2242         my $format = shift || 'Atom';
2243         my %res = (action => lc($format));
2244
2245         # feed links are possible only for project views
2246         return unless (defined $project);
2247         # some views should link to OPML, or to generic project feed,
2248         # or don't have specific feed yet (so they should use generic)
2249         return if ($action =~ /^(?:tags|heads|forks|tag|search)$/x);
2250
2251         my $branch;
2252         # branches refs uses 'refs/heads/' prefix (fullname) to differentiate
2253         # from tag links; this also makes possible to detect branch links
2254         if ((defined $hash_base && $hash_base =~ m!^refs/heads/(.*)$!) ||
2255             (defined $hash      && $hash      =~ m!^refs/heads/(.*)$!)) {
2256                 $branch = $1;
2257         }
2258         # find log type for feed description (title)
2259         my $type = 'log';
2260         if (defined $file_name) {
2261                 $type  = "history of $file_name";
2262                 $type .= "/" if ($action eq 'tree');
2263                 $type .= " on '$branch'" if (defined $branch);
2264         } else {
2265                 $type = "log of $branch" if (defined $branch);
2266         }
2267
2268         $res{-title} = $type;
2269         $res{'hash'} = (defined $branch ? "refs/heads/$branch" : undef);
2270         $res{'file_name'} = $file_name;
2271
2272         return %res;
2273 }
2274
2275 ## ----------------------------------------------------------------------
2276 ## git utility subroutines, invoking git commands
2277
2278 # returns path to the core git executable and the --git-dir parameter as list
2279 sub git_cmd {
2280         $number_of_git_cmds++;
2281         return $GIT, '--git-dir='.$git_dir;
2282 }
2283
2284 # quote the given arguments for passing them to the shell
2285 # quote_command("command", "arg 1", "arg with ' and ! characters")
2286 # => "'command' 'arg 1' 'arg with '\'' and '\!' characters'"
2287 # Try to avoid using this function wherever possible.
2288 sub quote_command {
2289         return join(' ',
2290                 map { my $a = $_; $a =~ s/(['!])/'\\$1'/g; "'$a'" } @_ );
2291 }
2292
2293 # get HEAD ref of given project as hash
2294 sub git_get_head_hash {
2295         return git_get_full_hash(shift, 'HEAD');
2296 }
2297
2298 sub git_get_full_hash {
2299         return git_get_hash(@_);
2300 }
2301
2302 sub git_get_short_hash {
2303         return git_get_hash(@_, '--short=7');
2304 }
2305
2306 sub git_get_hash {
2307         my ($project, $hash, @options) = @_;
2308         my $o_git_dir = $git_dir;
2309         my $retval = undef;
2310         $git_dir = "$projectroot/$project";
2311         if (open my $fd, '-|', git_cmd(), 'rev-parse',
2312             '--verify', '-q', @options, $hash) {
2313                 $retval = <$fd>;
2314                 chomp $retval if defined $retval;
2315                 close $fd;
2316         }
2317         if (defined $o_git_dir) {
2318                 $git_dir = $o_git_dir;
2319         }
2320         return $retval;
2321 }
2322
2323 # get type of given object
2324 sub git_get_type {
2325         my $hash = shift;
2326
2327         open my $fd, "-|", git_cmd(), "cat-file", '-t', $hash or return;
2328         my $type = <$fd>;
2329         close $fd or return;
2330         chomp $type;
2331         return $type;
2332 }
2333
2334 # repository configuration
2335 our $config_file = '';
2336 our %config;
2337
2338 # store multiple values for single key as anonymous array reference
2339 # single values stored directly in the hash, not as [ <value> ]
2340 sub hash_set_multi {
2341         my ($hash, $key, $value) = @_;
2342
2343         if (!exists $hash->{$key}) {
2344                 $hash->{$key} = $value;
2345         } elsif (!ref $hash->{$key}) {
2346                 $hash->{$key} = [ $hash->{$key}, $value ];
2347         } else {
2348                 push @{$hash->{$key}}, $value;
2349         }
2350 }
2351
2352 # return hash of git project configuration
2353 # optionally limited to some section, e.g. 'gitweb'
2354 sub git_parse_project_config {
2355         my $section_regexp = shift;
2356         my %config;
2357
2358         local $/ = "\0";
2359
2360         open my $fh, "-|", git_cmd(), "config", '-z', '-l',
2361                 or return;
2362
2363         while (my $keyval = <$fh>) {
2364                 chomp $keyval;
2365                 my ($key, $value) = split(/\n/, $keyval, 2);
2366
2367                 hash_set_multi(\%config, $key, $value)
2368                         if (!defined $section_regexp || $key =~ /^(?:$section_regexp)\./o);
2369         }
2370         close $fh;
2371
2372         return %config;
2373 }
2374
2375 # convert config value to boolean: 'true' or 'false'
2376 # no value, number > 0, 'true' and 'yes' values are true
2377 # rest of values are treated as false (never as error)
2378 sub config_to_bool {
2379         my $val = shift;
2380
2381         return 1 if !defined $val;             # section.key
2382
2383         # strip leading and trailing whitespace
2384         $val =~ s/^\s+//;
2385         $val =~ s/\s+$//;
2386
2387         return (($val =~ /^\d+$/ && $val) ||   # section.key = 1
2388                 ($val =~ /^(?:true|yes)$/i));  # section.key = true
2389 }
2390
2391 # convert config value to simple decimal number
2392 # an optional value suffix of 'k', 'm', or 'g' will cause the value
2393 # to be multiplied by 1024, 1048576, or 1073741824
2394 sub config_to_int {
2395         my $val = shift;
2396
2397         # strip leading and trailing whitespace
2398         $val =~ s/^\s+//;
2399         $val =~ s/\s+$//;
2400
2401         if (my ($num, $unit) = ($val =~ /^([0-9]*)([kmg])$/i)) {
2402                 $unit = lc($unit);
2403                 # unknown unit is treated as 1
2404                 return $num * ($unit eq 'g' ? 1073741824 :
2405                                $unit eq 'm' ?    1048576 :
2406                                $unit eq 'k' ?       1024 : 1);
2407         }
2408         return $val;
2409 }
2410
2411 # convert config value to array reference, if needed
2412 sub config_to_multi {
2413         my $val = shift;
2414
2415         return ref($val) ? $val : (defined($val) ? [ $val ] : []);
2416 }
2417
2418 sub git_get_project_config {
2419         my ($key, $type) = @_;
2420
2421         return unless defined $git_dir;
2422
2423         # key sanity check
2424         return unless ($key);
2425         $key =~ s/^gitweb\.//;
2426         return if ($key =~ m/\W/);
2427
2428         # type sanity check
2429         if (defined $type) {
2430                 $type =~ s/^--//;
2431                 $type = undef
2432                         unless ($type eq 'bool' || $type eq 'int');
2433         }
2434
2435         # get config
2436         if (!defined $config_file ||
2437             $config_file ne "$git_dir/config") {
2438                 %config = git_parse_project_config('gitweb');
2439                 $config_file = "$git_dir/config";
2440         }
2441
2442         # check if config variable (key) exists
2443         return unless exists $config{"gitweb.$key"};
2444
2445         # ensure given type
2446         if (!defined $type) {
2447                 return $config{"gitweb.$key"};
2448         } elsif ($type eq 'bool') {
2449                 # backward compatibility: 'git config --bool' returns true/false
2450                 return config_to_bool($config{"gitweb.$key"}) ? 'true' : 'false';
2451         } elsif ($type eq 'int') {
2452                 return config_to_int($config{"gitweb.$key"});
2453         }
2454         return $config{"gitweb.$key"};
2455 }
2456
2457 # get hash of given path at given ref
2458 sub git_get_hash_by_path {
2459         my $base = shift;
2460         my $path = shift || return undef;
2461         my $type = shift;
2462
2463         $path =~ s,/+$,,;
2464
2465         open my $fd, "-|", git_cmd(), "ls-tree", $base, "--", $path
2466                 or die_error(500, "Open git-ls-tree failed");
2467         my $line = <$fd>;
2468         close $fd or return undef;
2469
2470         if (!defined $line) {
2471                 # there is no tree or hash given by $path at $base
2472                 return undef;
2473         }
2474
2475         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
2476         $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/;
2477         if (defined $type && $type ne $2) {
2478                 # type doesn't match
2479                 return undef;
2480         }
2481         return $3;
2482 }
2483
2484 # get path of entry with given hash at given tree-ish (ref)
2485 # used to get 'from' filename for combined diff (merge commit) for renames
2486 sub git_get_path_by_hash {
2487         my $base = shift || return;
2488         my $hash = shift || return;
2489
2490         local $/ = "\0";
2491
2492         open my $fd, "-|", git_cmd(), "ls-tree", '-r', '-t', '-z', $base
2493                 or return undef;
2494         while (my $line = <$fd>) {
2495                 chomp $line;
2496
2497                 #'040000 tree 595596a6a9117ddba9fe379b6b012b558bac8423  gitweb'
2498                 #'100644 blob e02e90f0429be0d2a69b76571101f20b8f75530f  gitweb/README'
2499                 if ($line =~ m/(?:[0-9]+) (?:.+) $hash\t(.+)$/) {
2500                         close $fd;
2501                         return $1;
2502                 }
2503         }
2504         close $fd;
2505         return undef;
2506 }
2507
2508 ## ......................................................................
2509 ## git utility functions, directly accessing git repository
2510
2511 sub git_get_project_description {
2512         my $path = shift;
2513
2514         $git_dir = "$projectroot/$path";
2515         open my $fd, '<', "$git_dir/description"
2516                 or return git_get_project_config('description');
2517         my $descr = <$fd>;
2518         close $fd;
2519         if (defined $descr) {
2520                 chomp $descr;
2521         }
2522         return $descr;
2523 }
2524
2525 sub git_get_project_ctags {
2526         my $path = shift;
2527         my $ctags = {};
2528
2529         $git_dir = "$projectroot/$path";
2530         opendir my $dh, "$git_dir/ctags"
2531                 or return $ctags;
2532         foreach (grep { -f $_ } map { "$git_dir/ctags/$_" } readdir($dh)) {
2533                 open my $ct, '<', $_ or next;
2534                 my $val = <$ct>;
2535                 chomp $val;
2536                 close $ct;
2537                 my $ctag = $_; $ctag =~ s#.*/##;
2538                 $ctags->{$ctag} = $val;
2539         }
2540         closedir $dh;
2541         $ctags;
2542 }
2543
2544 sub git_populate_project_tagcloud {
2545         my $ctags = shift;
2546
2547         # First, merge different-cased tags; tags vote on casing
2548         my %ctags_lc;
2549         foreach (keys %$ctags) {
2550                 $ctags_lc{lc $_}->{count} += $ctags->{$_};
2551                 if (not $ctags_lc{lc $_}->{topcount}
2552                     or $ctags_lc{lc $_}->{topcount} < $ctags->{$_}) {
2553                         $ctags_lc{lc $_}->{topcount} = $ctags->{$_};
2554                         $ctags_lc{lc $_}->{topname} = $_;
2555                 }
2556         }
2557
2558         my $cloud;
2559         if (eval { require HTML::TagCloud; 1; }) {
2560                 $cloud = HTML::TagCloud->new;
2561                 foreach (sort keys %ctags_lc) {
2562                         # Pad the title with spaces so that the cloud looks
2563                         # less crammed.
2564                         my $title = $ctags_lc{$_}->{topname};
2565                         $title =~ s/ /&nbsp;/g;
2566                         $title =~ s/^/&nbsp;/g;
2567                         $title =~ s/$/&nbsp;/g;
2568                         $cloud->add($title, $home_link."?by_tag=".$_, $ctags_lc{$_}->{count});
2569                 }
2570         } else {
2571                 $cloud = \%ctags_lc;
2572         }
2573         $cloud;
2574 }
2575
2576 sub git_show_project_tagcloud {
2577         my ($cloud, $count) = @_;
2578         print STDERR ref($cloud)."..\n";
2579         if (ref $cloud eq 'HTML::TagCloud') {
2580                 return $cloud->html_and_css($count);
2581         } else {
2582                 my @tags = sort { $cloud->{$a}->{count} <=> $cloud->{$b}->{count} } keys %$cloud;
2583                 return '<p align="center">' . join (', ', map {
2584                         "<a href=\"$home_link?by_tag=$_\">$cloud->{$_}->{topname}</a>"
2585                 } splice(@tags, 0, $count)) . '</p>';
2586         }
2587 }
2588
2589 sub git_get_project_url_list {
2590         my $path = shift;
2591
2592         $git_dir = "$projectroot/$path";
2593         open my $fd, '<', "$git_dir/cloneurl"
2594                 or return wantarray ?
2595                 @{ config_to_multi(git_get_project_config('url')) } :
2596                    config_to_multi(git_get_project_config('url'));
2597         my @git_project_url_list = map { chomp; $_ } <$fd>;
2598         close $fd;
2599
2600         return wantarray ? @git_project_url_list : \@git_project_url_list;
2601 }
2602
2603 sub git_get_projects_list {
2604         my ($filter) = @_;
2605         my @list;
2606
2607         $filter ||= '';
2608         $filter =~ s/\.git$//;
2609
2610         my $check_forks = gitweb_check_feature('forks');
2611
2612         if (-d $projects_list) {
2613                 # search in directory
2614                 my $dir = $projects_list . ($filter ? "/$filter" : '');
2615                 # remove the trailing "/"
2616                 $dir =~ s!/+$!!;
2617                 my $pfxlen = length("$dir");
2618                 my $pfxdepth = ($dir =~ tr!/!!);
2619
2620                 File::Find::find({
2621                         follow_fast => 1, # follow symbolic links
2622                         follow_skip => 2, # ignore duplicates
2623                         dangling_symlinks => 0, # ignore dangling symlinks, silently
2624                         wanted => sub {
2625                                 # global variables
2626                                 our $project_maxdepth;
2627                                 our $projectroot;
2628                                 # skip project-list toplevel, if we get it.
2629                                 return if (m!^[/.]$!);
2630                                 # only directories can be git repositories
2631                                 return unless (-d $_);
2632                                 # don't traverse too deep (Find is super slow on os x)
2633                                 if (($File::Find::name =~ tr!/!!) - $pfxdepth > $project_maxdepth) {
2634                                         $File::Find::prune = 1;
2635                                         return;
2636                                 }
2637
2638                                 my $subdir = substr($File::Find::name, $pfxlen + 1);
2639                                 # we check related file in $projectroot
2640                                 my $path = ($filter ? "$filter/" : '') . $subdir;
2641                                 if (check_export_ok("$projectroot/$path")) {
2642                                         push @list, { path => $path };
2643                                         $File::Find::prune = 1;
2644                                 }
2645                         },
2646                 }, "$dir");
2647
2648         } elsif (-f $projects_list) {
2649                 # read from file(url-encoded):
2650                 # 'git%2Fgit.git Linus+Torvalds'
2651                 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
2652                 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
2653                 my %paths;
2654                 open my $fd, '<', $projects_list or return;
2655         PROJECT:
2656                 while (my $line = <$fd>) {
2657                         chomp $line;
2658                         my ($path, $owner) = split ' ', $line;
2659                         $path = unescape($path);
2660                         $owner = unescape($owner);
2661                         if (!defined $path) {
2662                                 next;
2663                         }
2664                         if ($filter ne '') {
2665                                 # looking for forks;
2666                                 my $pfx = substr($path, 0, length($filter));
2667                                 if ($pfx ne $filter) {
2668                                         next PROJECT;
2669                                 }
2670                                 my $sfx = substr($path, length($filter));
2671                                 if ($sfx !~ /^\/.*\.git$/) {
2672                                         next PROJECT;
2673                                 }
2674                         } elsif ($check_forks) {
2675                         PATH:
2676                                 foreach my $filter (keys %paths) {
2677                                         # looking for forks;
2678                                         my $pfx = substr($path, 0, length($filter));
2679                                         if ($pfx ne $filter) {
2680                                                 next PATH;
2681                                         }
2682                                         my $sfx = substr($path, length($filter));
2683                                         if ($sfx !~ /^\/.*\.git$/) {
2684                                                 next PATH;
2685                                         }
2686                                         # is a fork, don't include it in
2687                                         # the list
2688                                         next PROJECT;
2689                                 }
2690                         }
2691                         if (check_export_ok("$projectroot/$path")) {
2692                                 my $pr = {
2693                                         path => $path,
2694                                         owner => to_utf8($owner),
2695                                 };
2696                                 push @list, $pr;
2697                                 (my $forks_path = $path) =~ s/\.git$//;
2698                                 $paths{$forks_path}++;
2699                         }
2700                 }
2701                 close $fd;
2702         }
2703         return @list;
2704 }
2705
2706 our $gitweb_project_owner = undef;
2707 sub git_get_project_list_from_file {
2708
2709         return if (defined $gitweb_project_owner);
2710
2711         $gitweb_project_owner = {};
2712         # read from file (url-encoded):
2713         # 'git%2Fgit.git Linus+Torvalds'
2714         # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
2715         # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
2716         if (-f $projects_list) {
2717                 open(my $fd, '<', $projects_list);
2718                 while (my $line = <$fd>) {
2719                         chomp $line;
2720                         my ($pr, $ow) = split ' ', $line;
2721                         $pr = unescape($pr);
2722                         $ow = unescape($ow);
2723                         $gitweb_project_owner->{$pr} = to_utf8($ow);
2724                 }
2725                 close $fd;
2726         }
2727 }
2728
2729 sub git_get_project_owner {
2730         my $project = shift;
2731         my $owner;
2732
2733         return undef unless $project;
2734         $git_dir = "$projectroot/$project";
2735
2736         if (!defined $gitweb_project_owner) {
2737                 git_get_project_list_from_file();
2738         }
2739
2740         if (exists $gitweb_project_owner->{$project}) {
2741                 $owner = $gitweb_project_owner->{$project};
2742         }
2743         if (!defined $owner){
2744                 $owner = git_get_project_config('owner');
2745         }
2746         if (!defined $owner) {
2747                 $owner = get_file_owner("$git_dir");
2748         }
2749
2750         return $owner;
2751 }
2752
2753 sub git_get_last_activity {
2754         my ($path) = @_;
2755         my $fd;
2756
2757         $git_dir = "$projectroot/$path";
2758         open($fd, "-|", git_cmd(), 'for-each-ref',
2759              '--format=%(committer)',
2760              '--sort=-committerdate',
2761              '--count=1',
2762              'refs/heads') or return;
2763         my $most_recent = <$fd>;
2764         close $fd or return;
2765         if (defined $most_recent &&
2766             $most_recent =~ / (\d+) [-+][01]\d\d\d$/) {
2767                 my $timestamp = $1;
2768                 my $age = time - $timestamp;
2769                 return ($age, age_string($age));
2770         }
2771         return (undef, undef);
2772 }
2773
2774 sub git_get_references {
2775         my $type = shift || "";
2776         my %refs;
2777         # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
2778         # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
2779         open my $fd, "-|", git_cmd(), "show-ref", "--dereference",
2780                 ($type ? ("--", "refs/$type") : ()) # use -- <pattern> if $type
2781                 or return;
2782
2783         while (my $line = <$fd>) {
2784                 chomp $line;
2785                 if ($line =~ m!^([0-9a-fA-F]{40})\srefs/($type.*)$!) {
2786                         if (defined $refs{$1}) {
2787                                 push @{$refs{$1}}, $2;
2788                         } else {
2789                                 $refs{$1} = [ $2 ];
2790                         }
2791                 }
2792         }
2793         close $fd or return;
2794         return \%refs;
2795 }
2796
2797 sub git_get_rev_name_tags {
2798         my $hash = shift || return undef;
2799
2800         open my $fd, "-|", git_cmd(), "name-rev", "--tags", $hash
2801                 or return;
2802         my $name_rev = <$fd>;
2803         close $fd;
2804
2805         if ($name_rev =~ m|^$hash tags/(.*)$|) {
2806                 return $1;
2807         } else {
2808                 # catches also '$hash undefined' output
2809                 return undef;
2810         }
2811 }
2812
2813 ## ----------------------------------------------------------------------
2814 ## parse to hash functions
2815
2816 sub parse_date {
2817         my $epoch = shift;
2818         my $tz = shift || "-0000";
2819
2820         my %date;
2821         my @months = ("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec");
2822         my @days = ("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");
2823         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($epoch);
2824         $date{'hour'} = $hour;
2825         $date{'minute'} = $min;
2826         $date{'mday'} = $mday;
2827         $date{'day'} = $days[$wday];
2828         $date{'month'} = $months[$mon];
2829         $date{'rfc2822'}   = sprintf "%s, %d %s %4d %02d:%02d:%02d +0000",
2830                              $days[$wday], $mday, $months[$mon], 1900+$year, $hour ,$min, $sec;
2831         $date{'mday-time'} = sprintf "%d %s %02d:%02d",
2832                              $mday, $months[$mon], $hour ,$min;
2833         $date{'iso-8601'}  = sprintf "%04d-%02d-%02dT%02d:%02d:%02dZ",
2834                              1900+$year, 1+$mon, $mday, $hour ,$min, $sec;
2835
2836         $tz =~ m/^([+\-][0-9][0-9])([0-9][0-9])$/;
2837         my $local = $epoch + ((int $1 + ($2/60)) * 3600);
2838         ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($local);
2839         $date{'hour_local'} = $hour;
2840         $date{'minute_local'} = $min;
2841         $date{'tz_local'} = $tz;
2842         $date{'iso-tz'} = sprintf("%04d-%02d-%02d %02d:%02d:%02d %s",
2843                                   1900+$year, $mon+1, $mday,
2844                                   $hour, $min, $sec, $tz);
2845         return %date;
2846 }
2847
2848 sub parse_tag {
2849         my $tag_id = shift;
2850         my %tag;
2851         my @comment;
2852
2853         open my $fd, "-|", git_cmd(), "cat-file", "tag", $tag_id or return;
2854         $tag{'id'} = $tag_id;
2855         while (my $line = <$fd>) {
2856                 chomp $line;
2857                 if ($line =~ m/^object ([0-9a-fA-F]{40})$/) {
2858                         $tag{'object'} = $1;
2859                 } elsif ($line =~ m/^type (.+)$/) {
2860                         $tag{'type'} = $1;
2861                 } elsif ($line =~ m/^tag (.+)$/) {
2862                         $tag{'name'} = $1;
2863                 } elsif ($line =~ m/^tagger (.*) ([0-9]+) (.*)$/) {
2864                         $tag{'author'} = $1;
2865                         $tag{'author_epoch'} = $2;
2866                         $tag{'author_tz'} = $3;
2867                         if ($tag{'author'} =~ m/^([^<]+) <([^>]*)>/) {
2868                                 $tag{'author_name'}  = $1;
2869                                 $tag{'author_email'} = $2;
2870                         } else {
2871                                 $tag{'author_name'} = $tag{'author'};
2872                         }
2873                 } elsif ($line =~ m/--BEGIN/) {
2874                         push @comment, $line;
2875                         last;
2876                 } elsif ($line eq "") {
2877                         last;
2878                 }
2879         }
2880         push @comment, <$fd>;
2881         $tag{'comment'} = \@comment;
2882         close $fd or return;
2883         if (!defined $tag{'name'}) {
2884                 return
2885         };
2886         return %tag
2887 }
2888
2889 sub parse_commit_text {
2890         my ($commit_text, $withparents) = @_;
2891         my @commit_lines = split '\n', $commit_text;
2892         my %co;
2893
2894         pop @commit_lines; # Remove '\0'
2895
2896         if (! @commit_lines) {
2897                 return;
2898         }
2899
2900         my $header = shift @commit_lines;
2901         if ($header !~ m/^[0-9a-fA-F]{40}/) {
2902                 return;
2903         }
2904         ($co{'id'}, my @parents) = split ' ', $header;
2905         while (my $line = shift @commit_lines) {
2906                 last if $line eq "\n";
2907                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
2908                         $co{'tree'} = $1;
2909                 } elsif ((!defined $withparents) && ($line =~ m/^parent ([0-9a-fA-F]{40})$/)) {
2910                         push @parents, $1;
2911                 } elsif ($line =~ m/^author (.*) ([0-9]+) (.*)$/) {
2912                         $co{'author'} = to_utf8($1);
2913                         $co{'author_epoch'} = $2;
2914                         $co{'author_tz'} = $3;
2915                         if ($co{'author'} =~ m/^([^<]+) <([^>]*)>/) {
2916                                 $co{'author_name'}  = $1;
2917                                 $co{'author_email'} = $2;
2918                         } else {
2919                                 $co{'author_name'} = $co{'author'};
2920                         }
2921                 } elsif ($line =~ m/^committer (.*) ([0-9]+) (.*)$/) {
2922                         $co{'committer'} = to_utf8($1);
2923                         $co{'committer_epoch'} = $2;
2924                         $co{'committer_tz'} = $3;
2925                         if ($co{'committer'} =~ m/^([^<]+) <([^>]*)>/) {
2926                                 $co{'committer_name'}  = $1;
2927                                 $co{'committer_email'} = $2;
2928                         } else {
2929                                 $co{'committer_name'} = $co{'committer'};
2930                         }
2931                 }
2932         }
2933         if (!defined $co{'tree'}) {
2934                 return;
2935         };
2936         $co{'parents'} = \@parents;
2937         $co{'parent'} = $parents[0];
2938
2939         foreach my $title (@commit_lines) {
2940                 $title =~ s/^    //;
2941                 if ($title ne "") {
2942                         $co{'title'} = chop_str($title, 80, 5);
2943                         # remove leading stuff of merges to make the interesting part visible
2944                         if (length($title) > 50) {
2945                                 $title =~ s/^Automatic //;
2946                                 $title =~ s/^merge (of|with) /Merge ... /i;
2947                                 if (length($title) > 50) {
2948                                         $title =~ s/(http|rsync):\/\///;
2949                                 }
2950                                 if (length($title) > 50) {
2951                                         $title =~ s/(master|www|rsync)\.//;
2952                                 }
2953                                 if (length($title) > 50) {
2954                                         $title =~ s/kernel.org:?//;
2955                                 }
2956                                 if (length($title) > 50) {
2957                                         $title =~ s/\/pub\/scm//;
2958                                 }
2959                         }
2960                         $co{'title_short'} = chop_str($title, 50, 5);
2961                         last;
2962                 }
2963         }
2964         if (! defined $co{'title'} || $co{'title'} eq "") {
2965                 $co{'title'} = $co{'title_short'} = '(no commit message)';
2966         }
2967         # remove added spaces
2968         foreach my $line (@commit_lines) {
2969                 $line =~ s/^    //;
2970         }
2971         $co{'comment'} = \@commit_lines;
2972
2973         my $age = time - $co{'committer_epoch'};
2974         $co{'age'} = $age;
2975         $co{'age_string'} = age_string($age);
2976         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($co{'committer_epoch'});
2977         if ($age > 60*60*24*7*2) {
2978                 $co{'age_string_date'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
2979                 $co{'age_string_age'} = $co{'age_string'};
2980         } else {
2981                 $co{'age_string_date'} = $co{'age_string'};
2982                 $co{'age_string_age'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
2983         }
2984         return %co;
2985 }
2986
2987 sub parse_commit {
2988         my ($commit_id) = @_;
2989         my %co;
2990
2991         local $/ = "\0";
2992
2993         open my $fd, "-|", git_cmd(), "rev-list",
2994                 "--parents",
2995                 "--header",
2996                 "--max-count=1",
2997                 $commit_id,
2998                 "--",
2999                 or die_error(500, "Open git-rev-list failed");
3000         %co = parse_commit_text(<$fd>, 1);
3001         close $fd;
3002
3003         return %co;
3004 }
3005
3006 sub parse_commits {
3007         my ($commit_id, $maxcount, $skip, $filename, @args) = @_;
3008         my @cos;
3009
3010         $maxcount ||= 1;
3011         $skip ||= 0;
3012
3013         local $/ = "\0";
3014
3015         open my $fd, "-|", git_cmd(), "rev-list",
3016                 "--header",
3017                 @args,
3018                 ("--max-count=" . $maxcount),
3019                 ("--skip=" . $skip),
3020                 @extra_options,
3021                 $commit_id,
3022                 "--",
3023                 ($filename ? ($filename) : ())
3024                 or die_error(500, "Open git-rev-list failed");
3025         while (my $line = <$fd>) {
3026                 my %co = parse_commit_text($line);
3027                 push @cos, \%co;
3028         }
3029         close $fd;
3030
3031         return wantarray ? @cos : \@cos;
3032 }
3033
3034 # parse line of git-diff-tree "raw" output
3035 sub parse_difftree_raw_line {
3036         my $line = shift;
3037         my %res;
3038
3039         # ':100644 100644 03b218260e99b78c6df0ed378e59ed9205ccc96d 3b93d5e7cc7f7dd4ebed13a5cc1a4ad976fc94d8 M   ls-files.c'
3040         # ':100644 100644 7f9281985086971d3877aca27704f2aaf9c448ce bc190ebc71bbd923f2b728e505408f5e54bd073a M   rev-tree.c'
3041         if ($line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)([0-9]{0,3})\t(.*)$/) {
3042                 $res{'from_mode'} = $1;
3043                 $res{'to_mode'} = $2;
3044                 $res{'from_id'} = $3;
3045                 $res{'to_id'} = $4;
3046                 $res{'status'} = $5;
3047                 $res{'similarity'} = $6;
3048                 if ($res{'status'} eq 'R' || $res{'status'} eq 'C') { # renamed or copied
3049                         ($res{'from_file'}, $res{'to_file'}) = map { unquote($_) } split("\t", $7);
3050                 } else {
3051                         $res{'from_file'} = $res{'to_file'} = $res{'file'} = unquote($7);
3052                 }
3053         }
3054         # '::100755 100755 100755 60e79ca1b01bc8b057abe17ddab484699a7f5fdb 94067cc5f73388f33722d52ae02f44692bc07490 94067cc5f73388f33722d52ae02f44692bc07490 MR git-gui/git-gui.sh'
3055         # combined diff (for merge commit)
3056         elsif ($line =~ s/^(::+)((?:[0-7]{6} )+)((?:[0-9a-fA-F]{40} )+)([a-zA-Z]+)\t(.*)$//) {
3057                 $res{'nparents'}  = length($1);
3058                 $res{'from_mode'} = [ split(' ', $2) ];
3059                 $res{'to_mode'} = pop @{$res{'from_mode'}};
3060                 $res{'from_id'} = [ split(' ', $3) ];
3061                 $res{'to_id'} = pop @{$res{'from_id'}};
3062                 $res{'status'} = [ split('', $4) ];
3063                 $res{'to_file'} = unquote($5);
3064         }
3065         # 'c512b523472485aef4fff9e57b229d9d243c967f'
3066         elsif ($line =~ m/^([0-9a-fA-F]{40})$/) {
3067                 $res{'commit'} = $1;
3068         }
3069
3070         return wantarray ? %res : \%res;
3071 }
3072
3073 # wrapper: return parsed line of git-diff-tree "raw" output
3074 # (the argument might be raw line, or parsed info)
3075 sub parsed_difftree_line {
3076         my $line_or_ref = shift;
3077
3078         if (ref($line_or_ref) eq "HASH") {
3079                 # pre-parsed (or generated by hand)
3080                 return $line_or_ref;
3081         } else {
3082                 return parse_difftree_raw_line($line_or_ref);
3083         }
3084 }
3085
3086 # parse line of git-ls-tree output
3087 sub parse_ls_tree_line {
3088         my $line = shift;
3089         my %opts = @_;
3090         my %res;
3091
3092         if ($opts{'-l'}) {
3093                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa   16717  panic.c'
3094                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40}) +(-|[0-9]+)\t(.+)$/s;
3095
3096                 $res{'mode'} = $1;
3097                 $res{'type'} = $2;
3098                 $res{'hash'} = $3;
3099                 $res{'size'} = $4;
3100                 if ($opts{'-z'}) {
3101                         $res{'name'} = $5;
3102                 } else {
3103                         $res{'name'} = unquote($5);
3104                 }
3105         } else {
3106                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
3107                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t(.+)$/s;
3108
3109                 $res{'mode'} = $1;
3110                 $res{'type'} = $2;
3111                 $res{'hash'} = $3;
3112                 if ($opts{'-z'}) {
3113                         $res{'name'} = $4;
3114                 } else {
3115                         $res{'name'} = unquote($4);
3116                 }
3117         }
3118
3119         return wantarray ? %res : \%res;
3120 }
3121
3122 # generates _two_ hashes, references to which are passed as 2 and 3 argument
3123 sub parse_from_to_diffinfo {
3124         my ($diffinfo, $from, $to, @parents) = @_;
3125
3126         if ($diffinfo->{'nparents'}) {
3127                 # combined diff
3128                 $from->{'file'} = [];
3129                 $from->{'href'} = [];
3130                 fill_from_file_info($diffinfo, @parents)
3131                         unless exists $diffinfo->{'from_file'};
3132                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
3133                         $from->{'file'}[$i] =
3134                                 defined $diffinfo->{'from_file'}[$i] ?
3135                                         $diffinfo->{'from_file'}[$i] :
3136                                         $diffinfo->{'to_file'};
3137                         if ($diffinfo->{'status'}[$i] ne "A") { # not new (added) file
3138                                 $from->{'href'}[$i] = href(action=>"blob",
3139                                                            hash_base=>$parents[$i],
3140                                                            hash=>$diffinfo->{'from_id'}[$i],
3141                                                            file_name=>$from->{'file'}[$i]);
3142                         } else {
3143                                 $from->{'href'}[$i] = undef;
3144                         }
3145                 }
3146         } else {
3147                 # ordinary (not combined) diff
3148                 $from->{'file'} = $diffinfo->{'from_file'};
3149                 if ($diffinfo->{'status'} ne "A") { # not new (added) file
3150                         $from->{'href'} = href(action=>"blob", hash_base=>$hash_parent,
3151                                                hash=>$diffinfo->{'from_id'},
3152                                                file_name=>$from->{'file'});
3153                 } else {
3154                         delete $from->{'href'};
3155                 }
3156         }
3157
3158         $to->{'file'} = $diffinfo->{'to_file'};
3159         if (!is_deleted($diffinfo)) { # file exists in result
3160                 $to->{'href'} = href(action=>"blob", hash_base=>$hash,
3161                                      hash=>$diffinfo->{'to_id'},
3162                                      file_name=>$to->{'file'});
3163         } else {
3164                 delete $to->{'href'};
3165         }
3166 }
3167
3168 ## ......................................................................
3169 ## parse to array of hashes functions
3170
3171 sub git_get_heads_list {
3172         my ($limit, @classes) = @_;
3173         @classes = ('heads') unless @classes;
3174         my @patterns = map { "refs/$_" } @classes;
3175         my @headslist;
3176
3177         open my $fd, '-|', git_cmd(), 'for-each-ref',
3178                 ($limit ? '--count='.($limit+1) : ()), '--sort=-committerdate',
3179                 '--format=%(objectname) %(refname) %(subject)%00%(committer)',
3180                 @patterns
3181                 or return;
3182         while (my $line = <$fd>) {
3183                 my %ref_item;
3184
3185                 chomp $line;
3186                 my ($refinfo, $committerinfo) = split(/\0/, $line);
3187                 my ($hash, $name, $title) = split(' ', $refinfo, 3);
3188                 my ($committer, $epoch, $tz) =
3189                         ($committerinfo =~ /^(.*) ([0-9]+) (.*)$/);
3190                 $ref_item{'fullname'}  = $name;
3191                 $name =~ s!^refs/(?:head|remote)s/!!;
3192
3193                 $ref_item{'name'}  = $name;
3194                 $ref_item{'id'}    = $hash;
3195                 $ref_item{'title'} = $title || '(no commit message)';
3196                 $ref_item{'epoch'} = $epoch;
3197                 if ($epoch) {
3198                         $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3199                 } else {
3200                         $ref_item{'age'} = "unknown";
3201                 }
3202
3203                 push @headslist, \%ref_item;
3204         }
3205         close $fd;
3206
3207         return wantarray ? @headslist : \@headslist;
3208 }
3209
3210 sub git_get_tags_list {
3211         my $limit = shift;
3212         my @tagslist;
3213
3214         open my $fd, '-|', git_cmd(), 'for-each-ref',
3215                 ($limit ? '--count='.($limit+1) : ()), '--sort=-creatordate',
3216                 '--format=%(objectname) %(objecttype) %(refname) '.
3217                 '%(*objectname) %(*objecttype) %(subject)%00%(creator)',
3218                 'refs/tags'
3219                 or return;
3220         while (my $line = <$fd>) {
3221                 my %ref_item;
3222
3223                 chomp $line;
3224                 my ($refinfo, $creatorinfo) = split(/\0/, $line);
3225                 my ($id, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
3226                 my ($creator, $epoch, $tz) =
3227                         ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
3228                 $ref_item{'fullname'} = $name;
3229                 $name =~ s!^refs/tags/!!;
3230
3231                 $ref_item{'type'} = $type;
3232                 $ref_item{'id'} = $id;
3233                 $ref_item{'name'} = $name;
3234                 if ($type eq "tag") {
3235                         $ref_item{'subject'} = $title;
3236                         $ref_item{'reftype'} = $reftype;
3237                         $ref_item{'refid'}   = $refid;
3238                 } else {
3239                         $ref_item{'reftype'} = $type;
3240                         $ref_item{'refid'}   = $id;
3241                 }
3242
3243                 if ($type eq "tag" || $type eq "commit") {
3244                         $ref_item{'epoch'} = $epoch;
3245                         if ($epoch) {
3246                                 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3247                         } else {
3248                                 $ref_item{'age'} = "unknown";
3249                         }
3250                 }
3251
3252                 push @tagslist, \%ref_item;
3253         }
3254         close $fd;
3255
3256         return wantarray ? @tagslist : \@tagslist;
3257 }
3258
3259 ## ----------------------------------------------------------------------
3260 ## filesystem-related functions
3261
3262 sub get_file_owner {
3263         my $path = shift;
3264
3265         my ($dev, $ino, $mode, $nlink, $st_uid, $st_gid, $rdev, $size) = stat($path);
3266         my ($name, $passwd, $uid, $gid, $quota, $comment, $gcos, $dir, $shell) = getpwuid($st_uid);
3267         if (!defined $gcos) {
3268                 return undef;
3269         }
3270         my $owner = $gcos;
3271         $owner =~ s/[,;].*$//;
3272         return to_utf8($owner);
3273 }
3274
3275 # assume that file exists
3276 sub insert_file {
3277         my $filename = shift;
3278
3279         open my $fd, '<', $filename;
3280         print map { to_utf8($_) } <$fd>;
3281         close $fd;
3282 }
3283
3284 ## ......................................................................
3285 ## mimetype related functions
3286
3287 sub mimetype_guess_file {
3288         my $filename = shift;
3289         my $mimemap = shift;
3290         -r $mimemap or return undef;
3291
3292         my %mimemap;
3293         open(my $mh, '<', $mimemap) or return undef;
3294         while (<$mh>) {
3295                 next if m/^#/; # skip comments
3296                 my ($mimetype, $exts) = split(/\t+/);
3297                 if (defined $exts) {
3298                         my @exts = split(/\s+/, $exts);
3299                         foreach my $ext (@exts) {
3300                                 $mimemap{$ext} = $mimetype;
3301                         }
3302                 }
3303         }
3304         close($mh);
3305
3306         $filename =~ /\.([^.]*)$/;
3307         return $mimemap{$1};
3308 }
3309
3310 sub mimetype_guess {
3311         my $filename = shift;
3312         my $mime;
3313         $filename =~ /\./ or return undef;
3314
3315         if ($mimetypes_file) {
3316                 my $file = $mimetypes_file;
3317                 if ($file !~ m!^/!) { # if it is relative path
3318                         # it is relative to project
3319                         $file = "$projectroot/$project/$file";
3320                 }
3321                 $mime = mimetype_guess_file($filename, $file);
3322         }
3323         $mime ||= mimetype_guess_file($filename, '/etc/mime.types');
3324         return $mime;
3325 }
3326
3327 sub blob_mimetype {
3328         my $fd = shift;
3329         my $filename = shift;
3330
3331         if ($filename) {
3332                 my $mime = mimetype_guess($filename);
3333                 $mime and return $mime;
3334         }
3335
3336         # just in case
3337         return $default_blob_plain_mimetype unless $fd;
3338
3339         if (-T $fd) {
3340                 return 'text/plain';
3341         } elsif (! $filename) {
3342                 return 'application/octet-stream';
3343         } elsif ($filename =~ m/\.png$/i) {
3344                 return 'image/png';
3345         } elsif ($filename =~ m/\.gif$/i) {
3346                 return 'image/gif';
3347         } elsif ($filename =~ m/\.jpe?g$/i) {
3348                 return 'image/jpeg';
3349         } else {
3350                 return 'application/octet-stream';
3351         }
3352 }
3353
3354 sub blob_contenttype {
3355         my ($fd, $file_name, $type) = @_;
3356
3357         $type ||= blob_mimetype($fd, $file_name);
3358         if ($type eq 'text/plain' && defined $default_text_plain_charset) {
3359                 $type .= "; charset=$default_text_plain_charset";
3360         }
3361
3362         return $type;
3363 }
3364
3365 # guess file syntax for syntax highlighting; return undef if no highlighting
3366 # the name of syntax can (in the future) depend on syntax highlighter used
3367 sub guess_file_syntax {
3368         my ($highlight, $mimetype, $file_name) = @_;
3369         return undef unless ($highlight && defined $file_name);
3370         my $basename = basename($file_name, '.in');
3371         return $highlight_basename{$basename}
3372                 if exists $highlight_basename{$basename};
3373
3374         $basename =~ /\.([^.]*)$/;
3375         my $ext = $1 or return undef;
3376         return $highlight_ext{$ext}
3377                 if exists $highlight_ext{$ext};
3378
3379         return undef;
3380 }
3381
3382 # run highlighter and return FD of its output,
3383 # or return original FD if no highlighting
3384 sub run_highlighter {
3385         my ($fd, $highlight, $syntax) = @_;
3386         return $fd unless ($highlight && defined $syntax);
3387
3388         close $fd
3389                 or die_error(404, "Reading blob failed");
3390         open $fd, quote_command(git_cmd(), "cat-file", "blob", $hash)." | ".
3391                   quote_command($highlight_bin).
3392                   " --xhtml --fragment --syntax $syntax |"
3393                 or die_error(500, "Couldn't open file or run syntax highlighter");
3394         return $fd;
3395 }
3396
3397 ## ======================================================================
3398 ## functions printing HTML: header, footer, error page
3399
3400 sub get_page_title {
3401         my $title = to_utf8($site_name);
3402
3403         return $title unless (defined $project);
3404         $title .= " - " . to_utf8($project);
3405
3406         return $title unless (defined $action);
3407         $title .= "/$action"; # $action is US-ASCII (7bit ASCII)
3408
3409         return $title unless (defined $file_name);
3410         $title .= " - " . esc_path($file_name);
3411         if ($action eq "tree" && $file_name !~ m|/$|) {
3412                 $title .= "/";
3413         }
3414
3415         return $title;
3416 }
3417
3418 sub git_header_html {
3419         my $status = shift || "200 OK";
3420         my $expires = shift;
3421         my %opts = @_;
3422
3423         my $title = get_page_title();
3424         my $content_type;
3425         # require explicit support from the UA if we are to send the page as
3426         # 'application/xhtml+xml', otherwise send it as plain old 'text/html'.
3427         # we have to do this because MSIE sometimes globs '*/*', pretending to
3428         # support xhtml+xml but choking when it gets what it asked for.
3429         if (defined $cgi->http('HTTP_ACCEPT') &&
3430             $cgi->http('HTTP_ACCEPT') =~ m/(,|;|\s|^)application\/xhtml\+xml(,|;|\s|$)/ &&
3431             $cgi->Accept('application/xhtml+xml') != 0) {
3432                 $content_type = 'application/xhtml+xml';
3433         } else {
3434                 $content_type = 'text/html';
3435         }
3436         print $cgi->header(-type=>$content_type, -charset => 'utf-8',
3437                            -status=> $status, -expires => $expires)
3438                 unless ($opts{'-no_http_header'});
3439         my $mod_perl_version = $ENV{'MOD_PERL'} ? " $ENV{'MOD_PERL'}" : '';
3440         print <<EOF;
3441 <?xml version="1.0" encoding="utf-8"?>
3442 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
3443 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en-US" lang="en-US">
3444 <!-- git web interface version $version, (C) 2005-2006, Kay Sievers <kay.sievers\@vrfy.org>, Christian Gierke -->
3445 <!-- git core binaries version $git_version -->
3446 <head>
3447 <meta http-equiv="content-type" content="$content_type; charset=utf-8"/>
3448 <meta name="generator" content="gitweb/$version git/$git_version$mod_perl_version"/>
3449 <meta name="robots" content="index, nofollow"/>
3450 <title>$title</title>
3451 EOF
3452         # the stylesheet, favicon etc urls won't work correctly with path_info
3453         # unless we set the appropriate base URL
3454         if ($ENV{'PATH_INFO'}) {
3455                 print "<base href=\"".esc_url($base_url)."\" />\n";
3456         }
3457         # print out each stylesheet that exist, providing backwards capability
3458         # for those people who defined $stylesheet in a config file
3459         if (defined $stylesheet) {
3460                 print '<link rel="stylesheet" type="text/css" href="'.$stylesheet.'"/>'."\n";
3461         } else {
3462                 foreach my $stylesheet (@stylesheets) {
3463                         next unless $stylesheet;
3464                         print '<link rel="stylesheet" type="text/css" href="'.$stylesheet.'"/>'."\n";
3465                 }
3466         }
3467         if (defined $project) {
3468                 my %href_params = get_feed_info();
3469                 if (!exists $href_params{'-title'}) {
3470                         $href_params{'-title'} = 'log';
3471                 }
3472
3473                 foreach my $format qw(RSS Atom) {
3474                         my $type = lc($format);
3475                         my %link_attr = (
3476                                 '-rel' => 'alternate',
3477                                 '-title' => "$project - $href_params{'-title'} - $format feed",
3478                                 '-type' => "application/$type+xml"
3479                         );
3480
3481                         $href_params{'action'} = $type;
3482                         $link_attr{'-href'} = href(%href_params);
3483                         print "<link ".
3484                               "rel=\"$link_attr{'-rel'}\" ".
3485                               "title=\"$link_attr{'-title'}\" ".
3486                               "href=\"$link_attr{'-href'}\" ".
3487                               "type=\"$link_attr{'-type'}\" ".
3488                               "/>\n";
3489
3490                         $href_params{'extra_options'} = '--no-merges';
3491                         $link_attr{'-href'} = href(%href_params);
3492                         $link_attr{'-title'} .= ' (no merges)';
3493                         print "<link ".
3494                               "rel=\"$link_attr{'-rel'}\" ".
3495                               "title=\"$link_attr{'-title'}\" ".
3496                               "href=\"$link_attr{'-href'}\" ".
3497                               "type=\"$link_attr{'-type'}\" ".
3498                               "/>\n";
3499                 }
3500
3501         } else {
3502                 printf('<link rel="alternate" title="%s projects list" '.
3503                        'href="%s" type="text/plain; charset=utf-8" />'."\n",
3504                        $site_name, href(project=>undef, action=>"project_index"));
3505                 printf('<link rel="alternate" title="%s projects feeds" '.
3506                        'href="%s" type="text/x-opml" />'."\n",
3507                        $site_name, href(project=>undef, action=>"opml"));
3508         }
3509         if (defined $favicon) {
3510                 print qq(<link rel="shortcut icon" href="$favicon" type="image/png" />\n);
3511         }
3512
3513         print "</head>\n" .
3514               "<body>\n";
3515
3516         if (defined $site_header && -f $site_header) {
3517                 insert_file($site_header);
3518         }
3519
3520         print "<div class=\"page_header\">\n" .
3521               $cgi->a({-href => esc_url($logo_url),
3522                        -title => $logo_label},
3523                       qq(<img src="$logo" width="72" height="27" alt="git" class="logo"/>));
3524         print $cgi->a({-href => esc_url($home_link)}, $home_link_str) . " / ";
3525         if (defined $project) {
3526                 print $cgi->a({-href => href(action=>"summary")}, esc_html($project));
3527                 if (defined $action) {
3528                         print " / $action";
3529                 }
3530                 print "\n";
3531         }
3532         print "</div>\n";
3533
3534         my $have_search = gitweb_check_feature('search');
3535         if (defined $project && $have_search) {
3536                 if (!defined $searchtext) {
3537                         $searchtext = "";
3538                 }
3539                 my $search_hash;
3540                 if (defined $hash_base) {
3541                         $search_hash = $hash_base;
3542                 } elsif (defined $hash) {
3543                         $search_hash = $hash;
3544                 } else {
3545                         $search_hash = "HEAD";
3546                 }
3547                 my $action = $my_uri;
3548                 my $use_pathinfo = gitweb_check_feature('pathinfo');
3549                 if ($use_pathinfo) {
3550                         $action .= "/".esc_url($project);
3551                 }
3552                 print $cgi->startform(-method => "get", -action => $action) .
3553                       "<div class=\"search\">\n" .
3554                       (!$use_pathinfo &&
3555                       $cgi->input({-name=>"p", -value=>$project, -type=>"hidden"}) . "\n") .
3556                       $cgi->input({-name=>"a", -value=>"search", -type=>"hidden"}) . "\n" .
3557                       $cgi->input({-name=>"h", -value=>$search_hash, -type=>"hidden"}) . "\n" .
3558                       $cgi->popup_menu(-name => 'st', -default => 'commit',
3559                                        -values => ['commit', 'grep', 'author', 'committer', 'pickaxe']) .
3560                       $cgi->sup($cgi->a({-href => href(action=>"search_help")}, "?")) .
3561                       " search:\n",
3562                       $cgi->textfield(-name => "s", -value => $searchtext) . "\n" .
3563                       "<span title=\"Extended regular expression\">" .
3564                       $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
3565                                      -checked => $search_use_regexp) .
3566                       "</span>" .
3567                       "</div>" .
3568                       $cgi->end_form() . "\n";
3569         }
3570 }
3571
3572 sub git_footer_html {
3573         my $feed_class = 'rss_logo';
3574
3575         print "<div class=\"page_footer\">\n";
3576         if (defined $project) {
3577                 my $descr = git_get_project_description($project);
3578                 if (defined $descr) {
3579                         print "<div class=\"page_footer_text\">" . esc_html($descr) . "</div>\n";
3580                 }
3581
3582                 my %href_params = get_feed_info();
3583                 if (!%href_params) {
3584                         $feed_class .= ' generic';
3585                 }
3586                 $href_params{'-title'} ||= 'log';
3587
3588                 foreach my $format qw(RSS Atom) {
3589                         $href_params{'action'} = lc($format);
3590                         print $cgi->a({-href => href(%href_params),
3591                                       -title => "$href_params{'-title'} $format feed",
3592                                       -class => $feed_class}, $format)."\n";
3593                 }
3594
3595         } else {
3596                 print $cgi->a({-href => href(project=>undef, action=>"opml"),
3597                               -class => $feed_class}, "OPML") . " ";
3598                 print $cgi->a({-href => href(project=>undef, action=>"project_index"),
3599                               -class => $feed_class}, "TXT") . "\n";
3600         }
3601         print "</div>\n"; # class="page_footer"
3602
3603         if (defined $t0 && gitweb_check_feature('timed')) {
3604                 print "<div id=\"generating_info\">\n";
3605                 print 'This page took '.
3606                       '<span id="generating_time" class="time_span">'.
3607                       tv_interval($t0, [ gettimeofday() ]).
3608                       ' seconds </span>'.
3609                       ' and '.
3610                       '<span id="generating_cmd">'.
3611                       $number_of_git_cmds.
3612                       '</span> git commands '.
3613                       " to generate.\n";
3614                 print "</div>\n"; # class="page_footer"
3615         }
3616
3617         if (defined $site_footer && -f $site_footer) {
3618                 insert_file($site_footer);
3619         }
3620
3621         print qq!<script type="text/javascript" src="$javascript"></script>\n!;
3622         if (defined $action &&
3623             $action eq 'blame_incremental') {
3624                 print qq!<script type="text/javascript">\n!.
3625                       qq!startBlame("!. href(action=>"blame_data", -replay=>1) .qq!",\n!.
3626                       qq!           "!. href() .qq!");\n!.
3627                       qq!</script>\n!;
3628         } elsif (gitweb_check_feature('javascript-actions')) {
3629                 print qq!<script type="text/javascript">\n!.
3630                       qq!window.onload = fixLinks;\n!.
3631                       qq!</script>\n!;
3632         }
3633
3634         print "</body>\n" .
3635               "</html>";
3636 }
3637
3638 # die_error(<http_status_code>, <error_message>[, <detailed_html_description>])
3639 # Example: die_error(404, 'Hash not found')
3640 # By convention, use the following status codes (as defined in RFC 2616):
3641 # 400: Invalid or missing CGI parameters, or
3642 #      requested object exists but has wrong type.
3643 # 403: Requested feature (like "pickaxe" or "snapshot") not enabled on
3644 #      this server or project.
3645 # 404: Requested object/revision/project doesn't exist.
3646 # 500: The server isn't configured properly, or
3647 #      an internal error occurred (e.g. failed assertions caused by bugs), or
3648 #      an unknown error occurred (e.g. the git binary died unexpectedly).
3649 # 503: The server is currently unavailable (because it is overloaded,
3650 #      or down for maintenance).  Generally, this is a temporary state.
3651 sub die_error {
3652         my $status = shift || 500;
3653         my $error = esc_html(shift) || "Internal Server Error";
3654         my $extra = shift;
3655         my %opts = @_;
3656
3657         my %http_responses = (
3658                 400 => '400 Bad Request',
3659                 403 => '403 Forbidden',
3660                 404 => '404 Not Found',
3661                 500 => '500 Internal Server Error',
3662                 503 => '503 Service Unavailable',
3663         );
3664         git_header_html($http_responses{$status}, undef, %opts);
3665         print <<EOF;
3666 <div class="page_body">
3667 <br /><br />
3668 $status - $error
3669 <br />
3670 EOF
3671         if (defined $extra) {
3672                 print "<hr />\n" .
3673                       "$extra\n";
3674         }
3675         print "</div>\n";
3676
3677         git_footer_html();
3678         goto DONE_GITWEB
3679                 unless ($opts{'-error_handler'});
3680 }
3681
3682 ## ----------------------------------------------------------------------
3683 ## functions printing or outputting HTML: navigation
3684
3685 sub git_print_page_nav {
3686         my ($current, $suppress, $head, $treehead, $treebase, $extra) = @_;
3687         $extra = '' if !defined $extra; # pager or formats
3688
3689         my @navs = qw(summary shortlog log commit commitdiff tree);
3690         if ($suppress) {
3691                 @navs = grep { $_ ne $suppress } @navs;
3692         }
3693
3694         my %arg = map { $_ => {action=>$_} } @navs;
3695         if (defined $head) {
3696                 for (qw(commit commitdiff)) {
3697                         $arg{$_}{'hash'} = $head;
3698                 }
3699                 if ($current =~ m/^(tree | log | shortlog | commit | commitdiff | search)$/x) {
3700                         for (qw(shortlog log)) {
3701                                 $arg{$_}{'hash'} = $head;
3702                         }
3703                 }
3704         }
3705
3706         $arg{'tree'}{'hash'} = $treehead if defined $treehead;
3707         $arg{'tree'}{'hash_base'} = $treebase if defined $treebase;
3708
3709         my @actions = gitweb_get_feature('actions');
3710         my %repl = (
3711                 '%' => '%',
3712                 'n' => $project,         # project name
3713                 'f' => $git_dir,         # project path within filesystem
3714                 'h' => $treehead || '',  # current hash ('h' parameter)
3715                 'b' => $treebase || '',  # hash base ('hb' parameter)
3716         );
3717         while (@actions) {
3718                 my ($label, $link, $pos) = splice(@actions,0,3);
3719                 # insert
3720                 @navs = map { $_ eq $pos ? ($_, $label) : $_ } @navs;
3721                 # munch munch
3722                 $link =~ s/%([%nfhb])/$repl{$1}/g;
3723                 $arg{$label}{'_href'} = $link;
3724         }
3725
3726         print "<div class=\"page_nav\">\n" .
3727                 (join " | ",
3728                  map { $_ eq $current ?
3729                        $_ : $cgi->a({-href => ($arg{$_}{_href} ? $arg{$_}{_href} : href(%{$arg{$_}}))}, "$_")
3730                  } @navs);
3731         print "<br/>\n$extra<br/>\n" .
3732               "</div>\n";
3733 }
3734
3735 sub format_paging_nav {
3736         my ($action, $page, $has_next_link) = @_;
3737         my $paging_nav;
3738
3739
3740         if ($page > 0) {
3741                 $paging_nav .=
3742                         $cgi->a({-href => href(-replay=>1, page=>undef)}, "first") .
3743                         " &sdot; " .
3744                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
3745                                  -accesskey => "p", -title => "Alt-p"}, "prev");
3746         } else {
3747                 $paging_nav .= "first &sdot; prev";
3748         }
3749
3750         if ($has_next_link) {
3751                 $paging_nav .= " &sdot; " .
3752                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
3753                                  -accesskey => "n", -title => "Alt-n"}, "next");
3754         } else {
3755                 $paging_nav .= " &sdot; next";
3756         }
3757
3758         return $paging_nav;
3759 }
3760
3761 ## ......................................................................
3762 ## functions printing or outputting HTML: div
3763
3764 sub git_print_header_div {
3765         my ($action, $title, $hash, $hash_base) = @_;
3766         my %args = ();
3767
3768         $args{'action'} = $action;
3769         $args{'hash'} = $hash if $hash;
3770         $args{'hash_base'} = $hash_base if $hash_base;
3771
3772         print "<div class=\"header\">\n" .
3773               $cgi->a({-href => href(%args), -class => "title"},
3774               $title ? $title : $action) .
3775               "\n</div>\n";
3776 }
3777
3778 sub print_local_time {
3779         print format_local_time(@_);
3780 }
3781
3782 sub format_local_time {
3783         my $localtime = '';
3784         my %date = @_;
3785         if ($date{'hour_local'} < 6) {
3786                 $localtime .= sprintf(" (<span class=\"atnight\">%02d:%02d</span> %s)",
3787                         $date{'hour_local'}, $date{'minute_local'}, $date{'tz_local'});
3788         } else {
3789                 $localtime .= sprintf(" (%02d:%02d %s)",
3790                         $date{'hour_local'}, $date{'minute_local'}, $date{'tz_local'});
3791         }
3792
3793         return $localtime;
3794 }
3795
3796 # Outputs the author name and date in long form
3797 sub git_print_authorship {
3798         my $co = shift;
3799         my %opts = @_;
3800         my $tag = $opts{-tag} || 'div';
3801         my $author = $co->{'author_name'};
3802
3803         my %ad = parse_date($co->{'author_epoch'}, $co->{'author_tz'});
3804         print "<$tag class=\"author_date\">" .
3805               format_search_author($author, "author", esc_html($author)) .
3806               " [$ad{'rfc2822'}";
3807         print_local_time(%ad) if ($opts{-localtime});
3808         print "]" . git_get_avatar($co->{'author_email'}, -pad_before => 1)
3809                   . "</$tag>\n";
3810 }
3811
3812 # Outputs table rows containing the full author or committer information,
3813 # in the format expected for 'commit' view (& similar).
3814 # Parameters are a commit hash reference, followed by the list of people
3815 # to output information for. If the list is empty it defaults to both
3816 # author and committer.
3817 sub git_print_authorship_rows {
3818         my $co = shift;
3819         # too bad we can't use @people = @_ || ('author', 'committer')
3820         my @people = @_;
3821         @people = ('author', 'committer') unless @people;
3822         foreach my $who (@people) {
3823                 my %wd = parse_date($co->{"${who}_epoch"}, $co->{"${who}_tz"});
3824                 print "<tr><td>$who</td><td>" .
3825                       format_search_author($co->{"${who}_name"}, $who,
3826                                esc_html($co->{"${who}_name"})) . " " .
3827                       format_search_author($co->{"${who}_email"}, $who,
3828                                esc_html("<" . $co->{"${who}_email"} . ">")) .
3829                       "</td><td rowspan=\"2\">" .
3830                       git_get_avatar($co->{"${who}_email"}, -size => 'double') .
3831                       "</td></tr>\n" .
3832                       "<tr>" .
3833                       "<td></td><td> $wd{'rfc2822'}";
3834                 print_local_time(%wd);
3835                 print "</td>" .
3836                       "</tr>\n";
3837         }
3838 }
3839
3840 sub git_print_page_path {
3841         my $name = shift;
3842         my $type = shift;
3843         my $hb = shift;
3844
3845
3846         print "<div class=\"page_path\">";
3847         print $cgi->a({-href => href(action=>"tree", hash_base=>$hb),
3848                       -title => 'tree root'}, to_utf8("[$project]"));
3849         print " / ";
3850         if (defined $name) {
3851                 my @dirname = split '/', $name;
3852                 my $basename = pop @dirname;
3853                 my $fullname = '';
3854
3855                 foreach my $dir (@dirname) {
3856                         $fullname .= ($fullname ? '/' : '') . $dir;
3857                         print $cgi->a({-href => href(action=>"tree", file_name=>$fullname,
3858                                                      hash_base=>$hb),
3859                                       -title => $fullname}, esc_path($dir));
3860                         print " / ";
3861                 }
3862                 if (defined $type && $type eq 'blob') {
3863                         print $cgi->a({-href => href(action=>"blob_plain", file_name=>$file_name,
3864                                                      hash_base=>$hb),
3865                                       -title => $name}, esc_path($basename));
3866                 } elsif (defined $type && $type eq 'tree') {
3867                         print $cgi->a({-href => href(action=>"tree", file_name=>$file_name,
3868                                                      hash_base=>$hb),
3869                                       -title => $name}, esc_path($basename));
3870                         print " / ";
3871                 } else {
3872                         print esc_path($basename);
3873                 }
3874         }
3875         print "<br/></div>\n";
3876 }
3877
3878 sub git_print_log {
3879         my $log = shift;
3880         my %opts = @_;
3881
3882         if ($opts{'-remove_title'}) {
3883                 # remove title, i.e. first line of log
3884                 shift @$log;
3885         }
3886         # remove leading empty lines
3887         while (defined $log->[0] && $log->[0] eq "") {
3888                 shift @$log;
3889         }
3890
3891         # print log
3892         my $signoff = 0;
3893         my $empty = 0;
3894         foreach my $line (@$log) {
3895                 if ($line =~ m/^ *(signed[ \-]off[ \-]by[ :]|acked[ \-]by[ :]|cc[ :])/i) {
3896                         $signoff = 1;
3897                         $empty = 0;
3898                         if (! $opts{'-remove_signoff'}) {
3899                                 print "<span class=\"signoff\">" . esc_html($line) . "</span><br/>\n";
3900                                 next;
3901                         } else {
3902                                 # remove signoff lines
3903                                 next;
3904                         }
3905                 } else {
3906                         $signoff = 0;
3907                 }
3908
3909                 # print only one empty line
3910                 # do not print empty line after signoff
3911                 if ($line eq "") {
3912                         next if ($empty || $signoff);
3913                         $empty = 1;
3914                 } else {
3915                         $empty = 0;
3916                 }
3917
3918                 print format_log_line_html($line) . "<br/>\n";
3919         }
3920
3921         if ($opts{'-final_empty_line'}) {
3922                 # end with single empty line
3923                 print "<br/>\n" unless $empty;
3924         }
3925 }
3926
3927 # return link target (what link points to)
3928 sub git_get_link_target {
3929         my $hash = shift;
3930         my $link_target;
3931
3932         # read link
3933         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
3934                 or return;
3935         {
3936                 local $/ = undef;
3937                 $link_target = <$fd>;
3938         }
3939         close $fd
3940                 or return;
3941
3942         return $link_target;
3943 }
3944
3945 # given link target, and the directory (basedir) the link is in,
3946 # return target of link relative to top directory (top tree);
3947 # return undef if it is not possible (including absolute links).
3948 sub normalize_link_target {
3949         my ($link_target, $basedir) = @_;
3950
3951         # absolute symlinks (beginning with '/') cannot be normalized
3952         return if (substr($link_target, 0, 1) eq '/');
3953
3954         # normalize link target to path from top (root) tree (dir)
3955         my $path;
3956         if ($basedir) {
3957                 $path = $basedir . '/' . $link_target;
3958         } else {
3959                 # we are in top (root) tree (dir)
3960                 $path = $link_target;
3961         }
3962
3963         # remove //, /./, and /../
3964         my @path_parts;
3965         foreach my $part (split('/', $path)) {
3966                 # discard '.' and ''
3967                 next if (!$part || $part eq '.');
3968                 # handle '..'
3969                 if ($part eq '..') {
3970                         if (@path_parts) {
3971                                 pop @path_parts;
3972                         } else {
3973                                 # link leads outside repository (outside top dir)
3974                                 return;
3975                         }
3976                 } else {
3977                         push @path_parts, $part;
3978                 }
3979         }
3980         $path = join('/', @path_parts);
3981
3982         return $path;
3983 }
3984
3985 # print tree entry (row of git_tree), but without encompassing <tr> element
3986 sub git_print_tree_entry {
3987         my ($t, $basedir, $hash_base, $have_blame) = @_;
3988
3989         my %base_key = ();
3990         $base_key{'hash_base'} = $hash_base if defined $hash_base;
3991
3992         # The format of a table row is: mode list link.  Where mode is
3993         # the mode of the entry, list is the name of the entry, an href,
3994         # and link is the action links of the entry.
3995
3996         print "<td class=\"mode\">" . mode_str($t->{'mode'}) . "</td>\n";
3997         if (exists $t->{'size'}) {
3998                 print "<td class=\"size\">$t->{'size'}</td>\n";
3999         }
4000         if ($t->{'type'} eq "blob") {
4001                 print "<td class=\"list\">" .
4002                         $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4003                                                file_name=>"$basedir$t->{'name'}", %base_key),
4004                                 -class => "list"}, esc_path($t->{'name'}));
4005                 if (S_ISLNK(oct $t->{'mode'})) {
4006                         my $link_target = git_get_link_target($t->{'hash'});
4007                         if ($link_target) {
4008                                 my $norm_target = normalize_link_target($link_target, $basedir);
4009                                 if (defined $norm_target) {
4010                                         print " -> " .
4011                                               $cgi->a({-href => href(action=>"object", hash_base=>$hash_base,
4012                                                                      file_name=>$norm_target),
4013                                                        -title => $norm_target}, esc_path($link_target));
4014                                 } else {
4015                                         print " -> " . esc_path($link_target);
4016                                 }
4017                         }
4018                 }
4019                 print "</td>\n";
4020                 print "<td class=\"link\">";
4021                 print $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4022                                              file_name=>"$basedir$t->{'name'}", %base_key)},
4023                               "blob");
4024                 if ($have_blame) {
4025                         print " | " .
4026                               $cgi->a({-href => href(action=>"blame", hash=>$t->{'hash'},
4027                                                      file_name=>"$basedir$t->{'name'}", %base_key)},
4028                                       "blame");
4029                 }
4030                 if (defined $hash_base) {
4031                         print " | " .
4032                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4033                                                      hash=>$t->{'hash'}, file_name=>"$basedir$t->{'name'}")},
4034                                       "history");
4035                 }
4036                 print " | " .
4037                         $cgi->a({-href => href(action=>"blob_plain", hash_base=>$hash_base,
4038                                                file_name=>"$basedir$t->{'name'}")},
4039                                 "raw");
4040                 print "</td>\n";
4041
4042         } elsif ($t->{'type'} eq "tree") {
4043                 print "<td class=\"list\">";
4044                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4045                                              file_name=>"$basedir$t->{'name'}",
4046                                              %base_key)},
4047                               esc_path($t->{'name'}));
4048                 print "</td>\n";
4049                 print "<td class=\"link\">";
4050                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4051                                              file_name=>"$basedir$t->{'name'}",
4052                                              %base_key)},
4053                               "tree");
4054                 if (defined $hash_base) {
4055                         print " | " .
4056                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4057                                                      file_name=>"$basedir$t->{'name'}")},
4058                                       "history");
4059                 }
4060                 print "</td>\n";
4061         } else {
4062                 # unknown object: we can only present history for it
4063                 # (this includes 'commit' object, i.e. submodule support)
4064                 print "<td class=\"list\">" .
4065                       esc_path($t->{'name'}) .
4066                       "</td>\n";
4067                 print "<td class=\"link\">";
4068                 if (defined $hash_base) {
4069                         print $cgi->a({-href => href(action=>"history",
4070                                                      hash_base=>$hash_base,
4071                                                      file_name=>"$basedir$t->{'name'}")},
4072                                       "history");
4073                 }
4074                 print "</td>\n";
4075         }
4076 }
4077
4078 ## ......................................................................
4079 ## functions printing large fragments of HTML
4080
4081 # get pre-image filenames for merge (combined) diff
4082 sub fill_from_file_info {
4083         my ($diff, @parents) = @_;
4084
4085         $diff->{'from_file'} = [ ];
4086         $diff->{'from_file'}[$diff->{'nparents'} - 1] = undef;
4087         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4088                 if ($diff->{'status'}[$i] eq 'R' ||
4089                     $diff->{'status'}[$i] eq 'C') {
4090                         $diff->{'from_file'}[$i] =
4091                                 git_get_path_by_hash($parents[$i], $diff->{'from_id'}[$i]);
4092                 }
4093         }
4094
4095         return $diff;
4096 }
4097
4098 # is current raw difftree line of file deletion
4099 sub is_deleted {
4100         my $diffinfo = shift;
4101
4102         return $diffinfo->{'to_id'} eq ('0' x 40);
4103 }
4104
4105 # does patch correspond to [previous] difftree raw line
4106 # $diffinfo  - hashref of parsed raw diff format
4107 # $patchinfo - hashref of parsed patch diff format
4108 #              (the same keys as in $diffinfo)
4109 sub is_patch_split {
4110         my ($diffinfo, $patchinfo) = @_;
4111
4112         return defined $diffinfo && defined $patchinfo
4113                 && $diffinfo->{'to_file'} eq $patchinfo->{'to_file'};
4114 }
4115
4116
4117 sub git_difftree_body {
4118         my ($difftree, $hash, @parents) = @_;
4119         my ($parent) = $parents[0];
4120         my $have_blame = gitweb_check_feature('blame');
4121         print "<div class=\"list_head\">\n";
4122         if ($#{$difftree} > 10) {
4123                 print(($#{$difftree} + 1) . " files changed:\n");
4124         }
4125         print "</div>\n";
4126
4127         print "<table class=\"" .
4128               (@parents > 1 ? "combined " : "") .
4129               "diff_tree\">\n";
4130
4131         # header only for combined diff in 'commitdiff' view
4132         my $has_header = @$difftree && @parents > 1 && $action eq 'commitdiff';
4133         if ($has_header) {
4134                 # table header
4135                 print "<thead><tr>\n" .
4136                        "<th></th><th></th>\n"; # filename, patchN link
4137                 for (my $i = 0; $i < @parents; $i++) {
4138                         my $par = $parents[$i];
4139                         print "<th>" .
4140                               $cgi->a({-href => href(action=>"commitdiff",
4141                                                      hash=>$hash, hash_parent=>$par),
4142                                        -title => 'commitdiff to parent number ' .
4143                                                   ($i+1) . ': ' . substr($par,0,7)},
4144                                       $i+1) .
4145                               "&nbsp;</th>\n";
4146                 }
4147                 print "</tr></thead>\n<tbody>\n";
4148         }
4149
4150         my $alternate = 1;
4151         my $patchno = 0;
4152         foreach my $line (@{$difftree}) {
4153                 my $diff = parsed_difftree_line($line);
4154
4155                 if ($alternate) {
4156                         print "<tr class=\"dark\">\n";
4157                 } else {
4158                         print "<tr class=\"light\">\n";
4159                 }
4160                 $alternate ^= 1;
4161
4162                 if (exists $diff->{'nparents'}) { # combined diff
4163
4164                         fill_from_file_info($diff, @parents)
4165                                 unless exists $diff->{'from_file'};
4166
4167                         if (!is_deleted($diff)) {
4168                                 # file exists in the result (child) commit
4169                                 print "<td>" .
4170                                       $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4171                                                              file_name=>$diff->{'to_file'},
4172                                                              hash_base=>$hash),
4173                                               -class => "list"}, esc_path($diff->{'to_file'})) .
4174                                       "</td>\n";
4175                         } else {
4176                                 print "<td>" .
4177                                       esc_path($diff->{'to_file'}) .
4178                                       "</td>\n";
4179                         }
4180
4181                         if ($action eq 'commitdiff') {
4182                                 # link to patch
4183                                 $patchno++;
4184                                 print "<td class=\"link\">" .
4185                                       $cgi->a({-href => "#patch$patchno"}, "patch") .
4186                                       " | " .
4187                                       "</td>\n";
4188                         }
4189
4190                         my $has_history = 0;
4191                         my $not_deleted = 0;
4192                         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4193                                 my $hash_parent = $parents[$i];
4194                                 my $from_hash = $diff->{'from_id'}[$i];
4195                                 my $from_path = $diff->{'from_file'}[$i];
4196                                 my $status = $diff->{'status'}[$i];
4197
4198                                 $has_history ||= ($status ne 'A');
4199                                 $not_deleted ||= ($status ne 'D');
4200
4201                                 if ($status eq 'A') {
4202                                         print "<td  class=\"link\" align=\"right\"> | </td>\n";
4203                                 } elsif ($status eq 'D') {
4204                                         print "<td class=\"link\">" .
4205                                               $cgi->a({-href => href(action=>"blob",
4206                                                                      hash_base=>$hash,
4207                                                                      hash=>$from_hash,
4208                                                                      file_name=>$from_path)},
4209                                                       "blob" . ($i+1)) .
4210                                               " | </td>\n";
4211                                 } else {
4212                                         if ($diff->{'to_id'} eq $from_hash) {
4213                                                 print "<td class=\"link nochange\">";
4214                                         } else {
4215                                                 print "<td class=\"link\">";
4216                                         }
4217                                         print $cgi->a({-href => href(action=>"blobdiff",
4218                                                                      hash=>$diff->{'to_id'},
4219                                                                      hash_parent=>$from_hash,
4220                                                                      hash_base=>$hash,
4221                                                                      hash_parent_base=>$hash_parent,
4222                                                                      file_name=>$diff->{'to_file'},
4223                                                                      file_parent=>$from_path)},
4224                                                       "diff" . ($i+1)) .
4225                                               " | </td>\n";
4226                                 }
4227                         }
4228
4229                         print "<td class=\"link\">";
4230                         if ($not_deleted) {
4231                                 print $cgi->a({-href => href(action=>"blob",
4232                                                              hash=>$diff->{'to_id'},
4233                                                              file_name=>$diff->{'to_file'},
4234                                                              hash_base=>$hash)},
4235                                               "blob");
4236                                 print " | " if ($has_history);
4237                         }
4238                         if ($has_history) {
4239                                 print $cgi->a({-href => href(action=>"history",
4240                                                              file_name=>$diff->{'to_file'},
4241                                                              hash_base=>$hash)},
4242                                               "history");
4243                         }
4244                         print "</td>\n";
4245
4246                         print "</tr>\n";
4247                         next; # instead of 'else' clause, to avoid extra indent
4248                 }
4249                 # else ordinary diff
4250
4251                 my ($to_mode_oct, $to_mode_str, $to_file_type);
4252                 my ($from_mode_oct, $from_mode_str, $from_file_type);
4253                 if ($diff->{'to_mode'} ne ('0' x 6)) {
4254                         $to_mode_oct = oct $diff->{'to_mode'};
4255                         if (S_ISREG($to_mode_oct)) { # only for regular file
4256                                 $to_mode_str = sprintf("%04o", $to_mode_oct & 0777); # permission bits
4257                         }
4258                         $to_file_type = file_type($diff->{'to_mode'});
4259                 }
4260                 if ($diff->{'from_mode'} ne ('0' x 6)) {
4261                         $from_mode_oct = oct $diff->{'from_mode'};
4262                         if (S_ISREG($to_mode_oct)) { # only for regular file
4263                                 $from_mode_str = sprintf("%04o", $from_mode_oct & 0777); # permission bits
4264                         }
4265                         $from_file_type = file_type($diff->{'from_mode'});
4266                 }
4267
4268                 if ($diff->{'status'} eq "A") { # created
4269                         my $mode_chng = "<span class=\"file_status new\">[new $to_file_type";
4270                         $mode_chng   .= " with mode: $to_mode_str" if $to_mode_str;
4271                         $mode_chng   .= "]</span>";
4272                         print "<td>";
4273                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4274                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4275                                       -class => "list"}, esc_path($diff->{'file'}));
4276                         print "</td>\n";
4277                         print "<td>$mode_chng</td>\n";
4278                         print "<td class=\"link\">";
4279                         if ($action eq 'commitdiff') {
4280                                 # link to patch
4281                                 $patchno++;
4282                                 print $cgi->a({-href => "#patch$patchno"}, "patch");
4283                                 print " | ";
4284                         }
4285                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4286                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4287                                       "blob");
4288                         print "</td>\n";
4289
4290                 } elsif ($diff->{'status'} eq "D") { # deleted
4291                         my $mode_chng = "<span class=\"file_status deleted\">[deleted $from_file_type]</span>";
4292                         print "<td>";
4293                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4294                                                      hash_base=>$parent, file_name=>$diff->{'file'}),
4295                                        -class => "list"}, esc_path($diff->{'file'}));
4296                         print "</td>\n";
4297                         print "<td>$mode_chng</td>\n";
4298                         print "<td class=\"link\">";
4299                         if ($action eq 'commitdiff') {
4300                                 # link to patch
4301                                 $patchno++;
4302                                 print $cgi->a({-href => "#patch$patchno"}, "patch");
4303                                 print " | ";
4304                         }
4305                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4306                                                      hash_base=>$parent, file_name=>$diff->{'file'})},
4307                                       "blob") . " | ";
4308                         if ($have_blame) {
4309                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$parent,
4310                                                              file_name=>$diff->{'file'})},
4311                                               "blame") . " | ";
4312                         }
4313                         print $cgi->a({-href => href(action=>"history", hash_base=>$parent,
4314                                                      file_name=>$diff->{'file'})},
4315                                       "history");
4316                         print "</td>\n";
4317
4318                 } elsif ($diff->{'status'} eq "M" || $diff->{'status'} eq "T") { # modified, or type changed
4319                         my $mode_chnge = "";
4320                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4321                                 $mode_chnge = "<span class=\"file_status mode_chnge\">[changed";
4322                                 if ($from_file_type ne $to_file_type) {
4323                                         $mode_chnge .= " from $from_file_type to $to_file_type";
4324                                 }
4325                                 if (($from_mode_oct & 0777) != ($to_mode_oct & 0777)) {
4326                                         if ($from_mode_str && $to_mode_str) {
4327                                                 $mode_chnge .= " mode: $from_mode_str->$to_mode_str";
4328                                         } elsif ($to_mode_str) {
4329                                                 $mode_chnge .= " mode: $to_mode_str";
4330                                         }
4331                                 }
4332                                 $mode_chnge .= "]</span>\n";
4333                         }
4334                         print "<td>";
4335                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4336                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4337                                       -class => "list"}, esc_path($diff->{'file'}));
4338                         print "</td>\n";
4339                         print "<td>$mode_chnge</td>\n";
4340                         print "<td class=\"link\">";
4341                         if ($action eq 'commitdiff') {
4342                                 # link to patch
4343                                 $patchno++;
4344                                 print $cgi->a({-href => "#patch$patchno"}, "patch") .
4345                                       " | ";
4346                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4347                                 # "commit" view and modified file (not onlu mode changed)
4348                                 print $cgi->a({-href => href(action=>"blobdiff",
4349                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4350                                                              hash_base=>$hash, hash_parent_base=>$parent,
4351                                                              file_name=>$diff->{'file'})},
4352                                               "diff") .
4353                                       " | ";
4354                         }
4355                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4356                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4357                                        "blob") . " | ";
4358                         if ($have_blame) {
4359                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4360                                                              file_name=>$diff->{'file'})},
4361                                               "blame") . " | ";
4362                         }
4363                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4364                                                      file_name=>$diff->{'file'})},
4365                                       "history");
4366                         print "</td>\n";
4367
4368                 } elsif ($diff->{'status'} eq "R" || $diff->{'status'} eq "C") { # renamed or copied
4369                         my %status_name = ('R' => 'moved', 'C' => 'copied');
4370                         my $nstatus = $status_name{$diff->{'status'}};
4371                         my $mode_chng = "";
4372                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4373                                 # mode also for directories, so we cannot use $to_mode_str
4374                                 $mode_chng = sprintf(", mode: %04o", $to_mode_oct & 0777);
4375                         }
4376                         print "<td>" .
4377                               $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
4378                                                      hash=>$diff->{'to_id'}, file_name=>$diff->{'to_file'}),
4379                                       -class => "list"}, esc_path($diff->{'to_file'})) . "</td>\n" .
4380                               "<td><span class=\"file_status $nstatus\">[$nstatus from " .
4381                               $cgi->a({-href => href(action=>"blob", hash_base=>$parent,
4382                                                      hash=>$diff->{'from_id'}, file_name=>$diff->{'from_file'}),
4383                                       -class => "list"}, esc_path($diff->{'from_file'})) .
4384                               " with " . (int $diff->{'similarity'}) . "% similarity$mode_chng]</span></td>\n" .
4385                               "<td class=\"link\">";
4386                         if ($action eq 'commitdiff') {
4387                                 # link to patch
4388                                 $patchno++;
4389                                 print $cgi->a({-href => "#patch$patchno"}, "patch") .
4390                                       " | ";
4391                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4392                                 # "commit" view and modified file (not only pure rename or copy)
4393                                 print $cgi->a({-href => href(action=>"blobdiff",
4394                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4395                                                              hash_base=>$hash, hash_parent_base=>$parent,
4396                                                              file_name=>$diff->{'to_file'}, file_parent=>$diff->{'from_file'})},
4397                                               "diff") .
4398                                       " | ";
4399                         }
4400                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4401                                                      hash_base=>$parent, file_name=>$diff->{'to_file'})},
4402                                       "blob") . " | ";
4403                         if ($have_blame) {
4404                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4405                                                              file_name=>$diff->{'to_file'})},
4406                                               "blame") . " | ";
4407                         }
4408                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4409                                                     file_name=>$diff->{'to_file'})},
4410                                       "history");
4411                         print "</td>\n";
4412
4413                 } # we should not encounter Unmerged (U) or Unknown (X) status
4414                 print "</tr>\n";
4415         }
4416         print "</tbody>" if $has_header;
4417         print "</table>\n";
4418 }
4419
4420 sub git_patchset_body {
4421         my ($fd, $difftree, $hash, @hash_parents) = @_;
4422         my ($hash_parent) = $hash_parents[0];
4423
4424         my $is_combined = (@hash_parents > 1);
4425         my $patch_idx = 0;
4426         my $patch_number = 0;
4427         my $patch_line;
4428         my $diffinfo;
4429         my $to_name;
4430         my (%from, %to);
4431
4432         print "<div class=\"patchset\">\n";
4433
4434         # skip to first patch
4435         while ($patch_line = <$fd>) {
4436                 chomp $patch_line;
4437
4438                 last if ($patch_line =~ m/^diff /);
4439         }
4440
4441  PATCH:
4442         while ($patch_line) {
4443
4444                 # parse "git diff" header line
4445                 if ($patch_line =~ m/^diff --git (\"(?:[^\\\"]*(?:\\.[^\\\"]*)*)\"|[^ "]*) (.*)$/) {
4446                         # $1 is from_name, which we do not use
4447                         $to_name = unquote($2);
4448                         $to_name =~ s!^b/!!;
4449                 } elsif ($patch_line =~ m/^diff --(cc|combined) ("?.*"?)$/) {
4450                         # $1 is 'cc' or 'combined', which we do not use
4451                         $to_name = unquote($2);
4452                 } else {
4453                         $to_name = undef;
4454                 }
4455
4456                 # check if current patch belong to current raw line
4457                 # and parse raw git-diff line if needed
4458                 if (is_patch_split($diffinfo, { 'to_file' => $to_name })) {
4459                         # this is continuation of a split patch
4460                         print "<div class=\"patch cont\">\n";
4461                 } else {
4462                         # advance raw git-diff output if needed
4463                         $patch_idx++ if defined $diffinfo;
4464
4465                         # read and prepare patch information
4466                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
4467
4468                         # compact combined diff output can have some patches skipped
4469                         # find which patch (using pathname of result) we are at now;
4470                         if ($is_combined) {
4471                                 while ($to_name ne $diffinfo->{'to_file'}) {
4472                                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
4473                                               format_diff_cc_simplified($diffinfo, @hash_parents) .
4474                                               "</div>\n";  # class="patch"
4475
4476                                         $patch_idx++;
4477                                         $patch_number++;
4478
4479                                         last if $patch_idx > $#$difftree;
4480                                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
4481                                 }
4482                         }
4483
4484                         # modifies %from, %to hashes
4485                         parse_from_to_diffinfo($diffinfo, \%from, \%to, @hash_parents);
4486
4487                         # this is first patch for raw difftree line with $patch_idx index
4488                         # we index @$difftree array from 0, but number patches from 1
4489                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n";
4490                 }
4491
4492                 # git diff header
4493                 #assert($patch_line =~ m/^diff /) if DEBUG;
4494                 #assert($patch_line !~ m!$/$!) if DEBUG; # is chomp-ed
4495                 $patch_number++;
4496                 # print "git diff" header
4497                 print format_git_diff_header_line($patch_line, $diffinfo,
4498                                                   \%from, \%to);
4499
4500                 # print extended diff header
4501                 print "<div class=\"diff extended_header\">\n";
4502         EXTENDED_HEADER:
4503                 while ($patch_line = <$fd>) {
4504                         chomp $patch_line;
4505
4506                         last EXTENDED_HEADER if ($patch_line =~ m/^--- |^diff /);
4507
4508                         print format_extended_diff_header_line($patch_line, $diffinfo,
4509                                                                \%from, \%to);
4510                 }
4511                 print "</div>\n"; # class="diff extended_header"
4512
4513                 # from-file/to-file diff header
4514                 if (! $patch_line) {
4515                         print "</div>\n"; # class="patch"
4516                         last PATCH;
4517                 }
4518                 next PATCH if ($patch_line =~ m/^diff /);
4519                 #assert($patch_line =~ m/^---/) if DEBUG;
4520
4521                 my $last_patch_line = $patch_line;
4522                 $patch_line = <$fd>;
4523                 chomp $patch_line;
4524                 #assert($patch_line =~ m/^\+\+\+/) if DEBUG;
4525
4526                 print format_diff_from_to_header($last_patch_line, $patch_line,
4527                                                  $diffinfo, \%from, \%to,
4528                                                  @hash_parents);
4529
4530                 # the patch itself
4531         LINE:
4532                 while ($patch_line = <$fd>) {
4533                         chomp $patch_line;
4534
4535                         next PATCH if ($patch_line =~ m/^diff /);
4536
4537                         print format_diff_line($patch_line, \%from, \%to);
4538                 }
4539
4540         } continue {
4541                 print "</div>\n"; # class="patch"
4542         }
4543
4544         # for compact combined (--cc) format, with chunk and patch simplification
4545         # the patchset might be empty, but there might be unprocessed raw lines
4546         for (++$patch_idx if $patch_number > 0;
4547              $patch_idx < @$difftree;
4548              ++$patch_idx) {
4549                 # read and prepare patch information
4550                 $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
4551
4552                 # generate anchor for "patch" links in difftree / whatchanged part
4553                 print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
4554                       format_diff_cc_simplified($diffinfo, @hash_parents) .
4555                       "</div>\n";  # class="patch"
4556
4557                 $patch_number++;
4558         }
4559
4560         if ($patch_number == 0) {
4561                 if (@hash_parents > 1) {
4562                         print "<div class=\"diff nodifferences\">Trivial merge</div>\n";
4563                 } else {
4564                         print "<div class=\"diff nodifferences\">No differences found</div>\n";
4565                 }
4566         }
4567
4568         print "</div>\n"; # class="patchset"
4569 }
4570
4571 # . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
4572
4573 # fills project list info (age, description, owner, forks) for each
4574 # project in the list, removing invalid projects from returned list
4575 # NOTE: modifies $projlist, but does not remove entries from it
4576 sub fill_project_list_info {
4577         my ($projlist, $check_forks) = @_;
4578         my @projects;
4579
4580         my $show_ctags = gitweb_check_feature('ctags');
4581  PROJECT:
4582         foreach my $pr (@$projlist) {
4583                 my (@activity) = git_get_last_activity($pr->{'path'});
4584                 unless (@activity) {
4585                         next PROJECT;
4586                 }
4587                 ($pr->{'age'}, $pr->{'age_string'}) = @activity;
4588                 if (!defined $pr->{'descr'}) {
4589                         my $descr = git_get_project_description($pr->{'path'}) || "";
4590                         $descr = to_utf8($descr);
4591                         $pr->{'descr_long'} = $descr;
4592                         $pr->{'descr'} = chop_str($descr, $projects_list_description_width, 5);
4593                 }
4594                 if (!defined $pr->{'owner'}) {
4595                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}") || "";
4596                 }
4597                 if ($check_forks) {
4598                         my $pname = $pr->{'path'};
4599                         if (($pname =~ s/\.git$//) &&
4600                             ($pname !~ /\/$/) &&
4601                             (-d "$projectroot/$pname")) {
4602                                 $pr->{'forks'} = "-d $projectroot/$pname";
4603                         } else {
4604                                 $pr->{'forks'} = 0;
4605                         }
4606                 }
4607                 $show_ctags and $pr->{'ctags'} = git_get_project_ctags($pr->{'path'});
4608                 push @projects, $pr;
4609         }
4610
4611         return @projects;
4612 }
4613
4614 # print 'sort by' <th> element, generating 'sort by $name' replay link
4615 # if that order is not selected
4616 sub print_sort_th {
4617         print format_sort_th(@_);
4618 }
4619
4620 sub format_sort_th {
4621         my ($name, $order, $header) = @_;
4622         my $sort_th = "";
4623         $header ||= ucfirst($name);
4624
4625         if ($order eq $name) {
4626                 $sort_th .= "<th>$header</th>\n";
4627         } else {
4628                 $sort_th .= "<th>" .
4629                             $cgi->a({-href => href(-replay=>1, order=>$name),
4630                                      -class => "header"}, $header) .
4631                             "</th>\n";
4632         }
4633
4634         return $sort_th;
4635 }
4636
4637 sub git_project_list_body {
4638         # actually uses global variable $project
4639         my ($projlist, $order, $from, $to, $extra, $no_header) = @_;
4640
4641         my $check_forks = gitweb_check_feature('forks');
4642         my @projects = fill_project_list_info($projlist, $check_forks);
4643
4644         $order ||= $default_projects_order;
4645         $from = 0 unless defined $from;
4646         $to = $#projects if (!defined $to || $#projects < $to);
4647
4648         my %order_info = (
4649                 project => { key => 'path', type => 'str' },
4650                 descr => { key => 'descr_long', type => 'str' },
4651                 owner => { key => 'owner', type => 'str' },
4652                 age => { key => 'age', type => 'num' }
4653         );
4654         my $oi = $order_info{$order};
4655         if ($oi->{'type'} eq 'str') {
4656                 @projects = sort {$a->{$oi->{'key'}} cmp $b->{$oi->{'key'}}} @projects;
4657         } else {
4658                 @projects = sort {$a->{$oi->{'key'}} <=> $b->{$oi->{'key'}}} @projects;
4659         }
4660
4661         my $show_ctags = gitweb_check_feature('ctags');
4662         if ($show_ctags) {
4663                 my %ctags;
4664                 foreach my $p (@projects) {
4665                         foreach my $ct (keys %{$p->{'ctags'}}) {
4666                                 $ctags{$ct} += $p->{'ctags'}->{$ct};
4667                         }
4668                 }
4669                 my $cloud = git_populate_project_tagcloud(\%ctags);
4670                 print git_show_project_tagcloud($cloud, 64);
4671         }
4672
4673         print "<table class=\"project_list\">\n";
4674         unless ($no_header) {
4675                 print "<tr>\n";
4676                 if ($check_forks) {
4677                         print "<th></th>\n";
4678                 }
4679                 print_sort_th('project', $order, 'Project');
4680                 print_sort_th('descr', $order, 'Description');
4681                 print_sort_th('owner', $order, 'Owner');
4682                 print_sort_th('age', $order, 'Last Change');
4683                 print "<th></th>\n" . # for links
4684                       "</tr>\n";
4685         }
4686         my $alternate = 1;
4687         my $tagfilter = $cgi->param('by_tag');
4688         for (my $i = $from; $i <= $to; $i++) {
4689                 my $pr = $projects[$i];
4690
4691                 next if $tagfilter and $show_ctags and not grep { lc $_ eq lc $tagfilter } keys %{$pr->{'ctags'}};
4692                 next if $searchtext and not $pr->{'path'} =~ /$searchtext/
4693                         and not $pr->{'descr_long'} =~ /$searchtext/;
4694                 # Weed out forks or non-matching entries of search
4695                 if ($check_forks) {
4696                         my $forkbase = $project; $forkbase ||= ''; $forkbase =~ s#\.git$#/#;
4697                         $forkbase="^$forkbase" if $forkbase;
4698                         next if not $searchtext and not $tagfilter and $show_ctags
4699                                 and $pr->{'path'} =~ m#$forkbase.*/.*#; # regexp-safe
4700                 }
4701
4702                 if ($alternate) {
4703                         print "<tr class=\"dark\">\n";
4704                 } else {
4705                         print "<tr class=\"light\">\n";
4706                 }
4707                 $alternate ^= 1;
4708                 if ($check_forks) {
4709                         print "<td>";
4710                         if ($pr->{'forks'}) {
4711                                 print "<!-- $pr->{'forks'} -->\n";
4712                                 print $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "+");
4713                         }
4714                         print "</td>\n";
4715                 }
4716                 print "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
4717                                         -class => "list"}, esc_html($pr->{'path'})) . "</td>\n" .
4718                       "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
4719                                         -class => "list", -title => $pr->{'descr_long'}},
4720                                         esc_html($pr->{'descr'})) . "</td>\n" .
4721                       "<td><i>" . chop_and_escape_str($pr->{'owner'}, 15) . "</i></td>\n";
4722                 print "<td class=\"". age_class($pr->{'age'}) . "\">" .
4723                       (defined $pr->{'age_string'} ? $pr->{'age_string'} : "No commits") . "</td>\n" .
4724                       "<td class=\"link\">" .
4725                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary")}, "summary")   . " | " .
4726                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"shortlog")}, "shortlog") . " | " .
4727                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"log")}, "log") . " | " .
4728                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"tree")}, "tree") .
4729                       ($pr->{'forks'} ? " | " . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "forks") : '') .
4730                       "</td>\n" .
4731                       "</tr>\n";
4732         }
4733         if (defined $extra) {
4734                 print "<tr>\n";
4735                 if ($check_forks) {
4736                         print "<td></td>\n";
4737                 }
4738                 print "<td colspan=\"5\">$extra</td>\n" .
4739                       "</tr>\n";
4740         }
4741         print "</table>\n";
4742 }
4743
4744 sub git_log_body {
4745         # uses global variable $project
4746         my ($commitlist, $from, $to, $refs, $extra) = @_;
4747
4748         $from = 0 unless defined $from;
4749         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
4750
4751         for (my $i = 0; $i <= $to; $i++) {
4752                 my %co = %{$commitlist->[$i]};
4753                 next if !%co;
4754                 my $commit = $co{'id'};
4755                 my $ref = format_ref_marker($refs, $commit);
4756                 my %ad = parse_date($co{'author_epoch'});
4757                 git_print_header_div('commit',
4758                                "<span class=\"age\">$co{'age_string'}</span>" .
4759                                esc_html($co{'title'}) . $ref,
4760                                $commit);
4761                 print "<div class=\"title_text\">\n" .
4762                       "<div class=\"log_link\">\n" .
4763                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") .
4764                       " | " .
4765                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") .
4766                       " | " .
4767                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree") .
4768                       "<br/>\n" .
4769                       "</div>\n";
4770                       git_print_authorship(\%co, -tag => 'span');
4771                       print "<br/>\n</div>\n";
4772
4773                 print "<div class=\"log_body\">\n";
4774                 git_print_log($co{'comment'}, -final_empty_line=> 1);
4775                 print "</div>\n";
4776         }
4777         if ($extra) {
4778                 print "<div class=\"page_nav\">\n";
4779                 print "$extra\n";
4780                 print "</div>\n";
4781         }
4782 }
4783
4784 sub git_shortlog_body {
4785         # uses global variable $project
4786         my ($commitlist, $from, $to, $refs, $extra) = @_;
4787
4788         $from = 0 unless defined $from;
4789         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
4790
4791         print "<table class=\"shortlog\">\n";
4792         my $alternate = 1;
4793         for (my $i = $from; $i <= $to; $i++) {
4794                 my %co = %{$commitlist->[$i]};
4795                 my $commit = $co{'id'};
4796                 my $ref = format_ref_marker($refs, $commit);
4797                 if ($alternate) {
4798                         print "<tr class=\"dark\">\n";
4799                 } else {
4800                         print "<tr class=\"light\">\n";
4801                 }
4802                 $alternate ^= 1;
4803                 # git_summary() used print "<td><i>$co{'age_string'}</i></td>\n" .
4804                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
4805                       format_author_html('td', \%co, 10) . "<td>";
4806                 print format_subject_html($co{'title'}, $co{'title_short'},
4807                                           href(action=>"commit", hash=>$commit), $ref);
4808                 print "</td>\n" .
4809                       "<td class=\"link\">" .
4810                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") . " | " .
4811                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") . " | " .
4812                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree");
4813                 my $snapshot_links = format_snapshot_links($commit);
4814                 if (defined $snapshot_links) {
4815                         print " | " . $snapshot_links;
4816                 }
4817                 print "</td>\n" .
4818                       "</tr>\n";
4819         }
4820         if (defined $extra) {
4821                 print "<tr>\n" .
4822                       "<td colspan=\"4\">$extra</td>\n" .
4823                       "</tr>\n";
4824         }
4825         print "</table>\n";
4826 }
4827
4828 sub git_history_body {
4829         # Warning: assumes constant type (blob or tree) during history
4830         my ($commitlist, $from, $to, $refs, $extra,
4831             $file_name, $file_hash, $ftype) = @_;
4832
4833         $from = 0 unless defined $from;
4834         $to = $#{$commitlist} unless (defined $to && $to <= $#{$commitlist});
4835
4836         print "<table class=\"history\">\n";
4837         my $alternate = 1;
4838         for (my $i = $from; $i <= $to; $i++) {
4839                 my %co = %{$commitlist->[$i]};
4840                 if (!%co) {
4841                         next;
4842                 }
4843                 my $commit = $co{'id'};
4844
4845                 my $ref = format_ref_marker($refs, $commit);
4846
4847                 if ($alternate) {
4848                         print "<tr class=\"dark\">\n";
4849                 } else {
4850                         print "<tr class=\"light\">\n";
4851                 }
4852                 $alternate ^= 1;
4853                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
4854         # shortlog:   format_author_html('td', \%co, 10)
4855                       format_author_html('td', \%co, 15, 3) . "<td>";
4856                 # originally git_history used chop_str($co{'title'}, 50)
4857                 print format_subject_html($co{'title'}, $co{'title_short'},
4858                                           href(action=>"commit", hash=>$commit), $ref);
4859                 print "</td>\n" .
4860                       "<td class=\"link\">" .
4861                       $cgi->a({-href => href(action=>$ftype, hash_base=>$commit, file_name=>$file_name)}, $ftype) . " | " .
4862                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff");
4863
4864                 if ($ftype eq 'blob') {
4865                         my $blob_current = $file_hash;
4866                         my $blob_parent  = git_get_hash_by_path($commit, $file_name);
4867                         if (defined $blob_current && defined $blob_parent &&
4868                                         $blob_current ne $blob_parent) {
4869                                 print " | " .
4870                                         $cgi->a({-href => href(action=>"blobdiff",
4871                                                                hash=>$blob_current, hash_parent=>$blob_parent,
4872                                                                hash_base=>$hash_base, hash_parent_base=>$commit,
4873                                                                file_name=>$file_name)},
4874                                                 "diff to current");
4875                         }
4876                 }
4877                 print "</td>\n" .
4878                       "</tr>\n";
4879         }
4880         if (defined $extra) {
4881                 print "<tr>\n" .
4882                       "<td colspan=\"4\">$extra</td>\n" .
4883                       "</tr>\n";
4884         }
4885         print "</table>\n";
4886 }
4887
4888 sub git_tags_body {
4889         # uses global variable $project
4890         my ($taglist, $from, $to, $extra) = @_;
4891         $from = 0 unless defined $from;
4892         $to = $#{$taglist} if (!defined $to || $#{$taglist} < $to);
4893
4894         print "<table class=\"tags\">\n";
4895         my $alternate = 1;
4896         for (my $i = $from; $i <= $to; $i++) {
4897                 my $entry = $taglist->[$i];
4898                 my %tag = %$entry;
4899                 my $comment = $tag{'subject'};
4900                 my $comment_short;
4901                 if (defined $comment) {
4902                         $comment_short = chop_str($comment, 30, 5);
4903                 }
4904                 if ($alternate) {
4905                         print "<tr class=\"dark\">\n";
4906                 } else {
4907                         print "<tr class=\"light\">\n";
4908                 }
4909                 $alternate ^= 1;
4910                 if (defined $tag{'age'}) {
4911                         print "<td><i>$tag{'age'}</i></td>\n";
4912                 } else {
4913                         print "<td></td>\n";
4914                 }
4915                 print "<td>" .
4916                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'}),
4917                                -class => "list name"}, esc_html($tag{'name'})) .
4918                       "</td>\n" .
4919                       "<td>";
4920                 if (defined $comment) {
4921                         print format_subject_html($comment, $comment_short,
4922                                                   href(action=>"tag", hash=>$tag{'id'}));
4923                 }
4924                 print "</td>\n" .
4925                       "<td class=\"selflink\">";
4926                 if ($tag{'type'} eq "tag") {
4927                         print $cgi->a({-href => href(action=>"tag", hash=>$tag{'id'})}, "tag");
4928                 } else {
4929                         print "&nbsp;";
4930                 }
4931                 print "</td>\n" .
4932                       "<td class=\"link\">" . " | " .
4933                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'})}, $tag{'reftype'});
4934                 if ($tag{'reftype'} eq "commit") {
4935                         print " | " . $cgi->a({-href => href(action=>"shortlog", hash=>$tag{'fullname'})}, "shortlog") .
4936                               " | " . $cgi->a({-href => href(action=>"log", hash=>$tag{'fullname'})}, "log");
4937                 } elsif ($tag{'reftype'} eq "blob") {
4938                         print " | " . $cgi->a({-href => href(action=>"blob_plain", hash=>$tag{'refid'})}, "raw");
4939                 }
4940                 print "</td>\n" .
4941                       "</tr>";
4942         }
4943         if (defined $extra) {
4944                 print "<tr>\n" .
4945                       "<td colspan=\"5\">$extra</td>\n" .
4946                       "</tr>\n";
4947         }
4948         print "</table>\n";
4949 }
4950
4951 sub git_heads_body {
4952         # uses global variable $project
4953         my ($headlist, $head, $from, $to, $extra) = @_;
4954         $from = 0 unless defined $from;
4955         $to = $#{$headlist} if (!defined $to || $#{$headlist} < $to);
4956
4957         print "<table class=\"heads\">\n";
4958         my $alternate = 1;
4959         for (my $i = $from; $i <= $to; $i++) {
4960                 my $entry = $headlist->[$i];
4961                 my %ref = %$entry;
4962                 my $curr = $ref{'id'} eq $head;
4963                 if ($alternate) {
4964                         print "<tr class=\"dark\">\n";
4965                 } else {
4966                         print "<tr class=\"light\">\n";
4967                 }
4968                 $alternate ^= 1;
4969                 print "<td><i>$ref{'age'}</i></td>\n" .
4970                       ($curr ? "<td class=\"current_head\">" : "<td>") .
4971                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'}),
4972                                -class => "list name"},esc_html($ref{'name'})) .
4973                       "</td>\n" .
4974                       "<td class=\"link\">" .
4975                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'})}, "shortlog") . " | " .
4976                       $cgi->a({-href => href(action=>"log", hash=>$ref{'fullname'})}, "log") . " | " .
4977                       $cgi->a({-href => href(action=>"tree", hash=>$ref{'fullname'}, hash_base=>$ref{'fullname'})}, "tree") .
4978                       "</td>\n" .
4979                       "</tr>";
4980         }
4981         if (defined $extra) {
4982                 print "<tr>\n" .
4983                       "<td colspan=\"3\">$extra</td>\n" .
4984                       "</tr>\n";
4985         }
4986         print "</table>\n";
4987 }
4988
4989 sub git_search_grep_body {
4990         my ($commitlist, $from, $to, $extra) = @_;
4991         $from = 0 unless defined $from;
4992         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
4993
4994         print "<table class=\"commit_search\">\n";
4995         my $alternate = 1;
4996         for (my $i = $from; $i <= $to; $i++) {
4997                 my %co = %{$commitlist->[$i]};
4998                 if (!%co) {
4999                         next;
5000                 }
5001                 my $commit = $co{'id'};
5002                 if ($alternate) {
5003                         print "<tr class=\"dark\">\n";
5004                 } else {
5005                         print "<tr class=\"light\">\n";
5006                 }
5007                 $alternate ^= 1;
5008                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5009                       format_author_html('td', \%co, 15, 5) .
5010                       "<td>" .
5011                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
5012                                -class => "list subject"},
5013                               chop_and_escape_str($co{'title'}, 50) . "<br/>");
5014                 my $comment = $co{'comment'};
5015                 foreach my $line (@$comment) {
5016                         if ($line =~ m/^(.*?)($search_regexp)(.*)$/i) {
5017                                 my ($lead, $match, $trail) = ($1, $2, $3);
5018                                 $match = chop_str($match, 70, 5, 'center');
5019                                 my $contextlen = int((80 - length($match))/2);
5020                                 $contextlen = 30 if ($contextlen > 30);
5021                                 $lead  = chop_str($lead,  $contextlen, 10, 'left');
5022                                 $trail = chop_str($trail, $contextlen, 10, 'right');
5023
5024                                 $lead  = esc_html($lead);
5025                                 $match = esc_html($match);
5026                                 $trail = esc_html($trail);
5027
5028                                 print "$lead<span class=\"match\">$match</span>$trail<br />";
5029                         }
5030                 }
5031                 print "</td>\n" .
5032                       "<td class=\"link\">" .
5033                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
5034                       " | " .
5035                       $cgi->a({-href => href(action=>"commitdiff", hash=>$co{'id'})}, "commitdiff") .
5036                       " | " .
5037                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
5038                 print "</td>\n" .
5039                       "</tr>\n";
5040         }
5041         if (defined $extra) {
5042                 print "<tr>\n" .
5043                       "<td colspan=\"3\">$extra</td>\n" .
5044                       "</tr>\n";
5045         }
5046         print "</table>\n";
5047 }
5048
5049 ## ======================================================================
5050 ## ======================================================================
5051 ## actions
5052
5053 sub git_project_list {
5054         my $order = $input_params{'order'};
5055         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
5056                 die_error(400, "Unknown order parameter");
5057         }
5058
5059         my @list = git_get_projects_list();
5060         if (!@list) {
5061                 die_error(404, "No projects found");
5062         }
5063
5064         git_header_html();
5065         if (defined $home_text && -f $home_text) {
5066                 print "<div class=\"index_include\">\n";
5067                 insert_file($home_text);
5068                 print "</div>\n";
5069         }
5070         print $cgi->startform(-method => "get") .
5071               "<p class=\"projsearch\">Search:\n" .
5072               $cgi->textfield(-name => "s", -value => $searchtext) . "\n" .
5073               "</p>" .
5074               $cgi->end_form() . "\n";
5075         git_project_list_body(\@list, $order);
5076         git_footer_html();
5077 }
5078
5079 sub git_forks {
5080         my $order = $input_params{'order'};
5081         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
5082                 die_error(400, "Unknown order parameter");
5083         }
5084
5085         my @list = git_get_projects_list($project);
5086         if (!@list) {
5087                 die_error(404, "No forks found");
5088         }
5089
5090         git_header_html();
5091         git_print_page_nav('','');
5092         git_print_header_div('summary', "$project forks");
5093         git_project_list_body(\@list, $order);
5094         git_footer_html();
5095 }
5096
5097 sub git_project_index {
5098         my @projects = git_get_projects_list($project);
5099
5100         print $cgi->header(
5101                 -type => 'text/plain',
5102                 -charset => 'utf-8',
5103                 -content_disposition => 'inline; filename="index.aux"');
5104
5105         foreach my $pr (@projects) {
5106                 if (!exists $pr->{'owner'}) {
5107                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}");
5108                 }
5109
5110                 my ($path, $owner) = ($pr->{'path'}, $pr->{'owner'});
5111                 # quote as in CGI::Util::encode, but keep the slash, and use '+' for ' '
5112                 $path  =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
5113                 $owner =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
5114                 $path  =~ s/ /\+/g;
5115                 $owner =~ s/ /\+/g;
5116
5117                 print "$path $owner\n";
5118         }
5119 }
5120
5121 sub git_summary {
5122         my $descr = git_get_project_description($project) || "none";
5123         my %co = parse_commit("HEAD");
5124         my %cd = %co ? parse_date($co{'committer_epoch'}, $co{'committer_tz'}) : ();
5125         my $head = $co{'id'};
5126         my $remote_heads = gitweb_check_feature('remote_heads');
5127
5128         my $owner = git_get_project_owner($project);
5129
5130         my $refs = git_get_references();
5131         # These get_*_list functions return one more to allow us to see if
5132         # there are more ...
5133         my @taglist  = git_get_tags_list(16);
5134         my @headlist = git_get_heads_list(16);
5135         my @remotelist = $remote_heads ? git_get_heads_list(16, 'remotes') : ();
5136         my @forklist;
5137         my $check_forks = gitweb_check_feature('forks');
5138
5139         if ($check_forks) {
5140                 @forklist = git_get_projects_list($project);
5141         }
5142
5143         git_header_html();
5144         git_print_page_nav('summary','', $head);
5145
5146         print "<div class=\"title\">&nbsp;</div>\n";
5147         print "<table class=\"projects_list\">\n" .
5148               "<tr id=\"metadata_desc\"><td>description</td><td>" . esc_html($descr) . "</td></tr>\n" .
5149               "<tr id=\"metadata_owner\"><td>owner</td><td>" . esc_html($owner) . "</td></tr>\n";
5150         if (defined $cd{'rfc2822'}) {
5151                 print "<tr id=\"metadata_lchange\"><td>last change</td><td>$cd{'rfc2822'}</td></tr>\n";
5152         }
5153
5154         # use per project git URL list in $projectroot/$project/cloneurl
5155         # or make project git URL from git base URL and project name
5156         my $url_tag = "URL";
5157         my @url_list = git_get_project_url_list($project);
5158         @url_list = map { "$_/$project" } @git_base_url_list unless @url_list;
5159         foreach my $git_url (@url_list) {
5160                 next unless $git_url;
5161                 print "<tr class=\"metadata_url\"><td>$url_tag</td><td>$git_url</td></tr>\n";
5162                 $url_tag = "";
5163         }
5164
5165         # Tag cloud
5166         my $show_ctags = gitweb_check_feature('ctags');
5167         if ($show_ctags) {
5168                 my $ctags = git_get_project_ctags($project);
5169                 my $cloud = git_populate_project_tagcloud($ctags);
5170                 print "<tr id=\"metadata_ctags\"><td>Content tags:<br />";
5171                 print "</td>\n<td>" unless %$ctags;
5172                 print "<form action=\"$show_ctags\" method=\"post\"><input type=\"hidden\" name=\"p\" value=\"$project\" />Add: <input type=\"text\" name=\"t\" size=\"8\" /></form>";
5173                 print "</td>\n<td>" if %$ctags;
5174                 print git_show_project_tagcloud($cloud, 48);
5175                 print "</td></tr>";
5176         }
5177
5178         print "</table>\n";
5179
5180         # If XSS prevention is on, we don't include README.html.
5181         # TODO: Allow a readme in some safe format.
5182         if (!$prevent_xss && -s "$projectroot/$project/README.html") {
5183                 print "<div class=\"title\">readme</div>\n" .
5184                       "<div class=\"readme\">\n";
5185                 insert_file("$projectroot/$project/README.html");
5186                 print "\n</div>\n"; # class="readme"
5187         }
5188
5189         # we need to request one more than 16 (0..15) to check if
5190         # those 16 are all
5191         my @commitlist = $head ? parse_commits($head, 17) : ();
5192         if (@commitlist) {
5193                 git_print_header_div('shortlog');
5194                 git_shortlog_body(\@commitlist, 0, 15, $refs,
5195                                   $#commitlist <=  15 ? undef :
5196                                   $cgi->a({-href => href(action=>"shortlog")}, "..."));
5197         }
5198
5199         if (@taglist) {
5200                 git_print_header_div('tags');
5201                 git_tags_body(\@taglist, 0, 15,
5202                               $#taglist <=  15 ? undef :
5203                               $cgi->a({-href => href(action=>"tags")}, "..."));
5204         }
5205
5206         if (@headlist) {
5207                 git_print_header_div('heads');
5208                 git_heads_body(\@headlist, $head, 0, 15,
5209                                $#headlist <= 15 ? undef :
5210                                $cgi->a({-href => href(action=>"heads")}, "..."));
5211         }
5212
5213         if (@remotelist) {
5214                 git_print_header_div('remotes');
5215                 git_heads_body(\@remotelist, $head, 0, 15,
5216                                $#remotelist <= 15 ? undef :
5217                                $cgi->a({-href => href(action=>"remotes")}, "..."));
5218         }
5219
5220         if (@forklist) {
5221                 git_print_header_div('forks');
5222                 git_project_list_body(\@forklist, 'age', 0, 15,
5223                                       $#forklist <= 15 ? undef :
5224                                       $cgi->a({-href => href(action=>"forks")}, "..."),
5225                                       'no_header');
5226         }
5227
5228         git_footer_html();
5229 }
5230
5231 sub git_tag {
5232         my %tag = parse_tag($hash);
5233
5234         if (! %tag) {
5235                 die_error(404, "Unknown tag object");
5236         }
5237
5238         my $head = git_get_head_hash($project);
5239         git_header_html();
5240         git_print_page_nav('','', $head,undef,$head);
5241         git_print_header_div('commit', esc_html($tag{'name'}), $hash);
5242         print "<div class=\"title_text\">\n" .
5243               "<table class=\"object_header\">\n" .
5244               "<tr>\n" .
5245               "<td>object</td>\n" .
5246               "<td>" . $cgi->a({-class => "list", -href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
5247                                $tag{'object'}) . "</td>\n" .
5248               "<td class=\"link\">" . $cgi->a({-href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
5249                                               $tag{'type'}) . "</td>\n" .
5250               "</tr>\n";
5251         if (defined($tag{'author'})) {
5252                 git_print_authorship_rows(\%tag, 'author');
5253         }
5254         print "</table>\n\n" .
5255               "</div>\n";
5256         print "<div class=\"page_body\">";
5257         my $comment = $tag{'comment'};
5258         foreach my $line (@$comment) {
5259                 chomp $line;
5260                 print esc_html($line, -nbsp=>1) . "<br/>\n";
5261         }
5262         print "</div>\n";
5263         git_footer_html();
5264 }
5265
5266 sub git_blame_common {
5267         my $format = shift || 'porcelain';
5268         if ($format eq 'porcelain' && $cgi->param('js')) {
5269                 $format = 'incremental';
5270                 $action = 'blame_incremental'; # for page title etc
5271         }
5272
5273         # permissions
5274         gitweb_check_feature('blame')
5275                 or die_error(403, "Blame view not allowed");
5276
5277         # error checking
5278         die_error(400, "No file name given") unless $file_name;
5279         $hash_base ||= git_get_head_hash($project);
5280         die_error(404, "Couldn't find base commit") unless $hash_base;
5281         my %co = parse_commit($hash_base)
5282                 or die_error(404, "Commit not found");
5283         my $ftype = "blob";
5284         if (!defined $hash) {
5285                 $hash = git_get_hash_by_path($hash_base, $file_name, "blob")
5286                         or die_error(404, "Error looking up file");
5287         } else {
5288                 $ftype = git_get_type($hash);
5289                 if ($ftype !~ "blob") {
5290                         die_error(400, "Object is not a blob");
5291                 }
5292         }
5293
5294         my $fd;
5295         if ($format eq 'incremental') {
5296                 # get file contents (as base)
5297                 open $fd, "-|", git_cmd(), 'cat-file', 'blob', $hash
5298                         or die_error(500, "Open git-cat-file failed");
5299         } elsif ($format eq 'data') {
5300                 # run git-blame --incremental
5301                 open $fd, "-|", git_cmd(), "blame", "--incremental",
5302                         $hash_base, "--", $file_name
5303                         or die_error(500, "Open git-blame --incremental failed");
5304         } else {
5305                 # run git-blame --porcelain
5306                 open $fd, "-|", git_cmd(), "blame", '-p',
5307                         $hash_base, '--', $file_name
5308                         or die_error(500, "Open git-blame --porcelain failed");
5309         }
5310
5311         # incremental blame data returns early
5312         if ($format eq 'data') {
5313                 print $cgi->header(
5314                         -type=>"text/plain", -charset => "utf-8",
5315                         -status=> "200 OK");
5316                 local $| = 1; # output autoflush
5317                 print while <$fd>;
5318                 close $fd
5319                         or print "ERROR $!\n";
5320
5321                 print 'END';
5322                 if (defined $t0 && gitweb_check_feature('timed')) {
5323                         print ' '.
5324                               tv_interval($t0, [ gettimeofday() ]).
5325                               ' '.$number_of_git_cmds;
5326                 }
5327                 print "\n";
5328
5329                 return;
5330         }
5331
5332         # page header
5333         git_header_html();
5334         my $formats_nav =
5335                 $cgi->a({-href => href(action=>"blob", -replay=>1)},
5336                         "blob") .
5337                 " | ";
5338         if ($format eq 'incremental') {
5339                 $formats_nav .=
5340                         $cgi->a({-href => href(action=>"blame", javascript=>0, -replay=>1)},
5341                                 "blame") . " (non-incremental)";
5342         } else {
5343                 $formats_nav .=
5344                         $cgi->a({-href => href(action=>"blame_incremental", -replay=>1)},
5345                                 "blame") . " (incremental)";
5346         }
5347         $formats_nav .=
5348                 " | " .
5349                 $cgi->a({-href => href(action=>"history", -replay=>1)},
5350                         "history") .
5351                 " | " .
5352                 $cgi->a({-href => href(action=>$action, file_name=>$file_name)},
5353                         "HEAD");
5354         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
5355         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
5356         git_print_page_path($file_name, $ftype, $hash_base);
5357
5358         # page body
5359         if ($format eq 'incremental') {
5360                 print "<noscript>\n<div class=\"error\"><center><b>\n".
5361                       "This page requires JavaScript to run.\n Use ".
5362                       $cgi->a({-href => href(action=>'blame',javascript=>0,-replay=>1)},
5363                               'this page').
5364                       " instead.\n".
5365                       "</b></center></div>\n</noscript>\n";
5366
5367                 print qq!<div id="progress_bar" style="width: 100%; background-color: yellow"></div>\n!;
5368         }
5369
5370         print qq!<div class="page_body">\n!;
5371         print qq!<div id="progress_info">... / ...</div>\n!
5372                 if ($format eq 'incremental');
5373         print qq!<table id="blame_table" class="blame" width="100%">\n!.
5374               #qq!<col width="5.5em" /><col width="2.5em" /><col width="*" />\n!.
5375               qq!<thead>\n!.
5376               qq!<tr><th>Commit</th><th>Line</th><th>Data</th></tr>\n!.
5377               qq!</thead>\n!.
5378               qq!<tbody>\n!;
5379
5380         my @rev_color = qw(light dark);
5381         my $num_colors = scalar(@rev_color);
5382         my $current_color = 0;
5383
5384         if ($format eq 'incremental') {
5385                 my $color_class = $rev_color[$current_color];
5386
5387                 #contents of a file
5388                 my $linenr = 0;
5389         LINE:
5390                 while (my $line = <$fd>) {
5391                         chomp $line;
5392                         $linenr++;
5393
5394                         print qq!<tr id="l$linenr" class="$color_class">!.
5395                               qq!<td class="sha1"><a href=""> </a></td>!.
5396                               qq!<td class="linenr">!.
5397                               qq!<a class="linenr" href="">$linenr</a></td>!;
5398                         print qq!<td class="pre">! . esc_html($line) . "</td>\n";
5399                         print qq!</tr>\n!;
5400                 }
5401
5402         } else { # porcelain, i.e. ordinary blame
5403                 my %metainfo = (); # saves information about commits
5404
5405                 # blame data
5406         LINE:
5407                 while (my $line = <$fd>) {
5408                         chomp $line;
5409                         # the header: <SHA-1> <src lineno> <dst lineno> [<lines in group>]
5410                         # no <lines in group> for subsequent lines in group of lines
5411                         my ($full_rev, $orig_lineno, $lineno, $group_size) =
5412                            ($line =~ /^([0-9a-f]{40}) (\d+) (\d+)(?: (\d+))?$/);
5413                         if (!exists $metainfo{$full_rev}) {
5414                                 $metainfo{$full_rev} = { 'nprevious' => 0 };
5415                         }
5416                         my $meta = $metainfo{$full_rev};
5417                         my $data;
5418                         while ($data = <$fd>) {
5419                                 chomp $data;
5420                                 last if ($data =~ s/^\t//); # contents of line
5421                                 if ($data =~ /^(\S+)(?: (.*))?$/) {
5422                                         $meta->{$1} = $2 unless exists $meta->{$1};
5423                                 }
5424                                 if ($data =~ /^previous /) {
5425                                         $meta->{'nprevious'}++;
5426                                 }
5427                         }
5428                         my $short_rev = substr($full_rev, 0, 8);
5429                         my $author = $meta->{'author'};
5430                         my %date =
5431                                 parse_date($meta->{'author-time'}, $meta->{'author-tz'});
5432                         my $date = $date{'iso-tz'};
5433                         if ($group_size) {
5434                                 $current_color = ($current_color + 1) % $num_colors;
5435                         }
5436                         my $tr_class = $rev_color[$current_color];
5437                         $tr_class .= ' boundary' if (exists $meta->{'boundary'});
5438                         $tr_class .= ' no-previous' if ($meta->{'nprevious'} == 0);
5439                         $tr_class .= ' multiple-previous' if ($meta->{'nprevious'} > 1);
5440                         print "<tr id=\"l$lineno\" class=\"$tr_class\">\n";
5441                         if ($group_size) {
5442                                 print "<td class=\"sha1\"";
5443                                 print " title=\"". esc_html($author) . ", $date\"";
5444                                 print " rowspan=\"$group_size\"" if ($group_size > 1);
5445                                 print ">";
5446                                 print $cgi->a({-href => href(action=>"commit",
5447                                                              hash=>$full_rev,
5448                                                              file_name=>$file_name)},
5449                                               esc_html($short_rev));
5450                                 if ($group_size >= 2) {
5451                                         my @author_initials = ($author =~ /\b([[:upper:]])\B/g);
5452                                         if (@author_initials) {
5453                                                 print "<br />" .
5454                                                       esc_html(join('', @author_initials));
5455                                                 #           or join('.', ...)
5456                                         }
5457                                 }
5458                                 print "</td>\n";
5459                         }
5460                         # 'previous' <sha1 of parent commit> <filename at commit>
5461                         if (exists $meta->{'previous'} &&
5462                             $meta->{'previous'} =~ /^([a-fA-F0-9]{40}) (.*)$/) {
5463                                 $meta->{'parent'} = $1;
5464                                 $meta->{'file_parent'} = unquote($2);
5465                         }
5466                         my $linenr_commit =
5467                                 exists($meta->{'parent'}) ?
5468                                 $meta->{'parent'} : $full_rev;
5469                         my $linenr_filename =
5470                                 exists($meta->{'file_parent'}) ?
5471                                 $meta->{'file_parent'} : unquote($meta->{'filename'});
5472                         my $blamed = href(action => 'blame',
5473                                           file_name => $linenr_filename,
5474                                           hash_base => $linenr_commit);
5475                         print "<td class=\"linenr\">";
5476                         print $cgi->a({ -href => "$blamed#l$orig_lineno",
5477                                         -class => "linenr" },
5478                                       esc_html($lineno));
5479                         print "</td>";
5480                         print "<td class=\"pre\">" . esc_html($data) . "</td>\n";
5481                         print "</tr>\n";
5482                 } # end while
5483
5484         }
5485
5486         # footer
5487         print "</tbody>\n".
5488               "</table>\n"; # class="blame"
5489         print "</div>\n";   # class="blame_body"
5490         close $fd
5491                 or print "Reading blob failed\n";
5492
5493         git_footer_html();
5494 }
5495
5496 sub git_blame {
5497         git_blame_common();
5498 }
5499
5500 sub git_blame_incremental {
5501         git_blame_common('incremental');
5502 }
5503
5504 sub git_blame_data {
5505         git_blame_common('data');
5506 }
5507
5508 sub git_tags {
5509         my $head = git_get_head_hash($project);
5510         git_header_html();
5511         git_print_page_nav('','', $head,undef,$head);
5512         git_print_header_div('summary', $project);
5513
5514         my @tagslist = git_get_tags_list();
5515         if (@tagslist) {
5516                 git_tags_body(\@tagslist);
5517         }
5518         git_footer_html();
5519 }
5520
5521 sub git_heads {
5522         my $head = git_get_head_hash($project);
5523         git_header_html();
5524         git_print_page_nav('','', $head,undef,$head);
5525         git_print_header_div('summary', $project);
5526
5527         my @headslist = git_get_heads_list();
5528         if (@headslist) {
5529                 git_heads_body(\@headslist, $head);
5530         }
5531         git_footer_html();
5532 }
5533
5534 sub git_remotes {
5535         gitweb_check_feature('remote_heads')
5536                 or die_error(403, "Remote heads view is disabled");
5537
5538         my $head = git_get_head_hash($project);
5539         git_header_html();
5540         git_print_page_nav('','', $head,undef,$head);
5541         git_print_header_div('summary', $project);
5542
5543         my @remotelist = git_get_heads_list(undef, 'remotes');
5544         if (@remotelist) {
5545                 git_heads_body(\@remotelist, $head);
5546         }
5547         git_footer_html();
5548 }
5549
5550 sub git_blob_plain {
5551         my $type = shift;
5552         my $expires;
5553
5554         if (!defined $hash) {
5555                 if (defined $file_name) {
5556                         my $base = $hash_base || git_get_head_hash($project);
5557                         $hash = git_get_hash_by_path($base, $file_name, "blob")
5558                                 or die_error(404, "Cannot find file");
5559                 } else {
5560                         die_error(400, "No file name defined");
5561                 }
5562         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
5563                 # blobs defined by non-textual hash id's can be cached
5564                 $expires = "+1d";
5565         }
5566
5567         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
5568                 or die_error(500, "Open git-cat-file blob '$hash' failed");
5569
5570         # content-type (can include charset)
5571         $type = blob_contenttype($fd, $file_name, $type);
5572
5573         # "save as" filename, even when no $file_name is given
5574         my $save_as = "$hash";
5575         if (defined $file_name) {
5576                 $save_as = $file_name;
5577         } elsif ($type =~ m/^text\//) {
5578                 $save_as .= '.txt';
5579         }
5580
5581         # With XSS prevention on, blobs of all types except a few known safe
5582         # ones are served with "Content-Disposition: attachment" to make sure
5583         # they don't run in our security domain.  For certain image types,
5584         # blob view writes an <img> tag referring to blob_plain view, and we
5585         # want to be sure not to break that by serving the image as an
5586         # attachment (though Firefox 3 doesn't seem to care).
5587         my $sandbox = $prevent_xss &&
5588                 $type !~ m!^(?:text/plain|image/(?:gif|png|jpeg))$!;
5589
5590         print $cgi->header(
5591                 -type => $type,
5592                 -expires => $expires,
5593                 -content_disposition =>
5594                         ($sandbox ? 'attachment' : 'inline')
5595                         . '; filename="' . $save_as . '"');
5596         local $/ = undef;
5597         binmode STDOUT, ':raw';
5598         print <$fd>;
5599         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
5600         close $fd;
5601 }
5602
5603 sub git_blob {
5604         my $expires;
5605
5606         if (!defined $hash) {
5607                 if (defined $file_name) {
5608                         my $base = $hash_base || git_get_head_hash($project);
5609                         $hash = git_get_hash_by_path($base, $file_name, "blob")
5610                                 or die_error(404, "Cannot find file");
5611                 } else {
5612                         die_error(400, "No file name defined");
5613                 }
5614         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
5615                 # blobs defined by non-textual hash id's can be cached
5616                 $expires = "+1d";
5617         }
5618
5619         my $have_blame = gitweb_check_feature('blame');
5620         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
5621                 or die_error(500, "Couldn't cat $file_name, $hash");
5622         my $mimetype = blob_mimetype($fd, $file_name);
5623         # use 'blob_plain' (aka 'raw') view for files that cannot be displayed
5624         if ($mimetype !~ m!^(?:text/|image/(?:gif|png|jpeg)$)! && -B $fd) {
5625                 close $fd;
5626                 return git_blob_plain($mimetype);
5627         }
5628         # we can have blame only for text/* mimetype
5629         $have_blame &&= ($mimetype =~ m!^text/!);
5630
5631         my $highlight = gitweb_check_feature('highlight');
5632         my $syntax = guess_file_syntax($highlight, $mimetype, $file_name);
5633         $fd = run_highlighter($fd, $highlight, $syntax)
5634                 if $syntax;
5635
5636         git_header_html(undef, $expires);
5637         my $formats_nav = '';
5638         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
5639                 if (defined $file_name) {
5640                         if ($have_blame) {
5641                                 $formats_nav .=
5642                                         $cgi->a({-href => href(action=>"blame", -replay=>1)},
5643                                                 "blame") .
5644                                         " | ";
5645                         }
5646                         $formats_nav .=
5647                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
5648                                         "history") .
5649                                 " | " .
5650                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
5651                                         "raw") .
5652                                 " | " .
5653                                 $cgi->a({-href => href(action=>"blob",
5654                                                        hash_base=>"HEAD", file_name=>$file_name)},
5655                                         "HEAD");
5656                 } else {
5657                         $formats_nav .=
5658                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
5659                                         "raw");
5660                 }
5661                 git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
5662                 git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
5663         } else {
5664                 print "<div class=\"page_nav\">\n" .
5665                       "<br/><br/></div>\n" .
5666                       "<div class=\"title\">$hash</div>\n";
5667         }
5668         git_print_page_path($file_name, "blob", $hash_base);
5669         print "<div class=\"page_body\">\n";
5670         if ($mimetype =~ m!^image/!) {
5671                 print qq!<img type="$mimetype"!;
5672                 if ($file_name) {
5673                         print qq! alt="$file_name" title="$file_name"!;
5674                 }
5675                 print qq! src="! .
5676                       href(action=>"blob_plain", hash=>$hash,
5677                            hash_base=>$hash_base, file_name=>$file_name) .
5678                       qq!" />\n!;
5679         } else {
5680                 my $nr;
5681                 while (my $line = <$fd>) {
5682                         chomp $line;
5683                         $nr++;
5684                         $line = untabify($line);
5685                         printf qq!<div class="pre"><a id="l%i" href="%s#l%i" class="linenr">%4i</a> %s</div>\n!,
5686                                $nr, href(-replay => 1), $nr, $nr, $syntax ? $line : esc_html($line, -nbsp=>1);
5687                 }
5688         }
5689         close $fd
5690                 or print "Reading blob failed.\n";
5691         print "</div>";
5692         git_footer_html();
5693 }
5694
5695 sub git_tree {
5696         if (!defined $hash_base) {
5697                 $hash_base = "HEAD";
5698         }
5699         if (!defined $hash) {
5700                 if (defined $file_name) {
5701                         $hash = git_get_hash_by_path($hash_base, $file_name, "tree");
5702                 } else {
5703                         $hash = $hash_base;
5704                 }
5705         }
5706         die_error(404, "No such tree") unless defined($hash);
5707
5708         my $show_sizes = gitweb_check_feature('show-sizes');
5709         my $have_blame = gitweb_check_feature('blame');
5710
5711         my @entries = ();
5712         {
5713                 local $/ = "\0";
5714                 open my $fd, "-|", git_cmd(), "ls-tree", '-z',
5715                         ($show_sizes ? '-l' : ()), @extra_options, $hash
5716                         or die_error(500, "Open git-ls-tree failed");
5717                 @entries = map { chomp; $_ } <$fd>;
5718                 close $fd
5719                         or die_error(404, "Reading tree failed");
5720         }
5721
5722         my $refs = git_get_references();
5723         my $ref = format_ref_marker($refs, $hash_base);
5724         git_header_html();
5725         my $basedir = '';
5726         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
5727                 my @views_nav = ();
5728                 if (defined $file_name) {
5729                         push @views_nav,
5730                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
5731                                         "history"),
5732                                 $cgi->a({-href => href(action=>"tree",
5733                                                        hash_base=>"HEAD", file_name=>$file_name)},
5734                                         "HEAD"),
5735                 }
5736                 my $snapshot_links = format_snapshot_links($hash);
5737                 if (defined $snapshot_links) {
5738                         # FIXME: Should be available when we have no hash base as well.
5739                         push @views_nav, $snapshot_links;
5740                 }
5741                 git_print_page_nav('tree','', $hash_base, undef, undef,
5742                                    join(' | ', @views_nav));
5743                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash_base);
5744         } else {
5745                 undef $hash_base;
5746                 print "<div class=\"page_nav\">\n";
5747                 print "<br/><br/></div>\n";
5748                 print "<div class=\"title\">$hash</div>\n";
5749         }
5750         if (defined $file_name) {
5751                 $basedir = $file_name;
5752                 if ($basedir ne '' && substr($basedir, -1) ne '/') {
5753                         $basedir .= '/';
5754                 }
5755                 git_print_page_path($file_name, 'tree', $hash_base);
5756         }
5757         print "<div class=\"page_body\">\n";
5758         print "<table class=\"tree\">\n";
5759         my $alternate = 1;
5760         # '..' (top directory) link if possible
5761         if (defined $hash_base &&
5762             defined $file_name && $file_name =~ m![^/]+$!) {
5763                 if ($alternate) {
5764                         print "<tr class=\"dark\">\n";
5765                 } else {
5766                         print "<tr class=\"light\">\n";
5767                 }
5768                 $alternate ^= 1;
5769
5770                 my $up = $file_name;
5771                 $up =~ s!/?[^/]+$!!;
5772                 undef $up unless $up;
5773                 # based on git_print_tree_entry
5774                 print '<td class="mode">' . mode_str('040000') . "</td>\n";
5775                 print '<td class="size">&nbsp;</td>'."\n" if $show_sizes;
5776                 print '<td class="list">';
5777                 print $cgi->a({-href => href(action=>"tree",
5778                                              hash_base=>$hash_base,
5779                                              file_name=>$up)},
5780                               "..");
5781                 print "</td>\n";
5782                 print "<td class=\"link\"></td>\n";
5783
5784                 print "</tr>\n";
5785         }
5786         foreach my $line (@entries) {
5787                 my %t = parse_ls_tree_line($line, -z => 1, -l => $show_sizes);
5788
5789                 if ($alternate) {
5790                         print "<tr class=\"dark\">\n";
5791                 } else {
5792                         print "<tr class=\"light\">\n";
5793                 }
5794                 $alternate ^= 1;
5795
5796                 git_print_tree_entry(\%t, $basedir, $hash_base, $have_blame);
5797
5798                 print "</tr>\n";
5799         }
5800         print "</table>\n" .
5801               "</div>";
5802         git_footer_html();
5803 }
5804
5805 sub snapshot_name {
5806         my ($project, $hash) = @_;
5807
5808         # path/to/project.git  -> project
5809         # path/to/project/.git -> project
5810         my $name = to_utf8($project);
5811         $name =~ s,([^/])/*\.git$,$1,;
5812         $name = basename($name);
5813         # sanitize name
5814         $name =~ s/[[:cntrl:]]/?/g;
5815
5816         my $ver = $hash;
5817         if ($hash =~ /^[0-9a-fA-F]+$/) {
5818                 # shorten SHA-1 hash
5819                 my $full_hash = git_get_full_hash($project, $hash);
5820                 if ($full_hash =~ /^$hash/ && length($hash) > 7) {
5821                         $ver = git_get_short_hash($project, $hash);
5822                 }
5823         } elsif ($hash =~ m!^refs/tags/(.*)$!) {
5824                 # tags don't need shortened SHA-1 hash
5825                 $ver = $1;
5826         } else {
5827                 # branches and other need shortened SHA-1 hash
5828                 if ($hash =~ m!^refs/(?:heads|remotes)/(.*)$!) {
5829                         $ver = $1;
5830                 }
5831                 $ver .= '-' . git_get_short_hash($project, $hash);
5832         }
5833         # in case of hierarchical branch names
5834         $ver =~ s!/!.!g;
5835
5836         # name = project-version_string
5837         $name = "$name-$ver";
5838
5839         return wantarray ? ($name, $name) : $name;
5840 }
5841
5842 sub git_snapshot {
5843         my $format = $input_params{'snapshot_format'};
5844         if (!@snapshot_fmts) {
5845                 die_error(403, "Snapshots not allowed");
5846         }
5847         # default to first supported snapshot format
5848         $format ||= $snapshot_fmts[0];
5849         if ($format !~ m/^[a-z0-9]+$/) {
5850                 die_error(400, "Invalid snapshot format parameter");
5851         } elsif (!exists($known_snapshot_formats{$format})) {
5852                 die_error(400, "Unknown snapshot format");
5853         } elsif ($known_snapshot_formats{$format}{'disabled'}) {
5854                 die_error(403, "Snapshot format not allowed");
5855         } elsif (!grep($_ eq $format, @snapshot_fmts)) {
5856                 die_error(403, "Unsupported snapshot format");
5857         }
5858
5859         my $type = git_get_type("$hash^{}");
5860         if (!$type) {
5861                 die_error(404, 'Object does not exist');
5862         }  elsif ($type eq 'blob') {
5863                 die_error(400, 'Object is not a tree-ish');
5864         }
5865
5866         my ($name, $prefix) = snapshot_name($project, $hash);
5867         my $filename = "$name$known_snapshot_formats{$format}{'suffix'}";
5868         my $cmd = quote_command(
5869                 git_cmd(), 'archive',
5870                 "--format=$known_snapshot_formats{$format}{'format'}",
5871                 "--prefix=$prefix/", $hash);
5872         if (exists $known_snapshot_formats{$format}{'compressor'}) {
5873                 $cmd .= ' | ' . quote_command(@{$known_snapshot_formats{$format}{'compressor'}});
5874         }
5875
5876         $filename =~ s/(["\\])/\\$1/g;
5877         print $cgi->header(
5878                 -type => $known_snapshot_formats{$format}{'type'},
5879                 -content_disposition => 'inline; filename="' . $filename . '"',
5880                 -status => '200 OK');
5881
5882         open my $fd, "-|", $cmd
5883                 or die_error(500, "Execute git-archive failed");
5884         binmode STDOUT, ':raw';
5885         print <$fd>;
5886         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
5887         close $fd;
5888 }
5889
5890 sub git_log_generic {
5891         my ($fmt_name, $body_subr, $base, $parent, $file_name, $file_hash) = @_;
5892
5893         my $head = git_get_head_hash($project);
5894         if (!defined $base) {
5895                 $base = $head;
5896         }
5897         if (!defined $page) {
5898                 $page = 0;
5899         }
5900         my $refs = git_get_references();
5901
5902         my $commit_hash = $base;
5903         if (defined $parent) {
5904                 $commit_hash = "$parent..$base";
5905         }
5906         my @commitlist =
5907                 parse_commits($commit_hash, 101, (100 * $page),
5908                               defined $file_name ? ($file_name, "--full-history") : ());
5909
5910         my $ftype;
5911         if (!defined $file_hash && defined $file_name) {
5912                 # some commits could have deleted file in question,
5913                 # and not have it in tree, but one of them has to have it
5914                 for (my $i = 0; $i < @commitlist; $i++) {
5915                         $file_hash = git_get_hash_by_path($commitlist[$i]{'id'}, $file_name);
5916                         last if defined $file_hash;
5917                 }
5918         }
5919         if (defined $file_hash) {
5920                 $ftype = git_get_type($file_hash);
5921         }
5922         if (defined $file_name && !defined $ftype) {
5923                 die_error(500, "Unknown type of object");
5924         }
5925         my %co;
5926         if (defined $file_name) {
5927                 %co = parse_commit($base)
5928                         or die_error(404, "Unknown commit object");
5929         }
5930
5931
5932         my $paging_nav = format_paging_nav($fmt_name, $page, $#commitlist >= 100);
5933         my $next_link = '';
5934         if ($#commitlist >= 100) {
5935                 $next_link =
5936                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
5937                                  -accesskey => "n", -title => "Alt-n"}, "next");
5938         }
5939         my $patch_max = gitweb_get_feature('patches');
5940         if ($patch_max && !defined $file_name) {
5941                 if ($patch_max < 0 || @commitlist <= $patch_max) {
5942                         $paging_nav .= " &sdot; " .
5943                                 $cgi->a({-href => href(action=>"patches", -replay=>1)},
5944                                         "patches");
5945                 }
5946         }
5947
5948         git_header_html();
5949         git_print_page_nav($fmt_name,'', $hash,$hash,$hash, $paging_nav);
5950         if (defined $file_name) {
5951                 git_print_header_div('commit', esc_html($co{'title'}), $base);
5952         } else {
5953                 git_print_header_div('summary', $project)
5954         }
5955         git_print_page_path($file_name, $ftype, $hash_base)
5956                 if (defined $file_name);
5957
5958         $body_subr->(\@commitlist, 0, 99, $refs, $next_link,
5959                      $file_name, $file_hash, $ftype);
5960
5961         git_footer_html();
5962 }
5963
5964 sub git_log {
5965         git_log_generic('log', \&git_log_body,
5966                         $hash, $hash_parent);
5967 }
5968
5969 sub git_commit {
5970         $hash ||= $hash_base || "HEAD";
5971         my %co = parse_commit($hash)
5972             or die_error(404, "Unknown commit object");
5973
5974         my $parent  = $co{'parent'};
5975         my $parents = $co{'parents'}; # listref
5976
5977         # we need to prepare $formats_nav before any parameter munging
5978         my $formats_nav;
5979         if (!defined $parent) {
5980                 # --root commitdiff
5981                 $formats_nav .= '(initial)';
5982         } elsif (@$parents == 1) {
5983                 # single parent commit
5984                 $formats_nav .=
5985                         '(parent: ' .
5986                         $cgi->a({-href => href(action=>"commit",
5987                                                hash=>$parent)},
5988                                 esc_html(substr($parent, 0, 7))) .
5989                         ')';
5990         } else {
5991                 # merge commit
5992                 $formats_nav .=
5993                         '(merge: ' .
5994                         join(' ', map {
5995                                 $cgi->a({-href => href(action=>"commit",
5996                                                        hash=>$_)},
5997                                         esc_html(substr($_, 0, 7)));
5998                         } @$parents ) .
5999                         ')';
6000         }
6001         if (gitweb_check_feature('patches') && @$parents <= 1) {
6002                 $formats_nav .= " | " .
6003                         $cgi->a({-href => href(action=>"patch", -replay=>1)},
6004                                 "patch");
6005         }
6006
6007         if (!defined $parent) {
6008                 $parent = "--root";
6009         }
6010         my @difftree;
6011         open my $fd, "-|", git_cmd(), "diff-tree", '-r', "--no-commit-id",
6012                 @diff_opts,
6013                 (@$parents <= 1 ? $parent : '-c'),
6014                 $hash, "--"
6015                 or die_error(500, "Open git-diff-tree failed");
6016         @difftree = map { chomp; $_ } <$fd>;
6017         close $fd or die_error(404, "Reading git-diff-tree failed");
6018
6019         # non-textual hash id's can be cached
6020         my $expires;
6021         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6022                 $expires = "+1d";
6023         }
6024         my $refs = git_get_references();
6025         my $ref = format_ref_marker($refs, $co{'id'});
6026
6027         git_header_html(undef, $expires);
6028         git_print_page_nav('commit', '',
6029                            $hash, $co{'tree'}, $hash,
6030                            $formats_nav);
6031
6032         if (defined $co{'parent'}) {
6033                 git_print_header_div('commitdiff', esc_html($co{'title'}) . $ref, $hash);
6034         } else {
6035                 git_print_header_div('tree', esc_html($co{'title'}) . $ref, $co{'tree'}, $hash);
6036         }
6037         print "<div class=\"title_text\">\n" .
6038               "<table class=\"object_header\">\n";
6039         git_print_authorship_rows(\%co);
6040         print "<tr><td>commit</td><td class=\"sha1\">$co{'id'}</td></tr>\n";
6041         print "<tr>" .
6042               "<td>tree</td>" .
6043               "<td class=\"sha1\">" .
6044               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash),
6045                        class => "list"}, $co{'tree'}) .
6046               "</td>" .
6047               "<td class=\"link\">" .
6048               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash)},
6049                       "tree");
6050         my $snapshot_links = format_snapshot_links($hash);
6051         if (defined $snapshot_links) {
6052                 print " | " . $snapshot_links;
6053         }
6054         print "</td>" .
6055               "</tr>\n";
6056
6057         foreach my $par (@$parents) {
6058                 print "<tr>" .
6059                       "<td>parent</td>" .
6060                       "<td class=\"sha1\">" .
6061                       $cgi->a({-href => href(action=>"commit", hash=>$par),
6062                                class => "list"}, $par) .
6063                       "</td>" .
6064                       "<td class=\"link\">" .
6065                       $cgi->a({-href => href(action=>"commit", hash=>$par)}, "commit") .
6066                       " | " .
6067                       $cgi->a({-href => href(action=>"commitdiff", hash=>$hash, hash_parent=>$par)}, "diff") .
6068                       "</td>" .
6069                       "</tr>\n";
6070         }
6071         print "</table>".
6072               "</div>\n";
6073
6074         print "<div class=\"page_body\">\n";
6075         git_print_log($co{'comment'});
6076         print "</div>\n";
6077
6078         git_difftree_body(\@difftree, $hash, @$parents);
6079
6080         git_footer_html();
6081 }
6082
6083 sub git_object {
6084         # object is defined by:
6085         # - hash or hash_base alone
6086         # - hash_base and file_name
6087         my $type;
6088
6089         # - hash or hash_base alone
6090         if ($hash || ($hash_base && !defined $file_name)) {
6091                 my $object_id = $hash || $hash_base;
6092
6093                 open my $fd, "-|", quote_command(
6094                         git_cmd(), 'cat-file', '-t', $object_id) . ' 2> /dev/null'
6095                         or die_error(404, "Object does not exist");
6096                 $type = <$fd>;
6097                 chomp $type;
6098                 close $fd
6099                         or die_error(404, "Object does not exist");
6100
6101         # - hash_base and file_name
6102         } elsif ($hash_base && defined $file_name) {
6103                 $file_name =~ s,/+$,,;
6104
6105                 system(git_cmd(), "cat-file", '-e', $hash_base) == 0
6106                         or die_error(404, "Base object does not exist");
6107
6108                 # here errors should not hapen
6109                 open my $fd, "-|", git_cmd(), "ls-tree", $hash_base, "--", $file_name
6110                         or die_error(500, "Open git-ls-tree failed");
6111                 my $line = <$fd>;
6112                 close $fd;
6113
6114                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
6115                 unless ($line && $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/) {
6116                         die_error(404, "File or directory for given base does not exist");
6117                 }
6118                 $type = $2;
6119                 $hash = $3;
6120         } else {
6121                 die_error(400, "Not enough information to find object");
6122         }
6123
6124         print $cgi->redirect(-uri => href(action=>$type, -full=>1,
6125                                           hash=>$hash, hash_base=>$hash_base,
6126                                           file_name=>$file_name),
6127                              -status => '302 Found');
6128 }
6129
6130 sub git_blobdiff {
6131         my $format = shift || 'html';
6132
6133         my $fd;
6134         my @difftree;
6135         my %diffinfo;
6136         my $expires;
6137
6138         # preparing $fd and %diffinfo for git_patchset_body
6139         # new style URI
6140         if (defined $hash_base && defined $hash_parent_base) {
6141                 if (defined $file_name) {
6142                         # read raw output
6143                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6144                                 $hash_parent_base, $hash_base,
6145                                 "--", (defined $file_parent ? $file_parent : ()), $file_name
6146                                 or die_error(500, "Open git-diff-tree failed");
6147                         @difftree = map { chomp; $_ } <$fd>;
6148                         close $fd
6149                                 or die_error(404, "Reading git-diff-tree failed");
6150                         @difftree
6151                                 or die_error(404, "Blob diff not found");
6152
6153                 } elsif (defined $hash &&
6154                          $hash =~ /[0-9a-fA-F]{40}/) {
6155                         # try to find filename from $hash
6156
6157                         # read filtered raw output
6158                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6159                                 $hash_parent_base, $hash_base, "--"
6160                                 or die_error(500, "Open git-diff-tree failed");
6161                         @difftree =
6162                                 # ':100644 100644 03b21826... 3b93d5e7... M     ls-files.c'
6163                                 # $hash == to_id
6164                                 grep { /^:[0-7]{6} [0-7]{6} [0-9a-fA-F]{40} $hash/ }
6165                                 map { chomp; $_ } <$fd>;
6166                         close $fd
6167                                 or die_error(404, "Reading git-diff-tree failed");
6168                         @difftree
6169                                 or die_error(404, "Blob diff not found");
6170
6171                 } else {
6172                         die_error(400, "Missing one of the blob diff parameters");
6173                 }
6174
6175                 if (@difftree > 1) {
6176                         die_error(400, "Ambiguous blob diff specification");
6177                 }
6178
6179                 %diffinfo = parse_difftree_raw_line($difftree[0]);
6180                 $file_parent ||= $diffinfo{'from_file'} || $file_name;
6181                 $file_name   ||= $diffinfo{'to_file'};
6182
6183                 $hash_parent ||= $diffinfo{'from_id'};
6184                 $hash        ||= $diffinfo{'to_id'};
6185
6186                 # non-textual hash id's can be cached
6187                 if ($hash_base =~ m/^[0-9a-fA-F]{40}$/ &&
6188                     $hash_parent_base =~ m/^[0-9a-fA-F]{40}$/) {
6189                         $expires = '+1d';
6190                 }
6191
6192                 # open patch output
6193                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6194                         '-p', ($format eq 'html' ? "--full-index" : ()),
6195                         $hash_parent_base, $hash_base,
6196                         "--", (defined $file_parent ? $file_parent : ()), $file_name
6197                         or die_error(500, "Open git-diff-tree failed");
6198         }
6199
6200         # old/legacy style URI -- not generated anymore since 1.4.3.
6201         if (!%diffinfo) {
6202                 die_error('404 Not Found', "Missing one of the blob diff parameters")
6203         }
6204
6205         # header
6206         if ($format eq 'html') {
6207                 my $formats_nav =
6208                         $cgi->a({-href => href(action=>"blobdiff_plain", -replay=>1)},
6209                                 "raw");
6210                 git_header_html(undef, $expires);
6211                 if (defined $hash_base && (my %co = parse_commit($hash_base))) {
6212                         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6213                         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6214                 } else {
6215                         print "<div class=\"page_nav\"><br/>$formats_nav<br/></div>\n";
6216                         print "<div class=\"title\">$hash vs $hash_parent</div>\n";
6217                 }
6218                 if (defined $file_name) {
6219                         git_print_page_path($file_name, "blob", $hash_base);
6220                 } else {
6221                         print "<div class=\"page_path\"></div>\n";
6222                 }
6223
6224         } elsif ($format eq 'plain') {
6225                 print $cgi->header(
6226                         -type => 'text/plain',
6227                         -charset => 'utf-8',
6228                         -expires => $expires,
6229                         -content_disposition => 'inline; filename="' . "$file_name" . '.patch"');
6230
6231                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
6232
6233         } else {
6234                 die_error(400, "Unknown blobdiff format");
6235         }
6236
6237         # patch
6238         if ($format eq 'html') {
6239                 print "<div class=\"page_body\">\n";
6240
6241                 git_patchset_body($fd, [ \%diffinfo ], $hash_base, $hash_parent_base);
6242                 close $fd;
6243
6244                 print "</div>\n"; # class="page_body"
6245                 git_footer_html();
6246
6247         } else {
6248                 while (my $line = <$fd>) {
6249                         $line =~ s!a/($hash|$hash_parent)!'a/'.esc_path($diffinfo{'from_file'})!eg;
6250                         $line =~ s!b/($hash|$hash_parent)!'b/'.esc_path($diffinfo{'to_file'})!eg;
6251
6252                         print $line;
6253
6254                         last if $line =~ m!^\+\+\+!;
6255                 }
6256                 local $/ = undef;
6257                 print <$fd>;
6258                 close $fd;
6259         }
6260 }
6261
6262 sub git_blobdiff_plain {
6263         git_blobdiff('plain');
6264 }
6265
6266 sub git_commitdiff {
6267         my %params = @_;
6268         my $format = $params{-format} || 'html';
6269
6270         my ($patch_max) = gitweb_get_feature('patches');
6271         if ($format eq 'patch') {
6272                 die_error(403, "Patch view not allowed") unless $patch_max;
6273         }
6274
6275         $hash ||= $hash_base || "HEAD";
6276         my %co = parse_commit($hash)
6277             or die_error(404, "Unknown commit object");
6278
6279         # choose format for commitdiff for merge
6280         if (! defined $hash_parent && @{$co{'parents'}} > 1) {
6281                 $hash_parent = '--cc';
6282         }
6283         # we need to prepare $formats_nav before almost any parameter munging
6284         my $formats_nav;
6285         if ($format eq 'html') {
6286                 $formats_nav =
6287                         $cgi->a({-href => href(action=>"commitdiff_plain", -replay=>1)},
6288                                 "raw");
6289                 if ($patch_max && @{$co{'parents'}} <= 1) {
6290                         $formats_nav .= " | " .
6291                                 $cgi->a({-href => href(action=>"patch", -replay=>1)},
6292                                         "patch");
6293                 }
6294
6295                 if (defined $hash_parent &&
6296                     $hash_parent ne '-c' && $hash_parent ne '--cc') {
6297                         # commitdiff with two commits given
6298                         my $hash_parent_short = $hash_parent;
6299                         if ($hash_parent =~ m/^[0-9a-fA-F]{40}$/) {
6300                                 $hash_parent_short = substr($hash_parent, 0, 7);
6301                         }
6302                         $formats_nav .=
6303                                 ' (from';
6304                         for (my $i = 0; $i < @{$co{'parents'}}; $i++) {
6305                                 if ($co{'parents'}[$i] eq $hash_parent) {
6306                                         $formats_nav .= ' parent ' . ($i+1);
6307                                         last;
6308                                 }
6309                         }
6310                         $formats_nav .= ': ' .
6311                                 $cgi->a({-href => href(action=>"commitdiff",
6312                                                        hash=>$hash_parent)},
6313                                         esc_html($hash_parent_short)) .
6314                                 ')';
6315                 } elsif (!$co{'parent'}) {
6316                         # --root commitdiff
6317                         $formats_nav .= ' (initial)';
6318                 } elsif (scalar @{$co{'parents'}} == 1) {
6319                         # single parent commit
6320                         $formats_nav .=
6321                                 ' (parent: ' .
6322                                 $cgi->a({-href => href(action=>"commitdiff",
6323                                                        hash=>$co{'parent'})},
6324                                         esc_html(substr($co{'parent'}, 0, 7))) .
6325                                 ')';
6326                 } else {
6327                         # merge commit
6328                         if ($hash_parent eq '--cc') {
6329                                 $formats_nav .= ' | ' .
6330                                         $cgi->a({-href => href(action=>"commitdiff",
6331                                                                hash=>$hash, hash_parent=>'-c')},
6332                                                 'combined');
6333                         } else { # $hash_parent eq '-c'
6334                                 $formats_nav .= ' | ' .
6335                                         $cgi->a({-href => href(action=>"commitdiff",
6336                                                                hash=>$hash, hash_parent=>'--cc')},
6337                                                 'compact');
6338                         }
6339                         $formats_nav .=
6340                                 ' (merge: ' .
6341                                 join(' ', map {
6342                                         $cgi->a({-href => href(action=>"commitdiff",
6343                                                                hash=>$_)},
6344                                                 esc_html(substr($_, 0, 7)));
6345                                 } @{$co{'parents'}} ) .
6346                                 ')';
6347                 }
6348         }
6349
6350         my $hash_parent_param = $hash_parent;
6351         if (!defined $hash_parent_param) {
6352                 # --cc for multiple parents, --root for parentless
6353                 $hash_parent_param =
6354                         @{$co{'parents'}} > 1 ? '--cc' : $co{'parent'} || '--root';
6355         }
6356
6357         # read commitdiff
6358         my $fd;
6359         my @difftree;
6360         if ($format eq 'html') {
6361                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6362                         "--no-commit-id", "--patch-with-raw", "--full-index",
6363                         $hash_parent_param, $hash, "--"
6364                         or die_error(500, "Open git-diff-tree failed");
6365
6366                 while (my $line = <$fd>) {
6367                         chomp $line;
6368                         # empty line ends raw part of diff-tree output
6369                         last unless $line;
6370                         push @difftree, scalar parse_difftree_raw_line($line);
6371                 }
6372
6373         } elsif ($format eq 'plain') {
6374                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6375                         '-p', $hash_parent_param, $hash, "--"
6376                         or die_error(500, "Open git-diff-tree failed");
6377         } elsif ($format eq 'patch') {
6378                 # For commit ranges, we limit the output to the number of
6379                 # patches specified in the 'patches' feature.
6380                 # For single commits, we limit the output to a single patch,
6381                 # diverging from the git-format-patch default.
6382                 my @commit_spec = ();
6383                 if ($hash_parent) {
6384                         if ($patch_max > 0) {
6385                                 push @commit_spec, "-$patch_max";
6386                         }
6387                         push @commit_spec, '-n', "$hash_parent..$hash";
6388                 } else {
6389                         if ($params{-single}) {
6390                                 push @commit_spec, '-1';
6391                         } else {
6392                                 if ($patch_max > 0) {
6393                                         push @commit_spec, "-$patch_max";
6394                                 }
6395                                 push @commit_spec, "-n";
6396                         }
6397                         push @commit_spec, '--root', $hash;
6398                 }
6399                 open $fd, "-|", git_cmd(), "format-patch", @diff_opts,
6400                         '--encoding=utf8', '--stdout', @commit_spec
6401                         or die_error(500, "Open git-format-patch failed");
6402         } else {
6403                 die_error(400, "Unknown commitdiff format");
6404         }
6405
6406         # non-textual hash id's can be cached
6407         my $expires;
6408         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6409                 $expires = "+1d";
6410         }
6411
6412         # write commit message
6413         if ($format eq 'html') {
6414                 my $refs = git_get_references();
6415                 my $ref = format_ref_marker($refs, $co{'id'});
6416
6417                 git_header_html(undef, $expires);
6418                 git_print_page_nav('commitdiff','', $hash,$co{'tree'},$hash, $formats_nav);
6419                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash);
6420                 print "<div class=\"title_text\">\n" .
6421                       "<table class=\"object_header\">\n";
6422                 git_print_authorship_rows(\%co);
6423                 print "</table>".
6424                       "</div>\n";
6425                 print "<div class=\"page_body\">\n";
6426                 if (@{$co{'comment'}} > 1) {
6427                         print "<div class=\"log\">\n";
6428                         git_print_log($co{'comment'}, -final_empty_line=> 1, -remove_title => 1);
6429                         print "</div>\n"; # class="log"
6430                 }
6431
6432         } elsif ($format eq 'plain') {
6433                 my $refs = git_get_references("tags");
6434                 my $tagname = git_get_rev_name_tags($hash);
6435                 my $filename = basename($project) . "-$hash.patch";
6436
6437                 print $cgi->header(
6438                         -type => 'text/plain',
6439                         -charset => 'utf-8',
6440                         -expires => $expires,
6441                         -content_disposition => 'inline; filename="' . "$filename" . '"');
6442                 my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
6443                 print "From: " . to_utf8($co{'author'}) . "\n";
6444                 print "Date: $ad{'rfc2822'} ($ad{'tz_local'})\n";
6445                 print "Subject: " . to_utf8($co{'title'}) . "\n";
6446
6447                 print "X-Git-Tag: $tagname\n" if $tagname;
6448                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
6449
6450                 foreach my $line (@{$co{'comment'}}) {
6451                         print to_utf8($line) . "\n";
6452                 }
6453                 print "---\n\n";
6454         } elsif ($format eq 'patch') {
6455                 my $filename = basename($project) . "-$hash.patch";
6456
6457                 print $cgi->header(
6458                         -type => 'text/plain',
6459                         -charset => 'utf-8',
6460                         -expires => $expires,
6461                         -content_disposition => 'inline; filename="' . "$filename" . '"');
6462         }
6463
6464         # write patch
6465         if ($format eq 'html') {
6466                 my $use_parents = !defined $hash_parent ||
6467                         $hash_parent eq '-c' || $hash_parent eq '--cc';
6468                 git_difftree_body(\@difftree, $hash,
6469                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
6470                 print "<br/>\n";
6471
6472                 git_patchset_body($fd, \@difftree, $hash,
6473                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
6474                 close $fd;
6475                 print "</div>\n"; # class="page_body"
6476                 git_footer_html();
6477
6478         } elsif ($format eq 'plain') {
6479                 local $/ = undef;
6480                 print <$fd>;
6481                 close $fd
6482                         or print "Reading git-diff-tree failed\n";
6483         } elsif ($format eq 'patch') {
6484                 local $/ = undef;
6485                 print <$fd>;
6486                 close $fd
6487                         or print "Reading git-format-patch failed\n";
6488         }
6489 }
6490
6491 sub git_commitdiff_plain {
6492         git_commitdiff(-format => 'plain');
6493 }
6494
6495 # format-patch-style patches
6496 sub git_patch {
6497         git_commitdiff(-format => 'patch', -single => 1);
6498 }
6499
6500 sub git_patches {
6501         git_commitdiff(-format => 'patch');
6502 }
6503
6504 sub git_history {
6505         git_log_generic('history', \&git_history_body,
6506                         $hash_base, $hash_parent_base,
6507                         $file_name, $hash);
6508 }
6509
6510 sub git_search {
6511         gitweb_check_feature('search') or die_error(403, "Search is disabled");
6512         if (!defined $searchtext) {
6513                 die_error(400, "Text field is empty");
6514         }
6515         if (!defined $hash) {
6516                 $hash = git_get_head_hash($project);
6517         }
6518         my %co = parse_commit($hash);
6519         if (!%co) {
6520                 die_error(404, "Unknown commit object");
6521         }
6522         if (!defined $page) {
6523                 $page = 0;
6524         }
6525
6526         $searchtype ||= 'commit';
6527         if ($searchtype eq 'pickaxe') {
6528                 # pickaxe may take all resources of your box and run for several minutes
6529                 # with every query - so decide by yourself how public you make this feature
6530                 gitweb_check_feature('pickaxe')
6531                     or die_error(403, "Pickaxe is disabled");
6532         }
6533         if ($searchtype eq 'grep') {
6534                 gitweb_check_feature('grep')[0]
6535                     or die_error(403, "Grep is disabled");
6536         }
6537
6538         git_header_html();
6539
6540         if ($searchtype eq 'commit' or $searchtype eq 'author' or $searchtype eq 'committer') {
6541                 my $greptype;
6542                 if ($searchtype eq 'commit') {
6543                         $greptype = "--grep=";
6544                 } elsif ($searchtype eq 'author') {
6545                         $greptype = "--author=";
6546                 } elsif ($searchtype eq 'committer') {
6547                         $greptype = "--committer=";
6548                 }
6549                 $greptype .= $searchtext;
6550                 my @commitlist = parse_commits($hash, 101, (100 * $page), undef,
6551                                                $greptype, '--regexp-ignore-case',
6552                                                $search_use_regexp ? '--extended-regexp' : '--fixed-strings');
6553
6554                 my $paging_nav = '';
6555                 if ($page > 0) {
6556                         $paging_nav .=
6557                                 $cgi->a({-href => href(action=>"search", hash=>$hash,
6558                                                        searchtext=>$searchtext,
6559                                                        searchtype=>$searchtype)},
6560                                         "first");
6561                         $paging_nav .= " &sdot; " .
6562                                 $cgi->a({-href => href(-replay=>1, page=>$page-1),
6563                                          -accesskey => "p", -title => "Alt-p"}, "prev");
6564                 } else {
6565                         $paging_nav .= "first";
6566                         $paging_nav .= " &sdot; prev";
6567                 }
6568                 my $next_link = '';
6569                 if ($#commitlist >= 100) {
6570                         $next_link =
6571                                 $cgi->a({-href => href(-replay=>1, page=>$page+1),
6572                                          -accesskey => "n", -title => "Alt-n"}, "next");
6573                         $paging_nav .= " &sdot; $next_link";
6574                 } else {
6575                         $paging_nav .= " &sdot; next";
6576                 }
6577
6578                 git_print_page_nav('','', $hash,$co{'tree'},$hash, $paging_nav);
6579                 git_print_header_div('commit', esc_html($co{'title'}), $hash);
6580                 if ($page == 0 && !@commitlist) {
6581                         print "<p>No match.</p>\n";
6582                 } else {
6583                         git_search_grep_body(\@commitlist, 0, 99, $next_link);
6584                 }
6585         }
6586
6587         if ($searchtype eq 'pickaxe') {
6588                 git_print_page_nav('','', $hash,$co{'tree'},$hash);
6589                 git_print_header_div('commit', esc_html($co{'title'}), $hash);
6590
6591                 print "<table class=\"pickaxe search\">\n";
6592                 my $alternate = 1;
6593                 local $/ = "\n";
6594                 open my $fd, '-|', git_cmd(), '--no-pager', 'log', @diff_opts,
6595                         '--pretty=format:%H', '--no-abbrev', '--raw', "-S$searchtext",
6596                         ($search_use_regexp ? '--pickaxe-regex' : ());
6597                 undef %co;
6598                 my @files;
6599                 while (my $line = <$fd>) {
6600                         chomp $line;
6601                         next unless $line;
6602
6603                         my %set = parse_difftree_raw_line($line);
6604                         if (defined $set{'commit'}) {
6605                                 # finish previous commit
6606                                 if (%co) {
6607                                         print "</td>\n" .
6608                                               "<td class=\"link\">" .
6609                                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
6610                                               " | " .
6611                                               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
6612                                         print "</td>\n" .
6613                                               "</tr>\n";
6614                                 }
6615
6616                                 if ($alternate) {
6617                                         print "<tr class=\"dark\">\n";
6618                                 } else {
6619                                         print "<tr class=\"light\">\n";
6620                                 }
6621                                 $alternate ^= 1;
6622                                 %co = parse_commit($set{'commit'});
6623                                 my $author = chop_and_escape_str($co{'author_name'}, 15, 5);
6624                                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6625                                       "<td><i>$author</i></td>\n" .
6626                                       "<td>" .
6627                                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
6628                                               -class => "list subject"},
6629                                               chop_and_escape_str($co{'title'}, 50) . "<br/>");
6630                         } elsif (defined $set{'to_id'}) {
6631                                 next if ($set{'to_id'} =~ m/^0{40}$/);
6632
6633                                 print $cgi->a({-href => href(action=>"blob", hash_base=>$co{'id'},
6634                                                              hash=>$set{'to_id'}, file_name=>$set{'to_file'}),
6635                                               -class => "list"},
6636                                               "<span class=\"match\">" . esc_path($set{'file'}) . "</span>") .
6637                                       "<br/>\n";
6638                         }
6639                 }
6640                 close $fd;
6641
6642                 # finish last commit (warning: repetition!)
6643                 if (%co) {
6644                         print "</td>\n" .
6645                               "<td class=\"link\">" .
6646                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
6647                               " | " .
6648                               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
6649                         print "</td>\n" .
6650                               "</tr>\n";
6651                 }
6652
6653                 print "</table>\n";
6654         }
6655
6656         if ($searchtype eq 'grep') {
6657                 git_print_page_nav('','', $hash,$co{'tree'},$hash);
6658                 git_print_header_div('commit', esc_html($co{'title'}), $hash);
6659
6660                 print "<table class=\"grep_search\">\n";
6661                 my $alternate = 1;
6662                 my $matches = 0;
6663                 local $/ = "\n";
6664                 open my $fd, "-|", git_cmd(), 'grep', '-n',
6665                         $search_use_regexp ? ('-E', '-i') : '-F',
6666                         $searchtext, $co{'tree'};
6667                 my $lastfile = '';
6668                 while (my $line = <$fd>) {
6669                         chomp $line;
6670                         my ($file, $lno, $ltext, $binary);
6671                         last if ($matches++ > 1000);
6672                         if ($line =~ /^Binary file (.+) matches$/) {
6673                                 $file = $1;
6674                                 $binary = 1;
6675                         } else {
6676                                 (undef, $file, $lno, $ltext) = split(/:/, $line, 4);
6677                         }
6678                         if ($file ne $lastfile) {
6679                                 $lastfile and print "</td></tr>\n";
6680                                 if ($alternate++) {
6681                                         print "<tr class=\"dark\">\n";
6682                                 } else {
6683                                         print "<tr class=\"light\">\n";
6684                                 }
6685                                 print "<td class=\"list\">".
6686                                         $cgi->a({-href => href(action=>"blob", hash=>$co{'hash'},
6687                                                                file_name=>"$file"),
6688                                                 -class => "list"}, esc_path($file));
6689                                 print "</td><td>\n";
6690                                 $lastfile = $file;
6691                         }
6692                         if ($binary) {
6693                                 print "<div class=\"binary\">Binary file</div>\n";
6694                         } else {
6695                                 $ltext = untabify($ltext);
6696                                 if ($ltext =~ m/^(.*)($search_regexp)(.*)$/i) {
6697                                         $ltext = esc_html($1, -nbsp=>1);
6698                                         $ltext .= '<span class="match">';
6699                                         $ltext .= esc_html($2, -nbsp=>1);
6700                                         $ltext .= '</span>';
6701                                         $ltext .= esc_html($3, -nbsp=>1);
6702                                 } else {
6703                                         $ltext = esc_html($ltext, -nbsp=>1);
6704                                 }
6705                                 print "<div class=\"pre\">" .
6706                                         $cgi->a({-href => href(action=>"blob", hash=>$co{'hash'},
6707                                                                file_name=>"$file").'#l'.$lno,
6708                                                 -class => "linenr"}, sprintf('%4i', $lno))
6709                                         . ' ' .  $ltext . "</div>\n";
6710                         }
6711                 }
6712                 if ($lastfile) {
6713                         print "</td></tr>\n";
6714                         if ($matches > 1000) {
6715                                 print "<div class=\"diff nodifferences\">Too many matches, listing trimmed</div>\n";
6716                         }
6717                 } else {
6718                         print "<div class=\"diff nodifferences\">No matches found</div>\n";
6719                 }
6720                 close $fd;
6721
6722                 print "</table>\n";
6723         }
6724         git_footer_html();
6725 }
6726
6727 sub git_search_help {
6728         git_header_html();
6729         git_print_page_nav('','', $hash,$hash,$hash);
6730         print <<EOT;
6731 <p><strong>Pattern</strong> is by default a normal string that is matched precisely (but without
6732 regard to case, except in the case of pickaxe). However, when you check the <em>re</em> checkbox,
6733 the pattern entered is recognized as the POSIX extended
6734 <a href="http://en.wikipedia.org/wiki/Regular_expression">regular expression</a> (also case
6735 insensitive).</p>
6736 <dl>
6737 <dt><b>commit</b></dt>
6738 <dd>The commit messages and authorship information will be scanned for the given pattern.</dd>
6739 EOT
6740         my $have_grep = gitweb_check_feature('grep');
6741         if ($have_grep) {
6742                 print <<EOT;
6743 <dt><b>grep</b></dt>
6744 <dd>All files in the currently selected tree (HEAD unless you are explicitly browsing
6745     a different one) are searched for the given pattern. On large trees, this search can take
6746 a while and put some strain on the server, so please use it with some consideration. Note that
6747 due to git-grep peculiarity, currently if regexp mode is turned off, the matches are
6748 case-sensitive.</dd>
6749 EOT
6750         }
6751         print <<EOT;
6752 <dt><b>author</b></dt>
6753 <dd>Name and e-mail of the change author and date of birth of the patch will be scanned for the given pattern.</dd>
6754 <dt><b>committer</b></dt>
6755 <dd>Name and e-mail of the committer and date of commit will be scanned for the given pattern.</dd>
6756 EOT
6757         my $have_pickaxe = gitweb_check_feature('pickaxe');
6758         if ($have_pickaxe) {
6759                 print <<EOT;
6760 <dt><b>pickaxe</b></dt>
6761 <dd>All commits that caused the string to appear or disappear from any file (changes that
6762 added, removed or "modified" the string) will be listed. This search can take a while and
6763 takes a lot of strain on the server, so please use it wisely. Note that since you may be
6764 interested even in changes just changing the case as well, this search is case sensitive.</dd>
6765 EOT
6766         }
6767         print "</dl>\n";
6768         git_footer_html();
6769 }
6770
6771 sub git_shortlog {
6772         git_log_generic('shortlog', \&git_shortlog_body,
6773                         $hash, $hash_parent);
6774 }
6775
6776 ## ......................................................................
6777 ## feeds (RSS, Atom; OPML)
6778
6779 sub git_feed {
6780         my $format = shift || 'atom';
6781         my $have_blame = gitweb_check_feature('blame');
6782
6783         # Atom: http://www.atomenabled.org/developers/syndication/
6784         # RSS:  http://www.notestips.com/80256B3A007F2692/1/NAMO5P9UPQ
6785         if ($format ne 'rss' && $format ne 'atom') {
6786                 die_error(400, "Unknown web feed format");
6787         }
6788
6789         # log/feed of current (HEAD) branch, log of given branch, history of file/directory
6790         my $head = $hash || 'HEAD';
6791         my @commitlist = parse_commits($head, 150, 0, $file_name);
6792
6793         my %latest_commit;
6794         my %latest_date;
6795         my $content_type = "application/$format+xml";
6796         if (defined $cgi->http('HTTP_ACCEPT') &&
6797                  $cgi->Accept('text/xml') > $cgi->Accept($content_type)) {
6798                 # browser (feed reader) prefers text/xml
6799                 $content_type = 'text/xml';
6800         }
6801         if (defined($commitlist[0])) {
6802                 %latest_commit = %{$commitlist[0]};
6803                 my $latest_epoch = $latest_commit{'committer_epoch'};
6804                 %latest_date   = parse_date($latest_epoch);
6805                 my $if_modified = $cgi->http('IF_MODIFIED_SINCE');
6806                 if (defined $if_modified) {
6807                         my $since;
6808                         if (eval { require HTTP::Date; 1; }) {
6809                                 $since = HTTP::Date::str2time($if_modified);
6810                         } elsif (eval { require Time::ParseDate; 1; }) {
6811                                 $since = Time::ParseDate::parsedate($if_modified, GMT => 1);
6812                         }
6813                         if (defined $since && $latest_epoch <= $since) {
6814                                 print $cgi->header(
6815                                         -type => $content_type,
6816                                         -charset => 'utf-8',
6817                                         -last_modified => $latest_date{'rfc2822'},
6818                                         -status => '304 Not Modified');
6819                                 return;
6820                         }
6821                 }
6822                 print $cgi->header(
6823                         -type => $content_type,
6824                         -charset => 'utf-8',
6825                         -last_modified => $latest_date{'rfc2822'});
6826         } else {
6827                 print $cgi->header(
6828                         -type => $content_type,
6829                         -charset => 'utf-8');
6830         }
6831
6832         # Optimization: skip generating the body if client asks only
6833         # for Last-Modified date.
6834         return if ($cgi->request_method() eq 'HEAD');
6835
6836         # header variables
6837         my $title = "$site_name - $project/$action";
6838         my $feed_type = 'log';
6839         if (defined $hash) {
6840                 $title .= " - '$hash'";
6841                 $feed_type = 'branch log';
6842                 if (defined $file_name) {
6843                         $title .= " :: $file_name";
6844                         $feed_type = 'history';
6845                 }
6846         } elsif (defined $file_name) {
6847                 $title .= " - $file_name";
6848                 $feed_type = 'history';
6849         }
6850         $title .= " $feed_type";
6851         my $descr = git_get_project_description($project);
6852         if (defined $descr) {
6853                 $descr = esc_html($descr);
6854         } else {
6855                 $descr = "$project " .
6856                          ($format eq 'rss' ? 'RSS' : 'Atom') .
6857                          " feed";
6858         }
6859         my $owner = git_get_project_owner($project);
6860         $owner = esc_html($owner);
6861
6862         #header
6863         my $alt_url;
6864         if (defined $file_name) {
6865                 $alt_url = href(-full=>1, action=>"history", hash=>$hash, file_name=>$file_name);
6866         } elsif (defined $hash) {
6867                 $alt_url = href(-full=>1, action=>"log", hash=>$hash);
6868         } else {
6869                 $alt_url = href(-full=>1, action=>"summary");
6870         }
6871         print qq!<?xml version="1.0" encoding="utf-8"?>\n!;
6872         if ($format eq 'rss') {
6873                 print <<XML;
6874 <rss version="2.0" xmlns:content="http://purl.org/rss/1.0/modules/content/">
6875 <channel>
6876 XML
6877                 print "<title>$title</title>\n" .
6878                       "<link>$alt_url</link>\n" .
6879                       "<description>$descr</description>\n" .
6880                       "<language>en</language>\n" .
6881                       # project owner is responsible for 'editorial' content
6882                       "<managingEditor>$owner</managingEditor>\n";
6883                 if (defined $logo || defined $favicon) {
6884                         # prefer the logo to the favicon, since RSS
6885                         # doesn't allow both
6886                         my $img = esc_url($logo || $favicon);
6887                         print "<image>\n" .
6888                               "<url>$img</url>\n" .
6889                               "<title>$title</title>\n" .
6890                               "<link>$alt_url</link>\n" .
6891                               "</image>\n";
6892                 }
6893                 if (%latest_date) {
6894                         print "<pubDate>$latest_date{'rfc2822'}</pubDate>\n";
6895                         print "<lastBuildDate>$latest_date{'rfc2822'}</lastBuildDate>\n";
6896                 }
6897                 print "<generator>gitweb v.$version/$git_version</generator>\n";
6898         } elsif ($format eq 'atom') {
6899                 print <<XML;
6900 <feed xmlns="http://www.w3.org/2005/Atom">
6901 XML
6902                 print "<title>$title</title>\n" .
6903                       "<subtitle>$descr</subtitle>\n" .
6904                       '<link rel="alternate" type="text/html" href="' .
6905                       $alt_url . '" />' . "\n" .
6906                       '<link rel="self" type="' . $content_type . '" href="' .
6907                       $cgi->self_url() . '" />' . "\n" .
6908                       "<id>" . href(-full=>1) . "</id>\n" .
6909                       # use project owner for feed author
6910                       "<author><name>$owner</name></author>\n";
6911                 if (defined $favicon) {
6912                         print "<icon>" . esc_url($favicon) . "</icon>\n";
6913                 }
6914                 if (defined $logo_url) {
6915                         # not twice as wide as tall: 72 x 27 pixels
6916                         print "<logo>" . esc_url($logo) . "</logo>\n";
6917                 }
6918                 if (! %latest_date) {
6919                         # dummy date to keep the feed valid until commits trickle in:
6920                         print "<updated>1970-01-01T00:00:00Z</updated>\n";
6921                 } else {
6922                         print "<updated>$latest_date{'iso-8601'}</updated>\n";
6923                 }
6924                 print "<generator version='$version/$git_version'>gitweb</generator>\n";
6925         }
6926
6927         # contents
6928         for (my $i = 0; $i <= $#commitlist; $i++) {
6929                 my %co = %{$commitlist[$i]};
6930                 my $commit = $co{'id'};
6931                 # we read 150, we always show 30 and the ones more recent than 48 hours
6932                 if (($i >= 20) && ((time - $co{'author_epoch'}) > 48*60*60)) {
6933                         last;
6934                 }
6935                 my %cd = parse_date($co{'author_epoch'});
6936
6937                 # get list of changed files
6938                 open my $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6939                         $co{'parent'} || "--root",
6940                         $co{'id'}, "--", (defined $file_name ? $file_name : ())
6941                         or next;
6942                 my @difftree = map { chomp; $_ } <$fd>;
6943                 close $fd
6944                         or next;
6945
6946                 # print element (entry, item)
6947                 my $co_url = href(-full=>1, action=>"commitdiff", hash=>$commit);
6948                 if ($format eq 'rss') {
6949                         print "<item>\n" .
6950                               "<title>" . esc_html($co{'title'}) . "</title>\n" .
6951                               "<author>" . esc_html($co{'author'}) . "</author>\n" .
6952                               "<pubDate>$cd{'rfc2822'}</pubDate>\n" .
6953                               "<guid isPermaLink=\"true\">$co_url</guid>\n" .
6954                               "<link>$co_url</link>\n" .
6955                               "<description>" . esc_html($co{'title'}) . "</description>\n" .
6956                               "<content:encoded>" .
6957                               "<![CDATA[\n";
6958                 } elsif ($format eq 'atom') {
6959                         print "<entry>\n" .
6960                               "<title type=\"html\">" . esc_html($co{'title'}) . "</title>\n" .
6961                               "<updated>$cd{'iso-8601'}</updated>\n" .
6962                               "<author>\n" .
6963                               "  <name>" . esc_html($co{'author_name'}) . "</name>\n";
6964                         if ($co{'author_email'}) {
6965                                 print "  <email>" . esc_html($co{'author_email'}) . "</email>\n";
6966                         }
6967                         print "</author>\n" .
6968                               # use committer for contributor
6969                               "<contributor>\n" .
6970                               "  <name>" . esc_html($co{'committer_name'}) . "</name>\n";
6971                         if ($co{'committer_email'}) {
6972                                 print "  <email>" . esc_html($co{'committer_email'}) . "</email>\n";
6973                         }
6974                         print "</contributor>\n" .
6975                               "<published>$cd{'iso-8601'}</published>\n" .
6976                               "<link rel=\"alternate\" type=\"text/html\" href=\"$co_url\" />\n" .
6977                               "<id>$co_url</id>\n" .
6978                               "<content type=\"xhtml\" xml:base=\"" . esc_url($my_url) . "\">\n" .
6979                               "<div xmlns=\"http://www.w3.org/1999/xhtml\">\n";
6980                 }
6981                 my $comment = $co{'comment'};
6982                 print "<pre>\n";
6983                 foreach my $line (@$comment) {
6984                         $line = esc_html($line);
6985                         print "$line\n";
6986                 }
6987                 print "</pre><ul>\n";
6988                 foreach my $difftree_line (@difftree) {
6989                         my %difftree = parse_difftree_raw_line($difftree_line);
6990                         next if !$difftree{'from_id'};
6991
6992                         my $file = $difftree{'file'} || $difftree{'to_file'};
6993
6994                         print "<li>" .
6995                               "[" .
6996                               $cgi->a({-href => href(-full=>1, action=>"blobdiff",
6997                                                      hash=>$difftree{'to_id'}, hash_parent=>$difftree{'from_id'},
6998                                                      hash_base=>$co{'id'}, hash_parent_base=>$co{'parent'},
6999                                                      file_name=>$file, file_parent=>$difftree{'from_file'}),
7000                                       -title => "diff"}, 'D');
7001                         if ($have_blame) {
7002                                 print $cgi->a({-href => href(-full=>1, action=>"blame",
7003                                                              file_name=>$file, hash_base=>$commit),
7004                                               -title => "blame"}, 'B');
7005                         }
7006                         # if this is not a feed of a file history
7007                         if (!defined $file_name || $file_name ne $file) {
7008                                 print $cgi->a({-href => href(-full=>1, action=>"history",
7009                                                              file_name=>$file, hash=>$commit),
7010                                               -title => "history"}, 'H');
7011                         }
7012                         $file = esc_path($file);
7013                         print "] ".
7014                               "$file</li>\n";
7015                 }
7016                 if ($format eq 'rss') {
7017                         print "</ul>]]>\n" .
7018                               "</content:encoded>\n" .
7019                               "</item>\n";
7020                 } elsif ($format eq 'atom') {
7021                         print "</ul>\n</div>\n" .
7022                               "</content>\n" .
7023                               "</entry>\n";
7024                 }
7025         }
7026
7027         # end of feed
7028         if ($format eq 'rss') {
7029                 print "</channel>\n</rss>\n";
7030         } elsif ($format eq 'atom') {
7031                 print "</feed>\n";
7032         }
7033 }
7034
7035 sub git_rss {
7036         git_feed('rss');
7037 }
7038
7039 sub git_atom {
7040         git_feed('atom');
7041 }
7042
7043 sub git_opml {
7044         my @list = git_get_projects_list();
7045
7046         print $cgi->header(
7047                 -type => 'text/xml',
7048                 -charset => 'utf-8',
7049                 -content_disposition => 'inline; filename="opml.xml"');
7050
7051         print <<XML;
7052 <?xml version="1.0" encoding="utf-8"?>
7053 <opml version="1.0">
7054 <head>
7055   <title>$site_name OPML Export</title>
7056 </head>
7057 <body>
7058 <outline text="git RSS feeds">
7059 XML
7060
7061         foreach my $pr (@list) {
7062                 my %proj = %$pr;
7063                 my $head = git_get_head_hash($proj{'path'});
7064                 if (!defined $head) {
7065                         next;
7066                 }
7067                 $git_dir = "$projectroot/$proj{'path'}";
7068                 my %co = parse_commit($head);
7069                 if (!%co) {
7070                         next;
7071                 }
7072
7073                 my $path = esc_html(chop_str($proj{'path'}, 25, 5));
7074                 my $rss  = href('project' => $proj{'path'}, 'action' => 'rss', -full => 1);
7075                 my $html = href('project' => $proj{'path'}, 'action' => 'summary', -full => 1);
7076                 print "<outline type=\"rss\" text=\"$path\" title=\"$path\" xmlUrl=\"$rss\" htmlUrl=\"$html\"/>\n";
7077         }
7078         print <<XML;
7079 </outline>
7080 </body>
7081 </opml>
7082 XML
7083 }