Lady’s Gitweb - Gitweb/blob - gitweb.perl

   1 #!/usr/bin/perl
   2
   3 # gitweb - simple web interface to track changes in git repositories
   4 #
   5 # (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
   6 # (C) 2005, Christian Gierke
   7 #
   8 # This program is licensed under the GPLv2
   9
  10 use strict;
  11 use warnings;
  12 use CGI qw(:standard :escapeHTML -nosticky);
  13 use CGI::Util qw(unescape);
  14 use CGI::Carp qw(fatalsToBrowser);
  15 use Encode;
  16 use Fcntl ':mode';
  17 use File::Find qw();
  18 use File::Basename qw(basename);
  19 binmode STDOUT, ':utf8';
  20
  21 our $cgi = new CGI;
  22 our $version = "++GIT_VERSION++";
  23 our $my_url = $cgi->url();
  24 our $my_uri = $cgi->url(-absolute => 1);
  25
  26 # core git executable to use
  27 # this can just be "git" if your webserver has a sensible PATH
  28 our $GIT = "++GIT_BINDIR++/git";
  29
  30 # absolute fs-path which will be prepended to the project path
  31 #our $projectroot = "/pub/scm";
  32 our $projectroot = "++GITWEB_PROJECTROOT++";
  33
  34 # target of the home link on top of all pages
  35 our $home_link = $my_uri || "/";
  36
  37 # string of the home link on top of all pages
  38 our $home_link_str = "++GITWEB_HOME_LINK_STR++";
  39
  40 # name of your site or organization to appear in page titles
  41 # replace this with something more descriptive for clearer bookmarks
  42 our $site_name = "++GITWEB_SITENAME++"
  43                  || ($ENV{'SERVER_NAME'} || "Untitled") . " Git";
  44
  45 # filename of html text to include at top of each page
  46 our $site_header = "++GITWEB_SITE_HEADER++";
  47 # html text to include at home page
  48 our $home_text = "++GITWEB_HOMETEXT++";
  49 # filename of html text to include at bottom of each page
  50 our $site_footer = "++GITWEB_SITE_FOOTER++";
  51
  52 # URI of stylesheets
  53 our @stylesheets = ("++GITWEB_CSS++");
  54 # URI of a single stylesheet, which can be overridden in GITWEB_CONFIG.
  55 our $stylesheet = undef;
  56
  57 # URI of GIT logo (72x27 size)
  58 our $logo = "++GITWEB_LOGO++";
  59 # URI of GIT favicon, assumed to be image/png type
  60 our $favicon = "++GITWEB_FAVICON++";
  61
  62 # URI and label (title) of GIT logo link
  63 #our $logo_url = "http://www.kernel.org/pub/software/scm/git/docs/";
  64 #our $logo_label = "git documentation";
  65 our $logo_url = "http://git.or.cz/";
  66 our $logo_label = "git homepage";
  67
  68 # source of projects list
  69 our $projects_list = "++GITWEB_LIST++";
  70
  71 # show repository only if this file exists
  72 # (only effective if this variable evaluates to true)
  73 our $export_ok = "++GITWEB_EXPORT_OK++";
  74
  75 # only allow viewing of repositories also shown on the overview page
  76 our $strict_export = "++GITWEB_STRICT_EXPORT++";
  77
  78 # list of git base URLs used for URL to where fetch project from,
  79 # i.e. full URL is "$git_base_url/$project"
  80 our @git_base_url_list = grep { $_ ne '' } ("++GITWEB_BASE_URL++");
  81
  82 # default blob_plain mimetype and default charset for text/plain blob
  83 our $default_blob_plain_mimetype = 'text/plain';
  84 our $default_text_plain_charset  = undef;
  85
  86 # file to use for guessing MIME types before trying /etc/mime.types
  87 # (relative to the current git repository)
  88 our $mimetypes_file = undef;
  89
  90 # You define site-wide feature defaults here; override them with
  91 # $GITWEB_CONFIG as necessary.
  92 our %feature = (
  93         # feature => {
  94         #       'sub' => feature-sub (subroutine),
  95         #       'override' => allow-override (boolean),
  96         #       'default' => [ default options...] (array reference)}
  97         #
  98         # if feature is overridable (it means that allow-override has true value,
  99         # then feature-sub will be called with default options as parameters;
 100         # return value of feature-sub indicates if to enable specified feature
 101         #
 102         # use gitweb_check_feature(<feature>) to check if <feature> is enabled
 103
 104         # Enable the 'blame' blob view, showing the last commit that modified
 105         # each line in the file. This can be very CPU-intensive.
 106
 107         # To enable system wide have in $GITWEB_CONFIG
 108         # $feature{'blame'}{'default'} = [1];
 109         # To have project specific config enable override in $GITWEB_CONFIG
 110         # $feature{'blame'}{'override'} = 1;
 111         # and in project config gitweb.blame = 0|1;
 112         'blame' => {
 113                 'sub' => \&feature_blame,
 114                 'override' => 0,
 115                 'default' => [0]},
 116
 117         # Enable the 'snapshot' link, providing a compressed tarball of any
 118         # tree. This can potentially generate high traffic if you have large
 119         # project.
 120
 121         # To disable system wide have in $GITWEB_CONFIG
 122         # $feature{'snapshot'}{'default'} = [undef];
 123         # To have project specific config enable override in $GITWEB_CONFIG
 124         # $feature{'blame'}{'override'} = 1;
 125         # and in project config gitweb.snapshot = none|gzip|bzip2;
 126         'snapshot' => {
 127                 'sub' => \&feature_snapshot,
 128                 'override' => 0,
 129                 #         => [content-encoding, suffix, program]
 130                 'default' => ['x-gzip', 'gz', 'gzip']},
 131
 132         # Enable the pickaxe search, which will list the commits that modified
 133         # a given string in a file. This can be practical and quite faster
 134         # alternative to 'blame', but still potentially CPU-intensive.
 135
 136         # To enable system wide have in $GITWEB_CONFIG
 137         # $feature{'pickaxe'}{'default'} = [1];
 138         # To have project specific config enable override in $GITWEB_CONFIG
 139         # $feature{'pickaxe'}{'override'} = 1;
 140         # and in project config gitweb.pickaxe = 0|1;
 141         'pickaxe' => {
 142                 'sub' => \&feature_pickaxe,
 143                 'override' => 0,
 144                 'default' => [1]},
 145
 146         # Make gitweb use an alternative format of the URLs which can be
 147         # more readable and natural-looking: project name is embedded
 148         # directly in the path and the query string contains other
 149         # auxiliary information. All gitweb installations recognize
 150         # URL in either format; this configures in which formats gitweb
 151         # generates links.
 152
 153         # To enable system wide have in $GITWEB_CONFIG
 154         # $feature{'pathinfo'}{'default'} = [1];
 155         # Project specific override is not supported.
 156
 157         # Note that you will need to change the default location of CSS,
 158         # favicon, logo and possibly other files to an absolute URL. Also,
 159         # if gitweb.cgi serves as your indexfile, you will need to force
 160         # $my_uri to contain the script name in your $GITWEB_CONFIG.
 161         'pathinfo' => {
 162                 'override' => 0,
 163                 'default' => [0]},
 164
 165         # Make gitweb consider projects in project root subdirectories
 166         # to be forks of existing projects. Given project $projname.git,
 167         # projects matching $projname/*.git will not be shown in the main
 168         # projects list, instead a '+' mark will be added to $projname
 169         # there and a 'forks' view will be enabled for the project, listing
 170         # all the forks. This feature is supported only if project list
 171         # is taken from a directory, not file.
 172
 173         # To enable system wide have in $GITWEB_CONFIG
 174         # $feature{'forks'}{'default'} = [1];
 175         # Project specific override is not supported.
 176         'forks' => {
 177                 'override' => 0,
 178                 'default' => [0]},
 179 );
 180
 181 sub gitweb_check_feature {
 182         my ($name) = @_;
 183         return unless exists $feature{$name};
 184         my ($sub, $override, @defaults) = (
 185                 $feature{$name}{'sub'},
 186                 $feature{$name}{'override'},
 187                 @{$feature{$name}{'default'}});
 188         if (!$override) { return @defaults; }
 189         if (!defined $sub) {
 190                 warn "feature $name is not overrideable";
 191                 return @defaults;
 192         }
 193         return $sub->(@defaults);
 194 }
 195
 196 sub feature_blame {
 197         my ($val) = git_get_project_config('blame', '--bool');
 198
 199         if ($val eq 'true') {
 200                 return 1;
 201         } elsif ($val eq 'false') {
 202                 return 0;
 203         }
 204
 205         return $_[0];
 206 }
 207
 208 sub feature_snapshot {
 209         my ($ctype, $suffix, $command) = @_;
 210
 211         my ($val) = git_get_project_config('snapshot');
 212
 213         if ($val eq 'gzip') {
 214                 return ('x-gzip', 'gz', 'gzip');
 215         } elsif ($val eq 'bzip2') {
 216                 return ('x-bzip2', 'bz2', 'bzip2');
 217         } elsif ($val eq 'none') {
 218                 return ();
 219         }
 220
 221         return ($ctype, $suffix, $command);
 222 }
 223
 224 sub gitweb_have_snapshot {
 225         my ($ctype, $suffix, $command) = gitweb_check_feature('snapshot');
 226         my $have_snapshot = (defined $ctype && defined $suffix);
 227
 228         return $have_snapshot;
 229 }
 230
 231 sub feature_pickaxe {
 232         my ($val) = git_get_project_config('pickaxe', '--bool');
 233
 234         if ($val eq 'true') {
 235                 return (1);
 236         } elsif ($val eq 'false') {
 237                 return (0);
 238         }
 239
 240         return ($_[0]);
 241 }
 242
 243 # checking HEAD file with -e is fragile if the repository was
 244 # initialized long time ago (i.e. symlink HEAD) and was pack-ref'ed
 245 # and then pruned.
 246 sub check_head_link {
 247         my ($dir) = @_;
 248         my $headfile = "$dir/HEAD";
 249         return ((-e $headfile) ||
 250                 (-l $headfile && readlink($headfile) =~ /^refs\/heads\//));
 251 }
 252
 253 sub check_export_ok {
 254         my ($dir) = @_;
 255         return (check_head_link($dir) &&
 256                 (!$export_ok || -e "$dir/$export_ok"));
 257 }
 258
 259 # rename detection options for git-diff and git-diff-tree
 260 # - default is '-M', with the cost proportional to
 261 #   (number of removed files) * (number of new files).
 262 # - more costly is '-C' (or '-C', '-M'), with the cost proportional to
 263 #   (number of changed files + number of removed files) * (number of new files)
 264 # - even more costly is '-C', '--find-copies-harder' with cost
 265 #   (number of files in the original tree) * (number of new files)
 266 # - one might want to include '-B' option, e.g. '-B', '-M'
 267 our @diff_opts = ('-M'); # taken from git_commit
 268
 269 our $GITWEB_CONFIG = $ENV{'GITWEB_CONFIG'} || "++GITWEB_CONFIG++";
 270 do $GITWEB_CONFIG if -e $GITWEB_CONFIG;
 271
 272 # version of the core git binary
 273 our $git_version = qx($GIT --version) =~ m/git version (.*)$/ ? $1 : "unknown";
 274
 275 $projects_list ||= $projectroot;
 276
 277 # ======================================================================
 278 # input validation and dispatch
 279 our $action = $cgi->param('a');
 280 if (defined $action) {
 281         if ($action =~ m/[^0-9a-zA-Z\.\-_]/) {
 282                 die_error(undef, "Invalid action parameter");
 283         }
 284 }
 285
 286 # parameters which are pathnames
 287 our $project = $cgi->param('p');
 288 if (defined $project) {
 289         if (!validate_pathname($project) ||
 290             !(-d "$projectroot/$project") ||
 291             !check_head_link("$projectroot/$project") ||
 292             ($export_ok && !(-e "$projectroot/$project/$export_ok")) ||
 293             ($strict_export && !project_in_list($project))) {
 294                 undef $project;
 295                 die_error(undef, "No such project");
 296         }
 297 }
 298
 299 our $file_name = $cgi->param('f');
 300 if (defined $file_name) {
 301         if (!validate_pathname($file_name)) {
 302                 die_error(undef, "Invalid file parameter");
 303         }
 304 }
 305
 306 our $file_parent = $cgi->param('fp');
 307 if (defined $file_parent) {
 308         if (!validate_pathname($file_parent)) {
 309                 die_error(undef, "Invalid file parent parameter");
 310         }
 311 }
 312
 313 # parameters which are refnames
 314 our $hash = $cgi->param('h');
 315 if (defined $hash) {
 316         if (!validate_refname($hash)) {
 317                 die_error(undef, "Invalid hash parameter");
 318         }
 319 }
 320
 321 our $hash_parent = $cgi->param('hp');
 322 if (defined $hash_parent) {
 323         if (!validate_refname($hash_parent)) {
 324                 die_error(undef, "Invalid hash parent parameter");
 325         }
 326 }
 327
 328 our $hash_base = $cgi->param('hb');
 329 if (defined $hash_base) {
 330         if (!validate_refname($hash_base)) {
 331                 die_error(undef, "Invalid hash base parameter");
 332         }
 333 }
 334
 335 our $hash_parent_base = $cgi->param('hpb');
 336 if (defined $hash_parent_base) {
 337         if (!validate_refname($hash_parent_base)) {
 338                 die_error(undef, "Invalid hash parent base parameter");
 339         }
 340 }
 341
 342 # other parameters
 343 our $page = $cgi->param('pg');
 344 if (defined $page) {
 345         if ($page =~ m/[^0-9]/) {
 346                 die_error(undef, "Invalid page parameter");
 347         }
 348 }
 349
 350 our $searchtext = $cgi->param('s');
 351 if (defined $searchtext) {
 352         if ($searchtext =~ m/[^a-zA-Z0-9_\.\/\-\+\:\@ ]/) {
 353                 die_error(undef, "Invalid search parameter");
 354         }
 355         $searchtext = quotemeta $searchtext;
 356 }
 357
 358 our $searchtype = $cgi->param('st');
 359 if (defined $searchtype) {
 360         if ($searchtype =~ m/[^a-z]/) {
 361                 die_error(undef, "Invalid searchtype parameter");
 362         }
 363 }
 364
 365 # now read PATH_INFO and use it as alternative to parameters
 366 sub evaluate_path_info {
 367         return if defined $project;
 368         my $path_info = $ENV{"PATH_INFO"};
 369         return if !$path_info;
 370         $path_info =~ s,^/+,,;
 371         return if !$path_info;
 372         # find which part of PATH_INFO is project
 373         $project = $path_info;
 374         $project =~ s,/+$,,;
 375         while ($project && !check_head_link("$projectroot/$project")) {
 376                 $project =~ s,/*[^/]*$,,;
 377         }
 378         # validate project
 379         $project = validate_pathname($project);
 380         if (!$project ||
 381             ($export_ok && !-e "$projectroot/$project/$export_ok") ||
 382             ($strict_export && !project_in_list($project))) {
 383                 undef $project;
 384                 return;
 385         }
 386         # do not change any parameters if an action is given using the query string
 387         return if $action;
 388         $path_info =~ s,^$project/*,,;
 389         my ($refname, $pathname) = split(/:/, $path_info, 2);
 390         if (defined $pathname) {
 391                 # we got "project.git/branch:filename" or "project.git/branch:dir/"
 392                 # we could use git_get_type(branch:pathname), but it needs $git_dir
 393                 $pathname =~ s,^/+,,;
 394                 if (!$pathname || substr($pathname, -1) eq "/") {
 395                         $action  ||= "tree";
 396                         $pathname =~ s,/$,,;
 397                 } else {
 398                         $action  ||= "blob_plain";
 399                 }
 400                 $hash_base ||= validate_refname($refname);
 401                 $file_name ||= validate_pathname($pathname);
 402         } elsif (defined $refname) {
 403                 # we got "project.git/branch"
 404                 $action ||= "shortlog";
 405                 $hash   ||= validate_refname($refname);
 406         }
 407 }
 408 evaluate_path_info();
 409
 410 # path to the current git repository
 411 our $git_dir;
 412 $git_dir = "$projectroot/$project" if $project;
 413
 414 # dispatch
 415 my %actions = (
 416         "blame" => \&git_blame2,
 417         "blobdiff" => \&git_blobdiff,
 418         "blobdiff_plain" => \&git_blobdiff_plain,
 419         "blob" => \&git_blob,
 420         "blob_plain" => \&git_blob_plain,
 421         "commitdiff" => \&git_commitdiff,
 422         "commitdiff_plain" => \&git_commitdiff_plain,
 423         "commit" => \&git_commit,
 424         "forks" => \&git_forks,
 425         "heads" => \&git_heads,
 426         "history" => \&git_history,
 427         "log" => \&git_log,
 428         "rss" => \&git_rss,
 429         "search" => \&git_search,
 430         "search_help" => \&git_search_help,
 431         "shortlog" => \&git_shortlog,
 432         "summary" => \&git_summary,
 433         "tag" => \&git_tag,
 434         "tags" => \&git_tags,
 435         "tree" => \&git_tree,
 436         "snapshot" => \&git_snapshot,
 437         # those below don't need $project
 438         "opml" => \&git_opml,
 439         "project_list" => \&git_project_list,
 440         "project_index" => \&git_project_index,
 441 );
 442
 443 if (defined $project) {
 444         $action ||= 'summary';
 445 } else {
 446         $action ||= 'project_list';
 447 }
 448 if (!defined($actions{$action})) {
 449         die_error(undef, "Unknown action");
 450 }
 451 if ($action !~ m/^(opml|project_list|project_index)$/ &&
 452     !$project) {
 453         die_error(undef, "Project needed");
 454 }
 455 $actions{$action}->();
 456 exit;
 457
 458 ## ======================================================================
 459 ## action links
 460
 461 sub href(%) {
 462         my %params = @_;
 463         my $href = $my_uri;
 464
 465         # XXX: Warning: If you touch this, check the search form for updating,
 466         # too.
 467
 468         my @mapping = (
 469                 project => "p",
 470                 action => "a",
 471                 file_name => "f",
 472                 file_parent => "fp",
 473                 hash => "h",
 474                 hash_parent => "hp",
 475                 hash_base => "hb",
 476                 hash_parent_base => "hpb",
 477                 page => "pg",
 478                 order => "o",
 479                 searchtext => "s",
 480                 searchtype => "st",
 481         );
 482         my %mapping = @mapping;
 483
 484         $params{'project'} = $project unless exists $params{'project'};
 485
 486         my ($use_pathinfo) = gitweb_check_feature('pathinfo');
 487         if ($use_pathinfo) {
 488                 # use PATH_INFO for project name
 489                 $href .= "/$params{'project'}" if defined $params{'project'};
 490                 delete $params{'project'};
 491
 492                 # Summary just uses the project path URL
 493                 if (defined $params{'action'} && $params{'action'} eq 'summary') {
 494                         delete $params{'action'};
 495                 }
 496         }
 497
 498         # now encode the parameters explicitly
 499         my @result = ();
 500         for (my $i = 0; $i < @mapping; $i += 2) {
 501                 my ($name, $symbol) = ($mapping[$i], $mapping[$i+1]);
 502                 if (defined $params{$name}) {
 503                         push @result, $symbol . "=" . esc_param($params{$name});
 504                 }
 505         }
 506         $href .= "?" . join(';', @result) if scalar @result;
 507
 508         return $href;
 509 }
 510
 511
 512 ## ======================================================================
 513 ## validation, quoting/unquoting and escaping
 514
 515 sub validate_pathname {
 516         my $input = shift || return undef;
 517
 518         # no '.' or '..' as elements of path, i.e. no '.' nor '..'
 519         # at the beginning, at the end, and between slashes.
 520         # also this catches doubled slashes
 521         if ($input =~ m!(^|/)(|\.|\.\.)(/|$)!) {
 522                 return undef;
 523         }
 524         # no null characters
 525         if ($input =~ m!\0!) {
 526                 return undef;
 527         }
 528         return $input;
 529 }
 530
 531 sub validate_refname {
 532         my $input = shift || return undef;
 533
 534         # textual hashes are O.K.
 535         if ($input =~ m/^[0-9a-fA-F]{40}$/) {
 536                 return $input;
 537         }
 538         # it must be correct pathname
 539         $input = validate_pathname($input)
 540                 or return undef;
 541         # restrictions on ref name according to git-check-ref-format
 542         if ($input =~ m!(/\.|\.\.|[\000-\040\177 ~^:?*\[]|/$)!) {
 543                 return undef;
 544         }
 545         return $input;
 546 }
 547
 548 # very thin wrapper for decode("utf8", $str, Encode::FB_DEFAULT);
 549 sub to_utf8 {
 550         my $str = shift;
 551         return decode("utf8", $str, Encode::FB_DEFAULT);
 552 }
 553
 554 # quote unsafe chars, but keep the slash, even when it's not
 555 # correct, but quoted slashes look too horrible in bookmarks
 556 sub esc_param {
 557         my $str = shift;
 558         $str =~ s/([^A-Za-z0-9\-_.~()\/:@])/sprintf("%%%02X", ord($1))/eg;
 559         $str =~ s/\+/%2B/g;
 560         $str =~ s/ /\+/g;
 561         return $str;
 562 }
 563
 564 # quote unsafe chars in whole URL, so some charactrs cannot be quoted
 565 sub esc_url {
 566         my $str = shift;
 567         $str =~ s/([^A-Za-z0-9\-_.~();\/;?:@&=])/sprintf("%%%02X", ord($1))/eg;
 568         $str =~ s/\+/%2B/g;
 569         $str =~ s/ /\+/g;
 570         return $str;
 571 }
 572
 573 # replace invalid utf8 character with SUBSTITUTION sequence
 574 sub esc_html ($;%) {
 575         my $str = shift;
 576         my %opts = @_;
 577
 578         $str = to_utf8($str);
 579         $str = escapeHTML($str);
 580         if ($opts{'-nbsp'}) {
 581                 $str =~ s/ /&nbsp;/g;
 582         }
 583         $str =~ s|([[:cntrl:]])|(($1 ne "\t") ? quot_cec($1) : $1)|eg;
 584         return $str;
 585 }
 586
 587 # Make control characterss "printable".
 588 sub quot_cec {
 589         my $cntrl = shift;
 590         my %es = ( # character escape codes, aka escape sequences
 591                    "\t" => '\t',   # tab            (HT)
 592                    "\n" => '\n',   # line feed      (LF)
 593                    "\r" => '\r',   # carrige return (CR)
 594                    "\f" => '\f',   # form feed      (FF)
 595                    "\b" => '\b',   # backspace      (BS)
 596                    "\a" => '\a',   # alarm (bell)   (BEL)
 597                    "\e" => '\e',   # escape         (ESC)
 598                    "\013" => '\v', # vertical tab   (VT)
 599                    "\000" => '\0', # nul character  (NUL)
 600                    );
 601         my $chr = ( (exists $es{$cntrl})
 602                     ? $es{$cntrl}
 603                     : sprintf('\%03o', ord($cntrl)) );
 604         return "<span class=\"cntrl\">$chr</span>";
 605 }
 606
 607 # Alternatively use unicode control pictures codepoints.
 608 sub quot_upr {
 609         my $cntrl = shift;
 610         my $chr = sprintf('&#%04d;', 0x2400+ord($cntrl));
 611         return "<span class=\"cntrl\">$chr</span>";
 612 }
 613
 614 # quote control characters and escape filename to HTML
 615 sub esc_path {
 616         my $str = shift;
 617
 618         $str = esc_html($str);
 619         $str =~ s|([[:cntrl:]])|quot_cec($1)|eg;
 620         return $str;
 621 }
 622
 623 # git may return quoted and escaped filenames
 624 sub unquote {
 625         my $str = shift;
 626
 627         sub unq {
 628                 my $seq = shift;
 629                 my %es = ( # character escape codes, aka escape sequences
 630                         't' => "\t",   # tab            (HT, TAB)
 631                         'n' => "\n",   # newline        (NL)
 632                         'r' => "\r",   # return         (CR)
 633                         'f' => "\f",   # form feed      (FF)
 634                         'b' => "\b",   # backspace      (BS)
 635                         'a' => "\a",   # alarm (bell)   (BEL)
 636                         'e' => "\e",   # escape         (ESC)
 637                         'v' => "\013", # vertical tab   (VT)
 638                 );
 639
 640                 if ($seq =~ m/^[0-7]{1,3}$/) {
 641                         # octal char sequence
 642                         return chr(oct($seq));
 643                 } elsif (exists $es{$seq}) {
 644                         # C escape sequence, aka character escape code
 645                         return $es{$seq}
 646                 }
 647                 # quoted ordinary character
 648                 return $seq;
 649         }
 650
 651         if ($str =~ m/^"(.*)"$/) {
 652                 # needs unquoting
 653                 $str = $1;
 654                 $str =~ s/\\([^0-7]|[0-7]{1,3})/unq($1)/eg;
 655         }
 656         return $str;
 657 }
 658
 659 # escape tabs (convert tabs to spaces)
 660 sub untabify {
 661         my $line = shift;
 662
 663         while ((my $pos = index($line, "\t")) != -1) {
 664                 if (my $count = (8 - ($pos % 8))) {
 665                         my $spaces = ' ' x $count;
 666                         $line =~ s/\t/$spaces/;
 667                 }
 668         }
 669
 670         return $line;
 671 }
 672
 673 sub project_in_list {
 674         my $project = shift;
 675         my @list = git_get_projects_list();
 676         return @list && scalar(grep { $_->{'path'} eq $project } @list);
 677 }
 678
 679 ## ----------------------------------------------------------------------
 680 ## HTML aware string manipulation
 681
 682 sub chop_str {
 683         my $str = shift;
 684         my $len = shift;
 685         my $add_len = shift || 10;
 686
 687         # allow only $len chars, but don't cut a word if it would fit in $add_len
 688         # if it doesn't fit, cut it if it's still longer than the dots we would add
 689         $str =~ m/^(.{0,$len}[^ \/\-_:\.@]{0,$add_len})(.*)/;
 690         my $body = $1;
 691         my $tail = $2;
 692         if (length($tail) > 4) {
 693                 $tail = " ...";
 694                 $body =~ s/&[^;]*$//; # remove chopped character entities
 695         }
 696         return "$body$tail";
 697 }
 698
 699 ## ----------------------------------------------------------------------
 700 ## functions returning short strings
 701
 702 # CSS class for given age value (in seconds)
 703 sub age_class {
 704         my $age = shift;
 705
 706         if ($age < 60*60*2) {
 707                 return "age0";
 708         } elsif ($age < 60*60*24*2) {
 709                 return "age1";
 710         } else {
 711                 return "age2";
 712         }
 713 }
 714
 715 # convert age in seconds to "nn units ago" string
 716 sub age_string {
 717         my $age = shift;
 718         my $age_str;
 719
 720         if ($age > 60*60*24*365*2) {
 721                 $age_str = (int $age/60/60/24/365);
 722                 $age_str .= " years ago";
 723         } elsif ($age > 60*60*24*(365/12)*2) {
 724                 $age_str = int $age/60/60/24/(365/12);
 725                 $age_str .= " months ago";
 726         } elsif ($age > 60*60*24*7*2) {
 727                 $age_str = int $age/60/60/24/7;
 728                 $age_str .= " weeks ago";
 729         } elsif ($age > 60*60*24*2) {
 730                 $age_str = int $age/60/60/24;
 731                 $age_str .= " days ago";
 732         } elsif ($age > 60*60*2) {
 733                 $age_str = int $age/60/60;
 734                 $age_str .= " hours ago";
 735         } elsif ($age > 60*2) {
 736                 $age_str = int $age/60;
 737                 $age_str .= " min ago";
 738         } elsif ($age > 2) {
 739                 $age_str = int $age;
 740                 $age_str .= " sec ago";
 741         } else {
 742                 $age_str .= " right now";
 743         }
 744         return $age_str;
 745 }
 746
 747 # convert file mode in octal to symbolic file mode string
 748 sub mode_str {
 749         my $mode = oct shift;
 750
 751         if (S_ISDIR($mode & S_IFMT)) {
 752                 return 'drwxr-xr-x';
 753         } elsif (S_ISLNK($mode)) {
 754                 return 'lrwxrwxrwx';
 755         } elsif (S_ISREG($mode)) {
 756                 # git cares only about the executable bit
 757                 if ($mode & S_IXUSR) {
 758                         return '-rwxr-xr-x';
 759                 } else {
 760                         return '-rw-r--r--';
 761                 };
 762         } else {
 763                 return '----------';
 764         }
 765 }
 766
 767 # convert file mode in octal to file type string
 768 sub file_type {
 769         my $mode = shift;
 770
 771         if ($mode !~ m/^[0-7]+$/) {
 772                 return $mode;
 773         } else {
 774                 $mode = oct $mode;
 775         }
 776
 777         if (S_ISDIR($mode & S_IFMT)) {
 778                 return "directory";
 779         } elsif (S_ISLNK($mode)) {
 780                 return "symlink";
 781         } elsif (S_ISREG($mode)) {
 782                 return "file";
 783         } else {
 784                 return "unknown";
 785         }
 786 }
 787
 788 # convert file mode in octal to file type description string
 789 sub file_type_long {
 790         my $mode = shift;
 791
 792         if ($mode !~ m/^[0-7]+$/) {
 793                 return $mode;
 794         } else {
 795                 $mode = oct $mode;
 796         }
 797
 798         if (S_ISDIR($mode & S_IFMT)) {
 799                 return "directory";
 800         } elsif (S_ISLNK($mode)) {
 801                 return "symlink";
 802         } elsif (S_ISREG($mode)) {
 803                 if ($mode & S_IXUSR) {
 804                         return "executable";
 805                 } else {
 806                         return "file";
 807                 };
 808         } else {
 809                 return "unknown";
 810         }
 811 }
 812
 813
 814 ## ----------------------------------------------------------------------
 815 ## functions returning short HTML fragments, or transforming HTML fragments
 816 ## which don't beling to other sections
 817
 818 # format line of commit message.
 819 sub format_log_line_html {
 820         my $line = shift;
 821
 822         $line = esc_html($line, -nbsp=>1);
 823         if ($line =~ m/([0-9a-fA-F]{40})/) {
 824                 my $hash_text = $1;
 825                 if (git_get_type($hash_text) eq "commit") {
 826                         my $link =
 827                                 $cgi->a({-href => href(action=>"commit", hash=>$hash_text),
 828                                         -class => "text"}, $hash_text);
 829                         $line =~ s/$hash_text/$link/;
 830                 }
 831         }
 832         return $line;
 833 }
 834
 835 # format marker of refs pointing to given object
 836 sub format_ref_marker {
 837         my ($refs, $id) = @_;
 838         my $markers = '';
 839
 840         if (defined $refs->{$id}) {
 841                 foreach my $ref (@{$refs->{$id}}) {
 842                         my ($type, $name) = qw();
 843                         # e.g. tags/v2.6.11 or heads/next
 844                         if ($ref =~ m!^(.*?)s?/(.*)$!) {
 845                                 $type = $1;
 846                                 $name = $2;
 847                         } else {
 848                                 $type = "ref";
 849                                 $name = $ref;
 850                         }
 851
 852                         $markers .= " <span class=\"$type\">" . esc_html($name) . "</span>";
 853                 }
 854         }
 855
 856         if ($markers) {
 857                 return ' <span class="refs">'. $markers . '</span>';
 858         } else {
 859                 return "";
 860         }
 861 }
 862
 863 # format, perhaps shortened and with markers, title line
 864 sub format_subject_html {
 865         my ($long, $short, $href, $extra) = @_;
 866         $extra = '' unless defined($extra);
 867
 868         if (length($short) < length($long)) {
 869                 return $cgi->a({-href => $href, -class => "list subject",
 870                                 -title => to_utf8($long)},
 871                        esc_html($short) . $extra);
 872         } else {
 873                 return $cgi->a({-href => $href, -class => "list subject"},
 874                        esc_html($long)  . $extra);
 875         }
 876 }
 877
 878 sub format_diff_line {
 879         my $line = shift;
 880         my $char = substr($line, 0, 1);
 881         my $diff_class = "";
 882
 883         chomp $line;
 884
 885         if ($char eq '+') {
 886                 $diff_class = " add";
 887         } elsif ($char eq "-") {
 888                 $diff_class = " rem";
 889         } elsif ($char eq "@") {
 890                 $diff_class = " chunk_header";
 891         } elsif ($char eq "\\") {
 892                 $diff_class = " incomplete";
 893         }
 894         $line = untabify($line);
 895         return "<div class=\"diff$diff_class\">" . esc_html($line, -nbsp=>1) . "</div>\n";
 896 }
 897
 898 ## ----------------------------------------------------------------------
 899 ## git utility subroutines, invoking git commands
 900
 901 # returns path to the core git executable and the --git-dir parameter as list
 902 sub git_cmd {
 903         return $GIT, '--git-dir='.$git_dir;
 904 }
 905
 906 # returns path to the core git executable and the --git-dir parameter as string
 907 sub git_cmd_str {
 908         return join(' ', git_cmd());
 909 }
 910
 911 # get HEAD ref of given project as hash
 912 sub git_get_head_hash {
 913         my $project = shift;
 914         my $o_git_dir = $git_dir;
 915         my $retval = undef;
 916         $git_dir = "$projectroot/$project";
 917         if (open my $fd, "-|", git_cmd(), "rev-parse", "--verify", "HEAD") {
 918                 my $head = <$fd>;
 919                 close $fd;
 920                 if (defined $head && $head =~ /^([0-9a-fA-F]{40})$/) {
 921                         $retval = $1;
 922                 }
 923         }
 924         if (defined $o_git_dir) {
 925                 $git_dir = $o_git_dir;
 926         }
 927         return $retval;
 928 }
 929
 930 # get type of given object
 931 sub git_get_type {
 932         my $hash = shift;
 933
 934         open my $fd, "-|", git_cmd(), "cat-file", '-t', $hash or return;
 935         my $type = <$fd>;
 936         close $fd or return;
 937         chomp $type;
 938         return $type;
 939 }
 940
 941 sub git_get_project_config {
 942         my ($key, $type) = @_;
 943
 944         return unless ($key);
 945         $key =~ s/^gitweb\.//;
 946         return if ($key =~ m/\W/);
 947
 948         my @x = (git_cmd(), 'repo-config');
 949         if (defined $type) { push @x, $type; }
 950         push @x, "--get";
 951         push @x, "gitweb.$key";
 952         my $val = qx(@x);
 953         chomp $val;
 954         return ($val);
 955 }
 956
 957 # get hash of given path at given ref
 958 sub git_get_hash_by_path {
 959         my $base = shift;
 960         my $path = shift || return undef;
 961         my $type = shift;
 962
 963         $path =~ s,/+$,,;
 964
 965         open my $fd, "-|", git_cmd(), "ls-tree", $base, "--", $path
 966                 or die_error(undef, "Open git-ls-tree failed");
 967         my $line = <$fd>;
 968         close $fd or return undef;
 969
 970         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
 971         $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/;
 972         if (defined $type && $type ne $2) {
 973                 # type doesn't match
 974                 return undef;
 975         }
 976         return $3;
 977 }
 978
 979 ## ......................................................................
 980 ## git utility functions, directly accessing git repository
 981
 982 sub git_get_project_description {
 983         my $path = shift;
 984
 985         open my $fd, "$projectroot/$path/description" or return undef;
 986         my $descr = <$fd>;
 987         close $fd;
 988         chomp $descr;
 989         return $descr;
 990 }
 991
 992 sub git_get_project_url_list {
 993         my $path = shift;
 994
 995         open my $fd, "$projectroot/$path/cloneurl" or return;
 996         my @git_project_url_list = map { chomp; $_ } <$fd>;
 997         close $fd;
 998
 999         return wantarray ? @git_project_url_list : \@git_project_url_list;
1000 }
1001
1002 sub git_get_projects_list {
1003         my ($filter) = @_;
1004         my @list;
1005
1006         $filter ||= '';
1007         $filter =~ s/\.git$//;
1008
1009         if (-d $projects_list) {
1010                 # search in directory
1011                 my $dir = $projects_list . ($filter ? "/$filter" : '');
1012                 # remove the trailing "/"
1013                 $dir =~ s!/+$!!;
1014                 my $pfxlen = length("$dir");
1015
1016                 my ($check_forks) = gitweb_check_feature('forks');
1017
1018                 File::Find::find({
1019                         follow_fast => 1, # follow symbolic links
1020                         dangling_symlinks => 0, # ignore dangling symlinks, silently
1021                         wanted => sub {
1022                                 # skip project-list toplevel, if we get it.
1023                                 return if (m!^[/.]$!);
1024                                 # only directories can be git repositories
1025                                 return unless (-d $_);
1026
1027                                 my $subdir = substr($File::Find::name, $pfxlen + 1);
1028                                 # we check related file in $projectroot
1029                                 if ($check_forks and $subdir =~ m#/.#) {
1030                                         $File::Find::prune = 1;
1031                                 } elsif (check_export_ok("$projectroot/$filter/$subdir")) {
1032                                         push @list, { path => ($filter ? "$filter/" : '') . $subdir };
1033                                         $File::Find::prune = 1;
1034                                 }
1035                         },
1036                 }, "$dir");
1037
1038         } elsif (-f $projects_list) {
1039                 # read from file(url-encoded):
1040                 # 'git%2Fgit.git Linus+Torvalds'
1041                 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
1042                 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
1043                 open my ($fd), $projects_list or return;
1044                 while (my $line = <$fd>) {
1045                         chomp $line;
1046                         my ($path, $owner) = split ' ', $line;
1047                         $path = unescape($path);
1048                         $owner = unescape($owner);
1049                         if (!defined $path) {
1050                                 next;
1051                         }
1052                         if ($filter ne '') {
1053                                 # looking for forks;
1054                                 my $pfx = substr($path, 0, length($filter));
1055                                 if ($pfx ne $filter) {
1056                                         next;
1057                                 }
1058                                 my $sfx = substr($path, length($filter));
1059                                 if ($sfx !~ /^\/.*\.git$/) {
1060                                         next;
1061                                 }
1062                         }
1063                         if (check_export_ok("$projectroot/$path")) {
1064                                 my $pr = {
1065                                         path => $path,
1066                                         owner => to_utf8($owner),
1067                                 };
1068                                 push @list, $pr
1069                         }
1070                 }
1071                 close $fd;
1072         }
1073         @list = sort {$a->{'path'} cmp $b->{'path'}} @list;
1074         return @list;
1075 }
1076
1077 sub git_get_project_owner {
1078         my $project = shift;
1079         my $owner;
1080
1081         return undef unless $project;
1082
1083         # read from file (url-encoded):
1084         # 'git%2Fgit.git Linus+Torvalds'
1085         # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
1086         # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
1087         if (-f $projects_list) {
1088                 open (my $fd , $projects_list);
1089                 while (my $line = <$fd>) {
1090                         chomp $line;
1091                         my ($pr, $ow) = split ' ', $line;
1092                         $pr = unescape($pr);
1093                         $ow = unescape($ow);
1094                         if ($pr eq $project) {
1095                                 $owner = to_utf8($ow);
1096                                 last;
1097                         }
1098                 }
1099                 close $fd;
1100         }
1101         if (!defined $owner) {
1102                 $owner = get_file_owner("$projectroot/$project");
1103         }
1104
1105         return $owner;
1106 }
1107
1108 sub git_get_last_activity {
1109         my ($path) = @_;
1110         my $fd;
1111
1112         $git_dir = "$projectroot/$path";
1113         open($fd, "-|", git_cmd(), 'for-each-ref',
1114              '--format=%(refname) %(committer)',
1115              '--sort=-committerdate',
1116              'refs/heads') or return;
1117         my $most_recent = <$fd>;
1118         close $fd or return;
1119         if ($most_recent =~ / (\d+) [-+][01]\d\d\d$/) {
1120                 my $timestamp = $1;
1121                 my $age = time - $timestamp;
1122                 return ($age, age_string($age));
1123         }
1124 }
1125
1126 sub git_get_references {
1127         my $type = shift || "";
1128         my %refs;
1129         # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c      refs/tags/v2.6.11
1130         # c39ae07f393806ccf406ef966e9a15afc43cc36a      refs/tags/v2.6.11^{}
1131         open my $fd, "-|", $GIT, "peek-remote", "$projectroot/$project/"
1132                 or return;
1133
1134         while (my $line = <$fd>) {
1135                 chomp $line;
1136                 if ($line =~ m/^([0-9a-fA-F]{40})\trefs\/($type\/?[^\^]+)/) {
1137                         if (defined $refs{$1}) {
1138                                 push @{$refs{$1}}, $2;
1139                         } else {
1140                                 $refs{$1} = [ $2 ];
1141                         }
1142                 }
1143         }
1144         close $fd or return;
1145         return \%refs;
1146 }
1147
1148 sub git_get_rev_name_tags {
1149         my $hash = shift || return undef;
1150
1151         open my $fd, "-|", git_cmd(), "name-rev", "--tags", $hash
1152                 or return;
1153         my $name_rev = <$fd>;
1154         close $fd;
1155
1156         if ($name_rev =~ m|^$hash tags/(.*)$|) {
1157                 return $1;
1158         } else {
1159                 # catches also '$hash undefined' output
1160                 return undef;
1161         }
1162 }
1163
1164 ## ----------------------------------------------------------------------
1165 ## parse to hash functions
1166
1167 sub parse_date {
1168         my $epoch = shift;
1169         my $tz = shift || "-0000";
1170
1171         my %date;
1172         my @months = ("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec");
1173         my @days = ("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");
1174         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($epoch);
1175         $date{'hour'} = $hour;
1176         $date{'minute'} = $min;
1177         $date{'mday'} = $mday;
1178         $date{'day'} = $days[$wday];
1179         $date{'month'} = $months[$mon];
1180         $date{'rfc2822'} = sprintf "%s, %d %s %4d %02d:%02d:%02d +0000",
1181                            $days[$wday], $mday, $months[$mon], 1900+$year, $hour ,$min, $sec;
1182         $date{'mday-time'} = sprintf "%d %s %02d:%02d",
1183                              $mday, $months[$mon], $hour ,$min;
1184
1185         $tz =~ m/^([+\-][0-9][0-9])([0-9][0-9])$/;
1186         my $local = $epoch + ((int $1 + ($2/60)) * 3600);
1187         ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($local);
1188         $date{'hour_local'} = $hour;
1189         $date{'minute_local'} = $min;
1190         $date{'tz_local'} = $tz;
1191         $date{'iso-tz'} = sprintf ("%04d-%02d-%02d %02d:%02d:%02d %s",
1192                                    1900+$year, $mon+1, $mday,
1193                                    $hour, $min, $sec, $tz);
1194         return %date;
1195 }
1196
1197 sub parse_tag {
1198         my $tag_id = shift;
1199         my %tag;
1200         my @comment;
1201
1202         open my $fd, "-|", git_cmd(), "cat-file", "tag", $tag_id or return;
1203         $tag{'id'} = $tag_id;
1204         while (my $line = <$fd>) {
1205                 chomp $line;
1206                 if ($line =~ m/^object ([0-9a-fA-F]{40})$/) {
1207                         $tag{'object'} = $1;
1208                 } elsif ($line =~ m/^type (.+)$/) {
1209                         $tag{'type'} = $1;
1210                 } elsif ($line =~ m/^tag (.+)$/) {
1211                         $tag{'name'} = $1;
1212                 } elsif ($line =~ m/^tagger (.*) ([0-9]+) (.*)$/) {
1213                         $tag{'author'} = $1;
1214                         $tag{'epoch'} = $2;
1215                         $tag{'tz'} = $3;
1216                 } elsif ($line =~ m/--BEGIN/) {
1217                         push @comment, $line;
1218                         last;
1219                 } elsif ($line eq "") {
1220                         last;
1221                 }
1222         }
1223         push @comment, <$fd>;
1224         $tag{'comment'} = \@comment;
1225         close $fd or return;
1226         if (!defined $tag{'name'}) {
1227                 return
1228         };
1229         return %tag
1230 }
1231
1232 sub parse_commit {
1233         my $commit_id = shift;
1234         my $commit_text = shift;
1235
1236         my @commit_lines;
1237         my %co;
1238
1239         if (defined $commit_text) {
1240                 @commit_lines = @$commit_text;
1241         } else {
1242                 local $/ = "\0";
1243                 open my $fd, "-|", git_cmd(), "rev-list",
1244                         "--header", "--parents", "--max-count=1",
1245                         $commit_id, "--"
1246                         or return;
1247                 @commit_lines = split '\n', <$fd>;
1248                 close $fd or return;
1249                 pop @commit_lines;
1250         }
1251         my $header = shift @commit_lines;
1252         if (!($header =~ m/^[0-9a-fA-F]{40}/)) {
1253                 return;
1254         }
1255         ($co{'id'}, my @parents) = split ' ', $header;
1256         $co{'parents'} = \@parents;
1257         $co{'parent'} = $parents[0];
1258         while (my $line = shift @commit_lines) {
1259                 last if $line eq "\n";
1260                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
1261                         $co{'tree'} = $1;
1262                 } elsif ($line =~ m/^author (.*) ([0-9]+) (.*)$/) {
1263                         $co{'author'} = $1;
1264                         $co{'author_epoch'} = $2;
1265                         $co{'author_tz'} = $3;
1266                         if ($co{'author'} =~ m/^([^<]+) </) {
1267                                 $co{'author_name'} = $1;
1268                         } else {
1269                                 $co{'author_name'} = $co{'author'};
1270                         }
1271                 } elsif ($line =~ m/^committer (.*) ([0-9]+) (.*)$/) {
1272                         $co{'committer'} = $1;
1273                         $co{'committer_epoch'} = $2;
1274                         $co{'committer_tz'} = $3;
1275                         $co{'committer_name'} = $co{'committer'};
1276                         $co{'committer_name'} =~ s/ <.*//;
1277                 }
1278         }
1279         if (!defined $co{'tree'}) {
1280                 return;
1281         };
1282
1283         foreach my $title (@commit_lines) {
1284                 $title =~ s/^    //;
1285                 if ($title ne "") {
1286                         $co{'title'} = chop_str($title, 80, 5);
1287                         # remove leading stuff of merges to make the interesting part visible
1288                         if (length($title) > 50) {
1289                                 $title =~ s/^Automatic //;
1290                                 $title =~ s/^merge (of|with) /Merge ... /i;
1291                                 if (length($title) > 50) {
1292                                         $title =~ s/(http|rsync):\/\///;
1293                                 }
1294                                 if (length($title) > 50) {
1295                                         $title =~ s/(master|www|rsync)\.//;
1296                                 }
1297                                 if (length($title) > 50) {
1298                                         $title =~ s/kernel.org:?//;
1299                                 }
1300                                 if (length($title) > 50) {
1301                                         $title =~ s/\/pub\/scm//;
1302                                 }
1303                         }
1304                         $co{'title_short'} = chop_str($title, 50, 5);
1305                         last;
1306                 }
1307         }
1308         if ($co{'title'} eq "") {
1309                 $co{'title'} = $co{'title_short'} = '(no commit message)';
1310         }
1311         # remove added spaces
1312         foreach my $line (@commit_lines) {
1313                 $line =~ s/^    //;
1314         }
1315         $co{'comment'} = \@commit_lines;
1316
1317         my $age = time - $co{'committer_epoch'};
1318         $co{'age'} = $age;
1319         $co{'age_string'} = age_string($age);
1320         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($co{'committer_epoch'});
1321         if ($age > 60*60*24*7*2) {
1322                 $co{'age_string_date'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
1323                 $co{'age_string_age'} = $co{'age_string'};
1324         } else {
1325                 $co{'age_string_date'} = $co{'age_string'};
1326                 $co{'age_string_age'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
1327         }
1328         return %co;
1329 }
1330
1331 # parse ref from ref_file, given by ref_id, with given type
1332 sub parse_ref {
1333         my $ref_file = shift;
1334         my $ref_id = shift;
1335         my $type = shift || git_get_type($ref_id);
1336         my %ref_item;
1337
1338         $ref_item{'type'} = $type;
1339         $ref_item{'id'} = $ref_id;
1340         $ref_item{'epoch'} = 0;
1341         $ref_item{'age'} = "unknown";
1342         if ($type eq "tag") {
1343                 my %tag = parse_tag($ref_id);
1344                 $ref_item{'comment'} = $tag{'comment'};
1345                 if ($tag{'type'} eq "commit") {
1346                         my %co = parse_commit($tag{'object'});
1347                         $ref_item{'epoch'} = $co{'committer_epoch'};
1348                         $ref_item{'age'} = $co{'age_string'};
1349                 } elsif (defined($tag{'epoch'})) {
1350                         my $age = time - $tag{'epoch'};
1351                         $ref_item{'epoch'} = $tag{'epoch'};
1352                         $ref_item{'age'} = age_string($age);
1353                 }
1354                 $ref_item{'reftype'} = $tag{'type'};
1355                 $ref_item{'name'} = $tag{'name'};
1356                 $ref_item{'refid'} = $tag{'object'};
1357         } elsif ($type eq "commit"){
1358                 my %co = parse_commit($ref_id);
1359                 $ref_item{'reftype'} = "commit";
1360                 $ref_item{'name'} = $ref_file;
1361                 $ref_item{'title'} = $co{'title'};
1362                 $ref_item{'refid'} = $ref_id;
1363                 $ref_item{'epoch'} = $co{'committer_epoch'};
1364                 $ref_item{'age'} = $co{'age_string'};
1365         } else {
1366                 $ref_item{'reftype'} = $type;
1367                 $ref_item{'name'} = $ref_file;
1368                 $ref_item{'refid'} = $ref_id;
1369         }
1370
1371         return %ref_item;
1372 }
1373
1374 # parse line of git-diff-tree "raw" output
1375 sub parse_difftree_raw_line {
1376         my $line = shift;
1377         my %res;
1378
1379         # ':100644 100644 03b218260e99b78c6df0ed378e59ed9205ccc96d 3b93d5e7cc7f7dd4ebed13a5cc1a4ad976fc94d8 M   ls-files.c'
1380         # ':100644 100644 7f9281985086971d3877aca27704f2aaf9c448ce bc190ebc71bbd923f2b728e505408f5e54bd073a M   rev-tree.c'
1381         if ($line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)([0-9]{0,3})\t(.*)$/) {
1382                 $res{'from_mode'} = $1;
1383                 $res{'to_mode'} = $2;
1384                 $res{'from_id'} = $3;
1385                 $res{'to_id'} = $4;
1386                 $res{'status'} = $5;
1387                 $res{'similarity'} = $6;
1388                 if ($res{'status'} eq 'R' || $res{'status'} eq 'C') { # renamed or copied
1389                         ($res{'from_file'}, $res{'to_file'}) = map { unquote($_) } split("\t", $7);
1390                 } else {
1391                         $res{'file'} = unquote($7);
1392                 }
1393         }
1394         # 'c512b523472485aef4fff9e57b229d9d243c967f'
1395         elsif ($line =~ m/^([0-9a-fA-F]{40})$/) {
1396                 $res{'commit'} = $1;
1397         }
1398
1399         return wantarray ? %res : \%res;
1400 }
1401
1402 # parse line of git-ls-tree output
1403 sub parse_ls_tree_line ($;%) {
1404         my $line = shift;
1405         my %opts = @_;
1406         my %res;
1407
1408         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
1409         $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t(.+)$/s;
1410
1411         $res{'mode'} = $1;
1412         $res{'type'} = $2;
1413         $res{'hash'} = $3;
1414         if ($opts{'-z'}) {
1415                 $res{'name'} = $4;
1416         } else {
1417                 $res{'name'} = unquote($4);
1418         }
1419
1420         return wantarray ? %res : \%res;
1421 }
1422
1423 ## ......................................................................
1424 ## parse to array of hashes functions
1425
1426 sub git_get_heads_list {
1427         my $limit = shift;
1428         my @headslist;
1429
1430         open my $fd, '-|', git_cmd(), 'for-each-ref',
1431                 ($limit ? '--count='.($limit+1) : ()), '--sort=-committerdate',
1432                 '--format=%(objectname) %(refname) %(subject)%00%(committer)',
1433                 'refs/heads'
1434                 or return;
1435         while (my $line = <$fd>) {
1436                 my %ref_item;
1437
1438                 chomp $line;
1439                 my ($refinfo, $committerinfo) = split(/\0/, $line);
1440                 my ($hash, $name, $title) = split(' ', $refinfo, 3);
1441                 my ($committer, $epoch, $tz) =
1442                         ($committerinfo =~ /^(.*) ([0-9]+) (.*)$/);
1443                 $name =~ s!^refs/heads/!!;
1444
1445                 $ref_item{'name'}  = $name;
1446                 $ref_item{'id'}    = $hash;
1447                 $ref_item{'title'} = $title || '(no commit message)';
1448                 $ref_item{'epoch'} = $epoch;
1449                 if ($epoch) {
1450                         $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
1451                 } else {
1452                         $ref_item{'age'} = "unknown";
1453                 }
1454
1455                 push @headslist, \%ref_item;
1456         }
1457         close $fd;
1458
1459         return wantarray ? @headslist : \@headslist;
1460 }
1461
1462 sub git_get_tags_list {
1463         my $limit = shift;
1464         my @tagslist;
1465
1466         open my $fd, '-|', git_cmd(), 'for-each-ref',
1467                 ($limit ? '--count='.($limit+1) : ()), '--sort=-creatordate',
1468                 '--format=%(objectname) %(objecttype) %(refname) '.
1469                 '%(*objectname) %(*objecttype) %(subject)%00%(creator)',
1470                 'refs/tags'
1471                 or return;
1472         while (my $line = <$fd>) {
1473                 my %ref_item;
1474
1475                 chomp $line;
1476                 my ($refinfo, $creatorinfo) = split(/\0/, $line);
1477                 my ($id, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
1478                 my ($creator, $epoch, $tz) =
1479                         ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
1480                 $name =~ s!^refs/tags/!!;
1481
1482                 $ref_item{'type'} = $type;
1483                 $ref_item{'id'} = $id;
1484                 $ref_item{'name'} = $name;
1485                 if ($type eq "tag") {
1486                         $ref_item{'subject'} = $title;
1487                         $ref_item{'reftype'} = $reftype;
1488                         $ref_item{'refid'}   = $refid;
1489                 } else {
1490                         $ref_item{'reftype'} = $type;
1491                         $ref_item{'refid'}   = $id;
1492                 }
1493
1494                 if ($type eq "tag" || $type eq "commit") {
1495                         $ref_item{'epoch'} = $epoch;
1496                         if ($epoch) {
1497                                 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
1498                         } else {
1499                                 $ref_item{'age'} = "unknown";
1500                         }
1501                 }
1502
1503                 push @tagslist, \%ref_item;
1504         }
1505         close $fd;
1506
1507         return wantarray ? @tagslist : \@tagslist;
1508 }
1509
1510 ## ----------------------------------------------------------------------
1511 ## filesystem-related functions
1512
1513 sub get_file_owner {
1514         my $path = shift;
1515
1516         my ($dev, $ino, $mode, $nlink, $st_uid, $st_gid, $rdev, $size) = stat($path);
1517         my ($name, $passwd, $uid, $gid, $quota, $comment, $gcos, $dir, $shell) = getpwuid($st_uid);
1518         if (!defined $gcos) {
1519                 return undef;
1520         }
1521         my $owner = $gcos;
1522         $owner =~ s/[,;].*$//;
1523         return to_utf8($owner);
1524 }
1525
1526 ## ......................................................................
1527 ## mimetype related functions
1528
1529 sub mimetype_guess_file {
1530         my $filename = shift;
1531         my $mimemap = shift;
1532         -r $mimemap or return undef;
1533
1534         my %mimemap;
1535         open(MIME, $mimemap) or return undef;
1536         while (<MIME>) {
1537                 next if m/^#/; # skip comments
1538                 my ($mime, $exts) = split(/\t+/);
1539                 if (defined $exts) {
1540                         my @exts = split(/\s+/, $exts);
1541                         foreach my $ext (@exts) {
1542                                 $mimemap{$ext} = $mime;
1543                         }
1544                 }
1545         }
1546         close(MIME);
1547
1548         $filename =~ /\.([^.]*)$/;
1549         return $mimemap{$1};
1550 }
1551
1552 sub mimetype_guess {
1553         my $filename = shift;
1554         my $mime;
1555         $filename =~ /\./ or return undef;
1556
1557         if ($mimetypes_file) {
1558                 my $file = $mimetypes_file;
1559                 if ($file !~ m!^/!) { # if it is relative path
1560                         # it is relative to project
1561                         $file = "$projectroot/$project/$file";
1562                 }
1563                 $mime = mimetype_guess_file($filename, $file);
1564         }
1565         $mime ||= mimetype_guess_file($filename, '/etc/mime.types');
1566         return $mime;
1567 }
1568
1569 sub blob_mimetype {
1570         my $fd = shift;
1571         my $filename = shift;
1572
1573         if ($filename) {
1574                 my $mime = mimetype_guess($filename);
1575                 $mime and return $mime;
1576         }
1577
1578         # just in case
1579         return $default_blob_plain_mimetype unless $fd;
1580
1581         if (-T $fd) {
1582                 return 'text/plain' .
1583                        ($default_text_plain_charset ? '; charset='.$default_text_plain_charset : '');
1584         } elsif (! $filename) {
1585                 return 'application/octet-stream';
1586         } elsif ($filename =~ m/\.png$/i) {
1587                 return 'image/png';
1588         } elsif ($filename =~ m/\.gif$/i) {
1589                 return 'image/gif';
1590         } elsif ($filename =~ m/\.jpe?g$/i) {
1591                 return 'image/jpeg';
1592         } else {
1593                 return 'application/octet-stream';
1594         }
1595 }
1596
1597 ## ======================================================================
1598 ## functions printing HTML: header, footer, error page
1599
1600 sub git_header_html {
1601         my $status = shift || "200 OK";
1602         my $expires = shift;
1603
1604         my $title = "$site_name";
1605         if (defined $project) {
1606                 $title .= " - $project";
1607                 if (defined $action) {
1608                         $title .= "/$action";
1609                         if (defined $file_name) {
1610                                 $title .= " - " . esc_path($file_name);
1611                                 if ($action eq "tree" && $file_name !~ m|/$|) {
1612                                         $title .= "/";
1613                                 }
1614                         }
1615                 }
1616         }
1617         my $content_type;
1618         # require explicit support from the UA if we are to send the page as
1619         # 'application/xhtml+xml', otherwise send it as plain old 'text/html'.
1620         # we have to do this because MSIE sometimes globs '*/*', pretending to
1621         # support xhtml+xml but choking when it gets what it asked for.
1622         if (defined $cgi->http('HTTP_ACCEPT') &&
1623             $cgi->http('HTTP_ACCEPT') =~ m/(,|;|\s|^)application\/xhtml\+xml(,|;|\s|$)/ &&
1624             $cgi->Accept('application/xhtml+xml') != 0) {
1625                 $content_type = 'application/xhtml+xml';
1626         } else {
1627                 $content_type = 'text/html';
1628         }
1629         print $cgi->header(-type=>$content_type, -charset => 'utf-8',
1630                            -status=> $status, -expires => $expires);
1631         print <<EOF;
1632 <?xml version="1.0" encoding="utf-8"?>
1633 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
1634 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en-US" lang="en-US">
1635 <!-- git web interface version $version, (C) 2005-2006, Kay Sievers <kay.sievers\@vrfy.org>, Christian Gierke -->
1636 <!-- git core binaries version $git_version -->
1637 <head>
1638 <meta http-equiv="content-type" content="$content_type; charset=utf-8"/>
1639 <meta name="generator" content="gitweb/$version git/$git_version"/>
1640 <meta name="robots" content="index, nofollow"/>
1641 <title>$title</title>
1642 EOF
1643 # print out each stylesheet that exist
1644         if (defined $stylesheet) {
1645 #provides backwards capability for those people who define style sheet in a config file
1646                 print '<link rel="stylesheet" type="text/css" href="'.$stylesheet.'"/>'."\n";
1647         } else {
1648                 foreach my $stylesheet (@stylesheets) {
1649                         next unless $stylesheet;
1650                         print '<link rel="stylesheet" type="text/css" href="'.$stylesheet.'"/>'."\n";
1651                 }
1652         }
1653         if (defined $project) {
1654                 printf('<link rel="alternate" title="%s log" '.
1655                        'href="%s" type="application/rss+xml"/>'."\n",
1656                        esc_param($project), href(action=>"rss"));
1657         } else {
1658                 printf('<link rel="alternate" title="%s projects list" '.
1659                        'href="%s" type="text/plain; charset=utf-8"/>'."\n",
1660                        $site_name, href(project=>undef, action=>"project_index"));
1661                 printf('<link rel="alternate" title="%s projects logs" '.
1662                        'href="%s" type="text/x-opml"/>'."\n",
1663                        $site_name, href(project=>undef, action=>"opml"));
1664         }
1665         if (defined $favicon) {
1666                 print qq(<link rel="shortcut icon" href="$favicon" type="image/png"/>\n);
1667         }
1668
1669         print "</head>\n" .
1670               "<body>\n";
1671
1672         if (-f $site_header) {
1673                 open (my $fd, $site_header);
1674                 print <$fd>;
1675                 close $fd;
1676         }
1677
1678         print "<div class=\"page_header\">\n" .
1679               $cgi->a({-href => esc_url($logo_url),
1680                        -title => $logo_label},
1681                       qq(<img src="$logo" width="72" height="27" alt="git" class="logo"/>));
1682         print $cgi->a({-href => esc_url($home_link)}, $home_link_str) . " / ";
1683         if (defined $project) {
1684                 print $cgi->a({-href => href(action=>"summary")}, esc_html($project));
1685                 if (defined $action) {
1686                         print " / $action";
1687                 }
1688                 print "\n";
1689                 if (!defined $searchtext) {
1690                         $searchtext = "";
1691                 }
1692                 my $search_hash;
1693                 if (defined $hash_base) {
1694                         $search_hash = $hash_base;
1695                 } elsif (defined $hash) {
1696                         $search_hash = $hash;
1697                 } else {
1698                         $search_hash = "HEAD";
1699                 }
1700                 $cgi->param("a", "search");
1701                 $cgi->param("h", $search_hash);
1702                 $cgi->param("p", $project);
1703                 print $cgi->startform(-method => "get", -action => $my_uri) .
1704                       "<div class=\"search\">\n" .
1705                       $cgi->hidden(-name => "p") . "\n" .
1706                       $cgi->hidden(-name => "a") . "\n" .
1707                       $cgi->hidden(-name => "h") . "\n" .
1708                       $cgi->popup_menu(-name => 'st', -default => 'commit',
1709                                        -values => ['commit', 'author', 'committer', 'pickaxe']) .
1710                       $cgi->sup($cgi->a({-href => href(action=>"search_help")}, "?")) .
1711                       " search:\n",
1712                       $cgi->textfield(-name => "s", -value => $searchtext) . "\n" .
1713                       "</div>" .
1714                       $cgi->end_form() . "\n";
1715         }
1716         print "</div>\n";
1717 }
1718
1719 sub git_footer_html {
1720         print "<div class=\"page_footer\">\n";
1721         if (defined $project) {
1722                 my $descr = git_get_project_description($project);
1723                 if (defined $descr) {
1724                         print "<div class=\"page_footer_text\">" . esc_html($descr) . "</div>\n";
1725                 }
1726                 print $cgi->a({-href => href(action=>"rss"),
1727                               -class => "rss_logo"}, "RSS") . "\n";
1728         } else {
1729                 print $cgi->a({-href => href(project=>undef, action=>"opml"),
1730                               -class => "rss_logo"}, "OPML") . " ";
1731                 print $cgi->a({-href => href(project=>undef, action=>"project_index"),
1732                               -class => "rss_logo"}, "TXT") . "\n";
1733         }
1734         print "</div>\n" ;
1735
1736         if (-f $site_footer) {
1737                 open (my $fd, $site_footer);
1738                 print <$fd>;
1739                 close $fd;
1740         }
1741
1742         print "</body>\n" .
1743               "</html>";
1744 }
1745
1746 sub die_error {
1747         my $status = shift || "403 Forbidden";
1748         my $error = shift || "Malformed query, file missing or permission denied";
1749
1750         git_header_html($status);
1751         print <<EOF;
1752 <div class="page_body">
1753 <br /><br />
1754 $status - $error
1755 <br />
1756 </div>
1757 EOF
1758         git_footer_html();
1759         exit;
1760 }
1761
1762 ## ----------------------------------------------------------------------
1763 ## functions printing or outputting HTML: navigation
1764
1765 sub git_print_page_nav {
1766         my ($current, $suppress, $head, $treehead, $treebase, $extra) = @_;
1767         $extra = '' if !defined $extra; # pager or formats
1768
1769         my @navs = qw(summary shortlog log commit commitdiff tree);
1770         if ($suppress) {
1771                 @navs = grep { $_ ne $suppress } @navs;
1772         }
1773
1774         my %arg = map { $_ => {action=>$_} } @navs;
1775         if (defined $head) {
1776                 for (qw(commit commitdiff)) {
1777                         $arg{$_}{hash} = $head;
1778                 }
1779                 if ($current =~ m/^(tree | log | shortlog | commit | commitdiff | search)$/x) {
1780                         for (qw(shortlog log)) {
1781                                 $arg{$_}{hash} = $head;
1782                         }
1783                 }
1784         }
1785         $arg{tree}{hash} = $treehead if defined $treehead;
1786         $arg{tree}{hash_base} = $treebase if defined $treebase;
1787
1788         print "<div class=\"page_nav\">\n" .
1789                 (join " | ",
1790                  map { $_ eq $current ?
1791                        $_ : $cgi->a({-href => href(%{$arg{$_}})}, "$_")
1792                  } @navs);
1793         print "<br/>\n$extra<br/>\n" .
1794               "</div>\n";
1795 }
1796
1797 sub format_paging_nav {
1798         my ($action, $hash, $head, $page, $nrevs) = @_;
1799         my $paging_nav;
1800
1801
1802         if ($hash ne $head || $page) {
1803                 $paging_nav .= $cgi->a({-href => href(action=>$action)}, "HEAD");
1804         } else {
1805                 $paging_nav .= "HEAD";
1806         }
1807
1808         if ($page > 0) {
1809                 $paging_nav .= " &sdot; " .
1810                         $cgi->a({-href => href(action=>$action, hash=>$hash, page=>$page-1),
1811                                  -accesskey => "p", -title => "Alt-p"}, "prev");
1812         } else {
1813                 $paging_nav .= " &sdot; prev";
1814         }
1815
1816         if ($nrevs >= (100 * ($page+1)-1)) {
1817                 $paging_nav .= " &sdot; " .
1818                         $cgi->a({-href => href(action=>$action, hash=>$hash, page=>$page+1),
1819                                  -accesskey => "n", -title => "Alt-n"}, "next");
1820         } else {
1821                 $paging_nav .= " &sdot; next";
1822         }
1823
1824         return $paging_nav;
1825 }
1826
1827 ## ......................................................................
1828 ## functions printing or outputting HTML: div
1829
1830 sub git_print_header_div {
1831         my ($action, $title, $hash, $hash_base) = @_;
1832         my %args = ();
1833
1834         $args{action} = $action;
1835         $args{hash} = $hash if $hash;
1836         $args{hash_base} = $hash_base if $hash_base;
1837
1838         print "<div class=\"header\">\n" .
1839               $cgi->a({-href => href(%args), -class => "title"},
1840               $title ? $title : $action) .
1841               "\n</div>\n";
1842 }
1843
1844 #sub git_print_authorship (\%) {
1845 sub git_print_authorship {
1846         my $co = shift;
1847
1848         my %ad = parse_date($co->{'author_epoch'}, $co->{'author_tz'});
1849         print "<div class=\"author_date\">" .
1850               esc_html($co->{'author_name'}) .
1851               " [$ad{'rfc2822'}";
1852         if ($ad{'hour_local'} < 6) {
1853                 printf(" (<span class=\"atnight\">%02d:%02d</span> %s)",
1854                        $ad{'hour_local'}, $ad{'minute_local'}, $ad{'tz_local'});
1855         } else {
1856                 printf(" (%02d:%02d %s)",
1857                        $ad{'hour_local'}, $ad{'minute_local'}, $ad{'tz_local'});
1858         }
1859         print "]</div>\n";
1860 }
1861
1862 sub git_print_page_path {
1863         my $name = shift;
1864         my $type = shift;
1865         my $hb = shift;
1866
1867
1868         print "<div class=\"page_path\">";
1869         print $cgi->a({-href => href(action=>"tree", hash_base=>$hb),
1870                       -title => 'tree root'}, "[$project]");
1871         print " / ";
1872         if (defined $name) {
1873                 my @dirname = split '/', $name;
1874                 my $basename = pop @dirname;
1875                 my $fullname = '';
1876
1877                 foreach my $dir (@dirname) {
1878                         $fullname .= ($fullname ? '/' : '') . $dir;
1879                         print $cgi->a({-href => href(action=>"tree", file_name=>$fullname,
1880                                                      hash_base=>$hb),
1881                                       -title => esc_html($fullname)}, esc_path($dir));
1882                         print " / ";
1883                 }
1884                 if (defined $type && $type eq 'blob') {
1885                         print $cgi->a({-href => href(action=>"blob_plain", file_name=>$file_name,
1886                                                      hash_base=>$hb),
1887                                       -title => esc_html($name)}, esc_path($basename));
1888                 } elsif (defined $type && $type eq 'tree') {
1889                         print $cgi->a({-href => href(action=>"tree", file_name=>$file_name,
1890                                                      hash_base=>$hb),
1891                                       -title => esc_html($name)}, esc_path($basename));
1892                         print " / ";
1893                 } else {
1894                         print esc_path($basename);
1895                 }
1896         }
1897         print "<br/></div>\n";
1898 }
1899
1900 # sub git_print_log (\@;%) {
1901 sub git_print_log ($;%) {
1902         my $log = shift;
1903         my %opts = @_;
1904
1905         if ($opts{'-remove_title'}) {
1906                 # remove title, i.e. first line of log
1907                 shift @$log;
1908         }
1909         # remove leading empty lines
1910         while (defined $log->[0] && $log->[0] eq "") {
1911                 shift @$log;
1912         }
1913
1914         # print log
1915         my $signoff = 0;
1916         my $empty = 0;
1917         foreach my $line (@$log) {
1918                 if ($line =~ m/^ *(signed[ \-]off[ \-]by[ :]|acked[ \-]by[ :]|cc[ :])/i) {
1919                         $signoff = 1;
1920                         $empty = 0;
1921                         if (! $opts{'-remove_signoff'}) {
1922                                 print "<span class=\"signoff\">" . esc_html($line) . "</span><br/>\n";
1923                                 next;
1924                         } else {
1925                                 # remove signoff lines
1926                                 next;
1927                         }
1928                 } else {
1929                         $signoff = 0;
1930                 }
1931
1932                 # print only one empty line
1933                 # do not print empty line after signoff
1934                 if ($line eq "") {
1935                         next if ($empty || $signoff);
1936                         $empty = 1;
1937                 } else {
1938                         $empty = 0;
1939                 }
1940
1941                 print format_log_line_html($line) . "<br/>\n";
1942         }
1943
1944         if ($opts{'-final_empty_line'}) {
1945                 # end with single empty line
1946                 print "<br/>\n" unless $empty;
1947         }
1948 }
1949
1950 # print tree entry (row of git_tree), but without encompassing <tr> element
1951 sub git_print_tree_entry {
1952         my ($t, $basedir, $hash_base, $have_blame) = @_;
1953
1954         my %base_key = ();
1955         $base_key{hash_base} = $hash_base if defined $hash_base;
1956
1957         # The format of a table row is: mode list link.  Where mode is
1958         # the mode of the entry, list is the name of the entry, an href,
1959         # and link is the action links of the entry.
1960
1961         print "<td class=\"mode\">" . mode_str($t->{'mode'}) . "</td>\n";
1962         if ($t->{'type'} eq "blob") {
1963                 print "<td class=\"list\">" .
1964                         $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
1965                                                file_name=>"$basedir$t->{'name'}", %base_key),
1966                                 -class => "list"}, esc_path($t->{'name'})) . "</td>\n";
1967                 print "<td class=\"link\">";
1968                 print $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
1969                                              file_name=>"$basedir$t->{'name'}", %base_key)},
1970                               "blob");
1971                 if ($have_blame) {
1972                         print " | " .
1973                               $cgi->a({-href => href(action=>"blame", hash=>$t->{'hash'},
1974                                                            file_name=>"$basedir$t->{'name'}", %base_key)},
1975                                             "blame");
1976                 }
1977                 if (defined $hash_base) {
1978                         print " | " .
1979                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
1980                                                      hash=>$t->{'hash'}, file_name=>"$basedir$t->{'name'}")},
1981                                       "history");
1982                 }
1983                 print " | " .
1984                         $cgi->a({-href => href(action=>"blob_plain", hash_base=>$hash_base,
1985                                                file_name=>"$basedir$t->{'name'}")},
1986                                 "raw");
1987                 print "</td>\n";
1988
1989         } elsif ($t->{'type'} eq "tree") {
1990                 print "<td class=\"list\">";
1991                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
1992                                              file_name=>"$basedir$t->{'name'}", %base_key)},
1993                               esc_path($t->{'name'}));
1994                 print "</td>\n";
1995                 print "<td class=\"link\">";
1996                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
1997                                              file_name=>"$basedir$t->{'name'}", %base_key)},
1998                               "tree");
1999                 if (defined $hash_base) {
2000                         print " | " .
2001                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
2002                                                      file_name=>"$basedir$t->{'name'}")},
2003                                       "history");
2004                 }
2005                 print "</td>\n";
2006         }
2007 }
2008
2009 ## ......................................................................
2010 ## functions printing large fragments of HTML
2011
2012 sub git_difftree_body {
2013         my ($difftree, $hash, $parent) = @_;
2014         my ($have_blame) = gitweb_check_feature('blame');
2015         print "<div class=\"list_head\">\n";
2016         if ($#{$difftree} > 10) {
2017                 print(($#{$difftree} + 1) . " files changed:\n");
2018         }
2019         print "</div>\n";
2020
2021         print "<table class=\"diff_tree\">\n";
2022         my $alternate = 1;
2023         my $patchno = 0;
2024         foreach my $line (@{$difftree}) {
2025                 my %diff = parse_difftree_raw_line($line);
2026
2027                 if ($alternate) {
2028                         print "<tr class=\"dark\">\n";
2029                 } else {
2030                         print "<tr class=\"light\">\n";
2031                 }
2032                 $alternate ^= 1;
2033
2034                 my ($to_mode_oct, $to_mode_str, $to_file_type);
2035                 my ($from_mode_oct, $from_mode_str, $from_file_type);
2036                 if ($diff{'to_mode'} ne ('0' x 6)) {
2037                         $to_mode_oct = oct $diff{'to_mode'};
2038                         if (S_ISREG($to_mode_oct)) { # only for regular file
2039                                 $to_mode_str = sprintf("%04o", $to_mode_oct & 0777); # permission bits
2040                         }
2041                         $to_file_type = file_type($diff{'to_mode'});
2042                 }
2043                 if ($diff{'from_mode'} ne ('0' x 6)) {
2044                         $from_mode_oct = oct $diff{'from_mode'};
2045                         if (S_ISREG($to_mode_oct)) { # only for regular file
2046                                 $from_mode_str = sprintf("%04o", $from_mode_oct & 0777); # permission bits
2047                         }
2048                         $from_file_type = file_type($diff{'from_mode'});
2049                 }
2050
2051                 if ($diff{'status'} eq "A") { # created
2052                         my $mode_chng = "<span class=\"file_status new\">[new $to_file_type";
2053                         $mode_chng   .= " with mode: $to_mode_str" if $to_mode_str;
2054                         $mode_chng   .= "]</span>";
2055                         print "<td>";
2056                         print $cgi->a({-href => href(action=>"blob", hash=>$diff{'to_id'},
2057                                                      hash_base=>$hash, file_name=>$diff{'file'}),
2058                                       -class => "list"}, esc_path($diff{'file'}));
2059                         print "</td>\n";
2060                         print "<td>$mode_chng</td>\n";
2061                         print "<td class=\"link\">";
2062                         if ($action eq 'commitdiff') {
2063                                 # link to patch
2064                                 $patchno++;
2065                                 print $cgi->a({-href => "#patch$patchno"}, "patch");
2066                         }
2067                         print "</td>\n";
2068
2069                 } elsif ($diff{'status'} eq "D") { # deleted
2070                         my $mode_chng = "<span class=\"file_status deleted\">[deleted $from_file_type]</span>";
2071                         print "<td>";
2072                         print $cgi->a({-href => href(action=>"blob", hash=>$diff{'from_id'},
2073                                                      hash_base=>$parent, file_name=>$diff{'file'}),
2074                                        -class => "list"}, esc_path($diff{'file'}));
2075                         print "</td>\n";
2076                         print "<td>$mode_chng</td>\n";
2077                         print "<td class=\"link\">";
2078                         if ($action eq 'commitdiff') {
2079                                 # link to patch
2080                                 $patchno++;
2081                                 print $cgi->a({-href => "#patch$patchno"}, "patch");
2082                                 print " | ";
2083                         }
2084                         print $cgi->a({-href => href(action=>"blob", hash=>$diff{'from_id'},
2085                                                      hash_base=>$parent, file_name=>$diff{'file'})},
2086                                       "blob") . " | ";
2087                         if ($have_blame) {
2088                                 print $cgi->a({-href =>
2089                                                    href(action=>"blame",
2090                                                         hash_base=>$parent,
2091                                                         file_name=>$diff{'file'})},
2092                                               "blame") . " | ";
2093                         }
2094                         print $cgi->a({-href => href(action=>"history", hash_base=>$parent,
2095                                                      file_name=>$diff{'file'})},
2096                                       "history");
2097                         print "</td>\n";
2098
2099                 } elsif ($diff{'status'} eq "M" || $diff{'status'} eq "T") { # modified, or type changed
2100                         my $mode_chnge = "";
2101                         if ($diff{'from_mode'} != $diff{'to_mode'}) {
2102                                 $mode_chnge = "<span class=\"file_status mode_chnge\">[changed";
2103                                 if ($from_file_type != $to_file_type) {
2104                                         $mode_chnge .= " from $from_file_type to $to_file_type";
2105                                 }
2106                                 if (($from_mode_oct & 0777) != ($to_mode_oct & 0777)) {
2107                                         if ($from_mode_str && $to_mode_str) {
2108                                                 $mode_chnge .= " mode: $from_mode_str->$to_mode_str";
2109                                         } elsif ($to_mode_str) {
2110                                                 $mode_chnge .= " mode: $to_mode_str";
2111                                         }
2112                                 }
2113                                 $mode_chnge .= "]</span>\n";
2114                         }
2115                         print "<td>";
2116                         print $cgi->a({-href => href(action=>"blob", hash=>$diff{'to_id'},
2117                                                      hash_base=>$hash, file_name=>$diff{'file'}),
2118                                       -class => "list"}, esc_path($diff{'file'}));
2119                         print "</td>\n";
2120                         print "<td>$mode_chnge</td>\n";
2121                         print "<td class=\"link\">";
2122                         if ($action eq 'commitdiff') {
2123                                 # link to patch
2124                                 $patchno++;
2125                                 print $cgi->a({-href => "#patch$patchno"}, "patch") .
2126                                       " | ";
2127                         } elsif ($diff{'to_id'} ne $diff{'from_id'}) {
2128                                 # "commit" view and modified file (not onlu mode changed)
2129                                 print $cgi->a({-href => href(action=>"blobdiff",
2130                                                              hash=>$diff{'to_id'}, hash_parent=>$diff{'from_id'},
2131                                                              hash_base=>$hash, hash_parent_base=>$parent,
2132                                                              file_name=>$diff{'file'})},
2133                                               "diff") .
2134                                       " | ";
2135                         }
2136                         print $cgi->a({-href => href(action=>"blob", hash=>$diff{'to_id'},
2137                                                      hash_base=>$hash, file_name=>$diff{'file'})},
2138                                       "blob") . " | ";
2139                         if ($have_blame) {
2140                                 print $cgi->a({-href => href(action=>"blame",
2141                                                              hash_base=>$hash,
2142                                                              file_name=>$diff{'file'})},
2143                                               "blame") . " | ";
2144                         }
2145                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
2146                                                      file_name=>$diff{'file'})},
2147                                       "history");
2148                         print "</td>\n";
2149
2150                 } elsif ($diff{'status'} eq "R" || $diff{'status'} eq "C") { # renamed or copied
2151                         my %status_name = ('R' => 'moved', 'C' => 'copied');
2152                         my $nstatus = $status_name{$diff{'status'}};
2153                         my $mode_chng = "";
2154                         if ($diff{'from_mode'} != $diff{'to_mode'}) {
2155                                 # mode also for directories, so we cannot use $to_mode_str
2156                                 $mode_chng = sprintf(", mode: %04o", $to_mode_oct & 0777);
2157                         }
2158                         print "<td>" .
2159                               $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
2160                                                      hash=>$diff{'to_id'}, file_name=>$diff{'to_file'}),
2161                                       -class => "list"}, esc_path($diff{'to_file'})) . "</td>\n" .
2162                               "<td><span class=\"file_status $nstatus\">[$nstatus from " .
2163                               $cgi->a({-href => href(action=>"blob", hash_base=>$parent,
2164                                                      hash=>$diff{'from_id'}, file_name=>$diff{'from_file'}),
2165                                       -class => "list"}, esc_path($diff{'from_file'})) .
2166                               " with " . (int $diff{'similarity'}) . "% similarity$mode_chng]</span></td>\n" .
2167                               "<td class=\"link\">";
2168                         if ($action eq 'commitdiff') {
2169                                 # link to patch
2170                                 $patchno++;
2171                                 print $cgi->a({-href => "#patch$patchno"}, "patch") .
2172                                       " | ";
2173                         } elsif ($diff{'to_id'} ne $diff{'from_id'}) {
2174                                 # "commit" view and modified file (not only pure rename or copy)
2175                                 print $cgi->a({-href => href(action=>"blobdiff",
2176                                                              hash=>$diff{'to_id'}, hash_parent=>$diff{'from_id'},
2177                                                              hash_base=>$hash, hash_parent_base=>$parent,
2178                                                              file_name=>$diff{'to_file'}, file_parent=>$diff{'from_file'})},
2179                                               "diff") .
2180                                       " | ";
2181                         }
2182                         print $cgi->a({-href => href(action=>"blob", hash=>$diff{'from_id'},
2183                                                      hash_base=>$parent, file_name=>$diff{'from_file'})},
2184                                       "blob") . " | ";
2185                         if ($have_blame) {
2186                                 print $cgi->a({-href => href(action=>"blame",
2187                                                              hash_base=>$hash,
2188                                                              file_name=>$diff{'to_file'})},
2189                                               "blame") . " | ";
2190                         }
2191                         print $cgi->a({-href => href(action=>"history", hash_base=>$parent,
2192                                                     file_name=>$diff{'from_file'})},
2193                                       "history");
2194                         print "</td>\n";
2195
2196                 } # we should not encounter Unmerged (U) or Unknown (X) status
2197                 print "</tr>\n";
2198         }
2199         print "</table>\n";
2200 }
2201
2202 sub git_patchset_body {
2203         my ($fd, $difftree, $hash, $hash_parent) = @_;
2204
2205         my $patch_idx = 0;
2206         my $in_header = 0;
2207         my $patch_found = 0;
2208         my $diffinfo;
2209         my (%from, %to);
2210
2211         print "<div class=\"patchset\">\n";
2212
2213         LINE:
2214         while (my $patch_line = <$fd>) {
2215                 chomp $patch_line;
2216
2217                 if ($patch_line =~ m/^diff /) { # "git diff" header
2218                         # beginning of patch (in patchset)
2219                         if ($patch_found) {
2220                                 # close extended header for previous empty patch
2221                                 if ($in_header) {
2222                                         print "</div>\n" # class="diff extended_header"
2223                                 }
2224                                 # close previous patch
2225                                 print "</div>\n"; # class="patch"
2226                         } else {
2227                                 # first patch in patchset
2228                                 $patch_found = 1;
2229                         }
2230                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n";
2231
2232                         # read and prepare patch information
2233                         if (ref($difftree->[$patch_idx]) eq "HASH") {
2234                                 # pre-parsed (or generated by hand)
2235                                 $diffinfo = $difftree->[$patch_idx];
2236                         } else {
2237                                 $diffinfo = parse_difftree_raw_line($difftree->[$patch_idx]);
2238                         }
2239                         $from{'file'} = $diffinfo->{'from_file'} || $diffinfo->{'file'};
2240                         $to{'file'}   = $diffinfo->{'to_file'}   || $diffinfo->{'file'};
2241                         if ($diffinfo->{'status'} ne "A") { # not new (added) file
2242                                 $from{'href'} = href(action=>"blob", hash_base=>$hash_parent,
2243                                                      hash=>$diffinfo->{'from_id'},
2244                                                      file_name=>$from{'file'});
2245                         }
2246                         if ($diffinfo->{'status'} ne "D") { # not deleted file
2247                                 $to{'href'} = href(action=>"blob", hash_base=>$hash,
2248                                                    hash=>$diffinfo->{'to_id'},
2249                                                    file_name=>$to{'file'});
2250                         }
2251                         $patch_idx++;
2252
2253                         # print "git diff" header
2254                         $patch_line =~ s!^(diff (.*?) )"?a/.*$!$1!;
2255                         if ($from{'href'}) {
2256                                 $patch_line .= $cgi->a({-href => $from{'href'}, -class => "path"},
2257                                                        'a/' . esc_path($from{'file'}));
2258                         } else { # file was added
2259                                 $patch_line .= 'a/' . esc_path($from{'file'});
2260                         }
2261                         $patch_line .= ' ';
2262                         if ($to{'href'}) {
2263                                 $patch_line .= $cgi->a({-href => $to{'href'}, -class => "path"},
2264                                                        'b/' . esc_path($to{'file'}));
2265                         } else { # file was deleted
2266                                 $patch_line .= 'b/' . esc_path($to{'file'});
2267                         }
2268
2269                         print "<div class=\"diff header\">$patch_line</div>\n";
2270                         print "<div class=\"diff extended_header\">\n";
2271                         $in_header = 1;
2272                         next LINE;
2273                 }
2274
2275                 if ($in_header) {
2276                         if ($patch_line !~ m/^---/) {
2277                                 # match <path>
2278                                 if ($patch_line =~ s!^((copy|rename) from ).*$!$1! && $from{'href'}) {
2279                                         $patch_line .= $cgi->a({-href=>$from{'href'}, -class=>"path"},
2280                                                                 esc_path($from{'file'}));
2281                                 }
2282                                 if ($patch_line =~ s!^((copy|rename) to ).*$!$1! && $to{'href'}) {
2283                                         $patch_line = $cgi->a({-href=>$to{'href'}, -class=>"path"},
2284                                                               esc_path($to{'file'}));
2285                                 }
2286                                 # match <mode>
2287                                 if ($patch_line =~ m/\s(\d{6})$/) {
2288                                         $patch_line .= '<span class="info"> (' .
2289                                                        file_type_long($1) .
2290                                                        ')</span>';
2291                                 }
2292                                 # match <hash>
2293                                 if ($patch_line =~ m/^index/) {
2294                                         my ($from_link, $to_link);
2295                                         if ($from{'href'}) {
2296                                                 $from_link = $cgi->a({-href=>$from{'href'}, -class=>"hash"},
2297                                                                      substr($diffinfo->{'from_id'},0,7));
2298                                         } else {
2299                                                 $from_link = '0' x 7;
2300                                         }
2301                                         if ($to{'href'}) {
2302                                                 $to_link = $cgi->a({-href=>$to{'href'}, -class=>"hash"},
2303                                                                    substr($diffinfo->{'to_id'},0,7));
2304                                         } else {
2305                                                 $to_link = '0' x 7;
2306                                         }
2307                                         my ($from_id, $to_id) = ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
2308                                         $patch_line =~ s!$from_id\.\.$to_id!$from_link..$to_link!;
2309                                 }
2310                                 print $patch_line . "<br/>\n";
2311
2312                         } else {
2313                                 #$in_header && $patch_line =~ m/^---/;
2314                                 print "</div>\n"; # class="diff extended_header"
2315                                 $in_header = 0;
2316
2317                                 if ($from{'href'}) {
2318                                         $patch_line = '--- a/' .
2319                                                       $cgi->a({-href=>$from{'href'}, -class=>"path"},
2320                                                               esc_path($from{'file'}));
2321                                 }
2322                                 print "<div class=\"diff from_file\">$patch_line</div>\n";
2323
2324                                 $patch_line = <$fd>;
2325                                 chomp $patch_line;
2326
2327                                 #$patch_line =~ m/^+++/;
2328                                 if ($to{'href'}) {
2329                                         $patch_line = '+++ b/' .
2330                                                       $cgi->a({-href=>$to{'href'}, -class=>"path"},
2331                                                               esc_path($to{'file'}));
2332                                 }
2333                                 print "<div class=\"diff to_file\">$patch_line</div>\n";
2334
2335                         }
2336
2337                         next LINE;
2338                 }
2339
2340                 print format_diff_line($patch_line);
2341         }
2342         print "</div>\n" if $in_header; # extended header
2343
2344         print "</div>\n" if $patch_found; # class="patch"
2345
2346         print "</div>\n"; # class="patchset"
2347 }
2348
2349 # . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
2350
2351 sub git_project_list_body {
2352         my ($projlist, $order, $from, $to, $extra, $no_header) = @_;
2353
2354         my ($check_forks) = gitweb_check_feature('forks');
2355
2356         my @projects;
2357         foreach my $pr (@$projlist) {
2358                 my (@aa) = git_get_last_activity($pr->{'path'});
2359                 unless (@aa) {
2360                         next;
2361                 }
2362                 ($pr->{'age'}, $pr->{'age_string'}) = @aa;
2363                 if (!defined $pr->{'descr'}) {
2364                         my $descr = git_get_project_description($pr->{'path'}) || "";
2365                         $pr->{'descr'} = chop_str($descr, 25, 5);
2366                 }
2367                 if (!defined $pr->{'owner'}) {
2368                         $pr->{'owner'} = get_file_owner("$projectroot/$pr->{'path'}") || "";
2369                 }
2370                 if ($check_forks) {
2371                         my $pname = $pr->{'path'};
2372                         if (($pname =~ s/\.git$//) &&
2373                             ($pname !~ /\/$/) &&
2374                             (-d "$projectroot/$pname")) {
2375                                 $pr->{'forks'} = "-d $projectroot/$pname";
2376                         }
2377                         else {
2378                                 $pr->{'forks'} = 0;
2379                         }
2380                 }
2381                 push @projects, $pr;
2382         }
2383
2384         $order ||= "project";
2385         $from = 0 unless defined $from;
2386         $to = $#projects if (!defined $to || $#projects < $to);
2387
2388         print "<table class=\"project_list\">\n";
2389         unless ($no_header) {
2390                 print "<tr>\n";
2391                 if ($check_forks) {
2392                         print "<th></th>\n";
2393                 }
2394                 if ($order eq "project") {
2395                         @projects = sort {$a->{'path'} cmp $b->{'path'}} @projects;
2396                         print "<th>Project</th>\n";
2397                 } else {
2398                         print "<th>" .
2399                               $cgi->a({-href => href(project=>undef, order=>'project'),
2400                                        -class => "header"}, "Project") .
2401                               "</th>\n";
2402                 }
2403                 if ($order eq "descr") {
2404                         @projects = sort {$a->{'descr'} cmp $b->{'descr'}} @projects;
2405                         print "<th>Description</th>\n";
2406                 } else {
2407                         print "<th>" .
2408                               $cgi->a({-href => href(project=>undef, order=>'descr'),
2409                                        -class => "header"}, "Description") .
2410                               "</th>\n";
2411                 }
2412                 if ($order eq "owner") {
2413                         @projects = sort {$a->{'owner'} cmp $b->{'owner'}} @projects;
2414                         print "<th>Owner</th>\n";
2415                 } else {
2416                         print "<th>" .
2417                               $cgi->a({-href => href(project=>undef, order=>'owner'),
2418                                        -class => "header"}, "Owner") .
2419                               "</th>\n";
2420                 }
2421                 if ($order eq "age") {
2422                         @projects = sort {$a->{'age'} <=> $b->{'age'}} @projects;
2423                         print "<th>Last Change</th>\n";
2424                 } else {
2425                         print "<th>" .
2426                               $cgi->a({-href => href(project=>undef, order=>'age'),
2427                                        -class => "header"}, "Last Change") .
2428                               "</th>\n";
2429                 }
2430                 print "<th></th>\n" .
2431                       "</tr>\n";
2432         }
2433         my $alternate = 1;
2434         for (my $i = $from; $i <= $to; $i++) {
2435                 my $pr = $projects[$i];
2436                 if ($alternate) {
2437                         print "<tr class=\"dark\">\n";
2438                 } else {
2439                         print "<tr class=\"light\">\n";
2440                 }
2441                 $alternate ^= 1;
2442                 if ($check_forks) {
2443                         print "<td>";
2444                         if ($pr->{'forks'}) {
2445                                 print "<!-- $pr->{'forks'} -->\n";
2446                                 print $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "+");
2447                         }
2448                         print "</td>\n";
2449                 }
2450                 print "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
2451                                         -class => "list"}, esc_html($pr->{'path'})) . "</td>\n" .
2452                       "<td>" . esc_html($pr->{'descr'}) . "</td>\n" .
2453                       "<td><i>" . chop_str($pr->{'owner'}, 15) . "</i></td>\n";
2454                 print "<td class=\"". age_class($pr->{'age'}) . "\">" .
2455                       $pr->{'age_string'} . "</td>\n" .
2456                       "<td class=\"link\">" .
2457                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary")}, "summary")   . " | " .
2458                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"shortlog")}, "shortlog") . " | " .
2459                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"log")}, "log") . " | " .
2460                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"tree")}, "tree") .
2461                       ($pr->{'forks'} ? " | " . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "forks") : '') .
2462                       "</td>\n" .
2463                       "</tr>\n";
2464         }
2465         if (defined $extra) {
2466                 print "<tr>\n";
2467                 if ($check_forks) {
2468                         print "<td></td>\n";
2469                 }
2470                 print "<td colspan=\"5\">$extra</td>\n" .
2471                       "</tr>\n";
2472         }
2473         print "</table>\n";
2474 }
2475
2476 sub git_shortlog_body {
2477         # uses global variable $project
2478         my ($revlist, $from, $to, $refs, $extra) = @_;
2479
2480         $from = 0 unless defined $from;
2481         $to = $#{$revlist} if (!defined $to || $#{$revlist} < $to);
2482
2483         print "<table class=\"shortlog\" cellspacing=\"0\">\n";
2484         my $alternate = 1;
2485         for (my $i = $from; $i <= $to; $i++) {
2486                 my $commit = $revlist->[$i];
2487                 #my $ref = defined $refs ? format_ref_marker($refs, $commit) : '';
2488                 my $ref = format_ref_marker($refs, $commit);
2489                 my %co = parse_commit($commit);
2490                 if ($alternate) {
2491                         print "<tr class=\"dark\">\n";
2492                 } else {
2493                         print "<tr class=\"light\">\n";
2494                 }
2495                 $alternate ^= 1;
2496                 # git_summary() used print "<td><i>$co{'age_string'}</i></td>\n" .
2497                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
2498                       "<td><i>" . esc_html(chop_str($co{'author_name'}, 10)) . "</i></td>\n" .
2499                       "<td>";
2500                 print format_subject_html($co{'title'}, $co{'title_short'},
2501                                           href(action=>"commit", hash=>$commit), $ref);
2502                 print "</td>\n" .
2503                       "<td class=\"link\">" .
2504                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") . " | " .
2505                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") . " | " .
2506                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree");
2507                 if (gitweb_have_snapshot()) {
2508                         print " | " . $cgi->a({-href => href(action=>"snapshot", hash=>$commit)}, "snapshot");
2509                 }
2510                 print "</td>\n" .
2511                       "</tr>\n";
2512         }
2513         if (defined $extra) {
2514                 print "<tr>\n" .
2515                       "<td colspan=\"4\">$extra</td>\n" .
2516                       "</tr>\n";
2517         }
2518         print "</table>\n";
2519 }
2520
2521 sub git_history_body {
2522         # Warning: assumes constant type (blob or tree) during history
2523         my ($revlist, $from, $to, $refs, $hash_base, $ftype, $extra) = @_;
2524
2525         $from = 0 unless defined $from;
2526         $to = $#{$revlist} unless (defined $to && $to <= $#{$revlist});
2527
2528         print "<table class=\"history\" cellspacing=\"0\">\n";
2529         my $alternate = 1;
2530         for (my $i = $from; $i <= $to; $i++) {
2531                 if ($revlist->[$i] !~ m/^([0-9a-fA-F]{40})/) {
2532                         next;
2533                 }
2534
2535                 my $commit = $1;
2536                 my %co = parse_commit($commit);
2537                 if (!%co) {
2538                         next;
2539                 }
2540
2541                 my $ref = format_ref_marker($refs, $commit);
2542
2543                 if ($alternate) {
2544                         print "<tr class=\"dark\">\n";
2545                 } else {
2546                         print "<tr class=\"light\">\n";
2547                 }
2548                 $alternate ^= 1;
2549                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
2550                       # shortlog uses      chop_str($co{'author_name'}, 10)
2551                       "<td><i>" . esc_html(chop_str($co{'author_name'}, 15, 3)) . "</i></td>\n" .
2552                       "<td>";
2553                 # originally git_history used chop_str($co{'title'}, 50)
2554                 print format_subject_html($co{'title'}, $co{'title_short'},
2555                                           href(action=>"commit", hash=>$commit), $ref);
2556                 print "</td>\n" .
2557                       "<td class=\"link\">" .
2558                       $cgi->a({-href => href(action=>$ftype, hash_base=>$commit, file_name=>$file_name)}, $ftype) . " | " .
2559                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff");
2560
2561                 if ($ftype eq 'blob') {
2562                         my $blob_current = git_get_hash_by_path($hash_base, $file_name);
2563                         my $blob_parent  = git_get_hash_by_path($commit, $file_name);
2564                         if (defined $blob_current && defined $blob_parent &&
2565                                         $blob_current ne $blob_parent) {
2566                                 print " | " .
2567                                         $cgi->a({-href => href(action=>"blobdiff",
2568                                                                hash=>$blob_current, hash_parent=>$blob_parent,
2569                                                                hash_base=>$hash_base, hash_parent_base=>$commit,
2570                                                                file_name=>$file_name)},
2571                                                 "diff to current");
2572                         }
2573                 }
2574                 print "</td>\n" .
2575                       "</tr>\n";
2576         }
2577         if (defined $extra) {
2578                 print "<tr>\n" .
2579                       "<td colspan=\"4\">$extra</td>\n" .
2580                       "</tr>\n";
2581         }
2582         print "</table>\n";
2583 }
2584
2585 sub git_tags_body {
2586         # uses global variable $project
2587         my ($taglist, $from, $to, $extra) = @_;
2588         $from = 0 unless defined $from;
2589         $to = $#{$taglist} if (!defined $to || $#{$taglist} < $to);
2590
2591         print "<table class=\"tags\" cellspacing=\"0\">\n";
2592         my $alternate = 1;
2593         for (my $i = $from; $i <= $to; $i++) {
2594                 my $entry = $taglist->[$i];
2595                 my %tag = %$entry;
2596                 my $comment = $tag{'subject'};
2597                 my $comment_short;
2598                 if (defined $comment) {
2599                         $comment_short = chop_str($comment, 30, 5);
2600                 }
2601                 if ($alternate) {
2602                         print "<tr class=\"dark\">\n";
2603                 } else {
2604                         print "<tr class=\"light\">\n";
2605                 }
2606                 $alternate ^= 1;
2607                 print "<td><i>$tag{'age'}</i></td>\n" .
2608                       "<td>" .
2609                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'}),
2610                                -class => "list name"}, esc_html($tag{'name'})) .
2611                       "</td>\n" .
2612                       "<td>";
2613                 if (defined $comment) {
2614                         print format_subject_html($comment, $comment_short,
2615                                                   href(action=>"tag", hash=>$tag{'id'}));
2616                 }
2617                 print "</td>\n" .
2618                       "<td class=\"selflink\">";
2619                 if ($tag{'type'} eq "tag") {
2620                         print $cgi->a({-href => href(action=>"tag", hash=>$tag{'id'})}, "tag");
2621                 } else {
2622                         print "&nbsp;";
2623                 }
2624                 print "</td>\n" .
2625                       "<td class=\"link\">" . " | " .
2626                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'})}, $tag{'reftype'});
2627                 if ($tag{'reftype'} eq "commit") {
2628                         print " | " . $cgi->a({-href => href(action=>"shortlog", hash=>$tag{'name'})}, "shortlog") .
2629                               " | " . $cgi->a({-href => href(action=>"log", hash=>$tag{'name'})}, "log");
2630                 } elsif ($tag{'reftype'} eq "blob") {
2631                         print " | " . $cgi->a({-href => href(action=>"blob_plain", hash=>$tag{'refid'})}, "raw");
2632                 }
2633                 print "</td>\n" .
2634                       "</tr>";
2635         }
2636         if (defined $extra) {
2637                 print "<tr>\n" .
2638                       "<td colspan=\"5\">$extra</td>\n" .
2639                       "</tr>\n";
2640         }
2641         print "</table>\n";
2642 }
2643
2644 sub git_heads_body {
2645         # uses global variable $project
2646         my ($headlist, $head, $from, $to, $extra) = @_;
2647         $from = 0 unless defined $from;
2648         $to = $#{$headlist} if (!defined $to || $#{$headlist} < $to);
2649
2650         print "<table class=\"heads\" cellspacing=\"0\">\n";
2651         my $alternate = 1;
2652         for (my $i = $from; $i <= $to; $i++) {
2653                 my $entry = $headlist->[$i];
2654                 my %ref = %$entry;
2655                 my $curr = $ref{'id'} eq $head;
2656                 if ($alternate) {
2657                         print "<tr class=\"dark\">\n";
2658                 } else {
2659                         print "<tr class=\"light\">\n";
2660                 }
2661                 $alternate ^= 1;
2662                 print "<td><i>$ref{'age'}</i></td>\n" .
2663                       ($curr ? "<td class=\"current_head\">" : "<td>") .
2664                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'name'}),
2665                                -class => "list name"},esc_html($ref{'name'})) .
2666                       "</td>\n" .
2667                       "<td class=\"link\">" .
2668                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'name'})}, "shortlog") . " | " .
2669                       $cgi->a({-href => href(action=>"log", hash=>$ref{'name'})}, "log") . " | " .
2670                       $cgi->a({-href => href(action=>"tree", hash=>$ref{'name'}, hash_base=>$ref{'name'})}, "tree") .
2671                       "</td>\n" .
2672                       "</tr>";
2673         }
2674         if (defined $extra) {
2675                 print "<tr>\n" .
2676                       "<td colspan=\"3\">$extra</td>\n" .
2677                       "</tr>\n";
2678         }
2679         print "</table>\n";
2680 }
2681
2682 ## ======================================================================
2683 ## ======================================================================
2684 ## actions
2685
2686 sub git_project_list {
2687         my $order = $cgi->param('o');
2688         if (defined $order && $order !~ m/project|descr|owner|age/) {
2689                 die_error(undef, "Unknown order parameter");
2690         }
2691
2692         my @list = git_get_projects_list();
2693         if (!@list) {
2694                 die_error(undef, "No projects found");
2695         }
2696
2697         git_header_html();
2698         if (-f $home_text) {
2699                 print "<div class=\"index_include\">\n";
2700                 open (my $fd, $home_text);
2701                 print <$fd>;
2702                 close $fd;
2703                 print "</div>\n";
2704         }
2705         git_project_list_body(\@list, $order);
2706         git_footer_html();
2707 }
2708
2709 sub git_forks {
2710         my $order = $cgi->param('o');
2711         if (defined $order && $order !~ m/project|descr|owner|age/) {
2712                 die_error(undef, "Unknown order parameter");
2713         }
2714
2715         my @list = git_get_projects_list($project);
2716         if (!@list) {
2717                 die_error(undef, "No forks found");
2718         }
2719
2720         git_header_html();
2721         git_print_page_nav('','');
2722         git_print_header_div('summary', "$project forks");
2723         git_project_list_body(\@list, $order);
2724         git_footer_html();
2725 }
2726
2727 sub git_project_index {
2728         my @projects = git_get_projects_list($project);
2729
2730         print $cgi->header(
2731                 -type => 'text/plain',
2732                 -charset => 'utf-8',
2733                 -content_disposition => 'inline; filename="index.aux"');
2734
2735         foreach my $pr (@projects) {
2736                 if (!exists $pr->{'owner'}) {
2737                         $pr->{'owner'} = get_file_owner("$projectroot/$project");
2738                 }
2739
2740                 my ($path, $owner) = ($pr->{'path'}, $pr->{'owner'});
2741                 # quote as in CGI::Util::encode, but keep the slash, and use '+' for ' '
2742                 $path  =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
2743                 $owner =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
2744                 $path  =~ s/ /\+/g;
2745                 $owner =~ s/ /\+/g;
2746
2747                 print "$path $owner\n";
2748         }
2749 }
2750
2751 sub git_summary {
2752         my $descr = git_get_project_description($project) || "none";
2753         my $head = git_get_head_hash($project);
2754         my %co = parse_commit($head);
2755         my %cd = parse_date($co{'committer_epoch'}, $co{'committer_tz'});
2756
2757         my $owner = git_get_project_owner($project);
2758
2759         my $refs = git_get_references();
2760         my @taglist  = git_get_tags_list(15);
2761         my @headlist = git_get_heads_list(15);
2762         my @forklist;
2763         my ($check_forks) = gitweb_check_feature('forks');
2764
2765         if ($check_forks) {
2766                 @forklist = git_get_projects_list($project);
2767         }
2768
2769         git_header_html();
2770         git_print_page_nav('summary','', $head);
2771
2772         print "<div class=\"title\">&nbsp;</div>\n";
2773         print "<table cellspacing=\"0\">\n" .
2774               "<tr><td>description</td><td>" . esc_html($descr) . "</td></tr>\n" .
2775               "<tr><td>owner</td><td>$owner</td></tr>\n" .
2776               "<tr><td>last change</td><td>$cd{'rfc2822'}</td></tr>\n";
2777         # use per project git URL list in $projectroot/$project/cloneurl
2778         # or make project git URL from git base URL and project name
2779         my $url_tag = "URL";
2780         my @url_list = git_get_project_url_list($project);
2781         @url_list = map { "$_/$project" } @git_base_url_list unless @url_list;
2782         foreach my $git_url (@url_list) {
2783                 next unless $git_url;
2784                 print "<tr><td>$url_tag</td><td>$git_url</td></tr>\n";
2785                 $url_tag = "";
2786         }
2787         print "</table>\n";
2788
2789         if (-s "$projectroot/$project/README.html") {
2790                 if (open my $fd, "$projectroot/$project/README.html") {
2791                         print "<div class=\"title\">readme</div>\n";
2792                         print $_ while (<$fd>);
2793                         close $fd;
2794                 }
2795         }
2796
2797         open my $fd, "-|", git_cmd(), "rev-list", "--max-count=17",
2798                 git_get_head_hash($project), "--"
2799                 or die_error(undef, "Open git-rev-list failed");
2800         my @revlist = map { chomp; $_ } <$fd>;
2801         close $fd;
2802         git_print_header_div('shortlog');
2803         git_shortlog_body(\@revlist, 0, 15, $refs,
2804                           $cgi->a({-href => href(action=>"shortlog")}, "..."));
2805
2806         if (@taglist) {
2807                 git_print_header_div('tags');
2808                 git_tags_body(\@taglist, 0, 15,
2809                               $cgi->a({-href => href(action=>"tags")}, "..."));
2810         }
2811
2812         if (@headlist) {
2813                 git_print_header_div('heads');
2814                 git_heads_body(\@headlist, $head, 0, 15,
2815                                $cgi->a({-href => href(action=>"heads")}, "..."));
2816         }
2817
2818         if (@forklist) {
2819                 git_print_header_div('forks');
2820                 git_project_list_body(\@forklist, undef, 0, 15,
2821                                       $cgi->a({-href => href(action=>"forks")}, "..."),
2822                                       'noheader');
2823         }
2824
2825         git_footer_html();
2826 }
2827
2828 sub git_tag {
2829         my $head = git_get_head_hash($project);
2830         git_header_html();
2831         git_print_page_nav('','', $head,undef,$head);
2832         my %tag = parse_tag($hash);
2833         git_print_header_div('commit', esc_html($tag{'name'}), $hash);
2834         print "<div class=\"title_text\">\n" .
2835               "<table cellspacing=\"0\">\n" .
2836               "<tr>\n" .
2837               "<td>object</td>\n" .
2838               "<td>" . $cgi->a({-class => "list", -href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
2839                                $tag{'object'}) . "</td>\n" .
2840               "<td class=\"link\">" . $cgi->a({-href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
2841                                               $tag{'type'}) . "</td>\n" .
2842               "</tr>\n";
2843         if (defined($tag{'author'})) {
2844                 my %ad = parse_date($tag{'epoch'}, $tag{'tz'});
2845                 print "<tr><td>author</td><td>" . esc_html($tag{'author'}) . "</td></tr>\n";
2846                 print "<tr><td></td><td>" . $ad{'rfc2822'} .
2847                         sprintf(" (%02d:%02d %s)", $ad{'hour_local'}, $ad{'minute_local'}, $ad{'tz_local'}) .
2848                         "</td></tr>\n";
2849         }
2850         print "</table>\n\n" .
2851               "</div>\n";
2852         print "<div class=\"page_body\">";
2853         my $comment = $tag{'comment'};
2854         foreach my $line (@$comment) {
2855                 chomp($line);
2856                 print esc_html($line) . "<br/>\n";
2857         }
2858         print "</div>\n";
2859         git_footer_html();
2860 }
2861
2862 sub git_blame2 {
2863         my $fd;
2864         my $ftype;
2865
2866         my ($have_blame) = gitweb_check_feature('blame');
2867         if (!$have_blame) {
2868                 die_error('403 Permission denied', "Permission denied");
2869         }
2870         die_error('404 Not Found', "File name not defined") if (!$file_name);
2871         $hash_base ||= git_get_head_hash($project);
2872         die_error(undef, "Couldn't find base commit") unless ($hash_base);
2873         my %co = parse_commit($hash_base)
2874                 or die_error(undef, "Reading commit failed");
2875         if (!defined $hash) {
2876                 $hash = git_get_hash_by_path($hash_base, $file_name, "blob")
2877                         or die_error(undef, "Error looking up file");
2878         }
2879         $ftype = git_get_type($hash);
2880         if ($ftype !~ "blob") {
2881                 die_error("400 Bad Request", "Object is not a blob");
2882         }
2883         open ($fd, "-|", git_cmd(), "blame", '-p', '--',
2884               $file_name, $hash_base)
2885                 or die_error(undef, "Open git-blame failed");
2886         git_header_html();
2887         my $formats_nav =
2888                 $cgi->a({-href => href(action=>"blob", hash=>$hash, hash_base=>$hash_base, file_name=>$file_name)},
2889                         "blob") .
2890                 " | " .
2891                 $cgi->a({-href => href(action=>"history", hash=>$hash, hash_base=>$hash_base, file_name=>$file_name)},
2892                         "history") .
2893                 " | " .
2894                 $cgi->a({-href => href(action=>"blame", file_name=>$file_name)},
2895                         "HEAD");
2896         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
2897         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
2898         git_print_page_path($file_name, $ftype, $hash_base);
2899         my @rev_color = (qw(light2 dark2));
2900         my $num_colors = scalar(@rev_color);
2901         my $current_color = 0;
2902         my $last_rev;
2903         print <<HTML;
2904 <div class="page_body">
2905 <table class="blame">
2906 <tr><th>Commit</th><th>Line</th><th>Data</th></tr>
2907 HTML
2908         my %metainfo = ();
2909         while (1) {
2910                 $_ = <$fd>;
2911                 last unless defined $_;
2912                 my ($full_rev, $orig_lineno, $lineno, $group_size) =
2913                     /^([0-9a-f]{40}) (\d+) (\d+)(?: (\d+))?$/;
2914                 if (!exists $metainfo{$full_rev}) {
2915                         $metainfo{$full_rev} = {};
2916                 }
2917                 my $meta = $metainfo{$full_rev};
2918                 while (<$fd>) {
2919                         last if (s/^\t//);
2920                         if (/^(\S+) (.*)$/) {
2921                                 $meta->{$1} = $2;
2922                         }
2923                 }
2924                 my $data = $_;
2925                 chomp($data);
2926                 my $rev = substr($full_rev, 0, 8);
2927                 my $author = $meta->{'author'};
2928                 my %date = parse_date($meta->{'author-time'},
2929                                       $meta->{'author-tz'});
2930                 my $date = $date{'iso-tz'};
2931                 if ($group_size) {
2932                         $current_color = ++$current_color % $num_colors;
2933                 }
2934                 print "<tr class=\"$rev_color[$current_color]\">\n";
2935                 if ($group_size) {
2936                         print "<td class=\"sha1\"";
2937                         print " title=\"". esc_html($author) . ", $date\"";
2938                         print " rowspan=\"$group_size\"" if ($group_size > 1);
2939                         print ">";
2940                         print $cgi->a({-href => href(action=>"commit",
2941                                                      hash=>$full_rev,
2942                                                      file_name=>$file_name)},
2943                                       esc_html($rev));
2944                         print "</td>\n";
2945                 }
2946                 my $blamed = href(action => 'blame',
2947                                   file_name => $meta->{'filename'},
2948                                   hash_base => $full_rev);
2949                 print "<td class=\"linenr\">";
2950                 print $cgi->a({ -href => "$blamed#l$orig_lineno",
2951                                 -id => "l$lineno",
2952                                 -class => "linenr" },
2953                               esc_html($lineno));
2954                 print "</td>";
2955                 print "<td class=\"pre\">" . esc_html($data) . "</td>\n";
2956                 print "</tr>\n";
2957         }
2958         print "</table>\n";
2959         print "</div>";
2960         close $fd
2961                 or print "Reading blob failed\n";
2962         git_footer_html();
2963 }
2964
2965 sub git_blame {
2966         my $fd;
2967
2968         my ($have_blame) = gitweb_check_feature('blame');
2969         if (!$have_blame) {
2970                 die_error('403 Permission denied', "Permission denied");
2971         }
2972         die_error('404 Not Found', "File name not defined") if (!$file_name);
2973         $hash_base ||= git_get_head_hash($project);
2974         die_error(undef, "Couldn't find base commit") unless ($hash_base);
2975         my %co = parse_commit($hash_base)
2976                 or die_error(undef, "Reading commit failed");
2977         if (!defined $hash) {
2978                 $hash = git_get_hash_by_path($hash_base, $file_name, "blob")
2979                         or die_error(undef, "Error lookup file");
2980         }
2981         open ($fd, "-|", git_cmd(), "annotate", '-l', '-t', '-r', $file_name, $hash_base)
2982                 or die_error(undef, "Open git-annotate failed");
2983         git_header_html();
2984         my $formats_nav =
2985                 $cgi->a({-href => href(action=>"blob", hash=>$hash, hash_base=>$hash_base, file_name=>$file_name)},
2986                         "blob") .
2987                 " | " .
2988                 $cgi->a({-href => href(action=>"history", hash=>$hash, hash_base=>$hash_base, file_name=>$file_name)},
2989                         "history") .
2990                 " | " .
2991                 $cgi->a({-href => href(action=>"blame", file_name=>$file_name)},
2992                         "HEAD");
2993         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
2994         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
2995         git_print_page_path($file_name, 'blob', $hash_base);
2996         print "<div class=\"page_body\">\n";
2997         print <<HTML;
2998 <table class="blame">
2999   <tr>
3000     <th>Commit</th>
3001     <th>Age</th>
3002     <th>Author</th>
3003     <th>Line</th>
3004     <th>Data</th>
3005   </tr>
3006 HTML
3007         my @line_class = (qw(light dark));
3008         my $line_class_len = scalar (@line_class);
3009         my $line_class_num = $#line_class;
3010         while (my $line = <$fd>) {
3011                 my $long_rev;
3012                 my $short_rev;
3013                 my $author;
3014                 my $time;
3015                 my $lineno;
3016                 my $data;
3017                 my $age;
3018                 my $age_str;
3019                 my $age_class;
3020
3021                 chomp $line;
3022                 $line_class_num = ($line_class_num + 1) % $line_class_len;
3023
3024                 if ($line =~ m/^([0-9a-fA-F]{40})\t\(\s*([^\t]+)\t(\d+) [+-]\d\d\d\d\t(\d+)\)(.*)$/) {
3025                         $long_rev = $1;
3026                         $author   = $2;
3027                         $time     = $3;
3028                         $lineno   = $4;
3029                         $data     = $5;
3030                 } else {
3031                         print qq(  <tr><td colspan="5" class="error">Unable to parse: $line</td></tr>\n);
3032                         next;
3033                 }
3034                 $short_rev  = substr ($long_rev, 0, 8);
3035                 $age        = time () - $time;
3036                 $age_str    = age_string ($age);
3037                 $age_str    =~ s/ /&nbsp;/g;
3038                 $age_class  = age_class($age);
3039                 $author     = esc_html ($author);
3040                 $author     =~ s/ /&nbsp;/g;
3041
3042                 $data = untabify($data);
3043                 $data = esc_html ($data);
3044
3045                 print <<HTML;
3046   <tr class="$line_class[$line_class_num]">
3047     <td class="sha1"><a href="${\href (action=>"commit", hash=>$long_rev)}" class="text">$short_rev..</a></td>
3048     <td class="$age_class">$age_str</td>
3049     <td>$author</td>
3050     <td class="linenr"><a id="$lineno" href="#$lineno" class="linenr">$lineno</a></td>
3051     <td class="pre">$data</td>
3052   </tr>
3053 HTML
3054         } # while (my $line = <$fd>)
3055         print "</table>\n\n";
3056         close $fd
3057                 or print "Reading blob failed.\n";
3058         print "</div>";
3059         git_footer_html();
3060 }
3061
3062 sub git_tags {
3063         my $head = git_get_head_hash($project);
3064         git_header_html();
3065         git_print_page_nav('','', $head,undef,$head);
3066         git_print_header_div('summary', $project);
3067
3068         my @tagslist = git_get_tags_list();
3069         if (@tagslist) {
3070                 git_tags_body(\@tagslist);
3071         }
3072         git_footer_html();
3073 }
3074
3075 sub git_heads {
3076         my $head = git_get_head_hash($project);
3077         git_header_html();
3078         git_print_page_nav('','', $head,undef,$head);
3079         git_print_header_div('summary', $project);
3080
3081         my @headslist = git_get_heads_list();
3082         if (@headslist) {
3083                 git_heads_body(\@headslist, $head);
3084         }
3085         git_footer_html();
3086 }
3087
3088 sub git_blob_plain {
3089         my $expires;
3090
3091         if (!defined $hash) {
3092                 if (defined $file_name) {
3093                         my $base = $hash_base || git_get_head_hash($project);
3094                         $hash = git_get_hash_by_path($base, $file_name, "blob")
3095                                 or die_error(undef, "Error lookup file");
3096                 } else {
3097                         die_error(undef, "No file name defined");
3098                 }
3099         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
3100                 # blobs defined by non-textual hash id's can be cached
3101                 $expires = "+1d";
3102         }
3103
3104         my $type = shift;
3105         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
3106                 or die_error(undef, "Couldn't cat $file_name, $hash");
3107
3108         $type ||= blob_mimetype($fd, $file_name);
3109
3110         # save as filename, even when no $file_name is given
3111         my $save_as = "$hash";
3112         if (defined $file_name) {
3113                 $save_as = $file_name;
3114         } elsif ($type =~ m/^text\//) {
3115                 $save_as .= '.txt';
3116         }
3117
3118         print $cgi->header(
3119                 -type => "$type",
3120                 -expires=>$expires,
3121                 -content_disposition => 'inline; filename="' . "$save_as" . '"');
3122         undef $/;
3123         binmode STDOUT, ':raw';
3124         print <$fd>;
3125         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
3126         $/ = "\n";
3127         close $fd;
3128 }
3129
3130 sub git_blob {
3131         my $expires;
3132
3133         if (!defined $hash) {
3134                 if (defined $file_name) {
3135                         my $base = $hash_base || git_get_head_hash($project);
3136                         $hash = git_get_hash_by_path($base, $file_name, "blob")
3137                                 or die_error(undef, "Error lookup file");
3138                 } else {
3139                         die_error(undef, "No file name defined");
3140                 }
3141         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
3142                 # blobs defined by non-textual hash id's can be cached
3143                 $expires = "+1d";
3144         }
3145
3146         my ($have_blame) = gitweb_check_feature('blame');
3147         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
3148                 or die_error(undef, "Couldn't cat $file_name, $hash");
3149         my $mimetype = blob_mimetype($fd, $file_name);
3150         if ($mimetype !~ m/^text\//) {
3151                 close $fd;
3152                 return git_blob_plain($mimetype);
3153         }
3154         git_header_html(undef, $expires);
3155         my $formats_nav = '';
3156         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
3157                 if (defined $file_name) {
3158                         if ($have_blame) {
3159                                 $formats_nav .=
3160                                         $cgi->a({-href => href(action=>"blame", hash_base=>$hash_base,
3161                                                                hash=>$hash, file_name=>$file_name)},
3162                                                 "blame") .
3163                                         " | ";
3164                         }
3165                         $formats_nav .=
3166                                 $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
3167                                                        hash=>$hash, file_name=>$file_name)},
3168                                         "history") .
3169                                 " | " .
3170                                 $cgi->a({-href => href(action=>"blob_plain",
3171                                                        hash=>$hash, file_name=>$file_name)},
3172                                         "raw") .
3173                                 " | " .
3174                                 $cgi->a({-href => href(action=>"blob",
3175                                                        hash_base=>"HEAD", file_name=>$file_name)},
3176                                         "HEAD");
3177                 } else {
3178                         $formats_nav .=
3179                                 $cgi->a({-href => href(action=>"blob_plain", hash=>$hash)}, "raw");
3180                 }
3181                 git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
3182                 git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
3183         } else {
3184                 print "<div class=\"page_nav\">\n" .
3185                       "<br/><br/></div>\n" .
3186                       "<div class=\"title\">$hash</div>\n";
3187         }
3188         git_print_page_path($file_name, "blob", $hash_base);
3189         print "<div class=\"page_body\">\n";
3190         my $nr;
3191         while (my $line = <$fd>) {
3192                 chomp $line;
3193                 $nr++;
3194                 $line = untabify($line);
3195                 printf "<div class=\"pre\"><a id=\"l%i\" href=\"#l%i\" class=\"linenr\">%4i</a> %s</div>\n",
3196                        $nr, $nr, $nr, esc_html($line, -nbsp=>1);
3197         }
3198         close $fd
3199                 or print "Reading blob failed.\n";
3200         print "</div>";
3201         git_footer_html();
3202 }
3203
3204 sub git_tree {
3205         my $have_snapshot = gitweb_have_snapshot();
3206
3207         if (!defined $hash_base) {
3208                 $hash_base = "HEAD";
3209         }
3210         if (!defined $hash) {
3211                 if (defined $file_name) {
3212                         $hash = git_get_hash_by_path($hash_base, $file_name, "tree");
3213                 } else {
3214                         $hash = $hash_base;
3215                 }
3216         }
3217         $/ = "\0";
3218         open my $fd, "-|", git_cmd(), "ls-tree", '-z', $hash
3219                 or die_error(undef, "Open git-ls-tree failed");
3220         my @entries = map { chomp; $_ } <$fd>;
3221         close $fd or die_error(undef, "Reading tree failed");
3222         $/ = "\n";
3223
3224         my $refs = git_get_references();
3225         my $ref = format_ref_marker($refs, $hash_base);
3226         git_header_html();
3227         my $basedir = '';
3228         my ($have_blame) = gitweb_check_feature('blame');
3229         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
3230                 my @views_nav = ();
3231                 if (defined $file_name) {
3232                         push @views_nav,
3233                                 $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
3234                                                        hash=>$hash, file_name=>$file_name)},
3235                                         "history"),
3236                                 $cgi->a({-href => href(action=>"tree",
3237                                                        hash_base=>"HEAD", file_name=>$file_name)},
3238                                         "HEAD"),
3239                 }
3240                 if ($have_snapshot) {
3241                         # FIXME: Should be available when we have no hash base as well.
3242                         push @views_nav,
3243                                 $cgi->a({-href => href(action=>"snapshot", hash=>$hash)},
3244                                         "snapshot");
3245                 }
3246                 git_print_page_nav('tree','', $hash_base, undef, undef, join(' | ', @views_nav));
3247                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash_base);
3248         } else {
3249                 undef $hash_base;
3250                 print "<div class=\"page_nav\">\n";
3251                 print "<br/><br/></div>\n";
3252                 print "<div class=\"title\">$hash</div>\n";
3253         }
3254         if (defined $file_name) {
3255                 $basedir = $file_name;
3256                 if ($basedir ne '' && substr($basedir, -1) ne '/') {
3257                         $basedir .= '/';
3258                 }
3259         }
3260         git_print_page_path($file_name, 'tree', $hash_base);
3261         print "<div class=\"page_body\">\n";
3262         print "<table cellspacing=\"0\">\n";
3263         my $alternate = 1;
3264         # '..' (top directory) link if possible
3265         if (defined $hash_base &&
3266             defined $file_name && $file_name =~ m![^/]+$!) {
3267                 if ($alternate) {
3268                         print "<tr class=\"dark\">\n";
3269                 } else {
3270                         print "<tr class=\"light\">\n";
3271                 }
3272                 $alternate ^= 1;
3273
3274                 my $up = $file_name;
3275                 $up =~ s!/?[^/]+$!!;
3276                 undef $up unless $up;
3277                 # based on git_print_tree_entry
3278                 print '<td class="mode">' . mode_str('040000') . "</td>\n";
3279                 print '<td class="list">';
3280                 print $cgi->a({-href => href(action=>"tree", hash_base=>$hash_base,
3281                                              file_name=>$up)},
3282                               "..");
3283                 print "</td>\n";
3284                 print "<td class=\"link\"></td>\n";
3285
3286                 print "</tr>\n";
3287         }
3288         foreach my $line (@entries) {
3289                 my %t = parse_ls_tree_line($line, -z => 1);
3290
3291                 if ($alternate) {
3292                         print "<tr class=\"dark\">\n";
3293                 } else {
3294                         print "<tr class=\"light\">\n";
3295                 }
3296                 $alternate ^= 1;
3297
3298                 git_print_tree_entry(\%t, $basedir, $hash_base, $have_blame);
3299
3300                 print "</tr>\n";
3301         }
3302         print "</table>\n" .
3303               "</div>";
3304         git_footer_html();
3305 }
3306
3307 sub git_snapshot {
3308         my ($ctype, $suffix, $command) = gitweb_check_feature('snapshot');
3309         my $have_snapshot = (defined $ctype && defined $suffix);
3310         if (!$have_snapshot) {
3311                 die_error('403 Permission denied', "Permission denied");
3312         }
3313
3314         if (!defined $hash) {
3315                 $hash = git_get_head_hash($project);
3316         }
3317
3318         my $filename = basename($project) . "-$hash.tar.$suffix";
3319
3320         print $cgi->header(
3321                 -type => 'application/x-tar',
3322                 -content_encoding => $ctype,
3323                 -content_disposition => 'inline; filename="' . "$filename" . '"',
3324                 -status => '200 OK');
3325
3326         my $git = git_cmd_str();
3327         my $name = $project;
3328         $name =~ s/\047/\047\\\047\047/g;
3329         open my $fd, "-|",
3330         "$git archive --format=tar --prefix=\'$name\'/ $hash | $command"
3331                 or die_error(undef, "Execute git-tar-tree failed.");
3332         binmode STDOUT, ':raw';
3333         print <$fd>;
3334         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
3335         close $fd;
3336
3337 }
3338
3339 sub git_log {
3340         my $head = git_get_head_hash($project);
3341         if (!defined $hash) {
3342                 $hash = $head;
3343         }
3344         if (!defined $page) {
3345                 $page = 0;
3346         }
3347         my $refs = git_get_references();
3348
3349         my $limit = sprintf("--max-count=%i", (100 * ($page+1)));
3350         open my $fd, "-|", git_cmd(), "rev-list", $limit, $hash, "--"
3351                 or die_error(undef, "Open git-rev-list failed");
3352         my @revlist = map { chomp; $_ } <$fd>;
3353         close $fd;
3354
3355         my $paging_nav = format_paging_nav('log', $hash, $head, $page, $#revlist);
3356
3357         git_header_html();
3358         git_print_page_nav('log','', $hash,undef,undef, $paging_nav);
3359
3360         if (!@revlist) {
3361                 my %co = parse_commit($hash);
3362
3363                 git_print_header_div('summary', $project);
3364                 print "<div class=\"page_body\"> Last change $co{'age_string'}.<br/><br/></div>\n";
3365         }
3366         for (my $i = ($page * 100); $i <= $#revlist; $i++) {
3367                 my $commit = $revlist[$i];
3368                 my $ref = format_ref_marker($refs, $commit);
3369                 my %co = parse_commit($commit);
3370                 next if !%co;
3371                 my %ad = parse_date($co{'author_epoch'});
3372                 git_print_header_div('commit',
3373                                "<span class=\"age\">$co{'age_string'}</span>" .
3374                                esc_html($co{'title'}) . $ref,
3375                                $commit);
3376                 print "<div class=\"title_text\">\n" .
3377                       "<div class=\"log_link\">\n" .
3378                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") .
3379                       " | " .
3380                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") .
3381                       " | " .
3382                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree") .
3383                       "<br/>\n" .
3384                       "</div>\n" .
3385                       "<i>" . esc_html($co{'author_name'}) .  " [$ad{'rfc2822'}]</i><br/>\n" .
3386                       "</div>\n";
3387
3388                 print "<div class=\"log_body\">\n";
3389                 git_print_log($co{'comment'}, -final_empty_line=> 1);
3390                 print "</div>\n";
3391         }
3392         git_footer_html();
3393 }
3394
3395 sub git_commit {
3396         my %co = parse_commit($hash);
3397         if (!%co) {
3398                 die_error(undef, "Unknown commit object");
3399         }
3400         my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
3401         my %cd = parse_date($co{'committer_epoch'}, $co{'committer_tz'});
3402
3403         my $parent = $co{'parent'};
3404         if (!defined $parent) {
3405                 $parent = "--root";
3406         }
3407         open my $fd, "-|", git_cmd(), "diff-tree", '-r', "--no-commit-id",
3408                 @diff_opts, $parent, $hash, "--"
3409                 or die_error(undef, "Open git-diff-tree failed");
3410         my @difftree = map { chomp; $_ } <$fd>;
3411         close $fd or die_error(undef, "Reading git-diff-tree failed");
3412
3413         # non-textual hash id's can be cached
3414         my $expires;
3415         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
3416                 $expires = "+1d";
3417         }
3418         my $refs = git_get_references();
3419         my $ref = format_ref_marker($refs, $co{'id'});
3420
3421         my $have_snapshot = gitweb_have_snapshot();
3422
3423         my @views_nav = ();
3424         if (defined $file_name && defined $co{'parent'}) {
3425                 push @views_nav,
3426                         $cgi->a({-href => href(action=>"blame", hash_parent=>$parent, file_name=>$file_name)},
3427                                 "blame");
3428         }
3429         git_header_html(undef, $expires);
3430         git_print_page_nav('commit', '',
3431                            $hash, $co{'tree'}, $hash,
3432                            join (' | ', @views_nav));
3433
3434         if (defined $co{'parent'}) {
3435                 git_print_header_div('commitdiff', esc_html($co{'title'}) . $ref, $hash);
3436         } else {
3437                 git_print_header_div('tree', esc_html($co{'title'}) . $ref, $co{'tree'}, $hash);
3438         }
3439         print "<div class=\"title_text\">\n" .
3440               "<table cellspacing=\"0\">\n";
3441         print "<tr><td>author</td><td>" . esc_html($co{'author'}) . "</td></tr>\n".
3442               "<tr>" .
3443               "<td></td><td> $ad{'rfc2822'}";
3444         if ($ad{'hour_local'} < 6) {
3445                 printf(" (<span class=\"atnight\">%02d:%02d</span> %s)",
3446                        $ad{'hour_local'}, $ad{'minute_local'}, $ad{'tz_local'});
3447         } else {
3448                 printf(" (%02d:%02d %s)",
3449                        $ad{'hour_local'}, $ad{'minute_local'}, $ad{'tz_local'});
3450         }
3451         print "</td>" .
3452               "</tr>\n";
3453         print "<tr><td>committer</td><td>" . esc_html($co{'committer'}) . "</td></tr>\n";
3454         print "<tr><td></td><td> $cd{'rfc2822'}" .
3455               sprintf(" (%02d:%02d %s)", $cd{'hour_local'}, $cd{'minute_local'}, $cd{'tz_local'}) .
3456               "</td></tr>\n";
3457         print "<tr><td>commit</td><td class=\"sha1\">$co{'id'}</td></tr>\n";
3458         print "<tr>" .
3459               "<td>tree</td>" .
3460               "<td class=\"sha1\">" .
3461               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash),
3462                        class => "list"}, $co{'tree'}) .
3463               "</td>" .
3464               "<td class=\"link\">" .
3465               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash)},
3466                       "tree");
3467         if ($have_snapshot) {
3468                 print " | " .
3469                       $cgi->a({-href => href(action=>"snapshot", hash=>$hash)}, "snapshot");
3470         }
3471         print "</td>" .
3472               "</tr>\n";
3473         my $parents = $co{'parents'};
3474         foreach my $par (@$parents) {
3475                 print "<tr>" .
3476                       "<td>parent</td>" .
3477                       "<td class=\"sha1\">" .
3478                       $cgi->a({-href => href(action=>"commit", hash=>$par),
3479                                class => "list"}, $par) .
3480                       "</td>" .
3481                       "<td class=\"link\">" .
3482                       $cgi->a({-href => href(action=>"commit", hash=>$par)}, "commit") .
3483                       " | " .
3484                       $cgi->a({-href => href(action=>"commitdiff", hash=>$hash, hash_parent=>$par)}, "diff") .
3485                       "</td>" .
3486                       "</tr>\n";
3487         }
3488         print "</table>".
3489               "</div>\n";
3490
3491         print "<div class=\"page_body\">\n";
3492         git_print_log($co{'comment'});
3493         print "</div>\n";
3494
3495         git_difftree_body(\@difftree, $hash, $parent);
3496
3497         git_footer_html();
3498 }
3499
3500 sub git_blobdiff {
3501         my $format = shift || 'html';
3502
3503         my $fd;
3504         my @difftree;
3505         my %diffinfo;
3506         my $expires;
3507
3508         # preparing $fd and %diffinfo for git_patchset_body
3509         # new style URI
3510         if (defined $hash_base && defined $hash_parent_base) {
3511                 if (defined $file_name) {
3512                         # read raw output
3513                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
3514                                 $hash_parent_base, $hash_base,
3515                                 "--", $file_name
3516                                 or die_error(undef, "Open git-diff-tree failed");
3517                         @difftree = map { chomp; $_ } <$fd>;
3518                         close $fd
3519                                 or die_error(undef, "Reading git-diff-tree failed");
3520                         @difftree
3521                                 or die_error('404 Not Found', "Blob diff not found");
3522
3523                 } elsif (defined $hash &&
3524                          $hash =~ /[0-9a-fA-F]{40}/) {
3525                         # try to find filename from $hash
3526
3527                         # read filtered raw output
3528                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
3529                                 $hash_parent_base, $hash_base, "--"
3530                                 or die_error(undef, "Open git-diff-tree failed");
3531                         @difftree =
3532                                 # ':100644 100644 03b21826... 3b93d5e7... M     ls-files.c'
3533                                 # $hash == to_id
3534                                 grep { /^:[0-7]{6} [0-7]{6} [0-9a-fA-F]{40} $hash/ }
3535                                 map { chomp; $_ } <$fd>;
3536                         close $fd
3537                                 or die_error(undef, "Reading git-diff-tree failed");
3538                         @difftree
3539                                 or die_error('404 Not Found', "Blob diff not found");
3540
3541                 } else {
3542                         die_error('404 Not Found', "Missing one of the blob diff parameters");
3543                 }
3544
3545                 if (@difftree > 1) {
3546                         die_error('404 Not Found', "Ambiguous blob diff specification");
3547                 }
3548
3549                 %diffinfo = parse_difftree_raw_line($difftree[0]);
3550                 $file_parent ||= $diffinfo{'from_file'} || $file_name || $diffinfo{'file'};
3551                 $file_name   ||= $diffinfo{'to_file'}   || $diffinfo{'file'};
3552
3553                 $hash_parent ||= $diffinfo{'from_id'};
3554                 $hash        ||= $diffinfo{'to_id'};
3555
3556                 # non-textual hash id's can be cached
3557                 if ($hash_base =~ m/^[0-9a-fA-F]{40}$/ &&
3558                     $hash_parent_base =~ m/^[0-9a-fA-F]{40}$/) {
3559                         $expires = '+1d';
3560                 }
3561
3562                 # open patch output
3563                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
3564                         '-p', $hash_parent_base, $hash_base,
3565                         "--", $file_name
3566                         or die_error(undef, "Open git-diff-tree failed");
3567         }
3568
3569         # old/legacy style URI
3570         if (!%diffinfo && # if new style URI failed
3571             defined $hash && defined $hash_parent) {
3572                 # fake git-diff-tree raw output
3573                 $diffinfo{'from_mode'} = $diffinfo{'to_mode'} = "blob";
3574                 $diffinfo{'from_id'} = $hash_parent;
3575                 $diffinfo{'to_id'}   = $hash;
3576                 if (defined $file_name) {
3577                         if (defined $file_parent) {
3578                                 $diffinfo{'status'} = '2';
3579                                 $diffinfo{'from_file'} = $file_parent;
3580                                 $diffinfo{'to_file'}   = $file_name;
3581                         } else { # assume not renamed
3582                                 $diffinfo{'status'} = '1';
3583                                 $diffinfo{'from_file'} = $file_name;
3584                                 $diffinfo{'to_file'}   = $file_name;
3585                         }
3586                 } else { # no filename given
3587                         $diffinfo{'status'} = '2';
3588                         $diffinfo{'from_file'} = $hash_parent;
3589                         $diffinfo{'to_file'}   = $hash;
3590                 }
3591
3592                 # non-textual hash id's can be cached
3593                 if ($hash =~ m/^[0-9a-fA-F]{40}$/ &&
3594                     $hash_parent =~ m/^[0-9a-fA-F]{40}$/) {
3595                         $expires = '+1d';
3596                 }
3597
3598                 # open patch output
3599                 open $fd, "-|", git_cmd(), "diff", '-p', @diff_opts,
3600                         $hash_parent, $hash, "--"
3601                         or die_error(undef, "Open git-diff failed");
3602         } else  {
3603                 die_error('404 Not Found', "Missing one of the blob diff parameters")
3604                         unless %diffinfo;
3605         }
3606
3607         # header
3608         if ($format eq 'html') {
3609                 my $formats_nav =
3610                         $cgi->a({-href => href(action=>"blobdiff_plain",
3611                                                hash=>$hash, hash_parent=>$hash_parent,
3612                                                hash_base=>$hash_base, hash_parent_base=>$hash_parent_base,
3613                                                file_name=>$file_name, file_parent=>$file_parent)},
3614                                 "raw");
3615                 git_header_html(undef, $expires);
3616                 if (defined $hash_base && (my %co = parse_commit($hash_base))) {
3617                         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
3618                         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
3619                 } else {
3620                         print "<div class=\"page_nav\"><br/>$formats_nav<br/></div>\n";
3621                         print "<div class=\"title\">$hash vs $hash_parent</div>\n";
3622                 }
3623                 if (defined $file_name) {
3624                         git_print_page_path($file_name, "blob", $hash_base);
3625                 } else {
3626                         print "<div class=\"page_path\"></div>\n";
3627                 }
3628
3629         } elsif ($format eq 'plain') {
3630                 print $cgi->header(
3631                         -type => 'text/plain',
3632                         -charset => 'utf-8',
3633                         -expires => $expires,
3634                         -content_disposition => 'inline; filename="' . "$file_name" . '.patch"');
3635
3636                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
3637
3638         } else {
3639                 die_error(undef, "Unknown blobdiff format");
3640         }
3641
3642         # patch
3643         if ($format eq 'html') {
3644                 print "<div class=\"page_body\">\n";
3645
3646                 git_patchset_body($fd, [ \%diffinfo ], $hash_base, $hash_parent_base);
3647                 close $fd;
3648
3649                 print "</div>\n"; # class="page_body"
3650                 git_footer_html();
3651
3652         } else {
3653                 while (my $line = <$fd>) {
3654                         $line =~ s!a/($hash|$hash_parent)!'a/'.esc_path($diffinfo{'from_file'})!eg;
3655                         $line =~ s!b/($hash|$hash_parent)!'b/'.esc_path($diffinfo{'to_file'})!eg;
3656
3657                         print $line;
3658
3659                         last if $line =~ m!^\+\+\+!;
3660                 }
3661                 local $/ = undef;
3662                 print <$fd>;
3663                 close $fd;
3664         }
3665 }
3666
3667 sub git_blobdiff_plain {
3668         git_blobdiff('plain');
3669 }
3670
3671 sub git_commitdiff {
3672         my $format = shift || 'html';
3673         my %co = parse_commit($hash);
3674         if (!%co) {
3675                 die_error(undef, "Unknown commit object");
3676         }
3677
3678         # we need to prepare $formats_nav before any parameter munging
3679         my $formats_nav;
3680         if ($format eq 'html') {
3681                 $formats_nav =
3682                         $cgi->a({-href => href(action=>"commitdiff_plain",
3683                                                hash=>$hash, hash_parent=>$hash_parent)},
3684                                 "raw");
3685
3686                 if (defined $hash_parent) {
3687                         # commitdiff with two commits given
3688                         my $hash_parent_short = $hash_parent;
3689                         if ($hash_parent =~ m/^[0-9a-fA-F]{40}$/) {
3690                                 $hash_parent_short = substr($hash_parent, 0, 7);
3691                         }
3692                         $formats_nav .=
3693                                 ' (from: ' .
3694                                 $cgi->a({-href => href(action=>"commitdiff",
3695                                                        hash=>$hash_parent)},
3696                                         esc_html($hash_parent_short)) .
3697                                 ')';
3698                 } elsif (!$co{'parent'}) {
3699                         # --root commitdiff
3700                         $formats_nav .= ' (initial)';
3701                 } elsif (scalar @{$co{'parents'}} == 1) {
3702                         # single parent commit
3703                         $formats_nav .=
3704                                 ' (parent: ' .
3705                                 $cgi->a({-href => href(action=>"commitdiff",
3706                                                        hash=>$co{'parent'})},
3707                                         esc_html(substr($co{'parent'}, 0, 7))) .
3708                                 ')';
3709                 } else {
3710                         # merge commit
3711                         $formats_nav .=
3712                                 ' (merge: ' .
3713                                 join(' ', map {
3714                                         $cgi->a({-href => href(action=>"commitdiff",
3715                                                                hash=>$_)},
3716                                                 esc_html(substr($_, 0, 7)));
3717                                 } @{$co{'parents'}} ) .
3718                                 ')';
3719                 }
3720         }
3721
3722         if (!defined $hash_parent) {
3723                 $hash_parent = $co{'parent'} || '--root';
3724         }
3725
3726         # read commitdiff
3727         my $fd;
3728         my @difftree;
3729         if ($format eq 'html') {
3730                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
3731                         "--no-commit-id", "--patch-with-raw", "--full-index",
3732                         $hash_parent, $hash, "--"
3733                         or die_error(undef, "Open git-diff-tree failed");
3734
3735                 while (chomp(my $line = <$fd>)) {
3736                         # empty line ends raw part of diff-tree output
3737                         last unless $line;
3738                         push @difftree, $line;
3739                 }
3740
3741         } elsif ($format eq 'plain') {
3742                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
3743                         '-p', $hash_parent, $hash, "--"
3744                         or die_error(undef, "Open git-diff-tree failed");
3745
3746         } else {
3747                 die_error(undef, "Unknown commitdiff format");
3748         }
3749
3750         # non-textual hash id's can be cached
3751         my $expires;
3752         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
3753                 $expires = "+1d";
3754         }
3755
3756         # write commit message
3757         if ($format eq 'html') {
3758                 my $refs = git_get_references();
3759                 my $ref = format_ref_marker($refs, $co{'id'});
3760
3761                 git_header_html(undef, $expires);
3762                 git_print_page_nav('commitdiff','', $hash,$co{'tree'},$hash, $formats_nav);
3763                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash);
3764                 git_print_authorship(\%co);
3765                 print "<div class=\"page_body\">\n";
3766                 if (@{$co{'comment'}} > 1) {
3767                         print "<div class=\"log\">\n";
3768                         git_print_log($co{'comment'}, -final_empty_line=> 1, -remove_title => 1);
3769                         print "</div>\n"; # class="log"
3770                 }
3771
3772         } elsif ($format eq 'plain') {
3773                 my $refs = git_get_references("tags");
3774                 my $tagname = git_get_rev_name_tags($hash);
3775                 my $filename = basename($project) . "-$hash.patch";
3776
3777                 print $cgi->header(
3778                         -type => 'text/plain',
3779                         -charset => 'utf-8',
3780                         -expires => $expires,
3781                         -content_disposition => 'inline; filename="' . "$filename" . '"');
3782                 my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
3783                 print <<TEXT;
3784 From: $co{'author'}
3785 Date: $ad{'rfc2822'} ($ad{'tz_local'})
3786 Subject: $co{'title'}
3787 TEXT
3788                 print "X-Git-Tag: $tagname\n" if $tagname;
3789                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
3790
3791                 foreach my $line (@{$co{'comment'}}) {
3792                         print "$line\n";
3793                 }
3794                 print "---\n\n";
3795         }
3796
3797         # write patch
3798         if ($format eq 'html') {
3799                 git_difftree_body(\@difftree, $hash, $hash_parent);
3800                 print "<br/>\n";
3801
3802                 git_patchset_body($fd, \@difftree, $hash, $hash_parent);
3803                 close $fd;
3804                 print "</div>\n"; # class="page_body"
3805                 git_footer_html();
3806
3807         } elsif ($format eq 'plain') {
3808                 local $/ = undef;
3809                 print <$fd>;
3810                 close $fd
3811                         or print "Reading git-diff-tree failed\n";
3812         }
3813 }
3814
3815 sub git_commitdiff_plain {
3816         git_commitdiff('plain');
3817 }
3818
3819 sub git_history {
3820         if (!defined $hash_base) {
3821                 $hash_base = git_get_head_hash($project);
3822         }
3823         if (!defined $page) {
3824                 $page = 0;
3825         }
3826         my $ftype;
3827         my %co = parse_commit($hash_base);
3828         if (!%co) {
3829                 die_error(undef, "Unknown commit object");
3830         }
3831
3832         my $refs = git_get_references();
3833         my $limit = sprintf("--max-count=%i", (100 * ($page+1)));
3834
3835         if (!defined $hash && defined $file_name) {
3836                 $hash = git_get_hash_by_path($hash_base, $file_name);
3837         }
3838         if (defined $hash) {
3839                 $ftype = git_get_type($hash);
3840         }
3841
3842         open my $fd, "-|",
3843                 git_cmd(), "rev-list", $limit, "--full-history", $hash_base, "--", $file_name
3844                         or die_error(undef, "Open git-rev-list-failed");
3845         my @revlist = map { chomp; $_ } <$fd>;
3846         close $fd
3847                 or die_error(undef, "Reading git-rev-list failed");
3848
3849         my $paging_nav = '';
3850         if ($page > 0) {
3851                 $paging_nav .=
3852                         $cgi->a({-href => href(action=>"history", hash=>$hash, hash_base=>$hash_base,
3853                                                file_name=>$file_name)},
3854                                 "first");
3855                 $paging_nav .= " &sdot; " .
3856                         $cgi->a({-href => href(action=>"history", hash=>$hash, hash_base=>$hash_base,
3857                                                file_name=>$file_name, page=>$page-1),
3858                                  -accesskey => "p", -title => "Alt-p"}, "prev");
3859         } else {
3860                 $paging_nav .= "first";
3861                 $paging_nav .= " &sdot; prev";
3862         }
3863         if ($#revlist >= (100 * ($page+1)-1)) {
3864                 $paging_nav .= " &sdot; " .
3865                         $cgi->a({-href => href(action=>"history", hash=>$hash, hash_base=>$hash_base,
3866                                                file_name=>$file_name, page=>$page+1),
3867                                  -accesskey => "n", -title => "Alt-n"}, "next");
3868         } else {
3869                 $paging_nav .= " &sdot; next";
3870         }
3871         my $next_link = '';
3872         if ($#revlist >= (100 * ($page+1)-1)) {
3873                 $next_link =
3874                         $cgi->a({-href => href(action=>"history", hash=>$hash, hash_base=>$hash_base,
3875                                                file_name=>$file_name, page=>$page+1),
3876                                  -title => "Alt-n"}, "next");
3877         }
3878
3879         git_header_html();
3880         git_print_page_nav('history','', $hash_base,$co{'tree'},$hash_base, $paging_nav);
3881         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
3882         git_print_page_path($file_name, $ftype, $hash_base);
3883
3884         git_history_body(\@revlist, ($page * 100), $#revlist,
3885                          $refs, $hash_base, $ftype, $next_link);
3886
3887         git_footer_html();
3888 }
3889
3890 sub git_search {
3891         if (!defined $searchtext) {
3892                 die_error(undef, "Text field empty");
3893         }
3894         if (!defined $hash) {
3895                 $hash = git_get_head_hash($project);
3896         }
3897         my %co = parse_commit($hash);
3898         if (!%co) {
3899                 die_error(undef, "Unknown commit object");
3900         }
3901
3902         $searchtype ||= 'commit';
3903         if ($searchtype eq 'pickaxe') {
3904                 # pickaxe may take all resources of your box and run for several minutes
3905                 # with every query - so decide by yourself how public you make this feature
3906                 my ($have_pickaxe) = gitweb_check_feature('pickaxe');
3907                 if (!$have_pickaxe) {
3908                         die_error('403 Permission denied', "Permission denied");
3909                 }
3910         }
3911
3912         git_header_html();
3913         git_print_page_nav('','', $hash,$co{'tree'},$hash);
3914         git_print_header_div('commit', esc_html($co{'title'}), $hash);
3915
3916         print "<table cellspacing=\"0\">\n";
3917         my $alternate = 1;
3918         if ($searchtype eq 'commit' or $searchtype eq 'author' or $searchtype eq 'committer') {
3919                 $/ = "\0";
3920                 open my $fd, "-|", git_cmd(), "rev-list",
3921                         "--header", "--parents", $hash, "--"
3922                         or next;
3923                 while (my $commit_text = <$fd>) {
3924                         if (!grep m/$searchtext/i, $commit_text) {
3925                                 next;
3926                         }
3927                         if ($searchtype eq 'author' && !grep m/\nauthor .*$searchtext/i, $commit_text) {
3928                                 next;
3929                         }
3930                         if ($searchtype eq 'committer' && !grep m/\ncommitter .*$searchtext/i, $commit_text) {
3931                                 next;
3932                         }
3933                         my @commit_lines = split "\n", $commit_text;
3934                         my %co = parse_commit(undef, \@commit_lines);
3935                         if (!%co) {
3936                                 next;
3937                         }
3938                         if ($alternate) {
3939                                 print "<tr class=\"dark\">\n";
3940                         } else {
3941                                 print "<tr class=\"light\">\n";
3942                         }
3943                         $alternate ^= 1;
3944                         print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
3945                               "<td><i>" . esc_html(chop_str($co{'author_name'}, 15, 5)) . "</i></td>\n" .
3946                               "<td>" .
3947                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}), -class => "list subject"},
3948                                        esc_html(chop_str($co{'title'}, 50)) . "<br/>");
3949                         my $comment = $co{'comment'};
3950                         foreach my $line (@$comment) {
3951                                 if ($line =~ m/^(.*)($searchtext)(.*)$/i) {
3952                                         my $lead = esc_html($1) || "";
3953                                         $lead = chop_str($lead, 30, 10);
3954                                         my $match = esc_html($2) || "";
3955                                         my $trail = esc_html($3) || "";
3956                                         $trail = chop_str($trail, 30, 10);
3957                                         my $text = "$lead<span class=\"match\">$match</span>$trail";
3958                                         print chop_str($text, 80, 5) . "<br/>\n";
3959                                 }
3960                         }
3961                         print "</td>\n" .
3962                               "<td class=\"link\">" .
3963                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
3964                               " | " .
3965                               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
3966                         print "</td>\n" .
3967                               "</tr>\n";
3968                 }
3969                 close $fd;
3970         }
3971
3972         if ($searchtype eq 'pickaxe') {
3973                 $/ = "\n";
3974                 my $git_command = git_cmd_str();
3975                 open my $fd, "-|", "$git_command rev-list $hash | " .
3976                         "$git_command diff-tree -r --stdin -S\'$searchtext\'";
3977                 undef %co;
3978                 my @files;
3979                 while (my $line = <$fd>) {
3980                         if (%co && $line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)\t(.*)$/) {
3981                                 my %set;
3982                                 $set{'file'} = $6;
3983                                 $set{'from_id'} = $3;
3984                                 $set{'to_id'} = $4;
3985                                 $set{'id'} = $set{'to_id'};
3986                                 if ($set{'id'} =~ m/0{40}/) {
3987                                         $set{'id'} = $set{'from_id'};
3988                                 }
3989                                 if ($set{'id'} =~ m/0{40}/) {
3990                                         next;
3991                                 }
3992                                 push @files, \%set;
3993                         } elsif ($line =~ m/^([0-9a-fA-F]{40})$/){
3994                                 if (%co) {
3995                                         if ($alternate) {
3996                                                 print "<tr class=\"dark\">\n";
3997                                         } else {
3998                                                 print "<tr class=\"light\">\n";
3999                                         }
4000                                         $alternate ^= 1;
4001                                         print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
4002                                               "<td><i>" . esc_html(chop_str($co{'author_name'}, 15, 5)) . "</i></td>\n" .
4003                                               "<td>" .
4004                                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
4005                                                       -class => "list subject"},
4006                                                       esc_html(chop_str($co{'title'}, 50)) . "<br/>");
4007                                         while (my $setref = shift @files) {
4008                                                 my %set = %$setref;
4009                                                 print $cgi->a({-href => href(action=>"blob", hash_base=>$co{'id'},
4010                                                                              hash=>$set{'id'}, file_name=>$set{'file'}),
4011                                                               -class => "list"},
4012                                                               "<span class=\"match\">" . esc_path($set{'file'}) . "</span>") .
4013                                                       "<br/>\n";
4014                                         }
4015                                         print "</td>\n" .
4016                                               "<td class=\"link\">" .
4017                                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
4018                                               " | " .
4019                                               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
4020                                         print "</td>\n" .
4021                                               "</tr>\n";
4022                                 }
4023                                 %co = parse_commit($1);
4024                         }
4025                 }
4026                 close $fd;
4027         }
4028         print "</table>\n";
4029         git_footer_html();
4030 }
4031
4032 sub git_search_help {
4033         git_header_html();
4034         git_print_page_nav('','', $hash,$hash,$hash);
4035         print <<EOT;
4036 <dl>
4037 <dt><b>commit</b></dt>
4038 <dd>The commit messages and authorship information will be scanned for the given string.</dd>
4039 <dt><b>author</b></dt>
4040 <dd>Name and e-mail of the change author and date of birth of the patch will be scanned for the given string.</dd>
4041 <dt><b>committer</b></dt>
4042 <dd>Name and e-mail of the committer and date of commit will be scanned for the given string.</dd>
4043 EOT
4044         my ($have_pickaxe) = gitweb_check_feature('pickaxe');
4045         if ($have_pickaxe) {
4046                 print <<EOT;
4047 <dt><b>pickaxe</b></dt>
4048 <dd>All commits that caused the string to appear or disappear from any file (changes that
4049 added, removed or "modified" the string) will be listed. This search can take a while and
4050 takes a lot of strain on the server, so please use it wisely.</dd>
4051 EOT
4052         }
4053         print "</dl>\n";
4054         git_footer_html();
4055 }
4056
4057 sub git_shortlog {
4058         my $head = git_get_head_hash($project);
4059         if (!defined $hash) {
4060                 $hash = $head;
4061         }
4062         if (!defined $page) {
4063                 $page = 0;
4064         }
4065         my $refs = git_get_references();
4066
4067         my $limit = sprintf("--max-count=%i", (100 * ($page+1)));
4068         open my $fd, "-|", git_cmd(), "rev-list", $limit, $hash, "--"
4069                 or die_error(undef, "Open git-rev-list failed");
4070         my @revlist = map { chomp; $_ } <$fd>;
4071         close $fd;
4072
4073         my $paging_nav = format_paging_nav('shortlog', $hash, $head, $page, $#revlist);
4074         my $next_link = '';
4075         if ($#revlist >= (100 * ($page+1)-1)) {
4076                 $next_link =
4077                         $cgi->a({-href => href(action=>"shortlog", hash=>$hash, page=>$page+1),
4078                                  -title => "Alt-n"}, "next");
4079         }
4080
4081
4082         git_header_html();
4083         git_print_page_nav('shortlog','', $hash,$hash,$hash, $paging_nav);
4084         git_print_header_div('summary', $project);
4085
4086         git_shortlog_body(\@revlist, ($page * 100), $#revlist, $refs, $next_link);
4087
4088         git_footer_html();
4089 }
4090
4091 ## ......................................................................
4092 ## feeds (RSS, OPML)
4093
4094 sub git_rss {
4095         # http://www.notestips.com/80256B3A007F2692/1/NAMO5P9UPQ
4096         open my $fd, "-|", git_cmd(), "rev-list", "--max-count=150",
4097                 git_get_head_hash($project), "--"
4098                 or die_error(undef, "Open git-rev-list failed");
4099         my @revlist = map { chomp; $_ } <$fd>;
4100         close $fd or die_error(undef, "Reading git-rev-list failed");
4101         print $cgi->header(-type => 'text/xml', -charset => 'utf-8');
4102         print <<XML;
4103 <?xml version="1.0" encoding="utf-8"?>
4104 <rss version="2.0" xmlns:content="http://purl.org/rss/1.0/modules/content/">
4105 <channel>
4106 <title>$project $my_uri $my_url</title>
4107 <link>${\esc_html("$my_url?p=$project;a=summary")}</link>
4108 <description>$project log</description>
4109 <language>en</language>
4110 XML
4111
4112         for (my $i = 0; $i <= $#revlist; $i++) {
4113                 my $commit = $revlist[$i];
4114                 my %co = parse_commit($commit);
4115                 # we read 150, we always show 30 and the ones more recent than 48 hours
4116                 if (($i >= 20) && ((time - $co{'committer_epoch'}) > 48*60*60)) {
4117                         last;
4118                 }
4119                 my %cd = parse_date($co{'committer_epoch'});
4120                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
4121                         $co{'parent'}, $co{'id'}, "--"
4122                         or next;
4123                 my @difftree = map { chomp; $_ } <$fd>;
4124                 close $fd
4125                         or next;
4126                 print "<item>\n" .
4127                       "<title>" .
4128                       sprintf("%d %s %02d:%02d", $cd{'mday'}, $cd{'month'}, $cd{'hour'}, $cd{'minute'}) . " - " . esc_html($co{'title'}) .
4129                       "</title>\n" .
4130                       "<author>" . esc_html($co{'author'}) . "</author>\n" .
4131                       "<pubDate>$cd{'rfc2822'}</pubDate>\n" .
4132                       "<guid isPermaLink=\"true\">" . esc_html("$my_url?p=$project;a=commit;h=$commit") . "</guid>\n" .
4133                       "<link>" . esc_html("$my_url?p=$project;a=commit;h=$commit") . "</link>\n" .
4134                       "<description>" . esc_html($co{'title'}) . "</description>\n" .
4135                       "<content:encoded>" .
4136                       "<![CDATA[\n";
4137                 my $comment = $co{'comment'};
4138                 foreach my $line (@$comment) {
4139                         $line = to_utf8($line);
4140                         print "$line<br/>\n";
4141                 }
4142                 print "<br/>\n";
4143                 foreach my $line (@difftree) {
4144                         if (!($line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)([0-9]{0,3})\t(.*)$/)) {
4145                                 next;
4146                         }
4147                         my $file = esc_path(unquote($7));
4148                         $file = to_utf8($file);
4149                         print "$file<br/>\n";
4150                 }
4151                 print "]]>\n" .
4152                       "</content:encoded>\n" .
4153                       "</item>\n";
4154         }
4155         print "</channel></rss>";
4156 }
4157
4158 sub git_opml {
4159         my @list = git_get_projects_list();
4160
4161         print $cgi->header(-type => 'text/xml', -charset => 'utf-8');
4162         print <<XML;
4163 <?xml version="1.0" encoding="utf-8"?>
4164 <opml version="1.0">
4165 <head>
4166   <title>$site_name OPML Export</title>
4167 </head>
4168 <body>
4169 <outline text="git RSS feeds">
4170 XML
4171
4172         foreach my $pr (@list) {
4173                 my %proj = %$pr;
4174                 my $head = git_get_head_hash($proj{'path'});
4175                 if (!defined $head) {
4176                         next;
4177                 }
4178                 $git_dir = "$projectroot/$proj{'path'}";
4179                 my %co = parse_commit($head);
4180                 if (!%co) {
4181                         next;
4182                 }
4183
4184                 my $path = esc_html(chop_str($proj{'path'}, 25, 5));
4185                 my $rss  = "$my_url?p=$proj{'path'};a=rss";
4186                 my $html = "$my_url?p=$proj{'path'};a=summary";
4187                 print "<outline type=\"rss\" text=\"$path\" title=\"$path\" xmlUrl=\"$rss\" htmlUrl=\"$html\"/>\n";
4188         }
4189         print <<XML;
4190 </outline>
4191 </body>
4192 </opml>
4193 XML
4194 }