Lady’s Gitweb - Shushe/blob - lib/catalog2parser.xslt

   1 <?xml version="1.0"?>
   2 <!--
   3 ⁌ ⛩️📰 书社 ∷ lib/catalog2parser.xslt
   4
   5 © 2023–2024 Lady [@ Lady’s Computer]
   6
   7 This Source Code Form is subject to the terms of the Mozilla Public License, v 2.0.
   8 If a copy of the M·P·L was not distributed with this file, You can obtain one at <https://mozilla.org/MPL/2.0/>.
   9 -->
  10 <transform
  11         xmlns="http://www.w3.org/1999/XSL/Transform"
  12         xmlns:catalog="urn:oasis:names:tc:entity:xmlns:xml:catalog"
  13         xmlns:exsl="http://exslt.org/common"
  14         xmlns:exslstr="http://exslt.org/strings"
  15         xmlns:html="http://www.w3.org/1999/xhtml"
  16         xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  17         xmlns:xslt="http://www.w3.org/1999/XSL/TransformAlias"
  18         xmlns:书社="urn:fdc:ladys.computer:20231231:Shu1She4"
  19         exclude-result-prefixes="catalog exslstr"
  20         version="1.0"
  21 >
  22         <namespace-alias stylesheet-prefix="xslt" result-prefix="#default"/>
  23         <template match="/">
  24                 <xslt:transform version="1.0">
  25                         <xslt:param name="BUILDTIME" select="'1972-12-31T00:00:00Z'"/>
  26                         <xslt:param name="GENERATOR" select="false"/>
  27                         <xslt:param name="SRCREV" select="false"/>
  28                         <xslt:param name="SRCTIME" select="'1972-12-31T00:00:00Z'"/>
  29                         <xslt:param name="VERSION" select="false"/>
  30                         <xslt:variable name="书社:parsers">
  31                                 <html:dl>
  32                                         <for-each select="//catalog:uri">
  33                                                 <variable name="parser" select="document(@uri, .)"/>
  34                                                 <html:div>
  35                                                         <html:dt>
  36                                                                 <value-of select="@name"/>
  37                                                         </html:dt>
  38                                                         <choose>
  39                                                                 <when test="$parser/*/@书社:supported-media-types">
  40                                                                         <for-each select="exslstr:tokenize($parser/*/@书社:supported-media-types)">
  41                                                                                 <if test="not(translate(., '0123456789abcdefghijklmnopqrstuvwxyz!#$&#x26;-^_.+/', ''))">
  42                                                                                         <html:dd>
  43                                                                                                 <value-of select="."/>
  44                                                                                         </html:dd>
  45                                                                                 </if>
  46                                                                         </for-each>
  47                                                                 </when>
  48                                                                 <otherwise>
  49                                                                         <for-each select="$parser//xsl:template[not(@name) and not(@mode)]">
  50                                                                                 <variable name="match" select="@match"/>
  51                                                                                 <for-each select="namespace::*[local-name() and string()='http://www.w3.org/1999/xhtml']">
  52                                                                                         <variable name="matchstart">
  53                                                                                                 <value-of select="local-name()"/>
  54                                                                                                 <text>:</text>
  55                                                                                                 <text>script[@type=</text>
  56                                                                                         </variable>
  57                                                                                         <if test="starts-with($match, $matchstart) and substring($match, string-length($match))=']' and contains($match, '/')">
  58                                                                                                 <variable name="inner" select="substring-before(substring-after($match, $matchstart), ']')"/>
  59                                                                                                 <if test="starts-with($inner, '&#x22;') and substring($inner, string-length($inner))='&#x22;' or starts-with($inner, &#x22;'&#x22;) and substring($inner, string-length($inner))=&#x22;'&#x22;">
  60                                                                                                         <variable name="type" select="substring($inner, 2, string-length($inner)-2)"/>
  61                                                                                                         <if test="not(translate($type, '0123456789abcdefghijklmnopqrstuvwxyz!#$&#x26;-^_.+/', ''))">
  62                                                                                                                 <html:dd>
  63                                                                                                                         <value-of select="$type"/>
  64                                                                                                                 </html:dd>
  65                                                                                                         </if>
  66                                                                                                 </if>
  67                                                                                         </if>
  68                                                                                 </for-each>
  69                                                                         </for-each>
  70                                                                 </otherwise>
  71                                                         </choose>
  72                                                 </html:div>
  73                                         </for-each>
  74                                 </html:dl>
  75                         </xslt:variable>
  76                         <for-each select="//catalog:uri">
  77                                 <xslt:include href="{@uri}">
  78                                         <if test="contains(@name, ':')">
  79                                                 <attribute name="书社:id">
  80                                                         <value-of select="@name"/>
  81                                                 </attribute>
  82                                         </if>
  83                                 </xslt:include>
  84                         </for-each>
  85                         <xslt:template name="书社:apply-parsed-by">
  86                                 <xslt:param name="id"/>
  87                                 <xslt:param name="result" select="/.."/>
  88                                 <xslt:for-each select="$result/node()">
  89                                         <xslt:copy>
  90                                                 <xslt:attribute name="书社:parsed-by">
  91                                                         <xslt:value-of select="$id"/>
  92                                                         <xslt:if test="@书社:parsed-by">
  93                                                                 <xslt:text> </xslt:text>
  94                                                                 <xslt:value-of select="@书社:parsed-by"/>
  95                                                         </xslt:if>
  96                                                 </xslt:attribute>
  97                                                 <xslt:copy-of select="@*[not(namespace-uri()='urn:fdc:ladys.computer:20231231:Shu1She4' and local-name()='parsed-by')]|node()"/>
  98                                         </xslt:copy>
  99                                 </xslt:for-each>
 100                         </xslt:template>
 101                         <xslt:template match="/">
 102                                 <xslt:apply-templates select="node()" mode="书社:parse"/>
 103                         </xslt:template>
 104                         <xslt:template match="@*|node()" priority="-1">
 105                                 <xslt:copy>
 106                                         <xslt:apply-templates select="@*|node()" mode="书社:parse"/>
 107                                 </xslt:copy>
 108                         </xslt:template>
 109                         <xslt:template match="html:script[@type]" mode="书社:parse" priority="1">
 110                                 <xslt:variable name="parserdiv" select="exsl:node-set($书社:parsers)//html:div[html:dd=current()/@type]"/>
 111                                 <xslt:choose>
 112                                         <xslt:when test="$parserdiv">
 113                                                 <xslt:variable name="result">
 114                                                         <xslt:apply-templates select="."/>
 115                                                 </xslt:variable>
 116                                                 <xslt:variable name="reparsed-result">
 117                                                         <xslt:apply-templates select="exsl:node-set($result)/node()" mode="书社:parse"/>
 118                                                 </xslt:variable>
 119                                                 <xslt:call-template name="书社:apply-parsed-by">
 120                                                         <xslt:with-param name="id" select="$parserdiv/html:dt"/>
 121                                                         <xslt:with-param name="result" select="exsl:node-set($reparsed-result)"/>
 122                                                 </xslt:call-template>
 123                                         </xslt:when>
 124                                         <xslt:otherwise>
 125                                                 <xslt:apply-templates select="."/>
 126                                         </xslt:otherwise>
 127                                 </xslt:choose>
 128                         </xslt:template>
 129                         <xslt:template match="@*|node()" mode="书社:parse">
 130                                 <xslt:apply-templates select="."/>
 131                         </xslt:template>
 132                 </xslt:transform>
 133         </template>
 134         <output method="xml" encoding="UTF-8"/>
 135 </transform>