Lady’s Gitweb - Gitweb/blob - gitweb.perl

   1 #!/usr/bin/perl
   2
   3 # gitweb - simple web interface to track changes in git repositories
   4 #
   5 # (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
   6 # (C) 2005, Christian Gierke
   7 #
   8 # This program is licensed under the GPLv2
   9
  10 use 5.008;
  11 use strict;
  12 use warnings;
  13 # handle ACL in file access tests
  14 use filetest 'access';
  15 use CGI qw(:standard :escapeHTML -nosticky);
  16 use CGI::Util qw(unescape);
  17 use CGI::Carp qw(fatalsToBrowser set_message);
  18 use Encode;
  19 use Fcntl ':mode';
  20 use File::Find qw();
  21 use File::Basename qw(basename);
  22 use Time::HiRes qw(gettimeofday tv_interval);
  23 use Digest::MD5 qw(md5_hex);
  24
  25 binmode STDOUT, ':utf8';
  26
  27 if (!defined($CGI::VERSION) || $CGI::VERSION < 4.08) {
  28         eval 'sub CGI::multi_param { CGI::param(@_) }'
  29 }
  30
  31 our $t0 = [ gettimeofday() ];
  32 our $number_of_git_cmds = 0;
  33
  34 BEGIN {
  35         CGI->compile() if $ENV{'MOD_PERL'};
  36 }
  37
  38 our $version = "++GIT_VERSION++";
  39
  40 our ($my_url, $my_uri, $base_url, $path_info, $home_link);
  41 sub evaluate_uri {
  42         our $cgi;
  43
  44         our $my_url = $cgi->url();
  45         our $my_uri = $cgi->url(-absolute => 1);
  46
  47         # Base URL for relative URLs in gitweb ($logo, $favicon, ...),
  48         # needed and used only for URLs with nonempty PATH_INFO
  49         our $base_url = $my_url;
  50
  51         # When the script is used as DirectoryIndex, the URL does not contain the name
  52         # of the script file itself, and $cgi->url() fails to strip PATH_INFO, so we
  53         # have to do it ourselves. We make $path_info global because it's also used
  54         # later on.
  55         #
  56         # Another issue with the script being the DirectoryIndex is that the resulting
  57         # $my_url data is not the full script URL: this is good, because we want
  58         # generated links to keep implying the script name if it wasn't explicitly
  59         # indicated in the URL we're handling, but it means that $my_url cannot be used
  60         # as base URL.
  61         # Therefore, if we needed to strip PATH_INFO, then we know that we have
  62         # to build the base URL ourselves:
  63         our $path_info = decode_utf8($ENV{"PATH_INFO"});
  64         if ($path_info) {
  65                 # $path_info has already been URL-decoded by the web server, but
  66                 # $my_url and $my_uri have not. URL-decode them so we can properly
  67                 # strip $path_info.
  68                 $my_url = unescape($my_url);
  69                 $my_uri = unescape($my_uri);
  70                 if ($my_url =~ s,\Q$path_info\E$,, &&
  71                     $my_uri =~ s,\Q$path_info\E$,, &&
  72                     defined $ENV{'SCRIPT_NAME'}) {
  73                         $base_url = $cgi->url(-base => 1) . $ENV{'SCRIPT_NAME'};
  74                 }
  75         }
  76
  77         # target of the home link on top of all pages
  78         our $home_link = $my_uri || "/";
  79 }
  80
  81 # core git executable to use
  82 # this can just be "git" if your webserver has a sensible PATH
  83 our $GIT = "++GIT_BINDIR++/git";
  84
  85 # absolute fs-path which will be prepended to the project path
  86 #our $projectroot = "/pub/scm";
  87 our $projectroot = "++GITWEB_PROJECTROOT++";
  88
  89 # fs traversing limit for getting project list
  90 # the number is relative to the projectroot
  91 our $project_maxdepth = "++GITWEB_PROJECT_MAXDEPTH++";
  92
  93 # string of the home link on top of all pages
  94 our $home_link_str = "++GITWEB_HOME_LINK_STR++";
  95
  96 # extra breadcrumbs preceding the home link
  97 our @extra_breadcrumbs = ();
  98
  99 # name of your site or organization to appear in page titles
 100 # replace this with something more descriptive for clearer bookmarks
 101 our $site_name = "++GITWEB_SITENAME++"
 102                  || ($ENV{'SERVER_NAME'} || "Untitled") . " Git";
 103
 104 # html snippet to include in the <head> section of each page
 105 our $site_html_head_string = "++GITWEB_SITE_HTML_HEAD_STRING++";
 106 # filename of html text to include at top of each page
 107 our $site_header = "++GITWEB_SITE_HEADER++";
 108 # html text to include at home page
 109 our $home_text = "++GITWEB_HOMETEXT++";
 110 # filename of html text to include at bottom of each page
 111 our $site_footer = "++GITWEB_SITE_FOOTER++";
 112
 113 # URI of stylesheets
 114 our @stylesheets = ("++GITWEB_CSS++");
 115 # URI of a single stylesheet, which can be overridden in GITWEB_CONFIG.
 116 our $stylesheet = undef;
 117
 118 # URI of GIT logo (72x27 size)
 119 our $logo = "++GITWEB_LOGO++";
 120 # URI of GIT favicon, assumed to be image/png type
 121 our $favicon = "++GITWEB_FAVICON++";
 122 # URI of gitweb.js (JavaScript code for gitweb)
 123 our $javascript = "++GITWEB_JS++";
 124
 125 # URI and label (title) of GIT logo link
 126 #our $logo_url = "http://www.kernel.org/pub/software/scm/git/docs/";
 127 #our $logo_label = "git documentation";
 128 our $logo_url = "http://git-scm.com/";
 129 our $logo_label = "git homepage";
 130
 131 # source of projects list
 132 our $projects_list = "++GITWEB_LIST++";
 133
 134 # the width (in characters) of the projects list "Description" column
 135 our $projects_list_description_width = 25;
 136
 137 # group projects by category on the projects list
 138 # (enabled if this variable evaluates to true)
 139 our $projects_list_group_categories = 0;
 140
 141 # default category if none specified
 142 # (leave the empty string for no category)
 143 our $project_list_default_category = "";
 144
 145 # default order of projects list
 146 # valid values are none, project, descr, owner, and age
 147 our $default_projects_order = "project";
 148
 149 # show repository only if this file exists
 150 # (only effective if this variable evaluates to true)
 151 our $export_ok = "++GITWEB_EXPORT_OK++";
 152
 153 # don't generate age column on the projects list page
 154 our $omit_age_column = 0;
 155
 156 # don't generate information about owners of repositories
 157 our $omit_owner=0;
 158
 159 # show repository only if this subroutine returns true
 160 # when given the path to the project, for example:
 161 #    sub { return -e "$_[0]/git-daemon-export-ok"; }
 162 our $export_auth_hook = undef;
 163
 164 # only allow viewing of repositories also shown on the overview page
 165 our $strict_export = "++GITWEB_STRICT_EXPORT++";
 166
 167 # list of git base URLs used for URL to where fetch project from,
 168 # i.e. full URL is "$git_base_url/$project"
 169 our @git_base_url_list = grep { $_ ne '' } ("++GITWEB_BASE_URL++");
 170
 171 # default blob_plain mimetype and default charset for text/plain blob
 172 our $default_blob_plain_mimetype = 'text/plain';
 173 our $default_text_plain_charset  = undef;
 174
 175 # file to use for guessing MIME types before trying /etc/mime.types
 176 # (relative to the current git repository)
 177 our $mimetypes_file = undef;
 178
 179 # assume this charset if line contains non-UTF-8 characters;
 180 # it should be valid encoding (see Encoding::Supported(3pm) for list),
 181 # for which encoding all byte sequences are valid, for example
 182 # 'iso-8859-1' aka 'latin1' (it is decoded without checking, so it
 183 # could be even 'utf-8' for the old behavior)
 184 our $fallback_encoding = 'latin1';
 185
 186 # rename detection options for git-diff and git-diff-tree
 187 # - default is '-M', with the cost proportional to
 188 #   (number of removed files) * (number of new files).
 189 # - more costly is '-C' (which implies '-M'), with the cost proportional to
 190 #   (number of changed files + number of removed files) * (number of new files)
 191 # - even more costly is '-C', '--find-copies-harder' with cost
 192 #   (number of files in the original tree) * (number of new files)
 193 # - one might want to include '-B' option, e.g. '-B', '-M'
 194 our @diff_opts = ('-M'); # taken from git_commit
 195
 196 # Disables features that would allow repository owners to inject script into
 197 # the gitweb domain.
 198 our $prevent_xss = 0;
 199
 200 # Path to the highlight executable to use (must be the one from
 201 # http://www.andre-simon.de due to assumptions about parameters and output).
 202 # Useful if highlight is not installed on your webserver's PATH.
 203 # [Default: highlight]
 204 our $highlight_bin = "++HIGHLIGHT_BIN++";
 205
 206 # information about snapshot formats that gitweb is capable of serving
 207 our %known_snapshot_formats = (
 208         # name => {
 209         #       'display' => display name,
 210         #       'type' => mime type,
 211         #       'suffix' => filename suffix,
 212         #       'format' => --format for git-archive,
 213         #       'compressor' => [compressor command and arguments]
 214         #                       (array reference, optional)
 215         #       'disabled' => boolean (optional)}
 216         #
 217         'tgz' => {
 218                 'display' => 'tar.gz',
 219                 'type' => 'application/x-gzip',
 220                 'suffix' => '.tar.gz',
 221                 'format' => 'tar',
 222                 'compressor' => ['gzip', '-n']},
 223
 224         'tbz2' => {
 225                 'display' => 'tar.bz2',
 226                 'type' => 'application/x-bzip2',
 227                 'suffix' => '.tar.bz2',
 228                 'format' => 'tar',
 229                 'compressor' => ['bzip2']},
 230
 231         'txz' => {
 232                 'display' => 'tar.xz',
 233                 'type' => 'application/x-xz',
 234                 'suffix' => '.tar.xz',
 235                 'format' => 'tar',
 236                 'compressor' => ['xz'],
 237                 'disabled' => 1},
 238
 239         'zip' => {
 240                 'display' => 'zip',
 241                 'type' => 'application/x-zip',
 242                 'suffix' => '.zip',
 243                 'format' => 'zip'},
 244 );
 245
 246 # Aliases so we understand old gitweb.snapshot values in repository
 247 # configuration.
 248 our %known_snapshot_format_aliases = (
 249         'gzip'  => 'tgz',
 250         'bzip2' => 'tbz2',
 251         'xz'    => 'txz',
 252
 253         # backward compatibility: legacy gitweb config support
 254         'x-gzip' => undef, 'gz' => undef,
 255         'x-bzip2' => undef, 'bz2' => undef,
 256         'x-zip' => undef, '' => undef,
 257 );
 258
 259 # Pixel sizes for icons and avatars. If the default font sizes or lineheights
 260 # are changed, it may be appropriate to change these values too via
 261 # $GITWEB_CONFIG.
 262 our %avatar_size = (
 263         'default' => 16,
 264         'double'  => 32
 265 );
 266
 267 # Used to set the maximum load that we will still respond to gitweb queries.
 268 # If server load exceed this value then return "503 server busy" error.
 269 # If gitweb cannot determined server load, it is taken to be 0.
 270 # Leave it undefined (or set to 'undef') to turn off load checking.
 271 our $maxload = 300;
 272
 273 # configuration for 'highlight' (http://www.andre-simon.de/)
 274 # match by basename
 275 our %highlight_basename = (
 276         #'Program' => 'py',
 277         #'Library' => 'py',
 278         'SConstruct' => 'py', # SCons equivalent of Makefile
 279         'Makefile' => 'make',
 280 );
 281 # match by extension
 282 our %highlight_ext = (
 283         # main extensions, defining name of syntax;
 284         # see files in /usr/share/highlight/langDefs/ directory
 285         (map { $_ => $_ } qw(py rb java css js tex bib xml awk bat ini spec tcl sql)),
 286         # alternate extensions, see /etc/highlight/filetypes.conf
 287         (map { $_ => 'c'   } qw(c h)),
 288         (map { $_ => 'sh'  } qw(sh bash zsh ksh)),
 289         (map { $_ => 'cpp' } qw(cpp cxx c++ cc)),
 290         (map { $_ => 'php' } qw(php php3 php4 php5 phps)),
 291         (map { $_ => 'pl'  } qw(pl perl pm)), # perhaps also 'cgi'
 292         (map { $_ => 'make'} qw(make mak mk)),
 293         (map { $_ => 'xml' } qw(xml xhtml html htm)),
 294 );
 295
 296 # You define site-wide feature defaults here; override them with
 297 # $GITWEB_CONFIG as necessary.
 298 our %feature = (
 299         # feature => {
 300         #       'sub' => feature-sub (subroutine),
 301         #       'override' => allow-override (boolean),
 302         #       'default' => [ default options...] (array reference)}
 303         #
 304         # if feature is overridable (it means that allow-override has true value),
 305         # then feature-sub will be called with default options as parameters;
 306         # return value of feature-sub indicates if to enable specified feature
 307         #
 308         # if there is no 'sub' key (no feature-sub), then feature cannot be
 309         # overridden
 310         #
 311         # use gitweb_get_feature(<feature>) to retrieve the <feature> value
 312         # (an array) or gitweb_check_feature(<feature>) to check if <feature>
 313         # is enabled
 314
 315         # Enable the 'blame' blob view, showing the last commit that modified
 316         # each line in the file. This can be very CPU-intensive.
 317
 318         # To enable system wide have in $GITWEB_CONFIG
 319         # $feature{'blame'}{'default'} = [1];
 320         # To have project specific config enable override in $GITWEB_CONFIG
 321         # $feature{'blame'}{'override'} = 1;
 322         # and in project config gitweb.blame = 0|1;
 323         'blame' => {
 324                 'sub' => sub { feature_bool('blame', @_) },
 325                 'override' => 0,
 326                 'default' => [0]},
 327
 328         # Enable the 'snapshot' link, providing a compressed archive of any
 329         # tree. This can potentially generate high traffic if you have large
 330         # project.
 331
 332         # Value is a list of formats defined in %known_snapshot_formats that
 333         # you wish to offer.
 334         # To disable system wide have in $GITWEB_CONFIG
 335         # $feature{'snapshot'}{'default'} = [];
 336         # To have project specific config enable override in $GITWEB_CONFIG
 337         # $feature{'snapshot'}{'override'} = 1;
 338         # and in project config, a comma-separated list of formats or "none"
 339         # to disable.  Example: gitweb.snapshot = tbz2,zip;
 340         'snapshot' => {
 341                 'sub' => \&feature_snapshot,
 342                 'override' => 0,
 343                 'default' => ['tgz']},
 344
 345         # Enable text search, which will list the commits which match author,
 346         # committer or commit text to a given string.  Enabled by default.
 347         # Project specific override is not supported.
 348         #
 349         # Note that this controls all search features, which means that if
 350         # it is disabled, then 'grep' and 'pickaxe' search would also be
 351         # disabled.
 352         'search' => {
 353                 'override' => 0,
 354                 'default' => [1]},
 355
 356         # Enable grep search, which will list the files in currently selected
 357         # tree containing the given string. Enabled by default. This can be
 358         # potentially CPU-intensive, of course.
 359         # Note that you need to have 'search' feature enabled too.
 360
 361         # To enable system wide have in $GITWEB_CONFIG
 362         # $feature{'grep'}{'default'} = [1];
 363         # To have project specific config enable override in $GITWEB_CONFIG
 364         # $feature{'grep'}{'override'} = 1;
 365         # and in project config gitweb.grep = 0|1;
 366         'grep' => {
 367                 'sub' => sub { feature_bool('grep', @_) },
 368                 'override' => 0,
 369                 'default' => [1]},
 370
 371         # Enable the pickaxe search, which will list the commits that modified
 372         # a given string in a file. This can be practical and quite faster
 373         # alternative to 'blame', but still potentially CPU-intensive.
 374         # Note that you need to have 'search' feature enabled too.
 375
 376         # To enable system wide have in $GITWEB_CONFIG
 377         # $feature{'pickaxe'}{'default'} = [1];
 378         # To have project specific config enable override in $GITWEB_CONFIG
 379         # $feature{'pickaxe'}{'override'} = 1;
 380         # and in project config gitweb.pickaxe = 0|1;
 381         'pickaxe' => {
 382                 'sub' => sub { feature_bool('pickaxe', @_) },
 383                 'override' => 0,
 384                 'default' => [1]},
 385
 386         # Enable showing size of blobs in a 'tree' view, in a separate
 387         # column, similar to what 'ls -l' does.  This cost a bit of IO.
 388
 389         # To disable system wide have in $GITWEB_CONFIG
 390         # $feature{'show-sizes'}{'default'} = [0];
 391         # To have project specific config enable override in $GITWEB_CONFIG
 392         # $feature{'show-sizes'}{'override'} = 1;
 393         # and in project config gitweb.showsizes = 0|1;
 394         'show-sizes' => {
 395                 'sub' => sub { feature_bool('showsizes', @_) },
 396                 'override' => 0,
 397                 'default' => [1]},
 398
 399         # Make gitweb use an alternative format of the URLs which can be
 400         # more readable and natural-looking: project name is embedded
 401         # directly in the path and the query string contains other
 402         # auxiliary information. All gitweb installations recognize
 403         # URL in either format; this configures in which formats gitweb
 404         # generates links.
 405
 406         # To enable system wide have in $GITWEB_CONFIG
 407         # $feature{'pathinfo'}{'default'} = [1];
 408         # Project specific override is not supported.
 409
 410         # Note that you will need to change the default location of CSS,
 411         # favicon, logo and possibly other files to an absolute URL. Also,
 412         # if gitweb.cgi serves as your indexfile, you will need to force
 413         # $my_uri to contain the script name in your $GITWEB_CONFIG.
 414         'pathinfo' => {
 415                 'override' => 0,
 416                 'default' => [0]},
 417
 418         # Make gitweb consider projects in project root subdirectories
 419         # to be forks of existing projects. Given project $projname.git,
 420         # projects matching $projname/*.git will not be shown in the main
 421         # projects list, instead a '+' mark will be added to $projname
 422         # there and a 'forks' view will be enabled for the project, listing
 423         # all the forks. If project list is taken from a file, forks have
 424         # to be listed after the main project.
 425
 426         # To enable system wide have in $GITWEB_CONFIG
 427         # $feature{'forks'}{'default'} = [1];
 428         # Project specific override is not supported.
 429         'forks' => {
 430                 'override' => 0,
 431                 'default' => [0]},
 432
 433         # Insert custom links to the action bar of all project pages.
 434         # This enables you mainly to link to third-party scripts integrating
 435         # into gitweb; e.g. git-browser for graphical history representation
 436         # or custom web-based repository administration interface.
 437
 438         # The 'default' value consists of a list of triplets in the form
 439         # (label, link, position) where position is the label after which
 440         # to insert the link and link is a format string where %n expands
 441         # to the project name, %f to the project path within the filesystem,
 442         # %h to the current hash (h gitweb parameter) and %b to the current
 443         # hash base (hb gitweb parameter); %% expands to %.
 444
 445         # To enable system wide have in $GITWEB_CONFIG e.g.
 446         # $feature{'actions'}{'default'} = [('graphiclog',
 447         #       '/git-browser/by-commit.html?r=%n', 'summary')];
 448         # Project specific override is not supported.
 449         'actions' => {
 450                 'override' => 0,
 451                 'default' => []},
 452
 453         # Allow gitweb scan project content tags of project repository,
 454         # and display the popular Web 2.0-ish "tag cloud" near the projects
 455         # list.  Note that this is something COMPLETELY different from the
 456         # normal Git tags.
 457
 458         # gitweb by itself can show existing tags, but it does not handle
 459         # tagging itself; you need to do it externally, outside gitweb.
 460         # The format is described in git_get_project_ctags() subroutine.
 461         # You may want to install the HTML::TagCloud Perl module to get
 462         # a pretty tag cloud instead of just a list of tags.
 463
 464         # To enable system wide have in $GITWEB_CONFIG
 465         # $feature{'ctags'}{'default'} = [1];
 466         # Project specific override is not supported.
 467
 468         # In the future whether ctags editing is enabled might depend
 469         # on the value, but using 1 should always mean no editing of ctags.
 470         'ctags' => {
 471                 'override' => 0,
 472                 'default' => [0]},
 473
 474         # The maximum number of patches in a patchset generated in patch
 475         # view. Set this to 0 or undef to disable patch view, or to a
 476         # negative number to remove any limit.
 477
 478         # To disable system wide have in $GITWEB_CONFIG
 479         # $feature{'patches'}{'default'} = [0];
 480         # To have project specific config enable override in $GITWEB_CONFIG
 481         # $feature{'patches'}{'override'} = 1;
 482         # and in project config gitweb.patches = 0|n;
 483         # where n is the maximum number of patches allowed in a patchset.
 484         'patches' => {
 485                 'sub' => \&feature_patches,
 486                 'override' => 0,
 487                 'default' => [16]},
 488
 489         # Avatar support. When this feature is enabled, views such as
 490         # shortlog or commit will display an avatar associated with
 491         # the email of the committer(s) and/or author(s).
 492
 493         # Currently available providers are gravatar and picon.
 494         # If an unknown provider is specified, the feature is disabled.
 495
 496         # Picon currently relies on the indiana.edu database.
 497
 498         # To enable system wide have in $GITWEB_CONFIG
 499         # $feature{'avatar'}{'default'} = ['<provider>'];
 500         # where <provider> is either gravatar or picon.
 501         # To have project specific config enable override in $GITWEB_CONFIG
 502         # $feature{'avatar'}{'override'} = 1;
 503         # and in project config gitweb.avatar = <provider>;
 504         'avatar' => {
 505                 'sub' => \&feature_avatar,
 506                 'override' => 0,
 507                 'default' => ['']},
 508
 509         # Enable displaying how much time and how many git commands
 510         # it took to generate and display page.  Disabled by default.
 511         # Project specific override is not supported.
 512         'timed' => {
 513                 'override' => 0,
 514                 'default' => [0]},
 515
 516         # Enable turning some links into links to actions which require
 517         # JavaScript to run (like 'blame_incremental').  Not enabled by
 518         # default.  Project specific override is currently not supported.
 519         'javascript-actions' => {
 520                 'override' => 0,
 521                 'default' => [0]},
 522
 523         # Enable and configure ability to change common timezone for dates
 524         # in gitweb output via JavaScript.  Enabled by default.
 525         # Project specific override is not supported.
 526         'javascript-timezone' => {
 527                 'override' => 0,
 528                 'default' => [
 529                         'local',     # default timezone: 'utc', 'local', or '(-|+)HHMM' format,
 530                                      # or undef to turn off this feature
 531                         'gitweb_tz', # name of cookie where to store selected timezone
 532                         'datetime',  # CSS class used to mark up dates for manipulation
 533                 ]},
 534
 535         # Syntax highlighting support. This is based on Daniel Svensson's
 536         # and Sham Chukoury's work in gitweb-xmms2.git.
 537         # It requires the 'highlight' program present in $PATH,
 538         # and therefore is disabled by default.
 539
 540         # To enable system wide have in $GITWEB_CONFIG
 541         # $feature{'highlight'}{'default'} = [1];
 542
 543         'highlight' => {
 544                 'sub' => sub { feature_bool('highlight', @_) },
 545                 'override' => 0,
 546                 'default' => [0]},
 547
 548         # Enable displaying of remote heads in the heads list
 549
 550         # To enable system wide have in $GITWEB_CONFIG
 551         # $feature{'remote_heads'}{'default'} = [1];
 552         # To have project specific config enable override in $GITWEB_CONFIG
 553         # $feature{'remote_heads'}{'override'} = 1;
 554         # and in project config gitweb.remoteheads = 0|1;
 555         'remote_heads' => {
 556                 'sub' => sub { feature_bool('remote_heads', @_) },
 557                 'override' => 0,
 558                 'default' => [0]},
 559
 560         # Enable showing branches under other refs in addition to heads
 561
 562         # To set system wide extra branch refs have in $GITWEB_CONFIG
 563         # $feature{'extra-branch-refs'}{'default'} = ['dirs', 'of', 'choice'];
 564         # To have project specific config enable override in $GITWEB_CONFIG
 565         # $feature{'extra-branch-refs'}{'override'} = 1;
 566         # and in project config gitweb.extrabranchrefs = dirs of choice
 567         # Every directory is separated with whitespace.
 568
 569         'extra-branch-refs' => {
 570                 'sub' => \&feature_extra_branch_refs,
 571                 'override' => 0,
 572                 'default' => []},
 573
 574         # Redact e-mail addresses.
 575
 576         # To enable system wide have in $GITWEB_CONFIG
 577         # $feature{'email-privacy'}{'default'} = [1];
 578         'email-privacy' => {
 579                 'sub' => sub { feature_bool('email-privacy', @_) },
 580                 'override' => 1,
 581                 'default' => [0]},
 582 );
 583
 584 sub gitweb_get_feature {
 585         my ($name) = @_;
 586         return unless exists $feature{$name};
 587         my ($sub, $override, @defaults) = (
 588                 $feature{$name}{'sub'},
 589                 $feature{$name}{'override'},
 590                 @{$feature{$name}{'default'}});
 591         # project specific override is possible only if we have project
 592         our $git_dir; # global variable, declared later
 593         if (!$override || !defined $git_dir) {
 594                 return @defaults;
 595         }
 596         if (!defined $sub) {
 597                 warn "feature $name is not overridable";
 598                 return @defaults;
 599         }
 600         return $sub->(@defaults);
 601 }
 602
 603 # A wrapper to check if a given feature is enabled.
 604 # With this, you can say
 605 #
 606 #   my $bool_feat = gitweb_check_feature('bool_feat');
 607 #   gitweb_check_feature('bool_feat') or somecode;
 608 #
 609 # instead of
 610 #
 611 #   my ($bool_feat) = gitweb_get_feature('bool_feat');
 612 #   (gitweb_get_feature('bool_feat'))[0] or somecode;
 613 #
 614 sub gitweb_check_feature {
 615         return (gitweb_get_feature(@_))[0];
 616 }
 617
 618
 619 sub feature_bool {
 620         my $key = shift;
 621         my ($val) = git_get_project_config($key, '--bool');
 622
 623         if (!defined $val) {
 624                 return ($_[0]);
 625         } elsif ($val eq 'true') {
 626                 return (1);
 627         } elsif ($val eq 'false') {
 628                 return (0);
 629         }
 630 }
 631
 632 sub feature_snapshot {
 633         my (@fmts) = @_;
 634
 635         my ($val) = git_get_project_config('snapshot');
 636
 637         if ($val) {
 638                 @fmts = ($val eq 'none' ? () : split /\s*[,\s]\s*/, $val);
 639         }
 640
 641         return @fmts;
 642 }
 643
 644 sub feature_patches {
 645         my @val = (git_get_project_config('patches', '--int'));
 646
 647         if (@val) {
 648                 return @val;
 649         }
 650
 651         return ($_[0]);
 652 }
 653
 654 sub feature_avatar {
 655         my @val = (git_get_project_config('avatar'));
 656
 657         return @val ? @val : @_;
 658 }
 659
 660 sub feature_extra_branch_refs {
 661         my (@branch_refs) = @_;
 662         my $values = git_get_project_config('extrabranchrefs');
 663
 664         if ($values) {
 665                 $values = config_to_multi ($values);
 666                 @branch_refs = ();
 667                 foreach my $value (@{$values}) {
 668                         push @branch_refs, split /\s+/, $value;
 669                 }
 670         }
 671
 672         return @branch_refs;
 673 }
 674
 675 # checking HEAD file with -e is fragile if the repository was
 676 # initialized long time ago (i.e. symlink HEAD) and was pack-ref'ed
 677 # and then pruned.
 678 sub check_head_link {
 679         my ($dir) = @_;
 680         my $headfile = "$dir/HEAD";
 681         return ((-e $headfile) ||
 682                 (-l $headfile && readlink($headfile) =~ /^refs\/heads\//));
 683 }
 684
 685 sub check_export_ok {
 686         my ($dir) = @_;
 687         return (check_head_link($dir) &&
 688                 (!$export_ok || -e "$dir/$export_ok") &&
 689                 (!$export_auth_hook || $export_auth_hook->($dir)));
 690 }
 691
 692 # process alternate names for backward compatibility
 693 # filter out unsupported (unknown) snapshot formats
 694 sub filter_snapshot_fmts {
 695         my @fmts = @_;
 696
 697         @fmts = map {
 698                 exists $known_snapshot_format_aliases{$_} ?
 699                        $known_snapshot_format_aliases{$_} : $_} @fmts;
 700         @fmts = grep {
 701                 exists $known_snapshot_formats{$_} &&
 702                 !$known_snapshot_formats{$_}{'disabled'}} @fmts;
 703 }
 704
 705 sub filter_and_validate_refs {
 706         my @refs = @_;
 707         my %unique_refs = ();
 708
 709         foreach my $ref (@refs) {
 710                 die_error(500, "Invalid ref '$ref' in 'extra-branch-refs' feature") unless (is_valid_ref_format($ref));
 711                 # 'heads' are added implicitly in get_branch_refs().
 712                 $unique_refs{$ref} = 1 if ($ref ne 'heads');
 713         }
 714         return sort keys %unique_refs;
 715 }
 716
 717 # If it is set to code reference, it is code that it is to be run once per
 718 # request, allowing updating configurations that change with each request,
 719 # while running other code in config file only once.
 720 #
 721 # Otherwise, if it is false then gitweb would process config file only once;
 722 # if it is true then gitweb config would be run for each request.
 723 our $per_request_config = 1;
 724
 725 # read and parse gitweb config file given by its parameter.
 726 # returns true on success, false on recoverable error, allowing
 727 # to chain this subroutine, using first file that exists.
 728 # dies on errors during parsing config file, as it is unrecoverable.
 729 sub read_config_file {
 730         my $filename = shift;
 731         return unless defined $filename;
 732         # die if there are errors parsing config file
 733         if (-e $filename) {
 734                 do $filename;
 735                 die $@ if $@;
 736                 return 1;
 737         }
 738         return;
 739 }
 740
 741 our ($GITWEB_CONFIG, $GITWEB_CONFIG_SYSTEM, $GITWEB_CONFIG_COMMON);
 742 sub evaluate_gitweb_config {
 743         our $GITWEB_CONFIG = $ENV{'GITWEB_CONFIG'} || "++GITWEB_CONFIG++";
 744         our $GITWEB_CONFIG_SYSTEM = $ENV{'GITWEB_CONFIG_SYSTEM'} || "++GITWEB_CONFIG_SYSTEM++";
 745         our $GITWEB_CONFIG_COMMON = $ENV{'GITWEB_CONFIG_COMMON'} || "++GITWEB_CONFIG_COMMON++";
 746
 747         # Protect against duplications of file names, to not read config twice.
 748         # Only one of $GITWEB_CONFIG and $GITWEB_CONFIG_SYSTEM is used, so
 749         # there possibility of duplication of filename there doesn't matter.
 750         $GITWEB_CONFIG = ""        if ($GITWEB_CONFIG eq $GITWEB_CONFIG_COMMON);
 751         $GITWEB_CONFIG_SYSTEM = "" if ($GITWEB_CONFIG_SYSTEM eq $GITWEB_CONFIG_COMMON);
 752
 753         # Common system-wide settings for convenience.
 754         # Those settings can be overridden by GITWEB_CONFIG or GITWEB_CONFIG_SYSTEM.
 755         read_config_file($GITWEB_CONFIG_COMMON);
 756
 757         # Use first config file that exists.  This means use the per-instance
 758         # GITWEB_CONFIG if exists, otherwise use GITWEB_SYSTEM_CONFIG.
 759         read_config_file($GITWEB_CONFIG) and return;
 760         read_config_file($GITWEB_CONFIG_SYSTEM);
 761 }
 762
 763 # Get loadavg of system, to compare against $maxload.
 764 # Currently it requires '/proc/loadavg' present to get loadavg;
 765 # if it is not present it returns 0, which means no load checking.
 766 sub get_loadavg {
 767         if( -e '/proc/loadavg' ){
 768                 open my $fd, '<', '/proc/loadavg'
 769                         or return 0;
 770                 my @load = split(/\s+/, scalar <$fd>);
 771                 close $fd;
 772
 773                 # The first three columns measure CPU and IO utilization of the last one,
 774                 # five, and 10 minute periods.  The fourth column shows the number of
 775                 # currently running processes and the total number of processes in the m/n
 776                 # format.  The last column displays the last process ID used.
 777                 return $load[0] || 0;
 778         }
 779         # additional checks for load average should go here for things that don't export
 780         # /proc/loadavg
 781
 782         return 0;
 783 }
 784
 785 # version of the core git binary
 786 our $git_version;
 787 sub evaluate_git_version {
 788         our $git_version = qx("$GIT" --version) =~ m/git version (.*)$/ ? $1 : "unknown";
 789         $number_of_git_cmds++;
 790 }
 791
 792 sub check_loadavg {
 793         if (defined $maxload && get_loadavg() > $maxload) {
 794                 die_error(503, "The load average on the server is too high");
 795         }
 796 }
 797
 798 # ======================================================================
 799 # input validation and dispatch
 800
 801 # Various hash size-related values.
 802 my $sha1_len = 40;
 803 my $sha256_extra_len = 24;
 804 my $sha256_len = $sha1_len + $sha256_extra_len;
 805
 806 # A regex matching $len hex characters. $len may be a range (e.g. 7,64).
 807 sub oid_nlen_regex {
 808         my $len = shift;
 809         my $hchr = qr/[0-9a-fA-F]/;
 810         return qr/(?:(?:$hchr){$len})/;
 811 }
 812
 813 # A regex matching two sets of $nlen hex characters, prefixed by the literal
 814 # string $prefix and with the literal string $infix between them.
 815 sub oid_nlen_prefix_infix_regex {
 816         my $nlen = shift;
 817         my $prefix = shift;
 818         my $infix = shift;
 819
 820         my $rx = oid_nlen_regex($nlen);
 821
 822         return qr/^\Q$prefix\E$rx\Q$infix\E$rx$/;
 823 }
 824
 825 # A regex matching a valid object ID.
 826 our $oid_regex;
 827 {
 828         my $x = oid_nlen_regex($sha1_len);
 829         my $y = oid_nlen_regex($sha256_extra_len);
 830         $oid_regex = qr/(?:$x(?:$y)?)/;
 831 }
 832
 833 # input parameters can be collected from a variety of sources (presently, CGI
 834 # and PATH_INFO), so we define an %input_params hash that collects them all
 835 # together during validation: this allows subsequent uses (e.g. href()) to be
 836 # agnostic of the parameter origin
 837
 838 our %input_params = ();
 839
 840 # input parameters are stored with the long parameter name as key. This will
 841 # also be used in the href subroutine to convert parameters to their CGI
 842 # equivalent, and since the href() usage is the most frequent one, we store
 843 # the name -> CGI key mapping here, instead of the reverse.
 844 #
 845 # XXX: Warning: If you touch this, check the search form for updating,
 846 # too.
 847
 848 our @cgi_param_mapping = (
 849         project => "p",
 850         action => "a",
 851         file_name => "f",
 852         file_parent => "fp",
 853         hash => "h",
 854         hash_parent => "hp",
 855         hash_base => "hb",
 856         hash_parent_base => "hpb",
 857         page => "pg",
 858         order => "o",
 859         searchtext => "s",
 860         searchtype => "st",
 861         snapshot_format => "sf",
 862         extra_options => "opt",
 863         search_use_regexp => "sr",
 864         ctag => "by_tag",
 865         diff_style => "ds",
 866         project_filter => "pf",
 867         # this must be last entry (for manipulation from JavaScript)
 868         javascript => "js"
 869 );
 870 our %cgi_param_mapping = @cgi_param_mapping;
 871
 872 # we will also need to know the possible actions, for validation
 873 our %actions = (
 874         "blame" => \&git_blame,
 875         "blame_incremental" => \&git_blame_incremental,
 876         "blame_data" => \&git_blame_data,
 877         "blobdiff" => \&git_blobdiff,
 878         "blobdiff_plain" => \&git_blobdiff_plain,
 879         "blob" => \&git_blob,
 880         "blob_plain" => \&git_blob_plain,
 881         "commitdiff" => \&git_commitdiff,
 882         "commitdiff_plain" => \&git_commitdiff_plain,
 883         "commit" => \&git_commit,
 884         "forks" => \&git_forks,
 885         "heads" => \&git_heads,
 886         "history" => \&git_history,
 887         "log" => \&git_log,
 888         "patch" => \&git_patch,
 889         "patches" => \&git_patches,
 890         "remotes" => \&git_remotes,
 891         "rss" => \&git_rss,
 892         "atom" => \&git_atom,
 893         "search" => \&git_search,
 894         "search_help" => \&git_search_help,
 895         "shortlog" => \&git_shortlog,
 896         "summary" => \&git_summary,
 897         "tag" => \&git_tag,
 898         "tags" => \&git_tags,
 899         "tree" => \&git_tree,
 900         "snapshot" => \&git_snapshot,
 901         "object" => \&git_object,
 902         # those below don't need $project
 903         "opml" => \&git_opml,
 904         "project_list" => \&git_project_list,
 905         "project_index" => \&git_project_index,
 906 );
 907
 908 # finally, we have the hash of allowed extra_options for the commands that
 909 # allow them
 910 our %allowed_options = (
 911         "--no-merges" => [ qw(rss atom log shortlog history) ],
 912 );
 913
 914 # fill %input_params with the CGI parameters. All values except for 'opt'
 915 # should be single values, but opt can be an array. We should probably
 916 # build an array of parameters that can be multi-valued, but since for the time
 917 # being it's only this one, we just single it out
 918 sub evaluate_query_params {
 919         our $cgi;
 920
 921         while (my ($name, $symbol) = each %cgi_param_mapping) {
 922                 if ($symbol eq 'opt') {
 923                         $input_params{$name} = [ map { decode_utf8($_) } $cgi->multi_param($symbol) ];
 924                 } else {
 925                         $input_params{$name} = decode_utf8($cgi->param($symbol));
 926                 }
 927         }
 928 }
 929
 930 # now read PATH_INFO and update the parameter list for missing parameters
 931 sub evaluate_path_info {
 932         return if defined $input_params{'project'};
 933         return if !$path_info;
 934         $path_info =~ s,^/+,,;
 935         return if !$path_info;
 936
 937         # find which part of PATH_INFO is project
 938         my $project = $path_info;
 939         $project =~ s,/+$,,;
 940         while ($project && !check_head_link("$projectroot/$project")) {
 941                 $project =~ s,/*[^/]*$,,;
 942         }
 943         return unless $project;
 944         $input_params{'project'} = $project;
 945
 946         # do not change any parameters if an action is given using the query string
 947         return if $input_params{'action'};
 948         $path_info =~ s,^\Q$project\E/*,,;
 949
 950         # next, check if we have an action
 951         my $action = $path_info;
 952         $action =~ s,/.*$,,;
 953         if (exists $actions{$action}) {
 954                 $path_info =~ s,^$action/*,,;
 955                 $input_params{'action'} = $action;
 956         }
 957
 958         # list of actions that want hash_base instead of hash, but can have no
 959         # pathname (f) parameter
 960         my @wants_base = (
 961                 'tree',
 962                 'history',
 963         );
 964
 965         # we want to catch, among others
 966         # [$hash_parent_base[:$file_parent]..]$hash_parent[:$file_name]
 967         my ($parentrefname, $parentpathname, $refname, $pathname) =
 968                 ($path_info =~ /^(?:(.+?)(?::(.+))?\.\.)?([^:]+?)?(?::(.+))?$/);
 969
 970         # first, analyze the 'current' part
 971         if (defined $pathname) {
 972                 # we got "branch:filename" or "branch:dir/"
 973                 # we could use git_get_type(branch:pathname), but:
 974                 # - it needs $git_dir
 975                 # - it does a git() call
 976                 # - the convention of terminating directories with a slash
 977                 #   makes it superfluous
 978                 # - embedding the action in the PATH_INFO would make it even
 979                 #   more superfluous
 980                 $pathname =~ s,^/+,,;
 981                 if (!$pathname || substr($pathname, -1) eq "/") {
 982                         $input_params{'action'} ||= "tree";
 983                         $pathname =~ s,/$,,;
 984                 } else {
 985                         # the default action depends on whether we had parent info
 986                         # or not
 987                         if ($parentrefname) {
 988                                 $input_params{'action'} ||= "blobdiff_plain";
 989                         } else {
 990                                 $input_params{'action'} ||= "blob_plain";
 991                         }
 992                 }
 993                 $input_params{'hash_base'} ||= $refname;
 994                 $input_params{'file_name'} ||= $pathname;
 995         } elsif (defined $refname) {
 996                 # we got "branch". In this case we have to choose if we have to
 997                 # set hash or hash_base.
 998                 #
 999                 # Most of the actions without a pathname only want hash to be
1000                 # set, except for the ones specified in @wants_base that want
1001                 # hash_base instead. It should also be noted that hand-crafted
1002                 # links having 'history' as an action and no pathname or hash
1003                 # set will fail, but that happens regardless of PATH_INFO.
1004                 if (defined $parentrefname) {
1005                         # if there is parent let the default be 'shortlog' action
1006                         # (for http://git.example.com/repo.git/A..B links); if there
1007                         # is no parent, dispatch will detect type of object and set
1008                         # action appropriately if required (if action is not set)
1009                         $input_params{'action'} ||= "shortlog";
1010                 }
1011                 if ($input_params{'action'} &&
1012                     grep { $_ eq $input_params{'action'} } @wants_base) {
1013                         $input_params{'hash_base'} ||= $refname;
1014                 } else {
1015                         $input_params{'hash'} ||= $refname;
1016                 }
1017         }
1018
1019         # next, handle the 'parent' part, if present
1020         if (defined $parentrefname) {
1021                 # a missing pathspec defaults to the 'current' filename, allowing e.g.
1022                 # someproject/blobdiff/oldrev..newrev:/filename
1023                 if ($parentpathname) {
1024                         $parentpathname =~ s,^/+,,;
1025                         $parentpathname =~ s,/$,,;
1026                         $input_params{'file_parent'} ||= $parentpathname;
1027                 } else {
1028                         $input_params{'file_parent'} ||= $input_params{'file_name'};
1029                 }
1030                 # we assume that hash_parent_base is wanted if a path was specified,
1031                 # or if the action wants hash_base instead of hash
1032                 if (defined $input_params{'file_parent'} ||
1033                         grep { $_ eq $input_params{'action'} } @wants_base) {
1034                         $input_params{'hash_parent_base'} ||= $parentrefname;
1035                 } else {
1036                         $input_params{'hash_parent'} ||= $parentrefname;
1037                 }
1038         }
1039
1040         # for the snapshot action, we allow URLs in the form
1041         # $project/snapshot/$hash.ext
1042         # where .ext determines the snapshot and gets removed from the
1043         # passed $refname to provide the $hash.
1044         #
1045         # To be able to tell that $refname includes the format extension, we
1046         # require the following two conditions to be satisfied:
1047         # - the hash input parameter MUST have been set from the $refname part
1048         #   of the URL (i.e. they must be equal)
1049         # - the snapshot format MUST NOT have been defined already (e.g. from
1050         #   CGI parameter sf)
1051         # It's also useless to try any matching unless $refname has a dot,
1052         # so we check for that too
1053         if (defined $input_params{'action'} &&
1054                 $input_params{'action'} eq 'snapshot' &&
1055                 defined $refname && index($refname, '.') != -1 &&
1056                 $refname eq $input_params{'hash'} &&
1057                 !defined $input_params{'snapshot_format'}) {
1058                 # We loop over the known snapshot formats, checking for
1059                 # extensions. Allowed extensions are both the defined suffix
1060                 # (which includes the initial dot already) and the snapshot
1061                 # format key itself, with a prepended dot
1062                 while (my ($fmt, $opt) = each %known_snapshot_formats) {
1063                         my $hash = $refname;
1064                         unless ($hash =~ s/(\Q$opt->{'suffix'}\E|\Q.$fmt\E)$//) {
1065                                 next;
1066                         }
1067                         my $sfx = $1;
1068                         # a valid suffix was found, so set the snapshot format
1069                         # and reset the hash parameter
1070                         $input_params{'snapshot_format'} = $fmt;
1071                         $input_params{'hash'} = $hash;
1072                         # we also set the format suffix to the one requested
1073                         # in the URL: this way a request for e.g. .tgz returns
1074                         # a .tgz instead of a .tar.gz
1075                         $known_snapshot_formats{$fmt}{'suffix'} = $sfx;
1076                         last;
1077                 }
1078         }
1079 }
1080
1081 our ($action, $project, $file_name, $file_parent, $hash, $hash_parent, $hash_base,
1082      $hash_parent_base, @extra_options, $page, $searchtype, $search_use_regexp,
1083      $searchtext, $search_regexp, $project_filter);
1084 sub evaluate_and_validate_params {
1085         our $action = $input_params{'action'};
1086         if (defined $action) {
1087                 if (!is_valid_action($action)) {
1088                         die_error(400, "Invalid action parameter");
1089                 }
1090         }
1091
1092         # parameters which are pathnames
1093         our $project = $input_params{'project'};
1094         if (defined $project) {
1095                 if (!is_valid_project($project)) {
1096                         undef $project;
1097                         die_error(404, "No such project");
1098                 }
1099         }
1100
1101         our $project_filter = $input_params{'project_filter'};
1102         if (defined $project_filter) {
1103                 if (!is_valid_pathname($project_filter)) {
1104                         die_error(404, "Invalid project_filter parameter");
1105                 }
1106         }
1107
1108         our $file_name = $input_params{'file_name'};
1109         if (defined $file_name) {
1110                 if (!is_valid_pathname($file_name)) {
1111                         die_error(400, "Invalid file parameter");
1112                 }
1113         }
1114
1115         our $file_parent = $input_params{'file_parent'};
1116         if (defined $file_parent) {
1117                 if (!is_valid_pathname($file_parent)) {
1118                         die_error(400, "Invalid file parent parameter");
1119                 }
1120         }
1121
1122         # parameters which are refnames
1123         our $hash = $input_params{'hash'};
1124         if (defined $hash) {
1125                 if (!is_valid_refname($hash)) {
1126                         die_error(400, "Invalid hash parameter");
1127                 }
1128         }
1129
1130         our $hash_parent = $input_params{'hash_parent'};
1131         if (defined $hash_parent) {
1132                 if (!is_valid_refname($hash_parent)) {
1133                         die_error(400, "Invalid hash parent parameter");
1134                 }
1135         }
1136
1137         our $hash_base = $input_params{'hash_base'};
1138         if (defined $hash_base) {
1139                 if (!is_valid_refname($hash_base)) {
1140                         die_error(400, "Invalid hash base parameter");
1141                 }
1142         }
1143
1144         our @extra_options = @{$input_params{'extra_options'}};
1145         # @extra_options is always defined, since it can only be (currently) set from
1146         # CGI, and $cgi->param() returns the empty array in array context if the param
1147         # is not set
1148         foreach my $opt (@extra_options) {
1149                 if (not exists $allowed_options{$opt}) {
1150                         die_error(400, "Invalid option parameter");
1151                 }
1152                 if (not grep(/^$action$/, @{$allowed_options{$opt}})) {
1153                         die_error(400, "Invalid option parameter for this action");
1154                 }
1155         }
1156
1157         our $hash_parent_base = $input_params{'hash_parent_base'};
1158         if (defined $hash_parent_base) {
1159                 if (!is_valid_refname($hash_parent_base)) {
1160                         die_error(400, "Invalid hash parent base parameter");
1161                 }
1162         }
1163
1164         # other parameters
1165         our $page = $input_params{'page'};
1166         if (defined $page) {
1167                 if ($page =~ m/[^0-9]/) {
1168                         die_error(400, "Invalid page parameter");
1169                 }
1170         }
1171
1172         our $searchtype = $input_params{'searchtype'};
1173         if (defined $searchtype) {
1174                 if ($searchtype =~ m/[^a-z]/) {
1175                         die_error(400, "Invalid searchtype parameter");
1176                 }
1177         }
1178
1179         our $search_use_regexp = $input_params{'search_use_regexp'};
1180
1181         our $searchtext = $input_params{'searchtext'};
1182         our $search_regexp = undef;
1183         if (defined $searchtext) {
1184                 if (length($searchtext) < 2) {
1185                         die_error(403, "At least two characters are required for search parameter");
1186                 }
1187                 if ($search_use_regexp) {
1188                         $search_regexp = $searchtext;
1189                         if (!eval { qr/$search_regexp/; 1; }) {
1190                                 (my $error = $@) =~ s/ at \S+ line \d+.*\n?//;
1191                                 die_error(400, "Invalid search regexp '$search_regexp'",
1192                                           esc_html($error));
1193                         }
1194                 } else {
1195                         $search_regexp = quotemeta $searchtext;
1196                 }
1197         }
1198 }
1199
1200 # path to the current git repository
1201 our $git_dir;
1202 sub evaluate_git_dir {
1203         our $git_dir = "$projectroot/$project" if $project;
1204 }
1205
1206 our (@snapshot_fmts, $git_avatar, @extra_branch_refs);
1207 sub configure_gitweb_features {
1208         # list of supported snapshot formats
1209         our @snapshot_fmts = gitweb_get_feature('snapshot');
1210         @snapshot_fmts = filter_snapshot_fmts(@snapshot_fmts);
1211
1212         our ($git_avatar) = gitweb_get_feature('avatar');
1213         $git_avatar = '' unless $git_avatar =~ /^(?:gravatar|picon)$/s;
1214
1215         our @extra_branch_refs = gitweb_get_feature('extra-branch-refs');
1216         @extra_branch_refs = filter_and_validate_refs (@extra_branch_refs);
1217 }
1218
1219 sub get_branch_refs {
1220         return ('heads', @extra_branch_refs);
1221 }
1222
1223 # custom error handler: 'die <message>' is Internal Server Error
1224 sub handle_errors_html {
1225         my $msg = shift; # it is already HTML escaped
1226
1227         # to avoid infinite loop where error occurs in die_error,
1228         # change handler to default handler, disabling handle_errors_html
1229         set_message("Error occurred when inside die_error:\n$msg");
1230
1231         # you cannot jump out of die_error when called as error handler;
1232         # the subroutine set via CGI::Carp::set_message is called _after_
1233         # HTTP headers are already written, so it cannot write them itself
1234         die_error(undef, undef, $msg, -error_handler => 1, -no_http_header => 1);
1235 }
1236 set_message(\&handle_errors_html);
1237
1238 # dispatch
1239 sub dispatch {
1240         if (!defined $action) {
1241                 if (defined $hash) {
1242                         $action = git_get_type($hash);
1243                         $action or die_error(404, "Object does not exist");
1244                 } elsif (defined $hash_base && defined $file_name) {
1245                         $action = git_get_type("$hash_base:$file_name");
1246                         $action or die_error(404, "File or directory does not exist");
1247                 } elsif (defined $project) {
1248                         $action = 'summary';
1249                 } else {
1250                         $action = 'project_list';
1251                 }
1252         }
1253         if (!defined($actions{$action})) {
1254                 die_error(400, "Unknown action");
1255         }
1256         if ($action !~ m/^(?:opml|project_list|project_index)$/ &&
1257             !$project) {
1258                 die_error(400, "Project needed");
1259         }
1260         $actions{$action}->();
1261 }
1262
1263 sub reset_timer {
1264         our $t0 = [ gettimeofday() ]
1265                 if defined $t0;
1266         our $number_of_git_cmds = 0;
1267 }
1268
1269 our $first_request = 1;
1270 sub run_request {
1271         reset_timer();
1272
1273         evaluate_uri();
1274         if ($first_request) {
1275                 evaluate_gitweb_config();
1276                 evaluate_git_version();
1277         }
1278         if ($per_request_config) {
1279                 if (ref($per_request_config) eq 'CODE') {
1280                         $per_request_config->();
1281                 } elsif (!$first_request) {
1282                         evaluate_gitweb_config();
1283                 }
1284         }
1285         check_loadavg();
1286
1287         # $projectroot and $projects_list might be set in gitweb config file
1288         $projects_list ||= $projectroot;
1289
1290         evaluate_query_params();
1291         evaluate_path_info();
1292         evaluate_and_validate_params();
1293         evaluate_git_dir();
1294
1295         configure_gitweb_features();
1296
1297         dispatch();
1298 }
1299
1300 our $is_last_request = sub { 1 };
1301 our ($pre_dispatch_hook, $post_dispatch_hook, $pre_listen_hook);
1302 our $CGI = 'CGI';
1303 our $cgi;
1304 our $FCGI_Stream_PRINT_raw = \&FCGI::Stream::PRINT;
1305 sub configure_as_fcgi {
1306         require CGI::Fast;
1307         our $CGI = 'CGI::Fast';
1308         # FCGI is not Unicode aware hence the UTF-8 encoding must be done manually.
1309         # However no encoding must be done within git_blob_plain() and git_snapshot()
1310         # which must still output in raw binary mode.
1311         no warnings 'redefine';
1312         my $enc = Encode::find_encoding('UTF-8');
1313         *FCGI::Stream::PRINT = sub {
1314                 my @OUTPUT = @_;
1315                 for (my $i = 1; $i < @_; $i++) {
1316                         $OUTPUT[$i] = $enc->encode($_[$i], Encode::FB_CROAK|Encode::LEAVE_SRC);
1317                 }
1318                 @_ = @OUTPUT;
1319                 goto $FCGI_Stream_PRINT_raw;
1320         };
1321
1322         my $request_number = 0;
1323         # let each child service 100 requests
1324         our $is_last_request = sub { ++$request_number > 100 };
1325 }
1326 sub evaluate_argv {
1327         my $script_name = $ENV{'SCRIPT_NAME'} || $ENV{'SCRIPT_FILENAME'} || __FILE__;
1328         configure_as_fcgi()
1329                 if $script_name =~ /\.fcgi$/;
1330
1331         return unless (@ARGV);
1332
1333         require Getopt::Long;
1334         Getopt::Long::GetOptions(
1335                 'fastcgi|fcgi|f' => \&configure_as_fcgi,
1336                 'nproc|n=i' => sub {
1337                         my ($arg, $val) = @_;
1338                         return unless eval { require FCGI::ProcManager; 1; };
1339                         my $proc_manager = FCGI::ProcManager->new({
1340                                 n_processes => $val,
1341                         });
1342                         our $pre_listen_hook    = sub { $proc_manager->pm_manage()        };
1343                         our $pre_dispatch_hook  = sub { $proc_manager->pm_pre_dispatch()  };
1344                         our $post_dispatch_hook = sub { $proc_manager->pm_post_dispatch() };
1345                 },
1346         );
1347 }
1348
1349 sub run {
1350         evaluate_argv();
1351
1352         $first_request = 1;
1353         $pre_listen_hook->()
1354                 if $pre_listen_hook;
1355
1356  REQUEST:
1357         while ($cgi = $CGI->new()) {
1358                 $pre_dispatch_hook->()
1359                         if $pre_dispatch_hook;
1360
1361                 run_request();
1362
1363                 $post_dispatch_hook->()
1364                         if $post_dispatch_hook;
1365                 $first_request = 0;
1366
1367                 last REQUEST if ($is_last_request->());
1368         }
1369
1370  DONE_GITWEB:
1371         1;
1372 }
1373
1374 run();
1375
1376 if (defined caller) {
1377         # wrapped in a subroutine processing requests,
1378         # e.g. mod_perl with ModPerl::Registry, or PSGI with Plack::App::WrapCGI
1379         return;
1380 } else {
1381         # pure CGI script, serving single request
1382         exit;
1383 }
1384
1385 ## ======================================================================
1386 ## action links
1387
1388 # possible values of extra options
1389 # -full => 0|1      - use absolute/full URL ($my_uri/$my_url as base)
1390 # -replay => 1      - start from a current view (replay with modifications)
1391 # -path_info => 0|1 - don't use/use path_info URL (if possible)
1392 # -anchor => ANCHOR - add #ANCHOR to end of URL, implies -replay if used alone
1393 sub href {
1394         my %params = @_;
1395         # default is to use -absolute url() i.e. $my_uri
1396         my $href = $params{-full} ? $my_url : $my_uri;
1397
1398         # implicit -replay, must be first of implicit params
1399         $params{-replay} = 1 if (keys %params == 1 && $params{-anchor});
1400
1401         $params{'project'} = $project unless exists $params{'project'};
1402
1403         if ($params{-replay}) {
1404                 while (my ($name, $symbol) = each %cgi_param_mapping) {
1405                         if (!exists $params{$name}) {
1406                                 $params{$name} = $input_params{$name};
1407                         }
1408                 }
1409         }
1410
1411         my $use_pathinfo = gitweb_check_feature('pathinfo');
1412         if (defined $params{'project'} &&
1413             (exists $params{-path_info} ? $params{-path_info} : $use_pathinfo)) {
1414                 # try to put as many parameters as possible in PATH_INFO:
1415                 #   - project name
1416                 #   - action
1417                 #   - hash_parent or hash_parent_base:/file_parent
1418                 #   - hash or hash_base:/filename
1419                 #   - the snapshot_format as an appropriate suffix
1420
1421                 # When the script is the root DirectoryIndex for the domain,
1422                 # $href here would be something like http://gitweb.example.com/
1423                 # Thus, we strip any trailing / from $href, to spare us double
1424                 # slashes in the final URL
1425                 $href =~ s,/$,,;
1426
1427                 # Then add the project name, if present
1428                 $href .= "/".esc_path_info($params{'project'});
1429                 delete $params{'project'};
1430
1431                 # since we destructively absorb parameters, we keep this
1432                 # boolean that remembers if we're handling a snapshot
1433                 my $is_snapshot = $params{'action'} eq 'snapshot';
1434
1435                 # Summary just uses the project path URL, any other action is
1436                 # added to the URL
1437                 if (defined $params{'action'}) {
1438                         $href .= "/".esc_path_info($params{'action'})
1439                                 unless $params{'action'} eq 'summary';
1440                         delete $params{'action'};
1441                 }
1442
1443                 # Next, we put hash_parent_base:/file_parent..hash_base:/file_name,
1444                 # stripping nonexistent or useless pieces
1445                 $href .= "/" if ($params{'hash_base'} || $params{'hash_parent_base'}
1446                         || $params{'hash_parent'} || $params{'hash'});
1447                 if (defined $params{'hash_base'}) {
1448                         if (defined $params{'hash_parent_base'}) {
1449                                 $href .= esc_path_info($params{'hash_parent_base'});
1450                                 # skip the file_parent if it's the same as the file_name
1451                                 if (defined $params{'file_parent'}) {
1452                                         if (defined $params{'file_name'} && $params{'file_parent'} eq $params{'file_name'}) {
1453                                                 delete $params{'file_parent'};
1454                                         } elsif ($params{'file_parent'} !~ /\.\./) {
1455                                                 $href .= ":/".esc_path_info($params{'file_parent'});
1456                                                 delete $params{'file_parent'};
1457                                         }
1458                                 }
1459                                 $href .= "..";
1460                                 delete $params{'hash_parent'};
1461                                 delete $params{'hash_parent_base'};
1462                         } elsif (defined $params{'hash_parent'}) {
1463                                 $href .= esc_path_info($params{'hash_parent'}). "..";
1464                                 delete $params{'hash_parent'};
1465                         }
1466
1467                         $href .= esc_path_info($params{'hash_base'});
1468                         if (defined $params{'file_name'} && $params{'file_name'} !~ /\.\./) {
1469                                 $href .= ":/".esc_path_info($params{'file_name'});
1470                                 delete $params{'file_name'};
1471                         }
1472                         delete $params{'hash'};
1473                         delete $params{'hash_base'};
1474                 } elsif (defined $params{'hash'}) {
1475                         $href .= esc_path_info($params{'hash'});
1476                         delete $params{'hash'};
1477                 }
1478
1479                 # If the action was a snapshot, we can absorb the
1480                 # snapshot_format parameter too
1481                 if ($is_snapshot) {
1482                         my $fmt = $params{'snapshot_format'};
1483                         # snapshot_format should always be defined when href()
1484                         # is called, but just in case some code forgets, we
1485                         # fall back to the default
1486                         $fmt ||= $snapshot_fmts[0];
1487                         $href .= $known_snapshot_formats{$fmt}{'suffix'};
1488                         delete $params{'snapshot_format'};
1489                 }
1490         }
1491
1492         # now encode the parameters explicitly
1493         my @result = ();
1494         for (my $i = 0; $i < @cgi_param_mapping; $i += 2) {
1495                 my ($name, $symbol) = ($cgi_param_mapping[$i], $cgi_param_mapping[$i+1]);
1496                 if (defined $params{$name}) {
1497                         if (ref($params{$name}) eq "ARRAY") {
1498                                 foreach my $par (@{$params{$name}}) {
1499                                         push @result, $symbol . "=" . esc_param($par);
1500                                 }
1501                         } else {
1502                                 push @result, $symbol . "=" . esc_param($params{$name});
1503                         }
1504                 }
1505         }
1506         $href .= "?" . join(';', @result) if scalar @result;
1507
1508         # final transformation: trailing spaces must be escaped (URI-encoded)
1509         $href =~ s/(\s+)$/CGI::escape($1)/e;
1510
1511         if ($params{-anchor}) {
1512                 $href .= "#".esc_param($params{-anchor});
1513         }
1514
1515         return $href;
1516 }
1517
1518
1519 ## ======================================================================
1520 ## validation, quoting/unquoting and escaping
1521
1522 sub is_valid_action {
1523         my $input = shift;
1524         return undef unless exists $actions{$input};
1525         return 1;
1526 }
1527
1528 sub is_valid_project {
1529         my $input = shift;
1530
1531         return unless defined $input;
1532         if (!is_valid_pathname($input) ||
1533                 !(-d "$projectroot/$input") ||
1534                 !check_export_ok("$projectroot/$input") ||
1535                 ($strict_export && !project_in_list($input))) {
1536                 return undef;
1537         } else {
1538                 return 1;
1539         }
1540 }
1541
1542 sub is_valid_pathname {
1543         my $input = shift;
1544
1545         return undef unless defined $input;
1546         # no '.' or '..' as elements of path, i.e. no '.' or '..'
1547         # at the beginning, at the end, and between slashes.
1548         # also this catches doubled slashes
1549         if ($input =~ m!(^|/)(|\.|\.\.)(/|$)!) {
1550                 return undef;
1551         }
1552         # no null characters
1553         if ($input =~ m!\0!) {
1554                 return undef;
1555         }
1556         return 1;
1557 }
1558
1559 sub is_valid_ref_format {
1560         my $input = shift;
1561
1562         return undef unless defined $input;
1563         # restrictions on ref name according to git-check-ref-format
1564         if ($input =~ m!(/\.|\.\.|[\000-\040\177 ~^:?*\[]|/$)!) {
1565                 return undef;
1566         }
1567         return 1;
1568 }
1569
1570 sub is_valid_refname {
1571         my $input = shift;
1572
1573         return undef unless defined $input;
1574         # textual hashes are O.K.
1575         if ($input =~ m/^$oid_regex$/) {
1576                 return 1;
1577         }
1578         # it must be correct pathname
1579         is_valid_pathname($input) or return undef;
1580         # check git-check-ref-format restrictions
1581         is_valid_ref_format($input) or return undef;
1582         return 1;
1583 }
1584
1585 # decode sequences of octets in utf8 into Perl's internal form,
1586 # which is utf-8 with utf8 flag set if needed.  gitweb writes out
1587 # in utf-8 thanks to "binmode STDOUT, ':utf8'" at beginning
1588 sub to_utf8 {
1589         my $str = shift;
1590         return undef unless defined $str;
1591
1592         if (utf8::is_utf8($str) || utf8::decode($str)) {
1593                 return $str;
1594         } else {
1595                 return decode($fallback_encoding, $str, Encode::FB_DEFAULT);
1596         }
1597 }
1598
1599 # quote unsafe chars, but keep the slash, even when it's not
1600 # correct, but quoted slashes look too horrible in bookmarks
1601 sub esc_param {
1602         my $str = shift;
1603         return undef unless defined $str;
1604         $str =~ s/([^A-Za-z0-9\-_.~()\/:@ ]+)/CGI::escape($1)/eg;
1605         $str =~ s/ /\+/g;
1606         return $str;
1607 }
1608
1609 # the quoting rules for path_info fragment are slightly different
1610 sub esc_path_info {
1611         my $str = shift;
1612         return undef unless defined $str;
1613
1614         # path_info doesn't treat '+' as space (specially), but '?' must be escaped
1615         $str =~ s/([^A-Za-z0-9\-_.~();\/;:@&= +]+)/CGI::escape($1)/eg;
1616
1617         return $str;
1618 }
1619
1620 # quote unsafe chars in whole URL, so some characters cannot be quoted
1621 sub esc_url {
1622         my $str = shift;
1623         return undef unless defined $str;
1624         $str =~ s/([^A-Za-z0-9\-_.~();\/;?:@&= ]+)/CGI::escape($1)/eg;
1625         $str =~ s/ /\+/g;
1626         return $str;
1627 }
1628
1629 # quote unsafe characters in HTML attributes
1630 sub esc_attr {
1631
1632         # for XHTML conformance escaping '"' to '&quot;' is not enough
1633         return esc_html(@_);
1634 }
1635
1636 # replace invalid utf8 character with SUBSTITUTION sequence
1637 sub esc_html {
1638         my $str = shift;
1639         my %opts = @_;
1640
1641         return undef unless defined $str;
1642
1643         $str = to_utf8($str);
1644         $str = $cgi->escapeHTML($str);
1645         if ($opts{'-nbsp'}) {
1646                 $str =~ s/ /&nbsp;/g;
1647         }
1648         $str =~ s|([[:cntrl:]])|(($1 ne "\t") ? quot_cec($1) : $1)|eg;
1649         return $str;
1650 }
1651
1652 # quote control characters and escape filename to HTML
1653 sub esc_path {
1654         my $str = shift;
1655         my %opts = @_;
1656
1657         return undef unless defined $str;
1658
1659         $str = to_utf8($str);
1660         $str = $cgi->escapeHTML($str);
1661         if ($opts{'-nbsp'}) {
1662                 $str =~ s/ /&nbsp;/g;
1663         }
1664         $str =~ s|([[:cntrl:]])|quot_cec($1)|eg;
1665         return $str;
1666 }
1667
1668 # Sanitize for use in XHTML + application/xml+xhtml (valid XML 1.0)
1669 sub sanitize {
1670         my $str = shift;
1671
1672         return undef unless defined $str;
1673
1674         $str = to_utf8($str);
1675         $str =~ s|([[:cntrl:]])|(index("\t\n\r", $1) != -1 ? $1 : quot_cec($1))|eg;
1676         return $str;
1677 }
1678
1679 # Make control characters "printable", using character escape codes (CEC)
1680 sub quot_cec {
1681         my $cntrl = shift;
1682         my %opts = @_;
1683         my %es = ( # character escape codes, aka escape sequences
1684                 "\t" => '\t',   # tab             (HT)
1685                 "\n" => '\n',   # line feed       (LF)
1686                 "\r" => '\r',   # carriage return (CR)
1687                 "\f" => '\f',   # form feed       (FF)
1688                 "\b" => '\b',   # backspace       (BS)
1689                 "\a" => '\a',   # alarm (bell)    (BEL)
1690                 "\e" => '\e',   # escape          (ESC)
1691                 "\013" => '\v', # vertical tab    (VT)
1692                 "\000" => '\0', # nul character   (NUL)
1693         );
1694         my $chr = ( (exists $es{$cntrl})
1695                     ? $es{$cntrl}
1696                     : sprintf('\%2x', ord($cntrl)) );
1697         if ($opts{-nohtml}) {
1698                 return $chr;
1699         } else {
1700                 return "<span class=\"cntrl\">$chr</span>";
1701         }
1702 }
1703
1704 # Alternatively use unicode control pictures codepoints,
1705 # Unicode "printable representation" (PR)
1706 sub quot_upr {
1707         my $cntrl = shift;
1708         my %opts = @_;
1709
1710         my $chr = sprintf('&#%04d;', 0x2400+ord($cntrl));
1711         if ($opts{-nohtml}) {
1712                 return $chr;
1713         } else {
1714                 return "<span class=\"cntrl\">$chr</span>";
1715         }
1716 }
1717
1718 # git may return quoted and escaped filenames
1719 sub unquote {
1720         my $str = shift;
1721
1722         sub unq {
1723                 my $seq = shift;
1724                 my %es = ( # character escape codes, aka escape sequences
1725                         't' => "\t",   # tab            (HT, TAB)
1726                         'n' => "\n",   # newline        (NL)
1727                         'r' => "\r",   # return         (CR)
1728                         'f' => "\f",   # form feed      (FF)
1729                         'b' => "\b",   # backspace      (BS)
1730                         'a' => "\a",   # alarm (bell)   (BEL)
1731                         'e' => "\e",   # escape         (ESC)
1732                         'v' => "\013", # vertical tab   (VT)
1733                 );
1734
1735                 if ($seq =~ m/^[0-7]{1,3}$/) {
1736                         # octal char sequence
1737                         return chr(oct($seq));
1738                 } elsif (exists $es{$seq}) {
1739                         # C escape sequence, aka character escape code
1740                         return $es{$seq};
1741                 }
1742                 # quoted ordinary character
1743                 return $seq;
1744         }
1745
1746         if ($str =~ m/^"(.*)"$/) {
1747                 # needs unquoting
1748                 $str = $1;
1749                 $str =~ s/\\([^0-7]|[0-7]{1,3})/unq($1)/eg;
1750         }
1751         return $str;
1752 }
1753
1754 # escape tabs (convert tabs to spaces)
1755 sub untabify {
1756         my $line = shift;
1757
1758         while ((my $pos = index($line, "\t")) != -1) {
1759                 if (my $count = (8 - ($pos % 8))) {
1760                         my $spaces = ' ' x $count;
1761                         $line =~ s/\t/$spaces/;
1762                 }
1763         }
1764
1765         return $line;
1766 }
1767
1768 sub project_in_list {
1769         my $project = shift;
1770         my @list = git_get_projects_list();
1771         return @list && scalar(grep { $_->{'path'} eq $project } @list);
1772 }
1773
1774 ## ----------------------------------------------------------------------
1775 ## HTML aware string manipulation
1776
1777 # Try to chop given string on a word boundary between position
1778 # $len and $len+$add_len. If there is no word boundary there,
1779 # chop at $len+$add_len. Do not chop if chopped part plus ellipsis
1780 # (marking chopped part) would be longer than given string.
1781 sub chop_str {
1782         my $str = shift;
1783         my $len = shift;
1784         my $add_len = shift || 10;
1785         my $where = shift || 'right'; # 'left' | 'center' | 'right'
1786
1787         # Make sure perl knows it is utf8 encoded so we don't
1788         # cut in the middle of a utf8 multibyte char.
1789         $str = to_utf8($str);
1790
1791         # allow only $len chars, but don't cut a word if it would fit in $add_len
1792         # if it doesn't fit, cut it if it's still longer than the dots we would add
1793         # remove chopped character entities entirely
1794
1795         # when chopping in the middle, distribute $len into left and right part
1796         # return early if chopping wouldn't make string shorter
1797         if ($where eq 'center') {
1798                 return $str if ($len + 5 >= length($str)); # filler is length 5
1799                 $len = int($len/2);
1800         } else {
1801                 return $str if ($len + 4 >= length($str)); # filler is length 4
1802         }
1803
1804         # regexps: ending and beginning with word part up to $add_len
1805         my $endre = qr/.{$len}\w{0,$add_len}/;
1806         my $begre = qr/\w{0,$add_len}.{$len}/;
1807
1808         if ($where eq 'left') {
1809                 $str =~ m/^(.*?)($begre)$/;
1810                 my ($lead, $body) = ($1, $2);
1811                 if (length($lead) > 4) {
1812                         $lead = " ...";
1813                 }
1814                 return "$lead$body";
1815
1816         } elsif ($where eq 'center') {
1817                 $str =~ m/^($endre)(.*)$/;
1818                 my ($left, $str)  = ($1, $2);
1819                 $str =~ m/^(.*?)($begre)$/;
1820                 my ($mid, $right) = ($1, $2);
1821                 if (length($mid) > 5) {
1822                         $mid = " ... ";
1823                 }
1824                 return "$left$mid$right";
1825
1826         } else {
1827                 $str =~ m/^($endre)(.*)$/;
1828                 my $body = $1;
1829                 my $tail = $2;
1830                 if (length($tail) > 4) {
1831                         $tail = "... ";
1832                 }
1833                 return "$body$tail";
1834         }
1835 }
1836
1837 # takes the same arguments as chop_str, but also wraps a <span> around the
1838 # result with a title attribute if it does get chopped. Additionally, the
1839 # string is HTML-escaped.
1840 sub chop_and_escape_str {
1841         my ($str) = @_;
1842
1843         my $chopped = chop_str(@_);
1844         $str = to_utf8($str);
1845         if ($chopped eq $str) {
1846                 return esc_html($chopped);
1847         } else {
1848                 $str =~ s/[[:cntrl:]]/?/g;
1849                 return $cgi->span({-title=>$str}, esc_html($chopped));
1850         }
1851 }
1852
1853 # Highlight selected fragments of string, using given CSS class,
1854 # and escape HTML.  It is assumed that fragments do not overlap.
1855 # Regions are passed as list of pairs (array references).
1856 #
1857 # Example: esc_html_hl_regions("foobar", "mark", [ 0, 3 ]) returns
1858 # '<span class="mark">foo</span>bar'
1859 sub esc_html_hl_regions {
1860         my ($str, $css_class, @sel) = @_;
1861         my %opts = grep { ref($_) ne 'ARRAY' } @sel;
1862         @sel     = grep { ref($_) eq 'ARRAY' } @sel;
1863         return esc_html($str, %opts) unless @sel;
1864
1865         my $out = '';
1866         my $pos = 0;
1867
1868         for my $s (@sel) {
1869                 my ($begin, $end) = @$s;
1870
1871                 # Don't create empty <span> elements.
1872                 next if $end <= $begin;
1873
1874                 my $escaped = esc_html(substr($str, $begin, $end - $begin),
1875                                        %opts);
1876
1877                 $out .= esc_html(substr($str, $pos, $begin - $pos), %opts)
1878                         if ($begin - $pos > 0);
1879                 $out .= $cgi->span({-class => $css_class}, $escaped);
1880
1881                 $pos = $end;
1882         }
1883         $out .= esc_html(substr($str, $pos), %opts)
1884                 if ($pos < length($str));
1885
1886         return $out;
1887 }
1888
1889 # return positions of beginning and end of each match
1890 sub matchpos_list {
1891         my ($str, $regexp) = @_;
1892         return unless (defined $str && defined $regexp);
1893
1894         my @matches;
1895         while ($str =~ /$regexp/g) {
1896                 push @matches, [$-[0], $+[0]];
1897         }
1898         return @matches;
1899 }
1900
1901 # highlight match (if any), and escape HTML
1902 sub esc_html_match_hl {
1903         my ($str, $regexp) = @_;
1904         return esc_html($str) unless defined $regexp;
1905
1906         my @matches = matchpos_list($str, $regexp);
1907         return esc_html($str) unless @matches;
1908
1909         return esc_html_hl_regions($str, 'match', @matches);
1910 }
1911
1912
1913 # highlight match (if any) of shortened string, and escape HTML
1914 sub esc_html_match_hl_chopped {
1915         my ($str, $chopped, $regexp) = @_;
1916         return esc_html_match_hl($str, $regexp) unless defined $chopped;
1917
1918         my @matches = matchpos_list($str, $regexp);
1919         return esc_html($chopped) unless @matches;
1920
1921         # filter matches so that we mark chopped string
1922         my $tail = "... "; # see chop_str
1923         unless ($chopped =~ s/\Q$tail\E$//) {
1924                 $tail = '';
1925         }
1926         my $chop_len = length($chopped);
1927         my $tail_len = length($tail);
1928         my @filtered;
1929
1930         for my $m (@matches) {
1931                 if ($m->[0] > $chop_len) {
1932                         push @filtered, [ $chop_len, $chop_len + $tail_len ] if ($tail_len > 0);
1933                         last;
1934                 } elsif ($m->[1] > $chop_len) {
1935                         push @filtered, [ $m->[0], $chop_len + $tail_len ];
1936                         last;
1937                 }
1938                 push @filtered, $m;
1939         }
1940
1941         return esc_html_hl_regions($chopped . $tail, 'match', @filtered);
1942 }
1943
1944 ## ----------------------------------------------------------------------
1945 ## functions returning short strings
1946
1947 # CSS class for given age value (in seconds)
1948 sub age_class {
1949         my $age = shift;
1950
1951         if (!defined $age) {
1952                 return "noage";
1953         } elsif ($age < 60*60*2) {
1954                 return "age0";
1955         } elsif ($age < 60*60*24*2) {
1956                 return "age1";
1957         } else {
1958                 return "age2";
1959         }
1960 }
1961
1962 # convert age in seconds to "nn units ago" string
1963 sub age_string {
1964         my $age = shift;
1965         my $age_str;
1966
1967         if ($age > 60*60*24*365*2) {
1968                 $age_str = (int $age/60/60/24/365);
1969                 $age_str .= " years ago";
1970         } elsif ($age > 60*60*24*(365/12)*2) {
1971                 $age_str = int $age/60/60/24/(365/12);
1972                 $age_str .= " months ago";
1973         } elsif ($age > 60*60*24*7*2) {
1974                 $age_str = int $age/60/60/24/7;
1975                 $age_str .= " weeks ago";
1976         } elsif ($age > 60*60*24*2) {
1977                 $age_str = int $age/60/60/24;
1978                 $age_str .= " days ago";
1979         } elsif ($age > 60*60*2) {
1980                 $age_str = int $age/60/60;
1981                 $age_str .= " hours ago";
1982         } elsif ($age > 60*2) {
1983                 $age_str = int $age/60;
1984                 $age_str .= " min ago";
1985         } elsif ($age > 2) {
1986                 $age_str = int $age;
1987                 $age_str .= " sec ago";
1988         } else {
1989                 $age_str .= " right now";
1990         }
1991         return $age_str;
1992 }
1993
1994 use constant {
1995         S_IFINVALID => 0030000,
1996         S_IFGITLINK => 0160000,
1997 };
1998
1999 # submodule/subproject, a commit object reference
2000 sub S_ISGITLINK {
2001         my $mode = shift;
2002
2003         return (($mode & S_IFMT) == S_IFGITLINK)
2004 }
2005
2006 # convert file mode in octal to symbolic file mode string
2007 sub mode_str {
2008         my $mode = oct shift;
2009
2010         if (S_ISGITLINK($mode)) {
2011                 return 'm---------';
2012         } elsif (S_ISDIR($mode & S_IFMT)) {
2013                 return 'drwxr-xr-x';
2014         } elsif (S_ISLNK($mode)) {
2015                 return 'lrwxrwxrwx';
2016         } elsif (S_ISREG($mode)) {
2017                 # git cares only about the executable bit
2018                 if ($mode & S_IXUSR) {
2019                         return '-rwxr-xr-x';
2020                 } else {
2021                         return '-rw-r--r--';
2022                 };
2023         } else {
2024                 return '----------';
2025         }
2026 }
2027
2028 # convert file mode in octal to file type string
2029 sub file_type {
2030         my $mode = shift;
2031
2032         if ($mode !~ m/^[0-7]+$/) {
2033                 return $mode;
2034         } else {
2035                 $mode = oct $mode;
2036         }
2037
2038         if (S_ISGITLINK($mode)) {
2039                 return "submodule";
2040         } elsif (S_ISDIR($mode & S_IFMT)) {
2041                 return "directory";
2042         } elsif (S_ISLNK($mode)) {
2043                 return "symlink";
2044         } elsif (S_ISREG($mode)) {
2045                 return "file";
2046         } else {
2047                 return "unknown";
2048         }
2049 }
2050
2051 # convert file mode in octal to file type description string
2052 sub file_type_long {
2053         my $mode = shift;
2054
2055         if ($mode !~ m/^[0-7]+$/) {
2056                 return $mode;
2057         } else {
2058                 $mode = oct $mode;
2059         }
2060
2061         if (S_ISGITLINK($mode)) {
2062                 return "submodule";
2063         } elsif (S_ISDIR($mode & S_IFMT)) {
2064                 return "directory";
2065         } elsif (S_ISLNK($mode)) {
2066                 return "symlink";
2067         } elsif (S_ISREG($mode)) {
2068                 if ($mode & S_IXUSR) {
2069                         return "executable";
2070                 } else {
2071                         return "file";
2072                 };
2073         } else {
2074                 return "unknown";
2075         }
2076 }
2077
2078
2079 ## ----------------------------------------------------------------------
2080 ## functions returning short HTML fragments, or transforming HTML fragments
2081 ## which don't belong to other sections
2082
2083 # format line of commit message.
2084 sub format_log_line_html {
2085         my $line = shift;
2086
2087         # Potentially abbreviated OID.
2088         my $regex = oid_nlen_regex("7,64");
2089
2090         $line = esc_html($line, -nbsp=>1);
2091         $line =~ s{
2092         \b
2093         (
2094             # The output of "git describe", e.g. v2.10.0-297-gf6727b0
2095             # or hadoop-20160921-113441-20-g094fb7d
2096             (?<!-) # see strbuf_check_tag_ref(). Tags can't start with -
2097             [A-Za-z0-9.-]+
2098             (?!\.) # refs can't end with ".", see check_refname_format()
2099             -g$regex
2100             |
2101             # Just a normal looking Git SHA1
2102             $regex
2103         )
2104         \b
2105     }{
2106                 $cgi->a({-href => href(action=>"object", hash=>$1),
2107                                         -class => "text"}, $1);
2108         }egx;
2109
2110         return $line;
2111 }
2112
2113 # format marker of refs pointing to given object
2114
2115 # the destination action is chosen based on object type and current context:
2116 # - for annotated tags, we choose the tag view unless it's the current view
2117 #   already, in which case we go to shortlog view
2118 # - for other refs, we keep the current view if we're in history, shortlog or
2119 #   log view, and select shortlog otherwise
2120 sub format_ref_marker {
2121         my ($refs, $id) = @_;
2122         my $markers = '';
2123
2124         if (defined $refs->{$id}) {
2125                 foreach my $ref (@{$refs->{$id}}) {
2126                         # this code exploits the fact that non-lightweight tags are the
2127                         # only indirect objects, and that they are the only objects for which
2128                         # we want to use tag instead of shortlog as action
2129                         my ($type, $name) = qw();
2130                         my $indirect = ($ref =~ s/\^\{\}$//);
2131                         # e.g. tags/v2.6.11 or heads/next
2132                         if ($ref =~ m!^(.*?)s?/(.*)$!) {
2133                                 $type = $1;
2134                                 $name = $2;
2135                         } else {
2136                                 $type = "ref";
2137                                 $name = $ref;
2138                         }
2139
2140                         my $class = $type;
2141                         $class .= " indirect" if $indirect;
2142
2143                         my $dest_action = "shortlog";
2144
2145                         if ($indirect) {
2146                                 $dest_action = "tag" unless $action eq "tag";
2147                         } elsif ($action =~ /^(history|(short)?log)$/) {
2148                                 $dest_action = $action;
2149                         }
2150
2151                         my $dest = "";
2152                         $dest .= "refs/" unless $ref =~ m!^refs/!;
2153                         $dest .= $ref;
2154
2155                         my $link = $cgi->a({
2156                                 -href => href(
2157                                         action=>$dest_action,
2158                                         hash=>$dest
2159                                 )}, esc_html($name));
2160
2161                         $markers .= " <span class=\"".esc_attr($class)."\" title=\"".esc_attr($ref)."\">" .
2162                                 $link . "</span>";
2163                 }
2164         }
2165
2166         if ($markers) {
2167                 return ' <span class="refs">'. $markers . '</span>';
2168         } else {
2169                 return "";
2170         }
2171 }
2172
2173 # format, perhaps shortened and with markers, title line
2174 sub format_subject_html {
2175         my ($long, $short, $href, $extra) = @_;
2176         $extra = '' unless defined($extra);
2177
2178         if (length($short) < length($long)) {
2179                 $long =~ s/[[:cntrl:]]/?/g;
2180                 return $cgi->a({-href => $href, -class => "list subject",
2181                                 -title => to_utf8($long)},
2182                        esc_html($short)) . $extra;
2183         } else {
2184                 return $cgi->a({-href => $href, -class => "list subject"},
2185                        esc_html($long)) . $extra;
2186         }
2187 }
2188
2189 # Rather than recomputing the url for an email multiple times, we cache it
2190 # after the first hit. This gives a visible benefit in views where the avatar
2191 # for the same email is used repeatedly (e.g. shortlog).
2192 # The cache is shared by all avatar engines (currently gravatar only), which
2193 # are free to use it as preferred. Since only one avatar engine is used for any
2194 # given page, there's no risk for cache conflicts.
2195 our %avatar_cache = ();
2196
2197 # Compute the picon url for a given email, by using the picon search service over at
2198 # http://www.cs.indiana.edu/picons/search.html
2199 sub picon_url {
2200         my $email = lc shift;
2201         if (!$avatar_cache{$email}) {
2202                 my ($user, $domain) = split('@', $email);
2203                 $avatar_cache{$email} =
2204                         "//www.cs.indiana.edu/cgi-pub/kinzler/piconsearch.cgi/" .
2205                         "$domain/$user/" .
2206                         "users+domains+unknown/up/single";
2207         }
2208         return $avatar_cache{$email};
2209 }
2210
2211 # Compute the gravatar url for a given email, if it's not in the cache already.
2212 # Gravatar stores only the part of the URL before the size, since that's the
2213 # one computationally more expensive. This also allows reuse of the cache for
2214 # different sizes (for this particular engine).
2215 sub gravatar_url {
2216         my $email = lc shift;
2217         my $size = shift;
2218         $avatar_cache{$email} ||=
2219                 "//www.gravatar.com/avatar/" .
2220                         md5_hex($email) . "?s=";
2221         return $avatar_cache{$email} . $size;
2222 }
2223
2224 # Insert an avatar for the given $email at the given $size if the feature
2225 # is enabled.
2226 sub git_get_avatar {
2227         my ($email, %opts) = @_;
2228         my $pre_white  = ($opts{-pad_before} ? "&nbsp;" : "");
2229         my $post_white = ($opts{-pad_after}  ? "&nbsp;" : "");
2230         $opts{-size} ||= 'default';
2231         my $size = $avatar_size{$opts{-size}} || $avatar_size{'default'};
2232         my $url = "";
2233         if ($git_avatar eq 'gravatar') {
2234                 $url = gravatar_url($email, $size);
2235         } elsif ($git_avatar eq 'picon') {
2236                 $url = picon_url($email);
2237         }
2238         # Other providers can be added by extending the if chain, defining $url
2239         # as needed. If no variant puts something in $url, we assume avatars
2240         # are completely disabled/unavailable.
2241         if ($url) {
2242                 return $pre_white .
2243                        "<img width=\"$size\" " .
2244                             "class=\"avatar\" " .
2245                             "src=\"".esc_url($url)."\" " .
2246                             "alt=\"\" " .
2247                        "/>" . $post_white;
2248         } else {
2249                 return "";
2250         }
2251 }
2252
2253 sub format_search_author {
2254         my ($author, $searchtype, $displaytext) = @_;
2255         my $have_search = gitweb_check_feature('search');
2256
2257         if ($have_search) {
2258                 my $performed = "";
2259                 if ($searchtype eq 'author') {
2260                         $performed = "authored";
2261                 } elsif ($searchtype eq 'committer') {
2262                         $performed = "committed";
2263                 }
2264
2265                 return $cgi->a({-href => href(action=>"search", hash=>$hash,
2266                                 searchtext=>$author,
2267                                 searchtype=>$searchtype), class=>"list",
2268                                 title=>"Search for commits $performed by $author"},
2269                                 $displaytext);
2270
2271         } else {
2272                 return $displaytext;
2273         }
2274 }
2275
2276 # format the author name of the given commit with the given tag
2277 # the author name is chopped and escaped according to the other
2278 # optional parameters (see chop_str).
2279 sub format_author_html {
2280         my $tag = shift;
2281         my $co = shift;
2282         my $author = chop_and_escape_str($co->{'author_name'}, @_);
2283         return "<$tag class=\"author\">" .
2284                format_search_author($co->{'author_name'}, "author",
2285                        git_get_avatar($co->{'author_email'}, -pad_after => 1) .
2286                        $author) .
2287                "</$tag>";
2288 }
2289
2290 # format git diff header line, i.e. "diff --(git|combined|cc) ..."
2291 sub format_git_diff_header_line {
2292         my $line = shift;
2293         my $diffinfo = shift;
2294         my ($from, $to) = @_;
2295
2296         if ($diffinfo->{'nparents'}) {
2297                 # combined diff
2298                 $line =~ s!^(diff (.*?) )"?.*$!$1!;
2299                 if ($to->{'href'}) {
2300                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2301                                          esc_path($to->{'file'}));
2302                 } else { # file was deleted (no href)
2303                         $line .= esc_path($to->{'file'});
2304                 }
2305         } else {
2306                 # "ordinary" diff
2307                 $line =~ s!^(diff (.*?) )"?a/.*$!$1!;
2308                 if ($from->{'href'}) {
2309                         $line .= $cgi->a({-href => $from->{'href'}, -class => "path"},
2310                                          'a/' . esc_path($from->{'file'}));
2311                 } else { # file was added (no href)
2312                         $line .= 'a/' . esc_path($from->{'file'});
2313                 }
2314                 $line .= ' ';
2315                 if ($to->{'href'}) {
2316                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
2317                                          'b/' . esc_path($to->{'file'}));
2318                 } else { # file was deleted
2319                         $line .= 'b/' . esc_path($to->{'file'});
2320                 }
2321         }
2322
2323         return "<div class=\"diff header\">$line</div>\n";
2324 }
2325
2326 # format extended diff header line, before patch itself
2327 sub format_extended_diff_header_line {
2328         my $line = shift;
2329         my $diffinfo = shift;
2330         my ($from, $to) = @_;
2331
2332         # match <path>
2333         if ($line =~ s!^((copy|rename) from ).*$!$1! && $from->{'href'}) {
2334                 $line .= $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2335                                        esc_path($from->{'file'}));
2336         }
2337         if ($line =~ s!^((copy|rename) to ).*$!$1! && $to->{'href'}) {
2338                 $line .= $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2339                                  esc_path($to->{'file'}));
2340         }
2341         # match single <mode>
2342         if ($line =~ m/\s(\d{6})$/) {
2343                 $line .= '<span class="info"> (' .
2344                          file_type_long($1) .
2345                          ')</span>';
2346         }
2347         # match <hash>
2348         if ($line =~ oid_nlen_prefix_infix_regex($sha1_len, "index ", ",") |
2349             $line =~ oid_nlen_prefix_infix_regex($sha256_len, "index ", ",")) {
2350                 # can match only for combined diff
2351                 $line = 'index ';
2352                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2353                         if ($from->{'href'}[$i]) {
2354                                 $line .= $cgi->a({-href=>$from->{'href'}[$i],
2355                                                   -class=>"hash"},
2356                                                  substr($diffinfo->{'from_id'}[$i],0,7));
2357                         } else {
2358                                 $line .= '0' x 7;
2359                         }
2360                         # separator
2361                         $line .= ',' if ($i < $diffinfo->{'nparents'} - 1);
2362                 }
2363                 $line .= '..';
2364                 if ($to->{'href'}) {
2365                         $line .= $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2366                                          substr($diffinfo->{'to_id'},0,7));
2367                 } else {
2368                         $line .= '0' x 7;
2369                 }
2370
2371         } elsif ($line =~ oid_nlen_prefix_infix_regex($sha1_len, "index ", "..") |
2372                  $line =~ oid_nlen_prefix_infix_regex($sha256_len, "index ", "..")) {
2373                 # can match only for ordinary diff
2374                 my ($from_link, $to_link);
2375                 if ($from->{'href'}) {
2376                         $from_link = $cgi->a({-href=>$from->{'href'}, -class=>"hash"},
2377                                              substr($diffinfo->{'from_id'},0,7));
2378                 } else {
2379                         $from_link = '0' x 7;
2380                 }
2381                 if ($to->{'href'}) {
2382                         $to_link = $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
2383                                            substr($diffinfo->{'to_id'},0,7));
2384                 } else {
2385                         $to_link = '0' x 7;
2386                 }
2387                 my ($from_id, $to_id) = ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
2388                 $line =~ s!$from_id\.\.$to_id!$from_link..$to_link!;
2389         }
2390
2391         return $line . "<br/>\n";
2392 }
2393
2394 # format from-file/to-file diff header
2395 sub format_diff_from_to_header {
2396         my ($from_line, $to_line, $diffinfo, $from, $to, @parents) = @_;
2397         my $line;
2398         my $result = '';
2399
2400         $line = $from_line;
2401         #assert($line =~ m/^---/) if DEBUG;
2402         # no extra formatting for "^--- /dev/null"
2403         if (! $diffinfo->{'nparents'}) {
2404                 # ordinary (single parent) diff
2405                 if ($line =~ m!^--- "?a/!) {
2406                         if ($from->{'href'}) {
2407                                 $line = '--- a/' .
2408                                         $cgi->a({-href=>$from->{'href'}, -class=>"path"},
2409                                                 esc_path($from->{'file'}));
2410                         } else {
2411                                 $line = '--- a/' .
2412                                         esc_path($from->{'file'});
2413                         }
2414                 }
2415                 $result .= qq!<div class="diff from_file">$line</div>\n!;
2416
2417         } else {
2418                 # combined diff (merge commit)
2419                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2420                         if ($from->{'href'}[$i]) {
2421                                 $line = '--- ' .
2422                                         $cgi->a({-href=>href(action=>"blobdiff",
2423                                                              hash_parent=>$diffinfo->{'from_id'}[$i],
2424                                                              hash_parent_base=>$parents[$i],
2425                                                              file_parent=>$from->{'file'}[$i],
2426                                                              hash=>$diffinfo->{'to_id'},
2427                                                              hash_base=>$hash,
2428                                                              file_name=>$to->{'file'}),
2429                                                  -class=>"path",
2430                                                  -title=>"diff" . ($i+1)},
2431                                                 $i+1) .
2432                                         '/' .
2433                                         $cgi->a({-href=>$from->{'href'}[$i], -class=>"path"},
2434                                                 esc_path($from->{'file'}[$i]));
2435                         } else {
2436                                 $line = '--- /dev/null';
2437                         }
2438                         $result .= qq!<div class="diff from_file">$line</div>\n!;
2439                 }
2440         }
2441
2442         $line = $to_line;
2443         #assert($line =~ m/^\+\+\+/) if DEBUG;
2444         # no extra formatting for "^+++ /dev/null"
2445         if ($line =~ m!^\+\+\+ "?b/!) {
2446                 if ($to->{'href'}) {
2447                         $line = '+++ b/' .
2448                                 $cgi->a({-href=>$to->{'href'}, -class=>"path"},
2449                                         esc_path($to->{'file'}));
2450                 } else {
2451                         $line = '+++ b/' .
2452                                 esc_path($to->{'file'});
2453                 }
2454         }
2455         $result .= qq!<div class="diff to_file">$line</div>\n!;
2456
2457         return $result;
2458 }
2459
2460 # create note for patch simplified by combined diff
2461 sub format_diff_cc_simplified {
2462         my ($diffinfo, @parents) = @_;
2463         my $result = '';
2464
2465         $result .= "<div class=\"diff header\">" .
2466                    "diff --cc ";
2467         if (!is_deleted($diffinfo)) {
2468                 $result .= $cgi->a({-href => href(action=>"blob",
2469                                                   hash_base=>$hash,
2470                                                   hash=>$diffinfo->{'to_id'},
2471                                                   file_name=>$diffinfo->{'to_file'}),
2472                                     -class => "path"},
2473                                    esc_path($diffinfo->{'to_file'}));
2474         } else {
2475                 $result .= esc_path($diffinfo->{'to_file'});
2476         }
2477         $result .= "</div>\n" . # class="diff header"
2478                    "<div class=\"diff nodifferences\">" .
2479                    "Simple merge" .
2480                    "</div>\n"; # class="diff nodifferences"
2481
2482         return $result;
2483 }
2484
2485 sub diff_line_class {
2486         my ($line, $from, $to) = @_;
2487
2488         # ordinary diff
2489         my $num_sign = 1;
2490         # combined diff
2491         if ($from && $to && ref($from->{'href'}) eq "ARRAY") {
2492                 $num_sign = scalar @{$from->{'href'}};
2493         }
2494
2495         my @diff_line_classifier = (
2496                 { regexp => qr/^\@\@{$num_sign} /, class => "chunk_header"},
2497                 { regexp => qr/^\\/,               class => "incomplete"  },
2498                 { regexp => qr/^ {$num_sign}/,     class => "ctx" },
2499                 # classifier for context must come before classifier add/rem,
2500                 # or we would have to use more complicated regexp, for example
2501                 # qr/(?= {0,$m}\+)[+ ]{$num_sign}/, where $m = $num_sign - 1;
2502                 { regexp => qr/^[+ ]{$num_sign}/,   class => "add" },
2503                 { regexp => qr/^[- ]{$num_sign}/,   class => "rem" },
2504         );
2505         for my $clsfy (@diff_line_classifier) {
2506                 return $clsfy->{'class'}
2507                         if ($line =~ $clsfy->{'regexp'});
2508         }
2509
2510         # fallback
2511         return "";
2512 }
2513
2514 # assumes that $from and $to are defined and correctly filled,
2515 # and that $line holds a line of chunk header for unified diff
2516 sub format_unidiff_chunk_header {
2517         my ($line, $from, $to) = @_;
2518
2519         my ($from_text, $from_start, $from_lines, $to_text, $to_start, $to_lines, $section) =
2520                 $line =~ m/^\@{2} (-(\d+)(?:,(\d+))?) (\+(\d+)(?:,(\d+))?) \@{2}(.*)$/;
2521
2522         $from_lines = 0 unless defined $from_lines;
2523         $to_lines   = 0 unless defined $to_lines;
2524
2525         if ($from->{'href'}) {
2526                 $from_text = $cgi->a({-href=>"$from->{'href'}#l$from_start",
2527                                      -class=>"list"}, $from_text);
2528         }
2529         if ($to->{'href'}) {
2530                 $to_text   = $cgi->a({-href=>"$to->{'href'}#l$to_start",
2531                                      -class=>"list"}, $to_text);
2532         }
2533         $line = "<span class=\"chunk_info\">@@ $from_text $to_text @@</span>" .
2534                 "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2535         return $line;
2536 }
2537
2538 # assumes that $from and $to are defined and correctly filled,
2539 # and that $line holds a line of chunk header for combined diff
2540 sub format_cc_diff_chunk_header {
2541         my ($line, $from, $to) = @_;
2542
2543         my ($prefix, $ranges, $section) = $line =~ m/^(\@+) (.*?) \@+(.*)$/;
2544         my (@from_text, @from_start, @from_nlines, $to_text, $to_start, $to_nlines);
2545
2546         @from_text = split(' ', $ranges);
2547         for (my $i = 0; $i < @from_text; ++$i) {
2548                 ($from_start[$i], $from_nlines[$i]) =
2549                         (split(',', substr($from_text[$i], 1)), 0);
2550         }
2551
2552         $to_text   = pop @from_text;
2553         $to_start  = pop @from_start;
2554         $to_nlines = pop @from_nlines;
2555
2556         $line = "<span class=\"chunk_info\">$prefix ";
2557         for (my $i = 0; $i < @from_text; ++$i) {
2558                 if ($from->{'href'}[$i]) {
2559                         $line .= $cgi->a({-href=>"$from->{'href'}[$i]#l$from_start[$i]",
2560                                           -class=>"list"}, $from_text[$i]);
2561                 } else {
2562                         $line .= $from_text[$i];
2563                 }
2564                 $line .= " ";
2565         }
2566         if ($to->{'href'}) {
2567                 $line .= $cgi->a({-href=>"$to->{'href'}#l$to_start",
2568                                   -class=>"list"}, $to_text);
2569         } else {
2570                 $line .= $to_text;
2571         }
2572         $line .= " $prefix</span>" .
2573                  "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2574         return $line;
2575 }
2576
2577 # process patch (diff) line (not to be used for diff headers),
2578 # returning HTML-formatted (but not wrapped) line.
2579 # If the line is passed as a reference, it is treated as HTML and not
2580 # esc_html()'ed.
2581 sub format_diff_line {
2582         my ($line, $diff_class, $from, $to) = @_;
2583
2584         if (ref($line)) {
2585                 $line = $$line;
2586         } else {
2587                 chomp $line;
2588                 $line = untabify($line);
2589
2590                 if ($from && $to && $line =~ m/^\@{2} /) {
2591                         $line = format_unidiff_chunk_header($line, $from, $to);
2592                 } elsif ($from && $to && $line =~ m/^\@{3}/) {
2593                         $line = format_cc_diff_chunk_header($line, $from, $to);
2594                 } else {
2595                         $line = esc_html($line, -nbsp=>1);
2596                 }
2597         }
2598
2599         my $diff_classes = "diff";
2600         $diff_classes .= " $diff_class" if ($diff_class);
2601         $line = "<div class=\"$diff_classes\">$line</div>\n";
2602
2603         return $line;
2604 }
2605
2606 # Generates undef or something like "_snapshot_" or "snapshot (_tbz2_ _zip_)",
2607 # linked.  Pass the hash of the tree/commit to snapshot.
2608 sub format_snapshot_links {
2609         my ($hash) = @_;
2610         my $num_fmts = @snapshot_fmts;
2611         if ($num_fmts > 1) {
2612                 # A parenthesized list of links bearing format names.
2613                 # e.g. "snapshot (_tar.gz_ _zip_)"
2614                 return "snapshot (" . join(' ', map
2615                         $cgi->a({
2616                                 -href => href(
2617                                         action=>"snapshot",
2618                                         hash=>$hash,
2619                                         snapshot_format=>$_
2620                                 )
2621                         }, $known_snapshot_formats{$_}{'display'})
2622                 , @snapshot_fmts) . ")";
2623         } elsif ($num_fmts == 1) {
2624                 # A single "snapshot" link whose tooltip bears the format name.
2625                 # i.e. "_snapshot_"
2626                 my ($fmt) = @snapshot_fmts;
2627                 return
2628                         $cgi->a({
2629                                 -href => href(
2630                                         action=>"snapshot",
2631                                         hash=>$hash,
2632                                         snapshot_format=>$fmt
2633                                 ),
2634                                 -title => "in format: $known_snapshot_formats{$fmt}{'display'}"
2635                         }, "snapshot");
2636         } else { # $num_fmts == 0
2637                 return undef;
2638         }
2639 }
2640
2641 ## ......................................................................
2642 ## functions returning values to be passed, perhaps after some
2643 ## transformation, to other functions; e.g. returning arguments to href()
2644
2645 # returns hash to be passed to href to generate gitweb URL
2646 # in -title key it returns description of link
2647 sub get_feed_info {
2648         my $format = shift || 'Atom';
2649         my %res = (action => lc($format));
2650         my $matched_ref = 0;
2651
2652         # feed links are possible only for project views
2653         return unless (defined $project);
2654         # some views should link to OPML, or to generic project feed,
2655         # or don't have specific feed yet (so they should use generic)
2656         return if (!$action || $action =~ /^(?:tags|heads|forks|tag|search)$/x);
2657
2658         my $branch = undef;
2659         # branches refs uses 'refs/' + $get_branch_refs()[x] + '/' prefix
2660         # (fullname) to differentiate from tag links; this also makes
2661         # possible to detect branch links
2662         for my $ref (get_branch_refs()) {
2663                 if ((defined $hash_base && $hash_base =~ m!^refs/\Q$ref\E/(.*)$!) ||
2664                     (defined $hash      && $hash      =~ m!^refs/\Q$ref\E/(.*)$!)) {
2665                         $branch = $1;
2666                         $matched_ref = $ref;
2667                         last;
2668                 }
2669         }
2670         # find log type for feed description (title)
2671         my $type = 'log';
2672         if (defined $file_name) {
2673                 $type  = "history of $file_name";
2674                 $type .= "/" if ($action eq 'tree');
2675                 $type .= " on '$branch'" if (defined $branch);
2676         } else {
2677                 $type = "log of $branch" if (defined $branch);
2678         }
2679
2680         $res{-title} = $type;
2681         $res{'hash'} = (defined $branch ? "refs/$matched_ref/$branch" : undef);
2682         $res{'file_name'} = $file_name;
2683
2684         return %res;
2685 }
2686
2687 ## ----------------------------------------------------------------------
2688 ## git utility subroutines, invoking git commands
2689
2690 # returns path to the core git executable and the --git-dir parameter as list
2691 sub git_cmd {
2692         $number_of_git_cmds++;
2693         return $GIT, '--git-dir='.$git_dir;
2694 }
2695
2696 # quote the given arguments for passing them to the shell
2697 # quote_command("command", "arg 1", "arg with ' and ! characters")
2698 # => "'command' 'arg 1' 'arg with '\'' and '\!' characters'"
2699 # Try to avoid using this function wherever possible.
2700 sub quote_command {
2701         return join(' ',
2702                 map { my $a = $_; $a =~ s/(['!])/'\\$1'/g; "'$a'" } @_ );
2703 }
2704
2705 # get HEAD ref of given project as hash
2706 sub git_get_head_hash {
2707         return git_get_full_hash(shift, 'HEAD');
2708 }
2709
2710 sub git_get_full_hash {
2711         return git_get_hash(@_);
2712 }
2713
2714 sub git_get_short_hash {
2715         return git_get_hash(@_, '--short=7');
2716 }
2717
2718 sub git_get_hash {
2719         my ($project, $hash, @options) = @_;
2720         my $o_git_dir = $git_dir;
2721         my $retval = undef;
2722         $git_dir = "$projectroot/$project";
2723         if (open my $fd, '-|', git_cmd(), 'rev-parse',
2724             '--verify', '-q', @options, $hash) {
2725                 $retval = <$fd>;
2726                 chomp $retval if defined $retval;
2727                 close $fd;
2728         }
2729         if (defined $o_git_dir) {
2730                 $git_dir = $o_git_dir;
2731         }
2732         return $retval;
2733 }
2734
2735 # get type of given object
2736 sub git_get_type {
2737         my $hash = shift;
2738
2739         open my $fd, "-|", git_cmd(), "cat-file", '-t', $hash or return;
2740         my $type = <$fd>;
2741         close $fd or return;
2742         chomp $type;
2743         return $type;
2744 }
2745
2746 # repository configuration
2747 our $config_file = '';
2748 our %config;
2749
2750 # store multiple values for single key as anonymous array reference
2751 # single values stored directly in the hash, not as [ <value> ]
2752 sub hash_set_multi {
2753         my ($hash, $key, $value) = @_;
2754
2755         if (!exists $hash->{$key}) {
2756                 $hash->{$key} = $value;
2757         } elsif (!ref $hash->{$key}) {
2758                 $hash->{$key} = [ $hash->{$key}, $value ];
2759         } else {
2760                 push @{$hash->{$key}}, $value;
2761         }
2762 }
2763
2764 # return hash of git project configuration
2765 # optionally limited to some section, e.g. 'gitweb'
2766 sub git_parse_project_config {
2767         my $section_regexp = shift;
2768         my %config;
2769
2770         local $/ = "\0";
2771
2772         open my $fh, "-|", git_cmd(), "config", '-z', '-l',
2773                 or return;
2774
2775         while (my $keyval = <$fh>) {
2776                 chomp $keyval;
2777                 my ($key, $value) = split(/\n/, $keyval, 2);
2778
2779                 hash_set_multi(\%config, $key, $value)
2780                         if (!defined $section_regexp || $key =~ /^(?:$section_regexp)\./o);
2781         }
2782         close $fh;
2783
2784         return %config;
2785 }
2786
2787 # convert config value to boolean: 'true' or 'false'
2788 # no value, number > 0, 'true' and 'yes' values are true
2789 # rest of values are treated as false (never as error)
2790 sub config_to_bool {
2791         my $val = shift;
2792
2793         return 1 if !defined $val;             # section.key
2794
2795         # strip leading and trailing whitespace
2796         $val =~ s/^\s+//;
2797         $val =~ s/\s+$//;
2798
2799         return (($val =~ /^\d+$/ && $val) ||   # section.key = 1
2800                 ($val =~ /^(?:true|yes)$/i));  # section.key = true
2801 }
2802
2803 # convert config value to simple decimal number
2804 # an optional value suffix of 'k', 'm', or 'g' will cause the value
2805 # to be multiplied by 1024, 1048576, or 1073741824
2806 sub config_to_int {
2807         my $val = shift;
2808
2809         # strip leading and trailing whitespace
2810         $val =~ s/^\s+//;
2811         $val =~ s/\s+$//;
2812
2813         if (my ($num, $unit) = ($val =~ /^([0-9]*)([kmg])$/i)) {
2814                 $unit = lc($unit);
2815                 # unknown unit is treated as 1
2816                 return $num * ($unit eq 'g' ? 1073741824 :
2817                                $unit eq 'm' ?    1048576 :
2818                                $unit eq 'k' ?       1024 : 1);
2819         }
2820         return $val;
2821 }
2822
2823 # convert config value to array reference, if needed
2824 sub config_to_multi {
2825         my $val = shift;
2826
2827         return ref($val) ? $val : (defined($val) ? [ $val ] : []);
2828 }
2829
2830 sub git_get_project_config {
2831         my ($key, $type) = @_;
2832
2833         return unless defined $git_dir;
2834
2835         # key sanity check
2836         return unless ($key);
2837         # only subsection, if exists, is case sensitive,
2838         # and not lowercased by 'git config -z -l'
2839         if (my ($hi, $mi, $lo) = ($key =~ /^([^.]*)\.(.*)\.([^.]*)$/)) {
2840                 $lo =~ s/_//g;
2841                 $key = join(".", lc($hi), $mi, lc($lo));
2842                 return if ($lo =~ /\W/ || $hi =~ /\W/);
2843         } else {
2844                 $key = lc($key);
2845                 $key =~ s/_//g;
2846                 return if ($key =~ /\W/);
2847         }
2848         $key =~ s/^gitweb\.//;
2849
2850         # type sanity check
2851         if (defined $type) {
2852                 $type =~ s/^--//;
2853                 $type = undef
2854                         unless ($type eq 'bool' || $type eq 'int');
2855         }
2856
2857         # get config
2858         if (!defined $config_file ||
2859             $config_file ne "$git_dir/config") {
2860                 %config = git_parse_project_config('gitweb');
2861                 $config_file = "$git_dir/config";
2862         }
2863
2864         # check if config variable (key) exists
2865         return unless exists $config{"gitweb.$key"};
2866
2867         # ensure given type
2868         if (!defined $type) {
2869                 return $config{"gitweb.$key"};
2870         } elsif ($type eq 'bool') {
2871                 # backward compatibility: 'git config --bool' returns true/false
2872                 return config_to_bool($config{"gitweb.$key"}) ? 'true' : 'false';
2873         } elsif ($type eq 'int') {
2874                 return config_to_int($config{"gitweb.$key"});
2875         }
2876         return $config{"gitweb.$key"};
2877 }
2878
2879 # get hash of given path at given ref
2880 sub git_get_hash_by_path {
2881         my $base = shift;
2882         my $path = shift || return undef;
2883         my $type = shift;
2884
2885         $path =~ s,/+$,,;
2886
2887         open my $fd, "-|", git_cmd(), "ls-tree", $base, "--", $path
2888                 or die_error(500, "Open git-ls-tree failed");
2889         my $line = <$fd>;
2890         close $fd or return undef;
2891
2892         if (!defined $line) {
2893                 # there is no tree or hash given by $path at $base
2894                 return undef;
2895         }
2896
2897         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
2898         $line =~ m/^([0-9]+) (.+) ($oid_regex)\t/;
2899         if (defined $type && $type ne $2) {
2900                 # type doesn't match
2901                 return undef;
2902         }
2903         return $3;
2904 }
2905
2906 # get path of entry with given hash at given tree-ish (ref)
2907 # used to get 'from' filename for combined diff (merge commit) for renames
2908 sub git_get_path_by_hash {
2909         my $base = shift || return;
2910         my $hash = shift || return;
2911
2912         local $/ = "\0";
2913
2914         open my $fd, "-|", git_cmd(), "ls-tree", '-r', '-t', '-z', $base
2915                 or return undef;
2916         while (my $line = <$fd>) {
2917                 chomp $line;
2918
2919                 #'040000 tree 595596a6a9117ddba9fe379b6b012b558bac8423  gitweb'
2920                 #'100644 blob e02e90f0429be0d2a69b76571101f20b8f75530f  gitweb/README'
2921                 if ($line =~ m/(?:[0-9]+) (?:.+) $hash\t(.+)$/) {
2922                         close $fd;
2923                         return $1;
2924                 }
2925         }
2926         close $fd;
2927         return undef;
2928 }
2929
2930 ## ......................................................................
2931 ## git utility functions, directly accessing git repository
2932
2933 # get the value of config variable either from file named as the variable
2934 # itself in the repository ($GIT_DIR/$name file), or from gitweb.$name
2935 # configuration variable in the repository config file.
2936 sub git_get_file_or_project_config {
2937         my ($path, $name) = @_;
2938
2939         $git_dir = "$projectroot/$path";
2940         open my $fd, '<', "$git_dir/$name"
2941                 or return git_get_project_config($name);
2942         my $conf = <$fd>;
2943         close $fd;
2944         if (defined $conf) {
2945                 chomp $conf;
2946         }
2947         return $conf;
2948 }
2949
2950 sub git_get_project_description {
2951         my $path = shift;
2952         return git_get_file_or_project_config($path, 'description');
2953 }
2954
2955 sub git_get_project_category {
2956         my $path = shift;
2957         return git_get_file_or_project_config($path, 'category');
2958 }
2959
2960
2961 # supported formats:
2962 # * $GIT_DIR/ctags/<tagname> file (in 'ctags' subdirectory)
2963 #   - if its contents is a number, use it as tag weight,
2964 #   - otherwise add a tag with weight 1
2965 # * $GIT_DIR/ctags file, each line is a tag (with weight 1)
2966 #   the same value multiple times increases tag weight
2967 # * `gitweb.ctag' multi-valued repo config variable
2968 sub git_get_project_ctags {
2969         my $project = shift;
2970         my $ctags = {};
2971
2972         $git_dir = "$projectroot/$project";
2973         if (opendir my $dh, "$git_dir/ctags") {
2974                 my @files = grep { -f $_ } map { "$git_dir/ctags/$_" } readdir($dh);
2975                 foreach my $tagfile (@files) {
2976                         open my $ct, '<', $tagfile
2977                                 or next;
2978                         my $val = <$ct>;
2979                         chomp $val if $val;
2980                         close $ct;
2981
2982                         (my $ctag = $tagfile) =~ s#.*/##;
2983                         if ($val =~ /^\d+$/) {
2984                                 $ctags->{$ctag} = $val;
2985                         } else {
2986                                 $ctags->{$ctag} = 1;
2987                         }
2988                 }
2989                 closedir $dh;
2990
2991         } elsif (open my $fh, '<', "$git_dir/ctags") {
2992                 while (my $line = <$fh>) {
2993                         chomp $line;
2994                         $ctags->{$line}++ if $line;
2995                 }
2996                 close $fh;
2997
2998         } else {
2999                 my $taglist = config_to_multi(git_get_project_config('ctag'));
3000                 foreach my $tag (@$taglist) {
3001                         $ctags->{$tag}++;
3002                 }
3003         }
3004
3005         return $ctags;
3006 }
3007
3008 # return hash, where keys are content tags ('ctags'),
3009 # and values are sum of weights of given tag in every project
3010 sub git_gather_all_ctags {
3011         my $projects = shift;
3012         my $ctags = {};
3013
3014         foreach my $p (@$projects) {
3015                 foreach my $ct (keys %{$p->{'ctags'}}) {
3016                         $ctags->{$ct} += $p->{'ctags'}->{$ct};
3017                 }
3018         }
3019
3020         return $ctags;
3021 }
3022
3023 sub git_populate_project_tagcloud {
3024         my $ctags = shift;
3025
3026         # First, merge different-cased tags; tags vote on casing
3027         my %ctags_lc;
3028         foreach (keys %$ctags) {
3029                 $ctags_lc{lc $_}->{count} += $ctags->{$_};
3030                 if (not $ctags_lc{lc $_}->{topcount}
3031                     or $ctags_lc{lc $_}->{topcount} < $ctags->{$_}) {
3032                         $ctags_lc{lc $_}->{topcount} = $ctags->{$_};
3033                         $ctags_lc{lc $_}->{topname} = $_;
3034                 }
3035         }
3036
3037         my $cloud;
3038         my $matched = $input_params{'ctag'};
3039         if (eval { require HTML::TagCloud; 1; }) {
3040                 $cloud = HTML::TagCloud->new;
3041                 foreach my $ctag (sort keys %ctags_lc) {
3042                         # Pad the title with spaces so that the cloud looks
3043                         # less crammed.
3044                         my $title = esc_html($ctags_lc{$ctag}->{topname});
3045                         $title =~ s/ /&nbsp;/g;
3046                         $title =~ s/^/&nbsp;/g;
3047                         $title =~ s/$/&nbsp;/g;
3048                         if (defined $matched && $matched eq $ctag) {
3049                                 $title = qq(<span class="match">$title</span>);
3050                         }
3051                         $cloud->add($title, href(project=>undef, ctag=>$ctag),
3052                                     $ctags_lc{$ctag}->{count});
3053                 }
3054         } else {
3055                 $cloud = {};
3056                 foreach my $ctag (keys %ctags_lc) {
3057                         my $title = esc_html($ctags_lc{$ctag}->{topname}, -nbsp=>1);
3058                         if (defined $matched && $matched eq $ctag) {
3059                                 $title = qq(<span class="match">$title</span>);
3060                         }
3061                         $cloud->{$ctag}{count} = $ctags_lc{$ctag}->{count};
3062                         $cloud->{$ctag}{ctag} =
3063                                 $cgi->a({-href=>href(project=>undef, ctag=>$ctag)}, $title);
3064                 }
3065         }
3066         return $cloud;
3067 }
3068
3069 sub git_show_project_tagcloud {
3070         my ($cloud, $count) = @_;
3071         if (ref $cloud eq 'HTML::TagCloud') {
3072                 return $cloud->html_and_css($count);
3073         } else {
3074                 my @tags = sort { $cloud->{$a}->{'count'} <=> $cloud->{$b}->{'count'} } keys %$cloud;
3075                 return
3076                         '<div id="htmltagcloud"'.($project ? '' : ' align="center"').'>' .
3077                         join (', ', map {
3078                                 $cloud->{$_}->{'ctag'}
3079                         } splice(@tags, 0, $count)) .
3080                         '</div>';
3081         }
3082 }
3083
3084 sub git_get_project_url_list {
3085         my $path = shift;
3086
3087         $git_dir = "$projectroot/$path";
3088         open my $fd, '<', "$git_dir/cloneurl"
3089                 or return wantarray ?
3090                 @{ config_to_multi(git_get_project_config('url')) } :
3091                    config_to_multi(git_get_project_config('url'));
3092         my @git_project_url_list = map { chomp; $_ } <$fd>;
3093         close $fd;
3094
3095         return wantarray ? @git_project_url_list : \@git_project_url_list;
3096 }
3097
3098 sub git_get_projects_list {
3099         my $filter = shift || '';
3100         my $paranoid = shift;
3101         my @list;
3102
3103         if (-d $projects_list) {
3104                 # search in directory
3105                 my $dir = $projects_list;
3106                 # remove the trailing "/"
3107                 $dir =~ s!/+$!!;
3108                 my $pfxlen = length("$dir");
3109                 my $pfxdepth = ($dir =~ tr!/!!);
3110                 # when filtering, search only given subdirectory
3111                 if ($filter && !$paranoid) {
3112                         $dir .= "/$filter";
3113                         $dir =~ s!/+$!!;
3114                 }
3115
3116                 File::Find::find({
3117                         follow_fast => 1, # follow symbolic links
3118                         follow_skip => 2, # ignore duplicates
3119                         dangling_symlinks => 0, # ignore dangling symlinks, silently
3120                         wanted => sub {
3121                                 # global variables
3122                                 our $project_maxdepth;
3123                                 our $projectroot;
3124                                 # skip project-list toplevel, if we get it.
3125                                 return if (m!^[/.]$!);
3126                                 # only directories can be git repositories
3127                                 return unless (-d $_);
3128                                 # need search permission
3129                                 return unless (-x $_);
3130                                 # don't traverse too deep (Find is super slow on os x)
3131                                 # $project_maxdepth excludes depth of $projectroot
3132                                 if (($File::Find::name =~ tr!/!!) - $pfxdepth > $project_maxdepth) {
3133                                         $File::Find::prune = 1;
3134                                         return;
3135                                 }
3136
3137                                 my $path = substr($File::Find::name, $pfxlen + 1);
3138                                 # paranoidly only filter here
3139                                 if ($paranoid && $filter && $path !~ m!^\Q$filter\E/!) {
3140                                         next;
3141                                 }
3142                                 # we check related file in $projectroot
3143                                 if (check_export_ok("$projectroot/$path")) {
3144                                         push @list, { path => $path };
3145                                         $File::Find::prune = 1;
3146                                 }
3147                         },
3148                 }, "$dir");
3149
3150         } elsif (-f $projects_list) {
3151                 # read from file(url-encoded):
3152                 # 'git%2Fgit.git Linus+Torvalds'
3153                 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
3154                 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
3155                 open my $fd, '<', $projects_list or return;
3156         PROJECT:
3157                 while (my $line = <$fd>) {
3158                         chomp $line;
3159                         my ($path, $owner) = split ' ', $line;
3160                         $path = unescape($path);
3161                         $owner = unescape($owner);
3162                         if (!defined $path) {
3163                                 next;
3164                         }
3165                         # if $filter is rpovided, check if $path begins with $filter
3166                         if ($filter && $path !~ m!^\Q$filter\E/!) {
3167                                 next;
3168                         }
3169                         if (check_export_ok("$projectroot/$path")) {
3170                                 my $pr = {
3171                                         path => $path
3172                                 };
3173                                 if ($owner) {
3174                                         $pr->{'owner'} = to_utf8($owner);
3175                                 }
3176                                 push @list, $pr;
3177                         }
3178                 }
3179                 close $fd;
3180         }
3181         return @list;
3182 }
3183
3184 # written with help of Tree::Trie module (Perl Artistic License, GPL compatible)
3185 # as side effects it sets 'forks' field to list of forks for forked projects
3186 sub filter_forks_from_projects_list {
3187         my $projects = shift;
3188
3189         my %trie; # prefix tree of directories (path components)
3190         # generate trie out of those directories that might contain forks
3191         foreach my $pr (@$projects) {
3192                 my $path = $pr->{'path'};
3193                 $path =~ s/\.git$//;      # forks of 'repo.git' are in 'repo/' directory
3194                 next if ($path =~ m!/$!); # skip non-bare repositories, e.g. 'repo/.git'
3195                 next unless ($path);      # skip '.git' repository: tests, git-instaweb
3196                 next unless (-d "$projectroot/$path"); # containing directory exists
3197                 $pr->{'forks'} = [];      # there can be 0 or more forks of project
3198
3199                 # add to trie
3200                 my @dirs = split('/', $path);
3201                 # walk the trie, until either runs out of components or out of trie
3202                 my $ref = \%trie;
3203                 while (scalar @dirs &&
3204                        exists($ref->{$dirs[0]})) {
3205                         $ref = $ref->{shift @dirs};
3206                 }
3207                 # create rest of trie structure from rest of components
3208                 foreach my $dir (@dirs) {
3209                         $ref = $ref->{$dir} = {};
3210                 }
3211                 # create end marker, store $pr as a data
3212                 $ref->{''} = $pr if (!exists $ref->{''});
3213         }
3214
3215         # filter out forks, by finding shortest prefix match for paths
3216         my @filtered;
3217  PROJECT:
3218         foreach my $pr (@$projects) {
3219                 # trie lookup
3220                 my $ref = \%trie;
3221         DIR:
3222                 foreach my $dir (split('/', $pr->{'path'})) {
3223                         if (exists $ref->{''}) {
3224                                 # found [shortest] prefix, is a fork - skip it
3225                                 push @{$ref->{''}{'forks'}}, $pr;
3226                                 next PROJECT;
3227                         }
3228                         if (!exists $ref->{$dir}) {
3229                                 # not in trie, cannot have prefix, not a fork
3230                                 push @filtered, $pr;
3231                                 next PROJECT;
3232                         }
3233                         # If the dir is there, we just walk one step down the trie.
3234                         $ref = $ref->{$dir};
3235                 }
3236                 # we ran out of trie
3237                 # (shouldn't happen: it's either no match, or end marker)
3238                 push @filtered, $pr;
3239         }
3240
3241         return @filtered;
3242 }
3243
3244 # note: fill_project_list_info must be run first,
3245 # for 'descr_long' and 'ctags' to be filled
3246 sub search_projects_list {
3247         my ($projlist, %opts) = @_;
3248         my $tagfilter  = $opts{'tagfilter'};
3249         my $search_re = $opts{'search_regexp'};
3250
3251         return @$projlist
3252                 unless ($tagfilter || $search_re);
3253
3254         # searching projects require filling to be run before it;
3255         fill_project_list_info($projlist,
3256                                $tagfilter  ? 'ctags' : (),
3257                                $search_re ? ('path', 'descr') : ());
3258         my @projects;
3259  PROJECT:
3260         foreach my $pr (@$projlist) {
3261
3262                 if ($tagfilter) {
3263                         next unless ref($pr->{'ctags'}) eq 'HASH';
3264                         next unless
3265                                 grep { lc($_) eq lc($tagfilter) } keys %{$pr->{'ctags'}};
3266                 }
3267
3268                 if ($search_re) {
3269                         next unless
3270                                 $pr->{'path'} =~ /$search_re/ ||
3271                                 $pr->{'descr_long'} =~ /$search_re/;
3272                 }
3273
3274                 push @projects, $pr;
3275         }
3276
3277         return @projects;
3278 }
3279
3280 our $gitweb_project_owner = undef;
3281 sub git_get_project_list_from_file {
3282
3283         return if (defined $gitweb_project_owner);
3284
3285         $gitweb_project_owner = {};
3286         # read from file (url-encoded):
3287         # 'git%2Fgit.git Linus+Torvalds'
3288         # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
3289         # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
3290         if (-f $projects_list) {
3291                 open(my $fd, '<', $projects_list);
3292                 while (my $line = <$fd>) {
3293                         chomp $line;
3294                         my ($pr, $ow) = split ' ', $line;
3295                         $pr = unescape($pr);
3296                         $ow = unescape($ow);
3297                         $gitweb_project_owner->{$pr} = to_utf8($ow);
3298                 }
3299                 close $fd;
3300         }
3301 }
3302
3303 sub git_get_project_owner {
3304         my $project = shift;
3305         my $owner;
3306
3307         return undef unless $project;
3308         $git_dir = "$projectroot/$project";
3309
3310         if (!defined $gitweb_project_owner) {
3311                 git_get_project_list_from_file();
3312         }
3313
3314         if (exists $gitweb_project_owner->{$project}) {
3315                 $owner = $gitweb_project_owner->{$project};
3316         }
3317         if (!defined $owner){
3318                 $owner = git_get_project_config('owner');
3319         }
3320         if (!defined $owner) {
3321                 $owner = get_file_owner("$git_dir");
3322         }
3323
3324         return $owner;
3325 }
3326
3327 sub git_get_last_activity {
3328         my ($path) = @_;
3329         my $fd;
3330
3331         $git_dir = "$projectroot/$path";
3332         open($fd, "-|", git_cmd(), 'for-each-ref',
3333              '--format=%(committer)',
3334              '--sort=-committerdate',
3335              '--count=1',
3336              map { "refs/$_" } get_branch_refs ()) or return;
3337         my $most_recent = <$fd>;
3338         close $fd or return;
3339         if (defined $most_recent &&
3340             $most_recent =~ / (\d+) [-+][01]\d\d\d$/) {
3341                 my $timestamp = $1;
3342                 my $age = time - $timestamp;
3343                 return ($age, age_string($age));
3344         }
3345         return (undef, undef);
3346 }
3347
3348 # Implementation note: when a single remote is wanted, we cannot use 'git
3349 # remote show -n' because that command always work (assuming it's a remote URL
3350 # if it's not defined), and we cannot use 'git remote show' because that would
3351 # try to make a network roundtrip. So the only way to find if that particular
3352 # remote is defined is to walk the list provided by 'git remote -v' and stop if
3353 # and when we find what we want.
3354 sub git_get_remotes_list {
3355         my $wanted = shift;
3356         my %remotes = ();
3357
3358         open my $fd, '-|' , git_cmd(), 'remote', '-v';
3359         return unless $fd;
3360         while (my $remote = <$fd>) {
3361                 chomp $remote;
3362                 $remote =~ s!\t(.*?)\s+\((\w+)\)$!!;
3363                 next if $wanted and not $remote eq $wanted;
3364                 my ($url, $key) = ($1, $2);
3365
3366                 $remotes{$remote} ||= { 'heads' => () };
3367                 $remotes{$remote}{$key} = $url;
3368         }
3369         close $fd or return;
3370         return wantarray ? %remotes : \%remotes;
3371 }
3372
3373 # Takes a hash of remotes as first parameter and fills it by adding the
3374 # available remote heads for each of the indicated remotes.
3375 sub fill_remote_heads {
3376         my $remotes = shift;
3377         my @heads = map { "remotes/$_" } keys %$remotes;
3378         my @remoteheads = git_get_heads_list(undef, @heads);
3379         foreach my $remote (keys %$remotes) {
3380                 $remotes->{$remote}{'heads'} = [ grep {
3381                         $_->{'name'} =~ s!^$remote/!!
3382                         } @remoteheads ];
3383         }
3384 }
3385
3386 sub git_get_references {
3387         my $type = shift || "";
3388         my %refs;
3389         # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
3390         # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
3391         open my $fd, "-|", git_cmd(), "show-ref", "--dereference",
3392                 ($type ? ("--", "refs/$type") : ()) # use -- <pattern> if $type
3393                 or return;
3394
3395         while (my $line = <$fd>) {
3396                 chomp $line;
3397                 if ($line =~ m!^($oid_regex)\srefs/($type.*)$!) {
3398                         if (defined $refs{$1}) {
3399                                 push @{$refs{$1}}, $2;
3400                         } else {
3401                                 $refs{$1} = [ $2 ];
3402                         }
3403                 }
3404         }
3405         close $fd or return;
3406         return \%refs;
3407 }
3408
3409 sub git_get_rev_name_tags {
3410         my $hash = shift || return undef;
3411
3412         open my $fd, "-|", git_cmd(), "name-rev", "--tags", $hash
3413                 or return;
3414         my $name_rev = <$fd>;
3415         close $fd;
3416
3417         if ($name_rev =~ m|^$hash tags/(.*)$|) {
3418                 return $1;
3419         } else {
3420                 # catches also '$hash undefined' output
3421                 return undef;
3422         }
3423 }
3424
3425 ## ----------------------------------------------------------------------
3426 ## parse to hash functions
3427
3428 sub parse_date {
3429         my $epoch = shift;
3430         my $tz = shift || "-0000";
3431
3432         my %date;
3433         my @months = ("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec");
3434         my @days = ("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");
3435         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($epoch);
3436         $date{'hour'} = $hour;
3437         $date{'minute'} = $min;
3438         $date{'mday'} = $mday;
3439         $date{'day'} = $days[$wday];
3440         $date{'month'} = $months[$mon];
3441         $date{'rfc2822'}   = sprintf "%s, %d %s %4d %02d:%02d:%02d +0000",
3442                              $days[$wday], $mday, $months[$mon], 1900+$year, $hour ,$min, $sec;
3443         $date{'mday-time'} = sprintf "%d %s %02d:%02d",
3444                              $mday, $months[$mon], $hour ,$min;
3445         $date{'iso-8601'}  = sprintf "%04d-%02d-%02dT%02d:%02d:%02dZ",
3446                              1900+$year, 1+$mon, $mday, $hour ,$min, $sec;
3447
3448         my ($tz_sign, $tz_hour, $tz_min) =
3449                 ($tz =~ m/^([-+])(\d\d)(\d\d)$/);
3450         $tz_sign = ($tz_sign eq '-' ? -1 : +1);
3451         my $local = $epoch + $tz_sign*((($tz_hour*60) + $tz_min)*60);
3452         ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($local);
3453         $date{'hour_local'} = $hour;
3454         $date{'minute_local'} = $min;
3455         $date{'tz_local'} = $tz;
3456         $date{'iso-tz'} = sprintf("%04d-%02d-%02d %02d:%02d:%02d %s",
3457                                   1900+$year, $mon+1, $mday,
3458                                   $hour, $min, $sec, $tz);
3459         return %date;
3460 }
3461
3462 sub hide_mailaddrs_if_private {
3463         my $line = shift;
3464         return $line unless gitweb_check_feature('email-privacy');
3465         $line =~ s/<[^@>]+@[^>]+>/<redacted>/g;
3466         return $line;
3467 }
3468
3469 sub parse_tag {
3470         my $tag_id = shift;
3471         my %tag;
3472         my @comment;
3473
3474         open my $fd, "-|", git_cmd(), "cat-file", "tag", $tag_id or return;
3475         $tag{'id'} = $tag_id;
3476         while (my $line = <$fd>) {
3477                 chomp $line;
3478                 if ($line =~ m/^object ($oid_regex)$/) {
3479                         $tag{'object'} = $1;
3480                 } elsif ($line =~ m/^type (.+)$/) {
3481                         $tag{'type'} = $1;
3482                 } elsif ($line =~ m/^tag (.+)$/) {
3483                         $tag{'name'} = $1;
3484                 } elsif ($line =~ m/^tagger (.*) ([0-9]+) (.*)$/) {
3485                         $tag{'author'} = hide_mailaddrs_if_private($1);
3486                         $tag{'author_epoch'} = $2;
3487                         $tag{'author_tz'} = $3;
3488                         if ($tag{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3489                                 $tag{'author_name'}  = $1;
3490                                 $tag{'author_email'} = $2;
3491                         } else {
3492                                 $tag{'author_name'} = $tag{'author'};
3493                         }
3494                 } elsif ($line =~ m/--BEGIN/) {
3495                         push @comment, $line;
3496                         last;
3497                 } elsif ($line eq "") {
3498                         last;
3499                 }
3500         }
3501         push @comment, <$fd>;
3502         $tag{'comment'} = \@comment;
3503         close $fd or return;
3504         if (!defined $tag{'name'}) {
3505                 return
3506         };
3507         return %tag
3508 }
3509
3510 sub parse_commit_text {
3511         my ($commit_text, $withparents) = @_;
3512         my @commit_lines = split '\n', $commit_text;
3513         my %co;
3514
3515         pop @commit_lines; # Remove '\0'
3516
3517         if (! @commit_lines) {
3518                 return;
3519         }
3520
3521         my $header = shift @commit_lines;
3522         if ($header !~ m/^$oid_regex/) {
3523                 return;
3524         }
3525         ($co{'id'}, my @parents) = split ' ', $header;
3526         while (my $line = shift @commit_lines) {
3527                 last if $line eq "\n";
3528                 if ($line =~ m/^tree ($oid_regex)$/) {
3529                         $co{'tree'} = $1;
3530                 } elsif ((!defined $withparents) && ($line =~ m/^parent ($oid_regex)$/)) {
3531                         push @parents, $1;
3532                 } elsif ($line =~ m/^author (.*) ([0-9]+) (.*)$/) {
3533                         $co{'author'} = hide_mailaddrs_if_private(to_utf8($1));
3534                         $co{'author_epoch'} = $2;
3535                         $co{'author_tz'} = $3;
3536                         if ($co{'author'} =~ m/^([^<]+) <([^>]*)>/) {
3537                                 $co{'author_name'}  = $1;
3538                                 $co{'author_email'} = $2;
3539                         } else {
3540                                 $co{'author_name'} = $co{'author'};
3541                         }
3542                 } elsif ($line =~ m/^committer (.*) ([0-9]+) (.*)$/) {
3543                         $co{'committer'} = hide_mailaddrs_if_private(to_utf8($1));
3544                         $co{'committer_epoch'} = $2;
3545                         $co{'committer_tz'} = $3;
3546                         if ($co{'committer'} =~ m/^([^<]+) <([^>]*)>/) {
3547                                 $co{'committer_name'}  = $1;
3548                                 $co{'committer_email'} = $2;
3549                         } else {
3550                                 $co{'committer_name'} = $co{'committer'};
3551                         }
3552                 }
3553         }
3554         if (!defined $co{'tree'}) {
3555                 return;
3556         };
3557         $co{'parents'} = \@parents;
3558         $co{'parent'} = $parents[0];
3559
3560         foreach my $title (@commit_lines) {
3561                 $title =~ s/^    //;
3562                 if ($title ne "") {
3563                         $co{'title'} = chop_str($title, 80, 5);
3564                         # remove leading stuff of merges to make the interesting part visible
3565                         if (length($title) > 50) {
3566                                 $title =~ s/^Automatic //;
3567                                 $title =~ s/^merge (of|with) /Merge ... /i;
3568                                 if (length($title) > 50) {
3569                                         $title =~ s/(http|rsync):\/\///;
3570                                 }
3571                                 if (length($title) > 50) {
3572                                         $title =~ s/(master|www|rsync)\.//;
3573                                 }
3574                                 if (length($title) > 50) {
3575                                         $title =~ s/kernel.org:?//;
3576                                 }
3577                                 if (length($title) > 50) {
3578                                         $title =~ s/\/pub\/scm//;
3579                                 }
3580                         }
3581                         $co{'title_short'} = chop_str($title, 50, 5);
3582                         last;
3583                 }
3584         }
3585         if (! defined $co{'title'} || $co{'title'} eq "") {
3586                 $co{'title'} = $co{'title_short'} = '(no commit message)';
3587         }
3588         # remove added spaces, redact e-mail addresses if applicable.
3589         foreach my $line (@commit_lines) {
3590                 $line =~ s/^    //;
3591                 $line = hide_mailaddrs_if_private($line);
3592         }
3593         $co{'comment'} = \@commit_lines;
3594
3595         my $age = time - $co{'committer_epoch'};
3596         $co{'age'} = $age;
3597         $co{'age_string'} = age_string($age);
3598         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($co{'committer_epoch'});
3599         if ($age > 60*60*24*7*2) {
3600                 $co{'age_string_date'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3601                 $co{'age_string_age'} = $co{'age_string'};
3602         } else {
3603                 $co{'age_string_date'} = $co{'age_string'};
3604                 $co{'age_string_age'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
3605         }
3606         return %co;
3607 }
3608
3609 sub parse_commit {
3610         my ($commit_id) = @_;
3611         my %co;
3612
3613         local $/ = "\0";
3614
3615         open my $fd, "-|", git_cmd(), "rev-list",
3616                 "--parents",
3617                 "--header",
3618                 "--max-count=1",
3619                 $commit_id,
3620                 "--",
3621                 or die_error(500, "Open git-rev-list failed");
3622         %co = parse_commit_text(<$fd>, 1);
3623         close $fd;
3624
3625         return %co;
3626 }
3627
3628 sub parse_commits {
3629         my ($commit_id, $maxcount, $skip, $filename, @args) = @_;
3630         my @cos;
3631
3632         $maxcount ||= 1;
3633         $skip ||= 0;
3634
3635         local $/ = "\0";
3636
3637         open my $fd, "-|", git_cmd(), "rev-list",
3638                 "--header",
3639                 @args,
3640                 ("--max-count=" . $maxcount),
3641                 ("--skip=" . $skip),
3642                 @extra_options,
3643                 $commit_id,
3644                 "--",
3645                 ($filename ? ($filename) : ())
3646                 or die_error(500, "Open git-rev-list failed");
3647         while (my $line = <$fd>) {
3648                 my %co = parse_commit_text($line);
3649                 push @cos, \%co;
3650         }
3651         close $fd;
3652
3653         return wantarray ? @cos : \@cos;
3654 }
3655
3656 # parse line of git-diff-tree "raw" output
3657 sub parse_difftree_raw_line {
3658         my $line = shift;
3659         my %res;
3660
3661         # ':100644 100644 03b218260e99b78c6df0ed378e59ed9205ccc96d 3b93d5e7cc7f7dd4ebed13a5cc1a4ad976fc94d8 M   ls-files.c'
3662         # ':100644 100644 7f9281985086971d3877aca27704f2aaf9c448ce bc190ebc71bbd923f2b728e505408f5e54bd073a M   rev-tree.c'
3663         if ($line =~ m/^:([0-7]{6}) ([0-7]{6}) ($oid_regex) ($oid_regex) (.)([0-9]{0,3})\t(.*)$/) {
3664                 $res{'from_mode'} = $1;
3665                 $res{'to_mode'} = $2;
3666                 $res{'from_id'} = $3;
3667                 $res{'to_id'} = $4;
3668                 $res{'status'} = $5;
3669                 $res{'similarity'} = $6;
3670                 if ($res{'status'} eq 'R' || $res{'status'} eq 'C') { # renamed or copied
3671                         ($res{'from_file'}, $res{'to_file'}) = map { unquote($_) } split("\t", $7);
3672                 } else {
3673                         $res{'from_file'} = $res{'to_file'} = $res{'file'} = unquote($7);
3674                 }
3675         }
3676         # '::100755 100755 100755 60e79ca1b01bc8b057abe17ddab484699a7f5fdb 94067cc5f73388f33722d52ae02f44692bc07490 94067cc5f73388f33722d52ae02f44692bc07490 MR git-gui/git-gui.sh'
3677         # combined diff (for merge commit)
3678         elsif ($line =~ s/^(::+)((?:[0-7]{6} )+)((?:$oid_regex )+)([a-zA-Z]+)\t(.*)$//) {
3679                 $res{'nparents'}  = length($1);
3680                 $res{'from_mode'} = [ split(' ', $2) ];
3681                 $res{'to_mode'} = pop @{$res{'from_mode'}};
3682                 $res{'from_id'} = [ split(' ', $3) ];
3683                 $res{'to_id'} = pop @{$res{'from_id'}};
3684                 $res{'status'} = [ split('', $4) ];
3685                 $res{'to_file'} = unquote($5);
3686         }
3687         # 'c512b523472485aef4fff9e57b229d9d243c967f'
3688         elsif ($line =~ m/^($oid_regex)$/) {
3689                 $res{'commit'} = $1;
3690         }
3691
3692         return wantarray ? %res : \%res;
3693 }
3694
3695 # wrapper: return parsed line of git-diff-tree "raw" output
3696 # (the argument might be raw line, or parsed info)
3697 sub parsed_difftree_line {
3698         my $line_or_ref = shift;
3699
3700         if (ref($line_or_ref) eq "HASH") {
3701                 # pre-parsed (or generated by hand)
3702                 return $line_or_ref;
3703         } else {
3704                 return parse_difftree_raw_line($line_or_ref);
3705         }
3706 }
3707
3708 # parse line of git-ls-tree output
3709 sub parse_ls_tree_line {
3710         my $line = shift;
3711         my %opts = @_;
3712         my %res;
3713
3714         if ($opts{'-l'}) {
3715                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa   16717  panic.c'
3716                 $line =~ m/^([0-9]+) (.+) ($oid_regex) +(-|[0-9]+)\t(.+)$/s;
3717
3718                 $res{'mode'} = $1;
3719                 $res{'type'} = $2;
3720                 $res{'hash'} = $3;
3721                 $res{'size'} = $4;
3722                 if ($opts{'-z'}) {
3723                         $res{'name'} = $5;
3724                 } else {
3725                         $res{'name'} = unquote($5);
3726                 }
3727         } else {
3728                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
3729                 $line =~ m/^([0-9]+) (.+) ($oid_regex)\t(.+)$/s;
3730
3731                 $res{'mode'} = $1;
3732                 $res{'type'} = $2;
3733                 $res{'hash'} = $3;
3734                 if ($opts{'-z'}) {
3735                         $res{'name'} = $4;
3736                 } else {
3737                         $res{'name'} = unquote($4);
3738                 }
3739         }
3740
3741         return wantarray ? %res : \%res;
3742 }
3743
3744 # generates _two_ hashes, references to which are passed as 2 and 3 argument
3745 sub parse_from_to_diffinfo {
3746         my ($diffinfo, $from, $to, @parents) = @_;
3747
3748         if ($diffinfo->{'nparents'}) {
3749                 # combined diff
3750                 $from->{'file'} = [];
3751                 $from->{'href'} = [];
3752                 fill_from_file_info($diffinfo, @parents)
3753                         unless exists $diffinfo->{'from_file'};
3754                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
3755                         $from->{'file'}[$i] =
3756                                 defined $diffinfo->{'from_file'}[$i] ?
3757                                         $diffinfo->{'from_file'}[$i] :
3758                                         $diffinfo->{'to_file'};
3759                         if ($diffinfo->{'status'}[$i] ne "A") { # not new (added) file
3760                                 $from->{'href'}[$i] = href(action=>"blob",
3761                                                            hash_base=>$parents[$i],
3762                                                            hash=>$diffinfo->{'from_id'}[$i],
3763                                                            file_name=>$from->{'file'}[$i]);
3764                         } else {
3765                                 $from->{'href'}[$i] = undef;
3766                         }
3767                 }
3768         } else {
3769                 # ordinary (not combined) diff
3770                 $from->{'file'} = $diffinfo->{'from_file'};
3771                 if ($diffinfo->{'status'} ne "A") { # not new (added) file
3772                         $from->{'href'} = href(action=>"blob", hash_base=>$hash_parent,
3773                                                hash=>$diffinfo->{'from_id'},
3774                                                file_name=>$from->{'file'});
3775                 } else {
3776                         delete $from->{'href'};
3777                 }
3778         }
3779
3780         $to->{'file'} = $diffinfo->{'to_file'};
3781         if (!is_deleted($diffinfo)) { # file exists in result
3782                 $to->{'href'} = href(action=>"blob", hash_base=>$hash,
3783                                      hash=>$diffinfo->{'to_id'},
3784                                      file_name=>$to->{'file'});
3785         } else {
3786                 delete $to->{'href'};
3787         }
3788 }
3789
3790 ## ......................................................................
3791 ## parse to array of hashes functions
3792
3793 sub git_get_heads_list {
3794         my ($limit, @classes) = @_;
3795         @classes = get_branch_refs() unless @classes;
3796         my @patterns = map { "refs/$_" } @classes;
3797         my @headslist;
3798
3799         open my $fd, '-|', git_cmd(), 'for-each-ref',
3800                 ($limit ? '--count='.($limit+1) : ()),
3801                 '--sort=-HEAD', '--sort=-committerdate',
3802                 '--format=%(objectname) %(refname) %(subject)%00%(committer)',
3803                 @patterns
3804                 or return;
3805         while (my $line = <$fd>) {
3806                 my %ref_item;
3807
3808                 chomp $line;
3809                 my ($refinfo, $committerinfo) = split(/\0/, $line);
3810                 my ($hash, $name, $title) = split(' ', $refinfo, 3);
3811                 my ($committer, $epoch, $tz) =
3812                         ($committerinfo =~ /^(.*) ([0-9]+) (.*)$/);
3813                 $ref_item{'fullname'}  = $name;
3814                 my $strip_refs = join '|', map { quotemeta } get_branch_refs();
3815                 $name =~ s!^refs/($strip_refs|remotes)/!!;
3816                 $ref_item{'name'} = $name;
3817                 # for refs neither in 'heads' nor 'remotes' we want to
3818                 # show their ref dir
3819                 my $ref_dir = (defined $1) ? $1 : '';
3820                 if ($ref_dir ne '' and $ref_dir ne 'heads' and $ref_dir ne 'remotes') {
3821                     $ref_item{'name'} .= ' (' . $ref_dir . ')';
3822                 }
3823
3824                 $ref_item{'id'}    = $hash;
3825                 $ref_item{'title'} = $title || '(no commit message)';
3826                 $ref_item{'epoch'} = $epoch;
3827                 if ($epoch) {
3828                         $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3829                 } else {
3830                         $ref_item{'age'} = "unknown";
3831                 }
3832
3833                 push @headslist, \%ref_item;
3834         }
3835         close $fd;
3836
3837         return wantarray ? @headslist : \@headslist;
3838 }
3839
3840 sub git_get_tags_list {
3841         my $limit = shift;
3842         my @tagslist;
3843
3844         open my $fd, '-|', git_cmd(), 'for-each-ref',
3845                 ($limit ? '--count='.($limit+1) : ()), '--sort=-creatordate',
3846                 '--format=%(objectname) %(objecttype) %(refname) '.
3847                 '%(*objectname) %(*objecttype) %(subject)%00%(creator)',
3848                 'refs/tags'
3849                 or return;
3850         while (my $line = <$fd>) {
3851                 my %ref_item;
3852
3853                 chomp $line;
3854                 my ($refinfo, $creatorinfo) = split(/\0/, $line);
3855                 my ($id, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
3856                 my ($creator, $epoch, $tz) =
3857                         ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
3858                 $ref_item{'fullname'} = $name;
3859                 $name =~ s!^refs/tags/!!;
3860
3861                 $ref_item{'type'} = $type;
3862                 $ref_item{'id'} = $id;
3863                 $ref_item{'name'} = $name;
3864                 if ($type eq "tag") {
3865                         $ref_item{'subject'} = $title;
3866                         $ref_item{'reftype'} = $reftype;
3867                         $ref_item{'refid'}   = $refid;
3868                 } else {
3869                         $ref_item{'reftype'} = $type;
3870                         $ref_item{'refid'}   = $id;
3871                 }
3872
3873                 if ($type eq "tag" || $type eq "commit") {
3874                         $ref_item{'epoch'} = $epoch;
3875                         if ($epoch) {
3876                                 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3877                         } else {
3878                                 $ref_item{'age'} = "unknown";
3879                         }
3880                 }
3881
3882                 push @tagslist, \%ref_item;
3883         }
3884         close $fd;
3885
3886         return wantarray ? @tagslist : \@tagslist;
3887 }
3888
3889 ## ----------------------------------------------------------------------
3890 ## filesystem-related functions
3891
3892 sub get_file_owner {
3893         my $path = shift;
3894
3895         my ($dev, $ino, $mode, $nlink, $st_uid, $st_gid, $rdev, $size) = stat($path);
3896         my ($name, $passwd, $uid, $gid, $quota, $comment, $gcos, $dir, $shell) = getpwuid($st_uid);
3897         if (!defined $gcos) {
3898                 return undef;
3899         }
3900         my $owner = $gcos;
3901         $owner =~ s/[,;].*$//;
3902         return to_utf8($owner);
3903 }
3904
3905 # assume that file exists
3906 sub insert_file {
3907         my $filename = shift;
3908
3909         open my $fd, '<', $filename;
3910         print map { to_utf8($_) } <$fd>;
3911         close $fd;
3912 }
3913
3914 ## ......................................................................
3915 ## mimetype related functions
3916
3917 sub mimetype_guess_file {
3918         my $filename = shift;
3919         my $mimemap = shift;
3920         -r $mimemap or return undef;
3921
3922         my %mimemap;
3923         open(my $mh, '<', $mimemap) or return undef;
3924         while (<$mh>) {
3925                 next if m/^#/; # skip comments
3926                 my ($mimetype, @exts) = split(/\s+/);
3927                 foreach my $ext (@exts) {
3928                         $mimemap{$ext} = $mimetype;
3929                 }
3930         }
3931         close($mh);
3932
3933         $filename =~ /\.([^.]*)$/;
3934         return $mimemap{$1};
3935 }
3936
3937 sub mimetype_guess {
3938         my $filename = shift;
3939         my $mime;
3940         $filename =~ /\./ or return undef;
3941
3942         if ($mimetypes_file) {
3943                 my $file = $mimetypes_file;
3944                 if ($file !~ m!^/!) { # if it is relative path
3945                         # it is relative to project
3946                         $file = "$projectroot/$project/$file";
3947                 }
3948                 $mime = mimetype_guess_file($filename, $file);
3949         }
3950         $mime ||= mimetype_guess_file($filename, '/etc/mime.types');
3951         return $mime;
3952 }
3953
3954 sub blob_mimetype {
3955         my $fd = shift;
3956         my $filename = shift;
3957
3958         if ($filename) {
3959                 my $mime = mimetype_guess($filename);
3960                 $mime and return $mime;
3961         }
3962
3963         # just in case
3964         return $default_blob_plain_mimetype unless $fd;
3965
3966         if (-T $fd) {
3967                 return 'text/plain';
3968         } elsif (! $filename) {
3969                 return 'application/octet-stream';
3970         } elsif ($filename =~ m/\.png$/i) {
3971                 return 'image/png';
3972         } elsif ($filename =~ m/\.gif$/i) {
3973                 return 'image/gif';
3974         } elsif ($filename =~ m/\.jpe?g$/i) {
3975                 return 'image/jpeg';
3976         } else {
3977                 return 'application/octet-stream';
3978         }
3979 }
3980
3981 sub blob_contenttype {
3982         my ($fd, $file_name, $type) = @_;
3983
3984         $type ||= blob_mimetype($fd, $file_name);
3985         if ($type eq 'text/plain' && defined $default_text_plain_charset) {
3986                 $type .= "; charset=$default_text_plain_charset";
3987         }
3988
3989         return $type;
3990 }
3991
3992 # guess file syntax for syntax highlighting; return undef if no highlighting
3993 # the name of syntax can (in the future) depend on syntax highlighter used
3994 sub guess_file_syntax {
3995         my ($highlight, $file_name) = @_;
3996         return undef unless ($highlight && defined $file_name);
3997         my $basename = basename($file_name, '.in');
3998         return $highlight_basename{$basename}
3999                 if exists $highlight_basename{$basename};
4000
4001         $basename =~ /\.([^.]*)$/;
4002         my $ext = $1 or return undef;
4003         return $highlight_ext{$ext}
4004                 if exists $highlight_ext{$ext};
4005
4006         return undef;
4007 }
4008
4009 # run highlighter and return FD of its output,
4010 # or return original FD if no highlighting
4011 sub run_highlighter {
4012         my ($fd, $highlight, $syntax) = @_;
4013         return $fd unless ($highlight);
4014
4015         close $fd;
4016         my $syntax_arg = (defined $syntax) ? "--syntax $syntax" : "--force";
4017         open $fd, quote_command(git_cmd(), "cat-file", "blob", $hash)." | ".
4018                   quote_command($^X, '-CO', '-MEncode=decode,FB_DEFAULT', '-pse',
4019                     '$_ = decode($fe, $_, FB_DEFAULT) if !utf8::decode($_);',
4020                     '--', "-fe=$fallback_encoding")." | ".
4021                   quote_command($highlight_bin).
4022                   " --replace-tabs=8 --fragment $syntax_arg |"
4023                 or die_error(500, "Couldn't open file or run syntax highlighter");
4024         return $fd;
4025 }
4026
4027 ## ======================================================================
4028 ## functions printing HTML: header, footer, error page
4029
4030 sub get_page_title {
4031         my $title = to_utf8($site_name);
4032
4033         unless (defined $project) {
4034                 if (defined $project_filter) {
4035                         $title .= " - projects in '" . esc_path($project_filter) . "'";
4036                 }
4037                 return $title;
4038         }
4039         $title .= " - " . to_utf8($project);
4040
4041         return $title unless (defined $action);
4042         $title .= "/$action"; # $action is US-ASCII (7bit ASCII)
4043
4044         return $title unless (defined $file_name);
4045         $title .= " - " . esc_path($file_name);
4046         if ($action eq "tree" && $file_name !~ m|/$|) {
4047                 $title .= "/";
4048         }
4049
4050         return $title;
4051 }
4052
4053 sub get_content_type_html {
4054         # require explicit support from the UA if we are to send the page as
4055         # 'application/xhtml+xml', otherwise send it as plain old 'text/html'.
4056         # we have to do this because MSIE sometimes globs '*/*', pretending to
4057         # support xhtml+xml but choking when it gets what it asked for.
4058         if (defined $cgi->http('HTTP_ACCEPT') &&
4059             $cgi->http('HTTP_ACCEPT') =~ m/(,|;|\s|^)application\/xhtml\+xml(,|;|\s|$)/ &&
4060             $cgi->Accept('application/xhtml+xml') != 0) {
4061                 return 'application/xhtml+xml';
4062         } else {
4063                 return 'text/html';
4064         }
4065 }
4066
4067 sub print_feed_meta {
4068         if (defined $project) {
4069                 my %href_params = get_feed_info();
4070                 if (!exists $href_params{'-title'}) {
4071                         $href_params{'-title'} = 'log';
4072                 }
4073
4074                 foreach my $format (qw(RSS Atom)) {
4075                         my $type = lc($format);
4076                         my %link_attr = (
4077                                 '-rel' => 'alternate',
4078                                 '-title' => esc_attr("$project - $href_params{'-title'} - $format feed"),
4079                                 '-type' => "application/$type+xml"
4080                         );
4081
4082                         $href_params{'extra_options'} = undef;
4083                         $href_params{'action'} = $type;
4084                         $link_attr{'-href'} = esc_attr(href(%href_params));
4085                         print "<link ".
4086                               "rel=\"$link_attr{'-rel'}\" ".
4087                               "title=\"$link_attr{'-title'}\" ".
4088                               "href=\"$link_attr{'-href'}\" ".
4089                               "type=\"$link_attr{'-type'}\" ".
4090                               "/>\n";
4091
4092                         $href_params{'extra_options'} = '--no-merges';
4093                         $link_attr{'-href'} = esc_attr(href(%href_params));
4094                         $link_attr{'-title'} .= ' (no merges)';
4095                         print "<link ".
4096                               "rel=\"$link_attr{'-rel'}\" ".
4097                               "title=\"$link_attr{'-title'}\" ".
4098                               "href=\"$link_attr{'-href'}\" ".
4099                               "type=\"$link_attr{'-type'}\" ".
4100                               "/>\n";
4101                 }
4102
4103         } else {
4104                 printf('<link rel="alternate" title="%s projects list" '.
4105                        'href="%s" type="text/plain; charset=utf-8" />'."\n",
4106                        esc_attr($site_name),
4107                        esc_attr(href(project=>undef, action=>"project_index")));
4108                 printf('<link rel="alternate" title="%s projects feeds" '.
4109                        'href="%s" type="text/x-opml" />'."\n",
4110                        esc_attr($site_name),
4111                        esc_attr(href(project=>undef, action=>"opml")));
4112         }
4113 }
4114
4115 sub print_header_links {
4116         my $status = shift;
4117
4118         # print out each stylesheet that exist, providing backwards capability
4119         # for those people who defined $stylesheet in a config file
4120         if (defined $stylesheet) {
4121                 print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
4122         } else {
4123                 foreach my $stylesheet (@stylesheets) {
4124                         next unless $stylesheet;
4125                         print '<link rel="stylesheet" type="text/css" href="'.esc_url($stylesheet).'"/>'."\n";
4126                 }
4127         }
4128         print_feed_meta()
4129                 if ($status eq '200 OK');
4130         if (defined $favicon) {
4131                 print qq(<link rel="shortcut icon" href=").esc_url($favicon).qq(" type="image/png" />\n);
4132         }
4133 }
4134
4135 sub print_nav_breadcrumbs_path {
4136         my $dirprefix = undef;
4137         while (my $part = shift) {
4138                 $dirprefix .= "/" if defined $dirprefix;
4139                 $dirprefix .= $part;
4140                 print $cgi->a({-href => href(project => undef,
4141                                              project_filter => $dirprefix,
4142                                              action => "project_list")},
4143                               esc_html($part)) . " / ";
4144         }
4145 }
4146
4147 sub print_nav_breadcrumbs {
4148         my %opts = @_;
4149
4150         for my $crumb (@extra_breadcrumbs, [ $home_link_str => $home_link ]) {
4151                 print $cgi->a({-href => esc_url($crumb->[1])}, $crumb->[0]) . " / ";
4152         }
4153         if (defined $project) {
4154                 my @dirname = split '/', $project;
4155                 my $projectbasename = pop @dirname;
4156                 print_nav_breadcrumbs_path(@dirname);
4157                 print $cgi->a({-href => href(action=>"summary")}, esc_html($projectbasename));
4158                 if (defined $action) {
4159                         my $action_print = $action ;
4160                         if (defined $opts{-action_extra}) {
4161                                 $action_print = $cgi->a({-href => href(action=>$action)},
4162                                         $action);
4163                         }
4164                         print " / $action_print";
4165                 }
4166                 if (defined $opts{-action_extra}) {
4167                         print " / $opts{-action_extra}";
4168                 }
4169                 print "\n";
4170         } elsif (defined $project_filter) {
4171                 print_nav_breadcrumbs_path(split '/', $project_filter);
4172         }
4173 }
4174
4175 sub print_search_form {
4176         if (!defined $searchtext) {
4177                 $searchtext = "";
4178         }
4179         my $search_hash;
4180         if (defined $hash_base) {
4181                 $search_hash = $hash_base;
4182         } elsif (defined $hash) {
4183                 $search_hash = $hash;
4184         } else {
4185                 $search_hash = "HEAD";
4186         }
4187         my $action = $my_uri;
4188         my $use_pathinfo = gitweb_check_feature('pathinfo');
4189         if ($use_pathinfo) {
4190                 $action .= "/".esc_url($project);
4191         }
4192         print $cgi->start_form(-method => "get", -action => $action) .
4193               "<div class=\"search\">\n" .
4194               (!$use_pathinfo &&
4195               $cgi->input({-name=>"p", -value=>$project, -type=>"hidden"}) . "\n") .
4196               $cgi->input({-name=>"a", -value=>"search", -type=>"hidden"}) . "\n" .
4197               $cgi->input({-name=>"h", -value=>$search_hash, -type=>"hidden"}) . "\n" .
4198               $cgi->popup_menu(-name => 'st', -default => 'commit',
4199                                -values => ['commit', 'grep', 'author', 'committer', 'pickaxe']) .
4200               " " . $cgi->a({-href => href(action=>"search_help"),
4201                              -title => "search help" }, "?") . " search:\n",
4202               $cgi->textfield(-name => "s", -value => $searchtext, -override => 1) . "\n" .
4203               "<span title=\"Extended regular expression\">" .
4204               $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
4205                              -checked => $search_use_regexp) .
4206               "</span>" .
4207               "</div>" .
4208               $cgi->end_form() . "\n";
4209 }
4210
4211 sub git_header_html {
4212         my $status = shift || "200 OK";
4213         my $expires = shift;
4214         my %opts = @_;
4215
4216         my $title = get_page_title();
4217         print $cgi->header(-type=>get_content_type_html(), -charset => 'utf-8',
4218                            -status=> $status, -expires => $expires)
4219                 unless ($opts{'-no_http_header'});
4220         my $mod_perl_version = $ENV{'MOD_PERL'} ? " $ENV{'MOD_PERL'}" : '';
4221         print <<EOF;
4222 <?xml version="1.0" encoding="utf-8"?>
4223 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
4224 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en-US" lang="en-US">
4225 <!-- git web interface version $version, (C) 2005-2006, Kay Sievers <kay.sievers\@vrfy.org>, Christian Gierke -->
4226 <!-- git core binaries version $git_version -->
4227 <head>
4228 <meta name="generator" content="gitweb/$version git/$git_version$mod_perl_version"/>
4229 <meta name="robots" content="index, nofollow"/>
4230 <title>$title</title>
4231 EOF
4232         # the stylesheet, favicon etc urls won't work correctly with path_info
4233         # unless we set the appropriate base URL
4234         if ($ENV{'PATH_INFO'}) {
4235                 print "<base href=\"".esc_url($base_url)."\" />\n";
4236         }
4237         print_header_links($status);
4238
4239         if (defined $site_html_head_string) {
4240                 print to_utf8($site_html_head_string);
4241         }
4242
4243         print "</head>\n" .
4244               "<body>\n";
4245
4246         if (defined $site_header && -f $site_header) {
4247                 insert_file($site_header);
4248         }
4249
4250         print "<div class=\"page_header\">\n";
4251         if (defined $logo) {
4252                 print $cgi->a({-href => esc_url($logo_url),
4253                                -title => $logo_label},
4254                               $cgi->img({-src => esc_url($logo),
4255                                          -width => 72, -height => 27,
4256                                          -alt => "git",
4257                                          -class => "logo"}));
4258         }
4259         print_nav_breadcrumbs(%opts);
4260         print "</div>\n";
4261
4262         my $have_search = gitweb_check_feature('search');
4263         if (defined $project && $have_search) {
4264                 print_search_form();
4265         }
4266 }
4267
4268 sub git_footer_html {
4269         my $feed_class = 'rss_logo';
4270
4271         print "<div class=\"page_footer\">\n";
4272         if (defined $project) {
4273                 my $descr = git_get_project_description($project);
4274                 if (defined $descr) {
4275                         print "<div class=\"page_footer_text\">" . esc_html($descr) . "</div>\n";
4276                 }
4277
4278                 my %href_params = get_feed_info();
4279                 if (!%href_params) {
4280                         $feed_class .= ' generic';
4281                 }
4282                 $href_params{'-title'} ||= 'log';
4283
4284                 foreach my $format (qw(RSS Atom)) {
4285                         $href_params{'action'} = lc($format);
4286                         print $cgi->a({-href => href(%href_params),
4287                                       -title => "$href_params{'-title'} $format feed",
4288                                       -class => $feed_class}, $format)."\n";
4289                 }
4290
4291         } else {
4292                 print $cgi->a({-href => href(project=>undef, action=>"opml",
4293                                              project_filter => $project_filter),
4294                               -class => $feed_class}, "OPML") . " ";
4295                 print $cgi->a({-href => href(project=>undef, action=>"project_index",
4296                                              project_filter => $project_filter),
4297                               -class => $feed_class}, "TXT") . "\n";
4298         }
4299         print "</div>\n"; # class="page_footer"
4300
4301         if (defined $t0 && gitweb_check_feature('timed')) {
4302                 print "<div id=\"generating_info\">\n";
4303                 print 'This page took '.
4304                       '<span id="generating_time" class="time_span">'.
4305                       tv_interval($t0, [ gettimeofday() ]).
4306                       ' seconds </span>'.
4307                       ' and '.
4308                       '<span id="generating_cmd">'.
4309                       $number_of_git_cmds.
4310                       '</span> git commands '.
4311                       " to generate.\n";
4312                 print "</div>\n"; # class="page_footer"
4313         }
4314
4315         if (defined $site_footer && -f $site_footer) {
4316                 insert_file($site_footer);
4317         }
4318
4319         print qq!<script type="text/javascript" src="!.esc_url($javascript).qq!"></script>\n!;
4320         if (defined $action &&
4321             $action eq 'blame_incremental') {
4322                 print qq!<script type="text/javascript">\n!.
4323                       qq!startBlame("!. esc_attr(href(action=>"blame_data", -replay=>1)) .qq!",\n!.
4324                       qq!           "!. esc_attr(href()) .qq!");\n!.
4325                       qq!</script>\n!;
4326         } else {
4327                 my ($jstimezone, $tz_cookie, $datetime_class) =
4328                         gitweb_get_feature('javascript-timezone');
4329
4330                 print qq!<script type="text/javascript">\n!.
4331                       qq!window.onload = function () {\n!;
4332                 if (gitweb_check_feature('javascript-actions')) {
4333                         print qq!       fixLinks();\n!;
4334                 }
4335                 if ($jstimezone && $tz_cookie && $datetime_class) {
4336                         print qq!       var tz_cookie = { name: '$tz_cookie', expires: 14, path: '/' };\n!. # in days
4337                               qq!       onloadTZSetup('$jstimezone', tz_cookie, '$datetime_class');\n!;
4338                 }
4339                 print qq!};\n!.
4340                       qq!</script>\n!;
4341         }
4342
4343         print "</body>\n" .
4344               "</html>";
4345 }
4346
4347 # die_error(<http_status_code>, <error_message>[, <detailed_html_description>])
4348 # Example: die_error(404, 'Hash not found')
4349 # By convention, use the following status codes (as defined in RFC 2616):
4350 # 400: Invalid or missing CGI parameters, or
4351 #      requested object exists but has wrong type.
4352 # 403: Requested feature (like "pickaxe" or "snapshot") not enabled on
4353 #      this server or project.
4354 # 404: Requested object/revision/project doesn't exist.
4355 # 500: The server isn't configured properly, or
4356 #      an internal error occurred (e.g. failed assertions caused by bugs), or
4357 #      an unknown error occurred (e.g. the git binary died unexpectedly).
4358 # 503: The server is currently unavailable (because it is overloaded,
4359 #      or down for maintenance).  Generally, this is a temporary state.
4360 sub die_error {
4361         my $status = shift || 500;
4362         my $error = esc_html(shift) || "Internal Server Error";
4363         my $extra = shift;
4364         my %opts = @_;
4365
4366         my %http_responses = (
4367                 400 => '400 Bad Request',
4368                 403 => '403 Forbidden',
4369                 404 => '404 Not Found',
4370                 500 => '500 Internal Server Error',
4371                 503 => '503 Service Unavailable',
4372         );
4373         git_header_html($http_responses{$status}, undef, %opts);
4374         print <<EOF;
4375 <div class="page_body">
4376 <br /><br />
4377 $status - $error
4378 <br />
4379 EOF
4380         if (defined $extra) {
4381                 print "<hr />\n" .
4382                       "$extra\n";
4383         }
4384         print "</div>\n";
4385
4386         git_footer_html();
4387         goto DONE_GITWEB
4388                 unless ($opts{'-error_handler'});
4389 }
4390
4391 ## ----------------------------------------------------------------------
4392 ## functions printing or outputting HTML: navigation
4393
4394 sub git_print_page_nav {
4395         my ($current, $suppress, $head, $treehead, $treebase, $extra) = @_;
4396         $extra = '' if !defined $extra; # pager or formats
4397
4398         my @navs = qw(summary shortlog log commit commitdiff tree);
4399         if ($suppress) {
4400                 @navs = grep { $_ ne $suppress } @navs;
4401         }
4402
4403         my %arg = map { $_ => {action=>$_} } @navs;
4404         if (defined $head) {
4405                 for (qw(commit commitdiff)) {
4406                         $arg{$_}{'hash'} = $head;
4407                 }
4408                 if ($current =~ m/^(tree | log | shortlog | commit | commitdiff | search)$/x) {
4409                         for (qw(shortlog log)) {
4410                                 $arg{$_}{'hash'} = $head;
4411                         }
4412                 }
4413         }
4414
4415         $arg{'tree'}{'hash'} = $treehead if defined $treehead;
4416         $arg{'tree'}{'hash_base'} = $treebase if defined $treebase;
4417
4418         my @actions = gitweb_get_feature('actions');
4419         my %repl = (
4420                 '%' => '%',
4421                 'n' => $project,         # project name
4422                 'f' => $git_dir,         # project path within filesystem
4423                 'h' => $treehead || '',  # current hash ('h' parameter)
4424                 'b' => $treebase || '',  # hash base ('hb' parameter)
4425         );
4426         while (@actions) {
4427                 my ($label, $link, $pos) = splice(@actions,0,3);
4428                 # insert
4429                 @navs = map { $_ eq $pos ? ($_, $label) : $_ } @navs;
4430                 # munch munch
4431                 $link =~ s/%([%nfhb])/$repl{$1}/g;
4432                 $arg{$label}{'_href'} = $link;
4433         }
4434
4435         print "<div class=\"page_nav\">\n" .
4436                 (join " | ",
4437                  map { $_ eq $current ?
4438                        $_ : $cgi->a({-href => ($arg{$_}{_href} ? $arg{$_}{_href} : href(%{$arg{$_}}))}, "$_")
4439                  } @navs);
4440         print "<br/>\n$extra<br/>\n" .
4441               "</div>\n";
4442 }
4443
4444 # returns a submenu for the navigation of the refs views (tags, heads,
4445 # remotes) with the current view disabled and the remotes view only
4446 # available if the feature is enabled
4447 sub format_ref_views {
4448         my ($current) = @_;
4449         my @ref_views = qw{tags heads};
4450         push @ref_views, 'remotes' if gitweb_check_feature('remote_heads');
4451         return join " | ", map {
4452                 $_ eq $current ? $_ :
4453                 $cgi->a({-href => href(action=>$_)}, $_)
4454         } @ref_views
4455 }
4456
4457 sub format_paging_nav {
4458         my ($action, $page, $has_next_link) = @_;
4459         my $paging_nav;
4460
4461
4462         if ($page > 0) {
4463                 $paging_nav .=
4464                         $cgi->a({-href => href(-replay=>1, page=>undef)}, "first") .
4465                         " &sdot; " .
4466                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
4467                                  -accesskey => "p", -title => "Alt-p"}, "prev");
4468         } else {
4469                 $paging_nav .= "first &sdot; prev";
4470         }
4471
4472         if ($has_next_link) {
4473                 $paging_nav .= " &sdot; " .
4474                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
4475                                  -accesskey => "n", -title => "Alt-n"}, "next");
4476         } else {
4477                 $paging_nav .= " &sdot; next";
4478         }
4479
4480         return $paging_nav;
4481 }
4482
4483 ## ......................................................................
4484 ## functions printing or outputting HTML: div
4485
4486 sub git_print_header_div {
4487         my ($action, $title, $hash, $hash_base) = @_;
4488         my %args = ();
4489
4490         $args{'action'} = $action;
4491         $args{'hash'} = $hash if $hash;
4492         $args{'hash_base'} = $hash_base if $hash_base;
4493
4494         print "<div class=\"header\">\n" .
4495               $cgi->a({-href => href(%args), -class => "title"},
4496               $title ? $title : $action) .
4497               "\n</div>\n";
4498 }
4499
4500 sub format_repo_url {
4501         my ($name, $url) = @_;
4502         return "<tr class=\"metadata_url\"><td>$name</td><td>$url</td></tr>\n";
4503 }
4504
4505 # Group output by placing it in a DIV element and adding a header.
4506 # Options for start_div() can be provided by passing a hash reference as the
4507 # first parameter to the function.
4508 # Options to git_print_header_div() can be provided by passing an array
4509 # reference. This must follow the options to start_div if they are present.
4510 # The content can be a scalar, which is output as-is, a scalar reference, which
4511 # is output after html escaping, an IO handle passed either as *handle or
4512 # *handle{IO}, or a function reference. In the latter case all following
4513 # parameters will be taken as argument to the content function call.
4514 sub git_print_section {
4515         my ($div_args, $header_args, $content);
4516         my $arg = shift;
4517         if (ref($arg) eq 'HASH') {
4518                 $div_args = $arg;
4519                 $arg = shift;
4520         }
4521         if (ref($arg) eq 'ARRAY') {
4522                 $header_args = $arg;
4523                 $arg = shift;
4524         }
4525         $content = $arg;
4526
4527         print $cgi->start_div($div_args);
4528         git_print_header_div(@$header_args);
4529
4530         if (ref($content) eq 'CODE') {
4531                 $content->(@_);
4532         } elsif (ref($content) eq 'SCALAR') {
4533                 print esc_html($$content);
4534         } elsif (ref($content) eq 'GLOB' or ref($content) eq 'IO::Handle') {
4535                 print <$content>;
4536         } elsif (!ref($content) && defined($content)) {
4537                 print $content;
4538         }
4539
4540         print $cgi->end_div;
4541 }
4542
4543 sub format_timestamp_html {
4544         my $date = shift;
4545         my $strtime = $date->{'rfc2822'};
4546
4547         my (undef, undef, $datetime_class) =
4548                 gitweb_get_feature('javascript-timezone');
4549         if ($datetime_class) {
4550                 $strtime = qq!<span class="$datetime_class">$strtime</span>!;
4551         }
4552
4553         my $localtime_format = '(%02d:%02d %s)';
4554         if ($date->{'hour_local'} < 6) {
4555                 $localtime_format = '(<span class="atnight">%02d:%02d</span> %s)';
4556         }
4557         $strtime .= ' ' .
4558                     sprintf($localtime_format,
4559                             $date->{'hour_local'}, $date->{'minute_local'}, $date->{'tz_local'});
4560
4561         return $strtime;
4562 }
4563
4564 # Outputs the author name and date in long form
4565 sub git_print_authorship {
4566         my $co = shift;
4567         my %opts = @_;
4568         my $tag = $opts{-tag} || 'div';
4569         my $author = $co->{'author_name'};
4570
4571         my %ad = parse_date($co->{'author_epoch'}, $co->{'author_tz'});
4572         print "<$tag class=\"author_date\">" .
4573               format_search_author($author, "author", esc_html($author)) .
4574               " [".format_timestamp_html(\%ad)."]".
4575               git_get_avatar($co->{'author_email'}, -pad_before => 1) .
4576               "</$tag>\n";
4577 }
4578
4579 # Outputs table rows containing the full author or committer information,
4580 # in the format expected for 'commit' view (& similar).
4581 # Parameters are a commit hash reference, followed by the list of people
4582 # to output information for. If the list is empty it defaults to both
4583 # author and committer.
4584 sub git_print_authorship_rows {
4585         my $co = shift;
4586         # too bad we can't use @people = @_ || ('author', 'committer')
4587         my @people = @_;
4588         @people = ('author', 'committer') unless @people;
4589         foreach my $who (@people) {
4590                 my %wd = parse_date($co->{"${who}_epoch"}, $co->{"${who}_tz"});
4591                 print "<tr><td>$who</td><td>" .
4592                       format_search_author($co->{"${who}_name"}, $who,
4593                                            esc_html($co->{"${who}_name"})) . " " .
4594                       format_search_author($co->{"${who}_email"}, $who,
4595                                            esc_html("<" . $co->{"${who}_email"} . ">")) .
4596                       "</td><td rowspan=\"2\">" .
4597                       git_get_avatar($co->{"${who}_email"}, -size => 'double') .
4598                       "</td></tr>\n" .
4599                       "<tr>" .
4600                       "<td></td><td>" .
4601                       format_timestamp_html(\%wd) .
4602                       "</td>" .
4603                       "</tr>\n";
4604         }
4605 }
4606
4607 sub git_print_page_path {
4608         my $name = shift;
4609         my $type = shift;
4610         my $hb = shift;
4611
4612
4613         print "<div class=\"page_path\">";
4614         print $cgi->a({-href => href(action=>"tree", hash_base=>$hb),
4615                       -title => 'tree root'}, to_utf8("[$project]"));
4616         print " / ";
4617         if (defined $name) {
4618                 my @dirname = split '/', $name;
4619                 my $basename = pop @dirname;
4620                 my $fullname = '';
4621
4622                 foreach my $dir (@dirname) {
4623                         $fullname .= ($fullname ? '/' : '') . $dir;
4624                         print $cgi->a({-href => href(action=>"tree", file_name=>$fullname,
4625                                                      hash_base=>$hb),
4626                                       -title => $fullname}, esc_path($dir));
4627                         print " / ";
4628                 }
4629                 if (defined $type && $type eq 'blob') {
4630                         print $cgi->a({-href => href(action=>"blob_plain", file_name=>$file_name,
4631                                                      hash_base=>$hb),
4632                                       -title => $name}, esc_path($basename));
4633                 } elsif (defined $type && $type eq 'tree') {
4634                         print $cgi->a({-href => href(action=>"tree", file_name=>$file_name,
4635                                                      hash_base=>$hb),
4636                                       -title => $name}, esc_path($basename));
4637                         print " / ";
4638                 } else {
4639                         print esc_path($basename);
4640                 }
4641         }
4642         print "<br/></div>\n";
4643 }
4644
4645 sub git_print_log {
4646         my $log = shift;
4647         my %opts = @_;
4648
4649         if ($opts{'-remove_title'}) {
4650                 # remove title, i.e. first line of log
4651                 shift @$log;
4652         }
4653         # remove leading empty lines
4654         while (defined $log->[0] && $log->[0] eq "") {
4655                 shift @$log;
4656         }
4657
4658         # print log
4659         my $skip_blank_line = 0;
4660         foreach my $line (@$log) {
4661                 if ($line =~ m/^\s*([A-Z][-A-Za-z]*-([Bb]y|[Tt]o)|C[Cc]|(Clos|Fix)es): /) {
4662                         if (! $opts{'-remove_signoff'}) {
4663                                 print "<span class=\"signoff\">" . esc_html($line) . "</span><br/>\n";
4664                                 $skip_blank_line = 1;
4665                         }
4666                         next;
4667                 }
4668
4669                 if ($line =~ m,\s*([a-z]*link): (https?://\S+),i) {
4670                         if (! $opts{'-remove_signoff'}) {
4671                                 print "<span class=\"signoff\">" . esc_html($1) . ": " .
4672                                         "<a href=\"" . esc_html($2) . "\">" . esc_html($2) . "</a>" .
4673                                         "</span><br/>\n";
4674                                 $skip_blank_line = 1;
4675                         }
4676                         next;
4677                 }
4678
4679                 # print only one empty line
4680                 # do not print empty line after signoff
4681                 if ($line eq "") {
4682                         next if ($skip_blank_line);
4683                         $skip_blank_line = 1;
4684                 } else {
4685                         $skip_blank_line = 0;
4686                 }
4687
4688                 print format_log_line_html($line) . "<br/>\n";
4689         }
4690
4691         if ($opts{'-final_empty_line'}) {
4692                 # end with single empty line
4693                 print "<br/>\n" unless $skip_blank_line;
4694         }
4695 }
4696
4697 # return link target (what link points to)
4698 sub git_get_link_target {
4699         my $hash = shift;
4700         my $link_target;
4701
4702         # read link
4703         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
4704                 or return;
4705         {
4706                 local $/ = undef;
4707                 $link_target = <$fd>;
4708         }
4709         close $fd
4710                 or return;
4711
4712         return $link_target;
4713 }
4714
4715 # given link target, and the directory (basedir) the link is in,
4716 # return target of link relative to top directory (top tree);
4717 # return undef if it is not possible (including absolute links).
4718 sub normalize_link_target {
4719         my ($link_target, $basedir) = @_;
4720
4721         # absolute symlinks (beginning with '/') cannot be normalized
4722         return if (substr($link_target, 0, 1) eq '/');
4723
4724         # normalize link target to path from top (root) tree (dir)
4725         my $path;
4726         if ($basedir) {
4727                 $path = $basedir . '/' . $link_target;
4728         } else {
4729                 # we are in top (root) tree (dir)
4730                 $path = $link_target;
4731         }
4732
4733         # remove //, /./, and /../
4734         my @path_parts;
4735         foreach my $part (split('/', $path)) {
4736                 # discard '.' and ''
4737                 next if (!$part || $part eq '.');
4738                 # handle '..'
4739                 if ($part eq '..') {
4740                         if (@path_parts) {
4741                                 pop @path_parts;
4742                         } else {
4743                                 # link leads outside repository (outside top dir)
4744                                 return;
4745                         }
4746                 } else {
4747                         push @path_parts, $part;
4748                 }
4749         }
4750         $path = join('/', @path_parts);
4751
4752         return $path;
4753 }
4754
4755 # print tree entry (row of git_tree), but without encompassing <tr> element
4756 sub git_print_tree_entry {
4757         my ($t, $basedir, $hash_base, $have_blame) = @_;
4758
4759         my %base_key = ();
4760         $base_key{'hash_base'} = $hash_base if defined $hash_base;
4761
4762         # The format of a table row is: mode list link.  Where mode is
4763         # the mode of the entry, list is the name of the entry, an href,
4764         # and link is the action links of the entry.
4765
4766         print "<td class=\"mode\">" . mode_str($t->{'mode'}) . "</td>\n";
4767         if (exists $t->{'size'}) {
4768                 print "<td class=\"size\">$t->{'size'}</td>\n";
4769         }
4770         if ($t->{'type'} eq "blob") {
4771                 print "<td class=\"list\">" .
4772                         $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4773                                                file_name=>"$basedir$t->{'name'}", %base_key),
4774                                 -class => "list"}, esc_path($t->{'name'}));
4775                 if (S_ISLNK(oct $t->{'mode'})) {
4776                         my $link_target = git_get_link_target($t->{'hash'});
4777                         if ($link_target) {
4778                                 my $norm_target = normalize_link_target($link_target, $basedir);
4779                                 if (defined $norm_target) {
4780                                         print " -> " .
4781                                               $cgi->a({-href => href(action=>"object", hash_base=>$hash_base,
4782                                                                      file_name=>$norm_target),
4783                                                        -title => $norm_target}, esc_path($link_target));
4784                                 } else {
4785                                         print " -> " . esc_path($link_target);
4786                                 }
4787                         }
4788                 }
4789                 print "</td>\n";
4790                 print "<td class=\"link\">";
4791                 print $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
4792                                              file_name=>"$basedir$t->{'name'}", %base_key)},
4793                               "blob");
4794                 if ($have_blame) {
4795                         print " | " .
4796                               $cgi->a({-href => href(action=>"blame", hash=>$t->{'hash'},
4797                                                      file_name=>"$basedir$t->{'name'}", %base_key)},
4798                                       "blame");
4799                 }
4800                 if (defined $hash_base) {
4801                         print " | " .
4802                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4803                                                      hash=>$t->{'hash'}, file_name=>"$basedir$t->{'name'}")},
4804                                       "history");
4805                 }
4806                 print " | " .
4807                         $cgi->a({-href => href(action=>"blob_plain", hash_base=>$hash_base,
4808                                                file_name=>"$basedir$t->{'name'}")},
4809                                 "raw");
4810                 print "</td>\n";
4811
4812         } elsif ($t->{'type'} eq "tree") {
4813                 print "<td class=\"list\">";
4814                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4815                                              file_name=>"$basedir$t->{'name'}",
4816                                              %base_key)},
4817                               esc_path($t->{'name'}));
4818                 print "</td>\n";
4819                 print "<td class=\"link\">";
4820                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
4821                                              file_name=>"$basedir$t->{'name'}",
4822                                              %base_key)},
4823                               "tree");
4824                 if (defined $hash_base) {
4825                         print " | " .
4826                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
4827                                                      file_name=>"$basedir$t->{'name'}")},
4828                                       "history");
4829                 }
4830                 print "</td>\n";
4831         } else {
4832                 # unknown object: we can only present history for it
4833                 # (this includes 'commit' object, i.e. submodule support)
4834                 print "<td class=\"list\">" .
4835                       esc_path($t->{'name'}) .
4836                       "</td>\n";
4837                 print "<td class=\"link\">";
4838                 if (defined $hash_base) {
4839                         print $cgi->a({-href => href(action=>"history",
4840                                                      hash_base=>$hash_base,
4841                                                      file_name=>"$basedir$t->{'name'}")},
4842                                       "history");
4843                 }
4844                 print "</td>\n";
4845         }
4846 }
4847
4848 ## ......................................................................
4849 ## functions printing large fragments of HTML
4850
4851 # get pre-image filenames for merge (combined) diff
4852 sub fill_from_file_info {
4853         my ($diff, @parents) = @_;
4854
4855         $diff->{'from_file'} = [ ];
4856         $diff->{'from_file'}[$diff->{'nparents'} - 1] = undef;
4857         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4858                 if ($diff->{'status'}[$i] eq 'R' ||
4859                     $diff->{'status'}[$i] eq 'C') {
4860                         $diff->{'from_file'}[$i] =
4861                                 git_get_path_by_hash($parents[$i], $diff->{'from_id'}[$i]);
4862                 }
4863         }
4864
4865         return $diff;
4866 }
4867
4868 # is current raw difftree line of file deletion
4869 sub is_deleted {
4870         my $diffinfo = shift;
4871
4872         return $diffinfo->{'to_id'} eq ('0' x 40) || $diffinfo->{'to_id'} eq ('0' x 64);
4873 }
4874
4875 # does patch correspond to [previous] difftree raw line
4876 # $diffinfo  - hashref of parsed raw diff format
4877 # $patchinfo - hashref of parsed patch diff format
4878 #              (the same keys as in $diffinfo)
4879 sub is_patch_split {
4880         my ($diffinfo, $patchinfo) = @_;
4881
4882         return defined $diffinfo && defined $patchinfo
4883                 && $diffinfo->{'to_file'} eq $patchinfo->{'to_file'};
4884 }
4885
4886
4887 sub git_difftree_body {
4888         my ($difftree, $hash, @parents) = @_;
4889         my ($parent) = $parents[0];
4890         my $have_blame = gitweb_check_feature('blame');
4891         print "<div class=\"list_head\">\n";
4892         if ($#{$difftree} > 10) {
4893                 print(($#{$difftree} + 1) . " files changed:\n");
4894         }
4895         print "</div>\n";
4896
4897         print "<table class=\"" .
4898               (@parents > 1 ? "combined " : "") .
4899               "diff_tree\">\n";
4900
4901         # header only for combined diff in 'commitdiff' view
4902         my $has_header = @$difftree && @parents > 1 && $action eq 'commitdiff';
4903         if ($has_header) {
4904                 # table header
4905                 print "<thead><tr>\n" .
4906                        "<th></th><th></th>\n"; # filename, patchN link
4907                 for (my $i = 0; $i < @parents; $i++) {
4908                         my $par = $parents[$i];
4909                         print "<th>" .
4910                               $cgi->a({-href => href(action=>"commitdiff",
4911                                                      hash=>$hash, hash_parent=>$par),
4912                                        -title => 'commitdiff to parent number ' .
4913                                                   ($i+1) . ': ' . substr($par,0,7)},
4914                                       $i+1) .
4915                               "&nbsp;</th>\n";
4916                 }
4917                 print "</tr></thead>\n<tbody>\n";
4918         }
4919
4920         my $alternate = 1;
4921         my $patchno = 0;
4922         foreach my $line (@{$difftree}) {
4923                 my $diff = parsed_difftree_line($line);
4924
4925                 if ($alternate) {
4926                         print "<tr class=\"dark\">\n";
4927                 } else {
4928                         print "<tr class=\"light\">\n";
4929                 }
4930                 $alternate ^= 1;
4931
4932                 if (exists $diff->{'nparents'}) { # combined diff
4933
4934                         fill_from_file_info($diff, @parents)
4935                                 unless exists $diff->{'from_file'};
4936
4937                         if (!is_deleted($diff)) {
4938                                 # file exists in the result (child) commit
4939                                 print "<td>" .
4940                                       $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4941                                                              file_name=>$diff->{'to_file'},
4942                                                              hash_base=>$hash),
4943                                               -class => "list"}, esc_path($diff->{'to_file'})) .
4944                                       "</td>\n";
4945                         } else {
4946                                 print "<td>" .
4947                                       esc_path($diff->{'to_file'}) .
4948                                       "</td>\n";
4949                         }
4950
4951                         if ($action eq 'commitdiff') {
4952                                 # link to patch
4953                                 $patchno++;
4954                                 print "<td class=\"link\">" .
4955                                       $cgi->a({-href => href(-anchor=>"patch$patchno")},
4956                                               "patch") .
4957                                       " | " .
4958                                       "</td>\n";
4959                         }
4960
4961                         my $has_history = 0;
4962                         my $not_deleted = 0;
4963                         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4964                                 my $hash_parent = $parents[$i];
4965                                 my $from_hash = $diff->{'from_id'}[$i];
4966                                 my $from_path = $diff->{'from_file'}[$i];
4967                                 my $status = $diff->{'status'}[$i];
4968
4969                                 $has_history ||= ($status ne 'A');
4970                                 $not_deleted ||= ($status ne 'D');
4971
4972                                 if ($status eq 'A') {
4973                                         print "<td  class=\"link\" align=\"right\"> | </td>\n";
4974                                 } elsif ($status eq 'D') {
4975                                         print "<td class=\"link\">" .
4976                                               $cgi->a({-href => href(action=>"blob",
4977                                                                      hash_base=>$hash,
4978                                                                      hash=>$from_hash,
4979                                                                      file_name=>$from_path)},
4980                                                       "blob" . ($i+1)) .
4981                                               " | </td>\n";
4982                                 } else {
4983                                         if ($diff->{'to_id'} eq $from_hash) {
4984                                                 print "<td class=\"link nochange\">";
4985                                         } else {
4986                                                 print "<td class=\"link\">";
4987                                         }
4988                                         print $cgi->a({-href => href(action=>"blobdiff",
4989                                                                      hash=>$diff->{'to_id'},
4990                                                                      hash_parent=>$from_hash,
4991                                                                      hash_base=>$hash,
4992                                                                      hash_parent_base=>$hash_parent,
4993                                                                      file_name=>$diff->{'to_file'},
4994                                                                      file_parent=>$from_path)},
4995                                                       "diff" . ($i+1)) .
4996                                               " | </td>\n";
4997                                 }
4998                         }
4999
5000                         print "<td class=\"link\">";
5001                         if ($not_deleted) {
5002                                 print $cgi->a({-href => href(action=>"blob",
5003                                                              hash=>$diff->{'to_id'},
5004                                                              file_name=>$diff->{'to_file'},
5005                                                              hash_base=>$hash)},
5006                                               "blob");
5007                                 print " | " if ($has_history);
5008                         }
5009                         if ($has_history) {
5010                                 print $cgi->a({-href => href(action=>"history",
5011                                                              file_name=>$diff->{'to_file'},
5012                                                              hash_base=>$hash)},
5013                                               "history");
5014                         }
5015                         print "</td>\n";
5016
5017                         print "</tr>\n";
5018                         next; # instead of 'else' clause, to avoid extra indent
5019                 }
5020                 # else ordinary diff
5021
5022                 my ($to_mode_oct, $to_mode_str, $to_file_type);
5023                 my ($from_mode_oct, $from_mode_str, $from_file_type);
5024                 if ($diff->{'to_mode'} ne ('0' x 6)) {
5025                         $to_mode_oct = oct $diff->{'to_mode'};
5026                         if (S_ISREG($to_mode_oct)) { # only for regular file
5027                                 $to_mode_str = sprintf("%04o", $to_mode_oct & 0777); # permission bits
5028                         }
5029                         $to_file_type = file_type($diff->{'to_mode'});
5030                 }
5031                 if ($diff->{'from_mode'} ne ('0' x 6)) {
5032                         $from_mode_oct = oct $diff->{'from_mode'};
5033                         if (S_ISREG($from_mode_oct)) { # only for regular file
5034                                 $from_mode_str = sprintf("%04o", $from_mode_oct & 0777); # permission bits
5035                         }
5036                         $from_file_type = file_type($diff->{'from_mode'});
5037                 }
5038
5039                 if ($diff->{'status'} eq "A") { # created
5040                         my $mode_chng = "<span class=\"file_status new\">[new $to_file_type";
5041                         $mode_chng   .= " with mode: $to_mode_str" if $to_mode_str;
5042                         $mode_chng   .= "]</span>";
5043                         print "<td>";
5044                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
5045                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
5046                                       -class => "list"}, esc_path($diff->{'file'}));
5047                         print "</td>\n";
5048                         print "<td>$mode_chng</td>\n";
5049                         print "<td class=\"link\">";
5050                         if ($action eq 'commitdiff') {
5051                                 # link to patch
5052                                 $patchno++;
5053                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
5054                                               "patch") .
5055                                       " | ";
5056                         }
5057                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
5058                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
5059                                       "blob");
5060                         print "</td>\n";
5061
5062                 } elsif ($diff->{'status'} eq "D") { # deleted
5063                         my $mode_chng = "<span class=\"file_status deleted\">[deleted $from_file_type]</span>";
5064                         print "<td>";
5065                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
5066                                                      hash_base=>$parent, file_name=>$diff->{'file'}),
5067                                        -class => "list"}, esc_path($diff->{'file'}));
5068                         print "</td>\n";
5069                         print "<td>$mode_chng</td>\n";
5070                         print "<td class=\"link\">";
5071                         if ($action eq 'commitdiff') {
5072                                 # link to patch
5073                                 $patchno++;
5074                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
5075                                               "patch") .
5076                                       " | ";
5077                         }
5078                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
5079                                                      hash_base=>$parent, file_name=>$diff->{'file'})},
5080                                       "blob") . " | ";
5081                         if ($have_blame) {
5082                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$parent,
5083                                                              file_name=>$diff->{'file'})},
5084                                               "blame") . " | ";
5085                         }
5086                         print $cgi->a({-href => href(action=>"history", hash_base=>$parent,
5087                                                      file_name=>$diff->{'file'})},
5088                                       "history");
5089                         print "</td>\n";
5090
5091                 } elsif ($diff->{'status'} eq "M" || $diff->{'status'} eq "T") { # modified, or type changed
5092                         my $mode_chnge = "";
5093                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
5094                                 $mode_chnge = "<span class=\"file_status mode_chnge\">[changed";
5095                                 if ($from_file_type ne $to_file_type) {
5096                                         $mode_chnge .= " from $from_file_type to $to_file_type";
5097                                 }
5098                                 if (($from_mode_oct & 0777) != ($to_mode_oct & 0777)) {
5099                                         if ($from_mode_str && $to_mode_str) {
5100                                                 $mode_chnge .= " mode: $from_mode_str->$to_mode_str";
5101                                         } elsif ($to_mode_str) {
5102                                                 $mode_chnge .= " mode: $to_mode_str";
5103                                         }
5104                                 }
5105                                 $mode_chnge .= "]</span>\n";
5106                         }
5107                         print "<td>";
5108                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
5109                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
5110                                       -class => "list"}, esc_path($diff->{'file'}));
5111                         print "</td>\n";
5112                         print "<td>$mode_chnge</td>\n";
5113                         print "<td class=\"link\">";
5114                         if ($action eq 'commitdiff') {
5115                                 # link to patch
5116                                 $patchno++;
5117                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
5118                                               "patch") .
5119                                       " | ";
5120                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
5121                                 # "commit" view and modified file (not onlu mode changed)
5122                                 print $cgi->a({-href => href(action=>"blobdiff",
5123                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
5124                                                              hash_base=>$hash, hash_parent_base=>$parent,
5125                                                              file_name=>$diff->{'file'})},
5126                                               "diff") .
5127                                       " | ";
5128                         }
5129                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
5130                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
5131                                        "blob") . " | ";
5132                         if ($have_blame) {
5133                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
5134                                                              file_name=>$diff->{'file'})},
5135                                               "blame") . " | ";
5136                         }
5137                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
5138                                                      file_name=>$diff->{'file'})},
5139                                       "history");
5140                         print "</td>\n";
5141
5142                 } elsif ($diff->{'status'} eq "R" || $diff->{'status'} eq "C") { # renamed or copied
5143                         my %status_name = ('R' => 'moved', 'C' => 'copied');
5144                         my $nstatus = $status_name{$diff->{'status'}};
5145                         my $mode_chng = "";
5146                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
5147                                 # mode also for directories, so we cannot use $to_mode_str
5148                                 $mode_chng = sprintf(", mode: %04o", $to_mode_oct & 0777);
5149                         }
5150                         print "<td>" .
5151                               $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
5152                                                      hash=>$diff->{'to_id'}, file_name=>$diff->{'to_file'}),
5153                                       -class => "list"}, esc_path($diff->{'to_file'})) . "</td>\n" .
5154                               "<td><span class=\"file_status $nstatus\">[$nstatus from " .
5155                               $cgi->a({-href => href(action=>"blob", hash_base=>$parent,
5156                                                      hash=>$diff->{'from_id'}, file_name=>$diff->{'from_file'}),
5157                                       -class => "list"}, esc_path($diff->{'from_file'})) .
5158                               " with " . (int $diff->{'similarity'}) . "% similarity$mode_chng]</span></td>\n" .
5159                               "<td class=\"link\">";
5160                         if ($action eq 'commitdiff') {
5161                                 # link to patch
5162                                 $patchno++;
5163                                 print $cgi->a({-href => href(-anchor=>"patch$patchno")},
5164                                               "patch") .
5165                                       " | ";
5166                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
5167                                 # "commit" view and modified file (not only pure rename or copy)
5168                                 print $cgi->a({-href => href(action=>"blobdiff",
5169                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
5170                                                              hash_base=>$hash, hash_parent_base=>$parent,
5171                                                              file_name=>$diff->{'to_file'}, file_parent=>$diff->{'from_file'})},
5172                                               "diff") .
5173                                       " | ";
5174                         }
5175                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
5176                                                      hash_base=>$parent, file_name=>$diff->{'to_file'})},
5177                                       "blob") . " | ";
5178                         if ($have_blame) {
5179                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
5180                                                              file_name=>$diff->{'to_file'})},
5181                                               "blame") . " | ";
5182                         }
5183                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
5184                                                     file_name=>$diff->{'to_file'})},
5185                                       "history");
5186                         print "</td>\n";
5187
5188                 } # we should not encounter Unmerged (U) or Unknown (X) status
5189                 print "</tr>\n";
5190         }
5191         print "</tbody>" if $has_header;
5192         print "</table>\n";
5193 }
5194
5195 # Print context lines and then rem/add lines in a side-by-side manner.
5196 sub print_sidebyside_diff_lines {
5197         my ($ctx, $rem, $add) = @_;
5198
5199         # print context block before add/rem block
5200         if (@$ctx) {
5201                 print join '',
5202                         '<div class="chunk_block ctx">',
5203                                 '<div class="old">',
5204                                 @$ctx,
5205                                 '</div>',
5206                                 '<div class="new">',
5207                                 @$ctx,
5208                                 '</div>',
5209                         '</div>';
5210         }
5211
5212         if (!@$add) {
5213                 # pure removal
5214                 print join '',
5215                         '<div class="chunk_block rem">',
5216                                 '<div class="old">',
5217                                 @$rem,
5218                                 '</div>',
5219                         '</div>';
5220         } elsif (!@$rem) {
5221                 # pure addition
5222                 print join '',
5223                         '<div class="chunk_block add">',
5224                                 '<div class="new">',
5225                                 @$add,
5226                                 '</div>',
5227                         '</div>';
5228         } else {
5229                 print join '',
5230                         '<div class="chunk_block chg">',
5231                                 '<div class="old">',
5232                                 @$rem,
5233                                 '</div>',
5234                                 '<div class="new">',
5235                                 @$add,
5236                                 '</div>',
5237                         '</div>';
5238         }
5239 }
5240
5241 # Print context lines and then rem/add lines in inline manner.
5242 sub print_inline_diff_lines {
5243         my ($ctx, $rem, $add) = @_;
5244
5245         print @$ctx, @$rem, @$add;
5246 }
5247
5248 # Format removed and added line, mark changed part and HTML-format them.
5249 # Implementation is based on contrib/diff-highlight
5250 sub format_rem_add_lines_pair {
5251         my ($rem, $add, $num_parents) = @_;
5252
5253         # We need to untabify lines before split()'ing them;
5254         # otherwise offsets would be invalid.
5255         chomp $rem;
5256         chomp $add;
5257         $rem = untabify($rem);
5258         $add = untabify($add);
5259
5260         my @rem = split(//, $rem);
5261         my @add = split(//, $add);
5262         my ($esc_rem, $esc_add);
5263         # Ignore leading +/- characters for each parent.
5264         my ($prefix_len, $suffix_len) = ($num_parents, 0);
5265         my ($prefix_has_nonspace, $suffix_has_nonspace);
5266
5267         my $shorter = (@rem < @add) ? @rem : @add;
5268         while ($prefix_len < $shorter) {
5269                 last if ($rem[$prefix_len] ne $add[$prefix_len]);
5270
5271                 $prefix_has_nonspace = 1 if ($rem[$prefix_len] !~ /\s/);
5272                 $prefix_len++;
5273         }
5274
5275         while ($prefix_len + $suffix_len < $shorter) {
5276                 last if ($rem[-1 - $suffix_len] ne $add[-1 - $suffix_len]);
5277
5278                 $suffix_has_nonspace = 1 if ($rem[-1 - $suffix_len] !~ /\s/);
5279                 $suffix_len++;
5280         }
5281
5282         # Mark lines that are different from each other, but have some common
5283         # part that isn't whitespace.  If lines are completely different, don't
5284         # mark them because that would make output unreadable, especially if
5285         # diff consists of multiple lines.
5286         if ($prefix_has_nonspace || $suffix_has_nonspace) {
5287                 $esc_rem = esc_html_hl_regions($rem, 'marked',
5288                         [$prefix_len, @rem - $suffix_len], -nbsp=>1);
5289                 $esc_add = esc_html_hl_regions($add, 'marked',
5290                         [$prefix_len, @add - $suffix_len], -nbsp=>1);
5291         } else {
5292                 $esc_rem = esc_html($rem, -nbsp=>1);
5293                 $esc_add = esc_html($add, -nbsp=>1);
5294         }
5295
5296         return format_diff_line(\$esc_rem, 'rem'),
5297                format_diff_line(\$esc_add, 'add');
5298 }
5299
5300 # HTML-format diff context, removed and added lines.
5301 sub format_ctx_rem_add_lines {
5302         my ($ctx, $rem, $add, $num_parents) = @_;
5303         my (@new_ctx, @new_rem, @new_add);
5304         my $can_highlight = 0;
5305         my $is_combined = ($num_parents > 1);
5306
5307         # Highlight if every removed line has a corresponding added line.
5308         if (@$add > 0 && @$add == @$rem) {
5309                 $can_highlight = 1;
5310
5311                 # Highlight lines in combined diff only if the chunk contains
5312                 # diff between the same version, e.g.
5313                 #
5314                 #    - a
5315                 #   -  b
5316                 #    + c
5317                 #   +  d
5318                 #
5319                 # Otherwise the highlighting would be confusing.
5320                 if ($is_combined) {
5321                         for (my $i = 0; $i < @$add; $i++) {
5322                                 my $prefix_rem = substr($rem->[$i], 0, $num_parents);
5323                                 my $prefix_add = substr($add->[$i], 0, $num_parents);
5324
5325                                 $prefix_rem =~ s/-/+/g;
5326
5327                                 if ($prefix_rem ne $prefix_add) {
5328                                         $can_highlight = 0;
5329                                         last;
5330                                 }
5331                         }
5332                 }
5333         }
5334
5335         if ($can_highlight) {
5336                 for (my $i = 0; $i < @$add; $i++) {
5337                         my ($line_rem, $line_add) = format_rem_add_lines_pair(
5338                                 $rem->[$i], $add->[$i], $num_parents);
5339                         push @new_rem, $line_rem;
5340                         push @new_add, $line_add;
5341                 }
5342         } else {
5343                 @new_rem = map { format_diff_line($_, 'rem') } @$rem;
5344                 @new_add = map { format_diff_line($_, 'add') } @$add;
5345         }
5346
5347         @new_ctx = map { format_diff_line($_, 'ctx') } @$ctx;
5348
5349         return (\@new_ctx, \@new_rem, \@new_add);
5350 }
5351
5352 # Print context lines and then rem/add lines.
5353 sub print_diff_lines {
5354         my ($ctx, $rem, $add, $diff_style, $num_parents) = @_;
5355         my $is_combined = $num_parents > 1;
5356
5357         ($ctx, $rem, $add) = format_ctx_rem_add_lines($ctx, $rem, $add,
5358                 $num_parents);
5359
5360         if ($diff_style eq 'sidebyside' && !$is_combined) {
5361                 print_sidebyside_diff_lines($ctx, $rem, $add);
5362         } else {
5363                 # default 'inline' style and unknown styles
5364                 print_inline_diff_lines($ctx, $rem, $add);
5365         }
5366 }
5367
5368 sub print_diff_chunk {
5369         my ($diff_style, $num_parents, $from, $to, @chunk) = @_;
5370         my (@ctx, @rem, @add);
5371
5372         # The class of the previous line.
5373         my $prev_class = '';
5374
5375         return unless @chunk;
5376
5377         # incomplete last line might be among removed or added lines,
5378         # or both, or among context lines: find which
5379         for (my $i = 1; $i < @chunk; $i++) {
5380                 if ($chunk[$i][0] eq 'incomplete') {
5381                         $chunk[$i][0] = $chunk[$i-1][0];
5382                 }
5383         }
5384
5385         # guardian
5386         push @chunk, ["", ""];
5387
5388         foreach my $line_info (@chunk) {
5389                 my ($class, $line) = @$line_info;
5390
5391                 # print chunk headers
5392                 if ($class && $class eq 'chunk_header') {
5393                         print format_diff_line($line, $class, $from, $to);
5394                         next;
5395                 }
5396
5397                 ## print from accumulator when have some add/rem lines or end
5398                 # of chunk (flush context lines), or when have add and rem
5399                 # lines and new block is reached (otherwise add/rem lines could
5400                 # be reordered)
5401                 if (!$class || ((@rem || @add) && $class eq 'ctx') ||
5402                     (@rem && @add && $class ne $prev_class)) {
5403                         print_diff_lines(\@ctx, \@rem, \@add,
5404                                          $diff_style, $num_parents);
5405                         @ctx = @rem = @add = ();
5406                 }
5407
5408                 ## adding lines to accumulator
5409                 # guardian value
5410                 last unless $line;
5411                 # rem, add or change
5412                 if ($class eq 'rem') {
5413                         push @rem, $line;
5414                 } elsif ($class eq 'add') {
5415                         push @add, $line;
5416                 }
5417                 # context line
5418                 if ($class eq 'ctx') {
5419                         push @ctx, $line;
5420                 }
5421
5422                 $prev_class = $class;
5423         }
5424 }
5425
5426 sub git_patchset_body {
5427         my ($fd, $diff_style, $difftree, $hash, @hash_parents) = @_;
5428         my ($hash_parent) = $hash_parents[0];
5429
5430         my $is_combined = (@hash_parents > 1);
5431         my $patch_idx = 0;
5432         my $patch_number = 0;
5433         my $patch_line;
5434         my $diffinfo;
5435         my $to_name;
5436         my (%from, %to);
5437         my @chunk; # for side-by-side diff
5438
5439         print "<div class=\"patchset\">\n";
5440
5441         # skip to first patch
5442         while ($patch_line = <$fd>) {
5443                 chomp $patch_line;
5444
5445                 last if ($patch_line =~ m/^diff /);
5446         }
5447
5448  PATCH:
5449         while ($patch_line) {
5450
5451                 # parse "git diff" header line
5452                 if ($patch_line =~ m/^diff --git (\"(?:[^\\\"]*(?:\\.[^\\\"]*)*)\"|[^ "]*) (.*)$/) {
5453                         # $1 is from_name, which we do not use
5454                         $to_name = unquote($2);
5455                         $to_name =~ s!^b/!!;
5456                 } elsif ($patch_line =~ m/^diff --(cc|combined) ("?.*"?)$/) {
5457                         # $1 is 'cc' or 'combined', which we do not use
5458                         $to_name = unquote($2);
5459                 } else {
5460                         $to_name = undef;
5461                 }
5462
5463                 # check if current patch belong to current raw line
5464                 # and parse raw git-diff line if needed
5465                 if (is_patch_split($diffinfo, { 'to_file' => $to_name })) {
5466                         # this is continuation of a split patch
5467                         print "<div class=\"patch cont\">\n";
5468                 } else {
5469                         # advance raw git-diff output if needed
5470                         $patch_idx++ if defined $diffinfo;
5471
5472                         # read and prepare patch information
5473                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5474
5475                         # compact combined diff output can have some patches skipped
5476                         # find which patch (using pathname of result) we are at now;
5477                         if ($is_combined) {
5478                                 while ($to_name ne $diffinfo->{'to_file'}) {
5479                                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
5480                                               format_diff_cc_simplified($diffinfo, @hash_parents) .
5481                                               "</div>\n";  # class="patch"
5482
5483                                         $patch_idx++;
5484                                         $patch_number++;
5485
5486                                         last if $patch_idx > $#$difftree;
5487                                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5488                                 }
5489                         }
5490
5491                         # modifies %from, %to hashes
5492                         parse_from_to_diffinfo($diffinfo, \%from, \%to, @hash_parents);
5493
5494                         # this is first patch for raw difftree line with $patch_idx index
5495                         # we index @$difftree array from 0, but number patches from 1
5496                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n";
5497                 }
5498
5499                 # git diff header
5500                 #assert($patch_line =~ m/^diff /) if DEBUG;
5501                 #assert($patch_line !~ m!$/$!) if DEBUG; # is chomp-ed
5502                 $patch_number++;
5503                 # print "git diff" header
5504                 print format_git_diff_header_line($patch_line, $diffinfo,
5505                                                   \%from, \%to);
5506
5507                 # print extended diff header
5508                 print "<div class=\"diff extended_header\">\n";
5509         EXTENDED_HEADER:
5510                 while ($patch_line = <$fd>) {
5511                         chomp $patch_line;
5512
5513                         last EXTENDED_HEADER if ($patch_line =~ m/^--- |^diff /);
5514
5515                         print format_extended_diff_header_line($patch_line, $diffinfo,
5516                                                                \%from, \%to);
5517                 }
5518                 print "</div>\n"; # class="diff extended_header"
5519
5520                 # from-file/to-file diff header
5521                 if (! $patch_line) {
5522                         print "</div>\n"; # class="patch"
5523                         last PATCH;
5524                 }
5525                 next PATCH if ($patch_line =~ m/^diff /);
5526                 #assert($patch_line =~ m/^---/) if DEBUG;
5527
5528                 my $last_patch_line = $patch_line;
5529                 $patch_line = <$fd>;
5530                 chomp $patch_line;
5531                 #assert($patch_line =~ m/^\+\+\+/) if DEBUG;
5532
5533                 print format_diff_from_to_header($last_patch_line, $patch_line,
5534                                                  $diffinfo, \%from, \%to,
5535                                                  @hash_parents);
5536
5537                 # the patch itself
5538         LINE:
5539                 while ($patch_line = <$fd>) {
5540                         chomp $patch_line;
5541
5542                         next PATCH if ($patch_line =~ m/^diff /);
5543
5544                         my $class = diff_line_class($patch_line, \%from, \%to);
5545
5546                         if ($class eq 'chunk_header') {
5547                                 print_diff_chunk($diff_style, scalar @hash_parents, \%from, \%to, @chunk);
5548                                 @chunk = ();
5549                         }
5550
5551                         push @chunk, [ $class, $patch_line ];
5552                 }
5553
5554         } continue {
5555                 if (@chunk) {
5556                         print_diff_chunk($diff_style, scalar @hash_parents, \%from, \%to, @chunk);
5557                         @chunk = ();
5558                 }
5559                 print "</div>\n"; # class="patch"
5560         }
5561
5562         # for compact combined (--cc) format, with chunk and patch simplification
5563         # the patchset might be empty, but there might be unprocessed raw lines
5564         for (++$patch_idx if $patch_number > 0;
5565              $patch_idx < @$difftree;
5566              ++$patch_idx) {
5567                 # read and prepare patch information
5568                 $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
5569
5570                 # generate anchor for "patch" links in difftree / whatchanged part
5571                 print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
5572                       format_diff_cc_simplified($diffinfo, @hash_parents) .
5573                       "</div>\n";  # class="patch"
5574
5575                 $patch_number++;
5576         }
5577
5578         if ($patch_number == 0) {
5579                 if (@hash_parents > 1) {
5580                         print "<div class=\"diff nodifferences\">Trivial merge</div>\n";
5581                 } else {
5582                         print "<div class=\"diff nodifferences\">No differences found</div>\n";
5583                 }
5584         }
5585
5586         print "</div>\n"; # class="patchset"
5587 }
5588
5589 # . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
5590
5591 sub git_project_search_form {
5592         my ($searchtext, $search_use_regexp) = @_;
5593
5594         my $limit = '';
5595         if ($project_filter) {
5596                 $limit = " in '$project_filter/'";
5597         }
5598
5599         print "<div class=\"projsearch\">\n";
5600         print $cgi->start_form(-method => 'get', -action => $my_uri) .
5601               $cgi->hidden(-name => 'a', -value => 'project_list')  . "\n";
5602         print $cgi->hidden(-name => 'pf', -value => $project_filter). "\n"
5603                 if (defined $project_filter);
5604         print $cgi->textfield(-name => 's', -value => $searchtext,
5605                               -title => "Search project by name and description$limit",
5606                               -size => 60) . "\n" .
5607               "<span title=\"Extended regular expression\">" .
5608               $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
5609                              -checked => $search_use_regexp) .
5610               "</span>\n" .
5611               $cgi->submit(-name => 'btnS', -value => 'Search') .
5612               $cgi->end_form() . "\n" .
5613               $cgi->a({-href => href(project => undef, searchtext => undef,
5614                                      project_filter => $project_filter)},
5615                       esc_html("List all projects$limit")) . "<br />\n";
5616         print "</div>\n";
5617 }
5618
5619 # entry for given @keys needs filling if at least one of keys in list
5620 # is not present in %$project_info
5621 sub project_info_needs_filling {
5622         my ($project_info, @keys) = @_;
5623
5624         # return List::MoreUtils::any { !exists $project_info->{$_} } @keys;
5625         foreach my $key (@keys) {
5626                 if (!exists $project_info->{$key}) {
5627                         return 1;
5628                 }
5629         }
5630         return;
5631 }
5632
5633 # fills project list info (age, description, owner, category, forks, etc.)
5634 # for each project in the list, removing invalid projects from
5635 # returned list, or fill only specified info.
5636 #
5637 # Invalid projects are removed from the returned list if and only if you
5638 # ask 'age' or 'age_string' to be filled, because they are the only fields
5639 # that run unconditionally git command that requires repository, and
5640 # therefore do always check if project repository is invalid.
5641 #
5642 # USAGE:
5643 # * fill_project_list_info(\@project_list, 'descr_long', 'ctags')
5644 #   ensures that 'descr_long' and 'ctags' fields are filled
5645 # * @project_list = fill_project_list_info(\@project_list)
5646 #   ensures that all fields are filled (and invalid projects removed)
5647 #
5648 # NOTE: modifies $projlist, but does not remove entries from it
5649 sub fill_project_list_info {
5650         my ($projlist, @wanted_keys) = @_;
5651         my @projects;
5652         my $filter_set = sub { return @_; };
5653         if (@wanted_keys) {
5654                 my %wanted_keys = map { $_ => 1 } @wanted_keys;
5655                 $filter_set = sub { return grep { $wanted_keys{$_} } @_; };
5656         }
5657
5658         my $show_ctags = gitweb_check_feature('ctags');
5659  PROJECT:
5660         foreach my $pr (@$projlist) {
5661                 if (project_info_needs_filling($pr, $filter_set->('age', 'age_string'))) {
5662                         my (@activity) = git_get_last_activity($pr->{'path'});
5663                         unless (@activity) {
5664                                 next PROJECT;
5665                         }
5666                         ($pr->{'age'}, $pr->{'age_string'}) = @activity;
5667                 }
5668                 if (project_info_needs_filling($pr, $filter_set->('descr', 'descr_long'))) {
5669                         my $descr = git_get_project_description($pr->{'path'}) || "";
5670                         $descr = to_utf8($descr);
5671                         $pr->{'descr_long'} = $descr;
5672                         $pr->{'descr'} = chop_str($descr, $projects_list_description_width, 5);
5673                 }
5674                 if (project_info_needs_filling($pr, $filter_set->('owner'))) {
5675                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}") || "";
5676                 }
5677                 if ($show_ctags &&
5678                     project_info_needs_filling($pr, $filter_set->('ctags'))) {
5679                         $pr->{'ctags'} = git_get_project_ctags($pr->{'path'});
5680                 }
5681                 if ($projects_list_group_categories &&
5682                     project_info_needs_filling($pr, $filter_set->('category'))) {
5683                         my $cat = git_get_project_category($pr->{'path'}) ||
5684                                                            $project_list_default_category;
5685                         $pr->{'category'} = to_utf8($cat);
5686                 }
5687
5688                 push @projects, $pr;
5689         }
5690
5691         return @projects;
5692 }
5693
5694 sub sort_projects_list {
5695         my ($projlist, $order) = @_;
5696
5697         sub order_str {
5698                 my $key = shift;
5699                 return sub { $a->{$key} cmp $b->{$key} };
5700         }
5701
5702         sub order_num_then_undef {
5703                 my $key = shift;
5704                 return sub {
5705                         defined $a->{$key} ?
5706                                 (defined $b->{$key} ? $a->{$key} <=> $b->{$key} : -1) :
5707                                 (defined $b->{$key} ? 1 : 0)
5708                 };
5709         }
5710
5711         my %orderings = (
5712                 project => order_str('path'),
5713                 descr => order_str('descr_long'),
5714                 owner => order_str('owner'),
5715                 age => order_num_then_undef('age'),
5716         );
5717
5718         my $ordering = $orderings{$order};
5719         return defined $ordering ? sort $ordering @$projlist : @$projlist;
5720 }
5721
5722 # returns a hash of categories, containing the list of project
5723 # belonging to each category
5724 sub build_projlist_by_category {
5725         my ($projlist, $from, $to) = @_;
5726         my %categories;
5727
5728         $from = 0 unless defined $from;
5729         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5730
5731         for (my $i = $from; $i <= $to; $i++) {
5732                 my $pr = $projlist->[$i];
5733                 push @{$categories{ $pr->{'category'} }}, $pr;
5734         }
5735
5736         return wantarray ? %categories : \%categories;
5737 }
5738
5739 # print 'sort by' <th> element, generating 'sort by $name' replay link
5740 # if that order is not selected
5741 sub print_sort_th {
5742         print format_sort_th(@_);
5743 }
5744
5745 sub format_sort_th {
5746         my ($name, $order, $header) = @_;
5747         my $sort_th = "";
5748         $header ||= ucfirst($name);
5749
5750         if ($order eq $name) {
5751                 $sort_th .= "<th>$header</th>\n";
5752         } else {
5753                 $sort_th .= "<th>" .
5754                             $cgi->a({-href => href(-replay=>1, order=>$name),
5755                                      -class => "header"}, $header) .
5756                             "</th>\n";
5757         }
5758
5759         return $sort_th;
5760 }
5761
5762 sub git_project_list_rows {
5763         my ($projlist, $from, $to, $check_forks) = @_;
5764
5765         $from = 0 unless defined $from;
5766         $to = $#$projlist if (!defined $to || $#$projlist < $to);
5767
5768         my $alternate = 1;
5769         for (my $i = $from; $i <= $to; $i++) {
5770                 my $pr = $projlist->[$i];
5771
5772                 if ($alternate) {
5773                         print "<tr class=\"dark\">\n";
5774                 } else {
5775                         print "<tr class=\"light\">\n";
5776                 }
5777                 $alternate ^= 1;
5778
5779                 if ($check_forks) {
5780                         print "<td>";
5781                         if ($pr->{'forks'}) {
5782                                 my $nforks = scalar @{$pr->{'forks'}};
5783                                 if ($nforks > 0) {
5784                                         print $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks"),
5785                                                        -title => "$nforks forks"}, "+");
5786                                 } else {
5787                                         print $cgi->span({-title => "$nforks forks"}, "+");
5788                                 }
5789                         }
5790                         print "</td>\n";
5791                 }
5792                 print "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5793                                         -class => "list"},
5794                                        esc_html_match_hl($pr->{'path'}, $search_regexp)) .
5795                       "</td>\n" .
5796                       "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
5797                                         -class => "list",
5798                                         -title => $pr->{'descr_long'}},
5799                                         $search_regexp
5800                                         ? esc_html_match_hl_chopped($pr->{'descr_long'},
5801                                                                     $pr->{'descr'}, $search_regexp)
5802                                         : esc_html($pr->{'descr'})) .
5803                       "</td>\n";
5804                 unless ($omit_owner) {
5805                         print "<td><i>" . chop_and_escape_str($pr->{'owner'}, 15) . "</i></td>\n";
5806                 }
5807                 unless ($omit_age_column) {
5808                         print "<td class=\"". age_class($pr->{'age'}) . "\">" .
5809                             (defined $pr->{'age_string'} ? $pr->{'age_string'} : "No commits") . "</td>\n";
5810                 }
5811                 print"<td class=\"link\">" .
5812                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary")}, "summary")   . " | " .
5813                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"shortlog")}, "shortlog") . " | " .
5814                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"log")}, "log") . " | " .
5815                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"tree")}, "tree") .
5816                       ($pr->{'forks'} ? " | " . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "forks") : '') .
5817                       "</td>\n" .
5818                       "</tr>\n";
5819         }
5820 }
5821
5822 sub git_project_list_body {
5823         # actually uses global variable $project
5824         my ($projlist, $order, $from, $to, $extra, $no_header) = @_;
5825         my @projects = @$projlist;
5826
5827         my $check_forks = gitweb_check_feature('forks');
5828         my $show_ctags  = gitweb_check_feature('ctags');
5829         my $tagfilter = $show_ctags ? $input_params{'ctag'} : undef;
5830         $check_forks = undef
5831                 if ($tagfilter || $search_regexp);
5832
5833         # filtering out forks before filling info allows to do less work
5834         @projects = filter_forks_from_projects_list(\@projects)
5835                 if ($check_forks);
5836         # search_projects_list pre-fills required info
5837         @projects = search_projects_list(\@projects,
5838                                          'search_regexp' => $search_regexp,
5839                                          'tagfilter'  => $tagfilter)
5840                 if ($tagfilter || $search_regexp);
5841         # fill the rest
5842         my @all_fields = ('descr', 'descr_long', 'ctags', 'category');
5843         push @all_fields, ('age', 'age_string') unless($omit_age_column);
5844         push @all_fields, 'owner' unless($omit_owner);
5845         @projects = fill_project_list_info(\@projects, @all_fields);
5846
5847         $order ||= $default_projects_order;
5848         $from = 0 unless defined $from;
5849         $to = $#projects if (!defined $to || $#projects < $to);
5850
5851         # short circuit
5852         if ($from > $to) {
5853                 print "<center>\n".
5854                       "<b>No such projects found</b><br />\n".
5855                       "Click ".$cgi->a({-href=>href(project=>undef)},"here")." to view all projects<br />\n".
5856                       "</center>\n<br />\n";
5857                 return;
5858         }
5859
5860         @projects = sort_projects_list(\@projects, $order);
5861
5862         if ($show_ctags) {
5863                 my $ctags = git_gather_all_ctags(\@projects);
5864                 my $cloud = git_populate_project_tagcloud($ctags);
5865                 print git_show_project_tagcloud($cloud, 64);
5866         }
5867
5868         print "<table class=\"project_list\">\n";
5869         unless ($no_header) {
5870                 print "<tr>\n";
5871                 if ($check_forks) {
5872                         print "<th></th>\n";
5873                 }
5874                 print_sort_th('project', $order, 'Project');
5875                 print_sort_th('descr', $order, 'Description');
5876                 print_sort_th('owner', $order, 'Owner') unless $omit_owner;
5877                 print_sort_th('age', $order, 'Last Change') unless $omit_age_column;
5878                 print "<th></th>\n" . # for links
5879                       "</tr>\n";
5880         }
5881
5882         if ($projects_list_group_categories) {
5883                 # only display categories with projects in the $from-$to window
5884                 @projects = sort {$a->{'category'} cmp $b->{'category'}} @projects[$from..$to];
5885                 my %categories = build_projlist_by_category(\@projects, $from, $to);
5886                 foreach my $cat (sort keys %categories) {
5887                         unless ($cat eq "") {
5888                                 print "<tr>\n";
5889                                 if ($check_forks) {
5890                                         print "<td></td>\n";
5891                                 }
5892                                 print "<td class=\"category\" colspan=\"5\">".esc_html($cat)."</td>\n";
5893                                 print "</tr>\n";
5894                         }
5895
5896                         git_project_list_rows($categories{$cat}, undef, undef, $check_forks);
5897                 }
5898         } else {
5899                 git_project_list_rows(\@projects, $from, $to, $check_forks);
5900         }
5901
5902         if (defined $extra) {
5903                 print "<tr>\n";
5904                 if ($check_forks) {
5905                         print "<td></td>\n";
5906                 }
5907                 print "<td colspan=\"5\">$extra</td>\n" .
5908                       "</tr>\n";
5909         }
5910         print "</table>\n";
5911 }
5912
5913 sub git_log_body {
5914         # uses global variable $project
5915         my ($commitlist, $from, $to, $refs, $extra) = @_;
5916
5917         $from = 0 unless defined $from;
5918         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5919
5920         for (my $i = 0; $i <= $to; $i++) {
5921                 my %co = %{$commitlist->[$i]};
5922                 next if !%co;
5923                 my $commit = $co{'id'};
5924                 my $ref = format_ref_marker($refs, $commit);
5925                 git_print_header_div('commit',
5926                                "<span class=\"age\">$co{'age_string'}</span>" .
5927                                esc_html($co{'title'}) . $ref,
5928                                $commit);
5929                 print "<div class=\"title_text\">\n" .
5930                       "<div class=\"log_link\">\n" .
5931                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") .
5932                       " | " .
5933                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") .
5934                       " | " .
5935                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree") .
5936                       "<br/>\n" .
5937                       "</div>\n";
5938                       git_print_authorship(\%co, -tag => 'span');
5939                       print "<br/>\n</div>\n";
5940
5941                 print "<div class=\"log_body\">\n";
5942                 git_print_log($co{'comment'}, -final_empty_line=> 1);
5943                 print "</div>\n";
5944         }
5945         if ($extra) {
5946                 print "<div class=\"page_nav\">\n";
5947                 print "$extra\n";
5948                 print "</div>\n";
5949         }
5950 }
5951
5952 sub git_shortlog_body {
5953         # uses global variable $project
5954         my ($commitlist, $from, $to, $refs, $extra) = @_;
5955
5956         $from = 0 unless defined $from;
5957         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
5958
5959         print "<table class=\"shortlog\">\n";
5960         my $alternate = 1;
5961         for (my $i = $from; $i <= $to; $i++) {
5962                 my %co = %{$commitlist->[$i]};
5963                 my $commit = $co{'id'};
5964                 my $ref = format_ref_marker($refs, $commit);
5965                 if ($alternate) {
5966                         print "<tr class=\"dark\">\n";
5967                 } else {
5968                         print "<tr class=\"light\">\n";
5969                 }
5970                 $alternate ^= 1;
5971                 # git_summary() used print "<td><i>$co{'age_string'}</i></td>\n" .
5972                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
5973                       format_author_html('td', \%co, 10) . "<td>";
5974                 print format_subject_html($co{'title'}, $co{'title_short'},
5975                                           href(action=>"commit", hash=>$commit), $ref);
5976                 print "</td>\n" .
5977                       "<td class=\"link\">" .
5978                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") . " | " .
5979                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") . " | " .
5980                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree");
5981                 my $snapshot_links = format_snapshot_links($commit);
5982                 if (defined $snapshot_links) {
5983                         print " | " . $snapshot_links;
5984                 }
5985                 print "</td>\n" .
5986                       "</tr>\n";
5987         }
5988         if (defined $extra) {
5989                 print "<tr>\n" .
5990                       "<td colspan=\"4\">$extra</td>\n" .
5991                       "</tr>\n";
5992         }
5993         print "</table>\n";
5994 }
5995
5996 sub git_history_body {
5997         # Warning: assumes constant type (blob or tree) during history
5998         my ($commitlist, $from, $to, $refs, $extra,
5999             $file_name, $file_hash, $ftype) = @_;
6000
6001         $from = 0 unless defined $from;
6002         $to = $#{$commitlist} unless (defined $to && $to <= $#{$commitlist});
6003
6004         print "<table class=\"history\">\n";
6005         my $alternate = 1;
6006         for (my $i = $from; $i <= $to; $i++) {
6007                 my %co = %{$commitlist->[$i]};
6008                 if (!%co) {
6009                         next;
6010                 }
6011                 my $commit = $co{'id'};
6012
6013                 my $ref = format_ref_marker($refs, $commit);
6014
6015                 if ($alternate) {
6016                         print "<tr class=\"dark\">\n";
6017                 } else {
6018                         print "<tr class=\"light\">\n";
6019                 }
6020                 $alternate ^= 1;
6021                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6022         # shortlog:   format_author_html('td', \%co, 10)
6023                       format_author_html('td', \%co, 15, 3) . "<td>";
6024                 # originally git_history used chop_str($co{'title'}, 50)
6025                 print format_subject_html($co{'title'}, $co{'title_short'},
6026                                           href(action=>"commit", hash=>$commit), $ref);
6027                 print "</td>\n" .
6028                       "<td class=\"link\">" .
6029                       $cgi->a({-href => href(action=>$ftype, hash_base=>$commit, file_name=>$file_name)}, $ftype) . " | " .
6030                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff");
6031
6032                 if ($ftype eq 'blob') {
6033                         print " | " .
6034                               $cgi->a({-href => href(action=>"blob_plain", hash_base=>$commit, file_name=>$file_name)}, "raw");
6035
6036                         my $blob_current = $file_hash;
6037                         my $blob_parent  = git_get_hash_by_path($commit, $file_name);
6038                         if (defined $blob_current && defined $blob_parent &&
6039                                         $blob_current ne $blob_parent) {
6040                                 print " | " .
6041                                         $cgi->a({-href => href(action=>"blobdiff",
6042                                                                hash=>$blob_current, hash_parent=>$blob_parent,
6043                                                                hash_base=>$hash_base, hash_parent_base=>$commit,
6044                                                                file_name=>$file_name)},
6045                                                 "diff to current");
6046                         }
6047                 }
6048                 print "</td>\n" .
6049                       "</tr>\n";
6050         }
6051         if (defined $extra) {
6052                 print "<tr>\n" .
6053                       "<td colspan=\"4\">$extra</td>\n" .
6054                       "</tr>\n";
6055         }
6056         print "</table>\n";
6057 }
6058
6059 sub git_tags_body {
6060         # uses global variable $project
6061         my ($taglist, $from, $to, $extra) = @_;
6062         $from = 0 unless defined $from;
6063         $to = $#{$taglist} if (!defined $to || $#{$taglist} < $to);
6064
6065         print "<table class=\"tags\">\n";
6066         my $alternate = 1;
6067         for (my $i = $from; $i <= $to; $i++) {
6068                 my $entry = $taglist->[$i];
6069                 my %tag = %$entry;
6070                 my $comment = $tag{'subject'};
6071                 my $comment_short;
6072                 if (defined $comment) {
6073                         $comment_short = chop_str($comment, 30, 5);
6074                 }
6075                 if ($alternate) {
6076                         print "<tr class=\"dark\">\n";
6077                 } else {
6078                         print "<tr class=\"light\">\n";
6079                 }
6080                 $alternate ^= 1;
6081                 if (defined $tag{'age'}) {
6082                         print "<td><i>$tag{'age'}</i></td>\n";
6083                 } else {
6084                         print "<td></td>\n";
6085                 }
6086                 print "<td>" .
6087                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'}),
6088                                -class => "list name"}, esc_html($tag{'name'})) .
6089                       "</td>\n" .
6090                       "<td>";
6091                 if (defined $comment) {
6092                         print format_subject_html($comment, $comment_short,
6093                                                   href(action=>"tag", hash=>$tag{'id'}));
6094                 }
6095                 print "</td>\n" .
6096                       "<td class=\"selflink\">";
6097                 if ($tag{'type'} eq "tag") {
6098                         print $cgi->a({-href => href(action=>"tag", hash=>$tag{'id'})}, "tag");
6099                 } else {
6100                         print "&nbsp;";
6101                 }
6102                 print "</td>\n" .
6103                       "<td class=\"link\">" . " | " .
6104                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'})}, $tag{'reftype'});
6105                 if ($tag{'reftype'} eq "commit") {
6106                         print " | " . $cgi->a({-href => href(action=>"shortlog", hash=>$tag{'fullname'})}, "shortlog") .
6107                               " | " . $cgi->a({-href => href(action=>"log", hash=>$tag{'fullname'})}, "log");
6108                 } elsif ($tag{'reftype'} eq "blob") {
6109                         print " | " . $cgi->a({-href => href(action=>"blob_plain", hash=>$tag{'refid'})}, "raw");
6110                 }
6111                 print "</td>\n" .
6112                       "</tr>";
6113         }
6114         if (defined $extra) {
6115                 print "<tr>\n" .
6116                       "<td colspan=\"5\">$extra</td>\n" .
6117                       "</tr>\n";
6118         }
6119         print "</table>\n";
6120 }
6121
6122 sub git_heads_body {
6123         # uses global variable $project
6124         my ($headlist, $head_at, $from, $to, $extra) = @_;
6125         $from = 0 unless defined $from;
6126         $to = $#{$headlist} if (!defined $to || $#{$headlist} < $to);
6127
6128         print "<table class=\"heads\">\n";
6129         my $alternate = 1;
6130         for (my $i = $from; $i <= $to; $i++) {
6131                 my $entry = $headlist->[$i];
6132                 my %ref = %$entry;
6133                 my $curr = defined $head_at && $ref{'id'} eq $head_at;
6134                 if ($alternate) {
6135                         print "<tr class=\"dark\">\n";
6136                 } else {
6137                         print "<tr class=\"light\">\n";
6138                 }
6139                 $alternate ^= 1;
6140                 print "<td><i>$ref{'age'}</i></td>\n" .
6141                       ($curr ? "<td class=\"current_head\">" : "<td>") .
6142                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'}),
6143                                -class => "list name"},esc_html($ref{'name'})) .
6144                       "</td>\n" .
6145                       "<td class=\"link\">" .
6146                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'})}, "shortlog") . " | " .
6147                       $cgi->a({-href => href(action=>"log", hash=>$ref{'fullname'})}, "log") . " | " .
6148                       $cgi->a({-href => href(action=>"tree", hash=>$ref{'fullname'}, hash_base=>$ref{'fullname'})}, "tree") .
6149                       "</td>\n" .
6150                       "</tr>";
6151         }
6152         if (defined $extra) {
6153                 print "<tr>\n" .
6154                       "<td colspan=\"3\">$extra</td>\n" .
6155                       "</tr>\n";
6156         }
6157         print "</table>\n";
6158 }
6159
6160 # Display a single remote block
6161 sub git_remote_block {
6162         my ($remote, $rdata, $limit, $head) = @_;
6163
6164         my $heads = $rdata->{'heads'};
6165         my $fetch = $rdata->{'fetch'};
6166         my $push = $rdata->{'push'};
6167
6168         my $urls_table = "<table class=\"projects_list\">\n" ;
6169
6170         if (defined $fetch) {
6171                 if ($fetch eq $push) {
6172                         $urls_table .= format_repo_url("URL", $fetch);
6173                 } else {
6174                         $urls_table .= format_repo_url("Fetch URL", $fetch);
6175                         $urls_table .= format_repo_url("Push URL", $push) if defined $push;
6176                 }
6177         } elsif (defined $push) {
6178                 $urls_table .= format_repo_url("Push URL", $push);
6179         } else {
6180                 $urls_table .= format_repo_url("", "No remote URL");
6181         }
6182
6183         $urls_table .= "</table>\n";
6184
6185         my $dots;
6186         if (defined $limit && $limit < @$heads) {
6187                 $dots = $cgi->a({-href => href(action=>"remotes", hash=>$remote)}, "...");
6188         }
6189
6190         print $urls_table;
6191         git_heads_body($heads, $head, 0, $limit, $dots);
6192 }
6193
6194 # Display a list of remote names with the respective fetch and push URLs
6195 sub git_remotes_list {
6196         my ($remotedata, $limit) = @_;
6197         print "<table class=\"heads\">\n";
6198         my $alternate = 1;
6199         my @remotes = sort keys %$remotedata;
6200
6201         my $limited = $limit && $limit < @remotes;
6202
6203         $#remotes = $limit - 1 if $limited;
6204
6205         while (my $remote = shift @remotes) {
6206                 my $rdata = $remotedata->{$remote};
6207                 my $fetch = $rdata->{'fetch'};
6208                 my $push = $rdata->{'push'};
6209                 if ($alternate) {
6210                         print "<tr class=\"dark\">\n";
6211                 } else {
6212                         print "<tr class=\"light\">\n";
6213                 }
6214                 $alternate ^= 1;
6215                 print "<td>" .
6216                       $cgi->a({-href=> href(action=>'remotes', hash=>$remote),
6217                                -class=> "list name"},esc_html($remote)) .
6218                       "</td>";
6219                 print "<td class=\"link\">" .
6220                       (defined $fetch ? $cgi->a({-href=> $fetch}, "fetch") : "fetch") .
6221                       " | " .
6222                       (defined $push ? $cgi->a({-href=> $push}, "push") : "push") .
6223                       "</td>";
6224
6225                 print "</tr>\n";
6226         }
6227
6228         if ($limited) {
6229                 print "<tr>\n" .
6230                       "<td colspan=\"3\">" .
6231                       $cgi->a({-href => href(action=>"remotes")}, "...") .
6232                       "</td>\n" . "</tr>\n";
6233         }
6234
6235         print "</table>";
6236 }
6237
6238 # Display remote heads grouped by remote, unless there are too many
6239 # remotes, in which case we only display the remote names
6240 sub git_remotes_body {
6241         my ($remotedata, $limit, $head) = @_;
6242         if ($limit and $limit < keys %$remotedata) {
6243                 git_remotes_list($remotedata, $limit);
6244         } else {
6245                 fill_remote_heads($remotedata);
6246                 while (my ($remote, $rdata) = each %$remotedata) {
6247                         git_print_section({-class=>"remote", -id=>$remote},
6248                                 ["remotes", $remote, $remote], sub {
6249                                         git_remote_block($remote, $rdata, $limit, $head);
6250                                 });
6251                 }
6252         }
6253 }
6254
6255 sub git_search_message {
6256         my %co = @_;
6257
6258         my $greptype;
6259         if ($searchtype eq 'commit') {
6260                 $greptype = "--grep=";
6261         } elsif ($searchtype eq 'author') {
6262                 $greptype = "--author=";
6263         } elsif ($searchtype eq 'committer') {
6264                 $greptype = "--committer=";
6265         }
6266         $greptype .= $searchtext;
6267         my @commitlist = parse_commits($hash, 101, (100 * $page), undef,
6268                                        $greptype, '--regexp-ignore-case',
6269                                        $search_use_regexp ? '--extended-regexp' : '--fixed-strings');
6270
6271         my $paging_nav = '';
6272         if ($page > 0) {
6273                 $paging_nav .=
6274                         $cgi->a({-href => href(-replay=>1, page=>undef)},
6275                                 "first") .
6276                         " &sdot; " .
6277                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
6278                                  -accesskey => "p", -title => "Alt-p"}, "prev");
6279         } else {
6280                 $paging_nav .= "first &sdot; prev";
6281         }
6282         my $next_link = '';
6283         if ($#commitlist >= 100) {
6284                 $next_link =
6285                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
6286                                  -accesskey => "n", -title => "Alt-n"}, "next");
6287                 $paging_nav .= " &sdot; $next_link";
6288         } else {
6289                 $paging_nav .= " &sdot; next";
6290         }
6291
6292         git_header_html();
6293
6294         git_print_page_nav('','', $hash,$co{'tree'},$hash, $paging_nav);
6295         git_print_header_div('commit', esc_html($co{'title'}), $hash);
6296         if ($page == 0 && !@commitlist) {
6297                 print "<p>No match.</p>\n";
6298         } else {
6299                 git_search_grep_body(\@commitlist, 0, 99, $next_link);
6300         }
6301
6302         git_footer_html();
6303 }
6304
6305 sub git_search_changes {
6306         my %co = @_;
6307
6308         local $/ = "\n";
6309         open my $fd, '-|', git_cmd(), '--no-pager', 'log', @diff_opts,
6310                 '--pretty=format:%H', '--no-abbrev', '--raw', "-S$searchtext",
6311                 ($search_use_regexp ? '--pickaxe-regex' : ())
6312                         or die_error(500, "Open git-log failed");
6313
6314         git_header_html();
6315
6316         git_print_page_nav('','', $hash,$co{'tree'},$hash);
6317         git_print_header_div('commit', esc_html($co{'title'}), $hash);
6318
6319         print "<table class=\"pickaxe search\">\n";
6320         my $alternate = 1;
6321         undef %co;
6322         my @files;
6323         while (my $line = <$fd>) {
6324                 chomp $line;
6325                 next unless $line;
6326
6327                 my %set = parse_difftree_raw_line($line);
6328                 if (defined $set{'commit'}) {
6329                         # finish previous commit
6330                         if (%co) {
6331                                 print "</td>\n" .
6332                                       "<td class=\"link\">" .
6333                                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
6334                                               "commit") .
6335                                       " | " .
6336                                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
6337                                                              hash_base=>$co{'id'})},
6338                                               "tree") .
6339                                       "</td>\n" .
6340                                       "</tr>\n";
6341                         }
6342
6343                         if ($alternate) {
6344                                 print "<tr class=\"dark\">\n";
6345                         } else {
6346                                 print "<tr class=\"light\">\n";
6347                         }
6348                         $alternate ^= 1;
6349                         %co = parse_commit($set{'commit'});
6350                         my $author = chop_and_escape_str($co{'author_name'}, 15, 5);
6351                         print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6352                               "<td><i>$author</i></td>\n" .
6353                               "<td>" .
6354                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
6355                                       -class => "list subject"},
6356                                       chop_and_escape_str($co{'title'}, 50) . "<br/>");
6357                 } elsif (defined $set{'to_id'}) {
6358                         next if is_deleted(\%set);
6359
6360                         print $cgi->a({-href => href(action=>"blob", hash_base=>$co{'id'},
6361                                                      hash=>$set{'to_id'}, file_name=>$set{'to_file'}),
6362                                       -class => "list"},
6363                                       "<span class=\"match\">" . esc_path($set{'file'}) . "</span>") .
6364                               "<br/>\n";
6365                 }
6366         }
6367         close $fd;
6368
6369         # finish last commit (warning: repetition!)
6370         if (%co) {
6371                 print "</td>\n" .
6372                       "<td class=\"link\">" .
6373                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})},
6374                               "commit") .
6375                       " | " .
6376                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'},
6377                                              hash_base=>$co{'id'})},
6378                               "tree") .
6379                       "</td>\n" .
6380                       "</tr>\n";
6381         }
6382
6383         print "</table>\n";
6384
6385         git_footer_html();
6386 }
6387
6388 sub git_search_files {
6389         my %co = @_;
6390
6391         local $/ = "\n";
6392         open my $fd, "-|", git_cmd(), 'grep', '-n', '-z',
6393                 $search_use_regexp ? ('-E', '-i') : '-F',
6394                 $searchtext, $co{'tree'}
6395                         or die_error(500, "Open git-grep failed");
6396
6397         git_header_html();
6398
6399         git_print_page_nav('','', $hash,$co{'tree'},$hash);
6400         git_print_header_div('commit', esc_html($co{'title'}), $hash);
6401
6402         print "<table class=\"grep_search\">\n";
6403         my $alternate = 1;
6404         my $matches = 0;
6405         my $lastfile = '';
6406         my $file_href;
6407         while (my $line = <$fd>) {
6408                 chomp $line;
6409                 my ($file, $lno, $ltext, $binary);
6410                 last if ($matches++ > 1000);
6411                 if ($line =~ /^Binary file (.+) matches$/) {
6412                         $file = $1;
6413                         $binary = 1;
6414                 } else {
6415                         ($file, $lno, $ltext) = split(/\0/, $line, 3);
6416                         $file =~ s/^$co{'tree'}://;
6417                 }
6418                 if ($file ne $lastfile) {
6419                         $lastfile and print "</td></tr>\n";
6420                         if ($alternate++) {
6421                                 print "<tr class=\"dark\">\n";
6422                         } else {
6423                                 print "<tr class=\"light\">\n";
6424                         }
6425                         $file_href = href(action=>"blob", hash_base=>$co{'id'},
6426                                           file_name=>$file);
6427                         print "<td class=\"list\">".
6428                                 $cgi->a({-href => $file_href, -class => "list"}, esc_path($file));
6429                         print "</td><td>\n";
6430                         $lastfile = $file;
6431                 }
6432                 if ($binary) {
6433                         print "<div class=\"binary\">Binary file</div>\n";
6434                 } else {
6435                         $ltext = untabify($ltext);
6436                         if ($ltext =~ m/^(.*)($search_regexp)(.*)$/i) {
6437                                 $ltext = esc_html($1, -nbsp=>1);
6438                                 $ltext .= '<span class="match">';
6439                                 $ltext .= esc_html($2, -nbsp=>1);
6440                                 $ltext .= '</span>';
6441                                 $ltext .= esc_html($3, -nbsp=>1);
6442                         } else {
6443                                 $ltext = esc_html($ltext, -nbsp=>1);
6444                         }
6445                         print "<div class=\"pre\">" .
6446                                 $cgi->a({-href => $file_href.'#l'.$lno,
6447                                         -class => "linenr"}, sprintf('%4i', $lno)) .
6448                                 ' ' .  $ltext . "</div>\n";
6449                 }
6450         }
6451         if ($lastfile) {
6452                 print "</td></tr>\n";
6453                 if ($matches > 1000) {
6454                         print "<div class=\"diff nodifferences\">Too many matches, listing trimmed</div>\n";
6455                 }
6456         } else {
6457                 print "<div class=\"diff nodifferences\">No matches found</div>\n";
6458         }
6459         close $fd;
6460
6461         print "</table>\n";
6462
6463         git_footer_html();
6464 }
6465
6466 sub git_search_grep_body {
6467         my ($commitlist, $from, $to, $extra) = @_;
6468         $from = 0 unless defined $from;
6469         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
6470
6471         print "<table class=\"commit_search\">\n";
6472         my $alternate = 1;
6473         for (my $i = $from; $i <= $to; $i++) {
6474                 my %co = %{$commitlist->[$i]};
6475                 if (!%co) {
6476                         next;
6477                 }
6478                 my $commit = $co{'id'};
6479                 if ($alternate) {
6480                         print "<tr class=\"dark\">\n";
6481                 } else {
6482                         print "<tr class=\"light\">\n";
6483                 }
6484                 $alternate ^= 1;
6485                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6486                       format_author_html('td', \%co, 15, 5) .
6487                       "<td>" .
6488                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
6489                                -class => "list subject"},
6490                               chop_and_escape_str($co{'title'}, 50) . "<br/>");
6491                 my $comment = $co{'comment'};
6492                 foreach my $line (@$comment) {
6493                         if ($line =~ m/^(.*?)($search_regexp)(.*)$/i) {
6494                                 my ($lead, $match, $trail) = ($1, $2, $3);
6495                                 $match = chop_str($match, 70, 5, 'center');
6496                                 my $contextlen = int((80 - length($match))/2);
6497                                 $contextlen = 30 if ($contextlen > 30);
6498                                 $lead  = chop_str($lead,  $contextlen, 10, 'left');
6499                                 $trail = chop_str($trail, $contextlen, 10, 'right');
6500
6501                                 $lead  = esc_html($lead);
6502                                 $match = esc_html($match);
6503                                 $trail = esc_html($trail);
6504
6505                                 print "$lead<span class=\"match\">$match</span>$trail<br />";
6506                         }
6507                 }
6508                 print "</td>\n" .
6509                       "<td class=\"link\">" .
6510                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
6511                       " | " .
6512                       $cgi->a({-href => href(action=>"commitdiff", hash=>$co{'id'})}, "commitdiff") .
6513                       " | " .
6514                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
6515                 print "</td>\n" .
6516                       "</tr>\n";
6517         }
6518         if (defined $extra) {
6519                 print "<tr>\n" .
6520                       "<td colspan=\"3\">$extra</td>\n" .
6521                       "</tr>\n";
6522         }
6523         print "</table>\n";
6524 }
6525
6526 ## ======================================================================
6527 ## ======================================================================
6528 ## actions
6529
6530 sub git_project_list {
6531         my $order = $input_params{'order'};
6532         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
6533                 die_error(400, "Unknown order parameter");
6534         }
6535
6536         my @list = git_get_projects_list($project_filter, $strict_export);
6537         if (!@list) {
6538                 die_error(404, "No projects found");
6539         }
6540
6541         git_header_html();
6542         if (defined $home_text && -f $home_text) {
6543                 print "<div class=\"index_include\">\n";
6544                 insert_file($home_text);
6545                 print "</div>\n";
6546         }
6547
6548         git_project_search_form($searchtext, $search_use_regexp);
6549         git_project_list_body(\@list, $order);
6550         git_footer_html();
6551 }
6552
6553 sub git_forks {
6554         my $order = $input_params{'order'};
6555         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
6556                 die_error(400, "Unknown order parameter");
6557         }
6558
6559         my $filter = $project;
6560         $filter =~ s/\.git$//;
6561         my @list = git_get_projects_list($filter);
6562         if (!@list) {
6563                 die_error(404, "No forks found");
6564         }
6565
6566         git_header_html();
6567         git_print_page_nav('','');
6568         git_print_header_div('summary', "$project forks");
6569         git_project_list_body(\@list, $order);
6570         git_footer_html();
6571 }
6572
6573 sub git_project_index {
6574         my @projects = git_get_projects_list($project_filter, $strict_export);
6575         if (!@projects) {
6576                 die_error(404, "No projects found");
6577         }
6578
6579         print $cgi->header(
6580                 -type => 'text/plain',
6581                 -charset => 'utf-8',
6582                 -content_disposition => 'inline; filename="index.aux"');
6583
6584         foreach my $pr (@projects) {
6585                 if (!exists $pr->{'owner'}) {
6586                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}");
6587                 }
6588
6589                 my ($path, $owner) = ($pr->{'path'}, $pr->{'owner'});
6590                 # quote as in CGI::Util::encode, but keep the slash, and use '+' for ' '
6591                 $path  =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
6592                 $owner =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
6593                 $path  =~ s/ /\+/g;
6594                 $owner =~ s/ /\+/g;
6595
6596                 print "$path $owner\n";
6597         }
6598 }
6599
6600 sub git_summary {
6601         my $descr = git_get_project_description($project) || "none";
6602         my %co = parse_commit("HEAD");
6603         my %cd = %co ? parse_date($co{'committer_epoch'}, $co{'committer_tz'}) : ();
6604         my $head = $co{'id'};
6605         my $remote_heads = gitweb_check_feature('remote_heads');
6606
6607         my $owner = git_get_project_owner($project);
6608
6609         my $refs = git_get_references();
6610         # These get_*_list functions return one more to allow us to see if
6611         # there are more ...
6612         my @taglist  = git_get_tags_list(16);
6613         my @headlist = git_get_heads_list(16);
6614         my %remotedata = $remote_heads ? git_get_remotes_list() : ();
6615         my @forklist;
6616         my $check_forks = gitweb_check_feature('forks');
6617
6618         if ($check_forks) {
6619                 # find forks of a project
6620                 my $filter = $project;
6621                 $filter =~ s/\.git$//;
6622                 @forklist = git_get_projects_list($filter);
6623                 # filter out forks of forks
6624                 @forklist = filter_forks_from_projects_list(\@forklist)
6625                         if (@forklist);
6626         }
6627
6628         git_header_html();
6629         git_print_page_nav('summary','', $head);
6630
6631         print "<div class=\"title\">&nbsp;</div>\n";
6632         print "<table class=\"projects_list\">\n" .
6633               "<tr id=\"metadata_desc\"><td>description</td><td>" . esc_html($descr) . "</td></tr>\n";
6634         if ($owner and not $omit_owner) {
6635                 print  "<tr id=\"metadata_owner\"><td>owner</td><td>" . esc_html($owner) . "</td></tr>\n";
6636         }
6637         if (defined $cd{'rfc2822'}) {
6638                 print "<tr id=\"metadata_lchange\"><td>last change</td>" .
6639                       "<td>".format_timestamp_html(\%cd)."</td></tr>\n";
6640         }
6641
6642         # use per project git URL list in $projectroot/$project/cloneurl
6643         # or make project git URL from git base URL and project name
6644         my $url_tag = "URL";
6645         my @url_list = git_get_project_url_list($project);
6646         @url_list = map { "$_/$project" } @git_base_url_list unless @url_list;
6647         foreach my $git_url (@url_list) {
6648                 next unless $git_url;
6649                 print format_repo_url($url_tag, $git_url);
6650                 $url_tag = "";
6651         }
6652
6653         # Tag cloud
6654         my $show_ctags = gitweb_check_feature('ctags');
6655         if ($show_ctags) {
6656                 my $ctags = git_get_project_ctags($project);
6657                 if (%$ctags) {
6658                         # without ability to add tags, don't show if there are none
6659                         my $cloud = git_populate_project_tagcloud($ctags);
6660                         print "<tr id=\"metadata_ctags\">" .
6661                               "<td>content tags</td>" .
6662                               "<td>".git_show_project_tagcloud($cloud, 48)."</td>" .
6663                               "</tr>\n";
6664                 }
6665         }
6666
6667         print "</table>\n";
6668
6669         # If XSS prevention is on, we don't include README.html.
6670         # TODO: Allow a readme in some safe format.
6671         if (!$prevent_xss && -s "$projectroot/$project/README.html") {
6672                 print "<div class=\"title\">readme</div>\n" .
6673                       "<div class=\"readme\">\n";
6674                 insert_file("$projectroot/$project/README.html");
6675                 print "\n</div>\n"; # class="readme"
6676         }
6677
6678         # we need to request one more than 16 (0..15) to check if
6679         # those 16 are all
6680         my @commitlist = $head ? parse_commits($head, 17) : ();
6681         if (@commitlist) {
6682                 git_print_header_div('shortlog');
6683                 git_shortlog_body(\@commitlist, 0, 15, $refs,
6684                                   $#commitlist <=  15 ? undef :
6685                                   $cgi->a({-href => href(action=>"shortlog")}, "..."));
6686         }
6687
6688         if (@taglist) {
6689                 git_print_header_div('tags');
6690                 git_tags_body(\@taglist, 0, 15,
6691                               $#taglist <=  15 ? undef :
6692                               $cgi->a({-href => href(action=>"tags")}, "..."));
6693         }
6694
6695         if (@headlist) {
6696                 git_print_header_div('heads');
6697                 git_heads_body(\@headlist, $head, 0, 15,
6698                                $#headlist <= 15 ? undef :
6699                                $cgi->a({-href => href(action=>"heads")}, "..."));
6700         }
6701
6702         if (%remotedata) {
6703                 git_print_header_div('remotes');
6704                 git_remotes_body(\%remotedata, 15, $head);
6705         }
6706
6707         if (@forklist) {
6708                 git_print_header_div('forks');
6709                 git_project_list_body(\@forklist, 'age', 0, 15,
6710                                       $#forklist <= 15 ? undef :
6711                                       $cgi->a({-href => href(action=>"forks")}, "..."),
6712                                       'no_header');
6713         }
6714
6715         git_footer_html();
6716 }
6717
6718 sub git_tag {
6719         my %tag = parse_tag($hash);
6720
6721         if (! %tag) {
6722                 die_error(404, "Unknown tag object");
6723         }
6724
6725         my $head = git_get_head_hash($project);
6726         git_header_html();
6727         git_print_page_nav('','', $head,undef,$head);
6728         git_print_header_div('commit', esc_html($tag{'name'}), $hash);
6729         print "<div class=\"title_text\">\n" .
6730               "<table class=\"object_header\">\n" .
6731               "<tr>\n" .
6732               "<td>object</td>\n" .
6733               "<td>" . $cgi->a({-class => "list", -href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6734                                $tag{'object'}) . "</td>\n" .
6735               "<td class=\"link\">" . $cgi->a({-href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
6736                                               $tag{'type'}) . "</td>\n" .
6737               "</tr>\n";
6738         if (defined($tag{'author'})) {
6739                 git_print_authorship_rows(\%tag, 'author');
6740         }
6741         print "</table>\n\n" .
6742               "</div>\n";
6743         print "<div class=\"page_body\">";
6744         my $comment = $tag{'comment'};
6745         foreach my $line (@$comment) {
6746                 chomp $line;
6747                 print esc_html($line, -nbsp=>1) . "<br/>\n";
6748         }
6749         print "</div>\n";
6750         git_footer_html();
6751 }
6752
6753 sub git_blame_common {
6754         my $format = shift || 'porcelain';
6755         if ($format eq 'porcelain' && $input_params{'javascript'}) {
6756                 $format = 'incremental';
6757                 $action = 'blame_incremental'; # for page title etc
6758         }
6759
6760         # permissions
6761         gitweb_check_feature('blame')
6762                 or die_error(403, "Blame view not allowed");
6763
6764         # error checking
6765         die_error(400, "No file name given") unless $file_name;
6766         $hash_base ||= git_get_head_hash($project);
6767         die_error(404, "Couldn't find base commit") unless $hash_base;
6768         my %co = parse_commit($hash_base)
6769                 or die_error(404, "Commit not found");
6770         my $ftype = "blob";
6771         if (!defined $hash) {
6772                 $hash = git_get_hash_by_path($hash_base, $file_name, "blob")
6773                         or die_error(404, "Error looking up file");
6774         } else {
6775                 $ftype = git_get_type($hash);
6776                 if ($ftype !~ "blob") {
6777                         die_error(400, "Object is not a blob");
6778                 }
6779         }
6780
6781         my $fd;
6782         if ($format eq 'incremental') {
6783                 # get file contents (as base)
6784                 open $fd, "-|", git_cmd(), 'cat-file', 'blob', $hash
6785                         or die_error(500, "Open git-cat-file failed");
6786         } elsif ($format eq 'data') {
6787                 # run git-blame --incremental
6788                 open $fd, "-|", git_cmd(), "blame", "--incremental",
6789                         $hash_base, "--", $file_name
6790                         or die_error(500, "Open git-blame --incremental failed");
6791         } else {
6792                 # run git-blame --porcelain
6793                 open $fd, "-|", git_cmd(), "blame", '-p',
6794                         $hash_base, '--', $file_name
6795                         or die_error(500, "Open git-blame --porcelain failed");
6796         }
6797         binmode $fd, ':utf8';
6798
6799         # incremental blame data returns early
6800         if ($format eq 'data') {
6801                 print $cgi->header(
6802                         -type=>"text/plain", -charset => "utf-8",
6803                         -status=> "200 OK");
6804                 local $| = 1; # output autoflush
6805                 while (my $line = <$fd>) {
6806                         print to_utf8($line);
6807                 }
6808                 close $fd
6809                         or print "ERROR $!\n";
6810
6811                 print 'END';
6812                 if (defined $t0 && gitweb_check_feature('timed')) {
6813                         print ' '.
6814                               tv_interval($t0, [ gettimeofday() ]).
6815                               ' '.$number_of_git_cmds;
6816                 }
6817                 print "\n";
6818
6819                 return;
6820         }
6821
6822         # page header
6823         git_header_html();
6824         my $formats_nav =
6825                 $cgi->a({-href => href(action=>"blob", -replay=>1)},
6826                         "blob") .
6827                 " | ";
6828         if ($format eq 'incremental') {
6829                 $formats_nav .=
6830                         $cgi->a({-href => href(action=>"blame", javascript=>0, -replay=>1)},
6831                                 "blame") . " (non-incremental)";
6832         } else {
6833                 $formats_nav .=
6834                         $cgi->a({-href => href(action=>"blame_incremental", -replay=>1)},
6835                                 "blame") . " (incremental)";
6836         }
6837         $formats_nav .=
6838                 " | " .
6839                 $cgi->a({-href => href(action=>"history", -replay=>1)},
6840                         "history") .
6841                 " | " .
6842                 $cgi->a({-href => href(action=>$action, file_name=>$file_name)},
6843                         "HEAD");
6844         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6845         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6846         git_print_page_path($file_name, $ftype, $hash_base);
6847
6848         # page body
6849         if ($format eq 'incremental') {
6850                 print "<noscript>\n<div class=\"error\"><center><b>\n".
6851                       "This page requires JavaScript to run.\n Use ".
6852                       $cgi->a({-href => href(action=>'blame',javascript=>0,-replay=>1)},
6853                               'this page').
6854                       " instead.\n".
6855                       "</b></center></div>\n</noscript>\n";
6856
6857                 print qq!<div id="progress_bar" style="width: 100%; background-color: yellow"></div>\n!;
6858         }
6859
6860         print qq!<div class="page_body">\n!;
6861         print qq!<div id="progress_info">... / ...</div>\n!
6862                 if ($format eq 'incremental');
6863         print qq!<table id="blame_table" class="blame" width="100%">\n!.
6864               #qq!<col width="5.5em" /><col width="2.5em" /><col width="*" />\n!.
6865               qq!<thead>\n!.
6866               qq!<tr><th>Commit</th><th>Line</th><th>Data</th></tr>\n!.
6867               qq!</thead>\n!.
6868               qq!<tbody>\n!;
6869
6870         my @rev_color = qw(light dark);
6871         my $num_colors = scalar(@rev_color);
6872         my $current_color = 0;
6873
6874         if ($format eq 'incremental') {
6875                 my $color_class = $rev_color[$current_color];
6876
6877                 #contents of a file
6878                 my $linenr = 0;
6879         LINE:
6880                 while (my $line = <$fd>) {
6881                         chomp $line;
6882                         $linenr++;
6883
6884                         print qq!<tr id="l$linenr" class="$color_class">!.
6885                               qq!<td class="sha1"><a href=""> </a></td>!.
6886                               qq!<td class="linenr">!.
6887                               qq!<a class="linenr" href="">$linenr</a></td>!;
6888                         print qq!<td class="pre">! . esc_html($line) . "</td>\n";
6889                         print qq!</tr>\n!;
6890                 }
6891
6892         } else { # porcelain, i.e. ordinary blame
6893                 my %metainfo = (); # saves information about commits
6894
6895                 # blame data
6896         LINE:
6897                 while (my $line = <$fd>) {
6898                         chomp $line;
6899                         # the header: <SHA-1> <src lineno> <dst lineno> [<lines in group>]
6900                         # no <lines in group> for subsequent lines in group of lines
6901                         my ($full_rev, $orig_lineno, $lineno, $group_size) =
6902                            ($line =~ /^($oid_regex) (\d+) (\d+)(?: (\d+))?$/);
6903                         if (!exists $metainfo{$full_rev}) {
6904                                 $metainfo{$full_rev} = { 'nprevious' => 0 };
6905                         }
6906                         my $meta = $metainfo{$full_rev};
6907                         my $data;
6908                         while ($data = <$fd>) {
6909                                 chomp $data;
6910                                 last if ($data =~ s/^\t//); # contents of line
6911                                 if ($data =~ /^(\S+)(?: (.*))?$/) {
6912                                         $meta->{$1} = $2 unless exists $meta->{$1};
6913                                 }
6914                                 if ($data =~ /^previous /) {
6915                                         $meta->{'nprevious'}++;
6916                                 }
6917                         }
6918                         my $short_rev = substr($full_rev, 0, 8);
6919                         my $author = $meta->{'author'};
6920                         my %date =
6921                                 parse_date($meta->{'author-time'}, $meta->{'author-tz'});
6922                         my $date = $date{'iso-tz'};
6923                         if ($group_size) {
6924                                 $current_color = ($current_color + 1) % $num_colors;
6925                         }
6926                         my $tr_class = $rev_color[$current_color];
6927                         $tr_class .= ' boundary' if (exists $meta->{'boundary'});
6928                         $tr_class .= ' no-previous' if ($meta->{'nprevious'} == 0);
6929                         $tr_class .= ' multiple-previous' if ($meta->{'nprevious'} > 1);
6930                         print "<tr id=\"l$lineno\" class=\"$tr_class\">\n";
6931                         if ($group_size) {
6932                                 print "<td class=\"sha1\"";
6933                                 print " title=\"". esc_html($author) . ", $date\"";
6934                                 print " rowspan=\"$group_size\"" if ($group_size > 1);
6935                                 print ">";
6936                                 print $cgi->a({-href => href(action=>"commit",
6937                                                              hash=>$full_rev,
6938                                                              file_name=>$file_name)},
6939                                               esc_html($short_rev));
6940                                 if ($group_size >= 2) {
6941                                         my @author_initials = ($author =~ /\b([[:upper:]])\B/g);
6942                                         if (@author_initials) {
6943                                                 print "<br />" .
6944                                                       esc_html(join('', @author_initials));
6945                                                 #           or join('.', ...)
6946                                         }
6947                                 }
6948                                 print "</td>\n";
6949                         }
6950                         # 'previous' <sha1 of parent commit> <filename at commit>
6951                         if (exists $meta->{'previous'} &&
6952                             $meta->{'previous'} =~ /^($oid_regex) (.*)$/) {
6953                                 $meta->{'parent'} = $1;
6954                                 $meta->{'file_parent'} = unquote($2);
6955                         }
6956                         my $linenr_commit =
6957                                 exists($meta->{'parent'}) ?
6958                                 $meta->{'parent'} : $full_rev;
6959                         my $linenr_filename =
6960                                 exists($meta->{'file_parent'}) ?
6961                                 $meta->{'file_parent'} : unquote($meta->{'filename'});
6962                         my $blamed = href(action => 'blame',
6963                                           file_name => $linenr_filename,
6964                                           hash_base => $linenr_commit);
6965                         print "<td class=\"linenr\">";
6966                         print $cgi->a({ -href => "$blamed#l$orig_lineno",
6967                                         -class => "linenr" },
6968                                       esc_html($lineno));
6969                         print "</td>";
6970                         print "<td class=\"pre\">" . esc_html($data) . "</td>\n";
6971                         print "</tr>\n";
6972                 } # end while
6973
6974         }
6975
6976         # footer
6977         print "</tbody>\n".
6978               "</table>\n"; # class="blame"
6979         print "</div>\n";   # class="blame_body"
6980         close $fd
6981                 or print "Reading blob failed\n";
6982
6983         git_footer_html();
6984 }
6985
6986 sub git_blame {
6987         git_blame_common();
6988 }
6989
6990 sub git_blame_incremental {
6991         git_blame_common('incremental');
6992 }
6993
6994 sub git_blame_data {
6995         git_blame_common('data');
6996 }
6997
6998 sub git_tags {
6999         my $head = git_get_head_hash($project);
7000         git_header_html();
7001         git_print_page_nav('','', $head,undef,$head,format_ref_views('tags'));
7002         git_print_header_div('summary', $project);
7003
7004         my @tagslist = git_get_tags_list();
7005         if (@tagslist) {
7006                 git_tags_body(\@tagslist);
7007         }
7008         git_footer_html();
7009 }
7010
7011 sub git_heads {
7012         my $head = git_get_head_hash($project);
7013         git_header_html();
7014         git_print_page_nav('','', $head,undef,$head,format_ref_views('heads'));
7015         git_print_header_div('summary', $project);
7016
7017         my @headslist = git_get_heads_list();
7018         if (@headslist) {
7019                 git_heads_body(\@headslist, $head);
7020         }
7021         git_footer_html();
7022 }
7023
7024 # used both for single remote view and for list of all the remotes
7025 sub git_remotes {
7026         gitweb_check_feature('remote_heads')
7027                 or die_error(403, "Remote heads view is disabled");
7028
7029         my $head = git_get_head_hash($project);
7030         my $remote = $input_params{'hash'};
7031
7032         my $remotedata = git_get_remotes_list($remote);
7033         die_error(500, "Unable to get remote information") unless defined $remotedata;
7034
7035         unless (%$remotedata) {
7036                 die_error(404, defined $remote ?
7037                         "Remote $remote not found" :
7038                         "No remotes found");
7039         }
7040
7041         git_header_html(undef, undef, -action_extra => $remote);
7042         git_print_page_nav('', '',  $head, undef, $head,
7043                 format_ref_views($remote ? '' : 'remotes'));
7044
7045         fill_remote_heads($remotedata);
7046         if (defined $remote) {
7047                 git_print_header_div('remotes', "$remote remote for $project");
7048                 git_remote_block($remote, $remotedata->{$remote}, undef, $head);
7049         } else {
7050                 git_print_header_div('summary', "$project remotes");
7051                 git_remotes_body($remotedata, undef, $head);
7052         }
7053
7054         git_footer_html();
7055 }
7056
7057 sub git_blob_plain {
7058         my $type = shift;
7059         my $expires;
7060
7061         if (!defined $hash) {
7062                 if (defined $file_name) {
7063                         my $base = $hash_base || git_get_head_hash($project);
7064                         $hash = git_get_hash_by_path($base, $file_name, "blob")
7065                                 or die_error(404, "Cannot find file");
7066                 } else {
7067                         die_error(400, "No file name defined");
7068                 }
7069         } elsif ($hash =~ m/^$oid_regex$/) {
7070                 # blobs defined by non-textual hash id's can be cached
7071                 $expires = "+1d";
7072         }
7073
7074         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
7075                 or die_error(500, "Open git-cat-file blob '$hash' failed");
7076
7077         # content-type (can include charset)
7078         $type = blob_contenttype($fd, $file_name, $type);
7079
7080         # "save as" filename, even when no $file_name is given
7081         my $save_as = "$hash";
7082         if (defined $file_name) {
7083                 $save_as = $file_name;
7084         } elsif ($type =~ m/^text\//) {
7085                 $save_as .= '.txt';
7086         }
7087
7088         # With XSS prevention on, blobs of all types except a few known safe
7089         # ones are served with "Content-Disposition: attachment" to make sure
7090         # they don't run in our security domain.  For certain image types,
7091         # blob view writes an <img> tag referring to blob_plain view, and we
7092         # want to be sure not to break that by serving the image as an
7093         # attachment (though Firefox 3 doesn't seem to care).
7094         my $sandbox = $prevent_xss &&
7095                 $type !~ m!^(?:text/[a-z]+|image/(?:gif|png|jpeg))(?:[ ;]|$)!;
7096
7097         # serve text/* as text/plain
7098         if ($prevent_xss &&
7099             ($type =~ m!^text/[a-z]+\b(.*)$! ||
7100              ($type =~ m!^[a-z]+/[a-z]\+xml\b(.*)$! && -T $fd))) {
7101                 my $rest = $1;
7102                 $rest = defined $rest ? $rest : '';
7103                 $type = "text/plain$rest";
7104         }
7105
7106         print $cgi->header(
7107                 -type => $type,
7108                 -expires => $expires,
7109                 -content_disposition =>
7110                         ($sandbox ? 'attachment' : 'inline')
7111                         . '; filename="' . $save_as . '"');
7112         local $/ = undef;
7113         local *FCGI::Stream::PRINT = $FCGI_Stream_PRINT_raw;
7114         binmode STDOUT, ':raw';
7115         print <$fd>;
7116         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
7117         close $fd;
7118 }
7119
7120 sub git_blob {
7121         my $expires;
7122
7123         if (!defined $hash) {
7124                 if (defined $file_name) {
7125                         my $base = $hash_base || git_get_head_hash($project);
7126                         $hash = git_get_hash_by_path($base, $file_name, "blob")
7127                                 or die_error(404, "Cannot find file");
7128                 } else {
7129                         die_error(400, "No file name defined");
7130                 }
7131         } elsif ($hash =~ m/^$oid_regex$/) {
7132                 # blobs defined by non-textual hash id's can be cached
7133                 $expires = "+1d";
7134         }
7135
7136         my $have_blame = gitweb_check_feature('blame');
7137         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
7138                 or die_error(500, "Couldn't cat $file_name, $hash");
7139         my $mimetype = blob_mimetype($fd, $file_name);
7140         # use 'blob_plain' (aka 'raw') view for files that cannot be displayed
7141         if ($mimetype !~ m!^(?:text/|image/(?:gif|png|jpeg)$)! && -B $fd) {
7142                 close $fd;
7143                 return git_blob_plain($mimetype);
7144         }
7145         # we can have blame only for text/* mimetype
7146         $have_blame &&= ($mimetype =~ m!^text/!);
7147
7148         my $highlight = gitweb_check_feature('highlight');
7149         my $syntax = guess_file_syntax($highlight, $file_name);
7150         $fd = run_highlighter($fd, $highlight, $syntax);
7151
7152         git_header_html(undef, $expires);
7153         my $formats_nav = '';
7154         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7155                 if (defined $file_name) {
7156                         if ($have_blame) {
7157                                 $formats_nav .=
7158                                         $cgi->a({-href => href(action=>"blame", -replay=>1)},
7159                                                 "blame") .
7160                                         " | ";
7161                         }
7162                         $formats_nav .=
7163                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
7164                                         "history") .
7165                                 " | " .
7166                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
7167                                         "raw") .
7168                                 " | " .
7169                                 $cgi->a({-href => href(action=>"blob",
7170                                                        hash_base=>"HEAD", file_name=>$file_name)},
7171                                         "HEAD");
7172                 } else {
7173                         $formats_nav .=
7174                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
7175                                         "raw");
7176                 }
7177                 git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
7178                 git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
7179         } else {
7180                 print "<div class=\"page_nav\">\n" .
7181                       "<br/><br/></div>\n" .
7182                       "<div class=\"title\">".esc_html($hash)."</div>\n";
7183         }
7184         git_print_page_path($file_name, "blob", $hash_base);
7185         print "<div class=\"page_body\">\n";
7186         if ($mimetype =~ m!^image/!) {
7187                 print qq!<img class="blob" type="!.esc_attr($mimetype).qq!"!;
7188                 if ($file_name) {
7189                         print qq! alt="!.esc_attr($file_name).qq!" title="!.esc_attr($file_name).qq!"!;
7190                 }
7191                 print qq! src="! .
7192                       esc_attr(href(action=>"blob_plain", hash=>$hash,
7193                            hash_base=>$hash_base, file_name=>$file_name)) .
7194                       qq!" />\n!;
7195         } else {
7196                 my $nr;
7197                 while (my $line = <$fd>) {
7198                         chomp $line;
7199                         $nr++;
7200                         $line = untabify($line);
7201                         printf qq!<div class="pre"><a id="l%i" href="%s#l%i" class="linenr">%4i</a> %s</div>\n!,
7202                                $nr, esc_attr(href(-replay => 1)), $nr, $nr,
7203                                $highlight ? sanitize($line) : esc_html($line, -nbsp=>1);
7204                 }
7205         }
7206         close $fd
7207                 or print "Reading blob failed.\n";
7208         print "</div>";
7209         git_footer_html();
7210 }
7211
7212 sub git_tree {
7213         if (!defined $hash_base) {
7214                 $hash_base = "HEAD";
7215         }
7216         if (!defined $hash) {
7217                 if (defined $file_name) {
7218                         $hash = git_get_hash_by_path($hash_base, $file_name, "tree");
7219                 } else {
7220                         $hash = $hash_base;
7221                 }
7222         }
7223         die_error(404, "No such tree") unless defined($hash);
7224
7225         my $show_sizes = gitweb_check_feature('show-sizes');
7226         my $have_blame = gitweb_check_feature('blame');
7227
7228         my @entries = ();
7229         {
7230                 local $/ = "\0";
7231                 open my $fd, "-|", git_cmd(), "ls-tree", '-z',
7232                         ($show_sizes ? '-l' : ()), @extra_options, $hash
7233                         or die_error(500, "Open git-ls-tree failed");
7234                 @entries = map { chomp; $_ } <$fd>;
7235                 close $fd
7236                         or die_error(404, "Reading tree failed");
7237         }
7238
7239         my $refs = git_get_references();
7240         my $ref = format_ref_marker($refs, $hash_base);
7241         git_header_html();
7242         my $basedir = '';
7243         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7244                 my @views_nav = ();
7245                 if (defined $file_name) {
7246                         push @views_nav,
7247                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
7248                                         "history"),
7249                                 $cgi->a({-href => href(action=>"tree",
7250                                                        hash_base=>"HEAD", file_name=>$file_name)},
7251                                         "HEAD"),
7252                 }
7253                 my $snapshot_links = format_snapshot_links($hash);
7254                 if (defined $snapshot_links) {
7255                         # FIXME: Should be available when we have no hash base as well.
7256                         push @views_nav, $snapshot_links;
7257                 }
7258                 git_print_page_nav('tree','', $hash_base, undef, undef,
7259                                    join(' | ', @views_nav));
7260                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash_base);
7261         } else {
7262                 undef $hash_base;
7263                 print "<div class=\"page_nav\">\n";
7264                 print "<br/><br/></div>\n";
7265                 print "<div class=\"title\">".esc_html($hash)."</div>\n";
7266         }
7267         if (defined $file_name) {
7268                 $basedir = $file_name;
7269                 if ($basedir ne '' && substr($basedir, -1) ne '/') {
7270                         $basedir .= '/';
7271                 }
7272                 git_print_page_path($file_name, 'tree', $hash_base);
7273         }
7274         print "<div class=\"page_body\">\n";
7275         print "<table class=\"tree\">\n";
7276         my $alternate = 1;
7277         # '..' (top directory) link if possible
7278         if (defined $hash_base &&
7279             defined $file_name && $file_name =~ m![^/]+$!) {
7280                 if ($alternate) {
7281                         print "<tr class=\"dark\">\n";
7282                 } else {
7283                         print "<tr class=\"light\">\n";
7284                 }
7285                 $alternate ^= 1;
7286
7287                 my $up = $file_name;
7288                 $up =~ s!/?[^/]+$!!;
7289                 undef $up unless $up;
7290                 # based on git_print_tree_entry
7291                 print '<td class="mode">' . mode_str('040000') . "</td>\n";
7292                 print '<td class="size">&nbsp;</td>'."\n" if $show_sizes;
7293                 print '<td class="list">';
7294                 print $cgi->a({-href => href(action=>"tree",
7295                                              hash_base=>$hash_base,
7296                                              file_name=>$up)},
7297                               "..");
7298                 print "</td>\n";
7299                 print "<td class=\"link\"></td>\n";
7300
7301                 print "</tr>\n";
7302         }
7303         foreach my $line (@entries) {
7304                 my %t = parse_ls_tree_line($line, -z => 1, -l => $show_sizes);
7305
7306                 if ($alternate) {
7307                         print "<tr class=\"dark\">\n";
7308                 } else {
7309                         print "<tr class=\"light\">\n";
7310                 }
7311                 $alternate ^= 1;
7312
7313                 git_print_tree_entry(\%t, $basedir, $hash_base, $have_blame);
7314
7315                 print "</tr>\n";
7316         }
7317         print "</table>\n" .
7318               "</div>";
7319         git_footer_html();
7320 }
7321
7322 sub sanitize_for_filename {
7323     my $name = shift;
7324
7325     $name =~ s!/!-!g;
7326     $name =~ s/[^[:alnum:]_.-]//g;
7327
7328     return $name;
7329 }
7330
7331 sub snapshot_name {
7332         my ($project, $hash) = @_;
7333
7334         # path/to/project.git  -> project
7335         # path/to/project/.git -> project
7336         my $name = to_utf8($project);
7337         $name =~ s,([^/])/*\.git$,$1,;
7338         $name = sanitize_for_filename(basename($name));
7339
7340         my $ver = $hash;
7341         if ($hash =~ /^[0-9a-fA-F]+$/) {
7342                 # shorten SHA-1 hash
7343                 my $full_hash = git_get_full_hash($project, $hash);
7344                 if ($full_hash =~ /^$hash/ && length($hash) > 7) {
7345                         $ver = git_get_short_hash($project, $hash);
7346                 }
7347         } elsif ($hash =~ m!^refs/tags/(.*)$!) {
7348                 # tags don't need shortened SHA-1 hash
7349                 $ver = $1;
7350         } else {
7351                 # branches and other need shortened SHA-1 hash
7352                 my $strip_refs = join '|', map { quotemeta } get_branch_refs();
7353                 if ($hash =~ m!^refs/($strip_refs|remotes)/(.*)$!) {
7354                         my $ref_dir = (defined $1) ? $1 : '';
7355                         $ver = $2;
7356
7357                         $ref_dir = sanitize_for_filename($ref_dir);
7358                         # for refs neither in heads nor remotes we want to
7359                         # add a ref dir to archive name
7360                         if ($ref_dir ne '' and $ref_dir ne 'heads' and $ref_dir ne 'remotes') {
7361                                 $ver = $ref_dir . '-' . $ver;
7362                         }
7363                 }
7364                 $ver .= '-' . git_get_short_hash($project, $hash);
7365         }
7366         # special case of sanitization for filename - we change
7367         # slashes to dots instead of dashes
7368         # in case of hierarchical branch names
7369         $ver =~ s!/!.!g;
7370         $ver =~ s/[^[:alnum:]_.-]//g;
7371
7372         # name = project-version_string
7373         $name = "$name-$ver";
7374
7375         return wantarray ? ($name, $name) : $name;
7376 }
7377
7378 sub exit_if_unmodified_since {
7379         my ($latest_epoch) = @_;
7380         our $cgi;
7381
7382         my $if_modified = $cgi->http('IF_MODIFIED_SINCE');
7383         if (defined $if_modified) {
7384                 my $since;
7385                 if (eval { require HTTP::Date; 1; }) {
7386                         $since = HTTP::Date::str2time($if_modified);
7387                 } elsif (eval { require Time::ParseDate; 1; }) {
7388                         $since = Time::ParseDate::parsedate($if_modified, GMT => 1);
7389                 }
7390                 if (defined $since && $latest_epoch <= $since) {
7391                         my %latest_date = parse_date($latest_epoch);
7392                         print $cgi->header(
7393                                 -last_modified => $latest_date{'rfc2822'},
7394                                 -status => '304 Not Modified');
7395                         goto DONE_GITWEB;
7396                 }
7397         }
7398 }
7399
7400 sub git_snapshot {
7401         my $format = $input_params{'snapshot_format'};
7402         if (!@snapshot_fmts) {
7403                 die_error(403, "Snapshots not allowed");
7404         }
7405         # default to first supported snapshot format
7406         $format ||= $snapshot_fmts[0];
7407         if ($format !~ m/^[a-z0-9]+$/) {
7408                 die_error(400, "Invalid snapshot format parameter");
7409         } elsif (!exists($known_snapshot_formats{$format})) {
7410                 die_error(400, "Unknown snapshot format");
7411         } elsif ($known_snapshot_formats{$format}{'disabled'}) {
7412                 die_error(403, "Snapshot format not allowed");
7413         } elsif (!grep($_ eq $format, @snapshot_fmts)) {
7414                 die_error(403, "Unsupported snapshot format");
7415         }
7416
7417         my $type = git_get_type("$hash^{}");
7418         if (!$type) {
7419                 die_error(404, 'Object does not exist');
7420         }  elsif ($type eq 'blob') {
7421                 die_error(400, 'Object is not a tree-ish');
7422         }
7423
7424         my ($name, $prefix) = snapshot_name($project, $hash);
7425         my $filename = "$name$known_snapshot_formats{$format}{'suffix'}";
7426
7427         my %co = parse_commit($hash);
7428         exit_if_unmodified_since($co{'committer_epoch'}) if %co;
7429
7430         my $cmd = quote_command(
7431                 git_cmd(), 'archive',
7432                 "--format=$known_snapshot_formats{$format}{'format'}",
7433                 "--prefix=$prefix/", $hash);
7434         if (exists $known_snapshot_formats{$format}{'compressor'}) {
7435                 $cmd .= ' | ' . quote_command(@{$known_snapshot_formats{$format}{'compressor'}});
7436         }
7437
7438         $filename =~ s/(["\\])/\\$1/g;
7439         my %latest_date;
7440         if (%co) {
7441                 %latest_date = parse_date($co{'committer_epoch'}, $co{'committer_tz'});
7442         }
7443
7444         print $cgi->header(
7445                 -type => $known_snapshot_formats{$format}{'type'},
7446                 -content_disposition => 'inline; filename="' . $filename . '"',
7447                 %co ? (-last_modified => $latest_date{'rfc2822'}) : (),
7448                 -status => '200 OK');
7449
7450         open my $fd, "-|", $cmd
7451                 or die_error(500, "Execute git-archive failed");
7452         local *FCGI::Stream::PRINT = $FCGI_Stream_PRINT_raw;
7453         binmode STDOUT, ':raw';
7454         print <$fd>;
7455         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
7456         close $fd;
7457 }
7458
7459 sub git_log_generic {
7460         my ($fmt_name, $body_subr, $base, $parent, $file_name, $file_hash) = @_;
7461
7462         my $head = git_get_head_hash($project);
7463         if (!defined $base) {
7464                 $base = $head;
7465         }
7466         if (!defined $page) {
7467                 $page = 0;
7468         }
7469         my $refs = git_get_references();
7470
7471         my $commit_hash = $base;
7472         if (defined $parent) {
7473                 $commit_hash = "$parent..$base";
7474         }
7475         my @commitlist =
7476                 parse_commits($commit_hash, 101, (100 * $page),
7477                               defined $file_name ? ($file_name, "--full-history") : ());
7478
7479         my $ftype;
7480         if (!defined $file_hash && defined $file_name) {
7481                 # some commits could have deleted file in question,
7482                 # and not have it in tree, but one of them has to have it
7483                 for (my $i = 0; $i < @commitlist; $i++) {
7484                         $file_hash = git_get_hash_by_path($commitlist[$i]{'id'}, $file_name);
7485                         last if defined $file_hash;
7486                 }
7487         }
7488         if (defined $file_hash) {
7489                 $ftype = git_get_type($file_hash);
7490         }
7491         if (defined $file_name && !defined $ftype) {
7492                 die_error(500, "Unknown type of object");
7493         }
7494         my %co;
7495         if (defined $file_name) {
7496                 %co = parse_commit($base)
7497                         or die_error(404, "Unknown commit object");
7498         }
7499
7500
7501         my $paging_nav = format_paging_nav($fmt_name, $page, $#commitlist >= 100);
7502         my $next_link = '';
7503         if ($#commitlist >= 100) {
7504                 $next_link =
7505                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
7506                                  -accesskey => "n", -title => "Alt-n"}, "next");
7507         }
7508         my $patch_max = gitweb_get_feature('patches');
7509         if ($patch_max && !defined $file_name &&
7510                 !gitweb_check_feature('email-privacy')) {
7511                 if ($patch_max < 0 || @commitlist <= $patch_max) {
7512                         $paging_nav .= " &sdot; " .
7513                                 $cgi->a({-href => href(action=>"patches", -replay=>1)},
7514                                         "patches");
7515                 }
7516         }
7517
7518         git_header_html();
7519         git_print_page_nav($fmt_name,'', $hash,$hash,$hash, $paging_nav);
7520         if (defined $file_name) {
7521                 git_print_header_div('commit', esc_html($co{'title'}), $base);
7522         } else {
7523                 git_print_header_div('summary', $project)
7524         }
7525         git_print_page_path($file_name, $ftype, $hash_base)
7526                 if (defined $file_name);
7527
7528         $body_subr->(\@commitlist, 0, 99, $refs, $next_link,
7529                      $file_name, $file_hash, $ftype);
7530
7531         git_footer_html();
7532 }
7533
7534 sub git_log {
7535         git_log_generic('log', \&git_log_body,
7536                         $hash, $hash_parent);
7537 }
7538
7539 sub git_commit {
7540         $hash ||= $hash_base || "HEAD";
7541         my %co = parse_commit($hash)
7542             or die_error(404, "Unknown commit object");
7543
7544         my $parent  = $co{'parent'};
7545         my $parents = $co{'parents'}; # listref
7546
7547         # we need to prepare $formats_nav before any parameter munging
7548         my $formats_nav;
7549         if (!defined $parent) {
7550                 # --root commitdiff
7551                 $formats_nav .= '(initial)';
7552         } elsif (@$parents == 1) {
7553                 # single parent commit
7554                 $formats_nav .=
7555                         '(parent: ' .
7556                         $cgi->a({-href => href(action=>"commit",
7557                                                hash=>$parent)},
7558                                 esc_html(substr($parent, 0, 7))) .
7559                         ')';
7560         } else {
7561                 # merge commit
7562                 $formats_nav .=
7563                         '(merge: ' .
7564                         join(' ', map {
7565                                 $cgi->a({-href => href(action=>"commit",
7566                                                        hash=>$_)},
7567                                         esc_html(substr($_, 0, 7)));
7568                         } @$parents ) .
7569                         ')';
7570         }
7571         if (gitweb_check_feature('patches') && @$parents <= 1 &&
7572                 !gitweb_check_feature('email-privacy')) {
7573                 $formats_nav .= " | " .
7574                         $cgi->a({-href => href(action=>"patch", -replay=>1)},
7575                                 "patch");
7576         }
7577
7578         if (!defined $parent) {
7579                 $parent = "--root";
7580         }
7581         my @difftree;
7582         open my $fd, "-|", git_cmd(), "diff-tree", '-r', "--no-commit-id",
7583                 @diff_opts,
7584                 (@$parents <= 1 ? $parent : '-c'),
7585                 $hash, "--"
7586                 or die_error(500, "Open git-diff-tree failed");
7587         @difftree = map { chomp; $_ } <$fd>;
7588         close $fd or die_error(404, "Reading git-diff-tree failed");
7589
7590         # non-textual hash id's can be cached
7591         my $expires;
7592         if ($hash =~ m/^$oid_regex$/) {
7593                 $expires = "+1d";
7594         }
7595         my $refs = git_get_references();
7596         my $ref = format_ref_marker($refs, $co{'id'});
7597
7598         git_header_html(undef, $expires);
7599         git_print_page_nav('commit', '',
7600                            $hash, $co{'tree'}, $hash,
7601                            $formats_nav);
7602
7603         if (defined $co{'parent'}) {
7604                 git_print_header_div('commitdiff', esc_html($co{'title'}) . $ref, $hash);
7605         } else {
7606                 git_print_header_div('tree', esc_html($co{'title'}) . $ref, $co{'tree'}, $hash);
7607         }
7608         print "<div class=\"title_text\">\n" .
7609               "<table class=\"object_header\">\n";
7610         git_print_authorship_rows(\%co);
7611         print "<tr><td>commit</td><td class=\"sha1\">$co{'id'}</td></tr>\n";
7612         print "<tr>" .
7613               "<td>tree</td>" .
7614               "<td class=\"sha1\">" .
7615               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash),
7616                        class => "list"}, $co{'tree'}) .
7617               "</td>" .
7618               "<td class=\"link\">" .
7619               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash)},
7620                       "tree");
7621         my $snapshot_links = format_snapshot_links($hash);
7622         if (defined $snapshot_links) {
7623                 print " | " . $snapshot_links;
7624         }
7625         print "</td>" .
7626               "</tr>\n";
7627
7628         foreach my $par (@$parents) {
7629                 print "<tr>" .
7630                       "<td>parent</td>" .
7631                       "<td class=\"sha1\">" .
7632                       $cgi->a({-href => href(action=>"commit", hash=>$par),
7633                                class => "list"}, $par) .
7634                       "</td>" .
7635                       "<td class=\"link\">" .
7636                       $cgi->a({-href => href(action=>"commit", hash=>$par)}, "commit") .
7637                       " | " .
7638                       $cgi->a({-href => href(action=>"commitdiff", hash=>$hash, hash_parent=>$par)}, "diff") .
7639                       "</td>" .
7640                       "</tr>\n";
7641         }
7642         print "</table>".
7643               "</div>\n";
7644
7645         print "<div class=\"page_body\">\n";
7646         git_print_log($co{'comment'});
7647         print "</div>\n";
7648
7649         git_difftree_body(\@difftree, $hash, @$parents);
7650
7651         git_footer_html();
7652 }
7653
7654 sub git_object {
7655         # object is defined by:
7656         # - hash or hash_base alone
7657         # - hash_base and file_name
7658         my $type;
7659
7660         # - hash or hash_base alone
7661         if ($hash || ($hash_base && !defined $file_name)) {
7662                 my $object_id = $hash || $hash_base;
7663
7664                 open my $fd, "-|", quote_command(
7665                         git_cmd(), 'cat-file', '-t', $object_id) . ' 2> /dev/null'
7666                         or die_error(404, "Object does not exist");
7667                 $type = <$fd>;
7668                 defined $type && chomp $type;
7669                 close $fd
7670                         or die_error(404, "Object does not exist");
7671
7672         # - hash_base and file_name
7673         } elsif ($hash_base && defined $file_name) {
7674                 $file_name =~ s,/+$,,;
7675
7676                 system(git_cmd(), "cat-file", '-e', $hash_base) == 0
7677                         or die_error(404, "Base object does not exist");
7678
7679                 # here errors should not happen
7680                 open my $fd, "-|", git_cmd(), "ls-tree", $hash_base, "--", $file_name
7681                         or die_error(500, "Open git-ls-tree failed");
7682                 my $line = <$fd>;
7683                 close $fd;
7684
7685                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
7686                 unless ($line && $line =~ m/^([0-9]+) (.+) ($oid_regex)\t/) {
7687                         die_error(404, "File or directory for given base does not exist");
7688                 }
7689                 $type = $2;
7690                 $hash = $3;
7691         } else {
7692                 die_error(400, "Not enough information to find object");
7693         }
7694
7695         print $cgi->redirect(-uri => href(action=>$type, -full=>1,
7696                                           hash=>$hash, hash_base=>$hash_base,
7697                                           file_name=>$file_name),
7698                              -status => '302 Found');
7699 }
7700
7701 sub git_blobdiff {
7702         my $format = shift || 'html';
7703         my $diff_style = $input_params{'diff_style'} || 'inline';
7704
7705         my $fd;
7706         my @difftree;
7707         my %diffinfo;
7708         my $expires;
7709
7710         # preparing $fd and %diffinfo for git_patchset_body
7711         # new style URI
7712         if (defined $hash_base && defined $hash_parent_base) {
7713                 if (defined $file_name) {
7714                         # read raw output
7715                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7716                                 $hash_parent_base, $hash_base,
7717                                 "--", (defined $file_parent ? $file_parent : ()), $file_name
7718                                 or die_error(500, "Open git-diff-tree failed");
7719                         @difftree = map { chomp; $_ } <$fd>;
7720                         close $fd
7721                                 or die_error(404, "Reading git-diff-tree failed");
7722                         @difftree
7723                                 or die_error(404, "Blob diff not found");
7724
7725                 } elsif (defined $hash &&
7726                          $hash =~ $oid_regex) {
7727                         # try to find filename from $hash
7728
7729                         # read filtered raw output
7730                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7731                                 $hash_parent_base, $hash_base, "--"
7732                                 or die_error(500, "Open git-diff-tree failed");
7733                         @difftree =
7734                                 # ':100644 100644 03b21826... 3b93d5e7... M     ls-files.c'
7735                                 # $hash == to_id
7736                                 grep { /^:[0-7]{6} [0-7]{6} $oid_regex $hash/ }
7737                                 map { chomp; $_ } <$fd>;
7738                         close $fd
7739                                 or die_error(404, "Reading git-diff-tree failed");
7740                         @difftree
7741                                 or die_error(404, "Blob diff not found");
7742
7743                 } else {
7744                         die_error(400, "Missing one of the blob diff parameters");
7745                 }
7746
7747                 if (@difftree > 1) {
7748                         die_error(400, "Ambiguous blob diff specification");
7749                 }
7750
7751                 %diffinfo = parse_difftree_raw_line($difftree[0]);
7752                 $file_parent ||= $diffinfo{'from_file'} || $file_name;
7753                 $file_name   ||= $diffinfo{'to_file'};
7754
7755                 $hash_parent ||= $diffinfo{'from_id'};
7756                 $hash        ||= $diffinfo{'to_id'};
7757
7758                 # non-textual hash id's can be cached
7759                 if ($hash_base =~ m/^$oid_regex$/ &&
7760                     $hash_parent_base =~ m/^$oid_regex$/) {
7761                         $expires = '+1d';
7762                 }
7763
7764                 # open patch output
7765                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7766                         '-p', ($format eq 'html' ? "--full-index" : ()),
7767                         $hash_parent_base, $hash_base,
7768                         "--", (defined $file_parent ? $file_parent : ()), $file_name
7769                         or die_error(500, "Open git-diff-tree failed");
7770         }
7771
7772         # old/legacy style URI -- not generated anymore since 1.4.3.
7773         if (!%diffinfo) {
7774                 die_error('404 Not Found', "Missing one of the blob diff parameters")
7775         }
7776
7777         # header
7778         if ($format eq 'html') {
7779                 my $formats_nav =
7780                         $cgi->a({-href => href(action=>"blobdiff_plain", -replay=>1)},
7781                                 "raw");
7782                 $formats_nav .= diff_style_nav($diff_style);
7783                 git_header_html(undef, $expires);
7784                 if (defined $hash_base && (my %co = parse_commit($hash_base))) {
7785                         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
7786                         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
7787                 } else {
7788                         print "<div class=\"page_nav\"><br/>$formats_nav<br/></div>\n";
7789                         print "<div class=\"title\">".esc_html("$hash vs $hash_parent")."</div>\n";
7790                 }
7791                 if (defined $file_name) {
7792                         git_print_page_path($file_name, "blob", $hash_base);
7793                 } else {
7794                         print "<div class=\"page_path\"></div>\n";
7795                 }
7796
7797         } elsif ($format eq 'plain') {
7798                 print $cgi->header(
7799                         -type => 'text/plain',
7800                         -charset => 'utf-8',
7801                         -expires => $expires,
7802                         -content_disposition => 'inline; filename="' . "$file_name" . '.patch"');
7803
7804                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
7805
7806         } else {
7807                 die_error(400, "Unknown blobdiff format");
7808         }
7809
7810         # patch
7811         if ($format eq 'html') {
7812                 print "<div class=\"page_body\">\n";
7813
7814                 git_patchset_body($fd, $diff_style,
7815                                   [ \%diffinfo ], $hash_base, $hash_parent_base);
7816                 close $fd;
7817
7818                 print "</div>\n"; # class="page_body"
7819                 git_footer_html();
7820
7821         } else {
7822                 while (my $line = <$fd>) {
7823                         $line =~ s!a/($hash|$hash_parent)!'a/'.esc_path($diffinfo{'from_file'})!eg;
7824                         $line =~ s!b/($hash|$hash_parent)!'b/'.esc_path($diffinfo{'to_file'})!eg;
7825
7826                         print $line;
7827
7828                         last if $line =~ m!^\+\+\+!;
7829                 }
7830                 local $/ = undef;
7831                 print <$fd>;
7832                 close $fd;
7833         }
7834 }
7835
7836 sub git_blobdiff_plain {
7837         git_blobdiff('plain');
7838 }
7839
7840 # assumes that it is added as later part of already existing navigation,
7841 # so it returns "| foo | bar" rather than just "foo | bar"
7842 sub diff_style_nav {
7843         my ($diff_style, $is_combined) = @_;
7844         $diff_style ||= 'inline';
7845
7846         return "" if ($is_combined);
7847
7848         my @styles = (inline => 'inline', 'sidebyside' => 'side by side');
7849         my %styles = @styles;
7850         @styles =
7851                 @styles[ map { $_ * 2 } 0..$#styles/2 ];
7852
7853         return join '',
7854                 map { " | ".$_ }
7855                 map {
7856                         $_ eq $diff_style ? $styles{$_} :
7857                         $cgi->a({-href => href(-replay=>1, diff_style => $_)}, $styles{$_})
7858                 } @styles;
7859 }
7860
7861 sub git_commitdiff {
7862         my %params = @_;
7863         my $format = $params{-format} || 'html';
7864         my $diff_style = $input_params{'diff_style'} || 'inline';
7865
7866         my ($patch_max) = gitweb_get_feature('patches');
7867         if ($format eq 'patch') {
7868                 die_error(403, "Patch view not allowed") unless $patch_max;
7869         }
7870
7871         $hash ||= $hash_base || "HEAD";
7872         my %co = parse_commit($hash)
7873             or die_error(404, "Unknown commit object");
7874
7875         # choose format for commitdiff for merge
7876         if (! defined $hash_parent && @{$co{'parents'}} > 1) {
7877                 $hash_parent = '--cc';
7878         }
7879         # we need to prepare $formats_nav before almost any parameter munging
7880         my $formats_nav;
7881         if ($format eq 'html') {
7882                 $formats_nav =
7883                         $cgi->a({-href => href(action=>"commitdiff_plain", -replay=>1)},
7884                                 "raw");
7885                 if ($patch_max && @{$co{'parents'}} <= 1 &&
7886                         !gitweb_check_feature('email-privacy')) {
7887                         $formats_nav .= " | " .
7888                                 $cgi->a({-href => href(action=>"patch", -replay=>1)},
7889                                         "patch");
7890                 }
7891                 $formats_nav .= diff_style_nav($diff_style, @{$co{'parents'}} > 1);
7892
7893                 if (defined $hash_parent &&
7894                     $hash_parent ne '-c' && $hash_parent ne '--cc') {
7895                         # commitdiff with two commits given
7896                         my $hash_parent_short = $hash_parent;
7897                         if ($hash_parent =~ m/^$oid_regex$/) {
7898                                 $hash_parent_short = substr($hash_parent, 0, 7);
7899                         }
7900                         $formats_nav .=
7901                                 ' (from';
7902                         for (my $i = 0; $i < @{$co{'parents'}}; $i++) {
7903                                 if ($co{'parents'}[$i] eq $hash_parent) {
7904                                         $formats_nav .= ' parent ' . ($i+1);
7905                                         last;
7906                                 }
7907                         }
7908                         $formats_nav .= ': ' .
7909                                 $cgi->a({-href => href(-replay=>1,
7910                                                        hash=>$hash_parent, hash_base=>undef)},
7911                                         esc_html($hash_parent_short)) .
7912                                 ')';
7913                 } elsif (!$co{'parent'}) {
7914                         # --root commitdiff
7915                         $formats_nav .= ' (initial)';
7916                 } elsif (scalar @{$co{'parents'}} == 1) {
7917                         # single parent commit
7918                         $formats_nav .=
7919                                 ' (parent: ' .
7920                                 $cgi->a({-href => href(-replay=>1,
7921                                                        hash=>$co{'parent'}, hash_base=>undef)},
7922                                         esc_html(substr($co{'parent'}, 0, 7))) .
7923                                 ')';
7924                 } else {
7925                         # merge commit
7926                         if ($hash_parent eq '--cc') {
7927                                 $formats_nav .= ' | ' .
7928                                         $cgi->a({-href => href(-replay=>1,
7929                                                                hash=>$hash, hash_parent=>'-c')},
7930                                                 'combined');
7931                         } else { # $hash_parent eq '-c'
7932                                 $formats_nav .= ' | ' .
7933                                         $cgi->a({-href => href(-replay=>1,
7934                                                                hash=>$hash, hash_parent=>'--cc')},
7935                                                 'compact');
7936                         }
7937                         $formats_nav .=
7938                                 ' (merge: ' .
7939                                 join(' ', map {
7940                                         $cgi->a({-href => href(-replay=>1,
7941                                                                hash=>$_, hash_base=>undef)},
7942                                                 esc_html(substr($_, 0, 7)));
7943                                 } @{$co{'parents'}} ) .
7944                                 ')';
7945                 }
7946         }
7947
7948         my $hash_parent_param = $hash_parent;
7949         if (!defined $hash_parent_param) {
7950                 # --cc for multiple parents, --root for parentless
7951                 $hash_parent_param =
7952                         @{$co{'parents'}} > 1 ? '--cc' : $co{'parent'} || '--root';
7953         }
7954
7955         # read commitdiff
7956         my $fd;
7957         my @difftree;
7958         if ($format eq 'html') {
7959                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7960                         "--no-commit-id", "--patch-with-raw", "--full-index",
7961                         $hash_parent_param, $hash, "--"
7962                         or die_error(500, "Open git-diff-tree failed");
7963
7964                 while (my $line = <$fd>) {
7965                         chomp $line;
7966                         # empty line ends raw part of diff-tree output
7967                         last unless $line;
7968                         push @difftree, scalar parse_difftree_raw_line($line);
7969                 }
7970
7971         } elsif ($format eq 'plain') {
7972                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
7973                         '-p', $hash_parent_param, $hash, "--"
7974                         or die_error(500, "Open git-diff-tree failed");
7975         } elsif ($format eq 'patch') {
7976                 # For commit ranges, we limit the output to the number of
7977                 # patches specified in the 'patches' feature.
7978                 # For single commits, we limit the output to a single patch,
7979                 # diverging from the git-format-patch default.
7980                 my @commit_spec = ();
7981                 if ($hash_parent) {
7982                         if ($patch_max > 0) {
7983                                 push @commit_spec, "-$patch_max";
7984                         }
7985                         push @commit_spec, '-n', "$hash_parent..$hash";
7986                 } else {
7987                         if ($params{-single}) {
7988                                 push @commit_spec, '-1';
7989                         } else {
7990                                 if ($patch_max > 0) {
7991                                         push @commit_spec, "-$patch_max";
7992                                 }
7993                                 push @commit_spec, "-n";
7994                         }
7995                         push @commit_spec, '--root', $hash;
7996                 }
7997                 open $fd, "-|", git_cmd(), "format-patch", @diff_opts,
7998                         '--encoding=utf8', '--stdout', @commit_spec
7999                         or die_error(500, "Open git-format-patch failed");
8000         } else {
8001                 die_error(400, "Unknown commitdiff format");
8002         }
8003
8004         # non-textual hash id's can be cached
8005         my $expires;
8006         if ($hash =~ m/^$oid_regex$/) {
8007                 $expires = "+1d";
8008         }
8009
8010         # write commit message
8011         if ($format eq 'html') {
8012                 my $refs = git_get_references();
8013                 my $ref = format_ref_marker($refs, $co{'id'});
8014
8015                 git_header_html(undef, $expires);
8016                 git_print_page_nav('commitdiff','', $hash,$co{'tree'},$hash, $formats_nav);
8017                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash);
8018                 print "<div class=\"title_text\">\n" .
8019                       "<table class=\"object_header\">\n";
8020                 git_print_authorship_rows(\%co);
8021                 print "</table>".
8022                       "</div>\n";
8023                 print "<div class=\"page_body\">\n";
8024                 if (@{$co{'comment'}} > 1) {
8025                         print "<div class=\"log\">\n";
8026                         git_print_log($co{'comment'}, -final_empty_line=> 1, -remove_title => 1);
8027                         print "</div>\n"; # class="log"
8028                 }
8029
8030         } elsif ($format eq 'plain') {
8031                 my $refs = git_get_references("tags");
8032                 my $tagname = git_get_rev_name_tags($hash);
8033                 my $filename = basename($project) . "-$hash.patch";
8034
8035                 print $cgi->header(
8036                         -type => 'text/plain',
8037                         -charset => 'utf-8',
8038                         -expires => $expires,
8039                         -content_disposition => 'inline; filename="' . "$filename" . '"');
8040                 my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
8041                 print "From: " . to_utf8($co{'author'}) . "\n";
8042                 print "Date: $ad{'rfc2822'} ($ad{'tz_local'})\n";
8043                 print "Subject: " . to_utf8($co{'title'}) . "\n";
8044
8045                 print "X-Git-Tag: $tagname\n" if $tagname;
8046                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
8047
8048                 foreach my $line (@{$co{'comment'}}) {
8049                         print to_utf8($line) . "\n";
8050                 }
8051                 print "---\n\n";
8052         } elsif ($format eq 'patch') {
8053                 my $filename = basename($project) . "-$hash.patch";
8054
8055                 print $cgi->header(
8056                         -type => 'text/plain',
8057                         -charset => 'utf-8',
8058                         -expires => $expires,
8059                         -content_disposition => 'inline; filename="' . "$filename" . '"');
8060         }
8061
8062         # write patch
8063         if ($format eq 'html') {
8064                 my $use_parents = !defined $hash_parent ||
8065                         $hash_parent eq '-c' || $hash_parent eq '--cc';
8066                 git_difftree_body(\@difftree, $hash,
8067                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
8068                 print "<br/>\n";
8069
8070                 git_patchset_body($fd, $diff_style,
8071                                   \@difftree, $hash,
8072                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
8073                 close $fd;
8074                 print "</div>\n"; # class="page_body"
8075                 git_footer_html();
8076
8077         } elsif ($format eq 'plain') {
8078                 local $/ = undef;
8079                 print <$fd>;
8080                 close $fd
8081                         or print "Reading git-diff-tree failed\n";
8082         } elsif ($format eq 'patch') {
8083                 local $/ = undef;
8084                 print <$fd>;
8085                 close $fd
8086                         or print "Reading git-format-patch failed\n";
8087         }
8088 }
8089
8090 sub git_commitdiff_plain {
8091         git_commitdiff(-format => 'plain');
8092 }
8093
8094 # format-patch-style patches
8095 sub git_patch {
8096         git_commitdiff(-format => 'patch', -single => 1);
8097 }
8098
8099 sub git_patches {
8100         git_commitdiff(-format => 'patch');
8101 }
8102
8103 sub git_history {
8104         git_log_generic('history', \&git_history_body,
8105                         $hash_base, $hash_parent_base,
8106                         $file_name, $hash);
8107 }
8108
8109 sub git_search {
8110         $searchtype ||= 'commit';
8111
8112         # check if appropriate features are enabled
8113         gitweb_check_feature('search')
8114                 or die_error(403, "Search is disabled");
8115         if ($searchtype eq 'pickaxe') {
8116                 # pickaxe may take all resources of your box and run for several minutes
8117                 # with every query - so decide by yourself how public you make this feature
8118                 gitweb_check_feature('pickaxe')
8119                         or die_error(403, "Pickaxe search is disabled");
8120         }
8121         if ($searchtype eq 'grep') {
8122                 # grep search might be potentially CPU-intensive, too
8123                 gitweb_check_feature('grep')
8124                         or die_error(403, "Grep search is disabled");
8125         }
8126
8127         if (!defined $searchtext) {
8128                 die_error(400, "Text field is empty");
8129         }
8130         if (!defined $hash) {
8131                 $hash = git_get_head_hash($project);
8132         }
8133         my %co = parse_commit($hash);
8134         if (!%co) {
8135                 die_error(404, "Unknown commit object");
8136         }
8137         if (!defined $page) {
8138                 $page = 0;
8139         }
8140
8141         if ($searchtype eq 'commit' ||
8142             $searchtype eq 'author' ||
8143             $searchtype eq 'committer') {
8144                 git_search_message(%co);
8145         } elsif ($searchtype eq 'pickaxe') {
8146                 git_search_changes(%co);
8147         } elsif ($searchtype eq 'grep') {
8148                 git_search_files(%co);
8149         } else {
8150                 die_error(400, "Unknown search type");
8151         }
8152 }
8153
8154 sub git_search_help {
8155         git_header_html();
8156         git_print_page_nav('','', $hash,$hash,$hash);
8157         print <<EOT;
8158 <p><strong>Pattern</strong> is by default a normal string that is matched precisely (but without
8159 regard to case, except in the case of pickaxe). However, when you check the <em>re</em> checkbox,
8160 the pattern entered is recognized as the POSIX extended
8161 <a href="https://en.wikipedia.org/wiki/Regular_expression">regular expression</a> (also case
8162 insensitive).</p>
8163 <dl>
8164 <dt><b>commit</b></dt>
8165 <dd>The commit messages and authorship information will be scanned for the given pattern.</dd>
8166 EOT
8167         my $have_grep = gitweb_check_feature('grep');
8168         if ($have_grep) {
8169                 print <<EOT;
8170 <dt><b>grep</b></dt>
8171 <dd>All files in the currently selected tree (HEAD unless you are explicitly browsing
8172     a different one) are searched for the given pattern. On large trees, this search can take
8173 a while and put some strain on the server, so please use it with some consideration. Note that
8174 due to git-grep peculiarity, currently if regexp mode is turned off, the matches are
8175 case-sensitive.</dd>
8176 EOT
8177         }
8178         print <<EOT;
8179 <dt><b>author</b></dt>
8180 <dd>Name and e-mail of the change author and date of birth of the patch will be scanned for the given pattern.</dd>
8181 <dt><b>committer</b></dt>
8182 <dd>Name and e-mail of the committer and date of commit will be scanned for the given pattern.</dd>
8183 EOT
8184         my $have_pickaxe = gitweb_check_feature('pickaxe');
8185         if ($have_pickaxe) {
8186                 print <<EOT;
8187 <dt><b>pickaxe</b></dt>
8188 <dd>All commits that caused the string to appear or disappear from any file (changes that
8189 added, removed or "modified" the string) will be listed. This search can take a while and
8190 takes a lot of strain on the server, so please use it wisely. Note that since you may be
8191 interested even in changes just changing the case as well, this search is case sensitive.</dd>
8192 EOT
8193         }
8194         print "</dl>\n";
8195         git_footer_html();
8196 }
8197
8198 sub git_shortlog {
8199         git_log_generic('shortlog', \&git_shortlog_body,
8200                         $hash, $hash_parent);
8201 }
8202
8203 ## ......................................................................
8204 ## feeds (RSS, Atom; OPML)
8205
8206 sub git_feed {
8207         my $format = shift || 'atom';
8208         my $have_blame = gitweb_check_feature('blame');
8209
8210         # Atom: http://www.atomenabled.org/developers/syndication/
8211         # RSS:  http://www.notestips.com/80256B3A007F2692/1/NAMO5P9UPQ
8212         if ($format ne 'rss' && $format ne 'atom') {
8213                 die_error(400, "Unknown web feed format");
8214         }
8215
8216         # log/feed of current (HEAD) branch, log of given branch, history of file/directory
8217         my $head = $hash || 'HEAD';
8218         my @commitlist = parse_commits($head, 150, 0, $file_name);
8219
8220         my %latest_commit;
8221         my %latest_date;
8222         my $content_type = "application/$format+xml";
8223         if (defined $cgi->http('HTTP_ACCEPT') &&
8224                  $cgi->Accept('text/xml') > $cgi->Accept($content_type)) {
8225                 # browser (feed reader) prefers text/xml
8226                 $content_type = 'text/xml';
8227         }
8228         if (defined($commitlist[0])) {
8229                 %latest_commit = %{$commitlist[0]};
8230                 my $latest_epoch = $latest_commit{'committer_epoch'};
8231                 exit_if_unmodified_since($latest_epoch);
8232                 %latest_date = parse_date($latest_epoch, $latest_commit{'committer_tz'});
8233         }
8234         print $cgi->header(
8235                 -type => $content_type,
8236                 -charset => 'utf-8',
8237                 %latest_date ? (-last_modified => $latest_date{'rfc2822'}) : (),
8238                 -status => '200 OK');
8239
8240         # Optimization: skip generating the body if client asks only
8241         # for Last-Modified date.
8242         return if ($cgi->request_method() eq 'HEAD');
8243
8244         # header variables
8245         my $title = "$site_name - $project/$action";
8246         my $feed_type = 'log';
8247         if (defined $hash) {
8248                 $title .= " - '$hash'";
8249                 $feed_type = 'branch log';
8250                 if (defined $file_name) {
8251                         $title .= " :: $file_name";
8252                         $feed_type = 'history';
8253                 }
8254         } elsif (defined $file_name) {
8255                 $title .= " - $file_name";
8256                 $feed_type = 'history';
8257         }
8258         $title .= " $feed_type";
8259         $title = esc_html($title);
8260         my $descr = git_get_project_description($project);
8261         if (defined $descr) {
8262                 $descr = esc_html($descr);
8263         } else {
8264                 $descr = "$project " .
8265                          ($format eq 'rss' ? 'RSS' : 'Atom') .
8266                          " feed";
8267         }
8268         my $owner = git_get_project_owner($project);
8269         $owner = esc_html($owner);
8270
8271         #header
8272         my $alt_url;
8273         if (defined $file_name) {
8274                 $alt_url = href(-full=>1, action=>"history", hash=>$hash, file_name=>$file_name);
8275         } elsif (defined $hash) {
8276                 $alt_url = href(-full=>1, action=>"log", hash=>$hash);
8277         } else {
8278                 $alt_url = href(-full=>1, action=>"summary");
8279         }
8280         $alt_url = esc_attr($alt_url);
8281         print qq!<?xml version="1.0" encoding="utf-8"?>\n!;
8282         if ($format eq 'rss') {
8283                 print <<XML;
8284 <rss version="2.0" xmlns:content="http://purl.org/rss/1.0/modules/content/">
8285 <channel>
8286 XML
8287                 print "<title>$title</title>\n" .
8288                       "<link>$alt_url</link>\n" .
8289                       "<description>$descr</description>\n" .
8290                       "<language>en</language>\n" .
8291                       # project owner is responsible for 'editorial' content
8292                       "<managingEditor>$owner</managingEditor>\n";
8293                 if (defined $logo || defined $favicon) {
8294                         # prefer the logo to the favicon, since RSS
8295                         # doesn't allow both
8296                         my $img = esc_url($logo || $favicon);
8297                         print "<image>\n" .
8298                               "<url>$img</url>\n" .
8299                               "<title>$title</title>\n" .
8300                               "<link>$alt_url</link>\n" .
8301                               "</image>\n";
8302                 }
8303                 if (%latest_date) {
8304                         print "<pubDate>$latest_date{'rfc2822'}</pubDate>\n";
8305                         print "<lastBuildDate>$latest_date{'rfc2822'}</lastBuildDate>\n";
8306                 }
8307                 print "<generator>gitweb v.$version/$git_version</generator>\n";
8308         } elsif ($format eq 'atom') {
8309                 print <<XML;
8310 <feed xmlns="http://www.w3.org/2005/Atom">
8311 XML
8312                 print "<title>$title</title>\n" .
8313                       "<subtitle>$descr</subtitle>\n" .
8314                       '<link rel="alternate" type="text/html" href="' .
8315                       $alt_url . '" />' . "\n" .
8316                       '<link rel="self" type="' . $content_type . '" href="' .
8317                       $cgi->self_url() . '" />' . "\n" .
8318                       "<id>" . esc_url(href(-full=>1)) . "</id>\n" .
8319                       # use project owner for feed author
8320                       "<author><name>$owner</name></author>\n";
8321                 if (defined $favicon) {
8322                         print "<icon>" . esc_url($favicon) . "</icon>\n";
8323                 }
8324                 if (defined $logo) {
8325                         # not twice as wide as tall: 72 x 27 pixels
8326                         print "<logo>" . esc_url($logo) . "</logo>\n";
8327                 }
8328                 if (! %latest_date) {
8329                         # dummy date to keep the feed valid until commits trickle in:
8330                         print "<updated>1970-01-01T00:00:00Z</updated>\n";
8331                 } else {
8332                         print "<updated>$latest_date{'iso-8601'}</updated>\n";
8333                 }
8334                 print "<generator version='$version/$git_version'>gitweb</generator>\n";
8335         }
8336
8337         # contents
8338         for (my $i = 0; $i <= $#commitlist; $i++) {
8339                 my %co = %{$commitlist[$i]};
8340                 my $commit = $co{'id'};
8341                 # we read 150, we always show 30 and the ones more recent than 48 hours
8342                 if (($i >= 20) && ((time - $co{'author_epoch'}) > 48*60*60)) {
8343                         last;
8344                 }
8345                 my %cd = parse_date($co{'author_epoch'}, $co{'author_tz'});
8346
8347                 # get list of changed files
8348                 open my $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
8349                         $co{'parent'} || "--root",
8350                         $co{'id'}, "--", (defined $file_name ? $file_name : ())
8351                         or next;
8352                 my @difftree = map { chomp; $_ } <$fd>;
8353                 close $fd
8354                         or next;
8355
8356                 # print element (entry, item)
8357                 my $co_url = href(-full=>1, action=>"commitdiff", hash=>$commit);
8358                 if ($format eq 'rss') {
8359                         print "<item>\n" .
8360                               "<title>" . esc_html($co{'title'}) . "</title>\n" .
8361                               "<author>" . esc_html($co{'author'}) . "</author>\n" .
8362                               "<pubDate>$cd{'rfc2822'}</pubDate>\n" .
8363                               "<guid isPermaLink=\"true\">$co_url</guid>\n" .
8364                               "<link>" . esc_html($co_url) . "</link>\n" .
8365                               "<description>" . esc_html($co{'title'}) . "</description>\n" .
8366                               "<content:encoded>" .
8367                               "<![CDATA[\n";
8368                 } elsif ($format eq 'atom') {
8369                         print "<entry>\n" .
8370                               "<title type=\"html\">" . esc_html($co{'title'}) . "</title>\n" .
8371                               "<updated>$cd{'iso-8601'}</updated>\n" .
8372                               "<author>\n" .
8373                               "  <name>" . esc_html($co{'author_name'}) . "</name>\n";
8374                         if ($co{'author_email'}) {
8375                                 print "  <email>" . esc_html($co{'author_email'}) . "</email>\n";
8376                         }
8377                         print "</author>\n" .
8378                               # use committer for contributor
8379                               "<contributor>\n" .
8380                               "  <name>" . esc_html($co{'committer_name'}) . "</name>\n";
8381                         if ($co{'committer_email'}) {
8382                                 print "  <email>" . esc_html($co{'committer_email'}) . "</email>\n";
8383                         }
8384                         print "</contributor>\n" .
8385                               "<published>$cd{'iso-8601'}</published>\n" .
8386                               "<link rel=\"alternate\" type=\"text/html\" href=\"" . esc_attr($co_url) . "\" />\n" .
8387                               "<id>" . esc_html($co_url) . "</id>\n" .
8388                               "<content type=\"xhtml\" xml:base=\"" . esc_url($my_url) . "\">\n" .
8389                               "<div xmlns=\"http://www.w3.org/1999/xhtml\">\n";
8390                 }
8391                 my $comment = $co{'comment'};
8392                 print "<pre>\n";
8393                 foreach my $line (@$comment) {
8394                         $line = esc_html($line);
8395                         print "$line\n";
8396                 }
8397                 print "</pre><ul>\n";
8398                 foreach my $difftree_line (@difftree) {
8399                         my %difftree = parse_difftree_raw_line($difftree_line);
8400                         next if !$difftree{'from_id'};
8401
8402                         my $file = $difftree{'file'} || $difftree{'to_file'};
8403
8404                         print "<li>" .
8405                               "[" .
8406                               $cgi->a({-href => href(-full=>1, action=>"blobdiff",
8407                                                      hash=>$difftree{'to_id'}, hash_parent=>$difftree{'from_id'},
8408                                                      hash_base=>$co{'id'}, hash_parent_base=>$co{'parent'},
8409                                                      file_name=>$file, file_parent=>$difftree{'from_file'}),
8410                                       -title => "diff"}, 'D');
8411                         if ($have_blame) {
8412                                 print $cgi->a({-href => href(-full=>1, action=>"blame",
8413                                                              file_name=>$file, hash_base=>$commit),
8414                                               -title => "blame"}, 'B');
8415                         }
8416                         # if this is not a feed of a file history
8417                         if (!defined $file_name || $file_name ne $file) {
8418                                 print $cgi->a({-href => href(-full=>1, action=>"history",
8419                                                              file_name=>$file, hash=>$commit),
8420                                               -title => "history"}, 'H');
8421                         }
8422                         $file = esc_path($file);
8423                         print "] ".
8424                               "$file</li>\n";
8425                 }
8426                 if ($format eq 'rss') {
8427                         print "</ul>]]>\n" .
8428                               "</content:encoded>\n" .
8429                               "</item>\n";
8430                 } elsif ($format eq 'atom') {
8431                         print "</ul>\n</div>\n" .
8432                               "</content>\n" .
8433                               "</entry>\n";
8434                 }
8435         }
8436
8437         # end of feed
8438         if ($format eq 'rss') {
8439                 print "</channel>\n</rss>\n";
8440         } elsif ($format eq 'atom') {
8441                 print "</feed>\n";
8442         }
8443 }
8444
8445 sub git_rss {
8446         git_feed('rss');
8447 }
8448
8449 sub git_atom {
8450         git_feed('atom');
8451 }
8452
8453 sub git_opml {
8454         my @list = git_get_projects_list($project_filter, $strict_export);
8455         if (!@list) {
8456                 die_error(404, "No projects found");
8457         }
8458
8459         print $cgi->header(
8460                 -type => 'text/xml',
8461                 -charset => 'utf-8',
8462                 -content_disposition => 'inline; filename="opml.xml"');
8463
8464         my $title = esc_html($site_name);
8465         my $filter = " within subdirectory ";
8466         if (defined $project_filter) {
8467                 $filter .= esc_html($project_filter);
8468         } else {
8469                 $filter = "";
8470         }
8471         print <<XML;
8472 <?xml version="1.0" encoding="utf-8"?>
8473 <opml version="1.0">
8474 <head>
8475   <title>$title OPML Export$filter</title>
8476 </head>
8477 <body>
8478 <outline text="git RSS feeds">
8479 XML
8480
8481         foreach my $pr (@list) {
8482                 my %proj = %$pr;
8483                 my $head = git_get_head_hash($proj{'path'});
8484                 if (!defined $head) {
8485                         next;
8486                 }
8487                 $git_dir = "$projectroot/$proj{'path'}";
8488                 my %co = parse_commit($head);
8489                 if (!%co) {
8490                         next;
8491                 }
8492
8493                 my $path = esc_html(chop_str($proj{'path'}, 25, 5));
8494                 my $rss  = esc_attr(href('project' => $proj{'path'}, 'action' => 'rss', -full => 1));
8495                 my $html = esc_attr(href('project' => $proj{'path'}, 'action' => 'summary', -full => 1));
8496                 print "<outline type=\"rss\" text=\"$path\" title=\"$path\" xmlUrl=\"$rss\" htmlUrl=\"$html\"/>\n";
8497         }
8498         print <<XML;
8499 </outline>
8500 </body>
8501 </opml>
8502 XML
8503 }