Lady’s Gitweb - Shushe/blob - lib/catalog2transform.xslt

   1 <?xml version="1.0"?>
   2 <!--
   3 SPDX-FileCopyrightText: 2023, 2024 Lady <https://www.ladys.computer/about/#lady>
   4 SPDX-License-Identifier: MPL-2.0
   5 -->
   6 <!--
   7 ⁌ ⛩📰 书社 ∷ lib/catalog2transform.xslt
   8
   9 © 2023–2024 Lady [@ Ladys Computer].
  10
  11 This Source Code Form is subject to the terms of the Mozilla Public License, v 2.0.
  12 If a copy of the M·P·L was not distributed with this file, You can obtain one at <https://mozilla.org/MPL/2.0/>.
  13 -->
  14 <!DOCTYPE transform [
  15         <!ENTITY 书社 "urn:fdc:ladys.computer:20231231:Shu1She4">
  16         <!ENTITY xml "http://www.w3.org/XML/1998/namespace">
  17 ]>
  18 <transform
  19         xmlns="http://www.w3.org/1999/XSL/Transform"
  20         xmlns:dct="http://purl.org/dc/terms/"
  21         xmlns:catalog="urn:oasis:names:tc:entity:xmlns:xml:catalog"
  22         xmlns:exsl="http://exslt.org/common"
  23         xmlns:exslstr="http://exslt.org/strings"
  24         xmlns:html="http://www.w3.org/1999/xhtml"
  25         xmlns:nie="http://www.semanticdesktop.org/ontologies/2007/01/19/nie#"
  26         xmlns:nfo="http://www.semanticdesktop.org/ontologies/2007/03/22/nfo#"
  27         xmlns:rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"
  28         xmlns:svg="http://www.w3.org/2000/svg"
  29         xmlns:xlink="http://www.w3.org/1999/xlink"
  30         xmlns:xslt="http://www.w3.org/1999/XSL/TransformAlias"
  31         xmlns:书社="urn:fdc:ladys.computer:20231231:Shu1She4"
  32         exclude-result-prefixes="catalog"
  33         version="1.0"
  34 >
  35         <include href="literally.xslt"/>
  36         <namespace-alias stylesheet-prefix="xslt" result-prefix="#default"/>
  37         <param name="METADATA" select="'about:blank'"/>
  38         <template match="/">
  39                 <variable name="ids">
  40                         <for-each select="//catalog:uri[@name]">
  41                                 <书社:id>
  42                                         <value-of select="@name"/>
  43                                 </书社:id>
  44                         </for-each>
  45                 </variable>
  46                 <variable name="unique-ids">
  47                         <for-each select="exsl:node-set($ids)/*">
  48                                 <if test="not(preceding-sibling::*[string(.)=string(current())])">
  49                                         <copy-of select="."/>
  50                                 </if>
  51                         </for-each>
  52                 </variable>
  53                 <xslt:transform exclude-result-prefixes="nie nfo" extension-element-prefixes="exsl exslstr" version="1.0">
  54                         <xslt:param name="BUILDTIME" select="'1972-12-31T00:00:00Z'"/>
  55                         <xslt:param name="IDENTIFIER" select="false()"/>
  56                         <xslt:param name="PATH" select="'/unknown'"/>
  57                         <xslt:param name="SRCREV" select="false()"/>
  58                         <xslt:param name="THISREV" select="false()"/>
  59                         <xslt:variable name="书社:source" select="/"/>
  60                         <xslt:variable name="书社:about-fragment">
  61                                 <apply-templates select="document($METADATA)" mode="书社:literally">
  62                                         <with-param name="extension-element-namespaces" select="'http://exslt.org/common http://exslt.org/strings'"/>
  63                                 </apply-templates>
  64                         </xslt:variable>
  65                         <xslt:variable name="书社:about" select="exsl:node-set($书社:about-fragment)"/>
  66                         <xslt:variable name="书社:expansion-fragment">
  67                                 <xslt:apply-templates select="$书社:source/node()" mode="书社:expand"/>
  68                         </xslt:variable>
  69                         <xslt:variable name="书社:expansion" select="exsl:node-set($书社:expansion-fragment)"/>
  70                         <xslt:variable name="书社:result-fragment">
  71                                 <xslt:apply-templates select="$书社:expansion/node()"/>
  72                         </xslt:variable>
  73                         <xslt:variable name="书社:result" select="exsl:node-set($书社:result-fragment)"/>
  74                         <xslt:variable name="书社:destination">
  75                                 <xslt:choose>
  76                                         <xslt:when test="string($书社:source/@书社:destination)!=''">
  77                                                 <xslt:value-of select="$书社:source/@书社:destination"/>
  78                                         </xslt:when>
  79                                         <xslt:when test="starts-with($PATH, '/')">
  80                                                 <xslt:value-of select="substring-after($PATH, '/')"/>
  81                                         </xslt:when>
  82                                         <xslt:otherwise>
  83                                                 <xslt:value-of select="$PATH"/>
  84                                         </xslt:otherwise>
  85                                 </xslt:choose>
  86                         </xslt:variable>
  87                         <for-each select="//catalog:uri">
  88                                 <xslt:include href="{@uri}">
  89                                         <attribute name="书社:id">
  90                                                 <value-of select="@name"/>
  91                                         </attribute>
  92                                 </xslt:include>
  93                         </for-each>
  94                         <xslt:template name="书社:apply-attributes">
  95                                 <xslt:param name="and-version" select="false()"/>
  96                                 <xslt:param name="context-nodes" select="/.."/>
  97                                 <xslt:param name="destination-nodes" select="/.."/>
  98                                 <xslt:variable name="additional-attributes" select="$context-nodes/@*"/>
  99                                 <xslt:for-each select="$destination-nodes">
 100                                         <xslt:variable name="existing-attributes" select="@*"/>
 101                                         <xslt:choose>
 102                                                 <xslt:when test="self::*">
 103                                                         <xslt:variable name="context" select="."/>
 104                                                         <xslt:variable name="attribute-names">
 105                                                                 <xslt:for-each select="$existing-attributes|$additional-attributes">
 106                                                                         <书社:attribute>
 107                                                                                 <attribute name="local-name">
 108                                                                                         <text>{local-name()}</text>
 109                                                                                 </attribute>
 110                                                                                 <attribute name="name">
 111                                                                                         <text>{name()}</text>
 112                                                                                 </attribute>
 113                                                                                 <attribute name="namespace-uri">
 114                                                                                         <text>{namespace-uri()}</text>
 115                                                                                 </attribute>
 116                                                                         </书社:attribute>
 117                                                                 </xslt:for-each>
 118                                                         </xslt:variable>
 119                                                         <xslt:variable name="lang">
 120                                                                 <xslt:choose>
 121                                                                         <xslt:when test="(self::html:*|self::svg:*)/@lang">
 122                                                                                 <xslt:value-of select="@lang"/>
 123                                                                         </xslt:when>
 124                                                                         <xslt:when test="@xml:lang">
 125                                                                                 <xslt:value-of select="@xml:lang"/>
 126                                                                         </xslt:when>
 127                                                                         <xslt:when test="$additional-attributes[(parent::html:* or parent::svg:*) and namespace-uri()='' and local-name()='lang']">
 128                                                                                 <xslt:value-of select="$additional-attributes[(parent::html:* or parent::svg:*) and namespace-uri()='' and local-name()='lang']"/>
 129                                                                         </xslt:when>
 130                                                                         <xslt:when test="(self::html:* or self::svg:*) and $additional-attributes[(parent::书社:apply-attributes or parent::书社:apply-attributes-to-root) and namespace-uri()='' and local-name()='lang']">
 131                                                                                 <xslt:value-of select="$additional-attributes[(parent::书社:apply-attributes or parent::书社:apply-attributes-to-root) and namespace-uri()='' and local-name()='lang']"/>
 132                                                                         </xslt:when>
 133                                                                         <xslt:when test="$additional-attributes[namespace-uri()='&xml;' and local-name()='lang']">
 134                                                                                 <xslt:value-of select="$additional-attributes[namespace-uri()='&xml;' and local-name()='lang']"/>
 135                                                                         </xslt:when>
 136                                                                 </xslt:choose>
 137                                                         </xslt:variable>
 138                                                         <xslt:copy>
 139                                                                 <xslt:if test="$and-version and $THISREV">
 140                                                                         <xslt:attribute name="书社:version">
 141                                                                                 <xslt:value-of select="$THISREV"/>
 142                                                                         </xslt:attribute>
 143                                                                 </xslt:if>
 144                                                                 <xslt:if test="string($lang)!=''">
 145                                                                         <xslt:if test="self::html:* or self::svg:*">
 146                                                                                 <xslt:attribute name="lang">
 147                                                                                         <xslt:value-of select="$lang"/>
 148                                                                                 </xslt:attribute>
 149                                                                         </xslt:if>
 150                                                                         <xslt:attribute name="xml:lang">
 151                                                                                 <xslt:value-of select="$lang"/>
 152                                                                         </xslt:attribute>
 153                                                                 </xslt:if>
 154                                                                 <xslt:for-each select="exsl:node-set($attribute-names)/*">
 155                                                                         <xslt:choose>
 156                                                                                 <xslt:when test="@namespace-uri='&xml;'"/>
 157                                                                                 <xslt:when test="$context[self::html:* or self::svg:*] and @namespace-uri='' and @local-name='lang'"/>
 158                                                                                 <xslt:when test="@namespace-uri='&书社;' and @local-name='archived-as' and not($context-nodes/ancestor::*[not(self::书社:apply-attributes-to-root or self::书社:apply-attributes)][1][self::书社:archive])"/>
 159                                                                                 <xslt:when test="@namespace-uri='&书社;' and (@local-name='destination' or @local-name='disable-output-wrapping' or @local-name='version')"/>
 160                                                                                 <xslt:when test="preceding-sibling::*[@local-name=current()/@local-name and @namespace-uri=current()/@namespace-uri]"/>
 161                                                                                 <xslt:otherwise>
 162                                                                                         <xslt:attribute>
 163                                                                                                 <attribute name="name">
 164                                                                                                         <text>{@name}</text>
 165                                                                                                 </attribute>
 166                                                                                                 <attribute name="namespace">
 167                                                                                                         <text>{@namespace-uri}</text>
 168                                                                                                 </attribute>
 169                                                                                                 <xslt:for-each select="$existing-attributes[local-name()=current()/@local-name and namespace-uri()=current()/@namespace-uri]">
 170                                                                                                         <xslt:value-of select="."/>
 171                                                                                                         <xslt:if test="position()!=last()">
 172                                                                                                                 <xslt:text>
 173                                                                                                                         <text> </text>
 174                                                                                                                 </xslt:text>
 175                                                                                                         </xslt:if>
 176                                                                                                 </xslt:for-each>
 177                                                                                                 <xslt:if test="$existing-attributes[local-name()=current()/@local-name and namespace-uri()=current()/@namespace-uri] and $additional-attributes[local-name()=current()/@local-name and namespace-uri()=current()/@namespace-uri]">
 178                                                                                                         <xslt:text>
 179                                                                                                                 <text> </text>
 180                                                                                                         </xslt:text>
 181                                                                                                 </xslt:if>
 182                                                                                                 <xslt:for-each select="$additional-attributes[local-name()=current()/@local-name and namespace-uri()=current()/@namespace-uri]">
 183                                                                                                         <xslt:value-of select="."/>
 184                                                                                                         <xslt:if test="position()!=last()">
 185                                                                                                                 <xslt:text>
 186                                                                                                                         <text> </text>
 187                                                                                                                 </xslt:text>
 188                                                                                                         </xslt:if>
 189                                                                                                 </xslt:for-each>
 190                                                                                         </xslt:attribute>
 191                                                                                 </xslt:otherwise>
 192                                                                         </xslt:choose>
 193                                                                 </xslt:for-each>
 194                                                                 <xslt:copy-of select="node()"/>
 195                                                         </xslt:copy>
 196                                                 </xslt:when>
 197                                                 <xslt:otherwise>
 198                                                         <xslt:copy-of select="."/>
 199                                                 </xslt:otherwise>
 200                                         </xslt:choose>
 201                                 </xslt:for-each>
 202                         </xslt:template>
 203                         <xslt:template name="书社:wrap">
 204                                 <xslt:param name="nodes" select="/.."/>
 205                                 <xslt:variable name="modalinput">
 206                                         <xslt:copy-of select="$nodes"/>
 207                                         <apply-templates select="exsl:node-set($unique-ids)" mode="书社:literally"/>
 208                                 </xslt:variable>
 209                                 <xslt:variable name="metadata">
 210                                         <xslt:copy-of select="$nodes[self::html:html]/html:head/node()|$nodes[self::html:head]/node()"/>
 211                                         <xslt:apply-templates select="exsl:node-set($modalinput)/node()" mode="书社:metadata"/>
 212                                 </xslt:variable>
 213                                 <html:html>
 214                                         <xslt:copy-of select="$nodes[self::html:html]/@*"/>
 215                                         <xslt:if test="not($nodes[self::html:html]/@书社:archived-as) and $nodes/@书社:archived-as">
 216                                                 <xslt:attribute name="书社:archived-as">
 217                                                         <xslt:value-of select="$nodes/@书社:archived-as"/>
 218                                                 </xslt:attribute>
 219                                         </xslt:if>
 220                                         <xslt:if test="not($nodes[self::html:html]/@lang) and $nodes[self::html:*]/@lang|$nodes[self::svg:*]/@lang|$nodes/@xml:lang">
 221                                                 <xslt:attribute name="lang">
 222                                                         <xslt:value-of select="$nodes[self::html:*]/@lang|$nodes[self::svg:*]/@lang|$nodes/@xml:lang"/>
 223                                                 </xslt:attribute>
 224                                         </xslt:if>
 225                                         <xslt:if test="not($nodes[self::html:html]/@xml:lang) and $nodes[self::html:*]/@lang|$nodes[self::svg:*]/@lang|$nodes/@xml:lang">
 226                                                 <xslt:attribute name="xml:lang">
 227                                                         <xslt:value-of select="$nodes[self::html:*]/@lang|$nodes[self::svg:*]/@lang|$nodes/@xml:lang"/>
 228                                                 </xslt:attribute>
 229                                         </xslt:if>
 230                                         <html:head>
 231                                                 <xslt:copy-of select="$nodes[self::html:html]/html:head/@*|$nodes[self::html:head]/@*"/>
 232                                                 <html:title>
 233                                                         <xslt:for-each select="exsl:node-set($metadata)/html:title">
 234                                                                 <xslt:value-of select="."/>
 235                                                                 <xslt:if test="position()!=last()">
 236                                                                         <xslt:text>
 237                                                                                 <text> </text>
 238                                                                         </xslt:text>
 239                                                                 </xslt:if>
 240                                                         </xslt:for-each>
 241                                                 </html:title>
 242                                                 <xslt:copy-of select="exsl:node-set($metadata)/node()[not(self::html:title)]"/>
 243                                                 <html:meta name="generator">
 244                                                         <xslt:attribute name="content">
 245                                                                 <xslt:for-each select="exsl:node-set($metadata)/html:meta[@name='generator']">
 246                                                                         <xslt:value-of select="@content"/>
 247                                                                         <xslt:text>
 248                                                                                 <text>, </text>
 249                                                                         </xslt:text>
 250                                                                 </xslt:for-each>
 251                                                                 <xslt:text>
 252                                                                         <text>⛩📰 书社</text>
 253                                                                 </xslt:text>
 254                                                                 <xslt:if test="$THISREV">
 255                                                                         <xslt:text>
 256                                                                                 <text> (</text>
 257                                                                         </xslt:text>
 258                                                                         <xslt:value-of select="$THISREV"/>
 259                                                                         <xslt:text>
 260                                                                                 <text>)</text>
 261                                                                         </xslt:text>
 262                                                                 </xslt:if>
 263                                                         </xslt:attribute>
 264                                                 </html:meta>
 265                                         </html:head>
 266                                         <html:body>
 267                                                 <xslt:copy-of select="$nodes[self::html:html]/html:body/@*|$nodes[self::html:body]/@*"/>
 268                                                 <xslt:apply-templates select="exsl:node-set($modalinput)/node()" mode="书社:header"/>
 269                                                 <xslt:copy-of select="$nodes[not(self::html:html or self::html:head or self::html:body)]|$nodes[self::html:html]/node()[not(self::html:head or self::html:body)]|$nodes[self::html:html]/html:body/node()|$nodes[self::html:body]/node()"/>
 270                                                 <xslt:apply-templates select="exsl:node-set($modalinput)/node()" mode="书社:footer"/>
 271                                         </html:body>
 272                                 </html:html>
 273                         </xslt:template>
 274                         <xslt:template match="/" priority="1">
 275                                 <xslt:variable name="result-nodes" select="$书社:result/node()[not(self::书社:apply-attributes-to-root)]|$书社:result/书社:apply-attributes-to-root/descendant::node()[not(self::书社:apply-attributes-to-root) and not(ancestor::*[not(self::书社:apply-attributes-to-root)])]"/>
 276                                 <xslt:variable name="root-with-attributes">
 277                                         <xslt:choose>
 278                                                 <xslt:when test="not($result-nodes/self::html:*) or $result-nodes/self::书社:*[local-name()='raw-text' or local-name()='base64-binary' or local-name()='archive'] or $result-nodes/@书社:disable-output-wrapping or $书社:result//书社:apply-attributes-to-root/@书社:disable-output-wrapping">
 279                                                         <xslt:call-template name="书社:apply-attributes">
 280                                                                 <xslt:with-param name="and-version" select="true()"/>
 281                                                                 <xslt:with-param name="context-nodes" select="$书社:result//书社:apply-attributes-to-root"/>
 282                                                                 <xslt:with-param name="destination-nodes" select="$result-nodes"/>
 283                                                         </xslt:call-template>
 284                                                 </xslt:when>
 285                                                 <xslt:otherwise>
 286                                                         <xslt:variable name="wrapped-result">
 287                                                                 <xslt:call-template name="书社:wrap">
 288                                                                         <xslt:with-param name="nodes" select="$result-nodes"/>
 289                                                                 </xslt:call-template>
 290                                                         </xslt:variable>
 291                                                         <xslt:call-template name="书社:apply-attributes">
 292                                                                 <xslt:with-param name="and-version" select="true()"/>
 293                                                                 <xslt:with-param name="context-nodes" select="$书社:result//书社:apply-attributes-to-root"/>
 294                                                                 <xslt:with-param name="destination-nodes" select="exsl:node-set($wrapped-result)/node()"/>
 295                                                         </xslt:call-template>
 296                                                 </xslt:otherwise>
 297                                         </xslt:choose>
 298                                 </xslt:variable>
 299                                 <xslt:apply-templates select="exsl:node-set($root-with-attributes)/node()" mode="书社:apply"/>
 300                         </xslt:template>
 301                         <xslt:template match="@*|node()" priority="-1">
 302                                 <xslt:copy>
 303                                         <xslt:apply-templates select="@*|node()"/>
 304                                 </xslt:copy>
 305                         </xslt:template>
 306                         <xslt:template match="@*|node()" mode="书社:apply">
 307                                 <xslt:copy>
 308                                         <xslt:apply-templates select="@*|node()" mode="书社:apply"/>
 309                                 </xslt:copy>
 310                         </xslt:template>
 311                         <xslt:template match="@书社:destination|@书社:disable-output-wrapping|@书社:archived-as[../ancestor::*[not(self::书社:apply-attributes-to-root or self::书社:apply-attributes)]]" mode="书社:apply" priority="1"/>
 312                         <xslt:template match="书社:archive" mode="书社:apply" priority="1">
 313                                 <xslt:copy>
 314                                         <xslt:for-each select="@*">
 315                                                 <xslt:choose>
 316                                                         <xslt:when test="local-name()='archived-as' and namespace-uri()='&书社;' and ../ancestor::*[not(self::书社:apply-attributes-to-root or self::书社:apply-attributes)]"/>
 317                                                         <xslt:otherwise>
 318                                                                 <xslt:apply-templates select="." mode="书社:apply"/>
 319                                                         </xslt:otherwise>
 320                                                 </xslt:choose>
 321                                         </xslt:for-each>
 322                                         <xslt:for-each select="node()">
 323                                                 <xslt:choose>
 324                                                         <xslt:when test="self::*">
 325                                                                 <xslt:variable name="component">
 326                                                                         <xslt:choose>
 327                                                                                 <xslt:when test="self::书社:*[local-name()='raw-text' or local-name()='base64-binary' or local-name()='archive']|@书社:disable-output-wrapping">
 328                                                                                         <xslt:copy-of select="."/>
 329                                                                                 </xslt:when>
 330                                                                                 <xslt:otherwise>
 331                                                                                         <xslt:call-template name="书社:wrap">
 332                                                                                                 <xslt:with-param name="nodes" select="."/>
 333                                                                                         </xslt:call-template>
 334                                                                                 </xslt:otherwise>
 335                                                                         </xslt:choose>
 336                                                                 </xslt:variable>
 337                                                                 <xslt:apply-templates select="exsl:node-set($component)/node()" mode="书社:apply"/>
 338                                                         </xslt:when>
 339                                                         <xslt:otherwise>
 340                                                                 <xslt:apply-templates select="." mode="书社:apply"/>
 341                                                         </xslt:otherwise>
 342                                                 </xslt:choose>
 343                                         </xslt:for-each>
 344                                 </xslt:copy>
 345                         </xslt:template>
 346                         <xslt:template match="书社:apply-attributes" mode="书社:apply" priority="1">
 347                                 <xslt:variable name="children">
 348                                         <xslt:apply-templates mode="书社:apply"/>
 349                                 </xslt:variable>
 350                                 <xslt:call-template name="书社:apply-attributes">
 351                                         <xslt:with-param name="context-nodes" select="."/>
 352                                         <xslt:with-param name="destination-nodes" select="exsl:node-set($children)/node()"/>
 353                                 </xslt:call-template>
 354                         </xslt:template>
 355                         <xslt:template match="书社:apply-attributes-to-root" mode="书社:apply" priority="1">
 356                                 <xslt:apply-templates mode="书社:apply"/>
 357                         </xslt:template>
 358                         <xslt:template match="书社:link[@xlink:show='embed']" mode="书社:expand" priority="1">
 359                                 <xslt:variable name="identifier" select="string(@xlink:href)"/>
 360                                 <xslt:variable name="uri" select="document($METADATA)//*[@rdf:about=$identifier]/dct:hasFormat/*[nie:interpretedAs/*[@nie:mimeType='application/xml']]/@nfo:fileUrl[1]"/>
 361                                 <xslt:choose>
 362                                         <xslt:when test="$uri">
 363                                                 <xslt:variable name="expanded">
 364                                                         <xslt:apply-templates select="document($uri)" mode="书社:expand">
 365                                                                 <xslt:with-param name="identifier" select="$identifier"/>
 366                                                         </xslt:apply-templates>
 367                                                 </xslt:variable>
 368                                                 <xslt:for-each select="exsl:node-set($expanded)/node()">
 369                                                         <xslt:copy>
 370                                                                 <xslt:choose>
 371                                                                         <xslt:when test="self::html:*">
 372                                                                                 <xslt:attribute name="itemscope">itemscope</xslt:attribute>
 373                                                                                 <xslt:attribute name="itemtype">
 374                                                                                         <xslt:text>
 375                                                                                                 <text>&书社;:embed</text>
 376                                                                                         </xslt:text>
 377                                                                                         <xslt:for-each select="exslstr:tokenize(@itemtype)/token[string()!='&书社;:document']">
 378                                                                                                 <xslt:text>
 379                                                                                                         <text> </text>
 380                                                                                                 </xslt:text>
 381                                                                                                 <xslt:value-of select="."/>
 382                                                                                         </xslt:for-each>
 383                                                                                 </xslt:attribute>
 384                                                                                 <xslt:copy-of select="@*[not(namespace-uri()='' and (local-name()='itemscope' or local-name()='itemtype'))]|node()"/>
 385                                                                         </xslt:when>
 386                                                                         <xslt:otherwise>
 387                                                                                 <xslt:apply-templates select="@*|node()" mode="书社:expand"/>
 388                                                                         </xslt:otherwise>
 389                                                                 </xslt:choose>
 390                                                         </xslt:copy>
 391                                                 </xslt:for-each>
 392                                         </xslt:when>
 393                                         <xslt:otherwise>
 394                                                 <xslt:copy>
 395                                                         <xslt:apply-templates select="@*|node()" mode="书社:expand"/>
 396                                                 </xslt:copy>
 397                                         </xslt:otherwise>
 398                                 </xslt:choose>
 399                         </xslt:template>
 400                         <xslt:template match="/node()" mode="书社:expand" priority="0">
 401                                 <xslt:param name="identifier" select="$IDENTIFIER"/>
 402                                 <xslt:copy>
 403                                         <xslt:if test="self::*">
 404                                                 <xslt:attribute name="书社:cksum">
 405                                                         <xslt:value-of select="$书社:about//*[@rdf:about=$identifier]/nfo:hasHash[@nfo:hashAlgorithm='CRC32']/@nfo:hashValue"/>
 406                                                 </xslt:attribute>
 407                                                 <xslt:attribute name="书社:identifier">
 408                                                         <xslt:value-of select="$identifier"/>
 409                                                 </xslt:attribute>
 410                                                 <xslt:attribute name="书社:mtime">
 411                                                         <xslt:value-of select="$书社:about//*[@rdf:about=$identifier]/nfo:fileLastModified"/>
 412                                                 </xslt:attribute>
 413                                         </xslt:if>
 414                                         <xslt:choose>
 415                                                 <xslt:when test="self::html:*">
 416                                                         <xslt:attribute name="itemscope">itemscope</xslt:attribute>
 417                                                         <xslt:attribute name="itemtype">
 418                                                                 <xslt:text>
 419                                                                         <text>&书社;:document</text>
 420                                                                 </xslt:text>
 421                                                                 <xslt:for-each select="exslstr:tokenize(@itemtype)/token">
 422                                                                         <xslt:text>
 423                                                                                 <text> </text>
 424                                                                         </xslt:text>
 425                                                                         <xslt:value-of select="."/>
 426                                                                 </xslt:for-each>
 427                                                         </xslt:attribute>
 428                                                         <xslt:apply-templates select="@*[not(namespace-uri()='' and (local-name()='itemscope' or local-name()='itemtype') or namespace-uri()='&书社;' and (local-name()='cksum' or local-name()='identifier' or local-name()='mtime'))]|node()" mode="书社:expand"/>
 429                                                 </xslt:when>
 430                                                 <xslt:otherwise>
 431                                                         <xslt:apply-templates select="@*[not(namespace-uri()='&书社;' and (local-name()='cksum' or local-name()='identifier' or local-name()='mtime'))]|node()" mode="书社:expand"/>
 432                                                 </xslt:otherwise>
 433                                         </xslt:choose>
 434                                 </xslt:copy>
 435                         </xslt:template>
 436                         <xslt:template match="@*|node()[not(self::书社:link) or not(@xlink:show='embed')]" mode="书社:expand" priority="-1">
 437                                 <xslt:copy>
 438                                         <xslt:apply-templates select="@*|node()" mode="书社:expand"/>
 439                                 </xslt:copy>
 440                         </xslt:template>
 441                         <xslt:template match="text()" mode="书社:header"/>
 442                         <xslt:template match="text()" mode="书社:footer"/>
 443                         <xslt:template match="text()" mode="书社:metadata"/>
 444                         <xslt:output method="xml" encoding="UTF-8" cdata-section-elements="html:script html:style html:textarea 书社:raw-output 书社:raw-text"/>
 445                 </xslt:transform>
 446         </template>
 447         <output method="xml" encoding="UTF-8"/>
 448 </transform>